KT       TITLE 'IEMKT,PSEUDO CODE,SCAN UTILITY,PL/I(F)'                 00060031
*        LOGICAL  PHASE - PSEUDO-CODE                                   00120031
*        PHYSICAL PHASE - SCAN                                          00180031
*        MODULE         - IEMKT                                         00240031
* R18 464800                                                       0222 00300031
* R18 697200-697900,954800                                       21124  00360031
         SPACE 3                                                        00420031
*        THIS IS THE OLD VERSION 4 'LA' RENEMAD                         00480031
* FUNCTION-                                                             00540031
         SPACE                                                          00600031
*              PROVIDE TEXT-HANDLING ROUTINES FOR ALL PHYSICAL PHASES   00660031
*              IN THE PSEUDO-CODE LOGICAL PHASE.                        00720031
         SPACE 3                                                        00780031
* ENTRY POINTS-                                                         00840031
*        (1)   ENTRY FROM COMPILER CONTROL TWO BYTES BEYOND MODULE      00900031
*              LOAD POINT.UPDATE MODULE BASE REGISTER TO POINT AT SCAN  00960031
*              TRANSFER VECTOR.                                         01020031
*                                                                       01080031
*        (2)   TEXT-HANDLING UTILITIES FOR PSEUDO-CODE PHASES-          01140031
         SPACE                                                          01200031
*              SCINIT                                                   01260031
*              PICK UP ZTEXT FROM COMMUNICATIONS REGION FOR SYMBOLIC    01320031
*              START OF INPUT TEXT.CONVERT TO ABSOLUTE,LOAD INPUT       01380031
*              POINTER.                                                 01440031
*              GET A TEXT BLOCK FOR OUTPUT,UPDATE ZTEXT AND STORE       01500031
*              OUTPUT POINTER IN COMMUNICATIONS REGION.                 01560031
         SPACE                                                          01620031
*              SC1                                                      01680031
*              SCAN FROM CURRENT TRIPLE,LOOKING FOR A TRIPLE OF INTER-  01740031
*              EST TO THE USER.TRIPLES NECESSARY FOR SCAN HOUSEKEEPING  01800031
*              HAVE NON-ZERO TRT ENTRIES NOT GREATER THAN 72,USER       01860031
*              TRIPLES HAVE ENTRIES GREATER THAN 72.                    01920031
*              CONTROL IS RETURNED TO THE USER WITH THE TRIPLE OF       01980031
*              INTEREST INDICATED BY THE INPUT POINTER.                 02040031
         SPACE                                                          02100031
*              SC2                                                      02160031
*              MOVE THE CURRENT TRIPLE TO THE OUTPUT TEXT,BUMP IP TO    02220031
*              THE NEXT TRIPLE,THEN SCAN AS IN SC1                      02280031
         SPACE                                                          02340031
*              SC3                                                      02400031
*              DELETE THE CURRENT TRIPLE,THEN SCAN AS IN SC1            02460031
         SPACE                                                          02520031
*              SC4                                                      02580031
*              MARK INPUT TEXT BLOCK WANTED,GET NEXT TRIPLE             02640031
         SPACE                                                          02700031
*              SC5                                                      02760031
*              MARK INPUT TEXT BLOCK FREE,GET NEXT TRIPLE               02820031
         SPACE 1                                                        02880031
*              SC6                                                      02940031
*              MARK INPUT TEXT BLOCK WANTED, MOVE CURRENT TRIPLE TO     03000031
*              OUTPUT AND GET NEXT TRIPLE.                              03060031
         SPACE 1                                                        03120031
*              SC7                                                      03180031
*              MARK INPUT TEXT BLOCK FREE, MOVE CURRENT TRIPLE TO       03240031
*              OUTPUT AND GET NEXT TRIPLE.                              03300031
         SPACE                                                          03360031
*              SC8                                                      03420031
*              MARK INPUT TEXT BLOCK WANTED,MOVE JMP TRIPLE AND         03480031
*              PSEUDO-CODE INDICATED BY IP.                             03540031
         SPACE                                                          03600031
*              SC9                                                      03660031
*              MARK INPUT TEXT BLOCK FREE, MOVE JUMP TRIPLE AND PSEUDO  03720031
*              CODE INDICATED BY IP TO OUTPUT                           03780031
         SPACE 1                                                        03840031
*              SC10                                                     03900031
*              CONVERT SYMBOLIC TEXT REFERENCE IN PAR1 TO ABSOLUTE,IF   03960031
*              THE INDICATED INPUT BLOCK IS NOT THE CURRENT ONE,THEN    04020031
*              UPDATE THE SCAN HOUSEKEEPING                             04080031
         SPACE                                                          04140031
*              SC11                                                     04200031
*              MARK INPUT TEXT BLOCK WANTED,BUMP IP OVER THE CURRENT    04260031
*              JMP TRIPLE AND THE FOLLOWING PSEUDO-CODE.                04320031
         SPACE 1                                                        04380031
*              SC12                                                     04440031
*              MARK INPUT TEXT BLOCK FREE, BUMP IP OVER CURRENT JUMP    04500031
*              TRIPLE AND FOLLOWING PSEUDO-CODE.                        04560031
         SPACE 1                                                        04620031
*              DV1                                                      04680031
*              CREATE A DOPE VECTOR IN WORKSPACE FOR A BASED VARIABLE.  04740031
*              THE DOPE VECTOR MAY BE IN RELATIVE OR RELOCATED FORM.    04800031
         SPACE                                                          04860031
*              MV2                                                      04920031
*              MOVES USER GENERATED PSEUDO-CODE TO OUTPUT IN SUCH A     04980031
*              WAY THAT THE TEXT IN THE OUTPUT BLOCK IS CONTIGUOUS.     05040031
         SPACE 1                                                        05100031
*              MV3                                                      05160031
*              MOVE TO OUTPUT THE PSEUDO-CODE IN THE CONTINUOUS USER    05220031
*              BUFFER,POINTED AT BY PAR1,WITH THE NUMBER OF BYTES IN    05280031
*              PAR2.                                                    05340031
         SPACE                                                          05400031
*              MV3A                                                     05460031
*              AS MV3,BUT TRIPLES ARE MOVED                             05520031
         SPACE 3                                                        05580031
*INPUT-                                                                 05640031
         SPACE                                                          05700031
*              TEXT BLOCKS,DICTIONARY BLOCKS,PARAMETERS IN THE          05760031
*              COMMUNICATIONS REGION.                                   05820031
         SPACE 3                                                        05880031
*OUTPUT-       TEXT BLOCKS                                              05940031
         SPACE 3                                                        06000031
*EXTERNAL ROUTINES-CONTROL PHASE UTILITIES ONLY                         06060031
         SPACE 3                                                        06120031
*EXITS -                                                                06180031
*              NORMAL                                                   06240031
*              RETURN ON LINK REGISTER FROM ALL UTILITIES               06300031
*              ABNORMAL                                                 06360031
*              TERMINATE VIA ZABORT IF AN ILLEGAL ENTRY TO SCAN IS      06420031
*              MADE, OR IF A '00' TRIPLE IS FOUND IN THE INPUT TEXT     06480031
         SPACE 3                                                        06540031
*TABLES/WORKAREAS -                                                     06600031
*              THE ONLY TABLE USED IS THE SCAN TRT TABLE AND PARAMETER  06660031
*              BLOCK WHICH SERVES AS THE MEDIUM OF COMMUNICATION        06720031
*              BETWEEN SCAN AND THE USER. IT HAS THE FOLLOWING FORMAT-  06780031
*              0    SCTRT    256 BYTE TRANSLATE TABLE CONTAINING        06840031
*                            ENTRIES FOR TRIPLES OF INTEREST TO SCAN    06900031
*                            AND USER.                                  06960031
*              256  SCSTAD   ADDRESS (SYMBOLIC OR ABSOLUTE) OF LAST     07020031
*                            STATEMENT TRIPLE (CN,SL,SN OR SN2) MOVED   07080031
*                            TO OUTPUT                                  07140031
*              260  SCEOBO   ADDRESS OF END OF CURRENT OUTPUT BLOCK -3  07200031
*              264  SCJMP    ADDRESS OF LAST JUMP TRIPLE IN OUTPUT      07260031
*              268  SCPCG    COUNT OF PSEUDO-CODE GENERATED (INCLUDING  07320031
*                            JUMP TRIPLE LENGTH)                        07380031
*              272  SCTXTI   SYMBOLIC NAME OF CURRENT INPUT BLOCK IN    07440031
*                            SECOND BYTE.                               07500031
*              276  SCTXTO   SYMBOLIC NAME OF CURRENT OUTPUT BLOCK IN   07560031
*                            SECOND BYTE.                               07620031
*              280  SCWKS    WORKSPACE COUNT (LEFT JUSTIFIED HALF WORD) 07680031
*              284  SCBLK    DICT REF OF CURRENT BEGIN OR PROCEDURE     07740031
*                            BLOCK ENTRY TYPE 1.                        07800031
*              286  SCSTK    REGISTER USE BYTES.                        07860031
*              288  SCWSDR   DICT REF OF WORKSPACE                      07920031
*              290  SCOPT    PREFIX OPTION BYTE OF CURRENT STATEMENT    07980031
         SPACE 1                                                        08040031
*              TRIPLES OF INTEREST TO SCAN OR THE USER ARE REPRESENTED  08100031
*              BY NON-ZERO ENTRIES IN THE SCAN TRT TABLE AT POINTS      08160031
*              CORRESPONDING TO THE CODES OF THOSE TRIPLES.             08220031
*              THE FOLLOWING ENTRIES ARE MANDATORY-                     08280031
*              TRIPLE        SCAN ONLY      SCAN AND USER               08340031
*              FORMAT             4              40                     08400031
*              FORMAT'            8              44                     08460031
*              PROC              12              48                     08520031
*              BEGIN             16              52                     08580031
*              PROC'             20              56                     08640031
*              BEGIN'            24              60                     08700031
*              JUMP              28              64                     08760031
*              SN,SL,CN,SN2      32              68                     08820031
*              EOB               36               -                     08880031
*              EOP2               -              72                     08940031
*              EXITS FOR USER ONLY MUST HAVE VALUES EXCEEDING 72.       09000031
         SPACE 3                                                        09060031
*NOTES..                                                                09120031
*        (1)   THIS PHASE REQUIRES NO MODIFICATION AS A RESULT OF       09180031
*              CHANGES IN THE INTERNAL REPRESENTATION OF                09240031
*              EXTERNAL GRAPHICS                                        09300031
         SPACE                                                          09360031
*        (2)   REGISTER USAGE                                           09420031
*              IP                 INPUT TEXT POINTER                    09480031
*              TR                 PHYSICAL REGISTER ASSOCIATED          09540031
*                                 WITH TRT INSTRUCTION.                 09600031
*              SBASE              POINTS AT TRT TABLE AND SCAN          09660031
*                                 PARAMETER BLOCK IN USER PHASE         09720031
*              GRA,GRB            WORKING REGISTERS                     09780031
*              OP                 OUTPUT POINTER                        09840031
*              LBASE              PHASE BASE FOR IEMLA. POINTER TO      09900031
*                                 SCAN TRANSFER VECTOR                  09960031
*              DBASE              COMMUNICATIONS REGION BASE            10020031
*              ZBASE              CONTROL PHASE BASE                    10080031
*              LR1                SPECIAL LINK REGISTER 1               10140031
*              LR2                SPECIAL LINK REGISTER 2               10200031
*              LR                 LINK REGISTER                         10260031
*              BR                 BRANCH REGISTER                       10320031
         SPACE 1                                                        10380031
*        (3)   REFERENCES TO EXTERNAL ROUTINES, THE COMMUNICATIONS      10440031
*              REGION, AND THE SCAN PARAMETER BLOCK ARE MADE BY MEANS   10500031
*              OF RELOCATEABLE SYMBOLS OBTAINED BY COMBINATION OF       10560031
*              OFFSET DEFINITIONS AND USING STATEMENTS                  10620031
         EJECT                                                          10680031
IEMKT    START 0                                                        10740031
*                       DEFINITIONS OF SYMBOLS                          10800031
         SPACE 2                                                        10860031
*              GENERAL PURPOSE REGISTERS                                10920031
         SPACE 1                                                        10980031
LBASE    EQU   12                      PHASE BASE                       11040031
SBASE    EQU   3                       SCAN PARAMETER BLOCK BASE        11100031
DBASE    EQU   13                      DICTIONARY BASE                  11160031
ZBASE    EQU   11                      COMPILER CONTROL BASE            11220031
         SPACE 1                                                        11280031
LR       EQU   14                      LINK REGISTER                    11340031
LR1      EQU   7                       SPECIAL LINK REGISTER 1          11400031
LR2      EQU   8                       SPECIAL LINK REGISTER 2          11460031
BR       EQU   15                      BRANCH REGISTER                  11520031
IP       EQU   1                       INPUT POINTER                    11580031
TR       EQU   2                       SCAN RESULT REGISTER             11640031
         SPACE 1                                                        11700031
GR0      EQU   0                                                        11760031
OP       EQU   4                       INTERNAL OUTPUT POINTER          11820031
GRA      EQU   5                       WORK A                           11880031
GRB      EQU   6                            B                           11940031
         SPACE 1                                                        12000031
P        EQU   8                       MAXIMUM SAVED REGISTER NUMBER    12060031
Q        EQU   P+3                     NUMBER OF REGISTERS SAVED (14,   12120031
*                                    15,0 --- P)                        12180031
         SPACE 2                                                        12240031
*              BRANCH MNEMONICS                                         12300031
         SPACE 1                                                        12360031
B        EQU   15                      BRANCH                           12420031
BH       EQU   2                       BRANCH ON HIGH                   12480031
BL       EQU   4                                 LOW                    12540031
BE       EQU   8                                 EQUAL                  12600031
BNH      EQU   13                                NOT HIGH               12660031
BNL      EQU   11                                    LOW                12720031
BNE      EQU   7                                     EQUAL              12780031
BO       EQU   1                                 OVERFLOW/ONES          12840031
BP       EQU   2                                 PLUS                   12900031
BM       EQU   4                                 MINUS/MIXED            12960031
BZ       EQU   8                                 ZERO                   13020031
BNO      EQU   14                                NOT OVERFLOW/ONES      13080031
BNP      EQU   13                                    PLUS               13140031
BNM      EQU   11                                    MINUS/MIXED        13200031
BNZ      EQU   7                                     ZERO               13260031
         SPACE 2                                                        13320031
*              DEFINITIONS OF BLOCKS USED TO OBTAIN AUTOMATIC BASE      13380031
*        REGISTER ASSIGNMENT                                            13440031
         SPACE 1                                                        13500031
LBLOCK   EQU   *                                                        13560031
SBLOCK   EQU   *+X'1000'                                                13620031
DBLOCK   EQU   *+X'2000'                                                13680031
ZBLOCK   EQU   *+X'3000'                                                13740031
         SPACE 1                                                        13800031
         USING LBLOCK,LBASE                                             13860031
         USING SBLOCK,SBASE                                             13920031
         USING DBLOCK,DBASE                                             13980031
         USING ZBLOCK,ZBASE                                             14040031
         SPACE 2                                                        14100031
*              DEFINITIONS OF OFFSETS IN SCAN PARAMETER BLOCK           14160031
         SPACE 1                                                        14220031
SCTRT    EQU   SBLOCK                  TRANSLATE TABLE                  14280031
SCPBLK   EQU   SCTRT+256               START OF PARAMETER BLOCK         14340031
SCSTAD   EQU   SCPBLK                  ADDRESS OF LAST STATEMENT IN OP  14400031
SCEOBO   EQU   SCSTAD+4                EOB ADDRESS FOR CURRENT OUTPUT   14460031
SCJMP    EQU   SCEOBO+4                POSITION OF LAST JUMP            14520031
SCPCG    EQU   SCJMP+4                 COUNT OF PSEUDO CODE GENERATED   14580031
SCTXTI   EQU   SCPCG+4                 SYMBOLIC NAME OF CURRENT IP      14640031
SCTXTO   EQU   SCTXTI+4                SYMBOLIC NAME OF CURRENT OP      14700031
SCWKS    EQU   SCTXTO+4                WORKSPACE COUNT                  14760031
SCBLK    EQU   SCWKS+4                 DICT REF OF CURRENT BLOCK        14820031
SCSTK    EQU   SCBLK+2                 REGISTER USAGE BYTES             14880031
SCWSDR   EQU   SCSTK+2                 WORKSPACE DICT REF               14940031
SCOPT    EQU   SCWSDR+2                PREFIX OPTION CODE BYTE          15000031
         SPACE 1                                                        15060031
SCBKSZ   EQU   SCOPT+2-SCPBLK          LENGTH OF PARAMETER BLOCK        15120031
         SPACE 2                                                        15180031
*              DEFINITIONS OF OFFSETS IN COMMUNICATIONS REGION          15240031
         SPACE 1                                                        15300031
ZMYNAM   EQU   DBLOCK+112              NAME OF LAST PHASE ENTERED       15330000
ZSTAT    EQU   DBLOCK+124              CURRENT STATEMENT NUMBER         15360031
PAR1     EQU   DBLOCK+128              PARAMETER 1                      15420031
PAR2     EQU   PAR1+4                            2                      15480031
PAR6     EQU   PAR1+20                           6                      15540031
ZTEXT    EQU   DBLOCK+256              SYMBOLIC START OF INPUT TEXT     15600031
ZTBSZE   EQU   DBLOCK+264              TEXT BLOCK SIZE                  15660031
         SPACE 1                                                        15720031
ZCOMM    EQU   DBLOCK+304                                               15780031
ZSCNTV   EQU   ZCOMM+4                 ADDRESS OF SCAN TRANSFER VECTOR  15840031
ZPCOP    EQU   ZCOMM+8                 CURRENT OUTPUT POINTER           15900031
ZSMREG   EQU   ZCOMM+40                SYMBOLIC REGISTER NUMBER         15960031
ZOSMRG   EQU   ZCOMM+84                LAST OPTIMISER SYMBOLIC REGISTER 16020031
         SPACE 2                                                        16080031
*              DEFINITIONS OF OFFSETS IN CONTROL PHASE TRANSFER VECTOR  16140031
         SPACE 1                                                        16200031
ZUTXTC   EQU   ZBLOCK+X'14'            GET A TEXT BLOCK                 16260031
ZABORT   EQU   ZBLOCK+X'20'            ABORT                            16320031
ZUERR    EQU   ZBLOCK+X'30'            ERROR ENTRY                      16380031
ZDRFAB   EQU   ZBLOCK+X'34'            DICT REF TO ABSOLUTE             16440031
RLSCTL   EQU   ZBLOCK+X'48'            RELEASE CONTROL                  16500031
ZTXTRF   EQU   ZBLOCK+X'50'            ABSOLUTE TO TEXT REF             16560031
ZTXTAB   EQU   ZBLOCK+X'54'            TEXT REF TO ABSOLUTE             16620031
ZCHAIN   EQU   ZBLOCK+X'58'            CHAIN TO NEXT INPUT BLOCK        16680031
ZALTER   EQU   ZBLOCK+X'5C'            CHANGE TEXT BLOCK STATUS         16740031
DCL      EQU   X'C3'                   COMPILER LABEL ENTRY CODE        16800031
ESLN     EQU   8                       STATEMENT NUMBER IN LABEL ENTRY  16860031
ESLOT1   EQU   10                      OTHER1 CODE BYTE                 16920031
ESLVAR   EQU   11                      VARIABLE INFORMATION BYTE        16980031
ESLOT2   EQU   12                      OTHER 2                          17040031
ESLOT3   EQU   13                      OTHER 3                          17100031
ESLOT4   EQU   14                      OTHER 4                          17160031
ESTVAR   EQU   15                      NON DATA VARIABLE INFORMATION    17220031
EDADAT   EQU   15                      DATA CODE BYTE                   17280031
EDAVAR   EQU   21                      DATA VARIABLE INFORMATION        17340031
ESN2N    EQU   3                       STATEMENT NUMBER IN 2ND FILE     17400031
EWKSC    EQU   3                       WORKSPACE COUNT IN WKS ENTRIES   17460031
EWSREF   EQU   13                      WORKSPACE 1 REF                  17520031
EWFREF   EQU   17                      FORMAT WORKSPACE REF             17580031
         SPACE 2                                                        17640031
*              TRIPLE OPERATOR CODES                                    17700031
         SPACE 1                                                        17760031
FJUMP    EQU   X'5B'                   JUMP                             17820031
FSN      EQU   X'D0'                   STATEMENT NUMBER                 17880031
FSL      EQU   X'D2'                   STATEMENT LABEL                  17940031
FCN      EQU   X'D4'                   COMPILER NUMBER                  18000031
FEOB     EQU   X'ED'                   END OF BLOCK                     18060031
         SPACE 2                                                        18120031
*              PSEUDO CODE OPERATION CODES                              18180031
         SPACE 1                                                        18240031
PDROP    EQU   X'06'                   DROP                             18300031
POSM1    EQU   X'10'                   LITTERAL OFFSET                  18360031
PL       EQU   X'88'                   LOAD                             18420031
PA       EQU   X'8A'                   ADD                              18480031
PSTH     EQU   X'95'                   STORE HALF-WORD                  18540031
PST      EQU   X'A5'                   STORE                            18600031
PMVC     EQU   X'C1'                   MOVE                             18660031
         SPACE 2                                                        18720031
*              FLAG BITS                                                18780031
         SPACE 1                                                        18840031
PCODE    EQU   X'80'                 PSEUDO-CODE FLAG IN FLAG BYTE      18900031
SNSYM    EQU   X'40'                 POSITION OF SN IS SYMBOLIC         18960031
NPCODE   EQU   X'FF'-PCODE                                              19020031
NSNSYM   EQU   X'FF'-SNSYM                                              19080031
         EJECT                                                          19140031
*              INITIAL ENTRY POINT FROM COMPILER CONTROL WHEN PHASE     19200031
*        IS FIRST LOADED.                                               19260031
         SPACE 1                                                        19320031
LA0000   DC    C'KT'                   PHASE NAME EX 'KT'               19380031
         L     LBASE,PAR1              PICK UP PHASE BASE REGISTER AND  19440031
         MVC   ZMYNAM(2),H0            CLEAR PHASE NAME SLOT.           19470000
         BC    B,LA0001              BRANCH ROUND TRANSFER VECTOR TO    19500031
*                                    COMPLETE INITIALIZATION.           19560031
         SPACE 3                                                        19620031
*              SCAN TRANSFER VECTOR.                                    19680031
*        THIS TRANSFER VECTOR IS MOVED TO THE BEGINNING OF THE          19740031
*        PHASE DURING INITIALIZATION, OVERLAYING THE CODE AT LA0000     19800031
         SPACE 1                                                        19860031
SCTV     EQU   *                                                        19920031
*        SCANNING ENTRY POINTS                                          19980031
SCINIT   BC    B,LA0005                INITIALIZATION                   20040031
SC1      BC    B,LA0010                SCAN FROM CURRENT                20100031
SC2      BC    B,LA0011                MOVE CURRENT TRIPLE THEN SCAN    20160031
SC3      BC    B,LA0012                DELETE CURRENT TRIPLE THEN SCAN  20220031
SC4      BC    B,LA0020                SKIP CURRENT TRIPLE - TEXT WANT  20280031
SC5      BC    B,LA0021                SKIP CURRENT TRIPLE - TEXT FREE  20340031
SC6      BC    B,LA0025                MOVE CURRENT TRIPLE - TEXT WANT  20400031
SC7      BC    B,LA0026                MOVE CURRENT TRIPLE - TEXT FREE  20460031
SC8      BC    B,LA0030                MOVE JUMP - TEXT WANTED          20520031
SC9      BC    B,LA0031                MOVE JUMP - TEXT FREE            20580031
SC10     BC    B,LA0035                TEXT REF TO ABSOLUTE (INPUT)     20640031
SC11     BC    B,LA0040                SKIP OVER JUMP - TEXT WANTED     20700031
SC12     BC    B,LA0041                SKIP OVER JUMP - TEXT FREE       20760031
         SPACE 1                                                        20820031
*        TEXT MOVING ENTRY POINTS                                       20880031
DV1      BC    B,LA0070                CONSTRUCT DOPE VECTOR            20940031
MV2      BC    B,LA0050                MOVE USER CODE TO CONTIGUOUS OP  21000031
MV3      BC    B,LA0055                MOVE USER PSEUDO CODE            21060031
MV3A     BC    B,LA0056                MOVE USER TRIPLES                21120031
MV4      BC    B,LA0056                MOVE USER TRIPLES                21180031
MV4A     BC    B,LA0056                MOVE USER TRIPLES                21240031
         SPACE 1                                                        21300031
SCTVL    EQU   *-SCTV                  LENGTH OF TRANSFER VECTOR        21360031
         EJECT                                                          21420031
*              CONTINUATION OF INITIALIZATION FOR FIRST ENTRY. THE      21480031
*        ENSUING CODE IS USED ONLY ON THE FIRST ENTRY. THEREAFTER THE   21540031
*        SPACE IS USED AS A REGISTER SAVE AREA.                         21600031
         SPACE 1                                                        21660031
LA0001   MVC   LA0000(SCTVL),SCTV      MOVE TRANSFER VECTOR DOWN TO     21720031
*                                    BEGINNING OF PHASE AREA            21780031
         ST    LBASE,ZSCNTV            PLACE ADDRESS OF TRANSFER VECTOR 21840031
*                                       IN COMMUNICATIONS REGION        21900031
**  SET ZOSMRG TO ZERO TO PREVENT PSEUDO CODE PHASES OMITTING           21960031
**  DROP'S OF OPTIMISED REGISTERS                                       22020031
         MVI   ZOSMRG,X'00'                                             22080031
         MVI   ZOSMRG+1,X'FF'          SET FF FOR OE TO WORK CORRECTLY  22140031
*                                                                       22200031
         LH    GRA,ZSMREG+2                                             22260031
*                                    OPTIMISER.                         22320031
         LA    GRA,1(0,GRA)            NOW SET UP SYMBOLIC REGISTER     22380031
         STH   GRA,ZSMREG+2          NUMBERS IN PSEUDO-CODE SKELETONS   22440031
         MVC   PS041(2),ZSMREG+2       SR2                              22500031
         MVC   PS043(2),ZSMREG+2                                        22560031
         MVC   PS045(2),ZSMREG+2                                        22620031
         MVC   PS061(2),ZSMREG+2                                        22680031
         SPACE 1                                                        22740031
         LA    GRA,1(0,GRA)                                             22800031
         STH   GRA,ZSMREG+2                                             22860031
         MVC   PS031(2),ZSMREG+2       SR3                              22920031
         MVC   PS051(2),ZSMREG+2                                        22980031
         MVC   PS071(2),ZSMREG+2                                        23040031
         STH   GRA,DVPAR2              SAVE SR2 FOR RETURN IN PAR2      23100031
*                                    FOR ALLOCATE OR LOCATE             23160031
         SPACE 1                                                        23220031
         LA    GRA,LAZZ                RELEASE                          23280031
         ST    GRA,PAR1                                                 23340031
         SR    GRA,GRA                                                  23400031
         ST    GRA,PAR2                NOW SET UP PAR1 WITH 'ZZ' AND    23460031
         L     BR,RLSCTL             PAR2 0 AND RELEASE CONTROL         23520031
         BALR  LR,BR                                                    23580031
         SPACE 3                                                        23640031
*              THE ABOVE CODE IS OVERLAID DURING SCANNING WITH THE      23700031
*        FOLLOWING REGISTER SAVE AREA.                                  23760031
         SPACE 1                                                        23820031
DVPAR2   EQU   LA0000+SCTVL            RETURN VALUE FOR DV1 LOCATE      23880031
REFERS   EQU   DVPAR2+2                                                 23940031
LASAVE   EQU   DVPAR2+4                SAVE AREA                        24000031
IPSAVE   EQU   LASAVE+12               IP SAVE SLOT                     24060031
OPSAVE   EQU   LASAVE+24               SAVE SLOT FOR OP                 24120031
LRUT08   EQU   LASAVE+4*Q              SAVE 8                           24180031
         SPACE 1                                                        24240031
*              REGISTER SAVE AREA AND WORKSPACE FOR DV1                 24300031
DVSAVE   EQU   LRUT08+4              REGISTER SAVE AREA FOR DV1         24360031
DVSTXT   EQU   DVSAVE+4*Q            SYMBOLIC TEXT REF AND STRUCTURE    24420031
DVLEVL   EQU   DVSTXT                LEVEL NUMBER                       24480031
         SPACE 1                                                        24540031
*              AREA SET TO ZERO AT EACH ENTRY TO SCINIT.                24600031
INITZR   EQU   DVSTXT+4                                                 24660031
WKFMT    EQU   INITZR                  REMOTE FORMAT WORKSPACE COUNT    24720031
*                                    FOR CURRENT BLOCK.                 24780031
FLAG     EQU   WKFMT+2                 FLAG BYTE.                       24840031
STTRIP   EQU   FLAG+1                  STATEMENT TRIPLE TEMPORARY       24900031
*                                    WORKSPACE.                         24960031
HTEMP    EQU   STTRIP+3              WORKSPACE.                         25020031
WKPREV   EQU   STTRIP+5                WORKSPACE COUNT FOR PRECEDING    25080031
*                                    STATEMENT.                         25140031
INITZL   EQU   STTRIP+7-INITZR                                          25200031
*              END OF INITIALIZED AREA                                  25260031
         EJECT                                                          25320031
*              SCAN INITIALIZATION ROUTINE ENTERED AT BEGINNING OF      25380031
*        EVERY PSEUDO-CODE PHASE TO LOAD FIRST INPUT TEXT BLOCK, GET    25440031
*        AN OUTPUT TEXT BLOCK AND SET UP THE SCAN PARAMETER BLOCK       25500031
         SPACE 1                                                        25560031
LA0005   STM   LR,P,LASAVE             SAVE REGISTERS                   25620031
         XC    SCPBLK(SCBKSZ),SCPBLK   CLEAR THE PARAMETER BLOCK AND    25680031
         XC    INITZR(INITZL),INITZR CLEAR INITIALIZED AREA.            25740031
         L     IP,ZTEXT                PICK UP SYMBOLIC START OF INPUT  25800031
         BAL   LR1,UT01A             TEXT AND SET UP INPUT PARAMETERS   25860031
*                                    IN SCAN BLOCK                      25920031
         MVI   PAR2+3,0                SET PAR2 TO INDICATE NO PREVIOUS 25980031
         BAL   LR1,UT02B             BLOCK THEN GO AND GET AN OUTPUT    26040031
*                                    BLOCK AND SET UP OUTPUT PARAMS     26100031
*                                    IN SCAN BLOCK AND ZPCOP            26160031
         MVC   ZTEXT+1(1),SCTXTO+1     SET ZTEXT TO REFERENCE NEW       26220031
*                                    OUTPUT BLOCK.                      26280031
         BC    B,LA0008                GO TO COMMON RETURN SECTION      26340031
         EJECT                                                          26400031
*              COMMON RETURN SECTION                                    26460031
         SPACE 1                                                        26520031
*              THIS SECTION IS USED BY ALL SCAN ROUTINES TO RESTORE     26580031
*        REGISTERS AND RETURN TO THE CALLER. SEVERAL ENTRY POINTS ARE   26640031
*        AVAILABLE TO ALLOW FOR THOSE ROUTINES WHICH RETURN VALUES IN   26700031
*        REGISTERS.                                                     26760031
         SPACE 1                                                        26820031
LA0007   ST    IP,IPSAVE               RETURN FROM SPECIAL SCAN TRIPLE  26880031
         CH    TR,H36                SECTIONS. RETURN TO CALLER IF      26940031
         BCR   BNH,LR                SCAN ONLY, OTHERWISE FALL THROUGH  27000031
*                                    FOR USER RETURN                    27060031
         SPACE 1                                                        27120031
LA0008   BAL   LR1,UT01C               CHECK FOR END OF BLOCK           27180031
LA0009   LM    4,P,OPSAVE              RESTORE OP, -- P.                27240031
         LM    LR,0,LASAVE             RESTORE LR, BR AND 0             27300031
         MVI   MARKER,X'01'            SET THE MARKER BYTE TO ITS       27360031
*                                    STANDARD VALUE OF 'FREE'           27420031
         BCR   B,LR                    RETURN                           27480031
         EJECT                                                          27540031
*              SCANNING ROUTINES SC1, SC2 AND SC3                       27600031
         SPACE 1                                                        27660031
*              ON ENTRY IP ADDRESSES A TRIPLE IN THE INPUT TEXT. THE    27720031
*        TRIPLE IS NEVER AN END-OF-BLOCK MARKER AND, FOR SC2 AND SC3,   27780031
*        IS NEVER JUMP, SN, SL, CN OR SN2. TEXT IS SCANNED FROM THE     27840031
*        FIRST TRIPLE UNTIL A 'TRIPLE OF INTEREST' IS FOUND, WHEN ALL   27900031
*        THE SCANNED TEXT IS MOVED TO OUTPUT AND ACTION TAKEN AS        27960031
*        INDICATED BY THE VALUE OBTAINED FROM THE TRANSLATE TABLE       28020031
         SPACE 1                                                        28080031
LA0011   STM   LR,P,LASAVE             SC2. SAVE REGISTERS (PRESERVING  28140031
         SR    TR,TR                 INITIAL VALUE OF IP), THEN GO TO   28200031
         BC    B,LA1001              SCANNING LOOP, AVOIDING TESTING    28260031
*                                    THE FIRST TRIPLE.                  28320031
         SPACE 2                                                        28380031
LA0012   LA    IP,5(0,IP)              SC3. BUMP IP BY 5 BEFORE SAVING  28440031
*                                    SO THAT CURRENT TRIPLE IS IGNORED  28500031
         SPACE 2                                                        28560031
LA0010   STM   LR,P,LASAVE             SC1. SAVE REGISTERS              28620031
         SR    TR,TR                   SET RESULT REGISTER TO ZERO AND  28680031
         BC    B,LA1002              ENTER SCANNING LOOP                28740031
         SPACE 3                                                        28800031
*              COMMON RETURN SECTION                                    28860031
         SPACE 1                                                        28920031
LA1020   BAL   LR,LA0007               GO TO TEST FOR USER EXIT OR      28980031
*                                    CONTINUE SCAN.                     29040031
         SPACE 1                                                        29100031
*              SCANNING LOOP                                            29160031
LA1001   LA    IP,5(0,IP)              SCAN TO NEXT TRIPLE              29220031
LA1002   TRT   0(1,IP),SCTRT           TEST TRIPLE CODE AND SCAN TO     29280031
         BC    BZ,LA1001             NEXT IF NOT OF INTEREST            29340031
         SPACE 2                                                        29400031
*              A TRIPLE HAS BEEN FOUND WHICH IS OF INTEREST TO SCAN,    29460031
*        THE USER, OR BOTH. MOVE ALL THE 5 BYTE TRIPLES WHICH HAVE      29520031
*        JUST BEEN PASSED OVER AND THEN PERFORM WHATEVER ACTION IS      29580031
*        INDICATED BY THE TRANSLATED VALUE IN TR.                       29640031
         SPACE 1                                                        29700031
         L     GRA,IPSAVE              THE START OF TEXT TO BE MOVE     29760031
         LR    GRB,IP                IS IN IP SAVE AND THE LENGTH IS    29820031
         SR    GRB,GRA               THE DIFFERENCE BETWEEN IP AND      29880031
         BAL   LR2,UT03              IPSAVE. IT IS CONTIGUOUS SO USE    29940031
*                                    INTERNAL MOVE TRIPLES ROUTINE.     30000031
         SPACE 1                                                        30060031
*              NOW TEST RESULT REGISTER AND BRANCH TO APPROPRIATE       30120031
*        ACTION SECTION.                                                30180031
         SPACE 1                                                        30240031
         CH    TR,H36                                                   30300031
         BC    BL,LA1010(TR)           BRANCH ON VALUES 4-32            30360031
         CH    TR,H72                                                   30420031
         BC    BNH,LA1010-36(TR)       BRANCH ON VALUES 36-72           30480031
         BC    B,LA0008                USER VALUE (GREATER THAN 72) GO  30540031
*                                    TO RESTORE AND RETURN TO USER      30600031
         SPACE 1                                                        30660031
*              BRANCH TABLE FOR SPECIAL SCAN ACTIONS                    30720031
         SPACE 1                                                        30780031
LA1010   BC    B,LA0013                36    EOB OR ERROR               30840031
         BC    B,LA0014                4,40  FORMAT                     30900031
         BC    B,LA0015                8,44  FORMAT'                    30960031
         BC    B,LA0016                12,48 PROC                       31020031
         BC    B,LA0016                16,52 BEGIN                      31080031
         BC    B,LA0016                20,56 PROC'                      31140031
         BC    B,LA0016                24,60 BEGIN'                     31200031
         BC    B,LA0017                28,64 JUMP                       31260031
         BC    B,LA0018                32,68 SN, SL, SN2, CN            31320031
         BC    B,LA0019                72    EOP2                       31380031
         EJECT                                                          31440031
*              END-OF-BLOCK MARKER OR ERROR                             31500031
         SPACE 1                                                        31560031
*              THIS SECTION IS ENTERED FOR EOB OR ERROR TRIPLES. IF     31620031
*        ERROR A TERMINAL DIAGNOSTIC IS PRODUCED. IF END-OF-BLOCK THE   31680031
*        NEXT INPUT BLOCK IS BROUGHT IN.                                31740031
         SPACE 1                                                        31800031
LA0013   CLI   0(IP),FEOB              TEST FOR EOB AND GO TO ERROR     31860031
         BC    BNE,LA0080            SECTION IF NOT.                    31920031
         SPACE 1                                                        31980031
         BAL   LR1,UT01B               EOB. USE EOB ROUTINE TO CALL     32040031
         BC    B,LA1808              IN NEXT BLOCK THEN RESUME SCANNING 32100031
*                                    AFTER SETTING IPSAVE TO THE NEW    32160031
*                                    START OF SCAN POSITION             32220031
         EJECT                                                          32280031
*              FORMAT TRIPLE                                            32340031
         SPACE 1                                                        32400031
*              THIS SECTION IS ENTERED FOR FORMAT TRIPLES. THE          32460031
*        WORKSPACE COUNT AND WORKSPACE REF ENTRIES IN THE SCAN          32520031
*        PARAMETER BLOCK ARE CHANGED TO THE APPROPRIATE VALUES          32580031
*        FOR REMOTE FORMATS.                                            32640031
         SPACE 1                                                        32700031
LA0014   MVC   SCWKS(2),WKFMT          SET COUNT                        32760031
         MVC   SCWSDR(2),WKFREF        SET REF                          32820031
         BC    B,LA1020                GO TO TEST FOR USER RETURN       32880031
*                                    OR CONTINUE SCANNING               32940031
         SPACE 3                                                        33000031
*              FORMAT' TRIPLE                                           33060031
         SPACE 1                                                        33120031
*              THIS SECTION IS ENTERED FOR FORMAT' TRIPLES. THE         33180031
*        CURRENT WORKSPACE COUNT IS COPIED INTO THE RUNNING TOTAL OF    33240031
*        REMOTE FORMAT WORKSPACE FOR THIS BLOCK AND THE COUNT AND       33300031
*        REFERENCE PARAMETER BLOCK SLOTS RESTORED FOR WORKSPACE 1       33360031
         SPACE 1                                                        33420031
LA0015   MVC   WKFMT(2),SCWKS          SAVE RUNNING TOTAL               33480031
         XC    SCWKS(2),SCWKS          SET NORMAL COUNT TO ZERO         33540031
         BC    B,LA1602                RESTORE WORKSPACE 1 REF THEN GO  33600031
*                                    TO TEST FOR USER RETURN OR         33660031
*                                    CONTINUE SCANNING.                 33720031
         EJECT                                                          33780031
*              BLOCK TRIPLES                                            33840031
         SPACE 1                                                        33900031
*              THIS SECTION IS ENTERED FOR PROC, BEGIN, PROC' AND       33960031
*        BEGIN' TRIPLES. IF A BLOCK IS ABOUT TO BE LEFT (I.E. FOR       34020031
*        OTHER THAN THE FIRST PROC) THE FORMAT WORKSPACE FOR THAT       34080031
*        BLOCK IS UPDATED IF THE COUNT IS NON-ZERO. THE REFERENCE       34140031
*        OF THE NEW BLOCK, AND THE REFERENCES AND COUNTS OF THE         34200031
*        TWO TYPES OF WORKSPACE OBTAINED.                               34260031
         SPACE 1                                                        34320031
LA0016   CLC   WKFMT(2),H0             TEST FOR ZERO FORMAT WORKSPACE   34380031
         BC    BE,LA1601             COUNT                              34440031
         SPACE 1                                                        34500031
         LA    GRA,WKFREF              NON-ZERO SO ACCESS FORMAT        34560031
         BAL   LR2,UT07              WORKSPACE ENTRY AND COPY COUNT     34620031
         MVC   EWKSC(2,GRB),WKFMT    INTO IT.                           34680031
         SPACE 1                                                        34740031
LA1601   MVC   SCBLK(2),3(IP)          COPY REFERENCE OF NEW BLOCK      34800031
         CLC   SCBLK(2),H0           INTO SCBLK AND ACCESS ENTRY        34860031
         BC    BE,LA1020             UNLESS ZERO (IE JUST LEAVING       34920031
*                                    OUTERMOST BLOCK                    34980031
         SPACE 1                                                        35040031
         LA    GRA,SCBLK               POINT GRA AT REF, RETURN WITH    35100031
         BAL   LR2,UT07              GRB ADDRESSING ENTRY TYPE 1        35160031
         MVC   WKSREF(2),EWSREF(GRB)   SET UP THE INTERNAL WORKSPACE    35220031
         MVC   WKFREF(2),EWFREF(GRB) REFERENCE SLOTS.                   35280031
         LA    GRA,EWFREF(0,GRB)                                        35340031
         BAL   LR2,UT07                POINT GRB AT FORMAT WORKSPACE    35400031
         MVC   WKFMT(2),EWKSC(GRB)   ENTRY AND EXTRACT COUNT            35460031
         SPACE 1                                                        35520031
LA1602   MVC   SCWSDR(2),WKSREF        ENTRY FROM FORMAT'. PLACE THE    35580031
         BC    B,LA1020              WORKSPACE 1 REF IN SCWSDR, THEN    35640031
*                                    GO TO TEST FOR USER RETURN.        35700031
         EJECT                                                          35760031
*              JUMP TRIPLE                                              35820031
         SPACE 1                                                        35880031
*              THIS SECTION IS ENTERED FOR JUMP TRIPLES. A TEST IS      35940031
*        MADE INITIALLY FOR USER RETURN, AND IF REQUESTED CONTROL       36000031
*        RETURNS AT ONCE. IN THIS RESPECT JUMP DIFFERS FROM ALL OTHER   36060031
*        SPECIAL SCAN TRIPLES, SINCE IN OTHER CASES THE SCAN ACTION     36120031
*        IS PERFORMED IN ANY CASE BEFORE RETURNING.                     36180031
*              IF NOT A USER EXIT THE INTERNAL SC9 ROUTINE (UT08) IS    36240031
*        USED TO MOVE THE PSEUDO CODE BLOCK TO OUTPUT. ON RETURN IP     36300031
*        ADDRESSES THE NEXT TRIPLE AFTER THE PSEUDO CODE BLOCK,         36360031
*        EXCLUDING EOB TRIPLES.                                         36420031
         SPACE 1                                                        36480031
LA0017   BAL   LR,LA0007               IF USER EXIT GO STRAIGHT TO      36540031
*                                    RETURN SECTION                     36600031
         SPACE 1                                                        36660031
         BAL   LR,UT08                 OTHERWISE USE INTERNAL SC9 TO    36720031
         BC    B,LA1808              MOVE PSEUDO-CODE, THEN RESUME      36780031
*                                    SCAN FROM NEXT TRIPLE              36840031
         EJECT                                                          36900031
*              STATEMENT TRIPLES                                        36960031
         SPACE 1                                                        37020031
*              THIS SECTION IS ENTERED FOR SN, SL, SN2 AND CN TRIPLES   37080031
*        EACH OF THESE TRIPLES MAY BE 5 OR 7 BYTES LONG, 5 ONLY FOR     37140031
*        THE FIRST PSEUDO CODE PHASE. THE LAST 2 BYTES OF THE 7 BYTE    37200031
*        FORM CONTAIN THE WORKSPACE COUNT.                              37260031
*              A TEST IS MADE TO SEE IF THE WORKSPACE COUNT FOR THE     37320031
*        PREVIOUS STATEMENT HAS BEEN CHANGED, AND, IF SO, THE NEW       37380031
*        VALUE IS PLACED IN THE TRIPLE ADDRESSED BY SCSTAD.             37440031
*              THE NEW STATEMENT TRIPLE IS THEN MOVED TO OP AND THE     37500031
*        WORKSPACE COUNT AND STATEMENT NUMBER SLOTS UPDATED. THE        37560031
*        POSITION OF THE NEW TRIPLE IN OUTPUT IS SAVED IN SNADDR AND    37620031
*        THE PREFIX OPTION BYTE IS SET, UNLESS TRIPLE IS A CN           37680031
         SPACE 1                                                        37740031
LA0018   MVC   SCSTK(2),H0             CLEAR REGISTER STATUS BYTES      37800031
         CLC   SCWKS(2),WKPREV         TEST AND BRANCH IF WORKSPACE     37860031
         BC    BE,LA1802             COUNT UNCHANGED FROM INITIAL VALUE 37920031
         SPACE 1                                                        37980031
*              WORKSPACE COUNT CHANGED. FIND ADDRESS OF PREVIOUS        38040031
*        STATEMENT TRIPLE.                                              38100031
         L     OP,SCSTAD               PICK UP ADDRESS AND BRANCH IF    38160031
         TM    FLAG,SNSYM            ABSOLUTE                           38220031
         BC    BZ,LA1801                                                38280031
         SPACE 1                                                        38340031
         BAL   LR1,UT11                ADDRESS IS SYMBOLIC. CONVERT     38400031
*                                    TO ABSOLUTE IN OP LEAVING BLOCK    38460031
*                                    STATUS UNCHANGED                   38520031
         SPACE 1                                                        38580031
LA1801   MVC   5(2,OP),SCWKS           ADDRESS IS ABSOLUTE, JUST MOVE   38640031
*                                    IN UPDATED WORKSPACE COUNT         38700031
         SPACE 2                                                        38760031
*              NOW UPDATE STATEMENT NUMBER SLOT                         38820031
         SPACE 1                                                        38880031
LA1802   CLI   0(IP),FCN               IF CN NO NEED TO UPDATE PREFIX   38940031
         BC    BE,LA1807             OPTION OR STATEMENT NUMBER         39000031
         SPACE 1                                                        39060031
         LA    GRA,3(0,IP)             POINT GRA AT SECOND OPERAND      39120031
         CLI   0(IP),FSN               TEST FOR STATEMENT NUMBER AND    39180031
         BC    BE,LA1804             BRANCH IF IT IS                    39240031
         SPACE 1                                                        39300031
         BAL   LR2,UT07                NOT SN SO SECOND OPERAND IS      39360031
         LA    GRA,ESN2N(0,GRB)      DICT ENTRY. POINT GRB AT ENTRY     39420031
*                                    AND GRA AT SN IF SN2 ENTRY         39480031
         CLI   0(IP),FSL               TEST FOR STATEMENT LABEL         39540031
         BC    BNE,LA1804            BRANCH IF SN2.                     39600031
         SPACE 1                                                        39660031
         TM    0(GRB),DCL              SL. TEST FIRST FOR LABEL ENTRY   39720031
         BC    BM,LA1806             NOT ENTRY TYPE 1. IF NOT LABEL     39780031
*                                    DO NOT LOOK FOR A NEW STATEMENT    39840031
*                                    NUMBER.                            39900031
         LA    GRA,ESLN(0,GRB)         POINT GRA AT SN SLOT THEN TEST   39960031
         TM    ESLOT1(GRB),X'20'     FOR LABEL IN CHECK LIST. IF NOT    40020031
         BC    BZ,LA1804             THEN GRA IS POINTING  AT NUMBER    40080031
         SPACE 1                                                        40140031
         BAL   LR2,UT07                IF IN CHECK LIST ACCESS CHECK    40200031
         LA    GRA,ESN2N(0,GRB)        GET ST NO.FROM BCD ENTRY.   0222 40260031
*                                    THAT ENTRY.                        40320031
LA1804   MVC   ZSTAT+2(2),0(GRA)       MOVE STATEMENT NUMBER            40380031
LA1806   MVC   SCOPT(1),2(IP)          UPDATE PREFIX OPTION CODE        40440031
         SPACE 1                                                        40500031
*              NOW COPY STATEMENT TRIPLE INTO OUTPUT TEXT               40560031
         SPACE 1                                                        40620031
LA1807   LH    GRB,SNLNTH              GET INPUT STATEMENT TRIPLE       40680031
*                                    LENGTH AND MOVE INTO SKELETON.     40740031
         EX    GRB,LA1810            THIS PERMITS A ZERO WORKSPACE      40800031
         MVC   SCWKS(2),WKPREV       COUNT TO BE APPENDED FOR FIRST     40860031
         LA    IP,1(GRB,IP)          PASS. UPDATE SCWKS AND IP.         40920031
         SPACE 1                                                        40980031
         LA    GRB,7                   PUT 7 BYTE TRIPLE INTO OUTPUT    41040031
         LA    GRA,STTRIP                                               41100031
         BAL   LR2,UT03                                                 41160031
         SPACE 1                                                        41220031
         L     GRA,ZPCOP               COMPUTE POSITION OF TRIPLE IN    41280031
         SH    GRA,H7                OUTPUT (THIS IS DONE AFTER PUTTING 41340031
         ST    GRA,SCSTAD            IT OUT IN CASE IT WAS NECESSARY    41400031
         NI    FLAG,NSNSYM           TO START A NEW O/P BLOCK) ANDSET   41460031
*                                    FLAG TO ABSOLUTE                   41520031
*              NOW RETURN EITHER TO CONTINUE SCANNING OR TO THE USER.   41580031
         SPACE 1                                                        41640031
LA1808   BAL   LR,LA0007               CHECK FOR USER EXIT AND IF SO    41700031
         BC    B,LA1002              RETURN, OTHERWISE RESUME SCAN      41760031
         SPACE 1                                                        41820031
LA1810   MVC   STTRIP(0),0(IP)         COPY STATEMENT TRIPLE            41880031
         EJECT                                                          41940031
*              END-OF-PROGRAM MARKER                                    42000031
         SPACE 1                                                        42060031
*              THIS SECTION IS ENTERED AT END OF PROGRAM. THE CURRENT   42120031
*        INPUT AND OUTPUT TEXT BLOCKS ARE SET FREE AND NOT-WANTED       42180031
*        RESPECTIVELY AFTER COPYING THE EOP2 ACROSS                     42240031
         SPACE 1                                                        42300031
LA0019   BAL   LR2,UT03A               COPY EOP2                        42360031
         SPACE 1                                                        42420031
         MVC   PAR1+1(1),SCTXTI+1      FREE INPUT TEXT BLOCK            42480031
         MVI   PAR2+3,X'01'                                             42540031
         L     BR,ZALTER                                                42600031
         BALR  LR,BR                                                    42660031
         SPACE 1                                                        42720031
         MVC   PAR1+1(1),SCTXTO+1      MARK OUTPUT BLOCK NOT WANTED     42780031
         MVI   PAR2+3,X'02'                                             42840031
         L     BR,ZALTER                                                42900031
         BALR  LR,BR                                                    42960031
         SPACE 1                                                        43020031
         MVI   SNLNTH+1,6              SET INPUT STATEMENT TRIPLE       43080031
         BC    B,LA0008              LENGTH TO 7. RETURN TO USER        43140031
         EJECT                                                          43200031
*              SCANNING ROUTINES SC4 AND SC5                            43260031
         SPACE 1                                                        43320031
*              ON ENTRY IP ADDRESSES A TRIPLE WHICH IS TO BE SKIPPED,   43380031
*        MARKING THE TEXT WANTED (SC4) OR FREE (SC5).                   43440031
         SPACE 1                                                        43500031
LA0020   MVI   MARKER,X'03'            SC4. SET MARKER TO WANTED.       43560031
         SPACE 1                                                        43620031
LA0021   STM   LR,P,LASAVE             SC5. STORE REGISTERS             43680031
LA2101   LA    IP,5(0,IP)              UPDATE POINTER TO NEXT TRIPLE    43740031
         BC    B,LA0008              THEN RETURN (THE RETURN SECTION    43800031
*                                    INCLUDES AN END OF BLOCK TEST      43860031
         EJECT                                                          43920031
*              SCANNING ROUTINES SC6 AND SC7                            43980031
         SPACE 1                                                        44040031
*              ON ENTRY IP ADDRESSES A TRIPLE WHICH IS TO BE MOVED      44100031
*        TO THE OUTPUT STRING. THE INPUT TEXT IS MARKED WANTED (SC6)    44160031
*        OR FREE (SC7).                                                 44220031
         SPACE 1                                                        44280031
LA0025   MVI   MARKER,X'03'            SC6. SET MARKER TO WANTED        44340031
         SPACE 1                                                        44400031
LA0026   STM   LR,P,LASAVE             SC7. STORE REGISTERS             44460031
         CLC   H5,SNLNTH                IS THIS 1ST ENTRY TO SCAN IN    44520031
*                                        OPTIMISING PHASES (IE FROM KU) 44580031
         BC    BH,LAOPTM                BRANCH IF IT IS.                44640031
LA0027   BAL   LR2,UT03A                MOVE CURRENT TRIPLE TO OUTPUT.  44700031
         BC    B,LA2101              THEN GO TO UPDATE INPUT POINTER    44760031
*                                    AND RETURN                         44820031
LAOPTM   CLI   0(IP),X'D0'              IS THIS A STATEMENT NO TRIPLE.  44880031
         BC    BE,LASTMT                IF IT IS SET RETURN VALUE AND   44940031
*                                        EXPAND STATEMENT NO. TRIPLE.   45000031
         CLI   0(IP),X'BC'              IS THIS AN SN2 TRIPLE.          45060031
         BC    BE,LASTMT                IF IT IS SET RETURN VALUE       45120031
         CLI   0(IP),X'D4'              IS THIS AN CN TRIPLE.           45180031
         BC    BE,LASTMT                IF IT IS SET RETURN VALUE.      45240031
         CLI   0(IP),X'D2'              IS IT A STATEMENT LABEL TRIPLE. 45300031
         BC    BNE,LA0027              IF NOT CONTINUE NORMALLY         45360031
LASTMT   LH    TR,H72                   OTHERWISE SET USER RETURN VALUE 45420031
         B     LA0018                    AND EXPAND STNO TRIPLE TO      45480031
*                                        7 BYTES LENGTH.                45540031
         EJECT                                                          45600031
*              SCANNING ROUTINES SC8 AND SC9.                           45660031
         SPACE 1                                                        45720031
*              ON ENTRY IP ADDRESSES A JUMP TRIPLE. THE PSEUDO-CODE IS  45780031
*        TO BE MOVED TO THE OUTPUT BLOCK AND THE INPUT MARKED WANTED    45840031
*        (SC8) OR FREE (SC9).                                           45900031
         SPACE 1                                                        45960031
LA0030   MVI   MARKER,X'03'            SC8. SET MARKER TO WANTED        46020031
         SPACE 1                                                        46080031
LA0031   STM   LR,P,LASAVE             SC9. SAVE REGISTERS              46140031
LA3101   BAL   LR,UT08                 USE INTERNAL SC9 ROUTINE TO      46200031
*                                    MOVE PSEUDO AND UPDATE IP.         46260031
         BAL   LR1,UT01C               NOW CHECK FOR END-OF BLOCK AND   46320031
         CLI   0(IP),FJUMP           IF SO UPDATE TO NEXT TRIPLE. IF    46380031
         BC    BE,LA3101             THE NEXT TRIPLE IS A JUMP GO BACK  46440031
         BC    B,LA0009              TO MOVE THAT TOO. RETURN IF NOT    46500031
         EJECT                                                          46560031
*              SCANNING ROUTINE SC10                                    46620031
         SPACE 1                                                        46680031
*              PAR1 CONTAINS A SYMBOLIC ADDRESS WHICH IS TO BE USED AS  46740031
*        A NEW STARTING POINT FOR SCANNING INPUT TEXT.                  46800031
         SPACE 1                                                        46860031
LA0035   STM   LR,P,LASAVE             SAVE REGISTERS                   46920031
         L     IP,PAR1                 PICK UP SYMBOLIC ADDRESS AND     46980031
         BAL   LR1,UT01A             CONVERT TO ABSOLUTE.               47040031
         BC    B,LA0008                                                 47100031
         EJECT                                                          47160031
*              SCANNING POUTINES SC11 AND SC12                          47220031
         SPACE 1                                                        47280031
*              IP ADDRESSES A JUMP TRIPLE. THE INPUT POINTER IS         47340031
*        UPDATED TO ADDRESS THE TRIPLE FOLLOWING THE PSEUDO-CODE. THE   47400031
*        PSEUDO-CODE IS NOT MOVED AND THE TEXT IN THE INPUT IS MARKED   47460031
*        WANTED (SC11) OR FREE (SC12).                                  47520031
         SPACE 1                                                        47580031
LA0040   MVI   MARKER,X'03'            SET MARKER TO 'WANTED'           47640031
LA0041   STM   LR,P,LASAVE             SAVE REGISTERS                   47700031
         SPACE 1                                                        47760031
LA4001   MVC   HTEMP(2),1(IP)          UPDATE INPUT POINTER TO TRIPLE   47820031
         AH    IP,HTEMP              FOLLOWING JUMP, THEN CHECK FOR     47880031
         LA    IP,2(0,IP)            EOB.                               47940031
         BAL   LR1,UT01C                                                48000031
         SPACE 1                                                        48060031
         CLI   0(IP),FJUMP             TEST FOR ANOTHER JUMP (WHICH     48120031
         BC    BE,LA4001             MAY HAVE FOLLOWED EOB AND RETURN   48180031
         BC    B,LA0009              IF NOT, OTHERWISE UPDATE IP        48240031
*                                    AGAIN.                             48300031
         EJECT                                                          48360031
*              MOVING ROUTINE MV2                                       48420031
         SPACE 1                                                        48480031
*              THIS ROUTINE IS USED TO MOVE USER GENERATED PSEUDO-CODE  48540031
*        INTO THE OUTPUT TEXT. IT DIFFERS FROM MV3 ONLY IN THAT THE     48600031
*        CODE IS ALWAYS MOVED INTO A CONTIGUOUS AREA IN THE OUTPUT      48660031
*        TEXT BLOCK. IF THERE IS NOT ENOUGH ROOM IN THE CURRENT BLOCK   48720031
*        AN EOB MARKER IS INSERTED AND A NEW BLOCK STARTED.             48780031
         SPACE 1                                                        48840031
LA0050   STM   LR,P,LASAVE             SAVE REGISTERS                   48900031
         L     OP,ZPCOP                PICK UP CURRENT OUTPUT POINTER   48960031
         L     BR,SCEOBO             AND CALCULATE THE EXCESS OF THE    49020031
         SR    BR,OP                 NUMBER OF BYTES LEFT IN THE        49080031
         S     BR,PAR2               BLOCK OVER THE GIVEN CODE LENGTH   49140031
         CH    BR,H5                   IF THIS IS SUFFICIENT FOR A      49200031
         BC    BNL,LA5502            JUMP TRIPLE (THE WORST CASE - A    49260031
*                                    JUMP MAY NOT BE NEEDED IF A CODE   49320031
*                                    BLOCK IS ALREADY OPEN) GO STRAIGHT 49380031
*                                    TO NORMAL MV3 PROCEDURE.           49440031
         ST    OP,SCEOBO               OTHERWISE SET SCEOBO EQUAL TO    49500031
         BC    B,LA5502              OP SO AS TO FORCE CHAINING TO A    49560031
*                                    NEW BLOCK, THEN GO TO MV3          49620031
         EJECT                                                          49680031
*              MOVING ROUTINE MV3                                       49740031
         SPACE 1                                                        49800031
*              THIS ROUTINE IS USED TO MOVE USER GENERATED PSEUDO-CODE  49860031
*        INTO THE OUTPUT TEXT.                                          49920031
         SPACE 1                                                        49980031
LA0055   STM   LR,P,LASAVE             SAVE REGISTERS                   50040031
LA5502   LA    BR,UT04                 POINT BR AT UT04                 50100031
LA5501   L     GRA,PAR1                POINT GRA AT PSEUDO-CODE AND     50160031
         L     GRB,PAR2              SET LENGTH IN GRB, THEN CALL       50220031
         BALR  LR2,BR                INTERNAL MOVING ROUTINE            50280031
         BC    B,LA0009                RETURN                           50340031
         EJECT                                                          50400031
*              MOVING ROUTINE MV3A                                      50460031
         SPACE 1                                                        50520031
*              THIS ROUTINE IS USED TO MOVE USER GENERATED TRIPLES      50580031
*        INTO  THE OUTPUT TEXT.                                         50640031
         SPACE 1                                                        50700031
LA0056   STM   LR,P,LASAVE             SAVE REGISTERS                   50760031
         LA    BR,UT03                 POINT BR AT UT03, THEN GO TO     50820031
         BC    B,LA5501              MOVE TEXT                          50880031
         EJECT                                                          50940031
*              DOPE VECTOR CONSTRUCTION ROUTINE                         51000031
         SPACE 1                                                        51060031
*              THIS ROUTINE IS USED TO CONSTRUCT, IN WORKSPACE, A       51120031
*        DOPE VECTOR FOR A BASED STRUCTURE.                             51180031
         SPACE 1                                                        51240031
LA0070   STM   LR,P,DVSAVE             SAVE REGISTERS                   51300031
         LA    GR0,3                                                    51360031
         BAL   LR,UT09                 ROUND UP TO WORD BOUNDARY        51420031
         MVC   PS014(2),SCWKS                                           51480031
         MVC   PS044(2),PAR1           SET POINTER REF (IF PRESENT)     51540031
         MVC   PS013(2),PAR1+2         COPY DICT REF OF VARIABLE        51600031
         MVI   PS03,0                  SET FIRST TIME SWITCH FOR LOAD   51660031
         SPACE 1                                                        51720031
         MVC   PS012(2),SCWSDR         SET CURRENT WORKSPACE DICT REF   51780031
         MVC   PS052(2),SCWSDR       IN ALL SKELETONS                   51840031
         MVC   PS046(2),SCWSDR                                          51900031
         SPACE 1                                                        51960031
         LA    LR1,PS01                GENERATE MVC TO COPY DOPE VECTOR 52020031
         LA    LR2,PS01L             SKELETON INTO WORKSPACE            52080031
         BAL   LR,UT06                                                  52140031
         SPACE 1                                                        52200031
         LCR   BR,LR2                  SET BR TO POINT TO MVC INSTRN    52260031
         A     BR,ZPCOP              IN OUTPUT AND CONVERT ADDRESS TO   52320031
         BAL   LR,UT12               SYMBOLIC.                          52380031
         MVC   DVSTXT(4),PAR1                                           52440031
         MVI   DVLEVL,0              SET STRUCTURE LEVEL NUMBER TO ZERO 52500031
         SPACE 1                                                        52560031
         LA    GRA,PS013               POINT GRA AT DICT REF READY TO   52620031
*                                    ENTER MAIN LOOP                    52680031
         SPACE 1                                                        52740031
*              THIS IS THE MAIN STRUCTURE SCANNING LOOP. THE WHOLE      52800031
*        MINOR STRUCTURE DEFINED BY THE ARGUMENT DICT REF IS EXAMINED   52860031
*        AND CODE GENERATED TO FILL IN ANY ADJUSTABLE EXTENTS           52920031
         SPACE 1                                                        52980031
LA7002   MVC   PS042(2),0(GRA)         SET DICT REF IN LOAD IN CASE     53040031
*                                    RELOCATION REQUIRED                53100031
         BAL   LR2,UT07                GRB NOW ADDRESSES NEXT ENTRY     53160031
         LR    IP,GRB                  POINT IP AT ENTRY. IP RETAINS    53220031
*                                    THIS VALUE UNTIL NEXT CYCLE OF     53280031
*                                    THE LOOP.                          53340031
         OI    ESLOT3(IP),X'80'        SET DOPE VECTOR REQUIRED         53400031
         LA    GRA,EDAVAR(0,IP)        POINT GRA AT THE START OF THE    53460031
         TM    0(IP),X'0F'           VARIABLE INFORMATION (THIS IS      53520031
         BC    BO,LA7003             DIFFERENT FOR DATA VARIABLES FROM  53580031
         LA    GRA,ESTVAR(0,IP)      ALL OTHERS)                        53640031
         SPACE 1                                                        53700031
LA7003   TM    ESLVAR(IP),X'80'        TEST FOR DIMENSIONED AND IF      53760031
         BC    BZ,LA7004             OFFSET 2 PRESENT ADD 4             53820031
         MVC   PS032(2),2(GRA)         COPY POSSIBLE EXTENT VARIABLE    53880031
*                                    REFERENCE.                         53940031
         LA    GRA,4(0,GRA)                                             54000031
         SPACE 1                                                        54060031
LA7004   LR    TR,GRA                  GRA ADDRESSES FIRST VARIABLE     54120031
         TM    ESLVAR(IP),X'40'      INFORMATION AFTER OFFSET 2. NOW    54180031
         BC    BZ,LA7005             SET TR TO ADDRESS FIRST VARIABLE   54240031
         LA    TR,3(0,TR)            INFORMATION AFTER DIMENSIONED      54300031
         SPACE 1                                                        54360031
*              NOW IP ADDRESSES ENTRY, GRA ADDRESSES DIMENSION SLOT,    54420031
*        IF ANY, AND TR ADDRESSES STRUCTURE SLOT IF ANY.                54480031
         SPACE 1                                                        54540031
LA7005   TM    ESLVAR(IP),X'20'        TEST FOR STRUCTURE MEMBER AND    54600031
         BC    BZ,LA7009             BRANCH IF NOT.                     54660031
         SPACE 1                                                        54720031
*              ENTRY IS STRUCTURE MEMBER. IF THIS IS THE FIRST TIME     54780031
*        THROUGH SAVE.THE LOGICAL LEVEL NUMBER. OTHERWISE TEST AGAINST  54840031
*        THIS LEVEL TO SEE IF THE WHOLE OF THE SPECIFIED MINOR          54900031
*        STRUCTURE HAS BEEN PROCESSED.                                  54960031
         SPACE 1                                                        55020031
         CLI   DVLEVL,0                DVLEVL IS ZERO IF FIRST ENTRY    55080031
         BC    BE,LA7007                                                55140031
         CLC   DVLEVL(1),1(TR)         NOT FIRST. COMPARE WITH ORIGINAL 55200031
         BC    BNL,LA7020            AND GO TO END IF NOT LESS.         55260031
         BC    B,LA7008                                                 55320031
         SPACE 1                                                        55380031
LA7007   MVC   DVLEVL(1),1(TR)         FIRST. SET ORIGINAL LEVEL        55440031
         SPACE 1                                                        55500031
LA7008   TM    0(IP),X'0F'             TEST FOR NON-BASE ELEMENT AND    55560031
         BC    BO,LA7009             FOR SUCH ENTRIES SIMPLY CHAIN TO   55620031
         TM    0(IP),X'0E'           THE NEXT STRUCTURE MEMBER.         55680031
         BC    BO,LA7012                                                55740031
         SPACE 2                                                        55800031
*              DICTIONARY ENTRY IS SCALAR, ARRAY, OR BASE ELEMENT OF    55860031
*        STRUCTURE. CHECK FIRST FOR DIMENSION AND LOOK FOR ADJUSTABLE   55920031
*        BOUND.                                                         55980031
LA7009   CLI   PS044,0                 TEST IF RELOCATION CODE REQUIRED 56040031
         BC    BE,LA7014             BRANCH IF NOT                      56100031
         SPACE 1                                                        56160031
         MVC   PS047(2),SCWKS          SET WORKSPACE OFFSET AND DOPE    56220031
         OI    PS042+1,X'01'         VECTOR BIT                         56280031
         LA    LR1,PS04                                                 56340031
         LA    LR2,PS04L+PS06L                                          56400031
         BAL   LR,UT06                 GENERATE L,A,ST,DROP             56460031
         SPACE 1                                                        56520031
LA7014   LA    GR0,4                   UPDATE WORKSPACE CONUT BY 4 TO   56580031
         BAL   LR,UT09               ALLOW FOR VIRTUAL ORIGIN OR        56640031
*                                    ELEMENT ADDRESS                    56700031
         CR    GRA,TR                  IF GRA=TR THEN THERE IS NO       56760031
         BC    BE,LA7010             DIMENSION SLOT                     56820031
         SPACE 1                                                        56880031
         IC    GR0,0(0,GRA)            IF DIMENSIONED PICK UP NUMBER    56940031
         SLL   GR0,2                 OF DIMENSIONS AND ADD 4 TIMES      57000031
         BAL   LR,UT09               THIS TO WORKSPACE OFFSET SO THAT   57060031
*                                    THIS NOW ADDRESSES FIRST UPPER     57120031
*                                    BOUND.                             57180031
         LA    GRA,1(0,GRA)            GET ADDRESS OF DIMENSION TABLE   57240031
         BAL   LR2,UT07              ENTRY.                             57300031
         TM    16(GRB),X'FF'           TEST FOR ADJUSTABLE BOUND        57360031
         BC    BZ,LA7006                                                57420031
         SPACE 1                                                        57480031
         MVC   REFERS(2),18(GRB)       ADJUSTABLE. COPY REF INTO REFERS 57540031
         BAL   LR,UT10               THEN GENERATE LOAD (IF NECESSARY)  57600031
*                                    AND STH.                           57660031
LA7006   BAL   LR,UT09                 UPDATE WORKSPACE COUNT BY A      57720031
*                                    FURTHER 4*DIMENSION NUMBER         57780031
         SPACE 1                                                        57840031
*              NOW CHECK WHETHER ELEMENT IS A STRING OR AREA AND IF     57900031
*        SO CHECK FOR ADJUSTABILITY AND ADD 4 TO WORKSPACE COUNT.       57960031
         SPACE 1                                                        58020031
LA7010   TM    0(IP),X'0F'             TEST FOR STRING OR AREA DATA     58080031
         BC    BNO,LA7011            VARIABLE AND BRANCH IF NEITHER     58140031
         TM    EDADAT(IP),X'80'                                         58200031
         BC    BNZ,LA7011                                               58260031
         SPACE 1                                                        58320031
         TM    EDADAT(IP),X'40'        BRANCH IF EXTENT IS CONSTANT     58380031
         BC    BZ,LA7013                                                58440031
         SPACE 1                                                        58500031
         MVC   REFERS(2),EDADAT+1(IP)  FOR ADJUSTABLE EXTENT CASE       58560031
         BAL   LR,UT10               GENERATE LOAD (IF NECESSARY) AND   58620031
         OI    SCWKS+1,X'02'         TWO STH FOR MAX AND CURRENT        58680031
         BAL   LR,UT10               LENGTHS                            58740031
         SPACE 1                                                        58800031
LA7013   LA    GR0,4                   ADD FOUR TO WORKSPACE COUNT (THE 58860031
         BAL   LR,UT09               2 IS LOST IN THE ROUND DOWN)       58920031
         SPACE 1                                                        58980031
*              GENERATION OF CODE FOR THIS ELEMENT IS NOW COMPLETE.     59040031
*        CHECK FOR CONTINUATION OF LOOP OR EXIT.                        59100031
         SPACE 1                                                        59160031
LA7011   TM    ESLVAR(IP),X'20'        IF NOT STRUCTURE MEMBER,EXIT     59220031
         BC    BZ,LA7020                                                59280031
         TM    ESLOT1(IP),X'08'        IF LAST MEMBER OF STRUCTURE,     59340031
         BC    BO,LA7020             EXIT                               59400031
LA7012   LA    GRA,4(0,TR)             OTHERWISE POINT GRA AT NEXT      59460031
         BC    B,LA7002              MEMBER REF AND CONTINUE.           59520031
         SPACE 1                                                        59580031
*              GENERATION OF CODE FOR WHOLE STRUCTURE NOW COMPLETE.     59640031
*        FINALLY, FILL IN LENGTH AND DOPE VECTOR BIT IN INITIAL MVC     59700031
*        INSTRUCTION AND RETURN WORKSPACE OFFSET OF DOPE VECTOR.        59760031
         SPACE 1                                                        59820031
LA7020   CLI   PS03,0                  BEGIN BY DROPPING ANY REGISTERS  59880031
         BC    BE,LA7021             USED                               59940031
         TM    PS044+1,X'01'           IF DV1 WAS ENTERED FOR LOCATE    60000031
         BC    BNZ,LA7021            OR ALLOCATE THEN SR3 SHOULD NOT    60060031
*                                    BE DROPPED, BUT SAVED TO SET THE   60120031
*                                    REFER VARIABLE.                    60180031
         LA    LR1,PS07                IF SR3 HAS BEEN USED, DROP IT    60240031
         LA    LR2,PS07L                                                60300031
         BAL   LR,UT06                                                  60360031
         SPACE 1                                                        60420031
LA7021   L     OP,DVSTXT               ACCESS MOVE INSTRUCTION IN       60480031
         BAL   LR1,UT11              OUTPUT TEXT.                       60540031
         SPACE 1                                                        60600031
         OI    PS013+1-PS01(OP),X'01'  SET DOPE VECTOR BIT IN           60660031
*                                    STRUCTURE REF                      60720031
         MVC   PAR1+2(2),PS014         SET RETURN VALUE (DV OFFSET)     60780031
         LH    GRA,SCWKS             AND COMPUTE LENGTH                 60840031
         SH    GRA,PAR1+2                                               60900031
         BCTR  GRA,0                   LENGTH OF SKELETON - 1           60960031
         STC   GRA,PS011-PS01(0,OP)                                     61020031
         SRA   GRA,8                   REMOVE HALF LENGTH ALREADY 21124 61080031
         BZ    LA7022                  STORED BRANCH ON ZERO LEFT 21124 61140031
         STC   GRA,PS015-PS01(0,OP)    STORE HIGH ORDER HALF LENGT21124 61200031
         MVI   0(OP),X'F1'             CHANGE OP CODE TO MOVE LONG21124 61260031
LA7022   MVC   PAR2(4),DVPAR2          SET PAR2 IN CASE ENTRY WAS 21124 61320031
*                                      FOR LOCATE OR ALLOCATE.    21124 61380031
         SPACE 1                                                        61440031
         LM    LR,P,DVSAVE             RESTORE AND RETURN               61500031
         BCR   B,LR                                                     61560031
         EJECT                                                          61620031
*              ERROR EXIT.                                              61680031
         SPACE 1                                                        61740031
*              ALL ERRORS FOUND BY SCAN TERMINATE WITH MESSAGE 1200     61800031
         SPACE 1                                                        61860031
LA0080   MVC   PAR6+1(3),ERROR                                          61920031
         L     BR,ZUERR                                                 61980031
         BALR  LR,BR                   MAKE ERROR ENTRY                 62040031
         L     BR,ZABORT                                                62100031
         BALR  LR,BR                                                    62160031
         EJECT                                                          62220031
*              SUBROUTINE UT01                                          62280031
         SPACE 1                                                        62340031
*              THIS SUBROUTINE IS USED TO OBTAIN INPUT TEXT BLOCKS      62400031
*        AND SET UP THE SCAN PARAMETER SLOT SCTXTI. THERE ARE THREE     62460031
*        ENTRY POINTS -                                                 62520031
*              UT01A. IP CONTAINS SYMBOLIC TEXT REFERENCE. ON RETURN    62580031
*        IP ADDRESSES ABSOLUTE TEXT.                                    62640031
*              UT01B. OBTAINS THE TEXT BLOCK CHAINED FROM THE ONE       62700031
*        WHOSE NAME APPEARS IN SCTXTI. ON RETURN IP ADDRESSES THE       62760031
*        FIRST BYTE OF THE BLOCK.                                       62820031
*              UT01C. CHECKS FIRST FOR EOB TRIPLE IN INPUT. IF FOUND IT 62880031
*        CHAINS TO NEXT INPUT BLOCK, OTHERWISE JUST RETURNS.            62940031
*              LINK. SPECIAL LINK REGISTER LR1                          63000031
         SPACE 1                                                        63060031
UT01A    ST    IP,PAR1                 SET SYMBOLIC TEXT NAME IN PAR1   63120031
         ST    IP,SCTXTI             AND SCTXTI                         63180031
         L     BR,ZTXTAB               CONVERT TO ABSOLUTE AND SET      63240031
         BALR  LR,BR                 ABSOLUTE ADDRESS IN IP             63300031
         L     IP,PAR1                                                  63360031
         BCR   B,LR1                   RETURN                           63420031
         SPACE 2                                                        63480031
UT01C    CLI   0(IP),FEOB                                               63540031
         BCR   BNE,LR1                 NOT EOB. RETURN                  63600031
         SPACE 1                                                        63660031
UT01B    MVC   PAR1(4),SCTXTI          CHAIN FROM CURRENT INPUT BLOCK   63720031
         MVC   PAR2+3(1),MARKER      USING FREE/WANTED MARKER           63780031
         L     BR,ZCHAIN                                                63840031
         BALR  LR,BR                                                    63900031
         SPACE 1                                                        63960031
         L     IP,PAR2                 POINT IP AT START OF NEW BLOCK   64020031
         MVC   SCTXTI+1(1),PAR1+1      SET SYMBOLIC ADDRESS OF BLOCK    64080031
         SPACE 1                                                        64140031
         BCR   B,LR1                                                    64200031
         EJECT                                                          64260031
*              SUBROUTINE UT02                                          64320031
         SPACE 1                                                        64380031
*              THIS SUBROUTINE IS USED TO OBTAIN OUTPUT TEXT BLOCKS     64440031
*        AND SET UP THE SCAN PARAMETER BLOCK SLOTS FOR SCTXTO AND       64500031
*        SCEOBO. IT ALSO SETS ZPCOP (OUTPUT POINTER). THERE ARE TWO     64560031
*        ENTRY POINTS, UT02A AND UT02B.                                 64620031
*              UT02A. THE NEW OUTPUT BLOCK IS TO BE CHAINED FROM THE    64680031
*        PREVIOUS BLOCK AND THE PREVIOUS BLOCK IS MARKED NOT WANTED     64740031
*              UT02B. USED ONLY BY INITIALIZATION. A TEXT BLOCK IS      64800031
*        OBTAINED. PAR2 HAS ALREADY BEEN SET APPROPRIATELY              64860031
*              OUTPUT. PARAMETER BLOCK SET UP AND OP ADDRESSES FIRST    64920031
*        BYTE OF NEW BLOCK.                                             64980031
*              LINK. SPECIAL LINK REGISTER LR1                          65040031
         SPACE 1                                                        65100031
UT02A    MVI   0(OP),FEOB              SET END OF BLOCK MARKER IN       65160031
*                                    CURRENT OUTPUT BLOCK               65220031
         TM    FLAG,SNSYM              TEST WHETHER THE ADDRESS OF      65280031
         BC    BNZ,UT0201            THE PREVIOUS STATEMENT NUMBER IS   65340031
*                                    SYMBOLIC. IF IT IS GO STRAIGHT TO  65400031
*                                    OBTAIN NEW TEXT BLOCK              65460031
         L     BR,SCSTAD               IF ABSOLUTE CONVERT TO           65520031
         BAL   LR,UT12               SYMBOLIC.                          65580031
         MVC   SCSTAD(4),PAR1          SCSTAD NOW CONTAINS SYMBOLIC     65640031
         OI    FLAG,SNSYM            ADDRESS. SET FLAG BIT              65700031
         SPACE 1                                                        65760031
UT0201   MVC   PAR1+1(1),SCTXTO+1      GET NAME OF PREVIOUS BLOCK AND   65820031
         MVI   PAR2+3,X'82'          SET PAR2 TO INDICATE CHAIN AND     65880031
         SPACE 1                                                        65940031
UT02B    L     BR,ZUTXTC               GET NEW O/P BLOCK                66000031
         BALR  LR,BR                                                    66060031
         SPACE 1                                                        66120031
         MVC   SCTXTO+1(1),PAR1+1      SET NEW TEXT BLOCK REF FOR OP    66180031
         L     OP,PAR2                 SET ABSOLUTE OUTPUT ADDRESS IN   66240031
*                                    REGISTER OP                        66300031
         ST    OP,ZPCOP                SET OUTPUT POINTER VALUE IN      66360031
         L     GR0,ZTBSZE            COMMUNICATIONS REGION AND SET      66420031
         AR    GR0,OP                OP+ZTBSZE-3 AS END OF BLOCK        66480031
         SH    GR0,H3                ADDRESS                            66540031
         ST    GR0,SCEOBO                                               66600031
         SPACE 1                                                        66660031
         BCR   B,LR1                   RETURN                           66720031
         EJECT                                                          66780031
*              SUBROUTINE UT03                                          66840031
         SPACE 1                                                        66900031
*              THIS SUBROUTINE IS USED TO MOVE TRIPLES TO OUTPUT TEXT.  66960031
*              INPUT. A CONTIGUOUS STRING OF TRIPLE TEXT. GRA CONTAINS  67020031
*        THE ADDRESS OF THE FIRST BYTE AND GRB THE COUNT.               67080031
*              OUTPUT. TEXT HAS BEEN MOVED TO OUTPUT AND ZPCOP UPDATED. 67140031
*              IF THE OUTPUT TEXT CURRENTLY ENDS IN OPEN PSEUDO-CODE    67200031
*        THE STACK BYTES ARE APPENDED, OP UPDATED AND THE PSEUDO-CODE   67260031
*        SWITCH SET OFF. THE INPUT MAY BE ONLY A SINGLE 7 BYTE          67320031
*        STATEMENT TRIPLE OR A MULTIPLE OF 5. A CHECK IS MADE TO        67380031
*        ENSURE THAT STATEMENT TRIPLES DO NOT SPAN BLOCKS.              67440031
*              IF A NEW OUTPUT TEXT BLOCK IS REQUIRED THE PREVIOUS      67500031
*        STATEMENT NUMBER POSITION IN OUTPUT IS CONVERTED TO SYMBOLIC   67560031
*        FORM.                                                          67620031
*              A SPECIAL ENTRY UT03A IS PROVIDED TO MOVE THE CURRENT    67680031
*        INPUT TRIPLE TO THE OUTPUT.                                    67740031
*              LINK. SPECIAL LINK REGISTER LR2                          67800031
         SPACE 1                                                        67860031
UT03A    LR    GRA,IP                  TO MOVE CURRENT INPUT TRIPLE     67920031
         LA    GRB,5                 SET UP GRA AND GRB                 67980031
         SPACE 1                                                        68040031
UT03     LTR   GRB,GRB                 TEST FOR SPECIAL CASE OF ZERO    68100031
         BCR   BZ,LR2                COUNT AND RETURN IF ZERO           68160031
         SPACE 1                                                        68220031
         L     OP,ZPCOP                POINT OP AT OUTPUT               68280031
         TM    FLAG,PCODE              TEST FOR OPEN PSEUDO CODE        68340031
         BC    BZ,UT0301             GROUP, BRANCH IF NOT.              68400031
         SPACE 1                                                        68460031
         MVC   0(2,OP),SCSTK           IF OPEN PSEUDO-CODE, MOVE        68520031
         LA    OP,2(0,OP)            STACK INFORMATION INTO OUTPUT AND  68580031
         NI    FLAG,NPCODE           RESET FLAG BIT.                    68640031
         L     BR,SCJMP                GET ADDRESS OF LAST JUMP TRIPLE  68700031
         MVC   1(2,BR),SCPCG+2       AND SET LENGTH.                    68760031
         SPACE 1                                                        68820031
UT0301   L     BR,SCEOBO               GET ADDRESS OF END OF BLOCK      68880031
         SR    GR0,GR0               AND DETERMINE WHETHER THE TEXT     68940031
         SR    BR,OP                 WILL GO INTO THE CURRENT BLOCK     69000031
         CR    BR,GRB                                                   69060031
         BC    BNL,UT0302              BRANCH IF IT ALL FITS IN         69120031
         SPACE 1                                                        69180031
         CH    BR,H5                   NOT ROOM. IF LESS 5 BYTES THERE  69240031
         BC    BL,UT0303             IS NO ROOM FOR TRIPLES IN ANY      69300031
*                                    CASE.                              69360031
         CH    GRB,H7                  IF AT LEAST 5 LEFT THEN CHECK    69420031
         BC    BE,UT0302             FOR SPECIAL CASE OF STATEMENT      69480031
*                                    TRIPLE.                            69540031
         LA    GR0,5                                                    69600031
         SR    LR,LR                   OTHERWISE WORK OUT HOW MANY      69660031
         DR    LR,GR0                TRIPLES WILL GO INTO OUTPUT.       69720031
         MR    LR,GR0                                                   69780031
         LR    GR0,GRB                 SET COUNT IN GRB AND REMAINING   69840031
         LR    GRB,BR                COUNT IN GR0.                      69900031
         SR    GR0,GRB                                                  69960031
         SPACE 1                                                        70020031
UT0302   BAL   LR,UT05                 MOVE CONTIGUOUS TEXT ADDRESSED   70080031
*                                    BY GRA WITH LENGTH IN GRB. ON      70140031
*                                    RETURN GRA HAS BEEN INCREMENTED    70200031
*                                    BY GRB                             70260031
         LTR   GRB,GR0                 SET GRB TO REMAINING COUNT AND   70320031
         BCR   BZ,LR2                  IF ZERO RETURN                   70380031
         SPACE 2                                                        70440031
UT0303   BAL   LR1,UT02A               NOT END. CHAIN TO NEXT OP BLOCK  70500031
         BC    B,UT0301              AND CONTINUE MOVE                  70560031
         EJECT                                                          70620031
*              SUBROUTINE UT04                                          70680031
         SPACE 1                                                        70740031
*              THIS SUBROUTINE IS USED FOR MOVING CONTIGUOUS PSEUDO-    70800031
*        CODE  TEXT INTO OUTPUT                                         70860031
*              INPUT.  GRA ADDRESSES TEXT                               70920031
*                      GRB CONTAINS LENGTH                              70980031
*              OUTPUT. SCJMP, SCPCG, AND ZPCUP HAVE BEEN UPDATED.       71040031
*              LINK. SPECIAL LINK REGISTER LR2                          71100031
         SPACE 1                                                        71160031
UT04     L     OP,ZPCOP                PICK UP OUTPUT POINTER AND       71220031
         L     BR,SCEOBO             END OF BLOCK ADDRESS AND GET       71280031
         SR    BR,OP                 NUMBER OF BYTES LEFT               71340031
         SPACE 1                                                        71400031
         TM    FLAG,PCODE              TEST FOR PSEUDO CODE OPEN IN     71460031
         BC    BNZ,UT0403            OUTPUT AND BRANCH IF YES           71520031
         SPACE 1                                                        71580031
         CH    BR,H5                   NOT IN PSEUDO CODE. TEST FOR     71640031
         BC    BL,UT0404             ROOM FOR JUMP AND BRANCH IF NOT    71700031
         SPACE 1                                                        71760031
         MVI   0(OP),FJUMP             SET JUMP TRIPLE CODE IN OUTPUT   71820031
         ST    OP,SCJMP                SET ADDRESS OF PREVIOUS JUMP,    71880031
         LA    LR,5                  UPDATE OP AND REDUCE COUNT BY      71940031
         AR    OP,LR                 FIVE.                              72000031
         SR    BR,LR                                                    72060031
         OI    FLAG,PCODE              SET OPEN BLOCK FLAG AND          72120031
         ST    LR,SCPCG              INITIALIZE JUMP COUNT TO 5.        72180031
         SPACE 1                                                        72240031
UT0403   SR    GR0,GR0                 COMPARE PSEUDO CODE COUNT WITH   72300031
         CR    GRB,BR                ROOM LEFT IN BLOCK. BRANCH IF      72360031
         BC    BNH,UT0405            ROOM FOR ALL P/C.                  72420031
         SPACE 1                                                        72480031
         LR    GR0,GRB                 IF NOT ROOM, SET COUNT TO ROOM   72540031
         SR    GR0,BR                LEFT IN BLOCK AND SAVE RESIDUE     72600031
         LR    GRB,BR                IN GR0                             72660031
         SPACE 1                                                        72720031
UT0405   L     BR,SCPCG                UPDATE PSEUDO-CODE COUNT         72780031
         AR    BR,GRB                                                   72840031
         ST    BR,SCPCG                                                 72900031
         BAL   LR,UT05                 MOVE PSEUDO-CODE                 72960031
         LTR   GRB,GR0                 RESTORE COUNT, AND IF ZERO       73020031
         BCR   BZ,LR2                  IF ZERO RETURN                   73080031
         SPACE 1                                                        73140031
         LA    OP,2(0,OP)              OTHERWISE ALLOW SPACE FOR A      73200031
         NI    FLAG,NPCODE           DUMMY STACK BYTE PAIR, COPY        73260031
         L     BR,SCJMP              P/C COUNT AND SET PCODE FLAG OFF   73320031
         MVC   1(2,BR),SCPCG+2                                          73380031
         SPACE 1                                                        73440031
UT0404   BAL   LR1,UT02A               CHAIN TO NEXT OP BLOCK THEN GO   73500031
         BC    B,UT04                TO RECOMPUTE ROOM                  73560031
         EJECT                                                          73620031
*              SUBROUTINE UT05                                          73680031
         SPACE 1                                                        73740031
*              THIS SUBROUTINE IS USED TO MOVE CONTIGUOUS TEXT FROM     73800031
*        INPUT TO OUTPUT.                                               73860031
*              INPUT. GRA ADDRESSES TEXT, OP ADDRESSES TARGET TEXT AREA 73920031
*                     GRB CONTAINS COUNT                                73980031
*              OUTPUT. GRA CONTAINS GRA+GRB, OP HAS BEEN UPDATED TO     74040031
*        OP+GRB                                                         74100031
*              LINK. STANDARD LINK REGISTER LR                          74160031
         SPACE 1                                                        74220031
UT05     LTR   GRB,GRB                 TEST FOR SPECIAL CASE OF ZERO    74280031
         BC    BZ,UT0503             LENGTH AND RETURN                  74340031
         SPACE 1                                                        74400031
         BCTR  GRB,0                   SUBTRACT 1 FROM COUNT            74460031
UT0501   LA    BR,255                                                   74520031
         CR    GRB,BR                  COMPARE LENGTH-1 WITH 255. IF    74580031
         BC    BH,UT0502             GREATER MOVE 256 CHARACTERS THEN   74640031
*                                    MOVE AGAIN                         74700031
         LR    BR,GRB                  IF LESS OR EQUAL, MOVE THEN      74760031
*                                    RETURN                             74820031
UT0502   EX    BR,UT0510               MOVE                             74880031
         LA    BR,1(0,BR)                                               74940031
         AR    GRA,BR                  UPDATE SOURCE AND TARGET         75000031
         AR    OP,BR                 ADDRESSES AND COUNT                75060031
         SR    GRB,BR                                                   75120031
         BC    BNM,UT0501                                               75180031
UT0503   ST    OP,ZPCOP                UPDATE OUTPUT POINTER SLOT       75240031
         BCR   B,LR                    RETURN IF COUNT EXHAUSTED.       75300031
         SPACE 2                                                        75360031
UT0510   MVC   0(0,OP),0(GRA)                                           75420031
         EJECT                                                          75480031
*              SUBROUTINE UT06                                          75540031
         SPACE 1                                                        75600031
*              THIS SUBROUTINE IS USED BY DV1. IT IS USED TO            75660031
*        GENERATE PSEUDO-CODE.                                          75720031
*              INPUT. LR1 ADDRESSES CODE                                75780031
*                     LR2 CONTAINS LENGTH                               75840031
*              LINK. STANDARD LINK REGISTER LR                          75900031
         SPACE 1                                                        75960031
UT06     ST    LR1,PAR1                SET UP PAR1 AND PAR2 THEN        76020031
         ST    LR2,PAR2              RETURN THROUGH MV2                 76080031
         BC    B,LA0050                                                 76140031
         EJECT                                                          76200031
*              SUBROUTINE UT07                                          76260031
         SPACE 1                                                        76320031
*              THIS SUBROUTINE CONVERTS THE DICTIONARY REFERENCE        76380031
*        ADDRESSED BY GRA TO ABSOLUTE, AND RETURNS ADDRESS IN GRB.      76440031
*              LINK. SPECIAL LINK REGISTER LR2                          76500031
         SPACE 1                                                        76560031
UT07     MVC   PAR1+2(2),0(GRA)                                         76620031
         L     BR,ZDRFAB               CALL CONTROL ROUTINE             76680031
         BALR  LR,BR                                                    76740031
         L     GRB,PAR1                                                 76800031
         BCR   B,LR2                   RETURN                           76860031
         EJECT                                                          76920031
*              SUBROUTINE UT08                                          76980031
         SPACE 1                                                        77040031
*              THIS SUBROUTINE IS AN INTERNAL VERSION OF SC9. IP        77100031
*        ADDRESSES A JUMP TRIPLE. THE PSEUDO CODE IS MOVED TO OUTPUT    77160031
*        AND THE SCAN PARAMETER BLOCK UPDATED. ON RETURN IP ADDRESSES   77220031
*        THE TRIPLE FOLLOWING THE PSEUDO-CODE                           77280031
*              LINK. STANDARD LINK REGISTER LR                          77340031
         SPACE 1                                                        77400031
UT08     ST    LR,LRUT08               SAVE LINK                        77460031
         MVC   HTEMP(2),1(IP)                                           77520031
         LH    GRB,HTEMP               SET GRB TO LENGTH OF PSEUDO CODE 77580031
         SH    GRB,H5                                                   77640031
         LA    GRA,5(0,IP)             POINT GRA AT START OF PSEUDO     77700031
         BAL   LR2,UT04              CODE, THEN MOVE TO OP. ON RETURN   77760031
         MVC   SCSTK(2),0(GRA)       GRA ADDRESSES STACK BYTES          77820031
         LA    IP,2(0,GRA)             POINT IP AT NEXT TRIPLE          77880031
         L     LR,LRUT08               RESTORE AND RETURN               77940031
         BCR   B,LR                                                     78000031
         EJECT                                                          78060031
*              SUBROUTINE UT09                                          78120031
         SPACE 1                                                        78180031
*              THIS SUBROUTINE IS USED BY DV1 TO ALIGN AND INCREASE     78240031
*        THE WORKSPACE COUNT. THE INPUT COUNT IS ADDED TO SCWKS AND     78300031
*        THE RESULT ROUNDED DOWN TO WORD ALIGNMENT.                     78360031
*              INPUT. GR0 CONTAINS COUNT. GR0 IS RETURNED UNCHANGED.    78420031
         SPACE 1                                                        78480031
UT09     LH    BR,SCWKS                                                 78540031
         AR    BR,GR0                  UPDATE COUNT                     78600031
         STH   BR,SCWKS                                                 78660031
         NI    SCWKS+1,X'FC'           ROUND DOWN                       78720031
         BCR   B,LR                    RETURN                           78780031
         EJECT                                                          78840031
*              SUBROUTINE UT10                                          78900031
         SPACE 1                                                        78960031
*              THIS SUBROUTINE IS USED BY DV1 TO INSERT ADJUSTABLE      79020031
*        BOUND VALUES IN BASED VARIABLE DOPE VECTORS. SKELETONS PS03    79080031
*        AND PS05 ARE USED. THE OPERATION CODE OF PS03 IS ZERO FOR      79140031
*        THE FIRST CALL, WHEN A LOAD IS GENERATED, NON-ZERO OTHERWISE,  79200031
*        WHEN ONLY A STH IS PRODUCED.                                   79260031
*              INPUT. PS03 CONTAINS BOUND OR EXTENT REF                 79320031
*              LINK.  STANDARD LINK LR                                  79380031
         SPACE 1                                                        79440031
UT10     LA    LR1,PS05                SET UP ADDRESS AND LENGTH OF     79500031
         LA    LR2,PS05L             STH INSTRUCTION                    79560031
         CLI   PS03,0                  TEST FOR FIRST ENTRY AND         79620031
         BC    BNE,UT1001            BRANCH IF NOT.                     79680031
         MVI   PS03,PL                 FOR FIRST SET PS03 TO LOAD AND   79740031
         LA    LR1,PS03              SET ADDRESS AND COUNT FOR LOAD +   79800031
         LA    LR2,PS03L+PS05L       STH                                79860031
         TM    PS044+1,X'01'           TEST FOR LOCATE OR ALLOCATE      79920031
         BC    BNZ,UT1001            ENTRY. FOR OTHER ENTRIES THE       79980031
         MVC   PS032(2),REFERS       REFER VARIABLE RATHER THAN THE     80040031
*                                    EXTENT VARIABLE IS USED.           80100031
         SPACE 1                                                        80160031
UT1001   MVC   PS053(2),SCWKS          SET WORKSPACE COUNT              80220031
         BC    B,UT06                  GO TO GENERATE CODE              80280031
         EJECT                                                          80340031
*              SUBROUTINE UT11                                          80400031
         SPACE 1                                                        80460031
*              THIS SUBROUTINE IS USED TO CONVERT SYMBOLIC OUTPUT TEXT  80520031
*        REFERENCES TO ABSOLUTE. BLOCK STATUS IS UNCHANGED.             80580031
*              INPUT.  OP CONTAINS TEXT REF                             80640031
*              OUTPUT. OP CONTAINS TEXT ADDRESS                         80700031
*              LINK.   SPECIAL LINK LR1                                 80760031
         SPACE 1                                                        80820031
UT11     ST    OP,PAR1                 SET REF IN PAR1 AND NO STATUS    80880031
         MVI   PAR1,X'80'            CHANGE FLAG                        80940031
         L     BR,ZTXTAB                                                81000031
         BALR  LR,BR                                                    81060031
         L     OP,PAR1                 OP NOW CONTAINS ABS ADDRESS      81120031
         BCR   B,LR1                                                    81180031
         EJECT                                                          81240031
*              SUBROUTINE UT12                                          81300031
         SPACE 1                                                        81360031
*              THIS SUBROUTINE IS USED TO CONVERT ABSOLUTE OUTPUT       81420031
*        TEXT ADDRESSES TO SYMBOLIC FORM.                               81480031
*              INPUT.  BR CONTAINS TEXT ADDRESS                         81540031
*              OUTPUT. PAR1 CONTAINS SYMBOLIC ADDRESS                   81600031
*              LINK.   STANDARD LR.                                     81660031
         SPACE 1                                                        81720031
UT12     ST    BR,PAR2                 ABS ADDRESS IN PAR2              81780031
         MVC   PAR1+1(1),SCTXTO+1      BLOCK NAME IN PAR1               81840031
         L     BR,ZTXTRF               RETURN VIA TEXT REF ROUTINE      81900031
         BCR   B,BR                                                     81960031
         EJECT                                                          82020031
SNLNTH   DC    H'4'                    LENGTH OF SN TRIPLES (SET TO 6   82080031
*                                    AT EOP2 I.E. AFTER FIRST SCAN)     82140031
H0       DC    H'0'                                                     82200031
H3       DC    H'3'                                                     82260031
H5       DC    H'5'                                                     82320031
H7       DC    H'7'                                                     82380031
H36      DC    H'36'                   USED AS COMPARANDS FOR THE       82440031
H72      DC    H'72'                 VALUE RESULTING FROM TRT IN SCAN   82500031
WKSREF   DC    H'0'                    DICT REF OF WORKSPACE 1          82560031
WKFREF   DC    H'0'                    DICT REF OF FORMAT WORKSPACE     82620031
MARKER   DC    X'01'                   BLOCK DISPOSITION MARKER USED    82680031
*                                    WHEN CHAINING TO A NEW INPUT BLOCK 82740031
LAZZ     DC    C'ZZ'                   RELEASE LIST (NULL) USED WHEN    82800031
*                                    FIRST INITIALIZATION COMPLETED     82860031
*              PSEUDO CODE SKELETONS USED BY DV1                        82920031
         SPACE 1                                                        82980031
PS01     DC    AL1(PMVC)               MOVE SKELETON TO WORKSPACE       83040031
         DC    X'10'                   MVC WKS+OFFSET(L),SKDV           83100031
         DC    AL1(PS01L)              LENGTH OF PSEUDO CODE            83160031
PS011    DC    X'00'                   MACHINE INSTRUCTION LENGTH BYTE  83220031
PS012    DC    AL2(0)                  WORKSPACE REF                    83280031
PS013    DC    AL2(0)                  SKELETON DOPE VECTOR REF         83340031
PS014    DC    AL2(0)                  WORKSPACE OFFSET                 83400031
PS015    DC    AL1(0)                                             21124 83460031
PS01L    EQU   *-PS01                                                   83520031
         SPACE 1                                                        83580031
PS03     DC    AL1(PL)                 LOAD SR3 WITH EXTENT VALUE       83640031
PS031    DC    AL2(0)                  SR3                              83700031
PS032    DC    AL2(0)                  EXTENT OR BOUND REF              83760031
PS03L    EQU    *-PS03                                                  83820031
         SPACE 1                                                        83880031
PS05     DC    AL1(PSTH)               STH SR3, WKS+4 OR +6             83940031
PS051    DC    AL2(0)                  SR3                              84000031
PS052    DC    AL2(0)                  WORKSPACE REF                    84060031
         DC    AL1(POSM1)                                               84120031
PS053    DC    AL2(0)                  DV OFFSET IN WORKSPACE + 4       84180031
PS05L    EQU   *-PS05                                                   84240031
         SPACE 1                                                        84300031
PS07     DC    AL1(PDROP)              DROP SR3                         84360031
PS071    DC    AL2(0)                  SR3                              84420031
PS07L    EQU   *-PS07                                                   84480031
         SPACE 1                                                        84540031
PS04     DC    AL1(PL)                 LOAD SR2 WITH RELATIVE OFFSET    84600031
PS041    DC    AL2(0)                  SR2                              84660031
PS042    DC    AL2(0)                  SKELETON DOPE VECTOR REF         84720031
         DC    AL1(PA)                 A  SR2    POINTER VALUE          84780031
PS043    DC    AL2(0)                  SR2                              84840031
PS044    DC    AL2(0)                  POINTER REFERENCE                84900031
         DC    AL1(PST)                STORE RELOCATED ADDRESS IN WKS   84960031
PS045    DC    AL2(0)                  SR2                              85020031
PS046    DC    AL2(0)                  WORKSPACE REF                    85080031
         DC    AL1(POSM1)                                               85140031
PS047    DC    AL2(0)                  DV OFFSET IN WORKSPACE + 0       85200031
PS04L    EQU   *-PS04                                                   85260031
         SPACE 1                                                        85320031
PS06     DC    AL1(PDROP)              DROP SR2                         85380031
PS061    DC    AL2(0)                  SR2                              85440031
PS06L    EQU   *-PS06                                                   85500031
ERROR    DC    AL2(1200)               ERROR 1200 SKELETON              85560031
         DC    X'40'                                                    85620031
         END   IEMKT                                                    85680031
