         GBLB  &STD                                                     00010021
&STD     SETB  1                                                        00020021
AL       TITLE 'IEMAL,RESIDENT CONTROL PHASE,LARGE DICTIONARY,PL/I COMP*00030001
               ILER(F)'                                                 00060001
*        STATUS - CHANGE LEVEL 0                                        00120072
*                                                                       00120372
* 5.5  C 096300-101700,225300,226800,518700-519600            MCB 62615 00120672
* 5.5  C 202800-202900                                         KT 60039 00120972
* 5.5  C 447600,449100,449400-450600,453600-456000             KT 60037 00121272
* 5.5  A 088780                                               MCB 60026 00121572
* 5.4  C 202800.                                              MAC 52214 00122321
* 5.4  A 000000,497400.                                       MCB 54703 00122421
* 5.3B C 188100.                                          MCB/MAC 47635 00122656
* 5.3B A 312750.     ADDITION TO R20.0 FIX FOR A32318.        MAC 47635 00123256
* 5.3B C 696300                                              PJMG 45901 00124056
* 5.3A C 312580-312850                                        JLC 43391 00126056
* 5.2  A 203400,203700,247900,248100,756300                   JLC 33893 00128056
* 5.2  A 061800,248700,311700,555000,760900                   JRT 32318 00130056
*      C 019800-020400,069000,247800-248100,309000,310200,    JRT 32318 00132056
*        312600,339900,341700,358800,360000,554400            JRT 32318 00134056
*      D 260400,376200-378000,567900                          JRT 32318 00136056
* 5.2  A 293700                                               JRT 30357 00138056
*      C 363900                                               JRT 30357 00140056
*                                                                       00142056
* R18 087000,124500,530400,716400,726400                          H244  00150001
* R18 DUPLICATE OF H244                                           23556 00180001
* R18 243200*                                                     23286 00210001
* R18 864800-865200,865000                                        H268  00240001
* R18 499200,501600-508200,594370,611400,612900,760900            H319  00250001
* R18 870000                                                      20706 00270056
         EJECT                                                          00297046
         SPACE 3                                                        00305020
*              FUNCTIONS - 1)COMPILER INITIALISATION. IEMAB IS LOADED   00330001
*        IN ORDER TO PERFORM THIS FUNCTION                              00360001
*                          2)CHARACTER TRANSLATION. EBCIDIC OR BCD TO   00390001
*        INTERNAL AND BACK TO EXTERNAL. THE RELEVANT TABLE IS SUPPLIED  00420001
*        DEPENDING UPON THE OPTION                                      00450001
*                          3)DICTIONARY AND TEXT BLOCK CONTROL. THESE   00480001
*        INCLUDE,EVENTUALLY,THE SPILLING OF BLOCKS ONTO SYSUT1 AND THE  00510001
*        CONTROL THEREOF.                                               00540001
*                          4)PHASE LOADING. FACILITIES ARE ALLOWED FOR  00570001
*        MARKING PHASES,LOADING PHASES AND RETURNING CONTROL TO THE     00600001
*        CALLER,DELETING(RELEASING) PHASES AND PASSING CONTROL TO A NEW 00630001
*        PHASE.                                                         00660001
*                          5)INPUT/OUTPUT CONTROL ONTO SYSPRINT,SYSIN,  00690001
*        SYSLIN AND SYSPUNCH. CONTROL TO SYSUT3 IN IEMAC                00720001
*                                                                       00750001
*                                                                       00780001
*              ENTRY POINT - THE CONTROL PHASE HAS A MULTITUDE OF ENTRY 00810001
*        POINTS. THE ARE LISTED IN THE TRANSFER VECTOR AT THE START OF  00840001
*        THE PHASE                                                      00870001
*                                                                       00900001
*                                                                       00930001
*              INPUT - ONLY INPUT IS THE PARAMETER LIST POINTED AT BY   00960001
*        GENERAL REGISTER 1 ON ENTRY                                    00990001
*                                                                       01020001
*                                                                       01050001
*              OUTPUT - THE ONLY OUTPUT GENERATED BY THE COMPILER IS    01080001
*        THE RETURN CODE PLACED IN GENERAL REGISTER 15 ON COMPLETION OF 01110001
*        THE COMPILATION                                                01140001
*                                                                       01170001
*                                                                       01200001
*              EXTERNAL ROUTINES - 1)IEMAB THE COMPILER INITIALISER. IT 01230001
*        IS LOADED IMEDIATELY AFTER IEMAA HAS BEEN LOADED.              01260001
*                                  2)IEMAC. THE INTERMEDIATE FILE       01290001
*        CONTROL. RECORDS ARE WRITTEN ON SYSUT3 AND THE READ BACK.      01320001
*                                  3)IEMAD. INTER-PHASE DUMPING CONTROL 01350001
*        TESTRAN IS USED                                                01380001
*                                  5)IEMAF. GENERATED BY SYSGEN. IT     01410001
*        WILL INDICATE THE STATUS OF THE DEFAULT OPTIONS                01440001
*                                  6)IEMAG. SYSUT3 FILE SWITCHING. IT   01470001
*        IS CALLED BY IEMAC.                                            01500001
*                                  4)IEMAE. CLEAN-UP AFTER READIN AND   01530001
*        OPEN SYSLIN AND SYSPUNCH IF NECESSARY                          01560001
*                                                                       01590001
*                                                                       01620001
*              EXITS - THE EXIT IS THROUGH ZEND. IT IS THERE THAT THE   01650001
*        CONDITION CODE IS PICKED UP. THERE ARE NO ABNORMAL EXITS.      01680001
*                                                                       01710001
*                                                                       01740001
*              ATTRIBUTES - THIS CODE IS NOT REUSABLE                   01770001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 000-TSS 01780020
*        ----------------------------------------------------AL 000-TSS 01790020
         EJECT                                                          01800001
*                                                                       01830001
*              BASE THE COMPILER                                        01860001
*                                                                       01890001
         SPACE 2                                                        01920001
IEMAL    CSECT                                                          01950001
         USING *,CNTL2,CNTL3                                      32318 01990020
BASES    DC    A(*+4096)               ADDRESS IN SECOND BASE REG.32318 02030020
         DC    A(BASES)                                                 02070001
*                                                                       02100001
*        THESE ADDRESSES WILL BE MOVED INTO THE TRANSFER VECTOR         02130001
*        IN IEMAA BY IEMAB                                              02160001
*                                                                       02190001
TRVEC    DC    A(ZUPL)                 SYSPRINT                         02220001
         DC    A(ZURD)                 SYSIN                            02250001
         DC    A(ZUGC)                 GET SCRATCH CORE                 02280001
         DC    A(ZUTXTC)               GET A TEXT BLOCK                 02310001
         DC    A(ZURC)                 RELEASE SCRATCH CORE             02340001
         DC    A(ZDICAB)               DICT ENTRY-ALIGNED,ABSOLUTE      02370001
         DC    A(ZDICRF)                         -ALIGNED,REFERENCE     02400001
         DC    A(ZUERR)                MAKE AN ERROR MESSAGE ENTRY      02430001
         DC    A(ZDRFAB)               DICTIONARY REFERENCE TO ABSOLUTE 02460001
         DC    A(ZTXTRF)               TEXT POINTER-ABSOLUTE TO REF     02490001
         DC    A(ZTXTAB)                           -REF TO ABS          02520001
         DC    A(ZCHAIN)               FIND NEXT TEXT BLOCK IN CHAIN    02550001
         DC    A(ZALTER)               ALTER STATUS OF TEXT BLOCK       02580001
         DC    A(ZDABRF)               DICT-ABS TO REF                  02610001
         DC    A(ZNALRF)               DICT ENTRY-UNALIGNED,REF         02640001
         DC    A(ZNALAB)                         -UNALIGNED,ABS         02670001
         DC    A(RECONS)               RECONST. INSTRS IN AL            02700001
         DC    A(ALLOCA)               SCRATCH CORE                     02730001
         DC    A(ALLOCL)                                                02760001
CONSLTT  DC    A(TSLOTS+24)            TEXT ALLOCATION SLOTS            02790001
CONSLDD  DC    A(DSLOTS+24)            DICT ALLOCATION SLOTS            02820001
         DC    A(HEDING)               PAGE HEADING                     02850001
         DC    A(MAXPAG)               MAX. PAGE COUNT                  02880001
         DC    A(PAGNO)                PAGE NUMBER                      02910001
         DC    A(NUMFRE)               NO. FREE TRACKS                  02940001
         DC    A(FRSLOT)               LIST FREE TRACKS                 02970001
         DC    A(BLKTBL)                                                03000001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 019-TSS 03030001
         DC    A(SPILL)                                                 03060001
*        ----------------------------------------------------AL 019-TSS 03090001
         DC    A(CONCNT)                                                03120001
         DC    A(BTCHBUF)              BATCH CARD FOR PARM SCAN         03150001
DADDR    DS    F                                                        03180001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 027-TSS 03190019
         DC    A(UTIERR)             SYSUT1 ERROR RTN                   03210001
*        ----------------------------------------------------AL 027-TSS 03220019
         DC    A(ZURDAB)             SYSIN EOF RTN                      03240001
         DC    A(CONSLD)          FOR PHASE IEMCC                       03270001
BLKTBL   DC    10XL4'FF000000'                                          03300001
         EJECT                                                          03330001
*              ROUTINE ZDABRF                                           03360001
*                             THIS ROUTINE CONVERTS AN ABS ADDR (PAR2)  03390001
*        INTO A DIC REF (PAR1). ON ENTRY PAR1 CONTAINS A DIC REF TO THE 03420001
*        BLOCK WHICH CONTAINS THE ABS ADDR.                             03450001
*              IF THE REFERENCED BLOCK IS NOT IN USE, OR IS ON DISC,    03480001
*        COMPILATION TERMINATES.                                        03510001
*              THE REFERENCED BLOCK IS ADDED TO THE LAST LOOK TABLE,    03540001
*        WHICH IS USED TO DETERMINE WHICH BLOCKS MUST BE KEPT IN CORE.  03570001
*              A SPECIAL CASE EXISTS WHEN THE DIC REF IN PAR1 ON ENTRY  03600001
*        REFERENCES THE OVERFLOW BLOCK. THIS OFLO REF MUST NOT BE USED  03630001
*        (SEE ZAROFR).                                                  03660001
         SPACE 2                                                        03690001
*              HOUSEKEEPING AND INITIALISATION                          03720001
*                                                                       03750001
ZDABRF   STM   14,10,12(13)            SAVE CALLERS REGS                03780001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE REG              03810001
         L     CNTL3,BASES           LOAD SECOND BASE                   03840001
         ST    13,DICTEM               STORE SAVE AREA ADDR             03870001
         L     DICR,DADDR              POINT AT DICT                    03900001
         SPACE                                                          03930001
*              CALL CONSLD TO FIND DSLOT ENTRY FOR REQUIRED BLOCK       03960001
*                                                                       03990001
ZARCON   BAL   RR,CONSLD               POINTS GRA AT ADDR SLOT OF BLK   04020001
         SPACE                                                          04050001
*              TEST IF REFERENCED BLOCK IS IN USE                       04080001
*                                                                       04110001
         CLI   0(GRA),X'FF'                                             04140001
         BC    BE,BLKERR               NO, DIAGNOSE AND ABORT           04170001
         SPACE                                                          04200001
*              TEST IF REFERENCED BLOCK IS THE OVERFLOW BLOCK           04230001
*                                                                       04260001
         CLI   OFLOSW,X'FF'            TEST IF OFLO EXISTS              04290001
         BC    BNE,ZARTBC            NO, OMIT OFLO BLK TEST             04320001
         CL    GRA,ZOBSAD(DICR)        TEST IF PAR1 REFERENCES OFLO BLK 04350001
         BC    BE,ZAROFR             YES, DECODE OFLO REF TO FIND BLK   04380001
         SPACE                                                          04410001
*              TEST IF REFERENCED BLOCK IS IN CORE                      04440001
*                                                                       04470001
ZARTBC   TM    0(GRA),X'80'                                             04500001
         BC    BZ,ZARERR               NO, DIAGNOSE AND ABORT           04530001
         SPACE                                                          04560001
*              ADD BLOCK REFERENCE TO LAST LOOK TABLE                   04590001
*                                                                       04620001
ZARALL   MVC   LASLOK-2(6),LASLOK                                       04650001
         MVC   LASLOK+4(2),PAR1+2(DICR)                                 04680001
         SPACE                                                          04710001
*              GET ADDRESS OF BLOCK                                     04740001
*                                                                       04770001
         L     GRA,0(0,GRA)            GET ADDR OF DICT BLOCK           04800001
         N     GRA,STBITS              ZERO THE STATUS BYTE             04830001
         SPACE                                                          04860001
*              CALCULATE ABSOLUTE OFFSET                                04890001
*                                                                       04920001
         L     GRB,PAR2(0,DICR)        LOAD THE ABSOLUTE ADDRESS        04950001
         SR    GRB,GRA                 CALC ABS OFFSET IN BLOCK         04980001
         SPACE                                                          05010001
*              SET OFFSET SLOT COUNT AND POINT AT OFFSET SLOTS          05040001
*                                                                       05070001
         A     GRA,FONOF(DICR)         POINT AT FON                     05100001
         LH    GRC,0(GRA)              LOAD FON                         05130001
         LR    GRD,GRC                 COPY IT                          05160001
         LA    GRE,2(GRA)              POINT AT OFFSET SLOTS            05190001
         SPACE                                                          05220001
*              TEST FOR FON EQUAL TO ZERO                               05250001
*                                                                       05280001
         C     GRD,ZEROS                                                05310001
         BC    BE,ZARFOS             YES, OMIT OFFSET SLOT SEARCH       05340001
         SPACE                                                          05370001
*              SEARCH OFFSET SLOTS FOR GIVEN ABSOLUTE OFFSET            05400001
*                                                                       05430001
ZARNOS   LH    GRF,0(GRE)              LOAD AN OFFSET                   05460001
         CR    GRF,GRB                 TEST IF REQD OFFSET              05490001
         BC    BNE,ZARBOS            NO, BUMP TO NEXT OFFSET SLOT       05520001
*                                                                       05550001
         SR    GRD,GRC                 CALC SLOT NO OF REQD OFFSET      05580001
         BC    B,ZARNDR                BRANCH TO MAKE THE DIC REF       05610001
*                                                                       05640001
ZARBOS   LA    GRE,2(GRE)              BUMP TO NEXT OFFSET SLOT         05670001
         BCT   GRC,ZARNOS              LOOP TO TEST NEXT OFFSET         05700001
         SPACE                                                          05730001
*              REQD OFFSET SLOT DOES NOT YET EXIST, ONE MUST BE MADE.   05760001
*        TEST IF ROOM IN OFFSET SLOTS, IF NOT CALL OVERFLOW ROUTINE.    05790001
*                                                                       05820001
         CH    GRD,MAXFON(DICR)        TEST IF FON TOO LARGE            05850001
         BC    BNH,ZARFOS            NO, OMIT CALL TO OFLO ROUTINE      05880001
*                                                                       05910001
         LA    RR,ZARRET               LOAD RETURN ADDR                 05940001
         BC    B,ZOFLOR                GO TO MAKE AN OFLO DIC REF       05970001
         SPACE                                                          06000001
*              FILL FREE OFFSET SLOT, UPDATE FON.                       06030001
*                                                                       06060001
ZARFOS   STH   GRB,0(GRE)              SET ABS OFFSET IN OFFSET SLOT    06090001
         LA    GRF,1(GRD)              BUMP FON BY 1                    06120001
         STH   GRF,0(GRA)              STORE NEW FON                    06150001
         SPACE                                                          06180001
*              CREATE THE NEW DICT REF IN PAR1                          06210001
*                                                                       06240001
ZARNDR   NC    PAR1+2(2,DICR),ZMASK1(DICR) REMOVE OFFSET IN PAR1        06270001
         SLL   GRD,2                   MOVE OFFSET NO INTO PLACE        06300001
         O     GRD,PAR1(0,DICR)      AND OR TOGETHER BLOCK AND OFFSET   06330001
         ST    GRD,PAR1(0,DICR)        STORE NEW DICT REF               06360001
         SPACE                                                          06390001
*              TEST IF DICT REF HAS USED OFFSET SLOT IN ZNXTD. IF SO    06420001
*        UPDATE ZNXTD.                                                  06450001
*                                                                       06480001
         CLC   PAR1+2(2,DICR),ZNXTD+2(DICR)   IS REF SMALLER THAN ZNXTD 06510001
         BC    BL,ZARRET             YES, OMIT ZNXTD UPDATE             06540001
         LA    GRD,4(GRD)            NO, BUMP DICT REF BY 1             06570001
         STH   GRD,ZNXTD+2(DICR)       STORE NEW ZNXTD                  06600001
         SPACE                                                          06630001
*              RETURN TO USER                                           06660001
*                                                                       06690001
ZARRET   L     DICR,DICTEM             POINT AT THIS SAVE AREA          06720001
         BC    B,RETRTN                RETURN TO CALLER                 06750001
         SPACE 5                                                        06780001
ZARERR   MVC   PAR6+1(3,DICR),ERRF03   SAY REFERENCED BLK NOT IN CORE   06810001
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 06820020
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC ROUTINE         06840001
         BALR  RR,LR                   GO TO IT                         06870001
ERRF03   DC    X'0F03C0'                                          32318 06900020
         SPACE 5                                                        06930001
*              THIS ROUTINE PROVIDES AN ALTERNATIVE WAY OF DETERMINING  06960001
*        THE BLOCK NUMBER OF THE REFERENCED BLOCK WHEN THE REFERENCE IS 06990001
*        AN OVERFLOW DIC REF. (IF THE OFLO REF WERE USED IT COULD       07020001
*        INVOLVE LOADING THE OFLO BLOCK INTO CORE, WHICH COULD CAUSE    07050001
*        THE REFERENCED BLOCK TO BE SPILLED, THUS INVALIDATING THE ABS  07080001
*        ADDRESS.)                                                      07110001
*                                                                       07140001
ZAROFR   L     GRC,PAR2(DICR)          LOAD ABS ADDR                    07170001
         LR    GRD,GRC                 COPY IT                          07200001
         S     GRD,DICTSZ(DICR)        SUBTRACT BLK SIZE FROM ABS ADDR  07230001
         SR    GRE,GRE                 ZERO BLK NO                      07260001
         LA    GRA,DSLOTS+24           POINT AT DSLOTS                  07290001
*                                                                       07320001
ZARDSL   TM    0(GRA),X'F0'            TEST IF BLK IS IN CORE           07350001
         BC    BNM,ZARBDP            NO,BUMP DSLOT POINTER              07380001
*                                                                       07410001
         L     GRB,0(GRA)              LOAD BLK ADDR                    07440001
         N     GRB,STBITS              REMOVE STATUS BITS               07470001
*                                                                       07500001
         CR    GRC,GRB                 TEST IF ABS ADDR < BLK ADDR      07530001
         BC    BL,ZARBDP             YES, BUMP DSLOT POINTER            07560001
         CR    GRD,GRB                 TEST IF ABS ADDR < BLK ADDR +    07590001
*                                    BLK SIZE                           07620001
         BC    BNL,ZARBDP            NO, BUMP DSLOT POINTER             07650001
*                                                                       07680001
         MVC   ZARSLL+3(1),ZSHIFT+3(DICR) MAKE SHIFT TO BUILD NEW REF   07710001
ZARSLL   SLL   GRE,0                   CONSTRUCT BLK NO OF REF BLK      07740001
         ST    GRE,PAR1(DICR)          STORE BLK NO IN PAR1             07770001
         BC    B,ZARALL                RETURN TO USE BLK NO             07800001
*                                                                       07830001
ZARBDP   LA    GRA,4(GRA)              BUMP DSLOT POINTER               07860001
         CLI   1(GRA),X'FF'            TEST IF DSLOT STOPPER REACHED    07890001
         BC    BE,ZARERR             YES, DIAGNOSE AND ABORT            07920001
*                                                                       07950001
         LA    GRE,1(GRE)              BUMP BLK NO                      07980001
         BC    B,ZARDSL                LOOP TO TEST NEXT BLK            08010001
         EJECT                                                          08040001
*        ROUTINE ZDRFAB                                                 08070001
*                       THIS ROUTINE TAKES A DICTIONARY REFERENCE AND   08100001
*        CONVERTS IT TO AN ABSOLUTE ADDRESS. IF BLOCK IS NOT IN CORE    08130001
*        THEN TRYMRD IS ENTERED IN ORDER TO GET THE BLOCK INTO CORE     08160001
*        THE DICTIONARY REFERENCE IS FOUND IN PARAMETER 1 (PAR1). THE   08190001
*        ABSOLUTE ADDRESS IS RETURNED IN PAR1. THE LAST-LOOK ENTRY IS   08220001
*        ALWAYS MADE SINCE THIS ROUTINE IS ALWAYS CALLED FROM ZDICRF    08250001
*        ETC. ZDICRF DOES NOT MAKE ENTRIES INTO THE LAST-LOOK TABLE     08280001
*        DIRECTLY.                                                      08310001
         SPACE                                                          08340001
*                   ( YOU'VE GOT TO HAVE FAITH IN ZDRFAB, I TELL YOU )  08370001
         SPACE                                                          08400001
         SPACE 2                                                        08430001
*              HOUSEKEEPING FOR ZDRFAB                                  08460001
*                                                                       08490001
ZDRFAB   STM   14,CNTL2,12(DICR)       SAVE CALLERS REGISTERS           08520001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  08550001
         L     CNTL3,BASES             AND SECOND BASE                  08580001
         ST    DICR,DICTEM             STORE CALLERS SAVE AREA ADDR     08610001
         L     DICR,DADDR              POINT AT DICT                    08640001
         SPACE 3                                                        08670001
*        IF THE LOCK SLOT CONTAINS AN OVERFLOW REFERENCE AT ENTRY H244  08700001
*        TO ZDRFAB THIS WILL MAKE THINGS DIFFICULT FOR DFREE, SO  H244  08730001
*        AT THIS POINT THE CORRECT BLOCK NUMBER IS OBTAINED AND   H244  08760001
*        PLACED IN THE LOCK SLOT.                                 H244  08790001
         SPACE                                                          08820001
         SPACE                                                          08850001
         SPACE                                                          08857001
         CLC   PREVLOK(2),LOCK(DICR)    IS THIS SAME AS LAST LOCK H244  08864001
         BE    ZRACON                  BRANCH IF SO               H244  08871001
         MVC   LOKSV(2),LOCK(DICR)     SAVE LOCK SLOT FOR THIS    H244  08878001
         NI    LOKSV+1,X'FC'           REMOVE FLAG BITS.          60026 08881072
         MVC   PREVLOK(2),LOCK(DICR)   CALL AND NEXT              H244  08885001
         SPACE                                                          08892001
         CLC   LOCK(2,DICR),ZEROS      IS A BLOCK LOCKED          H244  08899001
         BE    ZRACON                  BRANCH IF NOT              H244  08910001
         SPACE                                                          08940001
         TM    OFLOSW,X'FF'            DOES OVERFLOW BLK EXIST    H244  08970001
         BZ    ZRACON                  BRANCH IF NOT              H244  09000001
         SPACE                                                          09030001
         MVC   TEMPX(2),PAR1+2(DICR)    SAVE DICT REF PASSED      H244  09060001
         MVC   PAR1+2(2,DICR),LOCK(DICR) POINT GRA AT DSLOT       H244  09090001
         BAL   RR,CONSLD               FOR LOCKED BLOCK           H244  09120001
         CLI   5(GRA),X'FF'            IS IT LAST DICT BLK        H244  09150001
         BNE   ZRALOK2                 BRANCH IF NOT              H244  09180001
         SPACE                                                          09210001
         CLC   TEMPX(2),LOCK(DICR)     IS DICREF PASSED SAME AS   H244  09240001
*                                      DICREF IN LOCK             H244  09270001
         BNE   ZRALOK1                 BRANCH IF NOT              H244  09300001
         SPACE                                                          09330001
         MVI   LOKSW,X'FF'             YES,SO SET SWITCH          H244  09360001
         B     ZRACON                  AND BRANCH                 H244  09390001
         SPACE                                                          09420001
*        IF HERE LOCK SLOT CONTAINS AN OVERFLOW DICT REF,         H244  09450001
*        DIFFERENT FROM THAT PASSED TO ZDRFAB IN PAR1             H244  09480001
         SPACE                                                          09510001
ZRALOK1  TM    0(GRA),X'80'            IS OVERFLOW BLK IN CORE    H244  09540001
         BO    ZRALOK3                 BRANCH IF SO               H244  09570001
         SPACE                                                          09600001
         DC    X'0000'       STOP IF OFLO BLK HAS SPILLED.        62615 09630072
         SPACE                                                          10200001
ZRALOK3  L     GRB,0(GRA)              LOAD OFLO BLK ADDR         H244  10230001
         N     GRB,STBITS              ZERO STATUS BYTE           H244  10260001
         NC    LOKSV(2),ZMASK(DICR)      GET OFFSET OF DIC. REF.  H244  10290020
         AH    GRB,LOKSV               CALC. ABS. A(OFL. ENTRY)   H244  10320020
         MVC   LOKSV(2),0(GRB)         PUT TRUE BLK NO IN LOCK    H244  10350001
         SPACE                                                          10380001
ZRALOK2  MVC   PAR1+2(2,DICR),TEMPX     RESTORE PAR1              H244  10410001
         SPACE                                                          10440001
*              FIND THE BLOCK, EXAMINE STATUS AND GET IT INTO CORE      10470001
*                                                                       10500001
ZRACON   BAL   RR,CONSLD               TO POINT GRA AT CORRECT DSLOT    10530001
         CLI   0(GRA),X'FF'            TEST IF BLOCK IS IN USE          10560001
         BC    BE,BLKERR             NO, DIAGNOSE ERROR AND ABORT       10590001
*                                                                       10620001
         TM    0(GRA),X'80'            TEST IF BLOCK IS IN CORE         10650001
         BC    BO,ZRABIC             YES, OMIT CODE TO GET BLK IN CORE  10680001
*                                                                       10710001
         MVC   RDTTR(3),1(GRA)         PASS TRYMRD REL TRK ADDR OF BLK  10740001
         BAL   RR,TRYMRD               TO GET BLOCK INTO CORE           10770001
         ST    GR0,0(GRA)              STORE BLOCK ADDR IN DSLOTS       10800001
         MVI   0(GRA),X'84'            SET STATUS AS IN CORE AND BUSY   10830001
*                                                                       10860001
ZRABIC   L     GRB,0(GRA)              LOAD BLOCK ADDR FROM DSLOTS      10890001
         N     GRB,STBITS              ZERO STATUS BYTE                 10920001
         SPACE                                                          10950001
*              TEST TYPE OF CALL TO ZDRFAB                              10980001
*                                                                       11010001
ZRATYP   CLI   SWTCH,X'00'             TEST FOR A CALL FROM ZDICRF      11040001
         BC    BNE,ZRADRF            YES, GOTO ZRADRF ROUTINE           11070001
*                                                                       11100001
         TM    OFLOSW,X'FF'            TEST IF OFLO BLOCK EXISTS        11130001
         BC    BZ,ZRALLK             NO, BRANCH FOR A NORMAL CALL       11160001
*                                                                       11190001
         CLI   5(GRA),X'FF'            TEST IF REF IS TO LAST DIC BLOCK 11220001
         BC    BE,ZRAOFB             YES, BRANCH FOR AN OFLO DIC REF    11250001
         SPACE                                                          11280001
*              ADD DICT REF TO LAST LOOK TABLE                          11310001
*                                                                       11340001
ZRALLK   MVC   LASLOK-2(6),LASLOK                                       11370001
         MVC   LASLOK+4(2),PAR1+2(DICR)                                 11400001
         SPACE                                                          11430001
*              TEST FOR 2ND HALF OF AN OVERFLOW REFERENCE CONVERSION    11460001
*                                                                       11490001
ZRAOFS   BC    NOP,ZRAOFA              *MODIFIED INSTRUCTION*           11520001
         SPACE                                                          11550001
*              NORMAL CALL                                              11580001
*                                                                       11610001
         NC    PAR1+2(2,DICR),ZMASK(DICR) CONSTRUCT OFFSET OF DIC REF   11640001
         LH    GRA,PAR1+2(DICR)        LOAD SLOT NO OF DICT REF         11670001
         SRL   GRA,1                   CONVERT SLOT NO TO A SLOT INDEX  11700001
         L     GRC,FONOF(DICR)         LOAD OFFSET OF FON               11730001
         AR    GRC,GRB                 POINT AT FON                     11760001
         AH    GRB,2(GRC,GRA)          ADD ABS OFFSET TO BLOCK ADDR     11790001
         SPACE                                                          11820001
*              STORE REQUIRED ABSOLUTE ADDRESS AND RETURN TO CALLER     11850001
*                                                                       11880001
ZRASTA   ST    GRB,PAR1(DICR)          PAR1 HOLDS ABS ADDR              11910001
         L     DICR,DICTEM             POINT AT CALLERS SAVE AREA       11940001
         BC    B,RETRTN                RETURN ROUTINE                   11970001
         SPACE 5                                                        12000001
*              A CALL FROM ZDICRF                                       12030001
*                                                                       12060001
ZRADRF   ST    GRB,PAR2(DICR)          STORE BLOCK ADDR                 12090001
         A     GRB,ZNXTOF(DICR)        CALC ADDR OF NEW DICT ENTRY      12120001
         BC    B,ZRASTA                                                 12150001
         SPACE 3                                                        12180001
*              AN OVERFLOW REFERENCE                                    12210001
*                                                                       12240001
ZRAOFB   NC    PAR1+2(2,DICR),ZMASK(DICR) CONSTRUCT OFFSET OF DIC REF   12270001
         AH    GRB,PAR1+2(0,DICR)      CALC ABS ADDR OF OFLO ENTRY      12300046
         MVC   PAR1+2(2,DICR),0(GRB)   MOVE TRUE BLOCK NO INTO PAR1     12330001
         LH    GRC,2(GRB)              LOAD TRUE OFFSET INTO GRC        12360001
         MVI   ZRAOFS+1,X'F0'          SET OFLO SWITCH TO BRANCH        12390001
         SPACE                                                          12420001
         CLI   LOKSW,X'FF'             IS LOCK SWITCH ON          H244  12450001
         BNE   ZRACON                  NO, SO LOOP TO GET TRUE BLKH244  12480001
         SPACE                                                          12510001
         MVI   LOKSW,X'00'             YES, SO SET SWITCH OFF     H244  12540001
         MVC   LOKSV(2),0(GRB)         AND PUT TRUE LOCKED BLK NO H244  12570001
*                                      IN LOCK SLOT               H244  12600001
         BC    B,ZRACON                LOOP TO GET TRUE BLK INTO CORE   12630001
         SPACE 3                                                        12660001
*              AN OVERFLOW REFERENCE (2ND PART)                         12690001
*                                                                       12720001
ZRAOFA   AR    GRB,GRC                 ADD TRUE BLK ADDR AND TRUE OFFST 12750001
         MVI   ZRAOFS+1,X'00'          RESTORE OFLO SWITCH              12780001
         BC    B,ZRASTA                                                 12810001
         EJECT                                                          12840001
*        ROUTINES ZNALAB,ZDICAB,ZNALRF,ZDICRF                           12870001
*                       THIS ROUTINE WILL MAKE A DICTIONARY ENTRY.      12900001
*        BLOCKS ARE AUTOMATICALLY SPANNED. NO ENTRY IS MADE ACROSS A    12930001
*        BLOCK BOUNDARY. THE N ROUTINES WILL MAKE ENTRIES AT THE NEXT   12960001
*        AVAILABLE LOCATION,OTHERWISE ENTRIES ARE ALIGNED ON THE NEXT   12990001
*        FULL WORD BOUNDARY.                                            13020001
*              THE SEQUENCE OF OPERATIONS IS AS FOLLOWS                 13050001
*             1) THE LENGTH OF THE ENTRY IS CHECKED TO SEE IF IT WILL   13080001
*            FIT INTO A COMPLETE DICTIONARY BLOCK. IF IT WILL NOT THEN  13110001
*            THE COMPILER CANNOT CONTINUE AND AN ABORT TAKES PLACE      13140001
*             2) THE DICT. REFERENCE TO THE NEXT AVAILABLE DICTIONARY   13170001
*            SPACE IS CONVERTED TO ABSOLUTE BY ZDRFAB. THIS ALSO ENSURE 13200001
*            S THAT THE BLOCK IS BROUGHT INTO CORE. AN ALIGNMENT ON THE 13230001
*            NEXT WORD BOUNDARY IS PERFORMED IF NECESSARY (IE THE       13260001
*            ROUTINE HAS BEEN ENTERED AT ZDICAB OR ZDICRF)              13290001
*             3) A CHECK IS MADE TO SEE IF THE  ENTRY WILL FIT INTO     13320001
*            THE REST OF THE CURRENT BLOCK. IF THE ENTRY WILL NOT FIT   13350001
*            THEN A BRANCH TO NEWBLK IS PERFORMED.                      13380001
*             4) THE ENTRY IS MOVED INTO THE BLOCK BY A MOVE-CHARACTERS 13410001
*            LOOP AT MOVLOP. IF A ZERO LENGTH ENTRY (FOR ZERO LENGTH    13440001
*            BIT STRINGS ETC) IS REQUIRED THIS LOOP IS BYPASSED.        13470001
*             5) THE ADDRESS OF THE LOCATION IMMEDIATELY AFTER THE LAST 13500001
*            POINT IN THE ENTRY IS CONVERTED TO A REFERENCE BY ENTRY TO 13530001
*            ZDABRF                                                     13560001
*             6) RETURN                                                 13590001
*             7) IF A NEW BLOCK IS REQUIRED, A DICTIONARY STOPPER,      13620001
*            X'CF',IS ENTERED FOLLOWED BY A REFERENCE TO THE NEXT BLOCK 13650001
*            TRYMRD IS ENTERED TO OBTAIN THE NEW BLOCK. THE NEW BLOCKS  13680001
*            ADDRESS IS ENTERED IN THE NEXT AVAILABLE SPACE IN THE      13710001
*            DICTIONARY BLOCK CONTROL AREA,DSLOTS. IT IS MARKED AS IN   13740001
*            CORE AND BUSY                                              13770001
*              THERE ARE TWO CONDITIONS WHICH WILL CAUSE THE COMPILER   13800001
*        TO TERMINATE- ENTRY TOO LONG AND DICTIONARY IS FULL.           13830001
         SPACE 2                                                        13860001
SWTCH    DC    X'00'                                                    13890001
ZNALAB   STM   14,CNTL2,12(DICR)    STORE BASES                         13920001
          L    CNTL2,BASOF(CNTL)                                        13950001
          MVI   SWTCH,X'81'        SET NALAB SWITCH                     13980001
         BC    B,DICST                                                  14010001
ZDICAB   STM   14,CNTL2,12(DICR)    STORE BASES                         14040001
          L    CNTL2,BASOF(CNTL)     LOAD FIRST BASE REGISTER           14070001
          MVI   SWTCH,X'41'        SET DICAB SWITCH                     14100001
         BC    B,DICST                                                  14130001
ZNALRF   STM   14,CNTL2,12(DICR)    STORE BASES                         14160001
          L    CNTL2,BASOF(CNTL)     LOAD FIRST BASE REGISTER           14190001
          MVI   SWTCH,X'82'        SET NALRF SWITCH                     14220001
         BC    B,DICST                                                  14250001
ZDICRF   STM   14,CNTL2,12(DICR)    STORE BASES                         14280001
          L    CNTL2,BASOF(CNTL)     LOAD FIRST BASE REGISTER           14310001
          MVI   SWTCH,X'42'        SET DICRF SWITCH                     14340001
         SPACE                                                          14370001
DICST    L     CNTL3,BASES             LOAD SECOND BASE REGISTER        14400001
         LA    GRA,SAVARD              POINT AT A NEW SAVE AREA         14430001
         ST    13,4(GRA)               CHAIN BACK                       14460001
         ST    GRA,8(13)               CHAIN FORWARD                    14490001
         L     DICR,DADDR              POINT AT DICT                    14520001
         SPACE                                                          14550001
*              TEST IF THIS ENTRY WILL FIT INTO A BLOCK                 14580001
*                                                                       14610001
         L     GRA,DICTSP(DICR)        LOAD USEABLE DICT SPACE VALUE    14640001
         LM    GRD,GRE,PAR1(DICR)       LOAD ENTRY ADDR AND LENGTH      14670001
         CR    GRA,GRE                 TEST IF ENTRY WILL FIT IN A BLK  14700001
         BC    BL,ERRF04             NO, DIAGNOSE AND ABORT             14730001
         SPACE                                                          14760001
*              FIND 1ST POSSIBLE SPACE FOR DICT ENTRY                   14790001
*                                                                       14820001
         LH    GRG,ZNXTD+2(DICR)       LOAD ZNXTD INTO GRG              14850001
         N     GRG,NEGBIT              CLEAR TOP HALF WORD              14880001
         STH   GRG,PAR1+2(DICR)        PAR1 HOLDS 1ST POSS DIC REF      14910001
         LA    DICR,SAVARD             POINT AT A SAVE AREA             14940001
         BAL   RR,ZDRFAB               GET ABS ADDR OF NEXT DICT SPACE  14970001
         L     DICR,DADDR              POINT AT DICT AGAIN              15000001
         LM    GRB,GRC,PAR1(DICR)      LOAD DIC ENTRY SPACE AND START   15030001
*                                    OF BLOCK                           15060001
         ST    GRE,PAR2(DICR)          RESTORE ENTRY LENGTH             15090001
         SPACE                                                          15120001
*              CORRECT FOR ALIGNED ENTRIES                              15150001
*                                                                       15180001
         TM    SWTCH,X'80'             IS ALIGNMENT REQUIRED            15210001
         BC    BO,ZDETEF             OMIT NEXT INSTNS IF NOT            15240001
         MVC   0(3,GRB),ZEROS          ZERO BYTES BETWEEN ENTRIES       15270001
         A     GRB,THREE               ALIGN ENTRY ADDR ON NEXT FULL    15300001
         N     GRB,MASKX             WORD                               15330001
         SPACE                                                          15360001
*              TEST IF ENTRY WILL FIT IN EXISTING BLOCK                 15390001
*                                                                       15420001
ZDETEF   AR    GRA,GRC                 GRA NOW POINTS AT END OF BLOCK   15450001
         LR    GRF,GRB                 COPY DIC ENTRY ADDR              15480001
         AR    GRF,GRE               ADD ENTRY LENGTH TO POINT AT END   15510001
         CR    GRF,GRA                 TEST IF ENTRY FITS EXISTING BLK  15540001
         BC    BH,ZDENBK             NO, GET A NEW DIC BLK              15570001
         SPACE                                                          15600001
*              MARK END OF PRESENT DICT                                 15630001
*                                                                       15660001
ZDEMED   MVI   0(GRF),X'ED'                                             15690001
         SPACE                                                          15720001
*              UPDATE ZNXTOF                                            15750001
*                                                                       15780001
         SR    GRF,GRC                 CALC OFFSET OF NEXT ENTRY        15810001
         ST    GRF,ZNXTOF(DICR)        STORE NEW OFFSET VALUE           15840001
         SPACE                                                          15870001
*              MOVE THE DICTIONARY ENTRY INTO THE BLOCK                 15900001
*                                                                       15930001
ZDEMEI   LR    GRF,GRB                 COPY DIC ENTRY ADDR              15960001
         LTR   GRE,GRE                 TEST IF ENTRY HAS ZERO LENGTH    15990001
         BC    BZ,ZDEONE             YES, OMIT THE MOVE                 16020001
*                                                                       16050001
ZDETEL   C     GRE,TW56                TEST IF LENGTH MORE THAN 256     16080001
         BC    BNH,ZDEMLE            NO, BRANCH TO PERFORM FINAL MOVE   16110001
*                                                                       16140001
         MVC   0(256,GRF),0(GRD)       MOVE 256 BYTES OF ENTRY IN       16170001
         A     GRF,TW56                BUMP ENTRY ADDR BY 256           16200001
         A     GRD,TW56                BUMP DICT ADDR BY 256            16230001
         S     GRE,TW56                REDUCE ENTRY LENGTH BY 256       16260001
         BC    B,ZDETEL                LOOP FOR MORE OF ENTRY           16290001
*                                                                       16320001
ZDEMLE   BCTR  GRE,0                   REDUCE ENTRY LENGTH BY 1 FOR MVC 16350001
         STC   GRE,ZDEMVC+1            INSERT CORRECTED LENGTH          16380001
ZDEMVC   MVC   0(0,GRF),0(GRD)         MOVE LAST PART OF ENTRY IN       16410001
         SPACE                                                          16440001
*              ONCE ONLY CODE. STORE THE 1ST DIC REF IN FSTDRF. MODIFY  16470001
*        TWO INSTNS IN ZDENBK.                                          16500001
*                                                                       16530001
ZDEONE   BC    NOP,ZDESPR              * PERM BRANCH AFTER 1ST USE      16560001
         MVI   ZDEONE+1,X'F0'          MAKE PREV INSTN A BRANCH         16590001
         STH   GRG,FSTDRF+2(DICR)      SET 1ST DIC REF                  16620001
         SPACE                                                          16650001
*              SET DIC REF AND ABS ADDR IN PAR1 AND PAR4 FOR RETURN     16680001
*                                                                       16710001
ZDESPR   TM    SWTCH,X'01'             TEST IF ABS ADDR REQD            16740001
         BC    BZ,ZDEREF             NO, BRANCH TO STORE DIC REF        16770001
*                                                                       16800001
         ST    GRB,PAR1(DICR)          STORE ABS ADDR                   16830001
         STH   GRG,PAR4+2(DICR)        STORE DIC REF                    16860001
         BC    B,ZDERET                OMIT DIC REF AND OFFSET PROCESS  16890001
*                                                                       16920001
ZDEREF   STH   GRG,PAR1+2(DICR)        STORE DIC REF                    16950001
         ST    GRB,PAR4(DICR)          STORE ABS ADDR                   16980001
         SPACE                                                          17010001
*              MAKE THE OFFSET SLOT ENTRY                               17040001
*                                                                       17070001
         SR    GRB,GRC                 CALC OFFSET OF DIC ENTRY         17100001
*                                                                       17130001
         A     GRC,FONOF(DICR)         POINT AT FON                     17160001
         LH    GRA,0(GRC)              LOAD FON                         17190001
         CH    GRA,MAXFON(DICR)        TEST IF FON TOO LARGE            17220001
         BC    BH,ZDEOFE             YES, BRANCH TO MAKE AN OFLO ENTRY  17250001
*                                                                       17280001
         LR    GRD,GRA                 COPY FON                         17310001
         AR    GRD,GRD                 DOUBLE FON TO MAKE SLOT OFFSET   17340001
         STH   GRB,2(GRD,GRC)          STORE OFFSET IN REQD OFFSET SLOT 17370001
         SPACE                                                          17400001
*              UPDATE FON                                               17430001
*                                                                       17460001
         LA    GRA,1(GRA)              BUMP FON BY 1                    17490001
         STH   GRA,0(GRC)              STORE NEW FON                    17520001
         SPACE                                                          17550001
*              UPDATE ZNXTD                                             17580001
*                                                                       17610001
         LA    GRG,4(GRG)              BUMP ZNXTD BY 4                  17640001
         ST    GRG,ZNXTD(DICR)         STORE NEW ZNXTD                  17670001
         SPACE                                                          17700001
*              HOUSEKEEPING AND RETURN                                  17730001
*                                                                       17760001
ZDERET   MVI   SWTCH,X'00'             SET DICT ENTRY SWITCH OFF        17790001
         LA    DICR,SAVARD             POINT AT PRESENT SAVE AREA       17820001
         L     DICR,4(DICR)            POINT AT CALLERS SAVE AREA       17850001
         BC    B,RETRTN                RETURN ROUTINE                   17880001
         EJECT                                                          17910001
*              CREATE A NEW DICTIONARY BLOCK                            17940001
         SPACE 2                                                        17970001
ZDENBK   EQU   *                                                        18000001
         SPACE                                                          18030001
*              CALCULATE NEW BLOCK NUMBER AND ZNXTD                     18060001
*                                                                       18090001
         MVC   ZDESRL+3(1),ZSHIFT+3(DICR) MAKE SHIFT TO REDUCE DIC REF  18120001
         MVC   ZDESLL+3(1),ZSHIFT+3(DICR) MAKE SHIFT TO BUILD NEW REF   18150001
ZDESRL   SRL   GRG,0                   *MOD INSTN* SHIFT BLOCK NO RIGHT 18180001
         LA    GRG,1(GRG)              BUMP BLOCK NO BY 1               18210001
         LR    GRB,GRG                 COPY NEW BLOCK NO                18240001
ZDESLL   SLL   GRG,0                   *MOD INSTN* RESTORE NEW BLOCK NO 18270001
         STH   GRG,ZNXTD+2(DICR)       STORE NEW ZNXTD                  18300001
         SPACE                                                          18330001
*              MARK END OF OLD BLOCK                                    18360001
*                                                                       18390001
ZDEMOB   CLI   DICTSZ+2(DICR),X'04'    TEST IF USING 1K BLKS            18420001
         BC    BNE,ZDEFEB            NO,MARK EOB                        18450001
         CLI   ZNXTD+2(DICR),X'02'     TEST IF 1ST DIC BLK JUST FULL    18480001
         BC    BE,ZDETNB             YES, DO NOT MARK EOB               18510001
ZDEFEB   L     GRA,PAR1(DICR)          POINT AT END OF LAST DIC ENTRY   18540001
         MVI   0(GRA),X'CF'            MAKE END OF BLOCK MARKER         18570001
         MVC   1(2,GRA),ZNXTD+2(DICR)  PUT NEW DIC REF AFTER EOB MARK   18600001
       SPACE                                                            18630001
*              TEST IF A NEW DICT BLOCK CAN BE MADE                     18660001
*                                                                       18690001
ZDETNB   AR    GRB,GRB                 CALC 4 TIMES BLK NO              18720001
         AR    GRB,GRB                                                  18750001
         LA    GRA,DSLOTS+24(GRB)      POINT AT DSLOTS SLOT FOR NEW BLK 18780001
         CLI   5(GRA),X'FF'            TEST FOR LAST BLOCK,       47635 18800056
*                                    ( I.E. THE OVERFLOW BLOCK.). 47635 18820056
         BC    BE,ERRF0D             YES, DIAGNOSE AND ABORT            18840001
         SPACE                                                          18870001
*              TEST IF THE NEW BLOCK ALREADY EXISTS                     18900001
*                                                                       18930001
         L     GR0,0(GRA)              LOAD BLK ADDR IN CASE IT IS FREE 18960001
         TM    0(GRA),X'F0'            TEST IF BLOCK IS IN CORE         18990001
         BC    BM,ZDENBA             YES, OMIT CALL TO TRYMRD           19020001
         SPACE                                                          19050001
*              GET THE NEW BLOCK INTO CORE                              19080001
*                                                                       19110001
         XC    RDTTR(4),RDTTR          SAY NO READ REQD IN TRYMRD       19140001
         BAL   RR,TRYMRD               GET A NEW DICT BLOCK             19170001
         SPACE                                                          19200001
*              GET NEW BLOCK ADDR AND UPDATE DSLOTS                     19230001
*                                                                       19260001
         ST    GR0,0(GRA)              SET NEW BLOCK ADDR IN DSLOTS     19290001
ZDENBA   MVI   0(GRA),X'84'            MARK NEW BLK AS IN CORE AND BUSY 19320001
         N     GR0,STBITS              CLEAR STATUS BYTE IN BLOCK ADDR  19350001
         SPACE                                                          19380001
*              SET REGISTERS TO POINT AT NEW BLOCK CORRECTLY            19410001
*                                                                       19440001
         LR    GRB,GR0                 POINT AT ADDR FOR DIC ENTRY      19470001
         LR    GRC,GR0                 POINT AT START OF BLK            19500001
         LR    GRF,GR0                 COPY ENTRY ADDR                  19530001
         AR    GRF,GRE               ADD ENTRY LEN TO POINT AT END      19560001
         SPACE                                                          19590001
*              SET FON IN NEW DICT BLOCK                                19620001
*                                                                       19650001
         L     GRA,FONOF(DICR)                                          19680001
         AR    GRA,GR0                 POINT AT FON IN NEW DICT BLOCK   19710001
         MVC   0(2,GRA),ZEROS          SET FON TO ZERO                  19740001
         SPACE                                                          19770001
*              RETURN TO MAKE DICT ENTRY                                19800001
*                                                                       19830001
         BC    B,ZDEMED                                                 19860001
         SPACE 5                                                        19890001
*              MAKE AN OVERFLOW DICTIONARY ENTRY                        19920001
*                                                                       19950001
ZDEOFE   LA    RR,ZDERET               LOAD RETURN ADDR                 19980001
         BC    B,ZOFLOR                GO TO MAKE AN OFLO DIC REF       20010001
         SPACE 5                                                        20040001
*              DICTIONARY ENTRY ERROR MESSAGES                          20070001
*                                                                       20100001
ERRF04   MVC   PAR6+1(3,DICR),ERRM04   SAY DICT ENTRY IS TOO LONG       20130001
         MVI   SWTCH,X'00'         REINITIALISE SWITCH                  20160001
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC ROUTINE         20190001
         BALR  RR,LR                   AND BRANCH TO IT                 20220001
*                                                                       20250001
ERRF0D   L     RR,PAR1(DICR)           * POINT AT END OF LAST     60039 20280072
         MVI   0(RR),X'ED'             * ENTRY & MARK AS E.O.D.   60039 20290072
         LA    GR0,ERRMS               SAY TOO MANY DICT BLOCKS   52214 20300021
         ST    GR0,PAR1(DICR)                                           20310001
         MVI   SWTCH,X'00'         REINITIALISE SWITCH                  20340001
         LA    13,ZSAV(0,DICR)         SET UP SAVE AREA FOR ZUPL  33893 20350020
         BAL   RR,ZUPL                 PRINT ERROR MSG ONLINE           20370001
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN  33893 20380020
         LA    GR0,16                                                   20400001
         ST    GR0,ERCODE(DICR)        SET TERMINAL ERROR CODE          20430001
         L     LR,ABORTOF(CNTL)        POINT AT ABORT ROUTINE           20460001
         BALR  RR,LR                   AND BRANCH TO IT                 20490001
*                                                                       20520001
ERRM04   DC    X'0F0440'                                          23286 20550001
         EJECT                                                          20580001
*              STORE CALLERS REGISTERS                                  20610001
*                                                                       20640001
ZOFLOR   STM   GR0,GRB,OFRSAV                                           20670001
         SPACE                                                          20700001
*              STORE BLOCK NO OF TRUE DIC REF IN OFENTY                 20730001
*                                                                       20760001
         L     GRA,PAR1(DICR)          LOAD DIC REF                     20790001
         N     GRA,ZMASK(DICR)         MAKE IT A BLOCK NO ONLY          20820001
         STH   GRA,OFENTY              STORE BLOCK NO IN OFENTY         20850001
         SPACE                                                          20880001
*              STORE OFFSET OF TRUE DIC REF IN OFENTY                   20910001
*                                                                       20940001
         STH   GRB,OFENTY+2                                             20970001
         SPACE                                                          21000001
*              CHECK EXISTENCE OF OVERFLOW BLOCK                        21030001
*                                                                       21060001
         L     GRA,ZOBSAD(DICR)        LOAD OFLO BLOCK SLOT ADDR        21090001
         CLI   0(GRA),X'FF'            TEST IF BLOCK IS IN USE          21120001
         BC    BE,OFINIT             NO, GET AND INITIALIZE OFLO BLOCK  21150001
         TM    0(GRA),X'80'            TEST IF BLOCK IS IN CORE         21180001
         BC    BZ,OFGTIN             NO, GET OFLO BLOCK INTO CORE       21210001
         SPACE                                                          21240001
*              TEST IF A NEW OVERFLOW DICT REF CAN BE MADE              21270001
*                                                                       21300001
OFTNDR   L     GRB,OFENOF(DICR)   AND NEW OFLO ENTRY OFFSET AND         21330001
         N     GRB,OFDCRF            OFLO BLOCK NO, IF RESULT NOT ZERO  21360001
         BC    BNZ,OFERRA            THERE ARE TOO MANY OFLO ENTRIES    21390001
         SPACE                                                          21420001
*              MAKE A NEW OVERFLOW DIC REF                              21450001
*                                                                       21480001
         L     GRB,OFENOF(DICR)   OR NEW OFLO ENTRY OFFSET,AND          21510001
         O     GRB,OFDCRF            OFLO BLOCK NO, RESULT NEW DIC REF  21540001
         ST    GRB,PAR1(DICR)          STORE NEW DIC REF.               21570001
         SPACE                                                          21600001
*              MOVE NEW OVERFLOW ENTRY IN                               21630001
*                                                                       21660001
         L     GRA,0(GRA)              LOAD OFLO BLOCK ADDR             21690001
         L     GRB,OFENOF(DICR)   LOAD OFFSET OF NEW OFLO ENTRY         21720001
         AR    GRA,GRB                 POINT AT POSN OF NEW OFLO ENTRY  21750001
         MVC   0(4,GRA),OFENTY         MOVE NEW OFLO ENTRY IN           21780001
         SPACE                                                          21810001
*              BUMP OFFSET OF NEXT ENTRY                                21840001
*                                                                       21870001
         LA    GRB,4(GRB)              BUMP OFLO ENTRY OFFSET           21900001
         ST    GRB,OFENOF(DICR)   STORE NEW OFLO ENTRY OFFSET           21930001
         SPACE                                                          21960001
*              RETURN TO CALLER                                         21990001
*                                                                       22020001
         LM    GR0,GRB,OFRSAV                                           22050001
         BCR   BR,RR                                                    22080001
         SPACE                                                          22110001
*              INITIALISATION FOR OVERFLOW BLOCK                        22140001
*                                                                       22170001
OFINIT   LH    GRB,ZOBNUM(DICR)        LOAD OFLO BLOCK NO               22200001
         MVC   OFBNSL+3(1),ZSHIFT+3(DICR) SET SHIFT VALUE IN NEXT INSTN 22230001
OFBNSL   SLL   GRB,0                   SHIFT OFLO BLK NO TO MAKE DIC RF 22260001
         ST    GRB,OFDCRF              STORE OFLO BLK DIC REF           22290001
         MVC   OFDNAM(2,DICR),MYNAM(DICR) SAY WHEN OFLO BLOCK CREATED   22320001
         MVI   OFLOSW,X'FF'            SHOW AN OFLO BLOCK EXISTS        22350001
         XC    RDTTR(4),RDTTR          SHOW NO READ REQD IN TRYMRD      22380001
         BC    B,OFGTNB                GET NEW BLOCK INTO CORE          22410001
         SPACE                                                          22440001
*              GET OVERFLOW BLOCK INTO CORE                             22470001
*                                                                       22500001
OFGTIN   DC    X'0000'       STOP IF OFLO BLK HAS SPILLED.        62615 22530072
OFGTNB   LR    GRB,RR                  HOLD ZOFLOR RETURN ADDR          22560001
         BAL   RR,TRYMRD               GET OFLO BLK INTO CORE           22590001
         LR    RR,GRB                  RESTORE ZOFLOR RETURN ADDR       22620001
         ST    GR0,0(GRA)              STORE OFLO BLK ADDR IN DSLOTS    22650001
         MVI   0(GRA),X'84'  LOCK IN OFLO BLK FOR EVER.           62615 22680072
         BC    B,OFTNDR                GO TO CONSTRUCT OFLO DIC REF     22710001
         SPACE                                                          22740001
*              TERMINAL ERROR IF TOO MANY OVERFLOW ENTRIES              22770001
*                                                                       22800001
OFERRA   LA    GR0,OFLMES              SAY TOO MANY OVFLOW ENTRIES24700 22810019
         ST    GR0,PAR1(DICR)                                     24700 22820019
         MVI   SWTCH,X'00'             REINITIALISE SWITCH        24700 22830019
         BAL   RR,ZUPL                 PRINT ERROR MSG ONLINE     24700 22840019
         LA    GR0,16                                             24700 22850019
         ST    GR0,ERCODE(DICR)        SET TERMINAL ERROR CODE    24700 22860019
         L     LR,ABORTOF(CNTL)        POINT AT ABORT ROUTINE     24700 22870019
         BALR  RR,LR                   AND BRANCH TO IT           24700 22880019
         SPACE                                                          22920001
*              OVERFLOW CONSTANTS                                       22950001
*                                                                       22980001
OFLOSW   DC    X'00'                   OFLO SWITCH ON IF OFLO BK EXISTS 23040001
OFRSAV   DC    3F'0'                   OFLO REG SAVE AREA               23070001
OFENTY   DC    F'0'                    OFLO ENTRY                       23100001
OFDCRF   DC    F'0'                    DIC REF TO START OF OFLO BLOCK   23130001
         EJECT                                                          23160001
*        ROUTINE ZUTXTC                                                 23190001
*                       THIS ROUTINE FINDS A NEW TEXT BLOCK. IF A FREE  23220001
*        BLOCK EXISTS, IT IS USED. IF NO FREE BLOCKS EXIST,A LOWER      23250001
*        PRIORITY BLOCK (WANTED OR UNWANTED) IS WRITTEN ON DISK. THE    23280001
*        NEW BLOCK IS MARKED AS IN-CORE AND BUSY.                       23310001
*              IF REQUESTED BY A NON-ZERO BYTE IN PAR2+3, THE CURRENT   23340001
*        BLOCK IS CHAINED TO THE NEW BLOCK AND THE STATUS OF THE CURREN 23370001
*        T BLOCK IS CHANGED. FOUR STATUS BYTES EXIST                    23400001
*             1) X'01' MEANS FREE THE BLOCK. THE INFORMATION CAN BE     23430001
*           OVERWRITTEN IF NECESSARY                                    23460001
*             2) X'02' A LOW PRIORITY OF USEFUL INFORMATION(REFERRED TO 23490001
*           AS UNWANTED). THE BLOCK IS NOT NECESSARILY IN CORE          23520001
*             3) X'03' A HIGH PRIORITY OF USEFUL INFORMATION(REFERRED   23550001
*           TO AS WANTED)                                               23580001
*             4) X'04' BUSY. THE BLOCK IS IN CORE AND WILL NOT BE       23610001
*           WRITTEN OUT                                                 23640001
*             IN THIS ROUTINE A SEARCH IS MADE FOR A X'01' BLOCK. IT    23670001
*        MUST BE NOTED THAT A X'80' BIT MEANS THAT A BLOCK IS IN CORE.  23700001
*        THUS WHEN A NEW BLOCK IS REQUIRED A SEARCH IS MADE FOR X'81'   23730001
*        BLOCK MEANING IN-CORE AND FREE.                                23760001
*             A LIST OF TEXT BLOCK ADDRESSES IS KEPT IN TSLOTS. IT IS   23790001
*        THIS LIST WHICH IS SCANNED.                                    23820001
*             IF A FREE BLOCK CANNOT BE FOUND THEN A ENTRY TO TRYMRT    23850001
*        IS MADE. THIS WILL EITHER CREATE A NEW BLOCK OR SPILL A WANT   23880001
*        OR UNWANT BLOCK ONTO DISK.                                     23910001
*             COMPILATION IS TERMINATED IF ALL TEXT BLOCKS ARE FULL,IE  23940001
*        IF TSLOTS HAS REACHED THE STOPPER                              23970001
*                                                                       24000001
         SPACE 2                                                        24030001
ZUTXTC   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               24060001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  24090001
         L     CNTL3,BASES             LOAD SECOND BASE                 24120001
         SPACE                                                          24150001
         BAL   RR,CONSLT               POINT AT CORRECT SLOT IN TSLOTS  24180001
         TM    PAR2+3(DICR),X'FF'      SEE IF ZERO STATUS BYTE          24210001
         BC    BM,ZTCHAN                                                24240001
         SPACE                                                          24270001
ZTBAK    LA    GRC,TSLOTS+24           INITIALISE AT TSLOTS             24300001
         XR    GRB,GRB                 COUNT=0                          24330001
         L     GRD,0(0,GRA)            PICK UP ADDRESS OF BLOCK         24360001
         A     GRD,TXTSZ(0,DICR)       ADD ON TEXT BLOCK SIZE           24390001
         SPACE                                                          24420001
ZTLOP    TM    0(GRC),X'80'            TEST IF BLOCK IN CORE            24450001
         BC    BZ,ONDSK                                                 24480001
         CLI   0(GRC),X'81'            TEST FOR FREE BLOCKS             24510001
         BC    BE,FREBLK                                                24540001
         CLI   0(GRC),X'FF'            TEST FOR FREE SLOT               24570001
         BC    BE,FRSLAT                                                24600001
ONDSK    LA    GRC,4(0,GRC)            BUMP TO NEXT SLOT IN TSLOTS      24630001
         LA    GRB,1(0,GRB)            COUNT+COUNT+1                    24660001
         CLI   1(GRC),X'FF'            TEST FOR STOPPER IN TSLOTS       24690001
         BC    BNE,ZTLOP                                                24720001
         SPACE                                                          24750001
         MVC   PAR6+1(3,DICR),ERRF06   ALL TEXT BLOCKS FULL       32318 24770020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 24790020
         LA    13,ZSAV(0,DICR)         SET UP SAVE AREA FOR ZUERR 33893 24800020
         BAL   RR,ZUERR                GO TO ERROR ROUTINE        32318 24810020
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN  33893 24820020
         L     LR,ABORTOF(CNTL)        POINT AT ZABORT                  24840001
         BALR  RR,LR                                                    24870001
ERRF06   DC    X'0F06C0'                                          32318 24880020
         SPACE                                                          24900001
ZTCHAN   TM    PAR2+3(DICR),X'80'      TEST IF CHAIN REQUIRED           24930001
         BC    BZ,NOCHAN                                                24960001
         MVI   CHANSW,X'FF'            SET CHAIN SWITCH ON              24990001
NOCHAN   TM    PAR2+3(DICR),X'07'      TEST FOR ANY STATUS CHANGE       25020001
         BC    BZ,ZTBAK                                                 25050001
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           25080001
         BC    BE,BLKERR                                                25110001
         NI    0(GRA),X'80'            CLEAR PREVIOUS STATUS BITS       25140001
         NI    PAR2+3(DICR),X'7F'      CLEAR CHAIN BIT FROM STATUS BYTE 25170001
         OC    0(1,GRA),PAR2+3(DICR)   INSERT NEW STATUS BYTE           25200001
         BC    B,ZTBAK                                                  25230001
         SPACE                                                          25260001
FREBLK   L     GR0,0(0,GRC)            PICK UP ADDRESS OF FREE BLOCK    25290001
         N     GR0,STBITS                                               25320001
         CLI   CHANSW,X'FF'            IS CHAIN SWITCH ON               25350001
         BC    BNE,NONEW                                                25380001
         STC   GRB,1(0,GRD)            STORE COUNT OF NEXT BLOCK IN     25410001
         BC    B,NONEW               CHAIN SLOT OF CURRENT BLOCK        25440001
         SPACE                                                          25470001
FRSLAT   CLI   CHANSW,X'FF'            TEST FOR CHAIN                   25500001
         BC    BNE,TCJUMP                                               25530001
         STC   GRB,1(0,GRD)            STORE COUNT OF NEXT BLK IN CHAIN 25560001
TCJUMP   XC    RDTTR(4),RDTTR          SHOW THAT NO BLOCK IS REQUIRED   25590001
         BAL   RR,TRYMRT             IN CORE AND MAKE SPACE FOR BLOCK   25620001
         ST    GR0,0(0,GRC)            PUT ADDRESS OF BLOCK IN TSLOTS   25650001
NONEW    MVI   0(GRC),X'84'            MARK AS IN-CORE AND BUSY         25680001
         MVI   CHANSW,X'00'            CLEAR CHAN-SWITCH                25710001
         ST    GR0,PAR2(0,DICR)        INSERT ABSOLUTE ADDRESS OF BLOCK 25740001
         MVI   PAR2(DICR),X'00'        CLEAR STATUS BYTE                25770001
         XC    PAR1+2(2,DICR),PAR1+2(DICR) SET OFFSET TO ZERO           25800001
         STC   GRB,PAR1+1(0,DICR)      INSERT COUNT AS REFERENCE        25830001
         LR    GRA,GR0                                                  25860001
         A     GRA,TXTSZ(0,DICR)       POINT AT END OF NEW BLOCK        25890001
         STC   GRB,5(0,GRA)            NAME THE NEW BLOCK               25920001
         SPACE                                                          25950001
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      25980001
         SPACE                                                          26010001
         EJECT                                                          26070001
*        ROUTINE ZCHAIN                                                 26100001
*                       THIS ROUTINE LOOKS AT CURRENT BLOCK (INDICATED  26130001
*        BY A TEXT REFERENCE IN PAR1(, PICKS UP CHAIN POINTER AND       26160001
*        POINTS AT NEW BLOCK. IF THE NEW BLOCK IS NOT IN CORE IT IS     26190001
*        BROUGHT INTO CORE.                                             26220001
*              THE CURRENT BLOCK NEED NOT BE IN CORE. PAR2+3 CONTAINS A 26250001
*        STATUS BYTE. THIS BYTE IS AS DESCRIBED IN ZUTXTC. THIS IS USED 26280001
*        TO MARK THE CURRENT BLOCK. IF A SIGN BIT IS PLACED IN PAR1     26310001
*        THEN THE STATUS OF THE NEXT BLOCK IN THE CHAIN IS UNCHANGED.   26340001
*              THE REFERENCE OF THE NEXT BLOCK IN THE CHAIN IS FOUND IN 26370001
*        THE LAST WORD BUT ONE IN THE TEXT BLOCK. THE LAST WORD IN THE  26400001
*        TEXT BLOCK CONTAINS THE NAME OF THE BLOCK.                     26430001
*                                                                       26460001
         SPACE 2                                                        26490001
ZCHAIN   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               26520001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  26550001
         L     CNTL3,BASES             LOAD SECOND BASE                 26580001
         SPACE                                                          26610001
         BAL   RR,CONSLT               POINT AT SLOT IN TSLOTS          26640001
         SPACE                                                          26670001
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           26700001
         BC    BE,BLKERR                                                26730001
         TM    0(GRA),X'80'            TEST IF BLOCK IN CORE            26760001
         BC    BZ,ZCGET                                                 26790001
         SPACE                                                          26820001
ZCBAK1   L     GRB,0(0,GRA)            PICK UP ADDRESS OF BLOCK         26850001
         N     GRB,STBITS              ELIMINATE STATUS BITS            26880001
         TM    PAR2+3(DICR),X'FF'      TEST IF STATUS CHANGE RQD TO     26910001
         BC    BM,CHNST              CURRENT BLOCK                      26940001
         SPACE                                                          26970001
ZCBAK2   A     GRB,TXTSZ(0,DICR)       ADD ON SPACE IN TEXT BLOCK       27000001
         XC    PAR1+2(2,DICR),PAR1+2(DICR) SET OFFSET TO ZERO           27030001
         MVC   PAR1+1(1,DICR),1(GRB)   INSERT BLOCK NUMBER OF CHAIN BLK 27060001
         BAL   RR,CONSLT               POINT AT CHAIN SLOT IN TSLOTS    27090001
         SPACE                                                          27120001
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           27150001
         BC    BE,BLKERR                                                27180001
         TM    0(GRA),X'80'            TEST IF BLOCK IN CORE            27210001
         BC    BO,ZCMARK                                                27240001
         SPACE                                                          27270001
         MVC   RDTTR(3),1(GRA)         MOVE IN TRACK ADDRESS OF BLOCK   27300001
         BAL   RR,TRYMRT               GET BLOCK INTO CORE              27330001
         ST    GR0,TEMP                PICK UP ADDRESS OF NEW BLOCK     27360001
         OI    0(GRA),X'80'            MARK BLOCK AS IN CORE            27390001
         MVC   1(3,GRA),TEMP+1         INSERT ADDRESS IN TSLOTS         27420001
         SPACE                                                          27450001
ZCMARK   TM    PAR1(DICR),X'80'        TEST IF STATUS CHANGE REQUIRED   27480001
         BC    BO,ZCJUMP                                                27510001
         MVI   0(GRA),X'84'            OTHERWISE MARK BLOCK AS BUSY     27540001
         SPACE                                                          27570001
ZCJUMP   L     GRA,0(0,GRA)            PICK UP ADDRESS OF BLOCK         27600001
         N     GRA,STBITS              REMOVE STATUS BITS               27630001
         ST    GRA,PAR2(0,DICR)        MOVE ABSOLUTE ADDRESS TO PAR2    27660001
         SPACE                                                          27690001
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      27720001
         SPACE                                                          27750001
ZCGET    MVC   RDTTR(3),1(GRA)         MOVE IN TR ACK ADDRESS OF BLOCK  27780001
         BAL   RR,TRYMRT               GET THE BLOCK INTO CORE          27810001
         ST    GR0,TEMP                PICK UP ADDRESS OF NEW BLOCK     27840001
         MVC   1(3,GRA),TEMP+1         STORE ADDRESS IN TSLOTS          27870001
         OI    0(GRA),X'80'            MARK BLOCK AS IN CORE            27900001
         BC    B,ZCBAK1                                                 27930001
         SPACE                                                          27960001
CHNST    NI    0(GRA),X'80'            CLEAR ALL EXCEPT INCORE BIT      27990001
         OC    0(1,GRA),PAR2+3(DICR)   INSERT NEW STATUS BYTE           28020001
         L     GRC,0(0,GRA)            PICK UP ADDRESS OF BLOCK         28050001
         A     GRC,TXTSZ(0,DICR)       POINT AT END OF BLOCK            28080001
         MVC   6(2,GRC),MYNAM(DICR)    MOVE IN NAME OF PHASE ISNG BLOCK 28110001
         BC    B,ZCBAK2                                                 28140001
         SPACE                                                          28170001
         EJECT                                                          28200001
*        ROUTINE ZALTER                                                 28230001
*                       THIS ROUTINE IS USED TO CHANGE THE STATUS OF A  28260001
*        TEXT BLOCK. THE BLOCK NEED NOT BE IN CORE                      28290001
*              IF THE BLOCK IS ON DISK AND IS THEN MADE FREE, THE SLOT  28320001
*        IS MARKED AS NOT IN USE (X'FF'). THE BLOCK NUMBER WILL THEN BE 28350001
*        ALLOCATED AGAIN AT A LATER DATE. THE NUMBER OF TEXT BLOCKS IS  28380001
*        REDUCED BY 1                                                   28410001
         SPACE 2                                                        28440001
ZALTER   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               28470001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  28500001
         L     CNTL3,BASES             LOAD SECOND BASE                 28530001
         SPACE                                                          28560001
         BAL   RR,CONSLT               POINT AT TSLOTS FOR THIS BLOCK   28590001
         SPACE                                                          28620001
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           28650001
         BC    BE,BLKERR                                                28680001
         NI    0(GRA),X'80'            CLEAR ALL STATI EXCEPT IN-CORE   28710001
         OC    0(1,GRA),PAR2+3(DICR) BIT. INSERT STATUS BYTE            28740001
         CLI   0(GRA),X'01'            SEE IF STATUS IS NOW ON-DISK AND 28770001
         BC    BNE,RETRTN       FREE. IF NOT,GO TO RETURNING ROUTINE    28800001
         MVI   0(GRA),X'FF'            SHOW SLOT IS FREE                28830001
         SPACE                                                          28860001
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      28890001
         EJECT                                                          28920001
*        ROUTINE ZTXTAB                                                 28950001
*                       CONVERTS A TEXT REFERENCE TO AN ABSOLUTE ADDRES 28980001
*        PAR1 WILL CONTAIN THE REFERENCE TO BE CONVERTED. IF THE BLOCK  29010001
*        IS NOT IN CORE IT WILL BE BROUGHT INTO CORE.                   29040001
*              THE BLOCK WILL BE MARKED IN-CORE AND BUSY UNLESS THERE   29070001
*        IS A SIGN BIT IN PAR1. IN THIS CASE THE STATUS OF THE BLOCK    29100001
*        WILL NOT CHANGE                                                29130001
         SPACE 2                                                        29160001
ZTXTAB   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               29190001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  29220001
         L     CNTL3,BASES             LOAD SECOND BASE                 29250001
         ST    DICR,DICTEM             STORE ADDRESS OF THIS SAVE AREA  29280001
         L     DICR,DADDR              POINT AT DICTIONARY              29310001
         SPACE                                                          29340001
         BAL   RR,CONSLT               POINT AT CORRECT TSLOTS SLOT     29370001
         CLC   TSLOTEND+1(3),1(GRA)    IS BLOCK TTR TOO HIGH?     30357 29380020
         BNH   BLKERR                  YES                        30357 29390020
         SPACE                                                          29400001
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           29430001
         BC    BE,BLKERR                                                29460001
         TM    0(GRA),X'80'            TEST IF BLOCK IS IN CORE         29490001
         BC    BZ,TABD                                                  29520001
         SPACE                                                          29550001
TABR     TM    PAR1(DICR),X'80'        SEE IF STATUS CHANGE REQUIRED    29580001
         BC    BO,SAME                                                  29610001
         MVI   0(GRA),X'84'            MARK AS INCORE AND BUSY          29640001
SAME     L     GRA,0(0,GRA)            PICK UP ADDRESS AND STATUS BITS  29670001
         N     GRA,STBITS              GET RID OF STATUS BITS           29700001
         AH    GRA,PAR1+2(0,DICR)      ADD OFFSET OF ORIGINAL REFERENCE 29730001
         ST    GRA,PAR1(0,DICR)        INSERT ABSOLUTE ADDRESS          29760001
         L     DICR,DICTEM             POINT AT SAVE AREA AGAIN         29790001
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      29820001
         SPACE                                                          29850001
TABD     MVC   RDTTR(3),1(GRA)         PICK UP TTR OF BLOCK             29880001
         BAL   RR,TRYMRT               GET BLOCK INTO CORE              29910001
         ST    GR0,TEMP                PICK UP ADDRESS OF BLOCK AND     29940001
         MVC   1(3,GRA),TEMP+1       STORE IN TSLOTS. STATUS LEFT ALONE 29970001
         OI    0(GRA),X'80'            MARK BLOCK AS IN CORE            30000001
         BC    B,TABR                                                   30030001
         EJECT                                                          30060001
*        ROUTINE ZTXTRF                                                 30090001
*                       THIS ROUTINE CONVERTS AN ABSOLUTE ADDRESS TO    30120001
*        A TEXT REFERENCE. PAR2 CONTAINS THE ABSOLUTE ADDRESS TO BE     30150001
*        CONVERTED. PAR1 WILL CONTAIN ANY REFERENCE FOR THE BLOCK       30180001
*        CONTAINING THE ABSOLUTE ADDRESS.                               30210001
*              IF THE REFERENCED BLOCK IS NOT IN CORE THEN THE COMPILER 30240001
*        WILL TERMINATE                                                 30270001
         SPACE 2                                                        30300001
ZTXTRF   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               30330001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  30360001
         L     CNTL3,BASES             LOAD SECOND BASE                 30390001
         SPACE                                                          30420001
         BAL   RR,CONSLT               POINT AT TSLOTS FOR THIS REFRNCE 30450001
         SPACE                                                          30480001
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           30510001
         BC    BE,BLKERR                                                30540001
         TM    0(GRA),X'80'            TEST IF BLOCK IN CORE            30570001
         BC    BZ,TRFER                                                 30600001
         SPACE                                                          30630001
         L     GR0,0(GRA)              PICK UP ADDRESS                  30660001
         N     GR0,STBITS              REMOVE STATUS BITS               30690001
         S     GR0,PAR2(0,DICR)        SUBTRACT ABSOLUTE ADDRESS TO GET 30720001
         LPR   GR0,GR0               OFFSET. SET TO A POSITIVE VALUE    30750001
         STH   GR0,PAR1+2(0,DICR)      CREATE REFERENCE                 30780001
         SPACE                                                          30810001
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      30840001
         SPACE                                                          30870001
TRFER    MVC   PAR6+1(3,DICR),ERRF05   TEXT BLOCK NOT IN CORE     32318 30890020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 30910020
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 30930001
         BALR  RR,LR                   ROUTINE IN AA                    30960001
         SPACE                                                          30990001
ERRF05   DC    X'0F05C0'                                          32318 31020020
         EJECT                                                          31050001
*              THESE INSTRUCTIONS GENERATE AN ERROR MESSAGE WHEN A      31080001
*        REFERENCED BLOCK IS NOT IN USE. THE COMPILER IS ABORTED.       31110001
*                                                                       31140001
BLKERR   MVC   PAR6+1(3,DICR),ERRF0C   REFERENCED BLOCK NOT IN USE      31170001
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 31180020
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 31200001
         BALR  RR,LR                   ROUTINE IN AA                    31230001
ERRF0C   DC    X'0F0CC0'                                          32318 31235020
         SPACE 3                                                        31240020
*              THIS ROUTINE PASSES THE NAME OF THE ACTIVE PHASE   32318 31245020
*        AT ERROR-GENERATION TIME TO ZUERR.                       32318 31250020
         SPACE 1                                                        31255020
PASMYNAM LH    GRC,MYNAM(0,DICR)       PICK UP PHASE LOADED NAME        31259021
         SH    GRC,=X'B0B0'            CHANGE TO INTERNAL CODE          31263021
         STH   GRC,NAMESL              SAVE NAME                        31267021
         LA    GRC,NAMESL              PASS ADDR OF NAME SAVE           31271021
         ST    GRC,PAR7(0,DICR)        SLOT TO MSG.                     31275021
         MVC   PAR8+2(2,DICR),K2+2     SET LGTH 2 FOR PHASE NAME  47635 31277056
         BR    RR                      ISSUE MSG.                       31279021
NAMESL   DS    H                       NAME SAVE SLOT                   31283021
         EJECT                                                          31290001
*        ROUTINE ZUGC                                                   31320001
*                       THIS ROUTINE ALLOCATES SPACE TO THE PHASES. ONE 31350001
*        4K BLOCK IS RESERVED FOR THIS PURPOSE. IF THE BLOCK IS  FULLY  31380001
*        USED A BLOCK OF TEXT OR DICTIONARY SIZE IS GIVEN. THIS IS TO   31410001
*        REDUCE THE POSSIBILITY OF STORAGE BINDS ON SMALL SYSTEMS. THE  31440001
*        BLOCKS ARE MARKED IN CONDIR AS T OR D BLOCKS. THEY ARE RELEASD 31470001
*        TO THE SYSTEM BY A FREEMAIN AT THE REQUIRED TIME. THE INITIAL  31500001
*        4K BLOCK IS NEVER RELEASED TO THE SYSTEM.                      31530001
*              REQUESTS FOR SCRATCH CORE ARE MADE BY INSERTING A COUNT  31560001
*        IN PAR1+3(1 BYTE). THIS COUNT WILL SHOW HOW MANY BLOCKS OF 512 31590001
*        BYTES ARE REQUIRED IN ONE CONTIGUOUS LUMP. THIS REQUEST FOR A  31620001
*        5X512 BLOCK (SAY) IS KNOWN AS 1 ALLOCATION. THIS IS IMPORTANT  31650001
*        FOR THE UNDERSTANDING OF ZURC,THE RELEASING OF SCRATCH CORE    31680001
*        ALLOCATIONS                                                    31710001
         SPACE 2                                                        31740001
ZUGC     STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               31770001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  31800001
         L     CNTL3,BASES             LOAD SECOND BASE                 31830001
         SPACE                                                          31860001
         XR    GR0,GR0                                                  31890001
         IC    GR0,PAR1+3(0,DICR)      PICK UP NUMBER OF 512 BYTES      31920001
         SLA   GR0,9                   NOW CONTAINS THE BYTES REQUIRED  31950001
         SPACE                                                          31980001
GCCHAN   BC    NOP,GCFST               BRANCH ON EVERY-ONE EXCEPT FIRST 32010001
         MVI   GCCHAN+1,X'F0'          CHANGE GCCHAN TO A PERMANENT BRC 32040001
         LA    GRA,CONDIR                                               32070001
         ST    GRA,POINTR              POINT AT CONDIR                  32100001
         XC    CONCNT(4),CONCNT        SET NUMBER OF ENTRIES TO ZERO    32130001
         SPACE                                                          32160001
GCFST    CL    GR0,FR96                SEE IF REQUEST IS GRTR THAN 4K   32190001
         BC    BH,GCERR                                                 32220001
         SPACE                                                          32250001
         L     GRA,POINTR              POINT AT CONDIR                  32280001
         CLI   0(GRA),X'FF'            IS IT AT STOPPER IN TABLE        32310001
         BC    BE,GCOUT                NO CORE ALLOCATED IF CONDIR FULL 32340001
         SPACE                                                          32370001
         CL    GR0,ALLOCL              ENOUGH SPACE LEFT IN FIRST 4K    32400001
         BC    BH,GETBLK                                                32430001
         SPACE                                                          32460001
         LM    GRB,GRC,ALLOCA          PICK UP ADDRESS OF ALLOCATED COR 32490001
         ST    GRB,0(0,GRA)            STORE ADDRESS IN CONDIR          32550001
         ST    GR0,4(0,GRA)            STORE AMOUNT IN CONDIR           32580001
         ST    GRB,PAR1(0,DICR)        STORE ADDRESS OF ALLOCATED CORE  32610001
         AR    GRB,GR0                 ALLOCA=ALLOCA+AMOUNT             32640001
         SR    GRC,GR0                 ALLOCL=ALLOCL-AMOUNT             32670001
         STM   GRB,GRC,ALLOCA          RESTORE ALLOCA AND ALLOCL        32700001
         ST    GR0,PAR2(0,DICR)        STORE AMOUNT OF ALLOCATED CORE   32730001
         SPACE                                                          32760001
GCBACK   LA    GRA,8(0,GRA)            BUMP TO NEXT IN CONDIR           32790001
         L     GRB,CONCNT                                               32820001
         LA    GRB,1(0,GRB)            COUNT NUMBER OF ENTRIES IN CONDR 32850001
         STM   GRA,GRB,POINTR          STORE POINTR AND CONCNT          32880001
         SPACE                                                          32910001
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      32940001
         SPACE                                                          32970001
GETBLK   LA    GRB,TSLOTS+24           POINT AT TEXT BLOCK CONTROL      33000001
         XR    GRC,GRC                 THIS WILL BE USED FOR COUNTING   33030001
         SPACE                                                          33060001
GCLOOP   TM    0(GRB),X'80'            SEE IF BLOCK IS IN CORE          33090001
         BC    BZ,NOTINC                                                33120001
         TM    0(GRB),X'70'                                             33150001
         BC    BO,NOTINC                                                33170001
         LA    GRC,1(0,GRC)            COUNT 1 BLOCK AS IN CIRE         33190001
NOTINC   LA    GRB,4(0,GRB)            BUMP TO NEXT IN CONTROL AREA     33210001
         CLI   1(GRB),X'FF'            SEE IF IT IS A STOPPER           33240001
         BC    BNE,GCLOOP                                               33270001
         CL    GRC,FOUR                SEE IF ENOUGH CORE BLOCKS AVAIL  33310001
         BC    BNH,GCOUT                 -ABLE TO STEAL ONE             33350001
*        THE ABOVE CODE IS UNSOPHISTICATED AND NEEDS EXPANDING TO       33390001
*              TO FIND IF ALL CORE HAS BEEN UDES YET.                   33430001
*        TEST FOR K PHASES RUNNING                                      33470001
         XC    RDTTR(4),RDTTR          INDICATE NO READ REQUIRED        33510001
         BAL   RR,TRYMRT               GET SPARE BLOCK,SPILL IF NEC     33550001
         SPACE 1                                                        33590001
         LR    GRB,GR0                 PICK UP NEW BLOCK ADDR           33630001
         L     GRC,DICTSZ(0,DICR)      PICK UP LENGTH                   33690001
         STM   GRB,GRC,PAR1(DICR)      PUT IN PARAMETER WORDS           33720001
         STM   GRB,GRC,0(GRA)          STORE IN CONDIR                  33750001
         OI    0(GRA),X'80'            MARK AS T OR D ALLOCATION        33810001
         BC    B,GCBACK                                                 33840001
         SPACE                                                          33870001
GCOUT    XC    PAR2(4,DICR),PAR2(DICR) SET PAR2 TO 0 TO SHOW NO ALLOCTN 33900001
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      33930001
         SPACE                                                          33960001
GCERR    MVC   PAR6+1(3,DICR),ERRF07   TOO MUCH SCRATCH REQUESTED 32318 33980020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 34000020
         LA    DICR,ABSAV              POINT AT NEW SAVE AREA           34020001
         BAL   RR,ZUERR                                                 34050001
         L     DICR,DADDR              POINT BACK AT OLD SAVE AREA      34080001
         BC    B,GCOUT                                                  34110001
         SPACE                                                          34140001
ERRF07   DC    X'0F07C0'                                          32318 34170020
         EJECT                                                          34200001
*        ROUTINE ZURC                                                   34230001
*                       THIS ROUTINE WILL RELEASE CORE ALLOCATED BY     34260001
*        ZUGC. THE MOST RECENT REQUESTS ARE RELEASED. A ZERO PARAMETER  34290001
*        IS IGNORED. THE NUMBER OF REQUIRED RELEASES IS PASSED IN PAR1. 34320001
*        IF THE BLOCK HAS BEEN OBTAINED BY A TRYMRD OR TRYMRT THEN THE  34350001
*        BLOCK IS RELEASED BY A FREEMAIN. OTHERWISE ADJUSTMENTS ARE     34380001
*        MADE TO ALLOCA AND ALLOCL                                      34410001
         SPACE 2                                                        34440001
ZURC     STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               34470001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  34500001
         L     CNTL3,BASES             LOAD SECOND BASE                 34530001
         LA    GRA,SAVARD              POINT AT NEXT SAVE AREA          34560001
         ST    DICR,4(0,GRA)           CHAIN FORWARDS                   34590001
         ST    GRA,8(0,DICR)           CHAIN BACKWARDS                  34620001
         SPACE                                                          34650001
         XR    GR0,GR0                 PICK UP COUNT OF NUMBER OF       34680001
         IC    GR0,PAR1+3(0,DICR)    REQUIRED RELEASES                  34710001
         SPACE                                                          34740001
         LTR   GR0,GR0                 TEST IF ZERO COUNT               34770001
         BC    BZ,RCRTN                                                 34800001
         CL    GR0,CONCNT              TEST IF TOO MANY RELEASES        34830001
         BC    BH,RCERR                                                 34860001
         SPACE                                                          34890001
         LM    GRA,GRD,ALLOCA          GRA=ALLOCA,GRB=ALLOCL,GRC=POINTR 34920001
RCLOP    S     GRC,EIGHT             GRD=CONCNT. REDUCE TO PREVIOUS     34950001
         TM    0(GRC),X'80'          CONDIR ENTRY. TEST FOR TRYMRD OR   34980001
         BC    BO,RCBLOK             TRYMRT MARKER                      35010001
         S     GRA,4(0,GRC)            ALLOCA=ALLOCA-LENGTH             35040001
         A     GRB,4(0,GRC)            ALLOCL=ALLOCL+LENGTH             35070001
RCBAK    BCTR  GRD,0                   REDUCE CONCNT BY 1               35100001
         BCT   GR0,RCLOP                                                35130001
         SPACE                                                          35160001
RCRTN    STM   GRA,GRD,ALLOCA          RESTORE ADDRESSES,COUNTS,ETC     35190001
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      35220001
         SPACE                                                          35250001
RCBLOK   STM   0,2,TEMP                STORE AWAY REGS                  35280001
         L     0,4(0,GRC)              PICK UP LENGTH                   35310001
         L     1,0(0,GRC)              PICK UP ADDRESS                  35340001
         N     1,STBITS                REMOVE BLOCK MARK FROM TOP BYTE  35370001
         CLI   SPILL,X'00'             BRANCH IF SPILLING               35380001
         BNE   RCTXBL                  TO GIVE BACK VIA TSLOTS          35390001
         LA    DICR,SAVARD             POINT AT SAVE AREA FOR FREEMAIN  35400001
         SPACE                                                          35430001
         SPACE                                                          35460001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 001-TSS 35490001
       FREEMAIN R,LV=(0),A=(1)                                          35520001
*        ----------------------------------------------------AL 001-TSS 35550001
         SPACE                                                          35580001
         SPACE                                                          35610001
         L     DICR,DADDR              RESTORE TO PREVIOUS SAVE AREA    35640001
         L     0,CORLFT(0,DICR)                                         35670001
         A     0,4(0,GRC)              CORLFT=CORLFT+LENGTH RELEASED    35700001
         ST    GR0,CORLFT(0,DICR)                                       35730001
         BC    B,RCTX2                                                  35737001
         SPACE 1                                                        35744001
RCTXBL   LA    2,TSLOTS+24             LOOK FOR SPARE TSLOT             35751001
RCTX3    CLI   0(2),X'FF'                                               35758001
         BNE   RCTX1                                                    35765001
         ST    1,0(2)                  FOUND                            35772001
         MVI   0(2),X'81'              SPARE T BLOCK CREATED            35779001
RCTX2    LM    0,2,TEMP                RESTORE REGS                     35786001
         B     RCBAK                                                    35793001
         SPACE 1                                                        35800001
RCTX1    LA    2,4(2)                  BUMP TO NEXT TSLOT               35807001
         CLI   1(2),X'FF'                                               35814001
         BNE   RCTX3                                                    35821001
         SPACE 1                                                        35828001
         MVC   PAR6+1(3,DICR),ERR18    END OF TSLOTS,COULD LOOK FOR     35835001
         L     LR,DYNAMOF(CNTL)        DSLOT BUT THIS IS IDSASTER       35842001
         BALR  RR,LR                   REALLY                           35849001
         SPACE 1                                                        35856001
ERR18    DC    X'0F1A00'                                                35863001
         SPACE 2                                                        35870001
RCERR    MVC   PAR6+1(3,DICR),ERRF08   ATTEMPT TO RELEASE         32318 35880020
*                                      UNALLOCATED CORE           32318 35890020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 35900020
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 35910001
         BALR  RR,LR                   ROUTINE IN AA                    35940001
         SPACE                                                          35970001
ERRF08   DC    X'0F08C0'                                          32318 36000020
         EJECT                                                          36030001
ALLOCA   DC    F'0'                    ADDRESS AND LENGTH OF SPACE      36060001
ALLOCL   DC    F'0'                  WITHIN FIRST 4K BLOCK              36090001
POINTR   DC    F'0'                    POINTER TO NEXT AVAILABLE SPACE  36120001
CONCNT   DC    F'0'                  IN CONDIR AND NUMBER OF ENTRIES    36150001
CONDIR   DC    32F'0'                  LIST OF ALLOCATIONS              36180001
         DC    X'FF'                   STOPPER FOR LONDIR TABLE         36210001
DSLOTS   DC    6F'0'                                                    36240001
         DC    128XL4'FF000000'                                         36270001
         DC    X'00FF0000'                                              36300001
TSLOTS   DC    6F'0'                                                    36330001
         DC    90XL4'FF000000'                                          36360001
TSLOTEND DC    X'00FF0000'             END OF TSLOTS MARKER       30357 36400020
         SPACE                                                          36420001
FR96     DC    F'4096'                                                  36450001
DICTEM   DC    F'0'                                                     36480001
FOUR     DC    F'4'                                                     36510001
EIGHT    DC    F'8'                                                     36540001
TEMP     DS    F                                                        36570001
TEMP1    DS    F                                                        36600001
TEMP2    DS    F                                                        36630001
TEMP4    DS    F                                                        36660001
STBITS   DC    X'00FFFFFF'                                              36690001
ZEROS    DC    XL4'00'                 PERMANENT ZEROS LOCATION         36720001
TW56     DC    F'256'                                                   36750001
NEXTAD   DC    F'0'                                                     36780001
NOTTR    DC    F'0'                                                     36810001
THREE    DC    XL4'03'                                                  36840001
MASKX    DC    X'FFFFFFFC'                                              36870001
NEGBIT   DC    X'0000FFFF'                                              36900001
WRTLTH   DC    F'0'                                                     36930001
RDTTR    DC    F'0'                                                     36960001
         CNOP  0,8                                                      36990001
CONVAR   DC    F'0'                                                     37020001
         DC    F'0'                                                     37050001
CHANSW   DC    X'00'                                                    37080001
WRTON    DC    X'00'                                                    37110001
MAKSW    DC    X'00'                                                    37170001
BMNAM    DC    C'BM'                                                    37200001
KTNAM    DC    C'KT'                                                    37230001
FSWTCH   DC    X'00'                                                    37260001
BTCHCD   DC    C'*'                                                     37290001
ERRMS    DC    X'0036'                                                  37320001
         DC    C'-'                                                     37350001
         DC    C'IEM3853I SOURCE PROGRAM TOO LARGE.'                    37380001
         DC    C' DICTIONARY IS FULL.'                                  37410001
OFLMES   DC    X'0047'                                            24700 37416019
         DC    C'-'                                               24700 37422019
         DC    C'IEM3909I EXTENDED DICTIONARY CAPACITY EXCEEDED.' 24700 37428019
         DC    C' COMPILATION TERMINATED.'                        24700 37434019
UTIMES   DC    X'001C'                                                  37440001
         DC    C'-'                                                     37470001
         DC    C'IEM3864I I/O ERROR ON SYSUT1'                          37500001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 030-TSS 37510020
OPERR1   DC    X'001E'                                                  37530001
         DC    C'-'                                                     37560001
         DC    C'IEM3878I UNABLE TO OPEN SYSUT1'                        37590001
*        ----------------------------------------------------AL 030-TSS 37690020
         EJECT                                                          37830001
*                   ROUTINE ZUERR.                                      37860001
         SPACE                                                          37890001
*              THIS ROUTINE INSERTS AN ERROR MESSAGE INTO THE           37920001
*        DICTIONARY.                                                    37950001
         SPACE                                                          37980001
*********************************************************************** 38010001
**                                                                   ** 38040001
**             INVOCATION OF THIS ROUTINE IS EQUIVALENT TO TWICE     ** 38070001
**       REFERENCING THE DICTIONARY IN THAT THE TWO BLOCKS LAST      ** 38100001
**       REFERENCED ARE THE LAST IN THE ERROR CHAIN AND THE ONE IN   ** 38130001
**       WHICH THE CURRENT MESSAGE IS INSERTED.                      ** 38160001
**                                                                   ** 38190001
*********************************************************************** 38220001
         SPACE                                                          38250001
*              ON ENTRY THIS ROUTINE EXPECTS TO FIND  -                 38280001
         SPACE                                                          38310001
*        (A)   LOCATION PAR6 WILL HOLD THE INDICATOR BYTES.   THESE ARE 38340001
         SPACE                                                          38370001
*              (1)  THE FIRST BYTE IS NOT USED.                         38400001
*              (2)  THE SECOND AND THIRD BYTES IDENTIFY THE MESSAGE.    38430001
         SPACE                                                          38460001
*              (3)  THE FIRST BIT OF THE FOURTH BYTE IS ONE IF TEXT     38490001
*              IS TO ACCOMPANY THE MESSAGE.                             38520001
         SPACE                                                          38550001
*              (4)  THE SECOND BIT OF THE FOURTH BYTE IS ONE IF THE     38580001
*              STATEMENT NUMBER IS RELEVANT.                            38610001
         SPACE                                                          38640001
*              (5)  THE THIRD BIT OF THE FOURTH BYTE IS ONE IF THE      38670001
*              MESSAGE HAS ASSOCIATED WITH IT A NUMERIC PARAMETER.      38700001
         SPACE                                                          38730001
*              (6)  THE FOURTH BIT OF THE FOURTH BYTE IS ONE IF THE     38760001
*              MESSAGE HAS ASSOCIATED WITH IT A DICTIONARY REFERENCE.   38790001
         SPACE                                                          38820001
*              (7)  THE LAST FOUR BITS OF THE FOURTH BYTE CONTAIN THE   38850001
*              SEVERITY CODE  -                                         38880001
         SPACE                                                          38910001
*                   0000   DISASTROUS                                   38940001
*                   0100   SERIOUS                                      38970001
*                   1000   WARNING                                      39000001
*                   1100   COMMENT                                      39030001
         SPACE                                                          39060001
*        (B)   IF THERE IS TO BE TEXT THEN PAR7 WILL HOLD A POINTER     39090001
*        TO IT AND PAR8 WILL HOLD THE LENGTH COUNT.                     39120001
         SPACE                                                          39150001
*        (C)   IF THERE IS TO BE A NUMERIC PARAMETER THEN ITS BINARY    39180001
*        VALUE MUST BE IN PAR5                                          39210001
         SPACE                                                          39240001
*        (D)   IF THERE IS AN ASSOCIATED DICTIONARY REFERENCE THEN      39270001
*        IT MUST APPEAR RIGHT ADJUSTED IN PAR7.                         39300001
         SPACE                                                          39330001
ZUERR    STM   14,CNTL2,12(GRDIC)      GET SOME WORK REGISTERS          39360001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  39390001
         L     CNTL3,BASES             LOAD SECOND BASE                 39420001
         LA    GRA,ZA107               POUNT AT NEW SAVE AREA           39450001
         ST    GRDIC,4(0,GRA)          CHAIN FORWARDS                   39480001
         ST    GRA,8(0,GRDIC)          CHAIN BACKWARDS                  39510001
         L     GRDIC,DADDR             POINT AT TRUE DICTIONARY         39540001
         SPACE                                                          39570001
         MVC   TEMPY(8),PAR1(DICR)     STORE PAR1 AND 2                 39600001
         CLI   MYNAM(GRDIC),C'X'       IF THE CALL IS FROM THE ERROR    39630001
         BC    BE,ZR51+4               MECHANISM WE SHALL IGNORE IT.    39660001
         CLC   MYNAM(2,GRDIC),BMNAM    IF CALL IS FROM BM               39690001
         BC    BE,ZR51+4               IGNORE IT                        39720001
         SPACE                                                          39750001
         ST    GR5,ZR3+2                                                39780001
         SPACE                                                          39810001
         LA    GR1,8(0,0)              MINIMUM LENGTH COUNT.            39840001
         SPACE                                                          39870001
         TM    PAR6+3(GRDIC),X'70'     TEST FOR STATEMENT NUMBER,       39900001
         BC    BZ,ZR50                 PARAMETER AND DICT. REFERENCE.   39930001
         SPACE                                                          39960001
         IC    RR,PAR6+3(0,GRDIC)      GET SIXTEEN TIMES THE OPTIONS    39990001
         N     RR,ZR1+2                CODE INTO RR                     40020001
         LR    LR,RR                   AND FOUR TIMES IT INTO LR        40050001
         SRL   LR,2                                                     40080001
         AR    RR,LR                   TWENTY TIMES THE OPTIONS CODE    40110001
*                                      INTO RR                          40140001
         SPACE                                                          40170001
         CNOP  0,4                                                      40200001
         SPACE                                                          40230001
         BC    B,*-16(RR)              BRANCH APPROPRIATELY             40260001
         SPACE                                                          40290001
*              HERE THE OPTIONS BITS SAID ONE.                          40320001
*              WE HAVE A DICTIONARY REFERENCE ONLY.                     40350001
         SPACE                                                          40380001
         LA    GR1,10(0,0)             PUT TEN IN THE LENGTH COUNT AND  40410001
         MVC   ZR104(2),PAR7+2(GRDIC)  MOVE IN THE DICTIONARY REFERENCE 40440001
         BC    B,ZR50                                                   40470001
         SPACE                                                          40500001
ZR1      DC    X'000A'                 TEXT LENGTH COMPARISON           40530001
         DC    X'00000070'             MASK FOR REGISTER                40560001
         SPACE                                                          40590001
*              HERE THE OPTIONS BITS SAID TWO.                          40620001
*              WE HAVE A NUMERIC PARAMETER ONLY.                        40650001
         SPACE                                                          40680001
         LA    GR1,10(0,0)             PUT TEN IN THE LENGTH COUNT      40710001
         MVC   ZR104(2),PAR5+2(GRDIC)  AND MOVE IN THE PARAMETER        40740001
         BC    B,ZR50                                                   40770001
         SPACE                                                          40800001
         DC    X'0004'                                                  40830001
ZR2      DC    X'0000000F'             MASK FOR REGISTER                40860001
         SPACE                                                          40890001
*              HERE THE OPTIONS BITS SAID THREE.                        40920001
*              WE HAVE BOTH A NUMERIC PARAMETER AND A DICTIONARY        40950001
*        REFERENCE.                                                     40980001
         SPACE                                                          41010001
         LA    GR1,12(0,0)             LENGTH COUNT TO TWELVE AND MOVE  41040001
         MVC   ZR104(2),PAR5+2(GRDIC)  IN FIRST THE PARAMETER AND THEN  41070001
         MVC   ZR105(2),PAR7+2(GRDIC)  THE DICTIONARY REFERENCE.        41100001
         BC    B,ZR50                                                   41130001
         SPACE                                                          41160001
*              HERE THE OPTIONS BITS SAID FOUR.                         41190001
*              WE HAVE ONLY A STATEMENT NUMBER.                         41220001
         SPACE                                                          41250001
         LA    GR1,10(0,0)             LENGTH COUNT TO TEN AND MOVE IN  41280001
         BAL   RR,CONSTT               PICK UP STATEMENT NUMBER         41310001
         BCR   NOP,0                                                    41340001
         BC    B,ZR50                                                   41370001
         SPACE                                                          41400001
ZR3      DS    1H                                                       41430001
         DS    1F                      TEMPORARY STORAGE                41460001
         SPACE                                                          41490001
*              HERE THE OPTIONS BITS SAID FIVE.                         41520001
*              WE HAVE A STATEMENT NUMBER AND A DICTIONARY REFERENCE.   41550001
         SPACE                                                          41580001
         LA    GR1,12(0,0)             LENGTH COUNT TO TWELVE AND MOVE  41610001
         BAL   RR,CONSTT               PICK UP STATEMENT NUMBER         41640001
         BCR   NOP,0                                                    41670001
         MVC   ZR105(2),PAR7+2(GRDIC)  DICTIONARY REFERENCE             41700001
         BC    B,ZR50                                                   41730001
         SPACE                                                          41760001
*              HERE THE OPTIONS BITS SAID SIX.                          41790001
*              WE HAVE A STATEMENT NUMBER AND A NUMERIC PARAMETER.      41820001
         SPACE                                                          41850001
         LA    GR1,12(0,0)             LENGTH COUNT TO TWELVE AND MOVE  41880001
         BAL   RR,CONSTT                                                41910001
         BCR   NOP,0                                                    41940001
         MVC   ZR105(2),PAR5+2(GRDIC)  BY THE NUMERIC PARAMETER.        41970001
         BC    B,ZR50                                                   42000001
         SPACE                                                          42030001
*              HERE THE OPTIONS BITS SAID SEVEN.                        42060001
*              WE HAVE A FULL HOUSE.                                    42090001
         SPACE                                                          42120001
         LA    GR1,14(0,0)             MAXIMUM LENGTH COUNT AND MOVE    42150001
         BAL   RR,CONSTT               PICK UP STATEMENT NUMBER         42180001
         BCR   NOP,0                                                    42210001
         MVC   ZR105(2),PAR5+2(GRDIC)  FOLLOWED BY NUMERIC PARAMETER    42240001
         MVC   ZR106(2),PAR7+2(GRDIC)  FOLLOWED BY DICTIONARY REFRNCE.  42270001
         SPACE                                                          42300001
*              WE HAVE INSERTED THE OPTIONS, IF ANY, AND ARE ABOUT TO   42330001
*        COMPLETE THE ENTRY.                                            42360001
         SPACE                                                          42390001
ZR50     STH   GR1,ZR101               PUT IN THE LENGTH COUNT AND THE  42420001
         MVC   ZR103(3),PAR6+1(GRDIC)  INDICATOR BYTES.                 42450001
         SPACE                                                          42480001
*              WE NOW SLOT THE ENTRY INTO THE DICTIONARY                42510001
*********************************************************************** 42540001
         ST    GR1,PAR2(0,GRDIC)       ON RETURN THE LOCATION PAR1      42570001
         LA    GR1,ZR100+1             CONTAINS THE DICTIONARY          42600001
         ST    GR1,PAR1(0,GRDIC)       REFERENCE OF THE LAST MADE       42630001
         LA    GRDIC,ZA107             POINT AT SAVE AREA               42660001
         BAL   RR,ZDICRF               ENTRY                            42690001
         L     GRDIC,DADDR             POINT AT DICTIONARY              42720001
*********************************************************************** 42750001
         SPACE                                                          42780001
         MVC   ZR3(2),PAR1+2(GRDIC)   SLOT AWAY THE DICTIONARY          42810001
*                                      REFERENCE                        42840001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 011-TSS 42870001
*        ----------------------------------------------------AL 011-TSS 42900001
         SPACE                                                          42930001
*              WE MUST NOW LINK THIS ENTRY TO THE CORRECT ERROR CHAIN.  42960001
         SPACE                                                          42990001
         L     GRB,PAR6(0,GRDIC)       LOAD SEVERITY CODE               43020001
         N     GRB,ZR2               AND USE IT AS AN INDEX             43050001
         SPACE                                                          43080001
*              POINT GR1 AT THE CORRECT CHAIN TERMINATOR                43110001
         SPACE                                                          43140001
         LA    GR1,ZDNXT+2(GRB,GRDIC)                                   43170001
         SPACE                                                          43200001
*              POINT GR5 AT THE LAST ENTRY IN THE CHAIN                 43230001
         SPACE                                                          43260001
         CLC   0(2,GR1),ZEROS          TEST IF THIS IS THE 1ST ENTRY OF 43290001
*                                    THIS SEVERITY (IF IT IS THE CHAIN  43320001
*                                    TERMINATOR POINTER WILL BE ZERO)   43350001
         BC    BNE,ZR54              NO, FIND PREVIOUS ENTRY ABSOLUTELY 43380001
*                                                                       43410001
         LA    GR5,ZERRD-1(GRB,GRDIC) YES, POINT REG5 3 BYTES BEFORE    43440001
*                                    APPROPRIATE HEADER SLOT (PRETEND   43470001
*                                    THAT THE HEADER SLOT IS PART OF A  43500001
*                                    PREVIOUS ENTRY)                    43530001
         BC    B,ZR55                  OMIT CALL TO ZDRFAB              43560001
         SPACE                                                          43590001
ZR54     MVC   PAR1+2(2,GRDIC),0(GR1)                                   43620001
         SPACE                                                          43650001
*********************************************************************** 43680001
         LA    GRDIC,ZA107             POINT AT SAVE AREA               43710001
         BAL   RR,ZDRFAB                                                43740001
         L     GRDIC,DADDR             POINT AT DICTIONARY              43770001
*********************************************************************** 43800001
         SPACE                                                          43830001
         L     GR5,PAR1(0,GRDIC)                                        43860001
         SPACE                                                          43890001
*              MOVE IN THE POINTER.                                     43920001
         SPACE                                                          43950001
ZR55     MVC   3(2,GR5),ZR3            TO THE LAST ENTRY AND TO         43980001
         MVC   0(2,GR1),ZR3            THE CHAIN TERMINATOR             44010001
         SPACE                                                          44040001
*              AND PROCESS TEXT, IF ANY.                                44070001
         SPACE                                                          44100001
         TM    PAR6+3(GRDIC),X'80'     TEST THE TEXT BIT                44130001
         BC    BO,ZR52                                                  44160001
         SPACE                                                          44190001
*              HERE WE HAVE NO TEXT, OR WE HAVE PROCESSED IT.           44220001
         SPACE                                                          44250001
ZR51     L     GR5,ZR3+2                                                44280001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 012-TSS 44310001
*        ----------------------------------------------------AL 012-TSS 44340001
         MVC   PAR1(8,DICR),TEMPY      RESTORE PAR1 AND 2               44370001
         LA    GRDIC,ZA107             POINT AT SAVE AREA               44400001
         L     GRDIC,4(0,GRDIC)        PICK UP ADDR OF PREVIOUS AREA    44430001
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      44460001
         SPACE                                                          44490001
*              HERE WE HAVE TEXT TO SLOT IN.                            44520001
         SPACE                                                          44550001
*              WE WILL NOT SLOT IN MORE THAN TEN CHARACTERS OF TEXT.    44580001
         SPACE                                                          44610001
ZR52     LH    GR1,PAR8+2(GRDIC)     LOAD TEXT LENGTH                   44640001
         LTR   GR1,GR1               IF NEGATIVE LENGTH                 44670001
         BC    BNM,ZR52A             THEN SPECIAL                       44700001
         LPR   GR1,GR1               STMT NO. ENTRY                     44730001
         MVI   ZR102,X'01'             * DENOTE STMT NO ENTRY     60037 44760072
         BC    B,ZR53                                                   44790001
ZR52A    CH    GR1,ZR1                                                  44820001
         BC    BL,ZR53               BTANCH IF LOWER THAN 10            44850001
         LH    GR1,ZR1                 SET LENGTH TO TEN                44880001
         MVI   ZR102,X'FF'             * DENOTE TRUNCATED TEXT    60037 44910072
ZR53     BCTR  GR1,0                   * SET UP FOR FINAL MVC OF  60037 44940072
         STC   GR1,DICMVC+1            * TEXT INTO DICT. ENTRY    60037 44960072
         LA    GR1,5(GR1)              * GR1 = TOTAL LENGTH OF    60037 44980072
         ST    GR1,PAR2(0,GRDIC)       * DICT. ENTRY TO BE MADE   60037 45000072
         STH   GR1,ZR101               STORE LENGTH IN SKELETON   60037 45020072
         LA    GR1,ZR100+1             * POINT AT SKELETON        60037 45040072
         ST    GR1,PAR1(0,GRDIC)       * PAR1 -> SKEL. PAR2 = LENGTH 37 45060072
         SPACE                                                          45090001
*********************************************************************** 45120001
         SPACE                                                          45150001
         LA    GRDIC,ZA107             POINT AT SAVE AREA               45180001
         BAL   RR,ZDICRF                                                45210001
         L     GRDIC,DADDR             POINT AT DICTIONARY              45240001
         SPACE                                                          45270001
*********************************************************************** 45300001
         SPACE                                                          45330001
*        THE SKELETON DICTIONARY ENTRY HAS BEEN MADE. PAR4 NOW    60037 45360072
*        CONTAINS THE ABSOLUTE ADDRESS OF THE SKELETON ENTRY IN   60037 45390072
*        THE DICTIONARY. IT REMAINS TO MOVE THE TEXT INTO THE ENTRY 037 45420072
         SPACE 1                                                        45450072
         L     GR1,PAR4(0,GRDIC)       * PICK UP A(DICT. ENTRY)   60037 45480072
         L     GR5,PAR7(0,GRDIC)       * PICK UP A(TEXT TO BE MOVED) 37 45510072
DICMVC   MVC   4(*-*,GR1),0(GR5)       * MOVE TEXT TO DICT ENTRY  60037 45540072
         MVI   ZR102,X'00'             * REINITIALIZE INDICATOR BYTE 37 45570072
         B     ZR51                    * RETURN                   60037 45600072
         SPACE                                                          45630001
         CNOP  0,4                                                      45660001
         SPACE                                                          45690001
ZR100    DC    XL2'00C8'               ERROR MESSAGE CODE BYTE          45720001
ZR101    DC    XL2'0000'               LENGTH COUNT                     45750001
ZR102    DC    XL2'0000'               SYMBOLIC CHAIN                   45780001
ZR103    DC    XL3'000000'             INDICATOR BYTES                  45810001
ZR104    DC    XL2'0000'               POSSIBLE STATEMENT NUMBER        45840001
ZR105    DC    XL2'0000'               POSSIBLE NUMERIC PARAMETER       45870001
ZR106    DC    XL2'0000'               POSSIBLE DICTIONARY REFERENCE    45900001
         DC    XL1'00'                                                  45930001
*        HERE WE ARE BACK ON A FOUR BYTE BOUNDARY.                      45960001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 013-TSS 45990001
ZA107    DS    18F                                                      46020001
*        ----------------------------------------------------AL 013-TSS 46050001
         SPACE                                                          46080001
*              VALUES OF SYMBOLIC NAMES.                                46110001
         SPACE                                                          46140001
GRDIC    EQU   13                                                       46170001
*                                                                       46200001
*              PICK UP STATEMENT NUMBER AND CONVERT IT TO BINARY IF     46230001
*        MACRO RUNNING                                                  46260001
*                                                                       46290001
CONSTT   TM    CCCODE+3(DICR),X'10'    SEE IF MACRO RUNNING             46320001
         BC    BZ,BINST                                                 46350001
         MVC   CONVAR+4(4),ZSTAT(DICR) PICK UP PACKED DECIMAL STATEMENT 46380001
         CVB   GRD,CONVAR            NUMBER AND CONVERT IT TO BINARY    46410001
         ST    GRD,CONVAR+4                                             46440001
         MVC   ZR104(2),CONVAR+6       PICK UP 2 BYTE BINARY VALUE      46470001
         BCR   BR,RR                                                    46500001
BINST    MVC   ZR104(2),ZSTAT+2(DICR)                                   46530001
         BCR   BR,RR                                                    46560001
         EJECT                                                          46590001
*        ROUTINES CONSLT AND CONSLD                                     46620001
*                       THESE ROUTINES TAKE A TEXT OR DICTIONARY        46650001
*        REFERENCE AND PROCEED TO POINT AT THE RELEVANT SLOT IN T OR D  46680001
*        SLOTS. THE ADDRESS IS RETURNED IN GRA, THE REFERENCE IS TAKEN  46710001
*        FROM PAR1 WHICH IS LEFT UNALTERED                              46740001
         SPACE 2                                                        46770001
CONSLT   XR    GRA,GRA                                                  46800001
         IC    GRA,PAR1+1(0,DICR)      PICK UP BLOCK COUNT FROM T REF   46830001
         AR    GRA,GRA                                                  46860001
         AR    GRA,GRA                 MULTIPLIED FOR WORD OFFSET       46890001
         A     GRA,CONSLTT             THIS GIVES ABS ADD OF SLOT       46920001
         BR    RR                      RETURN                           46950001
         SPACE 2                                                        46980001
CONSLD   BC    B,CONSLDB  ***** FIRST TIME BRANCH  *****                47010001
CONSLDC  LH    GRA,PAR1+2(0,DICR)      PICK UP D REF (OPT FOR 40)       47040001
         N     GRA,NEGBIT              REMOVE TOP HALF                  47070001
         N     GRA,ZMASK1-2(0,DICR)    REMOVE OFFSET                    47100001
CONSHF   SRL   GRA,0    ***** SHIFT SET BY FIRST TIME CODE   *****      47130001
         A     GRA,CONSLDD             THIS GIVES ABS ADDR OF SLOT      47160001
         BR    RR                      RETURN                           47190001
*              FIRST TIME CODE SEQUENCE TO SET SHIFT                    47220001
CONSLDB  MVI   CONSLD+1,X'00'          SET BR TO NOP                    47250001
         L     GRA,ZSHIFT(0,DICR)      GET NO OF BITS IN OFFSET         47280001
         S     GRA,K2                  REDUCE SHIFT BY 2                47310001
         STC   GRA,CONSHF+3            FOR WORD BLOCK OFFSET            47340001
         B     CONSLDC                                                  47370001
         EJECT                                                          47400001
*        ROUTINES TRYMRD AND TRYMRT.                                    47430001
*                       THESE ROUTINES INVESTIGATE THE CORE POSITION    47460001
*        AND PERFORM A GETMAIN IF THERE IS CORE AVAILABLE. IF NOT THEN  47490001
*        A SPILL SITUATION EXISTS AND DFREE AND TFREE ARE ENTERED. AN   47520001
*        ATTEMPT TO FIND A FREE BLOCK IS MADE FIRST EXCEPT FOR ENTRIES  47550001
*        FROM ZUTXTC                                                    47580001
         SPACE 2                                                        47610001
TRYMRT   STM   14,CNTL2,SAVAR+12       GET WORK REGISTERS               47640001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  47670001
         L     CNTL3,BASES             LOAD SECOND BASE                 47700001
         MVI   TEXTSW,X'FF'            SHOW IT IS A TEXT BLOCK TYPE     47730001
         LA    GRA,TSLOTS+24           POINT AT TSLOTS FOR SCAN         47760001
         BC    B,TRYONA                                                 47790001
         SPACE                                                          47820001
TRYMRD   STM   14,CNTL2,SAVAR+12       GET WORK REGISTERS               47850001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  47880001
         L     CNTL3,BASES             LOAD SECOND BASE                 47910001
         MVI   TEXTSW,X'00'            SHOW IT IS A DICT BLOCK TYPE     47940001
         LA    GRA,DSLOTS+24           POINT AT DSLOTS FOR SCAN         47970001
TRYONA   MVC   BLK(4),DICTSZ(DICR)     PICK UP BLOCK LENGTH             48000001
         CLI   SPILL,X'FF'             SEE IF SPILLING                  48030001
         BC    BE,YESPIL                                                48060001
         SPACE                                                          48090001
TRYON    CLI   0(GRA),X'81'            SEE IF THIS BLOCK IS IN-CORE AND 48120001
         BC    BE,BLFOND             FREE                               48150001
         LA    GRA,4(0,GRA)            BUMP TO NEXT SLOT                48180001
         CLI   1(GRA),X'FF'            TEST IF STOPPER                  48210001
         BC    BNE,TRYON                                                48240001
         SPACE                                                          48270001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 016-TSS 48300001
*              EXAMINE CONTENTS OF BLKTBL TO SEE IF IT CONTAINS ANY     48330001
*        UNUSED BLOCKS                                                  48360001
*                                                                       48390001
         LA    GRA,10                  SET BLOCK ENTRY COUNT            48420001
         LA    GRB,BLKTBL              POINT AT BLKTBL                  48450001
NXTENT   CLI   0(GRB),X'FF'            TEST FOR A USEFUL ENTRY          48480001
         BC    BE,USDBLK             BRANCH IF NO USE                   48510001
         L     GR0,0(0,GRB)            LOAD ADDR OF BLOCK INTO GR0      48540001
         MVI   0(GRB),X'FF'            MARK ENTRY USED                  48570001
         BC    B,TRYRTN                BRANCH TO EXIT                   48600001
USDBLK   LA    GRB,4(0,GRB)            BUMP TO NEXT ENTRY               48630001
         BCT   GRA,NXTENT              LOOP IF ANY ENTRIES LEFT         48660001
*        ----------------------------------------------------AL 016-TSS 48690001
         SPACE                                                          48720001
         L     GRA,CORLFT(DICR)                                         48750001
         C     GRA,BLK               SEE IF ROOM FOR ANOTHER BLOCK      48780001
         BC    BL,TRSPIL                                                48810001
         MVC   GETLST(4),BLK           PUT BLOCK LENGTH INTO GETMAIN    48840001
         MVC   GETLST+4(4),BLK                                          48870001
         LA    DICR,OSSAVR             PICK UP SAVE AREA FOR OS/360     48900001
         SPACE                                                          48930001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 002-TSS 48960001
       GETMAIN VC,LA=GETLST,A=ANSW                                      48990001
*        ----------------------------------------------------AL 002-TSS 49020001
         L     DICR,DADDR              POINT AT TRUE DICTIONARY AGAIN   49050001
         SPACE                                                          49080001
         BC    B,HERE(15)              TEST IF CORE GOT OK              49110001
HERE     BC    B,OK                                                     49140001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 003-TSS 49170001
         BC    B,TRSPIL                TAKE THIS ONE IF CORE NOT AVAILB 49200001
*        ----------------------------------------------------AL 003-TSS 49210020
         SPACE                                                          49230001
OK       L     GR0,CORLFT(0,DICR)      COMPUTE NEW VALUE OF AMOUNT OF   49260001
         S     GR0,BLK               CORE LEFT FOR TEXT AND DICTIONARY  49290001
         ST    GR0,CORLFT(0,DICR)    BLOCKS                             49320001
NOTRUE   L     GR0,ANSW                PICK UP ADDRESS OF NEW BLOCK     49350001
         SPACE                                                          49380001
TRYRTN   LM    14,15,SAVAR+12          RESTORE ALL REGISTERS            49410001
         N     GR0,STBITS              REMOVE STATUS BYTES              49440001
         LM    1,CNTL2,SAVAR+24                                         49470001
         MVI   SAVAR+12,X'FF'          SHOW RETURN IS COMPLETE          49500001
         BCR   BR,RR                                                    49530001
         SPACE                                                          49560001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 022-TSS 49590001
TRSPIL   CLI   SPILL,X'FF'             IS A SPILL SITUATION CURRENT     49620001
         BC    BE,YESPIL                                                49650001
         SPACE                                                          49680001
         L     GRB,PAROF(CNTL)         POINT AT                         49710001
         L     GRB,SPDCBOF(GRB)        SPILL DCB                        49740001
         AIF   (NOT &STD).L1                                            49747021
         LA    DICR,OSSAVR             SUPPLY S.A. TO OPEN.             49754021
.L1      ANOP                                                           49761021
         OPEN  ((GRB),OUTIN)           OPEN SPILL FILE                  49770001
         L     DICR,DADDR              POINT AT TRUE DICTIONARY AGAIN   49800001
         LR    GRA,GRB                 POINT AT SPILL DCB               49830001
         USING IHADCB,GRA                                               49860001
         TM    DCBOFLGS,X'10'          SEE IF SPILL FILE IS OPEN        49890001
         BO    YESPIL                                             H319  49920001
         LA    GR0,OPERR1              PRINT CANNOT OPEN SYSUT1         49950001
         ST    GR0,PAR1(0,DICR)                                         49980001
         BAL   RR,ZUPL                                                  50010001
         LA    GR0,16                  SHOW A TERMINAL ERROR HAS        50040001
         ST    GR0,ERCODE(0,DICR)    OCURRED                            50070001
         L     LR,ABORTOF(CNTL)        POINT AT ZABORT                  50100001
         BALR  RR,LR                                                    50130001
         SPACE                                                          50850001
YESPIL   CLI   TEXTSW,X'FF'            FIND IF GETTING A TEXT OR DICT   50880001
         BC    BE,TGET               BLOCK                              50910001
         BAL   RR,DFREE                GET SPACE FOR A DICTIONARY BLOCK 50940001
         BC    B,PICUP                                                  50970001
TGET     BAL   RR,TFREE                GET SPACE FOR A TEXT BLOCK       51000001
PICUP    L     GR0,BLOKAD              PICK UP ADDRESS OF BLOCK         51030001
         BC    B,TRYRTN                                                 51060001
*        ----------------------------------------------------AL 022-TSS 51090001
         SPACE                                                          51150001
BLFOND   MVI   0(GRA),X'00'            CLEAR STATUS                     51180001
         L     GR0,0(0,GRA)            PICK UP ADDRESS                  51210001
         MVI   0(GRA),X'FF'            MAKE SLOT FREE AGAIN             51240001
         BC    B,TRYRTN                                                 51270001
         EJECT                                                          51300001
*        ROUTINES DFREE AND TFREE                                       51330001
*                       THESE ROUTINES MAKE SPACE FOR A TEXT AND DICT   51360001
*        BLOCK. IF REQUIRED,A NEW BLOCK WILL BE READ IN. DFREE GOES     51390001
*        THROUGH A PROCEDURE TO CHANGE THE PRIORITIES OF DICTIONARY     51420001
*        BLOCKS ACCORDING TO ENTRIES IN THE LAST-LOOK TABLE AND THE     51450001
*        LOCK-SLOT. TEXT BLOCK PRIORITIES ARE CHANGED BY THE PHASE.     51480001
         SPACE 2                                                        51510001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 018-TSS 51540001
TFREE    STM   14,4,SAVAR2             GET WORK REGISTERS               51570001
         NI    FSWTCH,X'0F'            SHOW T FREE                      51600001
TAGAIN   LA    GRD,TSLOTS              POINT AT TSLOTS FOR A SCAN OF    51630001
         BC    B,COMON               TEXT BLOCKS                        51660001
         SPACE                                                          51690001
DFREE    STM   14,4,SAVAR2             GET WORK REGISTERS               51720001
         LA    GRD,DSLOTS+28           POINT AT START SCAN ADDRESS OF   51750001
         MVI   DICSW,X'FF'           DICTIONARY BLOCKS. SHOW IS DFREE   51780001
         OI    FSWTCH,X'F0'            SHOW D FREE                      51810001
         SPACE                                                          51840001
SETWNT   CLI   5(GRD),X'FF'            IS THIS THE OFLO BLK?      62615 51870072
         BE    ENDWNT                  YES, DONT CHANGE ITS STATUS62615 51900072
         CLI   0(GRD),X'FF'            IF THIS SLOT IS FREE       62615 51930072
         BE    SET2                    THEN BUMP TO NEXT.         62615 51960072
         NI    0(GRD),X'80'            SET ALL BITS OFF                 51990001
         OI    0(GRD),X'03'            MARK AS WANTED                   52020001
SET2     LA    GRD,4(0,GRD)            BUMP TO NEXT SLOT                52050001
         BC    B,SETWNT                                                 52080001
         SPACE                                                          52110001
ENDWNT   CLC   MYNAM(2,DICR),KTNAM     SEE IF K PHASES RUNNING          52140001
         BC    BNL,SETANY                                               52170001
         CLI   MYNAM(DICR),C'K'                                         52200001
         BC    BE,KIN                                                   52230001
         CLC   MYNAM(2,DICR),BMNAM                                      52260001
         BC    BE,SETANY                                                52290001
         CLI   MYNAM(DICR),C'C'        SEE IF READIN IS RUNNING         52320001
         BC    BH,SETANY                                                52350001
         TM    CCCODE+2(DICR),X'04'    SEE IF ONLY TWO BLOCKS           52380001
         BC    BO,SETDLS                                                52410001
         SPACE                                                          52440001
SETANY   LA    GRC,2                     SET 2 BLOCKS BUSY              52470001
         SPACE 1                                                        52500001
CONTIN   LA    GRB,LASLOK+4            POINT AT IN USE TABLE            52530001
         MVC   TEMPZ(4),PAR1(DICR)     SV PAR1 AS CONSLD IS USED        52560001
         CLC   LOCK(2,DICR),ZEROS      IF ANY LOCKED                    52590001
         BC    BE,SETBUS                                                52620001
         BCT   GRC,SETBUS              REDUCE NO OF BLOCKS BY 1         52650001
         BC    B,LOCKLCK               BRANCH AROUND IF 0               52680001
KIN      LA    GRC,1                   SET 1 D BLKS BUSY                52710001
         BC    B,CONTIN                AS IN K PHASES                   52740001
         SPACE 1                                                        52770001
SETBUS   MVC   PAR1+2(2,DICR),0(GRB)   MOVE IN REFERENCE                52800001
         BAL   RR,CONSLD                                                52830001
         NI    0(GRA),X'80'            CLE AR STATUS BITS               52860001
         OI    0(GRA),X'04'            MARK IN-CORE AND BUSY            52890001
         BCTR  GRB,0                   REDUCE TO NEXT IN LAST LOOK      52920001
         BCTR  GRB,0                 TABLE                              52950001
         BCT   GRC,SETBUS                                               52980001
         SPACE                                                          53010001
LOCKLCK  MVC   PAR1+2(2,DICR),LOKSV    PICK UP REF OF LOCKED BLK  H244  53040001
         BAL   RR,CONSLD                                                53070001
         NI    0(GRA),X'80'            CLEAR STATUS BITS                53100001
         OI    0(GRA),X'04'            LOCK BLOCK INYO CORE             53130001
         MVC   PAR1(4,DICR),TEMPZ      RESTORE PAR1 AGAIN               53160001
SETDLS   LA    GRD,DSLOTS              POINT AT DICTIONARY SLOTS        53190001
         SPACE                                                          53220001
COMON    LA    GRA,24(0,GRD)           POINT AT T OR DSLOTS+24          53250001
         LR    GRC,GRD                 POINT AT ADDRESSES OF CURRENT    53280001
         XR    GRD,GRD               SLOTS. SET COUNT TO ZERO           53310001
         SPACE                                                          53340001
DTLOP    CLI   0(GRA),X'81'            TEST IF BLOCK FREE               53370001
BF       BC    BE,FREE                                                  53400001
         CLI   0(GRA),X'82'            UNWANT                           53430001
BU       BC    BE,UNWANT                                                53460001
         CLI   0(GRA),X'83'            WANT                             53490001
BW       BC    BE,WANT                                                  53520001
CARYON   LA    GRA,4(0,GRA)            BUMP TO NEXT SLOT                53550001
         CLI   1(GRA),X'FF'            TEST FOR STOPPER SLOT            53580001
         BC    BNE,DTLOP                                                53610001
         BC    B,SEARCH                                                 53640001
         SPACE                                                          53670001
FREE     ST    GRA,FADDR(0,GRC)      STORE ADDRESS OF FREE SLOT         53700001
         MVI   BF+1,X'00'              SET TO A NOP                     53730001
         BC    B,TCOUNT                                                 53760001
         SPACE                                                          53790001
UNWANT   ST    GRA,UNADDR(0,GRC)     STORE ADDRESS OF ANWANT SLOT       53820001
         MVI   BU+1,X'00'              SET TO A NOP                     53850001
         BC    B,TCOUNT                                                 53880001
         SPACE                                                          53910001
WANT     ST    GRA,WADDR(0,GRC)      STORE ADDRESS OF WANT SLOT         53940001
         MVI   BW+1,X'00'            SET TO A NOP                       53970001
         BC    B,TCOUNT                                                 54000001
         SPACE                                                          54030001
TCOUNT   LA    GRD,1(0,GRD)            BUMP NO. OF NOPS CURRENT BY 1    54060001
         CL    GRD,THREE               TEST IF NO. OF NOPS IS 3         54090001
         BC    BNE,CARYON                                               54120001
         SPACE                                                          54150001
SEARCH   CLI   DICSW,X'FF'             TEST IF ENTRY THROUGH DFREE      54180001
         BC    BNE,FINDB                                                54210001
         CLC   MYNAM(2,DICR),KTNAM     SEE IF K PHASES RUNNING          54240001
         BC    BL,BYPAS3                                                54270001
BYPAS5   LA    GRE,5                   NO,SET FOR 4 BLOCKS              54300001
         BC    B,BYPAS4                                                 54330001
BYPAS3   CLI   MYNAM(DICR),C'K'                                         54360001
         BC    BL,BYPAS5                                                54390001
         LA    GRE,6                   YES,SET FOR 5 BLOCKS             54420001
BYPAS4   LA    GRD,TSLOTS+24           COUNT TO SEE IF SPARE T BLOCKS   54450001
CLOOP    TM    0(GRD),X'80'            SEE IF BLOCK IS IN CORE          54480001
         BC    BZ,NOT5                                                  54510001
         TM    0(GRD),X'70'                                             54540001
         BC    BZ,COUNTBL                                               54570001
NOT5     LA    GRD,4(0,GRD)            BUMP TO NEXT IN TSLOTS           54600001
         CLI   1(GRD),X'FF'            SEE IF IT IS THE STOPPER         54630001
         BC    BNE,CLOOP                                                54660001
         BC    B,FINDB                 THIS ONE IF 4 OR LESS TEXT BLOCK 54690001
COUNTBL  BCT   GRE,NOT5                ACTUALLY COUNT TEXT BLOCKS       54720001
         MVI   TAGBR+1,X'00'           MAKE IT A NOP SO CAN TRY TEXT    54750001
         BC    B,NOREAD                                                 54780001
         SPACE                                                          54810001
FINDB    XR    GR0,GR0                 SET 0 TO 0 AS A TEST AGAINS 0    54840001
         CL    GR0,FADDR(0,GRC)        TEST IF ANY FREE BLOCKS          54870001
         BC    BNE,GETF                                                 54900001
         CL    GR0,UNADDR(0,GRC)       TEST IF ANY UNWANT BLOCKS        54930001
         BC    BNE,GETU                                                 54960001
         CL    GR0,WADDR(0,GRC)        TEST IF ANY WANTED BLOCKS        54990001
         BC    BNE,GETW                                                 55020001
         SPACE 1                                                        55050001
         TM    FSWTCH,X'F0'            NO SPARE BLOCKS                  55080001
         BC    BNZ,KILL                KILL IF LOOKING FOR DBLOCK       55110001
         CLC   MYNAM(2,DICR),KTNAM     IF K PHASES RUNNING              55140001
         BC    BNL,KILL                                                 55170001
         CLI   MYNAM(DICR),C'K'                                         55200001
         BC    BL,KILL                                                  55230001
         TM    FSWTCH,X'01'            CHECK IF WE HAVE 5 IN-CORE BLKS  55260001
         BC    BO,KILL                                                  55290001
         OI    FSWTCH,X'01'            TRY AND GET FROM D BLOCKS        55320001
         LA    GRD,DSLOTS+28                                            55350001
         BC    B,SETWNT                                                 55380001
         SPACE 1                                                        55410001
KILL     MVC   PAR6+1(3,DICR),ERRF02   ALL TEXT BLOCKS IN CORE    32318 55420020
*                                      ARE BUSY                   32318 55430020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 55440020
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 55470001
         BALR  RR,LR                   ROUTINE IN AA                    55500001
ERRF02   DC    X'0F02C0'                                          32318 55510020
         SPACE                                                          55530001
GETF     L     GRA,FADDR(0,GRC)      POINT AT SLOT WITH FREE ADDRESS    55560001
         ST    GR0,FADDR(0,GRC)        SET ADDRESS TO ZERO              55590001
         MVC   BLOKAD(4),0(GRA)        PICK UP ADDRESS OF FREE BLOCK    55620001
         MVI   0(GRA),X'FF'            SET SLOT FREE                    55650001
         CL    GR0,RDTTR               SEE IF READ REQUIRED             55680001
         BC    BE,NOREAD                                                55710001
         BAL   RR,WDREAD               ENTER WRITE-DISK IN READ ONLY    55740001
         BC    B,NOREAD              MODE                               55770001
         SPACE                                                          55800001
GETU     L     GRA,UNADDR(0,GRC)     PICK UP ADDRESS OF UNWANT BLOCK    55830001
         ST    GR0,UNADDR(0,GRC)     SLOT. SET ADDRESS TO ZERO.         55860001
         BC    B,TRDTR                                                  55890001
         SPACE                                                          55920001
GETW     L     GRA,WADDR(0,GRC)      PICK UP ADDRESS OF WANTED BLOCK    55950001
         ST    GR0,WADDR(0,GRC)      SLOT. SET ADDRESS TO ZERO.         55980001
         SPACE                                                          56010001
TRDTR    MVC   BLOKAD(4),0(GRA)         PICK UP ADDRESS OF BLOCK TO BE  56040001
         CL    GR0,RDTTR             MADE FREE. SEE IF BLOCK REQUIRED   56070001
         BC    BE,WRTONL             INTO CORE                          56100001
         BAL   RR,WRTRD                A WRITE-READ ENTRY               56130001
         BC    B,MARK                                                   56160001
WRTONL   BAL   RR,WDWRIT               A WRITE ONLY ENTRY               56190001
         SPACE                                                          56220001
MARK     NI    0(GRA),X'7F'            MARK BLOCK AS ON DISK            56250001
         MVC   1(3,GRA),NOTTR          INSERT TRACK ADDRESS             56280001
NOREAD   MVI   DICSW,X'00'             SET DICSW OFF                    56310001
         XR    GR0,GR0                                                  56340001
         ST    GR0,FADDR(0,GRC)        SET SLOTS TO ZERO FOR NEXT ENTRY 56370001
         ST    GR0,UNADDR(0,GRC)     TO SPILL ROUTINES                  56400001
         ST    GR0,WADDR(0,GRC)                                         56430001
         MVI   BF+1,X'80'              SET TO BRANCH FOR NEXT SCAN OF   56460001
         MVI   BU+1,X'80'            SLOTS                              56490001
         MVI   BW+1,X'80'                                               56520001
TAGBR    BC    B,DFROUT                                                 56550001
         MVI   TAGBR+1,X'F0'           MAKE IT A BRANCH AGAIN           56580001
         BC    B,TAGAIN                                                 56610001
         SPACE                                                          56640001
DFROUT   LM    RR,4,SAVAR2             RELOAD REGISTERS                 56670001
         MVI   SAVAR2,X'FF'            SHOW RETURN IS COMPLETE          56700001
         BCR   BR,RR                                                    56730001
         SPACE                                                          56760001
         EJECT                                                          56820001
*        ----------------------------------------------------AL 018-TSS 56850001
*        ROUTINE WRTDSK                                                 56880001
*                       THIS ROUTINE IS THE ONE THAT ACTUALLY HAS       56910001
*        THE DATA MANAGEMENT MACROS TO CONTROL THE SPILL FILE. THREE    56940001
*        ENTRIES ARE SUPPLIED                                           56970001
*                       1) READ ONLY       ENTRY-POINT  WDREAD          57000001
*                       2) WRITE ONLY                   WDWRIT          57030001
*                   AND 3) WRITE-READ                   WRTRD           57060001
*        A LIST OF FREE SPACES ON THE SPILL DEVICE IS KEPT IN FRSLOT.   57090001
*              IF A WRITE ENTRY IS ENCOUNTERED THEN FRSCOTS IS CHECKED  57120001
*        TO SEE IF ANY FREE TRACKS ARE AVAILABLE WITHIN THE EXTENT OF   57150001
*        THE DATA-SET ALREADY WRITTEN. IF SUCH A HOLE DOES EXIST THEN   57180001
*        THE TTR OF THE TRACK IS PLACED IN TEMP4 AND WRITEX IS ENTERED. 57210001
*              IF A READ IS REQUESTED THEN READX IS ENTERED. THE TTR    57240001
*        IS PLACED IN A FREE SLOT IN FRSLOTS                            57270001
*              IF NO FREE TRACKS EXIST WITH A WRITE ENTRY THEN BSAM IS  57300001
*        USED TO WRITE A RECORD ON THE END OF THE EXISTING DATA-SET. IN 57330001
*        THIS WAY, PREFORMATTING IS PERFORMED AT THE SAME TIME AS THE   57360001
*        DATA-SET IS CREATED. LATER USE OF XDAP IS THEN ALLOWED.        57390001
*                                                                       57420001
         SPACE 2                                                        57450001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 014-TSS 57480001
WDWRIT   MVI   WRTON,X'FF'             SET WRITE ONLY SWITCH            57510001
         SPACE                                                          57540001
WRTRD    STM   14,4,SAVAR3             GET SOME WORK REGISTERS          57570001
         LA    DICR,OSSAVR             POINT AT SAVE AREA FOR OS/360    57600001
         CLI   SPILL,X'FF'         ARE WE SPILLING                      57630001
         BC    BE,SWDWRIT          BRANCH IF SO                         57660001
         MVI   SPILL,X'FF'         SHOW SPILL                           57690001
         L     GRD,DADDR                                                57720001
         MVC   SPLNAM(2,GRD),MYNAM(GRD)     MOVE IN NAME OF SPILL PHS   57750001
SWDWRIT  EQU   *                                                        57780001
         CLC   NUMFRE(4),ZEROS         SEE IF ANY FREE TRACKS ON DISK   57810001
         BC    BE,NOFREE                                                57840001
         SPACE                                                          57870001
         LA    GRA,FRSLOT              POINT AT LIST OF FREE TRACKS     57900001
         SPACE                                                          57930001
FRLOP    CLI   0(GRA),X'FF'            TEST IF SLOT IN USE              57960001
         BC    BNE,FONDT                                                57990001
         LA    GRA,3(0,GRA)            BUMP TO NEXT ENTRY IN FRESLOTS   58020001
         BC    B,FRLOP                                                  58050001
         SPACE                                                          58080001
FONDT    L     GRB,NUMFRE              NUMFRE= NUMFRE-1                 58110001
         BCTR  GRB,0                                                    58140001
         ST    GRB,NUMFRE                                               58170001
         MVC   NOTTR(3),0(GRA)         PICK UP TTR TO STORE IN SLOTS    58200001
         MVI   TEMP4+3,X'00'           SET ZERO BYTE TO ZERO            58230001
         MVC   TEMP4(3),0(GRA)         PICK UP TTR OF FREE TRACK ON     58260001
         MVI   0(GRA),X'FF'          DISK. SET SLOT FREE                58290001
         BAL   RR,WRITEX               WRITE BLOCK ONTO FREE TRACK      58320001
         SPACE                                                          58350001
WRTOUT   CLI   WRTON,X'FF'             TEST IF WRITE ONLY               58380001
         BC    BNE,READ                                                 58410001
         MVI   WRTON,X'00'             SET WRITE ONLY SWITCH OFF        58440001
         BC    B,WROUT                                                  58470001
         SPACE                                                          58500001
WDREAD   STM   14,4,SAVAR3             GET WORK REGISTERS               58530001
         LA    DICR,OSSAVR             POINT AT SAVE AREA FOR OS/360    58560001
         SPACE                                                          58590001
READ     MVC   TEMP4(4),RDTTR          PICK UP ADDRESS OF RCD TO READ   58620001
         BAL   RR,READX                READ BLOCK FROM DA DEVICE        58650001
         SPACE                                                          58680001
         LA    GRA,FRSLOT              POINT AT LIST OF FREE TRACKS     58710001
         SPACE                                                          58740001
FRLOOP   CLI   0(GRA),X'FF'            SEE IF SLOT FREE                 58770001
         BC    BE,FONDFR                                                58800001
         LA    GRA,3(0,GRA)            BUMP TO NEXT IN FRESLOTS         58830001
         CLC   0(3,GRA),ZEROS          SEE IF END OF LIST               58860001
         BC    BNE,FRLOOP                                               58890001
         SPACE                                                          58920001
         BC    B,WROUT                 THROW TRK ADDR AWAY, TABLE FULL  58950001
         SPACE                                                          58980001
FONDFR   MVC   0(3,GRA),RDTTR          MOVE IN ADDRESS OF FREE TRACK    59010001
         L     GRA,NUMFRE                                               59040001
         LA    GRA,1(0,GRA)            BUMP NUMBER OF FREE TRACKS BY 1  59070001
         ST    GRA,NUMFRE                                               59100001
         SPACE                                                          59130001
WROUT    LM    14,4,SAVAR3             RELOAD REGISTERS                 59160001
         MVI   SAVAR3,X'FF'            SHOW RETURN IS COMPLETE          59190001
         L     DICR,DADDR              POINT AT TRUE DICTIONARY         59220001
         BCR   BR,RR                                                    59250001
         SPACE                                                          59280001
NOFREE   MVI   WRSWCH+1,X'00'          SET SWITCH TO MAKE A NOTE OF TTR 59310001
         MVI   NONOTE+1,X'00'          SET SWITCH TO CONTROL LAST RCD   59340001
         L     GRB,BLK                 PICK UP TOTAL BLOCK LENGTH       59370001
         L     GRC,BLOKAD              PICK UP ADDRESS OF               59400001
         L     GRD,PAROF(CNTL)         POINT AT INIT LIST         H319  59410001
         L     GRD,UT1OF(GRD)          HENCE AT LGTH TO WRITE     H319  59420001
         LH    GRD,0(GRD)              PICK UP LENGTH TO WRITE    H319  59430001
         SPACE                                                          59460001
WRLOP    LA    DICR,OSSAVR             POINT AT NEW SAVE AREA           59490001
         SPACE                                                          59520001
         L     GR5,PAROF(CNTL)         POINT AT INIT LIST               59550001
         L     GR5,SPDCBOF(GR5)        HENCE AT SPILL DCB               59580001
         WRITE WDECB,SF,(GR5),(GRC),(GRD)          WRITE THIS RECORD    59610001
         SPACE                                                          59640001
         LA    1,WDECB                                                  59670001
         CHECK (1)                     CHECK WRITE IS OK                59700001
WRSWCH   BC    NOP,NONOTE                                               59730001
         MVI   WRSWCH+1,X'F0'          ONLY NOTE TTR ON FIRST RECORD    59760001
         LR    GRA,GR5                 POINT AT SPILL DCB               59790001
         NOTE  (1)                                                      59820001
         A     1,BUMPTR                BUMP R OF TTR TO ALLOW FOR POINT 59850001
         ST    1,NOTTR                                                  59880001
         SPACE                                                          59910001
NONOTE   BC    NOP,WRTOOT                                               59940001
         AR    GRC,GRD                 BUMP ADDR OF AREA TO BE WRITTEN  59970001
         SR    GRB,GRD                 REDUCE LENGTH TO BE WRITTEN      60000001
         LTR   GRB,GRB               SEE IF ANY LEFT TO BE WRITTEN      60030001
         BC    BZ,WRTOOT                                                60060001
         CR    GRD,GRB                 SEE IF LAST RECORD IS WRITTEN    60090001
         BC    BH,WRTCOM                                                60120001
         BC    B,WRLOP                                                  60150001
         SPACE                                                          60180001
WRTCOM   LR    GRD,GRB                 SET UP TO WRITE LAST BIT OF RCD  60210001
         MVI   NONOTE+1,X'F0'                                           60240001
         BC    B,WRLOP                                                  60270001
         SPACE                                                          60300001
WRTOOT   BC    B,WRTOUT                JUST AN EXTRA BRANCH             60330001
         EJECT                                                          60360001
         SPACE                                                          60390001
*                                                                       60420001
*              THIS ROUTINE ACTUALLY PERFORMS THE READING AND WRITING   60450001
*        OF TEXT AND DICTIONARY BLOCKS USING XDAP. THIS ROUTINE IS ONLY 60480001
*        ENTERED WHEN                                                   60510001
*              1) IT IS NECESSARY TO READ A BLOCK FROM DISK             60540001
*              2) IT IS NECESSARY TO FILL IN A HOLE IN THE DATASET MADE 60570001
*            BY A PREVIOUS READ                                         60600001
*              THE TTR OF THE RECORD IS FOUND IN TEMP4. THE FIRST PART  60630001
*        OF THE SPILL DCB IS SAVED AND THEN A POINT IS PERFORMED TO     60660001
*        CONVERT THE TTR TO ABSOLUTE IN THE DCB. XDAP USES THIS ABSOLUT 60690001
*        ADDRESS TO READ AND WRITE.                                     60720001
*              A TRACK-LENGTH OR A BLOCK-LENGTH IS WRITTEN AT A TIME,   60750001
*        DEPENDING UPON WHICH IS LEAST. TRACK-LENGTHS ARE WRITTEN UNTIL 60780001
*        THE BLOCK IS COMPLETE.                                         60810001
*              IF THE BLOCK SPANS MORE THAN ONE TRACK THEN THE TTR IN   60840001
*        TEMP4 IS BUMPED TO THE FIRST RECORD OF THE NEXT TRACK. THE     60870001
*        POINT IS PERFORMED EACH TIME ROUND THE LOOP IN ORDER TO        60900001
*        CONVERT THE NEW TTR                                            60930001
*                                                                       60960001
WRITEX   MVI   PLOOM+1,X'00'           SET FOR A WRITE                  60990001
         BC    B,XXX                                                    61020001
         SPACE                                                          61050001
READX    MVI   PLOOM+1,X'F0'           SET FOR A READ                   61080001
XXX      ST    RR,TEMPWR                                                61110001
         L     GR5,PAROF(CNTL)         POINT AT INITIALISATION LIST     61140001
         L     GRD,UT1OF(GR5)          AND HENCE AT LGTH TO WRITE H319  61150001
         L     GR5,SPDCBOF(GR5)        AND HENCE AT SPILL DCB           61170001
         SPACE                                                          61200001
         L     GRB,BLK                 PICK UP TOTAL BLOCK LENGTH       61230001
         L     GRC,BLOKAD              PICK UP ADDRESS OF BLOCK IN CORE 61260001
         LH    GRD,0(GRD)              PICK UP LGTH TO WRITE      H319  61290001
         MVI   CHEKX+1,X'00'           SET UP FOR ACTION                61320001
         SPACE                                                          61350001
         MVC   SAVPQ(16),4(GR5)      SAVE AREA ALTERED BY POINT         61380001
MDLOP    LR    1,GR5                 POINT AT SPILL DCB                 61410001
         LA    0,TEMP4                 POINT AT TTR TO BE CONVERTED     61440001
         SPACE                                                          61470001
         POINT (1),(0)                 GET ABSOLUTE ADDRESS OF TTR      61500001
         SPACE                                                          61530001
         LA    GRH,5(GR5)                                               61560001
PLOOM    BC    NOP,READY               BRANCH IF A READ REQUIRED        61590001
         SPACE                                                          61620001
         XDAP  ECBX,WI,(GR5),(3),(4),,(GRH),MF=E                        61650001
         SPACE                                                          61680001
         BC    B,IOCOMP                                                 61710001
         SPACE                                                          61740001
READY    XDAP  ECBX,RI,(GR5),(3),(4),,(GRH),MF=E                        61770001
         SPACE                                                          61800001
IOCOMP   LA    1,ECBX                  POINT AT IOB FOR WAIT            61830001
         SPACE                                                          61860001
         WAIT  ECB=(1)                 WAIT FOR READ OR WRITE TO COMPLT 61890001
         CLI   ECBX,X'7F'              TEST FOR ERROR ON SYSUT1         61920001
         BC    BNE,UTIERR                                               61950001
         SPACE                                                          61980001
CHEKX    BC    NOP,ALLOOP              BRANCH WHEN ALL BLOCK IS WRITTEN 62010001
         MVI   TEMP4+2,X'00'           SET R IN TTR TO ZERO             62040001
         L     GR0,TEMP4               PICK UP TTR OF RECORD            62070001
         A     GR0,BUMPTT              BUMP TO FIRST RCD OF NEXT TRACK  62100001
         ST    GR0,TEMP4                                                62130001
         AR    GRC,GRD                 BUMP ADDRESS                     62160001
         SR    GRB,GRD                 REDUCE LENGTH TO BE WRITTEN      62190001
         BC    BZ,ALLOOP                                                62220001
         CR    GRD,GRB                 SEE IF RECORD ALL WRITTEN        62250001
         BC    BNH,MDLOP               ON LAST LAP                      62280001
         SPACE                                                          62310001
ALMOST   LR    GRD,GRB                 SET UP TO I/O LAST BIT OF RECORD 62340001
         MVI   CHEKX+1,X'F0'                                            62370001
         BC    B,MDLOP                                                  62400001
         SPACE                                                          62430001
ALLOOP   L     RR,TEMPWR                                                62460001
         MVC   4(16,GR5),SAVPQ         RESTORE START OF SPILL DCB       62490001
         BCR   BR,RR                                                    62520001
         SPACE                                                          62550001
UTIERR   L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  62580001
         L     CNTL3,BASES             LOAD SECOND BASE                 62610001
         L     DICR,DADDR              POINT AT DICTIONARY              62640001
         MVI   IOERSW(DICR),X'FF'      SHOW I/O ERROR                   62670001
         L     LR,PAROF(CNTL)          POINT AT INITIALISATION LIST     62700001
         L     LR,DYNSWOF(LR)          HENCE AT DYNSW                   62730001
         MVI   0(LR),X'FF'             SHOW RETURN HERE                 62760001
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 62790001
         BALR  RR,LR                   ROUTINE IN AA                    62820001
         LA    GR0,UTIMES              SAY PERMANENT ERROR ON SYSUT1    62850001
         ST    GR0,PAR1(0,DICR)                                         62880001
         BAL   RR,ZUPL                                                  62910001
         LA    GR0,16                  SHOW A TERMINAL ERROR HAS        62940001
         ST    GR0,ERCODE(0,DICR)    OCURRED                            62970001
         L     LR,ZENDOF(CNTL)         POINT AT ZEND                    63000001
         BCR   BR,LR                   AND BRANCH                       63030001
*        ----------------------------------------------------AL 014-TSS 63060001
         EJECT                                                          63090001
         EJECT                                                          63120001
*        ROUTINE ZURD                                                   63150001
*                       THIS OBTAINS AN 80-CHARACTER CARD IMAGE FROM    63180001
*        SOME EXTERNAL DEVICE. ONLY ONE DCB IS USED. THE DCB IS OPENED  63210001
*        AND CLOSED DYNAMICALLY BY THE LOADING ROUTINE IN ORDER TO      63240001
*        SWITCH THE INPUT DEVICE. PAR1 CONTAINS THE ADDRESS OF THE AREA 63270001
*        INTO WHICH THE CARD IMAGE MUST BE PLACED. GET(MOVE) IS USED.   63300001
         SPACE 2                                                        63330001
ZURD     STM   14,CNTL2,12(DICR)       STORE REGS. REQUIRED BY ZURD     63360001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  63390001
         L     CNTL3,BASES             LOAD SECOND BASE                 63420001
         LA    2,SAVAR                                                  63450001
         ST    DICR,4(0,2)             STORE ADDRESS OF CALLING SAVE    63480001
         ST    2,8(0,DICR)           AREA AND OF CALLED SAVE AREA       63510001
         L     DICR,DADDR              POINT AT DICTIONARY              63540001
         L     0,PAR1(0,DICR)          PICK UP ADDRESS OF INPUT AREA    63570001
         SPACE                                                          63600001
         TM    CCCODE+2(DICR),X'01'    SEE IF SWITCH IS SET BY INTIAL-  63630001
RDBRCH   BC    BO,NOTREAD            ISOR. IF SO CARD ALREADY READ      63660001
         SPACE                                                          63690001
         LR    DICR,2                  POINT AT NEW SAVE AREA           63720001
         MVI   ZURDRT+3,X'04'          MAKE A NORMAL RETURN             63750001
         L     GRA,PAROF(CNTL)       POINT AT  INIT  LIST               63780001
         L     GRA,RDADDOF(GRA)        HENCE AT READ DCB ADDR           63810001
         L     GRA,0(0,GRA)          HENCE AT READ DCB                  63840001
         SPACE                                                          63870001
         GET   (1),(0)                 INSERT RECORD                    63900001
         SPACE                                                          63930001
RDLAST   L     DICR,DADDR                                               63960001
         SPACE                                                          63990001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 008-TSS 64020001
         USING IHADCB,GRA                                               64050001
         L     GRA,PAROF(CNTL)         POINT AT INITIALISATION LIST     64080001
         L     GRA,RDADDOF(GRA)        HENCE AT READ DCB ADDR           64110001
         L     GRA,0(0,GRA)            HENCE AT READ DCB                64140001
         LH    GRA,DCBLRECL            PICK UP RECORD LENGTH OF THIS    64170001
         ST    GRA,PAR2(0,DICR)      RECORD AND STORE TO TELL CALLER    64200001
         DROP  GRA                                                      64230001
         SPACE                                                          64260001
         L     GRC,PAR1(0,DICR)        POINT AT IN PUT BUFFER           64290001
*        ----------------------------------------------------AL 008-TSS 64320001
         CLC   0(1,GRC),BTCHCD         SEE IF IT IS A BATCH CONTROL CD  64350001
         BC    BNE,RDOUT                                                64380001
         LR    GRD,GRC                                                  64410001
BLNKOP   LA    GRD,1(GRD)          LOOK AT NEXT CHAR                    64440001
         CLI   0(GRD),X'40'        IS IT A BLANK                        64470001
         BC    BE,BLNKOP           BRANCH IF SO                         64500001
         CLC   0(7,GRD),PROCESSW   IS IT *  PROCESS                     64530001
         BC    BE,BATCH              BRANCH IF BATCH CARD         IEM00 64560001
         SPACE 1                                                  IEM00 64590001
         CLC   0(4,GRD),DATASW                                    IEM00 64620001
         BC    BNE,RDOUT             BRANCH IF NOT DATA CARD      IEM00 64650001
         SPACE 1                                                  IEM00 64680001
         L     LR,0(CNTL)            POSSIBLE ADDR OF DATA ROUTINEIEM00 64710001
         LTR   LR,LR                                              IEM00 64740001
         BC    BZ,RDOUT              BRANCH IF NOT LOAD AND GO    IEM00 64770001
         SPACE 1                                                  IEM00 64800001
         LR    13,2                  POINT TO SAVE AREA           IEM00 64830001
         BALR  RR,LR                                              IEM00 64860001
         BC    B,ZURDAB              MAKE END OF FILE RETURN      IEM00 64890001
         SPACE 1                                                  IEM00 64920001
BATCH    EX    GRA,SAVBTC            SAVE BATCH CARD TO LOOK FOR  IEM00 64950001
*                                                           PARM  IEM00 64980001
         STC   GRA,PARMLEN(0,DICR)     STORE RECORD LENGTH              65010001
         OI    CCCODE+3(DICR),X'08'    SHOW BATCH CARD FOUND            65040001
         BC    B,ZURDAB                                                 65070001
         SPACE                                                          65100001
RDOUT    LR    DICR,2                  POINT AT SAVE AREA               65130001
         L     DICR,4(0,DICR)          POINT AT NEXT LOWER SAVE AREA    65160001
         LM    14,CNTL2,12(DICR)       RELOAD ALL REGISTERS             65190001
         MVI   12(DICR),X'FF'          SHOW RETURN IS COMPLETE          65220001
ZURDRT   BC    B,4(0,RR)                                                65250001
         SPACE                                                          65280001
ZURDAB   L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  65310001
         L     CNTL3,BASES             LOAD SECOND BASE                 65340001
         MVI   ZURDRT+3,X'00'          MAKE IT EOF RETURN               65370001
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN        65400001
         OI    CCCODE+3(DICR),X'04'    SHOW END OF FILE CARD FOUND      65430001
         BC    B,RDOUT                                                  65460001
         SPACE                                                          65490001
NOTREAD  LR    GRA,GR0                 PICK UP INPUT AREA ADDRESS       65520001
         LA    GRD,READSL(0,DICR)      PICK UP ADDRESS OF FIRST CARD    65550001
         LH    GRC,READSL(0,DICR)      PICK UP LENGTH                   65580001
         ST    GRC,PAR2(0,DICR)                                         65610001
         BCTR  GRC,0                   REDUCE TO GIVE LENGTH OF BOVE    65640001
         STC   GRC,RCDMV+1                                              65670001
RCDMV    MVC   0(0,GRA),2(GRD)         MOVE RECORD INTO INPUT AREA      65700001
         MVI   RDBRCH+1,X'00'          ALL SUBSEQUENT CARDS ARE READ    65730001
         MVI   READSL(DICR),C' '       CLEAR PRINT AREA                 65760001
         MVC   READSL+1(80,DICR),READSL(DICR)                           65790001
         BC    B,RDOUT                                                  65820001
         SPACE                                                          65850001
SAVBTC   MVC   BTCHBUF(0),0(GRC)                                        65880001
         EJECT                                                          65910001
*              THE CONSTANT FIELDS FOR XDAP MACROS USED IN WRITEX       65940001
*        AND READX                                                      65970001
         SPACE 2                                                        66000001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 015-TSS 66030001
         XDAP  ECBX,WI,MF=L                                             66060001
*        ----------------------------------------------------AL 015-TSS 66090001
         EJECT                                                          66120001
*        ROUTINE ZUPL                                                   66150001
*                            THIS ROUTINE MOVES A LINE OF OUTPUT TO THE 66180001
*        OUTPUT BUFFER. PAGE CONTROL AND HEADINGS ARE PERFORMED AUTO-   66210001
*        MATICALLY.                                                     66240001
*              PAR1 POINTS AT THE LINE TO BE PRINTED. PAR3 MUST POINT   66270001
*        TO THE CALLERS HEADING LINE. THIS LINE WILL BE PRINTED ONLY    66300001
*        WHEN A SKIP TO A NEW PAGE OCCURS                               66330001
*              A COUNT OF THE LINES PRINTED/PAGE IS KEPT IN CCCOUN. IT  66360001
*        IS CHECKED AGAINST MAX LINES/PAGE BEFORE EVERY LINE IS PRINTED 66390001
*        IF THE PAGE IS FULL THEN THE NEWPAGE ROUTINE IS ENTERED. IT IS 66420001
*        HERE THAT PAGE NUMBERING IS PERFORMED.                         66450001
*              CONTROL ONLY LINES ARE EXPANDED BY ADDING 9 BLANKS. THIS 66480001
*        IS TO PREVENT I/O CHECKS SINCE THE O/S 360 DOES NOT SUPPORT    66510001
*        SUCH AN OBVIOUS REQUIREMENT                                    66540001
         SPACE 2                                                        66570001
ZUPL     STM   14,CNTL2,12(DICR)       STORE REGISTERS IN SAVE AREA     66600001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  66630001
         L     CNTL3,BASES             LOAD SECOND BASE                 66660001
         LA    GRA,OSSAVR              POINT AT NEW SAVE AREA           66690001
         ST    DICR,4(0,GRA)           CHAIN FORWARDS                   66720001
         ST    GRA,8(0,DICR)           CHAIN BACKWARDS                  66750001
         SPACE                                                          66780001
         L     GRE,CCCOUN              PICK UP PAGE COUNTER             66810001
         L     DICR,DADDR              POINT AT DICTIONARY              66840001
         L     GRD,PAR1(0,DICR)        PICK UP ADDRESS OF LINE TO PRINT 66870001
         CLI   THRSW,X'FF'             SEE IF THREE SPACE REQUIRED      66900001
         BC    BE,TRECC                                                 66930001
         SPACE                                                          66960001
         CLI    2(GRD),C'1'             SEE IF EJECT                    66990001
         BC    BE,EJLINE                                                67020001
MORLIN   CLI   HDSW,X'FF'              SEE IF FIRST LINE AFTER SUB HEAD 67050001
         BC    BNE,ON                                                   67080001
         MVI   HDSW,X'00'              CLEAR TO SHOW START OF PAGE IS   67110001
         BC    B,TWOCC               COMPLETE                           67140001
         SPACE                                                          67170001
ON       LA     GRA,1                                                   67200001
         CLI    2(GRD),C'+'             IS IT 0 LINES                   67230001
         BC     BE,L4                   BRANCH IF SO                    67260001
         CLI   2(GRD),C'0'              IS IT 2 LINES                   67290001
         BC     BE,L2                  BRANCH IF SO                     67320001
         CLI    2(GRD),C'-'             IS IT 3 LINES                   67350001
         BC     BE,L1                   BRANCH IF SO                    67380001
         MVI    2(GRD),C' '             MUST BE ONE LINE                67410001
         BC     B,L3                                                    67440001
L1       LA     GRA,1(GRA)                                              67470001
L2       LA     GRA,1(GRA)                                              67500001
L3       AR     GRE,GRA                 CALCULATE NEW CCCOUN            67530001
L4       MVI    HDSW,X'00'                                              67560001
         SPACE                                                          67590001
         CL    GRE,MAXPAG              SEE IF END OF PAGE HAS BEEN      67620001
         BC    BNL,NEWPAG            REACHED                            67650001
         SPACE                                                          67680001
         MVC   SETCC+1(1),2(GRD)       MOVE IN CNTL CHAR                67710001
         BC     B,TESTL                                                 67740001
         SPACE                                                          67770001
TRECC    MVI   SETCC+1,C'-'            SPACE 3                          67800001
         MVI   THRSW,X'00'                                              67830001
         BC    B,TESTL                                                  67860001
TWOCC    MVI   SETCC+1,C'0'            SPACE 2                          67890001
         SPACE                                                          67920001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 026-TSS 67930019
TESTL    LA    DICR,OSSAVR             POINT AT SAVE AREA               67950001
*        ----------------------------------------------------AL 026-TSS 67960019
         L     GRA,PAROF(CNTL)         POINT AT                         67980001
         L     GRA,PLDCBOF(GRA)        PRINT DCB                        68010001
         PUT   (1)                     FIND BUFFER SPACE                68040001
SETCC    MVI   4(GRA),X'00'            MOVE IN THE CC OP FOR THIS LINE  68070001
         SPACE                                                          68100001
         MVC   TEMP+2(2),0(GRD)        PICK UP LENGTH OF LINE           68130001
         LH    GRB,TEMP+2                                               68160001
         C     GRB,ZEROS               SEE IF CONTROL ONLY              68190001
         BC    BE,CONLYX                                                68220001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 010-TSS 68250001
*        ----------------------------------------------------AL 010-TSS 68280001
         SPACE                                                          68310001
         BCTR  GRB,0                   REDUCE LENGTH BY 1               68340001
         EX    GRB,PLMOVE              MOVE CHARACTERS TO BUFFER        68370001
         LA    GRB,1(0,GRB)            THIS GIVES TRUE LENGTH OF LINE   68400001
CONLY    LA    GRB,5(0,GRB)            THIS GIVES TRUE RECORD LENGTH    68430001
         ST    GRB,TEMP                                                 68460001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 006-TSS 68490001
         MVC   0(2,GRA),TEMP+2         INSERT LENGTH OF LOGICAL RECORD  68520001
*        ----------------------------------------------------AL 006-TSS 68550001
         SPACE                                                          68580001
         CLI   HDSW,X'FF'              SEE IF SUBSID HEADING            68610001
         BC    BNE,ZPLOUT                                               68640001
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN        68670001
         L     GRD,PAR1(0,DICR)        EVENTUALLY PRINT NEXT LINE       68700001
         BC    B,MORLIN                                                 68730001
         SPACE                                                          68760001
ZPLOUT   LA    GRA,OSSAVR              POINT AT SAVE AREA               68790001
         MVI   EJCSW,X'00'             ALWAYS TURN THIS SWITCH OFF      68820001
         MVI   HDSW,X'00'                                               68850001
         ST    GRE,CCCOUN              STORE PAGE LINE COUNT            68880001
         L     DICR,4(0,GRA)           POINT AT PREVIOUS SAVE AREA      68910001
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      68940001
         SPACE                                                          68970001
EJLINE   MVI   EJCSW,X'FF'             SHOW EJECT IN PROGRESS           69000001
         SPACE                                                          69030001
NEWPAG   AP    PAGNO(3),ONE(3)         ADD 1 TO PAGE NUMBER             69060001
         MVC   HEDING+113(6),EDWRD     EDIT INTO PAGE FIELD             69090001
         ED    HEDING+113(6),PAGNO                                      69120001
         MVI   THRSW,X'FF'             SHOW NEXT LINE MUST HAVE 3 SPACE 69150001
         LA    GRE,4                                                    69180001
         SPACE                                                          69210001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 023-TSS 69220019
*        ----------------------------------------------------AL 023-TSS 69230019
         LA    DICR,OSSAVR             POINT AT SAVE AREA               69240001
         L     GRA,PAROF(CNTL)         POINT AT                         69270001
         L     GRA,PLDCBOF(GRA)        PRINT DCB                        69300001
         PUT   (1)                     FIND BUFFER SPACE                69330001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 024-TSS 69340019
         MVC   0(125,GRA),HEDX         INSERT HEADING                   69360001
*        ----------------------------------------------------AL 024-TSS 69370019
         SPACE                                                          69390001
         L     DICR,DADDR              POINT AT DICTIONARY              69420001
         CLC   PAR3(4,DICR),ZEROS      SEE IF SECOND HEADING LINE RQD   69450001
         BC    BNE,SUBHED                                               69480001
         CLI   1(GRD),X'00'            SEE IF CONTROL ONLY              69510001
         BC    BE,ZPLOUT                                                69540001
         BC    B,TRECC                                                  69570001
SUBHED   L     GRD,PAR3(0,DICR)        PICK UP ADDRESS OF SUB-HEAD LINE 69600001
         LA    GRE,2(0,GRE)            HEADING + 1 BLANK LINE     45901 69630056
         MVI   HDSW,X'FF'                                               69660001
         BC    B,TRECC                                                  69690001
         SPACE                                                          69720001
CONLYX   EQU   *                                                  H268  69750001
         MVC   5(9,GRA),BLANKS         INSERT A DUMMY LINE              69780001
         LA    GRB,9(0,GRB)            BUMP TO GIVE A GOOD LINE COUNT   69810001
         BC    B,CONLY                                                  69840001
         SPACE                                                          69870001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 025-TSS 69880019
*        ----------------------------------------------------AL 025-TSS 69890019
EDWRD    DC    X'402020202020'                                          69900001
THRSW    DC    X'00'                                                    69930001
EJCSW    DC    X'00'                   SWITCH TO SHOW END OF PAGE       69960001
HDSW     DC    X'00'                   SWITCH TO SHOW USER HEADING      69990001
CCCOUN   DC    F'0'                    PAGE LINE COUNT                  70020001
MAXPAG   DC    F'55'                   MAXIMUM NUMBER OF LINES/PAGE     70050001
         SPACE                                                          70080001
BLANKS   DC    CL9' '                                             20706 70110001
         DS    0F                                                 20706 70140001
PAGNO    DC    X'00001F'               SET PAGE TO ONE ORIGINALLY       70170001
ONE      DC    X'00001F'               PAGE NUMBER INGREMENTER          70200001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 007-TSS 70230001
HEDX     DC    X'007C'                                                  70260001
         DC    X'0000'                                                  70290001
*        ----------------------------------------------------AL 007-TSS 70320001
         DC    C'1'                    EJECT CONTROL CHARACTER          70350001
HEDING   DS    104C                                                     70380001
         DC    C'PAGE'                                                  70410001
         DS    12C                                                      70440001
         SPACE                                                          70470001
PLMOVE   MVC   5(0,GRA),3(GRD)         MOVE IN LINE TO BE PRINTED       70500001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 004-TSS 70530001
SAVARD   DS    18F                                                      70560001
OSSAVR   DS    18F                                                      70590001
SAVAR    DS    18F                                                      70620001
*        ----------------------------------------------------AL 004-TSS 70650001
         EJECT                                                          70680001
TEMPZ    DS    F                                                        70710001
TEMPY    DC    2F'0'                                                    70740001
TEMSYN   DC    F'0'                                                     70770001
ABSAV    DS    18F                                                      70800001
BLK      DS    F                                                        70830001
ANSW     DS    F                                                        70860001
GETLST   DS    F                                                        70890001
         DS    F                                                        70920001
NUMFRE   DC    F'0'                    NUMBER OF FREE TRACKS            70950001
SAVAR3   DS    7F                                                       70980001
SAVPQ    DS    4F                                                       71010001
BLOKAD   DS    F                                                        71040001
SAVAR2   DS    7F                                                       71070001
TRKL     DS    F                                                        71100001
TEMPWR   DC    F'0'                                                     71130001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 009-TSS 71160001
*        ----------------------------------------------------AL 009-TSS 71190001
BUMPTR   DC    X'00000100'             USED TO BUMP R IN TTR            71220001
BUMPTT   DC    X'00010200'             BUMP TO FST RCD OF NEXT TRACK    71250001
FRSLOT   DC    30XL3'FF0000'           HOLDS TRACK ADDRESSES OF FREE    71280001
         DC    X'000000'             TRACKS ON DISK                     71310001
FADDR    EQU   0                                                        71340001
UNADDR   EQU   4                                                        71370001
WADDR    EQU   8                                                        71400001
         DC    X'0000'                                                  71430001
LASLOK   DC    X'0000'                                                  71460001
         DC    X'0000'                                                  71490001
         DC    X'0000'                                                  71520001
TEXTSW   DC    X'00'                   TEXT SWITCH FOR TRYMR            71550001
SPILL    DC    X'00'                   SPILL SWITCH                     71580001
DICSW    DC    X'00'                                                    71610001
LOKSW    DC    X'00'                                              H244  71640001
TEMPX    DC    X'0000'                                            H244  71670001
         DS    0H                                                 H244  71675020
LOKSV    DC    X'0000'                                            H244  71680001
PREVLOK  DC    X'0000'                                            H244  71690001
BTCHBUF  DC    101C' '                                                  71700001
PROCESSW DC    C'PROCESS'                                               71730001
DATASW   DC    C'DATA'                                            IEM00 71760001
K2       DC    F'2'                    CONSTANT 2                       71790001
         EJECT                                                          71820001
*              THIS ROUTINE RETURNS TO THE CALLER * * * * * ** * * * *  71850001
RETRTN   LM    14,CNTL2,12(DICR)        RELOAD REGISTERS                71880001
         MVI   12(DICR),X'FF'           SHOW RETURN IS COMPLETE         71910001
         BCR   BR,RR                    RETURN TO CALLER                71940001
         EJECT                                                          71970001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 028-TSS 71980019
*        ----------------------------------------------------AL 028-TSS 71990019
RECONS   STM   14,CNTL2,12(DICR)       STORE ZEND'S REGISTERS           72000001
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  72030001
         L     CNTL3,BASES             LOAD SECOND BASE                 72060001
         MVI   SPILL,X'00'             RECONSTITUTE                     72090001
         MVI   GCCHAN+1,X'00'          REINIT INSTRUCTION               72120001
         MVI   ZRAOFS+1,X'00'                                           72150001
         MVI   ZDEONE+1,X'00'                                           72180001
         L     GRA,NUMFRE              LOAD NO OF FREE TRACK ADDRESSES  72210001
         LTR   GRA,GRA                 TEST IF NUMFRE IS ZERO           72240001
         BC    BZ,NONFRE                YES, OMIT REINITIALISATION      72270001
*                                                                       72300001
         MVC   NUMFRE(4),ZEROS         ZERO NUMFRE                      72330001
         LA    GRA,30                  30 ENTRIES IN FRESLOTS           72360001
         LA    GRB,FRSLOT               POINT AT FREESLOTS              72390001
SLOTFF   MVI   0(GRB),X'FF'            SET SLOT TO NOT USED             72420001
         LA    GRB,3(0,GRB)            BUMP TO NEXT SLOT                72450001
         BCT   GRA,SLOTFF              LOOP IF MORE SLOTS               72480001
*                                                                       72510001
NONFRE   EQU   *                                                        72540001
         MVI   RDBRCH+1,X'10'          INSTRS IN AL                     72570001
         MVI   CONSLD+1,X'F0'          TO MAKE                          72600001
         MVC   CCCOUN(4),ZEROS         SERIALLY REUSABLE                72630001
         MVC   LOKSV(2),ZEROS                                     H244  72640001
         MVI   FSWTCH,X'00'            BLK CTL SWTCH FOR K PHASES       72660001
         LM    14,CNTL2,12(DICR)       RETURN TO                        72690001
         BCR   BR,RR                   ZEND                             72720001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 005-TSS 72750001
         EJECT                                                          72780001
         DCBD  DSORG=(BS),DEVD=DA                                       72810001
*        ----------------------------------------------------AL 005-TSS 72840001
         EJECT                                                          72870001
*                                                                       72900001
*              REGISTER EQUATES                                         72930001
*                                                                       72960001
GR0      EQU   0                                                        72990001
GR1      EQU   1                                                        73020001
GR5      EQU   5                                                        73050001
GRA      EQU   1                                                        73080001
GRB      EQU   2                                                        73110001
GRC      EQU   3                                                        73140001
GRD      EQU   4                                                        73170001
GRE      EQU   5                                                        73200001
GRF      EQU   6                                                        73230001
GRG      EQU   7                                                        73260001
GRH      EQU   8                                                        73290001
CNTL     EQU   11                                                       73320001
CNTL2    EQU   10                                                       73350001
RR       EQU   14                                                       73380001
CNTL3    EQU   9                                                        73410001
RT       EQU   12                                                       73440001
DICR     EQU   13                                                       73470001
LR       EQU   15                                                       73500001
*                                                                       73530001
*              BRANCH EQUATES                                           73560001
*                                                                       73590001
NOP      EQU   0                                                        73620001
B        EQU   15                                                       73650001
BR       EQU   15                                                       73680001
BH       EQU   2                                                        73710001
BL       EQU   4                                                        73740001
BNL      EQU   11                                                       73770001
BE       EQU   8                                                        73800001
BNE      EQU   7                                                        73830001
BNZ      EQU   7                                                        73860001
BNH      EQU   13                                                       73890001
BO       EQU   1                                                        73920001
BZ       EQU   8                                                        73950001
BM       EQU   4                                                        73980001
BNO      EQU   14                                                       74010001
BNM      EQU   11                                                       74040001
*              COMMUNICATIONS REGION EQUATES                            74070001
*                                                                       74100001
*                                                                       74130001
TLR      EQU   240                                                      74160001
ZTV      EQU   64                                                       74190001
ZTRAN1   EQU   68                                                       74220001
ZTRAN2   EQU   ZTRAN1+4                                                 74250001
ZNXTD    EQU   76                                                       74280001
ZSTAT    EQU   124                                                      74310001
PAR1     EQU   128                                                      74340001
PAR2     EQU   PAR1+4                                                   74370001
PAR3     EQU   PAR2+4                                                   74400001
PAR4     EQU   PAR3+4                                                   74430001
PAR5     EQU   PAR4+4                                                   74460001
PAR6     EQU   PAR5+4                                                   74490001
PAR7     EQU   PAR6+4                                                   74520001
PAR8     EQU   PAR7+4                                                   74550001
MYNAM    EQU   112                                                      74580001
FSTDIC   EQU   160                                                      74610001
TERMSW   EQU   176                                                      74640001
PARMLEN  EQU   197                                                      74670001
IOERSW   EQU   191                                                      74700001
SPLNAM   EQU   180                                                      74730001
SCNOF    EQU   184                                                      74760001
SECHF    EQU   185                                                      74790001
ZDROLF   EQU   186                                                      74820001
DICTSP   EQU   200                                                      74850001
ZNXTOF   EQU   204                                                      74880001
FONOF    EQU   208                                                      74910001
CCCODE   EQU   232                                                      74940001
ABOTOF   EQU   X'20'                                                    74970001
ZUST     EQU   X'4C'                                                    75000001
ARINT    EQU   248                                                      75030001
ERCODE   EQU   224                                                      75060001
ARMASK   EQU   273                                                      75090001
DICTSZ   EQU   260                                                      75120001
TXTSZ    EQU   264                                                      75150001
ZMASK    EQU   284                                                      75180001
LOCK     EQU   274                                                      75210001
ZSHIFT   EQU   280                                                      75240001
CORLFT   EQU   160                                                      75270001
ZMASK1   EQU   286                                                      75300001
ZPRNAM   EQU   288                                                      75330001
ZDNXT    EQU   96                                                       75360001
PERRSW   EQU   189                                                      75390001
ZERRD    EQU   80                      HEADERS OF ERROR CHAINS          75420001
OFDNAM   EQU   178                                                      75450001
ZOBNUM   EQU   182                                                      75480001
MAXFON   EQU   198                                                      75510001
FSTDRF   EQU   212                                                      75540001
OFFSLOF  EQU   228                                                      75570001
OFENOF   EQU   X'F4'                                                    75600001
ZOBSAD   EQU   172                                                      75630001
ZSAV     EQU   664                     REGISTER SAVE AREA         33893 75640020
*                                                                       75660001
*              THIS EQUATE IS FOR THE FIRST CARD READ BY THE INITIALISR 75690001
*                                                                       75720001
READSL   EQU   500                                                      75750001
*        TRANSFER VECTOR AND INITIALISATION LIST EQUATES                75780001
*                                                                       75810001
DYNAMOF  EQU   136                                                      75840001
ABORTOF  EQU   32                                                       75870001
DYNSWOF  EQU   88                                                       75900001
ZENDOF   EQU   108                                                      75930001
RDADDOF  EQU   60                                                       75960001
PAROF    EQU   28                                                       75990001
PLDCBOF  EQU   20                                                       76020001
SPDCBOF  EQU   40                                                       76050001
BASOF    EQU   140                                                      76080001
UT1OF    EQU   184                                                H319  76090001
TAB1OF   EQU   64                      TABLE 1 OFFSET             32318 76100020
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*AL 021-TSS 76110001
*        ----------------------------------------------------AL 021-TSS 76140001
*                                                                       76170001
         END   IEMAL                                                    76200001
