CI       TITLE 'IEMCI, FIRST PASS OF READIN      -  PL/I F '            00050015
         TITLE 'CI:- IEMCI, FIRST PASS OF READIN - PL/1(F)'             00056020
* 5.3B A 268000-268500,917500-918000,934500-935200            JAP 47697 00056656
*      C 112000,169500,194500-195500,267500-268000,272500     JAP 47697 00057256
*      C 278500,280000,519500-522500,523000-523500            JAP 47697 00057856
*      C 525500-526500,528000-528500,599000-599500            JAP 47697 00058456
*      C 631000-631500,651350-651400,758000-758500            JAP 47697 00059056
*      C 806500-807000                                        JAP 47697 00059656
*      D 199500-202500,298000-301500,798000-798500            JAP 47697 00060256
*      A 779780                                               JAP 49735 00060556
* 5.3A C 330500,406000,944000-944500                          PG  43444 00060856
* 5.2B C 300500-301000                                        KT  36960 00061456
* 5.2  C 729600-731600                                        JLC 25908 00062056
*      A 139700,401700,407200,542350,726200,731650-731900     JLC 28518 00062656
*      A 743700,785580-785900,935700                          JLC 28518 00063256
*      C 749000-750500,777500,779560-782220                   JLC 28518 00063856
*      D 571500,809000-822500                                 JLC 28518 00064456
*      A 798700                                               JLC 28532 00065056
*      C 637090-637900,643000-643500                          JLC 28532 00065656
*      A 158700,966200                                        JLC 30321 00066256
*      C 133500,134500,135500                                 JLC 30321 00066856
*                                                                       00067456
* R16 3275 519000                                                 12507 00068020
* R17 3275 274000-275500                                            H70 00074020
* R17 3275 129500-131000,143000-144500,965200                       I16 00080020
* R17 3275 514500                                                 19577 00086020
* R17 3275 555000-555300                                          19967 00092020
* R18 +032500,*398500,-(448000,484500),*486000,+965400            21134 00098020
* R18 *116500                                                      H220 00104020
* R18 *542000                                                      H268 00110020
* R18 +398000                                                     27130 00116020
* R19 *690000,*698000                                              H408 00122020
*                                                                       00132056
         SPACE 3                                                        00149719
*              FUNCTIONS - (1) CALLS COMPILER CONTROL TO OBTAIN SCRATCH 00150015
*        CORE. CARDS ARE READ INTO SOME OF THIS AREA, THE REMAINDER     00200015
*        IS USED FOR A STACKING PROCESS.                                00250015
*                          (3) PERFORMS THE MAIN SCAN FOR THIS PHYSICAL 00300015
*        PHASE.                                                         00350015
*                          (2) CALLS COMPILER CONTROL TO OBTAIN THE     00400015
*        FIRST TEXT BLOCK FOR THE OUTPUT TEXT PRODUCED BY THIS PHASE.   00450015
*                          (4) READS A CARD INTO THE READ AREA.         00500015
*                          (5) MOVES THE INPUT TEXT POINTER IN THE READ 00550015
*        AREA WHENEVER MATERIAL IS SCANNED, READING CARDS INTO THE READ 00600015
*        AREA AS REQUIRED.                                              00650015
*                          (6) HANDLES THE PRINTING OF THE SOURCE       00700015
*        PROGRAM.                                                       00750015
*                          (7) CHECKS STATEMENT LABELS AND INSERTS THEM 00800015
*        INTO THE DICTIONARY.                                           00850015
*                          (8) MAKES PARTAIL CHECK OF PREFIX OPTIONS    00900015
*        AND INSERTS THEM INTO THE DICTIONARY.                          00950015
*                          (9) CHECKS AND PROCESSES PROCEDURE AND ENTRY 01000015
*        STATEMENTS.                                                    01050015
*                          (10) SETS THE STATUS OF THE TEXT BLOCKS IT   01100015
*        USES.                                                          01150015
*                          (11) ON COMPLETION OF THIS PHASE IT RELEASES 01200015
*        THE SCRATCH CORE AND MODULE IEMCE, LOADS MODULES IEMCK AND     01250015
*        IEMCL OF THE NEXT PHASE, RELEASES ITSELF AND PASSES CONTROL TO 01300015
*        IEMCL.                                                         01350015
*                                                                       01400015
*              ENTRY POINTS. (1) WHEN THIS MODULE IS LOADED ENTRY IS AT 01450015
*        BDO.                                                           01500015
*                      (2) THROUGH A TRANSFER VECTOR AT A FIXED OFFSET. 01550015
*        AT THIS OFFSET A BRANCH IS MADE TO THE ROUTINE CALLED.         01600015
*                                                                       01650015
*              EXITS - NORMAL. THROUGH COMPILER CONTROL TO THE NEXT     01700015
*        PHASE.                                                         01750015
*                                                                       01800015
*              EXITS - ERROR. N/A.                                      01850015
IEMCI    START 0                                                        01900015
B5       EQU   IEMCI                                                    01950015
       SPACE                                                            02000015
*              DEFINE THE BASE REGISTER AND THE NAME FOR THIS PHASE.    02050015
         USING *,GR9                                                    02100015
         DC    C'CI'                                                    02150015
         BC    B,BD0                                                    02200015
       SPACE                                                            02250015
*              ROUTINES CONTAINED IN THIS PHASE.                        02300015
         CNOP  0,4                                                      02350015
         BC    B,STOK                                                   02400015
         BC    B,INCR                                                   02450015
         BC    B,BUMP                                                   02500015
         BC    B,READ                                                   02550015
         BC    B,READS                                                  02600015
         BC    B,RLETTR                                                 02650015
         BC    B,*                                                      02700015
         BC    B,*                                                      02750015
         BC    B,RSTART                                                 02800015
         BC    B,RDERR                                                  02850015
         BC    B,BADST1                                                 02900015
         BC    B,BADST3                                                 02950015
         BC    B,RNOON                                                  03000015
         BC    B,RDENT                                                  03050015
         BC    B,POPLST                                                 03100015
         BC    B,POPM                                                   03150015
         BC    B,BPROC                                                  03200001
         BC    B,RSTRT1                                                 03250015
         BC    B,RRETN                                            21134 03256001
         BC    B,FR1                                              21134 03262001
COMPTR   DS    F                                                        03270015
       SPACE                                                            03300015
         SPACE                                                          03350015
*********************************************************************** 03400015
       SPACE                                                            03450015
*              COMPILER CONTROL PASSES TO US THE SIZE HE ALLOWED FOR    03500015
*        THE READ AREA. WE DIVIDE THIS BY 512 TO FIND OUT HOW MANY      03550015
*        BLOCKS OF SCRATCH CORE TO REQUEST FOR THE READ AREA.           03600015
BD0      L     GRA,RASIZE(0,GRDIC)                                      03650015
         SRL   GRA,9(0)                                                 03700015
         ST    GRA,PAR1(0,GRDIC)                                        03750015
         L     LR,ZUGC(0,GRCC)                                          03800015
         BALR  RR,LR                                                    03850015
       SPACE                                                            03900015
         L     GRD,PAR1(0,GRDIC)                                        03950015
       SPACE                                                            04000015
*              SET UP A REGISTER WITH CONSTANT ONE FOR USE              04050015
*        THROUGHOUT ALL READIN PHASES AND PASSES.                       04100015
         LA    UR,1(0,0)                                                04150015
         AR    GRD,UR                  STEP BEGINNING OF READ AREA SO   04200015
*                                      THAT THERE IS NO PROTECTION      04250015
*                                      CRUNCH DUE TO FIDDLING AT RDGET  04300015
*                                      IN THE READ ROUTINE              04350015
         LR    DP,GRD                  SET DP, RP AND BRA TO START OF   04400015
         ST    GRD,RP(0,GRDIC)       READ AREA.                         04450015
         ST    GRD,COMPTR                                               04500015
         ST    GRD,BRA(0,GRDIC)                                         04550015
       SPACE                                                            04600015
         A     GRD,RASIZE(0,GRDIC)     COMPUTE THE ADDRESS OF THE END   04650015
         SR    GRD,UR                                                   04700015
         ST    GRD,LSTACK(0,GRDIC)   OF READ AREA AND SET LSTACK TO     04750015
*                                    THIS ADDRESS.                      04800015
       SPACE                                                            04850015
*              WE NOW COMPUTE THE ADDRESS OF THE BEGINING OF THE STACK. 04900015
*        THIS IS ALSO THE END OF THE READ AREA.                         04950015
       SPACE                                                            05000015
         SH    GRD,STSIZE                                               05050015
         ST    GRD,BSTACK(0,GRDIC)     SET BEGINING OF STACK POINTER,   05100015
         ST    GRD,STP(0,GRDIC)      STACKPOINTER, AND END OF READ      05150015
         ST    GRD,ERA(0,GRDIC)      AREA POINTER TO BEGINING OF STACK. 05200015
         MVI   0(GRD),NONE             ZEROISE BOTTOM OF STACK          05250015
       SPACE                                                            05300015
*              COMPILER CONTROL PASSES US THE SYMBOLIC ADDRESS OF A     05350015
*        TEXT BLOCK IN SSTEXT - THIS WE CONVERT TO AN ABSOLUTE ADDRESS  05400015
*        AND USE AS THE OUTPUT TEXT BLOCK.                              05450015
         MVC   BKNAME(4,GRDIC),SSTEXT(GRDIC)                            05500015
         MVC   PAR1(4,GRDIC),SSTEXT(GRDIC)                              05550015
         L     LR,ZTXTAB(0,GRCC)                                        05600015
         BALR  RR,LR                                                    05650015
       SPACE                                                            05700015
         LH    GRD,ZCNCHR(0,GRDIC)     PRINT CHARACTER                  05720015
         BCTR  GRD,0                   AND STORE IN COLNO               05740015
         AR    GRD,GRDIC                                                05760015
         ST    GRD,COLNO                                                05780015
*        SET NEST BIT TO ZERO IF NOLIST SPECIFIED                       05784015
         TM    CCCODE+2(GRDIC),X'80'                                    05788015
         BC    BZ,NOCC                                                  05792015
         NI    CCCODE+3(GRDIC),X'FE'                                    05796015
*        SET THE BEGINNING OF THE CURRENT BLOCK POINTER TO POINT        05800015
*              AT THE START OF THE OUTPUT BLOCK                         05820015
NOCC     L     GRD,PAR1(0,GRDIC)                                        05840015
         ST    GRD,BCB(0,GRDIC)                                         05900015
       SPACE                                                            05950015
*              RESET REGISTER 15 AS BASE REGISTER FOR BLOCK CA.         06000015
         LR    GR15,GR2                                                 06050015
       SPACE                                                            06100015
*              SET THE OUTPUT POINTER TO POINT AT THE START OF THE      06150015
*        OUTPUT BLOCK.                                                  06200015
         LR    OP,GRD                                                   06250015
       SPACE                                                            06300015
*              ADD TEXT BLOCK SIZE TO THE START OF OUTPUT BLOCK ADDRESS 06350015
*        AND SET END OF CURRENT BLOCK POINTER.                          06400015
         A     GRD,TBSIZE(0,GRDIC)                                      06450015
         SR    GRD,UR                                                   06500015
         ST    GRD,ECB(0,GRDIC)                                         06550015
       SPACE                                                            06600015
*              INITIALISE THE OUTPUT BUFFER FOR THE PRINT ROUTINE TO    06650015
*        PRINT THE FIRST LINE.                                          06700015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 009-TSS 06720020
         MVC   OUTBUF(3,GRDIC),OUT                                      06750015
*        ----------------------------------------------------CI 009-TSS 06770020
       SPACE                                                            06800015
         SPACE                                                          06850015
         SPACE                                                          06900015
*              SAVE THE NAME OF THIS PHASE.                             06950015
         MVC   ZNAME(2,GRDIC),B5                                        07000015
       SPACE                                                            07050015
*              INITIALISE STATEMENT NUMBER SLOT ZSTAT AND THE POINTER   07100015
*        TO THE LAST BYTE OF VALID PROGRAM LOP.                         07150015
         XC    ZSTAT(2,GRDIC),ZSTAT(GRDIC)   SET ZSTAT TO ZERO          07200015
*              SAVE THE BASE ADDRESS OF THIS PHASE                      07250015
         ST    GR9,BASEB5(0,GRDIC)                                      07300015
*              SAVE THE BASE ADDRESS OF THE COMMON PHASE CA             07350015
         ST    GR15,BASEBA(0,GRDIC)                                     07400015
       SPACE                                                            07450015
         TM    CCCODE+3(GRDIC),X'01'                                    07470015
         BC    BZ,NOHEAD                                                07480015
         BAL   GRB,HEAD(GR10)                                           07490015
NOHEAD   BAL   RR,READ                 READ FIRST CARD                  07510015
*********************************************************************** 07550015
       SPACE                                                            07600015
       EJECT                                                            07650015
*              THIS ROUTINE PERFORMS THE MAIN SCAN FOR THIS PHYSICAL    07700015
*        PHASE.                                                         07750015
*              IT IS THE FIRST ROUTINE ENTERED AFTER THE INITIALISATION 07800015
*        OF THIS PHYSICAL PHASE IS COMPLETED.                           07850015
*              IT IS ENTERED WITH THE INPUT TEXT POINTER DP POINTING    07900015
*        AT A STATEMENT KEYWORD, A STATEMENT LABEL, A PREFIX OPTION     07950015
*        OR THE START OF AN ASSIGNMENT STATEMENT OR NULL STATEMENT.     08000015
*              ITS PRIME FUNCTION IS TO TRANSLATE STATEMENT KEYWORDS    08050015
*        INTO INTERNAL CODE AND IDENTIFY THESE KEYWORDS BY BRANCHING    08100015
*        TO THE APPROPRIATE ROUTINE TO DIAGNOSE THAT STATEMENT.         08150015
*              AFTER TRANSLATING A VALID KEYWORD TO INTERNAL CODE,      08200015
*        IT CHECKS FOR THE STATEMENT BEING AN ASSIGNMENT STATEMENT      08250015
*        BY TESTING FOR AN EQUALS SIGN FOLLOWING THE KEYWORD.           08300015
*        THE CHARACTER FOLLOWING THE STATEMENT KEYWORD 'DECLARE'        08350015
*        IS CHECKED IN GREATER DETAIL FOR THE POSSIBILITY OF THE        08400015
*        STATEMENT BEING AN ASSIGNMENT STATEMENT. ALL STATEMENTS ARE    08450015
*        CHECKED FURTHER FOR BEING POSSIBLE ASSIGNMENT STATEMENTS BY    08500015
*        THEIR INDIVIDUAL STATEMENT PROCESSING ROUTINES.                08550015
*              IT KEEPS A COUNT OF THE STATEMENT NUMBER AND SAVES IT    08600015
*        IN A SLOT CALLED ZSTAT IN THE DICTIONARY.                      08650015
*              IT MAY PERFORM MORE THAN ONE SCAN ON A SINGLE            08700015
*        STATEMENT. FOR THIS REASON A SWITCH CALLED NUMSW IS SET ON     08750015
*        DURING THE FIRST SCAN TO INDICATE THAT THE STATEMENT HAS       08800015
*        BEEN NUMBERED.                                                 08850015
*              IT IDENTIFIES STATEMENT LABELS, INITIAL VALUES ON        08900015
*        LABELS AND PREFIX OPTIONS, AND CALLS THE ROUTINES TO HANDLE    08950015
*        THEM.                                                          09000015
*                                                                       09050015
*              IT CHECKS THE FIRST STATEMENT TO SEE IF IT IS A          09100015
*        PROCEDURE STATEMENT. IF IT IS NOT A PROCEDURE STATEMENT        09150015
*        THIS ROUTINE INSERTS A DUMMY PROCEDURE STATEMENT AND           09200015
*        ADDS ONE TO THE STATEMENT COUNT.  THIS DUMMY PROCEDURE         09250015
*        STATEMENT HAS NO LABEL, A UNIQUE LABEL WILL BE GENERATED FOR   09300015
*        IT IN A LATER PHYSICAL PHASE. FOR THIS REASON THE FORM OF      09350015
*        THE DUMMY PROCEDURE STATEMENT IS DIFFERENT TO A NORMAL         09400015
*        PROCEDURE STATEMENT SO THAT THE LATER PHASE CAN RECOGNISE      09450015
*        IT AS HAVING NO LABEL AND MAY COLLECT THE INFORMATION FROM     09500015
*        IT WHICH IS NECESSARY TO MAKE A DICTIONARY ENTRY OF THE UNIQUE 09550015
*        LABEL.                                                         09600015
*                                                                       09650015
*              ENTRY POINTS. (1) AFTER INITIALISATION OF THIS PHYSICAL  09700015
*        PHASE IS COMPLETED, ENTRY IS TO THE FIRST INSTRUCTION OF THIS  09750015
*        ROUTINE.                                                       09800015
*                            (2) SUBSEQUENT ENTRIES TO THIS ROUTINE     09850015
*        WITH THE INPUT TEXT POINTER DP POINTING AT THE START OF A      09900015
*        STATEMENT IS AT RSTART.                                        09950015
*                            (3) THE ENTRY POINT FOR THE SECOND SCAN    10000015
*        OF A SINGLE STATEMENT IS TO RLETTR.                            10050015
*                            (4) THE ENTRY POINT STOK IS USED WHEN      10100015
*        IT IS REQUIRED THAT THE SEMI COLON BE MOVED TO THE OUTPUT      10150015
*        TEXT.                                                          10200015
*                                                                       10250015
*              EXITS - NORMAL.  AT THE BEGINNING OF THE SCAN BY THIS    10300015
*        PHASE THE FLAG 'ENDFLG' IN A SLOT IN THE DICTIONARY IS TESTED, 10350015
*        IF IT IS 'ON' THEN THE LOGICAL END OF THE SOURCE PROGRAM HAS   10400015
*        BEEN REACHED, SO A BRANCH IS MADE TO THE ROUTINE LOPEND TO     10450015
*        PASS CONTROL TO THE NEXT PHYSICAL PHASE.                       10500015
*                                                                       10550015
*              EXITS - ERROR.  N/A.                                     10600015
*                                                                       10650015
*                                                                       10700015
*                                                                       10750015
         BAL   RR,INCR                  BUMP TO FIRST NON-BLANK CHAR    10800015
         STH   UR,ZSTAT(GRDIC)         FIRST STATEMENT MUST HAVE        10850015
         MVI   NUMSW(GRDIC),ALLONE     A NUMBER IN CASE OF ERRORS       10900015
         MVI   CARDNO(GRDIC),ALLONE      THE STATEMENT NUMBER           10950015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 010-TSS 10970020
         MVC   OUTBUF+3(6,GRDIC),WORK+2  MUST BE PRINTED TOO            11000015
*        ----------------------------------------------------CI 010-TSS 11020020
         STH   UR,CMPLBL(GRDIC)        SET UP COMPILER LABEL SLOT       11050015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 005-TSS 11070019
         BC    B,STARTA                                                 11100015
*        ----------------------------------------------------CI 005-TSS 11120019
         SPACE                                                          11150015
RSTART   MVI   LBLPOP,NONE   TURN OFF LABEL AND PREFIX OPTION FLAG47697 11200056
RSTRT1   MVI   NUMSW(GRDIC),NONE       SET NUMSW OFF                    11250015
         MVI   STYPE(GRDIC),NONE       SET STATEMENT TYPE TO NULL       11300015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 022-TSS 11310021
*        ----------------------------------------------------CI 022-TSS 11320021
         CLI   ENDFLG(GRDIC),X'FF'     IS THERE SOURCE TEXT AFTER LOP   11350015
         BC    BNE,STARTA                                               11400015
         SPACE                                                          11450015
         BAL   RR,MESAGE(0,GR12)       YES - PUT OUT MESSAGE 99 -       11500015
         DC    X'6344'                 TEXT FOLLOWING LOGICAL END.      11550015
         L     OP,SPO(0,GRDIC)         RESET OUTPUT POINTER             11600015
         CLI   0(OP),SL                DOES PREV STATEMENT         H220 11610001
         BNE   NOLAB                   HAVE A LABEL.  NO.          H220 11620001
         MVI   3(OP),X'9D'             CHANGE PREVIOUS STATEMENT   H220 11630001
         MVI   4(OP),X'EF'             TO A NULL STATEMENT.        H220 11640001
         LA    OP,5(OP)                POINT TO NEXT STATEMENT.    H220 11650001
NOLAB    BAL   RR,SOFLOW(0,GR12)       BUMP STACK POINTER          H220 11660001
         MVI   ENDFLG(GRDIC),NONE      RESET END FLAG                   11700015
         STC   UR,BKL(0,GRDIC)         SET LEVEL COUNT BACK TO ONE      11750015
         SPACE                                                          11800015
STARTA   ST    OP,SPO(0,GRDIC)                                          11850015
RLETTR   BAL   RR,TRCHAR(0,GR15)       TEST FOR AN ALPHABETIC           11900015
         BC    BNH,RCOM                                                 11950015
RSPR     ST    DP,SPR(0,GRDIC)                                          12000015
RNOON    CLI   NUMSW(GRDIC),NONE       TEST IF STATEMENT NUMBERED       12050015
         BC    BNZ,RNULL                                                12100015
         LH    GRA,ZSTAT(0,GRDIC)                                       12150015
         AR    GRA,UR                   ADD 1 TO ZSTAT                  12200015
         STH   GRA,ZSTAT(0,GRDIC)                                       12250015
       SPACE 1                                                          12255017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 003-TSS 12256019
*        ----------------------------------------------------CI 003-TSS 12257019
*              THERE IS A STATISTICAL PROGRAM IN THE O/S            I16 12260017
*        WHICH NEEDS TO KNOW THE MAXIMUM STATEMENT NUMBER COUNT.    I16 12265017
*        WE PUT THIS IN THE COMMUNICATIONS REGION FOR A MUCH LATER  I16 12270017
*        PHASE (AROUND TP) TO PROCESS.                              I16 12275017
       SPACE 1                                                          12280017
         STH   GRA,STMNTN(0,GRDIC)                                  I16 12285017
       SPACE 1                                                          12290017
         MVI   NUMSW(GRDIC),ALLONE     SET NUMSW ON                     12300015
         MVI   LCNT(GR10),NONE       SET INITIAL LABEL FLAGS OFF        12350015
         CLI   CARDNO(GRDIC),ALLONE                                     12400015
         BC    BZ,RNULL                                                 12450015
         STH   GRA,OSTAT(0,GRDIC)                                       12500015
BINDEC CVD     GRA,WORK                                                 12550015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 011-TSS 12570020
         MVC   OUTBUF+3(6,GRDIC),PATERN                                 12600015
        ED    OUTBUF+3(6,GRDIC),WORK+5                                  12650015
*        ----------------------------------------------------CI 011-TSS 12670020
         MVI   CARDNO(GRDIC),ALLONE                                     12700015
         TM    CCCODE+3(GRDIC),X'01'                                    12710015
         BC    BZ,RNULL                                                 12715015
         BAL   RR,NEST(0,GR10)                                          12720015
RNULL    CLI   POPSW(GRDIC),ALLONE                                      12750015
         BC    BE,POPM                                                  12800015
         CLI   NULLSW,ALLONE                                            12850015
         BC    BZ,NULLST                                                12900015
RALPH    BAL   RR,BUMP1(0,GR12)        BUMP DP BY 1                 I16 13000017
ALPHA    BAL   RR,TRCHAR(0,GR15)       TEST FOR AN ALPHAMERIC           13150015
         BC    BNE,RALPH                                                13200015
         BAL   RR,INCR                  BUMP TO NEXT NON-BLANK          13250015
RLABEL   CLI   0(DP),COLON                                              13300015
*                                      IS NEXT I/P CHAR. A COLON? 30321 13308020
         BNE   LPARTST                 NO                         30321 13316020
         LA    GRA,LABELS             POINT GRA AT LABELS         30321 13324020
ONUNITST CLI   ONSW(GR10),ALLONE       START OF AN ON-UNIT?       30321 13332020
         BCR   BNE,GRA                 NO,GO TO ADDRESS IN GRA    30321 13340020
         MVI   LCNT(GR10),NONE         SET OFF LABEL FLAG         30321 13344020
         MVC   PAR7(4,GRDIC),SPR(GRDIC) PASS A(START OF STAT.)    30321 13348020
         BAL   RR,MESAGE(0,GR12)       MESSAGE 125 -              30321 13356020
         DC    X'7DC8'                 ILLEGAL LABEL ON ON-UNIT   30321 13364020
         AR    DP,UR                   DP=DP+1                    30321 13372020
         B     RLETTR                  START SCAN AFTER COLON     30321 13380020
LPARTST  EQU   *                                                  30321 13388020
         CLI   0(DP),LPAR               TEST FOR LEFT PARENTHESIS       13400015
         BNE   NOTLPAR                 NO                         30321 13430020
         BAL   RR,INLBL(0,GR10)        CHECK FOR INITIAL LABEL          13500015
         LA    GRA,LABSUB              POINT GRA AT LABSUB        30321 13510020
         B     ONUNITST                                           30321 13530020
NOTLPAR  MVI   ONSW(GR10),NONE         SET OFF ON SWITCH          30321 13560020
STID     MVI   ALFFLG,X'00'                                             13600015
         BAL   RR,TRCHAR(0,GR15)                                        13650015
         BC    BNH,*+8                                                  13700015
         OI   ALFFLG,X'01'             SET ALPHABETIC FLAG              13750015
         L     DP,SPR(0,GRDIC)                                          13800015
         XR    GRA,GRA                                                  13850015
         BAL   RR,KEYWD(0,GR12)                                         13900015
         BC    B,ASSL                                                   13950015
         STC   GRA,ZFLAG2(0,GRDIC)     SAVE POSSIBLE STAT. TYPE   28518 13970020
         CLI   0(DP),EQUALS                                             14000015
         BC    BE,ASSN                                                  14050015
         CLI   0(DP),COMMA                                              14100015
         BC    BE,ASSN                                                  14150015
         CLI   0(DP),MINUS             TEST FOR POINTER QUALIFICATION   14200015
         BC    BNE,NOERP                                                14250015
         BAL   RR,BUMP1(0,GR12)        BUMP DP BY 1                 I16 14350017
         CLI   0(DP),GT                E.G. ' DO PT Z =... '            14500015
         BC    BE,ASSN                                                  14550015
         SR    DP,UR                                                    14600015
NOERP    CLI   0(DP),PERIOD                                             14650015
         BC    BNE,NOERQ                                                14700015
         ST    DP,START3(0,GRDIC)                                       14750015
         BAL   RR,BUMP                 BY AN ALPHABETIC                 14800015
         BAL   RR,TRCHAR(0,GR15)       IN CASE OF                       14850015
         BC    BH,ASSN               ' IF .3 GT A '                     14900015
         L     DP,START3(0,GRDIC)                                       14950015
NOERQ    STC   GRA,STYPE(GRDIC)                                         15000015
NOERR    MVI   ERRFLG(GRDIC),NONE                                       15050015
         BC    B,FSTST                                                  15100015
NULLST   MVI   NULLSW,NONE              SET UP FOR NULL STATEMENT       15150015
         MVI   STYPE(GRDIC),NLTYPE                                      15200015
         BC    B,NOERR                                                  15250015
ASSL     TM    ALFFLG,X'01'                                             15300015
         BC    BO,LABELS                                                15350015
ASSN     L     DP,SPR(0,GRDIC)                                          15400015
         MVI   STYPE(GRDIC),ASTYPE                                      15450015
FSTST    CLC   ZSTAT(2,GRDIC),ONE                                       15500015
         BC    BNZ,RDOWN                                                15550015
         CLI   STYPE(GRDIC),PRTYPE                                      15600015
         BC    BNZ,NOPROC                                               15650015
         MVI   STYPE(GRDIC),P1TYPE                                      15700015
         BC    B,RDOWN                                                  15750015
RCOM     CLI   0(DP),LPAR                                               15800015
         BC    BE,POPLST                                                15850015
         MVI   ONSW(GR10),NONE         SET OFF ON SWITCH          30321 15870020
         CLI   0(DP),SCOLON                                             15900015
         BC    BNE,BADST1                                               15950015
         MVI   NULLSW,ALLONE            SET NULLSW ON                   16000015
         MVI   ERRFLG(GRDIC),NONE                                       16050015
         BC    B,RSPR                                                   16100015
NOPROC   BAL   RR,MESAGE(0,GR12)       MESSAGE 111 - FIRST STATEMENT    16150015
         DC    X'6F04'                                                  16200015
         LA    GRA,10(0,0)                                              16250015
         BAL   RR,OPTEST(0,GR12)                                        16300015
         MVC   0(10,OP),DMPROC         MOVE DUMMY PROC TO OUTPUT        16350015
         AR    OP,GRA                                                   16400015
         ST    OP,SPO(0,GRDIC)                                          16450015
         MVC   BKL(2,GRDIC),DMPROC+7                                    16500015
         LH    GRA,ZSTAT(0,GRDIC)                                       16550015
         AR    GRA,UR                                                   16600015
         STH   GRA,ZSTAT(0,GRDIC)                                       16650015
         L     GRA,STP(0,GRDIC)                                         16700015
         ST    UR,0(0,GRA)                                              16750015
         MVI   0(GRA),X'80'                                             16800015
RDOWN    LA    GRA,3(0,0)                                               16850015
         BAL   RR,OPTEST(0,GR12)                                        16900015
         CLI   LBLPOP,NONE   BRANCH IF NO LABELS OR PREFIX        47697 16950056
         BC    BE,RMOVE              OPTIONS                            17000015
         MVC   1(2,OP),LBLPTR(GRDIC)                                    17050015
         TM    LCNT(GR10),X'40'                                         17100015
         BC    BO,PUTXD3               IF INITIAL                       17150015
         MVI   0(OP),SL                LABEL                            17200015
         BC    B,RSTERR                THEN                             17250015
PUTXD3   MVI   0(OP),SLDASH            PUT SL'                          17300015
         BC    B,RSTERR                                                 17350015
RMOVE    MVI   0(OP),SN                 MOVE SN,ZSTAT TO OP -  3 BYTES  17400015
         MVC   1(2,OP),ZSTAT(GRDIC)                                     17450015
RSTERR   AR    OP,GRA                                                   17500015
         MVC   ERRPTR(2,GRDIC),ZNXTOF(GRDIC)     SAVE NEXT OFFSET SLOT  17550015
         MVC   ERRPTR+2(2,GRDIC),ZNXTD(GRDIC)    AND NEXT DIC.REF.SLOT  17600015
         MVC   FRED(32,GR10),ZERRD(GRDIC)                               17650015
         BAL   GRA,FREEZE(GR12)                                         17670015
         LR    GRC,DP                                                   17700015
         S     GRC,SPR(0,GRDIC)                                         17750015
         ST    GRC,TEXTST(0,GRDIC)                                      17800015
         MVI   PSTYPE(GRDIC),NONE                                       17850015
MVTYPE   BAL   RR,OPTST1(0,GR12)                                        17900015
         MVC   0(1,OP),STYPE(GRDIC)                                     17950015
         AR    OP,UR                                                    18000015
         MVI   PAS(GRDIC),NONE                                          18050015
         XR    GRD,GRD                                                  18100015
         IC    GRD,STYPE(0,GRDIC)                                       18150015
         SH    GRD,X81                 SOBTRACT 81 FROM   STYPE         18200015
         SRL   GRD,1(0)                                                 18250015
         STC   GRD,TYPE                                                 18300015
         TR    TYPE(1),STAB                                             18350015
         IC    GRD,TYPE                                                 18400015
         BC    B,*(GRD)                                                 18450015
         BC    B,PROC                                                   18500015
         BC    B,ENTRY                                                  18550015
         BC    B,ASSIGN(0,GR10)                                         18600015
         BC    B,DO(0,GR10)                                             18650015
         BC    B,BEGIN(0,GR10)                                          18700015
         BC    B,END(0,GR10)                                            18750015
         BC    B,STAT2(0,GR10)                                          18800015
         BC    B,NULL                                                   18850015
         BC    B,IF(0,GR10)                                             18900015
         BC    B,ELSE(0,GR10)                                           18950015
        BC    B,ON(0,GR10)                                              19000015
         BC    B,PROC1                                                  19050015
         BC    B,SIGRVT(0,GR10)                                         19100015
         BC    B,STAT2(0,GR10)         DECLARE                          19150015
         SPACE 3                                                        19200015
RDERR    L     OP,SPO(0,GRDIC)                                          19250015
         LA    OP,3(0,OP)               SET OP=SPO+3                    19300015
         BC    B,MVTYPE                                                 19350015
         SPACE 3                                                        19400015
***************************************************************** 47697 19410056
*              THE FOLLOWING CODE WAS REORGANISED TO SAVE 8 BYTES 47697 19420056
*        AND THUS MAKE ROOM FOR APAR 47697 FIX (V 5.3B). CHANGED  47697 19430056
*        STATEMENTS ARE FLAGGED 47697 BUT THEY ARE NOT AN INHERENT47697 19440056
*        PART OF THE FIX.                                         47697 19450056
***************************************************************** 47697 19460056
         SPACE 1                                                        19470056
NULL     BAL   RR,CHECK(0,GR12)                                   47697 19480056
STOK     XC    SPR(4,GRDIC),SPR(GRDIC)                            47697 19490056
         CLI   0(DP),SCOLON            TEST FOR SEMI-COLON        47697 19500056
         BC    BE,NOSC1                                           47697 19510056
         BAL   RR,MESAGE(0,GR12)       MESSAGE 96-SEMI-COL INSRTED47697 19520056
         DC    X'6048'                                            47697 19530056
         SR    DP,UR                                              47697 19540056
NOSC1    BAL   RR,OPTST1(0,GR12)                                        19600015
         MVI   0(OP),SCOLON                                             19650015
         BAL   RR,STSCOP(0,GR10)       SAVE POSN OF SEMICOLON           19700015
         AR    OP,UR                                                    19750015
         BAL   RR,BUMP                 SKIP OVER THE SEMI-COLON         19800015
         BC    B,RSTART                                                 19850015
         SPACE 3                                                        19900015
       EJECT                                                            20300015
*              THIS ROUTINE HANDLES LABELS ON STATEMENTS.               20350015
*              THE MAIN SCAN ROUTINE FOR THIS PHYSICAL PHASE CHECKS     20400015
*        THAT THE CHARACTERS IN THE LABEL ARE VALID, IF THEY ARE VALID  20450015
*        IT CALLS THIS ROUTINE.                                         20500015
*              THIS ROUTINE IS ALSO CALLED BY THE ROUTINE THAT          20550015
*        GENERATES DUMMY STATEMENT LABELS. THE ENTRY POINT IS ALABEN    20600015
*        AND ONLY CONTAINING BLOCK LEVELS AND COUNTS ARE REQUIRED BY    20650015
*        THE CALLING ROUTINE.                                           20700015
*              FOR NORMAL LABELS IT IS ENTERED WITH THE INPUT TEXT      20750015
*        POINTER DP POINTING AT THE COLON ON THE LABEL WHICH THIS       20800015
*        ROUTINE IS TO PROCESS.                                         20850015
*              THE POINTER DP IS SET BACK TO THE START OF THE LABEL     20900015
*        AND THE LABEL IS CHECKED FOR BEING A VALID IDENTIFIER. ON      20950015
*        RETURN FROM THE ROUTINE THAT CHECKS THE IDENTIFIER,THE OUTPUT  21000015
*        TEXT POINTER OP IS RESET SO THAT THE LABEL IS LATER            21050015
*        OVERWRITTEN.                                                   21100015
*              THE LABEL IS TO BE PUT INTO THE DICTIONARY, A BUILD      21150015
*        AREA CALLED 'LABENT' IS USED IN WHICH TO FORM THE COMPLETE     21200015
*        LABEL ENTRY FOR ENTRY INTO THE DICTIONARY.                     21250015
*              THE BCD OF THE LABEL IS MOVED INTO LABENT PRECEDED BY A  21300015
*        ONE BYTE SLOT CONTAINING A COUNT OF ONE LESS THAN THE NUMBER   21350015
*        OF CHARACTERS IN THE LABEL.                                    21400015
*              THE NUMBER OF THE STATEMENT ON WHICH THE LABEL APPEARS   21450015
*        IS MOVED INTO LABENT.                                          21500015
*              SOME BLOCK LEVELS AND BLOCK COUNTS ARE NEEDED TO GO      21550015
*        INTO LABENT. (1) A COUNT OF THE CURRENT BLOCK LEVEL IS         21600015
*        OBTAINED FROM A SLOT IN THE DICTIONARY.                        21650015
*                     (2) THE BLOCK COUNT OF THE NEAREST CONTAINING     21700015
*        PROCEDURE OR BEGIN STATEMENT IS OBTAINED FROM THE STACK.       21750015
*                     (3) ANOTHER BLOCK COUNT IS REQUIRED THAT IS THE   21800015
*        BLOCK COUNT OF THE NEAREST CONTAINING ITERATIVE DO,            21850015
*        PROCEDURE OR BEGIN STATEMENT. THIS BLOCK COUNT IS ALSO         21900015
*        OBTAINED FROM THE STACK. OBVIOUSLY IF THE NEAREST CONTAINING   21950015
*        BLOCK IS NOT THAT OF AN ITERATIVE DO, THIS COUNT WILL BE THE   22000015
*        SAME COUNT AS OBTAINED FOR (2) ABOVE.                          22050015
*              IF THIS LABEL IS NOT THE FIRST LABEL ON THIS STATEMENT,  22100015
*        THIS ROUTINE SETS ON A BIT IN THE PREVIOUS LABEL DICTIONARY    22150015
*        ENTRY. THIS BIT INDICATES THAT ANOTHER LABEL FOLLOWS ON THIS   22200015
*        STATEMENT.                                                     22250015
*              IF THIS LABEL IS THE FIRST LABEL ON THIS STATEMENT,      22300015
*        THE DICTIONARY REFERENCE OF THIS LABEL IS STORED IN THE        22350015
*        SLOT LBLPTR IN THE DICTIONARY. THIS WILL BE USED BY THE MAIN   22400015
*        SCAN ROUTINE WHEN IT INSERTS THE LABEL DICTIONARY REFERENCE    22450015
*        INTO THE STATEMENT.                                            22500015
*                                                                       22550015
*              ENTRY POINTS.  (1) IF ALL THE FUNCTIONS OF THIS          22600015
*        ROUTINE ARE REQUIRED THEN ENTRY IS TO LABELS.                  22650015
*                             (2) IF ONLY THE CONTAINING BLOCK LEVEL    22700015
*        AND BLOCK COUNTS ARE REQUIRED THEN ENTRY IS TO ALABEN.         22750015
*                                                                       22800015
*              EXITS - NORMAL.  (1) IF THIS ROUTINE WAS CALLED BY THE   22850015
*        DUMMY LABEL GENERATING ROUTINE THEN EXIT IS BY A BRANCH TO     22900015
*        COMPLB IN THE DUMMY LABEL GENERATING ROUTINE.                  22950015
*                               (2) IF THIS ROUTINE WAS CALLED BY THE   23000015
*        MAIN SCAN ROUTINE THEN RETURN IS BY A BRANCH TO RLETTER IN     23050015
*        THE MAIN SCAN ROUTINE.                                         23100015
*                                                                       23150015
*                                                                       23200015
*                                                                       23250015
LABELS   NI    LCNT(GR10),X'7F'        SET INITIAL LABEL FLAG OFF       23300015
LABSUB   L     DP,SPR(0,GRDIC)         RESTORE DATA POINTER             23350015
         MVI   LABENT,X'00'            CODE BYTE FOR LABEL IS 0         23400015
         MVC   LABENT+8(2),ZSTAT(GRDIC)  STAT NO TO LABENT              23450015
         ST    OP,OPP(0,GRDIC)            STORE OP                      23500015
         BAL   RR,IDENT(0,GR15)                                         23550015
         L     OP,OPP(0,GRDIC)         RESET THE                        23600015
*                                      OUTPUT POINTER TO THE START OF   23650015
*                                      THE STATEMENT                    23700015
         SPACE                                                          23750015
         XR    GRE,GRE                 GET THE LENGTH OF THE BCD INTO   23800015
         IC    GRE,0(0,OP)             A SCRATCH REGISTER.              23850015
         SPACE                                                          23900015
         STC   GRE,*+5                 MOVE THE BCD INTO THE ENTRY      23950015
         MVC   LABENT+19(0),0(OP)                                       24000015
         SPACE                                                          24050015
         STC   GRE,LCNT+1(GR10)         SAVE BCD-LENGTH                 24100015
         SR    GRE,UR                  GET LENGTH - 1 FOR DICTIONARY    24150015
         TM    LCNT(GR10),X'80'        IF INITIAL LABEL                 24200015
         BC    BZ,LABSUC               ADD SUBSCRIPT LENGTH             24250015
         LH    GRD,LCNT+2(GR10)                                         24300015
         AR    GRE,GRD                                                  24350015
LABSUC   STC   GRE,LABENT+19           PUT LENGTH IN THE ENTRY          24400015
         SPACE                                                          24450015
         LA    GRE,21(0,GRE)           STORE THE TOTAL LENGTH OF THE    24500015
         ST    GRE,PAR2(0,GRDIC)       ENTRY IN A PARAMETER SLOT.       24550015
         SPACE                                                          24600015
*              HERE WE MUST DEAL WITH THE BLOCK LEVELS AND COUNTS.      24650015
         SPACE                                                          24700015
ALABEN   MVC   LABENT+17(1),BKL(GRDIC)   MOVE IN THE CURRENT BLOCK      24750015
*                                        LEVEL.                         24800015
         L     GRE,STP(0,GRDIC)        POINT A REGISTER AT THE STACK    24850015
         SPACE                                                          24900015
LLAB0    CLI   0(GRE),X'84'            LOOK FOR AN ITERATIVE DO.        24950015
         BC    BNE,LLAB2                                                25000015
         SPACE                                                          25050015
LLAB1    BC    0,LLAB2                                                  25100015
         MVC   LABENT+16(1),3(GRE)     THE FIRST TIME WE FIND AN        25150015
         MVI   LLAB1+1,X'F0'           ITERATIVE DO WE SET THE 'THIS    25200015
*                                      BLOCK' COUNT.                    25250015
         SPACE                                                          25300015
LLAB2    CLI   0(GRE),X'80'            TEST THE ENTRY FOR PROCEDURE     25350015
         BC    BE,LLAB2A               AND BEGIN.                       25400015
         CLI   0(GRE),X'81'                                             25450015
         BC    BE,LLAB2A                                                25500015
         C     GRE,BSTACK(0,GRDIC)     CHECK TO SEE IF WE ARE AT THE    25550015
*                                    BOTTOM OF THE STACK.               25600015
         BC    BNE,LLAB4             IF NO, LOOK AT PREVIOUS STACK      25650015
*                                    ENTRY.                             25700015
       SPACE                                                            25750015
*              WE HAVE REACHED THE BOTTOM OF THE STACK. THE STATEMENT   25800015
*        MUST BE THE FIRST PROCEDURE STATEMENT.                         25850015
         MVC   LABENT+16(3),ZERO       SET CONTAINING BLOCK LEVEL AND   25900015
*                                    COUNTS TO ZERO IN LABEL ENTRY.     25950015
         BC    B,RDE                                                    26000015
       SPACE                                                            26050015
         SPACE                                                          26100015
LLAB2A   MVC   LABENT+18(1),3(GRE)     WHEN WE FIND A PROCEDURE OR      26150015
         CLI   LLAB1+1,X'00'           BEGIN WE SET THE 'CONTAINING     26200015
         BC    BNE,LLAB3               BLOCK' COUNT.   IF WE HAVE NOT   26250015
         MVC   LABENT+16(1),3(GRE)     ALREADY FOUND AN ITERATIVE DO    26300015
         BC    B,RDE                   THIS IS ALSO THE 'THIS BLOCK'    26350015
LLAB3    MVI   LLAB1+1,X'00'           COUNT.                           26400015
         BC    B,RDE                                                    26450015
         SPACE                                                          26500015
LLAB4    SH    GRE,FOUR                                                 26550015
         BC    B,LLAB0                                                  26600015
RDE      CLI   NOLBFL,NONE             DOES THE STATEMENT HAVE A LABEL  26650015
         BC    BNE,COMPLB            IF NO THEN BRANCH.                 26700015
         TM    LBLPOP,MIXED1         LABEL ALREADY FOR STATEMENT? 47697 26707056
         BC    BZ,RDE1                 NO                         47697 26714056
         SPACE 1                                                        26721056
***************************************************************** 47697 26728056
*              THE FOLLOWING CODE WAS MOVED HERE TO SAVE 4 BYTES  47697 26735056
*        AND THUS MAKE ROOM FOR APAR 47697 FIX (V 5.3B). ALTHOUGH 47697 26742056
*        THE STATEMENTS ARE FLAGGED 47697 (EXCEPT FOR ONE, WHICH  47697 26749056
*        WAS ALREADY FLAGGED 36960), THEY ARE NOT AN INHERENT     47697 26756056
*        PART OF THE FIX.                                         47697 26763056
***************************************************************** 47697 26770056
         SPACE 1                                                        26777056
*        WE HAVE GOT MULTIPLE LABELS, SO MUST PUT SOME BITS ON    47697 26784056
         MVC   PAR1+2(2,GRDIC),DICPTR(GRDIC) GET ABSOLUTE ADDRESS 47697 26791056
         L     LR,ZDRFAB(0,GRCC)       OF PREVIOUS LABEL ENTRY    47697 26798056
         BALR  RR,LR                                              47697 26805056
         L     GR15,BASEBA(0,GRDIC)                               47697 26812056
         L     GRD,PAR1(0,GRDIC)                                  47697 26819056
         OI    10(GRD),MLBADC     SET MULT LABEL & ADCON REQ BITS 36960 26826056
RDE1     LA    GRD,LABENT              ADDRESS OF DICTIONARY ENTRY      26850015
         ST    GRD,PAR1(0,GRDIC)                                        26900015
RDENT    L     LR,ZDRFOF(0,GRCC)                                        26950015
         BALR  RR,LR                                                    27000015
         L     GR15,BASEBA(0,GRDIC)                                     27050015
         TM    LCNT(GR10),X'80'        TEST FOR SUBSCRIPTS              27100015
         BC    BO,SUBSCR               IF SO, PUT THEM IN THE           27150015
RDE4     MVI   ERRFLG(GRDIC),NONE      DICTIONARY ENTRY                 27200015
         CLI   LBLPOP,NONE   SAVE THE DICT REF IN LBLPTR IF       47697 27250056
         BC    BNE,RDE2              IT IS THE FIRST LABEL OR PREFIX    27300015
         MVC   LBLPTR(2,GRDIC),PAR1+2(GRDIC)    OPTION.                 27350015
RDE2     CLI   POPSW(GRDIC),ALLONE                                  H70 27400017
         BC    BE,RDE3                                             H70  27450017
         CLI   0(DP),COLON                                         H70  27500017
         BC    BE,RDE5                                             H70  27550017
         BAL   RR,MESAGE(0,GR12)       MESSAGE 95 - LABEL ON STATEMENT  27600015
         DC    X'5F48'                 HAS NO COLON. ONE ASSUMED        27650015
         SR    DP,UR                                                    27700015
RDE5     MVC   DICPTR(2,GRDIC),PAR1+2(GRDIC)  SAVE DIC. REF.            27750017
         BAL   RR,BUMP                 IN DICPTR                        27800017
         OI    LBLPOP,MIXED1           PUT LABEL SWITCH ON        47697 27850056
         BC    B,RLETTR                                                 27900015
RDE3     MVI   POPSW(GRDIC),NONE       SET POPSW OFF AGAIN              27950015
         OI    LBLPOP,MIXED2           PUT PREFIX OPTION SWITCH ON47697 28000056
         BC    B,RLETTR                                                 28050015
         EJECT                                                          28100015
         SPACE                                                          28150015
*        THIS ROUTINE INSERTS THE SUBSCRIPTS OF INITIAL LABELS INTO THE 28200015
*        DICTIONARY.                                                    28250015
*        IT IS ENTERED WITH                                             28300015
*         (1)  THE D.R. OF THE ENTRY IN PAR1                            28350015
*         (2)  THE LENGTH OF THE BCD IN LCNT+1                          28400015
*         (3)  THE ADDRESS OF THE LEFT PARENTHESIS IN START2            28450015
*                                                                       28500015
SUBSCR   SR    GRD,GRD                                                  28550015
         IC    GRD,LCNT+1(GR10)                                         28600015
         MVC   LCNT+2(2,GR10),PAR1+2(GRDIC) SAVE D.R.                   28650015
         L     LR,ZDRFAB(0,GRCC)       CONVERT D.R.                     28700015
         BALR  RR,LR                   TO ABSOLUTE                      28750015
         L     GR15,BASEBA(0,GRDIC)    POINT GRD AT THE SPACE IN THE    28800015
         LA    GRD,20(GRD)             DICTIONARY ENTRY WHERE THE       28850015
         A     GRD,PAR1(0,GRDIC)       SUBSCRIPTS MUST GO               28900015
         L     DP,START2(0,GRDIC)      POINT DP AT THE (                28950015
SUBSC1   MVC   0(1,GRD),0(DP)                                           29000015
         AR    GRD,UR                  INSERT CHARACTER AND BUMP        29050015
SUBSC2   BAL   RR,BUMP                 UNLESS IT'S A PLUS               29100015
         CLI   0(DP),PLUS                                               29150015
         BC    BE,SUBSC2                                                29200015
         CLI   0(DP),RPAR                                               29250015
         BC    BNE,SUBSC1                                               29300015
         MVI   0(GRD),RPAR                                              29350015
*                                 THE SUBSCRIPTS SHOULD NOW BE IN       29400015
*                                 THE DICTIONARY ENTRY WITHOUT ANY      29450015
*                                 BLANKS OR PLUS SIGNS.                 29500015
         BAL   RR,BUMP                 SKIP OVER THE RIGHT PAREN        29550015
         ST    UR,PAR1(0,GRDIC)                                         29600015
         MVC   PAR1+2(2,GRDIC),LCNT+2(GR10) RESTORE PAR1 AND RETURN     29650015
         BC    B,RDE4                                                   29700015
         SPACE 5                                                        29750015
***************************************************************** 47697 29810056
*              CODE TO SET MULTIPLE LABEL AND ADCON REQUIRED      47697 29870056
*        BITS WAS MOVED FROM HERE TO A POSITION IMMEDIATELY       47697 29930056
*        PRECEDING LABEL RDE1. THE CODE INCLUDES A STATEMENT      47697 29990056
*        FLAGGED 36960. BY MOVING THE CODE, 4 BYTES WERE SAVED.   47697 30050056
***************************************************************** 47697 30110056
       EJECT                                                            30200015
*              THIS ROUTINE READS A SOURCE RECORD INTO CORE AND         30250015
*        PRODUCES THE SOURCE LISTING COMPLETE WITH STATEMENT NUMBERS.   30300015
*        IT CHECKS FOR THE END OF THE SOURCE PROGRAM AND PASSES         30350015
*        CONTROL TO THE NEXT PHYSICAL PHASE.                            30400015
*             THE AREA INTO WHICH A SOURCE RECORD IS READ IS CALLED THE 30450015
*        READ AREA. IT WAS OBTAINED DURING THE INITIALISATION           30500015
*        OF THIS PHYSICAL PHASE, ITS SIZE WAS SPECIFIED BY COMPILER     30550015
*        CONTROL.                                                       30600015
*              THE AREA IN THE DICTIONARY IN WHICH EACH LINE OF THE     30650015
*        SOURCE LISTING IS FORMED IS CALLED THE OUTPUT BUFFER.          30700015
*              THIS ROUTINE CHECKS TO SEE IF THERE IS ENOUGH ROOM IN    30750015
*        THE READ AREA FOR THE RECORD. IF THERE IS NOT, IT MOVES THE    30800015
*        EXISTING STATEMENT TO THE START OF THE READ AREA. IF THE       30850015
*        STATEMENT IS TOO LONG FOR THE READ AREA, AND IS NOT A DECLARE  30900015
*        STATEMENT, A TERMINAL ERROR OCCURS.                            30950015
*              ON REACHING THE PHYSICAL END OF SOURCE PROGRAM IT        31000015
*        TESTS THE FLAG 'ENDFLG' TO SEE IF THE LOGICAL END OF PROGRAM   31050015
*        HAS ALREADY BEEN REACHED, IF THE LOGICAL END HAS NOT BEEN      31100015
*        REACHED, IT FORCES THE END OF SOURCE PROGRAM.                  31150015
*              AFTER COMPLETING THE LOGICAL END OF PROGRAM IT           31200015
*        RELEASES THE SCRATCH CORE AND MODULE IEMCE, LOADS MODULES      31250015
*        IEMCK AND IEMCL OF THE NEXT PHASE, RELEASES ITSELF AND         31300015
*        PASSES CONTROL TO IEMCL.                                       31350015
*                                                                       31400015
*              ENTRY POINTS. (1) WHEN THIS ROUTINE IS CALLED FROM A     31450015
*        NORMAL SITUATION, ENTRY IS TO READ.                            31500015
*                            (2) IF IT IS CALLED WHILST A CHARACTER     31550015
*        STRING IS BEING SCANNED, ENTRY IS TO READS.                    31600015
*                            (3) IF IT IS CALLED WHILST THE CONTENTS OF 31650015
*        A COMMENT IS BEING SCANNED, ENTRY IS TO READC.                 31700015
*                            (4) IF IT IS CALLED WHILST LOOKING AT WHAT 31750015
*         IS PERHAPS THE INITIAL SLASH OF A COMMENT, ENTRY IS TO READC1 31800015
*                            (5) IF IT IS CALLED WHILST LOOKING AT      31850015
*        WHAT IS PERHAPS THE FINAL ASTERISK OF A COMMENT, ENTRY IS TO   31900015
*        READC2.                                                        31950015
*                                                                       32000015
*              EXITS - NORMAL. (1) WITH THE EXCEPTION OF FINDING THE    32050015
*        LOGICAL OR PHYSICAL END OF PROGRAM, EXIT IS BY BRANCH ON       32100015
*        REGISTER TO THE LOCATION FOLLOWING THE INSTRUCTION THAT CALLED 32150015
*        THIS ROUTINE.                                                  32200015
*              (2) ON FINDING THE LOGICAL OR PHYSICAL END OF SOURCE     32250015
*        PROGRAM, CONTROL IS PASSED TO THE NEXT PHASE.                  32300015
*                                                                       32350015
*              EXITS - ERROR.  IF NO STATEMENTS ARE FOUND IN THE SOURCE 32400015
*        TEXT OR IF A STATEMENT IS TOO LONG FOR THE READ AREA, A BRANCH 32450015
*        IS MADE TO COMPILER CONTROL WHERE COMPILATION IS TERMINATED.   32500015
*                                                                       32550015
*                                                                       32600015
*                                                                       32650015
         SPACE 2                                                        32700015
READS    MVI   RSTSW,ALLONE            SET READ-STRING SWITCH ON TO     32750015
         BC    B,RDST                SHOW CALLED FROM WITHIN A STRING   32800015
         SPACE 2                                                        32850015
READ     MVI   RSTSW,NONE              NORMAL READ ENTRY                32900015
         SPACE                                                          32950015
         SPACE                                                          33000015
RDST     STM   GR2,GRE,REGS+4          STORE REGISTERS, INCLUDING 43444 33050021
*                                      THE SWITCH REGISTER AND STORE    33100015
         STM   RR,GR15,REGSTO          THE BRANCH AND LINK REGISTER.    33150015
         ST    GRC,REGS                                                 33200015
         SPACE                                                          33250015
RDST1    CLI   CARDNO(GRDIC),ALLONE    WE TEST A SWITCH TO SEE WHETHER  33300015
         BC    BE,RDCD                 OR NOT THIS PRESENT CARD NEEDS   33350015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 012-TSS 33370020
         MVI   OUTBUF+3(GRDIC),BLANK   A STATEMENT NUMBER, AND IF IT    33400015
         MVC   OUTBUF+4(5,GRDIC),OUTBUF+3(GRDIC)  DOES NOT WE BLANK     33450015
*        ----------------------------------------------------CI 012-TSS 33470020
*                                                 IT OUT.               33500015
         SPACE                                                          33550015
RDCD     MVI   CARDNO(GRDIC),NONE      RESET THE STATEMENT NUMBER       33600015
*                                      SWITCH                           33650015
         SPACE                                                          33700015
*              WE MUST FIRST DISCOVER WHETHER OR NOT THERE IS ENOUGH    33750015
*        ROOM IN THE READ AREA FOR ONE MORE CARD.   THERE CERTAINLY IS  33800015
*        IF THE STATEMENT POINTER IN THE READ AREA IS SET TO ZERO.      33850015
         SPACE                                                          33900015
         CLC   SPR(4,GRDIC),ZERO                                        33950015
         BC    BNE,MOROOM                                               34000015
         CLI   RSTSW,NONE                                               34050015
         BC    BNE,MOROOM                                               34100015
         SPACE                                                          34150015
*              HERE WE CERTAINLY HAVE ENOUGH ROOM                       34200015
         SPACE                                                          34250015
RD1      L     DP,BRA(0,GRDIC)          SET BOTH THE DATA POINER AND    34300015
         L     GRD,COMPTR            THE READ POINTER TO START OF READ  34350015
         L     GRE,RP(0,GRDIC)       AREA                               34400015
         SR    GRD,GRE                                                  34450015
         LTR   GRD,GRD                 IF RP NOT THE SAME AS COMPTR,    34500015
         BC    BZ,RD2                THERE IS PART OF A COMMENT LEFT    34550015
         SR    GRD,UR                FROM THE PREVIOUS RECORD AND THESE 34600015
         STC   GRD,*+5               BYTES HAVE TO BE MOVED DOWN TO THE 34650015
         MVC   0(*-*,DP),0(GRE)      START OF THE READ AREA TO GET      34700015
         ST    DP,RP(0,GRDIC)        SCANNED AGAIN.                     34750015
         LA    GRE,1(GRD,DP)           COMPTR IS RESET SO THAT THESE    34800015
         ST    GRE,COMPTR            BYTES DO NOT GET OVERWRITTEN BY    34850015
         BC    B,FSTPNT              THE NEW RECORD.                    34900015
         SPACE                                                          34950015
RD2      ST    DP,COMPTR               HERE THERE WERE NO COMENT BYTES  35000015
         ST    DP,RP(0,GRDIC)        LEFT OVER FROM PREVIOUS RECORD.    35050015
         SPACE                                                          35100015
         SPACE                                                          35150015
FSTPNT   BC    B,RDGET1                                                 35200015
*                                      THE CARD JUST READ IS NOT        35250015
*                                      PRINTED OUT THE FIRST TIME ROUND 35300015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 001-TSS 35320001
PRNT     TM    X'E9'(GRDIC),X'02'                                       35350015
         BC    BO,TSTPNT               TEST IF 48 CHARACTER             35400015
*                                      PROCESSOR HAS BEEN IN ACTION     35450015
*                                      WE MUST READ THE ORIGINAL CARD   35500015
*                                      INTO THE OUTPUT BUFFER.          35550015
         SPACE                                                          35600015
*              THE ORIGINAL SOURCE CARD FOLLOWS THE 60 CHARACTER CARD   35650015
*        ON THE INPUT DEVICE.                                           35700015
         SPACE                                                          35750015
*********************************************************************** 35800015
         SPACE                                                          35850015
         LA    GRA,OUTBUF+23(0,GRDIC)  GO TO COMPILER CONTROL TO READ   35900015
         ST    GRA,PAR1(0,GRDIC)       THE ORIGINAL CARD.               35950015
         L     LR,ZURD(0,GRCC)                                          36000015
         BALR  RR,LR                                                    36050015
         BC    B,IOERR(0,GR12)         THIS SHOULD NEVER BE THE LAST    36100015
*        ----------------------------------------------------CI 001-TSS 36120001
         SPACE                                                          36150015
*********************************************************************** 36200015
         SPACE                                                          36250015
*              WE ARE NOW ALL SET UP TO PRINT.                          36300015
         SPACE                                                          36350015
*********************************************************************** 36400015
         SPACE                                                          36450015
TSTPNT   TM    CCCODE+2(GRDIC),X'80'   SEE IF SOURCE LISTING REQD.      36500015
         BC    BO,RDGET                BRANCH IF NOT                    36550015
         SPACE                                                          36600015
         SPACE                                                          36650015
PRNT1    L     GRA,COLNO                                                36670015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 013-TSS 36675020
         MVC   OUTBUF+2(0,GRDIC),OUTBUF+23(GRA)                         36680015
         MVI   OUTBUF+23(GRA),X'40'                                     36690015
         LA    GRA,OUTBUF(0,GRDIC)      CHARACTER                       36710015
         ST    GRA,PAR1(0,GRDIC)       BY USING THE PRINT ROUTINE IN    36750015
         L     LR,ZUPLOF(0,GRCC)       COMPILER CONTROL.                36800015
         BALR  RR,LR                                                    36850015
         SPACE                                                          36900015
         MVC   OUTBUF+10(113,GRDIC),OUTBUF+9(GRDIC)                     36950015
*        ----------------------------------------------------CI 013-TSS 36970020
*********************************************************************** 37000015
         SPACE                                                          37050015
*              WE MUST NOW READ THE NEXT CARD.                          37100015
         SPACE                                                          37150015
*********************************************************************** 37200015
         SPACE                                                          37250015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 014-TSS 37270020
RDGET    MVI   OUTBUF+9(GRDIC),BLANK   BLANK OUT THE PRINT AREA         37300015
         MVC   OUTBUF+10(110,GRDIC),OUTBUF+9(GRDIC)                     37350015
*        ----------------------------------------------------CI 014-TSS 37370020
RDGET1   L     GRB,COMPTR              NEXT RECORD WANTED AT COMPTR.    37400015
         ST    GRB,PAR1(0,GRDIC)                                        37450015
         L     LR,ZURD(0,GRCC)         GET NEXT RECORD                  37500015
         BALR  RR,LR                                                    37550015
         BC    B,LSCRD                 BRANCH IF EOF                    37600015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 002-TSS 37610019
*        ----------------------------------------------------CI 002-TSS 37620019
         MVI   FSTPNT+1,X'00'          TURN OFF FIRST SWITCH            37650015
       SPACE 1                                                          37654017
*              THERE IS A STATISTICAL PROGRAM IN THE O/S            I16 37658017
*        WHICH NEEDS TO KNOW THE COUNT OF RECORDS. WE PUT THIS IN   I16 37662017
*        COMMUNICATIONS REGION FOR A MUCH LATER PHASE (AROUND TP    I16 37666017
*        TIME) TO OUTPUT IT.                                        I16 37670017
       SPACE 1                                                          37674017
         LH    GRD,SOURCN(0,GRDIC)                                  I16 37678017
         AR    GRD,UR                                               I16 37682017
         STH   GRD,SOURCN(0,GRDIC)                                  I16 37686017
       SPACE 1                                                          37690017
         L     GRD,PAR2(0,GRDIC)       PICK UP RECORD LENGTH            37700015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 020-TSS 37720020
         ST    GRD,RCDLTH              SAVE SO CHECK CAN BE MADE FOR    37750015
*        ----------------------------------------------------CI 020-TSS 37770020
*                                    AVAILABLE SPACE IN WHICH TO READ   37800015
         LH    GRB,ZMAG(0,GRDIC)       MARGIN INTO GRB                  37850015
         CR    GRB,GRD                 COMPARE WITH RECORD SIZE         37900015
         BC    BNH,RDGET2              BRANCH IF MARGIN LT RECORD SIZE  37950015
         LR    GRB,GRD                 OTHERWISE TAKE THE SMALLER       38000015
RDGET2   LH    GRD,ZSOR(0,GRDIC)       GET THE SOURCE START             38050015
         CH    GRD,RCDLTH+2            IF RECORD LENGTH                 38100015
         BC    BNH,RDGET3              LESS THAN SOURCE START           38150015
         OI    RCDLTH,X'80'            THEN SET A FLAG                  38200015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 027-TSS 38210021
*        ----------------------------------------------------CI 027-TSS 38220021
         BAL   RR,MESAGE(0,GR12)       AND PUT OUT A MESSAGE            38250015
         DC    X'5E4C'                                                  38300015
RDGET3   SR    GRB,GRD                 COMPUTE SIGNIFICANT LENGTH       38350015
         STC   GRB,RDMOVE+1            STORE IT AWAY WHERE              38400015
         AR    GRB,UR                                                   38450015
         ST    GRB,SIGLTH                                               38500015
         SR    GRD,UR                  COMPUTE OFFSET OF BEGINNING      38550015
         STC   GRD,RDMOVE+5            OF SOURCE TEXT AND INSERT        38600015
         L     GRD,RCDLTH              PICK UP RECORD LENGTH AGAIN      38650015
         SR    GRD,UR                  COMPUTE L-1 FOR BENEFIT OF 360   38700015
         STC   GRD,MOVOUT+1            INSERT LENGTH IN MOVE            38750015
         STC   GRD,TRSLAT+1          AND IN TR TO INTERNAL              38800015
         STC   GRD,CNVRT+1           AND IN TR TO EBCDIC                38850015
        L      GRD,COMPTR                                               38900015
         L     GRB,ZTRAN1(0,GRDIC)                                      38950015
TRSLAT   TR    0(*-*,GRD),0(GRB)       CONVERT TO INTERNAL CODES        39000015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 015-TSS 39020020
MOVOUT   MVC   OUTBUF+23(*-*,GRDIC),0(GRD) 7OVE IN INTERNAL FORM        39050015
         L     GRA,COLNO                                                39060015
         MVC   OUTBUF+2(1,GRDIC),OUTBUF+23(GRA)                         39070015
         L     GRB,ZTRAN2(0,GRDIC)                                      39100015
CNVRT    TR    OUTBUF+23(*-*,GRDIC),0(GRB)  CONVERT OUTPUT TO EBCDIC    39150015
*        ----------------------------------------------------CI 015-TSS 39170020
RDMOVE   MVC   0(0,GRD),0(GRD)                                          39200015
         L     GRD,RCDLTH                                               39250015
         LA    GRD,20(0,GRD)           CALCULATE RCDLTH+20 FOR CONTROL  39300015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 016-TSS 39320020
         STC   GRD,OUTBUF+1(0,GRDIC) CHARACTER IN OUTBUF                39350015
*        ----------------------------------------------------CI 016-TSS 39370020
         TM    RCDLTH,X'80'            TEST FOR TOO SHORT A RECORD      39400015
         BC    14,RRETN2              IF SO GET ADDRESS OF INTERNAL     39450015
         L     GRD,ZTRAN2(0,GRDIC)   TO EXTERNAL CODE TRANSLATION TABLE 39500015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 017-TSS 39520020
         MVC   OUTBUF+10(1,GRDIC),X'79'(GRD)                            39550015
*        ----------------------------------------------------CI 017-TSS 39570020
*                                      FOR AN ASTERISK IN THE           39600015
         NI    RCDLTH,X'7F'            RECORD AND GET THE NEXT RECORD   39650015
         BC    B,RDST1                                                  39700015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 021-TSS 39710020
*        ----------------------------------------------------CI 021-TSS 39720020
         SPACE                                                          39750015
RRETN2   EQU   *                                                        39800015
         CLI   RSTSW,ALLONE                                       27130 39803001
         BE    RRETN3                  BRANCH IF IN CHAR CONST    27130 39806001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 018-TSS 39808020
         CLI   OUTBUF+23(GRDIC),C' '                              21134 39810001
         BNE   RRETN3                  IS WHOLE RECORD BLANK?     21134 39820001
         MVC   BLNCOM+1(1),MOVOUT+1                               21134 39830001
BLNCOM   CLC   OUTBUF+24(0,GRDIC),OUTBUF+23(GRDIC)                21134 39840001
         BNE   RRETN3                  NO - CONTINUE.             21134 39844001
         MVC   OUTBUF+3(6,GRDIC),BLANKS YES - BLANK OUT STAT. NO. 21134 39848001
*        ----------------------------------------------------CI 018-TSS 39850020
         B     PRNT                     AND PRINT RECORD.         21134 39852001
BLANKS   DC    CL6' '                                             21134 39856001
RRETN3   L     GRD,SIGLTH                                         21134 39860001
         L     GRE,COMPTR              SET COMPTR TO THE END OF THE     39900015
         AR    GRE,GRD               RECORD JUST READ.                  39950015
         ST    GRE,COMPTR                                               40000015
RDTEST   SR    GRD,UR                                                   40050015
         XR    GR2,GR2                                                  40100015
         ST    DP,TRTST                SAVE DP IN CASE OF BAD CHARS     40150015
         L     GR14,KEYBAS(0,GRDIC)    PICK UP A(IEMCE)           28518 40170020
         EX    GRD,TRTEST              CHECK FOR VALID INPUT CODES      40200015
         BC    BNZ,INVAL                                                40250015
RRETN1   L     DP,RP(0,GRDIC)          RESET THE INPUT POINTER          40300015
         MVC   RP(4,GRDIC),COMPTR      RESET THE READ POINTER.          40350015
         SPACE                                                          40400015
RRETN    C     DP,RP(GRDIC)            IF NO SIGNIFICANT CHARACTERS     40450015
         BC    BE,RDST1              FROM THIS RECORD GO BACK FOR NEXT  40500015
         LM    RR,LR,REGSTO                                             40550015
         LM    GR2,GRE,REGS+4                                     43444 40600021
         L     GRC,REGS                                                 40650015
         BCR   B,RR                                                     40700015
         SPACE 1                                                        40710020
TRTEST   TRT   0(0,DP),TAB2OF(GR14)    TEST FOR VALID CHARS.      28518 40720020
         SPACE 3                                                        40750015
*              AN INVALID CHARACTER OR A SLASH HAS BEEN FOUND.          40800015
         SPACE                                                          40850015
INVAL    EQU   *                                                        40900015
         SPACE                                                          40950015
         ST    DP,BADCHR               NOTE THE POSITION OF INVALID     41000015
         L     DP,TRTST                CHARACTER AND RESET THE DATA     41050015
*                                      POINTER TO THE START OF THE      41100015
*                                      PRESENT SECTION OF INPUT TEXT.   41150015
         SPACE                                                          41200015
         SPACE                                                          41250015
         CLI   RSTSW,ALLONE                                             41300015
         BC    BE,FRS                  BRANCH IF ENTRY WAS VIA READS    41350015
         SPACE                                                          41400015
*              HERE WE HAVE FOUND AN INVALID CHARACTER FROM A NORMAL    41450015
*        CALL.   WE MUST FIND OUT WHETHER OR NOT WE HAVE SINCE GOT INTO 41500015
*        A STRING CONSTANT.                                             41550015
         SPACE                                                          41600015
LOOP2    CL    DP,BADCHR                IF THE DATA POINTER IS LOOKING  41650015
         BC    BNL,MESS1                AT HE BAD CHARACTER WE HAVE A   41700015
*                                       TRULY INVALID CHARACTER.        41750015
         SPACE                                                          41800015
         CLI   0(DP),QUOTE             IF WE SEE A QUOTE WE HAVE        41850015
         BC    BE,FR3                ENTERED A REGION O F FREEDOM       41900015
*                                      INSIDE A STRING CONSTANT.        41950015
         SPACE                                                          42000015
         SPACE                                                          42050015
LOOP4    AR    DP,UR                 OTHERWISE WE BUMP THE DATA         42100015
         BC    B,LOOP2                 POINTER AND CONTINUE THE SCAN.   42150015
         SPACE                                                          42200015
*              NOW WITHIN A STRING CONSTANT.                            42250015
         SPACE                                                          42300015
FR3      MVI   RSTSW,ALLONE            SET READ-STRING SWITCH ON.       42350015
         MVC   COMST(4,GRDIC),PAR7(GRDIC)   SAVE START OF MESSAGE       42400015
         ST    DP,PAR7(0,GRDIC)                                         42450015
         BC    B,FR4                   SET THE SWITCH TO 4 AND BUMP     42500015
*                                      THE DATA POINTER OVER IT.        42550015
         SPACE                                                          42600015
*              BEEN CALLED WHILE IN A STRING CONSTANT.                  42650015
         SPACE                                                          42700015
         SPACE                                                          42750015
*              THIS STEP ENSURES THAT WHEN A STRING TERMINATES IN       42800015
*        CC 72 OR ITS EQUIVALENT THEN THIS FACT IS RECOGNISED BY        42850015
*        THE READ STRING MECHANISM. IF THIS WERE NOT DONE THEN ANY      42900015
*        ILLEGAL CHARAS APPEARING IN  SUBSEQUENT STRINGS WOULD BE       42950015
*        FLAGGED AS INVALID SINCE THE APPEARANCE OF THE FIRST QUOTE     43000015
*        WOULD TURN OFF THE READS MODE.                                 43050015
         SPACE                                                          43100015
FRS      L     DP,PAR7(0,GRDIC)        RETURN TO BEGINNING OF STRING    43150015
FR4      AR    DP,UR                   PREPARE TO LOOK FOR BAD          43200015
*                                    CHARACTER.                         43250015
FR       CL    DP,BADCHR               IF WE HAVE FOUND THE INVALID     43300015
         BC    BE,FR1                  CHARACTER WE HAVE FINISHED BUT   43350015
         CLI   0(DP),QUOTE             IF NOT WE MUST ENSURE THAT WE    43400015
         BC    BE,FR2                  ARE STILL WITHIN A STRING.   IF  43450015
         AR    DP,UR                   WE ARE WE GO AND INSPECT THE     43500015
         BC    B,FR                    NEXT CHARACTER.                  43550015
         SPACE                                                          43600015
*              HERE WE HAVE FOUND AN INVALID CHARACTER INSIDE A STRING  43650015
*        CONSTANT.   WE CAN SPACE OVER IT AND CARRY ON.                 43700015
         SPACE                                                          43750015
FR1      L     GRD,COMPTR              CALCULATE LENGTH OF TEXT STILL   43800015
         SR    GRD,DP                TO BE SCANNED.                     43850015
         SR    GRD,UR                                                   43900015
         LTR   GRD,GRD                 END OF VALIDITY TEST             43950015
         BC    BZ,RRETN1             IF END OF LENGTH                   44000015
         AR    DP,UR                                                    44050015
         BC    B,RDTEST                                                 44100015
         SPACE                                                          44150015
*              WHILST SCANNING A STRING WE HAVE FOUND A QUOTE.          44200015
         SPACE                                                          44250015
FR2      AR    DP,UR                   IF THE NEXT CHARACTER IS THE     44300015
         CL    DP,BADCHR               INVALID ONE IT IS REALLY BAD.    44350015
         BC    BE,MESS1                UNLESS IT IS A SLASH.            44400015
         SPACE                                                          44450015
         CLI   0(DP),QUOTE             IF THE NEXT CHARACTER IS A QUOTE 44500015
         BC    BE,FR4                  WE ARE STILL WITHIN THE STRING   44550015
         MVI   RSTSW,NONE              BUT IF NOT WE BECOME A NORMAL    44600015
         MVC   PAR7(4,GRDIC),COMST(GRDIC)                               44650015
         BC    B,LOOP4               CASE ONCE AGAIN.                   44700015
         SPACE 3                                                        44750015
         SPACE                                                          48450015
*              TEST TO SEE IF IT WAS AN INVALID CHARACTER OR A SLASH    48500015
MESS1    CH    GR2,FOUR                                                 48550015
         BNE   CM1(0,GR12)                                        21134 48600001
         BAL   RR,MESAGE(0,GR12)     MESSAGE 97- INVALID                48650015
         DC    X'6148'                 CHARACTER REPLACED BY BLANK.     48700015
         SPACE                                                          48750015
         MVI   0(DP),BLANK             MOVE IN THE BLANK.               48800015
         L     GRD,ZTRAN2(0,GRDIC)     OBTAIN ADDR OF EXTERNAL CODES    48850015
         IC    GRD,X'79'(0,GRD)        GET ASTERISK REPLACEMENT         48900015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 019-TSS 48920020
         STC   GRD,OUTBUF+10(0,GRDIC)                                   48950015
*        ----------------------------------------------------CI 019-TSS 48970020
         SPACE                                                          49000015
         BC    B,FR1                   AND CARRY ON TESTING THE INPUT   49050015
*                                      STRING.                          49100015
         SPACE                                                          49150015
*              THESE INSTRUCTIONS TEST TO SEE IF THERE IS ENOUGH ROOM   49200015
*        FOR A NEW CARD IN THE READ AREA. IF NOT THE EXISTING TEXT IS   49250015
*        MOVED DOWN TO THE BEGINNING OF THE BLOCK AND POINTERS ARE      49300015
*        RELOCATED                                                      49350015
         SPACE                                                          49400015
MOROOM   L     GRA,ERA(0,GRDIC)                                         49450015
         S     GRA,COMPTR                                               49500015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 007-TSS 49520019
         C     GRA,RCDLTH                                               49550015
*        ----------------------------------------------------CI 007-TSS 49570019
         BC    BH,PRNT                                                  49600015
*                                      CALCULATE (ERA-COMPTR)+(SPR-BRA) 49650015
         A     GRA,SPR(0,GRDIC)                                         49700015
         S     GRA,BRA(0,GRDIC)                                         49750015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 008-TSS 49770019
         C     GRA,RCDLTH              TEST IF LESS THAN RECORD SIZE    49800015
*        ----------------------------------------------------CI 008-TSS 50000019
         BNH   TOLONG                  LENGTH IN RECORD.          23798 50200001
RESET    BAL   RR,SETAG(0,GR10)                                         50650015
         MVC   SPR(4,GRDIC),BRA(GRDIC)                                  51050015
         BC    B,MOROOM                                           19577 51250017
         SPACE 3                                                        51500015
LSCRD    CLC   ZSTAT(2,GRDIC),ZERO                                      51550015
         BC    BNE,LSCRD1              BRANCH IF SO.  ELSE-             51600015
         BAL   RR,MESAGE(0,GR12)       MESSAGE 90 - NO COMPLETE         51650015
         DC    X'5A00'               STATEMENTS IN THIS COMPILATION.    51700015
         L     LR,ZABORT(0,GRCC)                                        51750015
         BCR   B,LR                    ABORT                            51800015
LSCRD1   CLI   ENDFLG(GRDIC),X'FF'     LOGICAL END FOUND                51850015
         BC    BE,COMTST                                          12507 51900016
         BAL   RR,MESAGE(0,GR12)       MESSAGE 100 - END OF FILE  47697 51920056
         DC    X'6444'                 BEFORE LOGICAL END OF PROG 47697 51940056
         CLC   SPR(4,GRDIC),ZERO       ARE WE AT END OF STATEMENT?47697 51960056
         BC    BE,NOPOPS               YES-NO NEED FOR DUMMY STAT 47697 51980056
         C     OP,SPO(0,GRDIC)         ANYTHING TO BE DELETED?    47697 52000056
         BC    BE,POPTST               NO                         47697 52020056
         SPACE 1                                                        52040056
*              SPO IS POINTING EITHER AT THE START OF THE         47697 52060056
*        INCOMPLETE STATEMENT OR, IN THE CASE OF A DECLARE        47697 52080056
*        STATEMENT SPANNING BLOCKS, AT A COMMA AT THE START OF A  47697 52100056
*        TEXT BLOCK. IN THE FORMER CASE, THE WHOLE OF THE         47697 52120056
*        STATEMENT IS DELETED. IN THE LATTER CASE, THAT PART OF   47697 52140056
*        THE DECLARE STAEMENT IN THE CURRENT TEXT BLOCK IS        47697 52160056
*        DELETED AND THE COMMA IS REPLACED BY A SEMI-COLON, THUS  47697 52180056
*        LEAVING A SYNTACTICALLY-CORRECT DECLARE STATEMENT.       47697 52200056
         SPACE 1                                                        52220056
         L     OP,SPO(0,GRDIC)      DELETE WHOLE OR PART OF STMNT 47697 52240056
         CLI   0(OP),COMMA             IS THIS MIDDLE OF DECLARE? 47697 52260056
         BC    BE,MVSEMI               YES-GO TO REPLACE COMMA BY 47697 52280056
*                                    SEMI-COLON. NO NEED TO CALL  47697 52300056
*                                    OPTST1-WE ARE AT START OF BLK47697 52320056
POPTST   EQU   *                                                  47697 52340056
         CLI   LBLPOP,NONE   ANY LABELS OR PREFIX OPTIONS?        47697 52360056
         BC    BE,NOPOPS               NO - NO NEED FOR DUMMY STAT47697 52380056
*                                      IF SO, MAKE A DUMMY STATEMENT    52400015
         LA    GRA,5(0,0)                                               52450015
         BAL   RR,OPTEST(0,GR12)       TEST FOR ROOM                    52500015
         MVI   0(OP),SL      AT FIRST ASSUME NOT INITIAL LABEL    47697 52540056
         TM    LCNT(GR10),INITLB       IS THERE AN INITIAL LABEL? 47697 52580056
         BC    BZ,LEAVE                NO - LEAVE SL              47697 52620056
         MVI   0(OP),SLDASH            YES - OVERWRITE SL         47697 52660056
LEAVE    MVC   1(2,OP),LBLPTR(GRDIC)                                    52700015
         MVI   3(OP),NLTYPE                                             52750015
         LA    OP,4(0,OP)              BUMP OUTPUT PTR TO SEMI-COL47697 52780056
MVSEMI   MVI   0(OP),SCOLON            INSERT SEMI-COLON          47697 52810056
         AR    OP,UR                   BUMP OUTPUT POINTER BY 1   47697 52840056
         ST    OP,SPO(GRDIC)                                            52900015
NOPOPS   BAL   RR,XEND(0,GR10)                                          52950015
         BC    B,ALMOST                                                 53000015
LSCRD2   CLC   SPR(4,GRDIC),ZERO                                        53050015
         BC    BE,EOF                                                   53100015
         BAL   RR,MESAGE(0,GR12)       MESSAGE - SEMICOLON INSERTED     53150015
         DC    X'6048'                                                  53200015
         SPACE                                                          53250015
ALMOST   BAL   RR,OPTST1(0,GR12)                                        53300015
         MVI   0(OP),SCOLON             MOVE SEMICOLON TO OP            53350015
         AR    OP,UR                                                    53400015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 024-TSS 53420021
EOF      LA    GRA,5(0,0)                                               53450015
         BAL   RR,OPTEST(0,GR12)                                        53500015
         MVC   0(5,OP),EOP                                              53550015
         AR    OP,GRA                                                   53600015
       SPACE                                                            53650015
*              WE NOW RELEASE PHASES AND PASS CONTROL.                  53700015
       SPACE                                                            53750015
PASS     ST    UR,PAR1(0,GRDIC)        RELEASE THE SCRATCH CORE THAT WE 53800015
         L     LR,ZURC(0,GRCC)       USED FOR THE READ AREA AND STACK.  53850015
         BALR  RR,LR                                                    53900015
       SPACE                                                            53950015
         MVC   PAR1(4,GRDIC),BKNAME(GRDIC)    SET THE STATUS OF THE     54000015
         EX    0,MKBLOC(0,GR12)             OUTPUT BLOCK TO WANTED OR   54050015
         L     LR,ZALTER(0,GRCC)            UNWANTED.                   54100015
         BALR  RR,LR                                                    54150015
       SPACE                                                            54200015
         XC    PAR3(4,GRDIC),PAR3(GRDIC)  IF NEST OPTION ON, PAR3  H268 54210001
*        CONTAINS ADDRESS OF NEST HEADING.  THIS INSTRUCTION       H268 54220001
*        CLEARS PAR3                                               H268 54230001
         MVI   ZFLAG2(GRDIC),NONE      ZERO ZFLAG2                28518 54235020
         SPACE                                                          54240001
         LA    GRA,RLLST1              RELEASE PHASE CE                 54250015
         ST    GRA,PAR1(0,GRDIC)                                        54300015
         L     LR,RELESE(0,GRCC)                                        54350015
         BALR  RR,LR                                                    54400015
       SPACE                                                            54450015
         LA    GRA,CTLST1              LOAD PHASE CK                    54500015
         ST    GRA,PAR1(0,GRDIC)                                        54550015
         L     LR,ZLOADW(0,GRCC)                                        54600015
         BALR  RR,LR                                                    54650015
         MVC   KEYBAS(4,GRDIC),PAR1(GRDIC)         STORE ADDRESS OF CK  54700015
       SPACE                                                            54750015
         LA    GRA,RLLST2              RELEASE PHASE CG AND CI          54800015
         ST    GRA,PAR1(0,GRDIC)                                        54850015
         LA    GRA,CTLST2              PASS CONTROL TO CL               54900015
         ST    GRA,PAR2(0,GRDIC)                                        54950015
         L     LR,RLSCTL(0,GRCC)                                        55000015
         BCR   B,LR                                                     55050015
*        ----------------------------------------------------CI 024-TSS 55070021
RLLST1   DC    C'CEZZ'                                                  55100015
RLLST2   DC    C'CGCIZZ'                                                55150015
CTLST1   DC    C'CKZZ'                                                  55200015
CTLST2   DC    C'CLZZ'                                                  55250015
       SPACE                                                            55300015
         SPACE                                                          55350015
TOLONG   CLI   STYPE(GRDIC),DCTYPE     SEE IF IN A DECLARE STATEMENT    55400015
         BC    BNE,TOLNG1                                               55450015
*         AT THIS POINT WE ASSUME DCL STATEMENT                         55460015
*        SET PAS OFF                                                    55470015
         MVI   PAS(GRDIC),NONE                                          55480015
*        WE ARR IN A STRING AND MUST RELOCATE TEXT                      55560015
*        FROM START2 TO BRA                                             55590015
         CLC   SPR(4,GRDIC),START2(GRDIC)                         19577 55600017
         BC    BE,TOLNG2                                          19577 55610017
         MVC   SPR(4,GRDIC),START2(GRDIC)                               55620015
         BC    B,RESET                                                  55650015
TOLNG1   CLI   PSTYPE(GRDIC),DCTYPE    IF IN A DOUBTFUL DECLARE-ASSIGN, 55700015
         BC    BE,ASSM(0,GR10)                                          55750015
TOLNG2   EQU   *                                                  19577 55770017
         BAL   RR,MESAGE(0,GR12)       MESSAGE 107 - STATEMENT TOO LONG 55800015
         DC    X'6B40'                                                  55850015
         L     LR,ZABORT(0,GRCC)       ABORT.                           55900015
         BALR  RR,LR                                                    55950015
       SPACE 2                                                          55954016
*              TEST FOR AN INCOMPLETE COMMENT FOLLOWING           12507 55958016
*        LOGICAL END OF PROGRAM.                                  12507 55962016
       SPACE                                                            55966016
COMTST   CLC   RP(4,GRDIC),COMPTR      ARE WE IN A COMMENT        12507 55970016
         BC    BE,LSCRD2               NO                         12507 55974016
         BAL   RR,MESAGE(0,GR12)       MESSAGE 49 - INCOMPLETE    12507 55978016
         DC    X'3108'               COMMENT FOLLOWS LOGICAL      12507 55982016
         BC    B,LSCRD2              END OF PROGRAM.              12507 55986016
       SPACE 2                                                          55990016
         EJECT                                                          56000015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 025-TSS 56020021
*                       THIS IS THE INCREMENT ROUTINE. IT INCREMENTS TO 56050015
*        THE NEXT NON-BLANK CHARACTER.                                  56100015
         SPACE                                                          56150015
BUMP   AR      DP,UR                   INCREASE DP BY 1                 56200015
         C     DP,RP(0,GRDIC)                                           56250015
         BC    BE,INCS7                BRANCH TO READ ANOTHER CARD      56300015
INCR     ST    GRD,OSTEMP                                               56350015
         L     GRD,RP(0,GRDIC)                                          56400015
         SR    GRD,DP                 AREA                              56450015
INCR1    CLI   0(DP),BLANK                                              56500015
         BC    BNE,INCOUT            TEST FOR BLANKS                    56550015
         AR    DP,UR                                                    56600015
         C     DP,RP(0,GRDIC)        DO WE NEED TO READ                 56650015
         BC    BNL,INCS1                                                56700015
         BCT   GRD,INCR1             LOOP BACK FOR MORE                 56750015
INCS1    ST    RR,TEMPZ                                                 56800015
         BAL   RR,READ                  READ NEW CARD                   56850015
         L     RR,TEMPZ                                                 56900015
         BC    B,INCR+4                                                 56950015
INCOUT   L     GRD,OSTEMP                                               57000015
         BCR   B,RR                                                     57050015
INCS7    ST    GRD,OSTEMP                                               57060015
         BC    B,INCS1                                                  57070015
         SPACE 5                                                        57100015
         EJECT                                                          57200015
        EJECT                                                           57250015
*        ----------------------------------------------------CI 025-TSS 57270021
*              THIS ROUTINE DIAGNOSES PROCEDURE AND ENTRY STATEMENTS    57300015
*        IT IS ENTERED WITH THE INPUT TEXT POINTER DP POINTING AT THE   57350015
*        FIRST CHARACTER FOLLOWING THE KEYWORD 'PROCEDURE' OR 'ENTRY'   57400015
*              PARAMETER LISTS, OPTIONS AND ATTRIBUTES ON A PROCEDURE   57450015
*        STATEMENT ARE NOT HANDLED BY THIS ROUTINE.                     57500015
*              IF THE STATEMENT IS A PROCEDURE STATEMENT, THE BLOCK     57550015
*        LEVEL AND BLOCK COUNT IS INCREASED BY ONE. AN ENTRY IS MADE IN 57600015
*        THE STACK OF THE PROCEDURE STATEMENT CODE FOR THE STACK, THE   57650015
*        DICTIONARY REFERENCE OF THE STATEMENT LABEL (IF ANY), AND THE  57700015
*        BLOCK COUNT OF THE STATEMENT. THE BLOCK LEVEL AND BLOCK COUNT  57750015
*        IS THEN MOVED TO THE OUTPUT TEXT.                              57800015
*              IF THE STATEMENT IS AN ENTRY STATEMENT, THE CURRENT      57850015
*        BLOCK LEVEL AND BLOCK COUNT IS MOVED TO THE OUTPUT TEXT. THE   57900015
*        TOP ENTRY IN THE STACK IS CHECKED, IF IT SHOWS THAT THIS       57950015
*        ENTRY STATEMENT IS IN A BEGIN OR ITERATIVE DO BLOCK THEN THIS  58000015
*        ENTRY STATEMENT IS DELETED.                                    58050015
*                                                                       58100015
*              ENTRY POINTS. (1) TO PROCESS AN ENTRY STATEMENT, THE     58150015
*        ENTRY POINT ENTRY IS USED.                                     58200015
*                            (2) TO PROCESS THE FIRST PROCEDURE         58250015
*        STATEMENT OF THE SOURCE PROGRAM, THE ENTRY POINT PROC1 IS      58300015
*        USED.                                                          58350015
*                            (3) TO PROCESS A PROCEDURE STATEMENT OTHER 58400015
*        THAN THE FIRST, THE POINT PROC IS USED.                        58450015
*                                                                       58500015
*              EXITS - NORMAL.  ALL NORMAL RETURNS ARE TO RSTART IN THE 58550015
*        MAIN SCAN ROUTINE FOR THIS PHYSICAL PHASE.                     58600015
*                                                                       58650015
*              EXITS - ERROR.  IF THE SPECIFIED MAXIMUM LEVEL OF        58700015
*        NESTING IS EXCEEDED OR THE NUMBER OF BLOCKS IS TOO LARGE FOR   58750015
*        THE COMPILER TO HANDLE, THEN A BRANCH IS MADE TO COMPILER      58800015
*        CONTROL WHERE COMPILATION IS TERMINATED.                       58850015
*                                                                       58900015
*                                                                       58950015
*                                                                       59000015
         SPACE                                                          59050015
ENTRY    MVI   ENTSW,ALLONE            SET ENTSW FOR ENTRY STATEMENT    59100015
         BC    B,PRE                                                    59150015
PROC1    L     GRA,SPO(0,GRDIC)                                         59200015
         MVI   FRSTSW,ALLONE                                            59250015
         MVI   3(GRA),PRTYPE                                            59300015
PROC     MVI   ENTSW,NONE               TURN ENTSW OFF FOR PROC         59350015
PRE      LA    GRA,2(0,0)                                               59400015
         BAL   RR,OPTEST(0,GR12)                                        59450015
         MVC   0(2,OP),BKL(GRDIC)                                       59500015
         AR    OP,GRA                                                   59550015
         BAL   RR,STAT2(0,GR10)        JUMP OVER STATEMENT              59600015
         CLI   FRSTSW,ALLONE           NO STACK CHECK FOR FIRST PROC    59650015
         BC    BE,*+8                                                   59700015
         BAL   RR,NONEX(0,GR12)        CHECK THE STACK                  59750015
PRESW    CLI   ENTSW,ALLONE            BRANCH IF ENTRY STATEMENT        59800015
         BC    BE,PRENL                                                 59850015
         TM    LBLPOP,MIXED1           HAS THE STMNT GOT A LABEL? 47697 59900056
         BC    BO,PRLAB                YES                        47697 59950056
         BAL   RR,MESAGE(0,GR12)       MESSAGE 102 - PROCEDURE          60000015
         DC    X'6644'               STATEMENT HAS NO LABEL.            60050015
PRENA    MVI   NOLBFL,ALLONE           SE THE NO LABEL FLAG ON.         60100015
         BC    B,ALABEN   GET BLOCK LEVEL AND COUNTS FOR COMPILER LABEL 60150015
       SPACE                                                            60200015
*********************************                                       60250015
*  NOW MAKE THE COMPILER LABEL  *                                       60300015
*********************************                                       60350015
         SPACE                                                          60400015
COMPLB   MVI   NOLBFL,NONE             SET NO-LABEL-FLAG OFF            60450015
         MVI   LABENT,X'01'             CREATE A COMPILER LABEL         60500015
         MVC   LABENT+8(2),ZSTAT(GRDIC) LABEL                           60550015
         STC   UR,LABENT+19                                             60600015
         LH    GRA,CMPLBL(GRDIC)                                        60650015
         STH   GRA,LABENT+20                                            60700015
         AR    GRA,UR                  UPDATE NEXT-AVAILABLE-           60750015
         STH   GRA,CMPLBL(GRDIC)       COMPILER LABEL SLOT              60800015
         LA    GRA,LABENT                                               60850015
         ST    GRA,PAR1(GRDIC)                                          60900015
         LA    GRA,22                                                   60950015
         ST    GRA,PAR2(GRDIC)                                          61000015
         L     LR,ZDRFOF(0,GRCC)                                        61050015
         BALR  RR,LR                                                    61100015
         L     GR15,BASEBA(GRDIC)                                       61150015
         L     GRA,SPO(GRDIC)                                           61200015
         CLI   0(GRA),SL               WERE THERE ANY PREFIX OPTIONS    61250015
         BC    BE,PRLAB0                                                61300015
         MVI   0(GRA),SL                                                61350015
         MVC   1(2,GRA),PAR1+2(GRDIC)  IF NOT, CHANGE SN TO SL          61400015
PRLAB0   CLI   ENTSW,ALLONE                                             61450015
         BC    BE,PRBUMP                CONTINUE PROCESSING IF PROC.    61500015
       SPACE                                                            61550015
PRLAB    L     GRB,STP(0,GRDIC)                                         61600015
         CLI   FRSTSW,ALLONE           IS THIS THE FIRST PROCEDURE      61650015
         BC    BE,PRPL1              STATEMENT. IF YES THEN BRANCH.     61700015
         BAL   RR,SOFLOW(0,GR12)       BUMP UP STACK POINTER.           61750015
       SPACE                                                            61800015
PRPL1    MVI   FRSTSW,NONE                                              61850015
         L     GRA,SPO(0,GRDIC)                                         61900015
         XR    GRC,GRC                                                  61950015
         IC    GRC,BKL(0,GRDIC)                                         62000015
         AR    GRC,UR                  ADD 1 TO BKL                     62050015
         STC   GRC,BKL(0,GRDIC)                                         62100015
         CLI   BKL(GRDIC),X32          TEST TO SEE IF THE NESTING HAS   62150015
         BC    BH,PROPL              EXCEEDED THE MAXIMUM VALUE ALLOWED 62200015
*                                    IF IT HAS THEN BRANCH.             62250015
         IC    GRC,BKC(0,GRDIC)                                         62300015
         AR    GRC,UR                  ADD 1 TO BKC                     62350015
         STC   GRC,BKC(0,GRDIC)                                         62400015
         TM    BKC(GRDIC),ALLONE       TEST FOR OVERFLOW                62450015
         BC    BZ,PROPL                 BKC HAS OVERFLOWDE              62500015
         MVI   0(GRB),X'80'             STORE P CODE IN STACK ENTRY     62550015
         MVC   1(2,GRB),1(GRA)         MOVE LBLPTR TO STACK             62600015
*                                    STACK.                             62650015
PRBN     MVC   3(1,GRB),BKC(GRDIC)     PUT BKC IN STACK                 62700015
         MVC   4(2,GRA),BKL(GRDIC)     PUT BKL,BKC IN TEXT              62750015
         BC    B,PRBUMP                                                 62800015
PROPL    BAL   RR,MESAGE(0,GR12)       MESSAGE 106 - TOO MANY           62850015
         DC    X'6A40'                  PROCEDURES                      62900015
PRABT    L     LR,ZABORT(0,GRCC)                                        62950015
         BALR  RR,LR                                                    63000015
         SPACE                                                          63050015
PRENT    TM    LBLPOP,MIXED1           HAS THE STMNT GOT A LABEL? 47697 63100056
         BC    BO,PRBUMP               YES                        47697 63150056
         BAL   RR,MESAGE(0,GR12)       MESSAGE 103 ENTRY                63200015
         DC    X'6744'               STATEMENT HAS NO LABEL             63250015
         BC    B,PRENA                                                  63300015
PRENS    EQU   *                                                        63350015
*              WE LOOK DOWN THE STACK TO FIND THE TOP ENTRY OF A        63400015
*        PROCEDURE, DO, BEGIN OR ITDO. IF THE TOP ENTRY OF THESE IS A   63450015
*        BEGIN OR ITDO, WE BRANCH TO GIVE THE APPROPRIATE ERROR MESSAGE 63500015
*        AND DELETE THE ENTRY STATEMENT.                                63550015
         SPACE                                                          63600015
PRENL    L     GRB,STP(0,GRDIC)                                         63650015
         CLI   0(GRB),X'80'            TEST STACK FOR PROC              63700015
         BNE   BGNTST                  NOT PROC                   28532 63709020
         MVC   PAR1+2(2,GRDIC),1(GRB)  PASS LABEL PTR. IN PAR1    28532 63718020
         L     LR,ZDRFAB(0,GRCC)       CONVERT DIC. REF. TO       28532 63727020
         BALR  RR,LR                   ABSOLUTE ADDRESS           28532 63736020
         L     GR15,BASEBA(0,GRDIC)    RESET BASE REG. FOR CI     28532 63745020
         L     GRA,PAR1(0,GRDIC)       LOAD LABEL ENTRY ADDRESS   28532 63754020
PRLABTST EQU   *                                                  28532 63754920
         CLI   0(GRA),X'01'            IS IT A GENERATED PROC     28532 63755820
*                                      LABEL ENTRY?               28532 63756720
         BE    PRDEL                   YES                        28532 63757620
         CLI   0(GRA),X'70'            IS IT A PREFIX OPTION?     28532 63758520
         BNE   PRENT                   NO                         28532 63759420
         MVC   HWTEMP,1(GRA)           ALIGN ENTRY LENGTH         28532 63760320
         AH    GRA,HWTEMP              BUMP OVER ENTRY            28532 63761220
         B     PRLABTST                REPEAT                     28532 63762120
BGNTST   EQU   *                                                  28532 63790020
         CLI   0(GRB),X'81'            TEST STACK FOR BEGIN AT TOP      63800015
         BC    BE,PRDEL                                                 63850015
         CLI   0(GRB),X'84'            TEST FOR IT DO AT TOP OF STACK   63900015
         BC    BE,PRDEL                                                 63950015
         SH    GRB,FOUR                                                 64000015
         BC    B,PRENL+4                                                64050015
PRDEL    L     OP,SPO(0,GRDIC)                                          64100015
         MVI   3(OP),NLTYPE            REPLACE ENTRY BY NULL STATEMENT. 64150015
         MVI   4(OP),SCOLON                                             64200015
         LA    OP,5(0,OP)                                               64250015
         CLI   0(GRB),X'84'            ITDO AT TOP OF STACK?      28532 64300020
         BE    PRILL                   YES                        28532 64350020
PRENB    BAL   RR,MESAGE(0,GR12)       MESSAGE 112 - ENTRY STATEMENT    64400015
         DC    X'7044'               IN BEGIN DELETED                   64450015
         BC    B,PREND                                                  64500015
PRILL    BAL   RR,MESAGE(0,GR12)       MESAGE 108 - ENTRY STATEMENT     64550015
         DC    X'6C44'               IN IT DO DELETED                   64600015
PREND    EQU   *                                                        64650015
PRBUMP   CLI   0(DP),SCOLON            BUMP OVER THE SEMICOLON          64700015
         BC    BNE,PRBMP1            IF PRESENT                         64750015
         BAL   RR,BUMP                                                  64800015
PRBMP1   EQU   *                                                        64850015
         CLI   ENTSW,ALLONE                                             64900015
         BC    BNE,RSTART                                               64950015
         L     GRA,SPO(0,GRDIC)                                         65000015
         MVC   5(1,GRA),3(GRB)         CORRECT BKC FOR ENTRY IN TEXT    65050015
         BC    B,RSTART                                                 65100015
         SPACE 2                                                        65105001
*              THE ROUTINE PROC IS ENTERED AT THIS POINT FROM           65110001
*              THE ROUTINE BEGIN FOR A BEGIN STATEMENT THAT HAS         65115001
*              BEEN CHANGED TO A PROC.                                  65120001
         SPACE 1                                                        65125001
BPROC    MVI   ENTSW,NONE              TURN OFF 'ENTRY ST'MENT' SWITCH  65130001
         TM    LBLPOP,MIXED1           HAS THE STMNT GOT A LABEL? 47697 65135056
         BC    BO,PRLAB                YES                        47697 65140056
         BC    B,PRENA                                                  65145001
         SPACE 3                                                        65150015
         EJECT                                                          65400015
*              THIS ROUTINE HANDLES BAD STATEMENTS.                     65450015
*              IT IS ENTERED WITH THE INPUT POINTER DP POINTING AT THE  65500015
*        START OF THE INVALID TEXT.                                     65550015
*              ON ENTRY TO BADST1 THE ERROR FLAG 'ERRFLG' IS            65600015
*        TESTED, IF THIS FLAG IS 'ON' THE SWITCH 'NULLSW' IS SET 'ON'   65650015
*        AND TEXT UP TO THE SEMI COLON IS SKIPPED WITHOUT BEING MOVED   65700015
*        TO THE OUTPUT. IF ERRFLG IS 'OFF', TEXT IS SKIPPED UP TO THE   65750015
*        NEXT ALPHA-NUMERIC CHARACTER.                                  65800015
*              IF ENTRY IS TO BADST3, TEXT IS SKIPPED UP TO THE         65850015
*        SEMI COLON AND IS REPLACED IN THE OUTPUT TEXT BY A NULL        65900015
*        STATEMENT.                                                     65950015
*                                                                       66000015
*              ENTRY POINTS. (1) BADST1 EXPLAINED ABOVE.                66050015
*                            (2) BADST3 EXPLAINED ABOVE.                66100015
*                                                                       66150015
*              EXITS - NORMAL. (1) IF ENTRY WAS AT BADST1 WITH THE FLAG 66200015
*        'ERRFLG' SET 'ON', THEN EXIT IS BY A BRANCH TO STOK IN THE     66250015
*        MAIN SCAN ROUTINE FOR THIS PHYSICAL PHASE.                     66300015
*                              (2) IF ENTRY WAS AT BADST1 WITH THE FLAG 66350015
*        'ERRFLG' SET 'OFF', THEN EXIT IS BY A BRANCH TO RSPR IN THE    66400015
*        MAIN SCAN ROUTINE FOR THIS PHYSICAL PHASE.                     66450015
*                              (3) IF ENTRY WAS AT BADST3, EXIT IS BY   66500015
*        A BRANCH TO STOK IN THE MAIN SCAN ROUTINE FOR THIS PHYSICAL    66550015
*        PHASE.                                                         66600015
*                                                                       66650015
*              EXITS - ERROR.  N/A.                                     66700015
*                                                                       66750015
*                                                                       66800015
*                                                                       66850015
BADST1   ST    DP,SPR(0,GRDIC)          SET SPR TO POSITION OF DP       66900015
         ST    DP,PAR7(0,GRDIC)                                         66950015
         MVI   ST3FLG,X'00'                                             67000015
         CLI   ERRFLG(GRDIC),ALLONE     TEST ERRFLG                     67050015
         BC    BE,BADM                 BRANCH IF ERRFLG ON              67100015
         MVI   ERRFLG(GRDIC),ALLONE     OTHERWISE SET ERRFLG ON         67150015
         BC    B,BADB                                                   67200015
BADA     BAL   RR,BUMP                                                  67250015
BADB     BAL   RR,TRCHAR(0,GR15)       TEST FOR AN ALPHABETIC           67300015
         BC    BNH,BADC                IF SO , PUT OUT                  67350015
BADF     BAL   RR,MESAGE(0,GR12)       MESSAGE 109 - TEXT SKIPPED       67400015
         DC    X'6DC4'                                                  67450015
         BC    B,RSPR                                                   67500015
BADC     CLI   0(DP),QUOTE              TEST IF DP POINTING AT A QUOTE  67550015
         BC    BNE,BADD                                                 67600015
         MVC   COMST(4,GRDIC),PAR7(GRDIC) SAVE PAR7 ROUND CALL TO STRIN 67650015
         BAL   RR,STRING(0,GR10)       JUMP OVER STRING                 67700015
         MVC   PAR7(4,GRDIC),COMST(GRDIC)                               67750015
         BC    B,BADB                                                   67800015
BADD     CLI   0(DP),COLON             TEST FOR COLON                   67850015
         BC    BE,BADH                                                  67900015
         CLI   0(DP),SCOLON            TEST FOR SEMICOLON               67950015
         BC    BNE,BADA                BRANCH IF NOT SEMICOLON          68000015
         MVI   NULLSW,ALLONE            SET NULLSW ON                   68050015
         MVI   ERRFLG(GRDIC),NONE                                       68100015
         BC    B,BADF                                                   68150015
BADH     BAL   RR,BUMP                 BUMP OVER COLON                  68200015
         BAL   RR,MESAGE(0,GR12)       MESSAGE- TEXT SKIPPED            68250015
         DC    X'6DC4'                                                  68300015
         BC    B,RLETTR                                                 68350015
BADL     BAL   RR,BUMP                                                  68400015
BADM     CLI   0(DP),QUOTE              TEST FOR QUOTE                  68450015
         BC    BNE,BADO                                                 68500015
         MVC   COMST(4,GRDIC),PAR7(GRDIC) SAVE PAR7 ROUND CALL TO STRIN 68550015
         BAL   RR,STRING(0,GR10)       JUMP OVER STRING                 68600015
         MVC   PAR7(4,GRDIC),COMST(GRDIC)                               68650015
         BC    B,BADM                                                   68700015
BADO     CLI   0(DP),COLON             TEST FOR COLON                   68750015
         BC    BE,BADI                                                  68800015
         CLI   0(DP),SCOLON            TEST FOR SEMICOLON               68850015
         BC    BNE,BADL                                                 68900015
         BAL   RR,MESAGE(0,GR12)       MESSAGE 110 - TEXT SKIPPED       68950015
         DC    X'6DC4'                                             H408 69000019
         MVI   ERRFLG(GRDIC),NONE                                       69050015
         CLI   ST3FLG,ALLONE                                            69100015
         BC    BE,STOK                                                  69150015
BADK     MVI   NULLSW,ALLONE                                            69200015
         MVI   ERRFLG(GRDIC),NONE                                       69250015
         BC    B,RSPR                                                   69300015
BADST3   L     OP,SPO(0,GRDIC)                                          69350015
         MVI   ST3FLG,ALLONE                                            69400015
         MVI    3(OP),NLTYPE                                            69450015
         LA    OP,4(0,OP)                                               69500015
         BAL   RR,CHECK(0,GR12)                                         69550015
         MVC   PAR7(4,GRDIC),SPR(GRDIC)                                 69600015
         BC    B,BADM                                                   69650015
BADI     EQU   *                                                        69700015
         BAL   RR,MESAGE(0,GR12)       MESSAGE- TEXT SKIPPED            69750015
         DC    X'6DC4'                                             H408 69800019
         CLI   ST3FLG,ALLONE           FROM BADST3 ENTRY BRANCH TO      69850015
         BC    BNE,BADK                                                 69900015
         BC    B,NOSC1                 COMPLETE NULL STATEMENT          69950015
         EJECT                                                          70000015
*              THIS ROUTINE PERFORMS A PARTIAL DIAGNOSES OF PREFIX      70050015
*        OPTIONS.                                                       70100015
*              IT IS ENTERED WITH THE INPUT DATA POINTER DP POINTING AT 70150015
*        THE LEFT PARENTHESIS OF WHAT APPEARS TO BE A PREFIX OPTION.    70200015
*              IF A VALID PREFIX OPTION IS FOUND, IT WILL BE ENTERED    70250015
*        INTO THE DICTIONARY DURING THIS PHSICAL PHASE READY FOR        70300015
*        PROCESSING BY A LATER PHASE OF THE READIN STAGE.               70350015
*              THE PREFIX OPTION IS FORMED IN THE OUTPUT TEXT EXACTLY   70400015
*        AS IT WILL APPEAR IN THE DICTIONARY, THIS ROUTINE DOES NOT     70450015
*        MOVE IT TO THE DICTIONARY BUT USES PART OF ANOTHER ROUTINE TO  70500015
*        PERFORM THE MOVE. ALSO IT USES PART OF THE MAIN SCAN ROUTINE   70550015
*        OF THIS PHYSICAL PHASE TO OBTAIN THE STATEMENT NUMBER.         70600015
*              IF THE PREFIX OPTION IS NOT FOLLOWED BY A COLON, A COLON 70650015
*        IS ASSUMED MISSING AND THE PREFIX OPTION IS PROCESSED AS       70700015
*        NORMAL.                                                        70750015
*               IF THE OPTION IS FOUND INVALID OR FOLLOWS A LABEL, THE  70800015
*        OPTION IS DELETED.                                             70850015
*                                                                       70900015
*              ENTRY POINTS. THERE IS ONLY ONE ENTRY POINT TO THIS      70950015
*        ROUTINE, THAT IS AT POPLST.                                    71000015
*                                                                       71050015
*              EXITS - NORMAL.  A BRANCH IS MADE TO RDENT WHERE THE     71100015
*        DICTIONARY ENTRY OF THE OPTION IS PERFORMED.                   71150015
*                                                                       71200015
*              EXITS - ERROR. (1) IF THE OPTION FOLLOWS A LABEL THEN    71250015
*        A BRANCH IS MADE TO RLETTR IN THE MAIN SCAN ROUTINE OF THIS    71300015
*        PHYSICAL PHASE.                                                71350015
*                             (2) IF THE OPTION IS FOUND INVALID THEN A 71400015
*        BRANCH IS MADE TO BADST1 IN THE BAD STATEMENT PROCESSOR.       71450015
*                                                                       71500015
*                                                                       71550015
*                                                                       71600015
         SPACE 3                                                        71650015
POPLST   EQU   *                                                        71700015
         SPACE                                                          71750015
*              WE REMEMBER THE POSITION OF THE OUTPUT POINTER AND       71800015
*        BUILD UP A PREFIX OPTION ENTRY IN THE OUTPUT STREAM.           71850015
         ST    DP,SPR(0,GRDIC)         SET SPR                          71900015
         SPACE                                                          71950015
         ST    OP,OPP(0,GRDIC)         STORE AWAY THE OUTPUT POINTER    72000015
         SPACE                                                          72050015
         LA    GRA,4(0,0)              ENSURE THAT WE HAVE FOUR PLACES  72100015
         BAL   RR,OPTEST(0,GR12)       AVAILABLE IN THE OUTPUT STREAM.  72150015
         SPACE                                                          72200015
         MVI   0(OP),X'70'             MOVE IN THE PREFIX OPTION        72250015
*                                      IDENTIFIER BYTE.                 72300015
         SPACE                                                          72350015
         MVI   3(OP),LPAR              PUT IN THE LEFT PARENTHESIS.     72400015
         SPACE                                                          72450015
         AR    OP,GRA                  BUMP THE OUTPUT POINTER.         72500015
         SPACE                                                          72550015
         MVI   CHKSW,NONE              INITIALISE CHKSW                 72600015
         MVI   COMASW,NONE           AND COMASW                   28518 72620020
POPB     BAL   RR,BUMP                 SCAN TO NEXT NON BLANK           72650015
         SPACE                                                          72700015
*              DURING THIS PASS WE MAKE ONLY THE LEAST INVESTIGATION    72750015
*        OF PREFIX OPTION LISTS.   FULL INVESTIGATION IS DELAYED UNTIL  72800015
*        THE FOURTH PASS.                                               72850015
         SPACE                                                          72900015
POPA     BAL   RR,TRCHAR(0,GR15)       TEST FOR AN ALPHABETIC           72950015
         BH    IDNT                    ALPHABETIC FOUND           25908 72960020
         CLI   0(DP),COMMA             IS NEXT CHAR. A ,          25908 72970020
         BE    POPDUMY                 YES                        25908 72980020
         CLI   0(DP),RPAR              IS NEXT CHAR. A )?         25908 72990020
         BE    POPDUMY                 YES                        25908 73000020
         CLI   0(DP),COLON             IS NEXT CHAR. A :?         25908 73010020
         BNE   POPO                    NO                         25908 73020020
POPDUMY  LA    GRA,2                   TEST FOR SPACE IN O/P TEXT 25908 73030020
         BAL   RR,OPTEST(0,GR12)       TO INSET DUMMY DIC. REF.   25908 73040020
         MVI   0(OP),X'01'             MOVE IN LENGTH             25908 73050020
         MVI   1(OP),DUMMY             MOVE IN DUMMY              28518 73060020
         AR    OP,GRA                                             25908 73070020
         CLI   CHKSW,ALLONE            ARE WE IN A CHECK LIST?    25908 73080020
         BNE   POPC                    NO                         25908 73090020
         BAL   RR,MESGE1(0,GR12)       MESSAGE 82 - OPERAND       25908 73100020
         DC    X'5248'                 MISSING FROM CHECK LIST    25908 73110020
         B     POPC                                               25908 73120020
         SPACE 1                                                        73130020
*              HERE WE ARE LOOKING AT AN IDENTIFIER.              25908 73140020
         SPACE 1                                                        73150020
IDNT     EQU   *                                                  25908 73160020
         MVI   ARGSW,NONE              ALL ZEROS                  28518 73165020
         LA    GR2,TRUARG              SET UP EXIT1 FROM POPKWD   28518 73170020
         B     POPKWD                                             28518 73175020
TRUARG   L     DP,START1(0,GRDIC)      RELOAD START OF IDENTIFIER 28518 73180020
         MVI   COMASW,ALLONE           SET COMMA SWITCH TO ONES   28518 73185020
         MVI   ARGSW,ALLONE            ALL ONES                   28518 73190020
         BAL   RR,IDENT(0,GR15)        USE THE IDENT ROUTINE TO WORK    73200015
*                                      OUT WAY THROUGT THE KEYWORD.     73250015
         SPACE                                                          73300015
*              HERE WE ARE LOOKING AT THE NEXT NON-BLANK ITEM FOLLOWING 73350015
*        THE KEYWORD.                                                   73400015
         SPACE                                                          73450015
         CLI   CHKSW,ALLONE                                             73500015
         BC    BE,POPZ                 BRANCH IF IN CHECK LIST          73550015
         CLI   0(DP),LPAR              TEST FOR (                       73600015
         BC    BE,POPI                                                  73650015
POPC     CLI   0(DP),COMMA             TEST FOR COMMA                   73700015
         BC    BE,POPJ                                                  73750015
         CLI   0(DP),RPAR              TEST FOR )                       73800015
         BC    BE,POPR                                                  73850015
         CLI   0(DP),COLON             TEST FOR COLON                   73900015
         BC    BNE,POPO                ERROR IF NONE OF THESE           73950015
         BAL   RR,MESAGE(0,GR12)       MESSAGE 114-) INSERTED IN P O.   74000015
         DC    X'7248'                                                  74050015
         BC    B,POPS                                                   74100015
         SPACE                                                          74150015
*              ( SHOWS THE START OF A CHECK LIST                        74200015
POPI     MVI   CHKSW,ALLONE            SET CHKSW ON                     74250015
         SPACE                                                          74300015
POPJ     BAL   RR,OPTST1(0,GR12)                                        74350015
         MVI   COMASW,NONE             SET COMMA SWITCH TO ZEROS  28518 74370020
         MVC   0(1,OP),0(DP)           MOVE CHARACTER FROM DP TO OP     74400015
         AR    OP,UR                                                    74450015
         BC    B,POPB                                                   74500015
         SPACE                                                          74550015
POPZ     CLI   0(DP),PERIOD            TEST FOR QUALIFIED NAME          74600015
         BC    BNE,POPC                                                 74650015
         BC    B,POPJ                                                   74700015
         SPACE                                                          74750015
*              ) FOUND                                                  74800015
POPR     BAL   RR,BUMP                 GO TO NEXT NON BLANK             74850015
POPS     EQU   *                                                  28518 74950020
         BAL   RR,OPTST1(0,GR12)                                        75100015
         MVI   0(OP),RPAR              MOVE ) TO OP                     75150015
         AR    OP,UR                                                    75200015
         CLI   CHKSW,ALLONE                                             75250015
         BC    BE,POPH                 BRANCH IF END OF CHECK LIST      75300015
         SPACE                                                          75350015
*              NOW SHOULD BE AT END OF COMPLETE PREFIX LIST             75400015
         SPACE                                                          75450015
         CLI   0(DP),COLON             DETERMINE WHETHER OR NOT THE     75500015
         BC    BNE,POPL                NECESSARY COLON IS IN EVIDENCE.  75550015
         BAL   RR,BUMP                 BUMP OVER COLON                  75600015
         SPACE                                                          75650015
*              HERE WE ARE ALL SET TO MAKE A DICTIONARY REFERENCE       75700015
         SPACE                                                          75750015
POPN     TM    LBLPOP,MIXED1           INVALID PREFIX OPTION IF   47697 75800056
         BC    BO,POPP       LABEL ALREADY FOUND FOR THIS STMNT   47697 75850056
         MVI   POPSW(GRDIC),ALLONE     GO TO THE MAIN SCAN TO BUMP THE  75900015
         BC    B,RNOON                 STATEMENT NUMBER IF THE JOB HAS  75950015
* 9                                    NOT ALREADY BEEN DONE.           76000015
         SPACE                                                          76050015
POPM     EQU   *                                                        76100015
         SPACE                                                          76150015
         LA    GRA,2(0,0)              ENSURE THAT WE HAVE TWO PLACES   76200015
         BAL   RR,OPTEST(0,GR12)       AVAILABLE IN THE OUTPUT STREAM.  76250015
         SPACE                                                          76300015
         MVC   0(2,OP),ZSTAT(GRDIC)    MOVE IN THE STATEMENT NUMBER     76350015
         AR    OP,GRA                  AND BUMP THE OUTPUT POINTER.     76400015
         SPACE                                                          76450015
         L     GRB,OPP(0,GRDIC)        GET THE LENGTH OF THE DICTIONARY 76500015
         SR    OP,GRB                  ENTRY INTO A REGISTER.           76550015
         SPACE                                                          76600015
         STH   OP,POPTMP               MOVE THE LENGTH INTO THE ENTRY   76650015
         MVC   1(2,GRB),POPTMP                                          76700015
         SPACE                                                          76750015
         ST    OP,PAR2(0,GRDIC)        SET UP PARAMETER SLOTS READY TO  76800015
         ST    GRB,PAR1(0,GRDIC)       INSERT THE ENTRY INTO THE        76850015
*                                      DICTIONARY.                      76900015
         SPACE                                                          76950015
         L     OP,OPP(0,GRDIC)         RESET THE OUTPUT POINTER.        77000015
         SPACE                                                          77050015
         SPACE                                                          77100015
       SPACE                                                            77150015
         SPACE                                                          77200015
         BC    B,RDENT                 AND GO TO MAKE THE ENTRY AND     77250015
*                                      CONTINUE SCANNING.               77300015
         SPACE 3                                                        77350015
*              HERE WE HAVE AN APPARENTLY VALID PREFIX OPTION LIST      77400015
*        EXCEPT THAT IT IS NOT FOLLOWED BY A COLON.                     77450015
         SPACE                                                          77500015
POPL     CLI   ERRFLG(GRDIC),X'FF'     TEST WHETHER OR NOT WE ARE SURE  77550015
*                                      WE ARE AT THE START OF A NEW     77600015
*                                      STATEMENT.                       77650015
         SPACE                                                          77700015
         BE    DELODOP                 DELETE STATEMENT           28518 77750020
         BAL   RR,MESAGE(0,GR12)       MESSAGE 85                       77800015
         DC    X'5548'                 COLON INSERTED                   77850015
         BC    B,POPN                                                   77900015
         SPACE                                                          77950015
*              HERE ALL MAJOR SYNTAX ERRORS ARE DEALT WITH.       28518 77956020
         SPACE 1                                                        77962020
POPO     ST    DP,POPTMP               SAVE PTR. TO DODGY I/P     28518 77970020
         LA    GR2,QUOTST              SET UP EXIT2 FROM POPKWD   28518 77978020
         CLI   0(DP),QUOTE             IF THE NEXT CHAR IS A QUOTE49735 77980056
         BC    BE,QUOT2TST             GO AND SCAN FOR ITS MATE   49735 77982056
POPOLOOP CLI   0(DP),SCOLON            IS NEXT CHAR. A ;?         28518 77986020
         BNE   POPCOLN                 NO                         28518 77992020
         BAL   RR,MESGE1(0,GR12)       MESSAGE 126 -              28518 77998020
         DC    X'7E44'                 STATEMENT TOO MESSY        28518 78004020
         B     DELPOPST                DELETE STATEMENT           28518 78010020
POPCOLN  BAL   RR,BUMP                 BUMP TO NEXT NON-BLANK     28518 78016020
         CLI   0(DP),COLON             IS NEXT CHAR. A :?         28518 78022020
         BNE   POPKWD                  NO                         28518 78028020
DELMESS  MVC   PAR7(4,GRDIC),POPTMP    PASS START OF TEXT TO BE   28518 78034020
*                                      DELETED                    28518 78040020
         BAL   RR,MESAGE(0,GR12)       MESSAGE 127 - INVALID TEXT 28518 78046020
         DC    X'7FC4'                 IN PREFIX OPTIONS LIST     28518 78052020
         B     POPINCLN                YES                        28518 78062020
POPKWD   SR    GRA,GRA                 IS I/P PTR. POINTING AT A  28518 78088020
         BAL   RR,KEYWD(0,GR12)        VALID KEYWORD?             28518 78094020
         BR    GR2                     EXIT                       28518 78098020
         NOPR  0                       PADDING FOR KEYWORD RETURN 28518 78102020
         CLI   0(DP),COMMA             IS KEYWORD FOLLOWED BY ,?  28518 78106020
         BCR   BE,GR2                  YES - EXIT                 28518 78110020
         CLI   0(DP),RPAR              IS KEYWORD FOLLOWED BY )?  28518 78114020
         BCR   BE,GR2                  YES - EXIT                 28518 78118020
         CLI   0(DP),COLON             IS KEYWORD FOLLOWED BY :?  28518 78122020
         BCR   BE,GR2                  YES - EXIT                 28518 78126020
         L     DP,START1(0,GRDIC)      IT IS. RELOAD THE START OF 28518 78136020
*                                      STATEMENT PROPER           28518 78142020
         TS    ARGSW                   IS ARGSW ALL ZEROS?        28518 78152020
         BNZ   DELMESS                 DELETE MANGLED PART OF     28518 78162020
*                                      PREFIX OPTIONS LIST        28518 78178020
POPINCLN BCTR  DP,0                    STEP I0P PTR. DOWN 1       28518 78178420
         MVI   0(DP),COLON             MOVE COLON TO INPUT TEXT   28518 78178820
         BAL   RR,MESGE1(0,GR12)       MESSAGE 85 -               28518 78179220
         DC    X'5548'                 COLON INSERTED             28518 78179620
         TS    COMASW                  IS IT ZEROS?               28518 78180020
         BNZ   POPC                    NO                         28518 78180420
         B     POPDUMY                                            28518 78180820
QUOTST   CLI   0(DP),QUOTE             IS NEXT CHAR. A QUOTE?     28518 78181220
         BNE   EQLTST                  NO                         28518 78181620
QUOT2TST BAL   RR,BUMP                                            28518 78182020
         CLI   0(DP),QUOTE             IS NEXT CHAR. A 2ND QUOTE? 28518 78182420
         BNE   QUOT2TST                NO                         28518 78182820
         B     POPCOLN                 YES                        28518 78183220
EQLTST   CLI   0(DP),EQUALS            IS NEXT CHAR. AN =?        28518 78184020
         BNE   POPOLOOP                NO                         28518 78190020
         BAL   RR,MESGE1(0,GR12)       MESSAGE 135 - EXPRESSION   28518 78196020
         DC    X'8744'                 ON L.H.S. OF ASSIGNMENT    28518 78202020
         B     DELPOPST                DELETE STATEMENT           28518 78222020
POPH     MVI   CHKSW,NONE              NOE OUT OF CHECK LIST            78250015
         BC    B,POPC                                                   78300015
POPP     BAL   RR,MESAGE(0,GR12)       MESSAGE116-PREFIX OPTION         78350015
         DC    X'7448'               AFTER LABEL IS IGNORED             78400015
         L     OP,SPO(0,GRDIC)         DELETE P O                       78450015
         BC    B,RLETTR                                                 78550015
DELPOPST MVI   ERRFLG(GRDIC),ALLONE    STATEMENT IN ERROR         28518 78558020
DELODOP  L     OP,OPP(0,GRDIC)         RE-INITIALISE THE O/P PTR. 28518 78566020
         B     BADST1                                             28518 78574020
ARGSW    DC    X'FF'                                              28518 78582020
COMASW   DC    X'FF'                   COMMA SWITCH               28518 78590020
CHKSW    DC    X'00'                                                    78600015
POPTMP   DC    1F'0'                                                    78650017
         EJECT                                                          78700015
LABENT   DC    X'000013'                                                78750015
         DC    XL11'00'                                                 78800015
         DC    XL16'00'                                                 78850015
         DC    XL16'00'                                                 78900015
         DC    XL8'00'                                                  78950015
ST3FLG   DC    X'00'                                                    79000015
RSTSW    DC    X'00'                   READ STRING SWITCH               79050015
         SPACE                                                          79100015
PATERN   DC    X'402020202020'                                          79150015
         CNOP  0,8      ALIGN ' WORK ' ON A DOUBLE WORD                 79200015
WORK     DC    C'       1'                                              79250015
LTH      EQU   71                                                       79350015
SIGLTH   DC    F'71'                                                    79400015
RCDLTH   DC    F'80'                   LENGTH OF INPUT RECORD           79450015
TRTST    DC    F'0'                    TEMP CELL FOR READ ROUTINE       79500015
BADCHR   DC    XL4'00'                                                  79550015
ZERO     DC    XL4'00'                                                  79600015
X81      DC    H'129'                                                   79650015
ONE      DC    X'0001'                                                  79700015
FOUR     DC    XL2'04'                                                  79750015
***************************************************************** 47697 79770056
*              2 REDUNDANT CONSTANTS DELETED TO MAKE ROOM FOR     47697 79790056
*        APAR 47697 FIX (V 5.3B).                                 47697 79810056
***************************************************************** 47697 79830056
HWTEMP   DS    H                       HALF-WORD TEMP.            28532 79870020
EOP      DC    X'D00000EBEF'                                            79900015
OUT      DC    X'006440'                                                79950015
X60      DC    XL1'3C'                                                  80000015
ALFFLG   DC    X'00'                                                    80050015
       SPACE 2                                                          80100015
*              THIS IS A DUMMY PROCEDURE STATEMENT. THIS IS INSERTED IF 80150015
*        THE FIRST STATEMENT IS NOT A PROCEDURE. THE FIRST THREE BYTES  80200015
*        ARE THE CONTAINING BLOCK LEVELS AND COUNTS REQUIRED LATER WHEN 80250015
*        THIS STATEMENT IS COMPLETED.                                   80300015
       SPACE                                                            80350015
DMPROC   DC    X'D00001E30000000101EF'                                  80400015
       SPACE 2                                                          80450015
ENTSW    DC    XL1'00'                                                  80500015
FRSTSW   DC    XL1'00'                                                  80550015
NULLSW   DC    X'00'                                                    80600015
LBLPOP   DC    X'00'         FIRST 4 BITS ARE LABEL FLAG          47697 80650056
*                            LAST 4 BITS ARE PREFIX OPTION FLAG   47697 80700056
NOLBFL   DC    X'00'                   NO LABEL FLAG.                   80750015
TYPE     DC    X'00'                                                    80800015
STSIZE   DC    H'512'                                                   80850015
COLNO    DC    F'0'          ****  MOVED FROM END TO GET           H126 82260017
*                            ****  ADDRESSIBILITY                  H126 82270017
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 004-TSS 82280019
*        ----------------------------------------------------CI 004-TSS 82290019
STAB     DC    X'1C1C1C1C1C1C1C1C'                                      82300015
         DC    X'1C1C1C34341C200C'                                      82350015
         DC    X'1C38001C1C00381C'                                      82400015
         DC    X'080414001024281C'                                      82450015
         DC    X'1C1C1C1C1C1C1C1C'                                      82500015
         DC    X'301C1C1C1C1C1C1C'                                      82550015
         DC    X'1C1C1C0018000000'                                      82600015
         DC    X'00000000002C'                                          82650015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 006-TSS 82660019
*        ----------------------------------------------------CI 006-TSS 82670019
         EJECT                                                          82700015
*              SYMBOLIC OFFSETS IN THE COMMUNICATIONS REGION - READ IN  82750015
ZCOMM    EQU   304                                                      82800015
         SPACE                                                          82850015
ZCALLC   EQU   ZCOMM+0                 START OF CALL CHAIN              82900015
ZLABTB   EQU   ZCOMM+4                 START OF LABEL TABLE             82950015
ZIMPCH   EQU   ZCOMM+8                 START OF IMPLICIT CHAIN          83000015
ZALLCH   EQU   ZCOMM+12                START OF ALLOCATE CHAIN          83050015
ZFLAG1   EQU   ZCOMM+16                COMMUNICATIONS FLAG              83100015
*              THE FOLLOWING FLAGS ARE CONTAINED IN ZFLAG1              83150015
BIT1     EQU   X'80'                   DEFINED WITH ISUB FLAG           83200015
BIT2     EQU   X'40'                   ALLOCATE WITH ATTRIBUTE FLAG     83250015
BIT3     EQU   X'20'                   INITIAL FLAG                     83300015
BIT4     EQU   X'10'                   DIMENSION FLAG                   83350015
BIT5     EQU   X'08'                   PICTURE FLAG                     83400015
BIT6     EQU   X'04'                   ON FLAG                          83450015
BIT7     EQU   X'02'                   LIKE FLAG                        83500015
BIT8     EQU   X'01'                   DECLARE FLAG                     83550015
ZFLAG2   EQU   ZCOMM+17                                                 83600015
ZFLAG3   EQU   ZCOMM+18                                                 83650015
ZIFCT    EQU   ZCOMM+19                IF COUNT                         83700015
ZNIFCT   EQU   ZCOMM+21                NESTED IF COUNT                  83750020
ZDOCT    EQU   ZCOMM+22                DO COUNT                         83800015
ZBEGCT   EQU   ZCOMM+23                BEGIN COUNT                      83850015
ZPROCT   EQU   ZCOMM+24                PROCEDURE COUNT                  83900015
BCB      EQU   ZCOMM+60                BEGINING OF CURRENT BLOCK        83950015
ECB      EQU   BCB+4                   END OF CURRENT BLOCK             84000015
BRA      EQU   ECB+4                   START OF READ AREA               84050015
ERA      EQU   BRA+4                   END OF READ AREA                 84100015
RP       EQU   ERA+4                   END OF LAST INPUT SECTION IN THE 84150015
*                                    READ AREA                          84200015
SPO      EQU   RP+4                    POINTER TO START OF CURRENT      84250015
*                                    STATEMENT IN TEXT AREA             84300015
STP      EQU   SPO+4                   STACK POINTER                    84350015
BSTACK   EQU   STP+4                   START OF STACK                   84400015
LSTACK   EQU   BSTACK+4                LIMIT OF STACK                   84450015
OPP      EQU   LSTACK+4                TEXT STRING POINTER              84500015
STARTO   EQU   OPP+4                   READ AREA POINTERS               84550015
START1   EQU   STARTO+4                                                 84600015
START2   EQU   START1+4                                                 84650015
START3   EQU   START2+4                                                 84700015
SPR      EQU   START3+4                START OF CURRENT STATEMENT IN    84750015
*                                    READ AREA                          84800015
LOP      EQU   SPR+4                   POINTER TO THE LAST BYTE OF      84850015
*                                    VALID PROGRAM                      84900015
TEXTST   EQU   LOP+4                   START OF STATEMENT EXCLUDING     84950015
*                                    LABELS IN READ AREA                85000015
DICPTR   EQU   TEXTST+4                DICTIONARY REFERENCE OF LATEST   85050015
*                                    LABEL.                             85100015
LBLPTR   EQU   DICPTR+2                DICTIONARY REFERENCE OF FIRST    85150015
*                                    LABEL FOR CURRENT STATEMENT.       85200015
ERRPTR   EQU   LBLPTR+2                POSITION IN ERROR CHAIN AT START 85250015
*                                    OF STATEMENT                       85300015
LSTNO    EQU   ERRPTR+4                LAST STATEMENT NUMBER            85350015
OSTAT    EQU   LSTNO+2                 MOST RECENT STATEMENT NUMBER     85400015
PL       EQU   OSTAT+2                 PROCEDURE LEVEL                  85450015
BGL      EQU   PL+1                    BEGIN LEVEL                      85500015
BN       EQU   BGL+1                   BLOCK NUMBER                     85550015
PAS      EQU   BN+1                    POSSIBLE ASSIGNMENT SWITCH       85600015
PSTYPE   EQU   PAS+1                   PREVIOUS STATEMENT TYPE          85650015
STYPE    EQU   PSTYPE+1                STATEMENT TYPE                   85700015
ENDFLG   EQU   STYPE+1                 MARKS HAVING REACHED LOGICAL     85750015
*                                    END OF PROGRAM                     85800015
IFNO     EQU   ENDFLG+1                NUMBER OF IF STATEMENTS          85850015
CARDNO   EQU   IFNO+1                  MARKS STATEMENT NUMBER ALREADY   85900015
*                                    OUTPUT                             85950015
ERRFLG   EQU   CARDNO+1                ON IF SEMI-COLON IS MISSING      86000015
*                                    IN PREVIOUS STATEMENT              86050015
POPSW    EQU   ERRFLG+1                                                 86100015
INVDSW   EQU   POPSW+1                                                  86150015
CMPLBL   EQU   POPSW+2                                                  86200015
INFLAG   EQU   POPSW+5                 INTIAL ATTRIBUTE FLAG. ONE BYTE. 86250015
EXPSW    EQU   INFLAG+1                I/O SCAN AHEAD SWITCH. ONE BYTE  86300015
ITERFL   EQU   EXPSW+1                                                  86350015
SOFLSW   EQU   POPSW+10                                                 86400015
OFSW     EQU   SOFLSW+1                                                 86450015
DEFSW    EQU   OFSW+1                                                   86500015
NUMSW    EQU   DEFSW+1                                                  86550015
BASREG   EQU   NUMSW+1                                                  86600015
BASEB5   EQU   BASREG+4                                                 86650015
BASEBA   EQU   BASEB5+4                                                 86700015
KEYBAS   EQU   BASEBA+4                                                 86750015
OUTBUF   EQU   BCB+124                                                  86800015
BKNAME   EQU   BCB+248                                                  86850015
LSTCM0   EQU   BKNAME+4                POSN OF LAST COMMA AT ZERO PAREN 86900015
IBNAME   EQU   LSTCM0+4                                                 86950015
COMST    EQU   IBNAME+4                                                 87000015
DEFSUB   EQU   COMST+4                                                  87050015
DEFFLG   EQU   DEFSUB+4                                                 87100015
PICSRT   EQU   DEFFLG+4                                                 87150015
SOURCN   EQU   PICSRT+6                COUNT OF SOURCE RECORDS.     I16 87160017
STMNTN   EQU   SOURCN+2                COUNT OF SOURCE STATEMENTS.  I16 87170017
         SPACE                                                          87200015
BKL      EQU   OSTAT+2                                                  87250015
BKC      EQU   BKL+1                                                    87300015
PICFFL   EQU   BKC+1                   PICTURE FORMAT FLAG              87350015
         EJECT                                                          87400015
*              OFFSETS IN COMMUNICATIONS REGION - COMMON                87450015
         SPACE                                                          87500015
ZTV      EQU   64                                                       87550015
ZTRAN1   EQU   ZTV+4                   TRANSLATE TABLE ADDRESS -        87600015
*                                    EXTERNAL TO INTERNAL               87650015
ZTRAN2   EQU   ZTRAN1+4                 INTERNAL TO EXTERNAL            87700015
ZNXTD    EQU   ZTRAN2+6                NEXT DIC. REF.                   87750015
ZERRD    EQU   ZNXTD+2                 ERROR CHAIN HEADERS              87800015
ZERRS    EQU   ZERRD+4                                                  87850015
ZERRW    EQU   ZERRS+4                                                  87900015
ZERRC    EQU   ZERRW+4                                                  87950015
ZDNXT    EQU   ZERRC+4                  CURRENT ENDS OF ERROR CHAINS    88000015
ZSNXT    EQU   ZDNXT+4                                                  88050015
ZWNXT    EQU   ZSNXT+4                                                  88100015
ZCNXT    EQU   ZWNXT+4                                                  88150015
ZNAME    EQU   ZCNXT+4                  NAME OF CURRENT PHASE           88200015
ZCNCHR   EQU   ZNAME+6                                                  88230015
ZPROCN   EQU   ZCNCHR+2                START OF PROC CHAIN              88260015
ZSTAT    EQU   ZPROCN+6                 CURRENT STATEMENT NUMBER        88300015
PAR1     EQU   ZSTAT+2                                                  88350015
PAR2     EQU   PAR1+4                                                   88400015
PAR3     EQU   PAR2+4                                                   88450015
PAR4     EQU   PAR3+4                                                   88500015
PAR5     EQU   PAR4+4                                                   88550015
PAR6     EQU   PAR5+4                                                   88600015
PAR7     EQU   PAR6+4                                                   88650015
PAR8     EQU   PAR7+4                                                   88700015
ZDIC1    EQU   PAR8+4                                                   88750015
ZNXTOF   EQU   ZDIC1+X'2E'             NEXT OFFSET SLOT                 88800015
SSTEXT   EQU   256                                                      88850015
CCCODE   EQU   232                                                      88900015
DBSIZE   EQU   260                                                      88950015
TBSIZE   EQU   264                                                      89000015
RASIZE   EQU   268                                                      89050015
       SPACE                                                            89100015
*              SYMBOLIC OFFSETS OF ROUTINES IN COMPILER CONTROL.        89150015
       SPACE                                                            89200015
ZUPLOF   EQU   8                       PRINTS A LINE                    89250015
ZURD     EQU   12                      READS A CARD                     89300015
ZUGC     EQU   16                      GETS SCRATCH CORE                89350015
ZUTXTC   EQU   20                      GETS TEXT BLOCK                  89400015
ZURC     EQU   24                      RELEASES SCRATCH CORE            89450015
ZUPGMC   EQU   28                                                       89500015
ZABORT   EQU   32                      DUMPS AND GOES TO ERROR MESSAGE  89550015
*                                    ROUTINES                           89600015
ZLOADW   EQU   36                      LOADS AND RETURNS TO CALLER      89650015
ZDICAB   EQU   40                      DICTIONARY ENTRY WITH AN         89700015
*                                    ABSOLUTE ADDRESS                   89750015
ZDRFOF   EQU   44                                                       89800015
ZUERR    EQU   48                      MAKES ERROR MESSAGE ENTRY        89850015
ZDRFAB   EQU   52                      CONVERTS DICTIONARY REFERENCE    89900015
*                                    TO ABSOLUTE ADDRESS                89950015
ZDUMP    EQU   56                      DUMP CORE AND CONTINUE           90000015
REQEST   EQU   64                      GIVE A LIST OF PHASE NAMES       90050015
*                                    REQUIRED OR NOT WANTED FOR         90100015
*                                    THIS COMPILATION                   90150015
RELESE   EQU   68                                                       90200015
ZSOR     EQU   288                                                      90250015
ZMAG     EQU   290                                                      90300015
RLSCTL   EQU   72                      RELEASES ALL NAMED PHASES        90350015
*                                    AND PASSES TO NEXT PHASE           90400015
ZTXTRF   EQU   80                      ABSOLUTE TO TEXT REFERENCE       90450015
ZTXTAB   EQU   84                      TEXT REFERENCE TO ABSOLUTE       90500015
ZCHAIN   EQU   88                      FIND NEXT BLOCK IN CHAIN         90550015
ZALTER   EQU   92                      CHANGE TEXT BLOCK STATUS         90600015
ZDABRF   EQU   96                      ABSOLUTE TO DICTIONARY REFERENCE 90650015
       SPACE                                                            90700015
       SPACE                                                            90750015
         EJECT                                                          90800015
FSTNO    EQU   X'00'                                                    90850015
SIGLTA   EQU   80                                                       90900015
LTA      EQU   79                                                       90950015
CPICT    EQU   X'49'                                                    91000015
C8       EQU   X'C8'                                                    91050015
PREOPT   EQU   X'50'                                                    91100015
DUMMY   EQU   X'1F'                                                     91150015
OFOUR    EQU   X'04'                                                    91200015
X80      EQU   X'80'                                                    91250015
X05      EQU   X'05'                                                    91300015
X06      EQU   X'06'                                                    91350015
X0C      EQU   X'0C'                                                    91400015
X32      EQU   X'32'                                                    91450015
X46      EQU   X'46'                                                    91500015
X8B      EQU   X'8B'                                                    91550015
XC0      EQU   X'C0'                                                    91600015
SN       EQU   X'D0'                                                    91650015
SL     EQU     X'D2'                                                    91700015
SLDASH   EQU   X'D3'                   INITIAL LABEL                    91750015
INITLB   EQU   X'40'                   INITIAL LABEL FLAG IN LCNT 47697 91756056
*              WHEN AN INITIAL LABEL IS ENCOUNTERED, MODULE IEMCG 47697 91762056
*        SWITCHES ON THE FIRST 2 BITS IN LCNT. THE FIRST BIT IS   47697 91768056
*        SWITCHED OFF WHEN AN ORDINARY LABEL IS SUBSEQUENTLY FOUND47697 91774056
*        FOR THE STATEMENT. THE SECOND BIT IS NOT SWITCHED OFF    47697 91780056
*        UNTIL THE WHOLE STATEMENT HAS BEEN PROCESSED.            47697 91786056
MLBADC   EQU   X'81'       MULTIPLE LABEL AND ADCON REQUIRED BITS 47697 91792056
PICODE   EQU   X'49'                                                    91800015
FLCODE   EQU   X'42'                                                    91850015
VRCODE   EQU   X'48'                                                    91900015
CHCODE   EQU   X'4B'                                                    91950015
OPCODE   EQU   X'50'                                                    92000015
NLTYPE   EQU   X'9D'                                                    92050015
ASTYPE   EQU   X'9F'                                                    92100015
PRTYPE   EQU   X'B3'                                                    92150015
P1TYPE   EQU   X'D1'                                                    92200015
ILTYPE  EQU   X'AB'                                                     92250015
DCTYPE   EQU   X'AD'                                                    92300015
ENDDO   EQU   X'E7'                                                     92350015
ENITDO  EQU   X'E8'                                                     92400015
UNARYP  EQU   X'7D'                                                     92450015
UNARYM EQU   X'7B'                                                      92500015
BLANK    EQU   X'40'                                                    92550015
EQUAL    EQU   X'6B'                                                    92600015
UNSCOR   EQU   X'0A'                   UNDERSCORE                       92650015
PLUS     EQU   X'75'                                                    92700015
MINUS    EQU   X'73'                                                    92750015
COLON    EQU   X'48'                                                    92800015
QUOTE    EQU   X'42'                                                    92850015
LPAR     EQU   X'43'                                                    92900015
COMMA    EQU   X'41'                                                    92950015
PERCNT   EQU   X'4A'                                                    93000015
SCOLON   EQU   X'EF'                                                    93050015
SLASH    EQU   X'77'                                                    93100015
STAR     EQU   X'79'                                                    93150015
EQUALS   EQU   X'6B'                                                    93200015
PERIOD   EQU   X'46'                                                    93250015
GT       EQU   X'6D'                                                    93300015
RPAR     EQU   X'45'                                                    93350015
NONE     EQU   X'00'                                                    93400015
ALLONE   EQU   X'FF'                                                    93450015
MIXED1   EQU   X'F0'                                              47697 93460056
MIXED2   EQU   X'0F'                                              47697 93470056
       SPACE                                                            93500015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 026-TSS 93520021
NEXTPH   EQU   PASS                                                     93550015
*        ----------------------------------------------------CI 026-TSS 93560021
TAB2OF   EQU   X'280'                  OFFSET OF TAB2 IN CE       28518 93570020
         EJECT                                                          93600015
         SPACE 5                                                        93650015
DICLTH   EQU   B5+2                                                     93700015
LBLTMP   EQU   B5+4                                                     93750015
MES1   EQU     BD0                                                      93800015
MES2   EQU     BD0+4                                                    93850015
STEXT    EQU   BD0+8                                                    93900015
PRTEMP EQU     BD0+12                                                   93950015
REGSTO EQU     BD0+16                                                   94000015
RET1   EQU     BD0+20                                                   94050015
STP1   EQU     BD0+24                                                   94100015
LBLABS EQU     BD0+28                                                   94150015
COUNT  EQU     BD0+32                                                   94200015
OSTEMP   EQU   BD0+36                                                   94250015
DICABS EQU     BD0+40                                                   94300015
REGS   EQU     BD0+44                                                   94350015
TEMPZ    EQU   BD0+68                                             43444 94400021
TEMP     EQU   BD0+72                                             43444 94450021
         EJECT                                                          94500015
*                                                                       94550015
*              SYMBOLIC OFFSETS OF ROUTINES IN CA                       94600015
*                                                                       94650015
EXPAND   EQU   12                                                       94700015
EXP      EQU   EXPAND+4                                                 94750015
SINGLE   EQU   EXP+4                                                    94800015
EXPLST   EQU   SINGLE+4                                                 94850015
IDENT    EQU   EXPLST+4                                                 94900015
ACONST   EQU   IDENT+4                                                  94950015
SCONST   EQU   ACONST+4                                                 95000015
SQUID    EQU   SCONST+4                                                 95050015
DECINT   EQU   SQUID+4                                                  95100015
XPANDP   EQU   DECINT+4                                                 95150015
EXP2     EQU   XPANDP+4                                                 95200015
OPTOR    EQU   EXP2+4                                                   95250015
MVCHAR   EQU   OPTOR+4                                                  95300015
TRCHAR   EQU   MVCHAR+4                                                 95350015
         SPACE                                                          95400015
*              SYMBOLIC OFFSETS OF ROUTINES IN CC                       95450015
         SPACE                                                          95500015
*                                                                       95550015
KEYWD    EQU   8                                                        95600015
FLOAT    EQU   KEYWD+4                                                  95650015
PREC     EQU   FLOAT+4                                                  95700015
CHAR     EQU   PREC+4                                                   95750015
FILE     EQU   CHAR+4                                                   95800015
IOERR    EQU   FILE                                                     95850015
ONCOND   EQU   FILE+4                                                   95900015
OPTEST   EQU   ONCOND+4                                                 95950015
OPTST1   EQU   OPTEST+4                                                 96000015
OPTGET   EQU   OPTST1+4                                                 96050015
PICT     EQU   OPTGET+4                                                 96100015
CHECK    EQU   PICT+4                                                   96150015
NONEX    EQU   CHECK+4                                                  96200015
NULINS   EQU   NONEX+4                                                  96250015
MESAGE   EQU   NULINS+4                                                 96300015
SOFLOW   EQU   MESAGE+4                                                 96350015
MESGE1   EQU   SOFLOW+4                                                 96400015
SOFLW1   EQU   MESGE1+4                                                 96450015
MKBLOC   EQU   SOFLW1+4                                                 96500015
FREEZE   EQU   SOFLW1+8                                                 96510015
RESEXD   EQU   FREEZE+4                                                 96520015
BUMP1    EQU   RESEXD+4                                             I16 96530017
BUMPS    EQU   BUMP1+4                                              I16 96540017
CM1      EQU   BUMPS+4                                            21134 96545001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*CI 023-TSS 96546021
*        ----------------------------------------------------CI 023-TSS 96547021
       SPACE                                                            96550015
*              SYMBOLIC OFFSETS OF ROUTINES IN CG                       96600015
ONSW     EQU   5                       ON SWITCH                  30321 96620020
COMENT   EQU   8                                                        96650015
ERROR    EQU   COMENT+4                                                 96700015
END      EQU   ERROR+4                                                  96750015
ASSIGN   EQU   END+4                                                    96800015
DO       EQU   ASSIGN+4                                                 96850015
BEGIN    EQU   DO+4                                                     96900015
STAT2    EQU   BEGIN+4                                                  96950015
STRING   EQU   STAT2+4                                                  97000015
SETAG    EQU   STRING+4                                                 97050015
IF       EQU   SETAG+4                                                  97100015
ELSE     EQU   IF+4                                                     97150015
ON       EQU   ELSE+4                                                   97200015
XEND     EQU   ON+4                                                     97250015
SIGRVT   EQU   XEND+4                                                   97300015
ASSM     EQU   SIGRVT+4                                                 97350015
ERROR1   EQU   ASSM+4                                                   97400015
STSCOP   EQU   ERROR1+4                                                 97450015
INLBL    EQU   STSCOP+4                INITIAL LABELS                   97500015
NEST     EQU   INLBL+4                                                  97520015
HEAD     EQU   NEST+4                                                   97540015
LCNT     EQU   HEAD+4                                                   97560015
FRED     EQU   LCNT+4                                                   97600015
         EJECT                                                          97650015
*                  BRANCH ON CONDITION SYMBOLS                          97700015
         SPACE                                                          97750015
BNZ      EQU   7                                                        97800015
BZP      EQU   11                                                       97850015
B        EQU   15                                                       97900015
BR       EQU   15                                                       97950015
NOP      EQU   0                                                        98000015
NOPR     EQU   0                                                        98050015
BH       EQU   2                                                        98100015
BL       EQU   4                                                        98150015
BE       EQU   8                                                        98200015
BNH      EQU   13                                                       98250015
BNL      EQU   11                                                       98300015
BNE      EQU   7                                                        98350015
BO       EQU   1                                                        98400015
BP       EQU   2                                                        98450015
BM       EQU   4                                                        98500015
BZ       EQU   8                                                        98550015
         EJECT                                                          98600015
*                  VALUES OF SYMBOLIC REGISTERS                         98650015
         SPACE                                                          98700015
GRCC     EQU   11                      BASE OF COMPILER CONTROL         98750015
GRDIC    EQU   13                      BASE OF DICTIONARY               98800015
LR       EQU   15                      LINK TO COMPILER CONTROL         98850015
RR       EQU   14                      RETURN REGISTER                  98900015
GR15     EQU   15                                                       98950015
GR14     EQU   14                                                       99000015
GR13     EQU   13                                                       99050015
GRC      EQU   0                                                        99100015
DP       EQU   1                       DATA POINTER AND SCANNING.       99150015
GR2      EQU   2                                                        99200015
GRB      EQU   3                                                        99250015
GRA      EQU   4                                                        99300015
GRD      EQU   5                                                        99350015
GRE      EQU   6                                                        99400015
UR       EQU   7                       UNIT REGISTER                    99450015
OP       EQU   8                       OUTPUT STRING POINTER            99500015
GR9      EQU   9                                                        99550015
GR10     EQU   10                                                       99600015
GR12     EQU   12                                                       99650015
GRSH     EQU   2                                                        99700015
         DC    F'0'                                                     99750015
         END   IEMCI                                                    99800015
