FT       TITLE 'IEMFT DICTIONARY SCAN, OS/360 PL/I COMPILER(F).'        00040013
*                                                                       00060021
*                                                                       00064021
* 5.5  A 475000                                               PEP 62603 00064672
*      D 194800                                        SPACE  PEP 62603 00065272
* 5.5  C 326930-326960                                         KT 62603 00066072
* 5.4  C 269850-269860.                                       MAC 52204 00068021
* 5.3A A 521200.                                              MJG 40111 00072021
* 5.2B A 269840.                                              MJG 35287 00076021
* 5.2  C 475000-475600.                ( ALSO FIXES A34341. ) MJG  H448 00080021
* 5.1  A 326900.                       ( ALSO FIXES A28442. ) MJG  H402 00084021
* 5.0  A 847100.                                               JN  H275 00088021
*      C 270400.                                               JN  H275 00092021
* 5.0  C 090750,283200,286800-287200,616400-617200,            JN  H172 00096021
*        618400-618800,760400-789600.                          JN  H172 00100021
* R17    171400,173600.                                            H137 00104021
* R16    625600-628000,652800-654000.                                I1 00108021
*                                                                       00120013
*                                                                       00160013
*              STATUS - CHANGE LEVEL 0                                  00200013
*                                                                       00240013
*                                                                       00280013
*                                                                       00320013
*              FUNCTIONS.  (A) SCANS SECOND FILE AND INSERTS POINTERS   00360013
*        TO ITS STATEMENTS IN APPROPRIATE DICTIONARY ENTRIES.           00400013
*                          (B) SEQUENTIALLY SCANS THE DICTIONARY AND    00440013
*        DOES THE FOLLOWING.                                            00480013
*                          (1) EVERY ITEM WHICH IS A MEMBER OF A        00520013
*        STORAGE CLASS IS INSERTED IN THE APPROPRIATE CHAIN FOR THAT    00560013
*        CLASS                                                          00600013
*                          (2) CONSTANTS ARE PLACED IN THE CONSTANTS    00640013
*        CHAIN.  THEIR APPARENT PRECISION AND SCALE ARE CALCULATED.     00680013
*                          (3) ELEMENT LENGTHS ARE INSERTED IN THE      00720013
*        DIMENSION TABLES OF DIMENSIONED ITEMS.  DIMENSIONED ITEMS WITH 00760013
*        IDENTICAL ARRAY BOUNDS WILL HAVE SHARED A COMMON DIMENSION     00800013
*        TABLE.   SHOULD THE ELEMENT LENGTHS NOW BE FOUND TO BE DIFF-   00840013
*        ERENT, DUPLICATE TABLES ARE CREATED AND THE APPROPRIATE        00880013
*        ELEMENT LENGTHS INSERTED.                                      00920013
*                          (4) ITEMS WHICH ARE MEMBERS OF STRUCTURES    00960013
*        AND WHICH HAVE INHERITED DIMENSIONS, I.E. ARE CONTAINED IN A   01000013
*        STRUCTURE WHICH IS ITSELF DIMENSIONED, AT THIS STAGE INHERIT   01040013
*        THEIR DIMENSIONS. SHOULD THE INHERITED DIMENSIONS NOT BE       01080013
*        CONSTANT, SECOND FILE STATEMENTS ARE SET UP TO INITIALISE THE  01120013
*        BOUNDS IN THE OBJECT TIME DOPE VECTOR.                         01160013
*              NO COMMONING OF DIMENSION TABLES CAN BE CARRIED OUT FOR  01200013
*        STRUCTURE MEMBERS SINCE THEY ARE USED BY THE AGGREGATES        01240013
*        PROCESSOR.                                                     01280013
*                          (5) ITEMS WHICH HAVE EXPRESSIONS WHICH MUST  01320013
*        BE EVALUATED AT PROLOG TIME - PARAMETER DESCRIPTIONS FOR ENTRY 01360013
*        POINTS DECLARED IN THE BLOCK, AND DEFINED ITEMS - ARE PLACED   01400013
*        IN THE AUTOMATIC CHAIN FOR THE APPROPRIATE BLOCK.              01440013
*                          (6) ANY ITEM WHICH IS DESCRIBED BY A PICTURE 01480013
*        NOW HAS THE PRECISION AND SCALING, OR STRING LENGTH, EXTRACTED 01520013
*        FROM THE PICTURE ENTRY.                                        01560013
*               IN THE CASE OF REAL AND COMPLEX ITEMS SHARING THE SAME  01600013
*        NUMERIC PICTURE, THE TABLE ENTRY IS DUPLICATED. ONE COPY IS    01640013
*        THEN USED FOR REAL ATA AND THE OTHER FOR COMPLEX.              01680013
*                          (7) THE 'DOPE VECTOR REQUIRED' BIT IS SET ON 01720013
*        WHERE NECESSARY.                                               01760013
*                                                                       01800013
*                                                                       01840013
*                                                                       01880013
*              ENTRY POINTS - IEMFT, ENTERED FROM COMPILER CONTROL.     01920013
*                                                                       01960013
*                                                                       02000013
*                                                                       02040013
*              INPUT - COMMUNICATIONS REGION, DICTIONARY AND SECOND     02080013
*        FILE TEXT.                                                     02120013
*                                                                       02160013
*                                                                       02200013
*                                                                       02240013
*              OUTPUT - DICTIONARY ALTERED AS DESCRIBED UNDER FUNCTION, 02280013
*        AND SECOND FILE, PERHAPS WITH ADDITIONS.                       02320013
*                                                                       02360013
*                                                                       02400013
*                                                                       02440013
*              EXTERNAL ROUTINES - (1) ZDABRF. CONVERTS SYMBOLIC        02480013
*        DICTIONARY REFERENCE TO ABSOLUTE.                              02520013
*                                  (2) ZTXTAB. CONVERTS SYMBOLIC TEXT   02560013
*        REFERENCE TO ABSOLUTE.                                         02600013
*                                  (3) ZALTER. USED FOR ALTERING STATUS 02640013
*        OF TEXT BLOCKS WHEN SCANNING FROM ONE TO THE NEXT.             02680013
*                                  (4) ZDRFAB. CONVERTS SYMBOLIC        02720013
*        DICTIONARY REFERENCES TO ABSOLUTE.  USED FOR EXAMINING DICT-   02760013
*        IONARY ENTRIES.                                                02800013
*                                  (5) ZUGC.  USED FOR GETTING SCRATCH  02840013
*        CORE FOR TABLE OF POINTERS TO ENTRY TYP 1'S.                   02880013
*                                  (6) ZDICRF.  USED FOR MAKING DICT-   02920013
*        IONARY ENTRIES                                                 02960013
*                                  (7) ZUTXTC.  USED FOR GETTING MORE   03000013
*        TEXT BLOCKS IN THE EVENT OF THE SECOND FILE OVERFLOWING THE    03040013
*        PRESENT BLOCKS.                                                03080013
*                                  (8) ZUERR.  USED FOR CREATING ERROR  03120013
*        MESSAGE DICTIONARY ENTRIES.                                    03160013
*                                  (9) ZABORT.  USED FOR TERMINATING    03200013
*        COMPILER IN THE EVENT OF A TERMINAL ERROR.                     03240013
*                                  (10) RLSCTL.  USED FOR RETURNING     03280013
*        CONTROL TO COMPILER CONTROL.                                   03320013
*                                                                       03360013
*                                                                       03400013
*                                                                       03440013
*                                                                       03480013
*              EXITS, NORMAL - BEFORE CB2, CONTROL IS RETURNED TO COMP- 03520013
*        ILER CONTROL.                                                  03560013
*                                                                       03600013
*                                                                       03640013
*                                                                       03680013
*              EXITS, ERROR - FTERR1, CONTROL IS RELEASED HERE IN THE   03720013
*        EVENT OF A COMPILER ERROR.                                     03760013
*                                                                       03800013
*                                                                       03840013
*                                                                       03880013
*              TABLES/WORK AREAS.  512 BYTES OF SCRATCH CORE USED FOR   03920013
*        BUILDING A STACK OF POINTERS TO BLOCK HEADER ENTRY TYPE 1      03960013
*        ENTRIES.  SINCE THE HASH TABLE IS NO LONGER REQUIRED IT IS     04000013
*        USED AS THE SCRATCH CORE.                                      04040013
*                                                                       04080013
*                                                                       04120013
*                                                                       04160013
*              ATTRIBUTES - NOT REUSABLE (SEE NOTES).                   04200013
*                                                                       04240013
*                                                                       04280013
*                                                                       04320013
*              NOTES - (1) THIS PHASE DOES NOT REQUIRE ANY MODIFICATION 04360013
*        AS A RESULT OF CHANGES IN INTERNAL REPRESENTATION OF EXTERNAL  04400013
*        GRAPHICS.                                                      04440013
*                      (2) REGISTER USAGE - AS PER COMMENTS ON 'EQU'    04480013
*        CARDS BELOW.                                                   04520013
*                      (3)  THIS PHASE IS NOT REUSABLE SINCE THE EARLY  04560013
*        CODE IS OVERWRITTEN, AS TEMPORARY STORAGE, BY LATER CODE.      04600013
         EJECT                                                          04640013
IEMFT    START 0                                                        04680013
         USING *,GRBASE                                                 04720013
         DC    C'FT'                   PHASE IDENTIFICATION LETTERS.    04760013
         EJECT                                                          04800013
*                       SYMBOLIC REGISTERS                              04840013
         SPACE                                                          04880013
GRBASE   EQU   9                       BASE REGISTER OF MODULE.         04920013
GRCC     EQU   11                      COMPILER CONTROL BASE.           04960013
GRDIC    EQU   13                      BASE OF DICTIONARY.              05000013
         SPACE                                                          05040013
GRSP     EQU   1                       SCAN POINTER.                    05080013
GRP      EQU   10                      GENERAL POINTER                  05120013
         SPACE                                                          05160013
LR       EQU   15                      BRANCHING REGISTER               05200013
RR       EQU   14                      RETURN REGISTER                  05240013
         SPACE                                                          05280013
GRZ      EQU   8                       CONTAINS ZERO (EXCEPT IN STRUCT- 05320013
*                                    URE PROCESSING ROUTINE).           05360013
UR       EQU   7                       CONTAINS 1                       05400013
GR2      EQU   2                       TOP THREE BYTES KEPT CLEAR.      05440013
         SPACE                                                          05480013
GR3      EQU   3                       *                                05520013
GR4      EQU   4                        *                               05560013
GR5      EQU   5                        * WORKING REGISTERS IN STRUCT-  05600013
GR6      EQU   6                        * URE PROCESSOR.                05640013
GR10     EQU   10                       *                               05680013
GRD      EQU   12                      *                                05720013
GRW      EQU   3                       *                                05760013
GRX      EQU   4                        * WORKING REGISTERS IN REMAIND- 05800013
GRLTH    EQU   5                        * ER OF PHASE.                  05840013
GRY      EQU   6                       *                                05880013
         SPACE                                                          05920013
         SPACE                                                          05960013
UT       EQU   UR                      STRUCTURE PROCESSOR'S UNIT REG.  06000013
         EJECT                                                          06040013
*                       BRANCHING MNEMONICS                             06080013
         SPACE                                                          06120013
BO       EQU   1                       BRANCH ON - ONES                 06160013
BNO      EQU   14                                  NOT ONES             06200013
BP       EQU   2                                   PLUS                 06240013
BM       EQU   4                                   MINUS OR MIXED       06280013
BE       EQU   8                                   EQUAL                06320013
BNE      EQU   7                                   NOT EQUAL            06360013
BL       EQU   4                                   LOW                  06400013
BNL      EQU   11                                  NOT LOW              06440013
BH       EQU   2                                   HIGH                 06480013
BNH      EQU   13                                  NOT HIGH             06520013
BZ       EQU   8                                   ZERO                 06560013
BNZ      EQU   7                                   NOT ZERO             06600013
Z        EQU   8                                   ZERO                 06640013
B        EQU   15                      UNCONDITIONAL BRANCH             06680013
NOP      EQU   0                                                        06720013
         SPACE 5                                                        06760013
*              OFFSETS IN THE COMMUNICATIONS REGION                     06800013
         SPACE                                                          06840013
ZNEXTD   EQU   X'4C'                                                    06880013
FSTDRF   EQU   X'D6'                   SLOT CONTAINING REF OF FIRST     06920013
*                                    ENTRY IN THE DICTIONARY.           06960013
ZTRAN1   EQU   X'44'                                                    07000013
ZCOMM    EQU   304                                                      07040013
Z2FILE   EQU   ZCOMM+44                                                 07080013
ZMYNAM   EQU   X'70'                                                    07120013
ZCONCH   EQU   ZCOMM+78                                                 07160013
ZCITEM   EQU   ZCOMM+80                                                 07200013
ZSTACH   EQU   ZCOMM+68                STATIC STORAGE SLOT              07240013
ZHASH    EQU   ZCOMM+28                HEAD OF HASH TABLE.              07280013
ZFLAG1   EQU   ZCOMM+16                FLAG BYTE CONTAINING -           07320013
ZFLAG3   EQU   ZCOMM+18                                                 07360013
ZINLFL   EQU   X'08'                                                    07400013
ZSTRFL   EQU   X'02'                   STRUCTURE FLAG BIT.              07440013
ARINT    EQU   X'F8'                   CONTAINS ADDRESS OF INTERRUPT    07480013
*                                    RETURN ROUTINE.                    07520013
ARMSK    EQU   X'111'                  CONTAINS CODE FOR INTERRUPT TO   07560013
*                                    BE RETURNED.                       07600013
DDIO     EQU   ZCOMM+19                DATA DIRECTED IO                 07620015
PGDATA   EQU   X'0C'                                                    07640015
*                                    WITHOUT LIST FLAG BYTE AND         07680013
BIT      EQU   4                     APPROPRIATE BIT                    07720013
         SPACE 5                                                        07760013
*                       OFFSETS FOR COMPILER CONTROL.                   07800013
PAR1     EQU   X'80'                                                    07840013
PAR2     EQU   PAR1+4                                                   07880013
PAR6     EQU   X'94'                                                    07920013
ZUERR    EQU   X'30'                                                    07960013
ZABORT   EQU   X'20'                                                    08000013
ZDICRF   EQU   X'2C'                                                    08040013
ZLOCK    EQU   X'112'                                                   08080013
ZDABRF   EQU   X'60'                                                    08120013
ZDRFAB   EQU   X'34'                                                    08160013
ZALTER   EQU   X'5C'                                                    08200013
ZLSTXT   EQU   X'114'                  OFFSET OF TEXT REFERENCE TO      08240013
*                                    NEXT FREE BYTE.                    08280013
ZBLSIZ   EQU   X'108'                  OFFSET OF SLOT CONTAINING TEXT   08320013
*                                    BLOCK SIZE.                        08360013
ZUTXTC   EQU   X'14'                                                    08400013
ZTXTAB   EQU   X'54'                                                    08440013
ZUGC     EQU   X'10'                                                    08480013
ZTXTRF   EQU   X'50'                                                    08520013
ZMASK1   EQU   X'11E'                                                   08560013
ZURC     EQU   X'18'                                                    08600013
ZCHAIN   EQU   X'58'                                                    08640013
LOADW    EQU   X'24'                                                    08680013
         SPACE 3                                                        08720013
*              OFFSETS OF DATA AND ENTRY POINTS IN FU                   08760013
         USING *+X'1000',GRD                                            08800013
FU       EQU   *+X'1000'                                                08840013
FULIN    EQU   FU+2                                                     08880013
PROPIC   EQU   FU+6                                                     08920013
INMATE   EQU   FU+10                                                    08960013
MVTXT    EQU   FU+14                                                    09000013
MKDMTB   EQU   FU+18                                                    09040013
BCDENT   EQU   FU+22                                                    09050015
FTFINA   EQU   FU+26                                                    09060015
CHKBCD   EQU   FU+30                                                    09070015
MTFGEN   EQU   FU+34                                               H172 09075001
CDETAB   EQU   FU+X'F00'                                                09080013
MTFSKL   EQU   FU+X'F41'                                                09090015
SCFLSK   EQU   FU+X'F63'                                                09100015
         EJECT                                                          09120013
*                       SYMBOLIC CODE BYTES                             09160013
         SPACE 2                                                        09200013
ADF1     EQU   X'11'                                                    09240013
PEXP     EQU   X'16'                                                    09250015
BVEXP    EQU   X'17'                                                    09260015
EFIVE    EQU   X'83'                                                    09280013
GLORYH   EQU   X'10'                   SAVE/RESTORE BIT IN OTHER1       09320013
MAJORS   EQU   X'04'                   MAJOR STRUCTURE BIT IN OTHER4.   09360013
SYMBOL   EQU   X'80'                   SYMBOL BIT IN OTHER1 CODE BYTE.  09400013
ALIGN    EQU   X'08'                   ALIGN/PACKED BIT IN OTHER 4      09440013
ON       EQU   X'FF'                   FLAG    *                        09480013
OFF      EQU   0                       SETTINGS*                        09520013
DIMS     EQU   X'40'                   DIMENSION BIT IN VARIABLE BYTE.  09560013
DATAB    EQU   X'0F'                   CODE BYTE FOR A DATA ITEM.       09600013
STRBYT   EQU   X'0E'                   STRUCTURE CODE BYTE.             09640013
PABIT    EQU   X'20'                   PACKED/ALIGNED BIT IN DATA BYTE  09680013
LMIS     EQU   X'08'                   LAST MEMBER IN STRUCTURE BIT IN  09720013
*                                    OTHER1 CODE BYTE.                  09760013
ADJDIM   EQU   X'04'                   ADJUSTABLE DIMENSIONS BIT IN     09800013
*                                    OTHER1 CODE BYTE.                  09840013
ADJBND   EQU   X'FF'                   CODE IN DIMENSION TABLE TO       09880013
ASTBND   EQU   X'F0'                 INDICATE ADJUSTABLE BOUND, AND     09920013
*                                    ASTERISK BOUND.                    09960013
MTF1     EQU   X'7F'                   CODE IN DIMENSION TABLE FOR 1)   10000013
MTF2     EQU   X'3F'                 INITIALISED BY MTF, 2) INITIALIS-  10040013
*                                    -ED BY PREVIOUS MTF.               10080013
ENDBUF   EQU   X'ED'                   END OF TEXT BLOCK MARKER.        10120013
CHUNWT   EQU   X'82'                                                    10160013
PICOFF   EQU   7                                                        10200013
COPIED   EQU   2                                                        10240013
DNCHNG   EQU   1                       'DO NOT CHANGE' FLAG.            10280013
STRBIT   EQU   X'20'                   MEMBER OF STRUCTURE BIT          10320013
DIMED    EQU   X'40'                   DIMENSIONED BIT MASK             10360013
ADJLST   EQU   X'40'                   ADJUSTABLE LENGTH STRING BIT.    10400013
CHAR     EQU   X'04'                   CHARACTER BIT IN DATA BYTE       10440013
LONG     EQU   X'10'                   LONG    BIT IN DATA BYTE         10480013
CPLX     EQU   X'01'                   COMPLEX BIT IN DATA BYTE         10520013
FLOAT    EQU   X'02'                   FLOAT   BIT IN DATA BYTE         10560013
BINARY   EQU   X'04'                   BINARY  BIT IN DATA BYTE         10600013
STRNG    EQU   X'80'                   STRING BIT IN DATA BYTE          10640013
STCL     EQU   X'03'                   STORAGE CLASS BITS IN OTHER2     10680013
*                                    CODE BYTE.                         10720013
*              SYMBOLIC OFFSETS                                         10760013
         SPACE                                                          10800013
OTHER1   EQU   10                                                       10840013
VAR      EQU   11                                                       10880013
OTHER2   EQU   12                                                       10920013
OTHER3   EQU   13                                                       10960013
OTHER4   EQU   14                                                       11000013
DATA   EQU     15                                                       11040013
STATCH   EQU   3                       OFFSET OF STATIC CHAIN IN SAVE-  11080013
*                                    RESTORE ENTRY.                     11120013
DCLNO    EQU   8                       OFFSET OF DECLARE NUMBER IN A    11160013
DCLOFF   EQU   8                     SAVE RESTORE ENTRY AND IN A        11200013
*                                    STRUCTURE.                         11240013
STINOD   EQU   19                      OFFSET OF STRUCTURE INFORMATION  11280013
*                                    IN A SCALAR STRUCTURE              11320013
DILTH    EQU   3                       LENGTH OF DIMENSION INFORMATION  11360013
NXTMEM   EQU   4                       OFFSET OF DICTIONARY REFERENCE   11400013
*                                    OF NEXT MEMBER OF STRUCTURE FROM   11440013
*                                    START OF STRUCTURE INFORMATION.    11480013
VARINF   EQU   15                      OFFSET OF VARIBLE INFORMATION    11520013
*                                    FROM START OF STRUCTURE OR LABEL.  11560013
EXTDAT   EQU   6                       THE NUMBER OF EXTRA BYTES IN A   11600013
*                                    DATA ITEM BETWEEN CODE BYTES AND   11640013
*                                    VARIABLE INFORMATION AS OPPOSED TO 11680013
*                                    A LABEL.                           11720013
SNDADD   EQU   4                       LENGTH OF SECOND ADDRESS SLOT.   11760013
CTSTUT   EQU   2                       OFFSET OF REFERENCE OF CONTAIN-  11800013
*                                    ING STRUCTURE FROM START OF        11840013
*                                    STRUCTURE INFORMATION.             11880013
DINTAB   EQU   5                       OFFSET OF NUMBER OF DIMENSIONS   11920013
DTFLB    EQU   3                     IN A DIMENSION TABLE, OF ITS FLAG  11960013
USED     EQU   X'80'                 BYTE, THE USED BIT IN THAT BYTE,   12000013
USDNC    EQU   X'C0'                 THE COMBINATION USED AND DO NOT    12040013
*                                    COMMON.                            12080013
CNSTDS   EQU   9                       THE OFFSET OF THE DICTIONARY     12120013
*                                    REFERENCE OF THE CONTAINING        12160013
*                                    STRUCTURE FROM THE VARIABLE        12200013
*                                    INFORMATION IN A DIMENSIONED       12240013
*                                    STRUCTURE.                         12280013
VARIDS   EQU   15                      OFFSET OF VARIABLE INFORMATION   12320013
*                                    FROM START OF A DIMENSIONED        12360013
*                                    STRUCTURE.                         12400013
TIKBYT   EQU   3                       OFFSET OF BYTE IN A DIMENSION    12440013
USBYBS   EQU   X'10'                 TABLE AND OFFSET OF THE FLAG BIT   12480013
*                                    IN THIS BYTE USED TO INDICATE THAT 12520013
*                                    IT HAS BEEN USED IN ADV CODE.      12560013
LENGTH   EQU   30                      OFFSET OF LENGTH OF MOVE         12600013
DESTRF   EQU   11                    DESTINATION FIELD REFERENCE,       12640013
SRCFRF   EQU   15                    SOURCE FIELD REFERENCE,            12680013
DESTOF   EQU   20                    DESTINATION FIELD OFFSET,          12720013
SRCOFF   EQU   25                    SOURCE FIELD OFFSET IN AN MTF      12760013
MTFSL    EQU   34                    STATEMENT, AND LENGTH OF THE MTF   12800013
*                                    STATEMENT.                         12840013
USBYDR   EQU   10                      OFFSET INTO THE DIMENSION TABLE  12880013
*                                    OF THE DICTIONARY REFERENCE OF THE 12920013
*                                    FIRST BASE ELEMENT TO USE IT.      12960013
TINTAB   EQU   8                       OFFSETS IN THE DIMENSION TABLE   13000013
N1INTB   EQU   9                     OF BYTES TO STORE T AND N1.        13040013
DIMREF   EQU   7                       OFFSET OF DIMENSION TABLE        13080013
*                                    REFERENCE IN SECOND FILE           13120013
*                                    DICTIONARY ENTRY.                  13160013
DCNUM    EQU   3                       OFFSET OF DECLARE NUMBER AND     13200013
LEVCNT   EQU   10                  LEVEL IN 2ND FILE DICTIONARY         13240015
*                                    ENTRY.                             13280013
SCFELN   EQU   12                      LENGTH OF SECOND FILE ENTRY.     13320013
SCNFRF   EQU   1                       OFFSET OF REFERENCE TO SECOND    13360013
*                                    FILE ENTRY IN MTF SKELETON,AND ADV 13400013
ELTREF  EQU   11                       OFFSET OF DICTIONARY REFERENCE.  13440013
NODIMS   EQU   17                    TO ARRAY IN ADV STATEMENT AND THE  13480013
*                                    NUMBER OF DIMENSIONS.              13520013
WANTED   EQU   X'03'                   CODE TO MARK A TEXT BLOCK AS     13560013
*                                                                       13600013
UNWANT   EQU   X'02'                   AND NOT WANTED.                  13640013
F2D1     EQU   1                       DISPLACEMENT OF DICT REF IN 2ND  13680013
*                                    FILE ENTRY                         13720013
DA456    EQU   14                      OFFSET OF DATA BYTE IN ENTRIES   13760013
*                                    TYPE 4,5,&6                        13800013
E2DATA   EQU   8                       OFFSET OF DATA BYTE IN ENTRY     13840013
*                                    TYPE 2                             13880013
DIDATA   EQU   15                      OFFSET OF DATA BYTE IN DATA ITEM 13920013
PICBIT   EQU   8                                                        13960013
DIDN     EQU   8                       OFFSET OF DECLARE NO. IN DATA    14000013
*                                    ITEM ENTRY                         14040013
DIVARI   EQU   21                      OFFSET OF VARIABLE AREA          14080013
ELVAR    EQU   15                                                       14120013
DIPIC    EQU   19                                                       14160013
PICCDE   EQU   8                       OFFSET OF CODE BYTE IN PICTURE   14200013
PICNUM   EQU   X'80'                   TEST MASK FOR NUMERIC BIT        14240013
PE1CNT   EQU   4                                                        14280013
CDEBYT   EQU   10                      OFFSETS OF CODE BYTES IN DATA    14320013
*                                    EVENT, AND LABEL VARIABLE ENTRIES  14360013
ECB      EQU   5                                                        14400013
E1AUTO   EQU   11                                                       14440013
E3AUTO   EQU   11                                                       14480013
ECC      EQU   5                                                        14520013
PE1      EQU   X'80'                                                    14560013
CONDAT   EQU   5                                                        14600013
CONSTL   EQU   14                                                       14640013
CNLTH1   EQU   CONSTL+1                                                 14680013
         SPACE 10                                                       14720013
*              INTERNAL CODES                                           14760013
DECPNT   EQU   X'46'                                                    14800013
         SPACE                                                          14840013
SN2      EQU   X'BC'                                                    14880013
EOP2     EQU   X'EB'                                                    14920013
EOTB     EQU   X'ED'                                                    14960013
EODB     EQU   X'CF'                                                    15000013
BCDAPP   EQU   X'80'                                                    15040013
NRIS     EQU   X'40'                   'NOT REQUIRED IN SCAN BIT'       15080013
BLANK    EQU   X'40'                                                    15120013
         EJECT                                                          15160013
         SPACE                                                          15200013
         SPACE                                                          15240013
*              ENTRY POINTS AND DATA USED BY FU                         15280013
         L     GRBASE,PAR1(GRDIC)                                       15320013
         BC    B,FT000                                                  15360013
         BC    B,DD2A                  RETURN FROM MOVE OF LABEL STATS  15400013
         SPACE 4                                                        15440013
FT000    EQU   *                                                        15480013
         MVC   ZMYNAM(2,GRDIC),IEMFT                                    15520013
         SPACE                                                          15560013
         SR    GRZ,GRZ                 SET UP ZERO REGISTER             15600013
         LA    UR,1(0,0)               SET UP UNIT REGISTER             15640013
         SR    GR2,GR2                                                  15680013
         STH   GRZ,ZLOCK(GRDIC)                                         15720013
         MVI   ZSTACH(GRDIC),5         SET CODE BYTE IN STATIC SLOT     15760013
         SPACE                                                          15800013
*              LOAD FU                                                  15840013
         LA    GRX,FUNAM                                                15880015
         ST    GRX,PAR1(GRDIC)                                          15920013
         L     LR,LOADW(GRCC)                                           15960013
         BALR  RR,LR                                                    16000013
         MVC   FUBAS(4),PAR1(GRDIC)                                     16060015
*              SET UP INFORMATION FOR DECIMAL OVERFLOW INTERRUPT        16120013
*        HANDLING WHICH MAY BE REQUIRED BY THE STERLING CONSTANT        16160013
*        PROCESSOR                                                      16200013
         SPACE                                                          16240013
         L     GRX,BDYMSK              INSERT ONES IN BITS 4-7 OF GRX   16280013
         SPM   GRX                   AND SET PROGRAM MASK ENABLE        16320013
*                                    DECIMAL OVERFLOW INTERRUPT         16360013
         LA    GRX,LSDERR              SET UP INTERRUPT RETURN ADDRESS  16400013
         ST    GRX,ARINT(0,GRDIC)    SLOT                               16440013
         MVI   ARMSK(GRDIC),X'20'      AND BIT TO REQUEST RETURN OF     16480013
*                                    CONTROL FOLLOWING DECIMAL OVERFLOW 16520013
*                                    INTERRUPT.                         16560013
         SPACE                                                          16600013
         STH   GRZ,ZSTACH+4(0,GRDIC)                                    16640013
         STH   GRZ,ZCONCH(0,GRDIC)                                      16680013
         STH   GRZ,ZCITEM(0,GRDIC)                                      16720013
         SPACE                                                          16760013
         TM    DDIO(GRDIC),PGDATA                                       16800015
         BC    BZ,FT001                                                 16840015
         MVI   INCLUD,X'45'            NCE OF A DATA DIRECTED I/O       16880013
         MVI   INCLUD+1,X'E0'       STATEMENT. IF PRESENT MODIFY LATER  16920013
*                                    INSTRUCTION SO THAT THE SYMBOL BIT 16960013
*                                    IS SET ON. THIS SAVES MAKING THE   17000013
*                                    TEST FOR EACH DATA ITEM            17040013
         SPACE 5                                                        17080013
FT001    EQU   *                                                        17120013
         EJECT                                                          17400013
*              THE SECOND FILE IS NOW SCANNED AND POINTERS TO ITS       17440013
*        ENTRIES ARE PUT IN ASSOCIATED DICTIONARY ENTRIES.              17480013
         SPACE 3                                                        17520013
         L     GRSP,Z2FILE(0,GRDIC)    PICK UP POINTER TO START OF      17560013
*                                    SECOND FILE                        17600013
         ST    GRSP,PAR1(0,GRDIC)                                       17640013
AC1      ST    GRSP,SYMBLK             SAVE SYMBOLIC NAME OF THIS TEXT  17680013
*                                    BLOCK                              17720013
         L     LR,ZTXTAB(0,GRCC)       CONVERT POINTER TO ABSOLUTE      17760013
         BALR  RR,LR                                                    17800013
         SPACE                                                          17840013
         L     GRSP,PAR1(0,GRDIC)      SET UP POINTER TO 2ND FILE       17880013
*                                      TEST BYTE POINTED AT. IS IT -    17920013
AC2      CLI   0(GRSP),0             ZERO                               17960013
         BC    BE,AD5                                                   18000013
         CLI   0(GRSP),EOTB          END OF BLOCK OF TEXT               18040013
         BC    BE,AE3                                                   18080013
         CLI   0(GRSP),SN2           SN2                                18120013
         BC    BE,AF3                                                   18160013
         CLI   0(GRSP),EOP2          END OF SECOND FILE                 18200013
         BC    BE,B1                                                    18240013
         CLI   0(GRSP),X'FE'           IS IT ISUB MARKER                18280013
         BC    BE,AC3                  YES                              18320013
         BXH   GRSP,UR,AC2             IF NONE, RETURN FOR NEXT BYTE.   18360013
         SPACE 3                                                        18400013
*              JUMP OVER ISUB MARKER AND FOLLOWING NUMBER               18440013
AC3      LA    GRSP,2(GRSP)                                             18480013
         BC    B,AC2                                                    18520013
         SPACE 2                                                        18560013
*              PREPARATIONS ARE MADE FOR PICKING UP NEXT BLOCK OF TEXT. 18600013
AE3      MVC   PAR1(4,GRDIC),SYMBLK    MOVE SYMBOLIC NAME OF BLOCK      18660015
         ST    GRZ,PAR2(0,GRDIC)       CLEAR PAR2                       18720013
         MVI   PAR2+3(GRDIC),2         SET STATUS TO 'NIT WANTED'       18760013
         L     LR,ZCHAIN(0,GRCC)       CALL ROUTINE TO GET NEXT BLOCK   18800013
         BALR  RR,LR                                                    18840013
         SPACE                                                          18880013
         L     GRSP,PAR1(0,GRDIC)    BLOCK.                             18920013
         BC    B,AC1                   GO AND CONVERT IT TO ABSOLUTE.   18960013
         SPACE 3                                                        19000013
AF3      STH   GRZ,PAR1(0,GRDIC)       CLEAR FIRST TWO BYTES OF PAR1    19040013
         MVC   PAR1+2(2,GRDIC),F2D1(GRSP) MOVE IN POINTER TO DICTIONARY 19080013
         L     LR,ZDRFAB(0,GRCC)     REFERENCE AT CONVERT IT TO ABSOL-  19120013
         BALR  RR,LR                 UTE.                               19160013
         SPACE                                                          19200013
         L     GRX,PAR1(0,GRDIC)       POINT TO DICTIONARY ENTRY.       19240013
         CLI   9(GRX),ADF1             IF ADF CODE IN ENTRY, POINTERS   19280013
         BC    BE,AD5                NOT REQUIRED                       19320013
         CLI   9(GRX),PEXP           LIKEWISE NO POINTERS FOR           19328015
         BC    BE,AD5              PEXP AND BVEXP                       19336015
         CLI   9(GRX),BVEXP                                             19344015
         BC    BE,AD5                                                   19352015
         SPACE                                                          19360013
         MVC   PAR1+2(2,GRDIC),7(GRX)  EXTRACT POINTER TO SLOT IN AN-   19440013
*        L     LR,ZDRFAB(0,GRCC)   OTHER DICT ENTRY AND CONVERT   62603 19480072
         BALR  RR,LR                 IT TO ABSOLUTE                     19520013
         L     GRX,PAR1(0,GRDIC)                                        19560013
         L     GRY,SYMBLK              CONVERT POINTER TO SECOND FILE   19600013
         ST    GRY,PAR1(0,GRDIC)     TO SYMBOLIC.                       19640013
         ST    GRSP,PAR2(0,GRDIC)                                       19680013
         L     LR,ZTXTRF(0,GRCC)                                        19720013
         BALR  RR,LR                                                    19760013
         MVC   0(3,GRX),PAR1+1(GRDIC)  MOVE IT INTO THE DICTIONARY SLOT 19800013
         SPACE 2                                                        19840013
AD5      LA    GRSP,3(0,GRSP)          BUMP POINTER BY THREE AND RETURN 19880013
         BC    B,AC2                 TO EXAMINE NEXT BYTE.              19920013
         SPACE 3                                                        19960013
B1       EQU   *                                                        20000013
         SPACE 5                                                        20040013
*              THE ABSOLUTE POINTER TO THE NEXT AVAILABLE TEXT BYTE     20080013
*        AND THE NUMBER OF BYTES LEFT IN THE BLOCK ARE SAVED FOR THE    20120013
*        STRUCTURE PROCESSOR.                                           20160013
         SPACE 2                                                        20200013
         ST    GRSP,NXTBYT                                              20240013
         SPACE                                                          20280013
         L     LR,ZBLSIZ(0,GRDIC)      SUBTRACT 1+OFFSET ON NEXT AVAIL- 20320013
         SH    LR,ZLSTXT+2(0,GRDIC)  ABLE BYTE FROM BLOCK SIZE, TO GIVE 20360013
         SR    LR,UR                 NUMBER OF BYTES LEFT IN THIS BLOCK 20400013
         ST    LR,BYTSFR               SAVE RESULT                      20440013
         EJECT                                                          20480013
*              DICTIONARY SCAN                                          20520013
*                                                                       20560013
*              FUNCTION.  THE DICTIONARY IS SCANNED.  ANY ENTRIES WITH  20600013
*        THE 'NOT REQUIRED IN SCAN' BIT ON IN THEIR FIRST, IDENTIFYING, 20640013
*        CODE BYTE ARE SKIPPED.  FOR OTHER ENTRIES THE CODE BYTE IS     20680013
*        TRANSLATED INTO AN OFFSET IN A LIST OF BRANCH INSTRUCTIONS.    20720013
*        THE APPROPRIATE BRANCH TO THE ROUTINE FOR PROCESSING THE       20760013
*        ENTRY IS THEN TAKEN.                                           20800013
*                         WHEN THE END OF THE DICTIONARY IS REACHED,    20840013
*        SCRATCH CORE IS RELEASED AND CONTROL RETURNED TO COMPILER      20880013
*        CONTROL.                                                       20920013
*                                                                       20960013
*              ENTRY POINTS - (1) B1A FOR INITIALISATION.               21000013
*                             (2) B2.  CONTROL IS RETURNED TO THIS      21040013
*        POINT WHEN AN ENTRY HAS BEEN PROCESSED.  THE ENTRY IS SKIPPED  21080013
*        AND THE NEXT EXAMINED.                                         21120013
*                                                                       21160013
*              EXTERNAL ROUTINES - (1) ZDRFAB, FOR GETTING NEXT DICT-   21200013
*        IONARY BLOCK.                                                  21240013
*                                  (2) ZURC, FOR RELEASING SCRATCH CORE 21280013
*                                  (3) RLSCTL FOR RELEASING CONTROL     21320013
*                                                                       21360013
*              EXITS, NORMAL - (1) ONE OF LIST OF BRANCHES FOLLOWING    21400013
*        TRANSLATION.                                                   21440013
*                              (2) UPON RELEASING CONTROL.              21480013
*                                                                       21520013
*              EXITS, ERROR - FOLLOWING TRANSLATION, IN THE EVENT OF    21560013
*        AN UNRECOGNISED CODE BYTE BEING FOUND.                         21600013
*                                                                       21640013
*              TABLES/WORK AREAS - TRANSLATE TABLE 'CDETAB' AT END OF   21680013
*        PHASE IS USED FOR FINDING OFFSET OF BRANCHING VECTOR TO        21720013
*        APPROPRIATE ROUTINE.  THERE ARE OTHER CONSTANTS AND SOME CODE  21760013
*        IN THE SPACE IN  THE TABLE CORRESPONDING TO CODE BYTES WITH    21800013
*        THE 'NOT REQUIRED IN SCAN' BIT ON. (THESE BYTES ARE NOT        21840013
*        TRANSLATED).                                                   21880013
*                                                                       21920013
*              NOTES - N/A                                              21960013
         SPACE 5                                                        22000013
B1A      LA    GRSP,ENDICT             MAKE A DICTIONARY ENTRY, WITH    22040013
         ST    GRSP,PAR1(0,GRDIC)    A SPECIAL CODE BYTE, TO MARK THE   22080013
         LA    GRSP,4                PRESENT END OF THE DICTIONARY      22120013
         ST    GRSP,PAR2(0,GRDIC)                                       22160013
         SPACE                                                          22200013
         L     LR,ZDICRF(0,GRCC)                                        22240013
         BALR  RR,LR                                                    22280013
         SPACE                                                          22320013
         LA    GRSP,FSTDRF-1(0,GRDIC)  INITIALISE SCAN POINTER TO POINT 22360013
*                                    1 SHORT OF SYMBOLIC POINTER TO     22400013
*                                      START OF DICTIONARY.             22440013
BD3      MVC   ZLOCK(2,GRDIC),1(GRSP)  LOCK IN NEW BLOCK                22480013
         SPACE                                                          22520013
B1B      LH    GRSP,ZLOCK(0,GRDIC)     PICK UP REFERENCE TO NEXT BLOCK  22560013
         STH   GRSP,PAR1+2(0,GRDIC)  AND CONVERT IT TO ABSOLUTE         22600013
         L     LR,ZDRFAB(0,GRCC)                                        22640013
         BALR  RR,LR                                                    22680013
         L     GRSP,PAR1(0,GRDIC)      RESET SCAN POINTER               22720013
         SPACE                                                          22760013
BC2      CLI   0(GRSP),EODB            IS THIS THE END OF A DICTIONARY  22800013
         BC    BE,BD3                BLOCK                              22840013
         LA    GRSP,3(0,GRSP)          BUMP POINTER TO FULL WORD BOUND- 22880013
         N     GRSP,BDYMSK           ARY.                               22920013
         CLI   0(GRSP),X'4D'                                            22960013
         BC    BE,G3                                                    23000013
         CLI   0(GRSP),X'C3'           IF COMPILER LABEL ADD TO STATIC  23040013
         BC    BE,G3Y                CHAIN, IF VALID.             16691 23080017
         CLI   0(GRSP),X'CE'           IS IT LABEL BCD ENTRY. IF SO ADD 23120013
         BC    BNE,BC3               TO ST ATIC CHAINIF ENTRY FOR LABEL 23160013
         CLI   2(GRSP),10            VARIABLE. IF FOR LABEL CONSTANT    23200013
         BC    BE,G3                 IGNORE                             23240013
BC3      EQU   *                                                        23280013
         SPACE                                                          23320013
         TM    0(GRSP),NRIS            IS THE 'NOT REQUIRED IN SCAN'    23360013
         BC    BZ,CB2                BIT ON                             23400013
         SPACE 2                                                        23440013
B2       LR    GRX,GRSP                SAVE POINTER TO START OF ENTRY   23480013
         MVC   FW+2(2),1(GRSP)         BUMP ORIGIONAL POINTER BY FIRST  23520013
         AH    GRSP,FW+2             LENGTH                             23560013
         SPACE                                                          23600013
         TM    0(GRX),BCDAPP           IS THERE A BCD APPENDED          23640013
         BC    BO,BC2                                                   23680013
         SPACE                                                          23720013
         IC    GR2,0(0,GRSP)           IF SO, PICK UP BCD LENGTH-1      23760013
         LA    GRSP,2(GR2,GRSP)      BUMP POINTER TO END OF ENTRY.      23800013
         BC    B,BC2                                                    23840013
         SPACE 5                                                        23880013
FUNAM    DC    C'FU'                                                    24080015
*                                                                       24280015
FTFIN    L     GRD,FUBAS                                                24480015
         BC    B,FTFINA                                                 24680015
CB2      L     GRD,FUBAS                                                25080013
         TRT   0(0,GRSP),CDETAB                                         25120013
         BC    BZ,FTERR1                                                25160013
TRVECT   BC    B,TRVECT(2)          BRANCH TO APPROPRIATE ROUTINE.      25200013
         BC    B,DATVAR                DATA VARIABLE                    25240013
         BC    B,STRUCT                STRUCTURE                        25280013
         BC    B,EVLABV                EVENT OR LABEL VARIABLE          25320013
         BC    B,CONST                 CONSTANT                         25360013
         BC    B,G3X                   LABEL CONSTANT                   25400013
         BC    B,QA3                   ENTRY TYPE 2                     25440013
         BC    B,QA1                                                    25480013
         BC    B,QA4                   PROCEDURE AND BEGIN ENTRY TYPE 1 25520013
         BC    B,FORPAR                FILE PARAMETERS                  25560013
         BC    B,QA2                   ENTRY TYPE 3                     25600013
*                                    LABEL OR BUILTIN OR BUILTIN GEN.   25640013
         BC    B,QX                                                     25680013
         BC    B,G3                    FILE ENTRY - PUT IN STATIC CHAIN 25720013
         BC    B,B2                    ENTRY TYPE 1 FOR ENTRY STATEMENT 25760013
*                                    - SKIP IT.                         25800013
         BC    B,FTFIN                 FIRST ENTRY CREATED BY FT.       25840013
         EJECT                                                          25880013
*              ROUTINE FOR PROCESSING DATA AND LABEL VARIABLES.         25920013
*                                                                       25960013
*              FUNCTION - (1)  PROCESS ANY ASSOCIATED PICTURE, USING    26000013
*        ROUTINE PROPIC.                                                26040013
*                         (2)  SETS UP ELEMENT LENGTH FOR DIMENSION     26080013
*        TABLE ROUTINE.                                                 26120013
*                         (3)  THE SYMBOL BIT IS SET ON, IF NECESSARY.  26160013
*                         (4)  SETS'DOPE VECTOR REQUIRED' BIT.          26200013
*                                                                       26240013
*              ENTRY POINTS - DATVAR, FOR DATA ITEMS                    26280013
*                             EVLAB, FOR EVENTS OR LABEL VARIABLES.     26320013
*                                                                       26360013
*              EXTERNAL ROUTINES - ZDRFAB AND ZDICRF, IN COMPILER       26400013
*        CONTROL.  P1A, FOR DECIDING WHETHER, OR NOT, THE 'DOPE VECTOR  26440013
*        REQUIRED' BIT NEED BE SET ON.                                  26480013
*                                                                       26520013
*              EXITS - NORMAL - AFTER CYMBAL - RETURNS TO DICTIONARY    26560013
*        SCAN.                                                          26600013
*                               AFTER DG2 - GOES TO EXTEND IN STORAGE   26640013
*        CLASS CHAIN.                                                   26680013
*                               AT END OF ROUTINE - 'FALLS THROUGH' TO  26720013
*        DIMENSION TABLE ROUTINE.                                       26760013
*                                                                       26800013
*              EXITS - ERROR - NONE.                                    26840013
*                                                                       26880013
*              NOTES - NONE                                             26920013
*        SPACE 5                                                        26960013
DATVAR   MVI   UNCOM,OFF               INITIALIZE 'UNCOMMON' FLAG. H275 26964001
         SPACE                                                          26968001
*        IF THIS DATA VARIABLE IS FIXED BIN(15,0) THEN A           H275 26972001
*        WARNING MESSAGE IS PUT OUT.                               H275 26976001
         SPACE                                                          26980001
HLFMSG   BC    NOP,DD6                                             H275 26984001
         TM    OTHER2(GRSP),X'08'      IS IT A PARAMETER          52204 26985021
         BO    DD6A                    BRANCH IF SO               52204 26985421
         TM    0(GRSP),X'80'           IS THERE A BCD ATTACHED    52204 26985821
         BO    DD6                     NO - D.E. FOR PARM ATTRIBS 52204 26986221
*                                    IN ENTRY SPECIFICATION.      52204 26986621
*                                    DO NOT ISSUE MESSAGE.        52204 26987021
DD6A     EQU   *                                                  52204 26987421
         TM    DATA(GRSP),X'8C'        NUMERIC/CAD, SHORT & BINARY?H275 26988001
         BNO   DD6                     NO.                         H275 26992001
         TM    DATA(GRSP),X'52'        FIXED, SHORT, NOT POINTER   H275 26998001
         BNE   DD6                     OR OFFSET?    NO.           H275 27004001
         CLI   16(GRSP),X'0F'          IS IT HALF WORD           34341  27006020
         BH    DD6                     NO                        34341  27008020
         MVC   PAR6(4,GRDIC),HALFWD    PUT OUT WARNING MSG.        H275 27012001
         L     LR,ZUERR(GRCC)                                      H275 27016001
         BALR  RR,LR                                               H275 27020001
         MVI   HLFMSG+1,X'F0'                                      H275 27024001
         MVI   QA31+1,X'F0'            PUT OUT MESS ONCE                27026020
DD6      EQU   *                                                   H275 27028001
         SPACE                                                          27040013
*              FIRST LOOK AT THE ENTRY TO SEE IF THE UNALIGNED PHASE I1 27041016
*        WILL BE NEEDED. IF THE ENTRY IS STRING IT WONT BE NEEDED.   I1 27042016
*        THE SWITCH 'UNALSW' IS LOOKED AT BY ROUTINE MARKIX IN FU.   I1 27043016
*              TEST DATA BYTE FOR STRINGS                            I1 27044016
         TM    DATA(GRSP),X'80'                                      I1 27045016
*              BRANCH IF STRING                                      I1 27046016
         BC    BZ,DD1                                                I1 27047016
*              TEST FOR UNALIGNED                                    I1 27048016
         TM    OTHER4(GRSP),X'08'                                    I1 27049016
*              BRANCH IF ALIGNED                                     I1 27050016
         BC    BO,DD1                                                I1 27051016
         TM    DATA(GRSP),X'08'        IS IT NUMERIC PICTURE       H146 27051317
         BC    BNO,DD1               BRANCH ON YES.                H146 27051617
*              SET UNALIGNED SWITCH ON                               I1 27052016
         MVI   UNALSW,ON                                             I1 27053016
        SPACE 1                                                         27054016
DD1      EQU   *                                                     I1 27055016
         LA    GRP,DIDATA(GRSP)   POINT AT DATA BYTE                    27060015
         L     GRD,FUBAS          LOAD BASE OF FU                       27080015
         LA    GRW,DD2            SET POSS RETURN ON GRW                27100015
         BAL   RR,PROPIC                                                27120015
         SPACE 1                                                        27160013
*              IF ITEM IS LONG FLOAT SCALAR CONTROLLED VARIABLE SET     27200013
*        FLAG TO SAY GOOD VALUE IN OFFSET1 SLOT.                        27240013
         TM    OTHER2(GRSP),X'03'      CONTROLLED                       27280013
         BC    BNO,DD2                 NO                               27320013
         TM    DIDATA(GRSP),X'80'      IS IT STRING                     27360013
         BC    BNZ,DD2C                BRANCH IF NOT                    27400013
         TM    VAR(GRSP),X'01'         IS D.R. FROM ALLOCATE STATEMENT  27440013
         BC    BNZ,DD2               BRANCH IF SO                       27480013
         CLI   ALLSTR,ON                                                27520013
         BC    BE,DD2                                                   27560013
*        IF BOTH CTL AND DEFINED BITS ON, THEN VAR IS BASED VAR         27570015
         TM    VAR(GRSP),X'02'         IS IT DEFINED                    27580015
         BC    BO,DD2                  BRANCH IF BASED VAR              27590015
         OI    DIDATA(GRSP),X'40'      IF SO SET ADJUSTABLE LENGTH BIT  27600013
         BC    B,DD2                 ON                                 27640013
DD2C     TM    0(GRSP),X'10'         IS IT DIMENSIONED                  27680013
         BC    BO,DD2                BRANCH IF YES                      27720013
         TM    DIDATA(GRSP),X'92'    IS IT LONG FLOAT                   27760013
         BC    BNO,DD2                 NO                               27800013
         TM    OTHER2(GRSP),X'08'    TEST FOR PARAMETER                 27810015
         BC    BO,DD2                BRANCH IF SO                       27820015
         OI    OTHER3(GRSP),X'02'      SET 'GOOD VALUE IN OFFSET 1      27840013
*                                    SLOT' FLAG                         27880013
         SPACE                                                          28200013
DD2      LA    GRW,DIVARI(0,GRSP)    ENTRY INTO DICT ENTRY AND SET UP   28240013
*                                      POINTER TO VARIABLE INFORMATION. 28280013
         TM    DIDATA(GRSP),X'D0'      IS ITEM FOR OFFSET?         H172 28288001
         BC    BO,DD3                  YES.                        H172 28296001
         TM    DIDATA(GRSP),X'C0'      IS ITEM FOR POINTER?        H172 28304001
         BC    BO,DD3                                              H172 28312001
         TM    DIDATA(GRSP),X'80'      IS ITEM NUMERIC?            H172 28320001
         BC    BO,DD2B                 YES.                        H172 28328001
         TM    DIDATA(GRSP),X'0E'      IS ITEM FOR AREA?           H172 28336001
         BC    BO,DD3                                              H172 28344001
DD2B     TM    0(GRSP),X'80'           IS 'BCD' BIT ON?            H172 28352001
         BC    BO,DD3                  IF SO, DO NOT SET SYMBOL BIT     28360013
         TM    CDEBYT+2(GRSP),8        IS THIS AN F.P. (IN A STRUCTURE) 28400013
         BC    BO,DD3                  BRANCH IF SO                     28440013
         SPACE                                                          28480013
         TM    VAR(GRSP),3             IS ITEM DEFINED OR ALLOCATED     28520013
         BC    BNZ,DD3                                                  28560013
         TM    0(GRSP),X'20'           IS IT A MEMBER OF A STRUCTURE    28600013
         BC    BZ,CYMBAL                                                28640013
         CLI   ALLSTR,X'00'            IF SO, IS IT ALLOC/DEFN?    H172 28680001
         BC    BNE,DD3                 IF SO, DONT SET SYMBOL BIT  H172 28720001
         SPACE                                                          28760013
CYMBAL   L     GRD,FUBAS               RESTORE BASE REGISTER OF FU      28800013
******                                                           ****** 28840013
*                                                                     * 28880013
* FOLLOWING INSTRUCTION MAY BE A 'BAL' IF PUT DATA IS ABSENT          * 28920013
*                                                                     * 28960013
******                                                           ****** 29000013
INCLUD   BC    NOP,INMATE              CALL INCLUDE-MATRIX ROUTINE      29040013
******                                                           ****** 29080013
         BC    B,DD3                                                    29120013
         SPACE                                                          29160013
*              TEST FOR THE PRESENCE OF LABEL INITIALISATION FOR THIS   29200013
*        VARIABLE                                                       29240013
EVLABV   TM    0(GRSP),X'08'           IF THIS IS AN EVENT, GO TO       29280013
         BC    BNO,NOTSK             INSERT IN STORAGE CLASSS CHN       29290015
         LA    GRX,32(0,0)           SAVE ELEMENT LENGTH                29300015
         STH   GRX,ELTLTH            OF EVENT IN SLOT                   29310015
         TM    0(GRSP),X'01'         IS IT TASK                         29320015
         BC    BO,DD2D               BRANCH IF SO                       29330015
         BAL   RR,BCDENT             TASK VARABLE                       29340015
         BC    B,DD2D                                                   29350015
NOTSK    TM    0(GRSP),X'10'           IF NOT ARRAY,THIS KIND OF INIT.  29360015
         BC    BZ,DD2A               CANNOT HAPPEN                      29400013
*                                                                       29440013
         LA    GRW,VARINF(GRSP)        POINT GRW AT START OF VARIABLE   29480013
*                                    INFORMATION                        29520013
         TM    VAR(GRSP),X'80'                                          29560013
         BC    BZ,DD3A                                                  29600013
         LA    GRW,4(GRW)                                               29640013
*              GRW NOW POINTS AT START OF DIMENSION SLOT                29680013
DD3A     XR    GRX,GRX                                                  29720013
         IC    GRX,0(GRW)                                               29760013
         STH   GRX,DIMNO               STORE NUMBER OF DIMENSIONS       29800013
         LA    GRW,3(GRW)              BUMP GRW OVER DIMENSION SLOT     29840013
         TM    VAR(GRSP),X'20'                                          29880013
         BC    BZ,DD4                  BRANCH IF UNSTRUCTURED           29920013
         LA    GRW,10(GRW)             BUMP GRW OVER STRUCTURE INFO     29960013
DD4      TM    VAR(GRSP),X'10'                                          30000013
         BC    BZ,DD5                                                   30040013
         LA    GRW,2(GRW)                                               30080013
DD5      TM    3(GRW),X'FF'            TEST IF INITIAL LABEL STATEMENTS 30120013
         L     GRD,FUBAS             FOR THIS VARIABLE. IF SO GO TO     30160013
         BC    BO,FULIN              MOVE THEM TO THE SECOND FILE,      30200013
*                                    RETURNING TO DD2A                  30240013
         SPACE 2                                                        30280013
DD2A     LA    GRX,8(0,0)                                               30320015
         STH   GRX,ELTLTH            SAVE ELEMENT LENGTH                30360015
DD2D     LA    GRW,ELVAR(0,GRSP)                                        30400015
         MVI   UNCOM,OFF               INITIALISE 'UNCOMMON' FLAG       30440013
         SPACE                                                          30480013
DD3      EQU   *                                                        30520013
         SPACE                                                          30560013
         TM    CDEBYT+1(GRSP),STRBIT   RESUME DICTIONARY SCAN IF MEMBER 30600013
         BC    BO,B2                 OF STRUCTURE                       30640013
         BAL   RR,P1A                                                   30680013
         OI    CDEBYT+3(GRSP),X'80'                                     30720013
         SPACE 2                                                        30760013
DG2      TM    CDEBYT+1(GRSP),DIMED    IS ENTRY DIMENSIONED             30800013
         BC    BZ,G1                                                    30840013
         SPACE                                                          30880013
         TM    CDEBYT(GRSP),ADJDIM     IS ENTRY ADJUSTABLY DIMENSIONED. 30920013
         BC    BO,G1                   IF SO, GO STRAIGHT TO STORAGE    30960013
*                                    CLASS ROUTINE.                     31000013
         SPACE                                                          31040013
         MVI   ELTLTH-1,0              INITIALISE FLAG BYTE             31080013
         TM    0(GRSP),X'0C'         TEST FOR                           31090015
         BC    BNO,EXTCON            EVENT AND TASK VARIABLES           31100015
         TM    0(GRSP),X'02'                                            31110015
         BC    BZ,DG2B               SET ON UNCOM FLAG IF SO            31120015
EXTCON   TM    CDEBYT+2(GRSP),X'06'  IS IT EXT OR CONTROLLED            31130015
         BC    BNZ,DG2B                BRANCH IF SO                     31160013
         TM    CDEBYT+2(GRSP),8        IS THIS AN F.P.                  31200013
         BC    BO,DG2B                 BRANCH IF SO.                    31240013
         TM    CDEBYT+1(GRSP),2        IS ITEM DEFINED.                 31280013
         BC    BZ,DG2A                                                  31320013
DG2B     EQU   *                                                        31360013
         MVI   UNCOM,ON                IF SO, SET FLAG TO ENSURE ITS    31400013
         BC    B,EH1                 DIMENSION TABLE IS UNCOMMONED.     31440013
DG2A     TM    0(GRSP),X'0F'           IS IT A DATA ITEM.               31480013
         BC    BNO,EH1                 IF NOT, ELEMENT LENGTH ALREADY   31520013
*                                    SET                                31560013
         TM    DIDATA(GRSP),PICBIT     IS ITEM PICTURED                 31600013
         BC    BZ,DG2B                 BRANCH IF SO.                    31640013
         SPACE 2                                                        31680013
E1       TM    DIDATA(GRSP),X'80'                                       31720013
         BC    BO,EE1                                                   31760013
         TM    DIDATA(GRSP),X'52'    IS IT ADJ LGTH OR VARYING OR AREA  31800015
         BC    BZ,EC2                STRING. IF NOT. GO TO PICK UP      31840013
*                                    LENGTH.                            31880013
         MVI   UNCOM,ON                OTHERWISE, SET FLAG TO UNCOMMON  31920013
*                                    DIMENSION TABLE.                   31960013
         BC    B,EH1                                                    32000013
         SPACE                                                          32040013
EE1      TM    DIDATA(GRSP),FLOAT      IS DATA FIXED                    32080013
         BC    BZ,EE2                                                   32120013
         LA    GR2,8                   SET ELEMENT LENGTH TO 8          32160013
         SPACE                                                          32200013
         TM    DIDATA(GRSP),LONG       IS DATA LONG                     32240013
         BC    BO,EE1A                                                  32280013
EE1C     LA    GR2,4                   IF NOT, RESET ELEMENT LENGTH TO  32320013
*                                    FOUR.                              32360013
         SPACE                                                          32400013
EE1A     TM    DIDATA(GRSP),CPLX       IS DATA COMPLEX                  32440013
         BC    BZ,EE1B                                                  32480013
         AR    GR2,GR2                 IF SO DOUBLE ELEMENT LENGTH      32520013
EE1B     STH   GR2,ELTLTH                                               32560013
         BC    B,EH1                                                    32600013
         SPACE                                                          32640013
EE2      TM    DIDATA(GRSP),BINARY     IS DATA BINARY                   32680013
         BC    BNO,EE3                 GO TO SET LENGTH                 32690001
         TM    DIDATA(GRSP),X'40'      * IS THIS A POINTER OR     62603 32693072
         BO    EE1C                    * OFFSET, YES, GOTO EE1C   62603 32696072
         SPACE 1                                                        32700001
         TM    DIDATA+1(GRSP),X'F0'    IS P > 15                        32710001
         BC    BNZ,EE1C                GO IF SO TO SET LENGTH OF 4      32720001
         LA    GR2,2                   SET LENGTH OF 2                  32730001
         BC    B,EE1A                  GO TO TEST FOR CPLX              32740001
         SPACE 1                                                        32750001
EE3      IC    GR2,DIDATA+1(GRSP)      SET LENGTH                       32760001
         LA    GR2,2(0,GR2)                                             32840013
         SRA   GR2,1                                                    32880013
         BC    B,EE1A                                                   32920013
         SPACE 3                                                        32960013
         SPACE                                                          33000013
EC2      MVC   ELTLTH(2),DIDATA+1(GRSP) INSERT ELEMENT LENGTH           33040013
         TM    DIDATA(GRSP),CHAR       IS IT A STRING                   33080013
         BC    BO,EH1                                                   33120013
         MVI   ELTLTH-1,X'80'          SET FLAG BIT ON TO PREVENT       33160013
*                                    COMMONING WITH CHAR STRING.        33200013
         OC    ELTLTH-1(1),DIDATA(GRSP)   AND SET BIT ON, IF ALIGNED,   33240013
*                                    TO PREVENT COMMONING WITH PACKED   33280013
*                                    BIT STRINGS.                       33320013
EH1      TM    CDEBYT+1(GRSP),X'80'    IS THE 'SECOND OFFSET' PRESENT   33360013
         BC    BZ,*+8                IF SO BUMP VARIABLE POINTER TO     33400013
         LA    GRW,4(0,GRW)          NEXT OFFSET IN VAR. INFORMATION    33440013
         STH   GRZ,PAR1(0,GRDIC)                                        33480013
         MVC   PAR1+2(2,GRDIC),1(GRW)                                   33520013
         EJECT                                                          33560013
*              DIMENSION TABLE ROUTINE.                                 33600013
*                                                                       33640013
*              FUNCTION - AT THIS STAGE, DIMENSION TABLES ARE SHARED    33680013
*        BY IDENTIFIERS WITH SIMILAR ARRAY BOUNDS.  THEY MAY NOW ONLY   33720013
*        BE SHARED IF THE ELEMENT LENGTHS ALSO ARE THE SAME.  THIS      33760013
*        ROUTINE 'UNCOMMONS' DIMENSION TABLES WHERE NECESSARY BY MAKING 33800013
*        COPIES.                                                        33840013
*                                                                       33880013
*              ENTRY POINT - F0 - CONTROL PASSES SEQUENTIALLY FROM      33920013
*        PREVIOUS CODE.                                                 33960013
*                                                                       34000013
*              EXTERNAL ROUTINES - ZDRFAB, FOR FINDING DIMENSION TABLE. 34040013
*                                  ZDICRF, FOR COPYING DIMENSION TABLE. 34080013
*                                                                       34120013
*              EXITS - NORMAL - STRAIGHT-FORWARD BRANCHES TO G1 OR G1A  34160013
*                                                                       34200013
*              EXITS - ERROR - NONE.                                    34240013
*                                                                       34280013
*              NOTES - THE FOLLOWING FLAGS ARE USED -                   34320013
*                       (1)  UNCOM.  THIS IS SET ON BEFORE THE ROUTINE  34360013
*        IS ENTERED, WHEN IT IS ALREADY KNOWN THAT THE DIMENSION TABLE  34400013
*        MUST BE UNCOMMED BECAUSE  (A)  THE ELEMENT IS A STRING OF      34440013
*        ADJUSTABLE LENGTH.                                             34480013
*                                  (B)  THE ARRAY ISDEFINED.            34520013
*                                  (C)  THE ELEMENT LENGTH IS DEFINED   34560013
*        BY AN ERRONEOUS PICTURE.                                       34600013
*                       (2)  THE 'USED' FLAG.  THIS IS A BIT SET ON     34640013
*        IN A DIMENSION TABLE WHEN IT HAS HAD A DEFINITE ELEMENT LENGTH 34680013
*        ASSOCIATED WITH IT                                             34720013
*                       (3)  THE 'REPEATED' FLAG.  THIS IS A BIT SET    34760013
*        ON IN A DIMENSION TABLE WHICH HAS BEEN DUPLICATED ALREADY.     34800013
*                       (4)  THE 'DO NOT COMMON' FLAG.  THIS IS A BIT   34840013
*        SET ON IN A DIMENSION TABLE WHICH MUST NOT BE SHARED BY OTHER  34880013
*        ARRAYS.                                                        34920013
         SPACE 5                                                        34960013
F0       L     LR,ZDRFAB(0,GRCC)                                        35000013
         BALR  RR,LR                                                    35040013
         L     GRP,PAR1(0,GRDIC)       SET UP POINTER TO DIMENSION      35080013
*                                    TABLE                              35120013
         SPACE                                                          35160013
         SPACE                                                          35200013
F1       TM    3(GRP),X'80'            IS THE 'USED' FLAG ON            35240013
         BC    BO,FC3                                                   35280013
         SPACE                                                          35320013
FD1      OI    3(GRP),X'80'            IF NOT, SET 'USED' FLAG ON       35360013
         SPACE                                                          35400013
FD2      CLI   UNCOM,OFF               IS 'UNCOMMON' FLAG OFF.          35440013
         BC    BE,G1A                  IF SO, GO TO INSERT ELEMENT      35480013
*                                    LENGTH IN THE DIMENSION TABLE      35520013
         SPACE                                                          35560013
FE2      OI    3(GRP),X'40'            OTHERWISE, SET THE 'DO NOT       35600013
*                                    COMMON FLAG' ON.                   35640013
         BC    B,G1                                                     35680013
         SPACE 3                                                        35720013
FC3      CLI   UNCOM,ON                IS 'UNCOMMON' FLAG ON            35760013
         BC    BE,FD4                  IF SO, GO TO REPEAT T ABLE       35800013
         TM    3(GRP),X'40'            IS THE 'DO NOT COMMON' FLAG ON   35840013
         BC    BZ,FC4                                                   35880013
FD3      TM    3(GRP),X'20'            IS THE 'REPEATED' BIT ON         35920013
         BC    BZ,FD4                  IF NOT, GO AND CREATE NEW TABLE  35960013
         LH    GRX,6(0,GRP)            OTHERWISE, PICK UP POINTER TO    36000013
         ST    GRX,PAR1(0,GRDIC)     NEXT TABLE AND CONVERT IT          36040013
         MVC   1(2,GRW),PAR1+2(GRDIC)                                   36080013
         BC    B,F0                                                     36120013
         SPACE 2                                                        36160013
*              ELEMENT LENGTHS ARE NOW COMPARED. IF THEY ARE THE SAME   36200013
*        THERE IS NOTHING TO BE DONE. IF DIFFERENT, THE NEXT TABLE WITH 36240013
*        SIMILAR DIMENSIONS (THE PRESENCE OF WHICH IS INDICATED BY THE  36280013
*        'REPEATED' BIT) IS TRIED.                                      36320013
FC4      CLC   ELTLTH-1(3),9(GRP)      COMPARE ELEMENT LENGTHS, AND THE 36360013
*                                    ALIGNED BIT STRING FLAG BITS.      36400013
         BC    BE,G1                                                    36440013
         BC    B,FD3                                                    36480013
         SPACE                                                          36520013
FD4      MVC   PAR2+2(2,GRDIC),1(GRP)  PICK UP LENGTH OF ENTRY TO BE    36560013
         STH   GRZ,PAR2(0,GRDIC)     COPIED                             36600013
         ST    GRP,PAR1(0,GRDIC)                                        36640013
         L     LR,ZDICRF(0,GRCC)                                        36680013
         BALR  RR,LR                                                    36720013
         SPACE                                                          36760013
         OI    3(GRP),X'20'            SET 'REPEATED' BIT ON IN         36800013
*                                    ORIGIONAL ENTRY. (MUST NOT BE DONE 36840013
*                                    BEFORE MAKING COPY)                36880013
         MVC   6(2,GRP),PAR1+2(GRDIC)  SET CHAIN IN ORIGIONAL TABLE     36920013
*                                    TO NEW ONE                         36960013
         MVC   1(2,GRW),PAR1+2(GRDIC)  SET POINTER IN DICTIONARY ENTRY  37000013
         L     LR,ZDRFAB(0,GRCC)     FOR ITEM TO NEW TABLE. CONVERT     37040013
         BALR  RR,LR                 POINTER TO ABSOLUTE.               37080013
         SPACE                                                          37120013
         L     GRP,PAR1(0,GRDIC)       SET UP POINTER TO NEW TABLE AND  37160013
         BC    B,FD1                 GO TO INSERT ELEMENT LENGTH ETC.   37200013
         EJECT                                                          37240013
*              THE CURRENT ENTRY IS NOW INSERTED IN THE APPROPRIATE     37280013
*        STORAGE CLASS                                                  37320013
         SPACE 2                                                        37360013
         SPACE                                                          37400013
G1A      MVC   9(3,GRP),ELTLTH-1       INSERT ELEMENT LENGTHS, AND      37440013
*                                    FLAG BYTE INTO THIRD               37480013
*                                    WORD OF THE DIMENSION TABLE.       37520013
         NI    3(GRP),X'FB'            SET 'DO NOT COMMON' FLAG OFF     37560013
G1       TM    CDEBYT+2(GRSP),X'08'    IS F.P. BIT ON                   37600013
         BC    BO,FORPAR                                                37640013
         SPACE                                                          37680013
G5       TM    CDEBYT+2(GRSP),X'03'    TEST FOR -                       37720013
         BC    BO,GE1                             CONTROLLED            37760013
         BC    BM,G3                              STATIC                37800013
*                                                 AUTOMATIC             37840013
G2       IC    GR2,2(0,GRSP)                                            37880013
         SR    GR2,UR                                                   37920013
         IC    GR2,0(GRSP,GR2)         USE IT TO PICK UP BLOCK COUNT    37960013
G2A      LA    GRY,0(GR2,GR2)          DOUBLE GR2 INTO GRY              38000013
G4       L     GRX,ZHASH(0,GRDIC)      PICK UP POINTER TO ENTRY TYPE 1  38040013
*                                    STACK (IT OVERWRITES THE HASH      38080013
*                                    TABLE).                            38120013
         LH    GRX,0(GRY,GRX)          USE BLOCK COUNT TO FIND REFER-   38160013
         ST    GRX,PAR1(0,GRDIC)     ENCE OF HEADING E1 ENTRY.          38200013
         SPACE                                                          38240013
         L     LR,ZDRFAB(0,GRCC)       CONVERT IT TO ABSOLUTE.          38280013
         BALR  RR,LR                                                    38320013
         SPACE                                                          38360013
         L     GRX,PAR1(0,GRDIC)       SET UP POINTER TO ENTRY TYPE 1   38400013
         SPACE                                                          38440013
         MVC   3(2,GRSP),E1AUTO(GRX)   MOVE START OF CHAIN INTO ENTRY'S 38480013
*                                    HASH SLOT                          38520013
         SPACE                                                          38560013
*              CONVERT POINTER TO ENTRY TO SYMBOLIC                     38600013
G4A      ST    GRSP,PAR2(0,GRDIC)      STORE ABSOLUTE POINTER IN PARI   38640013
         MVC   PAR1+2(2,GRDIC),ZLOCK(GRDIC) MOVE IN SYMBOLIC NAME       38680013
         L     LR,ZDABRF(0,GRCC)                                        38720013
         BALR  RR,LR                                                    38760013
         MVC   E1AUTO(2,GRX),PAR1+2(GRDIC) RESET START OF CHAIN TO      38800013
*                                    POINT TO THIS ENTRY.               38840013
         CLI   0(GRSP),EFIVE           IS IT AN ENTRY TYPE 5.           38880013
         BC    BE,FP1                  IF SO, POINTER TO F.P. TYPE 1    38920013
*                                    MUST BE MOVED TO OVERWRITE L&C.    38960013
         BC    B,B2                                                     39000013
         SPACE 2                                                        39040013
         SPACE 2                                                        39080013
*              EXTEND CONTROLLED CHAIN.                                 39120013
         SPACE                                                          39160013
GE1      MVC   3(2,GRSP),ZCITEM(GRDIC) MOVE HEAD OF CHAIN INTO NEW      39200013
*                                    ENTRY                              39240013
*              CONVERT REFERENCE OF ENTRY TO SYMBOLIC                   39280013
         SPACE                                                          39320013
         ST    GRSP,PAR2(0,GRDIC)                                       39360013
         MVC   PAR1+2(2,GRDIC),ZLOCK(GRDIC)                             39400013
         L     LR,ZDABRF(0,GRCC)                                        39440013
         BALR  RR,LR                                                    39480013
         MVC   ZCITEM(2,GRDIC),PAR1+2(GRDIC) RESET HEAD OF CHAIN        39520013
         BC    B,B2                                                     39560013
         SPACE 2                                                        39600013
*              PROCESS LABEL CONSTANT                                   39640013
         SPACE                                                          39680013
G3X      CLI   0(GRSP),1               IS THIS A LABEL                  39720013
         L     GRD,FUBAS                                                39740015
         LA    RR,G3                 SWT UP RETURN REG                  39760015
         BC    BH,CHKBCD             CHECK FOR CERTAIN BIFS             39780015
*                                                                 16691 39786017
G3Y      DS    0H                      SUBSCRIPTED LABEL PREFIX.  16691 39792017
         TM    OTHER1(GRSP),X'10'      IS ERROR BIT ON IN LABEL (SET    39800013
*                                    BY PHASE EG)                       39840013
         BC    BO,B2A                  IF SO IGNOER IT                  39880013
*                                      OTHERWISE INSERT IN STATIC CHAIN 39920013
         SPACE 2                                                        39960013
*              EXTEND STATIC CHAIN                                      40000013
         SPACE                                                          40040013
G3       MVC   3(2,GRSP),ZSTACH+4(GRDIC) MOVE HEAD OF CHAIN INTO NEW    40080013
*                                    ENTRY                              40120013
         MVC   PAR1+2(2,GRDIC),ZLOCK(GRDIC) CONVERT POINTER TO ENTRY    40160013
         ST    GRSP,PAR2(0,GRDIC)        TO ABSOLUTE                    40200013
         L     LR,ZDABRF(0,GRCC)                                        40240013
         BALR  RR,LR                                                    40280013
         SPACE                                                          40320013
         L     GRX,PAR1(0,GRDIC)                                        40360013
         STH   GRX,ZSTACH+4(GRDIC)                                      40400013
         BC    B,B2                                                     40440013
B2A      NI    OTHER1(GRSP),X'EF'                                       40480013
         BC    B,B2                                                     40520013
         EJECT                                                          40560013
*              'DOPE VECTOR REQUIRED' ROUTINE                           40600013
*                                                                       40640013
*              FUNCTION - TO DECIDE WHETHER OR NOT THE 'DOPE VECTOR     40680013
*        REQUIRED' BIT NEED BE SET ON.  IT NEED BE SET ON FOR THE       40720013
*        FOLLOWING -                                                    40760013
*                    (1)  ARRAYS AND STRINGS WITH ADJUSTABLE EXTENTS.   40800013
*                    (2)  CONTROLLED ARRAYS AND STRINGS.                40840013
*                    (3)  STATIC EXTERNAL ARRAYS AND STRINGS.           40880013
*                    (4)  VARYING ARRAYS AND STRINGS.                   40920013
*                    (5)  ALL DEFINED DATA (INCLUDING SCALARS).         40960013
*                    (6)  ARRAYS WITH THE INITIAL ATTRIBUTE.            41000013
*                    (7)  BIT STRINGS                                   41040013
*                    (8)  ALL ARRAYS AND STRINGS IF THE COMPILATION     41080013
*                         INCLUDES A READ DATA WITH NO LIST. (THIS IS   41120013
*                         INDICATED BY THE 'SYMBOL' BIT).               41160013
*                                                                       41200013
*              FORMAL PARAMETERS NEVER NEED DOPE VECTORS.               41240013
*                                                                       41280013
*              ENTRY POINT - P1A ENTERED WITH REGISTER RR AS RETURN     41320013
*        REGISTER AND WITH GRSP POINTING TO THE BEGINNING OF THE ENTRY. 41360013
*                                                                       41400013
*              EXTERNAL ROUTINES - NONE                                 41440013
*                                                                       41480013
*              EXITS, NORMAL - EITHER TO ADDRESS IN RETURN REGISTER, IN 41520013
*        THE EVENT OF D.V. BEING REQUIRED, OR, OTHERWISE, TO FOUR BYTES 41560013
*        BEYOND (THUS SKIPPING THE INSTRUCTION WHICH SETS THE BIT ON).  41600013
*                                                                       41640013
*              EXITS, ERROR - NONE                                      41680013
*                                                                       41720013
*              TABLES/WORK AREAS - NONE                                 41760013
*                                                                       41800013
*              NOTES - THE CASE OF A LABEL VARIABLE MUST BE ISOLATED    41840013
*        SINCE THERE IS NOT ANY DATA BYTE.                              41880013
         SPACE 5                                                        41920013
*              TESTS ARE NOW MADE TO FIND OUT WHETHER THE 'DOPE VECTOR  41960013
*        REQUIRED' BIT NEED BE SET ON.                                  42000013
         SPACE                                                          42040013
P1A      TM    CDEBYT+1(GRSP),2        IS ITEM DEFINED                  42080013
         BCR   BO,RR                   IF SO D.V. REQUIRED              42120013
         SPACE                                                          42160013
         TM    CDEBYT+3(GRSP),X'80'    IF D.V. BIT IS ALREADY ON RETURN 42200013
         BCR   BO,RR                 'D.V. REQUIRED' SO THAT, IN THE    42240013
*                                    CASE OF STRUCTURE MEMBERS, DVSW    42280013
*                                    IS SET ON.                         42320013
         SPACE                                                          42360013
         TM    CDEBYT+2(GRSP),8        IS F.P. BIT ON                   42400013
         BC    BZ,*+12                                                  42440013
         TM    CDEBYT+2(GRSP),3        IS IT CONTROLLED                 42480013
         BC    BNO,4(0,RR)             IF NOT, NO D.V. REQUIRED         42520013
         TM    0(GRSP),7               IS ITEM LABEL VARIABLE           42560013
         BC    BNO,P2                                                   42600013
         TM    0(GRSP),8                                                42640013
         BC    BO,P2                                                    42680013
         SPACE                                                          42720013
         TM    VAR(GRSP),X'48'         IF INITIALISED LABEL ARRAY, D.V. 42760013
         BCR   BO,RR                 REQUIRED.                          42800013
         SPACE                                                          42840013
         TM    0(GRSP),X'20'           IS IT STRUCTURED                 42880013
         BC    BO,P1B                                                   42920013
         TM    CDEBYT+1(GRSP),DIMED    OR DIMENSIONED                   42960013
         BC    BZ,4(0,RR)              IF NEITHER, NO D.V. REQUIRED     43000013
         TM    CDEBYT(GRSP),4          IS IT ADJ. DIMS.                 43040013
         BCR   BO,RR                   IF SO, D.V. REQUIRED             43080013
         SPACE                                                          43120013
P1B      BAL   GRX,STEXT               IF IT IS EITHER A DIMENSIONED    43160013
*                                    OR STRUCTURED LABEL VARIABLE       43200013
*                                    GO TO CHECK WHETHER IT IS STATIC   43240013
*                                    EXTERNAL, OR CONTROLLED.           43280013
         BC    B,4(0,RR)               IF NOT  NO D.V. REQUIRED         43320013
         SPACE 3                                                        43360013
P2        TM    0(GRSP),X'0C'          TEST FOR TASK OR EVENT           43368015
          BC   BNO,P2A                                                  43376015
          TM   0(GRSP),X'02'                                            43384015
          BC   BO,P2A                                                   43392015
          TM   0(GRSP),X'30'           TEST FOR DIM OR STRUCT MEMBER    43400015
          BCR  BNZ,RR                  DV REQD IF EITHER                43408015
          BC   B,4(RR)                 OTHERWISE NO DV REQD             43416015
P2A       TM   CDEBYT+1(GRSP),DIMED                                     43424015
         BC    BZ,P4                                                    43440013
         BAL   GRX,PSYMB                                                43480013
         TM    CDEBYT(GRSP),4          IS IT VARIABLE DIMS.             43520013
         BCR   BO,RR                                                    43560013
         TM    CDEBYT+1(GRSP),8        IS IT INITIAL                    43600013
         BCR   BO,RR                   IF SO, D.V. REQUIRED.            43640013
         SPACE 5                                                        43680013
P4       TM    DIDATA(GRSP),X'80'      IS IT A STRING                   43720013
         BC    BO,4(0,RR)              IF NOT, NO D.V. REQUIRED         43760013
         BAL   GRX,PBSTR               GO TO MAKE FURTHER TESTS         43800013
         TM    CDEBYT+5(GRSP),X'50'    IS IT ADJUSTABLE LENGTH OR       43840013
         BCR   BNZ,RR                VARYING. IF SO, D.V. REQUIRED      43880013
         BC    B,4(0,RR)               D.V. NOT REQUIRED                43920013
         SPACE 5                                                        43960013
PBSTR    EQU   *                                                        44000013
         SPACE                                                          44010015
         TM    DIDATA(GRSP),X'02'      IS IT AREA                       44020015
         BCR   BO,RR                   IF SO, D.V. REQD                 44030015
         SPACE                                                          44040013
PSYMB    TM    INCLUD+1,X'E0'          HAS A PUT DATA BEEN FOUND        44080013
         BCR   BO,RR                                                    44120013
         SPACE                                                          44160013
STEXT    TM    CDEBYT+2(GRSP),3        IS IT CONTROLLED                 44200013
         BCR   BO,RR                   IF SO, D.V. REQUIRED             44240013
         SPACE                                                          44280013
         TM    CDEBYT+2(GRSP),5        IS IT STATIC EXTRNAL             44320013
         BCR   BO,RR                   IF SO, D.V. REQUIRED             44360013
         BCR   B,GRX                   OTHERWISE, GO TO CONTINUE TESTS  44400013
         EJECT                                                          44440013
*              ENTRY TYPE 4'S ARE INSERTED IN THE STATIC CHAIN.         44480013
         SPACE                                                          44520013
QX       MVC   3(2,GRSP),ZSTACH+4(GRDIC) INSERT ENTRY IN STATIC CHAIN.  44560013
         ST    GRSP,PAR2(0,GRDIC)                                       44600013
         MVC   PAR1+2(2,GRDIC),ZLOCK(GRDIC)  CONVERT POINTER TO ENTRY   44640013
         L     LR,ZDABRF(0,GRCC)    SYMBOLIC                            44680013
         BALR  RR,LR                                                    44720013
         SPACE                                                          44760013
         L     GRX,PAR1(0,GRDIC)                                        44800013
         STH   GRX,ZSTACH+4(GRDIC)   INSERT IN HEAD OF STATIC CHAIN.    44840013
         SPACE 5                                                        44880013
*              HERE ENTRIES TYPE 4,5,@6 ARE INSERTED IN THE AUTOMATIC   44920013
*        CHAIN                                                          44960013
         SPACE                                                          45000013
QA1      LA    RR,QA1A                                                  45060015
         LA    GRP,DA456(0,GRSP)       PICTURE.  SET UP POINTER TO DATA 45120013
         L     GRD,FUBAS                                                45160013
         BAL   GRW,PROPIC            BYTE AND GO TO PROCESS PICTURE.    45200013
         SPACE                                                          45240013
QA1A     IC    GR2,2(0,GRSP)           SET GR2 TO END OF ENTRY          45280013
         SR    GR2,UR                                                   45320013
         IC    GR2,0(GRSP,GR2)         PICK UP BLOCK COUNT              45360013
         LA    GRY,0(GR2,GR2)          DOUBLE IT                        45400013
         L     GRX,ZHASH(0,GRDIC)      PICK UP HEAD OF ENTRY TYPE 1     45440013
*                                    STACK.                             45480013
         LH    GRX,0(GRY,GRX)          PICK UP POINTER TO ENTRY TYPE 1  45520013
         ST    GRX,PAR1(0,GRDIC)       CONVERT TO ABSOLUTE              45560013
         L     LR,ZDRFAB(0,GRCC)                                        45600013
         BALR  RR,LR                                                    45640013
         L     GRX,PAR1(0,GRDIC)                                        45680013
         MVC   11(2,GRSP),E1AUTO(GRX)  MOVE START OF CHAIN INTO ENTRY'S 45720013
*                                    AUTOMATIC SLOT                     45760013
         BC    B,G4A                                                    45800013
         SPACE 5                                                        45840013
*              INSERT ENTRY TYPE 3 IN AUTOMATIC CHAIN.                  45880013
         SPACE                                                          45920013
QA2      EQU   *                                                        45960015
         MVC   PAR1+2(2,GRDIC),3(GRSP) ABSOLUTE                         46000013
QA2A     L     LR,ZDRFAB(0,GRCC)                                        46040013
         BALR  RR,LR                                                    46080013
         SPACE                                                          46120013
         L     GRX,PAR1(0,GRDIC)                                        46160013
         CLI   0(GRX),PE1              IS IT A PROCEDURE ENTRY TYPE 1   46200013
         BC    BE,QA2B               IF NOT, FOLLOW THE CIRCULAR PROC-  46240013
*                                    ENTRY CHAIN UNTIL IT IS FOUND.     46280013
         STH   GRZ,PAR1(0,GRDIC)                                        46320013
         MVC   PAR1+2(2,GRDIC),ECC(GRX)                                 46360013
         BC    B,QA2A                                                   46400013
         SPACE                                                          46440013
QA2B     MVC   PAR1+2(2,GRDIC),ECB(GRX)  PICK UP POINTER TO ENTRY TYPE  46480013
         CH    GRZ,PAR1+2(0,GRDIC)   ONE OF CONTAINING BLOCK. IF IT IS  46520013
         BC    BE,QA2C               A STOPPER. GO TO IMSERT ENTRY IN   46560013
*                                    AUTOMATIC CHAIN OF THIS BLOCK      46600013
*                                    OTHERWISE CONVERT POINTER TO       46640015
         BALR  RR,LR                 ABSOLUTE.                          46680013
         SPACE                                                          46720013
         L     GRX,PAR1(0,GRDIC)                                        46760013
         SPACE                                                          46800013
QA2C     MVC   E3AUTO(2,GRSP),E1AUTO(GRX)   INSERT IN AUTO CHAIN OF     46840013
*                                    CONTAINING BLOCK OR FIRST BLOCK.   46880013
         SPACE 2                                                        46920013
*              CONVERT REFERENCE TO THIS ENTRY TO SYMBOLIC.             46960013
         SPACE                                                          47000013
         ST    GRSP,PAR2(0,GRDIC)                                       47040013
         LH    GRY,ZLOCK(0,GRDIC)      PICK UP SYMBOLIC NAME OF SLOT    47080013
         ST    GRY,PAR1(0,GRDIC)     FROM ZLOCK                         47120013
         L     LR,ZDABRF(0,GRCC)                                        47160013
         BALR  RR,LR                                                    47200013
         SPACE                                                          47240013
         MVC   E1AUTO(2,GRX),PAR1+2(GRDIC)  PUT SYMBOLIC RERERENCE OF   47280013
         BC    B,B2                  THIS ENTRY AT HEAD OF AUTO CHAIN   47320013
         SPACE 3                                                        47360013
*              PROCESS ENTRY TYPE 2 ENTRIES                             47400013
         SPACE                                                          47440013
QA3      LA    GRP,E2DATA(0,GRSP)      FIND DATA BYTE.             H448 47450020
QA31     BC    NOP,X                                               H448 47460020
         TM    0(GRP),X'8C'            CAD, SHORT & BINARY?        H448 47470020
         BNO   X                       NO.                         H448 47480020
         TM    0(GRP),X'52'            FIXED,SHORT,NOT PRT/OFFSET. H448 47490020
         BNE   X                       NO.                         H448 47500020
         CLI   1(GRP),X'0F'          TEST PRECISION BYTE          62603 47503072
         BH    X                     BRANCH IF > 15               62603 47506072
         MVC   PAR6(4,GRDIC),HALFWD                                H448 47510020
         L     LR,ZUERR(GRCC)          PUT OUT WARNING MESSAGE,    H448 47520020
         BALR  RR,LR                                               H448 47530020
         MVI   QA31+1,X'F0'            ONCE.                       H448 47540020
         MVI   HLFMSG+1,X'F0'                                           47550020
X        EQU   *                                                   H448 47560020
         LA    RR,B2                                               H448 47570020
         LA    GRW,B2                  SET RETURN REGISTER              47600013
         L     GRD,FUBAS                                                47640013
         BC    B,PROPIC                                                 47680013
         SPACE 3                                                        47720013
*              PROCESS ENTRY TYPE 1 ENTRIES FOR PROCEDURE AND BEGIN     47760013
*        STATEMENTS                                                     47800013
         SPACE                                                          47840013
QA4      IC    GR2,PE1CNT(0,GRSP)      PICK UP BLOCK COUNT              47880013
QB4      LA    GRP,0(GR2,GR2)          DOUBLE IT INTO GRP               47920013
         LH    GRX,ZLOCK(0,GRDIC)                                       47960013
         ST    GRX,PAR1(0,GRDIC)     FROM ZLOCK AND STORE IN PAR1.      48000013
         ST    GRSP,PAR2(0,GRDIC)      ABSOLUTE POINTER IN PAR2         48040013
         L     LR,ZDABRF(0,GRCC)       CONVERT IT TO SYMBOLIC           48080013
         BALR  RR,LR                                                    48120013
         SPACE                                                          48160013
         L     GRX,ZHASH(0,GRDIC)      PICK UP HEAD OF ENTRY TYPE 1     48200013
*                                    STACK                              48240013
         LH    GRY,PAR1+2(0,GRDIC)     STORE SYMBOLIC REFERENCE OF      48280013
         STH   GRY,0(GRX,GRP)        THIS ENTRY IN TABLE AT OFFSET      48320013
*                                    GIVEN BY COUNT                     48360013
         CR    GR2,UR                  IS THIS THE FIRST ENTRY TYPE 1   48400013
         BC    BNE,B2                  IF NOT CONTINUE SCAN.            48440013
         STH   GRY,0(0,GRX)            OTHERWISE, PUT REFERENCE IN SLOT 48480013
*                                    FOR LEVEL ZERO                     48520013
         BC    B,B2                                                     48560013
         EJECT                                                          48600013
FORPAR   TM    CDEBYT+1(GRSP),STRBIT    IS FORMAL PARAMETER A MEMBER    48640013
         BC    BZ,FP1                OF A STRUCTURE.                    48680013
         SPACE                                                          48720013
         TM    OTHER4(GRSP),MAJORS     IF SO, IS IT A MAJOR STRUCTURE   48760013
         BC    BNO,B2                  IF NOT, RESUME SCAN              48800013
         SPACE                                                          48840013
FP1      IC    GR2,2(0,GRSP)           MOVE POINTER TO F.P. TYPE 1      48880013
         SH    GR2,TWO               ENTRY TO OVERWRITE L&C.            48920013
         LA    GRX,0(GRSP,GR2)                                          48960013
         MVC   0(2,GRX),3(GRSP)                                         49000013
         CLI   0(GRSP),EFIVE           IS THIS AN ENTRY TYPE 5          49040013
         BC    BE,B2                   RETURN IF SO                     49080013
         TM    CDEBYT+2(GRSP),3        IS F.P. ENTRY CONTROLLED         49120013
         BC    BO,GE1                  IF SO GO TO INSERT IN            49160013
*                                    CONTROLLED CHAIN                   49200013
         BC    B,B2                                                     49240013
         EJECT                                                          49280013
*              CONSTANTS ROUTINE                                        49320013
*                                                                       49360013
*              FUNCTION/OPERATION - DICTIONARY ENTRIES FOR CONSTANTS    49400013
*        ARE INSERTED IN THE CONSTANTS CHAIN.  THE STRING LENGTH OR     49440013
*        PRECISIONAND SCALE OF THE CONSTANTS ARE COMPUTED AND INSERTED  49480013
*        IN THE ENTRIES                                                 49520013
*              STERLING CONSTANTS ARE FIRST CONVERTED TO PENCE THEN     49560013
*        TREATED AS FIXED DECIMAL.                                      49600013
*                                                                       49640013
*              ENTRY POINT - CONST.  GRSP POINTS AT THE CONSTANT'S      49680013
*        ENTRY.                                                         49720013
*                                                                       49760013
*              EXTERNAL ROUTINE - ZDABRF FOR GETTING SYMBOLIC REFERENCE 49800013
*        OF CONSTANT.                                                   49840013
*                                                                       49880013
*              EXITS - NORMAL- RETURNS TO DICTIONARY SCAN.              49920013
*                                                                       49960013
*              EXITS - ERROR - FOLLOWING OVERFLOW INTERRUPTS CONTROL    50000013
*        IS RETURNED TO ROUTINE LSDERR, AS ARRANGED AT THE START OF     50040013
*        THE PHASE.                                                     50080013
*                                                                       50120013
*              TABLES/ WORK AREAS - N/A                                 50160013
*                                                                       50200013
*              NOTES - N/A                                              50240013
         SPACE 3                                                        50280013
CONST    MVC   3(2,GRSP),ZCONCH(GRDIC) EXTEND CONSTANTS CHAIN           50320013
         SPACE                                                          50360013
         MVI   SWITCH,0                                                 50400013
          MVC  PAR1+2(2,GRDIC),ZLOCK(GRDIC)                             50460015
         ST    GRSP,PAR2(0,GRDIC)      CONVERT POINTER TO SYMBOLIC      50520013
         L     LR,ZDABRF(0,GRCC)                                        50560013
         BALR  RR,LR                                                    50600013
         SPACE                                                          50640013
         LH    GRX,PAR1+2(0,GRDIC)                                      50680013
         CLI   CONDAT(GRSP),X'CC'      IF CONSTANT IS OF POINTER DATA   50720013
         BC    BE,B2                 TYPE, NO PROCESSING IS NECESSARY.  50760013
         STH   GRX,ZCONCH(GRDIC)       STORE IN HEAD OF CONSTANTS CHAIN 50800013
         SPACE                                                          50840013
         LA    GRP,CONSTL(0,GRSP)      SET UP POINTER TO START OF       50880013
         MVC   FW+2(2),1(GRSP)       CONSTANT. PICK UP ENTRY LENGTH AND 50920013
         LH    GRW,FW+2              USE IT TO SET UP POINTER TO END    50960013
         LA    GRW,0(GRSP,GRW)       OF ENTRY                           51000013
         ST    GRW,CONEND                                               51040013
         SR    GR2,GR2                 CLEAR 2 REGISTERS FOR COUNTING   51080013
         SR    GRY,GRY               PRECISION AND SCALE                51120013
         TM    CONDAT(GRSP),X'80'      IS CONSTANT A STRING             51160013
         BC    BZ,MJ1                  IF SO, GO TO COMPUTE LENGTH.     51200013
         SPACE                                                          51240013
         TM    CONDAT(GRSP),X'20'      IS IT A STERLING CONSTANT        51280013
         BC    BO,O1                                                    51320013
         BC    B,N1A                                                    51360013
         SPACE                                                          51400013
*                                      COMPUTE LENGTH OF STRING BY      51440013
MJ1      LH    GRX,FW+2              TAKING TOTAL LENGTH OF ENTRY AND   51480013
         SH    GRX,CONLTH            REDUCING IT BY THE LENGTH OF THE   51520013
         STH   GRX,FW+2              STANDARD INFORMATION.              51560013
         MVC   CONDAT+1(2,GRSP),FW+2   MOVE LENGTH INTO ENTRY           51600013
         BC    BNZ,B2                  RETURN TO SCAN IF STRING LENGTH  51640013
*                                    NOT ZERO.                          51680013
         SPACE                                                          51720013
*              FOR ZERO STRING LENGTHS THE ENTRY'S LENGTH IS BUMPED BY  51760013
*        ONE (THERE IS ROOM DUE TO THE FULL-WORD ALIGNMENT OF DICTION-  51800013
*        ARY ENTRIES).  IF STRING IS FOLLOWED BY AN END OF BLOCK        51840013
*        MARKER, THIS AND THE FOLLOWING POINTER MUST BE MOVED ALONG.    51880013
         SPACE                                                          51920013
         MVI   2(GRSP),CNLTH1                                           51960013
         CLI   CONSTL(GRSP),EODB       IS THIS THE END OF A DICTIONARY  52000013
         BC    BNE,B2                BLOCK. RETURN TO SCAN IF NOT.      52040013
         MVC   FW(3),CONSTL(GRSP)      SHIFT IT RIGHT OTHERWISE.        52080013
         MVC   CONSTL+1(3,GRSP),FW                                      52120013
         MVI   CONSTL(GRSP),X'00'      CONSTANT LEN TO ZERO      40111  52140021
         BC    B,B2                                                     52160013
         SPACE 5                                                        52200013
N1A      CLI   0(GRP),DECPNT                TEST NEXT BYTE IN STRING    52240013
         BC    BE,NC2                  IS IT - A RADIX POINT            52280013
         SPACE                                                          52320013
         CLI   0(GRP),9                        A DIGIT                  52360013
         BC    BNH,ND2                                                  52400013
         SPACE                                                          52440013
         CLI   0(GRP),X'15'                    THE LETTER E             52480013
         BC    BE,NG3                  GO AND TEST FOR FLOAT.           52520013
         SPACE                                                          52560013
         CLI   0(GRP),X'12'            IS IT LETTER B                   52600013
         BC    BE,NG4                                                   52640013
         SPACE                                                          52680013
         CLI   0(GRP),X'19'               OR LETTER J                   52720013
         BC    BNE,CERR                ERROR IF NEITHER                 52760013
         SPACE                                                          52800013
         BC    B,NG4                                                    52840013
         SPACE                                                          52880013
NG3      TM    CONDAT(GRSP),2          IS IT FLOAT                      52920013
         BC    BNO,CERR                                                 52960013
         SPACE                                                          53000013
NG4      LA    GRY,128(0,GRY)          BUMP 'Q' BY 128                  53040013
         STC   GRY,CONDAT+2(0,GRSP)    STORE 'Q' IN ENTRY               53080013
         STC   GR2,CONDAT+1(0,GRSP)    STORE 'P' IN ENTRY               53120013
         SPACE 2                                                        53160013
         TM    CONDAT(GRSP),X'04'      IS BINARY BIT ON                 53200013
         BC    BO,NK4                                                   53240013
         SPACE                                                          53280013
         CLI   CONDAT+1(GRSP),6        IT IS A DEC. CONS. IS PRECISION  53320013
         BC    BNH,B2                GREATER THAN 6                     53360013
NK5      OI    CONDAT(GRSP),X'10'      SET LONG BIT ON IF SO            53400013
         BC    B,B2                                                     53440013
         SPACE                                                          53480013
NK4      CLI   CONDAT+1(GRSP),X'15'    IT IS A BINARY CONSTANT. IS      53520013
         BC    BNH,B2                LENGTH GREATER THAN 21             53560013
         BC    B,NK5                                                    53600013
         SPACE 5                                                        53640013
NC2      OI    SWITCH,2                SET SW ON TO INDICATE THAT THE   53680013
NC3      AR    GRP,UR                RADIX POINT HAS BEEN REACHED. BUMP 53720013
         C     GRP,CONEND            POINTER. HAS IT REACHED END OF     53760013
         BC    BNE,N1A               CONSTANT. BRANCH ACCORDINGLY       53800013
         BC    B,NG4                                                    53840013
ND2      AR    GR2,UR                  BUMP 'P' COUNT                   53880013
         SPACE                                                          53920013
         TM    SWITCH,2                HAS RADIX POINT BEEN PASSED      53960013
         BC    BZ,NC3                                                   54000013
         AR    GRY,UR                  IF IT HAS, BUMP 'Q' COUNT        54040013
         BC    B,NC3                                                    54080013
         SPACE 5                                                        54120013
*              THIS ROUTINE COMPUTES PRECISION OF STERLING CONSTANTS.   54160013
         SPACE                                                          54200013
O1       MVI   CONDAT(GRSP),X'88'                                       54240013
         OI    8(GRSP),8               SET BIT ON TO INDICATE THAT THIS 54280013
*                                    IS A CONVERTED STERLING CONSTANT.  54320013
         LA    LR,PNDFLD                                                54360013
         LR    GRW,GRP               CONVERTING POUNDS TO SHILLINGS.    54400013
OB1      CLI   0(GRW),DECPNT           SCAN FOR .                       54440013
         BCR   BE,LR                                                    54480013
         C     GRW,CONEND                         OR END OF CONSTANT    54520013
         BCR   BE,LR                   BRANCH TO APPROPRIATE ROUTINE.   54560013
         BXH   GRW,UR,OB1              RETURN TO LOOK AT NEXT BYTE.     54600013
         SPACE 3                                                        54640013
OPACK    PACK  DW1(8),0(0,GRP)         PACK POUNDS FIELD                54680013
PNDFLD   LR    GRLTH,GRW               COMPUTE LENGTH OF POUNDS FIELD   54720013
         SR    GRLTH,GRP                                                54760013
         SR    GRLTH,UR                REDUCE BY ONE FOR EXECUTE INSTR- 54800013
         EX    GRLTH,OPACK           UCTION, WHICH PACKS POUNDS FIELD.  54840013
         OI    DW1+7,X'0F'             SET UP SIGN                      54880013
         SPACE                                                          54920013
*              THE POUNDS FIELD IS NOW CONVERTED TO SHILLINGS           54960013
         MVO   DW1(8),DW1(8)           MULTIPLY BY TEN BY MOVING WITH   55000013
         MVI   DW1+7,X'0F'           OFFSET AND RESETING SIGN           55040013
         SPACE                                                          55080013
         AP    DW1(8),DW1(8)           DOUBLE BY ADDING                 55120013
         SPACE 3                                                        55160013
         LA    LR,SHFLD                SET BRANCHING REGISTER TO NEXT   55200013
         AR    GRW,UR                ROUTINE - CONVERTS SHILLING TO     55240013
         LR    GRP,GRW               PENCE. ALSO UPDATE POINTERS TO     55280013
         BC    B,OB1                 START OF SHILLINGS FIELD           55320013
PACKSH   PACK  FW(4),0(0,GRP)          PACK SHILLINGS FIELD             55360013
SHFLD    LR    GRLTH,GRW               COMPUTE LENGTH OF SHILLINGS      55400013
         SR    GRLTH,GRP             FIELD                              55440013
         SR    GRLTH,UR                                                 55480013
         EX    GRLTH,PACKSH            PACK                             55520013
         OI    FW+3,X'0F'              SET UP SIGN                      55560013
         SPACE                                                          55600013
         AP    DW1(8),FW(4)            ADD SHILLINGS TO CONVERTED       55640013
*                                    POUNDS. CONVERT TOTAL TO PENCE AS  55680013
*                                    FOLLOWS.                           55720013
         SPACE                                                          55760013
         MVO   DW2(8),DW1(8)           SAVE TEN*SHILLINGS               55800013
         MVI   DW2+7,X'0F'             SET SIGN                         55840013
*              TEST TO SEE WHETHER ANY INFORMATION HAS BEEN LOST        55880013
*        THROUGH OVERFLOW IN THE LAST 'MVO' INSTRUCTION.                55920013
         SPACE                                                          55960013
         TM    DW1,X'F0'               WAS FIRST DIGIT ZERO             56000013
         BC    BZ,*+8                  IF SO, PROCEED.                  56040013
         BAL   RR,LSDERR               OTHERWISE, GO TO WRITE DIAGNOST- 56080013
*                                    IC.                                56120013
         SPACE                                                          56160013
         AP    DW1(8),DW1(8)           DOUBLE SHILLINGS                 56200013
         AP    DW1(8),DW2(8)           ADD TEN*SHILLINGS TO GIVE PENCE. 56240013
         SPACE 3                                                        56280013
         LA    LR,PNCFLD               SET BRANCHING REGISTER TO NEXT   56320013
         AR    GRW,UR                ROUTINE. RESET POINTERS            56360013
         LR    GRP,GRW                 RETURN.                          56400013
         BC    B,OB1                                                    56440013
PNCFLD   LR    GRLTH,GRW                                                56480013
         SR    GRLTH,GRP                                                56520013
         SR    GRLTH,UR                                                 56560013
         EX    GRLTH,PACKSH                                             56600013
         OI    FW+3,X'0F'                                               56640013
         SPACE                                                          56680013
         AP    DW1(8),FW(4)                                             56720013
         SPACE 3                                                        56760013
         LA    GRLTH,CONSTL(GRSP)      LENGTH OF FIELD                  56800013
         SR    GRLTH,GRW             CONVERTED TO PENCE INTO GRLTH      56840013
         LCR   GRLTH,GRLTH                                              56880013
*              THE FIRST TWO BYTES AND ANY FURTHER BYTES NECESSARY TO   56920013
*        REDUCE FIELD LENGTH TO 15 ARE NOW REPLACED BY BLANKS           56960013
         LA    GRP,CONSTL(0,GRSP)                                       57000013
         SPACE                                                          57040013
         LA    LR,14(0,0)              SET UP REGISTERS FOR BXH         57080013
         LCR   RR,UR                                                    57120013
         BC    B,XTBYTS                                                 57160013
         SPACE 1                                                        57200013
XSBYTS   MVI   0(GRP),BLANK            REPLACE SUBSEQUENT BYTES WITH    57240013
         AR    GRP,UR                                                   57280013
XTBYTS   EQU   *                                                        57320013
         BXH   GRLTH,RR,XSBYTS       BLANKS UNTIL LENGTH DROPS TO 15-1  57360013
         SPACE                                                          57400013
*                                    REPLACE CONSTANT BY CONVERTED      57440013
         SLL   GRLTH,4               VALUE,UNPACKED.                    57480013
         EX    GRLTH,UNPAK                                              57520013
         SRL   GRLTH,4                                                  57560013
*        SPACE                                                          57600013
*              BLANK OUT ANY REMAINING ZEROS                            57640013
         MVC   TEMP1(2),1(GRSP)                                         57680013
         LH    LR,TEMP1                                                 57720013
         AR    LR,GRSP                                                  57760013
         BCTR  LR,0                                                     57800013
         CLI   0(LR),DECPNT                                             57840013
         BC    BNE,XTB3                                                 57880013
         BCTR  LR,0                                                     57920013
         SPACE                                                          57960013
XTB3     CR    GRP,LR                                                   58000013
         BC    BNL,XTB2                                                 58040013
         TM    0(GRP),X'0F'          IS DIGIT ZERO                      58080013
         BC    BNZ,XTB2              BRANCH IF NOT                      58120013
         CLI   0(GRP),DECPNT         DECIMAL POINT REACHED              58160013
         BC    BE,XTB2               BRANCH IF SO                       58200013
         MVI   0(GRP),BLANK                                             58240013
         BCTR  GRLTH,0                                                  58280013
         LA    GRP,1(GRP)                                               58320013
         BC    B,XTB3                                                   58360013
         SPACE                                                          58400013
XTB2     EQU   *                                                        58440013
         LTR   GRLTH,GRLTH                                              58480013
         BC    BM,NC3+2                                                 58520013
         SR    GRW,UR                  POINT TO LAST BYTE               58560013
         OI    0(GRW),X'F0'            OVERWRITE SIGN WITH APPROPRIATE  58600013
         L     GRW,ZTRAN1(0,GRDIC)     TRANSLATE UNPACKED BYTES INTO    58640013
*                                    INTERNAL CODE                      58680013
         EX    GRLTH,TRA                                                58720013
         SPACE                                                          58760013
         BC    B,NC3+2                                                  58800013
         SPACE                                                          58840013
TRA      TR    0(0,GRP),0(GRW)         TRANSLATE INTO INTERNAL CODE     58880013
UNPAK    UNPK  0(0,GRP),DW1(8)         UNPACK CONSTANT                  58920013
         EJECT                                                          58960013
         EJECT                                                          59000013
FTERR1   MVC   PAR6+1(3,GRDIC),MESS1                                    59040013
CERR     EQU   FTERR1                                                   59080013
         L     RR,ZABORT(0,GRCC)                                        59120013
         L     LR,ZUERR(0,GRCC)                                         59160013
         BCR   B,LR                                                     59200013
         EJECT                                                          59240013
*              STRUCTURE PROCESSOR                                      59280013
*                                                                       59320013
*              FUNCTIONS (1) EXAMINES BASE ELEMENTS OF THE GIVEN        59360013
*        STRUCTURE, SETTING THE PACKED/ALIGNED BIT IN THEIR DATA BYTES, 59400013
*        AND THE 'ADJUSTABLE DIMENSIONS' BIT IN THE OTHER 1 BYTE, IF    59440013
*        REQUIRED.                                                      59480013
*                        (2) SETS THE 'NEEDS DOPE VECTOR' AND 'ADJUST-  59520013
*        ABLE DIMENSIONS' BITS IN THE MAJOR STRUCTURE DICTIONARY ENTRY, 59560013
*        IF REQUIRED.                                                   59600013
*                        (3) MAKES SURE THAT ALL DIMENSIONED BASE       59640013
*        ELEMENTS HAVE INDIVIDUAL (NOT COMMON) DIMENSION TABLES.        59680013
*                        (4) FOR A BASE ELEMENT WHICH HAS INHERITED     59720013
*        DIMENSIONS, CREATES A DIMENSION TABLE AND INCORPORATES ALL     59760013
*        DIMENSIONS INHERITED FROM THE CONTAINING STRUCTURES.  IF       59800013
*        ADJUSTABLE DIMENSIONS ARE INVOLVED, ALTERS OR CREATES SECOND   59840013
*        FILE STATEMENTS.                                               59880013
*                                                                       59920013
*              ENTRY POINT - STRUCT.  REGISTER GRSP POINTS TO A         59960013
*        DICTIONARY ENTRY FOR A STRUCTURE ITEM.                         60000013
*                                                                       60040013
*              EXTERNAL ROUTINES - ZDABRF (CONTROL PHASE) CONVERTS      60080013
*        ABSOLUTE ADDRESS TO DICTIONARY REFERENCE.                      60120013
*                                  ZDRFAB (CONTROL PHASE) CONVERTS      60160013
*        DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.                      60200013
*                                  P1A (THIS MODULE) CHECKS IF AN ITEM  60240013
*        REQUIRES A DOPE VECTOR.                                        60280013
*                                  ZDICRF (CONTROL PHASE) MAKES         60320013
*        DICTIONARY ENTRY.                                              60360013
*                                  MKDMTB (THIS MODULE) CREATES A       60400013
*        DIMENSION TABLE.                                               60440013
*                                  MVTXT (THIS MODULE) MOVES A STRING   60480013
*        OF DATA.                                                       60520013
*                                  AJDMRT (THIS MODULE) ALTER SECOND    60560013
*        FILE STATEMENTS AND THEIR DICTIONARY ENTRIES, FOR ADJUSTABLE   60600013
*        DIMENSIONS.                                                    60640013
*                                  ZUTXTC (CONTROL PHASE) GETS NEW TEXT 60680013
*        BLOCK.                                                         60720013
*                                                                       60760013
*              EXITS - NORMAL (1) TO B2, TO CONTINUE SCAN OF THE        60800013
*        DICTIONARY, IF THE STRUCTURE TO BE PROCESSED IS MINOR.         60840013
*                             (2) TO G1, TO INCORPORATE THE STRUCTURE   60880013
*        INTO ITS STORAGE CHAIN, WHEN ALL BASE ELEMENTS HAVE BEEN       60920013
*        PROCESSED.                                                     60960013
*                                                                       61000013
*              EXITS - ERROR - NONE.                                    61040013
*                                                                       61080013
*              NOTE - ROUTINE P1A RETURNS TO THE USUAL LINK ADDRESS IF  61120013
*        A DOPE VECTOR IS REQUIRED, AND FOUR BYTES FURTHER ON IF NOT.   61160013
*                                                                       61200013
         SPACE 5                                                        61240013
STRUCT   TM    OTHER4(GRSP),MAJORS                                      61280013
         BC    BZ,B2                   BRANCH IF MINOR STRUCTURE        61320013
         MVI   CONTIG,OFF          INITIALISE CONTIGUOUS SWITCH         61340015
         SPACE                                                          61360013
         MVC   PAR1+2(2,GRDIC),ZLOCK(GRDIC)  SET BLOCK REFERENCE        61400013
         ST    GRSP,PAR2(GRDIC)        GET THE MAJOR STRUCTURE          61440013
         L     LR,ZDABRF(GRCC)       DICTIONARY REFERENCE               61480013
         BALR  RR,LR                                                    61520013
         MVC   SPSTOR(2),PAR1+2(GRDIC) SAVE REFERENCE IN SPSTOR         61560013
         SPACE 4                                                        61600013
         TM    OTHER2(GRSP),X'10'  TEST FOR CONTIG                      61610015
         BC    BNO,ALCTST                                               61620015
         MVI   CONTIG,ON           TURN ON CONTIG SWITCH                61630015
ALCTST   MVI   ALLSTR,X'00'              ZEROISE ALL/DEF FLAG      H172 61640001
        TM    VAR(GRSP),3               IS STRUCTURE ALLOC/DEFN?   H172 61650001
         BC    BZ,*+20                 NEITHER                     H172 61660001
         TM    VAR(GRSP),1             IS STRUCTURE ALLOC?         H172 61670001
         BC    BZ,DFCTST               NO.                         H172 61680001
         MVI   ALLSTR,X'FF'              SET ALLOC FLAG TO 'FF'    H172 61690001
DFCTST   OI    ALLSTR,X'F0'              SET DEFN FLAG TO 'F0'     H172 61700001
*              THE FLAG, 'ALLSTR', SET ABOVE, IS USED TO INDICATE THAT  61760013
*        ANY STRUCTURE BASE ELEMENTS FOUND LATER IN THE SCAN ARE        61800013
*        ALLOCATED OR DEFINED.  THIS MUST BE SO, DUE TO THE ORDER  H172 61840001
*        IN WHICH ENTRIES ARE CREATED BY PREVIOUS PHASES.          H172 61880001
         SPACE                                                          61920013
         MVI   DVSW,OFF                INITIALISE 'DOPE VECTOR' SWITCH. 61960013
         MVI   CTLFL,OFF               INITIALISE 'CONTROLLED STORAGE   62000013
*                                    CLASS' FLAG TO OFF.                62040013
         ST    GRZ,DVOFF                                                62080013
         TM    OTHER2(GRSP),STCL                                        62120013
         BC    BNO,STR10               BRANCH IF STORAGE CLASS IS NOT   62160013
         TM    VAR(GRSP),X'02'                                          62170015
         BC    BO,STR10                                                 62180015
         MVI   CTLFL,ON              CONTROLLED. SET CONTROLLED FLAG ON 62200013
*                                      WHEN PROCESSING A BASE ELEMENT   62240013
*                                    DVOFF WILL CONTAIN THE OFFSET      62280013
*                                    FROM THE START OF THE MAJOR        62320013
*                                    STRUCTURES DOPE VECTOR OF THE      62360013
*                                    BASE ELEMENTS DOPE VECTOR.         62400013
         SPACE                                                          62440013
STR10    MVI   DIMBYT,0                INITIALISE ADJUSTABLE DIMENSIONS 62480013
*                                    FLAG TO OFF.                       62520013
         SPACE                                                          62840013
*              GR3 IS TO BE SET AT THE STRUCTURE INFORMATION. THE       62880013
*        POSITION OF THIS DEPENDS UPON WHETHER THE STRUCTURE IS         62920013
*        DIMENSIONED. FIRST SET GR3 AS THOUGH THE ITEM IS NOT           62960013
*        DIMENSIONED.                                                   63000013
STR030   LA    GR3,STINOD(GRSP)                                         63040013
         TM    VAR(GRSP),DIMS          TEST THE DIMS BIT IN THE         63080013
*                                    VARIABLE BYTE.                     63120013
         BC    BZ,STR040                                                63160013
         LA    GR3,DILTH(GR3)          INCREMENT GR3 BY THE LENGTH OF   63200013
*                                    THE DIMENSION INFORMATION.         63240013
STR040   MVC   BSELRF(2),NXTMEM(GR3)   SAVE THE REFENCE TO THE NEXT     63280013
*                                    ITEM IN THE STRUCTURE IN CASE IT   63320013
         MVC   PAR1+2(2,GRDIC),BSELRF IS A BASE ELEMENT. THEN CONVERT   63360013
         L     LR,ZDRFAB(GRCC)       THIS TO ABSOLUTE.                  63400013
         BALR  RR,LR                                                    63440013
         MVC   ZLOCK(2,GRDIC),BSELRF   LOCK IN BASE ELEMENT.            63480013
         L     GRSP,PAR1(GRDIC)        SET GRSP TO POINT AT THE NEXT    63520013
*                                    MEMBER, AND GR5 TO POINT AT THE    63560013
*                                    FIRST BYTE OF THE VARIABLE         63600013
         LA    GR5,VARINF(GRSP)      INFORMATION FOR AN ITEM WHICH IS   63640013
         LA    GR4,STR080            NOT DATA. SET UP A BRANCH REGISTER 63680013
         CLI   CONTIG,ON           IS STRUCT CONTIG                     63690015
         BC    BNE,ITMTST                                               63700015
         OI    OTHER2(GRSP),X'10'  SET CONTIG BIT ON                    63710015
ITMTST   TM    0(GRSP),DATAB       IS THIS ITEM DATA                    63720015
         BC    BNO,STR050              BRANCH IF NOT                    63760013
         LA    GR5,EXTDAT(GR5)         BUMP GR5 FOR THE EXTRA BYTES IN  63800013
*                                    A DATA ITEM.                       63840013
         BC    B,STR060                                                 63880013
STR050   TM    0(GRSP),STRBYT          TEST FOR A STRUCTURE             63920013
         BC    BNO,STR060              BRANCH IF NOT                    63960013
         LA    GR4,STR040              SET UP A BRANCH REGISTER         64000013
STR060   LA    GR3,SNDADD(GR5)         SET UP GR3 TO POINT AT THE       64040013
*              STRUCTURE INFORMATION OF A NON-DIMENSIONED ITEM.         64080013
         TM    VAR(GRSP),DIMS          TEST VARIABLE BYTE FOR           64120013
*                                    DIMENSIONS                         64160013
         BCR   BZ,GR4                  BRANCH IF NO DIMENSIONS          64200013
         LA    GR3,DILTH(GR3)          BUMP POINTER PAST DIMENSIONALITY 64240013
         BCR   B,GR4                                                    64280013
         SPACE                                                          64320013
*              IF THE ITEM AT GRSP IS A STRUCTURE THEN GR4 POINTS AT    64360013
*        STR040, OTHERWISE IT POINTS AT STR080.                         64400013
         EJECT                                                          64440013
*              WE NOW HAVE A BASE ELEMENT. THE ADDITION THIS ITEM MAKES 64480013
*        TO THE STRUCTURES DOPE VECTOR IS CALCULATED. ALSO THE ALIGNED/ 64520013
*        PACKED BIT IS SET ACCORDING AS ALIGFL IS SET.                  64560013
STR080   LA    LR,4                    INITIALISE OFFSET TO 4           64600013
         ST    LR,DVADD                                                 64640013
         SPACE                                                          64680013
         TM    0(GRSP),DATAB                                            64720013
         BC    BNO,STR090              BRANCH IF IT IS NOT A DATA ITEM  64760013
         TM    DATA(GRSP),STRNG                                         64800013
          BC   BO,STR090               BRANCH IF NOT STRING             64840013
         TM    OTHER2(GRSP),X'03'      TEST IF CONTROLLED STRING        64880013
         BC    BNO,STR081              BRANCH IF NOT                    64920013
         CLI   ALLSTR,ON                                                64960013
         BC    BE,STR081               BRANCH IF ALLOCATED ENTRY        65000013
         TM    DIDATA(GRSP),PICBIT                                      65040013
         BC    BZ,STR081               BRANCH IF PICTURED               65080013
         TM    VAR(GRSP),X'02'          IS IT BASED                     65090015
         BC    BO,STR081                BRANCH IF YES                   65100015
         OI    DIDATA(GRSP),X'40'      SET ADJUSTABLE LENGTH BIT ON     65120013
         SPACE 1                                                        65160013
STR081   LA    LR,8                                                     65200013
         ST    LR,DVADD                                                 65240013
STR090   TM    VAR(GRSP),DIMS          TEST THE ITEM FOR DIMENSION      65440013
         BC    BO,STR100             WE ARE NOT INTERESTED IF IT IS     65480013
*                                    IS A SCALAR, UNLESS IT IS THE      65520013
*                                    LAST ELEMENT IN A STRUCTURE        65560013
STR095   BAL   RR,P1A                  CHECK FOR DOPE VECTOR REQUIRED   65600013
         OI    OTHER3(GRSP),X'80'      SET FLAG IF NEEDS DOPE VECTOR    65640013
         SPACE                                                          65680013
         L     LR,DVADD                BUMP THE TOTAL DOPE VECTOR       65720013
         A     LR,DVOFF              OFFSET BY THE SIZE OF THE DOPE     65760013
         ST    LR,DVOFF              VECTOR FOR THE LAST ITEM TREATED.  65800013
         TM    OTHER1(GRSP),LMIS       PROCESS NEXT MEMBER IF NOT END   65840013
         BC    BNO,STR040            OF STRUCTURE                       65880013
         SPACE 10                                                       65920013
*                       THE END OF A STRUCTURE                          65960013
STR096   MVC   PAR1+2(2,GRDIC),SPSTOR  DECODE THE OLD VALUE OF GRSP,    66000013
         L     LR,ZDRFAB(GRCC)         I.E. THE MAJOR STRUCTURE.        66040013
         BALR  RR,LR                                                    66080013
         L     GRSP,PAR1(GRDIC)        LOAD UP GRSP AND THEN LOCK IN    66120013
         MVC   ZLOCK(2,GRDIC),SPSTOR THTHE BLOCK CONTAINING THE MAJOR   66160013
*                                    STRUCTURE.                         66200013
         CLI   DVSW,ON                 HAS DOPE VECTOR SWITCH BEEN SET  66240013
         BC    BE,STRDV                IF SO, GO TO SET BIT ON.         66280013
         BAL   RR,P1A                  OTHERWISE TEST FURTHER           66320013
STRDV    OI    OTHER3(GRSP),X'80'      SET BIT ON IN MAJOR STRUCTURE    66360013
         BC    B,G1                                                     66400013
         BC    BNE,*+8                 SKIP IF DOPE VECTOR NOT NEEDED   66440013
         OI    OTHER3(GRSP),X'80'      SET BIT IN MAJOR STRUCTURE       66480013
         TM    DIMBYT,X'F0'            SET THE ADJUSTABLE DIMENSIONS    66520013
         BC    BZ,*+8                BIT ON IN THE MAJOR STRUCTURE      66560013
         OI    OTHER1(GRSP),ADJDIM   IF THERE WERE SOME ANYWHERE IN     66600013
*                                    THE STRUCTUR.                      66640013
         MVI   DIMBYT,0                RE-INITIALISE THE FLAG BYTE.     66680013
         BC    B,G1                    BRANCH TO CHAIN ROUTINE          66720013
         SPACE 5                                                        66760013
*                       A DIMENSIONED BASE ELEMENT HAS BEEN FOUND.      66800013
*        GR5 POINTS AT THE VARIABLE INFORMATION, GR3 AT THE STRUCTURE   66840013
*        INFORMATION, AND GRSP AT THE FIRST BYTE OF THE BASE ELEMENT.   66880013
*              WE ARE GOING TO SAVE THE OFFSET OF THE VARIABLE          66920013
*        INFORMATION.                                                   66960013
STR100   LR    LR,GR5                                                   67000013
         SR    LR,GRSP                                                  67040013
         STH   LR,THSVIN                                                67080013
         SPACE                                                          67120013
         SPACE 4                                                        67160013
         IC    LR,SNDADD(0,GR5)        PICK UP NUMBER OF DIMENSIONS.    67200013
*                                    TOP 3 BYTES OF LR SHOULD BE CLEAR  67240013
*                                    ALREADY.                           67280013
         ST    LR,N1                   SAVE NUMBER OF DIMS.             67320013
         SLL   LR,3                    COMPUTE 8*N1                     67360013
         A     LR,DVADD                AND ADD TO CURRENT LENGTH FOR    67400013
         ST    LR,DVADD              THIS ITEMS DOPE VECTOR.            67440013
         CLC   ZEROS(2),SNDADD+1(GR5)   BRANCH IF THE DIMENSION TABLE   67480013
         BC    BE,STR110             REFERENCE IS ZERO.                 67520013
         MVC   PAR1+2(2,GRDIC),SNDADD+1(GR5)                            67560013
         L     LR,ZDRFAB(GRCC)         DECODE THE REFERENCE TO THE      67600013
         BALR  RR,LR                 DIMENSION TABLE, LOAD IN GR4       67640013
         L     GR4,PAR1(GRDIC)                                          67680013
         MVC   N2+3(1),DINTAB(GR4)   N2= NUMBER OF DIMENSIONS IN TABLE  67720013
         CLC   N1(4),N2                COMPARE N1 AND N2. IF THEY ARE   67760013
         BC    BNE,STR115            NOT EQUAL THE ITEM MUST HAVE       67800013
*                                    INHERITED DIMENSIONS.              67840013
         SPACE 2                                                        67880013
*        NO DIMENSIONS HAVE BEEN INHERITED. THE DIMENSION TABLE MUST    67920013
*        NOT BE SHARED. TEST FOR THIS NEXT                              67960013
         TM    DTFLB(GR4),USED         TEST THE USED BIT IN THE FLAG    68000013
*                                    BYTE.                              68040013
         BC    BO,STR105               BRANCH IF THE DIMENSION TABLE    68080013
*                                    IS USED.                           68120013
         MVI   DTFLB(GR4),X'C0'        MARK USED, DO NOT COMMON         68160013
         BC    B,STR095                                                 68200013
         SPACE 5                                                        68240013
*              THE DIMENSION TABLE HAS BEEN USED BY ANOTHER ITEM SO     68280013
*        A COPY MUST BE MADE.                                           68320013
         SPACE                                                          68360013
*              IF THE ITEM HAS ADJUSTABLE DIMENSIONS NO COPY            68400013
*        NEED BE MADE.                                                  68440013
         SPACE                                                          68480013
STR105   TM    OTHER1(GRSP),ADJDIM     BRANCH OUT FOR ADJUSTABLE        68520013
         BC    BO,STR095             DIMENSIONS                         68560013
         SPACE                                                          68600013
         ST    GR4,PAR1(GRDIC)         STORE THE ADDRESS OF THE ENTRY   68640013
         ST    GRZ,PAR2(GRDIC)       TO BE COPIED. SET PAR2 TO ZERO     68680013
         MVC   PAR2+2(2,GRDIC),1(GR4)  AND THEN TO TABLE LENGTH.        68720013
         L     LR,ZDICRF(GRCC)         MAKE THE DICTIONARY ENTRY,       68760013
         BALR  RR,LR                 GETTING A REFERENCE BACK.          68800013
         MVC   SNDADD+1(2,GR5),PAR1+2(GRDIC) STORE THE REFERENCE IN THE 68840013
         L     LR,ZDRFAB(GRCC)         ENTRY. CONVERT THE REFERENCE TO  68880013
         BALR  RR,LR                   ABSOLUTE                         68920013
         L     GR4,PAR1(GRDIC)         SET GR4 TO POINT AT THE NEW      68960013
*                                    DIMENSION TABLE ENTRY.             69000013
         OI    DTFLB(GR4),USDNC        SET THE USED AND DO NOT COMMON   69040013
         BC    B,STR095              BITS ON. BRANCH TO TEST FOR LAST   69080013
*                                    MEMBER IN A STRUCTURE.             69120013
         EJECT                                                          69160013
*                       IN THIS SECTION THE ITEM MUST INHERIT           69200013
*        DIMENSIONS FROM CONTAINING STRUCTURES.                         69240013
*        GRSP  POINTS AT THE FIRST BYTE OF THE ITEM                     69280013
*        GR5   POINTS AT THE VARIABLE INFORMATION                       69320013
         SPACE 4                                                        69360013
*        THIS SECTION DEALS WITH AN ITEM WITH NO DIMENSIONS OF ITS OWN  69400013
         SPACE                                                          69440013
         SPACE 2                                                        69480013
*              IF ARRAY DOES NOT INHERIT ALL ITS DIMENSOINS FROM THE    69520013
*        SAME CONTAINING STRUCTURE SET 'MIXED DIMENSIONS' BIT           69560013
STR110   LR    GRD,GR5                                                  69600013
STR111   MVC   PAR1+2(2,GRDIC),CNSTDS(GRD)                              69640013
         L     LR,ZDRFAB(GRCC)                                          69680013
         BALR  RR,LR                 SCAN TO CONTAINING STRUCTURE       69720013
         L     GRD,PAR1(GRDIC)                                          69760013
         SPACE                                                          69800013
         LA    GRD,VARINF(GRD)                                          69840013
         CLC   ZEROS(2),SNDADD+1(GRD)   HAS IT ANY DIMS OF ITS OWN      69880013
         BC    BE,STR111             CONTINUE SCAN BACK IF NOT          69920013
         SPACE                                                          69960013
         MVC   PAR1+2(2,GRDIC),SNDADD+1(GRD)                            70000013
         BALR  RR,LR                 GET DIMENSION TABLE ENTRY          70080013
         L     GRD,PAR1(GRDIC)                                          70120013
         SPACE                                                          70160013
         CLC   N1+3(1),DINTAB(GRD)     IS THIS ALL THE DIMS             70200013
         BC    BE,STR112             BRANCH IF YES                      70240013
         OI    OTHER3(GRSP),X'04'    SET MIXEE DIMENSIONS BIT           70280013
         SPACE 2                                                        70320013
STR112   MVC   T+3(1),SNDADD(GR5)      SET T = NO OF DIMS OF BASE ELEM  70360013
         L     GRD,FUBAS                                                70400013
         BAL   RR,MKDMTB               BRANCH TO MAKE A NEW DIMENSION   70440013
*                                    TABLE.                             70480013
         BC    B,STR180                BRANCH TO DEAL WITH ANY          70520013
*                                    ADJUSTABLE DIMENSIONS.             70560013
         SPACE 10                                                       70600013
*        THE ITEM IN THIS INSTANCE HAS DIMENSIONS OF ITS OWN, BUT MUST  70640013
*        INHERIT T=N1-N2 FROM THE CONTAINING STRUCTURES.                70680013
         SPACE                                                          70720013
STR115   OI    OTHER3(GRSP),X'04'      SET MIXED DIMENSIONS BIT         70760013
         L     GR6,N1                                                   70800013
         S     GR6,N2                                                   70840013
         ST    GR6,T                                                    70880013
         L     GRD,FUBAS                                                70920013
         BAL   RR,MKDMTB          BRANCH TO THE ROUTINE TO MAKE A       70960013
*                               DIMENSION TABLE                         71000013
*              WE NOW HAVE TO MOVE THE BOUNDS INFORMATION FROM THE OLD  71040013
*        DIMENSION TABLE TO THE NEW.                                    71080013
         LA    LR,12(GR4)              SET UP ADDRESS OF FIRST LOWER    71120013
         IC    GRZ,T+3               BOUND, I.E. SOURCE FIELD.          71160013
         SLA   GRZ,3                                                    71200013
         LA    GRZ,12(GR6,GRZ)         SET UP ADDRESS OF DESTINATION    71240013
*                                     FIELD.                            71280013
         L     GR10,N2                                                  71320013
         AR    GR10,GR10                                                71360013
         AR    GR10,GR10               SET UP 8*N2 AS THE LENGTH TO     71400013
         AR    GR10,GR10             BE MOVED.                          71440013
         L     GRD,FUBAS                                                71480013
         BAL   RR,MVTXT                BRANCH TO MOVE TEXT.             71520013
         EJECT                                                          71560013
*              THIS SECTION IS COMMON TO ARRAYS WHICH DO AND DO NOT     71600013
*        HAVE DIMENSIONS OF THEIR OWN.                                  71640013
STR180   TM    OTHER1(GRSP),ADJDIM     TEST FOR ADJUSTABLE DIMENSIONS   71680013
*                                    IN THE BASE ELEMENT.               71720013
         BC    BZ,STR185               BRANCH IF NONE.                  71760013
         L     RR,N2                                                    71800013
         AR    RR,RR                    THIS CODE SETS UP N3=2*THE      71840013
         ST    RR,N3               NUMBER OF DIMENSIONS THE ITEM HAD    71880013
         L     GR10,T              DECLARED WITH IT. GR10(P) IS SET     71920013
         SLA   GR10,3                TO POINT AT THE LOWER BOUND OF THE 71960013
         LA    GR10,12(GR10,GR6)   FIRST OF THESE DIMENSIONS IN THE     72000013
         BAL   RR,AJDMRT           NEW DIMENSION TABLE. BRANCH NEXT TO  72040013
*                                  ALTER ANY SECOND FILE STATEMENTS     72080013
*                                  AND DICTIONARY ENTRIES.              72120013
         SPACE                                                          72160013
STR185   MVC   PAR1+2(2,GRDIC),BSELRF  DECODE REFERENCE TO THE BASE     72200013
         L     LR,ZDRFAB(GRCC)       ELEMENT AND THEN CALCULATE THE     72240013
         BALR  RR,LR                 ADDRESS OF THE VARIABLE            72280013
         L     GR5,PAR1(GRDIC)       INFORMATION.                       72320013
         AH    GR5,THSVIN                                               72360013
STR190   MVC   THSTR(2),CNSTDS(GR5)    SAVE THE REFERENCE TO THE        72400013
*                                    CONTAINING STRUCTURE.              72440013
         MVC   PAR1+2(2,GRDIC),CNSTDS(GR5)                              72480013
         L     LR,ZDRFAB(GRCC)         CONVERT THE DICTIONARY           72520013
         BALR  RR,LR                      REFERENCE OF THE CONTAINING   72560013
         L     GR5,PAR1(GRDIC)            STRUCTURE TO ABSOLUTE. SET    72600013
*                                         GR5 TO POINT AT THE           72640013
*                                         CONTAINING STRUCTURE.         72680013
         CLC   ZEROS(2),SNDADD+VARIDS+1(GR5)  TEST FOR ZERO             72720013
         BC    BNE,STR195              DIMENSION TABLE REFERENCE.       72760013
         LA    GR5,VARIDS(GR5)         BRANCH IF NOT ZERO. OTHERWISE    72800013
         BC    B,STR190              SET GR5 TO POINT AT THE VARIABLE   72840013
*        INFORMATION, AND BRANCH TO GET THE CONTAINING STRUCTURE.       72880013
         SPACE                                                          72920013
STR195   MVC   PAR1+2(2,GRDIC),SNDADD+VARIDS+1(GR5)                     72960013
*                                    CONVERT THE DIMENSION TABLR        73000015
         BALR  RR,LR                 REFERENCE TO ABSOLUTE              73040013
         L     GR4,PAR1(GRDIC)                                          73080013
         MVC   N2+3(1),DINTAB(GR4)     SET UP  N2.                      73120013
         L     LR,T                                                     73160013
         S     LR,N2                   SET T= T - N2.                   73200013
         ST    LR,T                                                     73240013
         SLA   LR,3                    SET UP ADDRESS OF DESTINATION    73280013
         LA    GRZ,12(LR,GR6)        FIELD AS NEW DIMENSION TABLE +12+  73320013
         LA    LR,12(GR4)            8*T, ADDRESS OF SOURCE FIELD OLD   73360013
         L     GR10,N2               DIMENSION TABLE +12 , AND LENGTH   73400013
         AR    GR10,GR10             TO BE MOVED AS 8*N2.               73440013
         AR    GR10,GR10                                                73480013
         AR    GR10,GR10                                                73520013
         L     GRD,FUBAS                                                73560013
         BAL   RR,MVTXT                BRANCH TO MOVE TEXT              73600013
         SPACE                                                          73640013
STR200   TM    OTHER1(GR5),ADJDIM      TEST FOR ADJUSTABLE DIMENSIONS   73680013
         BC    BO,STR210               BRANCH IF THERE ARE ANY.         73720013
STR202   LA    GR3,SNDADD+DILTH+VARIDS(GR5)  SET GRZ AT THE STRUCTURE   73760013
         C     GRZ,T                 INFORMATION. TEST FOR T=0, AND     73800013
         BC    BE,STR205               BRANCH IF IT IS                  73840013
         LA    GR5,VARIDS(GR5)         BUMP GR5 TO POINT AT THE         73880013
         BC    B,STR190         VARIABLE INFORMATION IN A STRUCTURE.    73920013
         EJECT                                                          73960013
STR205   MVC   PAR1+2(2,GRDIC),BSELRF  DECODE THE REFERENCE TO THE      74000013
         L     LR,ZDRFAB(GRCC)       BASE ELEMENT PROCESSED.            74040013
         BALR  RR,LR                                                    74080013
         L     GR3,PAR1(GRDIC)         MARK THE OTHER1 BYTE IF IT HAS   74120013
         TM    DIMBYT,X'0F'          INHERITED ADJUSTABLE DIMENSIONS    74160013
         BC    BZ,*+8                                                   74200013
         OI    OTHER1(GR3),ADJDIM                                       74240013
         NI    DIMBYT,X'F0'            RE-INITIALISE THE DIMENSION      74280013
         LR    GRSP,GR3              TYPE BYTE. RESET SCAN POINTER      74320013
         SPACE                                                          74360013
         AH    GR3,THSVIN              BUMP GR3 TO POINT AT VARIABLE    74400013
*                                    INFORMATION, AND THEN STRUCTURE    74440013
*                                    INFORMATION.                       74480013
         LA    GR3,SNDADD+DILTH(GR3)                                    74520013
         BC    B,STR095                BRANCH TO TEST FOR THE LAST      74560013
*                                    MEMBER IN A STRUCTURE.             74600013
         SPACE                                                          74640013
*              THIS SECTION OF CODE DEALS WITH CONTAINING STRUCTURES    74680013
*        WHICH HAVE ADJUSTABLE DIMENSIONS                               74720013
STR210   MVI   DIMBYT,X'FF'            SET DIMENSION BYTE TO ADJUSTABLE 74760013
         MVC   PAR1+2(2,GRDIC),SNDADD+VARIDS+1(GR5)                     74800013
         L     LR,ZDRFAB(GRCC)        DECODE THE DIMENSION TABLE        74840013
         BALR  RR,LR                  REFERENCE.                        74880013
         L     GR4,PAR1(GRDIC)        GR4 POINTS AT THE OLD DIMENSION   74920013
         TM    TIKBYT(GR4),USBYBS  TABLE. TEST FOR THE DIMENSION TABLE  74960013
*                                   BEING PREVIOUSLY USED BY ANOTHER    75000013
*                                   BASE ELEMENT.                       75040013
         BC    BO,STR230              BRANCH IF IT HAS BEEN USED.       75080013
         OI    TIKBYT(GR4),USBYBS     SET THE ABOVE BIT ON.             75120013
         MVC   USBYDR(2,GR4),BSELRF   STORE THE REFERENCE OF THIS BASE  75160013
*                                    ELEMENT IN THE DIMENSION TABLE.    75200013
         CLI   CTLFL,ON                IF THE MAJOR STRUCTURE IS        75240013
         BC    BNE,STR215            CONTROLLED, REPLACE BASE ELEMENT   75280013
         MVC   USBYDR(2,GR4),DVOFF+2 REFERENCE BY DOPE VECTOR OFFSET    75320013
         SPACE                                                          75360013
STR215   MVC   TINTAB(1,GR4),T+3       STORE T AND N1 IN THE OLD        75400013
         MVC   N1INTB(1,GR4),N1+3    DIMENSION TABLE.                   75440013
         L     GR10,N2                                                  75480013
         AR    GR10,GR10                                                75520013
         ST    GR10,N3                 SET N3= 2*N2 AND                 75560013
         L     GR10,T                  GR10 = 12 + 8*T + NEW DIMENSION  75600013
         SLA   GR10,3                TABLE ADDRESS.                     75640013
         LA    GR10,12(GR10,GR6)                                        75680013
         BAL   RR,AJDMRT               BRANCH TO PROCESS ADJUSTABLE     75720013
*                                    DIMENSIONS.                        75760013
         MVC   PAR1+2(2,GRDIC),THSTR   DECODE POINTER TO CONTAINING     75800013
         L     LR,ZDRFAB(0,GRCC)     STRUCTURE                          75840013
         BALR  RR,LR                                                    75880013
         L     GR5,PAR1(0,GRDIC)                                        75920013
         BC    B,STR202                BRANCH TO TEST FOR ZERO T.       75960013
         SPACE 10                                                       76000013
STR230   L     GRD,FUBAS                                           H172 77000001
         BAL   RR,MTFGEN                                           H172 78000001
         SPACE 2                                                        79000013
*                 NXTBYT CONTAINS THE ABSOLUTE ADDRESS OF THE NEXT      79040013
*        FREE BYTE IN THE LAST TEXT BLOCK. BYTSFR CONTAINS THE NUMBER   79080013
*        OF BYTES AVAILABLE IN THAT BLOCK.                              79120013
         L     GR10,LENMSK             SET UP THE LENGTH OF THE MTF     79160013
         C     GR10,BYTSFR           SKELETON AND COMPARE WITH THE      79200013
         BC    BH,STR300             AVAILABLE SPACE, BRANCH IF INSUFF- 79240013
STR240   L     GRZ,NXTBYT            ICIENT. SET UP THE ADDRESS OF THE  79280013
         LA    LR,MTFSKL             DESTINATION FIELD (GRZ),THE SOURCE 79320013
         L     GRD,FUBAS                                                79360013
         BAL   RR,MVTXT              FIELD(LR),AND THE LENGTH(GR10).    79400013
         L     GR10,BYTSFR             *                           *    79440013
         S     GR10,LENMSK             *    UPDATE THE NO OF      *     79480013
         ST    GR10,BYTSFR             *    BYTES FREE AND THE     *    79520013
         L     GR10,NXTBYT             *    ADDRESS OF THE NEXT    *    79560013
         A     GR10,LENMSK             *    FREE BYTE BY THE LENGTH*    79600013
         ST    GR10,NXTBYT             *    OF THE MTF SKELETON    *    79640013
         MVI   0(GR10),EOP2            OUTPUT 'END OF PROGRAM' MARKER.  79680013
         XR    GRZ,GRZ                 CLEAR THE ZERO REGISTER AGAIN.   79720013
         SPACE 5                                                        79760013
*              HERE X'7F' IS INSERTED IN THE LOWER BOUND POSITION OF    79800013
*        THE FIRST INHERITED DIMENSION (THE T'TH BOUND). X'3F' IS       79840013
*        INSERTED IN THE CORRESPONDING UPPER BOUND, AND IN THE          79880013
*        UPPER AND LOWER BOUNDS OF THE FOLLOWING N2-1 DIMENSIONS.       79920013
         SPACE                                                          79960013
         MVC   PAR1+2(2,GRDIC),SCFLSK+DIMREF                            80000013
         L     LR,ZDRFAB(GRCC)               DECODE THE DICTIONARY      80040013
         BALR  RR,LR                 REFERENCE OF NEW DIMENSION TABLE   80080013
         L     GR10,PAR1(GRDIC)      +16*T+13, THEN SUBTRACT ONE FROM   80120013
         SR    GR10,UT               IT.                                80160013
         L     LR,N2                                                    80200013
         AR    LR,LR                                                    80240013
         SR    LR,UT                   WE NOW HAVE 2*N2-1 IN LR.        80280013
         MVI   0(GR10),MTF1            MOVE IN MARKER TO INDICATE THIS  80320013
*                                    BOUND IS INITIALISED BY AN MTF     80360013
*                                    STATEMENT.                         80400013
STR250   LA    GR10,4(GR10)            POINT AT SLOT FOR NEXT BOUND IN  80440013
*                                    THE DIMENSION TABLE.               80480013
         CLI   0(GR10),0               BRANCH IF THIS BOUND IS KNOWN    80520013
         BC    BE,*+8                AT COMPILE TIME.                   80560013
         MVI   0(GR10),MTF2            MOVE IN MARKER TO INDICATE THAT  80600013
*                                    THIS BOUND WILL BE INITIALISED BY  80640013
*                                    THE PREVIOUS MTF STATEMENT.        80680013
         BCT   LR,STR250               BRANCH BACK IF THERE ARE         80720013
         MVC   PAR1+2(2,GRDIC),THSTR   MORE TO DO                       80760013
         L     LR,ZDRFAB(GRCC)         DECODE THE REFENC TO THE         80800013
         BALR  RR,LR                 STRUCTURE WE ARE PROCESSING.       80840013
         L     GR5,PAR1(GRDIC)                                          80880013
         BC    B,STR202                BRANCH TO TEST FOR ZERO T.       80920013
*                                                                       80960013
         SPACE 10                                                       81000013
*              THIS SECTION OF CODE GETS A NEW TEXT BLOCK AS THERE IS   81040013
*        INSUFFICIENT SPACE IN THE OLD ONE.                             81080013
         SPACE                                                          81120013
*        THE FIRST THING TO BE DONE IS INSERT AN END OF BUFFER MARKER   81160013
*        AT THE END OF THE TEXT IN THE OLD BLOCK                        81200013
STR300   L     LR,NXTBYT                                                81240013
         MVI   0(LR),ENDBUF                                             81280013
*        WE NOW GET A NEW TEXT BLOCK, CHAIN IT TO THE OLD ONE, MARKING  81320013
*        THAT ONE UNWANTED AND THE NEW ONE BUSY.                        81360013
         MVC   PAR1+1(3,GRDIC),ZLSTXT+1(GRDIC)                          81400013
         MVI   PAR2+3(GRDIC),CHUNWT    SET THE STATUS BYTE TO CHAIN AND 81440013
*                                    MARK OLD BLOCK AS UNWANTED.        81480013
         L     LR,ZUTXTC(GRCC)                                          81520013
         BALR  RR,LR                   ON RETURN SET THE POINTER TO THE 81560013
         L     LR,PAR2(GRDIC)        NEXT FREE BYTE AS THE START OF THE 81600013
         ST    LR,NXTBYT             NEW BLOCK AND ZLSTXT THE CODED     81640013
         MVC   ZLSTXT+1(3,GRDIC),PAR1+1(GRDIC)  VERSION OF THIS         81680013
         L     LR,ZBLSIZ(GRDIC)        GET THE BLOCK SIZE, SUBTRACT THE 81720013
         SR    LR,UR                 BYTE NEEDED FOR END OF PROGRAM OR  81760013
         ST    LR,BYTSFR             END OF BLOCK MARKER.               81800013
         BC    B,STR240              PROGRAM OR END OF BLOCK, STORE     81840013
*              THIS AS THE NUMBER OF FREE BYTES, THEN RETURN.           81880013
         EJECT                                                          81920013
*              AJDMRT ROUTINE                                           81960013
*                                                                       82000013
*              FUNCTION - ALTERS SECOND FILE STATEMENTS AND THEIR       82040013
*        DICTIONARY ENTRIES, FOR ADJUSTABLE DIMENSIONS IN STRUCTURE     82080013
*        ITEMS.  THE DICTIONARY REFERENCE OF THE STRUCTURE BASE ELEMENT 82120013
*        IS INSERTED INTO THE SECOND FILE STATEMENT AND THE NUMBER OF   82160013
*        DIMENSIONS IS INCREASED BY THE NUMBER BEING INHERITED.  A      82200013
*        POINTER TO THE THREE-BYTE SLOT IN THE DIMENSION TABLE IS       82240013
*        INSERTED INTO THE SECOND FILE DICTIONARY ENTRY.  A NOTE IS     82280013
*        KEPT OF SOME SLOTS IN THE SECOND FILE DICTIONARY ENTRY, WHICH  82320013
*        WILL BE NEEDED IF MORE SECOND FILE STATEMENTS ARE CREATED.     82360013
*                                                                       82400013
*              ENTRY POINT -- AJDMRT.  REGISTER GR10 POINTS TO THE      82440013
*        FIRST SLOT TO BE EXAMINED IN THE DIMENSION TABLE, THE WORD N3  82480013
*        HOLDS THE NUMBER OF BOUNDS SLOTS TO BE EXAMINED, AND REGISTER  82520013
*        RR HOLDS THE RETURN ADDRESS.                                   82560013
*                                                                       82600013
*              EXTERNAL ROUTINES - ZDABRF (CONTROL PHASE) CONVERTS      82640013
*        ABSOLUTE ADDRESS TO DICTIONARY REFERENCE.                      82680013
*                                  ZTXTAB (CONTROL PHASE) CONVERTS TEXT 82720013
*        REFERENCE TO ABSOLUTE ADDRESS.                                 82760013
*                                  ZDRFAB (CONTROL PHASE) CONVERTS      82800013
*        DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.                      82840013
*                                  ZALTER (CONTROL PHASE) ALTERS STATUS 82880013
*        OF TEXT BLOCK.                                                 82920013
*                                                                       82960013
*              EXIT - NORMAL - VIA REGISTER RR                          83000013
*                                                                       83040013
*              EXIT - ERROR - NONE                                      83080013
         SPACE 5                                                        83120013
AJDMRT   ST    RR,ADJSTO               SAVE THE LINK REGISTER.          83160013
         L     GRZ,N3                                                   83200013
STR500   EQU   *                                                        83220015
         LA    LR,1(GR10)              CALCULATE P+1                    83240013
         ST    LR,PAR2(0,GRDIC)                                         83280013
         MVC   PAR1+2(2,GRDIC),ZLOCK(GRDIC) AND THEN CONVERT IT         83320013
         L     LR,ZDABRF(GRCC)                   TO A REFERENCE,        83360013
         BALR  RR,LR                                                    83400013
         L     GRD,PAR1(GRDIC)                   AND STORE IT IN GRD.   83440013
         CLI   0(GR10),ADJBND        TEST FOR ADJUSTABLE BOUND          83480015
         BC    BNE,STR510              BRANCH IF IT IS NOT ADJUSTABLE   83520013
         MVC   PAR1+1(3,GRDIC),1(GR10)                                  83560013
         L     LR,ZTXTAB(GRCC)         DECODE THE REFERENCE TO THE      83600013
         BALR  RR,LR                 SECOND FILE STATEMENT.             83640013
         STH   GRD,HLFWRD              SAVE CODED VERSION OF P+1        83680013
         L     LR,PAR1(GRDIC)          MOVE THE DICTIONARY REFERENCE    83720013
         MVC   ELTREF(2,LR),BSELRF   OF THE BASE ELEMENT INTO THE       83760013
         IC    GR2,NODIMS(LR)        SECOND FILE STATEMENT. THEN BUMP   83800013
         A     GR2,T                 THE NUMBER OF THE DIMENSIONS IN    83840013
         STC   GR2,NODIMS(LR)        THE STATEMENT BY T.                83880013
         MVC   PAR1+2(2,GRDIC),SCNFRF(LR)   DECODE THE REFERENCE TO THE 83920013
         L     LR,ZDRFAB(GRCC)         SECOND FILE STATEMENT DICTIONARY 83960013
         BALR  RR,LR                 ENTRY                              84000013
         L     LR,PAR1(GRDIC)                                           84040013
         MVC   DIMREF(2,LR),HLFWRD     SORE THE CODED P+1 IN IT         84080013
          L     GRD,FUBAS                                               84100015
         MVC   SCFLSK+DCNUM(4),DCNUM(LR)  PUT THE DECLARE NUMBER,       84120013
         MVC   SCFLSK+LEVCNT(2),LEVCNT(LR) DICTIONARY REFERENCE OF      84160013
*                                    ENTRY TYPE1, LEVEL AND COUNT INTO  84200013
*                                    THE SKELETEN OF THE SECOND FILE    84240013
*                                    DICTIONARY ENTRY.                  84280013
         MVC   PAR1+1(3,GRDIC),1(GR10) MARK THE TEXT BLOCK CONTAINING   84320013
         MVI   PAR2+3(GRDIC),WANTED    THE SECOND FILE STATEMENT        84360013
         L     LR,ZALTER(GRCC)         WANTED INSTED OF BUSY.           84400013
         BALR  RR,LR                                                    84440013
STR510   LA    GR10,4(GR10)            BUMP THE DIMENSION TABLE         84480013
         BCT   GRZ,STR500              BRANCH IF N3 IS NOT ZERO.        84560013
          L     GRD,FUBAS                                               84580015
         L     RR,ADJSTO                                                84600013
         BCR   B,RR                    RETURN IF IT IS.                 84640013
         EJECT                                                          84680013
ZEROS    DC    H'00'                                                    84690016
ALLSTR   DC    X'00'                                                    84700016
CONTIG   DC    X'00'                                                    84710016
HALFWD   DC    X'0002FC0C'                                         H275 84715001
         EJECT                                                          84720013
         ORG   IEMFT+X'FB8'                                             84760015
DIMNO    DC    F'0'                    NO OF DIMS OF LABEL ARRAY STORED 84800013
FUBAS    DC    F'0'                    BASE ADDR OF FU STORED HERE      84840013
*                                    HERE                               84880013
         SPACE 2                                                        84920013
         EJECT                                                          84960013
         SPACE                                                          85000013
         EJECT                                                          85960013
*              TEMPORARY STORAGE  -  THE CODE INITIALISING THE PHASE    86000013
*        AN THE SECOND FILE SCAN IS OVERWRITTEN.                        86040013
         SPACE 3                                                        86080013
DW1      EQU   IEMFT+40                DOUBLE WORDS FOR DECIMAL ARITH-  86120013
DW2      EQU   DW1+8                 METIC IN STERLING PROCESSOR.       86160013
FW       EQU   DW2+8                   TEMPORARY STORAGE FULL WORD.     86200013
CONEND   EQU   FW+4                    SAVES ADDRESS OF END OF CONSTANT 86240013
SYMBLK   EQU   CONEND+4                SAVES SYMBOLIC ADDRESS OF BLOCK. 86280013
DVOFF    EQU   SYMBLK+4                STORAGE FOR OFFSETS IN MAJOR     86320013
DVADD    EQU   DVOFF+4               STRUCTURE OF BASE ELEMENTS DOPE    86360013
*                                    VECTOR, AND LENGTH OF DOPE VECTOR. 86400013
TEMP     EQU   DVADD+4                                                  86440013
ELTLTH   EQU   TEMP+4                                                   86480013
DIM1     EQU   ELTLTH+2                                                 86520013
DVSW     EQU   DIM1+1                                                   86560013
DIMBYT   EQU   DVSW+1                  THIS BYTE IS USED AS TWO         86600013
*                                    SWITCHES. THE FIRST FOUR BITS      86640013
*                                    INDICATE THAT THERE IS AN          86680013
*                                    ADJUSTABLE DIMENSION SOMEWHERE IN  86720013
*                                    THE STRUCTURE IF ONES, THE SECOND  86760013
*                                    INDICATES WHETHER A BASE ELEMENT   86800013
*                                    IS TO INHERIT ADJUSTABLE DIMENS-   86840013
*                                    IONS.                              86880013
SWITCH   EQU   DIMBYT+1                                                 86920013
HLFWRD   EQU   SWITCH+1                                                 86960013
ADJSTO   EQU   HLFWRD+2                LINK REGISTER STORAGE FOR ADJMRT 87000013
MDTSTO   EQU   ADJSTO+4                LINK REGISTER STORAGE FOR MKDMTB 87040013
MVSTOR   EQU   MDTSTO+4                LINK REGISTER STORAGE FOR MVTXT. 87080013
BYTSFR   EQU   MVSTOR+4                CONTAINS NUMBER OF FREE BYTES IN 87120013
NXTBYT   EQU   BYTSFR+4              CURRENT TEXT BLOCK, AND ADDRESS OF 87160013
*                                    NEXT FREE BYTE.                    87200013
SPSTOR   EQU   NXTBYT+4                                                 87240013
ALIGFL   EQU   SPSTOR+4                                                 87280013
BSELRF   EQU   ALIGFL+1                                                 87320013
CTLFL    EQU   BSELRF+2                                                 87360013
THSTR    EQU   CTLFL+1                                                  87400013
THSVIN   EQU   THSTR+2                                                  87440013
*                                    MAJOR STRUCTURE IS CONTROLLED.     87480013
UNCOM    EQU   THSVIN+2                                                 87520013
         EJECT                                                          87560013
         CNOP  0,4                                                      87600013
BDYMSK   DC    F'-4'                                                    87640013
ENDICT   DC    X'10000400'             FIRST DICTIONARY ENTRY MADE BY   87680013
*                                    THIS PHASE TO MARK PRESENT END OF  87720013
*                                    DICTIONARY                         87760013
*              CONSTANTS USED BY THE STRUCTURE ROUTINE                  87800013
         SPACE                                                          87840013
N1       DC    F'0'                                                     87880013
N2       DC    F'0'                                                     87920013
N3       DC    F'0'                                                     87960013
T        DC    F'0'                                                     88000013
         DC    H'0'                                                     88040013
NWDMTB   DC    H'0'                                                     88080013
UNALSW   DC    X'00'                   UNALIGNED SWITCH              I1 88100016
LENMSK   DC    F'34'                                                    88120013
TEMP1    DC    F'0'                                                     88160013
ZSTCHO   DC    X'0175'                 DICTIONARY REFERENCE OF ZSTACH   88200013
*                                    PLUS ONE.                          88240013
         SPACE 3                                                        88280013
*              THIS ROUTINE IS ENTERED FOLLOWING A DECIMAL OVERFLOW     88320013
*        CONDITION IN THE STERLING CONSTANT PROCESSOR.                  88360013
         SPACE                                                          88400013
LSDERR   MVC   PAR6+1(3,GRDIC),MESS2   SET UP MESSAGE INFORMATION.      88440013
         L     LR,ZUERR(0,GRCC)        PICK UP POINTER TO ERROR EDITOR. 88480013
         BCR   B,LR                  GO TO IT. THE RETURN REGISTER      88520013
*                                    BACK TO THE STERLING CONSTANT      88560013
*                                    PROCESSOR (PERHAPS VIA THE CONTROL 88600013
*                                    SYSTEM) IS ALREADY SET UP.         88640013
MESS2    DC    X'02F704'                                                88680013
MESS1    DC    X'02F600'                                                88720013
         SPACE 3                                                        88760013
TWO      DC    1H'2'                                                    88800013
CONLTH   DC    H'14'                                                    88840013
         SPACE                                                          89000013
         END   IEMFT                                                    89040013
