FA       TITLE 'IEMFA CONTEXT AND HOUSEKEPING PHASE, DICTIONARY PL/I F' 00040013
IEMFA    START 0                                                        00080013
         USING *,9                                                      00120013
         USING IEMFA+X'2000',GR12                                       00160013
         DC    C'FA'                                                    00200013
* R21.6  -(242000,243200),+(245600,*),+(246200,*),+(246600,*)     45888 00210056
* R21.6  +246800                                                  45888 00220056
         SPACE 5                                                        00240013
*        TITLE IEMFA,   HOUSEKEEPING AND CONTEXT PHASE OF THE DICTION-  00280013
*              ARY, OS/360 PL/1 COMPILER(F).                            00320013
         SPACE 3                                                        00360013
*              STATUS- CHANGE LEVEL O                                   00400013
*        THIS MODULE CONTAINS A FIX FOR APAR  11219                     00420015
         SPACE 3                                                        00440013
*              FUNCTION/OPERATION                                       00480013
*                       THIS PHASE TIDIES UP ANY GARBAGE LEFT BY PREV-  00520013
*        IOUS PHASES IN THE TEXT.                                       00560013
*                       IT MAKES DICTIONARY ENTRIES FOR CONSTANTS, P    00600013
*        FORMAT ITEMS AND CONTEXTUAL DECLARATIONS OF FILES AND ON COND- 00640013
*        ITIONS.                                                        00680013
*                      IT RECOGNISES AS NON-BUILTIN NAMES APPEARING IN  00720013
*      SOME SETS POSITIONS.                                             00760013
*                       IT REORDERS SUBSCRIPT LISTS ON QUALIFIED NAMES  00800013
*              SO THAT ALL SUBSCRIPTS APPEAR WITHIN ONE SET OF PAREN-   00840013
*        THESES AT THE END OF THE QUALIFIED NAME.                       00880013
*                       TEXT IS MOVED FROM AN INPUT AREA TO AN OUTPUT   00920013
*        AREA AND SPECIAL ACTION IS TAKEN WHEN CERTAIN KEYWORDS OR CODE 00960013
*        BYTES AS FOLLOWS:-                                             01000013
         SPACE                                                          01040013
*              PROCEDURE OR BEGIN- REMOVE CHAINS FROM AFTER CODE BYTE   01080013
*        AND PICK UP NEW BLOCK LEVEL AND COUNT                          01120013
*              DECLARE - REMOVE WHOLE STATEMENT                         01160013
*              ENTRY   - REMOVE WHOLE STATEMENT EXCEPT FOR SN AT START  01200013
*              END     - PICK UP BLOCK LEVEL AND COUNT OF CONTAINING    01240013
*        BLOCK                                                          01280013
*              SN,SL   - SAVE STATEMENT NUMBER                          01320013
*              SN2     - PICK UP BLOCK LEVEL AND COUNT OF BLOCK FOR     01360013
*        THIS ENTRY.                                                    01400013
*              ON      - STORE CURRENT BLOCK LEVEL AND COUNT AFTER      01440013
*        ENTRY AND IF THIS IS A FILE CONDITION SET UP MECHANISM FOR     01480013
*        ENSURING THAT BCD FOLLOWING IS TREATED AS A FILE               01520013
*              CALL    - REMOVE 4-BYTE CHAIN FROM TEXT                  01560013
*              EOB     - GET NEW TEXT BLOCK FOR INPUT                   01600013
*              EOP     - SET UP RELEVANT COMMUNICATIONS CELLS TO POINT  01640013
*        AT NEW END OF FIRST OR SECOND TEXT FILE DEPENDING ON WHETHER   01680013
*        THIS IS THE FIRST OR SECOND EOP ENCOUNTERED. IF IT IS THE      01720013
*        SECOND THEN ANY SCRATCH CORE IS RELEASED AND CONTROL RETURNED  01760013
*        TO COMPILER CONTROL                                            01800013
*              ITERATIVE DO - NEW BLOCK COUNT IS PICKED UP.             01840013
*              ZERO OR BLANK- REMOVE ALL BLANKS OR ZEROS FOLLOWING, UP  01880013
*        TO THE FIRST NON-BLANK CHARACTER UNLESS PROCESSING IS IN AN    01920013
*        ALLOCATE STATEMENT OR SECOND FILE                              01960013
*              LEFT PARENTHESIS  - BUMP BRACKET COUNT                   02000013
*              RIGHT PARENTHESIS - REDUCE BRACKET COUNT                 02040013
*              SEMI-COLON   - CLEAR ALL FLAGS AND BRACKET COUNT         02080013
         SPACE 3                                                        02120013
*              ENTRY POINTS                                             02160013
*                       IEMFA- ENTRY FROM COMPILER CONTROL. LOCATION OF 02200013
*        FIRST TEXT BLOCK IS OBTAINED FROM COMMUNICATIONS REGION OF     02240013
*        FIRST DICTIONARY BLOCK. NEW TEXT BLOCK IS OBTAINED AND NEXT    02280013
*        PHASE LOADED.                                                  02320013
*                       CENDTS- ENTRY FROM PHASE IEMFB AND INTERNALLY   02360013
*        TO TEST IF THE OUTPUT POINTER IS AT END OF CURRENT OUTPUT      02400013
*        BLOCK. IF SO A NEW TEXT BLOCK IS OBTAINED.                     02440013
         SPACE 3                                                        02480013
*              INPUT                                                    02520013
*                       TEXT BLOCKS IN CORE STORAGE.                    02560013
         SPACE 3                                                        02600013
*              OUTPUT                                                   02640013
         SPACE 3                                                        02680013
*              ENTRY POINTS                                             02720013
*                       IEMFA- ENTRY FROM COMPILER CONTROL. LOCATION OF 02760013
*        FIRST TEXT BLOCK IS OBTAINED FROM COMMUNICATIONS REGION OF     02800013
*        FIRST DICTIONARY BLOCK. NEW TEXT BLOCK IS OBTAINED AND NEXT    02840013
*        PHASE LOADED.                                                  02880013
*                       CENDTS- ENTRY FROM PHASE IEMFB AND INTERNALLY   02920013
*        TO TEST IF THE OUTPUT POINTER IS AT END OF CURRENT OUTPUT      02960013
*        BLOCK. IF SO A NEW TEXT BLOCK IS OBTAINED.                     03000013
         SPACE 3                                                        03040013
*              INPUT                                                    03080013
*                       TEXT BLOCKS IN CORE STORAGE.                    03120013
         SPACE 3                                                        03160013
*              OUTPUT                                                   03200013
*                       TEXT BLOCKS IN CORE STORAGE.                    03240013
         SPACE 3                                                        03280013
*              EXTERNAL ROUTINES                                        03320013
*                       ZDRFAB  -  COMPILER CONTROL ROUTINE TO CONVERT  03360013
*        DICTIONARY REFERENCES TO ABSOLUTE ADDRESSES.                   03400013
*                       ZDABRF  -  COMPILER CONTROL ROUTINE TO CONVERT  03440013
*        ABSOLUTE ADDRESS TO DICTIONARY REFERENCE.                      03480013
*                       ZTXTAB  -  COMPILER CONTROL ROUTINE TO CONVERT  03520013
*        SYMBOLIC TEXT ADDRESS TO ABSOLUTE ADDRESS.                     03560013
*                       ZUTXTC  -  COMPILER CONTROL ROUTINE TO OBTAIN   03600013
*        NEW TEXT BLOCK.                                                03640013
*                       ZTXTRF -  COMPILER CONTROL ROUTINE TO CONVERT   03680013
*              AN ABSOLUTE  ADDRESS TO A SYMBOLIC TEXT REFERENCE.       03720013
*                       ZDICRF -  COMPILER CONTROL ROUTINE TO MAKE A    03760013
*              DICTIONARY ENTRY AND RETURN ITS DICTIONARY REFERENCE.    03800013
*                       LOADW   -  COMPILER CONTROL ROUTINE TO LOAD     03840013
*        NEW PHASE AND WAIT TILL LOADING IS FINISHED                    03880013
*                       ZUERR   -  COMPILER CONTROL ROUTINE TO PUT      03920013
*        ERROR MESSAGE IN DICTIONARY. (ALSO KNOWN AS ZERROF)            03960013
*                       ZABORT  -  COMPILER CONTROL ROUTINE TO INTER-   04000013
*        RUPT                                                           04040013
*                       ZALTER  -  COMPILER CONTROL ROUTINE TO CHANGE   04080013
*        STATUS OF TEXT BLOCK.                                          04120013
*                       RLSCTL  - COMPILER CONTROL ROUTINE TO PASS      04160013
*        CONTROL TO ANOTHER PHASE                                       04200013
*                       CEDICN  - ROUTINE TO MAKE DICTIONARY ENTRY FOR  04240013
*        NORMAL VARIABLE, (CALLED AS CFPDER). LOCATED IN IEMFB.         04280013
*                       CEENT2  - ROUTINE TO MAKE DICTIONARY ENTRY FOR  04320013
*        VARIABLE WHICH HAS BEEN PASSED AS AN ARGUEMENT (CALLED AS      04360013
*        CFPDR2). LOCATED IN IEMFB.                                     04400013
*                       CECON   - ROUTINE TO MAKE DICTIONARY ENTRY FOR  04440013
*        CONSTANT UNLESS ENTRY IS ALREADY PRESENT AND TO RETURN THE     04480013
*        APPROPRIATE DICTIONARY REFERENCE. LOCATED IN IEMFB.            04520013
*                       CEPICT  - ROUTINE TO MAKE DICTIONARY ENTRY FOR  04560013
*        PICTURE (P FORMAT ITEM) UNLESS SAME PICTURE IS ALREADY PRESENT 04600013
*        RETURNS DICTIONARY REFERENCE OF ENTRY. LOCATED IN IEMFB.       04640013
         SPACE 3                                                        04680013
*              EXIT - NORMAL                                            04720013
*                       VIA COMPILER CONTROL ROUTINE RLSCTL             04760013
         SPACE 3                                                        04800013
*              EXIT - ABNORMAL                                          04840013
*                       VIA COMPILER CONTROL ROUTINE ZABORT ON A TER-   04880013
*        MINAL ERROR                                                    04920013
         SPACE 3                                                        04960013
*              WORK AREA                                                05000013
*                       THIS PHASE USES TWO TABLES IN SCRATCH CORE      05040013
*        OBTAINED BY PHASE IEMEG CONTAINING STACK OF LEVEL NUMBERS AND  05080013
*        THE HASH TABLE. ADDRESSES ARE OBTAINED FROM THE COMMUNICATIONS 05120013
*        REGION.                                                        05160013
         SPACE 3                                                        05200013
*              ATTRIBUTES                                               05240013
*                       NOT REUSEABLE                                   05280013
         SPACE 3                                                        05320013
*              NOTES                                                    05360013
*                      THIS PHASE WILL REQUIRE CHANGE OF LITERALS       05400013
*      ONCHAR AND ONSOURCE IF NATIONAL LANGUAGE CHANGES.                05440013
*                       REFERENCES TO EXTERNAL ROUTINES IN IEMFB, ARE   05480013
*        LOCATED AT AN ABSOLUTE OFFSET FROM START OF IEMFA AND ARE      05520013
*        BRANCH INSTRUCTIONS TO A TABLE OF BRANCH INSTRUCTIONS AT THE   05560013
*        START OF IEMFB. IEMFB ALSO REQUIRES SOME COMMUNICATION CELLS   05600013
*        WHICH ARE AT THE START OF THAT PHASE AND THESE ARE ALSO ABSOL- 05640013
*        UTE OFFSETS IN IEMFA.                                          05680013
*                       REGISTER USAGE                                  05720013
*                            GR7- POINTER TO INPUT TEXT                 05760013
*                            GR6- POINTER TO OUTPUT TEXT                05800013
*                            GR9- BASE REGISTER FOR PHASE IEMFA         05840013
*                            GR11 - BASE REGISTER FOR COMPILER CONTROL  05880013
*                            GR12 - BASE REGISTER FOR PHASE IEMFB       05920013
*                            GR13 - BASE REGISTER OF FIRST DICTIONARY   05960013
*                                   BLOCK                               06000013
*                            GR15 - UNIT REGISTER                       06040013
*                            ALL OTHER REGISTERS ARE SCRATCH.           06080013
        EJECT                                                           06120013
*                       EQUIVALENCES FOR OFFSETS FROM THE S TART OF     06160013
*                       VARIOUS DICTIONARY ENTRIES                      06200013
         SPACE 2                                                        06240013
CLBLCL   EQU   15       OFFSET OF C IN A LABEL VARIABLE                 06280013
CEOTH1   EQU   10       OFFSET OF OTHER1 CODE BYTE                      06320013
CEVRBT   EQU   11       OFFSET OF VARIABLE CODE BYTE                    06360013
CEOTH2   EQU   12       OFFSET OF OTHER2 CODE BYTE                      06400013
CEOTH3   EQU   13       OFFSET OF OTHER3 CODE BYTE                      06440013
CEOTH4   EQU   14       OFFSET OF OTHER4 CODE BYTE                      06480013
CETOCB   EQU   15                      OFFSET TO END OF 4 CODE BYTES    06520013
CENWAD   EQU   5        OFFSET OF FULL ENTRY'S ADDRESS IN FP ENTRY      06560013
CLVVAR   EQU   12       OFFSET OF VARIABLE BYTE IN LABEL VARIABLE       06600013
CLCLT    EQU   18       OFFSET OF C IN LABEL CONSTANT                   06640013
CFPADR   EQU   CENWAD                                                   06680013
CEFPFA   EQU   CENWAD                                                   06720013
CFPEL    EQU   7        OFFSET OF L IN FP ENTRY                         06760013
CFPEC    EQU   8        OFFSET OF C IN FP ENTRY                         06800013
CYTOP    EQU   11                      OFFSET OF LENGTH BYTE IN PICTURE 06840013
CYWHOL   EQU   13                      OFFSET OF PICTURE IN PICT ENTRY  06880013
CEDAPL   EQU   6                       NUMBER OF EXTRA BYTES IN A DATA  06920013
*                                      ENTRY OVER A STRUCTURE ENTRY     06960013
CESNLN   EQU   3                       LENGTH OF DATA AFTER SN          07000013
CESNSN   EQU   8                       OFFSET OF ST NO. IN LABEL CONST  07040013
CESN2C   EQU   11                      OFFSET OF C IN SN2 ENTRY         07080013
CESN2L   EQU   10                      OFFSET OF L IN SN2 ENTRY         07120013
CTOBCD   EQU   15                      OFFSET OF BCD IN CONSTANT ENTRY  07160013
CEDBCN   EQU   5                       OFFSET OF DATA BYTE IN CONSTANT  07200013
CEOFSL   EQU   4                       LENGTH OF OFFSET SLOT IN VAR-    07240013
*                                      IABLE INFORMATION                07280013
CETOVI   EQU   15                      LENGTH OF OFFSET TO VARIABLE     07320013
*                                      INFORMATION IN A STRUCTURE ENTRY 07360013
CETRST   EQU   1                       OFFSET OF TRUE LEVEL NUMBER      07400013
*                                      FROM START OF STRUCTURE VARIABLE 07440013
*                                      INFORMATION                      07480013
CENSAD   EQU   4                       OFFSET OF ADDRESS OF NEXT STRUCT 07520013
*                                      -URE IN CHAIN FROM START OF      07560013
*                                      STRUCTURE VARIABLE INFORMATION   07600013
CETOTL   EQU   CETOVI+CEOFSL+CETRST    OFFSET OF TRUE LEVEL NUMBER FROM 07640013
*                                      START OF STRUCTURE ENTRY         07680013
CETONS   EQU   CETOVI+CEOFSL+CENSAD    OFFSET OF NEXT STRUCTURE ADDRESS 07720013
*                                      FROM START OF STRUCTURE ENTRY    07760013
CECTLN   EQU   05                      LENGTH OF BCD FOR  COUNT         07800013
CELNLN   EQU   06                      LENGTH OF BCD FOR  LINENO        07840013
CEPRLN   EQU   08                      LENGTH OF BCD FOR  PRIORITY      07880013
NONCON   EQU   X'01'                   NON CONTINUOUS FLAG              07920013
NONQUL   EQU   X'01'                   NON QUALIFIED FLAG               07960013
QUAL     EQU   X'FF'-NONQUL            QUALIFIED FLAG                   08000013
MINSTR   EQU   X'10'                   MINOR STRUCTURE FLAG             08040013
NONMIN   EQU   X'11'                   NONCON AND MINSTR FLAGS          08080013
CEFPCB   EQU   X'40'                   FORMAL PARAMETER ENTRY INITIAL   08120013
*                                      CODE BYTE                        08160013
MAXBCD   EQU   X'1F'                   MAXIMUM BCD LENGTH               08200013
AMBFLG   EQU   X'02'                   AMBIGUOUS FLAG                   08240013
NOAMBG   EQU   X'FD'                   TURN OFF AMBFLAG MASK            08280013
CENOBC   EQU   X'80'                   NO BCD BIT IN INITIAL BYTE       08320013
CEBEPL   EQU   6                       ADDITIONAL BYTES IN BASE OVER    08360013
*                                      STRUCTURE ENTRY                  08400013
CEBASE   EQU   X'2F'                   INITIAL BYTE FOR BASE ELEMENT    08440013
CEDIMZ   EQU   3                       DIMENSION INFORMATION SIZE       08480013
CEVARN   EQU   19                      DISTANCE TO VARIABLE INFORMATION 08520013
*                                      IN STRUCTURE ENTRY               08560013
CECNSR   EQU   2                       OFFSET OF CONTAINING STRUCTURE   08600013
*                                      ADDRESS FROM START OF STRUCTURE  08640013
*                                      INFORMATION                      08680013
CEDIMS   EQU   X'10'                   DIMENSION BIT IN INITIAL CODE    08720013
*                                      BYTE                             08760013
CESTRC   EQU   X'20'                   STRUCTURE BIT IN INITIAL BYTE    08800013
CEMSTR   EQU   X'04'                   MAJOR STRUCTURE IN OTHER 4 BYTE  08840013
CEFPCH   EQU   3                       OFFSET OF FP POINTER IN DATA     08880013
*                                      ENTRY                            08920013
         SPACE 2                                                        08960013
*                       OFFSET OF VARIOUS CODE BITS IN CODE BYTES       09000013
         SPACE 2                                                        09040013
CESYM    EQU   X'80'    SYMBOL BIT IN OTHER 1 BYTE                      09080013
CESVD    EQU   X'10'    SAVED  BIT IN OTHER 2 BYTE                      09120013
CECNTL   EQU   X'03'    CONTROLLED CODE IN OTHER 2  BYTE                09160013
CEDMBT   EQU   X'40'    DIMENSION BIT IN VARIABLE BYTE                  09200013
CEAMBT   EQU   X'80'                   AMBIGUOUS BIT IN OTHER 4 BYTE    09240013
CENDSR   EQU   X'08'                   END OF STRUCTURE BIT IN OTHER 2  09280013
CEOFBT   EQU   X'80'    OFFSET SLOT BIT IN VARIABLE BYTE                09320013
         SPACE 2                                                        09360013
*                            EQUIVALENCES FOR BRANCH CODES              09400013
         SPACE 2                                                        09440013
CENOP    EQU   0                                                        09480013
CEBO     EQU   1                                                        09520013
CEBP     EQU   2                                                        09560013
CEBH     EQU   2                                                        09600013
CEBM     EQU   4                                                        09640013
CEBL     EQU   4                                                        09680013
CEBNE    EQU   7                                                        09720013
CEBNZ    EQU   7                                                        09760013
CEBZ     EQU   8                                                        09800013
CEBE     EQU   8                                                        09840013
CEBNL    EQU   11                                                       09880013
CEBNH    EQU   13                                                       09920013
CEBNO    EQU   14                                                       09960013
CEBR     EQU   15                                                       10000013
BNE      EQU   CEBNE                                                    10040013
BE       EQU   CEBE                                                     10080013
B        EQU   CEBR                                                     10120013
BZ       EQU   CEBZ                                                     10160013
BNZ      EQU   CEBNZ                                                    10200013
BH       EQU   2                                                        10220015
*                            EQUIVALENCES FOR REGISTERS                 10240013
         SPACE                                                          10280013
GR0      EQU   0                                                        10320013
GR1      EQU   1                                                        10360013
GR2      EQU   2                                                        10400013
GR3      EQU   3                                                        10440013
GR4      EQU   4                                                        10480013
GR5      EQU   5                                                        10520013
GR6      EQU   6                                                        10560013
GR7      EQU   7                                                        10600013
GR8      EQU   8                                                        10640013
GR9      EQU   9                                                        10680013
GR10     EQU   10                                                       10720013
GR11     EQU   11                                                       10760013
GR12     EQU   12                                                       10800013
GR13     EQU   13                                                       10840013
GR14     EQU   14                                                       10880013
GR15     EQU   15                                                       10920013
*              ************            *************                    10960013
GRY      EQU   GR0                                                      11000013
GRW      EQU   GR1                                                      11040013
GRX      EQU   GR3                                                      11080013
GRR      EQU   GR4                                                      11120013
GRSP     EQU   GR7                                                      11160013
GRLR     EQU   10                                                       11200013
GRCC     EQU   GR11                                                     11240013
GRDIC    EQU   GR13                                                     11280013
GRRR     EQU   14                                                       11320013
GRUNIT   EQU   GR15                                                     11360013
GRRZ     EQU   GR15                                                     11400013
*                       EQU CARDS FOR CHASH                             11440013
GRHASH   EQU   0                                                        11480013
GRLTH    EQU   1                                                        11520013
GRP      EQU   2                                                        11560013
GRQ      EQU   3                                                        11600013
GRZ      EQU   4                                                        11640013
GRPTR    EQU   5                                                        11680013
*                       EQUIVALENCES FOR CODE BYTES AT START OF DICT    11720013
*                       ENTRY                                           11760013
         SPACE                                                          11800013
CBLTGN   EQU   X'06'                   BUILT-IN GENERIC FUNCT CODE BYTE 11840013
CENTP5   EQU   X'83'                   ENTRY TYPE 5                     11880013
CEGENL   EQU   X'42'                   GENERIC ENTRY LABEL              11920013
CSTLBL   EQU   X'00'                   STATEMENT LABEL CONST CODE BYTE  11960013
CFILE    EQU   X'09'                   FILE CODE BYTE                   12000013
CVARBL   EQU   X'0F'                   VARIABLE ITEM CODE BYTE          12040013
CFMPAR   EQU   X'40'                   FORMAL PARAMETER CODE BYTE       12080013
CEFLPR   EQU   X'89'                   FILE FORMAL PARAMETER CODE BYTE  12120013
CESTRD   EQU   X'20'                                                    12160013
CELVAR   EQU   X'07'                   LABEL VARIABLE CODE BYTE         12200013
CVRSTR   EQU   1                                                        12240013
CEVLAR   EQU   37                      CODE FOR ANY TYPE OF LABEL VARIA 12280013
         SPACE                                                          12320013
*                       EQUIVALENCES FOR  COMPILER CONTROL OFFSETS      12360013
         SPACE                                                          12400013
ZUGC     EQU   X'10'                                                    12440013
ZUGCOF   EQU   ZUGC                                                     12480013
ZUTXTC   EQU   X'14'                                                    12520013
ZURC     EQU   X'18'                                                    12560013
ZUPGMC   EQU   X'1C'                                                    12600013
ZABORT   EQU   X'20'                                                    12640013
ZLOADW   EQU   X'24'                                                    12680013
LOADW    EQU   ZLOADW                                                   12720013
ZDICAB   EQU   X'28'                                                    12760013
ZDICRF   EQU   X'2C'                                                    12800013
ZUERR    EQU   X'30'                                                    12840013
ZDRFAB   EQU   X'34'                                                    12880013
ZDUMP    EQU   X'38'                                                    12920013
REQEST   EQU   X'40'                                                    12960013
RELESE   EQU   X'44'                                                    13000013
RLSCTL   EQU   X'48'                                                    13040013
ZDRFOF   EQU   ZDICRF                                                   13080013
ZDRAOF   EQU   ZDRFAB                                                   13120013
ZURCOF   EQU   ZURC                                                     13160013
ZERROF   EQU   ZUERR                                                    13200013
ZDABOF   EQU   ZDICAB                                                   13240013
ZTXTRF   EQU   80                                                       13280013
ZTXTAB   EQU   84                                                       13320013
ZCHAIN   EQU   88                                                       13360013
ZALTER   EQU   92                                                       13400013
*                                                                       13440013
         SPACE                                                          13480013
*                       SET UP COMMUNICATIONS OFFSETS                   13520013
         SPACE                                                          13560013
ZNXTD    EQU   76                                                       13600013
ZMYNAM   EQU   112                                                      13640013
ZSTAT    EQU   124                                                      13680013
PAR1     EQU   128                                                      13720013
PAR2     EQU   132                                                      13760013
PAR3     EQU   136                                                      13800013
PAR4     EQU   140                                                      13840013
PAR5     EQU   144                                                      13880013
PAR6     EQU   148                                                      13920013
PAR7     EQU   152                                                      13960013
PAR8     EQU   156                                                      14000013
ZTXTST   EQU   256                                                      14040013
ZDTBSZ   EQU   260                                                      14080013
ZTXBSZ   EQU   264                                                      14120013
ZRABSZ   EQU   268                                                      14160013
ZLSTXT   EQU   276                                                      14200013
ZCOMM    EQU   304                                                      14240013
ZALLOC   EQU   ZCOMM+12                                                 14280013
ZDEFLG   EQU   ZCOMM+16                                                 14320013
ZDEFFL   EQU   ZCOMM+16                                                 14360013
ZALCFL   EQU   ZCOMM+17                                                 14400013
ZMPSTK   EQU   ZCOMM+56                                                 14440013
ZCDSTK   EQU   ZMPSTK                                                   14480013
ZHASH    EQU   ZCOMM+28                                                 14520013
Z2FILE   EQU   ZCOMM+44                                                 14560013
ZUPIC    EQU   ZCOMM+60                                                 14600013
CECTST   EQU   ZCOMM+88                                                 14640013
CEKYST   EQU   ZCOMM+92                                                 14680013
CE2LM    EQU   ZCOMM+93                                                 14720013
CEFFLG   EQU   ZCOMM+95                                                 14760013
CETSYM   EQU   ZCOMM+96                                                 14800013
CESTNM   EQU   ZSTAT                                                    14840013
*                                 EQUIVALENCES FOR CODE BYTES           14880013
         SPACE                                                          14920013
*                       EQUIVALENCES FOR CODE BYTES (INTERNAL REPRESEN- 14960013
*                       TATION)                                         15000013
         SPACE                                                          15040013
SET      EQU   X'0C'                                                    15048015
IN       EQU   X'2C'                                                    15056015
PEXP     EQU   X'16'                                                    15064015
BVEXP    EQU   X'17'                                                    15072015
CE2ATT   EQU   X'05'                   ATTRIBUTE OPTION                 15080013
CEIDN    EQU   X'07'                   IDENT OPTION                     15120013
CEFILE   EQU   X'10'                   FILE                             15160013
CEDATA   EQU   X'14'                   DATA ITEM                        15200013
CELED    EQU   X'12'                 LIST                               15220015
CEIDNT   EQU   X'1F'                   MAXIMUM LENGTH OF IDENTIFIER     15240013
CEVENT   EQU   X'23'                   EVENT OPTION                     15280013
CETASK   EQU   X'1B'                 TASK OPTION                        15300015
CEPRTY   EQU   X'24'                   PRIORITY OPTION                  15320013
CEUPAR   EQU   X'3C'                   UPWARD ARROW                     15360013
CEANCH   EQU   X'3A'                   ANCHOR SIGN                      15400013
CEDWAR   EQU   X'3E'                   DOWNWARD ARROW                   15440013
CEBLNK   EQU   X'40'                   BLANK                            15480013
CELPAR   EQU   X'43'                   LEFT PARENTHESIS                 15520013
CERPAR   EQU   X'45'                   RIGHT PARENTHESIS                15560013
CEFSTP   EQU   X'46'                   FULL STOP                        15600013
CELAR2   EQU   X'46'                   SECOND FILE LEFT ARROW           15640013
CEASEQ   EQU   X'47'                   LEFT ARROW OR ASSIGNMENT =       15680013
CELAR    EQU   CEASEQ                                                   15720013
CEUMB    EQU   X'5E'                   UMBRELLA                         15760013
CEDWAD   EQU   X'7E'                   DOWNWARD ARROW DASHED            15800013
CEALOC   EQU   X'81'                   ALLOCATE                         15840013
CEWAIT   EQU   X'89'                   WAIT                             15880013
CENVIR   EQU   X'8A'                   ENVIRONMENT OPTION               15920013
CEDSP    EQU   X'95'                   DISPLAY                          15960013
CESGNL   EQU   X'97'                   SIGNAL                           16000013
CERVRT   EQU   X'99'                   REVERT                           16040013
CEASGN   EQU   X'9F'                   ASSIGN                           16080013
CECALL   EQU   X'A1'                   CALL                             16120013
CEP      EQU   X'A4'                   P FORMAT                         16160013
CEIMPL   EQU   X'A9'                   IMPLICIT                         16200013
CEDECL   EQU   X'AD'                   DECLARE                          16240013
CENTRY   EQU   X'B1'                   ENTRY                            16280013
CEPROC   EQU   X'B3'                   PROCEDURE                        16320013
CEBEGN   EQU   X'B5'                   BEGIN                            16360013
CEITDO   EQU   X'B7'                   ITERATIVE DO                     16400013
CEDO     EQU   X'B9'                   DO                               16440013
CESND    EQU   X'BC'                   SN DASHED OR SN2                 16480013
CEDSC    EQU   X'C6'                   DSC MARKER                       16520013
CE2LVL   EQU   X'C8'                   SECOND LEVEL MARKER              16560013
CESN     EQU   X'D0'                   SN                               16600013
CESL     EQU   X'D2'                   S1                               16640013
CECN     EQU   X'D4'                   CN                               16680013
CECL     EQU   X'D6'                   CL                               16720013
CEOPEN   EQU   X'DD'                   OPEN                             16760013
CECLOS   EQU   X'DF'                   CLOSE                            16800013
CEONKC   EQU   X'E2'                   START OF FILE ON CONDITIONS      16840013
CENDDO   EQU   X'E7'                   END DO                           16880013
CEEND    EQU   X'E9'                   END                              16920013
CEEOP    EQU   X'EB'                   END OF PROGRAM                   16960013
CEEOB    EQU   X'ED'                   END OF BUFFER                    17000013
CESCLN   EQU   X'EF'                   SEMI-COLON                       17040013
CECONX   EQU   X'F0'                   CONSTANT                         17080013
CECHKN   EQU   X'F6'                   ON CHECK                         17120013
CEON     EQU   X'FB'                   ON                               17160013
CENCKN   EQU   X'FC'                   ON NOCHECK                       17200013
CESUB    EQU   X'FE'                   SUB                              17240013
CEASTR   EQU   X'FC'                   ASTERISK(SPARE-TYRE)             17280013
CESTR    EQU   CEASTR                                                   17320013
         EJECT                                                          17360013
*                       THIS PHASE PERFORMS A GENERAL TIDYING UP OF     17400013
*                       THE TEXT. IT REMOVES ALL THE GARBAGE LEFT IN    17440013
*                       THE TEXT BY PREVIOUS PHASES, REORDERS           17480013
*                       SUBSCRIPT LISTS TO THE END OF A VARIABLE AND    17520013
*                       MAKES DICTIONARY ENTRIES FOR CONSTANTS AND      17560013
*                       PICTURES IN FORMATS.                            17600013
*                       LOAD NEXT PHASE, PICK UP START OF INPUT TEXT    17640013
*                       FROM COMMUNICATION REGION, GET NEW TEXT BLOCK   17680013
*                       FOR OUTPUT AND UPDATE POINTERS IN COMMUNICATION 17720013
*                       REGION.                                         17760013
         SPACE                                                          17800013
         L     GR9,PAR1(GRDIC)                                          17840013
         LA    GR1,CELST2              PICK UP NAME OF NEXT PHASE       17880013
         ST    GR1,PAR1(0,GRDIC)       LOAD IT                          17920013
         L     GR1,LOADW(0,GR11)                                        17960013
         BALR  GR14,GR1                                                 18000013
         L     GR12,PAR1(0,GRDIC)      AND SET UP BASE REGISTER         18040013
         MVC   PAR1(4,GRDIC),ZTXTST(GRDIC) SYMB START OF TEXT           18090015
         MVC   CETSYM(3,GRDIC),ZTXTST+1(GRDIC)  SET UP SYM SCAN REG     18140015
         L     GR7,ZTXTAB(0,GR11)      CONVERT                          18200013
         BALR  GR14,GR7                TO ABSOLUTE                      18240013
         L     GR7,PAR1(0,GRDIC)       AND POINT GR7 AT IT              18280013
         XC    PAR1(4,GRDIC),PAR1(GRDIC)    CLEAR PAR1                  18320013
         MVI   PAR2+3(GRDIC),X'00'     SET UP PARAMETER TO GET NEW BLK  18360013
         L     GR6,ZUTXTC(0,GR11)      NEW BLOCK FOR                    18400013
         BALR  GR14,GR6                                                 18440013
         MVC   CESCYM(3),PAR1+1(GRDIC) SET UP SYMBOLIC ADDRESS SLOT     18480013
         MVC   ZTXTST(4,GRDIC),PAR1(GRDIC)  SET UP NEM TEXT START       18520013
         L     GR6,PAR2(0,GRDIC)       SET GR6 TO START OF BLOCK        18560013
*********************************************************************** 18600013
         LR    GR5,GR6                 CALCULATE                        18640013
         A     GR5,ZTXBSZ(0,GRDIC)     END LOCATION                     18680013
         S     GR5,CE4                 OF BLOCK                         18720013
         ST    GR5,CEENDB              AND STORE                        18760013
         EJECT                                                          18800013
*        INITIALISATION SECTION                                         18840013
*                       UPDATE ZMYNAME SLOT IN COMMUNICATIONS REGION    18880013
*                       AND SET UP UNIT REGISTER.                       18920013
*********************************************************************** 18960013
         MVC   ZMYNAM(2,GRDIC),CEPHNM  MOVE IN PHASE NAME               19000013
         LA    GR15,1(0,0)                                              19040013
         ST    GR15,PAR1(0,GRDIC)      SET UP TO                        19080013
         MVI   PAR1+3(GRDIC),X'02'     GET 1K OF SCRATCH CORE           19120013
         L     GR1,ZUGCOF(0,GR11)                                       19160013
         BALR  GR14,GR1                                                 19200013
         MVC   CEKSTA(4),PAR1(GRDIC)   SAVE SCRATCH ADDR                19260015
*                                      THE SCRATCH CORE JUST GOT        19320013
         BC    CEBR,CE300                                               19360013
*                                      BLOCK                            19400013
         EJECT                                                          19440013
*                       THIS IS WHERE WE GO OFF TO THE ROUTINE FOR      19480013
*                       THE TYPE OF BYTE MARKER FOUND                   19520013
         SPACE                                                          19560013
CE30     AR    GR7,GR15                BUMP SCAN POINTER                19600013
CE300    ST    GR7,CEPREV              SAVE VALUE OF GR7                19640013
         MVC   CEBYTE(1),0(GR7)        MOVE BYTE TO BE TESTED           19680013
         MVC   CELITM(1),CELST         MOVE LAST ITEM PICKED UP         19720013
         MVC   CELST(1),CEBYTE         STORE THIS ITEM JUST FOUND       19760013
         TR    CEBYTE(1),CETRAN        TRANSLATE BYTE TO AN OFFSET      19800013
         XR    GR1,GR1                 CLEAR GR1                        19840013
         IC    GR1,CEBYTE              AND STORE OFFSET IN IT           19880013
         EX    0,CETRTB(GR1)           EXECUTE BRANCH INSTRUCTION       19920013
         EJECT                                                          19960013
*              PARTIAL REFERENCE                                        19962015
*                                                                       19964015
*              WHEN EY FINDS A POINTER-QUALIFIED QUALIFIED NAME IT      19966015
*        COPIES THE ENTIRE STRUCTURE AND REPLACES THE FIRST MEMBER OF   19968015
*        THE NAME BY THE DICT REF. FA MUST REPLACE THE ENTIRE BCD BY    19970015
*        THIS REF.   FIRST REORDER THE NAME SO THAT ANY SUBSCRIPT LISTS 19972015
*        COME AT THE END                                                19974015
CEMIX    ST    GR7,S1                  SAVE ADDR OF START OF NAME       19976015
         XR    GR0,GR0                                                  19978015
         XR    GR1,GR1                                                  19980015
         MVI   MIXFL,X'FF'                                              19982015
         LA    GR7,3(GR7)                                               19984015
CEMIX1   CLI   1(GR7),X'40'          SKIP OVER ANY PADDING BLANKS       19986015
         BC    BNE,CEG3DZ                                               19988015
         LA    GR7,1(GR7)                                               19990015
         BC    CEBR,CEMIX1                                              19992015
         EJECT                                                          19994015
*                       THIS IS TO HANDLE FINDING OF AN IDENTIFIER      20000013
         SPACE                                                          20040013
*                       THIS SECTION REARRANGES THE TEXT SO THAT ANY    20080013
*                       SUBSCRIPTED ITEMS COME AT THE END OF ANY        20120013
*                       QUALIFIED IDENTIFIERS                           20160013
         SPACE 2                                                        20200013
CEID     ST    GR7,S1                  SAVE SCAN POINTER                20240013
         OI    CEFLAG,NONQUL           SET FLAG TO NON-QUALIFIED        20280013
CEG3DY   XR    GR0,GR0                 CLEAR GR0 OR SBRCT               20320013
         XR    GR1,GR1                 CLEAR GR1                        20360013
CEG3D2   EQU   CEID                                                     20400013
CEG3DX   IC    GR1,0(0,GR7)            AND BUMP                         20440013
         AR    GR7,GR1                 GR7 TO END OF IDENTIFIER         20480013
CEG3DZ   EQU   *                                                        20500015
         CLI   1(GR7),CELPAR           IS NEXT ITEM A LEFT PARENTHESIS  20520013
         BC    CEBNE,CEG3F2            NO                               20560013
         LR    GR2,GR7                 YES SO LET GR2 CONTAIN S2        20600013
         AR    GR0,GR15                BUMP SBRCT                       20640013
         AR    GR7,GR15                BUMP SCAN POINTER                20680013
         BC    CEBR,CEG3G1                                              20720013
         SPACE 2                                                        20760013
*                       NOW SEE IF NEXT ITEM IN TEXT IS A FULL-STOP AND 20800013
*        IF IT IS,THIS IS A QUALIFIED NAME                              20840013
         SPACE                                                          20880013
CEG3F2   CLI   1(GR7),CEFSTP           IS NEXT ITEM A FULL STOP         20920013
         BC    CEBNE,CEG3G2            NO                               20960013
         LA    GR7,2(0,GR7)            YES, BUMP SCAN POINTER OVER .    21000013
         NI    CEFLAG,QUAL             TURN FLAG TO QUALIFIED           21040013
         BC    CEBR,CEG3DX                                              21080013
         SPACE 2                                                        21120013
*                       SEE WHETHER NEXT ITEM IS AN IDENTIFIER. OR      21160013
*        PARENTHESIS AND ACT ACCORDINGLY                                21200013
         SPACE                                                          21240013
CEG3G1   AR    GR7,GR15                BUMP GR7 THE SCAN POINTER        21280013
         CLI   0(GR7),CEIDNT           IS THIS AN IDENTIFIER            21320013
         BC    CEBNH,CEG3J2            YES                              21360013
         CLI   0(GR7),CECONX           NO, SO IS IT A CONSTANT          21400013
         BC    CEBNL,CEG3J1            YES                              21440013
         CLI   0(GR7),CELPAR           NO, SO IS IT (                   21480013
         BC    CEBE,CEG3J3             YES                              21520013
         CLI   0(GR7),CERPAR           NO, SO IS IT )                   21560013
         BC    CEBNE,CEG3G1            NO, SO SKIP THIS ITEM            21600013
         SR    GR0,GR15                REDUCE SBRCT                     21640013
         BC    CEBZ,CEG4A1             YES                              21680013
         BC    CEBR,CEG3G1             NO,SO SKIP ITEM                  21720013
         SPACE                                                          21760013
*                       IF THIS BYTE IS SUB THEN SKIP OVER BINARY CONST 21800013
*        -ANT FOLLOWING IT.                                             21840013
         SPACE                                                          21880013
CEG3J1   CLI   0(GR7),CESUB            IS THIS SUB                      21920013
         BC    CEBNE,CEG3JZ            NO SO TRY NEXT ONE               21960013
         AR    GR7,GR15                BUMP OVER SUB AND RETURN         22000013
         BC    CEBR,CEG3G1             TO BUMP OVER BINARY CONSTANT     22040013
         SPACE 2                                                        22080013
*                       IF THIS IS AN ASTERISK THEN JUST SKIP OVER IT.  22120013
         SPACE                                                          22160013
CEG3JZ   CLI   0(GR7),CEASTR           IS THIS ASTERISK (SPARE TYRE)    22200013
         BC    CEBE,CEG3G1                                              22240013
         SPACE 2                                                        22280013
*                       THIS IS A CONSTANT INSIDE THE PARENTHESES, SO   22320013
*        MAKE A DICTIONARY ENTRY FOR THE CONSTANT,REPLACE IT IN TEXT BY 22360013
*        THE REFERENCE AND BLANKS                                       22400013
         SPACE                                                          22440013
         SPACE                                                          22480013
CEG3JX   STM   GR0,GR6,SAVE1           SAVE REGISTERS 0 TO 6.           22520013
         LR    GR6,GR7                 SET GR6 TO CODE BYTE             22560013
         CLI   0(GR6),CESTR            IS IT CHAR OR BIT                22600013
         BC    CEBH,CECCON             YES, SO BRANCH                   22640013
         MVC   CELNGT(1),1(GR7)        NO, PICK UP LENGTH OF CONSTANT   22680013
         BAL   GR2,CECON               GO TO CONSTANT ROUTINE           22720013
         XR    GR5,GR5                 CLEAF GR5                        22760013
         IC    GR5,CELNGT              PICK UP LENGTH OF CONSTANT       22800013
         SR    GR5,GR15                REDUCE BY ONE                    22840013
         BC    CEBZ,CERESX             AND BRANCH OUT IF IT WAS ZERO    22880013
CELOPX   AR    GR6,GR15                BUMP GR6 BY ONE                  22920013
         MVI   0(GR6),CEBLNK           AND PUT IN A BLANK               22960013
         BCT   GR5,CELOPX              REPEAT LOOP UNLESS COUNT IS ZERO 23000013
CERESX   LM    GR0,GR6,SAVE1           RESTORE REGISTERS 0 TO 6.        23040013
         BC    CEBR,CEG3G1                                              23080013
         SPACE 2                                                        23120013
*                       TEST TO SEE IF THIS IS A ZERO BYTE. IF IT IS,   23160013
*        WHAT FOLLOWS IS A DICTIONARY  REFERENCE SO WE SKIP OVER IT.    23200013
         SPACE                                                          23240013
CEG3J2   CLI   0(GR7),X'00'            IS THIS ZERO AND A DICT REF      23280013
         BC    CEBNE,CEG3J4            NO, SO BRANCH                    23320013
         LA    GR1,2                   SET GR1 TO 2 FOR DICT REF        23360013
         BC    CEBE,CEG3J5             REF                              23400013
CEG3J4   XR    GR1,GR1                 CLEAR GR1                        23440013
         IC    GR1,0(GR7)              PICK UP LENGTH OF ID             23480013
CEG3J5   AR    GR7,GR1                 BUMP POINTER BY LENGTH           23520013
         BC    CEBR,CEG3G1                                              23560013
         SPACE 2                                                        23600013
*                       FOR A LEFT PARETHESIS BUMP THE PARETHESIS COUNT 23640013
         SPACE                                                          23680013
CEG3J3   AR    GR0,GR15                BUMP SBRCT                       23720013
         BC    CEBR,CEG3G1                                              23760013
         SPACE                                                          23800013
CEG3GX   LR    GR7,GR2                 POINT GR7 BEFORE START OF (      23840013
CEG3G2   CLI   CE2LM(GRDIC),CEFILE     IS SECOND LEVEL STORE FILE       23880013
*                       IF THIS IS A FILE THEN GO TO SCAN DICTIONARY    23920013
         SPACE                                                          23960013
         BC    CEBE,CESC               YES, SO GO TO SCAN               24000013
         SPACE                                                          24040013
         CLI   MIXFL,X'FF'             TEST FOR PARTIAL REFERENCE.      24045015
         BC    BE,CEMIXA             BRANCH IF SO                       24050015
         L     GR4,S1                  SET GR4 TO START OF IDENTIFIER   24052015
         CLI   CE2LM(GRDIC),SET                                         24055015
         BC    CEBE,CESC0                                               24060015
         CLI   CE2LM(GRDIC),IN                                          24065015
         BC    CEBE,CESC0                                               24072015
CEWCX    CLI   CEWFLG,X'FF'            IS W FLAG ON                     24080013
         BC    CEBE,CESC0                                               24120015
         TM    CEFLAG,NONQUL           IS NAME QUALIFIED                24360013
         BC    CEBZ,CEIDOK             BRANCH IF SO                     24400013
         CLI   DATDFL,X'FF'          IS THIS CV OF DATA LIST DO         24440013
         BC    CEBE,CECONK           SKIP TEST OF BRACKET CNT IF SO     24480013
         CLI   CENFLG,X'FF'            IS THIS THE DATA LIST OF A GET   24520013
         BNE   CECONA                  STMT.                      45888 24560056
         CLI   CE2LM(GRDIC),CEDATA                                      24600013
         BH    CECONA                  HIGHER THAN DATA.          45888 24620056
         CLI   CE2LM(GRDIC),CELED                                       24640015
         BL    CECONA                  LOWER THAN LIST.           45888 24650056
         MVI   CEECPF(GR12),X'FF'      NON-BIF FLAG ON.           45888 24660056
*     THIS FLAG IS TESTED DURING MAKING A DICT ENTRY - SEE FB.    45888 24670056
        LR     GR1,GR15                                LOAD ONE         24680013
         B     CECONB                  GO COMPARE BRACKET COUNT.  45888 24688056
CECONA   CLI   CEECPF(GR12),X'FF'      NON-BIF FLAG ON?           45888 24696056
         BNE   CEIDOK                  NO, BRANCH.                45888 24704056
         SR    GR1,GR1                 LOAD ZERO.                 45888 24712056
CECONB  C      GR1,CEBCT                                                24720013
        BC     BNE,CEIDOK             SKIP OUT   IF WRONG BRACKET COUNT 24760013
CECONK   EQU   *                                                        24800013
         CLI   1(GR7),CELPAR           CHECK FOR SUBSCRIPT              24840013
         BC    BE,CEIDOK                                                24880013
        CLC    0(CECONC,GR4),CELONC   SKIP OUT   IF ONCHAR              24920013
        BC     BE,CEIDOK                                                24960013
         CLC   0(9,GR4),CEPRIY         CHECK FOR PRIORITY               24970015
         BC    BE,CEIDOK                                                24980015
        CLC    0(CECONS,GR4),CELONS   UNLESS ONSOURCE                   25000013
        BC     BNE,CESC               LOOKUP IN DICTIONARY.             25040013
         SPACE                                                          25080013
*                       CALCULATE AMOUNT OF TEXT TO BE MOVED. SEE IF IT 25120013
*        WILL FIT IN WHAT IS AVAILABLE IN THE OUTPUT AREA. IF THERE IS  25160013
*        NOT ENOUGH SPACE GET A NEW BLOCK. MOVE TEXT TO OUTPUT AREA.    25200013
         SPACE                                                          25240013
CEIDOK   LR    GR5,GR7                 SET GR5 TO END OF VARIABLE       25280013
         SR    GR5,GR4                 CALCULATE LENGTH TO BE MOVED     25320013
         LR    GR3,GR6                 SET GR3 TO CURRENT OUTPUT POS    25360013
         AR    GR3,GR5                 GR3 POINTS AT WHERE OUTPUT WILL  25400013
*                                      END IF WE DO THIS MOVE           25440013
         C     GR3,CEENDB              IS IT TOO FAR FOR THIS BLOCK     25480013
         BC    CEBL,CEZZX              NO, SO DO THE MOVE               25520013
         STM   GR4,GR5,SAVE2           YES, SO SAVE REGISTERS.          25560013
         BAL   GR14,CENEWB             AND GET NEW BLOCK                25600013
         LM    GR4,GR5,SAVE2                                            25640013
         BC    CEBR,CEZZX              NO, SO DO THE MOVE               25680013
CEZZX    C     GR5,CE256               IS IT 256 BYTES PLUS  -          25720013
         BC    CEBNL,CETOMC            YES, SO BRANCH TO MOVE 256       25760013
CEMVC6   STC   GR5,CEMVX4+1            STORE COUNT-1 IN MVC INSTRUCTION 25800013
CEMVX4   MVC   0(0,GR6),0(GR4)         MOVE NO OF BYTES REQUIRED        25840013
         AR    GR6,GR5                 BUMP OUTPUT POINTER              25880013
         BC    CEBR,CE31               RETURN                           25920013
         SPACE                                                          25960013
*                       ROUTINE TO MOVE 256 BYTES                       26000013
         SPACE                                                          26040013
CETOMC   MVC   0(256,GR6),0(GR4)       MOVE 256 BYTES                   26080013
         S     GR5,CE256               BUMP DOWN COUNT BY 256           26120013
         A     GR6,CE256               BUMP OUTPUT POINTER              26160013
         A     GR4,CE256               AND SCAN POSITION                26200013
         BC    CEBR,CEZZX              RETURN FOR NEXT SECTION          26240013
*              THIS IS A PARTIAL REFERENCE SO REPLACE ENTIRE NAME BY    26242015
*        THE REFERENCE                                                  26244015
CEMIXA   MVI   MIXFL,X'00'                                              26246015
         SPACE                                                          26248015
         LA    GR3,3(GR6)              TEST IF ROOM FOR REF             26250015
         C     GR3,CEENDB                                               26252015
         BC    CEBL,CEMIXB             GET NEW BLOCK IF NOT             26254015
         BAL   GR14,CENEWB                                              26256015
         SPACE                                                          26258015
CEMIXB   L     GR4,S1                                                   26260015
         MVC   0(3,GR6),1(GR4)         MOVE REF TO O/P                  26262015
         LA    GR6,3(GR6)              BUMP OUTPUT POINTER              26264015
         BC    CEBR,CE30               RETURN TO MAIN SCAN              26266015
         SPACE 4                                                        26268015
         SPACE 2                                                        26280013
*                       POINT GR7 AT START OF BCD AND SCAN BCD          26320013
         SPACE                                                          26330015
CESC0    C     GR15,CEBCT                                               26340015
         BC    CEBL,CEIDOK             DONT SCAN IF BKT CNT MORE THAN 1 26350015
         SPACE                                                          26360013
CESC     L     GR7,S1                  RELOAD GR7 TO BCD LENGTH-1       26400013
         BAL   GR2,CESCN               GO TO SCAN ROUTINE               26440013
         BC    CEBR,CE30               RETURN                           26480013
         SPACE                                                          26520013
*                       AT THIS POINT WE ARE POINTING AT CLOSING PAREN- 26560013
*        THESIS AROUND SUBSCRIPT. SAVE ITS ADDRESS AND IF ITS FOLLOWED  26600013
*        BY ANOTHER QUALIFIED NAME SKIP TO THE END OF THAT VARIABLE AND 26640013
*        SAVE THAT ADDRESS                                              26680013
         SPACE                                                          26720013
CEG4A1   LR    GR3,GR7                 SAVE SCAN POINTER IN GR3 AS S3   26760013
         CLI   1(GR7),CEFSTP           IS NEXT ITEM A .                 26800013
         BC    CEBNE,CEG3GX            NO, SO END OF SCAN               26840013
         LA    GR7,2(0,GR7)            YES SO BUMP OVER                 26880013
         XR    GR1,GR1                 PICK                             26920013
         IC    GR1,0(GR7)              UP IDENTIFIER LENGTH AND         26960013
         AR    GR7,GR1                 BUMP SCAN POINTER TO END         27000013
         LR    GR4,GR7                 SET GR4 TO THIS POINT AS S4      27040013
         LR    GR0,GR3                 CALCULATE                        27080013
         SPACE                                                          27120013
*                       CALCULATE LENGTHS TO BE MOVED TO MOVE ITEM IN   27160013
*        FORM A(I).B--- TO  A.B(I)---                                   27200013
         SPACE                                                          27240013
         SR    GR0,GR2                 S3-S2 =X                         27280013
         LR    GR1,GR4                 CALCULATE                        27320013
         SR    GR1,GR3                 S4-S3 = Y                        27360013
         CR    GR0,GR1                 IS X GREATER THAN Y              27400013
         BC    CEBH,CEQQX              YES                              27440013
         LR    GR14,GR0                SET W=MIN(X,Y)                   27480013
         BC    CEBR,CEQQY                                               27520013
         SPACE 2                                                        27560013
CEQQX    LR    GR14,GR1                SET W=MIN(X,Y)                   27600013
         MVI   CEXLAG,X'FF'        SET FLAG ON                          27640013
         SR    GR0,GR1                 SET GR0 TO  Z=X- Y               27680013
         SPACE 2                                                        27720013
CEQQY    BCTR  GR1,0                   REDUCE GR1 TO Y-1                27760013
         BCTR  GR14,0                  AND GR14 TO W-1                  27800013
         STC   GR1,CEMVX1+1            AND COMPLETE                     27840013
         STC   GR1,CEMVX3+1            THE MOVE                         27880013
         STC   GR14,CEMVX2+1           CHARACTER INSTRUCTIONS           27920013
         LA    GR14,1(GR1,GR2)         SET GR14 TO S2+Y                 27960013
         SPACE 2                                                        28000013
CEMVX1   MVC   CESCXT(0),1(GR3)        MOVE FROM S3+1 TO SCRATCH FOR Y  28040013
         CLI   CEXLAG,X'FF'            IS FLAG ON                       28080013
         BC    CEBNE,CEMVX2            NO SO BRANCH                     28120013
         MVI   CEXLAG,X'00'            CLEAR FLAG                       28160013
         LR    GR7,GR0                 SET GR7 TO Z                     28200013
         LA    GR3,0(GR14,GR7)         GR3 = S2+X                       28240013
         LR    GR7,GR4                 GR7 IS NOW AT S4                 28280013
         SPACE 2                                                        28320013
CELXP    MVC   0(1,GR7),0(GR3)         MOVE FROM S2+X TO S4 FOR Z       28360013
         BCTR  GR3,0                                                    28400013
         BCTR  GR7,0                   REDUCE LOCATION POINTERS         28440013
         BCT   GR0,CELXP               CONTINUE LOOP TILL COUNT DIES    28480013
         SPACE 2                                                        28520013
CEMVX2   MVC   1(0,GR14),1(GR2)        MOVE FROM S2+1 TO S2+Y+1 FOR W   28560013
*                       COMPLETE MOVE. IF ENTRY IS NOW OF FORM          28600013
*        A.B(I)(J) CHANGE IT TO READ A.B(I ,J)  THE BLANK WILL GET      28640013
*        REMOVE BY THE NEXT SCAN OF TEXT                                28680013
         SPACE                                                          28720013
CEMVX3   MVC   1(0,GR2),CESCXT     MOVE FROM SCRATCH TO S2+1 FOR Y      28760013
         CLI   1(GR4),CELPAR           IS NEXT ITEM PARENTHESIS         28800013
         BC    CEBNE,CEG4E4            NO                               28840013
         MVC   0(2,GR4),CECOMA         YES SO CHANGE )( \O ,O           28880013
         SPACE 2                                                        28920013
*                       REPEAT SCAN FROM START OF NEXT VARIABLE IN      28960013
*        QUALIFIED NAME                                                 29000013
         SPACE                                                          29040013
CEG4E4   LA    GR7,2(0,GR2)            SET GR7 TO S2+2                  29080013
         BC    CEBR,CEG3DY                                              29120013
         SPACE                                                          29160013
*                       ROUTINE FOR GOING TO MAKE A CONSTANT DICTIONARY 29200013
*        ENTRY                                                          29240013
         SPACE                                                          29280013
CECCON   MVC   CELENG+2(2),1(GR7)      MOVE IN CONSTANT LENGTH          29320013
         BAL   GR2,CECON               GO TO CONSTANT ROUTINE           29360013
         LH    GR5,CELENG+2            PICK UP LENGTH OF CONSTANT       29400013
         LTR   GR5,GR5                 IF ZERO LENGTH, SKIP BLANKING    29440013
         BC    CEBZ,CERESX           INSTRUCTIONS.                      29480013
         BC    CEBR,CELOPX             AND GO TO BLANK OUT REMAINS      29520013
         SPACE 2                                                        29560013
*                       THIS IS TRANSFER POINT FOR A CONSTANT MARKER    29600013
         SPACE                                                          29640013
CEINT    BAL   GR2,CECON               GO TO CONSTANT ROUTINE           29680013
         BC    CEBR,CE31                                                29720013
         SPACE 2                                                        29760013
*                       THIS IS TRANSFER POINT FOR A KEYWORD            29800013
         SPACE                                                          29840013
CEKEY    MVC   0(1,GR6),0(GR7)         MOVE KEYWORD TO TEXT             29880013
         MVC   CEKYST(1,GRDIC),0(GR7)  STORE KEYWORD                    29920013
         BAL   GR2,CEKYWD              GO TO KEYWORD ROUTINE            29960013
         BC    CEBR,CE31               BRANCH BACK                      30000013
         SPACE 2                                                        30040013
*                       THIS IS TRANSFER POINT FOR SECOND LEVEL MARKER  30080013
*        SAVE MARKER FOR FUTURE REFERENCE. SET FLAG ON IF IT IS EVENT   30120013
*        OR PRIORITY                                                    30160013
         SPACE                                                          30200013
CE2L     MVC   0(2,GR6),0(GR7)         MOVE ATTRIBUTE TO TEXT           30240013
         MVC   CE2LM(1,GRDIC),1(GR7)   SAVE ATTRIBUTE                   30280013
         MVI   CEWFLG,X'00'            TURN OFF W FLAG                  30300015
         AR    GR7,GR15                BUMP SCAN POINTER                30320013
         AR    GR6,GR15                BUMP OUTPUT POINTER              30360013
         CLI   CE2LM(GRDIC),CEVENT     IS SECOND LEVEL MARKER EVENT     30400013
         BC    CEBE,CEWONS             YES, SO GO TO SET FLAG ON        30440013
         CLI   CE2LM(GRDIC),CETASK     IS THIS TASK                     30480015
         BC    CEBE,CEWONS                                              30520015
         BC    CEBR,CE31                                                30560013
         SPACE 2                                                        30600013
         SPACE 2                                                        30640013
         SPACE                                                          30680013
CEWONS   MVI   CEWFLG,X'FF'            SET W FLAG ON                    30720013
         BC    CEBR,CE31                                                30760013
         SPACE 2                                                        30800013
*                       TRANSFER POINT FOR BLANK OR ZERO BYTE. IF IT IS 30840013
*        A ZERO THEN THE NEXT 3 BYTES ARE MOVED. IF IT IS A BLANK THEN  30880013
*        THE ACTION DEPENDS ON THE STATEMENT THAT WE ARE IN. IF IT IS   30920013
*        AN ALLOCATE STATEMENT THEN WE SKIP TO THE NEXT NON-BLANK       30960013
*        CHARACTER,  IF NOT THEN WE JUST SKIP THE BLANK.                31000013
         SPACE 2                                                        31040013
CEBNK    CLI   0(GR7),X'00'            IS THIS A ZERO BYTE              31080013
         BC    CEBNE,CEBNKX            NO, SO SKIP TO BLANK SECTION     31120013
         CLI   CELITM,CEEOB            IS THIS START OF NEW BLOCK       31160013
         BC    CEBE,CEBNK1             YES, SO GO TO SKIP TO NEXT NON   31200013
*                                      - BLANK CHARACTER                31240013
         MVC   0(3,GR6),0(GR7)         YES, SO MOVE DICTIONARY REFERENC 31280013
         LA    GR7,3(0,GR7)            AND                              31320013
         LA    GR6,3(0,GR6)            BUMP POINTERS                    31360013
         BAL   GR14,CENDTS                                              31400013
         BC    CEBR,CE300                                               31440013
*              THIS IS A BLANK, SO TEST WHAT STATEMENT WE  ARE IN       31480013
         SPACE                                                          31520013
CEBNKX    EQU   *                                                       31580015
         SPACE                                                          31640013
*              NOT AN ALLOCATE STATEMENT SO SKIP THIS BLANK             31680013
         SPACE                                                          31720013
         AR    GR7,GR15                BUMP SCAN POINTER                31760013
         BC    CEBR,CE300                                               31800013
         SPACE                                                          31840013
*                       NOT A DICTIONARY REFERENCE OO BYTE SO SKIP TO   31880013
*        NEXT NON-BLANK, NON-ZERO BYTE IN TEXT.                         31920013
         SPACE                                                          31960013
CEBNK1   TRT   0(256,GR7),CETRTT(GR12)                                  32000013
         BC    CEBZ,CEMOD              N0 CHARACTER                     32040013
         LR    GR7,GR1                 BUMP GR7 TO CHARACTER FOUND      32080013
         BC    CEBR,CE300                                               32120013
         SPACE 2                                                        32160013
*                       CEDARD IS THE ENTRY POINT FOR A DOWNWARD ARROW  32200013
*                       DASHED IN THE TEXT. THE ROUTINE TRANSFERS THE D 32240013
*                       DATA A BYTE AT A TIME UNTIL A LEFT ARROW IS FOU 32280013
*                       -ND                                             32320013
         SPACE 2                                                        32360013
CEDWAX   AR    GR6,GR15                BUMP OUTPUT POINTER              32400013
         AR    GR7,GR15                BUMP SCAN POINTER                32440013
         BAL   GR14,CENDTS             GO TO END TEST ROUTINE           32480013
         CLI   0(GR7),CELAR2           IS THIS SECOND FILE LEFT ARROW   32520013
         BC    CEBE,CE32               YES, SO BRANCH OUT               32560013
         CLI   0(GR7),X'00'            IS THIS A ZERO BYTE              32600013
         BC    CEBNE,CEDARD            NO, SO SKIP                      32640013
         MVC   0(3,GR6),0(GR7)         YES, SO MOVE IN DICT REFERENCE   32680013
         LA    GR6,2(0,GR6)            BUMP OUTPUT POINTER              32720013
         LA    GR7,2(0,GR7)            AND INPUT POINTER                32760013
         BC    CEBR,CEDWAX             AND BRANCH BACK                  32800013
CEDARD   MVC   0(1,GR6),0(GR7)         NO, SO MOVE ITEM TO TEXT AREA    32840013
         BC    CEBR,CEDWAX                                              32880013
         SPACE                                                          32920013
         SPACE 2                                                        32960013
CEMOD    LA    GR7,256(0,GR7)          NO CHARACTER FOUND SO BUMP BY    33000013
         BC    CEBR,CEBNK              256 AND TRY AGAIN                33040013
         SPACE 2                                                        33080013
*                       TRANSFER POINT FOR SEMI-COLON                   33120013
*        CLEAR ALL STORES AND FLAGS AND BRACKET COUNT                   33160013
         SPACE                                                          33200013
CESMCL   MVI   CEKYST(GRDIC),X'00'     CLEAR KEYWORD STORE              33240013
         MVI   CEWFLG,X'00'            CLEAR TASKING FLAG               33260016
         MVI   CE2LM(GRDIC),X'00'      AMD SECOND LEVEL MARKER STORE    33280013
         MVI   CENFLG,X'00'            SET N FLAG OFF                   33320013
        MVI    CEECPF(GR12),X'00'    NON BIF FLAG                       33360013
         XC    CEBCT(4),CEBCT          AND BRACKET COUNT                33400013
         BC    CEBR,CE32                                                33440013
         SPACE 2                                                        33480013
*                       TRANSFER POINT FOR WHEN A STATEMENT EXCEEDS     33520013
*                       A TEXT BLOCK IN SIZE                            33560013
         SPACE                                                          33600013
CERR28   MVI   CERR1R+1,X'8C'          MOVE IN ERROR CODE               33640013
         SPACE                                                          33680013
*                       TRANSFER POINT FOR ERROR                        33720013
         SPACE                                                          33760013
CERRRR   MVC   PAR6+1(3,GRDIC),CERR1R   MOVE IN CODE BYTE               33800013
        L     GR1,ZERROF(0,GR11)      GO TO ERROR ROUTINE               33840013
         BALR  GR14,GR1                                                 33880013
         L     GR1,ZABORT(0,GR11)                                       33920013
         BALR  GR14,GR1                                                 33960013
*********************************************************************** 34000013
         SPACE 2                                                        34040013
*                       TRANSFER POINT FOR LEFT PARENTHESIS             34080013
         SPACE                                                          34120013
CELP     L     GR1,CEBCT                                                34160013
         AR    GR1,GR15                 BUMP                            34200013
         ST    GR1,CEBCT                BRACKET COUNT                   34240013
         BC    CEBR,CE32                                                34280013
         SPACE 3                                                        34320013
*                       TRANSFER POINT FOR RIGHT PARENTHESIS            34360013
         SPACE                                                          34400013
CERP     L     GR1,CEBCT               REDUCE                           34440013
         SR    GR1,GR15                BRACKET COUNT                    34480013
         ST    GR1,CEBCT                                                34520013
         BC    CEBNZ,CE32              IF ITS ZERO                      34560013
         CLI   CEWFLG,X'FF'            AND WFLAG IS ON                  34600013
         BC    CEBNE,CE32              THEN                             34640013
         MVI   CEWFLG,X'00'            SET IT OFF                       34680013
         BC    CEBR,CE32                                                34720013
         SPACE 2                                                        34760013
*                       TRANSFER POINT TO MOVE ONE BYTE FROM THE INPUT  34800013
*        AREA TO THE OUTPUT AREA BUMP THE OUTPUT POINTER AND MAKE SURE  34840013
*        WE HAVE NOT REACHED THE END OF THE OUTPUT BLOCK                34880013
         SPACE 2                                                        34920013
CE32     MVC   0(1,GR6),0(GR7)                                          34960013
*                                                                       35000013
         SPACE                                                          35040013
CE31     AR    GR6,GR15                BUMP OUTPUT POINTER              35080013
         BAL   GR14,CENDTS             GO TO END TEST ROUTINE           35120013
         BC    CEBR,CE30                                                35160013
         SPACE 2                                                        35200013
*                       TRANSFER FOR SUB TO MOVE SUB AND BINARY CONST   35240013
         SPACE                                                          35280013
CESUBI   MVC   0(2,GR6),0(GR7)         MOVE SUB AND CONST               35320013
         LA    GR6,2(0,GR6)            BUMP                             35360013
         LA    GR7,2(0,GR7)            POINTERS                         35400013
         BAL   GR14,CENDTS             TEST FOR END OF BLOCK            35440013
         BC    CEBR,CE300              AND RETURN                       35480013
*                           TRANSFER FOR LEFT ARROW                     35520013
CELA    MVI    CEECPF(GR12),X'00'    NON BIF FLAG                       35560013
        BC     CEBR,CE32                                                35600013
         SPACE 3                                                        35640013
DOEQU    MVI   DATDFL,X'00'          SET DATA LIST DO FLAG OFF          35680013
         MVI   CEECPF(GR12),X'00'                                       35720013
         BC    CEBR,CE32                                                35760013
         SPACE 2                                                        35800013
         EJECT                                                          35840013
*              FUNCTION/OPERATION                                       35880013
         SPACE 3                                                        35920013
*                       THIS ROUTINE TESTS IF THE OUTPUT POINTER (GR6)  35960013
*                       IS AT THE END OF THE CURRENT TEXT BLOCK. IF NOT 36000013
*                       AN ORDINARY RETURN OCCURS BUT IF IT IS THEN A   36040013
*                       NEW TEXT BLOCK IS GOT AND CHAINED TO THE CURR-  36080013
*                       ENT ONE. THAT PART OF THE STATEMENT BEING PROC- 36120013
*                       ESSED WHICH IS IN THE CURRENT BLOCK IS MOVED    36160013
*                       INTO THE NEW BLOCK AND AN EOB MARKER PLACED AT  36200013
*                       THE END OF THE LAST COMPLETE STATEMENT IN THE   36240013
*                       CURRENT BLOCK. THE INPUT POINTER (GR6) AND      36280013
*                       OUTPUT POINTER (GR7) ARE UPDATED. THE CURRENT   36320013
*                       BLOCK IS THEN MARKED AS NOT WANTED.             36360013
*                       IF THE STATEMENT TO BE MOVED IS ALREADY A TEXT  36400013
*                       BLOCK LONG WE GIVE UP.                          36440013
*                       GR1,GR4,GR5 ARE USED AS SCRATCH REGISTERS       36480013
         SPACE 3                                                        36520013
*              ENTRY POINT                                              36560013
*                       CENDTS CALLED BY    BAL   GR14,CENDTS           36600013
         SPACE 3                                                        36640013
*              INPUT                                                    36680013
*              GR6 POINTS AT THE LAST BYTE USED IN THE OUTPUT BLOCK.    36720013
         SPACE 3                                                        36760013
*              OUTPUT                                                   36800013
*              GR6 POINTS AT THE LAST BYTE UED IN THE OUTPUT BLOCK.     36840013
         SPACE 3                                                        36880013
*              WORK AREA                                                36920013
*              N/A                                                      36960013
         SPACE 3                                                        37000013
*              EXTERNAL ROUTINES                                        37040013
*                       ZUTXTC    GET NEW TEXT BLOCK                    37080013
*                       ZTXTAB    CONVERT TEXT REFERENCE TO ABSOLUTE.   37120013
*                       ZALTER    CHANGE STATUS OF NAMED BLOCK.         37160013
         SPACE 3                                                        37200013
*              NOTES                                                    37240013
*              GR1,GR4,GR5 USED AS SCRATCH REGISTERS.                   37280013
         SPACE 3                                                        37320013
         SPACE 2                                                        37360013
CENDTS   C     GR6,CEENDB              HAVE WE REACHED THE LAST LOC IN  37400013
         BC    CEBL,CERETN             THIS BLOCK. NO, SO RETURN        37440013
         SPACE 2                                                        37480013
CENEWB   MVC   PAR1+1(3,GRDIC),CESCYM  MOVE IN SYMBOLIC ADDR OF BLOCK   37520013
         MVI   PAR2+3(GRDIC),X'84'     SET UP PARAMETERS TO CHAIN IN    37560013
         ST    GR14,CEGR14             SAVE GR14                        37600013
         L     GR5,ZUTXTC(0,GR11)      NEW BLOCK                        37640013
         BALR  GR14,GR5                                                 37680013
         MVC   CESCLM(3),CESCYM        SAVE SYMBOLIC ADDR OF LAST BLOCK 37720013
         MVC   CESCYM(3),PAR1+1(GRDIC) SAVE NEW SYMBOLIC ADDRESS        37760013
         LR    GR1,GR6                 SAVE VALUE OF GR6                37800013
         L     GR5,ZTXTAB(0,GR11)      CONVERT TO ABSOLUTE              37840013
         BALR  GR14,GR5                AND                              37880013
         L     GR6,PAR1(0,GRDIC)       SET GR6 POINTING TO START OF NEW 37920013
         LR    GR5,GR6                 BLOCK                            37960013
         A     GR5,ZTXBSZ(0,GRDIC)     CALCULATE END LOCATION           38000013
         S     GR5,CE4                 OF THIS BLOCK AND STORE          38040013
         ST    GR5,CEENDB                                               38080013
         L     GR5,CESTNL              LOAD GR5 WITH LOCATION OF LAST   38120013
         LR    GR4,GR5                 STATEMENT NUMBER IN OLD BLOCK    38160013
         SR    GR1,GR5                 SUBTRACT TO GET LENGTH OF TEXT   38200013
         SPACE 2                                                        38240013
CEBR1    C    GR1,CE256                TO BE MOVED. IT IT IS LESS THAN  38280013
         BC    CEBL,CEJMOV             255 BYTES BRANCH                 38320013
         SPACE                                                          38360013
         C     GR1,ZTXBSZ(0,GRDIC)     IS LENGTH 1 TEXT BLOCK           38400013
         BC    CEBNL,CERR28            IF SO IT IS AN ERROR             38440013
         MVC   0(256,GR6),0(GR4)       IF NOT MOVE 256 BYTES TO NEW BLK 38480013
         LA    GR4,256(0,GR4)          BUMP POINTERS                    38520013
         LA    GR6,256(0,GR6)                                           38560013
         S     GR1,CE256               REDUCE COUNT OF TEXT TO BE MOVED 38600013
         BC    CEBR,CEBR1             BY 256 AND TRY AGAIN              38640013
         SPACE 2                                                        38680013
CEJMOV   BCTR  GR1,0                   REDUCE COUNT FOR INSTRUCTION     38720013
         STC   GR1,CEMOV+1             LESS THAN 256 TO MOVE SO SET UP  38760013
CEMOV    MVC   0(0,GR6),0(GR4)         INSTRUCTION AND MOVE TEXT        38800013
         MVI   0(GR5),CEEOB            STORE EOB MARKER AND NEXT BLK    38840013
*                                      STATEMENT NUMBER IN THE OLD BLK  38880013
         LA    GR6,1(GR1,GR6)          BUMP TO END OF TEXT ENTRY        38920013
         MVC   PAR1+1(3,GRDIC),CESCLM  SET UP PARAMETERS                38960013
         MVI   PAR2+3(GRDIC),X'02'     TO MARK                          39000013
         L     GR5,ZALTER(0,GR11)      LAST TEXT BLOCK AS NOT WANTED    39040013
         BALR  GR14,GR5                                                 39080013
         L     GR14,CEGR14             RESTORE GR14                     39120013
CERETN   BCR   CEBR,GR14               AND RETURN.                      39160013
         EJECT                                                          39200013
*                       TRANSLATE TABLE FOR CODE BYTES ETC              39240013
         SPACE                                                          39280013
CETRAN   DC    X'14'                   0  AS FOR BLANK                  39320013
         DC    5X'040404040404'                                         39360013
         DC    X'04'                                                    39400013
         DC    2X'1818181818181818'                                     39440013
         DC    X'0018181800181818'     2ND FILE PSEUDO-VARIABLE MARKER  39480013
         DC    X'1818181818181818'                                      39520013
         DC    X'14'                   BLANK                            39560013
         DC    X'00'                                                    39600013
        DC    X'002400283030'         PARENS AND LEFT ARROWS            39640013
         DC    XL25'00'                                                 39680013
         DC    X'34'                                                    39720013
         DC    XL23'00'                                                 39760013
         DC    X'00000000002000'       DOWNWARD ARROW DASHED            39800013
         DC    X'080808080808'                                          39840013
         DC    X'1C0808081C08'         THEN SNAP                        39880013
         DC    12X'080808'                                              39900015
         DC    X'38'                   PARTIAL REFERENCE                39920015
         DC    11X'08'                                                  39940015
         DC    X'081C1C080808080808080808'  ELSE NOSNAP                 39960013
         DC    X'10'                   SECOND LEVEL MARKER              40000013
         DC    3X'080808080808080808080808'                             40040013
         DC    X'0808'                                                  40080013
         DC    X'1C'                   SEMI-COLON                       40120013
         DC    11XL1'0C'                                                40160013
         DC    X'08'                   ON                               40200013
         DC    X'000C2C0C'             SUB                              40240013
         EJECT                                                          40280013
*                       TABLE OF TRANSFER ADDRESSES FILLED IN AT OBJECT 40320013
*                       TIME                                            40360013
         SPACE                                                          40400013
CETRTB   BC    CEBR,CE32               0    BRANCH TO CONTINUATION      40440013
         BC    CEBR,CEID               4    BRANCH TO IDENTIFIER        40480013
         BC    CEBR,CEKEY              8    BRANCH TO KEYWORD SECTION   40520013
         BC    CEBR,CEINT              C    BRANCH TO CONSTANT SECTION  40560013
         BC    CEBR,CE2L               10   BRANCH TO 2ND LEVEL ROUTINE 40600013
         BC    CEBR,CEBNK              14   BRANCH TO BLANK ROUTINE     40640013
         BC    CEBR,CERRRR             18   BRANCH FOR ERROR            40680013
         BC    CEBR,CESMCL             1C   BRANCH TO SEMI-COLON ROUTNE 40720013
         BC    CEBR,CEDARD             20   BRANCH FOR DOWNWARD ARROW D 40760013
         BC    CEBR,CELP               24   BRANCH FOR LEFT PARENTHESIS 40800013
         BC    CEBR,CERP               28   BRANCH FOR RIGHT PAREN      40840013
         BC    CEBR,CESUBI             2C   BRANCH TO ISUB ROUTINE      40880013
        BC     CEBR,CELA              30   BRANCH FOR LEFT ARROW        40920013
         BC    CEBR,DOEQU            DO EQUALS MARKER                   40960013
         BC    CEBR,CEMIX              38 PARTIAL REFERENCE             40980015
         EJECT                                                          41000013
*              FUNCTION/OPERATION                                       41040013
         SPACE 3                                                        41080013
*        THE KEYWORD ROUTINE IS ENCOUNTERED ANYTIME THAT A KEYWORD IS   41120013
*        FOUND IN THE TEXT. IT TESTS WHETHER IT IS ONE OF THE KEYWORDS  41160013
*        THAT REQUIRES SPECIAL ACTION TO BE TAKEN. IF IT IS THEN        41200013
*        CONTROL IS PASSED TO THE RELEVANT SUBSECTION. IF NOT CONTROL   41240013
*        IS RETURNED TO THE GENERAL SCAN ROUTINE                        41280013
*                       CEKYST CONTAINS THE 1-BYTE CODED KEYWORD ON     41320013
*        ENTRY          GR7 POINTS AT CURRENT BYTE IN TEXT              41360013
*                       GR6 POINTS AT NEXT AVAILABLE SLOT IN OUTPUT     41400013
*                                                                       41440013
*                                                                       41480013
*                                                                       41520013
*                       PICK UP THE KEYWORD AND TRANSFER                41560013
*                       TO THE APPROPRIATE SECTION                      41600013
         SPACE 3                                                        41640013
*              ENTRY POINT                                              41680013
*                       CEKYWD    CALLED BY      BAL   GR2,CEKYWD.      41720013
         SPACE 3                                                        41760013
*              INPUT                                                    41800013
*              GR6 POINTS AT NEXT AVAILABLE BYTE IN OUTPUT AREA         41840013
*              GR7 POINTS AT THE 1-BYTE CODED KEYWORD.                  41880013
         SPACE 3                                                        41920013
*              OUTPUT                                                   41960013
*              DEPENDS ON KEYWORD UNDER CONSIDERATION.                  42000013
         SPACE 3                                                        42040013
*              EXTERNAL ROUTINES       N/A                              42080013
         SPACE 3                                                        42120013
*              WORK AREA               N/A                              42160013
         SPACE 3                                                        42200013
*              NOTES                                                    42240013
*              REGISTER USAGE ETC DEPENDS ON KEYWORD.                   42280013
         SPACE 3                                                        42320013
CEKYWD   MVC   CEBYTE(1),CEKYST(GRDIC) MOVE KEYWORD                     42360013
         TR    CEBYTE(1),CEKRAN-128    AND TRANSLATE IT TO AN OFFSET    42400013
         XR    GR1,GR1                 PICK UP THE OFFSET               42440013
         IC    GR1,CEBYTE              AND EXECUTE THE RELEVANT BRANCH  42480013
         EX    0,CEKTRB(GR1)           INSTRUCTION                      42520013
         EJECT                                                          42560013
         SPACE                                                          42600013
*                       PROCEDURE IS KEYWORD FOUND, SO UPDATE LEVEL     42640013
*                       POINTERS AND STACK AND SKIP TO SEMI-COLON       42680013
         SPACE 2                                                        42720013
CEKPRC   MVC   CECNTB(1),1(GR7)        UICT ENTRY AND PICK UP THE BLOCK 42760013
         MVC   CECNTC(1),2(GR7)        AND LEVEL COUNT                  42800013
         MVC   CECURL(1),CECNTC        UPDATE CURRENT LEVEL NUMBER      42840013
         MVC   1(2,GR6),1(GR7)         MOVE OVER L AND C                42880013
         LA    GR6,2(0,GR6)            BUMP OUTPUT POINTER              42920013
         CLI   0(GR7),CEPROC           IS THIS PROCEDURE                42960013
         LA    GR7,2(0,GR7)            BUMP SCAN POINTER OVER L AND C   43000013
         BC    CEBNE,CEBUMP            NO                               43040013
         LA    GR7,3(0,GR7)            NO  SO BUMP OVER 1 CHAIN         43080013
CEBUMP   LA    GR7,6(0,GR7)            BUMP OVER 2 CHAIN ENTRIES        43120013
         BC    CEBR,CEKDCL             GO TO SKIP TO SEMI-COLON         43160013
         SPACE 2                                                        43200013
*                       ROUTINE FOR ALL ENDS                            43240013
*        PICK UP LEVEL AND COUNT OF BLOCK INTO WHICH THE SCAN IS        43280013
*        DESCENDING                                                     43320013
         SPACE 2                                                        43360013
CEKEND   MVC   CECNTC(1),2(GR7)        CHANGE BLOCK COUNT               43400013
        MVC   CECURL(1),CECNTC        UPDATE THE CURRENT COUNT SLOT     43440013
         MVC   CECNTB(1),1(GR7)        AND UPDATE BLOCK COUNT           43480013
         MVC   1(2,GR6),1(GR7)         MOVE OVER L AND C                43520013
         LA    GR6,2(0,GR6)            AND BUMP OUTPUT POINTER          43560013
CEENDO   LA    GR7,2(0,GR7)            BUMP SCAN POINTER                43600013
         BCR   CEBR,GR2                                                 43640013
         SPACE 2                                                        43680013
*                       ROUTINE FOR DECLARE AND ENTRY TO DELETE STATE-  43720013
*        MENT INCLUDING SN ETC FOR DECLARE AND THEN POSITION SCAN POINT 43760013
*        -ER AT FIRST NON-BLANK CHARACTER AFTER THE CHAINS ETC          43800013
         SPACE                                                          43840013
CEKDCI   S     GR6,CE5X                REPOSITION TEXT POINTER          43880013
CENNTY   CLI   0(GR7),CENTRY           IS THIS ENTRY                    43920013
CEBMP1   LA    GR7,3(0,GR7)            BUMP POINTER OVER 3-BYTE CHAIN   43960013
         BC    CEBNE,CEKDCL            SKIP NEXT INSTRUCTION FOR DCL    44000013
         SR    GR6,GR15                REMOVE ENTRY BYTEFROM OUTPUT     44040013
         LA    GR7,2(0,GR7)            BUMP OVER LEVEL AND COUNT        44080013
CEKDCL   ST    GR2,CEPIT               SAVE GR2                         44120013
CEBN2    TRT   1(256,GR7),CEKSCT       TRT TO SEMI-COLON                44160013
         BC    CEBZ,CEKMD1             BRANCH IF ONE NOT FOUND IN 256BY 44200013
         L     GR2,CEPIT               RESTORE GR2                      44240013
         LR    GR7,GR1                 TES. SET GR7 UP TO SEMI- COLON   44280013
         BCTR  GR7,0                   AND BACKSPACE ONE                44320013
         BCR   CEBR,GR2                                                 44360013
         SPACE 2                                                        44400013
CEKMD1   LA    GR7,256(0,GR7)          BUMP GR7 BY 256 AND              44440013
         BC    CEBR,CEBN2              TRY ONCE MORE                    44480013
         SPACE 3                                                        44520013
*        THIS IS THE ROUTINE FOR SN CN                                  44560013
*        IT PICKS UP THE CURRENT STATMENT NUMBER AND MOVES SN ETC TO    44600013
*        THE OUTPUT AREA                                                44640013
         SPACE 2                                                        44680013
CEKSN    MVC   CESTNM+2(2,GRDIC),1(GR7)     MOVE REST OF STATEMENT      44720013
CEKSLN   MVC   1(CESNLN,GR6),1(GR7)    PICKING UP STATEMENT NUMBER      44760013
         ST    GR6,CESTNL              STORE POSITION OF SL OR SN       44800013
         LA    GR6,CESNLN(0,GR6)       BUMP POINTERS                    44840013
         LA    GR7,CESNLN(0,GR7)                                        44880013
         BCR   CEBR,GR2                                                 44920013
         SPACE 3                                                        44960013
*        THIS IS THE ROUTINE FOR SN'                                    45000013
*        PICK UP BLOCK LEVEL AND COUNT AND STATEMENT NUMBER FROM THE    45040013
*        ASSOCIATED DICTIONARY ENTRY.                                   45080013
         SPACE 2                                                        45120013
CEKSND   MVC   PAR1+2(2,GRDIC),1(GR7)  MOVE IN DICTIONARY REFERENCE     45160013
*********************************************************************** 45200013
         L     GR4,ZDRAOF(0,11)        AND GO OFF TO CONVERT IT TO      45240013
         BALR  GR14,GR4                                                 45280013
         L     GR5,PAR1(GRDIC)         LOAD GR5 WITH THE ABSOLUTE ADDRE 45320013
*********************************************************************** 45360013
         MVC   CECNTB(1),CESN2L(GR5)   PICK UP BLOCK COUNT              45400013
         MVC   CECNTC(1),CESN2C(GR5)   PICK UP LEVEL COUNT              45440013
         MVC   CESTNM+2(2,GRDIC),3(GR5)     PICK UP STATEMENT NUMBER    45480013
         MVC   CECURL(1),CECNTC        UPDATE CURRENT LEVEL             45520013
         CLI   7(GR7),PEXP             IS THIS PEXP                     45525015
         BC    BNE,CEKSNE            BRANCH IF NOT                      45530015
         MVI   CE2LM(GRDIC),SET        SET 2ND LEVEL MARKER STORE SO    45535015
*                                    THAT ON FINDING BCD OF POINTER     45540015
*                                    LATER IN STATEMENT A DICT ENTRY    45545015
*                                    WILL BE MADE FOR IT IF IT HAS NOT  45550015
*                                    BEEN DECLARED.                     45555015
         BC    B,CEKSLN                                                 45560015
CEKSNE   CLI   7(GR7),BVEXP            IS THIS BVEXP                    45565015
         BC    BNE,CEKSLN            BRANCH IF NOT                      45570015
         MVI   CE2LM(GRDIC),IN         SET 2ND LEVEL STORE TO IN SO     45575015
*                                    THAT BCD OF AREA WILL GET ITSELF A 45580015
*                                    DICT ENTRY                         45585015
         BC    B,CEKSLN                                                 45590015
         SPACE 3                                                        45600013
*        TRANSFER POINT FOR SL OR CL                                    45640013
*        PICK UP STATEMENT NUMBER FROM DICTIONARY ENTRY FOR LABEL       45680013
         SPACE 2                                                        45720013
CEKSL    MVC   PAR1+2(2,GRDIC),1(GR7)  PICK UP DICT ADDRESS             45760013
*********************************************************************** 45800013
         L     GR4,ZDRAOF(0,11)        ADDRESS TO AN ABSOLUTE           45840013
         BALR  GR14,GR4                                                 45880013
         L     GR5,PAR1(GRDIC)         LOAD GR5 WITH THE ABSOLUTE ADDR  45920013
*********************************************************************** 45960013
         MVC   CESTNM+2(2,GRDIC),CESNSN(GR5)     MOVE STATEMENT NUMBER  46000013
         BC    CEBR,CEKSLN                                              46040013
         SPACE 3                                                        46080013
*        TRANSFER POINT FOR P FORMAT ITEM                               46120013
         SPACE                                                          46160013
CEKPFR   BAL   GR4,CEPICT              GO TO PICTURE ROUTINE            46200013
         BCR   CEBR,GR2                                                 46240013
         EJECT                                                          46280013
         SPACE 2                                                        46320013
*                        TRANSFER POINT FOR ON. THIS SIMPLY PUTS        46360013
*                       THE BLOCK AND LEVEL COUNT IN THE TEXT AFTER     46400013
*                       ON BYTE IN THE TEXT                             46440013
*                       IT IS ALSO THE TRANSFER POINT FOR SIGNAL,REVERT 46480013
         SPACE                                                          46520013
CEKON    MVC   1(1,GR6),1(GR7)         MOVE IN CONDITION BYTE           46560013
         MVC   CEONCD(1,GR12),1(GR7)   MOVE ONCONDITON                  46600013
         AR    GR7,GR15                BUMP SCAN POINTER                46640013
         MVC   2(1,GR6),CECNTB         MOVE BLOCK LEVEL INTO TEXT       46680013
         MVC   3(1,GR6),CECNTC         MOVE BLOCK COUNT INTO TEXT       46720013
         LA    GR6,4(0,GR6)            BUMP POINTER                     46760013
         BAL   GR14,CENDTS             GO TO END TEST ROUTINE           46800013
         CLI   0(GR7),CEONKC           IS IT FILE OR CONDITION COND     46840013
         BC    CEBL,CEFONC                                              46880013
         CLI   0(GR7),CECHKN           IS IT CHECK                      46920013
         BC    CEBE,CE30               YES, SO RETURN                   46960013
         CLI   0(GR7),CENCKN           IS IT NOCHECK                    47000013
         BC    CEBE,CE30               YES, SO RETURN                   47040013
         MVI   CE2LM(GRDIC),CEFILE     MOVE FILE TO 2ND LEVEL STORE     47080013
CEFONC   BC    CEBR,CE30                                                47120013
*                                                                       47160013
*                           TRANSFER FOR GET                            47200013
CEGET   MVI    CENFLG,X'FF'           SET GET FLAG                      47240013
        MVI    CEECPF(GR12),X'FF'    NON BIF FLAG                       47280013
        BCR    CEBR,GR2                                                 47320013
         SPACE 3                                                        47360013
*        THIS IS TRANSFER POINT FOR ITERATIVE DO                        47400013
*        MOVE FOLLOWING TWO BYTES TO THE OUTPUT AREA                    47440013
         SPACE 2                                                        47480013
CEKIDO   MVC   1(2,GR6),1(GR7)         MOVE CV AND C TO OUT PUT         47520013
         LA    GR6,2(0,GR6)            BUMP                             47560013
CEKDO    LA    GR7,2(0,GR7)            POINTERS (SCAN OVER BLK NO)      47600013
CASGN   MVI    CEECPF(GR12),X'FF'    NON BIF FLAG                       47640013
         BCR   CEBR,GR2                RETURN                           47680013
         SPACE 3                                                        47720013
*        TRANSFER POINT FOR CALL TO BUMP OVER 4-BYTE CHAIN              47760013
         SPACE                                                          47800013
CEKCEN   CLI   1(GR7),X'FF'            IS NEXT BYTE FF                  47840013
         BC    CEBNE,CEBMX             NO, SO BRANCH                    47880013
         MVC   1(3,GR6),2(GR7)         MOVE IN DICT REF                 47920013
*                       OUTPUT AREA                                     47960013
         LA    GR6,3(0,GR6)            BUMP OUTPUT POINTER              48000013
CEBMX    LA    GR7,4(0,GR7)            BUMP SCAN POINTER                48040013
         BCR   CEBR,GR2                                                 48080013
         SPACE 3                                                        48120013
*        TRANSFER POINT FOR END OF BUFFER TO SET SCAN POINTER TO NEXT   48160013
*        BUFFER                                                         48200013
         SPACE                                                          48240013
CEKEOB   MVC   PAR1+1(3,GRDIC),CETSYM(GRDIC)     MOVE IN SYMBOLIC NAME  48280013
         MVI   PAR2+3(GRDIC),X'01'     MOVE IN CODE BYTE TO FREE BLOCK  48320013
         L     GR5,ZCHAIN(0,GR11)      PICK UP NEXT BLOCK IN CHAIN      48360013
         BALR  GR14,GR5                RELEASING CURRENT BLOCK          48400013
         L     GR7,PAR2(0,GRDIC)       LOAD GR7 WITH THE ABSOLUTE ADDR  48440013
         MVC   CETSYM(3,GRDIC),PAR1+1(GRDIC) OF NEW BLOCK AND UPDATE    48480013
*                                        SYMBOLIC ADDRESS               48520013
         BC    CEBR,CE300                                               48560013
         SPACE 3                                                        48600013
*        TRANSFER POINT FOR EOP TO TIDY UP OR START SECOND FILE         48640013
         SPACE                                                          48680013
CEKEOP   MVC   PAR1+1(3,GRDIC),CESCYM  CONVERT OUTPUT POINTER           48720013
         ST    GR6,PAR2(0,GRDIC)       TO SYMBOLIC ADDRESS              48760013
         L     GR5,ZTXTRF(0,GR11)                                       48800013
         BALR  GR14,GR5                CONVERT TO SYMBOLIC AND STORE    48840013
         CLI   CESFIL,X'00'            IS SECOND FILE FLAG ON           48880013
         BC    CEBE,CE1FIL             NO,SO TRANSFER                   48920013
         MVI   PAR2+3(GRDIC),X'02'     MARK THIS BLOCK                  48960013
         L     GR5,ZALTER(0,GR11)      AS NOT                           49000013
         BALR  GR14,GR5                WANTED ON THIS PART              49040013
         MVC   ZLSTXT+1(3,GRDIC),PAR1+1(GRDIC) IN COMMUNICATIONS REGION 49080013
         MVC   PAR1+1(3,GRDIC),CETSYM(GRDIC)     MOVE IN SYMBOLIC NAME  49120013
         MVI   PAR2+3(GRDIC),X'01'     MOVE IN CFME BYTE TO FREE BLK    49160013
         L     GR5,ZALTER(0,GR11)                                       49200013
         BALR  GR14,GR5                                                 49240013
         ST    GR15,PAR1(0,GRDIC)      SET UP COUNT OF SCRATCH CORE     49280013
*                                      CALLS TO BE RETURNED             49320013
         L     GR1,ZURC(0,GR11)        AND RELEASE                      49360013
         BALR  GR14,GR1                IT                               49400013
*                                                                     * 49440013
         SPACE 3                                                        49480013
*                       THIS SECTION HANDS CONTROL  BACK TO THE         49520013
*                        COMPILER CONTROL AFTER RELEASING THIS PHASE    49560013
*                       PHASE ON THE LIST GIVEN IT BY READ-IN.          49600013
         SPACE 2                                                        49640013
CEOUT    LA    GR1,CELIST              PICK UP                          49680013
         ST    GR1,PAR1(0,GRDIC)       PHASE NAME LIST                  49720013
         XC    PAR2(4,GRDIC),PAR2(GRDIC)    CLEAR PAR2 SO THAT CONTROL  49760013
         L     GR1,RLSCTL(0,GR11)      CAN BE RELEASED TO NEXT PHASE    49800013
         BALR  GR14,GR1                REQUESTED BY READ  IN            49840013
         SPACE 2                                                        49880013
*                        SET SECOND FILE FLAG ON AND RETURN             49920013
         SPACE                                                          49960013
CE1FIL   MVI   CESFIL,X'FF'            SET FLAG ON                      50000013
         L     GR5,PAR1(0,GRDIC)       PICK UP ADDRESS                  50040013
         LA    GR5,1(0,GR5)            ADD ONE AND STORE AT             50080013
         ST    GR5,Z2FILE(0,GRDIC)     IN START OF SECOND FILE SLOT     50120013
         BCR   CEBR,GR2                                                 50160013
         SPACE 3                                                        50200013
CEWAT    MVI   CEWFLG,X'FF'            SET WFLAG ON                     50240013
         BCR   CEBR,GR2                                                 50280013
         SPACE 3                                                        50320013
DATADO   MVI   DATDFL,X'FF'                                             50360013
         MVI   CEECPF(GR12),X'FF'                                       50400013
         BCR   CEBR,GR2                                                 50440013
         EJECT                                                          50480013
*        TRANSLATE TABLE FOR KEYWORDS GIVING OFFSET IN BRANCH TABLE     50520013
         SPACE 2                                                        50560013
CEKRAN   DC    X'000000000000000000'                                    50600013
         DC    X'10'                   WAIT                             50640013
         DC    X'00000000000000000000000000'                            50680013
         DC    X'3800380000'           SIGNAL,REVERT                    50720013
         DC    X'0000004400'           ASSIGN                           50760013
         DC    X'180000'               CALL                             50800013
         DC    X'2000000000'           P FORMAT                         50840013
         DC    X'1C000000'             IMPLICIT                         50880013
         DC    X'1C000000'             DECLARE                          50920013
         DC    X'0C00'                 ENTRY                            50960013
         DC    X'0400'                 PROCEDURE                        51000013
         DC    X'0400'                 BEGIN                            51040013
         DC    X'1400144800'         ITDO,DO,DATA LIST DO               51080013
         DC    X'2C00'                 SN'                              51120013
         DC    13X'00'                                                  51140015
         DC    X'24'               LOCATE                               51160015
         DC    4X'00'                                                   51180015
         DC    X'2800'                 SN                               51200013
         DC    X'3C00'                 SL                               51240013
         DC    X'2840'                 CN AND GET                       51280013
         DC    X'3C'                   CL                               51320013
         DC    X'000000000000'                                          51360013
         DC    X'000000'                                                51400013
         DC    X'00000000000000'                                        51440013
         DC    X'08080800'             END,END DO, END ITDO             51480013
         DC    X'3400'                 ENDPROG                          51520013
         DC    X'3000'                 ENDBLOCK                         51560013
         DC    X'00'                                                    51600013
         DC    X'000000000000'                                          51640013
         DC    X'000000000038'         ON                               51680013
         DC    X'00000000'                                              51720013
         EJECT                                                          51760013
*        TRANSFER TABLE                                                 51800013
         SPACE                                                          51840013
CEKTRB   BCR   CEBR,GR2                TRANSFER FOR NORMAL  KEYWORD     51880013
         BCR   CEBR,GR2                                                 51920013
         BC    CEBR,CEKPRC        4    TRANSFER FOR PROCEDURE           51960013
         BC    CEBR,CEKEND        8    TRANSFER FOR END                 52000013
         BC    CEBR,CENNTY        C    TRANSFER FOR ENTRY               52040013
         BC    CEBR,CEWAT         10   TRANSFER FOR WAIT                52080013
         BC    CEBR,CEKIDO       14    TRANSFER FOR ITERATIVE DO        52120013
         BC    CEBR,CEKCEN       18    TRANSFER FOR CALL                52160013
         BC    CEBR,CEKDCI       1C    TRANSFER FOR DECLARE OR IMPLICIT 52200013
         BC    CEBR,CEKPFR       20    TRANSFER FOR P FORMAT            52240013
         BC    CEBR,CELOCT         24 PAST TRANSFER FOR LOCATE          52280015
         BC    CEBR,CEKSN        28    TRANSFER FOR SN ETC              52320013
         BC    CEBR,CEKSND       2C    TRANSFER FOR SN'                 52360013
         BC    CEBR,CEKEOB        30   TRANSFER FOR EOB                 52400013
         BC    CEBR,CEKEOP        34   TRANSFER FOR END OF PROGRAM      52440013
         BC    CEBR,CEKON              38   TRANSFER FOR ON             52480013
         BC    CEBR,CEKSL              3C   TRANSFER FOR SL CL          52520013
        BC     CEBR,CEGET             40  TRANSFER FOR GET              52560013
         BC    CEBR,CASGN              44   TRANSFER FOR ASSIGN         52600013
         BC    CEBR,DATADO           DATA LIST DO                       52640013
         EJECT                                                          52680013
*                       TRANSLATE TABLE FOR SEMI-COLON                  52720013
*        AND END OF BLOCK MARKER                                        52760013
         SPACE 2                                                        52800013
CEKSCT   DC    23X'00000000000000000000'                                52840013
         DC    X'00000000000000FF00'                                    52880013
         DC    X'FF'                                                    52920013
         DC    2X'0000000000000000'                                     52960013
         EJECT                                                          53000013
*                       THIS ROUTINE SCANS DICTIONARY FOR CORRECT       53040013
*        DICTIONARY FOR GIVEN BCD                                       53080013
*                                                                       53120013
*                       ON ENTRY GR7 POINTS BCD LENGTH BYTE IN TEXT     53160013
*                                GR6 POINTS AT NEXT FREE BYTE IN THE    53200013
*                       OUTPUT BLOCK                                    53240013
*                       ALL REGISTERS USED ARE SAVED BY THE ROUTINE AND 53280013
*                       RESTORED                                        53320013
*                       ON EXIT GR7 POINTS AT LAST BYTE OF BCD          53360013
*                               GR6 POINTS AT END OF DICTIONARY REFER-  53400013
*                       ENCE JUST PLACED IN OUTPUT BLOCK                53440013
         SPACE 2                                                        53480013
*                       INITIALISATION AND HASHING                      53520013
*        POINT AT BCD AND HASH IT, TO GIVE OFFSET FROM START OF HASH    53560013
*        TABLE. IF SLOT IS ZERO THEN A NEW ENTRY IS REQUIRED, IF NOT    53600013
*        THEN THE HASH CHAIN MUST BE SCANNED.                           53640013
         SPACE                                                          53680013
*              SAVE START ADDRESS OF VARIABLE IN TEXT AND POSITION      53720013
*        POINTER AT START OF LAST SECTION OF VARIABLE'S BCD. I.E. AT    53760013
*        START FOR A NON-QUALIFIED NAME OR BEFORE LAST ITEM IN A        53800013
*        QUALIFIED NAME                                                 53840013
         SPACE 3                                                        53880013
*              FUNCTION/OPERATION                                       53920013
*                       TO SCAN THE DICTIONARY FOR A GIVEN BCD AND TO   53960013
*              RETURN THE ADDRESS OF THE RELEVANT DICTIONARY ENTRY WITH 54000013
*              THE SAME BCD AND WHICH IS KNOWN AT THIS POINT OF THE     54040013
*              PROGRAM. AN ILLEGAL ENTRY WILL RETURN A DUMMY REFERENCE  54080013
*              AND AN ERROR MESSAGE IS PRODUCED.                        54120013
*                       THIS SYMBOLIC ADDRESS IS PLACED IN THE OUTPUT   54160013
*              TEXT PRECEDED BY A ZERO BYTE.                            54200013
         SPACE 3                                                        54240013
*              ENTRY POINT                                              54280013
*                       CESCN - ENTERED BY       BAL   GR2,CESCN        54320013
         SPACE 3                                                        54360013
*              INPUT                                                    54400013
*              GR7 POINTS AT THE BCD LENGTH BYTE BEFORE THE BCD.        54440013
*              GR6 POINTS AT THE NEXT AVAILABLE BYTE IN THE OUTPUT AREA 54480013
         SPACE 3                                                        54520013
*              OUTPUT                                                   54560013
*              GR7 POINTS AT THE LAST BYTE OF THE BCD                   54600013
*              GR6 POINTS AT THE END OF DICTIONARY ENTRY IN THE OUTPUT  54640013
*              AREA.                                                    54680013
         SPACE 3                                                        54720013
*              EXIT     NORMAL - RETURN ON GR2.                         54760013
         SPACE 3                                                        54800013
*              WORK AREA                                                54840013
*              1K OF SCRATCH IS USED. START ADDRESS OF THIS AREA IS     54880013
*              IN CESTKA.                                               54920013
         SPACE 3                                                        54960013
*              NOTES                                                    55000013
*              REGISTERS USED ARE SAVED ON ENTRY AND RESTORED ON EXIT.  55040013
         SPACE 3                                                        55080013
         SPACE                                                          55120013
         SPACE                                                          55160013
CESCN    STM   GR14,GR5,SAVE3          SAVE REGISTERS 14 TO 5 INCLUSIVE 55200013
         SPACE                                                          55240013
*              CLEAR FLAGS AND SET UP COUNTS ETC. LOOK AT FIRST BCD     55280013
         SPACE                                                          55320013
         XC    CEFLAG(4),CEFLAG        CLEAR FLAGS                      55360013
         XC    OLDSTR(4,GRDIC),OLDSTR(GRDIC) CLEAR DICTIONARY REF STORE 55400013
         L     GR4,STKCNT              PICK UP STACK COUNT              55440013
         XR    GR4,GR4                 AND SET TO ZERO                  55480013
         ST    GR7,TXTSTR              SAVE START ADDRESS               55520013
         SPACE                                                          55560013
*              PICK UP BCD LENGTH AND SEE IF THIS IS A QUALIFIED NAME   55600013
*        OR ILLEGAL BCD LENGTH.                                         55640013
         SPACE                                                          55680013
         XR    GR1,GR1                 PICK UP                          55720013
         IC    GR1,0(0,GR7)            PICK UP BCD                      55760013
         CLI   0(GR7),MAXBCD           BCD LENGTH                       55800013
         BC    CEBH,CERR27             IS LENGTH TOO LONG               55840013
*                                      IF SO IT IS AN ERROR             55880013
         L     GR2,CESTKA              PICK UP START OF STACK           55920013
         ST    GR7,0(GR4,GR2)          STORE START OF TEXT AT BOTTOM    55960013
         AR    GR7,GR1                 IF NOT BUMP TO END OF BCD        56000013
         SPACE                                                          56040013
*              IS NEXT IN TEXT A . IF SO, THIS IS A QUALIFIED NAME      56080013
         SPACE                                                          56120013
         CLI   1(GR7),CEFSTP           IS NEXT ITEM A .                 56160013
         BC    CEBNE,CENQUL            NO SO THIS IS NOT A QUALIFIED    56200013
*                                      NAME                             56240013
         SPACE                                                          56280013
*              QUALIFIED NAME SO WORK ALONG TO ITS END SAVING START OF  56320013
*        EACH NEW BCD IN A STACK AND KEEPING A COUNT.                   56360013
         SPACE                                                          56400013
CEIDLP   LA    GR4,4(0,GR4)            BUMP STACK COUNT                 56440013
         LA    GR7,2(0,GR7)            BUMP SCAN POINTER OVER .         56480013
         ST    GR7,0(GR4,GR2)          SAVE ADDRESS OF NEXT BCD LENGTH  56520013
*                                      BYTE                             56560013
         CLI   0(GR7),MAXBCD           IS LENGTH TOO LONG               56600013
         BC    CEBH,CERR27             YES SO ERROR                     56640013
         IC    GR1,0(0,GR7)            NO, SO PICK UP LENGTH            56680013
         AR    GR7,GR1                 AND BUMP SCAN POINTER TO END OF  56720013
         CLI   1(GR7),CEFSTP           BCD. IS NEXT ITEM .              56760013
         BC    CEBE,CEIDLP             YES, SO CONTINUE SCAN            56800013
         BC    CEBR,CENDQL             NO, SO FINISH HERE               56840013
         SPACE 2                                                        56880013
*              SET FLAG ON AS THIS IS A NON-QUALIFIED NAME              56920013
         SPACE                                                          56960013
CENQUL   OI    CEFLAG,NONQUL           SET NON QUALIFIED BIT ON         57000013
         SPACE                                                          57040013
*              SAVE STACK COUNT AND POINT AT START OF BCD               57080013
         SPACE                                                          57120013
CENDQL   ST    GR4,STKCNT              SAVE STACK COUNT                 57160013
         ST    GR7,ENDADR              SAVE ADDRESS OF LAST BYTE OF     57200013
         L     GR7,0(GR2,GR4)          PICK  UP LAST ENTRY IN STACK     57240013
         SPACE                                                          57280013
*              SET UP REGISTERS FOR CALL TO HASH ROUTINE                57320013
         SPACE                                                          57360013
         BCTR  GR1,0                   REDUCE GR1 TO BCD LENGTH-1       57400013
         LA    GR5,1(0,GR7)            POINT GR5 AT THE BCD             57440013
         LR    GR14,GR1                SAVE GR1 IN GR14                 57480013
         BAL   GR15,CHASH              BRANCH TO HASH ROUTINE           57520013
*********************************************************************** 57560013
         L     GR2,ZHASH(0,GRDIC)      SET GR2 TO POINT AT START OF HAS 57600013
       AR      GR2,GR0                 GR2 POINTS AT THE CORRECT ENTRY  57640013
         CLC   0(2,GR2),CEZERO         IS HASH ENTRY ZERO AND A STOPPER 57680013
         BC    CEBE,CEC31          YES, SO BRANCH                       57720013
CEC2A    MVC   PAR1+2(2,GRDIC),0(GR2)  IN HASH TABLE SO WE MOVE POINTER 57760013
         MVC   CELSYM(2,GR12),0(GR2)    TO DICT ENTRY FROM HASG TABLE   57800013
         L     GR3,ZDRFAB(0,GR11)      CONVERT                          57840013
         ST    GR14,CEG14              SAVE GR14                        57880013
         BALR  GR14,GR3                TO ABSOLUTE                      57920013
         L     GR14,CEG14              RESTORE GR14                     57960013
         EJECT                                                          58000013
*        FROM ENTRY IN HASH TABLE. CHASH RETURNED OFFSET FROM START OF  58040013
*        HASH TABLE IN GR0. ADDRESS OF START OF HASH GABLE IS IN        58080013
*        COMMUNICATION REGION.                                          58120013
         SPACE                                                          58160013
CE3AX    L     GR3,PAR1(0,GRDIC)       GR3 CONTAINS DICT ENTRY ADDRESS  58200013
         ST    GR3,CADD2(0,GR12)       SAVE IN CADD2                    58240013
         SPACE                                                          58280013
*              IF THIS SHOULD BE A STRUCTURE AND IS NOT,THEN THERE IS   58320013
*        NO POINT DOING ANY MORE TESTING                                58360013
         SPACE                                                          58400013
CEGOAG   TM    CEFLAG,NONQUL           IS NOT QUALIFIED NAME FLAG ON    58440013
         BC    CEBO,CE3A               YES, SO BRANCH TO  COMPARE BCD   58480013
         TM    0(GR3),CESTRC           IS THIS A STRUCTURE              58520013
         BC    CEBO,CE3A               YES, SO COMPARE BCD              58560013
         CLI   0(GR3),CEFPCB           IS IT A FORMAL PARAMETER         58600013
         BC    CEBNE,CE22              NO, SO TRY AGAIN                 58640013
         SPACE                                                          58680013
*              TEST BCD. IF BCD IN DICTIONARY AND TEXT DO NOT AGREE     58720013
*        THEN RETURN IS TO RETURN ADDRESS 14.                           58760013
         SPACE                                                          58800013
CE3A     BAL   GR15,CE3XX                                               58840013
         BC    CEBR,CEAGRE             YES,AGREES.                      58880013
         BC    CEBR,CE22               NO BCD AGREEMENT                 58920013
         EJECT                                                          58960013
*        THIS ROUTINE COMPARES THE SOURCE VARIABLE AND DICT ENTRY TO    59000013
*        SEE IF THE LENGTH OF THE BCD'S IS THE SAME AND IF SO           59040013
*        WHETHER THE BCD IS THE SAME.                                   59080013
*        GR7 POINTS TO THE LENGTH BYTE IN THE SOURCE TEXT               59120013
*        IF VARIABLE IS A FORMAL PARAMTER THEN GR3 IS SET TO THE        59160013
*        DETAILED DICT ENTRY IF AGREEMENT WAS FOUND IN THE BCD'S.       59200013
*        IF NO BCD IS FOUND A RETURN IS MADE TO SCAN THE HASH CHAIN .   59240013
         SPACE 2                                                        59280013
CE3XX    TM    0(GR3),X'80'            IS BCD ATTACHED TO THIS ENTRY    59320013
         BC    CEBO,CE22               NO, SO BRANCH                    59360013
         MVC   CELENG+2(2),1(GR3)      YES,SO PICK UP LENGTH UP TO BCD  59400013
         L     GR1,CELENG              LOAD LENGTH TO BCD IN GR1        59440013
         XR    GR2,GR2                                                  59480013
         IC    GR2,0(GR1,GR3)          PICK UP BCD LENGTH OF DICT ENTRY 59520013
         CR    GR2,GR14                COMPARE REGISTERS TO SEE IF BCD  59560013
         BC    CEBNE,CE22B             LENGTHS ARE EQUAL. NO,SO BRANCH  59600013
         STC   GR2,CECOMP+1            YES,SO IS BCD THE SAME. SET UP   59640013
         AR    GR1,GR3                 INSTRUCTION.GR1 POINTS AT LENGTH 59680013
         SPACE 2                                                        59720013
CECOMP   CLC   1(0,GR1),1(GR7)         COMPARE BCD'S                    59760013
         BC    CEBE,CE22CZ             THEY DO AGREE                    59800013
         SPACE 2                                                        59840013
CE22B    LA    GR15,4(0,GR15)          BUMP RETURN ADDRESS BY 4         59880013
CE22CZ   BCR   CEBR,GR15                                                59920013
         EJECT                                                          59960013
*                       BCD AGREED AND THE LEVEL SO NOW SEE IF THIS     60000013
*                       IS A FORMAL PARAMETER ENTRY. IF SO THEN PICK    60040013
*                       UP ADDRESS FO COMPLETE ENTRY OR IF NONE MAKE    60080013
*                       ONE.                                            60120013
         SPACE                                                          60160013
CE22CC   CLI   0(GR3),X'40'            IS THIS A FORMAL PARAMETER       60200013
         BC    CEBNE,CE2K              NO, SO RETURN                    60240013
         CLC   CENWAD(2,GR3),CEZERO    IS THERE A FULL ENTRY'S ADDRESS  60280013
         BC    CEBE,CE22CE             NO                               60320013
*********************************************************************** 60360013
CEFPQQ   MVC   PAR1+2(2,GRDIC),CEFPFA(GR3) YES SO PICK UP FULL ENT AD   60400013
         MVC   CEFRSM(2),CELSYM(GR12)  SAVE SYMBOLIC ADDR. OF FP ENTRY  60440013
         MVC   CELSYM(2,GR12),CEFPFA(GR3)    AND                        60480013
         L     GR3,ZDRFAB(0,GR11)       CONVERT                         60520013
         ST    GR14,CEG14              SAVE GR14                        60560013
         BALR  GR14,GR3                 TO ABSOLUTE                     60600013
         L     GR14,CEG14              RESTORE GR14                     60640013
         L     GR3,PAR1(0,GRDIC)        SET GR3 TO FULL ENTRY           60680013
*********************************************************************** 60720013
CE22C    BC    CEBR,CE2                                                 60760013
         SPACE                                                          60800013
CE22CE   TM    CEFLAG,NONQUL           IS THIS A QUALIFIED N AME        60840013
         BC    CEBZ,CE22               YES, SO CONTINUE SCAN            60880013
         ST    GR3,CADD2(0,GR12)       STORE IN CADD2                   60920013
         MVC   CACL(1,GR12),CFPEL(GR3) MOVE IN 3-                       60960013
         MVC   CACC(1,GR12),CFPEC(GR3) AND C TO COLLECTION AREA         61000013
         BAL   GR2,CFPDR2              BRANCH TO ENTER CONSTANT         61040013
         BC    CEBR,CEFPQQ                                              61080013
         EJECT                                                          61120013
*        CHECK TO SEE IF DICT ENTRY COULD BE A VALID ENTRY              61160013
*                       CHECK TO SEE IF THE BLOCK COUNT OF THIS ENTRY   61200013
*        IS THE SAME OR KNOWN FROM THE CURRENT BLOCK.                   61240013
         SPACE                                                          61280013
CEAGRE   BCTR  GR1,0                   PICK  UP LEVL NO                 61320013
         CLC   CECURL(1),0(GR1)        IS CURRENT LEVEL NUMBER THE SAME 61360013
         BC    CEBE,CE22CC             AS DICT ENTRY'S, YES SO BRANCH   61400013
         BC    CEBL,CE22               LESS THAN                        61440013
         SPACE 2                                                        61480013
*                       THIS TESTS WHETHER LEVEL IS KNOWN FROM MAPSTK   61520013
         SPACE                                                          61560013
CEJ31    XR    GR15,GR15               CLEAR GR15                       61600013
         LR    GR5,GR15                AND GR5                          61640013
         LR    GR2,GR15                AND GR2                          61680013
         IC    GR15,CECURL             PICK UP CURRENT LEVEL NO IN GR15 61720013
         IC    GR5,0(0,GR1)            PICK UP DICT LEVEL NO IN GR5     61760013
         L     GR4,ZCDSTK(0,GRDIC)     PICK UP START OF STACK           61800013
CELOOP   IC    GR2,0(GR15,GR4)         PICK UP CONSTANT IN TABLE        61840013
         CR    GR5,GR2                 IS IT EQUAL TO DICT LEVEL        61880013
         BC    CEBE,CE22CC             YES, SO CHECK FOR FORMAL PARAM   61920013
         BC    CEBH,CE22               IS DICT LEVEL GREATER,YES SO OUT 61960013
         LR    GR15,GR2                NO, SO PICK UP NEW OFFSET FROM   62000013
         BC    CEBR,CELOOP             START OF STACK AND TRY AGAIN     62040013
         SPACE 2                                                        62080013
*              THE BCD AND LEVEL NUMBER ARE SATISFACTORY. SAVE LEVEL    62120013
*        NUMBER. IF THIS IS A QUALIFIED NAME WE MUST START TO SCAN      62160013
*        STRUCTURE TO SEE IF IT IS THE RIGHT ONE. IF NOT THEN THIS      62200013
*        ENTRY MAY BE THE FINAL ONE                                     62240013
         SPACE                                                          62280013
CE2K     MVC   CEFRSM(2),CELSYM(GR12)  SAVE SYMBOLIC ADDRESS OF ENTRY   62320013
*                                      WITH BCD                         62360013
CE2      MVC   CELVLX(1),0(GR1)        SAVE BLOCK LEVEL                 62400013
         TM    CEFLAG,NONQUL           IS THIS A QUALIFIED NAME         62440013
         BC    CEBO,CENRND             NO, SO BRANCH OUT                62480013
         TM    0(GR3),CESTRC           IS THIS ENTRY A STRUCTURE        62520013
         BC    CEBZ,CEPKUP             NO, SO GO TO CONTINUE SCAN OF    62560013
*                                      HASH CHAIN                       62600013
*              SEE IF WE HAVE A DICTIONARY REFERENCE IN STORE FOR THIS  62640013
*        TEXT  ITEM. IF NOT SAVE THIS ONE. IF YES AND ITS COUNT IS NOT  62680013
*        THE SAME LEAVE THE STORE ALONE, OTHERWISE SAVE CURRENT REFER-  62720013
*        ENCE                                                           62760013
         SPACE                                                          62800013
CESTTS   CLC   OLDSTR+2(2,GRDIC),CEZERO     IS OLD STORE EMPTY          62840013
         BC    CEBE,CEADSV             YES                              62880013
         CLC   OLDLVL(1),CELVLX        NO, SO ARE BLOCK COUNT  DIFFER-  62920013
         BC    CEBNE,CEPOST            ENT, NO SO BRANCH OUT AT END     62960013
CEADSV   MVC   OLDSYM(2),CELSYM(GR12)  SAVE SYMBOLIC ADDRESS AND        63000013
         MVC   OLDLVL(1),CELVLX        BLOCK COUNT                      63040013
         SPACE 2                                                        63080013
*              NOW THAT A VALID REFERENCE HAS BEEN FOUND SCAN DOWN THE  63120013
*        CHAIN WITHIN THE STRUCTURE MATCHING ITS BCD WITH THE TEXT      63160013
         SPACE                                                          63200013
         L     GR2,STKCNT              PICK UP STACK COUNT              63240013
         L     GR1,CESTKA              PICK UP START OF STACK           63280013
         MVC   CESTSM(2),CEFRSM        SAVE SYMBOLIC ADDRESS OF BCD     63320013
*                                      ENTRY                            63360013
         SPACE                                                          63400013
*              GET ADDRESS OF CONTAINING STRUCTURE, SEE IF THIS IS END  63440013
*        OF STACK. IF SO, THIS STRUCTURE SCAN IS OVER. IF NOT, REDUCE   63480013
*        STACK COUNT AND LOOK AT NEXT BCD ELEMENT IN TEXT               63520013
CESTSC   BAL   GR4,CESTUC              GO TO GET ADDRESS OF CONTAINING  63560013
*                                      STRUCTURE                        63600013
         LTR   GR2,GR2                 IS STACK COUNT ZERO              63640013
         BC    CEBZ,CEPMST             YES, SO BRANCH OUT               63680013
         S     GR2,CE4                 REDUCE STACK COUNT BY 4          63720013
         SPACE                                                          63760013
*              IF THE ADDRESS OF THE CONTAINING STRUCTURE IS ZERO THEN  63800013
*        WE ARE ALREADY AT END OF THIS STRUCTURE AND AS THE END OF TEXT 63840013
*        HAS NOT BEEN REACHED WE HAD BETTER TRY AGAIN                   63880013
         SPACE                                                          63920013
CECSTS   CLC   PAR1+2(2,GRDIC),CEZERO  IS CONTAINING STRUC ADDR ZERO    63960013
         BC    CEBE,CEPKUP             YES, SO CONTINUE SCAN            64000013
         L     GR7,0(GR2,GR1)          NO, SO PICK UP NEXT TEXT ADDRESS 64040013
         L     GR15,ZDRFAB(0,GR11)     CONVERT DICTIONARY REFERENCE TO  64080013
         BALR  GR14,GR15               ABSOLUTE                         64120013
         L     GR3,PAR1(0,GRDIC)       AND POINT GR3 AT IT              64160013
         TM    0(GR3),CENOBC           HAS THIS ANY BCD                 64200013
         BC    CEBO,CEFPHO             NO, SO GO TO FP ENTRY            64240013
         SPACE                                                          64280013
*              WE ARE NOW LOOKING AT NEXT STRUCTURE OR ITS FORMAL PARA- 64320013
*        METER ENTRY. NOW TEST BCD FOR AGREEMENT. IF AGREEMENT OCCURS   64360013
*        CONTINUE SCAN,IF NOT THEN REFERENCE IS NOT CONTINUOUS SO WE    64400013
*        SET FLAG ON AND CONTINUE TO SCAN STRUCTURE TO FIND AN AGREEING 64440013
*        BCD                                                            64480013
         SPACE                                                          64520013
CEBCDC   XR    GR14,GR14               CLEAR GR14                       64560013
         IC    GR14,0(0,GR7)           PICK UP BCD LENGTH               64600013
         BCTR  GR14,0                                                   64640013
         STM   GR1,GR2,CEDMP1          SAVE REGISTERS GR1 AND GR2       64680013
         BAL   GR15,CE3XX              GO TO COMPARE BCD'S              64720013
         BC    CEBR,CESTSX             AGREEMENT SO CONTINUE SCAN       64760013
         OI    CEFLOG,NONCON           NO AGREEMENT SO SET NOT CONTIN-  64800013
*                                      UOUS FLAG ON                     64840013
         LM    GR1,GR2,CEDMP1          RESTORE GR1 AND GR2              64880013
         BAL   GR4,CESTUC              GET NEXT STRUCTURE MEMBER IN     64920013
         BC    CEBR,CECSTS                                              64960013
CESTSX   LM    GR1,GR2,CEDMP1          RESTORE REGISTERS GR1,GR2        65000013
         BC    CEBR,CESTSC             CHAIN AND TRY AGAIN              65040013
         SPACE 2                                                        65080013
*              END(START) OF TEXT HAS BEEN REACHED SO SEE IF THIS IS    65120013
*        ALSO THE END(START) OF THE STRUCTURE. IF IT IS NOT WE SET      65160013
*        MINSTR FLAG ON.                                                65200013
CEPMST   CLC   PAR1+2(2,GRDIC),CEZERO  IS THIS A MAJOR STRUCTURE        65240013
         BC    CEBE,CEOSTS             YES, SO SKIP NEXT INSTRUCTION    65280013
         OI    CEFLOG,MINSTR           NO, SO SET FLAG ON               65320013
         SPACE 2                                                        65360013
*              IF THERE IS NO DICTIONARY REFERENCE IN STORE THEN WE     65400013
*        MUST SAVE THIS ONE AND THE FLAGS                               65440013
         SPACE                                                          65480013
CEOSTS   CLC   OLDSTR+2(2,GRDIC),CEZERO IS OLD STORE ZERO               65520013
         BC    CEBNE,OLDFTS            NO, SO GO TO CARRY OUT MORE TEST 65560013
         SPACE                                                          65600013
*              SAVE THIS DICTIONARY REFERENCE AND ASSOCIATED FLAGS AND  65640013
*        TURN AMBIGUOUS FLAG OFF                                        65680013
         SPACE                                                          65720013
CESVLE   MVC   OLDSTR+2(2,GRDIC),OLDSYM UPDATE OLD STORE                65760013
         MVC   OLDFLG(1),CEFLOG        SAVE FLAGS                       65800013
         NI    CEFLAG,NOAMBG           TURN AMBIGUOUS FLAG OFF          65840013
         BC    CEBR,CEPKUP             AND TRY AGAIN.                   65880013
         SPACE                                                          65920013
*              NOW TEST THE NEW AND OLD FLAGSTO SEE IF THIS             65960013
*        IS A VALID ENTRY AN INVALID ENTRY OR AN AMBIGUOUS ENTRY        66000013
         SPACE                                                          66040013
OLDFTS   TM    OLDFLG,NONMIN           ARE BOTH OLD FLAGS OFF           66080013
         BC    CEBNZ,CEBOFF            NO, SO BRANCH                    66120013
         TM    CEFLOG,NONMIN           YES, SO ARE BOTH NEW FLAGS OFF   66160013
         BC    CEBNZ,CEPKUP            NO, SO CONTINUE SCAN. YES THEN   66200013
*                                      IT IS AN AMBIGUOUS ENTRY         66240013
         SPACE 2                                                        66280013
*              FOR AN AMBIGUOUS ENTRY TURN FLAG ON AND TRY AGAIN        66320013
         SPACE                                                          66360013
CEAMBG   OI    CEFLAG,AMBFLG           SET AMBIGUOUS FLAG ON            66400013
         BC    CEBR,CEPKUP                                              66440013
         SPACE 2                                                        66480013
*              OLD STORE WAS NOT EMPTY SO TEST THE OLD AND CURRENT FLAG 66520013
*        TO SEE WHICH IS THE BETTER ENTRY OR IF THERE IS AMBIGUITY.     66560013
*              BOTH OLD FLAGS WERE NOT OFF SO IF BOTH NEW FLAGS ARE OFF 66600013
*        THEN THIS IS THE REFERENCE TO SAVE                             66640013
         SPACE                                                          66680013
CEBOFF   TM    OLDFLG,NONMIN           ARE BOTH OLD FLAGS ON            66720013
         BC    CEBO,CEBTON             YES, SO GO TO TEST NEW FLAGS     66760013
         TM    CEFLOG,NONMIN           NO, SO ARE BOTH NEW FLAGS OFF    66800013
         BC    CEBZ,CESVLE             YES, SO SAVE THIS ENTRY          66840013
         BC    CEBR,CEAMBG                                              66880013
         SPACE                                                          66920013
*              BOTH OLD FLAGS WERE ON, SO UNLESS BOTH NEW FLAGS ARE OFF 66960013
*        THIS IS AN AMBIGUOUS REFERENCE                                 67000013
         SPACE                                                          67040013
CEBTON   TM    CEFLOG,NONMIN           ARE BOTH NEW FLAGS OFF           67080013
         BC    CEBZ,CESVLE             YES, SO SAVE ADDRESS             67120013
         BC    CEBR,CEAMBG             NO, SO THIS IS AMBIGUOUS         67160013
         SPACE 2                                                        67200013
*              HASH CHAIN SLOT WAS EMPTY SO THIS IS END OF THE SEARCH   67240013
*        NOW SEARCH STORES ETC TO SEE IF ENTRY HAS BEEN FOUND. IF NON   67280013
*        HAS BEEN FOUND FOR A QUALIFIED NAME OR ONLY AN AMBIGUOUS       67320013
*        REFERENCE THEN THIS IS AN ERROR. IF NON HAS BEEN FOUND FOR A   67360013
*        NON-QUALIFIED NAME THEN A DEFAULT DATA DICTIONARY ENTRY MUST   67400013
*        BE MADE                                                        67440013
         SPACE 2                                                        67480013
CEC31X   LA    GR2,3(0,GR3)            SET GR2 3 BYTES BEFORE ENTRY     67520013
CEC31    TM    CEFLAG,NONQUL           IS NON QUALIFIED FLAG ON         67560013
         BC    CEBZ,CEPOST             NO, SO TEST REST OF FLAGS        67600013
         CLC   OLDSTR+2(2,GRDIC),CEZERO YES, SO IS STORE EMPTY          67640013
         BC    CEBE,CENWNT             YES, SO NEW ENTRY IS NEEDED      67680013
CEPOST   TM    CEFLAG,AMBFLG           IS AMBIGUOUS FLAG ON             67720013
         BC    CEBO,CERR3              YES, SO GO TO GIVE ERROR MESSAGE 67760013
         CLC   OLDSTR+2(2,GRDIC),CEZERO  IS STORE EMPTY                 67800013
         BC    CEBNE,CEFIN1            NO, SO GO TO PUT DICTIONARY REF- 67840013
*                                      ERENCE INTO TEXT                 67880013
         BC    CEBR,CERR4              YES, SO ITS AN ERROR             67920013
         SPACE                                                          67960013
*              NEW DICTIONARY ENTRY NEEDED SO SET UP PARAMETERS TO MAKE 68000013
*              IT                                                       68040013
         SPACE                                                          68080013
CENWNT   XC    CADD1(4,GR12),CADD1(GR12) CLEAR CADD1                    68120013
         S     GR2,CE3                 REDUCE POINTER BY 3              68160013
         ST    GR2,CADD2(0,GR12)       AND STORE                        68200013
         A     GR2,CE3                 RESTORE POINTER                  68240013
         BAL   GR2,CEPFDR              GO TO MAKE DICTIONARY ENTRY      68280013
         BC    CEBR,CEFIN1                                              68320013
         SPACE 2                                                        68360013
*              ROUTINE TO PICK UP ADDRESS OF CONTAINING STRUCTURE. ON   68400013
*        RETURN THE SYMBOLIC ADDRESS IS IN PAR1                         68440013
         SPACE                                                          68480013
CESTUC   MVC   PAR1+2(2,GRDIC),CESTSM  PICK UP SYMBOLIC ADDR OF STRUCT  68520013
         L     GR15,ZDRFAB(0,GR11)     -TURE AND CONVERT TO ABSOLUTE    68560013
         BALR  GR14,GR15                                                68600013
         L     GR15,PAR1(0,GRDIC)      GR15 POINTS AT START OF STRUCT   68640013
         LR    GR5,GR15                SET GR5 TO START OF STRUCTURE    68680013
         TM    0(GR15),CEBASE          IS THIS A BASE ELEMENT           68720013
         BC    CEBNO,CEDIMQ            NO, SO SKIP NEXT INSTRUCTION     68760013
         LA    GR5,CEBEPL(0,GR5)       YES, SO BUMP COUNT BY ADDITIONAL 68800013
*                                      NUMBER OF BYTES                  68840013
         SPACE                                                          68880013
*              CALCULATE TOTAL OFFSET OF STRUCTURE INFORMATION FROM     68920013
*        START OF VARIABLE INFORMATION IN A STRUCTURE MEMBER            68960013
         SPACE                                                          69000013
CEDIMQ   TM    0(GR15),CEDIMS          IS THIS A DIMENSIONED STRUCTURE  69040013
         BC    CEBZ,CENOUN             NO, SO SKIP NEXT INSTRUCTION     69080013
         LA    GR5,CEDIMZ(0,GR5)       YES, SO BUMP BY DIM INFO LENGTH  69120013
CENOUN   MVC   PAR1+2(2,GRDIC),CEVARN+CECNSR(GR5) MOVE ADDRESS OF CON-  69160013
         MVC   CESTSM(2),PAR1+2(GRDIC) TAINING STRUCTURE INTO PAR1 AND  69200013
*                                      STORE                            69240013
         BCR   CEBR,GR4                AND RETURN                       69280013
         SPACE 2                                                        69320013
*              ENTRY HAS NO BCD ATTACHED SO GO BACK TO FORMAL PARAMETER 69360013
*        ENTRY TO COMPARE THE BCD.                                      69400013
         SPACE                                                          69440013
CEFPHO   MVC   PAR1+2(2,GRDIC),CEFPCH(GR3) PICK UP POINTER TO FP ENTRY  69480013
         L     GR15,ZDRFAB(0,GR11)     CONVERT                          69520013
         BALR  GR14,GR15               TO ABSOLUTE                      69560013
         L     GR3,PAR1(0,GRDIC)       AND POINT GR3 AT ENTRY           69600013
         BC    CEBR,CEBCDC                                              69640013
         SPACE 2                                                        69680013
*              THIS IS A SUCCESSFUL REFERENCE AND THIS IS A NON-QUALIF- 69720013
*        IED NAME SO IF THIS DICTIONARY REFERENCE IS NOT A STRUCTURE WE 69760013
*        ARE CORRECT                                                    69800013
         SPACE                                                          69840013
CENRND   TM    0(GR3),CESTRD           IS THIS A STRUCTURE              69880013
         BC    CEBO,CESTTS             YES SO TRY ONCE MORE             69920013
         CLI   0(GR3),CVARBL       IS THIS DATA VARIABLE                69930015
         BC    CEBNE,CEFLTS                                             69940015
         LA    GR14,CNRND1                                              69950015
         BC    CEBR,CECHK          CHECKIF POINTER EVENT OR AREA        69960015
CEFLTS   CLI   CE2LM(GRDIC),CEFILE                                      69970015
         BC    CEBE,CNRND1                                              70000013
         CLI   0(GR3),X'06'          IS IT A FUNCTION                   70040013
         BC    CEBH,CNRND1                                              70080013
CERTRN   LM    GR14,GR5,SAVE3      RETURN                               70120015
         L     GR7,ENDADR                                               70160013
         L     GR4,S1                                                   70200013
         BC    B,CEIDOK                                                 70240013
CNRND1   CLC   OLDSTR+2(2,GRDIC),CEZERO  IS STORE ZERO                  70280013
         BC    CEBNE,CEPOST            NO, SO BRANCH TO TEST ENTRY      70320013
         MVC   OLDSTR+2(2,GRDIC),CELSYM(GR12)  SAVE DICTIONARY REF      70360013
         SPACE 2                                                        70400013
*              FINISH OFF BY PUTTING ZERO BYTE AND REFERENCE INTO TEXT  70440013
*        BUMPING SCAN POINTER TO END OF VARIABLE AND RETURNING          70480013
         SPACE 3                                                        70520013
CEFIN1   MVC   PAR1+2(2,GRDIC),CECTST+2(GRDIC)   &ICK UP DICTIONARY REF 70560013
         L     GR3,ZDRFAB(0,GR11)      CONVERT TO ABSOLUTE              70600013
         BALR  GR14,GR3                                                 70640013
         L     GR3,PAR1(0,GRDIC)       POINT GR3 AT ENTRY               70680013
         SPACE                                                          70720013
CEFINX   MVI   0(GR6),X'00'            MOVE IN ZERO BYTE                70760013
         SPACE 2                                                        70800013
CEFIN    MVC   1(2,GR6),CECTST+2(GRDIC)     GO TO CONVERT IT TO DICT R  70840013
*                                      CEADD WHERE CECONV LEFT IT.      70880013
         LA    GR6,3(0,GR6)            BUMP OUTPUT TEXT POINTER BY 3    70920013
         BAL   GR14,CENDTS              GO TO END TEST                  70960013
CERENT   LM    GR14,GR5,SAVE3          RESTORE REGISTERS.               71000013
         L     GR7,ENDADR              SET GR7 TO END OF BCD            71040013
         BCR   CEBR,GR2                RETURN                           71080013
         SPACE 3                                                        71120013
*              NOW WE MUST FIND OUT EXACTLY WHERE IN THE HASH CHAIN     71160013
*              THE NEW ITEM IS TO FIT                                   71200013
         SPACE                                                          71240013
CEMSSS   XC    CADD1(4,GR12),CADD1(GR12)    CLEAR CADD1                 71280013
         L     GR3,ZHASH(0,GRDIC)      PICK UP START OF HASH TABLE      71320013
         AR    GR3,GR0                 ADD OFFSET FOR THIS VARIABLE     71360013
         S     GR3,CE3                 REDUCE BY 3                      71400013
CEILOP   LR    GR4,GR3                 AND SAVE THE ABSOLUTE ADDRESS    71440013
         CLC   3(2,GR3),CEZERO         IS THIS HASH CHAIN STOPPER       71480013
         BC    CEBE,CENTMK             YES, SO WE ADD ON NEW ENTRY      71520013
         MVC   PAR1+2(2,GRDIC),3(GR3)  CONVERT                          71560013
         MVC   CELSYM(2,GR12),3(GR3)   SAVE THE SYMBOLIC ADDRESS OF     71600013
*                                      NEXT ITEM IN THE HASH CHAIN      71640013
         L     GR3,ZDRFAB(0,GR11)      SET GR3 AT THIS ENTRY AFTER      71680013
         BALR  GR14,GR3                CONVERSION                       71720013
         L     GR3,PAR1(0,GRDIC)                                        71760013
         XR    GR2,GR2                 CLEAR GR2                        71800013
         IC    GR2,2(0,GR3)            SET UP GR2 WITH                  71840013
         IC    GR2,2(0,GR3)            SET UP GR2 WITH LENGTH TO BCD    71880013
         AR    GR2,GR3                 BYTE OR END OF ENTRY             71920013
         BCTR  GR2,0                   REDUCE POINTER TO COUNT BYTE     71960013
         CLC   0(1,GR2),CECURL         IS THIS THE SAME AS THE CURRENT  72000013
*                                      BLOCK COUNT                      72040013
         BC    CEBH,CEILOP             NO, IT IS HIGHER SO CONTINUE     72080013
*                                      DOWN THE CHAIN                   72120013
         SPACE                                                          72160013
*              INSERTION POINT HAS BEEN FOUND SO PUT ADDRESSES IN THE   72200013
*              COMMUNICATION TABLE IN BLOCK IEMFB.                      72240013
         SPACE                                                          72280013
CENTMK   ST    GR4,CADD2(0,GR12)       SAVE THE ABSOLUTE ADDRESS        72320013
         MVC   CACC(1,GR12),CECNTC     MOVE IN BLOCK COUNT              72360013
         MVC   CACL(1,GR12),CECNTB     MOVE IN BLOCK LEVEL              72400013
         BAL   GR2,CEPFDR              GO TO MAKE NEW ENTRY             72440013
         BC    CEBR,CEFIN1                                              72480013
         EJECT                                                          72520013
         SPACE 2                                                        72560013
*              PICK UP START OF TEXT ETC AND TRY SCAN AGAIN. IF HASH    72600013
*        CHAIN IS ZERO THEN WE HAVE FINISHED                            72640013
         SPACE                                                          72680013
CEPKUP   MVC   PAR1+2(2,GRDIC),CEFRSM  PICK UP DICTIONARY REFERENCE OF  72720013
         L     GR15,ZDRFAB(0,GR11)     ENTRY WITH BCD                   72760013
         BALR  GR14,GR15               CONVERT TO ABSOLUTE AND POINT    72800013
         L     GR3,PAR1(0,GRDIC)       GR2 AT IT                        72840013
CE22     CLC   3(2,GR3),CEZERO         IS HASH CHAIN ZERO               72880013
         BC    CEBE,CEC31X             YES, SO END SCAN                 72920013
         SPACE                                                          72960013
*              HASH CHAIN HAS ENTRY SO SET UP POINTERS ETC FOR NEXT TRY 73000013
         SPACE                                                          73040013
         MVC   CELSYM(2,GR12),3(GR3)   IN HASH CHAIN                    73080013
         MVC   PAR1+2(2,GRDIC),3(GR3)  PICK UP ADDRESS OF NEXT ENTRY    73120013
         L     GR15,ZDRFAB(0,GR11)     CONVERT TO ABSOLUTE              73160013
         BALR  GR14,GR15                                                73200013
         L     GR2,STKCNT              PICK UP STACK COUNT              73240013
         L     GR4,CEKSTA              PICK UP START OF STACK           73280013
         L     GR7,0(GR2,GR4)          AND POINT GR7 AT START OF TEXT   73320013
         XR    GR14,GR14               CLEAR GR14                       73360013
         IC    GR14,0(0,GR7)           PICK UP BCD LENGTH               73400013
         BCTR  GR14,0                  REDUCE BY ONE                    73440013
         MVI   CEFLOG,X'00'            CLEAR FLAGS AND TRY AGAIN        73480013
         BC    CEBR,CE3AX              GO TO COMPARE BCD ETC.           73520013
         EJECT                                                          73560013
*              ROUTINE FOR GENERATING ERROR MESSAGES                    76520013
         SPACE 2                                                        76560013
CERR4    MVI   CERRC,X'8F'             MOVE IN CODE BYTE                76600013
         BC    CEBR,CERR                                                76640013
         SPACE                                                          76680013
*              PUT OUT ERROR MESSAGE PUT DUMMY REFERENCE INTO STORE     76720013
         SPACE                                                          76760013
CERR3    MVI   CERRC,X'92'             MOVE IN ERROR CODE               76800013
         BC    CEBR,CERR                                                76840013
         SPACE                                                          76880013
CERR     L     GR7,TXTSTR              POINT GR7 AT START OF TEXT       76920013
         XR    GR4,GR4                 PICK UP BCD LENGTH               76960013
         IC    GR4,0(0,GR7)            IN GRX                           77000013
         LA    GR7,1(0,GR7)            GR7 POINTS AT START OF BCD IN    77040013
         ST    GR7,PAR7(0,GRDIC)       TEXT STORE FOR ERROR MESSAGES    77080013
         ST    GR4,PAR8(0,GRDIC)       STORE BCD LENGTH                 77120013
         MVC   PAR6+1(3,GRDIC),CERR1C  SET UP ERROR CODE                77160013
         L     GR15,ZERROF(0,GR11)     CALL ERROR MESSAGE               77200013
         BALR  GR14,GR15               GENERATOR                        77240013
         MVC   OLDSTR+2(2,GRDIC),CEDUMD+1   PUT DUMMY REF IN STORE      77280013
         BC    CEBR,CEFIN1             AND GO TO FINISH OFF             77320013
         SPACE 2                                                        77360013
CERR27   MVC   PAR6+1(3,GR3),CER27M    MOVE IN CODE BYEE                77400013
         L     GR15,ZERROF(0,GR11)      ALL UP ERROR ROUTINE            77440013
         BALR  GR14,GR15                                                77480013
         L     GR15,ZABORT(0,GR11)     CALL ZABORT                      77520013
         BALR  GR14,GR15                                                77560013
*********************************************************************** 77600013
         EJECT                                                          77640013
*                       ERROR MESSAGE CODE SKELETONS                    77680013
         SPACE                                                          77720013
CERR1C   DC    X'02'                                                    77760013
CERRC    DC    X'00'                                                    77800013
CERRX    DC    X'C4'                                                    77840013
CER27M   DC    X'02'                                                    77880013
         DC    X'8D'                                                    77920013
         DC    X'40'                                                    77960013
         EJECT                                                          78000013
         SPACE 2                                                        78040013
*                       CONSTANTS AND WORKSPACE                         78080013
         SPACE                                                          78120013
CECOMA   DC    X'4140'                                                  78160013
CEXLAG   DC    X'00'                                                    78200013
CELST    DC    X'00'                                                    78280013
CEONCD   EQU   4                       OFFSET IN SECOND BLOCK           78320013
CEBYTE   DC    X'00'              DUPLICATE CELL                        78360013
CECNTB   DC    X'00'                                                    78400013
CECNTC   DC    X'00'                                                    78440013
CECURL   DC    X'00'                                                    78480013
CELITM   DC    X'00'                                                    78520013
CESFIL   DC    X'00'                                                    78560013
CEHSF    DC    X'00'                                                    78600013
CELESN   DC    X'00'                                                    78640013
CEDUMD   DC    X'000015'                                                78680013
CENFLG   DC    X'00'                                                    78720013
CESW1    DC    X'00'                                                    78760013
CESW2    DC    X'00'                                                    78800013
CEWFLG   DC    X'00'                                                    78840013
CESTNO   DC    X'00'                                                    78880013
CELNGT   DC    X'00'                                                    78920013
DATDFL   DC    X'00'                                                    78960013
CEFRST   DC    H'0'                                                     79000013
CELONC  DC     X'06262513181129'              ONCHAR                    79040013
CELONS  DC     X'082625322634291315'      ONSOURCE                      79080013
CEPRIY   DC    X'082729192629193338'  PRIORITY                          79100015
CECONC  EQU    7                                                        79120013
CECONS  EQU    9                                                        79160013
CEECPF   EQU   6                                                        79200013
CETRTT   EQU   X'EF8'                                                   79240013
         SPACE 5                                                        79280013
CE3      DC    F'3'                                                     79360013
CE4      DC    F'4'                                                     79400013
CE5X     DC    F'5'                                                     79440013
CE32X    DC    F'32'                                                    79480013
CEENDB   DC    F'0'               DUPLICATE CELL                        79560013
OLDLVL   DC    X'0'                                                     79600013
CELVLX   DC    X'0'                                                     79640013
CEFRSM   DC    H'0'                                                     79680013
CESTSM   DC    H'0'                                                     79720013
OLDSYM   DC    H'0'                                                     79760013
CEFLAG   DC    F'0'                                                     79800013
CEFLOG   EQU   CEFLAG+1                                                 79840013
OLDSTR   EQU   CECTST                                                   79880013
OLDFLG   EQU   CEFLAG+2                                                 79920013
CEKSTA   DC    F'0'                                                     79960013
CESTKA   EQU   CEKSTA                                                   80000013
STKCNT   DC    F'0'                                                     80040013
TXTSTR   DC    F'0'                                                     80080013
ENDADR   DC    F'0'                                                     80120013
CEDMP1   DS    2F                                                       80160013
CEG14    DC    F'0'                                                     80200013
CEGR14   DC    F'0'                                                     80240013
CELENG   DC    F'0'                                                     80280013
CEPIT    DC    F'0'               DUPLICATE CELL                        80320013
CEPREV   DC    F'0'                                                     80360013
CESCLM   DC    F'0'                    SYMBOLIC ADR OF LAST TEXT BLOCK  80400013
CESCYM   DC    F'0'                    ** DUPLICATE CELL**              80440013
CESTNL   DC    F'0'                                                     80480013
         SPACE 2                                                        80520013
*                       OFFSETS IN BLOCK IEMFB                          80560013
         SPACE                                                          80600013
CESVE    DC    F'0'                                                     80640013
CEXXX    DC    F'0'                                                     80680013
CACL     EQU   2                       OFFSET OD L IN BLOCK2 BASE GR12  80720013
CACC     EQU   3                       OFFSET OF C IN BLOCK2 BASE GR12  80760013
CADD1    EQU   8                       OFFSET OF CADD1 IN BLOCK2        80800013
CADD2    EQU   12                      OFFSET OF CADD2 IN BLOCK2        80840013
CELSYM   EQU   CADD1+2                                                  80880013
         SPACE 2                                                        80920013
FBB      EQU   IEMFA+X'2010'         START OF TRANSFER VECTOR IN FB     80960013
CFPDER   EQU   FBB                                                      81000013
CFPDR2   EQU   FBB+4                                                    81040013
CECON    EQU   FBB+8                                                    81080013
CEPICT   EQU   FBB+12                                                   81120013
CHASH    EQU   FBB+16                                                   81121015
CECHK    EQU   FBB+20                                                   81122015
CELOCT   EQU   FBB+24                                                   81123015
CASPAC   EQU   IEMFA+X'2E70'                                            81126015
SAVE1    EQU   CASPAC+32                                                81132015
SAVE2    EQU   SAVE1+28                                                 81138015
SAVE3    EQU   SAVE2+8                                                  81144015
CESCXT   EQU   SAVE3+32                                                 81150015
CEBCT    EQU   IEMFA+X'2FF8'                                            81155015
CE256    DC    F'256'             DUPLICATE CELL                        81160013
         SPACE 3                                                        81200013
CEZERO   DC    F'0'                                                     81240013
CFW      DC    1F'0'                   REGISTERS ARE LOADED AND STORED  81280013
S1       DC    F'0'                                                     81320013
T11      DC    F'211'                                                   81360013
CELIST   DC    C'FA'                                                    81400013
CELST2   DC    C'FBZZ'                                                  81440013
CEPHNM   EQU   CELIST                                                   81480013
CERR1R   DC    X'028E40'                                                81520013
MIXFL    DC    X'00'                                                    81600015
         SPACE 2                                                        81680013
         ORG   IEMFA+4088                                               81720013
         SPACE 2                                                        81760013
*                       FIXED BRANCH LOCATIONS FOR REFERENCE FROM IEMFB 81800013
         SPACE                                                          81840013
CENDTX   BC    CEBR,CENDTS                                              81880013
CE31X    BC    CEBR,CE31                                                81920013
CEPFDR   EQU   CFPDER                                                   81960013
         END   IEMFA                                                    82000013
