KO       TITLE 'PL1F COMPILER. PHASE IEMKO. SUBSCRIPT OPTIMISATION.'    00030001
         SPACE 3                                                        00033001
*        FUNCTIONS -                                                    00036001
*                                                                       00039001
*                                                                       00042001
*                                                                       00045001
*        PHASE KO DEALS WITH THE WHOLE PROGRAM TEXT WORKING FROM THE    00048001
*        INNERMOST DO LOOP OUTWARDS ( SEE PHASE KN FOR MORE DETAILS ).  00051001
*              THREE TYPES OF OPTIMISATION ARE PERFORMED ON THE         00054001
*        SUBSCRIPT LIST GIVEN IN THE SUBS TABLE. THESE ARE:             00057001
*        P1.  CONTROL VARIABLE TRANSFORMATION FOR DO LOOPS.             00060001
*        P2.  MOVING OUT INVARIANT EXPRESSIONS FROM DO LOOPS.           00063001
*        P3.  COMMONING EXPRESSIONS.                                    00066001
*              ALL THREE PROCESSES INVOLVE MATCHING EXPRESSIONS, SO     00069001
*        THAT A VALUE CALCULATED ONCE MAY BE USED AT LATER OCCURENCES   00072001
*        OF THE SAME EXPRESSION.                                        00075001
*        FOR THE FIRST TWO PROCESSES THE RANGE OVER WHICH MATCHING IS   00078001
*        ATTEMPTED IS THE RANGE OF THE WHOLE LOOP. FOR COMMONING THE    00081001
*        RANGE IS BETWEEN COMMON REGION BOUNDARIES. THESE BOUNDARIES    00084001
*        ARE POINTS IN THE PROGRAM TEXT WHERE VARIABLES INVOLVED ARE,   00087001
*        OR COULD BE, ASSIGNED TO.                                      00090001
*              THE PHASE FIRST CALLS SUBROUTINE KPUPDT. THIS CREATES    00093001
*        ANY NECESSARY EXTENSION TO THE SUBS REGION TABLE CAUSED BY     00096001
*        THE MOVING OUT OF CODE FROM AN ENCLOSING LOOP.                 00099001
*              SUBROUTINE KOBXCH IS THEN CALLED TO PERFORM SOME         00102001
*        INITIALISATION FOR LOOP OPTIMISATION. IT CREATES SOME INITIAL  00105001
*        PATCHES USING INFORMATION IN THE DO MAP DESCRIBING WHAT, IF    00108001
*        ANY, LOOP CONTROL OPTIMISATION IS POSSIBLE.                    00111001
*              THE MAIN MATCHING AND OPTIMISING SUBROUTINE KNOPTM IS    00114001
*        THEN CALLED TWICE IN SUCCESSION, THE FIRST TIME WITH           00117001
*        XOPTOPFL SET FOR TRANSFORMING AND INVARIANCE, THE SECOND       00120001
*        TIME FOR COMMONING. TEXT ( IN THE FORM OF SUBSCRIPT COMAS )    00123001
*        USED FOR THE FIRST TWO PROCESSES IS MARKED AS DEALT WITH,      00126001
*        AND WILL THUS NOT BE CONSIDERED FOR COMMONING IN THE SECOND    00129001
*        CALL OF KNOPTM.                                                00132001
*              KNOPTM SCANS THE SUBS TABLE AND MAKES REFERENCES TO THE  00135001
*        PROGRAM TEXT OF THOSE SUBSCRIPT LISTS FOR WHICH THERE IS AN    00138001
*        ENTRY IN THE TABLE. WHENEVER A MATCHED EXPRESSION CROSSES A    00141001
*        REGION BOUNDARY DURING COMMONING, THE OPERANDS OF THE          00144001
*        MATCHED EXPRESSION ARE CHECKED TO SEE IF THIS IS THE END OF    00147001
*        THE COMMON REGION FOR THIS EXPRESSION.                         00150001
*              IN THE FIRST TWO PROCESSES , THERE IS NO NEED TO CHECK   00153001
*        THE REGION BOUNDARIES SINCE SUBSCRIPT EXPRESSIONS WHICH ARE    00156001
*        MARKED IN A SUBS TABLE ENTRY AS INVARIANT OR TRANSFORMABLE     00159001
*        HAVE ALREADY BEEN CHECKED AGAINST THE USE LIST BY THE SUBS     00162001
*        TABLE BUILD PHASE.                                             00165001
*              WHERE SEVERAL ADJACENT COMAS ARE OPTIMISABLE THEY ARE    00168001
*        CONSIDERED AS A SINGLE EXPRESSION. THE GENERAL RULE FOR        00171001
*        MATCHING IS TO SELECT THE LARGEST POSSIBLE EXPRESSIONS. A      00174001
*        COMA EXPRESSION IS THE SMALLEST UNIT FOR MATCHING.             00177001
*              IF A SUBSCRIPT LIST IS FOUND TO BE OPTIMISABLE THE       00180001
*        ORIGINAL TRIPLES IN THE TEXT WILL BE AMENDED BY SUBROUTINE     00183001
*        KOMTCH TO REFER TO A RESULT GENERATED IN A PATCH. THE PATCHES  00186001
*        ARE HELD IN SEPARATE TEXT BLOCKS AND MERGED INTO THE PROGRAM   00189001
*        TEXT BY PHASE KU.                                              00192001
*              IN THE CASE OF COMMONING THE PATCH IS INSERTED BEFORE    00195001
*        THE FIRST USE OF THE COMMONED EXPRESSION. FOR AN INVARIANT     00198001
*        THE PATCH IS INSERTED OUTSIDE THE LOOP IMMEDIATELY BEFORE THE  00201001
*        ITDO TRIPLE. FOR A TRANSFORM TWO PATCHES MUST BE GENERATED     00204001
*        ONE IS SET TO THE INITIAL VALUE OUTSIDE THE LOOP, THE OTHER    00207001
*        BUMPS THE TRANSFORMED CONTROL VARIABLE BY THE TRANSFORMED      00210001
*        STEP. THE BUMPING UP PATCH IS INSERTED AT THE END OF THE       00213001
*        DO GROUP.                                                      00216001
*                                                                       00219001
*                                                                       00222001
*                                                                       00225001
         SPACE 3                                                        00228001
*              ENTRY POINT - 'IEMKO' FROM COMPILER CONTROL TO START     00231001
*        PHASE                                                          00234001
         SPACE 3                                                        00237001
*              INPUT - TEXT IN FORM OF TRIPLES.                         00240001
*        POINTERS ETC FROM DATA AREA IN KA (XLCR).                      00243001
*        SUBS/REGION TABLE FOR THE CURRENT LOOP.                        00246001
*        DICTIONARY ENTRIES FOR CONSTANTS.                              00249001
         SPACE 3                                                        00252001
*              OUTPUT - INPUT TEXT MODIFIED IN PLACE. PATCHES CREATED   00255001
*        IN THE PATCH FILE ARE POINTED AT FROM TEXT.                    00258001
*                                                                       00261001
         SPACE 3                                                        00264001
*              EXTERNAL ROUTINES   (1) CONTROL PHASE. THE FOLLOWING     00267001
*        ENTRIES ARE USED -ZDRFAB,ZURC,RLSCTL,ZLOADX,RELESE.            00270001
*             (2) TABLE HANDLING ROUTINES(IEMKA). THE FOLLOWING ENTRIES 00273001
*        ARE USED - KAHDAC,KAHERR,KAHFRE,KAHMDR,KAHSCN,KAHSET,KAHTXT,   00276001
*        KAHUDR.                                                        00279001
         SPACE 3                                                        00282001
*              EXIT - NORMAL - TO 'RLSCTL' IN CONTROL PHASE TO RELEASE  00285001
*        PHASE AND LOAD NEXT.                                           00288001
*                  KO LOADS KP AND KQ WITH ZLOADX AND RELEASES THEM     00291001
*                  WITH RELESE. ON EXIT KO RELEASES ITSELF AND KA       00294001
*                  AND LOADS THE NEXT PHASE KT BY A CALL TO RLSCTL.     00297001
*                  JUST BEFORE EXIT KO RELEASES 4K OF SCRATCH           00300001
*                  WHICH WAS OBTAINED BY KB.                            00303001
         SPACE 3                                                        00306001
*              WORKAREA - 4K OF SCRATCH OBTAINED BY IEMKA.              00309001
*              ATTRIBUTES - THIS BLOCK IS NOT READ ONLY AND NOT         00312001
*        REENTRANT.                                                     00315001
         SPACE 3                                                        00318001
*              NOTES - (1) THIS PHASE REQUIRES NO MODIFICATION AS A     00321001
*        RESULT OF CHANGES IN THE INTERNAL REPRESENTATION OF EXTERNAL   00324001
*        GRAPHICS.                                                      00327001
*                      (2) THIS PHASE REQUIRES THE 'IEMK' MACROS FOR    00330001
*        ASSEMBLY.                                                      00333001
*                      (3) THIS PHASE CONSISTS OF 3 CONTROL SECTIONS    00336001
*        - 'IEMKO', 'IEMKP' AND 'IEMKQ'                                 00339001
         EJECT                                                          00342001
         MACRO                                                          00345001
&NAME    GETDICT &DICREF,&XDICBSE                                       00360001
*                                                                       00390001
&NAME    MVC   PAR1+2(2),&DICREF .      MOVE DIC.REF.TO PARAM FIELD     00420001
         L     LR,ZDRFAB .              LINK TO ZDRFAB                  00450001
         BALR  RR,LR .                  TO CONVERT DIC.REF. TO ABS      00480001
         L     &XDICBSE,PAR1 .          BASE XDIC DSECT                 00510001
*                                                                       00540001
         MEND                                                           00570001
         EJECT                                                          00600001
         COPY  IEMKCOM                                                  00690001
         COPY  IEMKUTL                                                  00750001
         COPY  IEMKEQU                                                  00790001
         COPY  IEMKDRF                                                  00830001
         COPY  IEMKLCR                                                  00860001
         COPY  IEMKMAP                                                  00890001
         COPY  IEMKPCH                                                  00920001
         COPY  IEMKSKL                                                  00950001
         COPY  IEMKSRT                                                  00980001
         COPY  IEMKTRP                                                  01010001
         COPY  IEMKYSR                                                  01040001
*                                                                       01080001
YTRP     DSECT                         DESCRIBLES TRIPLE FORMAT         01110001
YTRPCODE DS    X                       CODE BYTE                        01140001
YTRPOP1  DS    XL2                     FIRST OPERAND                    01170001
YTRPOP2  DS    XL2                     SECOND OPERAND                   01200001
*                                                                       01230001
*                                                                       01260001
         EJECT                                                          01290001
*                                                                       01320001
*                                                                       01350001
IEMKP    DSECT                          TRANSFER VECTOR MAP FOR IEMKP   01380001
         USING IEMKP,GR8                BASE OF IEMKP                   01390001
         DS    CL2                                                      01410001
KOBXCH   DS    2H                        CHECK IT. SPEC.FOR BXLE,BXH    01440001
KOMTCH   DS    2H                       PROCESS MATCH CHAIN             01470001
KOPTCH   DS    2H                       MAKE PATCH                      01500001
*                                                                       01560001
*                                                                       01590001
         EJECT                                                          01620001
IEMKQ    DSECT                          TRANSFER VECTOR MAP FOR IEMKQ   01650001
         USING IEMKQ,GR8                BASE OF IEMKQ                   01660001
*                                                                       01680001
         DS    CL2                      MODULE IDENTIFIER               01710001
KPUPDT   DS    2H                       UPDATE SUBS TABLE FROM PATCHES  01740001
         EJECT                                                          01770001
SCRATCH  DSECT                                                          01776001
         USING SCRATCH,GR7              BASE CODE AND DATA IN SCRATCH   01782001
         COPY  IEMKNDT                                                  01788001
*                                                                       01788901
** TRANSFER VECTOR MAP FOR ROUTINES IN SCRATCH  (MOVED BY KN)           01789801
*                                                                       01790701
KNTRTY   DS    2H                      TEST TRIPLE TYPE                 01791601
KOMOVE   DS    2H                      MOVE TO PATCH BUILD AREA         01792501
KOSNDX   DS    2H                      ALLOCATE A SNDX REGISTER         01793401
KOSSBS   DS    2H                      START OF A SSUB LIST             01794301
KOSSBE   DS    2H                      END OF A SSUB LIST               01795201
KOEROR   DS    2H                      ERROR ROUTINE                    01796101
KOCVTX   DS    2H                      TEST FOR CONTROL VARIABLE        01797001
KOMCHN   DS    2H                      PROCESS A MATCH CHAIN            01797901
         EJECT                                                          01798801
IEMKO    CSECT                                                          01800001
KONAME   DC    CL2'KO'                                                  01860001
         IEMKPLR KO,KOINIT,R,DL=KAKOZZ,LL=KTZZ                          01920001
         USING IEMKO,GR9                                                01990001
*                                                                       02040001
*                                                                       02070001
**  TRANSFER VECTOR FOR  KO                                             02100001
*                                                                       02130001
*                                                                       02400001
*                                                                       02430001
*                                                                       02460001
*                                                                       02490001
         B     KOMAKC                   MAKE COMPILE TIME CONSTANT      02500001
         B     KOCVTX                   TEST FOR CV IN MATCHED TRIPLES  02510001
         EJECT                                                          02520001
KOINIT   IEMKENT TYPE=2                                                 02580001
*                                                                       02640001
*                                                                       02670001
*                                                                       02940001
         L     GR7,XLCRASCR           BASE ADDRESS OF SCRATCH CORE IS   02970001
*                                       BASE OF KNDATA AND KNCODE       03000001
*                                                                       03150001
         MVC   XOPTPARM,XOPTC001+2     SET DEFAULT OF PARM TO 1         03160001
*                                                                       03180001
         L     GR6,XOPTXMAP            ADDRESS OF CURRENT XMAP ENTRY    03780001
       IEMKTAB DR,XLCRMAP,SA=XLCRFMAP,AATO=(GR5)                        04416001
         USING XMAP,GR5                                                 04419001
INITMOVE MVC   0(XMAPEND-XMAP,GR6),XMAP                                 04422001
         DROP  GR5                                                      04425001
         USING XMAP,GR6                 REFERENCES TO XMAP FIELDS NOW   04428001
*                                       ADDRESS THE CURRENT ENTRY IN    04431001
*                                       SCRATCH CORE                    04434001
*                                                                       04437001
*                                                                       04440001
*                                                                       04442001
*                                                                       04444001
*                                                                       04446001
*  SELECT MODULE IEMKP OR IEMKQ                                         04448001
*  IEMKP IS NORMALLY LOADED FOR MOST OF THE PROCESSING                  04450001
*  IEMKQ IS LOADED ONLY FOR DO LOOPS WHICH HAVE HAD CODE MOVED INTO     04452001
*  THEM FROM AN ENCLOSED OPTIMISED DO LOOP                              04454001
*                                                                       04456001
*                                                                       04458001
*                                                                       04460001
**  TEST CURRENT DO MAP ENTRY FOR PROC OR ITDO                          04470001
*                                                                       04500001
         CLI   XMAPLEVL,XMAPEQ00        LEVL=O FOR PROC                 04530001
         BE    INITTSLD                 BRANCH IF PROC                  04560001
*                                                                       04590001
         CLI   XMAPPTCH,XOPTEQFF        IS THERE A PATCH CHAIN          04620001
         BE    INITTSLD                 BRANCH IF NO CHAIN              04650001
*                                                                       04680001
         TM    XOPTSWCH,XOPTKPLD        TEST IF IEMKP LOADED            04710001
         BZ    INITNLOD                 BRANCH IF NOT LOADED            04740001
*                                                                       04770001
         LA    GR1,XOPTKPZZ                                             04800001
         ST    GR1,PAR1                  ADDRESS OF MODULE NAME         04830001
         L     LR,RELESE                MODULE IEMKP                    04860001
         BALR  RR,LR                                                    04890001
*                                                                       04920001
INITNLOD LA    GR1,XOPTKQZZ                                             04950001
         ST    GR1,PAR1                  ADDRESS OF MODULE NAME         04980001
         L     LR,ZLOADX                 LOAD MODULE IEMKQ              05010001
         BALR  RR,LR                                                    05040001
         L     GR8,PAR1                  LOAD BASE REG FOR IEMKQ        05070001
         USING IEMKQ,GR8                BASE MODULE IEMKQ               05100001
*                                                                       05130001
         BAL   RR,KPUPDT                UPDATE SUBS REGION TABLE        05160001
*                                       PATCH FILE                      05190001
         LA    GR1,XOPTKQZZ                                             05220001
         ST    GR1,PAR1                  ADDRESS OF MODULE NAME         05250001
         L     LR,RELESE                 RELESE MODULE IEMKQ            05280001
         BALR  RR,LR                                                    05310001
*                                                                       05340001
INITKPLD LA    GR1,XOPTKPZZ              ADDRESS OF MODULE NAME         05370001
         ST    GR1,PAR1                                                 05400001
         L     LR,ZLOADX                 LOAD MODULE IEMKP              05430001
         BALR  RR,LR                                                    05460001
         L     GR8,PAR1                                                 05490001
         USING IEMKP,GR8                BASE MODULE IEMKP               05550001
         OI    XOPTSWCH,XOPTKPLD        SET SWITCH - IEMKP LOADED       05580001
*                                                                       05610001
*                                                                       05640001
**  TEST CURRENT DO MAP ENTRY FOR PROC OR ITDO                          05670001
*                                                                       05700001
INITTSLP CLI   XMAPLEVL,XMAPEQ00        LEVL=O FOR PROC                 05730001
         BE    INITCOMM                 GO TO COMMONING OPTIMISATION    05760001
         B     INITBXCH                                                 05790001
*                                                                       05820001
INITTSLD TM    XOPTSWCH,XOPTKPLD        TEST IF IEMKP LOADED            05850001
         BZ    INITKPLD                 BRANCH IF NOT LOADED            05880001
         B     INITTSLP                                                 05910001
*                                                                       05940001
INITBXCH BAL   RR,KOBXCH               CHECK ITERATIVE SPEC             06000001
*                                                                       06060001
         MVI   XOPTOPFL,XOPTTRIV                                        06090001
         BAL   RR,KNOPTM                TRANSFORM AND INVARIANT MATCH   06120001
INITCOMM MVI   XOPTOPFL,XOPTCOMM        COMMONING MATCH                 06150001
         BAL   RR,KNOPTM                                                06210001
*                                                                       06240001
**  TEST FOR END OF DO MAP                                              06270001
*                                                                       06300001
INITENDT CLI   XMAPSEQU,XMAPEQFF                                        06330001
         BE    INITCLER                                                 06360001
*                                                                       06361001
*  MAKE AN ENTRTY IN THE PATCH FILE TO MARK THE END OF THE EXTERNAL     06362001
*  CHAIN OF PATCHES FOR THE CURRENT LOOP. THIS ENTRTY CONTAINS ONLY     06363001
*  'NOP EOP' . THE EXTERNAL CHAIN FOR THE CURRENT LOOP LINKS ALL        06364001
*  CODE WHICH HAS MOVED OUT OF THE CURRENT LOOP. THE CHAIN HEAD IS      06365001
*  IN THE ENCLOSING DO MAP ENTRY                                        06366001
*                                                                       06367001
*                                                                       06368001
**  TEST FOR PROC OR ITDO                                               06369001
*                                                                       06370001
         CLI   XMAPLEVL,XMAPEQ00                                        06370101
         BE    INITMVON                 BRANCH IF PROC                  06370201
*                                                                       06370301
** SAVE END OF ITD' PATCH CHAIN FOR THIS LOOP IN CASE IT MUST BE        06370401
** CONTINUED FOR THE BUMP CODE PATCH OF THE ENCLOSING LOOP              06370501
*                                                                       06370601
         MVC   XOPTPCH5,XOPTPCH2                                        06370701
*                                                                       06370801
** MAKE LONG USSL PATCH AT TRIPLE AFTER CLN2 AFTER CV'                  06370901
*                                                                       06371001
**  SCAN FOR CV'                                                        06371101
*                                                                       06371201
         IEMKTAB SET,XLCRTXT,SA=XMAPITDO     START SCAN AT ITDO TRIPLE  06371301
*                                                                       06371401
INITZZZZ IEMKTAB SCAN,XLCRTXT,AATO=(GR2)                                06371501
*                                                                       06371601
         CLI   0(GR2),XTRPCVP           TEST FOR CV'                    06371701
         BNE   INITZZZZ                                                 06371801
*                                                                       06371901
**  SCAN FOR CLN2                                                       06372001
INITCLN2 IEMKTAB  SCAN,XLCRTXT,AATO=(GR2),SATO=XOPTTADR                 06373101
         CLI   0(GR2),XTRPCLN2          TEST FOR CLN2                   06373201
         BNE   INITCLN2                                                 06373301
*                                                                       06373401
         IEMKTAB  SCAN,XLCRTXT,AATO=(GR2),SATO=XOPTTADR                 06373501
*                                                                       06373601
         LA    GR0,X'88'                MAKE PATCH                      06373701
         LA    GR2,X'13'                LENGTH OF LONG USSL  -1         06373801
         L     GR3,XOPTINDX             ADDRESS OF LONG USSL            06373901
**  XOPTTADR SET UP ALREADY BY SCAN                                     06374001
         BAL   RR,KOPTCH                                                06374101
*** GET ENCLOSING DO MAP ENTRY                                          06374201
*                                                                       06374301
INITXXXX EQU   *                                                        06374401
       IEMKTAB DR,XLCRMAP,SA=XMAPOUTR,AATO=(GR5)                        06376001
         DROP  GR6                                                      06377001
         USING XMAP,GR5                                                 06378001
         CLI   XMAPPTCH,XOPTEQFF       TEST IF AN EXTERNAL CHAIN EXISTS 06379001
         BE    INITMVON                 BRANCH IF NO CHAIN              06380001
*                                                                       06381001
         TM    XOPTOPTX,XOPTCHN1        TEST IF PATCH CHAIN EXISTS      06381201
*                                       ON THIS ITDO TRIPLE             06381401
         BZ    INITMVON                 BRANCH IF NO CHAIN              06381601
*                                                                       06381801
         DROP  GR5                                                      06382001
         USING XMAP,GR6                                                 06383001
*                                                                       06384001
         LA    GR0,X'11'                   PATCH TYPE = ITDO WITH MOVE  06385001
         LA    GR2,XOPTTRP5-1           LENGTH TRIPLE-                 06386001
         LA    GR3,XOPTEOPT             ADDRESS OF EOP TRIPLE           06387001
         BAL   RR,KOPTCH                MAKE PATCH                      06388001
*                                                                       06389001
         MVC   XOPTWKTX,XMAPKPCH        GET CURRENT END ADDR.OF EXT.CHN 06389801
         IEMKTAB  DR,XLCRMAP,SA=XMAPOUTR,AATO=(GR5)                     06390601
         DROP  GR6                                                      06391401
         USING XMAP,GR5                ADDRESS OUTER DO MAP ENTRY       06392201
         MVC   XMAPKPCH,XOPTWKTX        SET ENCLOSING DO MAP 'END OF    06393001
*                                       EXTERNAL CHAIN ADDRESS'         06393801
*                                                                       06394601
         DROP   GR5                                                     06395401
         USING XMAP,GR6                 ADDRESS CURRENT DO MAP ENTRY IN 06396201
*                                       SCRATCH                         06397001
*                                                                       06397801
INITMVON DS    0H                                                       06399001
       IEMKTAB DR,XLCRMAP,SA=XMAPSEQU,AATO=(GR5)                        06409001
         B     INITMOVE                                                 06420001
*                                                                       06450001
**  EXIT FROM SUBSCRIPT OPTIMISATION PHASE TO PHASE KA                  06480001
*                                                                       06510001
*                                                                       06540001
INITCLER LA    GR1,XOPTKPZZ                                             06570001
         ST    GR1,PAR1                  ADDRESS OF MODULE NAME         06600001
         L     LR,RELESE                MODULE IEMKP                    06630001
         BALR  RR,LR                                                    06660001
*                                                                       06690001
       IEMKTAB TEST,XLCRUSE,NTA=INITNULL                                06696001
       IEMKTAB FREE,XLCRUSE                                             06702001
INITNULL DS    0H                                                       06706001
       IEMKTAB FREE,(XLCRMAP,XLCRSRT)                                   06710001
       IEMKTAB DEACT,XLCRPCH                                            06715001
         IEMKTAB  DEACT,XLCRTXT                                         06717001
         DROP  GR6                                                      06720001
INITEXIT IEMKLVE                                                        06750001
         EJECT                                                          06780001
*                                                                       28920001
*                                                                       28950001
*      BASE REGISTER USAGE FOR THE FOLLING CODE IN KO                   28980001
*                                                                       29010001
         USING XSRT,GR6                                                 29040001
         USING YSRT,GR5                                                 29070001
         USING YTRP,GR4                                                 29100001
*                                                                       29130001
*                                                                       29160001
         EJECT                                                          29190001
*                                                                       29220001
*                                                                       29250001
*        SUBROUTINE  KNOPTM            OPTIMISE                         29280001
*                                                                       29310001
*        MAKES A DOUBLE NESTED SCAN OF THE SUBS TABLE (AND ANY          29340001
*        EXTENSION) LOOKING FOR TRANSFORMABLE AND INVARIANT GROUPS OF   29370001
*        COMAS IF XOPTOPFL =0, AND FOR COMMONABLE EXPRESSIONS IF NOT.   29400001
*                                                                       29430001
KNOPTM   IEMKENT                                                        29460001
         MVC   XOPTCHNO(2),XOPTC000    ZEROISE MATCH CHAIN LENGTH       29490001
*                                                                       29495001
         L     GR1,XOPTAREA            SET UP MAX CODE ADDRESS          29496001
         LA    GR1,XOPTARTL-1(0,GR1)   IN MATCH AREA                    29497001
         ST    GR1,XOPTMAXL                                             29498001
*                                                                       29500001
*        SET OUTER SCAN TO APPROPRIATE PART OF SUBS/REGION TABLE        29505001
*                                                                       29510001
         USING  XMAP,GR3                                                29515001
*                                                                       29520001
         L     GR3,XOPTXMAP            CURRENT DO MAP ENTRY             29525001
       IEMKTAB SET,XLCRSRT,SA=XMAPSRGL,PTR=1                            29530001
*                                                                       29535001
         DROP  GR3                                                      29540001
*                                                                       29545001
*                                                                       29550001
OPTM0010 DS    0H                                                       29570001
       IEMKTAB SCAN,XLCRSRT,AATO=(GR6),SATO=XOPTSTPS,PTR=1              29590001
*                                      SCANS TO NEXT ENTRY IS XSRT      29610001
         CLI   XSRTCODE,XSRTLEND       TEST FOR END OF TABLE            29640001
         BE    OPTM0150                YES                              29670001
*                                                                       29700001
         CLI   XSRTCODE,XSRTEXTN       IS THERE AN EXTENSION TO XSRT?   29730001
         BNE   OPTM0020                NO                               29760001
*                                                                       29766001
         CLI   XOPTXRFX,X'FF'           TEST FOR ADDNL SSUBS ENTRIES    29772001
         BE    OPTM0150                 BRANCH IF NO EXTENSION          29778001
*                                                                       29784001
       IEMKTAB SET,XLCRSRT,SA=XOPTXRFX,PTR=1  YES  SO POSITION SCAN TO  29794001
*                                      START OF EXTENSION               29820001
         B     OPTM0010                                                 29850001
*                                                                       29880001
OPTM0020 ST    GR6,XOPTSTPA            GR6 BASES XSRT                   29910001
         TM    XSRTCODE,XSRTCSUB       REGION ENTRY ?                   29940001
         BZ    OPTM0010                YES                              29970001
*                                                                       30000001
OPTM0030 TM    XSRTCODE,XSRTCDLT       IS THIS ENTRY ENTIRELY DEALT WTH 30030001
         BNZ   OPTM0010                                                 30060001
*                                                                       30090001
OPTM0040 ST    GR6,PAR1                SET UP PARAMETERS AND ENTER      30120001
         BAL   RR,KNSECO               SEARCH COMAS                     30150001
         LTR   RC,RC                   ANY OPTIMISABLE COMAS FOUND ?    30180001
         BNZ   OPTM0010                NO, SO CONTINUE SCAN             30250001
*                                                                       30330001
*        SET UP PARAMETERS FOR TRIPLE MOVE                              30360001
*                                                                       30390001
OPTM0050 MVC   XOPTSTSP(2),PAR1        PAR1,PAR2 CORRECTLY SET          30420001
         MVC   XOPTFNSP(2),PAR2        ON EXIT FROM KNSECO              30450001
         ST    GR6,PAR5                SUBS ENTRY                       30480001
         BAL   RR,KNTRMV               MOVE TRIPLES TO MATCH AREA       30520001
*                                                                       30570001
         LTR   RC,RC                   RC WILL BE NON ZERO IF OPT EXP   30600001
         BNZ   OPTM0040                TOO LONG. TRY FOR SHORTER EXP    30630001
         MVC   XOPTARL1(2),PAR1        SAVE LENGTH OF MOVED CODE        30660001
         MVC   XOPTTHPS(3),XOPTSTPS    THISP=STARTP                     30690001
         MVC   XOPTLSTR(2),XOPTC000    LAST RANGE=0                     30720001
         MVC   XOPTFCOM(2),XOPTSTSP    START MATCH DIM NUMBER           30750001
         MVC   XOPTLCOM(2),XOPTFNSP    FINISH MATCH DIM NUMBER          30780001
*                                                                       30810001
*        ABOVE TWO PARAMETERS ARE CORRECTLY SET IF NO MATCH CAN BE      30840001
*        OBTAINED, AS EXP MAY BE TRANSFORMABLE OR INVARIANT.            30870001
*                                                                       30900001
       IEMKTAB SET,XLCRSRT,SA=XOPTTHPS,PTR=2                            30930001
*                                                                       30960001
*        SETS UP 2ND SCAN OF SUBS TABLE FOR SUBS(THPS)                  30990001
*                                                                       31020001
         MVI   XOPTFTSW,X'00'          SET FIRST SCAN SWITCH            31050001
*                                                                       31080001
*        THE INNER SCAN REALLY STARTS AT THE NEXT ENTRY AFTER THPS.     31110001
*        THE SWITCH ENABLES ONE EXTRA SCAN TO BE MADE INITIALLY         31140001
*                                                                       31170001
OPTM0060 MVC   XOPTLSPS(3),XOPTTHPS    LSPS IS THE SYMBOLIC ADDRESS OF  31200001
*                                      THE LAST OPTIMISED SUBS          31230001
OPTM0070 DS    0H                                                       31250001
       IEMKTAB SCAN,XLCRSRT,AATO=(GR5),SATO=XOPTTHPS,PTR=2              31270001
*                                                                       31290001
*        SCANS TO NEXT SUBS TABLE ENTRY                                 31320001
*                                                                       31350001
         CLI   YSRTCODE,XSRTLEND       END OF TABLE ?                   31380001
         BE    OPTM0160                YES                              31410001
*                                                                       31440001
         CLI   YSRTCODE,XSRTEXTN       IS THERE A TABLE EXTENSION ?     31470001
         BNE   OPTM0080                NO                               31500001
*                                                                       31506001
         CLI   XOPTXRFX,X'FF'           TEST FOR ADDNL SSUBS ENTRIES    31512001
         BE    OPTM0160                 BRANCH IF NO EXTENSION          31518001
*                                                                       31524001
       IEMKTAB SET,XLCRSRT,SA=XOPTXRFX,PTR=2  YES  SO POSITION SCAN TO  31534001
         B     OPTM0070                START  OF  EXTENSION             31560001
*                                                                       31590001
OPTM0080 CLI   XOPTFTSW,X'00'          IS THIS THE FIRST SIG SCAN ?     31620001
         BNE   OPTM0090                NO                               31650001
         MVI   XOPTFTSW,X'FF'          YES   SET MARKER AND SCAN TO     31680001
         B     OPTM0070                NEXT ENTRY                       31710001
*                                                                       31740001
OPTM0090 TM    YSRTCODE,XSRTCSUB       IS THIS A REGION ENTRY ?         31770001
         BNZ   OPTM0098                NO                               31800001
*                                                                       31830001
*        REGION ENTRY.   IF OPT IS P3, AND A MATCH CHAIN HAS BEEN       31860001
*        STARTED, WE MUST CHECK WHETHER THE ENTRY IS AN END REGION FOR  31890001
*        FOR THE MATCH EXPRESSION IN AREA2. IF SO,THE MATCH CHAIN MUST  31920001
*        BE PROCESSED AND A NEW MATCH LOOKED FOR.                       31950001
*                                                                       31980001
         CLI   XOPTOPFL,XOPTCOMM       OPT = P3 ?                       32010001
         BNE   OPTM0070                NO                               32040001
         CLC   XSRTSMAT(3),XOPTC000    YES, SEE IF MATCH CHAIN EXISTS   32070001
         BE    OPTM0070                NO                               32100001
         BAL   RR,KNCHRG               CHECK THAT THIS IS NOT AN END    32130001
*                                      REG FOR ANY VARIABLE IN AREA2    32160001
*                                                                       32190001
         LTR   RC,RC                                                    32220001
         BZ    OPTM0070                OK, SO CONTINUE SCAN             32250001
         B     OPTM0160                PROCESS MATCH CHAIN AND          32280001
*                                      CONTINUE OUTER SCAN              32310001
OPTM0098 TM    YSRTCODE,XSRTCDLT       IS SUBS ENTIRELY DEALT WITH ?    32340001
         BNZ   OPTM0070                YES                              32370001
*                                                                       32400001
OPTM0100 ST    GR5,PAR1                SUBS ADDRESS                     32430001
         BAL   RR,KNSECO               SEARCH FOR GROUP OF OPTIMISABLE  32460001
*                                      COMAS                            32490001
         LTR   RC,RC                   ANY FOUND ?                      32520001
         BNZ   OPTM0070                NO, SO CONTINUE SCAN             32590001
         ST    GR5,XOPTTHPA            ABS ADDRESS OF SCAN2 SUBS ENTRY  32610001
         MVC   XOPTSUBC(1),YSRTCODE    SUBS CODE FOR KNCMPR             32630001
*                                                                       32670001
*        WE NOW HAVE TWO GROUPS OF OPTIMISABLE COMAS ASSOCIATED WITH    32700001
*        SUBS(STP) AND SUBS(THP). FOR MATCHING THE DIMENSIONS OF THE    32730001
*        LATTER MUST BE EQUAL TO,OR WITHIN, THE DIMENSIONS OF THE       32760001
*        FORMER. A SMALLER RANGE IN SUBS(THP) WILL BE TAKEN IF          32790001
*        NECESSARY TO ENSURE THAT THIS CONDITION HOLDS.                 32820001
*                                                                       32850001
OPTM0110 MVC   XOPTSTTP(2),PAR1        START AND END DIMS               32880001
         MVC   XOPTFNTP(2),PAR2        FOR SUBS(THP)                    32910001
         CLC   XOPTSTTP(2),XOPTFNSP    ARE TWO RANGES DISJOINT ?        32940001
         BH    OPTM0070                YES SO NO MATCH WITH SUBS(THP)   32970001
         CLC   XOPTSTSP(2),XOPTFNTP                                     32980001
         BH    OPTM0070                                                 32990001
*                                                                       33000001
         CLC   XOPTSTSP(2),XOPTSTTP    IS START DIM(THP) IN  RANGE ?    33030001
         BNH   OPTM0120                YES                              33060001
         MVC   XOPTSTTP(2),XOPTSTSP    NO -SO SET IT TO START DIM OF    33090001
*                                      STP MATCHING GROUP               33120001
OPTM0120 CLC   XOPTFNTP(2),XOPTFNSP    IS END DIM (THP) IN REQ RANGE?   33150001
         BNH   OPTM0130                YES                              33180001
         MVC   XOPTFNTP(2),XOPTFNSP    NO -SO SET IT TO END DIM OF      33210001
*                                      STP MATCHING GROUP               33240001
*        NOW COMPARE CODE IN AREA WITH TEXT SPECIFIED BY DIMENSIONS     33340001
*        IN XOPTSTTP AND XOPTFNTP                                       33440001
*                                                                       33540001
OPTM0130 BAL   RR,KNCMPR                                                33640001
         MVC   XOPTTHSR(2),PAR5        RANGE OF MATCH IN BYTES          33810001
         CLC   XOPTTHSR(2),XOPTC000    IS RANGE ZERO ?                  33840001
         BE    OPTM0070                YES -SO SCAN TO NEXT SUBS        33870001
         CLC   XOPTTHSR(2),XOPTLSTR    COMPARE CURRENT MATCH RANGE WITH 33900001
*                                      THE PREVIOUS BEST                33930001
         BNE   OPTM0140                DIFFERENT                        33960001
*                                                                       33990001
*                                      THE SAME,SO CAN ADD SUBS(THP) TO 34020001
*        MATCH CHAIN IF BASE DIMS ARE THE SAME                          34050001
*                                                                       34080001
         CLC   PAR1(2),XOPTLABR                                         34110001
         BNE   OPTM0070                DIFFERENT SO NO MATCH            34140001
*                                                                       34170001
*        ADD SUBS(THP) TO MATCH CHAIN                                   34200001
*                                                                       34230001
OPTM0135 ST    GR6,XOPTTRBA            SAVE GR6                         34260001
*                                                                       34290001
       IEMKTAB DR,XLCRSRT,SA=XOPTLSPS,AATO=(GR6)                        34320001
*                                                                       34350001
*        UNLOCKED DIRECT REF TO SUBS(LASTP)                             34380001
*                                                                       34410001
         MVC   XSRTSMAT(3),XOPTTHPS    SET MATCH(LASTP)=THP             34440001
         L     GR6,XOPTTRBA            RESTORE GR6                      34470001
         LH    GR1,XOPTCHNO                                             34500001
         LA    GR1,1(0,GR1)            INCREMENT CHAIN ITEMS COUNT      34530001
         STH   GR1,XOPTCHNO                                             34560001
         B     OPTM0060                THP BECOMES LASTP THEN SCAN      34590001
*                                                                       34620001
OPTM0140 CLC   XOPTLSTR(2),XOPTTHSR    IS NEW MATCH RANGE BIGGER THAN   34650001
*                                      OLD ?                            34680001
         BH    OPTM0070                NO, SO CONTINUE SCAN             34710001
*                                                                       34740001
*        BETTER MATCH FOUND SO OLD CHAIN WILL BE SCRAPPED AND           34770001
*        A NEW ONE STARTED, UNLESS OPT= P3 AND THERE IS AN END REGION   34800001
*        FOR ONE OF THE MATCH VARIABLES                                 34830001
*                                                                       34860001
         CLI   XOPTOPFL,XOPTCOMM       OPT = P3 ?                       34890001
         BNE   OPTM0142                NO                               34920001
         MVC   XOPTPRSV(20),PAR1       SAVE (IN PARTICULAR) PAR'S 1,2,5 34950001
*                                      IF OLD CHAIN TO BE CONTINUED     34980001
         BAL   RR,KNMKVL               MAKE LIST OF VARIABLES IN CODE   35010001
*                                      IN AREA2 FOR REGION CHECKING.    35040001
*                                      CHECK REGION BOUNDARIES FROM     35070001
         BAL   RR,KNALRG               SUB(STPS) TO SUBS(THPS)          35100001
         L     GR5,PAR1                SET NEW SUB(THPS) ABS ADDRESS    35130001
         MVC   PAR1(20),XOPTPRSV       RESTORE RESULTS OF KNCMPR        35160001
*                                                                       35190001
         LTR   RC,RC                                                    35220001
         BZ    OPTM0142                OK- CAN MAKE NEW MATCH CHAIN     35250001
*                                      FAIL EXIT                        35280001
*        CANNOT MAKE NEW CHAIN,BUT MAY BE ABLE TO CONTINUE THE OLD ONE  35310001
*        PROVIDED THE NEWLY MATCHED RANGE OVERLAPS THE OLD. NOTE THAT   35340001
*        REGION CHECKS FOR THE CONTINUATION HAVE ALREADY BEEN DONE.     35370001
*                                                                       35400001
         CLC   XOPTLSTR(2),XOPTC000    IF MATCH CHAIN EMPTY, CONTINUE   35430001
         BE    OPTM0070                SCAN                             35460001
         CLC   XOPTFCOM(2),PAR1        SAME IF NEW MATCH DOES NOT       35490001
         BL    OPTM0070                COMPLETELY OVERLAP THE OLD       35520001
         CLC   PAR2(2),XOPTLCOM                                         35550001
         BL    OPTM0070                                                 35580001
         B     OPTM0135                ADD TO CHAIN                     35610001
*                                                                       35640001
*                                                                       35670001
OPTM0142 MVC   XOPTFCOM(2),PAR1        SET FROM COMPARE ROUTINE EXIT    35700001
         MVC   XOPTLCOM(2),PAR2        PARAMETERS                       35730001
         MVC   XOPTLSTR(2),PAR5                                         35760001
         MVC   XOPTLABR(2),PAR1                                         35790001
         MVC   XOPTARA3(4),PAR4        START ADDRESS OF MATCHED CODE    35800001
         BAL   RR,KNOMAC               OVERWRITE THE MATCH CHAIN        35820001
*                                                                       35850001
         MVC   XSRTSMAT(3),XOPTTHPS    START NEW MATCH CHAIN WITH       35880001
*                                      SUBS(THP) AND INITIALISE CHAIN   35910001
         MVC   XOPTCHNO(2),XOPTC001+2  ITEMS COUNT                      35940001
         B     OPTM0060                                                 35970001
*                                                                       36000001
*                                                                       36030001
*        ENTER ON END OF TABLE IN SCAN 1 (SUBS(STP))                    36060001
*                                                                       36090001
OPTM0150 DS    0H                                                       36110001
       IEMKTAB DEACT,XLCRSRT           DEACTIVATE THE SUBS TABLE        36130001
         IEMKLVE                       EXIT                             36150001
*                                                                       36180001
*                                                                       36210001
*                                                                       36240001
*        ENTER AT END OF SUBSTABLE SCAN 2 (SUBS(THP)                    36270001
*        ENTRY HERE MEANS THAT THERE WILL BE AN ENTRY TO KOMTCH         36300001
*        TO PROCESS THE MATCH CHAIN AND MAKE PATCHES. THE CHAIN MAY     36330001
*        BE EMPTY.                                                      36360001
*                                                                       36390001
OPTM0160 CLC   XOPTLSTR(2),XOPTC000    EXAMINE RANGE OF MATCH           36420001
         BZ    OPTM0180                B IF 0 (I.E. NO MATCH CHAIN)     36450001
         MVC   XOPTMCHR(2),XOPTLSTR    RANGE OF MATCHED CODE            36510001
*                                                                       36540001
OPTM0170 DS    0H                                                       36560001
       IEMKTAB SET,XLCRSRT,SA=XOPTTHPS,PTR=2                            36580001
*                                                                       36600001
*        REDUNDANT SET OF INNER SCAN PTR TO UNLOCK INNER SCAN           36630001
*                                                                       36660001
         BAL    RR,KOMTCH              PROCESS MATCH CHAIN. SUBS(STP)   36690001
*                                      ENTRY REMAINS LOCKED(ABS IN GR6) 36720001
         XC    XOPTCHNO(2),XOPTCHNO    ZEROISE CHAIN ITEMS COUNT        36750001
         B     OPTM0030                SCAN TO NEXT SUBS ENTRY (SCAN1)  36780001
*                                                                       36810001
OPTM0180 MVC   XOPTARA3(4),XOPTAREA    SET UP MATCHED CODE START        36830001
*                                      ADDRESS                          36850001
*                                      (TRIPLES OF SUBS(STP)            36870001
         MVC   XOPTMCHR(2),XOPTARL1    LENGTH OF CODE                   36900001
         B     OPTM0170                                                 36930001
*                                                                       36960001
*                                                                       36990001
         EJECT                                                          37020001
*                                                                       37050001
*                                                                       37080001
*        SUBROUTINE KNSECO             SEARCH COMAS                     37110001
*                                                                       37140001
*        ENTRY: PAR1 = ABS ADDRESS OF SUBS TABLE ENTRY                  37170001
*                                                                       37200001
*        THE ROUTINE SCANS SUBS ENTRY FORWARDS (EQUIVALENT TO BACKWARD  37230001
*        TEXT SCAN) LOOKING FOR THE FIRST GROUP OF COMAS OPTIMISABLE    37260001
*        AS INDICATED BY XOPTOPFL.                                      37290001
*                                                                       37320001
*        ON EXIT:                                                       37350001
*                                                                       37380001
*        PAR1 = START DIM NUMBER (LAST IN TEXT ORDER).                  37410001
*        PAR2 = END DIM NUMBER (FIRST IN TEXT ORDER).                   37440001
*                                                                       37470001
*                                                                       37500001
*                                                                       37530001
KNSECO   IEMKENT    TYPE=LL                                             37560001
         L     RC,XOPTC004             SET RETURN CODE = 4              37590001
         LH    GR2,XOPTC001+2          START DIM NUMBER                 37620001
         LR    GR3,GR2                 END DIM NUMBER                   37650001
         L     GR6,PAR1                ABS ADDRESS OF SUBS TAB ENTRY    37680001
*                                      GR6 BASES XSRT DSECT             37710001
         MVC   XOPTH1ZB+1(1),XSRTSNOC  MOVE COUNT OF COMAS TO HW BDRY   37740001
SECO0010 TM    XSRTSCCE,XSRTCDLT       COMA EXP CODE BYTE               37770001
         BNZ   SECO0050                BRANCH IF DEALT WITH             37800001
         CLI   XOPTOPFL,X'00'                                           37830001
         BNZ   SECO0040                B IF P3 (COMMONING)              37860001
         TM    XSRTSCCE,XSRTCTRA+XSRTCINV    TEST FOR TRANS OR INVAR    37890001
         BZ    SECO0050                NOT OPTIMISABLE                  37920001
*                                                                       37950001
SECO0020 SR    RC,RC                   RETURN CODE=0                    37980001
*                                                                       38010001
SECO0030 CH    GR2,XOPTH1ZB            END DIM = NO. OF TRIPLES ?       38040001
         BE    SECO0070                YES                              38070001
         LA    GR2,1(0,GR2)            NEXT DIMENSION                   38100001
         LA    GR6,XOPTCSTP(0,GR6)     POINTS AT NEXT SUBS ENTRY        38130001
         B     SECO0010                TEST NEXT COMA                   38160001
*                                                                       38190001
SECO0040 TM    XSRTSCCE,XSRTCCOM       TEST FOR COMMONING               38220001
         BNZ   SECO0020                B IF YES                         38250001
*                                                                       38280001
SECO0050 LTR   RC,RC                   DEALT WITH OR UNOPTIMISABLE      38310001
         BZ    SECO0060                B IF RETURN CODE ZERO            38340001
         LA    GR3,1(0,GR2)            START = NEXT END DIM             38370001
         B     SECO0030                                                 38400001
*                                                                       38430001
SECO0060 BCTR  GR2,0                   CORRECT DIM FOR EXIT             38460001
*                                                                       38490001
SECO0070 STH   GR3,PAR1                START DIM NUMBER                 38520001
         STH   GR2,PAR2                END DIM NUMBER                   38550001
         IEMKLVE    RC=(RC)            EXIT                             38580001
*                                                                       38610001
         EJECT                                                          38640001
*                                                                       38670001
*        SUBROUTINE KNANAL             ANALYSE                          38700001
*        PAR1(2) ANALYSED,CONTENTS INDICATED BY RETURN CODE             38730001
*                                                                       38760001
*        00FF            RC=0                                           38790001
*        0000            RC=4                                           38820001
*        DREF(CONST)     RC=8, XOPTCORF = DICT.REF.                     38850001
*        OTHER           RC=12                                          38880001
*                                                                       38910001
KNANAL   IEMKENT    TYPE=LL                                             38940001
         SR    GR2,GR2                 WORKING REG.SET IN RC AT END     38970001
         CLC   PAR1(2),XOPT00FF        =00FF?                           39000001
         BE    ANAL0010                YES                              39030001
         LA    GR2,XOPTRCIN(0,GR2)     =4                               39060001
         CLC   PAR1(2),XOPTC000        =0000?                           39090001
         BE    ANAL0010                YES                              39120001
         LA    GR2,XOPTRCIN(0,GR2)     =8                               39150001
         LH    GR4,PAR1                SAVE INPUT                       39180001
         GETDICT    PAR1,GR3           CONVERT DREF IN PAR1 TO ABS      39210001
         CLI   0(GR3),XOPTCNST         = DREF(CONSTANT)                 39240001
         BE    ANAL0020                YES                              39270001
         LA    GR2,XOPTRCIN(0,GR2)                                      39300001
*                                                                       39330001
ANAL0010 IEMKLVE    RC=(GR2)           EXIT WITH RC= GR2                39360001
*                                                                       39390001
ANAL0020 STH   GR4,XOPTCORF            MOVE DREF OF CONSTANT            39420001
         B     ANAL0010                                                 39450001
*                                                                       39480001
         EJECT                                                          39510001
*                                                                       40110001
*        SUBROUTINE KNOMAC             OVERWRITE MATCH CHAIN            40140001
*        OVERWRITES THE MATCH CHAIN AT SUBS.STP WITH ZEROS.             40170001
*        SUBS.STPA IS LOCKED ON ENTRY AND REMAINS LOCKED.               40200001
*        KNOMAC LOCKS NO ADDITIONAL ENTRIES                             40230001
*                                                                       40260001
KNOMAC   IEMKENT                                                        40290001
         L     GR6,XOPTSTPA            ABS ADDR OF START SUBS ENTRY     40320001
*                                      GR6 BASES XSRT                   40350001
         MVI   XOPTFWDB,X'00'          LAST 3 BYTES WILL BE USED FOR    40380001
*                                      TABLE REFERENCE                  40410001
OMAC0010 MVC   XOPTFWDB+1(3),XSRTSMAT  MOVE POINTER FROM CHAIN HEAD     40440001
         CLC   XSRTSMAT(3),XOPTC000    =0?                              40470001
         BE    OMAC0020                B IF YES                         40500001
         MVC   XSRTSMAT(3),XOPTC000    ZEROISE CHAIN SLOT               40530001
       IEMKTAB DR,XLCRSRT,SA=XOPTFWDB+1,AATO=(GR6)                      40560001
*                                                                       40590001
*        CONVERTS TABLE REF TO ABS IN GR6                               40620001
*                                                                       40650001
         B     OMAC0010                                                 40680001
*                                                                       40710001
OMAC0020 IEMKLVE                                                        40740001
*                                                                       40770001
         EJECT                                                          40800001
*                                                                       40830001
*        SUBROUTINE  KNCMPR            COMPARE TEXTS                    40860001
*                                                                       40890001
*        COMPARES THE CLEAN CODE IN MATCH AREA WITH THAT IN TEXT, FOR   40920001
*        THE CORRESPONDING DIMENSIONS. A RECORD OF THE LONGEST RANGE    40950001
*        OF MATCH IS KEPT. HASHING IS USED TO SAVE TEXT REFERENCES FOR  40980001
*        TRIPLES WHICH DONT IN FACT MATCH.                              41010001
*        ON EXIT:                                                       41040001
*              PAR1= START COMA DIM NUMBER (HWD)   I.E. RIGHTMOST       41070001
*              PAR2= FINISH COMA DIM NUMBER (HWD) I.E. LEFTMOST         41100001
*              PAR4= START ADDRESS OF MATCHED CODE                      41120001
*              PAR5= LENGTH OF MATCHED CODE (0 IF NO MATCH)             41140001
*                                                                       41160001
*              ONLY COMPLETE COMA OR COMA EXPRESSIONS ARE MATCHED       41280001
*                                                                       41282001
*        REGISTER USAGE                                                 41284001
*                                                                       41286001
*        GR2:  POINTS TO THE CURRENT TRIPLE IN THE MATCH AREA           41288001
*        GR3:  LAST COMPLETE COMA OR COMA EXPRESSION ADDRESS            41290001
*        GR4:  POINTS TO THE CURRENT TRIPLE IN TEXT                     41292001
*        GR5:  POINTS TO THE CURRENT COMA ENTRY IN SUBS(THPA)           41294001
*        GR6:  POINTS TO THE CURRENT COMA ENTRY IN SUBS(STPA)           41296001
*        GR8:  DIMENSION COUNT OF COMAS UNDER COMPARISON                41298001
*              ( IN RIGHT TO LEFT INCREASING NOTATION )                 41300001
*                                                                       41302001
*                                                                       41304001
*                                                                       41310001
KNCMPR   IEMKENT                                                        41340001
         L     GR2,XOPTAREA            MATCH CODE START ADDRESS         41360001
         LH    GR8,XOPTFNSP            DIMENSION COUNT                  41380001
*                                                                       41381001
*        ON ENTRY GR5,GR6 POINT TO THE CURRENT AND START SUBS ENTRIES   41382001
*        RESPECTIVELY. IF EITHER IS A SSUB, COMPARISON OF HASH TOTALS   41383001
*        MUST BE AVOIDED AS THEY ARE NOT SET FOR SSUB ENTRIES. THIS IS  41384001
*        DONE BY MODIFYING A BRANCH.                                    41385001
*                                                                       41386001
         XC    CMPR0042(1),CMPR0042    SET BRANCH FOR DROPPING THROUGH  41387001
*                                      ( SUBS )                         41388001
         MVC   PAR1(1),XSRTCODE                                         41389001
         OC    PAR1(1),YSRTCODE        OR OF SUBS CODES                 41390001
         TM    PAR1,XSRTCSSS           IS EITHER A SSUB ?               41391001
         BZ    CMPR0010                BRANCH IF NO                     41392001
*                                      YES, SO MUST MODIFY BRANCH TO    41393001
         OI    CMPR0042,X'F0'          AVOID HASH COMPARISON            41394001
*                                                                       41395001
*                                                                       41400001
*        FIRST SCAN AREA UNTIL DIMCOUNT = THAT AT START OF TEXT         41420001
*                                                                       41440001
CMPR0010 CH    GR8,XOPTFNTP            COUNT = FIRST TEXT DIMENSION     41460001
         BE    CMPR0030                YES                              41480001
         CLI   0(GR2),XTRPCOMA         IS TRIPLE COMA ?                 41500001
         BNE   CMPR0020                NO SO SKIP                       41520001
         BCTR  GR8,0                                                    41540001
*                                                                       41560001
CMPR0020 LA    GR2,XOPTTRLN(0,GR2)     SET POINTER TO NEXT TRIPLE       41580001
         B     CMPR0010                                                 41600001
*                                                                       41620001
CMPR0030 LR    GR3,GR2                 ADDR OF LAST COMPLETE COMA       41640001
         ST    GR2,XOPTMHCA            CURRENT POTENTIAL MATCH START    41660001
*                                      ADDRESS                          41680001
         MVI   XOPTMHBE,X'00'          SET MARKER TO SAY NO MATCH FOUND 41700001
         MVC   XOPTMHBR(2),XOPTC000    BEST RANGE OF MATCH              41720001
         STH   GR8,XOPTMHCF            CURRENT FINISH COMA NUMBER (     41740001
*                                      FIRST IN TEXT ORDER).            41760001
         LR    GR6,GR8                                                  41780001
         BCTR  GR6,0                                                    41800001
         MH    GR6,XOPTSTEP                                             41820001
         LR    GR5,GR6                                                  41840001
         A     GR6,XOPTSTPA            STPA+5*(DIMCOUNT-1)              41860001
         A     GR5,XOPTTHPA            THPA+5*(DIMCOUNT-1)              41880001
*                                                                       41900001
*        GR5,GR6 NOW POINT AT THE APPROPRIATE COMAS IN THE 2 SUBS TABLE 41920001
*        ENTRIES. NOW COMPARE THEIR HASH VALUES.                        41940001
*                                                                       41960001
CMPR0040 BC    0,CMPR0046              **** MODIFIED BRANCH TO AVOID    41968001
*                                      HASH COMPARISON FOR SSUB         41976001
CMPR0042 EQU   CMPR0040+1                                               41984001
*                                                                       41992001
         CLC   XSRTHASH(1),YSRTHASH    ARE HASH VALUES EQUAL ?          42000001
         BNE   CMPR0110                NO, SO NO MATCH                  42008001
*                                                                       42016001
CMPR0046 TM    XOPTSUBC,XSRTCSSS       SSUB ?                           42024001
         BNZ   CMPR0140                B IF YES                         42040001
         IEMKTAB  SET,XLCRTXT,SA=YSRTSCOM                               42060001
*                                                                       42080001
CMPR0050 TM    XOPTSUBC,XSRTCSSS       SSUB ?                           42100001
         BNZ   CMPR0150                B IF YES                         42120001
         IEMKTAB  SCAN,XLCRTXT,AATO=(GR4)                               42140001
*                                                                       42160001
CMPR0060 ST    GR4,PAR1                                                 42180001
         BAL   RR,KNTRTY               TYPE OF TRIPLE ?                 42200001
         LTR   RC,RC                                                    42220001
         BZ    CMPR0050                SCAN IF IGNORABLE                42240001
         CLC   0(XOPTTRLN,GR2),YTRPCODE  COMPARE TRIPLES IN TEXT AND    42260001
*                                      AREA                             42280001
         BNE   CMPR0110                NO MATCH                         42300001
         CLI   YTRPCODE,XTRPCOMA       IS TRIPLE A COMA ?               42320001
         BNE   CMPR0160                NO                               42340001
         CLC   YTRPOP1(2),XOPTCFNF     IS MULT FFFF?                    42360001
         BE    CMPR0170                YES- V.BOUND OR TOO LARGE        42380001
*                                                                       42400001
CMPR0070 BCTR  GR8,0                   DECREMENT DIMENSION COUNT        42420001
         SH    GR6,XOPTSTEP            AND CORRESPONDING SUBS ENTRY     42440001
         SH    GR5,XOPTSTEP            POINTERS                         42460001
         LA    GR3,XOPTTRLN(0,GR2)     SET NEXT COMPLETE COMA ADDRESS   42480001
         LR    GR2,GR3                 INCREMENT AREA POINTER           42500001
         CH    GR8,XOPTSTTP            FINISHED COMPARISON ?            42520001
         BNL   CMPR0040                NO                               42540001
*                                                                       42560001
CMPR0080 CLI   XOPTMHBE,X'00'          ARE RESULTS TO BE TAKEN FROM     42580001
*                                      CURRENT OR BEST SO FAR PARAMS?   42600001
         BE    CMPR0100                CURRENT                          42620001
         MVC   PAR1(2),XOPTMHBS        BEST SO FAR                      42640001
         MVC   PAR2(2),XOPTMHBF                                         42660001
         MVC   PAR5(2),XOPTMHBR                                         42680001
         L     GR1,XOPTMHBA            MATCHED TRIPLES START ADDRESS    42700001
*                                                                       42720001
CMPR0090 ST    GR1,PAR4                                                 42740001
         IEMKLVE                                                        42760001
*                                                                       42780001
CMPR0100 LA    GR8,1(0,GR8)                                             42800001
         STH   GR8,PAR1                START COMA NUMBER                42820001
         MVC   PAR2(2),XOPTMHCF        FINISH COMA NUMBER               42840001
         S     GR3,XOPTMHCA            LENGTH OF MATCHED CODE           42860001
         STH   GR3,PAR5                                                 42880001
         L     GR1,XOPTMHCA            ITS START ADDRESS                42900001
         B     CMPR0090                                                 42920001
*                                                                       42940001
CMPR0110 LR    GR1,GR3                                                  42960001
         S     GR1,XOPTMHCA            LENGTH OF MATCHED CODE           42980001
         BZ    CMPR0120                B IF NO MATCH                    43000001
         CH    GR1,XOPTMHBR            COMPARE WITH PREVIOUS BEST       43020001
         BL    CMPR0120                WORSE                            43040001
         MVI   XOPTMHBE,XOPTRCIN       SET NON ZERO TO SHOW BEST SO     43060001
         STH   GR1,XOPTMHBR            FAR PARAMETERS                   43080001
         MVC   XOPTMHBF(2),XOPTMHCF                                     43100001
         MVC   XOPTMHBA(4),XOPTMHCA                                     43120001
         LA    GR1,1(0,GR8)                                             43140001
         STH   GR1,XOPTMHBS                                             43160001
*                                                                       43180001
CMPR0120 CLI   0(GR2),XTRPCOMA         NOW SCAN TO NEXT COMA IN AREA    43200001
         BE    CMPR0130                COMA FOUND                       43220001
         LA    GR2,XOPTTRLN(0,GR2)                                      43240001
         B     CMPR0120                                                 43260001
*                                                                       43280001
CMPR0130 LA    GR1,XOPTTRLN(0,GR2)                                      43300001
         ST    GR1,XOPTMHCA            NEXT POSSIBLE MATCH START ADDR.  43320001
         LR    GR1,GR8                                                  43340001
         BCTR  GR1,0                                                    43360001
         STH   GR1,XOPTMHCF            NEXT POSS END COMA DIM NUMBER    43380001
         B     CMPR0070                                                 43400001
*                                                                       43420001
CMPR0140 IEMKTAB  ULDR,XLCRPCH                                          43440001
         IEMKTAB  DR,XLCRPCH,SA=YSRTSCOM,AATO=(GR4),OPT=L               43460001
*                                                                       43480001
*        GETS FIRST ADDRESS IN PATCH FILE FOR REQUIRED COMA             43500001
*                                                                       43520001
         B     CMPR0060                                                 43540001
*                                                                       43560001
CMPR0150 LA    GR4,XOPTTRLN(0,GR4)     SCAN TO NEXT TRIPLE IN PCH FILE  43580001
         B     CMPR0060                                                 43600001
*                                                                       43620001
CMPR0160 LA    GR2,XOPTTRLN(0,GR2)     SCAN TO NEXT TRIPLE IN AREA      43640001
         B     CMPR0050                NO, CONTINUE SCAN                43660001
*                                                                       43680001
CMPR0170 STM   GR5,GR6,PAR1            SAVE DSECT BASE REGISTERS        43700001
         L     GR5,XOPTTHPA            ABS ADDRESSES OF TWO SUBS        43720001
         L     GR6,XOPTSTPA            ENTRIES                          43740001
         CLC   XSRTRDRF(2),YSRTRDRF    HAVE ARRAYS SAME DIM-TABLE REFS? 43760001
         LM    GR5,GR6,PAR1            RESET                            43780001
         BE    CMPR0070                YES, SO CONSIDER MATCHED         43800001
         B     CMPR0110                NO MATCH                         43820001
*                                                                       43840001
*                                                                       44610001
         EJECT                                                          44640001
*                                                                       44670001
*        SUBROUTINE KNTRMV             TRIPLE MOVE                      44700001
*                                                                       44730001
*        ENTRY  PAR1= START DIM NUMBER (2 BYTES)                        44760001
*               PAR2= END   DIM NUMBER (2 BYTES)                        44790001
*              PAR5= ABS ADDRESS OF SUBS ENTRY (WHICH REMAINS LOCKED)   44820001
*                                                                       44880001
*        THE ROUTINE SCANS TEXT BETWEEN TRIPLES SPECIFIED BY PAR1,PAR2. 44910001
*        IT MOVES THE CLEANED UP TRIPLES TO SCRATCH.                    45010001
*              TRIPLES NOT OF THE FOLLOWING SET ARE IGNORED TO          45110001
*           IMPROVE THE MATCHING PERFORMANCE:                           45330001
*                                                                       45360001
*            +,-,PR+,PR-,X,/,COMA,COMR.                                 45390001
*                                                                       45420001
*        EXIT:  RC=0: CODE IN SPECIFIED AREA, LENGTH OF CODE (BYTES)    45450001
*                     IN PAR1(2).                                       45480001
*               RC=4: CODE TOO LONG TO FIT AREA. FIRST TEXT ORDER COMA  45510001
*                     MARKED DEALT WITH AND UNOPTIMISABLE.              45540001
*                                                                       45570001
*                                                                       45600001
KNTRMV   IEMKENT                                                        45630001
         USING XTRP,GR5                                                 45660001
*                                                                       45690001
         L     GR6,PAR5                                                 45720001
         MVC   XOPTSUBC(1),XSRTCODE    MOVE SUBS CODE TO S/R WORKSPACE  45750001
*                                                                       45780001
         LH    GR6,PAR1                START DIM                        45960001
         BCTR  GR6,0                   MINUS 1                          45990001
         MH    GR6,XOPTSTEP            X ENTRY LENGTH                   46020001
         A     GR6,PAR5                ADD START ADDRESS OF TABLE       46050001
         MVC   XOPTSTDM(3),XSRTSCOM    MOVE TEXT REF OF START DIMENSION 46080001
*                                                                       46110001
         LH    GR6,PAR2                END DIM                          46140001
         BCTR  GR6,0                                                    46170001
         MH    GR6,XOPTSTEP            X ENTRY LENGTH                   46200001
         A     GR6,PAR5                ADDRESS IN SUBS TABLE OF END     46230001
*                                      COMA ENTRY                       46260001
         ST    GR6,XOPTFNAD            SAVE                             46290001
         MVC   XOPTFNDM(3),XSRTSCOM    MOVE TEXT REF OF FIRST OPT.      46300001
*                                      COMA ENTRY                       46310001
*                                                                       46440001
         L     GR6,PAR5                                                 46500001
         L     GR4,XOPTAREA            MATCH AREA START ADDRESS         46510001
*                                                                       46520001
*        NOW SCAN AND MOVE NON-IGNORABLE TRIPLES TO MATCH AREA          46530001
*                                                                       46540001
*                                                                       46584001
TRMV0005 MVI   XOPTENDF,X'00'          SET 'NOT IN LAST COMA EXPR'      46587001
*                                                                       46593001
*                                                                       46596001
*        THE FOLLOWING SCAN CAN BE OF EITHER TEXT OR PATCH FILE. AS     46599001
*        HTAB SCAN CANNOT BE USED ON XLCRPCH, DIRECT REF IS USED TO     46602001
*        GET THE FIRST ADDRESS. SCANNING IS DONE BY INCREMENTING THIS   46605001
*        ADDRESS BY 5 FOR EACH TRIPLE - THE SYMBOLIC ADDRESS BEING      46608001
*        LIKEWISE KEPT.                                                 46611001
*                                                                       46614001
*                                                                       46617001
         TM    XOPTSUBC,XSRTCSSS       IS ENTRY SSUB ?                  46620001
         BNZ   TRMV0060                B IF YES                         46650001
       IEMKTAB SET,XLCRTXT,SA=XOPTFNDM SET UP FOR TEXT SCAN             46680001
*                                                                       46710001
TRMV0010 TM    XOPTSUBC,XSRTCSSS                                        46740001
         BNZ   TRMV0070                B IF SSUB                        46770001
       IEMKTAB SCAN,XLCRTXT,AATO=(GR5),SATO=XOPTCURR  SCAN TO NEXT TRPL 46800001
*                                      GR5 BASES XTRP DSECT             46830001
TRMV0015 CLC   XOPTCURR(3),XOPTSTDM    SCAN AT LAST SRT ENTRY ?         46860001
         BNE   TRMV0020                SKIP IF NOT                      46890001
         MVI   XOPTENDF,X'FF'          SET MARKER NON ZERO              46920001
*                                                                       46950001
TRMV0020 ST    GR5,PAR1                CURRENT TRIPLE ADDRESS           46980001
         BAL   RR,KNTRTY               TEST TRIPLE TYPE                 47010001
*                                                                       47040001
         B     TRMV0290                                                 47540001
*                                                                       48210001
TRMV0060 DS    0H                                                       48214001
       IEMKTAB ULDR,XLCRPCH                                             48218001
       IEMKTAB DR,XLCRPCH,SA=XOPTFNDM,AATO=(GR5),OPT=L                  48224001
*                                                                       48230001
*        GETS FIRST ADDRESS IN PATCH FILE FOR REQUIRED COMA             48240001
*                                                                       48250001
         MVC   XOPTCURR(3),XOPTFNDM    KEEP SYMBOLIC ADDRESS ALSO       48260001
         B     TRMV0015                                                 48270001
*                                                                       48280001
TRMV0070 LA    GR5,XOPTTRLN(0,GR5)     SCAN TO NEXT TRIPLE (ALL PCH     48290001
*                                      ITEMS ARE 5 BYTES LONG           48300001
         MVC   XOPTFWDB+1(3),XOPTCURR                                   48310001
         L     GR1,XOPTFWDB                                             48320001
         LA    GR1,XOPTTRLN(0,GR1)     KEEP SYMBOLIC ADDRESS IN STEP    48330001
         ST    GR1,XOPTFWDB                                             48340001
         MVC   XOPTCURR(3),XOPTFWDB+1                                   48350001
         B     TRMV0015                                                 48450001
*                                                                       48480001
*                                                                       53500001
TRMV0290 LTR   RC,RC                                                    53502001
         BZ    TRMV0010                SCAN TO NEXT IF IGNORABLE        53504001
         C     GR4,XOPTMAXL            IS OUTPUT AREA FULL ?            53506001
         BH    TRMV0340                YES                              53508001
         MVC   0(XOPTTRLN,GR4),XTRPCODE MOVE TRIPLES FROM TXT TO OUTPUT 53510001
         LA    GR4,XOPTTRLN(0,GR4)     AREA AND INCREMENT POINTER       53512001
         CLI   XTRPCODE,XTRPCOMA       COMA TRIPLE ?                    53514001
         BNE   TRMV0010                NO                               53516001
         CLI   XOPTENDF,X'00'          ARE WE PROCESSING LAST COMA ?    53518001
         BE    TRMV0010                NO, SO SCAN                      53520001
*                                                                       53522001
*        END OF SCAN                                                    53524001
*                                                                       53526001
         SR    GR2,GR2                 SET UP FOR SUCCESS EXIT CODE     53528001
         S     GR4,XOPTAREA            LENGTH OF CODE IN AREA           53531001
*                                                                       53534001
TRMV0300 TM    XOPTSUBC,XSRTCSSS       IS SUBS SSUB ?                   53536001
         BNZ   TRMV0330                YES                              53538001
*                                                                       53540001
TRMV0310 DS    0H                                                       53541001
       IEMKTAB DEACT,XLCRTXT           UNLOCK AFTER TEXT SCAN           53542001
*                                                                       53544001
TRMV0320 STH   GR4,PAR1                PASS LENGTH OF CODE IN AREA      53545001
         IEMKLVE    RC=(GR2)           EXIT                             53546001
*                                                                       53548001
*                                                                       53550001
TRMV0330 DS    0H                                                       53551001
       IEMKTAB ULDR,XLCRPCH            UNLOCK AFTER SCAN OF PATCH FILE  53552001
         B     TRMV0320                                                 53554001
*                                                                       53556001
TRMV0340 L     GR6,XOPTFNAD            ADDRESS OF FIRST TEXT ORDER COMA 53558001
*                                      ENTRY IN SRT                     53560001
         OI    XSRTSCCE,XSRTSDLT+XSRTSCDU                               53562001
*                                      MARKS ENTRY AS DEALT WITH AND    53564001
*                                      UNOPTIMISABLE                    53566001
TRMV0350 LA    GR2,XOPTRCIN            FAIL EXIT CODE                   53568001
         B     TRMV0300                EXIT                             53570001
*                                                                       53572001
*                                                                       53610001
         DROP  GR5                                                      53640001
         EJECT                                                          53670001
         EJECT                                                          56190001
*                                                                       56220001
*                                                                       56250001
*        SUBROUTINE KNMKVL             MAKE VARIABLES LIST              56280001
*                                                                       56310001
*        MAKES A LIST OF DREFS OF ALL VARIABLES IN OPERANDS OF          56340001
*        TRIPLES IN MATCH AREA. THE LIST IS TERMINATED WITH HWD ZERO.   56370001
*        THE ROUTINE ALSO SETS THE FLAG XOPTUNSF IF ANY OF THE          56400001
*        VARIABLES IN MATCHED CODE IS UNSAFE.                           56430001
*        ON ENTRY GR5 MUST POINT AT THE CURRENT SUBS TABLE ENTRY.       56460001
*        THE COMA DIMENSION NUMBERS FOR AREA CODE ARE IN PAR1 (START    56490001
*        DIM) AND PAR2 (ENDDIM).                                        56520001
*        THE LIST OF VARIABLES IS PUT IN SCRATCH, STARTING AT XOPTARVR. 56550001
*                                                                       56580001
KNMKVL   IEMKENT                                                        56610001
         USING YSRT,GR5                                                 56640001
         LH    GR1,PAR2                END DIMENSION NUMBER(= 1ST       56730001
         BCTR  GR1,0                   IN TEXT ORDER)                   56760001
         MH    GR1,XOPTSTEP            5*(PAR2-1)                       56790001
         AR    GR1,GR5                 ON ENTRY, GR5 POINTS TO CURRENT  56820001
*                                      SUBS ENTRY.                      56850001
         ST    GR1,XOPTFNAD            ADDRESS IN SUBS ENTRY OF FIRST   56880001
*                                      COMA IN AREA2 CODE               56910001
         LH    GR1,PAR1                                                 56940001
         BCTR  GR1,0                                                    56970001
         MH    GR1,XOPTSTEP            5*(START DIM-1)                  57000001
         AR    GR5,GR1                 FIRST RELEVANT SUBS TABLE ENTRY  57030001
*                                      GR5 BASES YSRT DSECT             57060001
         MVI   XOPTUNSF,X'00'          ZEROISE SAFE/UNSAFE MARKER       57090001
*                                                                       57120001
MKVL0005 OC    XOPTUNSF(1),YSRTSCCE    'OR' INTO FLAG THE UNSAFE MARKER 57150001
         NI    XOPTUNSF,XSRTSCUN       FROM THE COMA EXP CODE IN XSRT   57180001
         BNZ   MKVL0007                UNSAFE                           57210001
         C     GR5,XOPTFNAD            END OF SCAN ?                    57240001
         BE    MKVL0007                YES                              57270001
         LA    GR5,XOPTCSTP(0,GR5)     STEP TO NEXT COMA IN ENTRY       57300001
         B     MKVL0005                                                 57330001
*                                                                       57360001
*        UNSAFE FLAG SET. NOW MAKE VARIABLES LIST.                      57390001
*                                                                       57420001
MKVL0007 L     GR4,XOPTARVR            START OF VARIABLES LIST IN       57450001
*                                      SCRATCH                          57480001
         USING XTRP,GR5                                                 57510001
         L     GR5,PAR4                START OF MATCHED CODE            57540001
         LR    GR3,GR5                                                  57570001
         AH    GR3,PAR5                MAX ADDRESS IN AREA              57600001
         BCTR  GR3,0                   MAX ADDRESS OF ANY CODE IN AREA  57630001
*                                                                       57660001
MKVL0010 CR    GR5,GR3                                                  57690001
         BH    MKVL0040                END OF AREA2 SCAN                57720001
         CLI   XTRPCODE,XTRPCOMA       OP1 OF COMA CANNOT BE            57730001
         BE    MKVL0020                DREF (VARIABLE)                  57740001
         MVC   PAR1(2),XTRPOP1         OP1 OF CURRENT TRIPLE            57750001
         BAL   RR,KNANAL               ANALYSE                          57780001
         STC   RC,PAR1                                                  57810001
         CLI   PAR1,XOPTRVAR           IS OP1 = DREF(VARIABLE) ?        57840001
         BNE   MKVL0020                NO                               57870001
         MVC   0(XOPTOPLH,GR4),XTRPOP1 MOVE OPERAND TO SCRATCH LIST     57900001
         LA    GR4,XOPTOPLH(0,GR4)     UPDATE POINTER                   57930001
*                                                                       57960001
MKVL0020 MVC   PAR1(2),XTRPOP2         MOVE 2ND OPERAND                 57990001
         BAL   RR,KNANAL               ANALYSE                          58020001
         STC   RC,PAR1                                                  58050001
         CLI   PAR1,XOPTRVAR           DREF(VARIABLE)?                  58080001
         BNE   MKVL0030                NO                               58110001
         MVC   0(XOPTOPLH,GR4),XTRPOP2 MOVE TO LIST                     58140001
         LA    GR4,XOPTOPLH(0,GR4)     UPDATE LIST POINTER              58170001
*                                                                       58200001
MKVL0030 LA    GR5,XOPTTRLN(0,GR5)     MOVE AREA2 PTR TO NEXT TRIPLE    58230001
         B     MKVL0010                                                 58260001
*                                                                       58290001
MKVL0040 MVC   0(XOPTOPLH,GR4),XOPTC000   END OF LIST MARKER            58320001
         DROP  GR5                                                      58350001
         IEMKLVE                                                        58380001
*                                                                       58410001
         EJECT                                                          58440001
*                                                                       58470001
*                                                                       58500001
*        SUBROUTINE KNCHRG             CHECK REGION                     58530001
*                                                                       58560001
*        ENTRY:  GR5 POINTS TO A REGION ENTRY. THE ROUTINE CHECKS       58590001
*                WHETHER OR NOT THIS IS AN END REGION FOR COMMONING     58620001
*                FOR THE MATCHED CODE IN AREA                           58650001
*                                                                       58680001
KNCHRG   IEMKENT    TYPE=LL                                             58710001
         USING YSRT,GR5                                                 58740001
         L     GR4,XOPTARVR            START OF AREA VARIABLES LIST     58770001
         TM    YSRTCODE,XSRTCGLB+XSRTCITD                               58860001
         BNZ   CHRG0040                FAIL EXIT IF GLOBAL BOUNDARY     58890001
         CLC   0(XOPTOPLH,GR4),XOPTC000   LIST EMPTY ?                  58900001
         BE    CHRG0020                YES                              58910001
         TM    YSRTCODE,XSRTCUNS       SAFE PARTIAL BOUNDRY ?           58920001
         BZ    CHRG0010                YES                              58950001
         CLI   XOPTUNSF,X'00'          UNSAFE FLAG SET ?                58980001
         BNZ   CHRG0040                FAIL EXIT                        59010001
*                                                                       59040001
CHRG0010 CLC   0(XOPTOPLH,GR4),YSRTRDRF  TEST CURRENT LIST VARIABLE     59070001
*                                      AGAINST VARIABLE AT REG BDRY     59100001
         BE    CHRG0040                FAIL EXIT                        59130001
         LA    GR4,XOPTOPLH(0,GR4)     POINTS TO NEXT VAR IN AREA LIST  59160001
         CLC   0(XOPTOPLH,GR4),XOPTC000     END OF LIST ?               59190001
         BNE   CHRG0010                     NO                          59220001
*                                                                       59250001
CHRG0020 SR    RC,RC                   ZERO RETURN CODE - COMMONING     59280001
*                                      CAN CONTINUE                     59310001
         DROP  GR5                                                      59340001
CHRG0030 IEMKLVE    RC=(RC)                                             59370001
*                                                                       59400001
*                                                                       59430001
CHRG0040 LA    RC,4                    FAIL  END OF COMMONING FOR       59460001
         B     CHRG0030                CURRENT MATCH                    59490001
*                                                                       59520001
         EJECT                                                          59550001
*                                                                       59580001
*                                                                       59610001
*        SUBROUTINE  KNALRG            CHECK ALL REGIONS                59640001
*                                                                       59670001
*        TESTS ALL SUBS REGION ENTRIES BETWEEN SUBS(STPS) AND           59700001
*        SUBS(THPS).                                                    59730001
*        EXIT:      RC=0 IF NO END REGIONS FOUND FOR ANY OF THE         59760001
*                        VARIABLES IN AREA, ELSE                        59790001
*                   RC=4                                                59820001
*        THE ROUTINE INTERRUPS THE CURRENT INNER SCAN, WHICH IS         59850001
*        POSITIONED AT SUBS(THPS). A 'SET' IS PERFORMED BEFORE EXIT TO  59880001
*        REPOSITION THE SCAN CORRECTLY, BUT GR5, WHICH BASES THE VSRT   59910001
*        DSECT MUST BE RELOADED. ITS NEW VALUE WILL BE COMMUNICATED     59940001
*        VIA PAR1.                                                      59970001
*                                                                       60000001
KNALRG   IEMKENT                                                        60030001
         USING YSRT,GR5                                                 60060001
*                                                                       60090001
       IEMKTAB SET,XLCRSRT,SA=XOPTSTPS,PTR=2   SCAN FROM STPS           60120001
*                                                                       60150001
ALRG0010 DS    0H                                                       60170001
       IEMKTAB SCAN,XLCRSRT,AATO=(GR5),SATO=XOPTALCU,PTR=2              60190001
*                                                                       60210001
*        SCANS TO NEXT SUBS TABLE ENTRY                                 60240001
*                                                                       60270001
         CLI   YSRTCODE,XSRTEXTN       IS THERE A TABLE EXTENSION ?     60300001
         BNE   ALRG0020                NO                               60330001
*                                                                       60336001
         CLI   XOPTXRFX,X'FF'           TEST FOR ADDNL SSUBS ENTRIES    60342001
         BE    ALRG0020                 BRANCH IF NO EXTENSION          60348001
*                                                                       60354001
       IEMKTAB SET,XLCRSRT,SA=XOPTXRFX,PTR=2  YES  SO POSITION SCAN TO  60364001
         B     ALRG0010                START OF EXTENSION               60390001
*                                                                       60420001
ALRG0020 TM    YSRTCODE,XSRTCSUB       REGION ENTRY ?                   60450001
         BNZ   ALRG0040                NO                               60480001
         BAL   RR,KNCHRG               CHECK REGION                     60510001
*                                                                       60540001
         LTR   GR2,RC                                                   60570001
         BZ    ALRG0010                OK SO TRY NEXT                   60600001
*                                                                       60630001
ALRG0030 DS    0H                                                       60650001
       IEMKTAB SET,XLCRSRT,SA=XOPTTHPS,PTR=2   RESET SCAN TO SUBS(THPS) 60670001
*                                      AS ON ENTRY                      60690001
       IEMKTAB SCAN,XLCRSRT,AATO=(GR5),PTR=2                            60720001
         ST    GR5,PAR1                PASS NEW ABS ADDRESS             60750001
         IEMKLVE   RC=(GR2)                                             60780001
*                                                                       60810001
*                                      SUBS ENTRY                       60840001
ALRG0040 CLC   XOPTALCU(3),XOPTTHPS    END OF SCAN ?                    60870001
         BNE   ALRG0010                NO                               60900001
         SR    GR2,GR2                 SET SUCCESS EXIT CODE            60930001
         B     ALRG0030                                                 60960001
*                                                                       60990001
         EJECT                                                          61020001
*                                                                       61050001
*        DROP GLOBAL BASE REGISTERS FOR DSECTS USED IN KN               61080001
*                                                                       61110001
*                                                                       61140001
*                                                                       61170001
         DROP  GR4,GR5,GR6                                              61200001
*                                                                       61230001
         EJECT                                                          61260001
         EJECT                                                          78770001
*        SUBROUTINE KNCOMU             CONVERT AND MULTIPLY             78970001
*        ENTRY:                                                         79170001
*              PAR1(2) = DREF OF FIXED,DEC,INT,REAL,CONSTANT            79370001
*              PAR2(4) = ABS ADDRESS OF FIXED,BIN,INT,REAL,+VE,CONST    79570001
*              PAR5 = 0 IF CONVERT AND MULTIPLY                         79770001
*                      = 4 IF CONVERT ONLY (NO CHECK ON PRECN)          79970001
*                                                                       80170001
*        EXIT:                                                          80370001
*        RC=0,PAR5=0:   PAR1= PRODUCT, PRECN <16 BIN                    80470001
*              PAR5=4:  PAR1= CONVERTED CONSTANT, PRECN <9 DECIMAL      80570001
*        RC=4:          RESULT OUT OF REQUIRED RANGE                    80670001
*                                                                       80970001
         USING YSRT,GR5                                                 81170001
         USING XDRF,GR3                                                 81370001
*                                                                       81570001
KNCOMU   IEMKENT    TYPE=LL                                             81770001
         MVC   XOPTCOOP(1),PAR5        SAVE OPTIONS PARAMETER           81970001
         L     GR2,PAR2                ADDRESS OF BIN CONSTANT          82170001
         GETDICT    PAR1,GR3           CONVERT DREF TO ABSOLUTE IN GR3  82370001
         CLC   XDRFPRFC(1),XOPTCC08    IS PRECN OF DEC CONST > 8 ?      82570001
         BH    COMU0050                B IF SO TO FAIL EXIT             82770001
         SR    GR4,GR4                                                  82970001
         IC    GR4,XDRFPRFC                                             83170001
         BCTR  GR4,0                   BCD LENGTH LESS ONE              83370001
*                                                                       83570001
         MVI   XOPTBCSG,XOPTBCMU       SET TENTATIVE - INDICATOR        83770001
         CLI   XDRFBCDV,XTRPMNUS       HAS BCD A - SIGN ?               83970001
         BE    COMU0005                YES                              84170001
         MVI   XOPTBCSG,XOPTBCPL       NO -SO SET + MARKER              84370001
         CLI   XDRFBCDV,XTRPPLUS       HAS BCD A + SIGN ?               84570001
         BNE   COMU0010                NO                               84770001
*                                                                       84970001
*        NOW INCREMENT XDRF BASE REG TO ALLOW FOR SIGN BYTE             85170001
*                                                                       85370001
COMU0005 LA    GR3,1(0,GR3)                                             85570001
*                                                                       85770001
COMU0010 EX    GR4,COMU0060            CONVERT BCD TO PACKED DECIMAL    85970001
         MVN   XOPTPASG(1),XOPTBCSG    MOVE IN CORRECT SIGN             86170001
         CVB   GR5,XOPTPACK            AND CONVERT PACKED DEC TO BINARY 86370001
         CLI   XOPTCOOP,X'00'                                           86570001
         BE    COMU0015                B IF CONVERT AND MULTIPLY        86770001
         ST    GR5,PAR1                CONVERSION ONLY                  86970001
         SR    RC,RC                                                    87170001
         B     COMU0030                EXIT                             87370001
*                                                                       87570001
COMU0015 M     GR4,0(GR2)              MULTIPLY BY BINARY CONSTANT      87770001
         ST    GR5,PAR1                POSSIBLE RESULT                  87970001
         LTR   GR5,GR5                                                  88170001
         BL    COMU0040                B IF NEGATIVE                    88370001
         C     GR5,XOPTCFUF            IS RESULT TOO BIG ?              88570001
         BH    COMU0050                YES                              88770001
*                                      NO                               88970001
COMU0020 LTR   RC,GR4                  MUST BE ZERO AT THIS STAGE       89170001
         BNZ   COMU0050                NOT -SO FAIL EXIT                89370001
*                                                                       89570001
COMU0030 IEMKLVE    RC=(RC)                                             89770001
*                                                                       89970001
*                                      GR5 NEGATIVE                     90170001
COMU0040 A     GR4,XOPTC001            PRODUCT HAS PRECN < 25,GR5 WILL  90370001
*                                      NOW BE ZERO                      90570001
         C     GR5,XOPTCFNF            IS RESULT TOO SMALL              90770001
         BH    COMU0020                NO, SO TEST GR4                  90970001
*                                                                       91170001
COMU0050 LA    RC,4                    FAIL EXIT                        91370001
         B     COMU0030                                                 91570001
*                                                                       91770001
*                                                                       91970001
COMU0060 PACK  XOPTPACK(8),XDRFBCDV(1) CONVERT ZONED TO PACKED          92170001
*                                                                       92370001
         DROP  GR5                                                      92570001
         DROP  GR3                                                      92770001
*                                                                       92970001
*                                                                     * 93000001
**             KOADDC - ADD TWO BINARY FULLWORD VALUES.              ** 93030001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 93060001
**       A BINARY FULLWORD RESULT IS OBTAINED BY THE ADDITION OF THE ** 93090001
**       TWO INPUT BINARY VALUES.                                    ** 93120001
**       THIS ADDITION IS ONLY PERFORMED IF THE HIGHEST INPUT        ** 93150001
**       PRECISION IS LESS THAN 31.                                  ** 93180001
**       ON ENTRY THE BINARY VALUES ARE IN XOPTBIN1 AND XOPTBIN2.    ** 93210001
**       THE RELEVANT PRECISIONS ARE IN XOPTPRE1 AND XOPTPRE2.       ** 93240001
**       ON EXIT THE RESULTANT BINARY VALUE IS IN XOPTBINV WHICH IS  ** 93270001
**       PART OF DICTIONARY ENTRY SKELETON.                          ** 93300001
**       THE SUBROUTINE RETURN CODE VALUES ARE :-                    ** 93330001
**                       0 - NORMAL.                                 ** 93360001
**                       4 - UNOPTIMISABLE.                          ** 93390001
*                                                                     * 93420001
KOADDC   IEMKENT  TYPE=LL2                                              93450001
*                                                                     * 93480001
**       TEST IF PRECISION OF EITHER INPUT BINARY VALUE IS 31 OR     ** 93510001
**       GREATER. IF IT IS SET RETURN CODE =4 AND RETURN TO USER.    ** 93540001
*                                                                     * 93570001
         CLC   XOPTPRE1,XOPTC031        TEST PRECISION AND RETURN TO    93600001
         BNL   ADDCUNOP                  USER IF NOT LESS THAN 31.      93630001
         CLC   XOPTPRE2,XOPTC031        TEST PRECISION AND RETURN TO    93660001
         BNL   ADDCUNOP                  USER IF NOT LESS THAN 31.      93690001
*                                                                     * 93720001
**       BOTH BINARY VALUES HAVE PRECISIONS OF LESS THAN 31. THEY ARE** 93750001
**       ADDED THEREFORE AND RESULT IS PUT IN XOPTBINV.              ** 93780001
*                                                                     * 93810001
         L     GR2,XOPTBIN1             SET ONE BINARY VALUE IN         93840001
         A     GR2,XOPTBIN2              REGISTER, ADD VALUES AND       93870001
         ST    GR2,XOPTBIN2              FROM IT AND STORE RESULT.      93900001
         MVC   XOPTBINV(4),XOPTBIN2                                     93930001
         SR    RC,RC                    RETURN TO USER WITH ZERO        93960001
         B     ADDCEXIT                  RETURN CODE.                   93990001
*                                                                     * 94020001
**       WHEN UNOPTIMISABLE SET RETURN CODE TO 4                     ** 94050001
*                                                                     * 94080001
ADDCUNOP LA    RC,XOPTRCIN                                              94110001
*                                                                     * 94140001
**       MAKE RETURN TO CALLING MODULE WITH RETURN CODE SET.         ** 94170001
*                                                                     * 94200001
ADDCEXIT IEMKLVE  RC=(RC)                                               94230001
         EJECT                                                          94260001
*                                                                     * 94290001
**             KOSUBC - SUBTRACT TWO BINARY FULLWORD VALUES.         ** 94320001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 94350001
**       A BINARY FULLWORD RESULT IS OBTAINED BY THE SUBTRACTION OF  ** 94380001
**       THE TWO INPUT BINARY VALUES.                                ** 94410001
**       THIS SUBTRACTION IS ONLY PERFORMED IF THE HIGHEST INPUT     ** 94440001
**       VALUE PRECISION IS LESS THAN 31.                            ** 94470001
**       ON ENTRY THE BINARY VALUES ARE IN XOPTBIN1 AND XOPTBIN2.    ** 94500001
**       THE RELEVANT PRECISIONS ARE IN XOPTPRE1 AND XOPTPRE2.       ** 94530001
**       ON EXIT THE RESULTANT BINARY VALUE IS IN XOPTBINV WHICH IS  ** 94560001
**       PART OF DICTIONARY ENTRY SKELETON.                          ** 94590001
**       THE SUBROUTINE RETURN CODE VALUES ARE :-                    ** 94620001
**                       0 - NORMAL.                                 ** 94650001
**                       4 - UNOPTIMISABLE.                          ** 94680001
*                                                                     * 94710001
KOSUBC   IEMKENT  TYPE=LL2                                            * 94740001
*                                                                     * 94770001
**       TEST IF PRECISION OF EITHER INPUT BINARY VALUE IS 31 OR     ** 94800001
**       GREATER. IF IT IS SET RETURN CODE = 4 AND RETURN TO USER.   ** 94830001
*                                                                     * 94860001
         CLC   XOPTPRE1,XOPTC031        TEST PRECISION AND RETURN TO    94890001
         BNL   SUBCUNOP                  USER IF NOT LESS THAN 31.      94920001
         CLC   XOPTPRE2,XOPTC031        TEST PRECISION AND RETURN TO    94950001
         BNL   SUBCUNOP                  USER IF NOT LESS THAN 31.      94980001
*                                                                     * 95010001
**       BOTH BINARY VALUES HAVE PRECISIONS OF LESS THAN 31. THEY ARE** 95040001
**       SUBTRACTED THEREFORE AND RESULTANT IS PUT IN XOPTBINV.      ** 95070001
*                                                                     * 95100001
         L     GR2,XOPTBIN1             SET ONE BINARY VALUE IN         95130001
         S     GR2,XOPTBIN2              REGISTER, SUBTRACT 2ND VALUE   95160001
         ST    GR2,XOPTBIN2              STORE RESULTANT IN XOPTBINV.   95190001
         MVC   XOPTBINV(4),XOPTBIN2                                     95220001
         SR    RC,RC                    SET ZERO RETURN CODE.           95250001
         B     SUBCEXIT                 MAKE RETURN TO USER.            95280001
*                                                                     * 95310001
**       WHEN UNOPTIMISABLE SET RETURN CODE TO 4.                    ** 95340001
*                                                                     * 95370001
SUBCUNOP LA    RC,XOPTRCIN                                              95400001
*                                                                     * 95430001
**       MAKE RETURN TO CALLING MODULE WITH RETURN CODE SET.         ** 95460001
*                                                                     * 95490001
SUBCEXIT IEMKLVE  RC=(RC)                                               95520001
         EJECT                                                          95550001
*                                                                     * 95580001
**             KOTSTO - TEST GIVEN OPERAND.                          ** 95610001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 95640001
**       IF THE GIVEN OPERAND IS ZERO RETURN CODE IS SET TO VALUE 4  ** 95670001
**       AND RETURN IS MADE TO CALLING ROUTINE.                      ** 95700001
**       OTHERWISE ZDRFAB IS USED TO OBTAIN DICTIONARY ENTRY.        ** 95730001
**       THE ENTRY IS CHECKED TO DETERMINE IF IT IS FOR A DECIMAL OR ** 95760001
**       BINARY INTEGER CONSTANT. IF NETHER RETURN IS MADE TO CALLING** 95790001
**       MODULE WITH RETURN CODE SET TO 4.                           ** 95820001
**       OTHERWISE PRECISION IS FOUND AND STORED AND CONSTANT IS     ** 95850001
**       CONVERTED TO BINARY IF IN BCD FORMAT AND STORED. ZERO RETURN** 95880001
**       CODE VALUE IS SET AND RETURN IS MADE TO CALLING MODULE.     ** 95910001
**       ON ENTRY THE OPERAND TO BE TESTED MUST BE GIVEN IN PAR1.    ** 95940001
**       ON EXIT THE BINARY CONSTANT IS IN PAR1 AND THE PRECISION IS ** 95970001
**       IN PAR2.                                                    ** 96000001
**       RETURN CODE VALUES FROM THIS SUBROUTINE ARE :-              ** 96030001
**                       0 - OPTIMISABLE OPERAND.                    ** 96060001
**                       4 - UNOPTIMISABLE OPERAND.                  ** 96090001
*                                                                     * 96120001
KOTSTO   IEMKENT  TYPE=2                                                96150001
         USING XDRF,GR4                 PROVIDE BASE FOR XDRF DSECT.    96180001
*                                                                     * 96210001
**       TEST IF OPERAND IS ZERO AND RETURN TO USER WITH RETURN CODE ** 96240001
**       OF 4 IF IT IS.                                              ** 96270001
*                                                                     * 96300001
         CLC   PAR1+2(2),XOPTC000       CHECK IF OPERAND IS ZERO.       96330001
         BE    TSTOUNOP                 IF ZERO SET UNOPTIMIZABLE RC.   96360001
*                                                                     * 96390001
**       FOR NON ZERO OPERAND USE ZDRFAB TO OBTAIN DICTIONARY ENTRY. ** 96420001
*                                                                     * 96450001
         L     GR2,PAR1                 SAVE CONTENTS OF PAR1.          96480001
         L     LR,ZDRFAB                SET LINK REGISTER AND CALL      96510001
         BALR  RR,LR                     CONVERSION ROUTINE.            96540001
         L     GR4,PAR1                 LOAD XDRF BASE REGISTER WITH    96570001
*                                        ABSOLUTE ADDRESS OF DIC ENTRY. 96600001
         STH   GR2,PAR1                 RESET DIC REF IN 1ST HALF PAR1. 96630001
*                                                                     * 96660001
**       CHECK IF DICTIONARY ENTRY IS FOR A BINARY OR DECIMAL INTEGER** 96690001
**       CONSTANT OR NEITHER AND BRANCH ACCORDINGLY.                 ** 96720001
*                                                                     * 96750001
         CLI   XDRF,XDRFCNST            TEST IF ENTRY IS FOR A CONSTANT 96780001
         BNE   TSTOUNOP                  AND IF NOT RETURN TO USER.     96810001
*                                                                     * 96840001
         CLI   XDRFCSCE,XDRFCINT        TEST FOR ZERO SCALE FACTOR.     96870001
         BNE   TSTOUNOP                 IF NOT AN INTEGER RETURN TO     96900001
*                                        USER WITH RETURN CODE SET.     96930001
*                                                                     * 96960001
         CLI   XDRFCDAT,XDRFCADS        TEST IF FIXED DECIMAL CAD SHORT 96990001
         BE    TSTODCON                  OR LONG AND IF EITHER BRANCH   97020001
         CLI   XDRFCDAT,XDRFCADL         TO CHECK THAT BCD IS PRESENT   97050001
         BE    TSTODCON                  AND CONVERT TO BINARY.         97080001
*                                                                     * 97110001
         CLI   XDRFCDAT,XDRFRFBS        TEST IF REAL FIXED BINARY LONG  97140001
         BE    TSTOBCON                  OR SHORT AND IF EITHER BRANCH  97170001
         CLI   XDRFCDAT,XDRFRFBL         TO TEST FOR INTERNAL FORMAT.   97200001
         BE    TSTOBCON                                                 97230001
*                                                                     * 97260001
         B     TSTOUNOP                 BRANCH TO SET UNOPTIMISABLE     97290001
*                                        RETURN CODE BEFORE MAKING      97320001
*                                        RETURN TO USER.                97350001
*                                                                     * 97380001
**       FOR REAL FIXED DECIMAL INTEGER CONSTANTS CHECK THAT BCD IS  ** 97410001
**       PRESENT BEFORE  THE  DECIMAL TO BINARY CONVERSION ROUTINE   ** 97440001
**       KNCOMU IS USED. MAXIMUM BINARY VALUE RETURNED IS 27 BITS.   ** 97470001
**       MAXIMUM DECIMAL PRECISION THAT WILL BE CONVERTED IS 8.      ** 97500001
*                                                                     * 97530001
TSTODCON CLC   XDRFLNTH,XOPT000E        TEST FOR NO BCD PRESENT.        97560001
         BE    TSTOUNOP                 IF NO BCD MAKE RETURN TO USER   97590001
*                                        WITH RETURN CODE SET.          97620001
         MVI   PAR5,XOPTRCIN            SET NON ZERO VALUE IN PAR3 TO   97650001
*                                        SHOW CONVERSION ONLY.          97680001
         BAL   RR,KNCOMU                PERFORM CONVERSION ROUTINE WITH 97710001
*                                        BINARY VALUE RETURNED IN PAR1. 97740001
         B     TSTOPREC                 BRANCH TO FIND AND STORE        97770001
*                                        EFFECTIVE PRECISION.           97800001
*                                                                       97830001
**       FOR REAL FIXED BINARY INTEGER CONSTANTS A CHECK IS MADE TO  ** 97860001
**       DETERMINE WHETHER OR NOT BINARY VALUE IS IN INTERNAL FORMAT.** 97890001
**       IF NOT RETURN IS MADE TO USER WITH UNOPTIMISABLE RETURN     ** 97920001
**       CODE. OTHERWISE THE EFFECTIVE PRECISION IS FOUND AND STORED.** 97950001
*                                                                     * 97980001
TSTOBCON TM    XDRFTYPE,XDRFCBCD        TEST 1ST TWO BITS OF TYPE BYTE. 98010001
         BNO   TSTOUNOP                 IF NOT INTERNAL FORMAT RETURN   98040001
*                                        IS MADE TO USER.               98070001
         MVC   PAR1,XDRFBINV            OTHERWISE STORE BINARY IN PAR1  98100001
*                                        BEFORE FINDING PRECISION.      98130001
*                                                                     * 98160001
**       DETERMINE EFFECTIVE PRECISION FOR BINARY VALUE AND STORE    ** 98190001
**       THIS IN PAR2.                                               ** 98220001
*                                                                     * 98250001
TSTOPREC BAL   RR,KOPREC                PERFORM PRECISION DETERMINATION 98280001
         B     TSTOEXIT                 BRANCH TO MAKE RETURN WITH      98310001
*                                        RETURN CODE ALREADY SET.       98340001
*                                                                     * 98370001
**       FOR UNOPTIMISABLE CONDITIONS SET RETURN CODE TO 4 BEFORE    ** 98400001
**       MAKING RETURN.                                              ** 98430001
*                                                                     * 98460001
TSTOUNOP LA    RC,4                                                     98490001
*                                                                     * 98520001
**       RETURN TO CALLING MODULE WITH RETURN CODE SET               ** 98550001
*                                                                     * 98580001
         DROP  GR4                                                      98610001
TSTOEXIT IEMKLVE  RC=(RC)                                               98640001
         EJECT                                                          98645001
*                                                                     * 98650001
**             KOMAKC - BINARY CONSTANT SETUP SUBROUTINE.            ** 98655001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 98660001
**       THE 2ND OPERAND IS CHECKED, CONVERTED TO BINARY IF NECESSARY** 98665001
**       AND ITS PRECISION STORED. IF UNOPTIMISABLE RETURN IS MADE TO** 98670001
**       USER.                                                       ** 98675001
**       THE TRIPLE CODE IS CHECKED. IF COMA,1ST OPERAND IS TAKEN TO ** 98680001
**       BE 16 BIT BINARY AND TRIPLE IS TREATED AS MULT TRIPLE.      ** 98685001
**       IF IT IS A PREFIX MINUS TRIPLE IT IS TREATED AS A MINUS     ** 98690001
**       TRIPLE WITH A ZERO 1ST OPERAND.                             ** 98695001
**       1ST OPERAND FOR OTHER TRIPLE CODES IS CHECKED AS FOR 2ND    ** 98700001
**       OPERAND.                                                    ** 98705001
**       THE APPROPRIATE PROCESSING SUBROUTINE IS THEN USED TO CREATE** 98710001
**       A NEW CONSTANT IF POSSIBLE.                                 ** 98715001
**       A DICTIONARY ENTRY IS MADE FOR THE NEW CONSTANT AND RETURN  ** 98720001
**       IS MADE TO THE USER.                                        ** 98725001
**       THE RETURN CODE VALUES FROM THIS SUBROUTINE ARE :-          ** 98730001
**                       0 - NEW CONSTANT HAS BEEN CREATED.          ** 98735001
**                       4 - UNOPTIMISABLE.                          ** 98740001
**                       8 - UNINTERESTING TRIPLE.                   ** 98745001
**       REGISTERS GR2,GR3,GR4,GR5 ARE USED IN THIS SUBROUTINE.      ** 98750001
**       ON ENTRY REGISTER GR3 CONTAINS THE ADDRESS OF THE TRIPLE    ** 98755001
**       TO BE PROCESSED.                                            ** 98760001
**       ON EXIT XOPTDRF3 CONTAINS THE DICTIONARY REFERENCE OF THE   ** 98765001
**       NEWLY CREATED BINARY CONSTANT                               ** 98770001
KOMAKC   IEMKENT TYPE=1                                                 98775001
*                                                                     * 98780001
*                                                                     * 98785001
**       CLEAR THE SUBROUTINE WORK AREA AND BASE XTRP DSECT.         ** 98790001
*                                                                     * 98795001
         XC    XOPTMAKC,XOPTMAKC        COMPLETE WORK AREA IS CLEARED.  98800001
         USING XTRP,GR3                 PROVIDE BASE FOR XTRP DSECT.    98805001
*                                                                     * 98810001
**       USE KOTSTO SUBROUTINE TO DETERMINE IF 2ND OPERAND OF TRIPLE ** 98815001
**       IS OPTIMISABLE OR NOT. IF IT IS STORE VALUE AND PRECISION.  ** 98820001
*                                                                     * 98825001
         MVC   PAR1+2(2),XTRPOP2        PUT 2ND OPERAND IN PAR1.        98830001
         BAL   RR,KOTSTO                LINK TO PROCESS OPERAND.        98835001
         LTR   RC,RC                    TEST RETURN CODE.               98840001
         BNZ   MAKCEXIT                 IF UNOPTIMISABLE MAKE RETURN TO 98845001
*                                        USER.                          98850001
         MVC   XOPTBIN2,PAR1            STORE CONSTANT VALUE AND        98855001
         MVC   XOPTPRE2,PAR2             PRECISION IN RESERVED SLOTS.   98860001
*                                                                     * 98865001
**       BEFORE THE 1ST OPERAND OF THE TRIPLE IS TESTED SIMILARLY    ** 98870001
**       A CHECK IS MADE TO SEE IF THE SPECIAL CASE OF COMA OR       ** 98875001
**       PREFIX MINUS HAS OCCURRED.                                   * 98880001
*                                                                     * 98885001
         CLI   XTRP,XTRPCOMA                 TEST IF COMA TRIPLE.       98890001
         BNE   MAKCPRFM                      IF NOT COMA BRANCH TO TEST 98895001
*                                             FOR PREFIX MINUS.         98900001
*                                                                     * 98905001
**       FOR COMA TRIPLE 1ST OPERAND IS REGARDED AS 16 BIT +VE       ** 98910001
**       BINARY NUMBER. COMA IS THEN TREATED AS MULT TRIPLE.         ** 98915001
**       UNLESS  OP1=X'FFFF'                                            98920001
*                                                                       98925001
*                                                                     * 98930001
         CLC   XTRPOP1,XOPTCFNF         1ST TWO BYTES OF XOPTCFNF=FFFF  98935001
         BNE   MAKCOKCM                 BRANCH IF NOT ADJUSTABLE MULT   98940001
*                                                                       98945001
         LA    RC,4                     RETURN WITH CODE OF 4           98950001
         B     MAKCEXIT                 I.E. NOT OPTIMISABLE            98955001
*                                                                       98960001
MAKCOKCM MVC   XOPTBIN1+2(2),XTRPOP1    SET UP BINARY OPERAND STORAGE   98965001
*                                        FROM COMA FIRST OPERAND.       98970001
         LA    GR2,16                   SET PRECISION OF OPERAND FOR    98975001
         ST    GR2,XOPTPRE1              THIS CASE.                     98980001
         B     MAKCTEST                 BRANCH TO TRIPLE TEST ROUTINE.  98985001
*                                                                     * 98990001
**       TRIPLE IS NOT COMA SO TEST FOR PREFIX MINUS TRIPLE. IF IT IS** 98995001
**       SET FIRST BINARY OPERAND TO ZERO AND TREAT AS MNUS TRIPLE.  ** 99000001
*                                                                     * 99005001
MAKCPRFM CLI   XTRP,XTRPPRFM            TEST IF PREFIX MINUS TRIPLE.    99010001
         BNE   MAKCFRST                 IF NOT PREFIX MINUS BRANCH TO   99015001
*                                        TEST 1ST OPERAND.              99020001
         XC    XOPTBIN1,XOPTBIN1        CLEAR 1ST BINARY OPERAND AND    99025001
         XC    XOPTPRE1,XOPTPRE1         PRECISION STORAGE SLOTS.       99030001
         B     MAKCTEST                 BRANCH TO TRIPLE TEST ROUTINE.  99035001
*                                                                     * 99040001
**       CURRENT TRIPLE IS NEITHER COMA OR PREFIX MINUS. 1ST OPERAND ** 99045001
**       IS TESTED USING KOTSTO SUBROUTINE. IF IT IS OPTIMISABLE ITS ** 99050001
**       VALUE AND PRECISION ARE STORED IN RESERVED SLOTS.           ** 99055001
*                                                                     * 99060001
MAKCFRST MVC   PAR1+2(2),XTRPOP1        PUT 1ST OPERAND IN PAR1.        99065001
         BAL   RR,KOTSTO                LINK TO PROCESS OPERAND.        99070001
         LTR   RC,RC                    TEST RETURN CODE.               99075001
         BNZ   MAKCEXIT                 IF UNOPTIMISABLE RETURN TO USER 99080001
         MVC   XOPTBIN1,PAR1            STORE CONSTANT VALUE AND        99085001
         MVC   XOPTPRE1,PAR2             PRECISION IN RESERVED SLOTS.   99090001
*                                                                     * 99095001
**       BOTH OPERANDS ARE IN OPTIMISABLE FORM. USE KNTRTY SUBROUTINE** 99100001
**       TO TEST TRIPLE TYPE AND BRANCH ON RETURN CODE TO PROCESS.   ** 99105001
*                                                                     * 99110001
MAKCTEST ST    GR3,PAR1                 SET PARAMETER WORD WITH ADDRESS 99115001
*                                        OF CURRENT TRIPLE.             99120001
         BAL   RR,KNTRTY                LINK TO TEST CURRENT TRIPLE     99125001
*                                        TYPE.                          99130001
         LA    RR,MAKCFINL              SET RETURN POINT.               99135001
         B     MAKCTABL(RC)             BRANCH ON RETURN CODE.          99140001
MAKCTABL B     MAKCOTHR                 THESE TRIPLES NOT OF INTEREST.  99145001
         B     KOADDC                   PERFORM ADDITION SUBROUTINE.    99150001
         B     KOSUBC                   PERFORM SUBTRACTION SUBROUTINE. 99155001
         B     KOMLTC                   PERFORM MULTIPLY SUBROUTINE.    99160001
         B     MAKCOTHR                 TRIPLE IS NOT OF INTEREST.      99165001
         B     KOSUBC                   PROCESS PREFIX MINUS BY KOSUBC. 99170001
         B     MAKCOTHR                 TRIPLE IS NOT OF INTEREST.      99175001
         B     KOMLTC                   PROCESS COMA USING KOMLTC.      99180001
         B     MAKCOTHR                 TRIPLE IS NOT OF INTEREST.      99185001
*                                                                     * 99190001
**       FOR THOSE TRIPLES NOT OF INTEREST A RETURN CODE VALUE OF 8  ** 99195001
**       IS SET AND RETURN IS MADE TO THE USER.                      ** 99200001
*                                                                     * 99205001
MAKCOTHR LA    RC,8                     SET APPROPRIATE RETURN CODE.    99210001
         B     MAKCEXIT                 RETURN TO USER.                 99215001
*                                                                     * 99220001
**       TEST RETURN CODE FROM PROCESSING SUBROUTINES TO DETERMINE   ** 99225001
**       WHETHER A NEW BINARY CONSTANT HAS BEEN CREATED. IF IT HAS   ** 99230001
**       NOT MAKE RETURN TO USER.                                    ** 99235001
*                                                                     * 99240001
MAKCFINL LTR   RC,RC                    TEST PROCESSING SUBROUTINE      99245001
*                                        RETURN CODE.                   99250001
         BNZ   MAKCEXIT                 IF UNOPTIMISABLE RETURN TO USER 99255001
*                                        WITH RC ALREADY SET.           99260001
*                                                                     * 99265001
**       MAKE A DICTIONARY ENTRY FOR THE NEW CONSTANT, STORE         ** 99270001
**       REFERENCE IN RESERVED SLOT, SET SWITCH TO SHOW ENTRY HAS    ** 99275001
**       BEEN MADE AND SET RETURN CODE TO ZERO BEFORE RETURN TO USER.** 99280001
*                                                                     * 99285001
         LA    GR4,10                  SET ENTRY COUNT                  99290001
         LA    GR5,XOPTDTAB            SET ADDRESS OF DIC REF SAVE      99295001
*                                      AREA IN GR5                      99300001
MAKCDTAB CLC   0(2,GR5),XOPTC000       IS TABLE FOR D-REF ZERO          99305001
         BE    MAKCENTR                IF IT IS THEN MAKE TABLE ENTRY   99310001
         CLC   2(4,GR5),XOPTBINV       HAS CONSTANT ALREADY DIC ENTRY   99315001
         BE    MAKCCOPY                IF IT HAS THEN BY-PASS ROUTINE   99320001
*                                      TO MAKE ENTRY                    99325001
         LA    GR5,6(0,GR5)            INCREMENT TABLE POINTER TO NEXT  99330001
         BCT   GR4,MAKCDTAB            COUNT DOWN TABLE ENTRIES         99335001
MAKCENTR MVC   XOPTCCHN,ZCONCH         MOVE HEAD OF CONSTANT CHAIN TO   99340001
*                                                                       99345001
         LA    GR2,XOPTCNSK             SET ADDRESS OF ENTRY IN THE     99350001
         ST    GR2,PAR1                  PAR1 PARAMETER WORD.           99355001
         LA    GR2,L'XOPTCNSK           SET LENGTH OF ENTRY IN THE      99360001
         ST    GR2,PAR2                  PAR2 PARAMETER WORD.           99365001
         L     LR,ZDICRF                SET LINK REGISTER AND BRANCH    99370001
         BALR  RR,LR                     TO MAKE DICTIONARY ENTRY.      99375001
         MVC   ZCONCH,PAR1+2           STORE NEW HEAD OF CHAIN          99380001
         MVC   XOPTDRF3(2),PAR1+2       PUT DICT REF IN RESERVED SLOT.  99385001
*                                                                     * 99390001
         LTR   GR4,GR4                 WERE ALL TABLE ENTRIES FULL      99395001
         BZ    MAKCSETS                IF SO SET SWITCH AND EXIT        99400001
         MVC   0(2,GR5),PAR1+2         OTHERWISE MAKE ENTRY IN TABLE    99405001
         MVC   2(4,GR5),XOPTBINV       SET VALUE IN TABLE               99410001
         B     MAKCSETS                                                 99415001
*                                                                       99420001
MAKCCOPY MVC   XOPTDRF3(2),0(GR5)      COPY DIC REF FROM TABLE          99425001
MAKCSETS OI    XOPTOPTX,XOPTCTCT        SET SWITCH TO SHOW NEW CONSTANT 99430001
*                                        HAS BEEN SET UP.               99435001
         SR    RC,RC                    SET RETURN CODE TO ZERO.        99440001
*                                                                     * 99445001
**       RETURN TO USER WITH RETURN CODE SET.                        ** 99450001
*                                                                     * 99455001
         DROP  3                                                        99460001
MAKCEXIT IEMKLVE RC=(RC)                                                99465001
*                                                                     * 99470001
**             KOPREC - TEST PRECISION OF BINARY WORD.               ** 99475001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 99480001
**       A TEST IS MADE FOR THE MAXIMUM NEGATIVE NUMBER. IF FOUND A  ** 99485001
**       RETURN CODE OF 4 IS GIVEN.                                  ** 99490001
**       OTHER NEGATIVE NUMBERS ARE COMPLEMENTED.                    ** 99495001
**       THE PRECISION OF THE BINARY VALUE IS CALCULATED.            ** 99500001
**       ON ENTRY PAR1 CONTAINS THE BINARY FULLWORD THE PRECISION OF ** 99505001
**       WHICH IS REQUIRED.                                          ** 99510001
**       ON EXIT PAR1 REMAINS UNALTERED AND PAR2 CONTAINS THE        ** 99515001
**       PRECISION.                                                  ** 99520001
**       THE SUBROUTINE RETURN CODE VALUES ARE :-                    ** 99525001
**                       0 - NORMAL.                                 ** 99530001
**                       4 - UNOPTIMISABLE.                          ** 99535001
*                                                                     * 99540001
KOPREC   IEMKENT TYPE=LL2                                               99545001
*                                                                     * 99550001
**       COMPLEMENT ALL -VE NUMBERS EXCEPT MAXIMUM NEGATIVE NUMBER.  ** 99555001
*                                                                     * 99560001
         CLC   PAR1,XOPTCNEG            TEST FOR MAXIMUM NEGATIVE NO.   99565001
         BE    PRECUNOP                 IF IT IS MAXIMUM -VE NUMBER SET 99570001
*                                        RC = 4 AND MAKE RETURN.        99575001
         L     GR2,PAR1                 SET BINARY VALUE IN REGISTER.   99580001
         LPR   GR2,GR2                  COMPLEMENT IF NEGATIVE.         99585001
*                                                                     * 99590001
*                                                                     * 99595001
**       TEST PRECISION OF VALUE IN PAR1.                            ** 99600001
*                                                                     * 99605001
         LA    GR4,1                    INITIALISE PRECISION COUNT.     99610001
PRECCUNT SRA   GR2,1                    SHIFT BITS RIGHT 1 PLACE AND    99615001
         BZ    PRECRETN                  TEST FOR ZERO RESULT.          99620001
         LA    GR4,1(0,GR4)             INCREMENT PRECISION COUNT BY 1  99625001
*                                        IF RESULT OF SHIFT IS NOT ZERO 99630001
         B     PRECCUNT                 RETURN TO SHIFT AGAIN.          99635001
*                                                                     * 99640001
PRECRETN ST    GR4,PAR2                 STORE EFFECTIVE PRECISION IN    99645001
*                                        PAR2.                          99650001
         SR    RC,RC                    SET ZERO RETURN CODE.           99655001
         B     PRECEXIT                 MAKE RETURN TO USER.            99660001
PRECUNOP LA    RC,XOPTRCIN              SET UNOPTIMISABLE RETURN CODE.  99665001
*                                                                     * 99670001
**       RETURN TO CALLING MODULE WITH RETURN CODE SET.              ** 99675001
*                                                                     * 99680001
PRECEXIT IEMKLVE RC=(RC)                                                99685001
         EJECT                                                          99690001
*                                                                     * 99695001
**             KOMLTC - MULTIPLY TWO BINARY FULLWORD VALUES.         ** 99700001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 99705001
**       A BINARY FULLWORD RESULT IS OBTAINED BY MULTIPLYING TOGETHER** 99710001
**       THE TWO INPUT BINARY VALUES.                                ** 99715001
**       THIS MULTIPLICATION IS ONLY PERFORMED IF THE SUM OF THE     ** 99720001
**       PRECISIONS IS LESS THAN 32.                                 ** 99725001
**       ON ENTRY THE BINARY VALUES ARE IN XOPTBIN1 AND XOPTBIN2.    ** 99730001
**       THE RELEVANT PRECISIONS ARE IN XOPTPRE1 AND XOPTPRE2.       ** 99735001
**       ON EXIT THE RESULTANT BINARY VALUE IS IN XOPTBINV WHICH IS  ** 99740001
**       PART OF DICTIONARY ENTRY SKELETON.                          ** 99745001
**       THE SUBROUTINE RETURN CODE VALUES ARE :-                    ** 99750001
**                       0 - NORMAL.                                 ** 99755001
**                       4 - UNOPTIMISABLE.                          ** 99760001
*                                                                     * 99765001
KOMLTC   IEMKENT TYPE=LL2                                               99770001
*                                                                     * 99775001
*                                                                     * 99780001
**       TEST IF  PRECISION OF RESULT,WHICH IS EQUAL TO SUM OF INPUT ** 99785001
**       PRECISIONS, IS LESS THAN 32. IF NOT RETURN TO USER.         ** 99790001
*                                                                     * 99795001
         L     GR2,XOPTPRE1             LOAD PRECISION OF 1ST OPERAND   99800001
*                                        INTO REGISTER.                 99805001
         A     GR2,XOPTPRE2             ADD PRECISIONS.                 99810001
         C     GR2,XOPTC031             TEST IF RESULT < 32 OR NOT.     99815001
         BNH   MLTCMULT                 IF LESS PERFORM MULTIPLICATION. 99820001
         LA    RC,XOPTRCIN              OTHERWISE SET RETURN CODE = 4   99825001
*        B     MLTCEXIT                  AND MAKE RETURN TO USER.       99830001
*                                                                     * 99835001
**       OVERFLOW WILL NOT OCCUR SO MULTIPLICATION IS PERFORMED AND  ** 99840001
**       RESULTANT MOVED TO XOPTBINV.                                ** 99845001
*                                                                     * 99850001
MLTCMULT L     GR5,XOPTBIN1             LOAD MULTIPLICAND REGISTER.     99855001
         M     GR4,XOPTBIN2             MULTIPLY BINARY VALUES TOGETHER 99860001
         ST    GR5,XOPTBIN2             STORE RESULT FROM ODD REGISTER. 99865001
         MVC   XOPTBINV(4),XOPTBIN2                                     99870001
         SR    RC,RC                    SET ZERO RETURN CODE.           99875001
*                                                                     * 99880001
**       MAKE RETURN TO CALLING MODULE WITH RETURN CODE SET.         ** 99885001
*                                                                     * 99890001
MLTCEXIT IEMKLVE RC=(RC)                                                99895001
         EJECT                                                          99896001
         LTORG                                                          99926001
         END                                                            99956001
