EM       TITLE 'IEMEM, DECLARE PASS TWO, DICTIONARY, PL/I F'            00030013
         SPACE 3                                                        00060013
*              STATUS - CHANGE LEVEL 0.                                 00090064
*                                                                       00090364
*                                                                       00090664
*                                                                       00090764
* 5.4  A 659700.                                              MAC 52204 00090864
*      C 662500-662800.                                       MAC 52204 00090964
*      D 661300-661500.                                       MAC 52204 00091064
* 5.4  C 661600.                                              MAC 52184 00091264
* 5.3A A 276600.                                              MAC 43457 00091564
*      C 280500.                                              MAC 43457 00091864
* 5.2B A 047040.                                              MAC 33884 00092164
* 5.2  A 661500,662700.                                       MAC 34341 00092464
*      C 660000-660600.                                       MAC 34341 00092764
* 5.2  A 462300,463200,706200,707400.                         MAC 32270 00093064
* 5.1  A 687000.                                              MAC 28459 00093364
*      C 120600-120900,626700,670800-671100.                  MAC 28459 00093664
* 5.1          THE FOLLOWING STATEMENTS, ENVOLVING THE OBSOLETE         00093964
*        'SETS' AND 'USES' ATTRIBUTES HAVE BEEN DELETED:-               00094264
*      C 120600-120900,700300-700540.                         MAC       00094564
*      D 059100-059400,177300,189300-189600,222900-224400,    MAC       00094864
*        419700,517200.                                       MAC       00095164
* 5.1  A 191400.                                              MAC  H344 00095464
*      C 138300-138400,369600,558600.                         MAC  H344 00095764
* 5.1  A 344100.                                              MAC 24639 00096064
* 5.0  C 681300,683700-684000.                                MAC  H254 00096364
* 5.0  C 237600-238800,240000-240600,247500-248100,           CRS  H236 00096664
*        255600-255900,256800-257610.                         CRS  H236 00096964
*      D 242400-244500.                                       CRS  H236 00097264
* 5.0  C 230700.                                              CRS 21784 00097564
*     680200-680300                    FLAGGED AS 17.I1            H146 00100017
*     493800-496500                    FLAGGED AS 18351           19710 00110017
         SPACE 3                                                        00139920
*              FUNCTION / OPERATION - THIS MODULE CONSISTS OF THE       00149920
*        FOLLOWING ROUTINES.                                            00180013
         SPACE                                                          00210013
*              CGENSC. THIS IS THE MAIN CONTROLLING ROUTINE OF THE      00240013
*                      PHASE. CONTROL IS PASSED TO IT FROM 'ECHSKP',    00270013
*                      THE INITIAL HOUSEKEEPING ROUTINE IN MODULE       00300013
*                      IEMEK. THE ROUTINE 'CGENSC' FIRST INITIALISES    00330013
*                      VARIOUS TABLES AND POINTERS, THEN HANDLES THE    00360013
*                      SCANNING OF THE TEXT CHAINS OF PROCEDURE AND     00390013
*                      DECLARE STATEMENTS, CALLING ROUTINE 'CDCLSC'     00420013
*                      (MODULE IEMEL) TO PROCESS EACH DECLARE STATEMENT 00450013
*                      ENCOUNTERED. THEN AFTER SOME HOUSEKEEPING, THE   00480013
*                      PHASE IS BROUGHT TO AN END BY CALLING THE        00510013
*                      CONTROL PHASE ROUTINE 'RLSCTL'.                  00540013
         SPACE                                                          00570013
*              SECOP.  THIS ROUTINE IS CALLED BY ROUTINE 'PSPROC' IN    00600013
*                      MODULE IEMEL, TO MAKE A COPY OF A SECOND FILE    00630013
*                      STATEMENT, AND IN SOME CASES THE ASSOCIATED      00660013
*                      SECOND FILE DICTIONARY ENTRY AS WELL.            00690013
         SPACE                                                          00720013
*              CDICEN. THIS ROUTINE IS CALLED TO MAKE ANY DICTIONARY    00750013
*                      ENTRY FOR A VARIABLE. IT EXAMINES THE            00780013
*                      INFORMATION SET UP IN THE ATTRIBUTE COLLECTION   00810013
*                      AREA AND MAKES THE APPROPRIATE DICTIONARY ENTRY. 00840013
         SPACE                                                          00870013
*              CDFLT.  THIS ROUTINE IS CALLED TO APPLY DEFAULT          00900013
*                      ATTRIBUTES TO AN IDENTIFIER. IT TELLS WHICH      00930013
*                      ATTRIBUTES HAVE ALREADY BEEN APPLIED BY TESTING  00960013
*                      THE ATTRIBUTE COLLECTION AREA. IT THEN APPLIES   00990013
*                      DEFAULT ATTRIBUTES BY SETTING THE APPROPRIATE    01020013
*                      BITS IN ATTRIBUTE COLLECTION AREA.               01050013
         SPACE                                                          01080013
*              IMPATT. THIS ROUTINE APPLIES IMPLICIT ATTRIBUTES IN THE  01110013
*                      SAME WAY THAT 'CDFLT' APPLIES DEFAULT ATTRIBUTES 01140013
         SPACE                                                          01170013
*              CDIMAT. THIS IS ANOTHER NAME FOR 'IMPATT'.               01200013
         SPACE                                                          01230013
*              CDFATT. THIS ROUTINE APPLIES FACTORED ATTRIBUTES TO AN   01260013
*                      IDENTIFIER, BY SCANNING THE FACTORED ATTRIBUTE   01290013
*                      TABLE. (FOR DESCRIPTION OF THIS TABLE, SEE       01320013
*                      COMMENTS AT START OF MODULE IEMEL).              01350013
         SPACE                                                          01380013
*              MVTXT.  THIS ROUTINE IS CALLED BY ROUTINE 'SECOP' TO     01410013
*                      MOVE A SPECIFIED AMOUNT OF TEXT.                 01440013
         SPACE                                                          01470013
*              CHASH.  THIS ROUTINE IS CALLED BY ROUTINE 'BCDPR' IN     01500013
*                      MODULE IEMEL TO HASH THE BCD OF AN IDENTIFIER.   01530013
*                      IT USES THE HASH TABLE, WHICH IS DESCRIBED IN    01560013
*                      THE COMMENTS IN MODULE IEMEL.                    01590013
         SPACE                                                          01620013
*              ERROR.  THIS ROUTINE SETS UP THE PARAMETERS FOR AND      01650013
*                      HANDLES ALL CALLS TO THE CONTROL PHASE ERROR     01680013
*                      MESSAGE ROUTINE, 'ZUERR'. (NOTE THAT IT HAS AN   01710013
*                      UNUSUAL CALLING SEQUENCE).                       01740013
         SPACE 3                                                        01770013
*              ENTRY POINTS - IN TRANSFER VECTOR,                       01800013
         SPACE                                                          01830013
*              1. BRANCH TO 'CDICEN'.                                   01860013
*              2. BRANCH TO 'CDFATT'.                                   01890013
*              3. BRANCH TO 'IMPATT'.                                   01920013
*              4. BRANCH TO 'CDFLT'.                                    01950013
*              5. BRANCH TO 'CGENSC'.                                   01980013
*              6. BRANCH TO 'ERROR'.                                    02010013
*              7. BRANCH TO 'SECOP'.                                    02040013
*              8. BRANCH TO 'SECOP2' (SECONDARY ENTRY POINT TO SECOP).  02070013
*              9. BRANCH TO 'CHASH'.                                    02100013
         SPACE 3                                                        02130013
*              INPUT - THE ATTRIBUTE COLLECTION AREA.                   02160013
         SPACE 3                                                        02190013
*              OUTPUT - THE ATTRIBUTE COLLECTION AREA.                  02220013
         SPACE 3                                                        02250013
*              EXTERNAL ROUTINES -                                      02280013
         SPACE                                                          02310013
*              IN MODULE IEMEK,                                         02340013
*                   CDATPR, THE ATTRIBUTE PROCESSING ROUTINE.           02370013
         SPACE                                                          02400013
*              IN MODULE IEMEL,                                         02430013
*                   CDCLSC, THE ROUTINE THAT PROCESSES DCL STATEMENTS.  02460013
*                   UNWANT, THE ROUTINE THAT UNWANTS TEXT BLOCKS.       02490013
         SPACE                                                          02520013
*              IN CONTROL PHASE,                                        02550013
*                   ZUGC,   GET SCRATCH CORE.                           02580013
*                   ZURC,   RELEASE SCRATCH CORE.                       02610013
*                   ZLOADW, LOADS ANOTHER MODULE                        02640013
*                   ZDICRF, MAKES DICTIONARY ENTRY, RETURNING ITS REF.  02670013
*                   ZUERR,  MAKES ERROR MESSAGE DICTIONARY ENTRY.       02700013
*                   ZDRFAB, CONVERTS DICT.REF. TO ADDRESS.              02730013
*                   RLSCTL, RELEASE CONTROL.                            02760013
*                   ZTXTRF, CONVERTS ADDRESS TO TEXT REF.               02790013
*                   ZTXTAB, CONVERTS TEXT REF. TO ADDRESS.              02820013
*                   ZALTER, ALTERS STATUS OF A TEXT BLOCK.              02850013
*                   ZDABRF, CONVERTS ADDRESS TO DICT. REF.              02880013
         SPACE 3                                                        02910013
*              EXITS - NORMAL - BRANCHES TO EXTERNAL ROUTINES (LISTED   02940013
*        ABOVE).                                                        02970013
         SPACE 3                                                        03000013
*              EXITS - ERROR - NONE.                                    03030013
         SPACE 3                                                        03060013
*              TABLES / WORK AREAS.                                     03090013
         SPACE                                                          03120013
*              1. THE BUILTIN FUNCTION TABLE.                           03150013
*                 THIS IS A SET OF FOUR TABLES. TWO OF THE TABLES       03180013
*                 CONSIST OF THE BCD'S OF EACH OF BUILTIN AND GENERIC   03210013
*                 BUILTIN FUNCTIONS RESPECTIVELY, EACH BCD BEING        03240013
*                 FOLLOWED BY A TWO BYTE CODE. THE ENTRIES IN THE       03270013
*                 TABLES ARE ARRANGED IN ORDER OF INCREASING BCD        03300013
*                 LENGTH. THE OTHER TWO TABLES CONSIST OF HALFWORD      03330013
*                 OFFSETS DOWN THE 'BCD' TABLES TO THE STARTING POINT   03360013
*                 FOR BCD'S OF EACH PARTICULAR LENGTH.                  03390013
         SPACE                                                          03420013
*              2. ALSO THE FOLLOWING WORK AREAS, WHICH ARE ALL          03450013
*                 DESCRIBED IN THE COMMENTS FOR MODULE IEMEL.           03480013
*                 THE ATTRIBUTE COLLECTION AREA.                        03510013
*                 CSTCK3.                                               03540013
*                 THE HASH TABLE.                                       03570013
*                 THE FACTORED ATTRIBUTE TABLE.                         03600013
         SPACE 3                                                        03630013
*              ATTRIBUTES - NOT RE-USABLE.                              03660013
         SPACE 3                                                        03690013
*              NOTES - CHARACTER CODE DEPENDENCY.                       03720013
         SPACE                                                          03750013
*              THE OPERATION OF THIS MODULE DEPENDS ON AN INTERNAL      03780013
*        REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS          03810013
*        EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING HAS    03840013
*        BEEN ARRANGED SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS,   03870013
*        BY RE-ASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW    03900013
*        DEFINITIONS.                                                   03930013
         SPACE 4                                                        03960013
IEMEM    START 0                                                        03990013
         USING *,GREMB                                                  04020013
         EJECT                                                          04050013
*              ATTRIBUTE COLLECTION AREA                                04080013
         SPACE 4                                                        04110013
*        ATTRIBUTE COLLECTION AREA IS POINTED TO BY GRATCA.             04140013
         SPACE 2                                                        04170013
FLAGS3   EQU   0                       OFFSET OF THIRD CFLAG BYTE       04200013
         SPACE                                                          04230013
CFLA17   EQU   X'80'                   FLAG MEANING THAT AN ATTRIBUTE   04260013
*                                    HAS BEEN ENCOUNTERED INSIDE ENTRY. 04290013
CFLA18   EQU   X'40'                   COMPILATION MUST TERMINATE AT    04320013
*                                    END OF PHASE.                      04350013
CFLA19   EQU   X'20'                   TEMPORARY SCAN OF HASH CHAIN IS  04380013
*                                    BEING PERFORMED.                   04410013
CFLA20   EQU   X'10'                   A NON-MAJOR STRUCTURE MEMBER     04440013
*                                    DESCRIPTION HAS BEEN ENCOUNTERED   04470013
*                                    INSIDE AN 'ENTRY' ATTRIBUTE.       04500013
CFLA21   EQU   X'08'                   THE SECTION OF ROUTINE 'PSPROC'  04530013
*                                    THAT PROCESSES THE LAST MEMBER OF  04560013
*                                    GENERIC LISTS IS INHIBITED.        04590013
NFLA21   EQU   X'FF'-CFLA21            ANDING VALUE                     04620013
CFLA22   EQU   X'04'                   THE CURRENT INITIAL ATTRIBUTE IS 04650013
*                                    INAPPLICABLE TO SCALARS.           04680013
CFLA23   EQU   X'02'                   THE 'AREA' ATTRIBUTE HAS BEEN    04686015
*                                    APPLIED.                           04692015
CFLA24   EQU   X'01'                   THE 'EVENT' ATTRIBUTE HAS BEEN   04698015
*                                    APPLIED.                           04704015
         SPACE 2                                                        04704720
FLAGS4   EQU   FLAGS3+1                OFFSET OF 4TH CFLAG BYTE.  33884 04705420
         SPACE                                                          04706120
CFLA25   EQU   X'80'                   FLAG SET WHEN BLOCK BNDRY. 33884 04706820
*                                    IS CROSSED AFTER PARM. LIST  33884 04707520
*                                    OF AN ENTRY NAME WHICH IS    33884 04708220
*                                    NOT IN A GENERIC LIST.       33884 04708920
         SPACE 2                                                        04710013
DCLATT   EQU   FLAGS3+2                 OFFSET OF DECLARED ATTRIBUTES   04740013
*                                    REGION                             04770013
*              THE DECLARED ATTRIBUTES REGION (FIRST BYTE)              04800013
         SPACE 2                                                        04830013
DATA     EQU   X'80'                   DATA                             04860013
LABEL    EQU   X'40'                   LABEL                            04890013
NTRY     EQU   X'20'                   ENTRY                            04920013
TASKID   EQU   X'10'                   TASK IDENTIFIER                  04950013
FILE     EQU   X'08'                   FILE                             04980013
GENRIC   EQU   X'04'                   GENERIC                          05010013
BILTIN   EQU   X'02'                   BUILTIN                          05040013
STRUC    EQU   X'01'                   STRUCTURE                        05070013
GENBLT   EQU   GENRIC+BILTIN           PROG. GENERIC AND BUILTIN-IN     05100013
*                                    FUNCTION.                          05130013
         SPACE 2                                                        05160013
*              THE DECLARED ATTRIBUTES REGION (SECOND BYTE)             05190013
         SPACE 2                                                        05220013
CADSTR   EQU   X'80'                   CODED ARITHMETIC DATA OR STRING  05250013
STRING   EQU   X'7F'                   STRING                           05280013
RSMBIT   EQU   X'40'                   RADIX, SCALE, MODE OR BIT        05310013
BADGEN   EQU   X'08'                   CURRENT MEMBER OF GENERIC LIST   05340013
*                                    IS ILLEGAL.                        05370013
PCKD     EQU   X'04'                   PACKED/ALIGNED ATTRIBUTE HAS     05400013
NPCKD    EQU   X'FF'-PCKD            BEEN DECLARED.                     05430013
DIFRTV   EQU   X'02'                   FLAG MEANING THAT ENTRY POINT    05460013
*                                    HAS HAD A NEW ENTRY TYPE 2         05490013
*                                    CONSTRUCTED.                       05520013
INTERN   EQU   X'01'                   INTERNAL ATT. HAS BEEN SEEN.     05550013
         SPACE 4                                                        05580013
TYPBYT   EQU   DCLATT+2                OFFSET OF TYPE BYTES             05610013
         SPACE 4                                                        05640013
*              THE SEVEN TYPE BYTES                                     05670013
         SPACE 2                                                        05700013
*              THE 'ENTRY' BYTE                                         05730013
         SPACE                                                          05760013
ENTRY    EQU   DCLATT+2                OFFSET FROM HEAD OF AT.COL.AREA  05790013
         SPACE                                                          05820013
IRREDC   EQU   X'80'                   IRREDUCIBLE                      05850015
RDCBLE   EQU   X'40'                   REDUCIBLE                        05880015
SCNDY    EQU   X'08'                   SECONDARY                        05970013
RCURSV   EQU   X'04'                   RECURSIVE                        06000013
DATATT   EQU   X'02'                   HAS DATA ATTRIBUTES              06030013
         SPACE 2                                                        06060013
*              THE 'OTHER1' BYTE                                        06090013
         SPACE                                                          06120013
OTHER1   EQU   ENTRY+1                 OFFSET FROM HEAD OF AT.COL.AREA  06150013
         SPACE                                                          06180013
SYMBOL   EQU   X'80'                   SYMBOL / REQUIRES LOAD CONSTANT  06210013
DFNDN    EQU   X'40'                   DEFINED ON                       06240013
CHECK    EQU   X'20'                   MENTIONED IN A CHECK LIST        06270013
SAVED    EQU   X'10'                   SAVED                            06300013
LMSTRC   EQU   X'08'                   LAST MEMBER OF STRUCTURE         06330013
ADJDIM   EQU   X'04'                   ADJUSTABLE DIMENSIONS            06360013
ASTDIM   EQU   X'02'                   ASTERISK DIMENSIONS              06390013
ASTSTL   EQU   X'01'                   ASTERISK STRING LENGTH           06420013
         SPACE 2                                                        06450013
*              THE 'VARIABLE' BYTE                                      06480013
VARBLE   EQU   OTHER1+1                OFFSET FROM HEAD OF AT.COL.AREA  06510013
         SPACE                                                          06540013
SECASL   EQU   X'80'                   SECOND ADDRESS SLOT              06570013
DIMENS   EQU   X'40'                   DIMENSIONED                      06600013
MEMSTR   EQU   X'20'                   MEMBER OF A STRUCTURE            06630013
NOTSTR   EQU   X'DF'                   NOT STRUCTURE MEMBER             06660013
VALPOS   EQU   X'10'                   VALUE LIST FOR LABEL VARIABLES   06690013
*                                    OR POS FOR DEFINED ITEMS           06720013
INVLIK   EQU   X'08'                   LIKE IF A STRUCTURE AND INITIAL  06750013
*                                      VALUE OTHERWISE                  06780013
CODBYT   EQU   X'04'                   CODE BYTES (OTHER5 AND OTHER6)   06810013
DEFND    EQU   X'02'                   DEFINED                          06840013
         SPACE 2                                                        06870013
*              THE 'OTHER2' BYTE                                        06900013
OTHER2   EQU   VARBLE+1                OFFSET FROM HEAD OF AT.COL.AREA  06930013
         SPACE                                                          06960013
DYNDEF   EQU   X'80'                   DYNAMICALLY DEFINED              06990013
DFISUB   EQU   X'40'                   DEFINED WITH ISUB                07020013
ABNORM   EQU   X'20'                   ABNORMAL / NORMAL                07050013
NORMAB   EQU   X'DF'                   NORMAL                           07080013
SCNDRY   EQU   X'10'                   SECONDARY                        07110013
FMPRAM   EQU   X'08'                   FORMAL PARAMETER                 07140013
EXTINT   EQU   X'04'                   EXTERNAL / INTERNAL              07170013
INTEXT   EQU   X'FB'                   INTERNAL                         07200013
CNTRLD   EQU   X'03'                   CONTROLLED                       07230013
STATIC   EQU   X'01'                   STATIC                           07260013
AUTOMC   EQU   X'00'                   AUTOMATIC                        07290013
NSTAT    EQU   X'FD'                   STATIC MASK FOR ANDING           07320013
NAUTO    EQU   X'FC'                   AUTOMATIC MASK FOR ANDING        07350013
         SPACE 2                                                        07380013
*              THE 'OTHER3' BYTE                                        07410013
         SPACE                                                          07440013
OTHER3   EQU   OTHER2+1                OFFSET FROM HEAD OF AT.COL.AREA  07470013
         SPACE                                                          07500013
DVREQ    EQU   X'80'                   DOPE VECTOR REQUIRED             07530013
DEDREQ   EQU   X'40'                   DED REQUIRED                     07560013
NOSTOR   EQU   X'20'                   NO STORAGE REQUIRED FOR THE ITEM 07590013
ARISTO   EQU   X'10'                   ARISTOCRATIC                     07620013
CHAMEL   EQU   X'08'                   CHAMELEON                        07650013
NEGVO    EQU   X'04'                   NEGATIVE VIRTUAL ORIGIN          07680013
GVLRUB   EQU   X'02'                   GOOD VALUE / RUBBISH             07710013
GVRBSA   EQU   X'01'                   GOOD VALUE / RUBBISH (FOR        07740013
*                                    SECOND ADDRESS SLOT)               07770013
         SPACE 2                                                        07800013
*              THE 'OTHER4' BYTE                                        07830013
         SPACE                                                          07860013
OTHER4   EQU   OTHER3+1                OFFSET FROM HEAD OF AT.COL.AREA  07890013
PAMBIT   EQU   X'80'                   POSSIBLY AMBIGUOUS BIT           07920013
BNDCH    EQU   X'40'                   CHANGE OF BOUNDARY IN A STORAGE  07950013
*                                    CLASS CHAIN                        07980013
TEMTY2   EQU   X'20'                   TEMPORARY TYPE 2                 08010013
DFNDST   EQU   X'10'                   DEFINED STRUCTURE MEMBER (NOT    08040013
*                                    SET BY DCL PASS TWO).              08070013
ALGPAK   EQU   X'08'                   ALIGNED / PACKED                 08100013
PAKALG   EQU   X'F7'                   PACKED                           08130013
MAJSTR   EQU   X'04'                   MAJOR STRUCTURE                  08160013
         SPACE 2                                                        08190013
*              THE 'DATA' BYTE                                          08220013
         SPACE                                                          08250013
DATABT   EQU   OTHER4+1                OFFSET FROM HEAD OF AT.COL.AREA  08280013
         SPACE                                                          08310013
CANSTR   EQU   X'80'                   CAD OR NF / STRING               08340013
DSTRNG   EQU   X'7F'                   STRING                           08370013
         SPACE                                                          08400013
*              DEPENDING ON THE VALUE OF THE FIRST BIT, THE REMAINING   08430013
*        BITS HAVE TWO POSSIBLE INTERPRETATIONS                         08460013
         SPACE                                                          08490013
*              FOR CAD OR NF                                            08520013
         SPACE                                                          08550013
PINTER   EQU   X'C0'                   POINTER.                         08580013
STERLG   EQU   X'A0'                   STERLING                         08610013
LNGSHT   EQU   X'90'                   LONG / SHORT                     08640013
CADNF    EQU   X'88'                   CAD / NF                         08670013
BINDEC   EQU   X'84'                   BINARY / DECIMAL                 08700013
FLTFXD   EQU   X'82'                   FLOAT / FIXED                    08730013
COMPRL   EQU   X'81'                   COMPLEX / REAL                   08760013
         SPACE 2                                                        08790013
*              FOR STRINGS                                              08820013
ADJLTH   EQU   X'40'                   ADJUSTABLE LENGTH                08850013
FXMAX    EQU   X'BF'                   FIXED MAX LENGTH                 08880013
ALIGN    EQU   X'20'                   ALIGNED                          08910013
PACK     EQU   X'DF'                   PACKED                           08940013
VARYNG   EQU   X'10'                   VARYING                          08970013
NOPICT   EQU   X'08'                   NO PICTURE / PICTURE             09000013
PICT     EQU   X'F7'                   PICTURE                          09030013
BIT      EQU   X'FB'                   BIT                              09060013
CHAR     EQU   X'04'                   CHARACTER                        09090013
AREA     EQU   X'02'                   AREA.                            09120013
         SPACE 2                                                        09150013
CDFLAG   EQU   DATABT+1                OFFSET OF PRIVATE FLAGS (TO 2ND  09180013
*                                    PASS DECLARE                       09210013
         SPACE 2                                                        09240013
GENFG1   EQU   X'80'                   GENERIC FLAG 1                   09270013
GENFG2   EQU   X'40'                   GENERIC FLAG 2                   09300013
NEWBLK   EQU   X'20'                   'TEMPORARY SCAN IS IN A          09330013
*                                    DIFFERENT BLOCK FROM REAL SCAN'BIT 09360013
FPSTRC   EQU   X'10'                   FORMAL PARAMETER AND STRUCTURE   09390013
*                                    MEMBER                             09420013
NODICT   EQU   X'08'                   'DO NOT BUILD A DICT ENTRY' FLAG 09450013
PRDATA   EQU   X'04'                   'DATA ATTRIBUTE HAS BEEN APPLIED 09480013
*                                    FLAG                               09510013
PRFILE   EQU   X'02'                   'FILE ATTRIBUTE HAS BEEN APPLIED 09540013
*                                    FLAG                               09570013
PREC1    EQU   X'01'                 'PRECISION 1 HAS BEEN GIVEN'       09600013
         SPACE 4                                                        09630013
FLAGS    EQU   TYPBYT+8                OFFSET OF FLAG AREA              09660013
         SPACE 2                                                        09690013
*              FIRST FLAG BYTE                                          09720013
         SPACE                                                          09750013
CFLAG1   EQU   X'80'                   CFLAG1, I.E. THE FIRST LETTER OF 09780013
*                                    THE CURRENT IDENTIFIER IS IN THE   09810013
*                                    RANGE I - N.                       09840013
CFLAG2   EQU   X'40'                   CFLAG2, I.E. THE CURRENT         09870013
*                                    IDENTIFIER IS AN ENTRY NAME WITH   09900013
*                                    PARAMETER DESCRIPTION.             09930013
CFLAG3   EQU   X'20'                   CFLAG3, I.E. THE DICTIONARY      09960013
*                                    ENTRY TO BE CONSTRUCTED MUST HAVE  09990013
*                                    BCD APPENDED.                      10020013
CFLAG4   EQU   X'10'                   CFLAG4, I.E. THE CURRENT         10050013
*                                    IDENTIFIER IS A STRUCTURE MEMBER.  10080013
CFLAG5   EQU   X'08'                   CFLAG5, I.E. THE CURRENT         10110013
*                                    IDENTIFIER IS A MAJOR STRUCTURE.   10140013
CFLAG6   EQU   X'04'                   CFLAG6, I.E. THE CURRENT         10170013
*                                    IDENTIFIER HAS HAD A LEVEL NUMBER  10200013
*                                    APPLIED TO IT.                     10230013
CFLAG7   EQU   X'02'                   CFLAG7, I.E. THE CURRENT         10260013
*                                    IDENTIFIER HAS THE SAME BCD AS     10290013
*                                    ANOTHER IDENTIFIER IN THE SAME     10320013
*                                    BLOCK                              10350013
CFLAG8   EQU   X'01'                   CFLAG8, I.E. THE SCAN IS INSIDE  10380013
*                                    A PARENTHESISED LIST, USING CSTCK3 10410013
         SPACE 2                                                        10440013
*              SECOND FLAG BYTE                                         10470013
         SPACE                                                          10500013
CFLAG9   EQU   X'80'                   CFLAG9, I.E. THE CURRENT         10530013
*                                    IDENTIFIER IS THE LAST ONE IN THE  10560013
*                                    CURRENT DECLARE STATEMENT.         10590013
CFLA10   EQU   X'40'                   CFLAG10, I.E. A GENERIC ENTRY IS 10620013
*                                    BEING PROCESSED                    10650013
CFLA11   EQU   X'20'                   CFLAG11, I.E. THE CURRENT        10680013
*                                    BUILT-IN FUNCTION IS OF GENERIC    10710013
*                                    TYPE                               10740013
CFLA12   EQU   X'10'                   CFLAG12, I.E. THE CURRENT        10770013
*                                    ATTRIBUTE IS TO BE SKIPPED OVER,   10800013
*                                    AND NOT PROCESSED.                 10830013
CFLA13   EQU   X'08'                   CFLAG13, I.E. INHIBIT CADD1      10860013
*                                    PROCESSES.                         10890013
CFLA14   EQU   X'04'                   CFLAG14, I.E. STORE THE          10920013
*                                    ATTRIBUTE POINTER ON FINDING THE   10950013
*                                    FIRST COMMA.                       10980013
CFLA15   EQU   X'02'                   CFLAG15, I.E. ON FINDING A RIGHT 11010013
*                                    FACTOR BRACKET, REDUCE 'COUNT2' BY 11040013
*                                    ONE AND UPDATE 'CURRENT'.          11070013
CFLA16   EQU   X'01'                   CFLAG16, I.E. THE CURRENT        11100013
*                                    IDENTIFIER IS AN INTERNAL ENTRY    11130013
*                                    LABEL.                             11160013
         SPACE 2                                                        11190013
*              ONE'S COMPLEMENT OF CFLAGS                               11220013
         SPACE                                                          11250013
NFLAG1   EQU   X'7F'                   ONE'S COMP FOR CFLAG1 (FOR AND)  11280013
NFLAG2   EQU   X'BF'                   ONE'S COMP FOR CFLAG2 (FOR AND)  11310013
NFLAG3   EQU   X'DF'                   ONE'S COMP FOR CFLAG2 (FOR AND)  11340013
NFLAG4   EQU   X'EF'                   ONE'S COMP FOR CFLAG4 (FOR AND)  11370013
NFLAG5   EQU   X'F7'                   ONE'S COMP FOR CFLAG5 (FOR AND)  11400013
NFLAG6   EQU   X'FB'                   ONE'S COMP FOR CFLAG6 (FOR AND)  11430013
NFLAG7   EQU   X'FD'                   ONE'S COMP FOR CFLAG7 (FOR AND)  11460013
NFLAG8   EQU   X'FE'                   ONE'S COMP FOR CFLAG8 (FOR AND)  11490013
         SPACE 2                                                        11520013
NFLAG9   EQU   NFLAG1                                                   11550013
NFLA10   EQU   NFLAG2                                                   11580013
NFLA11   EQU   NFLAG3                                                   11610013
NFLA12   EQU   NFLAG4                                                   11640013
NFLA13   EQU   NFLAG5                                                   11670013
NFLA14   EQU   NFLAG6                                                   11700013
NFLA15   EQU   NFLAG7                                                   11730013
NFLA16   EQU   NFLAG8                                                   11760013
         SPACE 4                                                        11790013
DATINF   EQU   FLAGS+2                 OFFSET OF DATA INFORMATION       11820013
PICTAB   EQU   DATINF+4                OFFSET OF PICTURE TABLE ADDRESS  11850013
DCLNUM   EQU   PICTAB+2                OFFSET OF DECLARE NUMBER         11880013
LEVEL    EQU   DCLNUM+2                OFFSET OF LEVEL                  11910013
COUNT    EQU   LEVEL+1                 OFFSET OF COUNT                  11940013
BCDTRF   EQU   COUNT+1                 OFFSET OF TEXT REFERENCE TO THE  11970013
*                                    BCD                                12000013
LINK     EQU   BCDTRF+4                OFFSET OF LINK                   12030013
ASTFLG   EQU   LINK+4                  OFFSET OF THE              28459 12050019
*                                      'INCORRECT * DIMS.' FLAG.  28459 12070019
TESTMK   EQU   ASTFLG+2                OFFSET OF TEST MASK        28459 12090019
DIMINF   EQU   TESTMK+6                OFFSET OF DIMENSION INFORMATION  12120013
STRUCT   EQU   DIMINF+4                OFFSET OF STRUCTURE INFORMATION  12150013
POS      EQU   STRUCT+10               OFFSET OF POS                    12180013
LIKINV   EQU   POS+2                   OFFSET OF INITIAL VALUE OR LIKE  12210013
         SPACE 2                                                        12240013
OTHER5   EQU   LIKINV+4                OTHER5 CODE BYTE.                12270013
         SPACE                                                          12300013
PNTEXP   EQU   X'80'                   'POINTER VARIABLE EXPRESSION'    12330013
*                                    HAS BEEN SEEN INSIDE A POINTER     12360013
*                                    ATTRIBUTE.                         12390013
LIST     EQU   X'40'                   LIST ATTRIBUTE APPLIED.          12420013
         SPACE 2                                                        12450013
OTHER6   EQU   OTHER5+1                OTHER6 CODE BYTE.                12480013
         SPACE 2                                                        12510013
DEFINF   EQU   OTHER6+1                DEFINED INFORMATION.             12540013
LKIVOF   EQU   DEFINF+8                OFFSET OF LIKE/INITIAL INFO'     12570013
         SPACE 2                                                        12600013
*              THE VARIABLE INFORMATION REGION OF THE ATTRIBUTE         12630013
*        COLLECTION AREA HAS THE FOLLOWING ALTERNATIVE MEANING FOR A    12660013
*        FILE ATTRIBUTE                                                 12690013
         SPACE 2                                                        12720013
ENVIR    EQU   TESTMK+6                DICTIONARY REFERENCE OF          12750013
*                                    ENVIRONMENT ENTRY.                 12780013
NOATTS   EQU   ENVIR+4                 FULL WORD CONTAINING THE NUMBER  12810013
*                                    OF OTHER ATTRIBUTES THAT HAVE      12840013
*                                    BEEN APPLIED. NOTE THAT SINCE THE  12870013
*                                    ATTRIBUTE COLLECTION AREA IS HALF  12900013
*                                    WORD ALIGNED THIS ITEM WILL BE     12930013
*                                    FULL WORD ALIGNED.                 12960013
ATTENT   EQU   NOATTS+1                START OF WHAT WILL BE SKELETON   12990013
*                                    OF ENTRY FOR OTHER ATTRIBUTES.     13020013
ATTLST   EQU   NOATTS+4                START OF LIST OF OTHER ATTRIB-   13050013
*                                    -UTES APPLIED.                     13080013
         SPACE 4                                                        13110013
*              THE REMAINING REGION IS COMMON TO BOTH FILES AND DATA    13140013
COUNT1   EQU   LKIVOF+2                OFFSET OF COUNT1                 13170013
COUNT2   EQU   COUNT1+4                OFFSET OF COUNT2                 13200013
COUNT3   EQU   COUNT2+4                OFFSET OF COUNT3                 13230013
CADD1    EQU   COUNT3+4                OFFSET OF CADD1                  13260013
CADD2    EQU   CADD1+4                 OFFSET OF CADD2                  13290013
CADD3    EQU   CADD2+4                 OFFSET OF CADD3                  13320013
         SPACE                                                          13350013
*              END OF ATT. COL. AREA                                    13380013
         EJECT                                                          13410013
*              THE SCRATCH CORE WORKSPACE                               13440013
         SPACE 2                                                        13470013
*              THIS WORKSPACE FOLLOWS IMMEDIATELY AFTER THE ATT.COLL.   13500013
*        AREA                                                           13530013
         SPACE 4                                                        13560013
CASPAC   EQU   CADD3+8                 WORKSPACE FOR ROUTINE 'CHASH'    13590013
         SPACE                                                          13620013
REGST    EQU   CASPAC+32               REGISTER SAVE AREA FOR ROUTINE   13650013
*                                   'CDCLSC'.                           13680013
         SPACE                                                          13710013
STM      EQU   REGST+64                REGISTER SAVE AREA FOR ROUTINES  13740013
*                                   'CDICEN', AND 'CDFLT'.              13770013
         SPACE                                                          13800013
SCR1     EQU   STM+76                  TEXT REFERENCE OF BCD       H344 13810019
*                                    LENGTH BYTE.                  H344 13820019
BLDARA   EQU   SCR1+4                  DICTIONARY ENTRY BUILD AREA H344 13830019
*                                    (300 BYTES OF SCRATCH REMAIN) H344 13840019
         EJECT                                                          13860013
*              DEFINITION OF SYMBOLIC LABELS                            13890013
         SPACE 4                                                        13920013
*              SYMBOLIC LABELS ARE DEFINED IN THE FOLLOWING GROUPS      13950013
         SPACE 2                                                        13980013
*                  1. SYMBOLIC LABELS FOR INTERNAL CODE                 14010013
         SPACE                                                          14040013
*                  2. BRANCH MNEMONICS                                  14070013
         SPACE                                                          14100013
*                  3. SYMBOLIC LABELS FOR COMPILER CONTROL ROUTINES     14130013
         SPACE                                                          14160013
*                  4. SYMBOLIC LABELS FOR COMMUNICATIONS REGION         14190013
         SPACE                                                          14220013
*                  5. SYMBOLIC LABELS FOR COMMUNICATIONS REGION (DICT.  14250013
*                     SECTION).                                         14280013
         SPACE                                                          14310013
*                  6. SYMBOLIC LABELS FOR INITIAL CODE BYTES OF DICT.   14340013
*                     ENTRIES                                           14370013
         SPACE                                                          14400013
*                  7. SYMBOLIC LABELS FOR DCL PASS II ROUTINES CALLED   14430013
*                     BY THIS CONTROL SECTION                           14460013
         SPACE                                                          14490013
*                  8. MISCELLANEOUS SYMBOLIC LABELS FOR THIS CONTROL    14520013
*                     SECTION                                           14550013
         EJECT                                                          14580013
*              SYMBOLIC LABELS FOR INTERNAL CODE                        14610013
         SPACE 4                                                        14640013
CDXI     EQU   X'19'                   LETTER I                         14670013
CDXN     EQU   X'25'                   LETTER N                         14700013
COMMA    EQU   X'41'                   COMMA                            14730013
LBRCKT   EQU   X'43'                   LEFT BRACKET                     14760013
LBRKT    EQU   LBRCKT                                                   14790013
RBRCKT   EQU   X'45'                   RIGHT BRACKET                    14820013
RBRKT    EQU   RBRCKT                                                   14850013
LFBRKT   EQU   X'51'                   LEFT FACTOR BRACKET              14880013
RFBRKT   EQU   X'71'                   RIGHT FACTOR BRACKET             14910013
ALCATE   EQU   X'81'                   ALLOCATE STATEMENT               14940013
INTLAB   EQU   X'AB'                   INITIAL LABEL                    14970013
DCLARE   EQU   X'AD'                   DECLARE STATEMENT                15000013
ATTMKR   EQU   X'C8'                   SECOND LEVEL MARKER              15030013
ETB      EQU   X'ED'                   END OF TEXT BLOCK                15060013
SEMCLN   EQU   X'EF'                   SEMICOLON                        15090013
FXDCRL   EQU   X'F5'                   CONSTANT MARKER (FIXED,DEC,REAL) 15120013
FXBNRL   EQU   X'F7'                   CONSTANT MARKER (FIXED,BIN,REAL) 15150013
CDISUB   EQU   X'FE'                   ISUB MARKER                      15180013
ENDBLK   EQU   X'ED'                   END OF BLOCK.                    15210013
EOP      EQU   X'EB'                   END OF PROGRAM MARKER.           15240013
EXCLAM   EQU   X'F3'                   EXCLAMATION MARK.                15270013
QUEST    EQU   X'F1'                   QUESTION MARK.                   15300013
BQUEST   EQU   X'F7'                   BACKWARDS QUESTION MARK.         15330013
EOE      EQU   X'F5'                   END OF INITIAL DICT ENTRY MARKER 15360013
MINUS    EQU   X'73'                   MINUS SIGN                       15390013
ASTRSK   EQU   X'79'                   ASTERISK                         15420013
PLUS     EQU   X'75'                                                    15450013
NULL     EQU   X'9D'                                                    15480013
         SPACE 4                                                        15510013
*              ATTRIBUTE CODES.                                         15540013
ATINTR   EQU   X'61'                   INTERNAL                         15570013
ATEXTR   EQU   X'60'                   EXTERNAL                         15600013
ATENVR   EQU   X'8A'                   ENVIRONMENT                      15630013
ATFILE   EQU   X'10'                   FILE                             15660013
ATKEYD   EQU   X'83'                   KEYED                            15690013
         EJECT                                                          15720013
*              BRANCH MNEMONICS                                         15750013
         SPACE 4                                                        15780013
B        EQU   15                                                       15810013
BR       EQU   15                                                       15840013
         SPACE                                                          15870013
NOP      EQU   0                                                        15900013
NOPR     EQU   0                                                        15930013
         SPACE                                                          15960013
BH       EQU   2                                                        15990013
BL       EQU   4                                                        16020013
BE       EQU   8                                                        16050013
BLE      EQU   12                                                       16080013
         SPACE                                                          16110013
BNH      EQU   13                                                       16140013
BNL      EQU   11                                                       16170013
BNE      EQU   7                                                        16200013
         SPACE                                                          16230013
BO       EQU   1                                                        16260013
BZ       EQU   8                                                        16290013
BM       EQU   4                                                        16320013
         SPACE                                                          16350013
BNO      EQU   14                                                       16380013
BNZ      EQU   7                                                        16410013
BNM      EQU   11                                                       16440013
         SPACE                                                          16470013
BP       EQU   2                                                        16500013
         EJECT                                                          16530013
*              SYMBOLIC LABELS FOR COMPILER CONTROL ROUTINES            16560013
         SPACE 4                                                        16590013
ZUGC     EQU   X'10'                   GET CORE                         16620013
ZUTXTC   EQU   X'14'                                                    16650013
ZURC     EQU   X'18'                   RELEASE CORE                     16680013
ZABORT   EQU   X'20'                   ABORT                            16710013
ZLOADW   EQU   X'24'                   LOAD AND WAIT                    16740013
ZDICAB   EQU   X'28'                   MAKE DICT. ENTRY, RETURN ABS.    16770013
ZABOF    EQU   ZDICAB                                                   16800013
ZDICRF   EQU   X'2C'                   MAKE DICT. ENTRY, RETURN REF.    16830013
ZUERR    EQU   X'30'                   MAKE DICT. ENTRY FOR ERROR MESS. 16860013
ZDRFAB   EQU   X'34'                   DICT.REF. TO ABSOLUTE            16890013
REQEST   EQU   X'40'                   PHASE REQUEST                    16920013
RLSCTL   EQU   X'48'                   RELEASE CONTROL                  16950013
ZTXTRF   EQU   X'50'                   ABSOLUTE TO TEXT.REF.            16980013
ZTXTAB   EQU   X'54'                   TEXT.REF. TO ABSOLUTE            17010013
ZALTER   EQU   X'5C'                   ALTER TEXT BLOCK STATUS          17040013
ZDABRF   EQU   X'60'                   ABSOLUTE TO DICT.REF.            17070013
         EJECT                                                          17100013
*              SYMBOLIC LABELS FOR COMMUNICATIONS REGION                17130013
         SPACE 4                                                        17160013
MYNAME   EQU   X'70'                   PHASE NAME                       17190013
PAR1     EQU   X'80'                   PARAMETERS PASSED TO COMPILER    17220013
PAR2     EQU   PAR1+4                CONTROL                            17250013
PAR3     EQU   PAR2+4                                                   17280013
PAR4     EQU   PAR3+4                                                   17310013
PAR5     EQU   PAR4+4                                                   17340013
PAR6     EQU   PAR5+4                                                   17370013
PAR7     EQU   PAR6+4                                                   17400013
PAR8     EQU   PAR7+4                                                   17430013
ZSTAT    EQU   X'7C'                   STATEMENT NUMBER                 17460013
STEXOF   EQU   X'100'                  START OF TEXT                    17490013
ZLOCK    EQU   X'112'                  LOCK SLOT.                       17520013
ZNXTLC   EQU   X'114'                                                   17550013
ZBLSIZ   EQU   X'108'                                                   17580013
         EJECT                                                          17610013
*              SYMBOLIC LABELS FOR COMMUNICATIONS REGION (DICT.SECTION) 17640013
         SPACE 4                                                        17670013
ZCOMM    EQU   304                                                      17700013
ZFLAG1   EQU   ZCOMM+16                FLAG BYTE.                       17760013
ZSTRFL   EQU   X'02'                   'STRUCTURE' FLAG IN 'ZFLAG1'BYTE 17790013
ZFLAG2   EQU   ZCOMM+17                FLAG BYTE.                       17820013
ZINTST   EQU   X'40'                   STATIC INITIAL VALUES.           17850013
ZFLAG3   EQU   ZCOMM+18                FLAG BYTE.                       17880013
ZINTAC   EQU   X'01'                   AUTO / CTL INITIAL VALUES.       17910013
ZFLAG4   EQU   ZCOMM+19                FLAG BYTE.                       17940013
FILEFL   EQU   X'20'                   FILES ARE PRESENT.               17970013
HASHHD   EQU   ZCOMM+28                POINTER TO HASH TABLE            18000013
ZFATTS   EQU   ZCOMM+36                POINTER TO FACTORED ATT. TABLE   18030013
ZDEFCH   EQU   ZCOMM+74                HEAD OF CHAIN OF DEFINED ITEMS   18060013
ZLIKCH   EQU   ZCOMM+82                HEAD OF CHAIN OF LIKE ITEMS      18090013
ZPOLCH   EQU   ZCOMM+84                HEAD OF CHAIN OF POOL ITEMS      18120013
DFNCHN   EQU   ZCOMM+74                DEFINED CHAIN                    18150013
         EJECT                                                          18180013
*              SYMBOLIC LABELS FOR INITIAL CODE BYTES OF DICT.ENTRIES   18210013
         SPACE 4                                                        18240013
CONST    EQU   X'88'                                                    18270013
FMPAR1   EQU   X'40'                                                    18300013
PELBL    EQU   X'01'                                                    18330013
SPBLT    EQU   X'84'                   SPECIAL BUILTIN.                 18360013
PGNRC    EQU   X'02'                   PROGRAMMER GENERIC               18390013
STRCTR   EQU   X'0E'                   'STRUCTURE'                      18420013
FLPRAM   EQU   X'89'                   FILE PARAMETER                   18450013
E4       EQU   X'03'                   ENTRY TYPE 4                     18480013
E6       EQU   X'86'                   ENTRY TYPE 6                     18510013
E5       EQU   X'83'                   ENTRY TYPE 5                     18540013
FCONST   EQU   X'08'                   FILE CONSTANT                    18570013
BLTN     EQU   X'04'                   BUILT-IN FUNCTION                18600013
LBL      EQU   X'07'                   LABEL VARIABLE                   18630013
E2       EQU   X'85'                   ENTRY TYPR 2                     18660013
E3       EQU   X'84'                   ENTRY TYPE 3                     18690013
GNRC     EQU   X'06'                   GENERIC                          18720013
TSK      EQU   X'0C'                   TASK VARIABLE.                   18730015
EVNT     EQU   X'0D'                   EVENT VARIABLE.                  18740015
         EJECT                                                          18750013
*              SYMBOLIC LABELS FOR DCL PASS II ROUTINES CALLED BY       18780013
*        CONTROL SECTION IEMEM.                                         18810013
         SPACE 4                                                        18840013
CDATPR   EQU   14                      ATTRIBUTE PROCESSOR, IEMEK.      18870013
CDCLSC   EQU   X'0A'                   DECLARE SCAN, IEMEL              18900013
UNWANT   EQU   X'6E'                   'UNWANT' ROUTINE (MODULE EL)  I1 18990016
         EJECT                                                          19020013
*              MISCELLANEOUS SYMBOLIC LABELS FOR CONTROL SECTION IEMEM  19050013
         SPACE 4                                                        19080013
USCRAM   EQU   ZDRFAB                  JOHN HOPE'S NAMES FOR COMPILER   19110013
UNTEXT   EQU   ZTXTAB                CONTROL ROUTINES.                  19140013
BLDLTH   EQU   191                     LENGTH - 1 OF DICTIONARY    H344 19150019
*                                    ENTRY BUILD AREA IN SCRATCH.  H344 19160019
CURENT   EQU   X'14'                   SLOTS POINTING AT FACTORED       19170013
MAX      EQU   X'18'                 ATTRIBUTE TABLE FROM IEMEL.        19200013
ACDT1    EQU   X'1C'                   STRUCTURE TABLE POINTER          19230013
CLEVEL   EQU   X'28'                   LEVEL                            19260013
CCOUNT   EQU   X'29'                   COUNT                            19290013
TXTREF   EQU   X'20'                   TEXT REFRRENCE SLOT              19320013
PBSTRF   EQU   X'24'                   TEXT REFRRENCE SLOT              19350013
STK3AD   EQU   X'1C'                   CSTCK3 ADDRESS                   19380013
STK3PT   EQU   X'20'                   CSTCK3 POINTER                   19410013
NOBCD    EQU   X'80'                   NO BCD REQUIRED BIT              19440013
STRMEM   EQU   X'20'                   STRUCTURE MEMBER BIT             19470013
DIMS     EQU   X'10'                   DIMENSIONED BIT                  19500013
DATITM   EQU   X'0F'                   DATA ITEM CODE                   19530013
NXSPST   EQU   X'2C'                   SLOT FOR 'NEXT SOURCE POINTER'   19560013
NEWDIC   EQU   X'30'                                                    19590013
REFST    EQU   X'32'                                                    19620013
STRCOF   EQU   X'56'                   OFFSET OF 'STRCOF' SLOT IN    I1 19680016
*                                    'EL' TRANSFER VECTOR.              19740013
*              OFFSET TO FIRST BYTE OF EXPRESSION IN FOLLOWING          19770013
*        SECOND FILE STATEMENTS.                                        19800013
INTCAL   EQU   9                       INITIAL CALL.                    19830013
ADVOF    EQU   20                      ARRAY BOUNDS.                    19860013
SDVOF    EQU   15                      STRING LENGTH.                   19890013
ADFOF    EQU   10                      DEFINED.                         19920013
IVOF     EQU   14                      INITIAL VALUE.                   19950013
STTYP    EQU   4                       OFFSET OF STATEMENT TYPE         19980013
CDOF     EQU   8                       OFFSET OF SECOND CODE BYTE IN    20010013
*                                    THE TWO FOR ADV, SDV, ADF.         20040013
ITEMRF   EQU   12                      OFFSET IN SECOND FILE STATEMENT  20070013
*                                    OF DICTIONARY REFERENCE OF ITEM    20100013
*                                    WHOSE SDV, ADV, OR ADF STATEMENT   20130013
*                                    THIS IS.                           20160013
SLTREF   EQU   7                       OFFSET IN SECOND FILE DICTIONARY 20190013
*                                    ENTRY OF REF. TO THREE BYTE SLOT   20220013
INTTYP   EQU   7                       OFFSET OF TYPE BYTE IN INITIAL   20250013
*                                    2ND. FILE STAT.                    20280013
INTREF   EQU   11                      OFFSET OF ITEM REF SLOT IN       20310013
*                                    INITIAL 2ND. FILE STAT.            20340013
CALL     EQU   X'A1'                   CALL STATEMENT                   20370013
ADV      EQU   X'02'                   ADV  STATEMENT                   20400013
SDV      EQU   X'04'                   SDV  STATEMENT                   20430013
         SPACE 4                                                        20460013
         DC    C'EM'                   PHASE IDENTIFICATION             20490013
         SPACE 4                                                        20520013
*              TRANSFER INSTRUCTIONS TO ROUTINES IN THIS BLOCK          20550013
         SPACE 1                                                        20580013
         SPACE 4                                                        20610013
*                                      NAME OF ROUTINE                  20640013
         SPACE 2                                                        20670013
         BC    B,CDICEN                DICTIONARY ENTRY BUILD           20700013
         BC    B,CDFATT                FACTORED ATTRIBUTES              20730013
         BC    B,IMPATT                IMPLICIT ATTRIBUTES              20760013
         BC    B,CDFLT                 DEFAULT ATTRIBUTES               20790013
         BC    B,CGENSC                GENERAL SCAN                     20820013
         SPACE 4                                                        20850013
DEE3X2   DC    H'0'                    STORAGE FOR DICT.REF.OF E TYPE 3 20880013
         BC    B,ERROR                 ERROR ROUTINE.                   20910013
         BC    B,SECOP                 COPY SECOND FILE IF NECESSARY    20940013
         BC    B,SECOP2                COPY SECOND FILE                 20970013
         BC    B,CHASH                 HASHING ROUTINE.                 21000013
         BC    B,INTPRC                'INITIAL' POST-PROCESSING        21030013
*                                    ROUTINE.                           21060013
AREANO   DC    F'0'                    SLOT CONTAINING THE NUMBER OF    21090013
*                                    DATA DESCRIPTIONS GIVEN FOR THE    21120013
*                                    CURRENT AREA VARIABLE.             21150013
         SPACE                                                          21180013
CD0      DC    F'0'                                                     21210013
CD4      DC    F'4'                                                     21240013
CD7      DC    F'7'                                                     21270013
         SPACE                                                          21300013
PBLK     DC    F'0'                    SLOT WHICH IS UPDATED TO CONTAIN 21330013
*                                    REF OF TEXT BLOCK CONTAINING       21360013
*                                    CURRENT PROC STATEMENT.            21390013
DCBLK1   DC    F'0'                    SLOT WHICH IS UPDATED TO CONTAIN 21420013
*                                    REF OF TEXT BLOCK CONTAINING       21450013
*                                    CURRENT DECLARE STATEMENT.         21480013
DCBLK2   DC    F'0'                    SLOT WHICH IS UPDATED TO CONTAIN 21510013
*                                    REF OF TEXT BLOCK CONTAINING THAT  21540013
*                                    PART OF A DECLARE STATEMENT        21570013
*                                    INVOLVED IN A DUMMY SCAN (IF       21600013
*                                    DIFFERENT FROM THE ABOVE BLOCK)    21630013
NXPREF   DC    F'0'                    SLOT WHICH IS UPDATED TO CONTAIN 21660013
*                                    REF OF NEXT PROC STATEMENT         21690013
NXDCL    DC    F'0'                    SLOT WHICH IS UPDATED TO CONTAIN 21720013
*                                    REF OF NEXT DCL STATEMENT.         21750013
TMPAR8   DC    F'0'                                                     21780013
         EJECT                                                          21810013
*              'GENERAL SCAN'                                           21840013
         SPACE 3                                                        21870013
*              HERE WE INITIALISE THE POINTERS TO THE FACTORED          21900013
*        ATTRIBUTE TABLE.                                               21930013
         SPACE 2                                                        21960013
*              PICK UP ADDRESS OF START OF FACTORED ATTRIBUTE TABLE     21990013
*        FROM COMMUNICATIONS REGION AND STORE THE ADDRESS IN 'MAX' AND  22020013
*        IN 'CURENT'.                                                   22050013
         SPACE                                                          22080013
CGENSC   L     GR1,ZFATTS(GRDCPT)                                       22110013
         S     GR1,CD7                                                  22140013
         ST    GR1,MAX(0,GRELB)                                         22170013
         ST    GR1,CURENT(0,GRELB)                                      22200013
         SPACE 2                                                        22230013
*              INITIALISE POINTERS TO CSTCK3.                           22260013
         SPACE 2                                                        22740013
*              HERE WE INITIALISE THE STRUCTURE TABLE                   22770013
*              IT IS A REGION OF SCRATCH CORE. AND WE NOW GET THIS FROM 22800013
*        COMPILER CONTROL                                               22830013
         SPACE                                                          22860013
         LA    GRL,2                   SPECIFY IN PAR1 THAT 2 BLOCKS OF 22890013
         ST    GRL,PAR1(0,GRDCPT)    512 BYTES ARE REQUIRED.            22920013
         L     GRL,ZUGC(0,GRCP)        BRANCH TO 'GET CORE' ROUTINE     22950013
         BALR  GRR,GRL                                                  22980013
         SPACE                                                          23010013
         L     GRCDT1,PAR1(0,GRDCPT)   POINT GRC,T1 AT THE HEAD OF THE  23040013
*                                    STRUCTURE TABLE.             21784 23070001
         ST    GRCDT1,ACDT1(0,GRELB)                                    23100013
         SPACE 2                                                        23130013
*              HERE WE INITIALISE THE POINTER TO, AND CLEAR, THE        23160013
*        ATTRIBUTE COLLECTION AREA.                                     23190013
         SPACE                                                          23220013
         LA    GRATCA,260(0,GRCDT1)                                     23250013
         MVI   0(GRATCA),0                                              23280013
         MVC   1(256,GRATCA),0(GRATCA)                                  23310013
         MVC   257(255,GRATCA),256(GRATCA)                              23340013
         SPACE                                                          23370013
         SPACE                                                          23400013
         EJECT                                                          23430013
*              THIS SECTION OF THE GENERAL SCAN PERFORMS THE SCANNING   23460013
*        OF THE TEXT CHAINS, ALWAYS ENSURING THAT THE MINIMUM NUMBER OF 23490013
*        TEXTS BLOCKS ARE BUSY.                                         23520013
         SPACE 6                                                        23550013
*              THIS SECTION OF CODE SCANS THE CHAIN OF PROCEDURE        23580013
*        STATEMENTS                                                     23610013
         SPACE 2                                                        23640013
SCAN0    MVC   PAR1(4,GRDCPT),STEXOF(GRDCPT) SET UP IN PAR1 THE REF TO  23670013
*                                    THE START OF THE TEXT              23700013
         SPACE                                                          23730013
SCAN1    DS    0H                                                  H236 23760001
         MVI   PAR1(GRDCPT),X'80'      GET NEXT PROC STMNT ADDRESS H236 23790001
         L     GRL,ZTXTAB(0,GRCP)    WITHOUT CHANGING BLOCK STATUS H236 23820001
         BALR  GRR,GRL               (NO NEED TO UNBUSY LATER)     H236 23850001
         L     GRSCAN,PAR1(0,GRDCPT)                                    23910013
         MVC   NXPREF+1(3),7(GRSCAN)   SET UP REF TO NEXT PROC STATMNT. 23940013
         MVC   CLEVEL(2,GRELB),5(GRSCAN) SET UP LEVEL AND COUNT.        23970013
         MVC   DCBLK1+1(3),10(GRSCAN)  PICK UP HEAD OF DCL CHAIN   H236 24000001
SCAN3    DS    0H                                                  H236 24030001
         CLC   DCBLK1+1(3),ENDCHN      IS IT THE END ?             H236 24060001
         BC    BNE,SCAN4               IF NOT, GO TO SCAN DECLARE CHAIN 24090013
         SPACE                                                          24120013
*              HERE WE HAVE COME TO THE END OF THE DECLARE CHAIN FOR    24150013
*        THE CURRENT BLOCK.                                             24180013
         SPACE                                                          24210013
         MVC   PAR1+1(3,GRDCPT),NXPREF+1 SET REF OF NEXT PROC STMNT.    24480013
         CLC   PAR1+1(3,GRDCPT),ENDCHN IS THIS END OF CHAIN             24510013
         BC    BNE,SCAN1                                                24540013
         SPACE                                                          24570013
*              HERE WE HAVE REACHED THE END OF THE PROC CHAIN           24600013
         BC    B,CDZ8                                                   24630013
         SPACE 6                                                        24660013
*              THIS SECTION OF CODE SCANS THE DECLARE CHAIN             24690013
         SPACE 2                                                        24720013
SCAN4    DS    0H                                                  H236 24760001
         MVC   PAR1(4,GRDCPT),DCBLK1   FIRST                       H236 24800001
         L     GRL,ZTXTAB(0,GRCP)      PICK UP ADDRESS OF DECLARE       24840013
         BALR  GRR,GRL               STATEMENT, AND MARK TEXT BLOCK     24870013
         L     GRSCAN,PAR1(0,GRDCPT) BUSY                               24900013
         MVC   NXDCL+1(3),5(GRSCAN)    SET UP REF TO NEXT DCL           24930013
         SPACE                                                          24960013
*              NOW DECIDE WHAT KIND OF STATEMENT THIS IS                24990013
         SPACE                                                          25020013
         CLI   4(GRSCAN),DCLARE        IS IT DECLARE STMNT.             25050013
         BC    BE,SCAN5                                                 25080013
         CLI   4(GRSCAN),ALCATE        IS IT ALLOCATE STMNT.            25110013
         BC    BE,SCAN6                                                 25140013
         SPACE                                                          25170013
*              IF IT IS NONE OF THESE, COMPILER ERROR.                  25200013
         SPACE                                                          25230013
         DC    H'0'                    INTERRUPT                        25260013
         SPACE 2                                                        25290013
*              HERE IT IS A DECLARE STATEMENT                           25320013
SCAN5    BAL   GRR,CDCLSC(0,GRELB)     GO TO SCAN DCL STATEMENT         25350013
         SPACE                                                          25380013
SCAN6    MVC   PAR1(4,GRDCPT),DCBLK1   MARK CURRENT 'DECLARE' BLOCK     25410013
         MVI   PAR2+3(GRDCPT),X'02'  UNWANTED                           25440013
         L     GRL,ZALTER(0,GRCP)                                       25470013
         BALR  GRR,GRL                                                  25500013
         SPACE                                                          25530013
         MVC   DCBLK1(4),NXDCL         SET UP REF OF NEXT DECLARE  H236 25550001
         BC    B,SCAN3               STATEMENT, AND TRY AGAIN.     H236 25570001
*                                                                  H236 25590001
*              HERE WE RELEASE THE SCRATCH CORE THAT CONSTITUTED THE    25620013
*        STRUCTURE TABLE                                                25650013
         SPACE                                                          25680013
CDZ8     DS    0H                                                  H236 25686001
         CLC   ZFATTS(4,GRDCPT),CD0    IF THERE IS ONE -           H236 25692001
         BC    BE,CDZ9                                             H236 25698001
         MVC   PAR1(4,GRDCPT),ZCOMM+88(GRDCPT) FIRST WE MUST FREE  H236 25704001
         MVI   PAR2+3(GRDCPT),X'01'  THE FACTORED ATTRIBUTE TABLE  H236 25710001
         L     GRL,ZALTER(0,GRCP)    SCRATCH TEXT BLOCK.           H236 25716001
         BALR  GRR,GRL                                             H236 25722001
CDZ9     DS    0H                                                  H236 25728001
*                                      THEN, FOR SUBROUTINE PCKGE. H236 25734001
*                                    AND STRUCTURE TABLE ETC.,     H236 25740001
         LA    GR1,2                 SET LAST 2 SCR ALLOCATIONS    H236 25746001
*                                    TO BE RELEASED,               H236 25752001
         ST    GR1,PAR1(0,GRDCPT)    AND SET IT UP IN PAR1.             25770013
         SPACE                                                          25800013
         L     GRL,ZURC(0,GRCP)        BRANCH TO ZURC ROUTINE           25830013
         BALR  GRR,GRL                                                  25860013
         SPACE                                                          25890013
         XC    ZLOCK(2,GRDCPT),ZLOCK(GRDCPT) CLAAR THE 'LOCK' SLOT.     25920013
         SPACE 3                                                        25950013
*              FINAL EXIT                                               25980013
         SPACE                                                          26010013
EXIT     TM    FLAGS3(GRATCA),CFLA18   IF 'TERMINATION' FLAG IS ON,     26040013
         BC    BZ,EXIT1              GO TO ZABORT.                      26070013
         L     GRL,ZABORT(0,GRCP)                                       26100013
         BCR   BR,GRL                                                   26130013
         SPACE 2                                                        26160013
EXIT1    LA    GRR,RLSLST                                               26190013
         ST    GRR,PAR1(0,GRDCPT)                                       26220013
         XR    GRR,GRR                                                  26250013
         ST    GRR,PAR2(0,GRDCPT)                                       26280013
         L     GRL,RLSCTL(0,GRCP)                                       26310013
         BCR   BR,GRL                                                   26340013
         SPACE 4                                                        26370013
RLSLST   DC    C'EKELEMZZ'                                              26400013
         EJECT                                                          26430013
*              THE ROUTINE SECOP                                        26460013
         SPACE 5                                                        26490013
*        THIS ROUTINE COPIES A SECOND FILE STATEMENT AND ITS SECOND     26520013
*        FILE DICTIONARY ENTRY IF THESE ARE ALREADY IN USE FOR ANOTHER  26550013
*        ITEM.                                                          26580013
         SPACE 2                                                        26610013
*        THE SECONDARY ENTRY POINT KNOWS THE PAIR NEED TO BE COPIED.    26640013
         SPACE 2                                                        26670013
SECOP    ST    GRR,COPYST                                               26700013
         CLI   ITEMRF(GRL),0           BRANCH IF SECOND FILE STATEMENT  26730013
         BC    BNE,SECOP3            HAS BEEN USED.                     26760013
SECOP1   TM    DCLATT+1(GRATCA),DIFRTV                                  26790013
         BC    BZ,SECOP5                                                26820013
         MVC   ITEMRF(2,GRL),DEE3X2                                     26850013
         BC    B,SECOP4                                                 26880013
SECOP5   MVC   ITEMRF(2,GRL),NEWDIC(GRELB)                              26910013
SECOP4   MVC   PAR1+2(2,GRDCPT),1(GRL) DECODE REFERENCE TO              26940013
         L     GRR,ZDRFAB(0,GRCP)    SECOND FILE DICT. ENTRY, AND       26970013
         BALR  GRR,GRR               INSERT THE REF. OF THE 'TEXT REF.' 27000013
         L     GRR,PAR1(0,GRDCPT)    SLOT IN IT.                        27030013
         MVC   SLTREF(2,GRR),REFST(GRELB)                               27060013
         L     GRR,COPYST            SLOT IN THIS ENTRY.                27090013
         BCR   B,GRR                                                    27120013
         SPACE 10                                                       27150013
*              THE ROUTINE SECOP2.                                      27180013
         SPACE                                                          27210013
*              THIS IS A SECONDARY ENTRY POINT TO SECOP. THE FUNCTION   27240013
*        IS TO COPY THE SECOND FILE STATEMENT AND ITS ASSOCIATED        27270013
*        DICTIONARY ENTRY. THE SECOND FILE STATEMENT IS MADE TO POINT   27300013
*        AT THE SECOND FILE DICTIONARY ENTRY, AND THEN CONTROL IS       27330013
*        RETURNED TO SECOP TO COMPLET THE PROCESSING.                   27360013
         SPACE                                                          27390013
SECOP2   ST    GRR,COPYST              SAVE RETURN REGISTER             27420013
         SPACE                                                          27450013
*              THIS IS THE ENTRY IF SECOP ITSELF WAS CALLED.            27480013
         SPACE                                                          27510013
*              THE NEW SCAN POINTER GR1 IS MADE TO POINT AT THE FIRST   27540013
*        BYTE OF THE EXPRESSION IN THE SECOND FILE STATEMENT.ONLY       27570013
*        ADF, SDV, ADV, AND INITIAL CALL STATEMENTS ARE EXPECTED.       27600013
         SPACE                                                          27630013
SECOP3   STM   GR1,GR3,COPYST+4                                         27660013
         SPACE                                                          27667021
         CLI   STTYP(GRL),CALL         IS IT FOR INITIAL CALL     43457 27674021
         BC    BE,LP0                  BRANCH IF SO.              43457 27681021
         MVI   TYPESW,1                SET TYPE SWITCH TO ADV OR SDV    27690013
         SPACE                                                          27720013
         LA    GR2,ADVOF(GRL)          BUMP POINTER FOR ADV             27750013
         CLI   CDOF(GRL),ADV                                            27780013
         BC    BE,SCAN                 BRANCH IF IT IS                  27810013
         SPACE                                                          27840013
         LA    GR2,SDVOF(GRL)          BUMP POINTER FOR SDV STATEMENT   27870013
         CLI   CDOF(GRL),SDV                                            27900013
         BC    BE,SCAN                 BRANCH IF IT IS                  27930013
         SPACE                                                          27934015
         MVI   TYPESW,2                SET TYPE SW TO ADF OR INIT CALL  27938015
         TM    INTTYP(GRL),X'16'       IS IT A BVEXP OR PEXP ?          27944015
         BC    BO,SCAN                 BRANCH IF SO.                    27951015
         SPACE                                                          27960013
LP0      MVI   TYPESW,2                SET TYPE SW TO ADF         43457 27990021
*                                    OR INITIAL CALL.             43457 28020021
         LA    GR2,INTCAL(GRL)                                          28050021
         CLI   STTYP(GRL),CALL         BUMP POINTER FOR INITIAL CALL    28080013
         BC    BNE,LP7                                                  28110013
         MVI   FLAGBT,X'FF'                                             28140013
         BC    B,SCAN                                                   28170013
LP7      LA    GR2,IVOF(0,GRL)         BUMP POINTER FOR ORDINARY        28200013
         CLI   INTTYP(GRL),X'06'     INITIAL.                           28230013
         BC    BE,SCAN                                                  28260013
         SPACE                                                          28290013
         LA    GR2,ADFOF(0,GRL)        BUMP POINTER FOR ADF STMNT.      28320013
         SPACE                                                          28350013
SCAN     SR    GR1,GR1                                                  28380013
LOOP     CLI   0(GR2),32                                                28410013
         BC    BH,LP1                  BRANCH IF NOT IDENTIFIER LENGTH  28440013
         IC    GR1,0(GR2)                                               28470013
         LA    GR2,1(GR2,GR1)          BUMP SCAN POINTER BY IDENTIFIER  28500013
         BC    B,LOOP                LENGTH + 1.                        28530013
         SPACE                                                          28560013
LP1      CLI   0(GR2),X'EF'                                             28590013
         BC    BH,LP3                  BRANCH IF A CONSTANT             28620013
         BC    BE,LP6                  BRANCH IF A SEMI COLON           28650013
*              MUST NOW BE AN OPERATOR                                  28680013
         CLI   0(GR2),X'5E'            IS IT AN UMBRELLA.               28710013
         BC    BNE,LP2                 BRANCH IF NOT.                   28740013
         LA    GR2,2(GR2)              BUMP GR2 BY 4 FOR UMBRELLA AND   28760015
LP5      LA    GR2,1(GR2)                                               28780015
LP2      LA    GR2,1(GR2)            1 FOR OTHER OPERATORS.             28800013
         BC    B,LOOP                                                   28830013
         SPACE                                                          28860013
LP3      CLI   0(GR2),X'FC'                                             28890013
         BC    BH,LP4                  BRANCH IF NOT CONSTANT WITH ONE  28920013
*                                    BYTE LENGTH.                       28950013
         IC    GR1,1(GR2)              BUMP GR2 BY CONSTANT LENGTH      28980013
         LA    GR2,2(GR1,GR2)        PLUS 2.                            29010013
         BC    B,LOOP                                                   29040013
         SPACE                                                          29070013
LP4      CLI   0(GR2),X'FE'            BRANCH FOR SUB                   29100013
         BC    BE,LP5                                                   29130013
         MVC   TMFWST(2),1(GR2)                                         29160013
         LH    GR1,TMFWST              PICK UP STRING LENGTH            29190013
         LA    GR2,3(GR2,GR1)          BUMP GR2 BY LENGTH PLUS THREE    29220013
         BC    B,SCAN                                                   29290015
         SPACE 5                                                        29370013
LP6      SR    GR2,GRL                 GR2 CONTAINS LENGTH - 1          29400013
         LR    GR1,GRL                 GR1 POINTS AT FIRST BYTE.        29430013
         SPACE                                                          29460013
         MVC   PAR1+2(2,GRDCPT),1(GRL)                                  29490013
         L     GRL,ZDRFAB(GRCP)                                         29520013
         BALR  GRR,GRL                      PUT THE ADDRESS AND LENGTH  29550013
         L     GRL,PAR1(GRDCPT)           OF THE SECOND FILE DICTIONARY 29580013
         XC    PAR2(2,GRDCPT),PAR2(GRDCPT) ENTRY IN PAR1 AND 2. COPY    29610013
         MVC   PAR2+2(2,GRDCPT),1(GRL) THE ENTRY.                       29640013
         L     GRL,ZDICRF(GRCP)                                         29670013
         BALR  GRR,GRL                                                  29700013
         MVC   TMPH(2),PAR1+2(GRDCPT)  SAVE THE NEW REFERENCE           29730013
         SPACE                                                          29760013
         BAL   GRR,MVTXT               BRANCH TO COPY THE SECOND FILE   29790013
*                                    STATEMENT                          29820013
         L     GRL,STATAD                                               29850013
         CLI   FLAGBT,X'00'                                             29880013
         MVI   FLAGBT,X'00'                                             29910013
         BC    BE,LP8                                                   29940013
         MVC   6(3,GRL),NEWTRF+1                                        29970013
LP8      MVC   1(2,GRL),TMPH           INSERT THE REF. OF THE NEW 2ND.  30000013
*                                    FILE DICT. ENTRY.                  30030013
         LM    GR1,GR3,COPYST+4                                         30060013
*              IF THE STATEMENT IS TYPE 1 (SDV OR ADV) THE REFERENCE    30090013
*        TO THE ITEM WHICH OWNS THE STATEMENT IS TO BE INSERTED.        30120013
         CLI   TYPESW,1                                                 30150013
         BC    BE,SECOP1               BRANCH TO INSERT REFERENCE.      30180013
         CLI   INTTYP(GRL),X'06'       IF IT IS ORDINARY INITIAL WE PUT 30210013
         BC    BNE,SECOP4            THE REF OF THE CURRENT ITEM INTO   30240013
         CLI   4(GRL),CALL                                              30270013
         BC    BE,SECOP4                                                30300013
         MVC   INTREF(2,GRL),NEWDIC(GRELB) THE 2ND. FILE STAT.          30330013
         BC    B,SECOP4                                                 30360013
         EJECT                                                          30390013
*              THE 'INITIAL' POST-PROCESSING ROUTINE, INTPRC.           30420013
         SPACE 4                                                        30450013
*              THIS IS A SECTION OF THE POST-PROCESSING ROUTINE,        30480013
*        (MODULE IEMEL). IT IS IN THIS MODULE BECAUSE THERE IS NO ROOM  30510013
*        FOR IT IN IEMEL.                                               30540013
         SPACE                                                          30570013
*              WE FIRST EXAMINE THE 'INITIAL' DICT ENTRY TO SEE IF IT   30600013
*        HAS ALREADY BEEN USED. IF IT HAS WE MAKE A COPY OF IT. WE THEN 30630013
*        SCAN THE 'INITIAL' DICT ENTRY FOR POINTERS TO 2ND FILE STMNTS. 30660013
*        FOR EACH SUCH STATEMENT WE PICK UP THE ASSOCIATED SECOND FILE  30690013
*        DICT ENTRY, AND PUT INTO IT THE DICT REF OF THE SLOT IN THE    30720013
*        'INITIAL' DICT ENTRY WHICH CONTAINS THE TEXT REF OF THE SECOND 30750013
*        FILE STATEMENT. IF THE PAIR HAVE ALREADY BEEN USED WE MAKE A   30780013
*        COPY.                                                          30810013
         SPACE 4                                                        30840013
INTPRC   DS    0H                                                       30860015
         STM   GRR,GR3,COPYST+16       SAVE REGISTERS USED              30880015
         SPACE                                                          30900013
         TM    OTHER2(GRATCA),CNTRLD   HERE WE SET FLAGS IN THE COMM    30930013
         BC    BNM,INT1A             REGION, ZINTST FOR STATIC INITIAL, 30960013
         OI    ZFLAG2(GRDCPT),ZINTST AND ZINTAC FOR AUTOMATIC OR        30990013
         BC    B,INT1B               CONTROLLED INITIAL.                31020013
INT1A    OI    ZFLAG3(GRDCPT),ZINTAC                                    31050013
         SPACE                                                          31080013
INT1B    CLI   LIKINV+3(GRATCA),X'F0'  IS THIS A REAL INITIAL           31110013
         BC    BNE,INT1                NO SO SKIP POST PROCESSING       31140013
         SPACE                                                          31170013
         LH    GR0,LIKINV(0,GRATCA) POINT GR1 AT INITIAL DICTIONARY     31200013
         STH   GR0,PAR1+2(0,GRDCPT)  ENTRY, LOCKING IN THE BLOCK.       31230013
         STH   GR0,ZLOCK(0,GRDCPT)                                      31260013
         STH   GR0,ENTREF                                               31290013
         L     GRL,ZDRFAB(0,GRCP)                                       31320013
         BALR  GRR,GRL                                                  31350013
         L     GR1,PAR1(0,GRDCPT)                                       31380013
         SPACE                                                          31410013
         TM    4(GR1),X'10'            IF THE 'INITIAL' DICT ENTRY HAS  31440013
         BC    BZ,INT1C              ALREADY BEEN USED, MAKE A NEW COPY 31470013
         NI    4(GR1),X'EF'          (SETTING COPY FLAG AS NECESSARY).  31500013
         BC    B,INT2A                                                  31530013
INT1C    OI    FLAG,COPY                                                31560013
         MVC   PAR1+2(2,GRDCPT),NEWDIC(GRELB) AND SET UP ITS DICT REF   31590013
         L     GRL,ZDRFAB(0,GRCP)    IN THE DICT ENTRY FOR THE VARIABLE 31620013
         BALR  GRR,GRL               AND IN 'ENTREF'.                   31650013
         L     GR2,PAR1(0,GRDCPT)                                       31680013
         XC    PAR2(2,GRDCPT),PAR2(GRDCPT)                              31710013
         MVC   PAR2+2(2,GRDCPT),1(GR1)                                  31740013
         ST    GR1,PAR1(0,GRDCPT)                                       31770013
         L     GRL,ZDICRF(0,GRCP)                                       31800013
         BALR  GRR,GRL                                                  31830013
         AH    GR2,LKIVOF(0,GRATCA)                                     31860013
         MVC   0(2,GR2),PAR1+2(GRDCPT)                                  31890013
         MVC   ENTREF(2),PAR1+2(GRDCPT)                                 31920013
         L     GR1,PAR4(GRDCPT)        POINT GR1 AT ENTRY JUST MADE     31980015
         SPACE                                                          32040013
INT2A    MVC   TMFWST(2),1(GR1)        SET UP IN GR2 THE OFFSET OF THE  32070013
         LH    GR2,TMFWST            END OF THE 'INITIAL' DICT ENTRY.   32100013
         LA    GR3,5(0,0)            AND INITIALISE GR3 WITH THE OFFSET 32130013
*                                    OF THE FIRST ITEM IN THE ENTRY.    32160013
         SPACE                                                          32190013
INT2     CR    GR2,GR3                 TEST WHETHER WE HAVE COME TO THE 32220013
         BC    BE,INT1               END OF THE ENTRY. IF SO, RETURN.   32250013
         BC    BL,INT2B              IF BEYOND, COMPILER ERROR.         32280013
         SPACE                                                          32310013
         LA    GRZ,0(GR3,GR1)                                           32340013
         SPACE                                                          32370013
         CLI   0(GRZ),LBRCKT           HERE WE ARE SCANNING DOWN THE    32400013
         BC    BE,INT3               INITIAL VALUE DICT ENTRY, TESTING  32430013
*                                    FOR EACH OF THE POSSIBLE ITEMS.    32460013
         CLI   0(GRZ),RBRCKT         (GR1 POINTS AT THE START OF THE    32490013
         BC    BE,INT3               ENTRY AND GR3 CONTAINS THE OFFSET  32520013
*                                    OF THE CURRENT ITEM).              32550013
         CLI   0(GRZ),COMMA                                             32580013
         BC    BE,INT3                                                  32610013
         SPACE                                                          32640013
         CLI   0(GRZ),NULL                                              32670013
         BC    BE,INT3                                                  32700013
         SPACE                                                          32730013
         CLI   0(GRZ),ASTRSK                                            32760013
         BC    BE,INT3                                                  32790013
         SPACE                                                          32820013
         CLI   0(GRZ),PLUS                                              32850013
         BC    BE,INT5                                                  32880013
         SPACE                                                          32910013
         CLI   0(GRZ),MINUS                                             32940013
         BC    BE,INT5                                                  32970013
         SPACE                                                          33000013
         CLI   0(GRZ),EXCLAM                                            33030013
         BC    BE,INT4                                                  33060013
         SPACE                                                          33090013
         CLI   0(GRZ),QUEST                                             33120013
         BC    BE,INT5                                                  33150013
         SPACE                                                          33180013
         CLI   0(GRZ),BQUEST                                            33210013
         BC    BE,INT6                                                  33240013
         SPACE                                                          33270013
         CLI   0(GRZ),EOE                                               33300013
         BC    BE,INT7                                                  33330013
         SPACE                                                          33360013
INT2B    DC    H'0'                    COMPILER ERROR.                  33390013
         SPACE                                                          33420013
INT8     LA    GR3,1(0,GR3)            THESE INSTRUCTIONS BUMP GR3      33450013
INT5     LA    GR3,3(0,GR3)          APPROPRIATELY OVER THE CURRENT     33480013
INT3     LA    GR3,1(0,GR3)          ITEM. THEN WE BRANCH BACK TO       33510013
         BC    B,INT2                PROCESS THE NEXT ITEM.             33540013
         SPACE                                                          33570013
INT4     CLI   1(GRZ),MINUS            HERE IT IS AN EXCLAMATION MARK.  33600013
         BC    BE,INT8               DEPENDING WHETHER THE NEXT BYTE IS 33630013
         BC    B,INT5                A MINUS SIGN, WE BUMP APPROPRIATE  33660013
*                                    AMOUNT.                            33690013
         SPACE                                                          33720013
INT7     LA    GRL,2(GR3,GR1)          HERE WE HAVE FOUND A MARKER      33750013
*                                    SO POINT GRL AT THE CHAIN REF SLOT 33758015
*                                    (GR1 STILL POINTS AT THE ENTRY)    33766015
         MVC   PAR1+2(2,GRDCPT),ENTREF  PUT THE ENTRY REF INTO PAR1,    33774015
         ST    GRL,PAR2(0,GRDCPT)    AND THE SLOT ADDRESS INTO PAR2.    33782015
         L     GRR,ZDABRF(0,GRCP)      GET THE REF OF THIS SLOT,        33790015
         BALR  GRR,GRR                  AND                             33798015
         MVC   SLOTRF(2),PAR1+2(GRDCPT)  STORE IT FOR CHAINING.         33806015
*                                                                       33814015
*              THE FOLLOWING COMMENTS ARE MISLEADING.  NOTE THAT THE    33822015
*        CONTINUATION ENTRY MAY WELL RESIDE IN THE CURRENT DICTIONARY   33830015
*        BLOCK, AS IT WAS SCRATCH, NOT DICT. BLOCK LIMITED, IN EH.      33838015
*                                                                       33846015
*                                      GRL IS POINTING AT THE CHAIN REF 33854015
         MVC   PAR1+2(2,GRDCPT),0(GRL) DENOTING THAT THE INITIAL DICT   33870013
         LH    GRL,PAR1+2(0,GRDCPT)  ENTRY CONTINUES IN THE NEXT DICT   33900013
         STH   GRL,ZLOCK(0,GRDCPT)   BLOCK. WE POINT GR1 AT THE         33930013
         STH   GRL,ENTREF            CONTINUATION ENTRY, LOCKING IN THE 33960013
         L     GRL,ZDRFAB(0,GRCP)    NEW BLOCK, AND SAVING THE REF OF   33990013
         BALR  GRR,GRL               THE CONTINUATION ENTRY.            34020013
         L     GR1,PAR1(0,GRDCPT)                                       34050013
         SPACE                                                          34080013
         TM    FLAG,COPY                   IF THIS IS A CASE OF COPYING 34110013
         BC    BZ,INT7A                    DICT ENTRIES, WE MAKE A COPY 34140013
         XC    PAR2(2,GRDCPT),PAR2(GRDCPT) OF THE CONTINUATION ENTRY    34170013
         MVC   PAR2+2(2,GRDCPT),1(GR1)     CHAINING IT FROM THE         34200013
         L     GRL,ZDICRF(0,GRCP)          PREVIOUS ONE, AND POINTING   34230013
         BALR  GRR,GRL                     GR1 AT IT.                   34260013
         MVC   ENTREF(2),PAR1+2(GRDCPT)                                 34290013
         L     GR1,PAR4(GRDCPT)                                         34350015
         MVC   PAR1+2(2,GRDCPT),SLOTRF                                  34410013
         L     GRL,ZDRFAB(0,GRCP)                                 24639 34420019
         BALR  GRR,GRL                                                  34440013
         L     GR2,PAR1(0,GRDCPT)                                       34470013
         MVC   0(2,GR2),ENTREF                                          34500013
         SPACE                                                          34530013
INT7A    MVC   TMFWST(2),1(GR1)        SET UP IN GR2 THE OFFSET OF THE  34560013
         LH    GR2,TMFWST            END OF THE 'INITIAL' DICT ENTRY.   34590013
         LA    GR3,4(0,0)            AND INITIALISE GR3 WITH THE OFFSET 34620013
         BC    B,INT2                OF THE FIRST ITEM IN THE ENTRY.    34650013
         SPACE                                                          34680013
INT6     LR    GR0,GR3                 HERE WE HAVE FOUND A MARKER FOR  34710013
         LA    GR3,1(GR3,GR1)        A VARIABLE REPLICATION FACTOR.     34740013
         SPACE                                                          34770013
         MVC   PAR1+2(2,GRDCPT),ENTREF SET UP IN 'TMPH' THE DICT. REF.  34800013
         ST    GR3,PAR2(0,GRDCPT)    OF THE TEXT REF. SLOT IN THE       34830013
         L     GRR,ZDABRF(0,GRCP)    INITIAL VALUE ENTRY.               34860013
         BALR  GRR,GRR                                                  34890013
         MVC   TMPH(2),PAR1+2(GRDCPT)                                   34920013
         SPACE                                                          34950013
         MVC   PAR1+1(3,GRDCPT),0(GR3) WE PICK UP THE SECOND FILE       34980013
         OI    PAR1(GRDCPT),X'80'                                       34990015
         L     GRL,ZTXTAB(0,GRCP)    STATEMENT AND ASSOCIATED DICT      35010013
         BALR  GRR,GRL               ENTRY, TESTING THE 'INITIAL' DICT  35040013
         L     GRL,PAR1(0,GRDCPT)    ENTRY TO SEE IF THE PAIR HAVE BEEN 35070013
         MVC   PAR1+2(2,GRDCPT),1(GRL)   USED ALREADY.                  35120015
         L     GR3,ZDRFAB(GRCP)                                         35170015
         BALR  GRR,GR3                                                  35220015
         L     GR3,PAR1(0,GRDCPT)                                       35280013
         TM    FLAG,COPY                                                35310013
         BC    BO,INT9                                                  35340013
         SPACE                                                          35370013
         MVC   SLTREF(2,GR3),TMPH      HERE THE STATEMENT AND DICT.     35400013
*                                    ENTRY HAVE NOT BEEN USED BEFORE,   35430015
*                                    SO WE POINT FROM THE DICT. ENTRY   35460015
         BC    B,INT9A               TO THE SLOT IN THE 'INITIAL' DICT  35490013
*                                    ENTRY WHICH CONTAINS THE TEXT REF  35520013
*                                    OF THE 2ND. FILE STATEMENT.        35550013
         SPACE                                                          35580013
INT9     MVC   REFST(2,GRELB),TMPH     HERE THE STATEMENT AND DICT.     35610013
         BAL   GRR,SECOP2            ENTRY HAVE ALREADY BEEN USED.  WE  35640015
*                                    CALL SECOP TO MAKE A NEW COPY      35670015
*                                    OF EACH AND ALSO TO UPDATE THE     35700015
*                                    POINTER IN THE DICT. ENTRY.        35760013
         SPACE                                                          35790013
INT9A    MVC   INTREF(2,GRL),NEWDIC(GRELB) HERE WE UPDATE A SLOT IN THE 35820013
         LR    GR3,GR0                                                  35830015
         BC    B,INT5                SECOND FILE STMNT. WITH THE DICT.  35850013
*                                    REF. OF THE VARIABLE BEING         35880013
*                                    INITIALISED.                       35910013
         SPACE                                                          35940013
INT1     DS    0H                                                       35960015
         LM    GRR,GR3,COPYST+16       HERE WE HAVE REACHED THE END OF  35980015
         MVI   FLAG,0                THE INITIAL DICT ENTRY. WE RELOAD  36000013
         BCR   BR,GRR                REGISTERS, CLEAR THE 'COPY' FLAG,  36030013
*                                    AND RETURN.                        36060013
         EJECT                                                          36090013
*              ROUTINE 'CDICEN'                                         36120013
         SPACE                                                          36150013
*              THIS ROUTINE IS CALLED TO BUILD ANY OF THE DICT.ENTRIES  36180013
*        FOR DECLARE PASS TWO                                           36210013
         SPACE                                                          36240013
*              IT CONSISTS OF ONE MAIN ROUTINE WHICH BRANCHES TO ONE OF 36270013
*        10 SUBSIDIARY ROUTINES. THESE CAN MAKE USE OF ANY OF THREE     36300013
*        UTILITY ROUTINES.                                              36330013
         SPACE 4                                                        36360013
*              THE MAIN ROUTINE PERFORMS THE FOLLOWING FUNCTIONS,       36390013
         SPACE 2                                                        36420013
*                  1. IT DOES SOME INITIALISATION FOR THE DICT.ENTRY    36450013
         SPACE                                                          36480013
*                  2. IT SETS UP IN THE BUILD AREA THE INITIAL CODE     36510013
*                     BYTE OF THE DICT.ENTRY.                           36540013
         SPACE                                                          36570013
*                  3. IT DECIDES WHICH OF THE SUBSIDIARY ROUTINES TO    36600013
*                     BRANCH TO. (EACH OF THESE ROUTINES CONSTRUCTS     36630013
*                     DICT. ENTRIES OF ONE PARTICULAR FORMAT).          36660013
         EJECT                                                          36690013
*              THIS IS THE ENTRY POINT TO 'CDICEN'                      36720013
         SPACE 4                                                        36750013
*              MAIN ROUTINE                                             36780013
         SPACE 4                                                        36810013
CDICEN   STM   GR0,GRL,STM(GRATCA)     STORE ALL REGISTERS.             36840013
         SPACE 2                                                        36870013
         LA    GRBILD,BLDARA(0,GRATCA) CLEAR BUILD AREA AND SET UP      36900013
         MVI   0(GRBILD),X'00'       POINTER TO IT.                     36930013
         MVC   1(BLDLTH,GRBILD),0(GRBILD)                        H344   36960019
         SPACE 4                                                        36990013
*              NEXT WE ARE GOING TO SET THE HIGH ORDER FOUR BITS IN     37020013
*        THE INITIAL CODE BYTE ACCORDING TO THE RULES THAT GOVERN THEM  37050013
         SPACE                                                          37080013
         TM    FLAGS(GRATCA),CFLAG3    IF NO BCD REQUIRED, SET THE BIT  37110013
         BC    BO,CDIC1                                                 37140013
         OI    0(GRBILD),NOBCD                                          37170013
         SPACE                                                          37200013
CDIC1    TM    FLAGS(GRATCA),CFLAG4    IF MEMBER OF STRUCTURE, SET THE  37230013
         BC    BZ,CDIC2              BIT.                               37260013
         OI    0(GRBILD),STRMEM                                         37290013
         OI    ZFLAG1(GRDCPT),ZSTRFL   SET 'STRUCTURE' FLAG IN COMM.REG 37320013
         SPACE                                                          37350013
CDIC2    TM    VARBLE(GRATCA),DIMENS   IF DIMENSIONED, SET THE BIT.     37380013
         BC    BZ,CDIC3                                                 37410013
         OI    0(GRBILD),DIMS                                           37440013
         SPACE 4                                                        37470013
*              NEXT WE ARE GOING TO DECIDE WHICH SORT OF DICT. ENTRY IS 37500013
*        GOING TO BE MADE, BY TESTING INFORMATION IN THE ATT.COLL.AREA. 37530013
*        HAVING DECIDED, WE FINALISE THE INITIAL CODE BYTE AND BRANCH   37560013
*        TO THE APPROPRIATE SUBSIDIARY ROUTINE, TO BUILD THE DICT.ENTRY 37590013
         SPACE 2                                                        37620013
CDIC3    TM    DCLATT(GRATCA),NTRY     IS IT AN ENTRY POINT             37650013
         BC    BZ,CDIC4                                                 37680013
         TM    FLAGS(GRATCA),CFLAG7    IS THERE A SIMILAR BCD IN THIS   37710013
         BC    BZ,CDIC3A                                                37740015
         SPACE                                                          37770015
*              HERE THERE IS A SIMILAR BCD IN THE SAME BLOCK.           37800015
         SPACE                                                          37830015
CDIC9    MVI   0(GRBILD),E5            SET UP FOR ENTRY TYPE 5          37860015
         TM    OTHER2(GRATCA),FMPRAM   IS IT A FORMAL PARAMETER         37890015
         BC    BO,DEE456               YES - GO TO MAKE ENTRY TYPE 5    37920015
         SPACE                                                          37950015
         MVI   0(GRBILD),E3            NO - SET UP FOR ENTRY TYPE 3     37980015
         TM    FLAGS+1(GRATCA),CFLA16  IS IT AN INTERNAL ENTRY LABEL    38010015
         BC    BO,DEE3                 YES - GO TO MAKE ENTRY TYPE 3    38040015
         SPACE                                                          38070015
*              HERE THERE IS NO SIMILAR BCD IN THIS BLOCK               38100015
         SPACE                                                          38130015
CDIC3A   MVI   0(GRBILD),E4            SET UP FOR ENTRY TYPE 4          38160015
         TM    FLAGS(GRATCA),CFLAG3    IS BCD REQUIRED                  38190015
         BC    BO,DEE456               YES - MAKE ENTRY TYPE 4          38220015
         SPACE                                                          38250015
         MVI   0(GRBILD),E6            NO - MAKE ENTRY TYPE 6           38280015
         BC    B,DEE456              (PARAMETER DESCRIPTION)            38310015
         SPACE                                                          38490013
CDIC4    TM    DCLATT(GRATCA),STRUC    IS IT A STRUCTURE                38520013
         BC    BZ,CDIC5                                                 38550013
         OI    0(GRBILD),STRCTR        SET INITIAL CODE BYTE FOR        38580013
         BC    B,DESLF               STRUCTURE, AND GO TO 'STRUCTURE,   38610013
*                                    LABEL AND FILE PARAMETER' ROUTINE. 38640013
         SPACE                                                          38670013
CDIC5    TM    DCLATT(GRATCA),LABEL    IS IT A LABEL                    38700013
         BC    BZ,CDIC6                                                 38730013
         OI    0(GRBILD),LBL           SET INITIAL CODE BYTE FOR LABEL, 38760013
         BC    B,DESLF               AND GO TO 'STRUCTURE, LABEL AND    38790013
*                                    FILE PARAMETER' ROUTINE.           38820013
         SPACE                                                          38850013
CDIC6    TM    DCLATT(GRATCA),FILE     IS IT A FILE PARAMETER           38880013
         BC    BZ,CDIC7                                                 38910013
         OI    ZFLAG4(GRDCPT),FILEFL   WE NOW KNOW WE SHALL BE MAKING A 38940013
*                                    DICT. ENTRY FOR A FILE, SO WE SET  38970013
*                                    THE BIT IN THE COMM. REG. WHICH    39000013
*                                    INDICATES THE PRESENCE OF FILES.   39030013
         TM    OTHER2(GRATCA),FMPRAM                                    39060013
         BC    BZ,CDIC8                                                 39090015
         OI    0(GRBILD),FLPRAM        SET INITIAL CODE BYTE FOR        39120013
         BC    B,DESLF               FILE PARAMETER, AND GO TO          39150013
*                                    'STRUCTURE, LABEL AND FILE         39180013
*                                    PARAMETER' ROUTINE.                39210013
         SPACE                                                          39240013
CDIC7    TM    DCLATT(GRATCA),DATA     IS IT A DATA ITEM                39270013
         BC    BZ,CDIC8A                                                39300015
         OI    0(GRBILD),DATITM        SET INITIAL CODE BYTE FOR DATA   39330013
         BC    B,DEDATA              ITEM, AND GO TO 'DATA ITEM'        39360013
*                                    ROUTINE.                           39390013
         SPACE 2                                                        39420013
CDIC8    OI    0(GRBILD),FCONST        SET INITIAL CODE BYTE FOR FILE   39490015
         BC    B,FDIC1               CONSTANT. AND GO TO 'FILE CONST.'  39570013
*                                    ROUTINE                            39600013
         SPACE                                                          39630013
CDIC8A   DS    0H                                                       39640015
*              HERE IT IS NOT A DATA ITEM, AND WE CONTINUE TESTING.     39642015
         TM    DCLATT(GRATCA),TASKID   TASK OR EVENT VARIABLE ?         39645015
         BC    BZ,CDIC13               BRANCH IF NOT.                   39650015
         TM    FLAGS3(GRATCA),CFLA24   IS IT EVENT ?                    39655015
         BC    BO,CDIC12               BRANCH IF SO.                    39660015
         SPACE                                                          39665015
         OI    0(GRBILD),TSK           SET INITIAL CODE BYTE FOR TASK   39670015
         BC    B,DESLF               AND MAKE ENTRY AS FOR LABEL.       39680015
         SPACE                                                          39690015
CDIC12   DS    0H                                                       39700015
         OI    0(GRBILD),EVNT          SET INITIAL CODE BYTE FOR EVENT  39720015
         BC    B,DESLF               AND MAKE ENTRY AS FOR LABEL.       39740015
         SPACE                                                          39810013
CDIC13   TM    DCLATT(GRATCA),BILTIN   IS IT A BUILT-IN FUNCTION ENTRY  39840013
         BC    BZ,CDIC14                                                39870013
         TM    FLAGS(GRATCA),CFLAG8    BRANCH IF THE SCAN IS IN AN      39900013
         BC    BO,BLTSP              ENTRY DECLARATION.                 39930013
         SPACE                                                          39970015
         MVI   0(GRBILD),X'06'         SET UP GENERIC-TYPE CODE BYTE    40010015
         TM    FLAGS+1(GRATCA),CFLA11  IS IT IN FACT GENERIC            40050015
         BC    BO,CDIC19               YES.                             40090015
         MVI   0(GRBILD),BLTN          NO - RESET CODE BYTE             40130015
         SPACE                                                          40200013
CDIC19   MVC   BLTOF1(2,GRBILD),CADD1(GRATCA) MOVE IN HASH SLOT, TWO    40230013
         MVC   BLTOF2(2,GRBILD),OTHER2(GRATCA) CODE BYTES STORED IN     40260013
         MVC   BLTOF3(2,GRBILD),DCLNUM(GRATCA) OTHER2 AND OTHER3, AND   40290013
*                                              DECLARE NUMBER.          40320013
         LA    GRBILD,BLTOF3+2(GRBILD) BUMP BUILD POINT TO END AND      40350013
         BC    B,DEDA2               BRANCH TO INSERT L AND C           40380013
         SPACE                                                          40410013
*              ENTRY TO CONSTRUCT A THREE BYTE DICTIONARY ENTRY FOR     40440013
*        THE CASE OF DECLARING AN ARGUMENT BUILTIN IN AN ENTRY          40470013
*        DECLARATION.                                                   40500013
         SPACE                                                          40530013
BLTSP    MVI   0(GRBILD),SPBLT         INSERT LEADING CODE BYTE         40560013
         LA    GRBILD,3(GRBILD)        SET LENGTH TO THREE              40590013
         SR    GR1,GR1                 INDICATE NO BCD                  40620013
         BC    B,CDIC16                BRANCH TO INSERT IN DICTIONARY   40650013
         SPACE                                                          40680013
CDIC14   TM    DCLATT(GRATCA),GENRIC   IS IT A GENERIC FUNCTION ENTRY   40710013
         BC    BZ,CDIC15                                                40740013
         MVI   0(GRBILD),PGNRC         SET INITIAL CODE BYTE FOR        40770013
         MVC   GENOF1(2,GRBILD),CADD1(GRATCA)  MOVE IN HASH CHAIN       40800013
         MVC   GENOF2(2,GRBILD),DCLNUM(GRATCA) AND DECLARE NUMBER       40830013
         L     GR1,COUNT1(GRATCA)      STORE 2* THE NUMBER OF           40860013
         AR    GR1,GR1               ITEMS IN THE GENERIC LIST IN       40890013
         STC   GR1,GENOF3(GRBILD)    THE ENTRY.                         40920013
         LA    GRBILD,GENOF3+1(GR1,GRBILD)  BUMP BUILD POINTER PAST     40950013
*                                    SPACE FOR LAST DICTIONARY          40980013
*                                    REFERENCE                          41010013
         BC    B,DEDA2                 BRANCH TO INSERT L AND C AND BCD 41040013
         SPACE                                                          41070013
*              IF NONE OF THE ABOVE POSSIBILITIES APPLY, THIS IS A      41100013
*        COMPILER ERROR.                                                41130013
         SPACE                                                          41160013
CDIC15   DC    X'0000'                 INTERRUPT.                       41190013
         SPACE 4                                                        41220013
*              HERE WE HAVE COMPLETELY SET UP THE BUILD AREA AND WE PUT 41250013
*        THE ENTRY INTO THE DICTIONARY                                  41280013
         SPACE                                                          41310013
CDIC16   LA    GR2,BLDARA(0,GRATCA)    POINT PAR1 AT START OF BUILD     41340013
         ST    GR2,PAR1(0,GRDCPT)    AREA.                              41370013
         SR    GRBILD,GR2              SET UP OFFSET OF BCD LENGTH BYTE 41400013
         STC   GRBILD,2(0,GR2)       IN BUILD AREA.                     41430013
         SPACE                                                          41460013
         LA    GRBILD,0(GR1,GRBILD)    BUMP GRBILD BY ANY BCD LENGTH    41490013
         ST    GRBILD,PAR2(0,GRDCPT) AND SET UP TOTAL LENGTH IN PAR2.   41520013
         SPACE                                                          41550013
         L     GRL,ZDICRF(0,GRCP)                                       41580013
         BALR  GRR,GRL                                                  41610013
         SPACE 2                                                        41640013
         TM    FLAGS+1(GRATCA),CFLA13  ARE CADD1 PROCESSES INHIBITED    41670013
         BC    BO,CDIC17                                                41700013
         SPACE                                                          41730013
         L     GR2,CADD2(0,GRATCA)     MOVE NEW DICT.REF INTO ITS CHAIN 41760013
         MVC   3(2,GR2),PAR1+2(GRDCPT) SLOT (POINTED AT BY CADD2)       41790013
         SPACE 2                                                        41820013
*              THIS IS THE POINT WHERE WE RETURN TO THE ROUTINE THAT    41850013
*        CALLED 'CDICEN'.                                               41880013
         SPACE                                                          41910013
CDIC17   LM    GR0,GRL,STM(GRATCA)     RELOAD REGISTERS FROM SAVE AREA  41940013
         L     GRR,LINK(0,GRATCA)      SET RETURN REGISTER              41970013
         BCR   BR,GRR                  RETURN.                          42000013
         EJECT                                                          42030013
*              ROUTINE 'ADSLT2' (SECOND ADDRESS SLOT)                   42060013
         SPACE 4                                                        42090013
*              THIS IS A UTILITY SUBROUTINE FOR ROUTINE 'CDICEN'.       42120013
*              IT DECIDES WHETHER A SECOND ADDRESS SLOT SHOULD BE GIVEN 42150013
*              TO THE DICT.ENTRY BEING MADE, FROM THE INFORMATION       42180013
*              SET UP IN THE ATT.COLL.AREA.                             42210013
         SPACE 4                                                        42240013
ADSLT2   TM    DCLATT(GRATCA),DATA     IS THIS A DATA ITEM. IF SO. GO   42270013
         BC    BO,ADSL3              ON TESTING.                        42300013
         SPACE                                                          42330013
         TM    VARBLE(GRATCA),MEMSTR   IS THIS A STRUCTURE MEMBER.      42360013
         BC    BO,ADSL3              IF SO, GO ON TESTING               42390013
         SPACE                                                          42420013
         TM    DCLATT(GRATCA),LABEL+TASKID  IS IT LABEL,EVENT,OR TASK ? 42440015
*                                    (IF NOT, NO SLOT WILL BE PROVIDED) 42460015
         BC    BZ,ADSL2                                                 42480013
         SPACE                                                          42510013
ADSL3    TM    OTHER2(GRATCA),FMPRAM   IS IT A FORMAL PARAMETER. IF SO, 42540013
         BC    BO,ADSL4              GO ON TESTING.                     42570013
         SPACE                                                          42600013
         TM    OTHER2(GRATCA),CNTRLD   IS IT CONTROLLED                 42630013
         BC    BNO,ADSL5                                                42660013
         SPACE                                                          42690013
ADSL4    TM    VARBLE(GRATCA),MEMSTR   IS IT MEMBER OF STRUCTURE. 'YES' 42720013
         BC    BO,ADSL1              IF IT IS, 'NO' IF IT ISN'T.        42750013
         BC    B,ADSL2                                                  42780013
         SPACE                                                          42810013
ADSL5    TM    OTHER2(GRATCA),CNTRLD   IS IT STATIC. IF SO, GO ON       42840013
         BC    BNM,ADSL6             TESTING                            42870013
         SPACE                                                          42900013
         TM    OTHER2(GRATCA),EXTINT   IS IT EXTERNAL. 'YES' IF IT IS,  42930013
         BC    BO,ADSL1                                                 42960013
         SPACE                                                          42990013
ADSL6    TM    DATABT(GRATCA),CANSTR   'YES' IF IT IS A STRING.         43020013
         BC    BZ,ADSL1                                                 43050013
         SPACE                                                          43080013
         TM    VARBLE(GRATCA),MEMSTR   'YES'IF IT IS A MEMBER OF A      43110013
         BC    BO,ADSL1              STRUCTURE.                         43140013
         SPACE                                                          43170013
         TM    VARBLE(GRATCA),DEFND    'YES' IF IT IS DEFINED.          43200013
         BC    BO,ADSL1                                                 43230013
         SPACE                                                          43260013
         TM    VARBLE(GRATCA),DIMENS   'YES' IF IT IS DIMENSIONED.      43290013
         BC    BO,ADSL1                                                 43320013
         SPACE                                                          43350013
ADSL2    BCR   BR,GRR                  OTHERWISE, 'NO', AND RETURN      43380013
         SPACE                                                          43410013
ADSL1    OI    VARBLE(GRATCA),SECASL   HERE WE WANT THE SLOT, SO WE SET 43440013
         BCR   BR,GRR                THE BIT IN THE VARIABLE BYTE, AND  43470013
*                                    RETURN.                            43500013
         EJECT                                                          43530013
*              'VARINF' ROUTINE (VARIABLE INFORMATION)                  43560013
         SPACE 4                                                        43590013
*              THIS IS A UTILITY SUBROUTINE USED BY ROUTINE 'CDICEN'.   43620013
*        IT  MOVES  ALL VARIABLE INFORMATION (WHOSE PRESENCE IS SHOWN   43650013
*        IN THE VARIABLE BYTE) FROM THE ATT.COLL.AREA TO THE BUILD AREA 43680013
*              ON ENTRY, GRBILD MUST POINT TO THE FIRST BYTE OF THE     43710013
*        VARIABLE INFORMATION.                                          43740013
*              ON EXIT, GRBILD WILL POINT TO THE FIRST BYTE AFTER THE   43770013
*        VARIABLE INFORMATION.                                          43800013
         SPACE 4                                                        43830013
*              PROCESS THE 'SECOND ADDRESS SLOT'.                       43860013
         SPACE                                                          43890013
VARINF   TM    VARBLE(GRATCA),SECASL                                    43920013
         BC    BZ,VARI2                                                 43950013
         LA    GRBILD,4(0,GRBILD)      BUMP GRBILD. (THIS SLOT IS NEVER 43980013
*                                    FILLED BY THIS PHASE).             44010013
         SPACE 2                                                        44040013
*              PROCESS THE 'DIMENSIONED SLOT'.                          44070013
         SPACE                                                          44100013
VARI2    TM    VARBLE(GRATCA),DIMENS                                    44130013
         BC    BZ,VARI3                                                 44160013
         MVC   0(3,GRBILD),DIMINF+1(GRATCA) MOVE IN 'DIMENSION'         44190013
*                                    INFORMATION.                       44220013
         LA    GRBILD,3(0,GRBILD)      BUMP GRBILD OVER THE SLOT.       44250013
         SPACE 2                                                        44280013
*              PROCESS THE 'STRUCTURE MEMBER SLOT'.                     44310013
         SPACE                                                          44340013
VARI3    TM    VARBLE(GRATCA),MEMSTR                                    44370013
         BC    BZ,VARI4                                                 44400013
         MVC   0(10,GRBILD),STRUCT(GRATCA) MOVE IN 'STRUCTURE MEMBER'.  44430013
*                                    INFORMATION.                       44460013
         SPACE                                                          44490013
         LA    GR1,BLDARA(0,GRATCA)    SET UP IN SLOT 'STRCOF' THE      44520013
         LA    GR2,4(0,GRBILD)       OFFSET OF THE 'STRUCTURE MEMBER    44550013
         SR    GR2,GR1               DICT.REF' SLOT FROM THE START OF   44580013
         STH   GR2,STRCOF(0,GRELB)   THE DICT.ENTRY.                    44610013
         LA    GRBILD,10(0,GRBILD)     BUMP GRBILD OVER THE SLOT.       44640013
         SPACE 2                                                        44670013
*              PROCESS THE 'POS SLOT'                                   44700013
         SPACE                                                          44730013
VARI4    TM    VARBLE(GRATCA),VALPOS                                    44760013
         BC    BZ,VARI5                                                 44790013
         MVC   0(2,GRBILD),POS(GRATCA) MOVE IN 'POS' INFORMATION        44820013
         LA    GRBILD,2(0,GRBILD)      BUMP GRBILD OVER THE SLOT.       44850013
         SPACE 2                                                        44880013
*              PROCESS THE 'INITIAL VALUE, LIKE' SLOT.                  44910013
         SPACE                                                          44940013
VARI5    TM    VARBLE(GRATCA),INVLIK                                    44970013
         BC    BZ,VARI6                                                 45000013
         MVC   0(4,GRBILD),LIKINV(GRATCA) MOVE IN 'INITIAL VALUE /LIKE' 45030013
*                                    INFORMATION                        45060013
         SPACE                                                          45090013
         LA    GR1,BLDARA(0,GRATCA)    SET UP IN ATT.COLL.AREA THE      45120013
         LR    GR2,GRBILD            OFFSET OF THE 'INITIAL' SLOT FROM  45150013
         SR    GR2,GR1               THE START OF THE DICT.ENTRY.       45180013
         STH   GR2,LKIVOF(0,GRATCA)                                     45210013
         SPACE                                                          45240013
         LA    GRBILD,4(0,GRBILD)      BUMP GRBILD OVER THE SLOT        45270013
         SPACE 2                                                        45300013
*              PROCESS THE 'CODE BYTES' SLOT.                           45330013
         SPACE                                                          45360013
VARI6    TM    VARBLE(GRATCA),CODBYT                                    45390013
         BC    BZ,VARI7                                                 45420013
         MVC   0(2,GRBILD),OTHER5(GRATCA) MOVE CODE BYTES AND BUMP      45450013
         LA    GRBILD,2(0,GRBILD)    GRBILD OVER THE SLOT.              45480013
         SPACE 2                                                        45510013
*              PROCESS THE 'DEFINED' SLOT.                              45540013
         SPACE                                                          45570013
VARI7    TM    VARBLE(GRATCA),DEFND                                     45600013
         BC    BZ,VARI8                                                 45630013
         MVC   0(7,GRBILD),DEFINF(GRATCA) MOVE 'DEFINED' INFORMATION    45660013
         LA    GRBILD,7(0,GRBILD)    AND BUMP GRBILD OVER THE SLOT.     45690013
         SPACE 2                                                        45720013
*              NOW ALL VARIABLE INFORMATION HAS BEEN SET UP             45750013
         SPACE                                                          45780013
VARI8    BCR   BR,GRR                  RETURN                           45810013
         EJECT                                                          45840013
*              'BCDMVE' ROUTINE                                         45870013
         SPACE 4                                                        45900013
*              THIS IS A UTILITY SUBROUTINE USED BY ROUTINE 'CDICEN'.   45930013
*        IT MOVES THE BCD INTO THE BUILD AREA.                          45960013
*              ON ENTRY. GRBILD MUST POINT TO THE BYTE (IN THE BUILD    45990013
*        AREA) WHICH WILL CONTAIN THE BCD LENGTH.                       46020013
*              ON EXIT, GRBILD WILL BE UNCHANGED, AND GR1 WILL CONTAIN  46050013
*        THE BCD LENGTH + 1.                                            46080013
         SPACE 4                                                        46110013
BCDMVE   MVC   PAR1+1(3,GRDCPT),BCDTRF+1(GRATCA) PICK UP THE TEXT REF.  46140013
*                                    OF THE BCD LENGTH BYTE FROM THE    46170013
*                                    ATT.COLL.AREA.                     46200013
         SPACE                                                          46230013
         OI    PAR1(GRDCPT),X'80'      ENSURE STATUS OF BLOCK     32270 46240020
*                                    CONTAINING BCD IS NOT CHANGED.     46250020
         LR    GR0,GRR                                                  46260013
         L     GRL,ZTXTAB(0,GRCP)      CONVERT THE TEXT REF. TO ADDRESS 46290013
         BALR  GRR,GRL                                                  46320013
         NI    PAR1(GRDCPT),X'7F'                                 32270 46330020
         SPACE                                                          46350013
         L     GRL,PAR1(0,GRDCPT)      POINT GRL AT BCD LENGTH BYTE     46380013
         SR    GRR,GRR                                                  46410013
         IC    GRR,0(0,GRL)                                             46440013
         BCTR  GRR,0                   GRR CONTAINS BCD-LENGTH - 1      46470013
         STC   GRR,*+5                                                  46500013
         MVC   1(0,GRBILD),1(GRL)      MOVE IN THE BCD                  46530013
         STC   GRR,0(GRBILD)           MOVE IN 'BCD LENGTH - 1'.        46560013
         LA    GR1,2(0,GRR)            SET UP GR1 WITH BCD LENGTH +1.   46590013
         SPACE                                                          46620013
         LR    GRR,GR0                                                  46650013
         BCR   BR,GRR                  RETURN                           46680013
         EJECT                                                          46710013
*              'DEDATA' ROUTINE                                         46740013
         SPACE 4                                                        46770013
*              THIS IS A SUBSIDIARY ROUTINE TO ROUTINE 'CDICEN'.        46800013
*        IT CONSTRUCTS DICT. ENTRIES FOR:                               46830013
         SPACE                                                          46860013
*              1. DATA ITEMS.                                           46890013
*              2. DATA ITEM PARAMETER DESCRIPTIONS.                     46920013
         SPACE 4                                                        46950013
DEDATA   BAL   GRR,ADSLT2              GO TO PROCESS 2ND.ADDRESS SLOT   46980013
         SPACE                                                          47010013
         MVC   DATA2(2,GRBILD),CADD1(GRATCA) MOVE IN HASH CHAIN         47040013
         MVC   DATA4(2,GRBILD),DCLNUM(GRATCA) MOVE IN DECLARE NUMBER    47070013
         MVC   DATA5(6,GRBILD),OTHER1(GRATCA) MOVE IN 6 CODE BYTES      47100013
         MVC   DATA11(5,GRBILD),DATINF+1(GRATCA)   MOVE IN DATA         47140015
*                                    INFORMATION, AND ANY PIC. TABLE    47180015
*                                    REFERENCE.                         47220013
         SPACE                                                          47250013
         LA    GRBILD,DATA13(0,GRBILD) POINT GRBILD AT VARIABLE INF.    47280013
         BAL   GRR,VARINF            AND GO TO FILL IT IN.              47310013
         SPACE                                                          47340013
DEDA2    MVC   0(2,GRBILD),LEVEL(GRATCA)  MOVE IN LEVEL AND COUNT.      47370013
         SPACE                                                          47400013
         SR    GR1,GR1                 CLEAR GR1                        47430013
         LA    GRBILD,2(0,GRBILD)      POINT GRBILD AT LENGTH BYTE OF   47460013
         TM    FLAGS(GRATCA),CFLAG3  BCD AND GO TO MOVE IT IN IF        47490013
         BC    BZ,DEDA1              NECESSARY                          47520013
         BAL   GRR,BCDMVE                                               47550013
         SPACE                                                          47580013
DEDA1    BC    B,CDIC16                RETURN TO MAIN ROUTINE (CDICEN)  47610013
         EJECT                                                          47640013
*              'DESLF' ROUTINE                                          47670013
         SPACE 4                                                        47700013
*              THIS IS A SUBSIDIARY ROUTINE TO ROUTINE 'CDICEN'.        47730013
*        IT CONSTRUCTS DICT.ENTRIES FOR:                                47760013
         SPACE                                                          47790013
*              1. STRUCTURES.                                           47820013
*              2. STRUCTURE PARAMETERS.                                 47850013
*              3. LABEL VARIABLES.                                      47880013
*              4. LABEL VARIABLE PARAMETERS.                            47910013
*              5. FILE PARAMETERS.                                      47940013
*              6. TASK VARIABLES.                                       47950015
*              7. EVENT VARIABLES.                                      47960015
         SPACE 4                                                        47970013
DESLF    BAL   GRR,ADSLT2              GO TO PROCESS 2ND. ADDRESS SLOT  48000013
         SPACE                                                          48030013
         MVC   SLF2(2,GRBILD),CADD1(GRATCA) MOVE IN HASH CHAIN          48060013
         MVC   SLF4(2,GRBILD),DCLNUM(GRATCA) MOVE IN DECLARE NUMBER     48090013
         MVC   SLF5(5,GRBILD),OTHER1(GRATCA) MOVE IN 5 CODE BYTES       48120013
         SPACE                                                          48150013
         LA    GRBILD,SLF10(0,GRBILD)  POINT GRBILD AT START OF         48180013
         BAL   GRR,VARINF            VARIABLE INFORMATION AND GO TO     48210013
*                                    FILL IT IN.                        48240013
         SPACE                                                          48270013
*              IF THIS IS A LABEL VARIABLE, WE ALLOW FOR A SYMBOL SLOT. 48300013
*        (ALSO FOR TASK OR EVENT VARIABLES)                             48310015
         SPACE                                                          48320015
         TM    DCLATT(GRATCA),LABEL+TASKID                              48330015
         BC    BZ,DESL2                                                 48360013
         LA    GRBILD,2(0,GRBILD)                                       48390013
         SPACE                                                          48420013
DESL2    MVC   0(2,GRBILD),LEVEL(GRATCA) MOVE IN LEVEL AND COUNT        48450013
         SPACE                                                          48480013
         SR    GR1,GR1                 CLEAR GR1                        48510013
         LA    GRBILD,2(0,GRBILD)      POINT GRBILD AT LENGTH BYTE OF   48540013
         TM    FLAGS(GRATCA),CFLAG3  BCD AND GO TO MOVE IT IN IF        48570013
         BC    BZ,DESL1              NECESSARY.                         48600013
         BAL   GRR,BCDMVE                                               48630013
         SPACE                                                          48660013
DESL1    BC    B,CDIC16                RETURN TO MAIN ROUTINE (CDICEN)  48690013
         EJECT                                                          48720013
*              'DEE456' ROUTINE                                         48750013
         SPACE 4                                                        48780013
*              THIS IS A SUBSIDIARY ROUTINE TO ROUTINE 'CDICEN'.        48810013
*        IT CONSTRUCTS DICTIONARY ENTRIES FOR:                          48840013
         SPACE                                                          48870013
*              1. EXTERNAL ENTRY POINTS (ENTRY TYPE 4'S).               48900013
*              2. FORMAL PARAMETER DECLARATIONS (ENTRY TYPE 5'S).       48930013
*              3. PARAMETERS WHICH ARE ENTRY POINTS (ENTRY TYPE 6'S).   48960013
         SPACE 4                                                        48990013
DEE456   MVC   E43(2,GRBILD),CADD1(GRATCA) MOVE IN CHAIN SLOT           49020013
         MVC   E47(1,GRBILD),ENTRY(GRATCA) MOVE IN 'ENTRY'CODE BYTE.    49050013
         MVC   E48(1,GRBILD),DATABT(GRATCA) MOVE IN 'DATA' CODE BYTE.   49080013
         MVC   E49(5,GRBILD),DATINF+1(GRATCA)  MOVE IN DATA INFORMATION 49110015
*                                           AND ANY PICTURE REFERENCE.  49140015
         SPACE 2                                                        49200013
*              WE NOW SET THE 'MARKER BYTE' APPROPRIATELY.              49230013
         SPACE                                                          49260013
         L     GR2,COUNT1(0,GRATCA)    SET UP NUMBER OF PARAMETERS IN   49290013
*                                    GR2.                               49320013
         TM    FLAGS(GRATCA),CFLAG2                                     49350013
         BC    BO,E456A                BRANCH IF PAR. DESCR.      18351 49380017
*                                                                 18351 49410017
*              NO PARAMETERS.                                     18351 49440017
*                                                                 18351 49470017
         SR    GR2,GR2                 ENSURE 0 COUNT.            18351 49500017
         MVI   E412(GRBILD),E4B        SET MARKER BYTE            18351 49530017
         BC    B,E4562                                            18351 49560017
*                                                                 18351 49590017
E456A    DS    0H                                                 18351 49620017
         MVI   E412(GRBILD),E4A        SET MARKER BYTE            18351 49650017
         SPACE                                                          49680013
*              HERE THE NUMBER OF PARAMS. IS IN GR2                     49710013
         SPACE                                                          49740013
E4561    C     GR2,CD64                CHECK THAT IT DOES NOT EXCEED    49770013
         BC    BNH,E4562             THE IMPLEMENTION LIMIT             49800013
         SPACE                                                          49830013
         BAL   GRL,ERROR               IF IT DOES, GENERATE DIAGNOSTIC  49860013
         DC    X'022EC400'                                              49890013
         SPACE                                                          49920013
         LA    GR2,64(0,0)             FORCE NUMBER OF PARAMETERS TO 64 49950013
         ST    GR2,COUNT1(0,GRATCA)                                     49980013
         SPACE                                                          50010013
E4562    AR    GR2,GR2                 DOUBLE IT.                       50040013
         STC   GR2,E413(0,GRBILD)                                       50070013
         LA    GRBILD,E414(GR2,GRBILD) BUMP GRBILD OVER THE DICT.REFS   50100013
*                                    OF THE PARAM.DESCRIPTIONS.         50130013
         SPACE                                                          50160013
         MVC   E415(2,GRBILD),DCLNUM(GRATCA) SET UP DECLARE NUMBER      50190013
         MVC   E416(2,GRBILD),LEVEL(GRATCA) SET UP LEVEL AND COUNT.     50220013
         SPACE                                                          50250013
         LA    GRBILD,E418(0,GRBILD)   POINT GRBILD AT BYTE CONTAINING  50280013
*                                    BCD LENGTH.                        50310013
*              NOW WE PUT IN A BCD IF NECESSARY                         50340013
         SPACE                                                          50370013
         SR    GR1,GR1                 CLEAR GR1                        50400013
         TM    FLAGS(GRATCA),CFLAG3                                     50430013
         BC    BZ,DE4563                                                50460013
         SPACE                                                          50490013
         BAL   GRR,BCDMVE                                               50520013
         SPACE                                                          50550013
DE4563   BC    B,CDIC16                RETURN TO MAIN ROUTINE (CDICEN)  50580013
         EJECT                                                          50610013
*              'DEE3' ROUTINE                                           50640013
         SPACE 4                                                        50670013
*              THIS IS A SUBSIDIARY ROUTINE TO ROUTINE 'CDICEN'.        50700013
*        IT CONSTRUCTS DICT ENTRIES FOR:                                50730013
         SPACE                                                          50760013
*              1. INTERNAL ENTRY POINTS (ENTRY TYPE 3'S).               50790013
*              2. DATA DESCRIPTION OF THE INTERNAL ENTRY POINT (ENTRY   50820013
*                 TYPE 2'S).                                            50850013
         SPACE 4                                                        50880013
*              FIRST WE ARRANGE FOR CADD2 TO POINT AT THE OLD ENTRY     50910013
*        TYPE 2.                                                        50940013
         SPACE                                                          50970013
DEE3     MVC   PAR1+2(2,GRDCPT),CADD1(GRATCA) SET UP DICT.REF.OF 'ENTRY 51000013
*                                    LABEL'.                            51030013
         SPACE                                                          51060013
         L     GRL,ZDRFAB(0,GRCP)      POINT GR1 AT ENTRY LABEL DICT.   51090013
         BALR  GRR,GRL               ENTRY.                             51120013
         SPACE                                                          51150013
         L     GR1,PAR1(0,GRDCPT)                                       51180013
         MVC   PAR1+2(2,GRDCPT),11(GR1) SET UP DICT REF OF ENT TYPE 2.  51210013
         MVC   DEE3X1(2),11(GR1)     IN PAR1 AND IN 'DEE3X1'.           51240013
         SPACE                                                          51270013
         BALR  GRR,GRL                 POINT GR2 AT ENTRY TYPE 2        51300013
         SPACE                                                          51330013
         L     GR2,PAR1(0,GRDCPT)                                       51360013
         ST    GR2,CADD2(0,GRATCA)     AND CADD2.                       51390013
         MVC   ZLOCK(2,GRDCPT),DEE3X1  LOCK IN BLOCK CONTAINING CADD2.  51420013
         SPACE 2                                                        51450013
*              NOW WE BUILD THE ENTRY TYPE 3.                           51480013
         SPACE                                                          51510013
         MVC   E33(2,GRBILD),3(GR2)    SET UP DICT REF OF ENTRY TYPE 1  51540013
         MVC   E34(2,GRBILD),DEE3X1    SET UP DICT.REF.OF ENTRY TYPE 2  51570013
*                                    (IF A NEW ENTRY TYPE 2 IS NEEDED,  51600013
*                                    THIS SLOT WILL BE OVERWRITTEN      51630013
*                                    LATER).                            51660013
         MVC   E36(1,GRBILD),ENTRY(GRATCA) SET UP 'ENTRY' CODE BYTE     51690013
         MVC   E310(2,GRBILD),CADD1(GRATCA) SET UP DICT.REF.OF LABEL    51750013
         SPACE 2                                                        51780013
*              NOW WE POINT GR1 AT THE ENTRY TYPE 1.                    51810013
         SPACE                                                          51840013
         MVC   PAR1+2(2,GRDCPT),3(GR2)                                  51870013
         BALR  GRR,GRL                                                  51900013
         L     GR1,PAR1(0,GRDCPT)                                       51930013
         CLI   0(GR1),E3               IS IT AN ENTRY TYPE 3            51960013
         BC    BE,DEE35A                                                51990013
         CLI   0(GR1),E1P              IS IT 'PROCEDURE' ENTRY TYPE 1.  52020013
         BC    BE,DEE35B                                                52050013
         CLI   0(GR1),E1B              IS IT 'BEGIN' ENTRY TYPE 1.      52080013
         BC    BE,DEE35B                                                52110013
         CLI   0(GR1),E1E              IS IT 'ENTRY ' ENTRY TYPE 1.     52140013
         BC    BE,DEE35C                                                52170013
         SPACE                                                          52200013
         DC    H'0'                    OTHERWISE, COMPILER ERROR.       52230013
         SPACE 2                                                        52260013
*              HERE IT IS AN ENTRY TYPE 1 FROM A PROC/BEGIN STATEMENT   52290013
         SPACE                                                          52320013
DEE35B   LA    GR1,E1P1(0,GR1)         POINT GR1 AT BYTE CONTAINING     52350013
         BC    B,DEE35               'NO. OF PARAMS.'                   52380013
         SPACE 2                                                        52410013
*              HERE IT IS AN ENTRY TYPE 1 FROM AN ENTRY STATEMENT       52440013
         SPACE                                                          52470013
DEE35C   LA    GR1,E1E1(0,GR1)         POINT GR1 AT BYTE CONTAINING     52500013
         BC    B,DEE35               'NO. OF PARAMS'                    52530013
         SPACE 2                                                        52560013
*              HERE THE INTERNAL ENTRY LABEL IS MULTIPLY DECLARED.      52590013
         SPACE                                                          52620013
DEE35A   BAL   GRL,ERROR                                                52650013
         DC    X'0231C400'                                              52680013
         OI    CDFLAG(GRATCA),NODICT   INHIBIT MAKING OF DICT ENTRY     52710013
         BC    B,CDIC17                                                 52740013
         SPACE 2                                                        52770013
*              NOW WE DO SOME CHECKING OVER THE NUMBRR OF PARAMETERS.   52800013
         SPACE                                                          52830013
DEE35    L     GR2,COUNT1(0,GRATCA)    SET UP IN GR2, 'TWICE THE NUMBER 52860013
         AR    GR2,GR2               OF PARAMETERS.                     52890013
         TM    FLAGS(GRATCA),CFLAG2                                     52920013
         BC    BZ,DEE31                IF NO PARAMETERS, BRANCH.        52950013
         SPACE 2                                                        52980013
*              HERE THERE ARE SOME DECLARED PARAMETERS.                 53010013
         SPACE                                                          53040013
         MVI   E311(GRBILD),E311A      SET MARKER BYTE IN E3.           53070013
         STC   GR2,E312(0,GRBILD)      SET UP NO. IN BUILD AREA.        53100013
         CLC   E312(1,GRBILD),0(GR1)   COMPARE NUMBER OF DCLD. PARAMS   53130013
         BC    BE,DEE34              WITH NO. IN E1 (I.E. ON THE        53160013
*                                    INTERNAL ENTRY POINT).             53190013
         SPACE 2                                                        53220013
*              HERE A DIFFERENT NUMBER OF PARAMS. HAS BEEN DECLAEED     53250013
         SPACE                                                          53280013
         BAL   GRL,ERROR               GENERATE MESSAGE                 53310013
         DC    X'0232C400'                                              53340013
         SPACE 2                                                        53370013
*              NOW WE CHECK WHETHER THE NUMBER OF PARAMETERS IS WITHIN  53400013
*        THE IMPLEMENTATION LIMIT (64).                                 53430013
         SPACE                                                          53460013
DEE34    C     GR2,CD128                                                53490013
         BC    BLE,DEE36                                                53520013
         SPACE                                                          53550013
         BAL   GRL,ERROR               HERE THE NUMBER IS TOO LARGE.    53580013
         DC    X'022EC400'           GENERATE A MESSAGE AND TRUNCATE    53610013
         L     GR2,CD128             THE NUMBER.                        53640013
         SPACE 2                                                        53670013
         BC    B,DEE36                                                  53700013
*              HERE THERE WRER NO DECLARED PARAMETERS.                  53730013
         SPACE                                                          53760013
DEE31    MVI   E311(GRBILD),E311B      SET MARKER BYTE.                 53790013
         SR    GR2,GR2                                                  53820013
         IC    GR2,0(0,GR1)            FETCH NO. OF PARAMS FROM ENTRY   53850013
*                                    TYPE 1.                            53880013
         SPACE 2                                                        53910013
*              HERE THE CORRECT NO. OF PARAMETERS IS IN GR2             53940013
         SPACE                                                          53970013
DEE36    STC   GR2,E312(0,GRBILD)      SET UP THE NO. IN BUILD AREA     54000013
         LA    GRBILD,E313(GR2,GRBILD) BUMP GRBILD BEYOND PARAM         54030013
*                                    DESCRIPTIONS                       54060013
         MVC   E314(2,GRBILD),DCLNUM(GRATCA) SET UP DECLARE NUMBER      54090013
         LA    GRBILD,2(0,GRBILD)      BUMP GRBILD OVER DECLARE NUMBER  54120013
         SPACE 2                                                        54150013
*              NOW WE PUT THE ENTRY TYPE 3 INTO THE DICTIONARY          54180013
         SPACE                                                          54210013
         LA    GR2,BLDARA(0,GRATCA)                                     54240013
         ST    GR2,PAR1(0,GRDCPT)      POINT PAR1 AT START OF BUILD     54270013
*                                    AREA                               54300013
         SR    GRBILD,GR2                                               54330013
         ST    GRBILD,PAR2(0,GRDCPT)   SET UP LENGTH OF ENTRY IN PAR2   54360013
         STC   GRBILD,E32+1(0,GR2)   AND IN BUILD AREA                  54390013
         SPACE                                                          54420013
         L     GRL,ZDICRF(0,GRCP)      PUT THE ENTRY IN THE DICTIONARY  54450013
         BALR  GRR,GRL                                                  54480013
         SPACE                                                          54510013
*              NOW MOVE THE NEW DICT.REF. INTO THE ENTRY TYPE 2 (OLD),  54540013
*        AND INTO'DEE3X2'.                                              54570013
         SPACE                                                          54600013
         L     GR2,CADD2(0,GRATCA)                                      54630013
         MVC   E23(2,GR2),PAR1+2(GRDCPT)                                54660013
         MVC   DEE3X2(2),PAR1+2(GRDCPT)                                 54690013
         SPACE 2                                                        54720013
*              NOW WE COMPARE THE DATA TYPE OF THE NEW RETURNED VALUE   54750013
*        WITH THAT OF THE OLD ONE. WE DO THIS BY COMPARING THE EXISTING 54780013
*        ENTRY TYPE 2 WITH THE INFORMATION SET UP IN THE ATTRIBUTE      54810013
*        COLLECTION AREA.                                               54840013
         SPACE 2                                                        54870013
         CLC   E25(1,GR2),DATABT(GRATCA) COMPARE THE DATA BYTES         54900013
         BC    BNE,DEE33                                                54930013
         SPACE                                                          54960013
         SPACE 2                                                        54980015
*              DATA BYTES ARE THE SAME.  WE MUST NOW CHECK IF 'FIXED'   55000015
*        DATA INFORMATION AND 'PICTURE' REFS ARE, AS WELL.              55020015
         SPACE                                                          55040015
         CLC   E27(2,GR2),PICTAB(GRATCA) COMPARE 'PICTURE' DICT.REF.    55080013
         BC    BNE,DEE33                                                55110013
         SPACE                                                          55140013
         TM    DATABT(GRATCA),ADJLTH   IS THE 'NEW' RETURNED VALUE AN   55170013
         BC    BO,DEE33A             ADJUSTABLE LENGTH STRING.          55200013
         SPACE                                                          55207015
         CLC   E26(2,GR2),DATINF+1(GRATCA) COMPARE FIXED LENGTH DATA.   55214015
         BC    BNE,DEE33                                                55221015
         SPACE 2                                                        55230013
*              HERE THE DATA TYPES ARE THE SAME, AND SO WE DO NOT MAKE  55260013
*        A NEW ENTRY TYPE 2                                             55290013
         SPACE                                                          55320013
         BC    B,CDIC17                GO TO RETURN FROM CDICEN         55350013
         SPACE 2                                                        55380013
*              HERE WE MUST MAKE A NEW ENTRY TYPE 2, EITHER BECAUSE THE 55410013
*        DATA TYPES ARE DIFFERENT, OR BECAUSE THE NEW ONE IS AN         55440013
*        ADJUSTABLE LENGTH STRING.                                      55470013
         SPACE                                                          55500013
*              FIRST WE CLEAR THE BUILD AREA AND SET UP GRBILD.         55530013
         SPACE                                                          55560013
DEE33    BAL   GRL,ERROR               GENERATE WARNING MESSAGE.        55590013
         DC    X'023ACC00'                                              55620013
         SPACE                                                          55650013
DEE33A   OI    DCLATT+1(GRATCA),DIFRTV SET ON FLAG IN DCL ATT REG TO    55680013
*                                    SAY THAT A NEW ENTRY TYPE 2 HAS    55710013
*                                    BEEN CONSTRUCTED.                  55740013
         SPACE                                                          55770013
         LA    GRBILD,BLDARA(0,GRATCA)                                  55800013
         MVI   0(GRBILD),0                                              55830013
         MVC   1(BLDLTH,GRBILD),0(GRBILD)                          H344 55860019
         SPACE                                                          55890013
         MVI   E21(GRBILD),E2          SET UP CODE BYTE                 55920013
         MVC   E23(2,GRBILD),DEE3X2    SET UP DICT.REF.OF ENTRY TYPE 3  55950013
         MVC   E25(1,GRBILD),DATABT(GRATCA) SET UP DATA BYTE            55980013
         MVC   E26(5,GRBILD),DATINF+1(GRATCA)  SET  UP DATA INFORMATION 56010015
*                                           AND ANY PICTURE REFERENCE.  56040015
         SPACE                                                          56070013
         LA    GRBILD,E28(0,GRBILD)    BUMP GRBILD OVER THE ENTRY.      56100013
         SPACE 2                                                        56130013
*              LASTLY WE MUST ADJUST CADD2 TO POINT AT THE ENTRY TYPE 3 56160013
         SPACE                                                          56190013
         MVC   PAR1+2(2,GRDCPT),DEE3X2                                  56220013
         L     GRL,ZDRFAB(0,GRCP)                                       56250013
         BALR  GRR,GRL                                                  56280013
         SPACE                                                          56310013
         L     GR1,PAR1(0,GRDCPT)                                       56340013
         LA    GR1,E34-3(0,GR1)                                         56370013
         ST    GR1,CADD2(0,GRATCA)                                      56400013
         MVC   ZLOCK(2,GRDCPT),DEE3X2  LOCK IN BLOCK CONTAINING CADD2   56430013
         SPACE                                                          56460013
         SR    GR1,GR1                                                  56490013
         SPACE                                                          56520013
         BC    B,CDIC16                                                 56550013
         EJECT                                                          56580013
*              OFFSETS IN 'ENTRY TYPE 1' DICT ENTRY (FOR PROC/BEGIN     56610013
*        STATEMENTS).                                                   56640013
         SPACE 4                                                        56670013
E1P      EQU   X'80'                   CODE BYTE FOR PROC STATEMENT     56700013
E1B      EQU   X'81'                   CODE BYTE FOR BEGIN STATEMENT    56730013
E1P1     EQU   64                      OFFSET OF 'NO OF PARAMS' SLOT.   56760015
         EJECT                                                          56790013
*              OFFSETS IN 'ENTRY TYPE 1' DICT ENTRY (FOR ENTRY          56820013
*        STATEMENTS).                                                   56850013
         SPACE 4                                                        56880013
E1E      EQU   X'82'                   CODE BYTE                        56910013
E1E1     EQU   12                      OFFSET OF 'NO. OF PARAMS' SLOT   56940013
         EJECT                                                          56970013
*              OFFSETS IN AN 'ENTRY TYPE 2' DICT. ENTRY                 57000013
         SPACE 4                                                        57030013
E21      EQU   0                       CODE BYTE                        57060013
E22      EQU   E21+1                   LENGTH                           57090013
E23      EQU   E22+2                   DICT.REF. OF ENTRY TYPE 3        57120013
E24      EQU   E23+2                   OFFSET                           57150013
E25      EQU   E24+3                   DATA BYTE                        57180013
E26      EQU   E25+1                   DATA INFORMATION                 57210013
E27      EQU   E26+3                   DICT.REF OF PICTURE              57240013
E28      EQU   E27+2                   LENGTH OF ENTRY                  57270013
         EJECT                                                          57300013
*              OFFSETS IN AN 'ENTRY TYPE 3' DICTIONARY ENTRY            57330013
         SPACE 4                                                        57360013
E31      EQU   0                       CODE BYTE                        57390013
E32      EQU   E31+1                   LENGTH                           57420013
E33      EQU   E32+2                   DICT.REF.OF ENTRY TYPE 1         57450013
E34      EQU   E33+2                   DICT.REF.OF ENTRY TYPE 2         57480013
E35      EQU   E34+2                   OFFSET IN DSA                    57510013
E36      EQU   E35+3                   'ENTRY' CODE BYTE                57540013
E37      EQU   E36+1                   CHAIN (AUTOMATIC)                57570013
E38      EQU   E37+2                   SWITCH BYTES                     57600013
E39      EQU   E38+2                   SETS REFERENCE                   57630013
E310     EQU   E39+2                   DICT.REF.OF LABEL                57660013
E311     EQU   E310+2                  MARKER BYTE                      57690013
E311A    EQU   X'00'                   MARKER BYTE VALUE IF PARAMS      57720013
E311B    EQU   X'F0'                   MARKER BYTE VALUE IF NO PARAMS   57750013
E312     EQU   E311+1                  NUMBER OF PARAMS (*2).           57780013
E313     EQU   E312+1                  DICT.REF.OF FIRST PARAM.         57810013
         SPACE 2                                                        57840013
*              OFFSETS BEYOND PARAM. DESCRIPTIONS                       57870013
         SPACE                                                          57900013
E314     EQU   0                       DECLARE NUMBER                   57930013
         EJECT                                                          57960013
*              OFFSETS IN AN'ENTRY TYPE 4' DICTIONARY ENTRY             57990013
         SPACE 4                                                        58020013
E41      EQU   0                       CODE BYTE                        58050013
E42      EQU   E41+1                   LENGTH                           58080013
E43      EQU   E42+2                   CHAIN SLOT                       58110013
E44      EQU   E43+2                   OFFSET (STATIC)                  58140013
E45      EQU   E44+3                   OFFSET (DSA)                     58170013
E46      EQU   E45+3                   CHAIN (AUTOMATIC)                58200013
E47      EQU   E46+2                   'ENTRY' CODE BYTE                58230013
E48      EQU   E47+1                   'DATA' CODE BYTE                 58260013
E49      EQU   E48+1                   DATA INFORMATION                 58290013
E410     EQU   E49+3                   PICTURE REF.                     58320013
E411     EQU   E410+2                  SETS REF.                        58350013
E412     EQU   E411+2                  MARKER BYTE                      58380013
E413     EQU   E412+1                  NUMBER OF PARAMETERS (*2)        58410013
E414     EQU   E413+1                  DICT REFS. OF PARAM DESCRIPTIONS 58440013
         SPACE 2                                                        58470013
*              OFFSETS BEYOND PARAM DESCRIPTIONS.                       58500013
         SPACE                                                          58530013
E415     EQU   0                       DECLARE NUMBER                   58560013
E416     EQU   E415+2                  LEVEL                            58590013
E417     EQU   E416+1                  COUNT                            58620013
E418     EQU   E417+1                  BCD LENGTH - 1.                  58650013
E4A      EQU   X'00'                   MARKER BYTE VALUE (PARAMS)       58680013
E4B      EQU   X'FF'                   MARKER BYTE VALUE (NO PARAMS)    58710013
         EJECT                                                          58740013
*              OFFSETS IN A 'STRUCTURE, LABEL, OR FILE PARAMETER' DICT. 58770013
*        ENTRY                                                          58800013
         SPACE 4                                                        58830013
SLF0     EQU   0                       CODE BYTE                        58860013
SLF1     EQU   SLF0+1                  LENGTH                           58890013
SLF2     EQU   SLF1+2                  CHAIN                            58920013
SLF3     EQU   SLF2+2                  OFFSET                           58950013
SLF4     EQU   SLF3+3                  DECLARE NUMBER                   58980013
SLF5     EQU   SLF4+2                  OTHER1 BYTE                      59010013
SLF6     EQU   SLF5+1                  VARIABLE BYTE                    59040013
SLF7     EQU   SLF6+1                  OTHER2 BYTE                      59070013
SLF8     EQU   SLF7+1                  OTHER3 BYTE                      59100013
SLF9     EQU   SLF8+1                  OTHER4 BYTE                      59130013
SLF10    EQU   SLF9+1                  VARIABLE INFORMATION             59160013
         EJECT                                                          59190013
*              FORMAT OF A BUILTIN FUNCTION DICTIONARY ENTRY            59220013
         SPACE 5                                                        59250013
BLTOF1   EQU   3                       HASH CHAIN OFFSET                59280013
BLTOF2   EQU   8                       CODE BYTES OFFSET                59310013
BLTOF3   EQU   10                      DECLARE NUMBER OFFSET            59340013
         EJECT                                                          59370013
*              FORMAT OF GENERIC DICTIONARY ENTRY                       59400013
         SPACE 5                                                        59430013
GENOF1   EQU   3                       HASH CHAIN OFFSET                59460013
GENOF2   EQU   GENOF1+5                DECLARE NUMBER                   59490013
GENOF3   EQU   GENOF2+2                BYTE CONTAINING TWICE THE        59520013
*                                    NUMBER OF ITEMS IN THE GENERIC     59550013
*                                    LIST.                              59580013
         EJECT                                                          59610013
*              OFFSET IN A 'DATA ITEM' DICT.ENTRY.                      59640013
         SPACE 4                                                        59670013
DATA0    EQU   0                       CODE BYTE                        59700013
DATA1    EQU   DATA0+1                 LENGTH                           59730013
DATA2    EQU   DATA1+2                 CHAIN                            59760013
DATA3    EQU   DATA2+2                 OFFSET                           59790013
DATA4    EQU   DATA3+3                 DECLARE NUMBER                   59820013
DATA5    EQU   DATA4+2                 OTHER1 BYTE                      59850013
DATA6    EQU   DATA5+1                 VARIABLE BYTE                    59880013
DATA7    EQU   DATA6+1                 OTHER2 BYTE                      59910013
DATA8    EQU   DATA7+1                 OTHER3 BYTE                      59940013
DATA9    EQU   DATA8+1                 OTHER4 BYTE                      59970013
DATA10   EQU   DATA9+1                 DATA BYTE                        60000013
DATA11   EQU   DATA10+1                DATA INFORMATION                 60030013
DATA12   EQU   DATA11+3                SYMBOL SLOT                      60060013
DATA13   EQU   DATA12+2                VARIABLE INFORMATION             60090013
         SPACE 2                                                        60120013
         EJECT                                                          60150013
*              'FDIC1' ROUTINE.                                         60180013
         SPACE 4                                                        60210013
*              THIS ROUTINE BUILDS DICTIONARY ENTRIES FOR FILE          60240013
*        CONSTANTS.                                                     60270013
         SPACE 5                                                        60300013
FDIC1    MVI   FD1(BLDPTR),FLCNST      INSERT 'FILE CONSTANT' CODE BYTE 60330013
         MVC   FD1A(2,BLDPTR),CADD1(GRATCA) MOVE IN HASH CHAIN.         60360013
         MVC   FD2(2,BLDPTR),DCLNUM(GRATCA) MOVE IN DECLARE NUMBER,     60390013
         MVC   FD4(1,BLDPTR),OTHER2(GRATCA) OTHER2 CODE BYTE,           60420013
         MVC   FD5(2,BLDPTR),ENVIR(GRATCA)  DICTIONARY REFERENCE OF     60450013
*                                         ENVIRONMENT ENTRY.            60480013
         SPACE 2                                                        60510013
*              THE DICTIONARY ENTRY FOR THE FILE ATTRIBUTES HAS STILL   60540013
*        TO BE MADE. NONE IS MADE IF THE COUNT OF ATTRIBUTES IS ZERO.   60570013
*        IN THIS CASE THE SPACE FOR THE DICTIONARY REFERENCE IN THE     60600013
*        BUILD AREA WILL BE ZERO, AS IS REQUIRED. THEREFORE NOTHING     60630013
*        NEED BE MOVED IN.                                              60660013
         SPACE 2                                                        60690013
         L     SCRTCH,NOATTS(GRATCA)   PICK UP THE NUMBER OF ATTRIBUTES 60720013
         LTR   SCRTCH,SCRTCH                                            60750013
         BC    BZ,FDIC2                BRANCH IF THERE ARE ZERO.        60780013
         SPACE                                                          60810013
         LA    SCRTCH,3(SCRTCH)        GR1 NOW CONTAINS THE LENGTH OF   60840013
*                                    THE FILE ATTRIBUTES ENTRY          60870013
         ST    SCRTCH,PAR2(GRDCPT)     STORE THE LENGTH OF THE ENTRY    60900013
*                                    READY FOR THE INSERTION OF THE     60930013
*                                    ENTRY IN THE DICTIONARY, AND IN    60960013
         STH   SCRTCH,ATTENT+1(GRATCA) THE SKELETON.                    60990013
         MVI   ATTENT(GRATCA),X'C8'    INSERT LEADING CODE BYTE         61020013
         LA    SCRTCH,ATTENT(GRATCA)                                    61050013
         ST    SCRTCH,PAR1(GRDCPT)     POINT PAR1 AT COMPLETED SKELETON 61080013
         L     GRL,ZDICRF(GRCP)        LOAD ADDRESS OF ROUTINE TO       61110013
*                                    INSERT SKELETON IN DICTIONARY      61140013
         BALR  GRR,GRL                 BRANCH TO MAKE DICTIONARY ENTRY  61170013
         SPACE                                                          61200013
         MVC   FD3(2,BLDPTR),PAR1+2(GRDCPT) MOVE DICTIONARY REFERENCE   61230013
*                                    INTO BUILD AREA.                   61260013
FDIC2    LA    BLDPTR,FD6-FD1(BLDPTR)  BUMP BUILD POINTER TO POSITION   61290013
*                                    OF LEVEL AND COUNT.                61320013
         SPACE                                                          61350013
         MVC   0(2,BLDPTR),LEVEL(GRATCA) MOVE IN LEVEL AND COUNT        61380013
         LA    BLDPTR,2(0,BLDPTR)                                       61410013
         SPACE                                                          61440013
         BAL   GRR,BCDMVE              GO TO MOVE IN BCD.               61470013
         SPACE                                                          61500013
         BC    B,CDIC16                GO TO COMPLETE ENTRY.            61530013
         EJECT                                                          61560013
*              DESCRIPTION OF FILE DICTIONARY ENTRY                     61590013
         SPACE 3                                                        61620013
FLCNST   EQU   X'08'                   CODE BYTE FOR FILE CONSTANT.     61650013
FLPRM    EQU   X'89'                   CODE BYTE FOR FILE PARAMETER.    61680013
         SPACE 2                                                        61710013
FD1      EQU   0                       OFFSET OF INITIAL CODE BYTE      61740013
FD1A     EQU   FD1+3                   CHAIN                            61770013
FD2      EQU   FD1A+5                  DECLARE NUMBER                   61800013
FD3      EQU   FD2+2                   DICTIONARY REFERENCE OF          61830013
*                                    ATTRIBUTES ENTRY.                  61860013
FD4      EQU   FD3+2                   OTHER 2 CODE BYTE                61890013
FD5      EQU   FD4+1                   DICTIONARY REFERENCE OF          61920013
*                                    ENVIRONMENT ENTRY.                 61950013
FD6      EQU   FD5+2                   OFFSET OF LEVEL IN ENTRY         61980013
         SPACE 2                                                        62010013
*                                 END OF ENTRY                          62040013
         EJECT                                                          62070013
*              DESCRIPTION OF BUILT-IN FUNCTION ENTRY                   62100013
         SPACE 3                                                        62130013
BD1      EQU   0                       OFFSET OF INITIAL CODE BYTE      62160013
BD2      EQU   BD1+8                   OTHER 1 CODE BYTE                62190013
BD3      EQU   BD2+1                   OTHER 2 CODE BYTE                62220013
BD4      EQU   BD3+1                   DECLARE NUMBER                   62250013
BD5      EQU   BD4+2                   L                                62280013
         SPACE 2                                                        62310013
*                       END OF ENTRY                                    62340013
         EJECT                                                          62370013
*              ROUTINE 'CDFLT'.                                         62400013
         SPACE 4                                                        62430013
*              THIS ROUTINE FILLS IN THE DEFAULT ATTRIBUTES FOR AN      62460013
*        IDENTIFIER WHOSE DECLARED ATTRIBUTES DO NOT COMPLETELY DECIDE  62490013
*        ITS DATA TYPE.                                                 62520013
         SPACE 4                                                        62550013
*              THIS SECTION OF CODE DECIDES WHAT TYPE OF IDENTIFIER     62580013
*        THIS IS SO THAT WE KNOW WHAT DEFAULT CHARACTERISTICS WE MUST   62610013
*        EXAMINE.                                                       62640013
         SPACE                                                          62648019
CDFLT    TM    ASTFLG(GRATCA),X'FF'    IS CDFLT BEING CALLED BY   28459 62656019
*                                      'NCALD' IN IEMEL.          28459 62664019
         BC    BO,DF4A                 IF SO, GO TO 'ALIGNMENT'   28459 62672019
*                                    SECTION.                     28459 62680019
         STM   0,15,STM(GRATCA)                                   28459 62688019
         TM    DCLATT(GRATCA),GENBLT   IF IT IS PROG. GENERIC OR        62700013
         BC    BNZ,DF1               BUILT-IN FUNCTION, NO DEFAULTS.    62730013
         SPACE                                                          62760013
         TM    DCLATT(GRATCA),FILE     IF IT IS FILE, WE ONLY SUPPLY    62790013
         BC    BO,DF2                SCOPE   DEFAULTS.                  62820013
         SPACE                                                          62827015
         TM    DCLATT(GRATCA),STRUC    IF IT IS STRUCTURE, WE SUPPLY I1 62837016
         BC    BO,DF7              STORAGE CLASS AND SCOPE DEFAULTS  I1 62847016
         SPACE 1                                                     I1 62857016
*                                      *** SPACE SAVING CHANGES ***  I1 62867016
         LA    GRR,DF4                 SET REG. FOR BCR'S, TO DF4    I1 62877016
         SPACE 1                                                     I1 62887016
*        FOR TASK/EVENT OR LABEL, BRANCH TO SUPPLY DEFAULTS FOR      I1 62897016
*        ALIGNMENT, STORAGE CLASS, AND SCOPE.                        I1 62907016
         SPACE 1                                                     I1 62917016
         TM    DCLATT(GRATCA),TASKID+LABEL                           I1 62927016
         BCR   BNZ,GRR                                                  63000015
         SPACE                                                          63030015
         TM    DCLATT(GRATCA),DATA     HAVE DATA ATTRIBUTES BEEN DCLD.  63120013
         BC    BO,DF5                IF SO GO TO ANALYSE THEM.          63150013
         SPACE 4                                                        63180013
*              HERE WE KNOW THAT NO ATTRIBUTES WERE DECLARED, AND THE   63210013
*        IDENTIFIER IS BY DEFAULT A DATA ITEM.                          63240013
         OI    DCLATT(GRATCA),DATA                                      63270013
         SPACE                                                          63300013
DF6      TM    FLAGS(GRATCA),CFLAG1    DO THE IMPLICIT RULES OF 'I-N'   63330013
         BC    BZ,DF61               APPLY. IF NO,BRANCH.               63360013
         SPACE                                                          63390013
         OI    DATABT(GRATCA),BINDEC   SET UP 'FIXED BINARY REAL'.      63420013
         MVC   DATINF+1(2,GRATCA),PRSC1 AND DEFAULT PRECISION AND SCALE 63450013
*                                    FACTOR.                            63480013
         BCR   B,GRR                   GO TO APPLY DEFAULT ALIGNMENT    63510015
*                                    ATTRIBUTES.                        63540013
         SPACE                                                          63570013
*              HERE THE IMPLICIT RULES DO NOT APPLY.                    63600013
DF61     OI    DATABT(GRATCA),FLTFXD   SET UP 'FLOAT DECIMAL REAL'.     63630013
         MVC   DATINF+1(2,GRATCA),PRSC2 AND DEFAULT PRECISION AND SCALE 63660013
         BCR   B,GRR                   GO TO APPLY DEFAULT ALIGNMENT    63690015
*                                    ATTRIBUTES.                        63720013
         SPACE 4                                                        63750013
*              HERE THE IDENTIFIER HAS HAD DATA ATTRIBUTES APPLIED.     63780013
         SPACE                                                          63810013
DF5      TM    DCLATT+1(GRATCA),CADSTR IS IT CODED ARITH.DATA, RATHER   63840013
         BC    BO,DF51               THAN STRING.                       63870013
         TM    TESTMK+1(GRATCA),X'C0'  CHECK THAT CHAR OR BIT HAVE BEEN 63900013
         BCR   BNO,GRR               DECLARED. IF SO, GO TO SET DEFAULT 63930015
*                                    ALIGNMENT ATTS.                    63960013
         DC    H'0'                    OTHERWISE, COMPILER ERROR,       63990013
         SPACE                                                          64020013
*              HERE IT HAS BEEN DECLARED AS CAD.                        64050013
DF51     TM    DATABT(GRATCA),PINTER   IF A POINTER VARIABLE, DEFAULT   64080013
         BC    BNO,DF51A             IS FIXED BINARY.                   64110013
         OI    DATABT(GRATCA),BINDEC                                    64140013
         BCR   B,GRR                                                    64170015
         SPACE                                                          64200013
DF51A    TM    DATABT(GRATCA),NOPICT   HAS 'PICTURE' BEEN DECLARED. IF  64230013
         BCR   BZ,GRR                SO, GO TO GIVE ALIGMNENT DEFAULTS  64260015
         SPACE                                                          64290013
         TM    DCLATT+1(GRATCA),RSMBIT HAVE RADIX, SCALE OR MODE ATTS.  64320013
         BC    BZ,DF6                BEEN DECLARED, IF NOT GO TO SUPPLY 64350013
*                                    DEFAULT ONES.                      64380013
         SPACE                                                          64410013
*              HERE IT IS NOT A PICTURE                                 64440013
         TM    TESTMK(GRATCA),X'30'    HAVE FIXED/FLOAT BEEN DCLD, IF   64470013
         BC    BNO,DF52              NOT, WE SET THE DEFAULT AS FLOAT   64500013
         OI    DATABT(GRATCA),FLTFXD                                    64530013
DF55     TM    TESTMK+4(GRATCA),X'02'  HAS PRECISION BEEN DECLARED, IF  64560013
         BC    BO,DF54A              SO, GO TO SET DEFAULT, IF NOT,     64590013
         CLI   DATINF+1(GRATCA),0    WE CHECK FOR ZERO PRECISION.       64620013
         BC    BNE,DF53                                                 64650013
         BAL   GRL,ERROR               IF IT IS ZERO, GIVE A DIAGNOSTIC 64680013
         DC    X'0227C800'           AND SET UP DEFAULT VALUE.          64710013
         SPACE                                                          64740013
DF54A    TM    DATABT(GRATCA),BINDEC   IS IT BINARY                     64770013
         BC    BO,DF54                                                  64800013
         MVI   DATINF+1(GRATCA),6      FOR DECIMAL, SET UP DEFAULT      64830013
         BCR   B,GRR                                                    64860015
DF54     MVI   DATINF+1(GRATCA),21     FOR BINARY, SET UP DEFAULT       64890013
         BCR   B,GRR                                                    64920015
         SPACE                                                          64950013
*              HERE THERE HAS BEEN A FIXED/FLOAT DECLARATION            64980013
DF52     TM    DATABT(GRATCA),FLTFXD   IF IT IS FLOAT, GO BACK AND PUT  65010013
         BC    BO,DF55               IN THE DEFAULTS.                   65040013
         TM    TESTMK+4(GRATCA),X'03'  HERE IT IS FIXED. HAS PRECISION  65070013
         BC    BO,DF56               BEEN DECLARED. IF NOT, GO TO PUT   65100013
*                                    IN THE DEFAULTS                    65130013
         CLI   DATINF+1(GRATCA),0      IF ZERO PRECISION IS DECLARED,   65160013
         BC    BNE,DF52A             GIVE A DIAGNOSTIC AND SET UP THE   65190013
         BAL   GRL,ERROR             DEFAULT VALUE.                     65220013
         DC    X'0227C800'                                              65250013
         BC    B,DF56                                                   65280013
         SPACE                                                          65310013
DF52A    TM    CDFLAG(GRATCA),PREC1    WAS IT PRECISION1. IF NOT, GO TO 65340013
         BC    BNO,DF53              CHECK PRECISION, OTHERWISE, FIRST  65370013
         MVI   DATINF+2(GRATCA),X'80' PUT IN THE DEFAULT SCALING.       65400013
         BC    B,DF53                                                   65430013
         SPACE                                                          65460013
*              HERE IT IS FIXED, AND NO PRECISION IS DECLARED.          65490013
DF56     TM    DATABT(GRATCA),BINDEC   IS IT BINARY                     65520013
         BC    BO,DF58                                                  65550013
         MVC   DATINF+1(2,GRATCA),PRSC3 SET DEFAULT PRECISION AND SCALE 65580013
         BCR   B,GRR                 FOR DECIMAL, AND GO TO APPLY       65610015
*                                    ALIGNMENT DEFAULTS                 65640013
DF58     MVC   DATINF+1(2,GRATCA),PRSC1 SET DEFAULT PRECISION AND SCALE 65670013
         BCR   B,GRR                 FOR BINARY, THEN GO TO APPLY       65700015
*                                    ALIGNMENT DEFAULTS.                65730013
         SPACE                                                          65760013
*              HERE, PRECISION HAS BEEN DECLARED. WE SHALL SET THE      65790013
*        LONG/SHORT BIT APPROPRIATELY AND CHECK ALL PRECISIONS ARE      65820013
*        WITHIN IMPLEMENTATION LIMITS                                   65850013
DF53     TM    DATABT(GRATCA),BINDEC   IS IT BINARY OR DECIMAL          65880013
         BC    BNO,DF57                                                 65910013
         SPACE                                                          65940013
*              HERE IT IS BINARY                                        65970013
         CLI   DATINF+1(GRATCA),21     IS IT SHORT.               52204 66000064
         BCR   BLE,GRR                 IF SO, FINISH              52204 66030064
         OI    DATABT(GRATCA),LNGSHT   IF NOT SHORT, SET LONG BIT 52204 66060064
         TM    DATABT(GRATCA),FLTFXD   FIXED OR FLOAT                   66090013
         BC    BO,DF59                                                  66120013
         CLI   DATINF+1(GRATCA),31     CHECK THAT                 52184 66160064
         BCR   BLE,GRR               PRECISION IS WITHIN LIMITS. IF NOT 66180015
         MVI   DATINF+1(GRATCA),31   SPECIFY MAXIMUM.                   66210013
         BC    B,DF5A                                                   66240013
DF59     CLI   DATINF+1(GRATCA),53     CHECK THAT                 52204 66250064
         BCR   BLE,GRR               PRECISION IS WITHIN LIMITS. IF NOT 66300015
         MVI   DATINF+1(GRATCA),53   SPECIFY MAXIMUM.                   66330013
         BC    B,DF5A                                                   66360013
         SPACE                                                          66390013
*              HERE IT IS DECIMAL                                       66420013
DF57     CLI   DATINF+1(GRATCA),6      IS IT SHORT. IF SO, FINISH.      66450013
         BCR   BLE,GRR                                                  66480015
         OI    DATABT(GRATCA),LNGSHT   IF NOT SHORT, SET LONG BIT.      66510013
         TM    DATABT(GRATCA),FLTFXD   FIXED OR FLOAT                   66540013
         BC    BO,DF5B                                                  66570013
         CLI   DATINF+1(GRATCA),15     HERE IT IS FIXED. CHECK THAT     66600013
         BCR   BLE,GRR               PRECISION IS WITHIN LIMITS. IF NOT 66630015
         MVI   DATINF+1(GRATCA),15   SPECIFY MAXIMUM.                   66660013
         BC    B,DF5A                                                   66690013
DF5B     CLI   DATINF+1(GRATCA),16     HERE IT IS FLOAT. CHECK THAT     66720013
         BCR   BLE,GRR               PRECISION IS WITHIN LIMITS. IF NOT 66750015
         MVI   DATINF+1(GRATCA),16   SPECIFY MAXIMUM.                   66780013
         SPACE                                                          66810013
*              HERE THE PRECISION IS OUTSIDE THE MAXIMUM. GENERATE A    66840013
*        MESSAGE.                                                       66870013
DF5A     BAL   GRL,ERROR                                                66900013
         DC    X'0234C800'                                              66930013
         SPACE 4                                                        66960013
*              HERE THE CURRENT IDENTIFIER IS TO BE GIVEN DEFAULT       66990013
*        ALIGNMENT ATTRIBUTES.                                          67020013
         SPACE                                                          67050013
DF4      LA    GRR,DF7                 *****  RESET GRR  *****    28459 67080019
DF4A     TM    DCLATT+1(GRATCA),PCKD   HAVE PACKED/ALIGNED BEEN DCLD.   67110019
         BC    BO,DF47                 GO IF SO.                     I1 67140016
         SPACE 1                                                     I1 67170016
*        FOR STRUCTURE MEMBERS, PACKED/ALIGNED MAY BE INHERITED.     I1 67200016
         SPACE 1                                                     I1 67230016
         TM    VARBLE(GRATCA),MEMSTR   IS IT A STRUCTURE MEMBER      I1 67260016
         BC    BZ,DF43                 GO IF NOT                     I1 67290016
         L     GRCDT1,ACDT1(GRELB)     POINT GRCDT1 TO STRUCT. TABLE I1 67320016
         A     GRCDT1,COUNT1(GRATCA) ENTRY FOR CONTAINING STRUCT.    I1 67350016
         S     GRCDT1,CD4                                            I1 67380016
         TM    3(GRCDT1),X'02'         IS THERE PACKED/ALIGNED TO    I1 67410016
         BC    BZ,DF43               INHERIT - GO IF NOT             I1 67440016
         TM    3(GRCDT1),X'01'         IS IT ALIGNED                 I1 67470016
         BC    BO,DF41                 YES.                          I1 67500016
         SPACE 1                                                     I1 67530016
         TM    TESTMK+4(GRATCA),X'04'  IS 'PACKED' PERMITTED         I1 67560016
         BCR   BO,GRR                  YES.                          I1 67590016
         BAL   GRL,ERROR               NO - OUTPUT MESSAGE 'PACKED   I1 67620016
         DC    X'0C6DC800'           ATTRIBUTE IGNORED'              I1 67650016
DF41     OI    OTHER4(GRATCA),ALGPAK   SET 'ALIGNED' BIT IN OTHER4   I1 67680016
         TM    DATABT(GRATCA),CANSTR   AND IN DATA BYTE IF STRING.   I1 67710016
         BCR   BO,GRR                                                I1 67740016
         OI    DATABT(GRATCA),ALIGN                                  I1 67770016
         BCR   B,GRR                                                 I1 67800016
         SPACE 1                                                     I1 67830016
*        HERE PACKED/ALIGNED HAS NOT BEEN DECLARED OR INHERITED.     I1 67860016
*        WE GIVE THE DEFAULT 'PACKED' TO STRINGS, AND 'ALIGNED' TO   I1 67890016
*        ARITHMETIC AND OTHER DATA.                                  I1 67920016
         SPACE 1                                                     I1 67950016
DF43     TM    DATABT(GRATCA),CANSTR+AREA                            I1 67980016
         BC    BZ,DF44                 GO IF STRING                  I1 68010016
         TM    DATABT(GRATCA),NOPICT                              17.I1 68020017
         BCR   BZ,GRR                  OR PICTURE.                17.I1 68030017
         OI    OTHER4(GRATCA),ALGPAK                                 I1 68040016
         BCR   B,GRR                                                 I1 68070016
DF44     TM    VARBLE(GRATCA),DIMENS+MEMSTR   IS STRING IN AGGREGATE I1 68100016
         BC    BNZ,DF49                YES - ENSURE 'ALIGNED' BIT  H254 68120001
*                                          IN DATA BYTE IS NOT SET H254 68140001
         OI    DATABT(GRATCA),ALIGN    NO - SET DATA BYTE TO ALIGNED I1 68160016
         TM    DATABT(GRATCA),CHAR     IS IT BIT STRING              I1 68190016
         BCR   BO,GRR                  GO IF NOT.                    I1 68220016
         BC    B,DF48                  GO IF SO.                     I1 68250016
         SPACE 2                                                     I1 68280016
DF47     TM    OTHER4(GRATCA),ALGPAK   WAS IT 'ALIGNED'              I1 68310016
         BCR   BO,GRR                  YES.                          I1 68340016
         TM    DATABT(GRATCA),CANSTR+AREA        IS IT A STRING    H254 68360001
         BCR   BNZ,GRR                 GO IF NOT                   H254 68380001
         BC    B,DF44                  YES. CHECK IF IN AGGREGATE  H254 68400001
         SPACE 1                                                     I1 68430016
*              HERE WE HAVE A BIT STRING (NOT IN AN AGGREGATE).  WE  I1 68460016
*        MUST RESET THE 'ALIGNED' BIT IN THE DATA BYTE IF IT IS      I1 68490016
*        DEFINED OR FORMAL PARAMETER.                                I1 68520016
         SPACE 1                                                     I1 68550016
DF48     TM    OTHER2(GRATCA),FMPRAM   IS IT FORMAL PARAMETER        I1 68580016
         BC    BO,DF49                 YES.                          I1 68610016
         TM    VARBLE(GRATCA),DEFND    IS IT DEFINED                 I1 68640016
         BCR   BZ,GRR                  NO.                           I1 68670016
DF49     NI    DATABT(GRATCA),PACK     RESET 'ALIGNED' BIT           I1 68700016
         BCR   B,GRR                                              28459 68770019
         SPACE 4                                                        68850013
*              HERE THE CURRENT IDENTIFIER IS TO BE GIVEN DEFAULT       68880013
*        STORAGE CLASS ATTRIBUTES.                                      68910013
         SPACE                                                          68940013
DF7      TM    TESTMK+1(GRATCA),X'03'  IF NO STORAGE CLASS ATTRIBUTES   68970013
         LA    GRR,DF1                 *****  FINAL GRR RESET  *****    68980015
         BC    BNZ,DF74              ARE APPLICABLE, LEAVE THIS SECTION 69000013
         TM    TESTMK+2(GRATCA),X'80'                                   69030013
         BCR   BZ,GRR                                                   69060015
         SPACE                                                          69090013
*              WE DECIDE WHETHER STORAGE CLASS HAS BEEN DECLARED, IF IT 69120013
*        HAS, FINISH.                                                   69150013
DF74     TM    TESTMK+1(GRATCA),X'02'  IS STATIC ACCEPTABLE. IF NOT,    69180013
         BC    BNO,DF72              TEST WE HAVE NOT HAD EXTERNAL.     69210013
         TM    OTHER2(GRATCA),EXTINT   HAS EXTERNAL BEEN DCLD. IF SO,   69240013
         BC    BO,DF71               GO TO SET STATIC DEFAULT.          69270013
         TM    TESTMK+2(GRATCA),X'80'  IS CONTROLLED ACCEPTABLE. IF NOT 69300013
         BCR   BNO,GRR               FINISH.                            69330015
         SPACE                                                          69360013
DF73     NI    OTHER2(GRATCA),NAUTO    SET DEFAULT TO AUTOMATIC.        69390013
         BCR   B,GRR                                                    69420015
DF71     OI    OTHER2(GRATCA),STATIC   IF IT HAS, SET DEFAULT TO STATIC 69450013
         BCR   B,GRR                                                    69480015
         SPACE                                                          69510013
DF72     TM    OTHER2(GRATCA),EXTINT                                    69540013
         BCR   BZ,GRR                                                   69570015
         TM    OTHER2(GRATCA),CNTRLD                                    69600013
         BCR   BO,GRR                                                   69630015
         NI    OTHER2(GRATCA),INTEXT                                    69660013
         BAL   GRL,ERROR                                                69690013
         DC    X'0229C800'                                              69720013
         BC    B,DF73                                                   69750013
         SPACE 4                                                        69780013
*              HERE THE CURRENT IDENTIFIER IS A FILE AND ITS DEFAULT    69810013
*        SCOPE IS EXTERNAL.                                             69840013
         SPACE                                                          69870013
DF2      TM    TESTMK+1(GRATCA),X'0C'  HAVE SCOPE ATTRIBUTES BEEN       69900013
         BC    BNO,DF1               DECLARED. IF NOT, SET DEFAULT TO   69930013
         OI    OTHER2(GRATCA),EXTINT EXTERNAL.                          69960013
         SPACE 4                                                        69990013
*              NOW TEST IF THE IDENTIFIER IS AN ENTRY NEEDING DEFAULT   69994015
*        FOR REDUCIBLE/IRREDUCIBLE                                      69998015
         SPACE                                                          70002015
DF1      TM    DCLATT(GRATCA),NTRY     IS IT ENTRY                      70006015
         BC    BZ,DF1A                 - GO IF NOT                      70010015
         TM    ENTRY(GRATCA),RDCBLE+IRREDC   HAS (IR)RED BEEN SET       70014015
         BC    BNZ,DF1A                - GO IF SO                       70018015
         SPACE                                                          70022015
*              HERE A DEFAULT MUST BE APPLIED.  THIS WILL BE            70026015
*        'IRREDUCIBLE'.                                                 70036019
         SPACE                                                          70046019
DF11     OI    ENTRY(GRATCA),IRREDC    SET 'IRREDUCIBLE' BIT            70058015
         SPACE                                                          70062015
*              HERE WE HAVE FINISHED SETTING THE DEFAULT ATTRIBUTES     70066015
         SPACE 1                                                        70070015
DF1A     LM    0,15,STM(GRATCA)        RESTORE REGISTERS                70074015
         BCR   BR,GRR                  RETURN.                          70080013
         EJECT                                                          70110013
*              DATA AREA FOR ROUTINE CDFLT.                             70140013
         SPACE 4                                                        70170013
PRSC1    DC    X'0F80'                 DEFAULT PRECISION AND SCALE      70200013
*                                    FACTOR FOR 'FIXED BINARY'.         70230013
PRSC2    DC    X'0600'                 DEFAULT PRECISION AND SCALE      70260013
*                                    FACTOR FOR 'FLOAT DECIMAL'.        70290013
PRSC3    DC    X'0580'                 DEFAULT PRECISION AND SCALE      70320013
*                                    FACTOR FOR 'FIXED DECIMAL'.        70350013
         EJECT                                                          70380013
*              IMPLICIT ATTRIBUTES ROUTINE, IMPATT                      70410013
         SPACE 1                                                        70440013
         SPACE 2                                                        70470013
*              THIS ROUTINE TESTS THE FIRST LETTER OF THE IDENTIFIER    70500013
*        TO TELL WHETHER ITS DEFAULT (IF ANY) SHOULD BE FIXED RATHER    70530013
*        THAN FLOAT.                                                    70560013
         SPACE 4                                                        70590013
IMPATT   MVC   PAR1+1(3,GRDCPT),BCDTRF+1(GRATCA)                        70620013
         OI    PAR1(GRDCPT),X'80'      ENSURE STATUS OF BLOCK     32270 70630020
*                                    CONTAINING BCD IS NOT CHANGED.     70640020
         LR    GRL,GRR                                                  70650013
         L     GRR,ZTXTAB(0,GRCP)                                       70680013
         BALR  GRR,GRR                                                  70710013
         L     GR1,PAR1(0,GRDCPT)                                       70740013
         NI    PAR1(GRDCPT),X'7F'                                 32270 70750020
         SPACE                                                          70770013
         CLI   1(GR1),CDXI                                              70800013
         BCR   BL,GRL                                                   70830013
         CLI   1(GR1),CDXN                                              70860013
         BCR   BH,GRL                                                   70890013
         CLI   1(GR1),X'1F'                                             70920013
         BCR   BE,GRL                                                   70950013
         CLI   1(GR1),X'20'                                             70980013
         BCR   BE,GRL                                                   71010013
         SPACE                                                          71040013
         OI    FLAGS(GRATCA),CFLAG1                                     71070013
         BCR   BR,GRL                                                   71100013
         SPACE 4                                                        71130013
         SPACE 4                                                        71160013
         EJECT                                                          71190013
*              FACTORED ATTRIBUTES ROUTINE, CDFATT                      71220013
         SPACE 4                                                        71250013
*              THIS ROUTINE IS CALLED WHEN A FACTOR BRACKET HAS BEEN    71280013
*        ENCOUNTERED IN THE TEXT                                        71310013
         SPACE 2                                                        71340013
*              WE USE GR1 TO SCAN THE FACTORED ATTRIBUTE TABLE (WHICH   71370013
*        WAS SET UP BY DCL 1).                                          71400013
         SPACE                                                          71430013
CDFATT   ST    GRR,COPYST                                               71460013
         L     GR1,CURENT(0,GRELB)     SET GR1 TO THE ENTRY IN THE      71490013
*                                    TABLE WHICH CORRESPONDS TO THE     71520013
*                                    CURRENT LEVEL OF FACTORING.        71550013
         SPACE 2                                                        71580013
*              NOW PICK UP FROM THE CURRENT TABLE ENTRY THE TEXT REF.   71610013
*        OF THE LIST OF ATTRIBUTES IN THE TEXT WHICH CORRESPOND TO THE  71640013
*        CURRENT LEVEL OF FACTORING.                                    71670013
         SPACE                                                          71700013
FATT7    MVC   PAR1+1(3,GRDCPT),1(GR1) MOVE IT INTO PAR1                71730013
         SPACE                                                          71760013
         SPACE                                                          71790013
         L     GRL,ZTXTAB(0,GRCP)      BRANCH AND LINK TO ZTXTAB        71820013
         BALR  GRR,GRL               ROUTINE (COMPILER CONTROL) TO      71850013
*                                    CONVERT THE REF TO ABSOLUTE        71880013
*                                    ADDRESS                            71910013
         SPACE                                                          71940013
         L     GRATPO,PAR1(0,GRDCPT)   POINT GRATPO AT THE ATTRIBUTE    71970013
*                                    LIST                               72000013
         SPACE 2                                                        72030013
*              NOW WE SCAN THE ATTRIBUTE LIST IN THE TEXT               72060013
         SPACE                                                          72090013
FATT6    CLI   0(GRATPO),ATTMKR        IS THIS AN ATTRIBUTE MARKER      72120013
         BC    BE,FATT3                                                 72150013
         SPACE                                                          72180013
         CLI   0(GRATPO),X'00'         IS THIS A ZERO BYTE              72210013
         BC    BE,FATT10                                                72240013
         SPACE                                                          72270013
FATT12   CLI   0(GRATPO),COMMA         IS IT A COMMA                    72300013
         BC    BE,FATT4                                                 72330013
         SPACE                                                          72360013
         CLI   0(GRATPO),ENDBLK        IS IT AN END OF BLOCK MARKER.    72390013
         BC    BE,FATT4              DO AS FOR COMMA.                   72420013
         SPACE                                                          72450013
         CLI   0(GRATPO),RFBRKT        IS THIS A RIGHT FACTOR BRACKET   72480013
         BC    BE,FATT4                                                 72510013
         SPACE                                                          72540013
         CLI   0(GRATPO),SEMCLN        IS THIS A SEMICOLON              72570013
         BC    BE,FATT5                                                 72600013
         SPACE 2                                                        72630013
*              IF IT IS NONE OF THESE, COMPILER ERROR, DUMP.            72660013
         DC    X'0000'                 INTERRUPT                        72690013
         SPACE 2                                                        72720013
*              HERE GRATPO POINTS AT AN ATTRIBUTE MARKER                72750013
FATT3    ST    GR1,TMFWST                                               72780013
         SPACE                                                          72810013
         BAL   GRR,CDATPR(GRECB)                                        72840013
         SPACE                                                          72870013
         NI    FLAGS+1(GRATCA),NFLA12  SET OFF CFLAG12                  72900013
         SPACE                                                          72930013
         L     GR1,TMFWST                                               72960013
         BC    B,FATT6                                                  72990013
         SPACE 2                                                        73020013
*              HERE GRATPO POINTS AT A COMMA                            73050013
         SPACE                                                          73080013
FATT4    MVC   CDTEMP+1(3),4(GR1)      SET UP IN GR1 THE POINTER TO     73110013
         L     GR1,CDTEMP            NEXT ENTRY IN TABLE                73140013
         SPACE                                                          73170013
         CLC   CDTEMP+1(3),STPPR+1     IS IT A STOPPER, I.E. HAVE WE    73200013
         BC    BNE,FATT7             REACHED ZERO LEVEL OF FACTORING    73230013
         SPACE                                                          73260013
FATT5    L     GRR,COPYST              RELOAD LINK AND RETURN.          73290013
         BCR   BR,GRR                                                   73320013
         SPACE 4                                                        73350013
         SPACE 2                                                        73380013
         SPACE 2                                                        73410013
*              HERE GRATPO POINTS AT A ZERO BYTE.                       73440013
         SPACE                                                          73470013
FATT10   LA    GRATPO,1(GRATPO)        BUMP GRATPO BY ONE, AND GO TO    73500013
         BC    B,FATT6               CONTINUE THE SCAN.                 73530013
         SPACE 2                                                        73560013
         EJECT                                                          73590013
*              DATA AREA FOR CDFATT ROUTINE                             73620013
         SPACE 2                                                        73650013
STPPR    DC    X'00FFFFFF'             STOPPER IN FACTORED ATT. TABLE   73680013
         EJECT                                                          73710013
*              THE ROUTINE MVTXT                                        73740013
         SPACE 4                                                        73770013
*              THIS ROUTINE MOVES A LENGTH OF TEXT STARTING AT THE      73800013
*        ADDRESS IN GR1, FOR A LENGTH GIVEN BY GR2. THE COPIED TEXT     73830013
*        WILL START AT THE TEXT REFERENCE IN THE SLOT 'ZNXTLC', UNLESS  73860013
*        THE LENGTH OF TEXT IS LONGER THAN THE SPACE AVAILABLE IN THE   73890013
*        CURRENT TEXT BLOCK. IN THIS CASE THE TEXT IS COPIED INTO THE   73920013
*        NEXT AVAILABLE BLOCK. ON EXIT FROM THIS ROUTINE, ALL TEXT      73950013
*        BLOCKS EXCEPT THE CURRENT DECLARE BLOCK WILL BE UNWANTED OR    73980013
*        FREE.                                                          74010013
         SPACE 4                                                        74040013
MVTXT    ST    GRR,TMFWST              SAVE RETURN REGISTER             74070013
         SPACE                                                          74100013
         LH    GRR,ZBLSIZ+2(0,GRDCPT)  BRANCH IF TEXT TO BE MOVED WILL  74130013
         SH    GRR,ZNXTLC+2(0,GRDCPT) GO IN CURRENT BLOCK.              74160013
         SR    GRR,GR2                                                  74190013
         BC    BP,MV1                                                   74220013
         SPACE                                                          74250013
         MVC   PAR1+1(3,GRDCPT),ZNXTLC+1(GRDCPT)  SET LAST BYTE OF OLD  74280013
         L     GRL,ZTXTAB(0,GRCP)    BLOCK WITH END OF TEXT BLOCK       74310013
         BALR  GRR,GRL               MARKER.                            74340013
         L     GRL,PAR1(0,GRDCPT)                                       74370013
         MVI   0(GRL),ETB                                               74400013
         SPACE                                                          74430013
         MVI   PAR2+3(GRDCPT),X'82'   SPECIFY THAT OLD BLOCK MUST BE    74460013
*                                    CHAINED AND MARKED UNWANTED.       74490013
         CLC   ZNXTLC+1(1,GRDCPT),DCBLK1+1          IF OLD BLOCK IS     74520013
         BC    BNE,MV2               SAME AS THAT OF THE DECLARE, MARK  74550013
         MVI   PAR2+3(GRDCPT),X'84'  IT BUSY.                           74580013
MV2      MVC   PAR1+1(1,GRDCPT),ZNXTLC+1(GRDCPT)                        74610013
         L     GRL,ZUTXTC(0,GRCP)     GET NEW BLOCK.                    74640013
         BALR  GRR,GRL                                                  74670013
         L     GRR,PAR1(0,GRDCPT)     UPDATE ZNXTLC.                    74700013
         BC    B,MV1A                                                   74730013
MV1      L     GRR,ZNXTLC(0,GRDCPT)    UPDATE ZNXTLC.                   74760013
MV1A     LA    GRL,5(0,GRR)            SET CALL CHAIN REFERENCE.        74790013
         ST    GRL,NEWTRF                                               74820013
         ST    GRR,PAR1(0,GRDCPT)                                       74850013
         LA    GRR,1(GR2,GRR)                                           74880013
         ST    GRR,ZNXTLC(0,GRDCPT)                                     74910013
         L     GRL,ZTXTAB(0,GRCP)                                       74940013
         BALR  GRR,GRL                                                  74970013
         L     GRL,PAR1(0,GRDCPT)      SET UP GRL.                      75000013
         ST    GRL,STATAD                                               75030013
MV3      LR    GR3,GR2                 SET UP IN GR3 THE NUMBER OF 256  75060013
         SRL   GR3,8                 SECTIONS TO BE MOVED.              75090013
         LTR   GR3,GR3                                                  75120013
         BC    BZ,MV4                  BRANCH IF NONE.                  75150013
MV5      MVC   0(256,GRL),0(GR1)       MOVE 256.                        75180013
         LA    GR1,256(0,GR1)          BUMP BOTH POINTERS.              75210013
         LA    GRL,256(0,GRL)                                           75240013
         BCT   GR3,MV5                                                  75270013
         SPACE                                                          75300013
MV4      STC   GR2,MV6+1               PUT THE REMAINING AMOUNT IN      75330013
MV6      MVC   0(0,GRL),0(GR1)       LENGTH BYTE AND MOVE IT.           75360013
         SPACE                                                          75390013
         STC   GR2,MV7+3               PUT IN END OF PROGRAM MARKER.    75420013
MV7      LA    GRL,0(0,GRL)                                             75450013
         MVI   1(GRL),EOP                                               75480013
         SPACE                                                          75510013
         CLC   ZNXTLC+1(1,GRDCPT),DCBLK1+1        IF THE NEW BLOCK IS   75540013
         BC    BE,MV8                             DIFFERENT FROM THE    75570013
         MVC   PAR1+1(3,GRDCPT),ZNXTLC+1(GRDCPT)  DECLARE BLOCK, MARK   75600013
         MVI   PAR2+3(GRDCPT),X'02'               IT UNWANTED.          75630013
         L     GRL,ZALTER(0,GRCP)                                       75660013
         BALR  GRR,GRL                                                  75690013
         SPACE                                                          75720013
MV8      L     GRR,TMFWST              RELOAD GRR.                      75750013
         BCR   BR,GRR                  RETURN.                          75780013
         EJECT                                                          75810013
*                       ROUTINE CHASH                                   75840013
*                                                                       75870013
*              FUNCTION/OPERATION.  THIS ROUTINE DERIVES A FUNCTION     75900013
*        FROM THE BCD PASSED TO IT.  THE FUNCTION IS LESS THAN 422      75930013
*        AND IS EVEN. IT IS TO BE USED AS AN OFFSET IN THE HASH TABLE   75960013
*        GIVING THE HEAD OF THE HASH CHAIN LINKING BCD'S WITH THE SAME  75990013
*        HASH FUNCTION.                                                 76020013
*                                   THE FUNCTION IS OBTAINED BY EXTEND- 76050013
*        ING THE BCD WITH ZEROES UNTIL A MULTIPLE OF 4 BYTES LONG, THEN 76080013
*        ADDING 4 BYTE LENGTHS.  THE SUM IS DIVIDED BY 211.  THE        76110013
*        REMAINDER IS SET POSITIVE AND DOUBLED TO GIVE THE HASH RESULT  76140013
*        WHICH IS RETURNED.                                             76170013
*                                  THE CALLING SEQUENCE IS -            76200013
*        BAL   GRRR,CHASH   (SEE NOTES)                                 76230013
*                                  THE ROUTINE IS ENTERED WITH -        76260013
*              (1) GRPTR POINTER TO BCD TO BE HASHED.                   76290013
*              (2) GRLTH CONTAINING LENGTH-1 OF THE BCD                 76320013
*              THESE REGISTERS ARE RETURNED UNALTERED.                  76350013
*                                                                       76380013
*              EXTERNAL ROUTINES - NONE.                                76410013
*                                                                       76440013
*              EXITS NORMAL - UNCONDITIONAL BRANCH ON RETURN REGISTER.  76470013
*                                                                       76500013
*              EXITS ERROR - NONE                                       76530013
*                                                                       76560013
*              TABLES/WORK AREAS.  A WORKSPACE CASPAC 32 BYTES LONG,    76590013
*        AND FULL WORD ALIGNED IS REQUIRED. THE BCD IS MOVED INTO IT    76620013
*        FOR FULL WORD ALIGNMENT AND FOR EXTENDING WITH ZEROES          76650013
*                                  A FULL WORD CONSTANT T11, VALUE 211, 76680013
*        IS ALSO REQUIRED.                                              76710013
*                                                                       76740013
*              NOTES.  THE RETURN REGISTER MUST BE SET UP BY A 'BRANCH  76770013
*        AND LINK' INSTRUCTION, SINCE THE PROGRAM MASK IS REQUIRED IN   76800013
*        THE TOP BYTE.                                                  76830013
*                      REGISTERS GRX, AND GRY ARE REQUIRED FOR WORKING  76860013
*        AND THEIR ORIGIONAL CONTENTS ARE LOST.                         76890013
*                      REGISTERS GRX,GRY AND GRLTH,GRHASH ARE REQUIRED  76920013
*        TO BE EVEN ODD REGISTER PAIRS.                                 76950013
         SPACE 5                                                        76980013
CHASH    SR    GRY,GRY                                                  77010013
         SPM   GRY                     INHIBIT FIXED POINT OVERFLOW     77040013
*                                    INTERRUPTS DURING LOOP 'CARED'     77070013
*                                    BELOW.                             77100013
         LA    GRHASH,4                FOUR REQUIRED IN GRHASH, NOW AND 77130013
         LCR   GRX,GRHASH            LATER. SET GRX TO ONES IN ALL BITS 77160013
*                                    EXCEPT THE LAST TWO.               77190013
         NR    GRX,GRLTH               LENGTH-1 LESS LAST TWO BITS INTO 77220013
*                                    GRX                                77250013
         ST    GRY,CASPAC(GRX,GRATCA)  CLEAR FOUR BYTES IN CASPAC AT    77280013
*                                    OFFSET EQUAL TO FIRST FULL WORD    77310013
*                                    SHORT OF END OF BCD WHEN IT IS     77340013
*                                    MOVED INTO CASPAC.                 77370013
         EX    GRLTH,CAH1              MOVE BCD INTO CASPAC.            77400013
         SPACE                                                          77430013
*              THE BCD IS NOW IN CASPAC AND IS EXTENDED TO A FULL WORD  77460013
*        BOUNDARY WITH ZEROS.                                           77490013
         SPACE                                                          77520013
         SR    GRX,GRX                                                  77550013
CARED    A     GRY,CASPAC(GRX,GRATCA)  THIS LOOP ADDS FOUR BYTE LENGTHS 77580013
         BXLE  GRX,GRHASH,CARED      OF THE BCD INTO GRY UNTIL ALL IS   77610013
*                                    CONSUMED                           77640013
         SPACE                                                          77670013
         SR    GRX,GRX                                                  77700013
         D     GRX,T11                 DIVIDE SUM BY 211                77730013
         SPACE                                                          77760013
         LPR   GRHASH,GRX              SET REMAINDER POSITIVE           77790013
         AR    GRHASH,GRHASH           DOUBLE IT.                       77820013
         SPACE                                                          77850013
         SPM   GRRR                    RESET PROGRAM MASK               77880013
         BCR   B,GRRR                  RETURN                           77910013
         SPACE                                                          77940013
CAH1     MVC   CASPAC(0,GRATCA),0(GRPTR) MOVE IN BCD.                   77970013
         EJECT                                                          78000013
*              ERROR ROUTINE                                            78030013
         SPACE 4                                                        78060013
*              THIS ROUTINE HANDLES ALL CALLS TO THE COMPILER CONTROL   78090013
*        ERROR ROUTINE, 'ZUERR'.                                        78120013
*              THIS ROUTINE EXPECTS THAT                                78150013
         SPACE                                                          78180013
*              1. 'ZSTAT' CONTAINS THE CURRENT STATEMENT NUMBER.        78210013
         SPACE                                                          78240013
*              2. 'PAR7' CONTAINS THE ABSOLUTE ADDRESS OF THE BCD       78270013
         SPACE                                                          78300013
*              3. 'PAR8' CONTAINS THE BCD LENGTH                        78330013
         SPACE                                                          78360013
*              4. THE CALLING SEQUENCE IS OF THIS FORM                  78390013
         SPACE                                                          78420013
*        BAL   GRL,ERROR                                                78450013
*        DC    X'PPQQRR00'                                              78480013
         SPACE                                                          78510013
*              WHERE X'PPQQ' IS THE NUMBER OF THE DIAGNOSTIC, AND X'RR' 78540013
*        IS THE 'SUPPLY' CODE BYTE.                                     78570013
         SPACE 4                                                        78600013
ERROR    STM   GRR,GR3,CASPAC(GRATCA)  SAVE REGISTERS USED.             78630013
         SPACE                                                          78660013
         MVC   PAR6+1(3,GRDCPT),0(GRL) SET UP PAR6.                     78690013
         SPACE                                                          78720013
         LA    GR3,SCR1+1(0,GRATCA)    PICK UP TXT REF OF BCD LENGTH    78740015
*                                    BYTE FROM SCRATCH SLOT SET IN EL   78760015
         MVC   PAR1+1(3,GRDCPT),0(GR3)                                  78780013
         L     GRL,ZTXTAB(0,GRCP)                                       78810013
         BALR  GRR,GRL                                                  78840013
         L     GR1,PAR1(0,GRDCPT)                                       78870013
         LA    GR1,1(0,GR1)                                             78900013
         BAL   GRR,UNWANT(0,GRELB)     GO TO UNWANT THE BLOCK IF NEC.   78930013
         L     GR2,TMPAR8                                               78960013
         SPACE                                                          78990013
         STM   GR1,GR2,PAR7(GRDCPT)                                     79020013
         SPACE                                                          79050013
         L     GRL,ZUERR(0,GRCP)       GO TO CREATE AN ERROR MESSAGE    79080013
         BALR  GRR,GRL               DICT. ENTRY.                       79110013
         SPACE                                                          79140013
         LM    GRR,GR3,CASPAC(GRATCA)  RELOAD REGISTERS AND RETURN.     79170013
         BC    B,4(0,GRL)                                               79200013
         EJECT                                                          79230013
*              LABEL DEFINITIONS                                        79260013
         SPACE 2                                                        79290013
CDTEMP   DS    F                                                        79320013
TMFWST   DC    F'0'                                                     79350013
STATAD   DC    F'0'                                                     79410013
NEWTRF   DC    F'0'                                                     79440013
T11      DC    F'211'                                                   79470013
CD64     DC    F'64'                                                    79560013
CD128    DC    F'128'                                                   79590013
DEE3X1   DC    H'0'                    STORAGE FOR DICT REFS.           79620013
ENTREF   DC    H'0'                    SLOT FOR REF OF CURRENT 'INITIAL 79650013
*                                    DICT ENTRY (OR CONTINUATION).      79680013
SLOTRF   DC    H'0'                    SLOT FOR REF OF SLOT WHICH IS TO 79710013
*                                    POINT AT COPY OF CONTINUATION      79740013
*                                    'INITIAL' DICT ENTRY.              79770013
TMPH     DC    H'0'                                                     79800013
ENDCHN   EQU   STPPR+1                 CHAIN STOPPER                    79830013
FLAGBT   DC    X'00'                                                    79860013
TYPESW   DC    X'00'                                                    79890013
STRALG   DC    X'00'                   COPY OF 'OTHER4' CODE BYTE, USED 79920013
*                                    FOR INHERITING PACKED/ALIGNED IN   79950013
*                                    STRUCTURES.                        79980013
FLAG     DC    X'00'                   FLAG BYTE FOR 'INITIAL' POST-    80010013
*                                    PROCESSER.                         80040013
COPY     EQU   X'80'                   FLAG MEANING THAT COPYING OF     80070013
*                                    'INITIAL' DICT ENTRIES IS BEING    80100013
*                                    DONE.                              80130013
COPYST   DC    10F'0'                                                   80140015
         SPACE 4                                                        80160013
*              BASIC REGISTER SYMBOLS                                   80190013
         SPACE 1                                                        80220013
GR0      EQU   0                       UTILITY REGISTER                 80250013
GR1      EQU   1                       UTILITY REGISTER                 80280013
GR2      EQU   2                       UTILITY REGISTER                 80310013
GRATCA   EQU   4                       POINTER TO HEAD OF ATT.COLL.AREA 80340013
GR3      EQU   3                       UTILITY REGISTER                 80370013
GR5      EQU   1                       UTILITY REGISTER                 80400013
GRCDT1   EQU   5                       STRUCTURE TABLE POINTER          80430013
GRSCAN   EQU   7                       TEXT SCAN POINTER                80460013
GRATPO   EQU   8                       ATTRIBUTE POINTER                80490013
GRELB    EQU   9                       BASE REGISTER FOR EL BLOCK       80520013
GRECB    EQU   10                      BASE REGISTER FOR EC BLOCK       80550013
GREKB    EQU   10                                                       80580013
GRCP     EQU   11                      POINTER TO HEAD OF CONTROL PHASE 80610013
GREMB    EQU   12                      BASE REGISTER FOR EM BLOCK       80640013
GRDCPT   EQU   13                      POINTER TO HEAD OF DICTIONARY    80670013
GRR      EQU   14                      RETURN REGISTER                  80700013
GRL      EQU   15                      LINK REGISTER                    80730013
         SPACE 2                                                        80760013
*              OTHER REGISTER SYMBOLS                                   80790013
         SPACE 1                                                        80820013
GR8      EQU   GRATPO                                                   80850013
GRCMRG   EQU   GRDCPT                                                   80880013
GR10     EQU   GRR                                                      80910013
GRBILD   EQU   GR3                                                      80940013
BLDPTR   EQU   GRBILD                                                   80970013
SCRTCH   EQU   GR1                                                      81000013
GRHASH   EQU   GR0                                                      81030013
GRLTH    EQU   GR1                                                      81060013
GRX      EQU   GR2                                                      81090013
GRY      EQU   GR3                                                      81120013
GRZ      EQU   GRCDT1                                                   81150013
GRRR     EQU   GRR                                                      81180013
GRPTR    EQU   GRL                                                      81210013
         EJECT                                                          81240013
         EJECT                                                          81270013
         END   IEMEM                                                    81300013
