KP       TITLE 'PL1F COMPILER. PHASE IEMKP. SUBSCRIPT OPTIMISATION.'    00060031
*                                                                       00061001
*                                                                       00061219
*        THE FOLLOWING APARS HAVE BEEN FIXED IN THIS MODULE             00061419
*                                                                       00061619
* R19 132000,136800,195600,228600*,240000*                        30337 00061819
*********************************************************************** 00062001
*                                                                       00063001
* FUNCTION         THIS MODULE PROVIDES SUBROUTINES FOR KO.             00064001
*                  THE SUBROUTINES HAVE FACILITIES FOR GENERATING       00065001
*                  OPTIMISED SUBSCRIPT AND LOOP CONTROL CODE.           00066001
*                  GENERATED CODE IS PLACED IN THE PATCH FILE           00067001
*                  AND THE ORIGINAL TEXT IS AMENDED TO REFER TO         00068001
*                  RESULTS CALCULATED BY THE OPTIMISED CODE.            00069001
*                  THE CODE IN TEXT TO BE OPTIMISED IS LINKED BY        00070001
*                  A MATCH CHAIN IN THE SUBS/REGION TABLE XSRT          00071001
*                  CONSTRUCTED BY KO. THE MATCH CHAIN IS DELETED BY     00072001
*                  A ROUTINE IN THIS MODULE SO THAT THE SPACE IN        00073001
*                  XSRT MAY BE REUSED FOR ANOTHER MATCH CHAIN.          00074001
*                                                                       00075001
*                                                                       00076001
* ENTRY POINTS     (1)KOMTCH  THIS ROUTINE PERFORMS INITIALISATION FOR  00077001
*                  AN OPTIMISABLE DO LOOP AND CHECKS FOR BXLE,BXH.      00078001
*                  THE ITERATIVE SPECIFICATION TRIPLES OF THE DO LOOP   00079001
*                  ARE AMENDED TO PASS INFORMATION TO THE NEXT PHASE    00080001
*                  KU CONCERNING THE GENERATION OF BXLE,BXH CODE.       00081001
*                                                                       00082001
*                  (2)KOMTCH  PROCESS MATCHED CODE AND GENERATE         00083001
*                  OPTIMISED CODE. MODIFY ORIGINAL TEXT IN SUBSCRIPT    00084001
*                  LISTS TO REFER TO OPTIMISED CODE.MARK THE ENTRIES    00085001
*                  IN THE SUBS/RGN TABLE AS DEALT WITH AND DELETE       00086001
*                  THE MATCH CHAIN.                                     00087001
*                  AMEND ITERATIVE SPECIFICATION TRIPLES WHERE IT       00088001
*                  IS POSSIBLE TO PERFORM SPECIAL ARRAY EXPRESSION      00089001
*                  OPTIMISATION.                                        00090001
*                                                                       00091001
*                                                                       00092001
*                  (3)KOPTCH  MAKE AN ENTRY IN THE PATCH FILE           00093001
*                                                                       00094001
*                                                                       00095001
* INPUT            TEXT IN THE FORM OF TRIPLES, DICTIONARY ENTRIES OF   00096001
*                  ENTRY TYPE 1, TABLES IN TEXT BLOCKS. THE TABLES      00097001
*                  USED ARE THE DO MAP(XMAP),AND THE SUBS/REGION TABLE  00098001
*                  (XSRT).                                              00099001
*                  THE DATA AREA IN KA IS REQUIRED (XLCR).              00100001
*                                                                       00101001
*                                                                       00102001
*OUTPUT            TEXT IN OPTIMISABLE SUBSCRIPT LISTS IS AMENDED       00103001
*                  TO NOP,COMA NULL,COMR TRIPLES. TRIPLES AT THE HEAD   00104001
*                  AND TAIL OF OPTIMISABLE DO LOOPS ARE AMENDED. PTCH   00105001
*                  TRIPLES ARE USED TO OVERWRITE TRIPLES IN TEXT AT THE 00106001
*                  POINT OF INSERTION OF OPTIMISED CODE.                00107001
*                                                                       00108001
*                  DICTIONARY ENTRIES FOR ENTRY TYPE 1 ARE AMENDED      00109001
*                  TO CHAIN ON NEW AUTOMATIC TEMPORARIES. THE NEW       00110001
*                  TEMPORIES ARE OF TYPE FIXED BIN INTEGER.             00111001
*                                                                       00112001
*                  THE SUBS/REGION TABLE IS AMENDED TO DELETE THE       00113001
*                  MATCH CHAIN AND MARK THE PROCESSED ENTRIES AS        00114001
*                  DEALT WITH.                                          00115001
*                  THE PATCH FILE IS CREATED.                           00116001
*                                                                       00117001
*                                                                       00118001
* EXTERNAL ROUTINES (1)  COMPILER CONTROL ROUTINES: ZURC,RLSCTL,ZTXTAB, 00119001
*                  ZDRFAB,ZDICRF.                                       00120001
*                   (2) ROUTINES IN KA(TABLE HANDLING ROUTINES):        00121001
*                  KAHMDR,KAHDAC,KAHTXT,KAHERR,KAHBLD,KAHSCN,KAHSET.    00122001
*                                                                       00123001
*                                                                       00124001
* WORKSPACE        THIS MODULE USES THE WORKSPACE SET UP IN SCRATCH     00125001
*                  BY MODULE KN.                                        00126001
*                                                                       00127001
*                                                                       00128001
* NOTES            (1)  THE 3 MAIN SUBROUTINES IN THIS MODULE CALL      00129001
*                  SEVERAL LOWER LEVEL ROUTINES WHICH ARE LOCATED   :   00130001
*                                                                       00131001
*                  (A) IN THIS MODULE                                   00132001
*                  (B) IN SCRATCH                                       00133001
*                  (C) IN MODULE KO                                     00134001
*                                                                       00135001
*                                                                       00136001
*                  (2)  THIS MODULE REQUIRES THE IEMK... MACROS         00137001
*                  FOR ASSEMBLY                                         00138001
*                                                                       00139001
*                                                                       00140001
         EJECT                                                          00141001
         MACRO                                                          00142001
&NAME    GETDICT &DICREF,&XDICBSE                                       00180031
*                                                                       00240031
&NAME    MVC   PAR1+2(2),&DICREF .      MOVE DIC.REF.TO PARAM FIELD     00300031
         L     LR,ZDRFAB .              LINK TO ZDRFAB                  00360031
         BALR  RR,LR .                  TO CONVERT DIC.REF. TO ABS      00420031
         L     &XDICBSE,PAR1 .          BASE XDIC DSECT                 00480031
*                                                                       00540031
         MEND                                                           00600031
         EJECT                                                          00660031
**                                                                      00720031
         COPY  IEMKCOM                                                  00780031
         COPY  IEMKUTL                                                  00840031
         COPY  IEMKEQU                                                  00900031
         COPY  IEMKDRF                                                  00960031
         COPY  IEMKLCR                                                  01020031
         COPY  IEMKMAP                                                  01080031
         COPY  IEMKPCH                                                  01140031
         COPY  IEMKSKL                                                  01200031
         COPY  IEMKTRP                                                  01260031
         COPY  IEMKSRT                                                  01320031
*                                                                       01380031
IEMKO    DSECT                          TRANSFER VECTOR MAP FOR IEMKO   01440031
         USING *,GR9                                                    01500031
         DS    CL2                      2 BYTE PHASE IDENTIFIER         01560031
         IEMKPLR KO,0,R,DL=KAKOZZ,LL=KTZZ                               01620031
KOMAKC   DS    2H                       MAKE COMPILE TIME CONSTANT      01680031
         EJECT                                                          01800031
SCRATCH  DSECT                                                          01860031
         USING SCRATCH,GR7              BASE CODE AND DATA IN SCRATCH   01920031
         COPY  IEMKNDT                                                  01980031
*                                                                       01989001
** TRANSFER VECTOR MAP FOR ROUTINES IN SCRATCH  (MOVED BY KN)           01998001
*                                                                       02007001
KNTRTY   DS    2H                      TEST TRIPLE TYPE                 02016001
KOMOVE   DS    2H                      MOVE TO PATCH BUILD AREA         02025001
KOSNDX   DS    2H                      ALLOCATE A SNDX REGISTER         02034001
KOSSBS   DS    2H                      START OF A SSUB LIST             02043001
KOSSBE   DS    2H                      END OF A SSUB LIST               02052001
KOEROR   DS    2H                      ERROR ROUTINE                    02061001
KOCVTX   DS    2H                      TEST FOR CONTROL VARIABLE        02070001
KOMCHN   DS    2H                      PROCESS A MATCH CHAIN            02079001
         EJECT                                                          02088001
         EJECT                                                          02100031
IEMKP    CSECT                                                          02160031
         USING IEMKP,GR8                                                02220031
         DC    CL2'KP'                  MODULE IDENTIFIER               02280031
*                                                                       02340031
**  TRANSFER VECTOR FOR KP                                              02400031
*                                                                       02460031
         B     KOBXCH                    CHECK IT. SPEC.FOR BXLE,BXH    02520031
         B     KOMTCH                                                   02580031
         B     KOPTCH                   MAKE PATCH                      02640031
         EJECT                                                          02700031
*                                                                       02705001
** KOBXCH                                                               02710001
*                                                                       02715001
*  SUBROUTINE TO PERFORM INITIALISATION FOR OPTIMISING A DO LOOP.       02720001
*  INITIALISES VARIABLES & SWITCHES FOR BXLE,BXH LOOP CONTROL           02725001
*  AND MAKES USSL PATCHES AT ITDO TRIPLE AND HEAD OF LOOP (INSIDE).     02730001
*                                                                       02735001
*  SETS SWITCH BITS IN OP1 IF CV TRIPLE TO INDICATE WHETHER             02740001
*  ST,L INSTRUCTIONS MAY BE DELETED FROM INSIDE LOOP AT HEAD AND TAIL   02745001
*  IN BXLE,BXH CODE.                                                    02750001
*                                                                       02755001
*  ATTEMPS TO SUBTRACT 'STEP' FROM 'LIMIT' AT COMPILE TIME IF BOTH      02760001
*  ARE CONSTANTS  AND SETS SWITCH BIT IN OP1 OF DOEQ TRIPLE.            02765001
*  THE DREF. IN OP2 OF THE DOEQ TRIPLE IS SET TO THE DREF. OF THE       02770001
*  SUBTRACTED CONSTANT IF POSSIBLE.                                     02775001
*                                                                       02780001
*  SNDX REGISTERS ARE ALLOCATED FOR BXLE,BXH CODE AND PLACED IN THE     02785001
*  ITERATIVE SPECIFICATION TRIPLE OPERANDS. ALSO USSL PATCHES ARE MADE  02790001
*  FOR THESE REGISTERS.                                                 02795001
*                                                                       02800001
KOBXCH   IEMKENT TYPE=1                                                 02805001
         L     GR6,XOPTXMAP                                             02820031
         USING XMAP,GR6                 DO MAP DSECT                    02880031
         USING XTRP,GR5                 TRIPLE DSECT                    02940031
*                                                                       03000031
** MOVE CV COUNT FOR CURRENT LOOP FROM DO MAP TO HALF WORD WORK SPACE   03060031
*                                                                       03120031
         MVC   XOPTCVCT,XMAPCVCT                                        03180031
*                                                                       03240031
         NI    XOPTOPTX,XOPTRSX6       RESET'IT.SPEC.MODIFIED'SWITCH    03300031
*                                                                       03360031
*                                                                     * 03420031
**  XOPTSNDN= NO OF SNDX REGIGISTERS USED IN THIS LOOP                * 03480031
**  INITIALLY  XOPTSNDN=0                                             * 03540031
*                                                                     * 03600031
         MVC   XOPTSNDN,XOPTC000        INITIAL SETTING                 03660031
*                                                                       03720031
*                                                                       03780031
         MVC   XOPTSNDA,XMAPSNDA        MOVE TO  H  ALIGNED WORKSPACE   03840031
         MVC   XOPTOPTX,XMAPOPTX        MOVE SWITCH VECTOR TO WORKSPACE 03900031
*                                                                       03960031
**   SET VARIABLE USSL INDEX                                            04020031
*                                                                       04080031
         LA    GR1,XOPTJUSL                                             04140031
         ST    GR1,XOPTINDX             SAVE ADDR. OF LONG USSL         04200031
         LA    GR1,8(,GR1)                                              04260031
         ST    GR1,XOPTUSLX             USSL REG INDEX FOR LONG USSL.   04320031
         MVC   XOPTUSSL+3(10),XOPTUSRS  RESET LONG USSL SKELETON        04380031
*                                                                       04440031
         TM    XOPTOPTX,XOPTNKBX        TEST IF BXLE,BXH POSSIBLE FOR   04500031
         BO    BXCHEXIT                 THIS LOOP   BRANCH IF NO        04560031
         B     BXCHNOPC                BRANCH TO NOP FOLLOWING CLN2     04620031
BXCHONST CLI   XOPTSNDA+1,XOPTSNDG      TEST NO OF SNDXS AVAILABLE      04680031
         BL    BXCHEXIT                 BRANCH IF NOT AVAILABLE         04740031
*                                                                       04800031
** TEST IF NO'ST'REQUIRED AND XOPTCVCT=0                                04860031
** I.E. THERE ARE NO REFERENCES AT ALL TO THE CV IN A BXLE,BXH LOOP     04920031
*                                                                       04980031
         TM    XMAPSPEC,XMAPNOST       TEST IF ST MAY BE DELETED        05040031
         BZ    BXCHCOPY                 DO N'T BRANCH IF DELETE         05100031
*                                                                       05160031
         SR    GR1,GR1                                                  05220031
         CH    GR1,XOPTCVCT            TEST CV COUNT = 0                05280031
         BNZ   BXCHSRNP                                                 05340031
*                                                                       05400031
** COPY NO'ST' AND NO 'L' SWITCH SETTINGS TO MOST SIG. BYTE OF          05460031
** CV TRIPLE OP1                                                        05520031
*                                                                       05580031
BXCHCOPY MVC   XOPTWKBT,XMAPSPEC        TEST IF STORE MAY BE DELETED    05640031
         NI    XOPTWKBT,XMAPNOST+XMAPNOLD                               05700031
         IC    GR1,XOPTWKBT                                             05760031
         SLL   GR1,XOPTDEL4            GET'L','ST' SWITCHES TO MOST     05820031
         STC   GR1,XOPTWKBT            SIGNIFICANT END OF BYTE          05880031
         IEMKTAB DR,XLCRTXT,SA=XOPTCTXT,AATO=(GR5)                      05940031
         OC    XTRPOP1(1),XOPTWKBT     COPY SWITCHES TO CV TRIPLE       06000031
*                                                                       06060031
         OI    XOPTOPTX,XOPTOKIT       SET'IT.SPEC.MODIFIED' SWITCH     06120031
*                                                                       06180031
** SUBTRACT'STEP'FROM'INITIAL' AT COMPILE TIME IF POSSIBLE FOR BXLE,BXH 06240031
*                                                                       06300031
BXCHSRNP MVI   XOPTSRIN,X'00'          RESET'SR'REUIRED SWITCH          06360031
         MVC   XOPTMNUS+1(2),XOPTIREF  MOVE DREF OF'INIT' TO MNUS OP1   06420031
         MVC   XOPTMNUS+3(2),XOPTSREF  MOVE DREF OF 'STEP' TO MNUS OP2  06480031
         LA    GR3,XOPTMNUS            ADDRESS OF MINUS TRIPLE          06540031
         BAL   RR,KOMAKC               SUBTRACT 'STEP' FROM 'INIT'      06600031
*                                                                       06660031
         LTR   RC,RC                   TEST IF SUBTRACT SUCCESSFUL      06720031
         BNZ   BXCHSRST                BRANCH IF NOT SUCCESSFUL         06780031
*                                                                       06840031
         OI    XOPTSRIN,XOPTSRNP       REQUEST 'SR' ORDER FROM          06900031
*                                       PHASE KU TO BE DELETED          06960001
*                                                                       07020031
         IEMKTAB DR,XLCRTXT,SA=XOPTITXT,AATO=(GR5)                      07080031
         MVC   XTRPOP2,XOPTDRF3        MOVE DREF OF'INIT'-'STEP'        07140031
         MVC   XOPTSVIR,XOPTDRF3                                        07200031
*                                                                       07260031
BXCHSRST IEMKTAB DR,XLCRTXT,SA=XOPTITXT,AATO=(GR5)                      07320031
         OC    XTRPOP1(1),XOPTSRIN     SET OP1 OF DOEQ                  07380031
*                                      TO REQUEST 'SR' IN OR OUT        07440031
*                                                                       07500031
*                                                                       07560031
         MVI   XOPTPARM+1,XOPTSNDG      ALLOCATE  SNDXS FOR  BXLE,BXH   07620031
         BAL   RR,KOSNDX                                                07680031
*                                                                       07740031
       IEMKTAB DR,XLCRTXT,SA=XOPTCTXT,AATO=(GR5)                        07800031
         NC    XTRPOP1,XOPTXNEG         MASK OFF L.S. 14 BITS           07860031
         OC    XTRPOP1,ZSMREG+2         SET  SNDX IN OP1 OF CV TRIPLE   07920031
         L     GR1,XOPTUSLX                                             07980031
         MVC   0(2,GR1),ZSMREG+2          SAVE CV REG IN LONG USS       08040031
         LA    GR1,2(,GR1)              STEP USSL INDEX                 08100031
         ST    GR1,XOPTUSLX                                             08160031
*                                                                       08220031
*                                                                       08280031
**  SET UP PATCH SKELETONS'USSL 00 05 (ZSMREG)' FOR INSERT BEFORE LOOP  08340031
**                        'DROP (ZSMREG)'       FOR INSERT AFTER LOOP   08400031
**                                                                      08460031
*                                                                       08520031
         L     GR3,XOPTSAVE             LOAD SKELETON SAVE AREA ADDRESS 08580031
         USING XSKL,GR3                 BASE SKELETON DSECT             08640031
         MVC   KOPTSC,XSKLPTSC          RESET SKELETON C                08700031
         MVC   KOPTSD,XSKLPTSD          RESET SKELETON D                08760031
         MVC   PTSC0007,ZSMREG+2        MOVE SNDX REG.NO TO USSL  SKEL. 08820031
         MVC   PTSD0005,ZSMREG+2        MOVE SNDX REG.NO TO DROP  SKEL. 08880031
         MVC   XOPTCVRG,ZSMREG+2        SAVE SNOX REG.NO FOR LATER USE  08940031
         DROP  GR3                                                      09000031
** MAKE PATCH BEFORE ITDO TRIPLE                                        09060031
*                                                                       09120031
         LA    GR0,X'11'                PATCH TYPE                      09180031
         LA    GR2,L'KOPTSC-1           PATCH LENGTH                    09240031
         LA    GR3,KOPTSC               PATCH ADDRESS                   09300031
         BAL   RR,KOPTCH                                                09360031
*                                                                       09420031
** IF SNDX REG'S AVAILABLE ALLOCATE STEP AND LIMIT REG'S AND INSERT IN  09480031
** OP1 OF BY' AND TO' RESPECTIVLY. PUT OUT (USSL 00 05 REG) FOR STEP    09540031
** AND LIMIT REG'S. THIS MUST BE DONE IN ADDITION TO THE                09600031
** (USSL 01 05 REG) FOR THE STEP AND LIMIT AT THE HEAD OF THE LOOP      09660031
** CONTROL CODE TO ENSURE THAT REGISTER ALLOCATOR GETS THE ALLOCATION   09720031
** OF THE STEP/LIMIT CORRECT.. IT IS NECnSSARY TO GIVE AN USSL FOR THE  09780031
** CV REG AND THE STEP/LIMIT PAIR BEFORE ANY OTHER USSL'S FOR THIS LOOP 09840031
*                                                                       09900031
INITREGS MVC   XOPTPARM,XOPTC000        SET PARAM TO KOSNDX S/R TO 0    09960031
         BAL   RR,KOSNDX                  GET NEXT REG                  10020031
*                                                                       10080031
         TM    ZSMREG+3,XOPTLSBT          TEST LEAST SIG. BIT           10140031
         BO    INITREGS                  BRANCH IF REG NO IS ODD        10200031
*                                                                       10260031
         IEMKTAB  DR,XLCRTXT,SA=XOPTSTXT,AATO=(GR5)                     10320031
         MVC   XTRPOP1,ZSMREG+2           SET OP1 OF BY' TRIPLE         10380031
         OI    XTRPOP1,XOPTEVEN          SET REG PAIR BIT               10440031
*                                                                       10500031
         IEMKTAB DR,XLCRTXT,SA=XOPTLTXT,AATO=(GR5)                      10560031
         MVC   XTRPOP1,ZSMREG+2          SET OP1 OF TO'                 10620031
*                                                                       10680031
         MVC   PTSC0007,ZSMREG+2         MOVE SNDX REG.NO TO USSL       10740031
         OI    PTSC0007,XOPTEVEN         SET GEGISTER PAIR BIT          10800031
*                                                                       10860031
         LA    GR0,X'11'               MAKE ITDO PATCH                  10920031
         BAL   RR,KOPTCH                                                10980031
*                                                                       11040031
         MVC   PTSC0007,ZSMREG+2     MOVE SNDX REG NO TO USSL           11100031
*                                                                       11160031
         LA    GR0,X'11'             MAKE ITDO PATCH                    11220031
         BAL   RR,KOPTCH                                                11280031
*                                                                       11340031
** MAKE PATCH AFTER ITD' TRIPLE                                         11400031
*                                                                       11460031
*                                                                       11520031
         LA    GR0,X'22'                                                11580031
         LA    GR2,L'KOPTSD-1           PATCH LENGTH                    11640031
         LA    GR3,KOPTSC               PATCH ADDRESS                   11700031
          LA    GR3,KOPTSD              PATCH ADDRESS                   11760031
         BAL   RR,KOPTCH                                                11820031
*                                                                       11880031
       IEMKTAB DEACT,XLCRPCH                                            11940031
         B     BXCHEXIT                                                 12000031
BXCHNOPC IEMKTAB SET,XLCRTXT,SA=XOPTPREF  SET TO ITD'                   12060031
         IEMKTAB SCAN,XLCRTXT,AATO=(GR5)  ITD'                          12120031
         IEMKTAB SCAN,XLCRTXT,AATO=(GR5)  CLN2                          12180031
         MVI   XTRP,XTRPNOP             NOP CLN2 AFTER OPTIMISABLE ITD' 12240031
         B     BXCHONST                                                 12300031
*                                                                       12360031
         DROP  GR6                                                      12420031
         DROP  GR5                                                      12480031
*                                                                       12540031
BXCHEXIT IEMKLVE                                                        12600031
         EJECT                                                          12660031
         EJECT                                                          12720031
*                                                                       12780031
** KOSSB3                     DESTROYS  GR1 THROUGH GR5                 12840031
*                                                                       12900031
*  SUBROUTINE TO MOVE A SUBSCRIPT LIST INTO THE PATCH BUILD AREA        12960031
*  CHANGING THE SUBS/SUB' TRIPLES TO SSUB/SSB'.                         13020031
*  ALL MATCHED COMA  EXPRESSIONS ARE COPIED WITH AMENDMENTS             13080031
*  AS FOLLOWS  1  REFERENCES TO THE CONTROL VARIABLE ARE REPLACED       13140031
*                 BY REFERENCES TO THE 'STEP'.                          13200031
*                                                                 30337 13205019
*        IF THE CV AND STEP ARE REPRESENTED BY THE SAME PL1       30337 13210019
*        VARIABLE THIS FACT MUST BE COMMUNICATED TO KOSSB2 SO THAT30337 13215019
*        THE 'STEP' WILL NOT BE REPLACED BY THE 'INITIAL' VALUE,  30337 13220019
*        THIS BEING INCORRECT IMPLEMENTATION OF THE LANGUAGE.     30337 13225019
*                                                                 30337 13230019
*        IN THIS CASE, THE DICT REF OF THE STEP IN THE TRIPLE     30337 13235019
*        WILL HAVE THE LEAST SIGNIFICANT BIT SET ON.              30337 13240019
*        ROUTINE KOSSB2 WILL CLEAR THIS BIT AFTER USE.            30337 13245019
*                                                                 30337 13250019
*              2  ALL ADDITIVE INVARIANT PARTS OF THE EXPRESSION        13260031
*                 ARE DELETED.                                          13320031
*  ALL UNMATCHED COMA EXPRESSIONS ARE REPLACED BY COMA NULL             13380031
*  COMA NULL GENERATED BY ROUTINE KOSSB3 IS X'41 FFFF FFFF'             13390001
*  WHICH IS DIFFERENT FROM ALL OTHER COMA NULL'S OF X'41 00FF FFFF'     13400001
*  GENERATED BY ROUTINES KOSSBS AND KOSSBE,                             13410001
*  THIS ENABLES ROUTINE KOSSB2 TO DELETE  X'41 FFFF FFFF'               13420001
*  WHEN DOING THE SECOND SCAN ON BUMP CODE SSUB LISTS FOR               13430001
*  TRANSFORMS.                                                          13440001
*                                                                       13500031
KOSSB3   IEMKENT                                                        13560031
         USING XMAP,GR6                                                 13620031
         BAL   RR,KOSSBS                MOVE FIRST PART OF SUBS LIST    13680031
*                                                                 30337 13686019
*                                                                 30337 13692019
         CLC   XMAPCVDR,XOPTSREF        CHECK IF THESE ARE EQUAL  30337 13698019
         BNE   SSB3DIFF                 BRANCH IF NOT             30337 13704019
*                                                                 30337 13710019
         OI    XOPTSREF+1,X'01'         TEMPORARILY MODIFY THE DR 30337 13716019
*   OF THE STEP FOR THE RANGE OF THIS ROUTINE TO EFFECT THE       30337 13722019
*            RESULT REQUIRED ABOVE.                               30337 13728019
SSB3DIFF EQU   *                                                  30337 13734019
         NI    XOPTSWCH,XOPTSWRS        SET SWITCH BITS TO ZERO         13740031
         NI    XOPTSWCH,XOPTRSMV        SET XOPTMLCV OFF                13770001
         LA    GR4,0                    L00P COUNTER                    13800031
*                                                                       13860031
         LA    GR2,XOPTTRP5-1           LENGTH OF ONE TRIPLE - 1        13920031
*                                                                       13980031
SSB3AGIN L     GR1,XOPTARA3             ADDRESS OF MATCHED TRIPLES      14040031
         AR    GR1,GR4                  ADD LOOP COUNTER                14100031
         MVC   XOPTTRPL,0(GR1)          MOVE NEXT TRIPLE TO WORK SPACE  14160031
         ST    GR1,PAR1                 SET PARAM.ADDR.FOR KNTRTY S/R   14220031
         BAL   RR,KNTRTY                TEST TRIPLE TYPE                14280031
*                                                                       14340031
         B     SSB3TRTY(RC)                                             14400031
SSB3TRTY B     SSB3OTHR                                                 14460031
         B     SSB3PLUS                 PLUS                            14520031
         B     SSB3MNUS                 MNUS                            14580031
         B     SSB3MULT                 MULT                            14640031
         B     SSB3OTHR                 DIV                             14700031
         B     SSB3CHK2                 PRF-                            14760031
         B     SSB3OTHR                 PRF+                            14820031
         B     SSB3COMA                 COMA                            14880031
*                                                                       14940031
         B     SSB3OTHR                 COMR                            15000031
SSB3OTHR OI    XOPTOPTX,XOPTUOPP        SET BIT-THIS MATCH UNOPT.       15060031
         NI    XOPTSWCH,XOPTRSMV        RESET XOPTMLCV OFF              15090001
         B     SSB3STPR                                                 15120031
*                                                                       15180031
SSB3PLUS NI    XOPTSWCH,XOPTRSMV        RESET XOPTMLCV OFF              15220001
         CLC   XOPTOP1,XMAPCVDR         COMPARE OP1 FOR CONTROL VAR.    15260001
         BE    SSB3PLSN                                                 15300031
         CLC   XOPTOP2,XMAPCVDR         COMPARE OP2 FOR CONTROL VAR.    15360031
         BNE   SSB3STPR                                                 15420031
         MVC   XOPTOP2,XOPTSREF         MOVE DREF.OF'STEP'TO OP2        15480031
SSB3SETS OI    XOPTSWCH,XOPTPRFP+XOPTEXCV  SET SWITCH BITS              15540031
         B     SSB3STPR                                                 15600031
*                                                                       15660031
SSB3MNUS TM    XOPTSWCH,XOPTMLCV        IS XOPTMLCV SET                 15667001
         BZ    SSB3MOP1                 BRANCH IF NOT                   15674001
*                                                                       15681001
         NI    XOPTSWCH,XOPTRSMV        CLEAR XOPTMLCV                  15688001
*                                                                       15695001
         CLC   XOPTOP2,XOPTC000         TEST IF OP2 IS X'00'            15702001
         BNE   SSB3STPR                 BRANCH IF NOT                   15709001
*                                                                       15716001
         MVC   XOPTPROP,XOPTC000        SET PRF- OP2 TO X'00'           15723001
         LA    GR3,XOPTPRFM                                             15730001
         BAL   RR,KOMOVE                MOVE 'PRF- 00FF 0000' TO PATCH  15737001
*                                                                       15744001
         B     SSB3STPR                                                 15751001
*                                                                       15758001
*                                                                       15765001
SSB3MOP1 CLC   XOPTOP1,XMAPCVDR         COMPARE OP1 FOR CONTROL VAR.    15772001
         BE    SSB3PLSN                                                 15780031
         CLC   XOPTOP2,XMAPCVDR         COMPARE OP2 FOR CONTROL VAR.    15840031
         BNE   SSB3STPR                                                 15900031
*                                                                       15960031
         MVC   XOPTPROP,XOPTSREF        MOVE DREF.'STEP'TOPRF- TRIPLE   16020031
         LA    GR3,XOPTPRFM                                             16080031
         BAL   RR,KOMOVE                MOVE'PRF- 00FF(STEP)'TO PATCH   16140031
*                                                                       16200031
         OI    XOPTSWCH,XOPTEXCV        SET SWITCH                      16260031
         B     SSB3STPR                                                 16320031
*                                                                       16380031
SSB3MULT NI    XOPTSWCH,XOPTRSMV        RESET XOPTMLCV OFF              16410001
         CLC   XOPTOP1,XMAPCVDR         COMPARE OP1 FOR CONTROL VAR.    16440001
         BE    SSB3SMLC                                                 16470001
         B     SSB3CKM2                 BRANCH TO CHECK MULT OP2        16500001
SSB3CHK2 CLC   XOPTOP2,XMAPCVDR         COMPARE OP2 FOR CONTROL VAR.    16560031
         BNE   SSB3STPR                                                 16620031
SSB3MVCS MVC   XOPTOP2,XOPTSREF         MOVE DREF. OF'STEP' TO OP2      16680031
SSB3MLTN LA    GR3,XOPTTRPL                                             16740031
         BAL   RR,KOMOVE                                                16800031
*                                                                       16860031
         OI    XOPTSWCH,XOPTEXCV        SET SWITCH   CV PRESENT         16920031
*                                                                       16980031
SSB3COCD CLI   XOPTCODE,XTRPCOMA        TEST CURRENT TRIPLE IS A COMA   17040031
         BNE   SSB3STPR                                                 17100031
*                                                                       17160031
         NI    XOPTSWCH,XOPTSWRS        SET SWITCH BITS TO ZERO         17220031
*                                                                       17280031
SSB3STPR LA    GR4,XOPTTRP5(,GR4)       INCREMENT COUNTER BY            17340031
*                                       TRIPLE LENGTH                   17400031
*                                                                       17460031
         CH    GR4,XOPTMCHR             TEST FOR END OF MATCHED TRIPLES 17520031
         BL    SSB3AGIN                 BRANCH IF NOT END OF TRIPLES    17580031
         B     SSB3LAST                                                 17640031
*                                                                       17700031
*                                                                       17705001
SSB3SMLC OI    XOPTSWCH,XOPTMLCV        SET XOPTMLCV                    17710001
         B     SSB3MOVN                                                 17715001
*                                                                       17720001
*                                                                       17725001
SSB3CKM2 CLC   XOPTOP2,XMAPCVDR         COMPARE OP2 FOR CV              17730001
         BNE   SSB3STPR                 BRANCH IF NOT                   17735001
*                                                                       17740001
         OI    XOPTSWCH,XOPTMLCV        SET XOPTMLCV                    17745001
         B     SSB3MVCS                 REJOIN MAIN PATH                17750001
*                                                                       17755001
SSB3COMA NI    XOPTSWCH,XOPTRSMV        RESET XOPTMLCV OFF              17775001
         CLC   XOPTOP2,XOPTC000         TEST OP2 OF COMA = 0            17795001
         BNE   SSB3CKCV                                                 17820031
*                                                                       17880031
         TM    XOPTSWCH,XOPTPRFP                                        17940031
         BO    SSB3MVCM                                                 18000031
*                                                                       18060031
         TM    XOPTSWCH,XOPTEXCV                                        18120031
         BO    SSB3MLTN                                                 18180031
*                                                                       18240031
SSB3COMN LA    GR3,XOPTCOMN             ADDRESS OF COMA NULL TRIPLE     18300031
         MVC   XOPTCOMN+1(2),XOPTCOMN+3 SET COMA NULL OP1 TO X'FFFF'    18360031
         BAL   RR,KOMOVE                MOVE COMA NULL TO PATCH BUILD   18420031
         MVC   XOPTCOMN+1(2),XOPTNOPT+1 RESET COMA NULL OP1 TO X'00FF'  18480031
         B     SSB3COCD                                                 18540031
*                                                                       18600031
SSB3MVCM MVC   XOPTOP2,XOPTSREF         MOVE DREF.OF'STEP' TO OP1       18660031
         LA    GR3,XOPTTRPL             ADDRESS OF TRIPLE WORK SPACE    18720031
         BAL   RR,KOMOVE                MOVE COMA TRIPLE                18780031
         B     SSB3COCD                                                 18840031
*                                                                       18900031
SSB3PLSN MVC   XOPTOP1,XOPTSREF         MOVE DREF.OF'STEP' TO OP1       18960031
         B     SSB3SETS                                                 19020031
*                                                                       19080031
SSB3MOVN MVC   XOPTOP1,XOPTSREF         MOVE DREF.OF'STEP' TO OP1       19140031
         B     SSB3MLTN                                                 19200031
*                                                                       19260031
SSB3CKCV CLC   XOPTOP2,XMAPCVDR         TEST FOR CONTROL VARIABLE       19320031
         BE    SSB3MVCS                 BRANCH IF CONTROL VARIABLE      19380031
         B     SSB3COMN                                                 19440031
*                                                                       19500031
SSB3LAST BAL   RR,KOSSBE                MOVE LAST PART OF SUBS LIST     19560031
*                                                                 30337 19570019
         NI    XOPTSREF+1,X'FE'         CLEAR FLAG IN STEP DR     30337 19580019
*                                                                 30337 19590019
         DROP  GR6                                                      19620031
SSB3EXIT IEMKLVE                                                        19680031
         EJECT                                                          19740031
         EJECT                                                          19800031
** KOSSB2                     DESTROYS  GR1 THROUGH GR5                 19860031
*                                                                       19920031
*  SUBROUTINE TO MOVE A SUBSCRIPT LIST INTO THE PATCH BUILD AREA        19980031
*  CHANGING THE SUBS/SUB' TRIPLES TO SSUB/SSB'.                         20040031
*  ALL MATCHED COMA EXPRESSIONS ARE COPIED EXCEPT THE DICTIONARY        20100031
*  REFERENCES TO THE CONTROL VARIABLE ARE REPLACED BY DICTIONARY        20160031
*  REFERENCES TO THE 'INITIAL' (INITIAL,STEP,LIMIT TAKEN FROM SPEC. OF  20220031
*  CURRENT DO LOOP).                                                    20280031
*  ALL UNMATCHED COMA EXPRESSIONS ARE REPLACED BY COMA NULL.            20340031
*     COMA NULL = X'41 00FF FFFF'                                       20400031
*                                                                       20460031
KOSSB2   IEMKENT  TYPE=2                                                20520031
*                                                                       20580031
         USING XMAP,GR6                                                 20640031
*                                       MOVE FIRST PART OF SUBS LIST    20700031
         BAL   RR,KOSSBS                                                20760031
         NI    XOPTOPTX,XOPTCTRS        SET SWITCH BITS TO ZERO         20820031
*                                       MOVE AND AMEND THE MATCHED      20880031
*                                       TRIPLES IN THE PATCH BUILD      20940031
*                                       AREA                            21000031
*                                                                       21060031
         LA    GR4,0                    LOOP COUNTER                    21120031
         LA    GR3,XOPTTRPL             ADDRESS OF TRIPLE WORK SPACE    21180031
         LA    GR2,XOPTTRP5-1           LENGTH OF ONE TRIPLE - 1        21240031
SSB2AGIN L     GR1,XOPTARA3             ADDRESS OF MATCHED TRIPLES      21300031
         AR    GR1,GR4                  ADD LOOP COUNTER                21360031
         MVC   XOPTTRPL,0(GR1)          MOVE NEXT TRIPLE TO WORK SPACE  21420031
         ST    GR1,PAR1                 SET PARAM.ADDR.FOR KNTRTY S/R.  21480031
         BAL   RR,KNTRTY                TEST TRIPLE TYPE                21540031
         B     SSB2TRTY(RC)                                             21600031
SSB2TRTY B     SSB2OTHR                                                 21660031
         B     SSB2BOTH                 PLUS                            21720031
         B     SSB2BOTH                 MNUS                            21780031
         B     SSB2BOTH                 MULT                            21840031
         B     SSB2BOTH                 DIV                             21900031
         B     SSB2SECN                 PRF-                            21960031
         B     SSB2SECN                 PRF+                            22020031
         B     SSB2COMA                 COMA                            22080031
         B     SSB2OTHR                                                 22140031
*                                                                       22200031
SSB2COMA CLC   XOPTTRPL,XOPTCOMN        TEST FOR COMA NULL              22260031
         BE    SSB2OTHR                 DELETE COMA NULL                22320031
         B     SSB2SECN                                                 22380031
*                                                                       22440031
SSB2BOTH CLC   XOPTOP1,XMAPCVDR         COMPARE OP1 FOR CONTROL VAR.    22500031
         BNE   SSB2COP1                                                 22560031
*                                                                       22620031
         MVC   XOPTOP1,XOPTIREF         MOVE DICT.REF.OF'INITIAL'TO OP1 22680031
         B     SSB2CONS                                                 22740031
*                                                                       22800031
SSB2COP1 CLI   XOPTOP1+1,X'FF'          TEST FOR COMA NULL        30337 22810019
         BE    SSB2BYP1                                           30337 22820019
*                                                                 30337 22830019
         NI    XOPTOP1+1,X'FE'          ENSURE FLAG POSSIBLY SET  30337 22840019
*                                       BY KOSSB3 IS NOW SET OFF  30337 22850019
SSB2BYP1 EQU   *                                                  30337 22860019
         TM    XOPTOPTX,XOPTCTCT        TEST FOR COMPILE TIME CNST30337 22890019
         BZ    SSB2SECN                 BRANCH IF NO COMP.TIME CONST.   22920031
*                                                                       22980031
         CLC   XOPTOP1,XOPTC000         TEST OP1  FOR  ZERO             23040031
         BNE   SSB2SECN                                                 23100031
*                                                                       23160031
         TM    XOPTOPTX,XOPTCTCM        TEST MULT SWITCH                23220031
         BZ    SSB2PLMN                 BRANCH IF MULT SKIPPED          23280031
*                                                                       23340031
*                                                                       23400031
SSB2FRST MVC   XOPTOP1,XOPTDRF3         MOVE DREF.OF COMP.TIME CONST.   23460031
         NI    XOPTOPTX,XOPTCTRS        CLEAR COMP.TIME CONST. SWITCH   23520031
*                                                                       23580031
SSB2SECN CLC   XOPTOP2,XMAPCVDR         COMPARE OP2 FOR CONTROL VAR.    23640031
         BNE   SSB2COP2                                                 23700031
*                                                                       23760031
         MVC   XOPTOP2,XOPTIREF         MOVE DICT.REF.OF'INITIAL'TO OP1 23820031
         B     SSB2CHCK                                                 23880031
*                                                                       23940031
SSB2COP2 CLI   XOPTOP2+1,X'FF'          TEST FOR COMA NULL        30337 23950019
         BE    SSB2BYP2                                           30337 23960019
*                                                                 30337 23970019
         NI    XOPTOP2+1,X'FE'          ENSURE FLAG POSSIBLY SET  30337 23980019
*                                       BY KOSSB3 IS NOW SET OFF  30337 23990019
SSB2BYP2 EQU   *                                                  30337 24000019
         TM    XOPTOPTX,XOPTCTCT        TEST FOR COMPILE TIME CNST30337 24030019
         BZ    SSB2CONS                 BRANCH IF NO COMP.TIME CONST.   24060031
*                                                                       24120031
         CLC   XOPTOP2,XOPTC000         TEST OP2 FOR ZERO               24180031
         BNE   SSB2EXTR                                                 24240031
*                                                                       24300031
         MVC   XOPTOP2,XOPTDRF3         MOVE DREF.OF COMP.TIME CONST.   24360031
         NI    XOPTOPTX,XOPTCTRS        CLEAR COMP.TIME CONST.SWITCH    24420031
         B     SSB2CONS                                                 24480031
*                                                                       24540031
SSB2EXTR CLI   XOPTTRPL,XTRPMULT        TEST OPCODE EQUALS MULTIPLY     24600031
         BNE   SSB2NEXT                 BRANCH IF NO                    24660031
*                                                                       24720031
         OI    XOPTOPTX,XOPTCTCM        SET MULT SWITCH                 24780031
         B     SSB2NEXT                                                 24840031
*                                                                       24900031
SSB2PLMN CLC   XOPTOP2,XOPTC000         TEST OP2 FOR ZERO               24960031
         BNE   SSB2FRST                 BRANCH BACK TO FILL IN OP1      25020031
         B     SSB2SECN                 BRANCH TO FILL IN OP2           25080031
*                                                                       25140031
*                                                                       25200031
SSB2CHCK TM    XOPTOPTX,XOPTCTCT        CHECK PREVIOUS COMPILE TIME     25260031
         BO    SSB2EROR                 CONSTANT DEALT WITH             25320031
*                                                                       25380031
         B     SSB2CONS                                                 25440031
*                                                                       25500031
SSB2NEXT BAL   RR,KOMOVE                MOVE CURRENT TRIPLE TO PATCH    25560031
*                                       BUILD AREA                      25620031
*                                                                       25680031
SSB2OTHR LA    GR4,XOPTTRP5(,GR4)       INCREMENT COUNTER BY            25740031
*                                       TRIPLE LENGTH                   25800031
*                                                                       25860031
         CH    GR4,XOPTMCHR             TEST FOR END OF MATCHED TRIPLES 25920031
         BL    SSB2AGIN                 BRANCH IF NOT END OF TRIPLES    25980031
         B     SSB2LAST                                                 26040031
*                                                                       26100031
SSB2CONS CLI   XOPTCODE,XTRPCOMA        TEST TRIPLE CODE.               26160031
         BE    SSB2NEXT                 BRANCH IF COMA                  26220031
         BAL   RR,KOMAKC                MAKE COMPILE TIME CONSTANT      26280031
*                                                                       26340031
         LTR   RC,RC                    TEST RETURN CODE FROM KOMAKC    26400031
         BNZ   SSB2NEXT                 BRANCH IF NO CONSTANT MADE      26460031
*                                                                       26520031
         MVC   XOPTTRPL,XOPTNOPT        NO OP CURRENT TRIPLE            26580031
         B     SSB2NEXT                                                 26640031
*                                                                       26700031
*                                                                       26760031
SSB2LAST TM    XOPTOPTX,XOPTCTCT        TEST COMPILE TIME CONST.        26820031
         BO    SSB2EROR                 DEALT WITH                      26880031
*                                                                       26940031
         BAL   RR,KOSSBE                MOVE LAST PART OF SUBS LIST     27000031
         B     SSB2EXIT                                                 27060031
*                                                                       27120031
SSB2EROR L     GR1,XOPTC001             NUMERIC PARAM. TO ERROR MESSAGE 27180031
         B     KOEROR                   GIVE MESSAGE AND ABORT          27240031
*                                                                       27300031
*                                                                       27360031
*                                                                       27420031
         DROP  GR6                                                      27480031
SSB2EXIT IEMKLVE                                                        27540031
         EJECT                                                          27600031
** KOSSB1                     DESTROYS  GR1 THROUGH GR5                 27660031
*                                                                       27720031
*  SUBROUTINE TO MOVE A SUBSCRIPT LIST INTO THE PATCH BUILD AREA        27780031
*  CHANGING THE  SUBS/SUB' TRIPLES TO SSUB/SSB'.                        27840031
*  ALL MATCHED COMA EXPRESSIONS ARE COPIED.                             27900031
*  ALL UNMATCHED COMA EXPRESSIONS ARE REPLACED BY COMA NULL.            27960031
*     COMA NULL =  X'41 00FF FFFF'.                                     28020031
*                                                                       28080031
KOSSB1   IEMKENT  TYPE=2                                                28140031
*                                       MOVE FIRST PART OF SUBS LIST    28200031
         BAL   RR,KOSSBS                                                28260031
*                                                                       28320031
*                                                                       28380031
         L     GR3,XOPTARA3             MOVE MATCHED TRIPLES TO         28440031
         LH    GR2,XOPTMCHR             PATCH BUILD AREA                28500031
         BCTR  GR2,0                                                    28560031
         BAL   RR,KOMOVE                                                28620031
*                                       MOVE LAST PART OF SUBS LIST     28680031
         BAL   RR,KOSSBE                                                28740031
SSBIEXIT IEMKLVE                                                        28800031
         EJECT                                                          28860031
** KOPTCH                                                               28920031
*                                                                       28980031
*  SUBROUTINE TO MAKE AN ENTRY IN THE PATCH FILE FROM THE PATCH BUILD   29040031
*  AREA. OPTIONS ARE AVAILABLE TO MOVE THE PATCH DATA TO THE PATCH      29100031
*  BUILD AREA BEFORE MAKING AN ENTRY IN THE PATCH FILE. ENTRIES ARE     29160031
*  CHAINED TOGETHER IF THEY ARE TO BE INSERTED AT THE SAME POINT IN     29220031
*  TEXT. A PTCH TRIPLE IS PLACE IN THE TEXT AT THE POINT OF INSERTION.  29280031
*  THE OVERWRITTEN TRIPLE IS PLACED IN THE PATCH.                       29340031
*                                                                       29400031
*   TYPE IN GR0 =  X'01'     ITDO PATCH                                 29460031
*                  X'02'     ITD' PATCH                                 29520031
*                  X'04'     OTHER PATCH,XPCHCODE=X'00'                 29580031
*                  X'08'     OTHER PATCH,XPCHCODE=X'20'                 29640031
*                  X'11'     MOVE PATCH TO PATCH BUILD THEN AS X'01'    29700031
*                  X'22'     MOVE PATCH TO PATCH BUILD THEN AS X'02'    29760031
*                  X'44'     MOVE PATCH TO PATCH BUILD THEN AS X'04'    29820031
*                  X'88'     MOVE PATCH TO PATCH BUILD THEN AS X'08'    29880031
*     IF MOVE,SPECIFIED LENGTH IN GR2                                   29940031
*                      ADDRESS IN GR3                                   30000031
*     IF OTHER TYPE, TEXT REF. OF TRIPLE TO BE OVERWRITTEN IN XOPTTADR  30060031
*                                                                       30120031
KOPTCH   IEMKENT TYPE=1                                                 30180031
         IEMKTAB DEACT,XLCRPCH                                          30240031
         USING XPCH,GR4                                                 30300031
         USING XMAP,GR6                                                 30360031
         L     GR4,XOPTXPCH             BASE ADDR OF PATCH BUILD AREA.  30420031
         L     GR6,XOPTXMAP             BASE ADDR. OF CURRENT XMAP      30480031
         MVC   XPCHCHN,XOPTC000         CLEAR PATCH CHAIN.              30540031
         CH    GR0,XOPTH016             TEST TYPE                       30600031
         BNH   PTCHNOMV                 BRANCH IF NO MOVE REQUIRED      30660031
*                                                                       30720031
         MVC   XOPTSCRP,XOPTC000        SET PATCH BUILD POINTER TO ZERO 30780031
         BAL   RR,KOMOVE                MOVE PATCH                      30840031
*                                                                       30900031
PTCHNOMV LA    GR2,XOPTTRP5-1           LENGTH OF TRIPLE - 1            30960031
         LH    GR3,XOPTSCRP                                             31020031
         LA    GR3,XPCHDATA-XPCH(,GR3)  ADD LENGTH OF FIXED FIELDS      31080031
         AH    GR3,XOPTCH10             ADD LENGTH OF TWO TRIPLES       31140031
*                                       TO ALLOW FOR OVERWRITTEN TRIPLE 31200031
*                                                AND END OF PATCH TRPL. 31260031
         STH   GR3,XOPTWORK+2                                           31320031
         MVC   XPCHLEN,XOPTWORK+2                                       31380031
*                                                                       31440031
         LA    GR3,XOPTEOPT             MOVE END OF PATCH TRIPLE        31500031
         BAL   RR,KOMOVE                TO PATCH BUILD AREA             31560031
*                                                                       31620031
         MVC   XOPTSCRP,XOPTC000        CLEAR PATCH BUILD AREA POINTER  31680031
*                                                                       31740031
         LA    GR3,XOPTNOPT                                             31800031
*                                       MOVE NOP TRIPLE TO FIRST        31860031
         MVC   XPCHDATA-XPCH(XOPTTRP5,GR4),0(GR3)                       31920031
*                                       SPACE IN PATCH                  31980031
         MVC   XOPTSCRP,XOPTC000        RESET PATCH BUILD AREA POINTER  32040031
*                                       IN CASE  NO OP.TO BE OVERWRITN. 32100031
         STC   GR0,XOPTBYTE             STORE TYPE                      32160031
         TM    XOPTBYTE,XOPTPITD        TEST FOR ITDO TYPE PATCH        32220031
         BZ    PTCHTRY1                                                 32280031
*                                                                       32340031
**************                          NOW MAKE AN ITDO TYPE PATCH     32400031
*                                       *** 1ST TIME PATCH ***          32460031
         MVI   XPCHCODE,XPCHITDO        SET PATCH CODE TO ITDO TYPE.    32520031
         TM    XOPTOPTX,XOPTCHN1        TEST IF PATCH CHAIN REQUIRED    32580031
         BO    PTCHCHN1                 BRANCH IF CHAIN REQUIREQUIRED   32640031
*                                                                       32700031
         OI    XOPTOPTX,XOPTCHN1        SET SWITCH ON TO CAUSE ALL      32760031
*                                       FOLLOWING PATCHES AT ITDO TO    32820031
*                                       BE CHAINED TO THIS ONE          32880031
*                                                                       32940031
       IEMKTAB DR,XLCRTXT,SA=XMAPITDO,AATO=(GR3)                        33000031
*                                                                       33060031
         MVC   XOPTWKTX,XMAPITDO        SET PARAM.FOR S/R KOPCOM        33120031
         BAL   RR,KOPCOM                MOVE    A TRIPLE TO PATCH BUILD 33180031
*                                       AND MAKE PATCH ENTRY            33240031
*                                                                       33300031
         MVC   XOPTWKTX,XOPTPCH1        SAVE'PATCH BEFORE LAST'ADDRESS  33360031
         MVC   XOPTPCH1,XOPTPCH4        SAVE LAST PATCH ADDRESS         33420031
*                                                                       33480031
       IEMKTAB DR,XLCRMAP,SA=XMAPOUTR,AATO=(GR5)                        33540031
         DROP  GR6                                                      33600031
         USING XMAP,GR5                 ADDRESS XMAP TABLE ELEMENT      33660031
*                                       TEST GLOBAL REGION BOUNDARY     33720031
         CLI   XMAPLEVL,XMAPEQ00        TEST FOR ENCLOSING PROC.OR ITDO 33780031
         BE    PTCHEXIT                 BRANCH IF PROC.                 33840031
         CLI   XMAPPTCH,XOPTEQFF        TEST IF AN EXTERNAL PATCH CHAIN 33900031
*                                       ALREADY EXISTS ON THE ENCLOSING 33960031
*                                       LOOP                            34020031
         BNE   PTCHZCHN                 BRANCH IF A CHAIN EXISTS TO     34080031
*                                       CONTINUE THE CHAIN              34140031
*                                                                       34200031
*                                                                       34260031
         MVC   XMAPPTCH,XOPTPCH4        START EXTERNAL PATCH CHAIN      34320031
*                                       ON ENCLOSING DO MAP ENTRY       34380031
         DROP  GR5                                                      34440031
         USING XMAP,GR6                 RESTORE ADDRESSABILITY OF       34500031
*                                       XMAP ELEMENT IN SCRATCH         34560031
         MVC   XMAPKPCH,XOPTPCH4        SAVE CURRENT END OF EXTERNAL    34620031
*                                       PATCH CHAIN ADDRESS             34680031
         B     PTCHEXIT                                                 34740031
*                                                                       34800031
         DROP  GR6                                                      34860031
         USING XMAP,GR5                 ADDRESS ENCLOSING DO MAP ENTRY  34920031
*                                                                       34980031
PTCHZCHN IEMKTAB  DR,XLCRPCH,SA=XMAPKPCH,AATO=(GR4)                     35040031
         MVC   XPCHCHN,XOPTPCH4         CONTINUE PATCH CHAIN            35100031
*                                                                       35160031
         DROP  GR5                                                      35220031
         USING XMAP,GR6                 ADDRESS XMAP ELEMENT IN SCRATCH 35280031
*                                                                       35340031
         MVC   XMAPKPCH,XOPTPCH4        SAVE CURRENT END OF EXTERNAL    35400031
*                                       PATCH CHAIN ADDRESS             35460031
         B     PTCHEXIT                                                 35520031
*                                                                       35580031
*                                                                       35640031
**************                          *** NOT 1ST TIME ITDO PATCH *** 35700031
*                                                                       35760031
PTCHCHN1 MVC   XOPTWKTX,XOPTPCH1                                        35820031
*                                                                       35880031
       IEMKTAB BLDC,XLCRPCH,(GR4),SATO=XOPTPCH4   MAKE PATCH.           35940031
*                                                                       36000031
         MVC   XOPTPCH1,XOPTPCH4        SAVE LAST PATCH ADDRESS         36060031
*                                                                       36120031
       IEMKTAB DR,XLCRPCH,SA=XOPTWKTX,AATO=(GR4)                        36180031
*                                                                       36240031
         MVC   XPCHCHN,XOPTPCH4         CONTINUE PATCH CHAIN            36300031
         MVC   XMAPKPCH,XOPTPCH4        SAVE CURRENT END OF EXTERNAL    36360031
*                                       PATCH CHAIN ADDRESS             36420031
         B     PTCHEXIT                                                 36480031
*                                                                       36540031
*                                                                       36600031
**************                                                          36660031
*                                                                       36720031
PTCHTRY1 TM    XOPTBYTE,XOPTPITP             TEST FOR ITD' TYPE PATCH   36780031
         BZ    PTCHTRY2                                                 36840031
*                                                                       36900031
**************                          NOW MAKE AN ITD' TYPE PATCH     36960031
PTCHOPT1 MVI   XPCHCODE,XPCHITDP        SET PATCH CODE TO ITDP TYPE.    37020031
PTCHOPT2 TM    XOPTOPTX,XOPTCHN2        TEST IF PATCH CHAIN REQUIRED.   37080031
         BO    PTCHCHN2                 BRANCH IF CHAIN REQUIRED        37140031
*                                                                       37200031
         OI    XOPTOPTX,XOPTCHN2        SET SWITCH ON TO CAUSE ALL      37260031
*                                       FOLLOWING PATCHES AT ITD' TO    37320031
*                                       BE CHAINED TO THIS ONE          37380031
*                                                                       37440031
*                                                                       37500031
** MAKE ITD' TYPE PATCH AT THE TRIPLE FOLLING THE ITD' (CLN2 TRIPLE)    37560031
** IF LOOP IS NOT OPTIMISABLE FOR BXLE,BXH.                             37620031
*                                                                       37680031
** THIS SPECIAL ACTION IS REQUIRED BECAUSE LG ASSUMES ITD' ALWAYS       37740031
** FOLLOWED BY CLN2                                                     37800031
*                                                                       37860031
*                                                                       37920031
       IEMKTAB SET,XLCRTXT,SA=XOPTPREF  SET TO ITD'                     37980031
       IEMKTAB SCAN,XLCRTXT,AATO=(GR3)                                  38040031
       IEMKTAB SCAN,XLCRTXT,AATO=(GR3),SATO=XOPTWKTX  SCAN TO CLN2      38100031
*                                                                       38160031
         TM    XOPTOPTX,XOPTNKBX         TEST IF BXLE,BXH POSSIBLE      38220031
         BZ    PTCHOPT3                 BRANCH IF POSSIBLE              38280031
*                                                                       38340031
**  SET PATCH CODE TO 0 OVEWRITING ITD' CODE                            38400031
*                                                                       38460031
         MVI   XPCHCODE,XPCHOTHR                                        38520031
         B     PTCHOPT4                                                 38580031
*                                                                       38640031
PTCHOPT3 MVI   0(GR3),XTRPNOP           OVERWRITE CLN2 TRIPLE WITH NOP  38700031
         IEMKTAB  DR,XLCRTXT,SA=XOPTPREF,AATO=(GR3)   ITD'              38760031
*                                                                       38820031
         MVC   XOPTWKTX,XOPTPREF        SET PARAM.FOR S/R KOPCOM        38880031
PTCHOPT4 BAL   RR,KOPCOM                MOVE A TRIPLE TO PATCH BUILD    38940031
*                                       AND MAKE PATCH ENTRY            39000031
*                                                                       39060031
         MVC   XOPTPCH2,XOPTPCH4        SAVE LAST PATCH ADDRESS         39120031
*                                                                       39180031
         B     PTCHEXIT                                                 39240031
*                                                                       39300031
**************                          *** NOT 1ST TIME ITDO PATCH *** 39360031
*                                                                       39420031
PTCHCHN2 MVC   XOPTWKTX,XOPTPCH2                                        39480031
*                                                                       39540031
       IEMKTAB BLDC,XLCRPCH,(GR4),SATO=XOPTPCH4   MAKE PATCH.           39600031
*                                                                       39660031
         MVC   XOPTPCH2,XOPTPCH4        SAVE LAST PATCH ADDRESS         39720031
*                                                                       39780031
       IEMKTAB DR,XLCRPCH,SA=XOPTWKTX,AATO=(GR4)                        39840031
*                                                                       39900031
         MVC   XPCHCHN,XOPTPCH4         CONTINUE PATCH CHAIN            39960031
         B     PTCHEXIT                                                 40020031
*                                                                       40080031
*                                                                       40140031
**************                          NOW MAKE A NON ITDO,NON ITD'    40200031
*                                       TYPE PATCH                      40260031
*                                       *** 1ST TIME PATCH ***          40320031
PTCHTRY2 TM    XOPTBYTE,XOPTPOTH                                        40380031
         BZ    PTCHSET2                                                 40440031
         MVI   XPCHCODE,XPCHOTHR        PATCH TRIPLES ARE NOT TO BE     40500031
*                                        REORDERED BY MERGE PATCHES .   40560031
         B     PTCHONCD                                                 40620031
*                                                                       40680031
PTCHSET2 MVI   XPCHCODE,XPCHLAST                                        40740031
PTCHONCD DS    0H                                                       40800031
       IEMKTAB DR,XLCRTXT,SA=XOPTTADR,AATO=(GR5)                        40860031
*                                                                       40920031
         CLI   0(GR5),XTRPPTCH        COMPARE TRIPLE AT XOPTTADR        40980031
*                                       FOR OP.CODE = PTCH              41040031
         BE    PTCHCHN3                 BRANCH IF CHAIN REQUIRED        41100031
*                                                                       41160031
*                                                                       41220031
         LR    GR3,GR5                  SET ADDRESS TRIPLE TO BE OVER-  41280031
*                                       WRITTEN                         41340031
         MVC   XOPTWKTX,XOPTTADR        SET PARAM.FOR S/R KOPCOM        41400031
         BAL   RR,KOPCOM                MOVE    A TRIPLE TO PATCH BUILD 41460031
*                                       AND MAKE PATCH ENTRY            41520031
         CLC   XOPTTADR,XMAPITPP        IS THIS A PATCH BEFORE          41580031
         BNE   PTCHOCHN                  ITD' TRIPLE. BRANCH IF NO.     41640031
*                                                                       41700031
         MVC   XOPTPCH5,XOPTPCH4        SAVE LAST 'ITPP' PATCH ADDRESS. 41760031
         B     PTCHEXIT                                                 41820031
*                                                                       41880031
PTCHOCHN MVC   XOPTPCH3,XOPTPCH4        SAVE LAST 'OTHER' PATCH ADDR.   41940031
         B     PTCHEXIT                                                 42000031
*                                                                       42060031
**************                          *** NOT 1ST TIME      ***       42120031
*                                       *** NON ITDO,NON ITD' ***       42180031
PTCHCHN3 DS    0H                                                       42240031
       IEMKTAB BLDC,XLCRPCH,(GR4),SATO=XOPTPCH4                         42300031
*                                       MAKE PATCH.                     42360031
         CLC   XOPTTADR,XMAPITPP        IS THIS A PATCH BEFORE ITD'     42420031
         BNE   PTCHXCHN                 BRANCH IF NO.                   42480031
*                                                                       42540031
         MVC   XOPTWKTX,XOPTPCH5        MOVE LAST PATCH ADDRESS TO WKTX 42600031
         MVC   XOPTPCH5,XOPTPCH4        MOVE THIS PATCH ADDR TO LAST.   42660031
         B     PTCHYCHN                                                 42720031
*                                                                       42780031
PTCHXCHN MVC   XOPTWKTX,XOPTPCH3        MOVE LAST PATCH ADDR TO WKTX.   42840031
         MVC   XOPTPCH3,XOPTPCH4        MOVE THIS PATCH ADDR TO LAST.   42900031
*                                                                       42960031
PTCHYCHN DS    0H                                                       43020031
       IEMKTAB DR,XLCRPCH,SA=XOPTWKTX,AATO=(GR4)                        43080031
*                                                                       43140031
PTCHCONT MVC   XPCHCHN,XOPTPCH4         CONTINUE PATCH CHAIN            43200031
*                                                                       43260031
*                                                                       43320031
         DROP  GR4                                                      43380031
         DROP  GR6                                                      43440031
*                                                                       43500031
PTCHEXIT IEMKTAB DEACT,XLCRPCH                                          43560031
         IEMKLVE                                                        43620031
         EJECT                                                          43680031
** KOPCOM                                                               43740031
*                                                                       43800031
*  SUBROUTINE CALLED BY SUBROUTINE  KOPTCH  TO MAKE PATCH FILE ENTRY    43860031
*     INPUT PARAMETERS                                                  43920031
*     REQUIRED GR2= 4                                                   43980031
*              GR3= ADDRESS OF A TRIPLE TO BE MOVED TO PATCH            44040031
*              XOPTWKTX= TEXT REF.OF TRIPLE TO BE OVERWRITTEN WITH PTCH 44100031
*     RETURNS  XOPTPCH4= SYMB.TEXT REF.OF PATCH FILE ENTRY              44160031
KOPCOM   IEMKENT  TYPE=2                                                44220031
*                                                                       44280031
*                                       MOVE A TRIPLE TO PATCH BUILD    44340031
*                                                                       44400031
*        MOVE THE TRIPLE TO BE OVERWRITTEN TO START OF                  44460031
*        PATCH DATA AREA IN PATCH BUILD                                 44520031
         MVC   XPCHDATA-XPCH(XOPTTRP5,GR4),0(GR3)                       44580031
       IEMKTAB BLDC,XLCRPCH,(GR4),SATO=XOPTPCH4   MAKE PATCH            44640031
*                                                                       44700031
       IEMKTAB DR,XLCRTXT,SA=XOPTWKTX,AATO=(GR5)       TRIPLE TO BE     44760031
*                                                      OVERWRITTEN      44820031
         MVC   XOPTPCHT+2(L'XOPTPCH4),XOPTPCH4  MOVE PATCH ADDRESS      44880031
         MVC   0(XOPTTRP5,GR5),XOPTPCHT  OVERWRITE TRIPLE.              44940031
*                                                                       45000031
PCOMEXIT IEMKLVE                                                        45060031
         EJECT                                                          45120031
** KOMTCH                GR6 POINTS TO XSRT(XOPTSTPS) ON ENTRY          45180031
*                                                                       45240031
*  SUBROUTINE TO MAKE ENTRIES IN  THE PATCH FILE AND PROCESS A MATCH    45300031
*  CHAIN. THE PATCH ENTRIES CONTAIN OPIMISED CODE FOR THE 3 TYPES       45360031
*  OF SUBSCRIPT OPTIMISATION I.E. TRANSFORMED CONTROL VARIABLE,         45420031
*  INVARIANTS AND COMMONED EXPRESSIONS ALSO PATCHES MAY BE MADE FOR     45480031
*  THE BXLE,BXH CODE FOR OPTIMISED LOOP CONTROL.                        45540031
KOMTCH   IEMKENT  TYPE=2                                                45600031
*                                                                       45660031
         CLI   XOPTOPFL,XOPTTRIV        IS THIS A MATCH CHAIN FOR       45720031
         BNE   MTCHCHP3                 TRANSFORMS AND INVARIANTS       45780031
         USING XSKL,GR2                                                 45840031
         USING XTRP,GR3                                                 45900031
         USING XMAP,GR6                                                 45960031
         USING XSRT,GR5                                                 46020031
         USING XDRF,GR4                                                 46080031
         LR    GR5,GR6                                                  46140031
         LR    GR3,GR5                  PARAM TO KOCVTX S/R             46200031
         L     GR6,XOPTXMAP                                             46260031
*  MAKE TESTS ON ITERATIVE SPECIFICATION OF CURRENT LOOP TO SEE IF IT   46320031
*  IS POSSIBLE TO MODIFY IT.SPEC. TRIPLES TO CAUSE BUMP CODE OF A       46380031
*  TRANSFORM TO BE COMBINED WITH THE BXLE,BXH CODE OF LOOP CONTROL      46440031
*                                                                       46500031
         TM    XOPTOPTX,XOPTOKIT       TEST'IT.SPEC.MODIFIED'SWITCH     46560031
         BO    MTCHL22B                BRANCH IF MODIFIED               46620031
*                                                                       46680031
*                                                                       46740031
         TM    XMAPLOOP,XMAPAELP                                        46800031
         BZ    MTCHL22B                 BRANCH IF NOT AN ARRAY EXP.     46860031
*                                                                       46920031
         TM    XMAPLOOP,XMAPSBMS        TEST IF ENTRY OMITTED FROM XSRT 46980031
         BO    MTCHL22B                 BRANCH IF ANY OMITTED           47040031
*                                                                       47100031
         TM    XOPTOPTX,XOPTNKBX        TEST IF BXLE,BXH POSSIBLE FOR   47160031
         BO    MTCHL22B                 THIS LOOP,BRANCH IF NOT POSSIBL 47220031
*                                                                       47280031
         MVC   XOPTCNTR+2(2),XOPTLCOM   LAST MATCHED COMA NO            47340031
         MVC   XOPTCLIM+2(2),XOPTFCOM   FIRST MATCHED COMA NO           47400031
         BAL   RR,KOCVTX               TEST FOR CV IN MATCHED TRIPLES   47460031
*                                                                       47520031
         LTR   RC,RC                                                    47580031
         BZ    MTCHL22B                 BRANCH IF CV NOT FOUND          47640031
*                                                                       47700031
         TM    XOPTOPTX,XOPTISLC       TEST IF 'INIT','STEP','LIM'      47760031
         BO    MTCHL22B                ALL CONSTS.BRANCH IF NOT         47820031
*                                                                       47880031
         CLI   XOPTCOMS,XTRPCOMA                                        47940031
         BNE   MTCHL22B                 CV DOES NOT OCCUR IN COMA TRIPL 48000031
*                                                                       48060031
** CALCULATE NO OF OCCURENCES OF THE CONTROL VARIABLE IN THE CURRENT    48120031
** MATCH CHAIN AND TEST IF THIS WOULD REDUCE THE CV COUNT FOR THIS      48180031
** LOOP TO ZERO ASSUMING THE CURRENT MATCH CHAIN WERE COMPLETELY        48240031
** OPTIMISED                                                            48300031
*                                                                       48360031
         LH    GR1,XOPTCHNO            (NO OF CHAINED MATCHED ITEMS     48420031
         LA    GR1,1(,GR1)             (+1                              48480031
         MH    GR1,XOPTCVNO            (* CV COUNT IN MATCHED CODE      48540031
         STH   GR1,XOPTCVCH            TEST AGAINST TOTAL UNOPTIMISED   48600031
         SH    GR1,XOPTCVCT            NO OF CV OCCURENCES IN THIS      48660031
         BNZ   MTCHL22B                LOOP   BRANCH IF NON ZERO        48720031
*                                                                       48780031
*                                                                       48840031
*                                                                       48900031
*                                                                       48960031
         L     GR2,XOPTSAVE             ADDRESS OF SKELETON SAVE AREA   49020031
         MVC   KOPTSI,XSKLPTSI          RESET CODE SKELETONS            49080031
         MVC   KOPTSJ,XSKLPTSJ       JMP/LOAD/LOAD/LOAD/USSL/USSL       49140031
*                                       AND  JMP/DROP/DROP              49200031
         MVC   XOPTZSMR,XOPTCVRG        SET UP REG FOR COMR             49260031
         IEMKTAB  DR,XLCRTXT,SA=XOPTSTXT,AATO=(GR3)                     49320031
         MVC   PTSI0008,XTRPOP1       MOVE EVEN REG OF STEP/LIM.PAIR    49380031
         MVC   PTSI0013,XTRPOP1      FROM OP1 OF BY'                    49440031
         MVC   PTSJ0005,XTRPOP1                                         49500031
*                                                                       49560031
         IEMKTAB  DR,XLCRTXT,SA=XOPTLTXT,AATO=(GR3)                     49620031
         MVC   PTSI0015,XTRPOP1      MOVE ODD REG OF STEP/LIM. PAIR     49680031
         MVC   PTSI0020,XTRPOP1      FROM OP1 OF TO'                    49740031
         MVC   PTSJ0007,XTRPOP1                                         49800031
*                                                                       49860031
*                                                                       49920031
*                                                                       49980031
** TEST FOR ARRAY EXPRESSION WHERE MORE THAN ONE DIMENSION IS MATCHED   50040031
*                                                                       50100031
         MVC   XOPTSCRP,XOPTC000        RESET PATCH BUILD POINTER       50160031
*                                                                       50220031
*                                                                       50280031
         CLC   XOPTFCOM,XOPTLCOM        TEST NO DIMS MATCHED.           50340031
         BNE   MTCHL22B                 BRANCH TO GENERAL OPTIMISATION  50400031
         MVC   PTSI0005,XOPTCVRG        MOVE CV REG TO 'LOAD'           50460031
         MVC   XOPTCOMS+3(2),XOPTSVIR    MOVE DREF OF SUBTRACTED INIT   50520031
*                                       TRIPLE                          50580031
         LA    GR3,XOPTCOMS             ADDRESS OF COMA TRIPLE          50640031
         BAL   RR,KOMAKC                                                50700031
         LTR   RC,RC                                                    50760031
         BNZ   MTCHL22B                 BRANCH IF TRANSFORM IMPOSSIBLE  50820031
*                                                                       50880031
         MVC   PTSI0006,XOPTDRF3        MOVE DREF OF TRANSFORMED 'INIT' 50940031
*                                                                       51000031
*                                                                       51060031
*                                                                       51120031
MTCHDIMX MVC   XOPTCOMS+3(2),XOPTSREF   MOVE DREF OF 'STEP' TO COMA     51180031
*                                       TRIPLE                          51240031
         LA    GR3,XOPTCOMS             ADDRESS OF COMA TRIPLE          51300031
         BAL   RR,KOMAKC                                                51360031
         LTR   RC,RC                                                    51420031
         BNZ   MTCHL22B                 BRANCH IF TRANSFORM IMPOSSIBLE  51480031
*                                                                       51540031
         MVC   PTSI0009,XOPTDRF3        MOVE DREF OF TRANSFORMED 'STEP' 51600031
*                                                                       51660031
*                                                                       51720031
*                                                                       51780031
*                                                                       51840031
MTCHDIMY MVC   XOPTCOMS+3(2),XOPTLREF   MOVE DREF OF'LIMIT'TO COMA      51900031
*                                       TRIPLE                          51960031
         BAL   RR,KOMAKC                                                52020031
         LTR   RC,RC                                                    52080031
         BNZ   MTCHL22B                 BRANCH IF TRANSFORM IMPOSSIBLE  52140031
*                                                                       52200031
         MVC   PTSI0016,XOPTDRF3        MOVE DREF OF TRANSFORMED 'LIMT' 52260031
*                                                                       52320031
*                                                                       52380031
*                                                                       52440031
       IEMKTAB DR,XLCRTXT,SA=XOPTCTXT,AATO=(GR3)                        52500031
*                                                                       52560031
         MVC   XTRPOP2,XOPTCVRG         MOVE CV REGISTER TO OP2         52620031
         MVI   XTRPCODE,XTRPSTCV        SET *CV OP CODE                 52680031
*                                                                       52740031
       IEMKTAB DR,XLCRTXT,SA=XOPTSTXT,AATO=(GR3)                        52800031
         MVC   XTRPOP2,XTRPOP1       MOVE EVEN REG OF STEP/LIM.PAIR     52860031
*                                                                       52920031
       IEMKTAB DR,XLCRTXT,SA=XOPTLTXT,AATO=(GR3)                        52980031
         MVC   XTRPOP2,XTRPOP1       MOVE ODD REG OF STEP/LIM.PAIR      53040031
*                                    IN OP1 OF TO'                      53100031
*                                                                       53160031
*                                                                       53220031
         LA    GR2,L'KOPTSI-1           SET LENGTH OF PATCH - 1         53280031
         LA    GR3,KOPTSI               SET ADDRESS OF PATCH            53340031
         BAL   RR,KOMOVE                                                53400031
         L     GR2,XOPTSAVE             ADDR. OF SKELETON SAVE AREA     53460031
         MVC   KOPTSK,XSKLPTSK          MOVE  JMP/MDRP                  53520031
         LH    GR1,XOPTCHNO                                             53580031
         AH    GR1,XOPTC002+2                                           53640031
         STH   GR1,XOPTWORK                                             53700031
         MVC   PTSK0006,XOPTWORK        STORE NO OF DROPS               53760031
         MVC   PTSK0005,XOPTCVRG        MOVE REG NO TO MDRP             53820031
         LA    GR2,L'KOPTSK-1           LENGTH-1 OF JMP/MDRP            53880031
         LA    GR3,KOPTSK               ADDR. OF  JMP/MDRP              53940031
         BAL   RR,KOMOVE                                                54000031
         LA    GR0,X'01'                ITDO TYPE PATCH                 54060031
         BAL   RR,KOPTCH                MAKE PATCH AT ITDO OF---        54120031
*                                   JMP/LOAD/LOAD/USSL/LOAD/USSL        54180031
*                                      /JMP/MDRP                        54240031
*                                                                       54300031
         LA    GR0,X'22'                SET TYPE PARAM. OF KOPTCH S/R   54360031
         LA    GR2,L'KOPTSJ-1           SET LENGTH OF PATCH - 1         54420031
         LA    GR3,KOPTSJ               SET ADDRESS OF PATCH            54480031
         BAL   RR,KOPTCH                MAKE PATCH AT ITD' OF---        54540031
*                                   JMP/DROP/DROP                       54600031
*                                                                       54660031
**  REDUCE CV COUNT BY THE NO OF OPTIMISED OCCURENCES OF THE CV IN THE  54720031
** CURRENT MATCH CHAIN                                                  54780031
*                                                                       54840031
         LH    GR1,XOPTCVCT                                             54900031
         SH    GR1,XOPTCVCH                                             54960031
         STH   GR1,XOPTCVCT            REMAINING UNOPT COUNT            55020031
*                                                                       55080031
         OI    XOPTOPTX,XOPTOKIT                                        55140031
         BAL   RR,KOMCHN               MARK MATCH CHAIN DEALT WITH      55200031
*                                      AND OPTIMISED                    55260031
         B     MTCHRSET                BRANCH TO EXIT                   55320031
*                                                                       55380031
*                                                                       55440031
*  TEST FOR A SINGLE USE OF THE   CV   IN A SUBSCRIPT LIST WHERE THE    55500031
*  CORRESPONDING DIMENSION TABLE MULTIPLIER IS 1,2,4 OR 8.              55560031
*  IF THIS CASE IS FOUND THE SUBSCRIPT IS NOT OPTIMISED BECAUSE THE     55620031
*  OVERHEAD OF THE 'BUMP' CODE IS GREATER THAN THE GAIN ON THE          55680031
*  SUBSCRIPT CALCULATION. IN THIS CASE THE MATCH CHAINE IS MARKED       55740031
*  'DEALT WITH BUT NOT OPTIMISED' AND THE CHAIN DELETED.                55800031
*                                                                       55860031
MTCHL22B CLC   XOPTLCOM,XOPTFCOM        TEST ONLY ONE DIMENSION MATCHED 55920031
         BNE   MTCHCHAN                 BRANCH IF MORE THAN ONE         55980031
*                                                                       56040031
         CLC   XOPTCHNO,XOPTC000        TEST ONLY ONE USE               56100031
         BNE   MTCHCHAN                 BRANCH IF MORE THAN ONE         56160031
*                                                                       56220031
         L     GR3,XOPTARA3             GET ADDRESS OF MATCHED TRIPLES  56280031
         CLI   XTRPCODE,XTRPCOMA        TEST FOR COMA                   56340031
         BNE   MTCHCHAN                 BRANCH IF NOT A COMA            56400031
*                                                                       56460031
         CLC   XTRPOP2,XMAPCVDR         TEST FOR CONTROL VARIABLE       56520031
         BNE   MTCHCHAN                 BRANCH NOT CONTROL VARIABLE     56580031
*                                                                       56640031
         CLC   XTRPOP1,XOPTC001+2       COMPARE MULTIPLIER              56700031
         BE    MTCHMARK                                                 56760031
         CLC   XTRPOP1,XOPTC002+2                                       56820031
         BE    MTCHMARK                                                 56880031
         CLC   XTRPOP1,XOPTC004+2                                       56940031
         BE    MTCHMARK                                                 57000031
         CLC   XTRPOP1,XOPTC008+8                                       57060031
         BNE   MTCHCHAN                                                 57120031
*                                                                       57180031
*  MARK MATCHED EXPRESSIONS 'DEALT WITH BUT NOT OPTIMISED AND DELETE    57240031
*  THE MATCH CHAIN IF NO SNDX'S AVAILABLE                               57300031
*                                                                       57360031
MTCHMARK CLI   XOPTSNDA+1,XOPTEQU0      ARE SNDX'S AVAILABLE            57420031
         BH    MTCHCHAN                 BRANCH IF YES                   57480031
MTCHMRK1 DS    0H                                                       57540031
       IEMKTAB DR,XLCRSRT,SA=XOPTSTPS,AATO=(GR5)                        57600031
*                                       GET START OF MTCH.              57660031
MTCHXNOP LH    GR2,XOPTFCOM             CHAIN                           57720001
         SH    GR2,XOPTC001+2                                           57780031
         MH    GR2,XOPTSTEP            ADDRESS OF FIRST MATCHED COMA    57840031
         LH    GR4,XOPTFCOM            ENTRY=(XOPTFCOM-1)*STEP FROM     57900031
*                                       START OF XSRTSCOM               57960031
*                                                                       58020031
         LA    GR1,XSRTSCCE(GR2)                                        58080031
MTCHDNOP MVI   0(GR1),XSRTSCDU+XSRTSDLT MARK COMA DEALT WITH NOT        58140031
         LA    GR4,1(,GR4)              OPTIMISED                       58200031
         LA    GR1,XOPTCSTP(0,GR1)                                      58260031
         CH    GR4,XOPTLCOM             TEST IF ALL MATCHED COMA        58320031
         BNH   MTCHDNOP                 ENTRIES MARKED                  58380031
*                                                                       58440031
         CLC   XSRTSMAT,XOPTC000        TEST FOR END OF MATCH CHAIN     58500031
         BE    MTCHRSET                 BRANCH IF END OF CHAIN          58560031
*                                                                       58620031
         MVC   XOPTWKTX,XSRTSMAT        SAVE MATCH CHAIN/               58640001
         MVC   XSRTSMAT,XOPTC000        CLEAR MATCH CHAIN               58660001
         IEMKTAB DR,XLCRSRT,SA=XOPTWKTX,AATO=(GR5)   CHAIN TO NEXT      58680001
*                                                                       58700001
*                                                 ENTRY                 58740031
         B     MTCHXNOP                                                 58800001
*                                                                       58860031
*  CONSTRUCT PATCH CODE FOR TRANSFORMS AND INVARIANTS                   58920031
*                                                                       58980031
*                                                                       59040031
*                                                                       59100031
MTCHCHAN MVC   XOPTSCRP,XOPTC000        SET PATCH BUILD AREA POINTER    59160031
*                                       TO ZERO                         59220031
         MVC   XOPTCNTR+2(2),XOPTLCOM   LAST MATCHED COMA NO            59280031
         MVC   XOPTCLIM+2(2),XOPTFCOM   FIRST MATCHED COMA NO           59340031
*      SET UP GR3 FOR KOCVTS S/R                                        59400031
       IEMKTAB SET,XLCRSRT,SA=XOPTSTPS                                  59460031
       IEMKTAB SCAN,XLCRSRT,AATO=(GR3)                                  59520031
         BAL   RR,KOCVTX               TEST FOR CV IN MATCHED TRIPLES   59580031
*                                                                       59640031
** CALCULATE NO OF OCCURENCES OF THE CONTROL VARIABLE IN THE CURRENT    59700031
** MATCH CHAIN AND SAVE                                                 59760031
*                                                                       59820031
         LH    GR1,XOPTCHNO            (NO OF CHAINED MATCHED ITEMS     59880031
         LA    GR1,1(,GR1)             (+1                              59940031
         MH    GR1,XOPTCVNO            (* CV COUNT IN MATCHED CODE      60000031
         STH   GR1,XOPTCVCH                                             60060031
*                                                                       60120031
         CH    RC,XOPTC004+2                                            60180031
         BE    MTCHTRNS                 BRANCH IF CV FOUND              60240031
         CH    RC,XOPTC008+2                                            60300031
         BE    MTCHMRK1                 BRANCH IF CV DREF = 0           60360031
*                                                                       60420031
*  CONSTRUCT INVARIANT PATCHES                                          60480031
*                                                                       60540031
         MVI   XOPTUSSW,XOPTVUSL        SET USSL SWITCH                 60600031
         BAL   RR,KOSSB1                CONSTRUCT'SSUB' LIST OF TYPE 1  60660031
         MVC   XOPTZSMR,ZSMREG+2        SAVE SYMBOLIC REG NO            60720031
         BAL   RR,KOMCOM                MAKE ITDO AND ITD' TYPE PATCHES 60780031
         XI    XOPTUSSW,XOPTVUSL        RESET USSL SWITCH               60840031
         LTR   RC,RC                    TEST PATCH TOO BIG              60900031
         BNZ   MTCHMRK1                 BRANCH IF TOO BIG               60960031
         B     MTCHTEXT                                                 61020031
*                                                                       61080031
*                                                                       61140031
*  CONSTRUCT TRANSFORM PATCHES                                          61200031
*                                                                       61260031
MTCHTRNS TM    XMAPSPEC,XMAPBSPC+XMAPBDCV     FOR BAD LOOP SPEC,CV      61320031
         BNZ   MTCHMRK1                 BRANCH IF BAD SPEC.             61380031
         BAL   RR,KOSNDX                ALLOCATE SNDX FOR USSL/MDRP     61440031
         MVC   XOPTZSMR,ZSMREG+2        SAVE SYMBOLIC REG NO            61500031
         BAL   RR,KOMCOM                MAKE ITDO AND ITD' TYPE PATCHES 61560031
         LTR   RC,RC                    TEST PATCH TOO BIG              61620031
         BNZ   MTCHMRK1                 BRANCH IF TOO BIG               61680031
         LH    GR1,ZSMREG+2             REDUCE SYMBOLIC REG COUNTER     61740031
         BCTR  GR1,0                    BY 1 TO ALLOW FOR BUMP BY 1     61800031
         STH   GR1,ZSMREG+2             IN S/R KOSSB2                   61860031
         MVC   XOPTPARM,XOPTC000        SET PARM TO 0 TO PREVENT        61920031
*                                       DUPLICATE ALLOCATION IN S/R     61980031
*                                       KOSSB2                          62040031
         MVC   XOPTSCRP,XOPTC000        RESET PATCH BUILD POINTER       62100031
         BAL   RR,KOSSB2                                                62160031
         LA    GR0,1                    MAKE PATCH OF ITDO TYPE         62220031
         BAL   RR,KOPTCH                                                62280031
         CLC   XOPTCVNO,XOPTC001+2                                      62340031
         BNE   MTCHSVAR                 BRANCH IF MORE THAN ONE         62400031
*                                       REFERENCE TO THE CV IN MATCHED  62460031
*                                       TRIPLES                         62520031
*                                                                       62580031
         CLI   XOPTCOMS,XTRPCOMA        TEST FOR'COMA CV' TRIPLE        62640031
         BE    MTCHNOST                 BRANCH TO OMIT CONSTRUCTION     62700031
*                                       OF TRANSFORMED STEP CODE        62760031
*                                                                       62820031
*  CONSTRUCT THE TRANSFORMED STEP CODE                                  62880031
*                                                                       62940031
MTCHSVAR MVC   XOPTSCRP,XOPTC000        SET PATCH BUILD AREA POINTER    63000031
*                                       TO ZERO                         63060031
*                                                                       63120031
*  CREATE A TEMPORARY FIXED BINARY INTEGER (31,0)                       63180001
*                                                                       63240031
*                                                                       63300031
         MVC   PAR1+2(2),XMAPENT1                                       63360031
         L     LR,ZDRFAB                                                63420031
         BALR  RR,LR                    GET ABS.ADDR.OF CURRENT         63480031
         L     GR2,PAR1                                                 63540031
*                                                                       63600031
         MVC   XOPTAUTO,11(GR2)         MOVE HEAD OF AUTOMATIC CHAIN    63660031
*                                       TO TEMP DICT.ENTRY SKELETON     63720031
         MVC   XOPTLVCN,3(GR2)          MOVE LEVEL AND COUNT            63780031
*                                       TO TEMP DICT.ENTRY SKELETON     63840031
*                                                                       63900031
         LA    GR1,XOPTTEMP             SET ADDR.OF DICT.SKELETON       63960031
         ST    GR1,PAR1                                                 64020031
         LA    GR1,L'XOPTTEMP           SET LENGTH OF DICT.SKELETON     64080031
         ST    GR1,PAR2                                                 64140031
         L     LR,ZDICRF                MAKE DICTIONARY ENTRY           64200031
         BALR  RR,LR                                                    64260031
*                                                                       64320031
         MVC   11(2,GR2),PAR1+2         MOVE DICT.REF OF TEMP           64380031
*                                       TO HEAD OF AUTOMATIC CHAIN      64440031
*                                       IN ENTRY TYPE 1                 64500031
*                                                                       64560031
*                                                                       64620031
*                                                                       64680031
*  RESET CODE SKELETONS KOPTSD,E,F,G,H                                  64740031
*                                                                       64800031
         L     GR2,XOPTSAVE             ADDRESS OF SKELETON SAVE AREA   64860031
         MVC   KOPTSD(KOPTSI-KOPTSD),XSKLPTSD                           64920031
*                                                                       64980031
         MVC   PTSF0003,PAR1+2          MOVE DREF OF TEMP TO'BUY'       65040031
         MVC   XOPTPARM,XOPTC000        SET PARAM TO KOSNDX S/R = 0     65100031
         BAL   RR,KOSSB3                CONSTRUCT SSUB LIST OF TYPE 3   65160031
*                                                                       65220031
         L     GR1,XOPTARA3             USE AREA3 AS PATCH SAVE AREA    65280031
         LH    GR2,XOPTSCRP             LENGTH OF PATCH DATA            65340031
         BCTR  GR2,0                    DECREMENT LENGTH BY 1 FOR MVC   65400031
         L     GR3,XOPTXPCH             ADDRESS OF PATCH BUILD          65460031
         LA    GR3,XPCHDATA-XPCH+5(,GR3) ADD FIXED LENGTH               65520031
         EX    GR2,XOPTMVCJ             EX -  MVC 0(0,GR1),0(GR3)       65580031
*                                                                       65640031
         MVC   XOPTMCHR,XOPTSCRP        SET MATCHED TRIPLE LENGTH       65700031
*                                       TO LENGTH OF PATCH BUILD        65760031
         MVC   XOPTPARM,XOPTC000        SET PARAM TO KOSNDX S/R = 0     65820031
         MVC   XOPTSCRP,XOPTC000        CLEAR PATCH BUILD POINTER       65880031
         BAL   RR,KOSSB2                REPROCESS STEP CODE PATCH       65940031
*                                       TO DEAL WITH COMPILE TIME       66000031
*                                       CONSTANTS                       66060031
*                                                                       66120031
*  SET UP 'TMP/STORE/DROP' CODE                                         66180031
*                                                                       66240031
         MVC   PTSH0005,ZSMREG+2        REG NO                          66300031
         MVC   PTSH0006,PTSF0003        DICT.REF OF TEMP                66360031
         MVC   PTSH0008,ZSMREG+2        REG NO                          66420031
*                                                                       66480031
         LA    GR2,L'KOPTSH-1           LENGTH OF JMP/STORE/DROP-1      66540031
         LA    GR3,KOPTSH               SET ADDRESS                     66600031
         BAL   RR,KOMOVE                MOVE JMP/STORE/DROP TO PATCH    66660031
*                                       BUILDAREA                       66720031
*                                                                       66780031
         TM    XOPTOPTX,XOPTUOPP        TEST PATCH TOO LONG FOR PATCH   66840031
         BO    MTCHMRK1                 BUILD AREA- BRANCH IF TOO LONG  66900031
*                                                                       66960031
         LA    GR0,1                    PATCH=1                         67020031
         BAL   RR,KOPTCH                MAKE PATCH AT ITDO              67080031
*                                                                       67140031
         MVC   XOPTSCRP,XOPTC000        SET PATCH BUILD POINTER =0      67200031
         MVC   PTSG0003,PTSF0003        MOVE DREF OF TEMP TO'SELL'      67260031
*                                                                       67320031
*                                                                       67380031
         MVC   XOPTSCRP,XOPTC000        SET PATCH BUILD POINTER =0      67440031
*                                                                       67500031
*  NOW MAKE PATCH FOR BUMP CODE  'JMP/ADD'                              67560031
*                                                                       67620031
*                                                                       67680031
         MVC   PTSE0006,PTSF0003        MOVE DREF OF TEMP TO JMP/ADD    67740031
MTCHJADD MVC   PTSE0005,XOPTZSMR        MOVE REG NO TO  JMP/ADD         67800031
         LA    GR0,X'44'                MAKE PATCH BEFORE ITD'          67860031
         LA    GR2,L'KOPTSE-1           LENGTH OF JMP/ADD - 1           67920031
         LA    GR3,KOPTSE              ADDRESS OF JMP/ADD               67980031
         MVC   XOPTTADR,XMAPITPP        ADDRESS OF TRIPLE BEFORE ITD'.  68040031
         BAL   RR,KOPTCH                                                68100031
*                                                                       68160031
MTCHTEXT BAL   RR,KOMCHN                MARK MATCH CHAIN DEALT WITH     68220031
*                                       AND OPTIMISED                   68280031
*                                                                       68340031
*                                                                       68400031
** REDUCE CV COUNT BY THE NO OF OPTIMISED OCCURENCES OF THE CV IN THE   68460031
** CURRENT MATCH CHAIN                                                  68520031
*                                                                       68580031
         LH    GR1,XOPTCVCT                                             68640031
         SH    GR1,XOPTCVCH                                             68700031
         STH   GR1,XOPTCVCT                                             68760031
*                                                                       68820031
** TEST TO SEE IF 'ST' OR 'L' ORDERS IN BXLE,BXH CODE CAN BE DELETED    68880031
**                                                                      68940031
*                                                                       69000031
         TM    XOPTOPTX,XOPTNKBX       TEST IF BXLE POSSIBLE FOR        69060031
         BO    MTCHRSET                THIS LOOP  BRANCH IF NOT POSS.   69120031
*                                                                       69180031
         TM    XOPTOPTX,XOPTOKIT       TEST 'IT.SPEC.MODIFIED'          69240031
         BO    MTCHRSET                BRANCH IF ALREADY MODIFIED       69300031
*                                                                       69360031
         TM    XMAPSPEC,XMAPNOST       TEST IF'ST' MAY BE DELETED       69420031
         BO    MTCHDEL1                BRANCH IF DELETE                 69480031
*                                                                       69540031
** COPY'ST','L' SWITCHES TO OP1 OF CV TRIPLE                            69600031
*                                                                       69660031
MTCHCOPY MVC   XOPTWKBT,XMAPSPEC       MOVE TO WORK BYTE                69720031
MTCHCOPZ NI    XOPTWKBT,XMAPNOST+XMAPNOLD                               69780031
         IC    GR1,XOPTWKBT                                             69840031
         SLL   GR1,XOPTDEL4            GET'L','ST, SWITCHES TO MOST     69900031
*                                      SIG. END OF BYTE                 69960031
*                                                                       70020031
         STC   GR1,XOPTWKBT                                             70080031
         IEMKTAB DR,XLCRTXT,SA=XOPTCTXT,AATO=(GR3)                      70140031
         OC    XTRPOP1(1),XOPTWKBT     COPY SWITCHES TO CV OP1          70200031
*                                                                       70260031
*                                                                       70320031
         B     MTCHRSET                GO TO EXIT                       70380031
*                                                                       70440031
*                                                                       70500031
MTCHDEL1 SR    GR1,GR1                                                  70560031
         CH    GR1,XOPTCVCT            TEST IF ALL CV OCCURENCES IN     70620031
*                                      THIS LOOP OPTIMISED              70680031
         BE    MTCHDEL2                                                 70740031
*                                                                       70800031
         MVC   XOPTWKBT,XMAPSPEC       SET XMAPNOST BIT TO 0            70860031
         XI    XOPTWKBT,XMAPNOST       I.E. 'ST' REQUIRED               70920031
*                                                                       70980031
         B     MTCHCOPZ                                                 71040031
*                                                                       71100031
MTCHDEL2 OI    XOPTOPTX,XOPTOKIT       SET'IT.SPEC.MODIFIED'SWITCH      71160031
*                                                                       71220031
         B     MTCHCOPY                                                 71280031
*                                                                       71340031
*                                                                       71400031
         B     MTCHRSET                 BRANCH TO EXIT                  71460031
*                                                                       71520031
*  TRY TO MAKE COMPILE TIME CONSTANT FOR TRANSFORMED STEP               71580031
*                                                                       71640031
MTCHNOST LA    GR3,XOPTCOMS                                             71700031
         MVC   XOPTCOMS+3,XOPTSREF                                      71760031
         BAL  RR,KOMAKC                 MAKE COMPILE TIME CONSTANT      71820031
*                                                                       71880031
         LTR   RC,RC                    WAS STEP TRANSFORMED            71940031
*                                                                       72000031
         BNZ   MTCHSVAR                 BRANCH IF NO                    72060031
*                                                                       72120031
         MVC   PTSE0006,XOPTDRF3        MOVE THE DREF OF THE CONSTANT   72180031
         B     MTCHJADD                 TRANSFORMED STEP TO   JMP/ADD   72240031
*                                                                       72300031
*                                                                       72360031
*  CONSTRUCT PATCH FOR 'COMMON' MATCH CHAIN  -  PROCESS P3              72420031
*                                                                       72480031
*                                                                       72540031
MTCHCHP3 CLC   XOPTCHNO,XOPTC000        TEST NO ENTRIES IN CHAIN        72600031
         BE    MTCHMRK1                                                 72660031
*                                       SINGLE ENTRY 'DEALT WITH BUT    72720031
*                                       NOT OPTIMISED                   72780031
*                                                                       72840031
         BAL   RR,KOSSB1                CONSTRUCT SSUB LIST OF TYPE 1   72900031
         MVC   XOPTZSMR,ZSMREG+2        SAVE SYMBOLIC REG NO            72960031
*                                                                       73020031
*                                                                       73080031
         L     GR2,XOPTSAVE             ADDRESS OF SKELETON SAVE AREA   73140031
         MVC   KOPTSK,XSKLPTSK          RESET CODE SKELON  JMP/MDRP     73200031
*                                                                       73260031
         MVC   PTSK0005,ZSMREG+2        MOVE REG NO TO JMP/MDRP         73320031
         LH    GR1,XOPTCHNO                                             73380031
         LA    GR1,1(,GR1)                                              73440031
         ST    GR1,XOPTWORK                                             73500031
         MVC   PTSK0006,XOPTWORK+2      MOVE (XOPTCHNO+1) TO JMP/MDRP   73560031
*                                                                       73620031
         LA    GR2,L'KOPTSK-1           LENGTH OF  JMP/MDRP-1           73680031
         LA    GR3,KOPTSK               ADDRESS OF JMP/MDRP             73740031
         BAL   RR,KOMOVE                MOVE JMP/MDROP TO PATCH BUILD   73800031
*                                                                       73860031
         TM    XOPTOPTX,XOPTUOPP        TEST PATCH TOO LONG FOR PATCH   73920031
*                                       BUILD AREA                      73980031
         BO    MTCHMRK1                 BRANCH IF TOO LONG  TO MARK     74040031
*                                       CHAIN'DEALT WITH BUT NOT OPT.'  74100031
*                                                                       74160031
         BAL   RR,KOMCHN                PROCESS OPTIMISABLE MATCH CHAIN 74220031
*                                                                       74280031
       IEMKTAB SET,XLCRSRT,SA=XOPTSTPS                                  74340031
       IEMKTAB SCAN,XLCRSRT,AATO=(GR6)  GET FIRST XSRT ENTRY IN CHAIN   74400031
*                                                                       74460031
         LR    GR5,GR6                  XSRT IS BASED ON GR5 LOCALLY    74520031
*                                                                       74580031
         LH    GR1,XOPTFCOM                                             74640031
         BCTR  GR1,0                                                    74700031
         MH    GR1,XOPTSTEP            RELATIVE ADDRESS OF THE FIRST    74760031
*                                       MATCHED COMA IN XSRT(XOPTSTPS)  74820031
*                                                                       74880031
         LA    GR1,XSRTSCOM(GR1)                                        74940031
         MVC   XOPTTADR,0(GR1)          MOVE TEXT REF OF FIRST MATCHED  75000031
*                                       COMA EXPRESSION                 75060031
         LA    GR0,8                                                    75120031
         BAL   RR,KOPTCH                MAKE PATCH AT FIRST MATCHED     75180031
*                                       COMA                            75240031
*                                                                       75300031
MTCHRSET DS    0H                                                       75360031
       IEMKTAB SET,XLCRSRT,SA=XOPTSTPS  SET ADDRESS OF FIRST MATCHED    75420031
       IEMKTAB SCAN,XLCRSRT,AATO=(GR6)  ENTRY IN XSRT BEFORE EXIT       75480031
*                                                                       75540031
       IEMKTAB DEACT,XLCRTXT                                            75600031
       IEMKTAB DEACT,XLCRPCH                                            75660031
*                                                                       75720031
         DROP  GR2                                                      75780031
         DROP  GR3                                                      75840031
         DROP  GR4                                                      75900031
         DROP  GR5                                                      75960031
         DROP  GR6                                                      76020031
*                                                                       76080031
*                                                                       76140031
MTCHEXIT IEMKLVE                                                        76200031
         EJECT                                                          76260031
*                                                                       76320031
** KOMCOM                                                               76380031
*                                                                       76440031
*  SUBROUTINE USED TO MAKE TRANSFORM AND INVARIANT PATCHES              76500031
*  CALLED BY SUBROUTINE KOMTCH                                          76560031
*                                                                       76620031
KOMCOM   IEMKENT  TYPE=2                                                76680031
*                                                                       76740031
*  RESET CODE SKELETONS  JMP/USSL/MDRP  AND  JMP/DROP                   76800031
*                                                                       76860031
         USING XSKL,GR2                                                 76920031
         L     GR2,XOPTSAVE             ADDRESS OF SKELETON SAVE AREA   76980031
         MVC   KOPTSA,XSKLPTSA                                          77040031
         MVC   KOPTSD,XSKLPTSD                                          77100031
*                                                                       77160031
         LH    GR1,XOPTSNDA                                             77220031
         CH    GR1,XOPTC000             TEST IF SNDX REG'S AVAILABLE    77280031
         BH    MCOMSNDA                 BRANCH IF AVAILABLE             77340031
*                                                                       77400031
         MVC   PTSA0004(L'XOPTIGNR),XOPTIGNR  IGNORE USSL               77460031
         B     MCOMSNDN                                                 77520031
MCOMSNDA MVC   PTSA0007,ZSMREG+2        MOVE REG NO TO USSL             77580031
         OC    PTSA0005(1),XOPTUSSW        SET VARIABLE / INVARIANT     77640031
         TM    XOPTUSSW,XOPTVUSL                                        77700031
         BO    MCOMSNDN                 BRANCH IF INVARIANT             77760031
*                                                                       77820031
**  SAVE VARIANT USSL REG IN LONG USSL                                  77880031
*                                                                       77940031
         L     GR1,XOPTUSLX                                             78000031
         MVC   0(2,GR1),ZSMREG+2          SAVE REG IN LONG USSL         78060031
         LA    GR1,2(,GR1)               STEP USSL INDEX                78120031
         ST    GR1,XOPTUSLX                                             78180031
*                                                                       78240031
MCOMSNDN LH    GR1,XOPTCHNO                                             78300031
         A     GR1,XOPTC002                                             78360031
         ST    GR1,XOPTWORK                                             78420031
         MVC   PTSA0010,XOPTWORK+2      MOVE(XOPTCHNO+2) TO MDRP        78480031
         MVC   PTSA0009,ZSMREG+2        MOVE REG NO TO MDRP             78540031
*                                                                       78600031
         LA    GR2,L'KOPTSA-1           LENGTH OF  JMP/USSL/MDRP-1      78660031
         LA    GR3,KOPTSA               ADDRESS OF JMP/USSL/MDRP        78720031
         BAL   RR,KOMOVE                MOVE JMP/USSL/MDRP TO PATCH     78780031
*                                       BUILD AREA                      78840031
*                                                                       78900031
         TM    XOPTOPTX,XOPTUOPP        TEST PATCH TOO LONG             78960031
         BZ    MCOMOKLN                 BRANCH IF NOT TOO LONG          79020031
*                                                                       79080031
         LA    RC,4                     SET RC=4  FOR PATCH TOO LONG    79140031
         B     MCOMEXIT                                                 79200031
*                                                                       79260031
MCOMOKLN LA    GR0,1                    MAKE PATCH AT ITDO              79320031
         BAL   RR,KOPTCH                                                79380031
*                                                                       79440031
         MVC   XOPTSCRP,XOPTC000        SET PATCH BUILD POINTER =0      79500031
*                                                                       79560031
         MVC   PTSD0005,ZSMREG+2        MOVE REG NO TO  JMP/DROP        79620031
*                                                                       79680031
         LA    GR0,X'22'                MAKE PATCH AT ITD'              79740031
         LA    GR2,L'KOPTSD-1           LENGTH OF  JMP/DROP-1           79800031
         LA    GR3,KOPTSD               ADDRESS OF JMP/DROP             79860031
         BAL   RR,KOPTCH                                                79920031
*                                                                       79980031
         SR    RC,RC                                                    80040031
*                                                                       80100031
         DROP  GR2                                                      80160031
*                                                                       80220031
MCOMEXIT IEMKLVE  RC=(RC)                                               80280031
         EJECT                                                          80340031
         LTORG                                                          86340001
         END                                                            92340001
