         GBLB  &STD                                                     00010021
&STD     SETB  1                                                        00020021
AN       TITLE 'IEMAN,RESIDENT CONTROL PHASE,COMPILER CONTROL,OS/360,PLC00040015
               /I COMPILER(F)'                                          00080015
*             STATUS - CHANGE LEVEL 0                                   00081056
*                                                                       00082056
*                                                                       00083056
*                                                                       00084072
* 5.5  C 432800,434800,435200-436800,440800-444000             KT 60037 00084172
* 5.4  A 000000,497600.                                       MCB 54703 00084221
* 5.4  A 145600.                                              MAC 52214 00084321
* 5.3B A 259000.     ADDITION TO R20.0 FIX FOR A32318.        MAC 47635 00084556
* 5.3B C 738000                                              PJMG 45901 00085056
* 5.3A C 258760-259120                                        JLC 43391 00086056
* 5.2  A 145600,146000,172600,172900,805600                   JLC 33893 00087056
* 5.2  A 173600,257600,564000,811600                          JRT 32318 00088056
*      C 024800-025600,058800,060000,172400-172800,254000,    JRT 32318 00089056
*        255600,258800,295200,297600,319600,321200,563520     JRT 32318 00090056
*      D 189200,343200-345600,581200                          JRT 32318 00091056
* 5.2  A 233600                                               JRT 30357 00092056
*      C 327600                                               JRT 30357 00093056
*                                                                       00094056
* R18 150400*                                                     23286 00106001
* R18 739600-740000,739800                                        H268  00112001
* R18 500000,503200-512000,613000,636200,638000,812200            H319  00116001
* R18 744800                                                      20706 00136056
         SPACE                                                          00156056
*                                                                       00200015
*                                                                       00240015
*              FUNCTIONS - 1)COMPILER INITIALISATION. IEMAB IS LOADED   00280015
*        IN ORDER TO PERFORM THIS FUNCTION                              00320015
*                          2)CHARACTER TRANSLATION. EBCIDIC OR BCD TO   00360015
*        INTERNAL AND BACK TO EXTERNAL. THE RELEVANT TABLE IS SUPPLIED  00400015
*        DEPENDING UPON THE OPTION                                      00440015
*                          3)DICTIONARY AND TEXT BLOCK CONTROL. THESE   00480015
*        INCLUDE,EVENTUALLY,THE SPILLING OF BLOCKS ONTO SYSUT1 AND THE  00520015
*        CONTROL THEREOF.                                               00560015
*                          4)PHASE LOADING. FACILITIES ARE ALLOWED FOR  00600015
*        MARKING PHASES,LOADING PHASES AND RETURNING CONTROL TO THE     00640015
*        CALLER,DELETING(RELEASING) PHASES AND PASSING CONTROL TO A NEW 00680015
*        PHASE.                                                         00720015
*                          5)INPUT/OUTPUT CONTROL ONTO SYSPRINT,SYSIN,  00760015
*        SYSLIN AND SYSPUNCH. CONTROL TO SYSUT3 IN IEMAC                00800015
*                                                                       00840015
*                                                                       00880015
*              ENTRY POINT - THE CONTROL PHASE HAS A MULTITUDE OF ENTRY 00920015
*        POINTS. THE ARE LISTED IN THE TRANSFER VECTOR AT THE START OF  00960015
*        THE PHASE                                                      01000015
*                                                                       01040015
*                                                                       01080015
*              INPUT - ONLY INPUT IS THE PARAMETER LIST POINTED AT BY   01120015
*        GENERAL REGISTER 1 ON ENTRY                                    01160015
*                                                                       01200015
*                                                                       01240015
*              OUTPUT - THE ONLY OUTPUT GENERATED BY THE COMPILER IS    01280015
*        THE RETURN CODE PLACED IN GENERAL REGISTER 15 ON COMPLETION OF 01320015
*        THE COMPILATION                                                01360015
*                                                                       01400015
*                                                                       01440015
*              EXTERNAL ROUTINES - 1)IEMAB THE COMPILER INITIALISER. IT 01480015
*        IS LOADED IMEDIATELY AFTER IEMAA HAS BEEN LOADED.              01520015
*                                  2)IEMAC. THE INTERMEDIATE FILE       01560015
*        CONTROL. RECORDS ARE WRITTEN ON SYSUT3 AND THE READ BACK.      01600015
*                                  3)IEMAD. INTER-PHASE DUMPING CONTROL 01640015
*        TESTRAN IS USED                                                01680015
*                                  5)IEMAF. GENERATED BY SYSGEN. IT     01720015
*        WILL INDICATE THE STATUS OF THE DEFAULT OPTIONS                01760015
*                                  6)IEMAG. SYSUT3 FILE SWITCHING. IT   01800015
*        IS CALLED BY IEMAC.                                            01840015
*                                  4)IEMAE. CLEAN-UP AFTER READIN AND   01880015
*        OPEN SYSLIN AND SYSPUNCH IF NECESSARY                          01920015
*                                                                       01960015
*                                                                       02000015
*              EXITS - THE EXIT IS THROUGH ZEND. IT IS THERE THAT THE   02040015
*        CONDITION CODE IS PICKED UP. THERE ARE NO ABNORMAL EXITS.      02080015
*                                                                       02120015
*                                                                       02160015
*              ATTRIBUTES - THIS CODE IS NOT REUSABLE                   02200015
         EJECT                                                          02240015
*                                                                       02280015
*              BASE THE COMPILER                                        02320015
*                                                                       02360015
         SPACE 2                                                        02400015
IEMAN    CSECT                                                          02440001
         USING *,CNTL2,CNTL3                                      32318 02490020
BASES    DC    A(*+4096)               ADDRESS IN SECOND BASE REG.32318 02540020
         DC    A(BASES)                                                 02600015
*                                                                       02640015
*        THESE ADDRESSES WILL BE MOVED INTO THE TRANSFER VECTOR         02680015
*        IN IEMAA BY IEMAB                                              02720015
*                                                                       02760015
TRVEC    DC    A(ZUPL)                 SYSPRINT                         02800015
         DC    A(ZURD)                 SYSIN                            02840015
         DC    A(ZUGC)                 GET SCRATCH CORE                 02880015
         DC    A(ZUTXTC)               GET A TEXT BLOCK                 02920015
         DC    A(ZURC)                 RELEASE SCRATCH CORE             02960015
         DC    A(ZDICAB)               DICT ENTRY-ALIGNED,ABSOLUTE      03000015
         DC    A(ZDICRF)                         -ALIGNED,REFERENCE     03040015
         DC    A(ZUERR)                MAKE AN ERROR MESSAGE ENTRY      03080015
         DC    A(ZDRFAB)               DICTIONARY REFERENCE TO ABSOLUTE 03120015
         DC    A(ZTXTRF)               TEXT POINTER-ABSOLUTE TO REF     03160015
         DC    A(ZTXTAB)                           -REF TO ABS          03200015
         DC    A(ZCHAIN)               FIND NEXT TEXT BLOCK IN CHAIN    03240015
         DC    A(ZALTER)               ALTER STATUS OF TEXT BLOCK       03280015
         DC    A(ZDABRF)               DICT-ABS TO REF                  03320015
         DC    A(ZNALRF)               DICT ENTRY-UNALIGNED,REF         03360015
         DC    A(ZNALAB)                         -UNALIGNED,ABS         03400015
         DC    A(RECONS)               RECONST. INSTRS IN AL            03440015
         DC    A(ALLOCA)               SCRATCH CORE                     03480015
         DC    A(ALLOCL)                                                03520015
CONSLTT  DC    A(TSLOTS+24)            TEXT ALLOCATION SLOTS            03560001
CONSLDD  DC    A(DSLOTS+24)            DICT ALLOCATION SLOTS            03600001
         DC    A(HEDING)               PAGE HEADING                     03640015
         DC    A(MAXPAG)               MAX. PAGE COUNT                  03680015
         DC    A(PAGNO)                PAGE NUMBER                      03720015
         DC    A(NUMFRE)               NO. FREE TRACKS                  03760015
         DC    A(FRSLOT)               LIST FREE TRACKS                 03800015
         DC    A(BLKTBL)                                                03840015
         DC    A(SPILL)                                                 03880015
         DC    A(CONCNT)                                                03920015
         DC    A(BTCHBUF)              BATCH CARD FOR PARM SCAN         03960015
DADDR    DS    F                                                        04000015
         DC    A(UTIERR)             SYSUT1 ERROR RTN                   04040015
         DC    A(ZURDAB)             SYSIN EOF RTN                      04080015
BLKTBL   DC    10XL4'FF000000'                                          04120015
         EJECT                                                          04160015
*        ROUTINE ZDABRF                                                 04200015
*                       THIS ROUTINE TAKES AN ABSOLUTE ADDRESS IN PAR2  04240015
*        AND CONVERTS IT TO A REFERENCE. PAR1 MUST POINT AT THE BLOCK   04280015
*        WHICH CONTAINS THE ABSOLUTE ADDRESS                            04320015
*        PAR1 CONTAINS,IN FACT, A DICTIONARY REFERENCE TO THE BLOCK     04360015
*        WHICH CONTAINS THE ABSOLUTE ADDRESS. IF THE REFERENCED BLOCK   04400015
*        IS NOT IN USE OR IS NOT IN CORE THEN THE COMPILER TERMINATES.  04440015
*        THE ENTRY INTO THE LAST-LOOK TABLE (LASLOK) IS MADE ONLY WHEN  04480015
*        THE ENTRY TO ZDABRF IS NOT FROM THE ROUTINE THAT MAKES DICT-   04520015
*        IONARY ENTRIES (ZDICRF ETC). THE LAST-LOOK TABLE IS USED ONLY  04560015
*        WHEN DICTIONARY SPILL TAKES PLACE.                             04600015
*                                                                       04640015
         SPACE 2                                                        04680015
ZDABRF   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               04720015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  04760015
         L     CNTL3,BASES             LOAD SECOND BASE                 04800015
         ST    DICR,DICTEM             STORE ADDRESS OF THIS SAVE AREA  04840015
         L     DICR,DADDR              POINT AT TRUE DICTIONARY         04880015
         SPACE                                                          04920015
         BAL   RR,CONSLD               POINT AT SLOT IN DSLOTS          04960015
         SPACE                                                          05000015
         CLI   0(GRA),X'FF'            SEE IF BLOCK IN USE              05040015
         BC    BE,BLKERR                                                05080015
         TM    0(GRA),X'80'            TEST IF IN CORE. IF ON DISK, IT  05120015
         BC    BZ,ERRBF              IS AN ERROR                        05160015
         CLI   SWTCH,X'00'             TEST IF ENTRY FROM ZDICRF        05200015
         BC    BNE,NOENTY              BRANCH IF NO ENTRY IN LASLOK RQD 05240015
         SPACE                                                          05280015
         MVC   LASLOK-2(6),LASLOK      INSERT REF IN LAST-LOOK TABLE    05320015
         MVC   LASLOK+4(2),PAR1+2(DICR) TABLE                           05360015
         SPACE                                                          05400015
NOENTY   L     GRA,0(0,GRA)            GET ADDRESS OF BLOCK             05440015
         N     GRA,STBITS                                               05480015
         S     GRA,PAR2(0,DICR)        SUBTRACT ABSOLUTE ADDRESS TO GET 05520015
         LPR   GRA,GRA               REFERENCE. THEN TURN POSITIVE      05560015
         NC    PAR1+2(2,DICR),ZMASK1(DICR) REMOVE OFFSET IN             05600015
         O     GRA,PAR1(0,DICR)      PAR1 AND OR IN NEW OFFSET          05640015
         ST    GRA,PAR1(0,DICR)                                         05680015
         SPACE                                                          05720015
         L     DICR,DICTEM             POINT AT THIS SAVE AREA          05760015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      05800015
         SPACE                                                          05840015
ERRBF    MVC   PAR6+1(3,DICR),ERRF03   BLOCK NOT IN CORE          32318 05860020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 05880020
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC ROUTINE         05920015
         BALR  RR,LR                   IN AA                            05960001
ERRF03   DC    X'0F03C0'                                          32318 06000020
         EJECT                                                          06040015
*        ROUTINE ZDRFAB                                                 06080015
*                       THIS ROUTINE TAKES A DICTIONARY REFERENCE AND   06120015
*        CONVERTS IT TO AN ABSOLUTE ADDRESS. IF BLOCK IS NOT IN CORE    06160015
*        THEN TRYMRD IS ENTERED IN ORDER TO GET THE BLOCK INTO CORE     06200015
*        THE DICTIONARY REFERENCE IS FOUND IN PARAMETER 1 (PAR1). THE   06240015
*        ABSOLUTE ADDRESS IS RETURNED IN PAR1. THE LAST-LOOK ENTRY IS   06280015
*        ALWAYS MADE SINCE THIS ROUTINE IS ALWAYS CALLED FROM ZDICRF    06320015
*        ETC. ZDICRF DOES NOT MAKE ENTRIES INTO THE LAST-LOOK TABLE     06360015
*        DIRECTLY.                                                      06400015
         SPACE                                                          06410015
*                   ( YOU'VE GOT TO HAVE FAITH IN ZDRFAB  )             06420015
         SPACE                                                          06430015
         SPACE 2                                                        06440015
ZDRFAB   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               06480015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  06520015
         L     CNTL3,BASES             LOAD SECOND BASE                 06560015
         ST    DICR,DICTEM             STORE ADDRESS OF THIS SAVE AREA  06600015
         L     DICR,DADDR              POINT AT TRUE DICTIONARY         06640015
         SPACE                                                          06680015
         BAL   RR,CONSLD               POINT AT SLOT IN DSLOTS          06720015
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           06760015
         BC    BE,BLKERR                                                06800015
         CLI   SWTCH,X'00'             SEE IF ENTRY FROM ZDICRF         06840015
         BC    BNE,TONDK                                                06880015
         MVC   LASLOK-2(6),LASLOK      MOVE REFERENCE TO LAST LOOK      06920015
         MVC   LASLOK+4(2),PAR1+2(DICR) TABLE                           06960015
TONDK    TM    0(GRA),X'80'            TEST IF BLOCK ON DISK            07000015
         BC    BZ,RFOND                                                 07040015
         SPACE                                                          07080015
NOWIN    L     GRB,0(0,GRA)            PICK UP ADDRESS OF BLOCK         07120015
         N     GRB,STBITS                                               07160015
         NC    PAR1+2(2,DICR),ZMASK(DICR) REMOVE REFERENCE BITS TO GET  07200015
         AH    GRB,PAR1+2(0,DICR)      OFFSET. ADD OFFSET TO GET ABSOLT 07240015
         ST    GRB,PAR1(0,DICR)        ADDRESS                          07280015
         SPACE                                                          07320015
         L     DICR,DICTEM             POINT AT THIS SAVE AREA          07360015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      07400015
         SPACE                                                          07440015
RFOND    MVC   RDTTR(3),1(GRA)         INSERT RELATIVE TRACK ADDRESS    07480015
         BAL   RR,TRYMRD                                                07520015
         ST    GR0,0(0,GRA)            STORE ADDRESS OF BLOCK           07560015
         MVI   0(GRA),X'84'            MARK AS INCORE AND BUSY          07600015
         BC    B,NOWIN                                                  07640015
         EJECT                                                          07680015
*        ROUTINES ZNALAB,ZDICAB,ZNALRF,ZDICRF                           07720015
*                       THIS ROUTINE WILL MAKE A DICTIONARY ENTRY.      07760015
*        BLOCKS ARE AUTOMATICALLY SPANNED. NO ENTRY IS MADE ACROSS A    07800015
*        BLOCK BOUNDARY. THE N ROUTINES WILL MAKE ENTRIES AT THE NEXT   07840015
*        AVAILABLE LOCATION,OTHERWISE ENTRIES ARE ALIGNED ON THE NEXT   07880015
*        FULL WORD BOUNDARY.                                            07920015
*              THE SEQUENCE OF OPERATIONS IS AS FOLLOWS                 07960015
*             1) THE LENGTH OF THE ENTRY IS CHECKED TO SEE IF IT WILL   08000015
*            FIT INTO A COMPLETE DICTIONARY BLOCK. IF IT WILL NOT THEN  08040015
*            THE COMPILER CANNOT CONTINUE AND AN ABORT TAKES PLACE      08080015
*             2) THE DICT. REFERENCE TO THE NEXT AVAILABLE DICTIONARY   08120015
*            SPACE IS CONVERTED TO ABSOLUTE BY ZDRFAB. THIS ALSO ENSURE 08160015
*            S THAT THE BLOCK IS BROUGHT INTO CORE. AN ALIGNMENT ON THE 08200015
*            NEXT WORD BOUNDARY IS PERFORMED IF NECESSARY (IE THE       08240015
*            ROUTINE HAS BEEN ENTERED AT ZDICAB OR ZDICRF)              08280015
*             3) A CHECK IS MADE TO SEE IF THE  ENTRY WILL FIT INTO     08320015
*            THE REST OF THE CURRENT BLOCK. IF THE ENTRY WILL NOT FIT   08360015
*            THEN A BRANCH TO NEWBLK IS PERFORMED.                      08400015
*             4) THE ENTRY IS MOVED INTO THE BLOCK BY A MOVE-CHARACTERS 08440015
*            LOOP AT MOVLOP. IF A ZERO LENGTH ENTRY (FOR ZERO LENGTH    08480015
*            BIT STRINGS ETC) IS REQUIRED THIS LOOP IS BYPASSED.        08520015
*             5) THE ADDRESS OF THE LOCATION IMMEDIATELY AFTER THE LAST 08560015
*            POINT IN THE ENTRY IS CONVERTED TO A REFERENCE BY ENTRY TO 08600015
*            ZDABRF                                                     08640015
*             6) RETURN                                                 08680015
*             7) IF A NEW BLOCK IS REQUIRED, A DICTIONARY STOPPER,      08720015
*            X'CF',IS ENTERED FOLLOWED BY A REFERENCE TO THE NEXT BLOCK 08760015
*            TRYMRD IS ENTERED TO OBTAIN THE NEW BLOCK. THE NEW BLOCKS  08800015
*            ADDRESS IS ENTERED IN THE NEXT AVAILABLE SPACE IN THE      08840015
*            DICTIONARY BLOCK CONTROL AREA,DSLOTS. IT IS MARKED AS IN   08880015
*            CORE AND BUSY                                              08920015
*              THERE ARE TWO CONDITIONS WHICH WILL CAUSE THE COMPILER   08960015
*        TO TERMINATE- ENTRY TOO LONG AND DICTIONARY IS FULL.           09000015
         SPACE 2                                                        09040015
SWTCH    DC    X'00'                                                    09080015
ZNALAB   STM   14,CNTL2,12(DICR)    STORE BASES                         09120015
          L    CNTL2,BASOF(CNTL)                                        09160015
          MVI   SWTCH,X'81'        SET NALAB SWITCH                     09200015
         BC    B,DICST                                                  09240015
ZDICAB   STM   14,CNTL2,12(DICR)    STORE BASES                         09280015
          L    CNTL2,BASOF(CNTL)     LOAD FIRST BASE REGISTER           09320015
          MVI   SWTCH,X'41'        SET DICAB SWITCH                     09360015
         BC    B,DICST                                                  09400015
ZNALRF   STM   14,CNTL2,12(DICR)    STORE BASES                         09440015
          L    CNTL2,BASOF(CNTL)     LOAD FIRST BASE REGISTER           09480015
          MVI   SWTCH,X'82'        SET NALRF SWITCH                     09520015
         BC    B,DICST                                                  09560015
ZDICRF   STM   14,CNTL2,12(DICR)    STORE BASES                         09600015
          L    CNTL2,BASOF(CNTL)     LOAD FIRST BASE REGISTER           09640015
          MVI   SWTCH,X'42'        SET DICRF SWITCH                     09680015
         SPACE                                                          09720015
DICST    L     CNTL3,BASES             LOAD SECOND BASE REGISTER        09760015
         LA    GRA,SAVARD              POINT AT NEW SAVE AREA           09800015
         ST    DICR,4(0,GRA)           CHAIN FORWARD                    09840015
         ST    GRA,8(0,DICR)           CHAIN BACKWARDS                  09880015
         L     DICR,DADDR              POINT AT TRUE DICTIONARY         09920015
         SPACE                                                          09960015
         L     GRA,DICTSP(0,DICR)      TEST IF ENTRY WILL FIT A BLOCK   10000015
         C     GRA,PAR2(0,DICR)        COMPARE LENGTH WITH BLOCK SPACE  10040015
         BC    BL,ERR04                                                 10080015
         SPACE                                                          10120015
         MVC   TEMP(8),PAR1(DICR)      STORE ADDRESS AND LENGTH OF NEW  10160015
         SPACE                                                          10200015
         MVC   PAR1(4,DICR),ZNXTD(DICR) GET ABSOLUTE ADDRESS OF NEXT    10240015
         LA    DICR,SAVARD           AVAILABLE SPACE. POINT AT NEW SAVE 10280015
         BAL   RR,ZDRFAB             AREA. GET ABSOLUTE ADDRESS         10320015
         L     DICR,DADDR              POINT AT TRUE DICTIONARY AGAIN   10360015
         L     GRC,PAR1(0,DICR)                                         10400015
         MVC   0(3,GRC),ZEROS          SET BYTES BETWEEN ENTRYS TO ZERO 10440015
         ST    GRC,TEMP2               STORE ADDRESS INCASE ENTRY NOT   10480015
*                                      FIT                              10520015
         TM    SWTCH,X'80'             TEST IF ALIGNMENT REQUIRED FOR   10560015
         BC    BO,NALG               THIS ENTRY                         10600015
         A     GRC,THREE               ALIGN ON NEXT FULL WORD BOUNDARY 10640015
         N     GRC,MASKX                                                10680015
         SPACE                                                          10720015
NALG     MVC   PAR1(4,DICR),ZNXTD(DICR)                                 10760015
         BAL   RR,CONSLD                POINT AT SLOT WITH ADDRESS OF   10800015
         L     GRD,0(0,GRA)           THIS BLOCK. PICK UP START OF BLOK 10840015
         N     GRD,STBITS               GET RID OF STATUS BITS          10880015
         A     GRD,DICTSP(0,DICR)      CALC END OF USEABLE BLOCK        10920015
         SPACE                                                          10960015
         LR    GRB,GRC                                                  11000015
         A     GRB,TEMP1                GRB HOLDS END IF ENTRY IS MADE. 11040015
         CR    GRB,GRD                  TEST IF ENTRY WILL FIT IN THIS  11080015
         BC    BH,NEWBLK              BLOCK                             11120015
         SPACE                                                          11160015
SETUP    ST    GRB,NEXTAD              STORE NEXT AVAILABLE LOCN        11200015
         MVI   0(GRB),X'ED'          MARK PRESENT END OF DICT           11240015
         LM    GRA,GRB,TEMP            GRA=ADDRESS GRB=LENGTH           11280015
         MVC   PAR4(4,DICR),ZNXTD(DICR)   SAVE NEW REF FOR ABS CALL     11320015
         TM    SWTCH,X'01'             TEST IF REFERENCE REQUIRED       11360015
         BC    BO,MOLAP                                                 11400015
         MVC   TEMP2(4),ZNXTD(DICR)    MOVE IN REFERENCE OF NEXT ENTRY  11440015
         ST    GRC,PAR4(DICR)          SAVE NEW ABS FOR REF CALL        11480015
         SPACE                                                          11520015
MOLAP    LTR   GRB,GRB                 SEE IF ZERO LENGTH ENTRY         11560015
         BC    BZ,NOMOV                                                 11600015
         SPACE                                                          11640015
MOVLOP   C     GRB,TW56                SEE IF MORE THAN 256 CHARS TO    11680015
         BC    BH,SUMMOR             MOVE                               11720015
         BC    B,LASMOV                                                 11760015
SUMMOR   MVC   0(256,GRC),0(GRA)       MOVE PART OF ENTRY TO DICTIONARY 11800015
         A     GRC,TW56                BUMP DICTIONARY ADDRESS          11840015
         A     GRA,TW56                BUMP ENTRY ADDRESS               11880015
         S     GRB,TW56                REDUCE COUNT                     11920015
         BC    B,MOVLOP                                                 11960015
         SPACE                                                          12000015
LASMOV   BCTR  GRB,0                   REDUCE COUNT BY ONE TO GIVE THE  12040015
         STC   GRB,DICMOV+1          LAST MOVE THE CORRECT VALUE        12080015
DICMOV   MVC   0(0,GRC),0(GRA)         MOVE IN LAST BIT OF ENTRY        12120015
         SPACE                                                          12160015
NOMOV    MVC   PAR1(4,DICR),ZNXTD(DICR) PREPARE TO CONVERT END ADDRESS  12200015
         MVC   PAR2(4,DICR),NEXTAD   TO A DICTIONARY REFERENCE          12240015
         LA    DICR,SAVARD             POINT AT NEW SAVE AREA           12280015
         BAL   RR,ZDABRF                                                12320015
         L     DICR,DADDR              PICK UP TRUE DICTIONARY          12360015
         MVC   ZNXTD(4,DICR),PAR1(DICR) INSERT REF OF NEXT AVAIL LOCTN  12400015
         SPACE                                                          12440015
         L     GR0,TEMP2               PICK UP REFERENCE OR ABSOLUTE    12480015
         SPACE                                                          12520015
         TM    SWTCH,X'80'             TEST IF ALIGNMENT REQUIRED       12560015
         BC    BO,NALG1                                                 12600015
         A     GR0,THREE               ALIGN ON NEXT FULL WORD BOUNDARY 12640015
         N     GR0,MASKX             TO AGREE WITH ENTRY MADE           12680015
         SPACE                                                          12720015
NALG1    ST    GR0,PAR1(0,DICR)        STORE REQUIRED RESULT            12760015
         MVC   PAR2(4,DICR),TEMP1      RESTORE LENGTH                   12800015
         MVI   SWTCH,X'00'             SET ALL SWITCHES OFF             12840015
         SPACE                                                          12880015
         LA    DICR,SAVARD                                              12920015
         L     DICR,4(0,DICR)          PICK UP PREVIOUS SAVE AREA       12960015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      13000015
         SPACE                                                          13040015
NEWBLK   L     GRC,TEMP2               POINT AT UNALIGNED BYTE          13080015
         MVI   0(GRC),X'CF'            INSERT STOPPER AT END OF BLOCK   13120015
         LA    GRD,DSLOTS+24                                            13160015
         LA    GRA,4(0,GRA)            POINT AT NEXT IN DSLOTS          13200015
         CLI   1(GRA),X'FF'            TEST FOR STOPPER                 13240015
         BC    BE,ERR13                                                 13280015
         SR    GRD,GRA                                                  13320015
         LPR   GRD,GRD                 THIS IS OFFSET OF SLOT IN DSLOTS 13360015
         SPACE                                                          13400015
         MVC   SHIFTA+3(1),ZSHIFT+3(DICR) INSERT SHIFT TO MAKE REF      13440015
         SRA   GRD,2                   REDUCE OFFSET TO COUNT AND       13480015
SHIFTA   SLA   GRD,0                   MOVE REQUIRED NUMBER OF PLACES   13520015
         ST    GRD,ZNXTD(0,DICR)       INSERT REF OF NEW BLOCK          13560015
         MVC   1(2,GRC),ZNXTD+2(DICR)  STORE REF AFTER X'CF'            13600015
         L     GR0,0(0,GRA)            PICK UP IN CASE IS FREE          13640015
         CLI   0(GRA),X'81'            TEST IF THIS BLOCK IS IN CORE    13680015
         BC    BE,JUMPRF             AND FREE                           13720015
         CLI   0(GRA),X'83'            SEE IF HAS BEEN ALLOCATED        13760015
         BC    BE,JUMPRF                                                13800015
         CLI   0(GRA),X'84'            SEE IF HAS BEEN ALLOCATED        13840015
         BC    BE,JUMPRF                                                13880015
         SPACE                                                          13920015
         XC    RDTTR(4),RDTTR          SET RDTTR=0 TO SHOW NO READ RQRD 13960015
         MVI   MAKSW,X'FF'             SHOW IS A NEW DICT BLOCK ENTRY   14000015
         BAL   RR,TRYMRD               TRY FOR A NEW DICTIONARY BLOCK   14040015
         MVI   MAKSW,X'00'             TURN IT OFF AGAIN                14080015
JUMPRF   ST    GR0,0(0,GRA)            INSERT ADDRESS OF BLOCK          14120015
         MVI   0(GRA),X'84'            SET IN CORE AND BUSY             14160015
         N     GR0,STBITS              CLEAR STATUS BITS IF ANY         14200015
         LR    GRC,GR0                 PICK UP ADDRESS FOR MOVING ENTRY 14240015
         LR    GRB,GR0                 PICK UP ADDRESS OF BLOCK         14280015
         A     GRB,TEMP1               ADDLENGTH OF ENTRY               14320015
         ST    GR0,TEMP2               SHOW ABSOLUTE START OF BLOCK     14360015
         BC    B,SETUP                                                  14400015
         SPACE                                                          14440015
ERR13    LA    GR0,ERRMS               TOO MANY DICTIONARY BLOCKS       14480015
         ST    GR0,PAR1(0,DICR)                                         14520015
         MVI   SWTCH,X'00'         REINITIALISE SWITCH                  14560015
         MVI   0(GRC),X'ED'            MARK END OF DICT.          52214 14570021
         LA    13,ZSAV(0,DICR)         SET UP SAVE AREA FOR ZUPL  33893 14580020
         BAL   RR,ZUPL                                                  14600015
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN  33893 14620020
         LA    GR0,16                  SHOW A TERMINAL ERROR HAS        14640015
         ST    GR0,ERCODE(0,DICR)    OCURRED                            14680015
         L     LR,ABORTOF(CNTL)        POINT AT ZABORT                  14720015
         BALR  RR,LR                                                    14760015
ERR04    MVC   PAR6+1(3,DICR),ERRMS1   ENTRY TOO LOMG                   14800015
         MVI   SWTCH,X'00'         REINITIALISE SWITCH                  14840015
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 14880015
         BALR  RR,LR                   ROUTINE IN AA                    14920015
         SPACE                                                          14960015
         SPACE                                                          15000015
ERRMS1   DC    X'0F0440'                                          23286 15040001
         EJECT                                                          15080015
*        ROUTINE ZUTXTC                                                 15120015
*                       THIS ROUTINE FINDS A NEW TEXT BLOCK. IF A FREE  15160015
*        BLOCK EXISTS, IT IS USED. IF NO FREE BLOCKS EXIST,A LOWER      15200015
*        PRIORITY BLOCK (WANTED OR UNWANTED) IS WRITTEN ON DISK. THE    15240015
*        NEW BLOCK IS MARKED AS IN-CORE AND BUSY.                       15280015
*              IF REQUESTED BY A NON-ZERO BYTE IN PAR2+3, THE CURRENT   15320015
*        BLOCK IS CHAINED TO THE NEW BLOCK AND THE STATUS OF THE CURREN 15360015
*        T BLOCK IS CHANGED. FOUR STATUS BYTES EXIST                    15400015
*             1) X'01' MEANS FREE THE BLOCK. THE INFORMATION CAN BE     15440015
*           OVERWRITTEN IF NECESSARY                                    15480015
*             2) X'02' A LOW PRIORITY OF USEFUL INFORMATION(REFERRED TO 15520015
*           AS UNWANTED). THE BLOCK IS NOT NECESSARILY IN CORE          15560015
*             3) X'03' A HIGH PRIORITY OF USEFUL INFORMATION(REFERRED   15600015
*           TO AS WANTED)                                               15640015
*             4) X'04' BUSY. THE BLOCK IS IN CORE AND WILL NOT BE       15680015
*           WRITTEN OUT                                                 15720015
*             IN THIS ROUTINE A SEARCH IS MADE FOR A X'01' BLOCK. IT    15760015
*        MUST BE NOTED THAT A X'80' BIT MEANS THAT A BLOCK IS IN CORE.  15800015
*        THUS WHEN A NEW BLOCK IS REQUIRED A SEARCH IS MADE FOR X'81'   15840015
*        BLOCK MEANING IN-CORE AND FREE.                                15880015
*             A LIST OF TEXT BLOCK ADDRESSES IS KEPT IN TSLOTS. IT IS   15920015
*        THIS LIST WHICH IS SCANNED.                                    15960015
*             IF A FREE BLOCK CANNOT BE FOUND THEN A ENTRY TO TRYMRT    16000015
*        IS MADE. THIS WILL EITHER CREATE A NEW BLOCK OR SPILL A WANT   16040015
*        OR UNWANT BLOCK ONTO DISK.                                     16080015
*             COMPILATION IS TERMINATED IF ALL TEXT BLOCKS ARE FULL,IE  16120015
*        IF TSLOTS HAS REACHED THE STOPPER                              16160015
*                                                                       16200015
         SPACE 2                                                        16240015
ZUTXTC   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               16280015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  16320015
         L     CNTL3,BASES             LOAD SECOND BASE                 16360015
         SPACE                                                          16400015
         BAL   RR,CONSLT               POINT AT CORRECT SLOT IN TSLOTS  16440015
         TM    PAR2+3(DICR),X'FF'      SEE IF ZERO STATUS BYTE          16480015
         BC    BM,ZTCHAN                                                16520015
         SPACE                                                          16560015
ZTBAK    LA    GRC,TSLOTS+24           INITIALISE AT TSLOTS             16600015
         XR    GRB,GRB                 COUNT=0                          16640015
         L     GRD,0(0,GRA)            PICK UP ADDRESS OF BLOCK         16680015
         A     GRD,TXTSZ(0,DICR)       ADD ON TEXT BLOCK SIZE           16720015
         SPACE                                                          16760015
ZTLOP    TM    0(GRC),X'80'            TEST IF BLOCK IN CORE            16800015
         BC    BZ,ONDSK                                                 16840015
         CLI   0(GRC),X'81'            TEST FOR FREE BLOCKS             16880015
         BC    BE,FREBLK                                                16920015
         CLI   0(GRC),X'FF'            TEST FOR FREE SLOT               16960015
         BC    BE,FRSLAT                                                17000015
ONDSK    LA    GRC,4(0,GRC)            BUMP TO NEXT SLOT IN TSLOTS      17040015
         LA    GRB,1(0,GRB)            COUNT+COUNT+1                    17080015
         CLI   1(GRC),X'FF'            TEST FOR STOPPER IN TSLOTS       17120015
         BC    BNE,ZTLOP                                                17160015
         SPACE                                                          17200015
         MVC   PAR6+1(3,DICR),ERRF06   ALL TEXT BLOCKS FULL       32318 17230020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 17260020
         LA    13,ZSAV(0,DICR)         SET UP SAVE AREA FOR ZUERR 33893 17270020
         BAL   RR,ZUERR                GO TO ERROR ROUTINE        32318 17290020
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN  33893 17300020
         L     LR,ABORTOF(CNTL)        POINT AT ZABORT                  17320015
         BALR  RR,LR                                                    17360015
ERRF06   DC    X'0F06C0'                                          32318 17380020
         SPACE                                                          17400015
ZTCHAN   TM    PAR2+3(DICR),X'80'      TEST IF CHAIN REQUIRED           17440015
         BC    BZ,NOCHAN                                                17480015
         MVI   CHANSW,X'FF'            SET CHAIN SWITCH ON              17520015
NOCHAN   TM    PAR2+3(DICR),X'07'      TEST FOR ANY STATUS CHANGE       17560015
         BC    BZ,ZTBAK                                                 17600015
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           17640015
         BC    BE,BLKERR                                                17680015
         NI    0(GRA),X'80'            CLEAR PREVIOUS STATUS BITS       17720015
         NI    PAR2+3(DICR),X'7F'      CLEAR CHAIN BIT FROM STATUS BYTE 17760015
         OC    0(1,GRA),PAR2+3(DICR)   INSERT NEW STATUS BYTE           17800015
         BC    B,ZTBAK                                                  17840015
         SPACE                                                          17880015
FREBLK   L     GR0,0(0,GRC)            PICK UP ADDRESS OF FREE BLOCK    17920015
         N     GR0,STBITS                                               17960015
         CLI   CHANSW,X'FF'            IS CHAIN SWITCH ON               18000015
         BC    BNE,NONEW                                                18040015
         STC   GRB,1(0,GRD)            STORE COUNT OF NEXT BLOCK IN     18080015
         BC    B,NONEW               CHAIN SLOT OF CURRENT BLOCK        18120015
         SPACE                                                          18160015
FRSLAT   CLI   CHANSW,X'FF'            TEST FOR CHAIN                   18200015
         BC    BNE,TCJUMP                                               18240015
         STC   GRB,1(0,GRD)            STORE COUNT OF NEXT BLK IN CHAIN 18280015
TCJUMP   XC    RDTTR(4),RDTTR          SHOW THAT NO BLOCK IS REQUIRED   18320015
         BAL   RR,TRYMRT             IN CORE AND MAKE SPACE FOR BLOCK   18360015
         ST    GR0,0(0,GRC)            PUT ADDRESS OF BLOCK IN TSLOTS   18400015
NONEW    MVI   0(GRC),X'84'            MARK AS IN-CORE AND BUSY         18440015
         MVI   CHANSW,X'00'            CLEAR CHAN-SWITCH                18480015
         ST    GR0,PAR2(0,DICR)        INSERT ABSOLUTE ADDRESS OF BLOCK 18520015
         MVI   PAR2(DICR),X'00'        CLEAR STATUS BYTE                18560015
         XC    PAR1+2(2,DICR),PAR1+2(DICR) SET OFFSET TO ZERO           18600015
         STC   GRB,PAR1+1(0,DICR)      INSERT COUNT AS REFERENCE        18640015
         LR    GRA,GR0                                                  18680015
         A     GRA,TXTSZ(0,DICR)       POINT AT END OF NEW BLOCK        18720015
         STC   GRB,5(0,GRA)            NAME THE NEW BLOCK               18760015
         SPACE                                                          18800015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      18840015
         SPACE                                                          18880015
         EJECT                                                          18960015
*        ROUTINE ZCHAIN                                                 19000015
*                       THIS ROUTINE LOOKS AT CURRENT BLOCK (INDICATED  19040015
*        BY A TEXT REFERENCE IN PAR1(, PICKS UP CHAIN POINTER AND       19080015
*        POINTS AT NEW BLOCK. IF THE NEW BLOCK IS NOT IN CORE IT IS     19120015
*        BROUGHT INTO CORE.                                             19160015
*              THE CURRENT BLOCK NEED NOT BE IN CORE. PAR2+3 CONTAINS A 19200015
*        STATUS BYTE. THIS BYTE IS AS DESCRIBED IN ZUTXTC. THIS IS USED 19240015
*        TO MARK THE CURRENT BLOCK. IF A SIGN BIT IS PLACED IN PAR1     19280015
*        THEN THE STATUS OF THE NEXT BLOCK IN THE CHAIN IS UNCHANGED.   19320015
*              THE REFERENCE OF THE NEXT BLOCK IN THE CHAIN IS FOUND IN 19360015
*        THE LAST WORD BUT ONE IN THE TEXT BLOCK. THE LAST WORD IN THE  19400015
*        TEXT BLOCK CONTAINS THE NAME OF THE BLOCK.                     19440015
*                                                                       19480015
         SPACE 2                                                        19520015
ZCHAIN   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               19560015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  19600015
         L     CNTL3,BASES             LOAD SECOND BASE                 19640015
         SPACE                                                          19680015
         BAL   RR,CONSLT               POINT AT SLOT IN TSLOTS          19720015
         SPACE                                                          19760015
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           19800015
         BC    BE,BLKERR                                                19840015
         TM    0(GRA),X'80'            TEST IF BLOCK IN CORE            19880015
         BC    BZ,ZCGET                                                 19920015
         SPACE                                                          19960015
ZCBAK1   L     GRB,0(0,GRA)            PICK UP ADDRESS OF BLOCK         20000015
         N     GRB,STBITS              ELIMINATE STATUS BITS            20040015
         TM    PAR2+3(DICR),X'FF'      TEST IF STATUS CHANGE RQD TO     20080015
         BC    BM,CHNST              CURRENT BLOCK                      20120015
         SPACE                                                          20160015
ZCBAK2   A     GRB,TXTSZ(0,DICR)       ADD ON SPACE IN TEXT BLOCK       20200015
         XC    PAR1+2(2,DICR),PAR1+2(DICR) SET OFFSET TO ZERO           20240015
         MVC   PAR1+1(1,DICR),1(GRB)   INSERT BLOCK NUMBER OF CHAIN BLK 20280015
         BAL   RR,CONSLT               POINT AT CHAIN SLOT IN TSLOTS    20320015
         SPACE                                                          20360015
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           20400015
         BC    BE,BLKERR                                                20440015
         TM    0(GRA),X'80'            TEST IF BLOCK IN CORE            20480015
         BC    BO,ZCMARK                                                20520015
         SPACE                                                          20560015
         MVC   RDTTR(3),1(GRA)         MOVE IN TRACK ADDRESS OF BLOCK   20600015
         BAL   RR,TRYMRT               GET BLOCK INTO CORE              20640015
         ST    GR0,TEMP                PICK UP ADDRESS OF NEW BLOCK     20680015
         OI    0(GRA),X'80'            MARK BLOCK AS IN CORE            20720015
         MVC   1(3,GRA),TEMP+1         INSERT ADDRESS IN TSLOTS         20760015
         SPACE                                                          20800015
ZCMARK   TM    PAR1(DICR),X'80'        TEST IF STATUS CHANGE REQUIRED   20840015
         BC    BO,ZCJUMP                                                20880015
         MVI   0(GRA),X'84'            OTHERWISE MARK BLOCK AS BUSY     20920015
         SPACE                                                          20960015
ZCJUMP   L     GRA,0(0,GRA)            PICK UP ADDRESS OF BLOCK         21000015
         N     GRA,STBITS              REMOVE STATUS BITS               21040015
         ST    GRA,PAR2(0,DICR)        MOVE ABSOLUTE ADDRESS TO PAR2    21080015
         SPACE                                                          21120015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      21160015
         SPACE                                                          21200015
ZCGET    MVC   RDTTR(3),1(GRA)         MOVE IN TR ACK ADDRESS OF BLOCK  21240015
         BAL   RR,TRYMRT               GET THE BLOCK INTO CORE          21280015
         ST    GR0,TEMP                PICK UP ADDRESS OF NEW BLOCK     21320015
         MVC   1(3,GRA),TEMP+1         STORE ADDRESS IN TSLOTS          21360015
         OI    0(GRA),X'80'            MARK BLOCK AS IN CORE            21400015
         BC    B,ZCBAK1                                                 21440015
         SPACE                                                          21480015
CHNST    NI    0(GRA),X'80'            CLEAR ALL EXCEPT INCORE BIT      21520015
         OC    0(1,GRA),PAR2+3(DICR)   INSERT NEW STATUS BYTE           21560015
         L     GRC,0(0,GRA)            PICK UP ADDRESS OF BLOCK         21600015
         A     GRC,TXTSZ(0,DICR)       POINT AT END OF BLOCK            21640015
         MVC   6(2,GRC),MYNAM(DICR)    MOVE IN NAME OF PHASE ISNG BLOCK 21680015
         BC    B,ZCBAK2                                                 21720015
         SPACE                                                          21760015
         EJECT                                                          21800015
*        ROUTINE ZALTER                                                 21840015
*                       THIS ROUTINE IS USED TO CHANGE THE STATUS OF A  21880015
*        TEXT BLOCK. THE BLOCK NEED NOT BE IN CORE                      21920015
*              IF THE BLOCK IS ON DISK AND IS THEN MADE FREE, THE SLOT  21960015
*        IS MARKED AS NOT IN USE (X'FF'). THE BLOCK NUMBER WILL THEN BE 22000015
*        ALLOCATED AGAIN AT A LATER DATE. THE NUMBER OF TEXT BLOCKS IS  22040015
*        REDUCED BY 1                                                   22080015
         SPACE 2                                                        22120015
ZALTER   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               22160015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  22200015
         L     CNTL3,BASES             LOAD SECOND BASE                 22240015
         SPACE                                                          22280015
         BAL   RR,CONSLT               POINT AT TSLOTS FOR THIS BLOCK   22320015
         SPACE                                                          22360015
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           22400015
         BC    BE,BLKERR                                                22440015
         NI    0(GRA),X'80'            CLEAR ALL STATI EXCEPT IN-CORE   22480015
         OC    0(1,GRA),PAR2+3(DICR) BIT. INSERT STATUS BYTE            22520015
         CLI   0(GRA),X'01'            SEE IF STATUS IS NOW ON-DISK AND 22560015
         BC    BNE,RETRTN       FREE. IF NOT,GO TO RETURNING ROUTINE    22600015
         MVI   0(GRA),X'FF'            SHOW SLOT IS FREE                22640015
         SPACE                                                          22680015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      22720015
         EJECT                                                          22760015
*        ROUTINE ZTXTAB                                                 22800015
*                       CONVERTS A TEXT REFERENCE TO AN ABSOLUTE ADDRES 22840015
*        PAR1 WILL CONTAIN THE REFERENCE TO BE CONVERTED. IF THE BLOCK  22880015
*        IS NOT IN CORE IT WILL BE BROUGHT INTO CORE.                   22920015
*              THE BLOCK WILL BE MARKED IN-CORE AND BUSY UNLESS THERE   22960015
*        IS A SIGN BIT IN PAR1. IN THIS CASE THE STATUS OF THE BLOCK    23000015
*        WILL NOT CHANGE                                                23040015
         SPACE 2                                                        23080015
ZTXTAB   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               23120015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  23160015
         L     CNTL3,BASES             LOAD SECOND BASE                 23200015
         ST    DICR,DICTEM             STORE ADDRESS OF THIS SAVE AREA  23240015
         L     DICR,DADDR              POINT AT DICTIONARY              23280015
         SPACE                                                          23320015
         BAL   RR,CONSLT               POINT AT CORRECT TSLOTS SLOT     23360015
         CLC   TSLOTEND+1(3),1(GRA)    IS BLOCK TTR TOO HIGH?     30357 23370020
         BNH   BLKERR                  YES                        30357 23380020
         SPACE                                                          23400015
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           23440015
         BC    BE,BLKERR                                                23480015
         TM    0(GRA),X'80'            TEST IF BLOCK IS IN CORE         23520015
         BC    BZ,TABD                                                  23560015
         SPACE                                                          23600015
TABR     TM    PAR1(DICR),X'80'        SEE IF STATUS CHANGE REQUIRED    23640015
         BC    BO,SAME                                                  23680015
         MVI   0(GRA),X'84'            MARK AS INCORE AND BUSY          23720015
SAME     L     GRA,0(0,GRA)            PICK UP ADDRESS AND STATUS BITS  23760015
         N     GRA,STBITS              GET RID OF STATUS BITS           23800015
         AH    GRA,PAR1+2(0,DICR)      ADD OFFSET OF ORIGINAL REFERENCE 23840015
         ST    GRA,PAR1(0,DICR)        INSERT ABSOLUTE ADDRESS          23880015
         L     DICR,DICTEM             POINT AT SAVE AREA AGAIN         23920015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      23960015
         SPACE                                                          24000015
TABD     MVC   RDTTR(3),1(GRA)         PICK UP TTR OF BLOCK             24040015
         BAL   RR,TRYMRT               GET BLOCK INTO CORE              24080015
         ST    GR0,TEMP                PICK UP ADDRESS OF BLOCK AND     24120015
         MVC   1(3,GRA),TEMP+1       STORE IN TSLOTS. STATUS LEFT ALONE 24160015
         OI    0(GRA),X'80'            MARK BLOCK AS IN CORE            24200015
         BC    B,TABR                                                   24240015
         EJECT                                                          24280015
*        ROUTINE ZTXTRF                                                 24320015
*                       THIS ROUTINE CONVERTS AN ABSOLUTE ADDRESS TO    24360015
*        A TEXT REFERENCE. PAR2 CONTAINS THE ABSOLUTE ADDRESS TO BE     24400015
*        CONVERTED. PAR1 WILL CONTAIN ANY REFERENCE FOR THE BLOCK       24440015
*        CONTAINING THE ABSOLUTE ADDRESS.                               24480015
*              IF THE REFERENCED BLOCK IS NOT IN CORE THEN THE COMPILER 24520015
*        WILL TERMINATE                                                 24560015
         SPACE 2                                                        24600015
ZTXTRF   STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               24640015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  24680015
         L     CNTL3,BASES             LOAD SECOND BASE                 24720015
         SPACE                                                          24760015
         BAL   RR,CONSLT               POINT AT TSLOTS FOR THIS REFRNCE 24800015
         SPACE                                                          24840015
         CLI   0(GRA),X'FF'            SEE IF BLOCK IS IN USE           24880015
         BC    BE,BLKERR                                                24920015
         TM    0(GRA),X'80'            TEST IF BLOCK IN CORE            24960015
         BC    BZ,TRFER                                                 25000015
         SPACE                                                          25040015
         L     GR0,0(GRA)              PICK UP ADDRESS                  25080015
         N     GR0,STBITS              REMOVE STATUS BITS               25120015
         S     GR0,PAR2(0,DICR)        SUBTRACT ABSOLUTE ADDRESS TO GET 25160015
         LPR   GR0,GR0               OFFSET. SET TO A POSITIVE VALUE    25200015
         STH   GR0,PAR1+2(0,DICR)      CREATE REFERENCE                 25240015
         SPACE                                                          25280015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      25320015
         SPACE                                                          25360015
TRFER    MVC   PAR6+1(3,DICR),ERRF05   TEXT BLOCK NOT IN CORE     32318 25380020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 25400020
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 25440015
         BALR  RR,LR                   ROUTINE IN AA                    25480015
         SPACE                                                          25520015
ERRF05   DC    X'0F05C0'                                          32318 25560020
         EJECT                                                          25600015
*              THESE INSTRUCTIONS GENERATE AN ERROR MESSAGE WHEN A      25640015
*        REFERENCED BLOCK IS NOT IN USE. THE COMPILER IS ABORTED.       25680015
*                                                                       25720015
BLKERR   MVC   PAR6+1(3,DICR),ERRF0C   REFERENCED BLOCK NOT IN USE      25760015
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 25780020
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 25800015
         BALR  RR,LR                   ROUTINE IN AA                    25840015
ERRF0C   DC    X'0F0CC0'                                          32318 25846020
         SPACE 3                                                        25852020
*              THIS ROUTINE PASSES THE NAME OF THE ACTIVE PHASE   32318 25858020
*        AT ERROR-GENERATION TIME TO ZUERR.                       32318 25864020
         SPACE 1                                                        25870020
PASMYNAM LH    GRC,MYNAM(0,DICR)       PICK UP PHASE LOADED NAME        25876021
         SH    GRC,=X'B0B0'            CHANGE TO INTERNAL CODE          25882021
         STH   GRC,NAMESL              SAVE NAME                        25888021
         LA    GRC,NAMESL              PASS ADDR OF NAME SAVE           25894021
         ST    GRC,PAR7(0,DICR)        SLOT TO MSG.                     25900021
         MVC   PAR8+2(2,DICR),K2+2     SET LGTH 2 FOR PHASE NAME  47635 25903056
         BR    RR                      ISSUE MSG.                       25906021
NAMESL   DS    H                       NAME SAVE SLOT                   25912021
         EJECT                                                          25920015
*        ROUTINE ZUGC                                                   25960015
*                       THIS ROUTINE ALLOCATES SPACE TO THE PHASES. ONE 26000015
*        4K BLOCK IS RESERVED FOR THIS PURPOSE. IF THE BLOCK IS  FULLY  26040015
*        USED A BLOCK OF TEXT OR DICTIONARY SIZE IS GIVEN. THIS IS TO   26080015
*        REDUCE THE POSSIBILITY OF STORAGE BINDS ON SMALL SYSTEMS. THE  26120015
*        BLOCKS ARE MARKED IN CONDIR AS T OR D BLOCKS. THEY ARE RELEASD 26160015
*        TO THE SYSTEM BY A FREEMAIN AT THE REQUIRED TIME. THE INITIAL  26200015
*        4K BLOCK IS NEVER RELEASED TO THE SYSTEM.                      26240015
*              REQUESTS FOR SCRATCH CORE ARE MADE BY INSERTING A COUNT  26280015
*        IN PAR1+3(1 BYTE). THIS COUNT WILL SHOW HOW MANY BLOCKS OF 512 26320015
*        BYTES ARE REQUIRED IN ONE CONTIGUOUS LUMP. THIS REQUEST FOR A  26360015
*        5X512 BLOCK (SAY) IS KNOWN AS 1 ALLOCATION. THIS IS IMPORTANT  26400015
*        FOR THE UNDERSTANDING OF ZURC,THE RELEASING OF SCRATCH CORE    26440015
*        ALLOCATIONS                                                    26480015
         SPACE 2                                                        26520015
ZUGC     STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               26560015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  26600015
         L     CNTL3,BASES             LOAD SECOND BASE                 26640015
         SPACE                                                          26680015
         XR    GR0,GR0                                                  26720015
         IC    GR0,PAR1+3(0,DICR)      PICK UP NUMBER OF 512 BYTES      26760015
         SLA   GR0,9                   NOW CONTAINS THE BYTES REQUIRED  26800015
         SPACE                                                          26840015
GCCHAN   BC    NOP,GCFST               BRANCH ON EVERY-ONE EXCEPT FIRST 26880015
         MVI   GCCHAN+1,X'F0'          CHANGE GCCHAN TO A PERMANENT BRC 26920015
         LA    GRA,CONDIR                                               26960015
         ST    GRA,POINTR              POINT AT CONDIR                  27000015
         XC    CONCNT(4),CONCNT        SET NUMBER OF ENTRIES TO ZERO    27040015
         SPACE                                                          27080015
GCFST    CL    GR0,FR96                SEE IF REQUEST IS GRTR THAN 4K   27120015
         BC    BH,GCERR                                                 27160015
         SPACE                                                          27200015
         L     GRA,POINTR              POINT AT CONDIR                  27240015
         CLI   0(GRA),X'FF'            IS IT AT STOPPER IN TABLE        27280015
         BC    BE,GCOUT                NO CORE ALLOCATED IF CONDIR FULL 27320015
         SPACE                                                          27360015
         CL    GR0,ALLOCL              ENOUGH SPACE LEFT IN FIRST 4K    27400015
         BC    BH,GETBLK                                                27440015
         SPACE                                                          27480015
         LM    GRB,GRC,ALLOCA          PICK UP ADDRESS OF ALLOCATED COR 27520015
         ST    GRB,0(0,GRA)            STORE ADDRESS IN CONDIR          27600015
         ST    GR0,4(0,GRA)            STORE AMOUNT IN CONDIR           27640015
         ST    GRB,PAR1(0,DICR)        STORE ADDRESS OF ALLOCATED CORE  27680015
         AR    GRB,GR0                 ALLOCA=ALLOCA+AMOUNT             27720015
         SR    GRC,GR0                 ALLOCL=ALLOCL-AMOUNT             27760015
         STM   GRB,GRC,ALLOCA          RESTORE ALLOCA AND ALLOCL        27800015
         ST    GR0,PAR2(0,DICR)        STORE AMOUNT OF ALLOCATED CORE   27840015
         SPACE                                                          27880015
GCBACK   LA    GRA,8(0,GRA)            BUMP TO NEXT IN CONDIR           27920015
         L     GRB,CONCNT                                               27960015
         LA    GRB,1(0,GRB)            COUNT NUMBER OF ENTRIES IN CONDR 28000015
         STM   GRA,GRB,POINTR          STORE POINTR AND CONCNT          28040015
         SPACE                                                          28080015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      28120015
         SPACE                                                          28160015
GETBLK   LA    GRB,TSLOTS+24           POINT AT TEXT BLOCK CONTROL      28200015
         XR    GRC,GRC                 THIS WILL BE USED FOR COUNTING   28240015
         SPACE                                                          28280015
GCLOOP   TM    0(GRB),X'80'            SEE IF BLOCK IS IN CORE          28320015
         BC    BZ,NOTINC                                                28360015
         TM    0(GRB),X'70'                                             28400015
         BC    BO,NOTINC                                                28420001
         LA    GRC,1(0,GRC)            COUNT 1 BLOCK AS IN CIRE         28440001
NOTINC   LA    GRB,4(0,GRB)            BUMP TO NEXT IN CONTROL AREA     28480015
         CLI   1(GRB),X'FF'            SEE IF IT IS A STOPPER           28520015
         BC    BNE,GCLOOP                                               28560015
         CL    GRC,FOUR                SEE IF ENOUGH CORE BLOCKS AVAIL  28610001
         BNH   GCOUT                       ABLE TO STEAL ONE            28660001
*        THE ABOVE CODE IS UNSOPHISTICATED AND NEEDS EXPANDING TO       28710001
*              TO FIND IF ALL CORE HAS BEEN UDES YET.                   28760001
*        TEST FOR K PHASES RUNNING                                      28810001
         XC    RDTTR(4),RDTTR          INDICATE NO READ REQUIRED        28860001
         BAL   RR,TRYMRT               GET SPARE BLOCK,SPILL IF NEC     28910001
         SPACE 1                                                        28960001
         LR    GRB,GR0                 PICK UP NEW BLOCK ADDR           29010001
         L     GRC,DICTSZ(0,DICR)      PICK UP LENGTH                   29120015
         STM   GRB,GRC,PAR1(DICR)      PUT IN PARAMETER WORDS           29160015
         STM   GRB,GRC,0(GRA)          STORE IN CONDIR                  29200015
         OI    0(GRA),X'80'            MARK AS T OR D ALLOCATION        29280015
         BC    B,GCBACK                                                 29320015
         SPACE                                                          29360015
GCOUT    XC    PAR2(4,DICR),PAR2(DICR) SET PAR2 TO 0 TO SHOW NO ALLOCTN 29400015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      29440015
         SPACE                                                          29480015
GCERR    MVC   PAR6+1(3,DICR),ERRF07   TOO MUCH SCRATCH REQUESTED 32318 29500020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 29520020
         LA    DICR,ABSAV              POINT AT NEW SAVE AREA           29560015
         BAL   RR,ZUERR                                                 29600015
         L     DICR,DADDR              POINT BACK AT OLD SAVE AREA      29640015
         BC    B,GCOUT                                                  29680015
         SPACE                                                          29720015
ERRF07   DC    X'0F07C0'                                          32318 29760020
         EJECT                                                          29800015
*        ROUTINE ZURC                                                   29840015
*                       THIS ROUTINE WILL RELEASE CORE ALLOCATED BY     29880015
*        ZUGC. THE MOST RECENT REQUESTS ARE RELEASED. A ZERO PARAMETER  29920015
*        IS IGNORED. THE NUMBER OF REQUIRED RELEASES IS PASSED IN PAR1. 29960015
*        IF THE BLOCK HAS BEEN OBTAINED BY A TRYMRD OR TRYMRT THEN THE  30000015
*        BLOCK IS RELEASED BY A FREEMAIN. OTHERWISE ADJUSTMENTS ARE     30040015
*        MADE TO ALLOCA AND ALLOCL                                      30080015
         SPACE 2                                                        30120015
ZURC     STM   14,CNTL2,12(DICR)       GET WORK REGISTERS               30160015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  30200015
         L     CNTL3,BASES             LOAD SECOND BASE                 30240015
         LA    GRA,SAVARD              POINT AT NEXT SAVE AREA          30280015
         ST    DICR,4(0,GRA)           CHAIN FORWARDS                   30320015
         ST    GRA,8(0,DICR)           CHAIN BACKWARDS                  30360015
         SPACE                                                          30400015
         XR    GR0,GR0                 PICK UP COUNT OF NUMBER OF       30440015
         IC    GR0,PAR1+3(0,DICR)    REQUIRED RELEASES                  30480015
         SPACE                                                          30520015
         LTR   GR0,GR0                 TEST IF ZERO COUNT               30560015
         BC    BZ,RCRTN                                                 30600015
         CL    GR0,CONCNT              TEST IF TOO MANY RELEASES        30640015
         BC    BH,RCERR                                                 30680015
         SPACE                                                          30720015
         LM    GRA,GRD,ALLOCA          GRA=ALLOCA,GRB=ALLOCL,GRC=POINTR 30760015
RCLOP    S     GRC,EIGHT             GRD=CONCNT. REDUCE TO PREVIOUS     30800015
         TM    0(GRC),X'80'          CONDIR ENTRY. TEST FOR TRYMRD OR   30840015
         BC    BO,RCBLOK             TRYMRT MARKER                      30880015
         S     GRA,4(0,GRC)            ALLOCA=ALLOCA-LENGTH             30920015
         A     GRB,4(0,GRC)            ALLOCL=ALLOCL+LENGTH             30960001
RCBAK    BCTR  GRD,0                   REDUCE CONCNT BY 1               31000015
         BCT   GR0,RCLOP                                                31040015
         SPACE                                                          31080015
RCRTN    STM   GRA,GRD,ALLOCA          RESTORE ADDRESSES,COUNTS,ETC     31120015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      31160015
         SPACE                                                          31200015
RCBLOK   STM   0,2,TEMP                STORE AWAY REGS                  31240001
         L     0,4(0,GRC)              PICK UP LENGTH                   31280015
         L     1,0(0,GRC)              PICK UP ADDRESS                  31320015
         N     1,STBITS                REMOVE BLOCK MARK FROM TOP BYTE  31360015
         CLI   SPILL,X'00'             BRANCH IF SPILLING               31370001
         BNE   RCTXBL                  TO GIVE BACK VIA TSLOTS          31380001
         LA    DICR,SAVARD             POINT AT SAVE AREA FOR FREEMAIN  31400015
         SPACE                                                          31440015
         SPACE                                                          31480015
       FREEMAIN R,LV=(0),A=(1)                                          31520015
         SPACE                                                          31560015
         SPACE                                                          31600015
         L     DICR,DADDR              RESTORE TO PREVIOUS SAVE AREA    31640015
         L     0,CORLFT(0,DICR)                                         31680015
         A     0,4(0,GRC)              CORLFT=CORLFT+LENGTH RELEASED    31720015
         ST    GR0,CORLFT(0,DICR)                                       31760015
         BC    B,RCTX2                                                  31769001
         SPACE 1                                                        31778001
RCTXBL   LA    2,TSLOTS+24             LOOK FOR SPARE TSLOT             31787001
RCTX3    CLI   0(2),X'FF'                                               31796001
         BNE   RCTX1                                                    31805001
         ST    1,0(2)                  FOUND                            31814001
         MVI   0(2),X'81'              SPARE T BLOCK CREATED            31823001
RCTX2    LM    0,2,TEMP                RESTORE REGS                     31832001
         B     RCBAK                                                    31841001
         SPACE 1                                                        31850001
RCTX1    LA    2,4(2)                  BUMP TO NEXT TSLOT               31859001
         CLI   1(2),X'FF'                                               31868001
         BNE   RCTX3                                                    31877001
         SPACE 1                                                        31886001
         MVC   PAR6+1(3,DICR),ERR18    END OF TSLOTS,COULD LOOK FOR     31895001
         L     LR,DYNAMOF(CNTL)        DSLOT BUT THIS IS DISASTER       31904001
         BALR  RR,LR                   REALLY                           31913001
         SPACE 1                                                        31922001
ERR18    DC    X'0F1A00'                                                31931001
         SPACE 2                                                        31940001
RCERR    MVC   PAR6+1(3,DICR),ERRF08   ATTEMPT TO RELEASE         32318 31950020
*                                      UNALLOCATED CORE           32318 31960020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 31970020
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 32000015
         BALR  RR,LR                   ROUTINE IN AA                    32040015
         SPACE                                                          32080015
ERRF08   DC    X'0F08C0'                                          32318 32120020
         EJECT                                                          32160015
SAVAR    DS    18F                     SAVE AREA FOR NEXT LEVEL ROUTINE 32200015
SAVARD   DS    18F                                                      32240015
OSSAVR   DS    18F                                                      32280015
ALLOCA   DC    F'0'                    ADDRESS AND LENGTH OF SPACE      32320015
ALLOCL   DC    F'0'                  WITHIN FIRST 4K BLOCK              32360015
POINTR   DC    F'0'                    POINTER TO NEXT AVAILABLE SPACE  32400015
CONCNT   DC    F'0'                  IN CONDIR AND NUMBER OF ENTRIES    32440015
CONDIR   DC    32F'0'                  LIST OF ALLOCATIONS              32480015
         DC    X'FF'                   STOPPER FOR LONDIR TABLE         32520015
DSLOTS   DC    6F'0'                                                    32560015
         DC    64XL4'FF000000'                                          32600015
         DC    X'00FF0000'                                              32640015
TSLOTS   DC    6F'0'                                                    32680015
         DC    90XL4'FF000000'                                          32720015
TSLOTEND DC    X'00FF0000'             END OF TSLOTS MARKER       30357 32780020
         SPACE                                                          32800015
FR96     DC    F'4096'                                                  32840015
DICTEM   DC    F'0'                                                     32880015
FOUR     DC    F'4'                                                     32920015
EIGHT    DC    F'8'                                                     32960015
TEMP     DS    F                                                        33000015
TEMP1    DS    F                                                        33040015
TEMP2    DS    F                                                        33080015
TEMP4    DS    F                                                        33120015
STBITS   DC    X'00FFFFFF'                                              33160015
ZEROS    DC    XL4'00'                 PERMANENT ZEROS LOCATION         33200015
TW56     DC    F'256'                                                   33240015
NEXTAD   DC    F'0'                                                     33280015
NOTTR    DC    F'0'                                                     33320015
THREE    DC    XL4'03'                                                  33360015
MASKX    DC    X'FFFFFFFC'                                              33400015
NEGBIT   DC    X'0000FFFF'                                              33440015
WRTLTH   DC    F'0'                                                     33480015
RDTTR    DC    F'0'                                                     33520015
         CNOP  0,8                                                      33560015
CONVAR   DC    F'0'                                                     33600015
         DC    F'0'                                                     33640015
CHANSW   DC    X'00'                                                    33680015
WRTON    DC    X'00'                                                    33720015
MAKSW    DC    X'00'                                                    33800015
BMNAM    DC    C'BM'                                                    33840015
KTNAM    DC    C'KT'                                                    33850001
FSWTCH   DC    X'00'                                                    33860001
BTCHCD   DC    C'*'                                                     33880015
ERRMS    DC    X'0036'                                                  33920015
         DC    C'-'                                                     33960015
         DC    C'IEM3853I SOURCE PROGRAM TOO LARGE.'                    34000015
         DC    C' DICTIONARY IS FULL.'                                  34040015
UTIMES   DC    X'001C'                                                  34080015
         DC    C'-'                                                     34120015
         DC    C'IEM3864I I/O ERROR ON SYSUT1'                          34160015
OPERR1   DC    X'001E'                                                  34200015
         DC    C'-'                                                     34240015
         DC    C'IEM3878I UNABLE TO OPEN SYSUT1'                        34280015
         EJECT                                                          34600015
*                   ROUTINE ZUERR.                                      34640015
         SPACE                                                          34680015
*              THIS ROUTINE INSERTS AN ERROR MESSAGE INTO THE           34720015
*        DICTIONARY.                                                    34760015
         SPACE                                                          34800015
*********************************************************************** 34840015
**                                                                   ** 34880015
**             INVOCATION OF THIS ROUTINE IS EQUIVALENT TO TWICE     ** 34920015
**       REFERENCING THE DICTIONARY IN THAT THE TWO BLOCKS LAST      ** 34960015
**       REFERENCED ARE THE LAST IN THE ERROR CHAIN AND THE ONE IN   ** 35000015
**       WHICH THE CURRENT MESSAGE IS INSERTED.                      ** 35040015
**                                                                   ** 35080015
*********************************************************************** 35120015
         SPACE                                                          35160015
*              ON ENTRY THIS ROUTINE EXPECTS TO FIND  -                 35200015
         SPACE                                                          35240015
*        (A)   LOCATION PAR6 WILL HOLD THE INDICATOR BYTES.   THESE ARE 35280015
         SPACE                                                          35320015
*              (1)  THE FIRST BYTE IS NOT USED.                         35360015
*              (2)  THE SECOND AND THIRD BYTES IDENTIFY THE MESSAGE.    35400015
         SPACE                                                          35440015
*              (3)  THE FIRST BIT OF THE FOURTH BYTE IS ONE IF TEXT     35480015
*              IS TO ACCOMPANY THE MESSAGE.                             35520015
         SPACE                                                          35560015
*              (4)  THE SECOND BIT OF THE FOURTH BYTE IS ONE IF THE     35600015
*              STATEMENT NUMBER IS RELEVANT.                            35640015
         SPACE                                                          35680015
*              (5)  THE THIRD BIT OF THE FOURTH BYTE IS ONE IF THE      35720015
*              MESSAGE HAS ASSOCIATED WITH IT A NUMERIC PARAMETER.      35760015
         SPACE                                                          35800015
*              (6)  THE FOURTH BIT OF THE FOURTH BYTE IS ONE IF THE     35840015
*              MESSAGE HAS ASSOCIATED WITH IT A DICTIONARY REFERENCE.   35880015
         SPACE                                                          35920015
*              (7)  THE LAST FOUR BITS OF THE FOURTH BYTE CONTAIN THE   35960015
*              SEVERITY CODE  -                                         36000015
         SPACE                                                          36040015
*                   0000   DISASTROUS                                   36080015
*                   0100   SERIOUS                                      36120015
*                   1000   WARNING                                      36160015
*                   1100   COMMENT                                      36200015
         SPACE                                                          36240015
*        (B)   IF THERE IS TO BE TEXT THEN PAR7 WILL HOLD A POINTER     36280015
*        TO IT AND PAR8 WILL HOLD THE LENGTH COUNT.                     36320015
         SPACE                                                          36360015
*        (C)   IF THERE IS TO BE A NUMERIC PARAMETER THEN ITS BINARY    36400015
*        VALUE MUST BE IN PAR5                                          36440015
         SPACE                                                          36480015
*        (D)   IF THERE IS AN ASSOCIATED DICTIONARY REFERENCE THEN      36520015
*        IT MUST APPEAR RIGHT ADJUSTED IN PAR7.                         36560015
         SPACE                                                          36600015
ZUERR    STM   14,CNTL2,12(GRDIC)      GET SOME WORK REGISTERS          36640015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  36680015
         L     CNTL3,BASES             LOAD SECOND BASE                 36720015
         LA    GRA,ZA107               POUNT AT NEW SAVE AREA           36760015
         ST    GRDIC,4(0,GRA)          CHAIN FORWARDS                   36800015
         ST    GRA,8(0,GRDIC)          CHAIN BACKWARDS                  36840015
         L     GRDIC,DADDR             POINT AT TRUE DICTIONARY         36880015
         SPACE                                                          36920015
         MVC   TEMPY(8),PAR1(DICR)     STORE PAR1 AND 2                 36960015
         CLI   MYNAM(GRDIC),C'X'       IF THE CALL IS FROM THE ERROR    37000015
         BC    BE,ZR51+4               MECHANISM WE SHALL IGNORE IT.    37040015
         CLC   MYNAM(2,GRDIC),BMNAM    IF CALL IS FROM BM               37080015
         BC    BE,ZR51+4               IGNORE IT                        37120015
         SPACE                                                          37160015
         ST    GR5,ZR3+2                                                37200015
         SPACE                                                          37240015
         LA    GR1,8(0,0)              MINIMUM LENGTH COUNT.            37280015
         SPACE                                                          37320015
         TM    PAR6+3(GRDIC),X'70'     TEST FOR STATEMENT NUMBER,       37360015
         BC    BZ,ZR50                 PARAMETER AND DICT. REFERENCE.   37400015
         SPACE                                                          37440015
         IC    RR,PAR6+3(0,GRDIC)      GET SIXTEEN TIMES THE OPTIONS    37480015
         N     RR,ZR1+2                CODE INTO RR                     37520015
         LR    LR,RR                   AND FOUR TIMES IT INTO LR        37560015
         SRL   LR,2                                                     37600015
         AR    RR,LR                   TWENTY TIMES THE OPTIONS CODE    37640015
*                                      INTO RR                          37680015
         SPACE                                                          37720015
         CNOP  0,4                                                      37760015
         SPACE                                                          37800015
         BC    B,*-16(RR)              BRANCH APPROPRIATELY             37840015
         SPACE                                                          37880015
*              HERE THE OPTIONS BITS SAID ONE.                          37920015
*              WE HAVE A DICTIONARY REFERENCE ONLY.                     37960015
         SPACE                                                          38000015
         LA    GR1,10(0,0)             PUT TEN IN THE LENGTH COUNT AND  38040015
         MVC   ZR104(2),PAR7+2(GRDIC)  MOVE IN THE DICTIONARY REFERENCE 38080015
         BC    B,ZR50                                                   38120015
         SPACE                                                          38160015
ZR1      DC    X'000A'                 TEXT LENGTH COMPARISON           38200015
         DC    X'00000070'             MASK FOR REGISTER                38240015
         SPACE                                                          38280015
*              HERE THE OPTIONS BITS SAID TWO.                          38320015
*              WE HAVE A NUMERIC PARAMETER ONLY.                        38360015
         SPACE                                                          38400015
         LA    GR1,10(0,0)             PUT TEN IN THE LENGTH COUNT      38440015
         MVC   ZR104(2),PAR5+2(GRDIC)  AND MOVE IN THE PARAMETER        38480015
         BC    B,ZR50                                                   38520015
         SPACE                                                          38560015
         DC    X'0004'                                                  38600015
ZR2      DC    X'0000000F'             MASK FOR REGISTER                38640015
         SPACE                                                          38680015
*              HERE THE OPTIONS BITS SAID THREE.                        38720015
*              WE HAVE BOTH A NUMERIC PARAMETER AND A DICTIONARY        38760015
*        REFERENCE.                                                     38800015
         SPACE                                                          38840015
         LA    GR1,12(0,0)             LENGTH COUNT TO TWELVE AND MOVE  38880015
         MVC   ZR104(2),PAR5+2(GRDIC)  IN FIRST THE PARAMETER AND THEN  38920015
         MVC   ZR105(2),PAR7+2(GRDIC)  THE DICTIONARY REFERENCE.        38960015
         BC    B,ZR50                                                   39000015
         SPACE                                                          39040015
*              HERE THE OPTIONS BITS SAID FOUR.                         39080015
*              WE HAVE ONLY A STATEMENT NUMBER.                         39120015
         SPACE                                                          39160015
         LA    GR1,10(0,0)             LENGTH COUNT TO TEN AND MOVE IN  39200015
         BAL   RR,CONSTT               PICK UP STATEMENT NUMBER         39240015
         BCR   NOP,0                                                    39280015
         BC    B,ZR50                                                   39320015
         SPACE                                                          39360015
ZR3      DS    1H                                                       39400015
         DS    1F                      TEMPORARY STORAGE                39440015
         SPACE                                                          39480015
*              HERE THE OPTIONS BITS SAID FIVE.                         39520015
*              WE HAVE A STATEMENT NUMBER AND A DICTIONARY REFERENCE.   39560015
         SPACE                                                          39600015
         LA    GR1,12(0,0)             LENGTH COUNT TO TWELVE AND MOVE  39640015
         BAL   RR,CONSTT               PICK UP STATEMENT NUMBER         39680015
         BCR   NOP,0                                                    39720015
         MVC   ZR105(2),PAR7+2(GRDIC)  DICTIONARY REFERENCE             39760015
         BC    B,ZR50                                                   39800015
         SPACE                                                          39840015
*              HERE THE OPTIONS BITS SAID SIX.                          39880015
*              WE HAVE A STATEMENT NUMBER AND A NUMERIC PARAMETER.      39920015
         SPACE                                                          39960015
         LA    GR1,12(0,0)             LENGTH COUNT TO TWELVE AND MOVE  40000015
         BAL   RR,CONSTT                                                40040015
         BCR   NOP,0                                                    40080015
         MVC   ZR105(2),PAR5+2(GRDIC)  BY THE NUMERIC PARAMETER.        40120015
         BC    B,ZR50                                                   40160015
         SPACE                                                          40200015
*              HERE THE OPTIONS BITS SAID SEVEN.                        40240015
*              WE HAVE A FULL HOUSE.                                    40280015
         SPACE                                                          40320015
         LA    GR1,14(0,0)             MAXIMUM LENGTH COUNT AND MOVE    40360015
         BAL   RR,CONSTT               PICK UP STATEMENT NUMBER         40400015
         BCR   NOP,0                                                    40440015
         MVC   ZR105(2),PAR5+2(GRDIC)  FOLLOWED BY NUMERIC PARAMETER    40480015
         MVC   ZR106(2),PAR7+2(GRDIC)  FOLLOWED BY DICTIONARY REFRNCE.  40520015
         SPACE                                                          40560015
*              WE HAVE INSERTED THE OPTIONS, IF ANY, AND ARE ABOUT TO   40600015
*        COMPLETE THE ENTRY.                                            40640015
         SPACE                                                          40680015
ZR50     STH   GR1,ZR101               PUT IN THE LENGTH COUNT AND THE  40720015
         MVC   ZR103(3),PAR6+1(GRDIC)  INDICATOR BYTES.                 40760015
         SPACE                                                          40800015
*              WE NOW SLOT THE ENTRY INTO THE DICTIONARY                40840015
*********************************************************************** 40880015
         ST    GR1,PAR2(0,GRDIC)       ON RETURN THE LOCATION PAR1      40920015
         LA    GR1,ZR100+1             CONTAINS THE DICTIONARY          40960015
         ST    GR1,PAR1(0,GRDIC)       REFERENCE OF THE LAST MADE       41000015
         LA    GRDIC,ZA107             POINT AT SAVE AREA               41040015
         BAL   RR,ZDICRF               ENTRY                            41080015
         L     GRDIC,DADDR             POINT AT DICTIONARY              41120015
*********************************************************************** 41160015
         SPACE                                                          41200015
         MVC   ZR3(2),PAR1+2(GRDIC)   SLOT AWAY THE DICTIONARY          41240015
*                                      REFERENCE                        41280015
         SPACE                                                          41320015
*              WE MUST NOW LINK THIS ENTRY TO THE CORRECT ERROR CHAIN.  41360015
         SPACE                                                          41400015
         L     GR1,PAR6(0,GRDIC)       GET THE SEVERITY CODE INTO A     41440015
         SPACE                                                          41480015
         N     GR1,ZR2                 REGISTER READY TO INDEX.         41520015
         SPACE                                                          41560015
*              POINT GR1 AT THE CORRECT CHAIN TERMINATOR                41600015
         SPACE                                                          41640015
         LA    GR1,ZDNXT+2(GR1,GRDIC)                                   41680015
         SPACE                                                          41720015
*              POINT GR5 AT THE LAST ENTRY IN THE CHAIN.                41760015
         SPACE                                                          41800015
         MVC   PAR1+2(2,GRDIC),0(GR1)                                   41840015
         SPACE                                                          41880015
*********************************************************************** 41920015
         LA    GRDIC,ZA107             POINT AT SAVE AREA               41960015
         BAL   RR,ZDRFAB                                                42000015
         L     GRDIC,DADDR             POINT AT DICTIONARY              42040015
*********************************************************************** 42080015
         SPACE                                                          42120015
         L     GR5,PAR1(0,GRDIC)                                        42160015
         SPACE                                                          42200015
*              MOVE IN THE POINTER.                                     42240015
         SPACE                                                          42280015
         MVC   3(2,GR5),ZR3            TO THE LAST ENTRY AND TO         42320015
         MVC   0(2,GR1),ZR3            THE CHAIN TERMINATOR             42360015
         SPACE                                                          42400015
*              AND PROCESS TEXT, IF ANY.                                42440015
         SPACE                                                          42480015
         TM    PAR6+3(GRDIC),X'80'     TEST THE TEXT BIT                42520015
         BC    BO,ZR52                                                  42560015
         SPACE                                                          42600015
*              HERE WE HAVE NO TEXT, OR WE HAVE PROCESSED IT.           42640015
         SPACE                                                          42680015
ZR51     L     GR5,ZR3+2                                                42720015
         MVC   PAR1(8,DICR),TEMPY      RESTORE PAR1 AND 2               42760015
         LA    GRDIC,ZA107             POINT AT SAVE AREA               42800015
         L     GRDIC,4(0,GRDIC)        PICK UP ADDR OF PREVIOUS AREA    42840015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      42880015
         SPACE                                                          42920015
*              HERE WE HAVE TEXT TO SLOT IN.                            42960015
         SPACE                                                          43000015
*              WE WILL NOT SLOT IN MORE THAN TEN CHARACTERS OF TEXT.    43040015
         SPACE                                                          43080015
ZR52     LH    GR1,PAR8+2(GRDIC)     LOAD TEXT LENGTH                   43120015
         LTR   GR1,GR1               IF NEGATIVE LENGTH                 43160015
         BC    BNM,ZR52A             THEN SPECIAL                       43200015
         LPR   GR1,GR1               STMT NO. ENTRY                     43240015
         MVI   ZR102,X'01'             * DENOTE STMT NO ENTRY     60037 43280072
         BC    B,ZR53                                                   43320015
ZR52A    CH    GR1,ZR1                                                  43360015
         BC    BL,ZR53               BTANCH IF LOWER THAN 10            43400015
         LH    GR1,ZR1                 SET LENGTH TO TEN                43440015
         MVI   ZR102,X'FF'             * DENOTE TRUNCATED TEXT    60037 43480072
ZR53     BCTR  GR1,0                   * SET UP FOR FINAL MVC OF  60037 43520072
         STC   GR1,DICMVC+1            * TEXT INTO DICT. ENTRY    60037 43540072
         LA    GR1,5(GR1)              * GR1 = TOTAL LENGTH OF    60037 43560072
         ST    GR1,PAR2(0,GRDIC)       * DICT. ENTRY TO BE MADE   60037 43580072
         STH   GR1,ZR101               STORE LENGTH IN SKELETON   60037 43600072
         LA    GR1,ZR100+1             * POINT AT SKELETON        60037 43620072
         ST    GR1,PAR1(0,GRDIC)       * PAR1 -> SKEL. PAR2 = LENGTH 37 43640072
         SPACE                                                          43720015
*********************************************************************** 43760015
         SPACE                                                          43800015
         LA    GRDIC,ZA107             POINT AT SAVE AREA               43840015
         BAL   RR,ZDICAB                                                43880015
         L     GRDIC,DADDR             POINT AT DICTIONARY              43920015
         SPACE                                                          43960015
*********************************************************************** 44000015
         SPACE                                                          44040015
*        THE SKELETON DICTIONARY ENTRY HAS BEEN MADE. PAR1 NOW    60037 44080072
*        CONTAINS THE ABSOLUTE ADDRESS OF THE SKELETON ENTRY IN   60037 44120072
*        THE DICTIONARY. IT REMAINS TO MOVE THE TEXT INTO THE ENTRY 037 44160072
         SPACE 1                                                        44200072
         L     GR1,PAR1(0,GRDIC)       * PICK UP A(DICT. ENTRY)   60037 44240072
         L     GR5,PAR7(0,GRDIC)       * PICK UP A(TEXT TO BE MOVED) 37 44280072
DICMVC   MVC   4(*-*,GR1),0(GR5)       * MOVE TEXT TO DICT ENTRY  60037 44320072
         MVI   ZR102,X'00'             * REINITIALIZE INDICATOR BYTE 37 44360072
         B     ZR51                    * RETURN                   60037 44400072
         SPACE                                                          44440015
         CNOP  0,4                                                      44480015
         SPACE                                                          44520015
ZR100    DC    XL2'00C8'               ERROR MESSAGE CODE BYTE          44560015
ZR101    DC    XL2'0000'               LENGTH COUNT                     44600015
ZR102    DC    XL2'0000'               SYMBOLIC CHAIN                   44640015
ZR103    DC    XL3'000000'             INDICATOR BYTES                  44680015
ZR104    DC    XL2'0000'               POSSIBLE STATEMENT NUMBER        44720015
ZR105    DC    XL2'0000'               POSSIBLE NUMERIC PARAMETER       44760015
ZR106    DC    XL2'0000'               POSSIBLE DICTIONARY REFERENCE    44800015
         DC    XL1'00'                                                  44840015
*        HERE WE ARE BACK ON A FOUR BYTE BOUNDARY.                      44880015
ZA107    DS    18F                                                      44920015
         SPACE                                                          44960015
*              VALUES OF SYMBOLIC NAMES.                                45000015
         SPACE                                                          45040015
GRDIC    EQU   13                                                       45080015
*                                                                       45120015
*              PICK UP STATEMENT NUMBER AND CONVERT IT TO BINARY IF     45160015
*        MACRO RUNNING                                                  45200015
*                                                                       45240015
CONSTT   TM    CCCODE+3(DICR),X'10'    SEE IF MACRO RUNNING             45280015
         BC    BZ,BINST                                                 45320015
         MVC   CONVAR+4(4),ZSTAT(DICR) PICK UP PACKED DECIMAL STATEMENT 45360015
         CVB   GRD,CONVAR            NUMBER AND CONVERT IT TO BINARY    45400015
         ST    GRD,CONVAR+4                                             45440015
         MVC   ZR104(2),CONVAR+6       PICK UP 2 BYTE BINARY VALUE      45480015
         BCR   BR,RR                                                    45520015
BINST    MVC   ZR104(2),ZSTAT+2(DICR)                                   45560015
         BCR   BR,RR                                                    45600015
         EJECT                                                          45640015
*        ROUTINES CONSLT AND CONSLD                                     45680015
*                       THESE ROUTINES TAKE A TEXT OR DICTIONARY        45720015
*        REFERENCE AND PROCEED TO POINT AT THE RELEVANT SLOT IN T OR D  45760015
*        SLOTS. THE ADDRESS IS RETURNED IN GRA, THE REFERENCE IS TAKEN  45800015
*        FROM PAR1 WHICH IS LEFT UNALTERED                              45840015
         SPACE 2                                                        45880015
CONSLT   XR    GRA,GRA                                                  45920001
         IC    GRA,PAR1+1(0,DICR)      PICK UP BLOCK COUNT FROM T REF   45960001
         AR    GRA,GRA                                                  46000001
         AR    GRA,GRA                 MULTIPLIED FOR WORD OFFSET       46040001
         A     GRA,CONSLTT             THIS GIVES ABS ADDS OF SLOT      46080001
         BR    RR                      RETURN                           46120001
         SPACE 2                                                        46160001
CONSLD   BC    B,CONSLDB     *****FIRST TIME BRANCH*****                46200001
CONSLDC  LH    GRA,PAR1+2(0,DICR)      PICK UP DREF (OPTED FOR LW)      46240001
         N     GRA,NEGBIT              REMOVE TOP HALF                  46280001
         N     GRA,ZMASK1-2(0,DICR)    REMOVE OFFSET                    46320001
CONSHF   SRL   GRA,0     *****SHIFT SET BY FIRST TIME CODE*****         46360001
         A     GRA,CONSLDD             THIS GIVES ABSOLUTE ADDR OF SLOT 46400001
         BR    RR                                                       46440001
*              FIRST TIME CODE                                          46480001
CONSLDB  MVI   CONSLD+1,X'00'          SET TO NOP                       46520001
         L     GRA,ZSHIFT(0,DICR)      GET NO OF BITS IN OFFSET         46560001
         S     GRA,K2                  REDUCE SHIFT BY 2                46600001
         STC   GRA,CONSHF+3            FOR WORD BLOCK OFFSET            46640001
         B     CONSLDC                                                  46680001
         EJECT                                                          46800015
*        ROUTINES TRYMRD AND TRYMRT.                                    46840015
*                       THESE ROUTINES INVESTIGATE THE CORE POSITION    46880015
*        AND PERFORM A GETMAIN IF THERE IS CORE AVAILABLE. IF NOT THEN  46920015
*        A SPILL SITUATION EXISTS AND DFREE AND TFREE ARE ENTERED. AN   46960015
*        ATTEMPT TO FIND A FREE BLOCK IS MADE FIRST EXCEPT FOR ENTRIES  47000015
*        FROM ZUTXTC                                                    47040015
         SPACE 2                                                        47080015
TRYMRT   STM   14,CNTL2,SAVAR+12       GET WORK REGISTERS               47120015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  47160015
         L     CNTL3,BASES             LOAD SECOND BASE                 47200015
         MVI   TEXTSW,X'FF'            SHOW IT IS A TEXT BLOCK TYPE     47240015
         LA    GRA,TSLOTS+24           POINT AT TSLOTS FOR SCAN         47280015
         BC    B,TRYONA                                                 47320015
         SPACE                                                          47360015
TRYMRD   STM   14,CNTL2,SAVAR+12       GET WORK REGISTERS               47400015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  47440015
         L     CNTL3,BASES             LOAD SECOND BASE                 47480015
         MVI   TEXTSW,X'00'            SHOW IT IS A DICT BLOCK TYPE     47520015
         LA    GRA,DSLOTS+24           POINT AT DSLOTS FOR SCAN         47560015
TRYONA   MVC   BLK(4),DICTSZ(DICR)     PICK UP BLOCK LENGTH             47600015
         CLI   SPILL,X'FF'             SEE IF SPILLING                  47640015
         BC    BE,YESPIL                                                47680015
         SPACE                                                          47720015
TRYON    CLI   0(GRA),X'81'            SEE IF THIS BLOCK IS IN-CORE AND 47760015
         BC    BE,BLFOND             FREE                               47800015
         LA    GRA,4(0,GRA)            BUMP TO NEXT SLOT                47840015
         CLI   1(GRA),X'FF'            TEST IF STOPPER                  47880015
         BC    BNE,TRYON                                                47920015
         SPACE                                                          47960015
*              EXAMINE CONTENTS OF BLKTBL TO SEE IF IT CONTAINS ANY     48000015
*        UNUSED BLOCKS                                                  48040015
*                                                                       48080015
         LA    GRA,10                  SET BLOCK ENTRY COUNT            48120015
         LA    GRB,BLKTBL              POINT AT BLKTBL                  48160015
NXTENT   CLI   0(GRB),X'FF'            TEST FOR A USEFUL ENTRY          48200015
         BC    BE,USDBLK             BRANCH IF NO USE                   48240015
         L     GR0,0(0,GRB)            LOAD ADDR OF BLOCK INTO GR0      48280015
         MVI   0(GRB),X'FF'            MARK ENTRY USED                  48320015
         BC    B,TRYRTN                BRANCH TO EXIT                   48360015
USDBLK   LA    GRB,4(0,GRB)            BUMP TO NEXT ENTRY               48400015
         BCT   GRA,NXTENT              LOOP IF ANY ENTRIES LEFT         48440015
         SPACE                                                          48480015
         L     GRA,CORLFT(DICR)                                         48500015
         C     GRA,BLK               SEE IF ROOM FOR ANOTHER BLOCK      48520015
         BC    BL,TRSPIL                                                48560015
         MVC   GETLST(4),BLK           PUT BLOCK LENGTH INTO GETMAIN    48600015
         MVC   GETLST+4(4),BLK                                          48640015
         LA    DICR,OSSAVR             PICK UP SAVE AREA FOR OS/360     48680015
         SPACE                                                          48720015
       GETMAIN VC,LA=GETLST,A=ANSW                                      48760015
         L     DICR,DADDR              POINT AT TRUE DICTIONARY AGAIN   48800015
         SPACE                                                          48840015
         BC    B,HERE(15)              TEST IF CORE GOT OK              48880015
HERE     BC    B,OK                                                     48920015
         BC    B,TRSPIL                TAKE THIS ONE IF CORE NOT AVAILB 48960015
         SPACE                                                          49000015
OK       L     GR0,CORLFT(0,DICR)      COMPUTE NEW VALUE OF AMOUNT OF   49040015
         S     GR0,BLK               CORE LEFT FOR TEXT AND DICTIONARY  49080015
         ST    GR0,CORLFT(0,DICR)    BLOCKS                             49120015
NOTRUE   L     GR0,ANSW                PICK UP ADDRESS OF NEW BLOCK     49160015
         SPACE                                                          49200015
TRYRTN   LM    14,15,SAVAR+12          RESTORE ALL REGISTERS            49240015
         N     GR0,STBITS              REMOVE STATUS BYTES              49280015
         LM    1,CNTL2,SAVAR+24                                         49320015
         MVI   SAVAR+12,X'FF'          SHOW RETURN IS COMPLETE          49360015
         BCR   BR,RR                                                    49400015
         SPACE                                                          49440015
TRSPIL   CLI   SPILL,X'FF'             IS A SPILL SITUATION CURRENT     49480015
         BC    BE,YESPIL                                                49520015
         SPACE                                                          49680015
         L     GRB,PAROF(CNTL)         POINT AT                         49720015
         L     GRB,SPDCBOF(GRB)        SPILL DCB                        49760015
         AIF   (NOT &STD).L1                                            49770021
         LA    DICR,OSSAVR             SUPPLY S.A. TO OPEN.             49780021
.L1      ANOP                                                           49790021
         OPEN  ((GRB),OUTIN)           OPEN SPILL FILE                  49800015
         L     DICR,DADDR              POINT AT TRUE DICTIONARY AGAIN   49840015
         LR    GRA,GRB                 POINT AT SPILL DCB               49880015
         USING IHADCB,GRA                                               49920015
         TM    DCBOFLGS,X'10'          SEE IF SPILL FILE IS OPEN        49960015
         BO    YESPIL                                             H319  50000001
         LA    GR0,OPERR1              PRINT CANNOT OPEN SYSUT1         50040015
         ST    GR0,PAR1(0,DICR)                                         50080015
         BAL   RR,ZUPL                                                  50120015
         LA    GR0,16                  SHOW A TERMINAL ERROR HAS        50160015
         ST    GR0,ERCODE(0,DICR)    OCURRED                            50200015
         L     LR,ABORTOF(CNTL)        POINT AT ZABORT                  50240015
         BALR  RR,LR                                                    50280015
         SPACE                                                          51240015
YESPIL   CLI   TEXTSW,X'FF'            FIND IF GETTING A TEXT OR DICT   51280015
         BC    BE,TGET               BLOCK                              51320015
         BAL   RR,DFREE                GET SPACE FOR A DICTIONARY BLOCK 51360015
         BC    B,PICUP                                                  51400015
TGET     BAL   RR,TFREE                GET SPACE FOR A TEXT BLOCK       51440015
PICUP    L     GR0,BLOKAD              PICK UP ADDRESS OF BLOCK         51480015
         BC    B,TRYRTN                                                 51520015
         SPACE                                                          51560015
BLFOND   MVI   0(GRA),X'00'            CLEAR STATUS                     51600015
         L     GR0,0(0,GRA)            PICK UP ADDRESS                  51640015
         MVI   0(GRA),X'FF'            MAKE SLOT FREE AGAIN             51680015
         BC    B,TRYRTN                                                 51720015
         EJECT                                                          51760015
*        ROUTINES DFREE AND TFREE                                       51800015
*                       THESE ROUTINES MAKE SPACE FOR A TEXT AND DICT   51840015
*        BLOCK. IF REQUIRED,A NEW BLOCK WILL BE READ IN. DFREE GOES     51880015
*        THROUGH A PROCEDURE TO CHANGE THE PRIORITIES OF DICTIONARY     51920015
*        BLOCKS ACCORDING TO ENTRIES IN THE LAST-LOOK TABLE AND THE     51960015
*        LOCK-SLOT. TEXT BLOCK PRIORITIES ARE CHANGED BY THE PHASE.     52000015
         SPACE 2                                                        52040015
TFREE    STM   14,4,SAVAR2             GET WORK REGISTERS               52080015
         NI    FSWTCH,X'0F'            SHOW TFREE WNTRY                 52100001
TAGAIN   LA    GRD,TSLOTS              POINT AT TSLOTS FOR A SCAN OF    52120015
         BC    B,COMON               TEXT BLOCKS                        52160015
         SPACE                                                          52200015
DFREE    STM   14,4,SAVAR2             GET WORK REGISTERS               52240015
         LA    GRD,DSLOTS+28           POINT AT START SCAN ADDRESS OF   52280015
         MVI   DICSW,X'FF'           DICTIONARY BLOCKS. SHOW IS DFREE   52320015
         OI    FSWTCH,X'F0'            SHOW DFREE ENTRY                 52340001
         SPACE                                                          52360015
SETWNT   CLI   0(GRD),X'FF'            SEE IF SLOT IS FREE              52400015
         BC    BE,ENDWNT                                                52440015
         CLI   1(GRD),X'FF'            SEE IF STOPPER                   52480015
         BC    BE,ENDWNT                                                52520015
         NI    0(GRD),X'80'            SET ALL BITS OFF                 52560015
         OI    0(GRD),X'03'            MARK AS WANTED                   52600015
SET2     LA    GRD,4(0,GRD)            BUMP TO NEXT SLOT                52640015
         BC    B,SETWNT                                                 52680015
         SPACE                                                          52720015
ENDWNT   CLC   MYNAM(2,DICR),KTNAM     SEE IF K PHASES RUNNUNG          52730001
         BC    BNL,SETANY                                               52740001
         CLI   MYNAM(DICR),C'K'                                         52750001
         BC    BE,KIN                                                   52760001
         CLC   MYNAM(2,DICR),BMNAM                                      52770001
         BC    BE,SETANY                                                52800015
         CLI   MYNAM(DICR),C'C'        SEE IF READIN IS RUNNING         52840015
         BC    BH,SETANY                                                52880015
         TM    CCCODE+2(DICR),X'04'    SEE IF ONLY TWO BLOCKS           52920015
         BC    BO,SETDLS                                                52960015
         SPACE                                                          53000015
SETANY   LA    GRC,3                   SET 3 DICTS BUSY                 53030001
CONTIN   CLI   SWTCH,X'00'             ENTRY FROM ZDICRF                53060001
         BC    BE,BYPAS1                                                53090001
         BCTR  GRC,0                                                    53120001
         SPACE 1                                                        53150001
BYPAS1   LA    GRB,LASLOK+4            POINT AT INUSE TABLE             53180001
         MVC   TEMPZ(4),PAR1(DICR)     SV PAR1 AS CONSLD IS USED        53210001
         CLC   LOCK(2,DICR),ZEROS      IF ANY LOCKED                    53240001
         BC    BE,SETBUS                                                53270001
         BCT   GRC,SETBUS              REDUCE BY 1 NUMBER OF BLOCKS     53300001
         BC    B,LOCKLCK               BRANCH AROUND IF 0               53330001
KIN      LA    GRC,2                   SET 2 D BLKS BUSY                53360001
         BC    B,CONTIN                AS IN K PHASES                   53390001
         SPACE 1                                                        53420001
SETBUS   MVC   PAR1+2(2,DICR),0(GRB)   MOVE IN REFERENCE                53520015
         BAL   RR,CONSLD                                                53560015
         NI    0(GRA),X'80'            CLE AR STATUS BITS               53600015
         OI    0(GRA),X'04'            MARK IN-CORE AND BUSY            53640015
         BCTR  GRB,0                   REDUCE TO NEXT IN LAST LOOK      53680015
         BCTR  GRB,0                 TABLE                              53720015
         BCT   GRC,SETBUS                                               53760015
         SPACE                                                          53800015
LOCKLCK  MVC   PAR1+2(2,DICR),LOCK(DICR)  PICK UP REF OF LOCKED BLOCK   53840001
         BAL   RR,CONSLD                                                53880015
         NI    0(GRA),X'80'            CLEAR STATUS BITS                53920015
         OI    0(GRA),X'04'            LOCK BLOCK INYO CORE             53960015
         MVC   PAR1(4,DICR),TEMPZ      RESTORE PAR1 AGAIN               54000015
SETDLS   LA    GRD,DSLOTS              POINT AT DICTIONARY SLOTS        54040015
         SPACE                                                          54080015
COMON    LA    GRA,24(0,GRD)           POINT AT T OR DSLOTS+24          54120015
         LR    GRC,GRD                 POINT AT ADDRESSES OF CURRENT    54160015
         XR    GRD,GRD               SLOTS. SET COUNT TO ZERO           54200015
         SPACE                                                          54240015
DTLOP    CLI   0(GRA),X'81'            TEST IF BLOCK FREE               54280015
BF       BC    BE,FREE                                                  54320015
         CLI   0(GRA),X'82'            UNWANT                           54360015
BU       BC    BE,UNWANT                                                54400015
         CLI   0(GRA),X'83'            WANT                             54440015
BW       BC    BE,WANT                                                  54480015
CARYON   LA    GRA,4(0,GRA)            BUMP TO NEXT SLOT                54520015
         CLI   1(GRA),X'FF'            TEST FOR STOPPER SLOT            54560015
         BC    BNE,DTLOP                                                54600015
         BC    B,SEARCH                                                 54640015
         SPACE                                                          54680015
FREE     ST    GRA,FADDR(0,GRC)      STORE ADDRESS OF FREE SLOT         54720015
         MVI   BF+1,X'00'              SET TO A NOP                     54760015
         BC    B,TCOUNT                                                 54800015
         SPACE                                                          54840015
UNWANT   ST    GRA,UNADDR(0,GRC)     STORE ADDRESS OF ANWANT SLOT       54880015
         MVI   BU+1,X'00'              SET TO A NOP                     54920015
         BC    B,TCOUNT                                                 54960015
         SPACE                                                          55000015
WANT     ST    GRA,WADDR(0,GRC)      STORE ADDRESS OF WANT SLOT         55040015
         MVI   BW+1,X'00'            SET TO A NOP                       55080015
         BC    B,TCOUNT                                                 55120015
         SPACE                                                          55160015
TCOUNT   LA    GRD,1(0,GRD)            BUMP NO. OF NOPS CURRENT BY 1    55200015
         CL    GRD,THREE               TEST IF NO. OF NOPS IS 3         55240015
         BC    BNE,CARYON                                               55280015
         SPACE                                                          55320015
SEARCH   CLI   DICSW,X'FF'             TEST IF ENTRY THROUGH DFREE      55360015
         BC    BNE,FINDB                                                55400015
         CLC   MYNAM(2,DICR),KTNAM     SEE IF K PHASES RUNNING          55410001
         BC    BL,BYPAS3                                                55420001
BYPAS5   LA    GRE,5                   NO, SET FOR 4 BLOCKS             55430001
         BC    B,BYPAS4                                                 55440001
BYPAS3   CLI   MYNAM(DICR),C'K'                                         55450001
         BC    BL,BYPAS5                                                55460001
         LA    GRE,6                   YES, SET FOR 5 BLOCKS            55470001
BYPAS4   LA    GRD,TSLOTS+24           COUNT TO SEE IF SPARE TEXT BLKS  55480001
CLOOP    TM    0(GRD),X'80'            SEE IF BLOCK IS IN CORE          55520015
         BC    BZ,NOT5                                                  55560015
         TM    0(GRD),X'70'                                             55600015
         BC    BZ,COUNTBL                                               55640015
NOT5     LA    GRD,4(0,GRD)            BUMP TO NEXT IN TSLOTS           55680015
         CLI   1(GRD),X'FF'            SEE IF IT IS THE STOPPER         55720015
         BC    BNE,CLOOP                                                55760015
         BC    B,FINDB                 THIS ONE IF 4 OR LESS TEXT BLOCK 55800015
COUNTBL  BCT   GRE,NOT5                ACTUALLY COUNT TEXT BLOCKS       55840015
         MVI   TAGBR+1,X'00'           MAKE IT A NOP SO CAN TRY TEXT    55880015
         BC    B,NOREAD                                                 55920015
         SPACE                                                          55960015
FINDB    XR    GR0,GR0                 SET 0 TO 0 AS A TEST AGAINS 0    56000015
         CL    GR0,FADDR(0,GRC)        TEST IF ANY FREE BLOCKS          56040015
         BC    BNE,GETF                                                 56080015
         CL    GR0,UNADDR(0,GRC)       TEST IF ANY UNWANT BLOCKS        56120015
         BC    BNE,GETU                                                 56160015
         CL    GR0,WADDR(0,GRC)        TEST IF ANY WANTED BLOCKS        56200015
         BC    BNE,GETW                                                 56240015
         SPACE 1                                                        56248001
         TM    FSWTCH,X'F0'            NO SPARE BLOCKS                  56256001
         BC    BNZ,KILL                KILL IF LOOKING FOR D BLOCK      56264001
         CLC   MYNAM(2,DICR),KTNAM     IF K PHASES RUNNING              56272001
         BC    BNL,KILL                                                 56280001
         CLI   MYNAM(DICR),C'K'                                         56288001
         BC    BL,KILL                                                  56296001
         TM    FSWTCH,X'01'            CHK IF 5 IN-CORE BLKS AVAIL      56304001
         BC    BO,KILL                                                  56312001
         OI    FSWTCH,X'01'            TRY TO GET FROM D BLOCKS         56320001
         LA    GRD,DSLOTS+28                                            56328001
         BC    B,SETWNT                                                 56336001
         SPACE 1                                                        56344001
KILL     MVC   PAR6+1(3,DICR),ERRF02   ALL TEXT BLOCKS IN CORE    32318 56348020
*                                      ARE BUSY                   32318 56352020
         BAL   RR,PASMYNAM             PICK UP PHASE NAME         32318 56356020
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 56360015
         BALR  RR,LR                   ROUTINE IN AA                    56400015
ERRF02   DC    X'0F02C0'                                          32318 56420020
         SPACE                                                          56440015
GETF     L     GRA,FADDR(0,GRC)      POINT AT SLOT WITH FREE ADDRESS    56480015
         ST    GR0,FADDR(0,GRC)        SET ADDRESS TO ZERO              56520015
         MVC   BLOKAD(4),0(GRA)        PICK UP ADDRESS OF FREE BLOCK    56560015
         MVI   0(GRA),X'FF'            SET SLOT FREE                    56600015
         CL    GR0,RDTTR               SEE IF READ REQUIRED             56640015
         BC    BE,NOREAD                                                56680015
         BAL   RR,WDREAD               ENTER WRITE-DISK IN READ ONLY    56720015
         BC    B,NOREAD              MODE                               56760015
         SPACE                                                          56800015
GETU     L     GRA,UNADDR(0,GRC)     PICK UP ADDRESS OF UNWANT BLOCK    56840015
         ST    GR0,UNADDR(0,GRC)     SLOT. SET ADDRESS TO ZERO.         56880015
         BC    B,TRDTR                                                  56920015
         SPACE                                                          56960015
GETW     L     GRA,WADDR(0,GRC)      PICK UP ADDRESS OF WANTED BLOCK    57000015
         ST    GR0,WADDR(0,GRC)      SLOT. SET ADDRESS TO ZERO.         57040015
         SPACE                                                          57080015
TRDTR    MVC   BLOKAD(4),0(GRA)         PICK UP ADDRESS OF BLOCK TO BE  57120015
         CL    GR0,RDTTR             MADE FREE. SEE IF BLOCK REQUIRED   57160015
         BC    BE,WRTONL             INTO CORE                          57200015
         BAL   RR,WRTRD                A WRITE-READ ENTRY               57240015
         BC    B,MARK                                                   57280015
WRTONL   BAL   RR,WDWRIT               A WRITE ONLY ENTRY               57320015
         SPACE                                                          57360015
MARK     NI    0(GRA),X'7F'            MARK BLOCK AS ON DISK            57400015
         MVC   1(3,GRA),NOTTR          INSERT TRACK ADDRESS             57440015
NOREAD   MVI   DICSW,X'00'             SET DICSW OFF                    57480015
         XR    GR0,GR0                                                  57520015
         ST    GR0,FADDR(0,GRC)        SET SLOTS TO ZERO FOR NEXT ENTRY 57560015
         ST    GR0,UNADDR(0,GRC)     TO SPILL ROUTINES                  57600015
         ST    GR0,WADDR(0,GRC)                                         57640015
         MVI   BF+1,X'80'              SET TO BRANCH FOR NEXT SCAN OF   57680015
         MVI   BU+1,X'80'            SLOTS                              57720015
         MVI   BW+1,X'80'                                               57760015
TAGBR    BC    B,DFROUT                                                 57800015
         MVI   TAGBR+1,X'F0'           MAKE IT A BRANCH AGAIN           57840015
         BC    B,TAGAIN                                                 57880015
         SPACE                                                          57920015
DFROUT   LM    RR,4,SAVAR2             RELOAD REGISTERS                 57960015
         MVI   SAVAR2,X'FF'            SHOW RETURN IS COMPLETE          58000015
         BCR   BR,RR                                                    58040015
         SPACE                                                          58080015
         EJECT                                                          58160015
*        ROUTINE WRTDSK                                                 58200015
*                       THIS ROUTINE IS THE ONE THAT ACTUALLY HAS       58240015
*        THE DATA MANAGEMENT MACROS TO CONTROL THE SPILL FILE. THREE    58280015
*        ENTRIES ARE SUPPLIED                                           58320015
*                       1) READ ONLY       ENTRY-POINT  WDREAD          58360015
*                       2) WRITE ONLY                   WDWRIT          58400015
*                   AND 3) WRITE-READ                   WRTRD           58440015
*        A LIST OF FREE SPACES ON THE SPILL DEVICE IS KEPT IN FRSLOT.   58480015
*              IF A WRITE ENTRY IS ENCOUNTERED THEN FRSCOTS IS CHECKED  58520015
*        TO SEE IF ANY FREE TRACKS ARE AVAILABLE WITHIN THE EXTENT OF   58560015
*        THE DATA-SET ALREADY WRITTEN. IF SUCH A HOLE DOES EXIST THEN   58600015
*        THE TTR OF THE TRACK IS PLACED IN TEMP4 AND WRITEX IS ENTERED. 58640015
*              IF A READ IS REQUESTED THEN READX IS ENTERED. THE TTR    58680015
*        IS PLACED IN A FREE SLOT IN FRSLOTS                            58720015
*              IF NO FREE TRACKS EXIST WITH A WRITE ENTRY THEN BSAM IS  58760015
*        USED TO WRITE A RECORD ON THE END OF THE EXISTING DATA-SET. IN 58800015
*        THIS WAY, PREFORMATTING IS PERFORMED AT THE SAME TIME AS THE   58840015
*        DATA-SET IS CREATED. LATER USE OF XDAP IS THEN ALLOWED.        58880015
*                                                                       58920015
         SPACE 2                                                        58960015
WDWRIT   MVI   WRTON,X'FF'             SET WRITE ONLY SWITCH            59000015
         SPACE                                                          59040015
WRTRD    STM   14,4,SAVAR3             GET SOME WORK REGISTERS          59080015
         LA    DICR,OSSAVR             POINT AT SAVE AREA FOR OS/360    59120015
         CLI   SPILL,X'FF'         ARE WE SPILLING                      59125015
         BC    BE,SWDWRIT          BRANCH IF SO                         59130015
         MVI   SPILL,X'FF'         SHOW SPILLING                        59135015
         L     GRD,DADDR                                                59140015
         MVC   SPLNAM(2,GRD),MYNAM(GRD)     MOVE IN NAME OF SPILL PHS   59145015
SWDWRIT  EQU   *                                                        59150015
         CLC   NUMFRE(4),ZEROS         SEE IF ANY FREE TRACKS ON DISK   59160015
         BC    BE,NOFREE                                                59200015
         SPACE                                                          59240015
         LA    GRA,FRSLOT              POINT AT LIST OF FREE TRACKS     59280015
         SPACE                                                          59320015
FRLOP    CLI   0(GRA),X'FF'            TEST IF SLOT IN USE              59360015
         BC    BNE,FONDT                                                59400015
         LA    GRA,3(0,GRA)            BUMP TO NEXT ENTRY IN FRESLOTS   59440015
         BC    B,FRLOP                                                  59480015
         SPACE                                                          59520015
FONDT    L     GRB,NUMFRE              NUMFRE= NUMFRE-1                 59560015
         BCTR  GRB,0                                                    59600015
         ST    GRB,NUMFRE                                               59640015
         MVC   NOTTR(3),0(GRA)         PICK UP TTR TO STORE IN SLOTS    59680015
         MVI   TEMP4+3,X'00'           SET ZERO BYTE TO ZERO            59720015
         MVC   TEMP4(3),0(GRA)         PICK UP TTR OF FREE TRACK ON     59760015
         MVI   0(GRA),X'FF'          DISK. SET SLOT FREE                59800015
         BAL   RR,WRITEX               WRITE BLOCK ONTO FREE TRACK      59840015
         SPACE                                                          59880015
WRTOUT   CLI   WRTON,X'FF'             TEST IF WRITE ONLY               59920015
         BC    BNE,READ                                                 59960015
         MVI   WRTON,X'00'             SET WRITE ONLY SWITCH OFF        60000015
         BC    B,WROUT                                                  60040015
         SPACE                                                          60080015
WDREAD   STM   14,4,SAVAR3             GET WORK REGISTERS               60120015
         LA    DICR,OSSAVR             POINT AT SAVE AREA FOR OS/360    60160015
         SPACE                                                          60200015
READ     MVC   TEMP4(4),RDTTR          PICK UP ADDRESS OF RCD TO READ   60240015
         BAL   RR,READX                READ BLOCK FROM DA DEVICE        60280015
         SPACE                                                          60320015
         LA    GRA,FRSLOT              POINT AT LIST OF FREE TRACKS     60360015
         SPACE                                                          60400015
FRLOOP   CLI   0(GRA),X'FF'            SEE IF SLOT FREE                 60440015
         BC    BE,FONDFR                                                60480015
         LA    GRA,3(0,GRA)            BUMP TO NEXT IN FRESLOTS         60520015
         CLC   0(3,GRA),ZEROS          SEE IF END OF LIST               60560015
         BC    BNE,FRLOOP                                               60600015
         SPACE                                                          60640015
         BC    B,WROUT                 THROW TRK ADDR AWAY, TABLE FULL  60680015
         SPACE                                                          60720015
FONDFR   MVC   0(3,GRA),RDTTR          MOVE IN ADDRESS OF FREE TRACK    60760015
         L     GRA,NUMFRE                                               60800015
         LA    GRA,1(0,GRA)            BUMP NUMBER OF FREE TRACKS BY 1  60840015
         ST    GRA,NUMFRE                                               60880015
         SPACE                                                          60920015
WROUT    LM    14,4,SAVAR3             RELOAD REGISTERS                 60960015
         MVI   SAVAR3,X'FF'            SHOW RETURN IS COMPLETE          61000015
         L     DICR,DADDR              POINT AT TRUE DICTIONARY         61040015
         BCR   BR,RR                                                    61080015
         SPACE                                                          61120015
NOFREE   MVI   WRSWCH+1,X'00'          SET SWITCH TO MAKE A NOTE OF TTR 61160015
         MVI   NONOTE+1,X'00'          SET SWITCH TO CONTROL LAST RCD   61200015
         L     GRB,BLK                 PICK UP TOTAL BLOCK LENGTH       61240015
         L     GRC,BLOKAD              PICK UP ADDRESS OF               61280015
         L     GRD,PAROF(CNTL)         POINT AT INIT LIST         H319  61300001
         L     GRD,UT1OF(GRD)          HENCE AT LGTH TO WRITE     H319  61320001
         LH    GRD,0(GRD)              PICK UP LGTH               H319  61340001
         SPACE                                                          61360015
WRLOP    LA    DICR,OSSAVR             POINT AT NEW SAVE AREA           61400015
         SPACE                                                          61440015
         L     GR5,PAROF(CNTL)         POINT AT INIT LIST               61480015
         L     GR5,SPDCBOF(GR5)        HENCE AT SPILL DCB               61520015
         WRITE WDECB,SF,(GR5),(GRC),(GRD)          WRITE THIS RECORD    61560015
         SPACE                                                          61600015
         LA    1,WDECB                                                  61640015
         CHECK (1)                     CHECK WRITE IS OK                61680015
WRSWCH   BC    NOP,NONOTE                                               61720015
         MVI   WRSWCH+1,X'F0'          ONLY NOTE TTR ON FIRST RECORD    61760015
         LR    GRA,GR5                 POINT AT SPILL DCB               61800015
         NOTE  (1)                                                      61840015
         A     1,BUMPTR                BUMP R OF TTR TO ALLOW FOR POINT 61880015
         ST    1,NOTTR                                                  61920015
         SPACE                                                          61960015
NONOTE   BC    NOP,WRTOOT                                               62000015
         AR    GRC,GRD                 BUMP ADDR OF AREA TO BE WRITTEN  62040015
         SR    GRB,GRD                 REDUCE LENGTH TO BE WRITTEN      62080015
         LTR   GRB,GRB               SEE IF ANY LEFT TO BE WRITTEN      62120015
         BC    BZ,WRTOOT                                                62160015
         CR    GRD,GRB                 SEE IF LAST RECORD IS WRITTEN    62200015
         BC    BH,WRTCOM                                                62240015
         BC    B,WRLOP                                                  62280015
         SPACE                                                          62320015
WRTCOM   LR    GRD,GRB                 SET UP TO WRITE LAST BIT OF RCD  62360015
         MVI   NONOTE+1,X'F0'                                           62400015
         BC    B,WRLOP                                                  62440015
         SPACE                                                          62480015
WRTOOT   BC    B,WRTOUT                JUST AN EXTRA BRANCH             62520015
         EJECT                                                          62560015
         SPACE                                                          62600015
*                                                                       62640015
*              THIS ROUTINE ACTUALLY PERFORMS THE READING AND WRITING   62680015
*        OF TEXT AND DICTIONARY BLOCKS USING XDAP. THIS ROUTINE IS ONLY 62720015
*        ENTERED WHEN                                                   62760015
*              1) IT IS NECESSARY TO READ A BLOCK FROM DISK             62800015
*              2) IT IS NECESSARY TO FILL IN A HOLE IN THE DATASET MADE 62840015
*            BY A PREVIOUS READ                                         62880015
*              THE TTR OF THE RECORD IS FOUND IN TEMP4. THE FIRST PART  62920015
*        OF THE SPILL DCB IS SAVED AND THEN A POINT IS PERFORMED TO     62960015
*        CONVERT THE TTR TO ABSOLUTE IN THE DCB. XDAP USES THIS ABSOLUT 63000015
*        ADDRESS TO READ AND WRITE.                                     63040015
*              A TRACK-LENGTH OR A BLOCK-LENGTH IS WRITTEN AT A TIME,   63080015
*        DEPENDING UPON WHICH IS LEAST. TRACK-LENGTHS ARE WRITTEN UNTIL 63120015
*        THE BLOCK IS COMPLETE.                                         63160015
*              IF THE BLOCK SPANS MORE THAN ONE TRACK THEN THE TTR IN   63200015
*        TEMP4 IS BUMPED TO THE FIRST RECORD OF THE NEXT TRACK. THE     63240015
*        POINT IS PERFORMED EACH TIME ROUND THE LOOP IN ORDER TO        63280015
*        CONVERT THE NEW TTR                                            63320015
*                                                                       63360015
WRITEX   MVI   PLOOM+1,X'00'           SET FOR A WRITE                  63400015
         BC    B,XXX                                                    63440015
         SPACE                                                          63480015
READX    MVI   PLOOM+1,X'F0'           SET FOR A READ                   63520015
XXX      ST    RR,TEMPWR                                                63560015
         L     GR5,PAROF(CNTL)         POINT AT INITIALISATION LIST     63600015
         L     GRD,UT1OF(GR5)          AND HENCE AT LENGTH TO WRITH319  63620001
         L     GR5,SPDCBOF(GR5)        AND HENCE AT SPILL DCB           63640015
         SPACE                                                          63680015
         L     GRB,BLK                 PICK UP TOTAL BLOCK LENGTH       63720015
         L     GRC,BLOKAD              PICK UP ADDRESS OF BLOCK IN CORE 63760015
         LH    GRD,0(GRD)              PICK UP LGTH TO WRITE      H319  63800001
         MVI   CHEKX+1,X'00'           SET UP FOR ACTION                63840015
         SPACE                                                          63880015
         MVC   SAVPQ(16),4(GR5)      SAVE AREA ALTERED BY POINT         63920015
MDLOP    LR    1,GR5                 POINT AT SPILL DCB                 63960015
         LA    0,TEMP4                 POINT AT TTR TO BE CONVERTED     64000015
         SPACE                                                          64040015
         POINT (1),(0)                 GET ABSOLUTE ADDRESS OF TTR      64080015
         SPACE                                                          64120015
         LA    GRH,5(GR5)                                               64160015
PLOOM    BC    NOP,READY               BRANCH IF A READ REQUIRED        64200015
         SPACE                                                          64240015
         XDAP  ECBX,WI,(GR5),(3),(4),,(GRH),MF=E                        64280015
         SPACE                                                          64320015
         BC    B,IOCOMP                                                 64360015
         SPACE                                                          64400015
READY    XDAP  ECBX,RI,(GR5),(3),(4),,(GRH),MF=E                        64440015
         SPACE                                                          64480015
IOCOMP   LA    1,ECBX                  POINT AT IOB FOR WAIT            64520015
         SPACE                                                          64560015
         WAIT  ECB=(1)                 WAIT FOR READ OR WRITE TO COMPLT 64600015
         CLI   ECBX,X'7F'              TEST FOR ERROR ON SYSUT1         64640015
         BC    BNE,UTIERR                                               64680015
         SPACE                                                          64720015
CHEKX    BC    NOP,ALLOOP              BRANCH WHEN ALL BLOCK IS WRITTEN 64760015
         MVI   TEMP4+2,X'00'           SET R IN TTR TO ZERO             64800015
         L     GR0,TEMP4               PICK UP TTR OF RECORD            64840015
         A     GR0,BUMPTT              BUMP TO FIRST RCD OF NEXT TRACK  64880015
         ST    GR0,TEMP4                                                64920015
         AR    GRC,GRD                 BUMP ADDRESS                     64960015
         SR    GRB,GRD                 REDUCE LENGTH TO BE WRITTEN      65000015
         BC    BZ,ALLOOP                                                65040015
         CR    GRD,GRB                 SEE IF RECORD ALL WRITTEN        65080015
         BC    BNH,MDLOP               ON LAST LAP                      65120015
         SPACE                                                          65160015
ALMOST   LR    GRD,GRB                 SET UP TO I/O LAST BIT OF RECORD 65200015
         MVI   CHEKX+1,X'F0'                                            65240015
         BC    B,MDLOP                                                  65280015
         SPACE                                                          65320015
ALLOOP   L     RR,TEMPWR                                                65360015
         MVC   4(16,GR5),SAVPQ         RESTORE START OF SPILL DCB       65400015
         BCR   BR,RR                                                    65440015
         SPACE                                                          65480015
UTIERR   L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  65520015
         L     CNTL3,BASES             LOAD SECOND BASE                 65560015
         L     DICR,DADDR              POINT AT DICTIONARY              65600015
         MVI   IOERSW(DICR),X'FF'      SHOW I/O ERROR                   65640015
         L     LR,PAROF(CNTL)          POINT AT INITIALISATION LIST     65680015
         L     LR,DYNSWOF(LR)          HENCE AT DYNSW                   65720015
         MVI   0(LR),X'FF'             SHOW RETURN HERE                 65760015
         L     LR,DYNAMOF(CNTL)        POINT AT DYNAMIC                 65800015
         BALR  RR,LR                   ROUTINE IN AA                    65840015
         LA    GR0,UTIMES              SAY PERMANENT ERROR ON SYSUT1    65880015
         ST    GR0,PAR1(0,DICR)                                         65920015
         BAL   RR,ZUPL                                                  65960015
         LA    GR0,16                  SHOW A TERMINAL ERROR HAS        66000015
         ST    GR0,ERCODE(0,DICR)    OCURRED                            66040015
         L     LR,ZENDOF(CNTL)         POINT AT ZEND                    66080015
         BCR   BR,LR                   AND BRANCH                       66120015
         EJECT                                                          66160015
         EJECT                                                          66200015
*        ROUTINE ZURD                                                   66240015
*                       THIS OBTAINS AN 80-CHARACTER CARD IMAGE FROM    66280015
*        SOME EXTERNAL DEVICE. ONLY ONE DCB IS USED. THE DCB IS OPENED  66320015
*        AND CLOSED DYNAMICALLY BY THE LOADING ROUTINE IN ORDER TO      66360015
*        SWITCH THE INPUT DEVICE. PAR1 CONTAINS THE ADDRESS OF THE AREA 66400015
*        INTO WHICH THE CARD IMAGE MUST BE PLACED. GET(MOVE) IS USED.   66440015
         SPACE 2                                                        66480015
ZURD     STM   14,CNTL2,12(DICR)       STORE REGS. REQUIRED BY ZURD     66520015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  66560015
         L     CNTL3,BASES             LOAD SECOND BASE                 66600015
         LA    2,SAVAR                                                  66640015
         ST    DICR,4(0,2)             STORE ADDRESS OF CALLING SAVE    66680015
         ST    2,8(0,DICR)           AREA AND OF CALLED SAVE AREA       66720015
         L     DICR,DADDR              POINT AT DICTIONARY              66760015
         L     0,PAR1(0,DICR)          PICK UP ADDRESS OF INPUT AREA    66800015
         SPACE                                                          66840015
         TM    CCCODE+2(DICR),X'01'    SEE IF SWITCH IS SET BY INTIAL-  66880015
RDBRCH   BC    BO,NOTREAD            ISOR. IF SO CARD ALREADY READ      66920015
         SPACE                                                          66960015
         LR    DICR,2                  POINT AT NEW SAVE AREA           67000015
         MVI   ZURDRT+3,X'04'          MAKE A NORMAL RETURN             67040015
         L     GRA,PAROF(CNTL)       POINT AT  INIT  LIST               67080015
         L     GRA,RDADDOF(GRA)        HENCE AT READ DCB ADDR           67120015
         L     GRA,0(0,GRA)          HENCE AT READ DCB                  67160015
         SPACE                                                          67200015
         GET   (1),(0)                 INSERT RECORD                    67240015
         SPACE                                                          67280015
RDLAST   L     DICR,DADDR                                               67320015
         SPACE                                                          67360015
         USING IHADCB,GRA                                               67400015
         L     GRA,PAROF(CNTL)         POINT AT INITIALISATION LIST     67440015
         L     GRA,RDADDOF(GRA)        HENCE AT READ DCB ADDR           67480015
         L     GRA,0(0,GRA)            HENCE AT READ DCB                67520015
         LH    GRA,DCBLRECL            PICK UP RECORD LENGTH OF THIS    67560015
         ST    GRA,PAR2(0,DICR)      RECORD AND STORE TO TELL CALLER    67600015
         DROP  GRA                                                      67640015
         SPACE                                                          67680015
         L     GRC,PAR1(0,DICR)        POINT AT IN PUT BUFFER           67720015
         CLC   0(1,GRC),BTCHCD         SEE IF IT IS A BATCH CONTROL CD  67760015
         BC    BNE,RDOUT                                                67800015
         LR    GRD,GRC                                                  67805015
BLNKOP   LA    GRD,1(GRD)          LOOK AT NEXT CHAR                    67810015
         CLI   0(GRD),X'40'        IS IT A BLANK                        67815015
         BC    BE,BLNKOP           BRANCH IF SO                         67820015
         CLC   0(7,GRD),PROCESSW   IS IT *  PROCESS                     67825015
         BC    BE,BATCH              BRANCH IF BATCH CARD         IEM00 67828017
         SPACE 1                                                  IEM00 67831017
         CLC   0(4,GRD),DATASW                                    IEM00 67834017
         BC    BNE,RDOUT             BRANCH IF NOT DATA CARD      IEM00 67837017
         SPACE 1                                                  IEM00 67840017
         L     LR,0(CNTL)            POSSIBLE ADDR OF DATA ROUTINEIEM00 67843017
         LTR   LR,LR                                              IEM00 67846017
         BC    BZ,RDOUT              BRANCH IF NOT LOAD AND GO    IEM00 67849017
         SPACE 1                                                  IEM00 67852017
         LR    13,2                  POINT TO SAVE AREA           IEM00 67855017
         BALR  RR,LR                                              IEM00 67858017
         BC    B,ZURDAB              MAKE END OF FILE RETURN      IEM00 67861017
         SPACE 1                                                  IEM00 67864017
BATCH    EX    GRA,SAVBTC            SAVE BATCH CARD TO LOOK FOR  IEM00 67867017
*                                                           PARM  IEM00 67870017
         STC   GRA,PARMLEN(0,DICR)     STORE RECORD LENGTH              67880015
         OI    CCCODE+3(DICR),X'08'    SHOW BATCH CARD FOUND            67920015
         BC    B,ZURDAB                                                 67960015
         SPACE                                                          68000015
RDOUT    LR    DICR,2                  POINT AT SAVE AREA               68040015
         L     DICR,4(0,DICR)          POINT AT NEXT LOWER SAVE AREA    68080015
         LM    14,CNTL2,12(DICR)       RELOAD ALL REGISTERS             68120015
         MVI   12(DICR),X'FF'          SHOW RETURN IS COMPLETE          68160015
ZURDRT   BC    B,4(0,RR)                                                68200015
         SPACE                                                          68240015
ZURDAB   L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  68280015
         L     CNTL3,BASES             LOAD SECOND BASE                 68320015
         MVI   ZURDRT+3,X'00'          MAKE IT EOF RETURN               68360015
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN        68400015
         OI    CCCODE+3(DICR),X'04'    SHOW END OF FILE CARD FOUND      68440015
         BC    B,RDOUT                                                  68480015
         SPACE                                                          68520015
NOTREAD  LR    GRA,GR0                 PICK UP INPUT AREA ADDRESS       68560015
         LA    GRD,READSL(0,DICR)      PICK UP ADDRESS OF FIRST CARD    68600015
         LH    GRC,READSL(0,DICR)      PICK UP LENGTH                   68640015
         ST    GRC,PAR2(0,DICR)                                         68680015
         BCTR  GRC,0                   REDUCE TO GIVE LENGTH OF BOVE    68720015
         STC   GRC,RCDMV+1                                              68760015
RCDMV    MVC   0(0,GRA),2(GRD)         MOVE RECORD INTO INPUT AREA      68800015
         MVI   RDBRCH+1,X'00'          ALL SUBSEQUENT CARDS ARE READ    68840015
         MVI   READSL(DICR),C' '       CLEAR PRINT AREA                 68880015
         MVC   READSL+1(80,DICR),READSL(DICR)                           68920015
         BC    B,RDOUT                                                  68960015
         SPACE                                                          69000015
SAVBTC   MVC   BTCHBUF(0),0(GRC)                                        69040015
         EJECT                                                          69080015
*              THE CONSTANT FIELDS FOR XDAP MACROS USED IN WRITEX       69120015
*        AND READX                                                      69160015
         SPACE 2                                                        69200015
         XDAP  ECBX,WI,MF=L                                             69240015
         EJECT                                                          69280015
*        ROUTINE ZUPL                                                   69320015
*                            THIS ROUTINE MOVES A LINE OF OUTPUT TO THE 69360015
*        OUTPUT BUFFER. PAGE CONTROL AND HEADINGS ARE PERFORMED AUTO-   69400015
*        MATICALLY.                                                     69440015
*              PAR1 POINTS AT THE LINE TO BE PRINTED. PAR3 MUST POINT   69480015
*        TO THE CALLERS HEADING LINE. THIS LINE WILL BE PRINTED ONLY    69520015
*        WHEN A SKIP TO A NEW PAGE OCCURS                               69560015
*              A COUNT OF THE LINES PRINTED/PAGE IS KEPT IN CCCOUN. IT  69600015
*        IS CHECKED AGAINST MAX LINES/PAGE BEFORE EVERY LINE IS PRINTED 69640015
*        IF THE PAGE IS FULL THEN THE NEWPAGE ROUTINE IS ENTERED. IT IS 69680015
*        HERE THAT PAGE NUMBERING IS PERFORMED.                         69720015
*              CONTROL ONLY LINES ARE EXPANDED BY ADDING 9 BLANKS. THIS 69760015
*        IS TO PREVENT I/O CHECKS SINCE THE O/S 360 DOES NOT SUPPORT    69800015
*        SUCH AN OBVIOUS REQUIREMENT                                    69840015
         SPACE 2                                                        69880015
ZUPL     STM   14,CNTL2,12(DICR)       STORE REGISTERS IN SAVE AREA     69920015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  69960015
         L     CNTL3,BASES             LOAD SECOND BASE                 70000015
         LA    GRA,OSSAVR              POINT AT NEW SAVE AREA           70040015
         ST    DICR,4(0,GRA)           CHAIN FORWARDS                   70080015
         ST    GRA,8(0,DICR)           CHAIN BACKWARDS                  70120015
         SPACE                                                          70160015
         L     GRE,CCCOUN              PICK UP PAGE COUNTER             70200015
         L     DICR,DADDR              POINT AT DICTIONARY              70240015
         L     GRD,PAR1(0,DICR)        PICK UP ADDRESS OF LINE TO PRINT 70280015
         CLI   THRSW,X'FF'             SEE IF THREE SPACE REQUIRED      70320015
         BC    BE,TRECC                                                 70360015
         SPACE                                                          70400015
         CLI    2(GRD),C'1'             SEE IF EJECT                    70440015
         BC    BE,EJLINE                                                70480015
MORLIN   CLI   HDSW,X'FF'              SEE IF FIRST LINE AFTER SUB HEAD 70520015
         BC    BNE,ON                                                   70560015
         MVI   HDSW,X'00'              CLEAR TO SHOW START OF PAGE IS   70600015
         BC    B,TWOCC               COMPLETE                           70640015
         SPACE                                                          70680015
ON       LA     GRA,1                                                   70720015
         CLI    2(GRD),C'+'             IS IT 0 LINES                   70760015
         BC     BE,L4                   BRANCH IF SO                    70800015
         CLI   2(GRD),C'0'              IS IT 2 LINES                   70840015
         BC     BE,L2                  BRANCH IF SO                     70880015
         CLI    2(GRD),C'-'             IS IT 3 LINES                   70920015
         BC     BE,L1                   BRANCH IF SO                    70960015
         MVI    2(GRD),C' '             MUST BE ONE LINE                71000015
         BC     B,L3                                                    71040015
L1       LA     GRA,1(GRA)                                              71080015
L2       LA     GRA,1(GRA)                                              71120015
L3       AR     GRE,GRA                 CALCULATE NEW CCCOUN            71160015
L4       MVI    HDSW,X'00'                                              71200015
         SPACE                                                          71240015
         CL    GRE,MAXPAG              SEE IF END OF PAGE HAS BEEN      71280015
         BC    BNL,NEWPAG            REACHED                            71320015
         SPACE                                                          71360015
         MVC   SETCC+1(1),2(GRD)       MOVE IN CNTL CHAR                71400015
         BC     B,TESTL                                                 71440015
         SPACE                                                          71480015
TRECC    MVI   SETCC+1,C'-'            SPACE 3                          71520015
         MVI   THRSW,X'00'                                              71560015
         BC    B,TESTL                                                  71600015
TWOCC    MVI   SETCC+1,C'0'            SPACE 2                          71640015
         SPACE                                                          71680015
TESTL    LA    DICR,OSSAVR             POINT AT SAVE AREA               71720015
         L     GRA,PAROF(CNTL)         POINT AT                         71760015
         L     GRA,PLDCBOF(GRA)        PRINT DCB                        71800015
         PUT   (1)                     FIND BUFFER SPACE                71840015
SETCC    MVI   4(GRA),X'00'            MOVE IN THE CC OP FOR THIS LINE  71880015
         SPACE                                                          71920015
         MVC   TEMP+2(2),0(GRD)        PICK UP LENGTH OF LINE           71960015
         LH    GRB,TEMP+2                                               72000015
         C     GRB,ZEROS               SEE IF CONTROL ONLY              72040015
         BC    BE,CONLYX                                                72080015
         SPACE                                                          72120015
         BCTR  GRB,0                   REDUCE LENGTH BY 1               72160015
         EX    GRB,PLMOVE              MOVE CHARACTERS TO BUFFER        72200015
         LA    GRB,1(0,GRB)            THIS GIVES TRUE LENGTH OF LINE   72240015
CONLY    LA    GRB,5(0,GRB)            THIS GIVES TRUE RECORD LENGTH    72280015
         ST    GRB,TEMP                                                 72320015
         MVC   0(2,GRA),TEMP+2         INSERT LENGTH OF LOGICAL RECORD  72360015
         SPACE                                                          72400015
         CLI   HDSW,X'FF'              SEE IF SUBSID HEADING            72440015
         BC    BNE,ZPLOUT                                               72480015
         L     DICR,DADDR              POINT AT DICTIONARY AGAIN        72520015
         L     GRD,PAR1(0,DICR)        EVENTUALLY PRINT NEXT LINE       72560015
         BC    B,MORLIN                                                 72600015
         SPACE                                                          72640015
ZPLOUT   LA    GRA,OSSAVR              POINT AT SAVE AREA               72680015
         MVI   EJCSW,X'00'             ALWAYS TURN THIS SWITCH OFF      72720015
         MVI   HDSW,X'00'                                               72760015
         ST    GRE,CCCOUN              STORE PAGE LINE COUNT            72800015
         L     DICR,4(0,GRA)           POINT AT PREVIOUS SAVE AREA      72840015
         BC    B,RETRTN       BRANCH TO 'RETURN TO CALLER' ROUTINE      72880015
         SPACE                                                          72920015
EJLINE   MVI   EJCSW,X'FF'             SHOW EJECT IN PROGRESS           72960015
         SPACE                                                          73000015
NEWPAG   AP    PAGNO(3),ONE(3)         ADD 1 TO PAGE NUMBER             73040015
         MVC   HEDING+113(6),EDWRD     EDIT INTO PAGE FIELD             73080015
         ED    HEDING+113(6),PAGNO                                      73120015
         MVI   THRSW,X'FF'             SHOW NEXT LINE MUST HAVE 3 SPACE 73160015
         LA    GRE,4                                                    73200015
         SPACE                                                          73240015
         LA    DICR,OSSAVR             POINT AT SAVE AREA               73280015
         L     GRA,PAROF(CNTL)         POINT AT                         73320015
         L     GRA,PLDCBOF(GRA)        PRINT DCB                        73360015
         PUT   (1)                     FIND BUFFER SPACE                73400015
         MVC   0(125,GRA),HEDX         INSERT HEADING                   73440015
         SPACE                                                          73480015
         L     DICR,DADDR              POINT AT DICTIONARY              73520015
         CLC   PAR3(4,DICR),ZEROS      SEE IF SECOND HEADING LINE RQD   73560015
         BC    BNE,SUBHED                                               73600015
         CLI   1(GRD),X'00'            SEE IF CONTROL ONLY              73640015
         BC    BE,ZPLOUT                                                73680015
         BC    B,TRECC                                                  73720015
SUBHED   L     GRD,PAR3(0,DICR)        PICK UP ADDRESS OF SUB-HEAD LINE 73760015
         LA    GRE,2(0,GRE)            HEADING + 1 BLANK LINE     45901 73800056
         MVI   HDSW,X'FF'                                               73840015
         BC    B,TRECC                                                  73880015
         SPACE                                                          73920015
CONLYX   EQU   *                                                  H268  73980001
         MVC   5(9,GRA),BLANKS         INSERT A DUMMY LINE              74040015
         LA    GRB,9(0,GRB)            BUMP TO GIVE A GOOD LINE COUNT   74080015
         BC    B,CONLY                                                  74120015
         SPACE                                                          74160015
EDWRD    DC    X'402020202020'                                          74200015
THRSW    DC    X'00'                                                    74240015
EJCSW    DC    X'00'                   SWITCH TO SHOW END OF PAGE       74280015
HDSW     DC    X'00'                   SWITCH TO SHOW USER HEADING      74320015
CCCOUN   DC    F'0'                    PAGE LINE COUNT                  74360015
MAXPAG   DC    F'55'                   MAXIMUM NUMBER OF LINES/PAGE     74400015
         SPACE                                                          74440015
BLANKS   DC    CL9' '                                             20706 74460001
         DS    0F                                                 20706 74480001
PAGNO    DC    X'00001F'               SET PAGE TO ONE ORIGINALLY       74520015
ONE      DC    X'00001F'               PAGE NUMBER INGREMENTER          74560015
HEDX     DC    X'007C'                                                  74600015
         DC    X'0000'                                                  74640015
         DC    C'1'                    EJECT CONTROL CHARACTER          74680015
HEDING   DS    104C                                                     74720015
         DC    C'PAGE'                                                  74760015
         DS    12C                                                      74800015
         SPACE                                                          74840015
PLMOVE   MVC   5(0,GRA),3(GRD)         MOVE IN LINE TO BE PRINTED       74880015
         EJECT                                                          74920015
TEMPZ    DS    F                                                        74960015
TEMPY    DC    2F'0'                                                    75000015
TEMSYN   DC    F'0'                                                     75040015
ABSAV    DS    18F                                                      75080015
BLK      DS    F                                                        75120015
ANSW     DS    F                                                        75160015
GETLST   DS    F                                                        75200015
         DS    F                                                        75240015
NUMFRE   DC    F'0'                    NUMBER OF FREE TRACKS            75280015
SAVAR3   DS    7F                                                       75320015
SAVPQ    DS    4F                                                       75360015
BLOKAD   DS    F                                                        75400015
SAVAR2   DS    7F                                                       75440015
TRKL     DS    F                                                        75480015
TEMPWR   DC    F'0'                                                     75520015
BUMPTR   DC    X'00000100'             USED TO BUMP R IN TTR            75560015
BUMPTT   DC    X'00010200'             BUMP TO FST RCD OF NEXT TRACK    75600015
FRSLOT   DC    30XL3'FF0000'           HOLDS TRACK ADDRESSES OF FREE    75640015
         DC    X'000000'             TRACKS ON DISK                     75680015
FADDR    EQU   0                                                        75720015
UNADDR   EQU   4                                                        75760015
WADDR    EQU   8                                                        75800015
         DC    X'0000'                                                  75840015
LASLOK   DC    X'0000'                                                  75880015
         DC    X'0000'                                                  75920015
         DC    X'0000'                                                  75960015
TEXTSW   DC    X'00'                   TEXT SWITCH FOR TRYMR            76000015
SPILL    DC    X'00'                   SPILL SWITCH                     76040015
DICSW    DC    X'00'                                                    76080015
BTCHBUF  DC    101C' '                                                  76120015
PROCESSW DC    C'PROCESS'                                               76140015
DATASW   DC    C'DATA'                                            IEM00 76150017
K2       DC    F'2'                    CONSTANT 2                       76155001
         EJECT                                                          76160015
*              THIS ROUTINE RETURNS TO THE CALLER * * * * * ** * * * *  76200015
RETRTN   LM    14,CNTL2,12(DICR)        RELOAD REGISTERS                76240015
         MVI   12(DICR),X'FF'           SHOW RETURN IS COMPLETE         76280015
         BCR   BR,RR                    RETURN TO CALLER                76320015
         EJECT                                                          76360015
RECONS   STM   14,CNTL2,12(DICR)       STORE ZEND'S REGISTERS           76400015
         L     CNTL2,BASOF(CNTL)       LOAD FIRST BASE                  76440015
         L     CNTL3,BASES             LOAD SECOND BASE                 76480015
         MVI   SPILL,X'00'             RECONSTITUTE                     76520015
         MVI   GCCHAN+1,X'00'          REINIT INSTRUCTION               76560015
         L     GRA,NUMFRE              LOAD NO OF FREE TRACK ADDRESSES  76600015
         LTR   GRA,GRA                 TEST IF NUMFRE IS ZERO           76640015
         BC    BZ,NONFRE                YES, OMIT REINITIALISATION      76680015
*                                                                       76720015
         MVC   NUMFRE(4),ZEROS         ZERO NUMFRE                      76760015
         LA    GRA,30                  30 ENTRIES IN FRESLOTS           76800015
         LA    GRB,FRSLOT               POINT AT FREESLOTS              76840015
SLOTFF   MVI   0(GRB),X'FF'            SET SLOT TO NOT USED             76880015
         LA    GRB,3(0,GRB)            BUMP TO NEXT SLOT                76920015
         BCT   GRA,SLOTFF              LOOP IF MORE SLOTS               76960015
*                                                                       77000015
NONFRE   EQU   *                                                        77040015
         MVI   RDBRCH+1,X'10'          INSTRS IN AL                     77080015
         MVI   CONSLD+1,X'F0'          TO MAKE                          77120001
         MVC   CCCOUN(4),ZEROS         SERIALLY REUSABLE                77160015
         MVI   FSWTCH,X'00'            BLK CTL SW FOR K PHASES          77180001
         LM    14,CNTL2,12(DICR)       RETURN TO                        77200015
         BCR   BR,RR                   ZEND                             77240015
         EJECT                                                          77260001
         DCBD  DSORG=(BS),DEVD=DA                                       77280015
         EJECT                                                          77320015
*                                                                       77360015
*              REGISTER EQUATES                                         77400015
*                                                                       77440015
GR0      EQU   0                                                        77480015
GR1      EQU   1                                                        77520015
GR5      EQU   5                                                        77560015
GRA      EQU   1                                                        77600015
GRB      EQU   2                                                        77640015
GRC      EQU   3                                                        77680015
GRD      EQU   4                                                        77720015
GRE      EQU   5                                                        77760015
GRH      EQU   8                                                        77800015
CNTL     EQU   11                                                       77840015
CNTL2    EQU   10                                                       77880015
RR       EQU   14                                                       77920015
CNTL3    EQU   9                                                        77960015
RT       EQU   12                                                       78000015
DICR     EQU   13                                                       78040015
LR       EQU   15                                                       78080015
*                                                                       78120015
*              BRANCH EQUATES                                           78160015
*                                                                       78200015
NOP      EQU   0                                                        78240015
B        EQU   15                                                       78280015
BR       EQU   15                                                       78320015
BH       EQU   2                                                        78360015
BL       EQU   4                                                        78400015
BNL      EQU   11                                                       78440015
BE       EQU   8                                                        78480015
BNE      EQU   7                                                        78520015
BNZ      EQU   7                                                        78560015
BNH      EQU   13                                                       78600015
BO       EQU   1                                                        78640015
BZ       EQU   8                                                        78680015
BM       EQU   4                                                        78720015
BNM      EQU   11                                                       78760015
*              COMMUNICATIONS REGION EQUATES                            78800015
*                                                                       78840015
*                                                                       78880015
TLR      EQU   240                                                      78920015
ZTV      EQU   64                                                       78960015
ZTRAN1   EQU   68                                                       79000015
ZTRAN2   EQU   ZTRAN1+4                                                 79040015
ZNXTD    EQU   76                                                       79080015
ZSTAT    EQU   124                                                      79120015
PAR1     EQU   128                                                      79160015
PAR2     EQU   PAR1+4                                                   79200015
PAR3     EQU   PAR2+4                                                   79240015
PAR4     EQU   PAR3+4                                                   79280015
PAR5     EQU   PAR4+4                                                   79320015
PAR6     EQU   PAR5+4                                                   79360015
PAR7     EQU   PAR6+4                                                   79400015
PAR8     EQU   PAR7+4                                                   79440015
MYNAM    EQU   112                                                      79480015
FSTDIC   EQU   160                                                      79520015
TERMSW   EQU   176                                                      79560015
PARMLEN  EQU   197                                                      79600015
IOERSW   EQU   191                                                      79640015
SPLNAM   EQU   180                                                      79680015
SCNOF    EQU   184                                                      79720015
SECHF    EQU   185                                                      79760015
ZDROLF   EQU   186                                                      79800015
DICTSP   EQU   200                                                      79840015
ZNXTOF   EQU   204                                                      79880015
FONOF    EQU   208                                                      79920015
CCCODE   EQU   232                                                      79960015
ABOTOF   EQU   X'20'                                                    80000015
ZUST     EQU   X'4C'                                                    80040015
ARINT    EQU   248                                                      80080015
ERCODE   EQU   224                                                      80120015
ARMASK   EQU   273                                                      80160015
DICTSZ   EQU   260                                                      80200015
TXTSZ    EQU   264                                                      80240015
ZMASK    EQU   284                                                      80280015
LOCK     EQU   274                                                      80320015
ZSHIFT   EQU   280                                                      80360015
CORLFT   EQU   160                                                      80400015
ZMASK1   EQU   286                                                      80440015
ZPRNAM   EQU   288                                                      80480015
ZDNXT    EQU   96                                                       80520015
PERRSW   EQU   189                                                      80560015
ZSAV     EQU   664                     REGISTER SAVE AREA         33893 80580020
*                                                                       80600015
*              THIS EQUATE IS FOR THE FIRST CARD READ BY THE INITIALISR 80640015
*                                                                       80680015
READSL   EQU   500                                                      80720015
*        TRANSFER VECTOR AND INITIALISATION LIST EQUATES                80760015
*                                                                       80800015
DYNAMOF  EQU   136                                                      80840015
ABORTOF  EQU   32                                                       80880015
DYNSWOF  EQU   88                                                       80920015
ZENDOF   EQU   108                                                      80960015
RDADDOF  EQU   60                                                       81000015
PAROF    EQU   28                                                       81040015
PLDCBOF  EQU   20                                                       81080015
SPDCBOF  EQU   40                                                       81120015
BASOF    EQU   140                                                      81160015
TAB1OF   EQU   64                      TABLE 1 OFFSET             32318 81180020
*                                                                       81200015
UT1OF    EQU   184                                                H319  81220001
         END   IEMAN                                                    81240015
