* TITLE:GSP PANIC KEY ROUTINE                                           00900013
* STATUS:CHANGE LEVEL 0                                                 01800013
* FUNCTION:TO ABEND THE USERS PROGRAM OR TO RETURN CONTROL TO USER      02700013
*          PROGRAM AT POINT OF INTERRUPT.                               03600013
* ENTRY:ENTERED AT IFFAHA09 VIA A CANCEL KEY INTERRUPT FROM ANY         04500013
*       INITIALIZED TERMINAL.                                           05400013
* INPUT:GR#1 CONTAINS THE ADDRESS OF THE CANCEL KEY GACB.THE ROUTINE    06300013
*       THEN GOES INTO A WAIT STATE WAITING FOR A CANCEL OR END KEY     07200013
*       ATTENTION INPUT.                                                08100013
* OUTPUT:1.SECOND ATTENTION END KEY-ABEND WITH DUMP.                    09000013
*        2.SECOND ATTENTION CANCELKEY-RESTORE CONDITIONS EXISTING PRIOR 09900013
*          TO FIRST CANCEL KEY ATTENTION.                               10800013
* EXIT:RETURN TO CALLING PROGRAM OR ABEND DUMP.                         11700013
* RETURN CODES:NONE                                                     12600013
* ABEND CODE SYSTEM=063                                                 13500013
* ATTRIBUTES:RE-ENTRANT,PROBLEM PROGRAM MODE.                           14400013
REG0     EQU   0                       PARAM REG 0                      15300013
REG1     EQU   1                       PARAM REG 1                      16200013
RGACB    EQU   2                       GACB ADR                         17100013
RGTMCB   EQU   3                       GTMCB ADR                        18000013
RCORE    EQU   4                       ADR OF GOTTEN CORE               18900013
RA       EQU   6                       WORK REG                         19800013
RB       EQU   5                       WORK REG                         20700013
RINTRN   EQU   7                       INT RETURN ADR                   21600013
RATL     EQU   8                       ATTN LEVEL ADR REG               22500013
RBASE    EQU   9                       BASE REG                         23400013
RCOM     EQU   10                      COM AREA ADR                     24300013
RD       EQU   11                      WORK REG                         25200013
SPARE1   EQU   12                      RSVD PL1                         26100013
RSAVE    EQU   13                      SAVE AREA PTR                    27000013
ATYPE    EQU   3                       LOC OF ATN TYPE                  27900013
CANCEL   EQU   X'05'                   CANCEL ATTN                      28800013
END      EQU   X'01'                   END ATTN                         29700013
NEG      EQU   X'80'                   NEGATIVE NUMBER MASK             30600013
OFFSAVE  EQU   8                       SAVE AREA PTR OFFSET             31500013
ZERO     EQU   0                       ZERO                             32400013
IFFAHA09 CSECT                                                          33300013
         SAVE  (14,12)                                                  34200013
         BALR  RBASE,0                 SET UP BASE REG                  35100013
         USING *,RBASE                 DEFINE BASE REG                  36000013
         LR    RGACB,REG1              SAVE GACB ADR                    36900013
         L     RCOM,ZERO(RGACB)        LOAD COMAREA ADR                 37800013
         CLI   ATYPE(RCOM),CANCEL      CANCEL ATTN                      38700013
         BNE   OUTRTN                  BRANCH IF NO                     39600013
         L     REG0,MAINREQ            LOAD # OF BYTES                  40500013
         GETMAIN R,LV=(0)                                               41400013
         LR    RCORE,REG1              SAVE ADR OF GOTTEN CORE          42300013
         USING MAIN,RCORE              DEFINE DSECT                     43200013
         ST    RSAVE,SAVE+4            SAVE-SAVE AREA PTR               44100013
         LA    RD,SAVE                 LOAD ADR MY SAVE AREA            45000013
         ST    RD,OFFSAVE(RSAVE)       SAVE ADR OF MY SAVE AREA         45900013
         LA    RSAVE,SAVE              ESTABLISH NEW SAVE AREA          46800013
         SAEC  ATTNTYP=(A,END),MF=(E,(2))                               47700013
*********************************************************************** 48600013
*        STANDARDS DEVIATION ON MACRO USEAGE                          * 49500013
*********************************************************************** 50400013
PA0      XC    GACB(8),GACB            CLEAR PARAM AREA                 51300013
         ST    RGACB,GACB              GACB ADR TO PARAM LIST           52200013
         MVI   TYPE,X'02'              MOVE IN MODE=W                   53100013
         MVI   OPT,X'FF'               MOVE IN ALL UNIT                 54000013
         LA    REG1,GACB               LOAD ADR OF PARAM LIST           54900013
         L     15,48(RGACB)            LOAD ADR IF IGG019OK             55800013
         BALR  14,15                   BRANCH TO RTN                    56700013
*********************************************************************** 57600013
*        END OF DEVIATION                                             * 58500013
*********************************************************************** 59400013
         L     RCOM,ZERO(RGACB)        LOAD COMAREA ADR                 60300013
         CLI   ATYPE(RCOM),CANCEL      CANCEL ATTN                      61200013
         BE    PA1                     BRANCH IF CANCEL                 62100013
         CLI   ATYPE(RCOM),END         END KEY ATTENTION                63000013
         BNE   PA0                     BRANCH IF NOT END KEY            63900013
         L     RA,MINUS8               LOAD MINUS 4 DISPLACEMENT        64800013
         LA    RGTMCB,0(RA,RGACB)      LOAD ADR OF ADR OF GTMCB         65700013
         L     RGTMCB,0(RGTMCB)        LOAD GTMCB ADR                   66600013
         USING GTMCB,RGTMCB                                             67500013
         L     RB,GTMGSPCB             LOAD ADR OF GSPCB                68400013
         USING GSPCB,RB                                                 69300013
         L     RB,GSPNULLV             LOAD ADR OF NULL VARIABLE        70200013
         LA    REG1,X'063'             LOAD ABEND CODE                  71100013
         SLL   REG1,12                 POSITION CODE                    72000013
         TM    0(RB),NEG               IS NULL NEGATIVE                 72900013
         BO    PA2                     BRANCH IF YES                    73800013
         ABEND (1)                                                      74700013
PA2      ABEND (1),DUMP                                                 75600013
PA1      SAEC  ATTNTYP=(R,CANCEL),MF=(E,(2))                            76500013
OUT      LR    REG1,RCORE              LOAD ADR OF CORE TO FREE         77400013
         L     REG0,MAINREQ            LOAD AMOUNT OF CORE TO FREE      78300013
         L     RSAVE,SAVE+4            RESTORE OLD SAVE AREA            79200013
         FREEMAIN R,LV=(0),A=(1)                                        80100013
OUTRTN   RETURN (14,12),T                                               81000013
         DS    0F                                                       81900013
MINUS8   DC    X'FFFFFFFC'                                              82800013
MAINREQ  DC    A(128)                                                   83700013
ZERO1    DC    1F'0'                                                    84600013
         CNOP  0,8                                                      85500013
MAIN     DSECT                                                          86400013
SAVE     DS    18F                                                      87300013
GACB     DS    1F                                                       88200013
TYPE     DS    BL1                                                      89100013
OPT      DS    BL1                                                      90000013
TYP      DS    1H                                                       90900013
         COPY  GSPCB                                                    91800013
         COPY  GTMCB                                                    92700013
         END                                                            93600013
