EG       TITLE 'IEMEG, INITIALIZATION PHASE, DICTIONARY, OS/360 PL/I F' 00040015
*                                                                       00080064
*                                                                       00082064
*                                                                       00084064
*                                                                       00086064
* 5.4  C 704800-706400                                        MCB 52185 00088064
*      A 900200                                               MCB 52185 00090064
* 5.4  A 868400.                                              MAC 54771 00092064
*      C 866820-866848,875200-880800,889200-891600.           MAC 54771 00094064
* 5.4  C 802400.                                              MAC 52204 00096064
* 5.3B C 802400.                                              MAC 45962 00098064
* 5.2  A 249600.                                              MAC 28520 00100064
* 5.1  A 046800,052800,406800,864000,864800,866880.           MAC 28475 00102064
*      C 151200,162000-202400,262400-263200,284650-284700,    MAC 28475 00104064
*        320000,321200,348400,476500-476600,485300-485500,    MAC 28475 00106064
*        517800-518800,701200-702000,852000-852800,           MAC 28475 00108064
*        856400-860800,866860,899600-904760.                  MAC 28475 00110064
*      D 047200,153400-153600,861600-861800.                  MAC 28475 00112064
*              THE 'LABEL TABLE SCAN' ROUTINE WAS TRANSFERRED MAC 28475 00114064
*              FROM IEMEG TO IEMEF FOR THIS FIX.              MAC 28475 00116064
* R15          THIS MODULE CONTAINS A FIX FOR APAR 11016.               00118064
*                                                                       00120015
*                                                                       00160015
*                                                                       00200015
*                                                                       00240015
*              STATUS - CHANGE LEVEL 0                                  00280015
*                                                                       00320015
*                                                                       00360015
*                                                                       00400015
*              FUNCTIONS. (1) INITIALISES HASH TABLE                    00440015
*                         (2) SCANS LABEL TABLE IN DICTIONARY, AS       00480015
*        CREATED BY READ-IN AND INSERTS LABELS IN HASH CHAINS.          00520015
*        MULTIPLY DEFINED LABELS ARE SUPPRESSED AND AN ERROR MESSAGE    00560015
*        IS GENENERATED.                                                00600015
*                         (3) SCANS THE PROCEDURE-BEGIN AND ENTRY       00640015
*        CHAINS IS TEXT AND PROCESSES THE STATEMENTS AS FOLLOWS         00680015
*              FOR EACH PROCEDURE STATEMENT AND FOR EACH ENTRY STATE-   00720015
*        MENT IN ITS CHAIN, THE ENTRY TYPE 1 DICTIONARY ENTRY IS        00760015
*        CREATED.  THE FORMAL PARAMETERS ARE PROCESSED; THEIR ENTRY     00800015
*        TYPE 1 ENTRIES ARE CREATED.  IDENTICAL FORMAL PARAMETERS       00840015
*        (IN THE SAME BLOCK) ARE COMMONED TO THE SAME ENTRY.  ENTRY     00880015
*        TYPE 2 ENTRIES ARE CREATED FOR THE STATEMENTS' LABELS, THE     00920015
*        DATA INFORMATION BEING OBTAINED FROM THE STATEMENTS' ATTRIBUTE 00960015
*        LISTS AND DEFAULT RULES.                                       01000015
*              ENTRY TYPE 1 ENTRIES FOR BEGIN STATEMENTS ARE CREATED.   01040015
*              THE VARIOUS CHAINS LINKING THE ENTRY TYPE 1 ENTRIES ARE  01080015
*        GENERATED.                                                     01120015
*                         (4) 'MAP STACK' IS CREATED IN SCRATCH CORE.   01160015
*        THIS IS A STACK OF BLOCK NUMBERS SUCH THAT AN OFFSET EQUAL TO  01200015
*        A BLOCK NUMBER GIVES THE NUMBER OF THAT CONTAINING BLOCK.      01240015
*              ENTRY POINTS - CONTROL IS PASSED BY COMPILER CONTROL     01280015
*        TO THE THIRD BYTE OF THE MODULE, WHERE THE BASE REGISTER IS    01320015
*        LOADED.                                                        01360015
*                                                                       01400015
*                                                                       01440015
*                                                                       01480015
*              INPUT - COMMUNICATIONS REGION, LABEL TABLE IN DICTIONARY 01520015
*        AND TEXT AS LEFT BY READ-IN.                                   01560015
*                                                                       01600015
*                                                                       01640015
*                                                                       01680015
*              OUPUT - HASH TABLE AND 'MAP STACK' IN SCRATCH CORE.      01720015
*        COMMUNICATIONS REGION, DICTIONARY, AND SAME TEXT BLOCKS AS     01760015
*        FOR INPUT.                                                     01800015
*                                                                       01840015
*                                                                       01880015
*                                                                       01920015
*              EXTERNAL ROUTINES - (1) ZTXTAB. CONVERTS SYMBOLIC TEXT   01960015
*        REFERENCE TO ABSOLUTE.                                         02000015
*                                  (2) ZALTER. USED FOR ALTERING STATUS 02040015
*        OF TEXT BLOCKS WHEN SCANNING FROM ONE TO THE NEXT.             02080015
*                                  (3) ZDRFAB. CONVERTS SYMBOLIC        02120015
*        DICTIONARY REFERENCES TO ABSOLUTE.  USED FOR EXAMINING DICT-   02160015
*        IONARY ENTRIES.                                                02200015
*                                  (4) ZUGC.  USED FOR GETTING SCRATCH  02240015
*        CORE FOR HASH TABLE, ETC.                                      02280015
*                                  (5) ZURC.  RELEASES SCRATCH CORE.    02320015
*                                  (6) ZDICRF.  USED FOR MAKING DICT-   02360015
*        IONARY ENTRIES                                                 02400015
*                                  (7) ZUTXTC.  USED FOR GETTING MORE   02440015
*        TEXT BLOCKS IN THE EVENT OF THE SECOND FILE OVERFLOWING THE    02480015
*        PRESENT BLOCKS.                                                02520015
*                                  (8) ZUERR.  USED FOR CREATING ERROR  02560015
*        MESSAGE DICTIONARY ENTRIES.                                    02600015
*                                  (9) ZABORT.  USED FOR TERMINATING    02640015
*        COMPILER IN THE EVENT OF A TERMINAL ERROR.                     02680015
*                                  (10) RLSCTL.  USED FOR RETURNING     02720015
*              CONTROL TO COMPILER CONTROL.                             02760015
*                                  (11) ZDICRF.  INSERTS ENTRY IN       02800015
*        DICTIONARY AND RETURNS SYMBOLIC POINTER TO IT.                 02840015
*                                  (12) ZDABRF.  CONVERTS ABSOLUTE      02880015
*        DICTIONARY REFERENCE TO SYMBOLIC.                              02920015
*                                                                       02960015
*                                                                       03000015
*                                                                       03040015
*              EXITS, NORMAL - CONTROL IS RELEASED NORMALLY AT CAEND.   03080015
*                                                                       03120015
*                                                                       03160015
*                                                                       03200015
*              EXITS, ERROR -  COMPILATION IS TERMINATED IN THE EVENT   03240015
*        OF A COMPILER ERROR, AT CMPERR.  ROUTINE ZABORT IS CALLED.     03280015
*                                                                       03320015
*                                                                       03360015
*                                                                       03400015
*              TABLES AND WORK AREAS -                                  03440015
*                       (1)  HASH TABLE, CONSISTING OF ONE 512 BYTE     03480015
*        BLOCK OF SCRATCH CORE, CONTAINING TWO BYTE DICTIONARY REFER-   03520015
*        ENCES AS THE HEADS OF HASH CHAINS, AT OFFSETS GIVEN BY HASH    03560015
*        RESULTS.                                                       03600015
*                       (2)  'MAP STACK', THE SECOND HALF OF A 512 BYTE 03640015
*        BLOCK OF SCRATCH CORE, DESCRIBED UNDER FUNCTION (4) ABOVE.     03680015
*                       (3)  'BNSTK', THE FIRST HALF OF THE SCRATCH     03720015
*        BLOCK CONTAINING 'MAP STACK'.  IT IS USED FOR CREATING 'MAP    03760015
*        STACK'. IT CONTAINS A STACK OF BLOCK NUMBERS SUCH THAT AN      03800015
*        OFFSET EQUAL TO A BLOCK LEVEL GIVES THE NUMBER OF THE LAST     03840015
*        BLOCK ENCOUNTERED AT THAT LEVEL.                               03880015
*                       (4)'CASTK' IS A STACK SIMILAR TO 'BNSTK' BUT    03920015
*        IT CONTAINS DICTIONARY REFERENCES INSTEAD OF BLOCK NUMBERS.    03960015
*        IT IS USED FOR GENERATING THE 'CONTAING BLOCK CHAIN' IN ENTRY  04000015
*        TYPE 1 ENTRIES.                                                04040015
*                       (5) THE CODE USED FOR SCANNING THE LABEL TABLE  04080015
*        IS NOT REQUIRED ONCE THE TEXT SCAN HAS BEEN STARTED.  IT IS    04120015
*        THEREFORE USED AS A WORKSPACE, LARGELY FOR BUILDING ENTRY TYPE 04160015
*        1 ENTRIES, BUT ALSO FOR MANY OTHER MINOR USES.                 04200015
*                                                                       04240015
*                                                                       04280015
*                                                                       04320015
*              NOTES - THIS PHASE DOES NOT REQUIRE  ANY MODIFICATION AS 04360015
*        A RESULT OF CHANGES IN THE INTERNAL REPRESTATION OF EXTERNAL   04400015
*        GRAPHICS.                                                      04440015
         EJECT                                                          04480015
IEMEG    START 0                                                        04520015
         EJECT                                                          04560015
*                       SYMBOLIC REGISTERS                              04600015
         SPACE                                                          04640015
GRBASE   EQU   9                       BASE REGISTER OF MODULE          04680015
GREFB    EQU   12                      BASE REGISTER OF EF.             04700019
GRCC     EQU   11                      COMPILER CONTROL                 04760015
GRDIC    EQU   13                      DICTIONARY BASE                  04800015
GRUNIT   EQU   7                       MADE TO CONTAIN ONE              04840015
GRH      EQU   6                       POINTS TO HEAD OF HASH TABLE.    04880015
GRHASH   EQU   2                       RETURNS HASH RESULT.             04920015
GRLR     EQU   15                      BRANCHING REGISTER               04960015
GRRR     EQU   14                      RETURN REGISTER                  05000015
GRDP     EQU   8                       DICTIONARY SCAN POINTER          05040015
GRSP     EQU   8                       POINTS TO START OF STATEMENTS    05080015
*                                    DURING TEXT SCAN.                  05120015
GRPTR    EQU   1                       POINTER TO ITEM TO BE HASHED     05160015
GRP      EQU   1                       TEXT SCAN POINTER. N.B. USED IN  05200015
*                                    'TRT' INSTRUCTION.                 05240015
GR0      EQU   0                       **                               05280015
GRW      EQU   6                       *                                05300019
GRX      EQU   4                        *  WORKING REGISTERS            05320015
GRY      EQU   5                        *                               05360015
GRZ      EQU   10                      **                               05400015
GRLTH    EQU   3                       CONTAINS LENGTHS.                05440015
ATTPTR   EQU   2                       POINTER TO ATTRIBUTE COLLECTION  05480015
*                                    AREA, USED BY CDEFAT               05520015
         SPACE 5                                                        05560015
*                       BRANCHING MNEMONICS                             05600015
         SPACE 2                                                        05640015
BZ       EQU   8                       ZERO                             05680015
BM       EQU   4                       MINUS, OR MIXED                  05720015
BP       EQU   2                       POSITIVE                         05760015
BO       EQU   1                       ONES                             05800015
BNE      EQU   7                       NOT EQUAL                        05840015
BNL      EQU   11                      NOT LOW                          05880015
BNH      EQU   13                      NOT HIGH                         05920015
BE       EQU   8                       EQUAL                            05960015
BL       EQU   4                       LOW                              06000015
BH       EQU   2                       HIGH                             06040015
B        EQU   15                      UNCONDITIONAL BRANCH             06080015
BNZ      EQU   7                       NOT ZERO                         06120015
BNO      EQU   14                      NOT ONES                         06160015
         SPACE 10                                                       06200015
*                       INTERNAL CODES                                  06240015
DC       EQU   X'F8'                   DECIMAL INTEGER MARKER.          06280015
SC       EQU   X'EF'                   SEMI-COLON                       06320015
RB       EQU   X'45'                   RIGHT BRACKET                    06360015
LB       EQU   X'43'                   LEFT BRACKET                     06400015
COMMA    EQU   X'41'                                                    06440015
QUOTE    EQU   X'42'                                                    06480015
UNMI     EQU   X'7B'                   UNARY -                          06520015
UNPL     EQU   X'7D'                   UNARY +                          06560015
ATM      EQU   X'C8'                   ATTRIBUTE MARKER.                06600015
KSI      EQU   X'1F'                   READ-IN DUMMY                    06640015
SL       EQU   X'D2'                   STATEMENT LABEL MARKER           06680015
SN       EQU   X'D0'                   STATEMENT NUMBER MARKER          06720015
OPT      EQU   X'50'                   OPTIONS ATTRIBUTE                06760015
MAIN     EQU   X'B0'                   MAIN ATTRIBUTE                   06800015
TASK     EQU   X'B6'                   TASK ATTRIBUTE                   06840015
ONBLOK   EQU   X'B8'                   ON-BLOCK PSEUDO OPTION           06860015
REC      EQU   X'53'                   RECURSIVE ATTRIBUTE              06880015
ORDER    EQU   X'5D'                   ORDER ATTRIBUTE                  06890001
REORDR   EQU   X'5E'                   REORDER ATTRIBUTE                06900001
REN      EQU   X'B2'                   REENTRANT ATTRIBUTE              06920015
EODB     EQU   X'CF'                   END OF DICTIONARY BLOCK MARKER   06960015
EOP      EQU   X'EB'                   END OF PROGRAM MARKER.           07000015
ASTO     EQU   X'FC'                   * WITH RING                      07040015
CHAPIC   EQU   X'4E'                   CHARACTER PICTURE                07080015
         SPACE 5                                                        07120015
*                       COMMUNICATIONS REGION OFFSETS                   07160015
         SPACE                                                          07200015
PAR1     EQU   X'80'                   PARAMETERS FOR COMMUNICATION     07240015
PAR2     EQU   X'84'                 WITH COMPILER CONTROL.             07280015
PAR5     EQU   X'90'                                                    07320015
PAR6     EQU   X'94'                                                    07360015
PAR7     EQU   PAR6+4                                                   07400015
PAR8     EQU   PAR7+4                                                   07440015
ZMYNAM   EQU   X'70'                   SLOT FOR NAME OF MODULE.         07480015
ZSTAT    EQU   X'7E'                   STATEMENT NO. FOR ERROR EDITOR.  07520015
ZFSTDR   EQU   X'D6'                   FIRST DIC. REF.                  07560015
ZLSTXT   EQU   X'114'                  POINTS TO END OF TEXT            07600015
ZBLKSZ   EQU   X'108'                  CONTAINS SIZE OF TEXT BLOCK      07640015
ZNXTD    EQU   X'4C'                   CONTAINS REFERENCE TO NEXT       07680015
*                                    AVAILABLE DICTIONARY BYTE.         07720015
ZLABTB   EQU   X'300'                  START OF LABEL TABLE             07760015
ZTXTST   EQU   X'100'                  REFERENCE OF START OF TEXT       07800015
ZLOCK    EQU   X'110'                  LOCK-IN DICTIONARY BLOCK SLOT.   07840015
ZMASK1   EQU   X'11E'                  CONTAINS BIT PATTERN OF DICT REF 07880015
ZCOMM    EQU   X'130'                  START OF REGION NOT REQUIRED BY  07920015
*                                    COMPILER CONTROL.                  07960015
ZHASH    EQU   ZCOMM+28                HEAD OF HASH TABLE               08000015
ZMPSTK   EQU   ZCOMM+56                POINTER TO 'MAP STACK'           08040015
ZBLHD    EQU   ZCOMM+64                START OF BLOCK HEADER CHAIN.     08080015
ZUPIC    EQU   ZCOMM+60                START OF PICTURE CHAIN           08120015
VDIMC    EQU   ZCOMM+X'4A'             START OF VARIABLE DIMENSIONS     08160015
*                                    CHAIN (CLEARED BY THIS MODULE).    08200015
         SPACE 5                                                        08240015
*                       COMPILER CONTROL OFFSETS                        08280015
         SPACE                                                          08320015
ZTXTAB   EQU   X'54'                   SYMBOLIC TEXT REF. TO ABSOLUTE.  08360015
ZALTER   EQU   X'5C'                   ALTER TEXT BLOCK STATUS          08400015
ZDRFAB   EQU   X'34'                   SYMBOLIC DICT. REF. TO ABSOLUTE. 08440015
ZUGC     EQU   X'10'                   GET SCRATCH CORE                 08480015
ZDICRF   EQU   X'2C'                   MAKE DICT. ENTRY                 08520015
ZUTXTC   EQU   X'14'                   GET NEW TEXT BLOCK               08560015
ZUERR    EQU   X'30'                   ERROR MESSAGE PROCESSOR          08600015
ZABORT   EQU   X'20'                   ABORT                            08640015
RLSCTL   EQU   X'48'                   RELEASE CONTROL                  08680015
ZURC     EQU   X'18'                   RELEASE SCRATCH CORE.            08720015
ZDABRF   EQU   X'60'                   CONVERT ABSOLUTE DICTIONARY      08760015
*                                    REFERENCE TO SYMBOLIC.             08800015
         EJECT                                                          08840015
*                       FORMAT PARAMETERS                               08880015
         SPACE 2                                                        08920015
*              PROCEDURE STATEMENT IN TEXT                              08960015
         SPACE                                                          09000015
PROC     EQU   X'B3'                   IDENTIFYING CODE BYTE            09040015
PDLC     EQU   5                       OFFSET OF BLOCK LEVEL            09080015
PD1      EQU   7                       OFFSET OF PROC-BEGIN CHAIN.      09120015
PD2      EQU   13                      OFFSET OF ENTRY CHAIN.           09160015
PLTH     EQU   16                      OFFSET OF FORMAL PARAMETER AND   09200015
*                                    ATTRIBUTE LISTS                    09240015
         SPACE 3                                                        09280015
*              PROCEDURE ENTRY TYPE 1 DICTIONARY ENTRY.                 09320015
         SPACE                                                          09360015
PE1      EQU   X'80'                   CODE BYTE                        09400015
PBH      EQU   9                       OFFSET OF BLOCK HEADER CHAIN     09440015
PE1LTH   EQU   65                      LENGTH UP TO FORMAL PARAMETER    09480015
*                                    ADDRESSES                          09520015
PCC      EQU   40                      OFFSET OF CIRCULAR PROC-ENTRY    09560015
*                                    CHAIN                              09600015
PCB      EQU   5                       OFFSET OF POINTER TO CONTAINING  09640015
*                                    BLOCK'S ENTRY TYPE 1.              09680015
PL       EQU   7                       OFFSET OF POINTER TO LABEL       09720015
PCDE     EQU   42                      OFFSET OF OPTIONS CODE BYTE.     09760015
POPT     EQU   63                      OFFSET OF OPTIMISATION BYTE.     09780015
PWS      EQU   13                      OFFSET OF POINTERS TO WORKSPACE  09800015
*                                    ASSOCIATED WITH THE ENTRY.         09840015
PE1L2    EQU   PE1LTH-1-PBH            LENGTH INITIALLY SET TO ZERO     09880015
         SPACE 5                                                        09920015
*              BEGIN STATEMENT IN TEXT                                  09960015
         SPACE                                                          10000015
BEG      EQU   X'B5'                   CODE BYTE.                       10040015
*              OFFSETS ARE ASSUMED TO BE THE SAME AS FOR A PROCEDURE    10080015
*        STATEMENT.                                                     10120015
         SPACE 3                                                        10160015
*              BEGIN ENTRY TYPE 1 DICTIONARY ENTRY.                     10200015
         SPACE                                                          10240015
BE1      EQU   X'81'                   CODE BYTE                        10280015
BE1LTH   EQU   56                      TOTAL LENGTH OF ENTRY.           10320015
BBH      EQU   PBH                     OFFSET OF BLOCK HEADER CHAIN     10360015
BE1L2    EQU   BE1LTH-BBH              LENGTH OF ENTRY TO BE CLEARED    10400015
BCB      EQU   5                       OFFSET OF POINTER TO CONTAINING  10440015
*                                    BLOCK'S ENTRY TYPE 1.              10480015
BWS      EQU   13                      OFFSET OF POINTERS TO WORKSPACES 10520015
*                                    ASSOCIATED WITH THIS ENTRY.        10560015
BSNSL    EQU   7                       OFFSET OF STATEMENT NUMBER OR    10600015
*                                    POINTER TO LABEL.                  10640015
BE1FLG   EQU   34                      OFFSET OF SL OR SN FLAG.         10680015
BOPT     EQU   55                      OFFSET OF OPTIMISATION BYTE.     10690015
BDSA     EQU   25                                                       10700015
         SPACE 5                                                        10720015
*              ENTRY STATEMENT IN TEXT                                  10760015
         SPACE                                                          10800015
ELTH     EQU   10                      LENGTH UP FORMAL PARAMETER AND   10840015
*                                    ATTRIBUTE LISTS.                   10880015
EDLC     EQU   PDLC                    OFFSET OF BLOCK LEVEL.           10920015
ED1      EQU   7                       OFFSET OF ENTRY CHAIN.           10960015
         SPACE 3                                                        11000015
*              ENTRY STATEMENT ENTRY TYPE 1.                            11040015
         SPACE                                                          11080015
EE1      EQU   X'82'                   CODE BYTE                        11120015
EE1LTH   EQU   13                      LENGTH UP TO FORMAL PARAMETER    11160015
*                                    ADDRESSES.                         11200015
EL       EQU   PL                                                       11240015
ECC      EQU   5                       OFFSET OF CIRCULAR PROCEDURE-    11280015
*                                    ENTRY CHAIN.                       11320015
GAP      EQU   3                       LENGTH TO BE CLEARED             11360015
PEDIFF   EQU   PE1LTH-EE1LTH           DIFFERENCE IN LENGTHS BETWEEN    11400015
*                                    PROCEDURE AND ENTRY ENTRY TYPE 1'S 11440015
         SPACE 5                                                        11480015
*              FORMAL PARAMETER TYPE 1 ENTRIES.                         11520015
         SPACE                                                          11560015
FP1      EQU   X'40'                   CODE BYTE                        11600015
FPL      EQU   7                       OFFSET OF BLOCK LEVEL            11640015
FPLTH    EQU   9                       LENGTH UP TO BCD LENGTH-1.       11680015
         EJECT                                                          11720017
*              LABELS IN LABEL TABLE                                    11760015
         SPACE                                                          11800015
LDBN     EQU   18                      OFFSET OF BLOCK NUMBER           11840015
LABSN    EQU   8                       OFFSET OF STATEMENT NUMBER.      11880015
LBCDL    EQU   19                      OFFSET OF BCD LENGTH-1           11920015
FORMAT   EQU   14                      OFFSET OF FORMAT BYTE.     16771 11930017
FON      EQU   255                     FORMAT INDICATOR ON.       16771 11940017
*                                    (THIS INHIBITS A BRANCH-IN)  16771 11950017
OTHER1   EQU   10                      OTHER 1 CODE BYTE, CONTAINING -  11960015
MORLAB   EQU   1                       BIT TO INDICATE THAT THERE ARE   12000015
*                                    MORE LABELS TO FOLLOW.             12040015
         SPACE 5                                                        12080015
*              ATTRIBUTE COLLECTION AREA OFFSETS.                       12120015
         SPACE                                                          12160015
DAR1     EQU   0                       OFFSETS OF FIRST AND SECOND      12200015
DAR2     EQU   1                     DECLARED ATTRIBUTES REGION.        12240015
DATA     EQU   8                       OFFSET OF DATA BYTE              12280015
VINFP    EQU   13                      OFFSET OF FIRST PRECISION BYTE   12320015
STRLTH   EQU   13                      OFFSET OF STRING LENGTH OR       12360015
*                                    POINTER TO ASSOCIATED SECOND FILE  12400015
*                                    STATEMENT                          12440015
PICAD    EQU   16                      OFFSET OF PICTURE ADDRESS.       12480015
         SPACE 10                                                       12520015
*              BIT PATTERNS AND OFFSETS USED BY DEFAULT ROUTINE, CDEFAT 12560015
         SPACE                                                          12600015
X202     EQU   X'80'                   DATA                             12640015
X210     EQU   X'80'                   CODED ARITHMETIC BIT             12680015
X211     EQU   X'40'                   RADIX, SCALE, MODE BIT           12720015
X280     EQU   DATA                    OFFSET OF DATA BYTE              12760015
X286     EQU   X'04'                   DECIMAL/BINARY OR CHAR/BIT       12800015
X287     EQU   X'02'                   FLOAT/FIXED                      12840015
X300     EQU   10                      OFFSET OF FIRST FLAG BYTE        12880015
X301     EQU   X'80'                   CFLAG1                           12920015
X400     EQU   12                      ONE SHORT OF PRECISION BYTES     12960015
         SPACE                                                          13000015
Y200     EQU   X'82'                   MASK FOR FLOAT REAL DECIMAL      13040015
*                                    SHORT                              13080015
Y200A    EQU   6                       DEFAULT PRECISION                13120015
Y201     EQU   X'84'                   MASK FOR FIXED BINARY REAL SHORT 13160015
Y203B    EQU   128                                                      13200015
Y201A    EQU   15                                                       13240015
Y201B    EQU   X'80'                   DEFAULT SCALE OF 0 AS EXCESS 128 13280015
FLDDEF   EQU   6                       DEFAULT PRECISION FOR FLOAT DEC. 13320015
FLDMAX   EQU   16                      MAXIMUM PRECISION FOR FLOAT DEC. 13360015
FLBDEF   EQU   21                      DEFAULT PRECISION FOR FLOAT BIN. 13400015
FLBMAX   EQU   53                      MAXIMUM PRECISION FOR FLOAT BIN. 13440015
FIDDEF   EQU   5                       DEFAULT PRECISION FOR FIXED DEC. 13480015
FIDMAX   EQU   15                      MAXIMUM PRECISION FOR FIXED DEC. 13520015
FIBDEF   EQU   15                      DEFAULT PRECISION FOR FIXED BIN. 13560015
FIBMAX   EQU   31                      MAXIMUM PRECISION FOR FIXED BIN. 13600015
LONG     EQU   X'10'                   LONG BIT IN DATA BYTE.           13640015
         SPACE                                                          13680015
*              MASKS FOR TEST MASK REGION.                              13720015
Y500     EQU   32                      OFFSET OF START OF TEST MASK.    13760015
Y5000    EQU   Y500                                                     13800015
Y5001    EQU   Y500+1                                                   13840015
Y500A    EQU   X'30'                   FIXED AND FLOAT MASK             13880015
Y500B    EQU   X'30'                   PRECISION BITS MASK.             13920015
         EJECT                                                          13960015
*              BIT PATTERN OF OPTIONS CODE BYTE                         14000015
         SPACE                                                          14040015
OPTCDE   EQU   X'04'                   OPTIONS PRESENT BIT              14080015
RECCDE   EQU   X'08'                   RECURSIVE BIT                    14120015
TASCDE   EQU   X'10'                   TASK OPTION BIT                  14140015
MANCDE   EQU   X'20'                   MAIN BIT                         14160015
ONCODE   EQU   X'40'                   ON BLOCK BIT                     14200015
RENCDE   EQU   X'80'                   REENTRANT BIT                    14240015
         SPACE 5                                                        14280015
*              BITS INSERTED IN DATA BYTE BY ROUTINES FOR CORRESPONDING 14320015
*        ATTRIBUTES.                                                    14360015
         SPACE                                                          14400015
BINBIT   EQU   X'84'                   BINARY                           14440015
DECBIT   EQU   X'80'                   DECIMAL                          14480015
FIXBIT   EQU   X'80'                   FIXED                            14520015
FLOBIT   EQU   X'82'                   FLOAT                            14560015
REABIT   EQU   X'80'                   REAL                             14600015
COMBIT   EQU   X'81'                   COMPLEX                          14640015
VARBIT   EQU   X'10'                   VARYING                          14680015
CHRBIT   EQU   X'04'                   CHARACTER                        14720015
ADJBIT   EQU   X'40'                   ADJUSTABLE STRING LENGTH         14760015
ALIGN    EQU   X'20'                                                    14800015
         SPACE 5                                                        14840015
*              SECOND FILE STATEMENT OFFSETS.                           14880015
         SPACE                                                          14920015
ST2FDR   EQU   12                      OFFSET OF POINTER TO ASSOCIATED  14960015
*                                    DICTIONARY REFERENCE.              15000015
         EJECT                                                          15040015
         USING *,GRBASE                                                 15080015
         USING IEMEF,GREFB                                              15120019
         SPACE                                                          15160015
         DC    CL2'EG'                                                  15200015
*              INITIALIZE MODULE.                                       15240015
         SPACE 2                                                        15280015
         L     GRBASE,PAR1(0,GRDIC)                                     15320015
         SPACE                                                          15330015
         MVC   ZMYNAM(2,GRDIC),IEMEG   INSERT NAME OF PHASE IN          15400015
*                                    COMMUNICATIONS REGION.             15440015
         SPACE                                                          15480015
         LA    GRUNIT,1(0,0)           SET UP UNIT REGISTER.            15520015
         SPACE                                                          15560015
         SR    GRX,GRX                                                  15600015
         ST    GRX,ZUPIC(0,GRDIC)      CLEAR COMMUNICATION REGION SLOTS 15640015
         STH   GRX,VDIMC(0,GRDIC)    FOR PICTURE AND VARIABLE DIMS      15680015
*                                    CHAINS.                            15720015
         L     GRH,ZHASH(0,GRDIC)      POINT GRH AT THE HASH TABLE,     15760015
*                                    WHICH HAS BEEN PUT INTO SCRATCH    15800015
*                                    CORE BY PHASE ED.                  15840015
         SPACE                                                          15880015
CAA0     MVI   0(GRH),0                CLEAR HASH TABLE                 15920015
         MVC   1(256,GRH),0(GRH)                                        15960015
         MVC   257(165,GRH),256(GRH)                                    16000015
         SPACE                                                          16040015
         LH    GRDP,ZFSTDR(0,GRDIC)    GET START OF DICTIONARY.         16080015
         SPACE                                                          16120015
         SPACE 2                                                        16160015
         BC    B,CAA1                                                   16660019
         SPACE 4                                                        17160019
         ORG   IEMEG+X'3A'             BECAUSE SECTIONS OF THE          17660019
*                                    ABOVE CODE ARE LATER OVERWRITTEN   18160019
*                                    BY STORAGE, WE KEEP ROUTINE        18660019
*                                    'CHASH' AT A FIXED OFFSET.         19160019
         EJECT                                                          20280015
*                       ROUTINE CHASH                                   20320015
*                                                                       20360015
*              FUNCTION/OPERATION.  THIS ROUTINE DERIVES A FUNCTION     20400015
*        FROM THE BCD PASSED TO IT.  THE FUNCTION IS LESS THAN 422      20440015
*        AND IS EVEN. IT IS TO BE USED AS AN OFFSET IN THE HASH TABLE   20480015
*        GIVING THE HEAD OF THE HASH CHAIN LINKING BCD'S WITH THE SAME  20520015
*        HASH FUNCTION.                                                 20560015
*                                   THE FUNCTION IS OBTAINED BY EXTEND- 20600015
*        ING THE BCD WITH ZEROES UNTIL A MULTIPLE OF 4 BYTES LONG, THEN 20640015
*        ADDING 4 BYTE LENGTHS.  THE SUM IS DIVIDED BY 211.  THE        20680015
*        REMAINDER IS SET POSITIVE AND DOUBLED TO GIVE THE HASH RESULT  20720015
*        RETURNED.                                                      20760015
*                                  THE CALLING SEQUENCE IS -            20800015
*        BAL   GRRR,CHASH   (SEE NOTES)                                 20840015
*                                  THE ROUTINE IS ENTERED WITH -        20880015
*              (1) GRPTR POINTER TO BCD TO BE HASHED.                   20920015
*              (2) GRLTH CONTAINING LENGTH-1 OF THE BCD                 20960015
*              THESE REGISTERS ARE RETURNED UNALTERED.                  21000015
*                                                                       21040015
*              EXTERNAL ROUTINES - NONE.                                21080015
*                                                                       21120015
*              EXITS NORMAL - UNCONDITIONAL BRANCH ON RETURN REGISTER.  21160015
*                                                                       21200015
*              EXITS ERROR - NONE                                       21240015
*                                                                       21280015
*              TABLES/WORK AREAS.  A WORKSPACE CASPAC 32 BYTES LONG,    21320015
*        AND FULL WORD ALIGNED IS REQUIRED. THE BCD IS MOVED INTO IT    21360015
*        FOR FULL WORD ALIGNMENT AND FOR EXTENDING WITH ZEROES          21400015
*                                  A FULL WORD CONSTANT T11, VALUE 211, 21440015
*        IS ALSO REQUIRED.                                              21480015
*                                                                       21520015
*              NOTES.  THE RETURN REGISTER MUST BE SET UP BY A 'BRANCH  21560015
*        AND LINK' INSTRUCTION, SINCE THE PROGRAM MASK IS REQUIRED IN   21600015
*        THE TOP BYTE.                                                  21640015
*                      REGISTERS GRX, AND GRY ARE REQUIRED FOR WORKING  21680015
*        AND THEIR ORIGIONAL CONTENTS ARE LOST.                         21720015
*                      REGISTERS GRX,GRY AND GRLTH,GRHASH ARE REQUIRED  21760015
*        TO BE EVEN ODD REGISTER PAIRS.                                 21800015
               SPACE 5                                                  21840015
CHASH    SR    GRY,GRY                                                  21880015
         SPM   GRY                     INHIBIT FIXED POINT OVERFLOW     21920015
*                                    INTERRUPTS DURING LOOP 'CARED'     21960015
*                                    BELOW.                             22000015
         LA    GRHASH,4                FOUR REQUIRED IN GRHASH, NOW AND 22040015
         LCR   GRX,GRHASH            LATER. SET GRX TO ONES IN ALL BITS 22080015
*                                    EXCEPT THE LAST TWO.               22120015
         NR    GRX,GRLTH               LENGTH-1 LESS LAST TWO BITS INTO 22160015
*                                    GRX                                22200015
         ST    GRY,CASPAC(GRX)         CLEAR FOUR BYTES IN CASPAC AT    22240015
*                                    OFFSET EQUAL TO FIRST FULL WORD    22280015
*                                    SHORT OF END OF BCD WHEN IT IS     22320015
*                                    MOVED INTO CASPAC.                 22360015
         EX    GRLTH,CAH1              MOVE BCD INTO CASPAC.            22400015
         SPACE                                                          22440015
*              THE BCD IS NOW IN CASPAC AND IS EXTENDED TO A FULL WORD  22480015
*        BOUNDARY WITH ZEROS.                                           22520015
         SPACE                                                          22560015
         SR    GRX,GRX                                                  22600015
CARED    A     GRY,CASPAC(GRX)         THIS LOOP ADDS FOUR BYTE LENGTHS 22640015
         BXLE  GRX,GRHASH,CARED      OF THE BCD INTO GRY UNTIL ALL IS   22680015
*                                    CONSUMED                           22720015
         SPACE                                                          22760015
         SR    GRX,GRX                                                  22800015
         D     GRX,T11                 DIVIDE SUM BY 211                22840015
         SPACE                                                          22880015
         LPR   GRHASH,GRX              SET REMAINDER POSITIVE           22920015
         AR    GRHASH,GRHASH           DOUBLE IT.                       22960015
         SPACE                                                          23000015
         SPM   GRRR                    RESET PROGRAM MASK               23040015
         BCR   B,GRRR                  RETURN                           23080015
         SPACE                                                          23120015
CAH1     MVC   CASPAC(0),0(GRPTR)      MOVE IN BCD                      23160015
         EJECT                                                          23200015
         CNOP  0,4                     TO ASSIST TEMPORARY STORAGE      23240015
*                                    ALLOCATION. FROM CA6 TO CA7 WILL   23280015
*                                    BE OVERWRITTEN.                    23320015
         EJECT                                                          23360015
*              THE PROCEDURE - BEGIN CHAIN IN TEXT IS SCANNED. FOR      23400015
*        EACH PROCEDURE STATEMENT, ITS ENTRY TYPE 1 IS CREATED, ITS     23440015
*        ATTRIBUTES PROCESSED, AND ENTRY TYPE 2'S CREATED FOR EACH OF   23480015
*        ITS LABELS. THE SAME IS DONE FOR EACH ENTRY STATEMENT IN ITS   23520015
*        ENTRY CHAIN.                                                   23560015
*              THE ENTRY TYPE 1 FOR EACH BEGIN STATEMENT IS CREATED.    23600015
*              THE FOLLOWING CHAINS ARE CREATED -                       23640015
         SPACE                                                          23680015
*              BLOCK HEADER CHAIN - SEQUENTIALLY LINKS PROCEDURE AND    23720015
*                                   BEGIN ENTRY TYPE 1'S.               23760015
*              CONTAINING BLOCK CHAIN - POINTS FROM EACH ENTRY TYPE 1   23800015
*                                   TO THAT OF THE CONTAINING BLOCK.    23840015
*              CIRCULAR PROCEDURE/ENTRY CHAIN - CIRCULAR CHAIN LINKING  23880015
*                                   ENTRY TYPE 1 OF EACH PROCEDURE      23920015
*                                   STATEMENT AND THE ENTRY STATEMENTS  23960015
*                                   OF THE SAME BLOCK.                  24000015
         SPACE 5                                                        24040015
*              CORE REQUIRED FOR CREATING THE CHAINS IS INITIALIZED.    24080015
         SPACE                                                          24120015
*              CALST1 WILL BE USED FOR THE BLOCK HEADER CHAIN. IT       24160015
*        CONTAINS THE SYMBOLIC REFERENCE OF THE PREVIOUS ENTRY TYPE 1.  24200015
*        BY INITIALIZING IT TO A STANDARD OFFSET SHORT OF THE HEAD OF   24240015
*        THE CHAIN IN THE COMMUNICATIONS REGION, NO DISTINCTION BETWEEN 24280015
*        STARTING AND EXTENDING THE CHAIN NEED BE MADE IN LATER CODING. 24320015
         SPACE 3                                                        24360015
*              WE NOW PICK UP THE ADDRESS OF A SCRATCH CORE BLOCK,      24400015
*        OBTAINED BY PHASE ED, AND WHICH WILL BE USED AS 'MAPSTACK'.    24440015
         SPACE                                                          24480015
CA6      L     GRX,ZMPSTK(0,GRDIC)                                      24520015
         ST    GRX,BNSTK                                                24560015
         SPACE                                                          24600015
*              BNSTK POINTS TO A BLOCK OF SCRATCH CORE WHICH IS USED    24640015
*        FOR CREATING THE STACK HEADED BY ZMPSTK DESCRIBED BELOW.       24680015
*        THE BLOCK (BNSTK) CONTAINS A STACK OF BLOCK NUMBERS, UPDATED   24720015
*        DURING THE TEXT SCAN SO THAT AN OFFSET EQUAL TO A BLOCK LEVEL  24760015
*        GIVES THE BLOCK NUMBER OF THE LAST BLOCK AT THAT LEVEL.        24800015
         MVI   0(GRX),0                INITIALIZE FIRST BYTE TO ZERO    24840015
         SPACE 3                                                        24880015
         LA    GRX,256(0,GRX)                                           24920015
         ST    GRX,ZMPSTK(0,GRDIC)                                      24960015
         MVI   0(GRX),X'00'            CLEAR 1ST BYTE OF MAPSTACK 28520 24980020
         SPACE                                                          25000015
*              ZMPSTK IS MADE TO POINT TO THE SECOND HALF OF THE        25040015
*        SCRATCH BLOCK. HERE A STACK OF BLOCK NUMBERS IS BUILT UP SUCH  25080015
*        THAT AN OFFSET EQUAL TO A BLOCK NUMBER GIVES THE BLOCK NUMBER  25120015
*        OF THE CONTAINING BLOCK. IT IS SAVED FOR LATER PHASES AND      25160015
*        REFERRED TO AS 'MAP STACK'.                                    25200015
         SPACE 5                                                        25240015
*              WE NOW REQUEST A BLOCK OF SCRATCH CORE, TO BE CALLED     25280015
*        'CASTK', AND WHICH WILL BE RELEASED BY PHASE EG.               25320015
         SPACE                                                          25360015
         ST    GRUNIT,PAR1(0,GRDIC)                                     25400015
         L     GRLR,ZUGC(0,GRCC)                                        25440015
         BALR  GRRR,GRLR                                                25480015
         L     GRX,PAR1(0,GRDIC)                                        25520015
         ST    GRX,CASTK                                                25560015
         SPACE                                                          25600015
*              CASTK NOW POINTS TO A BLOCK OF SCRATCH CORE WHICH WILL   25640015
*        BE USED FOR CREATING THE CONTAINING BLOCK POINTERS. IT IS      25680015
*        SIMILAR TO THE STACK HEADED BY BNSTK EXCEPT THAT IT CONTAINS   25720015
*        DICTIONARY REFERENCES INSTEAD OF BLOCK NUMBERS AND THUS TWICE  25760015
*        THE OFFSET IS REQUIRED.                                        25800015
         SPACE                                                          25840015
         ST    GRUNIT,0(0,GRX)         CLEAR FIRST TWO BYTES.           25880015
         SPACE 5                                                        25920015
*              SET SCAN POINTER TO FIRST PROCEDURE STATEMENT (I.E. TO   25960015
*        START OF TEXT).                                                26000015
         SPACE                                                          26040015
         LA    GRSP,ZTXTST+1-PD1(0,GRDIC)                               26080015
         BC    B,CA8                                                    26120015
         SPACE                                                          26160015
         BC    B,CA7                   BECAUSE SECTIONS OF THIS CODE    26200015
         ORG   IEMEG+X'B0'           ARE LATER OVERWRITTEN BY STORAGE,  26250019
*                                    WE KEEP 'CA7' AT A FIXED OFFSET.   26300019
         SPACE 5                                                        26360015
CA7      MVC   PAR1+1(1,GRDIC),SYMN1   CHANGE STATUS OF BLOCK CONTAIN-  26400015
         MVI   PAR2+3(GRDIC),X'2'    ING LAST PROCEDURE OR BEGIN STATE- 26440015
         L     GRLR,ZALTER(0,GRCC)   MENT TO 'NOT WANTED'               26480015
         BALR  GRRR,GRLR                                                26520015
         SPACE 2                                                        26560015
         CLC   PD1(3,GRSP),STOP        IS PROC/BEGIN CHAIN A STOPPER.   26600015
         BC    BE,CAEND                END OF PHASE IF SO.              26640015
         SPACE 5                                                        26680015
CA8      MVI   PAR1(GRDIC),X'0'            CONVERT POINTER TO NEXT      26720015
         MVC   PAR1+1(3,GRDIC),PD1(GRSP) MEMBER OF PROC-BEGIN CHAIN TO  26760015
*                                        ABSOLUTE ADDRESS (ALSO MARKS   26800015
*                                        ITS BLOCK AS BUSY)             26840015
         MVC   SYMN1(1),PD1(GRSP)      SAVE SYMBOLIC NAME OF BLOCK      26880015
         L     GRLR,ZTXTAB(0,GRCC)                                      26920015
         BALR  GRRR,GRLR                                                26960015
         SPACE                                                          27000015
         L     GRSP,PAR1(0,GRDIC)      SET SCAN POINTER TO START OF NEW 27040015
*                                    STATEMENT.                         27080015
         SPACE 2                                                        27120015
         CLI   4(GRSP),PROC            IS IT A PROCEDURE STATEMENT      27160015
         BC    BE,CAPROC                                                27200015
         SPACE                                                          27240015
         CLI   4(GRSP),BEG             IS IT A BEGIN STATEMENT          27280015
         BC    BNE,CAE2                COMPILER ERROR, CODE 1.          27320015
         SPACE 2                                                        27360015
*              A BEGIN STATEMENT HAS BEEN FOUND. ITS ENTRY TYPE 1 WILL  27400015
*        BE CONSTRUCTED AND INSERTED IN THE DICTIONARY.                 27440015
         SPACE 2                                                        27480015
         MVI   CAWSP1,BE1              MOVE IN CODE BYTE                27520015
         MVI   CAWSP1+1,X'00'                                           27560015
         MVI   CAWSP1+2,BE1LTH                 ENTRY LENGTH             27600015
CA8A     MVC   CAWSP1+3(2),PDLC(GRSP)  BLOCK LEVEL AND COUNT            27640015
         SPACE 2                                                        27680015
         SR    GRZ,GRZ                                                  27720015
         IC    GRZ,PDLC(GRSP,0)        PICK UP BLOCK LEVEL              27760015
         STC   GRZ,BLKLEV            AND SAVE IT.                       27780015
         SR    GRZ,GRUNIT              BACK DATE TO CONTAINING BLOCK    27800015
         SR    GRY,GRY               LEVEL.                             27840015
         IC    GRY,PDLC+1(0,GRSP)      PICK UP BLOCK NUMBER             27880015
         L     GRX,BNSTK               SET UP POINTER TO STACK OF       27920015
         IC    GR0,0(GRX,GRZ)        BLOCK NUMBERS. PICK UP BLOCK NO.   27960015
         STC   GR0,256(GRX,GRY)      OF CONTAINING BLOCK. STORE IT IN   28000015
*                                    'MAP STACK' AT OFFSET GIVEN BY     28040015
*                                    BLOCK NUMBER OF THIS ENTRY.        28080015
         SPACE 3                                                        28120015
*              THE REFERENCE OF THE CONTAINING BLOCK'S ENTRY TYPE 1     28160015
*        IS NOW PICKED UP FROM THE STACK.                               28200015
         SPACE                                                          28240015
         LA    GRY,0(GRZ,GRZ)          DOUBLE LEVEL OF CONTAINING       28280015
*                                    BLOCK INTO GRY                     28320015
         A     GRY,CASTK               POINT TO DICTIONARY REFERENCE OF 28360015
         MVC   CAWSP1+BCB(2),0(GRY)  CONTAINING BLOCK AND MOVE IT INTO  28400015
*                                    ENTRY TYPE 1                       28440015
         SPACE 2                                                        28445015
*              AT THIS POINT WE WILL SLIDE OFF TO SEE IF OPTIONS ARE    28450015
*        TO BE INHERITED FROM CONTAINING BLOCKS.                        28455015
         SPACE                                                          28460015
         BAL   GRRR,OPTN1              BRANCH TO POUTINE IN EF.         28467019
         SPACE                                                          28475015
         CLI   4(GRSP),PROC            IF IT IS A PROC STAT BEING PROC- 28480015
         BC    BE,CAPRC1             ESSED RETURN TO IT.                28520015
         SPACE                                                          28560015
         XC    CAWSP1+BBH(BE1L2),CAWSP1+BBH  CLEAR REMAINDER            28600015
         MVC   CAWSP1+BSNSL(2),1(GRSP)  STATEMENT NO. OR LABEL          28640015
         MVC   CAWSP1+BE1FLG(1),0(GRSP)                                 28680015
         MVC   CAWSP1+BDSA(1),CATCDE   MOVE IN DSA BYTE                 28700015
         MVI   0(GRSP),SL                                               28720015
         SPACE 2                                                        28721001
*              WE HAVE YET TO MOVE IN THE OPTIMIZATION BYTE BUT         28722001
*              BEFORE DOING SO WE MUST CHECK FOR ORDER/REORDER          28723001
*              ON THE CURRENT BEGIN, SET THE OPTIMIZATION               28724001
*              BYTE ACCORDINGLY AND REPLACE THE ATTR MARKER             28725001
*              AND CODE BYTE BY ZEROS                                   28726001
         SPACE 1                                                        28727001
         CLI   PD2(GRSP),ATM           IS THERE AN ATTR MARKER ?        28728001
         BC    BNE,CA8D                NO. GO TO MOVE OPTIMIZATION BYTE 28729001
         SPACE 1                                                        28730001
         MVI   PD2(GRSP),X'00'         YES. ZEROIZE BYTE IN TEXT        28731001
         CLI   PD2+1(GRSP),ORDER       IS ATTR 'ORDER'                  28732001
         BC    BNE,CA8B                NO. MUST BE 'REORDER'            28733001
         SPACE 1                                                        28734001
         NI    OPTIM,X'FB'             YES. SET ORDER/REORDER BIT TO 0  28735001
         BC    B,CA8C                  GO TO ZEROIZE BYTE IN TEXT       28736001
         SPACE 1                                                        28737001
CA8B     OI    OPTIM,X'04'             ATTR IS 'REORDER'. SET BIT TO 1  28738001
CA8C     MVI   PD2+1(GRSP),X'00'       ZEROIZE BYTE IN TEXT             28739001
         SPACE 1                                                        28740001
CA8D     MVC   CAWSP1+BOPT(1),OPTIM    MOVE IN OPTIMIZATION BYTE        28741001
         SPACE 2                                                        28760015
         LA    GRX,BE1LTH(0,0)                                          28800015
         ST    GRX,PAR2(0,GRDIC)                                        28840015
         LA    GRX,CAWSP1              MOVE ENTRY TYPE 1 INTO THE       28880015
         ST    GRX,PAR1(0,GRDIC)     DICTIONARY.                        28920015
         L     GRLR,ZDICRF(0,GRCC)                                      28960015
         BALR  GRRR,GRLR                                                29000015
         SPACE 2                                                        29040015
         MVC   1(2,GRSP),PAR1+2(GRDIC) INSERT POINTER TO ENTRY TYPE 1   29080015
*                                    IN TEXT                            29120015
         SPACE 2                                                        29160015
*              THE BLOCK HEADER CHAIN WILL NOW BE EXTENDED              29200015
         SPACE                                                          29240015
         L     GRX,CALST1              PICK UP SYMBOLIC ADDRESS OF      29280015
         MVC   CALST1(4),PAR1(GRDIC) PREVIOUS BLOCK HEADER FROM CALST1. 29320015
*****                                UPDATE CALST1 TO NEW ONE.          29360015
*********************************************************************** 29400015
         ST    GRX,PAR1(0,GRDIC)       CONVERT PREVIOUS ONE TO ABSOLUTE 29440015
         L     GRLR,ZDRFAB(0,GRCC)                                      29480015
         BALR  GRRR,GRLR                                                29520015
*********************************************************************** 29560015
         SPACE                                                          29600015
         L     GRX,PAR1(0,GRDIC)                                        29640015
         MVC   BBH(2,GRX),CALST1+2     STORE ADDRESS OF NEW ONE IN      29680015
*                                    PREVIOUS ONE.                      29720015
         SPACE 2                                                        29760015
*              THE STACK OF BLOCK NUMBERS AND THE STACK OF DICT REFER-  29800015
*        ENCES ARE NOW UPDATED.                                         29840015
         SPACE 2                                                        29880015
         L     GRX,BNSTK               PICK UP HEAD OF STACK            29920015
         AR    GRX,GRZ                 GRZ STILL CONTAINS LEVEL-1       29960015
         MVC   1(1,GRX),PDLC+1(GRSP)                                    30000015
         MVC   2(2,GRY),CALST1+2       GRY STILL POINTS AT SLOT FOR     30040015
*                                    IMMEDIATELY CONTAINIG LEVEL. THE   30080015
*                                    DISPLACEMENT OF 2 UPDATES IT TO    30120015
*                                    SLOT FOR THIS LEVEL. CALST1 CONT-  30160015
*                                    AINS SYMBOLIC ADDRESS OF THIS      30200015
*                                    ENTRY                              30240015
         SPACE 2                                                        30280015
*              THE WORKSPACE ASSOCIATED WITH THE ENTRY IS NOW           30320015
*        INSERTED IN THE DICTIONARY AND POINTERS TO IT SRE SET UP.      30360015
         SPACE                                                          30400015
         BAL   GRX,MAKECA                                               30440015
         L     GRX,CALST1                                               30480015
         ST    GRX,PAR1(0,GRDIC)                                        30520015
*********************************************************************** 30560015
         L     GRLR,ZDRFAB(0,GRCC)     CONVERT POINTER TO ENTRY TYPE 1  30600015
         BALR  GRRR,GRLR             TO ABSOLUTE                        30640015
*********************************************************************** 30680015
         L     GRX,PAR1(0,GRDIC)                                        30720015
         MVC   BWS(6,GRX),CASPAC       MOVE POINTERS INTO ENTY TYPE 1   30760015
         SPACE                                                          30800015
         BC    B,CA7                   GO TO PICK UP NEW STATEMENT.     30840015
         SPACE 5                                                        30880015
*              A PROCEDURE STATEMENT HAS BEEN FOUND. THE BASIS OF ITS   30920015
*        ENTRY TYPE 1 IS BUILT UP IN CAWSP1.                            30960015
         SPACE 2                                                        31000015
CAPROC   MVI   CAWSP1,PE1              CODE BYTE                        31040015
         BC    B,CA8A                  GO TO UP DATE MAP STACK AS FOR   31080015
*                                    BEGIN STATEMENTS.                  31120015
         SPACE                                                          31160015
*              RETURNS HERE.                                            31200015
CAPRC1   ST    GRY,CATEMP              SAVE STACK POINTER               31240015
         SPACE                                                          31280015
         MVI   CAWSP1+PBH,X'0'                                          31320015
         MVC   CAWSP1+PBH+1(PE1L2),CAWSP1+PBH CLEAR REMAINDER OF ENTRY  31360015
         SPACE                                                          31400015
         MVC   CAWSP1+PL(2),1(GRSP)    MOVE IN POINTER TO LABEL         31440015
         SPACE 5                                                        31480015
         XC    CACNT(2),CACNT          CLEAR F.P. COUNT                 31520015
         LA    GRP,PLTH(0,GRSP)        SET A POINTER TO FIRST BYTE OF   31560015
*                                    OPTIONAL LISTS                     31600015
         CLI   0(GRP),LB               IS IT A LEFT BRACKET             31640015
         BC    BNE,CA9                 IF NOT, THEN THERE ARE NO F.P'S. 31680015
         SPACE                                                          31720015
         MVI   CAFLG2,PEDIFF           SET FLAG TO DIFFERENCE IN LENGTH 31760015
*                                    BETWEEN PROCEDURE AND ENTRY TYPE 1 31800015
*                                    ENTRIES.THIS IS USED BY CFORP.     31840015
         BAL   GRRR,CFORP              GO AND PROCESS FORMAL PARAMETER  31880015
*                                   LIST.                               31920015
         SPACE 5                                                        31960015
CA9      LA    GRX,PE1LTH(0,GREFB)                                      32000019
         AH    GRX,CACNT                                                32040015
         MVI   CAWSP(GRX),X'00'        LAST BYTE OF E.T.1 MUST BE 0     32080015
         SR    GRX,GREFB               LENGTH OF ENTRY IN GRX           32120019
         AR    GRX,GRUNIT                                               32160015
         ST    GRX,PAR2(0,GRDIC)                                        32200015
         MVC   CAWSP1+1(2),PAR2+2(GRDIC)  INSERT IN ENTRY TYPE 1        32240015
         SPACE                                                          32280015
         MVC   CAWSP1+PE1LTH-1(1),CACNT+1  INSERT F.P. COUNT            32320015
         SPACE                                                          32360015
         LA    GRX,CAWSP1              MOVE ENTRY TYPE 1 INTO THE       32400015
         ST    GRX,PAR1(0,GRDIC)     DICTIONARY.                        32440015
         L     GRLR,ZDICRF(0,GRCC)                                      32480015
         BALR  GRRR,GRLR                                                32520015
         MVC   1(2,GRSP),PAR1+2(GRDIC) MOVE POINTER INTO TEXT           32560015
         SPACE 2                                                        32600015
*              THE BLOCK HEADER CHAIN WILL NO W BE EXTENDED             32640015
         SPACE                                                          32680015
         L     GRX,CALST1            PICK UP SYMBOLIC ADDRESS OF        32720015
         MVC   CALST1(4),PAR1(GRDIC) PREVIOUS BLOCK HEADER FROM CALST1. 32760015
         LTR   GRX,GRX               UPDATE CALST1 TO NEW ONE. IF THIS  32800015
         BC    BNZ,NSTRT             IS THE START OF THE CHAIN, MERELY  32840015
         LA    GRX,ZBLHD-PBH+2(0,GRDIC) UPDATE COMM. REGION.            32880015
         BC    B,STRT                                                   32920015
         SPACE                                                          32960015
NSTRT    ST    GRX,PAR1(0,GRDIC)                                        33000015
         L     GRLR,ZDRFAB(0,GRCC)   CONVERT PREVIOUS ADDRESS TO ABSOL- 33040015
         BALR  GRRR,GRLR           UTE.                                 33080015
*****                                                                   33120015
         L     GRX,PAR1(0,GRDIC)                                        33160015
STRT     MVC   BBH(2,GRX),CALST1+2     STORE ADDRESS OF NEW ONE IN      33200015
*                                  PREVIOUS ONE.                        33240015
         SPACE 2                                                        33280015
         L     GRY,CATEMP              PICK UP STACK POINTER            33320015
         MVC   2(2,GRY),CALST1+2       UPDATE STACK OF BLOCK HEADER     33360015
*                                    ADDRESSES                          33400015
         SR    GRX,GRX                                                  33440015
         IC    GRX,PDLC(0,GRSP)        PICK UP BLOCK LEVEL.             33480015
         A     GRX,BNSTK               POINT TO BLOCK NUMBER SLOT.      33520015
         MVC   0(1,GRX),PDLC+1(GRSP)   INSERT BLOCK NUMBER              33560015
         SPACE                                                          33600015
*              THE CIRCULAR PROCEDURE-ENTRY CHAIN IS NOW STARTED        33640015
         SPACE                                                          33680015
         MVC   CACLO(2),1(GRSP)        SET CACLO TO CONTAIN SYMBOLIC    33720015
*                                    ADDRESS OF PROCEDURE STATEMENT'S   33760015
*                                    ENTRY TYPE 1                       33800015
         MVC   PAR1+2(2,GRDIC),CACLO                                    33840015
         L     GRLR,ZDRFAB(0,GRCC)                                      33880015
         BALR  GRRR,GRLR                                                33920015
         L     GRY,PAR1(0,GRDIC)                                        33960015
         MVC   PAR1+2(2,GRDIC),CACLO                                    34000015
         LA    GRX,PCC(0,GRY)                                           34040015
         ST    GRX,PAR2(0,GRDIC)                                        34080015
         L     GRLR,ZDABRF(0,GRCC)                                      34120015
         BALR  GRRR,GRLR                                                34160015
         MVC   CALST2(4),PAR1(GRDIC)                                    34200015
         MVC   0(2,GRX),CACLO          INSERT POINTER TO THIS ENTRY IN  34240015
*                                    CIRCULAR CHAIN SLOT.               34280015
         SPACE 2                                                        34320015
*              THE WORKSPACE, CAFENT, ASSOCIATED WITH THE ENTRY IS      34360015
*        NOW INSERTED IN THE DICTIONARY AND POINTERS TO IT ARE SET UP   34400015
         SPACE                                                          34440015
         BAL   GRX,MAKECA                                               34480015
         LR    GRX,GRY                                                  34520015
         SPACE                                                          34560015
         MVC   PWS(6,GRX),CASPAC       MOVE THEM INTO THE ENTRY TYPE 1  34600015
         SPACE                                                          34640015
         BC    B,CANATP                GO AND PROCESS ATTRIBUTE LIST.   34680015
         SPACE 5                                                        34720015
*              CHAIN OF ENTRY STATEMENTS MUST NOW BE PROCESSED.         34760015
         SPACE 2                                                        34800015
CA10     DS    0H                                                       34840019
         CLI   4(GRSP),PROC            IF IT IS A PROCEDURE STATEMENT   34880015
         BC    BNE,CA11              BEING PROCESSED, GRSP IS SAVED     34920015
         ST    GRSP,CAPTR1           FOR RETURN TO PROC CHAIN THEN UP-  34960015
         LA    GRSP,PD2-ED1(0,GRSP)  DATED SO THAT THE ENTRY CHAIN MAY  35000015
*                                    BE PICKED UP USING THE SAME OFFSET 35040015
         BC    B,CA12                AS FOR ENTRY STATEMENTS. ALSO, THE 35080015
*                                    TEXT BLOCK IS KEPT BUSY AS IT IS   35120015
*                                    REQUIRED FOR FINDING THE NEXT      35160015
*                                    PROCEDURE OR BEGIN STATEMENT.      35200015
         SPACE 2                                                        35240015
CA11     CLC   SYMN1(1),SYMN2          IS ENTRY STATEMENT IN SAME       35280015
         BC    BE,CA12                 BLOCK AS HEADING PROC STAT       35320015
         MVC   PAR1+1(1,GRDIC),SYMN2   ALTER STATUS OF BLOCK JUST PRO-  35360015
         MVI   PAR2+3(GRDIC),X'2'    CESSED TO 'NOT WANTED'             35400015
         L     GRLR,ZALTER(0,GRCC)                                      35440015
         BALR  GRRR,GRLR                                                35480015
         SPACE 2                                                        35520015
*              GRSP POINTS TO START OF AN ENTRY STATEMENT (EXCEPT WHEN  35560015
*        PICKING UP FIRST PROCEDURE STATEMENT)                          35600015
         SPACE                                                          35640015
CA12     CLC   ED1(3,GRSP),STOP        IS ENTRY CHAIN A STOPPER.        35680015
         BC    BNE,*+12                                                 35720015
         L     GRSP,CAPTR1             RESET POINTER TO PROCEDURE STAT. 35760015
         BC    B,CA7                                                    35800015
         MVC   SYMN2(1),ED1(GRSP)      SAVE SYMBOLIC NAME OF BLOCK      35840015
         MVI   PAR1(GRDIC),X'0'            CONVERT POINTER TO NEXT      35880015
         MVC   PAR1+1(3,GRDIC),ED1(GRSP) STATEMENT TO ABSOLUTE ADDRESS. 35920015
         L     GRLR,ZTXTAB(0,GRCC)       (HENCE MARK ITS BLOCK BUSY).   35960015
         BALR  GRRR,GRLR                                                36000015
         SPACE 2                                                        36040015
         L     GRSP,PAR1(0,GRDIC)          SET SCAN POINTER TO NEXT     36080015
*                                    STATEMENT                          36120015
         SPACE 2                                                        36160015
         SPACE 2                                                        36200015
*              THE BASIS OF AN ENTRY TYPE 1 FOR THE ENTRY STATEMENT     36240015
*        WILL NOW BE BUILT UP.                                          36280015
         SPACE                                                          36320015
CAESL    MVI   CAWSP1,EE1              CODE BYTE                        36360015
         MVC   CAWSP1+3(2),EDLC(GRSP)                                   36400015
         MVC   CAWSP1+EL(2),1(GRSP)    POINTER TO LABEL                 36440015
         MVC   CAWSP1+ECC(2),CACLO     POINTER TO HEADING PROCEDURE     36480015
*                                    STATEMENT INTO CIRCULAR CHAIN SLOT 36520015
         SPACE                                                          36560015
         XC    CAWSP1+EL+2(GAP),CAWSP1+2+EL                             36600015
*                                                    LATER PHASE        36640015
         XC    CACNT(2),CACNT          CLEAR F.P. COUNT                 36680015
         LA     GRP,ELTH(0,GRSP)             SET A POINTER TO FIRST     36720015
*                                    BYTE OF F.P. LIST - IF ANY         36760015
         CLI   0(GRP),LB               IS IT A LEFT BRACKET             36800015
         BC    BNE,CA13                IF NOT, NO F.P'S.                36840015
         SPACE                                                          36880015
         MVI   CAFLG2,X'0'             SET FLAG TO INFORM CFORP THAT    36920015
*                                    AN ENTRY STATEMENT CALLED THE      36960015
*                                    ROUTINE.                           37000015
         BAL   GRRR,CFORP                                               37040015
         SPACE 5                                                        37080015
CA13     LA    GRX,EE1LTH(0,0)         COMPUTE LENGTH OF ENTRY TYPE 1   37120015
         AH    GRX,CACNT                                                37160015
         ST    GRX,PAR2(0,GRDIC)                                        37200015
         MVC   CAWSP1+1(2),PAR2+2(GRDIC)  INSERT LENGTH IN ENTRY TYPE 1 37240015
         MVC   CAWSP1+EE1LTH-1(1),CACNT+1                               37280015
         LA    GRX,CAWSP1              INSERT ENTRY TYPE 1 IN DICTION-  37320015
         ST    GRX,PAR1(0,GRDIC)     ARY                                37360015
         L     GRLR,ZDICRF(0,GRCC)                                      37400015
         BALR  GRRR,GRLR                                                37440015
         MVC   1(2,GRSP),PAR1+2(GRDIC) MOVE POINTER TO ENTRY TYPE 1     37480015
*                                    INTO TEXT                          37520015
         SPACE 3                                                        37560015
*              THE CIRCULAR PROC/ENTRY CHAIN AND CALST2 ARE NOW UPDATED 37600015
         SPACE                                                          37640015
         L     GRLR,ZDRFAB(0,GRCC)                                      37680015
         BALR  GRRR,GRLR                                                37720015
         L     GRX,PAR1(0,GRDIC)                                        37760015
         LA    GRX,ECC(0,GRX)                                           37800015
         ST    GRX,PAR2(0,GRDIC)                                        37840015
         MVC   PAR1+2(2,GRDIC),1(GRSP)                                  37880015
         L     GRLR,ZDABRF(0,GRCC)                                      37920015
         BALR  GRRR,GRLR                                                37960015
         L     GRY,PAR1(0,GRDIC)                                        38000015
         MVC   PAR1+2(2,GRDIC),CALST2+2                                 38040015
         ST    GRY,CALST2                                               38080015
         L     GRLR,ZDRFAB(0,GRCC)                                      38120015
         BALR  GRRR,GRLR                                                38160015
         L     GRY,PAR1(0,GRDIC)                                        38200015
         MVC   0(2,GRY),1(GRSP)                                         38240015
         BC    B,CANATP                GO TO PROCESS ATTRIBUTE LIST.    38280015
         EJECT                                                          38320015
*              ROUTINE CFORP.  PROCESS FORMAL PARAMETERS.               38360015
*                                                                       38400015
*              FUNCTION/OPERATION.   THE FORMAL PARAMETER LIST ON A     38440015
*        PROCEDURE OR ENTRY STATEMENT IS SCANNED.  THE ENTRY TYPE 1     38480015
*        DICTIONARY ENTRY FOR EACH FORMAL PARAMETER IS CREATED.  IT IS  38520015
*        INSERTED IN THE HASH CHAIN AND A POINTER TO IT IS PLACED IN    38560015
*        THE ENTRY TYPE 1 FOR THE PROCEDURE OR ENTRY STATEMENT. SIMILAR 38600015
*        FORMAL PARAMETERS IN THE SAME BLOCK SHARE THE SAME FORMAL      38640015
*        PARAMETER ENTRY TYPE 1.                                        38680015
*              READ-IN DUMMIES IN THE FORMAL PARAMETER LIST ARE GIVEN   38720015
*        A ZERO POINTER IN THE PROCEDURE OR ENTRY TYPE1 ENTRY AND ARE   38760015
*        NOT GIVEN A DICTIONARY ENTRY.                                  38800015
*                                                                       38840015
*              EXTERNAL ROUTINES - CHASH, FOR HASHING THE FORMAL PARA-  38880015
*        METER'S BCD. ZDICRF, FOR MAKING THE DICTIONARY ENTRY.  CBCDL2, 38920015
*        FOR SCANNING DOWN THE HASH CHAIN.                              38960015
*                                                                       39000015
*              EXITS,NORMAL - LAST INSTRUCTION RETURNS CONTROL TO THE   39040015
*        PROCEDURE OR ENTRY STATEMENT SCAN.                             39080015
*                                                                       39120015
*              EXITS, ERROR - A FEW INSTRUCTIONS BEFORE THE END THERE   39160015
*        IS A BRANCH TO A COMPILER ERROR ROUTINE, TAKEN WHEN THE CLOS-  39200015
*        ING RIGHT BRACKET CANNOT BE FOUND.                             39240015
*                                                                       39280015
*              TABLES/WORK AREAS - THE FORMAL PARAMETER TYPE 1 IS BUILT 39320015
*        UP IN THE WORK SPACE CAWSP2.                                   39360015
*                                                                       39400015
*              NOTES - N/A.                                             39440015
         SPACE 3                                                        39480015
CFORP    ST    GRRR,CLINK                                               39520015
         MVI   CLINK,0                 INITIALIZE ERROR FLAG BYTE TO 0  39560015
CB0      MVI   0(GRP),X'0'             ERASE BYTE PRECEDING FORMAL      39600015
*                                    PARAMETER.                         39640015
         SR    GRLTH,GRLTH                                              39680015
         IC    GRLTH,1(0,GRP)          PICK UP NEXT BYTE                39720015
         SR    GRLTH,GRUNIT            IS IT AN IDENTIFIER LENGTH (I.E. 39760015
         CH    GRLTH,TH1             LESS THAN 32). ERROR IF NOT.       39800015
         BC    BNL,CAE3                                                 39840015
         SPACE                                                          39880015
         LA    GRX,2                                                    39920015
         MVI   1(GRP),0                CLEAR LENGTH BYTE                39960015
         AR    GRP,GRX                 POINT TO BCD, READY FOR CHASH.   40000015
         AH    GRX,CACNT               BUMP FORMAL PARAMETER COUNT AND  40040015
         CH    GRX,X80               CHECK THAT IT HAS NOT EXCEEDED     40080015
*                                    IMPLEMENTATION RESTRICTION OF 128  40120015
         BC    BH,CAE6X                IF IT HAS, GO TO PREPARE FOR     40160015
*                                    DIAGNOSTIC.                        40200015
         STH   GRX,CACNT                                                40240015
         SPACE                                                          40280015
         CLI   0(GRP),KSI              IS BCD A DUMMY                   40320015
         BC    BNE,CB1                 IF NOT, GO TO HASH IT            40360015
         MVC   CADP(2),ZERO            OTHERWISE, SET UP DUMMY POINTER  40400015
         BC    B,CB4                                                    40440015
         SPACE                                                          40480015
CAE6X    MVI   CLINK,X'FF'             SET ERROR FLAG SO THAT DIAGNOST- 40520015
         BC    B,CB5                 IC WILL BE WRITTEN WHEN THE END OF 40560015
*                                    THE F.P. LIST IS REACHED.          40600015
CB1      BAL   GRRR,CHASH                                               40640015
         SPACE                                                          40680015
         L     GRH,ZHASH(0,GRDIC)      POINT AT HASH TABLE.             40700019
         LA    GRX,0(GRH,GRHASH)                                        40720015
         SH    GRX,THREE               SET CLLST TO POINT 3 SHORT OF    40760015
         LA    GRZ,CB3                 SET UP REYURN LINKS AND          40800015
         BAL   GRY,CBCDL2              GO TO SCAN FOR SAME BCD          40840015
         SPACE 2                                                        40880015
*              AN ENTRY WITH THE SAME BCD HAS BEEN FOUND                40920015
         SPACE                                                          40960015
CB2      CLI   0(GRX),FP1              IS IT A FORMAL PARAMETER ENTRY   41000015
         BC    BE,CB2A                                                  41040015
         CLC   LDBN(1,GRX),PDLC+1(GRSP) COMPARE BLOCK NUMBERS           41080015
         BC    BE,CAE4                                                  41120015
         BC    BH,CBCDL2                                                41160015
         BC    B,CB3                                                    41200015
         SPACE                                                          41240015
CB2A     CLC   FPL+1(1,GRX),PDLC+1(GRSP) COMPARE BLOCK NUMBERS OF F.P'S 41280015
         BC    BH,CBCDL2               IF LOW SCAN FOR NEXT             41320015
         BC    BE,CB4A                 IF EQUAL THERE IS NO NEED TO     41360015
*                                    CREATE ANOTHER F.P.ENTRY TYPE 1    41400015
         SPACE                                                          41440015
*                                      AN  F.P. ENTRY TYPE 1 WILL BE    41480015
CB3      MVC   CAWSP2(3),STFP        BUILT UP IN CAWSP2. MOVE IN STAND- 41520015
*                                    ARD PART.                          41560015
         L     GRY,CALST             PICK UP POINTER TO PREVIOUS ENTRY. 41600015
         MVC   ZLOCK+2(1,GRDIC),SR1                                     41640015
         MVC   CAWSP2+3(2),3(GRY)      HASH POINTER                     41680015
         XC    CAWSP2+5(2),CAWSP2+5    CLEAR GAP                        41720015
         MVC   CAWSP2+FPL(2),PDLC(GRSP) BLOCK LEVEL & COUNT             41760015
         STC   GRLTH,CAWSP2+FPLTH      BCD LENGTH-1                     41800015
         EX    GRLTH,CB3A              AND FINALLY, THE BCD.            41840015
         SPACE                                                          41880015
         LA      GRX,FPLTH+2(0,GRLTH)  PREPARE TO INSERT ENTRY IN DICT- 41920015
         ST      GRX,PAR2(0,GRDIC)   IONARY. COMPUTE LENGTH.            41960015
         LA    GRX,CAWSP2                                               42000015
         ST    GRX,PAR1(0,GRDIC)                                        42040015
         SPACE                                                          42080015
         L     GRLR,ZDICRF(0,GRCC)                                      42120015
         BALR  GRRR,GRLR                                                42160015
         SPACE 2                                                        42200015
         MVC   CADP(2),PAR1+2(GRDIC)   LOAD CADP WITH SYMBOLIC ADDRESS  42240015
*                                    OF THE ENTRY.                      42280015
         SPACE                                                          42320015
*              EXTEND HASH CHAIN - GRY STILL POINTS TO PREVIOUS ENTRY.  42360015
         SPACE                                                          42400015
         MVC   3(2,GRY),CADP           MOVE POINTER TO THIS ONE INTO    42440015
         BC    B,CB4                 PREVIOUS ENTRY                     42480015
CB3A     MVC   CAWSP2+FPLTH+1(0),0(GRP)   MOVE IN BCD                   42520015
CB4B     XC    0(0,GRP),0(GRP)         CLEAR FORMAL PARAMETER FROM      42560015
*                                    SOURCE                             42600015
CB4A     L     GRY,CALST               LOAD CADP WITH SYMBOLIC ADDRESS  42640015
         MVC   CADP(2),3(GRY)        OF IDENTICAL FORMAL PARAMETER. (IT 42680015
*                                    IS FOUND IN PREVIOUS ENTRY,        42720015
         MVI   COMFLG,X'FF'            SET 'COMMONED' FLAG ON           42760015
CB4      SR    GRX,GRX                                                  42800015
         IC    GRX,CAFLG2                                               42840015
         LA    GRX,CAWSP1(GRX)         COMPUTE POSITION FOR THIS FORMAL 42880015
         AH    GRX,CACNT             PARAMETERS ADDRESS IN THE ENTRY    42920015
*                                    TYPE 1                             42960015
         CLI   COMFLG,X'FF'            IS 'COMMONED' FLAG ON.           43000015
         BC    BNE,CAE4RT                                               43040015
         MVI   COMFLG,0                                                 43080015
         LR    GRY,GRX                 IF SO, SCAN LIST OF PREVIOUS     43120015
         SH    GRY,CACNT             FORMAL PARAMETER ADDRESSES TO      43160015
LSTSCN   CR    GRX,GRY               CHECK THAT FORMAL PARAMETER        43200015
         BC    BE,CAE4RT             HAS NOT BEEN REPEATED.             43240015
         CLC   EE1LTH-2(2,GRY),CADP                                     43280015
         LA    GRY,2(0,GRY)                                             43320015
         BC    BNE,LSTSCN                                               43360015
         SPACE                                                          43400015
         MVC   PAR7+2(2,GRDIC),CADP    IF IT HAS SET UP MESSAGE AND     43440015
         MVC   PAR6+1(3,GRDIC),MESB    GO TO WRITE DIAGNOSTIC           43480015
         BAL   GRY,CAE4B                                                43520015
CAE4RT   MVC   EE1LTH-2(2,GRX),CADP    MOVE IN SYMBOLIC ADDRESS         43560015
CB5      EX    GRLTH,CB4B              CLEAR SOURCE                     43600015
         SPACE                                                          43640015
         LA    GRP,1(GRP,GRLTH)        BUMP POINTER TO BYTE AFTER F.P.  43680015
         CLI   0(GRP),COMMA          P TEST IT                          43720015
         BC    BE,CB0                  IF IT IS A COMMA RETURN TO       43760015
*                                    PROCESS NEXT FORMAL PARAMETER      43800015
         CLI   0(GRP),RB               IF IT IS A RIGHT BRACKET, THE    43840015
         BC    BNE,CAE5              END OF THE LIST HAS BEEN REACHED   43880015
*                                      ERROR OTHERWISE.                 43920015
         MVI   0(GRP),X'00'            CLEAR RIGHT BRACKET              43960015
         AR    GRP,GRUNIT              BUMP POINTER TO NEXT BYTE        44000015
         CLI   CLINK,0                 HAS THERE BEEN AN ERROR IN F.P.  44040015
         BC    BNE,CAE6              LIST. IF SO GO TO WRITE DIAGNOSTIC 44080015
         L     GRRR,CLINK              RESET RETURN REGISTER            44120015
         BCR   B,GRRR                  RETURN.                          44160015
         EJECT                                                          44200015
*                       ROUTINE CANATP                                  44240015
*                                                                       44280015
*              FUNCTION.  THIS ROUTINE SCANS THE ATTRIBUTES ON A PROC-  44320015
*        EDURE OR ENTRY STATEMENT.  THE APPROPRIATE BITS ARE SET ON IN  44360015
*        THE ENTRY TYPE 1 CODE BYTE FOR ANY OPTIONS WHICH MAY BE PRES-  44400015
*        ENT.  THE INFORMATION GIVEN BY THE LIST OF DATA ATTRIBUTES IS  44440015
*        GATHERED INTO THE 'ATTRIBUTE COLLECTION AREA' WHICH IS PASSED  44480015
*        TO THE DEFAULT ROUTINE.  A CHECK IS MADE FOR CONFLICTING DATA  44520015
*        ATTRIBUTES.                                                    44560015
*                                                                       44600015
*              EXTERNAL ROUTINES - ZDRFAB, FOR SETTING UP ABSOLUTE      44640015
*        POINTER TO ENTRY TYPE 1 SO THAT THE OPTIONS CODE BYTE MAY BE   44680015
*        INSERTED.                                                      44720015
*                             ALSO THE VARIOUS ROUTINES FOR PROCESSING  44760015
*        THE DATA ATTRIBUTES.  CONTROL IS PASSED TO THESE ROUTINES BY   44800015
*        MEANS OF AN OFFSET FOUND AT THE END OF THE TEST MASK ASSOCIAT- 44840015
*        ED WITH THE ATTRIBUTE.                                         44880015
*                                                                       44920015
*              ENTRY POINTS - CANATP IS THE INITIAL ENTRY POINT.  THE   44960015
*        DATA ATTRIBUTE ROUTINES RETURN CONTROL TO CAT3.                45000015
*                                                                       45040015
*              EXITS, NORMAL - FOLLOWING CAT3A, CONTROL IS PASSED TO    45080015
*        ROUTINE CTYPBL WHEN THE END OF THE ATTRIBUTE LIST HAS BEEN     45120015
*        REACHED.                                                       45160015
*                                                                       45200015
*              EXITS. ERROR - FOLLOWING CAT2B, BRANCHES TO A COMPILER   45240015
*        ERROR  ROUTINE IN THE EVENT OF NO RIGHT BRACKET FOLLOWING THE  45280015
*        OPTIONS LIST.                                                  45320015
*                             FOLLOWING CAT3, BRANCHES TO A COMPILER    45360015
*        ERROR ROUTINE IN THE EVENT OF NO SEMI-COLON BEING FOUND AT THE 45400015
*        END OF THE ATTRIBUTE LIST.                                     45440015
*                                                                       45480015
*              TABLES/WORK AREAS - WORK SPACE CAWSP2 IS USED AS THE 38  45520015
*        BYTE ATTRIBUTE COLLECTION AREA.                                45560015
*                                  THE TABLE 'ATABLE' IS USED FOR       45600015
*        TRANSLATING THE DATA ATTRIBUTES INTO A BIT POSITION IN A MASK. 45640015
*                                  THE TABLE 'MSKTAB' IS A TABLE OF     45680015
*        TWO BYTE MASKS EACH FOLLOWED BY A SINGLE BYTE OFFSET.          45720015
*              THE USE OF THESE TABLES IS DESCRIBED UNDER NOTES.        45760015
*                                                                       45800015
*              NOTES - DATA ATTRIBUTE CONFLICTS ARE DETECTED AS FOLLOWS 45840015
*        EACH DATA ATTRIBUTE HAS A CORRESPONDING BIT POSITION IN A TWO  45880015
*        BYTE MASK, CATMSK, WHICH IS INITIALISED TO ALL ONES.  THIS     45920015
*        POSITION IS FOUND BY USING THE TRANSLATE TABLE, ATABLE.  WHEN  45960015
*        AN ATTRIBUTE IS ENCOUNTERED ITS BIT IN CATMSK IS TESTED. IF    46000015
*        IT IS ZERO THE ATTRIBUTE CONFLICTS WITH A PREVIOUS ONE, SO IT  46040015
*        IS IGNORED AND A DIAGNOSTIC GIVEN. IF THE BIT IS ONE, THE TWO  46080015
*        BYTE MASK IN MSKTAB FOR THIS ATTRIBUTE IS FOUND AT AN OFFSET   46120015
*        ARRANGED TO BE THREE TIMES THE NUMBER GIVEN BY ATABLE.  THIS   46160015
*        MASKS CONTAINS ZEROS IN THE BIT POSITIONS CORRESPONDING TO THE 46200015
*        ATTRIBUTES WHICH CONFLICT WITH THE CURRENT ONE.  THIS IS       46240015
*        'ANDED' ON TO CATMSK SO THAT LATER CONFLICTS ARE DETECTED.     46280015
*              AT THE END OF THE MASK IN MSKTAB IS A SINGLE BYTE OFFSET 46320015
*        OF THE ROUTINE WHICH PROCESSES THE CURRENT ATTRIBUTE.          46360015
         SPACE 5                                                        46400015
CANATP   ST    GRP,CAPTR2            SAVE A POINTER TO START OF ATTRIB- 46440015
         MVI   EXPINF,X'0'           UTE LIST AND CLEAR SLOT FOR EXPR-  46480015
         MVC   EXPINF+1(7),EXPINF    ESSION INFORMATION AND OPTIONS     46520015
*                                    CODE BYTE (AT EXPINF+7)            46560015
         SPACE                                                          46640015
         MVI   CAWSP2,0                                                 46680015
         MVC   CAWSP2+1(31),CAWSP2                                      46720015
         MVC   CATMSK(4),TSTMSK        INITIALISE MASK FOR CHECKING FOR 46760015
*                                    CLASHING ATTRIBUTES                46800015
         MVI   CAWSP2+DATA,X'08'                                        46840015
         BC    B,CAT3+2                                                 46880015
         SPACE                                                          46920015
CAT1     AR    GRP,GRUNIT                                               46960015
         CLI   0(GRP),OPT              IS ATTRIBUTE OPTIONS             47000015
         BC    BNE,CAT4                                                 47040015
         SPACE                                                          47080015
         TM    CATCDE,OPTCDE           IS OPTIONS BIT IN CODE BYTE  AL- 47120015
         BC    BO,CAE7               READY ON. ERROR IF SO.             47160015
         SPACE                                                          47200015
         OI    CATCDE,OPTCDE           SET OPTIONS BIT IN CODE BYTE ON  47240015
         SPACE                                                          47280015
         CLI   1(GRP),LB               IS OPTIONS BYTE FOLLOWED BY (    47320015
         BC    BNE,CAE1                IF NOT, GO TO WRITE DIAGNOSTIC.  47360015
         BC    B,CAT2A                                                  47400015
         SPACE                                                          47440015
CAT2     CLI   1(GRP),COMMA            IS NEXT BYTE A COMMA             47480015
         BC    BNE,CAT2B               IF NOT, MUST BE AT END OF        47520015
*                                    OPTIONS LIST.                      47560015
CAT2A    LA    GRP,2(0,GRP)                                             47600015
         CLI   0(GRP),ATM                                               47640015
         BAL   GRRR,OPTN2              BRANCH TO ROUTINE IN EF          47650019
*                                    TO PROCESS THE OPTION.             47660019
         BXH   GRP,GRUNIT,CAT2         ON RETURN, BUMP POINTER AND GO   47670015
*                                    FOR MORE.                          47680015
CAT2B    AR    GRP,GRUNIT                                               47720015
         CLI   0(GRP),RB               OTHERWISE, IT SHOULD BE A RIGHT  47760015
         BC    BNE,CAE8              BRACKET CLOSING THE OPTIONS LIST.  47800015
         SPACE                                                          47840015
CAT3     AR    GRP,GRUNIT                                               47880015
         CLI   0(GRP),ATM                                               47920015
         BC    BE,CAT1                                                  47960015
         SPACE                                                          48000015
         CLI   0(GRP),SC                                                48040015
         BC    BNE,CAE9                                                 48080015
CAT3A    DS    0H                                                       48140015
         ST    GRUNIT,PAR1(0,GRDIC)     CLEAR FIRST BYTES OF PAR1       48200015
         MVC   PAR1+2(2,GRDIC),1(GRSP)  MOVE IN POINTER TO ENTRY TYPE 1 48240015
*                                    FROM SOURCE.                       48280015
         L     GRLR,ZDRFAB(0,GRCC)     CONVERT IT TO ABSOLUTE.          48320015
         BALR  GRRR,GRLR                                                48360015
         SPACE                                                          48400015
         L     GRX,PAR1(0,GRDIC)       SET UP POINTER TO ENTRY TYPE 1   48440015
         CLI   0(GRX),PE1              IS TI A PROC. ENTRY TYPE 1       48480015
         BC    BNE,CTYPBL                                               48520015
         BAL   GRRR,OPTN3              BRANCH TO ROUTINE IN EF TO       48530019
*                                    PERFORM OPTIONS POST PROCESSING.   48540019
         MVC   PCDE(1,GRX),CATCDE      MOVE CODE BYTE INTO ENTRY TYPE 1 48560015
         OC    POPT(1,GRX),OPTIM       PUT ORDER/REORDER BIT INTO       48570001
*                                    INTO OPTIMIZATION BYTE             48580001
*                                    OF ENTRY TYPE 1                    48590001
         BC    B,CTYPBL                                                 48600015
         SPACE 2                                                        48640015
CAT4     CLI   0(GRP),REC              RECURSIVE ?                      48690001
         BC    BNE,CAT4A               NO. GO TO TEST FOR ORDER         48740001
         OI    CATCDE,RECCDE           YES. SET RECURSIVE BIT IN        48790001
*                                    OPTIONS BYTE TO 1                  48840001
         BC    B,CAT4C                 GO TO LOOK FOR FURTHER ATTRS     48890001
         SPACE 1                                                        48940001
CAT4A    CLI   0(GRP),ORDER            ORDER ?                          48990001
         BC    BNE,CAT4B               NO. GO TO TEST FOR REORDER       49040001
         NI    OPTIM,X'FB'             YES. SET ORDER/REORDER BIT IN    49090001
*                                    OPTIMIZATION BYTE TO ZERO          49140001
         BC    B,CAT4C                 GO TO LOOK FOR FURTHER ATTRS     49190001
         SPACE 1                                                        49240001
CAT4B    CLI   0(GRP),REORDR           REORDER ?                        49290001
         BC    BNE,CAT5                NO. GO TO TEST FOR DATA ATTR     49340001
         OI    OPTIM,X'04'             YES. SET ORDER/REORDER BIT IN    49390001
*                                    OPTIMIZATION BYTE TO 1             49440001
CAT4C    BXH   GRP,GRUNIT,CAT3+2       GO TO LOOK FOR FURTHER ATTRS     49490001
CAT5     CLI   0(GRP),X'40'                                             49560015
         BC    BL,CAE11                CHECK FOR A VALID                49600015
         CLI   0(GRP),X'4E'            DATA ATTRIBUTE                   49640015
         BC    BH,CATPTR                                                49680015
         SR    2,2                                                      49720015
         TRT   0(1,GRP),ATABLE-64      TRANSLATE ATTRIBUTE              49760015
         BC    BZ,CAE11                ILLEGAL ATTRIBUTE                49800015
         SPACE                                                          49840015
         L     GRX,LFTBIT              INSERT BIT AT LEFT OF GRX AND    49880015
         SRL   GRX,63(2)             SHIFT IT BY GR2 LESS ONE TO POSIT- 49920015
         N     GRX,CATMSK            ION FOR THIS ATTRIBUTE AND CHECK   49960015
         BC    BZ,CAE12              AGAINST MASK THAT THERE IS NOT A   50000015
*                                    CLASH WITH A PREVIOUS ATTRIBUTE.   50040015
         SPACE                                                          50080015
CAT6     LA    GRX,0(2,2)                                               50120015
         AR    GRX,2                                                    50160015
*                                      3 TIMES GR2 INTO GRX TO GIVE     50200015
         LA    GRX,MSKTAB(GRX)       OFFSET OF MASK WITH ZEROES IN      50240015
         NC    CATMSK(2),0(GRX)      POSITIONS CORRESPONDING TO ATTRI-  50280015
*                                    BUTES CLASHING WITH THIS ONE. USE  50320015
*                                    IT TO UPDATE CHECKING MASK.        50360015
         SR    GRY,GRY                                                  50400015
         IC    GRY,2(0,GRX)            FIND OFFSET OF ROUTINE  (AT END  50440015
         BC    B,CATRNE(GRY)       OF MASK) AND GO TO IT.               50480015
CAT7A    AR    GRP,GRUNIT              THE ILLEGAL ATTRIBUTE WILL NOW   50520015
CAT7     CLI   0(GRP),ATM            SKIPPED OVER. IS NEXT BYTE ATTRI-  50560015
         BC    BE,CAT1               BUTE MARKER - IF SO NEXT ATTRIBUTE 50600015
*                                    HAS BEEN FOUND                     50640015
         CLI   0(GRP),SC               IS IT A SEMI-COLON. IF SO THE    50680015
         BC    BE,CAT3A              END OF ATTRIBUTE LIST HAS BEEN     50720015
*                                    REACHED SO RETURN                  50760015
         SPACE                                                          50800015
         CLI   0(GRP),X'F0'            IS IT A CONSTANT MARKER          50840015
         BC    BL,CAT7A                IF NOT TEST NEXT BYTE            50880015
         SPACE                                                          50920015
         SR    GRY,GRY                 IF SO SKIP OVER CONSTANT -       50960015
         IC    GRY,1(0,GRP)            PICK UP LENGTH                   51000015
         LA    GRP,2(GRP,GRY)          BU                               51040015
         BC    B,CAT7                                                   51080015
         EJECT                                                          51180015
*                                                                       51280015
*              THE ATTRIBUTE MAY BE POINTER, OFFSET, OR AREA.           51380015
*        THESE ARE PROCESSED IN EF.                                     51480015
*                                                                       51580015
CATPTR   DS    0H                                                       51680015
         BAL   GRRR,ATTRBT             BRANCH TO ROUTINE IN EF.         51780019
         BC    B,CAT7A                 NORMAL RETURN, TO MAIN SCAN      51980015
         BC    B,CACAD                 RETURN FOR POINTER.              52080015
         BC    B,CAAREA                RETURN FOR AREA                  52180015
         BC    B,CAE11                 RETURN FOR ILLEGAL ATTRIBUTE     52280015
         BC    B,CAE12                 RETURN FOR CLASHING ATTRIBUTE    52380015
         EJECT                                                          52480015
*              VARIOUS DATA ATTRIBUTE ROUTINES                          52520015
*                                                                       52560015
*              FUNCTION/OPERATION.  THIS SECTION OF CODE SETS THE       52600015
*        APPROPRIATE BITS IN THE ATTRIBUTE COLLECTION AREA FOR THE      52640015
*        ATTRIBUTES BINARY, DECIMAL, FIXED, FLOAT, COMPLEX,AND VARYING. 52680015
*        THERE ARE BRANCHING INSTRUCTIONS TO THE ROUTINES FOR PICTURE,  52720015
*        CHARACTER AND BIT.  THERE IS A ROUTINE WHICH EXTRACTS THE      52760015
*        PRECISION FROM THE PRECISION ATTRIBUTE AND INSERTS IT IN THE   52800015
*        ATTRIBUTE COLLECTION AREA.                                     52840015
*                                                                       52880015
*              ENTRY POINTS - THE THIRD, FOURTH AND FIFTH LETTERS OF A  52920015
*        LABEL ARE THE FIRST THREE LETTERS OF THE ATTRIBUTE BEING       52960015
*        PROCESSED. (CACAD IS NOT AN ENTRY POINT).  CONTROL IS PASSED   53000015
*        TO THE APPROPRIATE ROUTINE BY BRANCHING TO AN OFFSET FROM THE  53040015
*        FIRST ROUTINE, CABIN.                                          53080015
*                                                                       53120015
*              EXTERNAL ROUTINES - NONE.                                53160015
*                                                                       53200015
*              EXITS, NORMAL - RETURNS TO CAT3 AFTER CACAD, AND CAVAR.  53240015
*                                                                       53280015
*              EXITS, ERROR - NONE                                      53320015
*                                                                       53360015
*              NOTES - THE LAYOUT OF INSTRUCTIONS BETWEEN CABIN AND     53400015
*        CAPRK MUST NOT BE ALTERED WITHOUT ADJUSTING THE OFFSETS IN     53440015
*        TABLE MSKTAB ACCORDINGLY.                                      53480015
         SPACE 5                                                        53520015
CACAD    OI    CAWSP2+DAR1,X'80'                                        53560015
         OI    CAWSP2+DAR2,X'C0'       OR IN CAD AND RSM BITS           53600015
         BC    B,CAT3                                                   53640015
         SPACE                                                          53680015
CABIN    OI    CAWSP2+DATA,BINBIT                                       53720015
         BC    B,CACAD                                                  53760015
         SPACE                                                          53800015
CADEC    OI    CAWSP2+DATA,DECBIT                                       53840015
         BC    B,CACAD                                                  53880015
         SPACE                                                          53920015
CAFIX    OI    CAWSP2+DATA,FIXBIT                                       53960015
         BC    B,CACAD                                                  54000015
         SPACE                                                          54040015
CAFLO    OI    CAWSP2+DATA,FLOBIT                                       54080015
         BC    B,CACAD                                                  54120015
         SPACE                                                          54160015
CAREA    OI    CAWSP2+DATA,REABIT                                       54200015
         BC    B,CACAD                                                  54240015
         SPACE                                                          54280015
CACOM    OI    CAWSP2+DATA,COMBIT                                       54320015
         BC    B,CACAD                                                  54360015
         SPACE                                                          54400015
CAVAR    OI    CAWSP2+DATA,VARBIT                                       54440015
         OI    CAWSP2+DAR1,X'80'                                        54480015
         BC    B,CAT3                                                   54520015
         BC    B,CATPIC                                                 54560015
         BC    B,CATBIT                                                 54600015
         BC    B,CATCHA                                                 54640015
CAPRPK   PACK  CADW+4(4),4(0,GRP)      PACK DECIMAL CONSTANT            54680015
CAPRE1   SR    GRZ,GRZ                 CLEAR GRZ - IT WILL BE USED  AS  54720015
         OI    CAWSP2+DAR1,X'C0'     AN INDEX.                          54760015
         MVI   CAWSP2+VINFP+1,Y203B    INITIALIZE SCALE TO DEFAULT FOR  54800015
*                                    FIXED IN CASE IT IS NOT GIVEN.     54840015
         CLI   1(GRP),LB               IS NEXT BYTE LEFT BRACKET        54880015
         BC    BNE,CAE13               ERROR IF NOT                     54920015
         SPACE                                                          54960015
CAPREA   MVI   SIGN+1,X'0F'            MODIFY INSTRUCTION BELOW TO      55000015
         CLI   2(GRP),UNPL           SET SIGN POSITIVE. IF CONSTANT IS  55040015
         BC    BNE,CAPRE2            PRECEDED BY UNARY PLUS BUMP POINT- 55080015
         AR    GRP,GRUNIT            ER TO IGNORE IT.                   55120015
CAPRE2   CLI   2(GRP),UNMI             IS CONSTANT PRECEDED BY UNARY    55160015
         BC    BNE,CAPRE3            MINUS.                             55200015
         CR    GRZ,GRUNIT              IF SO, IS THIS THE SECOND CONST- 55240015
         BC    BNE,CAE13             ANT. ERROR, IF NOT.                55280015
         MVI   SIGN+1,X'0B'            MODIFY LATER INSTRUCTION TO SET  55320015
*                                    SIGN NEGATIVE.                     55360015
         AR    GRP,GRUNIT              BUMP BY ONE FOR SIGN             55400015
CAPRE3   CLI   2(GRP),DC               IS NEXT BYTE A DECIMAL CONSTANT  55440015
         BC    BNE,CAE14             MARKER. ERROR IF NOT               55480015
         SPACE                                                          55520015
         SR    GRLTH,GRLTH                                              55560015
         IC    GRLTH,3(0,GRP)          PICK UP CONSTANT LENGTH          55600015
         CH    GRLTH,THREE             SHOULD BE LESS THAN 3            55640015
         BC    BNL,CAE15                                                55680015
         SR    GRLTH,GRUNIT            REDUCE LENGTH FOR EXECUTE INSTR. 55720015
         EX    GRLTH,CAPRPK                                             55760015
SIGN     OI    CADW+7,0                SET SIGN ACCORDING TO ABOVE      55800015
*                                    MODIFICATIONS OF THIS INSTRUCTION  55840015
         CVB   GRX,CADW                                                 55880015
         LTR   GRZ,GRZ                 IF SCALING FACTOR,               55920015
         BC    BE,CAPRE4                                                55960015
         AH    GRX,X80                                   BUMP BY 128    56000015
         BC    BL,CAE13              AND ENSURE IT GOES POSITIVE. ERROR 56040015
*                                  OTHERWISE.                           56080015
CAPRE4   CH    GRX,T55               CHECK BINARY CONSTANT FITS IN      56120015
         BC    BH,CAE16              1 BYTE                             56160015
         SPACE                                                          56200015
         STC   GRX,CAWSP2+VINFP(GRZ)   MOVE PRECISION INTO EITHER 'P'   56240015
*                                    BYTE OR 'Q' BYTE DEPENDING ON      56280015
*                                    WHETHER GRZ CONTAINS 0 OR 1.       56320015
         SPACE                                                          56360015
         LA    GRP,4(GRP,GRLTH)        BUMP POINTER TO ONE SHORT OF     56400015
         LR    GRZ,GRUNIT            CLOSING BRACKET OR COMMA. BUMP     56440015
         CLI   1(GRP),RB             GRZ IN CASE THERE IS A SECOND PRE- 56480015
         BC    BNE,CAPREA            CISION. IF NOT ) THEN PROCESS NEXT 56520015
         BXH   GRP,GRUNIT,CAT3       PRECISION OTHERWISE RETURN.        56560015
         EJECT                                                          56600015
*              CHARACTER AND BIT ROUTINE.                               56640015
*                                                                       56680015
*              FUNCTION/OPERATION - THIS ROUTINE EXTRACTS THE STRING    56720015
*        LENGTH FROM THE ATTRIBUTES CHARACTER AND BIT.  IT DISTINGUISH- 56760015
*        ES THE FOLLOWING CASES.                                        56800015
*                                   IF THE LENGTH IS CONSTANT IT IS     56840015
*        CONVERTED TO BINARY, CHECKED FOR SIZE, AND PUT IN THE ATTRIB-  56880015
*        UTE COLLECTION AREA.                                           56920015
*              IF THE STRING LENGTH IS AN EXPRESSION, IT IS PUT INTO    56960015
*        A SECOND FILE STATEMENT.                                       57000015
*              IF NO LENGTH IS GIVEN A LENGTH OF ONE IS ASSUMED AND A   57040015
*        DIAGNOSTIC GENERATED.                                          57080015
*                                                                       57120015
*              ENTRY POINTS - CATBIT OR CATCHA DEPENDING ON WHETHER     57160015
*        THE ATTRIBUTE IS BIT OR CHAR.                                  57200015
*                                                                       57240015
*              EXTERNAL ROUTINE - ENT2F, USED FOR MAKING THE SECOND     57280015
*        FILE ENTRY.                                                    57320015
*                                                                       57360015
*              EXITS, NORMAL - LAST INSTRUCTION, AND BEFORE CHEXP.      57400015
*        CONTROL IS RETURNED TO CAT3.                                   57440015
*                                                                       57480015
*              EXITS, ERROR - NONE.                                     57520015
*                                                                       57560015
*              TABLES/WORK AREAS - EXPINF IS USED FOR SAVING INFORMA-   57600015
*        TION CONCERNING SECOND FILE STATEMENTS SO THAT THEY MAY BE     57640015
*        DUPLICATED WHERE NECESSARY.                                    57680015
*                                                                       57720015
*              NOTES - N/A                                              57760015
         SPACE 5                                                        57800015
CAAREA   DS    0H                      'AREA' IS USING THIS ROUTINE.    57820015
CATCHA   OI    CAWSP2+DATA,CHRBIT                                       57840015
CATBIT   OI    CAWSP2+DAR1,X'80'                                        57880015
         OI    CAWSP2+DATA,ALIGN                                        57920015
         SR    GRX,GRX                                                  57960015
         CLI   1(GRP),LB               IS NEXT BYTE LEFT BRACKET. IF    58000015
         BC    BNE,CHBER2            NOT, GO TO WRITE DIAGNOSTIC        58040015
         CLI   2(GRP),ASTO             IS STRING LENGTH *               58080015
         BC    BNE,*+12                                                 58120015
         LA    GRP,3(0,GRP)             ERROR IF SO                     58160015
         BC    B,CHBER2                GO TO WRITE DIAGNOSTIC.          58200015
         CLI   2(GRP),DC               IS THERE A CONSTANT MARKER AFTER 58240015
         BC    BNE,CHEXP             THE LEFT BRACKET. IF NOT, AN       58280015
*                                    EXPRESSION FOLLOWS.                58320015
         IC    GRX,3(0,GRP)            PICK UP CONSTANT'S LENGTH.       58360015
         LA    GRY,4(GRX,GRP)          POINT TO BYTE AFTER CONSTANT.    58400015
         CLI   0(GRY),RB               IS IT A RIGHT BRACKET.           58440015
         BC    BNE,CHEXP               IF NOT, THE CONSTANT IS PSRT OF  58480015
*                                    AN EXPRESSION                      58520015
         SR    GRX,GRUNIT              REDUCE LENGTH FOR EXECUTE.       58560015
         CH    GRX,FOUR                CHECK THAT IT IS NOT TOO LARGE   58600015
         BC    BH,CHBER                                                 58640015
         EX    GRX,CAPRPK              PACK CONSTANT AS FOR PRECISION.  58680015
         OI    CADW+7,X'0F'            SET SIGN +VE AND CONVERT TO      58720015
         CVB   GRY,CADW              BINARY.                            58760015
         STH   GRY,CFW+2                                                58800015
         MVC   CAWSP2+STRLTH(2),CFW+2  MOVE IT INTO ATTRIBUTE COLLECT-  58840015
         CH    GRY,VIIFFF            ION AREA. CHECK THAT IT WAS NOT    58880015
         BC    BH,CHBER              GREATER THAN X'7FFF'               58920015
         LA    GRP,5(GRP,GRX)          BUMP POINTER AND RETURN.         58960015
         BC    B,CAT3                                                   59000015
         SPACE 5                                                        59040015
*              THE STRING LENGTH IS AN EXPRESSION. IT WILL BE INSERTED  59080015
*        IN THE SECOND FILE.                                            59120015
         SPACE 3                                                        59160015
CHEXP    BAL   GRZ,CHEXPF                                               59200015
         SPACE                                                          59240015
*              SET UP THE INFORMATION REQUIRED BY THE ROUTINE WHICH     59280015
*        MAKES (OR REPEATS) THE SECOND FILE ENTRY                       59320015
         SPACE                                                          59360015
         ST    GRY,EXPINF                                               59400015
         STH   GRLTH,EXPINF+4                                           59440015
         BAL   GRZ,ENT2F                                                59480015
         SPACE                                                          59520015
         L     GRX,EXPINF             COLLECTION AREA.                  59560015
         MVC   0(16,GRX),STR2F         INSERT STANDARD INITIAL BYTES    59600015
         MVC   3(1,GRX),3(GRSP)        INSERT OPTIONS BYTE.             59640015
         BC    B,CAT3                                                   59680015
         EJECT                                                          59720015
*              PICTURE ROUTINE - CATPIC.                                59760015
*                                                                       59800015
*              FUNCTION/OPERATION.  THIS ROUTINE PROCESS THE PICTURE    59840015
*        ATTRIBUTE.  THE PICTURE IS INSERTED IN A DICTIONARY ENTRY      59880015
*        WHICH IS CHAINED TO OTHER PICTURE ENTRIES.  A POINTER TO THE   59920015
*        ENTRY IS INSERTED IN THE ATTRIBUTE COLLECTION AREA.  SIMILAR   59960015
*        PICTURES SHARE THE SAME DICTIONARY ENTRIES.                    60000015
*                                                                       60040015
*              ENTRY POINT - CATPIC                                     60080015
*                                                                       60120015
*              EXTERNAL ROUTINES - ZDICRF, FOR MAKING THE ENTRY         60160015
*                                  ZDABRF, FOR SETTING UP ABSOLUTE      60200015
*        POINTERS TO PREVIOUS ENTRIES.                                  60240015
*                                                                       60280015
*              EXITS, NORMAL - LAST INSTRUCTION BUT ONE RETURNS CONTROL 60320015
*        TO ROUTINE, CANATP.                                            60360015
*                                                                       60400015
*              EXITS, ERROR - THIRD INSTRUCTION, A BRANCH TO A COMPILER 60440015
*        ERROR ROUTINE IN THE EVENT OF NO PICTURE BEING FOUND AFTER THE 60480015
*        PICTURE ATTRIBUTE                                              60520015
*                                                                       60560015
*              TABLES/WORK AREAS - N/A.                                 60600015
*                                                                       60640015
*              NOTES - N/A                                              60680015
         SPACE 5                                                        60720015
         SPACE 3                                                        60760015
CATPIC   NI    CAWSP2+DATA,X'F7'       AND OUT 'NO PICTURE' BIT         60800015
         OI    CAWSP2+DATA,X'80'       INITIALIZE TO 'NOT STRINGS'      60840015
         CLI   0(GRP),CHAPIC           IS THIS A CHARACTER PICTURE      60880015
         BC    BNE,*+8                                                  60920015
         XI    CAWSP2+DATA,X'A4'       IF SO, SET NOT STRINGS BIT OFF   60960015
*                                    AND SET ALIGNED AND CHAR BITS ON.  61000015
         OI    CAWSP2+DAR1,X'80'                                        61040015
         SPACE                                                          61080015
         CLI   3(GRP),QUOTE            CHECK THAT PICTURE IS PRECEDED   61120015
         BC    BNE,PICERR            BY A QUOTATION MARK.  COMPILER     61160015
*                                    ERROR IF NOT.                      61200015
         SPACE                                                          61240015
         MVC   CFW+2(2),1(GRP)                                          61280015
         LH    GRLTH,CFW+2             PICK UP PICTURE LENGTH IN GRLTH  61320015
         LA    GRY,9(0,0)              BACK GRP TO AS MANY BYTES        61360015
         SR    GRP,GRY               BEFORE THE PICTURE AS IS THE START 61400015
         LA    GRX,ZUPIC-1(0,GRDIC)  OF A PICTURE ENTRY IN THE DICT.    61440015
CP3      ST    GRX,LSTPIC              RESET LSTPIC - INITIALLY TO      61480015
*                                    POINT 3 BYTES SHORT OF HEAD OF     61520015
*                                    PICTURE CHAIN - LATER 3 BYTES      61560015
*                                    SHORT OF CHAIN IN PICTURE ENTRY    61600015
         MVC   PAR1+2(2,GRDIC),3(GRX)  PICK UP POINTER TO NEXT PICTURE  61640015
         LH    GRX,PAR1+2(0,GRDIC)                                      61680015
         LTR   GRX,GRX                 IS IT A STOPPER                  61720015
         BC    BE,CP5                  IF SO GO AND MAKE PICTURE ENTRY  61760015
CP4      L     GRLR,ZDRFAB(0,GRCC)     CONVERT POINTER TO ABSOLUTE      61800015
         BALR  GRRR,GRLR                                                61840015
         SPACE                                                          61880015
         L     GRX,PAR1(0,GRDIC)                                        61920015
         SPACE                                                          61960015
         CLC   11(2,GRX),10(GRP)       COMPARE PICTURES                 62000015
         BC    BNE,CP3                 IF UNEQUAL, GO AND TRY NEXT      62040015
*                                    PICTURE IN TABLE.                  62080015
*                                      OTHERWISE COMPARE PICTURES.      62120015
CP8      LA    GRY,256(0,GRLTH)        INITIALISE GRY TO 256+LENGTH     62160015
         ST    GRP,CFW                 SAVE ABSOLUTE POINTERS TO TEXT   62200015
         ST    GRX,CFW2              AND DICTIONARY                     62240015
         SPACE                                                          62280015
CP8A     SH    GRY,T56                                                  62320015
         CH    GRY,T56                 ARE THERE MORE THAN 256 BYTES    62360015
         BC    BNH,CP10              TO BE COMPARED                     62400015
         CLC   13(256,GRX),13(GRP)     IF SO COMPARE LENGTHS OF 256     62440015
         LA    GRX,256(0,GRX)                                           62480015
         LA    GRP,256(0,GRP)                                           62520015
         BC    BE,CP8A                 IF THESE LENGTHS ARE EQUAL       62560015
*                                    GO TO TEST NEXT                    62600015
CP9A     L     GRX,CFW2                OTHERWISE, RESET POINTERS AND    62640015
         L     GRP,CFW               GO TO EXAMINE NEXT PICTURE IN      62680015
         BC    B,CP3                 TABLE.                             62720015
         SPACE 2                                                        62760015
CP10     SR    GRY,GRUNIT              THE REMAINING BYTES WILL NOW BE  62800015
         BC    BL,*+12               COMPARED. CHECK THERE ARE SOME. IF 62840015
         EX    GRY,CP9               NOT THEN THE PICTURES ARE EQUAL    62880015
         BC    BNE,CP9A                                                 62920015
         L     GRX,CFW2                RESET POINTERS                   62960015
         L     GRP,CFW                                                  63000015
         BC    B,CP10A                 GO TO SET UP POINTER IN DATA     63040015
*                                    BYTE                               63080015
         SPACE 2                                                        63120015
CP5      ST     GRP,PAR1(0,GRDIC)      THERE IS NO IDENTICAL PREVIOUS   63160015
         LA    GRY,13(0,GRLTH)       PICTURE, SO A NEW ENTRY IS CREATED 63200015
         ST    GRY,PAR2(0,GRDIC)       THE PICTURE IS MOVED IN WITH 13  63240015
         L     GRLR,ZDICRF(0,GRCC)   PRECEDING BYTES WHICH WILL BE      63280015
         BALR  GRRR,GRLR             OVERWRITTEN WITH STANDARD INFORM-  63320015
*                                    -ATION                             63360015
         L     GRX,LSTPIC              PICK UP POINTER TO LAST PICTURE  63400015
         MVC   3(2,GRX),PAR1+2(GRDIC)  SET POINTER IN LAST PICTURE TO   63440015
*                                    POINT TO NEW ONE.                  63480015
         SPACE                                                          63520015
         L     GRLR,ZDRFAB(0,GRCC)     CONVERT POINTER TO NEW ENTRY TO  63560015
         BALR  GRRR,GRLR             ABSOLUTE.                          63600015
         SPACE                                                          63640015
         L     GRX,PAR1(0,GRDIC)                                        63680015
         MVI   0(GRX),X'C8'            MOVE IN CODE BYTE                63720015
         STH   GRY,CFW+2               MOVE IN LENGTH                   63760015
         MVC   1(2,GRX),CFW+2                                           63800015
         MVI   3(GRX),X'00'            CLEAR NEXT 8 BYTES               63840015
         MVC   4(7,GRX),3(GRX)                                          63880015
         MVC   11(2,GRX),10(GRP)       MOVE IN PICTURE LENGTH           63920015
         SPACE 3                                                        63960015
CP10A    L     GRX,LSTPIC              PICK UP SYMBOLIC REFERENCE OF    64000015
         MVC   CAWSP2+PICAD(2),3(GRX)  PICTURE FROM PREVIOUS ENTRY AND  64040015
*                                    PUT IT IN SOURCE TEXT              64080015
         LA    GRP,14(GRLTH,GRP)       BUMP SCAN POINTER TO BYTE BEYOND 64120015
         BC    B,CAT3+2              PICTURE BEFORE RETURNING.          64160015
         SPACE                                                          64200015
CP9      CLC   13(0,GRX),13(GRP)       COMPARE PICTURES                 64240015
         EJECT                                                          64280015
*              ROUTINE CTYPBL - CREATE ENTRY TYPE 2'S                   64320015
*                                                                       64360015
*              FUNCTION/OPERATION - THIS ROUTINE SCANS THE LABELS ON    64400015
*        PROCEDURE AND ENTRY STATEMENTS AND CREATES THEIR ENTRY TYPE    64440015
*        2'S, PROCESSING THE ASSOCIATED DATA INFORMATION AS FOLLOWS.    64480015
*              (1)  THE DATA BYTE AND PRECISION VALUES ARE COMPLETED BY 64520015
*        DEFAULT RULES, USING ROUTINE CDEFAT.                           64560015
*              (2)  SECOND FILE STATEMENTS FOR ADJUSTABLE STRING        64600015
*        LENGTHS WILL HAVE ALREADY BEEN CREATED FOR THE FIRST LABEL;    64640015
*        THEY ARE COPIED FOR SUBSEQUENT LABELS.  THE ASSOCIATED DICT-   64680015
*        IONARY ENTRIES ARE CREATED.                                    64720015
*              A BIT IS SET ON IN THE FIRST LABEL IF ANY  SUBSEQUENT    64760015
*        LABEL HAS A DIFFERENT DATA BYTE IN ITS ENTRY TYPE 2.           64800015
*              A COUNT OF THE STATEMENT'S LABELS IS INSERTED IN THE     64840015
*        FIRST LABEL.                                                   64880015
*              FINALLY, THE ROUTINE ERASES THE ATTRIBUTES ON THE        64920015
*        PROCEDURE OR ENTRY STATEMENT.                                  64960015
*                                                                       65000015
*              ENTRY POINTS - CTYPBL,  STRAIGHT-FORWARD BRANCH TO IT    65040015
*        FROM ROUTINE 'CANATP'.                                         65080015
*                                                                       65120015
*              EXTERNAL ROUTINES - CDEFAT, COMPLETES DATA INFORMATION.  65160015
*                                  ENT2F, COPIES SECOND FILE STATEMENTS 65200015
*                                                                       65240015
*              EXITS, NORMAL - BRANCH TO CA10, FOLLOWING TYPFIN.        65280015
*                                                                       65320015
*              EXITS, ERROR - NONE.                                     65360015
*                                                                       65400015
*              TABLES/WORK AREAS - ATTCOL, THE ATTRIBUTE COLLECTION     65440015
*        AREA PASSED TO, AND RETURNED BY, CDEFAT                        65480015
*                                  CAWSP2, CONTAINS INITIAL INFORMATION 65520015
*        FOR ATTCOL.                                                    65560015
*                                  CASPAC, THE WORKSPACE IN WHICH THE   65600015
*        ENTRY TYPE 2 IS CREATED.                                       65640015
*                                                                       65680015
*              NOTES - N/A                                              65720015
         SPACE 5                                                        65760015
CTYPBL   MVC   PAR1+2(2,GRDIC),CAWSP1+PL  PICK UP POINTER TO FIRST      65800015
*                                    LABEL FROM ENTRY TYPE 1.           65840015
         LH    GRW,PAR1+2(0,GRDIC)                                      65920015
         STH   GRW,ZLOCK+2(0,GRDIC)    LOCK IN FIRST LABEL              65960015
         SPACE                                                          66000015
         L     GRLR,ZDRFAB(0,GRCC)     CONVERT REFE                     66040015
         BALR  GRRR,GRLR                                                66080015
         SPACE                                                          66120015
         L     GRW,PAR1(0,GRDIC)       SAVE POINTER TO FIRST LABEL AND  66160015
         MVC   CATEMP+2(2),8(GRW)    SAVE ITS STATEMENT NUMBER.         66200015
         LR    GRX,GRW                                                  66240015
         SPACE                                                          66280015
         SR    GR0,GR0                 INITIALIZE LABEL COUNT           66320015
         SPACE                                                          66360015
NEWLAB   AR    GR0,GRUNIT              BUMP LABEL COUNT                 66400015
         SPACE                                                          66440015
TYP1L    MVC   ATTCOL(38),CAWSP2       SET UP ATTRIBUTE COLLECTION AREA 66480015
*                                    FOR DEFAULT ROUTINE.               66520015
*              IT IS NOW DECIDED WHETHER OR NOT THE INITIAL LETTER OF   66560015
*        THE LABEL IS IN THE RANGE I-N.                                 66600015
         SPACE                                                          66640015
         CLI   0(GRX),X'C3'            IS IT A COMPILER LABEL.          66680015
         BC    BE,NOTIN                IF SO, THEN NOT I-N              66720015
         CLI   LBCDL+1(GRX),X'19'      COMPARE WITH I                   66760015
         BC    BL,NOTIN                                                 66800015
         CLI   LBCDL+1(GRX),X'25'      COMPARE WITH N                   66840015
         BC    BH,NOTIN                                                 66880015
         CLI   LBCDL+1(GRX),X'20'      IS IT A SPECIAL CHARACTER        66920015
         BC    BE,NOTIN                                                 66960015
         OI    ATTCOL+10,X'80'                                          67000015
NOTIN    ST    GRX,CFW                 SAVE POINTER TO LABEL            67040015
         BAL   GRRR,CDEFAT                                              67080015
         SPACE 2                                                        67120015
E2       EQU   *                                                        67160015
*              THE ENTRY TYPE 2 WILL NOW BE BUILT UP IN CASPAC          67200015
         SPACE                                                          67240015
         MVC   CASPAC(3),E2ST          MOVE IN STANDARD PART.           67280015
         MVC   CASPAC+3(2),1(GRSP)     POINTER TO ENTRY TYPE 1 FROM     67320015
*                                    TEXT                               67360015
         XC    CASPAC+5(3),CASPAC+5      CLEAR 3 BYTES                  67400015
         CR    GR0,GRUNIT              IS THIS THE FIRST LABEL.         67440015
         BC    BE,E2A                                                   67480015
         CLC   CASPAC+8(1),ATTCOL+DATA IF NOT, COMPARE THIS DATA BYTE   67520015
         BC    BE,E2B                WITH THAT OF PREVIOUS LABEL.       67560015
         MVI   13(GRW),1               IF DIFFERENT SET BIT ON FOR      67600015
E2A      MVC   CASPAC+8(1),ATTCOL+DATA PSEUDO-CODE.                     67640015
E2B      MVC   CASPAC+9(3),ATTCOL+VINFP                                 67680015
         MVC   CASPAC+12(2),ATTCOL+16  MOVE IN PICTURE ADDRESS          67720015
         SPACE 3                                                        67760015
*              ANY SECOND FILE STATEMENT ASSOCIATED WITH THIS ENTRY     67800015
*        MUST NOW BE PROCESSED. IF IT HAS NOT ALREADY BEEN USED BY A    67840015
*        PREVIOUS LABEL, ITS DICTIONARY POINTER IS MADE TO CONTAIN THE  67880015
*        ADDRESS OF THIS ENTRY TYPE II. IF IT HAS, THE ENTRY IS REPEAT- 67920015
*        ED. THE ASSOCIATED DICTIONARY ENTRY IS CREATED.                67960015
         SPACE 2                                                        68000015
         C     GRUNIT,EXPINF           TEST THE ABSOLUTE POINTER TO 2ND 68040015
         BC    BH,TYPJ               FILE STATEMENT. IF LESS THAN ONE   68080015
*                                    (IT CANNOT BE NEGATIVE) THEN THERE 68120015
*                                    IS NOT A 2ND FILE STATEMENT.       68160015
         SPACE                                                          68200015
         CR    GR0,GRUNIT              IS THIS THE FIRST LABEL. IF SO,  68240015
         BC    BE,TYPK               ITS 2ND FILE ENTRY IS ALREADY IN   68280015
         BAL   GRZ,ENT2F             TEXT. IF NOT, GO AND REPEAT ENTRY. 68320015
         SPACE                                                          68360015
TYPK     MVC   CASPAC+9(3),EXPINF+6    MOVE SYMBOLIC POINTER TO 2ND     68400015
*                                    FILE STATEMENT INTO ENTRY TYPE II  68440015
         SPACE 2                                                        68480015
*              THE ASSOCIATED DICTIONARY ENTRY IS NOW CREATED.          68520015
         SPACE                                                          68560015
         CR    GR0,GRUNIT              IS THIS THE FIRST LABEL          68600015
         BC    BNE,TYPI                IF NOT, DICENT HAS ALREADY BEEN  68640015
*                                    BUILT UP                           68680015
         SPACE                                                          68720015
         MVC   DICENT+3(2),8(GRW)      MOVE IN STATEMENT NUMBER         68760015
         MVC   DICENT+5(2),1(GRSP)             POINTER TO ENTRY TYPE 1  68800015
         MVC   DICENT+10(2),5(GRSP)        AND LEVEL AND COUNT          68840015
         L     GRY,EXPINF              POINT GRY AT 2ND FILE STATEMENT  68850015
         MVC   DICENT+9(1),8(GRY)    AND MOVE IN THE TYPE CODE BYTE.    68860015
         SPACE                                                          68880015
TYPI     ST    GRUNIT,PAR2(0,GRDIC)    CLEAR PAR2                       68920015
         MVI   PAR2+3(GRDIC),X'0C'     INSERT ENTRY LENGTH.             68960015
         LA    GRZ,DICENT                                               69000015
         ST    GRZ,PAR1(0,GRDIC)       INSERT ADDRESS OF ENTRY IN PAR1. 69040015
         L     GRLR,ZDICRF(0,GRCC)     MAKE DICTIONARY ENTRY            69080015
         BALR  GRRR,GRLR                                                69120015
         SPACE                                                          69160015
         L     GRY,EXPINF              PICK UP ABSOLUTE POINTER TO 2ND  69200015
         MVC   1(2,GRY),PAR1+2(GRDIC) FILE STATEMENT AND MOVE IN POINT- 69240015
*                                     ER TO DICTIONARY ENTRY.           69280015
         SPACE 2                                                        69320015
TYPJ     EQU   *                                                        69360015
         SPACE                                                          69400015
*              THE ENTRY TYPE 2 WILL NOW BE MOVED INTO THE DICTIONARY   69440015
         ST    GRUNIT,PAR2(0,GRDIC)      CLEAR FIRST 3 BYTES OF PAR2    69480015
         MVI   PAR2+3(GRDIC),X'0E'       INSERT LENGTH OF ENTRY         69520015
         LA    GRX,CASPAC                                               69560015
         ST    GRX,PAR1(0,GRDIC)         ADDRESS OF ENTRY               69600015
         L     GRLR,ZDICRF(0,GRCC)                                      69640015
         BALR  GRRR,GRLR                                                69680015
         L     GRX,CFW                 PICK UP POINTER TO LABEL         69720015
         MVC   11(2,GRX),PAR1+2(GRDIC) MOVE INTO LABEL POINTER TO ITS   69760015
*                                    ENTRY TYPE 2                       69800015
         C     GRUNIT,EXPINF           IS THERE AN ASSOCIATED SECOND    69840015
         BC    BH,TYPU               FILE STATEMENT.           IF SO    69880015
         MVC   ST2FDR(2,GRY),11(GRX)   MOVE POINTER TO ENTRY TYPE 2     69920015
*                                    INTO SECOND FILE FROM LABEL.       69960015
*                                    (GRY ALREADY POINTS TO STATEMENT). 70000015
         SPACE                                                          70040015
         SPACE                                                          70080015
         MVC   CFW2+2(2),PAR1+2(GRDIC) DIC. REF. OF ENTRY TYPE 2  28475 70090019
         L     GRLR,ZDRFAB(0,GRCC)     OBTAIN THE                 28475 70100019
         BALR  GRRR,GRLR                 ABSOLUTE ADDRESS         28475 70110019
         L     GRLR,PAR1(0,GRDIC)          OF THE ENTRY TYPE 2.   28475 70120019
         LA    GRLR,9(0,GRLR)          BUMP IT BY 9, TO POINT AT  28475 70130019
*                                    SLOT FOR 2ND FILE TEXT REF.  28475 70140019
         MVC   PAR1+2(2,GRDIC),CFW2+2  OBTAIN THE                 28475 70150019
         ST    GRLR,PAR2(0,GRDIC)        SYMBOLIC ADDRESS         28475 70160019
         L     GRLR,ZDABRF(0,GRCC)         OF THIS SLOT IN THE    28475 70170019
         BALR  GRRR,GRLR                     ENTRY TYPE 2,        28475 70180019
         MVC   CFW2+2(2),PAR1+2(GRDIC) AND SAVE IT.               28475 70190019
         MVC   PAR1+2(2,GRDIC),1(GRY)  CONVERT REFERENCE TO DICTIONARY  70240015
         L     GRLR,ZDRFAB(0,GRCC)   ENTRY ASSOCIATED WITH SECOND FILE  70280015
         BALR  GRRR,GRLR             STATEMENT TO ABSOLUTE.             70320015
         SPACE                                                          70360015
         L     GRY,PAR1(0,GRDIC)       MOVE POINTER TO SLOT (SAVED      70400015
         MVC   7(2,GRY),CFW2+2        ABOVE) INTO DICTIONARY ENTRY.     70440015
TYPU     BAL   GRRR,LABCNT   CHECK COUNT, IF = 255 & MORE LABELS  52185 70480064
*                            FOLLOW, ERROR. ELSE BUMP TO NEXT ONE.52185 70530064
         B     TYPFIN        RETURN+0 IF ERROR OR FINISHED.       52185 70580064
*                            RETURN+4 IF OK, GRX-> NEXT LABEL.    52185 70630064
TYPV     CLI   0(GRX),EODB             IS THIS THE END OF DICT. BLOCK   70680015
         BC    BE,TYPZ                 IF SO, GO TO FIND NEXT BLOCK.    70720015
         SPACE                                                          70760015
         LA    GRX,3(0,GRX)            OTHERWISE, SKIP TO FULL WORD     70800015
         N     GRX,BDYMSK            BOUNDARY.                          70840015
         SPACE                                                          70880015
TYPW     TM    0(GRX),X'80'            HAS NEXT ENTRY GOT BCD. IF SO,   70920015
         BC    BZ,NEWLAB             GO TO PROCESS IT.                  70960015
         SPACE                                                          71000015
         MVC   CATEMP+2(2),1(GRX)      PICK UP LENGTH OF NON- LABEL     71040015
         AH    GRX,CATEMP+2          ENTRY AND SKIP ENTRY.              71080015
         BC    B,TYPV                                                   71120015
*              PREPARE TO RETURN                                        71160015
         SPACE                                                          71200015
TYPFIN   STC   GR0,15(0,GRW)           INSERT LABEL COUNT IN 1ST LABEL  71240015
         L     GRX,CAPTR2              PICK UP START OF ATTRIBUTE LIST. 71280015
         CR    GRP,GRX                 IS IT SAME AS END                71320015
         BC    BE,CA10                 IF SO THERE NOTHING TO BE        71360015
*                                    ERASED                             71400015
         MVI   0(GRX),0              CLEAR FIRST BYTE OF LIST.          71440015
         LR    GRLTH,GRP               COMPUTE LENGTH OF LIST.          71480015
         SR    GRLTH,GRX                                                71520015
         SH    GRLTH,TWO               REDUCE BY 2 - 1 FOR EXECUTION @  71560015
         BC    BL,CA10               1 FOR BYTE ALREADY CLEARED. CHECK  71600015
CATX     SH    GRLTH,T56             THAT THERE MORE TO BE CLEARED.     71640015
         BC    BL,REM                  IF LESS THAN 256 GO AND CLEAR    71680015
         MVC   1(256,GRX),0(GRX)     REMAINDER. OTHERWISE CLEAR 256     71720015
         AH    GRX,T56                 BUMP POINTER AND                 71760015
         BC    B,CATX                GO BACK FOR MORE.                  71800015
ERASE    MVC   1(0,GRX),0(GRX)         ERASE REMAINDER                  71840015
REM      AH    GRLTH,T56             RESTORE LENGTH                     71880015
         EX    GRLTH,ERASE                                              71920015
         BC    B,CA10                                                   71960015
         SPACE 3                                                        72000015
TYPZ     EQU   *                                                        72040015
         MVC   PAR1+2(2,GRDIC),1(GRX)  MOVE IN SYMBOLIC REFERENCE OF    72080015
         L     GRLR,ZDRFAB(0,GRCC)   NEXT BLOCK AND CONVERT IT          72120015
         BALR  GRRR,GRLR                                                72160015
         SPACE                                                          72200015
         L     GRX,PAR1(0,GRDIC)                                        72240015
         BC    B,TYPW                                                   72280015
         EJECT                                                          72320015
*        ROUTINE ENT2F                                                  72360015
*                                                                       72400015
*              THIS ROUTINE IS MAKES SECOND FILE ENTRIES FOR STRING     72440015
*        LENGTH EXPRESSIONS. IT IS USED FOR EITHER CREATING THE FIRST   72480015
*        ENTRY OR FOR REPEATING IT FOR SUBSEQUENT LABELS ON THE PROC-   72520015
*        EDURE OR ENTRY STATEMENT.                                      72560015
*              IT IS ENTERED WITH EXPINF CONTAINING THE ABSOLUTE ADD-   72600015
*        RESS OF, AND THE LENGTH-1 OF THE ENTRY TO BE COPIED            72640015
*              ON RETURN EXPIMF CONTAINS THE ABSOLUTE ADDRESS, SYMBOLIC 72680015
*        REFERENCE AND LENGTH (SAME AS BEFORE) OF THE NEW ENTRY.        72720015
         SPACE 2                                                        72760015
ENT2F    L     GRX,ZLSTXT(0,GRDIC)     FIRST CHECK THAT THERE IS ROOM   72800015
*                                    IN THIS TEXT BLOCK                 72840015
         LH    GRY,ZLSTXT+2(GRDIC)     OFFSET IN SYMBOLIC REFERENCE     72880015
*                                    INTO GRY (NAME REMOVED)            72920015
         SPACE                                                          72960015
         ST    GRX,PAR1(0,GRDIC)       CONVERT REFERENCE TO NEXT AVAIL- 73000015
         L     GRLR,ZTXTAB(0,GRCC)   ABLE BYTE IN THIS BLOCK TO ABSOL-  73040015
         BALR  GRRR,GRLR             UTE.                               73080015
         L     GRX,PAR1(0,GRDIC)                                        73120015
         SPACE                                                          73160015
         LH    GRLTH,EXPINF+4          PICK UP ENTRY LENGTH-1           73200015
         LA    GRY,3(GRY,GRLTH)        IS THERE ROOM FOR ENTRY AND      73240015
         C     GRY,ZBLKSZ(0,GRDIC)   SEMI-COLON AND E.O.P. MARKER.      73280015
         BC    BNL,NEWBLK              IF NOT, GO AND GET NEW BLOCK.    73320015
         SPACE 2                                                        73360015
*              THERE IS ROOM IN THIS BLOCK                              73400015
ENT2F1   L     GRLR,EXPINF             PICK UP POINTER TO ENTRY AND     73440015
         ST    GRX,EXPINF            REPLADE WITH ADDRESS OF NEW ENTRY  73480015
         EX    GRLTH,MV2F            INSERT IT IN THE SECOND FILE.      73520015
         SPACE                                                          73560015
         CH    GRLTH,T55                                                73600015
         BC    BH,BIG2F                                                 73640015
         SPACE                                                          73680015
         AR    GRX,GRLTH                                                73720015
B2FRET   MVI   1(GRX),SC                                                73760015
         MVC   EXPINF+6(3),ZLSTXT+1(GRDIC)                              73800015
         SR    GRY,GRUNIT                                               73840015
         STH   GRY,ZLSTXT+2(GRDIC)     UPDATE ZLSTXT - OVERWRITE OLD    73880015
*                                    OFFSET WITH OLD OFFSET + LENGTH.   73920015
         BCR   B,GRZ                   RETURN                           73960015
         SPACE                                                          74000015
MV2F     MVC   0(0,GRX),0(GRLR)        EXECUTED ABOVE.                  74040015
         SPACE 2                                                        74080015
BIG2F    MVI   CATEMP,0                STORE JUNIOR BYTE OF LENGTH IN   74120015
         STC   GRLTH,CATEMP+1        A HALF-WORD                        74160015
         SH    GRLTH,CATEMP            REDUCE LENGTH AND BUMP POINTERS  74200015
         AH    GRX,CATEMP            BY AMOUNT ALREADY MOVED.           74240015
         AH    GRLR,CATEMP                                              74280015
BIG2F1   MVC   1(256,GRX),1(GRLR)      MOVE IN 256 BYTE CHUNK           74320015
         LA    GRX,256(0,GRX)          BUMP POINTERS                    74360015
         LA    GRLR,256(0,GRLR)                                         74400015
         SH     GRLTH,T56              REDUCE LENGTH                    74440015
         BC    BH,BIG2F1               MOVE MORE IF SOME LEFT.          74480015
         BC    B,B2FRET                OTHERWISE, DO TO FINISH ENTRY    74520015
NEWBLK   MVI   0(GRX),X'ED'                                             74560015
*                                    OLD BLOCK                          74600015
         SPACE                                                          74640015
*              IT IS NOW DECIDED WHETHER OR NOT THE OLD BLOCK IS TO     74680015
*        BE MARKED 'NOT WANTED'                                         74720015
         SPACE                                                          74760015
         CLC   SYMN1,ZLSTXT+1(GRDIC)   IS THE MOST RECENT PROCEDURE     74800015
         BC    BE,BUSY               STATEMENT IN THE OLD BLOCK. IF SO  74840015
         CLI   4(GRSP),PROC          IT MUST BE KEPT BUSY. IS IT A PROC 74880015
         BC    BE,NOTWNT             STAT. BEING PROCESSED. IF NOT, IS  74920015
         CLC   SYMN2,ZLSTXT+1(GRDIC) THIS ENTRY STATEMENT IN OLD BLOCK  74960015
         BC    BNE,NOTWNT            IF NOT, BLOCK CAN BE MARKED 'NOT   75000015
*                                    WANTED'                            75040015
BUSY     MVI   PAR2+3(GRDIC),X'84'                                      75080015
         BC    B,CHANGE                                                 75120015
NOTWNT   MVI   PAR2+3(GRDIC),X'82'     MARK OLD BLOCK 'NOT WANTED'.     75160015
         SPACE                                                          75200015
CHANGE   DS    0H                                                       75220015
         MVC   PAR1(4,GRDIC),ZLSTXT(GRDIC)                              75240015
         L     GRLR,ZUTXTC(0,GRCC)                                      75280015
         BALR  GRRR,GRLR                                                75320015
         SPACE                                                          75360015
         L     GRX,PAR2(GRDIC)         ABSOLUTE POINTER TO NEW BLOCK    75400015
         MVC   ZLSTXT(4,GRDIC),PAR1(GRDIC) INTO GRX AND UPDATE ZLSTXT.  75440015
         SPACE                                                          75480015
         LA    GRY,3(0,GRLTH)                                           75520015
         BC    B,ENT2F1                                                 75560015
         EJECT                                                          75600015
*                       ROUTINE CDFLT                                   75640015
         SPACE                                                          75680015
*              THIS ROUTINE COMPLETES THE ATTRIBUTE COLLECTION AREA     75720015
*        IN CASES WHERE THE ITEM HAS NOT BEEN DECLARED.                 75760015
         SPACE                                                          75800015
*              THE ATTRIBUTE COLLECTION REGION MAY HAVE BEEN STARTED    75840015
*        AS A RESULT OF AN IMPLICIT STATEMENT OR BECAUSE OF CONTEXT.    75880015
         SPACE                                                          75920015
*              THE DESCRIPTION OF THE ATTRIBUTE COLLECTION AREA IS      75960015
*        TAKEN FROM THE ROUTINE CDICEN.                                 76000015
         SPACE                                                          76040015
         SPACE                                                          76080015
*              MAKE THE ATTRIBUTE COLLECTION AREA ADDRESSIBLE           76120015
         SPACE                                                          76160015
CDEFAT   LA    ATTPTR,ATTCOL                                            76200015
         TM    X280(ATTPTR),X'C0'      IF POINTER , LOOK NO FURTHER.    76240015
         BCR   BO,GRRR                                                  76280015
         TM    X280(ATTPTR),X'08'      TEST FOR PICTURE                 76320015
         BCR   BZ,GRRR                                                  76360015
         CLI   X280(ATTPTR),X'2E'                                       76400015
         BCR   BE,GRRR                 SIMILARLY FOR AREA               76440015
         SPACE                                                          76480015
         CLI   0(ATTPTR),X'00'         WE ASK WHETHER THE FIRST BYTE OF 76520015
         BC    BNE,Y3A                 THE COLLECTION REGION IS ALL     76560015
*                                      ZERO                             76600015
         SPACE                                                          76640015
Y3       TM    X300(ATTPTR),X301       IF THE FLAG IS NOT ON WE GO TO   76680015
         BC    BZ,Y0                   THE SAME ROUTINE AS BEFORE AND   76720015
*                                      THE DEFAULT IS FLOAT.            76760015
         SPACE                                                          76800015
*              OTHERWISE WE MAKE THE DEFAULT TO BE FIXED BINARY REAL    76840015
         SPACE                                                          76880015
         OI    X280(ATTPTR),Y201       OR THE APPROPRIATE BITS INTO THE 76920015
*                                      DATA BYTE                        76960015
         SPACE                                                          77000015
         MVI   X400+1(ATTPTR),Y201A    SET UP THE DEFAULT PRECISION AND 77040015
         MVI   X400+2(ATTPTR),Y201B    SCALE FACTOR.                    77080015
         SPACE                                                          77120015
         BCR   B,GRRR                                                   77160015
Y0       OI    X280(ATTPTR),Y200       OR THE APPROPRIATE BITS INTO     77200015
*                                      THE DATA BYTE                    77240015
         SPACE                                                          77280015
         MVI   X400+1(ATTPTR),Y200A    MOVE IN THE DEFAULT PRECISION    77320015
         BCR   B,GRRR                                                   77360015
         SPACE 5                                                        77400015
*              HERE THE FIRST BYTE OF THE DECLARED ATTRIBUTE REGION IS  77440015
*        NOT ALL ZERO.                                                  77480015
         SPACE                                                          77520015
*              WE ASK WHETHER OR NOT THE DATA BIT IS ON.                77560015
         SPACE                                                          77600015
Y3A      TM    0(ATTPTR),X202                                           77640015
         BC    BZ,CMPER2                                                77680015
         SPACE                                                          77720015
*              THE DATA BIT IS ON.   IS THE CAD BIT ON IN THE SECOND    77760015
*        BYTE.                                                          77800015
         SPACE                                                          77840015
         TM    1(ATTPTR),X210                                           77880015
         BCR   BZ,GRRR                 IF NOT, NOTHING TO BE DONE.      77920015
         SPACE                                                          77960015
*              WE ARE LOOKING AT CODED ARITHMETIC DATA.   IS THE RADIX, 78000015
*        SCALE AND MODE BIT ON.                                         78040015
         SPACE                                                          78080015
         TM    1(ATTPTR),X211                                           78120015
         BC    BZ,Y3                                                    78160015
         SPACE                                                          78200015
*              THE RADIX, SCALE AND MODE BIT IS ON.   ARE BOTH THE      78240015
*        FIXED AND FLOAT BITS ON IN THE TEST MASK                       78280015
         SPACE                                                          78320015
         TM    Y5000(ATTPTR),Y500A                                      78360015
         BC    BM,*+8                                                   78400015
         SPACE                                                          78440015
*              NO FIXED/FLOAT ATTRIBUTE HAS BEEN DECLARED               78480015
         SPACE                                                          78520015
         OI    X280(ATTPTR),X287       SET THE FLOAT BIT ON IN THE      78560015
*                                      DATA BYTE.                       78600015
         SPACE                                                          78640015
PRECIS   ST   GRX,PRECX                SAVE  GRX                        78680015
         LA   GRX,PRECN                POINT GRX AT TABLE               78720015
         TM    X280(ATTPTR),X287       IF FIXED THEN ADD 6              78760015
         BC    BO,PREC3                                                 78800015
         LA    GRX,6(GRX)                                               78840015
PREC3    TM    X280(ATTPTR),X286       IF DECIMAL THEN ADD 3            78880015
         BC    BO,PREC4                                                 78920015
         LA    GRX,3(GRX)                                               78960015
PREC4    TM    0(ATTPTR),X'40'         WAS A PRECISION SPECIFIED        79000015
         BC    BZ,PREDEF               IF SO                            79040015
         CLC   X400+1(1,ATTPTR),1(GRX) WAS PRECISION TOO BIG            79080015
         BC    BH,PREC5                                                 79120015
         CLC   X400+1(1,ATTPTR),0(GRX) WAS PRECISION GREATER THAN SHORT 79160015
         BC    BNH,PRECR               PRECISION. IF SO                 79200015
         OI    X280(ATTPTR),LONG       SET LONG BIT                     79240015
         BC    B,PRECR                                                  79280015
PREC5    MVC   PAR6+1(3,GRDIC),CAE16M  PUT OUT A MESSAGE -              79320015
         BAL   GRY,CAE4A                                                79360015
PREDEF   MVC   X400+1(1,ATTPTR),2(GRX) DEFAULT VALUE ASSUMED            79400015
         L     GRX,PRECX                                                79440015
         MVI   X400+2(ATTPTR),Y201B    AND SCALE                        79480015
         TM    X280(ATTPTR),X287       IS IT FLOAT                      79520015
         BC    BZ,E2                                                    79560015
         MVI   X400+2(ATTPTR),0        IF SO RESET SCALE.               79600015
         BC    B,E2                    RETURN                           79640015
         SPACE 2                                                        79680015
PRECR    L     GRX,PRECX                                                79720015
         TM    X280(ATTPTR),X287                                        79760015
         BCR   BZ,GRRR                                                  79800015
         MVI   X400+2(ATTPTR),0                                         79840015
         BCR   B,GRRR                                                   79880015
         SPACE 3                                                        79920015
PRECX    DC    F'0'                                                     79960015
PRECN    DC    AL1(21)                 MAXIMUM SHORT FLOAT BINARY       80000015
         DC    AL1(FLBMAX)             MAXIMUM LONG                     80040015
         DC    AL1(FLBDEF)             DEFAULT                          80080015
         DC    AL1(6)                                FLOAT DECIMAL      80120015
         DC    AL1(FLDMAX)                                              80160015
         DC    AL1(FLDDEF)                                              80200015
         DC    AL1(21)                               FIXED BINARY 52204 80240064
         DC    AL1(FIBMAX)                                              80280015
         DC    AL1(FIBDEF)                                              80320015
         DC    AL1(6)                                FIXED DECIMAL      80360015
         DC    AL1(FIDMAX)                                              80400015
         DC    AL1(FIDDEF)                                              80440015
         EJECT                                                          80480015
CAE1     LA GRY,CAT3                                                    80520015
         MVC   PAR6+1(3,GRDIC),CAE7M                                    80560015
         BC    B,CAE4A                                                  80600015
         SPACE 5                                                        80640015
*              TEH NUMERIC PARAMETERS FOR TERMINAL ERRORS ARE SET UP IN 80680015
*        GRUNIT. (THIS IS DONE BY REPEATED REDUCTIONS TO SAVE THE SPACE 80720015
*        WHICH WOULD OTHERWISE BE REQUIRED FO BRANCHING ROUND THE CODE  80760015
         SPACE                                                          80800015
CMPER2   BCTR  GRUNIT,0                NO.2 - ERROR IN ATTCOL           80840015
CAE3     BCTR  GRUNIT,0                NO.3 - INPUT ERROR IN F.P. LIST  80880015
CAE9     BCTR  GRUNIT,0                NO.4 - NO SEMI-COLON             80920015
CAE5     BCTR  GRUNIT,0                NO.5 - NO ) AT END OF F.P. LIST. 80960015
PICERR   BCTR  GRUNIT,0                NO.6 - NO QUOTES ROUND PICTURE   81000015
CAE8     BCTR  GRUNIT,0                NO.7 - NO ) AT END OF OPTIONS.   81040015
CAE13    BCTR  GRUNIT,0                NO.8 - PRECISION FORMAT ERROR.   81080015
CAE14    AH    GRUNIT,EIGHT            NO.9 - SCALING VALUE ERROR.      81120015
CAE2     DS    0H                      NO.1 - INVALID STMT. ON CHAIN.   81140015
         ST    GRUNIT,PAR5(0,GRDIC)                                     81160015
CMPERR   MVC   PAR6+1(3,GRDIC),MES8    COMPILER ERROR.                  81200015
         L     GRLR,ZUERR(0,GRCC)                                       81240015
         BALR  GRRR,GRLR                                                81280015
         L     GRLR,ZABORT(0,GRCC)                                      81320015
         BALR  GRRR,GRLR                                                81360015
         SPACE 2                                                        81400015
DPA1     MVC   PAR6+1(3,GRDIC),DPA1M   TWO LABELS THE SAME.             81440015
         MVC   ZSTAT(2,GRDIC),LABSN(GRDP)                               81480015
EGERR    L     GRLR,ZUERR(0,GRCC)                                       81520015
         BCR   B,GRLR                  IN CASE OF DPA1, GRRR PRESET     81560015
         SPACE 2                                                        81600015
*              FORMAL PARAMETER AND LABEL ARE THE SAME.                 81640015
CAE4     LA    GRHASH,1(0,GRLTH)       SET UP POINTER TO BCD AND ITS    81680015
         STM   GRPTR,GRHASH,PAR7(GRDIC) LENGTH IN PAR7 AND PAR8, VIA    81720015
*                                    REGISTERS GRPTR AND GRHASH (WHICH  81760015
*                                    ARE ASSUMED TO BE  CONSECUTIVE).   81800015
         MVC   PAR6+1(3,GRDIC),CAE4M                                    81840015
         LA    GRY,CB4                                                  81880015
CAE4B    XC    CADP(2),CADP                                             81920015
CAE4A    MVC   PAR1+2(2,GRDIC),CAWSP1+PL AND LABEL ARE THE SAME.        81960015
         L     GRLR,ZDRFAB(0,GRCC)                                      82000015
         BALR  GRRR,GRLR                                                82040015
         L     GRRR,PAR1(0,GRDIC)      PICK UP POINTER TO LABEL AND     82080015
         MVC   ZSTAT(2,GRDIC),LABSN(GRRR) EXTRACT STATEMENT NUMBER.     82120015
         LR    GRRR,GRY                                                 82160015
         BC    B,EGERR                                                  82200015
         SPACE 2                                                        82240015
CAE6     L     GRY,CLINK               SET UP RETURN REGISTER.          82280015
         MVC   PAR6+1(3,GRDIC),MESA    SET UP MESSAGE.                  82320015
         BC    B,CAE4A                 GO TO FIND STATEMENT NO.         82360015
CAE7     MVC   PAR6+1(3,GRDIC),CAE7M                                    82400015
CAE10    EQU   CAE7                                                     82440015
         LA    GRY,CAE6A               RETURN LINK                      82480015
         BXH   GRP,GRUNIT,CAE4A                                         82520015
CAE11    LA    GRY,CAT7                                                 82560015
         MVC   PAR6+1(3,GRDIC),CAE11M                                   82600015
         BXH   GRP,GRUNIT,CAE4A                                         82640015
         SPACE 2                                                        82680015
CAE12    LA    GRY,CAT7                                                 82720015
         MVC   PAR6+1(3,GRDIC),CAE12M                                   82760015
         BXH   GRP,GRUNIT,CAE4A                                         82800015
         SPACE 2                                                        82840015
*              EROR IN PRECISION ATTRIBUTE. IGNORE ATTRIBUTE. DEFAULT   82880015
*        PRECISION WILL THEN BE GIVEN.                                  82920015
         SPACE                                                          82960015
CAE16    OI    CATMSK+1,3              RESTORE PRECISION BITS IN TEST   83000015
*                                    MASK FOR DEFAULT ROUTINE           83040015
         MVC   PAR6+1(3,GRDIC),CAE16M                                   83080015
CAE16A   EQU   *                                                        83120015
         LA    GRY,CAE6A               SET RETURN LINK TO ROUTINE FOR   83160015
         BC    B,CAE4A               FINDING END OF ATTRIBUTE.          83200015
CAE15    EQU   CAE16                                                    83240015
         SPACE 3                                                        83280015
CHBER    MVC   PAR6+1(3,GRDIC),CHBERM  SET UP MESSAGE                   83320015
         MVC   CAWSP2+STRLTH(2),VIIFFF SET STRING LENGTH TO MAXIMUM     83360015
         BC    B,CAE16A                                                 83400015
         SPACE 3                                                        83440015
CHBER2   MVI   CAWSP2+STRLTH,0                                          83480015
         STC   GRUNIT,CAWSP2+STRLTH+1                                   83520015
         LA GRY,CAT3                                                    83560015
         MVC   PAR6+1(3,GRDIC),MES9                                     83600015
         BC    B,CAE4A                                                  83640015
         SPACE 2                                                        83680015
CAE6A    CLI   0(GRP),RB               THIS LOOP SCANS FOR RIGHT BRACK- 83720015
         BC    BE,CAT3               ET THEN RETURNS TO MAIN ROUTINE    83760015
         BXH   GRP,GRUNIT,CAE6A                                         83800015
         SPACE                                                          83840015
         SPACE 3                                                        83880015
CAEND    L     GRX,ZLSTXT(0,GRDIC)                                      83920015
         ST    GRX,PAR1(0,GRDIC)                                        83960015
         L     GRLR,ZTXTAB(0,GRCC)                                      84000015
         BALR  GRRR,GRLR                                                84040015
         L     GRY,PAR1(0,GRDIC)       PICK UP ABSOLUTE POINTER TO END  84080015
         MVI   0(GRY),EOP            OF TEXT AND INSERT SECOND END OF   84120015
*                                    PROGRAM MARKER.                    84160015
         SPACE                                                          84200015
         ST    GRX,PAR1(0,GRDIC)       MARK BLOCK 'NOT WANTED'          84240015
         MVI   PAR2+3(GRDIC),2                                          84280015
         L     GRLR,ZALTER(0,GRCC)                                      84320015
         BALR  GRRR,GRLR                                                84360015
         SPACE                                                          84400015
         ST    GRUNIT,PAR1(0,GRDIC)    RELEASE SCRATCH CORE NOT         84440015
         L     GRLR,ZURC(0,GRCC)     REQUIRED BY LATER PHASES.          84480015
         BALR  GRRR,GRLR                                                84520015
         SPACE                                                          84560015
         LA    GRX,RLLST                                                84600015
         ST    GRX,PAR1(0,GRDIC)                                        84640015
         SR    GRX,GRX                                                  84680015
         ST    GRX,PAR2(0,GRDIC)                                        84720015
         SPACE                                                          84760015
         SPACE                                                          84800015
         L     GRLR,RLSCTL(0,GRCC)                                      84840015
         BCR   B,GRLR                                                   84880015
         EJECT                                                          84920015
*              CONSTANTS AND STORAGE                                    84960015
         SPACE                                                          85000015
*              STORAGE NOT REQUIRING ANY PARTICULAR INITIAL VALUE IS    85040015
*        PROVIDED BY OVERWRITING PART OF THE CODE ABOVE.                85080015
         SPACE                                                          85120015
CA       EQU   IEMEG                                                    85160015
CABL     EQU   IEMEG+2                 SAVES BLOCK LEVEL                85200019
CABN     EQU   CABL+1                  SAVES BLOCK NUMBER               85240019
CASPAC   EQU   CABN+1                  8 WORDS, 4 BYTE ALIGNED          85280019
CATEMP   EQU   CASPAC+32               FULL WORD WORKSPACE              85320015
NXTAB    EQU   CATEMP+4                SAVES ABSOLUTE ADDRESS OF END OF 85360015
*                                    DICTIONARY.                        85400015
CALST    EQU   NXTAB+4                 LAST ADDRESS IN HASH CHAIN       85440015
CADP     EQU   CALST+4                 SAVES DICTIONARY POINTER         85480015
CACNT    EQU   CADP+2                  FORMAL PARAMETER COUNT.          85520015
SYMN1    EQU   CACNT+2                 SYMBOLIC NAMES OF BLOCKS CONTAIN 85560015
SYMN2    EQU   SYMN1+1               ING CURRENT PROC AND ENTRY STATS.  85600015
         SPACE 2                                                        85650019
*              THE CODE BETWEEN 'CA6' AND 'CA7' IS OVERWRITTEN.         85700019
         SPACE                                                          85750019
LSTPIC   EQU   CA6                                                      85800019
EXPINF   EQU   CA6+8                                                    85850019
ATTCOL   EQU   EXPINF+10                                                85900019
CLINK    EQU   ATTCOL+38               SAVES RETURN REGISTER FOR CFORP  85950019
CATRNE   EQU   CABIN                                                    86000019
         SPACE 5                                                        86120015
RLLST    DC    C'EFEGZZ'               RELEASE LIST                     86200015
CALST1   DC    F'0'                                                     86240015
         EJECT                                                          86280015
*        THE FOLLOWING CONSTANTS ARE REFERENCED BY IEMEF -              86320015
         SPACE                                                          86360015
*        ZERO                                                           86400015
*        BDYMSK                                                         86420019
*        CFW                                                            86440015
*        FIFTEN                                                         86480015
*        THREE                                                          86500019
*        CAFENT                                                         86520015
*        SR1                                                            86560015
*        SR2                                                            86600015
         SPACE                                                          86640015
         SPACE                                                          86680015
*              FIXED OFFSET FOR REFERENCE BY IEMEF.               54771 86682064
         SPACE                                                          86682164
         ORG   IEMEG+X'F10'                                       54771 86682264
ATABLE   DC    X'2'                    DECIMAL                    54771 86682364
         DC    X'1'                    BINARY                     54771 86682464
         DC    X'4'                    FLOAT                      54771 86682564
         DC    X'3'                    FIXED                      54771 86682664
         DC    X'5'                    REAL                       54771 86682764
         DC    X'6'                    COMPLEX                    54771 86682864
         DC    X'B'                    PREC1                      54771 86682964
         DC    X'C'                    PREC2                      54771 86683064
         DC    X'7'                    VARYING                    54771 86683164
         DC    X'8'                    PICTURE                    54771 86683264
         DC    X'9'                    BIT                        54771 86683364
         DC    X'A'                    CHAR                       54771 86683464
         DC    X'0'                                               54771 86683564
         DC    X'0'                                               54771 86683664
         DC    X'D'                    PICTURE(CHARACTER)         54771 86683764
         DC    XL3'0'                                             54771 86683864
         BC    B,CHASH                 TRANSFER FOR EF TO HASH ROUTINE  86685619
         BC    B,CA6                   TRANSFER FOR EF TO PROC-BEGIN    86686419
*                                    AND ENTRY STATEMENT SCAN.          86687219
         BC    B,ENT2F                 TRANSFER FOR EF TO ENT2F ROUTINE 86688015
         BC    B,DPA1                  TRANSFER FOR EF TO ERROR ROUTINE 86689019
         DS    0H                      HALF WORD ALIGNMENT ENSURED      86690015
         DC    AL2(EXPINF-IEMEG)       OFFSET OF CA6+8, FOR ATTOF1      86692015
         DC    C' '                    SPARE BYTE TO ENSURE F35 FOLLOWS 86694015
CATCDE   DC    X'0'                    TEMPORARY OPTIONS CODE BYTE      86700015
OPTIM    DC    X'0'                    TEMPORARY OPTIMISATION BYTE      86710015
BLKLEV   DC    X'0'                    SAVED BLOCK LEVEL.               86720015
ZERO     DC    F'0'                                                     86760015
CFW2     DC    F'0'                                                     86800015
CADW     EQU   ZERO                                                     86840015
CAFENT   DC    XL16'C800080000000000C800080000000000'             54771 86850064
         DC    XL8'CA00080000000000'                              54771 86860064
LFTBIT   DC    X'80000000'                                              86880015
BDYMSK   DC    F'-4'                                                    86920015
CFW      DC    F'0'                                                     86960015
T11      DC    F'211'                                                   87000015
         SPACE                                                          87040015
TWO      DC    H'2'                                                     87080015
THREE    DC    H'3'                                                     87120015
FOUR     DC    H'4'                                                     87160015
EIGHT    DC    H'8'                                                     87200015
FIFTEN   DC    H'15'                                                    87240015
TH1      DC    H'31'                                                    87280015
X80      DC    H'128'                                                   87320015
T55      DC    H'255'                                                   87360015
T56      DC    H'256'                                                   87400015
VIIFFF   DC    H'32767'                                                 87440015
         EJECT                                                          87480015
TSTMSK   DC    X'FFFF0000'             1 BIT FOR EACH ACCEPTABLE  54771 87520064
*                                    ATTRIBUTE.                   54771 87620064
STR2F    DC    X'BC0000009F7E00000434430000004546'                54771 87720064
DICENT   DC    X'C8000C000000000000040000'                        54771 87820064
         SPACE 5                                                        88120015
E2ST     DC    X'85000E'               STANDARD PART OF ENTRY TYPE II   88160015
STFP     DC    X'400009'               STANDARD PART OF F.P. ENTRY      88200015
         SPACE 2                                                        88240015
*              TABLE OF MASKS WITH OFFSETS OF ROUTINES IN LAST BYTE.    88280015
         SPACE                                                          88320015
MSKTAB   EQU   STFP                                                     88360015
         DC    X'BC3000'               BINARY                           88400015
         DC    X'7C3008'               DECIMAL                          88440015
         DC    X'EC3010'               FIXED                            88480015
         DC    X'DC2018'               FLOAT                            88520015
         DC    X'F93620'               REAL                             88560015
         DC    X'F53028'               COMPLEX                          88600015
         DC    X'02C030'               VARYING                          88640015
         DC    X'0C003C'               PICTURE (NUMERIC)                88680015
         DC    X'020040'               BIT                              88720015
         DC    X'020044'               CHAR                             88760015
         DC    X'FC004E'               PREC1                            88800015
         DC    X'EC004E'               PREC2                            88840015
         DC    X'00003C'               PICTURE (CHARACTER)              88880015
         SPACE                                                          88920064
PATCH    DC    XL19'0'                                            54771 89010064
         SPACE                                                          89100064
STOP     EQU   BDYMSK                  ALL ONES FOR THREE BYTES         89200015
         SPACE 5                                                        89240015
*              ERROR MESSAGES                                           89280015
         SPACE                                                          89320015
CAE16M   DC    X'020644'                                                89360015
CHBERM   DC    X'020344'                                                89400015
CAE7M    DC    X'020444'                                                89440015
MES8     DC    X'020820'                                                89480015
MES9     DC    X'020944'                                                89520015
DPA1M    DC    X'020144'                                                89560015
CAE4M    DC    X'0202C4'                                                89600015
CAE11M   DC    X'020744'                                                89640015
CAE12M   DC    X'020544'                                                89680015
MESA     DC    X'020A44'                                                89720015
MESB     DC    X'020B54'                                                89760015
COMFLG   DC    X'0'                                                     89800015
SR1      DC    X'0'                                                     89840015
SR2      DC    X'0'                                                     89880015
         SPACE 5                                                        89920015
IEMEF    EQU   *                                                        89930019
CBCDL2   EQU   IEMEF+X'0E'                                              89940019
CHEXPF   EQU   CBCDL2+4                                                 89950019
MAKECA   EQU   CHEXPF+4                                                 89960019
OPTN1    EQU   MAKECA+4                CHECKS INHERITENCE OF OPTIONS    89970019
OPTN2    EQU   OPTN1+4                 PROCESSES PROCEDURE OPTIONS.     89980019
OPTN3    EQU   OPTN2+4                 DOES OPTION POST PROCESSING,     89990019
*                                    INCLUDING STATIC DSA SETTING.      90000019
ATTRBT   EQU   OPTN3+4                 OFFSET,POINTER,AREA PROCESSOR.   90010019
CAA1     EQU   ATTRBT+4                LABEL TABLE SCAN ROUTINE         90020019
LABCNT   EQU   CAA1+4        CHECK LABEL COUNT.                   52185 90025064
         SPACE 2                                                        90030019
*              THE ' LABEL TABLE SCAN' ROUTINE IN IEMEF IS NOT          90040019
*        REQUIRED ONCE THE TEXT SCAN HAS STARTED AND IT IS              90050019
*        USED AS A WORKSPACE.                                           90060019
         SPACE                                                          90070019
CAA      EQU   IEMEF+X'56'             OFFSET OF LABEL 'CAA1' IN EF.    90080019
CAFLG1   EQU   CAA                                                      90090019
CAFLG2   EQU   CAFLG1+1                                                 90100019
NCALST   EQU   CAFLG2+1                GAP                              90110019
BNSTK    EQU   NCALST+4                HEAD OF BLOCK NUMBER STACK       90120019
CASTK    EQU   BNSTK+4                 POINTER TO WORKSPACE             90130019
CALST2   EQU   CASTK+4                 POINTS TO CIRCULAR CHAIN SLOT    90140019
CACLO    EQU   CALST2+4                POINTER FOR CLOSING CIRC. CHAIN  90150019
CAPTR1   EQU   CACLO+4                 POINTER TP PROC STATEMENT        90160019
CAPTR2   EQU   CAPTR1+4                POINTER TO START OF ATTRIBUTES   90170019
CAWSP1   EQU   CAPTR1+4                WORKSPACE                        90180019
CAWSP    EQU   CAWSP1-IEMEF            OFFSET OF CAWSP1                 90190019
CAWSP2   EQU  CAWSP1+X'C0'             WORKSPACE                        90200019
CATMSK   EQU   CAWSP2+32               MASK FOR ATTRIBUTES CONFLICTS    90210019
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*EG 001-TSS 90477019
*        ----------------------------------------------------EG 001-TSS 90478019
         END   IEMEG                                                    90480015
