BN TITLE 'IEMBN - MACRO PROCESSOR - ERROR MESSAGE O/P PHASE, PL/I(F).'  00060013
*                                                                       00120013
*                                                                       00127018
* R18 477600,654000,729000,734400,770400,867000                   23351 00134018
*                                                                       00141018
*                                                                       00148018
*                                                                       00155018
*                                                                       00162018
*                                                                       00169018
IEMBN    START 0                                                        00180013
BN       EQU   IEMBN                                                    00240013
         USING *,XBBASE                                                 00300013
         DC    C'BN'                                                    00360013
*                                                                       00420013
*              FUNCTIONS                                                00480013
*                                                                       00540013
*             (1)   IEMXB IS CALLED BY IEMXA IF THERE ARE DIAGNOSTIC    00600013
*        MESSAGES TO BE PRINTED OUT.                                    00660013
*                                                                       00720013
*             (2)   UPON FIRST BEING CALLED THE ROUTINE SETS A STOPPER  00780013
*        IN A BYTE IMMEDIATELY FOLLOWING THE CHAIN HEADER OF THE LAST   00840013
*        CHAIN TO BE PROCESSED.                                         00900013
*                                                                       00960013
*             (3)   IT THEN SELECTS THE FIRST CHAIN TO BE PROCESSED     01020013
*        AND LOADS THE FIRST BLOCK OF MESSAGE SKELETONS, AS NOTED IN    01080013
*        THE BLOCK USAGE TABLE.                                         01140013
*                                                                       01200013
*             (4)   THE ROUTINE THEN CARRIES OUT THE FIRST PASS DOWN    01260013
*        THE CHAIN, BEFORE WHICH IT CALLS IEMKA TO PRINT OUT A HEADER   01320013
*        APPROPRIATE TO THE SEVERITY GRADE OF THE CHAIN.   DURING A     01380013
*        PASS DOWN A CHAIN ERROR ENTRIES ARE REMOVED FROM THE CHAIN     01440013
*        AS THE CORRESPONDING MESSAGE IS PUT OUT.                       01500013
*                                                                       01560013
*             (5)   UPON COMPLETING A CHAIN PASS IEMXB RETURNS TO THE   01620013
*        MAIN SCAN AND ONCE MORE SEARCHES THE HEADS OF THE ERROR CHAINS 01680013
*        IF IT FINDS IT HAS NO MORE WORK TO DO IT HANDS CONTROL BACK    01740013
*        TO IEMXA.   IF IT FINDS THERE ARE MORE MESSAGES TO PROCESS IT  01800013
*        LOADS THE NEXT REQUIRED BLOCK OF MESSAGES AND CARRIES ON.      01860013
*                                                                       01920013
*             (6)   THE PASS DOWN A CHAIN OF ERROR ENTRIES IN THE       01980013
*        DICTIONARY IS PERFORMED AS FOLLOWS.   TWO REGISTERS, 'LAST'    02040013
*        AND 'JUMP',ARE EMPLOYED AND AT THE OUTSET BOTH OF THESE ARE    02100013
*        POSITIONED AT THE CHAIN HEADER.   THE 'JUMP' REGISTER IS THEN  02160013
*        SET TO REFERENCE THE FIRST ENTRY IN THE CHAIN PROPER.   EACH   02220013
*        TIME THE 'JUMP' REGISTER IS SET TO REFERENCE A NEW CHAIN ENTRY 02280013
*        A TEST IS FIRST OF ALL MADE TO DETERMINE WHETHER OR NOT THIS   02340013
*        ENTRY CORRESPONDS TO A MESSAGE SKELETON RESIDENT IN THE BLOCK  02400013
*        CURRENTLY LOADED.   IF IT DOES SO CORRESPOND, THEN THE ENTRY   02460013
*        IS PROCESSED, AS DESCRIBED BELOW, AND THE MESSAGE IS PUT OUT.  02520013
*        THE PROCESSED ENTRY IS THEN REMOVED FROM THE CHAIN, BY MOVING  02580013
*        THE POINTER TO THE NEXT ENTRY UP TO THE 'LAST' REGISTER, AND   02640013
*        THE 'JUMP' REGISTER MOVES ON TO THE NEXT ENTRY UNLESS THE END  02700013
*        OF THE CHAIN HAS BEEN REACHED.   IF THE TEST REVEALS THAT THE  02760013
*        ENTRY IS NOT TO BE PROCESSED DURING THIS PASS, THEN THE 'LAST' 02820013
*        REGISTER IS MOVED UP TO THE 'JUMP' REGISTER BEFORE THE 'JUMP'  02880013
*        REGISTER MOVES ON TO THE NEXT CHAINED ENTRY.   WHEN ALL        02940013
*        ENTRIES IN THE CHAIN HAVE BEEN PROCESSED THE ALL ZERO CHAIN    03000013
*        STOPPER                                                        03060013
*                                                                       03120013
*             (7)   CHAINS ARE PROCESSED IN DECREASING ORDER OF         03180013
*        SEVERITY UNTIL THE ROUTINE ENCOUNTERS THE STOPPER.   IEMXB     03240013
*        THEN RETURNS CONTROL TO IEMXA.                                 03300013
*                                                                       03360013
*             (8)   WHEN AN ERROR ENTRY IN THE DICTIONARY IS FOUND      03420013
*        CORRESPONDING TO THE MESSAGE SKELETON BLOCK ALREADY LOADED     03480013
*        INTO CORES THE ENTRY IS PROCESSED AS FOLLOWS.                  03540013
*                                                                       03600013
*             (9)   HERE IS A DESCRIPTION OF THE FORMAT OF AN ERROR     03660013
*        ENTRY IN THE DICTIONARY.                                       03720013
*                                                                       03780013
*                 (A)   THE FIRST BYTE IS ORIGINALLY HEX C8.   THIS IS  03840013
*                 CHANGED DURING PROCESSING TO A BYTE CONTAINING A      03900013
*                 LETTER WHICH IDENTIFIES THE BLOCK IN WHICH THE        03960013
*                 CORRESPONDING MESSAGE SKELETON IS TO BE FOUND.        04020013
*                                                                       04080013
*                 (B)   THE NEXT TWO BYTES CONTAIN THE TOTAL LENGTH OF  04140013
*                 THE ENTRY.                                            04200013
*                                                                       04260013
*                 (C)   THE NEXT TWO BYTES CONTAIN A SYMBOLIC CHAIN     04320013
*                 POINTER.                                              04380013
*                                                                       04440013
*                 (D)   THE NEXT TWO BYTES CONTAIN THE MESSAGE NUMBER.  04500013
*                                                                       04560013
*                 (E)   THE NEXT BYTE CONTAINS A WEALTH OF INFORMATION. 04620013
*                                                                       04680013
*                       (1)   THE FIRST BIT IS A ONE IF THERE IS SOURCE 04740013
*                       TEXT ASSOCIATED WITH THIS MESSAGE.              04800013
*                                                                       04860013
*                       (2)   THE SECOND BIT IS A ONE IF THERE IS A     04920013
*                       STATEMENT NUMBER ASSOCIATED WITH THE MESSAGE.   04980013
*                                                                       05040013
*                       (3)   THE THIRD BIT IS A ONE IF THERE IS A      05100013
*                       NUMERIC PARAMETER ASSOCIATED WITH THE MESSAGE.  05160013
*                                                                       05220013
*                       (4)   THE FOURTH BIT IS A ONE IF THERE IS A     05280013
*                       DICTIONARY REFERENCE ASSOCIATED WITH THE        05340013
*                       MESSAGE                                         05400013
*                                                                       05460013
*                       (5)   THE LAST FOUR BITS CONTAIN THE SEVERITY   05520013
*                       CODE                                            05580013
*                                                                       05640013
*                            0000  TERMINAL                             05700013
*                            0100  SEVERE                               05760013
*                            1000  ERROR                                05820013
*                            1100  WARNING                              05880013
*                                                                       05940013
*                 (F)   UP TO SIX BYTES OF INFORMATION MAY FOLLOW.      06000013
*                 THEY CONTAIN                                          06060013
*                                                                       06120013
*                       (1)   A TWO BYTE STATEMENT NUMBER               06180013
*                                                                       06240013
*                       (2)   A TWO BYTE NUMERIC PARAMETER              06300013
*                                                                       06360013
*                       (3)   A TWO BYTE DICTIONARY REFERENCE.          06420013
*                                                                       06480013
*                 AND ANY OR ALL OF THE ABOVE MAY BE MISSING IN ANY     06540013
*                 PARTICULAR MESSAGE.   IF ANY IS MISSING, THE OTHERS   06600013
*                 SHIFT LEFT TO FILL THE GAP.                           06660013
*                                                                       06720013
*                 (G)   IF THERE IS TEXT ASSOCIATED WITH THIS MESSAGE   06780013
*                 IT FOLLOWS THE FIRST PART.   ITS FORMAT IS            06840013
*                                                                       06900013
*                       (1)   A CODE BYTE HEX C8                        06960013
*                                                                       07020013
*                       (2)   A TWO BYTE LENGTH COUNT                   07080013
*                                                                       07140013
*                       (3)   AN INDICATOR BYTE WHICH IS FF IF THE TEXT 07200013
*                       HAS BEEN TRUNCATED AND 00 IF IT HAS NOT.        07260013
*                                                                       07320013
*                       (4)   THE SOURCE TEXT ITSELF.                   07380013
*                                                                       07440013
*                                                                       07500013
*             (10)   WHEN THE 'JUMP' REGISTER IS REFERENCING AN ENTRY   07560013
*        WHICH IS TO BE PROCESSED A TABLE AT THE HEAD OF THE BLOCK OF   07620013
*        MESSAGE SKELETONS IS SCANNED.   THIS TABLE CONSISTS OF         07680013
*        ALTERNATING TWO-BYTE ENTRIES, THE MESSAGE NUMBER FOLLOWED      07740013
*        BY A POINTER TO THE APPROPRIATE SKELETON.                      07800013
*                                                                       07860013
*             (11)   THE FORMAT OF A MESSAGE SKELETON IS AS FOLLOWS     07920013
*                                                                       07980013
*                 (A)   'STANDARD' TEXT IS ASSEMBLED IN, EACH SEGMENT   08040013
*                 BEING PRECEDED BY A TWO BYTE LENGTH COUNT.            08100013
*                                                                       08160013
*                 (B)   EMBEDDED IN THE SKELETON ARE VARIOUS INDICATOR  08220013
*                 BYTES.   THE CONTENT OF THESE BYTES DETERMINES THE    08280013
*                 ROUTINE TO WHICH CONTROL IS TRANSFERRED UPON THEIR    08340013
*                 BEING ENCOUNTERED IN THE MESSAGE SKELETON.   THESE    08400013
*                 BYTES ARE AS FOLLOWS.                                 08460013
*                                                                       08520013
*                       (1)   HEX 00.   THIS IS THE FIRST BYTE OF A     08580013
*                       TWO BYTE LENGTH COUNT, AND IMPLIES STANDARD     08640013
*                       TEXT                                            08700013
*                                                                       08760013
*                       (2)   HEX 04.   THIS IMPLIES THAT A STATEMENT   08820013
*                       NUMBER IS TO BE INSERTED INTO THE OUTPUT        08880013
*                       BUFFER.   IN THE ENGLISH LANGUAGE VERSION THE   08940013
*                       STATEMENT NUMBER IS PRECEDED BY THE WORDS       09000013
*                       'STATEMENT NUMBER'.                             09060013
*                                                                       09120013
*                       (3)   HEX 14.   AS ABOVE, EXCEPT THAT THE       09180013
*                       NUMBER IS FOLLOWED BY SOME TEXT.   THIS IS NOT  09240013
*                       USED IN THE ENGLISH VERSION.                    09300013
*                                                                       09360013
*                       (4)   HEX 0C.   SOURCE TEXT IS TO BE INSERTED   09420013
*                       HERE.   IF THIS SOURCE TEXT IS TRUNCATED IT IS  09480013
*                       PRECEDED BY THE WORD 'BEGINNING' UNLESS THE     09540013
*                       LAST WORD IN THE TEXT ITSELF IS 'BEGINNING'.    09600013
*                                                                       09660013
*                       (5)   HEX 18.   AS ABOVE, EXCEPT THAT THE TEXT  09720013
*                       IS FOLLOWED BY SOME STANDARD PHRASE.   THIS IS  09780013
*                       NOT USED IN THE ENGLISH LANGUAGE VERSION.       09840013
*                                                                       09900013
*                       (6)   HEX 08.   THIS IMPLIES THAT A NUMERIC     09960013
*                       PARAMETER IS TO BE INSERTED.                    10020013
*                                                                       10080013
*                       (7)   HEX 1C.   THIS CAUSES THE BCD CORRESPOND- 10140013
*                       ING TO A DICTIONARY REFERENCE TO BE SLOTTED IN. 10200013
*                                                                       10260013
*                       (8)   HEX 10.   THIS IS THE 'END OF SKELETON'   10320013
*                       BYTE.                                           10380013
*                                                                       10440013
*             (12)   WHEN THE APPROPRIATE MESSAGE SKELETON HAS BEEN     10500013
*        ACCESSED A REGISTER, 'POINT', IS SET TO THE START OF IT.       10560013
*        'POINT' IS THEN MOVED DOWN THE SKELETON AND CONTROL IS         10620013
*        TRANSFERRED TO THE VARIOUS ROUTINES INDICATED BY THE INDICATOR 10680013
*        BYTES.   THE COMPLETED DIAGNOSTIC MESSAGE IS BUILT UP IN AN    10740013
*        OUTPUT AREA, PRECEDED BY ITS IDENTIFICATION NUMBER.   UPON     10800013
*        THE 'POINT' REGISTER FINDING THE END OF MESSAGE BYTE THE       10860013
*        MESSAGE IS PUT OUT.                                            10920013
*                                                                       10980013
*                                                                       11040013
*              ENTRY POINTS                                             11100013
*                                                                       11160013
*              ENTRY TO IEMXB IS FROM COMPILER CONTROL.                 11220013
*                                                                       11280013
*                                                                       11340013
*              INPUT                                                    11400013
*                                                                       11460013
*              INPUT TO IEMXB ARE THE CHAINS OF ERROR MESSAGE ENTRIES   11520013
*        IN THE COMPILER'S DICTIONARY AND THE MESSAGE SKELETON BLOCKS   11580013
*        IEMYB THROUGH IEMYX.                                           11640013
*                                                                       11700013
*                                                                       11760013
*              OUTPUT                                                   11820013
*                                                                       11880013
*              THE OUTPUT FROM IEMXB IS  PRINTED DIAGNOSTIC MESSAGES    11940013
*        ON THE OUTPUT LISTING.                                         12000013
*                                                                       12060013
*                                                                       12120013
*              EXTERNAL ROUTINES                                        12180013
*                                                                       12240013
*              IEMXB MAKES USE OF THE FOLLOWING COMPILER CONTROL        12300013
*        UTILITIES.                                                     12360013
*                                                                       12420013
*              (1)   ZUPL.   TO PRINT OUTPUT.                           12480013
*                                                                       12540013
*              (2)   ZLOAD.   TO LOAD MESSAGE SKELETON BLOCKS.          12600013
*                                                                       12660013
*              (3)   RELESE.   TO RELEASE MESSAGE SKELETON BLOCKS.      12720013
*                                                                       12780013
*              (4)   REQEST.   TO MARK MESSAGE SKELETON BLOCKS WHICH    12840013
*              ARE NOT WANTED                                           12900013
*                                                                       12960013
*              (5)   ZDRFAB.   TO UNSCRAMBLE DICTIONARY REFERENCES      13020013
*                                                                       13080013
*              IT CALLS ALSO A ROUTINE, XA12A, IN IEMXA WHICH PRINTS    13140013
*        OUT HEADINGS FOR THE VARIOUS GRADES OF MESSAGES.               13200013
*                                                                       13260013
*                                                                       13320013
*              EXITS                                                    13380013
*                                                                       13440013
*              THE ONLY EXIT FROM IEMXB IS TO RETURN CONTROL TO IEMXA   13500013
*        ON COMPLETION OF ITS TASK.                                     13560013
*                                                                       13620013
*                                                                       13680013
*              WORK AREA                                                13740013
*                                                                       13800013
*              ALL WORK AREA USED BY IEMXB IS INTERNAL TO ITSELF        13860013
*                                                                       13920013
*                                                                       13980013
*              NOTES                                                    14040013
*                                                                       14100013
*             (1)   ALL ASSEMBLED TEXT IS TRANSLATED INTO COMPILER'S    14160013
*        INTERNAL CODE AND AGAIN INTO EXTERNAL CODE BEFORE BEING        14220013
*        PRINTED.   ANY CHANGE IN THE INTERNAL REPRESENTATION OF        14280013
*        EXTERNAL GRAPHICS CAN BE ACCOMMODATED BY CHANGES TO THE TWO    14340013
*        TRANSLATE TABLES INVOLVED.                                     14400013
*                                                                       14460013
*             (2)   TRANSLATION TO LANGUAGES OTHER THAN ENGLISH.   THE  14520013
*        FORMATS OF BOTH THE TEXT ASSEMBLED INTO THIS MODULE AND THAT   14580013
*        IN THE BLOCKS OF MESSAGE SKELETONS HAVE BEEN DEVISED TO ALLOW  14640013
*        EASY TRANSLATION INTO NATIONAL LANGUAGES.   IT IS NECESSARY    14700013
*        ONLY TO SUBSTITUTE TEXT AS A DEFINED CHARACTER CONSTANT.       14760013
*        INDICATOR BYTES HAVE BEEN RESERVED WHICH MAY BE OF USE IN THIS 14820013
*        CONTEXT.                                                       14880013
*              THIS IS THE ENTRY POINT TO THE MAIN BLOCK OF THE ERROR   14940013
*        EDITOR MECHANISM.                                              15000013
         SPACE                                                          15060013
*              THIS BLOCK IS LOADED IF AND ONLY IF THERE ARE MESSAGES   15120013
*        TO BE PRINTED OUT.   IT IS CALLED AT THE START OF THE OUTPUT   15180013
*        PROCESS, AT WHICH POINT THE REGISTER 'INDEX' CONTAINS A VALUE  15240013
*        WHICH IS FOUR TIMES THE NUMBER OF THE CHAINS TO BE PROCESSED.  15300013
         SPACE                                                          15360013
*              THE FIRST STEP IS TO PLACE A MARKER IN CORES AT THE      15420013
*        FIRST BYTE OF THE FIRST CHAIN HEADER WHICH IS NOT TO BE        15480013
*        PRINTED OUT.   THIS MARKER IS LATER TESTED AND ITS PRESENCE    15540013
*        INHIBITS THE PROCESSING OF THAT CHAIN.                         15600013
         SPACE 2                                                        15660013
         SPACE                                                          15720013
XA8      LA    JUMP,ZERRD(INDEX,GRDIC)                                  15780013
         MVI   0(JUMP),X'FF'                                            15840013
         SPACE 10                                                       15900013
*              THE SO-CALLED 'BLOCK USAGE TABLE', WHICH CONTAINS A LIST 15960013
*        OF THOSE BLOCKS OF MESSAGE SKELETONS WHICH WILL BE REQUIRED    16020013
*        FOR THIS COMPILATION, HAS ALREADY BEEN COMPLETED BY IEMXA      16080013
*        BEFORE THIS BLOCK IS CALLED.   THE OFFSET OF THE BLOCK USAGE   16140013
*        TABLE FROM THE START OF IEMXA IS AVAILABLE AT A KNOWN LOCATION 16200013
*        IN IEMXA.   WE ARRANGE TO REFERENCE THIS TABLE.                16260013
         SPACE 3                                                        16320013
         L     USAGE,XA207(0,GRBASE)                                    16380013
         AR    USAGE,GRBASE                                             16440013
         EJECT                                                          16500013
*              THIS ROUTINE IS THE MAIN SCAN OF IEMXB.   ITS PURPOSE IS 16560013
*        TO INSPECT THE HEADS OF THE ERROR CHAINS IN THE DICTIONARY AND 16620013
*        TO DETERMINE WHETHER OR NOT A NON-EMPTY CHAIN EXISTS WHICH     16680013
*        IS TO BE PROCESSED.                                            16740013
         SPACE 2                                                        16800013
*              IF THE MARKER, INSERTED BY THE INITIALISATION PROCESS    16860013
*        OF THIS BLOCK, IS FOUND AN EXIT IS MADE TO THE TERMINATING     16920013
*        ROUTINE IN IEMXA.                                              16980013
         SPACE                                                          17040013
*              IF A NON-EMPTY CHAIN HEADER IS FOUND THEN A TRANSFER IS  17100013
*        MADE TO THE ROUTINE XA12 WHICH SETS UP THE NECESSARY INITIAL-  17160013
*        ISATION IN PREPARATION FOR PUTTING OUT THE DIAGNOSTIC MESSAGES 17220013
*        CONTAINED IN THIS CHAIN.                                       17280013
XA9      LA    JUMP,ZERRD-1(0,GRDIC)   SET THE JUMPING REGISTER TO THE  17340013
         XR    INDEX,INDEX             START OF THE CHAIN HEADERS AND   17400013
*                                      SCAN ALONG LOOKING FOR THE       17460013
XA10     CLI   1(JUMP),X'FF'           STOPPER OR FOR NON-ZERO CHAIN    17520013
         BC    BE,12(0,GRBASE)         HEADERS ----------------------   17580013
         SPACE                                                          17640013
         CLC   3(2,JUMP),XA205                                          17700013
         BC    BNE,XA12                                                 17760013
         SPACE                                                          17820013
         LA    JUMP,4(0,JUMP)          IF THE CHAIN HEADER IS EMPTY WE  17880013
         LA    INDEX,4(0,INDEX)        GO AND LOOK AT THE NEXT ONE.     17940013
         BC    B,XA10                                                   18000013
         SPACE 5                                                        18060013
*              HERE WE HAVE FOUND A NON ZERO CHAIN HEADER.              18120013
         SPACE                                                          18180013
XA12     CLI   1(JUMP),X'00'           INSPECT THE FIRST BYTE OF THE    18240013
         BC    BNE,XA21                CHAIN HEADER.                    18300013
         SPACE                                                          18360013
         BAL   RR,16(0,GRBASE)                                          18420013
         SPACE                                                          18480013
XA21     LA    USAGE,1(0,USAGE)        SCAN THE REGISTER ALONG THE      18540013
         CLI   0(USAGE),X'00'          BLOCK USAGE TABLE UNTIL A NON-   18600013
         BC    BE,XA21                 ZERO ENTRY IS FOUND.             18660013
         SPACE                                                          18720013
         CLI   0(USAGE),X'FF'          IF THE REGISTER IS REFERENCING   18780013
         BC    BE,XA30                 X'FF' WE HAVE OUTRUN THE TABLE   18840013
*                                      AND WE PRESERVE A DIGNIFIED      18900013
*                                      RESTRAINT FOR THE PRESENT.   WE  18960013
*                                      WILL FIND OUT THE NATURE OF THE  19020013
*                                      ERROR WHEN PROCESSING THE CHAIN. 19080013
         SPACE                                                          19140013
*              HERE WE ARE LOOKING AT A BLOCK NAME.   IS IT LEGAL.      19200013
         SPACE                                                          19260013
         LA    SCAN,XA209              LOOK FOR THE NAME OF THE BLOCK   19320013
XA21A    CLC   0(1,SCAN),0(USAGE)      IN THE VALID TABLE.   IF IT IS   19380013
         BC    BE,XA22                 THERE THEN GO AND LOAD IT.       19440013
         SPACE                                                          19500013
         CLI   0(SCAN),X'FF'           IF THE BLOCK IS NOT IN THE TABLE 19560013
         BC    BE,XA21                 THEN IT IS NOT VALID AND WE WILL 19620013
         LA    SCAN,1(0,SCAN)          NOT TRY TO LOAD IT.   WE SHALL   19680013
         BC    B,XA21A                 FIND OUT THE TROUBLE LATER.   WE 19740013
*                                      GO ON TO GET THE NEXT ONE.       19800013
         SPACE                                                          19860013
*              HERE WE HAVE IDENTIFIED THE NEXT VALID BLOCK TO BE       19920013
*        LOADED.                                                        19980013
         SPACE                                                          20040013
XA22     LA    SCAN,XA204              SET UP TO RELEASE CURRENT BLOCK  20100013
         ST    SCAN,PAR1(0,GRDIC)                                       20160013
         SPACE                                                          20220013
*********************************************************************** 20280013
         SPACE                                                          20340013
         L     LR,RELESE(0,GRCC)       RELEASE THE BLOCK                20400013
         BALR  RR,LR                                                    20460013
         SPACE                                                          20520013
*********************************************************************** 20580013
         SPACE                                                          20640013
*              NONE OF THE MESSAGE BLOCKS HAS BEEN MARKED AS EITHER     20700013
*        'WANTED' OR 'NOT WANTED'.   WE MUST SO ARRANGE THINGS THAT     20760013
*        ANY NOT WANTED BLOCK THAT PRECEDES THE ONE WE ARE JUST ABOUT   20820013
*        TO LOAD IS SO MARKED, AND IS SO MARKED ONLY ONCE.              20880013
         SPACE                                                          20940013
         LA    SCAN,XA210              SCAN ALONG THE BLOCK OF PHASE    21000013
XA23     CLI   1(SCAN),X'00'           NAMES.   IF THE NAME IS ZERO     21060013
         BC    BNE,XA24                THEN IGNORE IT                   21120013
         LA    SCAN,4(0,SCAN)                                           21180013
         BC    B,XA23                                                   21240013
         SPACE                                                          21300013
XA24     CLC   1(1,SCAN),0(USAGE)      IF THE IF THE BLOCK IN THE BLOCK 21360013
         BC    BNL,XA25                LIST PRECEDES THE BLOCK WE ARE   21420013
         ST    SCAN,PAR2(0,GRDIC)      JUST ABOUT TO LOAD WE MARK IT    21480013
         LA    SCAN,2(0,SCAN)          'NOT WANTED'                     21540013
         ST    SCAN,PAR1(0,GRDIC)                                       21600013
         SPACE                                                          21660013
*********************************************************************** 21720013
         SPACE                                                          21780013
         L     LR,REQEST(0,GRCC)       MARK THE BLOCK 'NOT WANTED'.     21840013
         BALR  RR,LR                                                    21900013
         SPACE                                                          21960013
*********************************************************************** 22020013
         SPACE                                                          22080013
         BCTR  SCAN,0                  ENSURE THAT WE DO NOT SO MARK    22140013
         MVI   0(SCAN),X'00'           THE SAME BLOCK AGAIN             22200013
         SPACE                                                          22260013
         LA    SCAN,3(0,SCAN)          BUMP THE SCAN REGISTER AND       22320013
         BC    B,XA23                  CARRY ON LOOKING                 22380013
         SPACE                                                          22440013
*              HERE WE HAVE FOUND THE CORRECT AND LEGAL BLOCK AND ARE   22500013
*        JUST ABOUT TO LOAD IT.                                         22560013
         SPACE                                                          22620013
XA25     MVI   1(SCAN),X'00'                                            22680013
         MVC   XA204+1(1),0(USAGE)     ADJUST THE STANDING LIST TO      22740013
         LA    SCAN,XA204              REFERENCE THE BLOCK AND SET THE  22800013
         ST    SCAN,PAR1(0,GRDIC)      PARAMETER SLOT TO LOAD IT.       22860013
         SPACE                                                          22920013
*********************************************************************** 22980013
         SPACE                                                          23040013
         L     LR,ZLOAD(0,GRCC)        LOAD THE NEXT BLOCK              23100013
         BALR  RR,LR                                                    23160013
         SPACE                                                          23220013
*********************************************************************** 23280013
         SPACE                                                          23340013
         L     BLKHED,PAR1(0,GRDIC)    AND BASE THE BLOCK JUST LOADED   23400013
         EJECT                                                          23460013
*              THE POSITION NOW IS THAT THE JUMP REGISTER IS LOOKING    23520013
*        AT A CHAIN HEADER AND WE ARE ABOUT TO GO DOWN THE CHAIN        23580013
*        LOOKING FOR ENTRIES                                            23640013
         SPACE 3                                                        23700013
         MVC   XA233(2),XA205          ARRANGE FOR THE DICTIONARY BLOCK 23760013
*                                      LOCKING SLOT TO BE SET TO ZERO.  23820013
         SPACE                                                          23880013
XA30     LR    LAST,JUMP               REMEMBER THE PRESENT POSITION    23940013
*                                      IN THE CHAIN.                    24000013
         SPACE                                                          24060013
         MVC   ZLOCK(2,GRDIC),XA233    SET THE LOCKING SLOT TO ENSURE   24120013
*                                      THAT THE DICTIONARY BLOCK        24180013
*                                      WHICH CONTAINS THE LAST ENTRY    24240013
*                                      IS NOT SPILLED                   24300013
         SPACE                                                          24360013
*              WE NOW SET THE JUMP REGISTER TO THE NEXT AND REMEMBER    24420013
*        ITS SYMBOLIC DICTIONARY ENTRY.                                 24480013
         SPACE                                                          24540013
         MVC   XA233(2),3(JUMP)        REMEMBER THE DICTIONARY          24600013
*                                      REFERENCE.                       24660013
         SPACE                                                          24720013
         MVC   PAR1+2(2,GRDIC),3(JUMP)   SET UP THE SYMBOLIC REFERENCE  24780013
         SPACE                                                          24840013
*********************************************************************** 24900013
         SPACE                                                          24960013
         L     LR,ZDRFAB(0,GRCC)         GET COMPILER CONTROL TO        25020013
         BALR  RR,LR                     UNSCRAMBLE THE REFERENCE       25080013
         SPACE                                                          25140013
*********************************************************************** 25200013
         SPACE                                                          25260013
         L     JUMP,PAR1(0,GRDIC)      POINT THE JUMP REGISTER AT THE   25320013
*                                      ENTRY WE ARE JUST ABOUT TO DEAL  25380013
*                                      WITH.                            25440013
         SPACE                                                          25500013
*              IN ANY EVENT WE WANT THE MESSAGE NUMBER SLOTTED INTO     25560013
*        THE OUTPUT BUFFER.                                             25620013
         SPACE                                                          25680013
         MVC   XA202+4(4),XA214        MOVE 'IEM' IN INTERNAL CODE      25740013
*                                      INTO THE MESSAGE.                25800013
         SPACE                                                          25860013
         XC    XA211(4),XA211           CLEAR CONVERT AREA TO ZERO      25920013
         MVC   XA211+2(2),5(JUMP)      CONVERT THE NUMBER AND UNPACK    25980013
         L     SCRTCH,XA211            IT                               26040013
         CVD   SCRTCH,XA212                                             26100013
         UNPK  XA212(4),XA212(8)                                        26160013
         SPACE                                                          26220013
         OI    XA212+3,X'F0'           CLEAR ZONE                       26280013
         SPACE                                                          26340013
XA32     MVC   XA202+7(4),XA212        MOVE THE NUMBER TO THE OUTPUT    26400013
*                                      BUFFER.                          26460013
         SPACE                                                          26520013
         MVI   XA202+11,C'I'           MOVE I INTO                      26580013
*                                      THE BUFFER TO FOLLOW THE NUMBER  26640013
         SPACE                                                          26700013
         MVC   XA202+12(3),XA215       MOVE IN THREE BLANKS AFTER THE   26760013
*                                      NUMBER.                          26820013
         SPACE                                                          26880013
         MVI   XA202+14,X'FF'          FAKE UP A NON-BLANK AT THE START 26940013
*                                      OF THE PRINT LINE                27000013
         MVI   XA200,X'00'                                              27060013
         MVI   XA200+1,X'0F'           SET INITIAL LENGTH COUNT TO      27120013
*                                      FIFTEEN                          27180013
         SPACE                                                          27240013
         LA    BUFFER,XA202+15         SET BUFFER REGISTER TO REFERENCE 27300013
*                                      THE NEXT BUFFER POSITION.        27360013
         SPACE                                                          27420013
*********************************************************************** 27480013
*********************************************************************** 27540013
         SPACE                                                          27600013
*              WE NOW GO OFF TO A ROUTINE WHICH INSPECTS THE MESSAGE    27660013
*        BLOCK NUMBER FOR LEGALITY.                                     27720013
         SPACE                                                          27780013
*              IF WE RETURN FROM THIS ROUTINE WE HAVE A NICE LEGAL      27840013
*        MESSAGE TO PUT OUT, OR NOT.                                    27900013
         SPACE                                                          27960013
         BC    B,XA150                                                  28020013
         SPACE                                                          28080013
*********************************************************************** 28140013
*********************************************************************** 28200013
         SPACE                                                          28260013
XA33     CLC   0(1,JUMP),0(USAGE)      IF THE BLOCK IDENTIFICATION AT   28320013
         BC    BE,XA34                 THE HEAD OF THE CHAIN ENTRY DOES 28380013
*                                      NOT CORRESPOND WITH THAT OF THE  28440013
*                                      BLOCK CURRENTLY REFERENCED THEN  28500013
         CLC   XA205(2),3(JUMP)        WE MUST LEAVE THE ENTRY IN THE   28560013
         BC    BE,XA9                  CHAIN READY FOR THE NEXT PASS    28620013
         BC    B,XA30                  THROUGH.   IF ITS CHAIN POINTER  28680013
*                                      IS ZERO WE HAVE FINISHED THIS    28740013
*                                      PASS.                            28800013
         SPACE                                                          28860013
*              HERE WE ARE ABOUT TO PROCESS A MESSAGE OF THE CURRENT    28920013
*        BLOCK.   WE TRY TO FIND THE MESSAGE.                           28980013
         SPACE                                                          29040013
XA34     LA    POINT,2(BLKHED)                                          29100013
         SPACE                                                          29160013
         CLC   0(2,POINT),5(JUMP)      COMPARE EACH MESSAGE NUMBER IN   29220013
         BC    BE,XA36-6               THE BLOCK HEADER TABLE WITH THE  29280013
*                                      NUMBER OF THE CURRENT MESSAGE    29340013
         SPACE                                                          29400013
         CLI   0(POINT),X'FF'          IF IT IS NOT THE NUMBER OF THE   29460013
         BC    BE,XA35                 CURRENT MESSAGE THEN CHECK       29520013
         LA    POINT,4(0,POINT)        WHETHER WE HAVE OUTRUN THE TABLE 29580013
         BC    B,XA34+4                IF NOT, GO ROUND AGAIN.          29640013
         SPACE 5                                                        29700013
*              HERE WE HAVE OUTRUN THE TABLE AND CANNOT FIND THE        29760013
*        MESSAGE SKELETON IN ITS STATED BLOCK.                          29820013
         SPACE                                                          29880013
XA35     MVC   XA801(1),0(JUMP)        SLOT THE CURRENT BLOCK IDENT-    29940013
*                                      IFICATION INTO THE COMPILER      30000013
*                                      DEBUGGING MESSAGE                30060013
         SPACE                                                          30120013
         XR    SCRTCH,SCRTCH           MOVE THE MESSAGE INTO THE        30180013
         IC    SCRTCH,XA800            OUTPUT AREA AND TRANSLATE IT     30240013
         STC   SCRTCH,*+5              TO INTERNAL CODE.                30300013
         MVC   0(0,BUFFER),XA800+1                                      30360013
         SPACE                                                          30420013
         AH    SCRTCH,XA200            UPDATE THE LENGTH COUNT AND PUT  30480013
         STH   SCRTCH,XA200            OUT THE MESSAGE                  30540013
         BC    B,XA40-4                                                 30600013
         SPACE 5                                                        30660013
*              HERE WE HAVE FOUND THE CORRECT MESSAGE NUMBER.   WE SET  30720013
*        A REGISTER TO THE HEAD OF THE MESSAGE SKELETON AND START TO    30780013
*        BUILD UP THE MESSAGE IN THE OUTPUT REGION                      30840013
         SPACE                                                          30900013
         LH    POINT,2(0,POINT)        SET THE POINT REGISTER TO THE    30960013
         AR    POINT,BLKHED            START OF THE MESSAGE             31020013
         SPACE                                                          31080013
*              HERE POINT IS REFERENCING SOME INDICATOR BYTE IN THE     31140013
*        MESSAGE SKELETON.                                              31200013
         SPACE                                                          31260013
XA36     LA    SCRTCH,XA230            TEST THE INDICATOR BYTE AGAINST  31320013
         CLC   0(1,POINT),0(SCRTCH)    A LIST OF VALID INDICATOR BYTES. 31380013
         BC    BE,XA36A                                                 31440013
         CLI   0(SCRTCH),X'FF'         IF WE ARRIVE AT THE END OF THE   31500013
         BC    BE,*+12                 LIST WITHOUT HAVING FOUND OUR    31560013
         LA    SCRTCH,1(0,SCRTCH)      BYTE WE ARE ALL AT SEA AND MUST  31620013
         BC    B,XA36+4                SAY SO.                          31680013
         SPACE                                                          31740013
*              HERE WE HAVE FOUND AN INVALID INDICATOR BYTE             31800013
         SPACE                                                          31860013
         XR    SCRTCH,SCRTCH           MOVE A COMPLAINT INTO THE        31920013
         IC    SCRTCH,XA870            OUTPUT BUFFER AND GO TO PRINT    31980013
         STC   SCRTCH,*+5              OUT THE MESSAGE.                 32040013
         MVC   0(0,BUFFER),XA870+1                                      32100013
         SPACE                                                          32160013
         AH    SCRTCH,XA200            UPDATE THE LENGTH COUNT.         32220013
         STH   SCRTCH,XA200                                             32280013
         BC    B,XA40-4                                                 32340013
         SPACE                                                          32400013
XA36A    XR    SCRTCH,SCRTCH           CARRY OUT AN INDEXED BRANCH TO   32460013
         IC    SCRTCH,0(0,POINT)       THE ROUTINE AS DETERMINED BY     32520013
         BC    B,XA37(SCRTCH)          THE INDICATOR BYTE IN THE        32580013
*                                      MESSAGE SKELETON.                32640013
         SPACE 3                                                        32700013
*        THE NEXT QUOTED BLOCK.                                         32760013
XA37     BC    B,XA50                  STANDARD TEXT                    32820013
         SPACE                                                          32880013
         BC    B,XA70                  STATEMENT NUMBER PRECEDED BY     32940013
*                                      ASSEMBLED TEXT                   33000013
         SPACE                                                          33060013
         BC    B,XA90                  NUMERIC PARAMETER                33120013
         SPACE                                                          33180013
         BC    B,XA110                 SOURCE TEXT PERHAPS PRECEDED BY  33240013
*                                      ASSEMBLED TEXT                   33300013
         SPACE                                                          33360013
         BC    B,XA40-4                END OF MESSAGE                   33420013
         SPACE                                                          33480013
         BC    B,XA70                  STATEMENT NUMBER FOLLOWED BY     33540013
*                                      ASSEMBLED TEXT                   33600013
         SPACE                                                          33660013
         BC    B,XA110                 SOURCE TEXT PERHAPS FOLLOWED BY  33720013
*                                      ASSEMBLED TEXT                   33780013
         SPACE                                                          33840013
         BC    B,XA130                 DICTIONARY REFERENCE             33900013
         SPACE 3                                                        33960013
*              HERE WE HAVE COMPLETED THE CONSTRUCTION OF THE MESSAGE   34020013
*        WHICH IS IN THE OUTPUT BUFFER IN INTERNAL CODE.                34080013
         SPACE                                                          34140013
         MVI   XA208,X'00'             RESET THE 'DID I SEE A MESSAGE'  34200013
*                                      SWITCH                           34260013
         SPACE                                                          34320013
XA40     MVI   XA202+14,X'40'          RESET THE FAKED UP NON-BLANK     34380013
         SPACE                                                          34440013
         LH    SCRTCH,XA200            IF THE LENGTH OF THE TEXT IS     34500013
         C     SCRTCH,XA226            MORE THAN 116 CHARACTERS WE HAVE 34560013
         BC    BH,XA44                 SOME ADJUSTMENT TO MAKE.         34620013
         SPACE                                                          34680013
*              HERE WE ARE JUST ABOUT TO PRINT OUT A LINE.              34740013
         SPACE                                                          34800013
XA41     L     POINT,ZTRAN2(0,GRDIC)   TRANSLATE THE LINE TO EXTERNAL   34860013
         SPACE                                                          34920013
         LA    POINT,XA200                                              34980013
         ST    POINT,PAR1(0,GRDIC)                                      35040013
         SPACE                                                          35100013
*********************************************************************** 35160013
         SPACE                                                          35220013
         L     LR,ZUPL(0,GRCC)                                          35280013
         BALR  RR,LR                                                    35340013
         SPACE                                                          35400013
*********************************************************************** 35460013
         SPACE                                                          35520013
         C     SCRTCH,XA226                                             35580013
         BC    BNH,XA45                                                 35640013
         SPACE                                                          35700013
*              HERE WE HAVE NOT YET FINISHED.                           35760013
         SPACE                                                          35820013
         SH    SCRTCH,XA200            GET INTO SCRATCH THE QUANTITY    35880013
*                                      OF TEXT TO BE MOVED              35940013
         SPACE                                                          36000013
         LR    HELP,SCRTCH             PUT THE LENGTH OF TEXT TO BE     36060013
         LA    POINT,XA202+15          MOVED INTO A REGISTER            36120013
         SPACE                                                          36180013
*              THE POINT REGISTER ADDRESSES THE REGION TO WHICH THE     36240013
*        TEXT IS TO BE MOVED AND THE BUFFER REGISTER IS REFERENCING     36300013
*        THE NEXT BIT OF TEXT TO BE PUT OUT.                            36360013
         SPACE                                                          36420013
XA42     C     HELP,XA228              IF THE LENGTH OF TEXT TO BE      36480013
         BC    BNH,XA43                MOVED IS MORE THAN 256 BYTES.    36540013
         SPACE                                                          36600013
         MVC   0(256,POINT),0(BUFFER)  HERE WE ARE MOVING 256 BYTES     36660013
         LA    POINT,256(0,POINT)      OF TEXT ALONG THE OUTPUT AREA    36720013
         LA    BUFFER,256(0,BUFFER)    AND RESETING REGISTERS.          36780013
         S     HELP,XA228                                               36840013
         BC    B,XA42                                                   36900013
         SPACE                                                          36960013
XA43     LTR   HELP,HELP                                                37020013
         BC    BE,*+16                                                  37080013
         BCTR  HELP,0                                                   37140013
         STC   HELP,*+5                                                 37200013
         MVC   0(0,POINT),0(BUFFER)                                     37260013
         SPACE                                                          37320013
         MVC   XA202(15),XA229         OBLITERATE THE ADMINISTRATIVE    37380013
*                                      MESSAGE IDENTIFICATION           37440013
         SPACE                                                          37500013
         LA    SCRTCH,15(0,SCRTCH)     ALLOW FOR THE EXTRA LENGTH IN    37560013
*                                      THE SCRATCH REGISTER.            37620013
         SPACE                                                          37680013
         C     SCRTCH,XA226            CHECK THE LENGTH OF TEXT         37740013
         BC    BH,XA44                 REMAINING.                       37800013
         SPACE                                                          37860013
*              HERE WE HAVE ONLY ONE MORE LINE OF TEXT.                 37920013
         SPACE                                                          37980013
         STH   SCRTCH,XA200            PUT IN THE LENGTH COUNT AND      38040013
         BC    B,XA41                  GO TO PRINT OUT THE LINE.        38100013
         SPACE                                                          38160013
*              HERE WE HAVE AN OVERLONG LENGTH OF TEXT.                 38220013
         SPACE                                                          38280013
XA44     LA    BUFFER,XA202            POINT THE BUFFER REGISTER        38340013
         A     BUFFER,XA226            AT THE FIRST BYTE WE WILL NOT    38400013
*                                      PUT OUT.                         38460013
         SPACE                                                          38520013
         BCTR  BUFFER,0                MOVE BACK THE BUFFER POINTER     38580013
         CLI   0(BUFFER),X'40'         UNTIL WE FIND THE RIGHTMOST      38640013
         BC    BNE,*-6                 BLANK                            38700013
         SPACE                                                          38760013
         LA    BUFFER,1(0,BUFFER)      SET THE BUFFER POINTER TO THE    38820013
*                                      FIRST NON-BLANK                  38880013
         SPACE                                                          38940013
         LR    HELP,BUFFER             SET UP THE LENGTH COUNT FOR      39000013
         LA    POINT,XA202             THIS SECTION OF TEXT.            39060013
         SR    HELP,POINT                                               39120013
         STH   HELP,XA200                                               39180013
         SPACE                                                          39240013
         BC    B,XA41                  GO AND PRINT THE LINE.           39300013
*              WE HAVE COMPLETED ACTION ON THIS MESSAGE AND WE ARE      39360013
*        ABOUT TO EXTRACT IT FROM THE CHAIN                             39420013
         SPACE                                                          39480013
XA45     MVC   3(2,LAST),3(JUMP)       EXTRACT THE ENTRY FROM THE CHAIN 39540013
         SPACE                                                          39600013
         CLC   XA205,3(JUMP)           IF WE ARE AT THE END OF A PASS   39660013
         BC    BNE,XA30+8              THROUGH A CHAIN WE GO TO RE-     39720013
         BC    B,XA9                   INITIALISE THE PROCESS.   IF NOT 39780013
*                                      WE FORGE ON.                     39840013
         EJECT                                                          39900013
*              THIS ROUTINE SLOTS STANDARD TEXT FROM THE MESSAGE        39960013
*        SKELETON INTO THE OUTPUT BUFFER AND TRANSLATES IT TO INTERNAL  40020013
*        CODE.                                                          40080013
         SPACE 3                                                        40140013
XA50     XR    SCRTCH,SCRTCH           GET THE LENGTH COUNT OF THE      40200013
         IC    SCRTCH,1(0,POINT)       TEXT INTO A SCRATCH REGISTER     40260013
         SPACE                                                          40320013
         STC   SCRTCH,*+5                                               40380013
         MVC   0(0,BUFFER),2(POINT)    MOVE IN THE TEXT AND TRANSLATE   40440013
         SPACE                                                          40500013
         SPACE                                                          40560013
         LA    POINT,2(SCRTCH,POINT)   BUMP THE POINT REGISTER OVER     40620013
*                                      THE TEXT AND LENGTH COUNT.       40680013
XA51     CLI   0(BUFFER),X'40'         LOOK TO SEE IF THE FIRST         40740013
         BC    BNE,XA52                CHARACTER IS A BLANK.            40800013
         SPACE                                                          40860013
         BCTR  SCRTCH,0                IF IT IS WE DEVOTE A LITTLE      40920013
         STC   SCRTCH,*+5              TIME TO GETTING RID OF IT AND    40980013
         MVC   0(0,BUFFER),1(BUFFER)   ALSO ANY BLANKS WHICH FOLLOW.    41040013
         BC    B,XA51                                                   41100013
         SPACE                                                          41160013
XA52     EQU   *                                                        41220013
         AR    BUFFER,SCRTCH           MOVE BUFFER POINTER OVER THE     41280013
*                                      NEW TEXT                         41340013
XA52A    BCTR  BUFFER,0                RESET BUFFER TO BYTE AFTER LAST  41400013
         BCTR  SCRTCH,0                NON BLANK CHARACTER OF TEXT.     41460013
         CLI   0(BUFFER),X'40'                                          41520013
         BC    BE,XA52A                                                 41580013
         LA    BUFFER,1(0,BUFFER)                                       41640013
         LA    SCRTCH,1(0,SCRTCH)                                       41700013
         SPACE                                                          41760013
         AH    SCRTCH,XA200            UPDATE THE LENGTH COUNT AND GO   41820013
         STH   SCRTCH,XA200            BACK.                            41880013
         BC    B,XA36                                                   41940013
         EJECT                                                          42000013
*              THIS ROUTINE SLOTS A STATEMENT NUMBER INTO THE OUTPUT    42060013
*        BUFFER.                                                        42120013
         SPACE                                                          42180013
*              THIS NUMBER MAY BE PRECEDED BY OR FOLLOWED BY ASSEMBLED  42240013
*        TEXT DEPENDING ON WHICH INDICATOR BYTE IS CURRENTLY REFERENCED 42300013
*        BY THE POINT REGISTER.                                         42360013
         SPACE                                                          42420013
XA70     TM    7(JUMP),X'40'           WE FIRST DETERMINE WHETHER OR    42480013
         BC    BZ,XA76                 NOT THE 'STATEMENT NUMBER' BIT   42540013
*                                      IN THE CODE BYTE OF THE CHAIN    42600013
*                                      ENTRY IS ON.                     42660013
         SPACE                                                          42720013
*              HERE WE ARE OK AND CAN SLOT IN THE NUMBER.               42780013
         SPACE                                                          42840013
         CLI   0(POINT),X'04'          DO WE REQUIRE ASSEMBLED TEXT     42900013
         BC    BNE,XA71                FIRST                            42960013
         SPACE                                                          43020013
*              HERE WE ARE TO SLOT IN THE ASSEMBLED TEXT FIRST.         43080013
         SPACE                                                          43140013
XA70A    LH    SCRTCH,XA200                                             43200013
         BCTR  BUFFER,0                                                 43260013
         BCTR  SCRTCH,0                                                 43320013
         CLI   0(BUFFER),X'40'         TO THE FIRST NON-BLANK.          43380013
         BC    BE,XA70A                                                 43440013
         LA    BUFFER,1(0,BUFFER)                                       43500013
         LA    SCRTCH,1(0,SCRTCH)                                       43560013
         STH   SCRTCH,XA200                                             43620013
         SPACE                                                          43680013
         XR    SCRTCH,SCRTCH                                            43740013
         IC    SCRTCH,XA900            GET THE LENGTH COUNT INTO A      43800013
         STC   SCRTCH,*+5              SCRATCH REGISTER AND MOVE THE    43860013
         MVC   0(0,BUFFER),XA900+1     ASSEMBLED TEXT INTO THE OUTPUT   43920013
*                                      AREA                             43980013
         SPACE                                                          44040013
         SPACE                                                          44100013
         AR    BUFFER,SCRTCH           BUMP THE BUFFER POINTER OVER     44160013
         AH    SCRTCH,XA200            THE ASSEMBLED TEXT AND UPDATE    44220013
         STH   SCRTCH,XA200            THE LENGTH COUNT.                44280013
         SPACE                                                          44340013
*              NOW SLOT IN THE NUMBER.                                  44400013
         SPACE                                                          44460013
         BC    B,XA72                                                   44520013
XA71     MVI   0(BUFFER),X'40'         IF THE ASSEMBLED TEXT IS TO      44580013
         LA    BUFFER,1(0,BUFFER)      FOLLOW THE NUMBER WE MUST SLOT   44640013
         LA    SCRTCH,XA200            IN A BLANK TO PRECEDE IT.   THIS 44700013
         LA    SCRTCH,1(0,SCRTCH)      IS IN COMPILER INTERNAL CODE.    44760013
         STH   SCRTCH,XA200            WE READJUST THE COUNTS, ETC.     44820013
         SPACE                                                          44880013
XA72     MVC   XA211+2(2),8(JUMP)      PUT NUMBER INTO SCRATCH          44940013
         MVC   XA211(2),XA205                                           45000013
         L     SCRTCH,XA211          REGISTER AND CONVERT IT TO DECIMAL 45060013
         CVD   SCRTCH,XA212                                             45120013
         UNPK  XA212(4),XA212(8)                                        45180013
         OI    XA212+3,X'F0'           CLEAR ZONE                       45240013
         SPACE                                                          45300013
         LA    HELP,XA212+4            SET TWO REGISTERS TO SPAN THE    45360013
         LA    SCRTCH,XA212            NUMBER AND SCAN UP THE LEFTMOST  45420013
XA73     CLI   0(SCRTCH),X'F0'         ONE TO ELINMINATE LAEDING ZEROS  45480013
         BC    BNE,XA73A                                                45540013
         LA    SCRTCH,1(0,SCRTCH)                                       45600013
         BC    B,XA73                                                   45660013
         SPACE                                                          45720013
XA73A    CR    SCRTCH,HELP             IF THE NUMBER WAS ZERO WE WILL   45780013
         BC    BL,XA74                 HAVE OVERSHOT                    45840013
         SPACE                                                          45900013
         MVC   0(7,BUFFER),UN                                           45960013
         LA    HELP,7                                                   46020013
         BC    B,XA74A                                                  46080013
UN       DC    C'UNKNOWN'                                               46140013
         SPACE                                                          46200013
XA74     SR    HELP,SCRTCH             MOVE THE NUMBER (IN INTERNAL     46260013
         STC   HELP,*+5                CODE) INTO THE OUTPUT BUFFER     46320013
         MVC   0(0,BUFFER),0(SCRTCH)                                    46380013
         SPACE                                                          46440013
XA74A    AR    BUFFER,HELP             BUMP THE BUFFER POINTER OVER     46500013
*                                      THE NUMBER                       46560013
         SPACE                                                          46620013
         AH    HELP,XA200              UPDATE THE LENGTH COUNT          46680013
         STH   HELP,XA200                                               46740013
         SPACE                                                          46800013
         CLI   0(POINT),X'04'          IF WE HAVE PRECEDED THE NUMBER   46860013
         BC    BNE,XA75                BY ASSEMBLED TEXT WE NEED A      46920013
         MVI   0(BUFFER),X'40'         BLANK TO FOLLOW IT SO WE SLOT    46980013
         LA    BUFFER,1(0,BUFFER)      ONE IN, UPDATE COUNTS AND GO     47040013
         LH    HELP,XA200              BACK                             47100013
         LA    HELP,1(0,HELP)                                           47160013
         STH   HELP,XA200                                               47220013
         LA    POINT,1(0,POINT)                                         47280013
         BC    B,XA36                                                   47340013
         SPACE                                                          47400013
*              HERE WE MOVE ASSEMBLED TEXT IN AFTER THE NUMBER.         47460013
XA75     XR    SCRTCH,SCRTCH                                            47520013
         IC    SCRTCH,XA905            GET THE LENGTH OF THE TEXT INTO  47580013
         STC   SCRTCH,*+5              A REGISTER, MOVE IN THE          47640013
         MVC   0(0,BUFFER),XA905+1     ASSEMBLED TEXT AND TRANSLATE IT  47700013
         SPACE                                                          47760013
XA755    DS    0H                      (ENTRY POINT FOR ERROR     23351 47780018
*                                    RECOVERY)                    23351 47800018
         AR    BUFFER,SCRTCH           BUMP THE BUFFER POINTER          47820013
         SPACE                                                          47880013
         AH    SCRTCH,XA200            ADJUST THE LENGTH COUNT          47940013
         STH   SCRTCH,XA200                                             48000013
         SPACE                                                          48060013
         LA    POINT,1(0,POINT)        BUMP THE POINT REGISTER AND      48120013
         BC    B,XA36                  GO BACK.                         48180013
         SPACE 5                                                        48240013
*********************************************************************** 48300013
*********************************************************************** 48360013
         SPACE                                                          48420013
*              HERE THERE IS A REQUEST FOR A STATEMENT NUMBER TO BE     48480013
*        SLOTTED INTO THE MESSAGE, AND ALAS THERE IS NO NUMBER IN THE   48540013
*        CHAIN ENTRY.                                                   48600013
         SPACE                                                          48660013
XA76     LA    SCRTCH,XA830                                             48720013
         BC    B,XA95A                                                  48780013
         SPACE                                                          48840013
*********************************************************************** 48900013
*********************************************************************** 48960013
         EJECT                                                          49020013
*              THIS ROUTINE SLOTS A NUMERIC PARAMETER INTO THE OUTPUT   49080013
*        BUFFER.                                                        49140013
         SPACE                                                          49200013
XA90     TM    7(JUMP),X'20'           TEST WHETHER OR NOT THE NUMERIC  49260013
         BC    BZ,XA95                 PARAMETER BIT IS ON IN THE CHAIN 49320013
*                                      ENTRY.                           49380013
         SPACE                                                          49440013
*              THE NUMERIC PARAMETER BIT IS ON AND WE CAN PROCEED.      49500013
         SPACE                                                          49560013
         TM    7(JUMP),X'40'           TEST THE STATEMENT NUMBER BIT.   49620013
         BC    BO,XA91                                                  49680013
         SPACE                                                          49740013
*              HERE THE STATEMENT NUMBER BIT IS NOT ON AND THE OFFSET   49800013
*        OF THE NUMERIC PARAMETER IS EIGHT.                             49860013
         SPACE                                                          49920013
         MVC   XA211+2(2),8(JUMP)      MOVE THE NUMBER READY FOR        49980013
         BC    B,XA92                  CONVERSION                       50040013
         SPACE                                                          50100013
*              HERE THE STATEMENT NUMBER BIT IS ON AND THE OFFSET OF    50160013
*        THE NUMERIC PARAMETER IS TEN.                                  50220013
         SPACE                                                          50280013
XA91     MVC   XA211+2(2),10(JUMP)     MOVE IN THE NUMBER               50340013
         SPACE                                                          50400013
*              HERE WE ARE ABOUT TO CONVERT THE NUMBER                  50460013
         SPACE                                                          50520013
XA92     MVC   XA211(2),XA205                                           50580013
         L     SCRTCH,XA211            LOAD SCRTCH WITH THE NUMBER,     50640013
         CVD   SCRTCH,XA212            CONVERT IT AND WORK IT INTO      50700013
         UNPK  XA212(4),XA212(8)       COMPILER INTERNAL CODE.          50760013
         OI    XA212+3,X'F0'           CLEAR ZONE                       50820013
         SPACE                                                          50880013
         LA    HELP,XA212+4            SET TWO REGISTERS TO SPAN THE    50940013
         LA    SCRTCH,XA212            NUMBER AND SCAN THE LEFTMOST     51000013
XA93     CLI   0(SCRTCH),X'F0'         ONE ALONG ELIMINATE LEADING      51060013
         BC    BNE,XA93A               ZEROS.                           51120013
         LA    SCRTCH,1(0,SCRTCH)                                       51180013
         BC    B,XA93                                                   51240013
         SPACE                                                          51300013
XA93A    CR    SCRTCH,HELP             IF THE NUMBER WAS ZERO WE WILL   51360013
         BC    BL,XA94                 HAVE OVERSHOT                    51420013
         SPACE                                                          51480013
         LR    SCRTCH,HELP             SET THINGS UP AS IF WE HAD       51540013
         BCTR  SCRTCH,0                STOPPED LOOKING AT A SINGLE ZERO 51600013
         SPACE                                                          51660013
XA94     SR    HELP,SCRTCH                                              51720013
         MVI   0(BUFFER),X'40'         MOVE THE NUMBER INTO THE OUTPUT  51780013
         STC   HELP,*+5                AREA WITH A BLANK (IN INTERNAL   51840013
         MVC   1(0,BUFFER),0(SCRTCH)   CODE) FORE AND AFT.              51900013
         AR    BUFFER,HELP                                              51960013
         MVI   1(BUFFER),X'40'         BUMP THE BUFFER POINTER OVER     52020013
         LA    BUFFER,2(0,BUFFER)      THE INSERT.                      52080013
         SPACE                                                          52140013
         AH    HELP,XA200              UPDATE THE LENGTH COUNT.         52200013
         LA    HELP,2(0,HELP)                                           52260013
         STH   HELP,XA200                                               52320013
         SPACE                                                          52380013
         LA    POINT,1(0,POINT)        BUMP THE POINT REGISTER OVER     52440013
         BC    B,XA36                  THE INDICATOR BYTE AND GO ON     52500013
         SPACE 5                                                        52560013
*********************************************************************** 52620013
*********************************************************************** 52680013
         SPACE                                                          52740013
*              HERE THERE IS A REQUEST FOR A NUMERIC PARAMETER AND      52800013
*        NONE HAS BEEN SUPPLIED.                                        52860013
         SPACE                                                          52920013
XA95     LA    SCRTCH,XA860                                             52980013
XA95A    XR    HELP,HELP                                                53040013
         IC    HELP,0(SCRTCH)                                           53100013
         MVI   0(BUFFER),X'40'         ADD A BLANK TO MESSAGE.          53160013
         STC   HELP,*+5                                                 53220013
         MVC   1(0,BUFFER),1(SCRTCH)   ADD ERROR INDICATING INSERT.     53280013
         LA    HELP,1(0,HELP)                                           53340013
         AR    BUFFER,HELP             UPDATE BUFFER POINTER.           53400013
         AH    HELP,XA200              UPDATE MESSAGE LENGTH.           53460013
         STH   HELP,XA200                                               53520013
         LA    POINT,1(0,POINT)                                         53580013
         BC    B,XA36                                                   53640013
         EJECT                                                          53700013
*              THIS ROUTINE SLOTS PROGRAMMER'S TEXT INTO THE OUTPUT     53760013
*        AREA.                                                          53820013
         SPACE                                                          53880013
*              THIS TEXT MAY BE EITHER PRECEDED BY OR FOLLOWED BY       53940013
*        ASSEMBLED TEXT IN THE EVENT THAT THE SOURCE PROGRAMMER'S TEXT  54000013
*        HAS BEEN TRUNCATED.   THE APPEARANCE OR OTHERWISE OF THE       54060013
*        ASSEMBLED TEXT IS DEPENDENT ON WHETHER OR NOT THE MESSAGE      54120013
*        SKELETON CONTAINS THE SAME TEXT IN AN EQUIVALENT POSITION.     54180013
         SPACE                                                          54240013
XA110    LR    SCRTCH,JUMP             SET A SCRATCH REGISTER TO THE    54300013
         MVC   XA223(2),1(SCRTCH)      START OF THE TEXT INSERTED IN    54360013
         AH    SCRTCH,XA223            THE DICTIONARY.                  54420013
         SPACE                                                          54480013
         CLI   0(SCRTCH),X'CF'         LOOK TO SEE WHETHER OR NOT THE   54540013
         BC    BNE,XA110A              TEXT IS IN THE NEXT DICTIONARY   54600013
*                                      BLOCK.                           54660013
         SPACE                                                          54720013
*              THE TEXT HAS BEEN SLOTTED INTO THE NEXT BLOCK.           54780013
         SPACE                                                          54840013
         MVC   PAR1+2(2,GRDIC),1(SCRTCH)   GET THE SYMBOLIC REFERENCE   54900013
*                                          INTO A PARAMETER SLOT        54960013
         SPACE                                                          55020013
*********************************************************************** 55080013
         SPACE                                                          55140013
         L     LR,ZDRFAB(0,GRCC)       GO TO COMPILER CONTROL TO        55200013
         BALR  RR,LR                   UNSCRAMBLE THE REFERENCE         55260013
         SPACE                                                          55320013
*********************************************************************** 55380013
         SPACE                                                          55440013
         L     SCRTCH,PAR1(0,GRDIC)    AND POINT THE SCRATCH REGISTER   55500013
         BC    B,XA110B                AT THE START OF THE TEXT         55560013
         SPACE                                                          55620013
*              HERE THE TEXT IS NOT IN THE NEXT BLOCK.                  55680013
         SPACE                                                          55740013
XA110A   LA    SCRTCH,3(0,SCRTCH)      BUMP THE SCRATCH REGISTER TO     55800013
         N     SCRTCH,XA216A           THE NEXT FOUR BYTE BOUNDARY.     55860013
         SPACE                                                          55920013
XA110B   TM    7(JUMP),X'80'           TEST WHETHER OR NOT THE TEXT     55980013
         BC    BZ,XA115                BIT IS ON IN THE CODE BYTE       56040013
         CLI   0(SCRTCH),X'C8'                                          56100013
         BC    BNE,XA115                                                56160013
         SPACE                                                          56220013
         CLI   3(SCRTCH),X'FF'         TEST TO FIND OUT WHETHER OR NOT  56280013
         BC    BNE,XA112               THE TEXT HAS BEEN TRUNCATED      56340013
         SPACE                                                          56400013
*              HERE THE TEXT HAS BEEN TRUNCATED AND WE MAY HAVE TO SLOT 56460013
*        IN ASSEMBLED TEXT.                                             56520013
         SPACE                                                          56580013
         CLI   0(POINT),X'0C'          TEST TO FIND OUT WHETHER THE     56640013
         BC    BNE,XA112               ASSEMBLED TEXT IS TO PRECEDE OR  56700013
*                                      FOLLOW THE PROGRAMMER'S TEXT     56760013
         SPACE                                                          56820013
*              HERE THE ASSEMBLED TEXT IS TO PRECEDE THE PROGRAMMER'S   56880013
*        TEXT.                                                          56940013
         SPACE                                                          57000013
         XR    HELP,HELP               GET THE LENGTH COUNT OF THE      57060013
         IC    HELP,XA910              ASSEMBLED TEXT INTO A SCRATCH    57120013
*                                      REGISTER, AND BUMP DOWN BY ONE   57180013
         BCTR  HELP,0                  TO ALLOW FOR THE BLANK AT THE    57240013
*                                      AND START.                       57300013
         SPACE                                                          57360013
         SR    BUFFER,HELP             SET THE BUFFER REGISTER TO THE   57420013
*                                      REQUIRED POSITION.               57480013
         SPACE                                                          57540013
         BCTR  HELP,0                  CHECK TO SEE WHETHER OR NOT THE  57600013
         STC   HELP,*+5                LAST N CHARACTERS IN THE MESSAGE 57660013
         CLC   0(0,BUFFER),XA910+2                                      57720013
         BC    BE,XA111                TEXT.                            57780013
         SPACE                                                          57840013
         LA    HELP,1(0,HELP)          RESTORE THE BUFFER POINTER.      57900013
         AR    BUFFER,HELP                                              57960013
         STC   HELP,*+5                                                 58020013
         MVC   0(0,BUFFER),XA910+1                                      58080013
         SPACE                                                          58140013
         LA    HELP,1(0,HELP)          MOVE UP THE BUFFER POINTER AND   58200013
         AR    BUFFER,HELP             ADJUST THE LENGTH COUNT.         58260013
         AH    HELP,XA200                                               58320013
         STH   HELP,XA200                                               58380013
         SPACE                                                          58440013
         BC    B,XA112                                                  58500013
         SPACE                                                          58560013
*              HERE THE PRECEDING PART OF THE MESSAGE WAS THE SAME AS   58620013
*        THE ASSEMBLED TEXT AND WE ONLY RESTORE THE BUFFER POINTER.     58680013
         SPACE                                                          58740013
XA111    LA    HELP,1(0,HELP)                                           58800013
         AR    BUFFER,HELP                                              58860013
         SPACE 3                                                        58920013
*              HERE WE ARE JUST ABOUT TO SLOT IN THE SOURCE TEXT.       58980013
         SPACE                                                          59040013
XA112    MVI   0(BUFFER),X'40'         MOVE 'QUOTE' INTO THE OUTPUT     59100013
         MVI   1(BUFFER),C''''       AREA                               59160013
         SPACE                                                          59220013
         MVC   XA223(2),1(SCRTCH)      GET THE LENGTH OF THE TEXT INTO  59280013
         LH    HELP,XA223              A SCRATCH REGISTER               59340013
         S     HELP,XA225                                               59400013
         SPACE                                                          59460013
         STC   HELP,*+5                MOVE IN THE TEXT IN INTERNAL     59520013
         MVC   2(0,BUFFER),4(SCRTCH)   CODE                             59580013
         SPACE                                                          59640013
         AR    BUFFER,HELP             BUMP THE BUFFER POINTER AND      59700013
         MVI   2(BUFFER),C''''       EBCDIC                             59760013
         MVI   3(BUFFER),X'40'         INTERNAL CODE                    59820013
         SPACE                                                          59880013
         A     BUFFER,XA225            FULLY UPDATE THE BUFFER POINTER  59940013
         SPACE                                                          60000013
         AH    HELP,XA200              UPDATE THE LENGTH COUNT.         60060013
         A     HELP,XA225                                               60120013
         STH   HELP,XA200                                               60180013
         SPACE                                                          60240013
*              HERE THE TEXT HAS BEEN SLOTTED IN.   DO WE HAVE TO       60300013
*        FOLLOW IT WITH ASSEMBLED TEXT.                                 60360013
         SPACE                                                          60420013
         CLI   0(POINT),X'0C'          IF THE INDICATOR BYTE IS '0C'    60480013
         BC    BNE,XA114               WE HAVE FINISHED                 60540013
         SPACE                                                          60600013
XA113    LA    POINT,1(0,POINT)        BUMP THE MESSAGE POINTER AND     60660013
         BC    B,XA36                  GO BACK FOR MORE                 60720013
         SPACE                                                          60780013
XA114    CLI   3(SCRTCH),X'FF'         IF THE TEXT HAS NOT BEEN         60840013
         BC    BNE,XA113               TRUNCATED WE HAVE FINISHED       60900013
         SPACE                                                          60960013
*              HERE WE MAY HAVE TO SLOT IN ASSEMBLED TEXT AFTER THE     61020013
*        SOURCE TEXT.                                                   61080013
         SPACE                                                          61140013
         XR    HELP,HELP               GET THE LENGTH COUNT OF THE      61200013
         IC    HELP,XA915              TEXT INTO A SCRATCH REGISTER     61260013
         SPACE                                                          61320013
         BCTR  HELP,0                  BUMP IT DOWN BY TWO TO ALLOW     61380013
         BCTR  HELP,0                  FOR THE LEADING BLANK AND THE    61440013
*                                      NATURE OF THE 360.               61500013
         SPACE                                                          61560013
         STC   HELP,*+5                COMPARE THE ASSEMBLED TEXT WITH  61620013
         CLC   1(0,POINT),XA915+2      THE NEXT BIT OF MESSAGE SKELETON 61680013
         BC    BE,XA113                AND IF THEY ARE IDENTICAL WE     61740013
*                                      HAVE FINISHED                    61800013
         SPACE                                                          61860013
*              HERE WE MUST SLOT THE TEXT INTO THE MESSAGE              61920013
         SPACE                                                          61980013
         LA    HELP,2(0,HELP)                                           62040013
         STC   HELP,*+5                MOVE IN THE TEXT AND TRANSLATE   62100013
         MVC   0(0,BUFFER),XA915+1     IT TO INTERNAL CODE              62160013
XA114A   AR    BUFFER,HELP             BUMP THE BUFFER POINTER AND      62220013
         AH    HELP,XA200              UPDATE THE LENGTH COUNT          62280013
         STH   HELP,XA200                                               62340013
         SPACE                                                          62400013
         BC    B,XA113                 AND RETURN                       62460013
         SPACE 5                                                        62520013
*              HERE WE HAVE BEEN ASKED TO SLOT IN TEXT AND NONE HAS     62580013
*        BEEN SUPPLIED.                                                 62640013
         SPACE                                                          62700013
XA115    XR    HELP,HELP               MOVE AN ADMONITORY MESSAGE INTO  62760013
         IC    HELP,XA840              THE OUTPUT BUFFER, TIDY UP AND   62820013
         STC   HELP,*+5                GO BACK FOR MORE.                62880013
         MVC   0(0,BUFFER),XA840+1                                      62940013
         SPACE                                                          63000013
         BC    B,XA114A                                                 63060013
         EJECT                                                          63120013
*              THIS ROUTINE SLOTS THE BCD CORRESPONDING TO A DICTIONARY 63180013
*        REFERENCE INTO THE MESSAGE.                                    63240013
         SPACE                                                          63300013
*              THIS ROUTINE DOES NOT CAUSE THE EJECTION FROM CORES OF   63360013
*        EITHER THE 'LAST' DICTIONARY BLOCK OR THE 'JUMP' BLOCK.        63420013
         SPACE 3                                                        63480013
XA130    TM    7(JUMP),X'10'           IF THE DICTIONARY REFERENCE BIT  63540013
         BC    BZ,XA134                IS NOT ON SOMEONE HAS MADE AN    63600013
*                                      ASS OF HIMSELF                   63660013
         SPACE                                                          63720013
*              THE DICTIONARY REFERENCE BIT IN THE CHAIN ENTRY IS ON.   63780013
         SPACE                                                          63840013
*              WE MUST NOW DISCOVER WHICH OTHER BITS ARE ON IN ORDER TO 63900013
*        GET HOLD OF THE REFERENCE                                      63960013
         SPACE                                                          64020013
         TM    7(JUMP),X'60'           INSPECT THE STATEMENT NUMBER     64080013
         BC    BO,XA131                AND NUMERIC PARAMETER BITS IN    64140013
         BC    BM,XA132                THE CODE BYTE                    64200013
         SPACE                                                          64260013
*              HERE NEITHER THE STATEMENT NUMBER BIT NOR THE NUMERIC    64320013
*        PARAMETER BIT IS ON AND THE REFERENCE IS AN OFFSET OF EIGHT    64380013
*        FROM THE JUMP REGISTER.                                        64440013
         SPACE                                                          64500013
         MVC   PAR1+2(2,GRDIC),8(JUMP)      MOVE THE REFERENCE INTO     64560013
         BC    B,XA132+6               PAR1.                            64620013
         SPACE                                                          64680013
*              HERE BOTH THE STATEMENT NUMBER BIT AND THE NUMERIC       64740013
*        PARAMETER BITS ARE ON AND THE REFERENCE IS AN OFFSET OF        64800013
*        TWELVE FROM THE JUMP REGISTER                                  64860013
         SPACE                                                          64920013
XA131    MVC   PAR1+2(2,GRDIC),12(JUMP)     MOVE THE REFERENCE INTO     64980013
         BC    B,XA132+6               PAR1,                            65040013
         SPACE                                                          65100013
*              HERE ONE OR OTHER OF THE STATEMENT NUMBER OR NUMERIC     65160013
*        PARAMETER BITS IS ON AND THE OFFSET IS TEN.                    65220013
         SPACE                                                          65280013
XA132    MVC   PAR1+2(2,GRDIC),10(JUMP)                                 65340013
         SPACE                                                          65400013
         CLC   FONOF(4,GRDIC),ZERO     EXTDIC ?                   23351 65410018
         BC    BE,XA132A               NO.                        23351 65420018
         MVC   XA231(2),XA234          YES.                       23351 65430018
XA132A   DS    0H                                                 23351 65440018
         CLC   PAR1+2(2,GRDIC),XA231   IF THIS REFERENCE IS LESS THAN   65460013
         BC    BL,XA135                X'0300' IT IS A REFERENCE TO AN  65520013
*                                      INSERTED VARIABLE, AND WE MUST   65580013
*                                      TAKE SPECIAL ACTION.             65640013
         SPACE                                                          65700013
*********************************************************************** 65760013
         SPACE                                                          65820013
XA133    L     LR,ZDRFAB(0,GRCC)                                        65880013
         BALR  RR,LR                                                    65940013
         SPACE                                                          66000013
*********************************************************************** 66060013
         SPACE                                                          66120013
         L     SCRTCH,PAR1(0,GRDIC)    POINT A SCRATCH REGISTER AT THE  66180013
*                                      REQUIRED ENTRY.                  66240013
         SPACE                                                          66300013
         XR    HELP,HELP               PICK UP LENGYT OF BCD            66360013
         IC    HELP,0(0,SCRTCH)                                         66420013
         SPACE                                                          66480013
         LA    SCRTCH,16(0,SCRTCH)     POINT SCRTCH AT BCD              66540013
         MVI   0(BUFFER),X'40'         MOVE BLANK INTO OUTPUT REGION    66600013
         BCTR  HELP,0                                                   66660013
         SPACE                                                          66720013
         C     HELP,XA232              IF THE LENGTH COUNT IS MORE      66780013
         BC    BH,XA137                THAN 31 WE HAVE BEEN HANDED AN   66840013
*                                      INVALID REFERENCE.               66900013
         SPACE                                                          66960013
         STC   HELP,*+5                MOVE IN THE BCD, WHICH IS IN     67020013
         MVC   1(0,BUFFER),0(SCRTCH)  EBCDIC                            67080013
         SPACE                                                          67140013
         AR    BUFFER,HELP             SET THE BUFFER POINTER TO TWO    67200013
*                                      BEFORE THE NEXT BYTE OF THE      67260013
*                                      OUTPUT REGION.                   67320013
         SPACE                                                          67380013
         MVI   2(BUFFER),X'40'         MOVE IN A TERMINATING BLANK      67440013
         SPACE                                                          67500013
         LA    BUFFER,3(0,BUFFER)      UPDATE TO ALLOW FOR TWO BLANKS   67560013
         LA    HELP,3(0,HELP)          AND A ONE LESS LENGTH COUNT.     67620013
         SPACE                                                          67680013
         AH    HELP,XA200              UPDATE THE LENGTH COUNT          67740013
         STH   HELP,XA200                                               67800013
         SPACE                                                          67860013
         LA    POINT,1(0,POINT)        BUMP THE POINT REGISTER AND      67920013
         MVC   PAR1+2(2,GRDIC),XA233   ENSURE THAT THE BLOCK OF THE     67980013
         L     LR,ZDRFAB(0,GRCC)       CURRENT ENTRY IS IN CORE.        68040013
         BALR  RR,LR                                                    68100013
         L     JUMP,PAR1(0,GRDIC)                                       68160013
         BC    B,XA36                  RETURN                           68220013
         SPACE 3                                                        68280013
*********************************************************************** 68340013
*********************************************************************** 68400013
         SPACE                                                          68460013
*              HERE THERE IS A REQUEST FOR THE BCD OF A DICTIONARY      68520013
*        REFERENCE TO BE SLOTTED INTO THE DICTIONARY, AND NO DICTIONARY 68580013
*        REFERENCE HAS BEEN SUPPLIED.                                   68640013
         SPACE                                                          68700013
XA134    LA    SCRTCH,XA850                                             68760013
         BC    B,XA95A                                                  68820013
         EJECT                                                          68880013
*              THE CHAIN ENTRY EVALUATOR.                               68940013
         SPACE                                                          69000013
*              THIS ROUTINE INSPECTS EACH ENTRY IN THE CHAIN FOR        69060013
*        LEGALITY.   IF FAULTS ARE DISCOVERED THE APPROPRIATE COMPILER  69120013
*        DIAGNOSTIC IS PRINTED OUT AGAINST THE MESSAGE NUMBER IN PLACE  69180013
*        OF THE MESSAGE TEXT.                                           69240013
         SPACE                                                          69300013
XA150    XR    SCRTCH,SCRTCH                                            69360013
         SPACE                                                          69420013
         CLI   0(JUMP),X'00'           IF THE BLOCK IDENTIFICATION IS   69480013
         BC    BNE,XA151               ZERO THEN THERE IS NO MENTION    69540013
*                                      OF IT IN THE MESSAGE ADDRESS     69600013
*                                      BLOCK.                           69660013
         SPACE                                                          69720013
*              WE HAVE ENCOUNTERED A MISSING MESSAGE.                   69780013
         SPACE                                                          69840013
*                                      MOVE THE APPROPRIATE COMPILER    69900013
         IC    SCRTCH,XA810            DIAGNOSTIC INTO THE OUTPUT       69960013
         STC   SCRTCH,*+5              BUFFER AND TRANSLATE IT TO       70020013
         MVC   0(0,BUFFER),XA810+1     INTERNAL CODE.                   70080013
XA150A   AH    SCRTCH,XA200            UPDATE LENGTH COUNT AND GO       70140013
         STH   SCRTCH,XA200            TO PUT THE MESSAGE OUT.          70200013
         MVI   XA208+1,X'00'           SET THE NULL MESSAGE SWITCH.     70260013
         BC    B,XA40                                                   70320013
         SPACE                                                          70380013
*              HERE THE MESSAGE IS QUOTED AS RESIDING IN A NAMED BLOCK. 70440013
*        IS THIS A LEGAL BLOCK FOR IT                                   70500013
         SPACE                                                          70560013
XA151    IC    SCRTCH,7(0,JUMP)        GET THE SEVERITY CODE INTO A     70620013
         N     SCRTCH,XA216            REGISTER.                        70680013
         SPACE                                                          70740013
         L     POINT,XA217(SCRTCH)     SET A REGISTER TO THE            70800013
         AR    POINT,XBBASE            APPROPRIATE LIST OF BLOCK        70860013
*                                      IDENTIFIERS                      70920013
         SPACE                                                          70980013
XA152    CLC   0(1,POINT),0(JUMP)      IF WE SEE OUR CURRENT BLOCK WE   71040013
         BC    BE,XA33                 ARE OK AND THE ENTRY IS LEGAL    71100013
         SPACE                                                          71160013
         CLI   0(POINT),C'Z'           IF WE SEE 'Z' WE HAVE OUTRUN     71220013
         BC    BE,XA153                THE LEGAL LIST AND ARE IN        71280013
*                                      TROUBLE                          71340013
         SPACE                                                          71400013
         LA    POINT,1(0,POINT)        OTHERWISE GO ROUND AGAIN         71460013
         BC    B,XA152                                                  71520013
         SPACE                                                          71580013
*              HERE WE HAVE OUTRUN THE LIST.                            71640013
         SPACE                                                          71700013
XA153    SRL   SCRTCH,2                SLOT A LETTER INDICATING THE     71760013
         IC    SCRTCH,XA222(SCRTCH)    SEVERITY INTO THE APPROPRIATE    71820013
         STC   SCRTCH,XA821            MESSAGE.                         71880013
         SPACE                                                          71940013
XA154    MVC   XA822(1),0(JUMP)        PUT IN THE QUOTED BLOCK          72000013
*                                      IDENTIFIER                       72060013
         SPACE                                                          72120013
         IC    SCRTCH,XA820            MOVE THE MESSAGE INTO THE OUTPUT 72180013
         STC   SCRTCH,*+5              BUFFER, AND PUT IT OUT           72240013
         MVC   0(0,BUFFER),XA820+1                                      72300013
         BC    B,XA150A                                                 72360013
         SPACE 3                                                        72420013
*              HERE WE HAVE BEEN HANDED THE DICTIONARY REFERENCE OF     72480013
*        'FUNNY THING', I.E. AN INSERTED VARIABLE.                      72540013
XA135    XR    SCRTCH,SCRTCH                                            72600013
         IC    SCRTCH,XA920            PUT A REMARK TO THIS EFFECT      72660013
         STC   SCRTCH,*+5              INTO THE BUFFER AND FORGE ON.    72720013
         MVC   0(0,BUFFER),XA920+1                                      72780013
         SPACE                                                          72840013
         BC    B,XA755                                            23351 72900018
         SPACE 3                                                        72960013
*              HERE WE HAVE BEEN HANDED AN INVALID DICTIONARY REFERENCE 73020013
*        THIS IS A COMPILER ERROR.                                      73080013
XA137    XR    SCRTCH,SCRTCH                                            73140013
         IC    SCRTCH,XA880            INSERT A REMARK INTO THE BUFFER  73200013
         STC   SCRTCH,*+5              AND GO ON WITH THE SCAN.         73260013
         MVC   0(0,BUFFER),XA880+1                                      73320013
         SPACE                                                          73380013
         BC    B,XA755                                            23351 73440018
         EJECT                                                          73500013
*              WORKSPACE                                                73560013
         SPACE                                                          73620013
         CNOP  0,4                                                      73680013
         SPACE                                                          73740013
XA200    DC    X'0000'                 THIS IS THE OUTPUT REGION.       73800013
XA201    DC    X'60'                   IT STARTS WITH THE LENGTH COUNT  73860015
XA202    DC    X'40404040'             AND THE CARRIAGE CONTROL         73920013
XA203    DC    16XL16'00'              CHARACTER.   FOUR BLANKX ARE     73980013
         DC    16XL16'00'                                               74040013
*                                      ASSEMBLED IN AND THE REMAINDER   74100013
*                                      IS ALL ZEROS.                    74160013
         SPACE                                                          74220013
XA204    DC    C'BOZZ'                                                  74280013
XA205    DC    X'0000'                 TO FIND ZERO CHAIN ENTRIES       74340013
XA205A   DC    X'00'                                                    74400013
XA206    DS    1F                      FOUR BYTE BOUNDARY               74460013
         SPACE                                                          74520013
XA207    EQU   X'14'                   OFFSET OF POINTER TO THE         74580013
*                                      BLOCK USAGE TABLE                74640013
XA208    DC    X'0000'                 THE TWO MESSAGE OUTPUT SWITCHES. 74700013
XA209    DC    C'PRSTUV'                                                74760013
         DC    X'FF'                                                    74820013
         DC    X'FF'                   TERMINATOR.                      74880013
XA210    DC    C'BPZZ'                                                  74940013
         DC    C'BRZZ'                                                  75000013
         DC    C'BSZZ'                                                  75060013
         DC    C'BTZZ'                                                  75120013
         DC    C'BUZZ'                                                  75180013
         DC    C'BVZZ'                                                  75240013
XA211    DC    F'0'                    TEMPORARY STORAGE                75300013
         CNOP  0,8                                                      75360013
XA212    DC    2F'0'                   WORKSPACE FOR CONVERT AND        75420013
*                                      UNPACK.INSTRUCTIONS.             75480013
XA213    DC    2F'0'                   SOURCE OF ZEROS FOR MOVE ZONES   75540013
*                                      INSTRUCTION.                     75600013
XA214    DC    C'IEM'                                                   75660013
XA215    DC    X'404040'               '   ' IN INTERNAL CODE .         75720013
         CNOP  0,4                                                      75780013
XA216    DC    X'0000000F'             AND OUT ALL BUT LAST FOUR BITS   75840013
XA216A   DC    X'FFFFFFFC'             AND OUT THE LAST TWO BITS        75900013
         SPACE                                                          75960013
XA217    DC    A(XA218-BN)                                              76020013
         DC    A(XA219-BN)                                              76080013
         DC    A(XA220-BN)                                              76140013
         DC    A(XA221-BN)                                              76200013
XA218    DC    C'PZ'                                                    76260013
XA219    DC    C'RZ'                                                    76320013
XA220    DC    C'STUZ'                                                  76380013
XA221    DC    C'VZ'                                                    76440013
XA222    DC    C'TSEW'                 SEVERITY LETTERS                 76500013
XA223    DS    1F                      RETURN REGISTER STORE            76560013
XA224    DC    C'BNZZ'                                                  76620013
XA225    DC    F'4'                                                     76680013
XA226    DC    F'116'                  LENGTH OF PRINT LINE             76740013
XA228    DC    F'256'                  FOR MOVING TEXT                  76800013
XA229    DC    16X'40'                 BLANKS IN INTERNAL CODE          76860013
         DC    8X'40'                                                   76920013
XA230    DC    X'0004080C1014181CFF'   VALID INDICATOR BYTES            76980013
XA231    DC    X'0300'                                                  77040013
XA234    DC    X'0178'                 FIRST REF WITH EXTDIC.     23351 77060018
ZERO     DC    F'0'                    FULLWORD ZERO.             23351 77080018
XA232    DC    1F'31'                                                   77100013
XA233    DC    1F'0'                                                    77160013
         EJECT                                                          77220013
*              COMPILER DEBUGGING MESSAGES                              77280013
         SPACE                                                          77340013
*********************************************************************** 77400013
*                                                                     * 77460013
*              PLEASE NOTE THAT NONE OF THE MESSAGES BELOW MAY EXCEED * 77520013
*        100 CHARACTERS IN LENGTH.                                    * 77580013
*                                                                     * 77640013
*********************************************************************** 77700013
         SPACE                                                          77760013
XA800    DC    AL1(XA802-XA800-1)                                       77820013
         DC    C'*** THIS MESSAGE'     THE IDENTIFICATION OF THE        77880013
         DC    C' CANNOT BE FOUND'     BLOCK CURRENTLY BEING EXAMINED   77940013
         DC    C' IN THE BLOCK QU'     IS SLOTTED INTO THE MESSAGE BY   78000013
         DC    C'OTED FOR IT, I.E'     INSTRUCTION XA35 AT POSITION     78060013
         DC    C'. BLOCK B'            XA801                            78120013
XA801    DC    C' '                                                     78180013
         DC    C'.   PLEASE RAISE'                                      78240013
         DC    C' AN APAR.'                                             78300013
XA802    DC    C' '                                                     78360013
         SPACE                                                          78420013
XA810    DC    AL1(XA811-XA810-1)      WE CANNOT FIND THE MESSAGE       78480013
         DC    C'*** THIS MESSAGE'                                      78540013
         DC    C' CANNOT BE IDENT'                                      78600013
         DC    C'IFIED.   PLEASE '                                      78660013
         DC    C'RAISE AN APAR.'                                        78720013
XA811    DC    C' '                                                     78780013
         SPACE                                                          78840013
XA820    DC    AL1(XA823-XA820-1)                                       78900013
         DC    C'*** THIS MESSAGE'                                      78960013
         DC    C' APPEARS EITHER '     ONE OF THE LETTERS T,S,E OR W    79020013
         DC    C'IN THE WRONG CHA'     IS SLOTTED INTO XA821 BY         79080013
         DC    C'IN OR IN THE WRO'     INSTRUCTIONS AT XA153.           79140013
         DC    C'NG BLOCK.   SEVE'                                      79200013
         DC    C'RITY '                                                 79260013
XA821    DC    C' '                    THE BLOCK IDENTIFIER IS SLOTTED  79320013
         DC    C' AND BLOCK B'         INTO XA822 BY INSRTUCTIONS AT    79380013
XA822    DC    C' '                    XA154.                           79440013
         DC    C'.   PLEASE RAISE'                                      79500013
         DC    C' AN APAR.'                                             79560013
XA823    DC    C' '                                                     79620013
         SPACE                                                          79680013
XA830    DC    AL1(XA831-XA830-1)                                       79740013
         DC    C'*** A LINE '                                           79800013
         DC    C'NUMBER SHOULD AP'                                      79860013
         DC    C'PEAR AT THIS POI'                                      79920013
         DC    C'NT BUT NONE HAS '                                      79980013
         DC    C'BEEN SUPPLIED.  '                                      80040013
         DC    C' PLEASE RAISE AN'                                      80100013
         DC    C' APAR ***'                                             80160013
XA831    DC    C' '                                                     80220013
         SPACE                                                          80280013
XA840    DC    AL1(XA841-XA840-1)                                       80340013
         DC    C'*** SOURCE TEXT '                                      80400013
         DC    C'SHOULD BE INSERT'                                      80460013
         DC    C'ED AT THIS POINT'                                      80520013
         DC    C' BUT NONE HAS BE'                                      80580013
         DC    C'EN SUPPLIED.   P'                                      80640013
         DC    C'LEASE RAISE AN A'                                      80700013
         DC    C'PAR ***'                                               80760013
XA841    DC    C' '                                                     80820013
         SPACE                                                          80880013
XA850    DC    AL1(XA851-XA850-1)                                       80940013
         DC    C'*** THE NAME OF '                                      81000013
         DC    C'AN IDENTIFIER SH'                                      81060013
         DC    C'OULD APPEAR AT T'                                      81120013
         DC    C'HIS POINT BUT TH'                                      81180013
         DC    C'E NECESSARY REFE'                                      81240013
         DC    C'RENCE TO IT HAS '                                      81300013
         DC    C'NOT BEEN SUPPLIE'                                      81360013
         DC    C'D.   PLEASE RAIS'                                      81420013
         DC    C'E AN APAR ***'                                         81480013
XA851    DC    C' '                                                     81540013
         SPACE                                                          81600013
XA860    DC    AL1(XA861-XA860-1)                                       81660013
         DC    C'*** A NUMERIC PA'                                      81720013
         DC    C'RAMETER SHOULD A'                                      81780013
         DC    C'PPEAR AT THIS PO'                                      81840013
         DC    C'INT BUT NONE HAS'                                      81900013
         DC    C' BEEN SUPPLIED. '                                      81960013
         DC    C'  PLEASE RAISE A'                                      82020013
         DC    C'N APAR ***'                                            82080013
XA861    DC    C' '                                                     82140013
         SPACE                                                          82200013
XA870    DC    AL1(XA871-XA870-1)                                       82260013
         DC    C' *** INVALID IND'                                      82320013
         DC    C'ICATOR BYTE IN M'                                      82380013
         DC    C'ESSAGE SKELETON.'                                      82440013
         DC    C'   PLEASE RAISE '                                      82500013
         DC    C'APAR. *** '                                            82560013
XA871    DC    C' '                                                     82620013
         SPACE                                                          82680013
XA880    DC    AL1(XA881-XA880-1)                                       82740013
         DC    C'*** THE NAME OF '                                      82800013
         DC    C'AN IDENTIFIER SH'                                      82860013
         DC    C'OULD APPEAR AT T'                                      82920013
         DC    C'HIS POINT BUT TH'                                      82980013
         DC    C'E REFERENCE SUPP'                                      83040013
         DC    C'LIED FOR IT IS I'                                      83100013
         DC    C'NVALID.   PLEASE'                                      83160013
         DC    C' RAISE AN APAR *'                                      83220013
         DC    C'**'                                                    83280013
XA881    DC    C' '                                                     83340013
         EJECT                                                          83400013
*              ASSEMBLED TEXT WHICH FORMS PART OF DIAGNOSTIC MESSAGES   83460013
         SPACE                                                          83520013
XA900    DC    AL1(XA901-XA900-1)      THIS MESSAGE IS '                83580013
         DC    C' LINE NUMBER '                                         83640013
XA901    DC    C' '                    AND PRECEDES THE NUMBER.         83700013
         SPACE                                                          83760013
XA905    DC    AL1(XA906-XA905-1)      THIS INDICATES STATEMENT NUMBER  83820013
         DC    C' XXX '                BUT IS TO FOLLOW THE NUMBER IN   83880013
XA906    DC    C' '                    THE TEXT.   NOT USED IN ENGLISH. 83940013
         SPACE                                                          84000013
XA910    DC    AL1(XA911-XA910-1)      OPTIONAL PREFIX TO TRUNCATED     84060013
         DC    C' BEGINNING'                                            84120013
XA911    DC    C' '                                                     84180013
         SPACE                                                          84240013
XA915    DC    AL1(XA916-XA915-1)      OPTIONAL SUFFIX TO TRUNCATED     84300013
         DC    C' XXX '                SOURCE TEXT.   NOT USED IN       84360013
XA916    DC    C' '                    ENGLISH.                         84420013
         SPACE                                                          84480013
XA920    DC    AL1(XA921-XA920-1)                                       84540013
         DC    C' * INSERTED VARI'                                      84600013
         DC    C'ABLE *'                                                84660013
XA921    DC    C' '                                                     84720013
         EJECT                                                          84780013
*                  VALUES OF SYMBOLIC REGISTERS.                        84840013
         SPACE                                                          84900013
SCRTCH   EQU   1                       SCRATCH REGISTER                 84960013
HELP     EQU   2                       SCRATCH REGISTER                 85020013
POINT    EQU   3                       SCANS MESSAGE SKELETON           85080013
USAGE    EQU   4                       SCANS BLOCK USAGE TABLE          85140013
BLKHED   EQU   5                       BASES DATA BLOCKS                85200013
JUMP     EQU   6                       PROCESSES ERROR CHAINS           85260013
LAST     EQU   7                       PROCESSES ERROR CHAINS           85320013
XBBASE   EQU   8                                                        85380013
SCAN     EQU   5                                                        85440013
INDEX    EQU   9                       COUNTS ALONG CHAIN HEADS         85500013
GRBASE   EQU   10                      PROGRAM BASE.                    85560013
GRCC     EQU   11                                                       85620013
BUFFER   EQU   12                      OUTPUT BUFFER REGISTER           85680013
GRDIC    EQU   13                      COMMUNICATIONS REGION.           85740013
RR       EQU   14                      RETURN REGISTER.                 85800013
LR       EQU   15                      LINK REGISTER.                   85860013
         SPACE 2                                                        85920013
*                  LOCATIONS IN THE COMMUNICATIONS REGION.              85980013
         SPACE                                                          86040013
PAR1     EQU   X'80'                                                    86100013
PAR2     EQU   PAR1+4                                                   86160013
PAR3     EQU   PAR1+8                                                   86220013
PAR4     EQU   PAR1+12                                                  86280013
PAR5     EQU   PAR1+16                                                  86340013
PAR6     EQU   PAR1+20                                                  86400013
PAR7     EQU   PAR1+24                                                  86460013
PAR8     EQU   PAR1+28                                                  86520013
ZERRD    EQU   80                                                       86580013
ZLOCK    EQU   274                                                      86640013
ZMYNAM   EQU   112                                                      86700013
FONOF    EQU   208                                                23351 86730018
ERRCOD   EQU   224                                                      86760013
ZTRAN2   EQU   72                      LOCATION OF THE TRANSLATE        86820013
*                                      TABLE FROM INTERNAL TO           86880013
*                                      EXTERNAL CODE IN COMPILER        86940013
*                                      CONTROL.                         87000013
         SPACE 2                                                        87060013
*                  OFFSETS OF ROUTINES IN COMPILER CONTROL.             87120013
         SPACE                                                          87180013
REQEST   EQU   X'40'                   REQUEST BLOCKS AHEAD             87240013
ZLOAD    EQU   X'24'                   LOAD AND WAIT ROUTINE.           87300013
ZDRFAB   EQU   X'34'                   SYMBOLIC TO ABSOLUTE DICTIONARY  87360013
*                                      REFERENCE.                       87420013
ZEND     EQU   X'6C'                   END OF ROAD.                     87480013
RELESE   EQU   X'44'                   RELEASE LOADED BLOCK.            87540013
ZUPL     EQU   X'08'                   PRINT A LINE.                    87600013
         EJECT                                                          87660013
*              EXTENDED BRANCH MNEMONICS                                87720013
         SPACE                                                          87780013
BNL      EQU   11                                                       87840013
B        EQU   15                                                       87900013
BE       EQU   8                                                        87960013
BZ       EQU   8                                                        88020013
BNE      EQU   7                                                        88080013
BO       EQU   1                                                        88140013
BM       EQU   4                                                        88200013
BL       EQU   4                                                        88260013
BH       EQU   2                                                        88320013
BNH      EQU   13                                                       88380013
         SPACE 5                                                        88440013
         END   IEMBN                                                    88500013
