*                                                                       00100013
*                                                                       00200013
*                             RESET INPUT PARAMETER LIST                00300013
*                                                                       00400013
*                             +0   A(GDSVAR) VARIABLE CONTAINING        00500013
*                                            THE ADDRESS OF THE         00600013
*                                            GDSCB                      00700013
*                                                                       00800013
*                             OPTIONAL:                                 00900013
*                             +4   A(CORVAL) CORRELATION VALUE          01000013
*                             +8   A(KEY)    KEY                        01100013
*                                                                       01200013
*                                                                       01300013
*                                                                       01400013
*                                                                       01500013
*                                                                       01600013
*                                                                       01700013
*                                                                       01800013
*        RESET IS ENTERED FROM THE DIRECTOR PART 2 WHEN BEING CALLED    01900013
*        BY A PROGRAM EXTERNAL TO GSP.  INTERNALLY, RESET IS CALLED     02000013
*        FROM ANY DATA GENERATING ROUTINE (SUCH AS PLINE) WHICH         02100013
*        ENCOUNTERS AN ERROR WHILE GENERATING DATA AND MUST RESTORE     02200013
*        THE SYSTEM TO THE CONDITION BEFORE THE CALL.  THE WAY RESET    02300013
*        DETERMINES IF THE CALL IS FROM AN INTERNAL ROUTINE FOR A KEY   02400013
*        LEVEL 1 GDS IS THAT IS SEARCHES THE KEY TABLE FOR THE KEY.     02500013
*        IF THE KEY IS NOT FOUND, THE LENGTH FIELD OF THE KEY IS        02600013
*        CHECKED FOR ZERO.  IF THE LENGTH IS ZERO IT IS ASSUMED         02700013
*        THAT THE CALL IS FROM THE INTERNAL ROUTINE.                    02800013
*                                                                       02900013
*        EXTERNAL ROUTINES REFERENCES ARE:                              03000013
*        KEY TABLE MANAGEMENT-IFFAHA03                                  03100013
*        BUFFER MANAGEMENT-IFFAHA02                                     03200013
*        EXEC-IFFAFA11                                                  03300013
*                                                                       03400013
*        EXTERNAL MACROS USED ARE:                                      03500013
*        LINK                                                           03600013
*        GWRITE                                                         03700013
*        WAIT                                                           03800013
*                                                                       03900013
         EJECT                                                          04000013
IFFAFA12 CSECT                                                          04100013
*2101,111000,121000                                                000A 04150019
*                                                                       04200013
*        ON ENTRY RESET ESTABLISHES A BASE REGISTER, SET UP THE WORK    04300013
*        AREA DSECT, ZEROS THE RETURN ARRAY, AND CHAINS THE SAVE        04400013
*        AREAS.                                                         04500013
         SAVE  (14,12)                                                  04600013
         BALR  BASE,0                                                   04700013
         USING *,BASE                                                   04800013
         LR    WORK,PARM           SET UP WORK AREA DSECT               04900013
         USING WORKAREA,WORK                                            05000013
         L     PARM,WRKPARM        LOAD ADDR OF PARM LIST               05100013
         L     ERRCD,WRKRTNCD                                           05200013
         XC    WRKSPVSR(12),WRKSPVSR ZERO SUPERVISOR PARAMETER LIST     05300013
         XC    0(20,ERRCD),0(ERRCD) ZERO RETURN ARRAY                   05400013
         ST    SAVE,WRKSAVE+4      CHAIN SAVE AREAS                     05500013
         LA    REGA,WRKSAVE                                             05600013
         ST    REGA,8(SAVE)                                             05700013
         LR    SAVE,REGA                                                05800013
*                                                                       05900013
*        RESET PICKS UP THE FIRST PARAMETER, THE GDSCB ADDRESS, INIT-   06000013
*        IALIZES THE DSCET AND CHECKS ITS VALIDITY.  IF VALID IT        06100013
*        NEXT INITIALIZES THE GTMCB DSECT.  IT ZEROS THE CORVAL         06200013
*        AND KEY LOCATION.  THE KEY IS THE FULL THREE WORDS OF          06300013
*        THE ACTUAL KEY THAT WOULD BE EXPECTED BACK FROM KEY            06400013
*        TABLE MANAGEMENT.                                              06500013
         L     GDSREG,GDS(PARM)    PICK UP ADDRESS OF GDSCB             06600013
         L     GDSREG,0(GDSREG)                                         06700013
         USING GDSCB,GDSREG        SET UP DSECT                         06800013
         C     GDSREG,GDSGDSCB     IS GDSCB VALID                       06900013
         BNE   ERR1                NO                                   07000013
         L     GTMREG,GDSGTMCB                                          07100013
         USING GTMCB,GTMREG        SET UP GTMCB DSECT                   07200013
         XC    WRKCORVL,WRKCORVL   ZERO CORVAL                          07300013
         XC    WRKKEY(12),WRKKEY   ZERO KEY                             07400013
         EJECT                                                          07500013
*                                                                       07600013
*        A CHECK IS MADE TO SEE IF THE GDS IS THE LAST PARAMETER        07700013
*        PASSED IN WHICH CASE THE ENTIRE GDS MUST BE RESET.  IF         07800013
*        THIS IS THE CASE A DUMMY KEY IS SET UP WITH A LOGICAL          07900013
*        ADDRESS OF ZERO.                                               08000013
         TM    GDS(PARM),LAST      IS THERE ONLY ONE PARM               08100013
         BO    RST00800            YES, RESET ENTIRE GDS                08200013
*                                                                       08300013
*        THE ADDITIONAL PARAMETERS, KEY AND CORVAL ARE CHECKED.         08400013
*        IF THE KEY IS PASSED THAT IS WHAT IS USED TO SEARCH THE        08500013
*        KEY TABLE.  IF THE KEY IS NOT FOUND, AND IN FACT WAS           08600013
*        PASSED, AND THE LENGTH IF THE KEY IS ZERO IT IS ASSUMED        08700013
*        THAT THIS IS A GSP RESET AND THE KEY TABLE RESET IS            08800013
*        BYPASSED.  IF THE KEY IS FOUND IT IS PLACED IN THE WORK        08900013
*        AREA AND THEN THE KEY TABLE IS RESET.  NOTE THAT FOR           09000013
*        LEVEL TWO ALL KEY TABLE MANIPULATION IS BYPASSED.              09100013
*                                                                       09200013
         CLC   NULL+1(3,ERRCD),CORVL+1(PARM)                            09300013
         BE    RST00100            YES                                  09500013
         L     REGB,CORVL(PARM)                                         09600013
         MVC   WRKCORVL,0(REGB)    PLACE CORVAL IN WORK AREA            09700013
RST00100 TM    CORVL(PARM),LAST    IS KEY PASSED                        09800013
         BO    RST00850                                                 09850013
         CLC   NULL+1(3,ERRCD),KEY+1(PARM) NULL                         09900013
         BE    RST00850            YES                                  09950013
         L     REGB,KEY(PARM)                                           10000013
         MVC   WRKKEY,0(REGB)      YES, PLACE KEY IN WORK AREA          10100013
         TM    GDSFLAGS,LEVEL2     IS THIS LEVEL 2                      10200013
         BO    RST00400            YES                                  10300013
         LA    REGB,WRKKEY                                              10400013
         ST    REGB,WRKPRLST+8     ADDR OF KEY                          10500013
         LA    REGB,KEYSRCH        SEARCH ON KEY CODE                   10600013
         EJECT                                                          10700013
RST00200 ST    REGB,WRKPRLST+4                                          10800013
         ST    GDSREG,WRKPRLST     ADDRESS OF GDSCB                     10900013
         LA    PARM,WRKPRLST                                            11000013
         L     REGB,GTMGSPCB       GET POINTER TO GSPCB            000A 11040019
         L     REGB,FE(REGB)       GET POINTER TO STATUS TABLE     000A 11080019
         L     REG15,ETE(REGB)     GET A&RS OF KEY TABLE MGMT      000A 11120019
         BALR  REG14,REG15         BRANCH TO KEY TABLE MGMT        000A 11160019
         LTR   REG15,REG15         FOUND                                11200013
         BNE   RST01000            NO                                   11300013
         MVC   WRKKEY(12),0(PARM)  SAVE ENTIRE KEY                      11400013
RST00300 LA    REGB,WRKKEY         BUILD PARM LIST TO RESET KEY TABLE   11500013
         ST    REGB,WRKPRLST+8     A KEY OF ZERO WILL RESET THE         11600013
         LA    REGB,RESETCDE       ENTIRE TABLE. FROM NOW ON A KEY      11700013
         ST    REGB,WRKPRLST+4     CONTAINING ZERO WILL                 11800013
         ST    GDSREG,WRKPRLST     SIGNIFY RESET THE ENTIRE GDS         11900013
         LA    PARM,WRKPRLST                                            12000013
         L     REGB,GTMGSPCB       GET POINTER TO GSPCB            000A 12040019
         L     REGB,FE(REGB)       GET POINTER TO STATUS TABLE     000A 12080019
         L     REG15,ETE(REGB)     GET ADRS OF KEY TABLE MGMT      000A 12120019
         BALR  REG14,REG15         BRANCH TO KEY TABLE MGMT        000A 12160019
         EJECT                                                          12200013
*                                                                       12300013
*        AT THIS POINT ALL POSSIBLE CASES THAT HAVE NOT EXITED          12400013
*        BECAUSE OF ERRORS ARE TOGETHER FOR THE LAST TIME.              12500013
*        WE HAVE A GUY RESETING THE GDS.  FOR THAT WRKKEY CONTAINS      12600013
*        ZERO.  THERE IS THE GUY RESETING A KEY OR CORVAL LEVEL         12700013
*        ONE.  FOR HIM WE HAVE A TWELVE BYTE KEY FROM THE KEY TABLE     12800013
*        CONTAINING ASSORTED INFORMATION ABOUT THE ELEMENT WE ARE       12900013
*        RESETING TO.  LAST WE HAVE A LEVEL TWO KEY OR A GSP            13000013
*        RESET KEY CONTAINING A LOGICAL BUFFER ADDRESS BUT NO           13100013
*        INFORMATION ABOUT THE ELEMENT WE ARE RESETING TO.              13200013
*        WE WILL SET UP THE OACB DSECT AND THE PROCESSING WILL          13300013
*        SPLIT INTO TWO PATHS.  ONE IS FOR THE RESET WHICH WILL         13400013
*        TAKE PLACE IN THE GDOA AND THE OTHER IS WHERE RESET            13500013
*        IN THE BUFFER.  NOTE THAT FOR EQUIVALENCE GDSS THE RESET       13600013
*        WILL ALWAYS BE IN THE GDOA.  ALSO, IF THE RESET IS             13700013
*        IN THE GDOA NO BUFFER WILL HAVE TO BE RELEASED SO THE          13800013
*        CALL TO BUFFER MANAGEMENT IS AT THE RESET TO THE BUFFER        13900013
*        ONLY.  A CHECK IS MADE TO SEE IF ANY DATA WAS EVER             14000013
*        GENERATED BECAUSE A RESET TO THE GDS MIGHT BE CALLED           14100013
*        BEFORE THIS.                                                   14200013
*                                                                       14300013
RST00400 LH    REGA,WRKKEY+2       LOAD LOGICAL START ADDR              14400013
         L     OACB,GDSAOACB       INITIALIZE OACB DSECT                14500013
         USING OACBARA,OACB                                             14600013
         TM    STATUS,NO           WAS BUFFER EVER ASSIGNED             14700013
         BO    RST00500            EXIT                                 14800013
         C     REGA,LOGSTRT        IS DATA IN GDOA                      14900013
         BL    RST00600            NO                                   15000013
         EJECT                                                          15100013
*                                                                       15200013
*        IF THE RESET IS IN THE GDOA THE LOGICAL CURRENT ADDRESS        15300013
*        IS SET TO THE ADDRESS IN THE KEY.  FOR THE RESET OF A          15400013
*        GDS THIS IS ZERO.  THE OLP IS SET BACK THE LENGTH OF THE       15500013
*        RESET.  THE LENGTH LEFT IS INCREASED THE LENGTH OF THE         15600013
*        RESET.  THE UNRESOLVED ADDRESS POINTER WHICH WOULD ALWAYS      15700013
*        BE SET FOR AN ELEMENT (NOT SEQUENCE OR SUBROUTINE) IS          15800013
*        SET TO ZERO.                                                   15900013
         L     REGB,LOGCURR        PICK UP LOGICAL CURRENT              16000013
         SR    REGB,REGA           SUBTRACT RESET LOGICAL TO DETERMINE  16100013
         ST    REGA,LOGCURR        LENGTH-KEY ADDR=NEW LOGCURR          16200013
         L     REGA,OLP            OLP                                  16300013
         SR    REGA,REGB           MINUS LENGTH OF RESET                16400013
         ST    REGA,OLP            IS NEW OLP                           16500013
         A     REGB,LENLEFT        LENGTH LEFT INCREASED BY LENGTH      16600013
         ST    REGB,LENLEFT        OF RESET                             16700013
         XC    CPU2(8),CPU2        ZERO UNRES ADDR POINTER              16800013
         EJECT                                                          16900013
*                                                                       17000013
*        A CHECK IS MADE TO SEE IF THERE IS A SEQUENCE OR SUBROUTINE    17100013
*        OPEN BEFORE THE RESET.  IF SO A CHECK IS MADE TO SEE IF        17200013
*        WE ARE RESETING WITHIN THE SEQUENCE OR SUBROUTINE, TO IT,      17300013
*        OR BEYOND IT.  IF WE ARE STILL WITHIN IT ALL SEQUENCE,         17400013
*        SUBROUTINE UPDATING IS COMPLETE.  IF WE ARE RESETING TO        17500013
*        IT, THE SEQUENCE, SUBROUTINE SWITCH IS SET TO ZERO,            17600013
*        THE GDSKEYSV ADDRESS IS SET TO ZERO AND THE UNRESOLVED         17700013
*        ADDRESS IN THE OACB, CPU1 OR BUF1 IS SET TO ZERO.  IF          17800013
*        WE ARE RESETING BEYOND IT A CHECK IS MADE TO SEE IF THIS       17900013
*        IS A SEQUENCE OR SUBROUTINE MEMBER KEY.  FOR A GDS, OR         18000013
*        A LEVEL TWO KEY THIS WILL ALWAYS BE ZERO.  IF THE KEY          18100013
*        DOES NOT BELONG TO A SEQUENCE OR SUBROUTINE THE SAME           18200013
*        PROCESSING TAKES PLACE AS FOR A RESET TO A SEQUENCE OR         18300013
*        SUBROUTINE KEY.  OTHERWISE THE KEY TABLE IS SEARCHED           18400013
*        FOR THE LAST SEQUENCE OR SUBROUTINE KEY BEFORE THIS            18500013
*        KEY (NOTE IT HAS ALREADY BEEN RESET TO THIS KEY SO             18600013
*        THE LAST KEY FOR A SEQUENCE OR SUBROUTINE WILL BE THE          18700013
*        ONE TO WHICH OUR KEY BELONGS.  THE SEQUENCE OR                 18800013
*        SUBROUTINE IS REOPENED BY SETTING THE LENGTH OF THE            18900013
*        SEQUENCE OR SUBROUTINE KEY IN THE KEY TABLE TO ZERO.           19000013
*        THE GDSKEYSV LOCATION IN THE GDSCB WILL BE SET TO THE          19100013
*        LOGICAL ADDRESS OF THE KEY AND THE SEQUENCE OR SUBROUTINE      19200013
*        STARTED WHICH WILL BE SET.  THE FLOW CONTROL RETURN ADDRESS    19300013
*        IS PLACED AT THE TOP OF THE SEQUENCE OR SUBROUTINE IN THE      19400013
*        GDOA AND THE CPU ADDRESS OF THE UNRESOLVED ADDRESS IS          19500013
*        SAVED IN THE CPU1 LOCATION IN THE OACB.                        19600013
*                                                                       19700013
RST00410 TM    GDSFLAGS,SEQ+SUB    IS A SEQ,SUB ALREADY OPEN            19800013
         BZ    RST00413            NO                                   19900013
         CLC   GDSKEYSV,WRKKEY+2   IS THIS THE ONE ALREADY OPEN         20000013
         BL    RST00440            WITHIN STARTED SEQ A OK              20100013
         BE    RST03200            RESET TO SEQUENCE KEY                20200013
RST00413 TM    WRKKEY+7,SEQM+SUBM  IS THE KEY SEQ OR SUBR MEMBER        20300013
         BZ    RST03200            NO ZERO SEQ AND EXIT                 20400013
         BAL   REG15,RST01920      SEARCH FOR DEQ KEY& CONVRT TO PHYSBF 20500013
         CLC   GDSGDOAL,H128       SUB SEG                              20600013
         BNE   RST00415            NO                                   20700013
         BAL   REG14,RST01100      GO GET SUBSEG ADDR                   20800013
         L     REGB,WRK128TP       PICK UP 128 START ADDR               20900013
RST00415 L     REGA,BLP            BUFFER LOAD POINT                    21000013
         SR    REGB,REGA           MINUS PHYS BUFFER                    21100013
         A     REGB,CRSA           POS IN GDOA OF START OF SEQ OR SUBR  21200013
         NI    GDSFLAGS,NTSEQSUB   ZERO SEQ/SUBR SW                     21300013
         L     REGC,WRKSEQKY       LOAD SEQ/SUBR KEY                    21400013
         TM    5(REGC),X'08'       SEQ                                  21500013
         BO    RST00420                                                 21600013
         OI    GDSFLAGS,SEQ        SET SEQ SW                           21700013
         B     RST00430                                                 21800013
         EJECT                                                          21900013
RST00420 OI    GDSFLAGS,SUB        SET SUBR SW                          22000013
         LA    REGB,8(REGB)        UPDATE TO INCLUDE OMIT               22100013
RST00430 LA    REGB,2(REGB)        TO THE ADDR                          22200013
         MVC   0(2,REGB),GDSOVDAT+2 MOVE IN FLOW CTL RTN ADDR           22300013
         ST    REGB,CPU1           SAVE CPU ADDR OF UNRES               22400013
         XC    BUF1,BUF1           ZERO BUFFER ADDR LOC                 22500013
         CLC   8(4,REGC),ZERO      IS IT CORRELATED                     22600013
         BNE   RST00440            NO                                   22700013
         OI    GDSFLAGS,CRVLPRES   SET CORRELATED FLAG IN GDS           22800013
*                                                                       22900013
*        A CHECK IS MADE TO SEE IF THIS IS AN EQUIVALENCE GDS WHICH     23000013
*        IS CURRENTLY IN THE BUFFER.  IF SO A CALL TO EXEC-IFFAFA11     23100013
*        IS MADE TO PLACE THE NEW COPY OF THE GDS OUT INTO THE BUFFER.  23200013
RST00440 TM    GDSFLAGS,EQUIV      IS THIS AN EQUIV IN THE BUFFER       23300013
         BZ    RST00500            NO EXIT                              23400013
         LA    REGA,GDSGDSCB       GDSCB                                23500013
         ST    REGA,WRKPRLST       IN PARM LIST                         23600013
         OI    WRKPRLST,LAST       SET LAST PARM SW                     23700013
         LA    REGA,WRKPRLST                                            23800013
         ST    REGA,WRKPRM         PARM LIST IN WORK AREA               23900013
         ST    ERRCD,WRKERR        FOR EXEC                             24000013
         LA    PARM,WRKPRM                                              24100013
         EJECT                                                          24200013
*//                                                                     24300013
*//      GO EXECUTE THIS EQUIVALENCE GDS                                24400013
*//                                                                     24500013
         LINK  EP=IFFAFA11,MF=(E,(1)),SF=(E,WRKSPVSR)                   24600013
*                                                                       24700013
*        THE CURRENT MODE SWITCH IS SET TO ZERO SO THAT THE NEXT        24800013
*        CALL TO A DATA GENERATING SUBROUTINE WILL GENERATE A SET       24900013
*        MODE ORDER.  CONTROL IS THEN RETURNED TO THE CALLING PROGRAM.  25000013
*                                                                       25100013
RST00500 MVI   GDSGRMOD,0          SET TO CONTROL MODE                  25200013
RST00550 L     SAVE,4(SAVE)        RETURN                               25300013
         RETURN (14,12),T                                               25400013
         EJECT                                                          25500013
*                                                                       25600013
*        IT HAS BEEN DETERMINED THAT THE RESET MUST TAKE PLACE          25700013
*        IN THE BUFFER.  A CHECK IS MADE TO SEE IF THE GDOA LENGTH      25800013
*        IS 128.  IF NOT THE LOGICAL ADDRESS OF THIS KEY IS DIVIDED     25900013
*        BY THE GDOA LENGTH LESS SIX FOR THE CONTROL BYTES TO DETER-    26000013
*        MINE WHICH SEGMENT OF BUFFER THIS BELONGS IN.  THE             26100013
*        QUOTIENT OF THE DIVIDE IS THE COUNT FIELD INTO THE BUFFER      26200013
*        CONTROL TABLE AND THE REMAINDER IS THE DISTANCE FROM THE       26300013
*        TOP OF THE SEGMENT THAT THIS LOGICAL ADDRESS IS LOCATED        26400013
*        AT.                                                            26500013
*                                                                       26600013
RST00600 CLC   GDSGDOAL,H128       IS GDOA A SUB SEGMENT                26700013
         BE    RST01050            YES, MUST BE HANDLED SEPARATELY      26800013
         SRDA  REGA,32             LOAD LOG INTO ODD REGISTER           26900013
         LH    REGC,GDSGDOAL       GDOA LEN                             27000013
         S     REGC,SIX            MINUS SIX                            27100013
         DR    REGA,REGC           DIVIDED INTO LOG ADDR=CT             27200013
         SR    REGD,REGD           ZERO REG                             27300013
         LH    REGC,GDSBCTEL       PICK UP DISPLACEMENT                 27400013
         MH    REGC,F3+2                                                27500013
         L     REG14,GTMBCTBL      TABLE ADDR                           27600013
RST00700 IC    REGD,2(REGC,REG14)  PICK UP COUNT                        27700013
         CR    REGD,REGB           EQUAL TO COUNT I HAVE                27800013
         BE    RST01300            YES                                  27900013
         IC    REGD,1(REGC,REG14)  PICK UP PTR TO NEXT                  28000013
         MH    REGD,F3+2                                                28100013
         CR    REGD,REGC           IS THIS LAST                         28200013
         BE    ERR2                                                     28300013
         LR    REGC,REGD                                                28400013
         SR    REGD,REGD                                                28500013
         B     RST00700                                                 28600013
RST00800 TM    GDSFLAGS,LEVEL2     LEVEL2                               28700013
         BO    RST00400            YES, DO NOT RESET KEY TABLE          28800013
         CLC   GDSKEYTB,ZERO       IS THERE A KEY TABLE                 28900013
         BE    RST00400            NO BYPASS DELETION                   29000013
         B     RST00300            RESET ENTIRE KEY TABLE               29100013
         EJECT                                                          29200013
RST00850 CLC   WRKCORVL,ZERO       IS IT CORRELATED                     29230013
         BE    RST00800            RESET GDS                            29260013
RST00900 LA    REGB,WRKCORVL       ADDR OF CORVL                        29300013
         ST    REGB,WRKPRLST+8                                          29400013
         LA    REGB,CORVSRCH       SEARCH ON CORVAL CODE                29500013
         B     RST00200            GO SEARCH                            29600013
RST01000 CLC   WRKKEY(2),ZERO      IS LENGTH IN KEY ZERO                29700013
         BE    RST00400            YES THIS IS A SYSTEM ERROR RESET     29800013
         B     ERR2                BAD KEY/CORVAL                       29900013
*                                                                       30000013
*        IF THE GDOA IS A SUBSEGMENT THE PHYSICAL ADDRESS OF THE        30100013
*        SUBSEGMENT IS COMPUTED AND THE LOGICAL ADDRESS IS THE          30200013
*        DISPLACEMENT INTO THE SEGMENT WHERE THE ELEMENT IS LOCATED.    30300013
*                                                                       30400013
RST01050 LA    REG14,RST01400                                           30500013
RST01100 LH    REGD,GDSBCTEL       PICK UP ELEM                         30600013
         M     REGC,F256                                                30700013
         LH    REGB,GDSBCTEL       DISP IN TABLE                        30800013
         MH    REGB,F3+2                                                30900013
         A     REGB,GTMBCTBL       ADDR OF TABLE                        31000013
         CLC   GDSBCTID,0(REGB)    IS SUBSEGMENT FIRST HALF             31100013
         BE    RST01200            YES                                  31200013
         AH    REGD,H128           NO, ADD 128 TO ADDR                  31300013
RST01200 LH    REGA,WRKKEY+2       LOAD LOG ADDR                        31400013
         ST    REGD,WRK128TP       SAVE 128 START                       31500013
         AR    REGD,REGA           COMPUTE BUFFER LOC                   31600013
         LA    REGD,2(REGD)        +2 FOR SET MODE                      31700013
         BR    REG14               RETURN TO CALLER                     31800013
         EJECT                                                          31900013
RST01300 L     REGD,F256           256                                  32000013
         ST    REGC,WRKDSP         SAVE DISP                            32100013
         M     REGC,WRKDSP         256 X DISP                           32200013
         D     REGC,F3             DIV BY 3                             32300013
         AR    REGD,REGA           PLUS DIST FROM TOP                   32400013
         LA    REGD,2(REGD)        +2 FOR SET MODE                      32500013
*                                                                       32600013
*        THE BUFFER ADDRESS IS SAVED.  THE CRSA IS SET EQUAL TO         32700013
*        THE GDOA AND SO IS THE OLP.  THE UNRESOLVED ADDRESS FOR AN     32800013
*        ELEMENT IS SET TO ZERO.  THE LOGICAL ADDRESS IN THE KEY        32900013
*        BECOMES THE LOGICAL CURRENT AND LOGICAL START ADDRESS.         33000013
*        THE BUFFER ADDRESS COMPUTED IS THE BLP.  IT IS ALSO THE        33100013
*        BUFFER START.  THE DISPLACEMENT INTO THE SEGMENT PLUS THE      33200013
*        SIX CONTROL BYTES SUBTRACTED FROM THE GDOA LENGTH BECOMES      33300013
*        THE LENGTH LEFT IN THE GDOA.  IF IT IS A SUBSEGMENT THE        33400013
*        CALL TO BUFFER MANAGEMENT IS BYPASSED.                         33500013
*                                                                       33600013
RST01400 ST    REGD,WRKBUFR        SAVE BUFFER ADDRESS                  33700013
         MVC   CRSA,GDOA           SET CRSA=GDOA                        33800013
         MVC   OLP,GDOA            SET OLP=CRSA,GDOA                    33900013
         XC    CPU2(8),CPU2        ZERO SECOND UNRES ADDR               34000013
         MVC   LOGSTRT+2(2),WRKKEY+2  SET UP NEW                        34100013
         MVC   LOGCURR,LOGSTRT     LOG START AND LOG CURRENT            34200013
         ST    REGD,BLP            SET UP BUFFER LOAD POINT             34300013
         ST    REGD,BUFSTART       AND BUFFER START                     34400013
         LH    REGB,GDSGDOAL       COMPUTE                              34500013
         S     REGB,SIX            LENGTH                               34600013
         SR    REGB,REGA           LEFT                                 34700013
         ST    REGB,LENLEFT        AND STORE                            34800013
         A     REGB,FOUR           ADD FOUR FOR TRANS ORD               34900013
         ST    REGB,BUFLEN          IN BUFFER LENGTH                    35000013
         CLC   GDSGDOAL,H128       IS THIS A SUBSEGMENT                 35100013
         BE    RST01600            YES                                  35200013
         EJECT                                                          35300013
*                                                                       35400013
*        HERE BUFFER MANAGEMENT IS CALLED PASSING IT IN DISPLACE-       35500013
*        MENT INTO THE BUFFER CONTROL TABLE OF THIS SEGMENT.  ANY       35600013
*        SUCCEEDING SEGMENTS WILL BE RELEASED TO THE SYSTEM BY          35700013
*        BUFFER MANAGEMENT.  A CHECK IS MADE TO SEE IF THE              35800013
*        REPLACEMENT DATA IF ANY IN THE GDSCB IS PART OF THE            35900013
*        RESET.  IF NOT IT IS LEFT AS IS.  IF YES THE FIELDS ARE        36000013
*        ZEROED AND THE FLAG TO SAVE THE NEXT FOUR BYTES AS             36100013
*        REPLACEMENT DATA ARE SET IN THE OACB FOR THE NEXT OVERFLOW.    36200013
*                                                                       36300013
         MVC   WRKPRLST(4),SIX     NO GO TO UBFFER MANAGEMENT           36400013
         ST    GDSREG,WRKPRLST+4   TO RESET BUFFER                      36500013
         L     PARM,WRKDSP                                              36600013
         SR    REG0,REG0                                                36700013
         D     REG0,F3                                                  36800013
         ST    PARM,WRKPRLST+8     DISP OF THIS ENTRY                   36900013
         LA    PARM,WRKPRLST                                            37000013
         ST    PARM,WRKPRM                                              37100013
         LA    PARM,WRKPRM                                              37200013
         ST    ERRCD,WRKERR                                             37300013
         L     REG15,STAT(ERRCD)                                        37400013
         L     REG15,BMGT(REG15)                                        37500013
         BALR  REG14,REG15         CALL BUFFER MANAGEMENT               37600013
         LH    REGB,GDSREPPB       PICK UP REPLACEMENT DATA ADDR        37700013
         LTR   REGB,REGB           ANY REPL DATA                        37800013
         BE    RST01600            NO                                   37900013
         EJECT                                                          38000013
         M     REGA,F3                                                  38100013
         D     REGA,F256           REFERENCE BCT FOR ENTRY FOR          38200013
         A     REGB,GTMBCTBL       THIS BUFFER ADDRESS                  38300013
         CLI   0(REGB),0           HAS BEEN RESET                       38400013
         BNE   RST03000            NO                                   38500013
RST01500 XC    GDSREPPB,GDSREPPB   ZERO REPLACEMENT DATA                38600013
         XC    GDSREPDT,GDSREPDT                                        38700013
         OI    STATUS,SAVEFOUR     SET  STATUS TO SAVE FOUR             38800013
RST01600 L     REGA,GTMDECB1       GRAPHIC DECB                         38900013
         L     REGB,GTMGRDCB       DCB                                  39000013
         LR    PARM,REGA                                                39100013
         WAIT  ECB=(1)             WAIT ON OLD I/O                      39200013
*                                                                       39300013
*        WE WILL NOW WRITE OUT A GTRU TO FLOW CONTROL                   39400013
*        AT THE ADDRESS DETERMINED. IN ALL CASES IT MAY                 39500013
*        NOT BE NEEDED BUT I CAN'T FIGURE OUT EASILY IF                 39600013
*        IT IS OR NOT                                                   39700013
*                                                                       39800013
         LR    PARM,REGA                                                39900013
         CLI   0(PARM),X'7F'                                            39920013
         BNE   ERR3                                                     39940013
         NI    0(PARM),X'BF'                                            39960013
         GWRITE (PARM),STR,(REGB),4,GDSOVDAT,BUFSTART+2,GDSFCBUF,MF=E   40000013
         EJECT                                                          40100013
*                                                                       40200013
*        A CHECK IS MADE TO SEE IF A SEQUENCE OR SUBROUTINE HAS BEEN    40300013
*        BEGUN BUT NOT COMPLETED.  IF YES A TEST IS MADE TO SEE IF      40400013
*        WE ARE RESETING WITHIN THE SEQUENCE OR SUBROUTINE, TO IT       40500013
*        OR BEYOND IT.  IF WE RESET TO THE SUBROUTINE OR SEQUENCE       40600013
*        THE FLAGS, UNRESOLVED ADDRESS AND LOGICAL ADDRESS OF THE       40700013
*        KEY IN THE GDSCB MUST BE SET TO ZERO.  IF WE ARE               40800013
*        RESETING BEYOND IT BUT NOT INTO ANOTHER SEQUENCE OR            40900013
*        SUBROUTINE THE SAME THING TAKES PLACE.  AFTER THIS CONTROL     41000013
*        IS RETURNED TO THE CALLING PROGRAM.                            41100013
*                                                                       41200013
RST01700 TM    GDSFLAGS,SEQ+SUB    IS SEQ/SUB BEGUN                     41300013
         BZ    RST01900            NO                                   41400013
         CLC   GDSKEYSV,WRKKEY+2   IS ELEMENT WITHIN THIS SEQ/SUB       41500013
         BL    RST00500            YES EXIT                             41600013
         BH    RST01900            NO                                   41700013
RST01750 NI    GDSFLAGS,NTSEQSUB   SET GDS NOT SEQ OR SUBR              41800013
         XC    CPU1(8),CPU1        ZERO UNRES ADDR                      41900013
         XC    GDSKEYSV,GDSKEYSV   ZERO ANY KEY                         42000013
         B     RST00500                                                 42100013
         EJECT                                                          42200013
*                                                                       42300013
*        WE NOW MUST FIND THE KEY TO THIS SEQUENCE OR SUBROUTINE,       42400013
*        AND REOPEN IT.  WE MUST SET UP AN UNRESOLVED ADDRESS           42500013
*        FOR THIS SEQ-SUBR AND GO INTO THE BUFFER  AND CHANGE           42600013
*        THE BRANCH ADDRESS OF THE INCLUDE/OMIT STRUCTURE TO            42700013
*        THE FLOW CONTROL RETURN ADDRESS SO THAT IF HE OMITS AN         42800013
*        UNFINISHED SEQ-SUBR HE WILL NOT BRANCH INTO BUFFER THAT        42900013
*        MAY NO LONGER BELONG TO HIM OR THAT CONTAINS OVERFLOW DATA     43000013
*                                                                       43100013
RST01900 TM    WRKKEY+7,SEQM+SUBM  IS THIS A SEQ/SUB MEMBER             43200013
         BZ    RST01750            NO RESET SW AND EXIT                 43300013
         LA    REG15,RST02750      SET TO FALL THROUGH                  43400013
RST01920 LH    REGA,WRKKEY+2       LOGICAL START ADDR OF KEY            43500013
         L     REGB,GDSKEYTB       KEY TABLE ADDR                       43600013
RST01950 LA    REGC,12(REGB)       ADDR OF FIRST KEY                    43700013
         L     REGD,4(REGB)        ADDR OF NEXT FREE LOCATION           43800013
RST02000 TM    4(REGC),X'20'       IS THIS KEY SEQ,SUBR,EOS, OR STROKE  43900013
         BO    RST02200            YES                                  44000013
RST02100 LA    REGC,12(REGC)       NEXT KEY                             44100013
         CR    REGC,REGD           ALL KEYS IN THIS TABLE CHECKED       44200013
         BNE   RST02000            NO                                   44300013
         L     REGB,0(REGB)        ALL TABLES CHECKED                   44400013
         LTR   REGB,REGB                                                44500013
         BZ    RST02300            YES                                  44600013
         B     RST01950            GO AGAIN                             44700013
         EJECT                                                          44800013
*                                                                       44900013
*        BECAUSE THE SEQUENCE/SUBROUTINE KEY IS THE LAST ONE IN         45000013
*        THE KEY TABLE, THE ADDRESS OF ANY KEY IS SAVED. THE            45100013
*        SECOND KEY REPLACES THE FIRST,ETC UNTIL THE ENTIRE             45200013
*        TABLE(S) IS SEARCHED. WHEN THIS IS DONE THE ADDRESS            45300013
*        I HAVE IS THE ADDRESS OF THE KEY I WANT.                       45400013
*                                                                       45500013
RST02200 TM    4(REGC),X'10'       IS THIS SEQ OR SUBR                  45600013
         BO    RST02100            NO                                   45700013
         ST    REGC,WRKSEQKY       SAVE                                 45800013
         B     RST02100                                                 45900013
RST02300 L     REGA,WRKSEQKY       PICK UP KEY ADDR                     46000013
         MVC   0(2,REGA),ZERO      ZERO LENGTH IN KEY                   46100013
         MVC   GDSKEYSV,2(REGA)    SAVE LOG ADDR OF KEY IN GDSCB        46200013
         LH    REGC,2(REGA)        OBTAIN LOGICAL ADDR OF KEY           46300013
         CLC   GDSGDOAL,H128       SUB SEGMENT                          46400013
         BE    RST02500            YES-WE ALREADY HAVE THE ADDR         46500013
         SRDA  REGC,32             SHIFT INTO ODD REGISTER              46600013
         LH    REGB,GDSGDOAL       GDOA LEN                             46700013
         S     REGB,SIX            MINUS SIX                            46800013
         DR    REGC,REGB           DIVIDE                               46900013
         L     REGA,GTMBCTBL                                            47000013
         LH    REGB,GDSBCTEL       BCT DISP                             47100013
         MH    REGB,F3+2                                                47200013
         SR    REG14,REG14                                              47300013
RST02400 IC    REG14,2(REGA,REGB)  PICK UP CNT FROM ENTRY               47400013
         CR    REG14,REGD          IS THIS THE SUBSEGMENT               47500013
         BE    RST02600            YES                                  47600013
         IC    REG14,1(REGA,REGB)  GET PTR TO NEXT                      47700013
         MH    REG14,F3+2                                               47800013
         CR    REG14,REGB          WAS THIS THE LAST                    47900013
         BE    ERR2                YES                                  48000013
         LR    REGB,REG14          KEEP LOOKING                         48100013
         SR    REG14,REG14                                              48200013
         B     RST02400                                                 48300013
RST02500 L     REGB,WRK128TP       ADDR OF 128 SUBSEGMENT               48400013
         B     RST02700                                                 48500013
         EJECT                                                          48600013
*                                                                       48700013
*        THE PHYSICAL BUFFER ADDRESS OF THE SEQUENCE MUST BE            48800013
*        COMPUTED SO THAT THE FLOW CONTROL ADDRESS CAN REPLACE          48900013
*        THE PREVIOUS RESOLVING ADDRESS THAT BRANCHES TO THE            49000013
*        END OF THE SEQUENCE.                                           49100013
*                                                                       49200013
RST02600 M     REGA,F256                                                49300013
         D     REGA,F3             COMPUTE PHYSICAL BEFFER ADDRESS      49500013
RST02700 AR    REGB,REGC           DISPL INTO PHYS ADDR                 49600013
         LA    REGB,2(REGB)        PLUS 2 FOR SET MODE                  49700013
         L     REGA,WRKSEQKY       LOAD SEQ-SUB KEY                     49800013
         BR    REG15                                                    49900013
         EJECT                                                          50000013
RST02750 NI    GDSFLAGS,NTSEQSUB   TURN OFF BOTH SWITCHES               50100013
         CLC   8(4,REGA),ZERO      CORRELATED                           50200013
         BNE   RST02770            NO                                   50300013
         OI    GDSFLAGS,CRVLPRES   SET SW                               50400013
RST02770 TM    4(REGA),X'08'       IS THIS A SEQUENCE                   50500013
         BO    RST02800            NO                                   50600013
         OI    GDSFLAGS,SEQ        SET SEQ SW                           50700013
         B     RST02900                                                 50800013
RST02800 OI    GDSFLAGS,SUB        SET SUBR SW                          50900013
RST02900 LA    REGB,2(REGB)        UPDATE TO ADDR LOCATION              51100013
         ST    REGB,WRKBUFR                                             51200013
         L     PARM,GTMDECB1       DECB                                 51300013
         WAIT  ECB=(1)             WAIT                                 51400013
         L     PARM,GTMDECB1                                            51500013
         CLI   0(PARM),X'7F'                                            51520013
         BNE   ERR3                                                     51540013
         NI    0(PARM),X'BF'                                            51560013
         L     REGA,GTMGRDCB       DCB                                  51600013
*                                  WRITE OUT F/C ADDR                   51700013
         GWRITE (PARM),STR,(REGA),2,GDSOVDAT+2,WRKBUFR+2,GDSFCBUF,MF=E  51800013
         ST    REGB,BUF1           SAVE LOC OF UNRES ADDR               51900013
         XC    CPU1,CPU1                                                52000013
         B     RST00500                                                 52100013
RST03000 CLC   WRKBUFR+2(2),GDSREPPB IS ADDR GR THAN OURS               52200013
         BH    RST03300            NO                                   52300013
         L     REGC,WRKBUFR                                             52400013
         A     REGC,LENLEFT        COMPUTE ADDR OF                      52500013
         LA    REGC,4(REGC)        END    OF SEGMENT                    52600013
         EJECT                                                          52700013
*                                                                       52800013
*        A CHECK IS MADE TO SEE IF THE REPLACEMENT DATA IS TO BE        52900013
*        RESET ALSO.  IF NOT IT IS LEFT AS IS.  IF YES, THE FIELDS      53000013
*        ARE SET TO ZERO AND THE FLAG TO SAVE THE NEXT FOUR BYTES       53100013
*        AS REPLACEMENT DATA ARE SET IN THE OACB FOR THE NEXT           53200013
*        OVERFLOW.                                                      53300013
         CH    REGC,GDSREPPB       IS ADDR LESS THEN END                53400013
         BH    RST01500            YES IT IS WITHIN AREA RESET          53500013
         B     RST01600            NO DO NOT RESET                      53600013
RST03200 NI    GDSFLAGS,NTSEQSUB   ZERO SEQ SUB SW                      53700013
         XC    CPU1(8),CPU1        ZERO UNRES ADDR                      53800013
         XC    GDSKEYSV,GDSKEYSV    SET SEQ KEY TO ZERO                 53900013
         B     RST00440                                                 54000013
RST03300 LH    REGC,GDSREPPB       ADDR FOR REPL DATA                   54005013
         A     REGC,F2                                                  54010013
         C     REGC,WRKBUFR        RESET HALF OF REP DATA               54015013
         BNE   RST01600            NO-DO NOT ZERO REP DATA              54020013
*        HALF THE REPLACEMENT DATA IS TO BE RESET. IT WILL BE RETURNED  54025013
*        TO THE GDOA AND THE PTRS WILL BE SET UP. THEN THE REPLACEMENT  54030013
*        DATA FIELDS IN THE GDSCB WILL BE ZEROED.                       54035013
         L     REGC,BUFSTART                                            54040013
         S     REGC,F2                                                  54045013
         ST    REGC,BUFSTART       BACK UP BUFFER START                 54050013
         ST    REGC,BLP            AND BLP                              54055013
         L     REGC,BUFLEN                                              54060013
         A     REGC,F2                                                  54065013
         ST    REGC,BUFLEN         ADD TWO TO LENGTH                    54070013
         L     REGC,OLP                                                 54075013
         MVC   0(2,REGC),GDSREPDT  MOVE FIRST TWO BYTES IN GDOA         54080013
         A     REGC,F2                                                  54085013
         ST    REGC,OLP            UPDATE OLP                           54090013
         B     RST01500            RESET REP DATA                       54095013
         EJECT                                                          54100013
ERR1     LA    REGA,ONE            FIRST PARM IN ERROR                  54200013
ERR1A    ST    REGA,PARER(ERRCD)                                        54300013
         OI    0(ERRCD),PRMER                                           54400013
         B     RST00550            RETURN                               54500013
ERR2     LA    REGA,TWO            CODE-BAD CORVAL                      54600013
         L     REGB,WRKKEY         IS THERE A KEY                       54700013
         LTR   REGB,REGB                                                54800013
         BZ    ERR1A               NO                                   54900013
         LA    REGA,ONE(REGA)      YES CODE FOR BAD KEY                 55000013
         B     ERR1A                                                    55100013
ERR3     OI    0(ERRCD),IO                                              55130013
         B     RST00550                                                 55160013
         EJECT                                                          55200013
*                                                                       55300013
*REGISTERS                                                              55400013
*                                                                       55500013
REG0     EQU   0                                                        55600013
PARM     EQU   1                                                        55700013
REGA     EQU   2                                                        55800013
REGB     EQU   3                                                        55900013
OACB     EQU   4                                                        56000013
WORK     EQU   5                   RST35800                             56100013
ERRCD    EQU   6                                                        56200013
GTMREG   EQU   7                   RST36000                             56300013
GDSREG   EQU   8                                                        56400013
BASE     EQU   9                                                        56500013
REGC     EQU   10                                                       56600013
REGD     EQU   11                                                       56700013
SAVE     EQU   13                                                       56800013
REG14    EQU   14                                                       56900013
REG15    EQU   15                                                       57000013
         EJECT                                                          57100013
GDS      EQU   0                                                        57200013
CORVL    EQU   4                                                        57300013
KEY      EQU   8                                                        57400013
LAST     EQU   X'80'                                                    57500013
NULL     EQU   20                                                       57600013
LEVEL2   EQU   X'10'                                                    57700013
NO       EQU   X'80'                                                    57800013
SEQ      EQU   X'04'                                                    57900013
SUB      EQU   X'02'                                                    58000013
STAT     EQU   24                                                       58100013
BMGT     EQU   816                                                      58200013
SAVEFOUR EQU   X'40'                                                    58300013
SEQM     EQU   X'40'                                                    58400013
SUBM     EQU   X'80'                                                    58500013
NTSEQSUB EQU   X'B9'                                                    58600013
CRVLPRES EQU   X'40'                                                    58700013
EQUIV    EQU   X'80'                                                    58800013
ONE      EQU   1                                                        58900013
PARER    EQU   16                                                       59000013
PRMER    EQU   X'08'                                                    59100013
TWO      EQU   2                                                        59200013
IO       EQU   X'04'                                                    59250013
ETE      EQU   828                                                 000A 59260019
FE       EQU   48                                                  000A 59270019
         EJECT                                                          59300013
RESETCDE DC    F'3'                                                     59400013
KEYSRCH  DC    F'2'                                                     59500013
CORVSRCH DC    F'5'                                                     59600013
H128     DC    H'128'                                                   59700013
F256     DC    F'256'                                                   59800013
F3       DC    F'3'                                                     59900013
SIX      DC    F'6'                                                     60000013
ZERO     DC    F'0'                                                     60100013
FOUR     DC    F'4'                                                     60200013
F2       DC    F'2'                                                     60250013
         EJECT                                                          60300013
WORKAREA DSECT                                                          60400013
WRKPARM  DS    F                                                        60500013
WRKRTNCD DS    F                                                        60600013
WRKSAVE  DS    18F                                                      60700013
WRKSPVSR DS    3F                                                       60800013
WRKCORVL DS    F                                                        60900013
WRKKEY   DS    3F                                                       61000013
WRKPRLST DS    4F                                                       61100013
WRKBUFR  DS    F                                                        61200013
WRKDSP   DS    F                                                        61300013
WRKSEQKY DS    F                                                        61400013
WRK128TP DS    F                                                        61500013
WRKPRM   DS    F                                                        61600013
WRKERR   DS    F                                                        61700013
         EJECT                                                          61800013
OACBARA  DSECT                                                          61900013
OTHER    DS    F                                                        62000013
GDOA     DS    F                                                        62100013
STATUS   DS    F                                                        62200013
CRSA     DS    F                                                        62300013
OLP      DS    F                                                        62400013
BLP      DS    F                                                        62500013
BUFSTART DS    F                                                        62600013
BUFLEN   DS    F                                                        62700013
CPU1     DS    F                                                        62800013
BUF1     DS    F                                                        62900013
CPU2     DS    F                                                        63000013
BUF2     DS    F                                                        63100013
LOGSTRT  DS    F                                                        63200013
LOGCURR  DS    F                                                        63300013
LENLEFT  DS    F                                                        63400013
         COPY  GDSCB                                                    63500013
         COPY  GTMCB                                                    63600013
         END                                                            63700013
