KE       TITLE 'PL/1 (F) COMPILER PHASE KE. DO-MAP BUILD TEXT SCAN.'    00010020
*                                                                       00020020
* 5.5  A 404610-405080,429120-429560,445400-445600            MCB 62605 00030072
*      C 408100,408800-411200,413000,414200,414300-414700,    MCB 62605 00032072
*      C 415100,418600,427720,427750,427780,427800-427880,    MCB 62605 00034072
*      C 427910,428500                                        MCB 62605 00036072
* 5.4  C 303300,303500.                                       MAC 52193 00040021
* 5.2  A 290500,310800.                                       MAC 32241 00047021
* 5.0  C 163860-163920,164130-164340.                         MAC  H328 00054021
*      D 209460,209780.                                       MAC  H328 00061021
*                                                                       00070801
*                                                                       00071001
*              FUNCTIONS - (1) SCAN THE DICTIONARY LOOKING FOR 'UNSAFE' 00071201
*        VARIABLES AND FLAGGING THEIR DICTIONARY ENTRIES. DURING THE    00072001
*        SCAN A TABLE CONTAINING THE DICTIONARY REFERENCES OF THE       00073001
*        TYPE 1 ENTRIES OF PROCS AND BEGINS AND POINTER VARIABLES IS    00074001
*        BUILT AND FLAGS ARE SET TO INDICATE THE PRESENCE OF CERTAIN    00075001
*        TYPES OF VARIABLES.                                            00076001
*                          (2) SCAN THE TEXT BUILDING A DO-MAP WHICH    00077001
*        IS A TABLE CONTAINING AN ENTRY FOR EACH PROCEDURE AND DO-LOOP  00078001
*        IN THE PROGRAM. DURING THE TEXT SCAN THE TABLE BUILT IN (1)    00079001
*        IS USED TO LOOK FOR FUNCTION OR PROCEDURE CALLS WHICH MAKE     00080001
*        THEIR ARGUMENTS UNSAFE.                                        00081001
         SPACE 3                                                        00082001
*              ENTRY POINT - 'IEMKE' FROM COMPILER CONTROL TO START     00083001
*        OF PHASE.                                                      00084001
         SPACE 3                                                        00085001
*              INPUT - DICTIONARY ENTRIES AND TEXT IN FORM OF TRIPLES.  00086001
         SPACE 3                                                        00087001
*              OUTPUT - DICTIONARY ENTRIES FOR UNSAFE VARIABLES ARE     00088001
*        MARKED WITH BIT FLAGS. A TABLE IS BUILT USING IEMKTAB MACROS.  00089001
*        THE TCA FOR THE TABLE IS IN THE LOCAL COMMUNICATIONS REGION    00090001
*        IN PHASE KA.                                                   00091001
         SPACE 3                                                        00092001
*              EXTERNAL ROUTINES (1) CONTROL PHASE. THE FOLLOWING       00093001
*        ENTRIES ARE USED - 'ZDRFAB' 'ZUERR' 'ZABORT' 'RLSCTL'.         00094001
*                                (2) TABLE HANDLING (IEMKA). THE        00095001
*        FOLLOWING ENTRIES ARE USED - 'KAHTXT' 'KAHSET' 'KAHBLD'        00096001
*        'KAHMDR' 'KAHDAC' 'KAHERR'.                                    00097001
         SPACE 3                                                        00098001
*              EXIT - NORMAL - 'RLSCTL' IN CONTROL PHASE TO RELEASE     00099001
*        PHASE AND LOAD NEXT.                                           00100001
         SPACE 3                                                        00101001
*              EXIT - ERROR - (1) 'ZABORT' IN COMPILER CONTROL IF A     00102001
*        COMPILER ERROR IS DETECTED BY THE PHASE. TERMINAL MESSAGE      00103001
*        IEM1210I IS GIVEN.                                             00104001
*                             (2) 'KAHERR' IN PHASE KA IF AN ERROR      00105001
*        OCCURS IN TABLE HANDLING. TERMINAL MESSAGE IEM1224I IS GIVEN.  00106001
         SPACE 3                                                        00107001
*              WORKAREA - A MAXIMUM OF 600 BYTES OF THE SCRATCH CORE    00108001
*        OBTAINED BY PHASE KA IS USED AS A STACK DURING THE TEXT SCAN.  00109001
         SPACE 3                                                        00110001
*              ATTRIBUTES - THIS BLOCK IS NOT READ-ONLY AND NOT         00111001
*        REENTRANT.                                                     00112001
         SPACE 3                                                        00113001
*              NOTES - (1) THIS PHASE REQUIRES NO MODIFICATION AS A     00114001
*        RESULT OF CHANGES IN THE INTERNAL REPRESENTATION OF EXTERNAL   00115001
*        GRAPHICS.                                                      00116001
*                      (2) THIS PHASE REQUIRES THE 'IEMK' MACROS FOR    00117001
*        ASSEMBLY.                                                      00118001
*                      (3) THIS PHASE CONSISTS OF 2 CONTROL SECTIONS    00119001
*        - 'IEMKE' AND 'IEMKE1'. NOTE THAT IEMKE1 (THE DICTIONARY SCAN  00120001
*        ROUTINE) WAS ORIGINALLY A SEPERATE PHASE CALLED KC. THE        00121001
*        COMBINATION HAS CAUSED SOME DISCREPANCY IN LABELLING           00122001
*        CONVENTIONS BETWEEN THE TWO DSECTS.                            00123001
*                                                                       00124001
         EJECT                                                          00125001
         MACRO                                                          00140001
&NAME    GETDICT &DICREF,&XDICBSE                                       00210001
*                                                                       00280001
&NAME    MVC   PAR1+2(2),&DICREF . MOVE DIC.REF. TO PARAMETER FIELD     00350001
         L     LR,ZDRFAB .         LINK TO ZDRFAB                       00420001
         BALR  RR,LR .               TO CONVERT DIC.REF. TO ABSOLUTE    00490001
         L     &XDICBSE,PAR1 .          BASE XDIC DSECT                 00560001
*                                                                       00630001
         MEND                                                           00700001
         EJECT                                                          00770001
         COPY  IEMKCOM                                                  00840001
         COPY  IEMKUTL                                                  00910001
*                                                                       00980001
** EQUATES FOR CONDITION CODE MASKS                                     01050001
*                                                                       01120001
ONES     EQU   1                                                        01190001
HI       EQU   2                                                        01260001
LO       EQU   4                                                        01330001
EQ       EQU   8                                                        01400001
*                                                                       01470001
** LOCAL REGISTER EQUATES                                               01540001
*                                                                       01610001
XTSCBASE EQU   8                   BASE REGISTER FOR XTSC DSECT         01680001
XTRPBASE EQU   7                    ,;     ,,    ,,  XTRP  ,,           01750001
XSTKBASE EQU   6                    ,,     ,,    ,,  XSTK  ,,           01820001
*                                                                       01890001
** ERROR CODE EQUATES                                                   01960001
*                                                                       02030001
ERR1     EQU   1                   STACK ERROR IN KEPRCP                02100001
ERR2     EQU   2                   STACK ERROR IN KEBGNP                02170001
ERR3     EQU   3                   STACK ERROR IN KEITDP                02240001
ERR4     EQU   4                   INSUFFICIENT SCRATCH CORE IN KEFUNC  02310001
ERR5     EQU   5                       ,,          ,,    ,,  ,, KESTCK  02380001
ERR6     EQU   6                   EOP TRIPLE PROCESSED                 02450001
*                                                                       02520001
XTSCDEL  IEMKTCA ET=F,L=3,OPS=S TO SUPPORT IEMKTAB MACROS               02590001
XTSCARG  IEMKTCA ET=F,L=2,OPS=S TO SUPPORT IEMKTAB MACROS               02660001
         EJECT                                                          02730001
         COPY  IEMKEQU                                                  02800001
         COPY  IEMKLCR                                                  02870001
         COPY  IEMKDFM                                                  02940001
*                                                                       03010001
** THE XSTK DSECT DESCRIBES AN ENTRY IN THE STACK.                      03080001
*                                                                       03150001
XSTK     DSECT                                                          03220001
         SPACE                                                          03290001
         USING *,XSTKBASE          PERMANENTLY BASED BY GR6             03360001
         SPACE                                                          03430001
*                                                                       03500001
XSTKCOPT DS    X                   STORE FOR XTSCOPT                    03570001
XSTKCUDO DS    XL3                 STORE FOR XTSCCUDO                   03640001
*                                                                       03710001
XSTKDCLV DS    XL2                 STORE FOR XTSCDCLV                   03780001
XSTKCODE DS    XL1                 CODE BYTE AND STORE FOR XTSCCVBT:    03850001
XSTKPROC EQU   X'08'                 ENTRY FOR PROC TRIPLE              03920001
XSTKBEGN EQU   X'04'                 ENTRY FOR BEGN TRIPLE              03990001
XSTKITDO EQU   X'02'                 ENTRY FOR ITDO TRIPLE              04060001
XSTKFUNC EQU   X'01'                 ENTRY FOR FUNC TRIPLE              04130001
XSTKDRPB DS    XL2                 STORE FOR XTSCDRPB                   04200001
XSTKFCBT DS    X                   STORE FOR XTSCFCBT                   04270001
XSTKSLCT DS    XL2                 STORE FOR XTSCSLCT                   04340001
XSTKEND  EQU   *                                                        04410001
*                                                                       04480001
         EJECT                                                          04550001
*                                                                       04620001
** THE XDIC DSECT DESCRIBES CERTAIN DICTIONARY ENTRY FIELDS.            04690001
*                                                                       04760001
XDIC     DSECT                                                          04830001
*                                                                       04900001
XDICCODE DS    X                   ENTRY TYPE CODE BYTE                 04970001
XDICDVAR EQU   X'0F'               DATA VARIABLE                        05040001
XDICDDVA EQU   X'1F'               DIMENSIONED DATA VARIABLE            05110001
XDICDVIS EQU   X'2F'               DATA VARIABLE IN STRUCTURE           05180001
XDICDDVS EQU   X'3F'               DIMENSIONED DATA VARIABLE IN STRUCT. 05250001
XDICTEMP EQU   X'80'               NO BCD INDICATES TEMPORARY           05320001
         SPACE                                                          05390001
XDICLENG DS    XL2                 LENGTH OF DICTIONARY ENTRY           05460001
         SPACE                                                          05530001
XDICDCLV DS    0XL2                DECLARE LEVEL OF PROCEDURE OR BEGIN  05600001
         DS    XL2                 FILLER                               05670001
XDICOFS1 DS    XL3                 OFFSET 1 FIELD                       05740001
         DS    XL4                 FILLER                               05810001
XDICOTH2 DS    X                   OTHER2 CODE BYTE                     05880001
XDICFPRM EQU   X'08'               FORMAL PARAMETER BIT                 05950001
XDICOTH3 DS    X                   OTHER 3 CODE BYTE                    06020001
XDICUNSF EQU   X'04'               SET ON IF VARIABLE IS UNSAFE         06090001
XDICOTH4 DS    X                   OTHER 4 CODE BYTE                    06160001
XDICDATA DS    X                   DATA CODE BYTE                       06230001
XDICPREC DS    XL2                 PRECISION AND SCALING                06300001
XDICINTG EQU   X'80'               TYPE INTEGER                         06370001
         ORG   XDIC+55                                                  06440001
XDICOB81 DS    X                   OPTIMISATION BYTE FOR TYPE 81 ENTRY  06510001
         ORG   XDIC+63                                                  06580001
XDICOB80 DS    X                   OPTIMISATION BYTE FOR TYPE 80 ENTRY  06650001
XDICREOR EQU   X'04'               ON FOR REORDER, OFF FOR ORDER        06720001
*                                                                       06790001
         EJECT                                                          06860001
         COPY  IEMKMAP                                                  06930001
         COPY  IEMKTRP                                                  07000001
         COPY  IEMKDEL                                                  07070001
*                                                                       07140001
** STANDARD PHASE HEADER.                                               07210001
*                                                                       07280001
IEMKE    CSECT                                                          07350001
         DC    C'KE'               PHASE IDENTIFIER                     07490001
         IEMKPLR KE,KEINIT,DL=KEZZ,LL=0,BASEREG=GR8                     07520001
*                                                                       07560001
         EJECT                                                          07630001
*                                                                       07700001
** KEINIT. THIS ROUTINE PERFORMS INITIALISATION AND CLEAN-UP FUNCTIONS. 07770001
**   PERMANENT BASE REGISTERS ARE LOADED, FIELDS IN THE XTSC CONTROL    07840001
**   BLOCK ARE INITIALIZED. KCDSIN IS CALLED TO PERFORM THE DICTIONARY  07910001
**   SCAN. AND KESCAN IS CALLED TO PERFORM THE TEXT SCAN. WHEN CONTROL  07980001
**   RETURNS FROM KESCAN THE TWO INTERNAL TABLES (XTSCDEL AND XTSCARG)  08050001
**   ARE FREED AND THE TEXT AND DO-MAP TABLES ARE DEACTIVATED.          08120001
*                                                                       08190001
KEINIT   IEMKENT TYPE=2                                                 08260001
         USING XTRP,XTRPBASE                                            08330001
*                                                                       08400001
         USING IEMKE1,GR9                                               08540001
*                                                                       08610001
         L     GR9,=A(IEMKE1)      BASE 2ND CSECT                       08750001
*                                                                       08820001
         SPACE                                                          08890001
         SPACE                                                          09030001
         SPACE                                                          09100001
       IEMKTAB SETZ,XLCRTXT                                             09170001
         SPACE                                                          09240001
         L     XSTKBASE,XLCRUASC   LOAD INITIAL STACK ADDRESS           09310001
         MVI   XTSCTRTB+XTRPPROC,X'4'   BUILD TRANSLATE TABLE           09380001
         MVI   XTSCTRTB+XTRPPRCP,X'8'                                   09450001
         MVI   XTSCTRTB+XTRPBEGN,X'C'                                   09520001
         MVI   XTSCTRTB+XTRPBGNP,X'10'                                  09590001
         MVI   XTSCTRTB+XTRPITDO,X'14'                                  09660001
         MVI   XTSCTRTB+XTRPITDP,X'18'                                  09730001
         MVI   XTSCTRTB+XTRPFUNC,X'1C'                                  09800001
         MVI   XTSCTRTB+XTRPGETD,X'20'                                  09870001
         MVI   XTSCTRTB+XTRPFNCM,X'24'                                  09940001
         MVI   XTSCTRTB+XTRPSUBS,X'28'                                  10010001
         MVI   XTSCTRTB+XTRPSUBP,X'2C'                                  10080001
         MVI   XTSCTRTB+XTRPCV,X'30'                                    10150001
         MVI   XTSCTRTB+XTRPCVP,X'34'                                   10220001
         MVI   XTSCTRTB+XTRPUDCM,X'38'                                  10290001
         MVI   XTSCTRTB+XTRPWHIL,X'38'                                  10360001
         MVI   XTSCTRTB+XTRPBYP,X'3C'                                   10430001
         MVI   XTSCTRTB+XTRPTOP,X'40'                                   10500001
         MVI   XTSCTRTB+XTRPEIO,X'44'                                   10570001
         MVI   XTSCTRTB+XTRPSTNO,X'48'                                  10640001
         MVI   XTSCTRTB+XTRPPUT,X'4C'                                   10670001
         MVI   XTSCTRTB+XTRPFNCP,X'50'                                  10710001
         MVI   XTSCTRTB+XTRPFMAT,X'54'                                  10730001
         MVI   XTSCTRTB+XTRPFMTP,X'58'                                  10750001
         SPACE                                                          10780001
         BAL   RR,KCDSIN           CALL DICT. SCAN ROUTINE              10850001
       IEMKTAB DEACT,XTSCDEL                                            10880001
         BAL   RR,KESCAN           CALL TEXT SCAN ROUTINE               10920001
         SPACE                                                          10990001
*                                                                       11060001
** CLEAN-UP SECTION.                                                    11130001
*                                                                       11200001
       IEMKTAB FREE,XTSCDEL                                             11270001
       IEMKTAB DEACT,(XLCRTXT,XLCRMAP)                                  11340001
       IEMKTAB TEST,XTSCARG,NTA=INITEXIT                                11410001
       IEMKTAB FREE,XTSCARG                                             11480001
*                                                                       11550001
INITEXIT IEMKLVE                                                        11620001
         EJECT                                                          11690001
*                                                                       11760001
** KESCAN. SCAN TEXT AND SELECT INTERESTING TRIPLES.                    11830001
**   THIS ROUTINE PERFORMS A SEQUENTIAL SCAN OF TEXT, TRANSLATING THE   11900001
**   CODE BYTE USING THE XTSCTRTB TRANSLATE TABLE. EACH TABLE ENTRY IS  11970001
**   ZERO IF THAT TRIPLE IS TO BE IGNORED (IN WHICH CASE THE NEXT       12040001
**   TRIPLE IS PROCESSED) OR A MULTIPLE OF FOUR, IN WHICH CASE THIS     12110001
**   VALUE IS USED TO BRANCH VIA A BRANCH TABLE TO THE APPROPRIATE      12210001
**   TRIPLE PROCESSING ROUTINE.                                         12310001
*                                                                       12460001
KESCAN   IEMKENT  TYPE=2                                                12530001
SCANNTRP DS    0H                                                       12570001
       IEMKTAB SCAN,XLCRTXT,TRTAB=XTSCTRTB,FBTO=(GR2),AATO=(XTRPBASE), -12610001
               SATO=XTSCCUTR,PSATO=XTSCTRPT                             12670001
         B     SCANRTAB-4(2)       BRANCH TO PROCESSING ROUTINE         12740001
*                                                                       12810001
SCANEXIT IEMKLVE                                                        12880001
         SPACE                                                          12950001
*                                                                       13020001
         EJECT                                                          13090001
*                                                                       13160001
** TRANSFER VECTOR TO TRIPLE PROCESSING ROUTINES                        13230001
*                                                                       13300001
SCANRTAB B     KEPROC              4 - PROC                             13370001
         B     KEPRCP              8 - PROC'                            13440001
         B     KEBEGN              C - BEGIN                            13510001
         B     KEBGNP             10 - BEGIN'                           13580001
         B     KEITDO             14 - ITERATIVE DO                     13650001
         B     KEITDP             18 - ITDO'                            13720001
         B     KEFUNC             1C - FUNCTION                         13790001
         B     KEGETD             20 - GET                              13860001
         B     KEFNCM             24 - FUNCTION COMMA                   13930001
         B     KESUBS             28 - SUBSCRIPT                        14000001
         B     KESUBP             2C - SUBSCRIPT'                       14070001
         B     KEPCVT             30 - CV                               14140001
         B     KEPCVP             34 - CV'                              14210001
         B     KEWUDC             38 - WHILE, UPSIDE-DOWN COMMA         14280001
         B     KEPBYT              3C - BY'                             14350001
         B     KEPTOT             40 - TO'                              14420001
         B     KEPEIO             44 - END I/O                          14490001
         B     KESTNO             48 - STATEMENT NUMBER                 14560001
         B     KEPPUT             4C - PUT                              14630001
         B     KEFNCP             50 - FUNCTION'                        14700001
         B     KEFMAT             54 - FORMAT                           14720001
         B     KEFMTP             58 - FORMAT'                          14740001
*                                                                       14770001
** END OF TABLE                                                         14840001
*                                                                       14910001
         EJECT                                                          14980001
*                                                                       15050001
** KEPROC. THIS ROUTINE PROCESSES THE PROC TRIPLE.                      15120001
**   THE NESTING LEVEL IS SET TO ZERO, AND THE CURRENT LOOP STATUS      15190001
**   FIELDS ARE STACKED. THE DECLARE LEVEL OF THE PROCEDURE IS OBTAINED 15260001
**   FROM ITS DICTIONARY ENTRY AND A DO-MAP ENTRY IS CREATED FOR THE    15330001
**   PROCEDURE.                                                         15400001
*                                                                       15470001
KEPROC   IEMKENT  TYPE=3                                                15540001
         USING XDIC,GR5                                                 15610001
*                                                                       15680001
         MVI   XTSCLEVL,X'00'      SET DO-LOOP NESTING LEVEL TO ZERO    15750001
         SPACE                                                          15820001
         LA    PR1,XSTKPROC        INDICATE PROC STACK ENTRY TO KESTCK  15890001
         BAL   RR,KESTCK           CALL STACK ROUTINE                   15960001
         LR    XSTKBASE,RC         LOAD NEW STACK ENTRY ADDRESS         16030001
         SPACE                                                          16100001
         GETDICT XTRPOP2,GR5       GET DICT. ENT. FOR PROCEDURE         16170001
         SPACE                                                          16240001
         MVC   XTSCDRPB,XTRPOP2    STORE DICT. REF. OF ENTRY TYPE 1     16310001
         MVC   XTSCDCLV,XDICDCLV   STORE DECLARE LEVEL OF CURRENT TEXT  16380001
*                                                                       16383001
         LH    GR2,XTSCBPIC             ) INCREMENT PREVIOUS       H328 16387001
         LA    GR2,1(0,GR2)             ) COUNT BY ONE             H328 16391001
*                                                                       16395001
         SR    GR1,GR1                  ) COMPARE THIS VALUE WITH       16398001
         IC    GR1,XTSCDCLV+1           ) CURRENT COUNT IN DICT.        16401001
         CR    GR1,GR2                  ) ENTRY TYPE 1                  16404001
         BE    PROCINCL                 BRANCH EQUAL  IE NOT ON UNIT    16407001
*                                                                       16410001
         MVC   XTSCDCLV+1(1),XTSCBPIC+1      RESET XTSCDCLV+1      H328*16414001
                                 SINGLE STATEMENT ON UNIT FOUND    H328 16418001
         B     PROCCONT                 CONTINUE                   H328 16422001
*                                                                  H328 16426001
PROCINCL STH   GR2,XTSCBPIC             UPDATE XTSCBPIC            H328 16430001
*                                                                       16437001
PROCCONT MVI   XTSCCOPT,X'00'           TURN OPTION BIT OFF             16477001
         TM    XDICOB80,XDICREOR   TEST FOR REORDER OPTION              16520001
         BO    PROCCDME            BRANCH IF ON                         16590001
         OI    XTSCCOPT,XTSCORDR   INDICATE ORDER                       16660001
PROCCDME EQU   *                                                        16730001
         SPACE                                                          16800001
         BAL   RR,KECDME           CALL ROUTINE TO CREATE DO-MAP ENTRY  16870001
         SPACE                                                          16940001
PROCEXIT IEMKLVE  RC=(RC),RP=SCANNTRP   RETURN TO PROCESS NEXT TRIPLE   17010001
         DROP  GR5                                                      17080001
         EJECT                                                          17150001
*                                                                       17220001
** KEPRCP. THIS ROUTINE PROCESSES THE PRC' TRIPLE.                      17290001
**   THE DO-END ROUTINE (KEDEND) IS CALLED TO COMPLETE THE DO-MAP ENTRY 17360001
**   FOR THE PROCEDURE AND RESTORE THE DO-LOOP STATUS FIELDS FROM THE   17430001
**   STACK. A TEST IS MADE TO SEE IF THE SCAN IS COMPLETE - IE THE LINK 17500001
**   FIELD TO AN OUTER DO-MAY ENTRY IS ZERO. IF SO, RETURN IS TO        17570001
**   SCANEXIT WHICH RETURNS CONTROL TO THE CLEAN-UP PHASE. OTHERWISE,   17640001
**   THE LOOP LEVEL FIELD IS RESET FROM THE NEXT OUTER DO-MAP ENTRY,    17710001
**   AND CONTROL RETURNS TO SCANNTRP TO PROCESS THE NEXT TRIPLE.        17780001
*                                                                       17850001
KEPRCP   IEMKENT  TYPE=3                                                17920001
         USING XMAP,GR5                                                 17990001
*                                                                       18060001
         TM    XSTKCODE,XSTKPROC   TEST IF TOP STACK ENTRY FOR PROC     18130001
         BO    PRCPDEND            BRANCH IF IT IS                      18200001
         LA    PR0,ERR1            ERROR IN STACK - LOAD ERROR CODE     18270001
         BAL   RR,KEERRH           CALL ERROR HANDLER                   18340001
         SPACE                                                          18410001
PRCPDEND BAL   RR,KEDEND           CALL DO-END ROUTINE                  18480001
         LR    XSTKBASE,RC         UPDATE STACK POINTER                 18550001
         SPACE                                                          18620001
         CLI    XTSCCUDO,X'FF'     TEST FOR END OF TEXT SCAN            18690001
         BNE   PRCPGODM            BRANCH IF NOT                        18760001
         LA    LR,SCANEXIT         SET LR TO CAUSE EXIT FROM KESCAN     18830001
         B     PRCPEXIT            GO TO KEPRCP EXIT                    18900001
         SPACE                                                          18970001
PRCPGODM DS    0H                                                       19010001
       IEMKTAB DR,XLCRMAP,SA=XTSCCUDO,AATO=(GR5)                        19050001
         SR    GR2,GR2             RESET                                19110001
         IC    GR2,XMAPLEVL          DO-LOOP                            19180001
         LA    GR2,1(0,GR2)          NESTING                            19250001
         STC   GR2,XTSCLEVL          LEVEL                              19320001
         SPACE                                                          19390001
         LA    LR,SCANNTRP         SET RETURN TO PROCESS NEXT TRIPLE    19460001
*                                                                       19530001
PRCPEXIT IEMKLVE  RP=(LR),RC=(RC)                                       19600001
         DROP  GR5                                                      19670001
         EJECT                                                          19740001
*                                                                       19810001
** KEBEGN. THIS ROUTINE PROCESSES THE BEGN TRIPLE.                      19880001
**   THE CURRENT LOOP STATUS FIELDS ARE STACKED AND THE DECLARE LEVEL   19950001
**   OF THE BEGIN IS OBTAINED FROM ITS DICTIONARY ENTRY.                20020001
**   THE OPTION (ORDER OR REORDER) FLAG IN THE ENTRY IS TESTED AND THE  20030001
**   SETTING STORED FOR MARKING DO-MAP ENTRIES FOR DO-LOOPS. IF THE     20040001
**   OPTION IS ORDER AND ORDER IS NOT CURRENTLY RULING, THE DO-MAP      20050001
**   ENTRY FOR THE NEXT OUTER LOOP OR PROCEDURE IS MARKED TO INDICATE   20060001
**   ORDER.                                                             20070001
*                                                                       20090001
KEBEGN   IEMKENT  TYPE=3                                                20160001
         USING XDIC,GR5                                                 20230001
         USING XMAP,GR4                                                 20300001
*                                                                       20370001
         LA    PR1,XSTKBEGN        INDICATE BEGIN STACK ENTRY TO KESTCK 20440001
         BAL   RR,KESTCK           MAKE STACK ENTRY                     20510001
         LR    XSTKBASE,RC         LOAD NEW STACK ENTRY ADDRESS         20580001
         SPACE                                                          20650001
         GETDICT XTRPOP2,GR5       GET DICT.ENTRY OF BEGIN              20720001
         SPACE                                                          20790001
         MVC   XTSCDRPB,XTRPOP2    STORE DICT. REF. OF ENTRY TYPE 1     20860001
         MVC   XTSCDCLV,XDICDCLV   MOVE NEW DECLARE LEVEL TO XTSC       20930001
*                                                                       20938001
         LH    GR2,XTSCBPIC             ) INCREMENT                     20954001
         LA    GR2,1(0,GR2)             ) COUNT BY                      20962001
         STH   GR2,XTSCBPIC             ) ONE                           20970001
*                                                                       20986001
         TM    XDICOB81,XDICREOR   TEST FOR REORDER OPTION              21000001
         BO    BEGNMOPT            BRANCH IF ON                         21070001
         TM    XTSCCOPT,XTSCORDR   TEST IF ORDER OPERATIVE              21140001
         BO    BEGNEXIT            EXIT IF SO                           21210001
       IEMKTAB DR,XLCRMAP,SA=XTSCCUDO,AATO=(GR4)                        21280001
         MVI   XMAPOPTN,XMAPORDR   MOVE IN ORDER TO OUTER DO LOOP       21350001
         MVI   XTSCCOPT,XTSCORDR   INDICATE ORDER OPERATIVE             21380001
         B     BEGNEXIT            EXIT                                 21420001
         SPACE                                                          21490001
BEGNMOPT MVI   XTSCCOPT,X'00'      INDICATE REORDER                     21560001
*                                                                       21630001
BEGNEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     21700001
         DROP  GR5                                                      21770001
         DROP  GR4                                                      21840001
         EJECT                                                          21910001
*                                                                       21980001
** KEBGNP. THIS ROUTINE PROCESSES THE BGN' TRIPLE.                      22050001
**   THE CURRENT OPTION AND DECLARE LEVEL FIELDS ARE RESTORED AND       22120001
**   THE TOP STACK ENTRY REMOVED.                                       22190001
*                                                                       22260001
KEBGNP   IEMKENT  TYPE=3                                                22330001
         SPACE                                                          22400001
         TM    XSTKCODE,XSTKBEGN   TEST IF TOP STACK ENTRY FOR BEGN     22470001
         BO    BGNPRSTO            BRANCH IF IT IS                      22540001
         LA    PR0,ERR2            ERROR IN STACK - LOAD ERROR CODE     22610001
         BAL   RR,KEERRH           CALL ERROR HANDLER                   22680001
         SPACE                                                          22750001
BGNPRSTO MVC   XTSCCOPT,XSTKCOPT   RESTORE CURRENT OPTION               22820001
         MVC   XTSCDCLV,XSTKDCLV   RESTORE DECLARE LEVEL                22890001
         MVC   XTSCDRPB,XSTKDRPB   RESTORE D.R. OF ENTRY TYPE 1         22960001
         SPACE                                                          23030001
         LA    XSTKBASE,XSTKEND-XSTK(0,XSTKBASE) REMOVE TOP STACK ENTRY 23100001
*                                                                       23170001
BGNPEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     23240001
         EJECT                                                          23310001
*                                                                       23380001
** KEITDO. THIS ROUTINE PROCESSES THE ITDO TRIPLE.                      23450001
**   THE CURRENT DO-MAP ENTRY IS MARKED AS A  NON-INNERMOST LOOP, THE   23520001
**   CURRENT LOOP STATUS FIELDS ARE STACKED, A DO-MAP ENTRY IS CREATED  23590001
**   FOR THE DO-LOOP AND IS CHAINED TO THE PREVIOUS (NEXT OUTER) ENTRY. 23660001
*                                                                       23730001
KEITDO   IEMKENT  TYPE=3                                                23800001
         USING XMAP,GR5                                                 23870001
*                                                                       23940001
       IEMKTAB DR,XLCRMAP,SA=XTSCCUDO,AATO=(GR5)                        24010001
         OI    XMAPTYPE,XMAPNTIN   SET NOT-INNERMOST BIT ON             24080001
*                                                                       24090001
         LH    GR2,XTSCBPIC             ) INCREMENT                     24100001
         LA    GR2,1(0,GR2)             ) COUNT BY                      24110001
         STH   GR2,XTSCBPIC             ) ONE                           24120001
         STC   GR2,XTSCDCLV+1           STORE IN XTSCDCLV 2ND BYTE      24130001
*                                                                       24140001
         SPACE                                                          24150001
         LA    PR1,XSTKITDO        INDICATE ITDO STACK ENTRY            24220001
         BAL   RR,KESTCK           MAKE STACK ENTRY                     24290001
         LR    XSTKBASE,RC         LOAD NEW STACK ENTRY ADDRESS         24360001
         SPACE                                                          24430001
         BAL   RR,KECDME           CREATE DO-MAP ENTRY                  24500001
*  PR1 NOW POINTS TO NEW DO MAP ENTRY                                   24570001
         LR    GR5,PR1             BASE XMAP DSECT FOR NEW ENTRY        24640001
         MVC   XMAPOUTR,XSTKCUDO   CHAIN NEW ENTRY TO NEXT OUTER ENTRY  24710001
*                                                                       24780001
ITDOEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     24850001
         DROP  GR5                                                      24920001
         EJECT                                                          24990001
*                                                                       25060001
** KEITDP. THIS ROUTINE PROCESSES THE ITD' TRIPLE.                      25130001
**   THE DO-END ROUTINE IS CALLED TO COMPLETE THE DO-MAP ENTRY FOR THIS 25200001
**   LOOP, AND THE NESTING LEVEL IS REDUCED BY ONE.                     25270001
*                                                                       25340001
KEITDP   IEMKENT  TYPE=3                                                25410001
         SPACE                                                          25480001
         TM    XSTKCODE,XSTKITDO   TEST IF TOP STACK ENTRY FOR ITDO     25550001
         BO    ITDPDEND            BRANCH IF IT IS                      25620001
         LA    PR0,ERR3            ERROR IN STACK - LOAD ERROR CODE     25690001
         BAL   RR,KEERRH           CALL ERROR HANDLER                   25760001
         SPACE                                                          25830001
ITDPDEND BAL   RR,KEDEND           CALL DO-END ROUTINE                  25900001
         LR    XSTKBASE,RC         UPDATE STACK POINTER                 25970001
         SPACE                                                          26040001
         SR    GR2,GR2             REDUCE                               26110001
         IC    GR2,XTSCLEVL          NESTING                            26180001
         BCTR  GR2,0                 LEVEL                              26250001
         STC   GR2,XTSCLEVL          BY ONE                             26320001
*                                                                       26390001
ITDPEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     26460001
         EJECT                                                          26530001
*                                                                       26600001
** KEPCVT. THIS ROUTINE PROCESSES THE CV TRIPLE.                        26670001
**   THIS IS THE FIRST STAGE IN ANALYSING THE CV SPEC. (ROUTINES        26740001
**   KEPCVP, KEWUDC, KEPBYT, KEPTOT COMPLETE THE ANALYSIS). THE         26810001
**   DICT.ENTRY FOR THE CV IS EXAMINED TO SEE IF THE CV IS A REAL FIXED 26880001
**   BINARY INTEGER. IF IT IS NOT, THE BAD CV BIT IN XTSCCVBT IS SET    26950001
**   ON. IF THE CV IS A TEMPORARY (IE., THE DO LOOP IS AN EXPANSION OF  27020001
**   AN ARRAY EXPRESSION) A BIT (XTSCTEMP) IS SET ON IN XTSCCVBT TO     27090001
**   INDICATE THE FACT                                                  27160001
*                                                                       27230001
KEPCVT   IEMKENT  TYPE=3                                                27300001
         USING XDIC,GR5                                                 27370001
*                                                                       27440001
         MVI   XTSCCVBT,X'00'      CLEAR CV CODE BYTE IN XTSC           27510001
         MVC   XTSCCVDR,XTRPOP2    SAVE CV. DIC. REF. FOR KEPCVP        27580001
         SPACE                                                          27650001
         CLC   XTRPOP2,=XL2'0'     TEST IF NO OPERAND                   27720001
         BNE   PCVTGTDE            BRANCH IF THERE IS                   27790001
         OI    XTSCCVBT,XTSCBSPC   INDICATE BAD SPEC                    27860001
         B     PCVTEXIT            EXIT                                 27930001
         SPACE                                                          28000001
PCVTGTDE EQU   *                                                        28070001
         GETDICT XTRPOP2,GR5       GET DICT.ENTRY OF CV                 28140001
         SPACE                                                          28210001
         MVC   XTSCWORK(1),XDICDATA MOVE DATA BYTE TO WORK FIELD        28280001
         NI    XTSCWORK,X'FF'-X'10' MASK OFF UNWANTED BIT               28350001
         CLI   XTSCWORK,X'8C'      TEST WHETHER REAL FIXED BINARY       28420001
         BNE   PCVTBDCV            BRANCH IF NOT                        28490001
         CLI   XDICPREC+1,XDICINTG TEST WHETHER INTEGER                 28560001
         BNE   PCVTBDCV            BRANCH IF NOT                        28630001
         SPACE                                                          28700001
PCVTTTMP TM    XDICCODE,XDICTEMP   TEST WHETHER TEMPORARY               28770001
         BZ    PCVTEXIT            EXIT IF NOT                          28840001
         TM    XDICOTH2,XDICFPRM   TEST IF FORMAL PARAMETER             28910001
         BO    PCVTEXIT            EXIT IF SO                           28980001
         OI    XTSCCVBT,XTSCTEMP   INDICATE TEMPORARY                   29050001
         LH    GR2,XTSCBPIC        DECREMENT                      32241 29057020
         BCTR  GR2,0                BLOCK COUNT                   32241 29064020
         STH   GR2,XTSCBPIC                                       32241 29071020
*                                  XTSCBPIC CONTAINS BLOCK COUNT  32241 29078020
*                                  SET BY READ IN; COMPILER       32241 29085020
*                                  CREATED DO LOOPS DO NOT EXIST  32241 29092020
*                                  AT THIS TIME AND ARE NOT       32241 29099020
*                                  INCLUDED IN THIS BLOCK COUNT.  32241 29106020
         B     PCVTEXIT            EXIT                                 29120001
         SPACE                                                          29190001
PCVTBDCV OI    XTSCCVBT,XTSCBDCV   INDICATE CV NOT REAL FIXED BIN INTGR 29260001
         B     PCVTTTMP            GO TO TEST FOR TEMPORARY             29330001
*                                                                       29400001
PCVTEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     29470001
         DROP  GR5                                                      29540001
         EJECT                                                          29610001
*                                                                       29680001
** KEPCVP. THIS ROUTINE PROCESSES THE CV' TRIPLE.                       29750001
**  THE CURRENT DO-MAP ENTRY IS MARKED ACCORDING TO THE SETTINGS        29820001
**  OF THE BITS IN XTSCCVBT.                                            29890001
*                                                                       29960001
KEPCVP   IEMKENT  TYPE=3                                                30030001
         USING XMAP,GR5                                                 30100001
*                                                                       30170001
       IEMKTAB DR,XLCRMAP,SA=XTSCCUDO,AATO=(GR5)                        30240001
         SPACE                                                          30310001
         TM    XTSCCTLB,XTSCINIO+XTSCIPTL+XTSCIFTL TEST IF INSIDE       30320001
         BZ    PCVPCONT                      I/O LIST, BRANCH IF NOT    30330001
         TM    XTSCCVBT,XTSCTEMP          TEST IF CV WAS A TEMP   52193 30333021
         BZ    PCVPIONT                   BRANCH IF NOT           52193 30336021
         OI    XMAPSPEC,XMAPBDCV+XMAPBSPC    INDICATE UNOPTIMIZABLE     30340001
         B     PCVPEXIT                                                 30350001
PCVPIONT OI    XMAPSPEC,XMAPBSPC       NOT INTERESTED IN THIS     52193 30352021
*                                    ITDO.                        52193 30354021
         MVC   XMAPCVDR,XTSCCVDR       MOVE IN CV. DIC. REF.      52193 30356021
         B     PCVPEXIT                                           52193 30358021
PCVPCONT EQU   *                                                        30360001
         TM    XTSCCVBT,XTSCBYBT+XTSCTOBT TEST WHETHER BOTH TO AND BY   30380001
         BO    PCVPSSPC                     ENCOUNTERED, BRANCH IF SO   30450001
         OI    XTSCCVBT,XTSCBSPC            ELSE TURN ON BAD SPEC.BIT   30520001
         SPACE                                                          30590001
PCVPSSPC MVC   XMAPSPEC,XTSCCVBT   SET SET SPEC.BITS IN DO-MAP ENTRY    30660001
         NI    XMAPSPEC,XMAPBDCV+XMAPBSPC CLEAR UNWANTED BITS           30730001
         MVC   XMAPCVDR,XTSCCVDR   MOVE IN CV. DIC. REF.                30800001
         SPACE                                                          30870001
         TM    XTSCCVBT,XTSCTEMP   TEST IF CV WAS A TEMPORARY           30940001
         BZ    PCVPEXIT            EXIT IF NOT                          31010001
         OI    XMAPLOOP,XMAPAELP   INDICATE LOOP FOR ARRAY EXPRESSION   31080001
         MVC   XMAPBCNT,XTSCBPIC+1 RESET COUNT FOR COMPILER       32241 31090020
*                                  CREATED LOOP TO THAT OF THE    32241 31100020
*                                  CONTAINING BLOCK.              32241 31110020
*                                                                       31150001
PCVPEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     31220001
         DROP  GR5                                                      31290001
         EJECT                                                          31360001
*                                                                       31430001
** KEWUDC. THIS ROUTINE PROCESSES THE WHILE AND UPSIDE-DOWN-COMMA 3PLS. 31500001
*                                                                       31570001
KEWUDC   IEMKENT  TYPE=3                                                31640001
*                                                                       31710001
         OI    XTSCCVBT,XTSCBSPC   INDICATE BAD SPEC.                   31780001
*                                                                       31850001
WUDCEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     31920001
         EJECT                                                          31990001
*                                                                       32060001
** KEPBYT. THIS ROUTINE PROCESSES THE BY TRIPLE.                        32130001
*                                                                       32200001
KEPBYT   IEMKENT  TYPE=3                                                32270001
*                                                                       32340001
         OI    XTSCCVBT,XTSCBYBT   INDICATE BY ENCOUNTERED              32410001
*                                                                       32480001
PBYTEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     32550001
         EJECT                                                          32620001
*                                                                       32690001
** KEPTOT. THIS ROUTINE PROCESSES THE TO TRIPLE.                        32760001
*                                                                       32830001
KEPTOT   IEMKENT  TYPE=3                                                32900001
*                                                                       32970001
         OI    XTSCCVBT,XTSCTOBT   INDICATE TO ENCOUNTERED              33040001
*                                                                       33110001
PTOTEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     33180001
         EJECT                                                          33250001
*                                                                       33320001
** KEGETD. THIS ROUTINE PROCESSES THE GET TRIPLE.                       33390001
*                                                                       33460001
KEGETD   IEMKENT  TYPE=3                                                33530001
         OI    XTSCCTLB,XTSCINIO   INDICATE WITHIN GET LIST             33600001
*                                                                       33670001
GETDEXIT IEMKLVE  NORC,RP=SCANNTRP                                      33740001
         EJECT                                                          33810001
*                                                                       33880001
** KEPEIO. THIS ROUTINE PROCESSES THE EIO TRIPLE.                       33950001
*                                                                       34020001
KEPEIO   IEMKENT  TYPE=3                                                34070001
         NI    XTSCCTLB,X'FF'-(XTSCINIO+XTSCIPTL) TURN OFF WITHIN-IO-  -34130001
                                                  LIST BITS             34170001
*                                                                       34230001
PEIOEXIT IEMKLVE  NORC,RP=SCANNTRP                                      34300001
         EJECT                                                          34370001
*                                                                       34440001
** KESTNO. THIS ROUTINE PROCESSES THE STATEMENT NUMBER TRIPLE.          34510001
**                                                                      34580001
KESTNO   IEMKENT  TYPE=3                                                34650001
         MVC   XTSCPREF,XTRPOP1+1                                       34720001
         MVC   ZSTAT+2(2),XTRPOP2       SET STATEMENT NUMBER SLOT       34750001
*                                                                       34790001
STNOEXIT IEMKLVE  NORC,RP=SCANNTRP                                      34860001
         EJECT                                                          34930001
*                                                                       34932001
** KEPPUT. THIS ROUTINE PROCESSES THE PUT TRIPLE.                       34934001
*                                                                       34936001
KEPPUT   IEMKENT  TYPE=3                                                34938001
         OI    XTSCCTLB,XTSCIPTL   INDICATE INSIDE PUT LIST             34940001
*                                                                       34942001
PPUTEXIT IEMKLVE  NORC,RP=SCANNTRP                                      34944001
         EJECT                                                          34946001
*                                                                       34948001
** KEFMAT. THIS ROUTINE PROCESSES THE FORMAT TRIPLE.                    34950001
*                                                                       34952001
KEFMAT   IEMKENT  TYPE=3                                                34954001
         OI    XTSCCTLB,XTSCIFTL   INDICATE INSIDE FORMAT LIST          34956001
*                                                                       34958001
FMATEXIT IEMKLVE  NORC,RP=SCANNTRP                                      34960001
         EJECT                                                          34962001
*                                                                       34964001
** KEFMTP. THIS ROUTINE PROCESSES THE FORMAT' TRIPLE.                   34966001
*                                                                       34968001
KEFMTP   IEMKENT  TYPE=3                                                34970001
         NI    XTSCCTLB,X'FF'-XTSCIFTL  CLEAR IN-FORMAT-LIST BIT        34972001
*                                                                       34974001
FMTPEXIT IEMKLVE  NORC,RP=SCANNTRP                                      34976001
         EJECT                                                          34978001
*                                                                       35000001
** KEFUNC. THIS ROUTINE PROCESSES THE FUNC TRIPLE.                      35070001
**   THE CURRENT WORK FIELDS ARE STORED IN THE STACK AND A FLAG IS SET  35080001
**   ON TO INDICATE THAT THE CURRENT TEXT IS WITHIN A FUNCTION NEST.    35090001
**   KELKUP IS CALLED TO SCAN THE LIST OF PROCEDURE DICTIONARY REFS.    35100001
**   BUILT BY KCDSIN TO SEE IF THE DICT REF OF THE CURRENT FUNCTION     35110001
**   IS IN IT. IF IT IS, THE CURRENT FUNCTION MAY BE UNSAFE AND FURTHER 35120001
**   TESTS ARE CARRIED OUT TO DETERMINE IF THIS IS SO.                  35130001
**                                                                      35140001
**   A FUNCTION IS CONSIDERED UNSAFE IF IT:                             35210001
**                                                                      35280001
**      (1) RETURNS A POINTER VALUE (IE ADDR OR NON-BUILT-IN FUNCTION   35350001
**                                     WITH POINTER ATTRIBUTE).         35420001
**      (2) IT IS AN INTERNAL NON-BUILT-IN PROCEDURE AND AN INTERNAL    35490001
**          POINTER VARIABLE IS DECLARED IN THE COMPILATION.            35560001
**      (3) IT IS A NON-BUILT-IN PROCEDURE AND AN EXTERNAL POINTER      35630001
**          VARIABLE IS DECLARED IN THE COMPILATION.                    35700001
**                                                                      35710001
**   IF THE FUNCTION IS UNSAFE, ITS ARGUMENTS MUST BE MARKED UNSAFE,    35720001
**   AND A FLAG IS SET TO INDICATE THIS FACT. FLAGS ARE ALSO SET TO     35730001
**   INDICATE IF THE PROCEDURE IS EXTERNAL OR A NON-BUILTIN FUNCTION.   35740001
*                                                                       35770001
KEFUNC   IEMKENT  TYPE=3                                                35840001
         USING XDEL,PR1                                                 35910001
*                                                                       35980001
         LA    PR1,XSTKFUNC        INDICATE FUNC STACK ENTRY            36050001
         BAL   RR,KESTCK           MAKE STACK ENTRY                     36120001
         LR    XSTKBASE,RC         LOAD ADDRESS OF NEW STACK ENTRY      36190001
         MVI   XTSCFCBT,XTSCIFNT   INDICATE NOW INSIDE FUNCTION NEST   -36230001
                                     AND CLEAR OTHER FLAG BITS          36270001
*                                                                       36330001
* THE FOLLOWING SECTION DETERMINES                                      36400001
** WHETHER THE CURRENT FUNCTION IS UNSAFE AND SETS THE UNSAFE FUNCTION  36470001
** BIT ACCORDINGLY.                                                     36540001
*                                                                       36610001
         SR    PR0,PR0             INDICATE SCAN FOR PROC. TO KELKUP    36680001
         LA    PR1,XTRPOP1           AND LOAD ADDRESS OF DIC.REF.       36750001
         BAL   RR,KELKUP           CALL ROUTINE TO SCAN LIST OF PROCS   36820001
         B     *+4(RC)             TEST RETURN CODE                     36890001
         B     FUNCFOUN              0 - FOUND - FUNCTION MAY BE UNSAFE 36960001
         B     FUNCEXIT              4 - NOT FOUND - FUNCTION IS SAFE   37030001
*                                                                       37100001
** TEST WHETHER FUNCTION IS UNSAFE. (PR1 POINTS TO LIST ENTRY).         37170001
*                                                                       37240001
FUNCFOUN TM    XDELCODE,XDELADDR   TEST IF ADDR                         37310001
         BO    FUNCMUSF            BRANCH IF SO                         37380001
         OI    XTSCFCBT,XTSCBIFB   INDICATE NON-BIF                     37450001
         SPACE                                                          37520001
FUNCTSFE TM    XDELCODE,XDELPRTP   TEST IF EXTERNAL PROC                37530001
         BZ    FUNCTSF2            BRANCH IF NOT                        37540001
         OI    XTSCFCBT,XTSCEXP2   INDICATE EXTERNAL PROC               37550001
FUNCTSF2 EQU   *                                                        37560001
         TM    XDELCODE,XDELPRPN   TEST IF PROC RETURNS POINTER VALUE   37610001
         BO    FUNCMUSF            BRANCH IF SO - FUNC UNSAFE           37660001
         TM    XTSCCODE,XTSCEPTR   TEST IF AN EXTERNAL POINTER EXISTS   37730001
         BO    FUNCMUSF            BRANCH IF SO - PROC UNSAFE           37800001
         TM    XDELCODE,XDELPRTP   TEST IF PROC INTERNAL OR EXTERNAL    37870001
         BO    FUNCMODL            BRANCH IF EXTERNAL - PROC SAFE       37940001
         TM    XTSCCODE,XTSCIPTR   TEST IF AN INTERNAL POINTER EXISTS   38010001
         BZ    FUNCEXIT            EXIT IF NOT - FUNCTION SAFE          38080001
         SPACE                                                          38150001
FUNCMUSF OI    XTSCFCBT,XTSCUNSF   MARK FUNCTION UNSAFE                 38220001
         B     FUNCEXIT            EXIT                                 38290001
         SPACE                                                          38360001
FUNCMODL TM    XTSCCODE,XTSCIPTR   TEST IF AN INTERNAL POINTER EXISTS   38430001
         BZ    FUNCEXIT            EXIT IF NOT                          38500001
         OI    XTSCFCBT,XTSCEXTP   MARK AS EXTERNAL PROCEDURE           38570001
*                                                                       38640001
FUNCEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     38710001
         DROP  PR1                                                      38780001
         EJECT                                                          38850001
*                                                                       38920001
** KEFNCP. THIS ROUTINE PROCESSES THE FNC' TRIPLE.                      38990001
**   IF THE FLAGS ARE SET INDICATING THAT THE CALLED PROCEDURE IS       39010001
**   EXTERNAL OR NON-BUILTIN THE SECOND OPERAND OF THE FNC' TRIPLE      39030001
**   IS FLAGGED TO INDICATE THIS TO PHASE KG. THE FUNCTION WORK FIELDS  39050001
**   ARE THEN RESET FROM THE STACK AND THE TOP STACK ENTRY REMOVED.     39070001
*                                                                       39130001
KEFNCP   IEMKENT  TYPE=3                                                39170001
         TM    XTSCFCBT,XTSCEXP2   TEST IF EXTERNAL PROC                39210001
         BZ    FNCPTBIF            BRANCH IF NOT                        39220001
         OI    XTRPOP2,X'40'       INDICATE EXT PROC TO PHASE KG        39230001
FNCPTBIF EQU   *                                                        39240001
         TM    XTSCFCBT,XTSCBIFB   TEST IF BUILT-IN FUNCTION            39270001
         BZ    FNCPUNST            BRANCH IF SO                         39340001
         OI    XTRPOP2,X'80'       INDICATE NON-BIF                     39410001
         SPACE                                                          39480001
FNCPUNST MVC   XTSCFCBT,XSTKFCBT   UNSTACK                              39550001
         MVC   XTSCSLCT,XSTKSLCT     FUNCTION ENTRY                     39620001
         LA    XSTKBASE,XSTKEND-XSTK(0,XSTKBASE) REMOVE TOP STACK ENTRY 39690001
*                                                                       39760001
FNCPEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     39830001
         EJECT                                                          39900001
*                                                                       39970001
** KEFNCM. THIS ROUTINE PROCESSES THE FNCM TRIPLE.                      40040001
**   IF THE PROC IS EXTERNAL A FLAG IS SET TO INDICATE THAT A PARAMETER 40045001
**   HAS BEEN PASSED TO AN EXTERNAL PROCEDURE. IF THE PROC IS UNSAFE    40050001
**   OR ALL EXTERNAL PROCS ARE UNSAFE AND THE PROC IS EXTERNAL, THE     40055001
**   ARGUMENT IS MARKED UNSAFE. OTHERWISE, IF THE PROC IS EXTERNAL,     40060001
**   KELKUP IS CALLED TO-SCAN THE LIST OF POINTERS SET UP BY KCDSIN TO  40065001
**   SEE IF THE ARGUMENT IS A POINTER. IF IT IS NOT, THE DICT.REF. OF   40070001
**   THE ARGUMENT IS STORED IN THE LIST OF ARGUMENTS TO EXTERNAL PROCS. 40075001
**   IF THE ARGUMENT IS A POINTER, A FLAG IS SET TO INDICATE THAT ALL   40080001
**   EXTERNAL PROCS ARE UNSAFE, AND THE ABOVE LIST IS SCANNED AND ALL   40085001
**   ENTRIES IN IT MARKED UNSAFE. IF A LABEL VARIABLE IS PASSED TO AN   40090001
**   EXTERNAL PROCEDURE A FLAG (XLCREXLV) IS SET TO INDICATE THE FACT.  40095001
*                                                                       40110001
KEFNCM   IEMKENT  TYPE=3                                                40180001
         USING XDIC,GR4                                                 40250001
*                                                                       40320001
         TM    XTSCFCBT,XTSCEXP2   TEST IF EXTERNAL PROC                40330001
         BZ    FNCMTZOP            BRANCH IF NOT                        40340001
         OI    XLCRCODE,XLCRBEEN   INDICATE PARAM PASSED TO EXT PROC    40350001
FNCMTZOP EQU   *                                                        40360001
         CLC   =XL2'0',XTRPOP2     TEST WHETHER DICT.REF. IN TRIPLE     40390001
         BE    FNCMEXIT            EXIT IF NOT                          40460001
*                                                                 62605 40461072
* PREPARE FOR STRUCTURE SCAN IF ARGT IS A STRUCTURE.              62605 40462072
*                                                                 62605 40463072
         MVC   THISDR,XTRPOP2          SAVE CURRENT DIC REF.      62605 40464072
         MVC   NEXTDR,=XL2'0'          CLEAR NEXT DIC REF.        62605 40465072
         GETDICT THISDR,GR4            GET D.E..ARGT.             62605 40466072
         TM    XDICCODE,XDICDVAR       IS IT XF TYPE?             62605 40467072
         BO    FNCMPREF                YES,PROCESS THE ARGUMENT.  62605 40468072
         TM    XDICCODE,X'0E'          IS IT A STRUCTURE?         62605 40469072
         BNO   FNCMPREF                NO, PROCESS THE ARGUMENT.  62605 40470072
*                                                                 62605 40471072
*  EACH ELEMENT OF THE STRUCTURE MUST BE SCANNED AND PROCESSED    62605 40472072
*  SEPARATELY. IF IT IS A MINOR STRUCTURE, ONLY THE MINOR         62605 40473072
*  STRUCTURE IS SCANNED.  DATA VARIABLES MAY BE MARKED UNSAFE.    62605 40474072
*  POINTERS AND LABEL VARIABLES CAN ALSO CAUSE SPECIAL ACTION.    62605 40475072
*                                                                 62605 40476072
*  FIRST POINT AT THE STRUCTURE SLOT IN THE ENTRY.                62605 40477072
         LA    RR,FNCM0004             RETRN PNT FROM SUBRTN.     62605 40478072
         SPACE 2                                                  62605 40479072
* SUBROUTINE. INPUT GR4->DIC ENTRY. OUTPUT RC->STRUCTURE SLOT,    62605 40480072
*                                          GR4 UNCHANGED.         62605 40481072
FNCMSTRS SR    RC,RC                   SUBRTN TO POINT AT STR SLOT62605 40482072
* NOTE - XDIC AND XDFM DSECTS BOTH DESCRIBE DICTIONARY ENTRY.     62605 40483072
         USING XDFM,GR4                                           62605 40484072
         TM    XDFMFVAR,X'80'          2ND OFFSET PRESENT?        62605 40485072
         BZ    FNCM0001                NO                         62605 40486072
         LA    RC,4(,RC)               YES, COUNT 4.              62605 40487072
FNCM0001 TM    XDFMFVAR,X'40'          DIMENSION SLOT PRESENT?    62605 40488072
         BZ    FNCM0002                NO                         62605 40489072
         LA    RC,3(,RC)               YES, COUNT 3.              62605 40490072
FNCM0002 TM    XDFMCODE,XDICDVAR       DATA VARIABLE?             62605 40491072
         BNO   FNCM0003                NO                         62605 40492072
         LA    RC,6(,RC)               YES, COUNT 6.              62605 40493072
FNCM0003 LA    RC,15(RC,GR4)           RC -> STRUCTURE SLOT.      62605 40494072
         BR    RR                      RETURN                     62605 40495072
*  END OF SUBROUTINE TO POINT RC AT STRUCTURE SLOT.               62605 40496072
         SPACE 2                                                  62605 40497072
FNCM0004 EQU   *                       CONTINUE INITIALISATION.   62605 40498072
         USING XDIC,GR4                                           62605 40499072
         MVC   TRUELEV,1(RC)           SAVE TRUE LEVEL NO.        62605 40500072
         SPACE 2                                                  62605 40501072
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     62605 40502072
FNCMLOOP EQU   *     MAIN LOOP FOR MEMBERS OF STRUCTURE.          62605 40503072
         MVC   NEXTDR,4(RC)            SAVE D.R..NEXT MEMBER      62605 40504072
*                                  N.B. ZERO FOR LAST MEMBER.     62605 40505072
*                                                                 62605 40506072
* ENTER HERE FOR NON-STRUCTURED ARGUMENT.                         62605 40507072
FNCMPREF EQU   *     PROCESS ARGT, OR MEMBER OF STRUCTURE ARGT.   62605 40508072
         SPACE                                                          40530001
         TM    XTSCFCBT,XTSCUNSF   TEST IF FUNCTION UNSAFE              40600001
         BZ    FNCMTEXT            BRANCH IF NOT                        40670001
FNCMGTDE EQU   *                                                        40740001
         GETDICT THISDR,GR4            GET D.E..ARGT.             62605 40810072
XLCRLABV EQU   X'20'                    LABEL VARIABLES PRESENT         40880072
XLCREXLV EQU   X'40'                    EXT. LAB. VARS PRESENT          40910072
         TM    XDICCODE,XDICDVAR       XF TYPE?                   62605 40940072
         BO    FNCMMKDE                YES, MARK UNSAFE.          62605 40970072
         TM    XDICCODE,X'0E'          XE TYPE?                   62605 41000072
         BNO   FNCMTLAB                NO, DONT MARK UNSAFE.      62605 41030072
*                                                                 62605 41060072
* ENTRY TYPES  0F 1F 2E 2F 3E 3F 8F 9F AE AF BE BF CAN BE MARKED. 62605 41090072
*                                                                 62605 41120072
         SPACE                                                          41160001
FNCMMKDE OI    XDICOTH3,XDICUNSF   MARK DICT. ENTRY UNSAFE              41230001
         B     FNCM9999                EXIT                       62605 41300072
         SPACE                                                          41370001
FNCMTEXT TM    XLCRCODE,XLCRLABV        TEST IF LABEL VARIABLES PRESENT 41375001
         BZ    FNCMTXT2                 BRANCH IF NOT                   41380001
*                                                                       41385001
         TM    XLCRCODE,XLCREXLV        TEST IF XLCREXLV ALREADY SET    41390001
         BO    FNCMTXT2                 IF SO BRANCH                    41395001
*                                                                       41400001
         TM    XTSCFCBT,XTSCEXP2        TEST IF EXT PROC                41405001
         BZ    FNCMTXT2                 BRANCH IF NOT                   41410001
*                                                                       41415001
         GETDICT THISDR,GR4            GET D.E..ARGT.             62605 41420072
*                                                                       41425001
         TM    XDICCODE,X'07'          COULD IT BE LABEL VBL?     62605 41430072
         BNO   FNCMTXT2                NO                         62605 41440072
         TM    XDICCODE,X'08'          MIGHT BE XF TYPE           62605 41450072
         BO    FNCMTXT2                BRANCH, NOT LABEL          62605 41460072
*                                                                       41475001
FNCMMKXT OI    XLCRCODE,XLCREXLV        SET XLCREXLV FLAG ON            41480001
*                                                                       41485001
*                                                                       41490001
FNCMTXT2 TM    XTSCFCBT,XTSCEXTP        TEST IF EXTERNAL PROC           41495001
         BZ    FNCM9999                EXIT IF NOT                62605 41510072
         TM    XTSCCTLB,XTSCPPEP   TEST IF ALL EXT PROCS UNSAFE         41580001
         BO    FNCMGTDE            BRANCH IF SO                         41650001
         SPACE                                                          41720001
         LA    PR0,4               INDICATE SCAN FOR POINTER TO KELKUP  41790001
         LA    PR1,THISDR              ADDR(D.R.) FOR KELKUP.     62605 41860072
         BAL   RR,KELKUP           SCAN LIST OF POINTERS                41930001
         B     *+4(RC)             TEST RETURN CODE                     42000001
         B     FNCMFOUN            0 - DIC.REF. FOUND IN LIST OF PTRS.  42070001
         B     FNCMADDL            4 - NOT FOUND                        42140001
         SPACE                                                          42210001
FNCMFOUN OI    XTSCCTLB,XTSCPPEP   INDICATE ALL EXT PROCS UNSAFE        42280001
       IEMKTAB TEST,XTSCARG,NTA=FNCMGTDE                                42330001
       IEMKTAB DEACT,XTSCARG                                            42370001
       IEMKTAB SETZ,XTSCARG                                             42430001
FNCMSCAN DS    0H                                                       42470001
       IEMKTAB SCAN,XTSCARG,AATO=(GR2),ETA=FNCMGTDE                     42510001
         GETDICT 0(GR2),GR4                                             42560001
         OI    XDICOTH3,XDICUNSF   MARK ENTRY UNSAFE                    42630001
         B     FNCMSCAN                                                 42700001
*                                                                       42770001
FNCMTLAB TM    XLCRCODE,XLCRLABV        TEST IF LABEL VARIABLES PRESENT 42771001
         BZ    FNCM9999                EXIT IF NOT                62605 42772072
*                                                                       42773001
         TM    XLCRCODE,XLCREXLV        TEST IF XLCREXLV ALREADY SET    42774001
         BO    FNCM9999                EXIT IF SO                 62605 42775072
*                                                                       42776001
         TM    XTSCFCBT,XTSCEXP2        TEST IF EXT PROC                42777001
         BZ    FNCM9999                EXIT IF NOT                62605 42778072
*                                                                       42779001
         TM    XDICCODE,X'07'          COULD IT BE LABEL VBL?     62605 42780072
         BNO   FNCM9999                NO                         62605 42782072
         TM    XDICCODE,X'08'          MIGHT BE XF TYPE           62605 42784072
         BO    FNCM9999                BRANCH, NOT LABEL.         62605 42786072
*                                                                       42789001
FNCMMKEX OI    XLCRCODE,XLCREXLV        SET EXTERNAL VARS FLAG.         42790001
         B     FNCM9999                                           62605 42791072
*                                                                       42792001
*                                                                       42793001
FNCMADDL DS    0H                                                       42810001
         IEMKTAB BLDC,XTSCARG,THISDR                              62605 42850072
*                                                                       42910001
*                                                                 62605 42912072
*  END OF LOOP FOR ARGT, OR MEMBER OF STRUCTURE ARGT.             62605 42914072
*  CHECK IF FINISHED, AND LOOP BACK WITH NEXT MEMBER IF NOT.      62605 42916072
*                                                                 62605 42918072
FNCM9999 EQU   *                                                  62605 42920072
         CLC   =XL2'0',NEXTDR          IS THERE ANOTHER MEMBER?   62605 42922072
         BE    FNCMEXIT                NO, FINISHED.              62605 42924072
*  GET NEXT MEMBER OF STRUCTURE, AND CHECK THE LEVEL NUMBER.      62605 42926072
         GETDICT NEXTDR,GR4                                       62605 42928072
         BAL   RR,FNCMSTRS             POINT RC AT STRUC SLOT.    62605 42930072
         CLC   TRUELEV,1(RC)           IF SAVED LEVEL < NEW      62605 42932072
         BNL   FNCMEXIT                LEVEL, MINOR STRUCTURE END.62605 42934072
*                                                                 62605 42936072
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     62605 42938072
*                                                                 62605 42940072
*     SET UP FOR NEXT MEMBER, WHICH NEEDS PROCESSING.             62605 42942072
*                                                                 62605 42944072
         MVC   THISDR,NEXTDR           D.R..CURRENT MEMBER.       62605 42946072
         B     FNCMLOOP     GOTO SET NEXTDR, AND PROCESS THIS ONE.62605 42948072
THISDR   DC    XL2'0'                  SAVE D.R..CURRENT ENTRY.   62605 42950072
NEXTDR   DC    XL2'0'    SAVE D.R..NEXT ENTRY  0000 AT END.      62605 42952072
TRUELEV  DC    X'00'     SAVE LEVEL NO OF STRUCTURE ARGT.         62605 42954072
         SPACE 2                                                  62605 42956072
FNCMEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     42980001
         DROP  GR4                                                      43050001
         EJECT                                                          43120001
*                                                                       43190001
** KESUBS. THIS ROUTINE PROCESSES THE SUBS TRIPLE.                      43260001
**   THE ROUTINE IS SIMILAR TO KEFNCM EXCEPT THAT AN INITIAL CHECK      43330001
**   IS MADE TO SEE WHETHER AN INNER OR OUTER SUBS TRIPLE IS BEING      43400001
**   PROCESSED. EXCEPT FOR UPDATING OF THE SUBS DEPTH COUNT IN THE      43470001
**   FUNCTAB ENTRY INNER SUBS TRIPLES ARE NOT PROCESSED                 43540001
*                                                                       43610001
KESUBS   IEMKENT  TYPE=3                                                43680001
         USING XDIC,GR4                                                 43750001
*                                                                       43820001
         TM    XTSCFCBT,XTSCIFNT   TEST IF IN FUNCTION NEST             43890001
         BZ    SUBSEXIT            EXIT IF NOT                          43960001
         LH    GR2,XTSCSLCT        LOAD SUBS LEVEL COUNT                44030001
         LA    GR2,1(0,GR2)        ADD 1                                44100001
         STH   GR2,XTSCSLCT        AND STORE UPDATED COUNT              44170001
         CH    GR2,=H'1'           TEST IF FIRST LEVEL                  44240001
         BNE   SUBSEXIT            EXIT IF NOT                          44310001
         SPACE                                                          44380001
*                                                                       44450001
** THE REMAINING CODE IS SIMILAR TO KEFNCM                              44520001
**  EXCEPT THAT NO STRUCTURE SCAN IS NEEDED, BECAUSE SUBS TRIPLE  62605 44540072
**  CANNOT HAVE A STRUCTURE ARGUMENT.                             62605 44560072
*                                                                       44590001
         CLC   =XL2'0',XTRPOP1     TEST IF OPERAND PRESENT              44660001
         BE    SUBSEXIT            EXIT IF NOT                          44730001
         TM    XTSCFCBT,XTSCUNSF   TEST IF ARGUMENT TO BE MARKED        44800001
         BZ    SUBSTEXT            BRANCH IF NOT                        44870001
         SPACE                                                          44940001
SUBSGTDE EQU   *                                                        45010001
         GETDICT XTRPOP1,GR4       GET DICT. ENTRY OF ARGUMENT          45080001
         CLI   XDICCODE,XDICDDVA   TEST WHETHER                         45150001
         BE    SUBSMKDE              DICT.ENTRY IS FOR                  45220001
         CLI   XDICCODE,XDICDDVS     DATA VARIABLE                      45290001
         BNE   SUBSTLAB                 BRANCH IF NOT                   45360001
         SPACE                                                          45430001
SUBSMKDE OI    XDICOTH3,XDICUNSF   MARK VARIABLE UNSAFE                 45500001
         B     SUBSEXIT              AND EXIT                           45570001
         SPACE                                                          45640001
SUBSTEXT TM    XLCRCODE,XLCRLABV        TEST IF LABEL VARIABLES PRESENT 45645001
         BZ    SUBSTXT2                 BRANCH IF NOT                   45650001
*                                                                       45655001
         TM    XLCRCODE,XLCREXLV        TEST IF XLCREXLV ALREADY SET    45660001
         BO    SUBSTXT2                 IF SO BRANCH                    45665001
*                                                                       45670001
         TM    XTSCFCBT,XTSCEXP2        TEST IF EXT PROC                45675001
         BZ    SUBSTXT2                 BRANCH IF NOT                   45680001
*                                                                       45685001
         GETDICT XTRPOP1,GR4           GET DICT ENTRY OF ARGUMENT       45690001
*                                                                       45695001
         CLI   XDICCODE,X'17'           TEST IF LABEL VARIABLE          45700001
         BE    SUBSMKXT                 IF SO BRANCH                    45705001
         CLI   XDICCODE,X'37'           TEST IF LABEL VARIABLE          45710001
         BE    SUBSMKXT                 IF SO BRANCH                    45715001
         CLI   XDICCODE,X'97'           TEST IF COMP CREATED LAB VAR    45720001
         BE    SUBSMKXT                 IF SO BRANCH                    45725001
*                                                                       45730001
         CLI   XDICCODE,X'B7'           TEST IF LABEL VARIABLE          45735001
         BNE   SUBSTXT2                 BRANCH IF NOT                   45740001
*                                                                       45745001
SUBSMKXT OI    XLCRCODE,XLCREXLV        SET XLCREXLV FLAG ON            45750001
*                                                                       45755001
*                                                                       45760001
SUBSTXT2 TM    XTSCFCBT,XTSCEXTP        TEST IF EXTERNAL PROC           45765001
         BZ    SUBSEXIT            EXIT IF NOT                          45780001
         TM    XTSCCTLB,XTSCPPEP   TEST IF ALL EXT PROCS UNSAFE         45850001
         BO    SUBSGTDE            BRANCH IF SO                         45920001
         SPACE                                                          45990001
         LA    PR0,4               INDICATE SCAN FOR POINTER TO KELKUP  46060001
         LA    PR1,XTRPOP1         LOAD ADDRESS OF DICT REF. FOR KELKUP 46130001
         BAL   RR,KELKUP           SCAN LIST OF POINTERS                46200001
         B     *+4(RC)             TEST RETURN CODE                     46270001
         B     SUBSFOUN            0 - DIC.REF. FOUND IN LIST OF PTRS.  46340001
         B     SUBSADDL            4 - NOT FOUND                        46410001
         SPACE                                                          46480001
SUBSFOUN OI    XTSCCTLB,XTSCPPEP   INDICATE ALL EXT PROCS UNSAFE        46550001
       IEMKTAB TEST,XTSCARG,NTA=SUBSGTDE                                46600001
       IEMKTAB DEACT,XTSCARG                                            46640001
       IEMKTAB SETZ,XTSCARG                                             46700001
SUBSSCAN DS    0H                                                       46740001
       IEMKTAB SCAN,XTSCARG,AATO=(GR3),ETA=SUBSGTDE                     46780001
         GETDICT 0(GR3),GR4                                             46830001
         OI    XDICOTH3,XDICUNSF   MARK VARIABLE UNSAFE                 46900001
         B     SUBSSCAN                                                 46970001
SUBSTLAB TM    XLCRCODE,XLCRLABV        TEST IF LABEL VARIABLES PRESENT 46972001
         BZ    SUBSEXIT                 BRANCH IF NOT                   46974001
*                                                                       46976001
         TM    XLCRCODE,XLCREXLV        TEST IF XLCREXLV ALREADY SET    46978001
         BO    SUBSEXIT                 IF SO BRANCH                    46980001
*                                                                       46982001
         TM    XTSCFCBT,XTSCEXP2        TEST IF EXT PROC                46984001
         BZ    SUBSEXIT                 BRANCH IF NOT                   46986001
*                                                                       46988001
         CLI   XDICCODE,X'17'           TEST FOR LABEL VARIABLE         46990001
         BE    SUBSMKEX                 IF SO BRANCH                    46992001
         CLI   XDICCODE,X'37'           TEST IF LABEL VARIABLE          46994001
         BE    SUBSMKEX                 IF SO BRANCH                    46996001
         CLI   XDICCODE,X'97'           TEST FOR COMPILER LAB VAR       46998001
         BE    SUBSMKEX                 IF SO BRANCH                    47000001
*                                                                       47002001
         CLI   XDICCODE,X'B7'           TEST IF LABEL VARIABLE          47004001
         BNE   SUBSEXIT                 BRANCH IF NOT                   47006001
*                                                                       47008001
SUBSMKEX OI    XLCRCODE,XLCREXLV        SET EXTERNAL VARS FLAG.         47010001
         B     SUBSEXIT                                                 47012001
*                                                                       47014001
*                                                                       47016001
         SPACE                                                          47040001
SUBSADDL DS    0H                                                       47080001
       IEMKTAB BLDC,XTSCARG,XTRPOP1                                     47120001
*                                                                       47180001
SUBSEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     47250001
         DROP  GR4                                                      47320001
         EJECT                                                          47390001
*                                                                       47460001
** KESUBP. THIS ROUTINE PROCESSES THE SUB' TRIPLE.                      47530001
**   FOR SUB' TRIPLES WITHIN A FUNCTION NEST, THE SUBS LEVEL COUNT IS   47550001
**   REDUCED BY 1.                                                      47570001
*                                                                       47600001
KESUBP   IEMKENT  TYPE=3                                                47670001
         TM    XTSCFCBT,XTSCIFNT   TEST WHETHER IN FUNCTION NEST        47740001
         BZ    SUBPEXIT            EXIT IF NOT                          47810001
         LH    GR2,XTSCSLCT        LOAD SUBS LEVEL COUNT                47880001
         SH    GR2,=H'1'           SUBTRACT 1                           47950001
         STH   GR2,XTSCSLCT        STORE UPDATED VALUE                  48020001
*                                                                       48090001
SUBPEXIT IEMKLVE  RC=(RC),RP=SCANNTRP RETURN TO PROCESS NEXT TRIPLE     48160001
         EJECT                                                          48230001
*                                                                       48300001
** KECDME. THIS ROUTINE CREATES A DO-MAP ENTRY.                         48370001
**   IF SUFFICIENT SPACE EXISTS IN THE CURRENT TEXT BLOCK, (XMAPEND-    48440001
**   XMAP) BYTES ARE ALLOCATED FOR THE NEW ENTRY. OTHERWISE A NEW TEXT  48510001
**   BLOCK IS OBTAINED AND CHAINED TO THE EXISTING ONE. CERTAIN FIELDS  48580001
**   IN THE NEW ENTRY ARE COMPLETED AND THE ROUTINE RETURNS TO THE      48650001
**   CALLER WITH THE ABSOLUTE ADDRESS OF THE NEW ENTRY IN PR1.          48720001
*                                                                       48790001
KECDME   IEMKENT  TYPE=1                                                48860001
         USING XMAP,GR5                                                 48930001
*                                                                       49000001
       IEMKTAB BLDT,XLCRMAP,SATO=XTSCCUDO,AATO=(GR5)                    49070001
         XC    XMAP(XMAPEND-XMAP),XMAP  CLEAR SPACE FOR NEW ENTRY       49140001
         SPACE                                                          49210001
         MVC   XMAPLEVL,XTSCLEVL   MOVE LOOP NESTING LEVEL TO NEW ENTRY 49280001
         SR    GR2,GR2             ADD ONE                              49350001
         IC    GR2,XTSCLEVL          TO                                 49420001
         LA    GR2,1(0,GR2)          NESTING                            49490001
         STC   GR2,XTSCLEVL          LEVEL FOR THIS LOOP                49560001
         SPACE                                                          49630001
         MVC   XMAPPREF,XTSCPREF   MOVE IN PREFIX OPTIONS BYTE          49700001
         MVC   XMAPTLVL,XTSCTLVL   MOVE IN TOTAL LEVEL BYTE             49770001
         SR    GR2,GR2             UPDATE                               49840001
         IC    GR2,XTSCTLVL          TOTAL                              49910001
         LA    GR2,1(0,GR2)          LEVEL                              49980001
    STC   GR2,XTSCTLVL               COUNT                              50050001
         TM    XTSCCTLB,XTSCINIO   TEST IF WITHIN GET LIST              50120001
         BZ    CDMECMVI            BRANCH IF NOT                        50190001
         OI    XMAPLOOP,XMAPGLST   INDICATE WITHIN GET LIST             50260001
CDMECMVI EQU   *                                                        50330001
         MVC   XMAPITDO,XTSCCUTR   MOVE IN TEXT REF. OF ITDO TRIPLE     50400001
         MVC   XMAPBLOK,XTSCDCLV   MOVE IN DECLARE LEVEL OF BLOCK       50470001
         MVC   XMAPENT1,XTSCDRPB   MOVE IN D.R. OF ENTRY TYPE 1         50540001
         MVC   XMAPOPTN,XTSCCOPT   MOVE IN RULING OPTION                50610001
         MVI   XMAPPTCH,X'FF'      INITIALISE                           50680001
         MVI   XMAPSRGL,X'FF'        HEAD OF LIST                       50750001
         MVI   XMAPUSEL,X'FF'        POINTER                            50820001
         MVI   XMAPSEQU,X'FF'        FIELDS                             50890001
         SPACE                                                          50960001
         LR    PR1,GR5             LOAD RETURN PARAMETER                51030001
*                                                                       51100001
CDMEEXIT IEMKLVE  RC=(RC)          RETURN TO CALLER                     51170001
         DROP  GR5                                                      51240001
         EJECT                                                          51310001
*                                                                       51380001
** KEDEND. DO-END ROUTINE - COMPLETES THE DO-MAP ENTRY.                 51450001
**   THE TEXT REF. OF THE ITD' OR PRC' TRIPLE IS STORED IN THE DO-MAP   51520001
**   ENTRY AND THE ENTRY IS CHAINED TO THE PREVIOUS ENTRY IN THE        51590001
**   PROCESSING SEQUENCE CHAIN, OR TO THE CHAIN HEADER IN XLCR IF THIS  51660001
**   IS THE FIRST LOOP IN THE CHAIN. THE XTSC LOOP STATUS FIELDS ARE    51730001
**   THEN RESTORED FROM THE TOP STACK ENTRY AND THE STACK ENTRY IS      51800001
**   REMOVED FROM THE STACK.                                            51870001
*                                                                       51940001
KEDEND   IEMKENT  TYPE=1                                                52010001
         USING XMAP,GR5                                                 52080001
*                                                                       52150001
       IEMKTAB DR,XLCRMAP,SA=XTSCCUDO,AATO=(GR5)                        52220001
         SPACE                                                          52290001
         MVC   XMAPITDP,XTSCCUTR   MOVE IN TEXT REF. OF ITD' TRIPLE     52360001
         MVC   XMAPITPP,XTSCTRPT   MOVE IN TEXT REF. OF PREVIOUS TRIPLE 52430001
         SPACE                                                          52500001
         CLI   XTSCCSEQ,X'FF'      CHECK IF THIS IS FIRST LOOP IN CHAIN 52570001
         BNE   DENDGNDE            BRANCH IF NOT                        52640001
         MVC   XLCRFMAP,XTSCCUDO   STORE TEXT REF. IN CHAIN HEADER      52710001
         B     DENDSALF            SKIP NORMAL CHAINING                 52780001
         SPACE                                                          52850001
DENDGNDE DS    0H                                                       52890001
       IEMKTAB DR,XLCRMAP,SA=XTSCCSEQ,AATO=(GR5)                        52930001
         MVC   XMAPSEQU,XTSCCUDO   CHAIN CURRENT ENTRY TO LAST ENTRY    52990001
         SPACE                                                          53060001
DENDSALF MVC   XTSCCSEQ,XTSCCUDO   STORE TEXT REF. OF NEW END OF CHAIN  53130001
         SPACE                                                          53200001
         MVC   XTSCCVBT,XSTKCODE   RESTORE CV CODE BYTE FROM STACK      53270001
         NI    XTSCCVBT,XTSCBSPC+XTSCBDCV+XTSCBYBT+XTSCTOBT+XTSCTEMP   -53340001
                                   (CLEAR UNWANTED BITS)                53410001
         MVC   XTSCCOPT(4),XSTKCOPT RESTORE OPTION AND CURRDO FIELDS    53480001
         MVC   XTSCDCLV,XSTKDCLV   RESTORE DECLARE LEVEL FIELD          53550001
         MVC   XTSCDRPB,XSTKDRPB   RESTORE XTSCDRPB                     53620001
         SR    GR2,GR2             DECREMENT                            53690001
         IC    GR2,XTSCTLVL          TOTAL                              53760001
         SH    GR2,=H'1'             LEVEL                              53830001
         STC   GR2,XTSCTLVL          COUNT                              53900001
         SPACE                                                          53970001
         LA    XSTKBASE,XSTKEND-XSTK(0,XSTKBASE) REMOVE STACK ENTRY     54040001
*                                                                       54110001
DENDEXIT IEMKLVE  RC=(XSTKBASE)                                         54180001
         DROP  GR5                                                      54250001
         EJECT                                                          54320001
*                                                                       54390001
** KELKUP. THIS ROUTINE SCANS THE LIST OF PROCEDURES AND POINTERS.      54460001
**   ON ENTRY, PR0 INDICATES THE TYPE OF DIC.ENTRY TO BE SCANNED FOR:   54530001
**                   0 - SCAN FOR PROCEDURE                             54600001
**                   4 - SCAN FOR POINTER                               54670001
**             PR1 POINTS TO THE DIC.REF. TO BE SCANNED FOR.            54740001
**   ON RETURN, IF RC = 0, PR1 POINTS TO THE LIST ENTRY FOUND.          54810001
**   RETURN CODES (RC):   0 - DIC.REF. FOUND                            54880001
**                        4 - DIC.REF. NOT FOUND.                       54950001
**                                                                      55020001
**   THE SCAN IS A SIMPLE SEQUENTIAL SCAN. SINCE THE LIST IS IN DICT.   55090001
**   REF. ORDER THE ROUTINE EXITS IF THE CURRENT LIST ENTRY BECOMES     55160001
**   GREATER THAN THE DIC.REF. BEING SCANNED FOR.                       55230001
*                                                                       55300001
KELKUP   IEMKENT  TYPE=1                                                55370001
         USING XDEL,GR5                                                 55440001
*                                                                       55510001
         LR    GR2,PR0        SAVE                                      55580001
         LR    GR3,PR1          PARAMETER REGISTERS                     55650001
         EX    0,LKUPTMTB(GR2) TEST WHETHER LIST HAS ANY MEMBERS        55720001
         BZ    LKUPNFND       BRANCH IF NOT - ENTRY NOT FOUND           55790001
         SPACE                                                          55860001
       IEMKTAB SET,XTSCDEL,SA=XTSCFAPR(GR2)                             55930001
         SPACE                                                          56000001
LKUPTEND DS    0H                                                       56040001
       IEMKTAB SCAN,XTSCDEL,AATO=(GR5),ETA=LKUPNFND                     56080001
         CLC   XDELDREF,0(GR3)     TEST WHETHER THIS IS REQUIRED ENTRY  56140001
         BH    LKUPNFND            IF HIGH, ENTRY NOT IN LIST           56210001
         BE    LKUPFOUN            IF EQUAL, THIS IS REQUIRED ENTRY     56280001
         LA    GR5,XDELEND1-XDEL(0,GR5) UPDATE XDEL BASE FOR NEXT ENTRY 56350001
         B     LKUPTEND            LOOP TO PROCESS NEXT ENTRY           56420001
         SPACE                                                          56490001
LKUPFOUN LR    PR1,GR5             LOAD RETURN PARAMETER REG.           56560001
         SR    RC,RC               SET ZERO RETURN CODE                 56630001
         B     LKUPEXIT            EXIT                                 56700001
         SPACE                                                          56770001
LKUPNFND LA    RC,4                INDICATE ENTRY NOT FOUND             56840001
         B     LKUPEXIT            EXIT                                 56910001
*                                                                       56980001
LKUPTMTB TM    XTSCCODE,XTSCADDR+XTSCIPRC+XTSCEPRC+XTSCPPRC             57050001
         TM    XTSCCODE,XTSCIPTR                                        57120001
*                                                                       57190001
LKUPEXIT IEMKLVE  RC=(RC)          RETURN TO CALLER                     57260001
         DROP  GR5                                                      57330001
         EJECT                                                          57400001
*                                                                       57470001
** KESTCK. THIS ROUTINE MAKES AN ENTRY IN THE STACK.                    57540001
**   ON ENTRY, THE LOW ORDER BYTE OF PR1 CONTAINS A CODE WHICH          57610001
**   INDICATES THE TYPE OF STACK ENTRY - PROC, BEGN OR ITDO. THIS       57680001
**   CODE IS STORED IN THE NEW STACK ENTRY TOGETHER WITH THE LOOP       57750001
**   STATUS FIELDS FROM XTSC. THE XSTKBASE REGISTER IS UPDATED TO       57820001
**   POINT TO THE NEW ENTRY.                                            57920001
*                                                                       58030001
KESTCK   IEMKENT  TYPE=1                                                58100001
*                                                                       58170001
         SH    XSTKBASE,=AL2(XSTKEND-XSTK) SET XSTK BASE FOR NEW ENTRY  58240001
         SPACE                                                          58310001
STCKMENT STC   PR1,XSTKCODE        STACK ENTRY TYPE CODE                58380001
         OC    XSTKCODE,XTSCCVBT     AND CV CODE BYTE                   58450001
         MVC   XSTKCOPT(4),XTSCCOPT STACK OPTION AND CURRDO FIELDS      58520001
         MVC   XSTKDCLV,XTSCDCLV   STACK DECLARE LEVEL                  58590001
         MVC   XSTKDRPB,XTSCDRPB   STACK D.R. OF ENTRY TYPE 1           58660001
         MVC   XSTKFCBT,XTSCFCBT   STACK FUNCTION CODE BYTE             58730001
         MVC   XSTKSLCT,XSTKSLCT   STACK SUBS LEVEL COUNT               58800001
*                                                                       58870001
STCKEXIT IEMKLVE  RC=(XSTKBASE)    RETURN TO CALLER                     58940001
         EJECT                                                          59010001
*                                                                       59080001
** KEERRH. ERROR HANDLER.                                               59150001
** AN ERROR MESSAGE IS INSERTED IN THE DICTIONARY AND THE COMPILATION   59220001
**   IS TERMINATED.                                                     59290001
*                                                                       59360001
KEERRH   IEMKENT  TYPE=3                                                59440001
         ST    PR0,PAR5                 STORE ERROR NUMBER IN PAR5      59470001
         CLI   PAR5+3,X'0A'             ) BRANCH IF ERROR               59500001
         BE    ERRHDICE                 ) IEMKE1                        59530001
*                                                                       59560001
         MVC   PAR6+1(3),=X'04BA60'     MOVE MESSAGE CODE TO PAR6       59640001
         B     ERRHUERR                                                 59670001
*                                                                       59700001
ERRHDICE MVC   PAR6+1(3),=X'04BB00'     MOVE MESSAGE CODE TO PAR6       59730001
*                                                                       59760001
ERRHUERR L     LR,ZUERR                 CALL ZUERR                      59790001
         BALR  RR,LR                 TO INSERT MESSAGE IN DICTIONARY    59830001
         L     LR,ZABORT           LOAD RETURN POINT ADDRESS            59930001
*                                                                       60030001
ERRHEXIT IEMKLVE  NORC,RP=(LR)                                          60230001
         EJECT                                                          60480001
         LTORG                                                          60550001
         EJECT                                                          60620001
*                                                                       60690001
**   EQUATE TABLE                                                    ** 60760001
*                                                                       60830001
*                   REGISTER EQUATES                                    60900001
GRDS     EQU   7                        DICTIONARY POINTER              60970001
GRXDEL   EQU   3                        TABLE POINTER                   61040001
GRBASE   EQU   9                        CSECT BASE REGISTER             61110001
GRSCR    EQU   6                        XISP DSECT BASE - SCRATCH BASE  61180001
GRX      EQU   1                        GENERAL WORKING REGISTER        61250001
*                                                                       61390001
GRPAR0   EQU   4                        PARAMETER REGISTERS.  IF THESE  61460001
GRPAR1   EQU   5                          WERE TO BE EQUATED TO ACTUAL  61530001
*                                         REGISTERS 0 & 1, IT MAY BE    61600001
*                                         NECESSARY TO ADD INSTRUCTIONS 61670001
*                                         TO SAVE THESE REGISTERS       61740001
*                                         AROUND CALLS TO UTILITY       61810001
*                                         ROUTINES                      61880001
*                                                                       61950001
*                                                                       62020001
*                   GENERAL EQUATES                                     62090001
*                                                                       62160001
BNO      EQU   14                       BRANCH ON NOT ONES              62230001
EODB     EQU   X'CF'                    END OF DICTIONARY BLOCK         62300001
BCDAPP   EQU   X'80'                    BCD APPENDED                    62370001
*                                                                       62440001
ZLOCK    EQU   LOCK                     RENAME ZLOCK                    62510001
         EJECT                                                          62580001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*KE 001-TSS 62610020
IEMKE1   CSECT                                                          62650001
*        ----------------------------------------------------KE 001-TSS 62680020
**                                                                      62720001
**             THIS MODULE SCANS THE DICTIONARY AND MARKS CERTAIN       62790001
**       VARIABLES SAFE/UNSAFE, AND PRODUCES A LIST OF DICTIONARY       62860001
**       REFERENCES TO INTERNAL POINTERS, INTERNAL AND EXTERNAL         62930001
**       PROCEDURES AND FUNCTIONS, AND ADDR FUNCTIONS, AND SETS FLAGS   63000001
**       TO STATE THAT THE ABOVE LISTS ARE PRESENT AND ALSO MARK THE    63070001
**       PRESENCE OF EXTERNAL POINTERS AND POINTER FUNCTIONS.           63140001
**                                                                      63210001
**                                                                      63280001
**             A VARIABLE IS DEFINED AS BEING UNSAFE IF IT              63350001
**       SATISFIES ANY OF THE FOLLOWING CONDITIONS:-                    63420001
**                                                                      63490001
**             1.                       EXTERNAL                        63560001
**             2.                       BASED OR DEFINED                63630001
**             3.                       DEFINED UPON                    63700001
**             4.                       PARAMETER                       63770001
**                                                                      63840001
**             ONLY VALID DICTIONARY ENTRIES WITH CODES ENDING IN       63910001
**       'E' OR 'F', EXCEPT 'CE' AND 'CF' ARE EXAMINED.  COMPILER       63980001
**       CREATED TEMPORIES ARE ASSUMED SAFE.                            64050001
**                                                                      64120001
**                                                                      64190001
**             THE SAFE/UNSAFE FLAG POSITION IS DEFINED IN              64260001
**       THE XDFM DSECT.                                                64330001
**                                                                      64400001
**                                                                      64470001
**             EACH DICTIONARY ENTRY IN THE CREATED LIST IS             64540001
**       PRECEDED BY A CODE BYTE, THESE VALUES BEING DEFINED IN         64610001
**       THE XDEL DSECT.                                                64680001
**                                                                      64750001
**                                                                      64820001
**             THIS LIST IS PASSED TO PHASE KE IN SCRATCH CORE          64890001
**       ALONG WITH CERTAIN PARAMETERS LOADED INTO SLOTS IN             64960001
**       MODULE KA, AS DEFINED BY XLCR DSECT, AND IN SCRATCH            65030001
**       CORE AS DEFINED BY XISP DSECT.                                 65100001
**                                                                      65170001
**                                                                      65240001
         EJECT                                                          65310001
*                                                                       65380001
** THE XTSC CONTROL BLOCK CONTAINS WORK FIELDS USED BY THE TEXT SCAN    65450001
** ROUTINE.                                                             65520001
*                                                                       65590001
         SPACE                                                          65660001
XTSC     DS    0D                                                       65730001
*                                                                       65800001
XTSCCTLB DC    AL1(0)              CONTROL BYTE:                        65870001
XTSCIPTL EQU   X'08'               ON IF INSIDE PUT LIST                65900001
XTSCINIO EQU   X'04'               ON IF IN GET LIST                    65940001
XTSCIFTL EQU   X'02'               ON IF INSIDE FORMAT LIST             65970001
XTSCPPEP EQU   X'01'               ON IF POINTER PASSED TO EXT PROC     66010001
         SPACE                                                          66080001
XTSCCUTR DC    XL3'0'              TEXT REF. OF CURRENT RIPLE           66150001
*                                                                       66220001
XTSCCODE DC    X'0'                CODE BYTE SET UP BY KCDS             66290001
XTSCADDR EQU   X'80'                 ADDR FUNCTION PRESENT              66360001
XTSCIPTR EQU   X'40'                 INTERNAL POINTER PRESENT           66430001
XTSCEPTR EQU   X'20'                 EXTERNAL POINTER PRESENT           66500001
XTSCIPRC EQU   X'10'                 INTERNAL PROCEDURE PRESENT         66570001
XTSCEPRC EQU   X'08'                 EXTERNAL PROCEDURE PRESENT         66640001
XTSCPPRC EQU   X'04'                 POINTER PROCEDURE PRESENT          66710001
         SPACE                                                          66780001
XTSCTRPT DC    XL3'0'              TEXT REF. OF PREVIOUS TRIPLE         66850001
*                                                                       66920001
XTSCPTR1 DC    A(0)                1ST FUNCTION LIST POINTER            66990001
XTSCPTR2 DC    A(0)                2ND FUNCTION LIST POINTER            67060001
XTSCWORK DC    A(0)                4 BYTE WORK AREA                     67130001
*                                                                       67200001
XTSCCVBT DC    X'0'                CONTROL BYTE FOR ANALYSING CV SPEC.  67270001
XTSCBSPC EQU   X'80'                 BAD SPECIFICATION    ) SEE         67340001
XTSCBDCV EQU   X'40'                 BAD CONTROL VARIABLE ) XMAPSPEC    67410001
XTSCBYBT EQU   X'20'                 BY ENCOUNTERED                     67480001
XTSCTOBT EQU   X'10'                 TO ENCOUNTERED                     67550001
XTSCTEMP EQU   X'01'                 CV IS A TEMPORARY                  67620001
         SPACE                                                          67690001
XTSCTLVL DC    X'00'               TOTAL LEVEL COUNT - ITDOS & PROCS    67760001
*                                                                       67830001
XTSCCOPT DC    AL1(XTSCORDR)       CURRENT OPTION RULING (CURROPT)      67900001
XTSCORDR EQU   X'80'               ON FOR ORDER, OFF FOR REORDER        67970001
         SPACE                                                          68040001
XTSCCUDO DC    X'FF0000'           TEXT REF. OF CURRENT DO MAP ENTRY    68110001
*                                                                       68180001
XTSCLEVL DC    X'0'                NESTING LEVEL OF DO LOOP             68250001
         SPACE                                                          68320001
XTSCCSEQ DC    X'FF0000'           TEXT REF. OF LAST DO MAP ENTRY IN   -68390001
                                     PROCESSING SEQUENCE CHAIN          68460001
*                                                                       68530001
         SPACE                                                          68600001
XTSCDCLV DC    XL2'0'              BLOCK IDENTIFIER OF CURRENT TEXT     68670001
*                                                                       68740001
XTSCFCBT DC    X'0'                FUNCTION CODE BYTE                   68810001
XTSCUNSF EQU   X'80'               ON IF FUNCTION UNSAFE                68880001
XTSCEXTP EQU   X'40'               ON IF EXTERNAL PROCEDURE             68950001
XTSCIFNT EQU   X'10'               ON IF INSIDE FUNCTION NEST           69020001
XTSCBIFB EQU   X'20'               ON IF BUILT-IN FUNCTION              69090001
XTSCEXP2 EQU   X'08'               ON IF EXTERNAL PROCEDURE             69120001
XTSCFAPR DC    AL3(0)              S.A. OF FIRST ADDR OR PROCEDURE     /69170001
                                     IN LIST                            69230001
XTSCPREF DS    X                   PREFIX OPTIONS BYTE FROM STNO TRIPLE 69300001
XTSCFIPV DC    AL3(0)              S.A. OF FIRST INTERNAL POINTER      -69370001
                                     IN LIST                            69440001
*                                                                       69510001
XTSCCVDR DC    XL2'0'              DICT. REF. OF CV.                    69580001
XTSCDRPB DC    XL2'0'              DICT. REF. OF PROC OR BEGIN          69650001
XTSCSLCT DC    H'0'                SUBS TRIPLES LEVEL COUNT             69720001
XTSCBPIC DC    H'0'                     BEGIN, PROC, ITDO COUNT         69740001
XTSCPPBL DC    X'0'                     PREVIOUS PROC/BEGN LEVEL COUNT  69760001
XTSCDEL  DC    A(XTSCDELA)         POINTER TO DEL TCA                   69790001
XTSCARG  DC    A(XTSCARGA)         POINTER TO DTCA FOR LIST OF ARGUMNTS 69860001
XTSCARG  IEMKTCA XTSCARGA,ET=F,L=2,OPS=S TCA FOR LIST OF ARGUMENTS TO  -69930001
                                      EXTERNAL PROCEDURES               70000001
XTSCDEL  IEMKTCA XTSCDELA,ET=F,L=3,OPS=S TCA FOR DICT. ENTRIES LIST     70070001
XTSCTRTB DC    256X'0'             TRANSLATE TABLE FOR SELECTING TRIPLS 70140001
*                                                                       70210001
         EJECT                                                          70280001
*                                                                       70350001
** THE FOLLOWING EQUATES REPLACE THE XISP DSECT                         70420001
*                                                                       70490001
XISPCODE EQU   XTSCCODE            FLAG BYTE:                           70560001
XISPADDR EQU   XTSCADDR                                                 70630001
XISPIPTR EQU   XTSCIPTR                                                 70700001
XISPEPTR EQU   XTSCEPTR                                                 70770001
XISPIPRC EQU   XTSCIPRC                                                 70840001
XISPEPRC EQU   XTSCEPRC                                                 70910001
XISPPPRC EQU   XTSCPPRC                                                 70980001
         EJECT                                                          71050001
KCDSIN   IEMKENT                        SAVE REGISTERS                  71120001
*                                                                       71190001
*                                                                       71260001
         USING XDEL,GRXDEL              BASE XDEL DSECT                 71330001
         USING XDFM,GRDS                BASE XDFM DSECT                 71400001
*                                                                       71470001
         EJECT                                                          71540001
*                                                                       71610001
**  MAIN CONTROLLING SECTION.                                         * 71680001
**  SCANS DICTIONARY, BRINGING IN NEW BLOCKS WHEN REQUIRED           ** 71750001
*                                       SET UP PARAMETERS TO MAKE       71820001
         LA    GRDS,KCDSENDC                 A DICTIONARY ENTRY, WITH   71890001
         ST    GRDS,PAR1                  A SPECIAL CODE TO MARK THE    71960001
         LA    GRDS,4                     PRESENT END OF THE DICTIONARY 72030001
         ST    GRDS,PAR2                                                72100001
*                                                                       72170001
         L     LR,ZDICRF                MAKE DICTIONARY ENTRY           72240001
         BALR  RR,LR                                                    72310001
*                                                                       72380001
*                                                                       72450001
         L     GRSCR,XLCRXISP           LOAD XISP BASE REGISTER         72520001
         MVI   XISPCODE,X'00'           CLEAR FLAGS                     72590001
*                                       OBTAIN SPACE FOR FIRST ENTRY    72660001
       IEMKTAB BLDT,XTSCDEL,AATO=(GRXDEL),SATO=KCDSSATO                 72730001
         LA    GRDS,FSTDRF+1            INITIALIZE SCAN POINTER TO      72800001
*                                         POINT ONE SHORT OF SYMBOLIC   72870001
*                                         POINTER TO START OF DICT      72940001
*                                                                       73010001
**  IT APPEARS THAT THE FIRST TWO BYTES OF FSTDRF ARE NOT USED          73080001
**        AT THIS POINT  -  INSTRUCTIONS COPIED FROM MODULE 'FT'        73150001
*                                                                       73220001
KCDSLKIN MVC   ZLOCK(2),1(GRDS)         LOCK IN NEW BLOCK               73290001
         MVC   KCDSLOCK,ZLOCK           PICK UP REFERENCE TO NEXT BLOCK 73360001
         MVC   PAR1+2(2),ZLOCK            STORE LOCALLY AND CONVERT TO  73430001
         L     LR,ZDRFAB                  ABSOLUTE VALUE USING ZDRFAB   73500001
         BALR  RR,LR                                                    73570001
*                                                                       73640001
         L     GRDS,PAR1                RESET DICTIONARY SCAN POINTER   73710001
*                                                                       73780001
KCDSBLND CLI   0(GRDS),EODB             IS THIS THE END OF A BLOCK      73850001
         BE    KCDSLKIN                 BRANCH IF END OF BLOCK FOUND    73920001
*                                                                       73990001
         LA    GRDS,3(0,GRDS)           BUMP POINTER TO FULLWORD        74060001
         N     GRDS,KCDSBDMK              BOUNDARY                      74130001
*                                                                       74200001
         XR    2,2                      CLEAR REGISTER 2 FOR TRT        74270001
         TRT   XDFMCODE,KCDSDETL                                        74340001
         BZ    KCDSEROR                 INCORRECT DICTIONARY CODE BYTE  74410001
*                                         FOUND                         74480001
KCDSBRTL B     KCDSBRTL(2)              BRANCH TABLE                    74550001
         B     KCDSVARS                      TYPE XE AND XF ENTRIES     74620001
         B     KCDSIGEN                      TYPE 06 ENTRY              74690001
         B     KCDSINTP                      TYPE 01 ENTRY              74760001
         B     KCDSEXTP                      TYPE 03 ENTRY              74830001
         B     KCDSTENT                      DICTIONARY TERMINATING     74900001
*                                              ENTRY FOUND              74970001
         B     KCDSNXTN                      OTHER NON ZERO ENTRIES     75040001
*                                                                       75110001
         B     KCDSLABV                 TYPE X7 ENTRIES                 75140001
         EJECT                                                          75180001
*                                                                       75250001
**  INCREMENT POINTER REGISTER TO BYTE FOLLOWING CURRENT ENTRY       ** 75320001
**  MAKES ALLOWANCE FOR ANY BCD THAT MAY BE PRESENT                  ** 75390001
*                                                                       75460001
KCDSNXTN LR    GRX,GRDS                 SAVE POINTER TO START OF ENTRY  75530001
         MVC   KCDSFW(2),XDFMLNTH       INCREASE POINTER BASE BY LENGTH 75600001
         NI    KCDSFW,X'7F'             ( ENSURE LENGTH IS POSITIVE )   75630001
         AH    GRDS,KCDSFW                OF ENTRY                      75670001
*                                                                       75740001
         TM    0(GRX),BCDAPP            IS THERE A BCD APPENDED         75810001
         BO    KCDSBLND                 BRANCH IF NO BCD                75880001
*                                                                       75950001
         XR    GRX,GRX                  CLEAR WORK REGISTER             76020001
         IC    GRX,0(0,GRDS)            PICK UP BCD LENGTH-1            76090001
         LA    GRDS,2(GRX,GRDS)         BUMP POINTER TO BYTE PAST       76160001
*                                         CURRENT ENTRY                 76230001
         B     KCDSBLND                 BRANCH TO EXAMINE NEXT ENTRY    76300001
*                                                                       76370001
         EJECT                                                          76440001
*                                                                       76510001
** EXAMINATION OF TYPE XE AND XF DICTIONARY ENTRIES TO DECIDE        ** 76580001
** WHETHER OR NOT THAT VARIABLE IS CLASSIFIED AS UNSAFE.             ** 76650001
** LOOKS ALSO FOR POINTER VARIABLES                                  ** 76720001
*                                                                       76790001
KCDSVARS TM    XDFMFVAR,XDFMEXTN        TEST IF EXTERNAL                76820001
         BO    KCDSIEXV                 IF SO BRANCH                    76850001
*                                                                       76880001
         TM    XDFMFOT2,XDFMEXTN        TEST IF EXTERNAL                76910001
         BO    KCDSIEXV                 IF SO BRANCH                    76940001
*                                                                       77000001
         TM    XDFMFOT2,XDFMPARM        TEST IF FORMAL PARAMETER        77070001
         BO    KCDSSETU                 BRANCH TEST POSITIVE            77140001
*                                                                       77280001
         TM    XDFMFVAR,XDFMBADF        TEST IF DEFINED OR BASED        77350001
         BO    KCDSSETU                 BRANCH TEST POSITIVE            77380001
*                                                                       77420001
         TM    XDFMFOT4,XDFMDFST        TEST IF MEMBER OF DFND STRUCT   77490001
         BO    KCDSSETU                 BRANCH TEST POSITIVE            77560001
*                                                                       77630001
         TM    XDFMFOT1,XDFMDFON        TEST IF DEFINED UPON            77730001
         BO    KCDSSETU                 IF SO BRANCH                    77830001
*                                                                       78050001
KCDSSETS NI    XDFMFSBT,XDFMSAFE        CLEAR UNSAFE FLAG               78120001
         B     KCDSTSTE                 BYPASS SETTING OF FLAG          78190001
*                                                                       78260001
KCDSIEXV OI    XLCRCODE,XLCRBEEN   INDICATE EXTERNAL VARIABLE PRESENT   78280001
         SPACE                                                          78300001
KCDSSETU OI    XDFMFSBT,XDFMUNSF        SET UNSAFE FLAG                 78330001
*                                                                       78400001
KCDSTSTE TM    XDFMCODE,XDFMCD0F        TEST FOR TYPE XF ENTRIES        78470001
         BM    KCDSNXTN                 BRANCH IF TYPE XF NOT FOUND     78540001
*                                         IE ENTRY DOES NOT CARRY DATA  78610001
*                                         BYTE                          78680001
         TM    XDFMFDAT,XDFMPNTR        TEST IF VARIABLE IS POINTER     78750001
         BC    BNO,KCDSNXTN             BRANCH IF NOT POINTER           78820001
*                                                                       78890001
**  POINTER FOUND                                                       78960001
*                                                                       79030001
         OI    XDFMFSBT,XDFMUNSF        SET UNSAFE FLAG FOR POINTER     79050001
*                                                                       79070001
         TM    XDFMFOT2,XDFMEXTN        TEST IF EXTERNAL                79100001
         BO    KCDSEXPN                 BRANCH IF EXTERNAL              79170001
*                                                                       79240001
         TM    XDFMFVAR,XDFMEXTN        TEST IF EXTERNAL                79310001
         BZ    KCDSINPN                 BRANCH IF NOT EXTERNAL          79380001
*                                                                       79450001
KCDSEXPN OI    XISPCODE,XISPEPTR        SET EXTERNAL POINTER FLAG       79520001
         B     KCDSNXTN                 BRANCH EXAMINE NEXT ENTRY       79590001
*                                                                       79660001
*                                                                       79730001
*                                                                       79800001
KCDSINPN TM    XISPCODE,XISPIPTR        TEST IF INTERNAL POINTER FLAG   79870001
*                                         ALREADY SET                   79940001
         BO    KCDSPSET                 BRANCH IF FLAG SET              80010001
*                                                                       80080001
         OI    XISPCODE,XISPIPTR        SET INTERNAL POINTER FLAG       80150001
*                                                                       80220001
         MVC   XTSCFIPV(3),KCDSSATO STORE FIRST ENTRY SYMB. ADDR.       80290001
*                                                                       80360001
*                                                                       80430001
KCDSPSET LR    GRPAR1,GRDS              LOAD DICTIONARY ABSOLUTE ADDR   80500001
         IC    GRPAR0,=AL1(XDELPNTR)    SET POINTER CODE                80570001
*                                                                       80640001
         B     KCDSLENT                 BRANCH TO LIST ENTRY IN TABLE   80710001
*                                                                       80780001
         EJECT                                                          80850001
*                                                                       80920001
**  EXAMINE BUILT-IN GENERIC FUNCTIONS TO FIND 'ADDR'S               ** 80990001
*                                                                       81060001
KCDSIGEN CLI   XDFM6TYP,XDFM6ADD        TEST FOR ADDR BUILT-IN FUNCTION 81130001
         BNE   KCDSNXTN                 BRANCH IF NOT FOUND TO EXAMINE  81200001
*                                         NEXT ENTRY                    81270001
*                                                                       81340001
         LR    GRPAR1,GRDS              SET REGISTERS 0 & 1 FOR MAKING  81410001
         IC    GRPAR0,=AL1(XDELADDR)      LIST ENTRY                    81480001
*                                                                       81550001
         TM    XISPCODE,XISPADDR        TEST IF ADDR FLAG ALREADY SET   81620001
         BO    KCDSLENT                 BRANCH IF SET TO ADD ENTRY      81690001
*                                         TO LIST                       81760001
         OI    XISPCODE,XISPADDR+XISPPPRC                               81830001
*                                       SET ADDR AND POINTER PROC FLAG  81900001
         EJECT                                                          81970001
*                                                                       82040001
**  THESE INSTRUCTIONS STORE ADDRESS OF FIRST PROC OR ADDR              82110001
**       ENTRY IN LIST                                                  82180001
*                                                                       82250001
KCDSTXRF TM    KCDSPRFL,KCDSFAPR        TEST IF XISPFAPR ALREADY SET    82320001
         BO    KCDSLENT                 BRANCH IF SET                   82390001
*                                                                       82460001
         OI    KCDSPRFL,KCDSFAPR        SET FLAG, XISPFAPR LOADED       82530001
*                                                                       82600001
         MVC   XTSCFAPR(3),KCDSSATO STORE FIRST ENTRY SYMB. ADDR.       82670001
*                                                                       82740001
         B     KCDSLENT                 BRANCH TO INCLUDE ENTRY IN LIST 82810001
*                                                                       82880001
         EJECT                                                          82950001
*                                                                       83020001
**  EXAMINE EXTERNAL PROCEDURE ENTRIES.  THESE ARE TO BE INCLUDED    ** 83090001
**  IN THE TABLE AND, IF THEY ARE FUNCTIONS RETURNING A POINTER, THE ** 83160001
**  ENTRIES ARE MARKED ACCORDINGLY                                   ** 83230001
*                                                                       83300001
KCDSEXTP LR    GRPAR1,GRDS              SET REGISTERS 0 & 1 FOR LOADING 83370001
         IC    GRPAR0,=AL1(XDELEXPR)      ENTRY IN TABLE                83440001
         OI    XISPCODE,XISPEPRC        SET EXTERNAL PROCEDURE FLAG     83510001
         TM    XDFM3DAT,XDFMPNTR        TEST IF FNC RETURNS POINTER     83580001
         BC    BNO,KCDSTXRF             BRANCH IF NO POINTER            83650001
*                                                                       83720001
         XC    KCDSFW(3),KCDSFW         SET KCDSFW EQUAL TO CODE FOR    83790001
         MVI   KCDSFW+3,XDELPRPN          POINTER FUNCTION              83860001
         O     GRPAR0,KCDSFW            OR THIS VALUE INTO CODE BYTE    83930001
*                                                                       84000001
         OI    XISPCODE,XISPPPRC        SET POINTER PROCEDURE FLAG      84070001
*                                                                       84140001
         B     KCDSTXRF                 BRANCH TO CHECK IF FIRST PROC   84210001
*                                         IN LIST                       84280001
*                                                                       84350001
         EJECT                                                          84420001
*                                                                       84490001
**   PATH FOLLOWED IF A CODE BYTE ENTRY IN A DICTIONARY ENTRY IS     ** 84560001
**   FOUND WHICH IS NOT ACCEPTABLE                                   ** 84630001
*                                                                       84700001
KCDSEROR LA    PR0,10                   LOAD ERROR CODE NUMBER          84800001
         B     KEERRH              CALL ERROR HANDLER                   84900001
*                                                                       85190001
         EJECT                                                          85195001
KCDSLABV OI    XLCRCODE,XLCRLABV        SET LABEL VARS PRESENT FLAG     85200001
*                                                                       85205001
         TM    XDFMFOT2,XDFMEXTN        ) BRANCH IF                     85210001
         BO    KCDSEXLV                 ) EXTERNAL                      85215001
*                                                                       85220001
         TM    XDFMFVAR,XDFMEXTN        ) BRANCH IF NOT                 85225001
         BZ    KCDSNXTN                 ) EXTERNAL                      85230001
*                                                                       85235001
KCDSEXLV OI    XLCRCODE,XLCREXLV        SET EXTERNAL LABEL VARS PRESENT 85240001
*                                                                       85245001
         B     KCDSNXTN                                                 85250001
         EJECT                                                          85260001
*                                                                       85330001
**  ADD ENTRY TO LIST, AND HANDLE THE ALLOCATION AND HOLDING OF FULL ** 85400001
**  TEXT BLOCKS                                                      ** 85470001
*                                                                       85540001
KCDSLENT MVC   PAR1+2(2),KCDSLOCK       SET PAR1 WITH DICT REF TO ENTRY 85610001
*                                         IN THIS BLOCK. USE ENTRY      85680001
*                                         WHICH INITIALLY CALLED THIS   85750001
*                                         PARTICULAR DICTIONARY BLOCK   85820001
         XC    PAR1(2),PAR1        CLEAR H.O. BYTES OF PAR1             85850001
         ST    GRPAR1,PAR2              LOAD PAR2 WITH ABSOLUTE ADDRESS 85890001
         MVI   PAR2,X'0'           CLEAR H.O. BYTE OF PAR2              85920001
         L     LR,ZDABRF                CALL ZDABRF TO CONVERT ABSOLUTE 85960001
         BALR  RR,LR                      ADDRESS TO DICTIONARY REF     86030001
*                                                                       86100001
*                                                                       86170001
*                                                                       86240001
*                                                                       86310001
KCDSMENT STC   GRPAR0,XDELCODE          STORE CODE BYTE                 86380001
         MVC   XDELDREF,PAR1+2          STORE DICTIONARY REFERENCE      86450001
*                                                                       86520001
         TM    XDELCODE,XDELPNTR        TEST IF ENTRY IS POINTER VAR    86590001
         BC    BNO,KCDSINCR             BRANCH IF NOT POINTER           86660001
*                                                                       86730001
*                                                                       86800001
         MVC   KCDSINPV+1(3),KCDSSATO   STORE ADDRESS OF LAST POINTER   86870001
KCDSINCR DS    0H                                                       86910001
       IEMKTAB BLDT,XTSCDEL,AATO=(GRXDEL),SATO=KCDSSATO                 86950001
*                                       GET SPACE FOR NEXT ENTRY        87010001
*                                                                       87080001
*                                                                       87150001
         B     KCDSNXTN           BRANCH TO EXAMINE NEXT ENTRY          87220001
         EJECT                                                          87290001
*                                                                       87360001
**  PROCESS INTERNAL PROCEDURES, DICTIONARY CODE 01                  ** 87430001
**  EXAMINE ENTRY TYPE 2 TO CHECK FUNCTIONS RETURNING POINTER        ** 87500001
*                                                                       87570001
KCDSINTP ST    GRDS,KCDSFW              TEMPORARILY STORE CURRENT       87640001
*                                         DICTIONARY ENTRY              87710001
*                                                                       87780001
         MVC   PAR1+2(2),XDFM1ENT       SET PAR1 FOR ZDRFAB, TO FIND    87850001
         L     LR,ZDRFAB                  ABSOLUTE ADDRESS FROM         87920001
         BALR  RR,LR                      DICTIONARY REFERENCE          87990001
*                                                                       88060001
         L     GRDS,PAR1                SET UP XDFM BASE REGISTER TO    88130001
*                                         ACCESS ENTRY TYPE 2           88200001
         MVC   KCDSFW(1),XDFM5DAT    OBTAIN DATA BYTE APPROPRIATE       88270001
*                                         TO ENTRY                      88340001
*                                                                       88410001
         L     GRDS,KCDSFW              RELOAD CURRENT DIC. ENTRY ADDR. 88480001
*                                                                       88550001
         IC    GRPAR0,=AL1(XDELINPR)    SET INTERNAL PROCEDURE CODE     88620001
         LR    GRPAR1,GRDS              SET ADDRESS PARAMETER           88690001
         OI    XISPCODE,XISPIPRC        SET INTERNAL PROCEDURE FLAG     88760001
         TM    KCDSFW,XDFMPNTR    TEST TO SEE IF FUNCTION RETURNS       88830001
*                                         A POINTER                     88900001
         BC    BNO,KCDSTXRF             BRANCH IF NOT A POINTER TO ADD  88970001
*                                         TO LIST                       89040001
         XC    KCDSFW(3),KCDSFW         SET KCDSFW EQUAL TO CODE FOR    89110001
         MVI   KCDSFW+3,XDELPRPN          POINTER FUNCTION              89180001
         O     GRPAR0,KCDSFW            OR THIS VALUE INTO CODE BYTE    89250001
*                                                                       89320001
         OI    XISPCODE,XISPPPRC        SET POINTER PROCEDURE FLAG      89390001
*                                                                       89460001
         B     KCDSTXRF                 BRANCH TO CHECK IF FIRST PROC   89530001
*                                         IN LIST                       89600001
*                                                                       89670001
         EJECT                                                          89740001
*                                                                       89810001
**   TERMINATE LIST.  MARK LAST POINTER VARIABLE, IF APPLICABLE      ** 89880001
**   AND TEXT BLOCK IF IN USE                                        ** 89950001
*                                                                       90020001
KCDSTENT MVI   XDELCODE,XDELLEND        ADD TABLE TERMINATING CODE      90090001
         XC    XDELDREF,XDELDREF        CLEAR REST OF ENTRY             90160001
         L     GRX,KCDSINPV             TEST WHETHER INTERNAL POINTER   90230001
         LTR   GRX,GRX                    ADDRESS SET                   90300001
*                                                                       90370001
         BZ    KCDSEXIT                 BRANCH IF NO POINTERS           90440001
*                                                                       90510001
*                                                                       90580001
KCDSFNTX MVC   PAR1,KCDSINPV            CONVERT TEXT REFERENCE TO       90650001
         L     LR,ZTXTAB                  ABSOLUTE ADDRESS USING ZTXTAB 90720001
         BALR  RR,LR                                                    90790001
*                                                                       90860001
         L     GRXDEL,PAR1              LOAD XDEL BASE AND FLAG POINTER 90930001
         OI    XDELCODE,XDELEPNT          ENTRY AS LAST IN LIST         91000001
*                                                                       91070001
*                                                                       91140001
KCDSEXIT MVI   0(GRDS),X'C8'            MOVE IN C8 CODE BYTE WHICH WILL 91210001
*                                         CAUSE ENTRY TO BE IGNORED BY  91280001
*                                         LATER PHASES                  91350001
         XC    ZLOCK(2),ZLOCK           CLEAR LOCK SLOT                 91420001
*                                                                       91490001
         IEMKLVE                        LEAVE MACRO                     91560001
*                                                                       91630001
         EJECT                                                          91700001
*                                                                       91770001
**   LOCAL DATA BLOCK AND EQUATES                                    ** 91840001
*                                                                       91910001
KCDSTEXT DC    F'0'                     TEXT REFERENCE OF CURRENT BLOCK 91980001
KCDSINPV DC    F'0'                     LAST INTERNAL POINTER IN LIST   92050001
KCDSFW   DC    F'0'                     FULLWORD WORK SPACE             92120001
KCDSBDMK DC    X'FFFFFFFC'              MASK TO GIVE FULLWORD ADDRESS   92190001
KCDSENDC DC    X'10000400'              TERMINAL ENTRY                  92260001
KCDSLOCK DC    H'0'                     DICTIONARY REFERENCE OF CURRENT 92330001
*                                         BLOCK                         92400001
KCDSTBFL DC    X'00'                    TEXT BLOCK IN USE FLAG          92470001
KCDSTBCD EQU   X'01'                    SET VALUE OF ABOVE FLAG         92540001
*                                                                       92610001
KCDSSATO DC    XL3'0'                   SYMBOLIC ADDRESS OF ENTRY       92680001
KCDSPRFL DC    X'00'                    FIRST PROCEDURE IN LIST FLAG    92750001
KCDSFAPR EQU   X'01'                    SET VALUE OF ABOVE FLAG         92820001
*                                                                       92890001
KCDSTXCD EQU   X'03'                    UNWANTED CODE FOR ZALTER        92960001
*                                                                       93030001
KCDSMES1 DC    X'04BA00'                ERROR MESSAGE CODE              93100001
*                                                                       93170001
*                                                                       93240001
KCDSDETL DC    X'180C18101818',X'081C18',3X'00',2X'18',X'0004'          93310001
         DC    X'14',6X'00',X'1C',4X'00',2X'18',X'0004'                 93380001
         DC    7X'00',X'1C',4X'00',2X'18',2X'04'                        93450001
         DC    7X'00',X'1C',4X'00',2X'18',2X'04'                        93520001
         DC    X'18',12X'00',X'18',2X'00'                               93590001
         DC    48X'00'                                                  93660001
         DC    7X'18',X'1C',2X'18',2X'00',2X'18',X'0004'                93730001
         DC    X'18',6X'00',X'1C',X'18',3X'00',2X'18',X'0004'           93800001
         DC    7X'00',X'1C',4X'00',2X'18',X'0404'                       93870001
         DC    7X'00',X'1C',4X'00',2X'18',X'0404'                       93940001
         DC    16X'18'                                                  94010001
*                                                                       94080001
         EJECT                                                          94150001
         LTORG                                                          94220001
         END                                                            94290001
