* MODULE NAME  CONVERT 1130 INTEGERS AND 16 BIT ALPHAMERIC DATA TO      00300017
*              S/360 FORMAT                                             00600017
*                                                                       00900017
* ENTRY POINT  GDCTI                                                    01200017
*                                                                       01500017
* EXIT         TO THE CALLING ROUTINE VIA REGISTER 14                   01800017
*                                                                       02100017
* INPUT        IN REGISTER 1 THE ADDRESS OF A PAREMETER LIST            02400017
*                 + 0 A(SUBARRAY)      1130 INPUT ARRAY                 02700017
*                 + 4 A(PRIMARRAY)     S/360 OUTPUT ARRAY               03000017
*                 + 8 A(ELCOUNT)       COUNT OF ELEMENS TO CONVERT      03300017
*                 +12 A(OSLGTH)        LENGTH (BYTES) OF S/360 ELEMENTS 03600017
*                                                                       03900017
* OUTPUT       AN ARRAY OF INTEGERS OR ALPHAMERIC DATA IN THE S/360     04200017
*              FORTRAN STANDARD LENGTH (4 BYTES) OR HALF WORD (2 BYTES) 04500017
*              FORMAT                                                   04800017
*                                                                       05100017
* EXTERNAL REFERENCES  NONE                                             05400017
*                                                                       05700017
* FUNCTION     1) TO CONVERT AN ARRAY OF INTEGERS IN THE 1130 FORTRAN   06000017
*              STANDARD PRECISION FORMAT TO AN ARRAY OF INTEGERS IN THE 06300017
*              S/360 FORTRAN STANDARD LENGTH FORMAT.                    06600017
*                                                                       06900017
*              2) TO CONVERT AN ARRAY OF INTEGERS IN THE 1130 FORTRAN   07200017
*              "ONE WORD INTEGER" FORMAT TO AN ARRAY OF INTEGERS IN THE 07500017
*              S/360 FORTRAN HALF WORD FORMAT.                          07800017
*                                                                       08100017
*              3) TO CONVERT AN ARRAY OF 16 BIT ALPHAMERIC DATA IN THE  08400017
*              1130 FORTRAN FORMAT TO AN ARRAY OF 16 BIT ALPHAMERIC     08700017
*              DATA IN THE S/360 FORMAT.                                09000017
         EJECT                                                          09300017
*                                                                       09600017
* REGISTER UTILIZATION                                                  09900017
*                                                                       10200017
INPL     EQU   0             SWITCH INDICATES IN PLACE CONVERSION       10500017
PLIST    EQU   1             INPUT PARAMETER LIST ADDRESS               10800017
FRAD     EQU   2             INPUT ARRAY ADDRESS                        11100017
TOAD     EQU   3             OUTPUT ARRAY ADDRESS                       11400017
ELCT     EQU   4             ELEMENT COUNT                              11700017
OSLGTH   EQU   5             SWITCH INDICATES OUTPUT ELEMENT LENGTH     12000017
BOTMT    EQU   6             BOTTOM ADDRESS OF OUTPUT ARRAY             12300017
CON1     EQU   6             CONVERSION REG                             12600017
BOTMF    EQU   7             BOTTOM ADDRESS OF INPUT ARRAY              12900017
CON2     EQU   7             CONVERSION REG                             13200017
CON3     EQU   8             CONVERSION REG                             13500017
TASK     EQU   8             TOTAL MOVE COUNT                           13800017
BASE     EQU   9             CSECT BASE                                 14100017
MOVE     EQU   15                                                       14400017
DELTA    EQU   10            MAXIMUM MOVE COUNT LESS THAN 256           14700017
LASTL    EQU   10                      LAST ELEM ADDR OF INPUT ARRAY    15000017
SLAVE    EQU   11            WORK REG                                   15300017
         EJECT                                                          15600017
GDCTI    CSECT                                                          15900017
         SAVE  (14,12)                 SAVE GENERAL REGISTERS           16200017
         BALR  BASE,0                  ESTABLISH ADDRESSABILITY         16500017
         USING *,BASE                                                   16800017
         LM    FRAD,OSLGTH,0(PLIST)    GET PARAMETERS                   17100017
         L     ELCT,0(ELCT)            GET ELEMENT COUNT                17400017
         L     OSLGTH,0(OSLGTH)        GET S/360 ELEMENT LENGTH CODE    17700017
         SR    INPL,INPL               INITIALIZE SWITCH                18000017
         SR    MOVE,MOVE                                                18300017
*                                                                       18600017
* IF THE ELEMENT COUNT IS NOT GREATER THAN ZERO CONTROL IS RETURNED TO  18900017
* THE CALLING ROUTINE WITHOUT CONVERSION.                               19200017
*                                                                       19500017
         LTR   ELCT,ELCT               SHOULD DATA BE CONVERTED         19800017
         BC    12,GDCTI250             NO                               20100017
*                                                                       20400017
* IF THE INPUT AND OUTPUT ARRAYS OVERLAP THE INPUT ARRAY DATA IS MOVED  20700017
* INTO THE OUTPUT ARRAY AND CONVERSION IS DONE IN PLACE. THREE DISTINCT 21000017
* TYPES OF OVERLAP ARE RECOGNIZED.                                      21300017
*        TYPE 1 - THE ARRAYS ARE COINCIDENT, NO DATA IS MOVED           21600017
*        TYPE 2 - THE BOTTOM OF THE INPUT ARRAY OVERLAPS THE TOP OF THE 21900017
*                 OUTPUT ARRAY, DATA IS MOVED INTO THE OUTPUT ARRAY     22200017
*                 STARTING AT THE BOTTOM.                               22500017
*        TYPE 3 - THE BOTTOM OF THE OUTPUT ARRAY OVERLAPS THE TOP OF    22800017
*                 THE INPUT ARRAY, DATA IS MOVED INTO THE OUTPUT ARRAY  23100017
*                 STARTING AT THE TOP.                                  23400017
*                                                                       23700017
         CR    FRAD,TOAD               TEST FOR TYPE OF OVERLAP         24000017
         BE    GDCTI140                TYPE 1                           24300017
         BL    GDCTI060                TYPE 2                           24600017
*                                                                       24900017
* TYPE 3 OVERLAP                                                        25200017
*                                                                       25500017
         LR    BOTMT,ELCT              COMPUTE THE ADDRESS OF THE       25800017
         CH    OSLGTH,NH1                BOTTOM OF THE OUTPUT ARRAY FOR 26100017
         BE    GDCTI010                                                 26400017
         SLL   BOTMT,2                   4 BYTE OUTPUT DATA             26700017
         B     GDCTI020                                                 27000017
GDCTI010 SLL   BOTMT,1                   2 BYTE OUTPUT DATA             27300017
GDCTI020 AR    BOTMT,TOAD                                               27600017
         CR    BOTMT,FRAD              ARE ARRAYS DISTINCT              27900017
         BNH   GDCTI150                YES                              28200017
*                                                                       28500017
* MOVE INPUT DATA TO OUTPUT ARRAY                                       28800017
*                                                                       29100017
         LR    TASK,ELCT               COMPUTE TOTAL MOVE COUNT         29400017
         CH    OSLGTH,NH1                                               29700017
         BE    GDCTI030                                                 30000017
         SLL   TASK,2                                                   30300017
         B     GDCTI040                                                 30600017
GDCTI030 SLL   TASK,1                                                   30900017
GDCTI040 CH    TASK,NH256              CAN MOVE BE COMPLETED            31200017
         BNH   GDCTI120                YES                              31500017
         MVC   0(256,TOAD),0(FRAD)     MOVE DATA TO OUTPUT ARRAY        31800017
         SH    TASK,NH256              ADJUST TOTAL MOVE COUNT          32100017
         AH    TOAD,NH256              ADJUST OUTPUT ARRAY INDEX        32400017
         AH    FRAD,NH256              ADJUST INPUT ARRAY INDEX         32700017
         B     GDCTI040                                                 33000017
*                                                                       33300017
* TYPE 2 OVERLAP                                                        33600017
*                                                                       33900017
GDCTI060 LR    BOTMF,ELCT              COMPUTE THE ADDRESS              34200017
         SLL   BOTMF,1                   OF THE BOTTOM OF               34500017
         AR    BOTMF,FRAD                THE INPUT ARRAY                34800017
         CR    BOTMF,TOAD              ARE ARRAYS DISTINCT              35100017
         BNH   GDCTI150                YES                              35400017
         CH    OSLGTH,NH1               IS OUTPUT DATA 2 BYTE           35700017
         BE    GDCTI070                YES                              36000017
         LH    MOVE,NH1                INDICATE CONVERT AFTER INVERT    36300017
         LH    INPL,NH1                INDICATE IN PLACE CONVERSION     36600017
*                                                                       36900017
* MOVE INPUT DATA TO OUTPUT ARRAY                                       37200017
*                                                                       37500017
         LR    TOAD,ELCT               COMPUTE THE ADDRESS              37800017
         SH    TOAD,NH1                  OF THE LAST                    38100017
         SLL   TOAD,1                    ELEMENT IN THE                 38400017
         AR    TOAD,FRAD                 INPUT ARRAY                    38700017
         B     GDCTI180                                                 39000017
GDCTI070 LR    BOTMT,ELCT              COMPUTE THE ADDRESS              39300017
         SLL   BOTMT,1                   OF THE BOTTOM OF               39600017
         AR    BOTMT,TOAD                THE OUTPUT ARRAY               39900017
         LR    DELTA,BOTMT             COMPUTE THE MAXIMUM MOVE COUNT   40200017
         SR    DELTA,BOTMF               LESS THAN 256                  40500017
         LR    TASK,BOTMF              COMPUTE TOTAL MOVE COUNT         40800017
         SR    TASK,FRAD                                                41100017
GDCTI090 CH    TASK,NH256              CAN MAXIMUM MOVE BE MADE         41400017
         BNH   GDCTI100                YES                              41700017
         CH    DELTA,NH256             CAN 256 BYTES BE MOVED           42000017
         BNH   GDCTI110                NO                               42300017
         SH    BOTMF,NH256             ADJUST INPUT ARRAY ADDRESS       42600017
         SH    BOTMT,NH256             ADJUST OUTPUT ARRAY ADDRESS      42900017
         MVC   0(256,BOTMT),0(BOTMF)   MOVE DATA TO OUTPUT ARRAY        43200017
         SH    TASK,NH256              ADJUST TOTAL MOVE COUNT          43500017
         B     GDCTI090                                                 43800017
GDCTI100 CR    TASK,DELTA              CAN MOVE BE COMPLETED            44100017
         BL    GDCTI120                YES                              44400017
GDCTI110 SR    BOTMT,DELTA             ADJUST OUTPUT ARRAY INDEX        44700017
         SR    BOTMF,DELTA             ADJUST INPUT ARRAY INDEX         45000017
         SH    DELTA,NH1               PREPARE MOVE COUNT               45300017
         EX    DELTA,MOVE2             MOVE DATA TO OUTPUT ARRAY        45600017
         AH    DELTA,NH1                                                45900017
         SR    TASK,DELTA              ADJUST TOTAL MOVE COUNT          46200017
         B     GDCTI090                                                 46500017
GDCTI120 SH    TASK,NH1                PREPARE MOVE COUNT               46800017
         EX    TASK,MOVE1              MOVE DATA TO OUTPUT ARRAY        47100017
*                                                                       47400017
* SETUP FOR CONVERSION                                                  47700017
*                                                                       48000017
GDCTI130 LM    FRAD,TOAD,0(PLIST)                                       48300017
         LR    FRAD,TOAD               PREPARE TO CONVERT IN PLACE      48600017
GDCTI140 LH    INPL,NH1                INDICATE CONVERSION IN PLACE     48900017
         LR    LASTL,ELCT              COMPUTE THE ADDRESS              49200017
         SH    LASTL,NH1                 OF THE LAST ELEMENT            49500017
         SLL   LASTL,1                   IN THE INPUT ARRAY             49800017
         AR    LASTL,FRAD                                               50100017
GDCTI150 LR    SLAVE,ELCT              COMPUTE THE ADDRESS OF THE       50400017
         SH    SLAVE,NH1                 LAST ELEMENT IN THE OUTPUT     50700017
         CH    OSLGTH,NH1                ARRAY FOR                      51000017
         BE    GDCTI160                                                 51300017
         SLL   SLAVE,2                   4 BYTE OUTPUT DATA             51600017
         B     GDCTI170                                                 51900017
GDCTI160 SLL   SLAVE,1                   2 BYTE OUTPUT DATA             52200017
GDCTI170 AR    TOAD,SLAVE                                               52500017
         CH    OSLGTH,NH1              SHOULD ELEMENT FORM BE CHANGED   52800017
         BNE   GDCTI210                YES                              53100017
*                                                                       53400017
* WHEN THE LENGTH OF THE OUTPUT ELEMENTS IS 2 BYTES THE ELEMENT FORMAT  53700017
* DOES NOT CHANGE. HOWEVER THE ORDER OF THE ELEMENTS IS INVERTED. NO    54000017
* DISTINCTION IS MADE ARITHMETIC INPUT AND ALPHAMERIC INPUT.            54300017
*                                                                       54600017
GDCTI180 LTR   INPL,INPL               SHOULD CONVERSION BE IN PLACE    54900017
         BP    GDCTI190                YES                              55200017
         MVC   0(2,TOAD),0(FRAD)       INVERT ARRAYS                    55500017
         SH    ELCT,NH1                DECREMENT ELEMENT COUNT          55800017
         B     GDCTI200                                                 56100017
GDCTI190 LH    SLAVE,0(TOAD)           SAVE ELEMENT FROM OVERLAY        56400017
         MVC   0(2,TOAD),0(FRAD)       INVERT ARRAY                     56700017
         STH   SLAVE,0(FRAD)                                            57000017
         SH    ELCT,NH2                DECREMENT ELEMENT COUNT          57300017
GDCTI200 LTR   ELCT,ELCT               IS INVERSION COMPLETE            57600017
         BC    12,GDCTI205             YES                              57900017
         AH    FRAD,NH2                 ADJUST INPUT ARRAY INDEX        58200017
         SH    TOAD,NH2                ADJUST OUTPUT ARRAY INDEX        58500017
         B     GDCTI180                                                 58800017
GDCTI205 LTR   MOVE,MOVE               MUST DATA BE CONVERTED AND MOVED 59100017
         BZ    GDCTI250                NO                               59400017
         LM    FRAD,ELCT,0(PLIST)      GET PARAMETERS                   59700017
         L     ELCT,0(ELCT)            GET ELEMENT COUNT                60000017
         LR    SLAVE,ELCT              COMPUTE THE ADDRESS              60300017
         SH    SLAVE,NH1                 OF THE LAST                    60600017
         SLL   SLAVE,1                   ELEMENT IN THE                 60900017
         AR    FRAD,SLAVE                INPUT ARRAY                    61200017
         LR    SLAVE,ELCT              COMPUTE THE ADDRESS              61500017
         SH    SLAVE,NH1                 OF THE LAST                    61800017
         SLL   SLAVE,2                   ELEMENT IN THE                 62100017
         AR    TOAD,SLAVE                OUTPUT ARRAY                   62400017
GDCTI207 LH    CON1,0(FRAD)            GET AN UNCONVERTED NUMBER        62700017
         SLL   CON1,16                 POSITION SIGN BIT                63000017
         SRA   CON1,16                 POSITION DATA                    63300017
         ST    CON1,0(TOAD)            STORE CONVERTED NUMBER           63600017
         BCT   ELCT,GDCTI208           IS CONVERSION COMPLETE           63900017
         B     GDCTI250                YES                              64200017
GDCTI208 SH    FRAD,NH2                ADJUST INPUT ARRAY ADDRESS       64500017
         SH    TOAD,NH4                ADJUST OUTPUT ARRAY ADDRESS      64800017
         B     GDCTI207                                                 65100017
*                                                                       65400017
* WHEN THE LENGTH OF THE OUTPUT ELEMENTS IS 4 BYTES THE ELEMENT FORMAT, 65700017
* AS WELL AS THEIR ARRAY ORDER MUST CHANGE.                             66000017
*                                                                       66300017
GDCTI210 LH    CON1,0(FRAD)            GET AN UNCONVERTED NUMBER        66600017
         SLL   CON1,16                 POSITION SIGN BIT                66900017
         SRA   CON1,16                 POSITION DATA                    67200017
         CH    ELCT,NH1                IS CONVERSION COMPLETE           67500017
         BNE   GDCTI220                NO                               67800017
         ST    CON1,0(TOAD)            STORE CONVERTED NUMBER           68100017
         B     GDCTI250                                                 68400017
GDCTI220 LH    CON2,2(FRAD)            GET AN UNCONVERTED NUMBER        68700017
         SLL   CON2,16                 POSITION SIGN BIT                69000017
         SRA   CON2,16                 POSITION DATA                    69300017
         LTR   INPL,INPL               SHOULD CONVERSION BE IN PLACE    69600017
         BZ    GDCTI225                NO                               69900017
         LH    CON3,0(LASTL)           GET AN UNCONVERTED NUMBER        70200017
         SLL   CON3,16                 POSITION SIGN BIT                70500017
         SRA   CON3,16                 POSITION DATA                    70800017
         ST    CON3,0(FRAD)            STORE CONVERTED NUMBER           71100017
         SH    ELCT,NH1                ADJUST ELEMENT COUNT             71400017
         SH    LASTL,NH2               ADJUST IN PLACE POINTER          71700017
GDCTI225 CH    ELCT,NH3                ARE THERE ONLY 3 ELEMENTS        72000017
         BNE   GDCTI230                NO                               72300017
         LH    CON3,4(FRAD)            GET AN UNCONVERTED NUMBER        72600017
         SLL   CON3,16                 POSITION SIGN BIT                72900017
         SRA   CON3,16                 POSITION DATA                    73200017
         ST    CON1,0(TOAD)            STORE CONVERTED NUMBER           73500017
         SH    TOAD,NH4                ADJUST OUTPUT ARRAY INDEX        73800017
         ST    CON2,0(TOAD)            STORE CONVERTED NUMBER           74100017
         SH    TOAD,NH4                ADJUST OUTPUT ARRAY INDEX        74400017
         ST    CON3,0(TOAD)            STORE CONVERTED NUMBER           74700017
         B     GDCTI250                                                 75000017
GDCTI230 ST    CON1,0(TOAD)            STORE CONVERTED NUMBER           75300017
         SH    ELCT,NH2                ADJUST ELEMENT COUNT             75600017
         LTR   ELCT,ELCT               IS CONVERSION COMPLETE           75900017
         BZ    GDCTI240                YES                              76200017
          BM    GDCTI250                                                76500017
         AH    FRAD,NH4                ADJUST INPUT ARRAY INDEX         76800017
         SH    TOAD,NH4                ADJUST OUTPUT ARRAY INDEX        77100017
         ST    CON2,0(TOAD)            STORE CONVERTED NUMBER           77400017
         SH    TOAD,NH4                ADJUST OUTPUT ARRAY INDEX        77700017
         B     GDCTI210                                                 78000017
GDCTI240 SH    TOAD,NH4                ADJUST OUTPUT ARRAY INDEX        78300017
         ST    CON2,0(TOAD)            STORE CONVERTED NUMBER           78600017
GDCTI250 RETURN (14,12),T                                               78900017
         EJECT                                                          79200017
*                                                                       79500017
* DEFINE CONSTANTS                                                      79800017
*                                                                       80100017
NH1      DC    H'1'                                                     80400017
NH2      DC    H'2'                                                     80700017
NH3      DC    H'3'                                                     81000017
NH4      DC    H'4'                                                     81300017
NH256    DC    H'256'                                                   81600017
MOVE1    MVC   0(0,TOAD),0(FRAD)                                        81900017
MOVE2    MVC   0(0,BOTMT),0(BOTMF)                                      82200017
         END                                                            82500017
