KJ       TITLE 'IEMKJ, LOOP CONTROL EXAMINATION AND SUBS TABLE BUILD.  X00000301
               OS/360  PL/1 F COMPILER.'                                00000601
*        SEE END OF COMMENTS FOR APARS FIXED IN THIS MODULE             00000800
*********************************************************************** 00001000
*                                                                     * 00001201
*                                                                     * 00001501
*              FUNCTIONS - (1) SCAN DO LOOP SPECS IN TEXT IDENTIFIED  * 00001801
*        BY SUCCESSIVE DO MAP TABLE ENTRIES.                          * 00002101
*                                                                     * 00002401
*                          (2) SCAN SUBSCRIPT EXPRESSIONS IN TEXT     * 00002701
*        IDENTIFIED BY ENTRIES IN THE SUBS/REGN LIST ATTACHED TO THE  * 00003001
*        SUCCESSIVE DO MAP TABLE ENTRIES.                             * 00003301
*                                                                     * 00003601
*                                                                     * 00003901
*                                                                     * 00004201
*              ENTRY POINT - 'IEMKJ' FROM COMPILER CONTROL TO START   * 00004501
*        PHASE.                                                       * 00004801
*                                                                     * 00005101
*                                                                     * 00005401
*                                                                     * 00005701
*              INPUT - TEXT IN FORM OF TRIPLES.  SEVERAL TABLES ARE   * 00006001
*        ALSO REQUIRED:-                                              * 00006301
*                       (1)  DO MAP - PRODUCED BY IEMKE; CONTROLS     * 00006601
*        THE ORDER OF PROCESSING.                                     * 00006901
*                                                                     * 00007201
*                       (2)  SUBS/REGN LIST - PRODUCED BY IEMKG.  THE * 00007501
*        REGION ENTRIES ARE TRANSFERED UNALTERED TO THE SUBS TABLE:   * 00007801
*        THE SUBS ENTRIES POINT TO SUBSCRIPT EXPRESSIONS TO BE        * 00008101
*        EXAMINED.                                                    * 00008401
*                                                                     * 00008701
*                       (3)  USE LIST - CREATED BY IEMKG.  USED IN    * 00009001
*        ANALYSING THE SUBSCRIPT EXPRESSIONS.                         * 00009301
*                                                                     * 00009601
*                                                                     * 00009901
*                                                                     * 00010201
*              OUTPUT - INPUT TEXT IS SLIGHTLY MODIFIED IN SITU.  NEW * 00010501
*        DICTIONARY ENTRIES FOR CONSTANTS USED IN THE LOOP SPEC. MAY  * 00010801
*        BE CREATED, OTHERWISE THE PRESENT ENTRIES WILL HAVE THEIR    * 00011101
*        TARGET DED'S SET.  THE SUBS TABLE IS CREATED AND THE SUBS/   * 00011401
*        REGN LIST DELETED.                                           * 00011701
*                                                                     * 00012001
*                                                                     * 00012301
*                                                                     * 00012601
*              EXTERNAL ROUTINES - (1) CONTROL PHASES.  THE FOLLOWING * 00012901
*        ENTRIES ARE USED - 'RLSCTL','ZDICRF','ZDRFAB','ZTXTAB'.      * 00013201
*                                                                     * 00013501
*                                  (2) TABLE HANDLING (IEMKA).  THE   * 00013801
*        FOLLOWING ENTRIES ARE USED - 'KAHBLD','KAHDAC','KAHERR',     * 00014101
*        'KAHFRE','KAHMDR','KAHSCN','KAHSET','KAHTXT'.                * 00014401
*                                                                     * 00014701
*                                                                     * 00015001
*                                                                     * 00015301
*              EXIT - NORMAL - 'RLSCTL' IN CONTROL PHASE TO RELEASE   * 00015601
*        PHASE AND LOAD NEXT.                                         * 00015901
*                                                                     * 00016201
*                                                                     * 00016501
*              EXIT - ERROR - 'KAHERR' IF AN ERROR OCCURS DURING TEXT * 00016801
*        SCAN OR TABLE HANDLING.  TERMINAL MESSAGE IEM1224I IS GIVEN. * 00017101
*                                                                     * 00017401
*                                                                     * 00017701
*                                                                     * 00018001
*              ATTRIBUTES - THIS PHASE IS NOT READ-ONLY AND IS        * 00018301
*        THEREFORE NOT REENTRANT                                      * 00018601
*                                                                     * 00018901
*                                                                     * 00019201
*                                                                     * 00019501
*              NOTES - (1) THIS PHASE REQUIRES THE 'IEMK' MACROS FOR  * 00019801
*        ASSEMBLY.                                                    * 00020101
*                                                                     * 00020401
*                      (2) THIS PHASE CONSITS OF 2 CONTROL SECTIONS   * 00020701
*        - 'IEMKJ' AND 'IEMKJ1'.                                      * 00021001
*                                                                     * 00021301
*                      (3) REGISTER USAGE WITHIN THIS PHASE IS        * 00021601
*        DEFINED IMMEDIATELY PRIOR TO THE FIRST CSECT 'IEMKJ'.        * 00021901
*                                                                     * 00022201
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*KJ 000-TSS 00022319
*        ----------------------------------------------------KJ 000-TSS 00022419
         EJECT                                                          00022501
*              GENERAL DESCRIPTION OF PHASE                           * 00022801
*                                                                     * 00023101
*                                                                     * 00023401
*                                                                     * 00023701
*        THIS PHASE CONSISTS OF TWO LOGICAL SECTIONS. THE FIRST       * 00030401
*   SECTION EXAMINES THE 'INITIAL','STEP' AND 'LIMIT' TO DECIDE       * 00030601
*   WHETHER OR NOT BXLE/BXH LOOP CONTROL CODE CAN BE USED.  THE       * 00030801
*   SECOND SECTION PROCESSES THE SUBS/REGN LIST CREATED BY PHASE KG,  * 00031001
*   EXAMINING THE SUBSCRIPT EXPRESSIONS LISTED AND DECIDES WHAT       * 00031201
*   OPTIMISATION, IF ANY, CAN BE APPLIED BY THE FOLLOWING PHASES.     * 00031401
*   THIS INFORMATION IS STORED IN THE SUBS REGION TABLE.              * 00031601
*                                                                     * 00031701
*        ALL PROCESSING IS DONE IN DO MAP ORDER  I.E. FOR EACH DO MAP * 00031801
*   ENTRY, STARTING WITH THAT ENTRY POINTED TO BY 'XLCRFMAP' AND      * 00032001
*   FOLLOWING THE CHAIN IN 'XMAPSEQU', THE FOLLOWING OPERATIONS ARE   * 00032201
*   PERFORMED.                                                        * 00032401
*                                                                     * 00032501
*        IF THE CURRENT 'XMAPLEVL' IS EQUAL TO 0 (I.E. THIS DO MAP    * 00032601
*   ENTRY IS FOR A PROC) THE FOLLOWING LOOP CONTROL TESTS ARE         * 00032801
*   BYPASSED AND PROCESSING CONTINUES WITH THE SECOND SECTION.        * 00033001
*                                                                     * 00033101
* 1.     MOST OF THE PROCESSING OF THE LOOP CONTROL MECHANISM IS      * 00033201
*   CONTAINED IN THE SUBROUTINE 'KJSRBXCH'.                           * 00033401
*                                                                     * 00033601
*        THIS ROUTINE SETS UP THE NUMBER OF SYNDX REGISTERS AVAILABLE * 00033801
*   FOR THIS LOOP AND STORES THIS VALUE IN THE APPROPRIATE SLOT IN    * 00034001
*   THE DO MAP ENTRY.  THE TEXT AND DICTIONARY REFERENCES OF THE      * 00034201
*   ITERATIVE SPECIFICATION ARE ALSO LOADED INTO SLOTS IN THE DO MAP  * 00034401
*   ENTRY.                                                            * 00034601
*                                                                     * 00034701
*        TO PERMIT BXLE/BXH CODE TO BE CREATED THE 'STEP' AND 'LIMIT' * 00034801
*   OF THE LOOP ARE CHECKED TO SEE IF THEY SATISFY THE REQUIRED       * 00035001
*   CONDITIONS.  THE OPERANDS OF THE ITERATIVE SPECIFICATION TRIPLES  * 00035201
*   IN THE TEXT ARE MODIFIED TO TRANSMIT THE RESULTS OF THESE TESTS   * 00035401
*   TO FOLLOWING PHASES.  A FLAG, 'XOPTNKBX' IS ALSO SET IN THE       * 00035601
*   DO MAP ENTRY IF THIS LOOP IS NOT OPTIMISABLE.                     * 00035801
*                                                                     * 00035901
*        IF, ON EXIT FROM 'KJSRBXCH' 'XOPTNKBX'IS SET ON CONTROL      * 00036001
*   PASSES TO THE SECOND SECTION OMITTING THE FURTHER TESTS ON THE    * 00036201
*   'INITIAL', 'STEP' AND 'LIMIT'.  THESE FURTHER TESTS CHECK WHETHER * 00036401
*   OR NOT THESE THREE ENTITIES ARE ALL CONSTANT AND IF NOT A FLAG,   * 00036601
*   'XOPTISLC' IS SET TO DENOTE THIS FACT.                            * 00036801
*                                                                     * 00036901
*        IN ADDITION, THE DICTIONARY ENTRY OF EACH CONSTANT USED IS   * 00037001
*   ACCESSED AND EXAMINED.  IF THE TARGET DED IS SET TO THAT REQUIRED * 00037201
*   BY THIS USE OF THE CONSTANT THEN THIS ENTRY IS SATISFACTORY.  IF  * 00037401
*   THE TARGET DED IS NOT SET AT ALL THEN THE REQUIRED DED IS         * 00037601
*   INSERTED AND THE ENTRY MODIFIED TO SHOW THAT THE TARGET DED HAS   * 00037801
*   BEEN SET.  IF HOWEVER THE TARGET DED HAS ALREADY BEEN SET TO A    * 00038001
*   FORMAT OTHER THAN THAT REQUIRED, AND THE NEXT ENTRY IN THE        * 00038201
*   CONSTANTS CHAIN IS NOT SATISFACTORY, A NEW DICTIONARY ENTRY IS    * 00038401
*   CREATED FROM THE CURRENT ENTRY.  THIS NEW ENTRY DIFFERS ONLY IN   * 00038601
*   THE TARGET DED, AND ALSO INCLUDES A COPY OF THE BCD AS THIS IS    * 00038801
*   REQUIRED BY A LATER PHASE.  THIS ENTRY IS INSERTED IN THE         * 00039001
*   CONSTANTS CHAIN NEXT TO THE ORIGINAL ENTRY, AND THE DICTIONARY    * 00039201
*   REFERENCE IN TEXT MODIFIED.                                       * 00039401
*                                                                     * 00039501
*        AS WELL AS HAVING THE TAGET DED SET AS REQUIRED A COPY OF    * 00039601
*   THE BCD MUST BE CONTAINED IN THE DICTIONARY ENTRY.  IF THE        * 00039801
*   DICTIONARY REFERENCE ORIGINALLY GIVEN SHOWS AN ENTRY WITH NO BCD  * 00040001
*   THEN FLAGS 'XOPTISLC' AND 'XOPTNKBX' ARE SET AND NO FURTHER       * 00040201
*   PROCESSING IS ATTEMPTED ON THAT PARTICULAR CONSTANT.              * 00040401
*                                                                     * 00040501
*        THE ABOVE DICT. ENTRY PROCESSING IS CONTAINED IN 'KJSRTDED'. * 00040601
*                                                                     * 00040701
* 2.     THE SECOND SECTION, THE EXAMINATION OF SUBSCRIPT EXPRESSIONS * 00040801
*   CHECKS THE CURRENT DO MAP ENTRY TO SEE IF TRANSFORMATION AND/OR   * 00041001
*   THE MOVING OUT OF INVARIANTS IS POSSIBLE.  IF NOT, FLAGS          * 00041201
*   'KJEXNOIN' AND/OR 'KJEXNOTR', CURRENT THROUGHOUT THE RANGE OF     * 00041401
*   THIS DO MAP ENTRY, ARE SET.  THE FOLLOWING PROCESSING MUST STILL  * 00041601
*   BE CARRIED OUT TO DECIDE WHETHER OR NOT COMMONING CAN BE EFFECTED.* 00041801
*                                                                     * 00041901
*        THE SUBS/REGN LIST IS NOW SCANNED ENTRY BY ENTRY STARTING AT * 00042001
*   THE ADDRESS HELD IN 'XMAPSRGL'.  THIS ADDRESS IS CHANGED TO POINT * 00042201
*   AT THE FIRST ENTRY IN THE NEWLY CREATED SUBS REGION TABLE.        * 00042401
*                                                                     * 00042501
*        FOR EACH 'REGION' ENTRY IN THE LIST, A TABLE 'REGION' ENTRY  * 00042601
*   IS CREATED BY COPYING THE INFORMATION GIVEN INTO AN ENTRY OF A    * 00042801
*   DIFFERENT FORMAT.  THE INFORMATION CONTENT REMAINS UNCHANGED.     * 00043001
*                                                                     * 00043101
*        FOR EACH 'SUBS' ENTRY IN THE LIST A TEXT SCAN IS INITIATED   * 00043201
*   STARTING WITH THE SUBS TRIPLE ADDRESSED IN THE GIVEN SUBS ENTRY.  * 00043401
*   THE DICTIONARY ENTRY OF THE ARRAY, WHOSE REFERENCE IS HELD IN THE * 00043601
*   FIRST OPERAND OF THIS TRIPLE IS ACCESSED AND EXAMINED.  IF THE    * 00043801
*   ARRAY IS:-                                                        * 00044001
*        1     CONTROLLED                                             * 00044201
*        2     UNALIGNED BIT STRING                                   * 00044401
*        3     VARIABLE OR ADJUSTABLE STRING                          * 00044601
*        THEN THE CURRENT LIST 'SUBS' ENTRY IS IGNORED AND FLAG       * 00044801
*   'XMAPSBMS' IS SET TO DENOTE THIS FACT; PROCESSING IS CONTINUED    * 00045001
*   WITH THE SCANNING OF THE SUBS/REGN LIST.  OTHERWISE THE DICT.     * 00045201
*   REFERENCE OF THE DOPE VECTOR AND THE NUMBER OF COMAS FOLLOWING    * 00045401
*   THE SUBS TRIPLE ARE OBTAINED FROM THIS ABOVE DICTIONARY ENTRY.    * 00045601
*   THE DOPE VECTOR DICTIONARY ENTRY IS NOW ACCESSED AND THAT DICT.   * 00045801
*   BLOCK LOCKED IN STORE.  A POINTER, 'KJSBDVML' IS THEN INITIALIZED * 00046001
*   TO POINT TO THE MULTIPLIER OF THE LEFTMOST SUBSCRIPT OF THE ARRAY.* 00046201
*                                                                     * 00046301
*        USING THE COMA COUNT FOUND ABOVE, THE LENGTH OF THE SUBS     * 00046401
*   ENTRY TO BE CREATED IS CALCULATED AND INFORMATION ALREADY KNOWN   * 00046601
*   IS INSERTED.  ANOTHER POINTER, 'GRSCOM', IS SET TO WHERE THE      * 00046801
*   INFORMATION ON THE FIRST COMA EXPRESSION IS TO BE STORED IN THE   * 00047001
*   SUBS ENTRY.  THE INFORMATION IN THE COMAS IS STORED IN REVERSE    * 00047201
*   ORDER, I.E. THE FIRST COMA MET IN TEXT IS REFERED TO LAST IN THE  * 00047401
*   SUBS ENTRY, AND THE LAST COMA MET COMES FIRST.  THIS IS BECAUSE   * 00047601
*   LATER PHASES WISH TO PROCESS THE COMAS FROM RIGHT TO LEFT.        * 00047801
*                                                                     * 00047901
*        THE TEXT SCAN STARTED ABOVE IS NOW CONTINUED TRIPLE BY       * 00048001
*   YRIPLE UNTIL A 'COMA' TRIPLE IS FOUND. TRIPLES WHICH ARE          * 00048201
*   ACCEPTABLE FOR PROCESSING ARE:-                                   * 00048401
*              PRE-,PLUS,MNUS AND MULT.                               * 00048601
*   THE RELEVENT OPERANDS OF THESE TRIPLES ARE EXAMINED TO DECIDE     * 00048801
*   WHETHER OR NOT THIS PARTICULAR COMA EXPRESSION SATISFIES THE      * 00049001
*   CONDITIONS UNDER WHICH AN EXPRESSION CAN BE OPTIMISED.  A         * 00049201
*   MEASURE OF THE COMPLEXITY OF THE EXPRESSION AS A WHOLE IS ALSO    * 00049401
*   OBTAINED WHILE PROCESSING THESE TRIPLES.                          * 00049601
*                                                                     * 00049701
*        IF A DIVD OR PRE+ TRIPLE ARE ENCOUNTERED THIS EXPRESSION CAN * 00049801
*   ONLY BE CONSIDERED FOR COMMONING AND SO A REDUCED EXPRESSION      * 00050001
*   ANALYSIS IS PERFORMED ON THE REMAINING TRIPLES.                   * 00050201
*                                                                     * 00050301
*        IF A TRIPLE OTHER THAN ANY OF THE ABOVE IS ENCOUNTERED THEN  * 00050401
*   THIS COMA EXPRESSION IS MARKED AS UNOPTIMISABLE AND NO FURTHER    * 00050601
*   PROCESSING IS APPLIED TO ANY TRIPLES UNTIL THE COMA TRIPLE.       * 00050801
*                                                                     * 00051001
*        ON REACHING THE COMA TRIPLE AN EXAMINATION IS MADE OF THE    * 00051201
*   RESULTS OF THE SEPARATE TRIPLE TESTS AND EXPRESSION COMPLEXITY    * 00051401
*   AND A CONCLUSION DRAWN AS TO WHAT TYPE OF OPTIMISATION, IF ANY,   * 00051601
*   IS POSSIBLE.  THIS INFORMATION IS THEN ADDED TO THE SUBS ENTRY.   * 00051801
*   IF THE MULTIPLIER IS LESS THAN 15 BITS THEN THIS IS LOADED INTO   * 00052001
*   OPERAND 1 OF THE COMA TRIPLE, OTHERWISE THIS IS SET TO X'FFFF'.   * 00052201
*                                                                     * 00052301
*        IF ANY FURTHER COMAS REMAIN ALL THE POINTERS ARE RESET AND   * 00052401
*   THE ABOVE PROCESSING IS REPEATED.  EACH COMA EXPRESSION IS        * 00052601
*   INDEPENDENT OF ALL THE OTHERS, ONLY THE FLAGS 'KJEXNOIN' AND      * 00052801
*   'KJEXNOTR' REMAINING UNCHANGED.  IF NO MORE COMAS REMAIN THE      * 00053001
*   CREATED SUBS ENTRY IS ADDED TO THE SUBS TABLE; PROCESSING         * 00053201
*   CONTINUES WITH THE SCANNING OF THE SUBS/REGN LIST.                * 00053401
*                                                                     * 00053501
*        AT THE END OF EACH SECTION OF THE SUBS/REGN LIST A TERMINAL  * 00053601
*   ENTRY IS ADDED TO THE SUBS TABLE AND THE NEXT DO.MAP ENTRY        * 00053801
*   ACCESSED AND THE ABOVE PROCESSING REPEATED.                       * 00054001
*                                                                     * 00054101
*        AFTER THE LAST DO MAP ENTRY HAS BEEN PROCESSED THE SUBS/REGN * 00054201
*   LIST IS DELETED AND CONTROL PASSED TO THE NEXT PHASE.             * 00054401
*                                                                     * 00054501
*********************************************************************** 00054601
         EJECT                                                          00054801
*                                                                       00060800
*        THE FOLLOWING APARS HAVE BEEN FIXED IN THIS MODULE             00066800
*                                                                       00072800
* 5.3B C 948072,948120,948348.    REGRESSION FIX FOR A40061.  MAC 49793 00074856
* 5.3A A 190000,609000.                                       MAC 41988 00076856
*      C 214064,465000.                                       MAC 41988 00078856
* 5.3A A 214040,948000.                                       MAC 40061 00080856
* 5.2  A 968100,969800.                                       CDP 31187 00082856
*   NB  THIS FIX TO 31187 WAS ISSUED AS A PTF -80005- TO ONE      31187 00084800
*        CUSTOMER ONLY.  IT HAS NOT BEEN APPLIED IN GENERAL AS IT 31187 00090800
*        WAS CONSIDERED OF ONLY MARGINAL IMPROVEMENT BUT HAS BEEN 31187 00096800
*        INCLUDED HERE AS A COMMENT.                              31187 00102800
*                                                                       00104856
*                                                                       00106856
         SPACE 3                                                        00109821
         MACRO                                                          00113821
&NAME    GETDICT &DICREF,&XDICBSE                                       00118001
*                                                                       00127001
&NAME    MVC   PAR1+2(2),&DICREF .      MOVE DIC.REF.TO PARAM FIELD     00136001
         L     LR,ZDRFAB .              LINK TO ZDRFAB                  00145001
         BALR  RR,LR .                  TO CONVERT DIC.REF. TO ABS      00154001
         L     &XDICBSE,PAR1 .          BASE XDIC DSECT                 00163001
*                                                                       00172001
         MEND                                                           00181001
         EJECT                                                          00190001
         COPY  IEMKCOM                                                  00240001
         COPY  IEMKUTL                                                  00320001
         COPY  IEMKEQU                                                  00410001
         COPY  IEMKDFM                                                  00480001
         COPY  IEMKDRF                                                  00540001
         COPY  IEMKLCR                                                  00620001
         COPY  IEMKMAP                                                  00710001
         COPY  IEMKSRG                                                  00800001
         COPY  IEMKSRT                                                  00900001
         COPY  IEMKTRP                                                  01000001
         COPY  IEMKUSE                                                  01100001
*                                                                       01200001
**       LOCAL EQUATES FOR IEMKJ                                        01300001
*                                                                       01400001
GRBASE   EQU   9                        PROGRAM BASE                    01500001
GRBASE2  EQU   8                        PROG BASE 2                     01550001
GRXUSE   EQU   6                        XUSE BASE  (KJSRUSEL)           01600001
GRXDFM   EQU   3                        XDFM BASE  (KJSRCHKP + MAIN)    01700001
GRSCOM   EQU   3                        XSRTSCOM BASE                   01800001
GROPR    EQU   7                        OPERAND ADDRESS  (KJSRCHKP)     01900001
GRXSRG   EQU   7                        XSRG BASE                       02000001
GRXSRT   EQU   6                        XSRT BASE                       02100001
GRXMAP   EQU   5                        XMAP BASE                       02200001
GRXTRP   EQU   4                        XTRP BASE                       02300001
*                                                                       02400001
GRCCNT   EQU   1                        COMA COUNT REGISTER (TEMPORARY) 02500001
*                                                                       02600001
GRX      EQU   1                        *                               02700001
GRY      EQU   2                        * WORK REGISTERS                02800001
GRZ      EQU   15                       *                               02900001
*                                                                       03000001
*                                                                       03100001
BNO      EQU   14                       BRANCH ON NO ONES               03200001
BNZ      EQU   7                        BRANCH ON NOT ZERO              03300001
*                                                                       03400001
*                                                                       03405001
*                                                                       03410001
XOPTITXT EQU   XMAPITXT                 TEXT REF OF DOEQ TRIPLE         03415001
XOPTSTXT EQU   XMAPSTXT                 TEXT REF OF BY'  TRIPLE         03420001
XOPTLTXT EQU   XMAPLTXT                 TEXT REF OF TO'  TRIPLE         03425001
XOPTCTXT EQU   XMAPCTXT                 TEXT REF OF CV   TRIPLE         03430001
XOPTIREF EQU   XMAPIREF                 DICT REF OF 'INITIAL'           03435001
XOPTSREF EQU   XMAPSREF                 DICT REF OF 'STEP'              03440001
XOPTLREF EQU   XMAPLREF                 DICT REF OF 'LIMIT'             03445001
XOPTLABI EQU   XMAPLABI                 OP2 OF ITD' TRIPLE              03450001
XOPTOPTX EQU   XMAPOPTX                 SWITCH VECTOR FOR PHASES KJ,KN  03455001
XOPTPREF EQU   XMAPITPP                 TEXT REF OF TRIPLE BEFORE ITD'  03460001
XOPTSNDA EQU   XMAPSNDA                 NO OF SNDXS AVAILABLE           03465001
*                                                                       03470001
*                                                                       03475001
XOPTISLC EQU   X'80'                    INIT,STEP,LIMIT NOT ALL CONST   03480001
*                                                                       03485001
         EJECT                                                          03500001
IEMKJ    CSECT                                                          07200001
*                                                                       07300001
         DC    C'KJ'                    MODULE NAME                     07400001
*                                                                       07500001
         IEMKPLR KJ,KJSB,DL=KJZZ,LL=0                                   07600001
KJSB     IEMKENT TYPE=2                                                 07700001
         USING IEMKJ1,GRBASE2           BASE SECOND CSECT               07850001
         USING XLCR,GRLCOM                                              07900001
         USING XSRG,GRXSRG              BASE SUBS/REGION LIST DSECT     08000001
         USING XSRT,GRXSRT              BASE SUBS TABLE DSECT           08100001
         USING XMAP,GRXMAP              BASE DO MAP DSECT               08200001
         USING XTRP,GRXTRP              BASE TRIPLE DSECT               08300001
         L     GRBASE2,=A(IEMKJ1)       LOAD SECOND BASE REGISTER       08450001
         LA    GRXSRT,KJSBXSRT          LOAD SUBS TABLE ENTRY BASE      08500001
*                                                                       08600001
*                                                                       08800001
         LA    GRXMAP,KJSBXSRT          INITIALLY LOAD GRXMAP TO BE     08900001
*                                         ABLE TO USE XMAPSEQU TO START 09000001
*                                         SEQUENCE                      09100001
         MVC   XMAPSEQU,XLCRFMAP        OBTAIN TEXT REFERENCE OF FIRST  09200001
*                                         DO MAP ENTRY                  09300001
*                                                                       09400001
KJSBZNXM CLI   XMAPSEQU,KJSBLMAP        TEST IF END OF DO MAP LIST      09500001
         MVI   KJSBFLAG,X'00'          CLEAR FIRST ENTRY IN XSRT FLAG   09600001
*                                                                       09700001
         BNE   KJSBZGTM                 BRANCH IF NOT END               09800001
*                                                                       09900001
         XC    LOCK,LOCK                CLEAR DICTIONARY LOCK SLOT      10000001
*                                                                       10060001
       IEMKTAB FREE,XLCRSRG                                             10130001
       IEMKTAB DEACT,(XLCRMAP,XLCRUSE,XLCRTXT)                          10160001
*                                                                       10200001
KJSBZEXT IEMKLVE                                                        10300001
*                                                                       10400001
**       OBTAIN NEXT DO MAP ENTRY AND LOAD BASE REGISTER GRXMAP         10500001
*                                                                       10600001
KJSBZGTM DS    0H                                                       10640001
       IEMKTAB DR,XLCRMAP,SA=XMAPSEQU,AATO=(GRXMAP),OPT=L               10680001
*                                                                       10720001
*                                                                       10760001
*                                                                       10800001
         EJECT                                                          10802001
         CLI   XMAPLEVL,X'0'            TEST IF XMAP LEVEL IS ZERO      10802601
         BE    KJSBZSKP                 IF SO BRANCH                    10803201
*                                                                       10804001
         BAL   RR,KJSRBXCH              CALL ROUTINE KJSRBXCH           10806001
*                                                                       10808001
*                                                                       10808201
*                                                                       10808401
         TM    XOPTOPTX,XOPTNKBX        TEXT IF LOOP OPTIMISABLE        10808601
         BO    KJSBZSKP                 BRANCH IF NOT                   10808801
*                                                                       10809001
*                                                                       10809201
         USING XDRF,GR6                 BASE DICTIONARY DSECT           10810001
*                                                                       10812001
         GETDICT XOPTIREF,GR6                                           10814001
         BAL   RR,KODECN                TEST 'INITIAL' IS A NICE        10816001
*                                         VARIABLE OR INT. CONSTANT     10818001
         B     *+4(RC)                  BRANCH IF NICE OR INT CONST     10820001
         OI    XOPTOPTX,XOPTISLC        SET NOT ALL CONSTANTS FLAG      10822001
         CLI   XDRFCODE,XDRFCNST        TEST 'INITIAL' IS A CONSTANT    10826001
         BE    *+12                     BRANCH IF CONSTANT              10827001
         OI    XOPTOPTX,XOPTISLC        SET NOT ALL CONSTANTS FLAG      10828001
         B     KJSBZSDC                 BRANCH, NOT CONSTANT DICT ENT   10829001
*                                                                       10830001
         LA    PR0,XMAPITXT             LOAD ADDRESS OF RELEVENT        10830201
*                                         TEXT REFERENCE                10830401
         LA    PR1,XMAPIREF             LOAD ADDRESS OF DICT REF        10830601
*                                                                       10830801
         BAL   RR,KJSRTDED              CALL ROUTINE TO SET DED         10831001
*                                                                       10831201
*                                                                       10831401
         B     *+4(RC)                  BRANCH IF DE NOT SUITABLE       10831601
         OI    XOPTOPTX,XOPTISLC+XOPTNKBX    SET NOT OPTIMISABLE        10831801
*                                                                       10832001
KJSBZSDC GETDICT XOPTSREF,GR6                                           10834001
*                                                                       10836001
         BAL   RR,KODECN                TEST 'STEP' IS A NICE           10838001
*                                         VARIABLE OR INT. CONSTANT     10840001
         B     *+4(RC)                  BRANCH IF NICE OR INT CONST     10842001
         OI    XOPTOPTX,XOPTISLC        SET NOT ALL CONSTANTS FLAG      10844001
         CLI   XDRFCODE,XDRFCNST        TEST 'STEP' IS A CONSTANT       10848001
         BE    *+12                     BRANCH IF CONSTANT              10849001
         OI    XOPTOPTX,XOPTISLC        SET NOT ALL CONSTANTS FLAG      10850001
         B     KJSBZLDC                 BRANCH, NOT CONSTANT DICT ENT   10851001
*                                                                       10852001
         LA    PR0,XMAPSTXT             LOAD ADDRESS OF RELEVENT        10852201
*                                         TEXT REFERENCE                10852401
         LA    PR1,XMAPSREF             LOAD ADDRESS OF DICT REF        10852601
*                                                                       10852801
         BAL   RR,KJSRTDED              CALL ROUTINE TO SET DED         10853001
*                                                                       10853201
*                                                                       10853401
         B     *+4(RC)                  BRANCH IF DE NOT SUITABLE       10853601
         OI    XOPTOPTX,XOPTISLC+XOPTNKBX    SET NOT OPTIMISABLE        10853801
*                                                                       10854001
KJSBZLDC GETDICT XOPTLREF,GR6                                           10856001
*                                                                       10858001
         BAL   RR,KODECN                TEST 'LIMIT' IS A NICE          10860001
*                                         VARIABLE OR INT. CONSTANT     10862001
         B     *+4(RC)                  BRANCH IF NICE OR INT CONST     10864001
         OI    XOPTOPTX,XOPTISLC        SET NOT ALL CONSTANTS FLAG      10866001
         CLI   XDRFCODE,XDRFCNST        TEST 'LIMIT' IS A CONSTANT      10870001
         BE    *+12                     BRANCH IF CONSTANT              10870501
         OI    XOPTOPTX,XOPTISLC        SET NOT ALL CONSTANTS FLAG      10871001
         B     KJSBZSKP                 BRANCH, NOT CONSTANT DICT ENT   10871501
         LA    PR0,XMAPLTXT             LOAD ADDRESS OF RELEVENT        10871701
*                                         TEXT REFERENCE                10871901
         LA    PR1,XMAPLREF             LOAD ADDRESS OF DICT REF        10872101
*                                                                       10872301
         BAL   RR,KJSRTDED              CALL ROUTINE TO SET DED         10872501
*                                                                       10872701
*                                                                       10872901
         B     *+4(RC)                  BRANCH IF DE NOT SUITABLE       10873101
         OI    XOPTOPTX,XOPTISLC+XOPTNKBX    SET NOT OPTIMISABLE        10873501
*                                                                       10874001
*                                                                       10876001
*                                                                       10880001
         DROP  GR6                                                      10882001
**                                                                      10884001
**                                                                      10886001
         USING XSRT,GRXSRT              BASE SUBS TABLE DSECT           10888001
         EJECT                                                          10890001
*                                                                       11100001
*                                                                       11200001
KJSBZSKP LA    GRXSRT,KJSBXSRT          RESET XSRT BASE REGISTER        11260001
         NI    KJEXFLAG,X'00'           CLEAR ALL EXPRESSION FLAGS      11320001
*                                                                       11400001
         TM    XMAPLOOP,XMAPPRBG        TEST IF ANY CONTAINED PROC/BEGN 11420001
         BO    KJSBZNIN                 IF SO BRANCH                    11440001
*                                                                       11460001
         CLI   XMAPLEVL,X'00'           TEST IF XMAPLEVL IS ZERO        11500001
         BNE   KJSBZTRA                 BRANCH IF LEVEL NON ZERO        11700001
*                                                                       12000001
KJSBZNIN OI    KJEXFLAG,KJEXNOIN        SET NO INVARIANTS FLAG          12100001
         B     KJSBZNTR                                                 12200001
*                                                                       12300001
KJSBZTRA TM    XMAPLOOP,XMAPATCV        TEST IF ASSIGNMENT TO CV        12400001
         BO    KJSBZNTR                 BRANCH IF FLAG SET              12500001
*                                                                       12600001
         TM    XMAPSPEC,XMAPBSPC+XMAPBDCV    TEST IF EITHER FLAG SET    12700001
         BZ    KJSBZISR                      BRANCH IF NEITHER SET      12800001
*                                                                       12900001
KJSBZNTR OI    KJEXFLAG,KJEXNOTR        SET NO TRANSFORMATION FLAG      13000001
*                                                                       13100001
*                                                                       13200001
         EJECT                                                          13300001
*                                                                       13400001
**       INITIALIZE PARAMETERS TO SCAN SUBS/REGION LIST                 13500001
*                                                                       13600001
KJSBZISR DS    0H                                                       13660001
       IEMKTAB SET,XLCRSRG,SA=XMAPSRGL                                  13720001
*                                                                       13800001
KJSBZNXG DS    0H                                                       13860001
       IEMKTAB SCAN,XLCRSRG,AATO=(GRXSRG)              GET NEXT ELEMENT 13920001
*                                                                       14000001
         TM    XSRGCODE,XSRGLEND        TEST FOR END OF LIST            14100001
         BC    BNO,KJSBZPCD                                             14200001
*                                                                       14300001
         MVI   XSRTCODE,XSRTLEND        LOAD TERMINAL CODE              14400001
         MVI   XSRTLNTH+1,X'03'         LOAD RECORD LENGTH              14500001
*                                                                       14600001
KJSBZNXT DS    0H                                                       14660001
       IEMKTAB BLDC,XLCRSRT,XSRT,SATO=KJSBFWWS    ADD ENTRY TO LIST     14720001
*                                                                       14820001
*                                                                       14860001
       IEMKTAB DEACT,(XLCRSRT)                                          14880001
*                                                                       14900001
KJSBZFEN TM    KJSBFLAG,X'FF'           TEST IF FIRST ENTRY IN TABLE    15000001
         BO    KJSBZNXM                 BRANCH IF NOT                   15100001
         OI    KJSBFLAG,X'FF'           SET FLAG                        15200001
         MVC   XMAPSRGL,KJSBFWWS       STORE TEXT REFERENCE IN XMAP     15300001
         B     KJSBZNXM                 RETURN TO PROCESS NEXT DO MAP   15400001
*                                         ENTRY                         15500001
*                                                                       15600001
         EJECT                                                          15700001
*                                                                       15800001
**             TEST WHICH TYPE OF ENTRY IS IN LIST                      15900001
*                                                                       16000001
KJSBZPCD TM    XSRGCODE,XSRGSUBS        TEST IF SUBS ENTRY              16100001
         BO    KJSBSUBS                 BRANCH IF SUBS ENTRY            16200001
*                                                                       16300001
*                                                                       16400001
**             CREATE SUBS TABLE REGION ENTRY                           16500001
*                                                                       16600001
         MVI   XSRTLNTH+1,X'06'         LOAD RECORD LENGTH              16700001
         MVC   XSRTCODE,XSRGCODE        SET CODE FOR REGION ENTRY       16800001
*                                                                       16900001
         CLI   XSRTCODE,XSRTCSFE        TEST FOR SAFE BOUNDARY          17000001
         BNE   KJSBRMTR                 BRANCH IF NOT                   17100001
*                                                                       17200001
*                                                                       17300001
*                                                                       17400001
*                                                                       17500001
KJSBRMDR MVI   XSRTLNTH+1,X'08'         RESET RECORD LENGTH             17600001
         MVC   XSRTRDRF,XSRGDREF        LOAD DR OF VARIABLE CHANGED     17700001
*                                                                       17800001
KJSBRMTR MVC   XSRTTEXT,XSRGTEXT        LOAD BOUNDARY TEXT REFERENCE    17900001
       IEMKTAB BLDC,XLCRSRT,XSRT,SATO=KJSBFWWS    ADD ENTRY TO LIST     17970001
       IEMKTAB DEACT,(XLCRSRT)                                          18030001
         B     KJSBCFEN                                                 18200001
*                                                                       18300001
         EJECT                                                          18400001
*                                                                       18500001
**             CREATE SUBS TABLE SUBS ENTRY                             18600001
*                                                                       18700001
KJSBSUBS MVI   XSRTCODE,XSRTCSUB        SET SUBS ENTRY FLAG             18800001
         MVC   XSRTTEXT,XSRGTEXT        LOAD TEXT REF  OF SUBS IN XSRT  18900001
         XC    XSRTSSTC(5),XSRTSSTC     CLEAR SUBS OPT WORKSPACE        19000001
         MVI   KJSBTFLG,X'00'           CLEAR TEMPORARY FLAGS.    41988 19050021
*                                                                       19100001
**             OBTAIN DICTIONARY REFERENCE OF DOPE VECTOR, AND NUMBER   19200001
**             OF SUBSCRIPT EXPRESSIONS                                 19300001
*                                                                       19400001
*                                                                       19500001
**       INITIALIZE TEXT SCAN TO POINT AT ENTRY HELD IN XSRTTEXT        19600001
*                                                                       19700001
*                                                                       19800001
       IEMKTAB SET,XLCRTXT,SA=XSRTTEXT                                  19900001
*                                                                       20000001
       IEMKTAB SCAN,XLCRTXT,AATO=(GRY)  OBTAIN SUBS TRIPLE ADDRESS      20100001
*                                                                       20200001
         MVC   PAR1+2(2),1(GRY)         LOAD PAR1 WITH THE FIRST        20300001
*                                         OPERAND OF THE TRIPLE, THE    20400001
*                                         DR OF THE ARRAY VARIABLE      20500001
         L     LR,ZDRFAB                CALL ZDRFAB TO LOAD DICTIONARY  20600001
         BALR  RR,LR                      ENTRY AND GIVE ABSOLUTE       20700001
*                                         ADDRESS                       20800001
*                                                                       20900001
         L     GRX,PAR1                 STORE ADDRESS OF DICT. ENTRY    21000001
*                                                                       21100001
         USING XDFM,GRXDFM              BASE DICTIONARY ENTRY DSECT     21200001
*                                                                       21300001
         LR    GRXDFM,GRX               LOAD XDFM DSECT BASE            21400001
*                                                                       21401001
         TM    XDFMFOT2,X'03'           TEST IF CONTROLLED              21402001
         BO    KJSBSOMT                 IF SO BRANCH                    21403001
*                                                                       21404001
         TM    XDFMFOT2,X'08'           TEST IF PARAMETER         40061 21404421
         BNO   KJSBNXTT                                           40061 21404821
         BAL   RR,KJSRTPRM              IF SO,TEST IF OPTIMISABLE 40061 21405221
         LTR   RC,RC                                              40061 21405621
         BZ    KJSBSOMT                 IF NOT, GO TO SET FLAG    40061 21406021
         OI    KJSBTFLG,KJSBUCOM        IF SO, SET SUBSCRIPTS     41988 21406221
*                                     UNCOMMONABLE FLAG.          41988 21406421
KJSBNXTT EQU   *                        CONTINUE TESTS.           40061 21406621
*                                                                       21407001
         TM    XDFMFDAT,X'80'           IS THIS A STRING ARRAY ?        21414001
         BO    KJSBSSVI                 BRANCH IF NOT                   21421001
*                                                                       21428001
         TM    XDFMFDAT,X'50'           IS THIS VARYING OR ADJUSTABLE ? 21435001
         BC    BNZ,KJSBSOMT             IF SO BRANCH                    21442001
*                                                                       21449001
         TM    XDFMFDAT,X'24'           IS THIS UNALIGNED BIT STRING ?  21456001
         BC    BNZ,KJSBSSVI             BRANCH IF NOT                   21463001
*                                                                       21470001
KJSBSOMT OI    XMAPLOOP,XMAPSBMS        SET SUBS OMITTED FLAG           21477001
         B     KJSBZNXG                 GET NEXT S/R LIST ELEMENT       21484001
*                                                                       21491001
*                                                                       21500001
**             OBTAIN DIMENSIONED INFORMATION FROM DICT. ENTRY          21600001
*                                                                       21700001
KJSBSSVI LA    GRX,21(0,GRX)            ADJUST GRX TO POINT TO START OF 21800001
*                                         VARIABLE INFORMATION          21900001
         TM    XDFMFVAR,KJSBVAR1        TEST IF SECOND ADDRESS SLOT     22000001
*                                         PRESENT                       22100001
         BC    BNO,KJSBSDVR             BRANCH IF ABSENT                22200001
         DROP  GRXDFM                   DROP XDFM BASE REGISTER         22300001
*                                                                       22400001
         LA    GRX,KJSBSASL(0,GRX)      ADJUST GRX TO POINT PAST SECOND 22500001
*                                         SLOT                          22600001
*                                                                       22700001
KJSBSDVR MVC   XSRTSDVR,1(GRX)          OBTAIN DOPE VECTOR DR           22800001
         MVC   XSRTSNOC,0(GRX)          OBTAIN NUMBER OF COMMAS         22900001
*                                                                       23000001
         EJECT                                                          23100001
*                                                                       23200001
**       SET UP REGISTERS TO ACCESS THE MULTIPLIERS IN THE DOPE VECTOR  23300001
*                                                                       23400001
         MVC   LOCK,XSRTSDVR            LOCK IN DICTIONARY BLOCK        23500001
         MVC   PAR1+2(2),XSRTSDVR       * CALL ZDRFAB TO                23600001
         L     LR,ZDRFAB                * LOAD MULTIPLIER               23700001
         BALR  RR,LR                    * TABLE INTO STORE              23800001
*                                                                       23900001
         L     GRX,PAR1                 INITIALIZE GRX                  24000001
         LA    GRX,12(0,GRX)            ADJUST GRX TO USE AS BASE VALUE 24100001
*                                         FOR ACCESSING BOUND AND       24200001
*                                         MULTIPLIER SLOTS              24300001
         XR    GRY,GRY                  CLEAR GRY                       24400001
         IC    GRY,XSRTSNOC             * MULTIPLY NUMBER OF COMMAS BY  24500001
         SLL   GRY,3                    * 8 TO GIVE OFFSET FROM GRX     24600001
         LA    GRZ,0(GRY,GRX)           POINT TO FIRST MULTIPLIER       24700001
         ST    GRZ,KJSBDVML                                             24800001
*                                                                       24900001
*                                                                       25000001
*                                                                       25100001
         EJECT                                                          25200001
         XR    GRCCNT,GRCCNT            CLEAR COMA COUNT REGISTER       25300001
         IC    GRCCNT,XSRTSNOC          LOAD IN NUMBER OF COMMAS        25400001
         STH   GRCCNT,KJSBFWWS          STORE NUMBER OF COMMAS          25500001
         STH   GRCCNT,KJSBCCNT          HOLD COMA COUNT                 25550001
         LA    GRY,XSRTSEND-XSRTSCOM    LOAD LENGTH OF SUBS COMA ENTRY  25600001
         MH    GRY,KJSBFWWS             AND MULTIPLY BY NO OF COMMAS    25700001
         LA    GRY,XSRTSCOM-XSRT(0,GRY) ) CALCULATE LENGTH OF ENTRY AND 25800001
         STH   GRY,KJSBFWWS             ) STORE                         25860001
         MVC   XSRTLNTH,KJSBFWWS        )                               25920001
*              CALCULATE ADDRESS OF FIRST SUBS COMA ENTRY IN XSRT       26000001
         LA    GRX,XSRTSEND-XSRTSCOM                                    26100001
         SR    GRY,GRX                                                  26200001
         LA    GRSCOM,0(GRY,GRXSRT)                                     26300001
         USING XSRTSCOM,GRSCOM          BASE SUBS TABLE COMA EXP. DATA  26400001
*                                                                       26500001
KJSBSNXC NI    KJEXFLAG,KJEXNOIN+KJEXNOTR         CLEAR LOCAL COMMA     26600001
         NI    KJEXFLG2,X'00'                     EXPRESSIONS FLAGS     26700001
         NI    XSRTSCCE,X'00'           CLEAR COMMA CODE FLAGS          26800001
         XC    KJOPEXPR,KJOPEXPR        SET EXPRESSION COUNT EQUAL ZERO 26900001
*                                                                       27000001
       IEMKTAB SCAN,XLCRTXT,AATO=(GRXTRP),SATO=XSRTSCOM                 27100001
*                                       OBTAIN FIRST TRIPLE AFTER SUBS  27200001
*                                         AND STORE TEXT REF IN XSRT    27300001
*                                                                       27400001
         B     KJSBSBYP                 BRANCH ROUND NORMAL SCAN CALL   27500001
*                                                                       27600001
KJSBSNXT DS    0H                                                       27660001
       IEMKTAB SCAN,XLCRTXT,AATO=(GRXTRP)    OBTAIN NEXT TRIPLE         27720001
*                                                                       27800001
KJSBSBYP XR    2,2                      CLEAR REG 2 FOR TRT             27900001
         TRT   XTRPCODE,KJSBTTAB        TEST TRIPLE CODE                28000001
*                                                                       28100001
         BZ    KJSBOTHR                 OTHER THAN THE FOLLOWING:-      28200001
KJSBSTAB B     KJSBSTAB(2)                                              28300001
         B     KJSBNPRM                 PREFIX MINUS                    28400001
         B     KJSBPLMS                 PLUS AND MINUS                  28500001
         B     KJSBMULT                 MULTIPLY                        28600001
         B     KJSBCOMA                 COMMA                           28700001
         B     KJSBDIVD                 DIVIDE                          28800001
         B     KJSBDSOP                 PREFIX PLUS                     28900001
         B     KJSBSNXT                 NOP AND IGNORABLE TRIPLES       29000001
         EJECT                                                          29100001
*                                                                       29200001
**             PROCESS PREFIX MINUS TRIPLE                              29300001
*                                                                       29400001
KJSBNPRM TM    KJEXFLAG,KJEXUCOM        * SCAN FOR END OF EXPRESSION    29500001
         BO    KJSBSNXT                 * IF EXPR. UNCOM FLAG SET       29600001
*                                                                       29700001
         TM    KJEXFLAG,KJEXVARE        * IF VARIABLE PRESENT, CHECK    29800001
         BO    KJSBDSOP                 * OPERAND FOR SAFE AND NICE     29900001
*                                                                       30000001
         LR    PR1,GRXTRP               * CALL KJSRCHKP TO              30100001
         IC    PR0,=X'FF'               * EXAMINE SECOND                30200001
         BAL   RR,KJSRCHKP              * OPERAND OF TRIPLE             30300001
*                                                                       30400001
         TM    KJOPRND2,KJOCZERO        TEST IF OPERAND X'00'           30500001
         BC    BNO,KJSBSNXT             BRANCH IF NOT                   30600001
         OI    KJEXFLG2,KJEX2PEX        SET PREFIX MINUS EXP. FLAG      30700001
*                                                                       30800001
         B     KJSBSNXT                 BRANCH TO PROCESS NEXT TRIPLE   30900001
*                                                                       31000001
         EJECT                                                          31100001
*                                                                       31200001
**             PROCESS PLUS OR MINUS TRIPLES                            31300001
*                                                                       31400001
KJSBPLMS TM    KJEXFLAG,KJEXUCOM        * SCAN FOR END OF EXPRESSION    31500001
         BO    KJSBSNXT                 * IF EXPR. UNCOM FLAG SET       31600001
*                                                                       31700001
         TM    KJEXFLAG,KJEXVARE        * IF VARIABLE PRESENT, CHECK    31800001
         BO    KJSBDFOP                 * OPERANDS FOR SAFE AND NICE    31900001
*                                                                       32000001
         LR    PR1,GRXTRP               * CALL KJSRCHKP TO              32100001
         XR    PR0,PR0                  * EXAMINE BOTH                  32200001
         BAL   RR,KJSRCHKP              * OPERANDS OF TRIPLE            32300001
*                                                                       32400001
         TM    KJOPRND1,KJOCCNST        TEST IF OPERAND1 IS CONSTANT    32500001
         BC    BNO,KJSBPINX             BRANCH IF NOT                   32600001
*                                                                       32700001
         TM    KJOPRND2,KJOCCNST        TEST IF OPERAND2 IS CONSTANT    32800001
         BC    BNO,KJSBPINX             BRANCH IF NOT                   32900001
*                                                                       33000001
         OI    KJEXFLAG,KJEXVARE+KJEXUCOM    SET EXPRESSION VARIABLE    33100001
*                                         AND UNCOMMONABLE FLAGS ON,    33200001
*                                         BOTH OPERANDS CONSTANT IS NOT 33300001
*                                         PERMITTED                     33400001
         B     KJSBSNXT                 BRANCH TO PROCESS NEXT TRIPLE   33500001
*                                                                       33600001
*                                                                       33700001
KJSBPINX LH    GRY,KJOPEXPR             * INCREMENT                     33800001
         LA    GRY,1(0,GRY)             * EXPRESSION                    33900001
         STH   GRY,KJOPEXPR             * COUNT BY ONE                  34000001
*                                                                       34100001
         B     KJSBSNXT                 BRANCH TO PROCESS NEXT TRIPLE   34200001
*                                                                       34300001
         EJECT                                                          34400001
*                                                                       34500001
**             PROCESS ANY OTHER TYPE OF TRIPLE                         34600001
*                                                                       34700001
KJSBOTHR OI    KJEXFLAG,KJEXVARE+KJEXUCOM    SET EXPRESSION VARIABLE    34800001
*                                         AND UNCOMMONABLE FLAGS ON.    34900001
         B     KJSBSNXT                 BRANCH TO PROCESS NEXT TRIPLE   35000001
*                                                                       35100001
         EJECT                                                          35200001
*                                                                       35300001
**             PROCESS DIVIDE TRIPLES AND PREFIX PLUS TRIPLES           35400001
**             THIS SECTION JUST EXAMINES EITHER BOTH OPERANDS FOR      35500001
**             NICE AND SAFE VARIABLES.                                 35600001
**             SEVERAL OTHER TRIPLES USE THIS SECTION IN WHOLE OR PART  35700001
**             IF THE EXPRESSION VARIABLE FLAG IS ALREADY SET.          35800001
*                                                                       35900001
KJSBDIVD TM    KJEXFLAG,KJEXUCOM        * SCAN FOR END OF EXPRESSION    36000001
         BO    KJSBSNXT                 * IF EXPR. UNCOM FLAG SET       36100001
*                                                                       36200001
KJSBDFOP LA    PR1,XTRPOP1              * CALL KJSRSOPC FOR             36300001
         BAL   RR,KJSRSOPC              * OPERAND1                      36400001
         STC   PR0,KJOPRND1             STORE CODE BYTE                 36500001
*                                                                       36600001
         LH    GRY,KJOPEXPR             ) INCREMENT                     36620001
         LA    GRY,1(0,GRY)             ) EXPRESSION                    36640001
         STH   GRY,KJOPEXPR             ) COUNT BY ONE                  36660001
*                                                                       36680001
         TM    KJOPRND1,KJOCUNSF        TEST IF OP. VARIABLE UNSAFE     36700001
         BC    BNO,KJSBDSOP                                             36800001
*                                                                       36900001
         OI    KJEXFLAG,KJEXUNSF        SET EXPRESSION UNSAFE FLAG      37000001
*                                                                       37100001
         B     KJSBDSOP                                                 37500001
*                                                                       38000001
**             PROCESS SECOND OPERAND                                   38100001
*                                                                       38200001
KJSBDSOP LA    PR1,XTRPOP2              * CALL KJSRSOPC FOR             38300001
         BAL   RR,KJSRSOPC              * OPERAND2                      38400001
         STC   PR0,KJOPRND2             STORE CODE BYTE                 38500001
*                                                                       38600001
         LH    GRY,KJOPEXPR             ) INCREMENT                     38630001
         LA    GRY,1(0,GRY)             ) EXPRESSION                    38660001
         STH   GRY,KJOPEXPR             ) COUNT BY ONE                  38700001
         TM    KJOPRND2,KJOCUNSF        TEST IF OP. VARIABLE UNSAFE     38740001
*                                                                       38800001
         BC    BNO,KJSBDVAR                                             38850001
*                                                                       38900001
         OI    KJEXFLAG,KJEXUNSF        SET EXPRESSION UNSAFE FLAG      39000001
*                                                                       39100001
*                                                                       40000001
KJSBDVAR OI    KJEXFLAG,KJEXVARE        SET EXPR. VARIABLE FLAG         40100001
*                                                                       40200001
         B     KJSBSNXT                 BRANCH TO SCAN NEXT TRIPLE.     40300001
*                                                                       40400001
         EJECT                                                          40500001
*                                                                       40600001
**             PROCESS MULTIPLY TRIPLE                                  40700001
*                                                                       40800001
KJSBMULT TM    KJEXFLAG,KJEXUCOM        * SCAN FOR END OF EXPRESSION    40900001
         BO    KJSBSNXT                 * IF EXPR. UNCOM FLAG SET       41000001
*                                                                       41100001
         TM    KJEXFLAG,KJEXVARE        * IF VARIABLE PRESENT, CHECK    41200001
         BO    KJSBDFOP                 * OPERANDS FOR SAFE AND NICE    41300001
*                                                                       41400001
         LR    PR1,GRXTRP               * CALL KJSRCHKP TO              41500001
         XR    PR0,PR0                  * EXAMINE BOTH                  41600001
         BAL   RR,KJSRCHKP              * OPERANDS OF TRIPLE            41700001
*                                                                       41800001
         LA    GRY,2                    * SET EXPRESSION VALUE          41900001
         STH   GRY,KJOPEXPR             * EQUAL TO TWO                  42000001
*                                                                       42100001
         TM    KJOPRND1,KJOCZERO        TEST IF OPERAND1 IS '00'        42200001
         BO    KJSBMVAR                 BRANCH IF '00'                  42300001
*                                                                       42400001
         TM    KJOPRND2,KJOCZERO        TEST IF OPERAND2 IS '00'        42500001
         BO    KJSBMVAR                 BRANCH IF '00'                  42600001
*                                                                       42700001
         TM    KJOPRND1,KJOCCNST        TEST IF OPERAND1 IS CONSTANT    42800001
         BO    KJSBMCNT                 BRANCH IF CONSTANT              42900001
*                                                                       43000001
         TM    KJOPRND2,KJOCCNST        TEST IF OPERAND2 IS CONSTANT    43100001
         BO    KJSBSNXT                 BRANCH IF CONSTANT TO SCAN NEXT 43200001
*                                         TRIPLE                        43300001
         B     KJSBMVAR                                                 43400001
*                                                                       43500001
*                                                                       43600001
KJSBMCNT TM    KJOPRND2,KJOCCNST        TEST IF OPERAND2 IS CONSTAND    43700001
         BC    BNO,KJSBSNXT             BRANCH IF NOT TO SCAN NEXT TRP. 43800001
*                                                                       43900001
         OI    KJEXFLAG,KJEXUCOM        SET EXPR. UNCOM FLAG, TWO       44000001
*                                         CONSTANTS ARE NOT PERMITTED   44100001
*                                                                       44200001
KJSBMVAR OI    KJEXFLAG,KJEXVARE        SET EXPR. VARIABLE FLAG         44300001
*                                                                       44400001
         B     KJSBSNXT                 BRANCH TO SCAN NEXT TRIPLE      44500001
*                                                                       44600001
         EJECT                                                          44700001
*                                                                       44800001
**             PROCESS COMMA TRIPLE, AND ANALYSE THE EXPRESSION         44900001
*                                                                       45000001
KJSBCOMA LR    PR1,GRXTRP               * CALL KJSRCHKP TO              45100001
         IC    PR0,=X'FF'               * EXAMINE SECOND                45200001
         BAL   RR,KJSRCHKP              * OPERAND OF TRIPLE             45300001
*                                                                       45400001
         TM    KJEXFLAG,KJEXVARE        TEST IF VARIABLE PRESENT        45500001
         BC    BNO,KJSBCOPN             BRANCH IF NO VAR                45600001
*                                                                       45700001
         TM    KJEXFLAG,KJEXUCOM        TEST IF UNCOMMONABLE            45800001
         BO    KJSBCUNO                 BRANCH IF UNCOM                 45900001
*                                                                       46000001
*                                                                       46300001
*                                                                       46400001
KJSBCCOM TM    KJSBTFLG,KJSBUCOM        TEST IF SUBSCRIPTS ARE    41988 46430021
*                                     COMMONABLE.                 41988 46460021
         BO    KJSBCAUS                 BRANCH IF NOT             41988 46490021
         OI    XSRTSCCE,XSRTCCOM        IF SO, SET COMA           41988 46520021
*                                     COMMONABLE FLAG.            41988 46550021
         B     KJSBCAUS                 BRANCH TO CHECK MULTIPLIERS     46600001
*                                                                       46700001
*                                                                       46800001
*                                                                       46900001
KJSBCUNO NI    XSRTSCCE,X'00'           CLEAR COMA CODE FLAGS,          47000001
*                                         EXPRESSION UNOPTIMISABLE      47100001
         B     KJSBCLCM                 BRANCH TO CONSIDER NEXT COMA    47200001
*                                                                       47300001
KJSBCORD CLC   KJOPEXPR,=H'1'           TEST EXPRESSION VALUE           47400001
         BH    KJSBCUNO                 BRANCH IF VALUE GREATER THAN 1  47500001
         B     KJSBCCOM                                                 47600001
*                                                                       47700001
*                                                                       47800001
KJSBCOPN TM    KJOPRND2,KJOCCNST        TEST IF COMA OPRND IS CONSTANT  47900001
         BC    BNO,KJSBCOPT             BRANCH IF NOT                   48000001
*                                                                       48100001
         OI    KJEXFLAG,KJEXINVR        SET EXPR. INVARIANT FLAG        48200001
*                                                                       48300001
KJSBCOPT TM    XMAPOPTN,XMAPORDR        TEST IF OPTION ORDER            48400001
         BZ    KJSBCCVT                 BRANCH IF REORDER               48500001
*                                                                       48600001
         CLC   KJOPEXPR,=H'1'           TEST EXPRESSION VALUE           48700001
         BH    KJSBCCOM                 BRANCH IF GREATER THAN 1        48800001
*                                                                       48900001
*                                                                       48920001
KJSBCCVT TM    KJEXFLAG,KJEXUNSF        TEST IF UNSAFE VAR. PRESENT     48940001
         BZ    KJSBCTCV                 BRANCH IF NOT                   48960001
*                                                                       48980001
         TM    XMAPLOOP,XMAPATUV        TEST IF ASSIGNMENT TO UNSF VAR  49000001
         BO    KJSBCCOM                 IF SO BRANCH                    49020001
*                                                                       49040001
KJSBCTCV TM    KJEXFLAG,KJEXCONV        TEST IF CV PRESENT              49060001
         BC    BNO,KJSBCINV             BRANCH IF NOT                   49100001
*                                                                       49200001
         TM    KJEXFLAG,KJEXNOTR        TEST IF TRANSFORMATION ALLOWED  49300001
         BO    KJSBCINV                 BRANCH IF NOT                   49400001
*                                                                       49500001
         TM    KJEXFLG2,KJEX2PEX        TEST IF PREFIX MINUS EXP.       49600001
         BO    KJSBCINV                 BRANCH IF PRESENT               49700001
*                                                                       49800001
         OI    XSRTSCCE,XSRTCTRA        SET COMA TRANSFORMABLE FLAG     49900001
*                                                                       50000001
KJSBCINV TM    KJEXFLAG,KJEXINVR        TEST IF INVARIANT PRESENT       50100001
         BC    BNO,KJSBCCOM             BRANCH IF NOT                   50200001
*                                                                       50300001
         TM    KJEXFLAG,KJEXNOIN        TEST IF INVARIANTS ALLOWED      50400001
         BO    KJSBCCOM                 BRANCH IF NOT                   50500001
*                                                                       50600001
         TM    KJEXFLAG,KJEXCONV        TEST IF CV PRESENT              50610001
         BZ    KJSBCSIN                 BRANCH IF NOT                   50620001
*                                                                       50630001
         TM    KJEXFLAG,KJEXNOTR        TEST IF TRANSFORMATION ALLOWED  50640001
         BO    KJSBCCOM                 BRANCH IF NOT                   50650001
*                                                                       50660001
**             IF CV IS PRESENT AND TRANSFORMATION NOT ALLOWED THEN     50670001
**             INVARIANTS ARE NOT CONSIDERED FOR OPTIMISATION EITHER.   50680001
*                                                                       50690001
KJSBCSIN OI    XSRTSCCE,XSRTCINV        SET COMA INVARIANTS FLAG        50700001
         B     KJSBCCOM                 BRANCH TO SET COMMONABLE FLAG   50800001
*                                                                       50900001
*                                                                       51000001
KJSBCFFF MVC   XTRPOP1,=X'FFFFFFFF'     SET COMA OP1 FOR VAR MULT       51030001
         B     KJSBCSET                                                 51060001
*                                                                       51100001
*                                                                       51200001
KJSBCAUS L     GRZ,KJSBDVML             ) TEST IF MULTIPLIER IS FIXED   51300001
         CLC   0(4,GRZ),=X'FFFFFFFF'    )                               51400001
         BE    KJSBCFFF                 ) BRANCH IF NOT                 51500001
         CLC   0(2,GRZ),=H'0'           TEST IF MULT FITS IN 2 BYTES    51600001
         BNE   KJSBCFFF                 BRANCH IF NOT                   51660001
*                                                                       51720001
         TM    2(GRZ),X'80'             TEST NUMBER LESS 16 BITS        51740001
         BO    KJSBCFFF                 BRANCH, MULTIPLIER TOO BIG      51770001
*                                                                       51800001
KJSBCSTO MVC   XTRPOP1,2(GRZ)           MOVE MULTIPLIER TO FIRST        51900001
*                                         OPERAND OF COMA TRIPLE        52000001
*                                                                       52100001
KJSBCSET OC    XSRTCODE,XSRTSCCE        SET SUBS ENTRY CODE FROM        52200001
*                                         INDIVIDUAL COMA CODE          52300001
*                                                                       52400001
         TM    KJEXFLAG,KJEXUNSF        TEST IF EXPRESSION UNSAFE       52500001
         BC    BNO,KJSBCLCM             BRANCH IF SAFE                  52600001
*                                                                       52700001
         OI    XSRTSCCE,XSRTSCUN        SET COMA UNSAFE FLAG            52800001
*                                                                       52900001
*                                                                       53500001
*                                                                       53600001
KJSBCLCM LH    GRCCNT,KJSBCCNT          RESET COMA COUNT IN REG         53650001
         BCT   GRCCNT,KJSBCRST          BRANCH TO ADJUST PARMS IF MORE  53700001
*                                         COMA EXPRESSIONS              53750001
*                                                                       53800001
       IEMKTAB BLDC,XLCRSRT,XSRT,SATO=KJSBFWWS    ADD ENTRY TO LIST     53870001
       IEMKTAB DEACT,(XLCRSRT,XLCRTXT)                                  53930001
KJSBCFEN TM    KJSBFLAG,X'FF'           TEST IF FIRST ENTRY IN TABLE    54100001
         BO    KJSBZNXG                 BRANCH IF NOT                   54200001
*                                         RESET ADDRESS SLOT IN XMAP    54300001
         OI    KJSBFLAG,X'FF'           SET FLAG                        54400001
         MVC   XMAPSRGL,KJSBFWWS       STORE TEXT REFERENCE IN XMAP     54500001
         B     KJSBZNXG                 BRANCH TO PROCESS NEXT          54600001
*                                         SUBS/REGN LIST ENTRY          54700001
*                                                                       54800001
KJSBCRST STH   GRCCNT,KJSBCCNT          RESTORE COMA COUNT              54860001
         LA    GRZ,XSRTSEND-XSRTSCOM    ) POINT GRSCOM AT NEXT AREA OF  54920001
         SR    GRSCOM,GRZ               ) SUBS ENTRY                    55000001
*                                                                       55100001
         L     GRZ,KJSBDVML             ) ADJUST MULTIPLIER POINTER TO  55200001
         LA    GRZ,4(0,GRZ)             ) POINT TO NEXT COMA            55300001
         ST    GRZ,KJSBDVML             ) INFORMATION                   55400001
*                                                                       55500001
         B     KJSBSNXC                                                 55600001
*                                                                       55700001
         DROP  GRSCOM                   DROP XSRTSCOM BASE REGISTER     55800001
         EJECT                                                          55900001
         LTORG                                                          56000001
         EJECT                                                          56100001
KJSBFWWS DC    F'0'                     FULL WORD WORK SPACE            56200001
*                                                                       56300001
KJOPEXPR DC    H'0'                     COMA EXPRESSION VALUE           56400001
KJSBCCNT DC    H'0'                     COMA CODE COUNT                 56450001
*                                                                       56500001
KJOPRND1 DC    X'0'                     * TWO CODE BYTES CONTAINING     56600001
KJOPRND2 DC    X'0'                     * INFORMATION ON THE TRIPLE     56700001
*                                       * OPERANDS                      56800001
*                                                                       56900001
**       FLAGS CONTAINED IN THE ABOVE CODE BYTES                        57000001
*                                                                       57100001
KJOCCONV EQU   X'80'                    CONTROL VARIABLE                57200001
KJOCCNST EQU   X'40'                    CONSTANT                        57300001
KJOCINVR EQU   X'20'                    INVARIANT                       57400001
KJOCNICE EQU   X'10'                    VARIABLE IS NICE                57500001
KJOCUNSF EQU   X'08'                    VARIABLE IS UNSAFE              57600001
KJOCNOTN EQU   X'04'                    VARIABLE IS NICE BUT ABNORMAL   57700001
KJOCUNOP EQU   X'02'                    OPERAND IS UNSUITABLE FOR       57800001
*                                         OPTIMISATION                  57900001
KJOCZERO EQU   X'01'                    OPERAND IS '00'                 58000001
*                                                                       58100001
*                                                                       58200001
KJEXFLAG DC    X'0'                     COMA EXPRESSION CODE BYTE       58300001
KJEXFLG2 DC    X'0'                     COMA EXPRESSION CODE BYTE 2     58400001
*                                                                       58500001
**       FLAGS CONTAINED IN THE ABOVE CODE BYTE                         58600001
*                                                                       58700001
KJEXVARE EQU   X'01'                    EXPRESSION CONTAINS VARIABLE    58800001
KJEXUCOM EQU   X'02'                    EXPR. IS UNCOMMONABLE           58900001
KJEXUNSF EQU   X'08'                    EXPR. CONTAINS UNSAFE VARIABLE  59000001
KJEXNOTN EQU   X'04'                    EXPR. CONTAINS NOTNICE VARIABLE 59100001
KJEXINVR EQU   X'20'                    EXPR. CONTAINS INVARIANT        59200001
KJEXCONV EQU   X'80'                    EXPR. CONTAINS CONTROL VARIABLE 59300001
KJEXNOIN EQU   X'40'                    INVARIANCE NOT PERMITTED        59400001
KJEXNOTR EQU   X'10'                    TRANSFORMATION NOT PERMITTED    59500001
*                                                                       59600001
**       THE LAST TWO FLAGS APPLY TO ALL THE COMA EXPRESSIONS WITHIN    59700001
**       THE SCOPE OF ONE SUBS/REGION LIST ENTRY                        59800001
*                                                                       59900001
KJEX2PEX EQU   X'80'                    PREFIX MINUS EXPRESSION         60000001
*                                                                       60100001
KJSBFLAG DC    X'00'                   FIRST ENTRY FLAG                 60200001
*                                                                       60300001
KJSBTXTL EQU   5                                                        60400001
KJSBSASL EQU   4                        LENGTH OF SECOND SLOT           60500001
KJSBVAR1 EQU   X'80'                    VARIABLE BYTE  SECOND SLOT      60600001
KJSBLMAP EQU   X'FF'                    CODE FOR END OF DO MAP          60700001
KJSBSRGL EQU   X'FF'                    NO SUBS/REGN LIST               60800001
*                                                                       60900001
KJSBTFLG DC    X'00'                    TEMPORARY FLAGS           41988 60920021
*                                                                 41988 60940021
KJSBUCOM EQU   X'80'                    ALL SUBSCRIPTS UNCOMMONABLE     60960021
KJSBTTAB DC    39X'0',X'1C',8X'0'       TRT TABLE FOR TRIPLES           61000001
         DC    15X'0',X'1C'                                             61100001
         DC    X'0010',14X'0'                                           61200001
         DC    32X'0'                                                   61300001
         DC    X'0000000800080014000C000400180000'                      61400001
         DC    128X'0'                                                  61500001
*                                                                       61600001
         DS    0H                                                       61700001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*KJ 001-TSS 61730019
KJSBXSRT DC    (XSRTSCOM-XSRT)X'00',(32*(XSRTSEND-XSRTSCOM))X'00'       61760001
*        ----------------------------------------------------KJ 001-TSS 61790019
*                                       SPACE FOR XSRT DSECT GIVING     61820001
*                                         32 COMA EXPRESSIONS IN SUBS   61900001
*                                         ENTRY                         62000001
*                                                                       62100001
*                                                                       62200001
KJSBDVML DC    A(0)                     ADDRESS OF DOPE VECTOR MULT     62300001
*                                                                       62400001
*                                                                       62410019
         EJECT                                                          62420019
*              SUBROUTINES CSECT                                        62430019
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*KJ 002-TSS 62440019
IEMKJ1   CSECT                                                          62450019
*        ----------------------------------------------------KJ 002-TSS 62460019
*                                                                       62470019
*                                                                       62480019
*                                                                       62490019
*                                                                       62500019
**                                                                      62601501
**       THIS ROUTINE SETS THE TARGET DED IN THE DICTIONARY ENTRY       62602001
**             OF A CONSTANT TO BE USED IN BXLE/BXH CODE.               62602501
**       IF THE DED IS ALREADY SET TO A NON USABLE VALUE, A NEW ENTRY   62603001
**             IS CREATED AND CHAINED TO THE PREVIOUS ENTRY.            62603501
**       ONLY ONE ENTRY IS CREATED FOR EACH REQUIRED DED VALUE FOR A    62604001
**             GIVEN CONSTANT.                                          62604501
**       IF NECESSARY, THE DICT. REFS. IN TEXT ARE UPDATED.             62605001
**                                                                      62605501
**       PR0 AND PR1 HOLD XMAP DSECT ADDRESSES TO XMAP_TXT AND          62606001
**             XMAP_REF ENTRIES RESPECTIVELY.                           62606501
*                                                                       62607001
**       GR6 CONTAINS THE ADDRESS OF THE DICTIONARY ENTRY               62607501
*                                                                       62608001
*                                                                       62608501
KJSRTDED IEMKENT                                                        62609001
*                                                                       62609501
         USING XDFM,GR6                 BASE DICTIONARY DSECT           62610001
*                                                                       62610501
         STM   PR0,PR1,TDEDPARS         SAVE PARAMETER REGISTERS        62611001
         MVC   LOCK,0(PR1)              LOCK IN DICT BLOCK              62611501
*                                                                       62612001
         MVC   TDEDDREF,0(PR1)          STORE DICT EEF                  62612501
         MVI   TDEDFLAG,X'00'           SET OFF TDEDFLAG                62613001
         CLC   XDFMLNTH,TDED000E        ) BRANCH TO MAIN TEST IF LENGTH 62613501
         BH    TDEDMAIN                 ) OF ENTRY GREATER THAN 14      62614001
*                                                                       62614501
         SR    RC,RC                                                    62615001
         B     TDEDEEXT                 BRANCH TO EXIT,  DICT ENTRY BAD 62615501
*                                                                       62616001
*                                                                       62616501
TDEDMAIN TM    XDFMCTYP,TDEDTYP1        TEST TYPE BYTE BITS 1 & 2       62617001
         BC    BNZ,TDEDTSDD             BRANCH IF NON ZERO              62617501
*                                                                       62618001
         TM    XDFMCTYP,TDEDTYP2        TEST TYPE BYTE BIT 8            62618501
         BZ    TDEDTEST                 BRANCH IF SET                   62619001
*                                                                       62619501
*                                                                       62620001
**       SET TARGET DED IN THE CURRENT DICTIONARY ENTRY                 62620501
*                                                                       62621001
*                                                                       62621501
*                                                                       62622001
         MVC   XDFMCTDD,TDEDFBDD        SET TARGET DED                  62622501
*                                                                       62623001
*                                                                       62623501
         CLC   XDFMCDAT(3),XDFMCTDD     TEST IF SOURCE AND TARGET EQUAL 62624001
         BE    TDEDTYPC                 IF SO BRANCH                    62624501
*                                                                       62625001
         MVI   XDFMCTYP,X'00'           SET TYPE BYTE TO ZERO           62625501
         B     TDEDEXIT                                                 62626001
*                                                                       62626501
TDEDTYPC MVI   XDFMCTYP,X'C0'           SET TYPE BYTE BITS 1 & 2        62627001
*                                                                       62627501
*                                                                       62628001
         B     TDEDEXIT                 BRANCH TO EXIT                  62628501
*                                                                       62629001
*                                                                       62629501
*                                                                       62630001
TDEDTSDD TM    XDFMCTYP,TDEDTYP1        TEST TYPE BYTE FOR X'C0'        62630501
         BM    TDEDTCHN                 BRANCH IF NOT X'C0'             62631001
*                                                                       62631501
*                                                                       62632001
TDEDTEST CLC   XDFMCTDD,TDEDFBDD        TEST IF TARGET DED AS REQUIRED  62632501
         BE    TDEDEXIT                 IF SO EXIT                      62633001
*                                                                       62633501
*                                                                       62634001
TDEDTCHN MVI   TDEDFLAG,X'FF'           SET TDEDFLAG ON                 62634501
         MVC   TDEDSHSH,XDFMCHCH        STORE CHAIN DICT REF            62635001
         CLC   XDFMCHCH,=H'0'           TEST IF END OF CHAIN            62635501
         BE    TDEDBLDF                 IF SO SKIP NEXT TEST            62636001
         MVC   TDEDDREF,TDEDSHSH        RESET DICT REF SLOT             62636501
*                                                                       62637001
         LR    GR7,GR6                  STORE REG GR6 AS DICT ENTRY     62637501
*                                         POINTED AT IS STILL IN STORE  62638001
*                                                                       62638501
         GETDICT TDEDSHSH,GR6           GET NEXT ENTRY IN CHAIN         62639001
*                                                                       62639501
         CLC   XDFMLNTH,TDED000E        TEST IF LENGTH IS 14            62640001
         BE    TDEDBLDE                 IF SO BRANCH                    62640501
*                                                                       62641001
         CLC   XDFMLNTH,1(GR7)          TEST DICT ENTRIES HAVE SAME     62641501
*                                           LENGTH                      62642001
         BNE   TDEDBLDE                 BRANCH IF NOT                   62642501
         MVC   TDEDHWWS,XDFMLNTH        )                               62643001
         LH    GR1,TDEDHWWS             ) CALCULATE LENGTH OF BCD       62643501
         SH    GR1,TDED000F             ) FOR CLC                       62644001
*                                                                       62644501
         STC   GR1,*+5                  SET FIELD LENGTH IN FOLLOWING   62645001
*                                         INSTRUCTION                   62645501
*                                                                       62646001
         CLC   XDFMCODE+14(0),14(GR7)   COMPARE BCD'S OF LAST AND       62646501
*                                         CURRENT DICT ENTRIES          62647001
         BE    TDEDMAIN                 BRANCH IF SAME TO SEE IF THIS   62647501
*                                         DICT ENTRY CAN BE USED        62648001
*                                                                       62648501
*                                                                       62649001
**       BUILD A NEW ENTRY                                              62649501
*                                                                       62650001
*                                                                       62650501
TDEDBLDE LR    GR6,GR7                  RESET GR6 TO LAST ENTRY         62651001
*                                                                       62651501
TDEDBLDF MVC   TDEDSSDD,XDFMCDAT        SET SOURCE DED                  62652001
         MVC   TDEDSLNT,XDFMLNTH        SET ENTRY LENGTH                62652501
*                                                                       62653001
*                                                                       62653501
         CLC   TDEDSSDD,TDEDFBDD        TEST IF SOURCE AND TARGET EQUAL 62654001
         BE    TDEDBTPC                 IF SO BRANCH                    62654501
*                                                                       62655001
         MVI   TDEDSTYP,X'00'           SET TYPE BYTE TO ZERO           62655501
         B     TDEDMCNT                                                 62656001
*                                                                       62656501
TDEDBTPC MVI   TDEDSTYP,X'C0'           SET TYPE BYTE BITS 1 & 2        62657001
*                                                                       62657501
TDEDMCNT MVC   TDEDHWWS,XDFMLNTH        )                               62658001
         LH    GR1,TDEDHWWS             ) CALCULATE LENGTH OF BCD       62658501
         SH    GR1,TDED000F             )  FOR MVC                      62659001
*                                                                       62659501
         STC   GR1,*+5                  SET FIELD LENGTH IN FOLLOWING   62660001
*                                         INSTRUCTION                   62660501
*                                                                       62661001
         MVC   TDEDSBCD(0),14(GR6)      MOVE BCD TO NEW SKELETON        62661501
*                                                                       62662001
         LA    GR1,TDEDSCOD             ) SET UP                        62662501
         ST    GR1,PAR1                 ) PARAMETERS                    62663001
         MVC   PAR2(2),=H'0'            )                               62663501
         MVC   PAR2+2(2),TDEDSLNT       ) AND                           62664001
*                                       ) MAKE A                        62664501
         L     LR,ZDICRF                ) DICTIONARY                    62665001
         BALR  RR,LR                    ) ENTRY                         62665501
*                                                                       62666001
         MVC   XDFMCHCH,PAR1+2          RESET HASH CHAIN                62666501
         MVC   TDEDDREF,PAR1+2          RESET DICT REF                  62667001
*                                                                       62667501
TDEDMODT MVI   TDEDFLAG,X'00'           RESET TDEDFLAG OFF              62668001
         XC    LOCK,LOCK                CLEAR LOCK SLOT                 62668501
*                                                                       62669001
         L     GR1,TDEDPARS+4           RESET APPROPRIATE SLOT IN XMAP  62669501
         MVC   0(2,GR1),TDEDDREF                                        62670001
*                                                                       62670501
*                                                                       62671001
**             OBTAIN RELEVENT TEXT REF                                 62671501
*                                                                       62672001
         L     GR1,TDEDPARS             LOAD ADDRESS OF TEXT REF.       62672501
         MVC   TDEDPARS+1(3),0(GR1)     STORE TEXT REF IN TDEDPARS      62673001
       IEMKTAB DR,XLCRTXT,SA=TDEDPARS+1,AATO=(GRXTRP)                   62673501
*                                                                       62674001
         USING XTRP,GRXTRP              BASE XTRP DSECT                 62674501
*                                                                       62675001
         MVC   XTRPOP2,TDEDDREF         RESET OP2 TO NEW DICT ENTRY     62675501
*                                                                       62676001
*                                                                       62676501
TDEDEXIT CLI   TDEDFLAG,X'FF'           TEST IF TDEDFLAG ON             62677001
         BE    TDEDMODT                 IF SO BRANCH                    62677501
         LA    RC,4                     SET RC WITH CORRECT VALUE       62678001
*                                                                       62678501
TDEDEEXT IEMKLVE  RC=(RC)                                               62679001
*                                                                       62679501
*                                                                       62680001
TDEDPARS DC    2F'0'                    PARAMETER STORAGE AREA          62680501
TDED000E DC    H'14'                    DICT ENTRY LENGTH WITH NO BCD   62681001
TDED000F DC    H'15'                    FOR LENGTH CALC FOR             62681501
*                                          MVC AND CLC                  62682001
TDEDHCHN DC    H'0'                                                     62682501
TDEDHWWS DC    H'0'                     WORK SPACE                      62683001
TDEDDREF DC    H'0'                     DICT REF OF USABLE ENTRY        62683501
*                                                                       62684001
*                                                                       62684501
*                                                                       62685001
**             DICTIONARY ENTRY SKELETON                                62685501
*                                                                       62686001
*                                                                       62686501
TDEDFLAG DC    X'0'                     FLAG BYTE TO SHOW WHETHER DR    62687001
*                                         IN TEXT HAS TO BE CHANGED     62687501
*                                                                       62688001
TDEDSCOD DC    X'88'                    CODE                            62688501
TDEDSLNT DC    XL2'0'                   LENGTH                          62689001
TDEDSHSH DC    XL2'0'                   HASH CHAIN                      62689501
TDEDSSDD DC    XL3'0'                   SOURCE DED                      62690001
TDEDSTYP DC    X'00'                    TYPE                            62690501
TDEDFBDD DC    X'9C1F80'                TARGET DED                      62691001
         DC    XL2'0'                   FILL                            62691501
TDEDSBCD DC    XL8'0'                   BCD AREA PLUS SPARE             62692001
*                                                                       62692501
*                                                                       62693001
*                                                                       62693501
TDEDTYP1 EQU   X'C0'                                                    62694001
TDEDTYP2 EQU   X'01'                                                    62694501
*                                                                       62695001
*                                                                       62695501
         LTORG                                                          62696001
         EJECT                                                          62696501
*                                                                       62700001
**       THIS ROUTINE SEARCHES THE USE LIST TO SEE IF THE GIVEN         62800001
**       DICTIONARY REFERENCE IS CONTAINED IN THIS LIST.  A RETURN      62900001
**       CODE VALUE IS GIVEN AS FOLLOWS:-                               63000001
**             4    NOT IN USE LIST                                     63100001
**             8    IN 'ASSIGNED TO' PART OF USE LIST                   63200001
**             C    IN 'INVARIANT'PART OF USE LIST                      63300001
**       ON ENTRY PR1 CONTAINS ADDRESS CONTAINING  DICTIONARY REFERENCE 63400001
**       ON EXIT PR1 CONTAINS ADDRESS OF VARIABLE IN USE LIST IF IT     63430001
**       IS PRESENT                                                     63460001
*                                                                       63500001
KJSRUSEL IEMKENT                                                        63600001
         LR    GRY,PR1                  STORE PR1 VALUE                 63700001
*                                                                       63800001
         USING XUSE,GRXUSE              BASE USE LIST DSECT             63900001
*                                                                       64000001
*                                                                       64100001
         LA    RC,USELNINL              INITIALIZE RETURN CODE          64200001
*                                                                       64300001
         CLI   XMAPUSEL,USELLEND        CHECK THAT A USE LIST EXISTS    64400001
         BE    USELEXIT                 BRANCH IF NO LIST               64500001
*                                                                       64600001
**             SET UP PARAMETERS TO INITIALIZE USE LIST SCAN            64700001
*                                                                       64800001
       IEMKTAB SET,XLCRUSE,SA=XMAPUSEL                                  64900001
*                                                                       65000001
USELNEXT DS    0H                                                       65060001
       IEMKTAB SCAN,XLCRUSE,AATO=(GRXUSE)              GET NEXT ELEMENT 65120001
*                                                                       65200001
**       GRXUSE BASES XUSE DSECT                                        65300001
*                                                                       65400001
*                                                                       65500001
         CLI   XUSECODE,XUSELEND        TEST FOR END OF LIST            65600001
         BE    USELSTEX                 BRANCH ON END OF LIST           65700001
*                                                                       65800001
         CLC   XUSEDREF,0(GRY)          COMPARE DICTIONARY REFERENCE    65900001
*                                         GIVEN WITH THAT IN USE LIST   66000001
         BNE   USELNEXT                 BRANCH IF NOT EQUAL             66100001
*                                                                       66200001
*                                                                       66220001
         LR    PR1,GRXUSE               STORE POSN OF ELEMENT           66240001
*                                                                       66260001
         LA    RC,USELASSN              SET RETURN CODE FOR ELEMENT     66300001
*                                         'ASSIGNED TO'                 66400001
*                                                                       66500001
         TM    XUSECODE,XUSEASSN        TEST IF VARIABLE 'ASSIGNED TO'  66600001
         BO    USELEXIT                 BRANCH IF 'ASSIGNED TO'         66700001
*                                                                       66800001
         LA    RC,USELINVR              SET RETURN CODE FOR ELEMENT     66900001
*                                         'INVARIANT'                   67000001
*                                                                       67100001
USELEXIT ST    RC,USELRCST              STORE RC TEMPORARILY            67120001
       IEMKTAB DEACT,(XLCRUSE)                                          67140001
*                                                                       67160001
         L     RC,USELRCST              RESET RC                        67180001
*                                                                       67200001
         IEMKLVE  RC=(RC)                                               67250001
*                                                                       67300001
*                                                                       67310001
*              RESET RC IN CASE SET OR SCAN CHANGE ITS VALUE            67320001
USELSTEX LA    RC,USELNINL              SET RC, DR NOT FOUND IN USELIST 67330001
         B     USELEXIT                                                 67340001
*                                                                       67350001
*                                                                       67400001
*                                                                       67500001
USELNINL EQU   X'04'                    VARIABLE NOT IN USE LIST        67600001
USELASSN EQU   X'08'                    VARIABLE IS ASSIGNED TO         67700001
USELINVR EQU   X'0C'                    VARIABLE IS INVARIANT           67800001
USELLEND EQU   X'FF'                    NO USE LIST                     67900001
*                                                                       68000001
USELRCST DC    F'0'                     RETURN CODE TEMP STORAGE        68050001
*                                                                       68100001
         LTORG                                                          68200001
         EJECT                                                          68300001
*                                                                       68400001
**       THIS ROUTINE EXAMINES AN OPERAND OF A TRIPLE AND SETS FLAGS    68500001
**       IN A CODE BYTE GIVING THE INFORMATION REQUIRED ON THE OPERAND  68600001
**       DURING THE ANALYSIS OF THE EXPRESSION WITHIN WHICH IT OCCURS.  68700001
**       ON ENTRY THE ADDRESS OF THE OPERAND IN THE TRIPLE IS PASSED    68800001
**       IN PR1.  PR1 REMAINS UNALTERED FOR USE IN KJSRUSEL.            68900001
**       ON EXIT THE CODE BYTE IS HELD IN THE LEAST SIGNIFICANT EIGHT   69000001
**       BITS OF PR0.                                                   69100001
*                                                                       69200001
*                                                                       69300001
KJSRSOPC IEMKENT                                                        69400001
*                                                                       69500001
         USING XDFM,GRXDFM              BASE DICTIONARY ENTRY DSECT     69600001
*                                                                       69700001
*                                                                       69800001
         XC    SOPCCODE,SOPCCODE        CLEAR CODE WORK SPACE           69900001
*                                                                       70000001
         LR    GROPR,PR1                LOAD ADDRESS OF OPERAND         70100001
         CLC   0(2,GROPR),=H'0'         TEST IF OPERAND IS X'00'        70200001
         BNE   SOPCCONS                 BRANCH IF NOT X'00'             70300001
*                                                                       70400001
         OI    SOPCCODE,KJOCZERO        SET X'00' FLAG                  70500001
         B     SOPCEXIT                 BRANCH, TEST COMPLETED          70600001
*                                                                       70700001
         EJECT                                                          70800001
*                                                                       70900001
**       TEST FOR CONSTANT OPERAND                                      71000001
*                                                                       71100001
SOPCCONS MVC   PAR1+2(2),0(GROPR)       LOAD PAR1 WITH DICT. REF.       71200001
         L     LR,ZDRFAB                CALL ZDRFAB TO CONVERT DICT.    71300001
         BALR  RR,LR                      REF. TO ABSOLUTE ADDRESS      71400001
*                                                                       71500001
         L     GRXDFM,PAR1              LOAD XDFM DSECT BASE REGISTER   71600001
         CLI   XDFMCODE,XDFMCONS        EXAMINE DICT. CODE BYTE FOR     71700001
*                                         CONSTANT ENTRY                71800001
         BNE   SOPCEXUS                 BRANCH IF NOT A CONSTANT        71900001
*                                                                       72000001
         OI    SOPCCODE,KJOCCNST        SET CONSTANT FLAG               72100001
*                                                                       72200001
         CLI   XDFMCSCE,XDFMCINT        TEST FOR INTEGER CONSTANT       72300001
         BNE   SOPCBCON                 BRANCH IF NOT INTEGER           72400001
*                                                                       72500001
         CLI   XDFMCDAT,XDFMCDEC        TEST FOR FIXED DECIMAL          72600001
         BNE   SOPCBCON                 BRANCH IF NOT                   72700001
*                                                                       72800001
         CLC   XDFMLNTH,SOPCLNBL        TEST IF BCD IS PRESENT          72900001
         BE    SOPCBCON                 BRANCH IF NOT                   73000001
*                                                                       73100001
         TM    XDFMCTYP,XDFMCBCD        TEST BCD IS IN EXTERNAL FORM    73200001
         BZ    SOPCEXIT                 BRANCH IF SO, TESTS COMPLETE    73300001
*                                                                       73400001
SOPCBCON OI    SOPCCODE,KJOCUNOP        SET FLAG STATING OPERAND IS     73500001
*                                         UNSUITABLE FOR OPTIMISATION   73600001
         B     SOPCEXIT                 BRANCH TO EXIT                  73700001
*                                                                       73800001
         EJECT                                                          73900001
*                                                                       74000001
SOPCEXUS LR    PR1,GROPR                RESET PR1                       74100001
         BAL   RR,KJSRUSEL              CALL KJSRUSEL TO SEE IF GIVEN   74200001
*                                         DICT. REF. IS IN USE LIST.    74300001
*                                         PR1 IS ALREADY LOADED         74400001
*                                                                       74500001
SOPCBTAB B     SOPCBTAB(RC)             BRANCH ACCORDING TO RETURN CODE 74600001
         B     SOPCEXAM                 DICT. REF. NOT IN USE LIST      74700001
         B     SOPCASSN                 IN USE LIST - ASSIGNED TO       74800001
*                                       IN USE LIST - INVARIANT         74900001
**                                      RETURN ADDRESS OF ITEM IN USE   74930001
**                                        LIST IN PR1                   74960001
*                                                                       75000001
*                                                                       75100001
**       TEST FOR CONTROL VARIABLE                                      75200001
*                                                                       75300001
SOPCCONV CLC   XMAPCVDR(2),0(GROPR)     CHECK FOR OPERAND BEING THE CV  75400001
         BNE   SOPCINVR                 BRANCH IF NOT CV                75500001
*                                                                       75600001
         OI    SOPCCODE,KJOCCONV        SET CONTROL VARIABLE FLAG       75700001
*                                                                       75800001
         B     SOPCASSN                                                 75900001
*                                                                       76000001
SOPCINVR OI    SOPCCODE,KJOCINVR        SET INVARIANT FLAG              76100001
*                                                                       76200001
SOPCASSN LR    GRXUSE,PR1                                               76240001
         USING XUSE,GRXUSE                                              76280001
*                                                                       76320001
         TM    XUSECODE,XUSEUNSF        TEST IF VARIABLE IS UNSAFE      76360001
         BZ    SOPCEXIT                 BRANCH IF SAFE                  76430001
         OI    SOPCCODE,KJOCUNSF        SET UNSAFE FLAG                 76500001
         B     SOPCEXIT                                                 76550001
*                                                                       76600001
*                                                                       77300001
**             EXAMINE CODE BYTE FOR SCALAR VARIABLE                    77400001
*                                                                       77500001
SOPCEXAM CLI   XDFMCODE,XDFMCD0F                                        77600001
         BE    SOPCCHDA                 BRANCH IF CODE '0F' FOUND       77700001
*                                                                       77800001
         CLI   XDFMCODE,XDFMCD8F        CHECK IF COMPILER CREATED, AND  77900001
         BE    SOPCCHDA                   IF SO BRANCH                  78000001
*                                                                       78100001
         CLI   XDFMCODE,XDFMCDAF        CHECK IF COMPILER CREATED, AND  78200001
         BE    SOPCCHDA                   AND IF SO BRANCH              78300001
*                                                                       78400001
         CLI   XDFMCODE,XDFMCD2F                                        78500001
         BNE   SOPCUNOP                 BRANCH IF OTHER THAN '2F'       78600001
*                                                                       78700001
**             EXAMINE DATA BYTE FOR REAL FIXED BINARY VARIABLE         78800001
*                                                                       78900001
SOPCCHDA CLI   XDFMFDAT,XDFMFSFB                                        79000001
         BE    SOPCCHIN                 BRANCH IF SHORT REAL FIX BIN    79100001
*                                                                       79200001
         CLI   XDFMFDAT,XDFMFLFB                                        79300001
         BNE   SOPCUNOP                 BRANCH IF NOT LONG REAL FIX BIN 79400001
*                                                                       79500001
**             EXAMINE DATA INFORMATION FOR INTEGER VARIABLE            79600001
*                                                                       79700001
SOPCCHIN CLI   XDFMFSCA,XDFMFINT                                        79800001
         BNE   SOPCUNOP                 BRANCH IF NOT INTEGER           79900001
*                                                                       80000001
*                                                                       80100001
*                                                                       80200001
         B     SOPCSAFE                                                 80400001
*                                                                       80500001
*                                                                       80600001
SOPCUNOP OI    SOPCCODE,KJOCUNOP        SET UNOPTIMISABLE FLAG          80700001
*                                                                       80800001
*                                                                       80900001
**             TEST FOR SAFE/UNSAFE VARIABLE                            81000001
*                                                                       81100001
SOPCSAFE TM    XDFMFSBT,XDFMUNSF                                        81200001
         BZ    SOPCEXIT                 BRANCH IF SAFE                  81300001
*                                                                       81400001
         OI    SOPCCODE,KJOCUNSF        SET UNSAFE FLAG                 81500001
*                                                                       81600001
*                                                                       81700001
**             COPY SOPCCODE TO EXIT PARAMETER                          81800001
*                                                                       81900001
SOPCEXIT IC    PR0,SOPCCODE                                             82000001
*                                                                       82100001
         IEMKLVE                                                        82200001
*                                                                       82300001
*                                                                       82400001
SOPCCODE DC    X'0'                      WORKING CODE BYTE              82500001
SOPCLNBL DC    H'14'                    LENGTH OF CONSTANT DICTIONARY   82600001
*                                         ENTRY WITH NO BCD             82700001
*                                                                       82800001
*                                                                       82900001
         LTORG                                                          83000001
         EJECT                                                          83100001
*                                                                       83200001
**       THIS ROUTINE EXAMINES THE OPERANDS OF THE TRIPLES WITHIN THE   83300001
**       CONTEXT OF EVALUATING THE TYPE OF EXPRESSION UNDER             83400001
**       CONSIDERATION                                                  83500001
**       ON ENTRY PR1 POINTS TO THE START OF THE TRIPLE, AND            83600001
**                PR0 CONTAINS A FLAG STATING WHICH OF THE TWO ENTRY    83700001
**       POINTS IS REQUIRED,                                            83800001
**       PR0=0 FOR BOTH OPERANDS                                        83900001
**       PR0=FF FOR SECOND OPERAND ONLY                                 84000001
**       THE RESULTS OF THE ROUTINE ARE PLACED IMMEDIATELY IN KJEXFLAG. 84100001
*                                                                       84200001
KJSRCHKP IEMKENT                                                        84300001
*                                                                       84400001
*                                                                       84500001
*                                                                       84600001
         LR    GRXTRP,PR1               STORE ADDRESS OF TRIPLE         84700001
         STC   PR0,CHKPFLAG             STORE FIRST/SECOND FLAG         84800001
         CLI   CHKPFLAG,X'00'           TEST FIRST/SECOND FLAG          84900001
         BNE   CHKPOPR2                 BRANCH IF SECOND OPERAND        85000001
*                                                                       85100001
         LA    PR1,XTRPOP1              SET PR1 TO START OF OPERAND 1   85200001
         B     CHKPOPCD                 BRANCH TO SET OPCODE            85300001
*                                                                       85400001
CHKPOPR2 LA    PR1,XTRPOP2              SET PR1 TO START OF OPERAND 2   85500001
*                                                                       85600001
CHKPOPCD BAL   RR,KJSRSOPC              BRANCH TO SET OP CODE BYTE FOR  85700001
*                                         OPERAND IN PR1                85800001
*                                                                       85900001
         STC   PR0,CHKPCODE             STORE OP CODE BYTE LOCALLY      86000001
*                                                                       86100001
         TM    CHKPCODE,KJOCZERO                                        86200001
         BO    CHKPBRNH                 BRANCH IF OPERAND IS '00'       86300001
*                                                                       86400001
         TM    CHKPCODE,KJOCCNST                                        86500001
         BC    BNO,CHKPOPRN             BRANCH IF NOT A CONSTANT        86600001
*                                                                       86700001
         TM    CHKPCODE,KJOCUNOP        CHECK IF CONSTANT IS SUITABLE   86800001
         BC    BNO,CHKPBRNH               FOR OPTIMISATION AND BRANCH   86900001
*                                         IF USABLE                     87000001
*                                                                       87100001
         OI    KJEXFLAG,KJEXVARE+KJEXUCOM    SET EXPRESSION VARIABLE    87200001
*                                            AND UNCOMMONABLE FLAGS     87300001
         B     CHKPBRNH                 BRANCH TO END OF OPERAND TEST   87400001
*                                                                       87500001
*                                                                       87600001
CHKPOPRN TM    CHKPCODE,KJOCUNSF        TEST IF OPERAND IS UNSAFE       87700001
         BC    BNO,CHKPSAFE             BRANCH IF SAFE                  87800001
*                                                                       87900001
         OI    KJEXFLAG,KJEXUNSF        SET EXPRESSION UNSAFE FLAG      88000001
*                                                                       88100001
CHKPSAFE TM    CHKPCODE,KJOCUNOP        TEST IF VARIABLE IS NICE        88200001
         BZ    CHKPCHCV                 IF SO BRANCH                    88300001
*                                                                       88400001
         OI    KJEXFLAG,KJEXVARE+KJEXUCOM    SET EXPRESSION VARIABLE    88500001
*                                            AND UNCOMMONABLE FLAGS     88600001
         B     CHKPBRNH                                                 88700001
*                                                                       88800001
*                                                                       89000001
*                                                                       89100001
*                                                                       89200001
CHKPCHCV TM    CHKPCODE,KJOCCONV        TEST IF OPERAND IS CONT. VAR.   89300001
         BO    CHKPCONV                 BRANCH IF CONTROL VARIABLE      89400001
*                                                                       89500001
         TM    CHKPCODE,KJOCINVR        TEST IF OPERAND IS INVARIANT    89600001
         BO    CHKPINVR                 BRANCH IF INVARIANT             89700001
*                                                                       89800001
CHKPVARE OI    KJEXFLAG,KJEXVARE        SET EXPRESSION VARIABLE FLAG    89900001
*                                                                       90000001
         LH    GRY,KJOPEXPR             * INCREMENT                     90100001
         LA    GRY,1(0,GRY)             * KJOPEXPR                      90200001
         STH   GRY,KJOPEXPR             * BY ONE                        90300001
         B     CHKPBRNH                                                 90400001
*                                                                       90500001
*                                                                       90600001
CHKPINVR TM    KJEXFLAG,KJEXINVR        TEST IF FIRST INVARIANT         90700001
         BO    CHKPINEX                 BRANCH IF NOT                   90800001
*                                                                       90900001
         OI    KJEXFLAG,KJEXINVR        SET EXPRESSION INVARIANT FLAG   91000001
*                                                                       91100001
         TM    KJEXFLAG,KJEXCONV        TEST IF CV ALSO PRESENT         91200001
         BC    BNO,CHKPBRNH             BRANCH IF NOT                   91300001
*                                                                       91400001
CHKPINEX LA    GRY,2                    * SET KJOPEXPR                  91500001
         STH   GRY,KJOPEXPR             * EQUAL TO TWO                  91600001
         B     CHKPBRNH                                                 91700001
*                                                                       91800001
*                                                                       91900001
CHKPCONV TM    KJEXFLAG,KJEXCONV        TEST IF FIRST CONTROL VARIABLE  92000001
         BO    CHKPVARE                 BRANCH IF NOT                   92100001
         OI    KJEXFLAG,KJEXCONV        SET CONTROL VARIABLE FLAG       92200001
*                                                                       92300001
         TM    KJEXFLAG,KJEXINVR        TEST IF INV ALSO PRESENT        92400001
         BO    CHKPINEX                 BRANCH IF PRESENT               92500001
*                                                                       92600001
*                                                                       92700001
*                                                                       92800001
CHKPBRNH CLI   CHKPFLAG,X'00'           CHECK IF FIRST OPERAND          92900001
         BNE   CHKPEXIT                 BRANCH IF SECOND                93000001
*                                                                       93100001
         MVC   KJOPRND1,CHKPCODE        SET OPERNAD 1 CODE BYTE         93200001
         OI    CHKPFLAG,X'FF'           SET CHKPFLAG FOR SECOND OPRND   93300001
         B     CHKPOPR2                 BRANCH TO EXAMINE SECOND OPRND  93400001
*                                                                       93500001
*                                                                       93600001
CHKPEXIT MVC   KJOPRND2,CHKPCODE        SET OPERAND 2 CODE BYTE         93700001
*                                                                       93800001
         IEMKLVE                                                        93900001
*                                                                       94000001
*                                                                       94100001
*                                                                       94200001
CHKPFLAG DC    X'0'                     FIRST/SECOND OPERAND FLAG       94300001
CHKPCODE DC    X'0'                     WORKING CODE BYTE               94400001
*                                            FLAGS AS FOR KJOPFLAG      94500001
*                                                                       94600001
*                                                                       94700001
         LTORG                                                          94800001
         EJECT                                                          94800621
*                                                                       94801221
**       THIS ROUTINE TESTS AN ARRAY PARAMETER TO DETERMINE             94801821
**       WHETHER IT MAY BE CONSIDERED IN SUBSCRIPT OPTIMISATION.        94802421
**       A CHECK IS MADE OF THE CONTAINING PROCEDURE, SPECIFYING        94803021
**       THIS ARRAY IN ITS PARAMETER LIST, TO DETERMINE WHETHER         94803621
**       THERE IS MORE THAN ONE ENTRY POINT.  IF THE PARAMETER IS       94804221
**       NOT SPECIFIED IN ALL THE ENTRY LISTS, THEN IT IS NOT           94804821
**       SAFE TO CARRY OUT SUBSCRIPT OPTIMISATION ON IT.                94805421
**                                                                      94806021
**       ON ENTRY, REGISTER 1 POINTS AT THE PARAMETER DIC. ENTRY        94806621
**                 REGISTER 2 POINTS TO ONE BYTE BEFORE DIC. REF. 49793 94807256
**       ON EXIT,  A RETURN CODE IS GIVEN AS FOLLOWS:-                  94807821
**                 0 - PARAMETER NOT GIVEN AT ALL ENTRY POINTS.         94808421
**                 4 - PARAMETER OK FOR OPTIMISATION.                   94809021
**                 REGISTERS 1 AND 2 ARE RETURNED UNALTERED.            94809621
         SPACE 1                                                        94810221
         SPACE 1                                                        94810821
KJSRTPRM IEMKENT                                                        94811421
         MVC   LOCK(2),1(GR2)           LOCK IN DIC. BLOCK        49793 94812056
*                                     CONTAINING PARAM. DIC ENTRY 40061 94812621
         LR    GR2,GRX                  STORE REG 1 VALUE         40061 94813221
         SPACE 1                                                        94813821
TPRMLKFP TM    0(GR2),TPRMABCD          IS A BCD ATTACHED         40061 94814421
         BO    TPRMFPDE                 IF NOT, GO TO PICK UP     40061 94815021
*                                     FORMAL PARAMETER ENTRY.     40061 94815621
         TM    0(GR2),TPRMSTRC          TEST FOR STRUC MEMBER     40061 94816221
         BNO   TPRMNOPT                                           40061 94816821
         TM    TPRMOOT4(GR2),TPRMMSTR   IS IT MAJOR STRUC         40061 94817421
         BO    TPRMNOPT                                           40061 94818021
         LA    GR3,TPRMOSDE(GR2)        POINT                     40061 94818621
         TM    0(GR2),TPRMSBEL                                    40061 94819221
         BNO   TPRMNBEL                   AT                      40061 94819821
         LA    GR3,6(GR3)                                         40061 94820421
TPRMNBEL TM    0(GR2),TPRMDIMD              STRUCTURE             40061 94821021
         BNO   TPRMNDIM                                           40061 94821621
         LA    GR3,3(GR3)                     INFORMATION         40061 94822221
TPRMNDIM MVC   PAR1+2(2),2(GR3)         PICK UP DIC REF OF        40061 94822821
*                                     CONTAINING STRUCTURE.       40061 94823421
         L     LR,ZDRFAB                                          40061 94824021
         BALR  RR,LR                                              40061 94824621
         L     GR2,PAR1                                           40061 94825221
         B     TPRMLKFP                 CONTINUE SCAN FOR MAJOR   40061 94825821
*                                     STRUC WITH F.P. DIC REF.    40061 94826421
         SPACE 1                                                        94827021
TPRMFPDE MVC   TPRMFPDR(2),3(GR2)       SAVE DIC REF OF F.P.ENTRY 40061 94827621
         MVC   PAR1+2(2),3(GR2)                                   40061 94828221
         L     LR,ZDRFAB                POINT AT FORMAL PARAMETER 40061 94828821
         BALR  RR,LR                      DICTIONARY              40061 94829421
         L     GR2,PAR1                     ENTRY.                40061 94830021
         SPACE 1                                                        94830621
         MVC   TPRMFPLC(2),TPRMOFLC(GR2) SAVE F.P. LEVEL, COUNT   40061 94831221
         MVC   TPRMRET1(2),XMAPENT1     SAVE DIC REF OF E.T.1 OF  40061 94831821
*                                     BLOCK CONTAINING CURRENT ITDO     94832421
TPRMGET1 MVC   PAR1+2(2),TPRMRET1       POINT AT E.T.1            40061 94833021
         BALR  RR,LR                      DICTIONARY              40061 94833621
         L     GR3,PAR1                     ENTRY.                40061 94834221
         CLI   0(GR3),TPRMBEGN          IS IT BEGIN E.T.1         49793 94834856
         BNE   TPRMPET1                 NO - PROC E.T.1           40061 94835421
         MVC   TPRMRET1(2),TPRMOBCB(GR3) YES - SAVE DIC REF OF    40061 94836021
*                                     CONTAINING BLOCK            40061 94836621
         B     TPRMGET1                 RETURN, TO FIND E.T.1 OF  40061 94837221
*                                     CONTAINING PROC.            40061 94837821
         SPACE 1                                                        94838421
TPRMPET1 CLC   TPRMOPLC(2,GR3),TPRMFPLC COMPARE LEVEL AND COUNT   40061 94839021
*                                     WITH THOSE OF F.P.          40061 94839621
         BE    TPRMTENT                 IF SAME, GO TO TEST IF    40061 94840221
*                                     MORE THAN 1 ENTRY POINT.    40061 94840821
         CLC   TPRMOBCB(2,GR3),KJHWZERO IS THERE A CONTAINING BLK 40061 94841421
         BE    TPRMNOPT                 NO, RETURN                40061 94842021
         MVC   TPRMRET1(2),TPRMOBCB(GR3) SAVE E.T.1 DIC REF       40061 94842621
         B     TPRMGET1                                           40061 94843221
         SPACE 1                                                        94843821
TPRMTENT CLC   TPRMOPCC(2,GR3),TPRMRET1 IS NEXT E.T.1 IN CHAIN    40061 94844421
*                                     SAME AS CURRENT E.T.1       40061 94845021
         BE    TPRMYOPT                 IF SO, NO OTHER ENTRY PTS 40061 94845621
*                                     SO GO TO SET R.C. TO 4      40061 94846221
         SPACE 3                                                        94846821
*        MORE THAN ONE ENTRY POINT, SO CHECK NOW MADE TO ENSURE   40061 94847421
*        PARAMETER IS SPECIFIED AT EACH.                          40061 94848021
         SPACE 1                                                        94848621
TPRMNEXT LR    GR2,GR3                                            40061 94849221
         CLI   0(GR2),TPRMENTY          IS IT AN ENTRY E.T.1      40061 94849821
         BE    TPRMEET1                                           40061 94850421
         LA    GR2,TPRMOP52(GR2)        NO, PROC E.T.1            40061 94851021
TPRMEET1 LA    GR2,TPRMOE11(GR2)        POINT AT BYTE BEFORE      40061 94851621
*                                     NO. OF PARAMETERS.          40061 94852221
         SR    GR4,GR4                                            40061 94852821
         IC    GR4,1(GR2)               PICK UP NO. OF PARAMS*2   40061 94853421
         SRL   GR4,1                    DIVIDE BY 2               40061 94854021
         LTR   GR4,GR4                  IS PARAM COUNT ZERO       40061 94854621
         BZ    TPRMNOPT                 IF SO, PARAM NOT GIVEN AT 40061 94855221
*                                     CURRENT ENTRY POINT         40061 94855821
*                                     GO TO SET R.C. TO 0         40061 94856421
