EW       TITLE 'IEMEW,LIKE PROCESSING PHASE, DICTIONARY, PL1/F, OS/360' 00040013
         SPACE 3                                                        00080013
*                                                                       00086064
* 5.4  A 146000,270000                                        PEP 54767 00087064
* 5.4  C 666000,692800                                        JAP 52168 00089064
*      A 735200                                               JAP 52168 00092064
* 5.2B C 475600                                               MAC 34407 00095064
*      C 346200,350200                                        MAC 35260 00098064
*      D 357600                                               MAC 35260 00101064
*      A 358000                                               MAC 35260 00104064
*                                                                       00107064
* R18 236000-236400,493600*,494000,496800*,497200,498800,         24001 00116001
* R18 502400*,504800*                                             24001 00117001
* R18 116400,118000,567200-567600,570000*,571900-572600            H225 00118001
         SPACE 2                                                        00159042
*              STATUS:  CHANGE LEVEL 0.                                 00179042
         SPACE 3                                                        00199042
*              FUNCTION:     THIS PHASE SCANS DOWN THE LIKE CHAIN BUILT 00219042
*                       BY DECLARE PASS TWO PHASE (EK,EL,EM) AND        00240013
*                       COMPLETES THE DICTIONARY ENTRIES FOR AND        00280013
*                       STRUCTURE DECLARED WITH A LIKE ATTRIBUTE. A BCD 00320013
*                       ENTRY OF THE LIKENED STRUCTURE NAME WAS PLACED  00360013
*                       IN THE DICTIONARY BY DECLARE PASS ONE PHASE(EI) 00400013
*                       AND THIS BCD IS USED TO FIND THE DICTIONARY     00440013
*                       ENTRY FOR THE LIKENED STRUCTURE. COPIES-WITH    00480013
*                       THE POSSIBLE EXCEPTION OF THOSE PARTS REFERING  00520013
*                       TO DIMENSIONS OF THE RELEVANT ELEMENTS OF THE   00560013
*                       LIKENED STRUCTURE ARE MADE IN THE DICTIONARY    00600013
*                       AND THE INCOMPLETE STRUCTURE'S CHAINS ARE UP-   00640013
*                       DATED TO INCLUDE THESE ENTRIES. THE HASH CHAIN  00680013
*                       IS UPDATED AND WHERE NECESSARY COPIES OF        00720013
*                       DIMENSION TABLES AND SECOND FILE STATEMENTS ARE 00760013
*                       ALSO MADE.  ANY ERRORS FOUND RESULT IN SERIOUS  00800013
*                       ERROR MESSAGES BEING PRODUCED.                  00840013
*                       IF THE FIRST STRUCTURE WAS DIMENSIONED THE ALL  00880013
*                       COPIES FROM THE LIKENED STUCTURE MUST HAVE THE  00920013
*                       INHERITED DIMENSION INFORMATION IN THEM.        00960013
*                       IF THE FIRST STRUCUTRE WAS NOT DIMENSIONED THEN 01000013
*                       THE COPIES MUST NOT CONTAIN ANY INHERITED       01040013
*                       DIMENSION INFORMATION.                          01080013
*                       IF A COPIED ENTRY REFERS TO A DIMENSION TABLE   01120013
*                       ENTRY WHICH CONTAINS VARIABLE DIMENSIONS THEN   01160013
*                       A COPY MUST ALSO BE MADE OF THE DIMENSION TABLE 01200013
*                       AND SECOND FILE ENTRIES AND THEIR DICTIONARY    01240013
*                       ENTRIES AND THE POINTERS UPDATED ACCORDINGLY.   01280013
*                       IF AN ERROR IS FOUND THEN THE STRUCTURE         01320013
*                       ENTRY IN THE DICTIONARY WITH THE LIKE ATTRIBUTE 01360013
*                       DATA MUST BE BLANKED OUT AND A COPY MADE OF THE 01400013
*                       STRUCTURE BUT AS A BASE ELEMENT. THIS ENTRY IS  01440013
*                       IS THEN PLACED IN THE APPROPRIATE STRUCTURE     01480013
*                       CHAIN.                                          01520013
         SPACE 3                                                        01560013
         SPACE 3                                                        01600013
*              ENTRY POINTS: IEMEW     ENTRY FROM COMPILER CONTROL.     01640013
         SPACE 3                                                        01680013
*              INPUT:   SYMBOLIC ADDRESS OF START OF CHAIN IN           01720013
*                       COMMUNICATIONS REGION.                          01760013
         SPACE 3                                                        01800013
*                       OUTPUT:        COMPLETED DICTIONARY ENTRIES FOR 01840013
*                       ALL STRUCTURES.                                 01880013
         SPACE 3                                                        01920013
*              EXTERNAL ROUTINES:                                       01960013
*                       ZDRFAB    CONVERT DICTIONARY REFERENCES TO      02000013
*                       ABSOLUTE ADDRESS.                               02040013
*                       ZUGC      GET SCRATCH CORE                      02080013
*                       ZURC      RELEASE SCRATCH CORE                  02120013
*                       ZDICRF    MAKE NEW DICTIONARY ENTRY.            02160013
*                       RLSCTL    RELEASE CONTROL TO COMPILER CONTROL.  02200013
*              EXIT:    NORMAL- VIA RLSCTL AND COMPILER CONTROL.        02240013
*                       ABNORMAL - N/A                                  02280013
         SPACE 3                                                        02320013
*        WORK AREA      1K OF SCRATCH CORE IS USED. THE FIRST KUI BYTES 02360013
*              FOR A STACK OF STRUCTURE CHAIN ADDRESSES OF CONTAINING   02400013
*              STRUCTURES AND THE SECOND 512 BYTES FOR ALL THE STORAGE  02440013
*              REQUIRED BY THE PROGRAM.                                 02480013
         SPACE 3                                                        02520013
*        ATTRIBUTES     NOT REUSABLE.                                   02560013
         SPACE 3                                                        02600013
*        NOTES                                                          02640013
*              REGISTER USAGE:    GR9 - BASE REGISTER FOR BLOCK IEMEW   02680013
*                                 GR11 - BASE REGISTER FOR COMPILER     02720013
*                                 GR12 - BASE REGISTER FOR STORAGE AREA 02760013
*                                 IN SCRATCH CORE.                      02800013
*                                        CONTROL                        02840013
*                                 GR13 - BASE REGISTER OF FIRST         02880013
*                                        DICTIONARY BLOCK.              02920013
*                                 GR15 - UNIT REGISTER                  02960013
*                                      ALL OTHER REGISTERS ARE SCRATCH  03000013
*                                      REGISTERS.                       03040013
         EJECT                                                          03080013
IEMEW    START 0                                                        03120013
         USING *,9                                                      03160013
EWSCRX   EQU   *+4096                                                   03200013
         USING EWSCRX,GR12                                              03240013
         USING *+X'2000',GR8                                            03280013
EX       EQU   *+X'2000'                                                03320013
         DC    C'EW'                                                    03360013
         SPACE 5                                                        03400013
*                       COMPILER CONTROL OFFSETS                        03440013
         SPACE 2                                                        03480013
ZUGC     EQU   X'10'                                                    03520013
ZLOC     EQU   X'112'                                                   03560013
ZUGCOF   EQU   ZUGC                                                     03600013
ZUTXTC   EQU   X'14'                                                    03640013
ZURC     EQU   X'18'                                                    03680013
ZUPGMC   EQU   X'1C'                                                    03720013
ZABORT   EQU   X'20'                                                    03760013
ZLOADW   EQU   X'24'                                                    03800013
LOADW    EQU   ZLOADW                                                   03840013
ZDICAB   EQU   X'28'                                                    03880013
ZDICRF   EQU   X'2C'                                                    03920013
ZUERR    EQU   X'30'                                                    03960013
ZDRFAB   EQU   X'34'                                                    04000013
ZDUMP    EQU   X'38'                                                    04040013
REQEST   EQU   X'40'                                                    04080013
RELESE   EQU   X'44'                                                    04120013
RLSCTL   EQU   X'48'                                                    04160013
ZDABRF   EQU   X'60'                                                    04200013
ZDRFOF   EQU   ZDICRF                                                   04240013
ZDRAOF   EQU   ZDRFAB                                                   04280013
ZURCOF   EQU   ZURC                                                     04320013
ZERROF   EQU   ZUERR                                                    04360013
ZDABOF   EQU   ZDICAB                                                   04400013
ZTXTRF   EQU   80                                                       04440013
ZTXTAB   EQU   84                                                       04480013
ZCHAIN   EQU   88                                                       04520013
ZALTER   EQU   92                                                       04560013
*                                                                       04600013
         SPACE                                                          04640013
*                       SET UP COMMUNICATIONS OFFSETS                   04680013
         SPACE                                                          04720013
ZMYNAM   EQU   112                                                      04760013
ZNXTD    EQU   76                                                       04800013
ZSTAT    EQU   124                                                      04840013
PAR1     EQU   128                                                      04880013
PAR2     EQU   132                                                      04920013
PAR3     EQU   136                                                      04960013
PAR4     EQU   140                                                      05000013
PAR5     EQU   144                                                      05040013
PAR6     EQU   148                                                      05080013
PAR7     EQU   152                                                      05120013
PAR8     EQU   156                                                      05160013
ZTXTST   EQU   256                                                      05200013
ZDTBSZ   EQU   260                                                      05240013
ZTXBSZ   EQU   264                                                      05280013
ZRABSZ   EQU   268                                                      05320013
ZLSTXT   EQU   276                                                      05360013
ZCOMM    EQU   304                                                      05400013
ZALLOC   EQU   ZCOMM+12                                                 05440013
ZDEFLG   EQU   ZCOMM+16                                                 05480013
ZDEFFL   EQU   ZCOMM+16                                                 05520013
ZALCFL   EQU   ZCOMM+17                                                 05560013
ZLIKCH   EQU   ZCOMM+82                                                 05600013
ZMPSTK   EQU   ZCOMM+56                                                 05640013
CECTST   EQU   ZCOMM+88                                                 05680013
OLDSTR   EQU   CECTST                                                   05720013
ZCDSTK   EQU   ZMPSTK                                                   05760013
ZHASH    EQU   ZCOMM+28                                                 05800013
Z2FILE   EQU   ZCOMM+44                                                 05840013
ZUPIC    EQU   ZCOMM+60                                                 05880013
EWDIMB   EQU   X'40'                                                    05920013
EWDIMR   EQU   X'BF'                                                    05960013
EWEOB    EQU   X'ED'                   END OF BLOCK MARKER              06000013
EWLPAR   EQU   X'43'                   LEFT PARENTHESIS                 06040013
EWRPAR   EQU   X'45'                   RIGHT PARENTHESIS                06080013
EWEOP    EQU   X'EB'                   END OF PROGRAM MARKER            06120013
EWSMCL   EQU   X'EF'                   SEMI-COLON                       06160013
CEFSTP   EQU   X'46'                                                    06200013
CEOTH1   EQU   10       OFFSET OF OTHER1 CODE BYTE                      06240013
CEVRBT   EQU   11       OFFSET OF VARIABLE CODE BYTE                    06280013
CETOCB   EQU   15                      OFFSET TO END OF 4 CODE BYTES    06320013
CEDMBT   EQU   X'40'    DIMENSION BIT IN VARIABLE BYTE                  06360013
CENDSR   EQU   X'08'                   END OF STRUCTURE BIT IN OTHER 2  06400013
CEDAPL   EQU   6                       NUMBER OF EXTRA BYTES IN A DATA  06440013
CENWAD   EQU   5        OFFSET OF FULL ENTRY'S ADDRESS IN FP ENTRY      06480013
CEFPFA   EQU   CENWAD                                                   06520013
NONCON   EQU   X'01'                   NON CONTINUOUS FLAG              06560013
NONQUL   EQU   X'01'                   NON QUALIFIED FLAG               06600013
MINSTR   EQU   X'10'                   MINOR STRUCTURE FLAG             06640013
NONMIN   EQU   X'11'                   NONCON AND MINSTR FLAGS          06680013
CEFPCB   EQU   X'40'                   FORMAL PARAMETER ENTRY INITIAL   06720013
*                                      CODE BYTE                        06760013
MAXBCD   EQU   X'1F'                   MAXIMUM BCD LENGTH               06800013
AMBFLG   EQU   X'02'                   AMBIGUOUS FLAG                   06840013
NOAMBG   EQU   X'FD'                   TURN OFF AMBFLAG MASK            06880013
CENOBC   EQU   X'80'                   NO BCD BIT IN INITIAL BYTE       06920013
CEBEPL   EQU   6                       ADDITIONAL BYTES IN BASE OVER    06960013
*                                      STRUCTURE ENTRY                  07000013
CEBASE   EQU   X'2F'                   INITIAL BYTE FOR BASE ELEMENT    07040013
CEDIMZ   EQU   3                       DIMENSION INFORMATION SIZE       07080013
CEVARN   EQU   19                      DISTANCE TO VARIABLE INFORMATION 07120013
*                                      IN STRUCTURE ENTRY               07160013
CECNSR   EQU   2                       OFFSET OF CONTAINING STRUCTURE   07200013
*                                      ADDRESS FROM START OF STRUCTURE  07240013
*                                      INFORMATION                      07280013
CEDIMS   EQU   X'10'                   DIMENSION BIT IN INITIAL CODE    07320013
*                                      BYTE                             07360013
CESTRC   EQU   X'20'                   STRUCTURE BIT IN INITIAL BYTE    07400013
CEFPCH   EQU   3                       OFFSET OF FP POINTER IN DATA     07440013
*                                      ENTRY                            07480013
         SPACE 2                                                        07520013
*                            EQUIVALENCES FOR BRANCH CODES              07560013
         SPACE 2                                                        07600013
CENOP    EQU   0                                                        07640013
CEBO     EQU   1                                                        07680013
CEBP     EQU   2                                                        07720013
CEBH     EQU   2                                                        07760013
CEBM     EQU   4                                                        07800013
CEBL     EQU   4                                                        07840013
CEBNE    EQU   7                                                        07880013
CEBNZ    EQU   7                                                        07920013
CEBZ     EQU   8                                                        07960013
BZ       EQU   CEBZ                                                     08000013
CEBE     EQU   8                                                        08040013
CEBNL    EQU   11                                                       08080013
CEBNH    EQU   13                                                       08120013
CEBNO    EQU   14                                                       08160013
CEBR     EQU   15                                                       08200013
BO       EQU   1                                                   H158 08205017
BM       EQU   4                                                        08210015
BNO      EQU   14                                                       08220015
BNM      EQU   9                                                        08230015
*                            EQUIVALENCES FOR REGISTERS                 08240013
         SPACE                                                          08280013
GR0      EQU   0                                                        08320013
GR1      EQU   1                                                        08360013
GR2      EQU   2                                                        08400013
GR3      EQU   3                                                        08440013
GR4      EQU   4                                                        08480013
GR5      EQU   5                                                        08520013
GR6      EQU   6                                                        08560013
GR7      EQU   7                                                        08600013
GR8      EQU   8                                                        08640013
GR9      EQU   9                                                        08680013
GR10     EQU   10                                                       08720013
GR11     EQU   11                                                       08760013
GR12     EQU   12                                                       08800013
GR13     EQU   13                                                       08840013
GR14     EQU   14                                                       08880013
GR15     EQU   15                                                       08920013
GRHASH   EQU   GR0                                                      08960013
GRLTH    EQU   GR1                                                      09000013
GRP      EQU   GR2                                                      09040013
GRQ      EQU   GR3                                                      09080013
GRZ      EQU   GR4                                                      09120013
GRPTR    EQU   GR5                                                      09160013
GRDIC    EQU   GR13                                                     09200013
*              ************            *************                    09240013
*                       EQU CARDS FOR CHASH                             09280013
GRRZ     EQU   GR15                                                     09320013
GRZZ     EQU   GR15                                                     09360013
EWNOP    EQU   0                                                        09400013
EWBO     EQU   1                                                        09440013
EWBP     EQU   2                                                        09480013
EWBH     EQU   2                                                        09520013
EWBM     EQU   4                                                        09560013
EWBL     EQU   4                                                        09600013
EWBNE    EQU   7                                                        09640013
EWBNZ    EQU   7                                                        09680013
EWBZ     EQU   8                                                        09720013
EWBE     EQU   8                                                        09760013
EWBNL    EQU   11                                                       09800013
EWBNH    EQU   13                                                       09840013
EWBNO    EQU   14                                                       09880013
EWBR     EQU   15                                                       09920013
B        EQU   EWBR                                                     09960013
BE       EQU   EWBE                                                     10000013
         SPACE                                                          10040013
*                       EQUIVALENCES FOR VARIOUS OFFSETS AND CODE BITS  10080013
         SPACE                                                          10120013
EWVARB   EQU   11                      OFFSET OF VARIABLE BYTE FROM     10160013
*                                      START OF DATA ENTRY              10200013
EWSTNO   EQU   1                       OFFSET OF TRUE LEVEL NUMBER FROM 10240013
*                                      START OF STRUCTURE INFORMATION   10280013
EWOTH1   EQU   10                      OFFSET OF OTHER1 BYTE FROM START 10320013
*                                      OF DATA ENTRY                    10360013
EWOTH2   EQU   12                      OFFSET OF OTHER2 BYTE FRIM START 10400013
*                                      OF DATA ENTRY                    10440013
EWOTH3   EQU   13                      OFFSET OF OTHER3 BYTE            10480013
EWSASZ   EQU   4                       SIZE OF SECOND ADDRESS SLOT      10520013
EWLKSZ   EQU   4                       LENGTH OF LIKE DATA IN           10560013
*                                      VARIABLE INFORMATION AREA        10600013
EWSTSZ   EQU   10                      LENGTH OF STRUCTURE DATA IN      10640013
*                                      VARIABLE INFORMATION AREA        10680013
EWPOSZ   EQU   2                       LENGTH OF POS DATA IN            10720013
*                                      VARIABLE INFORMATION AREA        10760013
EWPOSB   EQU   X'10'                   POS BIT IN VARIABLE BYTE         10800013
EWNOLB   EQU   X'F7'                   MASK TO SET LIKE BIT OFF         10840013
EWDIMP   EQU   1                       OFFSET OF DIMTAB POINTER FROM    10880013
*                                      START OF DIMENSIONED INFORMATION 10920013
EWDMTF   EQU   3                       OFFSET OF VARIABLE FLAG IN DIMTB 10960013
EWDTND   EQU   5                       OFFSET OF NO.OF DIMS IN DIMTAB   11000013
EWDMAD   EQU   1                       OFFSET OF 2ND FILE ADDRESS IN    11040013
*                                      DIMTAB BOUNDS ENTRY              11080013
EW2FDM   EQU   20                      LENGTH OF SN2 ENTRY AND LHS OF   11120013
*                                      ARRAY BOUND SECOND FILE STATEMNT 11160013
EWET1P   EQU   3                       OFFSET OF STNO. SLOT  IN SN2 D.R 11200013
EWDTPT   EQU   7                       OFFSET OF DICT PTR IN SN2 D.REF  11240013
EWDIMF   EQU   3                       TOTAL LENGTH OF DIMENSION DATA.  11280013
EWBEPL   EQU   6                       DIFFERENCE IN OFFSET OF START OF 11320013
*                                      VARIABLE INFORMATION AREA        11360013
EWBDTS   EQU   12                      START OF BOUNDS FROM START OF    11400013
*                                      DIMTAB ENTRY                     11440013
*                                      BETWEEN BASE ELEMENT AND STRUCT. 11480013
EWBKCH   EQU   2                       OFFSET OF BACKWARD CHAIN FROM    11520013
*                                      START OF STRUCTURE INFORMATION   11560013
EWVARI   EQU   15                      OFFSET OF START OF VARIABLE      11600013
*                                      INFORMATION IN A STRUCTURE       11640013
EWDTOF   EQU   16                      OFFSET OF START OF DATA     H225 11650001
*                                      INFORMATION IN DATA VAR.    H225 11660001
EWDVRI   EQU   21                      OFFSET OF START OF VARIABLE      11680013
*                                    INFORMATION IN DATA VARIABLE       11720013
EWENDB   EQU   X'08'                   LAST MEMBER OF STRUCTURE BIT     11760013
EWLKOF   EQU   X'F0'                   MASK FOR LIKE IN VARIABLE BYTE   11800013
EWOFFV   EQU   X'D4'                   MASK FOR OFFSET IN VAR BYTE H225 11820001
EWDMOF   EQU   X'80'                   MASK FOR DIMENSION DATA IN VAR   11840013
EWSTOF   EQU   X'C0'                   MASK FOR STRUCTURE DATA IN VAR   11880013
EWSEAS   EQU   X'80'                   SECOND ADDRESS SLOT BIT IN       11920013
*                                      VARIABLE BYTE                    11960013
EWSTFC   EQU   4                       OFFSET OF FORWARD STRUCTURE      12000013
*                                      CHAIN FROM START OF STRUCT. INFO 12040013
EWBASE   EQU   X'2F'                   BASE ELEMENT OF STRUCTURE        12080013
EWSMEM   EQU   X'20'                   STRUCTURED                       12120013
EWSTLB   EQU   X'27'                   STRUCTURED LABEL VARIABLE CODE   12160013
EWNOES   EQU   X'F7'                   MASK TO TURN OFF END OF STRUC-   12200013
*                                      TURE BIT IN OTHER 1 CODE BYTE    12240013
EWVDIM   EQU   X'01'                   VARIABLE DIMS FLAG IN DIMTAB ENT 12280013
EWMAXL   EQU   X'1F'                   MAXIMUM LENGTH OF IDENTIFIER     12320013
EWLIKB   EQU   X'08'                   LIKE BIT IN VARIABLE BYTE        12360013
EWBCDH   EQU   X'80'                   NO BCD CODE BIT IN INITIAL BYTE  12400013
EWDMSC   EQU   X'10'                   DIMENSIONED BIT IN INITIAL BYTE  12440013
EWDMSM   EQU   X'EF'                   MASK TO TURN  OFF                12480013
*                                      DIMENSIONED BIT IN INITIAL BYTE  12520013
EWASDM   EQU   X'03'                   * DIMENSIONS OR STRING LENGTH    12560013
EWASDR   EQU   X'F8'                   MASK TO CLEAR OUT * DATA         12600013
EWFPO2   EQU   X'08'                   FORMAL PARAMETER STRUCTURE       12640013
*                                      MEMBER BIT IN OTHER 2 BYTE       12680013
*                                      BIT IN OTHER2 BYTE               12720013
EWCNTR   EQU   X'03'                   CONTROLLED BITS IN OTHER2 BYTE   12760013
EWADST   EQU   X'80'                   STRING BIT IN DATA BYTE          12800013
EWADSL   EQU   X'40'                   ADJUSTABLE LENGTH STRING BIT IN  12840013
*                                      DATA BYTE                        12880013
EWINIT   EQU   X'08'                   INITIAL BIT IN VARIABLE BYTE     12920013
EWINMB   EQU   3                       OFFFSET OF FLAG IN INITIAL DATA  12960013
*                                      IN VARIABLE INFORMATION AREA     13000013
EWASLR   EQU   X'BF'                   MASK TO TURN OFF ADJUSTABLE      13040013
*                                      STRING BIT                       13080013
EWASTL   EQU   X'01'                   * LENGTH BIT IN OTHER1 BYTE      13120013
EWSLBL   EQU   X'27'                   STRUCTURED LABEL VARIABLE CODE   13160013
EWDATA   EQU   15                      OFFSET OF DATA BYTE IN DATA      13200013
*                                      ENTRY                            13240013
EWADVC   EQU   X'02'                   ADV SECOND FILE CODE             13280013
EWCDPS   EQU   8                       ADV CODE POSITION IN 2ND FILE    13320013
EWCAPS   EQU   4                       CALL CODE IN 2ND FILE            13360013
EWCALL   EQU   X'A1'                   CALL CODE                        13400013
EWCLOF   EQU   8                       OFFSET TO END OF CALL CHAIN IN   13440013
*                                      SECOND FILE STATEMENT            13480013
EWSDVC   EQU   15                      OFFSET TO ASSIGNMENT = BYTE      13520013
*                                      IN SECOND FILE STATEMENT         13560013
EWDCNO   EQU   8                       OFFSET OF DECLARE NUMBER FROM    13600013
*                                      START OF STRUCTURE ENTRY         13640013
CEOFSL   EQU   4                       LENGTH OF OFFSET SLOT IN VAR-    13680013
*                                      IABLE INFORMATION                13720013
CETOVI   EQU   15                      LENGTH OF OFFSET TO VARIABLE     13760013
*                                      INFORMATION IN A STRUCTURE ENTRY 13800013
CETRST   EQU   1                       OFFSET OF TRUE LEVEL NUMBER      13840013
*                                      FROM START OF STRUCTURE VARIABLE 13880013
*                                      INFORMATION                      13920013
CENSAD   EQU   4                       OFFSET OF ADDRESS OF NEXT STRUCT 13960013
*                                      STRUCTURE VARIABLE INFORMATION   14000013
CETOTL   EQU   CETOVI+CEOFSL+CETRST    OFFSET OF TRUE LEVEL NUMBER FROM 14040013
*                                      START OF STRUCTURE ENTRY         14080013
CETONS   EQU   CETOVI+CEOFSL+CENSAD    OFFSET OF NEXT STRUCTURE ADDRESS 14120013
*                                      FROM START OF STRUCTURE ENTRY    14160013
EWC8CB   EQU   X'C8'                   C8 INITIAL CODE BYTE             14200013
EWDBVB   EQU   X'40'                   DIMENSION BIT IN VARIABLE BYTE   14240013
CESTBT   EQU   X'20'                   STRUCTURE BIT IN INITIAL BYTE    14280013
EWBEPX   EQU   EWBEPL-3                                                 14320013
EWARPT   EQU   12                      OFFSET OF ARRAY DICTIONARY REFE  14360013
*                                      -ENCE FROM START OF SECOND FILE  14400013
*                                      STATEMENT                        14440013
EWIINT   EQU   X'19'                   INTERNAL CODE FOR I              14480013
EWNINT   EQU   X'25'                   INTERNAL CODE FOR N              14520013
EWFRCB   EQU   X'40'                   FORMAL PARAMETER ENTRY INITIAL   14560013
*                                      CODE BYTE                        14600013
EWCONS   EQU   X'88'                 DICT CODE BYTE FOR CONSTANT  54767 14620064
CALL     EQU   X'A1'                   CALL STATEMENT CODE BYTE         14640013
         EJECT                                                          14680013
EW0000   EQU   *                                                        14720013
*                       INITIALISATION SECTION TO SET UP PHASE NAME     14760013
*                       GET 512 BYTES OF SCRATCH CORE, PICK UP THE      14800013
*                       START OF THE LIKE CHAIN AND SET UP UNIT REGISTR 14840013
         SPACE                                                          14880013
         SPACE                                                          14920013
         XR    GR0,GR0                                                  14960013
         LA    GR15,1                  SET UP UNIT REGISTER             15000013
         L     GR9,PAR1(0,GRDIC)       SET UP BASE REGISTER             15040013
         MVC   ZMYNAM(2,GRDIC),EWPHNM  MOVE IN PHASE NAME               15080013
         LH    GR5,ZLIKCH(0,GRDIC)     PICK UP START OF LIKE CH AIN     15120013
         SPACE 4                                                        15160013
         SPACE 2                                                        15440013
*                       GET 1K OF SCRATCH CORE. 512 BYTES ARE USED FOR  15480013
*        A STACK. THE REST IS POINTED AT BY GR12, IS ZEROISED AND USED  15520013
*        AS STORAGE.                                                    15560013
         SPACE                                                          15600013
         MVC   PAR1(4,GRDIC),EWSCCT    MOVE IN NUMBER OF SCRATCH BLOCKS 15640013
*                                      REQUIRED                         15680013
         L     GR6,ZUGC(0,GR11)   CORE                                  15720013
         BALR  GR14,GR6                                                 15760013
         L     GR1,PAR1(0,GRDIC)       AND SET GR1 TO POINT AT IT       15800013
         LA    GR12,512(0,GR1)         SET GR12 TO START OF NEXT BLK    15840013
         MVI   EWST2F,X'00'            MOVE IN ZERO BYTE                15880013
         MVC   EWST2F+1(EWCLLN),EWST2F  AND CLEAR DATA AREA IN SCRATCH  15920013
         ST    GR1,EWSKST              AND BEGINNING                    15960013
         LA    GR1,1024(0,GR1)         BUMP TO START OF1K BLOCK         16000013
*                                      SCRATCH                          16040013
         ST    GR1,CEKSTA              STORE START ADDRESS              16080013
         EJECT                                                          16120013
*                       TEST WHETHER THERE IS ANOTHER ENTRY IN THE      16160013
*                       CHAIN. IF SO SAVE THE CHAIN ADDRESS. SET UP     16200013
*                       POINTER TO START OF THE STACK AND INVESTIGATE   16280013
*                       THE ORIGINAL STRUCTURE.                         16320013
         SPACE                                                          16360013
EWBEGN   LTR   GR5,GR5                 IS THIS END OF CHAIN             16400013
         BC    EWBZ,EWEND              YES. SO GO TO END UP PHASE       16440013
         SPACE                                                          16480013
*                       SAVE SYMBOLIC ADDRESS OF ITEM IN STACK  SAVE    16520013
*        ITS CODE BYTES AND DECLARE NUMBER, CALCULATE OFFSET OF START   16560013
*        OF STUCTURE AND SAVE.                                          16600013
         SPACE                                                          16640013
         MVI   BASFL,X'00'             TURN OFF FLAG FOR BASED STRUCT   16660015
EWSTRT   STH   GR5,EWSYMD+2            SAVE SYMBOLIC ADDRESS            16680013
         ST    GR5,EWA3                TWICE                            16720013
         ST    GR5,PAR1(0,GRDIC)       AND                              16760013
         L     GR5,ZDRFAB(0,GR11)      CONVERT                          16800013
         BALR  GR14,GR5                TO                               16840013
         L     GR5,PAR1(0,GRDIC)       ABSOLUTE                         16880013
         L     GR1,EWSKST              POINT GR1 AT START OF STACK      16920013
         MVC   0(2,GR1),EWSYMD+2       SET ADDRESS AT BOTTOM OF STACK   16960013
         TM    0(GR5),X'2E'            IS THIS A STRUCTURE ?       H122 16990017
         BC    EWBNO,EWRR1             NO - ERROR                  H122 17020017
         TM    0(GR5),X'01'            MAYBE A DATA ELEMENT ?      H122 17050017
         BC    EWBO,EWRR1              YES - ERROR.                H122 17080017
         SPACE                                                          17124015
         TM    EWOTH2(GR5),X'03'       TEST FOR 'BASED'                 17128015
         BC    BNO,EWSTRU                                               17132015
         TM    EWVARB(GR5),X'02'                                        17136015
         BC    BZ,EWSTRU                                                17140015
         OI    BASFL,X'F0'             IF SO SET FLAG                   17144015
         SPACE                                                          17148015
EWSTRU   EQU   *                                                        17152015
         MVC   EWORMX(5),EWOTH1(GR5)   PICK UP CODE BYTES               17160013
         NC    EWORMX(5),EWORMS        CLEAR OUT NON INHERITABLE BITS   17200013
*                                      THE NEW INHERITANCE              17240013
         MVC   EWDCLN(2),EWDCNO(GR5)   SAVE DECLARE NUMBER              17280013
         IC    GR0,EWVARB(0,GR5)       AND PICK UP VARIABLE BYTE        17320013
         BAL   GR2,EWVART              GO TO PICK UP ADDRESS OF START   17360013
         LA    GR3,EWVARI(0,GR3)                                        17400013
*                                      OF STRUCTURE INFORMATION IN      17440013
         ST    GR3,EWX1                AND STORE THIS OFFSET            17480013
         AR    GR3,GR5                                                  17520013
*                                      ENTRY                            17560013
         SPACE 2                                                        17600013
*                       STORE TRUE LEVEL NUMBER,ADDRESS OF FORWARD      17640013
*                       CHAIN SLOT AND NEXT ENTRY IN CHAIN              17680013
         SPACE                                                          17720013
         IC    GR0,EWSTNO(0,GR3)       PICK UP TRUE LEVEL NUMBER        17760013
         STC   GR0,EWT1+3              AND STORE                        17800013
         SPACE                                                          17840013
         MVC   EWNXCH(2),EWSTFC(GR3)                                    17880013
         MVC   EWA1+2(2),EWSTFC(GR3)   GET ADDRESS OF NEXT ENTRY IN     17920013
         MVC   EWW1(2),EWBKCH(GR3)     SAVE ADDRESS OF PREVIOUS STRUC   17960013
         SPACE 2                                                        18000013
*                       PICK UP NEXT STRUCTURE ELEMENT AND SEE IF ITS   18040013
*        LEVEL IS LESS THAN THE CURRENT ONE. IF SO, ITS AN ERROR. IF    18080013
*        NOT THEN SAVE ADDRESS OF FIRST ELEMENT AGAIN.                  18120013
         SPACE                                                          18160013
         L     GR2,EWA1                PICK UP ADDRESS OF NEXT STRUCT-  18200013
         LTR   GR2,GR2                 URE MEMBER. IS IT A STOPPER      18240013
         BC    EWBZ,EWLCPU             YES, SO SKIP THIS SECTION     -  18280013
         ST    GR2,PAR1(0,GRDIC)       NO, SO CONVERT                   18320013
         L     GR2,ZDRFAB(0,GR11)      TO ABSOLUTE                      18360013
         BALR  GR14,GR2                                                 18400013
         L     GR4,PAR1(0,GRDIC)                                        18440013
         IC    GR0,EWVARB(0,GR4)       PICK UP VARIABLE BYTE AND GO TO  18480013
         BAL   GR2,EWVART              GET OFFSET OF START OF STRUCTURE 18520013
         TM    0(GR4),EWBASE           IS THIS A BASE ELEMENT           18560013
         BC    EWBNO,EWADJ1            NO,SO BRANCH                     18600013
         LA    GR4,EWBEPL(0,GR4)       YES,SO BUMP OFFSET               18640013
EWADJ1   LA    GR4,EWVARI(GR3,GR4)     INFORMATION.                     18680013
         IC    GR0,EWSTNO(0,GR4)       PICK UP TRUE LEVEL NUMBER        18720013
         C     GR0,EWT1                IS IT LOWER OR EQUAL TO LAST     18760013
         BC    EWBH,EWRR2              ENTRY'S                          18800013
         LH    GR4,EWSYMD+2            STORE ADDRESS OF FIRST           18840013
         STH   GR4,EWA3+2              ELEMENT                          18880013
         SPACE 2                                                        18920013
*                       PICK UP LEVEL AND COUNT AND STORE               18960013
         SPACE                                                          19000013
EWLCPU   MVC   EWDUMP+2(2),1(GR5)      PICK UP LENGTH OF ENTRY TO BCD   19040013
         LR    GR4,GR5                 SET GR4                          19080013
         AH    GR4,EWDUMP+2            TO 2 BYTES BEFORE                19120013
         SR    GR4,GR15                THIS                             19160013
         SR    GR4,GR15                AND                              19200013
         MVC   EWLAC(2),0(GR4)         SAVE THE LEVEL AND COUNT         19240013
         SPACE 2                                                        19280013
*                       NOW TEST IF ORIGINAL ENTRY WAS DIMENSIONED      19320013
         SPACE                                                          19360013
         TM    0(GR5),EWDMSC           IS DIMENSION BIT ON              19400013
         BC    EWBO,EWDIMS             YES, SO BRANCH                   19440013
         XC    EWTEMP(4),EWTEMP        CLEAR TEMP                       19480013
         MVI   EWCF2,X'00'             SET CF2 OFF                      19520013
         SPACE                                                          19560013
*                       THIS ENTRY IS NOT DIMENSIONED SO TEST IF ITS    19600013
*        THE LAST MEMBER OF THE STRUCTURE                               19640013
         SPACE                                                          19680013
EWT3OF   XC    EWT3(4),EWT3            CLEAR T3                         19720013
         TM    EWOTH1(GR5),EWENDB      TEST LAST MEMBER OF STRUCTURE BT 19760013
         BC    EWBO,EWESOF             YES ITS ON SO BRANCH             19800013
         MVI   EWCF1,X'00'             NO SO SET FLAG CF1 OFF           19840013
*                                      C1 IS ZERO                       19880013
         SPACE 2                                                        19920013
*                       HERE WE PICK UP THE BCD OF THE LIKENED STRUCT-  19960013
*                       URE AND SCAN DICTIONARY TO FIND IT              20000013
         SPACE                                                          20040013
EWBCPU   IC    GR0,EWVARB(0,GR5)       PICK UP VARIABLE BYTE            20080013
         BAL   GR4,EWLKVI              GO TO GET OFFSET                 20120013
         TM    0(GR5),EWBASE           IN GR3. IS THIS A BASE ELEMENT   20160013
         BC    EWBNO,EWTOTL            NO, SO SKIP BUMPING OF OFFSET    20200013
         LA    GR3,EWBEPL(0,GR3)       BUMP BY DIFFERENCE               20240013
         SPACE                                                          20280013
*                       HERE WE LOOK AT THE LIKE DATA IN THE VARIABLE   20320013
*        INFORMATION AREA. SAVE THE VALUE OF THE NEXT ITEM IN THE LIKE  20360013
*        CHAIN, PICK UP THE SYMBOLIC ADDRESS OF THE BCD ENTRY IN THE    20400013
*        DICTIONARY AND THEN CLEAR THE LAST BYTE. THIS HELPS A LATER    20440013
*        PHASE DISTINGUISH A LIKE ENTRY FROM AN INITIAL ENTRY  WHICH    20480013
*        SHARE THE SAME SPACE                                           20520013
         SPACE                                                          20560013
EWTOTL   LA    GR4,EWVARI(GR3,GR5)     BUMP TO START OF LIKENED INFO    20600013
         MVC   EWLKCH+2(2),0(GR4)      SAVE LIKE CHAIN                  20640013
         CLI   EWERFG,X'FF'            IS ERROR FLAG ON                 20680013
         BC    EWBE,EWLKUD             YES, SO CONTINUE SCAN OF CHAIN   20720013
         MVC   PAR1+2(2,GRDIC),2(GR4)  PICK UP ADDRESS OF BCD ENTRY     20760013
         MVI   3(GR4),X'00'            SET BYTE TO ZERO FOR LATER PHAS  20800013
         MVC   ZLOC(2,GRDIC),2(GR4)    LOCK DICT BLOCK WITH BCD IN      20840013
         L     GR4,ZDRFAB(0,GR11)      CONVERT TO ABSOLUTE              20880013
         BALR  GR14,GR4                                                 20920013
         L     GR7,PAR1(0,GRDIC)       POINT GR7 AT ENTRY               20960013
         SPACE                                                          21000013
         LA    GR7,3(0,GR7)            POINT GR7 AND BCD LENGTH-1       21040013
         BAL   GR2,CESCN               GO TO SCAN ROUTINE               21080013
         MVC   ZLOC(2,GRDIC),EWZERO    CLEAR LOCK SLOT                  21120013
         SPACE 2                                                        21160013
         TM    0(GR6),X'2E'            IS THIS A STRUCTURE ?       H122 21230017
         BC    EWBNO,EWRR3             NO - ERROR                  H122 21300017
         TM    0(GR6),X'01'            MAYBE A DATA ELEMENT ?      H122 21370017
         BC    EWBO,EWRR3              YES - ERROR.                H122 21440017
         SPACE 2                                                        21520013
*                       NOW TEST NEW STRUCTURE FOR VALIDITY             21560013
*        IF IT IS A DIMENSIONED STRUCTURE THEN SAVE ITS NUMBER OF       21600013
*        DIMENSIONS.                                                    21640013
         SPACE                                                          21680013
         TM    EWVARB(GR6),EWLIKB      IS LIKE BIT ON                   21720013
         BC    EWBO,EWRR4              YES, SO ERROR                    21760013
         TM    EWOTH2(GR6),X'03'       TEST FOR BASED                   21848015
         BC    BNO,EWTOTM                                               21852015
         TM    EWVARB(GR6),X'02'                                        21856015
         BC    BZ,EWTOTM                                                21860015
         OI    BASFL,X'0F'             IF SO SET FLAG                   21864015
         SPACE                                                          21868015
EWTOTM   EQU   *                                                        21872015
         IC    GR0,EWVARB(0,GR6)       NO, SO PICK UP VARIABLE BYTE     21880013
         BAL   GR2,EWVART              GET OFFSET OF START OF STRUCTURE 21920013
         XC    EWTMDM(4),EWTMDM        CLEAR INHERITED SLOT             21960013
         LA    GR4,EWVARI-EWDIMF(GR3,GR6)   POINT AT POSSIBLE DIMENSION 22000013
*                                      DATA                             22040013
         TM    0(GR6),X'10'            IS THIS ITEM DIMENSIONED         22080013
         BC    EWBZ,EWNODM             NO, SO SKUP NEXT INSTRUCTION     22120013
         MVC   EWTMDM+3(1),0(GR4)      YES, SO PICK UP DIMENSIONALITY   22160013
*                                      OF STRUCTURE LIKENED TO          22200013
         SPACE                                                          22240013
         SPACE                                                          22280013
*                       SAVE THE TRUE LEVEL NUMBER OF THIS STRUCTURE    22320013
         SPACE                                                          22360013
EWNODM   LA    GR4,EWDIMF(0,GR4)       POINT AT STRUCTURE INFORMATION   22400013
         MVC   EWT2+3(1),EWSTNO(GR4)   PICK UP TRUE LEVEL NUMBER        22440013
         LH    GR2,EWT1+2              SET LN = T1+1                    22480013
         AR    GR2,GR15                                                 22520013
         STH   GR2,EWLN+2              STORE IN LN                      22560013
         SPACE 2                                                        22600013
*                       HAVING FOUND THE LIKENED STRUCTURE WE NEED ITS  22640013
*                       NEXT STRUCTURE IN ITS CHAIN.                    22680013
         SPACE 2                                                        22720013
*        SET GR6 TO POINT AT STRUCTURE ENTRY AND SAVE ITS LEVEL NUMBER  22760013
         SPACE                                                          22800013
         MVC   EWNXCH(2),EWSTFC(GR4)        SAVE ADDRESS OF NEXT ELEMNT 22840013
         MVC   PAR1+2(2,GRDIC),EWSTFC(GR4)  PICK UP SYMBOLIC ADDRESS OF 22880013
         BAL   GR6,EWGET6              GET ABSOLUTE ENTRY IN GR6        22920013
         IC    GR0,EWVARB(0,GR6)       AND PICK UP NEXT                 22960013
         BAL   GR2,EWVART              ENTRY IN CHAIN                   23000013
         TM    0(GR6),EWBASE           IS THIS A BASE ELEMENT           23040013
         BC    EWBNO,EWXDJ3            NO, SO SKIP NEXT INSTRUCTION     23080013
         LA    GR3,EWBEPL(0,GR3)       ADJUST COUNT FOR BASE ELEMENT    23120013
EWXDJ3   LA    GR2,EWVARI(GR3,GR6)     CALCULATE START OF STRUCTURE     23160013
         XR    GR3,GR3                 INFORMATION.PICK UP ITS TRUE     23200013
         IC    GR3,EWSTNO(0,GR2)       LEVEL                            23240013
         STC   GR3,EWT3+3              SET UP T3                        23280013
         STC   GR3,EWT3OL+3            AND FIRST T3 AS IT IS            23320013
         EJECT                                                          23360013
*                       ARRIVAL POINT FOR ALL ELEMENTS TO TEST IF VALID 23400013
         SPACE                                                          23440013
EWSTLP   TM    0(GR6),EWSTLB           IS THIS A LABEL OR BASE ELEMENT  23480013
         BC    EWBO,EWNOLK             YES                              23520013
         TM    EWVARB(GR6),EWLIKB      IS LIKE BIT ON                   23560013
        BC     EWBNO,LKEXP             NO,  SO CONTINUE           24001 23580001
         MVC   EWA3+2(2),EWSYMD+2      YES, SO ERROR. PICK UP DIC 24001 23600001
         BC    B,EWRR4                 REF. OF ORIGINAL STRUCTURE 24001 23620001
*                                      WITH LIKE ATTRIBUTE.       24001 23640001
LKEXP    TM    EWOTH3(GR6),CEFPCB      WAS THIS AN EXPANSION FROM LIKE  23660001
         BC    EWBO,EWRR4              YES, SO ERROR                    23680013
         SPACE 5                                                        23720013
*                       HERE WE TEST WHETHER THE ORIGINAL STRUCTURE OR  23760013
*                       THIS ELEMENT OF THE LIKENED STRUCTURE ARE       23800013
*                       DIMENSIONED. IF NEITHER THEN WE CAN SIMPLY COPY 23840013
*                       THE DICTIONARY ENTRY. IF THE ELEMENT IS DIMEN-  23880013
*                       SIONED THEN WE MUST GET ITS TRUE DIMENSION      23920013
*                       COUNT FROM THE DIMTAB ENTRY AND IF THERE IS NO  23960013
*                       SUCH ENTRY REMOVE ALL DIMENSION REFERENCES FROM 24000013
*                       THE ENTRY.  IF THE ORIGINAL ENTRY WAS DIMENSION 24040013
*                       -ED WE MUST EXPAND THIS ENTRY WITH THE DETAILS  24080013
*                       OF INHERITED DIMENSIONS. COPIES OF THE DIMTAB   24120013
*                       AND SECOND FILE ENTRIES SHOULD BE MADE IN THE   24160013
*                       CASE OF A LIKENED ELEMENT WITH ITS OWN DIMEN-   24200013
*                       SIONS                                           24240013
         SPACE                                                          24280013
EWNOLK   CLI   EWCF2,X'00'             IS CF2 FLAG ON                   24320013
         BC    EWBNE,EWORDM            NO, SO ORIGINAL WAS DIMENSIONED  24360013
         SPACE 2                                                        24400013
*                       IS ELEMENT DIMENSIONED                          24440013
         SPACE                                                          24480013
EWELTS   TM    0(GR6),X'10'            IS DIMENSION BIT ON              24520013
         BC    EWBO,EWELDM             YES,SO BRANCH                    24560013
         SPACE 2                                                        24600013
*                       NEITHER ELEMENT WAS DIMENSIONED SO MAKE A COPY  24640013
*                       OF STRUCTURE ENTRY.                             24680013
         SPACE                                                          24720013
         BAL   GR14,EWCOPY             GO TO COPY ENTRY                 24760013
         SPACE 2                                                        24800013
EWINCH   BAL   GR5,EWENMK              GO TO MAKE DICTIONARY ENTRY      24840013
         SPACE                                                          24880013
*                       UPDATE FORWARD CHAIN FROM OLD ENTRY             24920013
         SPACE                                                          24960013
EWUPOC   L     GR3,EWA3                PICK UP ADDRESS OF FORWARD CHAIN 25000013
         ST    GR3,PAR1(0,GRDIC)       CONVERT                          25040013
         BAL   GR3,EWGET3              GET ABSOLUTE ENTRY IN GR3        25080013
         AH    GR3,EWX1+2              BUMP BY SAVED OFFSET             25120013
         MVC   EWSTFC(2,GR3),EWLSTR    UPDATE CHAIN                     25160013
         SPACE 2                                                        25200013
*                       PICK UP ADDRESS POINTED AT BY GR1               25240013
         SPACE                                                          25280013
         IC    GR0,EWVARB(0,GR6)       PICK UP VARIABLE BYTE            25320013
         BAL   GR2,EWVART              GET OFFSET AND                   25360013
         TM    0(GR6),EWBASE           IS THIS A BASE ELEMENT           25400013
         BC    EWBNO,EWADJ2            NO, SO SKIP NEXT INSTRUCTION     25440013
         LA    GR3,EWBEPL(0,GR3)       ADJUST COUNT FOR BASE ELEMENT    25480013
         SPACE                                                          25520013
EWADJ2   LA    GR3,EWVARI(0,GR3)       BUMP GR3 FOR OFFSET              25560013
         STH   GR3,EWX1+2              STORE                            25600013
         LA    GR4,0(GR3,GR6)          POINT AT START OF STRUCTURE INFO 25640013
         MVC   EWNXCH(2),EWSTFC(GR4)   SAVE FORWARD CHAIN ADDRESS       25680013
         MVC   EWBKCH(2,GR4),0(GR1)    MOVE IN BACKWARD CHAIN           25720013
         MVC   EWSTNO(1,GR4),EWLN+3    MOVE IN TRUE LEVEL NUMBER.       25760013
         SPACE 2                                                        25800013
*                       UPDATE THE SLOTS FOR NEXT ROUND                 25840013
         SPACE                                                          25880013
         MVC   EWA3+2(2),EWLSTR        SAVE SYMBOLIC ADDRESS            25920013
         TM    EWSCRT,X'80'            IS BCD ATTACHED ?           H158 25930017
         BC    BO,NEWMEM               BRANCH ROUND IF NOT         H158 25940017
         SPACE 2                                                        25960013
*                       FIT NEW ENTRY INTO HASH CHAIN BY HASHING        26000013
*                       BCD AND SCANNING CHAIN TILL ENTRY OF LOW-       26040013
*                       ER OF EQUAL COUNT IS FOUND                      26080013
         SPACE                                                          26120013
EWHSCN   IC    GR0,2(0,GR6)            PICK UP LENGTH                   26160013
         LA    GR6,EWSCRT              POINT GR6 AT BCD LENGTH -1 BYTE  26200013
*                                      IN SCR ATCH WORK SPACE           26240013
         AR    GR6,GR0                 BUMP GR6 TO BCD LENGTH-1 SLOT    26280013
         STM   GR15,GR1,EWPIT          SAVE REGISTERS GR15 GR0 AND GR1  26320013
         XR    GR1,GR1                 CLEAR GR1                        26360013
         IC    GR1,0(0,GR6)            AND PICK UP BCD LENGTH-1         26400013
         STC   GR1,EWCOMX+1            STORE BCD LENGTH-1 IN COMPARE    26440013
         LA    GR5,1(0,GR6)            POINT GR5 AT THE BCD             26480013
         BAL   GRZZ,CHASH              AND HASH                         26520013
         L     GR3,ZHASH(0,GRDIC)      PICK UP START OF HASH TABLE      26560013
         AR    GR3,GR0                 BUMP BY RETURNED OFFSET          26600013
         LM    GR15,GR1,EWPIT          LOAD REGISTERS GR15 GR0 AND GR1  26640013
         SH    GR3,EW3+2               REDUCE BY 3                      26680013
         MVI   EWSNFG,X'00'            SET FLAG OFF                     26720013
EWHCLP   LR    GR7,GR3                 SAVE ADDRESS                     26760013
         MVC   EWDUMP+2(2),3(GR3)      SAVE SYMBOLIC ADDRESS            26800013
         L     GR2,EWDUMP              CONVERT                          26840013
         LTR   GR2,GR2                 IS IT ZERO                       26880013
         BC    EWBZ,EWHCEN             YES, SO GO TO COMPLETE CHAIN     26920013
         ST    GR2,PAR1(0,GRDIC)       TO                               26960013
         BAL   GR3,EWGET3              GET ABSOLUTE ENTRY IN GR3        27000013
         CLI   0(GR3),EWCONS         TEST IF CONSTANT DICT ENTRY  54767 27010064
         BC    EWBE,EWHCLP           SKIP IF CONSTANT             54767 27020064
         XR    GR4,GR4                 CLEAR GR4                        27040013
         IC    GR4,2(0,GR3)            PICK UP LENGTH                   27080013
         AR    GR4,GR3                                                  27120013
         CLC   0(1,GR6),0(GR4)         ARE BCD LENGTH-1 BYTES THE SAME  27160013
         BC    EWBNE,EWXLOP            NO, SO BRANCH OUT                27200013
EWCOMX   CLC   1(0,GR6),1(GR4)         ARE THE BCD'S THE SAME           27240013
         BC    EWBNE,EWXLOP            NO, SO BRANCH OUT                27280013
         MVI   EWSNFG,X'FF'            YES, SO SET FLAG ON              27320013
         SR    GR4,GR15                POINT GR4 AT BLOCK COUNT BYTE    27360013
         CLC   EWLAC+1(1),0(GR4)       IS THIS C SAME AS CURRENT        27400013
         BC    EWBNH,EWHCLP            IT IS NOT LOWER SO CONTINUE SCAN 27440013
         SPACE                                                          27480013
*                       SPACE HAS BEEN FOUND TO SLOT THIS ENTRY INTO    27520013
*        THE HASH CHAIN, SO DO JUST THAT                                27560013
         SPACE                                                          27600013
EWHCEN   MVC   3(2,GR7),EWLSTR         NOW PUT NEW ENTRY'S SYMBOLIC     27640013
*                                      ADDR. INTO HASH SLOT.       H158 27650017
         BC    B,*+10                  JUMP OVER NEXT MVC          H158 27660017
NEWMEM   DS    0H                      NO BCD ENTRY POINT.         H158 27670017
         MVC   EWDUMP+2(2),EWZERO      CLEAR THE DUMP SLOT         H158 27680017
         MVC   PAR1+2(2,GRDIC),EWLSTR  THEN GET (IN GR7)           H158 27690017
         L     GR2,ZDRFAB(0,GR11)      NEW ENTRY'S ADDRESS IN ABSOLUTE  27720013
         BALR  GR14,GR2                                                 27760013
         L     GR7,PAR1(0,GRDIC)                                        27800013
         MVC   3(2,GR7),EWDUMP+2       AND UPDATE ITS HASH CHAIN SLOT   27840013
         SPACE 2                                                        27880013
*                       PICK UP NEXT ITEM IN LIKENED STRUCTURE CHAIN    27920013
         SPACE                                                          27960013
         LH    GR2,EWNXCH              PICK UP ADDRESS OF NEXT ITEM IN  28040013
         LTR   GR2,GR2                 LIKE STRUCTURE. IF NONE BRANCH   28080013
         BC    EWBZ,EWNDCH             OUT                              28120013
         STH   GR2,PAR1+2(0,GRDIC)                                      28160013
         BAL   GR6,EWGET6              GET ABSOLUTE ENTRY IN GR6        28200013
         IC    GR0,EWVARB(0,GR6)       AND PICK UP NEXT                 28240013
         BAL   GR2,EWVART              ENTRY IN CHAIN                   28280013
         TM    0(GR6),EWBASE           IS THIS A BASE ELEMENT           28320013
         BC    EWBNO,EWADJ3            NO, SO SKIP NEXT INSTRUCTION     28360013
         LA    GR3,EWBEPL(0,GR3)       ADJUST COUNT FOR BASE ELEMENT    28400013
EWADJ3   LA    GR2,EWVARI(GR3,GR6)     CALCULATE START OF STRUCTURE     28440013
         XR    GR3,GR3                 INFORMATION.PICK UP ITS TRUE     28480013
         IC    GR3,EWSTNO(0,GR2)       LEVEL                            28520013
         L     GR4,EWT2                PICK UP T2                       28560013
         CR    GR3,GR4                 IS NEW LEVEL GREATER THAN T2     28600013
         BC    EWBNH,EWNDCH            NO,SO ITS THE END                28640013
         L     GR2,EWT3                PICK UP OLD T3                   28680013
         CR    GR3,GR2                 IS NEW LEVEL MORE THAN OLD T3    28720013
         BC    EWBE,EWSTLP             SAME SO TRY FOR NEXT ITEM        28760013
         BC    EWBL,EWRND              IT  IS LESS THAN OLD T3          28800013
         MVI   EWXFLG,X'FF'            GREATER SO SET FLAG ON           28840013
         SPACE                                                          28880013
*                       CALCULATE POSITION ADDRESS MUST GO IN THE STACK 28920013
*        AND STORE IT.                                                  28960013
         SPACE                                                          29000013
EWRND    STC   GR3,EWT3+3              YES,SO UPDATE T3                 29040013
         LR    GR2,GR3                                                  29080013
         SH    GR3,EWT3OL+2            SUBTRACT FIRST T3                29120013
         SR    GR2,GR4                 T3-T2 IN GR2                     29160013
         L     GR1,EWSKST              PICK UP START OF STACK           29200013
         AR    GR1,GR3                 SET GR1 TO STACK + 2 * (T3-T3OL) 29240013
         AR    GR1,GR3                                                  29280013
         AH    GR2,EWT1+2              AND CALCULATE LN = T1 + T3 - T2  29320013
         STH   GR2,EWLN+2              AND STORE                        29360013
         CLI   EWXFLG,X'FF'            IS FLAG ON                       29400013
         BC    EWBNE,EWSTLP            NO, SO TRY AGAIN                 29440013
         MVI   EWXFLG,X'00'            YES, SO SET FLAG OFF             29480013
         MVC   0(2,GR1),EWLSTR         UPDATE STACK                     29520013
         BC    EWBR,EWSTLP             CONTINUE COPYING                 29560013
*              SEE IF A VALID BCD ENTRY HAS BEEN FOUND AND IF SO WE     29600013
*              MUST GO AND MAKE AN INSERTION IN THE HASH CHAIN          29640013
         SPACE                                                          29680013
EWXLOP   CLI   EWSNFG,X'00'            IS FLAG ON                       29720013
         BC    EWBE,EWHCLP             NO, SO CONTINUE SCAN DOWN CHAIN  29760013
         BC    EWBR,EWHCEN             YES, SO GO TO MAKE INSERTION     29800013
         SPACE 2                                                        29840013
*                       AT END OF A LIKENED COPY COMPLETE FINAL FORWARD 29880013
*                       CHAIN AND SET END OF STRUCTURE BIT IF THIS IS   29920013
*                       NEW END OF STRUCTURE                            29960013
         SPACE                                                          30000013
EWNDCH   LH    GR3,EWX1+2              PICK UP START OF STRUCTURE       30040013
         AR    GR3,GR7               INFORMATION.                       30080013
         MVC   EWSTFC(2,GR3),EWA1+2    MOVE IN SAVED ADDRESS OF NEXT    30120013
         CLI   EWCF1,X'00'             ITEM IN ORIGINAL STRUCTURE       30160013
         BC    EWBZ,EWALIN             IF THIS WAS END OF STRUCTURE  I1 30200016
         OI    EWOTH1(GR7),EWENDB      THEN SET THAT CODE BIT ON        30240013
         SPACE 2                                                     I1 30248016
EWALIN   DS    0H                                                    I1 30256016
         BAL   GR14,ALIGN              BRANCH TO ALIGNMENT ROUTINE   I1 30264016
*                                    IN EV.                          I1 30272016
         SPACE 2                                                        30280013
*                       PICK UP LIKE CHAIN AND TRY FOR NEXT ITEM        30320013
         SPACE                                                          30360013
EWCHND   DS    0H                                                    I1 30380016
         L     GR5,EWLKCH              PICK UP LIKE CHAIN AND        I1 30400016
         BC    EWBR,EWBEGN             TRY AGAIN                        30440013
         SPACE 2                                                        30480013
*                       IF END OF STRUCTURE BIT IS ON IN ENTRY WE MUST  30520013
*                       SET IF OFF                                      30560013
         SPACE                                                          30600013
EWESOF   NI    EWOTH1(GR5),EWNOES      SET END OF STRUCTURE BIT OFF     30640013
         MVI   EWCF1,X'FF'             SET CF1 ON                       30680013
         BC    EWBR,EWBCPU                                              30720013
         SPACE 2                                                        30760013
*                       ORIGINAL STRUCTURE WAS DIMENSIONED SO SET FLAG  30800013
*                       ON AND SAVE ITS DIMENSIONS                      30840013
         SPACE                                                          30880013
EWDIMS   LA    GR4,EWSASZ              SET GR4 WITH SECOND ADDRESS SLOT 30920013
*                                      LENGTH                           30960013
EWNOFB   LA    GR3,EWVARI(GR4,GR5)     POINT GR3 AT START OF DIMENSION  31000013
         MVC   EWTEMP+3(1),0(GR3)      DATA AND STORE NO OF DIMS        31040013
         MVI   EWCF2,X'FF'             SET CF2 ON                       31080013
         BC    EWBR,EWT3OF             BRANCH BACK                      31120013
         SPACE                                                          31160013
EWLKUD   MVI   EWERFG,X'00'            SET ERROR FLAG OFF               31200013
         BC    EWBR,EWCHND                                              31240013
         EJECT                                                          31280013
*                       THIS ROUTINE TAKES BYTE IN GRO AND CALCULATES   31320013
*                       OFFSET FROM START OF VARIABLE DATA WITH THE     31360013
*        ANSWER RETURNED IN GR3.                                        31400013
         SPACE                                                          31440013
EWVART   XR    GR3,GR3                 CLEAR GR3                        31480013
         N     GR0,EWSTMS              CLEAR OUT DIMS BIT DOWNWARD      31520013
         BC    EWBZ,EWOUTX             BRANCH IF THIS ZERO              31560013
         SRL   GR0,4                   MOVE OUT LOWER 4 BITS            31600013
         LA    GR14,CVARTB             AND                              31640013
         AR    GR14,GR0                PICK UP OFFSET FROM              31680013
         IC    GR3,0(0,GR14)           TABLE                            31720013
EWOUTX   BCR   EWBR,GR2                RETURN                           31760013
         EJECT                                                          31800013
*                       FINISH OFF ROUTINE TO RELEASE SCRATCH CORE USED 31840013
*                       AND THEN RELEASE CONTROL                        31880013
         SPACE                                                          31920013
EWEND    ST    GR15,PAR1(0,GRDIC)      ENTER NUMBER OF SCRATCH CALLS    31960013
         L     GR1,ZURC(0,GR11)        RELEASE IT                       32000013
         BALR  GR14,GR1                                                 32040013
         LA    GR1,EWLIST              PICK UP PHASE NAME LIST          32080013
         ST    GR1,PAR1(0,GRDIC)       CLEAR PAR2                       32120013
         XC    PAR2(4,GRDIC),PAR2(GRDIC) AND                            32160013
         L     GR1,RLSCTL(0,GR11)        RELEASE CONTROL TO NEXT        32200013
         BALR  GR14,GR1                  PHASE                          32240013
         EJECT                                                          32280013
         SPACE                                                          32320013
*                       BRANCH POINT WHEN ORIGINAL STRUCTURE IS DIMEN-  32360013
*        SIONED                                                         32400013
         SPACE                                                          32440013
EWORDM   TM    0(GR6),EWDMSC           IS DIMENSION BIT ON              32480013
         BC    EWBNO,EWONDM            NO, SO BRANCH                    32520013
         SPACE 2                                                        32560013
*                       WE ARRIVE HERE WHEN ORIGINAL ENTRY AND THIS     32600013
*                       ENTRY ARE BOTH DIMENSIONED. HENCE A COPY OF     32640013
*                       THIS ENTRY IS NEEDED                            32680013
         SPACE                                                          32720013
EWXX     BAL   GR14,EWCOPY             GO TO COPY ROUTINE               32760013
         SPACE 2                                                        32800013
*                       FIND OUT LOCATION OF DIMENSION INFORMATION      32840013
         SPACE                                                          32880013
         LA    GR2,EWSCRT+EWVARI+EWSASZ POINT GR2 AT END OF SECOND      32920013
*                                      ADDRESS SLOT IN VARIABLE INFO.   32960013
         TM    EWSCRT,EWBASE           IS THIS A DATA ELEMENT ?      I1 33000016
         BC    EWBNO,EWNSAS            ELEMENT. NO SO SKIP NEXT INSTR-  33040013
         LA    GR2,EWBEPL(0,GR2)       UCTION. YES, SO BUMP POINTER.    33080013
         SPACE                                                          33120013
*                       NOW PICK UP THE NUMBER OF DIMENSIONS AND        33160013
*                       CALCULATE THE CORRECT NUMBER FROM THE VALUE     33200013
*                       FOR THIS ENTRY PLUS THOSE INHERITED FROM THE    33240013
*                       STRUCTURE WITH THE LIKE ATTRIBUTE LESS          33280013
*                       THOSE INHERITED BY THE ORIGINAL VERSION OF      33320013
*                       STRUCTURE                                       33360013
         SPACE                                                          33400013
EWNSAS   XR    GR4,GR4                 CLEAR GR4                        33440013
         IC    GR4,0(0,GR2)            PICK UP NUMBER OF DIMENSIONS     33480013
         AH    GR4,EWTEMP+2            ADD INHERITED DIMENSIONS         33520013
         SH    GR4,EWTMDM+2            SUBTRACTED THOSE INHERITED       33560013
*                                      ORIGINALLY                       33600013
         STC   GR4,0(0,GR2)            AND STORE ANSWER IN ENTRY        33640013
         MVC   EWDUMP+2(2),EWDIMP(GR2) PICK UP DIMTAB POINTER           33680013
         L     GR4,EWDUMP              IS IT ZERO                       33720013
         LTR   GR4,GR4                                                  33760013
         BC    EWBZ,EWINCH             GO OUT                           33800013
         ST    GR4,PAR1(0,GRDIC)       CONVERT TO                       33840013
         L     GR4,ZDRFAB(0,GR11)      ABSOLUTE                         33880013
         BALR  GR14,GR4                                                 33920013
         L     GR4,PAR1(0,GRDIC)                                        33960013
         SPACE 2                                                        34000013
*                       FIND OUT IF    VARIABLE DIMENSIONS OCCUR IN     34040013
*                       THIS TABLE IF SO COPIES WILL HAVE TO BE MADE OF 34080013
*                       SECOND FILE STATEMENTS AND DICTIONARY ENTRIES.  34120013
*                       IF NOT THEN THE CURRENT DIMENSION TABLE ENTRY   34160013
*                       WILL SUFFICE.                                   34200013
         SPACE                                                          34240013
         TM    EWDMTF(GR4),EWVDIM      IS VARIABLE DIMS FLAG ON         34280013
         BC    EWBZ,EWINCH                                              34320013
         EJECT                                                          34360013
*                       VARIABLE DIMENSIONS PRESENT SO WE MUST SCAN     34400013
*                       DIMTAB FOR REFERENCES TO SECOND FILE STATEMENTS 34440013
         SPACE                                                          34480013
         XC    PAR2(4,GRDIC),PAR2(GRDIC)                                34520013
         MVC   PAR2+2(2,GRDIC),1(GR4)  YES, SO PICK UP LENGTH OF ENTRY  34560013
         IC    GR0,EWDTND(0,GR4)       PICK UP ACTUAL NUMBER OF DIMS    34600013
         ST    GR0,EWDSV                                          35260 34620042
         ST    GR4,PAR1(0,GRDIC)       STORE START ADDRESS OF DICT      34640013
         L     GR7,ZDICRF(0,GR11)      AND COPY ENTRY INTO DICTIONARY   34680013
         BALR  GR14,GR7                                                 34720013
         L     GR7,PAR1(0,GRDIC)                                        34760013
         MVC   SAVEDR(2),PAR1+2(GRDIC) SAVE DIC REF                4884 34780016
         MVC   EWDIMP(2,GR2),PAR1+2(GRDIC)  MOVE IN NEW DIMENSION TABLE 34800013
*                                      ADDRESS                          34840013
         SPACE                                                          34845015
*              IF LIKENED STRUCTURE IS STATIC IT CANNOT HAVE ADJUSTABLE 34850015
*        BOUNDS                                                         34855015
         TM    EWORMX+2,X'03'                                           34860015
         BC    BM,EWAJST               BRANCH IF STATIC                 34865015
         SPACE                                                          34870015
         BAL   GR3,EWGET3              GET ABSOLUTE ENTRY IN GR3        34880013
         ST    GR3,EWXPOT              SAVE GR3                         34920013
         BAL   GR5,EWENMK              GO TO MAKE DICTIONARY ENTRY      34960013
         L     GR3,EWXPOT              RESTORE GR3                      35000013
         L     GR0,EWDSV                                          35260 35020042
         LR    GR5,GR0                 PICK UP NUMBER OF DIMENSIONS     35040013
         AR    GR5,GR5                 CALCULATE 8 X NUMBER OF DIMEN-   35080013
         AR    GR5,GR5                 SIONS                            35120013
         AR    GR5,GR5                 +12 TO GIVE OFFSET               35160013
         LA    GR5,EWBDTS-1(GR3,GR5)   CALCULATE END OF DIMENSIONN DATA 35200013
         LA    GR4,4(0,0)              GR4 CONTAINS 4                   35240013
         LA    GR3,EWBDTS(0,GR3)       BUMP GR3 TO START OF BOUNDS      35280013
         LA    GR7,1(GR3)              BUMP TO START OF BOUNDS,    4884 35290016
         ST    GR7,PAR2(GRDIC)       SET ABS POINTER IN PAR2       4884 35300016
*                                    (REF. IS STILL IN PAR1)       4884 35310016
         MVC   PAR1+2(2,GRDIC),SAVEDR  RESTORE DIC REF             4884 35315016
         L     GR14,ZDABRF(GR11)       THEN GET THE REF.           4884 35320016
         BALR  GR14,GR14               OF THIS INTO                4884 35330016
         L     GR7,PAR1(GRDIC)         GR7.                        4884 35340016
         SPACE                                                          35360013
*                       SCAN FOR VARIABLE ENTRIES BEGINNING FF          35400013
         SPACE                                                          35440013
EWSCLP   CLI   0(GR3),X'FF'            IS THIS FF CODE BYTE             35480013
         BC    EWBNE,EW2FRT            NO, SO SKIP                      35520013
         BAL   GR2,EW2FNT              YES, SO GO TO COPY ROUTINE       35560013
         SPACE                                                          35600013
EW2FRT   LA    GR7,1(GR3,GR4)      BUMP ABSOLUTE                   4884 35610016
         ST    GR7,PAR2(GRDIC)       ADDRESS.                      4884 35620016
         MVC   PAR1+2(2,GRDIC),SAVEDR  RESTORE DIC REF             4884 35630016
         L     GR14,ZDABRF(GR11)                                   4884 35640016
         BALR  GR14,GR14                                           4884 35650016
         L     GR7,PAR1(GRDIC)                                     4884 35660016
         BXLE  GR3,GR4,EWSCLP          BRANCH BACK IF NOT AT END        35680013
         BC    EWBR,EWUPOC             BRANCH TO UPDATE CHAINS          35720013
SAVEDR   DC    H'0'                                                4884 35720516
         SPACE                                                          35721015
*              LIKENED STRUCTURE IS STATIC AND HAS ADJUSTABLE BOUNDS.   35722015
*        SET ALL BOUNDS TO ZERO                                         35723015
EWAJST   XR    GR3,GR3                                                  35724015
         STH   GR7,PAR1+2(GRDIC)                                        35725015
         L     GR14,ZDRFAB(GR11)                                        35726015
         BALR  GR14,GR14                                                35727015
         L     GR7,PAR1(GRDIC)                                          35728015
         IC    GR3,5(GR7)                                               35729015
         SLA   GR3,8                   CALCULATE 8*NO OF DIMENSIONS -1  35730015
         BCTR  GR3,0                 AND INSERT IN XC INSTRUCTION       35731015
         STC   GR3,XC1+1                                                35732015
XC1      XC    12(0,GR7),12(GR7)       ZERO ALL ROUNDS                  35733015
         NI    EWSCRT+EWOTH1,X'F8'     TURN OFF ADJUSTABLE DIMENSIONS   35734015
         NI    EWDMTF(GR7),X'FE'     FLAGS                              35735015
         SPACE                                                          35736015
         MVC   PAR7+2(2,GRDIC),EWSYMD+2     MAKE ERROR MESSAGE  X'258'  35737015
         MVC   PAR6+1(3,GRDIC),EWRRX      OR DECIMAL 600                35738015
         MVI   PAR6+2(GRDIC),X'58'                                      35739015
         L     GR14,ZUERR(GR11)                                         35740015
         BALR  GR14,GR14                                                35741015
         SPACE                                                          35742015
         BC    B,EWINCH                                                 35743015
         SPACE 3                                                        35800013
EWDSV    DC    F'0'                                               35260 35820042
         EJECT                                                          35840013
*                       THIS IS FOR AN ENTRY WHERE THE LIKENED STRUCT-  35880013
*                       URE IS NOT DIMENSIONED BUT IT HAS TO INHERIT    35920013
*                       SOME. SO ANOTHER 3 BYTES MUST BE INSERTED IN    35960013
*                       COPY OF ENTRY                                   36000013
         SPACE                                                          36040013
EWONDM   LA    GR3,EWVARI-1+EWSASZ     PICK UP LENGTH TO END OF SECOND  36080013
*                                      ADDRESS SLOT                     36120013
         TM    0(GR6),EWBASE           IS THIS A BASE ELEMENT           36160013
         BC    EWBNO,EWJSTD            NO, SO SKIP                      36200013
         LA    GR3,EWBEPL(0,GR3)       YES, SO ADJUST OFFSET            36240013
         SPACE                                                          36280013
EWJSTD   EX    GR3,EWMVC3              EXECUTE MOVE CHARACTER           36320013
         LA    GR4,EWSCRT+1            PICK UP ATART OF SCRATCH AREA    36360013
         LA    GR4,0(GR3,GR4)          POINT GR4 AT DIMENSION INFORMAT- 36400013
         MVC   0(1,GR4),EWTEMP+3       ION POSITION. MOVE IN INHERITED  36440013
         MVC   1(2,GR4),EWZERO         DIMENSIONS. SET ZERO AS DIMTAB   36480013
         XR    GR2,GR2                 CLEAR GR2                        36520013
         IC    GR2,2(0,GR6)            POINTER. PICK UP LENGTH OF ENTRY 36560013
         TM    0(GR6),X'80'            IS THEIR ANY BCD                 36600013
         BC    EWBZ,EWBCDX             YES, SO BRANCH                   36640013
         SR    GR2,GR15                NO,SO REDUCE COUNT               36680013
         BC    EWBR,EWBCDY             AND BRANCH                       36720013
         SPACE                                                          36760013
EWBCDX   IC    GR0,0(GR2,GR6)          PICK UP BCD LENGTH-1             36800013
         AR    GR2,GR0                 BUMP TO GIVE TOTAL LENGTH OF     36840013
         AR    GR2,GR15                ENTRY-1                          36880013
         SPACE                                                          36920013
EWBCDY   SR    GR2,GR3                 CALCULATE LENGTH OF ENTRY LEFT   36960013
         AR    GR6,GR3                 INSTRUCTION. BUMP TO END OF DIMS 37000013
         EX    GR2,EWMVC4              EXECUTE MOVE CHARACTER           37040013
         SPACE                                                          37080013
         LA    GR2,EWDIMF+1(GR2,GR3)   STORE TOTAL L LENGTH             37120013
         ST    GR2,EWTOEN              OF ENTRY                         37160013
         XR    GR2,GR2                 AND PUT                          37200013
         IC    GR2,EWSCRT+2            LENGTH TO BCD IN GR2             37240013
         OI    EWSCRT+EWVARB,EWDIMB    SET DIM BIT ON IN VARIABLE BYTE  37280013
         OI    EWSCRT,EWDMSC           PUT DIMS BIT IN INIT BYTE        37320013
         AH    GR2,EW3+2               BUMP                             37360013
         STC   GR2,EWSCRT+2            LENGTH BY 3 AND STORE  IN ENTRY  37400013
         ST    GR2,EWLNTB              SAVE LENGTH TO BCD               37440013
         BC    EWBR,EWINCH                                              37480013
         SPACE 2                                                        37520013
EWMVC3   MVC   EWSCRT(0),0(GR6)        MOVE IN PART OF ENTRY            37560013
EWMVC4   MVC   3(0,GR4),1(GR6)         DATA AND COMPLETE MOVE           37600013
         EJECT                                                          37640013
*                       HERE THIS ENTRY IS DIMENSIONED BUT ORIGINAL IS  37680013
*                       NOT. SO IF THIS ENTRY HAS ITS OWN DIMENSIONS    37720013
*                       WE MUST TREAT IT THE SAME AS IF BOTH ITEMS WERE 37760013
*                       DIMENSIONED. IF NOT WE MAKE A COPY AND REMOVE   37800013
*                       THE DIMENSION DATA                              37840013
         SPACE                                                          37880013
EWELDM   LA    GR3,EWVARI-1+EWSASZ     PICK UP LENGTH TO END OF SECOND  37920013
*                                      ADDRESS SLOT                     37960013
         TM    0(GR6),EWBASE           IS THIS A BASE ELEMENT           38000013
         BC    EWBNO,EWJTR1            NO, SO SKIP                      38040013
         LA    GR3,EWBEPL(0,GR3)       YES, SO BUMP POINTER             38080013
*                       PICK UP ACTUAL NUMBER OF DIMENSIONS FOR         38120013
*        THIS ENTRY. IF ZERO, THEN CONTINUE WITH THIS SECTION TO        38160013
*        REMOVE ALL DIMENSION REFERENCES.                               38200013
         SPACE                                                          38240013
         SPACE                                                          38280013
EWJTR1   LA    GR4,0(GR3,GR6)          SET POINTER TO START OF DIMS DAT 38320013
         XR    GR2,GR2                 CLEAR GR2                        38360013
         IC    GR2,1(0,GR4)            PICK UP NUMBER OF DIMENSIONS     38400013
         SH    GR2,EWTMDM+2            SUBTRACT NUMBER INHERITED        38440013
         BC    EWBNZ,EWXX              IF IT IS NOT ZERO THEN ENTRY     38480013
*                                      HAS ITS OWN DIMENSIONS, SO EXIT  38520013
EWJTRZ   EX    GR3,EWMVC5            AND EXECUTE MOVE                   38560013
         SPACE                                                          38600013
         XR    GR2,GR2                 CLEAR GR2                        38640013
         IC    GR2,2(0,GR6)            PICK UP LENGTH TO BCD LENGTH-1   38680013
         TM    0(GR6),EWBCDH           BIT. IS THERE BCD                38720013
         BC    EWBO,EWBNOC             NO, SO SKIP                      38760013
         IC    GR0,0(GR2,GR6)          YES, SO PICK UP BCD LENGTH-1     38800013
         AR    GR2,GR15                BUMP BY 1                        38840013
         SPACE                                                          38880013
ENWIBC   AR    GR2,GR0                 GR2 = TOTAL LENGTH-1             38920013
EWBINC   LA    GR6,EWDIMF+1(GR3,GR6)   GR6 AFTER DIMS INFORMATION       38960013
         AR    GR3,GR15                BUMP GR3 BY 1                    39000013
         SR    GR2,GR3                 CALCULATE TOTAL REMAINING LENGTH 39040013
         SH    GR2,EW3+2               TO BE MOVED -1 IN GR2            39080013
         LA    GR4,EWSCRT(GR3)         PICK END OF CURRENT ENTRY        39120013
         EX    GR2,EWMVC6              AND EXECUTE MOVE                 39160013
         NI    EWSCRT+EWVARB,EWDIMR    CLEAR DIM BIT IN VARIABLE BYTE   39200013
         AR    GR2,GR3                 RESTORE GR2 TO TOTAL LENGTH      39240013
         AR    GR2,GR15                OF ENTRY                         39280013
         ST    GR2,EWTOEN              STORE TOTAL LENGTH               39320013
         IC    GR2,EWSCRT+2            ADJUST                           39360013
         S     GR2,EW3                 LENGTH IN                        39400013
         STC   GR2,EWSCRT+2            ENTRY                            39440013
         NI    EWSCRT,EWDMSM           CLEAR OUT DIMS BIT IN INIT BYTE  39480013
         ST    GR2,EWLNTB              SAVE LENGTH TO BCD               39520013
         BC    EWBR,EWINCH             RETURN                           39560013
         SPACE                                                          39600013
EWBNOC   SR    GR2,GR15                REDUCE TO TOTAL LENGTH -1        39640013
         BC    EWBR,EWBINC                                              39680013
         SPACE                                                          39720013
         SPACE 2                                                        39760013
EWMVC5   MVC   EWSCRT(0),0(GR6)        MOVE UP TO DIMS INFO             39800013
EWMVC6   MVC   0(0,GR4),0(GR6)         MOVE IN REST OF 5NTRY            39840013
         EJECT                                                          39880013
*                       ERROR MESSAGE SECTION                           39920013
         SPACE                                                          39960013
EWRR1    MVI   EWRRC,X'4D'             ERROR MESSAGE 1                  40000013
         MVI   EWERFG,X'FF'            SET ERROR FLAG ON                40040013
         BAL   GR1,EWERMS              ELEMENT LIKENED TO IS NOT A STRC 40080013
         BC    EWBR,EWBCPU             GO TO UPDATE LIKE CHAIN          40120013
         SPACE                                                          40160013
EWRR2    MVI   EWRRC,X'4E'             ERROR MESSAGE 2                  40200013
         MVI   EWERFG,X'FF'            SET ERROR FLAG ON                40240013
         BC    EWBR,EWCHEN             GO TO CHANGE ENTRY               40280013
         SPACE                                                          40320013
EWRR3    MVI   EWRRC,X'4F'             ERROR MESSAGE 3                  40360013
         BC    EWBR,EWCHEN             GO TO CHANGE ENTRY               40400013
         SPACE                                                          40440013
EWRR4    MVI   EWRRC,X'50'             ERROR MESSAGE 4                  40480013
         BC    EWBR,EWCHEN             GO TO CHANGE ENTRY               40520013
         SPACE 2                                                        40560013
EWRR5    MVI   EWRRC,X'51'             ERROR MESSAGE 5                  40600013
         LM    GR14,GR5,CEDUMP         RELOAD SAVED REGISTERS           40640013
         MVC   ZLOC(2,GRDIC),EWZERO          CLEAR LOCK SLOT            40680013
         BC    EWBR,EWCHEN             GO TO CHANGE ENTRY               40720013
         SPACE                                                          40760013
*                       IN THIS CASE WE MUST NOW REMOVE ANY REFERENCE   40800013
*                       * DIMENSIONS OR LENGTH FROM THE NEW ENTRY       40840013
         SPACE                                                          40880013
EWRR7    MVI   EWRRC,X'55'             MOVE IN CODE BYTE                40920013
         ST    GR1,EWGR1S              SAVE                             40960013
         BAL   GR1,EWERMS               GO TO ERROR MESSAGE GENERATOR   41000013
         L     GR1,EWGR1S              RESTORE                          41040013
         TM    EWSCRT+EWOTH1,EWASTM    IS THIS ASTERISK DIMENSIONS      41080013
         BC    EWBZ,EWENMY             NO, SO COMPLETE ENTRY            41120013
         NI    EWSCRT+EWOTH1,EWASDR     CLEAR OUT * INFORMATION         41160013
         LA    GR6,EWSCRT               POINT GR6 AT ENTRY IN SCRATCH   41200013
         LA    GR3,EWVARI+EWSASZ-1      GR3 TO END OF SECON ADDRESSSLOT 41240013
         TM    0(GR6),EWBASE           IS THIS A BASE ELEMENT           41280013
         BC    EWBNO,EWJTX1            NO, SO SKIP NEXT INSTRUCTION     41320013
         LA    GR3,EWBEPL(0,GR3)        BUMP FOR BASE                   41360013
EWJTX1   LA    GR4,0(GR3,GR6)          BUMP GR4, TO START OF DIM DATA   41400013
         MVC   PAR1+2(2,GRDIC),EWDIMP+1(GR4) PICK UP POINTER TO DIM.    41440013
         L     GR14,ZDRFAB(0,GR11)         TABLE.                       41480013
         BALR  GR14,GR14               CONVERT TI                       41520013
         L     GR14,PAR1(0,GRDIC)                                       41560013
         XC    PAR2(2,GRDIC),PAR2(GRDIC)      COPY TABLE                41600013
         MVC   PAR2+2(2,GRDIC),1(GR14)   PASS LENGTH                    41640013
         L     GR14,ZDICRF(0,GR11)                                      41680013
         BALR  GR14,GR14                                                41720013
         MVC   EWDIMP+1(2,GR4),PAR1+2(GRDIC) POINT TO COPY FROM ENTRY   41760013
         L     GR14,ZDRFAB(0,GR11)                                      41800013
         BALR  GR14,GR14                                                41840013
         L     GR14,PAR1(0,GRDIC)                                       41880013
         IC    GR14,5(0,GR14)          PICK UP NO. OF DIMS              41920013
         SLA   GR14,3                  MULTIPLY BY 8                    41960013
         BCTR  GR14,0                  REDUCE BY ONE                    42000013
         STC   GR14,*+9                MODIFY LENGTH BELOW              42040013
         L     GR14,PAR1(0,GRDIC)                                       42080013
         XC    12(0,GR14),12(GR14)     REPLACE ALL BOUNDS BY ZERO       42120013
         BC    EWBR,EWENMZ             RETURN                           42160013
         SPACE                                                          42200013
EWENMY   NI    EWSCRT+EWOTH1,EWASDR     CLEAR OUT * INFORMATION         42240013
         NI    EWSCRT+EWDATA,EWASLR    TURN OFF ADJUSTABLE LENGTH       42280013
*                                      STRING BIT                       42320013
         BC    EWBR,EWENMZ             YES, SO ENTRY IS THE RIGHT SIZE  42360013
         SPACE 2                                                        42400013
*                       MAKE ERROR MESSAGE AND BLANK OUT OLD ENTRY      42440013
         SPACE                                                          42480013
EWRR6    TM    0(GR6),EWBCDH           IS THE NO BCD BIT ON             42520013
         BC    EWBZ,EWRR6Z             NO, SO BRANCH                    42560013
         MVI   EWERFG,X'F0'            INDICATE 'NOBCD' CASE,      H122 42580017
         MVI   0(GR6),EWC8CB         AND SET C8 CODE BYTE          H122 42600017
         MVC   PAR1+2(2,GRDIC),3(GR6)  YES, SO PICK UP POINTER TO FORML 42640013
*                                      PARAMETER ENTRY                  42680013
         BAL   GR6,EWGET6              GET ABSOLUTE ENTRY IN GR6        42720013
         MVC   CENWAD(2,GR6),EWZERO    CLEAR OUT POINTER TO FULL ENTRY  42760013
         IC    GR2,2(0,GR6)            PICK UP LENGTH TO BCD -1 BYTE    42800013
         LA    GR5,0(GR2,GR6)          POINT GR5 AT BCD LENGTH - 1 BYTE 42840013
         SPACE                                                          42880013
EWRR6Z   IC    GR0,0(0,GR5)            PICK UP BCD LENGTH-1             42920013
         AR    GR0,GR15                BUMP TO BCD LENGTH               42960013
         ST    GR0,PAR8(0,GRDIC)       STORE LENGTH OF BCD              43000013
         AR    GR5,GR15                BUMP GR5 TO START OF BCD         43040013
         ST    GR5,PAR7(0,GRDIC)       STORE START OF BCD               43080013
         MVC   PAR6+1(3,GRDIC),EWRRZ   MOVE IN CODE BYTE                43120013
         BAL   GR1,EWERMN                                               43160013
         CLI   EWERFG,X'F0'            NO BCD ON OLD ENTRY ?       H122 43190017
         BC    BE,EWLKUD               THEN ZERO ERROR FLAG AND    H122 43220017
*                                    CONTINUE DOWN LIKE CHAIN.     H122 43250017
         MVI   0(GR6),EWC8CB           NO, SET FIRST BYTE TO C8         43280013
         STC   GR4,2(0,GR6)            SET LENGTH TO BE TOTAL LENGTH    43320013
         BC    B,EWLKUD                THEN ZERO ERROR FLAG AND    H122 43380017
*                                    CONTINUE DOWN LIKE CHAIN.     H122 43440017
         SPACE                                                          43520013
*                       SET UP ERROR MESSAGE AND CALL ZUERR             43560013
         SPACE                                                          43600013
         SPACE                                                          43640013
EWERMS   MVC   PAR7+2(2,GRDIC),EWSYMD+2 MOVE IN DICTIONARY REFERENCE    43680013
EWERMM   MVC   PAR6+1(3,GRDIC),EWRRX   AND CODE BYTES                   43720013
EWERMN   ST    GR5,EWGR5S              SAVE GR5                         43760013
         L     GR5,ZUERR(0,GR11)       CALL                             43800013
         BALR  GR14,GR5                ZUERR                            43840013
         L     GR5,EWGR5S              RESTORE GR5                      43880013
         BCR   EWBR,GR1                RETURN                           43920013
         SPACE 2                                                        43960013
CERR3    MVI   EWRRC,X'56'             MOVE IN CODE BYTE FOR AMBIGUOUS  44000013
         LM    GR14,GR5,CEDUMP         QUALIFIED N AME AND RESTORE      44040013
         BC    EWBR,EWCHEN             REGISTERS                        44080013
         EJECT                                                          44120013
*                       HAVING FOUND AN ERROR WHICH PREVENTS US FROM    44160013
*                       COMPLETING STRUCTURE. THEREFORE WE MUST MAKE    44200013
*                       LAST ENTRY INTO A BASE ELEMENT BY COPYING IT    44240013
*                       AND REMOVING OLD ENTRY                          44280013
         SPACE                                                          44320013
EWCHEN   L     GR6,EWSYMD              PICK UP ADDRESS OF STRUCTURE IN  44360013
         MVC   ZLOC(2,GRDIC),EWZERO    CLEAR LOCK SLOT                  44400013
         ST    GR6,PAR1(0,GRDIC)       LIKE CHAIN                       44440013
         BAL   GR6,EWGET6              GET ABSOLUTE ENTRY IN GR6        44480013
         XR    GR2,GR2                 CLEAR GR2                        44520013
         IC    GR2,2(0,GR6)            AND PICK UP LENGTH TO BCD-1 BYTE 44560013
         TM    0(GR6),EWBCDH           OR TOTAL LENGTH IF               44600013
         BC    EWBO,EWERNB             BRANCH IS TAKEN                  44640013
         SPACE                                                          44680013
         IC    GR0,0(GR2,GR6)          PICK UP BCD LENGTH-1             44720013
         LA    GR5,0(GR2,GR6)          POINT AT BYTE BEFORE BCD         44760013
         AR    GR2,GR15                GR2 = TOTAL LENGTH-1 OF ENTRY    44800013
         AR    GR2,GR0                                                  44840013
         LA    GR4,1(0,GR2)            GR4 = TOTAL LENGTH OF ENTRY      44880013
         SPACE 2                                                        44920013
*                       IF THERE IS NO BACKWARD CHAIN WE NEED TO GIVE   44960013
*                       ANOTER ERROR MESSAGE AND DELETE THE ENTRY       45000013
         SPACE                                                          45040013
EWERNC   CLC   EWW1(2),EWZERO          IS BACK CHAIN ZERO               45080013
         BC    EWBE,EWRR6              YES, SO ERROR                    45120013
         SPACE 2                                                        45160013
*                       MAKE ENTRY'S COPY IN SCRATCH BLOWN UP TO A      45200013
*                       BASE ELEMENT                                    45240013
         SPACE                                                          45280013
         LA    GR3,EWVARI-1            GR3 CONTAINS LENGTH TO VARIABLE  45320013
         EX    GR3,EWMVC7              DATA-1. MOVE ENTRY TO VARIABLE   45360013
         AR    GR3,GR15                INFORMATION AND BUMP GR3         45400013
         SPACE                                                          45440013
*                       PUT DEFAULT DATA VALUES INTO ENTRY DEPENDING ON 45480013
*        FIRST LETTER OF BCD                                            45520013
         SPACE                                                          45560013
         CLI   1(GR5),EWIINT           IS FIRST LETTER LESS THAN I      45600013
         BC    EWBL,EWTFLT             YES                              45640013
         CLI   1(GR5),EWNINT           NO SO IS IT MORE THAN N          45680013
         BC    EWBH,EWTFLT             NO SO IT IS FIXED                45720013
         MVC   EWSCRT+EWVARI(3),EWFIPR  MOVE IN DEFAULT CODE BYTE AND   45760013
*                                      PRECISION                        45800013
         BC    EWBR,EWBLNK                                              45840013
         SPACE                                                          45880013
EWTFLT   MVC   EWSCRT+EWVARI(3),EWFLPR  MOVE IN DEFAULT DATA            45920013
         SPACE                                                          45960013
*                       ADD ADDITIONAL ZERO BYTES TO MAKE BASE ELEMENT  46000013
*        AND CONTINUE SCAN UP TO LIKE DATA.                             46040013
         SPACE                                                          46080013
EWBLNK   MVC   EWSCRT+EWVARI+3(EWBEPX),EWZERO    MOVE IN EXTRA ZEROS    46120013
         LA    GR5,EWSASZ+EWSTSZ-1     SET GR5 TO LENGTH OF SECOND      46160013
*                                      ADDRESS SLOT AND STRUCTUREDATA   46200013
         TM    EWVARB(GR6),EWDBVB      IS DIMENSION BIT ON IN VAR BYTE  46240013
         BC    EWBNO,EWPOSI            NO, SO SKIP NEXT INSTRUCTION     46280013
         LA    GR5,EWDIMF(0,GR5)       YES SO BUMP GR5 BY DIMENSION     46320013
*                                      DATA LENGTH                      46360013
         SPACE                                                          46400013
EWPOSI   TM    EWVARB(GR6),EWPOSB       IS POS BIT ON IN VARIABLE BYTE  46440013
         BC    EWBNO,EWPOSN            NO, SO SKIP NEXT INSTRUCTION     46480013
         LA    GR5,EWPOSZ(0,GR5)       YES, SO BUMP BY LENGTH OF POS    46520013
*                                      DATA                             46560013
         SPACE                                                          46600013
*                       REMOVE ALL LIKE DATA INFORMATION FROM NEW ENTRY 46640013
         SPACE                                                          46680013
EWPOSN   EX    GR5,EWMVC8              MOVE UP TO LIKE DATA IN VARIA-   46720013
*                                      BLE INFORMATION                  46760013
         LA    GR3,EWLKSZ+1(GR3,GR5)   GR3 CONTAINS TOTAL LENGTH        46800013
*                                      MOVED TO-DATE AND SKIPPED OVER   46840013
         SR    GR2,GR3                 CALCULATE AMOUNT LEFT TO MOVE    46880013
         AR    GR3,GR6                 GR3 = NEXT LOCATION TO BE MOVED  46920013
         LA    GR5,EWSCRT+EWVARI+EWBEPL(GR5)     GR5 POINTS AT NEXT     46960013
*                                      FREE SLOT IN EWSCRT              47000013
         NI    EWSCRT+EWVARB,EWNOLB    CLEAR OUT LIKE BIT               47040013
         EX    GR2,EWMVC9              MOVE IN LAST PART OF ENTRY       47080013
         SPACE 2                                                        47120013
*                       BASE ELEMENT IS NOW IN SCRATCH SO COMPLETE      47160013
*                       CHANGE UPDATE LENGTH AND TURN OLD ENTRY INTO A  47200013
*                       C8 ENTRY                                        47240013
         SPACE                                                          47280013
         OI    EWSCRT,EWBASE           MAKE THIS A BASE ENTRY           47320013
         LA    GR5,EWSCRT                                               47360013
         LA    GR3,EWVARI+EWSASZ+6(GR5)  GR3=LENGTH TO END OF SECOND    47400013
         TM    EWVARB(GR5),EWDBVB      ADDRESS SLOT,ADD DIMENSION       47440013
         BC    EWBZ,EWNDIM             INFO IF PRESENT                  47480013
         LA    GR3,EWDIMF(0,GR3)                                        47520013
EWNDIM   CLC   EWA1+2(2),EWZERO        IF FORWARD LINK NOT ZERO   34407 47560042
         BC    EWBNE,EWNDIN            BRANCH, OTHER WISE               47600013
         OI    EWSCRT+EWOTH1,EWENDB    SET END OF STRUCT BIT ON         47640013
EWNDIN   XR    GR5,GR5                 PICK                             47680013
         IC    GR5,2(0,GR6)            LENGTH TO BCD LENGTH-1 BYTE AND  47720013
         STC   GR4,2(0,GR6)            MAKE LENGTH OF OLD ENTRY INTO    47760013
         MVI   0(GR6),EWC8CB           TOTAL LENGTH AND CHANGE CODE     47800013
*                                      BYTE TO C8                       47840013
         LA    GR5,EWBEPL-EWLKSZ(0,GR5) BUMP LENGTH BY ADDED BYTES      47880013
         STC   GR5,EWSCRT+2            AND STORE IN ENTRY               47920013
         LR    GR2,GR6                 SAVE ADDRESS OF OLD ENTRY        47960013
         LA    GR4,EWBEPL-EWLKSZ(0,GR4)     GR4=TOTAL LENGTH OF NEW     48000013
*                                      ENTRY                            48040013
         SPACE 2                                                        48080013
*                       PICK UP STRUCTURE BEFORE LIKENED ONE            48120013
         SPACE                                                          48160013
         LH    GR6,EWW1                PICK UP ADDRESS OF STRUCTURE     48200013
         STH   GR6,PAR1+2(0,GRDIC)     BEFORE LIKENED ONE AND CONVERT   48240013
EWEIRD   BAL   GR6,EWGET6              GET ABSOLUTE ENTRY IN GR6        48280013
*                                    ADDRESS SLOT                       48320013
         TM    0(GR6),X'01'            SEE IF 'XF' OR XE' ENTRY         48360013
         BC    EWBO,EWEIR2             BRANCH IF 'XF'                   48400013
         LA    GR3,EWVARI+EWSASZ(0,GR6) GR3=LENGTH TO END OF SECOND     48440013
EWEIR1   TM    EWVARB(GR6),EWDBVB                                       48480013
         BC    EWBZ,EWFRIP                                              48520013
         LA    GR3,EWDIMF(0,GR3)       IF PRESENT                       48560013
EWFRIP   CLC   EWSTFC(2,GR3),EWA3+2    DOES THIS POINT TO OLD DICT REF  48600013
         BC    EWBE,EWBEDE             YES                              48640013
         MVC   PAR1+2(2,GRDIC),EWSTFC(GR3)  NO SEARCH FORWARD           48680013
         BC    EWBR,EWEIRD             LOOKING AT NEXT FORWARD LINK     48720013
EWEIR2   LA    GR3,EWDVRI+EWSASZ(GR6)                                   48760013
         BC    EWBR,EWEIR1                                              48800013
         SPACE 2                                                        48840013
*                       MAKE DICTIONARY ENTRY FOR NEW BASE ELEMENT      48880013
*                       AND UPDATE FORWARD CHAIN IN PREVIOUS STRUCTURE  48920013
         SPACE                                                          48960013
EWBEDE   ST    GR4,PAR2(0,GRDIC)       STORE LENGTH IN ENTRY            49000013
         LA    GR4,EWSCRT              STORE ADDRESS OF START OF ENTRY  49040013
         ST    GR4,PAR1(0,GRDIC)       MAKE                             49080013
         L     GR5,ZDICRF(0,GR11)      MAKE DICTIONARY                  49120013
         BALR  GR14,GR5                ENTRY                            49160013
         MVC   EWSTFC(2,GR3),PAR1+2(GRDIC)  AND UPDATE FORWARD CHAIN    49200013
         OI    EWOTH3(GR6),CEFPCB      TURN ON THE DED BIT INDICATING   49240013
*                                      LIKE FOLLOWS                     49280013
         MVC   3(2,GR2),PAR1+2(GRDIC)  UPDATE HASH CHAIN IN OLD ENTRY   49320013
         BAL   GR3,EWGET3              GET ABSOLUTE ENTRY OF NEW  24001 49328001
*                                      DIC. REF. IN GR3           24001 49336001
         TM    EWVARB(GR3),EWDBVB      IS IT DIMENSIONED          24001 49344001
         BC    EWBZ,EWNDMS             NO,  SO BRANCH             24001 49352001
         LA    GR3,EWDIMF(0,GR3)       YES, SO BUMP OFFSET        24001 49360001
EWNDMS   LA    GR3,EWDVRI+EWSASZ(GR3)  POINT AT STRUCTURE INFO.   24001 49368001
         MVC   EWSTFC(2,GR3),EWA1+2    RESET FORWARD CHAIN        24001 49376001
         MVC   PAR7+2(2,GRDIC),3(GR2)       MOVE IN NEW REF.      24001 49384001
         BAL   GR1,EWERMM              GO TO ERROR ROUTINE              49400013
         LR    GR4,GR2                 POINT AT DELETED DIC ENTRY 24001 49410001
*                                      OF STRUC WITH INVALID LIKE 24001 49420001
         SPACE 2                                                        49440013
*                       HERE WE MUSY SEE IF WE HAVE ANY COPIED ITEMS TO 49480013
*                        TURN INTO C8 ENTRIES AND IF SO DO SO ;         49520013
         SPACE                                                          49560013
EWERSN   IC    GR0,EWVARB(0,GR4)       PICK UP VARIABLE BYTE            49600013
         BAL   GR2,EWVART                                               49640013
         TM    0(GR4),EWBASE           IS THIS A BASE ELEMENT     24001 49660001
         BC    EWBNO,EWJSTQ            NO,  SO BRANCH             24001 49680001
         LA    GR3,EWBEPL(0,GR3)       YES, SO BUMP OFFSET        24001 49700001
EWJSTQ   LA    GR3,EWVARI(GR3,GR4)     POINT GR3 AT STRUCTURE DATA      49720013
         MVI   0(GR4),EWC8CB           CHANGE INITIAL BYTE TO C8  24001 49740001
         CLC   EWSTFC(2,GR3),EWZERO    IS FORWARD CHAIN ZERO            49760013
         BC    EWBE,EWCHND             YES, SO FINISH AND CONTINUE SCAN 49800013
         CLC   EWSTFC(2,GR3),EWNXCH    IS IT SAME AS NEXT ENTRY         49840013
         BC    EWBE,EWCHND             YES, SO FINISH AND CONTINUE      49880013
         CLC   EWSTFC(2,GR3),EWA1+2    IS IT SAME AS NEXT ENTRY   24001 49890001
*                                      IN PREVIOUS STRUCTURE      24001 49900001
         BC    BE,EWCHND               YES,SO FINISH AND CONTINUE 24001 49910001
         MVC   PAR1+2(2,GRDIC),EWSTFC(GR3)  PICK UP SYMBOLIC ADDRESS    49920013
         MVC   EWSTFC(2,GR3),EWZERO    CLEAR FORWARD CHAIN              49960013
         L     GR4,ZDRFAB(0,GR11)      CONVERT TO ABSOLUTE              50000013
         BALR  GR14,GR4                                                 50040013
         L     GR4,PAR1(0,GRDIC)       POINT GR4 AT NEXT ENTRY          50080013
         XR    GR2,GR2                                                  50120013
         IC    GR2,2(0,GR4)            PICK UP LENGTH TO BCD            50160013
         TM    0(GR4),EWBCDH           IS THERE BCD                     50200013
         BC    EWBO,EWERSN             NO, SO SKIP NEXT PART      24001 50240001
         IC    GR0,0(GR2,GR4)          PICK UP BCD LENGTH-              50280013
         AR    GR2,GR15                SET GR2                          50320013
         AR    GR2,GR15                                                 50360013
         AR    GR2,GR0                 TO TOTAL LENGTH OF ENTRY         50400013
         STC   GR2,2(0,GR4)            OVER-WRITE WITH TOTAL LENGTH     50440013
         BC    EWBR,EWERSN             AND CONTINUE                     50520013
         SPACE                                                          50560013
EWERNB   LR    GR4,GR2                 GR4= TOTAL LENGTH                50600013
         SR    GR2,GR15                GR2= TOTAL LENGTH-1              50640013
         BC    EWBR,EWERNC                                              50680013
         SPACE 2                                                        50720013
EWMVC7   MVC   EWSCRT(0),0(GR6)        MOVE UP TO VARIABLE INFORMATION  50760013
EWMVC8   MVC   EWSCRT+EWVARI+EWBEPL(0),EWVARI(GR6)    MOVE VARIABLE     50800013
EWMVC9   MVC   1(0,GR5),0(GR3)         MOVE IN END OF ENTRY             50840013
*                                      INFORMATION ONWARDS              50880013
         EJECT                                                          50920013
         SPACE 3                                                        50960013
*              FUNCTION/OPERATION                                       51000013
*                       THIS IS THE ROUTINE TO COPY ENTRY INTO SCRATCH  51040013
*                       ONCE THE SIZE OF THE ENTRY HAS BEEN CALCULATED. 51080013
         SPACE 3                                                        51120013
*              ENTRY POINT                                              51160013
*              EWCOPY        BY   BAL   GR14,EWCOPY                     51200013
         SPACE 3                                                        51240013
*              INPUT                                                    51280013
*              GR6 POINTS AT ENTRY TO BE COPIED.                        51320013
         SPACE 3                                                        51360013
*              OUTPUT                                                   51400013
*              COPY OF ENTRY IN SCRATCH CORE STARTING AT EWSCRT.        51440013
         SPACE 3                                                        51480013
*              EXIT     NORMAL                                          51520013
*              RETURN ON GR2.                                           51560013
         SPACE 3                                                        51600013
*              WORK AREA                                                51640013
*              120 BYTES OF SCRATCH CORE STARTING AT EWSCRT             51680013
         SPACE 3                                                        51720013
*              NOTES                                                    51760013
*              REGISTERS USED ARE GR2,GR15.                             51800013
         SPACE 3                                                        51840013
         SPACE                                                          51880013
EWCOPY   XR    GR2,GR2                 CLEAR GR2                        51920013
         IC    GR2,2(0,GR6)                                             51960013
         STC   GR2,EWLNTB+3            SAVE LENGTH TO BCD LENGTH -1 BYT 52000013
         TM    0(GR6),EWBCDH           END. IS THERE ANY MORE BCD       52040013
         BC    EWBZ,EWBCDM             YES,SO BRANCH                    52080013
         SR    GR2,GR15                REDUCE COUNT FOR MVC INSTRUCTION 52120013
         BC    EWBR,EWBCDV             BRANCH TO MOVE ITEM TO SCRATCH   52160013
         SPACE                                                          52200013
EWBCDM   IC    GR0,0(GR2,GR6)          BCD LENGTH - 1                   52240013
         AR    GR2,GR0                 SET UP TOTAL LENGTH -1           52280013
         AR    GR2,GR15                BUMP BY 1                        52320013
         SPACE                                                          52360013
EWBCDV   EX    GR2,EWMVC               EXECUTE MOVE CHARCTER INSTR      52400013
         SPACE                                                          52440013
         AR    GR2,GR15                BUMP TO TOTAL LENGTH             52480013
         ST    GR2,EWTOEN              SAVE TOTAL LENGTH OF ENTRY       52520013
         SPACE                                                          52526015
         SPACE                                                          52550015
         BCR   EWBR,GR14               RETURN                           52560013
         SPACE 2                                                        52600013
EWMVC    MVC   EWSCRT(0),0(GR6)        MOVE ENTRY TO SCRATCH CORE       52640013
         EJECT                                                          52680013
********************  ROUTINE 'EWENMK'  ************************** H150 52685017
*                                                                  H150 52690017
*              THIS ROUTINE MAKES THE NEW DICTIONARY ENTRIES.      H150 52695017
*                                                                  H150 52700017
*              IT MUST -                                           H150 52705017
*                                                                  H150 52710017
*                       CLEAR OUT ALL INHERITED CODE BYTES AND SUBSTIT- 52720013
*                       -UTE THE NEW INHERITANCE                        52760013
*                       MAKE DICTIONARY ENTRY AND SAVE SYMBOLIC ADDRESS 52800013
*                       SUES REGISTERS GR2,GR4,GR14, RETURNS ABSOLUTE   52840013
*                       ADDRESS OF NEW ENTRY IN GR6                     52880013
         SPACE                                                          52920013
*              FUNCTION/OPERATION                                       52960013
*                       THIS SECTION COMPLETES THE NEW STRUCTURE ENTRY  53000013
*              THAT IS IN SCRATCH STARTING AT EWSCRT.  IT REMOVES       53040013
*              ANY INHERITED DATA FROM THE ENTRY AND GIVES IT ITS NEW   53080013
*              INHERITANCE. THE NEW STRUCTURE IS PUT INTO THE           53120013
*              DICTIONARY AND ANY SECOND FILE STATEMENTS FOR ADJUSTABLE 53160013
*              LENGTH STRINGS OR INITIAL ARE COPIED. SIMILARLY          53200013
*              DICTION ARY ENTRIES FOR INITIAL ARE COPIED.              53240013
         SPACE 3                                                        53280013
*              ENTRY POINT                                              53320013
*              EWENMK        BY   BAL   GR5,EWENMK.                     53360013
         SPACE 3                                                        53400013
*              INPUT                                                    53440013
*              STRUCTURE ENTRY TO BE COMPLETED IS IN SCRATCH CORE       53480013
*              STARTING AT EWSCRT.                                      53520013
         SPACE 3                                                        53560013
*              OUTPUT                                                   53600013
*              EWLSTR CONTAINS DICTIONARY REFERENCE OF NEW ENTRY        53640013
*              GR6 POINTS TO NEW STRUCTURE ENTRY IN DICTIONARY.         53680013
         SPACE 3                                                        53720013
*              EXTERNAL ROUTINES                                        53760013
*              EW2FNT   ROUTINE TO COPY SECOND FILE STATEMENT.          53800013
         SPACE 3                                                        53840013
*              EXIT     NORMAL                                          53880013
*              RETURN (VIA EW7RST) ON GR5                          H150 53900017
*                                                                       53920017
         SPACE 3                                                        53960013
*              WORK AREA                                                54000013
*              N/A                                                      54040013
         SPACE 3                                                        54080013
*              NOTES                                                    54120013
*              REGISTERS GR2,GR3,GR14,GR6 ARE USED.                     54160013
         SPACE 3                                                        54200013
EWENMK   NC    EWSCRT+EWOTH1(5),EWCOMS CLEAR OUT POSSIBLY INHERITED BIT 54240013
         OC    EWSCRT+EWOTH1(5),EWORMX S AND REPLACE BY THOSE WHICH ARE 54280013
*                                    INHERITED FROM NEW STRUCTURE. H150 54285017
         TM    BASFL,X'FF'             IS EITHER STRUCTURE BASED ? H150 54290017
         BC    BNM,NOMIX               BRANCH IF BOTH OR NEITHER.  H150 54295017
*                                      YES. ADJUSTMENT IS REQD FOR H150 54300017
         BAL   GR14,BASED            THE DEFINED SLOT.             H150 54305017
NOMIX    DS    0H                                                  H150 54310017
         TM    EWSCRT+EWOTH1,EWASDM    HAS THIS * DIMS OR LENGTH        54320013
         BC    EWBZ,EWENMZ             NO, SO SKIP ROUND                54360013
         TM    EWSCRT+EWOTH2,EWFPO2    YES, SO IS THIS PART OF A FORMAL 54400013
         BC    EWBO,EWENMZ             PARAMETER. YES, SO SKIP OUT      54440013
         TM    EWSCRT+EWOTH2,EWCNTR    NO, SO IS ITS STORAGE CLASS      54480013
         BC    EWBNO,EWRR7             CONTROLLED. NO, SO ERROR         54520013
EWENMZ   LA    GR3,EWSCRT-2            CALCULATE 2 BYTES BEFORE         54560013
         MVC   EWDCNO+2(2,GR3),EWDCLN  UPDATE DECLARE NUMBER            54600013
         AH    GR3,EWLNTB+2            BEFORE BCD LENGTH-1 AND          54640013
         MVC   0(2,GR3),EWLAC          STORE L AND C IN ENTRY           54680013
*                                      ORIGINAL ENTRY                   54720013
         SPACE 2                                                        54760013
*              IF ELEMENT IS PARAMETER AND HAS INITIAL REMOVE INITIAL   54800013
*        SLOT FROM ENTRY AND PUT OUT ERROR MESSAGE                      54840013
         TM    EWSCRT+EWVARB,EWINIT                                     54880013
         BC    BZ,EWENMX               BRANCH IF NO INITIAL             54920013
         SPACE                                                          54960013
         TM    EWSCRT+EWOTH2,X'03'   TEST FOR BASED                     54965015
         BC    EWBNO,EWENMJ          NTO ALLOWED WITH INITIAL           54970015
         TM    EWSCRT+EWVARB,X'02'                                      54975015
         BC    EWBO,EWENMI                                              54980015
         SPACE                                                          54985015
EWENMJ   EQU   *                                                        54990015
         TM    EWSCRT+EWOTH2,EWFPO2                                     55000013
         BC    BZ,EWENMX               BRANCH IF NOT PARAMETER          55040013
         SPACE                                                          55080013
EWENMI   EQU   *                                                        55100015
         NI    EWSCRT+EWVARB,X'FF'-EWINIT   TURN OFF INITIAL FLAG       55120013
         SPACE                                                          55160013
         IC    GR0,EWSCRT+EWVARB                                        55200013
         BAL   GR4,EWLKVI              CALCULATE OFFSET OF INITIAL INFO 55240013
         TM    EWSCRT,X'2F'            TEST IF LABEL ORDATA             55280013
         BC  CEBNO,EWENML              BRANCH IF LABEL                  55320013
         LA    GR3,EWBEPL(GR3)                                          55360013
EWENML   LA    GR3,EWVARI(GR3)         GR3= OFFSET OF INIT INFO         55400013
         SPACE                                                          55440013
         XR    GR4,GR4                                                  55480013
         IC    GR4,EWSCRT+2            REDUCE LENGTH IN D. E. BY 4      55520013
         S     GR4,CE4                                                  55560013
         STC   GR4,EWSCRT+2                                             55600013
         L     GR2,EWTOEN              SHIFT DICTIONARY ENTRY FROM      55640013
         S     GR2,CE4               BEYOND INITIAL SLOT 4 BYTES LEFT   55680013
         ST    GR2,EWTOEN            TO OBLITERATE INITIAL INFO         55720013
         SR    GR2,GR3                                                  55760013
         BCTR  GR2,0                                                    55800013
         LA    GR3,EWSCRT(GR3)                                          55840013
         STC   GR2,MVC1+1                                               55880013
MVC1     MVC   0(0,GR3),4(GR3)                                          55920013
         SPACE                                                          55960013
         MVI   EWRRC,X'57'                                              56000013
         ST    GR1,EWGR1S                                               56040013
         BAL   GR1,EWERMS              MAKE ERROR MESSAGE               56080013
         L     GR1,EWGR1S                                               56120013
         SPACE 2                                                        56160013
EWENMX   EQU   *                                                        56200013
         BAL   GR14,BCDTST             GO TO TEST IF BCD IS REQD.  H158 56220017
         SPACE                                                          56240013
*                       MAKE DICTIONARY ENTRY                           56280013
         SPACE                                                          56320013
         L     GR2,EWTOEN              PICK UP TRUE LENGTH OF ENTRY     56360013
         ST    GR2,PAR2(0,GRDIC)       STORE LENGTH IN PAR2             56400013
         LA    GR4,EWSCRT              AND START ADDRESS IN PAR1        56440013
         ST    GR4,PAR1(0,GRDIC)                                        56480013
         L     GR4,ZDICRF(0,GR11)      MAKE DICTIONARY ENTRY            56520013
         BALR  GR14,GR4                                                 56560013
         MVC   EWLSTR(2),PAR1+2(GRDIC) PICK UP SYMBOLIC ADDRESS         56600013
         BAL   GR6,EWGET6              GET ABSOLUTE ENTRY IN GR6        56640013
         SPACE                                                          56680013
*              IF THE ENTRY IS FOR AN ADJUSTABLE LENGTH STRING     H225 56710001
*        OR OFFSET VARIABLE, THE SECOND FILE STATEMENT AND         H225 56740001
*        SECOND FILE DICTIONARY ENTRY MUST BE COPIED.              H225 56770001
         SPACE                                                          56800013
         ST    GR7,EWGR1S              SAVE GR7                         56840013
         TM    0(GR6),EWBASE           IF THIS IS NOT A DATA ITEM       56880013
         BC    EWBNO,EWENNB            BR ANCH OUT                      56920013
         TM    EWDATA(GR6),EWADST      IS THIS A STRING                 56960013
         BC    EWBO,EWISIO             NO, SO GO TO TEST IF OFFSET H225 57000001
         TM    EWDATA(GR6),EWADSL      IS THIS AN ADJUSTABLE LENGTH     57040013
         BC    EWBZ,EWISIN             NO, SO GO TO TEST INITIAL        57080013
         TM    EWOTH1(GR6),EWASTL      IS * LENGTH BIT ON               57120013
         BC    EWBO,EWISIN                                              57160013
         SPACE                                                          57162015
         TM    EWOTH2(GR6),X'03'                                        57164015
         BC    BNM,EWISIM                                               57166015
         SPACE                                                          57168015
         NI    EWDATA(GR6),X'BF'       TURN OFF ADJUSTABLE LENGTH       57170015
         XC    EWDATA+1(3,GR6),EWDATA+1(GR6)  ZERO DATA INFORMATION     57172015
         SPACE                                                          57174015
         MVC   PAR7+2(2,GRDIC),EWSYMD+2  MAKE ERROR MESSAGE X'258'      57176015
         MVC   PAR6+1(3,GRDIC),EWRRX    (DEC 600)                       57178015
         MVI   PAR6+2(GRDIC),X'58'                                      57180015
         L     GR14,ZUERR(GR11)                                         57182015
         BALR  GR14,GR14                                                57184015
         BC    B,EWISIN                                                 57186015
         SPACE 2                                                        57188015
EWISIO   TM    EWDATA(GR6),EWOFFV      IS THIS AN OFFSET VAR.      H225 57195001
         BC    EWBNO,EWISIN            NO,  IT IS NUMERIC          H225 57202001
         LA    GR7,0(GR6)              YES, SO POINT GR7 AT OFFSET H225 57209001
*                                      DIC. ENTRY                  H225 57216001
         BC    EWBR,GETREF             GO TO GET DIC. REF. OF      H225 57223001
*                                      OFFSET DIC. ENTRY INTO GR7  H225 57230001
         SPACE                                                          57237001
EWISIM   EQU   *                       SET UP GR3 AND GR7 READY    H225 57244001
*                                      FOR ROUTINE TO COPY SECOND  H225 57251001
*                                      FILE STAT. AND DIC. ENTRY   H225 57258001
         LA    GR7,EWDTOF(GR6)         POINT GR7 AT DATA INFO.     H225 57265001
GETREF   ST    GR7,PAR2(GRDIC)         OBTAIN DIC. REF. OF THE     H225 57272001
         MVC   PAR1+2(2,GRDIC),EWLSTR  SECOND FILE STATEMENT       4884 57279001
         L     GR14,ZDABRF(GR11)       OR OFFSET DIC. ENTRY        H225 57286001
         BALR  GR14,GR14               THEN GET THE REF. OF THIS   4884 57293001
         L     GR7,PAR1(GRDIC)         INTO GR7                    4884 57300001
         LA    GR3,EWDATA(0,GR6)       POINT GR3 AT DATA INFO.     H225 57307001
         BAL   GR2,EW2FNT              GO TO COPY SECOND FILE ENTRY     57320013
         SPACE                                                          57360013
*                       TEST TO SEE IF THERE IS ANY INITIAL DATA FOR    57400013
*                       THIS ITEM AND IF SO COPY THE DICTIONARY         57440013
*                       REFERENCE OR OR SECOND FILE STATEMENT           57480013
         SPACE                                                          57520013
EWISIN   TM    EWVARB(GR6),EWINIT      IS INITIAL BYTE ON IN VAR BYTE   57560013
         BC    EWBZ,EW7RST             NO, SO BRANCH TO RETURN          57600013
         IC    GR0,EWVARB(0,GR6)       PICK UP VARIABLE BYTE            57640013
         BAL   GR4,EWLKVI              AND GO TO GET OFFSET             57680013
         TM    0(GR6),EWBASE           IS THIS A BASE DATA ITEM         57720013
         BC    EWBNO,EWALAB            NO, SO SKUP NEXT BUMP            57760013
         LA    GR3,EWBEPL(0,GR3)       ADD NUMBER OF EXTRA BYTES        57800013
EWALAB   LA    GR4,EWVARI-1(GR3,GR6)   GR4 POINTS 1 BEFORE SAART OF     57840013
*                                      INITIAL DATA                     57880013
         TM    EWINMB+1(GR4),X'FF'     IS AMRKER FLAG FF                57920013
         BC    EWBZ,EW7RST             ALL ZEROS SO NO ACTION REQUIRED  57960013
         TM    EWINMB+1(GR4),X'0F'     IS FLAG 0F                       58000013
         BC    EWBZ,EWDCCY             NO, SO COPY DICT REF             58040013
         LA    GR7,1(GR4)              YES, SO 2ND FILE STATEMENT MUST  58080013
         ST    GR7,PAR2(GRDIC)       BE COPIED                          58120013
         MVC   PAR1+2(2,GRDIC),EWLSTR                                   58160013
         L     GR14,ZDABRF(GR11)                                        58200013
         BALR  GR14,GR14                                                58240013
         L     GR7,PAR1(GRDIC)         GR7= D.R. OF INITIAL SLOT        58280013
         LR    GR3,GR4                                                  58320013
         BAL   GR2,EW2FNT              MAKE SECOND FILE COPY            58360013
         BC    EWBR,EW7RST                                              58400013
         SPACE                                                          58440013
         SPACE                                                          58480013
*                       TEST THAT THIS IS NOT A STRUCTURED LABEL        58520013
*                       VARIABLE, IF SO , TREAT FOR INITIAL.            58560013
         SPACE                                                          58600013
EWENNB   TM    0(GR6),EWSLBL           IS THIS A LABEL VARIABLE         58640013
         BC    EWBO,EWISIN             CHANGE TO EWISIN FOR SECOND REL  58680013
         OI    EWOTH3(GR6),CEFPCB      TURN ON THE NEEDS DED TO INDICAT 58720013
*                                      PART OF LIKE EXPANSION           58760013
         BC    EWBR,EW7RST             GO TO RETURN                     58800013
EWGET6   L     GR14,ZDRFAB(0,GR11)     LOAD CONSTANT CONVERSION         58840013
         BALR  GR14,GR14               CONVERT TO ABSOLUTE              58880013
         LR    GR14,GR6                SAVE RETURN REGISTER             58920013
         L     GR6,PAR1(0,GRDIC)       LOAD REGISTER 6 WITH NEW ENTRY   58960013
         BCR   EWBR,GR14               RETURN                           59000013
EWGET3   L     GR14,ZDRFAB(0,GR11)     LOAD CONSTANT CONVERSION         59040013
         BALR  GR14,GR14               CONVERT TO ABSOLUTE              59080013
         LR    GR14,GR3                SAVE RETURN REGISTER             59120013
         L     GR3,PAR1(0,GRDIC)       LOAD REGISTER 3 WITH NEW ENTRY   59160013
         BCR   EWBR,GR14               RETURN                           59200013
         EJECT                                                          59240013
*                       ROUTINE TO FIND OFFSET OF INITIAL OR LIKE       59280013
*                       INFORMATION FROM START OF VARIABLE INFORMAT-    59320013
*                       TION ARE A                                      59360013
         SPACE                                                          59400013
EWLKVI   SRL   GR0,4                   MOVE OUT LIKE BIT DOWNWARDS      59440013
         XR    GR3,GR3                 CLEAR GR3                        59480013
         LA    GR14,EVARTB             PICK UP START OF TABLE           59520013
         AR    GR14,GR0                BUMP BY OFFSET                   59560013
         IC    GR3,0(0,GR14)           PICK UP OFFSET FROM TABLE        59600013
         BCR   EWBR,GR4                AND RETURN                       59640013
         EJECT                                                          59680013
*                       THIS ROUTINE SCANS DICTIONARY FOR CORRECT       59720013
*              DICTIONARY REFERENCE FOR A GIVEN BCD.                    59760013
*              GR7 POINTS AT THE BCD LENGTH BYTE ON ENTRY               59800013
*              GR6 CONTAINS THE ABSOLUTE ADDRESS OF DICTIONARY ENTRY ON 59840013
*                                      EXIT.                            59880013
*              NO REGISTERS USED BY THE CALLING ROUTINE ARE DESTROYED.  59920013
         SPACE 2                                                        59960013
*                       INITIALISATION AND HASHING                      60000013
*                       PICK UP BCD, HASH IT AND PICK UP RESULTING OFF- 60040013
*        SET FROM START OF HASH TABLE. IF OFFSET IS ZERO THIS IS AN     60080013
*        ERROR                                                          60120013
         SPACE                                                          60160013
*              SAVE START ADDRESS OF VARIABLE IN TEXT AND POSITION      60200013
*        POINTER AT START OF LAST SECTION OF VARIABLE'S BCD. I.E. AT    60240013
*        START FOR A NON-QUALIFIED NAME OR BEFORE LAST ITEM IN A        60280013
*        QUALIFIED NAME                                                 60320013
         SPACE 3                                                        60360013
*              FUNCTION/OPERATION                                       60400013
*                       TO SCAN THE DICTIONARY FOR A GIVEN BCD AND TO   60440013
*              RETURN THE ADDRESS OF THE RELEVANT DICTIONARY ENTRY WITH 60480013
*              THE SAME BCD AND WHICH IS KNOWN AT THIS POINT OF THE     60520013
*              PROGRAM. AN ILLEGAL ENTRY WILL RETURN A DUMMY REFERENCE  60560013
*              AND AN ERROR MESSAGE IS PRODUCED.                        60600013
         SPACE 3                                                        60640013
*              ENTRY POINT                                              60680013
*                       CESCN - ENTERED BY       BAL   GR2,CESCN        60720013
         SPACE 3                                                        60760013
*              INPUT                                                    60800013
*              GR7 POINTS AT THE BCD LENGTH BYTE BEFORE THE BCD.        60840013
*              GR6 POINTS AT THE NEXT AVAILABLE BYTE IN THE OUTPUT AREA 60880013
         SPACE 3                                                        60920013
*              OUTPUT                                                   60960013
*              GR6 POINTS AT THE DICTIOARY ENTRY FOUND.                 61000013
*              AREA.                                                    61040013
         SPACE 3                                                        61080013
*              EXIT     NORMAL - RETURN ON GR2.                         61120013
         SPACE 3                                                        61160013
*              WORK AREA                                                61200013
*              1K OF SCRATCH IS USED. START ADDRESS OF THIS AREA IS     61240013
*              IN CESTKA.                                               61280013
         SPACE 3                                                        61320013
*              NOTES                                                    61360013
*              REGISTERS USED ARE SAVED ON ENTRY AND RESTORED ON EXIT.  61400013
         SPACE 3                                                        61440013
         SPACE                                                          61480013
         SPACE                                                          61520013
CESCN    STM   GR14,GR5,CEDUMP         SAVE REGISTERS 14 TO 5 INCLUSIVE 61560013
*                                    UTE TIDY AREA                      61600013
         SPACE                                                          61640013
*              CLEAR FLAGS AND SET UP COUNTS ETC. LOOK AT FIRST BCD     61680013
         SPACE                                                          61720013
         XC    CEFLAG(4),CEFLAG        CLEAR FLAGS                      61760013
         XC    OLDSTR(4,GRDIC),OLDSTR(GRDIC) CLEAR DICTIONARY REF STORE 61800013
         L     GR4,STKCNT              PICK UP STACK COUNT              61840013
         XR    GR4,GR4                 AND SET TO ZERO                  61880013
         ST    GR7,TXTSTR              SAVE START ADDRESS               61920013
         SPACE                                                          61960013
*              PICK UP BCD LENGTH AND SEE IF THIS IS A QUALIFIED NAME   62000013
*        OR ILLEGAL BCD LENGTH.                                         62040013
         SPACE                                                          62080013
         XR    GR1,GR1                 PICK UP                          62120013
         IC    GR1,0(0,GR7)            PICK UP BCD                      62160013
*                                      IF SO IT IS AN ERROR             62200013
         L     GR2,CESTKA              PICK UP START OF STACK           62240013
         ST    GR7,0(GR4,GR2)          STORE START OF TEXT AT BOTTOM    62280013
         AR    GR7,GR1                 IF NOT BUMP TO END OF BCD        62320013
         SPACE                                                          62360013
*              IS NEXT IN TEXT A . IF SO, THIS IS A QUALIFIED NAME      62400013
         SPACE                                                          62440013
         CLI   1(GR7),CEFSTP           IS NEXT ITEM A .                 62480013
         BC    CEBNE,CENQUL            NO SO THIS IS NOT A QUALIFIED    62520013
*                                      NAME                             62560013
         SPACE                                                          62600013
*              QUALIFIED NAME SO WORK ALONG TO ITS END SAVING START OF  62640013
*        EACH NEW BCD IN A STACK AND KEEPING A COUNT.                   62680013
         SPACE                                                          62720013
CEIDLP   LA    GR4,4(0,GR4)            BUMP STACK COUNT                 62760013
         LA    GR7,2(0,GR7)            BUMP SCAN POINTER OVER .         62800013
         ST    GR7,0(GR4,GR2)          SAVE ADDRESS OF NEXT BCD LENGTH  62840013
*                                      BYTE                             62880013
         IC    GR1,0(0,GR7)            NO, SO PICK UP LENGTH            62920013
         AR    GR7,GR1                 AND BUMP SCAN POINTER TO END OF  62960013
         CLI   1(GR7),CEFSTP           BCD. IS NEXT ITEM .              63000013
         BC    CEBE,CEIDLP             YES, SO CONTINUE SCAN            63040013
         BC    CEBR,CENDQL             NO, SO FINISH HERE               63080013
         SPACE 2                                                        63120013
*              SET FLAG ON AS THIS IS A NON-QUALIFIED NAME              63160013
         SPACE                                                          63200013
CENQUL   OI    CEFLAG,NONQUL           SET NON QUALIFIED BIT ON         63240013
         SPACE                                                          63280013
*              SAVE STACK COUNT AND POINT AT START OF BCD               63320013
         SPACE                                                          63360013
CENDQL   ST    GR4,STKCNT              SAVE STACK COUNT                 63400013
         ST    GR7,ENDADR              SAVE ADDRESS OF LAST BYTE OF     63440013
         L     GR7,0(GR2,GR4)          PICK  UP LAST ENTRY IN STACK     63480013
         SPACE                                                          63520013
*              SET UP REGISTERS FOR CALL TO HASH ROUTINE                63560013
         SPACE                                                          63600013
         BCTR  GR1,0                   REDUCE GR1 TO BCD LENGTH-1       63640013
         LA    GR5,1(0,GR7)            POINT GR5 AT THE BCD             63680013
         LR    GR14,GR1                SAVE GR1 IN GR14                 63720013
         BAL   GR15,CHASH              BRANCH TO HASH ROUTINE           63760013
*********************************************************************** 63800013
         L     GR2,ZHASH(0,GRDIC)      SET GR2 TO POINT AT START OF HAS 63840013
       AR      GR2,GR0                 GR2 POINTS AT THE CORRECT ENTRY  63880013
         CLC   0(2,GR2),CEZERO         IS HASH ENTRY ZERO AND A STOPPER 63920013
         BC    BE,EWRR5                IF SO, IDENTIFIER NOT REFERRED   63960013
*                                    TO ELSEWHERE. GO TO CREATE A DUMMY 64000013
*                                    DICTIONARY REFERENCE               64040013
CEC2A    MVC   PAR1+2(2,GRDIC),0(GR2)  IN HASH TABLE SO WE MOVE POINTER 64080013
         MVC   CELSYM(2),0(GR2)         TO DICT ENTRY FROM HASG TABLE   64120013
         ST    GR14,CEG14              SAVE REGISTER 14                 64160013
         BAL   GR3,EWGET3              GET ABSOLUTE ENTRY IN GR3        64200013
         L     GR14,CEG14              RESTORE REGISTER 14              64240013
         EJECT                                                          64280013
*        FROM ENTRY IN HASH TABLE. CHASH RETURNED OFFSET FROM START OF  64320013
*        HASH TABLE IN GR0. ADDRESS OF START OF HASH GABLE IS IN        64360013
*        COMMUNICATION REGION.                                          64400013
         SPACE                                                          64440013
*              IF THIS SHOULD BE A STRUCTURE AND IS NOT,THEN THERE IS   64480013
*        NO POINT DOING ANY MORE TESTING                                64520013
         SPACE                                                          64560013
CEGOAG   TM    CEFLAG,NONQUL           IS NOT QUALIFIED NAME FLAG ON    64600013
         BC    CEBO,CE3A               YES, SO BRANCH TO  COMPARE BCD   64640013
         TM    0(GR3),CESTRC           IS THIS A STRUCTURE              64680013
         BC    CEBO,CE3A               YES, SO COMPARE BCD              64720013
         CLI   0(GR3),CEFPCB           IS IT A FORMAL PARAMETER         64760013
         BC    CEBNE,CE22              NO, SO TRY AGAIN                 64800013
         SPACE                                                          64840013
*              TEST BCD. IF BCD IN DICTIONARY AND TEXT DO NOT AGREE     64880013
*        THEN RETURN IS TO RETURN ADDRESS 14.                           64920013
         SPACE                                                          64960013
CE3A     BAL   GR15,CE3XX                                               65000013
         BC    CEBR,CEAGRE             YES,AGREES.                      65040013
         BC    CEBR,CE22               NO BCD AGREEMENT                 65080013
         EJECT                                                          65120013
*        THIS ROUTINE COMPARES THE SOURCE VARIABLE AND DICT ENTRY TO    65160013
*        SEE IF THE LENGTH OF THE BCD'S IS THE SAME AND IF SO           65200013
*        WHETHER THE BCD IS THE SAME.                                   65240013
*        GR7 POINTS TO THE LENGTH BYTE IN THE SOURCE TEXT               65280013
*        IF VARIABLE IS A FORMAL PARAMTER THEN GR3 IS SET TO THE        65320013
*        DETAILED DICT ENTRY IF AGREEMENT WAS FOUND IN THE BCD'S.       65360013
*        IF NO BCD IS FOUND A RETURN IS MADE TO SCAN THE HASH CHAIN .   65400013
         SPACE 2                                                        65440013
CE3XX    TM    0(GR3),X'80'            IS BCD ATTACHED TO THIS ENTRY    65480013
         BC    CEBO,CE22               NO, SO BRANCH                    65520013
         MVC   CELENG+2(2),1(GR3)      YES,SO PICK UP LENGTH UP TO BCD  65560013
         L     GR1,CELENG              LOAD LENGTH TO BCD IN GR1        65600013
         XR    GR2,GR2                                                  65640013
         IC    GR2,0(GR1,GR3)          PICK UP BCD LENGTH OF DICT ENTRY 65680013
         CR    GR2,GR14                COMPARE REGISTERS TO SEE IF BCD  65720013
         BC    CEBNE,CE22B             LENGTHS ARE EQUAL. NO,SO BRANCH  65760013
         STC   GR2,CECOMP+1            YES,SO IS BCD THE SAME. SET UP   65800013
         AR    GR1,GR3                 INSTRUCTION.GR1 POINTS AT LENGTH 65840013
         SPACE 2                                                        65880013
*                       IF LENGTHS AGREED, COMPARE BCDS                 65920013
         SPACE                                                          65960013
*                       IF AGREEMENT IS NOT COMPLETE BUMP RETURN ADDRES 66000013
*        BY 4                                                           66040013
         SPACE                                                          66080013
CECOMP   CLC   1(0,GR1),1(GR7)         COMPARE BCD'S                    66120013
         BC    CEBE,CE22CZ             THE SAME SO RETURN               66160013
         SPACE 2                                                        66200013
CE22B    LA    GR15,4(0,GR15)          BUMP RETURN ADDRESS BY 4         66240013
CE22CZ   BCR   CEBR,GR15                                                66280013
         SPACE 5                                                        66320013
*                       IF THIS IS A FORMAL PARAMETER ENTRY THEN ADJUST 66360013
*        POINTER TO COMPLETE DATA ENTRY. IF NONE EXISTS IT IS AN ERROR. 66400013
         SPACE                                                          66440013
CE22CC   CLI   0(GR3),X'40'            IS THIS A FORMAL PARAMETER       66480013
         BC    CEBNE,CE2K              NO, SO RETURN                    66520013
         CLC   CENWAD(2,GR3),CEZERO    IS THERE A FULL ENTRY'S ADDRESS  66560013
         BC    CEBNE,CEFPQQ            YES                        52168 66600064
         SPACE 1                                                        66606064
         TM    CEFLAG,NONQUL           QUALIFIED NAME?            52168 66612064
         BC    CEBZ,CE22     YES - CONTINUE SCAN OF HASH CHAIN    52168 66618064
         BC    CEBR,ANYYET   NO - ERROR IF AN ITEM NOT YET FOUND  52168 66624064
         SPACE 1                                                        66630064
*********************************************************************** 66640013
CEFPQQ   MVC   PAR1+2(2,GRDIC),CEFPFA(GR3) YES SO PICK UP FULL ENT AD   66680013
         MVC   CEFRSM(2),CELSYM        SAVE SYMBOLIC ADDR. OF FP ENTRY  66720013
         MVC   CELSYM(2),CEFPFA(GR3)      AND                           66760013
         ST    GR3,CEFPSR              SAVE ADDRESS OF FP ENTRY         66800013
         ST    GR14,CEG14              SAVE REGISTER 14                 66840013
         BAL   GR3,EWGET3              GET ABSOLUTE ENTRY IN GR3        66880013
         L     GR14,CEG14              RESTORE REGISTER 14              66920013
*********************************************************************** 66960013
CE22C    BC    CEBR,CE2                                                 67000013
         EJECT                                                          67040013
*        CHECK TO SEE IF DICT ENTRY COULD BE A VALID ENTRY              67080013
         SPACE                                                          67120013
CEAGRE   BCTR  GR1,0                   PICK  UP LEVL NO                 67160013
         CLC   CECURL(1),0(GR1)        IS CURRENT LEVEL NUMBER THE SAME 67200013
         BC    CEBE,CE22CC             AS DICT ENTRY'S. YES SO BRANCH   67240013
         BC    CEBL,CE22               LESS THAN                        67280013
         SPACE 2                                                        67320013
*                       THIS IS THE SECTION TO SCAN SECOND LEVEL TABLE  67360013
*        TO SEE IF THIS LEVEL IS KNOWN FROM THE CURRENT LEVEL           67400013
         SPACE                                                          67440013
CEJ31    XR    GR15,GR15               CLEAR GR15                       67480013
         LR    GR5,GR15                AND GR5                          67520013
         LR    GR2,GR15                AND GR2                          67560013
         IC    GR15,CECURL             PICK UP CURRENT LEVEL NO IN GR15 67600013
         IC    GR5,0(0,GR1)            PICK UP DICT LEVEL NO IN GR5     67640013
         L     GR4,ZCDSTK(0,GRDIC)     PICK UP STACK ADDRESS            67680013
CELOOP   IC    GR2,0(GR15,GR4)         PICK UP CONSTANT IN TABLE        67720013
         CR    GR5,GR2                 IS IT EQUAL TO    DICT LEVEL     67760013
         BC    CEBE,CE22CC             YES, SO BRANCH                   67800013
         BC    CEBH,CE22               IS DICT LEVEL GREATER,YES SO OUT 67840013
         LR    GR15,GR2                NO, SO P-CK UP NEW OFFSET FROM   67880013
         BC    CEBR,CELOOP             START OF STACK AND TRY AGAIN     67920013
         SPACE 2                                                        67960013
*              THE BCD AND LEVEL NUMBER ARE SATISFACTORY. SAVE LEVEL    68000013
*        NUMBER. IF THIS IS A QUALIFIED NAME WE MUST START TO SCAN      68040013
*        STRUCTURE TO SEE IF IT IS THE RIGHT ONE. IF NOT THEN THIS      68080013
*        ENTRY MAY BE THE FINAL ONE                                     68120013
         SPACE                                                          68160013
CE2K     MVC   CEFRSM(2),CELSYM        SAVE SYMBOLIC ADDRESS OF ENTRY   68200013
*                                      WITH BCD                         68240013
CE2      MVC   CELVLX(1),0(GR1)        SAVE BLOCK LEVEL                 68280013
         TM    EWOTH3(GR3),CEFPCB      IS THIS PART OF A LIKE     15793 68290017
         BC    EWBO,CE22             EXPANSION?  THEN TRY AGAIN.  15793 68300017
         TM    CEFLAG,NONQUL           IS THIS A QUALIFIED NAME         68320013
         BC    CEBO,CENRND             NO, SO BRANCH OUT                68360013
         TM    0(GR3),CESTRC           IS THIS ENTRY A STRUCTURE        68400013
         BC    CEBZ,CEPKUP             NO, SO GO TO CONTINUE SCAN OF    68440013
*                                      HASH CHAIN                       68480013
*              SEE IF WE HAVE A DICTIONARY REFERENCE IN STORE FOR THIS  68600013
*        TEXT  ITEM. IF NOT SAVE THIS ONE. IF YES AND ITS COUNT IS NOT  68640013
*        THE SAME LEAVE THE STORE ALONE, OTHERWISE SAVE CURRENT REFER-  68680013
*        ENCE                                                           68720013
         SPACE                                                          68760013
CESTTS   CLC   OLDSTR+2(2,GRDIC),CEZERO     IS OLD STORE EMPTY          68800013
         BC    CEBE,CEADSV             YES                              68840013
         CLC   OLDLVL(1),CELVLX        NO, SO ARE BLOCK COUNT  DIFFER-  68880013
         BC    CEBNE,CEPOST            ENT, NO SO BRANCH OUT AT END     68920013
CEADSV   MVC   OLDSYM(2),CELSYM        SAVE SYMBOLIC ADDRESS AND        68960013
         MVC   OLDLVL(1),CELVLX        BLOCK COUNT                      69000013
         SPACE 2                                                        69040013
*              NOW THAT A VALID REFERENCE HAS BEEN FOUND SCAN DOWN THE  69080013
*        CHAIN WITHIN THE STRUCTURE MATCHING ITS BCD WITH THE TEXT      69120013
         SPACE                                                          69160013
         L     GR2,STKCNT              PICK UP STACK COUNT              69200013
         L     GR1,CESTKA              PICK UP START OF STACK           69240013
         MVC   CESTSM(2),CELSYM        SAVE SYMBOLIC ADDR OF BCD  52168 69280064
*                                      ENTRY                            69320013
         SPACE                                                          69360013
*              GET ADDRESS OF CONTAINING STRUCTURE, SEE IF THIS IS END  69400013
*        OF STACK. IF SO, THIS STRUCTURE SCAN IS OVER. IF NOT, REDUCE   69440013
*        STACK COUNT AND LOOK AT NEXT BCD ELEMENT IN TEXT               69480013
CESTSC   BAL   GR4,CESTUC              GO TO GET ADDRESS OF CONTAINING  69520013
*                                      STRUCTURE                        69560013
         LTR   GR2,GR2                 IS STACK COUNT ZERO              69600013
         BC    CEBZ,CEPMST             YES, SO BRANCH OUT               69640013
         S     GR2,CE4                 REDUCE STACK COUNT BY 4          69680013
         SPACE                                                          69720013
*              IF THE ADDRESS OF THE CONTAINING STRUCTURE IS ZERO THEN  69760013
*        WE ARE ALREADY AT END OF THIS STRUCTURE AND AS THE END OF TEXT 69800013
*        HAS NOT BEEN REACHED WE HAD BETTER TRY AGAIN                   69840013
         SPACE                                                          69880013
CECSTS   CLC   PAR1+2(2,GRDIC),CEZERO  IS CONTAINING STRUC ADDR ZERO    69920013
         BC    CEBE,CEPKUP             YES, SO CONTINUE SCAN            69960013
         L     GR7,0(GR2,GR1)          NO, SO PICK UP NEXT TEXT ADDRESS 70000013
         BAL   GR3,EWGET3              GET ABSOLUTE ENTRY IN GR3        70040013
         TM    0(GR3),CENOBC           HAS THIS ANY BCD                 70080013
         BC    CEBO,CEFPHO             NO, SO GO TO FP ENTRY            70120013
         SPACE                                                          70160013
*              WE ARE NOW LOOKING AT NEXT STRUCTURE OR ITS FORMAL PARA- 70200013
*        METER ENTRY. NOW TEST BCD FOR AGREEMENT. IF AGREEMENT OCCURS   70240013
*        CONTINUE SCAN,IF NOT THEN REFERENCE IS NOT CONTINUOUS SO WE    70280013
*        SET FLAG ON AND CONTINUE TO SCAN STRUCTURE TO FIND AN AGREEING 70320013
*        BCD                                                            70360013
         SPACE                                                          70400013
CEBCDC   XR    GR14,GR14               CLEAR GR14                       70440013
         IC    GR14,0(0,GR7)           PICK UP BCD LENGTH               70480013
         BCTR  GR14,0                                                   70520013
         STM   GR1,GR2,CEDMP1          SAVE REGISTERS GR1 AND GR2       70560013
         BAL   GR15,CE3XX              GO TO COMPARE BCD'S              70600013
         BC    CEBR,CESTSX             AGREEMENT SO CONTINUE SCAN       70640013
         OI    CEFLOG,NONCON           NO AGREEMENT SO SET NOT CONTIN-  70680013
*                                      UOUS FLAG ON                     70720013
         LM    GR1,GR2,CEDMP1          RESTORE GR1 AND GR2              70760013
         BAL   GR4,CESTUC              GET NEXT STRUCTURE MEMBER IN     70800013
         BC    CEBR,CECSTS                                              70840013
CESTSX   LM    GR1,GR2,CEDMP1          RESTORE REGISTERS GR1,GR2        70880013
         BC    CEBR,CESTSC             CHAIN AND TRY AGAIN              70920013
         SPACE 2                                                        70960013
*              END(START) OF TEXT HAS BEEN REACHED SO SEE IF THIS IS    71000013
*        ALSO THE END(START) OF THE STRUCTURE. IF IT IS NOT WE SET      71040013
*        MINSTR FLAG ON.                                                71080013
         SPACE                                                          71120013
CEPMST   CLC   PAR1+2(2,GRDIC),CEZERO  IS THIS A MAJOR STRUCTURE        71160013
         BC    CEBE,CEOSTS             YES, SO SKIP NEXT INSTRUCTION    71200013
         OI    CEFLOG,MINSTR           NO, SO SET FLAG ON               71240013
         SPACE 2                                                        71280013
*              IF THERE IS NO DICTIONARY REFERENCE IN STORE THEN WE     71320013
*        MUST SAVE THIS ONE AND THE FLAGS                               71360013
         SPACE                                                          71400013
CEOSTS   CLC   OLDSTR+2(2,GRDIC),CEZERO IS OLD STORE ZERO               71440013
         BC    CEBNE,OLDFTS            NO, SO GO TO CARRY OUT MORE TEST 71480013
         SPACE                                                          71520013
*              SAVE THIS DICTIONARY REFERENCE AND ASSOCIATED FLAGS AND  71560013
*        TURN AMBIGUOUS FLAG OFF                                        71600013
         SPACE                                                          71640013
CESVLE   MVC   OLDSTR+2(2,GRDIC),OLDSYM UPDATE OLD STORE                71680013
         MVC   OLDFLG(1),CEFLOG        SAVE FLAGS                       71720013
         NI    CEFLAG,NOAMBG           TURN AMBIGUOUS FLAG OFF          71760013
         BC    CEBR,CEPKUP             AND TRY AGAIN.                   71800013
         SPACE                                                          71840013
*              NOW TEST THE NEW AND OLD FLAGSTO SEE IF THIS             71880013
*        IS A VALID ENTRY AN INVALID ENTRY OR AN AMBIGUOUS ENTRY        71920013
         SPACE                                                          71960013
OLDFTS   TM    OLDFLG,NONMIN           ARE BOTH OLD FLAGS OFF           72000013
         BC    CEBNZ,CEBOFF            NO, SO BRANCH                    72040013
         TM    CEFLOG,NONMIN           YES, SO ARE BOTH NEW FLAGS OFF   72080013
         BC    CEBNZ,CEPKUP            NO, SO CONTINUE SCAN. YES THEN   72120013
*                                      IT IS AN AMBIGUOUS ENTRY         72160013
         SPACE 2                                                        72200013
*              FOR AN AMBIGUOUS ENTRY TURN FLAG ON AND TRY AGAIN        72240013
         SPACE                                                          72280013
CEAMBG   OI    CEFLAG,AMBFLG           SET AMBIGUOUS FLAG ON            72320013
         BC    CEBR,CEPKUP                                              72360013
         SPACE 2                                                        72400013
*              OLD STORE WAS NOT EMPTY SO TEST THE OLD AND CURRENT FLAG 72440013
*        TO SEE WHICH IS THE BETTER ENTRY OR IF THERE IS AMBIGUITY.     72480013
*              BOTH OLD FLAGS WERE NOT OFF SO IF BOTH NEW FLAGS ARE OFF 72520013
*        THEN THIS IS THE REFERENCE TO SAVE                             72560013
         SPACE                                                          72600013
CEBOFF   TM    OLDFLG,NONMIN           ARE BOTH OLD FLAGS ON            72640013
         BC    CEBO,CEBTON             YES, SO GO TO TEST NEW FLAGS     72680013
         TM    CEFLOG,NONMIN           NO, SO ARE BOTH NEW FLAGS OFF    72720013
         BC    CEBZ,CESVLE             YES, SO SAVE THIS ENTRY          72760013
         BC    CEBR,CEAMBG                                              72800013
         SPACE                                                          72840013
*              BOTH OLD FLAGS WERE ON, SO UNLESS BOTH NEW FLAGS ARE OFF 72880013
*        THIS IS AN AMBIGUOUS REFERENCE                                 72920013
         SPACE                                                          72960013
CEBTON   TM    CEFLOG,NONMIN           ARE BOTH NEW FLAGS OFF           73000013
         BC    CEBZ,CESVLE             YES, SO SAVE ADDRESS             73040013
         BC    CEBR,CEAMBG             NO, SO THIS IS AMBIGUOUS         73080013
         SPACE 2                                                        73120013
*              HASH CHAIN SLOT WAS EMPTY SO THIS IS END OF THE SEARCH   73160013
*        NOW SEARCH STORES ETC TO SEE IF ENTRY HAS BEEN FOUND. IF NON   73200013
*        HAS BEEN FOUND FOR A QUALIFIED NAME OR ONLY AN AMBIGUOUS       73240013
*        REFERENCE THEN THIS IS AN ERROR. IF NON HAS BEEN FOUND FOR A   73280013
*        NON-QUALIFIED NAME THEN A DEFAULT DATA DICTIONARY ENTRY MUST   73320013
*        BE MADE                                                        73360013
         SPACE 2                                                        73400013
CEC31X   LA    GR2,3(0,GR3)            SET GR2 3 BYTES BEFORE ENTRY     73440013
CEC31    TM    CEFLAG,NONQUL           IS NON QUALIFIED FLAG ON         73480013
         BC    CEBZ,CEPOST             NO, SO TEST REST OF FLAGS        73520013
ANYYET   EQU *                                                    52168 73540064
         CLC   OLDSTR+2(2,GRDIC),CEZERO YES, SO IS STORE EMPTY          73560013
         BC    BE,EWRR5                YES, SO THIS IS AN ERROR         73600013
CEPOST   TM    CEFLAG,AMBFLG           IS AMBIGUOUS FLAG ON             73640013
         BC    CEBO,CERR3              YES, SO GO TO GIVE MESSAGE       73680013
         CLC   OLDSTR+2(2,GRDIC),CEZERO  IS STORE EMPTY                 73720013
         BC    CEBNE,CEFIN1            NO, SO GO TO PUT DICTIONARY REF- 73760013
*                                      ERENCE INTO TEXT                 73800013
         BC    EWBR,EWRR5              YES, SO ITS AN ERROR             73840013
         SPACE                                                          73880013
*              NEW DICTIONARY ENTRY NEEDED SO SET UP PARAMETERS TO MAKE 73920013
         SPACE                                                          73960013
         SPACE 2                                                        74000013
*              ROUTINE TO PICK UP ADDRESS OF CONTAINING STRUCTURE. ON   74040013
*        RETURN THE SYMBOLIC ADDRESS IS IN PAR1                         74080013
         SPACE                                                          74120013
CESTUC   MVC   PAR1+2(2,GRDIC),CESTSM  PICK UP SYMBOLIC ADDR OF STRUCT  74160013
         L     GR15,ZDRFAB(0,GR11)     -TURE AND CONVERT TO ABSOLUTE    74200013
         BALR  GR14,GR15                                                74240013
         L     GR15,PAR1(0,GRDIC)      GR15 POINTS AT START OF STRUCT   74280013
         LR    GR5,GR15                SET GR5 TO START OF STRUCTURE    74320013
         TM    0(GR15),CEBASE          IS THIS A BASE ELEMENT           74360013
         BC    CEBNO,CEDIMQ            NO, SO SKIP NEXT INSTRUCTION     74400013
         LA    GR5,CEBEPL(0,GR5)       YES, SO BUMP COUNT BY ADDITIONAL 74440013
*                                      NUMBER OF BYTES                  74480013
         SPACE                                                          74520013
*              CALCULATE TOTAL OFFSET OF STRUCTURE INFORMATION FROM     74560013
*        START OF VARIABLE INFORMATION IN A STRUCTURE MEMBER            74600013
         SPACE                                                          74640013
CEDIMQ   TM    0(GR15),CEDIMS          IS THIS A DIMENSIONED STRUCTURE  74680013
         BC    CEBZ,CENOUN             NO, SO SKIP NEXT INSTRUCTION     74720013
         LA    GR5,CEDIMZ(0,GR5)       YES, SO BUMP BY DIM INFO LENGTH  74760013
CENOUN   MVC   PAR1+2(2,GRDIC),CEVARN+CECNSR(GR5) MOVE ADDRESS OF CON-  74800013
         MVC   CESTSM(2),PAR1+2(GRDIC) TAINING STRUCTURE INTO PAR1 AND  74840013
*                                      STORE                            74880013
         BCR   CEBR,GR4                AND RETURN                       74920013
         SPACE 2                                                        74960013
*              ENTRY HAS NO BCD ATTACHED SO GO BACK TO FORMAL PARAMETER 75000013
*        ENTRY TO COMPARE THE BCD.                                      75040013
         SPACE                                                          75080013
CEFPHO   MVC   PAR1+2(2,GRDIC),CEFPCH(GR3) PICK UP POINTER TO FP ENTRY  75120013
         BAL   GR3,EWGET3              GET ABSOLUTE ENTRY IN GR3        75160013
         BC    CEBR,CEBCDC                                              75200013
         SPACE 2                                                        75240013
*              THIS IS A SUCCESSFUL REFERENCE AND THIS IS A NON-QUALIF- 75280013
*        IED NAME SO IF THIS DICTIONARY REFERENCE IS NOT A STRUCTURE WE 75320013
*        ARE CORRECT                                                    75360013
         SPACE                                                          75400013
CENRND   TM    0(GR3),EWSMEM           IS THIS A STRUCTURE              75440013
         BC    CEBO,CESTTS             YES SO TRY ONCE MORE             75480013
         CLC   OLDSTR+2(2,GRDIC),CEZERO IS STORE EMPTY                  75520013
         BC    CEBNE,CEPOST            NO, SO BRANCH TO TEST ENTRY      75560013
         MVC   OLDSTR+2(2,GRDIC),CELSYM        SAVE DICTIONARY REF      75600013
         SPACE 2                                                        75640013
*              FINISH OFF BY PUTTING ZERO BYTE AND REFERENCE INTO TEXT  75680013
*        BUMPING SCAN POINTER TO END OF VARIABLE AND RETURNING          75720013
         SPACE                                                          75760013
CEFIN1   LH    GR6,CECTST+2(GRDIC)     PICK UP DICTIONARY REFERENCE     75800013
         STH   GR6,PAR1+2(0,GRDIC)     AND CONVERT TO ZERO              75840013
         BAL   GR6,EWGET6              GET ABSOLUTE ENTRY IN GR6        75880013
CERENT   LM    GR14,GR5,CEDUMP         RESTORE REGISTERS                75920013
         BCR   EWBR,GR2                RETURN                           75960013
         EJECT                                                          76000013
*              PICK UP START OF TEXT ETC AND TRY SCAN AGAIN. IF HASH    76040013
*        CHAIN IS ZERO THEN WE HAVE FINISHED                            76080013
         SPACE                                                          76120013
CEPKUP   MVC   PAR1+2(2,GRDIC),CEFRSM  PICK UP DICTIONARY REFERENCE OF  76160013
         BAL   GR3,EWGET3              GET ABSOLUTE ENTRY IN GR3        76200013
CE22     CLC   3(2,GR3),CEZERO         IS HASH CHAIN ZERO               76240013
         BC    CEBE,CEC31X             YES, SO END SCAN                 76280013
         SPACE                                                          76320013
*              HASH CHAIN HAS ENTRY SO SET UP POINTERS ETC FOR NEXT TRY 76360013
         SPACE                                                          76400013
         MVC   CELSYM(2),3(GR3)        IN HASH CHAIN                    76440013
         MVC   PAR1+2(2,GRDIC),3(GR3)  PICK UP ADDRESS OF NEXT ENTRY    76480013
         BAL   GR3,EWGET3              GET ABSOLUTE ENTRY IN GR3        76520013
         L     GR2,STKCNT              PICK UP STACK COUNT              76560013
         L     GR4,CEKSTA              PICK UP START OF STACK           76600013
         L     GR7,0(GR2,GR4)          AND POINT GR7 AT START OF TEXT   76640013
         XR    GR14,GR14               CLEAR GR14                       76680013
         IC    GR14,0(0,GR7)           PICK UP BCD LENGTH               76720013
         BCTR  GR14,0                  REDUCE BY ONE                    76760013
         MVI   CEFLOG,X'00'            CLEAR FLAGS AND TRY AGAIN        76800013
         BC    CEBR,CEGOAG             GO TO COMPARE BCD ETC...         76840013
         EJECT                                                          76880013
*                       ROUTINE CHASH                                   76920013
*                                                                       76960013
*              FUNCTION/OPERATION.  THIS ROUTINE DERIVES A FUNCTION     77000013
*        FROM THE BCD PASSED TO IT.  THE FUNCTION IS LESS THAN 422      77040013
*        AND IS EVEN. IT IS TO BE USED AS AN OFFSET IN THE HASH TABLE   77080013
*        GIVING THE HEAD OF THE HASH CHAIN LINKING BCD'S WITH THE SAME  77120013
*        HASH FUNCTION.                                                 77160013
*                                   THE FUNCTION IS OBTAINED BY EXTEND- 77200013
*        ING THE BCD WITH ZEROES UNTIL A MULTIPLE OF 4 BYTES LONG, THEN 77240013
*        ADDING 4 BYTE LENGTHS.  THE SUM IS DIVIDED BY 211.  THE        77280013
*        REMAINDER IS SET POSITIVE AND DOUBLED TO GIVE THE HASH RESULT  77320013
*        WHICH IS RETURNED.                                             77360013
*                                  THE CALLING SEQUENCE IS -            77400013
*        BAL   GRRZ,CHASH   (SEE NOTES)                                 77440013
*                                  THE ROUTINE IS ENTERED WITH -        77480013
*              (1) GRPTR POINTER TO BCD TO BE HASHED.                   77520013
*              (2) GRLTH CONTAINING LENGTH-1 OF THE BCD                 77560013
*              THESE REGISTERS ARE RETURNED UNALTERED.                  77600013
*                                                                       77640013
*              EXTERNAL ROUTINES - NONE.                                77680013
*                                                                       77720013
*              EXITS NORMAL - UNCONDITIONAL BRANCH ON RETURN REGISTER.  77760013
*                                                                       77800013
*              EXITS ERROR - NONE                                       77840013
*                                                                       77880013
*              TABLES/WORK AREAS.  A WORKSPACE CASPAC 32 BYTES LONG,    77920013
*        AND FULL WORD ALIGNED IS REQUIRED. THE BCD IS MOVED INTO IT    77960013
*        FOR FULL WORD ALIGNMENT AND FOR EXTENDING WITH ZEROES          78000013
*                                  A FULL WORD CONSTANT T11, VALUE 211, 78040013
*        IS ALSO REQUIRED.                                              78080013
*                                                                       78120013
*              NOTES.  THE RETURN REGISTER MUST BE SET UP BY A 'BRANCH  78160013
*        AND LINK' INSTRUCTION, SINCE THE PROGRAM MASK IS REQUIRED IN   78200013
*        THE TOP BYTE.                                                  78240013
*                      REGISTERS GRP, AND GRQ ARE REQUIRED FOR WORKING  78280013
*        AND THEIR ORIGIONAL CONTENTS ARE LOST.                         78320013
*                      REGISTERS GRP,GRQ AND GRLTH,GRHASH ARE REQUIRED  78360013
*        TO BE EVEN ODD REGISTER PAIRS.                                 78400013
         SPACE 5                                                        78440013
CHASH    SR    GRQ,GRQ                                                  78480013
         SPM   GRQ                     INHIBIT FIXED POINT OVERFLOW     78520013
*                                    INTERRUPTS DURING LOOP 'CARED'     78560013
*                                    BELOW.                             78600013
         LA    GRHASH,4                FOUR REQUIRED IN GRHASH, NOW AND 78640013
         LCR   GRP,GRHASH            LATER. SET GRP TO ONES IN ALL BITS 78680013
*                                    EXCEPT THE LAST TWO.               78720013
         NR    GRP,GRLTH               LENGTH-1 LESS LAST TWO BITS INTO 78760013
*                                      GRP                              78800013
         ST    GRQ,CASPAC(GRP)         CLEAR FOUR BYTES IN CASPAC AT    78840013
*                                    OFFSET EQUAL TO FIRST FULL WORD    78880013
*                                    SHORT OF END OF BCD WHEN IT IS     78920013
*                                    MOVED INTO CASPAC.                 78960013
         EX    GRLTH,CAH1              MOVE BCD INTO CASPAC.            79000013
         SPACE                                                          79040013
*              THE BCD IS NOW IN CASPAC AND IS EXTENDED TO A FULL WORD  79080013
*        BOUNDARY WITH ZEROS.                                           79120013
         SPACE                                                          79160013
         SR    GRP,GRP                                                  79200013
CARED    A     GRQ,CASPAC(GRP)         THIS LOOP ADDS FOUR BYTE LENGTHS 79240013
         BXLE  GRP,GRHASH,CARED      OF THE BCD INTO GRY UNTIL ALL IS   79280013
*                                    CONSUMED                           79320013
         SPACE                                                          79360013
         SR    GRP,GRP                                                  79400013
         D     GRP,T11                 DIVIDE SUM BY 211                79440013
         SPACE                                                          79480013
         LPR   GRHASH,GRP              SET REMAINDER POSITIVE           79520013
         AR    GRHASH,GRHASH           DOUBLE IT.                       79560013
         SPACE                                                          79600013
         SPM   GRRZ                    RESET PROGRAM MASK               79640013
         BCR   B,GRRZ                  RETURN                           79680013
         SPACE                                                          79720013
CAH1     MVC   CASPAC(0),0(GRPTR)      MOVE IN BCD                      79760013
         EJECT                                                          79800013
**********************************************************************  79810017
*                                                                       79820017
*              OFFSETS OF ENTRY POINTS TO ROUTINES IN IEMEV.            79830017
*                                                                       79840017
EWDCCY   EQU   EX+10                                                    79880015
EW7RST   EQU   EX+14                                                    79920015
EW2FNT   EQU   EX+18                                                    79960015
BASED    EQU   EX+22                                                    79980015
ALIGN    EQU   BASED+4                 TRANSFER VECTOR IN EV         I1 79990016
BCDTST   EQU   ALIGN+4                                             H158 79995017
         SPACE 4                                                        80000013
**********************************************************************  80020017
*                                                                       80040017
*              OFFSETS OF COMMON CONSTANT DATA IN IEMEV.                80060017
*                                                                       80080017
EWSNFG   EQU   EX+50           ******  HALFWORD ALIGNMENT ONLY  ******  80100017
EWFIPR   EQU   EWSNFG+1                                                 80120013
EWFLPR   EQU   EWFIPR+3                                                 80160013
EWRRZ    EQU   EWFLPR+3                                                 80200013
EWRRX    EQU   EWRRZ+3                                                  80240013
EWRRC    EQU   EWRRX+1                                                  80280013
EWCOMS   EQU   EWRRC+2                                                  80360013
EWORMS   EQU   EWCOMS+5                                                 80400013
EWORMX   EQU   EWORMS+5                                                 80440013
EWZERO   EQU   EWORMX+7                                                 80480013
EW3      EQU   EWZERO+4                                                 80520013
EWSTMS   EQU   EW3+4                                                    80560013
EW256    EQU   EWSTMS+4                                                 80600013
EWASTM   EQU   X'02'                                                    80640013
EWSCCT   EQU   EW256+4                                                  80680013
OLDLVL   EQU   EWSCCT+4                                                 80720013
CELVLX   EQU   OLDLVL+1                                                 80760013
CEFRSM   EQU   CELVLX+1                                                 80800013
CESTSM   EQU   CEFRSM+2                                                 80840013
OLDSYM   EQU   CESTSM+2                                                 80880013
CEFLAG   EQU   OLDSYM+2                                                 80920013
CEFLOG   EQU   CEFLAG+1                                                 80960013
OLDFLG   EQU   CEFLAG+2                                                 81000013
CEKSTA   EQU   CEFLAG+4                                                 81040013
CESTKA   EQU   CEKSTA                                                   81080013
STKCNT   EQU   CEKSTA+4                                                 81120013
TXTSTR   EQU   STKCNT+4                                                 81160013
CERSTA   EQU   TXTSTR+4                                                 81200013
ENDADR   EQU   CERSTA+4                                                 81240013
CE4      EQU   ENDADR+4                                                 81280013
CEDMP1   EQU   CE4+4                                                    81320013
T11      EQU   CEDMP1+8                                                 81360013
VARREP   EQU   T11+4                                                    81370015
BASFL    EQU   VARREP+1                                                 81380015
EWPHNM   EQU   BASFL+1                 'EVEWZZ'                    H150 81390017
         SPACE                                                          81400013
*                       WE USE SCRATCH CORE TO STORE OUR NON CONSTANT   81440013
*              DATA                                                     81480013
         SPACE                                                          81520013
EWSCRT   EQU   EWSCRX+4                                                 81560013
CASPAC   EQU   EWSCRT+120                                               81600013
CEDUMP   EQU   CASPAC+32                                                81640013
CELAST   EQU   CEDUMP+32                                                81680013
CEFPSR   EQU   CELAST+4                                                 81720013
EWGR1S   EQU   CEFPSR+4                                                 81760013
EWGR5S   EQU   EWGR1S+4                                                 81800013
EWA3     EQU   EWGR5S+4                                                 81840013
EWX1     EQU   EWA3+4                                                   81880013
EWSKST   EQU   EWX1+4                                                   81920013
CEG14    EQU   EWSKST+4                                                 81960013
EWST2F   EQU   CEG14+4                                                  82000013
EWSTST   EQU   EWST2F+4                                                 82040013
EWSYMD   EQU   EWSTST+4                                                 82080013
EWXPOT   EQU   EWSYMD+4                                                 82120013
EWT1     EQU   EWXPOT+4                                                 82160013
EWT2     EQU   EWT1+4                                                   82200013
EWT3     EQU   EWT2+4                                                   82240013
EWT3OL   EQU   EWT3+4                                                   82280013
EWTEMP   EQU   EWT3OL+4                                                 82320013
EWSFXX   EQU   EWTEMP+4                                                 82360013
EWTOEN   EQU   EWSFXX+4                                                 82400013
EWA1     EQU   EWTOEN+4                                                 82440013
EWA4     EQU   EWA1+4                                                   82480013
EWC1     EQU   EWA4+4                                                   82520013
EWDUMP   EQU   EWC1+4                                                   82560013
EWDCLN   EQU   EWDUMP+4                                                 82600013
EWTMDM   EQU   EWDCLN+4                                                 82640013
EWLKCH   EQU   EWTMDM+4                                                 82680013
EWLN     EQU   EWLKCH+4                                                 82720013
EWTXST   EQU   EWLN+4                                                   82760013
EWLNTB   EQU   EWTXST+4                                                 82800013
CELENG   EQU   EWLNTB+4                                                 82840013
CELSYM   EQU   CELENG+4                                                 82880013
CESVE    EQU   CELSYM+4                                                 82920013
EWNXCH   EQU   CESVE+4                                                  82960013
EWW1     EQU   EWNXCH+2                                                 83000013
CEFRST   EQU   EWW1+2                                                   83040013
EWLAC    EQU   CEFRST+2                                                 83080013
CESTNO   EQU   EWLAC+2                                                  83120013
CEHSF    EQU   CESTNO+1                                                 83160013
CELESN   EQU   CEHSF+1                                                  83200013
EWCF1    EQU   CELESN+1                                                 83240013
EWCF2    EQU   EWCF1+1                                                  83280013
CESW1    EQU   EWCF2+1                                                  83320013
CESW2    EQU   CESW1+1                                                  83360013
EWXFLG   EQU   CESW2+1                                                  83400013
EWERFG   EQU   EWXFLG+1                                                 83440013
EWCLLN   EQU   EWERFG+2-EWST2F                                          83480013
CEZERO   EQU   EWZERO                                                   83520013
CECURL   EQU   EWLAC+1                                                  83560013
EWLSTR   EQU   EWA4                                                     83600013
         EJECT                                                          83640013
*                       TRANSLATE TABLE FOR VARIABLE DATA               83680013
*                       EQUIVALENCES FOR VARIABLE INFORMATION           83720013
CX1      EQU   EWPOSZ                                                   83760013
CX2      EQU   EWSTSZ                                                   83800013
CX3      EQU   CX1+CX2                                                  83840013
CX4      EQU   EWDIMF                                                   83880013
CX8      EQU   EWSASZ                                                   83920013
CX12     EQU   CX8+CX4                                                  83960013
         SPACE 2                                                        84000013
CVARTB   DC    X'00'                                                    84040013
         DC    AL1(CX1)                                                 84080013
         DC    AL1(CX2)                                                 84120013
         DC    AL1(CX1+CX2)                                             84160013
         DC    AL1(CX4)                                                 84200013
         DC    AL1(CX4+CX1)                                             84240013
         DC    AL1(CX4+CX2)                                             84280013
         DC    AL1(CX4+CX2+CX1)                                         84320013
         DC    AL1(CX8)                                                 84360013
         DC    AL1(CX8+CX1)                                             84400013
         DC    AL1(CX8+CX2)                                             84440013
         DC    AL1(CX8+CX2+CX1)                                         84480013
         DC    AL1(CX8+CX4)                                             84520013
         DC    AL1(CX8+CX4+CX1)                                         84560013
         DC    AL1(CX8+CX4+CX2)                                         84600013
         DC    AL1(CX8+CX4+CX3)                                         84640013
EVARTB   EQU   CVARTB                                                   84680013
EWLIST   EQU   EWPHNM                                                   84720013
ZTXTND   EQU   ZLSTXT                                                   84760013
EWPIT    EQU   CEDUMP                                                   84800013
*                       PATCH AREA                                      84840013
         END   IEMEW                                                    84880013
