HP       TITLE 'IEMHP, ISUB-DEFINED SUBSTITUTION/PRETRANSLATOR, PL/I F' 00060013
IEMHP    START 0                                                        00120013
         SPACE 4                                                        00180013
*              STATUS - CHANGE LEVEL 0                                  00240013
*                                                                       00300013
*                                                                       00360013
*                                                                       00420013
*              FUNCTIONS (1) OBTAINS SCRATCH CORE FOR A STACK.          00480013
*                        (2) MOVES THE TEXT, SCANNING FOR DEFINED       00540013
*        SUBSCRIPT MARKERS.                                             00600013
*                        (3) WHEN ONE IS FOUND, PROCESSES THE TWO       00660013
*        SUBSCRIPT LISTS WHICH FOLLOW TO OBTAIN THE CORRESPONDING       00720013
*        SUBSCRIPT LIST FOR THE BASE ARRAY, AND OUTPUTS THIS IN PLACE   00780013
*        OF THE TWO INPUT LISTS.                                        00840013
*                                                                       00900013
*                                                                       00960013
*                                                                       01020013
*              ENTRY POINTS (1) INIT.  MAIN ENTRY FOR PROCESSING, FROM  01080013
*        CONTROL PHASE.                                                 01140013
*                                                                       01200013
*                                                                       01260013
*                                                                       01320013
*              INPUT - TEXT PRODUCED BY PRECEDING PHASE, IN WHICH A     01380013
*        REFERENCE TO AN ISUB-DEFINED ITEM HAS THE FORMAT SHOWN IN THE  01440013
*        FOLLOWING EXAMPLE -                                            01500013
*                                                                       01560013
*              DECLARE B (10,10,10),                                    01620013
*        A (10,10) DEFINED B (I+1SUB+P*2SUB, I+J+(Q-R)*2SUB, 1SUB);     01680013
*                                                                       01740013
*              THE REFERENCE  A(M,L-N)  WOULD APPEAR AS                 01800013
*                                                                       01860013
*        A DSM(I+SUB1+P*SUB2,I+J+(Q-R)*SUB2,SUB1)SM(M,L-N)              01920013
*                                                                       01980013
*        WHERE DSM = DEFINED SUBSCRIPT MARKER, SM = SUBSCRIPT MARKER,   02040013
*        AND SUB ARE ALL ONE-BYTE MARKERS, AND VARIABLES APPEAR AS      02100013
*        DICTIONARY REFERENCES.                                         02160013
*                                                                       02220013
*                                                                       02280013
*                                                                       02340013
*              OUTPUT - TEXT WITH BASE-ARRAY SUBSCRIPT LISTS FOR ISUB-  02400013
*        DEFINED ITEMS.  THE ABOVE EXAMPLE MIGHT APPEAR AS              02460013
*                                                                       02520013
*        (BUY T1; T1=M; BUY T2; T2=L-N;) B SM (I+T1+P*T2,I+J+(Q-R)*T2,  02580013
*        T1) (SELL T1; SELL T2;)                                        02640013
*                                                                       02700013
*        WHERE THE T'S ARE INTEGER TEMPORARIES.  THIS IS THE 'WORST     02760013
*        CASE' EXPANSION OF THE EXAMPLE - IF M WERE AN INTEGER, T1      02820013
*        WOULD NOT EXIST.                                               02880013
*                                                                       02940013
*                                                                       03000013
*                                                                       03060013
*              EXTERNAL ROUTINES - ZTXTAB - CONVERTS TEXT REFERENCE TO  03120013
*        ABSOLUTE ADDRESS.                                              03180013
*                                  ZUGC - GETS SCRATCH CORE.            03240013
*                                  ZDRFAB - CONVERTS DICTIONARY         03300013
*        REFERENCE TO ABOSLUTE ADDRESS.                                 03360013
*                                  ZCHAIN - GETS NEXT SOURCE TEXT BLOCK 03420013
*        IN THE CHAIN.                                                  03480013
*                                  ZTXTRF - CONVERTS ADDRESS TO TEXT    03540013
*        REFERENCE.                                                     03600013
*                                  ZURC - RELEASES SCRATCH CORE.        03660013
*                                  ZUTXTC - GETS TEXT CORE.             03720013
*                                  ZALTER - ALTERS STATUS OF TEXT BLOCK 03780013
*                                  RLSCTL - RELEASES CONTROL.           03840013
*                                  ZDICRF - MAKES DICTIONARY ENTRY.     03900013
*                                  ZUERR - MAKES DICTIONARY ENTRY FOR   03960013
*        ERROR MESSAGE.                                                 04020013
*                                  ZABORT - TERMINATES COMPILATION.     04080013
*                                                                       04140013
*              THE ABOVE ARE ALL CONTROL PHASE ROUTINES.                04200013
*                                                                       04260013
*                                                                       04320013
*                                                                       04380013
*              EXIT - NORMAL - VIA RLSCTL (CONTROL PHASE) WHEN ALL TEXT 04440013
*        HAS BEEN SCANNED.                                              04500013
*                                                                       04560013
*                                                                       04620013
*                                                                       04680013
*              EXIT - ERROR - VIA ZABORT (CONTROL PHASE) WHEN A         04740013
*        DISASTROUS ERROR IS FOUND.                                     04800013
*                                                                       04860013
*                                                                       04920013
*                                                                       04980013
*              TABLES - TABLE - A 256-BYTE TRT-TABLE USED TO SCAN THE   05040013
*        SOURCE TEXT.                                                   05100013
*                                                                       05160013
*                                                                       05220013
*                                                                       05280013
*              ATTRIBUTES - NONE.                                       05340013
*                                                                       05400013
*                                                                       05460013
*                                                                       05520013
*              NOTES (1) THIS MODULE REQUIRES NO MODIFICATION AS A      05580013
*        RESULT OF CHANGES IN THE INTERNAL REPRESENTATION OF EXTERNAL   05640013
*        GRAPHICS.                                                      05700013
*                                                                       05760013
*                    (2) REGISTER USAGE.  THE FOLLOWING SHOULD BE       05820013
*        ESPECIALLY NOTED -                                             05880013
*              GR0 - HOLDS CONSTANT '0'                                 05940013
*              SP - SOURCE TEXT SCAN POINTER                            06000013
*              STACK - POINTER TO PUSH-DOWN STACK                       06060013
*              ONE - HOLDS CONSTANT '1'                                 06120013
*              OP - OUTPUT TEXT POINTER                                 06180013
*                                                                       06240013
*                    (3) THE PUSH-DOWN STACK.  THIS STACK, KEPT IN      06300013
*        SCRATCH CORE, IS NECESSARY BECAUSE ISUB-DEFINED REFERENCES MAY 06360013
*        BE NESTED (WITHIN THE SUBSCRIPT-LIST OF ANOTHER SUCH ITEM).    06420013
*        IN FACT THERE ARE TWO STACKS.  ONE, WORKING FROM THE BOTTOM OF 06480013
*        SCRATCH CORE UPWARDS, HOLDS 28 BYTES OF PARAMETERS IN EACH     06540013
*        LEVEL.  THE OTHER WORKS FROM THE TOP OF SCRATCH DOWNWARDS, AND 06600013
*        HOLDS REFERENCES OF TEMPORARIES AND SUBSCRIPTS, THE NUMBER OF  06660013
*        BYTES REQUIRED FOR EACH LEVEL BEING A FUNCTION OF THE          06720013
*        DIMENSIONALITY OF THE DEFINED ARRAY.                           06780013
         EJECT                                                          06840013
*                       BRANCHING CONDITIONS                            06900013
         SPACE                                                          06960013
B        EQU   15            BRANCH ALWAYS                              07020013
BH       EQU   2                    ON HIGH                             07080013
BL       EQU   4                    ON LOW                              07140013
BE       EQU   8                    ON EQUAL                            07200013
BHE      EQU   10                   ON HIGH OR EQUAL                    07260013
BLE      EQU   12                   ON LOW OR EQUAL                     07320013
BNE      EQU   7                    ON NOT EQUAL                        07380013
BZ       EQU   8                    ON ZERO                             07440013
BNZ      EQU   7                    ON NOT ZERO                         07500013
BO       EQU   1                    ON ONES                             07560013
BNO      EQU   14                   ON NOT ONES                         07580016
NOP      EQU   0                    NEVER                               07600016
BM       EQU   4                    ON MINUS                            07620013
BMZ      EQU   12                   ON MINUS OR ZERO                    07680013
         SPACE 2                                                        07740013
*                       CODE BYTES                                      07800013
         SPACE                                                          07860013
SC       EQU   X'D0'         CODE FOR STATEMENT LABEL OR NUMBER         07920013
SN       EQU   X'D0'         STATEMENT NUMBER                           07980013
SL       EQU   X'D2'         STATEMENT LABEL                            08040013
CN       EQU   X'D4'         COMPILE-TIME STATEMENT NUMBER              08100013
CL       EQU   X'D6'         COMPILER STATEMENT LABEL                   08160013
SN2      EQU   X'BC'         AFTER-PROGRAM STATEMENT NUMBER             08220013
EOB      EQU   X'ED'         END OF BUFFER                              08280013
EOP      EQU   X'EB'         END OF PROGRAM                             08340013
LP       EQU   X'43'         LEFT PARENTHESIS                           08400013
RP       EQU   X'45'         RIGHT PARENTHESIS                          08460013
CMA      EQU   X'41'         COMMA                                      08520013
SUB      EQU   X'FE'         ISUB                                       08580013
DSM      EQU   X'2E'         DEFINED SUBSCRIPT MARKER                   08640013
SM       EQU   X'3E'         SUBSCRIPT MARKER                           08700013
AST      EQU   X'FC'         ASTERISK (CIRCLED)                         08760013
DIM      EQU   X'10'         TO TEST 4TH BIT OF DICT ENTRY              08820013
OPOF     EQU   X'00'         OPERAND MARKER                             08880013
SCLN     EQU   X'EF'         SEMI-COLON                                 08940013
LCB      EQU   X'51'         LEFT CURLY BRACKET                         09000013
RCB      EQU   X'71'         RIGHT CURLY BRACKET                        09060013
BUY      EQU   X'AD'         BUY STMT                                   09120013
SELL     EQU   X'AC'         SELL STMT                                  09180013
ASGT     EQU   X'9F'         ASSIGNMENT STMT                            09240013
AM       EQU   X'47'         ASSIGN-MARKER (LEFT ARROW)                 09300013
XD       EQU   X'20'         TO TEST 'MENTIONED IN CHECK LIST' BIT      09360013
ENT      EQU   X'B1'         ENTRY STATEMENT                            09420013
PROC     EQU   X'B3'         PROCEDURE STATEMENT                        09480013
BGN      EQU   X'B5'         BEGIN STATEMENT                            09540013
ENDB     EQU   X'E9'         END STATEMENT                              09600013
CADNF    EQU   X'80'         TO TEST DATA BYTE - CAD/NUMERIC FIELD      09660013
FXFL     EQU   X'02'         TO TEST DATA BYTE - FIXED/FLOAT            09720013
VARB     EQU   X'0F'         SCALAR VARIABLE DICTIONARY ENTRY           09780013
TMPFP    EQU   X'8F'         TEMPORARY OR FORMAL PARAMETER DICT ENTRY   09840013
CONST    EQU   X'88'         CONSTANT DICTIONARY ENTRY                  09900013
NEW      EQU   X'00'         NO CHAIN OR STATUS CHANGE                  09960013
FREE     EQU   X'01'         MARK OLD BLOCK FREE                        10020013
NWNT     EQU   X'02'         MARK OLD BLOCK NOT WANTED                  10080013
BUSY     EQU   X'00'         MARK OLD BLOCK BUSY                        10140013
OUT      EQU   X'82'         CHAIN AND MARK OLD BLOCK NOT WANTED        10200013
BSY      EQU   X'84'         CHAIN AND MARK OLD BLOCK BUSY              10260013
SUBRG    EQU   X'08'         TO TEST SUBRG BIT IN PREFIX OPTIONS BYTE   10264015
DON      EQU   X'CD'         CODE BYTE FOR ON STMT DICTIONARY ENTRY     10268015
SBRNGE   EQU   X'D8'         CODE BYTE FOR SUBRG CONDITION              10272015
IF       EQU   X'BB'         IF STATEMENT                               10276015
THEN     EQU   X'8A'         THEN                                       10280015
SGNL     EQU   X'97'         SIGNAL STATEMENT                           10284015
DE3      EQU   X'84'         CODE BYTE FOR DICTIONARY ENTRY TYPE 3      10288015
DE4      EQU   X'03'         CODE BYTE FOR DICTIONARY ENTRY TYPE 4      10292015
DE5      EQU   X'83'         CODE BYTE FOR DICTIONARY ENTRY TYPE 5      10296015
LT       EQU   X'6F'         LESS THAN                                  10300015
GT       EQU   X'6D'         GREATER THAN                               10304015
LOW      EQU   0             CODE FOR LOW-BOUND ADV                     10308015
HIGH     EQU   1             CODE FOR HIGH-BOUND ADV                    10312015
OPD      EQU   OPOF                                                     10320013
         SPACE 2                                                        10380013
*                       OFFSETS IN PUSH-DOWN STACK                      10440013
         SPACE                                                          10500013
CBLVL    EQU   0             CURLY BRACKET LEVEL           1 BYTE       10560013
RETDEF   EQU   0             RETURN ADDRESS IN DEFSUB      4 BYTES      10620013
END      EQU   4             END OF 2ND SUBSCRIPT LIST     4 BYTES      10680013
OPDRES   EQU   8             SOURCE TEXT ADDR OF OPERAND   4 BYTES      10740013
LEVEL    EQU   12            PARENTHESIS LEVEL             1 BYTE       10800013
DIMBAS   EQU   13            DIMENSIONALITY OF BASE ARRAY  1 BYTE       10860013
DICREF   EQU   14            ISUB-DEFINED DICT REFCE       2 BYTES      10920013
R3ST     EQU   16            POINTER TO LIST OF TEMPS      4 BYTES      10980013
LASTMP   EQU   20            START OF SUBSCRIPT-TEMP TABLE 4 BYTES      11040013
BASDIC   EQU   24            BASE ARRAY DICT REFCE         2 BYTES      11100013
DIMS     EQU   26            ISUB-DEFINED DIMENSIONALITY   1 BYTE       11160013
SW       EQU   27            SWITCH FOR SU-ROUTINES        1 BYTE       11220013
         SPACE                                                          11280013
*                       NOTE THAT SOME 1-BYTE ITEMS OCCUPY THE TOP      11340013
*                  BYTE OF A 4-BYTE ADDRESS ITEM, TO SAVE STACK SPACE   11400013
         SPACE 4                                                        11460013
*                       CONTROL AND OTHER OFFSETS                       11520013
         SPACE                                                          11580013
*              CONTROL PHASE ROUTINE TRANSFER VECTOR                    11640013
         SPACE                                                          11700013
ZUGCOF   EQU   16            ZUGC   - GET SCRATCH CORE                  11760013
ZUTXOF   EQU   20            ZUTXTC - GET TEXT CORE                     11820013
ZURCOF   EQU   24            ZURC   - RELEASE SCRATCH CORE              11880013
ZABORT   EQU   32            ZABORT - TERMINATE COMPILATION             11940013
ZDRFOF   EQU   44            ZDICRF - MAKE DICTIONARY ENTRY             12000013
ZUERR    EQU   48            ZUERR  - ADD TO ERROR MESSAGE CHAIN        12060013
ZDRAOF   EQU   52            ZDRFAB - CONVERT DICT REFCE TO ABS ADDR    12120013
RLSCTL   EQU   72            RLSCTL - RELEASE CONTROL                   12180013
ZTXROF   EQU   80            ZTXTRF - CONVERT ADDRESS TO TEXT REFCE     12240013
ZTXAOF   EQU   84            ZTXTAB - CONVERT TEXT REFCE TO ABS ADDR    12300013
ZCHNOF   EQU   88            ZCHAIN - GET NEXT TEXT BLOCK IN CHAIN      12360013
ZALTOF   EQU   92            ZALTER - ALTER STATUS OF TEXT BLOCK        12420013
         SPACE                                                          12480013
*              DICTIONARY COMMUNICATIONS REGION OFFSETS                 12540013
         SPACE                                                          12600013
ZTV      EQU   64            CONTROL TRANSFER VECTOR ADDRESS            12660013
MYNAME   EQU   112           PROGRAM IDENTITY                           12720013
STMTNO   EQU   126           STATEMENT NUMBER                           12780013
PAR1     EQU   128           PARAMETER SLOT 1                           12840013
PAR2     EQU   132           PARAMETER SLOT 2                           12900013
PAR6     EQU   PAR1+20       PARAMETER SLOT 6                           12960013
PAR7     EQU   PAR1+24       PARAMETER SLOT 7                           13020013
START    EQU   256           REFERENCE OF FIRST TEXT BYTE               13080013
TBLOCL   EQU   264           LENGTH OF TEXT BLOCK                       13140013
LOCK     EQU   274           DICTIONARY BLOCK LOCK SLOT                 13200013
LASTXT   EQU   276           REFERENCE OF LAST BYTE OF TEXT             13260013
ZCOMM    EQU   304           SECOND COMMUNICATIONS REGION               13320013
SECFIL   EQU   ZCOMM+44      REFCE OF FIRST BYTE OF SECOND TEXT FILE    13380013
ZCONCH   EQU   ZCOMM+78      START OF CONSTANTS CHAIN                   13440013
         SPACE                                                          13500013
*              TEXT AND DICTIONARY ENTRY OFFSETS                        13560013
         SPACE                                                          13620013
STCT     EQU   4             CONTROL BYTES AT START OF STMT             13680013
OFFSET   EQU   4             LENGTH OF OPTIONAL SECOND OFFSET SLOT      13740013
SN2NO    EQU   3             2ND FILE DICT ENTRY - STMT NUMBER          13800013
SLNO     EQU   8             STMT LABEL DICT ENTRY - STMT NUMBER        13860013
E1BCOD   EQU   34            DICT ENTRY TYPE 1 (BEGIN) - LABEL CODE     13920013
E1E1     EQU   5             DICT ENTRY TYPE 1 - E1 OF CONTAINING BLOCK 13980013
E1LBL    EQU   7             DICT ENTRY TYPE 1 - REFCE OF STMT LABEL    14040013
E1AUTO   EQU   11            DICT ENTRY TYPE 1 - AUTOMATIC CHAIN ANCHOR 14100013
DATINF   EQU   6                       LENGTH OF DATA/DATINF/SYMBOL     14110016
*                                    SLOT FIELDS IN DATA ENTRY.         14120016
STRUCT   EQU   10                      STRUCTURE SLOT LENGTH.           14130016
EXTRNL   EQU   2                       EXTERNAL (ESD) SLOT LENGTH.      14140016
DIMOFF   EQU   15                      DIMENSION SLOT OFFSET, AND       14150016
BASOFF   EQU   20                      BASE REFERENCE OFFSET, FOR       14160016
*              'SIMPLE' DIMENSIONED  LABEL, TASK, AND EVENT ENTRIES.    14170016
VBYTE    EQU   11            DATA ITEM DICT ENTRY - VARIABLE CODE BYTE  14220013
CHN      EQU   3             CONSTANT DICT ENTRY - CONSTANTS CHAIN      14280013
CONDA1   EQU   5             CONSTANT DICT ENTRY - 1ST DATA BYTE        14400013
CONTYP   EQU   8             CONSTANT DICT ENTRY - TYPE BYTE            14460013
CONDA2   EQU   9             CONSTANT DICT ENTRY - 2ND DATA BYTE        14520013
CONSF2   EQU   CONDA2+2      CONSTANT DICT ENTRY - 2ND SCALE FACTOR     14580013
CONNO    EQU   12            CONSTANT DICT ENTRY - STMT NUMBER          14610015
VARDAT   EQU   15            DATA ITEM DICT ENTRY - DATA BYTE           14640013
VARSF    EQU   VARDAT+2      DATA ITEM DICT ENTRY - SCALE FACTOR        14700013
DCL      EQU   8             DATA ITEM DICT ENTRY - DECLARE STMT NUMBER 14760013
BCDNO    EQU   3             LABEL BCD DICT ENTRY - STMT NUMBER         14820013
OTHER1   EQU   10            STMT LABEL ENTRY - 'OTHER 1' CODE BYTE     14880013
TLC      EQU   21            TEMPORARY DICT ENTRY - LEVEL & COUNT       14940013
E1LC     EQU   3             ENTRY TYPE 1 - LEVEL AND COUNT             15000013
ONID     EQU   8             ON CONDITION DICT ENTRY - IDENTIFIER CODE  15010015
ONLC     EQU   9             ON CONDITION DICT ENTRY - LEVEL AND COUNT  15020015
SBRGLE   EQU   11            LENGTH OF DICT ENTRY FOR SUBRG CONDITION   15030015
EAUT     EQU   11            DICT ENTRY TYPE 3/4/5 - AUTOMATIC CHAIN    15040015
         SPACE                                                          15060013
*              LENGTHS OF DATA ITEMS                                    15120013
         SPACE                                                          15180013
DUBLEN   EQU   56            TWICE LENGTH OF PUSH-DOWN STACK            15240013
STACKL   EQU   4094          SIZE OF SCRATCH CORE                       15300013
CONLN    EQU   14            LENGTH OF DICT ENTRY FOR CONSTANT (NO BCD) 15360013
ZEROLN   EQU   18            LENGTH OF DICT ENTRY FOR 'ZERO'            15420013
TEMPLE   EQU   23            LENGTH OF DICT ENTRY FOR TEMPORARY         15480013
         SPACE                                                          15540013
*              SWITCH BITS                                              15600013
         SPACE                                                          15660013
EOBON    EQU   X'40'         END-OF-BUFFER/ON                           15720013
EOBOFF   EQU   X'BF'                     /OFF                           15780013
T1ON     EQU   X'04'                                                    15840013
T1OFF    EQU   X'FB'                                                    15900013
L1ON     EQU   X'02'              L1 - 2ND SUBSCRIPT LIST BEING         15960013
L1OFF    EQU   X'FD'            SCANNED FOR EOB'S                       16020013
T1LIST   EQU   X'14'                                                    16080013
SUOFF    EQU   X'8F'                                                    16140013
LIST     EQU   X'50'                                                    16200013
LISTON   EQU   X'10'                                                    16260013
OMVON    EQU   X'40'                                                    16320013
ER1ON    EQU   X'80'                                                    16380013
ER1OFF   EQU   X'7F'                                                    16440013
TMP      EQU   X'03'                                                    16500013
NOTMP    EQU   X'FC'                                                    16560013
         SPACE 5                                                        16620013
*                       GENERAL REGISTERS                               16680013
         SPACE                                                          16740013
GR0      EQU   0             HOLDS 'ZERO'                               16800013
SP       EQU   1             SOURCE-TEXT POINTER                        16860013
L1       EQU   2             GENTST PARAMETER                           16920013
GRQ      EQU   2             FOR ONE-BYTE OPERANDS                      16980013
GR3      EQU   3             POINTER FOR TEMPS                          17040013
TEMPR    EQU   3             USED BY MOVE AND GENTST ROUTINES           17100013
CBL      EQU   3             CURLY BRACKET LEVEL                        17160013
GR4      EQU   4             TEMP-TABLE INCREMENT                       17220013
LVL      EQU   4             LEVEL OF PARENTHESES IN SUBLIST            17280013
GR5      EQU   5             TEMP-TABLE COMPARAND                       17340013
P3       EQU   6             DICTIONARY POINTER                         17400013
GR6      EQU   6             HOLDS ISUB NUMBER                          17460013
STACK    EQU   8             BASE FOR PUSH-DOWN STACK                   17520013
ONE      EQU   9             HOLDS 'ONE'                                17580013
P2       EQU   10            POINTS TO NEXT BYTE TO BE MOVED            17640013
CTRL     EQU   11            BASE FOR CONTROL PHASE                     17700013
OP       EQU   12            OUTPUT POINTER                             17760013
DICT     EQU   13            DICTIONARY BASE                            17820013
GRX      EQU   14            EXIT REGISTER FOR CALLING CONTROL ROUTINES 17880013
LINKR    EQU   14            SUBROUTINE LINK                            17940013
B1       EQU   15            BASE OF FIRST PHASE                        18000013
         EJECT                                                          18060013
*              MASTER ROUTINE                                           18120013
*                                                                       18180013
*              FUNCTIONS (1) CALLS COMPILER CONTROL TO LOAD MODULE      18240013
*        IEMHQ, GET 4K OF SCRATCH CORE FOR A PUSH-DOWN STACK, AND GET   18300013
*        TEXT CORE FOR THE OUTPUT TEXT, AND SETS UP POINTERS AND        18360013
*        CONSTANTS.                                                     18420013
*                        (2) SCANS THE SOURCE TEXT, MOVING IT TO OUTPUT 18480013
*        STATEMENT BY STATEMENT.                                        18540013
*                        (3) CALLS 'DEFSUB' WHEN AN ISUB-DEFINED        18600013
*        REFERENCE IS FOUND.                                            18660013
*                        (4) RELEASES CONTROL AT END OF SOURCE TEXT.    18720013
*                                                                       18780013
*              ENTRY POINTS (1) INIT - FROM COMPILER CONTROL            18840013
*                           (2) MASCAN - TO CONTINUE SCAN OF SOURCE     18900013
*        TEXT.                                                          18960013
*                                                                       19020013
*              EXTERNAL ROUTINES - ZLOADW (CONTROL PHASE) LOADS MODULE  19080013
*        IEMHQ.                                                         19140013
*                                  ZTXTAB (CONTROL PHASE) CONVERTS TEXT 19200013
*        REFERENCE TO ABSOLUTE ADDRESS.                                 19260013
*                                  ZUGC (CONTROL PHASE) GETS SCRATCH    19320013
*        CORE FOR STACK.                                                19380013
*                                  ZUTXTC (CONTROL PHASE) GETS TEXT     19440013
*        CORE FOR OUTPUT.                                               19500013
*                                  ZDRFAB (CONTROL PHASE) CONVERTS      19560013
*        DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.                      19620013
*                                  MOVE (THIS MODULE) MOVES TEXT FROM   19680013
*        SOURCE TO OUTPUT.                                              19740013
*                                  ZCHAIN (CONTROL PHASE) GETS NEXT     19800013
*        SOURCE TEXT BLOCK IN CHAIN.                                    19860013
*                                  ZTXTRF (CONTROL PHASE) CONVERTS      19920013
*        ADDRESS TO TEXT REFERENCE.                                     19980013
*                                  ZURC (CONTROL PHASE) RELEASES        20040013
*        SCRATCH CORE.                                                  20100013
*                                  ZALTER (CONTROL PHASE) ALTERS STATUS 20160013
*        OF TEXT BLOCK.                                                 20220013
*                                  RLSCTL (CONTROL PHASE) RELEASES      20280013
*        CONTROL.                                                       20340013
*                                                                       20400013
*              EXITS - NORMAL (1) TO DEFSUB (THIS MODULE) FROM MATEST,  20460013
*        WHEN AN ISUB-DEFINED ITEM IS FOUND.                            20520013
*                             (2) VIA RLSCTL (CONTROL PHASE) FROM MAFIN 20580013
*        WHEN THE END OF THE SOURCE TEXT IS FOUND.                      20640013
*                                                                       20700013
*              EXITS - ERROR - NONE.                                    20760013
*                                                                       20820013
*              TABLE - 'TABLE' IS USED TO SCAN THE SOURCE               20880013
*        TEXT BY THE TRT INSTRUCTION LABELLED MASCAN.                   20940013
         SPACE 2                                                        21000013
         USING *,B1                                                     21060013
PROGID   DC    C'HP'                                                    21120013
         L     15,PAR1(0,DICT)                                          21180013
         BC    B,INIT                                                   21240013
         SPACE 4                                                        21300013
*                       TRANSFER VECTOR                                 21360013
         SPACE                                                          21420013
         BC    B,ERROR                                                  21480013
         BC    B,ERMAS                                                  21540013
         SPACE 4                                                        21600013
INIT     LH    GR6,PROGID                                               21660013
         STH   GR6,MYNAME(0,DICT)                                       21720013
         SR    GR0,GR0                                                  21780013
         LA    ONE,1                                                    21840013
         L     CTRL,ZTV(0,DICT)                                         21900013
         SPACE                                                          21960013
         L     GR6,START(0,DICT)                                        22020013
         ST    GR6,INBLOK                                               22080013
         ST    GR6,PAR1(0,DICT)        SET SOURCE POINTER               22140013
         L     GRX,ZTXAOF(0,CTRL)                                       22200013
         BALR  LINKR,GRX                                                22260013
         L     SP,PAR1(0,DICT)                                          22320013
         SPACE 1                                                        22380013
         LA    GR4,8                   GET   4K  SCRATCH CORE FOR STACK 22440013
         ST    GR4,PAR1(0,DICT)                                         22500013
         L     GRX,ZUGCOF(0,CTRL)                                       22560013
         BALR  LINKR,GRX                                                22620013
         L     STACK,PAR1(0,DICT)                                       22680013
         ST    STACK,ORIGIN                                             22740013
         LA    STACK,STACKL(STACK)                                      22800013
         ST    STACK,LIMIT                                              22860013
         L     STACK,ORIGIN                                             22920013
         ST    LINKR,LOWPSW                                             22980013
         SPM   GR0                     MASK OFF INTERRUPTS              23040013
         SPACE 2                                                        23100013
         LA    OP,NEW                  GET TEXT BLOCK FOR OUTPUT        23160013
         ST    OP,PAR2(0,DICT)                                          23220013
         L     GRX,ZUTXOF(0,CTRL)                                       23280013
         BALR  LINKR,GRX                                                23340013
         L     OP,PAR1(0,DICT)                                          23400013
         ST    OP,START(0,DICT)        SAVE START OF OUTPUT             23460013
         ST    OP,OUBLOK                                                23520013
         L     OP,PAR2(0,DICT)         SET OUTPUT POINTER               23580013
         LR    P2,SP                                                    23640013
         L     GR6,TBLOCL(0,DICT)                                       23700013
         AR    GR6,OP                                                   23760013
         ST    GR6,BLKEND              SET BLKEND                       23820013
         BCT   SP,MASCAN                                                23880013
         SPACE 5                                                        23940013
MASTMT   ST    OP,STSTAT                                                24000013
         IC    GRQ,3(SP)               SAVE PREFIX OPTION BYTE          24020015
         STC   GRQ,POB                                                  24040015
         LA    SP,STCT(0,SP)                                            24060013
         SPACE 1                                                        24120013
MASCAN   TRT   1(256,SP),TABLE                                          24180013
         BC    BNZ,MATEST              BRANCH IF CHARACTER FOUND,       24240013
         LA    SP,256(0,SP)          OTHERWISE                          24300013
         BC    B,MASCAN              CONTINUE SCAN                      24360013
         SPACE 2                                                        24420013
MATEST   CLI   0(SP),OPOF              IS BYTE FOUND OPERAND            24480013
         BC    BNE,MATST3                                               24540013
         LA    SP,2(0,SP)              YES - BYPASS DICT REFCE AND      24600013
         BC    B,MASCAN              CONTINUE SCAN                      24660013
         SPACE 2                                                        24720013
MATST3   CLI   0(SP),DSM               IS BYTE FOUND DEFINED SUBSCRIPT  24780013
         BC    BNE,MA30              MARKER                             24840013
         SH    SP,THREE                YES - BACKSPACE SOURCE POINTER   24900013
         BC    B,DEFSUB                                                 24960013
               SPACE 2                                                  25020013
MA30     STC   2,FOUND                 STORE BYTE FOUND                 25080013
         CLI   FOUND,SC                IS BYTE FOUND A STMT LABEL/NO.   25140013
         BC    BNE,MATST4                                               25200013
         CLI   STCT(SP),ENDB           IS IT AN END STMT                25260013
         BC    BNE,MA31                                                 25320013
         L     GR4,AUTCHN              YES - GET CURRENT ENTRY TYPE 1   25380013
         MVC   PAR1+2(2,DICT),E1E1(GR4)                                 25440013
         L     GRX,ZDRAOF(CTRL)        CHAIN BACK TO ENTRY TYPE 1 OF    25500013
         BALR  LINKR,GRX             CONTAINING BLOCK                   25560013
         L     GR5,PAR1(DICT)                                           25620013
         ST    GR5,AUTCHN              SAVE ITS ADDRESS AND LOCK IN     25680013
         MVC   LOCK(2,DICT),E1E1(GR4) ITS DICTIONARY BLOCK              25740013
         SPACE 1                                                        25800013
MA31     CLI   0(SP),SN                IS THIS UNLABELLED STMT          25860013
         BC    BNE,MA32                                                 25920013
         MVC   STMTNO(2,DICT),1(SP)    YES - SET STMTNO FROM TEXT       25980013
         SPACE 1                                                        26040013
MA37     LA    LINKR,MASTMT            SET RETURN ADDRESS AND           26100013
         BC    B,MOVE                CALL 'MOVE' ROUTINE                26160013
MA32     CLI   0(SP),CN                SIMILARLY FOR COMPILER STMT      26220013
         BC    BE,MA37                                                  26280013
         ST    GR0,PAR1(0,DICT)        NO - GET STMT DICTIONARY ENTRY   26340013
         MVC   PAR1+2(2,DICT),1(SP)                                     26400013
         L     GR6,ZDRAOF(CTRL)                                         26460013
         BALR  LINKR,GR6                                                26520013
         L     GR4,PAR1(0,DICT)                                         26580013
         CLI   0(SP),SN2               IS IT SECOND FILE STMT           26640013
         BC    BNE,MA33                                                 26700013
         MVC   STMTNO(2,DICT),SN2NO(GR4)   YES - SET STMTNO FROM 2ND    26760013
         BC    B,MA37                    FILE DICT ENTRY                26820013
         SPACE 1                                                        26880013
MA33     CLI   STCT(SP),PROC               NO - LABELLED STMT - IS IT   26940013
         BC    BE,MA36                   PROCEDURE, ENTRY, BEGIN        27000013
         CLI   STCT(SP),ENT                                             27060013
         BC    BE,MA38                                                  27120013
         CLI   STCT(SP),BGN                                             27180013
         BC    BE,MA35                                                  27240013
MA34     TM    OTHER1(GR4),XD          NO - IS LABEL MENTIONED IN CHECK 27300013
         BC    BZ,MA340              LIST                               27360013
         MVC   PAR1+2(2,DICT),SLNO(GR4)  YES - GET LABEL BCD DICT ENTRY 27420013
         BALR  LINKR,GR6               AND SET STMTNO FROM IT           27480013
         L     GR4,PAR1(DICT)                                           27540013
         MVC   STMTNO(2,DICT),BCDNO(GR4)                                27600013
         BC    B,MA37                                                   27660013
MA340    MVC   STMTNO(2,DICT),SLNO(GR4)  NO - SET STMTNO FROM STATEMENT 27720013
         BC    B,MA37                    LABEL DICT ENTRY               27780013
         SPACE 1                                                        27840013
MA35     CLI   E1BCOD(GR4),SL              BEGIN STMT - IS IT LABELLED  27900013
MA36     ST    GR4,AUTCHN              SAVE ADDRESS OF ENTRY TYPE 1     27960013
         MVC   LOCK(2,DICT),1(SP)    AND LOCK IN ITS DICTIONARY BLOCK   28020013
         BC    BE,MA38                 GO IF PROC OR LABELLED BEGIN     28080013
         MVC   STMTNO(2,DICT),E1LBL(GR4)   NO - SET STMTNO FROM         28140013
         BC    B,MA37                    ENTRY TYPE 1                   28200013
         SPACE 1                                                        28260013
MA38     ST    GR0,PAR1(0,DICT)            YES, OR ENTRY STMT -         28320013
         MVC   PAR1+2(2,DICT),E1LBL(GR4) GET DICT ENTRY FOR STMT LABEL  28380013
         BALR  LINKR,GR6                                                28440013
         L     GR4,PAR1(0,DICT)                                         28500013
         BC    B,MA34                  AND GO TO SET STMTNO FROM THIS.  28560013
         SPACE 2                                                        28620013
MATST4   CLI   FOUND,EOB               IS BYTE FOUND EOB                28680013
         BC    BNE,MATST5                                               28740013
         BAL   LINKR,MOVE              YES - CALL 'MOVE' ROUTINE        28800013
         L     SP,INBLOK               GET NEXT BLOCK                   28860013
         ST    SP,PAR1(0,DICT)       IN CHAIN,                          28920013
         LA    SP,FREE               FREEING OLD BLOCK                  28980013
         ST    SP,PAR2(0,DICT)                                          29040013
         L     GRX,ZCHNOF(0,CTRL)                                       29100013
         BALR  LINKR,GRX                                                29160013
         L     SP,PAR1(0,DICT)                                          29220013
         ST    SP,INBLOK                                                29280013
         L     SP,PAR2(0,DICT)                                          29340013
         LR    P2,SP                                                    29400013
         BCT   SP,MASCAN                                                29460013
         SPACE 2                                                        29520013
MATST5   CLI   FOUND,EOP               IS BYTE FOUND EOP                29580013
         BC    BNE,MASCAN              NO - CONTINUE SCAN               29640013
         TM    EOPSW,X'FF'             IS THIS FIRST EOP                29700013
         BC    BNZ,MA2EOP                                               29760013
         AR    SP,ONE                  YES - INCLUDE EOP IN TEXT MOVED  29820013
MA2EOP   BAL   LINKR,MOVE              MOVE OUT TEXT                    29880013
         SPACE 1                                                        29940013
         ST    OP,PAR2(0,DICT)         GET SYMBOLIC TEXT REFERENCE      30000013
         L     GR4,OUBLOK            OF OUTPUT POINTER                  30060013
         ST    GR4,PAR1(0,DICT)                                         30120013
         L     GRX,ZTXROF(0,CTRL)                                       30180013
         BALR  LINKR,GRX                                                30240013
         L     GR4,PAR1(0,DICT)                                         30300013
         TM    EOPSW,X'FF'                                              30360013
         BC    BNZ,MAFIN                                                30420013
         ST    GR4,SECFIL(0,DICT)      FIRST EOP - STORE REFCE TO       30480013
         MVI   EOPSW,X'FF'           SECOND FILE, TIRN ON EOPSW, AND    30540013
         BCT   SP,MASCAN             CONTINUE SCAN                      30600013
         SPACE 5                                                        30660013
MAFIN    ST    GR4,LASTXT(0,DICT)      SECOND EOP - STORE REFCE TO      30720013
         MVI   0(OP),EOP             LAST TEXT BYTE                     30780013
         SPACE 1                                                        30840013
         ST    ONE,PAR1(0,DICT)        RELEASE SCRATCH CORE             30900013
         L     GRX,ZURCOF(0,CTRL)                                       30960013
         BALR  LINKR,GRX                                                31020013
         STH   GR0,LOCK(DICT)          UNLOCK DICTIONARY BLOCK          31080013
         L     LINKR,LOWPSW            RESTORE PROGRAM MASK             31140013
         SPM   LINKR                                                    31200013
         SPACE 1                                                        31260013
         L     GR4,INBLOK              FREE LAST INPUT TEXT BLOCK       31320013
         ST    GR4,PAR1(0,DICT)                                         31380013
         LA    GR4,FREE                                                 31440013
         ST    GR4,PAR2(0,DICT)                                         31500013
         L     GR6,ZALTOF(0,CTRL)                                       31560013
         BALR  LINKR,GR6                                                31620013
         SPACE 1                                                        31680013
         L     GR4,OUBLOK              MARK LAST OUTPUT BLOCK           31740013
         ST    GR4,PAR1(0,DICT)      'NOT WANTED'                       31800013
         LA    GR4,NWNT                                                 31860013
         ST    GR4,PAR2(0,DICT)                                         31920013
         BALR  LINKR,GR6                                                31980013
         SPACE 1                                                        32040013
         LA    GR4,EXIT                RELEASE CONTROL                  32100013
         ST    GR4,PAR1(0,DICT)                                         32160013
         ST    GR0,PAR2(0,DICT)                                         32220013
         L     GR4,RLSCTL(0,CTRL)                                       32280013
         BCR   B,GR4                                                    32340013
         SPACE 1                                                        32400013
EXIT     DC    C'HPZZ'                 RELEASE LIST FOR HP              32460013
         EJECT                                                          32520013
*              ERROR CONDITION ROUTINES - ERZERO & ERROR                32580013
*                                                                       32640013
*              FUNCTION - THESE ROUTINES ARE CALLED ONLY IF AN ERROR IS 32700013
*        FOUND.  ERZERO CREATES A CONSTANT INTEGER 0, TO BE USED IN AN  32760013
*        ATTEMPT TO PATCH AN ERROR (E.G. TO SUBSTITUTE FOR AN INVALID   32820013
*        SUBSCRIPT).  ERROR CALLS THE CONTROL PHASE TO RECORD AN ERROR  32880013
*        MESSAGE.                                                       32940013
*                                                                       33000013
*              ENTRY POINTS (1) ERZERO - TO CREATE A ZERO CONSTANT, IF  33060013
*        THIS HAS NOT BEEN DONE ALREADY.                                33120013
*                           (2) ERROR1 - TO RECORD AN ERROR MESSAGE     33180013
*        REFERRING TO THE BASE ARRAY USED IN THE DEFINING 'DECLARE'     33240013
*        STATEMENT.                                                     33300013
*                           (3) ERROR - TO RECORD AN ERROR MESSAGE      33360013
*        REFERRING TO THE DEFINED ARRAY.                                33420013
*                                                                       33480013
*              EXTERNAL ROUTINES - ZDICRF (CONTROL PHASE) MAKES         33540013
*        DICTIONARY ENTRY.                                              33600013
*                                  ZDRFAB (CONTROL PHASE) CONVERTS      33660013
*        DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.                      33720013
*                                  ZUERR (CONTROL PHASE) MAKES          33780013
*        DICTIONARY ENTRY FOR ERROR MESSAGE.                            33840013
*                                                                       33900013
*              EXIT - NORMAL - VIA LINKR                                33960013
*                                                                       34020013
*              EXIT - ERROR - NONE.                                     34080013
*                                                                       34140013
*              NOTE - CALLING SEQUENCE FOR ERROR AND ERROR1 IS -        34200013
*        BAL   LINKR,ERROR/1                                            34260013
*        DC    X'4-BYTE PARAMETER'                                      34320013
         SPACE 2                                                        34380013
ERZERO   CH    GR0,ERRDR               HAS DICT ENTRY BEEN MADE         34440013
         BCR   BNE,LINKR               YES - RETURN                     34500013
         SPACE 1                                                        34560013
         ST    LINKR,RETURN            NO - SAVE RETURN ADDRESS         34620013
         MVC   ZERO+CHN(2),ZCONCH(DICT)                                 34680013
         MVC   ZERO+CONNO(2),STMTNO(DICT)                               34710015
         LA    GRX,ZERO                MAKE DICTIONARY ENTRY            34740013
         ST    GRX,PAR1(DICT)                                           34800013
         LA    GRX,ZEROLN                                               34860013
         ST    GRX,PAR2(DICT)                                           34920013
         L     GRX,ZDRFOF(CTRL)                                         34980013
         BALR  LINKR,GRX                                                35040013
         SPACE 1                                                        35100013
         LH    GRX,PAR1+2(DICT)        STORE REFERENCE                  35160013
         STH   GRX,ZCONCH(DICT)                                         35220013
         AR    GRX,ONE               SETTING 'NOT TEMP' BIT             35280013
         STH   GRX,ERRDR                                                35340013
         L     LINKR,RETURN            RETURN                           35400013
         BCR   B,LINKR                                                  35460013
         SPACE 5                                                        35520013
ERROR1   STM   GR3,GR5,R345ST                                           35580013
         OI    GE,ER1ON                SET ERROR1-SWITCH                35640013
         LA    GR5,ERTAB               SET POINTER TO ERROR-TABLE       35700013
         CH    GR0,ERDRNO              ARE THERE ANY ENTRIES IN TABLE   35760013
         BC    BE,ERROR2               - GO IF NOT                      35820013
         LH    GR3,ERDRNO              LOAD NUMBER OF ENTRIES           35880013
         CH    GR3,LENGTH                                               35940013
         BC    BE,ERRAT                GO IF TABLE IS FULL              36000013
ERRO     LH    GR4,0(GR5)              LOAD NEXT ENTRY                  36060013
         CH    GR4,DICREF(STACK)                                        36120013
         BC    BE,ERRASS               GO IF THIS ENTRY ALREADY PRESENT 36180013
         LA    GR5,2(GR5)              REPEAT FOR NEXT ENTRY            36240013
         BCT   GR3,ERRO                                                 36300013
ERROR2   MVC   0(2,GR5),DICREF(STACK)  ENTER DICREF IN TABLE            36360013
         LH    GR3,ERDRNO              ADD ONE TO NUMBER OF ENTRIES     36420013
         AR    GR3,ONE                                                  36480013
         STH   GR3,ERDRNO                                               36540013
ERRAT    LH    GR3,STMTNO(DICT)        SAVE CURRENT STATEMENT NUMBER    36600013
         STH   GR3,ERSTMT                                               36660013
         ST    LINKR,BOOBOO                                             36720013
         LH    GRX,DICREF(STACK)       GET DICTIONARY ENTRY FOR         36780013
         STH   GRX,PAR1+2(DICT)      ERRONEOUS ITEM                     36840013
         L     GRX,ZDRAOF(CTRL)                                         36900013
         BALR  LINKR,GRX                                                36960013
         L     GRX,PAR1(DICT)                                           37020013
         MVC   STMTNO(2,DICT),DCL(GRX) SLOT STATEMENT NUMBER OF DECLARE 37080013
         L     LINKR,BOOBOO          STATEMENT INTO SLOT FOR ERR-EDITOR 37140013
         SPACE 2                                                        37200013
ERROR    MVC   PAR6(4,DICT),0(LINKR)   SET UP ID AND CODE BYTE          37260013
         ST    GR0,PAR7(0,DICT)                                         37320013
         MVC   PAR7+2(2,DICT),DICREF(STACK)   SET UP DICT REFCE         37380013
         ST    LINKR,BOOBOO            SAVE RETURN ADDRESS              37440013
         L     GRX,ZUERR(0,CTRL)       CALL ZUERR                       37500013
         BALR  LINKR,GRX                                                37560013
         L     LINKR,BOOBOO                                             37620013
         LA    LINKR,4(LINKR)          SET RETURN ADDRESS TO BYPASS     37680013
         TM    GE,ER1ON              PARAMETER                          37740013
         BCR   BZ,LINKR                RETURN UNLESS ERROR1-SWITCH SET  37800013
         SPACE 2                                                        37860013
ERRAS    LH    GR3,ERSTMT              RESTORE STATEMENT NUMBER         37920013
         STH   GR3,STMTNO(DICT)                                         37980013
         NI    GE,ER1OFF               RESET SWITCH                     38040013
         LM    GR3,GR5,R345ST                                           38100013
         BCR   B,LINKR                                                  38160013
         SPACE                                                          38220013
ERRASS   LA    LINKR,4(LINKR)                                           38280013
         BC    B,ERRAS                                                  38340013
         EJECT                                                          38400013
*              DEFSUB ROUTINE - PROCESS ISUB-DEFINED SUBSCRIPT LISTS    38460013
*                                                                       38520013
*              OPERATION (1) CHECKS THE DIMENSIONALITIES OF THE DEFINED 38580013
*        AND BASE ARRAYS.  (LET THESE = D AND B RESPECTIVELY).          38640013
*                        (2) SCANS THE SECOND SUBSCRIPT LIST, AND       38700013
*        OUTPUTS 'BUY' AND ASSIGNMENT STATEMENTS WHERE THE SUBSCRIPTS   38760013
*        ARE NOT INTEGER VARIABLES OR CONSTANTS.                        38820013
*                        (3) OUTPUTS THE REFERENCE OF THE BASE ARRAY.   38880013
*                        (4) FOLLOWS THIS WITH THE FIRST SUBSCRIPT LIST 38940013
*        FROM THE INPUT TEXT, REPLACING ISUBS BY THEIR CORRESPONDING    39000013
*        DICTIONARY REFERENCE (TEMPORARY OR INTEGER SUBSCRIPT).         39060013
*                        (5) OUTPUTS TEXT TO SELL ALL TEMPORARIES.      39120013
*                                                                       39180013
*              ENTRY POINTS (1) DEFSUB - FROM MASTER ROUTINE            39240013
*                           (2) DERCUR - FROM SUMOVE ROUTINE, WHEN AN   39300013
*        ISUB-DEFINED ITEM IS FOUND WITHIN A SUBSCRIPT-LIST OF ANOTHER  39360013
*        SUCH ITEM.                                                     39420013
*                                                                       39480013
*              EXTERNAL ROUTINES - ERROR (THIS MODULE) RECORDS ERROR    39540013
*        MESSAGE.                                                       39600013
*                                  ZABORT (CONTROL PHASE) TERMINATES    39660013
*        COMPILATION.                                                   39720013
*                                  ZDRFAB (CONTROL PHASE) CONVERTS      39780013
*        DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.                      39840013
*                                  MOVE (THIS MODULE) MOVES TEXT FROM   39900013
*        SOURCE TO OUTPUT.                                              39960013
*                                  SULIST (THIS MODULE) SKIPS OVER A    40020013
*        PARENTHESISED LIST.                                            40080013
*                                  ZTXTRF (CONTROL PHASE) CONVERTS      40140013
*        ADDRESS TO TEXT REFERENCE.                                     40200013
*                                  GENTST (THIS MODULE) TESTS IF ROOM   40260013
*        LEFT IN OUTPUT TEXT BLOCK.                                     40320013
*                                  ZDICRF (CONTROL PHASE) MAKES         40380013
*        DICTIONARY ENTRY.                                              40440013
*                                  ERZERO (THIS MODULE) SUPPLIES A ZERO 40500013
*        CONSTANT.                                                      40560013
*                                  SUMOVE (THIS MODULE) SCANS A         40620013
*        SUBSCRIPT BEFORE IT IS MOVED TO OUTPUT.                        40680013
*                                  ZTXTAB (CONTROL PHASE) CONVERTS TEXT 40740013
*        REFERENCE TO ABSOLUTE ADDRESS.                                 40800013
*                                  SUCBMV (THIS MODULE)SCANS A NESTED   40860013
*        STATEMENT BEFORE IT IS MOVED TO OUTPUT.                        40920013
*                                  ERROR1 (THIS MODULE) RECORDS ERROR   40980013
*        MESSAGE CONCERNING THE BASE ARRAY.                             41040013
*                                  SUSKIP (THIS MODULE) SKIPS TO END OF 41100013
*        A SUBSCRIPT.                                                   41160013
*                                  ZCHAIN (CONTROL PHASE) GETS NEXT     41220013
*        SOURCE TEXT BLOCK IN THE CHAIN.                                41280013
*                                                                       41340013
*              EXITS - NORMAL (1) TO SUSCAN IF ENTRY WAS MADE FROM      41400013
*        SUMOVE ROUTINE.                                                41460013
*                             (2) TO MASCAN IF ENTRY WAS MADE FROM      41520013
*        MASTER ROUTINE.                                                41580013
*                                                                       41640013
*              EXIT - ERROR - VIA ZABORT (CONTROL PHASE) IF A           41700013
*        DISASTROUS ERROR IS FOUND.                                     41760013
*                                                                       41820013
*              TABLES - A LIST IS KEPT IN THE TOP OF SCRATCH CORE OF    41880013
*        TEMPORARIES AND SUBSCRIPTS WHICH WILL BE USED TO REPLACE       41940013
*        ISUBS.  THIS CONTAINS D 2-BYTE REFERENCES (WHERE D IS THE      42000013
*        DIMENSIONALITY OF THE DEFINED ARRAY) CORRESPONDING TO          42060013
*        SUBSCRIPTS IN THE SECOND LIST OF THE INPUT REFERENCE.  IF A    42120013
*        REFERENCE IN THIS TABLE IS NOT A TEMPORARY (I.E. THE           42180013
*        CORRESPONDING SUBSCRIPT IS AN INTEGER), ITS LOWEST TWO BITS    42240013
*        WILL BE MADE NON-ZERO.  THE SLOT ENDSTC HOLDS THE ADDRESS OF   42300013
*        THIS TABLE.                                                    42360013
*                                                                       42420013
*              NOTES (1)REGISTER USAGE.                                 42480013
*              L1 - 'NUMBER OF BYTES' PARAMETER FOR GENTST              42540013
*              GR3 - POINTER TO ACCESS TABLE OF TEMPORARIES             42600013
*              GR4 - HOLDS CONSTANT '2' USED AS INCREMENT FOR TABLE OF  42660013
*                    TEMPORARIES                                        42720013
*              GR5 - POINTS TO END OF CURRENT SECTION IN TABLE OF       42780013
*                    TEMPORARIES                                        42840013
*              GR6 - HOLDS CURRENT ISUB-NUMBER WHEN PROCESSING FIRST    42900013
*                    SUBSCRIPT LIST                                     42960013
*                    (2) EOB-SWITCH.  AT THIS STAGE A SINGLE SOURCE     43020013
*        TEXT STATEMENT MAY SPAN TWO (OR MORE) TEXT BLOCKS, OWING TO    43080013
*        NESTED STATEMENTS INSERTED BY PREVIOUS PHASES (STRUCTURE AND   43140013
*        ARRAY ASSIGNMENT).  HENCE WHEN THIS ROUTINE IS ENTERED FROM    43200013
*        MASTER ROUTINE, A PRELIMINARY SCAN IS MADE OF THE SUBSCRIPT    43260013
*        LISTS TO SEE IF THEY SPAN A BLOCK.  IF SO, EOB-SWITCH IS SET   43320013
*        AND ALL TEXT ADDRESSES ARE STORED AS SYMBOLIC REFERENCES.      43380013
         SPACE 4                                                        43440013
*              DEFSUB IS ENTRY POINT FROM MASTER ROUTINE                43500013
         SPACE 1                                                        43560013
DEFSUB   MVI   TABLE+LP,LP             MODIFY TABLE TO INCLUDE (        43620013
         MVI   TABLE+RP,RP                                     )        43680013
         MVI   TABLE+CMA,CMA                                   ,        43740013
         MVI   TABLE+LCB,LCB                                   LCB      43800013
         MVI   TABLE+RCB,RCB                                   RCB      43860013
*              (FOR THE USE OF THE 'SUBMOVE' SUBROUTINE)                43920013
         BC    B,DEFINE                                                 43980013
         SPACE 2                                                        44040013
*              DERCUR IS ENTRY POINT FROM SUMOVE ROUTINE                44100013
         SPACE 1                                                        44160013
DERCUR   STC   LVL,LEVEL(STACK)        STORE PARAMETERS IN STACK        44220013
         STC   CBL,CBLVL(STACK)                                         44280013
         ST    GR5,LASTMP(STACK)                                        44340013
         LA    STACK,DUBLEN(STACK)     PUSH DOWN STACK                  44400013
         ST    STACK,TOPST             SAVE POSITION OF TOP OF STACK    44460013
         C     STACK,LIMIT             IS ALL SCRATCH CORE USED         44520013
         BC    BL,DESTOK                                                44580013
         SPACE                                                          44640013
         SPACE 1                                                        44700013
ERSTAK   BAL   LINKR,ERROR             YES - ERROR                      44760013
         DC    X'00038040'                                              44820013
ERTERM   L     GRX,ZABORT(CTRL)        TERMINATE COMPILATION            44880013
         BCR   B,GRX                                                    44940013
         SPACE 1                                                        45000013
*              CHECK DIMENSIONALITY OF ARRAYS                           45060013
         SPACE                                                          45120013
DESTOK   SH    STACK,LENGTH                                             45180013
DEFINE   ST    SP,OPDRES(STACK)                                         45240013
         MVI   SW(STACK),0             INITIALIZE SWITCHES              45300013
         MVC   PAR1+2(2,DICT),1(SP)    GET ADDRESS OF OPERAND           45360013
         MVC   DICREF(2,STACK),1(SP)                                    45420013
         L     GR4,ZDRAOF(0,CTRL)    DICTIONARY REFERENCE               45480013
         BALR  LINKR,GR4                                                45540013
         L     P3,PAR1(0,DICT)                                          45600013
         TM    0(P3),DIM               IS OPERAND DIMENSIONED           45660013
         BC    BNZ,DEDEF               YES                              45720013
         SPACE                                                          45780013
ERDIMS   BAL   LINKR,ERROR             NO - ERROR                       45840013
         DC    X'00038154'                                              45900013
DIMMO    CLI   4(SP),LP                DOES SUBSCRIPT LIST FOLLOW       45960013
         BC    BNE,ERDRET                                               46020013
         LA    SP,3(SP)                YES - MOVE OUT DICTIONARY        46080013
         BAL   LINKR,MOVE            REFCE,                             46140013
         LA    SP,2(SP)              AND SKIP                           46200013
         BAL   LINKR,SULIST          SUBSCRIPT LIST                     46260013
         CLI   2(SP),LP                IS THERE  A 2ND  SUBSCRIPT LIST  46320013
         BC    BNE,DERETN                                               46380013
         CLI   1(SP),SM                                                 46440013
         BC    BNE,DERETN                                               46500013
         LA    SP,3(SP)                YES - SKIP IT                    46560013
         BAL   LINKR,SULIST                                             46620013
         BC    B,DERETN                                                 46680013
ERDRET   LA    SP,2(SP)                RETURN TO LEAVE DEFSUB           46740013
         BC    B,DERETN                                                 46800013
*  *  *  END  OF  ERROR ROUTINE                                         46860013
         SPACE 1                                                        46920013
DEDEF    DS    0H                                                       46950016
         LR    LINKR,P3                SAVE POINTER TEMPORARILY.        46980016
         TM    0(P3),X'0F'             DATA ITEM ?                      47010016
         BC    BNO,DE2TST              NO. (LABEL, TASK, OR EVENT)      47040016
         LA    P3,DATINF(0,P3)         YES. BUMP POINTER BY DIFFRNCE.   47070016
DE2TST   DS    0H                                                       47100016
         TM    VBYTE(LINKR),X'80'      SECOND OFFSET SLOT ?             47130016
         BC    BZ,DEDIM                NO.                              47160016
         LA    P3,OFFSET(0,P3)         YES. BUMP SOME MORE.             47190016
DEDIM    BC    NOP,DEBASE              (NO-OP FIRST TIME)               47220016
         MVC   DIMS(1,STACK),DIMOFF(P3)  MOVE THE DIMENSION COUNT       47250016
*                                    INTO THE STACK.                    47280016
         TM    VBYTE(LINKR),X'20'      STRUCTURE MEMBER ?               47310016
         BC    BZ,EXTST                NO.                              47340016
         LA    P3,STRUCT(0,P3)         YES. BUMP P3.                    47370016
*                                                                       47400016
*              NOTE THAT ISUB DEFINING IS INCOMPATIBLE WITH             47430016
*              POSITION, LIKE, OR INITIAL.                              47460016
*                                                                       47490016
EXTST    DS    0H                                                       47520016
         TM    VBYTE(LINKR),X'04'      EXTERNAL ?                       47550016
         BC    BZ,DEBAS                NO.                              47580016
         LA    P3,EXTRNL(0,P3)         YES. BUMP P3.                    47610016
DEBAS    DS    0H                                                       47640016
         MVC   BASDIC(2,STACK),BASOFF(P3)  STACK THE BASE DIC. REF.     47670016
         SPACE 2                                                        47700016
         MVC   PAR1+2(2,DICT),BASDIC(STACK)                             47730016
         BALR  LINKR,GR4               GET THE BASE ARRAY ENTRY,        47760016
         L     P3,PAR1(DICT)         POINTED AT BY P3.                  47790016
         TM    0(P3),DIM               DIMENSIONED ?                    47820016
         BC    BZ,ERDIMS               ERROR IF NOT.                    47850016
         SPACE 2                                                        47880016
         OI    DEDIM+1,X'F0'           SET SWITCH FOR RETURN, THEN      47910016
         BC    B,DEDEF               BRANCH TO INCREMENT POINTER.       47940016
DEBASE   NI    DEDIM+1,X'0F'           RESTORE THE NO-OP, AND SET UP    47970016
         MVC   DIMBAS(1,STACK),DIMOFF(P3)  THE BASE DIMENSION COUNT.    48000016
         SPACE 1                                                        48360013
         CLI   DIMS(STACK),0           CHECK THAT NEITHER DEFINED       48420013
         BC    BE,ERDIMS             NOR BASE ARRAYS HAVE ZERO          48480013
         CLI   DIMBAS(STACK),0       DIMENSIONS                         48540013
         BC    BE,ERDIMS                                                48600013
         L     SP,INBLOK               SET SOURCE OPERAND BLOCK REFCE   48620015
         ST    SP,OPBLOK             = REFCE OF INPUT BLOCK             48640015
         SPACE 1                                                        48660013
*              PRELIMINARY SCAN OF SUBSCRIPT LISTS                      48720013
         SPACE                                                          48780013
         L     SP,OPDRES(STACK)                                         48840013
         BAL   LINKR,MOVE              MOVE OUT TEXT BEFORE ISUB REFCE  48900013
         OI    SW(STACK),T1ON          SET T1-SWITCH                    48960013
         LA    SP,5(SP)                SKIP OVER FIRST SUBSCRIPT LIST   49020013
         BAL   LINKR,SULIST                                             49080013
         NI    SW(STACK),T1OFF                                          49140013
         SPACE 2                                                        49200013
DESMQ    CLI   1(SP),SM                DOES IT END WITH SUBSCRIPT       49260013
         BC    BE,DELST2             MARKER                             49320013
         SPACE                                                          49380013
         BAL   LINKR,ERROR             NO - ERROR                       49440013
         DC    X'00038250'                                              49500013
         BC    B,ERTERM                TERMINATE COMPILATION            49560013
         SPACE 2                                                        49620013
DELST2   LA    SP,2(0,SP)              SET AND SAVE POINTER TO          49680013
         ST    SP,SPST               SECOND SUBSCRIPT LIST              49740013
         TM    GE,EOBON                                                 49800013
         BC    BNZ,DESYMO              GO IF EOB-SWITCH SET             49860013
         SPACE 1                                                        49920013
         C     STACK,ORIGIN            IS THIS A RECURSIVE CALL         49980013
         BC    BNE,DELOPD              - GO IF SO                       50040013
         OI    SW(STACK),L1ON          SET L1-SWITCH FOR SEEKING EOB'S  50100013
         AR    SP,ONE                  SCAN SECOND SUBSCRIPT-           50160013
         BAL   LINKR,SULIST          LIST (TO CHECK FOR EOB'S)          50220013
         SPACE 4                                                        50280013
         TM    GE,EOBON                                                 50340013
         BC    BZ,DELOPD               GO IF EOB-SWITCH NOT SET         50400013
         SPACE                                                          50460013
DESYMO   L     SP,OPBLOK                                                50520015
         ST    SP,PAR1(DICT)           CONVERT OPDRES TO SYMBOLIC       50580013
         L     SP,OPDRES(STACK)      TEXT REFERENCE                     50640013
         ST    SP,PAR2(DICT)                                            50700013
         L     GRX,ZTXROF(CTRL)                                         50760013
         BALR  LINKR,GRX                                                50820013
         L     SP,PAR1(DICT)                                            50880013
         ST    SP,OPDRES(STACK)                                         50940013
         L     SP,OPBLOK               ARE WE STILL IN THE OPERAND      50948015
         C     SP,INBLOK             SOURCE BLOCK                       50956015
         BC    BE,DELOPD               - GO IF SO                       50964015
         MVI   PAR2+3(DICT),NWNT       MARK OPERAND SOURCE BLOCK 'NOT   50972015
         L     GRX,ZALTOF(CTRL)      WANTED'                            50980015
         BALR  LINKR,GRX                                                50988015
         SPACE 2                                                        51000013
*              PUSH DOWN STACK FOR TEMPS                                51060013
         SPACE                                                          51120013
DELOPD   LR    GRQ,GR0                 BACKSPACE ENDSTC POINTER         51180013
         IC    GRQ,DIMS(STACK)       TO POINT TO BEGINNING              51240013
         AR    GRQ,GRQ                                                  51300013
         L     GR3,ENDSTC            OF TEMP-TABLE                      51360013
         LA    GR4,2                                                    51420013
         LR    GR5,GR3                 GR5 POINTS TO END OF NEW TEMP-   51480013
         SR    GR5,ONE               TABLE                              51540013
         SR    GR3,GRQ                                                  51600013
         C     GR3,TOPST               ERROR IF ENDSTC POINTER GOES     51660013
         BC    BL,ERSTAK             BELOW TOP OF PUSH-DOWN STACK       51720013
         ST    GR3,ENDSTC                                               51780013
         SPACE 1                                                        51840013
         LR    L1,ONE                  OUTPUT LEFT CURLY BRACKET        51900013
         BAL   LINKR,GENTST                                             51960013
         MVI   0(OP),LCB                                                52020013
         AR    OP,ONE                                                   52080013
         L     SP,SPST                 RESTORE SP                       52140013
         SPACE 4                                                        52200013
*              PROCESS SECOND SUBSCRIPT LIST                            52260013
         SPACE                                                          52320013
         NI    SW(STACK),L1OFF         RESET L1-SWITCH                  52380013
         SPACE 4                                                        52440013
DETEMQ   CLI   1(SP),AST               IS IT ASTERISK                   52500013
         BC    BNE,DESUB2              NO - PUT OUT SECOND SUBSCRIPT    52560013
         SPACE                                                          52620013
         BAL   LINKR,ERROR             YES - ERROR                      52680013
         DC    X'00038458'                                              52740013
         BAL   LINKR,ERZERO                                             52800013
         MVC   0(2,GR3),ERRDR          SLOT IN ZERO                     52860013
         LA    LINKR,DEGBD1            SKIP SUBSCRIPT AND CONTINUE      52920013
         BC    B,SUSKIP                                                 52980013
         SPACE                                                          53040013
DESUB2   CLI   1(SP),OPD               IS ITEM A DICTIONARY REFERENCE,  53100013
         BC    BNE,DEEND2                                               53160013
         CLI   4(SP),CMA             FOLLOWED BY , OR )                 53220013
         BC    BE,DENGUB                                                53280013
         CLI   4(SP),RP                                                 53340013
         BC    BNE,DEEND2              GO TO DEEND2 IF NOT              53400013
         SPACE                                                          53460013
DENGUB   MVC   PAR1+2(2,DICT),2(SP)    YES - EXAMINE TYPE OF DICT ENTRY 53520013
         SPACE 2                                                        53580013
*              TEST IF ASSIGNMENT TO TEMPORARY NEEDED.  EXIT TO DEGUB   53640013
*        IF SO, AND TO DEGUBD IF NOT.                                   53700013
         SPACE                                                          53760013
DENGB    LH    GRX,PAR1+2(DICT)                                         53820013
         STH   GRX,DRN14                                                53880013
         L     GRX,ZDRAOF(CTRL)                                         53940013
         BALR  LINKR,GRX                                                54000013
         L     GRX,PAR1(DICT)                                           54060013
         CLI   0(GRX),VARB             IS IT SCALAR VARIABLE, TEMP,     54120013
         BC    BE,DEVARB             OR FORMAL PARAMETER                54180013
         CLI   0(GRX),TMPFP                                             54240013
         BC    BE,DEVARB               - GO IF SO                       54300013
         CLI   0(GRX),CONST            IS IT CONSTANT                   54360013
         BC    B,DEGUB                 ( WAS BNE )                      54420015
         SPACE 2                                                        54480013
         CLI   CONTYP(GRX),X'01'       HAS CONSTANT BEEN USED           54540013
         BC    BE,DEK01                - GO IF NOT                      54600013
         MVC   DED1(3),CONDA1(GRX)     SAVE 'APPARENT DED'              54660013
DEKD2Q   TM    CONDA2(GRX),CADNF       IS IT FIXED-POINT WITH           54720013
         BC    BZ,DEKCHN             NON-POSITIVE SCALE FACTOR          54780013
         TM    CONDA2(GRX),FXFL                                         54840013
         BC    BNZ,DEKCHN              - GO IF NOT                      54900013
         CLI   CONSF2(GRX),X'80'                                        54960013
         BC    BLE,DEKUSE              - GO IF SO                       55020013
         SPACE 1                                                        55080013
DEKCHN   MVC   PAR1+2(2,DICT),CHN(GRX) GO TO NEXT ITEM IN CONSTANTS     55140013
         LH    GRX,DRN14             CHAIN                              55200013
         STH   GRX,DR14                                                 55260013
         LH    GRX,PAR1+2(DICT)                                         55320013
         STH   GRX,DRN14                                                55380013
         L     GRX,ZDRAOF(CTRL)                                         55440013
         BALR  LINKR,GRX                                                55500013
         L     GRX,PAR1(DICT)                                           55560013
         CLC   1(2,GRX),CONLEN         IS IT FOR THE SAME CONSTANT      55620013
         BC    BE,DEKD2Q               - GO IF SO TO EXAMINE DED        55680013
         SPACE 1                                                        55740013
         LA    GRX,CONSTE              MAKE DICT ENTRY FOR CONSTANT     55800013
         ST    GRX,PAR1(DICT)        WITH CORRECT DED                   55860013
         LA    GRX,CONLN                                                55920013
         ST    GRX,PAR2(DICT)                                           55980013
         MVC   CONSTE+CONNO(2),STMTNO(DICT)                             56010015
         L     GRX,ZDRFOF(CTRL)                                         56040013
         BALR  LINKR,GRX                                                56100013
         LH    GRX,PAR1+2(DICT)                                         56160013
         STH   GRX,0(GR3)              CONNECT UP WITH PREVIOUS         56220013
         LH    GRX,DR14              CONSTANT IN THE CHAIN              56280013
         STH   GRX,PAR1+2(DICT)                                         56340013
         L     GRX,ZDRAOF(CTRL)                                         56400013
         BALR  LINKR,GRX                                                56460013
         L     GRX,PAR1(DICT)                                           56520013
         MVC   CHN(2,GRX),0(GR3)                                        56580013
DEKVAR   OI    1(GR3),1              TEMP-TABLE AND SET 'NON-TEMP' BIT  56640013
         BC    B,DEGUBD                                                 56700013
         SPACE 1                                                        56760013
DEK01    MVC   CONTYP(4,GRX),DED2      INSERT 2ND DED AND SET TYPE BYTE 56820013
DEKUSE   LH    GRX,DRN14               SLOT THIS DICT REFCE INTO THE    56880013
         AR    GRX,ONE               TEMP-TABLE                         56940013
         STH   GRX,0(GR3)                                               57000013
         BC    B,DEGUBD                                                 57060013
         SPACE 2                                                        57120013
DEVARB   CLC   VARDAT(3,GRX),TEMPDE+VARDAT                              57220015
         BC    BE,DEKUSE               GO IF ITEM IS FIXED BIN (15,0)   57320015
         SPACE                                                          57540013
DEGUB    EQU   *                                                        57600013
         SPACE 2                                                        57660013
*              DEEND2 - CREATE TEMP                                     57720013
         SPACE                                                          57780013
DEEND2   L     GRX,AUTCHN              SLOT AUTOMATIC CHAIN INTO DICT   57840013
         MVC   TEMPDE+CHN(2),E1AUTO(GRX)  ENTRY                         57900013
         MVC   TEMPDE+TLC(2),E1LC(GRX)                                  57960013
         SPACE 1                                                        58020013
         LA    GRX,TEMPDE              MAKE DICT ENTRY FOR TEMP         58080013
         ST    GRX,PAR1(DICT)                                           58140013
         LA    GRX,TEMPLE                                               58200013
         ST    GRX,PAR2(DICT)                                           58260013
         L     GRX,ZDRFOF(CTRL)                                         58320013
         BALR  LINKR,GRX                                                58380013
         SPACE 1                                                        58440013
         L     GRX,AUTCHN              PUT DICT REFCE INTO AUTOMATIC    58500013
         MVC   E1AUTO(2,GRX),PAR1+2(DICT)  CHAIN ANCHOR IN ENTRY TYPE 1 58560013
         LH    GRX,PAR1+2(DICT)                                         58620013
         STH   GRX,0(GR3)              SLOT TEMP INTO TABLE AND INTO    58680013
         STH   GRX,TEMP1             TEXT TO BE OUTPUT                  58740013
         MVC   TEMP2(2),TEMP1                                           58800013
DEOBUY   LA    L1,10                   OUTPUT 'BUY TEMP'                58860013
         BAL   LINKR,GENTST          AND 'TEMP EQUALS' STATEMENTS       58920013
         MVC   0(10,OP),BUYTEM                                          58980013
         LA    OP,5(OP)                                                 59040013
         ST    OP,STSTAT                                                59100013
         LA    OP,5(OP)                                                 59160013
         SPACE                                                          59220013
         LA    P2,1(SP)                                                 59280013
         BAL   LINKR,SUMOVE            MOVE OUT SUBSCRIPT               59340013
         AR    SP,ONE                                                   59400013
         BAL   LINKR,MOVE                                               59460013
         SR    OP,ONE                  OUTPUT SEMI-COLON OVER CLOSING   59520013
         MVI   0(OP),SCLN            DELIMITER                          59580013
         AR    OP,ONE                                                   59640013
         BCT   SP,DEGBD1                                                59700013
         SPACE 2                                                        59760013
DEGUBD   EQU   *                                                        59820013
         SPACE                                                          59880013
*              TEST FOR END OF SECOND SUBSCRIPT LIST                    59940013
         SPACE 4                                                        60000013
         LA    SP,4(SP)                                                 60060013
DEGBD1   CLI   0(SP),CMA               IS DELIMITER A ,                 60120013
         BC    BNZ,DERPON              NO - )                           60180013
         BXLE  GR3,GR4,DETEMQ                                           60240013
DERSUB   BAL   LINKR,ERROR                                              60300013
         DC    X'00038658'                                              60360013
         CLI   0(SP),CMA               TOO MANY SUBSCRIPTS OR TOO FEW   60420013
         BC    BE,ERMANY               - GO IF TOO MANY                 60480013
         BAL   LINKR,ERZERO            FILL IN REMAINING SLOTS WITH     60540013
ERMVC    MVC   0(2,GR3),ERRDR        ZEROS                              60600013
         BXLE  GR3,GR4,ERMVC                                            60660013
         BC    B,DEDONE                                                 60720013
ERMANY   LA    LINKR,DEDONE            SKIP TO END OF SUBSCRIPT-LIST    60780013
         BC    B,SULIST              AND CONTINUE                       60840013
DERPON   BXLE  GR3,GR4,DERSUB                                           60900013
         SPACE 2                                                        60900815
*              IF SUBSCRIPTRANGE IS ENABLED, OUTPUT CONDITIONAL         60901615
*        'SIGNAL' STATEMENTS                                            60902415
         SPACE                                                          60903215
DEDONE   TM    POB,SUBRG                                                60904015
         BC    BZ,DELS21                                                60904815
         L     GR3,ENDSTC              RESET GR3 TO FIRST SUBSCRIPT     60905615
         SPACE 2                                                        60906415
         L     L1,ZDRAOF(CTRL)         YES - SEARCH AUTOMATIC CHAIN FOR 60907215
         L     GR6,AUTCHN            ITS DICTIONARY ENTRY               60908015
         MVC   PAR1+2(2,DICT),E1AUTO(GR6)                               60908815
DEAUTO   CH    GR0,PAR1+2(DICT)        IS IT END OF CHAIN               60909615
         BC    BE,DEMAKE               YES                              60910415
         SPACE                                                          60911215
         LH    GR4,PAR1+2(DICT)        NO - SAVE REFCE TO BE EXAMINED   60912015
         BALR  LINKR,L1                GET ITS DICTIONARY ENTRY         60912815
         L     GR6,PAR1(DICT)                                           60913615
         CLI   0(GR6),DON              IS IT AN ON CONDITION            60914415
         BC    BNE,DENON                                                60915215
         CLI   ONID(GR6),SBRNGE        YES - IS IT SUBRG                60916015
         BC    BNE,DEORCH                                               60916815
         BC    B,DEMADE                YES                              60917615
         SPACE 1                                                        60918415
DENON    CLI   0(GR6),DE3              CHAIN TO NEXT ITEM - ENTRY TYPES 60919215
         BC    BE,DESPCH             3, 4 AND 5 ARE SPECIAL CASES       60920015
         CLI   0(GR6),DE4                                               60920815
         BC    BE,DESPCH                                                60921615
         CLI   0(GR6),DE5                                               60922415
         BC    BNE,DEORCH              - GO IF ORDINARY CHAINING        60923215
DESPCH   MVC   PAR1+2(2,DICT),EAUT(GR6)                                 60924015
         BC    B,DEAUTO                                                 60924815
DEORCH   MVC   PAR1+2(2,DICT),CHN(GR6)                                  60925615
         BC    B,DEAUTO                                                 60926415
         SPACE 1                                                        60927215
DEMAKE   L     GRX,AUTCHN              MAKE DICTIONARY FOR SUBRG,       60928015
         MVC   SBRGDE+CHN(2),E1AUTO(GRX)  ADDED TO AUTO CHAIN           60928815
         MVC   SBRGDE+ONLC(2),E1LC(GRX)                                 60929615
         LA    GRX,SBRGDE                                               60930415
         ST    GRX,PAR1(DICT)                                           60931215
         LA    GRX,SBRGLE                                               60932015
         ST    GRX,PAR2(DICT)                                           60932815
         L     GRX,ZDRFOF(CTRL)                                         60933615
         BALR  LINKR,GRX                                                60934415
         L     GRX,AUTCHN              RE-ANCHOR AUTO CHAIN             60935215
         MVC   E1AUTO(2,GRX),PAR1+2(DICT)                               60936015
         LH    GR4,PAR1+2                                               60936815
         SPACE 2                                                        60937615
DEMADE   STH   GR4,DRSBRG              SET SUBRG REFCE INTO SKELETON    60938415
         MVC   DEF(2),DICREF(STACK)    SLOT IN DEFINED ARRAY REFCE      60939215
         LA    GR4,2                   RESET GR4                        60940015
         LA    L1,25                   LOAD LENGTH OF 'SIGNAL' STMT     60940815
         LR    GR6,ONE                 INITIALIZE DIMENSION NUMBER      60941615
         SPACE 1                                                        60942415
DENSBG   MVC   SUBSCR(2),0(GR3)        SET SUBSCRIPT REFCE IN SKELETON  60943215
         NI    SUBSCR+1,NOTMP          RESET 'NO TEMP' BITS             60944015
         STC   GR6,DIMNO               SLOT IN DIMENSION NUMBER,        60944815
         MVI   LTGT,LT               'LESS THAN', AND                   60945615
         MVI   LHBND,LOW             LOWER-BOUND TYPE ADV               60946415
         BAL   LINKR,GENTST            OUTPUT STATEMENT                 60947215
         MVC   0(25,OP),SIGNAL                                          60948015
         AR    OP,L1                                                    60948815
         ST    OP,STSTAT                                                60949615
         SPACE 1                                                        60950415
         MVI   LTGT,GT                 SLOT IN 'GREATER THAN' AND       60951215
         MVI   LHBND,HIGH            HIGHER-BOUND TYPE ADV              60952015
         BAL   LINKR,GENTST            OUTPUT STATEMENT                 60952815
         MVC   0(25,OP),SIGNAL                                          60953615
         AR    OP,L1                                                    60954415
         ST    OP,STSTAT                                                60955215
         AR    GR6,ONE                 BUMP DIMENSION NUMBER            60956015
         BXLE  GR3,GR4,DENSBG          GO TO DEAL WITH NEXT SUBSCRIPT   60956815
         SPACE                                                          60960013
*              CHANGE FROM SECOND SUBSCRIPT LIST TO FIRST               61020013
         SPACE                                                          61080013
DELS21   TM    GE,EOBON                                                 61140015
         BC    BZ,DEOBFB               GO IF EOB-SWITCH NOT SET         61200013
         SPACE 2                                                        61260013
         ST    SP,PAR2(DICT)           OBTAIN SYMBOLIC REFERENCE OF     61320013
         L     SP,INBLOK             SP AND SAVE IT AS END-OF-LIST      61380013
         ST    SP,PAR1(DICT)         LOCATION                           61440013
         L     GRX,ZTXROF(CTRL)                                         61500013
         BALR  LINKR,GRX                                                61560013
         L     SP,PAR1(DICT)                                            61620013
         ST    SP,END(STACK)                                            61680013
         SPACE                                                          61740013
         L     SP,OPDRES(STACK)        CONVERT SYMBOLIC REFERENCE OF    61800013
         LA    SP,0(SP)                                                 61860013
         ST    SP,PAR1(DICT)         OPERAND TO ABSOLUTE ADDRESS        61920013
         ST    SP,INBLOK               UPDATE INBLOK                    61950015
         L     GRX,ZTXAOF(CTRL)                                         61980013
         BALR  LINKR,GRX                                                62040013
         L     SP,PAR1(DICT)                                            62100013
         BC    B,DEOBNB                                                 62160013
         SPACE 2                                                        62220013
DEOBFB   ST    SP,END(STACK)           SAVE END-OF-LIST LOCATION        62280013
         L     SP,OPDRES(STACK)        RESET SP TO FIRST SUBSCRIPT-     62340013
DEOBNB   LA    SP,4(SP)              LIST                               62400013
         LR    P2,SP                                                    62460013
         LR    GR5,ONE                 INITIALIZE SUBSCRIPT COUNT       62520013
         SPACE                                                          62580013
         LA    L1,5                    OUTPUT RIGHT CURLY BRACKET,      62640013
         BAL   LINKR,GENTST          FOLLOWED BY REFERENCE OF BASE      62700013
         LH    GR4,BASDIC(STACK)                                        62760013
         STH   GR4,BASREF                                               62820013
         MVC   0(5,OP),BASE          ARRAY                              62880013
         AR    OP,L1                                                    62940013
         SPACE 2                                                        63000013
*              PROCESS FIRST SUBSCRIPT LIST                             63060013
         SPACE                                                          63120013
DENEXT   BAL   LINKR,SUMOVE            GO TO PROCESS NEXT SUBSCRIPT     63180013
         BAL   LINKR,MOVE            FROM FIRST LIST AND MOVE IT OUT    63240013
         CLI   0(SP),RP                                                 63300013
         BC    BE,DERP2                GO IF DELIMITER IS )             63360013
         EX    GR5,CDIMBS              ERROR IF SUBSCRIPT COUNT = BASE  63420013
         BC    BE,DERSB2             DIMENSIONALITY                     63480013
         BXH   GR5,ONE,DENEXT          BUMP SUBSCRIPT COUNT AND         63540013
*                                      GO TO EXAMINE NEXT SUBSCRIPT     63600013
         SPACE 2                                                        63660013
DERSB2   BAL   LINKR,ERROR1            'WRONG NUMBER OF SUBSCRIPTS'     63720013
         DC    X'00038658'             902 DECIMAL                      63780013
         CLI   0(SP),RP                                                 63840013
         BC    BE,ERFEW                GO IF TOO FEW SUBSCRIPTS         63900013
         BAL   LINKR,SULIST            TOO MANY - SKIP REST OF LIST     63960013
         BC    B,DEORP                                                  64020013
         SPACE                                                          64080013
ERFEW    BAL   LINKR,ERZERO            OBTAIN ZERO CONSTANT             64140013
         NI    ERRDR+1,NOTMP           RESET 'NO TEMP' BITS             64200013
         LR    L1,GR0                  OUTPUT ZEROS FOR SUBSCRIPTS      64260013
         IC    L1,DIMBAS(STACK)                                         64320013
         SR    L1,GR5                                                   64380013
         LR    GR5,L1                  GR5 HOLDS NUMBER OF SUBSCRIPTS   64440013
         AR    L1,L1                                                    64500013
         LA    L1,2(L1,L1)                                              64560013
         BAL   LINKR,GENTST                                             64620013
ERMVC4   MVC   0(4,OP),ERSUB           OUTPUT ',ZERO'                   64680013
         LA    OP,4(OP)                                                 64740013
         BCT   GR5,ERMVC4                                               64800013
         OI    ERRDR+1,TMP             SET 'NOT TEMP' BITS AGAIN        64860013
         BC    B,DEMRP                 FINISH WITH )                    64920013
         SPACE 2                                                        64980013
DERP2    EX    GR5,CDIMBS              ERROR IF SUBSCRIPT COUNT         65040013
         BC    BNE,DERSB2            NOT EQUALS BASE DIMENSIONALITY     65100013
DEORP    LA    L1,2                    OUTPUT )                         65160013
         BAL   LINKR,GENTST                                             65220013
DEMRP    MVI   0(OP),RP                                                 65280013
         SPACE                                                          65340013
         MVI   1(OP),LCB               OUTPUT LEFT CURLY BRACKET        65400013
         LA    OP,2(OP)                                                 65460013
         SPACE 2                                                        65520013
*              SELL ALL TEMPORARIES AND RETURN                          65580013
         SPACE                                                          65640013
         L     GR3,ENDSTC                                               65700013
         LR    GR5,ONE                 CLEAR TOP OF GR5                 65760013
         IC    GR5,DIMS(STACK)         SET GR5 TO END OF TEMP-TABLE     65820013
         AR    GR5,GR5                                                  65880013
         AR    GR5,GR3                                                  65940013
         SR    GR5,ONE                                                  66000013
         LA    GR4,2                   SET UP INCREMENT                 66060013
         LA    L1,5                    LOAD LENGTH OF 'SELL TEMP' STMT  66120013
DESTMQ   TM    1(GR3),TMP              IS THIS A TEMP                   66180013
         BC    BNZ,DENXSL              - GO IF NOT                      66240013
         LH    GR6,0(GR3)              SLOT TEMP INTO                   66300013
         STH   GR6,SELTM             'SELL TEMP' STATEMENT              66360013
         BAL   LINKR,GENTST                                             66420013
         MVC   0(5,OP),SELTEM                                           66480013
         LA    OP,5(OP)                                                 66540013
         ST    OP,STSTAT                                                66600013
DENXSL   BXLE  GR3,GR4,DESTMQ          REPEAT UNTIL NO MORE TEMPS       66660013
         SPACE                                                          66720013
DESOL2   LR    L1,ONE                  OUTPUT RIGHT CURLY BRACKET       66780013
         BAL   LINKR,GENTST                                             66840013
         MVI   0(OP),RCB                                                66900013
         AR    OP,ONE                                                   66960013
         SPACE                                                          67020013
         AR    GR5,ONE                 UPDATE ENDSTC POINTER TO ERASE   67080013
         ST    GR5,ENDSTC            TEMP-TABLES FOR THIS ITEM          67140013
         SPACE 4                                                        67200013
         L     SP,END(STACK)                                            67260013
         TM    GE,EOBON                                                 67320013
         BC    BZ,DERETN               GO UNLESS EOB-SWITCH SET         67380013
         ST    SP,INBLOK               UPDATE INBLOK                    67410015
         ST    SP,PAR1(DICT)           CONVERT SYMBOLIC REFERENCE OF    67440013
         L     GRX,ZTXAOF(CTRL)      END-OF-LIST LOCATION TO            67500013
         BALR  LINKR,GRX             ABSOLUTE ADDRESS                   67560013
         L     SP,PAR1(DICT)                                            67620013
DERETN   LA    P2,1(0,SP)              RESET P2                         67680013
         C     STACK,ORIGIN            WAS CALL FROM MASTER ROUTINE     67740013
         BC    BE,DEMAS                YES                              67800013
         SPACE 2                                                        67860013
         ST    STACK,TOPST                                              67920013
         SH    STACK,LENGTH            NO - DECREMENT STACK             67980013
DEOBFF   LR    CBL,GR0                 CLEAR REGISTERS                  68040013
         LR    LVL,GR0                                                  68100013
         IC    CBL,CBLVL(STACK)                                         68160013
         IC    LVL,LEVEL(STACK)                                         68220013
         L     GR5,LASTMP(STACK)                                        68280013
         BC    B,SUSCAN                                                 68340013
         SPACE 2                                                        68400013
DEMAS    MVI   TABLE+LP,0              RESET TABLE FOR MASTER ROUTINE   68460013
         MVI   TABLE+RP,0                                               68520013
         MVI   TABLE+CMA,0                                              68580013
         MVI   TABLE+LCB,0                                              68640013
         MVI   TABLE+RCB,0                                              68700013
         TM    GE,EOBON                RETURN TO MASTER SCAN UNLESS     68760013
         BC    BZ,MASCAN             EOB-SWITCH IS SET                  68820013
         SPACE                                                          68880013
         L     GR4,OPDRES(STACK)       RETURN TO OPDRES BLOCK           68940013
         ST    GR4,PAR1(DICT)                                           69000013
         LA    GR5,FREE                                                 69060013
         L     GR6,ZCHNOF(CTRL)                                         69120013
DETEXT   ST    GR5,PAR2(DICT)          CHAIN TO NEXT BLOCK, MARKING     69180013
         BALR  LINKR,GR6             PREVIOUS ONE FREE                  69240013
         CLC   PAR1+1(1,DICT),INBLOK+1   IS NEXT BLOCK THE END BLOCK    69300013
         BC    BNE,DETEXT              - GO IF NOT                      69360013
         NI    GE,EOBOFF               RESET EOB-SWITCH                 69420013
         BC    B,MASCAN                                                 69480013
         SPACE 4                                                        69540013
CDIMS    CLI   DIMS(STACK),0           SUBJECT OF EXECUTE INSTRNS       69600013
CDIMBS   CLI   DIMBAS(STACK),0         DITTO                            69660013
         EJECT                                                          69720013
*                       SUBLIST/SKIP/MOVE SUBROUTINE                    69780013
*                                                                       69840013
*              FUNCTION - SKIPS OVER OR PREPARES TO MOVE A SUBSCRIPT    69900013
*        EXPRESSION OR LIST THEREOF OR A NESTED STATEMENT.              69960013
*                                                                       70020013
*              ENTRY POINTS (1) SULIST, TO SKIP TO THE END OF A         70080013
*        PARENTHESISED LIST.                                            70140013
*                           (2) SUSKIP, TO SKIP OVER A SUBSCRIPT        70200013
*        EXPRESSION.                                                    70260013
*                           (3) SUSCAN, RETURN FROM DEFSUB AFTER        70320013
*        PROCESSING A NESTED ISUB-REFERENCE.                            70380013
*                           (4) SUMOVE, TO SCAN A SUBSCRIPT EXPRESSION  70440013
*        BEFORE IT IS MOVED TO OUTPUT.                                  70500013
*                           (5) ERMAS, FROM GENTST WHEN A SERIOUS ERROR 70560013
*        IS FOUND, TO RETURN TO THE MASTER ROUTINE.                     70620013
*              FOR ENTRY POINTS 1-4, REGISTER LINKR HOLDS THE RETURN    70680013
*        ADDRESS.  FOR ENTRY POINTS 2-4, REGISTER SP POINTS TO THE      70740013
*        OPENING DELIMITER - FOR SULIST, IT POINTS TO THE FIRST BYTE OF 70800013
*        THE LIST.                                                      70860013
*                                                                       70920013
*              EXTERNAL ROUTINES - ERROR (THIS MODULE) RECORDS ERROR    70980013
*        MESSAGE.                                                       71040013
*                                  MOVE (THIS MODULE) MOVES TEXT FROM   71100013
*        SOURCE TO OUTPUT.                                              71160013
*                                  ZCHAIN (CONTROL PHASE) GETS NEXT     71220013
*        SOURCE TEXT BLOCK IN THE CHAIN.                                71280013
*                                                                       71340013
*              EXITS - NORMAL (1) TO DERCUR, IF AN ISUB-DEFINED ITEM IS 71400013
*        FOUND DURING A 'PREPARING TO MOVE' SCAN.                       71460013
*                             (2) VIA LINKR WHEN THE CLOSING DELIMITER  71520013
*        IS FOUND.                                                      71580013
*                                                                       71640013
*              EXIT - ERROR - TO DEMAS TO RETURN TO MASTER ROUTINE IF A 71700013
*        SERIOUS ERROR IS FOUND.                                        71760013
*                                                                       71820013
*              TABLES - TABLE (THIS MODULE) IS A 256-BYTE TRT-TABLE     71880013
*        USED TO SCAN THE TEXT.  NOTE THAT IT CONTAINS STOPPERS FOR     71940013
*        COMMA AND LEFT AND RIGHT PARENTHESES AND CURLY BRACKETS, AS    72000013
*        WELL AS THOSE SHOWN IN THE LISTING.                            72060013
         SPACE                                                          72120013
SULIST   NI    SW(STACK),SUOFF         SUBLIST SKIP                     72180013
         OI    SW(STACK),LIST                                           72240013
         BCT   SP,SUALL                                                 72300013
         SPACE                                                          72360013
SUSKIP   NI    SW(STACK),SUOFF         SUB-EXPRESSION SKIP              72420013
         OI    SW(STACK),OMVON                                          72480013
         BC    B,SUALL                                                  72540013
         SPACE                                                          72600013
SUMOVE   NI    SW(STACK),SUOFF         SUB-EXPRESSION MOVE              72660013
SUALL    ST    GR3,R3ST(STACK)                                          72720013
         LR    CBL,GR0                 SET CURLY BRACKET LEVEL TO ZERO  72780013
SUALLB   LR    LVL,ONE                 SET LEVEL TO ONE                 72840013
         ST    LINKR,RETDEF(STACK)                                      72900013
         SPACE 2                                                        72960013
SUSCAN   TRT   1(256,SP),TABLE                                          73020013
         BC    BNZ,SUTEST              BRANCH IF CHARACTER FOUND        73080013
         LA    SP,256(0,SP)                                             73140013
         BC    B,SUSCAN                                                 73200013
         SPACE                                                          73260013
SUTEST   CLI   0(SP),OPOF              IS BYTE FOUND OPERAND            73320013
         BC    BNE,SUTST2                                               73380013
         LA    SP,2(0,SP)              YES - BYPASS DICT REFCE AND      73440013
         BC    B,SUSCAN              CONTINUE SCAN                      73500013
         SPACE 2                                                        73560013
SUTST2   CLI   0(SP),DSM               IS BYTE FOUND DEFINED SUBSCRIPT  73620013
         BC    BNE,SUST2A            MARKER                             73680013
         TM    SW(STACK),OMVON         YES - IS MOVE NEEDED             73740013
         BC    BNZ,SUSCAN              NO                               73800013
         SH    SP,THREE                YES - RECUR TO DEFSUB            73860013
         BC    B,DERCUR                                                 73920013
         SPACE 2                                                        73980013
SUST2A   CLI   0(SP),LP                IS BYTE FOUND (                  74040013
         BC    BNE,SUTST3                                               74100013
         BXH   LVL,ONE,SUSCAN          YES - BUMP LVL AND CONTINUE SCAN 74160013
         SPACE 2                                                        74220013
SUTST3   CLI   0(SP),RP                IS BYTE FOUND )                  74280013
         BC    BNE,SUTST4                                               74340013
         BCT   LVL,SUSCAN              YES - END IF LEVEL IS ONE        74400013
         BC    B,SURET               OTHERWISE DECREMENT LEVEL          74460013
         SPACE 2                                                        74520013
SUTST4   CLI   0(SP),CMA               IS BYTE FOUND COMMA              74580013
         BC    BNE,SUTST5                                               74640013
         CR    LVL,ONE                 YES - END IF LEVEL IS ONE,       74700013
         BC    BNE,SUSCAN                                               74760013
         CR    CBL,GR0               AND CURLY BRACKET LEVEL IS ZERO,   74820013
         BC    BNE,SUSCAN                                               74880013
SUEND2   TM    SW(STACK),LISTON      UNLESS SKIPPING SUBLIST            74940013
         BC    BNZ,SUSCAN                                               75000013
SURET    L     LINKR,RETDEF(STACK)                                      75060013
         L     GR3,R3ST(STACK)         RELOAD PARAMETERS                75120013
         LA    GR4,2                                                    75180013
         BCR   B,LINKR                                                  75240013
         SPACE 2                                                        75300013
SUTST5   CLI   0(SP),SUB               IS BYTE FOUND SUB                75360013
         BC    BNE,SUTST6                                               75420013
         TM    SW(STACK),OMVON                                          75480013
         BC    BZ,SUSUBS               GO IF MOVING OUT TEXT            75540013
         BXH   SP,ONE,SUSCAN           YES - BUMP SP AND CONTINUE SCAN  75600013
         SPACE 2                                                        75660013
SUTST6   CLI   0(SP),LCB               IS BYTE FOUND LEFT CURLY BRACKET 75720013
         BC    BNE,SUTST7                                               75780013
         AR    CBL,ONE                 YES - BUMP CBLEVEL               75840013
         BC    B,SUSCAN                                                 75900013
         SPACE 2                                                        75960013
SUTST7   CLI   0(SP),RCB               IS BYTE A RIGHT CURLY BRACKET    76020013
         BC    BNE,SUTST8                                               76080013
         SR    CBL,ONE                 YES - DECREMENT CBLEVEL AND      76140013
         BC    B,SUSCAN              CONTINUE SCAN                      76200013
         SPACE 2                                                        76260013
SUTST8   CLI   0(SP),EOB               IS BYTE FOUND EOB                76320013
         BC    BE,SUEOB                                                 76380013
         SPACE                                                          76440013
         BAL   LINKR,ERROR             NO - ERROR                       76500013
         DC    X'00038A54'                                              76560013
         SR    SP,ONE                                                   76620013
ERMAS    LR    P2,SP                   RETURN TO MASTER ROUTINE         76680013
         L     STACK,ORIGIN                                             76740013
         LA    STACK,STACKL(STACK)                                      76800013
         ST    STACK,LIMIT                                              76860013
         L     STACK,ORIGIN                                             76920013
         ST    GR0,TOPST                                                76980013
         BC    B,DEMAS                                                  77040013
*  *  *  END  OF  ERROR ROUTINE                                         77100013
         SPACE 2                                                        77160013
*              REPLACE ISUB BY REFERENCE OF ITS TEMPORARY OR SUBSCRIPT  77220013
         SPACE                                                          77280013
SUSUBS   BAL   LINKR,MOVE              MOVE TEXT BEFORE SUB             77340013
         LR    GR6,GR0                 CLEAR GR6                        77400013
         IC    GR6,1(SP)               INSERT ISUB-NUMBER               77460013
         EX    GR6,CDIMS               CHECK ISUB-NUMBER IS NOT TOO     77520013
         BC    BHE,SUOK3             LARGE                              77580013
         SPACE                                                          77640013
         BAL   LINKR,ERROR1            'ISUB NUMBER TOO GREAT'          77700013
         DC    X'00038558'             901 DECIMAL                      77760013
         IC    GR6,DIMS(STACK)         REPLACE ISUB-NUMBER BY MAXIMUM   77820013
         STC   GR6,1(SP)             ALLOWABLE                          77880013
         SPACE                                                          77940013
SUOK3    SR    GR6,ONE                 POINT GR6 TO CORRESPONDING TEMP  78000013
         AR    GR6,GR6                                                  78060013
         A     GR6,ENDSTC                                               78120013
         LA    L1,3                    OUTPUT DICT REF OF TEMP IN PLACE 78180013
         BAL   LINKR,GENTST          OF ISUB                            78240013
         MVI   0(OP),OPD                                                78300013
         MVC   1(2,OP),0(GR6)                                           78360013
         NI    2(OP),NOTMP             SET 'NOT TEMP' BIT OFF IF ON     78420013
         AR    OP,L1                                                    78480013
         LA    P2,2(SP)                                                 78540013
         BXH   SP,ONE,SUSCAN           SKIP ISUB-NUMBER AND CONTINUE    78600013
         SPACE 2                                                        78660013
*              END-OF-BLOCK- PROCESSING                                 78720013
         SPACE                                                          78780013
SUEOB    STC   CBL,CBLVL(STACK)        SAVE LEVELS                      78840013
         STC   LVL,LEVEL(STACK)                                         78900013
         TM    SW(STACK),OMVON         MOVE OUT TEXT IF MOVING          78960013
         BC    BNZ,SUEOB3                                               79020013
         BAL   LINKR,MOVE                                               79080013
         ST    OP,STSTAT                                                79140013
         SPACE                                                          79200013
SUEOB1   LA    CBL,NWNT                LOAD 'NOT WANTED' PARAMETER      79260013
SUEOB2   L     GRX,ZCHNOF(CTRL)                                         79320013
         L     SP,INBLOK               CHAIN TO NEXT BLOCK FROM INBLOK  79380013
         ST    SP,PAR1(DICT)                                            79440013
         ST    CBL,PAR2(DICT)                                           79500013
         BALR  LINKR,GRX                                                79560013
         L     SP,PAR1(DICT)                                            79620013
         ST    SP,INBLOK               RESET INBLOK                     79680013
SUEOB4   L     SP,PAR2(DICT)                                            79740013
         LR    P2,SP                                                    79800013
         LR    LVL,GR0                 RESTORE LEVELS                   79860013
         IC    LVL,LEVEL(STACK)                                         79920013
         IC    CBL,CBLVL(STACK)                                         79980013
         BCT   SP,SUSCAN               CONTINUE SCAN IN NEW BLOCK       80040013
         SPACE                                                          80100013
SUEOB3   OI    GE,EOBON                TURN ON EOB-SWITCH               80160013
         TM    SW(STACK),L1ON          RETURN IF L1-SWITCH SET (INITIAL 80220013
         BC    BNZ,SURET             SCAN OF SECOND SUBSCRIPT-LIST)     80280013
         TM    SW(STACK),T1LIST        CHAIN TO NEXT BLOCK UNLESS ON    80340013
         BC    BMZ,SUEOB1            INITIAL SCAN OF FIRST SUB-LIST,    80400013
         LA    CBL,BUSY              WHEN MARK THIS BLOCK 'BUSY' BEFORE 80460013
         NI    SW(STACK),T1OFF       CHAINING                           80520013
         BC    B,SUEOB2                                                 80580013
         EJECT                                                          80640013
*                       MOVE                                            80700013
*                                                                       80760013
*              FUNCTION - MOVES SOURCE TEXT TO OUTPUT                   80820013
*                                                                       80880013
*              ENTRY POINTS (1) MOVE - TO CHECK IF ENOUGH ROOM LEFT     80940013
*        IN OUTPUT BLOCK, CALL FOR NEW BLOCK IF NEEDED, AND MOVE TEXT.  81000013
*        REGISTER SP POINTS TO THE FIRST BYTE NOT TO BE MOVED, AND      81060013
*        BLKEND HOLDS THE ADDRESS OF THE END OF THE OUTPUT TEXT BLOCK.  81120013
*                           (2) MOVE2 - FROM GENTST, TO MOVE DATA TO    81180013
*        OUTPUT WITHOUT CHECKING.  REGISTER L1 HOLDS THE NUMBER OF      81240013
*        BYTES TO BE MOVED.                                             81300013
*              FOR BOTH ENTRY POINTS, REGISTER P2 POINTS TO THE FIRST   81360013
*        BYTE TO BE MOVED, REGISTER OP POINTS TO THE DESTINATION OF     81420013
*        THIS BYTE, AND REGISTER LINKR HOLDS THE RETURN ADDRESS.        81480013
*                                                                       81540013
*              EXTERNAL ROUTINE - GNTST3 (THIS MODULE) CHECKS LENGTH OF 81600013
*        STATEMENT BEING OUTPUT AND GETS NEW OUTPUT TEXT BLOCK.         81660013
*                                                                       81720013
*              EXIT - NORMAL - VIA REGISTER LINKR.                      81780013
*                                                                       81840013
*              EXIT - ERROR - NONE.                                     81900013
*                                                                       81960013
MOVE     STM   GRQ,GR3,ST23                                             82020013
         LR    L1,SP                                                    82080013
         SR    L1,P2                   GET LENGTH TO BE MOVED           82140013
         LR    TEMPR,OP                                                 82200013
         AR    TEMPR,L1                                                 82260013
         CL    TEMPR,BLKEND            IS THERE ROOM IN OUTPUT STRING   82320013
         BC    BM,MOVE2                YES                              82380013
         ST    LINKR,MVRAD             NO                               82440013
         BAL   LINKR,GNTST3            CALL GENERATE TEST FOR NEW BLOCK 82500013
         L     LINKR,MVRAD                                              82560013
         SPACE                                                          82620013
MOVE2    LA    TEMPR,256(0,0)                                           82680013
         CR    L1,TEMPR                IS LENGTH MORE THAN 256          82740013
         BC    BM,MVA                  NO                               82800013
         MVC   0(256,OP),0(P2)         YES MOVE 256                     82860013
         AR    P2,TEMPR                INCREASE AND DECREASE POINTERS   82920013
         AR    OP,TEMPR                                                 82980013
         SR    L1,TEMPR                                                 83040013
         BC    B,MOVE2                 GO BACK                          83100013
         SPACE                                                          83160013
MVA      CR    L1,GR0                  IS LENGTH STILL TO BE MOVED ZERO 83220013
         BC    BE,MVB                  YES                              83280013
         SR    L1,ONE                  NO                               83340013
         STC   L1,*+5                                                   83400013
         MVC   0(0,OP),0(P2)           MOVE THE REST                    83460013
         AR    OP,L1                                                    83520013
         AR    OP,ONE                                                   83580013
MVB      LR    P2,SP                                                    83640013
         LM    GRQ,GR3,ST23                                             83700013
         BCR   B,LINKR                 RETURN                           83760013
         EJECT                                                          83820013
*                       GENERATE TEST                                   83880013
*                                                                       83940013
*              FUNCTIONS - TESTS IF ROOM IN OUTPUT TEXT BLOCK FOR       84000013
*        FURTHER DATA.  IF NOT, PROVIDED THE CURRENT STATEMENT LENGTH   84060013
*        DOES NOT EXCEED ONE TEXT BLOCK, OBTAINS A NEW TEXT BLOCK, TO   84120013
*        WHICH IS TRANSFERRED THE FIRST PART OF THE CURRENT STATEMENT   84180013
*        IF NECESSARY, THE PREVIOUS TEXT BLOCK BEING MARKED NOT WANTED. 84240013
*                                                                       84300013
*              ENTRY POINTS (1) GENTST, TO PERFORM THE ABOVE FUNCTIONS. 84360013
*                           (2) GNTST3, FROM MOVE, TO CHECK STATEMENT   84420013
*        LENGTH AND GET NEW OUTPUT TEXT BLOCK.  REGISTER TEMPR POINTS   84480013
*        TO THE LOCATION (BEYOND THE END OF THE OUTPUT TEXT BLOCK)      84540013
*        WHERE THE LAST BYTE OF DATA TO BE OUTPUT WOULD FALL.           84600013
*              FOR BOTH ENTRY POINTS, REGISTER OP POINTS TO THE NEXT    84660013
*        FREE BYTE IN THE OUTPUT BLOCK, REGISTER L1 HOLDS THE NUMBER OF 84720013
*        BYTES TO BE OUTPUT, REGISTER LINKR HOLDS THE RETURN ADDRESS,   84780013
*        THE WORD 'BLKEND' POINTS TO THE END OF THE OUTPUT TEXT BLOCK,  84840013
*        AND THE WORD 'STSTAT' POINTS TO THE START OF THE STATEMENT     84900013
*        CURRENTLY BEING OUTPUT.                                        84960013
*                                                                       85020013
*              EXTERNAL ROUTINES - ERROR (THIS MODULE) RECORDS ERROR    85080013
*        MESSAGE.                                                       85140013
*                                  ZUTXTC (CONTROL PHASE) GETS NEW TEXT 85200013
*        BLOCK.                                                         85260013
*                                  MOVE2 (THIS MODULE) MOVES DATA TO    85320013
*        OUTPUT.                                                        85380013
*                                  ZALTER (CONTROL PHASE) ALTERS STATUS 85440013
*        OF TEXT BLOCK.                                                 85500013
*                                                                       85560013
*              EXIT - NORMAL - VIA REGISTER LINKR.                      85620013
*                                                                       85680013
*              EXIT - ERROR - TO ERMAS (THIS MODULE) IF STATEMENT IS    85740013
*        TOO LONG.                                                      85800013
*                                                                       85860013
GENTST   AR    OP,L1                                                    85920013
         C     OP,BLKEND               IS THERE ROOM IN OUTPUT BLOCK    85980013
         BC    BHE,GNTST2              - GO IF NOT                      86040013
         SR    OP,L1                                                    86100013
         BCR   B,LINKR                 RETURN                           86160013
         SPACE                                                          86220013
GNTST2   ST    GR3,ST3                                                  86280013
         LR    TEMPR,OP                                                 86340013
         SR    OP,L1                                                    86400013
         SPACE 2                                                        86460013
GNTST3   ST    LINKR,GTRAD                                              86520013
         S     TEMPR,STSTAT                                             86580013
         C     TEMPR,TBLOCL(0,DICT)    IS LENGTH OF STATEMENT MORE THAN 86640013
         BC    BLE,GTC               PERMITTED - GO IF NOT              86700013
         SPACE                                                          86760013
         BAL   LINKR,ERROR             ERROR - STATEMENT TOO LONG       86820013
         DC    X'00038B44'             (DECIMAL 907)                    86880013
         BC    B,ERMAS                                                  86940013
         SPACE                                                          87000013
GTC      CL    OP,STSTAT               IS OUTPUT POINTER AT STATEMENT   87060013
         BC    BNE,GTB               START. NO                          87120013
         MVI   0(OP),EOB               MAKE END OF BUFFER MARKER        87180013
         MVI   MSW,X'FF'               SET MOVE SWITCH ON               87240013
         LA    TEMPR,OUT               MARK OLD BLOCK NOT WANTED        87300013
         BC    B,GTE                                                    87360013
GTB      MVI   MSW,X'00'               SET MOVE SWITCH OFF              87420013
         LA    TEMPR,BSY               MARK OLD BLOCK BUSY              87480013
         SPACE                                                          87540013
GTE      ST    TEMPR,PAR2(0,DICT)      GET NEW OUTPUT TEXT BLOCK,       87600013
         L     TEMPR,OUBLOK          CHAINED TO OLD                     87660013
         ST    TEMPR,PAR1(0,DICT)                                       87720013
         ST    TEMPR,OUTBLK            SAVE NAME OF OLD BLOCK           87780013
         L     GRX,ZUTXOF(0,CTRL)                                       87840013
         BALR  LINKR,GRX                                                87900013
         L     TEMPR,PAR1(0,DICT)      STORE NAME OF NEW BLOCK          87960013
         ST    TEMPR,OUBLOK                                             88020013
         L     TEMPR,PAR2(0,DICT)                                       88080013
         A     TEMPR,TBLOCL(0,DICT)                                     88140013
         ST    TEMPR,BLKEND            SET BLOCKEND FOR NEW OUTPUT BLOK 88200013
         SPACE                                                          88260013
         CLI   MSW,X'FF'               IS MOVE SWITCH ON                88320013
         BC    BE,GETX                 - GO IF SO                       88380013
         SPACE                                                          88440013
         ST    L1,L1ST                 NO - SAVE LENGTH AND MOVE        88500013
         ST    P2,P2ST               POINTER                            88560013
         LR    L1,OP                   SET POINTERS TO MOVE FIRST PART  88620013
         L     P2,STSTAT             OF CURRENT STATEMENT FROM OLD      88680013
         SR    L1,P2                 OUTPUT BLOCK TO NEW BLOCK          88740013
         L     OP,PAR2(0,DICT)                                          88800013
         BAL   LINKR,MOVE2             CALL MOVE                        88860013
         L     L1,L1ST                 RESTORE LENGTH AND MOVE POINTER  88920013
         L     P2,P2ST                                                  88980013
         L     TEMPR,STSTAT            PUT END OF BUFFER MARKER         89040013
         MVI   0(TEMPR),EOB          INTO OLD BLOCK                     89100013
         L     TEMPR,PAR2(0,DICT)      RESET STATEMENT START            89160013
         ST    TEMPR,STSTAT                                             89220013
         SPACE                                                          89280013
GTD      L     TEMPR,OUTBLK            MARK OLD BLOCK NOT WANTED        89340013
         ST    TEMPR,PAR1(0,DICT)                                       89400013
         LA    TEMPR,NWNT                                               89460013
         ST    TEMPR,PAR2(0,DICT)                                       89520013
         L     TEMPR,ZALTOF(0,CTRL)                                     89580015
         LA    LINKR,GTRET           AND RETURN TO GTRET                89640015
         BCR   B,TEMPR                                                  89700015
         SPACE 2                                                        89760013
GETX     L     OP,PAR2(0,DICT)         SET OUTPUT POINTER,              89820013
         ST    OP,STSTAT             STATEMENT START                    89880013
GTRET    L     LINKR,GTRAD                                              89940013
         L     GR3,ST3                                                  90000013
         BCR   B,LINKR                 RETURN                           90060013
         EJECT                                                          90120013
MSW      DS    C                                                        90180013
GE       DC    X'00'                                                    90240013
EOPSW    DC    X'00'                                                    90300013
DR14     DS    H                                                        90360013
LENGTH   DC    H'28'                   LENGTH OF PUSH-DOWN STACK        90420013
THREE    DC    H'3'                                                     90480013
ERTAB    DS    32H                                                      90540013
ERSTMT   DS    H                                                        90600013
ERDRNO   DC    H'0'                                                     90660013
R345ST   DS    3F                                                       90720013
LOWPSW   DS    F                                                        90780013
BOOBOO   DS    F                       ERROR RETURN ADDRESS             90840013
TOPST    DC    F'0'                                                     90900013
INBLOK   DS    F             START OF INPUT BLOCK                       90960013
OPBLOK   DS    F             SOURCE OPERAND TEXT BLOCK REFERENCE        90990015
ORIGIN   DS    F             START OF SCRATCH CORE                      91020013
AUTCHN   DS    F                                                        91080013
RETURN   DS    F                                                        91140013
SPST     DS    F                                                        91200013
ENDSTC   DS    F                                                        91260013
LIMIT    EQU   ENDSTC        END OF SCRATCH CORE                        91320013
STSTAT   DS    F             START OF STATEMENT (ABSOLUTE)              91380013
OUBLOK   DS    F             START OF OUTPUT BLOCK (REFERENCE)          91440013
BLKEND   DS    F             END OF OUTPUT BLOCK (ABSOLUTE)             91500013
ST23     DS    F                                                        91560013
ST3      DS    F                                                        91620013
OUTBLK   DS    F                                                        91680013
MVRAD    DS    F                                                        91740013
GTRAD    DS    F                                                        91800013
L1ST     DS    F                                                        91860013
P2ST     DS    F                                                        91920013
         SPACE                                                          91980013
         DS    0H                                                       92040013
SELTEM   DC    AL1(SELL)     SELL                                       92100013
         DC    AL1(OPD)                                                 92160013
SELTM    DS    2C             TEMP                                      92220013
         DC    AL1(SCLN)       ;                                        92280013
         SPACE                                                          92340013
         DS    0H                                                       92400013
BASE     DC    AL1(RCB)                                                 92460013
         DC    AL1(OPD)                                                 92520013
BASREF   DS    H                                                        92580013
         DC    AL1(SM)                                                  92640013
         SPACE                                                          92700013
         DS    0H                                                       92760013
ERSUB    DC    AL1(CMA)                                                 92820013
         DC    AL1(OPD)                                                 92880013
ERRDR    DC    H'0'                                                     92940013
         SPACE                                                          93000013
         DS    0H                                                       93060013
BUYTEM   DC    AL1(BUY)      BUY                                        93120013
         DC    AL1(OPD)                                                 93180013
TEMP1    DS    2C             TEMP                                      93240013
         DC    AL1(SCLN)       ;                                        93300013
         DC    AL1(ASGT)        ASSIGNMENT -                            93360013
         DC    AL1(OPD)                                                 93420013
TEMP2    DS    2C                 TEMP                                  93480013
         DC    AL1(AM)            =                                     93540013
         SPACE                                                          93600013
         DS    0H                                                       93606015
SIGNAL   DC    AL1(IF)       IF                                         93612015
         DC    AL1(OPD)                                                 93618015
SUBSCR   DS    2C             SUBSCRIPT                                 93624015
LTGT     DS    C               < OR >                                   93630015
         DC    X'00000230'      ADV                                     93636015
         DC    AL1(LP)           (                                      93642015
         DC    AL1(OPD)                                                 93648015
DEF      DS    2C                 ARRAY                                 93654015
         DC    X'445E00'                                                93660015
LHBND    DS    C                   LBOUND OR HBOUND                     93666015
DIMNO    DS    C                    DIMENSION NUMBER                    93672015
         DC    AL1(RP)               )                                  93678015
         DC    AL1(THEN)              THEN                              93684015
         DC    AL1(SGNL)               SIGNAL                           93690015
         DC    AL1(OPD)                                                 93696015
DRSBRG   DS    H                        SUBSCRIPTRANGE                  93702015
         DC    AL1(SCLN)                 ;                              93708015
         SPACE                                                          93714015
SBRGDE   DC    AL1(DON)                                                 93720015
         DC    AL2(SBRGLE)                                              93726015
         DC    XL5'0'                                                   93732015
         DC    AL1(SBRNGE)                                              93738015
         DC    X'0000'                                                  93744015
         SPACE 1                                                        93750015
         DS    0H                                                       93756015
POB      DS    C                                                        93762015
CONSTE   DC    X'88'                                                    93780013
CONLEN   DC    AL2(CONLN)                                               93840013
DRN14    DS    2C                                                       93900013
DED1     DS    3C                                                       93960013
DED2     DC    X'008C0F800000'                                          94020015
         SPACE                                                          94080013
         DS    0H                                                       94140013
FOUND    DS    C                                                        94200013
TEMPDE   DC    X'8F'                                                    94260013
         DC    AL2(TEMPLE)                                              94320013
         DC    XL7'0'                                                   94380013
         DC    X'00000000208C'                                          94440013
         DC    X'0F80000000'                                            94500013
         DC    XL2'0'                                                   94560013
         SPACE                                                          94620013
ZERO     DC    X'88'                                                    94680013
         DC    AL2(ZEROLN)                                              94740013
         DC    XL2'0'                                                   94800013
         DC    X'8C0F80C0'                                              94860015
         DC    X'8C0F800000'                                            94920015
         DC    XL4'0'                                                   94980013
         EJECT                                                          95040013
TABLE    DC    64F'0'                                                   95100013
         ORG   TABLE+00                                                 95160013
         DC    AL1(OP)                                                  95220013
         ORG   TABLE+X'2E'                                              95280013
         DC    AL1(DSM)                                                 95340013
         ORG   TABLE+X'BC'                                              95400013
         DC    AL1(SC)                                                  95460013
         ORG   TABLE+X'D0'                                              95520013
         DC    AL1(SC)                                                  95580013
         ORG   TABLE+X'D2'                                              95640013
         DC    AL1(SC)                                                  95700013
         ORG   TABLE+X'D4'                                              95760013
         DC    AL1(SC)                                                  95820013
         ORG   TABLE+X'D6'                                              95880013
         DC    AL1(SC)                                                  95940013
         ORG   TABLE+X'EB'                                              96000013
         DC    AL1(EOP)                                                 96060013
         ORG   TABLE+X'ED'                                              96120013
         DC    AL1(EOB)                                                 96180013
         ORG   TABLE+X'FE'                                              96240013
         DC    AL1(SUB)                                                 96300013
         ORG   TABLE+256                                                96360013
         SPACE                                                          96420013
         END   IEMHP                                                    96480013
