KA       TITLE 'PL/1 (F) COMPILER K PHASES RESIDENT CONTROL MODULE.'    00060001
*                                                                       00070001
*                                                                       00080001
*              FUNCTIONS - (1) TO PROVIDE UTILITY ROUTINES FOR THE      00090001
*              K PHASES FOR HANDLING TABLES IN TEXT BLOCKS.THE ROUTINES 00100001
*              PROVIDE FACILITIES FOR BUILDING,SCANNING,MAKING DIRECT   00110001
*              REFERENCE,LOCKING,UNLOCKING AND FREEING TABLE ENTRIES.   00120001
*              THE NORMAL TEXT MAY ALSO BE PROCESSED BY THE TABLE       00130001
*              HANDLING ROUTINES.                                       00140001
*                                                                       00150001
*                          (2) TO PROVIDE A LOCAL COMMUNICATIONS REGION 00160001
*              FOR THE K PHASES. THIS DATA AREA IS BASED ON GRLCOM,     00170001
*              WHICH ALSO ACTS AS A BASE REGISTER FOR THIS MODULE.      00180001
*                                                                       00190001
*                                                                       00200001
*                                                                       00210001
*              EXTERNAL ROUTINES CALLED(IN COMPILER CONTROL):           00220001
*              RLSCTL,ZTXTAB,ZUTXTC,ZUERR,ZABORT,ZALTER,ZCHAIN.         00230001
*                                                                       00240001
*                                                                       00250001
*                                                                       00260001
*              ENTRY POINTS(1) NORMAL ENTRY FROM PREVIOUS PHASE.        00270001
*                                                                       00280001
*                          (2) ENTRIES FROM K PHASES FOR CALLS TO       00290001
*              UTILITIES - SEE TRANSFER VECTOR  KAVECT.                 00300001
*                                                                       00310001
*                                                                       00320001
*                                                                       00330001
*              EXIT POINTS (1) EXIT TO NEXT PHASE BY CALL TO RLSCTL.    00340001
*              KA REMAINS IN STORE FO USE BY OTHER K PHASES BUT IS      00350001
*              DELETED BY A CALL TO RLSCTL IN KO JUST BEFORE LOADING    00360001
*              MODULE KT.                                               00370001
*                                                                       00380001
*                          (2) TERMINAL ERROR BY CALL TO ZABORT.        00390001
*                                                                       00400001
*                                                                       00410001
*                                                                       00420001
*              WORK AREA   XLCR - THE K PHASES COMMUNICATIONS REGION    00430001
*              IN THIS MODULE KA.                                       00440001
*                                                                       00450001
*                                                                       00460001
*                                                                       00470001
*              NOTE        THIS MODULE REQUIRES THE IEMK... MACROS      00480001
*              FOR ASSEMBLY                                             00490001
         EJECT                                                          00780001
*                                                                       00840001
EQUD     DSECT                          DUMMY DSECT STATEMENT           00847001
*                                       PREVENTS THE ASSEMBLER GIVING   00854001
*                                       RISE TO A CSECT WITH NAME BLANK 00861001
*                                       AND LENGTH ZERO                 00868001
*                                       ON MEETING THE FIRST EQU        00875001
*                                       STATEMENT                       00882001
*                                                                       00889001
** LOCAL EQUATES                                                        00900001
*                                                                       00960001
SAVARNO  EQU   5                   DEPTH OF TYPE 1 SAVE AREA NESTING    01020001
GRX      EQU   2                   WORK REGISTER                        01080001
*                                                                       01140001
         SPACE 2                                                        01200001
         COPY  IEMKEQU                                                  01260001
         COPY  IEMKCOM                                                  01320001
         COPY  IEMKUTL                                                  01380001
         COPY  IEMKTRP                                                  01440001
*                                                                     * 01500001
** THE XTCA DSECT DESCRIBES THE FORMAT OF A TABLE CONTROL AREA       ** 01560001
**   AS SET UP BY THE DTCA MACRO-INSTRUCTION.                        ** 01620001
*                                                                     * 01680001
XTCA     DSECT                                                          01740001
*                                                                       01800001
         USING *,GR9               ALWAYS BASED BY GR9                  01860001
*                                                                       01920001
XTCAENTL DS    H                   LENGTH OF ENTRY OR DISP TO LENG FLD  01980001
XTCADISP DS    H                   DISPLACEMENT TO LENGTH IN V.L. ENTRY 02040001
*                                                                       02100001
XTCACODE DS    X                   TABLE TYPE AND STATUS CODE BYTE:     02160001
XTCANULL EQU   X'80'                 ON IF NO ENTRIES IN TABLE          02220001
XTCAACTV EQU   X'40'                 ON IF TABLE TO BE DEACTIVATED      02280001
XTCAFIXL EQU   X'20'                 TABLE CONTAINS FIXED LENGTH ENTRIS 02340001
XTCAVARL EQU   X'10'                 TABLE CONTAINS VAR. LENGTH ENTRIES 02400001
XTCAMIXD EQU   X'08'                 TABLE CONTAINS MIXED ENTRIES       02460001
XTCACPTR DS    X                   CURRENT POINTER - SET BY CALLER      02520001
XTCALLEN DS    H                   LENGTH OF LAST ENTRY                 02580001
*                                                                       02640001
XTCASTBL DS    A                   ADDRESS OF FIRST BLOCK LIST ENTRY    02700001
XTCASTCD DS    X                   START OF TABLE CODE (AS XPRGCODE)    02760001
XTCASTSA DS    XL3                 SYMBOLIC ADDRESS OF START OF TABLE   02820001
*                                                                       02880001
XTCAETAA DS    A                   ABSOLUTE ADDRESS OF LAST ENTRY MADE  02940001
XTCAETBL DS    A                   ADDRESS OF LAST BLOCK LIST ENTRY     03000001
XTCAETCD DS    X                   END OF TABLE CODE (AS XPRGCODE)      03060001
XTCAETSA DS    XL3                 SYMBOLIC ADDRESS OF END OF TABLE     03120001
*                                                                       03180001
** AT THIS POINT THE TCA CONTAINS UA TO 'NPTRS+1' POINTER REGIONS WHICH 03240001
**   ARE DESCRIBED BY THE XPRG DSECT. IF A DIRECT REFERENCE POINTER IS  03300001
**   IS PRESENT IT WILL APPEAR FIRST. THE REMAINING 'NPTRS' POINTERS    03360001
**   ARE SEQUENTIAL SCAN POINTERS.                                      03420001
*                                                                       03480001
XTCAPTRS EQU   *                   START OF LIST OF POINTERS            03540001
*                                                                       03600001
** THE FOLLOWING SECTION DESCRIBES THE TCA FOR TEXT TABLES              03660001
*                                                                       03720001
         ORG   XTCA                                                     03780001
XTCATPAR DS    A                   PARAMETER SLOT                       03840001
XTCATNAA DS    A                  A.A. OF NEXT ENTRY                    03900001
XTCATCDE DS    X                   CODE BYTE:                           03960001
XTCATLOK EQU   X'40'                 ON IF CURRENT ENTRY LOCKED         04020001
XTCATACT EQU   X'20'                                                    04080001
XTCATNSA DS    XL3                 S.A. OF NEXT ENTRY                   04140001
XTCATCAA DS    A                    A.A. OF CURRENT ENTRY               04200001
         DS    X                   NOT UESD                             04260001
XTCATCSA DS    XL3                 S.A. OF CURRENT ENTRY                04320001
         DS    X                   NOT USED                             04380001
XTCATPSA DS    XL3                 S.A. OF PREVIOUS ENTRY               04440001
*                                                                       04500001
         EJECT                                                          04560001
*                                                                       04620001
** THE XPRG DSECT DESCRIBES THE FORMAT OF A POINTER REGIONS.            04680001
*                                                                       04740001
XPRG     DSECT                                                          04800001
*                                                                       04860001
XPRGAATE DS    A                   ABSOLUTE ADDRESS OF TABLE ENTRY      04920001
XPRGABLE DS    A                   ADDRESS OF BLOCK LIST ENTRY          04980001
XPRGCODE DS    X                   CODE BYTE:                           05040001
XPRGLPRG EQU   X'80'                 ON FOR LAST POINTER REGION         05100001
XPRGLOCK EQU   X'40'                 ON IF ENTRY LOCKED                 05160001
XPRGSETD EQU   X'20'                 ON IF 'SET' WAS LAST OPERATION     05220001
XPRGSETZ EQU   X'10'                 ON IF 'SETZ' WAS LAST OPERATION    05280001
XPRGPACT EQU   X'08'                 ON IF POINTER IS ACTIVE            05340001
XPRGTOLK EQU   X'04'                 ON IF ENTRY TO BE LOCKED           05400001
XPRGFBOP EQU   X'02'                 ON IF BACKWARD OPTION SPECIFIED    05460001
XPRGKDOP EQU   X'01'                 ON IF DELETE OPTION SPECIFIED      05520001
XPRGSATE DS    XL3                 SYMBOLIC ADDRESS OF ENTRY            05580001
*                                                                       05640001
XPRGEND  EQU   *                                                        05700001
*                                                                       05760001
         EJECT                                                          05820001
         COPY  IEMKBLE                                                  05880001
*                                                                     * 05940001
**  Y VERSION OF XBLE DSECT                                          ** 06000001
*                                                                     * 06060001
YBLE     DSECT                                                          06120001
*                                                                       06180001
YBLELCNT DS    PL1                 FOR FIELD DESCRIPTIONS               06240001
YBLEANLE DS    AL3                   SEE XBLE                           06300001
YBLEBLKN DS    X                     DSECT                              06360001
YBLEAPLE DS    AL3                                                      06420001
YBLEDFEN DS    H                                                        06480001
YBLEDLEN DS    H                                                        06540001
*                                                                       06600001
YBLEEND  EQU   *                                                        06660001
*                                                                       06720001
         EJECT                                                          06780001
         DCBD                                                           06960001
         EJECT                                                          07020001
IEMKA    CSECT                                                          07080001
         DC    C'KA'               PHASE IDENTIFIER                     07140001
*                                                                       07200001
** THE FOLLOWING SECTION IS ENTERED FROM COMPILER CONTROL, PERFORMS     07260001
** INITIALISATION AND PASSES CONTROL TO THE PHASE LOADING ROUTINE.      07320001
*                                                                       07380001
         BALR  LR,0                USE LR AS                            07440001
         USING *,LR                  TEMPORARY BASE                     07500001
         MVC   ZMYNAM(2),=C'KA'                                         07560001
         LA    GRLCOM,KAXLCR       BASE LOCAL COMMUNICATIONS REGION     07620001
         LA    GR2,=C'ZZ'          STORE ADDRESS FO DELETE PHASE LIST   07630001
         ST    GR2,PAR1              IN PAR1                            07640001
         SR    GR2,GR2             SET ZERO FOR STORE                   07650001
         ST    GR2,PAR2            INDICATE NO LOAD LIST                07660001
         L     LR,RLSCTL           CALL RLSCTL TO LOAD                  07670001
         BR    LR                    NEXT PHASE                         07680001
         SPACE                                                          07740001
         USING KAXLCR,GRLCOM       GRLCOM IS NOW BASE                   07800001
         DROP  LR                                                       07860001
         EJECT                                                          07920001
*                                                                       07980001
** KAXLCR IS THE LOCAL COMMUNICATIONS REGION. IT HAS THE SAME LABELS AS 08040001
** THE XLCR DSECT MACRO WHICH IS USED TO DESCRIBE THIS AREA IN OTHER    08100001
** PHASES. THE XLCR MACRO MAY NOT THEREFORE BE USED IN THIS PHASE.      08160001
*                                                                       08220001
KAXLCR   DS    0D                                                       08280001
XLCRASCR DS    0A             ADDRESS OF START OF SCRATCH CORE          08340001
XLCRXISP DC    A(0)             AND OF INITIAL SCAN PARAMETER BLOCK     08400001
XLCRCODE DC    X'0'           CODE BYTE:                                08460001
XLCRPRBG EQU   X'01'          ON IF ABNORMAL UNSAFE VARIABLE PRESENT    08520001
XLCRABSF EQU   X'02'          ON IF PROC OR BEGIN IN CURRENT ITDO       08580001
XLCRFMAP DC    XL3'0'         TEXT REF. OF FIRST LOGICAL DO-MAP ENTRY   08640001
XLCRBSE1 DC    A(0)                                                     08820001
XLCRUASC DC    A(0)                UPPER ADDRESS OF SCRATCH CORE        08880001
         DC    X'00'                                                    08940001
XLCRONUS DC    XL3'0'              ON UNITS MASK                        09000001
XLCRAFFE DC    A(0)                ADDRESS OF FIRST FREE ENTRY IN      -09060001
                                     BLOCK LIST TABLE                   09120001
XLCRTXT  DC    A(0)                POINTERS                             09180001
XLCRMAP  DC    A(0)                  TO                                 09240001
XLCRUSE  DC    A(0)                  TCAS                               09300001
XLCRSRG  DC    A(0)                  FILLED IN                          09360001
XLCRSRT  DC    A(0)                  BY                                 09420001
XLCRPCH  DC    A(0)                  PHASE KB                           09480001
XLCREND  EQU   *                                                        09540001
*                                                                       09600001
         SPACE 2                                                        09660001
*                                                                       09720001
** THE KAVECT TRANSFER VECTOR PROVIDES LINKAGE BETWEEN OTHER KA PHASES  09780001
** AND THE COMMON ROUTINES IN THIS PHASE. IN THE XLCR DSECT, EACH       09840001
** BRANCH INSTRUCTION HAS THE SAME LABEL AS THE ROUTINE TO WHICH        09900001
** IT LINKS.                                                            09960001
*                                                                       10020001
KAVECT   DS    0H                                                       10080001
         B     KAHBLD         TABLE HANDLING - BLDC/T                   10260001
         B     KAHMDR                          DR                       10320001
         B     KAHUDR                          ULDR                     10380001
         B     KAHSET                          SET/SETZ                 10440001
         B     KAHSCN                          SCAN                     10500001
         B     KAHDAC                          DEACT                    10560001
         B     KAHFRE                          FREE                     10620001
         B     KAHTST              SET/SETZ TEXT                        10650001
         B     KAHTSC              SCAN TEXT                            10680001
         B     KAHTDA              DEACT TEXT                           10710001
         B     KAHERR                          ERROR HANDLER            10740001
*                                                                       10860001
         EJECT                                                          10920001
*********************************************************************** 21720001
*                                                                     * 21780001
* ROUTINE KAHBLD. (HANDLES BLDC/T OPERATIONS).                        * 21840001
*                                                                     * 21900001
*   THIS ROUTINE MAKES AN ENTRY IN THE SPECIFIED TABLE. FOR BLDC THE  * 21960001
*   TNTRY IS MOVED INTO THE NEXT AVAILABLE SPACE IN THE TABLE. FOR    * 22020001
*   BLDT A SPACE FOR AN ENTRY IS ALLOCATED AND ITS ADDRESS RETURNED   * 22080001
*   TO THE CALLER. IF THERE IS INSUFFICIENT SPACE IN THE CURRENT TEXT * 22140001
*   BLOCK FOR A NEW ENTRY OR THE TABLE IS NULL (HAS NO ENTRIES) A NEW * 22200001
*   TEXT BLOCK IS OBTAINED FROM COMPILER CONTROL AND AN ENTRY FOR THE * 22260001
*   BLOCK IS ADDED TO THE BLOCK LIST.                                 * 22320001
*                                                                     * 22380001
*   REGISTER USAGE:                                                   * 22440001
*                                                                     * 22500001
*        GR2 - LENGTH OF NEW ENTRY                                    * 22560001
*        GR5 - ADDRESS OF BLOCK LIST ENTRY                            * 22620001
*        GR6 - ADDRESS OF BLOCK LIST ENTRY                            * 22680001
*        GR7 - ADDRESS OF NEW ENTRY IN CORE IF BLDC                   * 22740001
*        GR8 - ABSOLUTE ADDRESS OF NEW OR CURRENT ENTRY               * 22800001
*        GR9 - ADDRESS OF TCA.                                        * 22860001
*                                                                     * 22920001
*   PARAMETERS PASSED:                                                * 22980001
*                                                                     * 23040001
*   ON ENTRY - PR0 - ADDRESS OF ENTRY IF BLDC, ELSE ZERO              * 23100001
*              PR1 - ADDRESS OF TCA                                   * 23160001
*                                                                     * 23220001
*   ON EXIT  - PR0 - ABSOLUTE ADDRESS OF NEW ENTRY.                   * 23280001
*             PR1 - ADDRESS OF S.A. FIELD IN PRG                      * 23340001
*                                                                     * 23400001
*   RETURN CODE:  NONE.                                               * 23460001
*                                                                     * 23520001
*   FAILS:  THE ONLY FAIL OCCURS WHEN THE BLOCK LIST TABLE BECOMES    * 23580001
*           FULL AND A NEW BLOCK IS TO BE ADDED TO A TABLE. THE       * 23640001
*           FAIL MAY BE OVERCOME BY INCREASING THE SIZE OF THE        * 23700001
*           BLOCK LIST TABLE. A FAIL MAY ALSO OCCUR IN MODULE KAHLOK. * 23760001
*                                                                     * 23820001
*********************************************************************** 23880001
         SPACE 2                                                        23940001
KAHBLD   IEMKENT  TYPE=1                                                24000001
*                                                                     * 24060001
         USING XBLE,GR6                                                 24120001
         USING YBLE,GR5                                                 24180001
*                                                                       24240001
         LR    GR9,PR1             BASE XTCA DSECT                      24300001
         L     GR6,XTCAETBL        BASE XBLE DSECT                      24360001
         SPACE                                                          24420001
*                                                                     * 24480001
         LR    GR7,PR0             SAVE BLDC ENTRY ADDRESS              24540001
*                                                                     * 24600001
*  DETERMINE LENGTH OF ENTRY. IF ENTRIES ARE FIXED LENGTH, THE LENGTH * 24660001
*  IS OBTAINED FROM XTCAENTL. OTHERWISE IT IS OBTAINED FROM THE ENTRY * 24740001
*  SKELETON ITSELF.                                                   * 24820001
*                                                                     * 24900001
         TM    XTCACODE,XTCAFIXL   TEST IF FIXED LENGTH                 24960001
         BO    HBLDLDLN            BRANCH IF SO                         25020001
         MVC   XTHRWORK(2),0(GR7)  ALIGN LENGTH FIELD OF ENTRY          25120001
         LH    GR2,XTHRWORK        LOAD LENGTH                          25260001
         B     HBLDTNUL            SKIP FIXED LENGTH LOAD               25320001
         SPACE                                                          25380001
HBLDLDLN LH    GR2,XTCAENTL        LOAD LENGTH OF ENTRY INTO GR2        25440001
         SPACE                                                          25500001
HBLDTNUL TM    XTCACODE,XTCANULL   IF NULL TABLE,                       25560001
         BO    HBLDGNTB              GO TO ROUTINE TO GET NEW TEXT BLCK 25620001
         SPACE                                                          25680001
         TM    XTCAETCD,XPRGLOCK   TEST IF CURRENT ENTRY LOCKED         25740001
         BO    HBLDUPDT            BRANCH IF SO                         25800001
         LA    PR1,XTCAETAA        LOAD PRG ADDRESS FOR KAHLOK          25860001
         BAL   RR,KAHLOK           CALL KAHLOK TO LOCK CURRENT ENTRY    25920001
         MVC   PAR1+1(3),XTCAETSA  MOVE S.A. TO PAR1                    25980001
         MVI   PAR1,X'80'          INDICATE NO STATUS CHANGE            26040001
         L     LR,ZTXTAB           CALL ZTXTAB                          26100001
         BALR  RR,LR                 TO CONVERT S.A. TO ABSOLUTE        26160001
         MVC   XTCAETAA+1(3),PAR1+1 STORE ABSOLUTE ADDRESS              26220001
         SPACE                                                          26280001
*                                                                     * 26340001
*  UPDATE CREATION POINTER WITH LENGTH OF LAST ENTRY MADE AND         * 26400001
*  DETERMINE WHETHER SUFFICIENT SPACE EXISTS IN CURRENT TEXT BLOCK    * 26460001
*  TO ADD A NEW ENTRY. IF INSUFFICIENT SPACE GO TO ROUTINE TO GET     * 26520001
*  NEW TEXT BLOCK.                                                    * 26580001
*                                                                     * 26640001
HBLDUPDT L     GR3,XTCAETAA        LOAD ABSOLUTE ADDRESS                26700001
         AH    GR3,XTCALLEN        ADD LAST ENTRY'S LENGTH              26760001
         ST    GR3,XTCAETAA        STORE UPDATED ADDRESS                26820001
         LH    GR3,XTCAETSA+1      LOAD TEXT REF. DISPLACEMENT          26880001
         AH    GR3,XTCALLEN        ADD LENGTH                           26940001
         STH   GR3,XTCAETSA+1      STORE UPDATED DISPLACEMENT           27000001
         AR    GR3,GR2             ADD LENGTH OF NEW ENTRY              27060001
         C     GR3,TXTSZ           COMPARE SUM WITH TEXT BLOCK SIZE     27120001
         BH    HBLDULPE              IF HIGH GO TO GET NEW TEXT BLOCK   27180001
         SPACE                                                          27240001
         MVC   XBLEDLEN,XTCAETSA+1 UPDATE BLE END OF TABLE POINTER      27300001
         SPACE                                                          27360001
*                                                                     * 27420001
*  TEST WHETHER OPERATION WAS BLDC. IF SO, MOVE ENTRY INTO BLOCK.     * 27480001
*                                                                     * 27540001
HBLDTBDC L     GR8,XTCAETAA        LOAD ADDRESS OF NEW ENTRY            27600001
         LTR   GR7,GR7             TEST IF BLDT                         27660001
         BZ    HBLDSTOL            BRANCH IF SO                         27720001
         LR    GR3,GR2             FORM LENGTH-1                        27780001
         BCTR  GR3,0                 FOR MVC                            27840001
         EX    GR3,HBLDMVCI        EXECUTE MOVE TO MOVE ENTRY TO BLOCK  27900001
         SPACE                                                          27960001
HBLDSTOL STH   GR2,XTCALLEN        SAVE LENGTH FOR UPDATING NEXT TIME   28020001
         LR    PR0,GR8             LOAD RETURN PARAMETER REGISTER       28080001
         LA    PR1,XTCAETSA        LOAD RETURN PARAMETER REGISTER       28140001
         B     HBLDEXIT            EXIT                                 28200001
         SPACE                                                          28260001
*                                                                     * 28320001
*  ROUTINE TO ADD A NEW BLOCK TO THE TABLE. THIS ROUTINE IS ENTERED   * 28380001
*  AT HBLDULPE IF THE TABLE ALREADY HAS ENTRIES AND AT HBLDGNTB IF    * 28440001
*  THE TABLE IS NULL. A NEW BLOCK IS OBTAINED FROM COMPILER CONTROL   * 28500001
*  AND AN ENTRY FOR THE BLOCK ADDED TO THE BLOCK LIST FOR THE TABLE.  * 28560001
*  THE CREATION POINTER IS UPDATED TO REFERENCE THE NEW BLOCK. FOR A  * 28620001
*  NULL TABLE THE START OF TABLE POINTER IS UPDATED TO SHOW THE START * 28680001
*  OF THE TABLE AND THE TABLE IS MARKED NON-NULL.                     * 28740001
*                                                                     * 28800001
HBLDULPE LA    PR1,XTCAETAA        LOAD ADDRESS OF PRG FOR KAHULK       28860001
         BAL   RR,KAHULK           CALL KAHULK TO UNLOCK ENTRY          28920001
         SPACE                                                          28980001
HBLDGNTB MVI   PAR2+3,X'00'        INDICATE NO CHAINING                 29040001
         L     LR,ZUTXTC           CALL ZUTXTC                          29100001
         BALR  RR,LR                 TO GET TEXT BLOCK                  29160001
         MVC   XTCAETSA,PAR1+1     STORE TEXT REF.                      29220001
         MVC   XTCAETAA+1(3),PAR2+1  AND ABSOLUTE ADDRESS OF NEW BLOCK  29280001
         SPACE                                                          29340001
*                                                                     * 29400001
*  ADD NEW ENTRY TO BLOCK LIST                                        * 29460001
*                                                                     * 29520001
         CLI   XTHRAFFE+1,X'FF'    TEST IF BLOCK LIST TABLE FULL        29580001
         BNE   HBLDGNFE            BRANCH IF NOT                        29640001
         XC    PAR5(5),PAR5        CLEAR PAR5                           29660001
         MVC   PAR6+1(3),=X'0F0600'   MOVE MESSAGE NUMBER TO PAR6       29680001
         L     LR,ZUERR            CALL ZUERR                           29700001
         BALR  RR,LR                 TO INSERT MESSAGE IN DICTIONARY    29720001
         L     LR,ZABORT           CALL ZABORT                          29740001
         BR    LR                    TO TERMINATE COMPILATION           29760001
         SPACE                                                          29820001
HBLDGNFE L     GR5,XTHRAFFE        BASE YBLE FOR FIRST FREE BLT ENTRY   29880001
         MVC   XTHRAFFE+1(3),YBLEANLE UPDATE NEXT FREE ENTRY POINTER    29940001
         XC    YBLEANLE,YBLEANLE   CLEAR POINTER TO NEXT ENTRY          30000001
         MVC   YBLEBLKN,XTCAETSA   MOVE BLOCK NUMBER                    30060001
         MVC   YBLEDFEN,XTCAETSA+1   AND DISPLACEMENTS                  30120001
         MVC   YBLEDLEN,XTCAETSA+1   TO NEW LIST ENTRY                  30180001
         MVI   YBLELCNT,X'0C'      SET LOCK COUNT FIELD TO ZERO         30210001
         SPACE                                                          30240001
         TM    XTCACODE,XTCANULL   TEST IF NULL TABLE                   30300001
         BO    HBLDNULT            BRANCH IF SO                         30360001
         MVC   YBLEAPLE,XTCAETBL+1 SET BACKWARDS CHAIN                  30420001
         ST    GR5,XTCAETBL        UPDATE BLE POINTER IN TCA            30480001
         MVC   XBLEANLE,XTCAETBL+1 SET FORWARD CHAIN IN PREVIOUS BLE    30540001
         B     HBLDLOCK            GO TO LOCK/UNLOCK ENTRY              30600001
         SPACE                                                          30660001
HBLDNULT ST    GR5,XTCAETBL        UPDATE BLE POINTER IN TCA            30720001
         XC    YBLEAPLE,YBLEAPLE   CLEAR BACKWARDS CHAIN                30780001
         SPACE                                                          30840001
         MVC   XTCASTBL(8),XTCAETBL INITIALIZE START OF TABLE POINTER   30900001
         MVI   XTCASTCD,X'0'       CLEAR CODE BYTE                      30960001
         SPACE                                                          31020001
         XI    XTCACODE,XTCANULL   TURN OFF NULL TABLE BIT              31080001
         SPACE                                                          31140001
HBLDLOCK LA    PR1,XTCAETAA        LOAD PRG ADDRESS FOR KAHLOK          31200001
         BAL   RR,KAHLOK           CALL KAHLOK TO LOCK ENTRY            31260001
         B     HBLDTBDC            RETURN TO MAINLINE                   31320001
         SPACE                                                          31380001
*                                                                       31440001
HBLDMVCI MVC   0(0,GR8),0(GR7)     MVC FOR EXECUTE                      31500001
*                                                                       31560001
HBLDEXIT IEMKLVE  NORC                                                  31620001
         DROP  GR5,GR6                                                  31680001
         EJECT                                                          31740001
*********************************************************************** 31800001
*                                                                     * 31860001
* ROUTINE KAHMDR. (HANDLES DR OPERATION).                             * 31920001
*                                                                     * 31980001
*   THIS ROUTINE RETURNS THE ABSOLUTE ADDRESS OF AN ENTRY IDENTIFIED  * 32040001
*   BY A SYMBOLIC ADDRESS SUPPLIED BY THE CALLER. IF LOCK IS          * 32100001
*   SPECIFIED, ANY CURRENT LOCKED DIRECT REFERENCE IS UNLOCKED AND    * 32160001
*   THE NEW ENTRY IS LOCKED.                                          * 32220001
*                                                                     * 32280001
*   REGISTER USAGE:                                                   * 32340001
*                                                                     * 32400001
*        GR6 - ADDRESS OF DIRECT REFERENCE POINTER                    * 32460001
*        GR7 - ADDRESS OF SYMBOLIC ADDRESS                            * 32520001
*        GR8 - ADDRESS OF BLOCK LIST ENTRY                            * 32580001
*        GR9 - ADDRESS OF TCA                                         * 32640001
*                                                                     * 32700001
*   PARAMETERS PASSED:                                                * 32760001
*                                                                     * 32820001
*   ON ENTRY - PR0 - ADDRESS OF SYMBOLIC ADDRESS                      * 32880001
*              PR1 - ADDRESS OF TCA                                   * 32940001
*                                                                     * 33000001
*   ON EXIT  - PR0 - ABSOLUTE ADDRESS OF ENTRY                        * 33060001
*                                                                     * 33120001
*   RETURN CODE:  NONE                                                * 33180001
*                                                                     * 33240001
*   FAILS:  THE ROUTINE WILL FAIL IF LOCK IS SPECIFIED AND FOUR       * 33300001
*           LOCKED ENTRIES ALREADY EXIST IN THE SYSTEM.               * 33360001
*           A FAIL WILL OCCUR IF THE REFERENCED TABLE IS NULL, OR     * 33420001
*           IF THE SUPPLIED SYMBOLIC ADDRESS SPECIFIES A BLOCK NOT    * 33480001
*           IN THE TABLE.                                             * 33540001
*                                                                     * 33600001
*********************************************************************** 33660001
         SPACE 2                                                        33720001
KAHMDR   IEMKENT  TYPE=1                                                33780001
*                                                                     * 33840001
         USING XBLE,GR8                                                 33900001
         USING XPRG,GR6                                                 33960001
*                                                                     * 34020001
         LR    GR9,PR1             BASE XTCA DSECT                      34080001
         LR    GR7,PR0             SAVE ADDRESS OF SA                   34140001
         LA    GR6,XTCAPTRS        BASE XPRG DSECT                      34200001
         SPACE                                                          34260001
*                                                                     * 34620001
*  THIS ROUTINE SCANS THE BLOCK LIST TO DETERMINE WHETHER ANY ENTRY   * 34680001
*  HAS THE SAME BLOCK NUMBER AS THE SUPPLIED SYMBOLIC ADDRESS. IF     * 34740001
*  NO SUCH ENTRY IS FOUND, THE ROUTINE FAILS.                         * 34800001
*                                                                     * 34860001
HMDRTSAD L     GR8,XTCASTBL        GET FIRST BLOCK LIST ENTRY           34920001
         SPACE                                                          34980001
HMDRTBLP CLC   XBLEBLKN,0(GR7)     TEST IF SAME BLOCK NO. AS SA         35040001
         BE    HMDRFOUN            EXIT FROM LOOP IF SO                 35100001
         L     GR8,XBLEANLE-1      LOAD CHAIN TO NEXT ENTRY             35280001
         B     HMDRTBLP            LOOP TO TRY NEXT ENTRY               35340001
         SPACE                                                          35400001
*                                                                     * 35640001
*  THE FOLLOWING ROUTINE CONVERTS THE SUPPLIED SYMBOLIC ADDRESS TO    * 35700001
*  ABSOLUTE. IF NO LOCK IS SPECIFIED THE ROUTINE THEN EXITS.          * 35760001
*  OTHERWISE, IF A CURRENT LOCKED ENTRY EXISTS IT IS UNLOCKED BY      * 35820001
*  KAHULK. THE NEW REFERENCE IS THEN LOCKED AND THE DIRECT REFERENCE  * 35880001
*  POINTER UPDATED.                                                   * 35940001
*                                                                     * 36000001
HMDRFOUN MVC   PAR1+1(3),0(GR7)    MOVE SYMBOLIC ADDRESS TO PAR1        36060001
         MVI   PAR1,X'80'          INDICATE NO STATUS CHANGE            36120001
         L     LR,ZTXTAB           CALL ZTXTAB                          36180001
         BALR  RR,LR                 TO CONVERT TO ABSOLUTE             36240001
         MVC   XPRGAATE+1(3),PAR1+1 STORE ABSOLUTE ADDRESS              36300001
         SPACE                                                          36360001
         TM    XPRGCODE,XPRGTOLK   TEST IF ENTRY TO BE LOCKED           36420001
         BZ    HMDREXIT            EXIT IF NOT                          36480001
         TM    XPRGCODE,XPRGLOCK   TEST IF A CURRENT LOCKED ENTRY       36540001
         BO    HMDRUNLK            BRANCH IF SO                         36600001
         CP    XTHRLCNT,=P'4'      TEST IF FOUR LOCKED ENTRIES ALREADY  36660001
         BNE   HMDRULCT            BRANCH IF NOT                        36720001
         LA    PR1,4               LOAD ERROR NUMBER                    36780001
         B     KAHERR              CALL ERROR HANDLER                   36840001
         SPACE                                                          36900001
HMDRULCT AP    XTHRLCNT,=P'1'      ADD 1 TO LOCK COUNT                  36960001
         SPACE                                                          37080001
HMDRMNBB MVC   PAR1+1(3),0(GR7)    MOVE S.A. TO PAR1                    37140001
         MVI   PAR1,X'00'          CLEAR H.O. BYTE                      37200001
         MVI   PAR2+3,X'04'        INDICATE BUSY                        37260001
         L     LR,ZALTER           CALL ZALTER                          37320001
         BALR  RR,LR                 TO MARK BLOCK BUSY                 37380001
         AP    XBLELCNT,=P'1'      ADD 1 TO BEL LOCK COUNT              37440001
         OI    XPRGCODE,XPRGLOCK   INDICATE LOCKED ENTRY                37470001
         SPACE                                                          37500001
HMDRUDRP MVC   XPRGSATE,0(GR7)     MOVE S.A. TO D.R. POINTER            37560001
         ST    GR8,XPRGABLE        STORE ADDRESS OF BLE                 37620001
         B     HMDREXIT            EXIT                                 37680001
         SPACE                                                          37740001
HMDRUNLK L     GR4,XPRGABLE        LOAD ADDRESS OF CURRENT BLE          37800001
         CLC   0(1,GR7),XBLEBLKN-XBLE(GR4) TEST IF SAME BLOCK NO. AS SA 37860001
         BE    HMDRUDRP            BRANCH IF SO                         37920001
         SPACE                                                          37980001
         LR    PR1,GR6             LOAD ADDRESS OF PRG FOR KAHULK       38040001
         BAL   RR,KAHULK           CALL KAHULK TO UNLOCK CURRENT ENTRY  38100001
         B     HMDRULCT            BRANCH TO MARK NEW BLOCK BUSY        38160001
         SPACE                                                          38220001
*                                                                       38280001
HMDREXIT L     PR0,XPRGAATE        LOAD RETURN PARAMETER REGISTER       38340001
         NI    XPRGCODE,X'FF'-XPRGTOLK  TURN OF 'TO BE LOCKED' BIT      38400001
         IEMKLVE  NORC                                                  38460001
         DROP  GR6,GR8                                                  38520001
         EJECT                                                          38580001
*********************************************************************** 38640001
*                                                                     * 38700001
* ROUTINE KAHUDR. (HANDLES ULDR OPERATION).                           * 38760001
*                                                                     * 38820001
*   THIS ROUTINE CALLS KAHULK TO UNLOCK THE DIRECT REFERENCE POINTER. * 38880001
*   IF THE ENTRY IS NOT LOCKED THE ROUTINE EXITS.                     * 38940001
*                                                                     * 39000001
*   REGISTER USAGE:                                                   * 39060001
*                                                                     * 39120001
*        GR9 - ADDRESS OF TCA                                         * 39180001
*                                                                     * 39240001
*   PARAMETERS PASSED:                                                * 39300001
*                                                                     * 39360001
*   ON ENTRY - PR1 - ADDRESS OF TCA                                   * 39420001
*                                                                     * 39480001
*   ON EXIT - NONE                                                    * 39540001
*                                                                     * 39600001
*   RETURN CODE: NONE                                                 * 39660001
*                                                                     * 39720001
*   FAILS: NONE                                                       * 39780001
*                                                                     * 39840001
*********************************************************************** 39900001
         SPACE 2                                                        39960001
KAHUDR   IEMKENT  TYPE=1                                                40020001
*                                                                       40080001
         LR    GR9,PR1             BASE XTCA DSECT                      40140001
         SPACE                                                          40200001
         LA    PR1,XTCAPTRS        LOAD DR PRG ADDRESS FOR KAHULK       40260001
         BAL   RR,KAHULK           CALL KAHULK TO UNLOCK ENTRY          40320001
         SPACE                                                          40380001
*                                                                       40440001
HUDREXIT IEMKLVE  NORC                                                  40500001
         EJECT                                                          40560001
*********************************************************************** 40620001
*                                                                     * 40680001
* ROUTINE KAHSET. (HANDLES SET/SETZ OPERATIONS).                      * 40740001
*                                                                     * 40800001
*   THIS ROUTINE POSITIONS A SCAN TO THE START OR END OF A TABLE      * 40860001
*   FOR SETZ OR TO AN ENTRY IDENTIFIED BY A SYMBOLIC ADDRESS          * 40920001
*   SUPPLIED BY THE CALLER FOR SET. IF A CURRENT LOCKED ENTRY EXISTS  * 40980001
*   IT IS UNLOCKED. FOR SET THE SUPPLIED SYMBOLIC ADDRESS IS CHECKED  * 41040001
*   TO ENSURE THAT IT REFERS TO A BLOCK WITHIN THE TABLE. THE POINTER * 41100001
*   IS IDENTIFIED BY THE XTCACPTR FIELD. THE TYPE OF OPERATION        * 41160001
*   IS DETERMINED FROM THE CONTENTS OF PR0. THE                       * 41220001
*   OPTION FOR SETZ IS DETERMINED FROM THE SETTING OF A BIT IN THE    * 41280001
*   XPRGCODE FIELD OF THE POINTER REGION. THIS BIT IS SET BY THE      * 41340001
*   CALLER.                                                           * 41400001
*                                                                     * 41460001
*   REGISTER USAGE:                                                   * 41520001
*                                                                     * 41580001
*        GR6 - ADDRESS OF POINTER REGION                              * 41640001
*        GR7 - ADDRESS OF SYMBOLIC ADDRESS                            * 41700001
*        GR8 - ADDRESS OF BLOCK LIST ENTRY                            * 41760001
*        GR9 - ADDRESS OF TCA                                         * 41820001
*                                                                     * 41880001
*   PARAMETERS PASSED:                                                * 41940001
*                                                                     * 42000001
*   ON ENTRY - PR0 - ADDRESS OF SYMBOLIC ADDRESS IF SET               * 42060001
*              PR1 - ADDRESS OF TCA                                   * 42120001
*                                                                     * 42180001
*   ON EXIT - NONE                                                    * 42240001
*                                                                     * 42300001
*   RETURN CODE:  NONE                                                * 42360001
*                                                                     * 42420001
*   FAILS:  THE ROUTINE WILL FAIL IF THE TABLE IS NULL. FOR SET A     * 42480001
*           FAIL WILL OCCUR IF THE SUPPLIED SYMBOLIC ADDRESS DOES     * 42540001
*           NOT REFER TO A BLOCK WITHIN THE TABLE.                    * 42600001
*                                                                     * 42660001
*********************************************************************** 42720001
         SPACE 2                                                        42780001
KAHSET   IEMKENT  TYPE=1                                                42840001
*                                                                       42900001
         USING XPRG,GR6                                                 42960001
         USING XBLE,GR8                                                 43020001
*                                                                       43080001
         LR    GR9,PR1             BASE XTCA DSECT                      43140001
         LR    GR7,PR0             SAVE S.A. ADDRESS                    43200001
         LH    GR6,0(0,RR)         LOAD DISP. TO PRG                    43300001
         LA    GR6,XTCAPTRS(GR6)   LOAD ADDRESS OF PRG                  43400001
         SPACE                                                          43680001
HSETNNUL NI    XPRGCODE,X'FF'-(XPRGSETD+XPRGSETZ) CLEAR SET/SETZ BITS   43740001
         SPACE                                                          43800001
         LTR   GR7,GR7             TEST IF SETZ                         43860001
         BZ    HSETSETZ            BRANCH IF SO                         43920001
*                                                                     * 43980001
*  THE FOLLOWING ROUTINE SCANS THE BLOCK LIST TO FIND AN ENTRY WITH   * 44040001
*  THE SAME BLOCK NUMBER AS THAT IN THE SUPPLIED SYMBOLIC ADDRESS.    * 44100001
*  IF NO SUCH ENTRY EXISTS, THE ROUTINE FAILS.                        * 44160001
*                                                                     * 44220001
         L     GR8,XTCASTBL        BASE XBLE FOR START OF LIST          44280001
         SPACE                                                          44340001
HSETSLLP CLC   XBLEBLKN,0(GR7)     COMPARE BLOCK NUMBERS                44400001
         BE    HSETFOUN            EXIT FROM LOOP IF EQUAL              44460001
         L     GR8,XBLEANLE-1      LOAD CHAIN TO NEXT ENTRY             44640001
         LA    GR8,0(0,GR8)                                             44670001
         B     HSETSLLP            LOOP TO TRY NEXT ENTRY               44700001
         SPACE                                                          44760001
*                                                                     * 44940001
*  MARK PRG TO INDICATE SET OPERATION, UNLOCK CURRENT ENTRY IF ANY,   * 45000001
*  UPDATE PRG FOR NEW CURRENT ENTRY.                                  * 45060001
*                                                                     * 45120001
         SPACE                                                          45180001
HSETFOUN OI    XPRGCODE,XPRGSETD   INDICATE SET PERFORMED               45240001
         SPACE                                                          45300001
         LR    PR1,GR6             LOAD PRG ADDRESS FOR KAHULK          45360001
         BAL   RR,KAHULK           CALL KAHULK TO UNLOCK CURRENT ENTRY  45420001
         SPACE                                                          45480001
         MVC   XPRGSATE,0(GR7)     STORE NEW SYMBOLIC ADDRESS           45540001
         ST    GR8,XPRGABLE        STORE ADDRESS OF BLOCK LIST ENTRY    45600001
         B     HSETEXIT            EXIT                                 45660001
         SPACE                                                          45720001
*                                                                     * 45780001
*  THIS ROUTINE PROCESSES THE SETZ OPERATION. THE CURRENT ENTRY IS    * 45840001
*  UNLOCKED IF NECESSARY, AND THE PRG IS UPDATED TO POINT TO THE      * 45900001
*  START OR END OF THE TABLE DEPENDING ON THE FORWARDS/BACKWARDS      * 45960001
*  OPTION BIT (XPRGFBOP) IN XPRGCODE.                                 * 46020001
*                                                                     * 46080001
HSETSETZ OI    XPRGCODE,XPRGSETZ   INDICATE SETZ HAS BEEN PERFORMED     46140001
         LR    PR1,GR6             LOAD PRG ADDRESS FOR KAHULK          46200001
         BAL   RR,KAHULK           CALL KAHULK TO UNLOCK CURRENT ENTRY  46260001
         SPACE                                                          46320001
         TM    XPRGCODE,XPRGFBOP   TEST IF BACKWARDS SPECIFIED          46380001
         BO    HSETBACK            BRANCH IF SO                         46440001
         MVC   XPRGABLE,XTCASTBL   MOVE IN ADDRESS OF BLE               46500001
         MVC   XPRGSATE,XTCASTSA   MOVE IN S.A. OF FIRST ENTRY          46560001
         B     HSETEXIT            EXIT                                 46620001
         SPACE                                                          46680001
HSETBACK MVC   XPRGABLE,XTCAETBL   MOVE IN ADDRESS OF BLE               46740001
         MVC   XPRGSATE,XTCAETSA   MOVE IN S.A. OF LAST ENTRY           46800001
         XI    XPRGCODE,XPRGFBOP   TURN OF F/B BIT                      46860001
*                                                                       46920001
HSETEXIT EQU   *                                                        46940001
*                                                                       46960001
** SPECIAL LINKAGE NOT SUPPORTED BY IEMKLVE                             46980001
*                                                                       47000001
         L     SAREG,0(0,SAREG)    RESET SAVE AREA POINTER              47020001
         LM    GR2,GR9,8(SAREG)    RESTORE GENERAL REGISTERS            47040001
         L     RR,4(0,SAREG)       LOAD RETURN POINT                    47060001
         B     2(0,RR)             RETURN                               47080001
         DROP  GR6,GR8                                                  47160001
         EJECT                                                          47220001
*********************************************************************** 47280001
*                                                                     * 47340001
* ROUTINE KAHSCN. (HANDLES SCAN OPERATION).                           * 47400001
*                                                                     * 47460001
*   THIS ROUTINE RETURNS THE ABSOLUTE AND SYMBOLIC ADDRESSES OF THE   * 47520001
*   'NEXT' ENTRY IN THE SPECIFIED TABLE. IF A SET OR SETZ WAS THE     * 47580001
*   LAST OPERATION PERFORMED, THIS IS THE ENTRY POSITIONED AT.        * 47640001
*   OTHERWISE THE FORWARD OR BACKWARD OPTION DETERMINES THE ENTRY.    * 47700001
*   IF THE END OF THE TABLE IS DETECTED                               * 47800001
*   CONTROL WILL BE PASSED TO THE ADDRESS SPECIFIED IN THE ETA        * 48000001
*   PARAMETER OF THE SCAN MACRO-INSTRUCTION.                          * 48060001
*                                                                     * 48120001
*   REGISTER USAGE:                                                   * 48180001
*                                                                     * 48240001
*        GR2 - LENGTH OF CURRENT ENTRY                                * 48300001
*        GR6 - ADDRESS OF BLE                                         * 48360001
*        GR7 - ADDRESS OF PRG                                         * 48420001
*        GR8 - ADDRESS OF ENTRY                                       * 48480001
*        GR9 - ADDRESS OF TCA                                         * 48540001
*                                                                     * 48600001
*   PARAMETERS PASSED:                                                * 48660001
*                                                                     * 48720001
*   ON ENTRY - PR1 - ADDRESS OF TCA                                   * 48780001
*                                                                     * 48840001
*   ON EXIT  - PR0 - ABSOLUTE ADDRESS OF NEXT ENTRY                   * 48900001
*              PR1 - ADDRESS OF S.A. FIELD IN PRG                     * 48960001
*                                                                     * 49020001
*   RETURN CODE:  0 - END OF TABLE                                    * 49080001
*                 4 - ADDRESS OF NEXT ENTRY RETURNED                  * 49140001
*                                                                     * 49200001
*   FAILS: A FAIL WILL OCCUR IF THE CURRENT ENTRY IS NOT LOCKED AND   * 49260001
*          FOUR LOCKED ENTRIES EXIST IN THE SYSTEM.                   * 49360001
*          THE ROUTINE WILL FAIL IF THE SPECIFIED POINTER IS NOT      * 49500001
*          ACTIVE - IE., NO PREVIOUS SET OR SETZ HAS BEEN PERFORMED.  * 49560001
*                                                                     * 49620001
*********************************************************************** 49680001
         SPACE 2                                                        49740001
KAHSCN   IEMKENT TYPE=LL1                                               49800001
*                                                                     * 49860001
         USING XPRG,GR7                                                 49920001
         USING XBLE,GR6                                                 49980001
*                                                                     * 50040001
         LR    GR9,PR1             BASE XTCA DSECT                      50100001
         LH    GR7,0(0,RR)         LOAD DISP. TO PRG                    50180001
         LA    GR7,XTCAPTRS(GR7)   LOAD ADDRESS OF PRG                  50260001
         L     GR6,XPRGABLE        BASE XBLE DSECT FROM PRG             50340001
         SPACE                                                          50400001
HSCNTLOK TM    XPRGCODE,XPRGLOCK   TEST IF CURRENT ENTRY LOCKED         50760001
         BO    HSCNTSET            BRANCH IF SO                         50820001
         BAL   GR3,HSCNLKRT        CALL LOCK SUBROUTINE                 50910001
         MVC   PAR1+1(3),XPRGSATE  MOVE SYMBOLIC ADDRESS TO PAR1        51000001
         MVI   PAR1,X'80'          INDICATE NO STATUS CHANGE            51060001
         L     LR,ZTXTAB           CALL ZTXTAB                          51120001
         BALR  RR,LR                 TO CONVERT S.A. TO ABSOLUTE        51180001
         MVC   XPRGAATE+1(3),PAR1+1 STORE ABSOLUTE ADDRESS              51240001
*                                                                     * 51300001
*  TEST IF SET OR SETZ WAS LAST OPERATION ON THIS POINTER, IF SO PASS * 51360001
*  TO SET/SETZ ROUTINE. OTHERWISE DETERMINE LENGTH OF CURRENT         * 51420001
*  (IE., LAST) ENTRY, AND PASS TO FORWARD OR BACKWARD SCAN ROUTINE    * 51480001
*  AS SPECIFIED BY THE XPRGCODE OPTION BITS.                          * 51540001
*                                                                     * 51600001
HSCNTSET TM    XPRGCODE,XPRGSETD+XPRGSETZ  TEST IF SET OR SETZ          51660001
         BNZ   HSCNHSET            BRANCH IF SO                         51720001
         SPACE                                                          51780001
         TM    XTCACODE,XTCAFIXL   TEST IF FIXED LENGTH ENTRIES         51840001
         BO    HSCNLDLN            BRANCH IF SO                         51900001
         SPACE                                                          51960001
         L     GR3,XPRGAATE        LOAD ADDRESS OF CURRENT ENTRY        52050001
         MVC   XTHRWORK(2),0(GR3)  ALIGN LENGTH FIELD                   52140001
         LH    GR2,XTHRWORK        LOAD LENGTH OF ENTRY                 52200001
         B     HSCNTOPB            SKIP FIXED LENGTH LOAD               52260001
         SPACE                                                          52320001
HSCNLDLN LH    GR2,XTCAENTL        LOAD LENGTH OF ENTRY                 52380001
         SPACE                                                          52440001
HSCNTOPB TM    XPRGCODE,XPRGFBOP   TEST IF OPT=B CODED                  52500001
         BO    HSCNBACK            BRANCH IF SO                         52560001
         SPACE                                                          52620001
*                                                                     * 52680001
*  THE FOLLOWING ROUTINE DETERMINES THE NEXT TABLE ENTRY FOR A        * 52740001
*  FORWARD SCAN. IF THE END OF TABLE IS DETECTED, THE ROUTINE EXITS   * 52800001
*  WITH RC=0. IF THE END OF                                           * 52860001
*  THE CURRENT BLOCK IS ENCOUNTERED, THE NEXT BLOCK IS DETERMINED     * 52920001
*  FROM THE BLOCK LIST. THE ROUTINE EXITS NORMALLY WITH A RETURN CODE * 52980001
*  OF 4.                                                              * 53040001
*                                                                     * 53100001
         CLC   XBLEDLEN,XPRGSATE+1 TEST IF END OF BLOCK                 53160001
         BE    HSCNFEBL            BRANCH IF SO                         53220001
         LH    GR3,XPRGSATE+1      LOAD DISPLACEMENT PART OF S.A.       53280001
         AR    GR3,GR2             ADD LENGTH OF LAST ENTRY             53340001
         STH   GR3,XPRGSATE+1      STORE UPDATED DISPLACEMENT           53400001
         L     GR3,XPRGAATE        LOAD ABSOLUTE ADDRESS                53460001
         AR    GR3,GR2             ADD LENGTH OF LAST ENTRY             53520001
         ST    GR3,XPRGAATE        STORE UPDATED ABSOLUTE ADDRESS       53580001
         B     HSCNSRC4            EXIT                                 53640001
         SPACE                                                          53700001
HSCNFEBL BAL   GR3,HSCNULRT        CALL UNLOCK SUBROUTINE               53790001
         CL    GR6,XTCAETBL        TEST IF END OF TABLE                 53880001
         BNE   HSCNFGNB            BRANCH IF NOT                        53940001
         SPACE                                                          54000001
HSCNTDLE EQU   *                                                        54060001
         SPACE                                                          54120001
HSCNSRC0 SR    RC,RC               SET RETURN CODE TO ZERO              54180001
         LA    PR1,15              LOAD ERROR NUMBER IN CASE NO ETA     54300001
         B     HSCNEXIT            EXIT                                 54360001
         SPACE                                                          54420001
HSCNFGNB L     GR6,XBLEANLE-1      POINT TO NEXT BLE IN BLOCK LIST      54480001
         LA    GR6,0(0,GR6)        CLEAR H.O. BYTE                      54540001
         MVC   XPRGSATE+1(2),XBLEDFEN MOVE DISP. OF 1ST ENTRY TO PRG    54600001
         MVC   XPRGSATE(1),XBLEBLKN MOVE BLOCK NO. TO PRG               54660001
         ST    GR6,XPRGABLE        STORE ADDRESS OF BLE IN PRG          54720001
         BAL   GR3,HSCNLKRT        CALL LOCK SUBROUTINE                 54810001
         MVC   PAR1+1(3),XPRGSATE  MOVE S.A. TO PAR1                    54900001
         MVI   PAR1,X'80'          INDICATE NO STATUS CHANGE            54960001
         L     LR,ZTXTAB           CALL ZTXTAB                          55020001
         BALR  RR,LR                 TO CONVERT S.A. TO ABSOLUTE        55080001
         MVC   XPRGAATE+1(3),PAR1+1 STORE ABSOLUTE ADDRESS              55140001
         B     HSCNSRC4            EXIT                                 55200001
         SPACE                                                          55260001
*                                                                     * 55320001
*  THE FOLLOWING ROUTINE DETERMINES THE NEXT TABLE ENTRY FOR A        * 55380001
*  BACKWARD SCAN. IT IS SIMILAR TO THE FORWARD SCAN ROUTINE.          * 55440001
*                                                                     * 55500001
HSCNBACK NI    XPRGCODE,X'FF'-XPRGFBOP CLEAR OPTION BIT                 55540001
         CLC   XBLEDFEN,XPRGSATE+1 TEST IF END (IE., START) OF BLOCK    55580001
         BE    HSCNBEBL                                                 55620001
         LH    GR3,XPRGSATE+1      LOAD DISP. PART OF S.A.              55680001
         SR    GR3,GR2             SUBTRACT LENGTH OF LAST ENTRY        55740001
         STH   GR3,XPRGSATE+1      STORE UPDATED S.A.                   55800001
         L     GR3,XPRGAATE        LOAD ABSOLUTE ADDRESS                55860001
         SR    GR3,GR2             SUBTRACT LENGTH OF LAST ENTRY        55920001
         ST    GR3,XPRGAATE        STORE UPDATED ABSOLUTE ADDRESS       55980001
         B     HSCNSRC4            EXIT                                 56040001
         SPACE                                                          56100001
HSCNBEBL BAL   GR3,HSCNULRT        CALL UNLOCK SUBROUTINE               56190001
         CL    GR6,XTCASTBL        TEST IF END (START) OF TABLE         56280001
         BE    HSCNTDLE            BRANCH IF SO                         56340001
         SPACE                                                          56400001
         L     GR6,XBLEAPLE-1      POINT TO NEXT BLE IN BLOCK LIST      56460001
         LA    GR6,0(0,GR6)        CLEAR H.O. BYTE                      56520001
         MVC   XPRGSATE+1(2),XBLEDLEN MOVE DISP. OF 1ST ENTRY TO PRG    56580001
         MVC   XPRGSATE(1),XBLEBLKN MOVE BLOCK NO. TO PRG               56640001
         ST    GR6,XPRGABLE        STORE ADDRESS OF BLE IN PRG          56700001
         BAL   GR3,HSCNLKRT             CALL LOCK SUBROUTINE            56790001
         MVC   PAR1+1(3),XPRGSATE  MOVE S.A. TO PAR1                    56880001
         MVI   PAR1,X'80'          INDICATE NO STATUS CHANGE            56940001
         L     LR,ZTXTAB           CALL ZTXTAB                          57000001
         BALR  RR,LR                 TO CONVERT S.A. TO ABSOLUTE        57060001
         MVC   XPRGAATE+1(3),PAR1+1 STORE ABSOLUTE ADDRESS              57120001
         B     HSCNSRC4                                                 57180001
*                                                                     * 57240001
*  THE FOLLOWING ROUTINE  IS ENTERED IF A SET OR SETZ WAS THE LAST    * 57300001
*  OPERATION ON THIS POINTER.                                         * 57360001
*                                                                     * 57420001
HSCNHSET NI    XPRGCODE,X'FF'-(XPRGSETD+XPRGSETZ) CLEAR SET BITS IN PRG 57480001
         SPACE                                                          57540001
*                                                                     * 57600001
*  COMMON EXIT SEQUENCE                                               * 57660001
*                                                                     * 57720001
HSCNSRC4 LA    RC,4                SET RETURN CODE TO 4                 57780001
         L     PR0,XPRGAATE        LOAD RETURN PARAMETER REGISTER       57840001
         LA    PR1,XPRGSATE        LOAD RETURN PARAMETER REGISTER       57900001
         SPACE                                                          57960001
*                                                                       57965001
** SPECIAL EXIT LINKAGE NOT SUPPORTED BY IEMKLVE                        57970001
*                                                                       57975001
HSCNEXIT EQU   *                                                        57980001
         LM    GR2,GR9,8(SAREG)    RESTORE GENERAL REGS.                57985001
         L     RR,4(0,SAREG)       LOAD RETURN POINT                    57990001
         B     2(LR,RR)            RETURN                               57995001
         SPACE                                                          58000001
*                                                                       58005001
** LOCK SUBROUTINE - SIMILAR TO KAHLOK                                  58010001
*                                                                       58015001
HSCNLKRT CP    XTHRLCNT,=PL1'4'    TEST IF FOUR LOCKS ALREADY           58020001
         BNE   HSCNLKRA            BRANCH IF NOT                        58025001
         LA    PR1,9               LOAD ERROR NUMBER                    58030001
         B     KAHERR              CALL ERROR HANDLER                   58035001
         SPACE                                                          58040001
HSCNLKRA AP    XTHRLCNT,=PL1'1'    ADD 1 TO OVERALL LOCK COUNT          58045001
         CP    XBLELCNT,=PL1'0'    TEST IF BLOCK BUSY                   58050001
         BNE   HSCNLKRB            BRANCH IF SO                         58055001
         MVC   PAR1+1(3),XPRGSATE  MOVE SA TO PAR1                      58060001
         MVI   PAR2+3,X'04'        INDICATE BUSY STATUS                 58065001
         L     LR,ZALTER           CALL ZALTER                          58070001
         BALR  RR,LR                 TO MARK BLOCK BUSY                 58075001
         SPACE                                                          58080001
HSCNLKRB AP    XBLELCNT,=PL1'1'    ADD 1 TO BLE LOCK COUNT              58085001
         OI    XPRGCODE,XPRGLOCK   INDICATE ENTRY LOCKED                58090001
         BR    GR3                 RETURN TO MAINLINE                   58095001
         SPACE                                                          58100001
*                                                                       58105001
** UNLOCK SUBROUTINE - SIMILAR TO KAHULK.                               58110001
*                                                                       58115001
HSCNULRT TM    XPRGCODE,XPRGLOCK   TEST IF ENTRY LOCKED                 58120001
         BZ    HSCNULRE            RETURN IF NOT                        58125001
         SPACE                                                          58130001
         SP    XTHRLCNT,=PL1'1'    SUBTRACT 1 FROM OVERALL LOCK COUNT   58135001
         SP    XBLELCNT,=PL1'1'    SUBTRACT 1 FROM BLE LOCK COUNT       58140001
         SPACE                                                          58145001
         CP    XBLELCNT,=PL1'0'    TEST IF NOW NO LOCKS ON THIS BLOCK   58150001
         BNE   HSCNULRA            EXIT IF NOT                          58155001
         MVC   PAR1+1(3),XPRGSATE  MOVE S.A. TO PAR1                    58160001
         MVI   PAR2+3,X'02'        INDICATE UNWANTED STATUS             58165001
         L     LR,ZALTER           CALL ZALTER                          58170001
         BALR  RR,LR                 TO MARK BLOCK UNWANTED             58175001
         SPACE                                                          58180001
HSCNULRA NI    XPRGCODE,X'FF'-XPRGLOCK TURN OFF 'LOCKED' BIT            58185001
*                                                                       58190001
HSCNULRE BR    GR3                 RETURN TO MAINLINE                   58195001
         DROP  GR6,GR7                                                  58200001
         EJECT                                                          58260001
*********************************************************************** 58320001
*                                                                     * 58380001
* ROUTINE KAHDAC. (HANDLE DEACT OPERATION).                           * 58440001
*                                                                     * 58500001
*   THE LIST OF POINTER REGIONS IN THE TCA IS SCANNED AND ANY LOCKED  * 58560001
*   ENTRIES ARE UNLOCKED. ROUTINE KAHULK PERFORMS THE UNLOCKING.      * 58620001
*                                                                     * 58680001
*   REGISTER USAGE:                                                   * 58740001
*                                                                     * 58800001
*        GR8 - ADDRESS OF PRG                                         * 58860001
*        GR9 - ADDRESS OF TCA                                         * 58920001
*                                                                     * 58980001
*   PARAMETERS PASSED:                                                * 59040001
*                                                                     * 59100001
*   ON ENTRY - PR1 - ADDRESS OF TCA                                   * 59160001
*                                                                     * 59220001
*   ON EXIT - NONE                                                    * 59280001
*                                                                     * 59340001
*   RETURN CODE: NONE                                                 * 59400001
*                                                                     * 59460001
*   FAILS: NONE                                                       * 59520001
*                                                                     * 59580001
*********************************************************************** 59640001
    SPACE 2                                                             59700001
KAHDAC   IEMKENT  TYPE=1                                                59760001
*                                                                     * 59820001
         USING XPRG,GR8                                                 59880001
*                                                                     * 59940001
         LR    GR9,PR1             BASE XTCA DSECT                      60000001
         SPACE                                                          60060001
         TM    XTCACODE,XTCANULL   TEST IF NULL TABLE                   60120001
         BO    HDACEXIT            EXIT IF SO                           60180001
         SPACE                                                          60240001
         LA    GR8,XTCAETAA        SET POINTER TO START OF PRG LIST     60300001
         SPACE                                                          60360001
HDACPSLP LR    PR1,GR8             LOAD PRG ADDRESS FOR KAHULK          60420001
         BAL   RR,KAHULK           CALL KAHULK TO UNLOCK ENTRY          60480001
         TM    XPRGCODE,XPRGLPRG   TEST IF LAST PRG                     60540001
         BO    HDACEXIT            EXIT IF SO                           60600001
         LA    GR8,XPRGEND-XPRG(0,GR8) POINT TO NEXT PRG                60660001
         B     HDACPSLP            LOOP TO PROCESS NEXT PRG             60720001
*                                                                     * 60780001
HDACEXIT IEMKLVE  NORC                                                  60840001
         DROP  GR8                                                      60900001
         EJECT                                                          60960001
*********************************************************************** 61020001
*                                                                     * 61080001
* ROUTINE KAHFRE. (HANDLES FREE OPERATION).                           * 61140001
*                                                                     * 61200001
*   THE BLOCK LIST IS SCANNED AND ALL BLOCKS USED BY THE TABLE ARE    * 61260001
*   MARKED FREE. THE BLOCK LIST ENTRIES ARE RETURNED TO THE FREE      * 61320001
*   LIST IN THE BLOCK LIST TABLE. THE TCA IS RE-INITIALIZED AND       * 61380001
*   MARKED NULL.                                                      * 61440001
*                                                                     * 61500001
*   REGISTER USAGE:                                                   * 61560001
*                                                                     * 61620001
*        GR7 - ADDRESS OF BLOCK LIST ENTRY                            * 61680001
*        GR8 - ADDRESS OF PRG                                         * 61740001
*        GR9 - ADDRESS OF TCA                                         * 61800001
*                                                                     * 61860001
*   PARAMETERS PASSED:                                                * 61920001
*                                                                     * 61980001
*   ON ENTRY - PR1 - ADDRESS OF TCA                                   * 62040001
*                                                                     * 62100001
*   ON EXIT - NONE                                                    * 62160001
*                                                                     * 62220001
*   RETURN CODE: NONE                                                 * 62280001
*                                                                     * 62340001
*   FAILS - THE ROUTINE WILL FAIL IF THE TABLE IS NULL.               * 62400001
*                                                                     * 62460001
*********************************************************************** 62520001
         SPACE 2                                                        62580001
KAHFRE   IEMKENT  TYPE=1                                                62640001
*                                                                     * 62700001
         USING XBLE,GR7                                                 62760001
         USING XPRG,GR8                                                 62820001
*                                                                     * 62880001
         LR    GR9,PR1             BASE XTCA DSECT                      62940001
         SPACE                                                          63000001
         TM    XTCACODE,XTCANULL   TEST IF NULL TABLE                   63060001
         BZ    HFRESBLF            BRANCH IF NOT                        63120001
         LA    PR1,7               LOAD ERROR NUMBER                    63180001
         B     KAHERR              CALL ERROR HANDLER                   63240001
         SPACE                                                          63300001
*                                                                     * 63360001
*  THE FOLLOWING ROUTINE SCANS THE BLOCK LIST MARKING ALL BLOCKS USED * 63420001
*  BY THE TABLE FREE. THE BLOCK LIST IS THEN APPENDED TO THE FREE     * 63480001
*  ENTRY LIST WHOSE HEADER IS IN XTHRAFFE.                            * 63540001
*                                                                     * 63600001
HFRESBLF L     GR7,XTCASTBL        LOAD ADDRESS OF FIRST BLE            63660001
         SPACE                                                          63720001
HFREFBLP MVC   PAR1+1(1),XBLEBLKN  MOVE BLOCK NO. TO PAR1               63780001
         XC    PAR1+2(2),PAR1+2    CLEAR DISPLACEMENT FIELD IN PAR1     63840001
         MVI   PAR2+3,X'01'        INDICATE FREE STATUS                 63900001
         L     LR,ZALTER           CALL ZALTER                          63960001
         BALR  RR,LR                 TO FREE BLOCK                      64020001
         C     GR7,XTCAETBL        TEST IF LAST BLE                     64080001
         BE    HFREFLST            BRANCH IF SO                         64140001
         L     GR7,XBLEANLE-1      LOAD CHAIN TO NEXT ENTRY             64200001
         LA    GR7,0(0,GR7)        CLEAR H.O. BYTE                      64260001
         B     HFREFBLP            LOOP TO PROCESS NEXT ENTRY           64320001
         SPACE                                                          64380001
HFREFLST MVC   XBLEANLE,XTHRAFFE+1 ADD BLOCK LIST                       64440001
         MVC   XTHRAFFE+1(3),XTCASTBL+1 TO FREE ENTRY LIST              64500001
         SPACE                                                          64560001
*                                                                     * 64620001
*  THE FOLLOWING ROUTINE REINITIALIZES THE TCA AND MARKS IT NULL.     * 64680001
*  THE LOCK COUNT IN XTHR IS DECREMENTED BY ONE FOR EACH PREVIOUSLY   * 64740001
*  LOCKED ENTRY FOUND IN THE PRG LIST.                                * 64800001
*                                                                     * 64860001
         LA    GR8,XTCAETAA        POINT TO FIRST PRG                   64920001
         SPACE                                                          64980001
HFREIPRG TM    XPRGCODE,XPRGLOCK   TEST IF ENTRY LOCKED                 65040001
         BZ    HFRECCBT            BRANCH IF NOT                        65100001
         SP    XTHRLCNT,=P'1'        ELSE DECREMENT LOCK COUNT          65160001
HFRECCBT NI    XPRGCODE,XPRGLPRG   CLEAR CODE BITS                      65220001
         BNZ   HFREMNUL            BRANCH IF LAST PRG PROCESSED         65280001
         LA    GR8,XPRGEND-XPRG(0,GR8) POINT TO NEXT PRG                65340001
         B     HFREIPRG            LOOP TO PROCESS NEXT PRG             65400001
         SPACE                                                          65460001
HFREMNUL OI    XTCACODE,XTCANULL   MARK TABLE NULL                      65520001
*                                                                     * 65580001
HFREEXIT IEMKLVE  NORC                                                  65640001
         DROP  GR7,GR8                                                  65700001
         EJECT                                                          65760001
*********************************************************************** 65820001
*                                                                     * 65880001
* SUBROUTINE KAHLOK.                                                  * 65940001
*                                                                     * 66000001
*   THIS ROUTINE LOCKS A TABLE ENTRY. THE ENTRY IS IDENTIFIED BY      * 66060001
*   THE ADDRESS OF ITS PRG. IF THE BLOCK CONTAINING THE ENTRY IS      * 66120001
*   NOT BUSY, IT IS MARKED BUSY. LOCK COUNTS IN XTHR AND THE BLE      * 66180001
*   ARE UPDATED.                                                      * 66240001
*                                                                     * 66300001
*   REGISTER USAGE:                                                   * 66360001
*                                                                     * 66420001
*        GR7 - ADDRESS OF BLE                                         * 66480001
*        GR8 - ADDRESS OF PRG                                         * 66540001
*                                                                     * 66600001
*   PARAMETERS PASSED:                                                * 66660001
*                                                                     * 66720001
*   ON ENTRY - PR1 - ADDRESS OF PRG                                   * 66780001
*                                                                     * 66840001
*   ON EXIT - NONE                                                    * 66900001
*                                                                     * 66960001
*   RETURN CODE:  NONE                                                * 67020001
*                                                                     * 67080001
*   FAILS: THE ROUTINE WILL FAIL IF FOUR LOCKED ENTRIES EXIST IN      * 67140001
*          THE SYSTEM.                                                * 67200001
*                                                                     * 67260001
*********************************************************************** 67320001
         SPACE 2                                                        67380001
KAHLOK   IEMKENT  TYPE=LL1                                              67440001
*                                                                     * 67500001
         USING XBLE,GR7                                                 67560001
         USING XPRG,GR8                                                 67620001
*                                                                     * 67680001
         LR    GR8,PR1             BASE XPRG DSECT                      67740001
         L     GR7,XPRGABLE        BASE XBLE DSECT                      67800001
         SPACE                                                          67860001
         CP    XTHRLCNT,=PL1'4'    TEST IF FOUR LOCKS ALREADY           67920001
         BNE   HLOKLOCK            BRANCH IF NOT                        67980001
         LA    PR1,9               LOAD ERROR NUMBER                    68040001
         B     KAHERR              CALL ERROR HANDLER                   68100001
         SPACE                                                          68160001
HLOKLOCK AP    XTHRLCNT,=PL1'1'    ADD 1 TO LOCK COUNT                  68220001
         CP    XBLELCNT,=PL1'0'    TEST IF BLOCK BUSY                   68280001
         BNE   HLOKUBLC            BRANCH IF SO                         68340001
         MVC   PAR1+1(3),XPRGSATE  MOVE S.A. TO PAR1                    68400001
         MVI   PAR2+3,X'04'        INDICATE BUSY STATUS                 68460001
         L     LR,ZALTER           CALL ZALTER                          68520001
         BALR  RR,LR                 TO MARK BLOCK BUSY                 68580001
         SPACE                                                          68640001
HLOKUBLC AP    XBLELCNT,=PL1'1'    ADD 1 TO BLE LOCK COUNT              68700001
         OI    XPRGCODE,XPRGLOCK   INDICATE ENTRY LOCKED                68760001
*                                                                       68820001
HLOKEXIT IEMKLVE  NORC                                                  68880001
         DROP  GR7,GR8                                                  68940001
         EJECT                                                          69000001
*********************************************************************** 69060001
*                                                                     * 69120001
* SUBROUTINE KAHULK.                                                  * 69180001
*                                                                     * 69240001
*   THIS ROUTINE UNLOCKS A TABLE ENTRY. THE ENTRY IS IDENTIFIED BY    * 69300001
*   THE ADDRESS OF ITS PRG. THE XTHR AND BLE LOCK COUNTS ARE          * 69360001
*   DECREMENTED. IF THE BLE LOCK COUNT IS THEN ZERO, THE BLOCK IS     * 69420001
*   MARKED UNWANTED.                                                  * 69480001
*                                                                     * 69540001
*   REGISTER USAGE:                                                   * 69600001
*                                                                     * 69660001
*        GR7 - ADDRESS OF BLE                                         * 69720001
*        GR8 - ADDRESS OF PRG                                         * 69780001
*                                                                     * 69840001
*   PARAMETERS PASSED:                                                * 69900001
*                                                                     * 69960001
*   ON ENTRY - PR1 - ADDRESS OF PRG                                   * 70020001
*                                                                     * 70080001
*   ON EXIT - NONE                                                    * 70140001
*                                                                     * 70200001
*   RETURN CODE: NONE                                                 * 70260001
*                                                                     * 70320001
*   FAILS: NONE                                                       * 70380001
*                                                                     * 70440001
*********************************************************************** 70500001
         SPACE 2                                                        70560001
KAHULK   IEMKENT  TYPE=LL1                                              70620001
*                                                                     * 70680001
         USING XBLE,GR7                                                 70740001
         USING XPRG,GR8                                                 70800001
*                                                                     * 70860001
         LR    GR8,PR1             BASE XPRG DSECT                      70920001
         L     GR7,XPRGABLE        BASE XBLE DSECT                      70980001
         SPACE                                                          71040001
         TM    XPRGCODE,XPRGLOCK   TEST IF ENTRY LOCKED                 71100001
         BZ    HULKEXIT            EXIT IF NOT                          71160001
         SPACE                                                          71220001
         SP    XTHRLCNT,=PL1'1'    SUBTRACT 1 FROM SYSTEM LOCK COUNT    71280001
         SP    XBLELCNT,=PL1'1'    SUBTRACT 1 FROM BLE LOCK COUNT       71340001
         SPACE                                                          71400001
         CP    XBLELCNT,=PL1'0'    TEST IF NO LOCKS ON THIS BLOCK       71460001
         BNE   HULKSLBO            EXIT IF NOT                          71520001
         SPACE                                                          71580001
         MVC   PAR1+1(3),XPRGSATE  MOVE S.A. TO PAR1                    71640001
         MVI   PAR2+3,X'02'        INDICATE UNWANTED STATUS             71700001
         L     LR,ZALTER           CALL ZALTER                          71760001
         BALR  RR,LR                 TO MARK BLOCK UNWANTED             71820001
HULKSLBO NI    XPRGCODE,X'FF'-XPRGLOCK TURN OFF 'LOCKED' BIT            71880001
*                                                                     * 71940001
HULKEXIT IEMKLVE  NORC                                                  72000001
         DROP  GR7,GR8                                                  72060001
         EJECT                                                          72120001
*                                                                     * 75180001
*  SET/SETZ ROUTINE. IF THE CURRENT ENTRY IS BUSY AND THE ADDRESS TO  * 75240001
*  BE POSITIONED AT IS IN A DIFFERENT BLOCK, THE CURRENT BLOCK IS     * 75300001
*  MARKED UNWANTED. THE NEW BLOCK IS MARKED BUSY. THE SYMBOLIC        * 75360001
*  ADDRESS POSITIONED AT IS CONVERTED TO ABSOLUTE AND STORED IN THE   * 75420001
*  'NEXT' POINTER FIELD IN THE TCA.                                   * 75480001
*                                                                     * 75540001
KAHTST   IEMKENT TYPE=LL                                                75560001
         L     GR9,XLCRTXT         BASE XTCA DSECT                      75580001
HTXTSETS TM    XTCATCDE,XTCATLOK   TEST IF ENTRY LOCKED                 75600001
         BO    HTXTSETU            BRANCH IF SO                         75660001
         SPACE                                                          75720001
HTXTSETD LTR   PR0,PR0             TEST IF SETZ (NO S.A. SUPPLIED)      75800001
         BNZ   HTXTSETC            BRANCH IF NOT                        75880001
         MVC   XTCATNSA,STARTX+1   UPDATE S.A. FIELD IN TCA             75960001
         OI    XTCATCDE,XTCATACT   MARK TABLE ACTIVE                    76020001
         B     HTXTEXIT            EXIT                                 76080001
HTXTSETC LR    GR3,PR0             MOVE S.A. ADDRESS TO WORK REGISTER   76140001
         MVC   XTCATNSA,0(GR3)       TO 'NEXT' S.A. FIELD IN TCA        76200001
         OI    XTCATCDE,XTCATACT   MARK TABLE ACTIVE                    76260001
         B     HTXTEXIT            EXIT                                 76380001
         SPACE                                                          76440001
HTXTSETU EQU   *                                                        76500001
         MVC   PAR1+1(3),XTCATCSA  MOVE S.A. TO PAR1                    76560001
         MVI   PAR2+3,X'02'        INDICATE UNWANTED STATUS             76620001
         L     LR,ZALTER           CALL ZALTER                          76680001
         BALR  RR,LR                 TO MARK BLOCK UNWANTED             76740001
         XI    XTCATCDE,XTCATLOK   TURN OFF LOCKED BIT                  76800001
         SP    XTHRLCNT,=PL1'1'    REDUCE SYSTEM LOCK COUNT             76860001
         B     HTXTSETD            RETURN TO MAIN LINE                  76920001
         EJECT                                                          76980001
*                                                                     * 77040001
*  SCAN ROUTINE. IF THE CURRENT BLOCK IS NOT BUSY, THE CURRENT S.A.   * 77100001
*  IS CONVERTED TO ABSOLUTE AND THE BLOCK MARKED BUSY. IF THE EOP     * 77160001
*  TRIPLE IS ENCOUNTERED THE ROUTINE MARKS THE CURRENT BLOCK UNWANTED * 77220001
*  AND EXITS WITH A RETURN CODE OF ZERO. IF AN EOB TRIPLE IS FOUND    * 77280001
*  THE CURRENT BLOCK IS MARKED UNWANTED AND THE NEXT BLOCK IS FOUND   * 77340001
*  BY CALLING ZCHAIN AND THE NEW BLOCK MARKED BUSY. THE 'NEXT'        * 77400001
*  POINTER FIELD IS STORED IN THE 'CURRENT' FIELD AND THE 'NEXT'      * 77460001
*  POINTERS UPDATED TO POINT TO THE NEXT ENTRY. IF A TRANSLATE TABLE  * 77520001
*  HAS BEEN SUPPLIED, THE CODE BYTE IS TRANSLATED AND IF THE RESULT   * 77580001
*  IS ZERO THE SCAN CONTINUES. OTHERWISE THE ROUTINE EXITS WITH A     * 77640001
*  RETURN CODE OF FOUR.                                               * 77700001
*                                                                     * 77760001
KAHTSC   IEMKENT TYPE=LL                                                77830001
         USING XTRP,GR8                                                 77900001
*                                                                       77970001
         L     GR9,XLCRTXT         BASE XTCA DSECT                      78040001
         SPACE                                                          78120001
HTXTSCNA TM    XTCATCDE,XTCATLOK   TEST IF ENTRY LOCKED                 78180001
         BO    HTXTSCNC            BRANCH IF SO                         78240001
         CP    XTHRLCNT,=PL1'4'    TEST IF FOUR LOCKED ENTRIES ALREADY  78300001
         BNE   HTXTSCNB            BRANCH IF NOT                        78360001
         LA    PR1,14              LOAD ERROR NUMBER                    78420001
         B     KAHERR              CALL ERROR HANDLER                   78480001
         SPACE                                                          78540001
HTXTSCNB AP    XTHRLCNT,=PL1'1'    UPDATE SYSTEM LOCK COUNT             78600001
         MVC   PAR1+1(3),XTCATNSA  MOVE S.A. TO PAR1                    78660001
         MVI   PAR1,X'00'          BLOCK TO BE MARKED BUSY              78720001
         L     LR,ZTXTAB           CALL ZTXTAB                          78780001
         BALR  RR,LR                 TO CONVERT S.A. TO ABSOLUTE        78840001
         MVC   XTCATNAA+1(3),PAR1+1 STORE ABSOLUTE ADDRESS              78900001
         OI    XTCATCDE,XTCATLOK   INDICATE ENTRY LOCKED                78960001
         SPACE                                                          79020001
HTXTSCNC L     GR8,XTCATNAA        LOAD ADDRESS OF ENTRY                79080001
         CLI   XTRPCODE,XTRPEOPT   TEST FOR END OF PROGRAM              79140001
         BE    HTXTSCNG            BRANCH IF EOP                        79200001
         CLI   XTRPCODE,XTRPEBLK   TEST FOR END OF BLOCK                79260001
         BE    HTXTSCNF            BRANCH IF EOB                        79320001
         SPACE                                                          79380001
HTXTSCND MVC   XTCATPSA,XTCATCSA   SAVE S.A. OF PREVIOUS ENTRY          79440001
         MVC   XTCATCAA(8),XTCATNAA SAVE CURRENT POINTER                79500001
         LA    GR2,XTRPEND-XTRP(0,GR8) FORM ADDRESS OF NEXT ENTRY       79560001
         ST    GR2,XTCATNAA              AND STORE IT IN 'NEXT' PTR     79620001
         LH    GR2,XTCATNSA+1      LOAD DISP. TO CURRENT ENTRY          79680001
         LA    GR2,XTRPEND-XTRP(0,GR2) UPDATE FOR NEXT ENTRY            79740001
         STH   GR2,XTCATNSA+1            AND STORE IN 'NEXT' PTR        79800001
         LTR   GR0,GR0             TEST IF TRANSLATE TABLE SUPPLIED     79860001
         BZ    HTXTSCNE            BRANCH IF NOT                        79920001
         SR    GR2,GR2             ZEROISE REG. FOR TRT                 79980001
         LR    GR3,GR0             LOAD ADDRESS OF TRANSLATE TABLE      80040001
         TRT   XTRPCODE,0(GR3)     TRANSLATE CODE BYTE                  80100001
         BZ    HTXTSCNC            LOOP IF ZERO RESULT                  80160001
         LR    PR0,GR2             LOAD RETURN PARAMETER REGISTER       80220001
         SPACE                                                          80280001
HTXTSCNE LR    PR1,GR9             LOAD RETURN PARAMETER REGISTER       80340001
         LA    RC,4                LOAD RETURN CODE                     80400001
         B     HTXTSCLV            EXIT                                 80460001
         SPACE                                                          80520001
HTXTSCNF MVC   PAR1+1(3),XTCATNSA  MOVE S.A. TO PAR1                    80580001
         MVI   PAR1,X'00'          INDICATE NEW BLOCK BUSY              80640001
         MVI   PAR2+3,X'02'        INDICATE UNWANTED STATUS             80700001
         L     LR,ZCHAIN           CALL ZCHAIN TO MARK CURRENT BLOCK    80760001
         BALR  RR,LR                 UNWANTED AND GET NEXT BLOCK IN CHN 80820001
         MVC   XTCATNSA,PAR1+1     STORE S.A. OF NEW BLOCK              80880001
         MVC   XTCATNAA+1(3),PAR2+1 STORE A.A. OF NEW BLOCK             80940001
         B     HTXTSCNC            RETURN TO MAIN LINE                  81000001
         SPACE                                                          81060001
HTXTSCNG MVC   PAR1+1(3),XTCATNSA  MOVE S.A. TO PAR1                    81120001
         MVI   PAR2+3,X'02'        INDICATE UNWANTED STATUS             81180001
         L     LR,ZALTER           CALL ZALTER                          81240001
         BALR  RR,LR                 TO MARK BLOCK UNWANTED             81300001
         SP    XTHRLCNT,=PL1'1'    REDUCE SYSTEM LOCK COUNT             81360001
         NI    XTCATCDE,X'FF'-(XTCATLOK+XTCATACT) CLEAR LOCKED AND     -81420001
                                                    ACTIVE STATUS BITS  81480001
         SR    RC,RC               SET RETURN CODE                      81540001
         LA    PR1,16              LOAD ERROR NUMBER IN CASE NO ETA     81600001
*                                                                       81610001
** SPECIAL EXIT LINKAGE NOT SUPPORTED BY IEMKLVE                        81620001
*                                                                       81630001
HTXTSCLV LM    GR2,GR9,8(SAREG)    RESTORE GENERAL REGS.                81640001
         L     RR,4(0,SAREG)       LOAD RETURN REGISTER                 81650001
         B     0(LR,RR)            RETURN                               81660001
         EJECT                                                          81720001
*                                                                     * 81780001
*  DEACT ROUTINE. IF THE CURRENT BLOCK IS BUSY IT IS MARKED UNWANTED  * 81840001
*  AND THE SYSTEM LOCK COUNT IS REDUCED BY ONE.                       * 81900001
*                                                                     * 81960001
KAHTDA   IEMKENT TYPE=LL                                                81980001
         L     GR9,XLCRTXT         BASE XTCA DSECT                      82000001
HTXTDEAC EQU *                                                          82020001
         TM    XTCATCDE,XTCATLOK   TEST IF ENTRY LOCKED                 82080001
         BZ    HTXTEXIT            EXIT IF NOT                          82140001
         MVC   PAR1+1(3),XTCATNSA  MOVE S.A. TO PAR1                    82200001
         MVI   PAR2+3,X'02'        INDICATE UNWANTED STATUS             82260001
         L     LR,ZALTER           CALL ZALTER                          82320001
         BALR  RR,LR                 TO MARK BLOCK UNWANTED             82380001
         SP    XTHRLCNT,=PL1'1'    REDUCE SYSTEM LOCK COUNT             82440001
         XI    XTCATCDE,XTCATLOK                                        82500001
         SPACE                                                          82560001
*                                                                       82620001
HTXTEXIT EQU   *                                                        82680001
         IEMKLVE  RC=(RC)                                               82740001
         DROP  GR8                                                      82800001
         EJECT                                                          82860001
*********************************************************************** 82920001
*                                                                     * 82980001
* ROUTINE KAHERR. (ERROR HANDLER).                                    * 83040001
*                                                                     * 83100001
*   THIS ROUTINE IS CALLED WHEN AN ERROR IS DETECTED IN ANY OF THE    * 83160001
*   OTHER TABLE HANDLING ROUTINES. IT GENERATES AN ERROR MESSAGE AND  * 83220001
*   CALLS THE COMPILER CONTROL ABORT ROUTINE.                         * 83280001
*                                                                     * 83340001
*   REGISTER USAGE: NONE                                              * 83400001
*                                                                     * 83460001
*   PARAMETERS PASSED:                                                * 83520001
*                                                                     * 83580001
*   ON ENTRY - PR1 - ERROR CODE NUMBER                                * 83640001
*                                                                     * 83700001
*********************************************************************** 83760001
         SPACE 2                                                        83820001
KAHERR   IEMKENT  TYPE=3                                                83880001
*                                                                       83940001
         ST    PR1,PAR5            STORE ERROR NUMBER IN PAR5           84000001
         MVC   PAR6+1(3),=X'04C820' MOVE MESSAGE CODE TO PAR6           84060001
         L     LR,ZUERR            CALL ZUERR                           84120001
         BALR  RR,LR                 TO INSERT MESSAGE IN DICTIONARY    84180001
         L     LR,ZABORT           LOAD ADDRESS OF ABORT ROUTINE        84540001
*                                                                       84600001
HERREXIT IEMKLVE  NORC,RP=(LR)     GO TO ABORT ROUTINE                  84660001
         EJECT                                                          84900001
*                                                                     * 84960001
** THE XTHR REGION CONTAINS ALL WORK FIELDS AND CONSTANTS USED       ** 85020001
** BY THE TABLE HANDLING ROUTINES.                                   ** 85080001
*                                                                     * 85140001
KAXTHR   DS    0D                                                       85200001
*                                                                       85260001
XTHRAFFE EQU   XLCRAFFE            ADDRESS OF FIRST FREE ENTRY IN      -85320001
                                     BLOCK LIST TABLE                   85380001
XTHRWORK DC    F'0'                WORK FIELD                           85440001
XTHRLCNT DC    PL1'0'              TOTAL NUMBER OF LOCKED ENTRIES       85500001
*                                                                       85560001
         EJECT                                                          85620001
*                                                                       85680001
*                                                                       85860001
         LTORG                                                          85920001
         END                                                            85980001
