KC       TITLE 'IEMKC, DO SPECIFICATION REORDER, OPTIMISATION, OS/360  C00060001
               PL/1 F COMPILER.'                                        00120001
*                                                                       00121056
*              APARS FIXED IN THIS MODULE                               00122056
*                                                                       00123056
*                                                                       00124056
* 5.4  C 837600-838200.                                       MAC 54703 00124564
* 5.3B A 102000                                           MAC PEP 49708 00125056
*      C 142800                                           MAC PEP 49708 00126056
*                                                                       00127056
*                                                                       00128056
         SPACE 5                                                        00129056
*              FUNCTIONS - (1) SCAN TEXT, LOOKING FOR DO LOOPS AND ON   00130001
*        UNITS.                                                         00140001
*                          (2) EXPRESSIONS ARE ANALYSED AND MOVED OUT   00150001
*        OF DO LOOP SPECIFICATIONS. NESTED LOOPS IN SPECIFICATIONS ARE  00160001
*        UNNESTED.                                                      00170001
*                          (3) TEXT REFERENCES OF ON UNITS ARE INSERTED 00180001
*         IN SUBS/REGION TABLE.                                         00190001
         SPACE 3                                                        00200001
*              ENTRY POINT - 'IEMKC' FROM COMPILER CONTROL TO START     00210001
*        PHASE.                                                         00220001
         SPACE 3                                                        00230001
*              INPUT - TEXT IN FORM OF TRIPLES. DICTIONARY ENTRIES ARE  00240001
*        REQUIRED FOR DATA TYPES FOR DETERMINING THE RESULT TYPES OF    00250001
*        EXPRESSIONS.                                                   00260001
         SPACE 3                                                        00270001
*              OUTPUT - INPUT TEXT IS MODIFIED IN PLACE. TRIPLES FOR    00280001
*        EXPRESSIONS IN DO LOOP SPECIFICATIONS ARE REORDERED, AND       00290001
*        ASSIGNMENTS TO TEMPORARIES ARE INSERTED. DICTIONARY ENTRIES    00300001
*        ARE CREATED FOR TEMPORARIES.                                   00310001
         SPACE 3                                                        00320001
*              EXTERNAL ROUTINES (1) CONTROL PHASE. THE FOLLOWING       00330001
*        ENTRIES ARE USED - 'ZDICRF','ZDRFAB','RLSCTL'.                 00340001
*                                (2) TABLE HANDLING (IEMKA). THE        00350001
*        FOLLOWING ENTRIES ARE USED - 'KAHTXT','KAHBLD','KAHDAC',       00360001
*        'KAHERR'.                                                      00370001
         SPACE 3                                                        00380001
*              EXIT - NORMAL - 'RLSCTL' IN CONTROL PHASE TO RELEASE     00390001
*        PHASE AND LOAD NEXT.                                           00400001
         SPACE 3                                                        00410001
*              EXIT - ERROR (1) 'KAHERR' IF A COMPILER ERROR OCCURS     00420001
*        DURING TEXT SCAN OR TABLE HANDLING. TERMINAL MESSAGE IEM1224I  00430001
*        IS GIVEN.                                                      00440001
*                            (2) 'ERR' IF A COMPILER ERROR IS DETECTED  00450001
*        IN PHASE. TERMINAL MESSAGE IEM3856I (PROGRAM CHECK TYPE 1)     00460001
*        IS GIVEN.                                                      00470001
         SPACE 3                                                        00480001
*              WORKAREA - 3K OF THE SCATCH AREA OBTAINED BY PHASE       00490001
*        IEMKA IS USED.                                                 00500001
         SPACE 3                                                        00510001
*              ATTRIBUTES - THIS BLOCK IS NOT READ-ONLY AND NOT         00520001
*        REENTRANT.                                                     00530001
         SPACE 3                                                        00540001
*              NOTES - (1) THIS PHASE REQUIRES NO MODIFICATION AS A     00550001
*        RESULT OF CHANGES IN THE INTERNAL REPRESENTATION OF EXTERNAL   00560001
*        GRAPHICS.                                                      00570001
*                      (2) THIS PHASE CONTAINS A VERSION OF THE         00580001
*        'EXPRESSION ANALYSER' ROUTINE USED IN PHASES IEMIN AND IEMLH.  00590001
*        ANY CORRECTIONS SHOULD BE CONSIDERED FOR ALL THREE PHASES.     00600001
*                      (3) THIS PHASE REQUIRES THE 'IEMK' MACROS FOR    00610001
*        ASSEMBLY.                                                      00620001
*                      (4) THIS PHASE CONSISTS OF 2 CONTROL SECTIONS    00630001
*        - 'IEMKC' AND 'IEMKC1'.                                        00640001
         EJECT                                                          00960001
IEMKC    START 0                                                        01020001
         PRINT NODATA                                                   01080001
*                       DEFINITIONS OF SYMBOLS                          01140001
         SPACE 1                                                        01200001
         COPY  IEMKEQU                                                  01260001
*        GENERAL PURPOSE REGISTER NAMES AND USE                         01320001
KCBASE   EQU   3                                                        01380001
KC1BASE  EQU   4                                                        01440001
IP       EQU   5                                                        01500001
IPR      EQU   5                                                        01560001
IPTR     EQU   5                                                        01620001
SRGR     EQU   5                                                        01650001
P1       EQU   8                                                        01680001
S        EQU   9                                                        01740001
BR       EQU   15                                                       01800001
TRTR     EQU   2                       SCAN TRT RESULT                  01860001
*              EXPRESSION ANALYSIS ROUTINE REGISTERS                    01920001
DSR      EQU   1                       DESCRIPTION REGISTER             01980001
STR      EQU   2                       STACK REGISTER                   02040001
G0       EQU   0                       WORK REGISTER 0                  02100001
G1       EQU   7                                     1 (ODD)            02160001
GRN      EQU   6                                     2 (EVEN)           02220001
         SPACE 1                                                        02280001
*        BRANCH MNEMONIC DEFINITIONS                                    02340001
B        EQU   15                      BRANCH                           02400001
NOP      EQU   0                       NO-OP                            02460001
         SPACE 1                                                        02520001
BH       EQU   2                       BRANCH ON HIGH                   02580001
BL       EQU   4                                 LOW                    02640001
BE       EQU   8                                 EQUAL                  02700001
BNH      EQU   13                                NOT HIGH               02760001
BNL      EQU   11                                    LOW                02820001
BNE      EQU   7                                     EQUAL              02880001
         SPACE 1                                                        02940001
BO       EQU   1                                 OVERFLOW/ONES          03000001
BP       EQU   2                       BRANCH ON PLUS                   03060001
BM       EQU   4                                 MINUS/MIXED            03120001
BZ       EQU   8                                 ZERO                   03180001
BNO      EQU   14                                    OVERFLOW/ONES      03240001
BNP      EQU   13                                NOT PLUS               03300001
BNM      EQU   11                                    MINUS/MIXED        03360001
BNZ      EQU   7                                     ZERO               03420001
         SPACE 1                                                        03480001
         COPY  IEMKUTL                                                  03540001
         COPY  IEMKCOM                                                  03600001
         COPY  IEMKLCR                                                  03660001
         COPY  IEMKSRG                                                  03690001
         EJECT                                                          03720001
*              WORK AREAS IN SCRATCH.                                   03780001
         SPACE 1                                                        03840001
MAXDO    EQU   20                      MAXIMUM DO NESTING               03900001
STK      EQU   0                       DO STACK                         03960001
MTYPE    EQU   0                                                        04020001
MITDO    EQU   0                                                        04080001
MDLIM    EQU   4                       POINTER TO LAST DELIMITER        04140001
MCVDED   EQU   8                       CV DESCRIPTION                   04180001
STKND    EQU   STK+12*MAXDO                                             04220001
REORLST  EQU   STKND                   REORDER LIST                     04260001
MOVELST  EQU   REORLST+5*3+5*8*MAXDO   MOVE LIST                        04320001
LSTND    EQU   MOVELST+5                                                04380001
ANSTK    EQU   STK+1072                EXPRESSION ANALYSIS STACK        04440001
         SPACE 2                                                        04500001
*              TRIPLE LAYOUT - USUALLY BASED ON IR                      04560001
         SPACE 1                                                        04620001
TPOD1    EQU   1                       1ST OPERAND - 2 BYTES            04680001
TPOD2    EQU   3                       2ND OPERAND - 2 BYTES            04740001
         SPACE 1                                                        04800001
*                       DESCRIPTION ITEM LAYOUT- OFFSETS FROM START     04860001
         SPACE 1                                                        04920001
DESFLG   EQU   0                       FLAG BYTE                        04980001
DESCDE   EQU   1                       CODE BYTE                        05040001
DESP     EQU   2                       PRECISION BYTE                   05100001
DESQ     EQU   3                       SCALE FACTOR BYTE                05160001
         SPACE 1                                                        05220001
*              DICTIONARY ENTRY CODE BYTES                              05280001
         SPACE 1                                                        05340001
DRCON    EQU   X'88'                   CONSTANT                         05400001
DRTEMP   EQU   X'8F'                   SCALAR TEMPORARY                 05460001
DRPICT   EQU   X'C8'                   PICTURE ENTRY                    05520001
         SPACE 1                                                        05580001
*              LAYOUT OF DICTIONARY ENTRY FOR CONSTANT.                 05640001
         SPACE 1                                                        05700001
DCFLG    EQU   0                       FLAG =X'88' FOR CONSTANT         05760001
DCDED1   EQU   5                       APPARENT DED (3 BYTES)           05820001
DCFLAG   EQU   8                       FLAG BYTE                        05880001
DCDED2   EQU   9                       TARGET TYPE                      05940001
DCSN     EQU   12                      STATEMENT NUMBER                 06000001
DCVAL    EQU   14                      VALUE OF CONSTANT                06060001
CONDE    EQU   X'88'                   CONSTANT DICT ENTRY CODE         06120001
         SPACE 1                                                        06180001
*              LAYOUT OF DICT ENTRY FOR VARIABLE                        06240001
         SPACE 1                                                        06300001
DEDATA   EQU   15                                                       06360001
DATCAD   EQU   X'80'                   CAD/STRING BIT                   06420001
DATPIC   EQU   X'08'                   PICTURE BIT                      06480001
DATADJ   EQU   X'40'                   ADJUSTABLE STRING TESTING MASK   06540001
DECHN    EQU   3                       CHAIN SLOT                       06600001
ESLOT1   EQU   10                      OTHER1                           06660001
DEOT2    EQU   12                      OTHER 2                          06720001
OT2CTL   EQU   X'03'                   CONTROLLED BITS                  06780001
OT2FP    EQU   X'08'                   FORMAL PARAMETER                 06840001
DEPICT   EQU   19                      PICTURE REF (SYMBOL SLOT)        06900001
DELC     EQU   25                      LEVEL,COUNT                      06960001
         SPACE 1                                                        07020001
ESN2N    EQU   3                       STATEMENT NUMBER IN SN2 ENTRY    07080001
ESLN     EQU   8                       STATEMENT NUMBER SLOT            07140001
         SPACE 1                                                        07200001
*              LAYOUT OF ENTRY TYPE 1 DICTIONARY ENTRY                  07260001
         SPACE 1                                                        07320001
DE1      EQU   X'C3'                   ENTRY TYPE 1 MASK                07380001
DE1LC    EQU   3                       LEVEL,COUNT IN ENTRY TYPE 1      07440001
ONCDE    EQU   8                       ON CODE BYTE                     07500001
DEAUTO   EQU   11                      HEAD OF AUTO CHAIN IN ET1        07560001
         SPACE 1                                                        07620001
*              LAYOUT OF PICTURE ENTRY                                  07680001
         SPACE 1                                                        07740001
DEPICP   EQU   9                       PRECISION/SCALE IN PICTURE ENTRY 07800001
DEPCRF   EQU   9                       PICTURE REF IN DED/SYMTAB ENTRY  07860001
         SPACE 1                                                        07920001
*              MASKS FOR TESTING DICTIONARY ENTRY CODES.                07980001
         SPACE 1                                                        08040001
VARDE    EQU   X'0F'                   MASK FOR VARIABLE DICT ENTRY     08100001
LABDE    EQU   X'08'                   MASK FOR LABEL DICT ENTRY        08160001
FILDE    EQU   X'04'                   MASK FOR FILE DICT ENTRY         08220001
TSKDE    EQU   X'01'                   MASK FOR TASK DICT ENTRY         08280001
ERRDE    EQU   X'F0'                   ERROR TYPE CODE                  08340001
         SPACE 1                                                        08400001
*              TRANSLATED TRIPLE OPERATION CODES                        08460001
         SPACE 1                                                        08520001
ACT      EQU   X'00'                   ARGUMENT COMBINATION             08580001
ADD      EQU   X'01'                   ADD/SUBTRACT                     08640001
MULT     EQU   X'02'                   MULTIPLY                         08700001
EXPON    EQU   X'04'                   EXPONENTIAL                      08760001
CPR      EQU   X'05'                   COMPARISON                       08820001
CONCAT   EQU   X'21'                   CONCATENATE                      08880001
NOT      EQU   X'33'                   NOT                              08940001
ISTK     EQU   4                       STACK ITEM SIZE                  09000001
PLUSZ    EQU   X'C0'                   PLUS ZONE                        09060001
         SPACE 1                                                        09120001
*              TRIPLE OPERATION CODES                                   09180001
         SPACE 1                                                        09240001
TRUMBR   EQU   X'5E'                   UMBRELLA                         09300001
TRNOP    EQU   X'3F'                   NOP                              09360001
TRASN    EQU   X'47'                   ASSIGN                           09420001
TRDOEQ   EQU   X'61'                   DO EQUALS                        09450001
TRUPCM   EQU   X'64'                   UPSIDE-DOWN COMMA-MULT DO SPEC   09480001
TRTO     EQU   X'80'                   TO                               09540001
TRBY     EQU   X'82'                   BY                               09600001
TRWHYL   EQU   X'84'                   WHILE                            09660001
TRCV     EQU   X'8C'                   CV                               09720001
TRITDO   EQU   X'B7'                   ITDO                             09780001
TRCVP    EQU   X'CC'                   CV'                              09840001
TRSN     EQU   X'D0'                   SN                               09900001
TRSL     EQU   X'D2'                   SL                               09960001
TRCLN2   EQU   X'D3'                   CLN2                             10020001
TRSN2    EQU   X'D4'                   SN2                              10080001
TRITDP   EQU   X'F7'                   ITDO'                            10140001
TRON     EQU   X'FB'                   ON                               10200001
TRCOMA   EQU   X'41'                   COMA                       49708 10230056
         EJECT                                                          10260001
IEMKC    CSECT                                                          10320001
         USING IEMKC1,KC1BASE                                           10390001
         USING XSRG,SRGR                                                10470001
         DC    C'KC'                                                    10500001
         IEMKPLR KC,KCSPEC,BASEREG=KCBASE,DL=KCZZ,LL=0                  10560001
KCSPEC   IEMKENT TYPE=2                                                 10620001
         L     KC1BASE,KC1OFS          SET BASE REGISTER FOR 2ND CSECT  10720001
         L     BR,XLCRASCR             START OF SCRATCH                 10860001
         LA    G1,STK(BR)                                               10920001
         ST    G1,STKZ                                                  10980001
         LA    G1,REORLST-5(BR)                                         11040001
         ST    G1,REORZ                                                 11100001
         LA    G1,MOVELST+5(BR)                                         11160001
         ST    G1,MOVEZ                                                 11220001
         LA    G1,ANSTK(BR)                                             11280001
         BC    B,INITB                                                  11340001
KC1OFS   DC    A(IEMKC1)               ADDRESS OF 2ND CSECT             11400001
         EJECT                                                          11460001
*                            PRIMARY TEXT SCAN.                         11468001
         SPACE 3                                                        11476001
*              FUNCTION - (1) SCAN TEXT UNTIL 'END-OF-PROGRAM' TRIPLE   11484001
*        IS REACHED.                                                    11492001
*                         (2) UPDATE STATEMENT NUMBER SLOT.             11500001
*                         (3) UPDATE THE DICTIONARY REFERENCE OF THE    11508001
*        CURRENT ENTRY TYPE 1.                                          11516001
*                         (4) FOR ON STATEMENTS, SET THE APPROPRIATE    11524001
*        BIT IN THE ONMASK ('XLCRONUS') AND ADD TEXT REFERENCE TO       11532001
*        SUBS/REGION TABLE.                                             11540001
*                         (5) BRANCH TO PROCESSING ROUTINE FOR ITDO     11548001
*        TRIPLES.                                                       11556001
         SPACE 3                                                        11564001
*              ENTRY POINT (1) 'STRT' TO START SCAN.                    11572001
*                          (2) 'NXTRP' TO CONTINUE SCAN AT NEXT TRIPLE. 11580001
         SPACE 3                                                        11588001
*              EXIT - NORMAL (1) 'EOP' AT END OF TEXT.                  11596001
*                            (2) 'DOLOOP' TO PROCESS DO LOOP SPECS.     11604001
         SPACE 3                                                        11612001
*              EXIT - ERROR (1) 'KAHERR' FOR COMPILER ERROR IN TEXT     11620001
*        SCAN.                                                          11628001
*                            (2) 'ERR' FOR COMPILER ERROR DETECTED IN   11636001
*        PHASE. REGISTER 14 ADDRESSES THE POINT OF DETECTION.           11644001
         SPACE 3                                                        11652001
STRT     DS    0H                                                       11680001
       IEMKTAB SETZ,XLCRTXT                                             11720001
NXTRP    DS    0H                                                       11750001
       IEMKTAB SCAN,XLCRTXT,AATO=(IP),SATO=DOREF,TRTAB=T1,ETA=EOP,     X11780001
               FBTO=(TRTR)                                              11820001
         BC    B,*(TRTR)                                                11880001
         BC    B,SL                    STATEMENT LABELS         X'04'   11940001
         BC    B,SN                    STATEMENT NUMBERS        X'08'   12000001
         BC    B,ONBLK                 ON                       X'0C'   12060001
         BC    B,DOLOOP                ITDO                     X'10'   12120001
         BC    B,BLOCK                 PROC,PROC',BEGIN,BEGIN'  X'14'   12180001
         BC    B,SYSTEM                SYSTEM TRIPLE                    12210001
         SPACE 3                                                        12240001
*        PROCESS STATEMENT NUMBER AND LABEL TRIPLES.                    12300001
         SPACE 3                                                        12360001
SN       LA    G1,TPOD2(IP)            POINT AT STATEMENT NUMBER        12420001
         BC    B,SL1                                                    12480001
SL       MVC   PAR1+2(2),TPOD2(IP)     LABEL DICT REF                   12540001
         L     LR,ZDRFAB                                                12600001
         BALR  RR,LR                                                    12660001
         L     LR,PAR1                                                  12720001
         LA    G1,ESN2N(LR)            SN FOR SN2 ENTRY                 12780001
         CLI   0(IP),TRSL              TEST FOR STATEMENT LABEL         12840001
         BC    BNE,SL1                 BRANCH IF SN2 TRIPLE             12900001
         TM    0(LR),DE1               SL. TEST TYPE                    12960001
         BC    BM,NXTRP                BRANCH IF ENTRY TYPE 1           13020001
         LA    G1,ESLN(LR)             SN SLOT                          13080001
         TM    ESLOT1(LR),X'20'        TEST FOR LABEL IN CHECK LIST     13140001
         BC    BZ,SL1                  BRANCH IF NOT                    13200001
         MVC   PAR1+2(2),0(G1)                                          13260001
         L     LR,ZDRFAB                                                13320001
         BALR  RR,LR                                                    13380001
         L     G1,PAR1                 ACCESS CHECK ENTRY               13440001
         LA    G1,ESLN(G1)                                              13500001
SL1      MVC   ZSTAT+2(2),0(G1)        MOVE STATEMENT NUMBER            13560001
         BC    B,NXTRP                                                  13620001
         SPACE 3                                                        13680001
*        RESET CURRENT ENTRY TYPE 1 AT BEGINNING AND END OF BLOCKS.     13740001
         SPACE 3                                                        13800001
BLOCK    MVC   ETYPE1(2),TPOD2(IP)                                      13860001
         BC    B,NXTRP                                                  13920001
         SPACE 3                                                        13930001
*        PROCESS SYSTEM TRIPLE                                          13940001
         SPACE 3                                                        13950001
SYSTEM   IEMKTAB SCAN,XLCRTXT          IGNORE SYSTEM AND SNAP/NOSNAP    13960001
         B     NXTRP                   TRIPLE AND CONTINUE SCAN         13970001
         SPACE 3                                                        13980001
*        PROCESS ON STATEMENTS.                                         14040001
         SPACE 3                                                        14100001
ONBLK    CLC   TPOD2(2,IP),X00FF       TEST FOR BLANK OPERAND OF CHECK  14160001
         BC    BNE,ON1                 BRANCH IF NOT CHECK              14220001
*                                      GET NEXT COMA TRIPLE       49708 14280056
      IEMKTAB SCAN,XLCRTXT,AATO=(IP),SATO=DOREF,ETA=EOP           49708 14290056
         CLI   0(IP),TRCOMA            TEST IF COMA TRIPLE        49708 14300056
         BC    BE,ONBLK                GO TO TEST IF '00FF' OPND  49708 14310056
       IEMKTAB SET,XLCRTXT,SA=DOREF    ELSE RESET SCAN POINTER    49708 14320056
         BC    B,NXTRP                 BACK TO SCAN               49708 14330056
ON1      MVC   PAR1+2(2),TPOD2(IP)     DICT REF OF ON STAT ENTRY        14340001
         L     LR,ZDRFAB                                                14400001
         BALR  RR,LR                                                    14460001
         L     G1,PAR1                 ADDRESS OF ENTRY                 14520001
         CLI   ONCDE(G1),X'D0'         TEST ON CONDITION CODE           14580001
         BC    BNL,ON2                 BRANCH IF VALID CODE             14610001
         BAL   RR,ERR                  BRANCH TO COMPILER ERROR         14640001
ON2      EQU   *                                                        14670001
         SR    TRTR,TRTR                                                14700001
         TRT   ONCDE(1,G1),ONTRT       TRANSLATE ON-CODE                14760001
         L     G1,BIT1                 BIT IN POSITION 1                14820001
         SRL   G1,0(TRTR)              SHIFT TO APPROPRIATE POSITION    14880001
         ST    G1,ONMASK                                                14940001
         OC    XLCRONUS(3),ONMASK      ADD BIT TO OVERALL ON MASK       15000001
         OC    ONMASK(3),ONMASK                                         15005001
         BZ    NXTRP                   BRANCH IF ERROR ON-UNIT          15010001
         SPACE 1                                                        15015001
*        MAKE AN ENTRY IN THE SUBS/REGION LIST CONSISTING OF A CODE     15020001
*        BYTE AND THE TEXT REF OF THE ON-UNIT.                          15025001
         SPACE 1                                                        15030001
         IEMKTAB BLDT,XLCRSRG,AATO=(SRGR) OBTAIN ADDRESS OF ENTRY       15035001
         STC   TRTR,XSRGCODE           MOVE IN CODE BYTE                15040001
         MVC   XSRGTEXT(3),DOREF       MOVE IN TEXT REF                 15045001
         IEMKTAB DEACT,XLCRSRG         DEACTIVATE THE TABLE             15050001
         BC    B,NXTRP                                                  15060001
         SPACE 3                                                        15120001
*              END OF PROGRAM.                                          15180001
         SPACE 3                                                        15240001
EOP      EQU   *                                                        15300001
SPECEXIT IEMKLVE  NORC                                                  15480001
         SPACE 3                                                        15490001
*              COMPILER ERROR. INVOKED BY  BAL RR,ERR                   15500001
         SPACE 1                                                        15510001
ERR      DC    H'0'                                                     15540001
         EJECT                                                          15600001
*                            PROCESS DO LOOPS.                          15601001
         SPACE 3                                                        15602001
*              FUNCTION (1) SCAN TEXT FROM AN 'ITDO' TRIPLE TO ITS      15603001
*        ASSOCIATED CV' TRIPLE, OR A TRIPLE PREVENTING LOOP             15604001
*        OPTIMISATION.                                                  15605001
*                       (2) IF A NESTED ITDO IS ENCOUNTERED, THEN ALL   15606001
*        CURRENT POINTERS ARE STACKED                                   15607001
*                       (3) REPLACE INPUT TEXT WITH REORDERED TRIPLES.  15608001
         SPACE 3                                                        15609001
*              ENTRY POINT - 'DOLOOP' TO SCAN TRIPLES AFTER ITDO.       15610001
*                            'RSCAN' TO STACK CURRENT POINTERS AND      15611001
*        CONTINUE SCAN WHEN NESTED ITDO IS REACHED                      15612001
*                            'CVEND' TO INSERT  THE REORDERED TEXT AT   15613001
*        THE END OF THE DO LOOP SCAN.                                   15614001
         SPACE 3                                                        15615001
*              EXIT - NORMAL - TO 'NXTRP' TO CONTINUE PRIMARY TEXT SCAN 15616001
         SPACE 3                                                        15617001
*              EXTERNAL ROUTINES (1) 'EXANAS','EXANAL' TO ANALYSE       15618001
*        EXPRESSIONS AND INSERT ASSIGNMENTS TO TEMPORARY.               15619001
*                                (2) 'MOVE' TO ADD TRIPLE TO 'MOVE'     15620001
*        LIST.                                                          15621001
*                                (3) 'MOVER' TO ADD TRIPLE TO 'REORDER' 15622001
*        LIST.                                                          15623001
*                                (4) 'MOVET' TO PUT 'REORDER' LIST      15624001
*        BACK IN TEXT.                                                  15625001
         SPACE 3                                                        15626001
*              NOTES - DURING THIS SCAN, TRIPLES ARE SORTED INTO THREE  15627001
*        CATEGORIES - (A) ANY EXPRESSION TRIPLES BETWEEN CV AND DOEQU,  15628001
*        TO AND TO', BY AND BY' ARE PUT INTO THE 'REORDER' LIST. THIS   15629001
*        LIST IS THE FIRST TO REPLACE THE ORIGINAL TEXT. ALL TRIPLES    15630001
*        IN A NESTED DO LOOP ARE PUT IN THE 'REORDER' LIST ALSO.        15631001
*                     (B) ITDO,CV,DOEQU,TO,TO',BY,BY',CV' TRIPLES ARE   15632001
*        PUT IN THE 'MOVE LIST, WHICH IS PUT BACK INTO TEXT AFTER THE   15633001
*        'REORDER' LIST.                                                15634001
*                     (C) IGNORE TRIPLES ARE DISCARDED WHILE SCANNING.  15635001
*        ANY SPACE REMAINING AFTER THE 'REORDER' AND 'MOVE' LISTS HAVE  15636001
*        BEEN PUT BACK INTO TEXT IS FILLED BY IGNORE TRIPLES. THESE     15637001
*        TRIPLES WERE ORIGINALLY GENERATED BY IEMIA TO ALLOW SPACE FOR  15638001
*        INSERTED ASSIGNMENTS TO TEMPORARY VARIABLES.                   15639001
*                      THE TEXT SCAN CONTINES UNTIL THE CV' TRIPLE IS   15640001
*        REACHED UNLESS THE CV IS NOT A SCALAR (CV TRIPLE DOES NOT      15641001
*        IMMEDIATELY FOLLOW ITDO TRIPLE), OR THERE ARE MULTIPLE SPECS   15642001
*        (UP-COMMA TRIPLE), OR THE RESULT OF A SPEC EXPRESSION IS AN    15643001
*        ADJUSTABLE STRING. IN THESE CASE, THE LOOP IS NOT OPTIMISED.   15644001
*                      TRIPLES AFTER THE CV' IN A NESTED LOOP ARE PUT   15645001
*        INTO THE 'REORDER' LIST. ALL TRIPLES IN A NESTED LOOP ARE PUT  15646001
*        INTO THE 'REORDER' LIST IF THE LOOP CANNOT BE OPTIMISED.       15647001
*                      EACH DO LOOP IN NEST HAS FOLLOWING 8 BYTE ENTRY  15648001
*        IN DO-STACK TABLE IN SCRATCH -                                 15649001
*        BYTE 0     'MTYPE'- X'00' FOR REORDER MODE DURING SCAN OF      15650001
*                                      OPTIMISABLE LOOP SPECS.          15651001
*                            X'FF' FOR SKIP MODE AFTER CV' OR UNOPT     15652001
*                                      NESTED LOOP SPEC.                15653001
*        BYTES 1-3  'MITDO' ADDRESS OF ITDO TRIPLE IN 'MOVE' LIST.      15654001
*        BYTES 4-7  'MDLIM' IF BYTE 4 IS X'00',ADDRESS IN 'REORDER'     15655001
*                           LIST OF 1ST TRIPLE IN REORDER EXPRESSION.   15656001
*                           IF BYTE 4 IS X'7F', TEXT REFERENCE OF 1ST   15657001
*                           TRIPLE IN REORDER EXPRESSION.               15658001
         SPACE 3                                                        15659001
DOLOOP   MVC   REORC(4),REORZ          INITIALISE REORDER LIST,         15660001
         MVC   MOVEC(4),MOVEZ                     MOVE LIST,            15720001
         L     S,STKZ                             DO NEST STACK.        15780001
DOLOOP1  BAL   RR,MOVE                 PUT ITDO IN MOVE LIST            15840001
         MVC   MITDO(4,S),MOVEC                                         15900001
         MVI   MTYPE(S),0              SET TO REORDER MODE              15960001
DOLOOP2  DS    0H                                                       16000001
       IEMKTAB SCAN,XLCRTXT,AATO=(IPR),SATO=ANREF   GET NEXT TRIPLE     16040001
         CLI   0(IPR),TRNOP                                             16080001
         BC    BE,DOLOOP2              BRANCH IF IGNORE TRIPLE          16140001
         CLI   0(IPR),TRCV                                              16200001
         BC    BNE,CVEND               NOT CV SO STOP 2ND SCAN          16260001
         LA    STR,TPOD2(IPR)                                           16270001
         LA    DSR,MCVDED(S)                                            16280001
         BAL   RR,DICDES               SET CV DESCRIPTION               16290001
RSCAN3   BAL   RR,MOVE                 PUT IN MOVE LIST                 16320001
         BC    B,EXANAS                IF CV,START EXPRESSION ANALYSIS  16380001
         SPACE 3                                                        16440001
RSCAN2   BAL   RR,MOVER                PUT TRIPLE IN REORDER LIST       16500001
RSCAN    DS    0H                                                       16540001
       IEMKTAB SCAN,XLCRTXT,AATO=(IPR),SATO=ANREF  GET NEXT TRIPLE      16580001
         CLI   MTYPE(S),0                                               16620001
         BC    BE,RSCAN1               BRANCH IF REORDER MODE           16680001
         CLI   0(IPR),TRITDO                                            16740001
         BC    BE,NEST                 BRANCH IF ITDO                   16800001
         CLI   0(IPR),TRITDP                                            16860001
         BC    BNE,RSCAN2               SCAN NEXT TRIPLE IF NOT ITDO'   16920001
         SPACE 3                                                        16980001
*              ITDO' TRIPLE IN SKIP LOOP.                               17040001
         SPACE 3                                                        17100001
UNNEST   SH    S,STKN                  REMOVE DO STACK ENTRY            17160001
         CLI   MTYPE(S),0              TEST ENVIRONMENT OF ITDO         17220001
         BC    BNE,RSCAN2              RETURN TO SKIP LOOP              17280001
         BAL   RR,MOVER                MOVE TRIPLE TO REORDER LIST      17340001
         BC    B,EXANAL               IF REORDER,RETURN TO EXP ANAL     17400001
         SPACE 3                                                        17460001
*              ITDO TRIPLE IN SKIP LOOP.                                17520001
         SPACE 3                                                        17580001
NEST     AH    S,STKN                  BUMP DO STACK POINTER            17640001
         BC    B,DOLOOP1               RESTART SCAN2                    17700001
         SPACE 3                                                        17760001
RSCAN1   CLI   0(IPR),TRTO                                              17860001
         BC    BE,RSCAN3               IF TO,ANALYSE EXPRESSION         17960001
         CLI   0(IPR),TRBY                                              18060001
         BC    BE,RSCAN3               IF BY,ANALYSE EXPRESSION         18160001
*                                      STOP SCAN FOR ANY OTHER TRIPLE   18260001
         SPACE 3                                                        18660001
CVEND    ST    IPR,SIPR                SAVE REORDER SCAN POINTER        18720001
         L     IPR,MITDO(S)            MOVE LIST START FOR THIS ITDO    18780001
         LA    IPR,0(0,IPR)            CLEAR FIRST BYTE                 18840001
CVEND1   BAL   RR,MOVER                MOVE INTO REORDER LIST           18900001
         SH    IPR,H5                                                   18960001
         C     IPR,MOVEC                                                19020001
         BC    BNL,CVEND1              BRANCH IF NOT FINISHED MOVE      19080001
         L     IPR,MITDO(S)                                             19140001
         LA    IPR,5(0,IPR)                                             19200001
         ST    IPR,MOVEC               RESET MOVE LIST POINTER          19260001
         L     IPR,SIPR                RESET REORDER SCAN POINTER       19320001
CVEND3   C     S,STKZ                                                   19380001
         BC    BE,CVEND2               BRANCH IF OUTERMOST DO NEST      19440001
         MVI   MTYPE(S),X'FF'          SET MODE TO SKIP                 19500001
         MVI   REORD,X'FF'             FLAG REORDER                     19560001
         BC    B,RSCAN2                CONTINUE REORDER SCAN            19620001
CVEND2   CLI   REORD,0                                                  19680001
         BC    BE,CVEND5               BRANCH IF NO REORDERING          19740001
         BAL   RR,MOVET                PUT REORDER LIST IN TEXT         19800001
CVEND4   DS    0H                                                       19840001
       IEMKTAB SCAN,XLCRTXT,AATO=(IP),SATO=DOREF  BUMP TEXT POINTER     19880001
         CLC   DOREF(3),ANREF                                           19920001
         BC    BE,CVEND5               BRANCH WHEN SCANS MATCH          19980001
         MVI   0(IP),TRNOP             FILL WITH IGNORE TRIPLE          20040001
         BC    B,CVEND4                                                 20100001
CVEND5   MVI   REORD,0                 STOP REORDER SCAN                20160001
         BC    B,NXTRP                 RETURN TO BASIC SCAN             20220001
         EJECT                                                          20280001
*                            LIST HANDLING ROUTINES.                    20282001
         SPACE 3                                                        20284001
*              FUNCTION (1) ADD TRIPLES TO 'REORDER' AND 'MOVE' LISTS.  20286001
*                       (2) MOVE 'REORDER' LIST BACK INTO TEXT.         20288001
         SPACE 3                                                        20290001
*              ENTRY POINT (1) 'MOVER' TO ADD THE TRIPLE ADDRESSED BY   20292001
*        REGISTER 'IPR' TO THE 'REORDER' LIST.                          20294001
*                          (2) 'MOVE' TO ADD THE TRIPLE ADDRESSED BY    20296001
*        REGISTER 'IPR' TO THE 'MOVE' LIST.                             20298001
*                          (3) 'MOVET' TO MOVE THE 'REORDER' LIST BACK  20300001
*        INTO TEXT.                                                     20302001
         SPACE 3                                                        20304001
*              EXIT - NORMAL - TO CALLING ROUTINE.                      20306001
         SPACE 3                                                        20308001
*              EXIT - ERROR - TO 'ERR' IF COMPILER ERROR DOES NOT ALLOW 20310001
*        SUFFICIENT SPACE IN ORIGINAL TEXT FOR REORDERED TRIPLES.       20312001
         SPACE 3                                                        20314001
*              NOTES - THE LISTS OCCUPY APPROX 800 BYTES OF SCRATCH     20316001
*        CORE. THE AREA STARTS WITH THE 'REORDER' LIST,WORKING          20318001
*        FORWARDS. THE AREA ENDS WITH THE 'MOVE' LIST, WORKING          20320001
*        BACKWARDS. EACH TIME A TRIPLE IS ADDED TO EITHER LIST, THE     20322001
*        LISTS ARE TESTED FOR OVERLAP. IF THIS OCCURS, THE REORDER LIST 20324001
*        IS WRITTEN BACK INTO TEXT. THE 'MOVE' LIST IS LARGE ENOUGH TO  20326001
*        CONTAIN ALL TRIPLES AT THE MAXIMUM DEPTH OF NESTING.           20328001
         SPACE 3                                                        20330001
MOVER    LA    BR,REORC                POINT TO CURRENT REORDER SLOT    20340001
         BC    B,MOV1                                                   20400001
MOVE     LA    BR,MOVEC                POINT TO CURRENT MOVE SLOT       20460001
MOV1     L     P1,0(BR)                CURRENT LIST POSITION            20520001
         AH    P1,4(BR)                                                 20580001
         MVC   MTEMP(4),MOVEC          SAVE MOVE POINTER                20610001
         ST    P1,0(BR)                NEXT LIST POSITION               20640001
         CLC   REORC+1(3),MOVEC+1                                       20700001
         BC    BL,MOV2                 BRANCH IF LISTS DON'T OVERLAP    20760001
         MVI   REORD,X'FF'                                              20820001
         STM   RR,BR,SRR               SAVE REGISTERS                   20880001
         BAL   RR,MOVET                 COPY REORDER LIST TO TEXT       20940001
       IEMKTAB SET,XLCRTXT,SA=ANREF         RESET REORDER SCAN          21000001
       IEMKTAB SCAN,XLCRTXT,AATO=(IPR)                                  21060001
         LM    RR,BR,SRR               RESTORE REGISTERS                21120001
         MVC   MOVEC(4),MTEMP          RESTORE MOVE POINTER             21140001
         BC    B,MOV1                  GO BACK TO MOVE                  21160001
MOV2     MVC   0(5,P1),0(IPR)          PUT TRIPLE IN LIST               21180001
         BCR   B,RR                    RETURN                           21240001
         SPACE 3                                                        21300001
MOVET    L     P1,REORZ                                                 21360001
         ST    RR,SRRT                 SAVE RETURN REGISTER             21420001
*              OBTAIN FIRST DO STACK ITEM WITH A DELIMITER POINTER IN   21480001
*        REORDER LIST.                                                  21540001
         ST    S,STKC                  CURRENT STACK POINTER            21600001
         L     S,STKZ                  OUTER DO ITEM                    21660001
MOV6     C     S,STKC                                                   21720001
         BC    BE,MOV7                 BRANCH IF TOP ITEM OF STACK      21780001
         CLI   MDLIM(S),X'00'                                           21840001
         BC    BE,MOV7             BRANCH IF POINTER IN REORDER LIST    21900001
         AH    S,STKN                                                   21960001
         BC    B,MOV6                                                   22020001
MOV7     EQU   *                                                        22080001
       IEMKTAB SET,XLCRTXT,SA=DOREF                                     22140001
MOV8     EQU   *                                                        22200001
         LA    P1,5(P1)                BUMP REORDER LIST POINTER        22260001
         C     P1,REORC                                                 22320001
         BC    BH,MOV5                 BRANCH IF ALL TRIPLES MOVED      22380001
         CLC   DOREF(3),ANREF                                           22440001
         BC    BNE,MOV3                BRANCH IF NO MATCH               22470001
         BAL   RR,ERR                  COMPILER ERROR IF SCANS MATCH    22500001
MOV3     EQU   *                                                        22530001
       IEMKTAB SCAN,XLCRTXT,AATO=(IP),SATO=DOREF   TEXT POINTER         22560001
MOV4     MVC   0(5,IP),0(P1)           MOVE TRIPLE FROM REORDER LIST    22620001
*                                    BACK INTO TEXT.                    22680001
         C     P1,MDLIM(S)                                              22740001
         BC    BNH,MOV8                BRANCH IF NOT START OF REORDER   22800001
         MVI   MDLIM(S),X'7F'          SET FLAG FOR TEXT REF            22860001
         MVC   MDLIM+1(3,S),DOREF      RESET POINTER TO TEXT REF        22920001
         C     S,STKC                                                   22980001
         BC    BE,MOV8                 BRANCH IF TOP ITEM IN STACK      23040001
         AH    S,STKN                  BUMP TO NEXT ITEM                23100001
         BC    B,MOV8                                                   23160001
MOV5     MVC   REORC(4),REORZ          RESET REORDER LIST POINTER       23220001
         L     RR,SRRT                 RESTORE RETURN REGISTER          23280001
         BCR   B,RR                    RETURN                           23340001
         EJECT                                                          23400001
*                       INITIALIZATION                                  23460001
         SPACE 1                                                        23490001
*              FUNCTIONS - THIS SECTION INITIALISES THE EXPRESSION      23520001
*        EVALUATION STACK. IT IS ENTERED ONCE,AFTER THE INITIALISATION  23550001
*        OF REMAINDER OF PHASE.                                         23580001
*                      (1) 2 512 BYTE BLOCKS OF SCRATCH CORE ARE        23640001
*        OBTAINED FOR RESULT STACKING                                   23700001
*                      (2) STACK POINTERS ARE INITIALIZED.              23760001
*                                                                       23820001
*              ENTRY POINT - INITB.  FROM IEMKC DURING INITIALISATION.  23880001
*                                                                       23940001
*              EXTERNAL ROUTINES - ZUGC.  COMPILER CONTROL ROUTINE      24000001
*        TO OBTAIN SCRATCH CORE.                                        24060001
*                                                                       24120001
*              EXITS - NORMAL - RETURN TO START OF TEXT SCAN.           24180001
*                                                                       24240001
*              EXITS - ERROR - NONE                                     24300001
         SPACE 1                                                        24360001
INITB    ST    G1,BGSTK                BEGINNING OF STACK               24420001
         LA    G1,2*512(0,G1)                                           24480001
         ST    G1,TOPSTK                                                24540001
         L     G1,BGSTK                                                 24600001
         LA    G0,ISTK                                                  24660001
         ST    G1,BSTK                 BOTTOM OF RESULT STACK           24720001
         SR    G1,G0                                                    24780001
         ST    G1,CSTK                 CURRENT TOP OF RESULT STACK      24840001
         L     G1,TOPSTK                                                24900001
         SR    G1,G0                                                    24960001
         ST    G1,TPSTK                SET TOP OF RESULT STACK          25020001
         BC    B,STRT                                                   25080001
         EJECT                                                          25140001
*                       EXPRESSION ANALYSER                             25200001
*              FUNCTIONS - (1) DETERMINES THE TYPE, SCALE, PRECISION    25260001
*        ETC. OF AN EXPRESSION.                                         25320001
*                          (2) IF AN EXPRESSION CONSISTS OF AN          25380001
*        UMBRELLA ONLY, MAKES A DICTIONARY ENTRY FOR A CONSTANT OF      25440001
*        'CONVERTED' TYPE.                                              25500001
*                          (3) RETURNS A DESCRIPTION OF THE RESULT      25560001
*        OF THE EXPRESSION                                              25620001
*                                                                       25680001
*              ENTRY POINTS - (1) EXANAS.  ENTERED AT START OF          25740001
*        EXPRESSION TO CHECK FOR UMBRELLAS.                             25800001
*                             (2) EXANAL.  ENTERED TO RESUME ANALYSIS   25860001
*        AFTER INTERRUPTION BY NESTED LOOP.                             25920001
*                                                                       25980001
*              INPUT - TEXT POINTER ADDRESSES TRIPLE BEFORE THE         26040001
*        EXPRESSION.                                                    26100001
*                                                                       26160001
*              OUTPUT - TEXT POINTER ADDRESSES TRIPLE WHICH TERMINATED  26220001
*        THE EXPRESSION (DOEQU,TO',BY',ITDO ETC.). THE EXPRESSION       26240001
*        TRIPLES ARE PUT IN THE 'REORDER' LIST. THE TRIPLE ASSIGNING    26260001
*        THE RESULT OF THE EXPRESSION TO A TEMPORARY VARIABLE IS PUT    26280001
*        IN THE 'REORDER' LIST. THE DELIMITER TRIPLE (DOEQU,TO',BY')    26300001
*        IS PUT IN THE 'ORDER' LIST.                                    26320001
*                       RESULT CONTAINS ONE OF THE FOLLOWING -          26340001
*        FIRST BYTE     REMAINDER                                       26400001
*          0F           DED OF RESULT TYPE       RESULT IS DATUM        26460001
*          07            -                       LABEL VARIABLE         26520001
*          0B           DICT REF OF CONSTANT     UMBRELLA CONST         26580001
*          OTHER         -                       TASK, EVENT OR ERROR   26640001
*                                                                       26700001
*              EXTERNAL ROUTINES - ZDICRF. COMPILER CONTROL ROUTINE     26760001
*        TO MAKE A DICTIONARY ENTRY.                                    26820001
*                                  ZDRFAB. COMPILER CONTROL ROUTINE     26880001
*        TO CONVERT DICTIONARY REFERENCES TO ABSOLUTE ADDRESSES         26940001
*                                  KAHTXT. KA TABLE HANDLING TO SCAN    26950001
*        TEXT TRIPLES.                                                  26960001
*                                  MOVE. PUT TRIPLES IN 'MOVE' LIST.    26970001
*                                  MOVER. PUT TRIPLES IN 'REORDER'      26980001
*        LIST.                                                          26990001
*                                      MOVET. EMPTY 'REORDER' LIST INTO 27000001
*        TEXT.                                                          27010001
*                                                                       27020001
*              EXITS - NORMAL - RETURN TO PRIMARY TEXT SCAN.            27030001
*                                                                       27120001
*              EXITS - ERROR - NONE                                     27180001
*                                                                       27240001
*              TABLES/WORKAREAS                                         27300001
*                      (1) THE RESULT STACK. THIS IS MAINTAINED         27360001
*        IN THE 1024 BYTE SCRATCH AREA OBTAINED DURING INITIALIZATION.  27420001
*        EACH ENTRY IS FOUR BYTES LONG AND COMPRISES A CODE BYTE AND    27480001
*        A DED. ENTRIES ARE MADE WHEN RESULTS ARE GENERATED BY          27540001
*        ARITMETIC OPERATIONS ETC., AND ARE REMOVED WHEN RESULTS ARE    27600001
*        USED (IMPLIED BY 00 OPERANDS IN CERTAIN TRIPLES)               27660001
*                      (2) THE SCAN TRANSLATE TABLE IS ENTIRELY         27720001
*        SEPARATE FROM THAT USED BY MAIN SCAN. IT RECOGNIZES ALL TRIPLE 27780001
*        WHICH CAN BE INVOLVED IN EXPRESSIONS, TOGETHER WITH RIGHT      27840001
*        ARROW, TO', BY' AND ITDO ON WHICH CONTROL IS RETURNED TO       27900001
*        THE CALLER.                                                    27960001
*                      (3) THE UMBRELLA CONSTANT TABLE IS USED TO KEEP  28020001
*        TRACK OF UP TO 16 CONSTANT ENTRIES MADE FROM UMBRELLA TRIPLES  28080001
*        THE ENTRIES ARE 4 BYTES LONG AND COMPRISE THE DICTIONARY       28140001
*        REFERENCE AND THE VALUE OF THE CONSTANT.                       28200001
*                                                                       28260001
*              NOTES - THE STACKING AND UNSTACKING OF RESULTS IS IN     28320001
*        EFFECT A SIMPLIFIED VERSION OF THAT USED IN PHASE LS.          28380001
*                      THE ROUTINE IS RECURSIVE TO ENABLE NESTED        28440001
*        ENTRIES TO BE MADE IN CASES WHERE EXPRESSIONS INVOLVE          28500001
*        FUNCTIONS WITH ARRAY ARGUMENTS.                                28560001
         SPACE 1                                                        28620001
*              ENTRY FOR START OF EXPRESSION.                           28680001
EXANAS   MVI   LA2+1,TRUMBR            SET UP UMBRELLA TRIPLE TEST      28740001
         MVC   MDLIM(4,S),REORC        START OF REORDER FOR EXPRESSION  28770001
         BC    B,LA1                                                    28800001
         SPACE 1                                                        28860001
*              ENTRY FOR RESUMPTION OF EXPRESSION.                      28920001
EXANAL   MVI   LA2+1,0                 SET UMBRELLA TEST TO TEST FOR    28980001
*                                    INVALID TRIPLE.                    29040001
LA1      ST    RR,WSRR02               SAVE RETURN REGISTER             29100001
         BC    B,LA3                                                    29160001
NEWTRP   BAL   RR,MOVER                MOVE CURRENT TRIPLE TO REORDER   29220001
*                                    LIST.                              29280001
LA3      DS    0H                                                       29320001
       IEMKTAB SCAN,XLCRTXT,AATO=(IPTR),SATO=ANREF     GET NEXT TRIPLE  29360001
         SPACE 1                                                        29400001
LA2      CLI   0(IPTR),0               TEST CURRENT TRIPLE FOR UMBRELLA 29460001
         BC    BE,UMBREL             IF EXANAS ENTRY. BRANCH IF SO.     29520001
         SPACE 2                                                        29580001
         MVI   LA2+1,0                 DISABLE UMBRELLA TEST            29640001
         TRT   0(1,IPTR),SCTRT         TRANSLATE TRIPLE OP CODE         29700001
         BC    BZ,NEWTRP               BRANCH IF TRIPLE NOT RECOGNIZED  29760001
         SPACE 2                                                        29820001
*              EXAMINE TYPE OF TRIPLE AND BRANCH TO APPROPRIATE         29880001
*              PROCESSING CODE.                                         29940001
*                                                                       30000001
         STC   TRTR,OPCOD              TRANSLATED OPERATION CODE        30060001
         TM    OPCOD,X'80'             TEST BIT 0                       30120001
         BC    BZ,LB3                  BRANCH TO RETURN IF NO INTEREST  30180001
         TM    OPCOD,X'40'             TEST BIT 1                       30240001
         BC    BO,LB1                  BRANCH IF NOT EXPRESSION TYPE    30300001
         NI    OPCOD,X'3F'             REMOVE BITS 0,1                  30360001
         BC    B,ARITH                                                  30420001
LB1      N     TRTR,F63                REMOVE BITS 0,1                  30480001
         BC    B,GENBR(TRTR)           GO TO GENERAL BRANCH             30540001
         SPACE 2                                                        30600001
*              GENERAL BRANCHES TO ROUTINE TO PROCESS NON-EXPRESSION    30660001
*              TYPE TRIPLES.                                            30720001
*                                                                       30780001
GENBR    BC    B,SUBSPT       X'C0'    SUBSCRIPT TRIPLE                 30840001
         BC    B,FUNCP3       X'C4'    FUNCTION PRIMED TRIPLE           30900001
         BC    B,LB3                                                 I8 30960001
         BC    B,COMMA3       X'CC'    COMMA TRIPLES                    31020001
         BC    B,DELIM1       X'D0'    TO',BY',RIGHT ARROW,INVERT COMMA 31080001
         BC    B,ASSIGN       X'D4'    ASSIGN,SPECIAL ASSIGN TRIPLES    31140001
         BC    B,NEST         X'DC'    ITDO                             31200001
         BC    B,LB3          X'DC'    FUNCTION                      I8 31260001
         BC    B,UMBR         X'E0'    UMBRELLA TRIPLE                  31320001
         SPACE 2                                                        31380001
*              SUBSCRIPT TRIPLE.                                        31440001
SUBSPT   LA    STR,TPOD1(IPTR)         ADDRESS OF 1ST OPERAND           31500001
         LA    DSR,DEST                                                 31560001
         BAL   RR,DICDES               PUT TYPE IN BUFFER 'DEST'        31620001
LB2      CLI   COMBIN,X'00'                                             31650001
         BC    BNE,TST5                BRANCH IF CV COMBINATION         31680001
         BAL   RR,ADDSTK               ADD RESULT TO STACK              31710001
LB3      EQU   NEWTRP                                                   31740001
         BC    B,NEWTRP                                                 31860001
         SPACE 2                                                        31920001
*              FUNCTION PRIMED TRIPLE.                                  31980001
FUNCP3   BAL   RR,MOVER                MOVE FUNCTION' TO REORDER LIST   32040001
       IEMKTAB SCAN,XLCRTXT,AATO=(IPTR),SATO=ANREF     GET 1ST TRIPLE   32100001
         MVC   DEST+DESCDE(3),2(IPTR)  COPY DESCRIPTION FROM FIRST   I8 32160001
         BAL   RR,MOVER              TMPD. MOVE IT TO REORDER LIST      32220001
       IEMKTAB SCAN,XLCRTXT,AATO=(IPTR),SATO=ANREF     GET 2ND TRIPLE   32280001
*                                      IF PRESENT,COPY PICTURE          32340001
         MVC   PICREF(2),TPOD1(IPTR) FROM SECOND TMPD                   32400001
         MVI   DEST+DESFLG,VARDE                                     I8 32460001
         BC    B,LB2                   GO TO STACK RESULT            I8 32520001
         SPACE 2                                                     I8 32580001
*              ASSIGN TRIPLE                                         I8 32640001
ASSIGN   LA    DSR,RESULT              RELEASE AS MANY RESULTS FROM  I8 32700001
         LA    STR,TPOD2(IPTR)       THE STACK AS THE NUMBER OF 00   I8 32760001
         BAL   RR,DICDES             OPERANDS                        I8 32820001
         LA    STR,TPOD1(IPTR)                                       I8 32880001
         BAL   RR,DICDES                                             I8 32940001
         BC    B,LB3                                                 I8 33000001
         SPACE 2                                                     I8 33060001
*              UMBRELLA TRIPLE OTHER THAN FIRST TRIPLE AFTER ENTRY   I8 33120001
UMBR     MVC   DEST+DESCDE(3),BITST    SET FIXED BINARY TYPE         I8 33180001
         MVI   DEST+DESFLG,VARDE                                     I8 33240001
         BC    B,LB2                   GO TO STACK RESULT               33300001
         SPACE 2                                                        33360001
*              COMMA TRIPLE.                                            33420001
COMMA3   CLC   TPOD2(2,IPTR),CNZERO    TEST FOR 00 SECOND OPERAND       33480001
         BC    BNE,LB3                 BRANCH IF CONTAINS A DICT REF    33540001
         LA    DSR,DEST                                                 33600001
         BAL   RR,RELSTK               RELEASE TOP ITEM FROM STACK      33660001
         BC    B,LB3                                                    33720001
         SPACE 2                                                        33780001
*              UMBRELLA TRIPLE                                          33840001
UMBREL   MVI   RESULT,X'0B'            SET RESULT CODE 0B               33900001
         MVI   RESULT+1,X'10'          SET CONSTANT BIT ON (DOF1CN)     33960001
         TM    3(IPTR),X'80'           TEST FOR -VE.                    34020001
         BC    BZ,LB5                  BRANCH IF +VE.                   34080001
         SPACE 1                                                        34140001
         OI    RESULT+1,X'08'          SET -VE. BIT (DOF1NG)            34200001
*              NOW LOOK TO SEE IF A DICTIONARY ENTRY HAS ALREADY BEEN   34260001
*        MADE FOR THIS CONSTANT                                         34320001
         SPACE 1                                                        34380001
LB5      MVC   DES2(2),3(IPTR)         GET CONSTANT FROM UMBRELLA       34440001
         LH    G0,DES2               TRIPLE AND PLACE IN G0             34500001
         LA    GRN,UMBTAB-4            SET ADDRESS OF BEGINNING AND     34560001
         LA    G1,UMBEND-4           END OF UMBRELLA TABLE, THEN SCAN   34620001
*                                    THROUGH LOOKING FOR THE CURRENT    34680001
LB8      LA    GRN,4(0,GRN)          CONSTANT.                          34740001
         CLI   0(GRN),0                IF THE DICTIONARY REFENCE SLOT   34800001
         BC    BE,LB9                IS EMPTY, USE IT FOR NEW CONST.    34860001
         SPACE 1                                                        34920001
         CH    G0,2(0,GRN)             IF NOT EMPTY SEE IF THE VALUE    34980001
         BC    BE,LB10               OF THE CORRESPONDING CONSTANT IS   35040001
*                                    THE SAME AS THE CURRENT ONE. IF    35100001
*                                    IT IS, GO TO USE SAME DICT REF.    35160001
         CR    GRN,G1                  OTHERWISE SEE IF THIS IS THE     35220001
         BC    BL,LB8                LAST ENTRY IN THE TABLE. GO TO     35280001
*                                    LOOK AT THE NEXT ENTRY IF NOT.     35340001
*                                    OVERWRITE WITH NEW ENTRY IF LAST   35400001
         SPACE 1                                                        35460001
LB9      STH   G0,2(0,GRN)             STORE VALUE IN DES2 AND THE      35520001
         ST    G0,DES2               SELECTED TABLE SLOT THEN PROCEED   35580001
*                                    TO MAKE A DICTIONARY ENTRY FOR THE 35640001
         MVC   UCONST(4),DES2        INTEGER IN ENTRY SKELETON          35700001
         MVC   UCONCH(2),ZCONCH        PLACE CONSTANT CHAIN HEAD IN     35760001
*                                    ENTRY SKELETON                     35820001
         LA    G1,UCONDE                                                35880001
         ST    G1,PAR1                 PAR1 = ADDRESS OF ENTRY          35940001
         LA    G1,UCONND-UCONDE                                         36000001
         ST    G1,PAR2                 PAR2 = LENGTH OF ENTRY           36060001
         L     LR,ZDICRF                                                36120001
         BALR  RR,LR                                                    36180001
         MVC   0(2,GRN),PAR1+2       CONSTANT CHAIN HEAD AND ALSO INTO  36240001
         MVC   ZCONCH(2),PAR1+2        COPY DICT REF OF ENTRY INTO      36300001
*                                    THE SELECTED TABLE SLOT.           36360001
         SPACE 1                                                        36420001
LB10     MVC   RESULT+2(2),0(GRN)      WHETHER A NEW OR OLD ENTRY, COPY 36480001
*                                    DICT REF INTO RESULT FIELD         36540001
         MVI   0(IPTR),TRNOP           NOP UMBRELLA TRIPLE IN CASE      36600001
*                                    NO REORDER.                        36660001
       IEMKTAB SCAN,XLCRTXT,AATO=(IPTR),SATO=ANREF  SKIP UMBRELLA TPL   36720001
         MVC   TPOD2(2,IPTR),RESULT+2  SET CONST DICT REF IN DELIMITER  36780001
         BC    B,TST4                                                   36840001
         EJECT                                                          36900001
*              TRIPLES WHICH MAY REQUIRE RETURN TO CALLING PHASE.       36960001
*                                                                       37020001
*          .................................................            37080001
*          .     TRIPLE    . GENERIC PHASE . DO EXPAN PHASE.            37140001
*          .................................................            37200001
*          .      TO'      . RELEASE RESULT. RETURN RESULT .            37260001
*          .               .               .               .            37320001
*          .      BY'      . RELEASE RESULT. RETURN RESULT .            37380001
*          .               .               .               .            37440001
*          .  RIGHT ARROW  . RELEASE RESULT. RETURN RESULT .            37500001
*          .               .               .               .            37560001
*          .  INVERT COMMA . RELEASE RESULT. RETURN RESULT .            37620001
*          .               .               .               .            37680001
*          .     ASSIGN    . RETURN RESULT . RELEASE RESULT.            37740001
*          .               .               .               .            37800001
*          . SPECIAL ASSIGN. RETURN RESULT . RELEASE RESULT.            37860001
*          .               .               .               .            37920001
*          .      ITDO     .     IGNORE    .     RETURN    .            37980001
*          .               .               .               .            38040001
*          .    FUNCTION   .     RETURN    .     IGNORE    .            38100001
*          .               .               .               .            38160001
*          .    'IGNORE'   .     RESULT    .     IGNORE    .            38220001
*          .................................................            38280001
*                                                                       38340001
DELIM1   LA    DSR,RESULT              EXAMINE SECOND OPERAND AND    I8 38400001
         LA    STR,TPOD2(IPTR)       RELEASE ITEM FROM STACK IF 00   I8 38460001
         BAL   RR,DICDES                                             I8 38520001
         SPACE 1                                                     I8 38580001
         CLI   RESULT,CONDE                                             38581001
         BC    BE,TST4                 BRANCH IF CONSTANT               38582001
         XC    SKASN+TPOD2(2),SKASN+TPOD2   CLEAR 2ND OPND IN ASSIGN    38583001
         CLI   0(IPTR),TRDOEQ                                           38584001
         BC    BNE,TST8                BRANCH IF NOT DOEQU TRIPLE       38585001
         TM    MCVDED+DESCDE(S),X'08'                                   38586001
         BC    BZ,TESTOP               BRANCH IF CV IS PICTURE          38587001
         MVC   RESULT(4),MCVDED(S)     SET TYPE TO THAT OF CV           38588001
         BC    B,TESTOP                                                 38589001
TST8     CLC   MCVDED(4,S),RESULT                                       38590001
         BC    BE,TESTOP               BRANCH IF SAME TYPE AS CV        38591001
         MVC   SKASN+TPOD2(2),TPOD2(IPTR)   MOVE 2ND OPND TO ASSIGN     38592001
         MVC   DEST(4),RESULT                                           38593001
         BAL   RR,ADDSTK               ADD RESULT TYPE TO STACK         38594001
         MVC   DEST(4),MCVDED(S)                                        38595001
         BAL   RR,ADDSTK               ADD CV TYPE TO STACK             38596001
         ST    IPTR,SIPR               SAVE INPUT POINTER               38597001
         LA    IPTR,SKACT                                               38598001
         MVI   COMBIN,X'FF'            SET COMBINATION SWITCH           38599001
         BC    B,LA2                   GO TO COMBINE TRIPLES            38600001
TST5     L     IPTR,SIPR               RESTORE INPUT POINTER            38601001
         TM    COMBIN,X'80'                                             38602001
         BC    BZ,TST6                 BRANCH IF RESULT TRUNCATED       38603001
         MVC   COMBIN(1),RESULT+DESCDE  DELIMITER TYPE                  38604001
         XC    COMBIN(1),DEST+DESCDE   COMBINED TYPE                    38605001
         TM    COMBIN,X'8A'            TEST ARITH/STR, CAD/PIC,FLT/FIX  38606001
         BC    BNZ,TST7                BRANCH IF ANY CHANGES            38607001
         TM    COMBIN,X'04'            TEST BIN/DEC                     38608001
         BC    BZ,TST6                 BRANCH IF NO CHANGE              38609001
         TM    DEST+DESCDE,X'02'                                        38610001
         BC    BO,TST6                 BRANCH IF BIN FLT/DEC FLT CHANGE 38611001
TST7     MVC   RESULT(4),DEST          COMBINED RESULT TYPE             38612001
         XC    TPOD2(2,IPTR),TPOD2(IPTR)    CLEAR 2ND OPND              38613001
TST6     MVI   COMBIN,X'00'            CLEAR SWITCH                     38614001
TESTOP   NC    TPOD2(2,IPTR),TPOD2(IPTR)                                38640001
         BC    BNE,TST4                BRANCH IF NOT 00  IE NO EXPR     38700001
         MVI   REORD,X'FF'             SET REORDER FLAG                 38760001
         TM    RESULT,X'0F'                                             38820001
         BC    BNO,TST9                 BRANCH IF NOT DATA VARIABLE.    39020001
*        DATA  VARIABLE.                                                39300001
TST1     MVC   SDIC+DEDATA(3),RESULT+1      COPY DATA BYTES             39360001
         XC    SDIC+DEPICT(2),SDIC+DEPICT   CLEAR PICTURE SLOT          39420001
         TM    SDIC+DEDATA,DATPIC           IS A PICTURE REQUIRED       39480001
         BC    BNZ,TST2                     BRANCH IF NOT               39540001
         MVC   SDIC+DEPICT(2),PICREF        COPY PICTURE DICT REF       39600001
TST2     TM    SDIC+DEDATA,DATADJ                                       39630001
         BC    BO,INSERT               BRANCH IF ADJUST STRING OR       39660001
*                                    POINTER OR OFFSET.                 39690001
         TM    SDIC+DEDATA,DATCAD                                       39720001
         BC    BO,TST3                 BRANCH IF CAD                    39750001
         TM    SDIC+DEDATA,X'0E'                                        39780001
         BC    BO,INSERT               BRANCH IF AREA                   39810001
         SPACE 2                                                        39820001
*              CREATE A TEMORARY VARIABLE OF SAME TYPE AS RHE RESULT    39830001
*        OF THE EXPRESSION. GENERATE AN ASSIGNMENT FROM THE EXPRESSION  39840001
*        TO THE TEMPORARY.                                              39850001
         SPACE 2                                                        39860001
TST3     MVC   PAR1+2(2),ETYPE1        CURRENT ENTRY TYPE 1.            39900001
         L     BR,ZDRFAB                                                39960001
         BALR  RR,BR                                                    40020001
         L     G1,PAR1                 ABSOLUTE ADDRESS                 40080001
         MVC   SDIC+DECHN(2),DEAUTO(G1)  START OF AUTO CHN IN NEW DE    40140001
         MVC   SDIC+DELC(2),DE1LC(G1)  COPY LEVEL AND COUNT             40200001
         LA    BR,SDIC                                                  40260001
         ST    BR,PAR1                                                  40320001
         LA    BR,SDICND-SDIC          LENGTH OF NEW ENTRY              40380001
         ST    BR,PAR2                                                  40440001
         L     LR,ZDICRF                                                40500001
         BALR  RR,BR                   MAKE NEW ENTRY IN DICTIONARY     40560001
         MVC   DEAUTO(2,G1),PAR1+2     NEW DICT REF CHAINED FROM E1     40620001
         MVC   TPOD2(2,IPR),PAR1+2     SET TEMP DICT REF IN DELIMIT     40680001
*                                    TRIPLE                             40740001
         MVC   SKASN+1(2),PAR1+2                                        40800001
         ST    IPR,SIPR                                                 40860001
         LA    IPR,SKASN               ASSIGN SKELETON                  40920001
         BAL   RR,MOVER                GET NEXT ITEM IN REORDER LIST    40980001
         L     IPR,SIPR                                                 41040001
TST4     BAL   RR,MOVE                 PUT DELIMITER IN MOVE LIST       41100001
         BC    B,RSCAN                 RESUME SCAN                      41160001
*                                                                       41160801
TST9     MVC   TPOD2(2,IPTR),SKASN+TPOD2     ) TO RESET TRIPLE OP2      41161601
         BC    B,INSERT                 ) CLEARED AT TST7 AND           41162401
*                                       ) NOT RESET                     41163201
         EJECT                                                          41164001
*              THE EXPRESSION CANNOT BE ASSIGNED TO A SIMPLE TEMPORARY  41168001
*        WHICH WOULD BE IN WORKSPACE, SO NO FURTHER ATTEMPT IS MADE TO  41172001
*        REORDER OR OPTIMISE THIS DO SPECIFICATION. THE 'REORDER' LIST  41176001
*        IS MOVED BACK INTO TEXT.(IF IT IS LARGE, PART MAY ALREADY BE   41180001
*        IN TEXT,SO THIS AVOIDS A SPECIAL CASE ACTION.) STARTING AT     41184001
*        THE ORIGINAL TEXT POSITION OF THE ITDO, THE 'ORDER' LIST IS    41188001
*        SWAPPED WITH TEXT UNTIL THE ORIGINAL 'ORDER' LIST IS INSERTED  41192001
*        INTO TEXT AND ALL SUBSEQUENT TEXT MOVED DOWN. THIS METHOD IS   41196001
*        A RELATIVELY SIMPLE WAY OF RETRIEVING A RARE SITUATION -       41200001
*        EFFICIENCY IS NOT CONSIDERED.                                  41204001
         SPACE 1                                                        41208001
INSERT   BAL   RR,MOVET                PUT REORDER LIST IN TEXT         41220001
         CLI   MDLIM(S),X'7F'           )  BRANCH IF                    41240001
         BC    BNE,INS4                 )  ABS ADDRESS                  41260001
         MVC   INREF(3),MDLIM+1(S)                                      41280001
       IEMKTAB SET,XLCRTXT,SA=INREF                                     41340001
         MVI   INSFLG,0                                                 41400001
INS1     L     P1,MITDO(S)                                              41460001
INS2     DS    0H                                                       41500001
       IEMKTAB SCAN,XLCRTXT,AATO=(IP),SATO=INREF    NEXT TRIPLE IN TEXT 41540001
         MVC   DUM(5),0(P1)                                             41580001
         MVC   0(5,P1),0(IP)                                            41640001
         MVC   0(5,IP),DUM             SWAP TRIPLES                     41700001
         CLC   INREF(3),DOREF                                           41760001
         BC    BNE,INS3                BRANCH IF NOT LAST TEXT TRIPLE   41820001
         ST    P1,MDLIM(S)             SAVE END OF ORDER LIST           41880001
         MVI   INSFLG,X'FF'            SET FOR LAST MOVE LOOP           41940001
INS3     SH    P1,H5                   NEXT MOVE LIST TRIPLE            42060001
         C     P1,MOVEC                                                 42120001
         BC    BNL,INS2                BRANCH IF NOT END OF LOOP        42180001
         CLI   INSFLG,X'FF'                                             42240001
         BC    BNE,INS1                BRANCH IF NOT LAST LOOP          42300001
         MVC   MOVEC(4),MDLIM(S)       RESET END OF ORDER LIST          42340001
INS4     EQU   *                                                        42360001
       IEMKTAB SCAN,XLCRTXT,SATO=DOREF  GET NEXT TRIPLE                 42380001
       IEMKTAB SET,XLCRTXT,SA=ANREF                                     42430001
       IEMKTAB SCAN,XLCRTXT,AATO=(IPR),SATO=ANREF                       42480001
         BC    B,CVEND                                                  42540001
         EJECT                                                          42600001
*              EXPRESSION TRIPLES.                                      42660001
ARITH    LA    G0,2                                                     42720001
         TM    OPCOD,X'10'             TEST WHETHER 1 OR 2 OPERANDS     42780001
         BC    BZ,LE1                  BRANCH IF 2 OPERANDS             42840001
         LA    G0,1                                                     42900001
LE1      STH   G0,OPND                 SET COUNT FOR LOOPS              42960001
         SPACE 2                                                        43020001
*              TEST FOR '00' OPERANDS AND SET DESCRIPTION BUFFERS.      43080001
         MVI   DEST+DESFLG,VARDE       SET TO VARIABLE                  43140001
         MVI   DEST+DESCDE,X'00'       CLEAR TARGET TYPE                43200001
         LA    DSR,DES2                2ND OPERAND DESCRIPTION BUFFER   43260001
         LA    STR,TPOD2(0,IPTR)       2ND OPERAND ADDRESS              43320001
LE2      BAL   RR,DICDES               GET OPERAND DESCRIPTION          43380001
         TM    DESFLG(DSR),VARDE       TEST OPERAND TYPE                43440001
         BC    BO,LE4                  BRANCH IF VARIABLE               43500001
         CLI   DESFLG(DSR),CONDE                                        43560001
         BC    BZ,LE4                  BRANCH IF CONSTANT               43620001
         MVC   DEST+DESFLG(2),ERRTYP   OTHER TYPE, SO SET FOR ERROR     43680001
LE4      OC    DEST+DESCDE(1),DESCDE(DSR)  OR IN OPERAND TYPE           43740001
         LA    DSR,DES1                1ST OPERAND DESCRIPTION BUFFER   43800001
         LA    STR,TPOD1(0,IPTR)       1ST OPERAND ADDRESS              43860001
         BCT   G0,LE2                  LOOP TEST                        43920001
         CLI   DEST+DESFLG,ERRDE                                        43980001
         BC    BZ,LB2                  RETURN IF RESULT IS ERROR TYPE   44040001
         SPACE 2                                                        44100001
         CLI   OPCOD,CONCAT                                             44160001
         BC    BNL,LST1                BRANCH IF STRING OPERATION       44220001
         CLI   OPCOD,CPR                                                44280001
         BC    BNE,LE5                 BRANCH IF NOT COMPARE            44340001
         MVC   DEST+DESCDE(3),CPRSLT    RESULT IS BIT STRING,LENGTH 1   44400001
         BC    B,LB2                   STACK RESULT AND GET NEXT TRIPLE 44460001
         SPACE 2                                                        44520001
*              SET RESULT TYPE FOR ARITHMETIC OPERATIONS.               44580001
LE5      MVI   DEST+DESCDE,X'88'                                        44640001
         LH    G0,OPND                                                  44700001
         LA    DSR,DES2                2ND OPERAND DESCRIPTION          44760001
LE6      TM    DESCDE(DSR),X'80'       TEST BIT 0                       44820001
         BC    BNZ,LE7                 BRANCH IF ARITH.                 44880001
         TM    DESCDE(DSR),X'04'       OTHERWISE REPLACE THE SOURCE     44940001
         MVC   DESCDE(3,DSR),CHARST  DED BY THE CORRESPONDING ARITH     45000001
         BC    BNZ,LE7               TYPE                               45060001
         MVC   DESCDE(3,DSR),BITST                                      45120001
LE7      OC    DEST+DESCDE(1),DESCDE(DSR)                               45180001
         LA    DSR,DES1                                                 45240001
         BCT   G0,LE6                  LOOP TEST                        45300001
         CLI   OPCOD,EXPON                                              45360001
         BC    BZ,EXPONT               BRANCH IF EXPONENTIAL OPERATION  45420001
         SPACE 2                                                        45480001
*              TEST FOR OPERAND CONVERSIONS.                            45540001
         TM    DEST+DESCDE,X'02'                                        45600001
         BC    BO,LE9                  BRANCH IF FLOATING RESULT        45660001
         NI    DEST+DESCDE,X'EF'       MAKE FIXED RESULT SHORT          45720001
LE9      LH    G0,OPND                                                  45780001
         LA    DSR,DES2                2ND OPERAND DESCRIPTION          45840001
LE10     BAL   RR,CONVT                CONVERT TO RESULT PRECISION      45900001
LE12     LA    DSR,DES1                1ST OPERAND DESCRIPTION          45960001
         BCT   G0,LE10                 LOOP TEST                        46020001
         SPACE 2                                                        46080001
*              CALCULATE PRECISION AND SCALING FOR ARITH OPERATIONS     46140001
         CLI   OPND+1,1                                                 46200001
         BC    BH,LE13                 BRANCH IF 2 OPERANDS             46260001
         MVC   DEST+DESP(2),DES2+DESP  UNARY +,- USE SOURCE P,Q         46320001
         BC    B,LB2                   STACK RESULT AND GET NEXT TRIPLE 46380001
LE13     TM    DEST+DESCDE,X'02'                                        46440001
         BC    BZ,LFX1                 BRANCH IF FIXED RESULT           46500001
         SPACE 2                                                        46560001
*              FLOATING RESULT.                                         46620001
         MVC   DEST+DESP(1),DES1+DESP  1ST OPERAND PRECISION IN RESULT  46680001
         CLC   DEST+DESP(1),DES2+DESP  COMPARE PRECISIONS               46740001
         BC    BNL,LE14                BRANCH IF 1ST NOT LESS           46800001
         MVC   DEST+DESP(1),DES2+DESP  2ND OPERAND PRECISION IN RESULT  46860001
LE14     MVI   DEST+DESQ,X'00'         CLEAR SCALE FACTOR               46920001
         BC    B,LB2                   STACK RESULT AND GET NEXT TRIPLE 46980001
         SPACE 2                                                        47040001
*              FIXED RESULT.                                            47100001
LFX1     LA    G0,31                   BIG N FOR BINARY                 47160001
         LA    G1,21                   MAX SHORT BINARY PRECISION       47220001
         TM    DEST+DESCDE,X'04'                                        47280001
         BC    BO,LFX2                 BRANCH IF BINARY RESULT          47340001
         LA    G0,15                   BIG N FOR DECIMAL                47400001
         LA    G1,6                    MAX SHORT DECIMAL PRECISION      47460001
LFX2     STH   G0,BIGN                 SET BIG N                        47520001
         STH   G1,SHORTP               SET MAX SHORT PRECISION          47580001
         CLI   OPCOD,EXPON                                              47640001
         BC    BZ,LEX4                 BRANCH IF EXPONENTIAL OPERATION  47700001
         IC    G0,DES1+DESQ            1ST OPERAND SCALE FACTOR (Q)     47760001
         IC    G1,DES2+DESQ            2ND OPERAND SCALE FACTOR (S)     47820001
         CLI   OPCOD,ADD                                                47880001
         BC    BH,LFX9                 BRANCH IF MULT OR DIVIDE         47940001
         SPACE 2                                                        48000001
*              FIXED ADD,SUBTRACT,ARGUMENT COMBINATION.                 48060001
         SR    G0,G1              (Q-S)=(X)                             48120001
         STH   G0,SHFT            STORE AS SHIFT                        48180001
         SR    G0,G0                                                    48240001
         IC    G0,DES1+DESP       1ST OPERAND PRECISION (P)             48300001
         IC    G1,DES2+DESP       2ND OPERAND PRECISION (R)             48360001
         TM    SHFT,X'80'         TEST SIGN OF SHIFT                    48420001
         BC    BO,LFX3            BRANCH IF NEGATIVE                    48480001
         MVC   DEST+DESQ(1),DES1+DESQ  RESULT SCALE FACTOR = (Q)        48540001
         AH    G1,SHFT            (R+X)                                 48600001
         BC    B,LFX4                                                   48660001
LFX3     MVC   DEST+DESQ(1),DES2+DESQ  RESULT SCALE FACTOR = (S)        48720001
         SH    G0,SHFT            (P-X)                                 48780001
LFX4     CR    G0,G1              COMPARE (P,R+X) OR (P-X,R)            48840001
         BC    BNH,LFX5           BRANCH IF LARGER IN G1                48900001
         LR    G1,G0                                                    48960001
LFX5     CLI   OPCOD,ACT                                                49020001
         BC    BZ,LFX12                BRANCH IF ARGUMENT COMBINATION   49080001
LFX11    LA    G1,1(G1)                BUMP PRECISION BY 1              49140001
LFX12    CH    G1,BIGN                 COMPARE WITH BIG N               49200001
         BC    BH,LFX6            BRANCH IF LARGER                      49260001
         CH    G1,SHORTP          COMPARE WITH MAX SHORT PRECISION      49320001
         BC    BNH,LFX8           BRANCH IF SHORT                       49380001
         BC    B,LFX7                                                   49440001
LFX6     LH    G1,BIGN                                                  49500001
         CLC   DEST+DESQ(1),DES1+DESQ  TEST WHETHER 1ST OPERAND IS      49510001
         BC    BE,LFX7               SHIFTED. BRANCH IF NO TRUNCATION.  49520001
         NI    COMBIN,X'7F'            CLEAR BIT 0 IN SWITCH            49530001
LFX7     OI    DEST+DESCDE,X'10'  SET LONG BIT ON                       49560001
LFX8     STC   G1,DEST+DESP                                             49620001
         BC    B,LB2                   STACK RESULT AND GET NEXT TRIPLE 49680001
         SPACE 2                                                        49740001
*              FIXED MULTIPLY.                                          49800001
LFX9     CLI   OPCOD,MULT                                               49860001
         BC    BNE,LFX10               BRANCH IF DIVISION               49920001
         AR    G0,G1                   (Q+S)                            49980001
         SH    G0,SF0                  SUBTRACT 128                     50040001
         STC   G0,DEST+DESQ            RESULT SCALE FACTOR              50100001
         SR    G0,G0                                                    50160001
         IC    G0,DES1+DESP            1ST OPERAND PRECISION (P)        50220001
         IC    G1,DES2+DESP            2ND OPERAND PRECISION (R)        50280001
         AR    G1,G0                   (P+R)                            50340001
         BC    B,LFX5                                                   50400001
         BC    B,LFX11                                                  50460001
         SPACE 2                                                        50520001
*              FIXED DIVIDE.                                            50580001
LFX10    SR    G0,G1                   (Q-S)                            50640001
         AH    G0,BIGN                 (N+Q-S)                          50700001
         IC    G1,DES1+DESP            1ST OPERAND PRECISION (P)        50760001
         SR    G0,G1                   (N-P+Q-S)                        50820001
         AH    G0,SF0                                                   50880001
         STC   G0,DEST+DESQ            RESULT SCALE FACTOR              50940001
         BC    B,LFX6                  GO TO SET RESULT PRECISION = N   51000001
         EJECT                                                          51060001
*              EXPONENTIAL OPERATIONS.                                  51120001
*                                                                       51180001
EXPONT   TM    DEST+DESCDE,X'02'       TEST RESULT TYPE                 51240001
         BC    BO,LEX9                 BRANCH IF FLOAT               I8 51300001
         CLI   DES2+DESFLG,CONDE                                        51360001
         BC    BNE,LEX9                BRANCH IF NOT A CONSTANT         51420001
         SPACE 2                                                        51480001
*              CALCULATE VALUE OF CONSTANT                              51540001
         MVC   PAR1+2(2),TPOD2(IPTR)                                    51600001
         L     LR,ZDRFAB                                                51660001
         BALR  RR,LR                   CONSTANT DICT ENTRY ADDRESS      51720001
         L     STR,PAR1                                                 51780001
         TM    DCDED1(STR),X'80'       TEST THE CONSTANT AND GO TO SET  51840001
         BC    BZ,LEX9               FLOAT RESULT IF NOT INTEGER        51900001
         TM    DCDED1(STR),X'02'                                        51960001
         BC    BO,LEX9                                                  52020001
         CLI   DCDED1+2(STR),X'80'                                      52080001
         BC    BNE,LEX9                                                 52140001
         CLI   DCVAL(STR),X'73'        IF -VE. THEN SET RESULT TYPE     52200001
         BC    BE,LEX9               TO FLOAT.                          52260001
         SR    DSR,DSR                                                  52320001
         IC    DSR,DES2+DESP           PRECISION=NO OF DIGITS           52380001
         TM    DES2+DESCDE,X'04'                                        52440001
         BC    BZ,LEX2                 BRANCH IF DECIMAL                52500001
LEX1     IC    GRN,DCVAL-1(STR,DSR)    NEXT BYTE OF VALUE IN DICT ENTRY 52560001
         SRDL  GRN,1                   SHIFT BIT 7 INTO ODD REGISTER-G1 52620001
         BCT   DSR,LEX1                BRANCH IF MORE DIGITS            52680001
         SR    GRN,GRN                                                  52740001
         IC    DSR,DES2+DESP           NO OF BITS                       52800001
         SLDL  GRN,0(DSR)              BINARY RESULT                    52860001
         BC    B,LFX1                                                   52920001
LEX2     LA    G1,DCVAL-1(STR,DSR)     ADDRESS OF LAST BYTE OF VALUE    52980001
         OI    0(G1),PLUSZ             INSERT PLUS ZONE                 53040001
         LA    DSR,111(DSR)            LENGTHS 7,P-1 FOR PACK INSTRUCTN 53100001
         EX    DSR,LEX3                EXECUTE PACK WITH MODIFIED LNGTH 53160001
         NI    0(G1),X'0F'             REMOVE ZONE                      53220001
         NC    EXPBUF(6),EXPBUF                                         53280001
         BC    BNE,LEX9                BRANCH IF NOT 12 LEADING ZEROS   53340001
         CVB   GRN,EXPBUF              CONVERT TO BINARY                53400001
         SPACE 2                                                        53460001
*              CALCULATE FEASABILITY, AND PRECISION,SCALE FACTOR OF     53520001
*              FIXED RESULT.                                            53580001
         BC    B,LFX1                  SET UP BIGN,SHORTP               53640001
LEX4     LTR   G0,GRN                  CONSTANT POWER (Y)               53700001
         BC    BZ,LEX9                 BRANCH TO FLOAT IF ZERO POWER    53760001
         MVC   EXPBUF(4),DES1                                           53820001
         LA    DSR,EXPBUF              CONVERT PRECISION-SCALING OF 1ST 53880001
         BAL   RR,CONVT                OPERAND,IF NECESSARY.            53940001
         SR    G1,G1                                                    54000001
         IC    G1,EXPBUF+DESP          1ST OPERAND PRECISION (P)        54060001
         LA    G1,1(G1)                (P+1)                            54120001
         MR    GRN,G0                  (P+1)*Y                          54180001
         BCTR  G1,0                    (P+1)*Y -1                       54240001
LEX5     CH    G1,BIGN                 COMPARE RESULT PREC WITH BIG N   54300001
         BC    BH,LEX9                 BRANCH TO FLOAT IF LARGER        54360001
         STC   G1,DEST+DESP                                             54420001
         CH    G1,SHORTP                                                54480001
         BC    BNH,LEX6                BRANCH IF SHORT RESULT           54540001
         OI    DEST+DESCDE,X'10'       SET RESULT TYPE TO LONG          54600001
LEX6     IC    G1,EXPBUF+DESQ          1ST OPERAND SCALE FACTOR (Q)     54660001
         SH    G1,SF0                                                   54720001
         MR    GRN,G0                  Q*Y                              54780001
         AH    G1,SF0                                                   54840001
         BC    BL,LEX7                 BRANCH IF SF .LT. -128           54900001
         CH    G1,MAXSF                                                 54960001
         BC    BNH,LEX8                BRANCH IF SF .LE. +127           55020001
LEX7     LCR   G1,GRN                  SET SF TO MAX OR MIN VALUE       55080001
LEX8     STC   G1,DEST+DESQ            RESULT SCALE FACTOR              55140001
         BC    B,LB2                   STACK RESULT AND GET NEXT TRIPLE 55200001
LEX3     PACK  EXPBUF(0),DCVAL(0,STR)    PACK CHARACTERS                55260001
         SPACE 2                                                        55320001
*              FLOAT RESULT                                             55380001
LEX9     OI    DEST+DESCDE,X'02'       FLOAT RESULT                     55440001
         TM    DES2+DESCDE,X'02'       IF THE SECOND OPERAND WAS     I8 55500001
         BC    BO,LE9                FLOAT GO TO TREAT AS NORMAL     I8 55560001
*                                    FLOAT OPERATION.                I8 55620001
         CLI   DES2+DESQ,X'80'         LIKEWISE IF THE SCALE IS NOT  I8 55680001
         BC    BNE,LE9               ZERO OR IT IS COMPLEX           I8 55740001
         TM    DES2+DESCDE,X'01'                                     I8 55800001
         BC    BO,LE9                                                I8 55860001
         SPACE 1                                                     I8 55920001
         MVC   DEST+DESCDE(3),DES1+DESCDE  2ND OPERAND IS REAL FIXED I8 55980001
         OI    DEST+DESCDE,X'0A'     INTEGER SO CONVERT FIRST OPERANDI8 56040001
         BC    B,LE14                TO FLOAT AND USE IT FOR THE     I8 56100001
*                                    RESULT PRECISION.               I8 56160001
         EJECT                                                          56220001
*              STRING OPERATIONS.                                       56280001
*                                                                       56340001
LST1     CLI   OPCOD,CONCAT                                             56400001
         BC    BNE,LST2                BRANCH IF NOT CONCAT             56460001
         TM    DEST+DESCDE,X'84'                                        56520001
         BC    BZ,LST2                 BRANCH IF BOTH OPNDS BIT STRING  56580001
         MVI   DEST+DESCDE,X'2C'       SET RESULT TO CHAR STRING        56640001
         BC    B,LST3                                                   56700001
LST2     MVI   DEST+DESCDE,X'28'       SET RESULT TO BIT STRING         56760001
LST3     LH    G0,OPND                 NUMBER OF OPERANDS               56820001
         LA    DSR,DES2                2ND OPERAND DESCRIPTION          56880001
LST4     BAL   RR,CONVST               CONVERT LENGTH,IF NECESSARY      56940001
         LA    DSR,DES1                1ST OPERAND DESCRIPTION          57000001
         BCT   G0,LST4                                                  57060001
         TM    DEST+DESCDE,X'40'                                        57120001
         BC    BO,LB2                  BRANCH IF RESULT IS ADJUSTABLE   57180001
         LH    G1,DES2+DESP            2ND OPERAND LENGTH               57240001
         CLI   OPCOD,CONCAT                                             57300001
         BC    BNE,LST5                BRANCH IF NOT CONCAT             57360001
         AH    G1,DES1+DESP            ADD LENGTHS FOR CONCAT           57420001
         BC    B,LST6                                                   57480001
LST5     CLI   OPCOD,NOT                                                57540001
         BC    BZ,LST6                 BRANCH IF 'NOT'                  57600001
         CH    G1,DES1+DESP            AND,OR ,SO COMPARE LENGTHS       57660001
         BC    BNL,LST6                BRANCH IF 1ST OPERAND SHORTER    57720001
         LH    G1,DES1+DESP                                             57780001
LST6     STH   G1,DEST+DESP            RESULT STRING LENGTH             57840001
         BC    B,LB2                   STACK RESULT AND GET NEXT TRIPLE 57900001
         EJECT                                                          57960001
*              CONVERT SUBROUTINE                                       58020001
*                                                                       58080001
*              TO CALCULATE CHANGES IN PRECISION,SCALE FACTOR DURING    58140001
*              CONVERSION TO ARITHMETIC TYPE. SOURCE DED IN DESCRIPTION 58200001
*              BUFFER ADDRESSED BY REGISTER DSR. TARGET DED IN          58260001
*              DESCRIPTION BUFFER 'DEST'.                               58320001
*                                                                       58380001
CONVT    MVC   CVTBUF(1),DEST+DESCDE   TARGET CODE BYTE                 58440001
         XC    CVTBUF(1),DESCDE(DSR)   CODE BYTE CHANGES                58500001
         NI    CVTBUF,X'06'            CLEAR ALL EXCEPT BIN/DEC,FLT/FIX 58560001
         BCR   BZ,RR                   RETURN IF NO CHANGES LEFT        58620001
         TM    CVTBUF,X'04'            TEST BINARY/DECIMAL BIT          58680001
         BC    BZ,LCV9                 BRANCH IF FIX-FLOAT ONLY         58740001
         SPACE 2                                                        58800001
*              DECIMAL TO BINARY CONVERSIONS.                           58860001
*              CONVERT PRECISION                                        58920001
         SR    G1,G1                   DECIMAL TO BINARY CONVERSION     58980001
         IC    G1,DESP(DSR)            SOURCE PRECISION (P)             59040001
         M     GRN,DBMULT              P*3.32                           59100001
         A     G1,CEIL1                                                 59160001
         SRA   G1,20                   CEIL(P*3.32)                     59220001
         TM    DEST+DESCDE,X'02'                                        59280001
         BC    BZ,LCV4                 BRANCH IF FIXED TARGET           59340001
         CH    G1,FLMAXP               COMPARE WITH MAX FLOAT PRECISION 59400001
         BC    BNH,LCV3                BRANCH IF NOT GREATER            59460001
         LH    G1,FLMAXP               SET TO 53                        59520001
LCV3     STC   G1,DESP(DSR)            TARGET PRECISION =CEIL(P*3.32)   59580001
LCV9     MVI   DESQ(DSR),X'80'         SF =ZERO FOR FLOAT TARGET        59640001
         BCR   B,RR                    RETURN                           59700001
LCV4     LA    G1,1(G1)                CEIL(P*3.32)+1                   59760001
         CH    G1,FXMAXP               COMPARE WITH MAX FIXED PRECISION 59820001
         BC    BNH,LCV5                BRANCH IF NOT GREATER            59880001
         LH    G1,FXMAXP               SET TO 31                        59940001
LCV5     STC   G1,DESP(DSR)            TARGET PRECISION                 60000001
         SPACE 2                                                        60060001
*              CONVERT SCALE FACTOR                                     60120001
         IC    G1,DESQ(DSR)            SOURCE SCALE FACTOR (Q)          60180001
         SH    G1,SF0                                                   60240001
         M     GRN,DBMULT              Q*3.32                           60300001
         LTR   G1,G1                                                    60360001
         BC    BNH,LCV6                BRANCH IF NEGATIVE               60420001
         A     G1,CEIL1                ROUND UP IF POSITIVE             60480001
LCV6     SRA   G1,20                                                    60540001
         AH    G1,SF0                                                   60600001
         BC    BL,LCV7                 BRANCH IF SF .LT. -128           60660001
         CH    G1,MAXSF                                                 60720001
         BC    BNH,LCV8                BRANCH IF SF .LE. +127           60780001
LCV7     LCR   G1,GRN                  SF OUT OF RANGE-SET TO MAX/MIN   60840001
LCV8     STC   G1,DESQ(DSR)            TARGET SCALE FACTOR              60900001
         BCR   B,RR                    RETURN                           60960001
         EJECT                                                          61020001
*              STRING CONVERT SUBROUTINE.                               61080001
*                                                                       61140001
*              TO CALCULATE CHANGES IN PRECISION,SCALE FACTOR DURING    61200001
*              CONVERSION TO STRING TYPE. SOURCE DED IN DESCRIPTION     61260001
*              BUFFER ADDRESSED BY REGISTER DSR. TARGET DED IN          61320001
*              DESCRIPTION BUFFER 'DEST'.                               61380001
*                                                                       61440001
CONVST   TM    DESCDE(DSR),X'80'       TEST SOURCE                      61500001
         BC    BO,LCS1                 BRANCH IF ARITH TYPE             61560001
         MVC   CVTBUF(1),DESCDE(DSR)                                    61620001
         NI    CVTBUF,X'50'            SELECT BITS 1,3                  61680001
         OC    DEST+DESCDE(1),CVTBUF   BITS 1,3 ON IF ADJUST OR VAR     61740001
         BCR   B,RR                    RETURN                           61800001
LCS1     SR    G1,G1                                                    61860001
         IC    G1,DESP(DSR)            SOURCE PRECISION (P)             61920001
         TM    DEST+DESCDE,X'04'       TEST TARGET                      61980001
         BC    BO,LCS6                 BRANCH IF CHAR STRING            62040001
         SPACE 2                                                        62100001
*              ARITH TYPE SOURCE AND BIT STRING TARGET.                 62160001
LCS2     TM    DESCDE(DSR),X'02'       TEST SOURCE FOR FLOAT/FIXED      62220001
         BC    BO,LCS3                 BRANCH IF FLOATING               62280001
         SR    GRN,GRN                                                  62340001
         IC    GRN,DESQ(DSR)           SOURCE SCALE FACTOR (Q)          62400001
         SH    GRN,SF0                                                  62460001
         SR    G1,GRN                  (P-Q)                            62520001
         BC    BNL,LCS3                BRANCH IF NOT NEGATIVE           62580001
         SR    G1,G1                   SET TO ZERO                      62640001
LCS3     TM    DESCDE(DSR),X'04'       TEST SOURCE FOR BIN/DEC          62700001
         BC    BO,LCS4                 BRANCH IF BINARY                 62760001
         M     GRN,DBMULT              Q*3.32                           62820001
         A     G1,CEIL1                ROUND UP                         62880001
         SRA   G1,20                                                    62940001
LCS4     CH    G1,FXMAXP               COMPARE WITH MAX FIX BIN PREC    63000001
         BC    BNH,LCS5                BRANCH IF NOT GREATER            63060001
         LH    G1,FXMAXP               SET TO MAX PRECISION             63120001
LCS5     STH   G1,DESP(DSR)            RESULT STRING LENGTH             63180001
         BCR   B,RR                    RETURN                           63240001
         SPACE 2                                                        63300001
*              ARITH TYPE SOURCE AND CHARACTER STRING TARGET.           63360001
LCS6     TM    DESCDE(DSR),X'08'       TEST SOURCE FOR CAD/NF           63420001
         BC    BO,LCS6A                BRANCH IF CAD                    63480001
         OI    DEST+DESCDE,X'40'       SET TARGET TO ADJUSTABLE         63540001
         BCR   B,RR                    RETURN                           63600001
LCS6A    TM    DESCDE(DSR),X'04'       TEST SOURCE FOR BIN/DEC          63660001
         BC    BO,LCS7                 BRANCH IF BINARY                 63720001
         TM    DESCDE(DSR),X'02'       TEST SOURCE FOR FLOAT/FIX        63780001
         BC    BO,LCS12                BRANCH IF FLOAT                  63840001
         STH   G1,DEST+DESP            SAVE SOURCE PRECISION            63900001
         IC    G1,DESQ(DSR)                                             63960001
         SH    G1,SF0                  SOURCE SCALE FACTOR (Q)          64020001
         BC    B,LCS9                                                   64080001
LCS7     M     GRN,BDMULT              P*1/3.32                         64140001
         A     G1,CEIL1                ROUND UP                         64200001
         SRA   G1,20                                                    64260001
         TM    DESCDE(DSR),X'02'       TEST SOURCE FOR FLOAT/FIX        64320001
         BC    BO,LCS12                BRANCH IF FLOATING               64380001
         LA    G1,1(G1)                BUMP PRECISION BY 1              64440001
         STH   G1,DEST+DESP                                             64500001
         IC    G1,DESQ(DSR)                                             64560001
         SH    G1,SF0                  SOURCE SCALE FACTOR (Q)          64620001
         M     GRN,BDMULT              Q*1/3.32                         64680001
         LTR   G1,G1                                                    64740001
         BC    BNH,LCS8                BRANCH IF LESS THAN ZERO         64800001
         A     G1,CEIL1                ROUND UP                         64860001
LCS8     SRA   G1,20                   TRUNCATE                         64920001
LCS9     BC    BL,LCS10                BRANCH IF Q LESS THAN ZERO       64980001
         CH    G1,DEST+DESP            COMPARE WITH P                   65040001
         BC    BH,LCS10                BRANCH IF Q .GT. P               65100001
         LA    G1,3                    SET FOR (P+3) LENGTH.            65160001
         BC    B,LCS11                                                  65220001
LCS10    LPR   GRN,G1                  MAKE Q POSITIVE                  65280001
         LA    G1,4                    SET FOR (P+4) LENGTH             65340001
         CH    GRN,H10                                                  65400001
         BC    BL,LCS11                BRANCH IF Q .LT. 10              65460001
         LA    G1,5                    SET FOR (P+5) LENGTH             65520001
         CH    GRN,H100                                                 65580001
         BC    BL,LCS11                BRANCH IF Q .LT. 100             65640001
         LA    G1,6                    SET FOR (P+6) LENGTH             65700001
LCS11    AH    G1,DEST+DESP            ADD PRECISION P                  65760001
         BC    B,LCS13                                                  65820001
LCS12    LA    G1,6(G1)                SET FOR (P+6) LENGTH - FLOATING  65880001
LCS13    TM    DESCDE(DSR),X'01'       TEST SOURCE FOR COMPLEX/REAL     65940001
         BC    BZ,LCS5                 BRANCH IF REAL                   66000001
         AR    G1,G1                                                    66060001
         LA    G1,1(G1)                LENGTH =2*W+1                    66120001
         BC    B,LCS5                                                   66180001
         EJECT                                                          66240001
*        'DICDES' SUBROUTINE TO SET UP THE DESCRIPTION FOR A TRIPLE     66300001
*        OPERAND. REGISTER STR ADDRESSES THE OPERAND,AND REGISTER DSR   66360001
*        ADDRESSES THE DESCRIPTION BUFFER FOR THE RESULT.               66420001
*           IF THE OPERAND IS '00', THE DESCRIPTION IS TAKEN FROM THE   66480001
*        TOP OF THE RESULT STACK. IF THE OPERAND IS NOT '00', THE       66540001
*        DESCRIPTION IS OBTAINED FROM THE CORRESPONDING DICTIONARY      66600001
*        ENTRY.                                                         66660001
*                                                                       66720001
DICDES   ST    RR,DCDSRR               SAVE RETURN REGISTER             66780001
         NC    0(2,STR),0(STR)         TEST OPERAND                     66840001
         BC    BNE,LDIC1               BRANCH IF DICT REF               66900001
         BAL   RR,RELSTK               GET TOP ITEM FROM RESULT STACK   66960001
         BC    B,LDIC4                                                  67020001
LDIC1    MVC   PAR1+2(2),0(STR)                                         67080001
         L     LR,ZDRFAB                                                67140001
         BALR  RR,LR                                                    67200001
         L     STR,PAR1                                                 67260001
         MVC   DESFLG(1,DSR),DCFLG(STR)                                 67320001
         CLI   DCFLG(STR),CONDE                                         67380001
         BC    BNE,LDIC2               BRANCH IF NOT A CONSTANT         67440001
         MVC   DESCDE(3,DSR),DCDED1(STR)  MOVE APPARENT DED OF CONSTANT 67500001
         BC    B,LDIC4                                                  67560001
LDIC2    TM    DCFLG(STR),VARDE                                         67620001
         BC    BNO,LDIC3               BRANCH IF NOT A VARIABLE         67680001
         MVC   DESCDE(3,DSR),DEDATA(STR)  MOVE VARIABLE DED             67740001
         MVC   PICREF(2),DEPICT(STR)   SAVE PICTURE REFERENCE           67800001
         BC    B,LDIC4                                                  67860001
LDIC3    MVI   DESCDE(DSR),X'00'       SET 2ND CODE BYTE TO LABEL       67920001
         TM    DCFLG(STR),LABDE                                         67980001
         BC    BZ,LDIC4                BRANCH IF LABEL                  68040001
         MVI   DESCDE(DSR),X'A0'       SET 2ND CODE BYTE TO FILE        68100001
         TM    DCFLG(STR),FILDE                                         68160001
         BC    BZ,LDIC4                BRANCH IF FILE                   68220001
         MVI   DESCDE(DSR),X'E0'       SET 2ND CODE BYTE TO TASK        68280001
         TM    DCFLG(STR),TSKDE                                         68340001
         BC    BZ,LDIC4                BRANCH IF TASK                   68400001
         MVI   DESCDE(DSR),X'80'       SET 2ND CODE BYTE TO EVENT       68460001
LDIC4    L     RR,DCDSRR                                                68520001
         BCR   B,RR                    RETURN                           68580001
         EJECT                                                          68640001
*              RESULT STACKING SUBROUTINE.                              68700001
*                                                                       68760001
*              'ADDSTK' ENTRY ADDS RESULT IN DESCRIPTION BUFFER 'DEST'  68820001
*              TO STACK.                                                68880001
*                                                                       68940001
*              'RELSTK' ENTRY MOVES RESULT FROM STACK TO DESCRIPTION    69000001
*              BUFFER ADDRESSED BY REGISTER DSR.                        69060001
*                                                                       69120001
ADDSTK   L     STR,CSTK                CURRENT TOP OF STACK             69180001
LSTK1    LA    STR,ISTK(STR)           BUMP CURRENT TOP ADDRESS         69240001
         C     STR,TPSTK                                                69300001
         BC    BH,LSTK3                BRANCH IF STACK FULL             69360001
         MVC   0(ISTK,STR),DEST        MOVE IN NEW DESCRIPTION          69420001
         BC    B,LSTK3                                                  69480001
         SPACE 2                                                        69540001
RELSTK   L     STR,CSTK                CURRENT TOP OF STACK             69600001
         C     STR,BSTK                                                 69660001
         BC    BL,STKERR               BRANCH IF ALREADY BELOW BOTTOM   69720001
         C     STR,TPSTK                                                69780001
         BC    BNH,LSTK2               BRANCH IF STACK NOT FULL         69840001
         SH    STR,SZSTK                                                69900001
STKERR   MVC   0(2,DSR),ERRTYP         SET RESULT TO ERROR TYPE         69960001
         BC    B,LSTK3                                                  70020001
LSTK2    MVC   0(ISTK,DSR),0(STR)      MOVE OUT TOP DESCRIPTION         70080001
LSTK2A   SH    STR,SZSTK                                                70140001
LSTK3    ST    STR,CSTK                RESET CURRENT TOP OF STACK       70200001
         BCR   B,RR                    RETURN                           70260001
         EJECT                                                          70320001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*KC 001-TSS 70330056
IEMKC1   CSECT                                                          70340001
*        ----------------------------------------------------KC 001-TSS 70350056
         SPACE 1                                                        70360001
*              CONSTANTS.                                               70380001
F63      DC    F'63'                                                    70440001
CNZERO   DC    F'0'                    ZERO                             70500001
DBMULT   DC    X'00351EB8'             DECIMAL TO BINARY MULTIPLIER     70560001
BDMULT   DC    X'0004D1BC'             BINARY TO DECIMAL MULT 1/3.32    70620001
CEIL1    DC    X'000FFFFF'             ROUND UP TO NEXT INTEGER         70680001
H10      DC    H'10'                                                    70740001
H100     DC    H'100'                                                   70800001
SF0      DC    H'128'                  ZERO SCALE FACTOR                70860001
FLMAXP   DC    H'53'                   MAXIMUM FLOAT BINARY PRECISION   70920001
FXMAXP   DC    H'31'                   MAXIMUM FIXED BINARY PRECISION   70980001
MAXSF    DC    H'255'                  MAXIMUM SCALE FACTOR             71040001
SZSTK    DC    AL2(ISTK)               STACK ITEM SIZE                  71100001
CPRSLT   DC    X'280001'               COMPARE RESULT                   71160001
CHARST   DC    X'980F80'               CHAR TO ARITH                    71220001
BITST    DC    X'9C1F80'             BIT TO ARITH                       71280001
ERRTYP   DC    AL1(ERRDE)              CODE BYTES FOR ERROR RESULT      71340001
         DC    X'FF'                                                    71400001
         SPACE 1                                                        71460001
*              SKELETON CONSTANT DICTIONARY ENTRY.                      71520001
         SPACE 1                                                        71580001
UCONDE   DC    X'88'                   CONSTANT DICT ENTRY SKELETON     71640001
         DC    AL2(UCONND-UCONDE)    USED FOR UMBRELLA OPERAND          71700001
UCONCH   DC    AL2(0)                  CHAIN FIELD                      71760001
         DC    X'9C1F80'               FIXED BINARY (31,0)              71820001
         DC    X'C0'                   TYPE = CONVERTED                 71880001
         DC    X'9C1F80'               FIXED BINARY (31,0)              71940001
         DC    2X'00'                                                   72000001
UCONST   DC    4X'00'                  SPACE FOR UMBRELLA OPERAND       72060001
UCONND   EQU   *                                                        72120001
         SPACE 1                                                        72180001
FCONDE   DC    AL1(DRCON)              SKELETON FOR FIXED BINARY        72240001
         DC    AL2(14)                                                  72300001
FCONCH   DC    AL2(0)                  CHAIN                            72360001
FCONST   DC    AL3(0)                  SOURCE TYPE                      72420001
FCONFL   DC    X'00'                   FLAG                             72480001
FCONTT   DC    X'9C1F80'               TARGET TYPE                      72540001
FCONSN   DC    X'0000'                 STATEMENT NUMBER                 72600001
         SPACE 1                                                        72660001
*              UMBRELLA CONSTANT ENTRIES TABLE                          72720001
*        EACH WORD IS ZERO OR CONTAINS A DICTIONARY REFERENCE OF A      72780001
*        CONSTANT AND THE HALFWORD VALUE OF THE CONSTANT. IT IS SET     72840001
*        TO ZERO BY ASSEMBLY AND ENTRIES ARE MADE WHENEVER AN UMBRELLA  72900001
*        TRIPLE HAS A DICTIONARY ENTRY MADE FOR ITS VALUE.              72960001
         SPACE 1                                                        73020001
         DS    0F                                                       73080001
UMBTAB   DC    4XL16'0'                ROOM FOR 16 ENTRIES              73140001
UMBEND   EQU   *                                                        73200001
         EJECT                                                          73260001
*              WORK SPACE.                                              73320001
EXPBUF   DC    D'0'                    EXPONT WORKSPACE                 73380001
WSLG01   DC    F'0'                    SAVE SLOT FOR LG BASE            73440001
WSRR01   DC    F'0'                    RETURN SAVE 1                    73500001
WSRR02   DC    F'0'                    RETURN SAVE 2                    73560001
DES1     DC    F'0'                    1ST OPERAND DESCRIPTION BUFFER   73620001
DES2     DC    F'0'                    2ND OPERAND DESCRIPTION BUFFER   73680001
DEST     DC    F'0'                    RESULT DESCRIPTION BUFFER        73740001
BSTK     DC    F'0'                    ADDRESS OF BOTTOM OF STACK       73800001
CSTK     DC    F'0'                    ADDRESS OF CURRENT TOP OF STACK  73860001
TPSTK    DC    F'0'                    ADDRESS OF TOP END OF STACK      73920001
BGSTK    DC    F'0'                    BOTTOM OF SCRATCH AREA           73980001
TOPSTK   DC    F'0'                    TOP OF SCRATCH AREA              74040001
DCDSRR   DC    F'0'                    RETURN REGISTER FOR 'DICDES'     74100001
TEMPE1   DC    H'0'                    E1 AND E2 TEMPORARIES USED TO    74160001
TEMPE2   DC    H'0'                  SAVE OPTIMIZATION REFERENCES       74220001
OPND     DC    H'0'                    NUMBER OF OPERANDS               74280001
BIGN     DC    H'0'                    BIG N FOR FIXED ARITH            74340001
SHORTP   DC    H'0'                    MAX SHORT PRECISION              74400001
SHFT     DC    H'0'                    FIXED ARITH SHIFT                74460001
CVTBUF   DC    X'0'                    WORKSPACE FOR CONVT              74520001
OPCOD    DC    X'0'                    OPERATION CODE                   74580001
PICREF   DC    H'0'                    PICTURE REF.                     74640001
         EJECT                                                          74700001
*              LAYOUT OF SCAN PARAMETER BLOCK.                          74760001
         DS    0F                                                       74820001
SCTRT    DC    X'24'         X'00'     ERROR                            74880001
         DC    XL45'0'                                                  74940001
         DC    X'C0'         X'2E'     DEFINED SUBSCRIPT                75000001
         DC    8X'0'                                                    75060001
         DC    X'D4'         X'37'     SPECIAL ASSIGN                   75120001
         DC    X'DC'         X'38'     IGNORE                           75180001
         DC    3X'0'                                                    75240001
         DC    X'DC'         X'3C'     FUNCTION                         75300001
         DC    XL4'0'                                                   75360001
         DC    X'CC'         X'41'     COMMA                            75420001
         DC    X'CC'         X'42'     FUNCTION COMMA                   75480001
         DC    X'0'                                                     75540001
         DC    X'CC'         X'44'     COMPILER FUNCTION COMMA          75600001
         DC    X'80'         X'45'     ACT - ARGUMENT COMBINATION       75660001
         DC    X'CC'         X'46'     COMPILER ASSIGN                  75720001
         DC    X'D4'         X'47'     ASSIGN                           75780001
         DC    X'0'                                                     75840001
         DC    X'A1'         X'49'     CONCAT                           75900001
         DC    X'0'                                                     75960001
         DC    X'A2'         X'4B'     OR                               76020001
         DC    X'0'                                                     76080001
         DC    X'A2'         X'4D'     AND                              76140001
         DC    X'0'                                                     76200001
         DC    X'B3'         X'4F'     NOT                              76260001
         DC    XL14'0'                                               I8 76320001
         DC    X'E0'         X'5E'     UMBRELLA                         76380001
         DC    2X'0'                                                    76440001
         DC    X'D0'         X'61'     DO ASSIGN                        76500001
         DC    2X'0'                                                    76560001
         DC    X'D0'         X'64'     INVERTED COMMA                   76620001
         DC    X'85'         X'65'     EQUAL OR LESS THAN               76680001
         DC    X'0'                                                     76740001
         DC    X'85'         X'67'     EQUAL OR GREATER THAN            76800001
         DC    X'0'                                                     76860001
         DC    X'85'         X'69'     NOT EQUAL TO                     76920001
         DC    X'0'                                                     76980001
         DC    X'85'         X'6B'     EQUAL TO                         77040001
         DC    X'0'                                                     77100001
         DC    X'85'         X'6D'     GREATER THAN                     77160001
         DC    X'0'                                                     77220001
         DC    X'85'         X'6F'     LESS THAN                        77280001
         DC    X'C4'         X'70'     COMPILER FUNCTION PRIMED         77340001
         DC    2X'0'                                                    77400001
         DC    X'81'         X'73'     MINUS                            77460001
         DC    X'0'                                                     77520001
         DC    X'81'         X'75'     PLUS                             77580001
         DC    X'0'                                                     77640001
         DC    X'83'         X'77'     DIVIDE                           77700001
         DC    X'0'                                                     77760001
         DC    X'82'         X'79'     MULTIPLY                         77820001
         DC    X'0'                                                     77880001
         DC    X'96'         X'7B'     UNARY MINUS                      77940001
         DC    X'C4'         X'7C'     FUNCTION PRIMED                  78000001
         DC    X'96'         X'7D'     UNARY PLUS                       78060001
         DC    X'C0'         X'7E'     SUBSCRIPT PRIME                  78120001
         DC    X'84'         X'7F'     EXPONENTIAL                      78180001
         DC    XL55'0'                                                  78240001
         DC    X'D8'         X'B7'     ITDO                             78300001
         DC    4X'0'                                                    78360001
         DC    X'20'         X'BC'     SN2                              78420001
         DC    3X'0'                                                    78480001
         DC    X'D0'         X'C0'     TO'                              78540001
         DC    X'0'                                                     78600001
         DC    X'D0'         X'C2'     BY'                              78660001
         DC    XL13'0'                                                  78720001
         DC    X'20'         X'D0'     SN                               78780001
         DC    X'0'                                                     78840001
         DC    X'20'         X'D2'     SL                               78900001
         DC    X'0'                                                     78960001
         DC    X'20'         X'D4'     CN                               79020001
         DC    XL24'0'                                                  79080001
         DC    X'24'         X'ED'     END-OF-BLOCK                     79140001
         DC    XL18'0'                                                  79200001
         SPACE 2                                                        79260001
*              END OF SCAN TABLE FOR EXPRESSION ANALYZER                79320001
         EJECT                                                          79380001
*              TRANSLATE TABLE FOR MAIN SCAN.                           79440001
         DS    0F                                                       79500001
T1       DC    134X'0'       00-85                                      79560001
         DC    X'0C'         86        SNAP                             79620001
         DC    X'0'          87                                         79650001
         DC    X'18'         88        SYSTEM                           79680001
         DC    39X'0'        89-AF                                      79710001
         DC    3X'0'         B0-B2                                      79740001
         DC    X'14'         B3        PROC                             79800001
         DC    X'0'          B4                                         79860001
         DC    X'14'         B5        BEGIN                            79920001
         DC    X'0'          B6                                         79980001
         DC    X'10'         B7        ITDO                             80040001
         DC    4X'0'         B8-BB                                      80100001
         DC    X'08'         BC        SN2                              80160001
         DC    X'0'          BD                                         80220001
         DC    X'0C'         BE        NOSNAP                           80280001
         DC    X'0'          BF                                         80340001
         DC    16X'0'        C0-CF                                      80400001
         DC    X'08'         D0        SN                               80460001
         DC    X'0'          D1                                         80520001
         DC    X'04'         D2        SL                               80580001
         DC    13X'0'        D3-DF                                      80640001
         DC    16X'0'        E0-EF                                      80700001
         DC    3X'0'         F0-F2                                      80760001
         DC    X'14'         F3        PROC'                            80820001
         DC    X'0'          F4                                         80880001
         DC    X'14'         F5        BEGIN'                           80940001
         DC    10X'0'        F6-FF                                      81000001
         SPACE 1                                                        81060001
*              END OF MAIN SCAN TRANSLATE TABLE.                        81120001
         EJECT                                                          81180001
*              TRANSLATE TABLE TO CONVERT ON-CODES TO A SHIFT TO SET    81240001
*       THE 'XLCRONUS' MASK.                                            81300001
         DS    0F                                                       81360001
ONTRT    EQU   *-X'D0'                                                  81420001
         DC    X'00'         D0        OVERFLOW                         81480001
         DC    X'20'                                                    81540001
         DC    X'01'         D2        UNDERFLOW                        81600001
         DC    X'20'                                                    81660001
         DC    X'02'         D4        ZERODIVIDE                       81720001
         DC    X'20'                                                    81780001
         DC    X'03'         D6        FIXED OVERFLOW                   81840001
         DC    X'20'                                                    81900001
         DC    X'04'         D8        SUBSCRIPT RANGE                  81960001
         DC    X'20'                                                    82020001
         DC    X'20'         DA        ERROR                            82080001
         DC    X'20'                                                    82140001
         DC    X'0D'         DC        FINISH                           82200001
         DC    X'20'                                                    82260001
         DC    X'05'         DE        SIZE                             82320001
         DC    X'20'                                                    82380001
         DC    X'06'         E0        CONVERSION                       82440001
         DC    X'20'                                                    82500001
         DC    X'07'         E2        STRING RANGE                     82560001
         DC    X'20'                                                    82620001
         DC    X'08'         E4        AREA                             82680001
         DC    X'13'         E5        PENDING                          82740001
         DC    X'0B'         E6        ENDFILE                          82800001
         DC    X'20'                                                    82860001
         DC    X'10'         E8        RECORD                           82920001
         DC    X'20'                                                    82980001
         DC    X'0C'         EA        END PAGE                         83040001
         DC    X'20'                                                    83100001
         DC    X'0E'         EC        KEY                              83160001
         DC    X'20'                                                    83220001
         DC    X'12'         EE        UNDEFINED FILE                   83280001
         DC    X'20'                                                    83340001
         DC    X'0A'         F0        CONDITION                        83400001
         DC    X'20'                                                    83460001
         DC    X'0F'         F2        NAME                             83520001
         DC    X'20'                                                    83580001
         DC    X'11'         F4        TRANSMIT                         83640001
         DC    3X'20'                                                   83700001
         DC    X'09'         F8        CHECK(VARIABLE)            54703 83760064
         DC    X'20'                                              54703 83790064
         DC    X'09'         FA        CHECK(LABEL)               54703 83820064
         DC    X'20'                                              54703 83850064
         DC    X'20'         FC        NOCHECK                          83880001
         DC    3X'20'                                                   83940001
         EJECT                                                          84000001
RESULT   DC    F'0'                                                     84060001
SIPR     DC    F'0'                                                     84120001
SRR      DC    2F'0'                                                    84180001
SRRT     DC    F'0'                                                     84240001
REORZ    DC    F'0'                    START OF REORDER LIST            84300001
REORC    DC    F'0'                    CURRENT POSITION IN REORDER LIST 84360001
H5       DC    H'5'                                                     84420001
STKN     DC    H'8'                    SIZE OF DO NEST STACK ITEM       84480001
MOVEZ    DC    F'0'                    START OF MOVE LIST               84540001
MOVEC    DC    F'0'                    CURRENT POSITION IN MOVE LIST    84600001
         DC    H'-5'                                                    84660001
ETYPE1   DC    H'0'                    CURRENT ENTRY TYPE 1.            84720001
STKC     DC    F'0'                    CURRENT TOP OF DO STACK          84780001
STKZ     DC    F'0'                                                     84840001
ONMASK   DC    F'0'                                                     84900001
MTEMP    DC    F'0'                    TEMPORORY MOVE POINTER           84930001
BIT1     DC    X'80000000'                                              84960001
X00FF    DC    X'00FF'                                                  85020001
DUM      DC    5X'0'                                                    85080001
INSFLG   DC    X'0'                    INSERT SCAN FLAG                 85140001
REORD    DC    X'00'                                                    85200001
DOREF    DC    3X'0'                   SYMB TEXT PTR - OUTER SCAN       85260001
ANREF    DC    3X'0'                   SYMB TEXT PTR - REORDER SCAN     85320001
INREF    DC    3X'0'                   SYMB TEXT PTR - INSERT SCAN      85380001
SDIC     DC    X'8F001B0000'                                            85440001
         DC    6X'00'                                                   85500001
         DC    X'80'                                                    85560001
         DC    15X'00'                                                  85620001
SDICND   EQU   *                                                        85680001
COMBIN   DC    X'00'                   TYPE COMBINATION SWITCH          85700001
SKACT    DC    X'4500000000'           TRIPLE SKELETON FOR ARG COMBINE  85720001
SKASN    DC    AL1(TRASN)              ASSIGN  TEMP  00                 85740001
         DC    X'00000000'                                              85800001
         END   IEMKC                                                    85860001
