KG       TITLE 'PL/1(F), IEMKG, DO EXAMINE PHASE, DO LOOP OPTIMISATION' 00003020
         SPACE 3                                                        00006020
*                                                                       00009020
*                                                                       00012020
*        THE FOLLOWING APARS HAVE BEEN FIXED IN THIS MODULE             00015020
*                                                                       00018020
*                                                                       00021064
*                                                                       00021564
*                                                                       00022064
* 5.4  A 220000.                                              MAC 54726 00022564
*      C 155200,550000,786000.                                MAC 54726 00023064
*      D 218000-218400.                                       MAC 54726 00023564
* 5.4  A 570000,587200.                                       MAC 54703 00024064
*      C 481600,570160,570324-570336,570348,570364-570380.    MAC 54703 00024564
*      D 570400-571600.                                       MAC 54703 00025064
* 5.3A C 036400.                                              MAC 35253 00025564
* 5.2B C 183200,557600,817200.                                MAC 35453 00026064
* 5.2  C 211600.                                              MAC 33903 00026564
*      D 209300-209400.                                       MAC 33903 00027064
* 5.2  A 417600.                                              MAC 32240 00027564
* 5.2  A 228800,254000,754800.                                MAC 30372 00028064
*      C 108800-109200,116800-117200.                         MAC 30372 00028564
* 5.2          ( A31635 IS ALSO FIXED BY FIX FOR A30372. )    MAC 31635 00029064
* 5.2  A 355200.                                              MAC 31190 00029564
*      C 353270,824400.                                       MAC 31190 00030064
*                                                                       00030564
*                                                                       00031064
*                                                                       00033020
*                                                                       00040201
* FUNCTIONS - (1) SCAN ON UNITS (IF ANY) TO NOTE 'BAD' ON-UNITS         00040301
*                                                                       00040401
*             (2) SCAN TEXT CORRESPONDING TO EACH DO-MAP ENTRY IN TURN  00040501
*                 AND CONSTRUCT 'USE' AND 'SUBS/REGION' LISTS WHICH     00040601
*                 ARE CHAINED OFF THE DO MAP ENTRIES.                   00040701
*                                                                       00040801
*             (3) SET VARIOUS FLAGS IN EACH DO-MAP ENTRY GIVING FURTHER 00040901
*                 INFORMATION ABOUT THE LOOP OR PROCEDURE.              00041001
         SPACE 3                                                        00041101
*                                                                       00041201
*        ON_UNITS ARE SCANNED USING A TABLE SET UP BY PHASE KC.         00041301
*        THE TABLE IS A SET OF 6_BYTE ENTRIES IN A TEXT BLOCK. THESE    00041401
*        ENTRIES CONTAIN A CODE BYTE SIGNIFYING THE TYPE OF ON_UNIT     00041501
*        AND THE TEXT REFERENCE OF THE SNAP OR NOSNAP TRIPLE            00041601
*        CORRESPONDING TO THE ON_UNIT.                                  00041701
*        THE ON_UNITS ARE SCANNED FOR:                                  00041801
*            (1) ASSIGNMENTS OR POSSIBLE ASSIGNMENTS TO REAL,FIXED      00041901
*                BINARY SCALAR INTEGER VARIABLES.                       00042001
*            (2) GO TO STATEMENTS WHERE THE LABEL IS OUTSIDE THE        00042101
*                ON_UNIT.                                               00042201
*        THE RESULT OF SCANNING THE ON_UNITS IS IN THE FORM OF TWO      00042301
*        MASKS - ATNVONUS AND GTLVONUS.                                 00042401
*        THESE MASKS CONSIST OF 20 BITS EACH CORRESPONDING TO A TYPE    00042501
*        OF ON_UNIT. IF A SIZE ON_UNIT IS FOUND WITH AN ASSIGNMENT      00042601
*        TO A 'NICE' VARIABLE IN IT, SAY, THEN THE 4TH BIT IN           00042701
*        ATNVONUS IS SET TO ONE AND SO ON                               00042801
*        HOWEVER, SINCE AN INTERRUPT IN AN ON_UNIT COULD CAUSE ENTRY    00042901
*        TO ANOTHER ON_UNIT WHICH MAY HAVE AN ASSIGNMENT TO A 'NICE'    00043001
*        VARIABLE ALL INTERRUPTS WHICH COULD OCCUR IN EACH OF THE       00043101
*        ON_UNITS MUST BE TAKEN INTO ACCOUNT.                           00043201
*        THIS IS ACHIEVED BY CONSTRUCTING A 20*20 BIT ARRAY CALLED      00043301
*        MATRIX AND OPERATING ON THIS MATRIX BY ROUTINES KGMTRX         00043401
*        AND KGMASK. AFTER THIS PROCESSING THE MASKS GIVE A TRUE        00043501
*        PICTURE OF THE WORST CASE THAT COULD POSSIBLY HAPPEN.          00043601
*                                                                       00043701
*        THESE MASKS ARE USED IN THE MAIN TEXT SCAN TO DECIDE ON        00043801
*        BOUNDARIES FOR ENTRY IN THE SUBS/REGION LIST.                  00043901
*                                                                       00044001
*        THE MAIN TEXT IS SCANNED IN DO MAP SEQUENCE. THAT IS USING     00044101
*        THE FIELD XLCRFMAP TO CHAIN TO THE FIRST DO MAP ENTRY AND      00044201
*        THEN XMAPSEQU IN EACH ENTRY THEREAFTER UNTIL THE END OF        00044301
*        CHAIN IS FOUND WHEN THE 1ST BYTE OF XMAPSEQU IS X'FF'.         00044401
*                                                                       00044501
*        THE START OF THE  TEXT CORRESPONDING TO EACH DO MAP ENTRY      00044601
*        IS CHAINED TO USING THE FIELD XMAPITDO WHICH IS THE TEXT       00044701
*        REFERENCE OF THE PROC OR ITDO TRIPLE.                          00044801
*                                                                       00044901
*        THE PURPOSE OF THIS TEXT SCAN IS TO BUILD UP TWO SEPARATE      00045001
*        LISTS, THE USE LIST AND SUBS/REGION LIST WHICH ARE CHAINED     00045101
*        OFF THE FIELDS XMAPUSEL AND XMAPSRGL RESPECTIVELY.             00045201
*        THE 1ST BYTE OF XMAPUSEL IS X'FF' IF THERE IS NO USE LIST,     00045301
*        OTHERWISE IT CONTAINS THE TEXT REFERENCE OF THE START OF       00045401
*        THE USE LIST. THE FIELD XMAPSRGL IS NEVER NULL EVEN IF         00045501
*        THERE IS ONLY AN END OF LIST MARKER IN THE SUBS/REGION LIST.   00045601
*                                                                       00045701
*   USE LIST.                                                           00045801
*                                                                       00045901
*        THIS IS A LIST OF DICTIONARY REFERENCES OF REAL,FIXED BINARY   00046001
*        SCALAR INTEGERS WHICH HAVE BEEN FOUND TO BE EITHER ASSIGNED    00046101
*        TO IN THE LOOP OR INVARIANT OVER THE LOOP AND FOUND WITHIN     00046201
*        A SUBCRIPT LIST. THE ENTRIES CONSIST OF A CODE BYTE            00046301
*        FOLLOWED BY THE TWO BYTE DICTIONARY REFERENCE. THREE BITS      00046401
*        ARE USED IN THE CODE BYTE TO INDICATE THAT THE VARIABLE        00046501
*        IS (1) ASSIGNED TO/INVARIANT                                   00046601
*           (2) SAFE/UNSAFE                                             00046701
*           (3) COMPILER CREATED TEMPORARY/USER VARIABLE                00046801
*                                                                       00046901
*   SUBS/REGION LIST.                                                   00047001
*                                                                       00047101
*        THIS IS A LIST OF POINTERS TO THE TEXT OF THE LOOP INDICATING  00047201
*        THE POSITIONS OF SUBSCRIPT LISTS AND REGION BOUNDARIES SUCH    00047301
*        AS PROCEDURE CALLS OR BRANCH IN POINTS WHICH PREVENT           00047401
*        SUBSCRIPT COMMONING.                                           00047501
*        THERE ARE FOUR TYPES OF ENTRY,ALL 6 BYTES IN LENGTH. THE 1ST   00047601
*        BYTE IS A CODE BYTE INDICATING THE TYPE OF ENTRY. THEN         00047701
*        FOLLOWS A 3_BYTE TEXT REFERENCE TO THE POINT IN TEXT AND       00047801
*        AN OPTIONAL 2_BYTE DICTIONARY REFERENCE.                       00047901
*           (1) SUBS ENTRY. THIS CONTAINS THE TEXT REFERENCE OF A       00048001
*               SUBS TRIPLE WHICH IS NOT NESTED, CONTAINS NO FUNCTION   00048101
*               REFERENCES AND REFERS TO AN ARRAY WHICH IS OF DATA      00048201
*               TYPE.                                                   00048301
*           (2) GLOBAL ENTRY. THIS CONTAINS THE TEXT REFERENCE OF A     00048401
*               TRIPLE WHICH IS CONSIDERED TO BE A GLOBAL REGION        00048501
*               BOUNDARY E.G.STATEMENT LABEL,CLN1,CALL TO A NON BUILT   00048601
*               IN FUNCTION ETC. I.E A POINT IN THE PROGRAM WHERE NO    00048701
*               VALUES CAN    BE HELD IN REGISTERS SINCE THE FLOW       00048801
*               OF CONTROL IS UNCERTAIN.                                00048901
*           (3) PARTIAL SAFE ENTRY. THIS INDICATES A POINT WHERE THE    00049001
*               VALUE OF A SINGLE REAL  FIXED BIN SCALAR INTEGER SAFE   00049101
*               VARIABLE IS CHANGED. THE DICTIONARY REFERENCE IS        00049201
*               INCLUDED IN THIS CASE.                                  00049301
*           (4) PARTIAL UNSAFE ENTRY. THIS INDICATES A POINT WHERE      00049401
*               THE VALUE OF AN UNSAFE VBLE IS CHANGE OR POSSIBLY       00049501
*               CHANGED.                                                00049601
*                                                                       00049701
*                                                                       00049801
*        TEXT IS SCANNED USING THE IEMKTAB MACRO AND THE MAIN SCANNING  00049901
*        ROUTINE KGSCAN TRANSFERS CONTROL TO THE APPROPRIATE TRIPLE     00050001
*        ROUTINES.                                                      00050101
*                                                                       00050201
*        EACH TRIPLE IS CONSIDERED AS A POSSIBLE CAUSE OF ENTRY TO      00050301
*        AN ON_UNIT CONTAINING AN ASSIGNMENT TO A 'NICE' VARIABLE.      00050401
*        THIS IS PERFORMED IN ROUTINE KGOTST WHICH 'ANDS' TOGETHER      00050501
*        THE TRIPLE MASK, PREFIX OPTIONS MASK AND ON_UNIT MASKS.        00050601
*        THE INDEX OBTAINED FROM THE TRANSLATE TABLE TO BRANCH TO THE   00050701
*        APPROPRIATE TRIPLE ROUTINE IS ALSO USED TO ACCESS THE          00050801
*        APPROPRIATE TRIPLE MASK. WORST CASE ASSUMPTIONS ARE MADE       00050901
*        IN CONSTRUCTING THE TRIPLE MASKS. E.G. THE PLUS TRIPLE IS      00051001
*        ASSUMED TO RAISE CONDITIONS   OVERFLOW,UNDERFLOW,ZERODIVIDE,   00051101
*        FIXEDOVERFLOW AND CONVERSION.                                  00051201
*                                                                       00051301
*        WHEN AN ASSIGNMENT TYPE OF TRIPLE IS FOUND THE VARIABLE        00051401
*        CONCERNED IS CONSIDERED FOR ENTRY INTO THE USE LIST AS         00051501
*        'ASSIGNED TO'. THE VARIABLE MAY ALREADY BE IN THE USE LIST     00051601
*        AS AN INVARIANT IN WHICH CASE THE 'ASSIGNED TO' BIT IS         00051701
*        SIMPLY SET ON. IF A TRIPLE IS FOUND WITHIN A SUBSCRIPT LIST    00051801
*        THEN ITS OPERANDS ARE CONSIDERED FOR ENTRY INTO THE USE        00051901
*        LIST AS INVARIANT.                                             00052001
*                                                                       00052101
*        THREE STACKS ARE MAINTAINED IN SCRATCH CORE                    00052201
*                                                                       00052301
*   USE STACK                                                           00052401
*                                                                       00052501
*                                                                       00052601
*                                                                       00052701
*        SINCE VARIABLES WHICH ARE ASSIGNED TO WITHIN A LOOP ARE        00052801
*        ALSO ASSIGNED IN THE CONTAINING LOOP, ALL ASSIGNED_TO VBLES    00052901
*        IN THE USE LIST MUST BE 'COLLAPSED' ONTO THE USE LIST OF       00053001
*        THE CONTAINING LOOP. THIS IS ACHIEVED BY MEANS OF THE USE      00053101
*        STACK. BEFORE THE LOOP SCAN COMMENCES IF THERE ARE ANY         00053201
*        ENTRIES IN THE USE STACK THEN THESE ARE COPIED ONTO THE        00053301
*        CURRENT USE LIST. THEN AT THE END THE LOOP THE 'ASSIGNED TO'   00053401
*        VBLES ARE COPIED ONTO THE USE STACK TOGETHER WITH THE LEVEL    00053501
*        NUMBER OF THE LOOP.                                            00053601
*                                                                       00053701
*   ITDO'/PROC' STACK.                                                  00053801
*                                                                       00053901
*        THIS STACK IS MAINTAINED TO SPEED UP SKIPPING ROUND            00054001
*        CONTAINED PROC'S OR ITDO'S SO THAT EVERY TIME AN ITDO OR       00054101
*        PROC TRIPLE IS ENCOUNTERED WHILE SCANNING A LOOP, THE TOP      00054201
*        STACK ELEMENT CONTAINS THE TEXT REFERENCE OF THE               00054301
*        CORRESPONDING ITDO' OR PROC' TRIPLE AND SCANNING CAN           00054401
*        RECOMMENCE THERE.                                              00054501
*                                                                       00054601
*  FNCM STACK                                                           00054701
*                                                                       00054801
*        IF A FUNCTION INVOCATION IS FOUND THEN IT IS ASSUMED THAT      00054901
*        ALL ARGUMENTS ARE ASSIGNED TO AT THE FNC' TRIPLE. BUT SINCE    00055001
*        THE FUNCTION MAY BE BUILTIN OR A SPECIAL CASE LIKE SUBSTR      00055101
*        WHERE ONLY THE 1ST ARGUMENT IS ASSIGNED TO OR THE FUNCTIONS    00055201
*        MAY BE NESTED,THE STACK WILL ENSURE THAT THE BOUNDARIES        00055301
*        COME IN THE CORRECT LOGICAL ORDER.                             00055401
*                                                                       00055501
*                                                                       00055601
*        WHEN THE END OF THE DO_MAP SEQUENCE CHAIN IS REACHED ALL       00055701
*        TABLES ARE DEACTIVATED AND CONTROL IS PASSED TO THE NEXT       00055801
*        PHASE.                                                         00055901
*                                                                       00056001
         SPACE 3                                                        00056101
*                                                                       00056201
* ENTRY POINT - 'KGMAIN' FROM COMPILER CONTROL                          00056301
         SPACE 3                                                        00056401
* INPUTS -    (1) DO MAP IN ONE OR MORE TEXT BLOCKS CHAINED BY FIELD    00056501
*                 'XMAPSEQU'. THE FIRST ENTRY IS CHAINED TO XLCRFMAP    00056601
*                 IN PHASE KA.                                          00056701
*                                                                       00056801
*             (2) TEXT IN FORM OF TRIPLES WHICH IS ACCESSED VIA FIELD   00056901
*                 'XMAPITDO' WHICH CONTAINS THE TEXT REF OF THE ITDO    00057001
*                 OR PROC TRIPLE CORRESPONDING TO THE DO MAP ENTRY      00057101
*                                                                       00057201
*             (3) ENTRIES IN THE SUBS/REGION LIST GIVING THE TEXT       00057301
*                 REFERENCES OF THE SNAP OR NOSNAP TRIPLES              00057401
*                 CORRESPONDING TO EACH ON-UNIT.                        00057501
         SPACE 3                                                        00057601
* OUTPUTS  - 'USE' AND 'SUBS/REGION' LISTS ARE CHAINED OFF EACH DO-MAP  00057701
*            ENTRY AND VARIOUS FLAGS ARE SET IN EACH ENTRY.             00057801
*            TEXT IS NOT MODIFIED.                                      00057901
         SPACE 3                                                        00058001
* EXTERNAL                                                              00058101
* ROUTINES -  (1) CONTROL PHASE.  THE FOLLOWING ENTRIES ARE USED        00058201
*                 -'ZDRFAB','ZUERR'                                     00058301
*                                                                       00058401
*             (2) TABLE HANDLING(IEMKA). THE FOLLOWING ENTRIES ARE      00058501
*                 USED - 'KAHBLD','KAHDAC','KAHERR','KAHFRE','KAHMDR',  00058601
*                 'KAHSCN','KAHSET','KAHTXT'.                           00058701
         SPACE 3                                                        00058801
* EXIT - NORMAL - 'RLSCTL' IN CONTROL PHASE TO RELEASE PHASE AND LOAD   00058901
*                 NEXT                                                  00059001
*                                                                       00059101
*        ERROR -  'KAHERR' IF AN ERROR OCCURS WHILE HANDLING TABLES     00059201
*                 OR TEXT. TERMINAL MESSAGE IEM1224I IS GIVEN.          00059301
*                                                                       00059401
*        ERROR -  'ZABORT' IN CONTROL PHASE IN SOME CASE WHERE AN       00059501
*                 ERROR IS DETECTED BY THIS PHASE. TERMINAL MESSAGE     00059601
*                 IEM1226I IS GIVEN                                     00059701
         SPACE 3                                                        00059801
* WORKAREA - 3K OF THE SCRATCH AREA OBTAINED BY IEMKA IS USED           00059901
*               IK IS FOR THE 'USE' STACK                               00060001
*               IK IS FOR THE 'ITDO'/PROC'' STACK                       00060101
*               200 BYTES IS FOR THE FUNCTION COMA STACK                00060201
         SPACE 3                                                        00060301
* ATTRIBUTES - THIS BLOCK IS NOT READ-ONLY AND NOT REENTRANT.           00060401
         SPACE 3                                                        00060501
* NOTES -     (1) THIS PHASE REQUIRES NO MODIFICATION AS A RESULT OF    00060601
*                 CHANGES IN THE INTERNAL REPRESENTATION OF EXTERNAL    00060701
*                 GRAPHICS                                              00060801
*                                                                       00060901
*             (2) THIS PHASE USES THE 'IEMK' MACROS FOR ASSEMBLY.       00061001
*                                                                       00061101
*             (3) THIS PHASE CONSISTS OF 2 CONTROL SECTIONS IEMKG AND   00061201
*                 IEMKG1.                                               00061301
         EJECT                                                          00061401
         COPY  IEMKCOM                                                  00080001
         COPY  IEMKUTL                                                  00120001
         COPY  IEMKEQU                                                  00160001
         COPY  IEMKDRF                                                  00200001
*                                                                       00240001
** THE XIPS DSECT DESCRIBES AN ENTRY IN THE ITDO'/PROC' STACK           00280001
*                                                                       00320001
XIPS     DSECT                                                          00360001
*                                                                       00400001
XIPSLEVL DS    X                       SUM OF ITDO AND PROC NEST LEVEL  00440001
*                                                                       00480001
XIPSTEXT DS    XL3                     TEXT REF OF ITDO' OR PROC'       00520001
*                                                                       00560001
XIPSEND  EQU   *                       END OF ENTRY                     00600001
         EJECT                                                          00640001
         COPY  IEMKLCR                                                  00680001
         COPY  IEMKMAP                                                  00720001
         COPY  IEMKSRG                                                  00760001
         COPY  IEMKTRP                                                  00800001
         COPY  IEMKUSE                                                  00840001
*                                                                       00880001
** THE XUST DSECT DESCRIBES AN ENTRY IN THE USE STACK                   00920001
*                                                                       00960001
XUST     DSECT                                                          01000001
*                                                                       01040001
XUSTLEVL DS    X                       ITDO LEVEL OF STACK ENTRY        01080001
*                                                                       01120001
XUSTCODE DS    X                       CODE BYTE                        01160001
*                                                                       01200001
XUSTDREF DS    CL2                     DICT REF OF VARIABLE             01240001
*                                                                       01280001
XUSTEND  EQU   *                       END OF ENTRY                     01320001
         EJECT                                                          01360001
*                                                                       01400001
** EQUATES USED BY THIS PHASE ONLY.                                     01440001
*                                                                       01480001
TR       EQU   2                       TRANSLATED TRIPLE CODE           01520001
IPSR     EQU   2                       ITDO'/PROC' STACK ENTRY          01560001
IP       EQU   3                       INPUT POINTER                    01600001
TRPR     EQU   IP                      TRIPLE BASE                      01640001
USTR     EQU   4                       USE STACK ENTRY                  01680001
DRFR     EQU   5                       DICTIONARY ENTRY                 01720001
USER     EQU   6                       USE LIST ENTRY                   01760001
MAPR     EQU   7                       DO MAP ENTRY                     01800001
SRGR     EQU   7                       SUBS/REGION LIST ENTRY           01840001
*                                                                       01880001
NULL     EQU   X'FF'                   NULL TEXT REFERENCE              01920001
NBIFLAG  EQU   X'80'                   FUNCTION IS NOT BUILT-IN         01960001
EXTFLAG  EQU   X'40'                   FUNCTION IS EXTERNAL             02000001
*                                                                       02040001
         EJECT                                                          02080001
IEMKG    CSECT                                                          02120001
         USING XDRF,DRFR               DICTIONARY REFERENCE             02160001
         USING XMAP,MAPR               DO MAP ENTRY                     02200001
         USING XUSE,USER               USE LIST                         02240001
         USING XUST,USTR               USE STACK                        02280001
         USING XTRP,TRPR               TRIPLE                           02320001
         USING XIPS,IPSR               ITDO'/PROC' STACK                02360001
NAME     DC    C'KG'                   PHASE NAME                       02400001
         IEMKPLR KG,KGMAIN,DL=KGZZ,LL=0                                 02440001
KGMAIN   IEMKENT TYPE=2                                                 02480001
         USING IEMKG1,GR8                                               02540001
*                                                                       02600001
         L     GR8,=A(IEMKG1)          BASE 2ND CSECT                   02660001
*                                                                       02720001
* PERFORM INITIAL TEXT SCAN TO ANALYSE ON-UNITS                         02760001
*                                                                       02800001
         BAL   RR,KGONSC               CALL ROUTINE TO SCAN ON-UNITS    02840001
*                                                                       02880001
* INITIALISE USE STACK                                                  02920001
*                                                                       02960001
         L     USTR,XLCRASCR           INITIALISE USE STACK POINTER     03000001
         MVI   XUSTLEVL,0              PUT DUMMY AS FIRST ENTRY         03040001
*                                                                       03080001
* INITIALISE ITDO'/PROC' STACK - THIS STACK IS MAINTAINED TO SPEED UP   03120001
* SKIPPING ROUND CONTAINED LOOPS.                                       03160001
*                                                                       03200001
         LR    GR2,USTR                BASE XIPS                        03240001
         AH    GR2,=H'1024'            USE STACK IS 1K                  03280001
         ST    GR2,USTKEND             END OF USE STACK ADDRESS         03320001
         ST    GR2,CURRSTK             CURRENT ITDO'/PROC' STACK PTR.   03360001
         MVI   XIPSLEVL,0              DUMMY 1ST ENTRY                  03400001
*                                                                       03440001
* INITIALISE FUNCTION COMA STACK. THIS STACK IS MAINTAINED SO THAT      03480001
* FUNCTION ARGUMENTS ARE MARKED AS BEING ASSIGNED TO AT THE             03520001
* CORRESPONDING FNC' TRIPLE.                                            03560001
*                                                                       03600001
         AH    GR2,=H'1024'            ITDO'/PROC' STACK IS       35253 03620021
         LA    GR2,384(GR2)            1408 BYTES LONG.           35253 03640021
         ST    GR2,FNSTK               STORE ADDRESS OF START OF        03680001
*                                      FUNCTION COMA STACK              03720001
         LA    GR2,200(GR2)            STACK HAS A LIMIT OF 100 ENTRIES 03760001
         ST    GR2,FNSTKEND            STORE END OF STACK ADDRESS       03800001
         LA    MAPR,DMAPBUFF                                            03840001
         EJECT                                                          03880001
         MVC   XMAPSEQU(3),XLCRFMAP    FIRST DO MAP ENTRY               03920001
*                                                                       03960001
* THIS IS THE START OF THE MAIN ROUTINE                                 04000001
*                                                                       04040001
MAIN100  CLI   XMAPSEQU,NULL                                            04080001
         BE    MAINEND                 EXIT FROM PHASE IF THE LAST DO   04120001
         MVC   CURRDO(3),XMAPSEQU      MAP ENTRY HAS BEEN PROCESSED     04160001
       IEMKTAB DR,XLCRMAP,SA=XMAPSEQU,AATO=(MAPR) BRING IN NEXT ENTRY   04200001
         MVC   DMAPBUFF(XMAPEND-XMAP),0(MAPR) COPY INTO BUFFER          04240001
*                                                                       04280001
* RESET FLAGS AND COUNTS AND CHAINS OFF DO MAP ENTRY                    04320001
*                                                                       04360001
         LA    MAPR,DMAPBUFF           BASE XMAP                        04400001
         MVI   KGCOD1,0                RESET FLAGS                      04440001
         MVC   PRFOPT(1),XMAPPREF      COPY OPTIONS RULING AT ITDO      04480001
         MVI   CURRSUB,NULL            PUT NULL IN CURRSUB              04520001
         XC    SUBCOUNT(2),SUBCOUNT    ZERO SUBCOUNT                    04560001
         XC    FNCOUNT(2),FNCOUNT      ZERO FNCOUNT                     04600001
         MVI   PREVCODE,0              CLEAR PREVCODE                   04640001
         XC    LOOPONUS(4),LOOPONUS    CLEAR MASK OF INTERRUPTS WHICH   04648001
*                                      CAN OCCUR OVER THE LOOP          04656001
         XC    LABCONUS(4),LABCONUS    CLEAR MASK OF INTERRUPTS WHICH   04664001
*                                      HAVE BRANCHES TO LABELS IN LOOP  04672001
*                                                                       04680001
* TEST WHETHER LOAD AND STORE OF CV REQUIRED                            04720001
*                                                                       04760001
         XC    CVCOUNT(2),CVCOUNT      CLEAR COUNT OF OCCURRENCES OF    04800001
*                                      CV WITHIN SUBS LISTS             04840001
         CLI   XMAPLEVL,0                                               04880001
         BE    MAIN102                 BRANCH IF PROC ENTRY             04920001
         TM    XMAPTYPE,XMAPNTIN                                        04960001
         BO    MAIN102                 BRANCH IF NOT INNERMOST LOOP     05000001
         TM    XMAPSPEC,XMAPBDCV                                        05040001
         BO    MAIN102                 BRANCH IF CV NOT A REAL FIXED    05080001
*                                      BINARY SCALAR INTEGER            05120001
         MVC   PAR1+2(2),XMAPCVDR                                       05160001
         L     LR,ZDRFAB               ACCESS DICT ENTRY OF CV          05200001
         BALR  RR,LR                                                    05240001
         L     DRFR,PAR1               BASE XDRF                        05280001
         TM    XDRFOTH3,XDRFUNSF       TEST UNSAFE BIT                  05320001
         BO    MAIN102                 BRANCH IF CV IS UNSAFE           05360001
         OI    XMAPSPEC,XMAPNOLD       NO LOAD OF CV REQUIRED(YET)      05400001
         TM    XDRFCODE,XDRFSTRM                                        05440001
         BO    MAIN102                 BRANCH IF CV IS STRUCTURE MEMBER 05480001
         OI    XMAPSPEC,XMAPNOST       NO STORE OF CV REQUIRED(YET)     05520001
         OI    XMAPSPEC,XMAPNOST+XMAPNOLD STORE AND LOAD OF CV NOT      05560001
*                                      REQUIRED(YET)                    05600001
*                                                                       05640001
* SET CURRSTK TO POINT AT FIRST ENTRY CORRESPONDING TO THIS LOOP.       05680001
*                                                                       05720001
MAIN102  L     IPSR,CURRSTK            POINT AT CURRENT ENTRY IN ITDO'/ 05760001
*                                      PROC' STACK                      05800001
MAIN104  CLC   XMAPTLVL(1),XIPSLEVL                                     05840001
         BNL   MAIN107                 BRANCH IF CURRENT NESTING        05880001
*                                      LEVEL >= STACK LEVEL             05920001
         SH    IPSR,=AL2(XIPSEND-XIPS) DECREMENT STACK POINTER          05960001
         B     MAIN104                                                  06000001
MAIN107  ST    IPSR,CURRSTK                                             06040001
*                                                                       06080001
* DETERMINE WHETHER A USE LIST IS TO BE CONSTRUCTED FOR THIS DO MAP     06120001
* ENTRY AND IF SO, WHETHER UNSAFE VARIABLES ARE GOING TO BE ALLOWED.    06160001
*                                                                       06200001
         CLI   XMAPLEVL,0                                               06240001
         BE    MAIN115                 BRANCH IF ENTRY IS FOR A PROC    06280001
         TM    XMAPLOOP,XMAPNUSL                                        06320001
         BO    MAIN115                 BRANCH IF NO USE LIST TO BE      06360001
*                                      CONSTRUCTED                      06400001
*                                                                       06440001
         OI    KGCOD1,USEFLAG          USE LIST IS TO BE CONSTRUCTED    06480001
*                                                                       06520001
*                                                                       06560001
* THERE MAY BE ENTRIES IN THE USE STACK WHICH ARE VARIABLES WHICH HAVE  06600001
* BEEN ASSIGNED TO WITHIN INNER LOOPS AND HAVE THEREFORE BEEN           06640001
* ASSIGNED TO WITHIN THE CURRENT LOOP AND THEREFORE MUST BE INCLUDED    06680001
* IN ITS USE LIST. A COMPARISON IS MADE BETWEEN THE LEVEL IN THE USE    06720001
* STACK ENTRY AND THE LEVEL OF THE CURRENT DO MAP ENTRY TO DECIDE       06760001
* WHETHER OR NOT TO UNSTACK THE ENTRY.                                  06800001
*                                                                       06840001
MAIN110  CLC   XMAPLEVL(1),XUSTLEVL                                     06880001
         BNL   MAIN115                 BRANCH IF LEVEL OF DO MAP ENTRY  06920001
*                                      IS NOT LESS THAN LEVEL OF ENTRY  06960001
*                                      IN USE STACK                     07000001
*                                                                       07040001
* UNSTACK ENTRY IN USE STACK ONTO USE LIST OF CURRENT DO LOOP.          07080001
*                                                                       07120001
         TM    XUSTCODE,XUSECTMP                                        07160001
         BO    MAIN113                 BRANCH IF COMPILER-CREATED TEMP  07200001
         TM    XMAPLOOP,XMAPOCTS                                        07240001
         BO    MAIN114                 BRANCH IF ONLY COMPILER-CREATED  07280001
*                                      TEMPS ARE ALLOWED IN USE LIST    07320001
MAIN113  MVC   USELBUFF(XUSEEND-XUSE),XUSTCODE UNSTACK USE LIST ENTRY   07360001
*                                      INTO BUFFER                      07400001
         BAL   RR,KGUSEN               MAKE ENTRY IN THE USE LIST       07440001
MAIN114  SH    USTR,=AL2(XUSTEND-XUST) DECREMENT STACK POINTER          07480001
         B     MAIN110                                                  07520001
*                                                                       07560001
* CHAIN TO PROC OR ITDO TRIPLE CORRESPONDING TO CURRENT DO MAP ENTRY.   07600001
*                                                                       07640001
MAIN115  DS    0H                                                       07680001
       IEMKTAB SET,XLCRTXT,SA=XMAPITDO                                  07720001
         CLI   XTRPCODE,XTRPPROC                                        07726001
         BNE   MAIN117                 BRANCH IF NOT PROC               07732001
         MVC   PAR1+2(2),XTRPOP2       ACCESS DICT ENTRY                07738001
         L     LR,ZDRFAB                   OF ENTRY TYPE 1              07744001
         BALR  RR,LR                                                    07750001
         L     DRFR,PAR1               BASE XDRF                        07756001
         OI    XMAPOPTN,XMAPORDR       SET OPTION TO ORDER              07762001
         TM    XDRF+63,X'04'                                            07768001
         BZ    MAIN117                 BRANCH IF ORDER ON THIS BLOCK    07774001
         NI    XMAPOPTN,X'FF'-XMAPORDR SET OPTION TO ORDER              07780001
MAIN117  IEMKTAB SCAN,XLCRTXT          SKIP TO NEXT TRIPLE              07786001
*                                                                       07800001
* BRANCH TO MAIN SCANNING ROUTINE IF ENTRY IS FOR A PROC                07840001
*                                                                       07880001
         CLI   XMAPLEVL,0                                               07920001
         BE    MAIN140                 BRANCH IF PROC ENTRY             07960001
MAIN120  DS    0H                                                       08000001
       IEMKTAB SCAN,XLCRTXT,AATO=(IP),ETA=KGERRR INSPECT NEXT TRIPLE    08040001
         CLI   XTRPCODE,XTRPCV                                          08080001
         BE    MAIN130                 BRANCH IF CV TRIPLE              08120001
         CLI   XTRPCODE,XTRPNOP                                         08160001
         BE    MAIN120                                                  08200001
*                                                                       08240001
* SINCE CV IS EITHER A PSEUDO-VARIABLE OR SUBSCRIPTED, VERY LITTLE      08280001
* OPTIMISATION CAN TAKE PLACE SO ASSUME LOOP CONTAINS A CALL TO A NON   08320001
* BUILTIN FUNCTION.                                                     08360001
*                                                                       08400001
         BAL   RR,KGDELT               DELETE USE LIST                  08440001
*                                                                       08480001
* SCAN FOR CV TRIPLE(CORRESPONDING TO THIS LOOP).                       08520001
*                                                                       08560001
         CLI   XTRPCODE,XTRPITDO                                        08600001
         BNE   MAIN120                 BRANCH IF NOT ITDO               08640001
         BAL   RR,KGITPR               BRANCH ROUND CONTAINED LOOP      08680001
         B     MAIN120                                                  08720001
*                                                                       08760001
* HAVE REACHED CV FOR THIS LOOP.                                        08800001
* IF EITHER AN ITDO OR FNC'(NON BUILTIN) TRIPLE IS FOUND THEN THE       08840001
* LOOP IS ASSUMED TO CONTAIN A CALL TO A NON BUILTIN FUNCTION           08880001
*                                                                       08920001
MAIN130  DS    0H                                                       08960001
       IEMKTAB SCAN,XLCRTXT,AATO=(IP),ETA=KGERRR                        09000001
         CLI   XTRPCODE,XTRPCVP                                         09040001
         BE    MAIN140                 BRANCH WHEN CV' IS REACHED       09080001
         CLI   XTRPCODE,XTRPITDO                                        09120001
         BNE   MAIN135                 BRANCH IF NOT ITDO               09160001
         OI    XMAPLOOP,XMAPOCTS       ASSUME NON BUILTIN FUNCTION CALL 09200001
         BAL   RR,KGITPR               SKIP ROUND CONTAINED LOOP        09240001
         B     MAIN130                                                  09280001
MAIN135  CLI   XTRPCODE,XTRPFNCP                                        09320001
         BNE   MAIN130                 BRANCH IF NOT FNC' TRIPLE        09360001
         TM    XTRPOP2,NBIFLAG                                          09400001
         BNO   MAIN130                 BRANCH IF NOT BUILTIN            09440001
         OI    XMAPLOOP,XMAPOCTS       ONLY COMPILER TEMPS IN USE LIST  09480001
         B     MAIN130                                                  09520001
*                                                                       09560001
* NOW CALL MAIN SCAN ROUTINE TO PROCESS TRIPLES OF INTEREST. CONTROL    09600001
* WILL BE RETURNED WHEN CORRESPONDING PROC' OR ITDO' IS REACHED.        09640001
*                                                                       09680001
MAIN140  BAL   RR,KGSCAN                                                09720001
*                                                                       09760001
* PUT A TERMINATING ENTRY IN THE SUBS/REGION LIST                       09800001
*                                                                       09840001
         MVI   SRGLCODE,XSRGLEND       END OF LIST                      09880001
         BAL   RR,KGSRGL               MAKE ENTRY                       09920001
*                                                                       09924001
* IF THIS IS AN INNERMOST LOOP THEN CALL KGINLP TO DECIDE WHETHER       09928001
* SYNDX REGISTERS CAN BE USED.                                          09932001
*                                                                       09936001
         CLI   XMAPLEVL,0                                               09940001
         BE    MAIN141                 BRANCH IF PROC                   09944001
         TM    XMAPTYPE,XMAPNTIN                                        09948001
         BO    MAIN141                 BRANCH IF NOT INNERMOST LOOP     09952001
         BAL   RR,KGINLP               PROCESS INNERMOST LOOP           09956001
*                                                                       09960001
* MOVE TEXT REF OF ITDO' OR PROC' INTO ITDO'/PROC' STACK TOGETHER WITH  10000001
* LEVEL OF NESTING.                                                     10040001
*                                                                       10080001
MAIN141  L     IPSR,CURRSTK            POINT AT CURRENT ENTRY           10120001
MAIN142  CLC   XMAPTLVL(1),XIPSLEVL                                     10160001
         BNL   MAIN143                 BRANCH IF CURRENT NESTING LEVEL  10200001
*                                      >= STACK LEVEL                   10240001
         SH    IPSR,=AL2(XIPSEND-XIPS) DECREMENT STACK POINTER          10280001
         B     MAIN142                                                  10320001
MAIN143  LA    IPSR,XIPSEND-XIPS(IPSR) UPDATE STACK POINTER             10360001
         MVC   XIPSLEVL(1),XMAPTLVL    MOVE IN LEVEL                    10400001
         MVC   XIPSTEXT(3),XMAPITDP    MOVE IN TEXT REF OF ITDO' OR     10440001
*                                      PROC' TRIPLE                     10480001
         ST    IPSR,CURRSTK            RESTORE STACK POINTER            10520001
*                                                                       10560001
* REWRITE PARTS OF CURRENT DO WHICH MAY HAVE BEEN ALTERED               10600001
*                                                                       10640001
       IEMKTAB DR,XLCRMAP,SA=CURRDO,AATO=(MAPR)                         10680001
         MVC   XMAPUSEL(3),DMAPBUFF+XMAPUSEL-XMAP                       10720001
         MVC   XMAPSRGL(3),DMAPBUFF+XMAPSRGL-XMAP                       10760001
         NI    DMAPBUFF+XMAPLOOP-XMAP,X'FF'-XMAPGLST                    10800001
         OC    XMAPLOOP(1),DMAPBUFF+XMAPLOOP-XMAP                       10840001
         MVC   WORK(1),DMAPBUFF+XMAPSPEC-XMAP                     30372 10870020
         NI    WORK,XMAPNOST+XMAPNOLD                             30372 10900020
         OC    XMAPSPEC(1),WORK                                   30372 10930020
         MVC   XMAPCVCT(2),CVCOUNT                                      10960001
*                                                                       11000001
* IF THERE IS A USE LIST THEN SORT ENTRIES SO THAT THE INVARIANT        11040001
* VARIABLES APPEAR FIRST                                                11080001
*                                                                       11120001
         LA    MAPR,DMAPBUFF                                            11160001
         CLI   XMAPUSEL,NULL                                            11200001
         BE    MAIN150                 BRANCH IF NO USE LIST            11240001
         BAL   RR,KGSORT               SORT USE LIST                    11280001
*                                                                       11320001
* PUT TERMINATING ENTRY IN USE LIST                                     11360001
*                                                                       11400001
         MVC   USELBUFF(3),=X'FFFFFF'  END OF LIST MARKER               11440001
         BAL   RR,KGUSEN               MAKE ENTRY                       11480001
MAIN150  CLI   XMAPLEVL,2                                               11520001
         BL    MAIN100                 BRANCH IF DO MAP ENTRY IS FOR A  11560001
*                                      PROC OR 1ST LEVEL ITDO.          11600001
       IEMKTAB DR,XLCRMAP,SA=XMAPOUTR,AATO=(MAPR) ACCESS OUTER ENTRY    11640001
         MVC   WORK(1),DMAPBUFF+XMAPLOOP-XMAP                     30372 11670020
         NI    WORK,XMAPOCTS+XMAPATUV                             30372 11700020
         OC    XMAPLOOP(1),WORK                                   30372 11730020
*                                                                       11760001
* THE FLAGS XMAPAGRB AND XMAPATUV HAVE NOW BEEN CARRIED OVER TO THE     11800001
* OUTER LOOP.                                                           11840001
*                                                                       11880001
*                                                                       11920001
* IF THERE IS A USE LIST FOR THE CURRENT DO MAP ENTRY THEN COPY THE     11960001
* ASSIGNED TO VARIABLES ONTO THE USE STACK IF THEY ARE NOT ALREADY      12000001
* THERE AT SAME LEVEL.                                                  12040001
*                                                                       12080001
         LA    MAPR,DMAPBUFF                                            12120001
         CLI   XMAPUSEL,NULL                                            12160001
         BE    MAIN190                 BRANCH IF NO USE LIST            12200001
       IEMKTAB SET,XLCRUSE,SA=XMAPUSEL,PTR=1 SET USE LIST POINTER       12240001
*                                                                       12280001
* SCAN USE LIST FOR 'ASSIGNED TO' ENTRIES.                              12320001
*                                                                       12360001
MAIN160  DS    0H                                                       12400001
       IEMKTAB SCAN,XLCRUSE,AATO=(USER),PTR=1 SCAN USE LIST             12440001
         CLI   XUSECODE,XUSELEND                                        12480001
         BE    MAIN190                 BRANCH IF END OF LIST            12520001
         TM    XUSECODE,XUSEASSN                                        12560001
         BNO   MAIN160                 BRANCH IF NOT ASSIGNED TO        12600001
*                                                                       12640001
* HAVE FOUND AN ASSIGNED TO VARIABLE - CHECK THAT IT IS NOT ALREADY     12680001
* IN THE USE STACK AT THE SAME LEVEL.                                   12720001
*                                                                       12760001
         LR    GR1,USTR                                                 12800001
MAIN170  CLC   XMAPLEVL(1),XUSTLEVL-XUST(GR1)                           12840001
         BNE   MAIN180                 BRANCH IF LEVELS DIFFER          12880001
         CLC   XUSEDREF(2),XUSTDREF-XUST(GR1)                           12920001
         BE    MAIN160                 BRANCH IF VARIABLE ALREADY IN    12960001
*                                      STACK                            13000001
         SH    GR1,=AL2(XUSTEND-XUST)  DECREMENT STACK POINTER          13040001
         B     MAIN170                                                  13080001
*                                                                       13120001
* VARIABLE NOT IN STACK, SO AN ENTRY MUST BE MADE                       13160001
*                                                                       13200001
MAIN180  LA    USTR,XUSTEND-XUST(USTR) INCREMENT STACK POINTER          13240001
         C     USTR,USTKEND                                             13280001
         BL    MAIN185                 BRANCH IF STACK NOT FULL         13320001
       IEMKTAB DR,XLCRMAP,SA=XMAPOUTR,AATO=(MAPR) ACCESS OUTER ENTRY    13360001
         OI    XMAPLOOP,XMAPNUSL       NO USE LIST FOR CONTAINING LOOP  13400001
         LA    MAPR,DMAPBUFF           BASE XMAP AGAIN                  13440001
         L     USTR,XLCRASCR           RESET STACK POINTER              13480001
         B     MAIN100                                                  13520001
MAIN185  MVC   XUSTLEVL(1),XMAPLEVL    LEVEL                            13560001
         MVC   XUSTCODE(3),XUSE                                         13600001
         B     MAIN160                                                  13640001
*                                                                       13680001
* IF CONTROL VARIABLE IS 'NICE' AND IS NOT ALREADY IN THE USE STACK     13720001
* AT THE SAME LEVEL, THEN MAKE AN ENTRY FOR IT                          13760001
*                                                                       13800001
MAIN190  DS    0H                                                       13840001
       IEMKTAB DEACT,XLCRUSE           DEACTIVATE USE LIST              13880001
         TM    XMAPSPEC,XMAPBDCV                                        13920001
         BO    MAIN100                 BRANCH IF CV NOT NICE            13960001
         LR    GR1,USTR                                                 14000001
MAIN200  CLC   XMAPLEVL(1),XUSTLEVL-XUST(GR1)                           14040001
         BNE   MAIN210                 BRANCH IF LEVELS DIFFER          14080001
         CLC   XMAPCVDR(2),XUSTDREF-XUST(GR1)                           14120001
         BE    MAIN100                 BRANCH IF ALREADY IN STACK       14160001
         SH    GR1,=AL2(XUSTEND-XUST)  DECREMENT STACK POINTER          14200001
         B     MAIN200                                                  14240001
*                                                                       14280001
* CV NOT ALREADY IN STACK, AN ENTRY MUST BE MADE                        14320001
*                                                                       14360001
MAIN210  LA    USTR,XUSTEND-XUST(USTR) INCREMENT STACK POINTER          14400001
         C     USTR,USTKEND                                             14440001
         BL    MAIN215                 BRANCH IF STACK NOT FULL         14480001
       IEMKTAB DR,XLCRMAP,SA=XMAPOUTR,AATO=(MAPR) ACCESS OUTER ENTRY    14520001
         OI    XMAPLOOP,XMAPNUSL       NO USE LIST TO BE CONSTRUCTED    14560001
*                                      FOR CONTAINING LOOP              14600001
         LA    MAPR,DMAPBUFF           BASE XMAP AGAIN                  14640001
         L     USTR,XLCRASCR           RESET STACK POINTER              14680001
         B     MAIN100                                                  14720001
MAIN215  MVC   XUSTLEVL(1),XMAPLEVL    LEVEL                            14760001
         MVI   XUSTCODE,XUSEASSN       SET VARIABLE AS ASSIGNED TO      14800001
         TM    XMAPLOOP,XMAPAELP                                        14840001
         BNO   MAIN220                 BRANCH IF CV IS NOT A COMPILER-  14880001
*                                      CREATED TEMPORARY                14920001
         OI    XUSTCODE,XUSECTMP       SET COMPILER TEMP BIT            14960001
MAIN220  MVC   XUSTDREF(2),XMAPCVDR    DICT REF OF CV                   15000001
         B     MAIN100                 BRANCH TO PROCESS NEXT DO MAP    15040001
*                                      ENTRY                            15080001
*                                                                       15120001
* DEACTIVATE TABLES AND RETURN TO CALLING PHASE                         15160001
*                                                                       15200001
MAINEND  DS    0H                                                       15240001
       IEMKTAB DEACT,(XLCRUSE,XLCRTXT,XLCRSRG,XLCRMAP)                  15280001
         IEMKLVE  NORC                                                  15320001
         EJECT                                                          15360001
*                                                                       15400001
*** KGALOC ************************************************************ 15440001
*                                                                       15480001
* FUNCTION - TO PROCESS ALLOCATE,FREE,INTO,KEYTO AND SET TRIPLES. 54726 15520064
*                                                                       15560001
*********************************************************************** 15600001
*                                                                       15640001
KGALOC   IEMKENT  TYPE=2                                                15680001
         BAL   RR,KGRFCV               CHECK FOR REFERENCES TO THE CV   15720001
         CLI   XTRPCODE,XTRPSTRG                                        15760001
         BNE   ALOC090                 BRANCH IF NOT STRING TRIPLE      15800001
         TM    XMAPLOOP,XMAPGLST                                        15840001
         BO    ALOCEND                 RETURN IF STMT IS GET STRING     15880001
         B     ALOC100                                                  15920001
ALOC090  CLI   XTRPCODE,XTRPKEYT                                        15960001
         BNE   ALOC100                 BRANCH IF NOT KEYTO TRIPLE       16000001
         BAL   RR,KGOTST               CALL ROUTINE TO DETERMINE        16040001
*                                      WHETHER ON-UNITS COULD BE        16080001
*                                      ENTERED FROM THIS TRIPLE         16120001
ALOC100  CLI   XTRPCODE,XTRPALOC                                        16130001
         BNE   ALOC110                 BRANCH IF NOT ALLOCATE TRIPLE    16140001
         MVI   SRGLCODE,XSRGGLBL                                        16144001
         BAL   RR,KGSRGL               GLOBAL REGION BOUNDARY           16148001
         BAL   RR,KGDELT               DELETE USE LIST                  16152001
         NI    XMAPSPEC,XMAPSTLD       STORE AND LOAD OF CV REQUIRED    16156001
ALOC110  OI    KGCOD1,ASSFLAG          VBLE BEING ASSIGNED TO           16160001
         MVC   USELDREF(2),XTRPOP2                                      16200001
         BAL   RR,KGUSEL               MAKE ENTRY IN USE LIST           16240001
ALOCEND  IEMKLVE  NORC                                                  16280001
         EJECT                                                          16320001
*                                                                       16360001
*** KGASSI ************************************************************ 16400001
*                                                                       16440001
* FUNCTION - TO PROCESS ASSIGN,MTAS,MSA AND MTA TRIPLES.                16480001
*            AN ENTRY IS MADE IN THE USE LIST FOR THE 1ST OPERAND       16520001
*                                                                       16560001
*********************************************************************** 16600001
*                                                                       16640001
KGASSI   IEMKENT  TYPE=2                                                16680001
         BAL   RR,KGRFCV               CHECK FOR REFERENCES TO THE CV   16720001
         BAL   RR,KGOTST               CALL ROUTINE TO DETERMINE        16760001
*                                      WHETHER ON-UNITS COULD BE        16800001
*                                      ENTERED FROM THIS TRIPLE         16840001
         OI    KGCOD1,ASSFLAG          VARIABLE IS BEING ASSIGNED TO    16880001
         MVC   USELDREF(2),XTRPOP1                                      16920001
         BAL   RR,KGUSEL               MAKE ENTRY IN USE LIST           16960001
ASSIEND  IEMKLVE  NORC                                                  17000001
         EJECT                                                          17040001
*                                                                       17080001
*** KGBEGN ************************************************************ 17120001
*                                                                       17160001
* FUNCTION - TO PROCESS BEGIN,R TRIPLES                                 17200001
*                                                                       17240001
*********************************************************************** 17280001
*                                                                       17320001
KGBEGN   IEMKENT  TYPE=2                                                17360001
         OI    XMAPLOOP,XMAPPRBG       LOOP CONTAINS A BEGIN BLOCK      17400001
         MVI   SRGLCODE,XSRGGLBL                                        17440001
         BAL   RR,KGSRGL               MAKE A GLOBAL ENTRY IN SUBS/     17480001
*                                      REGION LIST                      17520001
         BAL   RR,KGDELT               DELETE USE LIST                  17560001
         CLI   XTRPCODE,XTRPBEGN                                        17563001
         BNE   BEGNEND                 RETURN IF REMOTE TRIPLE          17566001
         MVC   PAR1+2(2),XTRPOP2       ACCESS DICT ENTRY OF ENTRY       17569001
         L     LR,ZDRFAB               TYPE 1 IF BEGIN TRIPLE           17572001
         BALR  RR,LR                                                    17575001
         L     DRFR,PAR1               BASE XDRF                        17578001
         OI    XMAPOPTN,XMAPORDR       SET OPTION TO ORDER              17581001
         TM    XDRF+55,X'04'                                            17584001
         BZ    BEGNEND                 RETURN IF ORDER RULING FOR THIS  17587001
*                                      BEGIN BLOCK                      17590001
         NI    XMAPOPTN,X'FF'-XMAPORDR SET OPTION TO REORDER            17593001
BEGNEND  IEMKLVE  NORC                                                  17600001
         EJECT                                                          17640001
*                                                                       17680001
*** KGBGNP ************************************************************ 17720001
*                                                                       17760001
* FUNCTION - TO PROCESS THE BEGIN' TRIPLE                               17800001
*                                                                       17840001
*********************************************************************** 17880001
*                                                                       17920001
KGBGNP   IEMKENT  TYPE=2                                                17960001
         MVI   SRGLCODE,XSRGGLBL                                        18000001
         BAL   RR,KGSRGL               MAKE A GLOBAL ENTRY IN SUBS/     18040001
*                                      REGION LIST                      18080001
         MVC   PAR1+2(2),XTRPOP2       ACCESS DICT ENTRY OF ENTRY       18082001
         L     LR,ZDRFAB               TYPE 1 OF OUTER BLOCK            18084001
         BALR  RR,LR                                                    18086001
         L     DRFR,PAR1               BASE XDRF                        18088001
         OI    XMAPOPTN,XMAPORDR       SET OPTION TO ORDER              18090001
         CLI   XDRFCODE,X'80'                                           18092001
         BNE   BGNP100                 BRANCH IF CONTAINING BLOCK IS    18094001
*                                      A BEGIN                          18096001
         TM    XDRF+63,X'04'                                            18098001
         BZ    BGNPEND                 RETURN IF ORDER IS RULING OPTION 18100001
*                                      IN CONTAINING PROC               18102001
         B     BGNP110                 BRANCH IF REORDER                18104001
*                                                                       18106001
BGNP100  TM    XDRF+55,X'04'                                            18108001
         BZ    BGNPEND                 RETURN IF OPTION RULING ON       18110001
*                                      CONTAINING BEGIN IS ORDER        18112001
BGNP110  NI    XMAPOPTN,X'FF'-XMAPORDR SET OPTION TO REORDER            18114001
BGNPEND  IEMKLVE  NORC                                                  18120001
         EJECT                                                          18160001
*                                                                       18200001
*** KGCLN1 ************************************************************ 18240001
*                                                                       18280001
* FUNCTION - TO PROCESS CLN1,CLN2 AND WHILE TRIPLES.                    18340042
*                                                                       18400001
*********************************************************************** 18440001
*                                                                       18480001
KGCLN1   IEMKENT  TYPE=2                                                18520001
         MVI   SRGLCODE,XSRGGLBL                                        18560001
         BAL   RR,KGSRGL               MAKE GLOBAL ENTRY                18600001
CLN1END  IEMKLVE  NORC                                                  18640001
         EJECT                                                          18680001
*                                                                       18720001
*** KGCOMA ************************************************************ 18760001
*                                                                       18800001
* FUNCTION - TO PROCESS THE COMMA TRIPLE.                               18840001
*            IF IT IS A SUBS COMA THEN AN ENTRY IS MADE IN USE LIST.    18880001
*            IF IT IS A COMA IN A GET STATEMENT THEN MAKE ENTRIES IN    18920001
*            BOTH THE USE AND SUBS/REGION LIST.                         18960001
*                                                                       19000001
*********************************************************************** 19040001
*                                                                       19080001
KGCOMA   IEMKENT  TYPE=2                                                19120001
         BAL   RR,KGRFCV               CHECK FOR REFERENCES TO THE CV   19160001
         BAL   RR,KGOTST               CALL ROUTINE TO DETERMINE        19200001
*                                      WHETHER THIS TRIPLE COULD CAUSE  19240001
*                                      ENTRY TO AN ON-UNIT              19280001
         OC    SUBCOUNT(2),SUBCOUNT                                     19320001
         BZ    COMA100                 BRANCH IF NOT SUBS COMA          19360001
         CLI   CURRSUB,NULL                                             19400001
         BE    COMAEND                 RETURN IF CURRSUB IS NULL        19440001
         MVC   USELDREF(2),XTRPOP2                                      19480001
         BAL   RR,KGUSEL               MAKE USE LIST ENTRY              19520001
         B     COMAEND                 RETURN                           19560001
COMA100  TM    XMAPLOOP,XMAPGLST                                        19600001
         BNO   COMAEND                 RETURN IF NOT GET STATEMENT      19640001
         OI    KGCOD1,ASSFLAG                                           19680001
         MVC   USELDREF(2),XTRPOP2                                      19720001
         BAL   RR,KGUSEL               MAKE USE LIST ENTRY              19760001
COMAEND  IEMKLVE  NORC                                                  19800001
         EJECT                                                          19840001
*                                                                       19880001
*** KGCOPY ************************************************************ 19920001
*                                                                       19960001
* FUNCTION - TO PROCESS COPY,READ,WRITE,REWRITE,LOCATE,PUT AND DELETE   20000001
*            TRIPLES.                                                   20040001
*            THE APPROPRIATE TRIPLE MASK IS 'OR'ED INTO THE SLOT AT     20080001
*            THE BEGINNING OF THE TRIPLE MASK TABLE.                    20120001
*                                                                       20160001
*********************************************************************** 20200001
*                                                                       20240001
KGCOPY   IEMKENT  TYPE=2                                                20280001
         LA    GR1,TRPMSK(TR)          ADDRESS TRIPLE MASK              20320001
         OC    TRPMSK(3),0(GR1)        'OR' INTO SLOT AT BEGINNING      20360001
*                                      OF TRIPLE MASKS.                 20400001
COPYEND  IEMKLVE  NORC                                                  20440001
         EJECT                                                          20480001
*                                                                       20520001
*** KGDATA ************************************************************ 20560001
*                                                                       20600001
* FUNCTION - TO PROCESS THE DATA TRIPLE                                 20640001
*            IF THE NEXT TRIPLE IS A DATA' TRIPLE THEN A GLOBAL ENTRY   20680001
*            IS MADE IN THE SUBS/REGION LIST AND THE USE LIST IS        20720001
*            DELETED.                                                   20760001
*                                                                       20800001
*********************************************************************** 20840001
*                                                                       20880001
KGDATA   IEMKENT  TYPE=2                                                20920001
       IEMKTAB SCAN,XLCRTXT,AATO=(IP),SATO=CURRTEXT INSPECT NEXT TRIPLE 20960001
         CLI   XTRPCODE,XTRPDATP                                        21000001
         BE    DATA100                 BRANCH IF DATA'                  21040001
       IEMKTAB SET,XLCRTXT,SA=CURRTEXT RESET SCAN                       21080001
         B     DATAEND                 RETURN                           21120001
DATA100  NI    XMAPSPEC,X'FF'-XMAPNOST  STORE OF CV REQUIRED.     33903 21130020
         TM    XMAPLOOP,XMAPGLST                                  33903 21140020
         BZ    DATAEND                  RETURN IF PUT STMT.       33903 21150020
         MVI   SRGLCODE,XSRGGLBL                                  33903 21160020
         BAL   RR,KGSRGL               MAKE A GLOBAL ENTRY IN SUBS/     21200001
*                                      REGION LIST                      21240001
         BAL   RR,KGDELT               DELETE USE LIST                  21280001
         NI    XMAPSPEC,XMAPSTLD       STORE AND LOAD REQUIRED          21320001
DATAEND  IEMKLVE  NORC                                                  21360001
         EJECT                                                          21400001
*                                                                       21440001
*** KGDELU ************************************************************ 21480001
*                                                                       21520001
* FUNCTION - TO DELETE UNSAFE ENTRIES FROM CURRENT USE LIST CHAINED OFF 21560001
*            CURRENT DO MAP ENTRY.                                      21600001
*                                                                       21640001
*********************************************************************** 21680001
*                                                                       21720001
KGDELU   IEMKENT  TYPE=1                                                21760001
         TM    XMAPLOOP,XMAPATUV                                        21880001
         BO    DELUEND                 RETURN IF UNSAFES HAVE ALREADY   21920001
*                                      BEEN DELETED                     21960001
         OI    XMAPLOOP,XMAPATUV       ASSIGNMENT TO AN UNSAFE          22000001
         CLI   XMAPUSEL,NULL                                      54726 22010064
         BE    DELUEND                 RETURN IF NO USE LIST      54726 22020064
*                                                                       22040001
* SET POINTER 1 AT START OF USE LIST                                    22080001
*                                                                       22120001
       IEMKTAB SET,XLCRUSE,SA=XMAPUSEL,PTR=1                            22160001
*                                                                       22200001
* SET POINTER 2 AT END OF LIST                                          22240001
*                                                                       22280001
       IEMKTAB SETZ,XLCRUSE,PTR=2,OPT=B                                 22320001
*                                                                       22360001
* SCAN BACKWARDS WITH POINTER 2 BEFORE ENTERING SORT LOOP               22400001
*                                                                       22440001
       IEMKTAB SCAN,XLCRUSE,PTR=2,OPT=B,AATO=(GR3)                      22480001
*                                                                       22520001
* SCAN FORWARDS WITH POINTER 1 UNTIL A SAFE ENTRY IS FOUND              22560001
*                                                                       22600001
DELU100  DS    0H                                                       22640001
       IEMKTAB SCAN,XLCRUSE,PTR=1,AATO=(USER),ETA=DELUEND,SATO=XMAPUSEL 22680001
         CR    GR3,USER                                                 22720001
         BNE   DELU110                 BRANCH IF PTRS DO NOT COINCIDE   22760001
         TM    XUSECODE,XUSEUNSF                                        22800001
         BNO   DELUEND                 BRANCH IF POINTERS COINCIDE BUT  22840001
*                                      ENTRY IS NOT AN UNSAFE           22880001
*                                                                       22884020
*        HERE THE WHOLE OF THE USE LIST HAS BEEN DELETED AND            22888020
*        THE XMAPUSEL POINTS AT A TERMINAL ENTRY.                       22892020
*                                                                       22896020
         MVI   XMAPUSEL,NULL           RESET XMAPUSEL SLOT TO     30372 22900020
*                                      INDICATE NO USE LIST, SO   30372 22904020
*                                      XMAPUSEL CAN BE CORRECTLY  30372 22908020
*                                      RESET TO POINT AT ANY      30372 22912020
*                                      FURTHER USE LIST ENTRIES.  30372 22916020
         B     DELU115                                                  22920001
DELU110  TM    XUSECODE,XUSEUNSF                                        22960001
         BNO   DELU120                 BRANCH IF NOT UNSAFE             23000001
DELU115  MVC   XUSE(3),=X'FFFFFF'      OVERWRITE ENTRY                  23040001
         B     DELU100                                                  23080001
DELU120  CLI   XUSECODE-XUSE(GR3),XUSEUNSF                              23120001
         BE    DELU140                 BRANCH IF ENTRY IS UNSAFE        23160001
*                                                                       23200001
* SCAN BACKWARDS WITH POINTER 2 UNTIL AN UNSAFE ENTRY IS FOUND          23240001
*                                                                       23280001
       IEMKTAB SCAN,XLCRUSE,PTR=2,AATO=(GR3),OPT=B                      23320001
         CR    GR3,USER                                                 23360001
         BE    DELUEND                 RETURN WHEN POINTERS COINCIDE    23400001
         B     DELU120                                                  23440001
DELU140  XC    XUSE(XUSEEND-XUSE),0(GR3) SWAP ENTRIES                   23480001
         XC    0(XUSEEND-XUSE,GR3),XUSE                                 23520001
         XC    XUSE(XUSEEND-XUSE),0(GR3)                                23560001
         MVC   XUSE(3),=X'FFFFFF'      OVERWRITE UNSAFE ENTRY           23600001
         B     DELU100                                                  23640001
DELUEND  DS    0H                                                       23680001
       IEMKTAB DEACT,XLCRUSE           DEACTIVATE USE LIST              23720001
         IEMKLVE  NORC                                                  23760001
         EJECT                                                          23800001
*                                                                       23840001
*** KGDELT ************************************************************ 23880001
*                                                                       23920001
* FUNCTION - TO DELETE FROM THE USE LIST ALL VARIABLES WHICH ARE NOT    23960001
*            COMPILER CREATED TEMPORARIES                               24000001
*                                                                       24040001
*********************************************************************** 24080001
*                                                                       24120001
KGDELT   IEMKENT  TYPE=1                                                24160001
         TM    XMAPLOOP,XMAPOCTS                                        24200001
         BO    DELTEND                 RETURN IF NON COMPILER-CREATED   24240001
*                                      TEMPS HAVE ALREADY BEEN DELETED  24280001
*                                                                       24320001
         OI    XMAPLOOP,XMAPOCTS       ONLY COMPILER CREATED TEMPS      24360001
*                                       IN USE LIST                     24400001
         CLI   XMAPUSEL,NULL                                            24440001
         BE    DELTEND                 BRANCH IF THERE IS NO USE LIST   24480001
*                                                                       24520001
* SET POINTER 1 AT START OF USE LIST                                    24560001
*                                                                       24600001
       IEMKTAB SET,XLCRUSE,SA=XMAPUSEL,PTR=1                            24640001
*                                                                       24680001
* SET POINTER 2 AT END OF LIST                                          24720001
*                                                                       24760001
       IEMKTAB SETZ,XLCRUSE,PTR=2,OPT=B                                 24800001
*                                                                       24840001
* SCAN BACKWARDS WITH POINTER 2 BEFORE ENTERING SORT LOOP               24880001
*                                                                       24920001
       IEMKTAB SCAN,XLCRUSE,PTR=2,OPT=B,AATO=(GR3)                      24960001
*                                                                       25000001
* SCAN FORWARDS WITH POINTER 1 UNTIL A COMPILER CREATED TEMP IS         25040001
*            FOUND                                                      25080001
*                                                                       25120001
DELT100  DS    0H                                                       25160001
       IEMKTAB SCAN,XLCRUSE,PTR=1,AATO=(USER),ETA=DELTEND,SATO=XMAPUSEL 25200001
         CR    GR3,USER                                                 25240001
         BNE   DELT110                 BRANCH IF PTRS DO NOT COINCIDE   25280001
         TM    XUSECODE,XUSECTMP                                        25320001
         BO    DELTEND                 BRANCH IF POINTERS COINCIDE BUT  25360001
*                                      ENTRY IS A COMPILER TEMP         25400001
*                                                                       25404020
*        HERE THE WHOLE OF THE USE LIST HAS BEEN DELETED AND            25408020
*        THE XMAPUSEL POINTS AT A TERMINAL ENTRY.                       25412020
*                                                                       25416020
         MVI   XMAPUSEL,NULL           RESET XMAPUSEL SLOT TO     30372 25420020
*                                      INDICATE NO USE LIST, SO   30372 25424020
*                                      XMAPUSEL CAN BE CORRECTLY  30372 25428020
*                                      RESET TO POINT AT ANY      30372 25432020
*                                      FURTHER USE LIST ENTRIES.  30372 25436020
         B     DELT115                                                  25440001
DELT110  TM    XUSECODE,XUSECTMP                                        25480001
         BO    DELT120                 BRANCH IF COMPILER TEMP          25520001
DELT115  MVC   XUSE(3),=X'FFFFFF'      OVERWRITE ENTRY                  25560001
         B     DELT100                                                  25600001
DELT120  TM    XUSECODE-XUSE(GR3),XUSECTMP                              25640020
         BNO   DELT140                 BRANCH IF ENTRY IS NOT A         25680020
*                                      COMPILER CREATED TEMP            25720001
*                                                                       25760001
* SCAN BACKWARDS WITH POINTER 2 UNTIL A NON COMPILER CREATED TEMP IS    25800001
*            FOUND.                                                     25840001
*                                                                       25880001
       IEMKTAB SCAN,XLCRUSE,PTR=2,AATO=(GR3),OPT=B                      25920001
         CR    GR3,USER                                                 25960001
         BE    DELTEND                 RETURN WHEN POINTERS COINCIDE    26000001
         B     DELT120                                                  26040001
DELT140  XC    XUSE(XUSEEND-XUSE),0(GR3) SWAP ENTRIES                   26080001
         XC    0(XUSEEND-XUSE,GR3),XUSE                                 26120001
         XC    XUSE(XUSEEND-XUSE),0(GR3)                                26160001
         B     DELT100                                                  26200001
DELTEND  IEMKLVE  NORC                                                  26240001
         EJECT                                                          26280001
*                                                                       26320001
*** KGEDIO ************************************************************ 26360001
*                                                                       26400001
* FUNCTION - TO PROCESS THE END I/O TRIPLE                              26440001
*                                                                       26480001
*********************************************************************** 26520001
*                                                                       26560001
KGEDIO   IEMKENT  TYPE=2                                                26600001
         SR    TR,TR                   CLEAR TRANSLATE REGISTER         26640001
         BAL   RR,KGOTST               SEE WHETHER THE I/O STATEMENT    26680001
*                                      COULD CAUSE ENTRY TO AN ON-      26720001
*                                      UNIT                             26760001
         XC    TRPMSK(3),TRPMSK        CLEAR 1ST SLOT IN TRPMSK         26800001
         NI    XMAPLOOP,X'FF'-XMAPGLST RESET FLAG IN DO MAP             26840001
EDIOEND  IEMKLVE  NORC                                                  26880001
         EJECT                                                          26920001
*                                                                       26960001
*** KGERRR ************************************************************ 27000001
*                                                                       27040001
* FUNCTION - TO PRODUCE A TERMINAL ERROR MESSAGE AND ABORT.             27080001
*                                                                       27120001
*********************************************************************** 27160001
*                                                                       27200001
KGERRR   IEMKENT  TYPE=LL3                                              27240001
         MVC   PAR6+1(3),=X'04CA40'    MOVE TERMINAL ERROR MESSAGE NO.  27280001
*                                      INTO PAR6                        27320001
         L     LR,ZUERR                PUT ERROR MESSAGE                27360001
         BALR  RR,LR                      IN DICTIONARY                 27400001
         L     LR,ZABORT               LOAD ADDRESS OF ABORT ROUTINE    27440001
         BR    LR                      BRANCH TO IT                     27480001
ERRREND  IEMKLVE  NORC                                                  27520001
         EJECT                                                          27560001
*                                                                       27600001
*** KGFNCM ************************************************************ 27640001
*                                                                       27680001
* FUNCTION - TO PROCESS FNCM TRIPLE.                                    27720001
*                                                                       27840001
*********************************************************************** 27880001
*                                                                       27920001
KGFNCM   IEMKENT  TYPE=2                                                27960001
         BAL   RR,KGRFCV               CHECK FOR REFERENCES TO THE CV   28000001
         BAL   RR,KGOTST               CALL ROUTINE TO DETERMINE        28040001
*                                      WHETHER ON-UNITS COULD BE        28080001
*                                      ENTERED FROM THIS TRIPLE         28120001
         TM    KGCOD1,FNSTFLAG                                          28160001
         BO    FNCMEND                 RETURN IF FUNCTION COMA STACK    28200001
*                                      HAS ALREADY OVERFLOWED           28240001
*                                                                       28280001
* MOVE 2ND OPERAND TO FUNCTION COMA STACK                               28320001
*                                                                       28360001
         L     GR1,FNSTK               LOAD CURRENT STACK POINTER       28400001
         MVC   0(2,GR1),XTRPOP2        MOVE DICT REF TO STACK           28440001
         LA    GR1,2(GR1)              BUMP POINTER                     28480001
         ST GR1,FNSTK                  SAVE IT                          28520001
         C     GR1,FNSTKEND            COMPARE WITH END OF STACK ADDR   28560001
         BL    FNCMEND                 RETURN IF STACK NOT FULL YET     28600001
*                                                                       28640001
* STACK IS FULL. SET FNSTFLAG TO 1 TO INDICATE THAT ALL FNC' TRIPLES    28680001
* FOR NON B.I.F.'S ARE TO BE MARKED AS GLOBAL REGION BOUNDARIES         28720001
* UNTIL FNCOUNT BECOMES ZERO ONCE MORE.                                 28760001
*                                                                       28800001
         OI    KGCOD1,FNSTFLAG         SET FLAG TO INDICATE STACK HAS   28840001
*                                      OVERFLOWED                       28880001
FNCMEND  IEMKLVE  NORC                                                  28920001
         EJECT                                                          28960001
*                                                                       29000001
*** KGFNCP ************************************************************ 29040001
*                                                                       29080001
* FUNCTION - TO PROCESS THE FNC' TRIPLE.                                29120001
*            IF THE FUNCTION IS NON-BUILTIN THEN A GLOBAL ENTRY IS      29160001
*            MADE IN THE SUBS/REGION LIST AND THE USE LIST IS           29200001
*            DELETED.                                                   29240001
*                                                                       29280001
*********************************************************************** 29320001
*                                                                       29360001
KGFNCP   IEMKENT  TYPE=2                                                29400001
         LH    GR1,FNCOUNT             FNCOUNT=FNCOUNT-1                29440001
         SH    GR1,H1                                                   29480001
         STH   GR1,FNCOUNT                                              29520001
         CLI   XTRPCODE,XTRPPVBL                                        29560001
         BE    FNCP140                 BRANCH IF PV' TRIPLE             29600001
         TM    XTRPOP2,NBIFLAG                                          29640001
         BO    FNCP120                 BRANCH IF FUNC. IS NOT BUILTIN   29680001
         OC    FNCOUNT(2),FNCOUNT                                       29720001
         BNZ   FNCP090                 BRANCH IF FUNCTION IS NESTED     29760001
*                                                                       29800001
* CHECK THAT FUNCTION IS NOT UNSPEC WHICH DOES NOT PRODUCE PV - PV'     29840001
* TRIPLES.                                                              29880001
*                                                                       29920001
         MVC   PAR1+2(2),XTRPOP1                                        29960001
         L     LR,ZDRFAB               ACCESS DICT ENTRY OF FUNCTION    30000001
         BALR  RR,LR                                                    30040001
         L     DRFR,PAR1               BASE XDRF                        30080001
         CLI   XDRFFNCD,XDRFUNSP                                        30120001
         BE    FNCP140                 BRANCH IF FUNCTION IS UNSPEC     30160001
         CLI   XDRFFNCD,XDRFSBST                                        30200001
         BNE   FNCP090                 BRANCH IF NOT SUBSTR             30240001
*                                                                       30280001
* FUNCTION IS SUBSTR WHICH CAN ONLY ASSIGN TO 1ST ARGUMENT              30320001
* SUBSTR MAY RAISE STRINGRANGE                                          30323001
*                                                                       30326001
         LA    GR2,1                                                    30329001
         SLL   GR2,24                  SET UP MASK FOR STRINGRANGE      30332001
         L     GR1,LOOPONUS                                             30335001
         NR    GR1,GR2                 UPDATE LOOPONUS                  30338001
         ST    GR1,LOOPONUS                                             30341001
         TM    XMAPOPTN,XMAPORDR                                        30344001
         BZ    FNCP095                 BRANCH IF REORDER IS RULING      30347001
         N     GR2,PRFOPT              'AND' IN PREFIX OPTIONS MASK     30350001
         BZ    FNCP095                 BRANCH IF STRINGRANGE DISABLED   30353001
         MVI   SRGLCODE,XSRGUNSF                                        30356001
         BAL   RR,KGSRGL               UNSAFE REGION BOUNDARY           30359001
         BAL   RR,KGDELU               DELETE UNSAFES FROM THE USE LIST 30362001
         N     GR2,ATNVONUS                                             30365001
         BZ    FNCP095                 BRANCH IF NO STRINGRANGE ON-     30368001
*                                      UNITS WITH ASSIGNMENTS TO 'NICE' 30371001
*                                      VARIABLES                        30374001
         MVI   SRGLCODE,XSRGGLBL                                        30377001
         BAL   RR,KGSRGL               GLOBAL REGION BOUNDARY           30380001
         BAL   RR,KGDELT               DELETE USE LIST                  30383001
FNCP095  DS    0H                                                       30386001
         L     GR1,FNSTK               LOAD STACK POINTER               30400001
         SH    GR1,=H'6'               POINT 3 ARGS BACK                30440001
         CLC   2(2,GR1),=X'FFFF'                                        30446001
         BNE   FNCP070                 BRANCH IF MORE THAN ONE ARG      30452001
         LA    GR1,4(GR1)              BUMP PAST ONLY ARG               30458001
         B     FNCP080                                                  30464001
FNCP070  DS    0H                                                       30470001
         CLC   0(2,GR1),=X'FFFF'                                        30480001
         BNE   FNCP080                 BRANCH IF THREE ARGUMENTS        30520001
         LA    GR1,2(GR1)              BUMP POINTER TO POINT            30560001
FNCP080  LA    GR1,2(GR1)              PAST 1ST ARGUMENT                30600001
         ST    GR1,FNSTK                                                30640001
         B     FNCP140                                                  30680001
FNCP090  TM    KGCOD1,FNSTFLAG                                          30720001
         BO    FNCP110                 BRANCH IF FUNCTION STACK HAS     30760001
*                                      ALREADY OVERFLOWED               30800001
*                                                                       30840001
* SINCE FUNCTION IS BUILTIN AND NOT A PSEUDO VARIABLE, NONE OF THE      30880001
* ARGUMENTS ARE BEING ASSIGNED TO. SET STACK POINTER TO START OF        30920001
* CURRENT ARGUMENT LIST.                                                30960001
*                                                                       31000001
         L     GR1,FNSTK               LOAD STACK POUNTER               31040001
FNCP100  BCTR  GR1,0                                                    31080001
         BCTR  GR1,0                   DECREMENT BY 2                   31120001
         ST    GR1,FNSTK               UPDATE FNSTK                     31160001
         CLC   0(2,GR1),=X'FFFF'                                        31200001
         BE    FNCPEND                 RETURN IF MARKER FOUND           31240001
         B     FNCP100                                                  31280001
*                                                                       31320001
* STACK HAS ALREADY OVERFLOWED. IF FNCOUNT=0 THEN FNSTFLAG IS SET TO    31360001
* ZERO AND THE STACK POINTER RESET.                                     31400001
*                                                                       31440001
FNCP110  OC    FNCOUNT(2),FNCOUNT                                       31480001
         BNZ   FNCPEND                 RETURN IF FNCOUNT NOT ZERO       31520001
         NI    KGCOD1,X'FF'-FNSTFLAG   RESET FLAG                       31560001
        L     GR1,FNSTKEND                                              31600001
         SH    GR1,=H'200'                                              31640001
         ST    GR1,FNSTK               RESET STACK POINTER              31680001
         B     FNCPEND                 RETURN                           31720001
*                                                                       31760001
* FUNCTION IS NON-BUILTIN. IF IT IS INTERNAL THEN IT IS ASSUMED THAT    31800001
* ALL VARIABLES ARE ASSIGNED TO AND A GLOBAL REGION BOUNDARY IS         31840001
* MARKED AT THIS POINT                                                  31880001
*                                                                       31920001
FNCP120  TM    XTRPOP2,EXTFLAG                                          31960001
         BO    FNCP130                 BRANCH IF FUNCTION IS EXTERNAL   32000001
FNCP125  MVI   SRGLCODE,XSRGGLBL                                        32040001
         BAL   RR,KGSRGL               BLOBAL REGION BOUNDARY           32080001
         BAL   RR,KGDELT               DELETE NON COMPILER TEMPS FROM   32120001
*                                      THE USE LIST                     32160001
         NI    XMAPSPEC,XMAPSTLD       STORE AND LOAD REQUIRED          32200001
         B     FNCP090                                                  32240001
*                                                                       32280001
* FUNCTION IS EXTERNAL. MARK AN UNSAFE BOUNDARY, DELETE UNSAFES FROM    32320001
* THE USE LIST AND THEN CONSIDER EACH ENTRY IN TURN FOR ENTRY INTO      32360001
* THE USE LIST.                                                         32400001
*                                                                       32440001
FNCP130  MVI   SRGLCODE,XSRGUNSF                                        32480001
         BAL   RR,KGSRGL               UNSAFE REGION BOUNDARY           32520001
         BAL   RR,KGDELU               DELETE UNSAFES FROM THE USE LIST 32560001
FNCP140  TM    KGCOD1,FNSTFLAG                                          32600001
         BO    FNCP125                 BRANCH IF FUNCTION STACK HAS     32640001
*                                      ALREADY OVERFLOWED               32680001
         L     GR2,FNSTK               LOAD STACK POINTER               32720001
FNCP150  SH    GR2,=H'2'               DECREMENT BY TWO                 32760001
         ST    GR2,FNSTK               UPDATE FNSTK                     32800001
         CLC   0(2,GR2),=X'FFFF'                                        32840001
         BE    FNCPEND                 RETURN IF END OF FNCM'S FOR THIS 32880001
*                                      CALL                             32920001
         MVC   USELDREF(2),0(GR2)      MOVE DICT REF TO BE CONSIDERED   32960001
         OI    KGCOD1,ASSFLAG          FOR ENTRY INTO USE LIST.(REGION  33000001
         BAL   RR,KGUSEL               BOUNDARIES WILL ALSO BE          33040001
*                                      GENERATED)                       33080001
         B     FNCP150                                                  33120001
FNCPEND  IEMKLVE  NORC                                                  33160001
         EJECT                                                          33200001
*                                                                       33240001
*** KGFTLT ************************************************************ 33280001
*                                                                       33320001
* FUNCTION - TO PROCESS FORMAT LIST, FORMAT LIST' TRIPLES.              33360001
*                                                                       33400001
*********************************************************************** 33440001
*                                                                       33480001
KGFTLT   IEMKENT TYPE=2                                                 33520001
         NI    XMAPLOOP,X'FF'-XMAPGLST RESET FLAG IN DO MAP ENTRY       33560001
         MVI   SRGLCODE,XSRGGLBL                                        33570001
         BAL   RR,KGSRGL               MAKE A GLOBAL ENTRY IN THE       33580001
*                                      SUBS/REGION LIST                 33590001
FTLTEND  IEMKLVE NORC                                                   33600001
         EJECT                                                          33640001
*                                                                       33680001
*** KGFUNC ************************************************************ 33720001
*                                                                       33760001
* FUNCTION - TO PROCESS FUNCTION TRIPLE                                 33800001
*                                                                       33840001
*********************************************************************** 33880001
*                                                                       33920001
KGFUNC   IEMKENT  TYPE=2                                                33960001
         LH    GR1,FNCOUNT             FNCOUNT=FNCOUNT+1                34000001
         LA    GR1,1(GR1)                                               34040001
         STH   GR1,FNCOUNT                                              34080001
         MVI   CURRSUB,NULL            SET CURRSUB TO NULL              34120001
         TM    KGCOD1,FNSTFLAG                                          34160001
         BO    FUNCEND                 RETURN IF FUNCTION COMA STACK    34200001
*                                      HAS ALREADY OVERFLOWED           34240001
         L     GR1,FNSTK               LOAD STACK POUNTER               34280001
         MVC   0(2,GR1),=X'FFFF'       PUT MARKER IN STACK              34320001
         LA    GR1,2(GR1)              BUMP POINTER                     34360001
         ST    GR1,FNSTK               UPDATE FNSTK                     34400001
         C     GR1,FNSTKEND                                             34440001
         BL    FUNCEND                 RETURN IF STACK NOT YET FULL     34480001
         OI    KGCOD1,FNSTFLAG         SET FLAG TO INDICATE THAT STACK  34520001
*                                      HAS OVERFLOWED                   34560001
FUNCEND  IEMKLVE  NORC                                                  34600001
         EJECT                                                          34640001
*                                                                       34680001
*** KGGETD ************************************************************ 34720001
*                                                                       34760001
* FUNCTION - TO PROCESS THE GET TRIPLE.                                 34800001
*                                                                       34840001
*********************************************************************** 34880001
*                                                                       34920001
KGGETD   IEMKENT  TYPE=2                                                34960001
         OI    XMAPLOOP,XMAPGLST       SET FLAG IN DO MAP               35000001
         BAL   RR,KGCOPY               CALL ROUTINE TO 'OR'             35040001
*                                      APPROPRIATE TRIPLE MASK INTO     35080001
*                                      SLOT AT BEGINNING OF MASK TABLE  35120001
GETDEND  IEMKLVE  NORC                                                  35160001
         EJECT                                                          35200001
*                                                                       35240001
*** KGGOTO ************************************************************ 35280001
*                                                                       35320001
* FUNCTION - TO PROCESS GOTO,GOOB,RETN TRIPLES                          35360020
*                                                                       35400001
*********************************************************************** 35440001
*                                                                       35480001
KGGOTO   IEMKENT TYPE=2                                                 35520001
         CLI   XTRPCODE,X'A3'                                     31190 35520620
         BE    GOTO100                 BRANCH IF RETN TRIPLE      31190 35521220
         CLI   XTRPCODE,X'A5'                                           35522001
         BE    GOTO100                 BRANCH IF GOOB TRIPLE            35524001
         OC    XTRPOP2(2),XTRPOP2                                       35526001
         BZ    GOTO100                 BRANCH IF 2ND OP ZERO            35528001
         MVC   PAR1+2(2),XTRPOP2       MOVE LABEL DICT REF TO PAR1      35530001
         L     LR,ZDRFAB                                                35532001
         BALR  RR,LR                   ACCESS DICT ENTRY OF LABEL       35534001
         L     DRFR,PAR1               BASE XDRF                        35536001
         CLC   16(1,DRFR),XMAPBCNT     COMPARE BLOCK COUNT OF LOOP      35538001
*                                      WITH THAT OF LABEL               35540001
         BE    GOTOEND                 RETURN IF LABEL IN THIS LOOP     35560001
GOTO100  NI    XMAPSPEC,X'FF'-XMAPNOST STORE OF CV REQUIRED             35580001
GOTOEND  IEMKLVE NORC                                                   35600001
         EJECT                                                          35600601
*                                                                       35601201
*** KGINLP ************************************************************ 35601801
*                                                                       35602401
* FUNCTION - TO PROCESS INNERMOST LOOPS TO DECIDE WHETHER THERE IS A    35603001
*            POSSIBILITY OF AN INTERRUPT CAUSING ENTRY TO AN ON-UNIT    35603601
*            WHICH COULD RETURN ABNORMALLY TO A LABEL IN THE LOOP.      35604201
*                                                                       35604801
*********************************************************************** 35605401
*                                                                       35606001
KGINLP   IEMKENT TYPE=2                                                 35606601
         TM    XMAPLOOP,XMAPPRBG                                        35607201
         BO    INLPEND                 RETURN IF THERE IS A PROC OR     35607801
*                                      BEGIN IN THE LOOP                35608401
*                                                                       35609001
* NOW DECIDE WHETHER AN INTERRUPT IN THE LOOP COULD CAUSE ENTRY TO      35609601
* AN ON-UNIT WHICH MAY RETURN ABNORMALLY TO A LABEL WITHIN THE LOOP     35610201
*                                                                       35610801
         TM    KGCOD1,LABFND                                            35611401
         BNO   INLPEND                 RETURN IF THERE ARE NO LABELS    35612001
*                                      IN THE LOOP                      35612601
*                                                                       35613201
* IF REORDER IS RULING THEN COMPUTATIONAL ON-UNITS CAN BE IGNORED       35613801
*                                                                       35614401
         TM    XMAPOPTN,XMAPORDR                                        35615001
         BO    INLP100                 BRANCH IF ORDER                  35615601
         MVI   LOOPONUS,0              CLEAR COMPUTATIONAL ON-UNITS     35616201
*                                                                       35616801
* IF THERE IS AN EXTERNAL LABEL VARIABLE IN THE PROGRAM OR A LABEL      35617401
* VARIABLE IS PASSED AS AN ARGUMENT TO AN EXTERNAL PROCEDURE THEN       35618001
* ALL BITS MUST BE SET ON IN GTLVONUS SINCE ANY LABEL COULD BE          35618601
* BRANCHED TO FROM AN EXTERNAL ON-UNIT                                  35619201
*                                                                       35619801
INLP100  TM    XLCRCODE,X'40'                                           35620401
         BNO   INLP110                 BRANCH IF NO EXT LABEL VBLES OR  35621001
*                                      LAB VBLES PASSED TO EXT PROCS    35621601
         SR    GR1,GR1                                                  35622201
         BCTR  GR1,0                   SET UP MASK OF ALL ONES          35622801
         ST    GR1,GTLVONUS            IN GTLVONUS                      35623401
INLP110  OC    LOOPONUS(3),LOOPONUS                                     35624001
         BZ    INLPEND                 RETURN IF NO INTERRUPTS CAN      35624601
*                                      OCCUR IN THE LOOP                35625201
*                                                                       35625801
* 'AND' TOGETHER LOOPONUS AND GTLVONUS TO DETERMINE WHETHER ANY         35626401
* ON-UNITS CAN BE ENTERED WHICH HAVE A GO TO LABEL VBLE STMT IN THEM    35627001
*                                                                       35627601
         L     GR1,LOOPONUS            LOAD UP LOOPONUS                 35628201
         N     GR1,GTLVONUS                                             35628801
         BNZ   INLP120                 BRANCH IF ON-UNITS WHICH CAN     35629401
*                                      BE ENTERED DO NOT HAVE GOTO      35630001
*                                      LABEL VARIABLE STMTS IN THEM     35630601
*                                                                       35631201
* NOW DETERMINE WHETHER ANY ON-UNITS WHICH CAN BE ENTERED CONTAIN       35631801
* GO TO LABEL CONST STMTS WHERE THE LABEL IS IN THIS LOOP               35632401
*                                                                       35633001
         L     GR1,LOOPONUS            LOAD UP LOOPONUS                 35633601
         N     GR1,LABCONUS                                             35634201
         BZ    INLPEND                 RETURN IF NONE OF THE ON-UNITS   35634801
*                                      WHICH CAN BE ENTERED CONTAIN     35635401
*                                      BRANCHES INTO THIS LOOP          35636001
INLP120  OI    XMAPLOOP,XMAPPRBG       SET LOOP TO HAVE A PROC OR BEGIN 35636601
*                                      TO ENSURE NO SYNDXS              35637201
INLPEND  IEMKLVE NORC                                                   35637801
         EJECT                                                          35640001
*                                                                       35680001
*** KGITPR ************************************************************ 35720001
*                                                                       35760001
* FUNCTION - TO PROCESS PROC AND ITDO TRIPLES.                          35800001
*                                                                       35840001
*********************************************************************** 35880001
*                                                                       35920001
KGITPR   IEMKENT  TYPE=2                                                35960001
         CLI   XTRPCODE,XTRPPROC                                        36000001
         BNE   ITPR100                 BRANCH IF NOT PROC TRIPLE        36040001
         OI    XMAPLOOP,XMAPPRBG       PROC WITHIN THIS LOOP            36080001
         MVI   SRGLCODE,XSRGGLBL                                        36120001
         BAL   RR,KGSRGL               GLOBAL REGION BOUNDARY           36160001
         BAL   RR,KGDELT               DELETE NON COMPILER TEMPS        36200001
*                                      FROM THE USE LIST                36240001
         B     ITPR110                                                  36280001
ITPR100  MVI   SRGLCODE,XSRGITDO                                        36320001
         BAL   RR,KGSRGL               ITDO BOUNDARY                    36360001
ITPR110  L     IPSR,CURRSTK            LOAD STACK POINTER               36400001
         LA    IPSR,XIPSEND-XIPS(IPSR) BUMP TO NEXT ENTRY               36440001
         ST    IPSR,CURRSTK            RESTORE POINTER                  36480001
       IEMKTAB SET,XLCRTXT,SA=XIPSTEXT RESET TEXT POINTER TO ITDO'/    *36520001
                                       PROC'                            36560001
       IEMKTAB SCAN,XLCRTXT,SATO=CURRTEXT,ETA=KGERRR SKIP THIS TRIPLE   36600001
ITPREND  IEMKLVE  NORC                                                  36640001
         EJECT                                                          36640801
*                                                                       36641601
*** KGMASK ************************************************************ 36642401
*                                                                       36643201
* FUNCTION - TO PROCESS A MASK CONSISTING OF ONE-BITS CORRESPONDING     36644001
*            TO EACH ON-UNIT HAVING A CERTAIN PROPERTY(E.G. A GO TO     36644801
*            LABEL VBLE) AND TO RETURN A SIMILAR MASK GIVING THE        36645601
*            'TRUE' PICTURE HAVING TAKEN INTO ACCOUNT THE INTERRUPTS    36646401
*            WHICH MAY OCCUR IN THE ON-UNITS THEMSELVES.                36647201
*                                                                       36648001
*********************************************************************** 36648801
*                                                                       36649601
KGMASK   IEMKENT TYPE=2                                                 36650401
         LH    GR2,=X'1000'            LOAD INITIAL MASK                36651201
         LA    GR4,76                  LOAD INDEX I                     36652001
         LH    GR3,=H'-4'              LOAD STEP AND LIMIT              36652801
MASK100  L     GR0,MATRIX(GR4)         LOAD ROW(I)                      36653601
         NR    GR0,GR1                 'AND' IN MASK OF 'BAD' ON-UNITS  36654401
         BZ    MASK110                 BRANCH IF THESE CONDITIONS COULD 36655201
*                                      NOT BE RAISED                    36656001
         OR    GR1,GR2                 'OR' IN BIT FOR THIS CONDITION   36656801
MASK110  SLL   GR2,1                   SHIFT MASK                       36657601
         BXH   GR4,GR3,MASK100         BRANCH IF NOT END OF MATRIX      36658401
MASKEND  IEMKLVE RC=(GR1)                                               36659201
         EJECT                                                          36660001
*                                                                       36660801
*** KGMTRX ************************************************************ 36661601
*                                                                       36662401
* FUNCTION - TO PROCESS THE MATRIX SET UP BY KGONSC TO GIVE A TRUE      36663201
*            PICTURE OF THE CONDITIONS WHICH CAN BE RAISED WITHIN       36664001
*            THE ON-UNITS FOR EACH ON-CONDITION.                        36664801
*                                                                       36665601
*********************************************************************** 36666401
*                                                                       36667201
KGMTRX   IEMKENT TYPE=1                                                 36668001
         LA    GR2,76                  LOAD I1 (1ST ROW INDEX)          36668801
         LH    GR3,=H'-4'              LOAD STEP AND LIMIT(FOR BOTH)    36669601
         LH    GR1,=X'1000'            LOAD INITIAL COLUMN MASK         36670401
MTRX100  LA    GR4,76                  LOAD I2 (2ND ROW INDEX)          36671201
MTRX110  L     GR0,MATRIX(GR4)         LOAD ROW(I2)                     36672001
         NR    GR0,GR1                 TEST I1'TH BIT                   36672801
         BZ    MTRX120                 BRANCH IF NOT ON                 36673601
         L     GR0,MATRIX(GR4)         LOAD ROW(I2)                     36674401
         O     GR0,MATRIX(GR2)         'OR' ROW(I1)                     36675201
         ST    GR0,MATRIX(GR4)         STORE ROW(I2)                    36676001
MTRX120  BXH   GR4,GR3,MTRX110         BRANCH IF NOT LAST ROW           36676801
         SLL   GR1,1                   SHIFT MASK ONE COLUMN            36677601
         BXH   GR2,GR3,MTRX100         BRANCH IF NOT LAST COLUMN        36678401
MTRXEND  IEMKLVE NORC                                                   36679201
         EJECT                                                          36680001
*                                                                       36720001
*** KGNICE ************************************************************ 36760001
*                                                                       36800001
* FUNCTION - TO RETURN A CODE SIGNIFYING WHETHER OR NOT A DICTIONARY    36840001
*            REFERENCE IS FOR A NORMAL REAL FIXED BINARY SCALAR INTEGER 36880001
*                                                                       36920001
*********************************************************************** 36960001
*                                                                       37000001
KGNICE   IEMKENT  TYPE=LL2                                              37040001
         SR    RC,RC                   CLEAR RETURN CODE                37080001
         TM    XDRFCODE,XDRFDVBL                                        37120001
         BNO   NICEEND                 RETURN IF NOT DATA VARIABLE      37160001
         TM    XDRFCODE,XDRFDIM                                         37200001
         BO    NICEEND                 RETURN IF DIMENSIONED            37240001
NICE100  CLI   XDRFDATA,XDRFRFBS                                        37280001
         BE    NICE110                 BRANCH IF REAL FIXED BIN SHORT   37320001
         CLI   XDRFDATA,XDRFRFBL                                        37360001
         BNE   NICEEND                 RETURN IF NOT REAL FIXED BINARY  37400001
*                                      LONG                             37440001
NICE110  CLI   XDRFSCAL,XDRFZERO                                        37480001
         BNE   NICEEND                 RETURN IF NOT INTEGER            37520001
         LA    RC,4                    SET RETURN CODE TO SHOW VARIABLE 37560001
*                                      IS 'NICE'.                       37600001
NICEEND  IEMKLVE  NORC                                                  37640001
         EJECT                                                          37650001
         LTORG                                                          37660001
         EJECT                                                          37680001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*KG 001-TSS 37690020
IEMKG1   CSECT                                                          37700001
*        ----------------------------------------------------KG 001-TSS 37710020
*                                                                       37720001
*** KGONSC ************************************************************ 37760001
*                                                                       37800001
* FUNCTION - TO SCAN ALL ON-UNITS IN THE PROGRAM AND TO SET UP THE      37810001
*            FOLLOWING MASKS:-                                          37820001
*               1. ATNVONUS - ON-UNITS WHICH HAVE AN ASSIGNMENT TO A    37830001
*                             'NICE' VARIABLE.                          37840001
*               2. GTLVONUS - ON-UNITS WHICH HAVE A GO TO LABEL VBLE    37850001
*                             STATEMENT                                 37860001
*                                                                       37920001
*********************************************************************** 37960001
*                                                                       38000001
KGONSC   IEMKENT TYPE=1                                                 38040001
         OC    XLCRONUS(3),XLCRONUS                                     38120001
         BZ    ONSCEND                 RETURN IF THERE ARE NO ON-UNITS  38160001
*                                                                       38240001
* SET POINTER TO SUBS/REGION LIST                                       38280001
*                                                                       38320001
         IEMKTAB SETZ,XLCRSRG                                           38360001
*                                                                       38400001
* SCAN THE SUBS/REGION LIST                                             38440001
* EACH ENTRY IN THIS LIST CONTAINS A CODE BYTE FOLLOWED BY A TEXT REF   38480001
* WHICH POINTS TO AN ON-UNIT.                                           38520001
*                                                                       38560001
ONSC100  IEMKTAB SCAN,XLCRSRG,AATO=(SRGR),ETA=ONSC380                   38600001
         SR    GR4,GR4                                                  38640001
         IC    GR4,0(SRGR)             GR4 HAS INDEX                    38680001
         L     GR6,=X'80000000'        LOAD INITIAL MASK                38720001
         SRL   GR6,0(GR4)              SHIFT TO INDICATE ON-UNIT        38760001
         ST    GR6,ONTEST              SAVE MASK                        38800001
         SLL   GR4,2                   MULTIPLY INDEX BY 4              38840001
         LA    GR4,MATRIX(GR4)         GR4 NOW ADDRESSES SLOT IN MATRIX 38880001
         L     GR1,ATNVONUS            LOAD MASK OF ON-UNITS CONTAINING 38920001
*                                      ASSIGNMENTS TO 'NICE' VBLES      38960001
         NR    GR6,GR1                                                  39000001
         BNZ   ONSC100                 BRANCH IF A BAD ON-UNIT HAS      39040001
         MVI   KGCOD1,0                ALREADY BEEN FOUND FOR THIS      39080001
*                                      CONDITION                        39120001
         IEMKTAB SET,XLCRTXT,SA=1(SRGR) SET TEXT POINTER AT ON-UNIT     39160001
*                                                                       39200001
* NOW SCAN FOR PROC TRIPLE CORRESPONDING THIS ON-UNIT.                  39240001
*                                                                       39280001
ONSC140 IEMKTAB SCAN,XLCRTXT,AATO=(IP),ETA=KGERRR  INSPECT NEXT TRIPLE  39320001
         CLI   XTRPCODE,XTRPPROC                                        39360001
         BNE   ONSC140                 BRANCH IF NOT PROC TRIPLE.       39400001
*                                                                       39440001
* HAVE REACHED PROC TRIPLE, NOW DETERMINE WHETHER ANY'NICE'VARIABLES    39480001
* COULD BE ASSIGNED TO IN THE ON UNIT, AND ALSO WHAT CONDITIONS COULD   39520001
* BE RAISED.                                                            39560001
ONSC150 IEMKTAB SCAN,XLCRTXT,AATO=(IP),ETA=KGERRR,TRTAB=KGTAB,FBTO=(TR) 39600001
ONSC151  CH    TR,=X'0048'                                              39640001
         BH    ONSC160                 BRANCH IF TRIPLE CANNOT CAUSE    39680001
*                                      ANY INTERRUPTS                   39720001
         L     GR1,0(GR4)              LOAD MASK SO FAR                 39760001
         O     GR1,TRPMSK(TR)          'OR' IN THIS TRIPLE MASK         39800001
         ST    GR1,0(GR4)              STORE IT BACK                    39840001
*                                                                       39880001
* NOW SEE WHETHER TRIPLE IS OF INTEREST IN DETERMINING WHETHER ANY      39920001
* 'NICE' VARIABLES COULD BE ASSIGNED TO.                                39960001
*                                                                       40000001
ONSC160  B     *(TR)                                                    40040001
         B     ONSC150       04                                         40080001
         B     ONSC170       08        FNCM                             40120001
         B     ONSC170       0C            KEYTO,ALLOCATE,INTO,FREE,CV  40160001
         B     ONSC150       10                                         40200001
         B     ONSC150       14                                         40240001
         B     ONSC150       18                                         40280001
         B     ONSC190       1C        ASSI,MTAS,MSA,MTA,BUY ASSI       40320001
         B     ONSC170       20        COMA                             40360001
         B     ONSC150       24                                         40400001
         B     ONSC150       28                                         40440001
         B     ONSC150       2C                                         40480001
         B     ONSC150       30                                         40520001
         B     ONSC150       34                                         40560001
         B     ONSC150       38                                         40600001
         B     ONSC210       3C        GET                              40640001
         B     ONSC150       40                                         40680001
         B     ONSC150       44                                         40720001
         B     ONSC150       48                                         40760001
         B     ONSC310       4C        SNAP,NOSNAP                      40800001
         B     ONSC150       50                                         40840001
         B     ONSC200       54        R                                40880001
         B     ONSC150       58                                         40920001
         B     ONSC220       5C        DATA                             40960001
         B     ONSC230       60        FNC',PV'                         41000001
         B     ONSC150       64                                         41040001
         B     ONSC250       68        ITDO,PROC                        41080001
         B     ONSC150       6C                                         41120001
         B     ONSC320       70        GOTO,GOOB                        41160001
         B     ONSC150       74                                         41200001
         B     ONSC150       78                                         41240001
         B     ONSC260       7C        SUB'                             41280001
         B     ONSC150       80                                         41320001
         B     ONSC150       84                                         41360001
         B     ONSC150       88                                         41400001
         B     ONSC270       8C        SUBS                             41440001
         B     ONSC350       90        SIGNAL                           41480001
         B     ONSC290       94        END I/O                          41520001
         B     ONSC100       98        PROC'                            41560001
*                                                                       41600001
* FNCM,COMA,KEYTO,INTO,ALLOCATE,FREE,CV                                 41640001
*                                                                       41680001
ONSC170  CLI   XTRPCODE,XTRPALOC                                        41700001
         BE    ONSC240                 BRANCH IF ALLOCATE               41720001
         OC    XTRPOP2(2),XTRPOP2                                       41740001
         BZ    ONSC150                 BRANCH IF OP IS TEMP             41760001
         CLC   XTRPOP2,=X'00FF'                                   32240 41770020
         BE    ONSC150                 BRANCH IF OP IS NULL       32240 41780020
         MVC   PAR1+2(2),XTRPOP2                                        41800001
         L     LR,ZDRFAB               ACCESS DICT ENTRY OF VARIABLE    41840001
         BALR  RR,LR                                                    41880001
         L     DRFR,PAR1               BASE XDRF                        41900001
         CLI   XDRFCODE,XDRFSTR+XDRFSTRM                                41920001
         BE    ONSC180                 BRANCH IF STRUCTURE ASSIGNED TO  41940001
         BAL   RR,KGNICE               DETERMINE WHETHER VBLE IS 'NICE' 41960001
         LTR   RC,RC                                                    42000001
         BZ    ONSC150                 BRANCH IF NOT 'NICE'             42040001
         CLI   XTRPCODE,XTRPFNCM                                        42080001
         BNE   ONSC172                 BRANCH IF NOT FNCM               42120001
         OI    KGCOD1,FNCMFLAG         SET FLAG TO INDICATE THERE HAS   42160001
         B     ONSC150                 BEEN A 'NICE' FNCM               42200001
*                                                                       42240001
ONSC172  CLI   XTRPCODE,XTRPCOMA                                        42280001
         BNE   ONSC180                 BRANCH IF NOT COMA TRIPLE        42320001
         OC    SUBCOUNT(2),SUBCOUNT                                     42360001
         BNZ   ONSC150                 BRANCH IF SUBS COMA              42400001
         TM    KGCOD1,GETFLAG                                           42440001
         BNO   ONSC150                 BRANCH IF NOT GET STMT           42460001
ONSC180  OC    ATNVONUS(3),ONTEST      MARK THIS ON-UNIT AS HAVING AN   42480001
         B     ONSC150                 ASSIGNMENT TO A NICE VBLE        42500001
*                                                                       42520001
* MSA,MTA,MTAS,BUY ASSI                                                 42560001
*                                                                       42600001
ONSC190  OC    XTRPOP1(2),XTRPOP1                                       42640001
         BZ    ONSC150                 BRANCH IF OP IS TEMP             42680001
         MVC   PAR1+2(2),XTRPOP1                                        42720001
         L     LR,ZDRFAB               ACCESS DICT ENTRY OF VARIABLE    42760001
         BALR  RR,LR                                                    42800001
         L     DRFR,PAR1               BASE XDRF                        42840001
         BAL   RR,KGNICE               DETERMINE WHETHER VBLE IS 'NICE' 42880001
         LTR   RC,RC                                                    42920001
         BZ    ONSC150                 BRANCH IF NOT 'NICE'             42960001
         B     ONSC180                 ON-UNIT HAS ASSN TO NICE VBLE    43040001
*                                                                       43050001
* R TRIPLE (REMOTE FORMAT ITEM)                                         43060001
*                                                                       43070001
ONSC200  CLI   XTRPCODE,X'A6'                                           43080001
         BE    ONSC240                 BRANCH IF R TRIPLE               43090001
         B     ONSC150                                                  43100001
*                                                                       43120001
* GET TRIPLE                                                            43160001
*                                                                       43200001
ONSC210  OI    KGCOD1,GETFLAG          TURN ON GETFLAG                  43240001
         B     ONSC150                                                  43280001
*                                                                       43320001
* DATA TRIPLE                                                           43360001
*                                                                       43400001
ONSC220  TM    KGCOD1,GETFLAG                                           43440001
         BNO   ONSC150                 BRANCH IF NOT GET STATEMENT      43480001
       IEMKTAB SCAN,XLCRTXT,AATO=(IP)                                   43520001
         CLI   XTRPCODE,XTRPDATP                                        43560001
         BE    ONSC180                 BRANCH IF GET DATA;              43600001
         TRT   XTRPCODE,KGTAB          TRANSLATE CODE BYTE              43640001
         BZ    ONSC150                 CONTINUE SCAN.                   43680001
         B     ONSC151                                                  43720001
*                                                                       43760001
* SUBS,SUB'                                                             43800001
*                                                                       43840001
ONSC270  LH    GR1,SUBCOUNT                                             43880001
         LA    GR1,1(GR1)              SUBCOUNT=SUBCOUNT + 1            43920001
         STH   GR1,SUBCOUNT                                             43960001
         B     ONSC150                                                  44000001
ONSC260  LH    GR1,SUBCOUNT                                             44040001
         BCTR  GR1,0                   SUBCOUNT=SUBCOUNT - 1            44080001
         STH   GR1,SUBCOUNT                                             44120001
         B     ONSC150                                                  44160001
*                                                                       44200001
* FNC',PV' TRIPLES                                                      44240001
*                                                                       44280001
ONSC230  CLI   XTRPCODE,XTRPPVBL                                        44320001
         BE    ONSC232                 BRANCH IF PSEUDO-VARIABLE        44360001
         TM    XTRPOP2,NBIFLAG                                          44400001
         BO    ONSC234                 BRANCH IF FUNCTION IS NOT        44440001
*                                      BUILTIN                          44480001
         MVC   PAR1+2(2),XTRPOP1                                        44520001
         L     LR,ZDRFAB               ACCESS DICT ENTRY OF FUNCTION    44560001
         BALR  RR,LR                                                    44600001
         L     DRFR,PAR1               BASE XDRF                        44640001
         CLI   XDRFFNCD,XDRFUNSP                                        44680001
         BNE   ONSC234                 BRANCH IF NOT UNSPEC             44720001
ONSC232  TM    KGCOD1,FNCMFLAG                                          44760001
         BO    ONSC180                 BRANCH IF FUNCTION IS PV AND     44800001
*                                      THERE HAS BEEN A 'NICE' FNCM     44840001
         B     ONSC150                 OTHERWISE CONTINUE SCAN.         44880001
ONSC234  TM    XTRPOP2,EXTFLAG                                          44920001
         BZ    ONSC240                 BRANCH IF INTERNAL FNC CALL      44940001
         TM    XLCRCODE,X'40'                                           44960001
         BNO   ONSC232                 BRANCH IF NO EXT LABEL VBLES     44980001
         OC    GTLVONUS(3),ONTEST      GO TO LABEL VBLE IN THIS ON-UNIT 45000001
         B     ONSC232                                                  45020001
ONSC240  OC    GTLVONUS(3),ONTEST      IF INTERNAL,ASSUME GO TO LABEL   45040001
         OC    ATNVONUS(3),ONTEST      VARIABLE AND ASSIGNMENT TO NICE  45060001
         B     ONSC100                 VBLE. SCAN FOR NEXT ON-UNIT      45080001
*                                                                       45100001
* PROC,ITDO TRIPLES                                                     45120001
*                                                                       45140001
ONSC250  CLI   XTRPCODE,XTRPITDO                                        45160001
         BE    ONSC150                 CONTINUE SCAN IF ITDO            45200001
         B     ONSC310                 BAD ON-UNIT IF PROC - ASSUME     45240001
*                                      THERE IS ALSO A CALL TO THIS     45280001
*                                      PROCEDURE SOMEWHERE.             45320001
*                                                                       45360001
* END I/O TRIPLE                                                        45400001
*                                                                       45440001
ONSC290  NI    KGCOD1,X'FF'-GETFLAG    TURN OFF GETFLAG                 45480001
         B     ONSC150                                                  45520001
*                                                                       45560001
*                                                                       45630001
* SNAP,NOSNAP. A NESTED ON-UNIT HAS BEEN FOUND. ASSUME THE WORST.       45700001
*                                                                       45770001
ONSC310  OC    ATNVONUS(3),ONTEST      THERE IS AN ASSIGN TO A NICE VBL 45840001
         OC    GTLVONUS(3),ONTEST      THERE IS A GO TO LABEL VBLE      45910001
         B     ONSC100                 LOOK FOR NEXT ON-UNIT            45980001
*                                                                       46050001
* GOTO,GOOB TRIPLES                                                     46120001
*                                                                       46190001
ONSC320  CLI   XTRPCODE,X'A7'                                           46260001
         BE    ONSC150                 BRANCH IF GOTO(WITHIN ON-UNIT)   46330001
         OC    XTRPOP2(2),XTRPOP2                                       46400001
         BZ    ONSC324                 IF 2ND OP IS ZERO THEN STMT IS   46470001
*                                      GO TO LABEL VBLE                 46540001
         MVC   PAR1+2(2),XTRPOP2       MOVE DICT REF OF LABEL TO PAR1   46610001
         L     LR,ZDRFAB                                                46680001
         BALR  RR,LR                   ACCESS DICT ENTRY                46750001
         L     DRFR,PAR1               BASE XDRF                        46820001
         CLI   XDRFCODE,X'00'                                           46890001
         BE    ONSC330                 BRANCH IF LABEL CONST            46960001
ONSC324  OC    GTLVONUS(3),ONTEST      ON-UNIT HAS GO TO LABEL VBLE     47030001
         B     ONSC150                 CONTINUE SCAN                    47100001
*                                                                       47170001
* A GO TO LABEL CONST HAS BEEN FOUND. SET APPROPIATE BIT IN GTLCONUS    47240001
* AND ALSO IN THE DICT ENTRY FOR THE CONST                              47310001
*                                                                       47380001
ONSC330  OC    5(3,DRFR),ONTEST        'OR' THIS ON-CONDITION INTO      47450001
*                                      THE DICT REF                     47520001
         B     ONSC150                 CONTINUE SCAN                    47590001
*                                                                       47800001
* SIGNAL TRIPLE                                                         47840001
*                                                                       47880001
ONSC350  CLC   XTRPOP2(2),=X'00FF'                                      47890001
         BNE   ONSC355                 BRANCH IF NOT CHECK CONDITION    47900001
         IEMKTAB SCAN,XLCRTXT,AATO=(IP) SKIP TO NEXT TRIPLE             47910001
ONSC355  MVC   PAR1+2(2),XTRPOP2       ACCESS DICT ENTRY OF             47920001
         L     LR,ZDRFAB                  ON-CONDITION                  47960001
         BALR  RR,LR                                                    48000001
         L     DRFR,PAR1               BASE XDRF                        48040001
         CLI   XDRFTYPE,X'DA'                                           48080001
         BE    ONSC150                 BRANCH IF ERROR ON-UNIT          48120001
         CLI   XDRFTYPE,SGNLCLB        IS IT SIGNAL CHECK(LAB)    54703 48160064
         BNE   ONSC357                 BRANCH IF NOT              54703 48166064
         LA    GR1,ONCODES+9           YES, TREAT AS FOR SIGNAL   54703 48172064
*                                      CHECK(VARIABLE)            54703 48178064
         B     ONSC370                                            54703 48184064
ONSC357  LA    GR1,ONCODES             ADDRESS LIST OF ONCODES    54703 48190064
ONSC360  CLC   0(1,GR1),XDRFTYPE                                        48200001
         BE    ONSC370                 BRANCH IF MATCH FOUND            48240001
         LA    GR1,1(GR1)              BUMP POINTER                     48280001
         B     ONSC360                 REPEAT                           48320001
*                                                                       48360001
ONSC370  LA    GR2,ONCODES             CALCULATE INDEX                  48400001
         SR    GR1,GR2                                                  48440001
         L     GR2,=X'80000000'        LOAD INITIAL MASK                48480001
         SRL   GR2,0(GR2)              SHIFT TO APPROPIATE POSITION     48520001
         O     GR2,0(GR4)              'OR' MASK SO FAR                 48560001
         ST    GR2,0(GR4)              STORE IT BACK                    48600001
         B     ONSC150                 CONTINUE SCAN                    48640001
*                                                                       48680001
*                                                                       48689001
* ALL ON-UNITS HAVE NOW BEEN PROCESSED. NOW CHANGE THE MASKS SET UP     48698001
* TO GIVE A TRUE PICTURE.                                               48707001
*                                                                       48716001
ONSC380  BAL   RR,KGMTRX               PROCESS MATRIX WHICH HAS BEEN    48725001
*                                      CONSTRUCTED                      48734001
         L     GR1,ATNVONUS            ON-UNITS WITH ASSIGNMENTS TO     48743001
         BAL   RR,KGMASK               NICE VBLES                       48752001
         ST    RC,ATNVONUS             STORE ALTERED MASK               48761001
         L     GR1,GTLVONUS            ON-UNITS WITH GO TO LABEL VBLES  48770001
         BAL   RR,KGMASK                                                48779001
         ST    RC,GTLVONUS             STORE ALTERED MASK               48788001
         IEMKTAB FREE,XLCRSRG                                           48797001
ONSCEND  IEMKLVE NORC                                                   48806001
         EJECT                                                          48815001
*                                                                       48824001
*** KGOTST ************************************************************ 48840001
*                                                                       48880001
* FUNCTION - TO TEST A GIVEN TRIPLE MASK AGAINST:                       48920001
*              1). PRFMSK TO SEE WHETHER ANY INTERRUPTS COULD           48960001
*                  OCCUR.                                               49000001
*              2). XLCRONUS TO SEE WHETHER THERE ARE ON-UNITS IN        49040001
*                  THE COMPILATION FOR THESE INTERRUPTS.                49080001
*            IF REORDER IS IN EFFECT THE FIRST BYTE OF THE PREFIX       49120001
*            MASK IS SET TO ZERO.                                       49160001
*                                                                       49200001
*********************************************************************** 49240001
*                                                                       49280001
KGOTST   IEMKENT  TYPE=2                                                49320001
         L     GR1,TRPMSK(TR)                                           49326001
         N     GR1,PRFOPT              UPDATE MASK OF ON-CONDITIONS     49332001
         O     GR1,LOOPONUS            WHICH CAN BE RAISED WITHIN       49340001
         ST    GR1,LOOPONUS            THIS ON-UNIT                     49350001
         LA    GR1,TRPMSK(TR)          ADDRESS TRIPLE MASK              49360001
         MVC   ONTEST(3),0(GR1)        MOVE TO WORK AREA                49400001
         TM    XMAPOPTN,XMAPORDR                                        49440001
         BO    OTST100                 BRANCH IF ORDER IS THE OPTION    49480001
*                                      RULING                           49520001
         MVI   ONTEST,0                CLEAR 1ST BYTE (COMPUTATIONAL    49560001
*                                      CONDITIONS)                      49600001
OTST100  NC    ONTEST(3),PRFOPT                                         49640001
         BZ    OTSTEND                 RETURN IF INTERRUPTS WHICH COULD 49680001
*                                      OCCUR ARE DISABLED               49720001
         NC    ONTEST(3),XLCRONUS                                       49760001
         BNZ   OTST110                 BRANCH IF UNSAFES COULD BE       49800001
*                                      ASSIGNED TO IN THE ON-UNITS      49840001
*                                      PRESENT                          49880001
*                                                                       49920001
* IF XLCRBEEN=0 THERE ARE NO EXTERNAL VARIABLES OR ARGUMENTS TO         49960001
* EXTERNAL PROCEDURES IN THE PROGRAM AND THEREFORE EXTERNAL ON-UNITS    50000001
* CAN HAVE NO EFFECT                                                    50040001
*                                                                       50080001
         TM    XLCRCODE,XLCRBEEN                                        50120001
         BNO   OTSTEND                 RETURN IF NO EXTERNALS           50160001
*                                                                       50200001
* IF THERE ARE EXTERNALS THEN THERE IS AN AN UNSAFE REGION BOUNDARY     50240001
*                                                                       50280001
         MVI   SRGLCODE,XSRGUNSF                                        50320001
         BAL   RR,KGSRGL               UNSAFE REGION BOUNDARY           50360001
         BAL   RR,KGDELU               DELETE UNSAFES FROM THE USE LIST 50400001
         B     OTSTEND                 RETURN                           50440001
*                                                                       50480001
OTST110  MVI   SRGLCODE,XSRGUNSF                                        50520001
         BAL   RR,KGSRGL               UNSAFE REGION BOUNDARY           50560001
         BAL   RR,KGDELU               DELETE UNSAFES                   50600001
         NI    XMAPSPEC,X'FF'-XMAPNOST STORE OF CV REQUIRED             50640001
*                                      SINCE  AN ON-UNIT COULD BE       50680001
*                                      ENTERED                          50720001
*                                                                       50760001
* TEST WHETHER ON-UNITS FOR CONDITIONS BEING RAISED CONTAIN ANY         50800001
* ASSIGNMENTS TO 'NICE' VARIABLES.                                      50840001
*                                                                       50880001
         NC    ONTEST(3),ATNVONUS      ON-UNITS WITH ASSNS TO NICE VBLS 50920001
         BZ    OTSTEND                 RETURN IF NO 'BAD' ON-UNITS      50960001
         MVI   SRGLCODE,XSRGGLBL                                        51000001
         BAL   RR,KGSRGL               GLOBAL REGION BOUNDARY           51040001
         BAL   RR,KGDELT               DELETE USE LIST                  51080001
         NI    XMAPSPEC,XMAPSTLD       STORE AND LOAD OF CV REQUIRED    51120001
OTSTEND  IEMKLVE  NORC                                                  51160001
         EJECT                                                          51200001
*                                                                       51240001
*** KGPLUS ************************************************************ 51280001
*                                                                       51320001
* FUNCTION - TO PROCESS PLUS,MINUS,MULTIPLY AND DIVIDE TRIPLES          51360001
*                                                                       51400001
*********************************************************************** 51440001
KGPLUS   IEMKENT  TYPE=2                                                51480001
         BAL   RR,KGRFCV               CHECK FOR REFERENCES TO THE CV   51520001
         BAL   RR,KGOTST            CALL ROUTINE TO DETERMINE           51560001
*                                      WHETHER ON-UNITS COULD BE        51600001
*                                      ENTERED FROM THIS TRIPLE         51640001
*                                                                       51680001
         CLI   CURRSUB,NULL                                             51720001
         BE    PLUSEND                 RETURN IF NOT WITHIN SUBS/SUB'   51760001
         MVC   USELDREF(2),XTRPOP1     CONSIDER 1ST OPERAND FOR ENTRY   51800001
         BAL   RR,KGUSEL               INTO USE LIST                    51840001
         MVC   USELDREF(2),XTRPOP2     CONSIDER 2ND OPERAND.            51880001
         BAL   RR,KGUSEL                                                51920001
PLUSEND  IEMKLVE  NORC                                                  51960001
         EJECT                                                          52000001
*                                                                       52040001
*** KGPRFM ************************************************************ 52080001
*                                                                       52120001
* FUNCTION - TO PROCESS PREFIX + AND PREFIX - TRIPLES.                  52160001
*                                                                       52200001
*********************************************************************** 52240001
*                                                                       52280001
KGPRFM   IEMKENT  TYPE=2                                                52320001
         BAL   RR,KGRFCV               CHECK FOR REFERENCES TO THE CV   52360001
         BAL   RR,KGOTST            CALL ROUTINE TO DETERMINE           52400001
*                                      WHETHER ON-UNITS COULD BE        52440001
*                                      ENTERED FROM THIS TRIPLE         52480001
         CLI   CURRSUB,NULL                                             52520001
         BE    PRFMEND                 RETURN IF NOT IN SUBS LIST       52560001
         MVC   USELDREF(2),XTRPOP2                                      52600001
         BAL   RR,KGUSEL               CONSIDER 2ND OP FOR ENTRY IN     52640001
*                                      THE USE LIST                     52680001
PRFMEND  IEMKLVE  NORC                                                  52720001
         EJECT                                                          52760001
*                                                                       52800001
*** KGRFCV ************************************************************ 52840001
*                                                                       52880001
* FUNCTION - TO CHECK TRIPLE OPERANDS FOR REFERENCES TO THE CV.         52920001
*                                                                       52960001
*********************************************************************** 53000001
*                                                                       53040001
KGRFCV   IEMKENT TYPE=LL2                                               53080001
         TM    XMAPSPEC,XMAPNOST                                        53120001
         BZ    RFCVEND                 RETURN IF THERE HAS BEEN AN      53160001
*                                      ASSIGNMENT TO THE CV OR A REF.   53200001
*                                      TO THE CV OUTSIDE A SUBS LIST    53240001
         CLC   XTRPOP1(2),XMAPCVDR                                      53280001
         BE    RFCV100                 BRANCH IF 1ST OP IS CV           53320001
         CLC   XTRPOP2(2),XMAPCVDR                                      53360001
         BE    RFCV100                 BRANCH IF 2ND OP IS CV           53400001
         B     RFCVEND                 RETURN IF NEITHER OP IS CV       53440001
*                                                                       53480001
* CV IS REFERENCED IN THIS TRIPLE. IF THE TRIPLE IS OUTSIDE A SUBS      53520001
* LIST THEN XMAPLDST IS SET TO ZERO. IF IT IS INSIDE A SUBS LIST THEN   53560001
* XMAPCVCT IS INCREMENTED BY ONE(OR TWO).                               53600001
*                                                                       53640001
RFCV100  OC    SUBCOUNT(2),SUBCOUNT                                     53680001
         BNZ   RFCV120                 BRANCH IF TRIPLE IS WITHIN       53720001
*                                      A SUBS LIST                      53760001
RFCV110  NI    XMAPSPEC,X'FF'-XMAPNOST STORE OF CV REQUIRED             53800001
         B     RFCVEND                 RETURN                           53840001
RFCV120  CLI   CURRSUB,NULL                                             53880001
         BE    RFCV110                 BRANCH IF SUBS IS NOT GOING TO   53920001
*                                      BE OPTIMISED                     53960001
*                                                                       54000001
RFCV130  LH    GR1,CVCOUNT                                              54040001
         LA    GR1,1(GR1)              INCREMENT COUNT BY ONE           54080001
         CLC   XTRPOP1(2),XTRPOP2                                       54120001
         BNE   RFCV140                 BRANCH IF ONE OCCURRENCE OF CV   54160001
         LA    GR1,1(GR1)              TWO OCCURRENCES                  54200001
RFCV140  STH   GR1,CVCOUNT                                              54240001
RFCVEND  IEMKLVE NORC                                                   54280001
         EJECT                                                          54320001
*                                                                       54360001
*** KGSCAN ************************************************************ 54400001
*                                                                       54440001
* FUNCTION - TO INSPECT EACH TRIPLE CODE IN TURN AND CALL THE           54480001
*            APPROPRIATE ROUTINE IF THE TRIPLE IS OF INTEREST           54520001
*                                                                       54560001
*********************************************************************** 54600001
*                                                                       54640001
KGSCAN   IEMKENT  TYPE=2                                                54680001
SCAN100  DS    0H                                                       54720001
       IEMKTAB SCAN,XLCRTXT,AATO=(IP),SATO=CURRTEXT,                   *54760001
               TRTAB=KGTAB,FBTO=(TR),ETA=KGERRR                         54800001
         LA    RR,SCAN100              LOAD RETURN POINT                54840001
         B     *(TR)                   BRANCH ON TRANSLATED VALUE       54880001
         B     KGTITL        04        TITLE,PSZ,LSZ ETC.               54920001
         B     KGFNCM        08        FNCM                             54960001
         B     KGALOC        0C        KEYTO,ALLOC,INTO,FREE,STRING,SET 55000064
         B     KGTITL        10        KEY,KEYFROM                      55040001
         B     KGPLUS        14        PLUS,MINUS,MULT                  55080001
         B     KGPRFM        18        PRF-,PRF+                        55120001
         B     KGASSI        1C        ASSI,MTAS,MSA,MTA,BUY ASSI       55160001
         B     KGCOMA        20        COMA                             55200001
         B     KGPLUS        24        DIVIDE,EXP                       55240001
         B     KGOTST        28        IN                               55280001
         B     KGOTST        2C        EXIT,STOP                        55320001
         B     KGOTST        30        OPEN,CLOSE                       55360001
         B     KGCOPY        34        COPY,REPLY                       55400001
         B     KGCOPY        38        PUT                              55440001
         B     KGGETD        3C        GET                              55480001
         B     KGCOPY        40        READ                             55520001
         B     KGCOPY        44        WRITE,REWRITE,LOCATE,DELETE      55560001
         B     KGOTST        48        WAIT                             55600001
         B     *             4C        NOT USED                         55640001
         B     KGBGNP        50        BEGIN'                           55680001
         B     KGBEGN        54        BEGIN                            55720001
         B     KGCLN1        58        CLN1,CLN2,WHYL             35243 55760042
         B     KGDATA        5C        DATA                             55800001
         B     KGFNCP        60        FNC',PV'                         55840001
         B     KGFUNC        64        FNC,PV                           55880001
         B     KGITPR        68        ITDO,PROC                        55920001
         B     KGERRR        6C        ERROR ROUTINE                    55960001
         B     KGGOTO        70        GOTO,GOLN,GOOB                   56000001
         B     KGSTNO        74        STNO,SN2,CN                      56040001
         B     KGSTLB        78        STLB                             56080001
         B     KGSUBP        7C        SUB'                             56120001
         B     *             80        NOT USED                         56160001
         B     *             84        NOT USED                         56200001
         B     KGFTLT        88        FORMAT LIST/LIST'                56240001
         B     KGSUBS        8C        SUBS                             56280001
         B     KGSGNL        90        SIGNAL                           56320001
         B     KGEDIO        94        END I/O                          56360001
         B     SCANEND       98        ITDO',PROC'                      56400001
SCANEND  EQU   *                                                        56440001
         IEMKLVE  NORC                                                  56480001
         EJECT                                                          56520001
*                                                                       56560001
*** KGSGNL ************************************************************ 56600001
*                                                                       56640001
* FUNCTION - TO PROCESS THE SIGNAL TRIPLE                               56680001
*                                                                       56720001
*********************************************************************** 56760001
*                                                                       56800001
KGSGNL   IEMKENT  TYPE=2                                                56840001
*                                                                       56880001
* SEE WHETHER ON-UNITS FOR THE CONDITION BEING SIGNALLED CONTAIN        56920001
* ANY ASSIGNMENTS TO 'NICE VARIABLES.                                   56960001
*                                                                       57000001
         SR    GR2,GR2                 CLEAR ONCODES ADDRESS REG  54703 57002064
SGNL080  DS    0H                                                 54703 57004064
         CLC   XTRPOP2(2),=X'00FF'                                      57008001
         BNE   SGNL095                 GO TO ACCESS ON-COND D.E.  54703 57016064
*                                                                       57018064
SGNL085  DS    0H                                                 54703 57020064
         IEMKTAB SCAN,XLCRTXT,AATO=(IP),SATO=CURRTEXT SKIP THIS TRIPLE  57024001
SGNL090  DS    0H                                                       57032001
         CLI   0(IP),TRCOMA            IS IT A COMA TRIPLE        54703 57032464
         BE    SGNL080                 YES, IT IS SIGNAL CHECK    54703 57032664
         IEMKTAB SET,XLCRTXT,SA=CURRTEXT NO,SO RESET SCAN POINTER 54703 57032864
         LTR   GR2,GR2                                            54703 57033064
         BZ    SGNLEND                 RETURN IF NO VALID         54703 57033264
*                                      ON-COND FOUND              54703 57033464
         B     SGNL110                                            54703 57033664
*                                                                       57034001
SGNL095  MVC   PAR1+2(2),XTRPOP2       ACCESS DICT ENTRY OF ON-COND     57034401
         L     LR,ZDRFAB                                          54703 57034864
         BALR  RR,LR                                                    57035201
         L     DRFR,PAR1               BASE XDRF                        57035601
         CLI   XDRFCODE,X'CD'                                           57036001
         BNE   SGNLEND                 RETURN IF NOT ON-COND D.E. 54703 57036464
         CLI   XDRFTYPE,SGNLCVR        IS IT SIGNAL CHECK(VAR)    54703 57036564
         BNE   SGNL097                                            54703 57036664
SGNL096  LA    GR2,ONCODES+9           YES, SET ONCODES REG       54703 57036764
         CLC   11(2,DRFR),XMAPCVDR     IS IT SIGNAL CHECK(CV)     54703 57036864
         BNE   SGNL085                 NO, TRY AGAIN              54703 57036964
         NI    XMAPSPEC,X'FF'-XMAPNOST YES, STORE OF CV REQUIRED  54703 57037064
         B     SGNL110                                            54703 57037164
*                                                                       57037264
SGNL097  CLI   XDRFTYPE,SGNLCLB        IS IT SIGNAL CHECK(LABEL)  54703 57037364
         BE    SGNL096                 YES, TREAT AS FOR SIGNAL   54703 57037464
*                                      CHECK(VARIABLE)            54703 57037564
*                                                                       57037664
SGNL098  DS    0H                                                       57038401
         CLI   XDRFTYPE,X'DA'                                           57200001
         BE    SGNLEND                 RETURN IF ERROR ON-UNIT          57240001
         LA    GR2,ONCODES             ADDRESS LIST OF ONCODES          57280001
SGNL100  CLC   0(1,GR2),XDRFTYPE                                        57320001
         BE    SGNL110                 BRANCH IF MATCH FOUND            57360001
         LA    GR2,1(GR2)              BUMP INDEX                       57400001
         B     SGNL100                                                  57440001
SGNL110  LA    GR1,ONCODES                                              57480001
         SR    GR2,GR1                 GR2 CONTAINS AN INDEX FOR THIS   57520001
*                                      ON-CONDITION                     57560001
         LR    GR1,GR2                                                  57600001
         L     GR2,=X'80000000'        LOAD INITIAL MASK                57640001
         SRL   GR2,0(GR1)              SHIFT TO CORRECT POSITION        57680001
         CH    GR1,=H'8'                                                57720001
         BNL   SGNL120                 BRANCH IF NOT A COMPUTATIONAL    57760001
*                                      ON-UNIT                          57800001
         TM    XMAPOPTN,XMAPORDR                                        57840001
         BZ    SGNLEND                 RETURN IF REORDER IS THE OPTION  57880001
*                                      RULING                           57920001
SGNL120  MVI   SRGLCODE,XSRGUNSF       UNSAFE REGION BOUNDARY AT THIS   57960001
         BAL   RR,KGSRGL               POINT                            58000001
         BAL   RR,KGDELU               DELETE UNSAFES FROM THE USE LIST 58040001
         MVC   ONTEST(3),XLCRONUS      MOVE MASK OF ON-UNITS TO A       58060001
         N     GR2,ONTEST              FULLWORD                         58080001
         BZ    SGNLEND                 RETURN IF THERE IS NO ON-UNIT    58120001
*                                      FOR THE CONDITION BEING          58160001
*                                      SIGNALLED                        58200001
         NI    XMAPSPEC,X'FF'-XMAPNOST STORE OF CV REQUIRED             58240001
         L     GR1,ATNVONUS            LOAD MASK OF 'BAD' ON-UNITS      58300001
         NR    GR2,GR1                                                  58360001
         BZ    SGNLEND                 RETURN IF THERE ARE NO 'BAD'     58400001
*                                      ON-UNITS FOR THE CONDITION       58440001
*                                      BEING SIGNALLED                  58480001
         MVI   SRGLCODE,XSRGGLBL                                        58520001
         BAL   RR,KGSRGL               GLOBAL REGION BOUNDARY           58560001
         BAL   RR,KGDELT               DELETE NON COMPILER-CREATED      58600001
*                                      TEMPS FROM THE USE LIST          58640001
         NI    XMAPSPEC,XMAPSTLD       STORE AND  LOAD OF CV REQUIRED   58680001
SGNLEND  IEMKLVE  NORC                                                  58720001
         SPACE 5                                                        58728064
TRCOMA   EQU   X'41'                   COMA TRIPLE                54703 58736064
SGNLCVR  EQU   X'F8'                   CHECK(VAR) ONCODE          54703 58744064
SGNLCLB  EQU   X'FA'                   CHECK(LABEL) ONCODE        54703 58752064
         EJECT                                                          58760001
*                                                                       58800001
*** KGSORT ************************************************************ 58840001
*                                                                       58880001
* FUNCTION - TO SORT THE USE LIST CORRESPONDING TO THE CURRENT DO MAP   58920001
*            ENTRY SO THAT THE INVARIANT ELEMENTS APPEAR FIRST.         58960001
*                                                                       59000001
*********************************************************************** 59040001
*                                                                       59080001
KGSORT   IEMKENT  TYPE=2                                                59120001
       IEMKTAB SET,XLCRUSE,SA=XMAPUSEL,PTR=1   SET 1ST POINTER AT START 59160001
       IEMKTAB SETZ,XLCRUSE,OPT=B,PTR=2 SET 2ND POINTER AT END          59200001
         XC    FSAVE(4),FSAVE                                           59240001
SORT100  DS    0H                                                       59280001
       IEMKTAB SCAN,XLCRUSE,AATO=(USER),PTR=1,ETA=SORTEND SCAN         *59320001
                                       FORWARD WITH 1ST POINTER         59360001
         C     USER,FSAVE                                               59400001
         BE    SORTEND                 RETURN IF POINTERS COINCIDE      59440001
         TM    XUSECODE,XUSEASSN                                        59480001
         BNO   SORT100                 BRANCH IF ENTRY IS INVARIANT     59520001
         ST    USER,FSAVE                                               59560001
SORT110  DS    0H                                                       59600001
       IEMKTAB SCAN,XLCRUSE,AATO=(USER),OPT=B,PTR=2 SCAN BACKWARDS     *59640001
                                       WITH 2ND POINTER                 59680001
         C     USER,FSAVE                                               59720001
         BE    SORTEND                 RETURN IF POINTERS COINCIDE      59760001
         TM    XUSECODE,XUSEASSN                                        59800001
         BO    SORT110                 BRANCH IF ENTRY IS NOT INVARIANT 59840001
* SWAP ENTRIES                                                          59880001
         L     GR1,FSAVE                                                59920001
         XC    XUSE(XUSEEND-XUSE),0(GR1)                                59960001
         XC    0(XUSEEND-XUSE,GR1),XUSE                                 60000001
         XC    XUSE(XUSEEND-XUSE),0(GR1)                                60040001
         ST    USER,FSAVE                                               60080001
         B     SORT100                                                  60120001
SORTEND  DS    0H                                                       60160001
       IEMKTAB DEACT,XLCRUSE           DEACTIVATE USE LIST              60200001
         IEMKLVE  NORC                                                  60240001
         EJECT                                                          60280001
*                                                                       60320001
*** KGSRGL ************************************************************ 60360001
*                                                                       60400001
* FUNCTION - TO MAKE AN ENTRY IN THE SUBS/REGION LIST ACCORDING TO      60440001
*            A CODE BYTE SRGLCODE WHICH WILL ITSELF FORM PART OF THE    60480001
*            ENTRY IF IT IS A SUBS TYPE ENTRY THEN THE TEXT REFENCE     60520001
*            IS COPIED FROM CURRSUB, OTHERWISE IT IS CALCULATED FROM    60560001
*            THE CURRENT INPUT POINTER.                                 60600001
*                                                                       60640001
*********************************************************************** 60680001
*                                                                       60720001
KGSRGL   IEMKENT  TYPE=2                                                60760001
         MVC   SRGLDREF(2),USELDREF    DICT REF OF SAFE VARIABLE        60800001
         MVC   SRGLTEXT(3),CURRTEXT    CURRENT TEXT REFERENCE           60840001
         CLI   SRGLCODE,XSRGLEND                                        60880001
         BNE   SRGL100                 BRANCH IF NOT END OF LIST        60920001
         MVC   SRGLBUFF+1(5),SRGLBUFF  SET WHOLE FIELD TO FF'S          60960001
         B     SRGL130                 BRANCH TO MAKE ENTRY             61000001
SRGL100  CLI   SRGLCODE,XSRGSUBS                                        61040001
         BNE   SRGL110                 BRANCH IF NOT SUBS ENTRY         61080001
         MVC   SRGLTEXT(3),CURRSUB     TEXT TEF OF SUBS TRIPLE          61120001
         MVI   PREVCODE,0              CLEAR CODE BYTE                  61160001
         B     SRGL120                                                  61200001
*                                                                       61240001
* IF IT IS THE 1ST ENTRY AND NOT A SUBS DO NOT MAKE AN ENTRY            61280001
*                                                                       61320001
SRGL110  CLI   XMAPSRGL,NULL                                            61360001
         BE    SRGLEND                 RETURN IF 1ST ENTRY              61400001
         CLI   SRGLCODE,XSRGSAFE                                        61440001
         BE    SRGL130                 BRANCH IF SAFE ENTRY             61480001
*                                                                       61520001
* IF THE ENTRY BEING MADE IS NOT SUBS OR SAFE AND HAS ALREADY BEEN MADE 61560001
* SINCE THE LAST SUBS THEN DO NOT MAKE AN ENTRY.                        61600001
*                                                                       61640001
         MVC   *+7(1),SRGLCODE         MOVE CODE INTO TM INSTRUCTION    61680001
         TM    PREVCODE,0            *(ALTERED BY PREVIOUS INSTR)       61720001
         BO    SRGLEND                 RETURN IF ENTRY ALREADY MADE     61760001
         OC    PREVCODE(1),SRGLCODE    SET CODE BYTE                    61800001
SRGL120  XC    SRGLDREF(2),SRGLDREF                                     61840001
SRGL130  CLI   XMAPSRGL,NULL                                            61880001
         BNE   SRGL140                 BRANCH IF NOT 1ST ELEMENT        61920001
       IEMKTAB BLDC,XLCRSRG,SRGLBUFF,SATO=XMAPSRGL MAKE ENTRY AND CHAIN*61960001
                                                  OFF DO MAP            62000001
         B     SRGLEND                                                  62040001
SRGL140  DS    0H                                                       62080001
       IEMKTAB BLDC,XLCRSRG,SRGLBUFF   MAKE ENTRY                       62120001
SRGLEND  IEMKLVE  NORC                                                  62160001
         EJECT                                                          62200001
*                                                                       62240001
*** KGSTNO ************************************************************ 62280001
*                                                                       62320001
* FUNCTION - TO PROCESS STNO AND SN2 TRIPLES                            62360001
*                                                                       62440001
*********************************************************************** 62480001
*                                                                       62520001
KGSTNO   IEMKENT  TYPE=2                                                62560001
         MVC   PRFOPT(1),XTRPOP1+1     COPY OPTIONS BYTE                62600001
         MVC   ZSTAT+2(2),XTRPOP2      COPY STATEMENT NUMBER            62640001
STNOEND  IEMKLVE  NORC                                                  62680001
         EJECT                                                          62720001
*                                                                       62760001
*** KGSTLB ************************************************************ 62800001
*                                                                       62840001
* FUNCTION - TO PROCESS THE STATEMENT LABEL TRIPLE                      62880001
*                                                                       63040001
*********************************************************************** 63080001
*                                                                       63120001
KGSTLB   IEMKENT  TYPE=2                                                63160001
         MVC   PRFOPT(1),XTRPOP1+1     COPY OPTIONS BYTE                63200001
         MVI   SRGLCODE,XSRGGLBL                                        63240001
         BAL   RR,KGSRGL               MAKE GLOBAL ENTRY IN SUBS/REGION 63280001
*                                      LIST                             63320001
*                                                                       63322001
* IF STATEMENT LABEL IS IN AN INNERMOST LOOP THEN UPDATE LABCONUS FROM  63324001
* SLOT IN DICT ENTRY OF LABEL                                           63326001
*                                                                       63328001
         CLI   XMAPLEVL,0                                               63330001
         BE    STLBEND                 RETURN IF PROC                   63332001
         TM    XMAPTYPE,XMAPNTIN                                        63334001
         BO    STLBEND                 RETURN IF NOT INNERMOST LOOP     63336001
         OI    KGCOD1,LABFND           LABEL FOUND IN THE LOOP          63337001
         MVC   PAR1+2(2),XTRPOP2                                        63338001
         L     LR,ZDRFAB               ACCESS DICT ENTRY OF LABEL       63340001
         BALR  RR,LR                                                    63342001
         L     DRFR,PAR1               BASE XDRF                        63344001
         CLI   XDRFCODE,X'00'                                           63346001
         BNE   STLBEND                 RETURN IF NOT STMT LABEL CNST    63348001
         OC    LABCONUS(3),5(DRFR)     ON-UNITS WHICH BRANCH TO THIS LB 63350001
STLBEND  IEMKLVE  NORC                                                  63360001
         EJECT                                                          63400001
*                                                                       63440001
*** KGSUBP ************************************************************ 63480001
*                                                                       63520001
* FUNCTION - TO PROCESS THE SUB' TRIPLE                                 63560001
*            IF CURRSUB IS NOT NULL THEN THIS ENTRY IS PUT IN THE       63600001
*            SUBS/REGION LIST. IF IT IS THEN XMAPSBMS IS SET IN THE     63640001
*            DO MAP ENTRY TO SIGNIFY THAT A SUBS HAS OCCURRED WHICH     63680001
*            WAS NOT CONSIDERED OPTIMISABLE.                            63720001
*            TESTS ARE ALSO MADE TO SEE WHETHER THE ARRAY IS BEING      63760001
*            ASSIGNED TO SINCE IT MAY BE UNSAFE.                        63800001
*                                                                       63840001
*********************************************************************** 63880001
*                                                                       63920001
KGSUBP   IEMKENT  TYPE=2                                                63960001
         LH    GR1,SUBCOUNT            SUBCOUNT=SUBCOUNT-1              64000001
         SH    GR1,H1                                                   64040001
         STH   GR1,SUBCOUNT                                             64080001
         CLI   CURRSUB,NULL                                             64120001
         BNE   SUBP100                 BRANCH IF CURRSUB IS NOT NULL    64160001
         OI    XMAPLOOP,XMAPSBMS       SET BIT IN DO MAP ENTRY TO       64200001
*                                      SIGNIFY THAT A SUBS OCCURRED     64240001
*                                      WHICH WAS NOT SUBSEQUENTLY PUT   64280001
*                                      IN THE SUBS/REGION LIST          64320001
         B     SUBP110                                                  64360001
*                                                                       64400001
* CURRSUB IS NOT NULL, SO MAKE AN ENTRY IN THE SUBS/REGION LIST.        64440001
*                                                                       64480001
SUBP100  MVI   SRGLCODE,XSRGSUBS       SET CODE BYTE                    64520001
         BAL   RR,KGSRGL               MAKE ENTRY                       64560001
         MVI   CURRSUB,NULL            RESET CURRSUB TO NULL            64600001
*                                                                       64640001
* NOW SEE WHETHER ARRAY ELEMENT IS BEING ASSIGNED TO.                   64680001
*                                                                       64720001
SUBP110  OC    SUBCOUNT(2),SUBCOUNT                                     64760001
         BZ    SUBP120                 BRANCH IF SUBS IS NOT NESTED     64800001
         OC    FNCOUNT(2),FNCOUNT                                       64840001
         BZ    SUBPEND                 RETURN IF SUBS IS NESTED BUT     64880001
*                                      NOT WITHIN FUNCTION CALL         64920001
*                                                                       64960001
* SUBS IS BEING ASSIGNED TO SO MAKE AN ENTRY IN USE LIST                65000001
*                                                                       65040001
SUBP120  MVC   USELDREF(2),XTRPOP1                                      65080001
         OI    KGCOD1,ASSFLAG          VBLE ASSIGNED TO                 65120001
         BAL   RR,KGUSEL               CONSIDER FOR ENTRY IN USE LIST   65160001
SUBPEND  IEMKLVE  NORC                                                  65200001
         EJECT                                                          65240001
*                                                                       65280001
*** KGSUBS ************************************************************ 65320001
*                                                                       65360001
* FUNCTION - TO PROCESS SUBS TRIPLE.                                    65400001
*                                                                       65600001
*********************************************************************** 65640001
*                                                                       65680001
KGSUBS   IEMKENT  TYPE=2                                                65720001
         LH    GR1,SUBCOUNT            SUBCOUNT=SUBCOUNT+1              65760001
         LA    GR1,1(GR1)                                               65800001
         STH   GR1,SUBCOUNT                                             65840001
         MVC   PAR1+2(2),XTRPOP1                                        65880001
         L     LR,ZDRFAB               ACCESS DICT ENTRY OF ARRAY       65920001
         BALR  RR,LR                                                    65960001
         L     DRFR,PAR1                                                66000001
         MVI   CURRSUB,NULL            PUT NULL IN CURRSUB              66040001
         TM    XDRFCODE,XDRFSTR                                         66080001
         BNO   SUBSEND                 RETURN IF NOT DATA VARIABLE      66120001
         TM    PRFOPT,XMAPSRON                                          66160001
         BO    SUBSEND                 RETURN IF SUBSCRIPTRANGE ENABLED 66200001
*                                                                       66240001
* SINCE ARRAY SATISFIES CONDITIONS, PUT CURRENT TEXT REFERENCE IN       66280001
* CURRSUB.                                                              66320001
*                                                                       66360001
         MVC   CURRSUB(3),CURRTEXT     MOVE INTO CURRSUB                66400001
SUBSEND  IEMKLVE  NORC                                                  66440001
         EJECT                                                          66480001
*                                                                       66520001
*** KGTITL ************************************************************ 66560001
*                                                                       66600001
* FUNCTION - TO PROCESS THE FOLLOWING TRIPLES:-                         66640001
*              TITLE,PAGESIZE,LINESIZE,FROM,IGNORE,LINE,CAT,OR,AND,     66680001
*              NOT,LE,GE,NE,EQ,GT,LESS,DELAY,LINE,SKIP,COL,A,B,P,R,     66720001
*              X,SKIP                                                   66760001
*                                                                       66800001
*********************************************************************** 66840001
*                                                                       66880001
KGTITL   IEMKENT TYPE=2                                                 66920001
         BAL   RR,KGOTST               CALL ROUTINE TO DETERMINE        66960001
*                                      WHETHER ON-UNITS COULD BE        67000001
*                                      ENTERED FROM THIS TRIPLE.        67040001
         BAL   RR,KGRFCV               CKECK FOR REFERENCES TO THE CV   67080001
TITLEND  IEMKLVE NORC                                                   67120001
         EJECT                                                          67160001
*                                                                       67200001
*** KGUSEL ************************************************************ 67240001
*                                                                       67280001
* FUNCTION - GIVEN A TRIPLE OPERAND, TO CONSIDER THE VARIABLE FOR ENTRY 67320001
*            INTO THE USE LIST, AND IF THE VARIABLE IS BEING ASSIGNED   67360001
*            TO,TO MAKE AN ENTRY IN THE SUBS/REGION LIST.               67400001
*                                                                       67440001
*********************************************************************** 67480001
*                                                                       67520001
KGUSEL   IEMKENT  TYPE=2                                                67560001
         OC    USELDREF(2),USELDREF                                     67600001
         BZ    USELEND                 RETURN IF TEMPORARY              67640001
*                                                                       67680001
* CHECK THAT VARIABLE IS NOT ALREADY IN THE USE LIST.                   67720001
*                                                                       67760001
         CLI   XMAPUSEL,NULL                                            67800001
         BE    USEL140                 BRANCH IF NO USE LIST            67840001
       IEMKTAB SET,XLCRUSE,SA=XMAPUSEL SET POINTER TO START OF LIST     67880001
USEL120  DS    0H                                                       67920001
       IEMKTAB SCAN,XLCRUSE,AATO=(USER),ETA=USEL140                     67960001
         CLC   XUSEDREF(2),USELDREF                                     68000001
         BNE   USEL120                 BRANCH IF NO MATCH               68040001
*                                                                       68080001
* VARIABLE IS ALREADY IN USE LIST.                                      68120001
*                                                                       68160001
         TM    KGCOD1,ASSFLAG                                           68200001
         BNO   USELEND                 RETURN IF VARIABLE IS NOT BEING  68240001
*                                      ASSIGNED TO                      68280001
         CLC   XMAPCVDR(2),USELDREF                                     68320001
         BNE   USEL130                 BRANCH IF NOT CONTROL VARIABLE   68360001
         OI    XMAPLOOP,XMAPATCV       ASSIGNMENT TO CONTROL VBLE       68400001
         NI    XMAPSPEC,XMAPSTLD       LOAD AND STORE OF CV REQUIRED    68440001
USEL130  TM    XUSECODE,XUSEUNSF                                        68480001
         BO    USEL190                 BRANCH IF UNSAFE                 68520001
         OI    XUSECODE,XUSEASSN       CHANGE CODE BYTE                 68560001
*                                                                       68600001
* NOW MAKE AN ENTRY IN THE SUBS/REGION LIST                             68640001
*                                                                       68680001
         MVI   SRGLCODE,XSRGSAFE       PARTIAL SAFE BOUNDARY            68720001
         BAL   RR,KGSRGL                                                68760001
         B     USELEND                                                  68800001
*                                                                       68840001
* VARIABLE IS NOT IN USE LIST - SEE WHETHER ENTRY MUST BE MADE          68880001
*                                                                       68920001
USEL140  MVC   PAR1+2(2),USELDREF                                       68960001
         L     LR,ZDRFAB               ACCESS DICTIONARY ENTRY          69000001
         BALR  RR,LR                                                    69040001
         L     DRFR,PAR1                                                69080001
         TM    XDRFCODE,XDRFDVBL                                        69120001
         BO    USEL150                 BRANCH IF DATA VARIABLE          69160001
         TM    XDRFCODE,XDRFSTR                                         69200001
         BNO   USELEND                 RETURN IF NOT STRUCTURE          69240001
         CLI   XDRFCODE,XDRFLBCD                                        69280001
         BE    USELEND                 RETURN IF LABEL BCD              69320001
*                                                                       69360001
* CODE BYTE IS O.K.                                                     69400001
*                                                                       69440001
USEL150  TM    KGCOD1,ASSFLAG                                           69480001
         BO    USEL170                 BRANCH IF VARIABLE ASSIGNED TO   69520001
         TM    KGCOD1,USEFLAG                                           69560001
         BZ    USELEND                 RETURN IF NO USE LIST TO BE      69600001
*                                      CONSTRUCTED                      69640001
         BAL   RR,KGNICE               CHECK DICT REF                   69680001
         LTR   RC,RC                                                    69720001
         BZ    USELEND                 RETURN IF VBLE IS NOT REAL FIXED 69760001
*                                      BINARY SCALAR INTEGER            69800001
         TM    XDRFOTH3,XDRFUNSF                                        69840001
         BO    USEL160                 BRANCH IF UNSAFE                 69880001
*                                                                       69920001
* MAKE AN ENTRY IN USE LIST WITH UNSAFE BIT OFF.                        69960001
*                                                                       70000001
         MVI   USELCODE,XUSESAFE       SPECIFY TYPE OF ENTRY            70040001
         BAL   RR,KGUSEN               MAKE AN ENTRY IN THE USE LIST    70080001
         B     USELEND                                                  70120001
*                                                                       70160001
* VARIABLE IS UNSAFE, ONLY MAKE ENTRY IF XMAPATUV IS OFF  I.E. THERE    70200001
* HAVE NOT BEEN ANY ASSIGNMENTS TO UNSAFE VARIABLES.                    70240001
*                                                                       70280001
USEL160  TM    XMAPLOOP,XMAPATUV                                        70320001
         BO    USELEND                 RETURN IF THERE HAS BEEN AN      70360001
*                                      ASSIGNMENT TO AN UNSAFE          70400001
*                                                                       70440001
* MAKE AN ENTRY WITH THE UNSAFE BIT ON.                                 70480001
*                                                                       70520001
         MVI   USELCODE,XUSEUNSF       SPECIFY TYPE OF ENTRY            70560001
         BAL   RR,KGUSEN               MAKE ENTRY                       70600001
         B     USELEND                                                  70640001
*                                                                       70680001
* VARIABLE HAS BEEN ASSIGNED TO - MAKE ENTRIES IN USE AND SUBS/REGION   70720001
* LISTS                                                                 70760001
*                                                                       70800001
USEL170  CLC   XMAPCVDR(2),USELDREF                                     70840001
         BNE   USEL180                 BRANCH IF NOT CONTROL VARIABLE   70880001
         OI    XMAPLOOP,XMAPATCV       ASSIGNMENT TO CONTROL VARIABLE   70920001
         NI    XMAPSPEC,XMAPSTLD       LOAD AND STORE OF CV REQUIRED    70960001
USEL180  TM    XDRFCODE,XDRFDVBL                                        71000001
         BNO   USEL205                 BRANCH IF A STRUCTURE            71040001
         TM    XDRFOTH3,XDRFUNSF                                        71080001
         BNO   USEL210                 BRANCH IF SAFE                   71120001
*                                                                       71160001
* VARIABLE IS UNSAFE AND IS BEING ASSIGNED TO. IF THIS IS THE FIRST     71200001
* TIME THIS HAS OCCURRED, THEN ALL UNSAFES MUST BE DELETED FROM THE     71240001
* USE LIST AND XMAPATUV SET TO ONE.                                     71280001
*                                                                       71320001
USEL190  TM    XMAPLOOP,XMAPATUV                                        71360001
         BO    USEL200                 BRANCH IF THERE HAS ALREADY BEEN 71400001
*                                      AN ASSIGNMENT TO AN UNSAFE       71440001
         BAL   RR,KGDELU               DELETE UNSAFES FROM USE LIST     71480001
USEL200  MVI   SRGLCODE,XSRGUNSF       SPECIFY CODE                     71520001
         BAL   RR,KGSRGL               MAKE AN UNSAFE ENTRY IN SUBS/    71560001
*                                      REGION LIST                      71600001
         B     USELEND                 RETURN                           71640001
*                                                                       71680001
* VARIABLE IS A STRUCTURE AND IS BEING ASSIGNED TO .                    71720001
* ASSUME  ALL VARIABLES ASSIGNED TO AT THIS POINT.                      71760001
*                                                                       71800001
USEL205  MVI   SRGLCODE,XSRGGLBL       MARK A GLOBAL REGION BOUNDARY    71840001
         BAL   RR,KGSRGL                  AT THIS POINT                 71880001
         BAL   RR,KGDELT               DELETE NON COMPILER-CREATED      71920001
*                                      TEMPS FROM THE USE LIST          71960001
         NI    XMAPSPEC,XMAPSTLD       STORE AND LOAD OF CV REQUIRED    72000001
*                                                                       72040001
* IF VARIABLE IS A NORMAL REAL FIXED BINARY SCALAR INTEGER THEN ENTRIES 72080001
* ARE MADE IN USE AND SUBS/REGION LISTS                                 72120001
*                                                                       72160001
USEL210  BAL   RR,KGNICE                                                72200001
         LTR   RC,RC                                                    72240001
         BZ    USELEND                 RETURN IF NOT 'NICE'             72280001
*                                                                       72320001
*                                                                       72360001
         MVI   SRGLCODE,XSRGSAFE                                        72400001
         BAL   RR,KGSRGL               MAKE ENTRY IN SUBS/REGION LIST   72440001
*                                                                       72480001
         TM    KGCOD1,USEFLAG                                           72520001
         BZ    USELEND                 RETURN IF NO USE LIST TO BE      72560001
*                                      CONSTRUCTED                      72600001
         MVI   USELCODE,XUSEASSN                                        72640001
         BAL   RR,KGUSEN               MAKE AN ENTRY IN THE USE LIST    72680001
*                                                                       72720001
USELEND  NI    KGCOD1,X'FF'-ASSFLAG    TURN OFF ASSFLAG                 72760001
       IEMKTAB DEACT,XLCRUSE           DEACTIVATE USE LIST              72800001
         IEMKLVE  NORC                                                  72840001
         EJECT                                                          72880001
*                                                                       72920001
*** KGUSEN ************************************************************ 72960001
*                                                                       73000001
* FUNCTION - TO MAKE AN ENTRY IN THE USE LIST AND IF NECESSARY INSERT   73040001
*            A HEADER CHAIN IN THE DO MAP ENTRY.                        73080001
*                                                                       73120001
*********************************************************************** 73160001
*                                                                       73200001
KGUSEN   IEMKENT  TYPE=2                                                73240001
         CLI   USELCODE,XUSELEND                                        73280001
         BE    USEN090                 BRANCH IF END OF LIST ENTRY      73320001
         CLI   XDRFCODE,XDRFTEMP                                        73360001
         BNE   USEN080                 BRANCH IF NOT TEMP               73400001
         TM    XDRFOTH2,XDRFPARM                                        73440001
         BO    USEN080                 BRANCH IF FORMAL PARAMETER       73480001
         OI    USELCODE,XUSECTMP       SET COMPILER TEMP BIT            73520001
         B     USEN090                                                  73560001
USEN080  TM    XMAPLOOP,XMAPOCTS                                        73600001
         BO    USENEND                 RETURN IF ONLY COMPILER TEMPS    73640001
*                                      ALLOWED IN THE USE LIST          73680001
USEN090  CLI   XMAPUSEL,NULL                                            73720001
         BNE   USEN100                 BRANCH IF NOT 1ST ENTRY IN LIST  73760001
       IEMKTAB BLDC,XLCRUSE,USELBUFF,SATO=XMAPUSEL MAKE ENTRY AND CHAIN*73800001
                                       OFF DO MAP ENTRY                 73840001
         B     USENEND                                                  73880001
USEN100  DS    0H                                                       73920001
       IEMKTAB BLDC,XLCRUSE,USELBUFF   MAKE ENTRY                       73960001
USENEND  DS    0H                                                       74000001
       IEMKTAB DEACT,XLCRUSE           DEACTIVATE USE LIST              74040001
         IEMKLVE  NORC                                                  74080001
         EJECT                                                          74120001
*                                                                       74160001
** FLAGS AND CONSTANTS USED BY THIS PHASE ONLY.                         74200001
*                                                                       74240001
FSAVE    DC    F'0'                                                     74280001
USTKEND  DC    F'0'                    ADDRESS OF END OF USE STACK      74320001
CURRSTK  DC    F'0'                    CURRENT POINTER TO ITDO'/PROC'   74360001
*                                      STACK                            74400001
MATRIX   DC    20F'0'                  ARRAY OF MASKS FOR EACH ON-      74440001
*                                      CONDITION                        74480001
H1       DC    H'1'                                                     74520001
H3       DC    H'3'                                                     74560001
*                                                                       74600001
SUBCOUNT DC    H'0'                    CURRENT DEPTH OF SUBS NESTING    74640001
FNCOUNT  DC    H'0'                    CURRENT DEPTH OF FNC NESTING     74680001
CVCOUNT  DC    H'0'                    COUNT OF OCCURRENCES OF CV       74720001
*                                      WITHIN SUBS LISTS                74760001
*                                                                       74800001
CURRDO   DC    XL3'00'                 TEXT REF OF CURRENT DO MAP ENTRY 74840001
CURRSUB  DC    XL3'00'                 TEXT REF OF SUBS TRIPLE          74880001
*                                                                       74920001
FNSTK    DC    F'0'                    ADDRESS OF CURRENT ENTRY IN      74960001
*                                      FUNCTION COMA STACK              75000001
FNSTKEND DC    F'0'                    ADDRESS OF END OF FUNCTION COMA  75040001
*                                      STACK                            75080001
SRGLBUFF EQU   *                                                        75120001
SRGLCODE DC    X'00'                                                    75160001
SRGLTEXT DC    XL3'00'                                                  75200001
SRGLDREF DC    XL2'00'                                                  75240001
PREVCODE DC    X'00'                                                    75280001
CURRTEXT DC    XL3'00'                                                  75320001
*                                                                       75360001
USELBUFF DC    XL3'00'                 ENTRY FOR USE LIST               75400001
USELCODE EQU   USELBUFF                CODE                             75440001
USELDREF EQU   USELCODE+1              DICT REF                         75480001
WORK     DC    X'00'                   TEMP WORK SPACE FOR CODE   30372 75490020
*                                      BYTE GIVING DETAILS OF LOOP      75500020
*                                                                       75520001
KGCOD1   DC    X'00'                   CODE BYTE SIGNIFYING -           75560001
FNCMFLAG EQU   X'01'                                                    75600001
GETFLAG  EQU   X'02'                                                    75640001
LABFND   EQU   X'40'                   LABEL FOUND WITHIN LOOP          75660001
USEFLAG  EQU   X'80'                   USE LIST TO BE CONSTRUCTED       75680001
ASSFLAG  EQU   X'20'                   VARIABLE IS BEING ASSIGNED TO    75720001
FNSTFLAG EQU   X'10'                   ON IF FUNCTION COMA STACK HAS    75760001
*                                      OVERFLOWED                       75800001
*                                                                       75840001
DMAPBUFF DC    (XMAPEND-XMAP)X'00'     BUFFER FOR CURRENT DO MAP ENTRY  75880001
*                                                                       75920001
ONCODES  DC    X'D0D2D4D6D8DEE0E2'                                      75960001
         DC    X'E4F8F0E6EADCECF2'                                      76000001
         DC    X'E8F4EEE5'                                              76040001
         EJECT                                                          76080001
*                  OUZFSSCSACCEEFKNRTUP                                 76120001
*                  FFDFBZOTRHNNNIEMERNN                                 76160001
*                  LLVLGENGEKDFPNYECNFG                                 76200001
         DS    0F                                                       76220001
PRFOPT   DC    BL3'000000001111111111111111' PREFIX OPTIONS MASK        76240001
ONTEST   DC    F'0'                    AREA FOR TESTING INTERRUPT MASKS 76280001
ATNVONUS DC    F'0'                    MASK CONTAINING ONE-BITS FOR     76300001
*                                      EACH ON-UNIT CONTAINING AN       76320001
*                                      ASSIGNMENT TO A NICE VARIABLE    76340001
LOOPONUS DC    F'0'                    CONDITIONS WHICH BE RAISED       76360001
*                                      WITHIN AN INNERMOST LOOP         76380001
GTLVONUS DC    F'0'                    ON-UNITS WITH GO TO LABEL VBLE   76400001
LABCONUS DC    F'0'                    ON-UNITS WHICH BRANCH TO LABEL   76420001
*                                      CONSTS IN THIS LOOP              76440001
*                                                                       76460001
* TRIPLE MASKS                                                          76480001
*                                                                       76500001
TRPMSK   DC    BL4'00'                 THIS SLOT IS USED FOR I/O STMTS  76520001
         DC    BL3'111101100000000000000000' PAGESIZE,LINESIZE,IGNORE,  76560001
*                                      LINE,CAT,OR,AND,NOT,LE,GE,NE,EQ, 76600001
*                                      GT,LESS,DELAY,LINE,SKIP,COL,A,   76640001
*                                      B,P,R,X,SKIP,TITLE,FROM          76680001
         DC    X'00'                                                    76720001
         DC    BL3'111101100000000000000000' FNCM                       76760001
         DC    X'00'                                                    76800001
         DC    BL3'111101100000000000000000' KEYTO                      76840001
         DC    X'00'                                                    76880001
         DC    BL3'111101100000000000000000' KEY,KEYFROM                76920001
         DC    X'00'                                                    76960001
         DC    BL3'111101100000000000000000' PLUS,MINUS,MULT            77000001
         DC    X'00'                                                    77040001
         DC    BL3'111101100000000000000000' PRF-,PRF+                  77080001
         DC    X'00'                                                    77120001
         DC    BL3'111101100000000000000000' ASSI,MTAS,MSA,MTA,BUY ASSI 77160001
         DC    X'00'                                                    77200001
         DC    BL3'111111100000000000000000' COMA(SUBS)                 77240001
         DC    X'00'                                                    77280001
         DC    BL3'111101100000000000000000' DIVIDE,EXP                 77320001
         DC    X'00'                                                    77360001
         DC    BL3'000000001000000000000000' IN                         77400001
         DC    X'00'                                                    77440001
         DC    BL3'000000000000010000000000' EXIT,STOP                  77480001
         DC    X'00'                                                    77520001
         DC    BL3'000000000000000000100000' OPEN,CLOSE                 77560001
         DC    X'00'                                                    77600001
         DC    BL3'000000000000100001100000' COPY,REPLY                 77640001
         DC    X'00'                                                    77680001
         DC    BL3'111101100000100001100000' PUT                        77720001
         DC    X'00'                                                    77760001
         DC    BL3'111101100001000101100000' GET                        77800001
         DC    X'00'                                                    77840001
         DC    BL3'000000000001001011110000' READ                       77880001
         DC    X'00'                                                    77920001
         DC    BL3'000000000000001011100000' WRITE,LOCATE,REWRITE,      77960001
*                                      DELETE                           78000001
         DC    X'00'                                                    78040001
         DC    BL3'000000000001001011110000' WAIT                       78080001
         DC    X'00'                                                    78120001
         EJECT                                                          78160001
KGTAB    EQU   *                                                        78200001
         DC    4X'00'                                                   78240001
         DC    X'04'         04        TITLE                            78280001
         DC    X'00'                                                    78320001
         DC    X'04'         06        PAGESIZE                         78360001
         DC    X'00'                                                    78400001
         DC    X'04'         08        LINESIZE                         78440001
         DC    X'00'                                                    78480001
         DC    X'0C'         0A        INTO                             78520001
         DC    X'04'         0B        FROM                             78560001
         DC    X'0C'         0C        SET                        54726 78600064
         DC    X'10'         0D        KEY                              78640001
         DC    X'00'                                                    78680001
         DC    X'04'         0F        IGNORE                           78720001
         DC    4X'00'                                                   78760001
         DC    X'5C'         14        DATA                             78800001
         DC    X'0C'         15        STRING                           78840001
         DC    X'04'         16        SKIP                             78880001
         DC    X'04'         17        LINE                             78920001
         DC    X'00'                                                    78960001
         DC    X'34'         19        COPY                             79000001
         DC    X'0C'         1A        KEYTO                            79040001
         DC    2X'00'                                                   79080001
         DC    X'28'         1D        IN                               79120001
         DC    X'10'         1E        KEYFROM                          79160001
         DC    X'88'         1F        FORMAT LIST                      79200001
         DC    5X'00'                                                   79240001
         DC    X'34'         25        COPY                             79280001
         DC    2X'00'                                                   79320001
         DC    X'1C'         28        MSA                              79360001
         DC    X'1C'         29        MTA                              79400001
         DC    13X'00'                                                  79440001
         DC    X'1C'         37        BUY ASSIGN                       79480001
         DC    2X'00'                                                   79520001
         DC    X'64'         3A        PSEUDO-VBLE                      79560001
         DC    X'00'                                                    79600001
         DC    X'64'         3C        FUNCTION                         79640001
         DC    X'00'                                                    79680001
         DC    X'8C'         3E        SUBS                             79720001
         DC    2X'00'                                                   79760001
         DC    X'20'         41        COMMA                            79800001
         DC    X'08'         42        FNCM                             79840001
         DC    4X'00'                                                   79880001
         DC    X'1C'         47        ASSI                             79920001
         DC    X'00'                                                    79960001
         DC    X'04'         49        CAT                              80000001
         DC    X'00'                                                    80040001
         DC    X'04'         4B        OR                               80080001
         DC    X'00'                                                    80120001
         DC    X'04'         4D        AND                              80160001
         DC    X'00'                                                    80200001
         DC    X'04'         4F        NOT                              80240001
         DC    7X'00'                                                   80280001
         DC    X'1C'         57        MTAS                             80320001
         DC    7X'00'                                                   80360001
         DC    X'88'         5F        FORMAT LIST'                     80400001
         DC    X'00'                                                    80440001
         DC    X'6C'         61        DOEQ                             80480001
         DC    3X'00'                                                   80520001
         DC    X'04'         65        LESS/EQUAL                       80560001
         DC    X'00'                                                    80600001
         DC    X'04'         67        GT/EQUAL                         80640001
         DC    X'00'                                                    80680001
         DC    X'04'         69        NOT EQUAL                        80720001
         DC    X'00'                                                    80760001
         DC    X'04'         6B        EQUAL                            80800001
         DC    X'00'                                                    80840001
         DC    X'04'         6D        GREATER                          80880001
         DC    X'00'                                                    80920001
         DC    X'04'         6F        LESS                             80960001
         DC    3X'00'                                                   81000001
         DC    X'14'         73        MINUS                            81040001
         DC    X'00'                                                    81080001
         DC    X'14'         75        PLUS                             81120001
         DC    X'00'                                                    81160001
         DC    X'24'         77        DIVIDE                           81200001
         DC    X'00'                                                    81240001
         DC    X'14'         79        MULT                             81280001
         DC    X'60'         7A        PSEUDO-VBLE'                     81320001
         DC    X'18'         7B        PRF-                             81360001
         DC    X'60'         7C        FNC'                             81400001
         DC    X'18'         7D        PRF+                             81440001
         DC    X'7C'         7E        SUB'                             81480001
         DC    X'24'         7F        EXP                              81520001
         DC    X'6C'         80        TO                               81560001
         DC    X'0C'         81        ALLOCATE                         81600001
         DC    X'6C'         82        BY                               81640001
         DC    X'0C'         83        FREE                             81680001
         DC    X'58'         84        WHILE                      35243 81700042
         DC    4X'00'                                             35243 81720042
         DC    X'48'         89        WAIT                             81760001
         DC    X'00'                                                    81800001
         DC    X'04'         8B        DELAY                            81840001
         DC    X'0C'         8C        CV                               81880001
         DC    X'2C'         8D        EXIT                             81920001
         DC    X'00'                                                    81960001
         DC    X'2C'         8F        STOP                             82000001
         DC    X'04'         90        LINE                             82040001
         DC    3X'00'                                                   82080001
         DC    X'04'         94        SKIP                             82120001
         DC    X'00'                                                    82160001
         DC    X'04'         96        COLUMN                           82200001
         DC    X'90'         97        SIGNAL                           82240001
         DC    8X'00'                                                   82280001
         DC    X'04'         A0        A                                82320001
         DC    X'00'                                                    82360001
         DC    X'04'         A2        B                                82400001
         DC    X'70'         A3        RETN                       31190 82440020
         DC    X'04'         A4        P                                82480001
         DC    X'70'         A5        GOOB                             82520001
         DC    X'54'         A6        R                                82560001
         DC    X'70'         A7        GOTO                             82600001
         DC    6X'00'                                                   82660001
         DC    X'04'         AE        X                                82720001
         DC    4X'00'                                                   82760001
         DC    X'68'         B3        PROC                             82800001
         DC    X'00'                                                    82840001
         DC    X'54'         B5        BEGIN                            82880001
         DC    X'00'                                                    82920001
         DC    X'68'         B7        ITDO                             82960001
         DC    4X'00'                                                   83000001
         DC    X'74'         BC        SN2                              83040001
         DC    2X'00'                                                   83060001
         DC    X'88'         BF        FORMAT                           83080001
         DC    X'6C'         C0        TO'                              83120001
         DC    X'00'                                                    83160001
         DC    X'6C'         C2        BY'                              83200001
         DC    4X'00'                                                   83240001
         DC    X'44'         C7        WRITE                            83280001
         DC    X'00'                                                    83320001
         DC    X'40'         C9        READ                             83360001
         DC    X'00'                                                    83400001
         DC    X'44'         CB        LOCATE                           83440001
         DC    4X'00'                                                   83480001
         DC    X'74'         D0        STNO                             83520001
         DC    X'58'         D1        CLN1                             83560001
         DC    X'78'         D2        STLB                             83600001
         DC    X'58'         D3        CLN2                             83640001
         DC    X'74'         D4        CN                               83680001
         DC    X'3C'         D5        GET                              83720001
         DC    X'00'                                                    83760001
         DC    X'38'         D7        PUT                              83800001
         DC    3X'00'                                                   83840001
         DC    X'44'         DB        REWRITE                          83880001
         DC    X'00'                                                    83920001
         DC    X'30'         DD        OPEN                             83960001
         DC    X'00'                                                    84000001
         DC    X'30'         DF        CLOSE                            84040001
         DC    17X'00'                                                  84080001
         DC    X'94'         F1        END I/O                          84120001
         DC    X'00'                                                    84160001
         DC    X'98'         F3        PROC'                            84200001
         DC    X'00'                                                    84220001
         DC    X'50'         F5        BEGIN'                           84240001
         DC    X'00'                                                    84260001
         DC    X'98'         F7        ITDO'                            84280001
         DC    7X'00'                                                   84300001
         DC    X'88'         FF        FORMAT'                          84320001
*                                                                       84340001
         EJECT                                                          84480001
         LTORG                                                          84520001
         END                                                            84560001
