EL       TITLE 'IEMEL, DECLARE PASS TWO, DICTIONARY, PL/I F'            00030013
         SPACE 3                                                        00060013
*              STATUS - CHANGE LEVEL 0.                                 00090013
*                                                                  H234 00100001
* R18 424200,453600-455400,462100       - PTM 715 -                H234 00110001
* R19 276600,891900-892200                                        24676 00113019
* R19 159900-160800,162400*                                        H344 00116019
* R19          THE FOLLOWING STATEMENTS, ENVOLVING THE OBSOLETE         00116619
*        'SETS' AND 'USES' ATTRIBUTES, HAVE BEEN ALTERED/DELETED:-      00117219
*     047400-050700,075600-075900*,199500*,207600.                      00117819
* R19 141900-142200,214500,657600-658500,724500-724800,           28459 00118419
*     726600,888000-888300*,892500-893100*,895200,963800-967800.  28459 00119019
* R19          STATEMENTS AFFECTED BY SPACE-SAVINGS FOR FIX FOR A27216- 00119119
*     394500,395400,397800-400200*,403800-405900,410520-410550,         00119219
*     415500-417000,417600,420300-421300,423900-424200,428100,431700,   00119319
*     434100,436500-437400,460500-460800.                               00119419
* R19 141900,411000-413100,432900,706500-707400*.                 27216 00119519
* R19 658500-658800,721200.                                        H400 00119619
* R20 *748800.                                                    34348 00119820
* R20          CHANGES MADE IN REMOVING ROUTINE 'BCDISB' TO       27169 00123820
* R20    MODULE IEMED TO GIVE SPACE FOR FOR FIX FOR APAR 27169.   27169 00127820
*     +210600,+278900,+372000,-372900-462900,*708000-708300.      27169 00131820
*     *141950,*142050,+142100,+201300,+216000,*355500,*366300,    27169 00135820
*     *370500-370800,*672900,+673500,+749400.                     27169 00139820
* R20 +063300,*215100,*633300-633600,*856800,+858600,+859500,     33884 00140820
*     *860400,*861000,*861900-864000,-864300-865200,              33884 00141820
*     *911800-915800,*927800-931800.                              33884 00142820
         SPACE 3                                                        00143820
*              FUNCTION / OPERATION - THIS MODULE CONSISTS OF ONE MAIN  00150013
*        ROUTINE, 'CDCLSC', WHICH PERFORMS ALL THE PROCESSING FOR ONE   00180013
*        DCL STATEMENT. ROUTINE CDCLSC CONSISTS OF THE FOLLOWING        00210013
*        SUBROUTINES.                                                   00240013
         SPACE                                                          00270013
*              INTLZE. THIS ROUTINE PERFORMS THE INITIALISATION         00300013
*        NECESSARY BEFORE WE SCAN EACH INDIVIDUAL DECLARE STATEMENT.    00330013
         SPACE                                                          00360013
*              DCIDPR. THIS ROUTINE PERFORMS THE INITIALISATION         00390013
*        NECESSARY BEFORE WE PICK UP EACH DECLARED IDENTIFIER. IT THEN  00420013
*        PICKS UP AND PROCESSES ANY LEVEL NUMBERS OR FACTOR BRACKETS    00450013
*        THAT MAY PRECEDE THE IDENTIFIER.                               00480013
         SPACE                                                          00510013
*              BCDPR. THIS ROUTINE PROCESSES THE BCD OF THE IDENTIFIER. 00540013
*        IT DETERMINES WHETHER ANOTHER IDENTICAL BCD HAS BEEN DECLARED  00570013
*        IN THE SAME PROCEDURE BLOCK, AND IF SO CALLS THE ROUTINE       00600013
*        'BCDISB'. IF A LEVEL NUMBER HAS BEEN DECLARED, WE CALL ROUTINE 00630013
*        'FRWSCN' TO SCAN FORWARD IN THE TEXT TO PICK UP THE NEXT LEVEL 00660013
*        NUMBER.                                                        00690013
         SPACE                                                          00720013
*              BCDISB. THIS ROUTINE IS CALLED WHEN A SIMILAR BCD TO     00750013
*        THE CURRENT ONE HAS BEEN FOUND IN THE SAME BLOCK. WE DECIDE    00780013
*        WHETHER THIS IS A LEGAL SITUATION, AND TAKE APPROPRIATE ACTION 00810013
*        IN EACH CASE.                                                  00840013
         SPACE                                                          00870013
*              SELMSK. THIS ROUTINE MOVES THE APPROPRIATE TEST MASK     00900013
*        INTO THE ATTRIBUTE COLLECTION AREA, NOW THAT WE KNOW WHAT SORT 00930013
*        OF IDENTIFIER THIS IS. WE ALSO ARRANGE FOR THE INHERITING OF   00960013
*        STORAGE CLASS IN STRUCTURES.                                   00990013
         SPACE                                                          01020013
*              FACLVN. THIS ROUTINE IS CALLED BY 'BCDPR' TO PICK UP ANY 01050013
*        FACTORED LEVEL NUMBERS FROM THE FACTORED ATTRIBUTE TABLE.      01080013
         SPACE                                                          01110013
*              FRWSCN. THIS ROUTINE IS CALLED BY 'BCDPR' TO SCAN        01140013
*        FORWARD FOR THE NEXT LEVEL NUMBER.                             01170013
         SPACE                                                          01200013
*              STRPR. THIS ROUTINE PROCESSES STRUCTURE MEMBERS, FINDING 01230013
*        THEIR TRUE LEVEL NUMBERS, AND MAKING ENTRIES IN THE STRUCTURE  01260013
*        TABLE.                                                         01290013
         SPACE                                                          01320013
*              ATLSCN. THIS ROUTINE SCANS THE ATTRIBUTE LIST            01350013
*        IMMEDIATELY FOLLOWING THE IDENTIFIER, CALLING ROUTINE 'CDATPR' 01380013
*        ( IN MODULE EK) TO PROCESS EACH ATTRIBUTE PICKED UP.           01410013
         SPACE                                                          01440013
*              PREPRC. THIS ROUTINE PERFORMS SOME CHECKING FOR THOSE    01470013
*        CASES OF CONFLICTING ATTRIBUTES WHICH CAN ONLY BE TOLD WHEN WE 01500013
*        HAVE REACHED THE END OF THE ATTRIBUTE LIST.                    01530013
         SPACE                                                          01560013
*              AT THIS STAGE WE CALL ROUTINE 'CDICEN' (MODULE EM) TO    01590013
*        MAKE THE DICT. ENTRY FOR THE VARIABLE.                         01620013
         SPACE                                                          01650013
*              PSPROC. THIS ROUTINE DOES SOME POST-PROCESSING. IN MANY  01680013
*        CASES THE DICT. REF. OF THE NEWLY MADE DICT. ENTRY MUST BE PUT 01710013
*        INTO A CHAIN SLOT SOMEWHERE. (E.G. THE STRUCTURE MEMBER CHAIN, 01740013
*        THE CHAIN OF LIKENED STRUCTURES, ETC.).                        01770013
         SPACE                                                          01800013
*              UNWANT. THIS ROUTINE IS CALLED FROM MANY PLACES TO MARK  01830013
*        A TEXT BLOCK UNWANTED IF IT IS DIFFERENT FROM THE TEXT BLOCK   01860013
*        CONTAINING THE PART OF THE DECLARE STATEMENT THAT WE ARE       01890013
*        CURRENTLY SCANNING.                                            01920013
         SPACE 3                                                        01950013
*              ENTRY POINTS - THE FOUR BRANCHING INSTRUCTIONS IN THE    01980013
*        TRANSFER VECTOR WHICH BRANCH TO ROUTINES STRPR, PSPROC, CDCLSC 02010013
*        AND NHERIT RESPECTIVELY.                                       02040013
         SPACE 3                                                        02070013
*              INPUT - THE DECLARE STATEMENT IN THE TEXT.               02100013
         SPACE 3                                                        02130013
*              OUTPUT - THE ATTRIBUTE COLLECTION AREA, A WORKSPACE IN   02160013
*        SCRATCH CORE.                                                  02190013
         SPACE 3                                                        02220013
*              EXTERNAL ROUTINES -                                      02250013
         SPACE                                                          02280013
*              IN MODULE IEMEK,                                         02310013
         SPACE                                                          02340013
*              CDATPR - THIS ROUTINE PROCESSES AN ATTRIBUTE, SETTING    02370013
*                       APPROPRIATE IN THE ATT. COLL. AREA.             02400013
         SPACE                                                          02430013
*              BLANK -  THIS ROUTINE BLANKS OUT TEXT IN THE DECLARE     02460013
*                       STATEMENT.                                      02490013
         SPACE 2                                                        02520013
*              IN MODULE IEMEM,                                         02550013
         SPACE                                                          02580013
*              CDICEN - THIS ROUTINE CONSTRUCTS DICTIONARY ENTRIES.     02610013
         SPACE                                                          02640013
*              CDFATT - THIS ROUTINE PICKS UP FACTORED ATTRIBUTES BY    02670013
*                       SCANNING THE FACTORED ATTRIBUTE.                02700013
         SPACE                                                          02730013
*              CDIMAT - THIS ROUTINE APPLIES ANY IMPLICIT ATTRIBUTES.   02760013
         SPACE                                                          02790013
*              CDFLT  - THIS ROUTINE APPLIES DEFAULT ATTRIBUTES.        02820013
         SPACE                                                          02850013
*              ERROR  - THIS ROUTINE HANDLES ALL CALLS TO 'ZUERR', THE  02880013
*                       COMPILER CONTROL ERROR MESSAGE ROUTINE.         02910013
         SPACE                                                          02940013
*              CHASH  - THIS ROUTINE HASHES A BCD.                      02970013
         SPACE 2                                                        03000013
*              IN CONTROL PHASE,                                        03030013
         SPACE                                                          03060013
*              ZDRFAB - CONVERTS DICTIONARY REFERENCE TO ABSOLUTE       03090013
*                       ADDRESS.                                        03120013
         SPACE                                                          03150013
*              ZTXTRF - CONVERTS ABSOLUTE ADDRESS TO TEXT REFERENCE.    03180013
         SPACE                                                          03210013
*              ZTXTAB - CONVERTS TEXT REFERENCE TO ABSOLUTE ADDRESS.    03240013
         SPACE                                                          03270013
*              ZDABRF - CONVERTS ABSOLUTE ADDRESS TO DICTIONARY         03300013
*                       REFERENCE.                                      03330013
         SPACE                                                          03360013
*              ZCHAIN - CREATES NEW TEXT BLOCK, CHAINING IT TO NAMED    03390013
*                       BLOCK.                                          03420013
         SPACE                                                          03450013
*              ZALTER - CHANGES THE STATUS OF A TEXT BLOCK.             03480013
         SPACE 3                                                        03510013
*              EXITS - NORMAL - AT 'END', RETURN TO ROUTINE 'CGENSC',   03540013
*        (MODULE EM).                                                   03570013
         SPACE 3                                                        03600013
*              EXITS - ERROR - NONE.                                    03630013
         SPACE 3                                                        03660013
*              TABLES / WORK AREAS -                                    03690013
         SPACE                                                          03720013
*              1. THE ATTRIBUTE COLLECTION AREA.                        03750013
*                 THIS IS A WORKSPACE IN SCRATCH CORE USED TO           03780013
*                 ACCUMULATE INFORMATION ABOUT THE IDENTIFIER. ITS      03810013
*                 FORMAT IS THAT OF AN EXPANDED DICTIONARY ENTRY AND    03840013
*                 IS DESCRIBED IN DETAIL BY MEANS OF 'EQU' CARDS.       03870013
         SPACE                                                          03900013
*              2. CSTCK3.                                               03930013
*                 THIS IS A STACK OF WORKSPACES USED MAINLY BY THE      03960013
*                 'ENTRY' ROUTINE IN MODULE IEMEK. ITS FORMAT IS        03990013
*                 DESCRIBED IN THAT MODULE.                             04020013
         SPACE                                                          04050013
*              3. STRUCTURE TABLE.                                      04080013
*                 THIS IS A TABLE INITIALISED EACH TIME WE ENCOUNTER A  04110013
*                 MAJOR STRUCTURE. IT CONSISTS OF FOUR BYTE ENTRIES.    04140013
*                 THE FIRST ENTRY BELONGS TO THE MAJOR STRUCTURE, THE   04170013
*                 SECOND ENTRY TO THE MOST RECENT MEMBER WHOSE TRUE     04200013
*                 LEVEL NUMBER IS 2, THE N'TH ENTRY TO THE MOST RECENT  04230013
*                 STRUCTURE MEMBER WHOSE TRUE LEVEL NUMBER IS N.        04260013
*                 THE FIRST BYTE OF THE ENTRY IS THE DECLARED LEVEL     04290013
*                 NUMBER, THE SECOND BYTE CONTAINS THE NUMBER OF        04320013
*                 DIMENSIONS (INCLUDING INHERITED ONES). THE LAST TWO   04350013
*                 BYTES CONTAIN THE STRUCTURE MEMBER'S DICTIONARY       04380013
*                 REFERENCE. THE STRUCTURE TABLE IS IN SCRATCH CORE.    04410013
         SPACE                                                          04440013
*              3. HASH TABLE.                                           04470013
*                 THIS TABLE IS A SERIES OF DICTIONARY REFERENCES, EACH 04500013
*                 ONE BEING THE START OF A HASH CHAIN. THE HASHING      04530013
*                 ROUTINE, WHEN PASSED A BCD, RETURNS THE HASH RESULT   04560013
*                 AS THE OFFSET OF THE CHAIN HEADER SLOT FROM THE START 04590013
*                 OF THE HASH TABLE. THE TABLE IS SET UP INITIALLY BY   04620013
*                 MODULE IEMEG INTO SCRATCH CORE, BUT IS ADDED TO BY    04650013
*                 MOST OF THE DICTIONARY PHASES.                        04680013
         SPACE                                                          04710013
*              4. THE FACTORED ATTRIBUTE TABLE.                         04810019
*                 THIS TABLE IS SET UP BY MODULE IEMEI IN SCRATCH CORE. 05100013
*                 IT CONTAINS TEXT REFERENCES TO FACTORED ATTRIBUTE     05130013
*                 LISTS WHICH ENABLE THIS PHASE TO PICK UP FACTORED     05160013
*                 ATTRIBUTES AND LEVEL NUMBERS. THE FORMAT OF THE TABLE 05190013
*                 IS DESCRIBED IN THE COMMENTS FOR MODULE IEMEI.        05220013
         SPACE 3                                                        05250013
*              ATTRIBUTES - NOT RE-USABLE.                              05280013
         SPACE 3                                                        05310013
*              NOTES - CHARACTER CODE DEPENDENCY.                       05340013
         SPACE                                                          05370013
*              THE OPERATION OF THIS MODULE DEPENDS ON AN INTERNAL      05400013
*        REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS          05430013
*        EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING HAS    05460013
*        BEEN ARRANGED SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS,   05490013
*        BY RE-ASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW    05520013
*        DEFINITIONS.                                                   05550013
         SPACE 4                                                        05580013
IEMEL    START 0                                                        05610013
         USING *,GRELB                                                  05640013
         EJECT                                                          05670013
*              ATTRIBUTE COLLECTION AREA                                05700013
         SPACE 4                                                        05730013
*        ATTRIBUTE COLLECTION AREA IS POINTED TO BY GRATCA.             05760013
         SPACE 2                                                        05790013
FLAGS3   EQU   0                       OFFSET OF THIRD CFLAG BYTE       05820013
         SPACE                                                          05850013
CFLA17   EQU   X'80'                   FLAG MEANING THAT AN ATTRIBUTE   05880013
*                                    HAS BEEN ENCOUNTERED INSIDE ENTRY. 05910013
CFLA18   EQU   X'40'                   COMPILATION MUST TERMINATE AT    05940013
*                                    END OF PHASE.                      05970013
CFLA19   EQU   X'20'                   TEMPORARY SCAN OF HASH CHAIN IS  06000013
*                                    BEING PERFORMED.                   06030013
CFLA20   EQU   X'10'                   A NON-MAJOR STRUCTURE MEMBER     06060013
*                                    DESCRIPTION HAS BEEN ENCOUNTERED   06090013
*                                    INSIDE AN 'ENTRY' ATTRIBUTE.       06120013
CFLA21   EQU   X'08'                   THE SECTION OF ROUTINE 'PSPROC'  06150013
*                                    THAT PROCESSES THE LAST MEMBER OF  06180013
*                                    GENERIC LISTS IS INHIBITED.        06210013
NFLA21   EQU   X'FF'-CFLA21            ANDING VALUE                     06240013
CFLA22   EQU   X'04'                   THE CURRENT INITIAL ATTRIBUTE IS 06270013
*                                    INAPPLICABLE TO SCALARS.           06300013
         SPACE 2                                                        06330013
FLAGS4   EQU   FLAGS3+1                OFFSET OF 4TH CFLAG BYTE.  33884 06333020
         SPACE                                                          06336020
CFLA25   EQU   X'80'                   FLAG SET WHEN BLOCK BNDRY. 33884 06339020
*                                    IS CROSSED AFTER PARM. LIST  33884 06342020
*                                    OF AN ENTRY NAME WHICH IS    33884 06345020
*                                    NOT IN A GENERIC LIST.       33884 06348020
NFLA25   EQU   X'7F'                   ANDING VALUE.              33884 06351020
         SPACE 2                                                        06354020
DCLATT   EQU   FLAGS3+2                 OFFSET OF DECLARED ATTRIBUTES   06360013
*                                    REGION                             06390013
*              THE DECLARED ATTRIBUTES REGION (FIRST BYTE)              06420013
         SPACE 2                                                        06450013
DATA     EQU   X'80'                   DATA                             06480013
LABEL    EQU   X'40'                   LABEL                            06510013
NTRY     EQU   X'20'                   ENTRY                            06540013
TASKID   EQU   X'10'                   TASK IDENTIFIER                  06570013
FILE     EQU   X'08'                   FILE                             06600013
GENRIC   EQU   X'04'                   GENERIC                          06630013
BILTIN   EQU   X'02'                   BUILTIN                          06660013
STRUC    EQU   X'01'                   STRUCTURE                        06690013
NTRUC    EQU   X'FE'                                                    06720013
ENTBLT   EQU   X'22'                   BOTH ENTRY AND BUILTIN BITS      06750013
SDL      EQU   STRUC+DATA+LABEL        STRUCTURE AND DATA AND LABEL.    06780013
         SPACE 2                                                        06810013
*              THE DECLARED ATTRIBUTES REGION (SECOND BYTE)             06840013
         SPACE 2                                                        06870013
CADSTR   EQU   X'80'                   CODED ARITHMETIC DATA OR STRING  06900013
STRING   EQU   X'7F'                   STRING                           06930013
RSMBIT   EQU   X'40'                   RADIX, SCALE, MODE OR BIT        06960013
BADGEN   EQU   X'08'                   CURRENT MEMBER OF GENERIC LIST   06990013
*                                    IS ILLEGAL.                        07020013
PCKD     EQU   X'04'                   PACKED/ALIGNED ATTRIBUTE HAS     07050013
NPCKD    EQU   X'FF'-PCKD            BEEN DECLARED.                     07080013
DIFRTV   EQU   X'02'                   FLAG MEANING THAT ENTRY POINT    07110013
*                                    HAS HAD A NEW ENTRY TYPE 2         07140013
*                                    CONSTRUCTED.                       07170013
INTERN   EQU   X'01'                   INTERNAL ATT. HAS BEEN SEEN.     07200013
         SPACE 4                                                        07230013
TYPBYT   EQU   DCLATT+2                OFFSET OF TYPE BYTES             07260013
         SPACE 4                                                        07290013
*              THE SEVEN TYPE BYTES                                     07320013
         SPACE 2                                                        07350013
*              THE 'ENTRY' BYTE                                         07380013
         SPACE                                                          07410013
ENTRY    EQU   DCLATT+2                OFFSET FROM HEAD OF AT.COL.AREA  07440013
         SPACE                                                          07470013
ABNRML   EQU   X'80'                   ABNORMAL                         07500013
NORMAL   EQU   X'40'                   NORMAL                           07530013
SCNDY    EQU   X'08'                   SECONDARY                        07620013
RCURSV   EQU   X'04'                   RECURSIVE                        07650013
DATATT   EQU   X'02'                   HAS DATA ATTRIBUTES              07680013
         SPACE 2                                                        07710013
*              THE 'OTHER1' BYTE                                        07740013
         SPACE                                                          07770013
OTHER1   EQU   ENTRY+1                 OFFSET FROM HEAD OF AT.COL.AREA  07800013
         SPACE                                                          07830013
SYMBOL   EQU   X'80'                   SYMBOL / REQUIRES LOAD CONSTANT  07860013
DFNDN    EQU   X'40'                   DEFINED ON                       07890013
CHECK    EQU   X'20'                   MENTIONED IN A CHECK LIST        07920013
SAVED    EQU   X'10'                   SAVED                            07950013
LMSTRC   EQU   X'08'                   LAST MEMBER OF STRUCTURE         07980013
NMSTRC   EQU   X'F7'                                                    08010013
ADJDIM   EQU   X'04'                   ADJUSTABLE DIMENSIONS            08040013
ASTDIM   EQU   X'02'                   ASTERISK DIMENSIONS              08070013
NASTAJ   EQU   X'FF'-ASTDIM-ADJDIM                                      08100013
ASTSTL   EQU   X'01'                   ASTERISK STRING LENGTH           08130013
NASTSL   EQU   X'FF'-ASTSTL                                             08160013
         SPACE 2                                                        08190013
         SPACE                                                          08200019
*              THE 'VARIABLE' BYTE                                      08220013
VARBLE   EQU   OTHER1+1                OFFSET FROM HEAD OF AT.COL.AREA  08250013
         SPACE                                                          08280013
SECASL   EQU   X'80'                   SECOND ADDRESS SLOT              08310013
DIMENS   EQU   X'40'                   DIMENSIONED                      08340013
NDMENS   EQU   X'FF'-DIMENS                                             08370013
MEMSTR   EQU   X'20'                   MEMBER OF A STRUCTURE            08400013
NOTSTR   EQU   X'DF'                   NOT STRUCTURE MEMBER             08430013
VALPOS   EQU   X'10'                   VALUE LIST FOR LABEL VARIABLES   08460013
*                                    OR POS FOR DEFINED ITEMS           08490013
INVLIK   EQU   X'08'                   LIKE IF A STRUCTURE AND INITIAL  08520013
*                                      VALUE OTHERWISE                  08550013
CODBYT   EQU   X'04'                   CODE BYTES (OTHER5 AND OTHER6)   08580013
DEFND    EQU   X'02'                   DEFINED                          08610013
NPOS     EQU   X'EF'                   COMPLEMENT OF 'POS'              08640013
NINVLK   EQU   X'FF'-INVLIK                                             08670013
         SPACE 2                                                        08700013
*              THE 'OTHER2' BYTE                                        08730013
OTHER2   EQU   VARBLE+1                OFFSET FROM HEAD OF AT.COL.AREA  08760013
         SPACE                                                          08790013
DYNDEF   EQU   X'80'                   DYNAMICALLY DEFINED              08820013
DFISUB   EQU   X'40'                   DEFINED WITH ISUB                08850013
ABNORM   EQU   X'20'                   ABNORMAL / NORMAL                08880013
NORMAB   EQU   X'DF'                   NORMAL                           08910013
SCNDRY   EQU   X'10'                   SECONDARY                        08940013
FMPRAM   EQU   X'08'                   FORMAL PARAMETER                 08970013
EXTINT   EQU   X'04'                   EXTERNAL / INTERNAL              09000013
INTEXT   EQU   X'FB'                   INTERNAL                         09030013
CNTRLD   EQU   X'03'                   CONTROLLED                       09060013
STATIC   EQU   X'01'                   STATIC                           09090013
AUTOMC   EQU   X'00'                   AUTOMATIC                        09120013
NSTAT    EQU   X'FD'                   STATIC MASK FOR ANDING           09150013
NAUTO    EQU   X'FC'                   AUTOMATIC MASK FOR ANDING        09180013
         SPACE 2                                                        09210013
*              THE 'OTHER3' BYTE                                        09240013
         SPACE                                                          09270013
OTHER3   EQU   OTHER2+1                OFFSET FROM HEAD OF AT.COL.AREA  09300013
         SPACE                                                          09330013
DVREQ    EQU   X'80'                   DOPE VECTOR REQUIRED             09360013
DEDREQ   EQU   X'40'                   DED REQUIRED                     09390013
NOSTOR   EQU   X'20'                   NO STORAGE REQUIRED FOR THE ITEM 09420013
ARISTO   EQU   X'10'                   ARISTOCRATIC                     09450013
CHAMEL   EQU   X'08'                   CHAMELEON                        09480013
NEGVO    EQU   X'04'                   NEGATIVE VIRTUAL ORIGIN          09510013
GVLRUB   EQU   X'02'                   GOOD VALUE / RUBBISH             09540013
GVRBSA   EQU   X'01'                   GOOD VALUE / RUBBISH (FOR        09570013
*                                    SECOND ADDRESS SLOT)               09600013
         SPACE 2                                                        09630013
*              THE 'OTHER4' BYTE                                        09660013
         SPACE                                                          09690013
OTHER4   EQU   OTHER3+1                OFFSET FROM HEAD OF AT.COL.AREA  09720013
PAMBIT   EQU   X'80'                   POSSIBLY AMBIGUOUS BIT           09750013
BNDCH    EQU   X'40'                   CHANGE OF BOUNDARY IN A STORAGE  09780013
*                                    CLASS CHAIN                        09810013
TEMTY2   EQU   X'20'                   TEMPORARY TYPE 2                 09840013
DFNDST   EQU   X'10'                   DEFINED STRUCTURE MEMBER (NOT    09870013
*                                    SET BY DCL PASS TWO).              09900013
ALGPAK   EQU   X'08'                   ALIGNED / PACKED                 09930013
PAKALG   EQU   X'F7'                   PACKED                           09960013
MAJSTR   EQU   X'04'                   MAJOR STRUCTURE                  09990013
NAJSTR   EQU   X'FB'                                                    10020013
         SPACE 2                                                        10050013
*              THE 'DATA' BYTE                                          10080013
         SPACE                                                          10110013
DATABT   EQU   OTHER4+1                OFFSET FROM HEAD OF AT.COL.AREA  10140013
         SPACE                                                          10170013
CANSTR   EQU   X'80'                   CAD OR NF / STRING               10200013
DSTRNG   EQU   X'7F'                   STRING                           10230013
         SPACE                                                          10260013
*              DEPENDING ON THE VALUE OF THE FIRST BIT, THE REMAINING   10290013
*        BITS HAVE TWO POSSIBLE INTERPRETATIONS                         10320013
         SPACE                                                          10350013
*              FOR CAD OR NF                                            10380013
         SPACE                                                          10410013
PINTER   EQU   X'C0'                   POINTER.                         10440013
STERLG   EQU   X'A0'                   STERLING                         10470013
LNGSHT   EQU   X'90'                   LONG / SHORT                     10500013
CADNF    EQU   X'88'                   CAD / NF                         10530013
BINDEC   EQU   X'84'                   BINARY / DECIMAL                 10560013
FLTFXD   EQU   X'82'                   FLOAT / FIXED                    10590013
COMPRL   EQU   X'81'                   COMPLEX / REAL                   10620013
         SPACE 2                                                        10650013
*              FOR STRINGS                                              10680013
ADJLTH   EQU   X'40'                   ADJUSTABLE LENGTH                10710013
FXMAX    EQU   X'BF'                   FIXED MAX LENGTH                 10740013
ALIGN    EQU   X'20'                   ALIGNED                          10770013
PACK     EQU   X'DF'                   PACKED                           10800013
VARYNG   EQU   X'10'                   VARYING                          10830013
NOPICT   EQU   X'08'                   NO PICTURE / PICTURE             10860013
PICT     EQU   X'F7'                   PICTURE                          10890013
BIT      EQU   X'FB'                   BIT                              10920013
CHAR     EQU   X'04'                   CHARACTER                        10950013
AREA     EQU   X'02'                   AREA.                            10980013
NADJCH   EQU   X'FF'-ADJLTH                                             11010015
         SPACE 2                                                        11040013
CDFLAG   EQU   DATABT+1                OFFSET OF PRIVATE FLAGS (TO 2ND  11070013
*                                    PASS DECLARE                       11100013
         SPACE 2                                                        11130013
GENFG1   EQU   X'80'                   GENERIC FLAG 1                   11160013
GENFG2   EQU   X'40'                   GENERIC FLAG 2                   11190013
NEWBLK   EQU   X'20'                   'TEMPORARY SCAN IS IN A          11220013
*                                    DIFFERENT BLOCK FROM REAL SCAN'BIT 11250013
FPSTRC   EQU   X'10'                   FORMAL PARAMETER AND STRUCTURE   11280013
*                                    MEMBER                             11310013
NODICT   EQU   X'08'                   'DO NOT BUILD A DICT ENTRY' FLAG 11340013
PRDATA   EQU   X'04'                   'DATA ATTRIBUTE HAS BEEN APPLIED 11370013
*                                    FLAG                               11400013
PRFILE   EQU   X'02'                   'FILE ATTRIBUTE HAS BEEN APPLIED 11430013
*                                    FLAG                               11460013
NOGENS   EQU   X'3F'                   MASK USED FOR TURNING OFF BOTH   11490013
*                                    GENFG1 AND GENFG2.                 11520013
NOTGNF   EQU   X'C0'                   MASK FOR TURNING OFF ALL EXCEPT  11550013
*                                    GENFLAGS1 AND 2.                   11580013
PREC1    EQU   X'01'                 'PRECISION 1 HAS BEEN GIVEN'       11610013
         SPACE 4                                                        11640013
FLAGS    EQU   TYPBYT+8                OFFSET OF FLAG AREA              11670013
         SPACE 2                                                        11700013
*              FIRST FLAG BYTE                                          11730013
         SPACE                                                          11760013
CFLAG1   EQU   X'80'                   CFLAG1, I.E. THE FIRST LETTER OF 11790013
*                                    THE CURRENT IDENTIFIER IS IN THE   11820013
*                                    RANGE I - N.                       11850013
CFLAG2   EQU   X'40'                   CFLAG2, I.E. THE CURRENT         11880013
*                                    IDENTIFIER IS AN ENTRY NAME WITH   11910013
*                                    PARAMETER DESCRIPTION.             11940013
CFLAG3   EQU   X'20'                   CFLAG3, I.E. THE DICTIONARY      11970013
*                                    ENTRY TO BE CONSTRUCTED MUST HAVE  12000013
*                                    BCD APPENDED.                      12030013
CFLAG4   EQU   X'10'                   CFLAG4, I.E. THE CURRENT         12060013
*                                    IDENTIFIER IS A STRUCTURE MEMBER.  12090013
CFLAG5   EQU   X'08'                   CFLAG5, I.E. THE CURRENT         12120013
*                                    IDENTIFIER IS A MAJOR STRUCTURE.   12150013
CFLAG6   EQU   X'04'                   CFLAG6, I.E. THE CURRENT         12180013
*                                    IDENTIFIER HAS HAD A LEVEL NUMBER  12210013
*                                    APPLIED TO IT.                     12240013
CFLAG7   EQU   X'02'                   CFLAG7, I.E. THE CURRENT         12270013
*                                    IDENTIFIER HAS THE SAME BCD AS     12300013
*                                    ANOTHER IDENTIFIER IN THE SAME     12330013
*                                    BLOCK                              12360013
CFLAG8   EQU   X'01'                   CFLAG8, I.E. THE SCAN IS INSIDE  12390013
*                                    A PARENTHESISED LIST, USING CSTCK3 12420013
CFLG48   EQU   X'11'                   CFLAGS 4 AND 8                   12450013
CFLS45   EQU   CFLAG4+CFLAG5           CFLAGS 4 AND 5.                  12480013
         SPACE 2                                                        12510013
*              SECOND FLAG BYTE                                         12540013
         SPACE                                                          12570013
CFLAG9   EQU   X'80'                   CFLAG9, I.E. THE CURRENT         12600013
*                                    IDENTIFIER IS THE LAST ONE IN THE  12630013
*                                    CURRENT DECLARE STATEMENT.         12660013
CFLA10   EQU   X'40'                   CFLAG10, I.E. A GENERIC ENTRY IS 12690013
*                                    BEING PROCESSED                    12720013
CFLA11   EQU   X'20'                   CFLAG11, I.E. THE CURRENT        12750013
*                                    BUILT-IN FUNCTION IS OF GENERIC    12780013
*                                    TYPE                               12810013
*                                    THE CURRENT ATTRIBUTE CANNOT BE    12840013
*                                    APPLIED.                           12870013
CFLA12   EQU   X'10'                   CFLAG12, I.E. THE CURRENT        12900013
*                                    ATTRIBUTE IS TO BE SKIPPED OVER,   12930013
*                                    AND NOT PROCESSED.                 12960013
CFLA13   EQU   X'08'                   CFLAG13, I.E. INHIBIT CADD1      12990013
*                                    PROCESSES.                         13020013
CFLA14   EQU   X'04'                   CFLAG14, I.E. STORE THE          13050013
*                                    ATTRIBUTE POINTER ON FINDING THE   13080013
*                                    FIRST COMMA.                       13110013
CFLA15   EQU   X'02'                   CFLAG15, I.E. ON FINDING A RIGHT 13140013
*                                    FACTOR BRACKET, REDUCE 'COUNT2' BY 13170013
*                                    ONE AND UPDATE 'CURRENT'.          13200013
CFLA16   EQU   X'01'                   CFLAG16, I.E. THE CURRENT        13230013
*                                    IDENTIFIER IS AN INTERNAL ENTRY    13260013
*                                    LABEL                              13290013
         SPACE 2                                                        13320013
*              ONE'S COMPLEMENT OF CFLAGS                               13350013
         SPACE                                                          13380013
NFLAG1   EQU   X'7F'                   ONE'S COMP FOR CFLAG1 (FOR AND)  13410013
NFLAG2   EQU   X'BF'                   ONE'S COMP FOR CFLAG2 (FOR AND)  13440013
NFLAG3   EQU   X'DF'                   ONE'S COMP FOR CFLAG2 (FOR AND)  13470013
NFLAG4   EQU   X'EF'                   ONE'S COMP FOR CFLAG4 (FOR AND)  13500013
NFLAG5   EQU   X'F7'                   ONE'S COMP FOR CFLAG5 (FOR AND)  13530013
NFLAG6   EQU   X'FB'                   ONE'S COMP FOR CFLAG6 (FOR AND)  13560013
NFLAG7   EQU   X'FD'                   ONE'S COMP FOR CFLAG7 (FOR AND)  13590013
NFLAG8   EQU   X'FE'                   ONE'S COMP FOR CFLAG8 (FOR AND)  13620013
         SPACE 2                                                        13650013
NFLAG9   EQU   NFLAG1                                                   13680013
NFLA10   EQU   NFLAG2                                                   13710013
NFLA11   EQU   NFLAG3                                                   13740013
NFLA12   EQU   NFLAG4                                                   13770013
NFLA13   EQU   NFLAG5                                                   13800013
NFLA14   EQU   NFLAG6                                                   13830013
NFLA15   EQU   NFLAG7                                                   13860013
NFLA16   EQU   NFLAG8                                                   13890013
         SPACE 4                                                        13920013
DATINF   EQU   FLAGS+2                 OFFSET OF DATA INFORMATION       13950013
PICTAB   EQU   DATINF+4                OFFSET OF PICTURE TABLE ADDRESS  13980013
DCLNUM   EQU   PICTAB+2                OFFSET OF DECLARE NUMBER         14010013
LEVEL    EQU   DCLNUM+2                OFFSET OF LEVEL                  14040013
COUNT    EQU   LEVEL+1                 OFFSET OF COUNT                  14070013
BCDTRF   EQU   COUNT+1                 OFFSET OF TEXT REFERENCE TO THE  14100013
*                                    BCD                                14130013
LINK     EQU   BCDTRF+4                OFFSET OF LINK                   14160013
ASTFLG   EQU   LINK+4                  OFFSET OF THE              28459 14170019
*                                      'INCORRECT * DIMS.' FLAG.  28459 14180019
MDCFLG   EQU   ASTFLG+1                OFFSET OF THE 'POSSIBLE    27216 14185019
*                                    MULTIPLE DCL' FLAG.          27216 14190019
MAJBCD   EQU   X'08'                   CURRENT IDENTIFIER IS A    27169 14195020
*                                    MAJOR STRUCTURE.             27216 14200019
MBEBCD   EQU   X'88'                   CURRENT IDENTIFIER IS A    27169 14205020
*                                    MINOR STRUCTURE/BASE ELEMENT.27216 14210019
MDCEPR   EQU   X'10'                   CURRENT IDENTIFIER HAS     27169 14211020
*                                    SAME BCD AS EXTERNAL PROC.   27169 14212020
MDEHCS   EQU   X'01'                   END OF HASH CHAIN SCAN FLG 27169 14213020
TESTMK   EQU   MDCFLG+1                OFFSET OF TEST MASK.       27216 14215019
         SPACE                                                          14220019
*              OFFSETS WITHIN VARIABLE INFORMATION                      14230015
DIMINF   EQU   TESTMK+6                OFFSET OF DIMENSION INFORMATION  14250013
STRUCT   EQU   DIMINF+4                OFFSET OF STRUCTURE INFORMATION  14280013
POS      EQU   STRUCT+10               OFFSET OF POS                    14310013
LIKINV   EQU   POS+2                   OFFSET OF INITIAL VALUE OR LIKE  14340013
         SPACE 2                                                        14370013
OTHER5   EQU   LIKINV+4                OTHER5 CODE BYTE.                14400013
         SPACE                                                          14430013
PNTEXP   EQU   X'80'                   'POINTER VARIABLE EXPRESSION'    14460013
*                                    HAS BEEN SEEN INSIDE A POINTER     14490013
*                                    ATTRIBUTE.                         14520013
LIST     EQU   X'40'                   LIST ATTRIBUTE APPLIED.          14550013
         SPACE 2                                                        14580013
OTHER6   EQU   OTHER5+1                OTHER6 CODE BYTE.                14610013
         SPACE 2                                                        14640013
DEFINF   EQU   OTHER6+1                DEFINED INFORMATION.             14670013
LKIVOF   EQU   DEFINF+8                OFFSET OF LIKE/INITIAL INFO'     14700013
         SPACE 2                                                        14730013
*              THE VARIABLE INFORMATION REGION OF THE ATTRIBUTE         14760013
*        COLLECTION AREA HAS THE FOLLOWING ALTERNATIVE MEANING FOR A    14790013
*        FILE ATTRIBUTE                                                 14820013
         SPACE 2                                                        14850013
ENVIR    EQU   TESTMK+6                DICTIONARY REFERENCE OF          14880013
*                                    ENVIRONMENT ENTRY.                 14910013
NOATTS   EQU   ENVIR+4                 FULL WORD CONTAINING THE NUMBER  14940013
*                                    OF OTHER ATTRIBUTES THAT HAVE      14970013
*                                    BEEN APPLIED. NOTE THAT SINCE THE  15000013
*                                    ATTRIBUTE COLLECTION AREA IS HALF  15030013
*                                    WORD ALIGNED THIS ITEM WILL BE     15060013
*                                    FULL WORD ALIGNED.                 15090013
ATTENT   EQU   NOATTS+1                START OF WHAT WILL BE SKELETON   15120013
*                                    OF ENTRY FOR OTHER ATTRIBUTES.     15150013
ATTLST   EQU   NOATTS+4                START OF LIST OF OTHER ATTRIB-   15180013
*                                    -UTES APPLIED.                     15210013
         SPACE 4                                                        15240013
*              THE REMAINING REGION IS COMMON TO BOTH FILES AND DATA    15270013
COUNT1   EQU   LKIVOF+2                OFFSET OF COUNT1                 15300013
COUNT2   EQU   COUNT1+4                OFFSET OF COUNT2                 15330013
COUNT3   EQU   COUNT2+4                OFFSET OF COUNT3                 15360013
CADD1    EQU   COUNT3+4                OFFSET OF CADD1                  15390013
CADD2    EQU   CADD1+4                 OFFSET OF CADD2                  15420013
CADD3    EQU   CADD2+4                 OFFSET OF CADD3                  15450013
         SPACE                                                          15480013
*              END OF ATT. COL. AREA                                    15510013
ACALTH   EQU   CADD3+4                 LENGTH OF ATT.COLL.AREA          15540013
         EJECT                                                          15570013
*              THE SCRATCH CORE WORKSPACE                               15600013
         SPACE 2                                                        15630013
*              THIS WORKSPACE FOLLOWS IMMEDIATELY AFTER THE ATT.COLL.   15660013
*        AREA                                                           15690013
         SPACE 4                                                        15720013
CASPAC   EQU   CADD3+8                 WORKSPACE FOR ROUTINE 'CHASH'    15750013
         SPACE                                                          15780013
REGST    EQU   CASPAC+32               REGISTER SAVE AREA FOR ROUTINE   15810013
*                                   'CDCLSC'.                           15840013
         SPACE                                                          15870013
STM      EQU   REGST+64                REGISTER SAVE AREA FOR ROUTINES  15900013
*                                   'CDICEN', AND 'CDFLT'.              15930013
         SPACE                                                          15960013
PREPST   EQU   STM+64                  REGISTER STORAGE FOR        H344 16010019
*                                    ROUTINE 'PREPRC'.             H344 16060019
LISTOF   EQU   PREPST+4                WORD USED TO GIVE THE OFFSET OF  16110013
*                                    THE NEXT AVAILABLE SLOT IN A       16140013
*                                    GENERIC ENTRY WHEN PROCESSING A    16170013
*                                    GENERIC LIST.                      16200013
PSSTOR   EQU   LISTOF+4                REG. STORAGE FOR ROUTINE PSPROC. 16230013
SCR1     EQU   PSSTOR+4                TEXT REFERENCE OF BCD       H344 16236019
*                                    LENGTH BYTE.                  H344 16242019
BLDARA   EQU   SCR1+4                  DICTIONARY ENTRY BUILD AREA H344 16248019
*                                    (300 BYTES OF SCRATCH REMAIN) H344 16254019
         EJECT                                                          16260013
*              DEFINITION OF SYMBOLIC LABELS                            16290013
         SPACE 4                                                        16320013
*              SYMBOLIC LABELS ARE DEFINED IN THE FOLLOWING GROUPS      16350013
         SPACE 2                                                        16380013
*                  1. SYMBOLIC LABELS FOR INTERNAL CODE                 16410013
         SPACE                                                          16440013
*                  2. BRANCH MNEMONICS                                  16470013
         SPACE                                                          16500013
*                  3. SYMBOLIC LABELS FOR COMPILER CONTROL ROUTINES     16530013
         SPACE                                                          16560013
*                  4. SYMBOLIC LABELS FOR COMMUNICATIONS REGION         16590013
         SPACE                                                          16620013
*                  5. SYMBOLIC LABELS FOR COMMUNICATIONS REGION (DICT.  16650013
*                     SECTION).                                         16680013
         SPACE                                                          16710013
*                  6. SYMBOLIC LABELS FOR INITIAL CODE BYTES OF DICT.   16740013
*                     ENTRIES                                           16770013
         SPACE                                                          16800013
*                  7. SYMBOLIC LABELS FOR DCL PASS II ROUTINES CALLED   16830013
*                     BY THIS CONTROL SECTION                           16860013
         SPACE                                                          16890013
*                  8. MISCELLANEOUS SYMBOLIC LABELS FOR THIS CONTROL    16920013
*                     SECTION                                           16950013
         EJECT                                                          16980013
*              SYMBOLIC LABELS FOR INTERNAL CODE                        17010013
         SPACE 4                                                        17040013
CDXI     EQU   X'19'                   LETTER I                         17070013
CDXN     EQU   X'25'                   LETTER N                         17100013
COMMA    EQU   X'41'                   COMMA                            17130013
LBRCKT   EQU   X'43'                   LEFT BRACKET                     17160013
LBRKT    EQU   LBRCKT                                                   17190013
RBRCKT   EQU   X'45'                   RIGHT BRACKET                    17220013
RBRKT    EQU   RBRCKT                                                   17250013
LFBRKT   EQU   X'51'                   LEFT FACTOR BRACKET              17280013
RFBRKT   EQU   X'71'                   RIGHT FACTOR BRACKET             17310013
ALCATE   EQU   X'81'                   ALLOCATE STATEMENT               17340013
INTLAB   EQU   X'AB'                   INITIAL LABEL                    17370013
DCLARE   EQU   X'AD'                   DECLARE STATEMENT                17400013
ATTMKR   EQU   X'C8'                   SECOND LEVEL MARKER              17430013
ETB      EQU   X'ED'                   END OF TEXT BLOCK                17460013
SEMCLN   EQU   X'EF'                   SEMICOLON                        17490013
FXDCRL   EQU   X'F5'                   CONSTANT MARKER (FIXED,DEC,REAL) 17520013
FXBNRL   EQU   X'F7'                   CONSTANT MARKER (FIXED,BIN,REAL) 17550013
CDISUB   EQU   X'FE'                   ISUB MARKER                      17580013
ENDBLK   EQU   X'ED'                   END OF TEXT BLOCK MARKER         17610013
DCBLK1   EQU   X'40'                   'TEXT REF OF CURRENT DCL STMNT'  17640013
*                                    SLOT                               17670013
DCBLK2   EQU   X'44'                   'TEXT REF OF CURRENT DCL STMNT.  17700013
*                                    (IF IN DUMMY SCAN)' SLOT.          17730013
         SPACE 4                                                        17760013
*              ATTRIBUTE CODES.                                         17790013
ATINTR   EQU   X'61'                   INTERNAL                         17820013
ATEXTR   EQU   X'60'                   EXTERNAL                         17850013
ATENVR   EQU   X'8A'                   ENVIRONMENT                      17880013
ATFILE   EQU   X'10'                   FILE                             17910013
ATKEYD   EQU   X'83'                   KEYED                            17940013
         EJECT                                                          17970013
*              BRANCH MNEMONICS                                         18000013
         SPACE 4                                                        18030013
B        EQU   15                                                       18060013
BR       EQU   15                                                       18090013
         SPACE                                                          18120013
NOP      EQU   0                                                        18150013
NOPR     EQU   0                                                        18180013
         SPACE                                                          18210013
BH       EQU   2                                                        18240013
BL       EQU   4                                                        18270013
BE       EQU   8                                                        18300013
BLE      EQU   12                                                       18330013
         SPACE                                                          18360013
BNH      EQU   13                                                       18390013
BNL      EQU   11                                                       18420013
BNE      EQU   7                                                        18450013
         SPACE                                                          18480013
BO       EQU   1                                                        18510013
BZ       EQU   8                                                        18540013
BM       EQU   4                                                        18570013
         SPACE                                                          18600013
BNO      EQU   14                                                       18630013
BNZ      EQU   7                                                        18660013
BNM      EQU   11                                                       18690013
         SPACE                                                          18720013
BP       EQU   2                                                        18750013
         EJECT                                                          18780013
*              SYMBOLIC LABELS FOR COMPILER CONTROL ROUTINES            18810013
         SPACE 4                                                        18840013
ZUGC     EQU   X'10'                   GET CORE                         18870013
ZUTXTC   EQU   X'14'                                                    18900013
ZURC     EQU   X'18'                   RELEASE CORE                     18930013
ZABORT   EQU   X'20'                   ABORT                            18960013
ZLOADW   EQU   X'24'                   LOAD AND WAIT                    18990013
ZDICAB   EQU   X'28'                   MAKE DICT. ENTRY, RETURN ABS.    19020013
ZABOF    EQU   ZDICAB                                                   19050013
ZDICRF   EQU   X'2C'                   MAKE DICT. ENTRY, RETURN REF.    19080013
ZUERR    EQU   X'30'                   MAKE DICT. ENTRY FOR ERROR MESS. 19110013
ZDRFAB   EQU   X'34'                   DICT.REF. TO ABSOLUTE            19140013
REQEST   EQU   X'40'                   PHASE REQUEST                    19170013
RLSCTL   EQU   X'48'                   RELEASE CONTROL                  19200013
ZTXTRF   EQU   X'50'                   ABSOLUTE TO TEXT.REF.            19230013
ZTXTAB   EQU   X'54'                   TEXT.REF. TO ABSOLUTE            19260013
ZDABRF   EQU   X'60'                   ABSOLUTE TO DICT.REF.            19290013
ZCHAIN   EQU   X'58'                   PICK UP NEXT TEXT BLOCK IN CHAIN 19320013
ZALTER   EQU   X'5C'                   ALTER TEXT BLOCK STATUS          19350013
         EJECT                                                          19380013
*              SYMBOLIC LABELS FOR COMMUNICATIONS REGION                19410013
         SPACE 4                                                        19440013
MYNAME   EQU   X'70'                   PHASE NAME                       19470013
PAR1     EQU   X'80'                   PARAMETERS PASSED TO COMPILER    19500013
PAR2     EQU   PAR1+4                CONTROL                            19530013
PAR3     EQU   PAR2+4                                                   19560013
PAR4     EQU   PAR3+4                                                   19590013
PAR5     EQU   PAR4+4                                                   19620013
PAR6     EQU   PAR5+4                                                   19650013
PAR7     EQU   PAR6+4                                                   19680013
PAR8     EQU   PAR7+4                                                   19710013
ZSTAT    EQU   X'7C'                   STATEMENT NUMBER                 19740013
STEXOF   EQU   X'100'                  START OF TEXT                    19770013
ZLOCK    EQU   X'112'                  LOCK SLOT.                       19800013
         EJECT                                                          19830013
*              SYMBOLIC LABELS FOR COMMUNICATIONS REGION (DICT.SECTION) 19860013
         SPACE 4                                                        19890013
ZCOMM    EQU   304                                                      19920013
ZFLAG2   EQU   ZCOMM+17                FLAG BYTE 2.                     19980013
ZINTST   EQU   X'40'                   STATIC INITIAL VARIABLES EXIST.  20010013
ZFLAG3   EQU   ZCOMM+18                FLAG BYTE 3                      20040013
ZINTAC   EQU   X'01'                   AUTO/CTL INITIALISATION.         20070013
HASHHD   EQU   ZCOMM+28                POINTER TO HASH TABLE            20100013
ZFATTS   EQU   ZCOMM+36                POINTER TO FACTORED ATT. TABLE   20130013
ZPROC1   EQU   ZCOMM+64                HEAD OF E.T.1 CHAIN        27169 20140020
ZDEFCH   EQU   ZCOMM+74                HEAD OF CHAIN OF DEFINED ITEMS   20160013
DFNCHN   EQU   ZCOMM+74                DEFINED CHAIN                    20190013
ZLIKCH   EQU   ZCOMM+82                HEAD OF CHAIN OF LIKE ITEMS      20220013
ZPOLCH   EQU   ZCOMM+84                HEAD OF CHAIN OF POOL ITEMS      20250013
         EJECT                                                          20280013
*              SYMBOLIC LABELS FOR INITIAL CODE BYTES OF DICT.ENTRIES   20310013
         SPACE 4                                                        20340013
CONST    EQU   X'88'                                                    20370013
FMPAR1   EQU   X'40'                                                    20400013
PELBL    EQU   X'01'                                                    20430013
E2BYT    EQU   X'85'                   ENTRY TYPE 2 CODE BYTE.          20460013
          EJECT                                                         20470019
*              SYMBOLIC LABELS FOR DCL PASS II ROUTINES CALLED BY       20490013
*        CONTROL SECTION IEMEL                                          20520013
          SPACE 4                                                       20560019
CDICEN   EQU   2                       BUILD DICT.ENTRY, IEMEM          20610013
CDFATT   EQU   6                       APPLY FACTORED ATTRIBUTES, IEMEM 20640013
CDIMAT   EQU   10                      APPLY IMPLICIT ATTRIBUTES, IEMEM 20670013
CDFLT    EQU   14                      APPLY DEFAULT ATTRIBUTES, IEMEM  20700013
CDATPR   EQU   14                      ATTRIBUTE PROCESSOR, IEMEK       20730013
SAVE2    EQU   X'24'                   ATTRIBUTE PROCESSOR, IEMEK.28459 20760019
SECOP    EQU   X'1C'                                                    20790013
SECOP2   EQU   X'20'                                                    20820013
ERROR    EQU   X'18'                   ERROR ROUTINE                    20850013
DEE3X2   EQU   X'16'                   SLOT TO TAKE DICT.REF.OF ENTRY   20880013
*                                    TYPE 3.                            20910013
CHASH    EQU   X'24'                   HASHING ROUTINE, IEMEM.          20940013
TMPAR8   EQU   X'50'                                                    20970013
BLANK    EQU   X'12'                   BLANKING OUT ROUTINE, IEMEK.     21000013
FACLVN   EQU   X'16'                   FACTORED LEVEL NO.RTN., IEMEK.   21010015
INTPRC   EQU   X'28'                   'INITIAL' POST-PROCESSER (MODULE 21030013
*                                    IEMEM).                            21060013
BCDISB   EQU   X'14'                   IN IEMED                   REPAK 21070020
         EJECT                                                          21090013
*              MISCELLANEOUS SYMBOLIC LABELS FOR CONTROL SECTION IEMEL  21120013
         SPACE 4                                                        21150013
SL       EQU   X'D2'                   INITIAL CODE BYTE OF STATEMENT   21180013
*                                    WITH LABEL                         21210013
SN       EQU   X'D0'                   INITIAL CODE BYTE OF STATEMENT   21240013
*                                    WITH ONLY NUMBER                   21270013
STK3AD   EQU   X'1C'                   SLOT IN IEMEK FOR CSTCK3 ADDRESS 21300013
STK3PT   EQU   X'20'                   SLOT IN IEMEK FOR CSTCK3 POINTER 21330013
STTNUM   EQU   8                       OFFSET OF SLOT FOR STATEMENT NO. 21360013
*                                    IN STATEMENT LABEL DICT. ENTRY     21390013
ZL1      EQU   LEVEL-1                 LENGTH FIELD IN MVC INSTRUCTION  21420013
ZL2      EQU   COUNT1-ASTFLG-1         LENGTH FIELD IN MVC INSTR. 28459 21450019
ZL3      EQU   DCLNUM-DATINF-1         LENGTH FIELD IN MVC INSTRUCTION  21480013
ZL4      EQU   FLAGS-4                                            33884 21510020
ZL5      EQU   LINK-BCDTRF-1           LENGTH FIELD IN MVC INSTRUCTION  21540013
DINVAR   EQU   16                      DATA INF. OFFSET                 21570013
SLTREF   EQU   7                       DICT.REF.OFFSET IN 2ND. FILE     21600013
FSTLBP   EQU   7                       OFFSET OF PROC LABEL DIC.  27169 21610020
*                                    REF. IN PROC E.T.1.          27169 21620020
E3INE2   EQU   3                       OFFSET OF REFERENCE TO ENTRY     21630013
*                                    TYPE 3 IN ENTRY TYPE 2.            21660013
DINE2    EQU   9                       DATA INFO OFFSET IN ENTRY TYPE 2 21690013
EXE4E2   EQU   6                       EXCESS OF ABOVE OFFSET IN E4     21720013
NMDMOF   EQU   5                       OFFSET OF NO.OF DIMS IN DIMTABLE 21750013
FRSTBD   EQU   12                      OFFSET OF 1ST.BOUND IN DIM TABLE 21780013
ITEMRF   EQU   12                      OFFSET OF DICT.REF. OF ITEM      21810013
*                                    WHOSE SDV, ADV OR OTHER STATEMENT  21840013
*                                    THIS IS.                           21870013
GNFSDR   EQU   11                      OFFSET IN A GENERIC ENTRY OF     21900013
*                                    FIRST REFERENCE TO AN ITEM WHICH   21930013
*                                    WAS IN THE GENERIC LIST.           21960013
GENOF3   EQU   10                      OFFSET IN GENERIC FUNCTION ENTRY 21990013
*                                    OF 2* NUMBER OF FAMILY MEMBERS.    22020013
STOTH1   EQU   10                      OFFSET OF OTHER1 BYTE IN         22050013
*                                    STRUCTURE DICTIONARY ENTRY.        22080013
STOTH4   EQU   14                      OFFSET OF OTHER4 BYTE IN         22110013
*                                    STRUCTURE DICT ENTRY.              22140013
         SPACE 5                                                        22170013
*              FORMAT OF AN ENTRY IN CSTACK3.  STK3PT POINTS AT THE     22200013
*        CURRENT ENTRY. CSTACK3 IS USED WHEN PROCESSING A GENERIC OR    22230013
*        ENTRY DECLARATION.                                             22260013
         SPACE                                                          22290013
FLAG     EQU   0                       FLAG BYTE WITH THE FOLLOWING     22320013
*                                    FLAGS                              22350013
FLGON    EQU   X'80'                   MASKS USED FOR COPYING GFLAG12   22380013
FLGOFF   EQU   X'7F'                 INTO THE STACK, AND FOR TURNING    22410013
*                                    THE COPY OFF.                      22440013
FL9ON    EQU   X'40'                   THE SAME FOR CFLAG 9             22470013
FL9OFF   EQU   X'BF'                                                    22500013
         SPACE                                                          22530013
POINTR   EQU   FLAG+1                  SLOT TO TAKE COPY OF SCAN        22560013
*                                    POINTER.                           22590013
LINK1    EQU   POINTR+3                SLOT TO TAKE RETURN LINK SET     22620013
*                                    FOR 'CDICEN' ROUTINE.              22650013
LINK2    EQU   LINK1+4                 SLOT TO TAKE RETURN LINK FOR     22680013
*                                    RETURN FROM ATTRIBUTE ROUTINE.     22710013
REF1     EQU   LINK2+4                                                  22740013
REF2     EQU   REF1+2                                                   22770013
         DC    C'EL'                                                    22800013
         SPACE 4                                                        22830013
*              TRANSFER INSTRUCTIONS TO ROUTINES IN THIS BLOCK          22860013
         SPACE 1                                                        22890013
         BC    B,STRPR                                                  22920013
         BC    B,PSPROC                                                 22950013
         BC    B,CDCLSC                                                 22980013
         BC    B,NHERIT                                                 23010013
         SPACE 4                                                        23040013
LSTRCF   DC    H'0'                    SLOT CONTAINING OFFSET OF THE    23070013
*                                    'FORWARD CHAIN SLOT' IN DICT.      23100013
*                                    ENTRY FOR MOST RECENT STRUCTURE    23130013
*                                    MEMBER.                            23160013
         SPACE 2                                                        23190013
CURENT   DC    F'0'                    POINTER TO FACTORED ATTRIBUTE    23220013
*                                    TABLE                              23250013
         SPACE                                                          23280013
MAX      DC    F'0'                    POINTER TO FACTORED ATTRIBUTE    23310013
         SPACE                                                          23340013
ACDT1    DC    F'0'                    POINTER TO HEAD OF STRUCTURE     23370013
*                                    TABLE (MINUS 4).                   23400013
BLANK1   DC    F'0'                    POINTERS FOR BLANKING OUT        23430013
BLANK2   DC    F'0'                  RUUTINE. (NEED NOT BE IN TRANSFER  23460013
*                                    VECTOR).                           23490013
CLEVEL   DC    X'00'                   CURRENT BLOCK LEVEL              23520013
CCOUNT   DC    X'00'                   CURRENT BLOCK COUNT              23550013
GENREF   DC    H'0'                    SLOT FOR DICT REF OF GENERIC     23580013
*                                    ITEM. (NEED NOT BE IN TRANSFER     23610013
*                                    VECTOR).                           23640013
NXSPST   DC    F'0'                    STORAGE FOR 'NEXT SCAN POINTER'  23670013
NEWDIC   DC    H'0'                                                     23700013
REFST    DC    H'0'                                                     23730013
PRESNT   DC    X'00'                   LEVEL NUMBER OF PRESENT ITEM     23760013
NEXT     DC    X'00'                   LEVEL NUMBER OF NEXT ITEM        23790013
         EJECT                                                          23820013
*              TABLE OF INITIALISING MASKS                              23850013
         SPACE 4                                                        23880013
*              WHEN IT IS DECIDED WHAT TYPE OF IDENTIFIER IS BEING      23910013
*        PROCESSED, ONE OF THE MASKS IS CHOSEN FROM THIS TABLE, AND IS  23940013
*        MOVED INTO THE TEST MASK IN THE ATTRIBUTE COLLECTION AREA      23970013
*              THE PRESENCE OF A 'ONE' BIT(CORRESPONDING TO A CERTAIN   24000013
*        ATTRIBUTE) IN THE MASK, MEANS THAT THE ATTRIBUTE IS APPLICABLE 24030013
*        TO THAT TYPE OF IDENTIFIER. THE PRESENCE OF A ZERO BIT MEANS   24060013
*        THAT IT IS NOT APPLICABLE.                                     24090013
         SPACE 3                                                        24120013
*              DESCRIPTION OF EACH MASK                                 24150013
         SPACE 3                                                        24180013
*        MASK  1    FORMAL PARAMETERS WHICH ARE NOT MEMBERS OF A        24210013
*                   STRUCTURE.                                          24240013
         SPACE 2                                                        24270013
*        MASK  2    FORMAL PARAMETERS WHICH ARE MAJOR STRUCTURES.       24300013
         SPACE 2                                                        24330013
*        MASK  3    FORMAL PARAMETERS WHICH ARE MINOR STRUCTURES.       24360013
         SPACE 2                                                        24390013
*        MASK  4    FORMAL PARAMETERS WHICH ARE BASE ELEMENTS OF A      24420013
*                   STRUCTURE.                                          24450013
         SPACE 2                                                        24480013
*        MASK  5   ANY IDENTIFIERS WHICH AREN'T MEMBERS OF A STRUCTURE  24510013
*                   AND WHICH ARE NOT FORMAL PARAMETERS.                24540013
         SPACE 2                                                        24570013
*        MASK  6    MAJOR STRUCTURES WHICH ARE NOT FORMAL PARAMETERS.   24600013
         SPACE 2                                                        24630013
*        MASK  7    MINOR STRUCTURES WHICH ARE NOT FORMAL PARAMETERS.   24660013
         SPACE 2                                                        24690013
*        MASK  8    BASE ELEMENTS OF STRUCTURES WHICH ARE NOT FORMAL    24720013
*                   PARAMETERS.                                         24750013
         SPACE 2                                                        24780013
*        MASK  9    INTERNAL ENTRY POINTS                               24810013
         SPACE 2                                                     I1 24817016
*        NOTE. MASKS 1, 2, 3, AND 4 ARE OBTAINED BY 'AND'ING MASK P  I1 24824016
*        WITH MASKS 5, 6, 7, AND 8, RESPECTIVELY.                    I1 24831016
         EJECT                                                          24840013
*        BIT                 OFFSET              CORRESPONDING          24870013
*        PATTERN OF          DOWN                ATTRIBUTE              24900013
*        EACH MASK           MASK (HEX)                                 24930013
         SPACE 4                                                        24960013
*  1 2 3 4   5 6 7 8   9                                                24990013
         SPACE 2                                                        25020013
*  1 0 0 1   1 0 0 1   1     0                   BINARY                 25050013
*  1 0 0 1   1 0 0 1   1     1                   DECIMAL                25080013
*  1 0 0 1   1 0 0 1   1     2                   FIXED                  25110013
*  1 0 0 1   1 0 0 1   1     3                   FLOAT                  25140013
         SPACE                                                          25170013
*  1 0 0 1   1 0 0 1   1     4                   REAL                   25200013
*  1 0 0 1   1 0 0 1   1     5                   COMPLEX                25230013
*  1 0 0 1   1 0 0 1   1     6                   VARYING                25260013
*  1 0 0 1   1 0 0 1   1     7                   PICTURE                25290013
         SPACE 2                                                        25320013
*  1 0 0 1   1 0 0 1   1     8                   BIT                    25350013
*  1 0 0 1   1 0 0 1   1     9                   CHAR                   25380013
*  1 0 0 1   1 0 0 1   1     A                   ADJUSTABLE LENGTH      25410013
*  1 0 0 1   1 0 0 1   0     B                   EVENT                  25440015
         SPACE                                                          25470013
*  0 0 0 0   1 1 1 1   1     C                   INTERNAL               25500013
*  0 0 0 0   1 1 0 0   0     D                   EXTERNAL               25530013
*  0 0 0 0   1 1 0 0   0     E                   STATIC                 25560013
*  0 0 0 0   1 1 0 0   0     F                   AUTOMATIC              25590013
         SPACE 2                                                        25620013
*  1 1 0 0   1 1 0 0   0     10                  CONTROLLED             25650013
*  0 0 0 0   1 0 0 1   0     11                  INITIAL                25680013
*  1 1 1 1   1 1 1 1   0     12                  * DIMS                 25710013
*  1 0 0 1   1 0 0 1   0     13                  * LENGTH               25740013
         SPACE                                                          25770013
*  1 1 1 1   1 1 1 1   0     14                  FIXED DIMS             25800013
*  1 1 1 1   1 1 1 1   0     15                  VARIABLE DIMS          25830013
*  1 1 0 1   1 1 0 1   0     16                  LIKE                   25860013
*  0 0 0 0   1 1 0 0   0     17                  POS                    25890013
         SPACE 2                                                        25920013
*  0 0 0 0   1 1 0 0   0     18                  DEFINED                25950013
*  1 0 0 0   1 0 0 0   1     19                  ENTRY                  25980013
*  1 0 0 0   1 0 0 0   1     1A                  USES                   26010013
*  1 0 0 0   1 0 0 0   1     1B                  SETS                   26040013
         SPACE                                                          26070013
*  1 0 0 1   1 0 0 1   0     1C                  TASK                   26100015
*  1 0 0 1   1 0 0 1   0     1D                  OFFSET                 26130015
*  1 1 0 0   1 1 0 0   0     1E                  CONTIGUOUS             26160015
*  0 0 0 0   1 0 0 0   0     1F                  GENERIC                26190013
         SPACE 2                                                        26220013
*  1 0 0 1   1 0 0 1   0     20                  LABEL                  26250013
*  0 0 0 0   1 0 0 0   0     21                  BUILTIN                26280013
*  1 0 0 0   1 0 0 0   1     22                  RETURNS                26310013
*  0 0 0 0   1 0 0 1   0     23                  INITIAL WITHOUT CALL   26340015
         SPACE                                                          26370013
*  1 1 1 1   1 1 1 1   0     24                  ALIGNED             I1 26400016
*  1 1 1 1   1 1 1 1   0     25                  PACKED              I1 26430016
*  1 0 0 1   1 0 0 1   1     26                  PRECISION 1            26460013
*  1 0 0 1   1 0 0 1   1     27                  PRECISION 2            26490013
         SPACE 2                                                        26520013
*  1 0 0 1   1 0 0 1   1     27                  CHARACTER PICTURE      26550013
*  1 0 0 0   1 0 0 0   1     29                  REDUCIBLE              26580013
*  1 0 0 0   1 0 0 0   1     2A                  IRREDUCIBLE            26610013
*  0 0 0 0   1 0 0 1   0     2B                  INITIAL (VAR REP)      26640013
         SPACE                                                          26670013
*  1 0 0 1   1 0 0 1   0     2C                  AREA                   26700013
*  0 0 0 0   1 1 0 0   0     2D                  BASED (POINTER)        26730015
*  1 0 0 1   1 0 0 1   0     2E                  POINTER                26760013
*  1 1 0 0   1 1 0 0   0     2F                  CELL                I1 26790016
         EJECT                                                          26820013
*              STORAGE FOR THE MASKS                                    26850013
         SPACE 4                                                        26880013
*              (SEE BELOW FOR TEST MASK P.)                          I1 26980016
         SPACE 2                                                        27120013
TMASK5   DC    X'FFFFFFFFFFFF'         TEST MASK 5.                     27150013
         SPACE 2                                                        27180013
TMASK6   DC    X'000FAF820C05'         TEST MASK 6.                     27210015
         SPACE 2                                                        27240013
TMASK7   DC    X'00082C000C00'         TEST MASK 7.  MINOR STRUCTS.  I1 27270016
         SPACE 2                                                     I1 27300016
TMASK8   DC    X'FFF87E0C9F9A'         TEST MASK 8.  BASE ELEMENTS.  I1 27330016
         SPACE 2                                                        27360013
TMASK9   DC    X'FFE8007023E0'         TEST MASK 9.                     27390015
         EJECT                                                          27420013
*              MORE SLOTS IN TRANSFER VECTOR                            27450013
         SPACE 4                                                        27480013
DEFOFF   DC    H'0'                    OFFSET OF DEFINED INFORMATION    27510013
STRCOF   DC    H'0'                    SLOT WHICH WILL CONTAIN OFFSET   27540013
*                                    OF 'STRUCTURE MEMBER' SLOT FROM    27570013
*                                    START OF DICT.ENTRY.               27600013
H16      DC    H'16'                   SIZE OF CSTCK3 ENTRY.(NEED NOT   27630013
*                                    BE IN TRANSFER VECTOR).            27660013
         SPACE                                                          27667019
STCLAS   DC    X'00'                   SLOT FOR STORAGE CLASS OF  24676 27674019
*                                    MAJOR STRUCTURE.             24676 27681019
ACDCRT   DC    A(DCNRTN-IEMEL)         SLOT CONTAINING OFFSET OF RETURN 27690013
*                                    POINT FROM CDICEN.                 27720013
BLNKST   DC    F'0'                    PARAMETERS FOR ROUTINE 'BLANK'.  27750013
BLNKFN   DC    F'0'                  (IN MODULE EK).                    27780013
         SPACE                                                          27810013
TMASKP   DC    X'FFF0BE7EAFEB'         TEST MASK P. PARAMETERS.      I1 27830016
         SPACE                                                          27850015
         BC    B,UNWANT                'UNWANT' ROUTINE.                27870013
TEMCUR   DC    F'0'                    TEMP SLOT FOR 'CURENT'           27880015
STOP     DC    X'FFFFFFFE'             STOPPER IN F.A. TABLE.           27890015
         BC    B,ATLSCN                                           REPAK 27892020
         BC    B,AZDC2                                            REPAK 27894020
         BC    B,SELMSK                                           REPAK 27896020
         EJECT                                                          27900013
*              THE DECLARE SCAN ROUTINE, CDCLSC                         27930013
         SPACE 4                                                        27960013
*               THIS ROUTINE EXPECTS THAT ON ENTRY, GRSCAN POINTS TO    27990013
*        THE FIRST BYTE OF THE DECLARE STATEMENT.                       28020013
         SPACE 4                                                        28050013
CDCLSC   STM   0,15,REGST(GRATCA)      STORE ALL REGISTERS              28080013
         EJECT                                                          28110013
*              'INITIALISATON OF THE DECLARE SCAN' ROUTINE, 'INTLZE'.   28140013
         SPACE 4                                                        28170013
*              THIS ROUTINE PERFORMS THE NECESSARY INITIALISATION JUST  28200013
*        BEFORE WE SCAN EACH INDIVIDUAL DECLARE STATEMENT.              28230013
         SPACE 4                                                        28260013
*              FIRST WE SET UP THE SLOT 'NEXDCL'. IT CONTAINS THE TEXT  28290013
*        REFERENCE OF THE NEXT MEMBER OF THE DECLARE CHAIN.             28320013
         SPACE                                                          28350013
INTLZE   MVC   NEXDCL+1(3),5(GRSCAN)                                    28380013
         SPACE 3                                                        28410013
*              NEXT WE SET UP THE SLOT 'CBLANK'. IT CONTAINS THE        28440013
*        ADDRESS OF THE FIRST BYTE TO BE BLANKED OUT WHEN WE LATER      28470013
*        ERASE THE DECLARATION LIST.                                    28500013
         SPACE                                                          28530013
         LA    GR2,8(0,GRSCAN)                                          28560013
         ST    GR2,PAR2(0,GRDCPT)        SET 'BLNKST' TO CONTAIN TEXT   28590013
         MVC   PAR1+1(1,GRDCPT),DCBLK1+1(GREMB) REF OF 1ST BYTE OF DCLN 28620013
         L     GRL,ZTXTRF(0,GRCP)        LIST.                          28650013
         BALR  GRR,GRL                                                  28680013
         MVC   BLNKST(4),PAR1(GRDCPT)                                   28710013
         SPACE 3                                                        28740013
*              NEXT WE CLEAR THE ATTRIBUTE COLLECTION AREA              28770013
         SPACE                                                          28800013
         MVI   0(GRATCA),X'00'                                          28830013
         MVC   1(ACALTH,GRATCA),0(GRATCA)                               28860013
         SPACE 3                                                        28890013
*              NEXT SET UP IN THE ATT.COLL.AREA THE RETURN LINK FOR     28920013
*        ROUTINE CDICEN.                                                28950013
         SPACE                                                          28980013
         LA    GR2,DCNRTN                                               29010013
         ST    GR2,LINK(0,GRATCA)                                       29040013
         SPACE 3                                                        29070013
*              NEXT SET UP IN THE ATT.COLL.AREA THE CURRENT BLOCK LEVEL 29100013
*        AND COUNT.                                                     29130013
         SPACE                                                          29160013
         MVC   LEVEL(2,GRATCA),CLEVEL                                   29190013
         SPACE 3                                                        29220013
*              NEXT WE SET UP IN THE ATT.COLL.AREA THE CURRENT          29250013
*        STATEMENT NUMBER.                                              29280013
         SPACE                                                          29310013
*              FIRST WE TEST WHETHER THERE IS A STATEMENT LABEL         29340013
         SPACE                                                          29370013
         CLI   0(GRSCAN),SN            IS IT A STATEMENT NUMBER         29400013
         BC    BE,ITZ1                                                  29430013
         SPACE                                                          29460013
         CLI   0(GRSCAN),SL            IS IT A STATEMENT LABEL          29490013
         BC    BE,ITZ2                                                  29520013
         SPACE                                                          29550013
*              HERE IT IS NEITHER STMNT.NUMBER OR STMNT. LABEL, SO THIS 29580013
*        IS A COMPILER ERROR.                                           29610013
         SPACE                                                          29640013
         DC    X'0000'                 INTERRUPT                        29670013
         SPACE 2                                                        29700013
*              HERE IT IS A STATEMENT NUMBER                            29730013
         SPACE                                                          29760013
ITZ1     MVC   DCLNUM(2,GRATCA),1(GRSCAN) MOVE THE STATEMENT NUMBER     29790013
*                                    FROM THE TEXT TO THE ATT.COLL.AREA 29820013
         BC    B,ITZ3                  GO TO NEXT SECTION               29850013
         SPACE 2                                                        29880013
*              HERE IT IS A STATEMENT LABEL.                            29910013
         SPACE                                                          29940013
ITZ2     MVC   PAR1+2(2,GRDCPT),1(GRSCAN)  WE PICK UP THE 'STATEMENT    29970013
*                                    LABEL' DICT. ENTRY.                30000013
         SPACE                                                          30030013
         L     GRL,ZDRFAB(0,GRCP)      CALL THE 'ZDRFAB' ROUTINE TO     30060013
         BALR  GRR,GRL               CONVERT TO ABSOLUTE ADDRESS        30090013
         SPACE                                                          30120013
         L     GR1,PAR1(0,GRDCPT)      POINT GR1 AT THE DICT.ENTRY      30150013
         SPACE                                                          30180013
         MVC   DCLNUM(2,GRATCA),STTNUM(GR1) MOVE THE STATEMENT NUMBER   30210013
*                                    INTO THE ATT.COLL.AREA.            30240013
         SPACE 3                                                        30270013
*              LASTLY WE BUMP THE SCAN POINTER, GRSCAN, TO POINT AT THE 30300013
*        FIRST BYTE OF THE DECLARATION LIST.                            30330013
         SPACE                                                          30360013
ITZ3     LA    GRSCAN,8(0,GRSCAN)                                       30390013
         SPACE                                                          30420013
         ST    GRSCAN,NXSPST         INITIALISE NXSPST.                 30450013
         SPACE                                                          30480013
         MVC   ZSTAT+2(2,GRDCPT),DCLNUM(GRATCA) SET UP DECLARE NUMBER   30510013
*                                      IN ZSTAT.                        30540013
         EJECT                                                          30570013
*              DECLARED IDENTIFIER PROCESSING ROUTINE, DCIDPR           30600013
         SPACE 4                                                        30630013
*              THIS ROUTINE SCANS A FRESH ITEM IN A DECLARATION LIST    30660013
*        UP TO THAT BYTE WHICH CONTAINS THE LENGTH OF THE BCD.          30690013
*              THUS IT EXPECTS THAT ON ENTRY, GRSCAN WILL POINT AT THE  30720013
*        FIRST BYTE OF A DECLARATION LIST, OR ELSE AT THE FIRST BYTE    30750013
*        FOLLOWING A COMMA. ON EXIT, GRSCAN WILL POINT AT THE BYTE      30780013
*        CONTAINING THE LENGTH OF THE BCD.                              30810013
*              THIS ROUTINE LOOKS FOR TWO TYPES OF CHARACTER THAT CAN   30840013
*        PRECEDE THE BCD,                                               30870013
         SPACE                                                          30900013
*              1.   FOR FACTOR BRACKETS, IT UPDATES THE POINTERS TO THE 30930013
*                   FACTORED ATTRIBUTE TABLE, AND BUMPS THE COUNT OF    30960013
*                   FACTORING LEVEL.                                    30990013
         SPACE                                                          31020013
*              2.   FOR A LEVEL NUMBER, IT STORES IT IN THE 'PRESENT    31050013
*                   LEVEL NUMBER' SLOT AND CONTINUES THE SCAN.          31080013
         SPACE                                                          31110013
*              WHEN THE SCAN REACHES THE BCD. WE BRANCH TO THE 'BCDPR'  31140013
*        ROUTINE, WHICH PROCESSES THE BCD.                              31170013
         EJECT                                                          31200013
*              THIS IS THE ENTRY POINT TO THE ROUTINE                   31230013
         SPACE 3                                                        31260013
DCIDPR   OI    DATABT(GRATCA),CADNF    BEFORE WE START THE SCAN, WE     31290013
*                                    INITIALIZE THE 'NO PICTURE' BIT TO 31320013
*                                    ONE.                               31350013
         SPACE                                                          31380013
AZDA2    EQU   DCIDPR                  TEMPORARY CARD DEFINING ENTRY    31410013
*                                    POINT TO THIS ROUTINE.             31440013
         SPACE                                                          31470013
         L     GRSCAN,NXSPST                                            31500013
         SPACE                                                          31530013
         OI    DCLATT+1(GRATCA),CADSTR INITIALISE 'CAD' BIT TO ONE IN   31560013
*                                    DECLARED ATTRIBUTES REGION.        31590013
         SPACE                                                          31620013
         MVI   PRESNT,0                CLEAR 'PRESENT LEVEL NO.' SLOT.  31650013
         SPACE 2                                                        31680013
*              NOW WE TEST THE BYTE POINTED AT BY GRSCAN.               31710013
         SPACE                                                          31740013
DCID1    CLI   0(GRSCAN),X'00'         IS IT ZERO                       31770013
         BC    BE,DCID2                                                 31800013
         SPACE                                                          31830013
         TM    0(GRSCAN),X'C0'         ARE THE TWO HIGH ORDER BITS ZERO 31860013
         BC    BZ,BCDPR              (I.E. DOES THE BYTE CONTAIN THE    31890013
*                                    LENGTH OF A BCD). IF SO, WE GO     31920013
*                                    STRAIGHT TO THE ROUTINE BCDPR.     31950013
         SPACE                                                          31980013
         CLI   0(GRSCAN),LFBRKT        IS IT A LEFT FACTOR BRACKET      32010013
         BC    BE,DCID3                                                 32040013
         SPACE                                                          32070013
         CLI   0(GRSCAN),FXBNRL        IS IT A CONSTANT MARKER (FIXED   32100013
         BC    BE,DCID4              BINARY REAL). I.E. IS THE NEXT     32130013
*                                    BYTE A LEVEL NUMBER.               32160013
         SPACE 2                                                        32190013
*              IF IT IS NONE OF THESE POSSIBILITIES, THIS IS A COMPILER 32220013
*        ERROR.                                                         32250013
         SPACE 2                                                        32280013
         SPACE                                                          32310013
         DC    X'0000'                 INTERRUPT                        32340013
         SPACE 3                                                        32370013
*              HERE GRSCAN POINTS AT A ZERO BYTE                        32400013
         SPACE                                                          32430013
DCID2    LA    GRSCAN,1(GRSCAN)        BUMP GRSCAN TO THE NEXT BYTE AND 32460013
         BC    B,DCID1               GO TO CONTINUE THE SCAN            32490013
         SPACE 2                                                        32520013
*              HERE GRSCAN POINTS AT A FACTOR BRACKET                   32550013
         SPACE                                                          32580013
DCID3    L     GR2,COUNT2(0,GRATCA)    WE ARE ENTERING ONE HIGHER LEVEL 32610013
         LA    GR2,1(0,GR2)          OF FACTORING. SO WE BUMP THE COUNT 32640013
         ST    GR2,COUNT2(0,GRATCA)  OF FACTORING LEVEL BY ONE.         32670013
         SPACE                                                          32700013
         L     GR2,MAX                 ALSO WE BUMP THE POINTER 'MAX'   32730013
         LA    GR2,7(0,GR2)          TO THE FACTORED ATTRIBUTE TABLE    32760013
         ST    GR2,MAX               TO POINT AT THE NEXT ENTRY IN THE  32790013
*                                    TABLE.                             32820013
         SPACE                                                          32850013
         MVC   CURENT(4),MAX           SET 'CURENT' EQUAL TO 'MAX'      32950015
         BC    B,DCID2                 BUMP GRSCAN AND CONTINUE         33050015
         SPACE 2                                                        33150013
*              HERE GRSCAN POINTS AT A CONSTANT MARKER, I.E. THE NEXT   33180013
*        BYTE IS A LEVEL NUMBER.                                        33210013
         SPACE                                                          33240013
DCID4    MVC   PRESNT(1),1(GRSCAN)     MOVE THE LEVEL NUMBER INTO THE   33310015
*                                    SLOT CONTAINING THE PRESENT LEVEL  33390013
*                                    NUMBER                             33420013
         SPACE                                                          33450013
         OI    FLAGS(GRATCA),CFLAG6    SET 'LEVEL NMMBER APPLIED' FLAG  33480013
         SPACE                                                          33510013
         LA    GRSCAN,2(GRSCAN)        BUMP GRSCAN PAST THE LEVEL       33540015
         BC    B,DCID1               NUMBER AND GO TO CONTINUE THE      33570013
*                                    SCAN                               33600013
         EJECT                                                          33630013
*              'BCDPR'  BCD PROCESSING ROUTINE.                         33660013
         SPACE 4                                                        33690013
BCDPR    LA    GR1,1(0,GRSCAN)         POINT PAR7 AT THE BCD.           33720013
         ST    GR1,PAR7(0,GRDCPT)                                       33750013
         SPACE                                                          33780013
         SR    GR1,GR1                 SET UP BCD LENGTH IN PAR8        33810013
         IC    GR1,0(GRSCAN)                                            33840013
         ST    GR1,TMPAR8(0,GREMB)                                      33870013
         SPACE                                                          33900013
         OI    FLAGS(GRATCA),CFLAG3    SET ON CFLAG3.                   33930013
         ST    GRSCAN,PAR2(0,GRDCPT)            SET UP IN PAR4 AND IN   33960013
         MVC   PAR1+1(1,GRDCPT),DCBLK1+1(GREMB) 'BCDTRF', THE TEXT REF  33990013
         L     GR4,ZTXTRF(0,GRCP)               OF THE BCD LENGTH BYTE, 34020013
         BALR  GRR,GR4                          AND IN THE FIRST BYTE   34050013
         MVC   BCDTRF(4,GRATCA),PAR1(GRDCPT)    OF 'BCDTRF', THE BCD    34080013
         MVC   SCR1(4,GRATCA),PAR1(GRDCPT)      LENGTH.   N.B. -        34100015
*                                      SCR1 USED IN PLACE OF PAR4       34120015
         MVC   BCDTRF(1,GRATCA),0(GRSCAN)                               34140013
         SPACE 2                                                        34170013
         CLC   COUNT2(4,GRATCA),CD0    ANY FACTORING ?              H91 34200017
         BC    BE,AZ100                NO.                          H91 34230017
         SPACE 1                                                    H91 34260017
         BAL   GRR,FACLVN(0,GREKB)     YES.  GO TO APPLY ANY        H91 34290017
*                                    FACTORED LEVEL NUMBERS.        H91 34320017
         SPACE 1                                                    H91 34350017
AZ100    DS    0H                                                   H91 34380017
         TM    FLAGS(GRATCA),CFLAG6    IS 'LEVEL NUMBER APPLIED'        34470013
*                                    FLAG ON.                           34500013
         BC    BZ,AZDB2                                                 34530013
         SPACE 2                                                        34560013
AZ106    XR    GR2,GR2                 SET UP BCD LENGTH + 1 IN GR2     34590013
         IC    GR2,0(GRSCAN)                                            34620013
         LA    GRTMSC,1(GRSCAN,GR2)    POINT GRTMSC AT FIRST BYTE AFTER 34650013
*                                    THE IDENTIFIER                     34680013
         BC    B,AZDF1                                                  34710013
         SPACE 2                                                        34740013
*              SET UP REQUIREMENTS FOR HASHING ROUTINE                  34770013
         SPACE 1                                                        34800013
AZDB2    LA    GRPTR,1(0,GRSCAN)       POINT GRPTR TO BCD               34830013
         LR    GRB,GRSCAN              POINT GRB TO BCD LENGTH BYTE     34860013
         SR    GRLTH,GRLTH                                              34890013
         IC    GRLTH,0(GRSCAN)         PUT BCD LENGTH INTO GRLTH        34920013
         BCTR  GRLTH,0                 PUT BCD LENGTH-1 INTO GRLTH      34950013
         SPACE 1                                                        34980013
         BAL   GRR,CHASH(0,GREMB)      BRANCH TO HASHING ROUTINE, WHICH 35010013
*                                    RETURNS HASH RESULT IN GRHASH      35040013
         SPACE 2                                                        35070013
         L     GR3,HASHHD(GRDCPT)      POINT GR3 TO HEAD OF HASH TABLE  35100013
         AR    GR3,GRHASH              GR3 NOW CONTAINS ABSOLUTE        35130013
*                                    ADDRESS OF HASH SLOT               35160013
         MVC   CADD1(2,GRATCA),0(GR3)  PUT CONTENTS OF HASH SLOT INTO   35190013
*                                    CADD1                              35220013
         SH    GR3,CD3                                                  35250013
         ST    GR3,CADD2(GRATCA)       CADD2 NOW CONTAINS ABSOLUTE      35280013
*                                    ADDRESS OF HASH SLOT MINUS 3.      35310013
         SPACE 1                                                        35340013
AZ110    CLC   CADD1(2,GRATCA),CD0     IS CADD1 ZERO                    35370013
         BC    BE,AZDE1                                                 35400013
         SPACE 2                                                        35430013
*              NOW CADD1 IS CONVERTED TO AN ABSOLUTE ADDRESS            35460013
         MVC   PAR1+2(2,GRDCPT),CADD1(GRATCA)  PUT DICT REF INTO PAR1   35490013
         SPACE 2                                                        35520013
AZ111    L     GRL,ZDRFAB(GRCP)        BRANCH TO ZDRFAB ROUTINE   27169 35550020
         BALR  GRR,GRL               (CONTROL PHASE)                    35580013
         SPACE 2                                                        35610013
         L     GR4,PAR1(0,GRDCPT)      PUT THE ABSOLUTE ADDRESS OF THE  35640013
         ST    GR4,TMFWST            DICT. ENTRY INTO TMFWST.           35670013
         SPACE                                                          35700013
*                                      TEST INITIAL CODE BYTE OF DICT.  35730013
         CLI   0(GR4),CONST          ENTRY, IS IT AN ENTRY FOR A CONST. 35760013
         BC    BE,AZDC2                                                 35790013
         SPACE 1                                                        35820013
         MVC   CDZEMP+2(2),1(GR4)      PICK UP LENGTH OF DICT ENTRY     35850013
         AH    GR4,CDZEMP+2            POINT GR4 (AND TEMP1) AT BCD     35880013
*                                    LENGTH BYTE.                       35910013
         SR    GR5,GR5                                                  35940013
         IC    GR5,0(GR4)              SET UP BCD LENGTH IN GR5         35970013
         L     GR1,TMPAR8(0,GREMB)                                      36000013
         BCTR  GR1,0                                                    36030013
         CR    GR1,GR5                 COMPARE THIS BCD LENGTH WITH     36060013
         BC    BNE,AZDC2               THAT OF THE BCD IN THE DECLARE   36090013
*                                    STATEMENT                          36120013
         SPACE 2                                                        36150013
*                                      NOW COMPARE THE BCD'S THEMSELVES 36180013
         SPACE 1                                                        36210013
         LA    GR4,1(0,GR4)            POINT GR4 TO THE BCD IN THE      36240013
*                                    DICTIONARY ENTRY.                  36270013
         LA    GRB,1(0,GRSCAN)         POINT GRB TO THE BCD IN THE      36300013
*                                    DECLARE STATEMENT.                 36330013
         SPACE 1                                                        36360013
*                                      TO COMPARE THE BCD'S, WE HAVE    36390013
*                                    SET UP THE BCD LENGTH IN GR5. THIS 36420013
*                                    LENGTH IS STORED INTO THE LENGTH   36450013
*                                    FIELD OF THE COMPARE INSTRUCTION.  36480013
         STC   GR5,*+5                                                  36510013
         CLC   0(0,GR4),0(GRB)         COMPARE THE BCD'S.               36540013
         BC    BE,AZDD1                                                 36570013
         SPACE 1                                                        36600013
AZDC2    TM    MDCFLG(GRATCA),MDEHCS   IS IT END OF SCAN          27169 36610020
         BC    BO,AZDE1                IF SO, GO TO SET TEST MASK 27169 36620020
         L     GR3,TMFWST              SET CADD2 = TMFWST         27169 36630020
         ST    GR3,CADD2(GRATCA)                                        36660013
         MVC   ZLOCK(2,GRDCPT),CADD1(GRATCA) LOCK IN BLOCK CONTAININI   36690013
*                                    CADD2.                             36720013
         MVC   CADD1(2,GRATCA),3(GR3)  LOAD CADD1 FROM CADD2 + 3        36750013
         BC    B,AZ110                                                  36780013
         SPACE 2                                                        36810013
*              COMPARE THE BLOCK COUNT IN THE DICTIONARY ENTRY WITH     36840013
*        THAT IN THE ATTRIBUTE COLLECTION AREA                          36870013
         SPACE 1                                                        36900013
AZDD1    BCTR  GR4,0                   POINT GR4 TO THE 'BLOCK COUNT'   36930013
         BCTR  GR4,0                 IN THE DICTIONARY ENTRY.           36960013
*                                    IN THE DICTIONARY ENTRY            36990013
         CLC   0(1,GR4),COUNT(GRATCA)  COMPARE THE BLOCK COUNTS         37020013
         BC    BE,AZDD3                IF EQUAL, BRANCH           27169 37024020
         BC    BH,AZDC2                IF CURRENT BLK. CNT HIGHER 27169 37028020
*                                    CONTINUE SCAN OF HASH CHAIN  27169 37032020
         CLI   0(GR4),X'00'            IF LOW, CHECK IF OTHER ID. 27169 37036020
*                                    IS THE EXTERNAL PROC.        27169 37040020
         BC    BE,AZDD2                IF SO, GO TO SET FLAG      27169 37044020
         MVC   PAR1+2(2,GRDCPT),ZPROC1+2(GRDCPT)   PICK UP DIC.   27169 37048020
*                                    REF. OF E.T.1. OF EXT. PROC. 27169 37052020
         L     GRL,ZDRFAB(GRCP)      AND CONVERT IT               27169 37056020
         BALR  GRR,GRL               TO ABSOLUTE.                 27169 37060020
         L     GR3,PAR1(0,GRDCPT)                                 27169 37064020
         MVC   PAR1+2(2,GRDCPT),FSTLBP(GR3) PICK UP DIC. REF. OF  27169 37068020
*                                    EXT. PROC. LABEL             27169 37072020
         OI    MDCFLG(GRATCA),MDEHCS                              27169 37076020
         BC    B,AZ111                 GO TO CHECK FOR SAME BCD   27169 37080020
*                                    AS EXT. PROC.                27169 37084020
AZDD2    EQU   *                                                  27169 37088020
         OI    MDCFLG(GRATCA),MDCEPR   IF SO, SET FLAG            27169 37092020
         BC    B,AZDE1                 GO TO SET TEST MASK        27169 37096020
AZDD3    EQU   *                                                  27169 37100020
         OI    FLAGS(GRATCA),CFLAG7    SET ON 'BCD IN SAME BLOCK' FLAG  37110013
         SPACE                                                          37140013
         L     GR4,TMFWST              POINT GR4 AT DICT ENTRY FOR      37170013
*                                    OTHER IDENT.                       37200013
         L     GREDB,X'190'(0,GRDCPT)  BASE IEMED AND BRANCH TO   REPAK 37207020
         BC    B,BCDISB(0,GREDB)     BCDISB ROUTINE.              REPAK 37214020
GREDB    EQU   15                                                 REPAK 37221020
         SPACE 1                                                        37230013
         EJECT                                                          37260013
*              'SELMSK' ROUTINE, SELECT TEST MASK.                      46320013
         SPACE 2                                                        46350013
*              THIS ROUTINE DECIDES WHICH OF THE TEST MASKS SHOULD BE   46380013
*        INITIALISED IN THE ATTRIBUTE COLLECTION AREA, BY ASKING        46410013
*        QUESTIONS ABOUT THE NATURE OF THE IDENTIFIER.                  46440013
*              THIS ROUTINE ALSO HAS A MECHANISM TO CAUSE INHERITING OF 46470013
*        STORAGE CLASS IN STRUCTURES.                                   46500013
         SPACE 4                                                        46530013
SELMSK   TM    FLAGS(GRATCA),CFLAG4    IS THIS A STRUCTURE MEMBER       46560013
         BC    BO,SELM1                                                 46590013
         SPACE                                                          46620013
AZDE1    EQU   SELMSK                  TEMPORARY LABEL DEFINITION       46650013
         SPACE                                                          46680013
         SPACE                                                          46710013
         MVC   TESTMK(6,GRATCA),TMASK5 INITIALISE TEST MASK FOR         46740013
         BC    B,ATLSCN              UNSTRUCTURED IDENTIFIER, AND GO TO 46770013
*                                    SCAN ATTRIBUTE LIST.               46800013
         SPACE 2                                                        46830013
*              HERE IT IS A MEMBER OF A STRUCTURE                       46860013
         SPACE                                                          46890013
SELM1    OI    CDFLAG(GRATCA),PRDATA   DISALLOW FILE ATTRIBUTES.        46920013
         TM    STCLAS,FMPRAM           INHERIT 'FORMAL PARAMETER' BIT   46950013
         BC    BZ,SELM1A             IF NECESSARY.                      46980013
         OI    OTHER2(GRATCA),FMPRAM                                    47010013
         BC    B,SELM2                                                  47040013
SELM1A   TM    CDFLAG(GRATCA),FPSTRC   IS IT A FORMAL PARAMETER AND     47070013
         BC    BO,SELM2              STRUCTURE MEMBER.                  47100013
         SPACE 2                                                        47130013
*              HERE IT IS NOT A FORMAL PARAMETER                        47160013
         SPACE                                                          47190013
         MVC   TESTMK(6,GRATCA),TMASK5  INITIALIZE FOR NON-PARAMS.   I1 47200016
         SPACE 1                                                     I1 47210016
SELM2A   TM    DCLATT(GRATCA),STRUC    IS IT A STRUCTURE             I1 47220016
         BC    BO,SELM3                                                 47250013
         SPACE                                                          47280013
         NC    TESTMK(6,GRATCA),TMASK8   INITIALIZE MASK FOR BASE    I1 47310016
         BC    B,SELM4               ELEMENT                            47340013
         SPACE 2                                                        47370013
*              HERE IT IS A STRUCTURE                                   47400013
         SPACE                                                          47430013
SELM3    TM    FLAGS(GRATCA),CFLAG5    IS IT A MAJOR STUCTURE           47460013
         BC    BO,SELM5                                                 47490013
         SPACE                                                          47520013
         NC    TESTMK(6,GRATCA),TMASK7   INITIALIZE MASK FOR MINOR   I1 47550016
         BC    B,SELM4               STRUCTURE.                         47580013
         SPACE 2                                                        47610013
*              HERE IT IS A MAJOR STRUCTURE                             47640013
         SPACE                                                          47670013
SELM5    NC    TESTMK(6,GRATCA),TMASK6   INITIALIZE MASK FOR MAJOR   I1 47700016
*                                    STRUCTURE                          47730013
         SPACE                                                          47760013
SELM6    DS    0H                                                       47790015
         BC    B,ATLSCN                RETURN TO SCAN ATTRIBUTE LIST.   47820015
         SPACE 2                                                        47850013
*              HERE THIS IS A FORMAL PARAMETER AND A STRUCTURE MEMBER   47880013
         SPACE                                                          47910013
SELM2    MVC   TESTMK(6,GRATCA),TMASKP  INITIALIZE MASK FOR FORMAL   I1 48010016
         BC    B,SELM2A              PARAMETERS                      I1 48110016
         SPACE 4                                                        48420013
*              HERE THIS IS A MINOR STRUCTURE OR A BASE ELEMENT, AND    48450013
*        IT NOW INHERITS THE STORAGE CLASS OF ITS MAJOR STRUCTURE.      48480013
         SPACE                                                          48510013
SELM4    TM    STCLAS,CNTRLD           TEST THE STORAGE CLASS OF THE    48540013
         BC    BZ,SELM9              MAJOR STRUCTURE, WHICH HAS BEEN    48570013
         BC    BO,SELM10             SAVED IN 'STCLAS'                  48600013
         SPACE 2                                                        48630013
*              HERE THE MAJOR STRUCTURE IS STATIC                       48660013
         SPACE                                                          48690013
         OI    OTHER2(GRATCA),STATIC   SET 'OTHER2' BYTE AND TEST MASK  48720013
         NC    TESTMK(6,GRATCA),STATMK TO 'STATIC'.                     48750013
         BC    B,SELM11                                                 48780013
         SPACE 2                                                        48810013
*              HERE THE MAJOR STRUCTURE IS AUTOMATIC.                   48840013
         SPACE                                                          48870013
SELM9    OI    OTHER2(GRATCA),AUTOMC   SET 'OTHER2' BYTE AND TEST MASK  48900013
         NC    TESTMK(6,GRATCA),AUTOMK TO 'AUTOMATIC'.                  48930013
         BC    B,SELM11                                                 48960013
         SPACE 2                                                        48990013
*              HERE THE MAJOR STRUCTURE IS CONTROLLED.                  49020013
         SPACE                                                          49050013
SELM10   OI    OTHER2(GRATCA),CNTRLD   SET 'OTHER2' BYTE AND TEST MASK  49080013
         TM    STCLAS,X'80'            TEST FOR BASED                   49088015
         BC    BO,SELM12               BRANCH IF SO                     49096015
         NC    TESTMK(6,GRATCA),CONTMK   AND IN 'CONTROLLED' MASK       49104015
         BC    B,SELM11                                                 49112015
SELM12   NC    TESTMK(6,GRATCA),BASDMK   AND IN 'BASED' MASK            49120015
         OI    VARBLE(GRATCA),DEFND    INHERIT DEFINED BIT.             49131015
         SPACE 2                                                        49140013
SELM11   TM    STCLAS,EXTINT           IF MAJOR STRUCTURE IS EXTRRNAL,  49170013
         BC    BZ,ATLSCN             INHERIT THE BIT.                   49200013
         OI    OTHER2(GRATCA),EXTINT                                    49230013
         BC    B,ATLSCN                                                 49260013
         EJECT                                                          50910013
*              'FRWSCN', THE FORWARD SCAN ROUTINE.                      50940013
         SPACE 4                                                        50970013
*              THIS ROUTINE SCANS FORWARD PAST THE CURRENT IDENTIFIER,  51000013
*        TO PICK UP THE LEVEL NUMBER APPLIED TO THE NEXT IDENTIFIER.    51030013
AZDF1    MVC   TEMCUR(4),CURENT        SET TEMCUR=CURENT                51060013
         MVC   TEMMAX(4),MAX           SET TEMMAX=MAX                   51090013
         MVC   TMCNT2(4),COUNT2(GRATCA) SET TMCNT2=COUNT2               51120013
         SPACE 1                                                        51150013
         OI    FLAGS+1(GRATCA),CFLA12  SET CFLAG 12 ON (THE ATTRIBUTE   51180013
*                                    BEING PROCESSED MUST BE IGNORED)   51210013
         SPACE 1                                                        51240013
*              NOW TEST THE BYTE POINTED AT BY GRTMSC (TEMPORARY SCAN   51270013
*        POINTER)                                                       51300013
         SPACE 1                                                        51330013
AZ124A   CLI   0(GRTMSC),ATTMKR        IS IT AN ATTRIBUTE MARKER        51360013
         BC    BE,AZ120                                                 51390013
         SPACE 1                                                        51420013
         CLI   0(GRTMSC),RFBRKT        IS IT A RIGHT FACTOR BRACKET     51450013
         BC    BE,AZ121                                                 51480013
         SPACE 1                                                        51510013
         CLI   0(GRTMSC),COMMA         IS IT A COMMA                    51540013
         BC    BE,AZ122                                                 51570013
         SPACE 2                                                        51600013
         CLI   0(GRTMSC),ENDBLK        IS IT 'END OF BLOCK' MARKER      51630013
         BC    BE,AZ122A                                                51660013
         SPACE 2                                                        51690013
         CLI   0(GRTMSC),SEMCLN        IS IT A SEMICOLON                51720013
         BC    BE,AZDK2                                                 51750013
         SPACE 1                                                        51780013
         CLI   0(GRTMSC),X'00'         IS IT ZERO                       51810013
         BC    BE,AZ123                                                 51840013
         SPACE 1                                                        51870013
         SPACE                                                          51900013
*              IF IT IS NONE OF THESE IT IS A COMPILER ERROR.           51930013
         SPACE                                                          51960013
         SPACE 2                                                        51990013
         DC    X'0000'                 INTERRUPT                        52020013
         SPACE 2                                                        52050013
*              (GRTMSC POINTS TO AN ATTRIBUTE MARKER)                   52080013
AZ120    LR    GRATPO,GRTMSC           SET ATTRIBUTE POINTER = TEMP.    52110013
*                                    SCAN POINTER                       52140013
         BAL   GRR,CDATPR(0,GRECB)     BRANCH TO ATTRIBUTE PROCESSER.   52170013
         LR    GRTMSC,GRATPO           SET TEMP. SCAN POINTER EQUAL TO  52200013
*                                    NEW VALUE OF ATTRIBUTE POINTER.    52230013
*                                    (I.E. IT POINTS TO THE FIRST BYTE  52260013
*                                    WHICH DOES NOT CONCERN THE         52290013
*                                    RELEVANT ATTRIBUTE.)               52320013
         BC    B,AZ124A                                                 52350013
         SPACE 2                                                        52380013
*              (GRTMSC POINTS TO A RIGHT FACTOR BRACKET)                52410013
AZ121    L     GR3,TEMCUR              LOAD TEMCUR FROM CONTENTS OF     52440013
         MVC   TEMCUR+1(3),4(GR3)    TEMCUR + 4. (IN FACTORED ATTRIBUTE 52470013
*                                    TABLE)                             52500013
         L     GR3,TMCNT2              DECREMENT TMCNT2 BY ONE          52530013
         BCTR  GR3,0                                                    52560013
         ST    GR3,TMCNT2                                               52590013
AZ123    LA    GRTMSC,1(GRTMSC)        BUMP TEMPORARY SCAN POINTER BY   52620013
         BC    B,AZ124A              ONE.                               52650013
         SPACE 2                                                        52680013
*              HERE GRTMSC POINTS AT A SEMICOLON.                       52710013
AZDK2    MVI   NEXT,0                  CLEAR NEXT LEVEL NUMBER SLOT,    52740013
         NI    FLAGS+1(GRATCA),NFLA12 AND CFLAG12.                      52770013
         BC    B,AZDG1                                                  52800013
         SPACE 2                                                        52830013
*              HERE GRTMSC POINTS AT AN END OF BLOCK MARKER             52860013
AZ122A   MVC   PAR1+1(3,GRDCPT),DCBLK1+1(GREMB) GO TO COMP CTL TO PICK  52890013
         MVI   PAR1(GRDCPT),X'00'    UP NEXT TEXT BLOCK, MARKING IT     52920013
         MVI   PAR2+3(GRDCPT),X'00'  BUSY, AND LEAVING STATUS OF        52950013
         L     GRL,ZCHAIN(0,GRCP)    CURRENT BLOCK UNALTERED. SET UP    52980013
         BALR  GRR,GRL               REF OF NEW BLOCK IN 'DCBLK2' AND   53010013
         MVC   DCBLK2(4,GREMB),PAR1(GRDCPT) POINT GRTMSC AT THE NEW     53040013
         L     GRTMSC,PAR2(0,GRDCPT) BLOCK.                             53070013
         OI    CDFLAG(GRATCA),NEWBLK   SET ON 'NEW BLOCK' FLAG.         53100013
         BC    B,AZ124A                                                 53130013
         SPACE 2                                                        53160013
*              (GRTMSC POINTS TO A COMMA)                               53190013
AZ122    LA    GRTMSC,1(GRTMSC)        BUMP TEMPORARY SCAN POINTER PAST 53220013
*                                    THE COMMA.                         53250013
         SPACE                                                          53280013
         NI    FLAGS+1(GRATCA),NFLA12  SET CFLAG 12 OFF.                53310013
         MVI   NEXT,0                  SET 'NEXT' = 0 (LEVEL NUMBER OF  53340013
*                                    NEXT ITEM)                         53370013
         SPACE 2                                                        53400013
*              NOW TEST THE BYTE POINTED AT BY THE TEMPORARY SCAN       53430013
*              POINTER                                                  53460013
         SPACE 1                                                        53490013
*              IS IT ZERO                                               53520013
AZ124    CLI   0(GRTMSC),X'00'                                          53550013
         BC    BE,AZ124B                                                53580013
         SPACE                                                          53610013
*              IS IT AN IDENTIFIER LENGTH                               53640013
         TM    0(GRTMSC),X'C0'         (TEST IF ITS TWO HIGH ORDER BITS 53670013
         BC    BZ,AZ124C             ARE ZERO)                          53700013
         SPACE 1                                                        53730013
*              IS IT A LEVEL NUMBER                                     53760013
         CLI   0(GRTMSC),FXBNRL        (TEST FOR A FIXED BINARY REAL    53790013
         BC    BE,AZ125              CONSTANT MARKER).                  53820013
         SPACE 1                                                        53850013
*              IS IT A LEFT FACTOR BRACKET                              53880013
         CLI   0(GRTMSC),LFBRKT                                         53910013
         BC    BE,AZ126                                                 53940013
         SPACE 1                                                        53970013
         SPACE 2                                                        54000013
*              IF IT IS NONE OF THESE IT IS A COMPILER ERROR.           54030013
         SPACE                                                          54060013
         SPACE 2                                                        54090013
         DC    X'0000'                                                  54120013
         SPACE 2                                                        54150013
*              HERE GRTMSC POINTS AT AN IDENTIFIER LENGTH               54180013
AZ124C   TM    CDFLAG(GRATCA),NEWBLK   ARE WE IN A DIFFERENT TEXT BLOCK 54210013
         BC    BZ,AZDG1              FROM THE REAL SCAN. IF SO, MARK    54240013
         MVC   PAR1(4,GRDCPT),DCBLK2(GREMB) THE 'TEMPORARY SCAN' BLOCK  54270013
         MVI   PAR2+3(GRDCPT),X'02'  UNWANTED.                          54300013
         L     GRL,ZALTER(0,GRCP)                                       54330013
         BALR  GRR,GRL                                                  54360013
         BC    B,AZDG1                                                  54390013
         SPACE 2                                                        54420013
*              IT IS A ZERO BYTE                                        54450013
AZ124B   LA    GRTMSC,1(GRTMSC)                                         54480013
         BC    B,AZ124                                                  54510013
         SPACE 2                                                        54540013
*              IT IS A LEVEL NUMBER                                     54570013
AZ125    MVC   NEXT(1),1(GRTMSC)       MOVE THE LEVEL NUMBER INTO       54600013
*                                    'NEXT' (NEXT LEVEL NUMBER SLOT)    54630013
         LA    GRTMSC,2(GRTMSC)        BUMP TEMPORARY SCAN POINTER PAST 54660013
         BC    B,AZ124               THE LEVEL NUMBER                   54690013
         SPACE 2                                                        54720013
*              IT IS A LEFT FACTOR BRACKET                              54750013
AZ126    LA    GRTMSC,1(GRTMSC)        BUMP TEMP. SCAN POINTER BY ONE.  54780013
         L     GR3,TEMMAX              BUMP TEMMAX BY SEVEN, AND SET    54810013
         LA    GR3,7(GR3)            TEMCUR = TEMMAX                    54840013
         ST    GR3,TEMMAX                                               54870013
         ST    GR3,TEMCUR                                               54900013
         L     GR3,TMCNT2              BUMP TMCNT2 BY ONE.              54930013
         LA    GR3,1(0,GR3)                                             54960013
         ST    GR3,TMCNT2                                               54990013
         BC    B,AZ124                                                  55020013
         SPACE 2                                                        55050013
AZDG1    CLI   NEXT,0                  IS 'NEXT' EQUAL TO ZERO.         55080013
         BC    BNE,AZ127A                                               55110013
         SPACE 1                                                        55140013
AZ130    CLC   TMCNT2(4),CD0           ARE WE AT ZERO FACTORING LEVEL   55170013
         BC    BE,AZ128                                                 55200013
         SPACE                                                          55230013
         CLC   TEMCUR+1(3),STOP        DOES TEMCUR CONTAIN A STOPPER.   55260013
         BC    BE,AZ128                                                 55290013
         SPACE                                                          55320013
         L     GR3,TEMCUR              TEST THE LEVEL NUMBER IB THE     55350013
         CLI   0(GR3),X'00'          ENTRY IN THE FACTORED ATTRIBUTE    55380013
         BC    BNE,AZ129             WHICH IS POINTED AT BY TEMCUR      55410013
*                                      IS IT ZERO.                      55440013
         SPACE                                                          55470013
         MVC   TEMCUR+1(3),4(GR3)      LOAD TEMCUR FROM TEMCUR + 4      55500013
         BC    B,AZ130                                                  55530013
         SPACE 2                                                        55537015
*              THE BYTE POINTED TO BY TEMCUR IS NOT ZERO,(IT IS A LEVEL 55544015
*        NUMBER)                                                        55551015
         SPACE 2                                                        55560013
AZ129    MVC   NEXT(1),0(GR3)          MOVE INTO 'NEXT' THE BYTE        55590013
*                                    POINTED AT BY TEMCUR.              55620013
         SPACE                                                          55650013
AZ127A   CLI   NEXT,1                                                   55680013
         BC    BNE,AZ127                                                55710013
         SPACE 2                                                        55740013
AZ128    OI    OTHER1(GRATCA),LMSTRC   SET ON THE 'LAST MEMBER OF A     55770013
*                                    STRUCTURE' BIT IN THE OTHER1 BYTE  55870015
         SPACE 2                                                        55980013
AZ127    LA    GRR,AZDB2               SET UP NORMAL RETURN FOR ROUTINE 56010013
*                                    'STRPR' AND BRANCH TO IT.          56040013
         EJECT                                                          56070013
*              'STRPR' ROUTINE                                          56100013
         SPACE 2                                                        56130013
*              THIS ROUTINE PROCESSES STRUCTURE MEMBERS, DETERMINING    56160013
*        TRUE LEVEL NUMBERS AND MAKING ENTRIES IN THE STRUCTURE TABLE.  56190013
         SPACE 4                                                        56220013
STRPR    TM    FLAGS(GRATCA),CFLAG4    IS THE MEMBER OF STRUCTURE       56250013
         BC    BO,AZ135              FLAG ON                            56280013
         SPACE 1                                                        56310013
         CLI   PRESNT,1                IS PRESENT=1.                    56340013
         BC    BE,AZ132                                                 56370013
         SPACE 1                                                        56400013
         SPACE 2                                                        56430013
*              HERE WE HAVE FOUND THAT THE DECLARED LEVEL OF THIS MAJOR 56460013
*        STRUCTURE IS NOT UNITY. THIS MUST BE FORCED, AND WE GENERATE   56490013
*        A DIAGNOSTIC TO SAY SO.                                        56520013
         SPACE 2                                                        56550013
*              CALL THE ERROR ROUTINE TO PUT OUT DIAGNOSTIC NO. X'0225' 56580013
         SPACE                                                          56610013
         BAL   GRL,ERROR(GREMB)                                         56640013
         DC    X'0225C800'                                              56670013
         SPACE 2                                                        56700013
         MVI   PRESNT,1                SET PRESENT = 1.                 56730013
         SPACE 3                                                        56760013
*              HERE WE KNOW THAT THE IDENTIFIER IS AT LEVEL ONE. WE ASK 56790013
*        WHETHER IT IS IN FACT A STRUCTURE. IF THE 'END OF STRUCTURE'   56820013
*        BIT IS SET, IT IS NOT A STRUCTURE.                             56850013
         SPACE 2                                                        56880013
AZ132    TM    OTHER1(GRATCA),LMSTRC                                    56910013
         BC    BZ,AZ132A                                                56940013
         SPACE 2                                                        56970013
*              HERE IT IS NOT A STRUCTURE.                              57000013
         SPACE                                                          57030013
         SPACE                                                          57060013
         OI    TESTMK+2(GRATCA),X'02'  ALTER TEST MASK TO ALLOW 'LIKE'  57090013
*                                    ATTRIBUTE                          57120013
         NI    FLAGS(GRATCA),NFLAG6    TURN OFF 'LEVEL NUMBER APPLIED'  57150013
*                                    FLAG                               57180013
         SPACE                                                          57210013
         NI    OTHER1(GRATCA),NMSTRC   TURN OFF 'LAST MEMBER OF STRUCT' 57240013
*                                    BIT                                57270013
         SPACE                                                          57300013
         BCR   BR,GRR                  RETURN                           57330013
         SPACE 3                                                        57360013
*              HERE IT IS A MAJOR STRUCTURE. WE CLEAR THE CDT1 TABLE    57390013
         SPACE                                                          57420013
AZ132A   L     GRCDT1,ACDT1            POINT GRCDT1 AT THE STRUCTURE    57450013
*                                    TABLE                              57480013
         MVI   0(GRCDT1),X'00'                                          57510013
         MVC   1(256,GRCDT1),0(GRCDT1)                                  57540013
         MVI   4(GRCDT1),1             SET UP LEVEL NUMBER 'ONE' IN THE 57570013
*                                    CDT1 TABLE                         57600013
         OI    OTHER4(GRATCA),MAJSTR   SET ON THE 'MAJOR STRUCTURE' BIT 57630013
*                                    IN THE 'OTHER 4' BYTE.             57660013
         OI    DCLATT(GRATCA),STRUC    SET ON THE 'STRUCTURE' BIT IN    57690013
*                                    THE DECLARED ATTRIBUTE REGION      57720013
         SPACE                                                          57750013
         OI    FLAGS(GRATCA),CFLS45    SET ON CFLAG4 (MEMBER OF STRUCT) 57780013
*                                    AND CFLAG5 (MAJOR STRUCTURE)       57810013
         SPACE                                                          57840013
         OI    VARBLE(GRATCA),MEMSTR   SET ON 'MEMBER OF STRUCTURE' BIT 57870013
*                                    IN VARIABLE BYTE.                  57900013
         SPACE                                                          57930013
         MVC   COUNT1(4,GRATCA),CD4    SET COUNT1 TO 4                  57960013
         SPACE                                                          57990013
         BC    B,AZ133                                                  58020013
         SPACE 2                                                        58050013
*              SET ON THE 'MEMBER OF STRUCTURE' BIT IN THE VARIABLE     58080013
*        BYTE                                                           58110013
         SPACE                                                          58140013
AZ135    OI    VARBLE(GRATCA),MEMSTR                                    58170013
         SPACE 2                                                        58200013
*              NOW POINT GR1 AT THE CURRENT ENTRY IN THE CDT1 STRUCTURE 58230013
*        TABLE                                                          58260013
         SPACE                                                          58290013
AZ135A   L     GR2,COUNT1(0,GRATCA)    PUT COUNT1 INTO GR2.             58320013
         LR    GR1,GR2                                                  58350013
         A     GR1,ACDT1               POINT GR1 AT CDT1 TABLE ENTRY    58380013
*                                    FOR CURRENT STRUCTURE MEMBER.      58410013
         SPACE 2                                                        58440013
*        TEST THE LEVEL NUMBER IN THE CURRENT ENTRY. COMPARE IT WITH    58470013
*        'PRESENT'                                                      58500013
         SPACE                                                          58530013
         CLC   0(1,GR1),PRESNT                                          58560013
         BC    BL,AZ131                                                 58590013
         SPACE 2                                                        58620013
*              IT IS NOT  LESS THAN PRESENT, SO WE SCAN BACK UP THE     58650013
*        TABLE FOR THE ENTRY WITH THE SAME LEVEL NUMBER AS IN 'PRESENT' 58680013
         SPACE                                                          58710013
         S     GR2,CD4                                                  58740013
         ST    GR2,COUNT1(0,GRATCA)                                     58770013
         BC    B,AZ135A                                                 58800013
         SPACE 2                                                        58830013
*              HERE WE HAVE COME TO THE CORRECT ENTRY IN THE STRUCTURE  58860013
*        TABLE                                                          58890013
         SPACE                                                          58920013
AZ131    CH    GR2,CD248               CHECK THAT TRUE LEVEL NUMBER     58950013
         BC    BLE,AZ131A            DOES NOT EXCEED 63.                58990015
         SPACE                                                          59040013
         BAL   GRL,ERROR(GREMB)        HERE IT HAS, SO WE GENERATE A    59070013
         DC    X'0226C400'           DIAGNOSTIC AND SET FLAG TO IGNORE  59100013
         OI    CDFLAG(GRATCA),NODICT THIS DECLARATION.                  59130013
         NI    FLAGS(GRATCA),NFLAG4                                     59160013
         NI    VARBLE(GRATCA),NOTSTR                                    59190013
         MVC   PAR1+2(2,GRDCPT),DRPRMS PICK UP MOST RECENT STRUCTURE    59220013
         L     GRL,ZDRFAB(0,GRCP)    MEMBER. SET ON 'LAST MEMBER OF     59250013
*                                    STRUCTURE' BIT IN IT.              59280013
         LR    GR2,GRR                                                  59310013
         BALR  GRR,GRL                                                  59340013
         L     GR1,PAR1(0,GRDCPT)                                       59370013
         OI    STOTH1(GR1),LMSTRC                                       59400013
         BCR   BR,GR2                                                   59430013
         SPACE                                                          59460013
*              HERE THE TRUE LEVEL NUMBER DOES NOT EXCEED 63.           59550015
         SPACE                                                          59640013
AZ131A   LA    GR2,4(GR2)              BUMP COUNT1 BY 4.                59670013
         ST    GR2,COUNT1(0,GRATCA)                                     59700013
         BC    BE,AZ136                IF THE TRUE LEVEL NUMBER = 63,   59705015
*                                    GO AND FORCE THIS STRUCTURE MEMBER 59710015
*                                    TO BE A BASE ELEMENT.              59715015
*        (CONDITION CODE FOR THE BRANCH WAS SET BY THE CH INSTRUCTION   59720015
*        AT AZ131.)                                                     59725015
         SPACE 2                                                        59730013
         CLC   PRESNT(1),NEXT          COMPARE PRESENT WITH NEXT        59760013
         BC    BNL,AZ136                                                59790013
         SPACE                                                          59820013
*              HERE 'PRESENT' IS LESS THAN 'NEXT'. HENCE THIS IS NOT A  59850013
*        BASE ELEMENT.                                                  59880013
         SPACE                                                          59910013
AZ131B   OI    DCLATT(GRATCA),STRUC    SET ON 'STRUCTURE' BIT IN        59940013
*                                    DECLARED ATT. REGION               59970013
         BC    B,AZ136A                                                 60000013
         SPACE 2                                                        60030013
*              HERE WE CHECK WHETHER WE HAVE REACHED THE END OF THE     60060013
*        STRUCTURE.                                                     60090013
         SPACE                                                          60120013
AZ136    CLI   NEXT,1                  IS NEXT = 1.                     60150013
         BC    BNE,AZ136A                                               60180013
         SPACE 2                                                        60210013
*              HERE 'NEXT' IS = 1. SO WE HAVE REACHED THE END OF THE    60240013
*        STRUCTURE.                                                     60270013
         SPACE                                                          60300013
         OI    OTHER1(GRATCA),LMSTRC   SET ON THE 'LAST MEMBER OF       60330013
*                                    STRUCTURE' BIT.                    60360013
         SPACE 2                                                        60390013
*              HERE WE ARE PROCESSING A MINOR STRUCTURE OR BASE         60420013
*        ELEMENT                                                        60450013
         SPACE                                                          60480013
AZ136A   L     GR2,ACDT1               POINT GR2 BACK AT THE ENTRY FOR  60510013
         A     GR2,COUNT1(0,GRATCA)  THE CONTAINING STRUCTURE.          60540013
         S     GR2,CD4                                                  60570013
         MVC   STRUCT+2(2,GRATCA),2(GR2) MOVE THE DICT REF TO THE       60600013
         NI    STRUCT+3(GRATCA),X'FC'   CONTAINING STRUCT. INTO THE  I1 60630016
*                                    'STRUCTURE INFORMATION' IN THE     60660013
*                                    ATT. COLL. AREA                    60690013
         SPACE 2                                                        60720013
*              NOW WE ARE PROCESSING ANY STRUCTURE MEMBER               60750013
         SPACE                                                          60780013
AZ133    L     GR2,ACDT1               POINT GR2 AT CURRENT STRUCTURE   60810013
         A     GR2,COUNT1(0,GRATCA)  TABLE ENTRY.                       60840013
         SPACE                                                          60870013
         MVC   0(1,GR2),PRESNT         STORE 'PRESNT' INTO STRUCTURE    60900013
*                                    TABLE ENTRY                        60930013
         MVC   STRUCT(1,GRATCA),PRESNT AND STORE IT INTO THE            60960013
*                                    'STRUCTURE INFORMATION' IN THE     60990013
*                                    ATT. COLL. AREA                    61020013
         SPACE 2                                                        61050013
*              NOW WE CALCULATE THE TRUE LEVEL NUMBER (N) OF THE        61080013
*        CURRENT STRUCTURE MEMBER. THIS IS GIVEN BY,                    61110013
*              N =  COUNT1 / 4 .                                        61140013
         SPACE                                                          61170013
         L     GR3,COUNT1(0,GRATCA)    DIVIDE COUNT1 BY 4.              61200013
         SRA   GR3,2                                                    61230013
AZ133A   STC   GR3,STRUCT+1(GRATCA)    PUT THE TRUE LEVEL NUMBER INTO   61260013
*                                    THE 'STRUCTURE INFORMATION IN THE  61290013
*                                    ATTRIBUTE COLLECTION AREA.         61320013
         SPACE                                                          61350013
         OI    CDFLAG(GRATCA),PRDATA   SET 'DATA' FLAG IN PRIVATE FLAG  61380013
*                                    BYTE                               61410013
         SPACE                                                          61440013
         BCR   BR,GRR                  RETURN                           61470013
         EJECT                                                          61500013
*              'ATLSCN' ROUTINE, SCAN ATTRIBUTE LIST.                   61530013
         SPACE 4                                                        61560013
*              FIRST WE BUMP GRSCAN OVER THE BCD.                       61590013
ATLSCN   SR    GR1,GR1                                                  61620013
         SPACE                                                          61650013
AZDH1    EQU   ATLSCN                                                   61680013
         SPACE                                                          61710013
         IC    GR1,0(GRSCAN)           PUT BCD LENGTH IN GR1            61740013
         LA    GRSCAN,1(GR1,GRSCAN)    BUMP GRSCAN TO FIRST BYTE AFTER  61770013
*                                    BCD.                               61800013
*              TEST THE BYTE POINTED AT BY THE SCAN POINTER             61830013
AZ143A   CLI   0(GRSCAN),ATTMKR        IS IT AN ATTRIBUTE MARKER        61860013
         BC    BE,AZ137                                                 61890013
         SPACE 1                                                        61920013
         CLI   0(GRSCAN),COMMA         IS IT A COMMA                    61950013
         BC    BE,AZ138                                                 61980013
         SPACE                                                          62010013
         CLI   0(GRSCAN),ENDBLK        IS IT AN 'END OF TEXT BLOCK'     62040013
         BC    BE,AZ138A             MARKER                             62070013
         SPACE 1                                                        62100013
         CLI   0(GRSCAN),SEMCLN        IS IT A SEMICOLON                62130013
         BC    BE,AZ139                                                 62160013
         SPACE 1                                                        62190013
         CLI   0(GRSCAN),RFBRKT        IS IT A RIGHT FACTOR BRACKET     62220013
         BC    BE,AZ140                                                 62250013
         SPACE 1                                                        62280013
         CLI   0(GRSCAN),X'00'         IS IT ZERO                       62310013
         BC    BE,AZ141                                                 62340013
         SPACE 1                                                        62370013
         CLI   0(GRSCAN),RBRCKT        IS IT A RIGHT BRACKET            62400013
         BC    BE,AZ142                                                 62430013
         SPACE 2                                                        62460013
*              IF IT IS NONE OF THESE, COMPILER ERROR, DUMP             62490013
         SPACE 2                                                        62520013
         SPACE 2                                                        62550013
         DC    X'0000'                                                  62580013
         SPACE 2                                                        62610013
AZ137    LR    GRATPO,GRSCAN           AET ATTRIBUTE POINTER TO THE     62640013
*                                    SAME BYTE AS THE SOURCE POINTER    62670013
         BAL   GRR,CDATPR(0,GREKB)     PROCESS ATTRIBUTES               62700013
         SPACE                                                          62730013
         NI    FLAGS+1(GRATCA),NFLA12  SET OFF CFLAG12                  62760013
         LR    GRSCAN,GRATPO           RESET SOURCE POINTER FROM THE    62790013
         BC    B,AZ143A              ATTRIBUTE POINTER                  62820013
         SPACE 2                                                        62850013
*              HERE GRSCAN POINTS AT AN 'END OF TEXT BLOCK' MARKER.     62880013
AZ138A   TM    FLAGBT,BLKSW            HAVE WE ALREADY CROSSED A BLOCK  62910013
         BC    BZ,AZ138B             BOUNDARY                           62940013
         MVC   BLNKFN(4),BLANK1                                         62970013
         BAL   GRR,BLANK(0,GREKB)      GO TO BLANK OUT PREVIOUS BLOCK.  63000013
         MVC   BLNKST(4),BLANK2                                         63030013
         SPACE                                                          63060013
AZ138B   OI    FLAGBT,BLKSW                                             63090013
         ST    GRSCAN,PAR2(0,GRDCPT)             SAVE TEXT REF OF 'ED'  63120013
         MVC   PAR1+1(1,GRDCPT),DCBLK1+1(GREMB)  IN 'BLANK1'            63150013
         L     GRL,ZTXTRF(0,GRCP)                                       63180013
         BALR  GRR,GRL                                                  63210013
         MVC   BLANK1(4),PAR1(GRDCPT)                                   63240013
         L     GRL,ZCHAIN(GRCP)        GET NEXT TEXT BLOCK IN CHAIN     63270015
         TM    DCLATT(GRATCA),GENRIC   IS THIS A GENERIC IDENTIFIER     63300015
         BC    BO,AZ138E               IF SO, BRANCH              33884 63310020
         TM    FLAGS(GRATCA),CFLAG2    IS THIS AN ENTRY NAME WITH 33884 63320020
*                                    PARAMETER DESCRIPTION.       33884 63330020
         BC    BZ,AZ138C               GO IF NOT                  33884 63340020
         OI    FLAGS4(GRATCA),CFLA25   SET FLAG TO INDICATE       33884 63350020
*                                    'BLOCK CROSSED AFTER NON-    33884 63360020
*                                    GENERIC ENTRY NAME PARM.LIST'33884 63370020
AZ138E   MVI   PAR2+3(GRDCPT),X'04'    KEEP OLD BLOCK BUSY.       33884 63380020
         BALR  GRR,GRL                                                  63390015
         BC    B,AZ138D                DO NOT UPDATE DCBLK1             63420015
AZ138C   MVI   PAR2+3(GRDCPT),X'02'    MARK OLD BLOCK 'NOT WANTED'      63450015
         BALR  GRR,GRL                                                  63480015
         MVC   DCBLK1(4,GREMB),PAR1(GRDCPT)    UPDATE DCBLK1            63510015
AZ138D   L     GRSCAN,PAR2(GRDCPT)     POINT GRSCAN AT NEW BLOCK        63540015
         MVC   BLANK2(4),PAR1(GRDCPT)  SAVE TEXT REF OF FIRST BYTE OF   63570013
*                                    NEW BLOCK IN 'BLANK2'.             63600013
         BC    B,AZ143A                                                 63630013
         SPACE 2                                                        63660013
AZ138    LA    GRNXSP,1(GRSCAN)        STORE SOURCE POINTER + 1 IN      63690013
*                                    'NEXT SOURCE POINTER'.             63720013
         ST    GRNXSP,NXSPST                                            63750013
         TM    CDFLAG(GRATCA),GENFG1   IS GENFG1 ON                     63780013
         BC    BZ,AZDI1                                                 63810013
         SPACE 1                                                        63840013
AZ144    BC    B,AZDI3                 BRANCH, MISSING OUT CALLING THE  63870013
*                                    FACTORED ATTRIBUTE ROUTINE.        63900013
         SPACE 2                                                        63930013
AZ139    OI    FLAGS+1(GRATCA),CFLAG9  SET ON CFLAG 9                   63960013
         BC    B,AZDI3                                                  63990013
         SPACE 2                                                        64020013
AZ140    L     GR2,COUNT2(GRATCA)                                       64050013
         BCTR  GR2,0                   DECREMENT COUNT 2                64080013
         ST    GR2,COUNT2(GRATCA)                                       64110013
         SPACE                                                          64140013
         L     GR2,CURENT                                               64170013
         MVC   CURENT+1(3),4(GR2)      RESET CERRENT TO PREVIOUS LEVEL  64200013
*                                    OF FACTORING.                      64230013
         SPACE 2                                                        64260013
AZ141    LA    GRSCAN,1(GRSCAN)        BUMP SOURCE POINTER BY ONE       64290013
         BC    B,AZ143A                                                 64320013
         SPACE 2                                                        64350013
AZ142    OI    CDFLAG(GRATCA),GENFG2   SET GENFG2 ON                    64380013
*                                      THIS INDICATES 'LAST ITEM IN A   64410013
*                                    GENERIC LIST'                      64440013
         LA    GR0,1(0,GRSCAN)                                          64470013
         ST    GR0,NXSPST                                               64500013
         BC    B,AZDI3                 BRANCH, MISSING OUT CALLING THE  64530013
*                                    FACTORED ATTRIBUTES ROUTINE        64560013
         SPACE 2                                                        64590013
AZDI1    CLC   COUNT2(4,GRATCA),CD0    IS COUNT2 ZERO                   64620013
         BC    BE,AZDI3                                                 64650013
         SPACE 2                                                        64680013
AZDI2    BAL   GRR,CDFATT(0,GREMB)     BRANCH TO FACTORED ATTRIBUTES    64710013
*                                    ROUTINE                            64740013
         SPACE 2                                                        64770013
AZDI3    BAL   GRR,CDIMAT(0,GREMB)     BRANCH TO IMPLICIT ATTRIBUTES    64800013
*                                    ROUTINE (IN EM BLOCK)              64830013
         SPACE 2                                                        64860013
         OC    TESTMK(5,GRATCA),SAVE2(GRECB) OR INTO THE TEST MASK ANY  64890013
*                                    ATTRIBUTES THAT HAVE BEEN SEEN     64920013
*                                    INSIDE A 'RETURNS' ATTRIBUTE.      64950013
         SPACE                                                          64980013
         SPACE 2                                                        65010013
         BAL   GRR,CDFLT(0,GREMB)      BRANCH TO DEFAULT ATTRIBUTES     65040013
*                                    ROUTINE                            65070013
         SPACE                                                          65100013
*                                      FALL INTO 'PREPRC' ROUTINE       65140015
         EJECT                                                          65190013
*              PRE-PROCESSING ROUTINE, 'PREPRC'                         65220013
         SPACE 4                                                        65250013
*              THIS ROUTINE PERFORMS SOME CHECKING IMMEDIATELY BEFORE   65280013
*        WE GO TO ROUTINE 'CDICEN' TO MAKE THE DICTIONARY ENTRY.        65310013
         SPACE 4                                                        65340013
PREPRC   TM    FLAGS+1(GRATCA),CFLA16  IS THIS AN INTERNAL ENTRY LABEL  65400015
         BC    BZ,PREP2                IF SO, GO AND CHECK WHETHER IT   65460013
         BAL   GRR,INTENT            IS BEING MULTIPLY DECLARED         65490013
         SPACE                                                          65520013
PREP2    TM    DCLATT(GRATCA),LABEL    IS IT 'LABEL', IF SO, DON'T      65550013
         BC    BO,PREP3              CHECK FOR POS.                     65580013
         SPACE                                                          65610013
         TM    VARBLE(GRATCA),VALPOS   HAS 'POS' BEEN GIVEN.            65640013
         BC    BZ,PREP3                IF SO, GO TO CHECK WHETHER       65670013
         BAL   GRR,POSCHK            'DEFINED' HAS BEEN GIVEN.          65700013
         SPACE                                                          65730013
PREP3    TM    OTHER2(GRATCA),CNTRLD   IS THIS 'CTL' OR 'BASED'   28459 65750019
         BC    BNO,PREP3A                                         28459 65770019
         TM    VARBLE(GRATCA),DEFND    YES, TEST FOR 'BASED'.     28459 65790019
         BC    BNO,PREP4               IF 'CTL', BRANCH           28459 65810019
PREP3A   TM    OTHER2(GRATCA),FMPRAM   IS THIS A NON-PARAMETER    28459 65830019
         BC    BNO,PREP3B            WHICH IS NOT CONTROLLED       H400 65840019
         BAL   GRR,NCPALD              IF NOT, CHECK THAT WE HAVE  H400 65850019
*                                    NOT HAD VAR. DIMS., AREA SIZE H400 65860019
*                                    OR STRING LENGTH.             H400 65870019
         BC    B,PREP4                                             H400 65880019
PREP3B   TM    FLAGS(GRATCA),CFLAG3                                H400 65890019
         BC    BZ,PREP4                                                 65910013
         BAL   GRR,NCALD               IF SO, GO TO CHECK THAT WE HAVE  65940013
*                                    NOT HAD * STRING LENGTH OR *       65970013
*                                    DIMENSIONS                         66000013
         SPACE                                                          66030013
PREP4    TM    FLAGS(GRATCA),CFLAG3    IS THIS A PARAMETER DECLARED     66060013
         BC    BO,PREP5              'INITIAL'.                         66090013
         TM    DCLATT(GRATCA),STRUC                                     66120013
         BC    BO,PREP5                                                 66150013
         TM    VARBLE(GRATCA),INVLIK                                    66180013
         BC    BZ,PREP5                                                 66210013
         BAL   GRR,INTPAR              IF IT IS, GO TO CHECK THAT IT IS 66240013
*                                    'CONTROLLED'.                      66270013
         SPACE                                                          66300013
PREP5    TM    DCLATT+1(GRATCA),RSMBIT HAVE WE HAD 'VARYING'.           66330013
         BC    BO,PREP6                                                 66360013
         TM    DATABT(GRATCA),VARYNG                                    66390013
         BC    BZ,PREP6                IF SO, CHECK THAT THIS IS        66420013
         BAL   GRR,VARCHK            A STRING.                          66450013
         SPACE                                                          66480013
PREP6    TM    FLAGS(GRATCA),CFLAG4    IS THIS A MEMBER OF A STRUCTURE. 66510013
         BC    BZ,PREP6A               IF SO, GO AND APPLY ANY          66540013
         BAL   GRR,NHERIT            INHERITED DIMENSIONS.              66570013
         SPACE                                                          66600013
PREP6A   TM    DCLATT(GRATCA),NTRY     IS THIS AN ENTRY POINT, IF SO    66630013
         BC    BZ,PREP7              CHECK WHETHER 'INTERNAL' OR        66660013
         BAL   GRR,SCPCHK            'EXTERNAL' HAS BEEN WRONGLY GIVEN  66690013
         SPACE                                                          66720013
PREP7    TM    CDFLAG(GRATCA),GENFG1   IS THE CURRENT IDENTIFIER A      66750013
         BC    BZ,PREP8              MEMBER OF A GENERIC LIST.          66780013
         BAL   GRR,GENCHK              IF SO, GO TO CHECK THAT IT IS A  66810013
*                                    LEGAL MEMBER.                      66840013
         SPACE 2                                                        66870013
PREP8    TM    OTHER2(GRATCA),CNTRLD   IF STATIC, GO TO CHECK FOR       66900013
         BC    BNM,PREP9             STATIC INITIAL LABELS OR STATIC    66930013
         BAL   GRR,SILCHK            INITIAL CALL.                      66960013
         SPACE 2                                                        66990013
PREP9    TM    DCLATT(GRATCA),LABEL    IF A LABEL VARIABLE, GO TO TEST  67020013
         BC    BZ,PREP10             IF IT IS DIMENSIONED.              67050013
         BAL   GRR,LABVAR                                               67080013
         SPACE 2                                                        67110013
PREP10   TM    FLAGS3(GRATCA),CFLA22   IF WE HAVE APPLIED AN INITIAL I1 67200016
         BC    BZ,PREP11            ATT. WHICH IS INAPPLICABLE TO 27169 67260020
         BAL   GRR,INTCHK            SCALARS, GO TO CHECK THIS IS NOT A 67320013
*                                    SCALAR                             67350013
         SPACE 2                                                        67356020
PREP11   TM    DCLATT(GRATCA),FILE     IF IT IS A FILE, GO TO     27169 67362020
         BC    BNO,PREP12            TEST IF EXT. WITH SAME NAME  27169 67368020
         BAL   GRR,EXTFIL            AS EXT. PROC.                27169 67374020
         SPACE                                                          67380013
PREP12   BC    B,COMPLT                EXIT                             67420015
         EJECT                                                          67470013
         SPACE 4                                                        67500013
*              THIS SECTION OF ROUTINE 'PREPRC' TAKES CARE OF INHERITED 67530013
*        DIMENSIONS.                                                    67560013
         SPACE 4                                                        67590013
*              HERE WE ARE PROCESSING A STRUCTURE MEMBER, AND WE ARE    67620013
*        GOING TO UPDATE ITS STRUCTURE TABLE ENTRY AND THE ATT.COLL.    67650013
*        AREA WITH ITS CORRECT NUMBER OF DIMENSIONS, (INCLUDING ANY     67680013
*        INHERITED ONES).                                               67710013
         SPACE 2                                                        67740013
*              FIRST WE POINT GR2 AT THE CURRENT ENTRY IN THE STRUCTURE 67770013
*        TABLE                                                          67800013
         SPACE                                                          67830013
NHERIT   L     GR2,COUNT1(0,GRATCA)                                     67860013
         A     GR2,ACDT1                                                67890013
         SPACE 2                                                        67920013
*              NOW WE SET UP IN GR1 THE DECLARED NUMBER OF DIMENSIONS   67950013
*        FOR THIS STRUCTURE MEMBER                                      67980013
         SPACE                                                          68010013
         XR    GR1,GR1                                                  68040013
         IC    GR1,DIMINF+1(0,GRATCA)                                   68070013
         SPACE 2                                                        68100013
*              NOW WE TEST WHETHER WE ARE IN A MAJOR STRUCTURE          68130013
         SPACE                                                          68160013
         TM    FLAGS(GRATCA),CFLAG5    IF WE ARE, WE DO NOT NEED TO     68190013
         BC    BO,AZ143              LOOK FOR INHERITED DIMS.     RL00# 68220017
         SPACE 3                                                        68250013
*              HERE WE ARE PROCESSING A MINOR STRUCTURE OR BASE ELEMENT 68280013
*        SO WE PICK UP THE NUMBER OF DIMENSIONS OF THE CONTAINING       68310013
*        STRUCTURE                                                      68340013
         SPACE 2                                                        68370013
*              POINT GR3 AT THE CONTAINING STRUCTURE'S ENTRY IN THE     68400013
*        STRUCTURE TABLE                                                68430013
         SPACE                                                          68460013
         LR    GR3,GR2                                                  68490013
         S     GR3,CD4                                                  68520013
         SPACE 2                                                        68550013
*              NOW WE SET UP IN GR4 THE NUMBER OF DIMENSIONS OF THE     68580013
*        CONTAINING STRUCTURE                                           68610013
         SPACE                                                          68640013
         SR    GRZ,GRZ                                                  68670013
         IC    GRZ,1(0,GR3)                                             68700013
         SPACE 2                                                        68730013
*              NOW WE TEST WHETHER THE CONTAINING STRUCTURE IS          68760013
*        DIMENSIONED                                                    68790013
         SPACE                                                          68820013
         LTR   GRZ,GRZ                 IF THE NUMBER OF DIMENSIONS IS   68850013
         BC    BZ,AZ145A             ZERO, BRANCH ROUND THE NEXT        68880013
*                                    INSTRUCTION                        68910013
         SPACE 2                                                        68940013
*              HERE THE CONTAINING STRUCTURE IS DIMENSIONED             68970013
         SPACE                                                          69000013
AZ145C   OI    VARBLE(GRATCA),DIMENS   WE ENSURE THAT THE CURRENT       69030013
*                                    STRUCTURE MEMBER IS DIMENSIONED.   69060013
*                                    (THIS BIT IS ALREADY SET IF THE    69090013
*                                    CURRENT MEMBER HAD DECLARED        69120013
*                                    DIMENSIONS).                       69150013
         SPACE 2                                                        69180013
*              NOW WE ADD ON THE INHERITED DIMENSIONS TO THE NUMBER OF  69210013
*        DIMENSIONS THAT WERE DECLARED.                                 69240013
         SPACE                                                          69270013
AZ145A   AR    GRZ,GR1                                                  69300013
         SPACE 2                                                        69330013
*              NOW WE CHECK THAT THE DIMENSIONS (DECLARED AND           69360013
*        INHERITED) OF THE CURRENT STRUCTURE MEMBER ARE NOT GREATER     69390013
*        THAN 32.                                                       69420013
         SPACE                                                          69450013
         CH    GRZ,CD32                                                 69480013
         BC    BNH,AZ145                                                69510013
         SPACE 2                                                        69540013
*              HERE THERE ARE MORE THAN 32 DIMENSIONS. WE MUST GENERATE 69570013
*        A DIAGNOSTIC, AND PUT THE CORRECTED NUMBER INTO GR1.           69600013
         SPACE                                                          69630013
         BAL   GRL,ERROR(0,GREMB)      GENERATE ERROR MESSAGE.          69660013
         DC    X'023BC400'                                              69690013
         SPACE                                                          69720013
         SR    GRZ,GR1                 RESET THE COUNT, AND       RL00# 69770017
*        TURN OFF IMMEDIATELY APPLIED DIMENSION BITS - INHERITED  RL00# 69820017
         NI    OTHER1(GRATCA),NASTAJ   DIMENSIONS RETAINED.       RL00# 69870017
         MVC   DIMINF+2(2,GRATCA),CD0  THEN ZERO THE DIMTAB SLOT. RL00# 69920017
         SPACE 3                                                        69970017
*              THE TOTAL NO OF DIMENSIONS IS IN GRZ.              RL00# 70020017
         SPACE                                                          70110013
AZ145    STC   GRZ,DIMINF+1(0,GRATCA)  SET IT UP IN THE ATT.COLL.AREA   70140013
         SPACE 2                                                        70170013
AZ143    MVC   1(1,GR2),DIMINF+1(GRATCA)  SET UP NO. OF DIMS IN THE     70200013
*                                    CURRENT ENTRY.                     70230013
         BCR   BR,GRR                  RETURN                           70260013
         EJECT                                                          70290013
*              THIS SECTION OF ROUTINE 'PREPRC' TAKES CARE OF INTERNAL  70320013
*        ENTRY LABELS                                                   70350013
         SPACE 4                                                        70380013
INTENT   TM    DCLATT(GRATCA),NTRY     HAS AN ATTRIBUTE BEEN SEEN WHICH 70410013
         BCR   BO,GRR                IMPLIES 'ENTRY'.                   70440013
         SPACE                                                          70470013
*              HERE NO ATTRIBUTE HAS BEEN GIVEN IMPLYING 'ENTRY', SO IT 70500013
*        IS A MULTIPLE DECLARATION AND WE GIVE A DIAGNOSTIC.            70530013
         SPACE                                                          70560013
         BAL   GRL,ERROR(GREMB)                                         70590013
         DC    X'0231C400'                                              70620013
         SPACE                                                          70770015
         OI    CDFLAG(GRATCA),NODICT   INHIBIT MAKING OF D.E.     REPAK 70800020
         NI    FLAGS(GRATCA),NFLAG4    SET OFF 'MBR. OF STRUC'FLG.REPAK 70830020
         BCR   B,GRR                   EXIT                       REPAK 70860020
         EJECT                                                          70890013
*              THIS SECTION OF ROUTINE 'PREPRC' TAKES CARE OF 'POS'     70920013
*        WITHOUT 'DEFINED'.                                             70950013
         SPACE 4                                                        70980013
POSCHK   TM    VARBLE(GRATCA),DEFND    HAS 'DEFINED' BEEN GIVEN         71010013
         BCR   BO,GRR                                                   71040013
         SPACE                                                          71070013
*              HERE 'POS' HAS BEEN GIVEN WITHOUT 'DEFINED',SO WE RUB    71100013
*        OUT 'POS' AND GENERATE A DIAGNOSTIC.                           71130013
         SPACE                                                          71160013
         NI    VARBLE(GRATCA),NPOS                                      71190013
         SPACE 2                                                        71220013
CLASH    BAL   GRL,ERROR(0,GREMB)    (COMMON CALLING SEQUENCE)          71250013
         DC    X'0229C800'                                              71280013
         SPACE                                                          71310013
POSC1    BCR   BR,GRR                  RETURN                           71340013
         EJECT                                                          71370013
*              THIS SECTION OF ROUTINE 'PREPRC' CHECKS THAT IF'VARYING' 71400013
*        IS GIVEN, IT IS ON A STRING.                                   71430013
         SPACE                                                          71460013
VARCHK   TM    DATABT(GRATCA),CANSTR                                    71490013
         BCR   BZ,GRR                                                   71520013
         SPACE                                                          71550013
*              HERE IT IS NOT A STRING SO WE DELETE 'VARYING' AND GIVE  71580013
*        A DIAGNOSTIC.                                                  71610013
         SPACE                                                          71640013
         NI    DATABT(GRATCA),X'EF'                                     71670013
         SPACE                                                          71700013
         BC    B,CLASH                                                  71730013
         EJECT                                                          71760013
*              THIS SECTION OF ROUTINE 'PREPRC' CHECKS THAT INITIAL IS  71790013
*        ONLY ALLOWED WITH 'CONTROLLED' PARAMETERS                      71820013
         SPACE 4                                                        71850013
INTPAR   TM    OTHER2(GRATCA),CNTRLD   IS IT 'CONTROLLED'               71880013
         BCR   BO,GRR                                                   71910013
         SPACE                                                          71940013
*              HERE IT IS NOT CONTROLLED SO WE DELETE 'INITIAL' AND     71970013
*        GIVE A DIAGNOSTIC.                                             72000013
         SPACE                                                          72030013
         NI    VARBLE(GRATCA),X'F7'                                     72060013
         SPACE                                                          72090013
         BC    B,CLASH                                                  72120013
         EJECT                                                          72121019
*              THIS SECTION OF ROUTINE 'PREPRC' CHECKS THAT PARAMETERS  72122019
*        WHICH ARE NOT CONTROLLED, DO NOT HAVE VARIABLE DIMENSIONS,     72123019
*        STRING LENGTH OR AREA SIZE.                                    72124019
         SPACE 4                                                        72125019
NCPALD   TM    OTHER1(GRATCA),ADJDIM   IF VARIABLE ARRAY DIMS.,    H400 72126019
         BC    BZ,NCPAL                                            H400 72127019
         TM    OTHER1(GRATCA),ASTDIM   CHECK THAT ARE * DIMENSIONS H400 72128019
         BCR   BNZ,GRR                                             H400 72129019
         BAL   GRL,ERROR(GREMB)        IF NOT, ISSUE ERROR MESSAGE H400 72130019
         DC    X'0241C800'                                         H400 72131019
         SPACE                                                          72132019
NCPAL    TM    DATABT(GRATCA),CANSTR   IS IT A STRING/AREA VAR.    H400 72133019
         BCR   BO,GRR                  NO, SO RETURN.              H400 72134019
         TM    DATABT(GRATCA),ADJLTH   YES, IF ADJUST. AREA SIZE   H400 72135019
*                                    OR STRING LENGTH,             H400 72136019
         BCR   BZ,GRR                                              H400 72137019
         TM    OTHER1(GRATCA),ASTSTL   CHECK FOR * NOTATION.       H400 72138019
         BCR   BNZ,GRR                                             H400 72139019
         BAL   GRL,ERROR(GREMB)        IF NOT, ISSUE ERROR MESSAGE H400 72140019
         DC    X'0241C800'                                         H400 72141019
         BCR   B,GRR                   RETURN                      H400 72142019
         EJECT                                                          72150013
*              THIS SECTION OF ROUTINE 'PREPRC' CHECKS THAT             72180013
*        NON-PARAMETERS WHICH ARE NOT CONTROLLED, DO NOT GET'*'STRING   72210013
*        LENGTH OR DIMENSIONS.                                          72240013
         SPACE 4                                                        72270013
NCALD    TM    OTHER1(GRATCA),ASTDIM   IF ASTERISK DIMENSIONS, DELETE   72300013
         BC    BZ,NCALD2             ASTERISK DIMENSION ATTRIBUTE, AND  72330013
         NI    OTHER1(GRATCA),NASTAJ GENERATE MESSAGE.                  72360013
         NI    VARBLE(GRATCA),NDMENS                                    72390013
         XC    DIMINF+1(3,GRATCA),DIMINF+1(GRATCA) CLEAR 'DIMS' SLOT    72420013
         OI    ASTFLG(GRATCA),X'FF'    'INCORRECT * DIMS.' FLAG ON28459 72430019
         LR    GR2,GRR                                            28459 72440019
         BAL   GRR,CDFLT(GREMB)        CHECK ALIGNMENT ATTRIBUTES 28459 72450019
         BAL   GRR,CLASH                                          28459 72460019
         LR    GRR,GR2                                            28459 72470019
         SPACE                                                          72510013
NCALD2   TM    OTHER1(GRATCA),ASTSTL   IF ASTERISK STRING LENGTH,       72540013
         BCR   BZ,GRR                DELETE ASTERISK STRING ATTRIBUTE,  72570013
         NI    OTHER1(GRATCA),NASTSL AND GENERATE MESSAGE.              72600013
         NI    DATABT(GRATCA),NADJCH                                    72630013
         TM    DATABT(GRATCA),AREA     IS IT AN AREA              28459 72636019
         BC    BZ,NCALD3                                          28459 72642019
         MVC   DATINF+1(2,GRATCA),DARS IF SO, SET DEFAULT AREA    28459 72648019
*                                    SIZE OF 1000 BYTES.          28459 72654019
         BC    B,CLASH                                            28459 72660019
         SPACE                                                          72666019
NCALD3   MVI   DATINF+1(GRATCA),0      IF NOT, SET DEFAULT STRING 28459 72672019
         MVI   DATINF+2(GRATCA),DSTL LENGTH OF 1.                 28459 72678019
         BC    B,CLASH                                            28459 72684019
         EJECT                                                          72690013
*              THIS SECTION OF RUOTINE PREPRC CHECKS WHETHER ENTRY      72720013
*        POINTS HAVE BEEN WRONGLY GIVEN 'INT.' OR 'EXT.' ATTRIBUTES.    72750013
         SPACE                                                          72780013
SCPCHK   TM    FLAGS+1(GRATCA),CFLA16  IS IT INTERNAL ENTRY POINT.      72810013
         BC    BO,SCPC1              BRANCH IF IT IS.                   72840013
         TM    DCLATT+1(GRATCA),INTERN HAVE WE SEEN INTERNAL ATTRIBUTE  72870013
         BC    BO,CLASH                                                 72900013
         BCR   BR,GRR                                                   72930013
         SPACE                                                          72960013
SCPC1    TM    OTHER2(GRATCA),EXTINT   HAVE WE SEEN EXTERNAL ATTRIBUTE  72990013
         BCR   BZ,GRR                                                   73020013
         SPACE                                                          73050013
SCPC2    BC    B,CLASH                                                  73080013
         EJECT                                                          73110013
*              THIS SECTION OF ROUTINE 'PREPRC' CHECKS MEMBERS OF       73140013
*        GENERIC LISTS.                                                 73170013
         SPACE                                                          73200013
GENCHK   TM    DCLATT(GRATCA),NTRY     IF NO ATTRIBUTES IMPLYING ENTRY  73230013
         BC    BO,GENC1              HAVE BEEN GIVEN, IT IS ILLEGAL,    73260013
         BAL   GRL,ERROR(0,GREMB)    AND WE DELETE IT.                  73290013
         DC    X'0235C800'                                              73320013
         BC    B,GENC2                                                  73350013
GENC1    TM    FLAGS3(GRATCA),CFLA20   IF THE MEMBER HAS BEEN GIVEN     73380013
         BCR   BZ,GRR                STRUCTURE PARAMETER DESCRIPTIONS,  73410013
         BAL   GRL,ERROR(0,GREMB)    ITIT IS A DEFERRED FEATURE AND WE  73440013
         DC    X'023DC400'           DELETE IT.                         73470013
GENC2    OI    DCLATT+1(GRATCA),BADGEN                                  73500013
         OI    CDFLAG(GRATCA),NODICT                                    73530013
         LA    GR1,DCNRTN              RESET RETURN LINK IN ATTRIBUTE   73560013
         ST    GR1,LINK(0,GRATCA)    COLLECTION AREA.                   73590013
         BCR   BR,GRR                  RETURN.                          73620013
         EJECT                                                          73650013
*              THIS SECTION OF ROUTINE 'PREPRC' CHECKS FOR STATIC       73680013
*        INITIAL LABELS, AND FOR STATIC INITIAL CALL.                   73710013
         SPACE                                                          73740013
SILCHK   CLI   LIKINV+3(GRATCA),X'0F'                                   73770013
         BC    BE,SILCH1                                                73800013
         TM    DCLATT(GRATCA),LABEL                                     73830013
         BCR   BZ,GRR                                                   73860013
         TM    DCLATT(GRATCA),STRUC                                     73890013
         BCR   BO,GRR                                                   73920013
         TM    VARBLE(GRATCA),INVLIK                                    73950013
         BCR   BZ,GRR                                                   73980013
SILCH1   NI    VARBLE(GRATCA),NINVLK   DELETE THE 'INITIAL' BIT AND     74010013
         BC    B,CLASH               GIVE A DIAGNOSTIC.                 74040013
         EJECT                                                          74070013
*              THIS SECTION OF ROUTINE 'PREPRC' SETS ON THE 'INITIAL    74100013
*        VALUE' BIT FOR NON-STATIC LABEL ARRAYS.                        74130013
         SPACE                                                          74160013
LABVAR   TM    VARBLE(GRATCA),DIMENS                                    74190013
         BCR   BZ,GRR                                                   74220013
         TM    OTHER2(GRATCA),CNTRLD                                    74250013
         BCR   BM,GRR                                                   74280013
         OI    VARBLE(GRATCA),INVLIK                                    74310013
         BCR   BR,GRR                                                   74340013
         EJECT                                                          74370013
*              THIS SECTION OF ROUTINE 'PREPRC' CHECKS THAT 'INITIAL'   74640013
*        IS NOT WRONGLY APPLIED TO SCALARS.                             74670013
         SPACE                                                          74700013
INTCHK   TM    VARBLE(GRATCA),INVLIK   FIRST CHECK INITIAL HAS NOT      74730013
         BCR   BZ,GRR                ALREADY BEEN DELETED.              74760013
         TM    VARBLE(GRATCA),DIMENS   CHECK WHETHER DIMENSIONED. IF    74790013
         BCR   BO,GRR                NOT, DELETE INITIAL AND GIVE       74820013
         BAL   GRL,ERROR(0,GREMB)    DIAGNOSTIC.                        74850013
         DC    X'0242C800'                                        34348 74880020
         NI    VARBLE(GRATCA),NINVLK                                    74910013
         BCR   BR,GRR                                                   74940013
         EJECT                                                          74942020
*              THE SECTION OF ROUTINE 'PREPRC' CHECKS THAT AN     27169 74944020
*        EXTERNAL FILE CONSTANT DOES NOT HAVE THE SAME NAME       27169 74946020
*        AS THE EXTERNAL PROCEDURE.                               27169 74948020
         SPACE                                                          74950020
EXTFIL   TM    OTHER2(GRATCA),EXTINT   IS IT EXTERNAL             27169 74952020
         BCR   BNO,GRR                 IF NOT, RETURN             27169 74954020
         TM    MDCFLG(GRATCA),MDCEPR   HAS IT THE SAME NAME AS    27169 74956020
*                                    THE EXTERNAL PROC.           27169 74958020
         BCR   BNO,GRR                 IF NOT, RETURN             27169 74960020
         BAL   GRL,ERROR(GREMB)        IF SO, GIVE A DIAGNOSTIC   27169 74962020
         DC    X'0240C800'                                        27169 74964020
         OI    CDFLAG(GRATCA),NODICT   INHIBIT MAKING OF D.E.     27169 74966020
         BCR   B,GRR                   RETURN.                    27169 74968020
         EJECT                                                          74970013
*              THIS SECTION OF ROUTINE 'CDCLSC' COMPLETES THE           75000013
*        PROCESSING OF THE IDENTIFIER ONCE ALL THE INFORMATION          75030013
*        DESCRIBING IT HAS BEEN SET UP IN THE ATT. COLL. AREA.          75060013
         SPACE 4                                                        75090013
COMPLT   TM    CDFLAG(GRATCA),NODICT   WE MAKE THE DICT. ENTRY IF IT IS 75120013
         BC    BZ,CDICEN(0,GREMB)    NOT INHIBITED. THEN WE PERFORM THE 75150013
*                                    NECESSARY POST-PROCESSING.         75180013
DCNRTN   BAL   GRR,PSPROC                                               75210013
         SPACE                                                          75240013
COMP1    TM    FLAGS+1(GRATCA),CFLAG9  IF THIS IS NOT THE LAST ITEM IN  75270013
         BC    BO,COMP2              THE DCL STMNT., WE SET UP GRSCAN   75300013
*                                    AND TURN OFF CFLAG8, THEN BRANCH   75330013
         NI    FLAGS(GRATCA),NFLAG8  BACK TO THE DECLARED IDENTIFIER    75360013
         BC    B,DCIDPR              PROCESSING ROUTINE, FOR THE NEXT   75390013
*                                    IDENTIFIER.                        75420013
         SPACE                                                          75450013
COMP2    TM    FLAGBT,BLKSW            BLANK OUT THE TEXT IN THE        75480013
         BC    BZ,COMP3              CURRENT BLOCK, AND IN THE PREVIOUS 75510013
         NI    FLAGBT,NBLKSW         BLOCK IF THE DCL STMNT CROSSED A   75540013
         MVC   BLNKFN(4),BLANK1      BLOCK BOUNDARY.                    75570013
         BAL   GRR,BLANK(0,GREKB)                                       75600013
         MVC   BLNKST(4),BLANK2                                         75630013
COMP3    ST    GRSCAN,PAR2(0,GRDCPT)                                    75660013
         MVC   PAR1+1(1,GRDCPT),BLNKST+1                                75690013
         L     GRL,ZTXTRF(0,GRCP)                                       75720013
         BALR  GRR,GRL                                                  75750013
         MVC   BLNKFN(4),PAR1(GRDCPT)                                   75780013
         BAL   GRR,BLANK(0,GREKB)                                       75810013
         SPACE                                                          75840013
         LM    0,15,REGST(GRATCA)      RELOAD REGISTERS AND RETURN.     75870013
         BCR   BR,GRR                                                   75900013
         EJECT                                                          75930013
*              THE POST-PROCESSING ROUTINE 'PSPROC'                     75960013
         SPACE 4                                                        75990013
*              THIS ROUTINE PERFORMS THOSE PROCESSING JOBS THAT MUST BE 76020013
*        DONE AFTER THE DICTIONARY ENTRY FOR THE IDENTIFIER HAS BEEN    76050013
*        MADE.                                                          76080013
         SPACE 4                                                        76110013
PSPROC   ST    GRR,PSSTOR(0,GRATCA)    SAVE RETURN REGISTER.            76140013
         SPACE                                                          76170013
         XC    SAVE2(6,GREKB),SAVE2(GREKB) IN ALL CASES WE CLEAR THE    76200013
*                                    SECOND TEST MASK SAVE AREA.        76230013
         SPACE                                                          76260013
         TM    CDFLAG(GRATCA),NODICT   IF THE DICT ENTRY HAS BEEN       76290013
         BC    BO,PSPR8              INHIBITED, WE ONLY EXECUTE THE     76320013
*                                      LAST FEW SECTIONS OF THE POST-   76350013
*                                    PROCESSER.                         76380013
         SPACE                                                          76410013
         MVC   NEWDIC(2),PAR1+2(GRDCPT) WE SAVE THE REF AND ADDRESS OF  76440013
         L     GRR,ZDRFAB(0,GRCP)    THE ENTRY JUST MADE.               76470013
         BALR  GRR,GRR                                                  76500013
         MVC   NEWADR(4),PAR1(GRDCPT)                                   76530013
         EJECT                                                          76560013
*              THIS SECTION OF ROUTINE 'PSPROC' IS USED FOR ENTRY       76590013
*        POINTS WITH PARAMETER DESCRIPTION.                             76620013
*              WE SET UP TWO SLOTS IN CSTCK3. 'REF1' WILL CONTAIN THE   76650013
*        DICT. REF. OF THE ENTRY TYPE 3, 4, OR 5 FOR THE ENTRY POINT.   76680013
*        'REF2' WILL CONTAIN THE OFFSET FROM 'REF1' OF THE BYTE 3 BYTES 76710013
*        BEFORE THE FIRST PARAMETER DICT. REF. SLOT.                    76740013
         SPACE 4                                                        76770013
PSPR1    TM    FLAGS(GRATCA),CFLAG2    THE DICT. REF. FOR THE ENTRY     76800013
         BC    BZ,PSPR2              POINT IS PICKED UP EITHER FROM     76830013
         L     GR1,STK3PT(0,GREKB)   'NEWDIC', OR, IF A FRESH ENTRY     76860013
         TM    DCLATT+1(GRATCA),DIFRTV TYPE 2 HAS BEEN MADE, FROM       76890013
         BC    BZ,PSPR1A             'DEE3X2', AND THE DICT. REF. IS    76920013
         LH    GRR,DEE3X2(0,GREMB)   STORED IN 'REF1'.                  76950013
         BC    B,PSPR1B                                                 76980013
PSPR1A   LH    GRR,NEWDIC                                               77010013
PSPR1B   STH   GRR,REF1(0,GR1)                                          77040013
         SPACE                                                          77070013
         TM    FLAGS+1(GRATCA),CFLA16  IF AN ENTRY TYPE 3 HAS BEEN MADE 77100013
         BC    BO,PSPR1C             REF2 IS SET UP AS 18. IF IT WAS AN 77130013
         LA    GRR,21                ENTRY TYPE 4 OR 5, REF2 IS SET UP  77160013
         BC    B,PSPR1D              AS 21.                             77190013
PSPR1C   LA    GRR,18                                                   77220013
PSPR1D   STH   GRR,REF2(0,GR1)                                          77250013
         EJECT                                                          77280013
*              THIS SECTION OF ROUTINE 'PSPROC' IS USED FOR DEFINED     77310013
*        ITEMS AND BASED VARIABLES.                                     77340013
*              WE ADD THE NEW ENTRY TO THE 'DEFINED' CHAIN, AND POINT   77370013
*        THE SECOND FILE DICT. ENTRY AT THE START OF THE NEW DICT.      77400013
*        ENTRY. IF THE 2ND. FILE STATEMENT AND DICT. ENTRY HAVE ALREADY 77430013
*        BEEN USED THROUGH FACTORING, THE PAIR ARE COPIED.              77460013
         SPACE 4                                                        77490013
PSPR2    DS    0H                                                       77494015
         TM    VARBLE(GRATCA),DEFND    IS IT DEFINED ?  BRANCH IF SO,   77498015
         BC    BO,PSPR22             AND TEST FOR BASED, ETC.           77502015
PSPR20   DS    0H                                                       77506015
         TM    DATABT(GRATCA),X'D4'    IS THIS AN OFFSET VAR ?          77510015
         BC    BNO,PSPR3               NO.  THEN TRY NEXT SECTION.      77514015
         SPACE 2                                                        77518015
*              OFFSET VARIABLE.  NEEDS PROCESSING LIKE BASED, FOR       77522015
*        PEXP AND 2ND FILE D.E. DIC. REF. INSERTIONS.                   77526015
         SPACE                                                          77530015
         MVI   PSPR2F+1,X'00'          DROP THRU ON OFFSET              77532015
         MVC   PAR1+1(3,GRDCPT),DATINF+1(GRATCA)  MOVE THE PEXP TEXT    77534015
         BC    B,PSPR35              REF INTO PAR1, AND BRANCH TO       77538015
*                                    CONVERT TO ABSOLUTE.               77542015
         SPACE                                                          77552015
*              IF THIS IS A BASED STRUCTURE MEMBER, DO NOTHING.         77554015
         SPACE                                                          77556015
PSPR22   DS    0H                                                       77556315
         MVI   PSPR2E+1,X'F0'          ENSURE OFFSET RETURN IS MADE     77556415
         TM    OTHER2(GRATCA),CNTRLD   BASED ?                          77556615
         BC    BZ,PSPR25               NO. PUT ON DEFINED CHAIN, ETC.   77557215
         TM    VARBLE(GRATCA),MEMSTR   STRUCTURE MEMBER ?               77558015
         BC    BZ,PSPR30               NO. PROCESS                      77560015
         TM    OTHER4(GRATCA),MAJSTR   MAJOR ?                          77562015
         BC    BZ,PSPR2E               NO - SKIP PROCESSING             77564015
         BC    B,PSPR30                YES. PROCESS.                    77566015
PSPR25   DS    0H                                                       77570015
         MVC   DFNCHN(2,GRDCPT),NEWDIC DICT. ENTRY, AND GRL TO POINT AT 77580013
PSPR30   DS    0H                                                       77590015
         MVC   PAR1+1(3,GRDCPT),DEFINF+4(GRATCA) THE 2ND. FILE STMNT.   77610013
PSPR35   DS    0H                                                       77620015
         L     GRL,ZTXTAB(0,GRCP)                                       77640013
         BALR  GRR,GRL                                                  77670013
         L     GRL,PAR1(0,GRDCPT)                                       77700013
         MVC   PAR1+2(2,GRDCPT),1(GRL)                                  77730013
         L     GR2,ZDRFAB(0,GRCP)                                       77760013
         BALR  GRR,GR2                                                  77790013
         L     GR3,PAR1(0,GRDCPT)                                       77820013
         SPACE                                                          77850013
         CLI   SLTREF(GR3),0           IF THE PAIR HAVE ALREADY BEEN    77880013
         BC    BE,PSPR2A             USED THROUGH FACTORING, WE CALL    77910013
         MVC   REFST(2),NEWDIC       THE ROUTINE 'SECOP' TO COPY THEM.  77940013
         BAL   GRR,SECOP2(0,GREMB)                                      77970013
         BC    B,PSPR2F                                                 78000015
         SPACE                                                          78030013
PSPR2A   MVC   SLTREF(2,GR3),NEWDIC    IN NON-FACTORING CASE, POINT THE 78060013
*                                    2ND. FILE DICT. ENTRY AT THE NEW   78090013
*                                    DICT. ENTRY.                       78120013
         SPACE                                                          78124015
PSPR2F   DS    0H                  *** THIS INSTRUCTION IS MODIFIED *** 78126015
         BC    B,PSPR2C                BRANCH IF PROCESSING DEFINED OR  78128015
*                                    BASED - NO-OP IF PROCESSING OFFSET 78130015
         MVI   PSPR2F+1,X'F0'          RESET SWITCH TO BRANCH, AND      78135515
         MVI   PSPR2E+1,X'00'        ENSURE WE DROP OUT THIS TIME.      78136015
         MVC   DEFINF+4(3,GRATCA),DATINF+1(GRATCA)     PUT A VALID      78137015
         BC    B,PSPR2D              TEXT REFERENCE INTO DEFINF.        78137215
         SPACE                                                          78137415
PSPR2C   TM    OTHER2(GRATCA),CNTRLD   BASED OR DEFINED ?               78137615
         BC    BNO,PSPR2B              - GO IF DEFINED                  78137815
         SPACE                                                          78138215
*              BASED OR OFFSET                                          78138415
         SPACE                                                          78138615
PSPR2D   DS    0H                                                       78139015
         MVC   11(2,GRL),NEWDIC        IF SO, PUT THIS DIC REF IN       78140015
*                                    THE SECOND FILE SLOT.              78144015
         SPACE                                                          78150013
PSPR2B   LA    GR3,DEFINF+4(0,GRATCA)  WE 'UNWANT' THE BLOCK CONTAINING 78180013
         BAL   GRR,UNWANT            THE 2ND. FILE STMNT. IF NECESSARY. 78210013
PSPR2E   DS    0H                                                       78220015
         BC    B,PSPR20              GO BACK, TO PROCESS OFFSET, MAYBE. 78230015
         EJECT                                                          78240013
*              THIS SECTION OF ROUTINE 'PSPROC' IS USED FOR LIKENED     78270013
*        STRUCTURES.                                                    78300013
*              WE ADD THE STRUCTURE TO THE 'LIKE' CHAIN.                78330013
         SPACE 4                                                        78360013
PSPR3    TM    DCLATT(GRATCA),STRUC                                     78390013
         BC    BZ,PSPR4                                                 78420013
         TM    VARBLE(GRATCA),INVLIK                                    78450013
         BC    BZ,PSPR4                                                 78480013
         MVC   ZLIKCH(2,GRDCPT),NEWDIC                                  78510013
         EJECT                                                          78540013
*              THIS SECTION OF ROUTINE 'PSPROC' IS USED FOR STRINGS     78570013
*        WHOSE LENGTH IS ADJUSTABLE, BUT NOT ASTERISK.                  78600013
*              WE POINT THE 2ND. FILE DICT. ENTRY AT THE SLOT WHICH     78630013
*        CONTAINS THE REF. OF THE 2ND. FILE STMNT., AND IN THE CASE OF  78660013
*        FACTORING A COPY IS MADE OF THE PAIR.                          78690013
         SPACE 4                                                        78720013
PSPR4    TM    DATABT(GRATCA),CANSTR                                    78750013
         BC    BO,PSPR5                                                 78780013
         TM    DATABT(GRATCA),ADJLTH                                    78810013
         BC    BZ,PSPR5                                                 78840013
         TM    OTHER1(GRATCA),ASTSTL                                    78870013
         BC    BO,PSPR5                                                 78900013
         MVC   PAR1+1(3,GRDCPT),DATINF+1(GRATCA)                        78930013
         L     GRL,ZTXTAB(0,GRCP)                                       78960013
         BALR  GRR,GRL                                                  78990013
         L     GRL,PAR1(0,GRDCPT)                                       79020013
         SPACE                                                          79050013
         LH    GR1,NEWDIC              WE SET UP IN 'REFST' THE DICT    79080013
         STH   GR1,PAR1+2(0,GRDCPT)  REF. OF THE SLOT WHICH CONTAINS    79110013
         L     GR2,NEWADR            THE TEXT REF. OF THE SECOND FILE   79140013
         TM    FLAGS+1(GRATCA),CFLA16 STMNT. FOR NON ENTRY POINTS THE   79170013
         BC    BO,PSPR4B             OFFSET FROM THE START OF THE ENTRY 79200013
         TM    DCLATT(GRATCA),NTRY   IS 16, FOR ENTRY TYPE 3'S IT IS 9, 79230013
         BC    BO,PSPR4A             AND FOR ALL OTHER ENTRY POINTS IT  79260013
         LA    GR2,1(0,GR2)          IS 15.                             79290013
PSPR4A   LA    GR2,6(0,GR2)                                             79320013
PSPR4B   LA    GR2,9(0,GR2)                                             79350013
         ST    GR2,PAR2(0,GRDCPT)                                       79380013
         L     GRR,ZDABRF(0,GRCP)                                       79410013
         BALR  GRR,GRR                                                  79440013
         MVC   REFST(2),PAR1+2(GRDCPT)                                  79470013
         SPACE                                                          79500013
         BAL   GRR,SECOP(0,GREMB)      WE GO TO ROUTINE 'SECOP' TO      79530013
         LA    GR3,DATINF+1(0,GRATCA) POINT THE 2ND. FILE DICT. ENTRY   79560013
         BAL   GRR,UNWANT            AT THE SLOT CONTAINING THE REF. OF 79590013
*                                    THE 2ND. FILE STMNT., AND, IN THE  79620013
*                                    CASE OF FACTORING, TO COPY THE     79650013
*                                    PAIR. THEN WE UNWANT THE BLOCK     79680013
*                                    CONTAINING THE STMNT., IF          79710013
*                                    NECESSARY.                         79740013
         EJECT                                                          79770013
*              THIS SECTION OF ROUTINE 'PSPROC' IS USED FOR ARRAYS WITH 79800013
*        ADJUSTABLE, NON-ASTERISK BOUNDS.                               79830013
*              WE PICK UP THE DESCRIPTION OF EACH BOUND IN THE          79860013
*        DIMENSION TABLE DICT. ENTRY, AND FOR EACH ONE THAT IS          79890013
*        ADJUSTABLE WE PERFORM THE SAME PROCESS AS WE DID ABOVE FOR     79920013
*        STRINGS.                                                       79950013
         SPACE 4                                                        79980013
PSPR5    TM    OTHER1(GRATCA),ADJDIM   FIRST WE SET UP THE DICT. REF.   80010013
         BC    BZ,PSPR6              OF THE DIMENSION TABLE IN GR2 AND  80040013
         TM    OTHER1(GRATCA),ASTDIM ITS ADDRESS IN GR3.                80070013
         BC    BO,PSPR6                                                 80100013
         LH    GR2,DIMINF+2(0,GRATCA)                                   80130013
         STH   GR2,PAR1+2(0,GRDCPT)                                     80160013
         STH   GR2,ZLOCK(0,GRDCPT)                                      80190013
         L     GRL,ZDRFAB(0,GRCP)                                       80220013
         BALR  GRR,GRL                                                  80250013
         L     GR3,PAR1(0,GRDCPT)                                       80280013
         SPACE                                                          80310013
         SR    GR1,GR1                 IN SCANNING THE DIMENSION TABLE  80340013
         IC    GR1,NMDMOF(0,GR3)     WE SHALL UPDATE GR1 TO CONTAIN THE 80370013
         AR    GR1,GR1               NUMBER OF BOUNDS REMAINING TO BE   80400013
         LA    GR3,FRSTBD(0,GR3)     PROCESSED, GR2 TO CONTAIN THE REF. 80430013
*                                    OF THE 'TEXT REF.' SLOT IN THE     80460013
*                                    CURRENT BOUND, AND GR3 TO CONTAIN  80490013
*                                    THE ADDRESS OF THE CURRENT BOUND.  80520013
         SPACE                                                          80550013
PSPR5B   CLI   0(GR3),X'FF'            THIS LOOP PROCESSES ONE BOUND AT 80580013
         BC    BNE,PSPR5A            EACH TIME ROUND. FOR EACH          80610013
         MVC   PAR1+1(3,GRDCPT),1(GR3) ADJUSTABLE ONE, WE POINT THE 2ND 80640013
         L     GRL,ZTXTAB(0,GRCP)    FILE DICT. ENTRY AT THE SLOT IN    80670013
         BALR  GRR,GRL               THE DIMENSION TABLE WHICH CONTAINS 80700013
         L     GRL,PAR1(0,GRDCPT)    THE REF. OF THE 2ND. FILE STMNT.   80730013
         MVC   PAR1+2(2,GRDCPT),DIMINF+2(GRATCA) ALSO, COPIES ARE MADE  80760013
         LA    GR2,1(0,GR3)          OF THE PAIR IF THE DIMENSION       80790013
         ST    GR2,PAR2(0,GRDCPT)    ATTRIBUTE WAS FACTORED.            80820013
         L     GRR,ZDABRF(0,GRCP)                                       80850013
         BALR  GRR,GRR                                                  80880013
         MVC   REFST(2),PAR1+2(GRDCPT)                                  80910013
         BAL   GRR,SECOP(0,GREMB)                                       80940013
         LA    GR3,1(0,GR3)                                             80970013
         BAL   GRR,UNWANT                                               81000013
         BCTR  GR3,0                                                    81030013
PSPR5A   LA    GR3,4(0,GR3)                                             81060013
         BCT   GR1,PSPR5B                                               81090013
         EJECT                                                          81120013
*              THIS SECTION OF ROUTINE 'PSPROC' IS USED FOR INITIALISED 81150013
*        VARIABLES.                                                     81180013
*              WE SEPARATELY PROCESS ORDINARY INITIAL, AND INITIAL      81210013
*        CALL. WHERE 2ND. FILE STATEMENTS ARE CONCERNED, THE CHAIN IS   81240013
*        COMPLETED AND COPIES MADE WHERE NECESSARY.                     81270013
         SPACE 4                                                        81300013
PSPR6    TM    DCLATT(GRATCA),STRUC                                     81330013
         BC    BO,PSPR7                                                 81360013
         TM    VARBLE(GRATCA),INVLIK                                    81390013
         BC    BZ,PSPR7                                                 81420013
         CLI   LIKINV+3(GRATCA),X'0F'                                   81450013
         BC    BE,PSPR6A                                                81480013
         CLI   LIKINV+3(GRATCA),X'F0'                                   81510013
         BC    BNE,PSPR7                                                81540013
         SPACE                                                          81570013
         BAL   GRR,INTPRC(0,GREMB)     FOR THE CASE OF ORDINARY INITIAL 81600013
         BC    B,PSPR7               WE GO TO A ROUTINE IN MODULE IEMEM 81630013
*                                    TO PROCESS IT.                     81660013
         SPACE                                                          81690013
PSPR6A   MVC   PAR1+1(3,GRDCPT),LIKINV(GRATCA) WE POINT GRL AT THE 2ND. 81720013
         L     GRL,ZTXTAB(0,GRCP)    FILE STATEMENT, AND 'REFST' AT THE 81750013
         BALR  GRR,GRL               SLOT WHICH TAKES THE REF. OF THE   81780013
         L     GRL,PAR1(0,GRDCPT)    2ND. FILE STATEMENT.               81810013
         MVC   PAR1+2(2,GRDCPT),NEWDIC                                  81840013
         L     GR2,NEWADR                                               81870013
         AH    GR2,LKIVOF(0,GRATCA)                                     81900013
         ST    GR2,PAR2(0,GRDCPT)                                       81930013
         L     GRR,ZDABRF(0,GRCP)                                       81960013
         BALR  GRR,GRR                                                  81990013
         MVC   REFST(2),PAR1+2(GRDCPT)                                  82020013
         SPACE                                                          82050013
         MVC   PAR1+2(2,GRDCPT),1(GRL) TEST WHETHER THE 2ND. FILE STMNT 82080013
         L     GRR,ZDRFAB(0,GRCP)    HAS ALREADY BEEN USED. IF SO, GO   82110013
         BALR  GRR,GRR               TO COPY IT, OTHERWISE MERELY SLOT  82140013
         L     GRR,PAR1(0,GRDCPT)    IN THE POINTER TO THE DICT. ENTRY  82170013
         CLI   SLTREF(GRR),0         OF THE INITIALISED ITEM.           82200013
         BC    BE,PSPR6B                                                82230013
         BAL   GRR,SECOP2(0,GREMB)                                      82260013
         BC    B,PSPR6C                                                 82290013
         SPACE                                                          82320013
PSPR6B   MVC   SLTREF(2,GRR),REFST                                      82350013
PSPR6C   LA    GR3,LIKINV(0,GRATCA)                                     82380013
         BAL   GRR,UNWANT                                               82410013
         EJECT                                                          82440013
*              THIS SECTION OF ROUTINE 'PSPROC' IS USED FOR STRUCTURE   82470013
*        MEMBERS.                                                       82500013
*              WE COMPLETE THE FORWARD STRUCTURE MEMBER CHAIN, SET UP   82530013
*        INFORMATION TO BE INHERITED, AND UPDATE THE STRUCTURE TABLE,   82560013
*        AND ADJUST VARIOUS FLAGS.                                      82590013
         SPACE 4                                                        82620013
PSPR7    TM    VARBLE(GRATCA),MEMSTR   EXCLUDE NON STRUCTURE-MEMBERS.   82650013
         BC    BZ,PSPR8                                                 82680013
         LH    GR1,NEWDIC                                               82710013
         SPACE                                                          82740013
         TM    FLAGS(GRATCA),CFLAG5    FOR MAJOR STRUCTURES, WE SAVE    82770013
         BC    BZ,PSPR7A             THE 'SCOPE AND STORAGE CLASS' BYTE 82800013
         MVC   STCLAS(1),OTHER2(GRATCA) FOR INHERITING PURPOSES, AND    82830013
         STH   GR1,DRLSMS            ALSO SET UP DRLSMS (DICT. REF. OF  82860013
*                                    MOST RECENT MAJOR STRUCTURE).      82866015
         TM    OTHER2(GRATCA),CNTRLD   TEST                             82872015
         BC    BZ,PSPR7B                   FOR                          82878015
         TM    VARBLE(GRATCA),DEFND           BASED.                    82884015
         BC    BZ,PSPR7B               BRANCH IF NOT.                   82890015
         OI    STCLAS,X'80'            SET DYNAMIC-DEFINED BIT SO THAT  82896015
*                                    DEFINED BIT WILL BE INHERITED FOR  82902015
*                                    ALL STRUCTURE MEMBERS.             82908015
         BC    B,PSPR7B                                                 82914015
         SPACE                                                          82920013
PSPR7A   MVC   PAR1+2(2,GRDCPT),DRPRMS FOR NON-MAJOR STRUCTURE MEMBERS  82950013
         L     GRL,ZDRFAB(0,GRCP)    WE UPDATE THE FORWARD STRUCTURE    82980013
         BALR  GRR,GRL               MEMBER CHAIN WITH THE DICT. REF.   83010013
         L     GR2,PAR1(0,GRDCPT)    OF THE CURRENT MEMBER.             83040013
         AH    GR2,LSTRCF                                               83070013
         MVC   0(2,GR2),NEWDIC                                          83100013
         SPACE                                                          83130013
PSPR7B   MVC   LSTRCF(2),STRCOF        IN ALL CASES WE UPDATE 'LSTRCF'  83160013
*                                    WITH THE OFFSET OF THE 'FORWARD    83190013
*                                    CHAIN SLOT' FROM THE START OF THE  83220013
*                                    DICT. ENTRY WE HAVE JUST MADE.     83250013
         SPACE                                                          83280013
         L     GR2,ACDT1               WITH DICT. REF. OF ENTRY WE HAVE 83310013
         A     GR2,COUNT1(0,GRATCA)  JUST MADE, WE UPDATE 'DRPRMS' AND  83340013
         STH   GR1,2(0,GR2)          THE STRUCTURE TABLE.               83370013
         STH   GR1,DRPRMS                                               83400013
         SPACE                                                          83430013
         TM    DCLATT(GRATCA),STRUC    IF THIS IS A STRUCTURE, SET   I1 83432016
         BC    BZ,PSPR7D             CODE BITS IN THE STRUCT. TABLE  I1 83434016
*                            ENTRY FOR PACKED/ALIGNED INHERITANCE    I1 83436016
         TM    DCLATT+1(GRATCA),PCKD   WAS PACKED/ALIGNED DECLARED   I1 83438016
         BC    BZ,PSPR7C               GO IF NOT                     I1 83440016
         SPACE 1                                                     I1 83442016
         OI    3(GR2),X'02'            SET BIT TO IND. INHERITANCE   I1 83444016
         TM    OTHER4(GRATCA),ALGPAK   WAS IT ALIGNED                I1 83446016
         BC    BZ,PSPR7D               NO.                           I1 83448016
         OI    3(GR2),X'01'            YES - SET 'ALIGNED' CODE BIT  I1 83450016
         BC    B,PSPR7D                                              I1 83452016
         SPACE 1                                                     I1 83454016
*        PACKED/ALIGNED WAS NOT DECLARED, SO MUST BE INHERITED.      I1 83456016
         SPACE 1                                                     I1 83458016
PSPR7C   TM    FLAGS(GRATCA),CFLAG5    IF THIS IS NOT THE MAJOR      I1 83460016
         BC    BO,PSPR7D             STRUCTURE, SET THE INHERITANCE  I1 83462016
         LA    GR3,3                 CODE BITS TO COPY THOSE OF THE  I1 83464016
         S     GR2,CD4               ENTRY FOR THE CONTAINING LEVEL. I1 83466016
         IC    GR1,3(GR2)                                            I1 83468016
         NR    GR1,GR3                 ISOLATE THE 2 CODE BITS       I1 83470016
         STC   GR1,*+5                                               I1 83472016
         OI    7(GR2),0                'OR' THEM INTO THE NEW ENTRY  I1 83474016
         SPACE 2                                                     I1 83476016
PSPR7D   TM    OTHER1(GRATCA),LMSTRC   IF THIS IS THE LAST MEMBER OF I1 83478016
         BC    BZ,PSPR8              THE STRUCTURE, CLEAR APPROPRIATE   83490013
         NI    FLAGS(GRATCA),NFLAG4  FLAGS.                             83550015
         MVI   STCLAS,0                                                 83610013
         EJECT                                                          83640013
*              THIS SECTION OF ROUTINE 'PSPROC' IS USED FOR MEMBERS OF  83670013
*        GENERIC LISTS.                                                 83700013
*              WE POINT THE GENERIC DICT. ENTRY AT THE GENERIC LIST     83730013
*        MEMBER WHICH WE HAVE JUST CONSTRUCTED. IF THE CURRENT MEMBER   83760013
*        IS ILLEGAL, WE ADJUST THE GENERIC ENTRY.                       83790013
         SPACE 4                                                        83820013
PSPR8    TM    CDFLAG(GRATCA),GENFG1   FIRST WE EXCLUDE CASES WHERE THE 83850013
         BC    BZ,PSPR9              IDENT. IS NOT A MEMBER OF A        83880013
         TM    FLAGS(GRATCA),CFLAG8  GENERIC LIST, AND WHERE THE IDENT. 83910013
         BC    BO,PSPR9              IS A PARAMETER INSIDE AN ENTRY     83940013
         MVC   PAR1+2(2,GRDCPT),GENREF ATTRIBUTE. THEN WE SET UP THE    83970013
         L     GRL,ZDRFAB(0,GRCP)    ADDRESS OF THE GENERIC ENTRY IN    84000013
         BALR  GRR,GRL               GR2.                               84030013
         L     GR2,PAR1(0,GRDCPT)                                       84060013
         SPACE                                                          84090013
         TM    DCLATT+1(GRATCA),BADGEN FOR ILLEGAL MEMBERS OF GENERIC   84120013
         BC    BZ,PSPR8A             LISTS WE DECREMENT THE MEMBER      84150013
         IC    GR1,GENOF3(0,GR2)     COUNT IN THE GENERIC DICT. ENTRY.  84180013
         BCTR  GR1,0                                                    84210013
         BCTR  GR1,0                                                    84240013
         STC   GR1,GENOF3(0,GR2)                                        84270013
         BC    B,PSPR9                                                  84300013
         SPACE                                                          84330013
PSPR8A   TM    DCLATT(GRATCA),NTRY                                      84360013
         BC    BZ,PSPR9                                                 84390013
         L     GR1,LISTOF(0,GRATCA)    WE UPDATE THE GENERIC DICT.      84420013
         LA    GR3,0(GR2,GR1)        ENTRY WITH THE DICT. REF. OF THE   84450013
         MVC   PAR1+2(2,GRDCPT),NEWDIC CURRENT MEMBER. THIS REF. IS     84480013
         BALR  GRR,GRL               EITHER IN 'NEWDIC', OR, IF WE HAVE 84510013
         L     GRR,PAR1(0,GRDCPT)    MADE A NEW ENTRY TYPE 2, IT IS IN  84540013
         CLI   0(GRR),E2BYT          THE ENTRY TYPE 2. LASTLY WE UPDATE 84570013
         BC    BNE,PSPR8B            THE OFFSET IN THE GENERIC ENTRY TO 84600013
         MVC   0(2,GR3),E3INE2(GRR)  THE SLOT FOR THE REF. TO THE NEXT  84630013
         BC    B,PSPR8C              MEMBER.                            84660013
PSPR8B   MVC   0(2,GR3),NEWDIC                                          84690013
PSPR8C   LA    GR1,2(0,GR1)                                             84720013
         ST    GR1,LISTOF(0,GRATCA)                                     84750013
         EJECT                                                          84780013
*              THIS SECTION OF ROUTINE 'PSPROC' IS USED FOR GENERIC     84810013
*        ENTRY POINTS.                                                  84840013
*              WE SET UP POINTERS TO THE START OF THE GENERIC ENTRY     84870013
*        AND TO THE SLOT WHICH WILL POINT TO THE FIRST LIST MEMBER.     84900013
*        WE ALSO ADJUST VARIOUS FLAGS.                                  84930013
         SPACE 4                                                        84960013
PSPR9    TM    DCLATT(GRATCA),GENRIC   WE SET GENREF TO POINT AT THE    84990013
         BC    BZ,PSPRA              GENERIC ENTRY, AND LISTOF TO       85020013
         MVC   GENREF(2),NEWDIC      CONTAIN THE OFFSET TO THE SLOT FOR 85050013
         LA    GR2,GNFSDR            THE REF. OF THE FIRST MEMBER.      85080013
         ST    GR2,LISTOF(0,GRATCA)                                     85110013
         SPACE                                                          85140013
         L     GR1,STK3PT(0,GREKB)     INTERCHANGE THE VALUE OF THE     85170013
         XC    POINTR(3,GR1),NXSPST+1 STORED POINTER IN CSTACK3 WITH    85200013
         XC    NXSPST+1(3),POINTR(GR1) THE 'NEXT' SCAN POINTER.         85230013
         XC    POINTR(3,GR1),NXSPST+1                                   85260013
         SPACE                                                          85290013
         OI    CDFLAG(GRATCA),GENFG1   SET FLAG MEANING THAT MEMBERS OF 85320013
*                                    A GENERIC LIST ARE BEING PROCESSED 85350013
         SPACE                                                          85380013
         XC    COUNT1(4,GRATCA),COUNT1(GRATCA) CLEAR COUNT1.            85410013
         SPACE                                                          85440013
         NI    FLAG(GR1),FL9OFF        STACK THE SETTING OF CFLAG9.     85470013
         TM    FLAGS+1(GRATCA),CFLAG9                                   85500013
         BC    BZ,PSPRA                                                 85530013
         OI    FLAG(GR1),FL9ON                                          85560013
         XI    FLAGS+1(GRATCA),CFLAG9                                   85590013
         EJECT                                                          85620013
*              THIS SECTION OF ROUTINE 'PSPROC' IS USED FOR THE LAST    85650013
*        MEMBER OF GENERIC LISTS AND WHEN A BLOCK BOUNDARY HAS          85660020
*        BEEN CROSSED AFTER THE PARMETER LIST OF AN ENTRY NAME          85670020
*        WHICH IS NOT A MEMBER OF A GENERIC LIST.                       85680020
*              WE UNSTACK CFLAGS, RESTORE NXSPST FROM CSTCK3, BUMP DOWN 85710013
*        THE CSTACK3 POINTER, TURN OFFTHE GENERIC FLAGS, AND IN THE     85740013
*        CASE WHERE WE HAVE ALREADY CROSSED A BLOCK BOUNDARY, WE ERASE  85770013
*        THE PREVIOUS BLOCK.                                            85800013
         SPACE 4                                                        85830013
PSPRA    TM    CDFLAG(GRATCA),GENFG2                                    85860013
         BC    BO,PSPRAA                                          33884 85870020
         TM    FLAGS4(GRATCA),CFLA25                              33884 85880020
         BC    BZ,PSPRB                                                 85890013
         TM    FLAGS3(GRATCA),CFLA21   TEST FLAG THAT INHIBITS THIS     85920013
         BC    BO,PSPRB              SECTION.                           85950013
         NI    FLAGS4(GRATCA),NFLA25                              33884 85955020
         BC    B,PSPRAC                                           33884 85960020
         SPACE                                                          85965020
PSPRAA   TM    FLAGS3(GRATCA),CFLA21                              33884 85970020
         BC    BO,PSPRB                                           33884 85975020
         L     GR1,STK3PT(0,GREKB)                                      85980013
         TM    FLAG(GR1),FL9ON                                          86010013
         BC    BZ,PSPRAB                                          33884 86040020
         OI    FLAGS+1(GRATCA),CFLAG9                                   86070013
PSPRAB   MVC   NXSPST+1(3),POINTR(GR1)                            33884 86100020
         SH    GR1,H16                                                  86130013
         ST    GR1,STK3PT(0,GREKB)                                      86160013
         NI    CDFLAG(GRATCA),NOGENS                              33884 86170020
         TM    FLAGS+1(GRATCA),CFLAG9  IF THIS IS ALSO THE LAST   33884 86180020
         BC    BZ,PSPRAC             ID. IN THE DCL STATEMENT,    33884 86200020
         LA    GRSCAN,1(GRSCAN)      BUMP GRSCAN TO POINT AT THE  33884 86220020
*                                    SEMI-COLON FOR BLANK ROUTINE 33884 86240020
         SPACE                                                          86260020
PSPRAC   TM    FLAGBT,BLKSW            IF THIS IS A CASE IN WHICH 33884 86280020
         BC    BZ,PSPRB              A BLOCK BOUNDARY WAS CROSSED 33884 86300020
         MVC   TMFWST(4),DCBLK1(GREMB) BEFORE A GENERIC OR ENTRY  33884 86320020
         MVC   DCBLK1(4,GREMB),BLANK2  ATTRIBUTE, THEN MARK THE   33884 86420020
         LA    GR3,TMFWST+1          OLD BLOCK 'NOT WANTED.'      33884 86520020
         BAL   GRR,UNWANT                                         33884 86620020
         BC    B,PSPRB                                                  86720015
         EJECT                                                          87090013
*              END OF ROUTINE 'PSPROC'.                                 87120013
         SPACE 4                                                        87150013
PSPRC    L     GRR,PSSTOR(0,GRATCA)    RELOAD LINK AND RETURN.          87180013
         BCR   BR,GRR                                                   87210013
         EJECT                                                          87240013
*              'UNWANT' ROUTINE.                                        87270013
         SPACE 4                                                        87300013
*              THIS ROUTINE EXAMINES THE TEXT BLOCK WHOSE REFERENCE IS  87330013
*        POINTED AT BY GR3. IF THE TEXT BLOCK IS DIFFERENT FROM DCBLK1  87360013
*        (THE CURRENT DECLARE BLOCK) IT IS MARKED UNWANTED.             87390013
         SPACE                                                          87420013
UNWANT   CLC   DCBLK1+1(1,GREMB),0(GR3)                                 87450013
         BCR   BE,GRR                                                   87480013
         MVC   PAR1+1(3,GRDCPT),0(GR3)                                  87510013
         MVI   PAR2+3(GRDCPT),X'02'                                     87540013
         L     GRL,ZALTER(0,GRCP)                                       87570013
         BCR   BR,GRL                 (RETURN REGISTER HAS BEEN SET).   87600013
         EJECT                                                          87630013
*              BASIC REGISTER SYMBOLS                                   87660013
         SPACE 4                                                        87690013
GR0      EQU   0                       SCRATCH REGISTER                 87720013
GR1      EQU   1                       SCRATCH REGISTER                 87750013
GR2      EQU   2                       SCRATCH REGISTER                 87780013
GR3      EQU   3                       SCRATCH REGISTER                 87810013
GRATCA   EQU   4                       POINTER TO HEAD OF ATTRIBUTE     87840013
*                                    COLLECTION AREA                    87870013
GRCDT1   EQU   5                       POINTER TO HEAD OF STRUCTURE'S   87900013
*                                    CDT1 TABLE                         87930013
GRTMSC   EQU   6                       TEMPORARY SCAN REGISTER          87960013
GRSCAN   EQU   7                       TEXT SCAN REGISTER               87990013
GRATPO   EQU   8                       ATTRIBUTE POINTER                88020013
GRELB    EQU   9                       BASE FOR EL BLOCK                88050013
GRECB    EQU   10                      BASE FOR EC BLOCK                88080013
GREKB    EQU   10                      BASE FOR EK BLOCK                88110013
GRCP     EQU   11                      POINTER TO HEAD OF CONTROL PHASE 88140013
GREMB    EQU   12                      BASE FOR EM BLOCK                88170013
GRDCPT   EQU   13                      DICTIONARY POINTER               88200013
GRR      EQU   14                      RETURN REGISTER                  88230013
GRL      EQU   15                      LINK REGISTER                    88260013
         SPACE 2                                                        88290013
*              OTHER SYMBOLS FOR REGISTERS                              88320013
         SPACE 1                                                        88350013
GRNXSP   EQU   GR1                 'NEXT' SCAN POINTER                  88380013
GRHASH   EQU   GR0                                                      88410013
GRLTH    EQU   GR1                                                      88440013
GRX      EQU   GR2                                                      88470013
GRY      EQU   GR3                                                      88500013
GRZ      EQU   GRCDT1                                                   88530013
GR4      EQU   GRR                                                      88560013
GRPTR    EQU   GRL                                                      88590013
GR5      EQU   GRL                                                      88620013
GRB      EQU   GR2                                                      88650013
GSTART   EQU   GR2                     POINTER TO START OF DECLARATION  88680013
*                                      LIST                             88710013
         EJECT                                                          88740013
CDZEMP   DS    F                       TEMP. FULL-WORD LOCATION         88770013
NEXDCL   DS    F                       LOCATION FOR DICT REF OF NEXT    88860013
*                                    DECLARE STATEMENT                  88890013
TEMMAX   DS    F                       TEMPORARY STORAGE FOR 'MAX'      89010013
TMCNT2   DC    F'0'                    TEMPORARY STORAGE FOR 'COUNT2'   89040013
TMFWST   DS    F                       TEMP FULL-WORD STORE.            89070013
STATMK   DC    X'FFDE4A0E9F8B'         TEST MASK FOR 'STATIC' ATT.      89090015
BASDMK   DC    X'FDF80F0E8F8B'         TEST MASK FOR 'BASED' ATT.       89110015
AUTOMK   DC    X'FFF94E0E9F9B'         TEST MASK FOR 'AUTOMATIC' ATT.   89130013
CONTMK   DC    X'FFFCFE0E9F9B'         TEST MASK FOR 'CONTROLLED' ATT.  89160013
DRPRMS   DC    H'0'                    SLOT FOR DICT REF OF MOST RECENT 89340013
*                                    STRUCTURE MEMBER.                  89370013
DRLSMS   DC    H'0'                    SLOT FOR DICT REF OF LAST MAJOR  89400013
*                                    STRUCTURE.                         89430013
NEWADR   DC    F'0'                    SLOT FOR ADDRESS OF DICT. ENTRY  89460013
*                                    MOST RECENTLY MADE.                89490013
         SPACE                                                          89495019
FLAGBT   DC    X'00'                   FLAG BYTE                        89500019
BLKSW    EQU   X'80'                   END OF BLOCK SWITCH              89505019
NBLKSW   EQU   X'FF'-BLKSW             ANDING VALUE.                    89510019
         SPACE                                                          89515019
DSTL     EQU   X'01'                   DEFAULT STRING LENGTH.     28459 89520019
DARS     DC    H'1000'                 DEFAULT AREA SIZE.         28459 89525019
         SPACE                                                          89530019
CD0      DC    F'0'                    DEFINE INTEGER                   89535019
CD4      DC    F'4'                    DEFINE INTEGER                   89540019
CD3      DC    H'3'                                                     89545019
CD32     DC    H'32'                                                    89550013
CD248    DC    H'248'                                                   89580013
         EJECT                                                          89980015
*              THIS FINAL SECTION OF ROUTINE 'PSPROC' IS USED FOR ALL   90380015
*        IDENTIFIERS. WE CLEAR THE ATTRIBUTE COLLECTION AREA EXCEPT FOR 90780015
*        THE FOLLOWING:-                                                91080020
*        CFLA21,CFLA25,CFLAG4,CFLAG9,GENFG1,GENFG2,DCLNUM,              91380020
*        CFLA18 - FINAL ABORT FLAG - IS ALSO RETAINED.               I1 91780016
         SPACE 4                                                        91980015
PSPRB    DS    0H                                                    I1 92180016
         NI    FLAGS3(GRATCA),CFLA18+CFLA21                          I1 92380016
         NI    FLAGS4(GRATCA),CFLA25                              33884 92680020
         MVI   FLAGS4+1(GRATCA),0                                 33884 92980020
         MVC   FLAGS4+2(ZL4,GRATCA),FLAGS4+1(GRATCA)              33884 93280020
         NI    CDFLAG(GRATCA),NOTGNF                                    93580015
         NI    FLAGS(GRATCA),CFLAG4                                     93980015
         NI    FLAGS+1(GRATCA),CFLAG9                                   94380015
         MVI   DATINF(GRATCA),0                                         94780015
         MVC   DATINF+1(ZL3,GRATCA),DATINF(GRATCA)                      95180015
         MVI   BCDTRF(GRATCA),0                                         95580015
         MVC   BCDTRF+1(ZL5,GRATCA),BCDTRF(GRATCA)                      95980015
         MVI   ASTFLG(GRATCA),0                                   28459 96380019
         MVC   ASTFLG+1(ZL2,GRATCA),ASTFLG(GRATCA)                28459 96780019
         BC    B,PSPRC                                                  97180015
         END                                                            97580015
