KQ       TITLE 'IEMKQ,   EXTEND SUBS TABLE WITH SSUBS ENTRIES          X00002001
               OS/360  PL/1 F COMPILER.'                                00004001
*           THIS MODULE CONTAINS FIXES TO THE FOLLOWING APARS.          00004419
*                                                                       00004819
* R19 173000,182600,212000,269000,484000                          30355 00005219
*                                                                       00005619
*                                                                       00006019
*                                                                       00006419
         EJECT                                                          00006819
*********************************************************************** 00007219
*                                                                     * 00008001
*                                                                     * 00010001
*                                                                     * 00012001
*              FUNCTIONS - (1) MODIFY THE PARTICULAR SUBS TABLE       * 00014001
*        TERMINAL ENTRY TO SHOW AN EXTENSION MAY EXIST.               * 00016001
*                                                                     * 00018001
*                          (2) SCAN GIVEN PATCH FILE ENTRIES AND      * 00020001
*        ANALYSE THE SUBSCRIPT EXPRESSIONS, IF ANY, CONTAINED         * 00022001
*        THEREIN.                                                     * 00024001
*                                                                     * 00026001
*                                                                     * 00028001
*              ENTRY POINT - 'KPUPDT', ONLY ENTRY IN TRANSFER VECTOR  * 00030001
*        AT START OF IEMKQ, CALLED BY IEMKO.                          * 00032001
*                                                                     * 00034001
*                                                                     * 00036001
*                                                                     * 00038001
*              INPUT - PATCH FILE GIVEN BY DO MAP ENTRY HELD IN KO'S  * 00040001
*        WORKSPACE.  THE USE LIST CREATED BY IEMKG IS ALSO REQUIRED.  * 00042001
*                                                                     * 00044001
*              OUTPUT - PATCH FILE UNCHANGED: POSSIBLE EXTENSIONS     * 00046001
*        TO SUBS TABLE.                                               * 00048001
*                                                                     * 00050001
*                                                                     * 00052001
*                                                                     * 00054001
*              EXTERNAL ROUTINES - (1) CONTROL PHASE.  THE FOLLOWING  * 00056001
*        ENTRY IS USED - 'ZDRFAB'.                                    * 00058001
*                                                                     * 00060001
*                                  (2) TABLE HANDLING (IEMKA).  THE   * 00062001
*        FOLLOWING ENTRIES ARE USED - 'KAHBLD','KAHDAC','KAHERR',     * 00064001
*        'KAHMDR','KAHSCN','KAHSET'.                                  * 00066001
*                                                                     * 00068001
*                                                                     * 00070001
*                                                                     * 00072001
*              EXIT - NORMAL - RETURN TO IEMKO VIA RETURN REGISTER.   * 00074001
*                                                                     * 00076001
*              EXIT - ERROR - 'KAHERR' IF AN ERROR OCCURS DURING      * 00078001
*        TABLE HANDLING.  TERMINAL MESSAGE IEM1224I IS GIVEN.         * 00080001
*                                                                     * 00082001
*                                                                     * 00084001
*                                                                     * 00086001
*              ATTRIBUTES - THIS MODULE IS LOADED AND RELEASED BY     * 00088001
*        MODULE IEMKO.                                                * 00090001
*                                                                     * 00092001
*                                                                     * 00094001
*                                                                       00096001
*              NOTES - (1) THIS MODULE REQUIRES THE 'IEMK' MACROS     * 00098001
*        FOR ASSEMBLY.                                                * 00100001
*                                                                     * 00102001
*                      (2) THIS MODULE ACCESSES STORAGE SLOTS IN      * 00104001
*        SCRATCH SET UP BY IEMKN AND ALSO USED BY IEMKO AND IEMKP.    * 00106001
*                                                                     * 00108001
*                      (3)  REGISTER USAGE WITHIN THIS MODULE IS      * 00110001
*        DEFINED IMMEDIATELY PRIOR TO THE CSECT, 'IEMKQ'.             * 00112001
*                                                                     * 00114001
*                                                                     * 00116001
*                                                                     * 00118001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*KQ 000-TSS 00118619
*        ----------------------------------------------------KQ 000-TSS 00119219
*                                                                     * 00120001
*                                                                     * 00122001
*                                                                     * 00124001
         EJECT                                                          00126001
*              GENERAL DESCRIPTION OF THE MODULE                      * 00128001
*                                                                     * 00130001
*                                                                     * 00132001
*                                                                     * 00134001
*                                                                     * 00136001
*                                                                     * 00138001
*        THIS MODULE IS A MODIFIED AND SIMPLIFIED VERSION OF THE      * 00140001
*   SECOND SECTION OF PHASE KJ AND IS DESIGNED TO PROCESS THE COMA    * 00142001
*   EXPRESSIONS FOUND AFTER A 'SSUB' TRIPLE IN A PATCH FILE ENTRY.    * 00144001
*   TN KQ COMA EXPRESSIONS ARE NOT CONSIDERED FOR COMMONING.  ENTRY   * 00146001
*   TO KQ IS FROM MODULE KO AND IS CONDITIONAL ON PROCESSING WITHIN   * 00148001
*   THAT MODULE.                                                      * 00150001
*                                                                     * 00152001
*                                                                     * 00154001
*                                                                     * 00156001
*                                                                     * 00158001
*        ON ENTRY TO KPUPDT (THE CONTROL SECTION OF MODULE KQ) FROM   * 00160001
*   KO 'XOPTXMAP' CONTAINS THE ADDRESS OF THE CURRENT DO MAP ENTRY.   * 00162001
*   'XOPTXREF' IS ALSO SET TO SHOW THAT, AS YET, NO EXTENSION HAS     * 00164001
*   BEEN ADDED TO THE SUBS TABLE.                                     * 00166001
*                                                                     * 00168001
*                                                                     * 00170001
*        IF, ON EXAMINATION OF 'XMAPPTCH', THE ADDRESS OF THE PATCH   * 00172001
*   FILE ENTRY, NO ENTRY EXISTS CONTROL IS IMMEDIATELY RETURNED TO KO.* 00174001
*   OTHERWISE THE SUBS TABLE REFERENCED IN 'XMAPSRGL' IS SCANNED TO   * 00176001
*   FIND THE TERMINAL ENTRY WHICH IS THEN MODIFIED SLIGHTLY TO SHOW   * 00178001
*   THAT AN EXTENSION MIGHT HAVE BEEN CREATED BY KQ.                  * 00180001
*                                                                     * 00182001
*                                                                     * 00184001
*        THE CONTENTS OF THE PATCH FILE ENTRY ADDRESSED ABOVE ARE NOW * 00186001
*   SCANNED TO FIND A 'SSUB' TRIPLE.  ALL OTHER TRIPLES ARE IGNORED   * 00188001
*   UNTIL A 'SSUB' TRIPLE IS FOUND EXCEPT FOR 'JMP' AND 'EOP' TRIPLES.* 00190001
*   WHEN A 'JMP' TRIPLE IS MET, THE FOLLOWING PSEUDO CODE IS BYPASSED.* 00192001
*   WHEN AN 'EOP' TRIPLE IS ENCOUNTERED, THE CHAIN SLOT IN THE        * 00194001
*   CURRENT PATCH ENTRY IS EXAMINED TO SEE IF ANOTHER ENTRY IS TO BE  * 00196001
*   PROCESSED.  IF SO THIS ENTRY IS SCANNED AS ABOVE, OTHERWISE       * 00198001
*   CONTROL IS RETURNED TO KO.  THE 'SSUB' TRIPLE WILL ALSO BE        * 00200001
*   IGNORED IF 'XMAPPRBE' IS SET (I.E. A CONTAINED PROC/BEEN EXISTS   * 00202001
*   INHIBITING ANY FURTHER OPTIMISATION).  IT IS ASSUMED THAT THE     * 00204001
*   WHOLE OF A PATCH FILE ENTRY RESIDES IN THE SAME TEXT BLOCK.       * 00206001
*                                                                     * 00208001
*                                                                     * 00210001
*        ON FINDING A 'SSUB' TRIPLE SUBROUTINE 'KPSSUB' IS CALLED.    * 00212001
*   THE PROCESSING OF THE TRIPLES FOLLOWING THE 'SSUB' TRIPLE IS      * 00214001
*   SIMILAR TO THAT EMPLOYED IN PHASE KJ FOR TRIPLES FOLLOWING THE    * 00216001
*   'SUBS' TRIPLE.  IT IS HOWEVER POSSIBLE TO ASSUME THAT ALL         * 00218001
*   VARIABLES ARE 'NICE' THUS REDUCING THE OPERAND PROCESSING.  ALSO, * 00220001
*   AS COMMONING IS NOT TO BE CONSIDERED FURTHER TRIPLES 'DIVD' AND   * 00222001
*   'PRE+' ARE TREATED AS UNACCEPTABLE TRIPLES AS FAR AS THE          * 00224001
*   EXPRESSION IS CONCERNED.                                          * 00226001
*                                                                     * 00228001
*                                                                     * 00230001
*        AN EXTRA TRIPLE, 'COMR', MUST NOW BE SEARCHED FOR AND IS TO  * 00232001
*   BE TREATED AS A PROCESSED 'COMA' EXPRESSION.  IN ADDITION, ON     * 00234001
*   FINDING A COMA TRIPLE, THE SECOND OPERAND MUST BE EXAMINED FOR    * 00236001
*   X'FFFF' AS IN THIS CASE THE COMA EXPRESSION HAS ALSO ALREADY BEEN * 00238001
*   PROCESSED.  AS ALL THE OTHER COMA TRIPLES HAVE BEEN MOVED FROM    * 00240001
*   TEXT TO THE PATCH FILE AND ALSO PROCESSED BY PHASE KJ IT IS       * 00242001
*   UNNECESSARY TO SET THE FIRST OPERAND OF A COMA TRIPLE BY          * 00244001
*   REFERENCE TO THE MULTIPLIER.                                      * 00246001
*                                                                     * 00248001
*                                                                     * 00250001
*        IF ANY 'SSUB' ENTRIES ARE CREATED AND ADDED TO THE SUBS      * 00252001
*   TABLE, THE SYMBOLIC ADDRESS OF THE FIRST IS RETURNED TO KO IN     * 00254001
*   'XOPTXREF'.                                                       * 00256001
*                                                                     * 00258001
*                                                                     * 00260001
*                                                                     * 00262001
*                                                                     * 00264001
*                                                                     * 00266001
*********************************************************************** 00268001
         EJECT                                                          00270001
         COPY  IEMKCOM                                                  00272001
         COPY  IEMKUTL                                                  00300001
         COPY  IEMKEQU                                                  00400001
         COPY  IEMKDRF                                                  00500001
         COPY  IEMKLCR                                                  00600001
         COPY  IEMKMAP                                                  00700001
         COPY  IEMKPCH                                                  00800001
         COPY  IEMKSRT                                                  00900001
         COPY  IEMKTRP                                                  01000001
         COPY  IEMKUSE                                                  01100001
DATA     DSECT                                                          01200001
         USING DATA,GR7                                                 01300001
*                                                                       01400001
         COPY  IEMKNDT                                                  01500001
         EJECT                                                          01600001
*                                                                       01700001
*        LOCAL REGISTER EQUATES FOR KPUPDT                              01800001
*                                                                       01900001
GRXMAP   EQU   6                                                        02000001
GRXTRP   EQU   5                                                        02100001
GRXSRT   EQU   4                                                        02200001
GRXPCH   EQU   3                                                        02300001
GRXDRF   EQU   3                                                        02400001
GRCCNT   EQU   3                                                        02500001
GRXUSE   EQU   3                                                        02600001
GRSCOM   EQU   9                                                        02700001
GROPR    EQU   4                                                        02800001
GRX      EQU   15                                                       02900001
GRY      EQU   2                                                        03000001
*                                                                       03100001
BNO      EQU   14                       BRANCH IF NOT ONES              03200001
BNZ      EQU   7                        BRANCH IF NON ZERO              03250001
         EJECT                                                          03300001
IEMKQ    CSECT                                                          03400001
*                                                                       03500001
         DC    C'KQ'                                                    03600001
*                                                                       03700001
         USING IEMKQ,GR8                ) MODULE KQ                     03800001
*                                                                       03900001
**             BRANCH TABLE                                             04000001
*                                                                       04100001
*                                                                       04200001
         B     KPUPDT                                                   04300001
*                                                                       04400001
*                                                                       04500001
         EJECT                                                          04600001
*                                                                       04700001
**       THIS IS A VERSION OF PHASE KJ MODIFIED TO SCAN TEXT TRIPLES ** 04800001
**       FROM THE PATCH FILE AND PROCESS THE RESTRICTED TYPES OF     ** 04900001
**       EXPRESSIONS FOUND AFTER THE SSUBS TRIPLES.                  ** 05000001
*                                                                       05100001
*                                                                       05200001
KPUPDT   IEMKENT  TYPE=1                                                05300001
*                                                                       05400001
         USING XMAP,GRXMAP              ) BASE REQUIRED DSECTS          05500001
         USING XTRP,GRXTRP  5           )                               05600001
         USING XSRT,GRXSRT  4           ) AND  '                        05700001
         USING XPCH,GRXPCH  3           )                               05800001
*                                                                       05900001
         MVI   UPDTENTC,X'00'           SET INITIAL ENTRY FLAG          06000001
*                                                                       06100001
         L     GRXMAP,XOPTXMAP          LOAD XMAP BASE REGISTER         06200001
         LA    GRXSRT,SSUBXSRT          LOAD XSRT BASE REGISTER         06300001
         MVI   XOPTXRFX,UPDTLEND        SET TEXT REF. OF EXTENSION TO   06400001
*                                         SHOW NO TABLE YET EXISTS      06500001
         CLI   XMAPPTCH,UPDTLEND        TEST FOR PRESENCE OF PATCH FILE 06600001
         BE    UPDTEXIT                 BRANCH IF NO FILE               06700001
*                                                                       06800001
         EJECT                                                          06900001
**             SCAN CURRENT SUBS/REGION TABLE TO FIND END OF TABLE      07000001
**             AND MARK WITH CODE STATING THAT AN EXTENSION EXISTS.     07100001
*                                                                       07200001
       IEMKTAB SET,XLCRSRT,SA=XMAPSRGL       SET SCAN PARAMETERS        07300001
*                                                                       07400001
UPDTGSRT DS    0H                                                       07460001
       IEMKTAB SCAN,XLCRSRT,AATO=(GRXSRT)    GET NEXT ENTRY             07520001
*                                                                       07600001
         TM    XSRTCODE,XSRTEXTN        TEST FOR END OF LIST            07700001
         BC    BNO,UPDTGSRT             BRANCH IF NOT END OF LIST       07800001
*                                                                       07900001
         MVI   XSRTCODE,XSRTEXTN        RESET CODE                      08000001
*                                                                       08100001
       IEMKTAB DEACT,XLCRSRT                                            08150001
         EJECT                                                          08200001
*                                                                       08300001
**             SCAN PATCH FILE USING LOCAL REGISTER ADDITION INSTEAD    08400001
**             OF HTAB ROUTINES.  BY DEFINITION, A SINGLE PATCH RECORD  08500001
**             LIES COMPLETELY WITHIN A SINGLE TEXT BLOCK.              08600001
*                                                                       08700001
**             INITALIZE LOCAL REGISTER USING HTAB SET AND SCAN         08800001
*                                                                       08900001
       IEMKTAB DR,XLCRPCH,SA=XMAPPTCH,AATO=(GRXPCH),OPT=L               09100001
         MVC   UPDTSADD+1(3),XMAPPTCH   STORE PATCH SYMB ADD FOR SSUB   09300001
UPDTGPCH LA    GRXTRP,XPCHDATA-XPCH(0,GRXPCH)                           09500001
*                                                                       09700001
UPDTNTRP CLI   XTRPCODE,XTRPEOPT        TEST IF END OF PATCH FILE       09800001
         BNE   UPDTCONT                 BRANCH IF NOT                   09900001
*                                                                       10000001
         CLC   XPCHCHN(3),=X'000000'    TEST FOR PRESENCE OF FURTHER    10100001
         BE    UPDTEXIT                   PATCH AND IF NOT BANCH        10200001
*                                                                       10300001
**             RESET  PARAMETERS TO SCAN NEXT PATCH                     10400001
*                                                                       10500001
         MVC   UPDTSADD+1(3),XPCHCHN    STORE PATCH SYMB ADD FOR SSUB   10550001
       IEMKTAB DR,XLCRPCH,SA=XPCHCHN,AATO=(GRXPCH),OPT=L                10620001
         B     UPDTGPCH                 BRANCH TO SCAN PATCH ENTRY      10700001
*                                                                       10800001
*                                                                       10900001
         EJECT                                                          11000001
*                                                                       11100001
UPDTCONT CLI   XTRPCODE,XTRPSSUB        TEST IF SSUBS TRIPLE            11200001
         BNE   UPDTTJMP                 BRANCH IF NOT                   11300001
*                                                                       11400001
         TM    XMAPLOOP,XMAPPRBG        TEST IF ANY CONTAINED PROC/BEGN 11420001
         BO    UPDTTJMP                 IF SO IGNORE SSUB               11440001
*                                                                       11460001
*                                                                       11500001
         L     PR0,UPDTSADD             LOAD SYMBOLIC ADDRESS OF PATCH  11600001
*                                         ENTRY TO PASS TO KPSRSSUB     11700001
         BAL   RR,KPSSUB                  AND BRANCH TO SUBROUTINE.     11800001
*                                                                       11900001
         LR    GRXTRP,PR1               RESET PATCH TRIPLE POINTER      11930001
*                                                                       11960001
         CLI   UPDTENTC,X'FF'           TEST IF THIS WAS FIRST ADDITION 12000001
         BE    UPDTNTRP                 BRANCH IF NOT                   12100001
*                                                                       12200001
         MVI   UPDTENTC,X'FF'           SET FLAG TO SHOW AT LEAST ONE   12300001
*                                         SSUBS ENTRY EXISTS            12400001
         ST    PR0,UPDTFWWS             ) SET XOPTXRFX TO SYMBOLIC      12500001
         MVC   XOPTXRFX,UPDTFWWS+1      ) ADDRESS OF FIRST ENTRY        12600001
*                                                                       12700001
**             AT THIS POINT, GRXTRP POINTS TO NEXT PATCH TRIPLE        12800001
*                                                                       12900001
         B     UPDTNTRP                 BRANCH TO TEST NEXT TRIPLE      13000001
*                                                                       13100001
         EJECT                                                          13200001
*                                                                       13300001
UPDTTJMP CLI   XTRPCODE,XTRPJUMP        TEST IF JUMP TRIPLE             13400001
         BE    UPDTJUMP                 BRANCH IF JUMP TRIPLE           13500001
*                                                                       13600001
**             IGNORE ANY OTHER TRIPLES AND INCREMENT GRXTRP TO POINT   13700001
**             TO THE NEXT PATCH TRIPLE                                 13800001
*                                                                       13900001
         LA    GRXTRP,XTRPEND-XTRP(0,GRXTRP)                            14000001
*                                                                       14100001
         B     UPDTNTRP                 BRANCH TO TEST NEXT TRIPLE      14200001
*                                                                       14300001
*                                                                       14400001
*                                                                       14500001
UPDTJUMP MVC   UPDTFWWS(2),XTRPOP1      ) INCREMENT GRXTRP TO           14600001
         LH    GRX,UPDTFWWS             ) POINT TO TRIPLE FOLLOWING     14700001
         LA    GRXTRP,2(GRX,GRXTRP)     ) PSEUDO CODE AND STATUS BYTES  14800001
*                                                                       14900001
         B     UPDTNTRP                 BRANCH TO TEST NEXT TRIPLE      15000001
*                                                                       15100001
*                                                                       15200001
UPDTEXIT CLI   UPDTENTC,X'00'           TEST IF ANY SSUBS ENTRIES HAVE  15300001
         BE    UPDTWOUT                   BEEN CREATED, BRANCH IF NOT   15400001
*                                                                       15500001
**             CREATE SUBS/REGION EXTENSION TERMINATING ENTRY.          15600001
*                                                                       15700001
         LA    GRXSRT,SSUBXSRT          REBASE XSRT FOR TERM ENTRY      15750001
         MVI   XSRTCODE,XSRTLEND        SET TERMINAL CODE               15800001
         MVC   XSRTLNTH,=H'3'           SET RECORD LENGTH               15900001
       IEMKTAB BLDC,XLCRSRT,XSRT        ADD ENTRY TO LIST               16000001
*                                                                       16200001
       IEMKTAB DEACT,(XLCRUSE,XLCRSRT,XLCRPCH)                          16250001
UPDTWOUT IEMKLVE                        RETURN TO CALLING POINT         16320001
*                                                                       16400001
UPDTSADD DC    A(0)                     SYMBOLIC ADDRESS OF SSUBS ENTRY 16500001
UPDTFWWS DC    F'0'                     FULL WORD WORK SPACE            16600001
UPDTENTC DC    X'0'                     INITIAL ENTRY FLAG              16700001
UPDTLEND EQU   X'FF'                    LIST TERMINAL CODE IN SYMB ADD  16800001
         LTORG                                                          16900001
         EJECT                                                          17000001
*                                                                       17100001
**       THIS SUBROUTINE IS THE SHORTEND VERSION OF PHASE KJ TO       * 17200001
**       PROCESS THE TRIPLES FOLLOWING A SSUBS TRIPLE                 * 17300001
*                                                                 30355 17310019
*                                                                 30355 17320019
*        IF THE ARRAY BEING OPTIMISED IS A DUMMY BOUGHT AT EXECUTION    17330019
*        TIME OPTIMISATION MUST NOT CAUSE REFERENCES TO THIS ARRAY TO   17340019
*        OCCUR BEFORE IT IS ACTUALLY BOUGHT.  HENCE IF THE ARRAY IS A   17350019
*        TEMPORARY TYPE 2 - OR A COBOL TEMPORARY - IT CANNOT BE         17360019
*        CONSIDERED FOR FURTHER OPTIMISATION.                           17370019
*                                                                 30355 17380019
*                                                                 30355 17390019
*                                                                       17400001
*                                                                       17500001
KPSSUB   IEMKENT  TYPE=1                                                17600001
*                                       ) SA IS IN LAST 3 BYTES         17700001
         ST    PR0,SSUBFWWS             ) CALCULATE TEXT REFERENCE OF   17800001
         LR    GRX,GRXTRP               ) SSUBS TRIPLE FROM SA OF PATCH 17900001
         SR    GRX,GRXPCH               ) FROM PR0, AND TRIPLE ABSOLUTE 18000001
         AH    GRX,SSUBFWWS+2           ) ADDRESS HELD IN GRXTRP AND    18100001
         STH   GRX,SSUBFWWS+2           ) PATCH AA IN GRXPCH            18200001
         LA    GRXSRT,SSUBXSRT          BASE XSRT DSECT                 18220001
         MVC   SSUBSASA,SSUBFWWS        STORE SSUB SYMBOLIC ADDRESS     18240001
         XC    SSUBFLAG,SSUBFLAG        CLEAR FLAG BYTE                 18260001
         XC    SSUBTMP2,SSUBTMP2        CLEAR TEMP TYPE2 FLAG     30355 18280019
         MVC   XSRTTEXT,SSUBFWWS+1      STORE SA IN XSRT                18300001
*                                                                       18400001
         TM    XMAPLOOP,XMAPATCV        TEST IF CV ASSIGNED TO          18500001
         BO    SSUBSNOT                 IF SO BRANCH                    18600001
*                                                                       18700001
         TM    XMAPSPEC,XMAPBSPC+XMAPBDCV    TEST LOOP SPEC             18800001
         BZ    SSUBSSET                 BRANCH IF CLEAN                 18900001
*                                                                       19000001
SSUBSNOT OI    SSUBFLAG,SSUBNOTR        SET OVERALL NO TRANS. FLAG      19100001
*                                                                       19200001
SSUBSSET MVI   XSRTCODE,XSRTCSUB+XSRTCSSS    SET SUBS AND SSUBS FLAGS   19300001
         XC    XSRTSSTC(5),XSRTSSTC     CLEAR SUBS OPT WORKSPACE        19400001
*                                                                       19500001
*                                                                       20100001
         MVC   PAR1+2(2),XTRPOP1        ) LOAD DICTIONARY ENTRY OF      20200001
         L     LR,ZDRFAB                ) ARRAY VARIABLE                20300001
         BALR  RR,LR                    )                               20400001
*                                                                       20500001
         L     GRX,PAR1                 LOAD ABSOLUTE ADDRESS OF        20600001
*                                         DICTIONARY ENTRY              20700001
*                                                                       20800001
         DROP  GRXPCH                                                   20900001
         USING XDRF,GRXDRF              BASE XDRF DSECT                 21000001
*                                                                       21100001
         LR    GRXDRF,GRX               LOAD BASE REGISTER              21200001
*                                                                 30355 21206019
**       IF ARRAY IS BOUGHT AT RUN TIME, MARK AS BEING NO LONGER  30355 21212019
**                      OPTIMISABLE.                              30355 21218019
*                                                                 30355 21224019
         TM    XDRFOTH3+1,X'20'         TEST OTHER 4 BIT 2 FOR TEMP.    21230019
*                                       TYPE 2 OR COBOL TEMP      30355 21236019
         BZ    SSUBNOTT                 BRANCH IF NOT             30355 21242019
*                                                                 30355 21248019
         MVI   SSUBTMP2,X'FF'           TEMP TYPE2 ARRAY FOUND    30355 21254019
*                                                                 30355 21260019
*        HOWEVER THE SCAN OF THE PATCH FILE MUST BE CONTINUED TO  30355 21266019
*        ENSURE THAT ALL POINTERS ARE CORRECT ON EXIT FROM KPUPDT.30355 21272019
*                                                                 30355 21278019
SSUBNOTT EQU   *                                                  30355 21284019
*                                                                 30355 21290019
*                                                                       21300001
**             OBTAIN DIMENSIONED INFORMATION FROM DICT. ENTRY          21400001
*                                                                       21500001
         LA    GRX,21(0,GRX)            ADJUST GRX TO POINT TO START OF 21600001
*                                         VARIABLE INFORMATION          21700001
*                                                                       21800001
         TM    XDRFVARB,XDRFVVAR        TEST IF SECOND ADDRESS SLOT     21900001
         BZ    SSUBSVAR                   PRESENT, BRANCH IF NOT        22000001
         DROP  GRXDRF                                                   22100001
*                                                                       22200001
         LA    GRX,4(0,GRX)             ADJUST GRX TO POINT PAST        22300001
*                                         SECOND SLOT                   22400001
*                                                                       22500001
SSUBSVAR MVC   XSRTSDVR,1(GRX)          OBTAIN DOPE VECTOR DR           22600001
         MVC   XSRTSNOC,0(GRX)          OBTAIN NUMBER OF COMMAS         22700001
*                                                                       22800001
*                                                                       23000001
*                                                                       23500001
*                                                                       24600001
*                                                                       24700001
         XR    GRCCNT,GRCCNT            CLEAR COMA COUNT REGISTER       24800001
         IC    GRCCNT,XSRTSNOC          LOAD NUMBER OF COMMAS           24900001
         STH   GRCCNT,SSUBFWWS          HOLD THIS VALUE                 25000001
         LA    GRY,XSRTSEND-XSRTSCOM    LOAD LENGTH OF SSUBS COMA ENTRY 25100001
         MH    GRY,SSUBFWWS               AND MULTIPLY BY NO OF COMMAS  25200001
         LA    GRY,XSRTSCOM-XSRT(0,GRY) ) CALCULATE AND STORE LENGTH    25300001
         STH   GRY,SSUBFWWS             ) OF ENTRY                      25360001
         MVC   XSRTLNTH,SSUBFWWS        )                               25420001
*                                                                       25500001
**             CALCULATE ADDRESS OF FIRST SSUBS COMA ENTRY IN XSRT      25600001
*                                                                       25700001
         LA    GRX,XSRTSEND-XSRTSCOM                                    25800001
         SR    GRY,GRX                                                  25900001
         LA    GRSCOM,0(GRY,GRXSRT)                                     26000001
*                                                                       26100001
         USING XSRTSCOM,GRSCOM          BASE SSUBS TABLE COMA EXP. DATA 26200001
*                                                                       26300001
         EJECT                                                          26400001
*                                                                       26500001
*                                                                       26600001
SSUBSNXC NI    SSUBFLAG,X'00'+SSUBNOTR  CLEAR LOCAL COMA EXP. FLAGS     26700001
         NI    XSRTSCCE,X'00'           CLEAR COMA CODE FLAGS           26800001
         XC    SSUBEXPR,SSUBEXPR        SET EXPRESSION COUNT TO ZERO    26900001
*                                                                 30355 26910019
         CLI   SSUBTMP2,X'00'           TEST IF ARRAY IS TEMP 2   30355 26920019
         BE    SSUBNOT2                 BRANCH IF NOT             30355 26930019
*                                       OTHERWISE NO FURTHER OPTIMISING 26940019
         OI    SSUBFLAG,SSUBUNOP        SET EXPR UNOPT FLAG       30355 26950019
*                                                                 30355 26960019
SSUBNOT2 EQU   *                                                  30355 26970019
*                                                                       27000001
**             OBTAIN FIRST TRIPLE AFTER SSUBS AND STORE TEXT           27100001
**             REF IN XSRT                                              27200001
*                                                                       27300001
*                                                                       27310001
*                                                                       27320001
**             CALCULATE SYMBOLIC ADDRESS OF COMA EXPRESSION            27330001
*                                                                       27340001
**             ASSUMES PATCH LIES COMPLETELY WITHIN ONE TEXT BLOCK      27350001
*                                                                       27360001
*                                                                       27370001
         LA    GRXTRP,XTRPEND-XTRP(0,GRXTRP)      ADDRESS NEXT TRIPLE   27380001
*                                                                       27390001
         LA    GRX,XTRPEND-XTRP         ) KEEP SYMBOLIC                 27400001
         A     GRX,SSUBSASA             ) ADDRESS UPDATE WITH           27410001
         ST    GRX,SSUBSASA             ) ABSOLUTE ADDRESS              27420001
*                                                                       27430001
         MVC   XSRTSCOM,SSUBSASA+1      SET COMA EXP SYMB ADD           27440001
*                                                                       27500001
         B     SSUBSBYP                 BRANCH ROUND NORMAL SCAN CALL   27600001
*                                                                       27700001
SSUBSNXT LA    GRXTRP,XTRPEND-XTRP(0,GRXTRP)      ADDRESS NEXT TRIPLE   27720001
*                                                                       27740001
         LA    GRX,XTRPEND-XTRP         ) KEEP SYMBOLIC                 27760001
         A     GRX,SSUBSASA             ) ADDRESS UPDATE WITH           27780001
         ST    GRX,SSUBSASA             ) ABSOLUTE ADDRESS              27800001
*                                                                       27820001
*                                                                       27900001
SSUBSBYP XR    2,2                      CLEAR REGISTER 2 FOR TRT        28000001
         TRT   XTRPCODE,SSUBTTAB        TEST TRIPLE CODE                28100001
*                                                                       28200001
         BZ    SSUBOTHR                 OTHER THAN THE FOLLOWING        28300001
SSUBSTAB B     SSUBSTAB(2)                                              28400001
         B     SSUBNPRM                 PREFIX MINUS                    28500001
         B     SSUBPLMS                 PLUS AND MINUS                  28600001
         B     SSUBMULT                 MULTIPLY                        28700001
         B     SSUBCOMA                 COMMA                           28800001
         B     SSUBOTHR                 DIVIDE         ) NOT ACCEPTABLE 28900001
         B     SSUBOTHR                 PREFIX PLUS    ) FOR TRANSFORMS 29000001
         B     SSUBSNXT                 NOP AND IGNORABLE TRIPLES       29100001
         B     SSUBCOMR                 COMR                            29200001
*                                                                       29300001
         EJECT                                                          29400001
*                                                                       29500001
SSUBNPRM TM    SSUBFLAG,SSUBUNOP        ) SCAN FOR END OF EXPRESSION    29600001
         BO    SSUBSNXT                 ) IF EXPR. UNOPT FLAG SET       29700001
*                                                                       29800001
         IC    PR0,=X'FF'               ) CALL KPSRCHKP TO EXAMINE      29900001
         BAL   RR,KPCHKP                ) SECOND OPERAND OF TRIPLE.     30000001
*                                                                       30100001
         TM    SSUBOPN2,SSUBZERO        TEST IF OPERAND X'00'           30200001
         BC    BNO,SSUBSNXT             BRANCH IF NOT                   30300001
*                                                                       30400001
         OI    SSUBFLAG,SSUBPMEX        SET PREFIX MINUS EXP. FLAG      30500001
         B     SSUBSNXT                 BRANCH TO PROCESS NEXT TRIPLE   30600001
*                                                                       30700001
         EJECT                                                          30800001
*                                                                       30900001
*                                                                       31000001
**             PROCESS PREFIX MINUS TRIPLE                              31100001
*                                                                       31200001
*                                                                       31300001
**             PROCESS PLUS OR MINUS TRIPLES                            31400001
*                                                                       31500001
SSUBPLMS TM    SSUBFLAG,SSUBUNOP        ) SCAN FOR END OF EXPRESSION    31600001
         BO    SSUBSNXT                 ) IF EXPR. UNOPT FLAG SET       31700001
*                                                                       31800001
         XR    PR0,PR0                  ) CALL KPSRCHKP TO EXAMINE BOTH 31900001
         BAL   RR,KPCHKP                ) OPERANDS OF TRIPLE.           32000001
*                                                                       32100001
         TM    SSUBOPN1,SSUBCNST        TEST IF OPERAN1 IS CONSTANT     32200001
         BZ    SSUBPINX                 BRANCH IF NOT                   32300001
*                                                                       32400001
         TM    SSUBOPN2,SSUBCNST        TEST IF OPERAND2 IS CONSTANT    32500001
         BZ    SSUBPINX                 BRANCH IF NOT                   32600001
*                                                                       32700001
         OI    SSUBFLAG,SSUBUNOP        ) SET UNOPTIMISABLE FLAG, BOTH  32800001
*                                       ) OPERANDS CONSTANT IS NOT      32900001
*                                       ) PERMITTED                     33000001
         B     SSUBSNXT                 BRANCH TO PROCESS NEXT TRIPLE   33100001
*                                                                       33200001
*                                                                       33300001
SSUBPINX LH    GRX,SSUBEXPR             ) INCREMENT                     33400001
         LA    GRX,1(0,GRX)             ) EXPRESSION                    33500001
         STH   GRY,SSUBEXPR             ) COUNT BY ONE                  33600001
*                                                                       33700001
         B     SSUBSNXT                                                 33800001
*                                                                       33900001
         EJECT                                                          34000001
*                                                                       34100001
**             PROCESS ANY OTHER TYPE OF TRIPLE                         34200001
*                                                                       34300001
SSUBOTHR OI    SSUBFLAG,SSUBUNOP        SET EXP UNOPTIMISABLE FLAG      34400001
         B     SSUBSNXT                                                 34500001
*                                                                       34600001
         EJECT                                                          34700001
*                                                                       34800001
**             PROCESS MULTIPLY TRIPLE                                  34900001
*                                                                       35000001
SSUBMULT TM    SSUBFLAG,SSUBUNOP        ) SCAN FOR END OF EXPRESSION    35100001
         BO    SSUBSNXT                 ) IF EXPR. UNOPT FLAG SET       35200001
*                                                                       35300001
         XR    PR0,PR0                  ) CALL KPSRCHKP TO EXAMINE      35400001
         BAL   RR,KPCHKP                ) BOTH OPERANDS OF TRIPLE.      35500001
*                                                                       35600001
         LA    GRX,2                    ) SET EXPRESSION VALUE          35700001
         STH   GRX,SSUBEXPR             ) EQUAL TO TWO                  35800001
*                                                                       35900001
         TM    SSUBOPN1,SSUBZERO        TEST IF OPERAND1 IS '00'        36000001
         BO    SSUBMUNO                 IF SO BRANCH                    36100001
*                                                                       36200001
         TM    SSUBOPN2,SSUBZERO        TEST IF OPERAND2 IS '00'        36300001
         BO    SSUBMUNO                 IF SO BRANCH                    36400001
*                                                                       36500001
         TM    SSUBOPN1,SSUBCNST        TEST IF OPERAND1 IS CONSTANT    36600001
         BO    SSUBMCNT                 IF SO BRANCH                    36700001
*                                                                       36800001
         TM    SSUBOPN2,SSUBCNST        TEST IF OPERAND2 IS CONSTANT    36900001
         BO    SSUBSNXT                 IF SO BRANCH TO NEXT TRIPLE     37000001
*                                                                       37100001
SSUBMUNO OI    SSUBFLAG,SSUBUNOP        SET UNOPTIMISABLE FLAG          37200001
         B     SSUBSNXT                                                 37300001
*                                                                       37400001
*                                                                       37500001
SSUBMCNT TM    SSUBOPN2,SSUBCNST        TEST IF OPERAND2 IS CONSTANT    37600001
         BO    SSUBMUNO                 IF SO BRANCH                    37700001
*                                                                       37800001
         B     SSUBSNXT                                                 37900001
*                                                                       38000001
         EJECT                                                          38100001
*                                                                       38200001
**             PROCESS COMR TRIPLE                                      38300001
*                                                                       38400001
SSUBCOMR MVI   XSRTSCCE,XSRTSDLT        MARK AS DEALT WITH              38500001
         B     SSUBCUNS                                                 38600001
*                                                                       38700001
         EJECT                                                          38800001
*                                                                       38900001
**             PROCESS COMMA TRIPLE                                     39000001
*                                                                       39100001
SSUBCOMA CLC   XTRPOP2,=X'FFFF'         EXAMINE OPERAND2                39200001
         BNE   SSUBCCON                 BRANCH IF NOT 'FFFF'            39300001
*                                                                       39400001
         MVI   XSRTSCCE,XSRTSDLT        MARK AS DEALT WITH              39500001
         B     SSUBCUNS                                                 39600001
*                                                                       39700001
SSUBCCON IC    PR0,=X'FF'               ) CALL KPCHKP TO EXAMINE        39800001
         BAL   RR,KPCHKP                ) SECOND OPERAND OF TRIPLE      39900001
*                                                                       40000001
         TM    SSUBFLAG,SSUBUNOP        TEST IF UNOPTIMISABLE           40100001
         BZ    SSUBCCNT                 BRANCH IF NOT                   40200001
*                                                                       40300001
SSUBCUNO NI    XSRTSCCE,X'00'           CLEAR COMA CODE FLAGS,          40400001
*                                         EXPRESSION UNOPTIMISABLE      40500001
         B     SSUBCLCM                 BRANCH TO END OF LOOP           40600001
*                                                                       40700001
*                                                                       40800001
SSUBCCNT TM    SSUBOPN2,SSUBCNST        ) IF OPERAND2 OF                40900001
         BZ    SSUBCOPT                 ) TRIPLE IS A CONSTANT          41000001
*                                       )                               41100001
         OI    SSUBFLAG,SSUBINVR        ) SET INVARIANT FLAG            41200001
*                                                                       41300001
SSUBCOPT TM    SSUBFLAG,SSUBCONV+SSUBINVR    ) BRANCH IF NO CONTROL     41400001
         BZ    SSUBCUNO                      ) VARIABLE OR INVARIANT    41500001
*                                                                       41600001
         TM    XMAPOPTN,XMAPORDR        ) BRANCH IF UNDER               41700001
         BZ    SSUBCCVT                 ) OPTION REORDER                41800001
*                                                                       41900001
         CLC   SSUBEXPR,=H'1'           TEST EXPRESSION VALUE           42000001
         BH    SSUBCUNO                 BRANCH IF GREATER THAN ONE      42100001
*                                                                       42200001
SSUBCCVT TM    SSUBFLAG,SSUBUNSF        TEST IF UNSAFE VARIABLES        42300001
         BZ    SSUBCTCV                 BRANCH IF NOT                   42400001
*                                                                       42500001
         TM    XMAPLOOP,XMAPATUV        TEST IF ASSIGNMENT TO UNSAFE    42600001
         BO    SSUBCUNO                 IF SO BRANCH                    42700001
*                                                                       42800001
SSUBCTCV TM    SSUBFLAG,SSUBCONV        ) BRANCH IF NO                  42900001
         BZ    SSUBCINV                 ) CONTROL VARIABLE              43000001
*                                                                       43100001
         TM    SSUBFLAG,SSUBNOTR+SSUBPMEX    ) BRANCH IF TRANSFORM NOT  43200001
         BC    BNZ,SSUBCINV                  ) PERMITTED                43300001
*                                                                       43400001
         OI    XSRTSCCE,XSRTCTRA        MARK AS TRANSFORMABLE           43500001
*                                                                       43600001
SSUBCINV TM    SSUBFLAG,SSUBINVR        ) BRANCH IF NO                  43700001
         BZ    SSUBCDVM                 ) INVARIANTS                    43800001
*                                                                       43900001
*                                                                       43910001
         TM    SSUBFLAG,SSUBCONV        TEST IF CV PRESENT              43920001
         BZ    SSUBCSIN                 BRANCH IF NOT                   43930001
*                                                                       43940001
         TM    SSUBFLAG,SSUBNOTR        TEST IF TRANSFORMATION ALLOWED  43950001
         BO    SSUBCUNO                 BRANCH IF NOT                   43960001
*                                                                       43970001
**             IF CV PRESENT AND TRANSFORMATION NOT ALLOWED THEN        43980001
**             INVARIANTS ARE NOT CONSIDERED FOR OPTIMISATION EITHER.   43990001
*                                                                       44000001
SSUBCSIN OI    XSRTSCCE,XSRTCINV        MARK AS INVARIANT               44010001
*                                                                       44100001
*                                                                       44500001
SSUBCDVM OC    XSRTCODE,XSRTSCCE        SET SSUBS CODE FROM             44900001
*                                         INDIVIDUAL CODE               45300001
*                                                                       45400001
SSUBCUNS TM    SSUBFLAG,SSUBUNSF        ) MARK INDIVIDUAL COMA CODE     45500001
         BZ    SSUBCLCM                 ) UNSAFE IF ANY UNSAFE          45600001
         OI    XSRTSCCE,XSRTSCUN        ) VARIABLES PRESENT             45700001
*                                                                       45800001
SSUBCLCM BCT   GRCCNT,SSUBCRST          BRANCH TO ADJUST PARAMETERS     45900001
*                                                                       46000001
       IEMKTAB BLDC,XLCRSRT,XSRT,SATO=SSUBFWWS+1  ADD ENTRY TO LIST     46100001
*                                                                       46200001
*                                                                       46400001
         LA    GRXTRP,XTRPEND-XTRP(0,GRXTRP) INCREMENT GRXTRP TO POINT  46500001
*                                              TO NEXT PATCH TRIPLE     46600001
*                                                                       46700001
         L     PR0,SSUBFWWS             RETURN SYMB ADD IN PR0          46800001
         LR    PR1,GRXTRP               RETURN GRXTRP VALUE IN PR1      46850001
         IEMKLVE                                                        46920001
*                                                                       47000001
*                                                                       47100001
*                                                                       47200001
SSUBCRST LA    GRX,XSRTSEND-XSRTSCOM    ) POINT GRSCOM AT NEXT AREA OF  47300001
         SR    GRSCOM,GRX               ) SSUBS ENTRY                   47400001
*                                                                       47500001
*                                                                       47900001
         B     SSUBSNXC                 BRANCH TO PROCESS NEXT COMA     48000001
*                                         EXPRESSION                    48100001
*                                                                       48200001
         DROP  GRSCOM                                                   48300001
*                                                                       48400001
*                                                                 30355 48410019
*                                                                 30355 48420019
SSUBTMP2 DC    X'00'                    FLAG SET IF ARRAY IS A DYNAMIC  48430019
*                                       TEMP - TEMP TYPE2         30355 48440019
*                                       IE  BOUGHT AT PROGRAM RUN TIME  48450019
         EJECT                                                          48500001
         LTORG                                                          48600001
         EJECT                                                          48700001
*                                                                       48800001
SSUBFWWS DC    F'0'                     FULL WORD WORK SPACE            48900001
SSUBSASA DC    F'0'                     SAVE PATCH SYMBOLIC ADDRESS     48950001
*                                                                       49000001
*                                                                       49200001
SSUBEXPR DC    H'0'                     COMA EXPRESSION VALUE           49300001
*                                                                       49400001
SSUBOPN1 DC    X'0'                     ) TRIPLE OPERANDS INFORMATION   49500001
SSUBOPN2 DC    X'0'                     ) CODE BYTES                    49600001
*                                                                       49700001
SSUBNOTR EQU   X'80'                    NO TRANSFORMATION               49800001
SSUBUNOP EQU   X'40'                    UNOPTIMISABLE                   49900001
SSUBCONV EQU   X'20'                    CONTROL VARIABLE PRESENT        50000001
SSUBINVR EQU   X'10'                    INVARIANT PRESENT               50100001
SSUBCNST EQU   X'08'                    CONSTANT                        50200001
SSUBZERO EQU   X'04'                    OPERAND IS X'04'                50300001
SSUBPMEX EQU   X'02'                    PREFIX MINUS EXPRESSION         50400001
SSUBUNSF EQU   X'01'                    UNSAFE (VARIABLE/EXPRESSION)    50500001
*                                                                       50600001
*                                                                       50700001
SSUBFLAG DC    X'0'                     COMA EXPRESSION CODE BYTE       50800001
*                                                                       50900001
*                                                                       51000001
SSUBTTAB DC    15X'0',X'1C'                                             51100001
         DC    23X'0',X'1C',8X'0'                                       51200001
         DC    15X'0',X'1C'                                             51300001
         DC    X'0010',14X'0'                                           51400001
         DC    32X'0'                                                   51500001
         DC    X'0000000800082014000C000400180000'                      51600001
         DC    128X'0'                                                  51700001
*                                                                       51800001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*KQ 001-TSS 51830019
SSUBXSRT DC    (XSRTSCOM-XSRT)X'00',(32*(XSRTSEND-XSRTSCOM))X'00'       51860001
*        ----------------------------------------------------KQ 001-TSS 51890019
*                                       SPACE FOR XSRT DSECT GIVING     51920001
*                                         32 COMA EXPRESSIONS IN SSUBS  52000001
*                                         ENTRY                         52100001
*                                                                       52200001
         EJECT                                                          52300001
*                                                                       52400001
**       THIS ROUTINE SEARCHES THE USE LIST TO SEE IF THE GIVEN         52500001
**       DICTIONARY REFERENCE IS CONTAINED IN THIS LIST.  A RETURN      52600001
**       CODE VALUE IS GIVEN AS FOLLOWS:-                               52700001
**             4    NOT IN USE LIST                                     52800001
**             8    IN 'ASSIGNED TO' PART OF USE LIST                   52900001
**             C    IN 'INVARIANT'PART OF USE LIST                      53000001
**       ON ENTRY PR1 CONTAINS ADDRESS CONTAINING  DICTIONARY REFERENCE 53100001
**       ON EXIT PR1 CONTAINS 0 IF VARIABLE IS SAFE                     53200001
**                         OR 4 IF VARIABLE IS UNSAFE                   53300001
*                                                                       53400001
KPUSEL   IEMKENT  TYPE=1                                                53500001
         LR    GRY,PR1                  STORE PR1 VALUE                 53600001
*                                                                       53700001
         USING XUSE,GRXUSE              BASE USE LIST DSECT             53800001
*                                                                       53900001
*                                                                       54000001
*                                                                       54200001
         CLI   XMAPUSEL,USELLEND        CHECK THAT A USE LIST EXISTS    54300001
         BE    USELSTEX                BRANCH IF NO LIST                54400001
*                                                                       54500001
**             SET UP PARAMETERS TO INITIALIZE USE LIST SCAN            54600001
*                                                                       54700001
       IEMKTAB SET,XLCRUSE,SA=XMAPUSEL                                  54800001
*                                                                       54900001
USELNEXT DS    0H                                                       54960001
       IEMKTAB SCAN,XLCRUSE,AATO=(GRXUSE)              GET NEXT ELEMENT 55020001
*                                                                       55100001
**       GRXUSE BASES XUSE DSECT                                        55200001
*                                                                       55300001
*                                                                       55400001
         CLI   XUSECODE,XUSELEND        TEST FOR END OF LIST            55500001
         BE    USELSTEX                 BRANCH ON END OF LIST           55600001
*                                                                       55700001
         CLC   XUSEDREF,0(GRY)          COMPARE DICTIONARY REFERENCE    55800001
*                                         GIVEN WITH THAT IN USE LIST   55900001
         BNE   USELNEXT                 BRANCH IF NOT EQUAL             56000001
*                                                                       56100001
*              TEST IF VARIABLE IS SAFE OR UNSAFE                       56150001
*                                                                       56200001
         SR    PR1,PR1                 INITIALIZE PARAMETER SAFE FLAG   56250001
         TM    XUSECODE,XUSEUNSF       TEST USE LIST ENTRY UNSAFE FLAG  56300001
         BZ    USELSTAS                BRANCH IF SAFE                   56350001
*                                                                       56400001
         LA    PR1,4                   SET PARAMETER UNSAFE             56450001
*                                                                       56500001
USELSTAS LA    RC,USELASSN             SET RETURN CODE FOR ELEMENT      56550001
*                                         'ASSIGNED TO'                 56600001
*                                                                       56700001
         TM    XUSECODE,XUSEASSN        TEST IF VARIABLE 'ASSIGNED TO'  56800001
         BO    USELEXIT                 BRANCH IF 'ASSIGNED TO'         56900001
*                                                                       57000001
USELSTIN LA    RC,USELINVR             SET RETURN CODE FOR ELEMENT      57100001
*                                         'INVARIANT'                   57200001
*                                                                       57300001
USELEXIT IEMKLVE  RC=(RC)                                               57400001
*                                                                       57500001
*                                                                       57502001
*                                                                       57504001
*        ROUTE IF NO USE LIST, OR DR IS NOT IN USE LIST                 57506001
*                                                                       57508001
USELSTEX MVC   PAR1+2(2),0(GRY)        )  CALL ZDRFAB TO                57510001
         L     LR,ZDRFAB               )  ACCESS DICT ENTRY             57512001
         BALR  RR,LR                   )                                57514001
*                                                                       57516001
         L     GR4,PAR1                LOAD GR4 AS BASE REG OF XDRF     57518001
         USING XDRF,GR4                                                 57520001
*                                                                       57522001
         TM    XMAPLOOP,XMAPOCTS       ) TEST IF ONLY COMP CREATED      57524001
         BZ    USELSAFE                ) TEMPS IN USE LIST.  NO, HENCE  57526001
*                                      ) ASSUME VARIABLE IS INVARIANT   57528001
*                                                                       57530001
*                                                                       57532001
**             TEST IF VARIABLE IS COMPILER CREATED TEMPORARY           57534001
*                                                                       57536001
         LA    RC,USELNINL             INITIALIZE RC                    57538001
         CLI   XDRFCODE,XDRFTEMP       IS CODE REQUIRED VALUE?          57540001
         BNE   USELEXIT                BRANCH IF NOT                    57542001
*                                                                       57544001
         TM    XDRFOTH2,XDRFPARM       IS THIS A PARAMETER?             57546001
         BO    USELEXIT                IF SO BRANCH                     57548001
*                                                                       57550001
USELSAFE SR    PR1,PR1                 INITIALIZE PARAMETER SAFE FLAG   57552001
         TM    XDRFOTH3,XDRFUNSF       TEST IF VARIABLE UNSAFE          57554001
         BZ    USELSTIN                BRANCH IF SAFE                   57556001
*                                                                       57558001
         LA    PR1,4                   SET PARAMETER FLAG UNSAFE        57560001
         B     USELSTIN                                                 57562001
*                                                                       57564001
         DROP  GR4                                                      57566001
*                                                                       57568001
*                                                                       57600001
*                                                                       57700001
USELNINL EQU   X'04'                    VARIABLE NOT IN USE LIST        57800001
USELASSN EQU   X'08'                    VARIABLE IS ASSIGNED TO         57900001
USELINVR EQU   X'0C'                    VARIABLE IS INVARIANT           58000001
USELLEND EQU   X'FF'                    NO USE LIST                     58100001
*                                                                       58200001
*                                                                       58300001
         LTORG                                                          58400001
         EJECT                                                          58500001
*                                                                       58600001
**       THIS ROUTINE EXAMINES AN OPERAND OF A TRIPLE AND SETS FLAGS    58700001
**       IN A CODE BYTE GIVING THE INFORMATION REQUIRED ON THE OPERAND  58800001
**       DURING THE ANALYSIS OF THE EXPRESSION WITHIN WHICH IT OCCURS.  58900001
**       ON ENTRY THE ADDRESS OF THE OPERAND IN THE TRIPLE IS PASSED    59000001
**       IN PR1.  PR1 REMAINS UNALTERED FOR USE IN KJSRUSEL.            59100001
**       ON EXIT THE CODE BYTE IS HELD IN THE LEAST SIGNIFICANT EIGHT   59200001
**       BITS OF PR0.                                                   59300001
*                                                                       59400001
*                                                                       59500001
KPSOPC   IEMKENT  TYPE=1                                                59600001
*                                                                       59700001
         USING XDRF,GRXDRF              BASE DICTIONARY ENTRY DSECT     59800001
*                                                                       59900001
         XC    SOPCCODE,SOPCCODE        CLEAR CODE WORK SPACE           60000001
*                                                                       60100001
         LR    GROPR,PR1                LOAD ADDRESS OF OPERAND         60200001
         CLC   0(2,GROPR),=H'0'         TEST IF OPERAND IS X'00'        60300001
         BNE   SOPCCONS                 BRANCH IF NOT                   60400001
*                                                                       60500001
         OI    SOPCCODE,SSUBZERO        SET X'00' FLAG                  60600001
         B     SOPCEXIT                 BRANCH, TEST COMPLETED          60700001
*                                                                       60800001
         EJECT                                                          60900001
*                                                                       61000001
**             TEST FOR CONSTANT OPERAND                                61100001
*                                                                       61200001
SOPCCONS MVC   PAR1+2(2),0(GROPR)       ) BRING IN DICTIONARY ENTRY     61300001
         L     LR,ZDRFAB                )                               61400001
         BALR  RR,LR                    )                               61500001
*                                                                       61600001
         L     GRXDRF,PAR1              LOAD XDRF BASE REGISTER         61700001
         CLI   XDRFCODE,XDRFCNST        TEST IF CONSTANT DICT ENTRY     61800001
         BNE   SOPCEXUS                 BRANCH IF NOT                   61900001
*                                                                       62000001
         OI    SOPCCODE,SSUBCNST        SET CONSTANT FLAG               62100001
         B     SOPCEXIT                                                 62200001
*                                                                       62300001
         EJECT                                                          62400001
*                                                                       62500001
*                                                                       62600001
SOPCEXUS LR    PR1,GROPR                RESET PR1                       62700001
         BAL   RR,KPUSEL                CALL KPUSEL TO SEE IF GIVEN     62800001
*                                         DICT REF IS IN USE LIST.      62900001
*                                                                       63000001
SOPCBTAB B     SOPCBTAB(RC)             BRANCH ACCORDING TO RETURN CODE 63100001
         B     SOPCSAFE                 DICT. REF. NOT IN USE LIST      63200001
         B     SOPCASSN                 IN USE LIST - ASSIGNED TO       63300001
*                                       IN USE LIST - INVARIANT         63400001
*                                                                       63500001
**             TEST FOR CONTROL VARIABLE                                63600001
*                                                                       63700001
SOPCCONV CLC   XMAPCVDR(2),0(GROPR)     CHECK FOR OPERAND BEING THE CV  63800001
         BNE   SOPCINVR                 BRANCH IF NOT                   63900001
*                                                                       64000001
         OI    SOPCCODE,SSUBCONV        SET CONTROL VARIABLE FLAG       64100001
*                                                                       64200001
         B     SOPCASSN                                                 64300001
*                                                                       64400001
SOPCINVR OI    SOPCCODE,SSUBINVR        SET INVARIANT FLAG              64500001
*                                                                       64600001
SOPCASSN LTR   PR1,PR1                 TEST IF VARIABLE IS SAFE         64800001
         BZ    SOPCEXIT                IF SO BRANCH                     65000001
*                                                                       65200001
         OI    SOPCCODE,SSUBUNSF        SET UNSAFE FLAG                 65300001
         B     SOPCEXIT                                                 65400001
*                                                                       65500001
*                                                                       65600001
SOPCSAFE TM    XDRFOTH3,XDRFUNSF        ) BRANCH IF VARIABLE IS SAFE    65700001
         BZ    SOPCEXIT                 )                               65800001
*                                                                       65900001
         OI    SOPCCODE,SSUBUNSF        SET UNSAFE FLAG                 66000001
*                                                                       66100001
**             COPY SOPCCODE TO EXIT PARAMETER                          66200001
*                                                                       66300001
SOPCEXIT IC    PR0,SOPCCODE                                             66400001
*                                                                       66500001
         IEMKLVE                                                        66600001
*                                                                       66700001
SOPCCODE DC    X'0'                     WORKING CODE BYTE               66800001
*                                                                       66900001
         LTORG                                                          67000001
         EJECT                                                          67100001
*                                                                       67200001
**       THIS ROUTINE EXAMINES THE OPERANDS OF THE TRIPLES WITHIN THE   67300001
**       CONTEXT OF EVALUATING THE TYPE OF EXPRESSION UNDER             67400001
**       CONSIDERATION                                                  67500001
**       ON ENTRY PR0 CONTAINS A FLAG STATING WHICH OF THE TWO ENTRY    67600001
**       POINTS IS REQUIRED,                                            67700001
**       PR0=0 FOR BOTH OPERANDS                                        67800001
**       PR0=FF FOR SECOND OPERAND ONLY                                 67900001
**       THE RESULTS OF THE ROUTINE ARE PLACED IMMEDIATELY IN SSUBFLAG. 68000001
*                                                                       68100001
KPCHKP   IEMKENT  TYPE=1                                                68200001
*                                                                       68300001
*                                                                       68400001
         STC   PR0,CHKPFLAG             STORE FIRST/SECOND OP FLAG      68500001
         CLI   CHKPFLAG,X'00'           TEST FIRST/SECOND OP FLAG       68600001
         BNE   CHKPOPR2                 BRANCH IF SECOND OPERAND        68700001
*                                                                       68800001
         LA    PR1,XTRPOP1              SET PR1 TO START OF OPERAND 1   68900001
         B     CHKPOPCD                 BRANCH TO SET OPCODE            69000001
*                                                                       69100001
CHKPOPR2 LA    PR1,XTRPOP2              SET PR1 TO START OF OPERAND 2   69200001
*                                                                       69300001
CHKPOPCD BAL   RR,KPSOPC                BRANCH TO SET OPCODE BYTE FOR   69400001
*                                         OPERAND IN PR1                69500001
*                                                                       69600001
         STC   PR0,CHKPCODE             STORE OP CODE BYTE LOCALLY      69700001
*                                                                       69800001
         TM    CHKPCODE,SSUBZERO                                        69900001
         BO    CHKPBRNH                 BRANCH IF OPERAND IS '00'       70000001
*                                                                       70100001
         TM    CHKPCODE,SSUBCNST                                        70200001
         BO    CHKPBRNH                 BRANCH IF A CONSTANT            70300001
*                                                                       70400001
         TM    CHKPCODE,SSUBUNSF        TEST IF OPERAND IS UNSAFE       70500001
         BZ    CHKPCHCV                 BRANCH IF SAFE                  70600001
*                                                                       70700001
         OI    SSUBFLAG,SSUBUNSF        SET EXPRESSION UNSAFE FLAG      70800001
*                                                                       70900001
CHKPCHCV TM    CHKPCODE,SSUBCONV        TEST IF OPERAND IS CONT. VAR.   71000001
         BO    CHKPCONV                 IF SO BRANCH                    71100001
*                                                                       71200001
         TM    CHKPCODE,SSUBINVR        TEST IF OPERAND IS INVARIANT    71300001
         BO    CHKPINVR                 IF SO BRANCH                    71400001
*                                                                       71500001
CHKPUNOP OI    SSUBFLAG,SSUBUNOP        SET UNOPTIMISABLE FLAG          71600001
         B     CHKPBRNH                                                 71700001
*                                                                       71800001
*                                                                       71900001
CHKPINVR TM    SSUBFLAG,SSUBINVR        TEST IF FIRST INVARIANT         72000001
         BO    CHKPINEX                 BRANCH IF NOT                   72100001
*                                                                       72200001
         OI    SSUBFLAG,SSUBINVR        SET EXPRESSION INVARIANT FLAG   72300001
*                                                                       72400001
         TM    SSUBFLAG,SSUBCONV        TEST IF CV ALSO PRESENT         72500001
         BZ    CHKPBRNH                 BRANCH IF NOT                   72600001
*                                                                       72700001
CHKPINEX LA    GRX,2                    ) SET EXPRESSION COUNT          72800001
         STH   GRX,SSUBEXPR             ) EQUAL TO TWO                  72900001
         B     CHKPBRNH                                                 73000001
*                                                                       73100001
CHKPCONV TM    SSUBFLAG,SSUBCONV        TEST IF FIRST CONTROL VARIABLE  73200001
         BO    CHKPUNOP                 BRANCH IF NOT                   73300001
*                                                                       73400001
         OI    SSUBFLAG,SSUBCONV        SET CONTROL VARIABLE FLAG       73500001
*                                                                       73600001
         TM    SSUBFLAG,SSUBINVR        TEST IF INV ALSO PRESENT        73700001
         BO    CHKPINEX                 IF SO BRANCH                    73800001
*                                                                       73900001
*                                                                       74000001
*                                                                       74100001
CHKPBRNH CLI   CHKPFLAG,X'00'           CHECK IF FIRST OPERAND          74200001
         BNE   CHKPEXIT                 BRANCH IF SECOND                74300001
*                                                                       74400001
         MVC   SSUBOPN1,CHKPCODE        SET OPERAND 1 CODE BYTE         74500001
         OI    CHKPFLAG,X'FF'           SET CHKPFLAG FOR SECOND OPRND   74600001
         B     CHKPOPR2                 BRANCH TO EXAMINE SECOND OPRND  74700001
*                                                                       74800001
*                                                                       74900001
CHKPEXIT MVC   SSUBOPN2,CHKPCODE        SET OPERAND 2 CODE BYTE         75000001
*                                                                       75100001
         IEMKLVE                                                        75200001
*                                                                       75300001
*                                                                       75400001
CHKPFLAG DC    X'0'                     FIRST/SECOND OPERAND FLAG       75500001
CHKPCODE DC    X'0'                     WORKING CODE BYTE               75600001
*                                            FLAGS AS FOR SSUBFLAG      75700001
*                                                                       75800001
*                                                                       75900001
         LTORG                                                          76000001
         EJECT                                                          76100001
         END                                                            76200001
