* TITLE:ITST-TEST STATUS                                                00500013
* STATUS:CHANGE LEVEL 0                                                 01000013
* FUNCTION:TO RETURN TO THE USER A VALUE CORRESPONDING TO THE TYPE OF   01500013
*          DATA CURRENTLY IN EFFECT FOR A PARTICULAR OPTION DEFINITION  02000013
*          SUBROUTINE FOR THE ASSOCIATED GRAPHIC DATA SET.              02500013
* ENTRY:ENTERED AT IFFAJA04 VIA A CALL TO ITST.                         03000013
* INPUT:GR#1 CONTAINS THE ADDRESS OF A WORK/SAVE AREA.THE FIRST WORD OF 03500013
*       THIS AREA CONTAINS THE ADDRESS OF A PARAMETER LIST CONSTRUCTED  04000013
*       AS FOLLOWS:                                                     04500013
*        1.GDSNAME-ADDRESS OF A VARIABLE WHICH CONTAINS THE ADDRESS OF  05000013
*          A GDSCB.                                                     05500013
*        2.OPTIONSUBRTN-ADDRESS OF A VARIABLE OR CONSTANT WHOSE VALUE   06000013
*          INDICATES ONE OF THE FOLLOWING:                              06500013
*         (1)SDATM SUBROUTINE(X COORDINATE)                             07000013
*         (2)SDATM SUBROUTINE(Y COORDINATE)                             07500013
*         (3)SGRAM SUBROUTINE                                           08000013
*         (4)SCHAM SUBROUTINE                                           08500013
* OUTPUT:GR#0 WILL CONTAIN ONE OF THE FOLLOWING VALUES:                 09000013
*        SUBRTN  VALUE  MEANING                                         09500013
*        ******  *****  *********************************************** 10000013
*        SDATM    1     X(Y) IS REAL,ABSOLUTE                           10500013
*                 2     X(Y) IS REAL,INCREMENTAL                        11000013
*                 3     X(Y) IS INTEGER,ABSOLUTE                        11500013
*                 4     X(Y) IS INTEGER,INCREMENTAL                     12000013
*        SGRAM    1     OUTPUT OPTIMIZED                                12500013
*                 2     OUTPUT ABSOLUTE                                 13000013
*                 3     OUTPUT INCREMENTAL                              13500013
*        SCHAM    1     CHARACTERS ARE BASIC SIZE AND PROTECTED         14000013
*               2       CHARACTERS ARE LARGE SIZE AND PROTECTED         14500013
*                 3     CHARACTERS ARE BASIC SIZE AND UNPROTECTED       15000013
*                 4     CHARACTERS ARE LARGE SIZE AND UNPROTECTED       15500013
* EXIT:RETURN TO CALLER VIA REGISTER 14.                                16000013
* ERROR EXIT:IN THE EVENT OF INVALID PARAMETERS OR REQUESTED INFORMATIN 16500013
*            NOT AVAILABLE,A VALUE OF 0 WILLBE RETURNED IN GR#0.        17000013
* ATTRIBUTES:RE-ENTRANT,PROBLEM PROGRAM MODE                            17500013
* NOTES:THIS ROUTINE EXAMINES THE FOLLOWING CONGROL BLOCKS:             18000013
*       1.GDSCB                                                         18500013
*       2.GTMCB                                                         19000013
*       3.GSPCB                                                         19500013
R0       EQU   0                       PARM REG 0                       20000013
R1       EQU   1                       PARM REG 1                       20500013
RLIST    EQU   2                       WORK AREA REG                    21000013
RPARM    EQU   3                       USER PARAMETERS REG              21500013
RDATA    EQU   4                       DATA REG                         22000013
RA       EQU   5                       WORK REG                         22500013
RB       EQU   6                       WORK REG                         23000013
RGDSCB   EQU   7                       GDSCB REG                        23500013
RBASE    EQU   9                       BASE REG                         24000013
RSAVE    EQU   13                      SAVE REG                         24500013
PRIOR    EQU   4                       PREVIOUS SAVE AREA               25000013
REG0     EQU   20                      OFFSET TO REG 0                  25500013
XRA      EQU   X'80'                   X-REAL-ABSOLUTE                  26000013
XRI      EQU   X'40'                   X-REAL-INCREMENTAL               26500013
XIA      EQU   X'20'                   X-INT-ABSOLUTE                   27000013
XII      EQU   X'10'                   X-INT-INCREMENTAL                27500013
YRA      EQU   X'08'                   Y-REAL-ABSOLUTE                  28000013
YRI      EQU   X'04'                   Y-REAL-INCREMENTAL               28500013
YIA      EQU   X'02'                   Y-INT-ABSOLUTE                   29000013
YII      EQU   X'01'                   Y-INT-INCREMENTAL                29500013
BP       EQU   X'08'                   BASIC CHAR-PROTECTED             30000013
BUP      EQU   X'02'                   BASIC CHAR-UNPROTECTED           30500013
LP       EQU   X'04'                   LARGE CHAR-PROTECTED             31000013
LUP      EQU   X'01'                   LARGE CHAR-UNPROTECTED           31500013
OPTI     EQU   X'04'                   OUTPUT OPTIMIZED                 32000013
ABS      EQU   X'02'                   OUTPUT ABSOLUTE                  32500013
INC      EQU   X'01'                   OUTPUT INCREMENTAL               33000013
LAST     EQU   X'80'                   LAST PARAM                       33500013
ZERO     EQU   0                       ZERO                             34000013
GID      EQU   X'03'                   GDSCB ID                         34500013
IFFAJA04 CSECT                                                          35000013
         SAVE  (14,12)                 SAVE REGS                        35500013
         BALR  RBASE,0                 SET UP BASE REG                  36000013
         USING *,RBASE                 DEFINE BASE REG                  36500013
         LR    RLIST,R1                LOAD REG                         37000013
         USING WORKAREA,RLIST          DEFINE DSECT                     37500013
         L     RPARM,PLIST             LOAD ADR OF USER PARM LIST       38000013
         USING PARM,RPARM              DEFINE DSECT                     38500013
         L     RDATA,PRIOR(RSAVE)      LOAD ADR OF PREVIOUS SAVE AREA   39000013
         B     AROUND                  BRANCH                           39500013
ERROR    SR    RB,RB                   INDICATE ERROR                   40000013
OUTRTN   ST    RB,REG0(RDATA)          STORE DATA                       40500013
         RETURN (14,12),T              RETURN TO CALLER                 41000013
AROUND   TM    GDS,LAST                LAST PARAM                       41500013
         BO    ERROR                   BRANCH IF YES                    42000013
         L     RGDSCB,GDS              LOAD INDIRECT PTR TO GDSCB       42500013
         L     RGDSCB,ZERO(RGDSCB)     LOAD GDSCB ADR                   43000013
         USING GDSCB,RGDSCB            DEFINE DSECT                     43500013
         CLI   GDSGDSID,GID            VALID GDSCB                      44000013
         BNE   ERROR                   BRANCH-NOT VALID                 44500013
         L     RA,GDSGTMCB             LOAD GTMCB ADR                   45000013
         USING GTMCB,RA                DEFINE DSECT                     45500013
         L     RB,GTMGSPCB             LOAD GSPCB ADR                   46000013
         USING GSPCB,RB                DEFINE DSECT                     46500013
         DROP  RA                                                       47000013
         L     RA,OPT                  LOAD OPTSUBROUTINE VALUE PTR     47500013
         LA    RA,ZERO(RA)             ZERO HI ORDER BYTE               48000013
         CL    RA,GSPNULLV             EQUAL NULL ADR                   48500013
         BE    ERROR                   BRANCH=NULL                      49000013
         DROP  RB                                                       49500013
         L     RA,ZERO(RA)             LOAD VALUE                       50000013
         CL    RA,ONE                  VALUE=1                          50500013
         BE    IT05                    BRANCH TO SDATM X CO-OR CHECKS   51000013
         CL    RA,TWO                  VALUE=2                          51500013
         BE    IT06                    BRANCH TO SDATM Y CO-OR CHECKS   52000013
         CL    RA,THREE                VALUE=3                          52500013
         BE    IT07                    BRANCH TO SGRAM CHECKS           53000013
         CL    RA,FOUR                 VALUE=4                          53500013
         BE    IT08                    BRANCH TO SCHAM CHECKS           54000013
         B     ERROR                   BRANCH                           54500013
IT01     L     RB,ONE                  LOAD CONSTANT                    55000013
         B     OUTRTN                  BRANCH                           55500013
IT02     L     RB,TWO                  LOAD CONSTANT                    56000013
         B     OUTRTN                  BRANCH                           56500013
IT03     L     RB,THREE                LOAD CONSTANT                    57000013
         B     OUTRTN                  BRANCH                           57500013
IT04     L     RB,FOUR                 LOAD CONSTANT                    58000013
         B     OUTRTN                  BRANCH                           58500013
IT05     TM    GDSDATMD,XRA            X-REAL-ABS                       59000013
         BO    IT01                    BRANCH IF YES                    59500013
         TM    GDSDATMD,XRI            X-REAL-INC                       60000013
         BO    IT02                    BRANCH IF YES                    60500013
         TM    GDSDATMD,XIA            X-INT-ABS                        61000013
         BO    IT03                    BRANCH IF YES                    61500013
         TM    GDSDATMD,XII            X-INT-INC                        62000013
         BO    IT04                    BRANCH IF YES                    62500013
         B     ERROR                   BRANCH                           63000013
IT06     TM    GDSDATMD,YRA            Y-REAL-ABS                       63500013
         BO    IT01                    BRANCH IF YES                    64000013
         TM    GDSDATMD,YRI            Y-REAL-INC                       64500013
         BO    IT02                    BRANCH IF YES                    65000013
         TM    GDSDATMD,YIA            Y-INT-ABS                        65500013
         BO    IT03                    BRANCH IF YES                    66000013
         TM    GDSDATMD,YII            Y-INT-INCR                       66500013
         BO    IT04                    BRANCH IF YES                    67000013
         B     ERROR                   BRANCH                           67500013
IT07     TM    GDSCURMD,OPTI           OUTPUT OPTIMIZE                  68000013
         BO    IT01                    BRANCH IF YES                    68500013
         TM    GDSCURMD,ABS            OUTPUT ABSOLUTE                  69000013
         BO    IT02                    BRANCH IF YES                    69500013
         TM    GDSCURMD,INC            OUTPUT INCREMENTAL               70000013
         BO    IT03                    BRANCH IF YES                    70500013
         B     ERROR                   BRANCH                           71000013
IT08     TM    GDSCHARS,BP             CHARS=BASIC PROTECTED            71500013
         BO    IT01                    BRANCH IF YES                    72000013
         TM    GDSCHARS,LP             CHARS=LARGE PROTECTED            72500013
         BO    IT02                    BRANCH IF YES                    73000013
         TM    GDSCHARS,BUP            CHARS=BASIC-UNPROTECTED          73500013
         BO    IT03                    BRANCH IF YES                    74000013
         TM    GDSCHARS,LUP            CHARS=LARGE=UNPROTECTED          74500013
         BO    IT04                    BRANCH IF YES                    75000013
         B     ERROR                   BRANCH                           75500013
         DS    0F                                                       76000013
ONE      DC    A(1)                                                     76500013
TWO      DC    A(2)                                                     77000013
THREE    DC    A(3)                                                     77500013
FOUR     DC    A(4)                                                     78000013
         CNOP  0,8                                                      78500013
WORKAREA DSECT                                                          79000013
PLIST    DS    1F                                                       79500013
PARM     DSECT                                                          80000013
GDS      DS    1F                                                       80500013
OPT      DS    1F                                                       81000013
         COPY  GDSCB                                                    81500013
         COPY GTMCB                                                     82000013
         COPY  GSPCB                                                    82500013
         END                                                            83000013
