EI       TITLE 'IEMEI, DECLARE PASS ONE, DICTIONARY, OS/360 PL/I (F)'   00060015
*                                                                       00120015
*                                                                       00180015
*                                                                       00240015
*              STATUS - CHANGE LEVEL 0.                                 00300015
*                                                                       00360072
*                                                                       00362072
* 5.5  A 734400                                                KT 62613 00364072
*                                                                       00366072
* R17 376200-384000                                                 H91 00370001
* R17 460800-461400,639600,640800                                  H146 00380001
* R18 204600-206400,214800-219000,231600,236400-237000,296400-     H236 00390001
*     297600,343200-343800,364800-372000,894600,896400             H236 00400001
* R19    THE DESCRIPTIONS OF ROUTINES WITH THE FLAG 186/7 HAVE    186/7 00401019
* R19    BEEN ALTERED BY THE FIX FOR H186 AND H187.               186/7 00402019
* R19    THE STATEMENTS ALTERED/INSERTED/DELETED BY THIS FIX ARE- 186/7 00403019
*     024600*,148800*,321000-331800,333600-336000,531000-538800,  186/7 00404019
*     540600*,541800*,585600*,594600-599400,601200,719200*,       186/7 00405019
*     721200-721800,735600-736200,781200-791400,846600,           186/7 00406019
*     864000-886800,918000,920400*,922200,928200-928800,930600,   186/7 00407019
*     937200-937800.                                              186/7 00408019
* R19 162000,291600-291800,292000,734610-734680,792900*,918600.    H361 00409019
* R19 023400-024000*,037200-037800,150000-150600*,465600-469200,        00410019
*     793200,795600-822600*,919800*,939600-940800,942600-943200.        00411019
*                                                                       00420015
*                                                                       00480015
*              FUNCTION - SCANS DECLARE STATEMENTS IN TEXT AND MODIFIES 00540015
*        THEM TO ASSIST DECLARE PASS TWO AS FOLLOWS -                   00600015
*              (1) STRUCTURE LEVEL MARKERS ARE REPLACED BY THEIR BINARY 00660015
*        EQUIVALENTS.                                                   00720015
*              (2) BRACKETS USED FOR FACTORING ATTRIBUTES ARE REPLACED  00780015
*        BY DIFFERENT CODES AND A FACTORED ATTRIBUTE TABLE IS BUILT UP. 00840015
*        THE TABLE LINKS EACH FACTORED LEVEL WITH THE ATTRIBUTE LISTS   00900015
*        WHICH APPLY TO THAT LEVEL.                                     00960015
*              (3) PROCESSES ATTRIBUTES WHICH HAVE INFORMATION, OTHER   01020015
*        THAN THE SINGLE CODE BYTE, ASSOCIATED WITH THEM, AS LISTED     01080015
*        BELOW.                                                         01140015
*              CHARACTER AND BIT. FIXED STRING LENGTHS ARE CONVERTED    01200015
*        TO BINARY. ASTERISK LENGTHS ARE REPLACED BY A  SPECIAL         01260015
*        CODE BYTE.  ADJUSTABLE STRING LENGTHS ARE INSERTED IN A SECOND 01320015
*        FILE STATEMENT AND ARE REPLACED BY A POINTER TO THE STATEMENT. 01380015
*              PICTURE. A PICTURE TABLE ENTRY IS CREATED IN THE DICT-   01440015
*        IONARY AND INSERTED IN THE PICTURE CHAIN. THE PICTURE IN TEXT  01500015
*        IS REPLACED THE REFERENCE OF THE TABLE. SIMILAR TABLES ARE     01560015
*        COMMONED.                                                      01620015
*              ENTRY AND GENERIC. A COUNT OF THE ASSOCIATED BRACKETS    01680015
*        IS KEPT TO AVOID CONFUSION WITH FACTORED ATTRIBUTE BRACKETS.   01740015
*              DEFINED. THE BASE IDENTIFIER AND SUBSCRIPT LIST, IF ANY, 01800015
*        IS INSERTED IN A SECOND FILE STATEMENT. IN THE CASE OF DEFINED 01860015
*        WITH I-SUBS THE LIST IS CHECKED FOR ERRORS, EACH I-SUB IS      01920015
*        CONVERTED TO BINARY AND PLACED BEFORE ITS COEFFICIENT EXPRESS- 01980015
*        ION. TEXT IS REPLACED BY A POINTER TO THE SECOND FILE STATE-   02040015
*        MENT.                                                          02100015
*              POSITION. THE CONSTANT IS CONVERTED TO BINARY            02160015
*              LIKE. A BCD. DICTIONARY ENTRY IS CREATED FOR THE FOLLOW- 02220015
*        ING IDENTIFIER, WHICH IS REPLACED BY A POINTER TO THE ENTRY    02280015
*              ENVIRONMENT. THE FOLLOWING DICTIONARY REFERENCE, LEFT BY 02520015
*        READ-IN, IS SKIPPED.                                           02580015
*              DIMENSIONS, INITIAL, INITIAL CALL AND PRECISION.  THESE  02640015
*        ATTRIBUTES ARE PROCESSED IN THE SECOND MODULE 'IEMEJ'          02700015
*                                                                       02760015
*                                                                       02820015
*                                                                       02880015
*              ENTRY POINTS - ENTERED FROM COMPILER CONTROL AT IEMEI.   02940015
*        CCGS2 IS THE ENTRY POINT TO WHICH THE SECOND MODULE 'IEMEJ'    03000015
*        RETURNS CONTROL. THE ADDRESS OF THIS POINT IS PASSED TO        03060015
*        'IEMEJ' IN GENERAL REGISTER GRRR (EQU 14).                     03120015
*                                                                       03180015
*                                                                       03240015
*                                                                       03300015
*              INPUT - COMMUNICATIONS REGION, DICTIONARY AND TEXT.      03360015
*                                                                       03420015
*                                                                       03480015
*                                                                       03540015
*              OUTPUT - DICTIONARY, AS FOR INPUT BUT WITH PICTURE       03600015
*        TABLE ENTRIES, DICTIONARY ENTRIES ASSOCIATED WITH SECOND FILE  03660015
*        STATEMENTS, ENTRIES FOR LIKE AND POSSIBLY ERROR MESSAGE        03720019
*        ENTRIES, ADDED.                                                03780019
*                       TEXT,AS FOR INPUT BUT WITH DECLARE STATEMENTS   03840015
*        MODIFIED AND SECOND FILE STATEMENTS ADDED.                     03900015
*                       FACTORED ATTRIBUTE TABLE IN SCRATCH CORE.       03960015
*                                                                       04020015
*                                                                       04080015
*                                                                       04140015
*              EXTERNAL ROUTINES - (1) ZLOADW. USED FOR LOADING SECOND  04200015
*        MODULE 'IEMEJ'                                                 04260015
*                                  (2) ZTXTAB. CONVERTS SYMBOLIC TEXT   04320015
*        REFERENCE TO ABSOLUTE.                                         04380015
*                                  (3) ZALTER. USED FOR ALTERING STATUS 04440015
*        OF TEXT BLOCKS WHEN SCANNING FROM ONE TO THE NEXT.             04500015
*                                  (4) ZDRFAB. CONVERTS SYMBOLIC        04560015
*        DICTIONARY REFERENCES TO ABSOLUTE.  USED FOR EXAMINING DICT-   04620015
*        IONARY ENTRIES.                                                04680015
*                                  (5) ZUGC.  USED FOR GETTING SCRATCH  04740015
*        CORE FOR THE FACTORED ATTRIBUTE TABLE.                         04800015
*                                  (6) ZDICRF.  USED FOR MAKING DICT-   04860015
*        IONARY ENTRIES                                                 04920015
*                                  (7) ZUTXTC.  USED FOR GETTING MORE   04980015
*        TEXT BLOCKS IN THE EVENT OF THE SECOND FILE OVERFLOWING THE    05040015
*        PRESENT BLOCKS.                                                05100015
*                                  (8) ZUERR.  USED FOR CREATING ERROR  05160015
*        MESSAGE DICTIONARY ENTRIES.                                    05220015
*                                  (9) ZABORT.  USED FOR TERMINATING    05280015
*        COMPILER IN THE EVENT OF A TERMINAL ERROR.                     05340015
*                                  (10) RLSCTL.  USED FOR RETURNING     05400015
*              CONTROL TO COMPILER CONTROL.                             05460015
*                                                                       05520015
*                                  (11) CDDIMS.  ROUTINE IN 'IEMEJ'     05580015
*        USED FOR PROCESSING DIMENSIONS.                                05640015
*                                  (12) CDPREC.  ROUTINE IN 'IEMEJ'     05700015
*        USED FOR PROCESSING PRECISION.                                 05760015
*                                  (13) EJINIT.  ROUTINE IN 'IEMEJ'     05820015
*        USED FOR PROCESSING THE ATTRIBUTE INITIAL.                     05880015
*                                                                       05940015
*                                                                       06000015
*              EXITS, NORMAL - CCFIN IS THE NORMAL EXIT FROM THIS       06060015
*        FROM THIS MODULE, CONTROL IS RELEASED VIA ROUTINE RLSCTL.      06120015
*                                                                       06180015
*                                                                       06240015
*                                                                       06300015
*              EXITS, ABNORMAL - IN THE EVENT OF A TERMINAL ERROR       06360015
*        CONTROL IS RELEASED AT  CMPERR  VIA THE ROUTINE  ZABORT        06420015
*                                                                       06480015
*                                                                       06540015
*                                                                       06600015
*              TABLES/WORK AREAS - APART FROM THE FACTORED ATTRIBUTE    06660015
*        TABLE IN SCRATCH CORE, NO MAJOR WORK AREAS OR TABLES IS USED   06720015
*        BY THIS MODULE                                                 06780015
*                                                                       06840015
*                                                                       06900015
*                                                                       06960015
*              ATTRIBUTES - REUSABLE                                    07020015
*                                                                       07080015
*                                                                       07140015
*                                                                       07200015
*              NOTES - (1) THIS PHASE DOES NOT REQUIRE ANY MODIFICATION 07260015
*        AS A RESULT OF CHANGES IN INTERNAL REPRESENTATION OF EXTERNAL  07320015
*        GRAPHICS.                                                      07380015
*                      (2)  REGISTER USAGE - AS PER COMMENTS ON 'EQU'   07440015
*        CARDS BELOW.                                                   07500015
         EJECT                                                          07560015
IEMEI    START 0                                                        07620015
         USING *,GRBASE                                                 07680015
EJ       EQU   *+4096                  SET UP COMMUNICATIONS WITH       07740015
         USING EJ,GRB2               SECOND MODULE.                     07800015
         SPACE                                                          07860015
         DC    C'EI'                   IDENTIFICATION LETTERS           07920015
         EJECT                                                          07980015
*                       SYMBOLIC REGISTERS                              08040015
         SPACE 2                                                        08100015
GRBASE   EQU   9                       BASE OF THIS MODULE              08160015
GRB2     EQU   12                      BASE OF SECOND MODULE 'IEMEJ'    08220015
GRDIC    EQU   13                      BASE OF DICTIONARY               08280015
GRCC     EQU   11                      BASE OF COMPILER CONTROL         08340015
GRSP     EQU   1                       TEXT SCAN POINTER                08400015
GRPTR    EQU   6                       GENERAL POINTERS                 08460015
GRLR     EQU   2                       BRANCHING REGISTER.              08520015
GRRR     EQU   14                      RETURN REGISTER.                 08580015
*        EQU                                                            08640015
GR6      EQU   6                       *                                08700015
GR7      EQU   7                       *                                08760015
GR8      EQU   8                       *                                08820015
GRW      EQU   4                       * WORKING REGISTERS              08880015
GRY      EQU   10                      *                                08940015
GR10     EQU   10                      *                                09000015
         SPACE                                                          09060015
GRX      EQU   5                       WORKING REGISTER                 09120015
GRLTH    EQU   3                       CONTAINS VARIOUS LENGTHS         09180015
GRUNIT   EQU   15                      CONTAINS 1                       09240015
*                                      THE ABOVE THREE REGISTERS MUST   09300015
*                                    BE ODD SINCE THEY ARE USED FOR     09360015
*                                    BUMP POINTER WITH THE INSTRUCTION  09420015
*                                    'BXH'.                             09480015
         SPACE 10                                                       09540015
*                       COMPILER CONTROL OFFSETS                        09600015
         SPACE 2                                                        09660015
ZLOADW   EQU   X'24'                   LOAD AND WAIT                    09720015
ZTXTAB   EQU   X'54'                   SYMBOLIC TEXT REF. TO ABSOLUTE.  09780015
ZALTER   EQU   X'5C'                   ALTER TEXT BLOCK STATUS          09840015
ZDRFAB   EQU   X'34'                   SYMBOLIC DICT. REF. TO ABSOLUTE. 09900015
ZUGC     EQU   X'10'                   GET SCRATCH CORE                 09960015
ZDICRF   EQU   X'2C'                   MAKE DICT. ENTRY                 10020015
ZUTXTC   EQU   X'14'                   GET NEW TEXT BLOCK               10080015
ZUERR    EQU   X'30'                   ERROR MESSAGE PROCESSOR          10140015
ZABORT   EQU   X'20'                   ABORT                            10200015
RLSCTL   EQU   X'48'                   RELEASE CONTROL                  10260015
ZTXTRF   EQU   X'50'                   ABSOLUTE TEXT REF. TO SYMBOLIC.  10320015
ZCHAIN   EQU   X'58'                                                    10380015
         SPACE 5                                                        10440015
*              OFFSETS OF ROUTINES IN SECOND MODULE.                    10500015
         SPACE 2                                                        10560015
DIMO     EQU   2                       DIMENSION ROUTINE.               10620015
PREO     EQU   6                       PRECISION ROUTINE.               10680015
INITO    EQU   10                      INITIAL ROUTINE.                 10740015
         SPACE 3                                                        10800015
*              OFFSETS OF ROUTINES IN EH                                10860015
         SPACE                                                          10920015
EHPNTR   EQU   X'16'                   POINTER                          10980015
CTLPTR   EQU   EHPNTR+4                CONTROLLED(POINTER)              11040015
         SPACE 10                                                       11100015
*                       COMMUNICATIONS REGION OFFSETS                   11160015
         SPACE 2                                                        11220015
ZCOMM    EQU   X'130'                  START OF REGION EXCLUSIVELY FOR  11280015
*                                    DICTIONARY PHASES.                 11340015
PAR1     EQU   X'80'                   PARAMETERS FOR COMMUNICATION     11400015
PAR2     EQU   X'84'                 WITH COMPILER CONTROL.             11460015
PAR6     EQU   X'94'                                                    11520015
PAR5     EQU   X'90'                                                    11580015
ZMYNAM   EQU   X'70'                   SLOT FOR NAME OF MODULE.         11640015
ZSTAT    EQU   X'7E'                   STATEMENT NO. FOR ERROR EDITOR.  11700015
ZLSTXT   EQU   X'114'                  POINTS TO END OF TEXT            11760015
ZBLKSZ   EQU   X'108'                  CONTAINS SIZE OF TEXT BLOCK      11820015
ZTXTST   EQU   X'100'                  POINTS TO START OF TEXT.         11880015
         SPACE                                                          11940015
ZFATTB   EQU   ZCOMM+X'24'             POINTS TO FACTORED ATT. TABLE    12000015
ZSCRCH   EQU   ZCOMM+X'58'             COUNT OF SCRATCH BLOCKS          12060015
ZUPIC    EQU   ZCOMM+X'3C'             HEAD OF PICTURE CHAIN.           12120015
         SPACE 10                                                       12180015
*                       BRANCHING MNEMONICS                             12240015
         SPACE 10                                                       12300015
*                       INTERNAL CODES                                  12360015
         SPACE 2                                                        12420015
SLASH    EQU   X'77'                                                    12480015
AST      EQU   X'79'                   ASTERISK                         12540015
PLUS     EQU   X'75'                   +                                12600015
MINUS    EQU   X'73'                   -                                12660015
RVERSE   EQU   X'06'                   THIS CODE IS A BIT STRING WITH   12720015
*                                    ONES IN THE POSITIONS CORRESPOND-  12780015
*                                    ING TO THE BITS WHICH DIFFER IN    12840015
*                                    'PLUS' AND 'MINUS' ABOVE.          12900015
UNPL     EQU   X'7D'                   UNARY +                          12960015
UNMI     EQU   X'7B'                   UNARY -                          13020015
QUOTE    EQU   X'42'                                                    13080015
COMMA    EQU   X'41'                                                    13140015
PERIOD   EQU   X'46'                                                    13200015
LB       EQU   X'43'                   LEFT BRACKET                     13260015
RB       EQU   X'45'                   RIGHT BRACKET                    13320015
CLB      EQU   X'51'                   CURLY LEFT BRACKET               13380015
CRB      EQU   X'71'                   CURLY RIGHT BRACKET              13440015
SC       EQU   X'EF'                   SEMI-COLON                       13500015
FBR      EQU   X'F7'                   FIXED BINARY REAL MARKER         13560015
DC       EQU   X'F8'                   DECIMAL INTEGER MARKER.          13620015
ATM      EQU   X'C8'                   ATTRIBUTE MARKER.                13680015
SN       EQU   X'D0'                   STATEMENT NUMBER MARKER          13740015
RASK     EQU   X'FC'                   ASTERISK WITH RING.              13800015
EOP      EQU   X'EB'                   END OF PROGRAM MARKER.           13860015
EOB      EQU   X'ED'                   END OF BLOCK MARKER.             13920015
SUB      EQU   X'FE'                   I-SUB MARKER                     13980015
RAST     EQU   RASK                                                     14040015
         SPACE                                                          14100015
FSTATT   EQU   X'46'                   CODES FOR FIRST AND LAST (IN     14160015
LSTATT   EQU   X'8A'                 ORDER OF INTERNAL CODE) ATTRIBUTES 14220015
*                                    PROCESSED BY EI AND EJ.            14280015
         SPACE                                                          14340015
DIMS     EQU   X'4C'                   DIMENSIONS                       14400015
PREC1    EQU   X'46'                   PRECISION1                       14460015
PREC2    EQU   X'47'                   PRECISION2                       14520015
ENT      EQU   X'58'                   ENTRY                            14580015
CHAR     EQU   X'4B'                   CHARACTER                        14640015
BIT      EQU   X'4A'                   BIT                              14700015
DEF      EQU   X'6B'                   DEFINED                          14760015
GEN      EQU   X'59'                   GENERIC                          14820015
LIK      EQU   X'6A'                   LIKE                             14940015
ENV      EQU   X'8A'                 ENVIRONMENT                        15120015
PIC      EQU   X'49'                   PICTURE                          15180015
NPIC1    EQU   X'4E'                   NUMERIC PICTURE CODE PASSED BY   15240015
*                                    READ-IN                            15300015
NPIC2    EQU   X'7F'                   NUMERIC PICTURE CODE PASSED TO   15360015
*                                    DECLARE PASS TWO                   15420015
LABEL    EQU   X'4D'                                                    15480015
INIT     EQU   X'69'                   INITIAL                          15540015
POS      EQU   X'6F'                 POSITION                           15600015
RETNS    EQU   X'5F'                                                    15660015
UNWANT   EQU   2                                                        15720015
         SPACE 2                                                        15780015
BZ       EQU   8                       ZERO                             15840015
BM       EQU   4                       MINUS, OR MIXED                  15900015
BP       EQU   2                       POSITIVE                         15960015
BO       EQU   1                       ONES                             16020015
BNE      EQU   7                       NOT EQUAL                        16080015
BNL      EQU   11                      NOT LOW                          16140015
BNH      EQU   13                      NOT HIGH                         16200015
BNO      EQU   14                      NOT ALL ONES.               H361 16230019
BE       EQU   8                       EQUAL                            16260015
BL       EQU   4                       LOW                              16320015
BH       EQU   2                       HIGH                             16380015
B        EQU   15                      UNCONDITIONAL BRANCH             16440015
BNZ      EQU   7                       NOT ZERO                         16500015
         SPACE 10                                                       16560015
*                       OTHER CODES                                     16620015
         SPACE 2                                                        16680015
PROC     EQU   X'B3'                   CODE BYTE FOR PROC STATEMENT     16740015
BEG      EQU   X'B5'                   CODE BYTE FOR BEGIN STATEMENT    16800015
DECL     EQU   X'AD'                   CODE BYTE FOR DECLARE STATEMENT  16860015
ALLOC    EQU   X'81'                   CODE BYTE FOR ALLOCATE STATEMENT 16920015
ELSE     EQU   X'BD'                   ELSE STATEMENT.                  16980015
LSN      EQU   8                       DISPLACEMENT IN LABEL OF STATE-  17040015
*                                    MENT NUMBER                        17100015
ADF1     EQU   X'11'                                                    17160015
ADF2     EQU   X'12'                                                    17220015
ADF3     EQU   X'13'                                                    17280015
ZATTID   EQU   ZCOMM+8                 POINTER TO ATTRIBUTE TIDY AREA.  17340015
ZFLAG3   EQU   ZCOMM+18                FLAG SLOT                        17400015
ZSETFL   EQU   X'40'                   SETS FLAG                        17460015
         EJECT                                                          17520015
         MVC   ZMYNAM(2,GRDIC),IEMEI   SET 'MY NAME' SLOT.              17580015
         SPACE 2                                                        17640015
*              LOAD NEXT 4K BLOCK                                       17700015
         SPACE                                                          17760015
         LA    GRX,NXT4K                                                17820015
         ST    GRX,PAR1(0,GRDIC)                                        17880015
         SPACE                                                          17940015
         L     GRLR,ZLOADW(0,GRCC)                                      18000015
         BALR  GRRR,GRLR                                                18060015
         ST    GR10,EHBASE             STORE BASE OF EH                 18120015
         SPACE                                                          18180015
         L     GRB2,PAR1(0,GRDIC)                                       18240015
*              SET UP BASE REGISTER FOR NEXT 4K BLOCK                   18300015
         LA    GRX,CTXTRM              SET UP POINTER TO CTXTRM FOR USE 18360015
         ST    GRX,CCPTR3            BY 2ND 4K BLOCK                    18420015
         SPACE                                                          18480015
         SPACE                                                          18540015
         EJECT                                                          18600015
*                       TEXT CHAIN SCAN                                 18660015
*                                                                       18720015
*              FUNCTION.  THE FOLLOWING CODE, AS FAR AS CCGS1A, FINDS   18780015
*        THE NEXT DECLARE STATEMENT TO BE PROCESSED.                    18840015
*                                                                       18900015
*              ENTRY POINTS.  CCGS1, PROCESSES FIRST PROCEDURE STATE-   18960015
*        MENT                                                           19020015
*                             CCGS0, FINDS NEW PROC OR BEGIN STATEMENT  19080015
*                             CCGSE, FINDS NEW DECLARE STATEMENT.       19140015
*                                                                       19200015
*              EXTERNAL ROUTINES.  COMPILER CONTROL ROUTINES            19260015
*                                                                       19320015
*              EXITS NORMAL.  SEQUENTIAL FLOW.                          19380015
*                                                                       19440015
*              EXITS ERROR.  COMPILER ERROR DETECTED BETWEEN CC1SN      19500015
*        AND CCGS1A                                                     19560015
*                                                                       19620015
*              NOTES.  SYMNM1 CONTAINS SYMBOLIC NAME OF TEXT BLOCK OF   19680015
*        CURRENT PROC OR BEGIN STATEMENT. SYMNM2 THAT OF THE CURRENT    19740015
*        DECLARE STATEMENT. CCPTR1 AND CCPTR2 CONTAIN THE SYMBOLIC      19800015
*        POINTERS TO THE  NEXT PROC OR BEGIN STATEMENT AND DECLARE      19860015
*        STATEMENTS.                                                    19920015
         SPACE 3                                                        19980015
         L     GRSP,ZTXTST(0,GRDIC)    PICK UP START OF TEXT FROM       20040015
*                                    COMMUNICATIONS REGION.             20100015
         BC    B,CCGS1                 GO AND PROCESS FIRST STATEMENT   20160015
*                                    AS FOR OTHER MEMBERS OF PROC-BEGIN 20220015
*                                    CHAIN                              20280015
*              THE END OF A DECLARE CHAIN HAS BEEN REACHED.             20340015
         SPACE                                                          20400015
CCGS00   DS    0H                      FIRST, WE                   H236 20500001
         MVC   PAR1+1(1,GRDIC),SYMNM2+1 OTHERWISE MARK OLD BLOCK 'NOT   20700015
         MVI   PAR2+3(GRDIC),UNWANT  WANTED                             20760015
         SPACE                                                          20820015
         L     GRLR,ZALTER(0,GRCC)                                      20880015
         BALR  GRRR,GRLR                                                20940015
         SPACE                                                          21000015
         SPACE 3                                                        21060015
*              THE NEXT MEMBER OF THE PROCEDURE-BEGIN CHAIN MUST BE     21120015
*        FOUND.                                                         21180015
         SPACE                                                          21240015
CCGS0    L     GRSP,CCPTR1             PICK UP POINTER TO NEXT PROC OR  21300015
         C     GRSP,STOP             BEGIN STATEMENT. IS IT A STOPPER   21360015
         BC    BE,CCFIN                END OF PHASE IF SO.              21420015
         SPACE                                                          21960015
CCGS1    ST    GRSP,SYMNM1             SAVE SYMBOLIC NAME OF NEW BLOCK. 22020015
SAMEBL   ST    GRSP,SYMNM2             ALSO, INITIALISE NAME OF DECLARE 22080015
*                                    STATEMENTS BLOCK TO THAT OF ITS    22140015
*                                    CHAIN'S HEADER,                    22200015
         ST    GRSP,PAR1(0,GRDIC)      CONVERT POINTER TO ABSOLUTE.     22260015
         L     GRLR,ZTXTAB(0,GRCC)                                      22320015
         BALR  GRRR,GRLR                                                22380015
         SPACE                                                          22440015
         L     GRSP,PAR1(0,GRDIC)      SET UP SCAN POINTER.             22500015
         MVC   CCPTR1+1(3),7(GRSP)     SAVE SYMBOLIC POINTER TO NEXT    22560015
*                                    MEMBER OF PROC-BEGIN CHAIN.        22620015
         MVC   CCPTR2+1(3),10(GRSP)  AND OF DECLARE CHAIN.              22680015
         SPACE 2                                                        22740015
*              THE DICTIONARY ENTRY ASSOCIATED WITH SECOND FILE STATE-  22800015
*        MENTS WILL NOW BE STARTED  IN DICENT.                          22860015
         SPACE                                                          22920015
         MVC   DICENT+5(2),1(GRSP)     MOVE IN POINTER TO STATEMENTS    22980015
*                                    ENTRY TYPE 1.                      23040015
         MVC   DICENT+10(2),5(GRSP)    MOVE IN BLOCK IDENTIFIER.        23100015
         MVC   OPTBYT(1),3(GRSP)       SAVE OPTIONS BYTE                23160015
*              WE MAY NOW 'UNWANT' THE BLOCK CONTAINING THE PROC   H236 23167001
*              OR BEGIN STATEMENT.                                 H236 23174001
*                                                                  H236 23181001
         MVC   PAR1+1(1,GRDIC),SYMNM1+1                            H236 23188001
         MVI   PAR2+3(GRDIC),UNWANT                                H236 23195001
         L     GRLR,ZALTER(0,GRCC)                                 H236 23202001
         BALR  GRRR,GRLR                                           H236 23209001
         SPACE 5                                                        23220015
CCGSE    L     GRSP,CCPTR2             PICK UP POINTER TO NEXT DECLARE  23280015
         C     GRSP,STOP             STATEMENT. IS IT A STOPPER.        23340015
         BC    BE,CCGS00               IF SO, GO TO GET NEXT CHAIN.     23400015
         SPACE                                                          23460015
         CLC   CCPTR2+1(1),SYMNM2+1    OTHERWISE, IS OLD DECLARE        23520015
         BC    BE,SMEBLK             STATEMENT IN SAME BLOCK AS NEW     23580015
*                                    IF NOT,                       H236 23670001
         MVC   PAR1+1(1,GRDIC),SYMNM2+1  MARK OLD  'NOT                 23760015
         MVI   PAR2+3(GRDIC),UNWANT  WANTED'                            23820015
         L     GRLR,ZALTER(0,GRCC)                                      23880015
         BALR  GRRR,GRLR                                                23940015
         SPACE                                                          24000015
         ST    GRSP,SYMNM2             SAVE SYMBOLIC NAME OF NEW BLOCK. 24060015
         SPACE                                                          24120015
SMEBLK   ST    GRSP,PAR1(0,GRDIC)      CONVER POINTER TO ABSOLUTE       24180015
         L     GRLR,ZTXTAB(0,GRCC)                                      24240015
         BALR  GRRR,GRLR                                                24300015
         SPACE                                                          24360015
         L     GRSP,PAR1(0,GRDIC)      SET GRSP TO POINT TO DECLARE     24420015
*                                    STATEMENT.                         24480015
         SPACE                                                          24540015
*              DICENT IS NOW CONTINUED                                  24600015
         CLI   0(GRSP),SN                                               24660015
         BC    BE,CC1SN                                                 24720015
         MVC   PAR1+2(2,GRDIC),1(GRSP)  IF NOT SN THEN BYTES 2 AND 3    24780015
         L     GRLR,ZDRFAB(0,GRCC)    POINT TO A LABEL IN WHICH THE     24840015
         BALR  GRRR,GRLR             STATEMENT NO. CAN BE FOUND         24900015
         L     GRX,PAR1(0,GRDIC)                                        24960015
         MVC   DICENT+3(2),LSN(GRX)    MOVE IN STAT NO. FROM LABEL      25020015
         BC    B,*+10                                                   25080015
*                                    OR                                 25140015
CC1SN    MVC   DICENT+3(2),1(GRSP)     MOVE IN STAT NO. FROM SOURCE     25200015
         SPACE                                                          25260015
         SPACE                                                          25320015
         XC    CCPL(2),CCPL            SET PARENTHESIS LEVEL ZERO IN    25380015
*                                    ANTICIPATION OF FACTOR ROUTINES.   25440015
         MVC   CCPTR2+1(3),5(GRSP)     SAVE SYMBOLIC POINTER TO NEXT    25500015
*                                    DECLARE STATEMENT                  25560015
         MVI   IEMEI+2,DECL            SET DECLARE FLAG                 25620015
         SPACE                                                          25680015
         CLI   4(GRSP),DECL            IS IT A DECLARE STATEMENT        25740015
         BC    BE,CCGS1A                                                25800015
         CLI   4(GRSP),ALLOC           OR AN ALLOCATE STATEMENT         25860015
         BC    BNE,CMPER1              IF NOT, COMPILER ERROR.          25920015
         MVI   IEMEI+2,ALLOC           SET ALLOCATE FLAG                25980015
         SPACE                                                          26040015
         LA    GRSP,3(0,GRSP)          BUMP POINTER BY LENGTH OF        26100015
*                                    EXTRA CHAIN.                       26160015
CCGS1A   LA    GRSP,7(0,GRSP)          BUMP POINTER TO ONE SHORT OF     26220015
*                                    STAT OF DECLARATION LIST           26280015
         EJECT                                                          26340015
*                       DECLARE STATEMENT TEXT SCAN.                    26400015
*                                                                       26460015
*              FUNCTION.  SCANS ITEMS IN TEXT A BRANCHES TO APPROPRIATE 26520015
*        ROUTINES FOR PROCESSING THEM.                                  26580015
*                                                                       26640015
*              ENTRY POINTS.  CCGS2A OR CCGS2 DEPENDING ON WHETHER THE  26700015
*        SCAN POINTER NEED BE BUMPED OR NOT                             26760015
*                                                                       26820015
*              EXTERNAL ROUTINES. NONE                                  26880015
*                                                                       26940015
*              EXITS NORMAL.  FOLLOWING TESTS FOR CONSTANT, ATTRIBUTE,  27000015
*        BRACKET, OR SEMI-COLON.                                        27060015
*                                                                       27120015
*              EXITS ERROR.  COMPILER ERROR. SCAN FINDS SOMETHING OUT-  27180015
*        SIDE LIMITED SET OF POSSIBILITIES.                             27240015
         SPACE 3                                                        27300015
CCGS2A   AR    GRSP,GRUNIT             BUMP SCAN POINTER                27360015
CCGS2    CLI   0(GRSP),X'20'           TEST FOR IDENTIFIER LENGTH.      27420015
         BC    BNL,CCGS2B              IF NOT, GO TO NEXT TEXT          27480015
         SPACE                                                          27540015
         CLI   0(GRSP),0               OTHERWISE, CHECK THAT IT IS NOT  27600015
         BC    BE,CMPER2             ZERO. IF SO, COMPILER ERROR.       27660015
         SPACE                                                          27720015
         SR    GRLTH,GRLTH                                              27780015
         IC    GRLTH,0(0,GRSP)         PICK UP IDENTIFIER LENGTH AND    27840015
         BXH   GRSP,GRLTH,CCGS2A     SKIP IDENTIFIER.                   27900015
CCGS2B   CLI   0(GRSP),DC              TEST FOR CONSTANT MARKER         27960015
         BC    BE,CCONST                                                28020015
         CLI   0(GRSP),ATM                      ATTRIBUTE MARKER        28080015
         BC    BE,CCGSAT                                                28140015
         CLI   0(GRSP),LB                       LEFT BRACKET            28200015
         BC    BE,CCGSLB                                                28260015
         CLI   0(GRSP),RB                       RIGHT BRACKET           28320015
         BC    BE,CCGSRB                                                28380015
         CLI   0(GRSP),COMMA                    COMMA                   28440015
         BC    BE,CCGS2A                                                28500015
         CLI   0(GRSP),PERIOD                   PERIOD                  28560015
         BC    BE,CCGS2A                                                28620015
         CLI   0(GRSP),PT                                               28680015
         BC    BE,CCGS2A                                                28740015
         CLI   0(GRSP),SC                       SEMI-COLON.             28800015
         BC    BE,CCGSE                GO TO GET NEXT STATEMENT.        28860015
         CLI   0(GRSP),ELSE            IS IT AN ELSE CODE AT END OF     28920015
         BC    BE,CCGSE              ALLOCATE STATEMENT. IF SO, TREAT   28980015
*                                    AS SEMI-COLON.                     29040015
         CLI   0(GRSP),EOB             IS THIS THE END OF A TEXT BLOCK  29100015
         BC    BE,NXTBLK               THEN GET THE NEXT ONE.           29120015
         CLI   IEMEI+2,ALLOC           IS THIS AN ALLOCATE STMT ?       29140015
         BC    BNE,CMPER3              NO; COMPILER ERROR CODE 23. H361 29170019
*                                    (UNRECOGNISABLE BYTE IN DCL STMT.) 29200015
         TM    0(GRSP),X'FD'           IS IT CHAR/BIT CONSTANT     H361 29202019
         BC    BNO,CCGS2A              NO, SO CONTINUE SCAN.       H361 29204019
         MVC   STGLTH+2(2),1(GRSP)     YES, PICK UP 2-BYTE LENGTH, H361 29206019
         A     GRSP,STGLTH             ADD IT TO POINTER.          H361 29208019
         LA    GRSP,3(0,GRSP)          BUMP POINTER BY 3.          H361 29210019
         BC    B,CCGS2                                             H361 29212019
         SPACE                                                          29220015
*              PREPARE TO GET NEXT BLOCK.                               29280015
         SPACE                                                          29340015
NXTBLK   DS    0H                                                       29370015
         MVI   PAR1(GRDIC),0           CLEAR TOP BYTE OF PAR1 SO THAT   29400015
*                                    NEW BLOCK WILL BE MARKED BUSY      29460015
         MVC   PAR1+1(1,GRDIC),SYMNM2+1 SYMBOLIC NAME OF CURRENT BLOCK  29520015
*                                    INTO PAR1.                         29580015
         MVI   PAR2+3(GRDIC),UNWANT    IF NOT, CHANGE STATUS BYTE TO    29820015
*                                    'NOT WANTED'.                      29880015
         SPACE                                                          29940015
         L     GRLR,ZCHAIN(0,GRCC)                                      30000015
         BALR  GRRR,GRLR                                                30060015
         MVC   SYMNM2+1(1),PAR1+1(GRDIC) SAVE SYMBOLIC NAME OF BLOCK    30120015
         SPACE                                                          30180015
         L     GRSP,PAR2(0,GRDIC)      PICK UP ABSOLUTE POINTER TO      30240015
*                                    NEXT BLOCK.                        30300015
         BC    B,CCGS2                                                  30360015
         SPACE 4                                                        30363015
*              CONSTANT INTEGER.  WE MUST DETERMINE WHAT THIS IS FROM   30366015
*              ITS CONTEXT.                                             30369015
         SPACE                                                          30372015
CCONST   DS    0H                                                       30375015
         CLI   IEMEI+2,ALLOC           IS THIS AN ALLOCATE STMT ?       30378015
         BC    BNE,CCGSCM              NO. THEN GO TO PROCESS THIS      30381015
*                                    STRUCTURE LEVEL.                   30384015
         SR    GR6,GR6                 USE GR6 FOR THE SCAN AHEAD       30387015
         IC    GR6,1(GRSP)             TO                               30390015
         LA    GR6,2(GR6,GRSP)         SKIP THE CONSTANT.               30393015
         CLI   0(GR6),X'20'            IF FOLLOWED BY AN IDENTIFIER     30396015
         BC    BL,CCGSCM               LENGTH, OR                       30399015
         CLI   0(GR6),LB               A LEFT BRACKET,                  30402015
         BC    BE,CCGSCM               IT'S A STRUCTURE LEVEL.          30405015
         LR    GRSP,GR6                ELSE BUMP GRSP OVER THIS         30408015
         BC    B,CCGS2               INTEGER, WHICH MUST BE IN A        30411015
*                                    DIMENSION EXPRESSION IN AN         30414015
*                                    ALLOCATE CLAUSE.                   30417015
         EJECT                                                          30420015
*                       STRUCTURE LEVEL PROCESSOR.                186/7 30480019
*                                                                       30540015
*              FUNCTION.  SETS UP REGISTERS FOR BRANCH TO ROUTINE       30600019
*        'TZRBN' TO CHECK THE STRUCTURE LEVEL AND REPLACES THE          30660019
*        LEVEL IN TEXT BY THE BINARY VALUE RETURNED.                    30720019
*                                                                       30780015
*              ENTRY POINTS.  CCGSM, NORMAL ENTRY POINT TO WHICH        30840015
*        CONTROL IS PASSED WHEN THE GENERAL SCAN OF TEXT FINDS A        30900015
*        CONSTANT MARKER.                                               30960015
*                             CCGRUB, POINT TO WHICH CONTROL RETURNS    31020015
*        FROM ERROR ROUTINE 'TZERR'.                                    31080019
*                                                                       31140015
*              EXTERNAL ROUTINE.  'TZERR' REDUCES STRUCTURE LEVEL       31180019
*        TO 255 IF THIS HAS BEEN EXCEEDED AND GENERATES                 31220019
*        CORRESPONDING ERROR MESSAGE. IT RETURNS, IN GRW, THE           31260019
*        BINARY VALUE TO BE INSERTED INTO THE TEXT.                     31300019
*                                                                       31380015
*              EXITS-NORMAL.  BRANCHES EITHER TO FACTORED LEFT BRACKET  31440015
*        ROUTINE, IF LEVEL IS FOLLOWED BY A LEFT BRACKET, OR RETURNS TO 31500015
*        TEXT SCAN.                                                     31560015
*                                                                       31620015
*              EXITS ERROR. N/A.                                        31680015
*                                                                       31740015
*              TABLES/WORK AREAS.  SAVE AREA TZSAV FOR REGISTER         31800019
*        GRLTH, CONTAINING THE LENGTH-1 OF THE LEVEL VALUE.             31860019
*                                                                       31920015
*              NOTES. N/A                                               31980015
         SPACE 5                                                        32040015
CCGBLK   XC    2(0,GRSP),2(GRSP)       CLEAR TEXT BYTES           186/7 32090019
CCGSCM   MVI   CCSTR,X'FF'             SET STRUCTURE MARKER ON    186/7 32140019
         SR    GRLTH,GRLTH                                        186/7 32190019
         IC    GRLTH,1(0,GRSP)                                    186/7 32240019
         SR    GRLTH,GRUNIT            LENGTH-1 OF STRUC. LEVEL   186/7 32290019
         ST    GRLTH,TZSAV             SAVE GRLTH BEFORE BRANCH   186/7 32340019
*                                      TO ROUTINE 'TZRBN'.        186/7 32390019
         LA    GRPTR,2(0,GRSP)         POINT AT BYTE AFTER THAT   186/7 32440019
*                                      CONTAINING LGTH. OF CONST. 186/7 32490019
         LH    GRW,TWO                 LOAD MAX. LENGTH ALLOWED-1 186/7 32540019
         LH    GR7,MAXLVL              LOAD MAX LEVEL VALUE       186/7 32590019
         LA    GRX,MES2                LOAD ERROR MESSAGE ADDR.   186/7 32640019
         BAL   GRLR,TZRBN              GO TO CHECK LEVEL VALUE.   186/7 32690019
*                                      ON RETURN, GRW CONTAINS    186/7 32740019
*                                      VALID LEVEL NO. IN BINARY  186/7 32790019
         SPACE                                                          32840019
CCGRUB   STC   GRW,1(0,GRSP)           INSERT IT INTO THE TEXT    186/7 32890019
         L     GRLTH,TZSAV             RELOAD LGTH. OF CONST.-1   186/7 32940019
         EX    GRLTH,CCGBLK            CLEAR OUT DEC. CONSTANT    186/7 32990019
         MVI   0(GRSP),FBR            CHANGE CONST. MKR. TO FIXED 186/7 33040019
         LA    GRSP,3(GRLTH,GRSP)      SKIP CONSTANT              186/7 33090019
         CLI   0(GRSP),LB              IS IT FOLLOWED BY (.             33240015
         BC    BNE,CCGS2                                                33300015
         STC   GRW,CCSTL               SAVE LVL. FOR FACTORED ATT.186/7 33360019
         LA    GRLTH,3(0,GRLTH)        COMPUTE POINTER TO BINARY  186/7 33420019
         LCR   GRLTH,GRLTH             STRUCTURE LEVEL, IN GRLTH. 186/7 33480019
         AR    GRLTH,GRSP                                         186/7 33540019
         XC    0(2,GRLTH),0(GRLTH)    ERASE STRUC. LVL. FROM TEXT 186/7 33600019
         BC    B,CCFLP                                                  33660015
         EJECT                                                          33720015
*              FACTORED ATTRIBUTE LEFT BRACKET PROCESSOR                33780015
*                                                                       33840015
*              FUNCTION/OPERATION.  THIS ROUTINE SETS UP 7 BYTE SLOTS   33900015
*        IN SCRATCH CORE.  EACH SLOT CORRESPONDS TO A LEVEL OF          33960015
*        FACTORING.  THE STRUCTURE LEVEL FOR THE CORRESPONDING FACTOR   34020015
*        LEVEL IS INSERTED IN THE FIRST BYTE.  BYTES 2-4 ARE USED BY    34080015
*        THE FACTORED ATTRIBUTE RIGHT BRACKET PROCESSOR. BYTES 5-7      34140015
*        ARE MADE TO POINT TO THE LAST SLOT WITH ZERO IN BYTES 2-4      34200015
*        (I.E. THE CONTAINING LEVEL SLOT), OR, IN THE FIRST CASE, ARE   34260015
*        MADE A STOPPER.   IN ORDER TO LIFT THE LIMIT OF ONLY      H236 34300001
*        73 FACTORING BRACKETS (1 SCRATCH ALLOCATION), A SCRATCH   H236 34340001
*        TEXT BLOCK NOW HOLDS THE FACTORED ATTRIBUTE TABLE.        H236 34380001
*                                                                       34440015
*              ENTRY POINTS.  CCGSLB, WHERE IT IS CHECKED THAT THE      34500015
*        BRACKET IS NOT WITHIN AN ENTRY ATTRIBUTE LIST, AND CCFLP, THE  34560015
*        ENTRY POINT USED WHEN THE BRACKET IMMEDIATELY FOLLOWS A        34620015
*        STRUCTURE CONSTANT AND THUS CANNOT BE WITHIN AN ENTRY OR       34680015
*        GENERIC LIST.                                                  34740015
*                                                                       34800015
*              EXTERNAL ROUTINE.  ZUGC, FOR GETTING SCRATCH CORE.       34860015
*                                                                       34920015
*              EXITS-NORMAL.  FOLLOWING CCFLPC. RETURNS TO TEXT SCAN.   34980015
*                                                                       35040015
*              EXITS, ERROR.  NONE.                                     35100015
*                                                                       35160015
*              TABLES/WORK AREAS.  FACTORED ATTRIBUTE TABLE AS DESCRIB- 35220015
*        ED UNDER FUNCTION.                                             35280015
*                                                                       35340015
*              NOTES. N/A.                                              35400015
         SPACE 3                                                        35460015
CCGSLB   CLI   IEMEI+2,ALLOC           ARE WE IN AN ALLOCATE STATEMENT  35520015
         BC    BE,CCGS2A               IF SO IGNORE SET OR IN CLAUSE    35580015
         CH    GRUNIT,GNTCNT           IS GENERIC BRACKET COUNT         35640015
         BC    BH,CCFLP          ZERO. IF SO, GO TO PROCESS BRACKET AS  35700015
*                                FACTORED ATTRIBUTE BRACKET.            35760015
         LR    GRX,GRUNIT          OTHERWISE, BUMP GENERIC AND ENTRY    35820015
         AH    GRX,GNTCNT        BRACKET COUNT.                         35880015
         STH   GRX,GNTCNT                                               35940015
         BXH   GRSP,GRUNIT,CCGS2                                        36000015
CCFLP    LA    GRX,7(0,0)              WILL BE USED THROUGHOUT ROUTINE  36060015
         MVI   0(GRSP),CLB             REPLACE ( BY CURLY (             36120015
         SPACE                                                          36180015
         CLI   FACT,0                  IS THIS THE FIRST FACTORED       36240015
         MVI   FACT,X'FF'            ATTRIBUTE BRACKET                  36300015
         BC    BNE,CCFLPA              BRANCH IF NOT                    36360015
         SPACE                                                          36420015
         SR    GRLR,GRLR               NO CHAINING.                H236 36460001
         ST    GRLR,PAR2(0,GRDIC)         JUST -                   H236 36500001
         L     GRLR,ZUTXTC(0,GRCC)     GET A TEXT BLOCK,           H236 36540001
         BALR  GRRR,GRLR             MARKING IT BUSY.              H236 36580001
*                                                                  H236 36620001
         MVC   ZSCRCH(4,GRDIC),PAR1(GRDIC)  SAVE REF OF BLOCK,     H236 36660001
         L     GRPTR,PAR2(0,GRDIC)     POINT AT IT BY GRPTR, AND   H236 36700001
         ST    GRPTR,ZFATTB(0,GRDIC) SET UP SLOTS IN ZCOMM,        H236 36740001
         SR    GRPTR,GRX             BACK UP ONE ENTRY,            H236 36780001
         ST    GRPTR,CCPTR           INIT CURRENT PTR SLOT,        H236 36820001
         AR    GRPTR,GRX             RESET TO START, AND           H236 36860001
         A     GRPTR,ZBLKSZ(0,GRDIC)  CALCULATE END OF TEXT BLOCK. H236 36900001
         ST    GRPTR,CCEND                                         H236 36940001
*                                      AS WE DONT CHAIN, WE HAVE   H236 36980001
*                                    8 SPARE BYTES TO COPE WITH    H236 37020001
*                                    END CONDITIONS.               H236 37060001
         SPACE                                                          37260015
CCFLPA   L     GRPTR,CCPTR           POINT TO LAST ENTRY                37320015
         AR    GRPTR,GRX               UPDATE TO THIS ENTRY             37380015
         ST    GRPTR,CCPTR                                              37440015
         LR    GRW,GRPTR                                                37500015
         C     GRPTR,CCEND             IS THIS THE END OF A BLOCK       37560015
         BC    BNL,FCTERR              YES.  TOO MANY FACTOR LEVELS H91 37860017
*                                 BRANCH TO INDICATE TABLE OVERFLOW H91 38160017
         SPACE                                                          38460015
NUFCOR   CLC   CCPL(2),ZERO          IS PAREN LEVEL ZERO. I.E. IS       38520015
         BC    BNE,CCFLPB            THIS THE START OG A NEW LIST.      38580015
*                                      BR ANCH IF NOT                   38640015
         MVC   4(3,GRW),FF             SET UP STOPPER IF NEW LIST       38700015
         BC    B,CCFLPC                                                 38760015
         SPACE                                                          38820015
CCFLPB   SR    GRPTR,GRX             SCAN BACK THROUGH TABLE FOR LAST   38880015
         CLC   1(3,GRPTR),ZERO         SLOT WITHOUT POINTER TO AN ATTR- 38940015
*                                    BUTE LIST. THIS IS THE SLOT FOR    39000015
*                                    THE CONTAINING LEVEL               39060015
         BC    BNE,CCFLPB                                               39120015
         SPACE                                                          39180015
         ST    GRPTR,CFW                                                39240015
         MVC   4(3,GRW),CFW+1        POINT TO CONTAINING LEVEL'S SLOT   39300015
         ST    GRPTR,CFW                                                39360015
         MVC   4(3,GRW),CFW+1          SET UP 2ND POINTER IN NEW SLOT   39420015
         SPACE                                                          39480015
CCFLPC   LH    GRX,CCPL                                                 39540015
         AR    GRX,GRUNIT                                               39600015
         STH   GRX,CCPL                INCREASE PARENTHESIS LEVEL       39660015
         MVC   0(1,GRW),CCSTL          MOVE STRUCTURE   LEVEL INTO NEW  39720015
         MVI   CCSTL,0                                                  39780015
         XC    1(3,GRW),1(GRW)       SLOT. CLEAR NEXT THREE BYTES AND   39840015
         BXH   GRSP,GRUNIT,CCGS2                                        39900015
         SPACE                                                          39960015
         EJECT                                                          40020015
*              FACTORED ATTRIBUTE RIGHT BRACKET PROCESSOR               40080015
*                                                                       40140015
*              FUNCTION/OPERATION.  THIS ROUTINE INSERTS THE POINTERS   40200015
*        TO THE ATTRIBUTE LISTS IN TEXT IN THE APPROPRIATE SLOTS IN     40260015
*        THE FACTORED ATTRIBUTE TABLE SET UP BY THE LEFT BRACKET        40320015
*        PROCESSOR                                                      40380015
*                                                                       40440015
*              ENTRY POINTS.  CCGSRB, BRANCHED TO, FROM THE GENERAL     40500015
*        TEXT SCAN                                                      40560015
*                                                                       40620015
*              EXTERNAL ROUTINES.  ZTXTRF, CONVERTS TEXT POINTER TO     40680015
*        ATTRIBUTE LIST TO SYMBOLIC.                                    40740015
*                                                                       40800015
*              EXITS, NORMAL.  JUST BEFORE CCFRA, CONTROL IS RETURNED   40860015
*        TO THE TEXT SCAN                                               40920015
*                                                                       40980015
*              EXITS, ERROR. NONE                                       41040015
*                                                                       41100015
*              TABLES/WORK AREAS.  FACTORED ATTRIBUTE TABLE DESCRIBEB   41160015
*        IN THE FACTORED ATTRIBUTE LEFT BRACKET PROCESSOR.              41220015
*                                                                       41280015
*              NOTES. N/A                                               41340015
         SPACE 3                                                        41400015
CCGSRB   CLI   IEMEI+2,ALLOC           ARE WE IN AN ALLOCATE STATEMENT  41460015
         BC    BE,CCGS2A               IF SO IGNORE SET OR IN CLAUSE    41520015
         CH    GRUNIT,GNTCNT           IS GENERIC BRACKET COUNT         41580015
         BC    BH,CCFRP              COUNT. IF SO, THIS IS A FACTORING  41640015
*                                    BRACKET                            41700015
         LH    GRX,GNTCNT              OTHERWISE, REDUCE GENERIC AND    41760015
         SR    GRX,GRUNIT            ENTRY BRACKET COUNT.               41820015
         STH   GRX,GNTCNT                                               41880015
         BXH   GRSP,GRUNIT,CCGS2       RETURN TO TEXT SCAN.             41940015
         SPACE                                                          42000015
CCFRP    LA    GRX,7(0,0)              WILL BE REQUIRED LATER IN THE    42060015
*                                      ROUTINE                          42120015
         SPACE                                                          42180015
         MVI   0(GRSP),CRB             PUT CURLY RIGHT BRACKET IN TEXT  42240015
         SPACE                                                          42300015
         L     GRPTR,CCPTR                                              42360015
CCFRZ    CLC   1(3,GRPTR),ZERO                                          42420015
         BC    BNE,CCFRA                                                42480015
         AR    GRSP,GRUNIT                                              42540015
         ST    GRSP,PAR2(0,GRDIC)      CONVERT POINTER TO SYMBOLIC      42600015
         MVC   PAR1(4,GRDIC),SYMNM2                                     42660015
         L     GRLR,ZTXTRF(0,GRCC)                                      42720015
         BALR  GRRR,GRLR                                                42780015
         MVC   1(3,GRPTR),PAR1+1(GRDIC)  SET POINTER IN SLOT TO         42840015
*                                    ATTRIBUTE IN TEXT                  42900015
         LH    GRW,CCPL                                                 42960015
         SR    GRW,GRUNIT                                               43020015
         STH   GRW,CCPL                REDUCE PARENTHESIS LEVEL.        43080015
         BC    B,CCGS2                 RETURN                           43140015
         SPACE 2                                                        43200015
CCFRA    CLC   1(3,GRPTR),FE           IS IT THE START OF A BLOCK       43260015
         BC    BE,CCFRX                IF SO GO AND PICK UP POINTER     43320015
         SR    GRPTR,GRX               OTHERWISE REDUCE POINTER BY 7    43380015
         BC    B,CCFRZ                 AND GO TO EXAMINE PREVIOUS SLOT  43440015
         SPACE                                                          43500015
CCFRX    MVC   CFW+1(3),4(GRPTR)       SET GRPTR TO POINT TO LAST ENTRY 43560015
         L     GRPTR,CFW             OF PREVIOUS BLOCK AND              43620015
         BC    B,CCFRZ                 GO TO EXAMINE IT                 43680015
         EJECT                                                          43740015
*              ATTRIBUTE ROUTINE SELECTOR.                              43800015
*                                                                       43860015
*              FUNCTION/OPERATION.  THIS SEGMENT OF CODE TRANSLATES     43920015
*        THE ATTRIBUTE FOLLOWING THE ATTRIBUTE MARKER (POINTED AT BY    43980015
*        GRSP) TO GIVE AN OFFSET TO THE BRANCH TO THE APPROPRIATE       44040015
*        ROUTINE.  IN ORDER TO REDUCE THE SIZE OF THE TRANSLATE TABLE,  44100015
*        A CHECK IS FIRST MADE TO SEE THAT THE ATTRIBUTE LIES WITHIN    44160015
*        THE RANGE PROCESSED BY THIS PHASE.                             44220015
*                                                                       44280015
*              ENTRY POINT. CCGSAT,  DIRECT BRANCH FROM TEXT SCAN TO    44340015
*        THIS POINT.                                                    44400015
*                                                                       44460015
*              EXTERNAL ROUTINES. NONE                                  44520015
*                                                                       44580015
*              EXITS, NORMAL.  ONE FOR EACH ATTRIBUTE PROCESSED BY THIS 44640015
*        MODULE, TO THE APPROPRIATE ROUTINE, AND ONE FOR THOSE WHICH    44700015
*        ARE NOT, BACK TO THE TEXT SCAN.                                44760015
*                                                                       44820015
*              EXITS, ERROR - NONE.                                     44880015
*                                                                       44940015
*              TABLES/WORK AREAS - TRANSLATE TABLE ATTRIB.  THE FIRST   45000015
*        BYTE OF THIS TABLE CORRESPONDS TO THE FIRST ATTRIBUTE PROCESS- 45060015
*        ED, NOT TO AN ARGUMENT OF ZERO.                                45120015
*                                                                       45180015
*              NOTES - N/A                                              45240015
         SPACE 5                                                        45300015
CCGSAT   AR    GRSP,GRUNIT                                              45360015
         CLI   0(GRSP),FSTATT          IS ATTRIBUTE WITHIN THE INTERNAL 45420015
         BC    BL,CCGS2A             CODE RANGE OF THE ATTRIBUTES PRO-  45480015
         CLI   0(GRSP),LSTATT        CESSED IN THIS PHASE.              45540015
         BC    BH,CCGS2A               CONTINUE SCAN, IF NOT.           45600015
         SR    2,2                     OTHERWISE -                      45660015
         L     GR10,EHBASE             RESTORE BASE OF EH               45720015
         LA    GRRR,CCGS2              SET UP RETURN LINK               45780015
         TRT   0(1,GRSP),ATTRIB-FSTATT TRANSLATE ATTRIBUTE              45840015
         BC    B,*+4(2)                BRANCH TO APPROPRIATE ROUTINE    45900015
O00      BC    B,CCGS2A                NOT INTERESTED IN THIS ATTRIBUTE 45960015
O04      BC    B,CCDEF                 DEFINED                          46020015
O08      BC    B,NPICT                 NUMERIC PICTURE                  46080017
O0C      BC    B,CATPIC                CHARACTER PICTURE                46140017
O10      BC    B,LIKE                  LIKE                             46200015
O14      BC    B,GENTRY                GENERIC, ENTRY OR RETURNS        46260015
O18      BC    B,CHABIT                CHARACTER OR BIT                 46320015
O1C      BC    B,POSIT                 POSITION                         46380015
O20      BC    B,AREA                  AREA                             46440015
O24      BC    B,ENVMNT                ENVIRONMENT                      46500015
O28      BC    B,DIMO(0,GRB2)          DIMENSIONS                       46560019
O2C      BC    B,PREO(0,GRB2)          PRECISION                        46620019
O30      BC    B,INITO(0,GRB2)         INITIAL/INITIAL CALL             46680019
O34      BC    B,EHPNTR(0,GR10)        OFFSET                           46740019
O38      BC    B,CTLPTR(0,GR10)        CONTROLLED(POINTER)              46800019
O3C      CLI   1(GRSP),LB              LABEL                            46860019
         BC    BE,INITO(0,GRB2)        ..                               46980015
         BC    B,CCGS2A                ..                               47040015
         EJECT                                                          47100015
*              GENERIC AND ENTRY ROUTINE                                47160015
*                                                                       47220015
*              THIS ROUTINE BUMPS GENERIC AND ENTRY BRACKET COUNT       47280015
*        FOR THE BRACKET IMMEDIATELY FOLLOWING THE ATTRIBUTE.           47340015
         SPACE 2                                                        47400015
GENTRY   CLI   1(GRSP),LB                                               47460015
         BC    BNE,CCGS2A                                               47520015
         LR    GRX,GRUNIT                                               47580015
         AH    GRX,GNTCNT                                               47640015
         STH   GRX,GNTCNT                                               47700015
         BXH   GRSP,GRUNIT,CCGS2A                                       47760015
         EJECT                                                          47820015
*                       DEFINED ATTRIBUTE PROCESSOR.              186/7 47920019
*                                                                       48060015
*        FUNCTION - MAKES SECOND FILE STATEMENTS FOR EACH OF THE        48120015
*                   THREE TYPES OF DEFINING                             48180015
*                                                                       48240015
*              (1)  SIMPLY DEFINED                                      48300015
*                       'IDV' CODE 11                                   48360015
*              (2)  ARRAY DEFINED                                       48420015
*                       'IDV' CODE 12                                   48480015
*              (3)  I-SUB DEFINED                                       48540015
*                       'IDV' CODE 13                                   48600015
*                                                                       48660015
*              ENTRY POINT.  CCDEF, NORMAL ENTRY TO WHICH CONTROL       48680019
*        IS PASSED FROM THE ATTRIBUTE ROUTINE SELECTOR.                 48700019
*                            DEFX9, POINT TO WHICH CONTROL              48720019
*        RETURNS FROM ERROR ROUTINE 'TZERR'.                            48740019
*                                                                       48760019
*              EXTERNAL ROUTINES.  TZRBN REDUCES I-SUB VALUE TO         48780019
*        32 IF THIS HAS BEEN EXCEEDED AND GENERATES THE                 48800019
*        CORRESPONDING ERROR MESSAGE. IT RETURNS, IN GRW, THE           48820019
*        BINARY VALUE TO BE INSERTED INTO THE TEXT.                     48840019
*                                  CTXTRM, TO FIND ROOM IN SECOND FILE. 48860019
*                                                                       48880019
*              EXIT NORMAL.  FOLLOWING ERASER. RETURNS TO TEXT SCAN.    48900019
*              EXIT ERROR.   COMPILER ERROR COMPER5 DETECTED AFTER      48920019
*        CCDEFO AND COMPILER ERROR COMPER3 DETECTED AFTER DEFX3B.       48940019
*                                                                       48960019
*              TABLES/WORK AREAS.  SAVE AREA TZSAV FOR REGISTERS        48980019
*        GRLTH,GRW AND GRX.                                             49000019
         SPACE 5                                                        49020019
CCDEF    LR    GRX,GRSP                SAVE CODE BYTE ADDRESS           49140015
* TOP 3 BYTES OF GRLTH NOT USED. MUST BE LEFT WITH ZEROES IN THEM.      49200015
         SR    GRLTH,GRLTH                                              49260015
         MVC   ZSTAT+2(2,GRDIC),DICENT+3                                49320015
CCDEF0   LA    GRSP,2(0,GRSP)                                           49380015
         CLI   0(GRSP),X'1F'           TEST FOR AN IDENTIFIER           49440015
         BC    BH,CMPER5               COMPILER ERROR IF NOT            49500015
         IC    GRLTH,0(GRSP)           SKIP OVER THE IDENTIFIER         49560015
         AR    GRSP,GRLTH                                               49620015
         CLI   1(GRSP),PERIOD          WHICH MAY BE QUALIFIED           49680015
         BC    BE,CCDEF0                                                49740015
         CLI   1(GRSP),PT              OR POINTER QUALIFIED             49800015
         BC    BE,CCDEF0                                                49860015
         SPACE 3                                                        49920015
* CHECK FOR SUBSCRIPTS                                                  49980015
CCDEF1   CLI   1(GRSP),LB              SIMPLY DEFINED (TYPE 1)          50040015
         BC    BE,CCDEF2                                                50100015
         MVI   DEFSN+7,ADF1                                             50160015
         BC    B,DEFX1                                                  50220015
         SPACE                                                          50280015
CCDEF2   CLI   1(GRX),X'FF'            ARRAY  DEFINED (TYPE 2)          50340015
         BC    BE,CCDEF3                                                50400015
         MVI   DEFSN+7,ADF2                                             50460015
         BC    B,DEFX1                                                  50520015
         SPACE                                                          50580015
CCDEF3   MVI   DEFSN+7,ADF3            I-SUB  DEFINED (TYPE 3)          50640015
         SPACE                                                          50700015
DEFX1    MVC   DEFSN+3(1),DICENT+12    PREFIX OPTIONS.                  50760015
         MVI   DICENT+9,ADF1                                            50820015
         LA    GRW,12(0,0)                                              50880015
         ST    GRW,PAR2(0,GRDIC)                                        50940015
         LA    GRW,DICENT              MAKE SECOND FILE                 51000015
         ST    GRW,PAR1(0,GRDIC)       DICTIONARY ENTRY                 51060015
         L     GRLR,ZDICRF(0,GRCC)                                      51120015
         BALR  GRRR,GRLR                                                51180015
         MVC   DEFSN+1(2),PAR1+2(GRDIC)                                 51240015
         CLI   DEFSN+7,ADF1            IF THERE ARE NO SUBSCRIPTS       51300015
         BC    BE,DEFX5                SKIP THE NEXT SECTION OF CODE    51360015
         SPACE                                                          51420015
* WE MUST NOW FIND THE LENGTH OF THE SECOND FILE STATEMENT              51480015
         LR    GRW,GRUNIT                                               51540015
         AR    GRSP,GRUNIT                                              51600015
DEFX2    AR    GRSP,GRUNIT             GRW IS FOR PARENTHESIS COUNTING  51660015
         CLI   0(GRSP),LB                                               51720015
         BC    BNE,DEFX3               LEFT BRACKET                     51780015
         AR    GRW,GRUNIT              ADD 1                            51840015
         BC    B,DEFX2                                                  51900015
         SPACE                                                          51960015
DEFX3    CLI   0(GRSP),RB                                               52020015
         BC    BNE,DEFX4               RIGHT BRACKET                    52080015
         SR    GRW,GRUNIT              SUBTRACT 1                       52140015
         BC    BNZ,DEFX2               CONTINUE SCANNING EXPRESSION.    52149015
         SPACE 2                                                        52158015
*              THE ZERO LEVEL ')' HAS BEEN ENCOUNTERED. AS THE BASE     52167015
*        MAY BE A QUALIFIED DIMENSIONED STRUCTURE ELEMENT, WE MAY NOW   52176015
*        HAVE TO SKIP OVER THE BASE IDENTIFIER.                         52185015
         SPACE                                                          52194015
DEFX3A   DS    0H                                                       52203015
         CLI   1(GRSP),PERIOD          QUALIFIED ?                      52212015
         BC    BE,DEFX3B               BRANCH IF SO.                    52221015
         CLI   1(GRSP),PT              POINTER QUALIFIED ?              52230015
         BC    BNE,DEFX5               NO. THEN GO TO NEXT SECTION.     52239015
DEFX3B   DS    0H                                                       52248015
         LA    GRSP,2(GRSP)            POINT AT IDENTIFIER LENGTH       52257015
         CLI   0(GRSP),X'1F'           IS IT VALID ?                    52266015
         BC    BH,CMPER3               BRANCH IF NOT                    52275015
         IC    GRLTH,0(GRSP)           ELSE -                           52284015
         AR    GRSP,GRLTH              SKIP OVER IDENTIFIER             52293015
         BC    B,DEFX3A              AND CHECK IF QUALIFIED.            52302015
         SPACE                                                          52320015
DEFX4    CLI   0(GRSP),CHARS           SKIP OVER CHARACTER STRINGS      52380015
         BC    BNE,DEFX8                                                52440015
         MVC   DEFR(2),1(GRSP)         IN CASE THEY CONTAIN             52500015
         AH    GRSP,DEFR                                                52560015
         LA    GRSP,2(GRSP)            PARENTHESES                      52620015
         BC    B,DEFX2                                                  52680015
         SPACE                                                          52740015
DEFX8    CLI   0(GRSP),SUB             TEST FOR I-SUBS                  52800015
         BC    BNE,DEFX2                                                52860015
* I-SUB MUST BE CONVERTED TO BINARY                                     52920015
         IC    GRLTH,1(GRSP)           LENGTH OF I-SUB IN GRLTH         52980015
         SR    GRLTH,GRUNIT                                             53040015
         STM   GRLTH,GRX,TZSAV         STORE REGS. BEFORE BRANCH  186/7 53100019
*                                      TO ROUTINE 'TZRBN'.        186/7 53160019
         LA    GRPTR,2(0,GRSP)         POINT AT BYTE AFTER THAT   186/7 53220019
*                                      CONTAINING LGTH. OF CONST. 186/7 53280019
         LR    GRW,GRUNIT              LOAD MAX. LENGTH ALLOWED-1 186/7 53340019
         LH    GR7,SUB32               LOAD MAX. ISUB VALUE       186/7 53400019
         LA    GRX,MES6                LOAD ERROR MESSAGE ADDR.   186/7 53460019
         BAL   GRLR,TZRBN              GO TO CHECK ISUB VALUE.    186/7 53520019
*                                      ON RETURN, GRW CONTAINS A  186/7 53580019
*                                      VALID ISUB VALUE IN BINARY 186/7 53640019
         SPACE                                                          53700019
DEFX9    STC   GRW,1(GRSP)             INSERT IT INTO THE TEXT    186/7 53760019
         LM    GRLTH,GRX,TZSAV         RELOAD REGS. USED BY TZRBN 186/7 53820019
         MVI   2(GRSP),BLANK                                            53940015
         LTR   GRLTH,GRLTH             FILL THE REMAINDER WITH          54000015
         BC    BZ,DEFXA                BLANKS FOR NOW             186/7 54040019
         SR    GRLTH,GRUNIT          ONE BLANK IS ALREADY THERE         54090015
         EX    GRLTH,DEFBLK          SO MOVE IN THE REST, AND           54120015
         AR    GRLTH,GRUNIT          RESTORE GRLTH FOR THE BUMP.        54150015
DEFXA    LA    GRSP,2(GRLTH,GRSP)      UPDATE SCAN POINTER        186/7 54190019
         BC    B,DEFX2                                                  54240015
         EJECT                                                          54300015
* AND ALL THE I-SUBS HAVE BEEN CONVERTED TO BINARY                      54360015
* GRSP NOW POINTS AT THE LAST CHARACTER OF THE DEFINED BASE.            54420015
         SPACE                                                          54480015
DEFX5    LR    GRLTH,GRSP                                               54540015
         SR    GRLTH,GRX                                                54600015
         LA    GRLTH,11(GRLTH)         TOTAL LENGTH IN GRLTH            54660015
* MAKE SURE WE HAVE ENOUGH ROOM FOR THE SECOND FILE TEXT ENTRY          54720015
         BAL   GR6,CTXTRM                                               54780015
* ON RETURN VIA GR6, GR7 CONTAINS THE SYMBOLIC ADDRESS OF THE SN2       54840015
*                AND GR8 CONTAINS THE ABSOLUTE ADDRESS OF THE SN2.      54900015
* HAVING REQUESTED THE MAXIMUM SIZE REQUIRED FOR THE 2ND FILE           54960015
* STATEMENT, WE MUST NOW TRANSFER THE STATEMENT FROM THE TEXT           55020015
* INTO THE SECOND FILE.                                                 55080015
* IF THERE WERE ANY I-SUBS THEN THE BLANKS MUST NOT BE TRANSFERRED.     55140015
* IN THIS CASE WE MOVE IT A PIECE AT A TIME IN WHICH CASE               55200015
* THE STATEMENT WILL NOT BE AS LONG AS THE LENGTH REQUESTED.            55260015
* GRSC IS USED TO SCAN FOR BLANKS                                       55320015
* GR7 POINTS AT THE END OF THE STATEMENT FOR THE BXLE INSTRUCTION       55380015
* GR6 INCREMENTS THE SCAN POINTER        FOR THE BXLE INSTRUCTION       55440015
* GR8 IS THE OUTPUT POINTER                                             55500015
* GRW POINTS AT THE SEGMENT OF THE EXPRESSION BEING SCANNED             55560015
*        AND IS UPDATED EVERY TIME A PORTION IS MOVED                   55620015
* GRLTH CONTAINS THE LENGTH OF THE SEGMENT TO BE MOVED( NOT LENGTH-1 )  55680015
         ST    GR7,DEFR2                                                55740015
         ST    GR8,DEFR                SAVE ADDRESS OF SN2              55800015
         MVC   0(10,GR8),DEFSN         INSERT STANDARD PART             55860015
         LA    GR8,10(GR8)                                              55920015
         LR    GR7,GRSP                POINT GR7 AT END OF EXPRESSION   55980015
         LA    GRSP,2(GRX)                                              56040015
         LR    GR6,GRUNIT              SET UP INCREMENT REGISTER        56100015
         LR    GRW,GRSP                SET START-OF-TEXT POINTER        56160015
DEFX6    CLI   0(GRSP),BLANK                                            56220015
         BC    BE,DEFSUB                                                56280015
         BXLE  GRSP,GR6,DEFX6                                           56340015
DEFSUB   LR    GRLTH,GRSP                                               56400015
         SR    GRLTH,GRW                                                56460015
DEF256   CH    GRLTH,T56                                                56520015
         BC    BL,DEFMV                                                 56580015
         MVC   0(256,GR8),0(GRW)                                        56640015
         AH    GR8,T56                                                  56700015
         AH    GRW,T56                                                  56760015
         SH    GRLTH,T56                                                56820015
         BC    B,DEF256                                                 56880015
DEFMV    EX    GRLTH,DEFMOV            MOVE PORTION OF TEXT             56940015
         AR    GR8,GRLTH               UPDATE OUTPUT POINTER            57000015
         CR    GRSP,GR7                                                 57060015
         BC    BH,DEFX12               IF MORE TEXT TO FOLLOW           57120015
DEFX7    AR    GRSP,GRUNIT                                              57180015
         CLI   0(GRSP),BLANK           SKIP OVER BLANKS                 57240015
         BC    BE,DEFX7                                                 57300015
         LR    GRW,GRSP                RESET START-OF-TEXT POINTER      57360015
         BC    B,DEFX6                 AND CONTINUE SCANNING            57420015
         SPACE                                                          57480015
DEFX12   MVI   0(GR8),RB                                                57540015
         MVI   1(GR8),SC               COMPLETE THE STATEMENT           57600015
         LA    GR8,2(GR8)              UPDATE OUTPUT POINTER            57660015
         S     GR8,DEFR                                                 57720015
         A     GR8,DEFR2                                                57780015
         ST    GR8,ZLSTXT(GRDIC)       UPDATE LAST-TEXT SLOT            57840015
         SR    GRSP,GRUNIT                                              57900015
         MVC   1(3,GRX),DEFR2+1        INSERT TEXT REFERENCE OF SN2     57960015
         LA    GRLTH,4(GRX)            INTO TEXT                        58020015
         SPACE                                                          58080015
ERASER   CR    GRLTH,GRSP              ERADICATE REMAINDER OF TEXT      58140015
         BC    BH,CCGS2A               IF ANY                           58200015
         LR    0,GRUNIT                REGS 0 + 1 FOR INCREMENT + INDEX 58260015
ERASE0   MVI   0(GRLTH),X'00'                                           58320015
         BXLE  GRLTH,0,ERASE0                                           58380015
         BC    B,CCGS2A                                                 58440015
         SPACE 3                                                        58500015
DEFBLK   MVC   3(0,GRSP),2(GRSP)                                        58620015
DEFMOV   MVC   0(0,GR8),0(GRW)                                          58680015
PT       EQU   X'62'                                                    58740015
CHARS    EQU   X'FD'                   CHARACTER STRING CODE BYTE       58800015
BLANK    EQU   X'40'                                                    58860015
         EJECT                                                          58920015
*                       POSITION PROCESSOR.                       186/7 58930019
*                                                                       58940019
*              FUNCTION.  SETS UP REGISTERS FOR BRANCH TO ROUTINE       58950019
*        'TZRBN' TO CHECK THE POSITION CONSTANT AND REPLACES            58960019
*        THE POSITION CONSTANT IN TEXT BY BINARY VALUE RETURNED.        58970019
*                                                                       58980019
*              ENTRY POINTS.  POSIT, NORMAL ENTRY TO WHICH CONTROL      58990019
*        IS PASSED FROM THE ATTRIBUTE ROUTINE SELECTOR.                 59000019
*                            POSITA, POINT TO WHICH CONTROL             59010019
*        RETURNS FROM ERROR ROUTINE 'TZERR'.                            59020019
*                                                                       59030019
*              EXTERNAL ROUTINE.  TZRBN REDUCES A POS. CONSTANT         59040019
*        TO 32,767 IF THIS HAS BEEN EXCEEDED AND GENERATES              59050019
*        THE CORRESPONDING ERROR MESSAGE. IT RETURNS, IN GRW,           59060019
*        THE BINARY VALUE TO BE INSERTED INTO THE TEXT.                 59070019
*                                                                       59080019
*              EXIT NORMAL.  BACK TO THE TEXT SCAN.                     59090019
*              EXIT ERROR.   NONE.                                      59100019
*                                                                       59110019
*              TABLES/WORK AREAS.  SAVE AREA TZSAV FOR REGISTERS        59120019
*        GRLTH AND GRW.                                                 59130019
         SPACE 3                                                        59140019
POSCLE   XC    3(0,GRSP),3(GRSP)                                        59340015
POSIT    SR    GRLTH,GRLTH                                              59400015
         IC    GRLTH,3(0,GRSP)                                    186/7 59440019
         SR    GRLTH,GRUNIT            LENGTH-1 OF POS. CONST.    186/7 59480019
         STM   GRLTH,GRW,TZSAV         SAVE REGS. BEFORE BRANCH   186/7 59520019
*                                      TO ROUTINE 'TZRBN'.        186/7 59560019
         LA    GRPTR,4(0,GRSP)         POINT AT BYTE AFTER THAT   186/7 59600019
*                                      CONTAINING LGTH. OF CONST. 186/7 59640019
         LH    GRW,FOUR                LOAD MAX. LENGTH ALLOWED-1 186/7 59680019
         L     GR7,OFFFF               LOAD MAX. POS CONST. VALUE 186/7 59720019
         LA    GRX,MES10               LOAD ERROR MESSAGE ADDR.   186/7 59760019
         BAL   GRLR,TZRBN              GO TO CHECK POS. CONSTANT  186/7 59800019
*                                      ON RETURN, GRW CONTAINS A  186/7 59840019
*                                      VALID POS CONSTANT IN BIN. 186/7 59880019
         SPACE                                                          60000015
POSITA   STH   GRW,CCFW+2              REPLACE ( AND CONSTANT MARKER    60060015
         MVC   1(2,GRSP),CCFW+2      IN TEXT WITH BINARY CONSTANT       60120015
         LM    GRLTH,GRW,TZSAV         RELOAD REGS. USED BY TZRBN 186/7 60150019
         SPACE                                                          60180015
         LA    GRLTH,2(0,GRLTH)                                         60240015
         EX    GRLTH,POSCLE            CLEAR EXCESS BYTES FROM TEXT.    60300015
         LA    GRSP,4(GRLTH,GRSP)      UPDATE SCAN POINTER              60360015
         BC    B,CCGS2                 RETURN.                          60420015
         EJECT                                                          60480015
*              ROUTINE CTXTRM                                           60540015
         SPACE                                                          60600015
*              THIS ROUTINE TESTS FOR SUFFICIENT ROOM IN TEXT BLOCK FOR 60660015
*        SECOND FILE ENTRY. IF INSUFFICIENT, A NEW TEST BLOCK IS        60720015
*        OBTAINED. GRLTH CONTAINS LENGTH OF ENTRY TO BE MADE (EXCLUDING 60780015
*        FOLLOWING E.O.P MARKER). GR8 IS RETURNED CONTAINING ABSOLUTE   60840015
*        POINTER TO WHERE ENTRY SHOULD BE MADE. GR7 IS RETURNED         60900015
*        CONTAINING THE CORRESPONDING SYMBOLIC POINTER. GR615 THE LINK  60960015
*        REGISTER.                                                      61020015
         SPACE                                                          61080015
CTXTRM   L     GR7,ZLSTXT(0,GRDIC)     CONVERT SYMBOLIC POINTER TO LAST 61140015
         ST    GR7,PAR1(0,GRDIC)     TEXT TO ABSOLUTE                   61200015
         L     GRLR,ZTXTAB(0,GRCC)                                      61260015
         BALR  GRRR,GRLR                                                61320015
         SPACE                                                          61380015
         L     GR8,PAR1(0,GRDIC)       ABSOLUTE POINTER INTO GR8.       61440015
         LH    GR7,ZLSTXT+2(0,GRDIC)   PICK UP OFFSET OF LAST TEXT BYTE 61500015
         AR    GR7,GRLTH             OFFSET. ADD ENTRY LENGTH AND COM.  61560015
         C     GR7,ZBLKSZ(0,GRDIC)   PARE WITH BLOCK SIZE. IF LOW, THEN 61620015
         L     GR7,ZLSTXT(0,GRDIC)   THERE IS ROOM.                     61680015
         BCR   BL,GR6                                                   61740015
         MVI   0(GR8),EOB              OTHERWISE, INSERT END OF BLOCK   61800015
*                                    MARKER.                            61860015
         ST    GR7,PAR1(0,GRDIC)       GET NEW BLOCK. CHAIN IT IN AND   61920015
         LA    GR7,X'80'(0,0)                                           61980015
         CLC   SYMNM2+1(1),ZLSTXT+1(GRDIC)                              62040015
         BC    BE,*+8                                                   62100015
         LA    GR7,2(0,GR7)                                             62160015
         ST    GR7,PAR2(0,GRDIC)                                        62220015
         L     GRLR,ZUTXTC(0,GRCC)                                      62280015
         BALR  GRRR,GRLR                                                62340015
         SPACE                                                          62400015
         L     GR7,PAR1(0,GRDIC)       SYMBOLIC REFERENCE INTO GR7      62460015
         L     GR8,PAR2(0,GRDIC)       ABSOLUTE REFERENCE INTO GR8      62520015
         BCR   B,GR6                                                    62580015
         EJECT                                                          62640015
*              PICTURE ROUTINE - CATPIC                                 62700015
*              FUNCTION/OPERATION - THIS ROUTINE PROCESSES NUMERIC AND  62760015
*        CHARACTER PICTURES.  THE PICTURE IS INSERTED IN A DICTIONARY   62820015
*        ENTRY, WHICH IS CHAINED TO PREVIOUS PICTURE ENTRIES, AND IS    62880015
*        REPLACED IN TEXT BY A POINTER TO THE ENTRY.  SIMILAR PICTURES  62940015
*        SHARE THE SAME ENTRY.                                          63000015
*                                                                       63060015
*        ENTRY POINTS - NPICT FOR NUMERIC PICTURES                      63120015
*                       CATPIC FOR CHARACTER PICTURES.                  63180015
*                                                                       63240015
*              EXTERNAL ROUTINES - ZDICRF, FOR MAKING THE ENTRY         63300015
*                                  ZDABRF, FOR FINDING PREVIOUS ENTRIES 63360015
*                                                                       63420015
*              EXITS, NORMAL - BEFORE CP6A                              63480015
*                                                                       63540015
*              EXITS, ERROR - THIRD INSTRUCTION.                        63600015
*                                                                       63660015
*              TABLES/ WORK AREAS - N/A                                 63720015
*                                                                       63780015
*              NOTES N/A                                                63840015
         SPACE 3                                                        63900015
CATPIC   MVI   0(GRSP),X'7F'           CHANGE CHAR PICT CODE BYTE       63960017
*                                    FOR DECLARE PASS TWO.              64020015
NPICT    CLI   3(GRSP),QUOTE           CHECK PICTURE IS PRECEDED        64080017
         BC    BNE,CMPER6            BY A QUOTE MARK. COMPILER ERROR IF 64140015
*                                  NOT.                                 64200015
         SPACE                                                          64260015
         MVC   CFW+2(2),1(GRSP)                                         64320015
         LH    GRLTH,CFW+2             PICK UP PICTURE LENGTH IN GRLTH  64380015
         LA    GRY,9(0,0)              BACK-DATE GRSP TO AS MANY BYTES  64440015
         SR    GRSP,GRY              BEFORE THE PICTURE AS IS THE START 64500015
         LA    GRX,ZUPIC-1(0,GRDIC)  OF A PICTURE ENTRY IN THE DICT.    64560015
CP3      ST    GRX,LSTPIC              RESET LSTPIC - INITIALLY TO      64620015
*                                    POINT 3 BYTES SHORT OF HEAD OF     64680015
*                                    PICTURE CHAIN - LATER 3 BYTES      64740015
*                                    SHORT OF CHAIN IN PICTURE ENTRY    64800015
         MVC   PAR1+2(2,GRDIC),3(GRX)  PICK UP POINTER TO NEXT PICTURE  64860015
         LH    GRX,PAR1+2(0,GRDIC)                                      64920015
         LTR   GRX,GRX                 IS IT A STOPPER                  64980015
         BC    BE,CP5                  IF SO GO AND MAKE PICTURE ENTRY  65040015
CP4      L     GRLR,ZDRFAB(0,GRCC)     CONVERT POINTER TO ABSOLUTE      65100015
         BALR  GRRR,GRLR                                                65160015
         SPACE                                                          65220015
         L     GRX,PAR1(0,GRDIC)                                        65280015
         SPACE                                                          65340015
         CLC   11(2,GRX),10(GRSP)      COMPARE LENGTHS                  65400015
         BC    BNE,CP3                 IF EQUAL GO AND TRY NEXT PICTURE 65460015
*                                    IN TABLE                           65520015
CP8      LA    GRY,256(0,GRLTH)        INITIALISE GRY TO 256+LENGTH     65580015
         ST    GRSP,CFW                SAVE ABSOLUTE POINTERS TO TEXT   65640015
         ST    GRX,CFW2              AND DICTIONARY                     65700015
         SPACE                                                          65760015
CP8A     SH    GRY,T56                                                  65820015
         CH    GRY,T56                 ARE THERE MORE THAN 256 BYTES    65880015
         BC    BNH,CP10              TO BE COMPARED                     65940015
         CLC   13(256,GRX),13(GRSP)    IF SO COMPARE LENGTHS OF 256     66000015
         LA    GRX,256(0,GRX)                                           66060015
         LA    GRSP,256(0,GRSP)                                         66120015
         BC    BE,CP8A                 IF THESE LENGTHS ARE EQUAL       66180015
*                                    GO TO TEST NEXT                    66240015
CP9A     L     GRX,CFW2                OTHERWISE, RESET POINTERS AND    66300015
         L     GRSP,CFW              GO TO EXAMINE NEXT PICTURE IN      66360015
         BC    B,CP3                 TABLE.                             66420015
         SPACE 2                                                        66480015
CP10     SR    GRY,GRUNIT              THE REMAINING BYTES WILL NOW BE  66540015
         BC    BL,*+12               COMPARED. CHECK THERE ARE SOME. IF 66600015
         EX    GRY,CP9               NOT THEN THE PICTURES ARE EQUAL    66660015
         BC    BNE,CP9A                                                 66720015
         L     GRX,CFW2                RESET POINTERS                   66780015
         L     GRSP,CFW                                                 66840015
         BC    B,CP10A                 GO TO ERASE PICTURE AND SET UP   66900015
*                                    POINTER IN TEXT                    66960015
         SPACE 2                                                        67020015
CP5      ST    GRSP,PAR1(0,GRDIC)      THERE IS NO IDENTICAL PREVIOUS   67080015
         LA    GRY,13(0,GRLTH)       PICTURE, SO A NEW ENTRY IS CREATED 67140015
         ST    GRY,PAR2(0,GRDIC)       THE PICTURE IS MOVED IN WITH 13  67200015
         L     GRLR,ZDICRF(0,GRCC)   PRECEDING BYTES WHICH WILL BE      67260015
         BALR  GRRR,GRLR             OVERWRITTEN WITH STANDARD INFORM-  67320015
*                                    -ATION                             67380015
         L     GRX,LSTPIC              PICK UP POINTER TO LAST PICTURE  67440015
         MVC   3(2,GRX),PAR1+2(GRDIC)  SET POINTER IN LAST PICTURE TO   67500015
*                                    POINT TO NEW ONE.                  67560015
         SPACE                                                          67620015
         L     GRLR,ZDRFAB(0,GRCC)     CONVERT TO NEW ENTRY TO          67680015
         BALR  GRRR,GRLR             ABSOLUTE.                          67740015
         SPACE                                                          67800015
         L     GRX,PAR1(0,GRDIC)                                        67860015
         MVI   0(GRX),X'C8'            MOVE IN CODE BYTE                67920015
         STH   GRY,CFW+2               MOVE IN LENGTH                   67980015
         MVC   1(2,GRX),CFW+2                                           68040015
         MVI   3(GRX),X'00'            CLEAR NEXT 8 BYTES               68100015
         MVC   4(7,GRX),3(GRX)                                          68160015
         MVC   6(2,GRX),DICENT+3       MOVE STATEMENT NO INTO THE    I5 68180016
*                                    STATIC STORAGE OFFSET SLOT.     I5 68200016
         MVC   11(2,GRX),10(GRSP)                                       68220015
         SPACE 2                                                        68280015
*              THE PICTURE WILL NOW BE ERASED FROM SOURCE.              68340015
         SPACE                                                          68400015
CP10A    L     GRX,LSTPIC              PICK UP SYMBOLIC REFERENCE OF    68460015
         MVC   10(2,GRSP),3(GRX)     PICTURE FROM PREVIOUS ENTRY AND    68520015
*                                    PUT IT IN SOURCE TEXT.             68580015
         CH    GRLTH,T56               ARE THERE MORE THAN 256 BYTES    68640015
         BC    BL,CP6                TO BE ERASED.                      68700015
         SPACE                                                          68760015
CP7      MVI   12(GRSP),X'00'          CLEAR 256 BYTES                  68820015
         MVC   13(255,GRSP),12(GRSP)                                    68880015
         SPACE                                                          68940015
         SH    GRLTH,T56                                                69000015
         AH    GRSP,T56                                                 69060015
         CH    GRLTH,T56               ARE THERE MORE THAN 256 BYTES    69120015
         BC    BNL,CP7               LEFT TO ERASE. IF SO GO AND ERASE  69180015
*                                    THEM. OTHERWISE -                  69240015
         SPACE                                                          69300015
CP6      MVI   12(GRSP),X'00'          CLEAR REMAINDER FROM SOURCE      69360015
         LTR   GRLTH,GRLTH             CHECK THAT THERE ARE SOME TO BE  69420015
         BC    BL,*+8                CLEARED.                           69480015
         EX    GRLTH,CP6A                                               69540015
         SPACE                                                          69600015
         LA    GRSP,14(GRLTH,GRSP)     BUMP SCAN POINTER TO BYTE BEYOND 69660015
         BC    B,CCGS2                 PICTURE BEFORE RETURNING         69720015
         SPACE                                                          69780015
CP6A     MVC   13(0,GRSP),12(GRSP)     CLEAR CORE - EXECUTED ABOVE      69840015
         SPACE 2                                                        69900015
CP9      CLC   13(0,GRX),13(GRSP)      COMPARE PICTURES - EXECUTED      69960015
*                                    ABOVE                              70020015
CFW2     DS    1F                                                       70080015
         EJECT                                                          70140015
*                       CHAR OR BIT  ROUTINE.                     186/7 70200019
         SPACE                                                          70260015
*              FUNCTION/OPERATION -                                     70320015
*              THIS ROUTINE PROCESSES ATTRIBUTES CHARACTER AND BIT.     70380015
*        IF THE LENGTH IS AN EXPRESSION AN ASSIGNMENT STATEMENT IS      70440015
*        INSERTED IN THE SECOND FILE AND A POINTER TO IT IS PLACED IN   70500015
*        THE TEXT. IF THE LENGTH IS A CONSTANT IT IS CONVERTED TO       70560015
*        BINARY. IF THE LENGTH IS * A CODE BYTE IS PUT IN THE TEXT TO   70620015
*        SIGNIFY THIS.                                                  70680015
*                                                                       70740015
*              ENTRY POINT -  CHABIT, NORMAL ENTRY TO WHICH CONTROL     70760019
*        IS PASSED FROM THE ATTRIBUTE ROUTINE SELECTOR.                 70780019
*                             CHCONB, POINT TO WHICH CONTROL IS         70800019
*        PASSED FROM THE ERROR ROUTINE 'TZERR'.                         70820019
*                                                                       70860015
*              EXTERNAL ROUTINES - CTXTRM, TO FIND ROOM IN SECOND FILE  70920015
*                                  ZDICRF - TO MAKE DICTIONARY ENTRY    70980015
*        ASSOCIATED WITH SECOND FILE STATEMENTS.                        71000019
*                                  TZRBN, REDUCES STRING LENGTH         71020019
*        CONSTANT TO 32,767 IF THIS HAS BEEN EXCEEDED AND               71040019
*        GENERATES THE CORRESPONDING ERROR MESSAGE. IT RETURNS,         71060019
*        IN GRW, THE BINARY VALUE TO BE INSERTED INTO THE TEXT.         71080019
*                                                                       71100015
*              EXITS, NORMAL - CHRSK, CHCONS, CHBEND.                   71160015
*                                                                       71220015
*              EXITS, ERROR - FOLLOWING CHCONS - STRING TOO LARGE.      71280015
*                                                                       71340015
*              TABLES/WORK AREAS - SAVE AREA TZSAV FOR REGISTERS        71380019
*        GRLTH AND GRW.                                                 71420019
*                                                                       71460015
*              NOTES - N/A                                              71520015
         SPACE 5                                                        71580015
*              AREA HAS ALMOST IDENTICAL SYNTAX AS CHAR, AND WILL BE    71590015
*              PROCESSED BY THIS ROUTINE.                               71600015
         SPACE 2                                                        71610015
AREA     DS    0H                                                       71620015
         MVI   CHFLG1,X'FF'            INDICATE USE BY AREA             71630015
         BC    B,CHASK               AND BRANCH TO CHECK FOR *.         71640015
         SPACE                                                          71650015
CHABIT   DS    0H                                                       71660015
         MVI   CHFLG1,X'00'            INDICATE USE BY CHAR OR BIT      71670015
         SPACE                                                          71700015
CHASK    DS    0H                                                       71740015
         CLI   2(GRSP),RASK            ASTERISK LENGTH ?                71780015
         BC    BE,CHRSK                                                 71820015
         SPACE                                                          71880015
CHADC    DS    0H                                                       71900015
         SR    GRLTH,GRLTH             ZERO LENGTH REG.           186/7 71920019
         CLI   2(GRSP),DC                                               71940015
         BC    BNE,CHB1                                                 72000015
         SPACE                                                          72010015
*              WE ARE NOW LOOKING AT A DECIMAL INTEGER CONSTANT. IS IT  72020015
*        FOLLOWED IMMEDIATELY BY A RIGHT PARENTHESIS ?                  72030015
         SPACE                                                          72040015
         SPACE                                                          72060015
         IC    GRLTH,3(GRSP)                                      186/7 72120019
         LA    GRW,4(GRLTH,GRSP)                                  186/7 72180019
         CLI   0(GRW),RB                                                72240015
         MVC   MAXLTH+2(2),FFFF                                         72300015
         BC    BE,CHCONS               BRANCH - CONSTANT FOUND.         72360015
         SPACE                                                          72420015
CHB1     LA    GRY,2(0,GRSP)           SAVE POINTER TO START OF EXPRESS 72480015
         MVI   1(GRSP),X'FF'         -ION. REPLACE ( WITH CODE BYTE.    72540015
         SPACE                                                          72600015
         AR    GRSP,GRUNIT             BUMP SCAN POINTER TO (           72660015
         LR    GRW,GRUNIT              SET UP GRY AS  (COUNT            72720015
         SPACE                                                          72780015
*              THE END OF THE EXPRESSION WILL NOW BE LOCATED BY FINDING 72840015
*        THE FINAL RIGHT BRACKET.                                       72900015
         SPACE                                                          72960015
CHB2     AR    GRSP,GRUNIT             BUMP POINTER TO NEXT BYTE        73020015
CHB3     CLI   0(GRSP),LB              IS IT A (                        73080015
         BC    BNE,*+8                                                  73140015
         BXH   GRW,GRUNIT,CHB2         IF SO BUMP (COUNT AND RETURN     73200015
         TM    0(GRSP),X'E0'           IS IT AN IDENTIFIER LENGTH       73260015
         BC    BZ,CHB4                 IF SO GO TO SKIP IDENTIFIER      73320015
         CLI   0(GRSP),X'F0'           IS IT A CONSTANT MARKER          73380015
         BC    BL,CHB5                 IF NOT TRY NEXT TEST             73440015
         CLI   0(GRSP),X'FC'           * IS IT ARRAY CROSS SECTION62613 73441072
*                                      * (ILLEGAL BUT DIAGNOSED BY IA)  73442072
         BE    CHB2                    * YES, TEST NEXT BYTE      62613 73443072
         CLI   0(GRSP),X'FD'           IS IT CHAR OR BIT CONSTANT ?     73447015
         BC    BL,CHB35                BRANCH IF NOT.                   73454015
         MVC   STGLTH+2(2),1(GRSP)     PICK UP THE 2-BYTE LENGTH,  H361 73461019
         A     GRSP,STGLTH             ADD IT TO TEXT POINTER      H361 73468019
         LA    GRSP,3(0,GRSP)        BUMP ON UPTO FOLLOWING BYTE, AND   73475015
         BC    B,CHB3                GO BACK TO TEST IT.                73482015
CHB35    DS    0H                                                       73489015
         AR    GRSP,GRUNIT             OTHERWISE, POINT TO CONSTANT     73500015
CHB4     IC    GRLTH,0(GRSP)           LENGTH. BUMP POINTER BY    186/7 73560019
         BXH   GRSP,GRLTH,CHB2         LGTH. RETURN FOR NEXT BYTE 186/7 73620019
CHB5     CLI   0(GRSP),RB              IS IT A RIGHT BRACKET            73680015
         BC    BNE,CHB2                IF NOT GO AND TEST NEXT BYTE     73740015
         BCT   GRW,CHB2                OTHERWISE, REDUCE (36U5T AND     73800015
*                                    TEST IT FOR ZERO                   73860015
         SPACE                                                          73920015
*              GRSP NOW POINTS TO THE CLOSING RIGHT BRACKET.            73980015
*        THE EXPRESSION MUST BE MOVED INTO THE SECOND FILE.             74040015
         SPACE                                                          74100015
         LA    GRLTH,17(0,GRSP)        COMPUTE LENGTH OF 2ND FILE ENTRY 74160015
         SR    GRLTH,GRY             (EXPRESSION LENGTH + 16 INITIAL    74220015
*                                    BYTES + SEMICOLON)                 74280015
         BAL   GR6,CTXTRM              GO TO FIND ROOM FOR ENTRY        74340015
         SPACE 2                                                        74400015
*              THE DICTIONARY ENTRY ASSOCIATED WITH THE 2ND FILE        74460015
*        STATEMENT HAS ALREADY BEEN BUILT UP IN DICENT. IT IS NOW MOVED 74520015
*        INTO THE DICTIONARY                                            74580015
         SPACE                                                          74640015
         MVI   DICENT+9,4                                               74700015
         LA    GRX,DICENT                                               74760015
         ST    GRX,PAR1(0,GRDIC)                                        74820015
         LA    GRX,12(0,0)                                              74880015
         ST    GRX,PAR2(0,GRDIC)                                        74940015
         L     GRLR,ZDICRF(0,GRCC)                                      75000015
         BALR  GRRR,GRLR                                                75060015
         SPACE 2                                                        75120015
*              THE SECOND FILE STATEMENT IS NOW CREATED                 75180015
         MVC   0(16,GR8),ST2FLE        MOVE IN STANDARD PART AND INSERT 75240015
         MVC   1(2,GR8),PAR1+2(GRDIC) POINTER TO DICTIONARY ENTRY.      75300015
         SPACE                                                          75360015
         MVC   3(1,GR8),OPTBYT         MOVE IN OPTIONS BYTE.            75420015
         SPACE 2                                                        75480015
         SH    GRLTH,ATEEN                                              75540015
         EX    GRLTH,MVE2F             MOVE IN EXPRESSION FOR LENGTH    75600015
         EX    GRLTH,ERATX           IN JUNIOR BYTE OF GRLTH AND CLEAR  75660015
*                                    SAME FROM TEXT                     75720015
         MVI   0(GRSP),0               ERASE ).                         75780015
         ST    GR7,CFW                 MOVE SYMBOLIC POINTER TO SECOND  75840015
         MVC   0(3,GRY),CFW+1        FILE ENTRY INTO TEXT               75900015
         SPACE                                                          75960015
*              ZLSTXT IS NOW UPDATED.                                   76020015
         SPACE                                                          76080015
         LA    GR7,18(GRLTH,GR7)       BUMP SYMBOLIC POINTER TO START   76140015
         ST    GR7,ZLSTXT(0,GRDIC)   OF ENTRY BY ENTRY LENGTH AND STORE 76200015
*                                    IN ZLSTXT.                         76260015
         SPACE                                                          76320015
         CH    GRLTH,T56               IS LENGTH GREATER THAN 256. IF   76380015
         BC    BNL,BIGEXP             SO, GO TO DEAL WITH LENGTHS NOT   76440015
*                                     YET MOVED IN                      76500015
         LA    GR8,1(GR8,GRLTH)                                         76560015
CHBEND   MVI   16(GR8),SC              PUT SEMI-COLON AT END OF 2ND     76620015
         BXH   GRSP,GRUNIT,CCGS2     FILE STATEMENT AND RETURN TO SCAN  76680015
MVE2F    MVC   16(0,GR8),0(GRY)                                         76740015
ERATX    XC    0(0,GRY),0(GRY)                                          76800015
BIGEXP   AR    GRLTH,GRUNIT            BUMP GRLTH (CONVENIENT LATER)    76860015
         MVI   CFW,0                   STORE JUNIOR BYTE OF GRLTH IN    76920015
         STC   GRLTH,CFW+1           HALF WORD AND USE FOR REDUCING     76980015
         SH    GRLTH,CFW             GRLTH AND BUMP GR8 AND GRY.        77040015
         AH    GR8,CFW                                                  77100015
         AH    GRY,CFW                                                  77160015
MV256    MVC   16(256,GR8),0(GRY)      MOVE 256 BYTES OF EXPRESSION     77220015
*                                    INTO SECOND FILE                   77280015
         MVI   0(GRY),0                CLEAR TEXT.                      77340015
         MVC   1(255,GRY),0(GRY)                                        77400015
         AH    GRY,T56                 BUMP POINTERS                    77460015
         AH    GR8,T56                                                  77520015
         SH    GRLTH,T56               AND REDUCE LENGTH                77580015
         BC    BNH,CHBEND              IS THERE ANY LENGTH LEFT         77640015
         BC    B,MV256                                                  77700015
         SPACE 2                                                        77760015
CHRSK    MVI   1(GRSP),X'F0'                                            77820015
         MVC   2(2,GRSP),ZERO                                           77880015
         LA    GRSP,4(0,GRSP)                                           77940015
         BC    B,CCGS2                 RETURN                           78000015
         SPACE 2                                                        78060015
CHLAST   XC    4(0,GRSP),4(GRSP)                                        78110019
CHCONS   SR    GRLTH,GRUNIT            REDUCE CONSTANT'S LGTH. BY 1     78160019
         STM   GRLTH,GRW,TZSAV         STORE REGS. TO BE USED BY  186/7 78210019
*                                      ROUTINE 'TZRBN'.           186/7 78260019
         LA    GRPTR,4(0,GRSP)         POINT AT BYTE AFTER THAT   186/7 78310019
*                                      CONTAINING LGTH. OF CONST. 186/7 78360019
         LH    GRW,FOUR                LOAD MAX. LENGTH ALLOWED-1 186/7 78410019
         L     GR7,MAXLTH              LOAD MAX. VALUE            186/7 78460019
         LA    GRX,MES7                LOAD ERROR MESSAGE ADDR.   186/7 78510019
         BAL   GRLR,TZRBN              GO TO CHECK STRING LTH.    186/7 78560019
*                                      ON RETURN, GRW CONTAINS    186/7 78610019
*                                      VALID LENGTH IN BINARY     186/7 78660019
         SPACE                                                          78710019
CHCONB   STH   GRW,CFW+2                                          186/7 78760019
         MVI   1(GRSP),0               REPLACE ( AND CONST. MKR.  186/7 78810019
         MVC   2(2,GRSP),CFW+2         IN TEXT WITH BINARY VALUE  186/7 78860019
         LM    GRLTH,GRW,TZSAV         RELOAD REGS. USED BY TZRBN.186/7 78910019
         AR    GRLTH,GRUNIT                                       186/7 78960019
         EX    GRLTH,CHLAST          CLEAR EXCESS BYTES FROM TEXT 186/7 79010019
         LA    GRSP,5(GRLTH,GRSP)      UPDATE POINTER             186/7 79060019
         BC    B,CCGS2                 RETURN.                    186/7 79110019
         SPACE 3                                                        79200015
CHFLG1   DC    1H'0'                                                    79260015
         EJECT                                                          79320015
*              ENVIRONMENT ATTRIBUTE.                                   79340019
         SPACE 2                                                        79360019
ENVMNT   LA    GRSP,5(0,GRSP)          BUMP POINTER OVER DICT REF (IN   79380015
*                                    BRACKETS) LEFT BY READ-IN.         79440015
         BC    B,CCGS2                                                  79500015
         SPACE 5                                                        82320015
*              THE FOLLOWING ROUTINE PROCESSES THE LIKE ATTRIBUTE.  THE 82380015
*        BASE IDENTIFIER (WHICH MAY BE QUALIFIED) MUST BE MOVED INTO    82440015
*        THE DICTIONARY, PRECEDED BY A CODE BYTE (X'C8') AND THE        82500015
*        ENTRY'S LENGTH.  THIS IS DONE BY OVERWRITING THREE BYTES OF    82560015
*        TEXT AND RESTORING THEM AFTER THE ENTRY HAS BEEN MADE.  THE    82620015
*        BASE IDENTIFIER IS REPLACED BY A POINTER TO THE DICTIONARY     82680015
*        ENTRY AND EXCESS BYTES ARE CLEARED.                            82740015
         SPACE 3                                                        82800015
LIKE     SR    GRLTH,GRLTH                                              82860015
         SPACE                                                          82920015
         LR    GRW,GRSP                SAVE POINTER TO 'LIKE' BYTE      82980015
*              SCAN FOR END OF IDENTIFIER (PERHAPS QUALIFIED)           83040015
NXTBCD   IC    GRLTH,1(0,GRSP)         PICK UP BCD LENGTH               83100015
         LA    GRSP,2(GRLTH,GRSP)      BUMP POINTER TO BYTE AFTER BCD.  83160015
         CLI   0(GRSP),PERIOD          IS BCD FOLLOWED BY A PERIOD.     83220015
         BC    BE,NXTBCD               IF SO, GO TO SKIP NEXT BCD       83280015
         CLI   0(GRSP),PT                                               83340015
         BC    BE,NXTBCD                                                83400015
         SPACE                                                          83460015
*              GRSP NOW POINTS AT BYTE FOLLOWING THE BASE IDENTIFIER    83520015
         SPACE                                                          83580015
         SH    GRW,TWO                 POINT THREE BYTES SHORT OF       83640015
         MVC   CFW+1(3),0(GRW)       IDENTIFIER. SAVE BYTES TO BE OVER- 83700015
*                                    WRITTEN.                           83760015
         MVI   0(GRW),X'C8'            REPLACE WITH CODE BYTE OF DICT-  83820015
*                                    IONARY ENTRY.                      83880015
         LR    GRLTH,GRSP                                               83940015
         SR    GRLTH,GRW               COMPUTE LENGTH OF ENTRY.         84000015
         ST    GRLTH,PAR2(0,GRDIC)     INSERT IN PAR2                   84060015
         MVC   1(2,GRW),PAR2+2(GRDIC)  AND IN ENTRY TO BE MADE          84120015
         ST    GRW,PAR1(0,GRDIC)       POINTER TO ENTRY INTO PAR1       84180015
         L     GRLR,ZDICRF(0,GRCC)     MAKE ENTRY                       84240015
         BALR  GRRR,GRLR                                                84300015
         SPACE                                                          84360015
         MVC   3(2,GRW),PAR1+2(GRDIC)  INSERT POINTER TO ENTRY IN TEXT  84420015
         MVC   0(3,GRW),CFW+1          RESTORE PRECEDING TEXT           84480015
         SPACE                                                          84540015
         LA    GRLTH,5(GRW)            POINT GRLTH AT BYTE AFTER        84600015
         BCT   GRSP,ERASER             TEXT REF.                        84660015
         EJECT                                                          84661019
*                       ROUTINE TZRBN.                            186/7 84662019
         SPACE                                                          84663019
*              FUNCTION.  TO CHECK THE VALIDITY OF:-              186/7 84664019
*             (1)   A STRUCTURE LEVEL                             186/7 84665019
*             (2)   AN I-SUB VALUE                                186/7 84666019
*             (3)   A POSITION CONSTANT                           186/7 84667019
*             (4)   A STRING LENGTH                               186/7 84668019
*                                                                       84669019
*              SKIPS OVER PRECEEDING ZERO BYTES, IF ANY, AND      186/7 84670019
*        CONVERTS THE VALUE TO BINARY. IF VALID, THIS IS          186/7 84671019
*        RETURNED IN REGISTER GRW TO BE INSERTED INTO THE TEXT.   186/7 84672019
*        IF A NON-ZERO PRECEEDING BYTE IS FOUND OR THE BINARY     186/7 84673019
*        VALUE IS INVALID, A BRANCH IS MADE TO THE ERROR          186/7 84674019
*        ROUTINE 'TZERR'.                                         186/7 84675019
*        THE FOLLOWING REGISTERS ARE USED AND CONTAIN ON ENTRY:-  186/7 84676019
*                                                                       84677019
*        GRLR  NORMAL RETURN ADDRESS.                             186/7 84678019
*        GRX   APPROPRIATE ERROR MESSAGE ADDRESS.                 186/7 84679019
*        GRPTR ADDRESS OF THE TEXT BYTE AFTER THAT CONTAINING     186/7 84680019
*               THE LENGTH OF THE VALUE TO BE CHECKED.            186/7 84681019
*        GRW   MAXIMUM NUMBER-1 OF BYTES FOR CONTAINING THE VALUE 186/7 84682019
*        GRLTH LENGTH OF THE VALUE REDUCED BY 1 FOR PACK INSTR.   186/7 84683019
*        GR7   MAXIMUM (IN BINARY) ALLOWED FOR THE VALUE.         186/7 84684019
*                                                                       84685019
*        ENTRY - AT TZRBN                                         186/7 84686019
*                                                                       84687019
*        EXTERNAL ROUTINE - TZERR, ISSUES THE APPROPRIATE ERROR   186/7 84688019
*              MESSAGE AND RETURNS THE ASSOCIATED MAXIMUM VALUE   186/7 84689019
*              IN GRW TO THE ROUTINE WHICH BRANCHED TO TZRBN.     186/7 84690019
*                                                                       84691019
*        EXIT  - NORMAL - VIA ADDRESS IN GRX, TO CALLING ROUTINE. 186/7 84692019
*              - ERROR  - BRANCHES TO ERROR ROUTINE 'TZERR'.      186/7 84693019
*                                                                       84694019
*        TABLES/WORK AREA - CONSTANT IS PACKED INTO DOUBLE WORD   186/7 84695019
*              CCDW, THE FIRST WORD OF WHICH IS ALWAYS ZERO.      186/7 84696019
         SPACE 3                                                        84697019
TZRBN    CR    GRLTH,GRW               IS VALUE HELD IN MORE THAN 186/7 84698019
*                                      MAX. NO. OF BYTES ALLOWED  186/7 84699019
         BC    BNH,TZLOK               NO, SO BRANCH              186/7 84700019
         SR    GRLTH,GRW               YES, SO CALCULATE NO. OF   186/7 84701019
*                                      EXTRA BYTES.               186/7 84702019
TESTZ    CLI   0(GRPTR),X'00'          CHECK FOR PREFIX ZERO(S).  186/7 84703019
         BC    BNE,TZERR               NON-ZERO VALUE, SO ERROR   186/7 84704019
         AR    GRPTR,GRUNIT                                       186/7 84705019
         BCT   GRLTH,TESTZ                                        186/7 84706019
         LR    GRLTH,GRW               PREFIX BYTES ALL ZERO SO   186/7 84707019
*                                      SET GRLTH TO MAX. LGTH-1   186/7 84708019
*                                      GRPTR POINTS TO VALUE.     186/7 84709019
TZLOK    EX    GRLTH,TZPAK             PACK THE VALUE             186/7 84710019
         OI    CCDW+7,X'0F'            SET SIGN POSITIVE          186/7 84711019
         CVB   GRW,CCDW                CONVERT IT TO BINARY       186/7 84712019
         CR    GRW,GR7                 IS IT GREATER THAN MAXIMUM 186/7 84713019
         BC    BH,TZERR                IF SO, GO TO ISSUE MESSAGE 186/7 84714019
         BCR   B,GRLR                  IF NOT, RETURN.            186/7 84715019
         SPACE                                                          84716019
TZPAK    PACK  CCDW+4(4),0(0,GRPTR)                               186/7 84717019
         EJECT                                                          84720015
*              ERROR ROUTINES                                           84780015
         SPACE 3                                                        84840015
*              COMPILER ERRORS - SET UP NUMERIC PARAMETERS              84900015
         SPACE                                                          84960015
CMPER6   LA    GRUNIT,1(GRUNIT)        26 - NO QUOTE MARK AFTER PICTURE 85020015
         SPACE                                                          85080015
CMPER5   LA    GRUNIT,1(GRUNIT)        25 - NO BASE IDENTIFIER AFTER    85140015
*                                           DEFINED ATTRIBUTE           85200015
CMPER4   LA    GRUNIT,1(GRUNIT)        24 - CANNOT RECOGNISE ATTRIBUTE  85260015
         SPACE                                                          85320015
CMPER3   LA    GRUNIT,1(GRUNIT)        23 - CANNOT RECOGNISE BYTE IN    85380015
*                                          DECLARE STATEMENT            85440015
CMPER2   LA    GRUNIT,1(GRUNIT)        22 - IDENTIFIER LENGTH OF ZERO   85500015
         SPACE                                                          85560015
CMPER1   LA    GRUNIT,20(GRUNIT)       21 - WRONG STATEMENT TYPE IN     85620015
*                                           DECLARE CHAIN               85680015
         SPACE                                                          85740015
         ST    GRUNIT,PAR5(GRDIC)                                       85800015
         SPACE                                                          85860015
*              COMPILER ERROR.  NUMBER X'0210'                          85920015
         SPACE                                                          85980015
CMPERR   MVC   PAR6+1(3,GRDIC),MES1    ERROR MESSAGE INFORMATION INTO   86040015
         L     GRRR,ZABORT(0,GRCC)     SET UP RETURN REGISTER SO THAT   86100015
*                                    CONTROL IS PASSED DIRECTLY TO      86160015
*                                    ZABORT.                            86220015
         BC    B,EIERR                                                  86280015
         SPACE 3                                                        86340015
*              NO MORE SCRATCH CORE CONTIGUOUS WITH THAT ALREADY  186/7 86430019
*        ALLOCATED TO THE FACTORED ATTRIBUTE TABLE - X'20D'.      186/7 86520019
         SPACE                                                          86610019
FCTERR   MVC   PAR6+1(3,GRDIC),MESSD+1                                  86700019
         L     GRLR,ZUERR(0,GRCC)                                       86790019
         L     GRRR,ZABORT(0,GRCC)                                      86880019
         BCR   B,GRLR                                                   86970019
         SPACE                                                          87060019
MESSD    DC    X'00020D00'                                              87150019
         EJECT                                                          87240019
*              TZERR IS BRANCHED TO FROM ROUTINE 'TZRBN'.         186/7 87330019
*        THE ERROR MESSAGES ISSUED BY THIS ROUTINE ARE:-          186/7 87420019
*                                                                       87510019
*         STRUCTURE LEVEL TOO LARGE.   NUMBER  X'0211'.           186/7 87600019
*         I-SUB TOO LARGE.             NUMBER  X'0215'.           186/7 87690019
*         STRING LENGTH TOO LARGE.     NUMBER  X'0216'.           186/7 87780019
*         POS. CONSTANT TOO LARGE.     NUMBER  X'0219'.           186/7 87870019
         SPACE                                                          87960019
TZERR    LR    GRW,GR7                 PICK UP MAX. LEGAL VALUE   186/7 88050019
         LR    GRRR,GRLR               LOAD RETURN ADDRESS        186/7 88140019
         MVC   PAR6+1(3,GRDIC),0(GRX)  ERROR MESSAGE INFORMATION  186/7 88230019
EIERR    MVC   ZSTAT(2,GRDIC),DICENT+3   STATEMENT NUMBER INTO    186/7 88320019
         L     GRLR,ZUERR(0,GRCC)      COMMUNICATIONS REGION.     186/7 88410019
         BCR   B,GRLR                  GO TO ISSUE ERROR MESSAGE  186/7 88500019
         EJECT                                                          88740015
CCFIN    L     GRX,ZLSTXT(0,GRDIC)                                      88800015
         ST    GRX,PAR1(0,GRDIC)                                        88860015
         L     GRLR,ZTXTAB(0,GRCC)                                      88920015
         BALR  GRRR,GRLR                                                88980015
         L     GRX,PAR1(0,GRDIC)                                        89040015
         MVI   0(GRX),EOP                                               89100015
         MVC   PAR1+1(1,GRDIC),ZLSTXT+1(GRDIC)  MARK BLOCK CONTAINING   89160015
         MVI   PAR2+3(GRDIC),UNWANT  SECOND END OF PROGRAM MARKER 'NOT  89220015
         L     GRLR,ZALTER(0,GRCC)   WANTED'                            89280015
         BALR  GRRR,GRLR                                                89340015
         SPACE                                                          89400015
         SPACE                                                          89700015
*              RELEASE CONTROL                                          89760015
         LA    GRX,RLLST                                                89820015
         ST    GRX,PAR1(0,GRDIC)                                        89880015
         SR    GRX,GRX                                                  89940015
         ST    GRX,PAR2(0,GRDIC)                                        90000015
         L     GRLR,RLSCTL(0,GRCC)                                      90060015
         BALR  GRRR,GRLR                                                90120015
RLLST    DC    C'EHEIEJZZ'             RELEASE LIST                     90180015
         SPACE 5                                                        90240015
*              THE FOLLOWING STORAGE AND CONSTANTS ARE REQUIRED -       90300015
         SPACE 2                                                        90360015
         CNOP  0,8                                                      90420015
CCDW     DC    2F'0'                   DOUBLE WORD, USED FOR CONVERSION 90480015
*                                    TO BINARY. FIRST WORD KEPT ZERO    90540015
ZERO     EQU   CCDW                  FOR COMPARISONS.                   90600015
CCPTR    DS    1F                      POINTER TO FACTORED ATTRIBUTE    90660015
*                                    TABLE                              90720015
CCPTR1   DC    1F'0'                                                    90780015
CCPTR2   DC    1F'0'                                                    90840015
CCFW     DC    1F'0'                   THIS IS USED AS A FULL WORD VIA  90900015
*                                    WHICH REGISTERS ARE LOADED WITH 3  90960015
*                                    BYTE ADDRESSES. TO SAVE REPEATED   91020015
*                                    CLEARING, THE FIRST BYTE IS LEFT   91080015
*                                    AS ZERO THROUGHOUT.                91140015
FF       DC    XL3'FFFFFF'                                              91200015
FE       DC    XL3'FFFFFE'             THESE LAST 6 BYTES MUST BE CONT- 91260015
*                                    IGIOUS.                            91320015
LSTPIC   DC    1F'0'                                                    91380015
NXT4K    DC    C'EJZZ'                                                  91440015
CCEND    DS    1F                                                       91500015
DICENT   EQU   EJ+16                   DICTIONARY ENTRY ASSOCIATED WITH 91560015
*                                    SECOND FILE STATEMENTS. (IN EJ)    91620015
CCPTR3   EQU   DICENT+12                                                91680015
OPTBYT   EQU   CCPTR3                                                   91740015
STOP     DC    X'00FFFFFF'             CHAIN STOPPER                    91800015
CCSTL    DC    X'0'                    HOLDS STRUCTURE LEVEL.     186/7 91820019
MAXLVL   DC    1H'255'                                            186/7 91840019
MAXLTH   DC    1F'0'                                                    91860015
STGLTH   DC    1F'0'                   HOLDS 2-BYTE LENGTH OF A    H361 91880019
*                                      STRING CONSTANT'S LENGTH.   H361 91900019
TWO      DC    1H'2'                                                    91920015
FOUR     DC    1H'4'                                              186/7 92010019
ATEEN    DC    H'18'                                                    92100015
TF6      DC    1H'256'                                                  92160015
T56      EQU   TF6                                                      92220015
SUB32    DC    1H'32'                                             186/7 92250019
OFFFF    DC    1F'32767'                                                92280015
FFFF     EQU   OFFFF+2                                                  92340015
GNTCNT   DC    1H'0'                   GENERIC AND ENTRY BRACKET COUNT  92400015
CCPL     DS    1H                                                       92460015
FACT     DC    XL1'0'                                                   92520015
DEFSN    DC    X'BC000011'             SECOND FILE TEXT                 92580015
         DC    X'4A0000003043'               SKELETON FOR DEFINED.      92640015
ST2FLE   DC    X'BC0000009F7E00000434430000004546'                      92700015
CCSTR    DS    1C                                                       92760015
EHBASE   DS    F                       STORE FOR BASE REGISTER OF EH    92940015
DEFR     DC    F'0'                                                     93000015
DEFR2    DC    F'0'                                                     93060015
TZSAV    DC    3F'0'                                              186/7 93090019
         SPACE 5                                                        93120015
*              ERROR MESSAGES.                                          93180015
         SPACE 2                                                        93240015
MES1     DC    X'021060'               COMPILER ERROR - TERMINARE.      93300015
MES2     DC    X'021144'               STRUCTURE LEVEL TOO LARGE        93360015
MES3     DC    X'021244'               ERROR IN DEFINING SUBSCRIPT LIST 93420015
MES4     DC    X'021344'               NON-LINEAR IN I-SUBS             93480015
MES5     DC    X'021444'               * AS SUBSCRIPT                   93540015
MES6     DC    X'021544'               I-SUB TOO LARGE                  93600015
MES7     DC    X'021644'               STRING LENGTH TOO LARGE.         93660015
* MES8, 'KEY LENGTH TOO LARGE'   - X'021744', NOT USED; DELETED.  186/7 93720019
* MES9, 'REGION VALUE TOO GREAT' - X'021844', NOT USED; DELETED.  186/7 93780019
MES10    DC    X'021944'               POS. CONSTANT TOO LARGE.         93840015
CFW      EQU   CCFW                                                     93900015
ATTRIB   DC    X'2C2C'                 X46/X47 - PRECISION 1 & 2        93960019
X48      DC    X'00081818283C0C00'     NUM.PIC/BIT/CHAR/DIMS/LABEL/PIC  94020019
X50      DC    X'0000000000000000'                                      94080019
X58      DC    X'1414000000000014'     ENTRY/GENERIC/RETURNS            94140015
X60      DC    X'0000000000000000'                                      94200015
X68      DC    X'003010040000001C'     INIT/LIKE/DEFINED/POS            94260019
X70      DC    X'2000000000383400'     AREA(NUM)/BASED/OFFSET           94320019
X78      DC    X'0000200000000000'     AREA(EXP)                        94380015
X80      DC    X'0000000000000000'                                      94440015
X88      DC    X'000024'               ENV                              94500015
         EJECT                                                          94560015
*              THE FOLLOWING STORAGE AREA IS ASSEMBLED IN AS A FIXED    94620015
*        OFFSET FROM THE START OF MODULE IEMEI, SO THAT THE SLOTS       94680015
*        WITHIN IT CAN BE ADDRESSED BY OTHER MODULES.                   94740015
         SPACE 2                                                        94800015
         ORG   IEMEI+X'FF8'                                             94860015
         SPACE                                                          94920015
SYMNM1   DC    F'0'                    WORD CONTAINING TEXT REF OF      94980015
*                                    CURRENT PROC / BEGIN STATAMENT.    95040015
         SPACE                                                          95100015
SYMNM2   DC    F'0'                    WORD CONTAINING TEXT REF OF      95160015
*                                    CURRENT DECLARE STATEMENT.         95220015
         EJECT                                                          95280015
         END   IEMEI                                                    95340015
