FE       TITLE 'IEMFE BCD TO DICTIONARY REFERENCE, DICTIONARY PL/I F.'  00040013
IEMFE    START 0                                                        00080013
*                                                                       00100072
*                                                                       00103072
* 5.5  A 148800,411600,576000,780800                          MCB 57444 00106072
* 5.2  A 236980,258460,349600                                 MJG 32245 00109072
* 5.2  A 236650,236950,25800                                  MJG 31620 00112072
*                                                                       00115072
         USING *,9                                                      00120013
         DC    C'FE'                                                    00160013
         SPACE 5                                                        00200013
*        TITLE IEMFE    BCD TO DICTIONARY REFERENCE OF THE DICTIONARY   00240013
*              OS/360 PL/1 COMPILER(F)                                  00280013
         SPACE 3                                                        00320013
*              STATUS - CHANGE LEVEL O                                  00360013
         SPACE 3                                                        00400013
*              FUNCTION/OPERATION                                       00440013
*                       THIS PHASE MOVES THE TEXT FROM THE INPUT AREA   00480013
*              TO THE OUTPUT AREA REPLACING THE BCD IN THE INPUT TEXT   00520013
*              BY THE CORRESPONDING REFERENCE TO THE DICTIONARY ENTRY.  00560013
*              AT THE END OF THIS PHASE THE TEXT WILL CONSIST OF CODE   00600013
*              BYTES AND TWO BYTE DICTIONARY REFERENCES PRECEEDED BY A  00640013
*              ZERO BYTE.  THIS IS THE FORMAT AS REQUIRED BY THE TRANS- 00680013
*              LATION PHASES.                                           00720013
*                       SPECIAL ACTION IS TAKEN WHEN CERTAIN SPECIAL    00760013
*              KEYWORDS OR CODE BYTES ARE FOUND IN THE TEXT AS FOLLOWS  00800013
         SPACE                                                          00840013
*                       PROCEDURE - BLOCK LEVEL AND COUNT ARE PICKED UP 00880013
*              AND REMOVED FROM THE OUTPUT TEXT.                        00920013
*                       BEGIN     - AS FOR PROCEDURE                    00960013
*                       END       - MARKER IS PLACED IN THE OUTPUT TEXT 01000013
*              AFTER THE END CODE BYTE FOLLOWED BY A ZERO BYTE AND THE  01040013
*              BLOCK LEVEL AND COUNT OF THE CONTAINING BLOCK.           01080013
*                       SN        - STATEMENT NUMBER IS PICKED UP AND   01120013
*              THE FOLLOWING THREE BYTES PLACED IN THE OUTPUT TEXT      01160013
*                       SL        - AS FOR SN                           01200013
*                       SN2       - BLOCK LEVEL AND COUNT OF BLOCK FROM 01240013
*              WHICH THIS STATEMENT WAS MADE AND THEN TREAT AS FOR SN   01280013
*                       ON,SIGNAL,REVERT  - PLACE BLOCK LEVEL AND COUNT 01320013
*              IN THE OUTPUT TEXT BETWEEN THE ON (SIGNAL,REVERT) CODE   01360013
*              BYTE AND THE CONDITION BYTE                              01400013
*                       ITERATIVE DO      - BLOCK COUNT IS PICKED UP    01440013
*              AND REMOVED FROM THE OUTPUT TEXT. SET ASSIGN FLAG ON.    01480013
*                       EOP  -    IF THIS IS THE FIRST END OF PROGRAM   01520013
*              MARKER FOUND THEN POINTER TO THE START OF THE SECOND     01560013
*              FILE IS UPDATED IN THE COMMUNICATIONS REGION OF THE      01600013
*              DICTIONARY. IF THIS IS THE SECOND END OF PROGRAM MARKER  01640013
*              THEN THE END OF TEXT SLOT IN THE COMMUNICATIONS REGION   01680013
*              IS UPDATED, ANY SCRATCH CORE GOT BY THIS PHASE IS RELEAS 01720013
*              -ED, PHASES IEMGK, IEMGP, IEMGQ, IEMGR  ARE MARKED WANT- 01760013
*              ED OR UNWANTED DEPENDING ON THE PRESCENCE OF AN ARGUE-   01800013
*              MENT LIST IN THE PROGRAM OR NOT,  THE INCLUDE CARD DICT- 01840013
*              IONARY ENTRY IS MADE AND CONTROL IS RETURNED TO COMPILER 01880013
*              CONTROL.                                                 01920013
*                       EOB  -    THE NEXT TEXT BLOCK IN THE CHAIN OF   01960013
*              INPUT TEXT BLOCKS IS GOT AND THE CURRENT ONE FREED.      02000013
*                       LEFT PARENTHESIS  - IF THE PREVIOUS ITEM IN THE 02040013
*              TEXT WAS A DICTIONARY REFERENCE TO AN ARRAY THEN A       02080013
*              SUBSCRIPT MARKER IS PLACED IN THE OUTPUT TEXT BEFORE THE 02120013
*              PARENTHESIS. IF THE PREVIOUS DICTIONARY REFERENCE WAS A  02160013
*              FUNCTION THEN THE VALID OF ITS POSITION IS CHECKED AND   02200013
*              A FUNCTION MARKER OR PSEUDO-VARIABLE MARKER PLACED IN    02240013
*              THE OUTPUT TEXT, THE PARENTHESIS COUNT IS BUMPED.        02280013
*                       ASSIGNMENT  -  SET ASSIGN FLAG ON               02320013
*                       ASSIGNMENT =   SET ASSIGN FLAG OFF              02360013
*                       DO =           SET ASSIGN FLAG OFF              02400013
*                       ZERO BYTE   -  MOVE IT AN NEXT TWO BYTES TO THE 02440013
*              OUTPUT TEXT AREA                                         02480013
*                       SEMI-COLON  -  SET FLAGS OFF AND CLEAR BRACKET  02520013
*              COUNTS.                                                  02560013
         SPACE                                                          02600013
*                       WHEN AN IDENTIFIER IS FOUND IT IS HASHED AND    02640013
*              IF THE CORRESPONDING SLOT IN THE HASH TABLE IS EMPTY     02680013
*              THEN A CALL IS MADE TO BLOCK IEMFF TO MAKE A NEW DICTION 02720013
*              -ARY ENTRY. IF THE SLOT IS NOT EMPTY THEN THE HASH CHAIN 02760013
*              IS SCANNED TO SEE IF BCD AGREEMENT CAN BE FOUND IN ANY   02800013
*              MEMBER IN THE CHAIN. IF NONE, THEN A NEW ENTRY IS MADE.  02840013
*              IF AGREEMENT IS FOUND THEN A CHECK IS MADE TO SEE IF     02880013
*              THIS ENTRY IS IN THE SAME BLOCK AS IS BEING CURRENTLY    02920013
*              PROCESSED OR IF IT IS KNOWN. IF SO THEN THE SEARCH IS    02960013
*              OVER AND WE HAVE OUR DICTIONARY REFERENCE. IF NOT THEN   03000013
*              WE MUST MAKE A NEW ENTRY AND USE ITS REFERENCE.          03040013
*                       HOWEVER, IF WE ARE MAKING A SCAN FOR A QUALIF-  03080013
*              IED NAME THEN WE CAN NOT MAKE A NEW ENTRY AND WHEN WE    03120013
*              HAVE FOUND A VALID ENTRY FOR THE FIRST PART OF THE       03160013
*              QUALIFIED NAME THEN ITS STRUCTURE MUST BE SCANNED TO     03200013
*              MAKE SURE THAT THE REST OF THE NAME OCCURS IN THIS       03240013
*              STRUCTURE. IF NO AGREEMENT IS FOUND THEN THE SEARCH MUST 03280013
*              BE RENEWED.                                              03320013
*                       IF TOTAL AGREEMENT IS FOUND IT IS POSSIBLE THAT 03360013
*              IT IS FOR A FORMAL PARAMETER ENTRY. IF SO, THEN THE      03400013
*              REFERENCE USED MUST BE FOR THE DETAILED ENTRY, WHICH MAY 03440013
*              HAVE TO BE MADE.                                         03480013
         SPACE 3                                                        03520013
*              ENTRY POINTS                                             03560013
*                       IEMFE- ENTRY FROM COMPILER CONTROL. LOCATION OF 03600013
*              INPUT TEXT AREA IS OBTAINED AND NEW OUTPUT TEXT BLOCK IS 03640013
*              GOT AND THE SLOT FOR TEXT START IN THE COMMUNICATIONS    03680013
*              REGION OF THE DICTIONARY IS UPDATED. 512 BYTES OF SCRAT- 03720013
*              CH CORE IS OBTAINED AND BLOCK IEMFF  IS LOADED AND SCAN- 03760013
*              NING COMMENCES                                           03800013
         SPACE 3                                                        03840013
*              INPUT                                                    03880013
*                       TEXT BLOCKS IN CORE STORAGE                     03920013
         SPACE 3                                                        03960013
*              OUTPUT                                                   04000013
*                       TEXT BLOCKS IN CORE STORAGE                     04040013
         SPACE 3                                                        04080013
*              EXTERNAL ROUTINES                                        04120013
*                       ZTXTRF -  COMPILER CONTROL ROUTINE TO CONVERT   04160013
*              AN ABSOLUTE  ADDRESS TO A SYMBOLIC TEXT REFERENCE.       04200013
*                       ZDICRF -  COMPILER CONTROL ROUTINE TO MAKE A    04240013
*              DICTIONARY ENTRY AND RETURN ITS DICTIONARY REFERENCE.    04280013
*                       ZDRFAB  -  COMPILER CONTROL ROUTINE TO CONVERT  04320013
*        DICTIONARY REFERENCES TO ABSOLUTE ADDRESSES.                   04360013
*                       ZDABRF  -  COMPILER CONTROL ROUTINE TO CONVERT  04400013
*        ABSOLUTE ADDRESS TO DICTIONARY REFERENCE.                      04440013
*                       ZTXTAB  -  COMPILER CONTROL ROUTINE TO CONVERT  04480013
*        SYMBOLIC TEXT ADDRESS TO ABSOLUTE ADDRESS.                     04520013
*                       ZUTXTC  -  COMPILER CONTROL ROUTINE TO OBTAIN   04560013
*        NEW TEXT BLOCK.                                                04600013
*                       LOADW   -  COMPILER CONTROL ROUTINE TO LOAD     04640013
*        NEW PHASE AND WAIT TILL LOADING IS FINISHED                    04680013
*                       ZUERR   -  COMPILER CONTROL ROUTINE TO PUT      04720013
*        ERROR MESSAGE IN DICTIONARY. (ALSO KNOWN AS ZERROF)            04760013
*                       ZABORT  -  COMPILER CONTROL ROUTINE TO INTER-   04800013
*        RUPT                                                           04840013
*                       ZALTER  -  COMPILER CONTROL ROUTINE TO CHANGE   04880013
*        STATUS OF TEXT BLOCK.                                          04920013
*                       RLSCTL  - COMPILER CONTROL ROUTINE TO PASS      04960013
*        CONTROL TO ANOTHER PHASE                                       05000013
*                       ZUGC  -   COMPILER CONTROL ROUTINE TO GET       05040013
*              SCRATCH CORE                                             05080013
*                       ZURC  -   COMPILER CONTROL ROUTINE TO RELEASE   05120013
*              SCRATCH CORE.                                            05160013
*                       REQEST  - COMPILER CONTROL ROUTINE TO MARK      05200013
*              LATER PHASES AS WANTED OR UNWANTED                       05240013
*                       CEDICN  - ROUTINE TO MAKE DICTIONARY ENTRY FOR  05280013
*              NORMAL VARIABLE (CALLED AS CFPDER) LOCATED IN IEMFF      05320013
*                       CEENT2  - ROUTINE TO MAKE DICTIONARY ENTRY FOR  05360013
*              FORMAL PARAMETERS                                        05400013
         SPACE 3                                                        05440013
*              EXIT- NORMAL                                             05480013
*                       VIA COMPILER CONTROL ROUTINE RLSCTL             05520013
         SPACE 3                                                        05560013
*              EXIT- ABNORMAL                                           05600013
*                       VIA COMPILER CONTROL ROUTINES ZUERR AND ZABORT  05640013
*              ON A TERMINAL ERROR.                                     05680013
         SPACE 3                                                        05720013
*              WORK AREA                                                05760013
*                       THIS ROUTINE USES 512 BYTES OF SCRATCH FOR A    05800013
*              STACK OF FUNCTION REFERENCES AND TWO OTHER AREAS OF      05840013
*              SCRATCH CORE FOR THE STACK OF BLOCK LEVEL NUMBERS AND    05880013
*              HASH TABLE. THESE AREAS WERE OBTAINED BY PHASE IEMEG AND 05920013
*              NOT RELEASED. THE 512 BYTE BLOCK OBTAINED BY THIS PHASE  05960013
*              IS RELEASED AT THE END OF THE PHASE                      06000013
         SPACE 3                                                        06040013
*              ATTRIBUTES                                               06080013
*                       NOT REUSEABLE                                   06120013
         SPACE 3                                                        06160013
*              NOTES                                                    06200013
*                       THIS PHASE IS INDEPENDENT OF CHANGES TO EXTER-  06240013
*              NAL GRAPHICS PROVIDED THAT INTERNAL CODES REMAIN UNALTER 06280013
*              -ED                                                      06320013
*                       COMMUNICATIONS TABLE IN IEMFF AND ENTRY POINTS  06360013
*              ARE AT FIXED OFFSETS FROM THE START OF THAT BLOCK        06400013
*                            GR7- POINTER TO INPUT TEXT                 06440013
*                            GR6- POINTER TO OUTPUT TEXT                06480013
*                            GR9- BASE REGISTER FOR PHASE IEMFA         06520013
*                            GR11 - BASE REGISTER FOR COMPILER CONTROL  06560013
*                            GR12 - BASE REGISTER FOR PHASE IEMFB       06600013
*                            GR13 - BASE REGISTER OF FIRST DICTIONARY   06640013
*                                   BLOCK                               06680013
*                            GR15 - UNIT REGISTER                       06720013
*                            ALL OTHER REGISTERS ARE SCRATCH.           06760013
        EJECT                                                           06800013
*                       EQUIVALENCES FOR OFFSETS  FROM THE START OF     06840013
*                       VARIOUS DICTIONARY ENTRIES                      06880013
         SPACE 2                                                        06920013
CLBLCL   EQU   15       OFFSET OF C IN A LABEL VARIABLE                 06960013
CEOTH1   EQU   10       OFFSET OF OTHER1 CODE BYTE                      07000013
CEVRBT   EQU   11       OFFSET OF VARIABLE CODE BYTE                    07040013
CEOTH2   EQU   12       OFFSET OF OTHER2 CODE BYTE                      07080013
CEOTH3   EQU   13       OFFSET OF OTHER3 CODE BYTE                      07120013
CEOTH4   EQU   14       OFFSET OF OTHER4 CODE BYTE                      07160013
CETOCB   EQU   15                      OFFSET TO END OF 4 CODE BYTES    07200013
CENWAD   EQU   5        OFFSET OF FULL ENTRY'S ADDRESS IN FP ENTRY      07240013
CLVVAR   EQU   12       OFFSET OF VARIABLE BYTE IN LABEL VARIABLE       07280013
CLCLT    EQU   18       OFFSET OF C IN LABEL CONSTANT                   07320013
CFPADR   EQU   CENWAD                                                   07360013
CEFPFA   EQU   CENWAD                                                   07400013
CFPEL    EQU   7        OFFSET OF L IN FP ENTRY                         07440013
CFPEC    EQU   8        OFFSET OF C IN FP ENTRY                         07480013
CYTOP    EQU   11                      OFFSET OF LENGTH BYTE IN PICTURE 07520013
CYWHOL   EQU   13                      OFFSET OF PICTURE IN PICT ENTRY  07560013
CEDAPL   EQU   6                       NUMBER OF EXTRA BYTES IN A DATA  07600013
*                                      ENTRY OVER A STRUCTURE ENTRY     07640013
CESNLN   EQU   3                       LENGTH OF DATA AFTER SN          07680013
CESNSN   EQU   8                       OFFSET OF ST NO. IN LABEL CONST  07720013
CESN2C   EQU   11                      OFFSET OF C IN SN2 ENTRY         07760013
CESN2L   EQU   10                      OFFSET OF L IN SN2 ENTRY         07800013
CTOBCD   EQU   15                      OFFSET OF BCD IN CONSTANT ENTRY  07840013
CEDBCN   EQU   5                       OFFSET OF DATA BYTE IN CONSTANT  07880013
CEOFSL   EQU   4                       LENGTH OF OFFSET SLOT IN VAR-    07920013
*                                      IABLE INFORMATION                07960013
CETOVI   EQU   15                      LENGTH OF OFFSET TO VARIABLE     08000013
*                                      INFORMATION IN A STRUCTURE ENTRY 08040013
CETRST   EQU   1                       OFFSET OF TRUE LEVEL NUMBER      08080013
*                                      FROM START OF STRUCTURE VARIABLE 08120013
*                                      INFORMATION                      08160013
CENSAD   EQU   4                       OFFSET OF ADDRESS OF NEXT STRUCT 08200013
*                                      -URE IN CHAIN FROM START OF      08240013
*                                      STRUCTURE VARIABLE INFORMATION   08280013
CETOTL   EQU   CETOVI+CEOFSL+CETRST    OFFSET OF TRUE LEVEL NUMBER FROM 08320013
*                                      START OF STRUCTURE ENTRY         08360013
CETONS   EQU   CETOVI+CEOFSL+CENSAD    OFFSET OF NEXT STRUCTURE ADDRESS 08400013
*                                      FROM START OF STRUCTURE ENTRY    08440013
CEBIF1   EQU   8                       OFFSET OF 1ST CODE BYTE IN       08450001
*                                    BUILT IN FUNCTION ENTRY            08460001
CEBIF2   EQU   9                       OFFSET OF 2ND CODE BYTE IN       08480013
*                                      BUILT-IN FUNCTION ENTRY          08520013
NONCON   EQU   X'01'                   NON CONTINUOUS FLAG              08560013
NONQUL   EQU   X'01'                   NON QUALIFIED FLAG               08600013
MINSTR   EQU   X'10'                   MINOR STRUCTURE FLAG             08640013
NONMIN   EQU   X'11'                   NONCON AND MINSTR FLAGS          08680013
CEFPCB   EQU   X'40'                   FORMAL PARAMETER ENTRY INITIAL   08720013
*                                      CODE BYTE                        08760013
MAXBCD   EQU   X'1F'                   MAXIMUM BCD LENGTH               08800013
AMBFLG   EQU   X'02'                   AMBIGUOUS FLAG                   08840013
NOAMBG   EQU   X'FD'                   TURN OFF AMBFLAG MASK            08880013
CENOBC   EQU   X'80'                   NO BCD BIT IN INITIAL BYTE       08920013
CEBEPL   EQU   6                       ADDITIONAL BYTES IN BASE OVER    08960013
*                                      STRUCTURE ENTRY                  09000013
CEBASE   EQU   X'2F'                   INITIAL BYTE FOR BASE ELEMENT    09040013
CEDIMZ   EQU   3                       DIMENSION INFORMATION SIZE       09080013
CEVARN   EQU   19                      DISTANCE TO VARIABLE INFORMATION 09120013
*                                      IN STRUCTURE ENTRY               09160013
CECNSR   EQU   2                       OFFSET OF CONTAINING STRUCTURE   09200013
*                                      ADDRESS FROM START OF STRUCTURE  09240013
*                                      INFORMATION                      09280013
CEDIMS   EQU   X'10'                   DIMENSION BIT IN INITIAL CODE    09320013
*                                      BYTE                             09360013
CESTRC   EQU   X'20'                   STRUCTURE BIT IN INITIAL BYTE    09400013
OPTBT    EQU   X'2A'              OPTIONS BYTE FOR ENTRY TYPE 1   H441  09420020
CEFPCH   EQU   3                       OFFSET OF FP POINTER IN DATA     09440013
*                                      ENTRY                            09480013
         SPACE 2                                                        09520013
*                       OFFSET OF VARIOUS CODE BITS IN CODE BYTES       09560013
         SPACE 2                                                        09600013
CESYM    EQU   X'80'    SYMBOL BIT IN OTHER 1 BYTE                      09640013
CESVD    EQU   X'10'    SAVED  BIT IN OTHER 2 BYTE                      09680013
CECNTL   EQU   X'03'    CONTROLLED CODE IN OTHER 2  BYTE                09720013
CEDMBT   EQU   X'40'    DIMENSION BIT IN VARIABLE BYTE                  09760013
CEAMBT   EQU   X'80'                   AMBIGUOUS BIT IN OTHER 4 BYTE    09800013
CENDSR   EQU   X'08'                   END OF STRUCTURE BIT IN OTHER 2  09840013
CEOFBT   EQU   X'80'    OFFSET SLOT BIT IN VARIABLE BYTE                09880013
         SPACE 2                                                        09920013
*                            EQUIVALENCES FOR BRANCH CODES              09960013
         SPACE 2                                                        10000013
CENOP    EQU   0                                                        10040013
CEBO     EQU   1                                                        10080013
CEBP     EQU   2                                                        10120013
CEBH     EQU   2                                                        10160013
CEBM     EQU   4                                                        10200013
CEBL     EQU   4                                                        10240013
CEBNE    EQU   7                                                        10280013
CEBNZ    EQU   7                                                        10320013
CEBZ     EQU   8                                                        10360013
CEBE     EQU   8                                                        10400013
CEBNL    EQU   11                                                       10440013
CEBNH    EQU   13                                                       10480013
CEBNO    EQU   14                                                       10520013
CEBR     EQU   15                                                       10560013
BNE      EQU   CEBNE                                                    10600013
BE       EQU   CEBE                                                     10640013
B        EQU   CEBR                                                     10680013
BZ       EQU   CEBZ                                                     10720013
BNZ      EQU   CEBNZ                                                    10760013
*                            EQUIVALENCES FOR REGISTERS                 10800013
         SPACE                                                          10840013
GR0      EQU   0                                                        10880013
GR1      EQU   1                                                        10920013
GR2      EQU   2                                                        10960013
GR3      EQU   3                                                        11000013
GR4      EQU   4                                                        11040013
GR5      EQU   5                                                        11080013
GR6      EQU   6                                                        11120013
GR7      EQU   7                                                        11160013
GR8      EQU   8                                                        11200013
GR9      EQU   9                                                        11240013
GR10     EQU   10                                                       11280013
GR11     EQU   11                                                       11320013
GR12     EQU   12                                                       11360013
GR13     EQU   13                                                       11400013
GR14     EQU   14                                                       11440013
GR15     EQU   15                                                       11480013
*              ************            *************                    11520013
GRY      EQU   GR0                                                      11560013
GRW      EQU   GR1                                                      11600013
GRX      EQU   GR3                                                      11640013
GRR      EQU   GR4                                                      11680013
GRSP     EQU   GR7                                                      11720013
GRLR     EQU   10                                                       11760013
GRCC     EQU   GR11                                                     11800013
GRDIC    EQU   GR13                                                     11840013
GRRR     EQU   14                                                       11880013
GRUNIT   EQU   GR15                                                     11920013
GRRZ     EQU   GR15                                                     11960013
*                       EQU CARDS FOR CHASH                             12000013
GRHASH   EQU   0                                                        12040013
GRLTH    EQU   1                                                        12080013
GRP      EQU   2                                                        12120013
GRQ      EQU   3                                                        12160013
GRZ      EQU   4                                                        12200013
GRPTR    EQU   5                                                        12240013
*                       EQUIVALENCES FOR CODE BYTES AT START OF DICT    12280013
*                       ENTRY                                           12320013
         SPACE                                                          12360013
CBLTGN   EQU   X'06'                   BUILT-IN GENERIC FUNCT CODE BYTE 12400013
CENTP5   EQU   X'83'                   ENTRY TYPE 5                     12440013
CEGNEL   EQU   X'42'                   GENERIC ENTRY LABEL              12480013
CSTLBL   EQU   X'00'                   STATEMENT LABEL CONST CODE BYTE  12520013
CFILE    EQU   X'09'                   FILE CODE BYTE                   12560013
CVARBL   EQU   X'0F'                   VARIABLE ITEM CODE BYTE          12600013
CFMPAR   EQU   X'40'                   FORMAL PARAMETER CODE BYTE       12640013
CEFLPR   EQU   X'89'                   FILE FORMAL PARAMETER CODE BYTE  12680013
CESTRD   EQU   X'20'                                                    12720013
CELVAR   EQU   X'07'                   LABEL VARIABLE CODE BYTE         12760013
CEXETP   EQU   X'03'                   EXTERNAL ENTRY LABEL             12800013
CECNTX   EQU   X'88'                   INITAL CODE BYTE FOR CONSTANT    12840013
CVRSTR   EQU   1                                                        12880013
CEVLAR   EQU   37                      CODE FOR ANY TYPE OF LABEL VARIA 12920013
         SPACE                                                          12960013
*                       EQUIVALENCES FOR  COMPILER CONTROL OFFSETS      13000013
         SPACE                                                          13040013
ZUGC     EQU   X'10'                                                    13080013
ZUGCOF   EQU   ZUGC                                                     13120013
ZUTXTC   EQU   X'14'                                                    13160013
ZURC     EQU   X'18'                                                    13200013
ZUPGMC   EQU   X'1C'                                                    13240013
ZABORT   EQU   X'20'                                                    13280013
ZLOADW   EQU   X'24'                                                    13320013
LOADW    EQU   ZLOADW                                                   13360013
ZDICAB   EQU   X'28'                                                    13400013
ZDICRF   EQU   X'2C'                                                    13440013
ZUERR    EQU   X'30'                                                    13480013
ZDRFAB   EQU   X'34'                                                    13520013
ZDUMP    EQU   X'38'                                                    13560013
REQEST   EQU   X'40'                                                    13600013
RELESE   EQU   X'44'                                                    13640013
RLSCTL   EQU   X'48'                                                    13680013
ZDRFOF   EQU   ZDICRF                                                   13720013
ZDRAOF   EQU   ZDRFAB                                                   13760013
ZURCOF   EQU   ZURC                                                     13800013
ZERROF   EQU   ZUERR                                                    13840013
ZDABOF   EQU   ZDICAB                                                   13880013
ZTXTRF   EQU   80                                                       13920013
ZTXTAB   EQU   84                                                       13960013
ZCHAIN   EQU   88                                                       14000013
ZALTER   EQU   92                                                       14040013
*                                                                       14080013
         SPACE                                                          14120013
*                       SET UP COMMUNICATIONS OFFSETS                   14160013
         SPACE                                                          14200013
ZNXTD    EQU   76                                                       14240013
ZMYNAM   EQU   112                                                      14280013
ZCOMM    EQU   304                                                      14320013
ZHASH    EQU   ZCOMM+28                                                 14360013
ZSTAT    EQU   124                                                      14400013
PAR1     EQU   128                                                      14440013
PAR2     EQU   132                                                      14480013
PAR3     EQU   136                                                      14520013
PAR4     EQU   140                                                      14560013
PAR5     EQU   144                                                      14600013
PAR6     EQU   148                                                      14640013
PAR7     EQU   152                                                      14680013
PAR8     EQU   156                                                      14720013
ZOPT     EQU   196                     OPTIONS BYTE                     14740019
ZTXTST   EQU   256                                                      14760013
ZDTBSZ   EQU   260                                                      14800013
ZTXBSZ   EQU   264                                                      14840013
ZRABSZ   EQU   268                                                      14880013
ZLOCK    EQU   274                                                57444 14900072
ZLSTXT   EQU   276                                                      14920013
ZALLOC   EQU   ZCOMM+12                                                 14960013
ZDEFLG   EQU   ZCOMM+16                                                 15000013
ZDEFFL   EQU   ZCOMM+16                                                 15040013
ZALCFL   EQU   ZCOMM+17                                                 15080013
ZARGFL   EQU   ZCOMM+18                                                 15120013
ZFLAG4   EQU   ZCOMM+19                                                 15140015
ZFATTB   EQU   ZCOMM+38                                                 15160013
ZMPSTK   EQU   ZCOMM+56                                                 15200013
ZCDSTK   EQU   ZMPSTK                                                   15240013
Z2FILE   EQU   ZCOMM+44                                                 15280013
CECTST   EQU   ZCOMM+88                                                 15320013
CEKYST   EQU   ZCOMM+92                                                 15360013
CE2LM    EQU   ZCOMM+93                                                 15400013
CEFFLG   EQU   ZCOMM+95                                                 15440013
CETSYM   EQU   ZCOMM+96                                                 15480013
ZUPIC    EQU   ZCOMM+60                                                 15520013
ZPROC1   EQU   ZCOMM+64                START OF ENTRY TYPE 1 CHN  H441  15540020
         SPACE                                                          15560013
*                       EQUIVALENCES FOR CODE BYTES (INTERNAL REPRESEN- 15600013
*                       TATION)                                         15640013
         SPACE                                                          15680013
CEDATA   EQU   X'14'                   DATA ITEM                        15720013
CEFTLS   EQU   X'1F'                   FORMAT LIST                      15760013
CEIDNT   EQU   X'1F'                   MAXIMUM IDENTIFIER LENGTH        15800013
CEUPAR   EQU   X'3C'                   UPWARD ARROW                     15840013
CEANCH   EQU   X'3A'                   ANCHOR SIGN                      15880013
CEDWAR   EQU   X'3E'                   DOWNWARD ARROW                   15920013
CEBLNK   EQU   X'40'                   BLANK                            15960013
CECOMA   EQU   X'41'                   COMMA                            16000013
CELPAR   EQU   X'43'                   LEFT PARENTHESIS                 16040013
CERPAR   EQU   X'45'                   RIGHT PARENTHESIS                16080013
CEFSTP   EQU   X'46'                   FULL STOP                        16120013
CEASEQ   EQU   X'47'                   LEFT ARROW OR ASSIGNMENT =       16160013
CELAR    EQU   CEASEQ                                                   16200013
CEUMB    EQU   X'5E'                   UMBRELLA                         16240013
CEDWAD   EQU   X'7E'                   DOWNWARD ARROW DASHED            16280013
CEALOC   EQU   X'81'                   ALLOCATE                         16320013
CEWAIT   EQU   X'89'                   WAIT                             16360013
CEDSP    EQU   X'95'                   DISPLAY                          16400013
CESGNL   EQU   X'97'                   SIGNAL                           16440013
CERVRT   EQU   X'99'                   REVERT                           16480013
CEASGN   EQU   X'9F'                   ASSIGN                           16520013
CECALL   EQU   X'A1'                   CALL                             16560013
CEP      EQU   X'A4'                   P FORMAT                         16600013
CEGOTO   EQU   X'A7'                   GO TO                            16640013
CEIMPL   EQU   X'A9'                   IMPLICIT                         16680013
CEDECL   EQU   X'AD'                   DECLARE                          16720013
CENTRY   EQU   X'B1'                   ENTRY                            16760013
CEPROC   EQU   X'B3'                   PROCEDURE                        16800013
CEBEGN   EQU   X'B5'                   BEGIN                            16840013
CEITDO   EQU   X'B7'                   ITERATIVE DO                     16880013
CEDO     EQU   X'B9'                   DO                               16920013
CESND    EQU   X'BC'                   SN DASHED OR SN2                 16960013
CEFRMT   EQU   X'BF'                 FORMAT                             17000013
CEDSC    EQU   X'C6'                   DSC MARKER                       17040013
CE2LVL   EQU   X'C8'                   SECOND LEVEL MARKER              17080013
CESN     EQU   X'D0'                   SN                               17120013
CESL     EQU   X'D2'                   S1                               17160013
CECN     EQU   X'D4'                   CN                               17200013
CECL     EQU   X'D6'                   CL                               17240013
CEFONC   EQU   X'E0'                                                    17280013
CENDDO   EQU   X'E7'                   END DO                           17320013
CEEND    EQU   X'E9'                   END                              17360013
CEEOP    EQU   X'EB'                   END OF PROGRAM                   17400013
CEEOB    EQU   X'ED'                   END OF BUFFER                    17440013
CESCLN   EQU   X'EF'                   SEMI-COLON                       17480013
CECONX   EQU   X'F0'                   CONSTANT                         17520013
CEON     EQU   X'FB'                   ON                               17560013
CESUB    EQU   X'FE'                   SUB                              17600013
CEASTR   EQU   X'FC'                   ASTERISK(SPARE-TYRE)             17640013
CESTR    EQU   CEASTR                                                   17680013
STRING   EQU   X'15'                                                    17720013
KEYTO    EQU   X'1A'                                                    17760013
KEYFRM   EQU   X'1E'                                                    17800013
IDENT    EQU   X'07'                                                    17840013
REPLY    EQU   X'25'                                                    17880013
CESBYT   EQU   X'26'                   STRING INDICATOR IN              17890001
*                                    BUILT IN FUNCTION DICT ENTRY       17900001
         EJECT                                                          17920013
*                       LOAD NEXT PHASE, PICK UP START OF INPUT TEXT    17960013
*                       FROM COMMUNICATION REGION, GET NEW TEXT BLOCK   18000013
*                       FOR OUTPUT AND UPDATE POINTERS IN COMMUNICATION 18040013
*                       REGION.                                         18080013
         SPACE                                                          18120013
         L     GR9,PAR1(GRDIC)                                          18160013
         LA    GR1,CELST2              POINT                            18200013
         ST    GR1,PAR1(0,GRDIC)       TO PHASE LIST                    18240013
         L     GR1,LOADW(0,GR11)       AND LOAD SECOND HALF OF THIS     18280013
         BALR  GR14,GR1                PHASE                            18320013
         L     GR12,PAR1(0,GRDIC)      LOAD GR12 WITH ITS START ADDRESS 18360013
         MVC   CETSYM(3,GRDIC),ZTXTST+1(GRDIC)   FILL TEXT SYM ADDR     18400013
*********************************************************************** 18440013
         L     GR7,ZTXTST(0,GRDIC)     PICK UP SYMBOLIC ADDR OF START   18480013
         ST    GR7,PAR1(0,GRDIC)       OF TEXT                          18520013
         L     GR7,ZTXTAB(0,GR11)      CONVERT                          18560013
         BALR  GR14,GR7                TO ABSOLUTE                      18600013
         L     GR7,PAR1(0,GRDIC)       AND POINT GR7 AT IT              18640013
         XC    PAR1(4,GRDIC),PAR1(GRDIC)    CLEAR PAR1                  18680013
         MVI   PAR2+3(GRDIC),X'00'     SET UP PARAMETER TO GET NEW BLK  18720013
         L     GR6,ZUTXTC(0,GR11)      NEW BLOCK FOR                    18760013
         BALR  GR14,GR6                                                 18800013
         MVC   CESCYM(3),PAR1+1(GRDIC) SET UP SYMBOLIC ADDRESS SLOT     18840013
         MVC   ZTXTST(4,GRDIC),PAR1(GRDIC)  SAVE NEW START OF TEXT      18880013
         L     GR6,PAR2(0,GRDIC)       AND POINT GR6 AT IT              18920013
*********************************************************************** 18960013
         LR    GR5,GR6                 CALCULATE                        19000013
         A     GR5,ZTXBSZ(0,GRDIC)     END LOCATION                     19040013
         S     GR5,CE4                 OF BLOCK                         19080013
         ST    GR5,CEENDB              AND STORE                        19120013
         EJECT                                                          19160013
*        INITIALISATION SECTION                                         19200013
*                       UPDATE ZMYNAME SLOT IN COMMUNICATIONS REGION    19240013
*                       AND SET UP UNIT REGISTER.                       19280013
*                       GET 512 BYTES OF SCRATCH CORE                   19320013
         SPACE                                                          19360013
         MVC   ZMYNAM(2,GRDIC),CEPHNM  MOVE IN PHASE NAME               19400013
         MVC   PAR1(3,GRDIC),CEZERO    CLEAR PAR1                       19440013
         MVI   PAR1+3(GRDIC),X'03'     MOVE IN PARAMETER TO GET 1.5K OF 19480013
*                                      SCRATCH CORE FOR 3 STACKS        19520013
         L     GR1,ZUGCOF(0,GR11)      CALL UP COMPILER CONTROL         19560013
         BALR  GR14,GR1                FOR 512 BYTES OF SCRATCH CORE    19600013
*********************************************************************** 19640013
         MVC   CEDSTA+1(3),PAR1+1(GRDIC)    AND STORE ADDRESS OF START  19680013
         LA    GR15,1(0,0)             SET UP UNIT REGISTER             19720013
         ST    GR15,CECRCT             SET SCRATCH CORE COUNT TO ONE    19760013
         L     GR5,CEDSTA                                               19800013
         SPACE 2                                                        19840013
CEG21    LA    GR5,256(0,GR5)          BUMP ADDRESS BY 256 TO GIVE      19880013
         ST    GR5,CELVLS              START OF BLOCK LEVEL STACK       19920013
         LA    GR5,256(0,GR5)          START OF TEXT STACK              19960013
         ST    GR5,CEKSTA              STORE START ADDRESS              20000013
         BC    CEBR,CE300                                               20040013
*                                      BLOCK                            20080013
         EJECT                                                          20120013
*                       THIS IS WHERE WE GO OFF TO THE ROUTINE FOR      20160013
*                       THE TYPE OF BYTE MARKER FOUND                   20200013
         SPACE                                                          20240013
CE30     AR    GR7,GR15                BUMP SCAN POINTER                20280013
CE300    ST    GR7,CEPREV              SAVE VALUE OF GR7                20320013
         MVC   CEBYTE(1),0(GR7)        MOVE BYTE TO BE TESTED           20360013
         MVC   CELITM(1),CELST         MOVE LAST ITEM PICKED UP         20400013
         MVC   CELST(1),CEBYTE         STORE THIS ITEM JUST FOUND       20440013
         TR    CEBYTE(1),CETRAN        TRANSLATE BYTE TO AN OFFSET      20480013
         XR    GR1,GR1                 CLEAR GR1                        20520013
         IC    GR1,CEBYTE              AND STORE OFFSET IN IT           20560013
         EX    0,CETRTB(GR1)           EXECUTE BRANCH INSTRUCTION       20600013
         EJECT                                                          20640013
*                       THIS IS TO HANDLE FINDING OF AN IDENTIFIER      20680013
         SPACE                                                          20720013
CEID     BAL   GR2,CESCAN              GO TO SCAN DICT ROUTINE          20760013
         BC    CEBR,CE30                                                20800013
         SPACE 2                                                        20840013
*                       THIS IS TRANSFER POINT FOR A KEYWORD            20880013
         SPACE                                                          20920013
CEKEY    MVC   0(1,GR6),0(GR7)         MOVE KEYWORD TO TEXT             20960013
         MVC   CEKYST(1,GRDIC),0(GR7)  STORE KEYWORD                    21000013
         SPACE 1                                                        21006001
         MVI GOPSW,X'0F'               SET 'GET OR PUT' SWITCH TO       21012001
*                                    'NEITHER'                          21018001
         CLI   CEKYST(GRDIC),X'D7'     TURN 'GET OR PUT' SWITCH ON      21024001
         BC    CEBNE,CEKEY1          IF KEYWORD IS 'PUT' AND OFF IF     21030001
         MVI   GOPSW,X'FF'           KEYWORD IS 'GET'                   21036001
         BC    CEBR,CEKEY2                                              21042001
CEKEY1   CLI   CEKYST(GRDIC),X'D5'                                      21048001
         BC    CEBNE,CEKEY2                                             21054001
         MVI   GOPSW,X'00'                                              21060001
         SPACE 1                                                        21066001
CEKEY2   BAL   GR2,CEKYWD              GO TO KEYWORD ROUTINE            21072001
         BC    CEBR,CE31               BRANCH BACK                      21080013
         SPACE 1                                                        21088001
GOPSW    DC    X'00'                   'GET OR PUT' SWITCH              21096001
*                                      TURNED ON FOR 'PUT' KEYWORD      21104001
*                                      SET TO X'0F' FOR NEITHER         21112001
         SPACE 2                                                        21120013
*                       THIS IS TRANSFER POINT FOR SECOND LEVEL MARKER  21160013
         SPACE                                                          21200013
CE2L     CLI   1(GR7),STRING           IN THE CASES WHERE THE 2ND LEVEL 21240013
         BC    CEBNE,CE2LC             IN THE CASES WHERE THE SECOND    21260001
         CLI   GOPSW,X'FF'           LEVEL MARKER PRECEDES THE STRING   21280001
         BC    CEBE,CE2LA              OPTION IN A PUT STATEMENT, OR    21300001
         BC    CEBR,CE2LB            KEYTO OR REPLY OPTIONS, WE         21320001
CE2LC    CLI   1(GR7),KEYTO          ARE IN A 'SETS' POSITION, AND WE   21340001
         BC    CEBE,CE2LA            SET A FLAG TO PREPARE US FOR       21360013
         CLI   1(GR7),REPLY          PSEUDO-VARIABLES RATHER THAN       21400013
         BC    CEBNE,CE2LB           BUILT-IN FUNCTIONS.                21440013
CE2LA    MVI   CEFFLG(GRDIC),X'FF'                                      21480013
         MVI   SETS,X'FF'                                               21520013
CE2LB    MVC   0(2,GR6),0(GR7)         MOVE THE TWO BYTES TO OUTPUT     21560013
         MVC   CE2LM(1,GRDIC),1(GR7)   AND STORE ATTRIBUTE              21600013
         AR    GR7,GR15                BUMP                             21640013
         AR    GR6,GR15                POINTERS                         21680013
         BC    CEBR,CE31                                                21720013
         SPACE 2                                                        21760013
         SPACE                                                          21800013
*                       THIS IS THE TRANSFER POINT FOR (                21840013
*        NOW LOOK AT ITEM PRECEDING THIS TO SEE IF IT IS NECESSARY TO   21880013
*        INSERT A MARKER                                                21920013
*              PICK UP PREVIOUS ITEM AND IF IT IS A VARIABLE CONTINUE   21960013
*        TESTING. IF IT IS A DUMMY REFERENCE DELETE THE LIST.           22000013
         SPACE                                                          22040013
CELP     CLI   CELITM,CEIDNT           IS PREVIOUS ITEM A VARIABLE      22080013
         BC    CEBH,CE34ZZ             NO                               22120013
         BCTR  GR6,0              YES SO PICK UP                        22160013
         BCTR  GR6,0              LAST DICT REF FROM OUTPUT TEXT        22200013
         MVC   CEDRF(2),0(GR6)    STORE IT IN CEDREF                    22240013
         CLC   CEDUMD+1(2),CEDRF       IS THIS A DUMMY DICT REF         22280013
         LA    GR6,2(0,GR6)       RESTORE GR6                           22320013
         BC    CEBE,CEFNCX             YES SO REMOVE FOLLOWING PARENTHE 22360013
*                                      -SISED LIST                      22400013
         SPACE 2                                                        22440013
*                       THIS PICKS UP ABS ADDR OF VARIABLE              22480013
         SPACE                                                          22520013
         MVC   PAR1+2(2,GRDIC),CEDRF   LOAD IN SYMBOLIC ADDRESS         22560013
*********************************************************************** 22600013
         L     GR1,ZDRAOF(0,GR11)                                       22640013
         BALR  GR14,GR1                                                 22680013
         L     GR5,PAR1(0,GRDIC)       SET GR1 TO POINT AT ENTRY        22720013
*********************************************************************** 22760013
         SPACE 2                                                        22800013
*                       GR5 CONTAINS ABSOLUTE ADDRESS OF DICT ENTRY     22840013
*        NOW SEE IF THIS IS A FUNCTION, LABEL OR ARRAY                  22880013
         SPACE                                                          22920013
         TM    0(GR5),X'10'       IS DIMENSIONED BIT ON IN 1ST CODE BYT 22960013
         BC    CEBO,CEGG41        YES                                   23000013
         CLI   0(GR5),CBLTGN           IS THIS WITHIN FUNCTION ID RANGE 23040013
         BC    CEBH,CE34X              CODE BYTE. NOT A SIMPLE ONE BUT  23080013
*                                      BRANCH TO TEST FOR OTHERS        23120013
         CLI   0(GR5),X'00'       YES.IT COULD BE IF NOT A ST. LAB. CON 23160013
         BC    CEBE,CE34               NO,AFTER ALL ITS NOT A FUNCTION  23200013
         CLI   0(GR5),CEXETP           IS IT A LABEL                    23240013
         BC    CEBNH,CEG1D4            IF SO, SKIP PSEUDO VAR TEST      23280013
         SPACE                                                          23320013
*              THIS IS A FUNCTION SO TEST WHETHER THE MARKER TO GO      23360013
*        BEFORE THE ( IS A FUNCTION MARKER OR PSEUDO-VARIABLE MARKER    23400013
         SPACE                                                          23440013
CE34Y    TM    CEBIF2(GR5),X'10'       IS PSEUDO VARIABLE BIT ON        23480013
*                                      -IN FUNCTION ENTRY               23520013
         BC    CEBNO,CEG1D4            NO, SO BRANCH ROUND NEXT BLK     23560001
         CLI   CEFFLG(GRDIC),X'00'     IS FFLAG OFF                     23600013
         BC    CEBE,CEG1D4             YES, SO ITS A FUNCTION           23640013
         CLI   SETS,X'FF'              ARE WE IN (PUT) STRING, KEYTO OR 23645001
*                                    REPLY OPTION                       23650001
         BC    CEBNE,CE34XB            NO. GO TO TEST ( COUNT           23655001
         CLI   CEBIF1(GR5),CESBYT      YES.IS IT STRING PV              23660001
         BNE   NESTPV                  NO,CHECK NESTED P.V'S     31620  23665020
         MVI   SPVESW,X'FF'            NO.  UNSUPPORTED IN (PUT)        23670001
         BC    CEBR,CEFNCY           STRING, KEYTO OR REPLY OPTION SO   23675001
*                                    GO TO SUBSTITUTE DUMMY REF IN      23680001
*                                    TEXT, ISSUE DIAGNOSTIC IEM0659     23685001
*                                    AND DELETE PARETHESIZED LIST       23690001
*                                    FOLLOWING                          23695001
NESTPV   CLC   CEONE(4),CEBCT          IS BRAK COUNT ONE         31620  23696020
         BE    CE34XA                   YES, MARK AS P.V.         31620 23697020
         B     G1D4A                                             31620  23698020
CE34XB   EQU   *                                                        23698420
         CLC   CEONE(4),CEBCT          IS BRAK CNT 0,1,>1        32245  23698820
         BL    CEG1D4                  FUNCTION                  32245  23699220
         BE    G1D4A                   POSS P.V.            19093/32245 23699620
         SPACE 1                                                        23700001
CE34XA   MVI   0(GR6),CEANCH           MOVE OUT PV MARKER               23750001
         MVI   PSUFLG,X'FF'            SET PSUEDO VARIABLE FLAG ON19093 23780001
         BC    CEBR,CEG1F6                                              23800013
         SPACE                                                          23840013
*              FUNCTION SO SET FLAG ON AND THEN TEST VALIDITY OF POSIT- 23880013
*        ION OF THE FUNCTION. UPDATE FUNCTION STACK                     23920013
       SPACE 1                                                          23924001
G1D4A    CLI   PSUFLG,X'FF'          IS THIS A NESTED PSUEDO      19093 23928001
         BC    BNE,CEG1D4            VARIABLE, IF NOT THEN BRANCH 19093 23932001
       SPACE 1                                                          23936001
*              NESTED PSUEDO VARIABLE, SO ITS AN ERROR.           19093 23940001
         MVI   CERRC,X'94'                                        19093 23944001
         BC    B,CERR                                             19093 23948001
       SPACE 1                                                          23952001
         SPACE                                                          23960013
CEG1D4   MVI   CFNFLG,X'FF'            SET FNCFLG ON                    24000013
         SPACE 2                                                        24040013
CE35     BAL   GR2,CEFNCT              GO TO CHECK ROUTINE              24080013
         MVI   0(GR6),CEUPAR           MOVE IN MARKER TO TEXT           24120013
         LA    GR1,1(0,GR6)            BUMP OUTPUT POINTER              24160013
         SPACE                                                          24680013
*              SET FLAG OFF AND BUMP BRACKET COUNT FOR THIS PSEUDO-     24720013
*        VARIABLE                                                       24760013
         SPACE                                                          24800013
CEG1F6   MVI   CEBFLG,X'00'            CLEAR BFLAG                      24840013
         L     GR1,CEBCT               BUMP                             24880013
         AR    GR1,GR15                BRACKET COUNT BY ONE             24920013
         ST    GR1,CEBCT               AND STORE                        24960013
         BC    CEBR,CEGC53                                              25000013
         SPACE                                                          25040013
*              SET FLAG OFF AND BUMP BRACKET COUNT                      25080013
         SPACE                                                          25120013
CEG1F5   L     GR1,CEBCT               BUMP BRACKET COUNT BY ONE        25160013
         AR    GR1,GR15                                                 25200013
         ST    GR1,CEBCT                                                25240013
         MVI   CEBFLG,X'00'            SET B FLAG OFF                   25280013
         BC    CEBR,CEGC52                                              25320013
         SPACE                                                          25360013
*              A FUNCTION, PSEUDO-VARIABLE OR CALL IS PRESENT IN THE    25400013
*        PROGRAM WITH AN ARGUMENT LIST SO SET FLAG ON                   25440013
         SPACE                                                          25480013
CEGC53   OI    ZARGFL(GRDIC),X'10'     SET ARGFL FLAG ON                25520013
         SPACE                                                          25560013
*              BUMP OUTPUT POINTER AND RETURN                           25600013
         SPACE                                                          25640013
CEGC52   AR    GR6,GR15                BUMP OUTPUT POINTER              25680013
         BC    CEBR,CE32                                                25720013
         SPACE 2                                                        25760013
*                       THIS IS TRANSFER POINT FOR ASSIGNMENT EQUAL     25800013
*              ALSO A COMMA USED INSIDE NESTED P.V'S             31620  25820020
         SPACE 2                                                        25840013
CEAE     EQU   *                                                        25846020
         MVI   CEFFLG(GRDIC),X'FF'     RESET FOR POSS P.V.'S     32245  25852020
         CLI   0(GR7),X'57'            IS IT MULT ASSIGN          2245  25858020
         BE    NEST                    YES MORE P.V.S POSSIBLE    2245  25864020
         CLI   0(GR7),X'41'            IS IT COMMA?              32245  25870020
         BNE   ASSIGN                  NO MUST DE ASSIGN EQUAL   32245  25876020
         CLC   CEBCT,CEZERO            IS BRAC COUNT ZERO(MULT ASSIGN)  25882020
         BE    NEST                    YES,SO NOT INSIDE FUNC    32245  25888020
ASSIGN   EQU   *                                                 32245  25894020
         MVI   CEFFLG(GRDIC),X'00'                               32245  25900020
NEST     EQU   *                                                 32245  25906020
         BC    CEBR,CE32                                                25920013
         SPACE 2                                                        25960013
*                       TRANSFER POINT FOR )                            26000013
*        REDUCE BRACKET COUNT AND RETURN                                26040013
         SPACE                                                          26080013
CERP     L     GR1,CEBCT               PICK UP BRACKET COUNT            26120013
         LTR   GR1,GR1                 IS IT ZERO                       26160013
         BZ    CEG5G3                                                   26200019
         SR    GR1,GR15                NO, SO REDUCE COUNT BY 1         26240013
         ST    GR1,CEBCT               AND STORE                        26280013
         LTR   GR1,GR1                 IS IT ZERO                   H55 26290017
         BC    CEBNE,CE32            NO SO BRANCH                   H55 26300017
         MVI   SETS,X'00'            YES SO CLEAR SETS SWITCH       H55 26310017
         MVI   PSUFLG,X'00'               AND PV FLAG                   26315001
         BC    CEBR,CE32                                                26320013
         SPACE 2                                                        26360013
*              ROUTINE TO HANDLE NESTED FUNCTIONS OR CALL STATEMENTS.   26400013
*        IT IS ENTERED WHEN FINAL CLOSING PARENTHESIS IS ENCOUNTERED IN 26440013
*        A STATEMENT.                                                   26480013
         SPACE                                                          26520013
CEG5G3   CLI   CEKYST(GRDIC),CECALL    IS KEYWORD CALL                  26640013
         BC    CEBE,CEG6A1             YES,SO BRANCH                    26680013
         CLI   CEKYST(GRDIC),CEWAIT    IS THE KEYWORD WAIT              26720013
         BC    CEBNE,CE32              NO, SO CONTINUE                  26760013
         MVI   CEWFLG,X'00'            SET W FLAG OFF                   26800013
         CLI   1(GR7),CELPAR           IS NEXT ITEM (                   26840013
         BC    CEBNE,CE32              NO, SO RETURN                    26880013
         MVC   0(2,GR6),CERPWT         YES, SO MOVE ) AND WTC MARKER    26920013
         LA    GR6,2(0,GR6)            BUMP TEXT POINTER                26960013
         BC    B,CE31P                                                  27000013
CERPWT   DC    X'45C6'                 RIGHT PAREN AND WAIT MARKER.     27040013
         SPACE 2                                                        27080013
         SPACE 2                                                        27400013
CEG6A1   CLI   CEBFLG,X'FF'            IS B FLAG ON                     27440013
         BC    CEBNE,CEG6D2            NO                               27480013
         MVI   CEBFLG,X'00'            YES, SO SET B FLAG OFF           27520013
         MVI   0(GR6),CEDWAR           MOVE DOWNWARD ARROW TO           27560013
         AR    GR6,GR15                TEXT AND BUMP POINTER            27600013
CEG6D2   MVI   0(GR6),CERPAR           MOVE IN ) TO TEXT                27640013
         AR    GR6,GR15                BUMP TEXT POINTER                27680013
         CLI   1(GR7),CELPAR           IS NEXT ITEM A (                 27720013
         BC    CEBNE,CE31P             NO, SO RETURN                    27760013
         AR    GR6,GR15                BUMP TEXT POINTER                27800013
         SPACE 2                                                        27840013
*              THIS IS AN ARRAY WITH SUBSCRIPTS SO INSERT MARKER        27880013
         SPACE 2                                                        27920013
CEGG41   MVI   0(GR6),CEDWAR           PUT DOWNWARD ARROW IN TEXT       27960013
         BC    CEBR,CEG1F5                                              28000013
         SPACE 2                                                        28040013
         SPACE 2                                                        28080013
*                       TRANSFER POINT FOR SEMI-COLON                   28120013
*        CLEAR FLAGS, STORES AND BRACKET COUNT                          28160013
         SPACE                                                          28200013
CESMCL   MVI   CEKYST(GRDIC),X'00'     CLEAR KEYWORD STORE              28240013
         MVI   CE2LM(GRDIC),X'00'      CLEAR SECOND LEVEL MARKER STORE  28280013
         XC    CEBCT(4),CEBCT          AND BRACKET COUNT                28320013
         MVI   CEFFLG(GRDIC),X'00'     CLEAR FLAG                       28360013
         MVI   CEFMST,X'00'            CLEAR FORMAT STORE               28400013
         MVI   PSUFLG,X'00'                                       19093 28420001
         BC    CEBR,CE32                                                28440013
         SPACE 2                                                        28480013
*                       TEXT ITEM ( IS NOT PRECEDED BY DICTIONARY       28520013
*        REFERENCE WHICH DOES NOT REFER TO AN ARRAY OR FUNCTION. TEST   28560013
*        TO SEE IF THE ENTRY IS VALID. IF NOT GIVE AN ERROR MESSAGE     28600013
         SPACE                                                          28640013
         SPACE 2                                                        28680013
CE34X    CLI   0(GR5),CENTP5           IS THIS ENTRY TYPE 5             28720013
         BC    CEBE,CE34Y              YES, SO TREAT AS FUNCTION        28760013
         CLI   0(GR5),CEGNEL           IS IT GENERIC ENTRY LABEL        28800013
         BC    CEBE,CE34Y              YES, SO TREAT AS FUNCTION        28840013
         CLI   0(GR5),CECNTX           IS THIS A CONSTANT               28880013
         BC    CEBNE,CE34              NO, SO IT IS AN ERROR            28920013
         SPACE 2                                                        28960013
*                       IF THIS IS A CONSTANT REPLICATION FACTOR IN A   29000013
*                       FORMAT LIST THEN IT IS VALID                    29040013
         SPACE                                                          29080013
         CLI   CE2LM(GRDIC),CEFTLS     IS THIS A FORMAT LIST            29120013
         BC    CEBE,CE34ZZ             YES, SO BRANCH ROUND             29160013
         CLI   CEFMST,CEFRMT           IS THIS A FORMAT STATEMENT       29200013
         BC    CEBNE,CE34              NO, SO IT IS AN ERROR            29240013
CE34ZZ   L     GR1,CEBCT               BUMP BRACKET COUNT               29280013
         AR    GR1,GR15                BY ONE                           29320013
         ST    GR1,CEBCT               AND STORE                        29360013
         BC    CEBR,CE32               AND CONTINUE SCAN                29400013
         SPACE                                                          29440013
*                       ERROR MESSAGE POINT. GIVE MESSAGE AND DELETE    29480013
*        PARENTHESISED LIST                                             29520013
         SPACE                                                          29560013
CE34     BAL   GR4,CER68P              GO TO ERROR ROUTINE              29600013
         SPACE 2                                                        29640013
CEGZX    BC    CEBR,CEFNCX             GO TO REMOVE LIST                29680013
         SPACE 2                                                        29720013
*                       TRANSFER POINT FOR DICTIONARY REFERENCE CODE 00 29760013
*        MOVE WHOLE OF REFERENCE TO THE OUTPUT AREA                     29800013
         SPACE 2                                                        29840013
CEDDRF   MVC   0(3,GR6),0(GR7)    MOVE DICTIONARY REF TO TEXT           29880013
         LA    GR6,3(0,GR6)            BUMP                             29920013
         LA    GR7,3(0,GR7)            POINTERS                         29960013
         BAL   GR14,CENDTS             TEST FOR END OF OUTPUT BLOCK AND 30000013
         BC    CEBR,CE300              CONTINUE                         30040013
         SPACE 2                                                        30080013
*                       TRANSFER POINT FOR WHEN A STATEMENT EXCEEDS     30120013
*                       A TEXT BLOCK IN SIZE                            30160013
         SPACE                                                          30200013
CERR28   MVC   PAR6+1(3,GRDIC),CERR2R  MOVE IN ERROR CODE         H408  30220019
         B     *+10                                               H408  30240019
         SPACE                                                          30280013
*                      TRANSFER POINT FOR ERROR                         30320013
         SPACE                                                          30360013
CERRRR   MVC   PAR6+1(3,GRDIC),CERR1R   MOVE IN CODE BYTE               30400013
        L     GR1,ZERROF(0,GR11)      GO TO ERROR ROUTINE               30440013
         BALR  GR14,GR1                                                 30480013
         L     GR1,ZABORT(0,GR11)                                       30520013
         BALR  GR14,GR1                                                 30560013
*********************************************************************** 30600013
         SPACE 2                                                        30640013
         SPACE 2                                                        30680013
CE32     MVC   0(1,GR6),0(GR7)                                          30720013
*                                                                       30760013
         SPACE                                                          30800013
CE31     AR    GR6,GR15                BUMP OUTPUT TEXT POINTER         30840013
CE31P    BAL   GR14,CENDTS             GO TO END TEST ROUTINE           30880013
         BC    CEBR,CE30                                                30920013
         SPACE 2                                                        30960013
*                       TRANSFER POINT TO MOVE SUB AND BINARY CONSTANT  31000013
         SPACE                                                          31040013
CEISUB   MVC   0(2,GR6),0(GR7)         MOVE SUB AND BINARY CONST        31080013
         LA    GR7,2(0,GR7)            ADJUST                           31120013
         LA    GR6,2(0,GR6)            POINTERS                         31160013
         BAL   GR14,CENDTS             TEST FOR END OF BLOCK            31200013
         BC    CEBR,CE300                                               31240013
         EJECT                                                          31280013
*              FUNCTION/OPERATION                                       31320013
         SPACE 3                                                        31360013
*                       THIS ROUTINE TESTS IF THE OUTPUT POINTER (GR6)  31400013
*                       IS AT THE END OF THE CURRENT TEXT BLOCK. IF NOT 31440013
*                       AN ORDINARY RETURN OCCURS BUT IF IT IS THEN A   31480013
*                       NEW TEXT BLOCK IS GOT AND CHAINED TO THE CURR-  31520013
*                       ENT ONE. THAT PART OF THE STATEMENT BEING PROC- 31560013
*                       ESSED WHICH IS IN THE CURRENT BLOCK IS MOVED    31600013
*                       INTO THE NEW BLOCK AND AN EOB MARKER PLACED AT  31640013
*                       THE END OF THE LAST COMPLETE STATEMENT IN THE   31680013
*                       CURRENT BLOCK. THE INPUT POINTER (GR6) AND      31720013
*                       OUTPUT POINTER (GR7) ARE UPDATED. THE CURRENT   31760013
*                       BLOCK IS THEN MARKED AS NOT WANTED.             31800013
*                       IF THE STATEMENT TO BE MOVED IS ALREADY A TEXT  31840013
*                       BLOCK LONG WE GIVE UP.                          31880013
*                       GR1,GR4,GR5 ARE USED AS SCRATCH REGISTERS       31920013
         SPACE 3                                                        31960013
*              ENTRY POINT                                              32000013
*                       CENDTS CALLED BY    BAL   GR14,CENDTS           32040013
         SPACE 3                                                        32080013
*              INPUT                                                    32120013
*              GR6 POINTS AT THE LAST BYTE USED IN THE OUTPUT BLOCK.    32160013
         SPACE 3                                                        32200013
*              OUTPUT                                                   32240013
*              GR6 POINTS AT THE LAST BYTE UED IN THE OUTPUT BLOCK.     32280013
         SPACE 3                                                        32320013
*              WORK AREA                                                32360013
*              N/A                                                      32400013
         SPACE 3                                                        32440013
*              EXTERNAL ROUTINES                                        32480013
*                       ZUTXTC    GET NEW TEXT BLOCK                    32520013
*                       ZTXTAB    CONVERT TEXT REFERENCE TO ABSOLUTE.   32560013
*                       ZALTER    CHANGE STATUS OF NAMED BLOCK.         32600013
         SPACE 3                                                        32640013
*              NOTES                                                    32680013
*              GR1,GR4,GR5 USED AS SCRATCH REGISTERS.                   32720013
         SPACE 3                                                        32760013
         SPACE 2                                                        32800013
CENDTS   C     GR6,CEENDB              HAVE WE REACHED THE LAST LOC IN  32840013
         BC    CEBL,CERETN             THIS BLOCK. NO, SO RETURN        32880013
         SPACE 2                                                        32920013
CENEWB   MVC   PAR1+1(3,GRDIC),CESCYM            MOVE IN SYMBOLIC ADDR  32960013
         MVI   PAR2+3(GRDIC),X'84'     SET UP PARAMETERS TO CHAIN IN    33000013
         ST    GR14,CEGR14             SAVE GR14                        33040013
         L     GR5,ZUTXTC(0,GR11)      NEW BLOCK                        33080013
         BALR  GR14,GR5                                                 33120013
         MVC   CESCLM(3),CESCYM        SAVE SYMBOLIC ADDR OF LAST BLOCK 33160013
         MVC   CESCYM(3),PAR1+1(GRDIC) SAVE NEW SYMBOLIC ADDRESS        33200013
         LR    GR1,GR6                 SAVE VALUE OF GR6                33240013
         L     GR5,ZTXTAB(0,GR11)      CONVERT TO ABSOLUTE              33280013
         BALR  GR14,GR5                AND                              33320013
         L     GR6,PAR1(0,GRDIC)       SET GR6 POINTING TO START OF NEW 33360013
         LR    GR5,GR6                 BLOCK                            33400013
         A     GR5,ZTXBSZ(0,GRDIC)     CALCULATE END LOCATION           33440013
         S     GR5,CE4                 OF THIS BLOCK AND STORE          33480013
         ST    GR5,CEENDB                                               33520013
         L     GR5,CESTNL              LOAD GR5 WITH LOCATION OF LAST   33560013
         LR    GR4,GR5                 STATEMENT NUMBER IN OLD BLOCK    33600013
         SR    GR1,GR5                 SUBTRACT TO GET LENGTH OF TEXT   33640013
         SPACE 2                                                        33680013
CEBR1    C    GR1,CE256                TO BE MOVED. IT IT IS LESS THAN  33720013
         BC    CEBL,CEJMOV             255 BYTES BRANCH                 33760013
         SPACE                                                          33800013
         C     GR1,ZTXBSZ(0,GRDIC)     IS LENGTH 1 TEXT BLOCK           33840013
         BC    CEBNL,CERR28            IF SO IT IS AN ERROR             33880013
         MVC   0(256,GR6),0(GR4)       IF NOT MOVE 256 BYTES TO NEW BLK 33920013
         LA    GR4,256(0,GR4)          BUMP POINTERS                    33960013
         LA    GR6,256(0,GR6)                                           34000013
         S     GR1,CE256               REDUCE COUNT OF TEXT TO BE MOVED 34040013
         BC    CEBR,CEBR1             BY 256 AND TRY AGAIN              34080013
         SPACE 2                                                        34120013
CEJMOV   BCTR  GR1,0                   REDUCE COUNT FOR INSTRUCTION     34160013
         STC   GR1,CEMOV+1             LESS THAN 256 TO MOVE SO SET UP  34200013
CEMOV    MVC   0(0,GR6),0(GR4)         INSTRUCTION AND MOVE TEXT        34240013
         MVI   0(GR5),CEEOB            STORE EOB MARKER AND NEXT BLK    34280013
*                                      STATEMENT NUMBER IN THE OLD BLK  34320013
         LA    GR6,1(GR6,GR1)          BUMP POINTER TO END OF TEXT NTRY 34360013
         C     GR7,SFLPNT          HAS 2ND FILE JUST STARTED            34364015
         BC    CEBNE,CENOT2        NO                                   34368015
*        IF SO, MUST UPDATE START OF 2ND FILE SLOT IN DICT              34372015
         MVC   PAR1+1(3,GRDIC),CESCYM        SET UP FOR ZTXTRF CALL     34376015
         ST    GR6,PAR2(GRDIC)                                          34380015
         L     GR5,ZTXTRF(GR11)                                         34384015
         BALR  GR14,GR5            CALL ZTXRRF                          34388015
         MVC   Z2FILE(4,GRDIC),PAR1(GRDIC)      UPDARE POINTER          34392015
CENOT2   EQU   *                                                        34396015
         MVC   PAR1+1(3,GRDIC),CESCLM  SET UP PARAMETERS                34400013
         MVI   PAR2+3(GRDIC),X'02'     TO MARK                          34440013
         L     GR5,ZALTER(0,GR11)      LAST TEXT BLOCK AS NOT WANTED    34480013
         BALR  GR14,GR5                                                 34520013
         L     GR14,CEGR14             RESTORE GR14                     34560013
CERETN   BCR   CEBR,GR14               AND RETURN.                      34600013
         EJECT                                                          34640013
*                       TRANSLATE TABLE FOR CODE BYTES ETC              34680013
         SPACE                                                          34720013
CETRAN   DC    X'28'                   DICTIONARY REFERENCE             34760013
         DC    5X'040404040404'                                         34800013
         DC    X'04'                                                    34840013
         DC    4X'0000000000000000'                                     34880013
         DC    X'30'                   BLANK                            34920013
         DC    X'1000'                 COMMA                            34960020
         DC    X'08'                   LEFT PAREN (                     35000013
         DC    X'00'                                                    35040013
         DC    X'0C'                   RIGHT PAREN <                    35080013
         DC    X'10'                   SECOND FILE LEFT ARROW           35120013
         DC    X'10'                   LEFT ARROW                       35160013
         DC    2X'00000000000000'                                       35180020
         DC    X'00100000000000'                                        35200020
         DC    X'00000000100000'       DO LEFT ARROW                    35240013
         DC    3X'00000000000000'                                       35280013
         DC    X'00000000003000'                                        35320013
         DC    X'141414141414'                                          35360013
         DC    X'201414142014'         THEN SNAP                        35400013
         DC    5X'141414141414'                                         35440013
         DC    X'1410'                 LABEL ARRAY INITIAL              35480013
         DC    2X'1414141414141414'                                     35520013
         DC    X'142020141414141414141414'  ELSE NOSNAP                 35560013
         DC    X'18'                   SECOND LEVEL MARKER              35600013
         DC    3X'141414141414141414141414'                             35640013
         DC    X'1414'                                                  35680013
         DC    X'20'                   SEMI-COLON                       35720013
         DC    11XL1'1C'               CONSTANTS                        35760013
         DC    X'14'                   ON                               35800013
         DC    X'001C2C1C'             SUB,                             35840013
         EJECT                                                          35880013
*                       TABLE OF TRANSFER ADDRESSES FILLED IN AT OBJECT 35920013
*                       TIME                                            35960013
         SPACE                                                          36000013
CETRTB   BC    CEBR,CE32               0 BRANCH TO CONTINUATION         36040013
         BC    CEBR,CEID               4 BRANCH FOR IDENTIFIER          36080013
         BC    CEBR,CELP               8 BRANCH FOR LEFT PARENTHESES    36120013
         BC    CEBR,CERP               C BRANCH FOR RIGHT PARENTHESES   36160013
         BC    CEBR,CEAE              10 BRANCH FOR ASSIGNMENT EQUALS   36200013
         BC    CEBR,CEKEY             14 BRANCH FOR KEYWORD             36240013
         BC    CEBR,CE2L              18 BRANCH FOR 2ND LEVEL MARKER    36280013
         BC    CEBR,CERRRR             1C BRANCH FOR ERROR              36320013
         BC    CEBR,CESMCL            20 BRANCH FOR SEMI- COLON         36360013
         BC    CEBR,*                  24 PAST BRANCH FOR DOWN ARROW'   36400013
         BC    CEBR,CEDDRF            28 BRANCH FOR DICT REF            36440013
         BC    CEBR,CEISUB             2C   BRANCH FOR ISUB             36480013
         BC    CEBR,CE30               30   BRANCH FOR BLANK            36520013
         EJECT                                                          36560013
*                       THIS ROUTINE SCANS DICTIONARY FOR CORRECT       36600013
*        DICTIONARY FOR GIVEN BCD                                       36640013
*                                                                       36680013
*                       ON ENTRY GR7 POINTS BCD LENGTH BYTE IN TEXT     36720013
*                                GR6 POINTS AT NEXT FREE BYTE IN THE    36760013
*                       OUTPUT BLOCK                                    36800013
*                       ALL REGISTERS USED ARE SAVED BY THE ROUTINE AND 36840013
*                       RESTORED                                        36880013
*                       ON EXIT GR7 POINTS AT LAST BYTE OF BCD          36920013
*                               GR6 POINTS AT END OF DICTIONARY REFER-  36960013
*                       ENCE JUST PLACED IN OUTPUT BLOCK                37000013
         SPACE 2                                                        37040013
*                       INITIALISATION AND HASHING                      37080013
*        POINT AT BCD AND HASH IT, TO GIVE OFFSET FROM START OF HASH    37120013
*        TABLE. IF SLOT IS ZERO THEN A NEW ENTRY IS REQUIRED, IF NOT    37160013
*        THEN THE HASH CHAIN MUST BE SCANNED.                           37200013
         SPACE                                                          37240013
*              SAVE START ADDRESS OF VARIABLE IN TEXT AND POSITION      37280013
*        POINTER AT START OF LAST SECTION OF VARIABLE'S BCD. I.E. AT    37320013
*        START FOR A NON-QUALIFIED NAME OR BEFORE LAST ITEM IN A        37360013
*        QUALIFIED NAME                                                 37400013
         SPACE 3                                                        37440013
*              FUNCTION/OPERATION                                       37480013
*                       TO SCAN THE DICTIONARY FOR A GIVEN BCD AND TO   37520013
*              RETURN THE ADDRESS OF THE RELEVANT DICTIONARY ENTRY WITH 37560013
*              THE SAME BCD AND WHICH IS KNOWN AT THIS POINT OF THE     37600013
*              PROGRAM. AN ILLEGAL ENTRY WILL RETURN A DUMMY REFERENCE  37640013
*              AND AN ERROR MESSAGE IS PRODUCED.                        37680013
*                       THIS SYMBOLIC ADDRESS IS PLACED IN THE OUTPUT   37720013
*              TEXT PRECEDED BY A ZERO BYTE.                            37760013
         SPACE 3                                                        37800013
*              ENTRY POINT                                              37840013
*                       CESCN - ENTERED BY       BAL   GR2,CESCN        37880013
         SPACE 3                                                        37920013
*              INPUT                                                    37960013
*              GR7 POINTS AT THE BCD LENGTH BYTE BEFORE THE BCD.        38000013
*              GR6 POINTS AT THE NEXT AVAILABLE BYTE IN THE OUTPUT AREA 38040013
         SPACE 3                                                        38080013
*              OUTPUT                                                   38120013
*              GR7 POINTS AT THE LAST BYTE OF THE BCD                   38160013
*              GR6 POINTS AT THE END OF DICTIONARY ENTRY IN THE OUTPUT  38200013
*              AREA.                                                    38240013
         SPACE 3                                                        38280013
*              EXIT     NORMAL - RETURN ON GR2.                         38320013
         SPACE 3                                                        38360013
*              WORK AREA                                                38400013
*              1K OF SCRATCH IS USED. START ADDRESS OF THIS AREA IS     38440013
*              IN CESTKA.                                               38480013
         SPACE 3                                                        38520013
*              NOTES                                                    38560013
*              REGISTERS USED ARE SAVED ON ENTRY AND RESTORED ON EXIT.  38600013
         SPACE 3                                                        38640013
         SPACE                                                          38680013
CESCN    STM   GR14,GR5,CEDUMP         SAVE REGISTERS 14 TO 5 INCLUSIVE 38720013
         SPACE                                                          38760013
*              CLEAR FLAGS AND SET UP COUNTS ETC. LOOK AT FIRST BCD     38800013
         SPACE                                                          38840013
         XC    CEFLAG(4),CEFLAG        CLEAR FLAGS                      38880013
         XC    OLDSTR(4,GRDIC),OLDSTR(GRDIC) CLEAR DICTIONARY REF STORE 38920013
         L     GR4,STKCNT              PICK UP STACK COUNT              38960013
         XR    GR4,GR4                 AND SET TO ZERO                  39000013
         ST    GR7,TXTSTR              SAVE START ADDRESS               39040013
         SPACE                                                          39080013
*              PICK UP BCD LENGTH AND SEE IF THIS IS A QUALIFIED NAME   39120013
*        OR ILLEGAL BCD LENGTH.                                         39160013
         SPACE                                                          39200013
         XR    GR1,GR1                 PICK UP                          39240013
         IC    GR1,0(0,GR7)            PICK UP BCD                      39280013
         CLI   0(GR7),MAXBCD           BCD LENGTH                       39320013
         BC    CEBH,CERR27             IS LENGTH TOO LONG               39360013
*                                      IF SO IT IS AN ERROR             39400013
         L     GR2,CESTKA              PICK UP START OF STACK           39440013
         ST    GR7,0(GR4,GR2)          STORE START OF TEXT AT BOTTOM    39480013
         AR    GR7,GR1                 IF NOT BUMP TO END OF BCD        39520013
         SPACE                                                          39560013
*              IS NEXT IN TEXT A . IF SO, THIS IS A QUALIFIED NAME      39600013
         SPACE                                                          39640013
         CLI   1(GR7),CEFSTP           IS NEXT ITEM A .                 39680013
         BC    CEBNE,CENQUL            NO SO THIS IS NOT A QUALIFIED    39720013
*                                      NAME                             39760013
         SPACE                                                          39800013
*              QUALIFIED NAME SO WORK ALONG TO ITS END SAVING START OF  39840013
*        EACH NEW BCD IN A STACK AND KEEPING A COUNT.                   39880013
         SPACE                                                          39920013
CEIDLP   LA    GR4,4(0,GR4)            BUMP STACK COUNT                 39960013
         LA    GR7,2(0,GR7)            BUMP SCAN POINTER OVER .         40000013
         ST    GR7,0(GR4,GR2)          SAVE ADDRESS OF NEXT BCD LENGTH  40040013
*                                      BYTE                             40080013
         CLI   0(GR7),MAXBCD           IS LENGTH TOO LONG               40120013
         BC    CEBH,CERR27             YES SO ERROR                     40160013
         IC    GR1,0(0,GR7)            NO, SO PICK UP LENGTH            40200013
         AR    GR7,GR1                 AND BUMP SCAN POINTER TO END OF  40240013
         CLI   1(GR7),CEFSTP           BCD. IS NEXT ITEM .              40280013
         BC    CEBE,CEIDLP             YES, SO CONTINUE SCAN            40320013
         BC    CEBR,CENDQL             NO, SO FINISH HERE               40360013
         SPACE 2                                                        40400013
*              SET FLAG ON AS THIS IS A NON-QUALIFIED NAME              40440013
         SPACE                                                          40480013
CENQUL   OI    CEFLAG,NONQUL           SET NON QUALIFIED BIT ON         40520013
         SPACE                                                          40560013
*              SAVE STACK COUNT AND POINT AT START OF BCD               40600013
         SPACE                                                          40640013
CENDQL   ST    GR4,STKCNT              SAVE STACK COUNT                 40680013
         ST    GR7,ENDADR              SAVE ADDRESS OF LAST BYTE OF     40720013
         L     GR7,0(GR2,GR4)          PICK  UP LAST ENTRY IN STACK     40760013
         SPACE                                                          40800013
*              SET UP REGISTERS FOR CALL TO HASH ROUTINE                40840013
         SPACE                                                          40880013
         BCTR  GR1,0                   REDUCE GR1 TO BCD LENGTH-1       40920013
         LA    GR5,1(0,GR7)            POINT GR5 AT THE BCD             40960013
         LR    GR14,GR1                SAVE GR1 IN GR14                 41000013
         BAL   GR15,CHASH              BRANCH TO HASH ROUTINE           41040013
*********************************************************************** 41080013
         L     GR2,ZHASH(0,GRDIC)      SET GR2 TO POINT AT START OF HAS 41120013
       AR      GR2,GR0                 GR2 POINTS AT THE CORRECT ENTRY  41160013
         MVC   ZLOCK(2,GRDIC),0(GR2)    LOCK 1ST ENTRY ON HASH    57444 41170072
*                                       CHAIN, OR SET TO ZERO.    57444 41180072
         CLC   0(2,GR2),CEZERO         IS HASH ENTRY ZERO AND A STOPPER 41200013
         BC    CEBE,CEC31          YES, SO BRANCH                       41240013
CEC2A    MVC   PAR1+2(2,GRDIC),0(GR2)  IN HASH TABLE SO WE MOVE POINTER 41280013
         MVC   CELSYM(2,GR12),0(GR2)    TO DICT ENTRY FROM HASG TABLE   41320013
         L     GR3,ZDRFAB(0,GR11)      CONVERT                          41360013
         ST    GR14,CEG14              SAVE GR14                        41400013
         BALR  GR14,GR3                TO ABSOLUTE                      41440013
         L     GR14,CEG14              RESTORE GR14                     41480013
         EJECT                                                          41520013
*        FROM ENTRY IN HASH TABLE. CHASH RETURNED OFFSET FROM START OF  41560013
*        HASH TABLE IN GR0. ADDRESS OF START OF HASH GABLE IS IN        41600013
*        COMMUNICATION REGION.                                          41640013
         SPACE                                                          41680013
CE3AX    L     GR3,PAR1(0,GRDIC)       GR3 CONTAINS DICT ENTRY ADDRESS  41720013
         ST    GR3,CADD2(0,GR12)       SAVE IN CADD2                    41760013
         SPACE                                                          41800013
*              IF THIS SHOULD BE A STRUCTURE AND IS NOT,THEN THERE IS   41840013
*        NO POINT DOING ANY MORE TESTING                                41880013
         SPACE                                                          41920013
CEGOAG   TM    CEFLAG,NONQUL           IS NOT QUALIFIED NAME FLAG ON    41960013
         BC    CEBO,CE3A               YES, SO BRANCH TO  COMPARE BCD   42000013
         TM    0(GR3),CESTRC           IS THIS A STRUCTURE              42040013
         BC    CEBO,CE3A               YES, SO COMPARE BCD              42080013
         CLI   0(GR3),CEFPCB           IS IT A FORMAL PARAMETER         42120013
         BC    CEBNE,CE22              NO, SO TRY AGAIN                 42160013
         SPACE                                                          42200013
*              TEST BCD. IF BCD IN DICTIONARY AND TEXT DO NOT AGREE     42240013
*        THEN RETURN IS TO RETURN ADDRESS 14.                           42280013
         SPACE                                                          42320013
CE3A     BAL   GR15,CE3XX                                               42360013
         BC    CEBR,CEAGRE             YES,AGREES.                      42400013
         BC    CEBR,CE22               NO BCD AGREEMENT                 42440013
         EJECT                                                          42480013
*        THIS ROUTINE COMPARES THE SOURCE VARIABLE AND DICT ENTRY TO    42520013
*        SEE IF THE LENGTH OF THE BCD'S IS THE SAME AND IF SO           42560013
*        WHETHER THE BCD IS THE SAME.                                   42600013
*        GR7 POINTS TO THE LENGTH BYTE IN THE SOURCE TEXT               42640013
*        IF VARIABLE IS A FORMAL PARAMTER THEN GR3 IS SET TO THE        42680013
*        DETAILED DICT ENTRY IF AGREEMENT WAS FOUND IN THE BCD'S.       42720013
*        IF NO BCD IS FOUND A RETURN IS MADE TO SCAN THE HASH CHAIN .   42760013
         SPACE 2                                                        42800013
CE3XX    TM    0(GR3),X'80'            IS BCD ATTACHED TO THIS ENTRY    42840013
         BC    CEBO,CE22               NO, SO BRANCH                    42880013
         MVC   CELENG+2(2),1(GR3)      YES,SO PICK UP LENGTH UP TO BCD  42920013
         L     GR1,CELENG              LOAD LENGTH TO BCD IN GR1        42960013
         XR    GR2,GR2                                                  43000013
         IC    GR2,0(GR1,GR3)          PICK UP BCD LENGTH OF DICT ENTRY 43040013
         CR    GR2,GR14                COMPARE REGISTERS TO SEE IF BCD  43080013
         BC    CEBNE,CE22B             LENGTHS ARE EQUAL. NO,SO BRANCH  43120013
         STC   GR2,CECOMP+1            YES,SO IS BCD THE SAME. SET UP   43160013
         AR    GR1,GR3                 INSTRUCTION.GR1 POINTS AT LENGTH 43200013
         SPACE 2                                                        43240013
*                       BCD LENGTHS WERE THE SAME SO COMPARE BCDS       43280013
         SPACE                                                          43320013
CECOMP   CLC   1(0,GR1),1(GR7)         COMPARE BCD'S                    43360013
         BC    CEBE,CE22CZ             THEY DO AGREE                    43400013
         SPACE 2                                                        43440013
*                       IN CASE OF NON-AGREEMENT BUMP RETURN ADDRESS    43480013
*        BY 4                                                           43520013
         SPACE                                                          43560013
CE22B    LA    GR15,4(0,GR15)          BUMP RETURN ADDRESS BY 4         43600013
CE22CZ   BCR   CEBR,GR15                                                43640013
         EJECT                                                          43680013
*                       BCD AGREED AND THE LEVEL SO NOW SEE IF THIS     43720013
*                       IS A FORMAL PARAMETER ENTRY. IF SO THEN PICK    43760013
*                       UP ADDRESS FO COMPLETE ENTRY OR IF NONE MAKE    43800013
*                       ONE.                                            43840013
         SPACE                                                          43880013
CE22CC   CLI   0(GR3),X'40'            IS THIS A FORMAL PARAMETER       43920013
         BC    CEBNE,CE2K              NO, SO RETURN                    43960013
         CLC   CENWAD(2,GR3),CEZERO    IS THERE A FULL ENTRY'S ADDRESS  44000013
         BC    CEBE,CE22CE             NO                               44040013
*********************************************************************** 44080013
CEFPQQ   MVC   PAR1+2(2,GRDIC),CEFPFA(GR3) YES SO PICK UP FULL ENT AD   44120013
         MVC   CEFRSM(2),CELSYM(GR12)  SAVE SYMBOLIC ADDR. OF FP ENTRY  44160013
         MVC   CELSYM(2,GR12),CEFPFA(GR3)    AND                        44200013
         L     GR3,ZDRFAB(0,GR11)       CONVERT                         44240013
         ST    GR14,CEG14              SAVE GR14                        44280013
         BALR  GR14,GR3                 TO ABSOLUTE                     44320013
         L     GR14,CEG14              RESTORE GR14                     44360013
         L     GR3,PAR1(0,GRDIC)        SET GR3 TO FULL ENTRY           44400013
*********************************************************************** 44440013
CE22C    BC    CEBR,CE2                                                 44480013
         SPACE                                                          44520013
CE22CE   TM    CEFLAG,NONQUL           IS THIS A QUALIFIED N AME        44560013
         BC    CEBZ,CE22               YES, SO CONTINUE SCAN            44600013
         ST    GR3,CADD2(0,GR12)       STORE IN CADD2                   44640013
         MVC   CACL(1,GR12),CFPEL(GR3) MOVE IN 3-                       44680013
         MVC   CACC(1,GR12),CFPEC(GR3) AND C TO COLLECTION AREA         44720013
         BAL   GR2,CFPDR2              BRANCH TO ENTER CONSTANT         44760013
         BC    CEBR,CEFPQQ                                              44800013
         EJECT                                                          44840013
*                       CHECK TO SEE IF THE BLOCK COUNT OF THIS ENTRY   44880013
*        IS THE SAME OR KNOWN FROM THE CURRENT BLOCK.                   44920013
         SPACE                                                          44960013
CEAGRE   BCTR  GR1,0                   PICK  UP LEVL NO                 45000013
         CLC   CECURL(1),0(GR1)        IS CURRENT LEVEL NUMBER THE SAME 45040013
         BC    CEBE,CE22CC             AS DICT ENTRY'S, YES SO BRANCH   45080013
         BC    CEBL,CE22               LESS THAN                        45120013
         SPACE 2                                                        45160013
*                       THIS IS SECTION TO SCAN STACK TO FIND OUT IF    45200013
*                       THIS LEVEL IS VALID                             45240013
         SPACE                                                          45280013
CEJ31    XR    GR15,GR15               CLEAR GR15                       45320013
         LR    GR5,GR15                 AND GR5                         45360013
         LR    GR2,GR15                 AND GR2                         45400013
         IC    GR5,0(0,GR1)            PICK UP DICT LEVEL IN GR5        45440013
         IC    GR15,CECURL             PICK UP CURRENT LEVEL NO IN GR15 45480013
         L     GR4,ZCDSTK(0,GRDIC)     PICK UP START OF STACK           45520013
CELOOP   IC    GR2,0(GR15,GR4)         PICK UP CONSTANT IN TABLE        45560013
         CR    GR5,GR2                 IS IT EQUAL TO DICT LEVEL        45600013
         BC    CEBE,CE22CC             YES, SO CHECK FOR FORMAL PARAM   45640013
         BC    CEBH,CE22               IS DICT LEVEL GREATER,YES SO OUT 45680013
         LR    GR15,GR2                NO, SO PICK UP NEW OFFSET FROM   45720013
         BC    CEBR,CELOOP             START OF STACK AND TRY AGAIN     45760013
         SPACE 2                                                        45800013
*              THE BCD AND LEVEL NUMBER ARE SATISFACTORY. SAVE LEVEL    45840013
*        NUMBER. IF THIS IS A QUALIFIED NAME WE MUST START TO SCAN      45880013
*        STRUCTURE TO SEE IF IT IS THE RIGHT ONE. IF NOT THEN THIS      45920013
*        ENTRY MAY BE THE FINAL ONE                                     45960013
         SPACE                                                          46000013
CE2K     MVC   CEFRSM(2),CELSYM(GR12)  SAVE SYMBOLIC ADDRESS OF ENTRY   46040013
*                                      WITH BCD                         46080013
CE2      MVC   CELVLX(1),0(GR1)        SAVE BLOCK LEVEL                 46120013
         TM    CEFLAG,NONQUL           IS THIS A QUALIFIED NAME         46160013
         BC    CEBO,CENRND             NO, SO BRANCH OUT                46200013
         TM    0(GR3),CESTRC           IS THIS ENTRY A STRUCTURE        46240013
         BC    CEBZ,CEPKUP             NO, SO GO TO CONTINUE SCAN OF    46280013
*                                      HASH CHAIN                       46320013
*              SEE IF WE HAVE A DICTIONARY REFERENCE IN STORE FOR THIS  46360013
*        TEXT  ITEM. IF NOT SAVE THIS ONE. IF YES AND ITS COUNT IS NOT  46400013
*        THE SAME LEAVE THE STORE ALONE, OTHERWISE SAVE CURRENT REFER-  46440013
*        ENCE                                                           46480013
         SPACE                                                          46520013
CESTTS   CLC   OLDSTR+2(2,GRDIC),CEZERO     IS OLD STORE EMPTY          46560013
         BC    CEBE,CEADSV             YES                              46600013
         CLC   OLDLVL(1),CELVLX        NO, SO ARE BLOCK COUNT  DIFFER-  46640013
         BC    CEBNE,CEPOST            ENT, NO SO BRANCH OUT AT END     46680013
CEADSV   MVC   OLDSYM(2),CELSYM(GR12)  SAVE SYMBOLIC ADDRESS AND        46720013
         MVC   OLDLVL(1),CELVLX        BLOCK COUNT                      46760013
         SPACE 2                                                        46800013
*              NOW THAT A VALID REFERENCE HAS BEEN FOUND SCAN DOWN THE  46840013
*        CHAIN WITHIN THE STRUCTURE MATCHING ITS BCD WITH THE TEXT      46880013
         SPACE                                                          46920013
         L     GR2,STKCNT              PICK UP STACK COUNT              46960013
         L     GR1,CESTKA              PICK UP START OF STACK           47000013
         MVC   CESTSM(2),CEFRSM        SAVE SYMBOLIC ADDRESS OF BCD     47040013
*                                      ENTRY                            47080013
         SPACE                                                          47120013
*              GET ADDRESS OF CONTAINING STRUCTURE, SEE IF THIS IS END  47160013
*        OF STACK. IF SO, THIS STRUCTURE SCAN IS OVER. IF NOT, REDUCE   47200013
*        STACK COUNT AND LOOK AT NEXT BCD ELEMENT IN TEXT               47240013
CESTSC   BAL   GR4,CESTUC              GO TO GET ADDRESS OF CONTAINING  47280013
*                                      STRUCTURE                        47320013
         LTR   GR2,GR2                 IS STACK COUNT ZERO              47360013
         BC    CEBZ,CEPMST             YES, SO BRANCH OUT               47400013
         S     GR2,CE4                 REDUCE STACK COUNT BY 4          47440013
         SPACE                                                          47480013
*              IF THE ADDRESS OF THE CONTAINING STRUCTURE IS ZERO THEN  47520013
*        WE ARE ALREADY AT END OF THIS STRUCTURE AND AS THE END OF TEXT 47560013
*        HAS NOT BEEN REACHED WE HAD BETTER TRY AGAIN                   47600013
         SPACE                                                          47640013
CECSTS   CLC   PAR1+2(2,GRDIC),CEZERO  IS CONTAINING STRUC ADDR ZERO    47680013
         BC    CEBE,CEPKUP             YES, SO CONTINUE SCAN            47720013
         L     GR15,ZDRFAB(0,GR11)     CONVERT DICTIONARY REFERENCE TO  47800013
         BALR  GR14,GR15               ABSOLUTE                         47840013
         L     GR3,PAR1(0,GRDIC)       AND POINT GR3 AT IT              47880013
         CLI   0(GR3),X'C8'            IS THIS AN INVALID ENTRY   18910 47890017
         BC    CEBE,CEPKUP           BRANCH ON YES.               18910 47900017
         L     GR7,0(GR2,GR1)          PICK UP NEXT TEXT ADDRESS. 18910 47910017
         TM    0(GR3),CENOBC           HAS THIS ANY BCD                 47920013
         BC    CEBO,CEFPHO             NO, SO GO TO FP ENTRY            47960013
         SPACE                                                          48000013
*              WE ARE NOW LOOKING AT NEXT STRUCTURE OR ITS FORMAL PARA- 48040013
*        METER ENTRY. NOW TEST BCD FOR AGREEMENT. IF AGREEMENT OCCURS   48080013
*        CONTINUE SCAN,IF NOT THEN REFERENCE IS NOT CONTINUOUS SO WE    48120013
*        SET FLAG ON AND CONTINUE TO SCAN STRUCTURE TO FIND AN AGREEING 48160013
*        BCD                                                            48200013
         SPACE                                                          48240013
CEBCDC   XR    GR14,GR14               CLEAR GR14                       48280013
         IC    GR14,0(0,GR7)           PICK UP BCD LENGTH               48320013
         BCTR  GR14,0                                                   48360013
         STM   GR1,GR2,CEDMP1          SAVE REGISTERS GR1 AND GR2       48400013
         BAL   GR15,CE3XX              GO TO COMPARE BCD'S              48440013
         BC    CEBR,CESTSX             AGREEMENT SO CONTINUE SCAN       48480013
         OI    CEFLOG,NONCON           NO AGREEMENT SO SET NOT CONTIN-  48520013
*                                      UOUS FLAG ON                     48560013
         LM    GR1,GR2,CEDMP1          RESTORE GR1 AND GR2              48600013
         BAL   GR4,CESTUC              GET NEXT STRUCTURE MEMBER IN     48640013
         BC    CEBR,CECSTS                                              48680013
CESTSX   LM    GR1,GR2,CEDMP1          RESTORE REGISTERS GR1,GR2        48720013
         BC    CEBR,CESTSC             CHAIN AND TRY AGAIN              48760013
         SPACE 2                                                        48800013
*              END(START) OF TEXT HAS BEEN REACHED SO SEE IF THIS IS    48840013
*        ALSO THE END(START) OF THE STRUCTURE. IF IT IS NOT WE SET      48880013
*        MINSTR FLAG ON.                                                48920013
         SPACE                                                          48960013
CEPMST   CLC   PAR1+2(2,GRDIC),CEZERO  IS THIS A MAJOR STRUCTURE        49000013
         BC    CEBE,CEOSTS             YES, SO SKIP NEXT INSTRUCTION    49040013
         OI    CEFLOG,MINSTR           NO, SO SET FLAG ON               49080013
         SPACE 2                                                        49120013
*              IF THERE IS NO DICTIONARY REFERENCE IN STORE THEN WE     49160013
*        MUST SAVE THIS ONE AND THE FLAGS                               49200013
         SPACE                                                          49240013
CEOSTS   CLC   OLDSTR+2(2,GRDIC),CEZERO IS OLD STORE ZERO               49280013
         BC    CEBNE,OLDFTS            NO, SO GO TO CARRY OUT MORE TEST 49320013
         SPACE                                                          49360013
*              SAVE THIS DICTIONARY REFERENCE AND ASSOCIATED FLAGS AND  49400013
*        TURN AMBIGUOUS FLAG OFF                                        49440013
         SPACE                                                          49480013
CESVLE   MVC   OLDSTR+2(2,GRDIC),OLDSYM UPDATE OLD STORE                49520013
         MVC   OLDFLG(1),CEFLOG        SAVE FLAGS                       49560013
         NI    CEFLAG,NOAMBG           TURN AMBIGUOUS FLAG OFF          49600013
         BC    CEBR,CEPKUP             AND TRY AGAIN.                   49640013
         SPACE                                                          49680013
*              NOW TEST THE NEW AND OLD FLAGSTO SEE IF THIS             49720013
*        IS A VALID ENTRY AN INVALID ENTRY OR AN AMBIGUOUS ENTRY        49760013
         SPACE                                                          49800013
OLDFTS   TM    OLDFLG,NONMIN           ARE BOTH OLD FLAGS OFF           49840013
         BC    CEBNZ,CEBOFF            NO, SO BRANCH                    49880013
         TM    CEFLOG,NONMIN           YES, SO ARE BOTH NEW FLAGS OFF   49920013
         BC    CEBNZ,CEPKUP            NO, SO CONTINUE SCAN. YES THEN   49960013
*                                      IT IS AN AMBIGUOUS ENTRY         50000013
         SPACE 2                                                        50040013
*              FOR AN AMBIGUOUS ENTRY TURN FLAG ON AND TRY AGAIN        50080013
         SPACE                                                          50120013
CEAMBG   OI    CEFLAG,AMBFLG           SET AMBIGUOUS FLAG ON            50160013
         BC    CEBR,CEPKUP                                              50200013
         SPACE 2                                                        50240013
*              OLD STORE WAS NOT EMPTY SO TEST THE OLD AND CURRENT FLAG 50280013
*        TO SEE WHICH IS THE BETTER ENTRY OR IF THERE IS AMBIGUITY.     50320013
*              BOTH OLD FLAGS WERE NOT OFF SO IF BOTH NEW FLAGS ARE OFF 50360013
*        THEN THIS IS THE REFERENCE TO SAVE                             50400013
         SPACE                                                          50440013
CEBOFF   TM    OLDFLG,NONMIN           ARE BOTH OLD FLAGS ON            50480013
         BC    CEBO,CEBTON             YES, SO GO TO TEST NEW FLAGS     50520013
         TM    CEFLOG,NONMIN           NO, SO ARE BOTH NEW FLAGS OFF    50560013
         BC    CEBZ,CESVLE             YES, SO SAVE THIS ENTRY          50600013
         BC    CEBR,CEAMBG                                              50640013
         SPACE                                                          50680013
*              BOTH OLD FLAGS WERE ON, SO UNLESS BOTH NEW FLAGS ARE OFF 50720013
*        THIS IS AN AMBIGUOUS REFERENCE                                 50760013
         SPACE                                                          50800013
CEBTON   TM    CEFLOG,NONMIN           ARE BOTH NEW FLAGS OFF           50840013
         BC    CEBZ,CESVLE             YES, SO SAVE ADDRESS             50880013
         BC    CEBR,CEAMBG             NO, SO THIS IS AMBIGUOUS         50920013
         SPACE 2                                                        50960013
*              HASH CHAIN SLOT WAS EMPTY SO THIS IS END OF THE SEARCH   51000013
*        NOW SEARCH STORES ETC TO SEE IF ENTRY HAS BEEN FOUND. IF NON   51040013
*        HAS BEEN FOUND FOR A QUALIFIED NAME OR ONLY AN AMBIGUOUS       51080013
*        REFERENCE THEN THIS IS AN ERROR. IF NON HAS BEEN FOUND FOR A   51120013
*        NON-QUALIFIED NAME THEN A DEFAULT DATA DICTIONARY ENTRY MUST   51160013
*        BE MADE                                                        51200013
         SPACE 2                                                        51240013
CEC31X   LA    GR2,3(0,GR3)            SET GR2 3 BYTES BEFORE ENTRY     51280013
CEC31    TM    CEFLAG,NONQUL           IS NON QUALIFIED FLAG ON         51320013
         BC    CEBZ,CEPOST             NO, SO TEST REST OF FLAGS        51360013
         CLC   OLDSTR+2(2,GRDIC),CEZERO YES, SO IS STORE EMPTY          51400013
         BC    CEBE,CENWNT             YES, SO NEW ENTRY IS NEEDED      51440013
CEPOST   TM    CEFLAG,AMBFLG           IS AMBIGUOUS FLAG ON             51480013
         BC    CEBO,CERR3              YES, SO GO TO GIVE ERROR MESSAGE 51520013
         CLC   OLDSTR+2(2,GRDIC),CEZERO  IS STORE EMPTY                 51560013
         BC    CEBNE,CEFIN1            NO, SO GO TO PUT DICTIONARY REF- 51600013
*                                      ERENCE INTO TEXT                 51640013
         BC    CEBR,CERR4              YES, SO ITS AN ERROR             51680013
         SPACE                                                          51720013
*              NEW DICTIONARY ENTRY NEEDED SO SET UP PARAMETERS TO MAKE 51760013
*              IT                                                       51800013
         SPACE                                                          51840013
CENWNT   XC    CADD1(4,GR12),CADD1(GR12) CLEAR CADD1                    51880013
         S     GR2,CE3                 REDUCE POINTER BY 3              51920013
         ST    GR2,CADD2(0,GR12)       AND STORE                        51960013
         A     GR2,CE3                 RESTORE POINTER                  52000013
         BAL   GR2,CEPFDR              GO TO MAKE DICTIONARY ENTRY      52040013
         BC    CEBR,CEFIN1                                              52080013
         SPACE 2                                                        52120013
*              ROUTINE TO PICK UP ADDRESS OF CONTAINING STRUCTURE. ON   52160013
*        RETURN THE SYMBOLIC ADDRESS IS IN PAR1                         52200013
         SPACE                                                          52240013
CESTUC   MVC   PAR1+2(2,GRDIC),CESTSM  PICK UP SYMBOLIC ADDR OF STRUCT  52280013
         L     GR15,ZDRFAB(0,GR11)     -TURE AND CONVERT TO ABSOLUTE    52320013
         BALR  GR14,GR15                                                52360013
         L     GR15,PAR1(0,GRDIC)      GR15 POINTS AT START OF STRUCT   52400013
         LR    GR5,GR15                SET GR5 TO START OF STRUCTURE    52440013
         TM    0(GR15),CEBASE          IS THIS A BASE ELEMENT           52480013
         BC    CEBNO,CEDIMQ            NO, SO SKIP NEXT INSTRUCTION     52520013
         LA    GR5,CEBEPL(0,GR5)       YES, SO BUMP COUNT BY ADDITIONAL 52560013
*                                      NUMBER OF BYTES                  52600013
         SPACE                                                          52640013
*              CALCULATE TOTAL OFFSET OF STRUCTURE INFORMATION FROM     52680013
*        START OF VARIABLE INFORMATION IN A STRUCTURE MEMBER            52720013
         SPACE                                                          52760013
CEDIMQ   TM    0(GR15),CEDIMS          IS THIS A DIMENSIONED STRUCTURE  52800013
         BC    CEBZ,CENOUN             NO, SO SKIP NEXT INSTRUCTION     52840013
         LA    GR5,CEDIMZ(0,GR5)       YES, SO BUMP BY DIM INFO LENGTH  52880013
CENOUN   MVC   PAR1+2(2,GRDIC),CEVARN+CECNSR(GR5) MOVE ADDRESS OF CON-  52920013
         MVC   CESTSM(2),PAR1+2(GRDIC) TAINING STRUCTURE INTO PAR1 AND  52960013
*                                      STORE                            53000013
         BCR   CEBR,GR4                AND RETURN                       53040013
         SPACE 2                                                        53080013
*              ENTRY HAS NO BCD ATTACHED SO GO BACK TO FORMAL PARAMETER 53120013
*        ENTRY TO COMPARE THE BCD.                                      53160013
         SPACE                                                          53200013
CEFPHO   MVC   PAR1+2(2,GRDIC),CEFPCH(GR3) PICK UP POINTER TO FP ENTRY  53240013
         L     GR15,ZDRFAB(0,GR11)     CONVERT                          53280013
         BALR  GR14,GR15               TO ABSOLUTE                      53320013
         L     GR3,PAR1(0,GRDIC)       AND POINT GR3 AT ENTRY           53360013
         BC    CEBR,CEBCDC                                              53400013
         SPACE 2                                                        53440013
*              THIS IS A SUCCESSFUL REFERENCE AND THIS IS A NON-QUALIF- 53480013
*        IED NAME SO IF THIS DICTIONARY REFERENCE IS NOT A STRUCTURE WE 53520013
*        ARE CORRECT                                                    53560013
         SPACE                                                          53600013
CENRND   TM    0(GR3),X'2E'          WE TEST                            53610015
         BC    CEBNO,STRTST          FOR MAJOR STRUCTURE                53620015
         TM    CEOTH4(GR3),X'04'     TEST FOR MAJOR STRUCTURE           53630015
         BC    CEBO,STOTST           BRANCH IF SO                       53640015
         BC    B,CESTTS                                                 53650015
STRTST   TM    0(GR3),CESTRD                                            53660015
         BC    CEBO,CESTTS             YES SO TRY ONCE MORE             53680013
STOTST   EQU   *                                                        53700015
         CLC   OLDSTR+2(2,GRDIC),CEZERO IS STORE EMPTY                  53720013
         BC    CEBNE,CEPOST            NO, SO BRANCH TO TEST ENTRY      53760013
         MVC   OLDSTR+2(2,GRDIC),CELSYM(GR12)  SAVE DICTIONARY REF      53800013
         SPACE 2                                                        53840013
*              FINISH OFF BY PUTTING ZERO BYTE AND REFERENCE INTO TEXT  53880013
*        BUMPING SCAN POINTER TO END OF VARIABLE AND RETURNING          53920013
         SPACE                                                          53960013
CEFIN1   MVI   0(GR6),X'00'            MOVE IN ZERO BYTE TO OUTPUT AREA 54000013
         SPACE 2                                                        54040013
CEFIN    MVC   1(2,GR6),CECTST+2(GRDIC)     GO TO CONVERT IT TO DICT R  54080013
         MVC   PAR1+2(2,GRDIC),OLDSTR+2(GRDIC)   CONVERT TO             54120013
         L     GR15,ZDRFAB(0,GR11)     ABSOLUTE                         54160013
         BALR  GR14,GR15                                                54200013
         L     GR3,PAR1(0,GRDIC)       AND POINT GR3 AT ENTRY           54240013
         L     GR7,ENDADR              SET GR7 TO END OF BCD            54280013
*                                      CEADD WHERE CECONV LEFT IT.      54320013
         LA    GR6,3(0,GR6)            BUMP OUTPUT TEXT POINTER BY 3    54360013
         BAL   GR14,CENDTS              GO TO END TEST                  54400013
         CLC   CECTST+2(2,GRDIC),CEDUMD+1   IS THIS A DUMMY REF         54440013
         BC    CEBE,CERENT             YES SO THERE IS NOTHING TO TEST  54480013
*                                                                       54520013
*                       TEST ENTRY TO SEE IF THIS MIGHT HAVE TO BE      54560013
*        FOLLOWED BY A FUNCTION MARKER IF THIS IS A FUNCTION WITH NO    54600013
*        ARGUMENTS                                                      54640013
         SPACE                                                          54680013
         CLI   0(GR3),CBLTGN           IS THIS WITHIN RANGE OF FUNCTION 54720013
         BC    CEBH,CERNT              NO, SO GO AND RETURN             54760013
         CLI   0(GR3),CSTLBL           YES, BUT IS IT STILL NOT ONE     54800013
         BC    CEBE,CERENT             YES,IT IS NOT A FUNCTION         54840013
         CLI   CEKYST(GRDIC),CEGOTO    IS THIS GO TO                    54880013
         BC    CEBNE,CELXTS            BRANCH IF NOT                    54890015
         CLC   CEBCT(4),CEZERO         IS BRACKET COUNT ZERO            54900015
         BC    CEBE,CERENT             YES, SO RETURN                   54920013
*                                                                       54960013
CELXTS   CLI   1(GR7),CELPAR           IS NEXT TEXT ITEM (              55000013
         BC    CEBE,CERENT             YES, SO SKIP NEXT INSTRUCTIONS   55040013
         SPACE                                                          55080013
         OI    FLAG,FUNC               SET FLAG TO SAY THAT A FUNCTION  55120013
*                                    HAS BEEN DETECTED WITHIN THE       55160013
*                                    COMPILATION.                       55200013
*                                                                       55240013
         CLI   CEFFLG(GRDIC),X'FF'     IS F FLAG ON                     55280013
         BC    CEBE,CEPSVR             YES SO TREAT FOR PSEUDO-VAR      55320013
         SPACE                                                          55360013
*                       A FUNCTION MARKER HAS TO BE INSERTED, SO DO SO  55400013
         SPACE                                                          55440013
CEUPMV   MVI   0(GR6),CEUPAR           STORE UPWARD ARROW IN TEXT       55480013
CEBMPT   LA    GR6,1(0,GR6)            BUMP OUTPUT POINTER              55520013
         SPACE                                                          55560013
*                       NOW RESTORE REGISTERS AND RETURN                55600013
         SPACE                                                          55640013
CERENT   LM    GR14,GR5,CEDUMP         RESTORE REGISTERS                55680013
         BCR   CEBR,GR2                RETURN                           55720013
         SPACE 2                                                        55760013
*                       IT IS NOT A FUNCTION BUT MAY STILL NEED THE     55800013
*        MARKER AFTER IT.                                               55840013
         SPACE                                                          55880013
CERNT    CLI   0(GR3),CENTP5           IS THIS ENTRY TYPE 5             55920013
         BC    CEBNE,CERENT            NO, SO GO TO NORMAL END          55960013
         BC    CEBR,CELXTS                                              56000013
         SPACE 2                                                        56040013
*                       COULD THIS BE A PSEUDO-VARIABLE BECAUSE IF IT   56080013
*        IS IT NEEDS A DIFFERENT MARKER                                 56120013
         SPACE                                                          56160013
CEPSVR   CLC   CEZERO(4),CEBCT         IS BRACKET COUNT ZERO. IF NOT,   56200013
         BC    BE,CPSVR1             CHECK WHETHER WE ARE IN THE        56240013
         CLI   SETS,X'FF'            SPECIAL CASE OF                    56260001
*                                    (PUT) STRING, KEYTO,               56280001
         MVI   SETS,0                OR REPLY OPTIONS. IF NOT, TREAT    56320013
         BC    CEBNE,CEUPMV          AS FUNCTION.                       56360013
CPSVR1   CLI   0(GR3),CEXETP           IS THIS A BUILT-IN OR GENERIC    56400013
         BC    CEBNH,CEFNWR            FUNCTION. IF NOT IT IS AN ERROR  56440013
         TM    CEBIF2(GR3),X'10'       YES, SO IS THIS A POSSIBLE       56480013
         BC    CEBNO,CEFNWR            PSEUDO-VARIABLE. NO,SO BRANCH    56520013
         CLI   CEBIF1(GR3),X'89'       IS THIS PRIORITY P.V.     H441   56523020
         BNE   TASKOK                  NO - SO NO ACTION         H441   56526020
         MVC   PAR1+2(2,GRDIC),ZPROC1+2(GRDIC)  D.R. OF          H441   56530020
         L     GR15,ZDRFAB(0,GR11)     (EXTERNAL) PROC           H441   56535020
         BALR  GR14,GR15               CONVERT TO ABSOLUTE       H441   56538020
         L     GR5,PAR1(GRDIC)         PICK UP ADDR                     56541020
         TM    OPTBT(GR5),X'10'        IS TASK OPTION ON         H441   56544020
         BNO   NONTASK                 NO ERROR                         56547020
TASKOK   EQU    *                                                       56550020
         MVI   0(GR6),CEANCH           YES, MOVE IN PSEUDO VARIABLE     56560013
         BC    CEBR,CEBMPT             MARKER AND BRANCH                56600013
         SPACE                                                          56640013
*                       ERRONEOUS USE OF FUNCTION SO GIVE ERROR AND     56680013
*                       REPLACE DICT REF BY DUMMY                       56720013
         SPACE                                                          56760013
NONTASK  BAL   GR2,CERR16              PRITITY P.V. ON NON-TASK  H441   56780020
         B     *+8                     ENVIRONMENT               H441   56800020
CEFNWR   BAL   GR2,CERR15              GOTO ERROR ROUTINE               56820020
         S     GR6,CE3                 BACKSPACE POINTER TO START OF    56840013
         MVC   0(3,GR6),CEDUMD         DICT REF AND REPLACE BY DUMMY    56880013
         A     GR6,CE3                 RESTORE POINTER                  56920013
         BC    CEBR,CERENT             AND GET OUT                      56960013
         EJECT                                                          57000013
         SPACE 2                                                        57040013
*              PICK UP START OF TEXT ETC AND TRY SCAN AGAIN. IF HASH    57080013
*        CHAIN IS ZERO THEN WE HAVE FINISHED                            57120013
         SPACE                                                          57160013
CEPKUP   MVC   PAR1+2(2,GRDIC),CEFRSM  PICK UP DICTIONARY REFERENCE OF  57200013
         L     GR15,ZDRFAB(0,GR11)     ENTRY WITH BCD                   57240013
         BALR  GR14,GR15               CONVERT TO ABSOLUTE AND POINT    57280013
         L     GR3,PAR1(0,GRDIC)       GR2 AT IT                        57320013
CE22     CLC   3(2,GR3),CEZERO         IS HASH CHAIN ZERO               57360013
         BC    CEBE,CEC31X             YES, SO END SCAN                 57400013
         SPACE                                                          57440013
*              HASH CHAIN HAS ENTRY SO SET UP POINTERS ETC FOR NEXT TRY 57480013
         SPACE                                                          57520013
         MVC   CELSYM(2,GR12),3(GR3)   IN HASH CHAIN                    57560013
         MVC   PAR1+2(2,GRDIC),3(GR3)  PICK UP ADDRESS OF NEXT ENTRY    57600013
         MVC   ZLOCK(2,GRDIC),3(GR3)    LOCK NEXT ENTRY ON HASH CH57444 57620072
         L     GR15,ZDRFAB(0,GR11)     CONVERT TO ABSOLUTE              57640013
         BALR  GR14,GR15                                                57680013
         L     GR2,STKCNT              PICK UP STACK COUNT              57720013
         L     GR4,CEKSTA              PICK UP START OF STACK           57760013
         L     GR7,0(GR2,GR4)          AND POINT GR7 AT START OF TEXT   57800013
         XR    GR14,GR14               CLEAR GR14                       57840013
         IC    GR14,0(0,GR7)           PICK UP BCD LENGTH               57880013
         BCTR  GR14,0                  REDUCE BY ONE                    57920013
         MVI   CEFLOG,X'00'            CLEAR FLAGS AND TRY AGAIN        57960013
         BC    CEBR,CE3AX              GO TO COMPARE BCD ETC.           58000013
         EJECT                                                          58040013
*                       ROUTINE CHASH                                   58080013
*                                                                       58120013
*              FUNCTION/OPERATION.  THIS ROUTINE DERIVES A FUNCTION     58160013
*        FROM THE BCD PASSED TO IT.  THE FUNCTION IS LESS THAN 422      58200013
*        AND IS EVEN. IT IS TO BE USED AS AN OFFSET IN THE HASH TABLE   58240013
*        GIVING THE HEAD OF THE HASH CHAIN LINKING BCD'S WITH THE SAME  58280013
*        HASH FUNCTION.                                                 58320013
*                                   THE FUNCTION IS OBTAINED BY EXTEND- 58360013
*        ING THE BCD WITH ZEROES UNTIL A MULTIPLE OF 4 BYTES LONG, THEN 58400013
*        ADDING 4 BYTE LENGTHS.  THE SUM IS DIVIDED BY 211.  THE        58440013
*        REMAINDER IS SET POSITIVE AND DOUBLED TO GIVE THE HASH RESULT  58480013
*        WHICH IS RETURNED.                                             58520013
*                                  THE CALLING SEQUENCE IS -            58560013
*        BAL   GRRZ,CHASH   (SEE NOTES)                                 58600013
*                                  THE ROUTINE IS ENTERED WITH -        58640013
*              (1) GRPTR POINTER TO BCD TO BE HASHED.                   58680013
*              (2) GRLTH CONTAINING LENGTH-1 OF THE BCD                 58720013
*              THESE REGISTERS ARE RETURNED UNALTERED.                  58760013
*                                                                       58800013
*              EXTERNAL ROUTINES - NONE.                                58840013
*                                                                       58880013
*              EXITS NORMAL - UNCONDITIONAL BRANCH ON RETURN REGISTER.  58920013
*                                                                       58960013
*              EXITS ERROR - NONE                                       59000013
*                                                                       59040013
*              TABLES/WORK AREAS.  A WORKSPACE CASPAC 32 BYTES LONG,    59080013
*        AND FULL WORD ALIGNED IS REQUIRED. THE BCD IS MOVED INTO IT    59120013
*        FOR FULL WORD ALIGNMENT AND FOR EXTENDING WITH ZEROES          59160013
*                                  A FULL WORD CONSTANT T11, VALUE 211, 59200013
*        IS ALSO REQUIRED.                                              59240013
*                                                                       59280013
*              NOTES.  THE RETURN REGISTER MUST BE SET UP BY A 'BRANCH  59320013
*        AND LINK' INSTRUCTION, SINCE THE PROGRAM MASK IS REQUIRED IN   59360013
*        THE TOP BYTE.                                                  59400013
*                      REGISTERS GRP, AND GRQ ARE REQUIRED FOR WORKING  59440013
*        AND THEIR ORIGIONAL CONTENTS ARE LOST.                         59480013
*                      REGISTERS GRP,GRQ AND GRLTH,GRHASH ARE REQUIRED  59520013
*        TO BE EVEN ODD REGISTER PAIRS.                                 59560013
         SPACE 5                                                        59600013
CHASH    SR    GRQ,GRQ                                                  59640013
         SPM   GRQ                     INHIBIT FIXED POINT OVERFLOW     59680013
*                                    INTERRUPTS DURING LOOP 'CARED'     59720013
*                                    BELOW.                             59760013
         LA    GRHASH,4                FOUR REQUIRED IN GRHASH, NOW AND 59800013
         LCR   GRP,GRHASH            LATER. SET GRP TO ONES IN ALL BITS 59840013
*                                    EXCEPT THE LAST TWO.               59880013
         NR    GRP,GRLTH               LENGTH-1 LESS LAST TWO BITS INTO 59920013
*                                      GRP                              59960013
         ST    GRQ,CASPAC(GRP)         CLEAR FOUR BYTES IN CASPAC AT    60000013
*                                    OFFSET EQUAL TO FIRST FULL WORD    60040013
*                                    SHORT OF END OF BCD WHEN IT IS     60080013
*                                    MOVED INTO CASPAC.                 60120013
         EX    GRLTH,CAH1              MOVE BCD INTO CASPAC.            60160013
         SPACE                                                          60200013
*              THE BCD IS NOW IN CASPAC AND IS EXTENDED TO A FULL WORD  60240013
*        BOUNDARY WITH ZEROS.                                           60280013
         SPACE                                                          60320013
         SR    GRP,GRP                                                  60360013
CARED    A     GRQ,CASPAC(GRP)         THIS LOOP ADDS FOUR BYTE LENGTHS 60400013
         BXLE  GRP,GRHASH,CARED      OF THE BCD INTO GRY UNTIL ALL IS   60440013
*                                    CONSUMED                           60480013
         SPACE                                                          60520013
         SR    GRP,GRP                                                  60560013
         D     GRP,T11                 DIVIDE SUM BY 211                60600013
         SPACE                                                          60640013
         LPR   GRHASH,GRP              SET REMAINDER POSITIVE           60680013
         AR    GRHASH,GRHASH           DOUBLE IT.                       60720013
         SPACE                                                          60760013
         SPM   GRRZ                    RESET PROGRAM MASK               60800013
         BCR   B,GRRZ                  RETURN                           60840013
         SPACE                                                          60880013
CAH1     MVC   CASPAC(0),0(GRPTR)      MOVE IN BCD                      60920013
         EJECT                                                          60960013
         SPACE                                                          61000013
*                       ROUTINES FOR GENERATING ERROR MESSAGES          61040013
         SPACE                                                          61080013
CERR4    MVI   CERRC,X'8F'             MOVE IN CODE BYTE                61120013
         BC    CEBR,CERR                                                61160013
         SPACE                                                          61200013
*              PUT OUT ERROR MESSAGE PUT DUMMY REFERENCE INTO STORE     61240013
         SPACE                                                          61280013
CERR3    MVI   CERRC,X'92'             MOVE IN ERROR CODE               61320013
         BC    CEBR,CERR                                                61360013
         SPACE                                                          61400013
CERR     L     GR7,TXTSTR              POINT GR7 AT START OF TEXT       61440013
         XR    GR4,GR4                 PICK UP BCD LENGTH               61480013
         IC    GR4,0(0,GR7)            IN GRX                           61520013
         LA    GR7,1(0,GR7)            GR7 POINTS AT START OF BCD IN    61560013
         ST    GR7,PAR7(0,GRDIC)       TEXT STORE FOR ERROR MESSAGES    61600013
         ST    GR4,PAR8(0,GRDIC)       STORE BCD LENGTH                 61640013
         MVC   PAR6+1(3,GRDIC),CERR1C  SET UP ERROR CODE                61680013
         L     GR15,ZERROF(0,GR11)     CALL ERROR MESSAGE               61720013
         BALR  GR14,GR15               GENERATOR                        61760013
         MVC   OLDSTR+2(2,GRDIC),CEDUMD+1   PUT DUMMY REF IN STORE      61800013
         BC    CEBR,CEFIN1             AND GO TO FINISH OFF             61840013
         SPACE 2                                                        61880013
         SPACE 2                                                        61920013
*********************************************************************** 61960013
CERR27   MVC   PAR6+1(3,GR3),CER27M    MOVE IN CODE BYEE                62000013
         L     GR15,ZERROF(0,GR11)      ALL UP ERROR ROUTINE            62040013
         BALR  GR14,GR15                                                62080013
         L     GR15,ZABORT(0,GR11)     CALL ZABORT                      62120013
         BALR  GR14,GR15                                                62160013
         SPACE 2                                                        62200013
CER68P   MVC   PAR6+1(3,GRDIC),CER68M  MOVE IN CODE BYTES               62240013
         L     GR5,ZERROF(0,GR11)      GO TO                            62280013
         BALR  GR14,GR5                ERROR                            62320013
         BCR   CEBR,GR4                ROUTINE                          62360013
         SPACE                                                          62400013
CERR1C   DC    X'02'                                                    62440013
CERRC    DC    X'00'                                                    62480013
CERRX    DC    X'C4'                                                    62520013
CER27M   DC    X'02'                                                    62560013
         DC    X'8D'                                                    62600013
         DC    X'40'                                                    62640013
CER68M   DC    X'02'                                                    62680013
CER68X   DC    X'A5'                                                    62720013
         DC    X'44'                                                    62760013
         EJECT                                                          62800013
*              FUNCTION/OPERATION                                       62840013
         SPACE 3                                                        62880013
*                       THIS ROUTINE PICKS UP THE KEYWORD STORED IN     62920013
*        CEKYST AND PERFORMS THE NECESSARY ALTERATIONS IF THE KEYWORD   62960013
*        IS ONE OF A SPECIAL GROUP.                                     63000013
*                       GR7 IS POINTING AT THE KEYWORD IN THE TEXT      63040013
*                       GR6 IS POINTING AT THE NEXT VACANT TEXT SLOT    63080013
*        THE KEYWORD ROUTINE IS ENCOUNTERED ANYTIME THAT A KEYWORD IS   63120013
*        FOUND IN THE TEXT. IT TESTS WHETHER IT IS ONE OF THE KEYWORDS  63160013
*        THAT REQUIRES SPECIAL ACTION TO BE TAKEN. IF IT IS THEN        63200013
*        CONTROL IS PASSED TO THE RELEVANT SUBSECTION. IF NOT CONTROL   63240013
*        IS RETURNED TO THE GENERAL SCAN ROUTINE                        63280013
*                       CEKYST CONTAINS THE 1-BYTE CODED KEYWORD ON     63320013
*        ENTRY          GR7 POINTS AT CURRENT BYTE IN TEXT              63360013
*                       GR6 POINTS AT NEXT AVAILABLE SLOT IN OUTPUT     63400013
*                                                                       63440013
*                                                                       63480013
*                                                                       63520013
*                       PICK UP THE KEYWORD AND TRANSFER                63560013
*                       TO THE APPROPRIATE SECTION                      63600013
         SPACE 3                                                        63640013
*              ENTRY POINT                                              63680013
*                       CEKYWD    CALLED BY      BAL   GR2,CEKYWD.      63720013
         SPACE 3                                                        63760013
*              INPUT                                                    63800013
*              GR6 POINTS AT NEXT AVAILABLE BYTE IN OUTPUT AREA         63840013
*              GR7 POINTS AT THE 1-BYTE CODED KEYWORD.                  63880013
         SPACE 3                                                        63920013
*              OUTPUT                                                   63960013
*              DEPENDS ON KEYWORD UNDER CONSIDERATION.                  64000013
         SPACE 3                                                        64040013
*              EXTERNAL ROUTINES       N/A                              64080013
         SPACE 3                                                        64120013
*              WORK AREA               N/A                              64160013
         SPACE 3                                                        64200013
*              NOTES                                                    64240013
*              REGISTER USAGE ETC DEPENDS ON KEYWORD.                   64280013
         SPACE 3                                                        64320013
         SPACE                                                          64360013
CEKYWD   MVC   CEBYTE(1),CEKYST(GRDIC)      MOVE& NHWORD                64400013
         TR    CEBYTE(1),CEKRAN-128    AND TRANSLATE IT TO AN OFFSET    64440013
         XR    GR1,GR1                 PICK UP THE OFFSET               64480013
         IC    GR1,CEBYTE              AND EXECUTE THE RELEVANT BRANCH  64520013
         EX    0,CEKTRB(GR1)           INSTRUCTION                      64560013
         EJECT                                                          64600013
*                       PROCEDURE IS KEYWORD FOUND, SO UPDATE LEVEL     64640013
*                       POINTERS AND STACK AND SKIP TO SEMI-COLON       64680013
         SPACE 2                                                        64720013
CEKPRC   MVC   CECNTB(1),1(GR7)        UICT ENTRY AND PICK UP THE BLOCK 64760013
         MVC   CECNTC(1),2(GR7)        AND LEVEL COUNT                  64800013
         MVC   CECURL(1),CECNTC        UPDATE CURRENT COUNT SLOT        64840013
         LA    GR7,2(0,GR7)            BUMP SCAN POINTER                64880013
         BCR   CEBR,GR2                RETURN                           64920013
         SPACE 2                                                        64960013
*                       ROUTINE FOR END ITERATIVE DO                    65000013
*        PICK UP LEVEL AND COUNT OF BLOCK INTO WHICH THE SCAN IS        65040013
*        DESCENDING                                                     65080013
         SPACE 2                                                        65120013
CEKEDO   MVC   CECNTC(1),2(GR7)        CHANGE BLOCK COUNT               65160013
        MVC   CECURL(1),CECNTC        UPDATE THE CURRENT COUNT SLOT     65200013
CEENDO   LA    GR7,2(0,GR7)            BUMP POINTERS OVER COUNTS        65240013
         BCR   CEBR,GR2                                                 65280013
         SPACE 2                                                        65320013
*              ROUTINE FOR ASSIGNMENT JUST SETS FFLAG ON                65360013
         SPACE 2                                                        65400013
CEKASN   MVI   CEFFLG(GRDIC),X'FF'     SET FFLAG ON                     65440013
         BCR   CEBR,GR2                RETURN                           65480013
         EJECT                                                          65520013
         SPACE 3                                                        65560013
*        THIS IS THE ROUTINE FOR SN CN                                  65600013
*        IT PICKS UP THE CURRENT STATMENT NUMBER AND MOVES SN ETC TO    65640013
*        THE OUTPUT AREA                                                65680013
         SPACE 2                                                        65720013
CEKSN    MVC   CESTNM+2(2,GRDIC),1(GR7)     MOVE REST OF STATEMENT TO   65760013
CEKSLN   MVC   1(CESNLN,GR6),1(GR7)    PICKING UP STATEMENT NUMBER.     65800013
         ST    GR6,CESTNL              SAVE OUTPUT POINTER              65840013
         LA    GR6,CESNLN(0,GR6)       BUMP POINTERS                    65880013
         LA    GR7,CESNLN(0,GR7)                                        65920013
         BCR   CEBR,GR2                                                 65960013
         SPACE 3                                                        66000013
*        THIS IS THE ROUTINE FOR SN'                                    66040013
*        PICK UP BLOCK LEVEL AND COUNT AND STATEMENT NUMBER FROM THE    66080013
*        ASSOCIATED DICTIONARY ENTRY.                                   66120013
         SPACE 2                                                        66160013
CEKSND   MVC   PAR1+2(2,GRDIC),1(GR7)  MOVE IN DICTIONARY REFERENCE     66200013
*********************************************************************** 66240013
         L     GR4,ZDRAOF(0,11)        AND GO OFF TO CONVERT IT TO      66280013
         BALR  GR14,GR4                                                 66320013
         L     GR5,PAR1(GRDIC)         LOAD GR5 WITH THE ABSOLUTE ADDRE 66360013
*********************************************************************** 66400013
         MVC   CECNTB(1),CESN2L(GR5)   PICK UP BLOCK COUNT              66440013
         MVC   CECNTC(1),CESN2C(GR5)   PICK UP BLOCK COUNT              66480013
         MVC   CECURL(1),CECNTC        UPDATE CURRENT LEVEL             66520013
         MVC   CESTNM+2(2,GRDIC),3(GR5)      PICK UP STATEMENT NUMBER   66560013
         BC    CEBR,CEKSLN                                              66600013
         SPACE 3                                                        66640013
*        TRANSFER POINT FOR SL OR CL                                    66680013
*        PICK UP STATEMENT NUMBER FROM DICTIONARY ENTRY FOR LABEL       66720013
         SPACE 2                                                        66760013
CEKSL    MVC   PAR1+2(2,GRDIC),1(GR7)  PICK UP DICT ADDRESS             66800013
*********************************************************************** 66840013
         L     GR4,ZDRAOF(0,11)        ADDRESS TO AN ABSOLUTE           66880013
         BALR  GR14,GR4                                                 66920013
         L     GR5,PAR1(GRDIC)         LOAD GR5 WITH THE ABSOLUTE ADDR  66960013
*********************************************************************** 67000013
         MVC   CESTNM+2(2,GRDIC),CESNSN(GR5)     MOVE STATEMENT NUMBER  67040013
         BC    CEBR,CEKSLN                                              67080013
         SPACE 3                                                        67120013
*        TRANSFER POINT FOR END. IT PICKS UP THE ADDRESS OF THE DICT    67160013
*        ENTRY FOR THE CONTAINING BLOCK AND PLACES THE 2-BYTE REFERENCE 67200013
*        AFTER UMBRELLA MARKER AND 00 BYTE IN TEXT                      67240013
         SPACE 2                                                        67280013
CEKEND   MVI   1(GR6),CEUMB            MOVE IN MARKER AND               67320013
         MVI   2(GR6),X'00'            ZERO BYTE TO TEXT                67360013
         MVC   CECNTB(1),1(GR7)        CHANGE BLOCK LEVEL               67400013
         MVC   3(2,GR6),1(GR7)         MOVE CONTAINING LEVELS TO TEXT   67440013
         LA    GR6,5(0,GR6)            BUMP POINTER                     67480013
         BAL   GR14,CENDTS             GO TO END TEST ROUTINE           67520013
         BCTR  GR6,0                                                    67560013
         BC    CEBR,CEKEDO             BRANCH TO REDUCE LEVEL COUNT     67600013
         EJECT                                                          67640013
         SPACE 2                                                        67680013
         SPACE 2                                                        67720013
*                        TRANSFER POINT FOR ON. THIS SIMPLY PUTS        67760013
*                       THE BLOCK AND LEVEL COUNT IN THE TEXT AFTER     67800013
*                       ON BYTE IN THE TEXT                             67840013
*                       IT IS ALSO THE TRANSFER POINT FOR SIGNAL,REVERT 67880013
         SPACE                                                          67920013
CEKON    MVC   1(3,GR6),1(GR7)         MOVE CONDITION L AND C TO OUTPUT 67960013
         MVC   CEONCD(1,GR12),1(GR7)   SAVE ON CONDITION                68000013
         LA    GR6,4(0,GR6)            BUMP                             68040013
         LA    GR7,4(0,GR7)            POINTERS                         68080013
         BAL   GR14,CENDTS             TEST FOR END OF BLOCK            68120013
         BC    CEBR,CE300                                               68160013
         SPACE 3                                                        68200013
*        THIS IS TRANSFER POINT FOR ITERATIVE DO                        68240013
         SPACE 2                                                        68280013
CEKIDO   MVC   1(1,GR6),1(GR7)         MOVE CV TO OUTPUT                68320013
         AR    GR6,GR15                BUMP                             68360013
CEKDO    LA    GR7,2(0,GR7)            POINTERS (SCAN OVER BLK NO)      68400013
CEKLDO   MVI   CEFFLG(GRDIC),X'FF'     SET FLAG ON                      68440013
         BCR   CEBR,GR2                RETURN                           68480013
         SPACE 2                                                        68520013
*                       TRANSFER POINT FOR CALL                         68560013
         SPACE                                                          68600013
CEKCEN   OI    FLAG,FUNC               SET FLAG TO SAY THAT THE PROGRAM 68640013
*                                    CONTAINS A FUNCTION REFERENCE      68680013
         CLI   1(GR7),CELPAR           IS NEXT ITEM (                   68720013
         BCR   CEBNE,GR2               NO SO RETURN                     68760013
CEBMV    MVI   1(GR6),CELPAR           YES SO MOVE IT TO OUTPUT AREA    68800013
         MVI   CEBFLG,X'FF'            SET B FLAG ON                    68840013
         AR    GR7,GR15                BUMP                             68880013
         AR    GR6,GR15                POINTERS                         68920013
         BC    CEBR,GR2                                                 68960013
         SPACE 3                                                        69000013
*        TRANSFER POINT FOR END OF BUFFER TO SET SCAN POINTER TO NEXT   69040013
*        BUFFER                                                         69080013
         SPACE                                                          69120013
CEKEOB   MVC   PAR1+1(3,GRDIC),CETSYM(GRDIC)     MOVE IN SYMBOLIC NAME  69160013
         MVI   PAR2+3(GRDIC),X'01'     MOVE IN CODE BYTE TO FREE BLOCK  69200013
         L     GR5,ZCHAIN(0,GR11)      PICK UP NEXT BLOCK IN CHAIN      69240013
         BALR  GR14,GR5                RELEASING CURRENT BLOCK          69280013
         L     GR7,PAR2(0,GRDIC)       LOAD GR7 WITH THE ABSOLUTE ADDR  69320013
         MVC   CETSYM(3,GRDIC),PAR1+1(GRDIC)     OF NEW BLK AND UPDATE  69360013
*                                        SYMBOLIC ADDRESS               69400013
         BC    CEBR,CE300                                               69440013
         SPACE 3                                                        69480013
*        TRANSFER POINT FOR EOP TO TIDY UP OR START SECOND FILE         69520013
         SPACE                                                          69560013
CEKEOP   MVC   PAR1+1(3,GRDIC),CESCYM  MOVE IN SYMBOLIC TEXT ADDR       69600013
         ST    GR6,PAR2(0,GRDIC)       TEXT BLOCK STORE ABSOLUTE ADDR   69640013
         L     GR5,ZTXTRF(0,GR11)      OF LAST TEXT ITEM .              69680013
         BALR  GR14,GR5                CONVERT TO SYMBOLIC AND STORE    69720013
         CLI   CESFIL,X'00'            IS SECOND FILE FLAG ON           69760013
         BC    CEBE,CE1FIL             YES, SO BRANCH                   69800013
         MVC   ZLSTXT+1(3,GRDIC),PAR1+1(GRDIC) IN COMMUNICATIONS REGION 69840013
         MVI   PAR2+3(GRDIC),X'02'     MARK AS NOT WANTED               69880013
         L     GR5,ZALTER(0,GR11)                                       69920013
         BALR  GR14,GR5                                                 69960013
         MVC   PAR1+1(3,GRDIC),CETSYM(GRDIC)                            70000013
         MVI   PAR2+3(GRDIC),X'01'     MOVE IN CODE BYTE TO FREE BLK    70040013
         L     GR5,ZALTER(0,GR11)                                       70080013
         BALR  GR14,GR5                                                 70120013
*                                                                     * 70160013
*                                                                     * 70200013
*                           RELEASE SPARE CORE HERE                   * 70240013
*                                                                     * 70280013
*                                                                     * 70320013
*                                                                     * 70360013
         SPACE 3                                                        70400013
*                       THIS SECTION RELEASES ANY SCRATCH CORE THAT     70440013
*                       WAS GOT BY THIS PHASE AND THEN HANDS CONTROL    70480013
*                       BACK TO COMPILER CONTROL TO LOAD THE NEXT       70520013
*                       PHASE ON THE LIST GIVEN IT BY READ-IN.          70560013
*                       MARK PHASES IEMGK,GQ,GP,GR, WANTED OR NOT WANT- 70600013
*                       AND MAKE INCLUDE CARD DICTIONARY ENTRY          70640013
         SPACE 2                                                        70680013
         L     GR1,CECRCT              RELEASE                          70720013
         LTR   GR1,GR1                 IS CECRT ZERO                    70760013
         BC    CEBZ,CEOUT              YES, SO SKUP NEXT SECTION        70800013
         ST    GR1,PAR1(0,GRDIC)       SCRATCH                          70840013
         L     GR1,ZURC(0,GR11)        CORE                             70880013
         BALR  GR14,GR1                                                 70920013
         XC    CECRCT(4),CECRCT        CLEAR CECRCT                     70960013
CEOUT    TM    ZARGFL(GRDIC),X'10'     IF FUNCTIONS WITH ARGUMENTS ARE  71000013
         BC    BZ,REQ1               PRESENT, WE MARK GK, GP, GQ, GR    71040013
         MVC   WNTLST(10),UNWNLS       AND GO WANTED                    71080015
         MVC   UNWNLS(10),IGNORE                                        71120015
         BC    B,REQ2                                                   71160013
         SPACE                                                          71200013
REQ1     TM    FLAG,FUNC               IF FUNCTIONS, BUT NO ARGUMENTS,  71240013
         BC    BNZ,CEMKGK          PRESENT MARK ONLY GK WANTED          71260015
         TM    ZFLAG4(GRDIC),X'01'                                      71280015
         BO    CEMKGK                IF BIT ON, MARK GK WANTED  A27138  71288019
         CLI   ZOPT(GRDIC),1         DONT MARK GK WANTED IF OPT=0 27138 71296019
         BE    REQ2                  ( IE 1 IN ZOPT)             A27138 71304019
*                                    OTHERWISE MARK GK WANTED           71312019
CEMKGK   MVC   WNTLST(2),UNWNLS                                         71320015
         MVC   UNWNLS(2),IGNORE                                         71360013
         SPACE                                                          71400013
REQ2     LA    GR1,WNTLST              POINT PAR1 AND PAR2 AT           71440013
         ST    GR1,PAR1(0,GRDIC)     APPROPRIATE LISTS AND CALL         71480013
         LA    GR1,UNWNLS            'REQEST' ROUTINE.                  71520013
         ST    GR1,PAR2(0,GRDIC)                                        71560013
         L     GR1,REQEST(0,GR11)                                       71600013
         BALR  GR14,GR1                                                 71640013
         SPACE                                                          71680013
*                       MAKE INCLUDE CARD DICTIONARY ENTRY              71720013
         SPACE                                                          71760013
         LA    GR1,CEINCL              PICK UP START OF INCLUDE CARD    71800013
         ST    GR1,PAR1(0,GRDIC)       DICTIONARY ENTRY. STORE ADDRESS  71840013
         LA    GR1,44                  AND COUNT OF LENGTH              71880013
         ST    GR1,PAR2(0,GRDIC)                                        71920013
         L     GR1,ZDICRF(0,GR11)      MAKE DICTIONARY ENTRY            71960013
         BALR  GR14,GR1                                                 72000013
         MVC   ZFATTB(2,GRDIC),PAR1+2(GRDIC) STORE REFERENCE IN COMMUN- 72040013
         L     GR1,ZDRFAB(0,GR11)      ICATIONS REGION                  72080013
         BALR  GR14,GR1                CONVERT TO ABSOLUTE              72120013
         L     GR1,PAR1(0,GRDIC)                                        72160013
         MVI   3(GR1),X'00'            AND CLEAR REST OF ENTRY          72200013
         MVC   4(40,GR1),3(GR1)        TO ZERO                          72240013
         LA    GR1,CELIST              PICK UP                          72280013
         ST    GR1,PAR1(0,GRDIC)       PHASE NAME LIST                  72320013
         XC    PAR2(4,GRDIC),PAR2(GRDIC)    CLEAR PAR2 SO THAT CONTROL  72360013
         L     GR1,RLSCTL(0,GR11)      CAN BE RELEASED TO NEXT PHASE    72400013
         BALR  GR14,GR1                REQUESTED BY READ  IN            72440013
         SPACE 3                                                        72480013
         SPACE 3                                                        72520013
*                       TRANSFER POINT FOR WAIT                         72560013
         SPACE 2                                                        72600013
CEKWAT   MVI   CEBRCT,X'01'            SET (COUNT TO 1                  72640013
         AR    GR7,GR15                BUMP POINTER OVER (              72680013
         MVI   CEWFLG,X'FF'            SET FLAG ON                      72720013
         MVI   1(GR6),CELPAR           IS NEXT ITEM IN SCAN A (         72760013
         AR    GR6,GR15                BUMP TEXT POINTER                72800013
         BCR   CEBR,GR2                                                 72840013
         SPACE 2                                                        72880013
*                        SET SECOND FILE FLAG ON AND RETURN             72920013
         SPACE                                                          72960013
CE1FIL   MVI   CESFIL,X'FF'            SET FLAG ON                      73000013
         ST    GR7,SFLPNT          SAVE GR7 FOR CENDTS                  73020015
         L     GR5,PAR1(0,GRDIC)       LOAD UP THE SYMBOLIC ADDR        73040013
         AR    GR5,GR15                BUMP BY ONE                      73080013
         ST    GR5,Z2FILE(0,GRDIC)     AND STORE AS START OF FILE 2     73120013
         BCR   CEBR,GR2                                                 73160013
         SPACE 2                                                        73200013
*                       TRANSFER POINT FOR FORMAT TO SET UP FORMAT STOR 73240013
         SPACE                                                          73280013
CEFMMV   MVI   CEFMST,CEFRMT         MOVE IN FORMAT BYTE                73320013
         BCR   CEBR,GR2              RETURN                             73360013
         SPACE 3                                                        73400013
CESCAN   EQU   CESCN                                                    73440013
         EJECT                                                          73480013
*        TRANSLATE TABLE FOR KEYWORDS GIVING OFFSET IN BRANCH TABLE     73520013
         SPACE 2                                                        73560013
CEKRAN   DC    4X'00'                                                   73600013
         DC    X'44'                   WHILE                            73640013
         DC    4X'00'                                                   73680013
         DC    X'30'                   WAIT                             73720013
         DC    X'00000000000000000000000000'      DISPLAY               73760013
         DC    X'3400340000'           SIGNAL, REVERT,                  73800013
         DC    X'0000001000'           ASSIGN                           73840013
         DC    X'180000'               CALL                             73880013
         DC    X'0000000000'           P FORMAT                         73920013
         DC    2X'00000000'                                             73960013
         DC    X'0000'                                                  74000013
         DC    X'0400'                 PROCEDURE                        74040013
         DC    X'0400'                 BEGIN                            74080013
         DC    X'14000C'               ITDO AND DO                      74120013
         DC    X'1C00'                 LIST DO                          74160013
         DC    X'2400'                 SN'                              74200013
         DC    X'0048'               FORMAT                             74240013
         DC    2X'0000000000000000'                                     74280013
         DC    X'2000'                 SN                               74320013
         DC    X'3800'                 SL                               74360013
         DC    X'2000'                 CN                               74400013
         DC    X'38'                   CL                               74440013
         DC    2X'0000000000000000'                                     74480013
         DC    X'3C'                   END DO                           74520013
         DC    X'40'                   ENDITDO                          74560013
         DC    X'0800'                 END                              74600013
         DC    X'2C00'                 ENDPROG                          74640013
         DC    X'2800'                 ENDBLOCK                         74680013
         DC    X'00'                                                    74720013
         DC    X'0000000000000000000000'                                74760013
         DC    X'3400000000'           ON                               74800013
         EJECT                                                          74840013
*        TRANSFER TABLE                                                 74880013
         SPACE                                                          74920013
CEKTRB   BCR   CEBR,GR2                TRANSFER FOR NORMAL  KEYWORD     74960013
         BCR   CEBR,GR2                                                 75000013
         BC    CEBR,CEKPRC        4    TRANSFER FOR PROCEDURE           75040013
         BC    CEBR,CEKEND        8    TRANSFER FOR END                 75080013
         BC    CEBR,CEKDO         C    TRANSFER FOR    DO               75120013
         BC    CEBR,CEKASN       10    TRANSFER FOR ASSIGNMENT          75160013
         BC    CEBR,CEKIDO       14    TRANSFER FOR ITERATIVE DO        75200013
         BC    CEBR,CEKCEN       18    TRANSFER FOR CALL                75240013
         BC    CEBR,CEKLDO       1C    TRANSFER FOR LIST DO             75280013
         BC    CEBR,CEKSN        20    TRANSFER FOR SN ETC              75320013
         BC    CEBR,CEKSND       24    TRANSFER FOR SN'                 75360013
         BC    CEBR,CEKEOB       280   TRANSFER FOR EOB                 75400013
         BC    CEBR,CEKEOP       2C4   TRANSFER FOR END OF PROGRAM      75440013
         BC    CEBR,CEKWAT       30    TRANSFER FOR WAIT DISPLAY        75480013
         BC    CEBR,CEKON        34    TRANSFER FOR ON                  75520013
         BC    CEBR,CEKSL        38    TRANSFER FOR SL,CL               75560013
         BC    CEBR,CEENDO       3C    TRANSFER FOR END DO              75600013
         BC    CEBR,CEKEDO       40    TRANSFER FOR END ITERATIVE DO    75640013
         BC    CEBR,CEAE         44    TRANSFER FOR WHILE               75680013
         BC    CEBR,CEFMMV       48    TRANSFER FOR FORMAT              75720013
         EJECT                                                          75760013
*                       THIS ROUTINE TESTS THE POSITION WHERE A         75800013
*                       FUNCTION HAS BEEN FOUND. IF IT IS IN AN         75840013
*                       ILLEGAL POSITION IT IS REPLACED BY A            75880013
*                       DUMMY REFERENCE AND THE FOLLOWING ITEMS         75920013
*                       IN PARENTHESES ARE DELETED. AN ERROR            75960013
*                       MESSAGE IS GENERATED.                           76000013
         SPACE                                                          76040013
CEFNCT   CLI   CEFFLG(GRDIC),X'FF'     IS FFLAG ON                      76080013
         BCR   CEBNE,GR2               NO, SO RETURN                    76120013
         C     GR15,CEBCT              IF BRACKET COUNT IS ZERO,   H378 76140019
         BCR   CEBL,GR2                THEN THIS IS AN ERROR. IF   H378 76160019
         BH    CEFNCY                  IT IS 1 AND WE ARE IN (PUT) H378 76180019
         CLI   SETS,X'FF'              STRING, KEYTO OR REPLY, IT  H378 76200019
         BCR   CEBNE,GR2               IS AN ERROR. OTHERWISE OK.  H378 76220019
CEFNCY   BAL   GR2,CERR15                                               76240001
         SPACE                                                          76280013
*                       THIS IS AN ERROR SO REPLACE PREVIOUS DICTIONARY 76320013
*        REFERENCE BY A DUMMY                                           76360013
         SPACE                                                          76400013
CEFNCX   XR    GR2,GR2                 CLEAR GR2                        76440013
         LR    GR5,GR6                                                  76480013
         BCTR  GR5,0                   PICK UP LOCATION OF OLD 2-BYTE   76520013
         BCTR  GR5,0                   ENTRY                            76560013
         MVC   0(2,GR5),CEDUMD+1       REPLACE BY DUMMY REFERENCE       76600013
         SPACE                                                          76640013
*                       BUMP SCAN POINTER UNTIL A ) IS FOUND AT THE     76680013
*        SAME LEVEL AS THE CURRENT (.                                   76720013
         SPACE                                                          76760013
CEFNCZ   LR    GR5,GR15                PICK UP BRACKET COUNT            76800013
         SPACE                                                          76840013
CEOLOP   AR    GR7,GR15                BUMP GR7                         76880013
CEOLYP   CLI   0(GR7),X'1F'            IS THIS AN IDENTIFIER            76920013
         BC    CEBH,CEOLXP             NO SO TRY FOR ( OR )             76960013
         CLI   0(GR7),X'00'            IS IT ZERO AND A DICT REF        77000013
         BC CEBH,CEOLZP                NO SO BRANCH FOR IDENTIFIER      77040013
         LA    GR7,3(0,GR7)            BUMP BY 3                        77080013
         BC    CEBR,CEOLYP             AND TRY AGAIN                    77120013
         SPACE                                                          77160013
CEOLZP   IC    GR2,0(0,GR7)            PICK UP IDENTIFIER LENGTH        77200013
         AR    GR7,GR2                 BUMP BY LENGTH                   77240013
         BC    CEBR,CEOLOP             AND TRY AGAIN                    77280013
CEOLXP   CLI   0(GR7),CELPAR           IS IT A (                        77320013
         BC    CEBNE,CERTRY            NO SO TRY FOR )                  77360013
         AR    GR5,GR15                BUMP BRACKET COUNT               77400013
         BC    CEBR,CEOLOP             AND TRY AGAIN                    77440013
         SPACE 2                                                        77480013
CERTRY   CLI   0(GR7),CERPAR           IS IT A )                        77520013
         BC    CEBNE,CEOLOP            NO SO TRY AGAIN                  77560013
         SR    GR5,GR15                REDUCE BRACKET COUNT             77600013
         BC    CEBNZ,CEOLOP            IF NOT ZERO TRY AGAIN            77640013
         BC    CEBR,CE30                                                77680013
         SPACE                                                          77720013
*              ISSUE ERROR MESSAGE. IF SPVESW IS ON WE                  77730001
*              HAVE STRING PV IN (PUT) STRING, KEYTO OR REPLY           77740001
*              OPTION AND WE ISSUE MESSAGE IEM0659 TO SAY THAT          77750001
*              THIS IS NOT SUPPORTED. IF SPVESW IS OFF WE HAVE AN       77760001
*              INVALID USE OF A FUNCTION AND WE ISSUE MESSAGE           77770001
*              IEM0673                                                  77780001
         SPACE 1                                                        77790001
CERR15   L     GR4,ZERROF(0,GR11)      SET ADDR OF ERROR ROUTINE        77800001
         CLI   SPVESW,X'FF'            IS SPVESW ON                     77810001
         BC    CEBNE,CER1              NO. GO TO ISSUE IEM0673          77820001
         MVC   PAR6+1(3,GR13),CEUFMS   YES. ISSUE IEM0659               77830001
         BC    CEBR,CER2                                                77840001
CER1     MVC   PAR6+1(3,GR13),CFMSG    ISSUE IEM0673                    77850001
CER2     BALR  GR14,GR4                                                 77860001
         MVI   SPVESW,X'00'            TURN SPVESW OFF                  77870001
*********************************************************************** 77960013
         BCR   CEBR,GR2                                                 78000013
CERR16   EQU   *                                                 H441   78001020
         L     GR4,ZERROF(0,GR11)      MSG661 FOR ILLEGAL        H441   78002020
         MVC   PAR6+1(3,GR13),TASKMS   PRIORITY P.V.             H441   78003020
         B     CER2                                                     78004020
         SPACE 1                                                        78008001
CEUFMS   DC    X'029344'               CODE FOR MESSAGE IEM0659         78016001
SPVESW   DC    X'00'                   'STRING PV IN (PUT) STRING,      78024001
*                                    KEYTO OR REPLY' SWITCH             78032001
TASKMS   DC    X'029544'               MSG661                    H441   78036020
         EJECT                                                          78040013
         DS    20F                     PATCH AREA                       78080013
*  NB.  ORG  FE+X'EA6' FOLLOWS - PATCH AREA MAY NOT BE 20 WORDS.  57444 78100072
         EJECT                                                          78120013
*                       CONSTANTS REGION STARTS AT FIXED OFFSET SO THAT 78160013
*        BLOCK IEMFF CAN COMMUNICATE                                    78200013
         SPACE                                                          78240013
         ORG   IEMFE+3750                                               78280013
CENDTX   BC    CEBR,CENDTS             BRANCH TO CENDTS                 78320013
CE31XX   BC    CEBR,CE31               BRANCH TO CE31                   78360013
CEBCT    DC    F'0'                                                     78400013
         SPACE 2                                                        78440013
CEINCL   DC    X'C8002C'               START OF INCLUDE CARD DICT REF   78480013
CEWFLG   DC    X'00'                                                    78520013
CEBYTE  DC    X'00'                                                     78560013
CEFMST   DC    X'00'                                                    78600013
CECNTB   DC    X'00'                                                    78640013
CECNTC   DC    X'00'                                                    78680013
CECURL   DC    X'00'                                                    78720013
CEDUMD   DC    X'000015'                                                78760013
CEHSF    DC    X'00'                                                    78800013
CELESN   DC    X'00'                                                    78840013
CELITM   DC    X'00'                                                    78880013
CELIST   DC    C'FE'                                                    78920013
CELST2   DC    C'FFZZ'                                                  78960013
         SPACE                                                          79000013
*              THIS IS A 'WANTED PHASES' LIST, USED IN MARKING GK, GP,  79040013
*        GQ, GR APPROPRIATELY.                                          79080013
WNTLST   DC    X'F0F0'                 GK NOT WANTED.                   79120013
         DC    X'F0F0'                 GO NOT WANTED                    79140015
         DC    X'F0F0'                 GP NOT WANTED.                   79160013
         DC    X'F0F0'                 GQ NOT WANTED.                   79200013
         DC    X'F0F0'                 GR NOT WANTED.                   79240013
         DC    C'ZZ'                   STOPPER.                         79280013
         SPACE                                                          79320013
*              THIS IS THE 'NOT WANTED PHASES' LIST.                    79360013
UNWNLS   DC    C'GK'                                                    79400013
         DC    C'GO'                                                    79420015
         DC    C'GP'                                                    79440013
         DC    C'GQ'                                                    79480013
         DC    C'GR'                                                    79520013
         DC    C'IG'                                                    79530015
         DC    C'ML'                                                    79540015
         DC    C'ZZ'                   STOPPER                          79560013
IGNORE   DC    10X'F0'                                                  79600015
CEIGML   DC    C'IGML'                 PHASE NAMES IG ML                79640013
CEIGIG   DC    C'IG'                                                    79680013
CELST    DC    X'00'                                                    79720013
CEPHNM   EQU   CELIST                                                   79760013
CERR1R   DC    X'02D340'                                          H408  79780019
CERR2R   DC    X'033440'                                          H408  79800019
CESFIL   DC    X'00'                                                    79840013
CESTNO   DC    X'00'                                                    79880013
CESW1    DC    X'00'                                                    79920013
CESW2    DC    X'00'                                                    79960013
PSUFLG   DC    X'00'                   PSUEDO VARIABLE FLAG.      19093 79980001
CFMSG    DC    X'02A144'                                                80000013
CFNFLG   DC    X'00'                                                    80040013
CEBFLG   DC    X'00'                                                    80080013
CEFRST   DC    H'0'                                                     80120013
CASPAC   DC    8F'0'                                                    80160013
CEBRCT   DC    F'0'                                                     80200013
CECRCT   DC    F'0'                                                     80240013
CEDRF    DC    F'0'                                                     80280013
CEDSTA   DC    F'0'                                                     80320013
CEDUMP   DC    8F'0'                                                    80360013
CEENDB   DC    F'0'               DUPLICATE CELL                        80400013
CEG14    DC    F'0'                                                     80440013
CEFNX    DC    F'0'                                                     80480013
CEGR14   DC    F'0'                                                     80520013
CELAST   DC    F'0'                                                     80560013
CELENG   DC    F'0'                                                     80600013
CELVLS   DC    F'0'                                                     80640013
CESTAC   EQU   CELVLS                                                   80680013
CEPREV   DC    F'0'                                                     80720013
CEFSTC   DC    F'0'                                                     80760013
CESCYM   DC    F'0'                                                     80800013
CESCLM   DC    F'0'                    SYMBOLIC ADR OF LAST TEXT BLOCK  80840013
CESTNL   DC    F'0'                                                     80880013
CESTNM   EQU   ZSTAT                                                    80920013
CESVE    DC    F'0'                                                     80960013
CEFNST   EQU   CEDSTA                                                   81000013
CEZERO   DC    F'0'               DUPLICATE CELL                        81040013
CEONE    DC    F'1'                                              31620  81060020
CE3      DC    F'3'                                                     81080013
CE4      DC    F'4'                                                     81120013
CE256    DC    F'256'             DUPLICATE CELL                        81160013
OLDLVL   DC    X'0'                                                     81200013
CELVLX   DC    X'0'                                                     81240013
CEFRSM   DC    H'0'                                                     81280013
CESTSM   DC    H'0'                                                     81320013
OLDSYM   DC    H'0'                                                     81360013
CEFLAG   DC    F'0'                                                     81400013
CEFLOG   EQU   CEFLAG+1                                                 81440013
OLDSTR   EQU   CECTST                                                   81480013
OLDFLG   EQU   CEFLAG+2                                                 81520013
CEKSTA   DC    F'0'                                                     81560013
CESTKA   EQU   CEKSTA                                                   81600013
STKCNT   DC    F'0'                                                     81640013
TXTSTR   DC    F'0'                                                     81680013
CERSTA   DC    F'0'                                                     81720013
ENDADR   DC    F'0'                                                     81760013
CEDMP1   DS    2F                                                       81800013
         SPACE 2                                                        81840013
*                       OFFSET FOR STORAGE IN IEMFF                     81880013
         SPACE                                                          81920013
CACL     EQU   2                       OFFSET OD L IN BLOCK2 BASE GR12  81960013
CACC     EQU   3                       OFFSET OF C IN BLOCK2 BASE GR12  82000013
CEONCD   EQU   4                                                        82040013
CADD1    EQU   8                       OFFSET OF CADD1 IN BLOCK2        82080013
CADD2    EQU   12                      OFFSET OF CADD2 IN BLOCK2        82120013
CELSYM   EQU   CADD1+2                                                  82160013
T11      DC    F'211'                                                   82200013
CEB2OF   EQU   16                      OFFSET OF START OF BRANCH TABLE  82240013
*                                      IN SECOND BLOCK                  82280013
CFPDER   BC    CEBR,CEB2OF+0(0,GR12)                                    82320013
CFPDR2   BC    CEBR,CEB2OF+4(0,GR12)                                    82360013
CEPFDR   EQU   CFPDER                                                   82400013
SETS     DC    X'00'                   THIS FLAG BYTE IS SET TO X'FF'   82440013
*                                    WHEN WE ARE IN THE SPECIAL TYPES   82480013
*                                    OF SETS POSITION IN THE STRING,    82520013
*                                    KEYTO, OR REPLY OPTIONS.           82560013
         SPACE                                                          82600013
FLAG     DC    X'00'                   FLAG BYTE, CONSISTING OF THE     82640013
*                                    FOLLOWING BITS.                    82680013
SFLPNT   DC    F'0'                                                     82700015
FUNC     EQU   X'80'                   BIT MEANING THAT A FUNCTION HAS  82720013
*                                    BEEN DETECTED IN THE COMPILATION.  82760013
         END   IEMFE                                                    82800013
