* TITLE:STEOS-SET EOS                                                   00200013
* STATUS:CHANGE LEVEL0                                                  00400013
* FUNCTION:TO SET AND END ORDER SEQUENCE ORDER INTO THE BUFFER.         00600013
* ENTRY:ENTERED AT IFFAFA15 VIA A CALL TO STEOS.                        00800013
* INPUT:GR#1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA.THE FIRST WORD    01000013
*       CONTAINS THE ADDRESS OF A PARAMETER LIST CONSTRUCTED AS FOLLOWS 01200013
*       1.GDSNAME-A VARIABLE WHICH CONTAINS THE ADDRESS OF THE GASCB.   01400013
*       2.CORVAL-A VARIABLE WHICH CONTAINS A USER CORRELATION VALUE.    01600013
*       3.KEY-A VARIABLE INTO WHICH STEOS WILL PLACE A KEY.             01800013
*       4.GENCODE-A VARIABLE WHOSE VALUE INDICATES:                     02000013
*         1-GENERATE IN INCLUDE STATUS                                  02200013
*         2-GENERATE IN OMIT STATUS                                     02400013
* OUTPUT:THE END ORDER SEQUENCE ORDER IS PLACED IN THE BUFFER IN THE    02600013
*        STATUS REQUESTED BY GENCODE.THE KEY IS RETURNED TO THE CALLER. 02800013
* EXIT:RETURN TO CALLER VIA REGISTER 14.                                03000013
* RETURN CODES:3,0 NO STORAGE OR NO BUFFER AVAILABLE                    03200013
*              4,1 INVALID GDSCB                                        03400013
*              4,2 CORVAL IS 0                                          03600013
*              4,4 INVALID GENCODE                                      03800013
*              0,0 SUCCESSFULL                                          04000013
* ATTRIBUTES:RE-ENTRANT,PROBLEM PROGRAM MODE                            04200013
* EXTERNAL ROUTINES:DATA STORE                                          04400013
*                   KEY MANAGEMENT                                      04600013
*                   RESET                                               04800013
* NOTES:THE FOLLOWING CONTROL BLOCKS ARE EXAMINED BY THIS ROUTINE:      05000013
*       1.GDSCB                                                         05200013
*       2.GTMCB                                                         05400013
*       3.GSPCB                                                         05600013
*       4.OACB                                                          05800013
R0       EQU   0                       PARM REG 0                       06000013
R1       EQU   1                       PARM REG 1                       06200013
RLIST    EQU   2                       WORKAREA REG                     06400013
RPARM    EQU   3                       USER PARM LIST REG               06600013
RGDSCB   EQU   4                       GDSCB ADR REG                    06800013
RBASE    EQU   9                       BASE REG                         07000013
RA       EQU   10                      WORK REG                         07200013
RB       EQU   11                      WORK REG                         07400013
SPARE1   EQU   12                      RESERVED FOR PL1                 07600013
RSAVE    EQU   13                      SAVE AREA PTR REG                07800013
RC       EQU   14                      WORK REG                         08000013
RD       EQU   15                      WORK REG                         08200013
ADD1     EQU   1                       ADD INFO 1                       08400013
ADD4     EQU   4                       ADD INFO 4                       08600013
BFRSUB   EQU   X'80'                   BUFFER SUBROUTINE                08800013
BFRSUBA  EQU   X'02'                   BFR SUBROUTINE BEGUN             09000013
DUMKEY   EQU   X'08'                   DUMMY KEY                        09200013
EOS      EQU   X'30'                   END ORDER SEQUENCE               09400013
GID      EQU   X'03'                   GDSCB ID                         09600013
INCLUDE  EQU   X'04'                   INCLUDE                          09800013
INTKYCOR EQU   X'80'                   INTERNAL KEY/CORVAL SWITCH       10000013
LAST     EQU   X'80'                   LAST PARM                        10200013
LEVEL2   EQU   X'10'                   LEVEL 2 GDS                      10400013
LOGS     EQU   52                      OFFSET TO LOGICAL BFR START      10600013
LOGSTART EQU   2                       LOG START IN KEY                 10800013
MULTIPLE EQU   X'80'                   MULTIPLE KEY BIT                 11000013
OFFSAVE  EQU   8                       SAVE AREA CHAIN                  11200013
RCC3     EQU   12                      OFFSET TO ADD INFO               11400013
RCC4     EQU   16                      OFFSET TO ADD INFO               11600013
RC3      EQU   X'10'                   RTN CODE 3                       11800013
RC4      EQU   X'08'                   RTN CODE 4                       12000013
SEQ      EQU   X'40'                   SEQUENCE PART                    12200013
SEQA     EQU   X'04'                   SEQUENCE BEGUN                   12400013
USECOR   EQU   X'40'                   USER CORVAL                      12600013
USEGEN   EQU   X'10'                   USER GENCODE                     12800013
USEKEY   EQU   X'20'                   USER KEY                         13000013
ZERO     EQU   0                       ZERO                             13200013
FE       EQU   48                                                  000A 13260019
ETE      EQU   828                                                 000A 13320019
IFFAFA15 CSECT                                                          13400013
*1677,536000                                                       000A 13500019
         SAVE  (14,12)                 SAVE REGS                        13600013
         BALR  RBASE,0                 SET UP BASE REG                  13800013
         USING *,RBASE                 DEFINE BASE REG                  14000013
         LR    RLIST,R1                LOAD REGISTER                    14200013
         USING WORKAREA,RLIST          DEFINE DSECT                     14400013
         L     RPARM,PLIST             LOAD ADR OF USER PARAM LIST      14600013
         USING PARAM,RPARM             DEFINE DSECT                     14800013
         ST    RSAVE,SAVE+4            SAVE-SAVE AREA PTR               15000013
         LA    RD,SAVE                 LOAD ADR OF MY SAVE AREA         15200013
         ST    RD,OFFSAVE(RSAVE)       STORE IN USER SAVE AREA          15400013
         LA    RSAVE,SAVE              ESTABLISH NEW SAVE AREA          15600013
         L     RA,RCA                  LOAD RTN CODE ARRAY ADR          15800013
         XC    ZERO(20,RA),ZERO(RA)    INITIALIZE RTN CODE ARRAY        16000013
         B     AROUND                  BRANCH                           16200013
ERROR    L     RA,RCA                  LOAD RTN CODE ARRAY ADR          16400013
         STC   RB,ZERO(RA)             STORE RTN CODE                   16600013
         ST    RC,ZERO(RA,RD)          STORE ADD INFO AT PROPER OFFSET  16800013
OUTRTN   L     RSAVE,SAVE+4            RESTORE OLD SAVE AREA PTR        17000013
         RETURN (14,12),T              RETURN                           17200013
AROUND   XC    SWITCH(1),SWITCH        INITIALIZE SWITCH                17400013
         XC    TEMPKEY(12),TEMPKEY     INITIALIZE TEMPORARY KEY         17600013
         L     RGDSCB,GDSNM            LOAD INDIRECT PTR TO GDSCB       17800013
         LA    RGDSCB,ZERO(RGDSCB)     ZERO HI ORDER BYTE               18000013
         L     RGDSCB,ZERO(RGDSCB)     LOAD GDSCB ADR                   18200013
         USING GDSCB,RGDSCB            DEFINE DSECT                     18400013
         CLI   GDSGDSID,GID            VALID  GDSCB                     18600013
         BE    ST01                    BRANCH IF VALID                  18800013
         LA    RC,ADD1                 LOAD ADD INFO                    19000013
ST02     LA    RB,RC4                  LOAD RTN CODE                    19200013
         LA    RD,RCC4                 LOAD ADD INFO OFFSET             19400013
         B     ERROR                   BRANCH                           19600013
ST01     TM    GDSNM,LAST              IS THIS THE LAST PARM            19800013
         BO    ST03                    BRANCH-LAST PARAM                20000013
         L     RA,GDSGTMCB             LOAD GTMCB ADR                   20200013
         USING GTMCB,RA                DEFINE DSECT                     20400013
         L     RB,GTMGSPCB             LOAD GSPCB ADR                   20600013
         USING GSPCB,RB                DEFINE DSECT                     20800013
         L     RC,CORVAL               LOAD CORVAL ADR                  21000013
         LA    RC,ZERO(RC)             ZERO HI ORDER BYTE               21200013
         CL    RC,GSPNULLV             CORVAL=NULL                      21400013
         BE    ST04                    BRANCH-CORVAL=NULL               21600013
         OI    SWITCH,USECOR           INDICATE USER CORVAL PRESENT     21800013
         CLC   ZERO(4,RC),ZERO1        USER CORVAL=0                    22000013
         BNE   ST04                    BRANCH-CORVAL NOT EQUAL TO 0     22200013
         L     RC,TWO                  LOAD ADD INFO                    22400013
         B     ST02                    BRANCH                           22600013
ST04     TM    CORVAL,LAST             IS THIS THE LAST PARM            22800013
         BO    ST03                    BRANCH-LAST PARM                 23000013
         L     RC,KEY                  LOAD KEY ADR                     23200013
         LA    RC,ZERO(RC)             ZERO HI ORDER BYTE               23400013
         CL    RC,GSPNULLV             KEY=NULL                         23600013
         BE    ST05                    BRANCH-KEY=NULL                  23800013
         OI    SWITCH,USEKEY           INDICATE USER KEY PRESENT        24000013
ST05     TM    KEY,LAST                LAST PARAM                       24200013
         BO    ST03                    BRANCH-LAST PARM                 24400013
         L     RC,GENCODE              LOAD GENCODE ADR                 24600013
         LA    RC,ZERO(RC)             ZERO HI ORDER BYTE               24800013
         CL    RC,GSPNULLV             GEN CODE=NULL                    25000013
         BE    ST03                    BRANCH-GENCODE=NULL              25200013
         OI    SWITCH,USEGEN           INDICATE USER GENCODE PRESENT    25400013
         L     RC,ZERO(RC)             LOAD VALUE OF GENCODE            25600013
         CL    RC,ONE                  GEN CODE=1                       25800013
         BE    ST03                    BRANCH IF YES                    26000013
         CL    RC,TWO                  GEN CODE=2                       26200013
         BE    ST03                    BRANCH IF YES                    26400013
ST23     LA    RC,ADD4                 LOAD ADD INFO CODE               26600013
         B     ST02                    BRANCH                           26800013
ST03     TM    GDSFLAGS,LEVEL2         LEVEL 2 GDS                      27000013
         BO    ST06                    BRANCH-LEVEL 2                   27200013
         TM    SWITCH,USECOR           USER CORVAL PRESENT              27400013
         BC    14,ST06                 BRANCH IF NO                     27600013
ST19     L     RC,GDSAOACB             LOAD ADR OF OACB                 27800013
         L     RD,LOGS(RC)             LOAD LOGICAL START (BFR)         28000013
         STH   RD,TEMPKEY+2            STORE IN KEY                     28200013
         OI    W1A,MULTIPLE            INDICATE MULTIPLE IN KEY         28400013
         OI    W1A,EOS                 INDICATE END ORDER SEQUENCE      28600013
         TM    SWITCH,USEGEN           USER GEN CODE                    28800013
         BO    ST07                    BRANCH-YES                       29000013
ST09     OI    W1A,INCLUDE             SET INCLUDE STATUS               29200013
         B     ST08                    BRANCH                           29400013
ST07     L     RA,GENCODE              LOAD ADR OF GENCODE VALUE        29600013
         LA    RA,ZERO(RA)             ZERO HI ORDER BYTE               29800013
         CLC   ZERO(4,RA),ONE          GENCODE=ONE                      30000013
         BE    ST09                    BRANCH IF YES                    30200013
ST08     TM    GDSFLAGS,SEQA           PART OF SEQUENCE                 30400013
         BC    14,ST10                 BRANCH-NO                        30600013
         OI    W1D,SEQ                 INDICATE PART OF SEQUENCE        30800013
ST10     TM    GDSFLAGS,BFRSUBA        PART OF BFR SUBROUTINE           31000013
         BC    14,ST11                 BRANCH-NO                        31200013
         OI    W1D,BFRSUB              INDICATE PART OF BFR SUB         31400013
ST11     TM    SWITCH,DUMKEY           IS THIS OUT OF LINE REQUEST      31600013
         BO    ST20                    BRANCH IF YES                    31800013
         L     RA,CORVAL               LOAD CORVAL ADR                  32000013
         LA    RA,ZERO(RA)             ZERO HI ORDER BYTE               32200013
         MVC   CORVALA(4),ZERO(RA)     MOVE IN CORVAL                   32400013
         OI    SWITCH,INTKYCOR         SET INTERNAL SWITCH              32600013
ST06     TM    SWITCH,USEKEY           IS THERE KEY PARAM               32800013
         BO    ST12                    BRANCH IF YES                    33000013
ST13     TM    SWITCH,USEGEN           USER GENCODE                     33200013
         BO    ST14                    BRANCH IF YES                    33400013
ST21     TM    SWITCH,INTKYCOR         INTERNAL SWITCH ON               33600013
         BO    ST15                    BRANCH IF YES                    33800013
         MVC   RTNARY(4),RCA           MOVE IN RTN CODE ARRAY ADR       34000013
         ST    RGDSCB,GDSCBA           STORE GDSCB ADR                  34200013
         MVC   VALUEA(4),TWO           MOVE IN VALUE                    34400013
         MVC   ORDER(2),GEOS           MOVE IN ORDER                    34600013
         LA    R1,GDSCBA               LOAD PARAM LIST ADR              34800013
         LINK  EP=IFFAHA05,MF=(E,(1))  LINK TO DATA STORE               35000013
         XC    GDSGRMOD(1),GDSGRMOD    CLEAR MODE                       35200013
         LTR   RD,RD                   DATA STORE SUCCESSFULL           35400013
         BZ    ST16                    BRANCH-YES                       35600013
         B     OUTRTN                  BRANCH                           35800013
ST16     TM    SWITCH,USEKEY           IS THERE A KEY                   36000013
         BC    14,OUTRTN               BRANCH IF NO                     36200013
         L     RA,KEY                  LOAD ADR OF KEY                  36400013
         LA    RA,ZERO(RA)             ZERO HIGH ORDER BYTE             36600013
         SR    RB,RB                   CLEAR REG                        36800013
         LH    RB,LOGSTART(RA)         LOAD PREV LOGICAL START          37000013
         L     RC,GDSAOACB             LOAD OACB ADDRESS                37200013
         L     RD,LOGS(RC)             LOAD NEW LOGICAL START           37400013
         SR    RD,RB                   DETERMINE LENGTH                 37600013
         STH   RD,ZERO(RA)             STORE IN USER KEY                37800013
         B     OUTRTN                  BRANCH                           38000013
ST12     TM    GDSFLAGS,LEVEL2         LEVEL2 GDS                       38200013
         BC    14,ST17                 BRANCH IF NO                     38400013
         L     RA,GDSAOACB             LOAD OACB ADR                    38600013
         L     RB,LOGS(RA)             LOAD LOGICAL BFR START           38800013
         L     RA,KEY                  LOAD KEY ADR                     39000013
         LA    RA,ZERO(RA)             ZERO HI ORDER BYTE               39200013
         STH   RB,LOGSTART(RA)         STORE IN USER KEY                39400013
         B     ST13                    BRANCH                           39600013
ST17     TM    SWITCH,INTKYCOR         INTERNAL SWITCH ON               39800013
         BC    14,ST18                 BRANCH IF NO                     40000013
         L     RA,KEY                  LOAD ADR OF KEY                  40200013
         LA    RA,ZERO(RA)             ZERO HI ORDER BYTE               40400013
         MVC   LOGSTART(2,RA),TEMPKEY+2 OVE IN LOGICAL START            40600013
         B     ST13                    BRANCH                           40800013
ST18     OI    SWITCH,DUMKEY           SET OUT OF LINE REQUEST          41000013
         B     ST19                    BRANCH                           41200013
ST20     OI    SWITCH,INTKYCOR         INDICATE INTERNAL KEY            41400013
         L     RA,KEY                  LOAD KEY ADR                     41600013
         LA    RA,ZERO(RA)             ZERO HI ORDER BYTE               41800013
         MVC   LOGSTART(2,RA),TEMPKEY+2  MOVE IN LOGICAL START          42000013
         B     ST13                    BRANCH                           42200013
ST14     L     RA,GENCODE              LOAD GEN CODE ADR                42400013
         LA    RA,ZERO(RA)             ZERO HI ORDER BYTE               42600013
         CLC   ZERO(4,RA),ONE          GENCODE=1                        42800013
         BE    ST21                    BRANCH IF YES                    43000013
         TM    SWITCH,INTKYCOR         INTERNAL SWITCH ON               43200013
         BO    ST22                    BRANCH IF YES                    43400013
         B     ST23                    BRANCH-GENCODE ERROR             43600013
ST22     MVC   ORDER(2),GTRU           SET UP OMIT                      43800013
ST24     ST    RGDSCB,GDSCBA           STORE GDSCB ADR                  44000013
         MVC   RTNARY(4),RCA           MOVE IN RTN CODE ARRAY ADR       44200013
         MVC   VALUEA(4),CALL1         MOVE IN VALUE                    44400013
         B     ST25                    BRANCH                           44600013
ST15     MVC   ORDER(2),GNOP4          SET UP INCLUDE                   44800013
         B     ST24                    BRANCH                           45000013
ST25     LA    R1,GDSCBA               LOAD PARAM LIST ADR              45200013
         LINK  EP=IFFAHA05,MF=(E,(1))  TO DATA STORE                    45400013
         LTR   RD,RD                   DATA STORE SUCCESSFULL           45600013
         BZ    ST26                    BRANCH IF YES                    45800013
         B     OUTRTN                  BRANCH                           46000013
ST26     ST    RGDSCB,GDSCBA           STORE GDSCB ADR                  46200013
         MVC   RTNARY(4),RCA           MOVE IN RTN CODE ARRAY ADDRESS   46400013
         MVC   VALUEA(4),TWO           MOVE IN CONSTANT                 46600013
         MVC   ORDER(2),GEOS           MOVE IN ORDER                    46800013
         LA    R1,GDSCBA               LOAD PARM LIST ADR               47000013
         LINK  EP=IFFAHA05,MF=(E,(1))  TO DATA STORE                    47200013
         LTR   RD,RD                   DATA STORE SUCCESSFULL           47400013
         BZ    ST27                    BRANCH IF YES                    47600013
         B     RESET                   BRANCH                           47800013
ST27     ST    RGDSCB,GDSCBA           STORE GDSCB ADR                  48000013
         MVC   RTNARY(4),RCA           MOVE IN RTN CODE ARRAY ADR       48200013
         MVC   VALUEA(4),CALL3         MOVE IN CONSTANT                 48400013
         LA    R1,GDSCBA               LOAD ADR OF PARM LIST            48600013
         LINK  EP=IFFAHA05,MF=(E,(1))  TO DATA STORE                    48800013
         XC    GDSGRMOD(1),GDSGRMOD    CLEAR MODE                       49000013
         LTR   RD,RD                   DATA STORE SUCCESSFULL           49200013
         BZ    ST28                    BRANCH IF YES                    49400013
         B     RESET                   BRANCH                           49600013
ST28     L     RA,GDSAOACB             LOAD OACB ADR                    49800013
         L     RA,LOGS(RA)             LOAD NEW LOGICAL START ADR       50000013
         SR    RB,RB                   CLEAR REG                        50200013
         LH    RB,TEMPKEY+2            LOAD OLD LOGICAL START ADR       50400013
         SR    RA,RB                   DETERMINE LENGTH                 50600013
         STH   RA,TEMPKEY              STORE LENGTH IN KEY              50800013
         TM    SWITCH,USEKEY           USER KEY                         51000013
         BO    ST29                    BRANCH IF YES                    51200013
         B     ST30                    BRANCH                           51400013
ST29     L     RA,KEY                  LOAD ADR USER KEY                51600013
         LA    RA,ZERO(RA)             ZERO HI ORDER BYTE               51800013
         MVC   ZERO(4,RA),TEMPKEY      MOVE IN KEY                      52000013
ST30     MVC   CODEA(4),CODE           MOVE IN CODE                     52200013
         ST    RGDSCB,GDSCBB           STORE GDSCB ADR                  52400013
         LA    RA,CODEA                LOAD ADR OF CODE                 52600013
         ST    RA,CODEB                STORE CODE ADR                   52800013
         LA    RA,TEMPKEY              LOAD ADR OF KEY                  53000013
         ST    RA,KEYB                 STORE KEY ADR                    53200013
         LA    R1,GDSCBB               LOAD ADR OF PARM LIST            53400013
         L     RA,GDSGTMCB         GET POINTER TO GTMCB            000A 53460019
         L     RA,4(RA)            GET POINTER TO GSPCB            000A 53520019
         L     RA,FE(RA)           GET POINTER TO STATUS TABLE     000A 53580019
         L     RD,ETE(RA)          GET ADRS OF KEY TABLE MGMT      000A 53640019
         BALR  RC,RD               BRANCH TO KEY TABLE MGMT        000A 53700019
         LTR   RD,RD                   KEY TABLE SUCCESSFULL            53800013
         BZ    OUTRTN                  BRANCH IF YES                    54000013
         L     RA,RCA                  LOAD RTN CODE ARRAY ADR          54200013
         MVI   ZERO(RA),RC3            MOVE IN RTN CODE                 54400013
         LA    RB,ADD4                 LOAD ADD INFO                    54600013
         ST    RB,RCC3(RA)             STORE ADD INFO                   54800013
RESET    L     RA,RCA                  LOAD RTN CODE ARRAY ADR          55000013
         MVC   SAVE1(20),ZERO(RA)      SAVE ARRAY                       55200013
         XC    GDSGRMOD(1),GDSGRMOD    RESET MODE                       55400013
         L     RB,GDSAOACB             LOAD OACB ADR                    55600013
         L     RB,LOGS(RB)             LOAD NEW LOGICAL START ADR       55800013
         SR    RC,RC                   CLEAR REG                        56000013
         LH    RC,TEMPKEY+2            LOAD OLD LOGICAL START ADR       56200013
         SR    RB,RC                   DETERMINE LENGTH                 56400013
         STH   RB,TEMPKEY              STORE LENGTH                     56600013
         LA    RB,GDSCBC               LOAD ADR OF PARM                 56800013
         ST    RB,GDSCBD               STORE ADR                        57000013
         ST    RGDSCB,GDSCBC           STORE GDSCB ADR                  57200013
         LA    RB,TEMPKEY              LOAD ADR OF KEY                  57400013
         ST    RB,KEYD                 STORE KEY ADR                    57600013
         TM    SWITCH,USECOR           USER CORVAL                      57800013
         BO    ST31                    BRANCH IF YES                    58000013
         XC    CORVALC(4),CORVALC      INDICATE ZERO CORVAL             58200013
         B     ST32                    BRANCH                           58400013
ST31     L     RB,CORVAL               LOAD ADR OF CORVAL               58600013
         LA    RB,ZERO(RB)             ZERO HI ORDER BYTE               58800013
         MVC   CORVALC(4),ZERO(RB)     MOVE IN USER CORVAL              59000013
ST32     LA    RB,CORVALC              LOAD PARM ADR                    59200013
         ST    RB,CORVALD              STORE ADR                        59400013
         MVI   KEYD,LAST               INDICATE LAST PARM               59600013
         MVC   RTNARYB(4),RCA          MOVE IN RTN CODE ARRAY ADR       59800013
         LA    RB,GDSCBD               LOAD ADR PARM LIST               60000013
         ST    RB,PLISTB               STORE ADR                        60200013
         LA    R1,PLISTB               LOAD ADR OF PARM LIST            60400013
         LINK  EP=IFFAFA12,MF=(E,(1))  TO RESET                         60600013
         MVC   ZERO(20,RA),SAVE1       RESTORE RTN CODE ARRAY           60800013
         B     OUTRTN                  BRANCH                           61000013
         DS    0F                                                       61200013
ZERO1    DC    1F'0'                                                    61400013
ONE      DC    A(1)                                                     61600013
TWO      DC    A(2)                                                     61800013
GNOP4    DC    X'2AC0'                                                  62000013
GTRU     DC    X'2AFF'                                                  62200013
GEOS     DC    X'2A81'                                                  62400013
CALL1    DC    X'01000004'                                              62600013
CALL3    DC    X'02000000'                                              62800013
         DS    0F                                                       63000013
CODE     DC    1F'1'                                                    63200013
         CNOP  0,8                                                      63400013
         COPY  GSPCB                                                    63600013
         COPY  GTMCB                                                    63800013
         COPY  GDSCB                                                    64000013
PARAM    DSECT                                                          64200013
GDSNM    DS    1F                                                       64400013
CORVAL   DS    1F                                                       64600013
KEY      DS    1F                                                       64800013
GENCODE  DS    1F                                                       65000013
WORKAREA DSECT                                                          65200013
PLIST    DS    1F                                                       65400013
RCA      DS    1F                                                       65600013
SAVE     DS    18F                                                      65800013
SWITCH   DS    X   '                                                    66000013
*              X'80'                   KEY/CORVAL INTERNALLY            66200013
*              X'40'                   USER CORVAL                      66400013
*              X'20'                   USER KEY                         66600013
*              X'10'                   USER GENCODE                     66800013
TEMPKEY  DS    1F                                                       67000013
W1A      DS    1X                                                       67200013
W1B      DS    1X                                                       67400013
W1C      DS    1X                                                       67600013
W1D      DS    1X                                                       67800013
CORVALA  DS    1F                                                       68000013
GDSCBA   DS    1F                                                       68200013
RTNARY   DS    1F                                                       68400013
VALUEA   DS    1H                                                       68600013
VALUEB   DS    1H                                                       68800013
ORDER    DS    1H                                                       69000013
         DS    1H                                                       69200013
CODEA    DS    1F                                                       69400013
GDSCBB   DS    1F                                                       69600013
CODEB    DS    1F                                                       69800013
KEYB     DS    1F                                                       70000013
SAVE1    DS    5F                                                       70200013
GDSCBC   DS    1F                                                       70400013
CORVALC  DS    1F                                                       70600013
GDSCBD   DS    1F                                                       70800013
CORVALD  DS    1F                                                       71000013
KEYD     DS    1F                                                       71200013
PLISTB   DS    1F                                                       71400013
RTNARYB  DS    1F                                                       71600013
         END                                                            71800013
