         GBLB  &STD                                                     00020021
&STD     SETB  1                                                        00040021
AA       TITLE 'IEMAA,RESIDENT CONTROL PHASE,COMPILER CONTROL,OS/360 PLC00080015
               /I COMPILER(F)'                                          00160015
*                                                                       00240015
*              STATUS - CHANGE LEVEL 0                                  00320015
*                                                                       00322056
* 5.5  A 168800,173600,177600                                  KT 60069 00324072
* 5.5  A 588800                                                KT 57455 00324172
* 5.5  C 516800,528000-531200,547400-547600,549600-554400      KT 57455 00324272
*        559200-560000                                         KT 57455 00324372
* 5.5  D 517600,533600-543200,555200                           KT 57455 00324472
* 5.4  A 000000,119200,454000,454100,749200                   MCB 54703 00324621
* 5.4  C 121600,175200                                        MCB 54704 00325221
* 5.3B C 003600-003800  *** REWORKING OF FLAGGING COMMENTS.   CRS 47664 00326056
*      D 002000,003996-005176                                 CRS 47664 00328056
* 5.3A C 798800-798900                                        PG  43462 00330056
* 5.3A C 499200-506400                                        JLC Z2074 00332056
*      D 494400-496800                                        JLC Z2074 00334056
* 5.3A *** THIS FIX WAS MADE FROM REL 20.0 ON BY A NUMBER     CRS 31173 00336056
*      *** OF PEOPLE, FOR FETCH PROTECT SUPPORT.              CRS 31173 00338056
*      ** THE CHANGES WERE SO COMPLEX THAT ONLY THE END       CRS 31173 00340056
*      ** RESULT WILL BE GIVEN, AS FOLLOWS -                  CRS 31173 00342056
*                                                             MCB 31173 00344056
* 5.2B C 330700-332800,358000,393200,403000-406200            JLC 31173 00346056
*      D 361600-363200                                        PG  31173 00348056
*      A 785800-786100                                        CRS 31173 00350056
*                                                             MAC 31173 00352056
* 5.2B A 984000                                               JLC Z2151 00354056
*      C 715400-718400  (REPACKAGE -> IEMAK)                  JLC Z2151 00356056
* 5.2  A 382200,627600,641200,666800,668400,715300,717600     JLC 33893 00358056
*      C 652000-652800                                        JLC 33893 00360056
*      D 384000,654400                                        JLC 33893 00362056
*                                                                       00364056
*                                                                       00366056
* R18 135200*,176800,591200*                                     PTM825 00386001
* R18              FOR CONTROL PURPOSES PTM825 WAS MADE INTO APAR  H229 00392001
* R18 155200-156000,536800*,540800*,590800-591400,                 H229 00392301
* R18 744800*,748800,752800,798400,918400                          H229 00392601
* R18 176000,177200                                                H235 00393001
* R18 174200,176400                                               H207  00395001
* R18 DUPLICATE OF H207                                           23263 00396001
* R18 174250,176320                                               H313  00397001
* R18 174300,176260                                               H319  00398001
* R19 APAR 21158 HAS BEEN FIXED BY I24                                  00398619
* R19 791400,812000,814530,818900,836800                            I24 00399219
         SPACE 3                                                        00519620
*              FUNCTIONS - 1)COMPILER INITIALISATION. IEMAB IS LOADED   00560015
*        IN ORDER TO PERFORM THIS FUNCTION                              00640015
*                          2)CHARACTER TRANSLATION. EBCIDIC OR BCD TO   00720015
*        INTERNAL AND BACK TO EXTERNAL. THE RELEVANT TABLE IS SUPPLIED  00800015
*        DEPENDING UPON THE OPTION                                      00880015
*                          3)DICTIONARY AND TEXT BLOCK CONTROL. THESE   00960015
*        INCLUDE,EVENTUALLY,THE SPILLING OF BLOCKS ONTO SYSUT1 AND THE  01040015
*        CONTROL THEREOF.                                               01120015
*                          4)PHASE LOADING. FACILITIES ARE ALLOWED FOR  01200015
*        MARKING PHASES,LOADING PHASES AND RETURNING CONTROL TO THE     01280015
*        CALLER,DELETING(RELEASING) PHASES AND PASSING CONTROL TO A NEW 01360015
*        PHASE.                                                         01440015
*                          5)INPUT/OUTPUT CONTROL ONTO SYSPRINT,SYSIN,  01520015
*        SYSLIN AND SYSPUNCH. CONTROL TO SYSUT3 IN IEMAC                01600015
*                                                                       01680015
*                                                                       01760015
*              ENTRY POINT - THE CONTROL PHASE HAS A MULTITUDE OF ENTRY 01840015
*        POINTS. THE ARE LISTED IN THE TRANSFER VECTOR AT THE START OF  01920015
*        THE PHASE                                                      02000015
*                                                                       02080015
*                                                                       02160015
*              INPUT - ONLY INPUT IS THE PARAMETER LIST POINTED AT BY   02240015
*        GENERAL REGISTER 1 ON ENTRY                                    02320015
*                                                                       02400015
*                                                                       02480015
*              OUTPUT - THE ONLY OUTPUT GENERATED BY THE COMPILER IS    02560015
*        THE RETURN CODE PLACED IN GENERAL REGISTER 15 ON COMPLETION OF 02640015
*        THE COMPILATION                                                02720015
*                                                                       02800015
*                                                                       02880015
*              EXTERNAL ROUTINES - 1)IEMAB THE COMPILER INITIALISER. IT 02960015
*        IS LOADED IMEDIATELY AFTER IEMAA HAS BEEN LOADED.              03040015
*                                  2)IEMAC. THE INTERMEDIATE FILE       03120015
*        CONTROL. RECORDS ARE WRITTEN ON SYSUT3 AND THE READ BACK.      03200015
*                                  3)IEMAD. INTER-PHASE DUMPING CONTROL 03280015
*                                  5)IEMAF. GENERATED BY SYSGEN. IT     03440015
*        WILL INDICATE THE STATUS OF THE DEFAULT OPTIONS                03520015
*                                  6)IEMAG. SYSUT3 FILE SWITCHING. IT   03600015
*        IS CALLED BY IEMAC.                                            03680015
*                                  4)IEMAE. CLEAN-UP AFTER READIN AND   03760015
*        OPEN SYSLIN AND SYSPUNCH IF NECESSARY                          03840015
*                                                                       03920015
*                                                                       04000015
*              EXITS - THE EXIT IS THROUGH ZEND. IT IS THERE THAT THE   04080015
*        CONDITION CODE IS PICKED UP. THERE ARE NO ABNORMAL EXITS.      04160015
*                                                                       04240015
*                                                                       04320015
*              ATTRIBUTES - THIS CODE IS NOT REUSABLE                   04400015
         EJECT                                                          04480015
*                                                                       04560015
*              BASE THE COMPILER                                        04640015
*                                                                       04720015
         SPACE 2                                                        04800015
*              FOR THE ENTRY POINT IEMAA, REGISTER 1              IEM00 04808017
*        POINTS TO A PARAMETER LIST WHICH HAS ONE OF              IEM00 04816017
*        THE THREE FORMS                                          IEM00 04824017
*                                                                 IEM00 04832017
*        (1)   A( OPTION LIST ) OR                                IEM00 04840017
*                 O                                               IEM00 04848017
*        (2)   A( OPTION LIST )                                   IEM00 04856017
*              A( ALTERNATE DDNAME LIST ) OR                      IEM00 04864017
*                                                                 IEM00 04872017
*        (3)   A( OPTION LIST )                                   IEM00 04880017
*              A( ALTERNATE DDNAME LIST )                         IEM00 04888017
*              A( PAGE NUMBER )                                   IEM00 04896017
*                                                                       04897017
*        (4)   A( OPTIONS LIST )                                        04898017
*              A( ALTERNATE DDNAME LIST )                               04899017
*              A( PAGE NUMBER )                                         04900017
*              A( DATA ROUTINE )                                        04901017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 000-TSS 04902020
         SPACE 2                                                  IEM00 04904017
IEMAA    START 0                                                  IEM00 04912017
*        ----------------------------------------------------AA 000-TSS 04916020
         SPACE 1                                                  IEM00 04920017
         USING *,15                                               IEM00 04928017
         SPACE 1                                                  IEM00 04936017
         STM   14,12,12(13)          STORE OS/360 REGISTERS       IEM00 04944017
         L     CNTL,BASAD1           LOAD BASE REGISTER           IEM00 04952017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 047-TSS 04954020
*        ----------------------------------------------------AA 047-TSS 04956020
         B     ZINIT                                              IEM00 04960017
         SPACE 1                                                  IEM00 04968017
BASAD1   DC    A(SECT1)                                           IEM00 04976017
         SPACE 1                                                  IEM00 04984017
         DROP  15                                                 IEM00 04992017
         SPACE 5                                                  IEM00 05000017
         USING *,CNTL                                             IEM00 05392017
         SPACE 1                                                  IEM00 05400017
SECT1    DC    A(0)                    ADDRESS OF DATA ROUTINE    IEM00 05408017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 021-TSS 05412020
         DC    A(RDDCB)                ADDRESS OF SYSIN DCB       IEM00 05416017
*        ----------------------------------------------------AA 021-TSS 05426020
         EJECT                                                          05440015
*                                                                       05520015
*              THE TRANSFER VECTOR. IT CONTAINS THE ADDRESSES OF THE    05600015
*        ENTRY POINTS OF THE VARIOUS ROUTINES WITHIN THE CONTROL PHASE  05680015
*                                                                       05760015
*        THE OFFSET OF EACH ADCON IS FIXED AND IS KNOWN BY ALL THE      05840015
*        COMPILER PHASES. IF A COMPILER PHASE WISHES TO CALL A COMPILER 05920015
*        ROUTINE THEN ITS LINK REGISTER IS LOADED WITH THE ADCON        06000015
*        FROM A FIXED OFFSET WITHIN THE CONTROL PHASE. IN ALL CASES THE 06080015
*        RETURN REGISTER MUST BE 14.                                    06160015
*                                                                       06240015
*                                                                       06320015
*              THIS IS THE PRE-INITIALISER. THE OPERATIONS IT PERFORMS  06400015
*        ARE   1) A GETMAIN TO FIND A SAVE AREA                         06480015
*              2) READ THE TIMER IN ORDER TO TIME THE COMPILATION       06560015
*              3) LINK TO IEMAB. THIS IS THE REAL INITIALISER. THE LINK 06640015
*             IS PERFORMED IN ORDER TO LOAD THE PHASE INTO LOW CORE.    06720015
*             THIS WILL RESULT IN A LOW DEGREE OF FRAGMENTATION OF CORE 06800015
*             BETWEEN PHASES AND TEXT AND DICTIONARY BLOCKS             06880015
*              4) ISSUE A SPIE TO ENABLE THE COMPILER TO DEAL WITH ALL  06960015
*             TYPES OF PROGRAM CHECK                                    07040015
*              5) LOAD THE FIRST REQUESTED PHASE. THIS CAN BE           07120015
*                          MACRO PROCESSOR                              07200015
*                          48 CHARACTER SET (IEMBA)                     07280015
*                       OR READIN PASS-1 (IEMCA)                        07360015
*                                                                       07440015
         DC    A(0)    ZUPL            WILL HOLD PRINT ROUTINE          07520015
         DC    A(0)    ZURD                      SYSIN                  07600015
         DC    A(0)    ZUGC                      SCRATCH CORE FINDER    07680015
         DC    A(0)    ZUTXTC                    GET A TEXT BLOCK       07760015
         DC    A(0)    ZURC                      RELEASE SCRATCH CORE   07840015
         DC    A(ADDLST)               LIST OF ADDRESSES FOR INITIALTON 07920015
         DC    A(ZABORT)               ABORTS COMPILER                  08000015
         DC    A(LOADW)                LOADS PHASE AND RETURNS TO CALLR 08080015
         DC    A(0)    ZDICAB          WILL HOLD DIC ENTRY-ALIGNED,ABS  08160015
         DC    A(0)    ZDICRF                             -ALIGNED,REF  08240015
         DC    A(0)    ZUERR                     ERROR MSSG ENTRY       08320015
         DC    A(0)    ZDRFAB                    DIC REF TO ABSOLUTE    08400015
         DC    A(LOADX)                SPECIAL ENTRY FOR RELOADED PHASE 08480015
         DC    A(0)                    USE NOT KNOWN - DUMPS MAYBE      08560001
         DC    A(REQEST)               MARK PHASE AS REQUESTED,NOT WANT 08640015
         DC    A(RELESE)               DELETE THE LOADED PHASE          08720015
         DC    A(RLSCTL)               DELETE PHASE AND PASS CONTROL    08800015
         DC    A(0)  ZUST              ADDRESS OF IEMAD                 08880001
         DC    A(0)    ZTXTRF          WILL HOLD TEXT ABSOLUTE TO REF   08960015
         DC    A(0)    ZTXTAB                    TEXT REF TO ABSOLUTE   09040015
         DC    A(0)    ZCHAIN                    NEXT TEXT BLOCK IN CHN 09120015
         DC    A(0)    ZALTER                    ALTER STATUS OF TXT BL 09200015
         DC    A(0)    ZDABRF                    DIC- ABS TO REF        09280015
         DC    A(0)    ZNALRF                    DIC ENTRY-UNALGND,REF  09360015
         DC    A(0)    ZNALAB                              UNALGND,ABS  09440015
         DC    A(ZEND)                 TERMINATE JOB-STEP               09520015
         DC    A(ZULF)                 SYSTEM LOAD FILE                 09600015
         DC    A(ZUSP)                 SYSPUNCH                         09680015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 044-TSS 09720020
         DC    A(0)                    HOLDS ADDRESS OF INTER FILE RTN  09760015
*        ----------------------------------------------------AA 044-TSS 09800020
         DC    A(0)                                                     09840015
         DC    A(RLSCTLX)              SPECIAL ENTRY FOR OVERLAY        09920015
         DC    A(0)                    ROUTINE TO RECONST. INSTRS IN AL 10000015
         DC    A(DYNAMIC)                        DYNAMIC DUMP ROUTINE   10080015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 039-TSS 10120020
         DC    A(0)                    ADDR OF SECOND CONTROL PHASE     10160015
*        ----------------------------------------------------AA 039-TSS 10200020
         SPACE                                                          10240015
         EJECT                                                          10320015
         SPACE                                                          10400015
ZINIT    BALR  GRA,0                   GET PROGRAM MASK                 10480015
         ST    GRA,PMASK               AND RETAIN IT                    10560015
         LA    GRA,FSTSAV              POINT AT SAVE AREA               10640015
         ST    DICR,4(0,GRA)           CHAIN FORWARDS IN NEW SAVE ARE   10720015
         ST    GRA,8(0,DICR)           CHAIN BACKWARDS IN OS/360 SAVE   10800015
         LR    DICR,GRA                                                 10880015
         ST    GRA,KEEP                STORE ADDRESS OF THIS SAVE AREA  10960015
         SPACE                                                          11040015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 001-TSS 11090020
BATCH    STIMER TASK,TUINTVL=KTIME                                      11140015
         TIME  BIN                                                20221 11180001
         ST    GR0,KTIME2                                         20221 11220001
*        ----------------------------------------------------AA 001-TSS 11250020
         SPACE                                                          11280015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 002-TSS 11320020
         LINK  EP=IEMAB                                                 11360015
*        ----------------------------------------------------AA 002-TSS 11400020
         SPACE                                                          11440015
         SPACE                                                          11520015
         BC    B,HEREX(LR)             TEST RETURN FROM INIT PHASE      11600015
HEREX    BC    B,KILL                                                   11680015
         SPACE                                                          11760015
         L     DICR,DADDR              POINT AT DICTIONARY              11840015
         TM    CCCODE+2(DICR),X'40'    TEST IF CHECK SPECIFIED          11920015
         AIF   (NOT &STD).L1                                            11930021
         LA    DICR,SAVAR              PROVIDE S.A. TO SPIE MACROS.     11940021
.L1      ANOP                                                           11950021
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 003-TSS 11960020
         BC    BZ,CHKA                 BRANCH IF CHK SPECIFIED          12000015
         SPIE  PIH,((1,15))            WE HANDLE ALL PROGRAM CHECKS     12080015
ROPA     CLI   PICAD+3,X'01'      HAVE WE STORED EXTERNAL PICA    54704 12160021
         BNE   NCHK               ALREADY(BATCHING). DONT STORE   54704 12170021
         ST    1,PICAD            IT AGAIN IF SO.                 54704 12180021
*        ----------------------------------------------------AA 003-TSS 12200020
         SPACE                                                          12240015
NCHK     L     DICR,DADDR              POIMT AT DICTIONARY              12320015
         ST    CNTL,ZTV(0,DICR)        STORE CONTROL BASE               12400015
         SPACE                                                          12480015
         CLI   TERMSW(DICR),X'FF'      SEE IF COMPILER MUST BE KILLED   12560015
         BC    BNE,LODFST                                               12640015
         BAL   RR,ABORT                                                 12720015
         SPACE                                                          12800015
LODFST   LA    GR0,LODLST              POINT AT AM FOR LOADW            12880015
         ST    GR0,PAR1(0,DICR)                                         12960015
         BAL   RR,LOADW                LOAD FIRST PHASE                 13040015
         SPACE                                                          13120015
         L     LR,PAR1(0,DICR)         PICK UP LOAD POINT               13200015
         LA    LR,2(0,LR)              BUMP OVER PHASE ID               13280015
         BALR  RR,LR                   ENTER FIRST PHASE                13360015
         SPACE                                                          13440015
KILL     TM    NOCRSW,X'0F'  WAS THERE AN I/O ERR ON SYSPRINT AB PTM825 13480001
         BO    ZEND                                              PTM825 13520001
         LA    LR,16                   SHOW TERMINAL ERROR       PTM825 13560001
         BC    B,HADIT                                                  13600015
         SPACE                                                          13680015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 004-TSS 13720020
CHKA     SPIE  ,                       ALLOW ABENDS ON CALLED COMPLNS   13760015
         BC    B,ROPA                RUN WITH CHK                       13840015
*        ----------------------------------------------------AA 004-TSS 13880020
         EJECT                                                          13920015
*                                                                       14000015
*              INITIALISAYION LIST. THIS IS USED BY INITIALISER         14080015
*        TO REFERENCE LOCATIONS IN THE CONTROL PHASE . IT IS ALSO USED  14160015
*        BY OTHER OPTIONAL CONTROL ROUTINES (DUMP AND INTERMEDIATE      14240015
*        FILE)                                                          14320015
*                                                                       14400015
         DS    0D                                                       14480015
ADDLST   DC    A(0)    ALLOCA          WILL HOLD SCRATCH CORE           14560015
         DC    A(0)    ALLOCL                                           14640015
         DC    A(0)    TSLOTS+24                 TEXT AND               14720015
         DC    A(0)    DSLOTS+24                 DICT ALLOCATION SLOTS  14800015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 022-TSS 14840020
         DC    A(RDDCB)                READ AND PRINT DCB               14880015
         DC    A(PLDCB)                                                 14960015
*        ----------------------------------------------------AA 022-TSS 15000020
         DC    A(LOADL)                MODEL LOAD LIST                  15040015
         DC    A(PD)                   PHASE DIRECTORY                  15120015
         DC    A(0)    HEDING                    PAGE HEADING           15200015
         DC    A(0)    MAXPAG                    MAX PAGE COUNT         15280015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 023-TSS 15320020
         DC    A(SPDCB)                ADDRESS OF SPILL DCB             15360015
*        ----------------------------------------------------AA 023-TSS 15400020
         DC    A(DADDR)                ADDRESS OF SLOT WITH DICT ADDR.  15440015
ADLF     DC    A(LFDCB)                                            H229 15520001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 024-TSS 15560020
ADSYP    DC    A(SYPDCB)                                           H229 15600001
*        ----------------------------------------------------AA 024-TSS 15640020
         DC    A(CHK)                  ADDRESS OF INSTRUCTION TO DUMP   15680015
         DC    A(RDADD)                ADDR OF SLOT POINTING AT RDDCB   15760015
         DC    A(TAB1)                 TRANSLATE TABLE EXTERNAL TO INT  15840015
         DC    A(TAB3)                 INTERNAL TO EXTERNAL             15920015
         DC    A(ERRF14)                                                16000015
         DC    A(PLMES+3)                                               16080015
         DC    A(0)    PAGNO                     PAGE NUMBER            16160015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 020-TSS 16200020
         DC    A(SCNDLST)              LAST HALF                        16240015
*        ----------------------------------------------------AA 020-TSS 16280020
         DC    A(DYNSW)                          SWITCH FOR DYNAMIC     16320015
         DC    A(0)    NUMFRE                    NUMBER OF FREE TRACKS  16400015
         DC    A(0)    FRSLOT                    LIST OF FREE TRACKS    16480015
         DC    A(0)    BLKTBL                                           16560015
         DC    A(SPILL)                                                 16640015
         DC    A(0)    CONCNT                                           16720015
         SPACE                                                          16800015
KEEP     DS    F                                                        16880015
         DC    A(SYSUT3)               * A(ALT DDNAME FOR SYSUT3) 60069 16900072
         DS    0D                                                       16920015
KTIME    DC    A(1000000*30*60)                                         16960015
         DC    A(0)                                                     17000015
         DC    A(GENSW)                                                 17040015
         DC    A(0)    BTCHBUF                   BTCH CD FOR PARM SCAN  17120015
         DC    A(ERCSV)                                                 17200015
         DC    A(0)    UTIERR        ERROR RTN SYSUT1                   17280015
         DC    A(0)    ZURDAB        SYSIN EOF RTN                      17360015
         DC    A(SYSLIB)               * A(ALT DDNAME FOR SYSLIB) 60069 17365072
KTIME2   DS    D                                                  20221 17370001
         DC    A(ATADDR)               A(SLOT HOLDING A(IEMAT)).  IEMAT 17380001
         DC    A(INPIH)                ADDRESSES OF BRANCHS IN AA IEMAT 17390001
         DC    A(INRELS)               WHICH IEMAT WILL MAKE INTO IEMAT 17400001
         DC    A(INLOAD)               NOPS IF TRACING OR PATCHNG.IEMAT 17410001
         DC    A(CORSZE)               ADDR OF SLOT WITH CORE SIZEH207  17420001
         DC    A(AEABTSW)                                         H313  17425001
         DC    A(UT1BLK)               ADDR OF SLOT WITH SYSUT1   H319  17430001
*                                      'LENGTH TO WRITE'          H319  17435001
LODLST   DC    C'AMZZ'                 LIST TO GET MARKING PHASE        17440015
PICAD    DC    F'1'               EXT.PICA ADDR.   INIT EMPTY.    54704 17520021
PMASK    DS    F                                                        17600015
CORSZE   DC    F'0'                                               H207  17620001
UT1BLK   DC    H'0'                                               H319  17626001
AEABTSW  DC    X'00'                   AE ABORT SWITCH            H313  17632001
*              THE FOLLOWING SWITCHES ARE ACCESSED AS OFFSETS      H235 17640001
*                  FROM GENSW BY IEMAB/IEMAK                       H235 17660001
GENSW    DC    X'00'                                                    17680015
NOCRSW   DC    X'F0'              ON UNTIL COMM REGION AVAILABLE PTM825 17720001
BUFSW    DC    X'00'                   SET ON FOR LARGE SYSPRINT   H235 17730001
MESSW    DC    X'00'                   SHOWS SYSIN STATUS          H235 17740001
ERCSV    DC    X'00'                                                    17760015
SYSUT3   DC    C'SYSUT3  '             * ALT DDNAME SLOT          60069 17780072
SYSLIB   DC    X'0000000000000000'                                60069 17800072
         EJECT                                                          17840015
*                       TRANSLATE TABLES                                17920015
*                                                                       18000015
*              THESE ARE USED TO TRANSLATE EXTERNAL CODES (WHICH MAY    18080015
*        VARY EG. EBCDIC,BCD) INTO A FIXED FORMAT INTERNAL CODE. THE    18160015
*        REVERSE TABLE IS ALSO INCLUDED. THE TABLE ACTUALLY USED DEPEND 18240015
*        S UPON THE OPTION SPECIFIED AT INVOCATION TIME. IF BCD IS      18320015
*        SPECIFIED THEN THE BELOW TABLES ARE OVERWRITTEN BY AB. THE BCD 18400015
*        TRANSLATION TABLES ARE USED                                    18480015
*                                                                       18560015
*                                                                       18640015
*                       TRANSLATE TABLE EXTERNAL TO INTERNAL            18720015
*                                                                       18800015
TAB1     DC    XL16'4C4E505C5D5E5FF4616C6E0B0C0D0E0F'                   18880015
         DC    XL16'7C7A7D7EC1C2C3C4C5C61A1B1C1D1E1F'                   18960015
         DC    XL16'7BC7C8C9D1D2D3D4D5D62A2B2C2D2E2F'                   19040015
         DC    XL16'5B31D7D8D9E2E3E4E5E63A3B3C3D3E3F'                   19120015
         DC    XL16'40E7E8E944F0F147F249F3466F43754B'                   19200015
         DC    XL16'4D5152535455565758595A307945EF4F'                   19280015
         DC    XL16'737762636465666768696A414A0A6D60'                   19360015
         DC    XL16'707172F574F676F778F8482010426B7F'                   19440015
         DC    XL16'808182838485868788898A8B8C8D8E8F'                   19520015
         DC    XL16'909192939495969798999A9B9C9D9E9F'                   19600015
         DC    XL16'A0A1A2A3A4A5A6A7A8A9AAABACADAEAF'                   19680015
         DC    XL16'B0B1B2B3B4B5B6B7B8B9BABBBCBDBEBF'                   19760015
         DC    XL16'C0111213141516171819CACBCCCDCECF'                   19840015
         DC    XL16'D0212223242526272829DADBDCDDDEDF'                   19920015
         DC    XL16'E0E13233343536373839EAEBECEDEEF9'                   20000015
         DC    XL16'00010203040506070809FAFBFCFDFEFF'                   20080015
         EJECT                                                          20160015
*                                                                       20240015
*                       TRANSLATE TABLE INTERNAL TO EXTERNAL            20320015
*                                                                       20400015
TAB3     DC    XL16'F0F1F2F3F4F5F6F7F8F96D0B0C0D0E0F'                   20480015
         DC    XL16'7CC1C2C3C4C5C6C7C8C91A1B1C1D1E1F'                   20560015
         DC    XL16'7BD1D2D3D4D5D6D7D8D92A2B2C2D2E2F'                   20640015
         DC    XL16'5B31E2E3E4E5E6E7E8E93A3B3C3D3E3F'                   20720015
         DC    XL16'406B7D4D445D4B477A496C4F0050015F'                   20800015
         DC    XL16'025152535455565758595A3003040506'                   20880015
         DC    XL16'6F0862636465666768696A7E096E0A4C'                   20960015
         DC    XL16'70717260744E7661785C11201012137F'                   21040015
         DC    XL16'808182838485868788898A8B8C8D8E8F'                   21120015
         DC    XL16'909192939495969798999A9B9C9D9E9F'                   21200015
         DC    XL16'A0A1A2A3A4A5A6A7A8A9AAABACADAEAF'                   21280015
         DC    XL16'B0B1B2B3B4B5B6B7B8B9BABBBCBDBEBF'                   21360015
         DC    XL16'C0141516171819212223CACBCCCDCECF'                   21440015
         DC    XL16'D0242526272829323334DADBDCDDDEDF'                   21520015
         DC    XL16'E0E13536373839414243EAEBECEDEE5E'                   21600015
         DC    XL16'4546484A0773757779EFFAFBFCFDFEFF'                   21680015
         EJECT                                                          21840015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 005-TSS 21880020
SAVAR    DS    18F                     SAVE AREA FOR NEXT LEVEL ROUTINE 21920015
FSTSAV   DS    18F                                                      22000015
*        ----------------------------------------------------AA 005-TSS 22040020
DICTEM   DC    F'0'                                                     22080015
TEMP     DS    F                                                        22160015
TEMP4    DS    F                                                        22240015
SAVPAR   DS    F                                                        22320015
ZEROS    DC    XL4'00'                 PERMANENT ZEROS LOCATION         22400015
COUNT    DC    X'00'                                                    22480015
LOADAG   DC    X'00'                                                    22560015
CVNAM    DC    C'CV'                                                    22640015
XANAM    DC    C'XA'                                                    22720015
BMNAM    DC    C'BM'                                                    22800015
ASNAM    DC    C'AS'                                                    22880015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 030-TSS 22900020
*        ----------------------------------------------------AA 030-TSS 22920020
ABMESDC  DC    X'0014'                                                  22960015
         DC    C'-'                                                     23040015
         DC    C'IEM3855I ERROR IN '                                    23120015
ABMSDC1  DC    C'XY'                                                    23200015
         EJECT                                                          23280015
*        LOAD ROUTINES                                                  23360015
*                       THESE ROUTINES WILL LOAD PHASES AND PASS CONTRL 23440015
*        TO A NEW PHASE IF NECESSARY. INTERFACES WITH OPERATING SYSTEM  23520015
*        ARE LOAD AND DELETE.                                           23600015
*              THE VARIOUS ENTRY POINTS ARE                             23680015
*            1)RELESE. THIS WILL DELETE PHASES CONTAINED IN A PHASE     23760015
*        NAME LIST. THE NAME IS BUILT UP TO ITS FULL VALUE 'IEMXY   '   23840015
*        AND THE THE DELETE MACRO IS ISSUED. THIS OPERATION IS PERFORMD 23920015
*        FIRST IF RLSCTL IS ENTERED                                     24000015
*            2)RLSCTL. THIS WILL PERFORM A RELEASE AS DESCRIBED ABOVE   24080015
*        AND THEN PASS CONTROL TO THE PHASE POINTED AT BY PAR2. IF PAR2 24160015
*        IS ZERO THEN THE PHASE DIRECTORY IS SCANNED FOR THE NEXT       24240015
*        WANTED PHASE. THIS IS LOADED AND ENTERED                       24320015
*            3)LOADX. THIS IS A SPECIAL TYPE OF LOADW ENTRY.IT ALLOWS   24400015
*        PHASES TO BE LOADED SEVERAL TIMES. THE ONLY DIFFERENCE FROM    24480015
*        LOADW IS THAT THE RELATIVE TRACK ADDRESS IN THE DIRECTORY IS   24560015
*        NOT OVERWRITTEN WITH THE LOAD ADDRESS.                         24640015
*            4)LOADW. AN ENTRY WHICH CAUSES A NAMED PHASE TO BE LOADED. 24720015
*        THE ADDRESS OF THE LOAD POINT IS PLACED IN PAR1. CONTROL IS    24800015
*        RETURNED TO THE CALLER.                                        24880015
*            5)REQEST. AN ENTRY WHICH ALLOWS PHASES TO BE MARKED AS     24960015
*        WANTED AND NOT WANTED. PAR1 POINTS AT A LIST OF WANTED PHASES, 25040015
*        PAR2 POINTS TO A LIST OF UNWANTED PHASES.                      25120015
*              6)RLSCTLX. THIS IS A SPECIAL FORM OF RLSCTL.IT ALLOWS    25140001
*        PHASES  TO BE LOADED SEVERAL TIMES.THE RELATIVE TRK ADDR       25160001
*        IN THE PHASE DIRECTORY IS NOT OVERWRITTEN WITH THE LOAD ADDR.  25180001
*                                                                       25200015
*              PHASE LISTS CONSIST OF 2 BYTE PHASE NAMES (IE THE XY OF  25280015
*        IEMXY). THE LAST NAME IN THE LIST IS ZZ WHICH ACTS AS A STOPPR 25360015
*        00 CHARACTERS ARE TREATED AS A NULL ENTRY AND ARE IGNORED. THE 25440015
*        LISTS ARE POINTED AT BY PAR1 OR PAR2 DEPENDING UPON ENTRY      25520015
*        POINT                                                          25600015
*                                                                       25680015
*              A DESCRIPTION OF THE STATUS BYTE IN THE PHASE DIRECTORY  25760015
*        WOULD BE INSTRUCTIVE AT THIS POINT. IT IS INITIALLY ZERO       25840015
*            BIT 1    1 MEANS PHASE REQUESTED  0 NOT REQUESTED          25920015
*                2    1             LOADED                              26000015
*                3    1             LOADING                             26080015
*                4    1             ACTIVATED (EITHER ENTERED DIRECTLY  26160015
*                                               OR BY A LOADW)          26240015
*                5    1             DELETED                             26320015
*                6    1       DUMP CAN TAKE PLACE ON THIS PHASE         26400015
*                7    1       PHASE NOT WANTED                          26480015
*                8    1       DUMP REQUIRED AT END OF PHASE             26560015
*              THE MOST COMMON STATES OF THE BYTE ARE THUS              26640015
*            X'80'  REQUESTED,NOT LOADED                                26720015
*            X'02'  NOT WANTED                                          26800015
*            X'A0'  LOADING- IF THIS APPEARS IN A DUMP WITH A LOAD      26880015
*                   ABEND THEN IT IS AN ERROR THAT OCCURRED WHILE TRYNG 26960015
*                   TO LOAD THIS PHASE. CHECK THE COMPILER LIBRARY FOR  27040015
*                   ITS PRESENCE                                        27120015
*            X'F4'  LOADED AND ACTIVATED                                27200015
*            X'FC'  DELETED                                             27280015
*                                                                       27360015
*              SEE PHASE IEMAB FOR A DESCRIPTION OF THE PHASE DIRECTORY 27440015
*        BRIEFLY EACH ENTRY IS 12 BYTES LONG. PHASE NAME BYTES 1-2,     27520015
*        STATUS BYTE 3                                                  27600015
*                                                                       27680015
*              UPON ENTRY TO THE ROUTINE A CHECK IS MADE TO SEE IF A    27760015
*        DUMP REQUEST HAS BEEN MADE. IF YES AND IT IS A RLSCTL ENTRY    27840015
*        THEN THE DUMPING ROUTINES ARE ENTERED. PHASE IEMAD IS LOADED   27920015
*        AND ENTERED. THIS PHASE WILL DUMP THE PARTS OF CORE BEING USED 28000015
*        BY THE COMPILER.                                               28100001
*                                                                       28240015
*              A SPECIAL CASE EXISTS WHEN THE COMPILER IS RUNNING AT    28320015
*        THE MINIMUM DESIGN POINT. READIN AND THE 48-CHARACTER SET WILL 28400015
*        USE ONLY 2 TEXT AND 2 DICTIONARY BLOCKS. WHEN READIN TERMINATE 28480015
*        THEN THE BLOCKS HAVE TO BE EXPANDED TO 4 OF EACH. SYSIN OR     28560015
*        SYSUT3 CAN ALSO BE CLOSED. SYSPUNCH AND SYLIN WILL BE OPENED.  28640015
*        ON ANYTHING. IEMAE IS LOADED AND                               28720015
*        ALL THE ABOVE MENTIONED OPERATIONS ARE PERFORMED BY IEMAE. THE 28800015
*        PHASE IEMAE IS LINKED TO IN ORDER TO GET IT INTO LOW CORE AND  28880015
*        TRY TO REDUCE FRAGMENTATION OF CORE. IT IS ONLY ENTERED ONCE   28960015
*                                                                       29040015
*              WHEN A PHASE IS TO BE LOADED, THE ELEMENTS IN THE PHASE  29120015
*        DIRECTORY ARE INSERTED INTO A MODEL LOAD LIST. THIS MODEL IS   29200015
*        INSERTED IN THE CONTROL PHASE BY AB. IT IS ONE OF THE LOAD     29280015
*        LISTS GENERATED BY THE BLDL. A SPECIAL CASE EXISTS WHEN A      29360015
*        PHASE HAS MORE THAN ONE TEXT RECORD IN ITS LOAD MODULE. THE    29440015
*        RELEVANT BIT IS SET. A DS OR AN ORG AT THE END OF A PHASE CAN  29520015
*        CAUSE PROBLEMS AND PREVENT LOADING. IF THE STATUS BYTE IS AT   29600015
*        X'A0' AND AN ERROR HAS OCCURRED THE CHECK THE LAST FEW INSTRTN 29680015
*        OF THE RELEVANT PHASE FIRST                                    29760015
         SPACE 2                                                        29840015
RELESE   MVI   COUNT,X'01'             COUNT INDICATES ENTRY TYPE. IT   29920015
         BC    B,LODON               MUST BE CONTAIND IN FIRST 4K BLOCK 30160015
RLSCTLX  MVI   LOADAG,X'FF'            SPECIAL ENTRY FOR OVERLAY        30240015
RLSCTL   MVI   COUNT,X'02'           OF CODE.                           30320015
         BC    B,LODON                                                  30560015
LOADX    MVI   LOADAG,X'FF'            SHOW IS SPECIAL LOADW ENTRY      30640015
LOADW    MVI   COUNT,X'04'                                              30720015
         BC    B,LODON                                                  30960015
REQEST   MVI   COUNT,X'08'                                              31040015
         SPACE                                                          31280015
LODON    STM   14,CNTL2,12(DICR)       STORE OLD REGS                   31330001
         LA    GRA,SAVAR               POINT AT NEW SAVE AREA           31380001
         ST    DICR,4(0,GRA)           CHAIN FORWARDS                   31440015
         L     DICR,DADDR              POINT AT TRUE DICTIONARY         31520015
         SPACE                                                          31600015
         CLI   SCNOF(DICR),X'FF'       SEE IF INITIALISE AT START OF PD 31680015
         BC    BE,BRCHZ                                                 31760015
         MVI   SCNOF(DICR),X'FF'       SHOW INIT COMPLET                31840015
         L     GRA,PAROF(CNTL)         POINT AT INIT LIST               31920015
         L     GRA,PDOF(GRA)           HENCE AT PHASE DIRECTORY         32000015
         ST    GRA,SCNPNT              POINT AT START OF PD             32080015
         SPACE                                                          32160015
BRCHZ    TM    COUNT,X'02'             TEST FOR A RLSCTL                32240015
         BC    BZ,NODUMP                                                32320015
         SPACE                                                          32400015
         TM    CCCODE(DICR),X'80'      TEST IF DUMP REQUIRED            32480015
         BC    BZ,NODUMP                                                32560015
         SPACE                                                          32640015
         LA    DICR,ABSAV              POINT AT FREE SAVE AREA          32720015
ENTERS   L     LR,ZUST(0,CNTL)         PICK UP ADDR OF DUMP ROUTINE     32800015
         BALR  RR,LR                   GO TO DUMPING                    32880015
         L     DICR,DADDR              POINT AT DICTIONARY              32960015
         SPACE                                                          33040015
NODUMP   LM    GRB,GRC,PAR1(DICR)      PICK UP PARMS.             31173 33070021
         TM    COUNT,X'08'             IS IT A REQUEST REQUEST?   31173 33100021
         BO    TRYREQ                  YES                        31173 33130021
         TM    COUNT,X'03'             IS IT A LOAD REQUEST?      31173 33160021
         BZ    TRYLDW                  YES - NO RELEASE           31173 33190021
         MVC   RELST,0(GRB)            COPY RELEASE LIST          31173 33220021
         TM    COUNT,X'01'             WAS THIS A RELESE CALL?    31173 33228021
         BO    RELSCN                YES - NO LOAD LIST.          31173 33236021
         LTR   GRD,GRC               SAVE ORIGINAL ADDR(LOADLIST) 31173 33244021
         BZ    RELSCN                IF ZERO, NO LIST FROM RLSCTL 31173 33252021
         MVC   LOADLST,0(GRD)          COPY LOAD LIST.            31173 33260021
RELSCN   EQU   *                                                  31173 33268021
         LA    GRC,RELST               POINT AT COPY              31173 33280021
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 006-TSS 33380020
*        ----------------------------------------------------AA 006-TSS 33400020
         L     GRB,PAROF(CNTL)         POINT AT INIT LIST               33440015
         L     GRB,PDOF(GRB)           HENCE AT PHASE DIRECTORY         33520015
         SPACE                                                          33600015
SEZD     CLC   0(2,GRC),ZEDS                                            33680015
         BC    BE,ENDRLS                                                33760015
         CLC   0(2,GRC),ZCHARS         SEE IF SIGNIFICANT ENTRY         33840015
         BC    BE,RLSAGN                                                33920015
         SPACE                                                          34000015
RLSLOP   CLC   0(2,GRC),0(GRB)         SEE IF NAME IN LIST IS THE NAME  34080015
         BC    BE,RLSTHS             IN THE PHASE DIRECTORY             34160015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 031-TSS 34200020
         LA    GRB,12(0,GRB)           BUMP TO NEXT IN PHASE DIRECTORY  34240015
*        ----------------------------------------------------AA 031-TSS 34280020
         CLI   0(GRB),X'00'            TEST FOR END OF PHASE DIRECTORY  34320015
         BC    BNE,RLSLOP                                               34400015
         SPACE                                                          34480015
         MVC   PAR6+1(3,DICR),ERR9     NAME IN RELEASE LIST NOT IN PD   34560015
         LR    GRB,GRC                 SET REGISTERS TO MAKE CORRECT    34640015
         BC    B,NOTDIR              ERROR MESSAGE ENTRY                34720015
         SPACE                                                          34800015
RLSTHS   OI    STAT(GRB),X'FC'         MARK AS RELEASED                 34880015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 007-TSS 34920020
         MVC   DELST+3(2),0(GRC)       INSERT NAME OF PHASE TO BE       34960015
         LA    DICR,SAVAR            DELETED. POINT AT SAVE AREA        35040015
         LA    0,DELST                 POINT AT DELETE LIST             35120015
         SPACE                                                          35200015
       DELETE  EPLOC=(0)               DELETE PHASE AS REQUIRED         35280015
*        ----------------------------------------------------AA 007-TSS 35284020
         SPACE 1                                                        35288001
INRELS   B     NOTRACE3                MADE NOP BY AT IF TRACING. IEMAT 35296001
         STM   14,15,STORE2            SAVE R14 & R15.            IEMAT 35304001
         L     15,ATADDR               POINT R15 AT IEMAT.        IEMAT 35312001
         BAL   14,TRACRELS(0,15)       LINK TO TRACRELS IN IEMAT. IEMAT 35320001
         LM    14,15,STORE2            RESTORE R14 & R15.         IEMAT 35328001
NOTRACE3 EQU   *                                                  IEMAT 35336001
         SPACE 1                                                        35344001
         SPACE                                                          35360015
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN        35440015
RLSAGN   LA    GRC,2(0,GRC)            BUMP TO NEXT IN RELESE LIST      35520015
         BC    B,SEZD                                                   35600015
         SPACE                                                          35680015
ENDRLS   EQU   *                                                        35740021
         TM    COUNT,X'01'             TEST FOR RELESE ONLY       31173 35800021
         BZ    TRYCTL                  GO TO CONTROL OF INPUT FILES     35860001
         B     RETRTN                  RETURN TO CALLER                 35960001
         SPACE                                                          36080015
         EJECT                                                          36400015
*              THESE INSTRUCTIONS CONTROL THE ALLOCATIONS OF DCB'S TO   36480015
*        THE INTERMEDIATE FILES. DCBS ARE SWITCHED DYNAMICALLY SO THAT  36560015
*        THE ZURD ROUTINE NEED HAVE NO KNOWLEDGE OF THE FILE BEING      36640015
*        CURRENTLY READ                                                 36720015
         SPACE 2                                                        36800015
         SPACE                                                          36880015
TRYCTL   BC    NOP,TRYLOD  ***** THIS IS SWITCHED *****                 36960001
*        THIS ROUTINE IS ONLY ENTERED FOR RLSCTL AND RLSCTLX            37040001
*        AND ONLY WHEN THE INPUT PHASES ARE ACTIVE.                     37120001
         CLC   MYNAM(2,DICR),ASNAM     IS IT AS RLSCTLING               37200015
         BC    BE,LOADAE             IF YES LINK TO AE                  37280015
         CLC   MYNAM(2,DICR),CVNAM     IS IT CV RLSCTLING               37360015
         BC    BE,LOADAE             IF YES LINK TO AE                  37440015
         TM    CCCODE(DICR),X'40'      HAS ABORT OCCURRED               37520015
         BC    BZ,TRYLOD              IF NOT OMIT AE                    37600015
         CLI   MYNAM(DICR),X'C3'     IF YES IS IT IN READ IN            37680015
         BC    BNE,TRYLOD            IF NOT OMIT AE                     37760015
         SPACE                                                          37840015
LOADAE   LA    DICR,ABSAV              LOAD AE                          37940001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 008-TSS 38040020
         LINK  EP=IEMAE                LOAD TEXT AND DICTIONARY CONTROL 38160015
*        ----------------------------------------------------AA 008-TSS 38200020
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN  33893 38220020
         BC    B,AEABORT(LR)           TEST IF AE WISHES TO ABORT CMPLR 38240015
AEABORT  BAL   RR,ABORT                                                 38320015
         CLC   MYNAM(2,DICR),ASNAM                                      38480015
         BC    BE,TRYLOD                                                38560015
         MVI   TRYCTL+1,X'F0'  ***** SET CODE SWITCH TO BYPASS *****    38640001
         BC    B,TRYLOD                                                 38720015
         EJECT                                                          38800015
*              THESE INSTRUCTIONS LOAD THE REQUIRED PHASE. CONTROL IS   38880015
*        PASSED TO THE REQUIRED PHASE IF NECESSARY. IT IS ONLY ENTERED  38960015
*        BY A LOADW,LOADX(TO TRYLDW);RLSCTL,RLSCTLX(TO TRYLOD) ENTRY.   39040001
         SPACE 2                                                        39120015
TRYLOD   EQU   *                                                  31173 39320021
         L     GRC,SCNPNT              PHASE DIR CURRENT POSITION.      39520001
         CLI   ZDROLF(DICR),X'FF'      SEE IF IN OVERLAY                39720001
         BNE   NOLIFT                                                   39920001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 032-TSS 40020020
         LA    GRC,12(0,GRC)                                            40120001
*        ----------------------------------------------------AA 032-TSS 40220020
NOLIFT   LTR   GRB,GRD                 PUT PAR2 IN GRB            31173 40300021
         BZ    NOLOP                   NO LOAD LIST               31173 40380021
         LA    GRB,LOADLST             POINT AT COPY              31173 40540021
         B     NAMED                                              31173 40620021
NOLOP    TM    STAT(GRC),X'08'         SEE IF PHASE HAS BEEN DELETED    40720015
         BC    BO,PHDEL                                                 40800015
         TM    STAT(GRC),X'80'         SEE IF REQUESTED                 40880015
         BC    BO,LOAD               LOAD IT                            40960015
         TM    STAT(GRC),X'02'         TEST IF NOT WANTED               41040015
         BC    BZ,LOAD                                                  41120015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 033-TSS 41160020
PHDEL    LA    GRC,12(0,GRC)           BUMP TO NEXT IN PHASE DIRECTORY  41200015
*        ----------------------------------------------------AA 033-TSS 41240020
         BC    B,NOLOP                                                  41280015
         SPACE                                                          41360015
TRYLDW   L     GRB,PAR1(0,DICR)        POINT AT LIST GIVEN BY PAR1      41380001
         L     GRC,SCNPNT                                               41400001
NAMED    CLC   0(2,GRB),0(GRC)         SEE IF IT IS REQUIRED PHASE      41440015
         BC    BE,LOAD                                                  41520015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 034-TSS 41560020
         LA    GRC,12(0,GRC)           BUMP TO NEXT IN PHASE DIRECTORY  41600015
*        ----------------------------------------------------AA 034-TSS 41640020
         CLI   0(GRC),X'00'            TEST FOR END OF DIRECTORY        41680015
         BC    BNE,NAMED                                                41760015
         SPACE                                                          41840015
         MVC   PAR6+1(3,DICR),ERR10    PHASE NOT IN PHASE DIRECTORY     41920015
NOTDIR   ST    GRB,PAR7(0,DICR)        POINT AT NAME OF PHASE           42000015
         TM    CCCODE+3(DICR),X'10'    IF MACRO RUNNING,NAME REQUIRED   42080015
         BC    BO,NOTR1              IN EBCDIC                          42160015
         TR    0(2,GRB),TAB1           TRANSLATE TO INTERNAL CODE       42240015
NOTR1    EQU   *                                                        42320015
         LA    GRA,2                                                    42400015
         ST    GRA,PAR8(0,DICR)        SHOW PHASE NAME IS 2 LONG        42480015
         BAL   RR,DYNAMIC                                               42560015
         SPACE                                                          42640015
LOAD     OI    STAT(GRC),X'A0'         MARK AS REQUESTED AND LOADING    42720015
         NI    STAT(GRC),X'F3'         SET DELETE AND DUMP BITS OFF     42800001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 009-TSS 42840020
*                (FOR PHASES LOADED MORE THAN ONCE)                     42880015
         MVC   LOADL+3(2),0(GRC)       MOVE IN NAME                     42960015
         MVC   CONCAT(2),CNBR(GRC)     MOVE IN CONCAT NUMBER AND LIB ID 43040015
         MVC   TTRFTR(3),FTR(GRC)      MOVE IN TTR OF FIRST TEXT RECORD 43120015
         MVC   TOTCOR+1(4),CONTIG(GRC) CONTIGUOUS REQUIRED CORE         43200015
         NI    TOTCOR-2,X'FE'          SET TEXT RECOED BIT OFF          43280015
         CLC   CONTIG(2,GRC),CONTIG+2(GRC) SEE IF ONLY ONE TXET RECORD  43360015
         BC    BNE,PONTLD                                               43440015
         OI    TOTCOR-2,X'01'          INDICATE ONLY 1 TEXT RCD.  47664 43520056
         SPACE                                                          43600015
PONTLD   LA    0,LOADL                 POINT AT LOAD LIST               43680015
         LA    DICR,SAVAR              POINT AT SAVE AREA               43760015
         SPACE                                                          43840015
         LOAD DE=(0)                   LOAD REQUIRED PHASE              43920015
*        ----------------------------------------------------AA 009-TSS 43960020
         SPACE                                                          44000015
         OI    STAT(GRC),X'50'         MARK AS LOADED AND ACTIVE        44050001
         L     DICR,DADDR              POINT AT D0 AGAIN                44100001
         ST    0,PAR1(0,DICR)          STORE LOAD ADDR                  44150001
         SPACE                                                          44200001
INLOAD   B     NOTRACE4                MADE NOP BY AT IF TRACING. IEMAT 44250001
         STM   14,15,STORE2            SAVE R14 & R15.            IEMAT 44300001
         LA    DICR,SAVAR              POINT R13 AT SAVE AREA.    IEMAT 44350001
         L     15,ATADDR               POINT R15 AT IEMAT.        IEMAT 44400001
         BAL   14,TRACLOAD(0,15)       LINK TO LOAD IN IEMAT.     IEMAT 44450001
         L     DICR,DADDR              POINT R13 AT DICT. AGAIN.  IEMAT 44500001
         LM    14,15,STORE2            RESTORE R14 & R15.         IEMAT 44550001
NOTRACE4 EQU   *                                                  IEMAT 44600001
         SPACE 1                                                        44650001
         CLI   LOADAG,X'FF'            SEE IF OVERLAY ENTRY             44700001
         BE    NOBUMP                                                   44750001
         OI    STAT(GRC),X'04'         MARK AS DUMPABLE                 44800001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 035-TSS 44820020
         ST    0,TEMP                  MOVE ADDR OF PHASE               44850001
         MVC   FTR(3,GRC),TEMP+1         INTO PHASE DIRECTORY           44900001
*        ----------------------------------------------------AA 035-TSS 44930020
         CLI   ZDROLF(DICR),X'FF'      SEE IF OVERLAY WITH RLSCTL IS    44960015
         BC    BE,NOBUMP             REQUIRED                           45040015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 036-TSS 45080020
         LA    GRC,12(0,GRC)           BUMP TO ONE AFTER LAST LOADED    45120015
*        ----------------------------------------------------AA 036-TSS 45160020
         ST    GRC,SCNPNT                                               45200015
         SPACE                                                          45280015
NOBUMP   MVI   LOADAG,X'00'            RESET LOAD TYPE FOR NEXT ENTRY   45360015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 045-TSS 45380020
*        ----------------------------------------------------AA 045-TSS 45400020
         AIF   (NOT &STD).L2                                            45402021
         LA    DICR,SAVAR              PROVIDE S.A. TO TTIMER.          45404021
.L2      ANOP                                                           45406021
         TTIMER                                                         45410046
         AIF   (NOT &STD).L3                                            45412021
         L     DICR,DADDR              POINT AT DICT AGAIN.             45414021
.L3      ANOP                                                           45416021
         ST    0,ZTIM(0,DICR)          SAVE IT FOR PHASE DUMP           45420046
         TM    COUNT,X'04'             TEST FOR A LOADW ENTRY           45440015
         BC    BO,RETRTN     IF SO,BRANCH TO RETURNING ROUTINE          45520015
         SPACE                                                          45600015
         LM    14,CNTL2,12(DICR)       RELOAD REGISTERS                 45680015
         MVI   12(DICR),X'FF'          SHOW RETURN IS COMPLETE          45760015
         XC    LOCK(2,DICR),LOCK(DICR) CLEAR LOCK SLOT FOR NEXT PHASE   45840015
         XC    ZSTAT(4,DICR),ZSTAT(DICR) SET STMNT NUMBER TO ZERO       45920015
         XC    PAR3(4,DICR),PAR3(DICR) CLEAR ANY UNWANTED SECOND HEADRS 46000015
         L     RR,PAR1(0,DICR)         PICK UP RETURN ADDRESS           46080015
         LA    RR,2(0,RR)              BUMP TO GIVE STANDARD ENTRY PONT 46160015
         BCR   BR,RR                                                    46240015
         EJECT                                                          46320015
*              THESE INSTRUCTIONS MARK PHASES AS REQUESTED. PHASES MUST 46400015
*        BE REQUESTED IN THE ORDER THAT THEY APPEAR IN THE PHASE        46480015
*        DIRECTORY.                                                     46560015
         SPACE 2                                                        46640015
TRYREQ   MVI   SWACH+1,X'00'           MAKE SWITCH ON, EFFECTIVELY      46720015
         MVI   RQSWCH,X'00'            SHOW IS SCANNING FIRST LIST      46800015
         MVI   SET+1,X'80'             SET TO MARK PHASES AS REQUESTED  46880015
         L     GRB,PAR1(0,DICR)        PICK UP START OF REQUEST LIST    46960015
         MVC   SAVPAR(4),PAR2(DICR)    SAVE PAR2 FOR ENTRY TO ZUERR     47040015
         SPACE                                                          47120015
REQLOP   CLC   0(2,GRB),ZEDS           IS IT END OF LIST                47200015
         BC    BE,SWACH                                                 47280015
         CLC   0(2,GRB),ZCHARS         IGNORE THIS ENTRY                47360015
         BC    BE,JUMP                                                  47440015
         SPACE                                                          47520015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 042-TSS 47560020
         CLI   RQSWCH,X'00'            SEE IF IT IS IN SECOND LIST      47600015
         BC    BNE,SECSCAN                                              47680015
*        ----------------------------------------------------AA 042-TSS 47720020
         SPACE                                                          47760015
OFFAGN   L     GRA,SCNPNT              INIT SCAN AT LAST ENTERED        47840015
         SPACE                                                          47920015
RQLOP1   CLC   0(2,GRB),0(GRA)         NAME IN PHASE DIRECTORY          48000015
         BC    BE,SET                                                   48080015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 037-TSS 48120020
         LA    GRA,12(0,GRA)           BUMP TO NEXT IN PHASE DIRECTORY  48160015
*        ----------------------------------------------------AA 037-TSS 48200020
         CLI   0(GRA),X'00'            TEST IF END OF PHASE DIRECTORY   48240015
         BC    BNE,RQLOP1                                               48320015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 038-TSS 48360020
         SPACE                                                          48400015
SECSCAN  L     GRA,SCOF+ADDLST                                          48480015
         MVI   RQSWCH,X'FF'                                             48560015
         SPACE                                                          48640015
RQLOP2   CLC   0(2,GRB),0(GRA)         SEE IF REQUESTED OR NOT WANTED   48720015
         BC    BE,SET                PHASE IS IN SECOND LIST            48800015
         LA    GRA,3(0,GRA)            BUMP TO NEXT IN SECOND LIST      48880015
         CLI   0(GRA),X'00'            SEE IF IT IS END OF LIST         48960015
         BC    BNE,RQLOP2                                               49040015
*        ----------------------------------------------------AA 038-TSS 49080020
         SPACE                                                          49120015
         MVC   PAR6+1(3,DICR),ERR12    PHASE NOT IN DIRECTORY           49200015
         LA    GRC,0(0,GRB)            POINT AT NAME OF PHASE           49280015
         ST    GRC,PAR7(0,DICR)                                         49360015
         LA    GRA,2                   FIX LENGTH OF NAME               49760015
         ST    GRA,PAR8(0,DICR)                                         49840015
         BAL   RR,DYNAMIC              TERMINATE COMPILATION            50240021
         SPACE                                                          50720015
SET      OI    2(GRA),X'00'            MARK PHASE AS REQUESTED OR NOT   50800015
JUMP     LA    GRB,2(0,GRB)          WANTED. BUMP TO NEXT IN LIST       50880015
         BC    B,REQLOP                                                 50960015
         SPACE                                                          51040015
SWACH    BC    NOP,RETRTN    ON 2ND TIME THRU',BRANCH TO RETURN ROUTINE 51120015
         MVI   SWACH+1,X'F0'                                            51200015
         MVI   SET+1,X'02'             SET TO MARK AS NOT WANTED        51280015
         MVI   RQSWCH,X'00'            POINT AT FIRST LIST AGAIN        51360015
         L     GRB,SAVPAR              POINT AT NOT-WANT LIST           51440015
         BC    B,REQLOP                                                 51520015
         EJECT                                                          51600015
ONE      DC    X'001F'                 * CARD COUNT INCREMENT     57455 51680072
*        ROUTINES ZULF AND ZUSP                                         51840015
*                       THESE ROUTINES PRODUCE CARD IMAGES OF THE       51920015
*        COMPILED OBJECT DECK. THE DDNAMES OF THE FILES ARE SYSPUNCH    52000015
*        AND SYSLIN. LOCATION COUNT MUST APPEAR IN THE FIRST 4K OF CODE 52080015
*              IF PERMANENT I/O ERROR OCCURS ON THE RELEVANT FILE THEN  52160015
*        A MESSAGE IS INSERTED IN THE DICTIONARY AND THE OPTION BIT SET 52240015
*        TO NOLOAD OR NODECK. THE I/O IS THEN BYPASSED ON THE NEXT      52320015
*        ENTRY.                                                         52400015
*              THE OUTPUT RECORDS ARE NUMBERED SEQUENTIALLY AND NAMED   52480015
*        WITH THE FIRST EXTERNAL PROCEDURE NAME. THIS WILL BE FOUND IN  52560015
*        ZPRNAM IN THE COMMUNICATIONS REGION OF THE DICTIONARY          52640015
         SPACE 2                                                        52720015
ZULF     EQU   *                                                        52800072
         STM   14,CNTL2,12(DICR)       * SAVE CALLERS REGS        57455 52840072
         L     GRA,ADLF                * POINT GRA AT SYSLIN      57455 52880072
         B     ZULFSP                                             57455 52920072
         SPACE 1                                                        52960072
ZUSP     EQU   *                                                        53000072
         STM   14,CNTL2,12(DICR)       * SAVE CALLERS REGS        57455 53040072
         L     GRA,ADSYP               * POINT GRA AT SYSPUNCH    57455 53080072
         SPACE 1                                                        53120072
ZULFSP   LA    GRB,SAVAR               * POINT AT NEW SAVE AREA   57455 53160072
         ST    DICR,4(0,GRB)           CHAIN FORWARDS                   53200015
         ST    GRB,8(0,DICR)           CHAIN BACKWARDS                  53280015
PUTLS    LR    DICR,GRB                                                 54400015
         PUT   (1)                     FIND BUFFER SPACE                54480015
         SPACE                                                          54560015
OUTBCK   L     DICR,DADDR              POINT AT DICT AGAIN              54640015
         L     GRB,PAR1(0,DICR)        PICK UP ADDRESS OF OUTPUT AREA   54720015
         TM    CCCODE+3(DICR),X'10'    * IS THIS A MACDCK CALL    57455 54740072
         BO    MCD                     * YES, EXIT                57455 54770072
         MVC   0(76,GRA),0(GRB)        INSERT TEXT                      54800015
         TM    CCCODE(DICR),X'18'      SEE IF BOTH LOAD AND PUNCH       54880015
LFBR     BC    NOP,NOADD               * FLIPPED BY NOADD         57455 54960072
         AP    CARNO(3),ONE(2)         * INCREMENT THE CARD COUNT 57455 55050072
NOADD    XI    LFBR+1,X'80'            * NOP -> BZ ; BZ -> NOP    57455 55140072
         UNPK  75(5,GRA),CARNO(3)      * INSERT SEQUENCE          57455 55230072
         OI    79(GRA),X'F0'           * NUMBER AND IDENTIFICATION 7455 55320072
         MVC   72(4,GRA),ZPRNAM(DICR)  * INTO CARD I/O AREA       57455 55410072
         SPACE                                                          55600015
NOFLE    L     DICR,DADDR              POINT AT DICTIONARY              55680015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      55760015
         SPACE                                                          55840015
MCD      MVC   0(80,GRA),0(GRB)        * CARD TO I/O BUFFER       57455 55920072
         B     NOFLE                   * PICK UP COMMON EXIT CODE 57455 56000072
         EJECT                                                          56080015
*              THESE INSTRUCTIONS DEAL WITH THE I/O ERRORS AS THEY      56160015
*        OCCUR. THE ERRORS ARE DEALT WITH AS FOLLOWS                    56240015
*              1)SYSPLIN. THE ERROR RECORD IS PRINTED OUT ON SYSPRINT   56320015
*        AND A MESSAGE IS INSERTED INTO THE DICTIONARY. THE RECORD IS   56400015
*        ACCEPTED.                                                      56480015
*              2)SYSLIN. ERROR MESSAGE INSERTED IN DICTIONARY AND       56560015
*        GENERATION OF LOAD FILE IS TERMINATED. COMPILATION CONTINUES   56640015
*              3)SYSPRINT. A WTO IS PERFORMED AND THE COMPILATION IS    56720015
*        TERMINATED WITH TERMINAL ERROR CODE                            56800015
*              4)SYSPUNCH.ERROR MESSAGE INSERTED IN DICTIONARY.         56880015
*        GENERATION OF PUNCHED DECK IS TERMINATED                       56960015
*              5)SYSUT1. MESSAGE APPEARS ON SYSPRINT. THE ERROR HANDLNG 57040015
*        TAKES PLACE IN THE SPILL MECHANISM. THE ERROR CAN APPEAR BOTH  57120015
*        FROM BSAM(WRITE) AND XDAP(READ,WRITE)                          57200015
*              6)SYSUT3. OPERATION DEPENDS UPON WHETHER INPUT OR OUTPUT 57280015
*        ERROR. OUTPUT- CAUSES PRINT OF MESSAGE AND COMPILER TERMIATED. 57360015
*        INPUT-RECORD IS PRINTED OUT AND MESSAGE INSERTED INTO DICT.    57440015
*        BLOCK IS ACCEPTED.                                             57520015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 010-TSS 57560020
         SPACE 2                                                        57600015
LFERRX   STM   RR,10,LASSAV            SAVE ALL REGISTERS               57680015
         L     DICR,DADDR              POINT AT DICTIONARY              57760015
         MVI   IOERSW(DICR),X'FF'      SHOW I/O ERROR                   57840015
         MVC   PAR6+1(3,DICR),ERRF15   INSERT MSG NUMBER            H64 57920016
         OI    CCCODE(DICR),X'10'      SHOW LOAD FILE NO LONGER RQD     58000015
ENTERR   LA    DICR,ABSAV              POINT AT NEW SAVE AREA           58080015
         L     LR,ZUEROF(CNTL)                                          58160015
         BALR  RR,LR                 BRANCH TO ZUERR                    58240015
         LM    RR,10,LASSAV            RESTORE ALL REGISTERS            58320015
         B     NOFLE                   * PICK UP COMMON EXIT CODE 57455 58400072
         SPACE                                                          58480015
SPERRX   STM   RR,10,LASSAV            SAVE ALL REGISTERS               58560015
         L     DICR,DADDR                                               58640015
         MVI   IOERSW(DICR),X'FF'      SHOW I/O ERROR                   58720015
         MVC   PAR6+1(3,DICR),ERRF17   SHOW ERROR ON PUNCH              58800015
         OI    CCCODE(DICR),X'08'      SYSPUNCH CANNOT CONTINUE         58880015
         OI    CCCODE+3(DICR),X'40'    * SET OFF MACDCK OPTION    57455 58920072
         BC    B,ENTERR                                                 58960015
         EJECT                                                          59040001
PLERRX   SYNADAF ACSMETH=QSAM          GET A SAVE AREA FOR WTO   PTM825 59060001
         LR    GRC,GRA                 SAVE GRA UNTIL WTO FINISH   H229 59065001
         MVC   8(16,GRC),M3862A        SET UP IEM3862I MESSAGE     H229 59070001
         MVC   24(56,GRC),49(GRC)          & ERROR TYPE            H229 59075001
         MVC   6(2,GRC),MCSFLGS        PICK UP MCS FLAGS           H229 59080001
         MVC   80(4,GRC),DESCRTCD      & DESCRIPTOR & ROUTING CODESH229 59085001
         LA    GRA,76                  SET LENGTH OF LIST          H229 59090001
         STH   GRA,4(GRC)                                          H229 59095001
         LA    GRA,4(GRC)              POINT AT LIST               H229 59100001
         WTO   ,MF=(E,(1))             ISSUE  MESSAGE              H229 59105001
         MVC   17(5,GRC),M3862B        SET UP REST OF MESSAGE      H229 59110001
         MVC   22(23,GRC),105(GRC)                                 H229 59115001
         MVC   45(4,GRC),DESCRTCD      & DESCRIPTOR & ROUTING CODESH229 59120001
         LA    GRA,41                  SET LENGTH OF LIST          H229 59125001
         STH   GRA,4(GRC)                                          H229 59130001
         LA    GRA,4(GRC)              POINT AT LIST               H229 59135001
         WTO   ,MF=(E,(1))             ISSUE  MESSAGE              H229 59140001
         LR    GRA,GRC                 RESTORE MSG POINTER         H229 59145001
         SYNADRLS                                                PTM825 59160001
         L     DICR,DADDR                                               59200015
         MVI   IOERSW(DICR),X'FF'      SHOW I/O ERROR                   59280015
         LA    GR0,16                                                   59360015
         ST    GR0,ERCODE(0,DICR)      SHOW TERMINAL                    59440015
         MVI   PERRSW(DICR),X'FF'      APPLY SWITCH FOR USE IN IEMAK    59520015
         BC    B,ZEND                                                   59600015
*        ----------------------------------------------------AA 010-TSS 59640020
*                                                                       59680015
*              THIS IS THE SYNAD TAKEN BY THE INPUT DCB. THE RECORD IN  59760015
*        THE BUFFER IS ACCEPTED AND IS PRINTED OUT PRECEEDED BY A       59840015
*        MESSAGE NUMBER. A RETURN IS THEN MADE TO CONTINUE PROCESSING   59920015
*        THE RECORD. A MESSAGE IS INSERTED IN THE DICTIONARY ONCE ONLY  60000015
*                                                                       60080015
RDERRX   STM   RR,13,LASSAV            SAVE ALL REGISTERS               60160015
         LR    GRB,GR0                                                  60240015
         L     DICR,DADDR              POINT AT TRUE DICTIONARY         60320015
         LR    GRC,GR0                                                  60400015
         LA    GRC,0(0,GRC)            CLEAR TOP BYTE                   60480015
         SRL   GRB,24                  THIS GETS REQUIRED OFFSET        60560015
         AR    GRB,GRC                 NOW POINT AT CCW                 60640015
         L     GRB,0(0,GRB)            POINT AT BUFFER                  60720015
         MVC   PLMESDC(10),0(GRB)      PICK UP FIRST 10 CHARS OF BUFFER 60800015
         MVC   TEMP4(4),PAR1(DICR)                                      60880015
         MVC   PAR6+1(3,DICR),ERRF14   ENTER MESSAGE TO DICTIONARY      60960015
         LA    GRA,PLMES                                                61040015
         ST    GRA,PAR1(0,DICR)        POINT AT LINE                    61120015
         LA    DICR,ABSAV              POINT AT NEW SAVE AREA           61200015
         L     LR,ZUPLOF(CNTL)                                          61280015
         BALR  RR,LR                 BRANCH TO ZUPL                     61360015
JMPBRC   BC    NOP,JMPE14                                               61440015
         L     LR,ZUEROF(CNTL)                                          61520015
         BALR  RR,LR                 BRANCH TO ZUERR                    61600015
         MVI   JMPBRC+1,X'F0'                                           61680015
JMPE14   L     DICR,DADDR                                               61760015
         MVC   PAR1(4,DICR),TEMP4                                       61840015
         LM    RR,13,LASSAV            RESTORE ALL REGISTERS            61920015
         BCR   BR,RR                                                    62000015
         EJECT                                                          62080015
*                                                                       62160015
*              THIS ROUTINE IS ENTERED WHEN THE CONTROL PHASE ABORTS    62240015
*        THE COMPILER. A TEST FOR THE DUMP OPTION IS MADE. IF THE DUMP  62320015
*        IS REQUIRED THEN ALL THE REGISTERS AND PAR1 TO PAR8 ARE        62400015
*        PRINTED OUT. THE REGISTERS PRINTED ARE THOSE THAT ARE SAVED    62480015
*        WHEN THE ENTRY TO THE CONTROL PHASE IS MADE                    62560015
*                                                                       62640015
DYNAMIC  ST    RR,DICTEM               STORE INCASE RETURN ON RR RQD    62720015
         STM   0,15,ABSAV              SAVE REGS. BEFORE DYNAMIC  33893 62760020
         TM    CCCODE(DICR),X'80'      SEE IF DUMP RQD                  62800015
         BC    BZ,NABDMP                                                62880015
         MVC   SAVAR(32),PAR1(DICR)    SAVE ALL PARAMETERS              62960015
         MVC   LASSAV+56(8),12(DICR)   PICK UP REGS 14 AND 15           63040015
         MVC   LASSAV(44),20(DICR)     PICK UP 0 TRHRU 10               63120015
         STM   11,13,LASSAV+44         PICK UP 11 12 AND 13             63200015
         LA    GRA,SAVAR               SAVE ADDRESSES OF PARS AND REGS  63280015
         LA    GRB,LASSAV                                               63360015
         STM   GRA,GRB,PAR1(DICR)                                       63440015
         MVI   PAR1(DICR),X'03'        SAM TYPE 3 DYNAMIC DUMP          63520015
         L     LR,ZUST(0,CNTL)         CALL AD                          63600015
         BALR  RR,LR                                                    63680015
NABDMP   L     RR,DICTEM                                                63760015
         CLI   DYNSW,X'FF'                                              63840015
         BCR   BE,RR                   RETURN TO CALLER                 63920015
         L     LR,ZUEROF(CNTL)                                          64000015
         BALR  RR,LR                 BRANCH TO ZUERR                    64080015
         LM    0,15,ABSAV              RESTORE REGS. AT ENTRY     33893 64120020
         BAL   RR,ABORT                                                 64160015
         EJECT                                                          64240015
*                       THIS ROUTINE CAUSES THE COMPILER TO TERMINATE   64320015
*        ABNORMALLY OWING TO AN IRREDEMABLE ERROR. ALL CURRENTLY LOADED 64400015
*        PHASES ARE PLACED IN A RELEASE LIST AND CONTROL IS PASSED TO   64480015
*        PHASE XA                                                       64560015
*              IF THE DUMP OPTION HAS BEEN SPECIFIED THEN A CHECK IS    64640015
*        MADE TO SEE IF THE DUMP ROUTINES HAVE BEEN LOADED. THEY ARE    64720015
*        THEN LOADED AND ENTERED. THIS IS MAINLY TO DEAL WITH PROGRAM   64800015
*        CHECKS.                                                        64880015
         SPACE 2                                                        64960015
*              SAVE REGISTERS AND BASE AA                               65040015
*                                                                       65120015
ZABORT   STM   0,15,ABSAV              STORE REGS. ON ENTRY       33893 65220020
*                                                                       65360015
         LA    GR0,ABSAV               STORE ADDR OF REG SAVE AREA IN   65520015
         ST    GR0,FSTDIC+8(DICR)    AA IN DICT                         65600015
         XC    LOCK(2,DICR),LOCK(DICR) UNLOCK DICT BLOCK                65680015
         SPACE                                                          65760015
*              TEST FOR FIRST ENTRY TO ABORT ROUTINE                    65840015
*                                                                       65920015
         TM    CCCODE(DICR),X'40'      HAS ABORT ALREADY OCCURED        66000015
         BC    BO,ABRTWO             YES, BRANCH TO SAY SO              66080015
         OI    CCCODE(DICR),X'40'    NO, SHOW ABORT HAS OCCURED NOW     66160015
         SPACE                                                          66240015
*              TEST WHETHER DUMP REQUIRED                               66320015
*                                                                       66400015
         TM    CCCODE(DICR),X'80'      IS DUMP REQUIRED                 66480015
         BC    BZ,ERRPHS             NO, GO TO TEST FOR ERROR PHASES    66560015
         MVI   PAR1(DICR),X'00'      YES, SHOW NOT A DYNAMIC DUMP       66640015
         LA    13,LASSAV               SET UP SAVE AREA FOR AD    33893 66680020
         L     LR,ZUST(CNTL)           LINK TO PHASE AD                 66720015
         BALR  RR,LR                                                    66800015
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN  33893 66840020
         SPACE                                                          66880015
*              TEST FOR ERROR MESSAGE PHASES IN TROUBLE                 66960015
*                                                                       67040015
ERRPHS   CLI   MYNAM(DICR),C'X'        IS IT PHASE XA                   67120015
         BC    BNE,TRYBM             NO, TRY PHASE BM                   67200015
         MVC   ABMSDC1(2),XANAM      YES, SAY SO                        67280015
         BC    B,ABMES                 BRANCH TO PRINT ERROR MSG        67360015
*                                                                       67440015
TRYBM    CLC   MYNAM(2,DICR),BMNAM     IS IT BM                         67520015
         BC    BNE,PHSREL            NO, GO TO RELEASE PHASES           67600015
         MVC   ABMSDC1(2),BMNAM      YES, SAY SO                        67680015
         BC    B,ABMES                 BRANCH TO PRINT ERROR MSG        67760015
         SPACE                                                          67840015
*              MAKE A LIST OF ALL LOADED PHASES                         67920015
*                                                                       68000015
PHSREL   L     GRA,PAROF(CNTL)         POINT AT INIT LIST               68080015
         L     GRA,PDOF(GRA)           HENCE AT PHASE DIRECTORY         68160015
         LA    GRB,RELLST              POINT AT RELEASE LIST            68240015
*                                                                       68320015
PHSLOP   TM    2(GRA),X'08'            IS THIS PHASE DELETED            68400015
         BC    BO,BMPPHS             YES, LOOK AT NEXT PHASE            68480015
         TM    2(GRA),X'70'          NO, IS PHASE LOADED, LOADING, OR   68560015
*                                    ACTIVATED, OR ANY COMBINATION OF 3 68640015
         BC    BZ,BMPPHS             NO, LOOK AT NEXT PHASE             68720015
         MVC   0(2,GRB),0(GRA)       YES, ADD PHASE TO RELEASE LIST     68800015
         LA    GRB,2(GRB)              BUMP RELEASE LIST POINTER        68880015
*                                                                       68960015
BMPPHS   LA    GRA,12(GRA)             POINT AT NEXT PHASE              69040015
         CLI   0(GRA),X'00'            IS IT END OF DIRECTORY           69120015
         BC    BNE,PHSLOP            NO, GO TO TEST NEXT PHASE          69200015
         MVC   0(2,GRB),RELLST+12    PUT IN STOPPER                     69240015
         SPACE                                                          69280015
*              DETERMINE WHICH PHASE CAN CARRY ON, AND PASS CONTROL     69360015
*                                                                       69440015
         TM    CCCODE+3(DICR),X'10'    TEST IF MACRO RUNNING            69520015
         BC    BZ,TRYJZ              NO, GO TO TEST FOR SECOND HALF     69600015
         LA    GRB,BMNAM                                                69800001
         BC    B,STMPHS                RELEASE CTL TO BM                69820001
         SPACE 1                                                        69840001
TRYJZ    CLI   SECHF(DICR),X'FF'       TEST IF 2ND HALF OF COMPILER     69920015
         BC    BE,LOADXA             YES, GO TO RELEASE TO XA           70000015
         LA    GRB,JZNAM             NO, POINT AT JZ                    70080015
         BC    B,STMPHS                GO TO RELEASE CONTROL TO JZ      70160015
*                                                                       70240015
LOADXA   LA    GRB,XANAM               POINT AT XA                      70320015
*                                                                       70400015
STMPHS   LA    GRA,RELLST              POINT AT RELEASE LIST            70480015
         STM   GRA,GRB,PAR1(DICR)      STORE PHASE NAMES                70560015
         BAL   RR,RLSCTL               LINK TO RELEASE CONTROL          70640015
         SPACE 5                                                        70720015
*              ERROR MESSAGES WHEN CONTINUATION IS IMPOSSIBLE           70800015
*                                                                       70880015
ABRTWO   LA    GR0,DUBAB               POINT AT MSG FOR DOUBLE ABORT    70960015
         BC    B,ABPRNT                GO TO PRINT MSG                  71040015
*                                                                       71120015
ABMES    LA    GR0,ABMESDC             POINT AT ERROR IN XA OR BM MSG   71200015
*                                                                       71280015
ABPRNT   ST    GR0,PAR1(DICR)          STORE MSG POINTER                71360015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 049-TSS 71400020
         L     LR,ZUPLOF(CNTL)                                          71440015
*        ----------------------------------------------------AA 049-TSS 71480020
         BALR  RR,LR                 BRANCH TO  ZUPL                    71520015
         TM    CCCODE(DICR),X'40'      DOUBLE ABORT?              33893 71530020
         MVI   ERCODE+3(DICR),X'10'    SET TERMINAL ERROR CODE          71600046
         BNO   ZEND                    DEPART IN PEACE                  71670046
         MVI   0(CNTL),X'FF'           SHOW ABEND IS TO OCCUR           71740046
         LA    GRC,3865                PICK UP ERROR NO. FOR USER CODE  71810046
         BC    B,ZEND                                                   71920015
         SPACE 5                                                        72000015
*              CONSTANTS                                                72080015
*                                                                       72160015
RELLST   DC    C'000000000000ZZ'       RELEASE LIST                     72240015
JZNAM    DC    C'JZ'                                                    72320015
*                                                                       72400015
DUBAB    DC    X'0020'                                                  72480015
         DC    C'-'                                                     72560015
         DC    C'IEM3865I ERROR IN COMPILER ABORT'                      72640015
         EJECT                                                          72720015
*        ROUTINE ZEND.                                                  72800015
*                       THIS ROUTINE CAUSES A NORMAL RETURN TO BE MADE  72880015
*        TO THE OPERATING SYSTEM. IT SS THE ONLY WAY OF NORMALLY        72960015
*        TERMINATING A JOB STEP. THE EEROR COBE IS PLACED IN REGISTER   73040015
*        15. IT IS THIS ERROR CODE WHICH IS USED TO DETERMINE THE       73120015
*        ACTION OF THE NEXT JOB STEP.                                   73200015
*              THE TIMER IS READ FOR THE SECOND TIME AND THE TIME OF    73280015
*        COMPILATION IS PRINTED IN MINUTES AND HUNDRETHS OF MINUTES.    73360015
         SPACE 2                                                        73440015
ZEND     LA    DICR,FSTSAV                                        IEM00 73520017
*                                                                       73600015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 011-TSS 73640020
         LINK  EP=IEMAK                                                 73680015
*        ----------------------------------------------------AA 011-TSS 73720020
         L     DICR,DADDR                                               73760015
         BC    B,BTCHSWT(LR)                                            73840015
BTCHSWT  BC    B,NOLINK                                                 73920015
         MVI   SCNOF(DICR),X'00'       RECONSTITUTE INSTRS IN ORDER     74000015
         MVI   TRYCTL+1,X'00'          TO MAKE CODE SERIALLY REUSABLE   74080015
         MVC   CARNO(3),REINCAR        REINIT. CARNO                    74160015
         L     LR,RECON(CNTL)          POINT AT RTN WHICH RECONSTS      74240015
         BALR  RR,LR                   INSTRNS IN AL                    74320015
         OI    DADDR,X'80'             >HOW AB WE ARE BATCH COMPILING   74400015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 025-TSS 74440020
         L     GRA,4(CNTL)             REPOINT ZURD AT SYSIN DCB   H229 74480001
*        ----------------------------------------------------AA 025-TSS 74520020
         ST    GRA,RDADD                                                74560015
         L     DICR,KEEP               POINT AT SAVE AREA AS IF FST NTR 74640015
         BC    B,BATCH                                                  74720015
*                                                                       74800015
NOLINK   EQU   *                                                        74880015
         TM    NOCRSW,X'0F'  WAS THERE AN I/O ERROR ON SYSPRINT AB H229 74900001
         BO    NOSPIE  YES, ON EXIT FROM AB WE WENT TO KILL RTN    H229 74920001
         AIF   (NOT &STD).L4                                            74925021
         LA    DICR,FSTSAV             PROVIDE S.A. TO SPIE.            74930021
.L4      ANOP                                                           74935021
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 012-TSS 74940020
         L     GRA,PICAD               LOAD OLD PICA ADDRESS            74960015
*              ISSUE A SPIE TO ALLOW OS TO HANDLE PROGRAM INTERRUPTS    75040015
         SPIE  MF=(E,(GRA))            RESET PICA                       75120015
*        ----------------------------------------------------AA 012-TSS 75160020
         L     GRA,PMASK               PICK UP ORIGINAL PROGRAM MASK    75200015
         SPM   GRA                     RESET PROGRAM MASK               75280015
NOSPIE   EQU   *                                                   H229 75320001
         LR    LR,RT                   LOAD RETURN CODE,SAVED IN AK     75360015
HADIT    L     GRA,KEEP                POINT REG13 AT O/S (OR CALLERS)  75440015
         L     13,4(0,GRA)           SAVE AREA                          75520015
         L     14,12(0,13)             RELOAD ALL REGS EXECPT REG15     75600015
         LM    0,12,20(13)                                              75680015
         MVI   12(DICR),X'FF'          SHOW RETURN IS COMPLETE          75760015
CHK      BCR   BR,RR                   GO TO OS/360 TO END JOB          75840015
         EJECT                                                          75920015
ZEDS     DC    C'ZZ'                   STOPPER IN NAME LISTS            76000015
ERR9     DC    X'0F0980'                                                76080015
ERR10    DC    X'0F0A80'                                                76160015
ZCHARS   DC    C'00'                                                    76240015
RQSWCH   DC    X'00'                                                    76320015
ERR12    DC    X'0F1280'                                                76400015
ERRF15   DC    X'0F1500'                                                76480016
ERRF17   DC    X'0F1700'                                                76560015
LSTRLS   DS    F                                                        76640015
SCNPNT   DS    F                                                        76720015
TEMSYN   DC    F'0'                                                     76800015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 026-TSS 76840020
RDADD    DC    A(RDDCB)                POINTS AT READ DCB               76880015
*        ----------------------------------------------------AA 026-TSS 76920020
         CNOP  0,4                                                      76960015
STNAME   DC    C'IEMAD   '                                              77040015
DELST    DC    C'IEM     '                                              77120015
LOADL    DC    C'IEMXY   '             PHASE NAME                       77200015
TTRMR    DC    XL3'00'                 TTR OF FIRST MEMBER RECORD       77280015
CONCAT   DC    X'00'                   CONCAT NUMBER                    77360015
LIBID    DC    X'00'                   LIBRARY ID                       77440015
ALIND    DC    X'00'                   ALIAS INDICATOR                  77520015
TTRFTR   DC    XL3'00'                 TTR OF FIRST TEXT RECORD         77600015
ZEROBT   DC    X'00'                   ZERO BYTE                        77680015
         DC    XL3'00'                 TTR OF NOTE OR SCATTER TABLE     77760015
         DC    X'00'                   NUMBER OF ENTRIES IN NOTE LIST   77840015
         DC    XL2'00'                 MODULE ATTRIBUTES                77920015
TOTCOR   DC    XL3'00'                 TOTAL CONTIGUOUS CORE REQUIRED   78000015
FSTREC   DC    XL2'00'                 LENGTH OF FIRST TEXT RECORD      78080015
         DC    X'00'                                                    78160015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 013-TSS 78200020
ABSAV    DS    18F                                                      78240015
LASSAV   DS    18F                                                      78320015
*        ----------------------------------------------------AA 013-TSS 78360020
DYNSW    DC    X'00'                                                    78560015
RELST    DS    CL12                    RELEASE LIST               31173 78580020
LOADLST  DS    CL12                    LOAD LIST                  31173 78610046
         SPACE                                                          78640015
STAT     EQU   2                                                        78720015
CNBR     EQU   3                                                        78800015
FTR      EQU   5                                                        78880015
CONTIG   EQU   8                                                        78960015
CARNO    DC    X'00000F'                                                79040015
REINCAR  DC    X'00000F'                                                79120015
         SPACE                                                          79130001
*        TABLE USED BY PIH IMPRECISE INTERRUPT ROUTINE              I24 79138019
         SPACE                                                          79146019
         DC    X'0B0A0F0E'                                          I24 79154019
         DC    X'0D0C0908'                                          I24 79162019
         DC    X'07060504'                                          I24 79170019
ENDTAB   EQU   *-1                                                  I24 79178019
INTCDE   DS    C                       ONE BYTE STORE               I24 79186019
         EJECT                                                          79200015
SIGCHR   DC    F'72'                   SIGNIFICANT CHRS IN FIXED RECORD 79280015
NUMCHR   DC    F'80'                   NUMBER OF CHARS. IN FIXED RECORD 79360015
SPILL    DC    X'00'                   SPILL SWITCH                     79440015
ERRF14   DC    X'0F1408'                                                79520015
PLMES    DC    X'0013'                                                  79600015
         DC    C'-'                                                     79680015
         DC    C'IEM3860I '                                             79760015
PLMESDC  DC    10C' '                                                   79840015
M3862A   DC    C'IEM3862I I/O ERR'                                 H229 79850001
M3862B   DC    C'CONT-'                                            H229 79860001
MCSFLGS  DC    B'1000000000000000'     MCS FLAGS FOR WTO           H229 79870001
DESCRTCD DC    B'0000010000000000'   WTO DESCRIPTOR CODE (=6)     43462 79880021
         DC    B'0100000000100000'   WTO ROUTING CODES (=2,11)    43462 79890021
         EJECT                                                          79920015
*        ROUTINE PIH                                                    80000015
*                       THIS ROUTINE WILL HANDLE ALL PROGRAM INTERRUPTS 80080015
*        THAT OCCUR DURING THE RUNNING OF THE COMPILER. THE INTERRUPT   80160015
*        TYPE IS CHECKED AGAINST THE MASK IN ARMASK. IF THE MASK        80240015
*        INDICATES THAT THE PHASE IS WILLING TO DEAL WITH THIS TYPE OF  80320015
*        INTERRUPT THEN CONTROL IS PASSED TO THE ADDRESS IN ARINT.      80400015
*        OTHERWISE CONTROL IS PASSED TO ZABORT. REG 1 CONTAINS THE      80480015
*        PIE ADDRESS ON ENTRY.                                          80560015
         SPACE 2                                                        80640015
         CNOP  0,4                                                      80720015
         USING *,15                                                     80800015
PIH      STM   GRH,RR,STORE1           STORE REGS REQUIRED BY PIH.      80820001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 014-TSS 80826020
*        ----------------------------------------------------AA 014-TSS 80832020
INPIH    B     NOTPRIV                 MADE NOP BY AT IF TRACING. IEMAT 80840001
         CLI   7(1),X'02'              IS INTERRUPT PRIVLGD OP..  IEMAT 80860001
         BNE   NOTPRIV                 BRANCH IF NOT.             IEMAT 80880001
         STM   14,15,STORE2            SAVE R14 & R15.            IEMAT 80900001
         L     15,ATADDR               POINT R15 AT IEMAT.        IEMAT 80920001
         BAL   14,TRACEIT(0,15)        LINK TO TRACEIT IN IEMAT.  IEMAT 80940001
STORE2   DC    2F'0'                   HOLDS R14 & R15.           IEMAT 80960001
         LM    14,15,0(14)             RESTORE R14 & R15.         IEMAT 80980001
NOTPRIV  L     DICR,DADDR              POINT DICR AT DICTIONARY.  IEMAT 81000001
         L     CNTL,ZTV(0,DICR)        PICK UP CONTROL BASE             81040015
         BC    B,PSFIN                                                  81120015
STORE1   DS    8F                                                   I24 81200019
DADDR    DC    F'0'                                                     81280015
ATADDR   DC    F'0'                    LOAD POINT OF IEMAT.       IEMAT 81320001
PSFIN    BC    NOP,0                                                    81360015
         DROP  15                                                       81440015
         SPACE                                                          81443001
         TM    7(1),X'0F'              IS IT A PRECISE INTERRUPT    I24 81453019
         BNZ   PREC                    BRANCH IF SO                 I24 81463019
         SPACE                                                          81473019
*        THE FOLLOWING CODE TRANSLATES AN IMPRECISE INTERRUPTION    I24 81483019
*        CODE (ON MODEL 91 OR 195) INTO THE CORRESPONDING PRECISE   I24 81493019
*        INTERRUPTION CODE.                                         I24 81503019
         SPACE                                                          81513019
         LA    GRI,ENDTAB              POINT AT END OF TABLE        I24 81523019
         MVC   INTCDE(1),6(1)          PICK UP 1ST BYTE OF INT CODE I24 81533019
IMPREC1  LA    GRH,128                 SET TOP BIT IN 4TH BYTE      I24 81543019
IMPREC2  EX    GRH,TSTINT              IS IT THIS INTERRUPT         I24 81553019
         BO    TESTAR                  BRANCH IF SO                 I24 81563019
         BCTR  GRI,0                   REDUCE TABLE POINTER         I24 81573019
         SRA   GRH,1                   SHIFT THE TEST BIT AND IF 1STI24 81583019
         BNZ   IMPREC2                 BYTE NOT FINI GOTO TEST AGAINI24 81593019
         MVC   INTCDE(1),7(1)          OTHERWISE PICK UP 2ND BYTE   I24 81603019
         B     IMPREC1                 AND DO IT ALL AGAIN          I24 81613019
         SPACE                                                          81623019
TSTINT   TM    INTCDE,X'00'            EXECUTED INSTRUCTION         I24 81633019
         SPACE                                                          81643019
PREC     LA    GRI,7(1)                POINT AT INT CODE            I24 81653019
TESTAR   TM    0(GRI),X'08'            IS IT ARITH INTERRUPT        I24 81663019
         BC    BO,ARINTX                                                81680015
         SPACE                                                          81760015
PIHABT   MVC   PAR6+1(3,DICR),ERR16    INSERT INTERRUPT MESSAGE         81840015
         MVC   PAR5+3(1,DICR),0(GRI)   INSERT INTERRUPT TYPE        I24 81890019
         MVI   PAR5+2(DICR),X'00'      CLEAR PAR5+2                 I24 81940019
         LA    GRB,MYNAM(DICR)         POINT AT PHASE NAME              82000015
         ST    GRB,PAR7(0,DICR)        STORE FOR ERROR MESSAGE          82080015
         TR    0(2,GRB),TAB1           TRANSLATE TO INTERNAL            82160015
         LA    GRH,2                                                    82240015
         ST    GRH,PAR8(0,DICR)        SHOW NAME TWO BYTES LONG         82320015
         LA    DICR,ABSAV            PSW. POINT AT NEW SAVE AREA        82400015
         L     CNTL3,ZUEROF(CNTL)                                       82480015
         BALR  RR,CNTL3              BRANCH TO ZUERR                    82560015
         L     DICR,DADDR                                               82640015
         TR    0(2,GRB),TAB3           TRANSLATE BACK TO EXTERNAL       82720015
         OI    CCCODE+2(DICR),X'02'    SHOW PROGRAM CHECK HAS OCCURRED  82800015
         MVC   FSTDIC(8,DICR),4(1)     STORE INTERRUPT ADDRESS          82880015
         MVC   9(3,1),ABOTOF+1(11)     INSERT OF ABORT ROUTINE          82960015
         LM    GRH,RR,STORE1           RELOAD REGISTERS                 83040015
         USING PIH,15                                                   83120015
         L     DICR,DADDR              LOAD DICR TO POINT AT DICTIONARY 83200015
         DROP  15                                                       83280015
         L     CNTL,ZTV(0,DICR)        LOAD UP CONTROL BASE             83360015
         BCR   BR,RR                   BRANCH TO ABORT VIA OS 360       83440015
         SPACE                                                          83520015
ARINTX   LA    GRH,128                 INSERT 1 IN LH BIT OF RH BYTE    83600015
         MVC   SHIFTI+3(1),0(GRI)      PICK UP ERROR INDICATOR      I24 83680019
         NI    SHIFTI+3,X'07'        PSW IN PIE                         83760015
SHIFTI   SRL   GRH,0                   SHIFT TO BE LIKE ARMASK          83840015
         STC   GRH,PIHTST+1            STORE FOR COMPARISON WITH ARMASK 83920015
PIHTST   TM    ARMASK(DICR),X'00'      SEE IF INTERRUPT IS ONE THAT CAN 84000015
         BC    BZ,PIHABT             BE DEALT WITH                      84080015
         SPACE                                                          84160015
         CLC   ARINT(4,DICR),ZEROS     TEST IF THERE IS A LIKELY ADDRSS 84240015
         BC    BE,PIHABT             FOR INTERRUPT HANDLER              84320015
         SPACE                                                          84400015
         L     15,ARINT(0,DICR)        PICK UP ADDRESS OF PHASE PIH     84480015
         LM    GRH,RR,STORE1           RELOAD REGISTERS                 84560015
         BCR   BR,15                   PASS CONTROL TO PHASE            84640015
ERR16    DC    X'0F10E0'                                                84720015
         EJECT                                                          84800015
*              THIS ROUTINE RETURNS TO THE CALLER * * * * * ** * * * *  84880015
RETRTN   LM    14,10,12(DICR)          RELOAD REGISTERS                 84960015
         MVI   12(DICR),X'FF'           SHOW RETURN IS COMPLETE         85040015
         BCR   BR,RR                    RETURN TO CALLER                85120015
         EJECT                                                          85200015
*                                                                       85280015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 046-TSS 85320020
*              SYSUT1 ERROR EXIT ROUTINE                                85360015
*                                                                       85440015
UTIERA   LA    LR,ADDLST                                                85520015
         L     LR,UTOF(LR)           POINT AT ERROR ROUTINE IN AL       85600015
         BCR   BR,LR                                                    85680015
*        ----------------------------------------------------AA 046-TSS 85720020
*                                                                       85760015
*              SYSIN EOF ROUTINE                                        85840015
*                                                                       85920015
ENDCD    LA    LR,ADDLST                                                86000015
         L     LR,ZUROF(LR)          POINT AT EOF RTN IN AL             86080015
         BCR   BR,LR                                                    86160015
         EJECT                                                          86240015
*              DCB MACRO DESCRIPTION FOR SPILL FILE                     86320015
*                                                                       86400015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 019-TSS 86440020
SPDCB    DCB   DSORG=PS,                                               C86480015
               MACRF=(WP),                                             C86560015
               DDNAME=SYSUT1,                                          C86640015
               DEVD=DA,                                                C86720015
               OPTCD=W,                                                C86800015
               RECFM=U,                                                C86880015
               SYNAD=UTIERA,                                           C86960015
               NCP=1                                                    87040015
*        ----------------------------------------------------AA 019-TSS 87080020
         EJECT                                                          87120015
*                                                                       87200015
*              SYSIN DCB.                                               87280015
*                                                                       87360015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 015-TSS 87400020
RDDCB    DCB   DSORG=PS,                                               C87440015
               MACRF=(GM),                                             C87520015
               DDNAME=SYSIN,                                           C87600015
               SYNAD=RDERRX,                                           C87680015
               EODAD=ENDCD,                                            C87760015
               EROPT=ACC                                                87840015
*        ----------------------------------------------------AA 015-TSS 87880020
         EJECT                                                          87920015
*                                                                       88000015
*              LOAD FILE DCB                                            88080015
*                                                                       88160015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 018-TSS 88200020
LFDCB    DCB   DSORG=PS,                                               C88240015
               MACRF=(PL),                                             C88320015
               DDNAME=SYSLIN,                                          C88400015
               RECFM=FB,                                               C88480015
               LRECL=80,                                               C88560015
               SYNAD=LFERRX,                                           C88640015
               EROPT=SKP                                                88720015
*        ----------------------------------------------------AA 018-TSS 88760020
         EJECT                                                          88800015
*                                                                       88880015
*              SYSPUNCH DCB                                             88960015
*                                                                       89040015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 016-TSS 89080020
SYPDCB   DCB   DSORG=PS,                                               C89120015
               MACRF=(PL),                                             C89200015
               DDNAME=SYSPUNCH,                                        C89280015
               RECFM=FB,                                               C89360015
               LRECL=80,                                               C89440015
               SYNAD=SPERRX,                                           C89520015
               EROPT=SKP                                                89600015
*        ----------------------------------------------------AA 016-TSS 89640020
         EJECT                                                          89680015
*                                                                       89760015
*              SYSPRINT DCB                                             89840015
*                                                                       89920015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 017-TSS 89960020
PLDCB    DCB   DSORG=PS,                                               C90000015
               MACRF=(PL),                                             C90080015
               DDNAME=SYSPRINT,                                        C90160015
               RECFM=VBA,                                              C90240015
               LRECL=125,                                              C90320015
               SYNAD=PLERRX,                                           C90400015
               EROPT=SKP                                                90480015
*        ----------------------------------------------------AA 017-TSS 90520020
         EJECT                                                          90560015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 040-TSS 90680020
PD       DS    1476C                   123 ENTRIES OF 12 BYTES          90720001
SCNDLST  DS    360C                    120 ENTRIES OF 3 BYTES           90800001
         DCBD  DSORG=(BS),DEVD=DA                                       90880015
         EJECT                                                          90960015
*                                                                       91040015
*              REGISTER EQUATES                                         91120015
*        ----------------------------------------------------AA 040-TSS 91160020
*                                                                       91200015
GR0      EQU   0                                                        91280015
GR1      EQU   1                                                        91360015
GR5      EQU   5                                                        91440015
GRA      EQU   1                                                        91520015
GRB      EQU   2                                                        91600015
GRC      EQU   3                                                        91680015
GRD      EQU   4                                                        91760015
GRE      EQU   5                                                        91840015
GRF      EQU   6                                                -  H229 91860001
GRH      EQU   7                                                  21158 91890001
GRI      EQU   8                                                  21158 91940001
CNTL     EQU   11                                                       92000015
CNTL2    EQU   10                                                       92080015
RR       EQU   14                                                       92160015
CNTL3    EQU   9                                                        92240015
RT       EQU   12                                                       92320015
DICR     EQU   13                                                       92400015
LR       EQU   15                                                       92480015
*                                                                       92560015
*              BRANCH EQUATES                                           92640015
*                                                                       92720015
NOP      EQU   0                                                        92800015
B        EQU   15                                                       92880015
BR       EQU   15                                                       92960015
BH       EQU   2                                                        93040015
BL       EQU   4                                                        93120015
BNL      EQU   11                                                       93200015
BE       EQU   8                                                        93280015
BNE      EQU   7                                                        93360015
BNZ      EQU   7                                                        93440015
BNH      EQU   13                                                       93520015
BO       EQU   1                                                        93600015
BZ       EQU   8                                                        93680015
BM       EQU   4                                                        93760015
BNO      EQU   14                                                       93800015
*              COMMUNICATIONS REGION EQUATES                            93840015
*                                                                       93920015
*                                                                       94000015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AA 041-TSS 94020020
*        ----------------------------------------------------AA 041-TSS 94040020
ABORT    EQU   ZABORT                                                   94080015
TLR      EQU   240                                                      94160015
ZTV      EQU   64                                                       94240015
ZTRAN1   EQU   68                                                       94320015
ZTRAN2   EQU   ZTRAN1+4                                                 94400015
ZNXTD    EQU   76                                                       94480015
ZSTAT    EQU   124                                                      94560015
PAR1     EQU   128                                                      94640015
PAR2     EQU   PAR1+4                                                   94720015
PAR3     EQU   PAR2+4                                                   94800015
PAR4     EQU   PAR3+4                                                   94880015
PAR5     EQU   PAR4+4                                                   94960015
PAR6     EQU   PAR5+4                                                   95040015
PAR7     EQU   PAR6+4                                                   95120015
PAR8     EQU   PAR7+4                                                   95200015
MYNAM    EQU   112                                                      95280015
FSTDIC   EQU   160                                                      95360015
TERMSW   EQU   176                                                      95440015
PARMLEN  EQU   197                                                      95520015
IOERSW   EQU   191                                                      95600015
SPLNAM   EQU   180                                                      95680015
SCNOF    EQU   184                                                      95760015
SECHF    EQU   185                                                      95840015
ZDROLF   EQU   186                                                      95920015
DICTSP   EQU   200                                                      96000015
ZNXTOF   EQU   204                                                      96080015
FONOF    EQU   208                                                      96160015
CCCODE   EQU   232                                                      96240015
ABOTOF   EQU   X'20'                                                    96320015
ZUST     EQU   X'4C'                                                    96400015
ARINT    EQU   248                                                      96480015
ERCODE   EQU   224                                                      96560015
ARMASK   EQU   273                                                      96640015
DICTSZ   EQU   260                                                      96720015
TXTSZ    EQU   264                                                      96800015
ZMASK    EQU   284                                                      96880015
LOCK     EQU   274                                                      96960015
ZSHIFT   EQU   280                                                      97040015
CORLFT   EQU   160                                                      97120015
ZMASK1   EQU   286                                                      97200015
ZPRNAM   EQU   288                                                      97280015
ZDNXT    EQU   96                                                       97360015
PERRSW   EQU   189                                                      97440015
SCOF     EQU   84                                                       97520015
PAROF    EQU   28                                                       97600015
PDOF     EQU   28                                                       97680015
RECON    EQU   132                                                      97760015
ZUEROF   EQU   48                                                       97840015
ZUPLOF   EQU   8                                                        97920015
UTOF     EQU   140                                                      98000015
ZUROF    EQU   144                                                      98080015
*                                                                       98160015
*              THIS EQUATE IS FOR THE FIRST CARD READ BY THE INITIALISR 98240015
*                                                                       98320015
READSL   EQU   500                                                      98400015
ZTIM     EQU   X'2FC'                  START OF PHASE TIME        Z2151 98405046
         SPACE 1                                                        98410001
TRACLOAD EQU   4                       OFFSETS OF                 IEMAT 98420001
TRACRELS EQU   8                       ENTRY POINTS               IEMAT 98430001
TRACEIT  EQU   12                      IN IEMAT.                  IEMAT 98440001
         END   IEMAA                                                    98480015
