         TITLE 'PSGMT --IFFAFA02'                                       00090013
*********************************************************************** 00180013
*                                                                       00270013
*TITLE         PSGMT                                                  * 00360013
*                                                                     * 00450013
*MODULE NAME   IFFAFA02                                               * 00540013
*                                                                     * 00630013
*STATUS        CHANGE LEVEL 000                                       * 00720013
*                                                                     * 00810013
*FUNCTION/OPERATION                                                   * 00900013
*  TO PRODUCE LINE SEGMENTS ON THE GRAPHIC OUTPUT MEDIUM AT THE       * 00990013
*  POSITIONS SPECIFIED BY THE ARGUMENTS, AND TO UPDATE GRAPHIC        * 01080013
*  DATA PREVIOUSLY PRODUCED BY PSGMT. EACH LINE SEGMENT IS IS         * 01170013
*  DETERMINED BY TWO SUPPLIED ARGUMENT POINTS.                        * 01260013
*  EACH LINE SEGMENT TO BE DISPLAYED DEMANDS TWO CALLS TO THE DATA    * 01350013
*  GENERATION ROUTINE, THE FIRST TO MOVE THE BEAM TO THE SEGMENT      * 01440013
*  START POINT (BLANKED MODE), THE SECOND TO DISPLAY THE LINE         * 01530013
*  SEGMENT(UNBLANKED MODE).                                           * 01620013
*                                                                     * 01710013
*ENTRY POINT   IFFAFA02- CSECT NAME                                   * 01800013
*                                                                     * 01890013
*INPUT   REGISTER 1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA. THE     * 01980013
*  FIRST WORD CONTAINS THE ADDRESS OF A VARIABLE LENGTH PARAMETER     * 02070013
*  LIST ON A FULL WORD BOUNDARY, THE SECOND WORD CONTAINS THE         * 02160013
*  ADDRESS OF THE RETURN ARRAY. THE NULL VARIABLE IS AT AN OFFSET     * 02250013
*  OF 20 FROM THE RETURN ARRAY, AND THE ADDRESS OF THE STATUS TABLE   * 02340013
*  IS AT AN OFFSET OF 24 FROM THE RETURN ARRAY.                       * 02430013
*FORMAT OF PARAMETER LIST                                             * 02520013
* REQUIRED PARAMETERS                                                 * 02610013
*                                                                     * 02700013
*  +0   A(VAR)      ADDRESS OF A VARIABLE WHICH CONTAINS THE GDSCB    * 02790013
*                   ADDRESS.                                          * 02880013
*  +4   A(UVAL1)    ADDRESS OF THE U VALUE PARAMETER FOR THE SEGMENT  * 02970013
*                   START.                                            * 03060013
*  +8   A(VVAL1)    ADDRESS OF THE V VALUE PARAMETER FOR THE SEGMENT  * 03150013
*                   START.                                            * 03240013
* +12   A(UVAL2)    ADDRESS OF THE U VALUE PARAMETER FOR THE SEGMENT  * 03330013
*                   END.                                              * 03420013
* +16   A(VVAL2)    ADDRESS OF THE V VALUE PARAMETER FOR THE SEGMENT  * 03510013
*                   END.                                              * 03600013
*                                                                     * 03690013
*  OPTIONAL PARAMETERS                                                * 03780013
*                                                                     * 03870013
* +20   A(CORRVAL)  ADDRESS OF A FULL WORD CONTAINING A CORRELATION   * 03960013
*                   VALUE.                                            * 04050013
* +24   A(KEY)      ADDRESS OF KEY VARIABLE                             04140013
* +28   A(GENCODE)  ADDRESS OF THE CODE WHICH SPECIFIES THE TYPE OF     04230013
*                   OUTPUT - EITHER BLANKED, UNBLANKED, OR UPDATE     * 04320013
* +32   A(COUNT)    ADDRESS OF A VARIABLE WHICH CONTAINS THE COUNT    * 04410013
*                   OF THE NUMBER OF DATA ELEMENTS TO BE GENERATED.   * 04500013
* +36   A(U-INDEX1) ADDRESS OF THE INDEX TO BE USED IN OBTAINING THE  * 04590013
*                   NEXT U ELEMENT FOR THE START OF THE SEGMENT, WHEN * 04680013
*                   MORE THAN ONE DATA ELEMENT IS BEING GENERATED.    * 04770013
* +40   A(V-INDEX1) ADDRESS OF THE INDEX TO BE USED IN OBTAINING THE  * 04860013
*                   NEXT V ELEMENT FOR THE START OF THE SEGMENT, WHEN * 04950013
*                   MORE THAN ONE DATA ELEMENT IS BEING GENERATED.    * 05040013
* +44   A(U-INDEX2) ADDRESS OF THE INDEX TO BE USED IN OBTAINING THE  * 05130013
*                   NEXT U ELEMENT FOR THE END OF THE SEGMENT WHEN    * 05220013
*                   MORE THAN ONE DATA ELEMENT IS BEING GENERATED.    * 05310013
* +48   A(V-INDEX2) ADDRESS OF THE INDEX TO BE USED IN OBTAINING THE  * 05400013
*                   NEXT V.ELEMENT FOR THE END OF THE SEGMENT WHEN    * 05490013
*                   MORE THAN ONE DATA ELEMENT IS BEING GENERATED.    * 05580013
* +52   A(U-INCR1)  ADDRESS OF A VALUE TO BE ADDED TO THE UVAL1 TO    * 05670013
*                   OBTAIN THE NEXT UVAL1 FOR THE START OF THE LINE   * 05760013
*                   SEGMENT WHEN MORE THAN ONE DATA ELEMENT IS BEING  * 05850013
*                   GENERATED.                                        * 05940013
* +56   A(V-INCR1)  ADDRESS OF A VALUE TO BE ADDED TO THE VVAL1 TO    * 06030013
*                   OBTAIN THE NEXT VVAL1 FOR THE START OF THE LINE   * 06120013
*                   SEGMENT WHEN MORE THAN ONE DATA ELEMENT IS BEING  * 06210013
*                   GENERATED                                         * 06300013
* +60   A(U-INCR2)  ADDRESS OF A VALUE TO BE ADDED TO UVAL2 TO OBTAIN * 06390013
*                   THE NEXT UVAL2 FOR THE END OF THE LINE SEGMENT    * 06480013
*                   WHEN MORE THAN ONE DATA ELEMENT IS BEING GENER-   * 06570013
*                   ATED.                                             * 06660013
* +64   A(V-INCR2)  ADDRESS OF A VALUE TO BE ADDED TO VVAL2 TO OBTAIN * 06750013
*                   THE NEXT VVAL2 FOR THE END OF THE LINE SEGMENT    * 06840013
*                   WHEN MORE THAN ONE DATA ELEMENT IS BEING GENER-   * 06930013
*                   ATED.                                             * 07020013
*                                                                     * 07110013
*OUTPUT                                                               * 07200013
*  THE DATA WILL BE SCISSORED AND SCALED AND IF IT APPEARS ON THE     * 07290013
*  SCREEN AND/OR GRID, ORDERS WILL BE GENERATED FOR IT IN THE GDOA.   * 07380013
*                                                                     * 07470013
*EXTERNAL ROUTINES                                                    * 07560013
*  IFFAFA12    RESET                                                    07650013
*  IFFAHA03 - KEY TABLE MANAGEMENT                                    * 07740013
*  IFFAHA04 - DATA GENERATION                                         * 07830013
*  IFFAHA06 - SCALE                                                   * 07920013
*  IFFAHA07 - SCISSOR                                                 * 08010013
*  IFFAHA13 - GET GDOA'S FOR UPDATE                                   * 08100013
*  IFFAHA14 - WRITE OUT UPDATE                                        * 08190013
*                                                                     * 08280013
*EXITS - NORMAL- BACK TO CALLER VIA REGISTER 14                       * 08370013
*      - ERROR - BACK TO CALLER VIA REGISTER 14                       * 08460013
*  APPROPRIATE CODES ARE SET IN THE RETURN ARRAY -VALUES = 0,1,2,3,4  * 08550013
*                                                                     * 08640013
*                                                                     * 08730013
*                                                                     * 08820013
*TABLES/WORKAREAS -  SEE WORKAREA DSECT                               * 08910013
*                                                                     * 09000013
*ATTRIBUTES       -  REENTRANT, PROBLEM PROGRAM MODE                  * 09090013
*                                                                     * 09180013
*********************************************************************** 09270013
         EJECT                                                          09360013
IFFAFA02 CSECT                          PSEGMT                          09450013
*2024,695700-698400                                                000A 09490018
*D601500-601800                                                  A29395 09500000
         SPACE                                                          09540013
* REGISTERS                                                             09630013
REGZERO  EQU   0                                                        09720013
PARM     EQU   1                                                        09810013
LOOPCT   EQU   1                                                        09900013
REGA     EQU   2                                                        09990013
ERRCD    EQU   3                                                        10080013
REGB     EQU   4                                                        10170013
WORK     EQU   5                                                        10260013
REGD     EQU   6                                                        10350013
GTMREG   EQU   7                                                        10440013
GDSREG   EQU   8                                                        10530013
BASE     EQU   9                                                        10620013
REGC     EQU   10                                                       10710013
COUNT    EQU   11                                                       10800013
REGE     EQU   11                                                       10890013
SAVE     EQU   13                                                       10980013
RETURN   EQU   14                                                       11070013
REGFIFTN EQU   15                                                       11160013
FLT2     EQU   2                        FLOATING POINT REG              11250013
         SPACE 2                                                        11340013
*        PARAMETER LIST EQUATES                                         11430013
*                        REQUIRED PARAMETERS                            11520013
GDS      EQU   0                        ADR OF VARIABLE HOLDING GDS ADR 11610013
X        EQU   4                        ADR OF X VALUE FOR SEGMT START  11700013
Y        EQU   8                        ADR OF Y VALUE FOR SEGMT START  11790013
X2       EQU   12                       ADR OF X VALUE FOR SEGMT END    11880013
Y2       EQU   16                       ADR OF Y VALUE FOR SEGMT END    11970013
*                        OPTIONAL PARAMETERS                            12060013
FE       EQU   48                                                  000A 12090018
ETE      EQU   828                                                 000A 12120018
COR      EQU   20                       ADR OF CORRELATION VALUE        12150013
KEY      EQU   24                       ADR OF KEY LOCATION             12240013
GEN      EQU   28                       ADR OF CODE                     12330013
CT       EQU   32                       ADR OF COUNT                    12420013
XINDEX   EQU   36                       ADR OF X START INDEX            12510013
YINDEX   EQU   40                       ADR OF Y START INDEX            12600013
XINDEX2  EQU   44                       ADR OF X END INDEX              12690013
YINDEX2  EQU   48                       ADR OF Y END INDEX              12780013
XINCR    EQU   52                       ADR OF X START INCREMENT        12870013
YINCR    EQU   56                       ADR OF Y START INCREMENT        12960013
XINCR2   EQU   60                       ADR OF X END INCREMENT          13050013
YINCR2   EQU   64                       ADR OF Y END INCREMENT          13140013
         EJECT                                                          13230013
ON       EQU   X'FF'                                                    13320013
REPONLY  EQU   X'02'                                                    13410013
UPDATE   EQU   X'FF'                                                    13500013
INCLUDE  EQU   X'04'                                                    13590013
SWOFF    EQU    X'3F'                                                   13680013
OMIT     EQU   X'FB'                                                    13770013
XINDX    EQU   X'C0'                                                    13860013
YINDX    EQU   X'0C'                                                    13950013
XINC     EQU   X'30'                                                    14040013
YINC     EQU   X'03'                                                    14130013
NOX      EQU   X'0F'                                                    14220013
NOY      EQU   X'F0'                                                    14310013
PRM      EQU   X'08'                                                    14400013
STRG     EQU   X'10'                                                    14490013
SCISSOR  EQU   X'40'                                                    14580013
NOSCISS  EQU   X'10'                                                    14670013
LEVEL2   EQU   X'10'                                                    14760013
OPT      EQU   X'04'                                                    14850013
INC      EQU   X'01'                                                    14940013
INCSW    EQU   X'02'                                                    15030013
ABS      EQU   X'02'                                                    15120013
ABSSW    EQU   X'03'                                                    15210013
SUBR     EQU   X'02'                                                    15300013
MEMSUB   EQU   X'80'                                                    15390013
SEQ      EQU   X'04'                                                    15480013
MEMSEQ   EQU   X'40'                                                    15570013
NFNL     EQU   X'40'                                                    15660013
MULT     EQU   X'80'                                                    15750013
BEAMSW   EQU   X'08'                                                    15840013
CORRE    EQU   X'10'                                                    15930013
KEYED    EQU   X'20'                                                    16020013
REALY    EQU   X'0C'                                                    16110013
REALX    EQU   X'C0'                                                    16200013
ABSOLXY  EQU   X'AA'                                                    16290013
XABS     EQU   X'A0'                    SWITCH SETTING IN GDSCB         16380013
YABS     EQU   X'0A'                                                    16470013
XREALI   EQU   X'40'                                                    16560013
YREALI   EQU   X'04'                                                    16650013
XINTGI   EQU   X'10'                                                    16740013
YINTGI   EQU   X'01'                                                    16830013
LAST     EQU   X'80'                                                    16920013
LASTIN   EQU   X'C0'                                                    17010013
LASTON   EQU   X'1F'                                                    17100013
XFOUR    EQU   X'FC'                                                    17140013
STOR     EQU   12                                                       17190013
PARMERR  EQU   16                                                       17280013
NULL     EQU   20                                                       17370013
NL       EQU   21                                                       17460013
CURRLOG  EQU   52                                                       17550013
STAT     EQU   24                                                       17640013
DGEN     EQU   840                                                      17730013
SCISS    EQU   876                                                      17820013
SCALE    EQU   864                                                      17910013
CVTLINK  EQU   8                                                        18000013
         EJECT                                                          18090013
*        THIS CODE ESTABLIHES ADDRESSABILITY FOR IFFAFA02, FOR THE      18180013
*        GDSCB AND FOR THE WORKAREA. THE RETURN ARRAY IS SET TO ZERO,   18270013
*        AND THE SAVE AREAS ARE CHAINED.                                18360013
         SPACE                                                          18450013
         USING *,15                                                     18540013
         SAVE  (14,12)                                                  18630013
         DROP  15                                                       18720013
         LR    BASE,15                  LOAD CONTROL SECTION BASE       18810013
         USING IFFAFA02,BASE                                            18900013
         LR    WORK,PARM                LOAD WORK AREA BASE             18990013
         USING WORKAREA,WORK                                            19080013
         XC    WKSWITCH(8),WKSWITCH     ZERO SWITCH AREAS               19170013
         L     PARM,WKPARM              LOAD PARAMETER LIST ADDRESS     19260013
         L     ERRCD,WKRTNCD                                            19350013
         XC    0(20,ERRCD),0(ERRCD)     ZERO RETURN ARRAY               19440013
         L     GDSREG,GDS(PARM)         PICK UP ADDRESS OF GDS ADDRESS  19530013
         L     GDSREG,0(GDSREG)         ADDRESS OF GDSCB                19620013
         USING GDSCB,GDSREG                                             19710013
         L     COUNT,TWO                SET COUNT DEFAULT TO TWO        19800013
         LA    REGA,WKSAVE              CHAIN SAVE AREAS                19890013
         ST    REGA,8(SAVE)                                             19980013
         ST    SAVE,4(REGA)                                             20070013
         LR    SAVE,REGA                REG 13 CONTAINS ADR OF THIS     20160013
*                                          SAVE AREA                    20250013
*                                                                       20340013
*        THE GDSCB PASSED IS CHECKED FOR VALIDITY, AND IF IT IS VALID,  20430013
*        A SKELETON PARAMETER LIST FOR DATA GENERATION IS SET UP,       20520013
*        WITH SWITCHES INITIALIZED TO MULTIPLE ENTRY, OUTPUT TYPE=      20610013
*        VECTOR, STATUS IS INCLUDE,OUTPUT IS OPTIMIZED, FIRST ENTRY,    20700013
*        NOT KEYED, NOT CORVALED, BEAM OFF.                             20790013
*                                                                       20880013
         MVC   WKSWAREA+1(1),GDSDATMD  SAVE DATA MODE SW FROM GDSCB     20970013
         C     GDSREG,GDSGDSCB                                          21060013
         BNE   AFAERR10                 BRANCH IF INVALID GDSCB         21150013
         XC    WKSPVSR(12),WKSPVSR     ZERO PARM LIST FOR LINK MACRO    21240013
         XC    WKADDR(68),WKADDR        ZERO PARAMETER FIELDS           21330013
         MVC   WKBITS,BITS              MOVE OPTION SWITCHES,           21420013
         ST    GDSREG,WKGDS              GDSCB ADDRESS, AND             21510013
         MVC   WKRTN,WKRTNCD             RETURN CODE ARRAY ADDRESS      21600013
*                                       INTO PARAMETER LIST             21690013
         EJECT                                                          21780013
*        REQUIRED PARAMETERS (X AND Y VALUES FOR START AND END OF       21870013
*        SEGMENT) ARE EXAMINED, AND THE TYPE OF DATA PASSED IS          21960013
*        DETERMINED.                                                    22050013
         TM    GDS(PARM),LAST                                           22140013
         BO    AFAERR20                 BRANCH IF REQ PARMS NOT PRESENT 22230013
         MVC   WKSWITCH+3(1),GDSDATMD  IINITIALIZE DATA MODE SWITCH     22320013
*                                         IN WORK AREA                  22410013
         TM    GDSFLAGS,SEQ                                             22500013
         BZ    AFAREQ03                                                 22590013
         OI    WKBITS+3,MEMSEQ          OTHERWISE SET SWITCH IN KEY     22680013
AFAREQ03 TM    GDSFLAGS,SUBR                                            22770013
         BZ    AFAREQ05                                                 22860013
         OI    WKBITS+3,MEMSUB         SET SWITCH IN KEY                22900013
         BAL   RETURN,AFAREQ90         IF SUBR, GO CHECK DATA MODE      22950013
AFAREQ05 TM    X(PARM),LAST                                             23040013
         BO    AFAERR20                 BRANCH IF REQ PARMS NOT PRESENT 23130013
         TM    Y(PARM),LAST                                             23220013
         BO    AFAERR20                 BRANCH IF REQ PARMS NOT PRESENT 23310013
         TM    X2(PARM),LAST                                            23400013
         BO    AFAERR20                 BRANCH IF REQ PARMS NOT PRESENT 23490013
         TM    Y2(PARM),LAST                                            23580013
         BO    AFAREQ10                 START PROCESSING PARMS          23670013
         TM    COR(PARM),LAST                                           23760013
         BO    AFAREQ10                 START PROCESSING PARMS          23850013
         TM    KEY(PARM),LAST                                           23940013
         BO    AFAREQ10             START PROCESSING PARMS              24030013
*                                                                       24120013
*CHECK FOR GENCODE OF 3- AND IF IT IS, PROCESS IT                       24210013
*                                                                       24300013
         CLC   NL(3,ERRCD),GEN+1(PARM)                                  24390013
         BE    AFAREQ10                 BRANCH IF GENCODE NULL          24480013
         L     REGA,GEN(PARM)                                           24570013
         L     REGA,0(REGA)             PICK UP GENCODE                 24660013
         C     REGA,THREE                                               24750013
         BE    AFAOPT10                                                 24840013
*                                                                       24930013
AFAREQ10 L     REGA,X(PARM)             ADDRESS OF X START VALUE        25020013
         L     REGA,0(REGA)             X VALUE                         25110013
         TM    WKSWITCH+3,XABS                                          25200013
         BZ    AFAREQ60                 BRANCH IF X INCREMENTAL         25290013
         ST    REGA,WKXABS              PUT ABSOLUTE VALUE IN PARM LIST 25380013
AFAREQ20 ST    REGA,WKXVAL              SAVE COPY OF X VALUE            25470013
         L     REGB,Y(PARM)             ADDRESS OF Y START VALUE        25560013
         L     REGB,0(REGB)             Y VALUE                         25650013
         TM    WKSWITCH+3,YABS                                          25740013
         BZ    AFAREQ65                 BRANCH IF Y INCREMENTAL         25830013
         ST    REGB,WKYABS              PUT ABSOLUTE VALUE IN PARM LIST 25920013
AFAREQ30 ST    REGB,WKYVAL              SAVE COPY OF Y VALUE            26010013
         L     REGA,X2(PARM)            ADDRESS OF X END VALUE          26100013
         L     REGA,0(REGA)             X END VALUE                     26190013
         ST    REGA,WKXVAL2             SAVE COPY OF X END VALUE        26280013
         TM    WKSWITCH+3,XABS                                          26370013
         BZ    AFAREQ50                 BRANCH IF X END INCREMENTAL     26460013
AFAREQ35 L     REGB,Y2(PARM)                                            26550013
         L     REGB,0(REGB)             Y END VALUE                     26640013
         ST    REGB,WKYVAL2                                             26730013
         TM    WKSWITCH+3,YABS                                          26820013
         BZ    AFAREQ70                BRANCH IF Y END INCREMENTAL      26910013
AFAREQ40 TM    Y2(PARM),LAST                                            27000013
         BO    AFADAT10                 BRANCH IF NO OPTIONAL PARMS     27090013
         CLI   WKSWITCH,UPDATE                                          27180013
         BE    AFAOPT55                BRANCH IF UPDATE- CORRBAL,KEY    27270013
*                                       AND GENCODE ALREADY PROCESSED   27360013
         B     AFAOPT10                                                 27450013
         EJECT                                                          27540013
*INITIALIZATION OF INCREMENT TOTALS                                     27630013
*                                                                       27720013
AFAREQ60 ST    REGA,WKXINCR             PUT X INCR VALUE IN PARM LIST   27810013
         ST    REGA,WKXTOT               AND SAVE COPY FOR COMPUTING    27900013
         B     AFAREQ20                                                 27990013
*                                                                       28080013
*                                                                       28170013
AFAREQ65 ST    REGB,WKYINCR             PUT Y INCR VALUE IN PARM LIST   28260013
         ST    REGB,WKYTOT               AND SAVE COPY FOR COM          28350013
         B     AFAREQ30                                                 28440013
*                                                                       28530013
*REGA CONTAINS X END INCREMENT                                          28620013
*                                                                       28710013
AFAREQ50 TM    WKSWITCH+3,REALX                                         28800013
         BM    AFAREQ55                 BRANCH IF REAL NUMBER           28890013
         A     REGA,WKXTOT              1ST X END INCR IS FROM X START  28980013
         ST    REGA,WKXTOT2             KEEP CURRENT POINTER TO BEAM    29070013
         B     AFAREQ35                                                 29160013
AFAREQ55 LE    FLT2,WKXVAL2                                             29250013
         AE    FLT2,WKXTOT              ADD X START INCREMENT           29340013
         STE   FLT2,WKXTOT2             SAVE TOTAL                      29430013
         B     AFAREQ35                                                 29520013
*                                                                       29610013
*REGB CONTAINS Y END INCREMENT                                          29700013
*                                                                       29790013
AFAREQ70 TM    WKSWITCH+3,REALY                                         29880013
         BM    AFAREQ75                 BRANCH IF REAL NUMBER           29970013
         A     REGB,WKYTOT              ADD TO Y START INCREMENT        30060013
         ST    REGB,WKYTOT2             SAVE TOTAL                      30150013
         B     AFAREQ40                                                 30240013
AFAREQ75 LE    FLT2,WKYVAL2                                             30330013
         AE    FLT2,WKYTOT              ADD Y START INCREMENT           30420013
         STE   FLT2,WKYTOT2             SAVE TOTAL                      30510013
         B     AFAREQ40                                                 30600013
         EJECT                                                          30690013
*        RESETS DATA MODE SWITCHES IN TEMPORARY WORK AREA FOR           30780013
*        BUFFER SUBROUTINE. INPUT DATA SET TO INCREMENTAL MODE          30870013
*                                                                       30960013
AFAREQ90 MVI   WKSWITCH+3,X'00'         ZERO OUT SWITCH AREA            31050013
         TM    GDSDATMD,REALX                                           31140013
         BZ    AFAREQ96                 BRANCH IF X VALUE INTEGER       31230013
         OI    WKSWITCH+3,XREALI        SET SWITCH FOR REAL,INCR  X     31320013
AFAREQ92 TM    GDSDATMD,REALY                                           31410013
         BZ    AFAREQ98                 BRANCH IF Y VALUE INTEGER       31500013
         OI    WKSWITCH+3,YREALI        SET SWITCH FOR REAL,INCR  Y     31590013
         MVC   GDSDATMD(1),WKSWITCH+3  STORE NEW SWITCH IN GDSCB        31680013
         BR    RETURN                                                   31770013
*                                                                       31860013
AFAREQ96 OI    WKSWITCH+3,XINTGI        SET SWITCH FOR INTEGER,INCR X   31950013
         B     AFAREQ92                                                 32040013
AFAREQ98 OI    WKSWITCH+3,YINTGI        SET SWITCH FOR INTEGER,INCR Y   32130013
         MVC   GDSDATMD(1),WKSWITCH+3  STORE NEW SWITCH IN GDSCB        32220013
         BR    RETURN                                                   32310013
         EJECT                                                          32400013
*        THIS SECTION OF CODE EXAMINES THE OPTIONAL PARAMETERS          32490013
*        CORRVAL, KEY, AND GENCODE, AND TESTS THEM FOR VALIDITY         32580013
AFAOPT10 CLC   NL(3,ERRCD),COR+1(PARM)                                  32670013
         BE    AFAOPT15                 BRANCH IF CORRVAL NOT PASSED    32760013
         TM    GDSFLAGS,LEVEL2                                          32850013
         BO    AFAOPT15                BRANCH IF LEVEL 2 CORRVAL        32940013
         L     REGD,COR(PARM)           LOAD ADDRESS OF CORRVAL         33030013
         MVC   WKCORVL,0(REGD)          PLACE CORRVAL IN PARAM LIST     33120013
         OI    WKBITS+2,CORRE          SET CORRVAL SWITCH IN PARM LIST  33210013
AFAOPT15 TM    COR(PARM),LAST                                           33300013
         BO    AFADAT10                 BRANCH IF NO MORE PARAMETERS    33390013
         CLC   NL(3,ERRCD),KEY+1(PARM)                                  33480013
         BE    AFAOPT20                 BRANCH IF KEY NOT PASSED        33570013
         MVC   WKKEY,KEY(PARM)          PLACE ADDRESS OF KEY IN PARM    33660013
*                                           LIST                        33750013
         TM    GDSFLAGS,LEVEL2                                          33840013
         BO    AFAOPT20                 BRANCH IF LEVEL 2 KEY           33930013
         OI    WKBITS+2,KEYED           OTHERWISE SET KEY SWITCH IN     34020013
*                                           PARM LIST                   34110013
AFAOPT20 TM    KEY(PARM),LAST                                           34200013
         BO    AFADAT10                 BRANCH IF NO MORE PARAMETERS    34290013
         CLC   NL(3,ERRCD),GEN+1(PARM)                                  34380013
         BE    AFAOPT25                 BRANCH IF GENCODE NOT PASSED    34470013
         L     REGD,GEN(PARM)           PICK UP CODE ADDRESS            34560013
         L     REGD,0(REGD)             PICK UP ACTUAL CODE             34650013
         C     REGD,ONE                                                 34740013
         BE    AFAOPT25                 BRANCH IF STATUS='INCLUDE'      34830013
*                                      (SWT ALREADY SET IN PARM LIST)   34920013
         CLC   WKCORVL(8),ZERO         CHECK FOR CORRVAL AND/OR KEY     35010013
         BZ    AFAERR30                 BRANCH IF STATUS NOT INCLUDE    35100013
*                                         AND ELEMENT NOT KEYED OR      35190013
*                                         CORRVALED-ERROR               35280013
         C     REGD,TWO                                                 35370013
         BNE   AFAOPT30                 BRANCH IF STATUS NOT 'OMIT'     35460013
         TM    GDSFLAGS,LEVEL2                                          35550013
         BO    AFAERR30                 BRANCH IF LEVEL 2 AND 'OMIT'    35640013
*                                         STATUS SPECIFIED-ERROR        35730013
         NI    WKBITS,OMIT              TURN OFF INCLUDE SWITCH         35820013
AFAOPT25 TM    WKBITS+2,CORRE                                           35910013
         BZ    AFAOPT55                 BRANCH IF NOT CORRELATED        36000013
         CLC   WKCORVL,ZERO                                             36090013
         BE    AFAERR40                 BRANCH IF CORRVAL=0,-ERROR      36180013
         B     AFAOPT55                                                 36270013
*                                                                       36360013
AFAOPT30 C     REGD,THREE                                               36450013
         BNE   AFAERR30                 BRANCH IF NOT 'UPDATE'  -ERROR  36540013
         TM    GDSFLAGS,SUBR                                            36630013
         BO    AFAERR20                 BRANCH IF UPDATE WHEN GENERAT-  36720013
*                                         ING SUBROUTINE -ERROR         36810013
         TM    GDSFLAGS,LEVEL2                                          36900013
         BO    AFAOPT45                 BRANCH IF LEVEL2 TO SET KEY     36990013
         TM    WKBITS+2,KEYED                                           37080013
         BZ    AFAOPT50                 BRANCH IF ELEMENT NOT KEYED     37170013
*                                       PREPARE PARAMS FOR KEY SEARCH   37260013
         L     REGD,KEY(PARM)           LOAD KEY ADDRESS                37350013
         ST    REGD,WKKADDR             AND PUT IN PARAMETER LIST       37440013
         LA    REGD,TWO                CODE FOR SEARCH ON KEY           37530013
AFAOPT35 ST    REGD,WKCODE              WORK CODE ADDRESS               37620013
         LA    REGD,AFAOPT37                                            37710013
         ST    REGD,WKTEMP             SAVE RETURN ADDRESS              37800013
*                                                                       37890013
*SEARCH ON KEY OR CORRVAL - ADDRESS IN REGISTER 1                       37980013
*                                                                       38070013
         B     AFAKEY10                                                 38160013
AFAOPT37 LTR   REGFIFTN,REGFIFTN       TEST RETURN CODE                 38250013
         BNE   AFAERR20                 BRANCH IF INVALID KEY           38340013
         MVC   WKADDR,0(PARM)           MOVE KEY FIELDS INTO PARM LIST  38430013
         OC    WKBITS+3(1),7(PARM)      GET FLAGS FROM OLD KEY          38520013
         TM    WKBITS+3,MEMSUB                                          38610013
         BZ    AFAOPT38                                                 38700013
         BAL   RETURN,AFAREQ90                                          38790013
AFAOPT38 TM    4(PARM),INCLUDE                                          38880013
         BO    AFAOPT39                                                 38970013
         NI    WKBITS,OMIT              TURN OFF INCLUDE SWITCH         39060013
AFAOPT39 ST    PARM,WKSTORAD           SAVE KEY ADDR IN KEY TABLE       39160013
AFAOPT40 MVI   WKSWITCH,UPDATE          SET UPDATE SWITCH               39420013
AFAOPT42 L     PARM,WKPARM             RESTORE PARAMETER REG. POINTER   39510013
         B     AFAREQ10                                                 39600013
*                                                                       39690013
*                                                                       39780013
*                                                                       39870013
*                                                                       39960013
AFAOPT45 L     REGD,KEY(PARM)           LOAD KEY ADDRESS                40050013
         MVC   WKADDR,0(REGD)           PLACE KEY IN PARM LIST          40140013
         B     AFAOPT40                                                 40230013
*                                                                       40320013
AFAOPT50 CLC  WKCORVL,ZERO                                              40410013
         BE    AFAERR20                 BAD PARAMETER COMBINATION       40500013
*                                                                       40590013
*PREPARE FOR SEARCH ON CORRVAL                                          40680013
*                                                                       40770013
         LA    REGD,WKCORVL             LOAD CORRVAL ADDRESS            40860013
         ST    REGD,WKKADDR             AND PUT IN PARAMETER LIST       40950013
         LA    REGD,FIVE                 SEARCH                         41040013
         B     AFAOPT35                 BRANCH TO GET REST OF PARAMS    41130013
*                                         AND TO CALL KEY MANAGEMENT    41220013
         EJECT                                                          41310013
*        THIS SECTION EXAMINES THE COUNT PARAMETER, IF THE COUNT IS     41400013
*        NOT SPECIFIED IT IS SET TO TWO (TWO CALLS TO THE DATA          41490013
*        GENERATION ROUTINE ARE NEEDED FOR EACH LINE SEGMENT). IF       41580013
*        THE COUNT IS 0, NO DATA IS GENERATED AND CONTROL IS RETURNED   41670013
*        TO THE CALLER. IF THE COUNT IS LESS THAN ZERO AN ERROR         41760013
*        RETURN IS MADE. OTHERWISE THE COUNT IS MULTIPLIED BY TWO,      41850013
*        AND PROCESSING CONTINUES.                                      41940013
*                                                                       42030013
AFAOPT55 TM    GEN(PARM),LAST                                           42120013
         BO    AFADAT10                 BRANCH IF END OF PARM LIST      42210013
         CLC   NL(3,ERRCD),CT+1(PARM)                                   42300013
         BE    AFADAT10                 BRANCH IF COUNT NULL            42390013
         L     COUNT,CT(PARM)                                           42480013
         L     COUNT,0(COUNT)           LOAD COUNT                      42570013
         LTR   COUNT,COUNT                                              42660013
         BZ    AFARET10                 RETURN IF COUNT = 0             42750013
         BM    AFAERR70                 ERROR IF COUNT LESS THAN ZERO   42840013
         SLA   COUNT,1                 MULTIPLY COUNT BY 2              42930013
         C     COUNT,TWO                                                43020013
         BE    AFADAT10                 BRANCH IF ONE LINE TO BE        43110013
*                                       DISPLAYED                       43200013
         EJECT                                                          43290013
*        THIS SECTION EXAMINES THE X START INDEX, Y START INDEX,        43380013
*        X END INDEX, Y END INDEX, X START INCR, Y START INCR,          43470013
*        X END INCR, AND Y END INCR PARAMETERS.                         43560013
*        THESE PARAMETERS ARE CHECKED ONLY WHEN MORE THAN ONE LINE      43650013
*        SEGMENT IS TO BE DISPLAYED.                                    43740013
         TM    CT(PARM),LAST                                            43830013
         BO    AFAINX50                 BRANCH IF END OF PARAMETER LIST 43920013
         CLC   NL(3,ERRCD),XINDEX+1(PARM)                               44010013
         BE    AFAINX10                 BRANCH IF X START INDEX NULL    44100013
         L     REGD,XINDEX(PARM)                                        44190013
         L     REGD,0(REGD)             PICK UP INDEX VALUE             44280013
         SLA   REGD,2                   MULTIPLY BY 4                   44370013
         ST    REGD,WKXCHNG             SAVE INDEXING FACTOR            44460013
         OI    WKSWITCH+1,XINDX         SET SWITCH IN WORK AREA         44550013
AFAINX10 TM    XINDEX(PARM),LAST                                        44640013
         BO    AFAINX50                 BRANCH IF END OF PARAMETER LIST 44730013
         CLC   NL(3,ERRCD),YINDEX+1(PARM)                               44820013
         BE    AFAINX15                 BRANCH IF Y START INDEX NULL    44910013
         L     REGD,YINDEX(PARM)                                        45000013
         L     REGD,0(REGD)             PICK UP INDEX VALUE             45090013
         SLA   REGD,2                   MULTIPLY BY 4                   45180013
         ST    REGD,WKYCHNG             SAVE INDEXING FACTOR            45270013
         OI    WKSWITCH+1,YINDX         SET SWITCH IN WORK AREA         45360013
AFAINX15 TM    YINDEX(PARM),LAST                                        45450013
         BO    AFAINX50                 BRANCH IF END OF PARM LIST      45540013
         CLC   NL(3,ERRCD),XINDEX2+1(PARM)                              45630013
         BE    AFAINX20                 BRANCH IF X END INDEX NULL      45720013
         L     REGD,XINDEX2(PARM)                                       45810013
         L     REGD,0(REGD)            PICK UP INDES VALUE              45900013
         SLA   REGD,2                   MULTIPLY BY 4                   45990013
         ST    REGD,WKXCHNG2            SAVE INDEX FACTOR               46080013
         OI    WKSWITCH+2,XINDX        SET SWITCH IN WORK AREA          46170013
AFAINX20 TM    XINDEX2(PARM),LAST                                       46260013
         BO    AFAINX50                 BRANCH IF END OF PARM LIST      46350013
         CLC   NL(3,ERRCD),YINDEX2+1(PARM)                              46440013
         BE    AFAINX25                 BRANCH IF Y END INDEX NULL      46530013
         L     REGD,YINDEX2(PARM)                                       46620013
         L     REGD,0(REGD)             PICK UP INDEX VALUE             46710013
         SLL   REGD,2                   MULTIPLY BY 4                   46800013
         ST    REGD,WKYCHNG2            SAVE INDEX FACTOR               46890013
         OI    WKSWITCH+2,YINDX        SET SWITCH IN WORK AREA          46980013
         EJECT                                                          47070013
AFAINX25 TM    YINDEX2(PARM),LAST                                       47160013
         BO    AFAINX50                 BRANCH IF END OF PARAMETER LIST 47250013
         CLC   NL(3,ERRCD),XINCR+1(PARM)                                47340013
         BE    AFAINX30                 BRANCH IF X START INCR NULL     47430013
         TM    WKSWITCH+1,XINDX         WAS X START INDEX ALSO PASSED   47520013
         BO    AFAERR20                 BRANCH IF YES-ERROR             47610013
         L     REGD,XINCR(PARM)                                         47700013
         MVC   WKXCHNG,0(REGD)          SACE INCREMENT VALUE            47790013
         OI    WKSWITCH+1,XINC          SET SWITCH IN WORK AREA         47880013
AFAINX30 TM    XINCR(PARM),LAST                                         47970013
         BO    AFAINX50                 BRANCH IF END OF PARAMETER LIST 48060013
         CLC   NL(3,ERRCD),YINCR+1(PARM)                                48150013
         BE    AFAINX35                 BRANCH IF Y START INCR NULL     48240013
         TM    WKSWITCH+1,YINC          WAS Y START INDEX ALSO PASSED   48330013
         BO    AFAERR20                 BRANCH IF YES- ERROR            48420013
         L     REGD,YINCR(PARM)                                         48510013
         MVC   WKYCHNG,0(REGD)          SAVE INCREMENT VALUE            48600013
         OI    WKSWITCH+1,YINC                                          48690013
AFAINX35 TM    YINCR(PARM),LAST                                         48780013
         BO    AFAINX50                 BRANCH IF END OF PARAMETER LIST 48870013
         CLC   NL(3,ERRCD),XINCR2+1(PARM)                               48960013
         BE    AFAINX40                 BRANCH IF X END INCREMENT NULL  49050013
         TM    WKSWITCH+2,XINDX         WAS X END INDEX ALSO PASSED     49140013
         BO    AFAERR20                 BRANCH IF YES- ERROR            49230013
         L     REGD,XINCR2(PARM)                                        49320013
         MVC   WKXCHNG2,0(REGD)         SAVE INCREMENT VALUE            49410013
         OI    WKSWITCH+2,XINC          SET SWITCH IN WORK AREA         49500013
AFAINX40 TM    XINCR2(PARM),LAST                                        49590013
         BO    AFAINX50                 BRANCH IF END OF PARAMETER LIST 49680013
         CLC   NL(3,ERRCD),YINCR2+1(PARM)                               49770013
         BE    AFAINX50                 BRANCH IF Y ENC INCREMENT NULL  49860013
         TM    WKSWITCH+2,YINDX         WAS Y END INDEX ALSO PASSED     49950013
         BO    AFAERR20                 BRANCH IF YES- ERROR            50040013
         L     REGD,YINCR2(PARM)                                        50130013
         MVC   WKYCHNG2,0(REGD)         SAVE INCREMENT VALUE            50220013
         OI    WKSWITCH+2,YINC          SET SWITCH IN WORK AREA         50310013
         EJECT                                                          50400013
*        THIS SECTION CHECKS WHICH OF THE INDEX AND INCREMENT PARAMS    50490013
*        HAVE BEEN PASSED AND SETS UP DEFAULT CONDITIONS WHERE          50580013
*        NECESSARY.                                                     50670013
*                                                                       50760013
AFAINX50 TM    WKSWITCH+1,XINDX+XINC                                    50850013
         BM    AFAINX55                 BRANCH IF X START IX/INC THERE  50940013
         MVC   WKXCHNG,FOUR              OTHERWISE, SET INDEX VALUE=4   51030013
         OI    WKSWITCH+1,XINDX         AND SET SWITCH IN WORK AREA     51120013
AFAINX55 TM    WKSWITCH+1,YINDX+YINC                                    51210013
         BM    AFAINX60                 BRANCH IF Y START IX/INC THERE  51300013
         MVC   WKYCHNG,FOUR              OTHERWISE, SET INDEX VALUE=4   51390013
         OI    WKSWITCH+1,YINDX          AND SET SWITCH IN WORK AREA    51480013
AFAINX60 TM    WKSWITCH+2,XINDX+XINC                                    51570013
         BM    AFAINX65                 BRANCH IF X END IX/INC PRESENT  51660013
         MVC   WKXCHNG2,FOUR             OTHERWISE, SET INDEX VALUE=4   51750013
         OI    WKSWITCH+2,XINDX          AND SET SWITCH IN WORK AREA    51840013
AFAINX65 TM    WKSWITCH+2,YINDX+YINC                                    51930013
         BM    AFADAT10                 BRANCH IF Y END IX/INC PRESENT  52020013
         MVC   WKYCHNG2,FOUR             OTHERWISE,SET INDEX VALUE=4    52110013
         OI    WKSWITCH+2,YINDX          AND SET SWOTCH IN WORK AREA    52200013
         EJECT                                                          52290013
*        THIS SECTION COMPLETES THE PARAMETER LIST FOR THE CALL TO      52380013
*        THE DATA GENERATION ROUTINE AND, IF MORE THAN ONE LINE         52470013
*        SEGMENT IS TO BE DISPLAYED, SETS UP THE LOOP FOR FUTURE        52560013
*        ENTRIES. PSGMT WILL ALWAYS MAKE MULTIPLE ENTRIES TO THE        52650013
*        DATA GENERATION ROUTINE, AND OUTPUT WILL ALWAYS BE VECTOR.     52740013
*                                                                       52830013
AFADAT10 TM    WKBITS+3,MEMSUB                                          52920013
         BO    AFADAT70                BRANCH IF BUFFER SUBROUTINE      53010013
*                                        SUBROUTINE-OUTPUT INCREMENTAL  53100013
*TEST FOR OUTPUT DATA MODE                                              53190013
*                                                                       53280013
         TM    GDSCURMD,OPT                                             53370013
         BO    AFADAT20                 BRANCH IF OPTIMIZE MODE- SWITCH 53460013
*                                        ALREADY SET                    53550013
         TM    GDSCURMD,INC                                             53640013
         BO    AFADAT70                 BRANCH IF INCREMENTAL MODE      53730013
         XI    WKBITS,ABSSW            SET SWITCH TO ABSOLUTE MODE      53820013
*                                                                       53910013
*                                                                       54000013
AFADAT20 MVC   WKXCURR(4),GDSXCURR      SAVE X-Y CURRENT VALUE          54090013
         MVC   WKXLAST(8),GDSXLAST      SAVE X-Y LAST VALUE             54180013
         CLI   WKSWITCH,UPDATE                                          54270013
         BE    AFADAT75                 BRANCH IF UPDATE                54360013
         L     REGD,GDSAOACB            GET OACB ADDRESS                54450013
         L     REGD,CURRLOG(REGD)       GET LOGICAL START AND           54540013
         STH   REGD,WKADDR+2             STORE IN PARAMETER LIST        54630013
         EJECT                                                          54720013
*SET UP LOOP CONTROL IF MORE THAN ONE LINE SEGMENT TO BE GENERATED.     54810013
*                                                                       54900013
AFADAT25 C     COUNT,TWO                                                54990013
         BE    AFASSD10                 BRANCH IF ONE LINE TO GENERATE  55080013
AFADAT30 TM    WKSWITCH+1,XINDX                                         55170013
         BZ    AFADAT35                 BRANCH IF X START INCREMENTAL   55260013
         MVC   WKXVAL,X(PARM)           REPLACE X VALUE WITH X ADDR     55350013
AFADAT35 TM    WKSWITCH+1,YINDX                                         55440013
         BZ    AFADAT40                 BRANCH IF Y START INCREMENTAL   55530013
         MVC   WKYVAL,Y(PARM)           REPLACE Y VALUE WITH Y ADDR     55620013
AFADAT40 TM    WKSWITCH+2,XINDX                                         55710013
         BZ    AFADAT45                 BRANCH IF X END INCREMENTAL     55800013
         MVC   WKXVAL2,X2(PARM)         REPLACE X2 VALUE WITH X2 ADDR   55890013
AFADAT45 TM    WKSWITCH+2,YINDX                                         55980013
         BZ    AFASSD10                 BRANCH IF Y END INCREMENTAL     56070013
         MVC   WKYVAL2,Y2(PARM)         REPLACE Y2 VALUE WITH Y2 ADDR   56160013
         B     AFASSD10                                                 56250013
*                                                                       56340013
*                                                                       56430013
*                                                                       56520013
AFADAT70 XI    WKBITS,INCSW                                             56610013
         B     AFADAT20                                                 56700013
*/                                                                      56790013
*GET GDOA'S FOR UPDATE                                                  56880013
*                                                                       56970013
AFADAT75 L     REGD,16                  CVT                             57060013
         L     REGD,CVTLINK(REGD)       LINK LIB DCB                    57150013
         LA    PARM,WKADDR                                              57240013
*                                                                       57330013
*        LINK  EP=IFFAHA13,DCB=(REGD),MF=(E,(1)),SF=(E,WKSPVSR)         57420013
         LINK  EP=IFFAHA13,MF=(E,(1)),SF=(E,WKSPVSR)                    57510013
         LTR   REGFIFTN,REGFIFTN                                        57600013
         BNE   AFAERR90                                                 57690013
         L     PARM,WKPARM             RESTORE PARAMETER POINTER        57780013
         B     AFADAT25                                                 57870013
         EJECT                                                          57960013
*THIS SECTION OF CODE IS ENTERED TWICE FOR EVERY LINE SEGMENT TO BE     58050013
*GENERATED. IT INCLUDES CALLS TO THE SCALE, SCISSOR(WHEN REQUESTED),    58140013
*AND DATA GENERATION ROUTINES.                                          58230013
         SPACE                                                          58320013
AFASSD10 LA    PARM,WKGDS                                               58410013
*/       CALL  SCALE                                                    58500013
*/                                                                      58590013
         L     REGFIFTN,STAT(ERRCD)     ADDRESS OF STATUS TABLE         58680013
         L     REGFIFTN,SCALE(REGFIFTN) ADDRESS OF SCALE                58770013
         BALR  RETURN,REGFIFTN          BRANCH TO SCALE                 58860013
         LTR   REGFIFTN,REGFIFTN                                        58950013
         BNE   AFARES10                                                 59040013
         TM    WKBITS+3,MEMSUB         TEST FOR BUFFER SUBROUTINE       59130013
         BO    AFASSD25                IF IS, NO SCISS, NO BEAM REPOS   59220013
         TM    GDSSCISS,NOSCISS                                         59310013
         BZ    AFASSD15                 BRANCH IF SCISSOR WANTED        59400013
*                                                                       59490013
*THESE VALUES ARE SET BY THE SCISSOR ROUTINE, SO ARE SET IN PSEGMT ONLY 59580013
*WHEN THERE IS TO BE NO SCISSORING                                      59670013
*                                                                       59760013
         MVC   GDSXLAST,WKXABS          * SET XLAST                     59850013
         L     PARM,WKXABS                                              59870013
         SH    PARM,GDSXCURR            RECOMPUTE INCREMENT AND PUT     59890013
         ST    PARM,WKXINCR              IN PARAMETER LIST              59910013
         MVC   GDSXCURR,WKXABS+2        *     XCURR                     59940013
         MVC   GDSYLAST,WKYABS          *     YLAST AND                 60030013
         L     PARM,WKYABS                                              60050013
         SH    PARM,GDSYCURR            RECOMPUTE INCREMENT AND PUT     60070013
         ST    PARM,WKYINCR              IN PARAMETER LIST              60090013
         MVC   GDSYCURR,WKYABS+2        *     YCURR IN GDSCB            60120013
         NI    GDSSCISS,LASTON                                          60210013
         B     AFASSD25                                                 60300013
*                                                                       60390013
*CALL TO SCISSOR ROUTINE                                                60480013
*                                                                       60570013
AFASSD15 LA    PARM,WKGDS                                               60660013
*/                                                                      60750013
*/       CALL  SCISSOR                                                  60840013
         L     REGFIFTN,STAT(ERRCD)     ADDRESS OF STATUS TABLE         60930013
         L     REGFIFTN,SCISS(REGFIFTN) ADDRESS OF SCISSOR              61020013
         BALR  RETURN,REGFIFTN          BRANCH TO SCISSOR               61110013
         LTR   REGFIFTN,REGFIFTN                                        61200013
         BZ    AFASSD20                 BRANCH IF SCISSOR RETURN OK     61290013
         C     REGFIFTN,FOUR                                            61380013
         BE    AFARES10                                                 61470013
         B     AFASSD30                 OTHERWISE SKIP CALL TO DATA GEN 61560013
         EJECT                                                          61650013
AFASSD20 TM    WKBITS+2,LASTIN                                          61740013
         BZ    AFASSD25                ALWAYS GENERATE FIRST VECTOR     61830013
         CLC   WKXINCR(8),ZERO          IF NO MOVEMENT                  61920013
         BE    AFASSD30                  BRANCH PAST CALL TO DATA GEN   62010013
*CALL TO DATA GENERATION ROUTINE                                        62100013
*                                                                       62190013
AFASSD25 LA    PARM,WKADDR                                              62280013
*/                                                                      62370013
*/       CALL  DATA GEN                                                 62460013
*/                                                                      62550013
         L     REGFIFTN,STAT(ERRCD)     ADDRESS OF STATUS TABLE         62640013
         L     REGFIFTN,DGEN(REGFIFTN)  ADDRESS OF DATA GEN             62730013
         BALR  RETURN,REGFIFTN          BRANCH TO DATA GEN              62820013
         LTR   REGFIFTN,REGFIFTN                                        62910013
         BNE   AFARES10                                                 63000013
         NI    WKBITS+2,SWOFF                                           63090013
         OI    WKBITS+2,NFNL            SET NOT FIRST NOT LAST SWITCH   63180013
         SPACE                                                          63270013
AFASSD30 BCT   COUNT,AFASET05          BRANCH IF MORE TO DO             63360013
         TM    WKBITS+2,LASTIN                                          63450013
         BZ    AFAERR80                BRANCH IF FIRST PASS SWITCH      63540013
*                                      STILL ON - NO DATA GENERATED     63630013
         BO    AFASSD50                B-&NCH &F L&00 &&-   &&          63720013
*                                      CALL DATA GEN AGAIN              63810013
         CLI   WKSWITCH,UPDATE                                          63900013
         BE    AFASSD80                 BRANCH IF UPDATE                63990013
         SPACE                                                          64080013
*PREPARE KEY                                                            64170013
*                                                                       64260013
         L     COUNT,GDSAOACB                                           64350013
         L     COUNT,CURRLOG(COUNT)    GET CURRENT LOGICAL ADDRESS      64440013
         SH    COUNT,WKADDR+2          COMPUTE ELEMENT LENGTH           64530013
         LTR   COUNT,COUNT                                              64620013
         BZ    AFAERR80                 ERROR IF NO DATA GENERATED      64710013
         STH   COUNT,WKADDR            PLACE LENGTH IN KEY              64800013
         L     COUNT,WKKEY                                              64890013
         LTR   COUNT,COUNT                                              64980013
         BE    AFASSD35                 BRANCH IF NO USER VARIABLE      65070013
         MVC   0(4,COUNT),WKADDR       PLACE KEY IN USER VARIABLE       65160013
AFASSD35 TM    WKBITS+2,KEYED+CORRE                                     65250013
         BZ    AFARET10                BRANCH IF NOT KEYED OR CORREL    65340013
*                                                                       65430013
*   PREPARE PARAM LIST                                                  65520013
         SPACE                                                          65610013
         LA    REGA,ONE                CODE FOR ADDING KEY TO TABLE     65700013
         ST    REGA,WKCODE                                              65790013
         LA    REGA,AFASSD40           SAVE RETURN ADDRESS              65880013
         ST    REGA,WKTEMP                                              65970013
         LA    REGA,WKADDR                                              66060013
         ST    REGA,WKKADDR                                             66150013
         B     AFAKEY10                                                 66240013
*                                                                       66330013
AFASSD40 LTR   REGFIFTN,REGFIFTN                                        66420013
         BNE   AFAERR90                 BRANCH IF NOT ENOUGH STORAGE    66510013
         SPACE                                                          66600013
AFARET10 CLI   WKSWITCH,UPDATE                                          66690013
         BNE   AFARET15                 BRANCH IF NOT UPDATE            66780013
         TM    GDSFLAGS,LEVEL2                                          66790013
         BO    AFARET15                BRANCH IF LEVEL 2-NO KEY TABLE   66800013
         L     PARM,WKSTORAD                                            66810013
         MVC   4(4,PARM),WKBITS        MOVE IN NEW KEY SWITCHES         66820013
         TM    WKBITS+2,CORRE                                           66870013
         BZ    AFARET15                 BRANCH IF NO CORRVAL            66960013
         MVC   8(4,PARM),WKCORVL        MOVE IN NEW CORRVAL             67140013
AFARET15 MVC   GDSDATMD(1),WKSWAREA+1   RESTORE DATA MODE SWITCH        67230013
AFARET17 L     SAVE,4(SAVE)                                             67320013
AFARET20 RETURN (14,12),T                                               67410013
         SPACE 2                                                        67450013
AFASSD50 OI  WKBITS+2,REPONLY          SET FLAG TO GENERATE REPOS VECT  67500013
         XC    WKDATA1(32),WKDATA1                                      67590013
         MVC   WKXABS+2(2),GDSXCURR    PLACE CURRENT BEAM POSITION      67680013
         MVC   WKYABS+2(2),GDSYCURR    FROM GDS INTO PARAMETER LIST     67770013
         LA    COUNT,1                 RESET COUNT REGISTER             67860013
         B     AFASSD25                CALL DATA GEN AGAIN              67950013
         EJECT                                                          68040013
*CALL DATA STORE TO WRITE OUT UPDATE                                    68130013
*                                                                       68220013
*WRITE OUT UPDATE                                                       68310013
*                                                                       68400013
AFASSD80 LA    PARM,WKADDR                                              68490013
         L     REGD,16                  CVT                             68580013
         L     REGD,CVTLINK(REGD)                                       68670013
*        LINK  EP=IFFAHA14,DCB=(REGD),MF=(E,(1)),SF=(E,WKSPVSR)         68760013
         LINK  EP=IFFAHA14,MF=(E,(1)),SF=(E,WKSPVSR)                    68850013
         B     AFARET10                                                 68940013
         SPACE                                                          69030013
*                                                                       69120013
*LINKAGE TO KEY MANAGEMENT ROUTINE                                      69210013
*                                                                       69300013
AFAKEY10 ST    GDSREG,WKGDS1                                            69390013
         LA    PARM,WKGDS1                                              69480013
         L     REGA,GDSGTMCB       GET POINTER TO GTMCB            000A 69550018
         L     REGA,4(REGA)        GET POINTER TO GSPCB            000A 69620018
         L     REGA,FE(REGA)       GET POINTER TO STATUS TABLE     000A 69690018
         L     REGFIFTN,ETE(REGA)  GET ADRS OF KEY TABLE MGMT      000A 69760018
         BALR  RETURN,REGFIFTN     BRANCH TO KEY TABLE MGMT        000A 69830018
         L     RETURN,WKTEMP            PICK UP RETURN ADDRESS          69930013
         BR    RETURN                                                   70020013
         EJECT                                                          70110013
*THIS SECTION IS ENTERED ON RETURN FROM THE DATA GENERATION ROUTINE   * 70200013
*WHEN DATA REMAINS TO BE GENERATED. THE DATA AREA IN THE PARAMETER    * 70290013
*LIST IS ZEROED, AND THE BEAM OFF/ON SWITCH IS FLIPPED. THE X AND Y   * 70380013
*VALUES TO BE USED (X AN Y START IF THE BEAM IS OFF, AND X AND Y END  * 70470013
*IF THE BEAM IS ON) ARE UPDATED AND PLACED IN THE PARAMETER LIST        70560013
*                                                                       70650013
*RESETTING AND INITIALIZATION                                           70740013
*                                                                       70830013
AFASET05 XC    WKDATA1(32),WKDATA1      ZERO DATA FIELDS IN PARM LIST   70920013
         XI    WKBITS+2,BEAMSW          FLIP BEAM OFF/ON SWITCH         71010013
         LA    LOOPCT,2                 SET UP LOOP CONTROL FOR UPDATE  71100013
*                                                                       71190013
*INITIALIZE FOR FIRST PASS- X ENTRY                                     71280013
*                                                                       71370013
         SR    REGB,REGB                INDEX TO PARM LIST, FOR X=0     71460013
         MVC   WKSWAREA(1),WKSWITCH+3   MOVE DATA MODE SWITCH TO WORK   71550013
         NI    WKSWAREA,NOY              AREA AND ELIMINATE Y SWITCHES  71640013
         TM    WKBITS+2,BEAMSW                                          71730013
         BO    AFASET10                 BRANCH IF X AND Y END VALUES    71820013
*                                        TO BE USED                     71910013
*INITIALIZE FOR X-Y START VALUES                                        72000013
         SR    REGD,REGD                INDEX TO WKAREAS =0 FOR X START 72090013
         LA    REGC,WKSWITCH+1          SWITCH ADDRESS FOR X-Y START    72180013
         B     AFASET15                 GO TO PROCESS                   72270013
*                                                                       72360013
*INITIALIZE FOR X-Y END VALUES                                          72450013
*                                                                       72540013
AFASET10 LA    REGD,8                   INDEX TO WKAREAS=8 FOR X END    72630013
         LA    REGC,WKSWITCH+2          SWITCH ADDRESS FOR X-Y END      72720013
*                                                                       72810013
*LOOPCT= LOOP CONTROL INFORMATION                                       72900013
*REGB  = INDEX TO VALUES IN PARM LIST                                   72990013
*REGC  = ADDRESS OF SWITCH AREA                                         73080013
*REGD  = INDEX TO WORK AREA                                             73170013
*                                                                       73260013
AFASET15 TM    0(REGC),XINDX                                            73350013
         BZ    AFASET50                 BRANCH IF INCREMENT PARM PASSED 73440013
         EJECT                                                          73530013
*THIS SECTION ENTERED WHEN INDEX PARAMETER PASSED                       73620013
*                                                                       73710013
AFASET20 L     REGA,WKXVAL(REGD)        PICK UP POINTER TO DATA         73800013
         TM    WKSWAREA+2,ON                                            73890013
         BZ    AFASET90                 BRANCH IF 1ST TIME X-Y END USED 73980013
         A     REGA,WKXCHNG(REGD)       OTHERWISE, UPDATE POINTER       74070013
         ST    REGA,WKXVAL(REGD)         AND SAVE IT                    74160013
         TM    WKSWAREA,ABSOLXY                                         74250013
         BZ    AFASET95                 BRANCH IF DATA MODE INCREMENTAL 74340013
AFASET25 LA    REGB,WKXABS(REGB)        GET POINTER TO PARM LIST ENTRY  74430013
         MVC   0(4,REGB),0(REGA)        MOVE VALUE INTO PARM LIST       74520013
AFASET30 BCT   LOOPCT,AFASET40          *                               74610013
*                                                                       74700013
*X AND Y VALUES NOW UPDATED                                             74790013
         C     COUNT,ONE                                                74880013
         BE    AFASET35                 BRANCH IF LAST CALL TO DATA GEN 74970013
         OI    WKSWAREA+2,ON           SET SWITCH 1ST X,Y END USED      75060013
         B     AFASSD10                                                 75150013
*                                                                       75240013
AFASET35 TM    WKBITS+2,LASTIN                                          75330013
         BZ    AFASET37      BRANCH IF NO DATA GENERATED YET            75420013
         OI    WKBITS+2,LASTIN         SET LAST PASS SWITCH             75510013
         B     AFASSD10                                                 75600013
AFASET37 XI    WKBITS,MULT             MULT ENTRY HAS BECOME SINGLE     75690013
         B     AFASSD10                                                 75780013
         EJECT                                                          75870013
*INITIALIZATION FOR SECOND PASS THROUGH LOOP (Y VALUES)                 75960013
*                                                                       76050013
AFASET40 LA    REGB,4                   IX VALUE FOR PARM LIST=4 FOR Y  76140013
         AR    REGD,REGB                IX TO WK AREA FOR Y=4 PLUS X IX 76230013
*                                       SWITCH ADDR (REG C) REMAINS     76320013
         MVC   WKSWAREA(1),WKSWITCH+3   MOVE DATA MODE SWITCH AND       76410013
         NI    WKSWAREA,NOX              ELIMINATE ANY X SWITCHES       76500013
         TM    0(REGC),YINDX                                            76590013
         BZ    AFASET50                 BRANCH IF INCREMENT PARM PASSED 76680013
         B     AFASET20                                                 76770013
         EJECT                                                          76860013
*INCREMENT PARAMETER PASSED, DATA MODE ABSOLUTE OR INCREMENTAL          76950013
*                                                                       77040013
AFASET50 TM    WKSWAREA+2,ON                                            77130013
         BZ    AFASET60                 BRANCH IF 1ST TIME X-Y END USED 77220013
         TM    WKSWAREA,ABSOLXY                                         77310013
         BZ    AFASET65                 BRANCH IF DATA MODE INCREMENTAL 77400013
         TM    WKSWAREA,REALX+REALY                                     77490013
         BM    AFASET55                 BRANCH IF INCREMENT REAL        77580013
         L     REGA,WKXVAL(REGD)                                        77670013
         A     REGA,WKXCHNG(REGD)       ADD INCREMENT                   77760013
         ST    REGA,WKXVAL(REGD)        SAVE NEW VALUE AND              77850013
AFASET52 ST    REGA,WKXABS(REGB)         PLACE IT IN PARM LIST          77940013
         B     AFASET30                 RETURN TO CHECK LOOP COUNT      78030013
*                                                                       78120013
*INCREMENT VALUE REAL                                                   78210013
         SPACE                                                          78300013
AFASET55 LE    FLT2,WKXVAL(REGD)                                        78390013
         AE    FLT2,WKXCHNG(REGD)       ADD INCREMENT                   78480013
         STE   FLT2,WKXVAL(REGD)        SAVE NEW VALUE AND              78570013
         STE   FLT2,WKXABS(REGB)         PLACE IT IN PARAMETER LIST     78660013
         B     AFASET30                 RETURN TO CHECK LOOP COUNT      78750013
*                                                                       78840013
* X OR Y END INCREMENTED, FIRST TIME REFERENCED                         78930013
         SPACE                                                          79020013
AFASET60 L     REGA,WKXVAL(REGD)        PICK UP VALUE                   79110013
         TM    WKSWAREA,ABSOLXY                                         79200013
         BM    AFASET52                 BRANCH IF DATA MODE ABSOLUTE    79290013
         ST    REGA,WKXINCR(REGB)      PLACE INCR IN PARM LIST          79380013
         B     AFASET30                 RETURN TO CHECK LOOP COUNT      79470013
*                                                                       79560013
*DATA MODE INCREMENTAL, INCREMENT PARAMETER PASSED                      79650013
*                                                                       79740013
AFASET65 L     REGA,WKXCHNG(REGD)                                       79830013
         ST    REGA,WKTEMP                                              79920013
         B     AFASUB10                                                 80010013
         SPACE                                                          80100013
* X OR Y END INDEXED, FIRST TIME REFERENCED                             80190013
*                                                                       80280013
AFASET90 TM    WKSWAREA,ABSOLXY                                         80370013
         BM    AFASET25                 BRANCH IF DATA MODE ABSOLUTE    80460013
         LA    REGB,WKXINCR(REGB)       GET POINTER TO PARM LIST ENTRY  80550013
         MVC   0(4,REGB),0(REGA)        PLACE VALUE IN PARM LIST        80640013
         B     AFASET30                                                 80730013
*                                                                       80820013
*X OR Y INDEXED, DATA MODE INCREMENTAL                                  80910013
*                                                                       81000013
AFASET95 MVC   WKTEMP,0(REGA)           MOVE INCREMENT INTO WORK AREA   81090013
         B     AFASUB10                 GO TO COMPUTE INCREMENT         81180013
         EJECT                                                          81270013
*THIS ROUTINE COMPUTES THE INCREMENT TO BE PASSED TO THE SCALE          81360013
*ROUTINE. IT EXPECTS WKTEMP TO HOLD THE INCREMENT, AND THE VARIOUS      81450013
*REGISTERS AS SET UP- REGB-INDEX TO PARAMETER LIST, REGD-INDEX TO       81540013
*WORK AREAS, AND REGC-SWITCH ADDRESS. REGISTER 15 IS USED AS A          81630013
*WORK REGISTER                                                          81720013
*                                                                       81810013
AFASUB10 LR    REGFIFTN,REGD                                            81900013
         C     REGFIFTN,EIGHT                                           81990013
         BL    AFASUB50                 BRANCH IF UPDATING X OR Y START 82080013
         S     REGFIFTN,EIGHT           ESTABLISH IX TO X OR Y START    82170013
AFASUB15 TM    WKSWAREA,REALX+REALY                                     82260013
         BM    AFASUB60                 BRANCH IF FLOATING POINT        82350013
         L     REGA,WKTEMP              PICK UP INCREMENT               82440013
         A     REGA,WKXTOT(REGD)         ADD TO CUMULATIVE POSITION     82530013
         ST    REGA,WKXTOT(REGD)         AND SAVE NEW TOTAL             82620013
         S     REGA,WKXTOT(REGFIFTN)    FIND DIFFERENCE FROM LAST POSIT 82710013
         ST    REGA,WKXINCR(REGB)      AND SAVE IN PARM LIST            82800013
         B     AFASET30                 RETURN TO CHECK LOOP COUNT      82890013
*                                                                       82980013
AFASUB50 LA    REGFIFTN,8(REGFIFTN)     ESTABLISH INDEX TO X OR Y END   83070013
         B     AFASUB15                                                 83160013
*                                                                       83250013
*INCREMENT REAL NUMBER                                                  83340013
*                                                                       83430013
AFASUB60 LE    FLT2,WKTEMP             PICK UP INCREMENT                83520013
         AE    FLT2,WKXTOT(REGD)         ADD TO CUMULATIVE POAITION     83610013
         STE   FLT2,WKXTOT(REGD)         AND SAVE NEW TOTAL             83700013
         SE    FLT2,WKXTOT(REGFIFTN)    COMPUTE INCREMENT               83790013
         STE   FLT2,WKXINCR(REGB)        AND PUT IN PARAMETER LIST      83880013
         B     AFASET30                 RETURN TO CHECK LOOP COUNT      83970013
         EJECT                                                          84060013
AFAERR10 MVC   PARMERR(4,ERRCD),ONE     GDS INVALID                     84150013
         OI     0(ERRCD),PRM                                            84240013
         B     AFARET17                                                 84330013
*                                                                       84420013
AFAERR20 OI    0(ERRCD),PRM             PARAMETER ERROR                 84510013
         B     AFARET15                                                 84600013
*                                                                       84690013
AFAERR30 MVC   PARMERR(4,ERRCD),EIGHT   GENCODE ERROR                   84780013
         B     AFAERR20                                                 84870013
*                                                                       84960013
AFAERR40 MVC   PARMERR(4,ERRCD),SIX     CORRVAL ERROR                   85050013
         B     AFAERR20                                                 85140013
*                                                                       85230013
AFAERR70 MVC   PARMERR(4,ERRCD),NINE    COUNT ERROR                     85320013
AFAERR80 OI    0(ERRCD),SCISSOR         NO DATA GENERATION              85410013
         B     AFARET15                                                 85500013
*                                                                       85590013
AFAERR90 OI    0(ERRCD),STRG            MAIN STORAGE EXCEEDED           85680013
         MVC   STOR(4,ERRCD),FOUR                                       85770013
         B     AFARES10                                                 85860013
*                                                                       85950013
*CALL RESET IF ERROR RETURN FROM SCALE OR DATA GEN                      86040013
*                                                                       86130013
AFARES10 MVC   GDSXCURR(4),WKXCURR      RESTORE BEAM POINTERS           86220013
         MVC   GDSXLAST(8),WKXLAST                                      86310013
         CLI   WKSWITCH,UPDATE                                          86400013
         BE    AFARET15                BRANCH IF UPDATE-RESET NOT       86490013
*                                       NECESSARY                       86580013
         MVC   WKDATA2(20),0(ERRCD)     SAVE RETURN ARRAY               86670013
         LA    REGA,GDSGDSCB            VAR HOLDING ADDR OF GDSCB       86760013
         ST    REGA,WKGDS                                               86850013
         LA    REGA,WKGDS               ADDRESS OF PARAMETER LIST       86940013
         ST    REGA,WKGDS1               STORED IN WORK AREA            87030013
         L     REGA,NULL(ERRCD)         NULL FOR CORRVAL IN PARM LIST   87120013
         ST    REGA,WKRTN                                               87210013
         LA    REGA,WKADDR              ADDRESS OF KEY IN PARM LIST     87300013
         ST    REGA,WKDATA1                                             87390013
         OI    WKDATA1,LAST             LAST PARM INDICATION            87480013
         ST    ERRCD,WKCODE             ADDRESS OF RETURN ARRAY         87570013
         LA    PARM,WKGDS1              ADDRESS OF WORK AREA            87660013
         L     REGA,16                                                  87750013
         L     REGA,CVTLINK(REGA)       LINK LIB DCB                    87840013
*      LINK EP=IFFAFA12,DCB=(REGA),MF=(E,(1)),SF=(E,WKSPVSR)            87930013
         LINK  EP=IFFAFA12,MF=(E,(1)),SF=(E,WKSPVSR)                    88020013
         MVC   0(20,ERRCD),WKDATA2      RESTORE RETURN ARRAY            88110013
         B     AFARET15                                                 88200013
         EJECT                                                          88290013
*CONSTANTS                                                              88380013
*                                                                       88470013
ZERO     DC    2F'0'                                                    88560013
ONE      DC    F'1'                                                     88650013
TWO      DC    F'2'                                                     88740013
THREE    DC    F'3'                                                     88830013
FOUR     DC    F'4'                                                     88920013
FIVE     DC    F'5'                                                     89010013
SIX      DC    F'6'                                                     89100013
SEVEN    DC    F'7'                                                     89190013
EIGHT    DC    F'8'                                                     89280013
NINE     DC    F'9'                                                     89370013
BITS     DC    B'10000111'              MULTIPLE,VECTOR,INCLUDE,        89460013
         DC    X'00'                     OPTIMIZED, FIRST PASS, NO KEY, 89550013
         DC    B'00000000'               NO CORRVAL, BEAM OFF           89640013
         DC    X'00'                                                    89730013
         EJECT                                                          89820013
WORKAREA DSECT                                                          89910013
WKPARM   DS    F                        ADDRESS OF PARAMETER LIST       90000013
WKRTNCD  DS    F                        ADDRESS OF RETURN ARRAY         90090013
WKSAVE   DS    18F                      REGISTER SAVE AREA              90180013
WKSWITCH DS    F                                                        90270013
*                                       BYTE 0 - UPDATE SWITCH          90360013
*                                       BYTE 1                          90450013
*                                          X'C0' - X INDEX              90540013
*                                          X'0C' - Y INDEX              90630013
*                                          X'30' - X INCREMENT          90720013
*                                          X'03' - Y INCREMENT          90810013
*                                       BYTE 2                          90900013
*                                          X'C0' - X2 INDEX             90990013
*                                          X'0C' - Y2 INDEX             91080013
*                                          X'30' - X2 INCREMENT         91170013
*                                          X'03' - Y2 INCREMENT         91260013
*                                       BYTE 3   - COPY OF INPUT DATA   91350013
*                                          MODE SWITCH FROM GDSCB       91440013
WKSWAREA DS    F                                                        91530013
WKSPVSR  DS    3F                                                       91620013
WKSTORAD DS    F                                                        91710013
WKTEMP   DS    F                                                        91800013
WKXCHNG  DS    F                                                        91890013
WKYCHNG  DS    F                                                        91980013
WKXCHNG2 DS    F                                                        92070013
WKYCHNG2 DS    F                                                        92160013
WKXVAL   DS    F                                                        92250013
WKYVAL   DS    F                                                        92340013
WKXVAL2  DS    F                                                        92430013
WKYVAL2  DS    F                                                        92520013
WKXTOT   DS    F                                                        92610013
WKYTOT   DS    F                                                        92700013
WKXTOT2  DS    F                                                        92790013
WKYTOT2  DS    F                                                        92880013
WKXCURR  DS    H                        *                               92970013
WKYCURR  DS    H                        *SAVE AREA FOR INFORMATION      93060013
WKXLAST  DS    F                        *  FROM GDSCB                   93150013
WKYLAST  DS    F                        *                               93240013
* START OF PARAMETER LIST PASSED TO DATA GENERATION ROUTINE             93330013
*                                                                       93420013
WKADDR   DS    F                        BUFFER LENGTH & LOG. BUFF ADDR  93510013
WKBITS   DS    F                        SWITCHES                        93600013
WKCORVL  DS    F                        CORRVAL                         93690013
WKKEY    DS    F                        KEY                             93780013
* START OF PARAMETER LIST PASSED TO SCALING AND SCISSORING ROUTINES     93870013
WKGDS    DS    F                        ADDRESS OF GDSCB                93960013
WKRTN    DS    F                        ADDRESS OF RETURN ARRAY         94050013
WKDATA1  DS    F                            *                           94140013
WKDATA2  DS    F                            *                           94230013
WKDATA3  DS    F                            *                           94320013
WKDATA4  DS    F                        DATA ARRAY                      94410013
WKXABS   DS    F                            *                           94500013
WKYABS   DS    F                            *                           94590013
WKXINCR  DS    F                            *                           94680013
WKYINCR  DS    F                            *                           94770013
WKTOTX   DS    F                        X INCREMENT THUS FAR            94860013
WKTOTY   DS    F                        Y INCREMENT THUS FAR            94950013
WKENDCT  DS    F                                                        95040013
* PARAMETERS FOR KEY MANAGEMENT ROUTINE                                 95130013
WKGDS1   DS    F                        ADDRESS OF GDSCB                95220013
WKCODE   DS    F                        CODE FOR KEY MANAGEMENT         95310013
WKKADDR  DS    F                        ADDRESS OF KEY                  95400013
         COPY  GDSCB                                                    95490013
         COPY  GTMCB                                                    95580013
         END                                                            95670013
