 TITLE 'IKDGTEND'  PROCESSOR-TO-PROCESSOR TERMINATION ROUTINE           00300017
*STATUS: CHANGE LEVEL 000                                             * 00600017
*FUNCTION/OPERATION: TO TERMINATE THE PROCESSOR-TO-PROCESSOR PROGRAM  * 00900017
*   1. CLOSE/DISABLE THE BTAM COMMUNICATION LINE                      * 01200017
*   2. FREE STORAGE ACQUIRED FOR USER RD/WRT BFRS AND FOR GTCB        * 01500017
*   3. DELETE IKDRDWRT, IKDGTCLT AND IKDGTIRB ROUTINES                * 01800017
*   4. FOR USER ASYNCHRONOUS ROUTINE CALL TO GTEND, RESTORES MAINLINE * 02100017
*   I/O STATUS                                                        * 02400017
*                                                                     * 02700017
*ENTRY POINTS: ENTRY AT IKDGTEND VIA LINK FROM IKDGTCLR (CONTROLLER)  * 03000017
*                                                                     * 03300017
*INPUT: REGISTER 11 POINTS TO USER'S PARAMETER LIST                   * 03600017
*   REGISTER 3 POINTS TO THE PTOP UNIT ASSIGNMENT TABLE (IKDUATBL)    * 03900017
*   REGISTER 4 POINTS TO THE GTCB REFERENCED BY USER'S DSRN           * 04200017
*                                                                     * 04500017
*OUTPUT: RETURN CODES TO IKDGTCLR (CONTROLLER) IN REGISTER 15         * 04800017
*   A) ZERO - END OF USER JOB, CONTROLLER SHOULD DELETE IKDUATBL      * 05100017
*   B) FOUR - USER ASYNCHRONOUS ROUTINE ENDED, CONTROLLER SHOULD FREE * 05400017
*   ASYNCHRONOUS ROUTINE SAVE AREA STORAGE                            * 05700017
*   C) EIGHT - USER TERMINATED ONE BTAM LINE, OTHER LINES STILL OPEN  * 06000017
*   IN JOB; CONTROLLER SHOULD NOT DELETE IKDUATBL                     * 06300017
*                                                                     * 06600017
*EXTERNAL ROUTINES: NONE                                              * 06900017
*                                                                     * 07200017
*EXITS-NORMAL: RETURN TO CONTROLLER                                   * 07500017
*     -ERROR: NONE                                                    * 07800017
*                                                                     * 08100017
*TABLES/WORK AREAS: GRAPHIC TELECOMMUNICATION CONTROL BLOCK (GTCB),   * 08400017
*   UNIT ASSIGNMENT TABLE (IKDUATBL)                                  * 08700017
*                                                                     * 09000017
*ATTRIBUTES: REENTRANT, TRANSIENT, NON-PRIVELEGED                     * 09300017
*                                                                     * 09600017
*NOTES: NONE                                                          * 09900017
R0       EQU   0                       REGISTER EQUATES                 10200017
R1       EQU   1                            CONTINUED                   10500017
R2       EQU   2                            CONTINUED                   10800017
RUATBL   EQU   3                            CONTINUED                   11100017
RGTCB    EQU   4                            CONTINUED                   11400017
R5       EQU   5                            CONTINUED                   11700017
RBASE    EQU   7                            CONTINUED                   12000017
RDCB     EQU   8                            CONTINUED                   12300017
RASYNSV  EQU   9                            CONTINUED                   12600017
RSAVE    EQU   13                           CONTINUED                   12900017
R14      EQU   14                           CONTINUED                   13200017
R15      EQU   15                           CONTINUED                   13500017
*                                                                       13800017
ZERO     EQU   0                       PROGRAM EQUATES                  14100017
ONE      EQU   1                            EQUATE 1                    14400017
TWO      EQU   2                            EQUATE 2                    14700017
THREE    EQU   3                            EQUATE 3                    15000017
FOUR     EQU   4                            EQUATE 4                    15300017
FIVE     EQU   5                            EQUATE 5                    15600017
SIX      EQU   6                            EQUATE 6                    15900017
EIGHT    EQU   8                            EQUATE 8                    16200017
AFLGS    EQU   12                           EQUATE 12                   16500017
INFO     EQU   28                           EQUATE 28                   16800017
UCBAD    EQU   32                      EQUATE       32                  17100017
SVDISP   EQU   72                           EQUATE 72                   17400017
USECNT   EQU   412                     USECNT FIELD DISP IN UATBL       17700017
*                                                                       18000017
GTEND    EQU   X'01'                   FLAG BIT                         18300017
ASYEND   EQU   X'0200'                 HEADER FOR ASYN MSG END          18600017
HDRLNG   EQU   X'04'                   HDR LENGTH                       18900017
MSGEND   EQU   X'0800'                 HDR FOR END MSG                  19200017
WTIXR    EQU   X'10'                   OP TYPE FLAG                     19500017
ASYNC    EQU   X'20'                   1130 ASYN  REQ FLAG              19800017
WTASY    EQU   X'20'                   WAIT FOR ASYN END MSG FLAG       20100017
HALTIO   EQU   X'48'                   HALT I/O COMPLETION CODE         20400017
WTOFF    EQU   X'5F'                   TURN OFF CODE                    20700017
ENDOFF   EQU   X'7F'                   OFF CODE                         21000017
BIT      EQU   X'80'                   HI-ORDER BIT                     21300017
WTEND    EQU   X'80'                   WAIT FOR END MSG FLAG            21600017
STARTED  EQU   X'83'                   STATUS CODE = 3                  21900017
ASYREQ   EQU   X'88'                   ASYN END MSG HEADER              22200017
TERMREQ  EQU   X'98'                   END MSG HEADER                   22500017
ENDASY   EQU   X'DF'                   OFF FLAG                         22800017
IKDGTEND CSECT                                                          26400017
         SAVE  (14,12),,*                                               26800017
         BALR  RBASE,R0                ESTABLISH BASE REGISTER 7        27200017
         USING *,RBASE                      CONTINUE                    27600017
         USING IKDGTCB,RGTCB           EST. GTCB DSECT BASE REG 4       28000017
         LA    RDCB,GTCDCB             EST. DCB DSECT BASE              28400017
         USING IHADCB,RDCB                  CONTINUE                    28800017
*                                                                       29200017
         TM    GTCFLAGS,ASYNC          ASYN ROUTINE REQUEST             29600017
         BO    ASYNSV                  BRANCH IF YES                    30000017
         ST    RSAVE,GTCSVAR+FOUR      EST. SAVE AREA CHAIN             30400017
         LR    R2,RSAVE                     CONTINUE                    30800017
         LA    RSAVE,GTCSVAR                CONTINUE                    31200017
         ST    RSAVE,EIGHT(R2)              CONTINUE                    31600017
         OI    FLGS3,WTEND             SET GTEND RTN ENTERED FLAG       32000017
PENDING  EQU   *                       CHECK I/O STATUS                 32400017
         MVI   GTCECB,ZERO             CLEAR ECB TO 0                   32800017
         CLI   GTCLSTWR,STARTED   HAS USER WRITE  BEEN STARTED          33200017
         BNE   CHKPTOP                 BRANCH IF NOT                    33600017
*                                                                       34000017
WAITWRT  EQU   *                                                        34400017
         LA    R1,GTCECB                                                34800017
         OI    FLGS3,WTEND             SET GTEND IN WAIT STATE FLAG     35200017
         WAIT  ECB=(1)                 WAIT FOR PENDING USER WRITE      35600017
*                                                                       36000017
         NI    FLGS3,ENDOFF            SET WAIT FLG OFF                 36400017
         B     CHKSTAT                 BRANCH TO RESETPL                36800017
CHKPTOP  EQU   *                                                        37200017
         TM    FLGS2,WTIXR             HAS PTOP WRITTEN A MSG           37600017
         BO    WAITWRT                 BRANCH IF YES                    38000017
*                                                                       38400017
CHKSTAT  EQU   *                       ISSUE RESETPL                    38800017
         LA    R1,GTCPDECB             LOAD DECB ADR IN PARAM REG 1     39200017
         RESETPL (1)                   HALT I/O                         39600017
         LA    R1,GTCECB         SET ECB ADDRESS                        40000017
         C     R15,CON4                IS RETURN CODE AN ERROR TYPE     40400017
         BE    SETWT              BRANCH IF EQUAL                       40800017
*                                                                       41200017
         L     R2,DCBDEBAD             GET UCB ADR FROM DEB             41260017
         L     R2,UCBAD(R2)                                             41320017
         TM    FOUR(R2),WTEND          WAS HALTIO ISSUD                 41380017
         BNZ   SETR1              SET POINTER TO DECB                   41420017
         LA    R1,GTCPDECB                                              41460017
         B     SETWT              BRANCH TO WAIT FOR I/O COMPLETEION    41500017
SETR1    EQU   *                                                        41540017
*                                                                       41580017
         LA    R1,GTCPDECB        SET DECB POINTER                      41630017
         CLI   GTCPDECB,HALTIO         IS HALTIO COMPLETE               41680017
         BE    CHKASYN                 BRANCH IF YES                    42100017
*                                                                       42400017
*                                                                       42800017
*                                                                       43200017
SETWT    EQU   *                                                        43600017
         TM    GTCFLAGS,GTEND          HAS 1130 GTENDED                 44000017
         BO    CHKASYN                 BRANCH IF YES                    44400017
*                                                                       44800017
         OI    FLGS3,WTEND             SET GTEND IN WAIT STATE FLAG     45600017
         WAIT  ECB=(1)                 WAIT FOR I/O ON RESETPL          46000017
*                                                                       46400017
         NI    FLGS3,ENDOFF            SET WAIT FLG OFF                 46800017
CHKASYN  EQU   *                                                        47200017
         TM    GTCFLAGS,ASYNC          REQ FROM 360 ASYN RTN            47600017
         BZ    CHKEND                  BRANCH IF NOT                    48000017
*                                                                       48400017
         L     R2,GTCSVINF             LOAD ADR OF ML-STATUS SVAREA     48800017
         MVC   AFLGS(ONE,R2),GTCFLAGS   MOVE FLGS1 TO SAVE AREA         49200017
         MVC   GTCECB(INFO),ZERO(R2)    MOVE ML STATUS TO GTCB          49600017
*                                                                       50000017
CHKEND   TM    GTCFLAGS,GTEND          HAS 1130 USER CALLED GTEND       50400017
         BZ    WRITE                   BRANCH IF NOT                    50800017
*                                                                       51200017
         TM    GTCFLAGS,ASYNC          ASYN RTN REQUEST                 51600017
         BO    ASYNRET                 BRANCH IF YES                    52000017
*                                                                       52400017
UPDATE   LA    R2,GTCDCB               SET UP CLOSE PARAM LIST          52800017
         ST    R2,GTCPTPWR             PUT DCB ADR IN LIST              53300017
         MVI   GTCPTPWR,BIT            SET HI-ORDER BIT                 53800017
         LA    R1,GTCPTPWR             PUT LIST ADR IN PARAM REG        54300017
*                                                                       54800017
         CLOSE  MF=(E,(1))             CLOSE DCB                        55200017
*                                                                       55600017
         LH    R2,GTCWRSIZ             GET WR BFR SIZE                  55620017
         AH    R2,GTCRDSIZ             ADD READ BFR SIZE                55640017
         L     R1,GTCWRBUF             LOAD ADR OF BFR                  55660017
         C     R1,GTCRDBUF             READ AND WRITE BFR SAME          55680017
         BE    ADD8                    BRANCH IF YES                    55700017
*                                                                       55720017
         LA    R2,EIGHT(R2)            ADD HDR LNG 8                    55740017
*                                                                       55760017
ADD8     LA    R2,EIGHT(R2)            ADD HDR LNG 8                    55780017
         LR    R0,R2                   LOAD LNG INTO PARAM REG          55800017
*                                                                       55820017
         FREEMAIN R,LV=(0),A=(1)       FREE RD/WR BFR CORE              55840017
*                                                                       55860017
         L     R0,GTCBGET              LOAD GTCB LNG IN REG 0           56160017
         LR    R1,RGTCB                PUT GTCB ADR IN REG 1            56460017
         L     RSAVE,GTCSVAR+FOUR      SAVE CALLER'S REG 13             56760017
         SR    R2,R2                   CLEAR REG 2                      57200017
         IC    R2,ZERO(RGTCB)           INSERT DSRN FOR INDEX           57600017
         S     R2,CON1                 SUBTRACT 1 FROM DSRN TO INDEX    58000017
         SLL   R2,TWO                  MULTIPLY BY 4                    58400017
         AR    R2,RUATBL               ADD ADR OF PTOP UATBL            58800017
         XC    ZERO(FOUR,R2),ZERO(R2)  CLEAR UATBL SLOT FOR GTCB ADR    59200017
*                                                                       59600017
         FREEMAIN R,LV=(0),A=(1)       FREE GTCB CORE                   60000017
*                                                                       60400017
         L     R5,USECNT(RUATBL)       LOAD USECNT FIELD                60800017
         BCT   R5,GOBACK               BRANCH IF USECNT NOT ZERO        61200017
*                                                                       61600017
*                                                                       62000017
         DELETE EP=IKDRDWRT                                             62400017
*                                                                       62800017
         DELETE EP=IKDGTCLT                                             63200017
*                                                                       63600017
         DELETE EP=IKDGTIRB                                             64000017
*                                                                       64400017
*                                                                       64800017
GOBACK   EQU   *                                                        65200017
         ST    R5,USECNT(RUATBL)       RESTORE UPDATED USECNT           65400017
         LTR   R5,R5                   IS USECNT EQUAL TO ZERO          65600017
         BNZ   RETURNCD                BRANCH IF NOT                    66000017
*                                                                       66400017
         RETURN (14,12),T,RC=0         RETURN TO INDICATE END OF JOB    66800017
*                                                                       67200017
*                                                                       67600017
RETURNCD RETURN (14,12),T,RC=8         RETURN TO INDICATE LINES OPEN    68000017
*                                                                       68400017
*                                                                       68800017
ASYNSV   LA    R2,SVDISP(RSAVE)        SET UP SVAREA FOR ASYN RTN REQ   69200017
         ST    RSAVE,FOUR(R2)               CONTINUE                    69600017
         ST    R2,EIGHT(RSAVE)              CONTINUE                    70000017
         LR    RASYNSV,RSAVE           SAVE ADR                         70400017
         LR    RSAVE,R2                     CONTINUE                    70800017
         B     PENDING                 BRANCH TO CHECK I/O STATUS       71200017
*                                                                       71600017
*                                                                       72000017
*                                                                       72400017
WRITE    EQU   *                       SET UP MESSAGE                   72800017
         MVC   GTCPTPWR(TWO),DCBBSTSX  MOVE IN CTL CHARS DLE STX        73200017
         MVC   GTCPTPWR+THREE(ONE),GTCDSRNO      COMPLETE MSG HEADER    73600017
         LH    R1,GTCWRSEQ             UPDATE SEQUENCE NUMBER           74000017
         LA    R1,ONE(R1)                   CONTINUE                    74300017
         STH   R1,GTCWRSEQ                  CONTINUE                    74600017
         STC   R1,GTCPTPWR+FOUR        INSERT SEQ NO. IN HDR            74900017
         MVI   GTCPTPWR+FIVE,HDRLNG    FINISH HDR                       75200017
*                                                                       75500017
         TM    GTCFLAGS,ASYNC          ASYN END REQUEST                 75800017
         BO    SETASYN                 BRANCH IF YES                    76100017
*                                                                       76400017
         MVI   GTCPTPWR+TWO,TERMREQ    INSERT MSG CODE                  76700017
         OI    FLGS3,WTEND             SET GTEND IN WAIT STATE TO END   77600017
         LA    R2,MSGEND               GET END MSG CODE                 78000017
         B     WTIXRMSG                BRANCH TO ISSUE WRITE            78400017
*                                                                       78800017
SETASYN  EQU   *                       SET UP ASYN END MSG              79200017
         MVI   GTCPTPWR+TWO,ASYREQ     INSERT CODE                      79600017
         LA    R2,ASYEND               GET ASYN END MSG CODE            80000017
         OI    FLGS3,WTASY             SET GTEND WAITING FOR ASYN END   80400017
*                                                                     * 80800017
*                                  WRITE END MESSAGE FOR ASYN OR END  * 81200017
*                                                                     * 81600017
WTIXRMSG STH   R2,GTCPTPWR+SIX         INSERT PROPER MSG CODE           82000017
         MVI   FLGS2,WTIXR             SET PTOP WTIXR FLAG              82400017
         MVI   GTCECB,ZERO             CLEAR ECB TO ZERO                82800017
         LA    R1,GTCPDECB             GET DECB ADR                     83200017
         LA    R2,GTCPTPWR             GET WRBUF ADR                    83600017
         WRITE  (1),TIXR,(8),(2),10,,1,MF=E                             84000017
*                                                                       84400017
*                                                                       84800017
WAITEND  EQU   *                                                        85200017
         LA    R1,GTCECB                                                85600017
         WAIT  ECB=(1)                 WAIT FOR I/O COMPLETION          86000017
*                                                                       86400017
         NI    FLGS3,WTOFF             SET WAIT FLAGS OFF               86800017
         TM    GTCFLAGS,ASYNC          ASYNC END MSG REQ                87200017
         BZ    UPDATE                  BRANCH IF NOT                    87600017
*                                                                       88000017
ASYNRET  EQU   *                                                        88400017
         NI    GTCFLAGS,ENDASY         SET ASYNC BIT OFF                88800017
         LR    RSAVE,RASYNSV           RESTORE SVAR PTR                 89200017
         RETURN (14,12),T,RC=4         RETURN WITH RETURN CODE = 4      89600017
*                                                                     * 90000017
*                       CONSTANTS  DEFINED                            * 90400017
*                                                                     * 90800017
CON1     DC    F'1'                    CONSTANT  EQUAL  TO  1           91200017
CON4     DC    F'4'                    CONSTANT  EQUAL  TO  4           91600017
GTCBGET  DC    F'512'                  LENGTH OF GTCB STORAGE           92000017
         CNOP  0,4                                                      92400017
         COPY  IKDGTCB                                                  92800017
         DCBD  DSORG=CX,DEVD=BS                                         93200017
         END                                                            93600017
