KB       TITLE 'PL/1 (F) COMPILER PHASE KB. K PHASE INITIALISATION.'    01000001
*                                                                       01040001
*                                                                       01080001
* FUNCTIONS        (1)TO GET 4K OF SCRATCH CORE FOR USE BY THE K PHASES 01120001
*                 THIS IS NOT RELEASED UNTIL KO IS COMPLETE JUST BEFORE 01160001
*                  KO RELEASES ITSELF AND KA,AND LOADS KT.              01200001
*                                                                       01240001
*                  (2)TO ALLOCATE A SPACE IN SCRATCH FOR THE REGISTER   01280001
*                  SAVE STACK FOR THE K PHASES.                         01320001
*                                                                       01360001
*                  (3)TO BUILD A BLOCK LIST IN SCRATCH FOR THE TABLE    01400001
*                  HANDLING ROUTINES IN KA.                             01440001
*                                                                       01480001
*                  (4)TO MOVE THE TCA TABLE CONTROL AREAS TO SCRATCH.   01520001
*                  THE IEMKTCA MACROS WHICH DEFINE THE TABLE CONTROL    01560001
*                  AREAS APPEAR IN EVERY PHASE WHICH USES THE TABLE     01600001
*                  HANDLING ROUTINES (BY COPYING IEMKLCR).              01640001
*                  HOWEVER KB IS THE ONLY MODULE IN WHICH THE IEMKTCA   01680001
*                  MACROS ACTUALLY EXPAND INTO A DATA AREA. THE MACRO   01720001
*                  CALLS ARE REQUIRED IN THE OTHER MODULES TO SET       01760001
*                  ASSEMBLE-TIME VARIABLES WHICH AFFECT THE EXPANSION   01800001
*                  OF THE IEMKTAB MACROS IN THOSE MODULES.              01840001
*                                                                       01880001
*                                                                       01920001
*                                                                       01960001
* ENTRY POINT      FROM COMPILER CONTROL TO START OF PHASE IEMKB.       02000001
*                                                                       02040001
*                                                                       02080001
*                                                                       02120001
* EXIT             TO COMPILER CONTROL VIA CALL TO RLSCTL TO LOAD       02160001
*                  NEXT PHASE.                                          02200001
*                                                                       02240001
*                                                                       02280001
*                                                                       02320001
* EXTERNAL ROUTINES (IN CIMPILER CONTROL): ZUGC,RLSCTL.                 02360001
*                                                                       02400001
*                                                                       02440001
*                                                                       02480001
* NOTE             THIS MODULE REQUIRES THE IEMK... MACROS FOR ASSEMBLY 02520001
         EJECT                                                          02560001
EQUD     DSECT                          DUMMY DSACT STATEMENT           02600001
*                                       PREVENTS THE ASSEMBLER GIVING   02640001
*                                       RISE TO A CSECT WITH NAME BLANK 02680001
*                                       ON MEETING THE FIRST EQU        02720001
*                                       STATEMENT                       02760001
*                                                                       02800001
         COPY  IEMKEQU                                                  02840001
         COPY  IEMKUTL                                                  03000001
         COPY  IEMKCOM                                                  04000001
         COPY  IEMKMAP                                                  05000001
         COPY  IEMKUSE                                                  06000001
         COPY  IEMKSRG                                                  07000001
         COPY  IEMKBLE                                                  08000001
         COPY  IEMKLCR                                                  09000001
IEMKB    CSECT                                                          10000001
         DC    C'KB'                                                    11000001
         IEMKPLR KB,KBSTUP,G,DL=KBZZ,LL=0                               11500001
         SPACE 2                                                        12000001
*                                                                     * 13000001
** KBSTUP. THIS MODULE SETS UP THE BLOCK LIST TABLE AND DTCAS USED   ** 14000001
** BY THE TABLE HANDLING ROUTINES IN PHASE KA.                       ** 15000001
*                                                                     * 16000001
KBSTUP   IEMKENT TYPE=2                                                 17000001
         USING XBLE,GR8                                                 18000001
*                                                                       19000001
*                                                                       22000001
         L     GR8,XLCRASCR        LOAD ADDRESS OF SCRATCH CORE         23000001
         LA    GR2,4095(0,GR8)     FORM UPPER LIMIT OF SCRATCH CORE     24000001
         ST    GR2,XLCRUASC        STORE IN XLCR                        25000001
         LA    GR8,4*(SSAVARNO+FSAVARNO*(SAREG-GR2+2))(0,GR8) AND BUMP -26000001
                                             IT PAST SAVE AREA STACK    27000001
*                                                                       28000001
** BUILD BLOCK LIST TABLE                                               29000001
*                                                                       30000001
         ST    GR8,XLCRAFFE        STORE START OF BLOCK LIST TABLE      31000001
         LA    GR2,NOBLKS-1        LOAD LOOP COUNT - NO. OF ENTRIES     32000001
STUPBLST LA    GR3,XBLEEND-XBLE(0,GR8)  LOAD ADDRESS OF NEXT ENTRY      33000001
         ST    GR3,XBLEANLE-1      STORE IN FORWARD CHAIN FIELD         34000001
         MVI   XBLELCNT,X'0C'      SET LOCK COUNT TO ZERO               35000001
         XC    XBLEBLKN(8),XBLEBLKN CLEAR REMAINING FIELDS              36000001
         LR    GR8,GR3             POINT TO NEXT ENTRY                  37000001
         BCT   GR2,STUPBLST        LOOP NOBLKS TIMES                    38000001
         SPACE                                                          39000001
         MVC   XBLELCNT(4),=X'0CFF0000' INDICATE LAST ENTRY             40000001
         LA    GR8,XBLEEND-XBLE(0,GR8)  BUMP PTR PAST FINAL ENTRY       41000001
         SPACE                                                          42000001
*                                                                       43000001
** MOVE DTCAS TO SCRATCH CORE AND SET POINTERS IN XLCR                  44000001
*                                                                       45000001
         LA    GR2,6               LOAD LOOP COUNT - NO. OF TABLES      46000001
         LA    GR3,XLCRTXT         POINT TO FIRST POINTER IN XLCR       47000001
         LA    GR4,STUPMVIT        POINT TO FIRST MVC INSTR. IN TABLE   48000001
STUPMVIL ST    GR8,0(0,GR3)        SET XLCR POINTER                     49000001
         EX    0,0(0,GR4)          MOVE TABLE TO SCRATCH                50000001
         SR    GR5,GR5             UPDATE SCRATCH CORE POINTER          51000001
         IC    GR5,1(0,GR4)          (GR8)  WITH LENGTH TAKEN FROM      52000001
         LA    GR8,1(GR5,GR8)        MVC INSTRUCTION                    53000001
         LA    GR3,4(0,GR3)        UPDATE XLCR PTRS POINTER             54000001
         LA    GR4,6(0,GR4)        POINT TO NEXT MVC INSTRUCTION        55000001
         BCT   GR2,STUPMVIL        LOOP FOR NEXT TABLE                  56000001
         SPACE                                                          57000001
         ST    GR8,XLCRASCR        UPDATE POINTER TO SCRATCH CORE FOR  -58000001
                                     OTHER USERS                        59000001
*                                                                       60000001
STUPEXIT IEMKLVE  NORC                                                  61000001
*                                                                       62000001
STUPMVIT MVC   0(STUPTXTE-STUPTXT,GR8),STUPTXT                          63000001
         MVC   0(STUPMAPE-STUPMAP,GR8),STUPMAP                          64000001
         MVC   0(STUPUSEE-STUPUSE,GR8),STUPUSE                          65000001
         MVC   0(STUPSRGE-STUPSRG,GR8),STUPSRG                          66000001
         MVC   0(STUPSRTE-STUPSRT,GR8),STUPSRT                          67000001
         MVC   0(STUPPCHE-STUPPCH,GR8),STUPPCH                          68000001
*                                                                       69000001
XLCRTXT  IEMKTCA STUPTXT,ET=T                                           70000001
STUPTXTE EQU   *                                                        71000001
XLCRMAP  IEMKTCA STUPMAP,ET=F,L=(XMAPEND-XMAP),OPS=R                    72000001
STUPMAPE EQU   *                                                        73000001
XLCRUSE IEMKTCA STUPUSE,ET=F,L=(XUSEEND-XUSE),OPS=S,NPTRS=2             74000001
STUPUSEE  EQU   *                                                       75000001
XLCRSRG  IEMKTCA STUPSRG,ET=F,L=(XSRGEND-XSRG),OPS=S                    76000001
STUPSRGE EQU   *                                                        77000001
XLCRSRT  IEMKTCA STUPSRT,ET=V,DLF=0,NPTRS=2                             78000001
STUPSRTE EQU   *                                                        79000001
XLCRPCH  IEMKTCA STUPPCH,ET=V,DLF=0                                     80000001
STUPPCHE EQU   *                                                        81000001
*                                                                       82000001
         LTORG                                                          83000001
         END                                                            84000001
