* TITLE:ITBP/RTBP-TEST INTEGER/REAL BEAM POSITION                       00400013
* STATUS:CHANGE LEVEL 0                                                 00800013
* FUNCTION:TO RETURN TO THE USER EITHER THE X OR Y COORDINATE WHERE THE 01200013
*          2250 BEAM IS CURRENTLY POSITIONED OR THE X OR Y COORDINATE   01600013
*          WHERE THE USER INTENDED THE BEAM TO BE POSITIONED.           02000013
* ENTRY:ENTERED AT IFFAJA02 VIA A CALL TO ITBP OR AT IFFAJA03 VIA A     02400013
*       CALL TO RTBP.                                                   02800013
* INPUT:GR#1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA.THE FIRST WORD OF 03200013
*       THIS AREA CONTAINS THE ADDRESS OF A PARAMETER LIST CONSTRUCTED  03600013
*       AS FOLLOWS:                                                     04000013
*        1.GDSNAME-ADDRESS OF A VARIABLE WHICH CONTAINS THE ADDRESS OF  04400013
*          A GDSCB.                                                     04800013
*        2.INFO-ADDRESS OF A VARIABLE OR CONSTANT WHICH CONTAINS ONE OF 05200013
*          THE FOLLOWING VALUES:                                        05600013
*         (1)-RETURN X COORDINATE WHERE BEAM IS SUPPOSED TO BE.         06000013
*         (2)-RETURN X COORDINATE WHERE BEAM ACTUALLY IS.               06400013
*         (3)-SAME AS 1 EXCEPT FOR Y.                                   06800013
*         (4)-SAME AS 2 EXCEPT FOR Y.                                   07200013
* OUTPUT:GR#0(ITBP) OR FLOATING POINT REG 0(RTBP) CONTAINS THE SCALED   07600013
*        PROGRAMMER COORDINATE REQUESTED OF THE TYPE(INTEGER-ITBP OR    08000013
*        REAL-RTBP) AND FORM (ABSOLUTE OR INCREMENTAL) CURRENTLY        08400013
*        APPLICABLE FOR THE SPECIFIED GRAPHIC DATA SET.                 08800013
* EXIT:RETURN TO CALLER VIA REGISTER 14.                                09200013
* ERROR EXIT:IN THE EVENT OF INVALID PARAMETERS OR A CALL TO RTBP IN    09600013
*            INTEGER MODE OR A CALL TO ITBP IN REAL MODE,GR#0(ITBP) OR  10000013
*            FLOATING POINT REG#0(RTBP) WILL CONTAIN THE MAXIMUM        10400013
*            NEGATIVE VALUE UPON RETURN TO THE CALLER.                  10800013
* ATTRIBUTES:RE-ENTRANT,PROBLEM PROGRAM MODE.                           11200013
* EXTERNAL ROUTINES:CNVRT                                               11600013
* NOTES:THIS ROUTINE EXAMINES THE FOLLOWING CONTROL BLOCKS:             12000013
*       1.GDSCB                                                         12400013
*       2.GTMCB                                                         12800013
*       3.GSPCB                                                         13200013
R0       EQU   0                       PARM REG 0                       13600013
R1       EQU   1                       PARM REG 1                       14000013
RLIST    EQU   2                       WORK AREA REG                    14400013
RPARM    EQU   3                       PARAMETER(USER) REG              14800013
RDATA    EQU   4                       DATA REG                         15200013
RGDSCB   EQU   5                       GDSCB REG                        15600013
RA       EQU   6                       WORK REG                         16000013
RB       EQU   7                       WORK REG                         16400013
RC       EQU   8                       WORK REG                         16800013
RBASE    EQU   9                       BASE REG                         17200013
SPARE    EQU   12                      RSVD PL/1                        17600013
RSAVE    EQU   13                      SAVE AREA PTR                    18000013
R15      EQU   15                      ENTRY/WORK REG                   18400013
ZERO     EQU   0                       ZERO                             18800013
LAST     EQU   X'80'                   LAST PARM                        19200013
RTBPA    EQU   X'80'                   RTBP ENTRY SWITCH                19600013
PRIOR    EQU   4                       OFFSET TO NEXT HIGHER SAVE AREA  20000013
REG0     EQU   20                      OFFSET TO REG 0 IN SAVE AREA     20400013
CHAIN    EQU   8                       CHAIN SAVE AREAS                 20800013
GID      EQU   X'03'                   GDSCB ID                         21200013
XINT     EQU   X'30'                   X INTEGER                        21600013
XREAL    EQU   X'C0'                   X REAL                           22000013
YINT     EQU   X'03'                   Y INTEGER                        22400013
YREAL    EQU   X'0C'                   Y REAL                           22800013
RTNCDE   EQU   X'00'                   RTN CODE =ZERO                   23200013
ONEA     EQU   1                       ONE                              23600013
         CSECT                                                          24000013
         ENTRY IFFAJA02                ITBP                             24400013
         ENTRY IFFAJA03                RTBP                             24800013
         USING *,15                                                     25200013
IFFAJA02 SAVE  (14,12)                 ITBP ENTRY POINT                 25600013
         B     NEXT                                                     26000013
IFFAJA03 SAVE  (14,12)                 RTBP ENTRY POINT                 26400013
         SR    R15,R15                 INDICATE ENTERED BY RTBP         26800013
NEXT     BALR  RBASE,0                 SET UP BASE REG                  27200013
         DROP  15                                                       27600013
         USING *,RBASE                 DEFINE BASE REG                  28000013
         LR    RLIST,R1                LOAD WORK AREA REG               28400013
         USING WORKAREA,RLIST          DEFINE DSECT                     28800013
         XC    SWITCH(1),SWITCH        CLEAR SWITCH                     29200013
         LTR   R15,R15                 IS THIS AN ITBP ENTRY            29600013
         BC    7,BP01                  BRANCH IF YES                    30000013
         OI    SWITCH,RTBPA            INDICATE RTBP ENTRY              30400013
BP01     L     RPARM,PLIST             LOAD ADDRESS OF USER PARM LIST   30800013
         USING PARM,RPARM              DEFINE DSECT                     31200013
         L     RDATA,PRIOR(RSAVE)      LOAD ADR OF PRIOR SAVE AREA      31600013
         ST    RSAVE,SAVE+4            SAVE REG 13 DAVE AREA PTR        32000013
         LA    R15,SAVE                LOAD ADR OF MY SAVE AREA         32400013
         ST    R15,CHAIN(RSAVE)        CHAIN SAVE AREAS                 32800013
         LA    RSAVE,SAVE              ESTABLISH NEW  SAVE AREA         33200013
         B     AROUND                  BRANCH                           33600013
ERROR    TM    SWITCH,RTBPA            RTBP CALL                        34000013
         BO    BP02                    BRANCH IF YES                    34400013
         L     R15,MAX                 LOAD MAX NEG NUMBER              34800013
         ST    R15,REG0(RDATA)         INDICATE ERROR IN GR#0           35200013
         B     OUTRTN                  BRANCH                           35600013
BP02     LE    R0,MAXR                 INDICATE ERROR IN FP REG#0       36000013
OUTRTN   L     RSAVE,SAVE+4            RESTORE SAVE AREA PTR            36400013
         RETURN (14,12),T              RETURN TO CALLER                 36800013
AROUND   TM    GDSNAME,LAST            LAST PARAM                       37200013
         BO    ERROR                   BRANCH IF LAST PARAMETER         37600013
         L     RGDSCB,GDSNAME          LOAD INDIRECT PTR TO GDSCB       38000013
         L     RGDSCB,ZERO(RGDSCB)     LOAD GDSCB ADR                   38400013
         USING GDSCB,RGDSCB            DEFINE DSECT                     38800013
         CLI   GDSGDSID,GID            VALID GDSCB                      39200013
         BNE   ERROR                   BRANCH-NOT VALID                 39600013
         L     RA,GDSGTMCB             LOAD GTMCB ADR                   40000013
         USING GTMCB,RA                DEFINE DSECT                     40400013
         L     RB,GTMGSPCB             LOAD GSPCB ADR                   40800013
         USING GSPCB,RB                DEFINE DSECT                     41200013
         L     RC,INFO                 LOAD PTR TO INFO                 41600013
         LA    RC,ZERO(RC)             ZERO HI ORDER BYTE               42000013
         CL    RC,GSPNULLV             INFO=NULL                        42400013
         BE    ERROR                   BRANCH IF YES                    42800013
         L     RC,ZERO(RC)             LOAD VALUE OF INFO               43200013
         XC    GDSA(24),GDSA           CLEAR INPUT PARAM AREA           43600013
         CL    RC,ONE                  INFO=1                           44000013
         BE    BP03                    BRANCH=1                         44400013
         CL    RC,TWO                  INFO=2                           44800013
         BE    BP04                    BRANCH=2                         45200013
         CL    RC,THREE                INFO=3                           45600013
         BE    BP05                    BRANCH=3                         46000013
         CL    RC,FOUR                 INFO=4                           46400013
         BE    BP06                    BRANCH=4                         46800013
         B     ERROR                   BRANCH                           47200013
BP03     L     RA,GDSXLAST             LOAD XLAST FIELD                 47600013
         ST    RA,XIA                  STORE INTO PARAM LIST            48000013
         B     BP07                    BRANCH                           48400013
BP04     SR    RA,RA                   CLEAR REG                        48800013
         LH    RA,GDSXCURR             LOAD X CURR FIELD                49200013
         ST    RA,XIA                  STORE INTO PARAM LIST            49600013
         B     BP07                    BRANCH                           50000013
BP05     L     RA,GDSYLAST             LOAD YLAST FIELD                 50400013
         ST    RA,YIA                  STORE IN PARAM LIST              50800013
         B     BP08                    BRANCH                           51200013
BP06     SR    RA,RA                   CLEAR REG                        51600013
         LH    RA,GDSYCURR             LOAD Y CURR FIELD                52000013
         ST    RA,YIA                  STORE IN PARAM LIST              52400013
         B     BP08                    BRANCH                           52800013
BP07     TM    SWITCH,RTBPA            RTBP ENTRY                       53200013
         BO    BP09                    BRANCH IF RTBP                   53600013
         TM    GDSDATMD,XINT           X=INTEGER                        54000013
         BC    8,ERROR                 BRANCH-X NOT INTEGER MODE        54400013
         B     BP10                    BRANCH                           54800013
BP09     TM    GDSDATMD,XREAL          X=REAL                           55200013
         BC    8,ERROR                 BRANCH- X NOT REAL MODE          55600013
         B     BP10                    BRANCH                           56000013
BP08     TM    SWITCH,RTBPA            RTBP ENTRY                       56400013
         BO    BP11                    BRANCH-RTBP                      56800013
         TM    GDSDATMD,YINT           Y=INTEGER                        57200013
         BC    8,ERROR                 BRANCH- Y NOT INTEGER MODE       57600013
         B     BP10                    BRANCH                           58000013
BP11     TM    GDSDATMD,YREAL          Y=REAL                           58400013
         BC    8,ERROR                 BRANCH-Y NOT REAL MODE           58800013
BP10     ST    RGDSCB,GDSA             ADR OF GDSCB TO PARAM LIST       59200013
         LA    RA,ONEA                 LOAD CONSTANT                    59600013
         ST    RA,CONA                 STORE VALUE IN PARAM LIST        60000013
         LA    RA,GDSA                 LOAD ADR                         60400013
         ST    RA,GDS                  PUT ADR IN PARAM LIST            60800013
         LA    RA,CONA                 LOAD ADR                         61200013
         ST    RA,CON                  STORE IN PARAM LIST              61600013
         LA    RA,XIA                  LOAD ADR                         62000013
         ST    RA,XI                   STORE IN PARAM LIST              62400013
         LA    RA,YIA                  LOAD ADR                         62800013
         ST    RA,YI                   STORE IN PARAM LIST              63200013
         LA    RA,XOA                  LOAD ADR                         63600013
         ST    RA,XO                   STORE ADR IN PARAM LIST          64000013
         LA    RA,YOA                  LOAD ADR                         64400013
         ST    RA,YO                   STORE IN PARAM LIST              64800013
         MVI   YO,LAST                 INDICATE LAST PARAM              65200013
         LA    RA,GDS                  LOAD ADR                         65600013
         ST    RA,PARAM                STORE ADR IN PARAM LIST          66000013
         LA    RA,RCC                  LOAD ADR                         66400013
         ST    RA,RCB                  STORE IN PARAM LIST              66800013
         XC    RCC(20),RCC             CLEAR RETURN CODE ARRAY          67200013
         LA    R1,PARAM                LOAD ADR                         67600013
         LINK  EP=IFFAGA08,MF=(E,(1))  LINK TO CONVERT ROUTINE          68000013
         CLI   RCC,RTNCDE              CONVERT SUCCESSFULL              68400013
         BNE   ERROR                   BRANCH IF NOT SUCCESSFULL        68800013
         CL    RC,TWO                  X OR Y OUTPUT                    69200013
         BC    2,BP12                  BRANCH FOR Y OUTPUT              69600013
         TM    SWITCH,RTBPA            REAL OR INTEGER OUTPUT           70000013
         BO    BP13                    BRANCH -REAL OUTPUT              70400013
         L     RA,XOA                  LOAD X RESULTS                   70800013
         ST    RA,REG0(RDATA)          STORE RESULTS                    71200013
         B     OUTRTN                  BRANCH                           71600013
BP13     LE    R0,XOA                  RESULTS TO FP REG 0              72000013
         B     OUTRTN                  BRANCH                           72400013
BP12     TM    SWITCH,RTBPA            REAL OR INTEGER OUTPUT           72800013
         BO    BP14                    BRANCH-REAL OUTPUT               73200013
         L     RA,YOA                  LOAD RESULTS                     73600013
         ST    RA,REG0(RDATA)          STORE RESULTS                    74000013
         B     OUTRTN                  BRANCH                           74400013
BP14     LE    R0,YOA                  RESULTS TO FP REG # 0            74800013
         B     OUTRTN                  BRANCH                           75200013
         DS    0F                                                       75600013
MAX      DC    X'80000000'                                              76000013
MAXR     DC    X'FFFFFFFF'                                              76400013
ONE      DC    A(1)                                                     76800013
TWO      DC    A(2)                                                     77200013
THREE    DC    A(3)                                                     77600013
FOUR     DC    A(4)                                                     78000013
         CNOP  0,8                                                      78400013
PARM     DSECT                                                          78800013
GDSNAME  DS    1F                                                       79200013
INFO     DS    1F                                                       79600013
WORKAREA DSECT                                                          80000013
PLIST    DS    1F                                                       80400013
RCA      DS    1F                                                       80800013
SWITCH   DS    1F                                                       81200013
*              BIT 0=0 IFFAJ02(ITBP) ENTRY                              81600013
*              BIT 0=1 IFFAJ03(RTBP) ENTRY                              82000013
SAVE     DC    18F'0'                                                   82400013
GDS      DS    1F                      ARD OR GDSA                      82800013
CON      DS    1F                      ADR OF CONA                      83200013
XI       DS    1F                      ADR OF XIA                       83600013
YI       DS    1F                      ADR OF YIA                       84000013
XO       DS    1F                      ADR OF XOA                       84400013
YO       DS    1F                      ADR OF YOA + X'80' IN HI BYTE    84800013
GDSA     DS    1F                      ADR OF GDSCB                     85200013
CONA     DS    1F                      VALUE OF ONE                     85600013
XIA      DS    1F                      VALUE OF X INPUT OR 0            86000013
YIA      DS    1F                      VALUE OF Y INPUT OR 0            86400013
XOA      DS    1F                      LOCATION WHERE X RESULTS STORED  86800013
YOA      DS    1F                      LOCATION WHERE Y RESULTS STORED  87200013
RCC      DS    5F                      RTN CODE ARRAY                   87600013
PARAM    DS    1F                      ADR OF GDS                       88000013
RCB      DS    1F                      ADR OF RTN CODE ARRAY (RCC)      88400013
         COPY  GDSCB                                                    88800013
         COPY  GTMCB                                                    89200013
         COPY  GSPCB                                                    89600013
         END                                                            90000013
