* TITLE:IDPOS-INDICATE POSITION                                         00400013
* STATUS:CHANGE LEVEL 0                                                 00800013
* FUNCTION:TO PASS TO GSP THE POSITION OF THE BEAM FOR SUBSEQUENT DATA  01200013
*          GENERATION.                                                  01600013
* ENTRY:ENTERED AT IFFAFA13 VIA A CALL TO IDPOS.                        02000013
* INPUT:GR#1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA.THE FIRST WORD    02400013
*       CONTAINS THE ADDRESS OF A PARAMETER LIST CONSTRUCTED AS FOLLOWS 02800013
*       1.GDSNAME:ADDRESS OF A VARIABLE WHICH CONTAINS THE ADDRESS OF   03200013
*         THE GDSCB.                                                    03600013
*       2.XCOOR:ADDRESS OF A CONSTANT OR VARIABLE,THE VALUE OF WHICH    04000013
*         DESIGNATES THE POSITION THAT IS TO BE USED AS THE ABSOLUTE    04400013
*         STARTING POINT FROM WHICH OTHER X CO-ORDINATES ARE TO BE      04800013
*         COMPUTED.                                                     05200013
*       3.YCOOR-SAME AS X EXCEPT IN THE Y DIRECTION.                    05600013
*             4.XBEAM-ADDRESS OF A CONSTANT OR VARIABLE WHICH CONTAINS  06000013
*                     THE VALUE OF THE XBEAM POSITION.                  06400013
*             5.YBEAM-SAME AS XBEAM EXCEPT IN Y DIRECTION.              06800013
* OUTPUT:NONE TO CALLER.THE GPSXLAST AND GPSYLAST FIELDS OF THE GPSCB   07200013
*        ARE UPDATED TO REFLECT THE NEW POSITION.GDSXCURR AND           07600013
*        GDSYCURR FIELDS ARE SET EQUAL TO GDSXLAST AND GDSYLAST(NO BEAM 08000013
*        PARAMETERS PASSED) OR ARE UPDATED TO REFLECT THE NEW BEAM      08400013
*        POSITIONS.                                                     08800013
* EXIT:RETURN TO CALLER VIA REGISTER  14.                               09200013
* RETURN CODES:2,0  SCALING ERROR                                       09600013
*              4,0  INSUFFICIENT NUMBER OF PARAMETERS                   10000013
*              4,1  INVALID GDSCB                                       10400013
*              0,0  SUCCESSFULL                                         10800013
* ATTRIBUTES:RE-ENTRANT,PROBLEM PROGRAM MODE                            11200013
* EXTERNAL ROUTINES:SCALE                                               11600013
* NOTES:THIS ROUTINE EXAMINES THE FOLLOWING CONTROL BLOCKS:             12000013
*       1.GDSCB                                                         12400013
*       2.GTMCB                                                         12800013
*       3.GSPCB                                                         13200013
R0       EQU   0                       PARM REQ 0                       13600013
R1       EQU   1                       PARM REG 1                       14000013
RLIST    EQU   2                       WORKAREA REG                     14400013
RPARAM   EQU   3                       USER PARAM LIST REG              14800013
RGDSCB   EQU   4                       GDSCB ADR REG                    15200013
RE       EQU   8                       WORK REG                         15600013
RBASE    EQU   9                       BASE REG                         16000013
RA       EQU   10                      WORK REG                         16400013
RB       EQU   11                      WORK REG                         16800013
SPARE1   EQU   12                      RSVD PL1                         17200013
RSAVE    EQU   13                      SAVE AREA PTR                    17600013
RC       EQU   14                      WORK REG                         18000013
RD       EQU   15                      WORK REG                         18400013
ZERO     EQU   0                       ZERO                             18800013
RC4      EQU   X'08'                   RTN CODE 4                       19200013
RCC4     EQU   16                      OFFSET TO RC 4                   19600013
ADD1     EQU   1                       ADD INFO                         20000013
LAST     EQU   X'80'                   LAST PARAM                       20400013
GID      EQU   X'03'                   GDSCB ADR                        20800013
OFFSAVE  EQU   8                       SAVE AREA CHAIN                  21200013
XREAL    EQU   X'C0'                   REAL MODE X                      21600013
XINTG    EQU   X'30'                   INTEGER MODE X                   22000013
YREAL    EQU   X'0C'                   REAL MODE Y                      22400013
YINTG    EQU   X'03'                   INTEGER MODE Y                   22800013
XREL     EQU   X'80'                   X-REAL-ABSOLUTE                  23200013
XINT     EQU   X'20'                   X-INTEGER ABSOLUTE               23600013
YREL     EQU   X'08'                   Y-REAL-ABSOLUTE                  24000013
YINT     EQU   X'02'                   Y-INTEGER-ABSOLUTE               24400013
IFFAFA13 CSECT                                                          24800013
         SAVE  (14,12)                                                  25200013
         BALR  RBASE,0                 SET UP BASE REG                  25600013
         USING *,RBASE                 DEFINE BASE REG                  26000013
         LR    RLIST,R1                LOAD REG                         26400013
         USING WORKAREA,RLIST          DEFINE DSECT                     26800013
         L     RPARAM,PLIST            LOAD ADR USER PARM LIST          27200013
         USING PARAM,RPARAM            DEFINE DSECT                     27600013
         ST    RSAVE,SAVE+4            SAVE-SAVE AREA PTR               28000013
         LA    RD,SAVE                 LOAD ADR OF MY SAVE AREA         28400013
         ST    RD,OFFSAVE(RSAVE)       STORE IN USER SAVE AREA          28800013
         LA    RSAVE,SAVE              ESTABLISH NEW SAVE AREA          29200013
         L     RA,RCA                  LOAD RTN CODE ARRAY ADR          29600013
         XC    ZERO(20,RA),ZERO(RA)    INITIALIZE ARRAY                 30000013
         B     AROUND                  BRANCH                           30400013
ERROR    L     RA,RCA                  LOAD RTN CODE ARRAY ADR          30800013
         STC   RB,ZERO(RA)             STORE RTN CODE                   31200013
         ST    RC,ZERO(RA,RD)          STORE ADD INFO                   31600013
OUTRTN   L     RSAVE,SAVE+4            RESTORE OLD SAVE AREA PTR        32000013
         RETURN (14,12),T              RETURN TO CALLING PROGRAM        32400013
AROUND   TM    GDSNM,LAST              LAST PARAM                       32800013
         BO    IND01                   BRANCH-YES                       33200013
         TM    XCOOR,LAST              LAST PARAM                       33600013
         BO    IND01                   BRANCH-YES                       34000013
         B     IND02                   BRANCH                           34400013
IND01    SR    RC,RC                   ADD INFO=0                       34800013
IND03    LA    RB,RC4                  LOAD RTN CODE                    35200013
         LA    RD,RCC4                 LOAD OFFSET                      35600013
         B     ERROR                   BRANCH                           36000013
IND02    L     RGDSCB,GDSNM            LOAD IN DIRECT PTR TO GDSCB      36400013
         L     RGDSCB,ZERO(RGDSCB)     LOAD PTR TO GDSCB                36800013
         USING GDSCB,RGDSCB            DEFINE DSECT                     37200013
         CLI   GDSGDSID,GID            IS THIS VALID GDSCB              37600013
         BE    IND04                   BRANCH IF YES                    38000013
         LA    RC,ADD1                 LOAD ADD INFO                    38400013
         B     IND03                   BRANCH                           38800013
IND04    L     RA,GDSGTMCB             LOAD GTMCB ADR                   39200013
         USING GTMCB,RA                DEFINE DSECT                     39600013
         L     RB,GTMGSPCB             LOAD GSPCB ADR                   40000013
         USING GSPCB,RB                DEFINE DSECT                     40400013
         L     RC,XCOOR                LOAD XCOOR PARM                  40800013
         CL    RC,GSPNULLV             XCOOR=NULL                       41200013
         BE    IND01                   BRANCH-YES                       41600013
         L     RC,YCOOR                L YCOOR PARM                     42000013
         LA    RC,ZERO(RC)             ZERO HI-ORDER BYTE               42400013
         CL    RC,GSPNULLV             YCOOR=NULL                       42800013
         BE    IND01                   BRANCH-YES                       43200013
         XC    DATARAY(52),DATARAY     CLEAR INPUT DATA ARRAY           43600013
         ST    RGDSCB,DATARAY          GDSCB ADR TO ARRAY               44000013
         MVC   RTNARAY(4),RCA          ADR OF RTN CODE ARRAY TO ARRAY   44400013
         L     RA,XCOOR                LOAD ADR OF X CO-ORD INATE       44800013
         MVC   XABS(4),ZERO(RA)        X CO-ORD TO ARRAY                45200013
         L     RA,YCOOR                LOAD ADR OF Y CO-ORDINATE        45600013
         LA    RA,ZERO(RA)             CLEAR HI ORDER BYTE              46000013
         MVC   YABS(4),ZERO(RA)        Y CO-ORD TO ARRAY                46400013
         IC    RE,GDSDATMD             SAVE DATA MODE                   46800013
         XC    MODE(1),MODE            CLEAR TEMP MODE AREA             47200013
         TM    GDSDATMD,XREAL          IS X REAL                        47600013
         BC    5,IND05                 BRANCH-X REAL                    48000013
         OI    MODE,XINT               SET X=INTEGER                    48400013
         B     IND06                   BRANCH                           48800013
IND05    OI    MODE,XREL               SET X=REAL                       49200013
IND06    TM    GDSDATMD,YREAL          IS Y REAL                        49600013
         BC    5,IND07                 BRANCH-Y REAL                    50000013
         OI    MODE,YINT               SET Y= INTEGER                   50400013
         B     IND08                   BRANCH                           50800013
IND07    OI    MODE,YREL               SET Y=REAL                       51200013
IND08    MVC   GDSDATMD(1),MODE        MOVE IN DUMMY MODE               51600013
         LA    R1,DATARAY              LOAD INPUT PARAM LIST ADR        52000013
         LINK  EP=IFFAHA06,MF=(E,(1))                                   52400013
         LTR   RD,RD                   WAS SCALE SUCCESSFULL            52800013
         BZ    IND09                   BRANCH IF YES                    53200013
         STC   RE,GDSDATMD             RESTORE DATA MODE                53600013
         B     OUTRTN                  BRANCH                           54000013
IND09    MVC   SAVEX(4),GDSXLAST       SAVE VALUE                       54400013
         MVC   SAVEY(4),GDSYLAST       SAVE VALUE                       54800013
         MVC   GDSXLAST(4),XABS        MOVE IN SCALED DATA              55200013
         MVC   GDSYLAST(4),YABS        MOVE IN SCALED DATA              55600013
         TM    YCOOR,LAST              WAS BEAM PASSED                  56000013
         BO    IND10                   BRANCH-NO BEAM PASSED            56400013
         B     IND11                   BRANCH TO BEAM PROCESSING        56800013
IND10    MVC   GDSXCURR(2),XABS+2      MOVE IN SCALLED DATA             57200013
         MVC   GDSYCURR(2),YABS+2      MOVE IN SCALED DATA              57600013
         STC   RE,GDSDATMD             RESTORE DATA MODE IN GDSCB       58000013
         B     OUTRTN                  BRANCH                           58400013
IND11    XC    DATARAY(52),DATARAY     CLEAR DATA ARRAY                 58800013
         ST    RGDSCB,DATARAY          GDSCB ADR TO DATA ARRAY          59200013
         MVC   RTNARAY(4),RCA          MOVE IN ADR OF RTN CODE ARRAY    59600013
         L     RA,GDSGTMCB             LOAD GTMCB ADR                   60000013
         L     RB,GTMGSPCB             LOAD GSPCB ADR                   60400013
         L     RA,XBEAM                LOAD ADR OF XBEAM                60800013
         LA    RA,ZERO(RA)             ZERO HI ORDER BYTE               61200013
         CL    RA,GSPNULLV             XBEAM=NULL                       61600013
         BE    IND17                   BRANCH=NULL                      62000013
         MVC   XABS(4),ZERO(RA)        X BEAM TO INPUT ARRAY            62400013
IND12    TM    XBEAM,LAST              LAST PARAM                       62800013
         BO    IND17                   BRANCH LAST PARAM                63200013
         L     RA,YBEAM                LOAD ADR OF YBEAM                63600013
         LA    RA,ZERO(RA)             ZERO HI ORDER BYTE               64000013
         CL    RA,GSPNULLV             YBEAM=NULL                       64400013
         BE    IND17                   BRANCH=NULL                      64800013
         MVC   YABS(4),ZERO(RA)        MOVE IN YBEAM TO INPUT ARRAY     65200013
IND14    LA    R1,DATARAY              LOAD ADR OF PARAM LIST           65600013
         LINK  EP=IFFAHA06,MF=(E,(1))  LINK TO SCALE                    66000013
         LTR   RD,RD                   WAS SCALE SUCCESSFULL            66400013
         BZ    IND15                   BRANCH-SCALE SUCCESSFULL         66800013
         STC   RE,GDSDATMD             RESTORE DATA MODE                67200013
         MVC   GDSXLAST(4),SAVEX       RESTORE GDSXLAST TO PREVIOUS VAL 67600013
         MVC   GDSYLAST(4),SAVEY       RESTORE GDSYLAST TO PREVIOUS VAL 68000013
         B     OUTRTN                  BRANCH                           68400013
IND15    STC   RE,GDSDATMD             RESTORE DATA MODE                68800013
         MVC   GDSXCURR(2),XABS+2      MOVE IN SCALED XBEAM             69200013
         MVC   GDSYCURR(2),YABS+2      MOVE IN SCALED YBEAM             69600013
         B     OUTRTN                  BRANCH                           70000013
IND17    MVC   GDSXLAST(4),SAVEX       RESTORE XLAST                    70400013
         MVC   GDSYLAST(4),SAVEY       RESTORE YLAST                    70800013
         STC   RE,GDSDATMD             RESTORE DATA MODE                71200013
         B     IND01                   BRANCH                           71600013
         CNOP  0,8                                                      72000013
         COPY  GTMCB                                                    72400013
         COPY  GSPCB                                                    72800013
         COPY  GDSCB                                                    73200013
PARAM    DSECT                                                          73600013
GDSNM    DS    1F                                                       74000013
XCOOR    DS    1F                                                       74400013
YCOOR    DS    1F                                                       74800013
XBEAM    DS    1F                                                       75200013
YBEAM    DS    1F                                                       75600013
WORKAREA DSECT                                                          76000013
PLIST    DS    1F                                                       76400013
RCA      DS    1F                                                       76800013
SAVE     DS    18F                                                      77200013
SAVEX    DS    1F                                                       77600013
SAVEY    DS    1F                                                       78000013
MODE     DS    1F                                                       78400013
DATARAY  DS    1F                                                       78800013
RTNARAY  DS    1F                                                       79200013
DUMMY1   DS    4F                                                       79600013
XABS     DS    1F                                                       80000013
YABS     DS    1F                                                       80400013
DUMMY2   DS    5F                                                       80800013
         END                                                            81200013
