KU       TITLE 'IEMKU  DO LOOP CONTROL AND MERGE PATCHES OPTIMISATION, C00000620
               OS/360 PL/1 F COMPILER'                                  00001220
* 5.5  C                                                          62595 00001572
* R20 +615300,*750400-753900,*867300-868700,*870100,+871500.      32286 00001820
*        FIX FOR 32286  INVOLVES CHANGES TO MACROS IEMKUCM & IEMKUEQ    00002472
*        FIX FOR 62595  INVOLVES CHANGES TO MACRO  IEMKUCM              00003072
         SPACE                                                          00003620
*              FUNCTIONS - (1) SCAN TEXT, LOOKING FOR OPTIMISABLE DO  * 00004220
*        LOOPS, SUBSCRIPT LISTS AND TEXT PATCHES. (IEMKU).            * 00005001
*                          (2) DEPENDING ON TEXT SCAN, CONTROL        * 00006001
*        PROCESSING SEQUENCE IN IEMKU, IEMKV. (IEMKU).                * 00007001
*                          (3) SET UP A LOOP CONTROL SKELETON FOR     * 00008001
*        EACH OPTIMISED LOOP AND REPLACE LOOP PROLOGUE SPECIFICATION  * 00009001
*        WITH OPTIMISED CODE. EPILOGUE OPTIMISED CODE IS STACKED AND  * 00010001
*        SAVED. (IEMKU).                                              * 00011001
*                          (4) CONTROL PATCH FILE PROCESSING. (IEMKV).* 00012001
*                          (5) SUBSCRIPT LIST OPTIMISATION PROCESSING * 00013001
*        FOR BOTH TEXT AND PATCH FILE SUBSCRIPT LISTS. (IEMKV).       * 00014001
*                          (6) LOOP EPILOGUE SPECIFICATION IS REPLACED* 00015001
*        WITH OPTIMISED CODE FROM STACK FOR OPTIMISABLE LOOP. (IEMKV) * 00016001
*                          (7) PATCH FILE IS FREED.                   * 00017001
         SPACE 3                                                        00018001
         SPACE 3                                                        00019001
*              ENTRY POINT - 'IEMKU' FROM COMPILER CONTROL TO START   * 00020001
*        PHASE.                                                       * 00021001
         SPACE 3                                                        00022001
*              INPUT - TEXT IN FORM OF TRIPLES AND THE PATCH FILE     * 00023001
*        CREATED BY IEMKO AND ALSO HELD IN TEXT BLOCKS. DICTIONARY    * 00024001
*        ENTRIES ARE REQUIRED TO DETERMINE TYPE OF STEP IN LOOP,      * 00025001
*        WHETHER CONTROL VARIABLE IS A COMPILER GENERATED TEMPORARY   * 00026001
*        AND TYPE OF INITIAL.                                         * 00027001
         SPACE 3                                                        00028001
*              OUTPUT - TEXT IN FORM PART TRIPLES, PART PSEUDO-CODE.  * 00029001
*        OPTIMISABLE LOOP SPECIFICATIONS HAVE BEEN REPLACED BY        * 00030001
*        SKELETONS OF OPTIMISED CODE PARTLY IN TRIPLES, PARTLY IN     * 00031001
*        PSEUDO-CODE. SUBSCRIPT LISTS MAY HAVE BEEN MODIFIED BY       * 00032001
*        REPLACING 'COMA' TRIPLES WITH 'COMA-NULL' OR 'COMR' TRIPLES  * 00033001
*        AND INSERTION OF 'OFS'.  TEXT HAS BEEN EXPANDED BY INSERTION * 00034001
*        OF PATCH FILE ENTRIES, THESE ALSO CONSISTING OF TRIPLES AND  * 00035001
*        PSEUDO-CODE. DICTIONARY ENTRIES ARE CREATED FOR TEMPORARIES  * 00036001
*        USED IN LOOP CONTROL CODE.                                   * 00037001
         SPACE 3                                                        00038001
*              EXTERNAL ROUTINES -                                    * 00039001
*                       (1) CONTROL PHASE. THE FOLLOWING ENTRIES ARE  * 00040001
*        USED  - 'ZDICRF'  'ZDRFAB', 'ZLOADW', 'ZTXTRF', 'ZUGC',      * 00041001
*                'ZTXTAB', 'ZUERR', 'ZURC', 'ZABORT, 'ZALTER',        * 00042001
*                'RLSCTL'.                                            * 00043001
*                       (2) TEXT SCAN (IEMKT). THE FOLLOWING ENTRIES  * 00044001
*        ARE USED -                                                     00045001
*                'SCINIT', 'SC1', 'SC3', 'SC5', 'SC6', 'MV3', 'MV3A'. * 00046001
         SPACE 3                                                        00047001
*              EXIT - NORMAL - 'RLSCTL' TO RELEASE PHASE AND LOAD     * 00048001
*        NEXT.                                                        * 00049001
         SPACE 3                                                        00050001
*              EXIT - ERROR - 'ZUERR' TO PLACE TERMINAL ERROR         * 00051001
*        MESSAGE IN DICTIONARY, THEN 'ZABORT' TO TERMINATE COMPILATION* 00052001
*        TERMINAL MESSAGE NUMBER IEM122OI WITH NUMERIC PARAMETER IS   * 00053001
*        GIVEN.                                                       * 00054001
         SPACE 3                                                        00055001
*              WORKAREA - 4K OF SCRATCH IS OBTAINED AND USED TO STACK * 00056001
*        LOOP SKELETON EPILOGUES.                                     * 00057001
         SPACE 3                                                        00058001
*              ATTRIBUTES - THIS BLOCK IS NOT READ ONLY AND NOT       * 00059001
*        REENTRANT.                                                   * 00060001
         SPACE 3                                                        00061001
*              NOTES - (1) THIS PHASE REQUIRES THE 'IEMK' MACROS FOR  * 00062001
*        ASSEMBLY.                                                    * 00063001
*                      (2) THIS IS THE FIRST PHASE TO USE THE 'IEMKT' * 00064001
*        TEXT SCAN FACILITY.                                          * 00065001
*                      (3) 'IEMKU' DEALS WITH PHASE INITIALISATION    * 00066001
*              MAIN TEXT SCAN AND PROCESSING CONTROL, SETTING UP THE  * 00067001
*              OPTIMISED LOOP CODE SKELETONS.                         * 00068001
*                          'IEMKV' DEALS WITH PATCH PROCESSING AND    * 00069001
*              MERGING, SUBSCRIPT LIST PROCESSING, ERROR HANDLING AND * 00070001
*              PHASE TERMINATION.                                     * 00071001
*                      (4) REGISTER USAGE -                           * 00072001
*              GR1 - CURRENT INPUT TEXT POINTER.                     * 00073001
*              GR2 - RETURN VALUE REGISTER.        - REQUIRED BY 'KT'* 00074001
*              GR3 - POINTS AT SCAN PARAMETER AREA.                  * 00075001
*              GR4 - WORK REGISTER.                                   * 00076001
*              GR5 - WORK REGISTER.                                   * 00077001
*              GR6 - BASE FOR PATCH DESCRIPTOR DSECT - XPCH.          * 00078001
*              GR7 - BASE FOR TRIPLE DESCRIPTOR DSECT - XTRP.         * 00079001
*              GR8 - BASE FOR 'IEMKV' 4K MODULE.                      * 00080001
*              GR9 - BASE FOR 'IEMKU' 4K MODULE.                      * 00081001
*              REMAINDER AS STANDARD.                                 * 00082001
*                      (5) IN CASE OF ABORT THE FOLLOWING MAY BE OF   * 00083001
*              USE -                                                  * 00084001
*                  'KUREG' CONTAINS INPUT TEXT POINTER AS AT LAST    * 00085001
*              USE OF SCAN (IEMKT).                                   * 00086001
*                  'KUSCAN' - THE SCAN PARAMETER AREA - IS DESCRIBED  * 00087001
*              BY THE XSCN DSECT BASED ON REGISTER 3. THIS CONTAINS   * 00088001
*              THE SCAN TRT ACTION TABLE AND SLOTS WITH VARIOUS USEFUL* 00089001
*              POINTERS.                                              * 00090001
*                  'KUSBYT', 'KUABYT' ARE STATUS BYTES FOR 'IEMKU'    * 00091001
*                  'KVSBT1 , 'KVSBT2  ARE STATUS BYTES FOR 'IEMKV'    * 00092001
*                  'KUERBT',  IS THE ERROR PARAMETER BYTE FROM WHICH  * 00093001
*              THE SPECIFIC CAUSE OF AN ABORT MAY BE FOUND.           * 00094001
         EJECT                                                          00095001
*                                                                     * 00140001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*KU 001-TSS 00160056
*        ----------------------------------------------------KU 001-TSS 00180056
**       STANDARD  EQUATES.                                          ** 00210001
*                                                                     * 00280001
         COPY  IEMKUEQ                                                  00350001
*                                                                     * 00420001
**       STANDARD  DSECTS.                                            * 00490001
*                                                                     * 00560001
         COPY  IEMKCOM                                                  00630001
         COPY  IEMKEQU                                                  00700001
         COPY  IEMKSCN                                                  00800001
         COPY  IEMKSLA                                                  00890001
         COPY  IEMKTRP                                                  00970001
         COPY  IEMKUTL                                                  01040001
         DCBD                                                           01190001
         COPY  IEMKKVT                                                  01260001
         COPY  IEMKVCM                                                  01330001
         EJECT                                                          01400001
IEMKU    CSECT                                                          01470001
*                                                                     * 01540001
**       PROVIDE BASE REGISTERS FOR PHASE AND DSECTS.                ** 01610001
*                                                                     * 01680001
         USING *,PRBASE                 PROVIDE PHASE BASE REGISTER.    01750001
         USING XTRP,GR7                 BASE TRIPLE DESCRIPTOR DSECT.   01820001
*                                                                     * 01890001
**       PROVIDE NAME FOR PHASE AND LOAD PHASE BASE REGISTER.        ** 01960001
**       LOAD SAVE AREA BASE REGISTER AS REQUIRED BY MACROS.         ** 02030001
**       PERFORM PHASE INITIALIZATION SUBROUTINE.                    ** 02100001
*                                                                     * 02170001
*                                                                     * 02240001
KUNAME   DC    C'KU'                    SET PHASE NAME.                 02310001
         L     PRBASE,PAR1              LOAD PHASE BASE REGISTER.       02380001
         LA    SAREG,KUSAVE             SAVE AREA ADDRESS IS SET        02450001
*                                       AS REQUIRED BY ENTRY AND LEAVE  02520001
*                                       MACROS.                         02590001
         B     KUMAIN                   BRANCH TO MAIN ROUTINE.         02660001
         B     KUITDO                   BRANCH TO ITDO SUBROUTINE.      02730001
         COPY  IEMKUCM                                                  02800001
         EJECT                                                          02870001
*********************************************************************** 02970001
*                                                                     * 03080001
**             KUMAIN - THE PHASE CONTROL ROUTINE.                   ** 03140001
**       THIS IS THE HIGHEST LEVEL ROUTINE OF PHASES KU & KV AND     ** 03200001
**        CONTROLS THE PROCESSING DONE IN MODULES KU AND KV.         ** 03260001
**        THE FIRST PART OF THE ROUTINE CONTROLS THE MAJOR TEXT SCAN ** 03320001
**        UPON WHICH THE REMAINDER OF THE PROCESSING DEPENDS.        ** 03380001
**        MODULE KU IS LARGELY DEVOTED TO LOOP CONTROL PROCESSING.   ** 03440001
**        MODULE KV CONTAINS THE SUBROUTINES FOR PATCH, SUBSCRIPT    ** 03500001
**       LIST,ERROR AND END PROCESSING.                              ** 03560001
**        THE EXIT FROM THIS ROUTINE IS NORMALLY BY A CALL TO KUENDS ** 03620001
**        OR ABNORMALLY TO KVERRS.                                   ** 03680001
*                                                                     * 03740001
*********************************************************************** 03750001
*                                                                     * 03760001
KUMAIN   IEMKENT   NOTRACE,TYPE=1                                       03770001
*                                                                     * 03780001
**       PHASE IS INITIALISED ONCE. PROCESS INITIALISATION           ** 03790001
**       IS PERFORMED BEFORE EACH ENTRY TO MAIN SCAN.                ** 03800001
*                                                                     * 03810001
         BAL   RR,KUINIT                PERFORM PHASE INITIALISATION.   03820001
*                                                                     * 03830001
*                                                                     * 03850001
**       PERFORM PREPROCESSING INITIALIZATION SUBROUTINE.            ** 03920001
*                                                                     * 03990001
MAINSETS BAL   RR,KUSETS                PERFORM PROCESSING              04060001
*                                                                     * 04130001
**       PERFORM KUSCN1 SUBROUTINE TO FIND A TRIPLE OF INTEREST.     ** 04200001
**       RETURN CODE REGISTER CONTAINS RETURN VALUE DEPENDENT ON     ** 04270001
**       TRIPLE FOUND. RETURN VALUES ARE :-                          ** 04340001
**                       0 - EOP2 TRIPLE                             ** 04410001
**                       4 - ITDO TRIPLE                             ** 04480001
*                        8 - NOP  TRIPLE.                               04550001
**                      12 - PTCH TRIPLE.                            ** 04620001
**                      16 - SUBS TRIPLE.                            ** 04690001
**                      20 - SUBO TRIPLE.                            ** 04760001
**                      24 - COMR TRIPLE.                            ** 04830001
**                      28 - COMA TRIPLE.                            ** 04900001
**                      32 - SUBP TRIPLE.                            ** 04970001
**                      36 - ITDP TRIPLE.                            ** 05000001
*                                                                     * 05040001
         BAL   RR,KUSCN1                PERFORM PRIMARY SCAN SUBROUTINE 05110001
*                                                                     * 05180001
         LA    RR,MAINTOUT                                              05250001
         B     MAINTAB1(RC)             INDEX BRANCH WITH RETURN CODE.  05320001
MAINTAB1 B     KUENDS                   PERFORM END OF PHASE ROUTINE.   05390001
         B     MAINITDO                 CONTINUE SEQUENTIAL PROCESSING. 05460001
         B     MAINSETS                 DELETE NOP TRIPLES FROM TEXT.   05560001
         B     MAINPTCH                 BRANCH TO PATCH PROCESSOR.      05660001
         B     KVSUBS                   PROCESS SUBS TRIPLE.            05760001
         B     KVSUBS                   PROCESS SUBO (INSERT OFS) TRPL. 05860001
         B     KVCOMR                   PROCESS COMR TRIPLE.            05960001
         B     KVCOMA                   PROCESS COMA TRIPLE.            06060001
         B     KVSUBP                   PROCESS SUB' TRIPLE.            06160001
         LA    RR,MAINSETS              SET NEW RETURN POINT TO AVOID   06260001
*        OUTPUT OF CURRENT TRIPLE - DONE IN KVITDP IF NECESSARY.        06360001
         B     KVITDP                   PERFORM ITD' PROCESSING.        06460001
*                                                                     * 07070001
**       OUTPUT CURRENT TRIPLE TO TEXT BEFORE RETURNING TO MAIN SCAN.** 07140001
*                                                                     * 07210001
MAINIOUT LA    GR7,KVITDO               SET ADDRESS OF UNOPT ITDO OR    07280001
MAINTOUT ST    GR7,PAR1                  CURRENT TRIPLE IN              07350001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE IN PAR2    07420001
         ST    GR4,PAR2                  SLOT                           07490001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          07560001
*                                                                     * 07566001
**       HAS SUBS TRIPLE JUST BEEN OUTPUT. IF IT HAS THEN GET TEXT   ** 07572001
**       REF. IF NOT THEN RETURN TO CONTINUE SCAN.                   ** 07578001
*                                                                     * 07584001
MAINSREF TM    KVSBT2,KUS1ON            WAS LAST TRIPLE SUBS.           07590001
         BZ    MAINSETS                 RETURN TO SCAN IF NOT.          07596001
         NI    KVSBT2,KUS1OF            SET SWITCH OFF.                 07602001
*                                                                     * 07608001
**       OBTAIN TEXT REFERENCE OF CURRENT OUTPUT TEXT POINTER USING  ** 07614001
**       ZTXTRF PROCESSING ROUTINE AND HENCE GET T-REF OF SUBS TRPL  ** 07620001
*                                                                     * 07626001
         L     GR4,SCTXTO               PLACE WORD CONTAINING OUTPUT    07632001
         ST    GR4,PAR1                  TEXT BLOCK NAME IN PAR1.       07638001
         L     GR4,ZPCOP                SET CURRENT ADDRESS TO OUTPUT   07644001
         ST    GR4,PAR2                  TEXT BLOCK IN PAR2.            07650001
         L     LR,ZTXTRF                LOAD BRANCH REGISTER.           07656001
         BALR  RR,LR                    GET TEXT REFERENCE OF CURRENT   07662001
         L     GR4,PAR1                  OUTPUT POINTER AND STORE IN    07668001
         LA    GR5,KUTRLN               SUBTRACT LENGTH OF TRIPLE TO    07674001
         SR    GR4,GR5                   GIVE TEXT REF OF SUBS.         07680001
         ST    GR4,KVSBST                RESERVED SLOT.                 07686001
         B     MAINSETS                 RETURN TO PRESCAN INITIALISER.  07692001
*                                                                     * 07700001
**       PERFORM PATCH PROCESSING SUBROUTINE AND TEST RETURN CODE TO ** 07770001
**       DETERMINE WHETHER AN OPTIMIZABLE ITDO WAS ENCOUNTERED IN    ** 07840001
**       PATCH.                                                      ** 07910001
*                                                                     * 07980001
MAINPTCH BAL   RR,KVPTCH                PROCESS PTCH TRIPLE.            08050001
         B     MAINPRET(RC)             BRANCH ON RETURN CODE.          08100001
MAINPRET B     MAINCVAR                 PROCEED FOR OPTIMISABLE ITDO.   08150001
         B     MAINIOUT                 OUTPUT UNOPTIMISABLE ITDO.      08200001
         B     MAINSREF                 DO NOT OUTPUT PTCH TRIPLE.      08260001
*                                                                     * 08330001
**       PERFORM KUITDO SUBROUTINE TO TEST ITDO SECOND OPERAND.      ** 08400001
**       STATUS SWITCH 1 AND RETURN CODE ARE SET ACCORDINGLY. THE    ** 08470001
**       STATUS SWITCH 1 IS SET ON IF SINDEXES ARE NOT USED. THE     ** 08540001
**       SUBROUTINE RETURN CODE VALUES ARE :-                        ** 08610001
**                       0 -  OPTIMIZABLE.                           ** 08680001
**                       4 -  UNOPTIMIZABLE.                         ** 08750001
*                                                                     * 08820001
MAINITDO BAL   RR,KUITDO                PERFORM ITDO CHECKING S-ROUTINE 08890001
         LTR   RC,RC                    TEST SUBROUTINE RETURN CODE.    08960001
         BZ    MAINCVAR                 IF ITDO OPTIMIZABLE PROCEED.    09030001
         B     MAINTOUT                 IF NOT OUTPUT CURRENT(ITDO)     09100001
*                                        TRIPLE AND RESUME SCAN.        09170001
*                                                                     * 09240001
**       CONTINUE MAIN PROCESSING BY OBTAINING NEXT TRIPLE. THIS MUST** 09310001
**       BE CV OR *CV. ANY OTHER TRIPLE SIGNIFIES COMPILER ERROR.    ** 09380001
**       SUBROUTINE KUCVAR OBTAINS THE TRIPLE, CHECKS THE TRIPLE     ** 09450001
**       TYPE AND SETS STATUS SWITCHES 2,3 & 4 ACCORDINGLY. RETURN   ** 09520001
**       CODE VALUE IS 0 - NORMAL RETURN ONLY.                       ** 09590001
*                                                                     * 09660001
MAINCVAR BAL   RR,KUCVAR                PERFORM CV CHECKING SUBROUTINE. 09730001
*                                                                     * 09800001
**       THE SECOND SCAN SUBROUTINE IS PERFORMED TO OBTAIN DICTIONARY** 09870001
**       REFERENCES FOR  REQUIRED LOOP CONTROL ELEMENTS. THESE ARE   ** 09940001
**       STORED IN RESERVED SLOTS IN KUSTDR IN PHASE COMMUNICATION   ** 10010001
**       REGION KUCOMM. THE KUSCN2 SUBROUTINE RETURN CODE VALUE IS :    10080001
**                  O - NORMAL ONLY.                                    10150001
*                                                                     * 10220001
         BAL   RR,KUSCN2                PERFORM SECOND SCAN SUBROUTINE. 10290001
*                                                                     * 10360001
**       THE INITIAL (DOEQ) DICTIONARY REFERENCE IS CHECKED AND      ** 10430001
**       SWITCH 5 IS SET ON TO INDICATE A FIXED BINARY INTEGER. THE  ** 10500001
**       STEP (BY) DICTIONARY REFERENCE IS CHECKED AND THE SINDEX    ** 10570001
**       STATUS SWITCH IS TESTED. KUSTEP SUBROUTINE RETURN CODE VALUE** 10640001
**       IS SET ACCORDINGLY. THE RETURN CODE VALUES ARE :-           ** 10710001
**                       O -  STEP CONSTANT.                         ** 10780001
**                       4 -  STEP UNKNOWN + SINDEXES.               ** 10850001
**                       8 -  STEP UNKNOWN NON SINDEX.               ** 10920001
*                                                                     * 10990001
         BAL   RR,KUSTEP                PERFORM STEP TEST SUBROUTINE.   11060001
         LA    RR,MAINSETS              SET RETURN REGISTER  WITH       11130001
*                                        ADDRESS TO WHICH RETURN IS TO  11200001
*                                        BE MADE AFTER SKLTON IS SET UP 11270001
         B     MAINSKEL(RC)             INDEX BRANCH WITH RETURN CODE.  11340001
*                                                                     * 11410001
**       BRANCH TABLE FOR SETTING UP REQUIRED DO LOOP SKELETON.      ** 11480001
*                                                                     * 11550001
MAINSKEL B     KUSKL3                   SET UP CONSTANT STEP SKELETON.  11620001
         B     KUSKL2                   SET UP SINDX VARIABLE SKELETON. 11690001
         B     KUSKL1                   SET UP NON SINDX VAR SKELETON.  11760001
*                                                                     * 11780001
**       ERROR HAS OCCURED IN RETURN FROM SCAN.                      ** 11800001
*                                                                     * 11820001
*                                                                     * 11900001
**       END MAIN ROUTINE WITH STANDARD MACRO.                       ** 11970001
*                                                                     * 12040001
MAINEXIT IEMKLVE                                                        12110001
         EJECT                                                          12180001
*********************************************************************** 12250001
*                                                                     * 12320001
**             KUINIT - INITIALIZATION SUBROUTINE.                   ** 12390001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :          ** 12460001
**        MODULE KV IS LOADED AND ITS BASE REGISTER IS SET.          ** 12530001
**        BASE REGISTERS NOT ALREADY SET ON ENTRY TO PHASE ARE LOADED** 12600001
**        PHASE NAME IS SET IN COMMUNICATION REGION.                 ** 12670001
**        SCRATCH CORE IS OBTAINED AND SKELETON STACK INITIALIZED.   ** 12740001
**        SCAN TRANSLATE TABLE IS INITIALIZED.                       ** 12810001
**        KVTTAB TRANSLATE TABLE IS INITIALIZED FOR USE IN KVPTCH    ** 12880001
**        SUBROUTINE.                                                ** 12950001
**        SCAN INITIALIZING ROUTINE IS INVOKED.                      ** 13020001
**        THE PHASE ERROR AND STATUS SWITCHES ARE ZEROIZED.          ** 13090001
**       THE SUBROUTINE RETURN CODE VALUE IS :-                      ** 13160001
**                       0 - NORMAL RETURN ONLY.                     ** 13230001
*                                                                     * 13300001
*********************************************************************** 13370001
*                                                                       13440001
KUINIT   IEMKENT   NOTRACE,TYPE=LL2                                     13510001
*                                                                     * 13580001
**       SET KU PHASE NAME IN COMMUNICATIONS REGION AND USE ZLOAD TO ** 13650001
**       LOAD MODULE KV AND PROVIDE BASE REGISTER ADDRESS.           ** 13720001
*                                                                     * 13790001
         MVC   ZMYNAM(2),KUNAME         SET PHASE NAME IN COMM REGION.  13860001
*                                                                     * 13930001
         LA    GR4,KUNAKV               SET ADDRESS OF NAME BLOCK IN    14000001
         ST    GR4,PAR1                  PAR1.                          14070001
         L     LR,ZLOADW                SET ADDR OF LOAD ROUTINE.       14140001
         BALR  RR,LR                     REGISTER AND LOAD MODULE KV.   14210001
         L     GR8,PAR1                 SET KU BASE REGISTER.           14280001
*                                                                     * 14350001
**       GET 4K OF SCRATCH CORE                                      ** 14420001
*                                                                     * 14490001
         LA    GR4,KUSCRT               SET NO OF SCRATCH CORE BLOCKS   14560001
         ST    GR4,PAR1                 REQUIRED IN PARAMETER AREA.     14630001
         L     LR,ZUGC                  SET UP BRANCH REGISTER.         14700001
         BALR  RR,LR                    BRANCH WITH RETURN TO GET CORE. 14770001
         L     GR4,PAR1                 LOAD ADDRESS OF SCRATCH CORE.   14840001
*                                                                     * 14910001
**       INITIALIZE SCRATCH CORE STACK AREA. NOTE THE ADDRESS HELD   ** 14980001
**       IN KUSCPT ALWAYS POINTS TO STACK ENTRY MARKER (I.E. LAST    ** 15050001
**       3 BYTES OF EACH STACK ENTRY).                               ** 15120001
*                                                                     * 15190001
         MVC   0(4,GR4),KUHIGH          SET STACK BASE MARKER BYTES.    15260001
         ST    GR4,KUSCPT               SAVE STACK POINTER.             15330001
*                                                                     * 15400001
**       LOAD BASE REGISTERS NOT ALREADY SET ON ENTRY TO PHASE.      ** 15470001
*                                                                     * 15540001
         LA    PR3,KUSCAN               LOAD SCAN PARAMETER DSECT BASE. 15610001
*                                                                     * 15680001
**       INITIALISE TRANSLATE AND TEST TABLE FOR USE IN PATCH        ** 15750001
**       PROCESSING.                                                 ** 15820001
*                                                                     * 15890001
         XC    KVTTAB,KVTTAB            CLEAR TABLE.                    15960001
         MVI   KVTTAB+XTRPEOPT,X'04'    SET RETURN CODE FOR END PATCH.  16030001
         MVI   KVTTAB+XTRPSSUB,X'08'    SET RETURN CODE FOR SSUB.       16100001
         MVI   KVTTAB+XTRPSSBP,X'0C'    SET RETURN CODE FOR SSB'.       16170001
         MVI   KVTTAB+XTRPCOMR,X'10'    SET RETURN CODE FOR COMR.       16240001
         MVI   KVTTAB+XTRPCOMA,X'14'    SET RETURN CODE FOR COMA.       16310001
         MVI   KVTTAB+XTRPBYCH,X'18'    SET RETURN CODE FOR BUY CHMLN.  16340001
         MVI   KVTTAB+XTRPNOP,X'1C'     SET RETURN CODE FOR NO OP.      16370001
         MVI   KVTTAB+XTRPSTNO,X'20'    SET RETURN CODE FOR STNO        16390001
         MVI   KVTTAB+XTRPSTLB,X'20'    SET RETURN CODE FOR 8TLB TRPLE. 16395001
         MVI   KVTTAB+XTRPSTCN,X'20'    SET RETURN CODE FOR CN.         16400001
         MVI   KVTTAB+XTRPSTNT,X'20'    SET RETURN CODE FOR SN2         16405001
         MVI   KVTTAB+XTRPBYCH,X'24'    SET DUMMY END OF 20 TYPE PATCH. 16412001
         MVI   KVTTAB+XTRPSUBS,X'28'     SET RETURN CODE FOR SUBS TRPL  16419001
         MVI   KVTTAB+XTRPSUBO,X'28'     SET RETURN CODE FOR SUBO TRPL  16426001
         MVI   KVTTAB+XTRPSUBP,X'2C'     SET RETURN CODE FOR SUB' TRPL  16433001
         MVI   KVTTAB+XTRPJUMP,X'30'     SET RETURN CODE FOR JUMP TRPL  16440001
*                                                                     * 16450001
**       THIS SETS UP THE BASIC SCAN TRANSLATE TABLE WHICH IS A      ** 16520001
**        REQUIRED MINIMUM FOR THE SCAN ROUTINE.                     ** 16590001
*                                                                     * 16660001
         XC    SCTRT,SCTRT              CLEAR SCAN TABLE.               16730001
         MVI   SCTRT,X'24'              ERROR TRIPLE.                   16800001
         MVI   SCTRT+XTRPJUMP,X'1C'     JUMP                            16870001
         MVI   SCTRT+XTRPPROC,X'0C'     PROC                            16940001
         MVI   SCTRT+XTRPBEGN,X'10'     BEGIN                           17010001
         MVI   SCTRT+XTRPSTNT,X'20'     SN2                             17080001
         MVI   SCTRT+XTRPFMAT,X'04'     FORMAT                          17150001
         MVI   SCTRT+XTRPSTNO,X'20'     SN                              17220001
         MVI   SCTRT+XTRPSTLB,X'20'     SL                              17290001
         MVI   SCTRT+XTRPSTCN,X'20'     CN                              17360001
         MVI   SCTRT+XTRPEBLK,X'24'     EOB                             17430001
         MVI   SCTRT+XTRPPRCP,X'14'     PROC'                           17500001
         MVI   SCTRT+XTRPBGNP,X'18'     BEGIN'                          17570001
         MVI   SCTRT+XTRPFMTP,X'08'     FORMAT'                         17640001
         MVI   SCTRT+XTRPEOP2,X'48'     EOP2.                           17710001
*                                                                     * 17780001
**       INVOKE SCAN INITIALIZER ROUTINE.                            ** 17850001
*                                                                     * 17920001
         BAL   RR,SCINIT                INITIALIZE SCAN.                17990001
         ST    PR1,KUREG1                                               18090001
*                                                                     * 18200001
**       ZEROIZE PHASE ERROR SWITCH AND STATUS BYTES.                ** 18270001
*                                                                     * 18340001
         XC    KUSBYT,KUSBYT            ZEROIZE KU STATUS BYTE.         18410001
         XC    KVSBT1,KVSBT1            ZEROIZE 1ST KV STATUS BYTE.     18480001
         XC    KVSBT2,KVSBT2            ZEROIZE 2ND KV STATUS BYTE.     18550001
         XC    KUERBT,KUERBT            CLEAR ERROR NUMBER BYTE.        18620001
         XC    KUABYT,KUABYT                                            18700001
         OI    KUABYT,KUS1ON            GIVE INITIAL VALUE TO           18710001
         OI    KUSBYT,KUS7ON             SWITCHES AUX 1 AND SWITCH 7.   18720001
*                                                                     * 18760001
*                                                                     * 18830001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE.             ** 18900001
*                                                                     * 18970001
INITEXIT IEMKLVE                                                        19040001
         EJECT                                                          19110001
*********************************************************************** 24850001
*                                                                     * 24920001
**             KUSCN1 - SET UP 1ST SCAN TABLE AND PERFORM 1ST SCAN.  ** 24990001
**       THIS SUBROUTINE MUST SET UP RETURN VALUES IN SCAN TABLE FOR    25060001
**       TRIPLES ENCOUNTERED DURING FIRST SCAN. IN ADDITION RETURN   ** 25130001
**       VALUES SET UP PREVIOUSLY FOR SECOND SCAN MUST BE ZEROIZED.  ** 25200001
**       FIRST SCAN ROUTINE IS PERFORMED USING SC1. RETURN CODE      ** 25270001
**       VALUES ARE :                                                ** 25340001
**                       0 - EOP2 TRIPLE.                            ** 25410001
**                       4 - ITDO TRIPLE.                            ** 25480001
**                       8 - NOP  TRIPLE.                            ** 25550001
**                      12 - PTCH TRIPLE.                            ** 25620001
**                      16 - SUBS TRIPLE.                            ** 25690001
**                      20 - SUBO TRIPLE.                            ** 25760001
**                      24 - COMR TRIPLE.                            ** 25830001
**                      28 - COMA TRIPLE.                            ** 25900001
**                      32 - SUBP TRIPLE.                            ** 25970001
**                      36 - ITDP TRIPLE.                            ** 26000001
*                                                                     * 26040001
*********************************************************************** 26110001
*                                                                     * 26180001
KUSCN1   IEMKENT  TYPE=LL2                                              26230001
         L     PR1,KUREG1               LOAD SCAN TRIPLE POINTER.       26280001
*                                                                     * 26320001
**       TEST TO SEE IF SCAN TABLE NEEDS TO BE INITIALIZED.          ** 26390001
*                                                                     * 26460001
         TM    KUSBYT,KUS8ON            TEST STATUS SWITCH.             26530001
         BO    SCN1TYP3                 BRANCH IF ON.                   26600001
         OI    KUSBYT,KUS8ON            SET STATUS SWITCH.              26670001
         MVI   SCTRT+XTRPITDO,X'4C'     ***  -                          26740001
         MVI   SCTRT+XTRPNOP,X'50'                                      26810001
         MVI   SCTRT+XTRPPTCH,X'54'       THESE TRIPLES ARE THOSE FROM  26880001
         MVI   SCTRT+XTRPSUBS,X'58'       WHICH RETURN IS REQUIRED WHEN 26950001
         MVI   SCTRT+XTRPSUBO,X'5C'       ENCOUNTERED IN COURSE OF THE  27020001
         MVI   SCTRT+XTRPCOMR,X'60'       PRIMARY SCAN.                 27090001
         MVI   SCTRT+XTRPCOMA,X'64'                                     27160001
         MVI   SCTRT+XTRPSUBP,X'68'                                     27200001
         MVI   SCTRT+XTRPITDP,X'6C'                               - *** 27250001
*                                                                     * 27300001
         MVI   SCTRT+XTRPDOEQ,X'00'     ***  -                          27370001
         MVI   SCTRT+XTRPCVP,X'00'                                      27440001
         MVI   SCTRT+XTRPTOP,X'00'        THESE TRIPLES ARE SET TO GIVE 27510001
         MVI   SCTRT+XTRPBYP,X'00'        RETURN BEFORE 2ND SCAN AND    27580001
         MVI   SCTRT+XTRPTO,X'00'         ARE SET HERE TO GIVE NO       27650001
         MVI   SCTRT+XTRPBY,X'00'         RETURN.                       27720001
         MVI   SCTRT+XTRPCLN2,X'00'                              -  *** 27790001
*                                                                     * 27860001
**       PERFORM SCAN USING SC1 AND TABLE CREATED ABOVE.             ** 27930001
*                                                                     * 28000001
SCN1SWCH BC    15,SCN1FRST                                              28070001
SCN1TYP3 BAL   RR,SC3                   IGNORE CRRNT TRIPLE @ SCAN.     28140001
         B     SCN1RETN                 BRANCH TO TEST RETURN VALUE.    28210001
SCN1FRST MVI   SCN1SWCH+1,X'00'                                         28280001
         BAL   RR,SC1                   PERFORM SCAN.                   28350001
*                                                                     * 28420001
**       ANALYSE RETURN VALUE AND SET SUBROUTINE RETURN CODE         ** 28490001
**       ACCORDINGLY.                                                ** 28560001
*                                                                     * 28630001
SCN1RETN LA    GR4,KUDECR               SET DECREMENT VALUE.            28700001
         ST    PR1,KUREG1               STORE SCAN TRIPLE POINTER.      28730001
         SR    PR2,GR4                  DECREMENT RETURNED VALUE.       28770001
*                                                                     * 28840001
**       SET XTRP DSECT BASE REGISTER TO POINT AT CURRENT TRIPLE.    ** 28910001
*                                                                     * 28980001
         LR    GR7,PR1                  SET XTRP BASE REGISTER.         29050001
*                                                                     * 29120001
**       RETURN TO CALLING MODULE SETTING RETURN CODE.               ** 29190001
*                                                                     * 29260001
SCN1EXIT IEMKLVE  RC=(PR2)                                              29330001
         EJECT                                                          29400001
*********************************************************************** 29470001
*                                                                     * 29540001
**             KUSCN2 - SET UP 2ND SCAN TABLE AND PERFORM 2ND SCAN.  ** 29610001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS : -        ** 29680001
**        THE RETURN VALUES FOR TRIPLES REQUIRED IN 2ND SCAN ARE SET.** 29750001
**        RETURN VALUES FOR TRIPLES SET BEFORE 1ST SCAN ARE ZEROISED.** 29820001
**        THIS 2ND SCAN ROUTINE USES THE SC2 SCAN FACILITY TO OBTAIN ** 29890001
**        TRIPLES INDIVIDUALLY WITHOUT ANY OUTPUT BEING MADE TO TEXT.** 29960001
**        DICTIONARY REFERENCES OF THE  DOEQ, TO', AND BY' ARE       ** 30030001
**        STORED AND THE COMPILER LABEL FROM CLN2 TRIPLE IS SAVED.   ** 30100001
**        THE SUBROUTINE RETURN CODE VALUE IS :                      ** 30170001
**                       0- NORMAL ONLY.                             ** 30240001
*                                                                     * 30310001
*********************************************************************** 30380001
*                                                                     * 30450001
KUSCN2   IEMKENT  TYPE=2                                                30520001
*                                                                     * 30590001
**       SET STATUS SWITCH TO SHOW TRT TABLE MUST BE SET BEFORE SCN1.** 30660001
*                                                                     * 30730001
         NI    KUSBYT,KUS8OF                                            30800001
         MVI   SCTRT+XTRPITDO,X'00'     ***  -                          30870001
         MVI   SCTRT+XTRPITDP,X'00'       THESE TRIPLES ARE SET BEFORE  30940001
         MVI   SCTRT+XTRPPTCH,X'00'       1ST SCAN AND ARE SET HERE TO  31010001
         MVI   SCTRT+XTRPSUBS,X'00'       GIVE NO RETURN WHEN FOUND.    31080001
         MVI   SCTRT+XTRPSUBO,X'00'                                     31150001
         MVI   SCTRT+XTRPCOMR,X'00'                                     31220001
         MVI   SCTRT+XTRPCOMA,X'00'                                     31290001
         MVI   SCTRT+XTRPSUBP,X'00'                                     31330001
         MVI   SCTRT+XTRPNOP,X'00'                                - *** 31370001
         MVI   SCTRT+XTRPDOEQ,X'4C'     *** -                           31430001
         MVI   SCTRT+XTRPCVP,X'50'        THESE TRIPLES ARE THE ONES    31500001
         MVI   SCTRT+XTRPTOP,X'54'        FROM WHICH RETURN IS REQUIRED 31570001
         MVI   SCTRT+XTRPBYP,X'58'        WHEN ENCOUNTERED DURING 2ND   31640001
         MVI   SCTRT+XTRPTO,X'5C'         SCAN.                         31710001
         MVI   SCTRT+XTRPBY,X'60'                                       31780001
         MVI   SCTRT+XTRPCLN2,X'64'                              -  *** 31850001
*                                                                     * 31920001
**       PERFORM TEXT SCAN FOR WANTED TRIPLES.                       ** 31990001
*                                                                     * 32060001
         LA    GR4,KUDECR               SET SCAN RETURN DECREMENTING    32130001
*                                       VALUE.                          32200001
         L     PR1,KUREG1               RESTORE PR1 REGISTER.           32230001
SCN2STRT BAL   RR,SC3                   PERFORM TEXT SCAN USING SC3 TO  32270001
*                                       PREVENT CURRENT TRIPLE BEING    32340001
*                                       OUTPUT.                         32410001
         ST    PR1,KUREG1               STORE PR1 CONTENTS.             32440001
         SR    PR2,GR4                  DECREMENT RETURN VALUE.         32480001
*                                                                     * 32550001
**       SET XTRP DSECT BASE REGISTER TO POINT AT CURRENT TRIPLE.    ** 32620001
*                                                                     * 32690001
         LR    GR7,PR1                  SET XTRP BASE REGISTER.         32760001
*                                                                     * 32830001
**       BRANCH ON RETURN VALUE TO STORE REQUISITE OPERAND.          ** 32900001
*                                                                     * 32970001
         B     SCN2BTAB(PR2)            USE RETURN CODE TO INDEX BRANCH 33040001
SCN2BTAB B     SCN2ERRS                 END OF PROGRAM - ERROR.         33110001
         B     SCN2DOEQ                 PROCESS DOEQ TRIPLE.            33180001
         B     SCN2STRT                 WHEN CV' RETURN TO SCAN.        33250001
         B     SCN2TOP                  PROCESS TO'  TRIPLE.            33320001
         B     SCN2BYP                  PROCESS BY'  TRIPLE.            33390001
         B     SCN2STRT                 RETURN TO SCAN.                 33460001
         B     SCN2STRT                 RETURN TO SCAN.                 33530001
         B     SCN2CLN2                 PROCESS COMPILER LABEL TRIPLE.  33600001
*                                                                     * 33670001
**       CHECK WHETHER BY' TRIPLE HAS ALREADY BEEN FOUND. IF NOT     ** 33740001
**       STORE DR(BY') IN RESERVED SLOT AND RETURN TO SCAN.          ** 33810001
*                                                                     * 33880001
SCN2BYP  CLC   KUSTBP,KUZERO            CHECK THAT BY' SLOT IS CLEAR.   33950001
         BNE   SCN2DUPL                 IF NOT CLEAR PROCESS ERROR.     34020001
         MVC   KUSTBP,XTRPOP2           STORE DR(BY') IN RESERVED SLOT. 34090001
         MVC   KURGST,XTRPOP1           STORE STEP REGISTER.            34120001
         B     SCN2STRT                 BRANCH TO RESUME SCAN.          34160001
*                                                                     * 34230001
**       CHECK WHETHER TO' TRIPLE HAS ALREADY BEEN FOUND. IF NOT     ** 34300001
**       STORE DR(TO') IN RESERVED SLOT AND RETURN TO SCAN.          ** 34370001
*                                                                     * 34440001
SCN2TOP  CLC   KUSTTP,KUZERO            CHECK THAT TO' SLOT IS CLEAR.   34510001
         BNE   SCN2DUPL                 IF NOT CLEAR PROCESS ERROR.     34580001
         MVC   KUSTTP,XTRPOP2           STORE DR(TO') IN RESERVED SLOT. 34650001
         MVC   KURGLM,XTRPOP1           STORE LIMIT REGISTER.           34680001
         B     SCN2STRT                 BRANCH TO RESUME SCAN.          34720001
*                                                                     * 34790001
**       CHECK WHETHER DOEQ TRIPLE HAS ALREADY BEEN FOUND. IF NOT    ** 34860001
**       STORE DR(DOEQ) IN RESERVED SLOT AND RETURN TO RESUME SCAN.  ** 34930001
*                                                                     * 35000001
SCN2DOEQ CLC   KUSTDO,KUZERO            CHECK THAT DOEQ SLOT IS CLEAR.  35070001
         BNE   SCN2DUPL                 IF NOT CLEAR PROCESS ERROR.     35140001
         MVC   KUSTDO,XTRPOP2           STORE DR(DOEQ) IN RESERVED SLOT 35210001
*                                                                     * 35220001
         TM    XTRPOP1,KUS1ON           IF HIGH ORDER BIT IS ON THEN    35230001
         BZ SCN2STRT                     SR INSTRUCTION MAY BE NO-OP'D. 35240001
         OI    KUABYT,KUS2ON            SET AUX SWITCH ON.              35250001
         B     SCN2STRT                 BRANCH TO RESUME SCAN.          35280001
*                                                                     * 35350001
**       CHECK THAT ALL REQUIRED ELEMENTS OF LOOP CONTROL HAVE BEEN  ** 35420001
**       FOUND.                                                      ** 35490001
*                                                                     * 35560001
SCN2CLN2 CLC   KUSTIT,KUZERO            CHECK THAT ITDO OPERAND HAS     35630001
*                                       BEEN STORED.                    35700001
         BE    SCN2ERRS                 IF NOT STORED, SET ERROR CODE.  35770001
         CLC   KUSTCV,KUZERO            CHECK DR(CV) HAS BEEN STORED.   35840001
         BE    SCN2ERRS                 IF NOT STORED  SET ERROR CODE.  35910001
         CLC   KUSTDO,KUZERO            CHECK DR(DOEQ) HAS BEEN STORED. 35980001
         BE    SCN2ERRS                 IF NOT STORED, SET ERROR CODE.  36050001
         CLC   KUSTTP,KUZERO            CHECK DR(TO') HAS BEEN STORED.  36120001
         BE    SCN2ERRS                 IF NOT STORED, SET ERROR CODE.  36190001
         CLC   KUSTBP,KUZERO            CHECK DR(BY') HAS BEEN STORED.  36260001
         BE    SCN2ERRS                 IF NOT STORED, SET ERROR CODE.  36330001
*                                                                     * 36400001
**       STORE COMPILER LABEL FROM CLN2 TRIPLE AND EXIT.             ** 36470001
*                                                                     * 36540001
         MVC   KUPLAB,XTRPOP2           STORE PROLOGUE COMPILER LABEL.  36610001
         B     SCN2EXIT                 BRANCH TO LEAVE SUBROUTINE.     36680001
*                                                                     * 36750001
**       SET ERROR INDICATOR AND PERFORM ABORT                       ** 36820001
*                                                                     * 36890001
SCN2ERRS MVI   KUERBT,X'02'             ERROR PARAMETER NUMBER - 2.     36960001
         B     KVERRS                   GO TO ERROR ABORT ROUTINE.      37030001
SCN2DUPL MVI   KUERBT,X'03'             ERROR PARAMETER NUMBER - 3.     37100001
         B     KVERRS                   GO TO ERROR ABORT ROUTINE       37170001
*                                                                     * 37240001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE              ** 37310001
*                                                                     * 37380001
SCN2EXIT IEMKLVE                                                        37450001
         EJECT                                                          37520001
*********************************************************************** 37590001
*                                                                     * 37660001
*                                                                     * 37730001
**             KUITDO - PROCESS ITDO TRIPLE.                         ** 37800001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 37870001
**        THE ITDO TRIPLE 2ND OPERAND IS TESTED TO DETERMINE WHETHER ** 37940001
**        OR NOT LOOP HAS BEEN MARKED OPTIMIZABLE.                   ** 38010001
**        THE APPROPRIATE STATUS SWITCH IS SET ON IF THE 2ND OPERAND ** 38080001
**        HIGH ORDER BIT IS ON INDICATING THAT SINDEX REGISTERS ARE  ** 38150001
**        AVAILABLE.                                                 ** 38220001
**        THE SUBROUTINE RETURN CODE VALUES ARE :-                   ** 38290001
**                       O - OPTIMIZABLE                             ** 38360001
**                       4 - UNOPTIMIZABLE.                          ** 38430001
*********************************************************************** 38500001
*                                                                     * 38570001
KUITDO   IEMKENT  TYPE=LL2                                              38640001
         SR    GR4,GR4                  ZEROIZE REG TO CARRY RETN CODE. 38710001
         CLC   XTRPOP2,KUZERO           TEST 2ND OPERAND FOR ZERO.      38780001
         BE    ITDOUNOP                 BRANCH TO SET UNOPTIMIZABLE     38850001
*                                        RETURN CODE IF ZERO.           38920001
         MVC   KUSTIT,XTRPOP2           STORE 2ND OP IN RESERVED SLOT.  38990001
*                                                                     * 39060001
**       LOOP IS MARKED AS OPTIMIZABLE. CHECK STACK COUNT. IF ITDO   ** 39130001
**       NEST IMPLEMENTATION LIMIT FOR THIS PHASE (49) IS EXCEEDED   ** 39200001
**       INDICATE ERROR.                                             ** 39270001
*                                                                     * 39340001
         SR    GR5,GR5                  INCREMENT THE NESTING LEVEL     39410001
         IC    GR5,KUNEST                COUNT BEFORE COMPARISON        39480001
         LA    GR5,1(0,GR5)              WITH THE NESTING LEVEL LIMIT.  39550001
         STC   GR5,KUNEST                                               39620001
         CLI   KUNEST,KULMIT            TEST ITDO NESTING LEVEL.        39690001
         BNH   ITDOCONT                 IF WITHIN LIMIT CONTINUE.       39760001
*                                                                     * 39780001
         MVI   KUERBT,X'07'             ERROR PARAMETER NUMBER - 7.     39800001
         B     KVERRS                   BRANCH TO PHASE ERROR ROUTINE.  39820001
*                                                                     * 39840001
         B     KVERRS                   BRANCH TO PHASE ERROR ROUTINE.  39900001
ITDOCONT TM    XTRPOP2,KUTFLG           TEST 2ND OPERAND HIGH ORDER BIT 39970001
         BZ    ITDOS1OF                 IF SINDEXES USED SET STATUS     40040001
*                                       SWITCH 1 ON .                   40110001
         NI    KUSTIT,KUS1OF            SET HIGH ORDER BIT OFF.         40180001
         OI    KUSBYT,KUS1ON            SET SWITCH 1 ON - SNDX USED     40250001
         B     ITDOEXIT                 BRANCH TO LEAVE POINT.          40320001
ITDOS1OF NI    KUSBYT,KUS1OF            SET SW1 OFF - SNDXS NOT USED.   40390001
         B     ITDOEXIT                 BRANCH TO LEAVE POINT.          40460001
ITDOUNOP LA    GR4,KUUNOP               SET UNOPT RETURN CODE VALUE     40530001
*                                                                     * 40600001
**       RETURN TO CALLING MODULE WITH RETURN CODE SET.              ** 40670001
*                                                                     * 40740001
ITDOEXIT IEMKLVE  RC=(GR4)                                              40810001
         EJECT                                                          40880001
*********************************************************************** 40950001
*                                                                     * 41020001
**             KUCVAR - PROCESS CV OR *CV TRIPLE.                    ** 41090001
**       THIS SUBROUTINE OBTAINS THE NEXT TRIPLE, CHECKS THAT IT IS  ** 41160001
**       A CV OR *CV TRIPLE. STATUS SWITCH 2 IS SET ON IF CV IS A    ** 41200001
**       COMPILER GENERATED TEMPORARY. SWITCH 3 IS SET ON IF STORE   ** 41240001
**       AT HEAD OF LOOP MAY BE DROPPED. AUXILIARY STATUS (KUABYT)   ** 41280001
**       SWITCH 3 IS SET ON IF LOAD MAY BE DROPPED BECAUSE CV IS     ** 41320001
**       NOT ALTERED. BOTH SWITCHES ARE SET FOR AN *CV TRIPLE AND    ** 41370001
**       SWITCH 4 IS SET ON ALSO. THE RETURN CODE VALUE IS :-        ** 41440001
**                       0 - NORMAL ONLY.                            ** 41510001
*                                                                     * 41580001
*********************************************************************** 41650001
*                                                                     * 41720001
KUCVAR   IEMKENT  TYPE=2                                                41790001
*                                                                     * 41860001
**       OBTAIN NEXT TRIPLE AFTER ITDO, UPDATE XTRP DSECT BASE AND   ** 41930001
**       STORE OPERANDS.                                             ** 42000001
*                                                                     * 42070001
CVARFIND L     PR1,KUREG1               SET SCAN INPUT POINTER.         42100001
         BAL   RR,SC5                   SKIP CURRENT TRIPLE AND GET NXT 42140001
         ST    PR1,KUREG1                                               42170001
         LR    GR7,PR1                                                  42210001
         MVC   KUSTCV,XTRPOP2           STORE 2ND OP IN RESERVED SLOT.  42280001
         MVC   KUSTOP,XTRPOP1           STORE 1ST OP IN RESERVED SLOT.  42350001
         NI    KUSTOP,KUS1OF            ENSURE HIGH ORDER BIT IS ZERO.  42420001
         NI    KUSTOP,KUS2OF            ENSURE NEXT TO H-ORDER BIT OFF. 42450001
*                                                                     * 42490001
**       IF NOT CV, *CV OR NOP TRIPLE THEN AN ERROR HAS OCCURRED      * 42520001
**       IN A PREVIOUS PHASE.                                        ** 42550001
*                                                                     * 42580001
         CLI   XTRPCODE,XTRPNOP         ANY NOP TRIPLE FOUND HERE MAY   42610001
         BE    CVARFIND                  BE IGNORED AND DROPPED.        42640001
         CLI   XTRPCODE,XTRPSTCV        TEST FOR *CV TRIPLE.            42700001
         BE    CVARSTCV                 BRANCH ON *CV.                  42770001
         CLI   XTRPCODE,XTRPCV          TEST FOR CV TRIPLE.             42840001
         BE    CVARTEMP                 BRANCH ON CV.                   42910001
*                                                                     * 42950001
         MVI   KUERBT,X'04'             ERROR PARAMETER NUMBER - 4.     42990001
         B     KVERRS                   BRANCH TO PHASE ERROR ROUTINE.  43050001
*                                                                     * 43120001
**       TEST CV TRIPLE TO DETERMINE WHETHER IT IS COMPILER GENERATED** 43190001
**       TEMPORARY AND SET SWITCH 2 ACCORDINGLY.                     ** 43260001
**       CONVERT DR(CV) TO ABSOLUTE AND OBTAIN DICTIONARY ENTRY OF CV** 43400001
*                                                                     * 43430001
CVARTEMP MVC   PAR1+2(2),XTRPOP2                                        43470001
*                                       SET DR(CV) IN PARAMETER WORD.   43540001
         L     LR,ZDRFAB                SET ADDRESS OF CONVERSION       43680001
*                                        ROUTINE IN BRANCH REGISTER.    43750001
         BALR  RR,LR                    GET ABSOLUTE DICTIONARY ADDRESS 43820001
         L     GR4,PAR1                 SET BASE POINTER TO DICT ENTRY. 43960001
         CLI   KUDCDE(GR4),KUPARM       TEST DIC CODE FOR FORMAL        44030001
*                                       PARAMETER/COMPILER GEN TEMP.    44100001
         BNE   CVARS2OF                 BRANCH NOT TEMPORARY/F-PARAMTER 44170001
         TM    KUDOTH(GR4),KUFORM       TEST WHETHER FORMAL PARAMETER.  44240001
         BO    CVARS2OF                 BRANCH NOT TEMPORARY.           44310001
         OI    KUSBYT,KUS2ON            SET SWITCH 2 ON.                44380001
         B     CVARSNOP                 BRANCH TO TEST IF SAFE TO NO-OP 44420001
*                                        LOAD AND STORE.                44460001
CVARS2OF NI    KUSBYT,KUS2OF            SET SWITCH 2 OFF.               44520001
*                                                                     * 44590001
**       TEST CV OP1 HIGH ORDER BITS TO CHECK IF STORE AND LOAD      ** 44650001
**       EITHER SIDE OF LOOP MAY BE IGNORED OR NOT.                  ** 44710001
*                                                                     * 44770001
CVARSNOP NI    KUSBYT,KUS3OF            SET OFF BOTH SWITCHES USED TO   44830001
         NI    KUABYT,KUS3OF             INDICATE NO-OPS.               44890001
         TM    XTRPOP1,KUS1ON           IF HIGH ORDER BIT IS ON         44950001
         BZ    CVARLNOP                  SWITCH 3 ON TO SHOW STORE MAY  45010001
         OI    KUSBYT,KUS3ON             BE NO-OP'D                     45070001
CVARLNOP TM    XTRPOP1,KUS2ON           IF NEXT TO HIGH ORDER BIT IS ON 45130001
         BZ    CVAREXIT                  SET SWITCH 3 ON IN AUXILIARY   45190001
         OI    KUABYT,KUS3ON             BYTE TO SHOWLOAD TO BE DROPPED 45250001
         B     CVAREXIT                 BRANCH TO LEAVE SUBROUTINE.     45360001
*                                                                     * 45430001
**       SET SWITCH  4  TO SHOW *CV TRIPLE. SET SWITCHES 2 AND 3 AS  ** 45500001
**       CV TYPE IS UNIMPORTANT IN THIS CASE.                        ** 45570001
*                                                                     * 45640001
CVARSTCV OI    KUSBYT,KUS2ON            SET SWITCH 2 ON.                45710001
         OI    KUSBYT,KUS3ON            SET SWITCH 3 ON.                45780001
         OI    KUSBYT,KUS4ON            SET SWITCH 4 ON.                45850001
*                                                                     * 45920001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE.             ** 45990001
*                                                                     * 46060001
CVAREXIT IEMKLVE                                                        46130001
         EJECT                                                          46200001
*********************************************************************** 46270001
*                                                                     * 46340001
**             KUSTEP - PROCESS STEP SUBROUTINE.                     ** 46410001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 46480001
**        THE DOEQ DICTIONARY REFERENCE IS CHECKED AND THE           ** 46550001
**        APPROPRIATE SWITCH IS SET IF INITIAL IS A FIXED BINARY     ** 46620001
**       INTEGER VARIABLE OR CONSTANT.                               ** 46690001
**        THE LOOP STEP IS CHECKED TO DETERMINE WHETHER STEP IS A    ** 46760001
**        CONSTANT OR VARIABLE.                                      ** 46830001
**        THE SINDEX AVAILABILITY STATUS SWITCH IS TESTED AND THE    ** 46900001
**        SUBROUTINE RETURN CODE IS SET DEPENDING ON ABOVE FACTORS.  ** 46970001
**        THE SUBROUTINE RETURN CODE VALUES ARE :-                   ** 47040001
**                       O -  STEP CONSTANT.                         ** 47110001
**                       4 -  STEP UNKNOWN, SINDEXES USED.           ** 47180001
**                       8 -  STEP UNKNOWN, SINDEXES NOT USED.       ** 47250001
**                                                                   ** 47320001
*                                                                     * 47390001
*********************************************************************** 47460001
*                                                                     * 47530001
KUSTEP   IEMKENT  TYPE=2                                                47570001
*                                                                     * 47610001
**       SET AUX SW 1 ON TO SHOW THAT LOOP CONTROL SKELETON WILL BE  ** 47620001
**       CREATED AND NEW COMPILER GENERATED LABELS WILL THEREFORE BE ** 47630001
**       REQUIRED FROM ROUTINE KUSETS.                               ** 47640001
*                                                                     * 47650001
         OI    KUABYT,KUS1ON            NEW LABELS WILL BE NEEDED.      47660001
*                                                                     * 47670001
**       OBTAIN DICTIONARY ENTRY OF INITIAL (DOEQ).                  ** 47740001
*                                                                     * 47810001
STEPDOEQ MVC   PAR1+2(2),KUSTDO                                         47880001
*                                       SET DR(DOEQ) IN PARAMETER WORD. 47950001
         L     LR,ZDRFAB                SET ADDRESS OF CONVERSION       48020001
*                                        ROUTINE IN BRANCH REGISTER.    48090001
         BALR  RR,LR                    GET ABSOLUTE DICTIONARY ADDRESS 48160001
         L     GR4,PAR1                 SET BASE POINTER TO DICTIONARY  48230001
*                                        ENTRY.                         48300001
*                                                                     * 48370001
**       TEST DOEQ DICTIONARY ENTRY FOR FIXED BINARY INTEGER. SET    ** 48440001
**       SWITCH 5 ON IF DOEQ IS FIXED BINARY INTEGER                 ** 48510001
*                                                                     * 48580001
         NI    KUSBYT,KUS5OF            SET SWICH 5 OFF.                48650001
         CLI   KUDCDE(GR4),KUCNST       IS THIS A CONSTANT.             48700001
         BE    STEPS5ON                 IF IT IS SET SWITCH 5 ON.       48750001
         CLI   KUDATA(GR4),KUBRFL       IS THIS VARIABLE REAL           48800001
         BNE   STEPDRBY                  FIXED BINARY LONG OR           48850001
         CLI   KUDATA(GR4),KUBRFS        SHORT.  IF NEITHER THEN        48900001
         BNE   STEPDRBY                  LEAVE SWITCH 5 OFF.            48950001
         CLI   KUSCLE(GR4),KUINTG       TEST IF INTEGER.                49000001
         BNE   STEPDRBY                 BRANCH IF NOT INTEGER.          49070001
STEPS5ON OI    KUSBYT,KUS5ON            CONSTANT OR VARIABLE BIN INTG.  49170001
*                                        SWITCH 5 ON.                   49210001
*                                                                     * 49280001
**       OBTAIN DICTIONARY ENTRY OF STEP (BY).                       ** 49350001
*                                                                     * 49420001
STEPDRBY SR    GR5,GR5                  INITIALISE RETURN VALUE.        49440001
         TM    KUSBYT,KUS4ON            IS THIS A *CV CASE.             49460001
         BO    STEPPOST                 BRANCH IF YES (STEP UNITY).     49480001
         MVC   PAR1+2(2),KUSTBP                                         49500001
*                                       SET DR(BY) IN PARAMETER AREA.   49560001
         L     LR,ZDRFAB                SET ADDRESS OF CONVERSION       49630001
*                                        ROUTINE IN BRANCH REGISTER.    49700001
         BALR  RR,LR                    GET ADDRESS OF DICTIONARY ENTRY 49770001
         L     GR4,PAR1                 SET BASE POINTER TO DICTIONARY  49840001
*                                        ENTRY.                         49910001
*                                                                     * 49980001
**       CHECK STEP TYPE AND IF VARIABLE WHETHER OR NOT SINDEXES ARE ** 50050001
**       USED. SET RETURN CODE VALUE ACCORDINGLY.                    ** 50120001
*                                                                     * 50190001
         SR    GR5,GR5                  INITIALISE RETURN VALUE TO ZERO 50220001
         CLI   0(GR4),KUCNST            CHECK FOR CONSTANT.             50340001
         BE    STEPSIGN                 BRANCH IF CONSTANT TO TEST SIGN 50400001
         TM    KUSBYT,KUS1ON            CHECK IF SINDEXES USED.         50470001
         BO    STEPSNDX                 BRANCH IF SINDEXES USED.        50540001
         LA    GR5,KUNSNX               SET NON SNDX RETURN CODE VALUE. 50610001
         B     STEPEXIT                 BRANCH TO LEAVE SUBROUTINE.     50680001
STEPSNDX LA    GR5,KUSNDX               SET SNDX AVAILABLE RETURN CODE. 50750001
         B     STEPEXIT                 BRANCH TO LEAVE SUBROUTINE.     50820001
STEPSIGN CLI   14(GR4),X'73'            CHECK IF -VE STEP.              50890001
         BE    STEPEXIT                 EXIT ON STEP BEING -VE.         50960001
STEPPOST OI    KUSBYT,KUS6ON            SET STATUS SWITCH 6 ON.         51030001
*                                                                     * 51100001
**       RETURN TO CALLING MODULE WITH RETURN CODE SET.              ** 51170001
*                                                                     * 51240001
STEPEXIT IEMKLVE  RC=(GR5)                                              51310001
         EJECT                                                          51380001
*********************************************************************** 51450001
*                                                                     * 51520001
**             KUSKL3 - GENERATE SKELETON FOR CONSTANT STEP LOOP     ** 51590001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS : -        ** 51660001
**        THE KUSKL3 SKELETON IS COPIED INTO A STORAGE AREA AND      ** 51730001
**        KUSKL3 IS THEN MODIFIED AND COMPLETED AS REQUIRED.         ** 51800001
**        THE MODIFICATIONS CONSIST OF DELETING TRIPLE AND PSEUDO-   *  51870001
**        CODE ITEMS MADE REDUNDANT BY PRESENCE OF *CV TRIPLE.       ** 51940001
**        THE LOOP IS CORRECTED FOR STEP SIGN.                       ** 52010001
**        COMPILER LABELS ARE INSERTED AS REQUIRED.                  ** 52080001
**        SYMBOLIC REGISTERS ARE ALLOCATED FOR NO *CV CASE.          ** 52150001
**        THE LOOP PROLOGUE IS OUTPUT TO TEXT AND EPILOGUE IS STORED ** 52220001
**        IN SCRATCH CORE STACK AS TYPE 3 FOR NON *CV (CV) CASE OR   ** 52290001
**        TYPE 4 FOR *CV CASE.                                       ** 52360001
**        FINALLY STORED KUSKL3 SKELETON IS RESTORED.                ** 52430001
**        THE SUBROUTINE RETURN CODE VALUE IS : -                    ** 52500001
**                       0 - NORMAL ONLY.                            ** 52570001
*                                                                     * 52640001
*********************************************************************** 52710001
*                                                                     * 52780001
KUSKL3   IEMKENT  TYPE=2                                                52850001
*                                                                     * 52920001
**       STORE BASIC SKELETON BEFORE MODIFICATION.                   ** 52990001
*                                                                     * 53060001
         MVC   KUSKLT(KULEN3),KUSKEL3   STORE CONSTANT STEP SKELETON.   53130001
*                                                                     * 53200001
**       TEST SWITCH 4 FOR *CV PRESENT.                              ** 53270001
*                                                                     * 53340001
         TM    KUSBYT,KUS4ON            TEST FOR *CV.                   53410001
         BZ    SKL3CVAR                 BRANCH IF NO *CV                53480001
*                                                                     * 53550001
**       FOR *CV NO-OP LOAD AND STORE INSTRUCTIONS FOR CV, STEP,     ** 53620001
**       LIMIT AND INITIAL. OPERANDS THAT NORMALLY CONTAIN SYMBOLIC  ** 53690001
**       REGISTERS ARE ALLOCATED REGISTER VALUES FROM CV, STEP AND   ** 53760001
**       LIMIT OPERANDS.SKELETON MAY BE CONSIDERED TO START AT       ** 53830001
**       PROLOGUE SR INSTRUCTION FOR *CV CASE.                       ** 53900001
*                                                                     * 53970001
         MVC   KU3O07,KUSTCV            ALTER LOOP PROLOGUE SR          54040001
         MVC   KU3T07,KUSTBP             INSTRUCTION.                   54110001
         MVC   KU3O08,KUSTTP            ALTER LOOP PROLOGUE BCTR.       54180001
         MVC   KU3T08,KUSTBP             INSTRUCTION.                   54250001
         MVC   KU3C05(5),KUIGNR        NO-OP THE KEEP             62595 54270072
         MVC   KU3C06(5),KUIGNR        NO-OP THE KEEP             62595 54290072
*                                                                     * 54320001
**       JUMP, STORE AND REGISTER STATUS BYTES WHICH ARE THE LAST 3  ** 54390001
**       ITEMS OF  LOOP PROLOGUE ARE IGNORED WHEN THERE IS AN *CV.   ** 54460001
**       LIKEWISE FIRST 3 ITEMS OF LOOP EPILOGUE MAY BE IGNORED FOR  ** 54530001
**       *CV CASE.                                                   ** 54600001
*                                                                     * 54670001
         MVC   KU3O14,KUSTCV            REGISTER PROVIDED BY *CV OPRND. 54740001
         MVC   KU3O15,KUSTBP            REGISTER PROVIDED BY STEP OPRND 54810001
*                                        INSTEAD OF SYMBOLIC REGISTER.  54880001
*                                                                     * 54950001
**       IN *CV CASE THE LAST 4 ITEMS OF EPILOGUE (JUMP TRIPLE AND   ** 55020001
**       CONTENTS) MAY BE IGNORED. BRANCH TO FILL IN COMPILER LABELS.** 55090001
*                                                                     * 55160001
         B     SKL3LABL                 BRANCH TO FILL IN LABELS.       55230001
*                                                                     * 55300001
**       THE FOLLOWING IS PERFORMED IN THE NON *CV CASE. FIRST       ** 55370001
**       TEST INITIAL SWITCH 5. IF INITIAL FIXED BINARY INTEGER FIRST** 55440001
**       TRIPLE (ASGN) MAY BE NOP'D.                                 ** 55510001
*                                                                     * 55580001
SKL3CVAR MVC   KURGCV,KUSTOP            SYM REG GIVEN IN CV 1ST OP.     55650001
         TM    KUSBYT,KUS5ON            TEST TYPE OF INITIAL.           55720001
         BZ    SKL3STRT                 BRANCH IF NOT FIX BIN INTEGER.  55790001
         MVI   KU3C01,XTRPNOP           SET NOP CODE.                   55860001
         MVC   KU3T02,KUSTDO            INSERT DR(INIT) INSTEAD OF      55930001
*                                        DR(CV).                        56000001
         B     SKL3CONT                 BRANCH TO FILL REMAINING SYM    56070001
*                                        REGISTERS AND TRIPLE OPERANDS. 56140001
*                                                                     * 56210001
**       FOR INIT NOT FIX BIN INTEGER FILL ASGN TRIPLE OPERANDS AND  ** 56280001
**       FIRST LOAD OPERAND.                                         ** 56350001
*                                                                     * 56420001
SKL3STRT MVC   KU3O01,KUSTCV            SET DR(CV) AND DR(INIT) IN      56490001
         MVC   KU3T01,KUSTDO             ASGN TRIPLE.                   56560001
         MVC   KU3T02,KUSTCV            SET DR(CV) IN 2ND OP OF 1ST     56630001
*                                        LOAD INSTRUCTION.              56700001
*                                                                     * 56770001
**       INSERT REMAINING DICTIONARY REFERENCES AS REQUIRED.         ** 56840001
*                                                                     * 56910001
SKL3CONT MVC   KU3T03,KUSTBP            SET DR(STEP) IN 2ND OPERAND.    56980001
         MVC   KU3T04,KUSTTP            SET DR(LIMIT) IN 2ND OPERAND.   57050001
         MVC   KU3T11,KUSTCV            SET DR(CV) IN 2ND OPERANDS OF   57120001
         MVC   KU3T12,KUSTCV             STORE AND LOAD INSTRUCTIONS.   57190001
         MVC   KU3T17,KUSTCV                                            57260001
*                                                                     * 57330001
**       INSERT SYMBOLIC REGISTERS IN SKELETON. THESE REGISTERS HAVE ** 57400001
**       ALREADY BEEN OBTAINED AND INSERTED IN RESPECTIVE STORAGE    ** 57470001
**       SLOTS. IN THIS CASE (NON *CV CONSTANT STEP) THE SYMBOLIC    ** 57540001
**       REGISTER FOR CV IS ALLOCATED BEFORE KU AND GIVEN IN FIRST   ** 57610001
**       OPERAND OF CV TRIPLE.                                       ** 57680001
*                                                                     * 57750001
         MVC   KU3O02,KURGCV            SET SYM REG FOR CV IN LOAD.     57820001
         MVC   KU3O03,KURGST            SET SYM REG FOR STEP IN LOAD.   57890001
         MVC   KU3O04,KURGLM            SET SYM REG FOR LIMIT IN LOAD.  57960001
         MVC   KU3T05,KURGST            SET SYM REG FOR STEP IN KEP1.   58030001
         MVC   KU3T06,KURGLM            SET SYM REG FOR LIMIT IN KEP1.  58100001
         MVC   KU3O07,KURGCV            SET SYM REGS FOR CV AND STEP    58170001
         MVC   KU3T07,KURGST             IN SR INSTRUCTION.             58240001
         MVC   KU3O08,KURGLM            SET SYM REGS FOR LIMIT AND STEP 58310001
         MVC   KU3O11,KURGCV            SET SYM REG FOR CV IN STORE.    58450001
*                                                                     * 58520001
**       DO GROUP.                                                   ** 58590001
*                                                                     * 58660001
         MVC   KU3O12,KURGCV            SET SYM REG FOR CV IN LOAD.     58730001
         MVC   KU3O14,KURGCV            SET SYM REG FOR CV IN BXLE.     58800001
         MVC   KU3O15,KURGST            SET SYM REG FOR STEP IN OSM2.   58870001
         MVC   KU3O17,KURGCV            SET SYM REG FOR CV IN STORE.    58940001
         MVC   KU3O18,KURGST            SET SYM REG FOR STEP IN DROP.   59010001
         MVC   KU3O19,KURGLM            SET SYM REG FOR LIMIT IN DROP.  59080001
         OI    KUSBYT,KUS7ON            SET SWITCH TO SHOW GENERATED    59085001
*                                        SYMBOLIC REGS HAVE BEEN USED.  59090001
*                                                                     * 59095001
**       IF CV IS A COMPILER GENERATED TEMPORARY THEN LOAD AND       ** 59100001
**       STORE INSTRUCTIONS IN LOOP EPILOGUE MAY BE DROPPED          ** 59105001
*                                                                     * 59110001
         TM    KUSBYT,KUS2ON            CHECK IF COMP. GEN. TEMPORARY.  59115001
         BZ    SKL3SNOP                 BRANCH IF NOT.                  59125001
         MVC   KU3C12(5),KUIGNR          ST AND LOAD INSTRUCTIONS.      59140001
         MVC   KU3C17(5),KUIGNR                                         59145001
*                                                                     * 59145401
**       NO-OP LOAD AND STORE EITHER SIDE OF LOOP IF PERMITTED       ** 59145801
*                                                                     * 59146201
SKL3SNOP TM    KUSBYT,KUS3ON            IF SWITCH 3 IS ON THEN PUT      59146601
         BZ    SKL3LNOP                 IGNORE OVER STORE INSTRUCTION   59147001
         MVC   KU3C11(5),KUIGNR          AT HEAD OF LOOP.               59147401
*                                                                     * 59147801
SKL3LNOP TM    KUABYT,KUS3ON            IF SWITCH 3 (AUX) IS ON THEN    59148201
         BZ    SKL3LABL                  PUT IGNORE OVER LOAD AT TAIL   59148601
         MVC   KU3C12(5),KUIGNR          OF LOOP.                       59149001
*                                                                     * 59150001
**       THE FOLLOWING IS COMMON TO *CV AND CV CASES. INSERT LABELS  ** 59220001
**       IN SKELETON.                                                ** 59290001
*                                                                     * 59360001
SKL3LABL MVC   KU3T09,KULAB1            INSERT GENERATED LABEL.         59430001
         MVC   KU3T10,KUPLAB            INSERT LABEL FROM CLN2 IN LOOP  59500001
*                                        PROLOGUE (CL.2).               59570001
         MVC   KU3T13,KULAB1            INSERT GENERATED LABEL.         59640001
         MVC   KU3T14,KUPLAB            INSERT LABEL FROM CLN2 IN LOOP  59710001
*                                        PROLOGUE (CL.2).               59780001
         TM    KUABYT,KUS2ON            IS SR INSTRUCTION TO BE NO-OP'D 59850001
         BZ    SKL3SIGN                 IF NOT BRANCH TO FILL IN        59920001
         MVC   KU3C07(5),KUIGNR          LABELS . OTHERWISE NO-OP SR    59990001
*                                                                     * 60060001
**       THE STEP SIGN IS CHECKED AND THE BXLE INSTRUCTION IS        ** 60130001
**       REPLACED BY BXH IF STEP IS NEGATIVE. THE BCTR INSTRUCTION IN** 60200001
**       PROLOGUE IS NOP'D IF STEP IS +VE.                           ** 60270001
*                                                                     * 60340001
SKL3SIGN TM    KUSBYT,KUS6ON            TEST STATUS SWITCH 6.           60410001
         BO    SKL3NOPR                 BRANCH IF STEP +VE              60480001
         MVI   KU3C14,KUBXH             SET UP BXH OP CODE.             60550001
         B     SKL3CHCK                 BRANCH TO INSERT GENRTD LOOP.   60620001
SKL3NOPR MVC   KU3C08(5),KUIGNR         NOP BCTR WITH IGNORE P-S ITEM.  60720001
*                                                                     * 60970001
**       THE CONSTANT STEP LOOP SKELETON IS COMPLETE. THE SKELETON   ** 61040001
**       PROLOGUE IS NOW INSERTED IN OUTPUT TEXT WHILE THE SKELETON  ** 61110001
**       EPILOGUE IS STACKED IN SCRATCH CORE. TWO ROUTINES TO OUTPUT ** 61180001
**       THE SKELETON PROLOGUE TO TEXT FOLLOW ONE FOR THE *CV CASE   ** 61250001
**       AND ONE FOR CV CASE. THERE ARE TWO EPILOGUE TYPES DESIGNATED** 61320001
**       AS TYPES 3 AND 4 FOR CV AND *CV CASES RESPECTIVELY.         ** 61390001
SKL3CHCK TM    KUSBYT,KUS4ON            TEST FOR *CV CASE.              61460001
         BO    SKL3STCV                 BRANCH IF *CV.                  61530001
*                                                                     * 61536020
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE TO ** 61542020
**       BE OUTPUT TO TEXT.                                          ** 61548020
*                                                                     * 61554020
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.  32286 61560020
         LA    GR4,KU3C03               SET ADDRESS OF PSEUDO-    32286 61566020
         ST    GR4,PAR1                  CODE IN PAR1.            32286 61572020
         LA    GR4,10                   SET LENGTH OF CODE TO BE  32286 61578020
         ST    GR4,PAR2                  OUTPUT IN PAR2           32286 61584020
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE.       32286 61590020
*                                                                     * 61600001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF ASGN TRIPLE AND** 61670001
**       OUTPUT TRIPLE TO TEXT. THIS CODE IS FOR CV CASE.            ** 61740001
*                                                                     * 61810001
         LA    GR4,KU3C01               SET ADDRESS OF TRIPLE IN THE    61880001
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           61950001
         LA    GR4,KUTRLN               SET LENGTH OF CODE TO BE OUTPUT 62020001
         ST    GR4,PAR2                  IN PAR2 PARAMETER WORD.        62090001
         BAL   RR,MV3A                  OUPUT TRIPLE TO TEXT.           62160001
*                                                                     * 62230001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE TO ** 62300001
**       BE OUTPUT TO TEXT.                                          ** 62370001
*                                                                     * 62440001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS BYTES.  62510001
         LA    GR4,KU3C02               SET ADDRESS OF PSEUDO-CODE      62580001
         ST    GR4,PAR1                  IN PAR1 PARAMETER WORD.        62650001
         LA    GR4,KUPSC1               SET LENGTH OF CODE TO BE OUTPUT 62720001
         ST    GR4,PAR2                  IN PAR2 PARAMETER WORD.        62790001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     62860001
*                                                                     * 62930001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF CLN2 TRIPLE AND** 63000001
**       OUTPUT TRIPLE TO TEXT.                                      ** 63070001
*                                                                     * 63140001
         LA    GR4,KU3C10               SET ADDRESS OF TRIPLE IN THE    63210001
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           63280001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE IN THE     63350001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           63420001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          63490001
*                                                                     * 63560001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF STORE PSEUDO-  ** 63630001
**       CODE ITEM AND OUTPUT TO TEXT.                               ** 63700001
*                                                                     * 63770001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS BYTES.  63840001
         LA    GR4,KU3C11               SET ADDRESS OF PSEUD-CODE ITEM  63910001
         ST    GR4,PAR1                  IN PAR1 PARAMETER WORD.        63980001
         LA    GR4,KUPSC2               SET LENGTH OF PSEUDO-CODE ITEM  64050001
         ST    GR4,PAR2                  IN PAR2 PARAMETER WORD.        64120001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE ITEM TO TEXT 64190001
*                                                                     * 64260001
**       THE LOOP SKELETON EPILOGUE IS STACKED IN SCRATCH CORE WITH  ** 64330001
**       AN EXTRA 3 BYTE TYPE MARKER. THE MARKER CONTAINS THE        ** 64400001
**       ITDO 2ND OPERAND AND THE TYPE OF LOOP TO WHICH THE EPILOGUE ** 64470001
**       BELONGS. THIS IS EPILOGUE TYPE 3.                           ** 64540001
*                                                                     * 64610001
         L     GR4,KUSCPT               SET STACK POINTER IN REGISTER.  64680001
         MVC   KUMLEN(KUEPL3,GR4),KU3C12                                64750001
*                                       STORE SKELETON IN SCRATCH CORE. 64820001
         LA    GR4,KUMLEN+KUEPL3(GR4)   UPDATE STACK POINTER BY LENGTH  64890001
*                                        OF EPILOGUE + 3 BYTE MARKER.   64960001
         MVC   0(2,GR4),KUSTIT          INSERT ITDO 2ND OPERAND.        65030001
         MVI   2(GR4),KUMRK3            INSERT MARKER TO SHOW EPILOGUE  65100001
*                                        IS FOR SKELETON TYPE 3.        65170001
         ST    GR4,KUSCPT               SAVE STACK POINTER.             65240001
         B     SKL3REST                 BRANCH TO RESTORE BASIC         65310001
*                                        SKELETON.                      65380001
*                                                                     * 65450001
**       THE FOLLOWING CODE IS FOR THE *CV CASE. SET PAR1 AND PAR2   ** 65520001
**       WITH THE ADDRESS AND LENGTH OF PSEUDO-CODE ITEMS TO BE      ** 65590001
**       OUTPUT TO TEXT.                                             ** 65660001
*                                                                     * 65730001
SKL3STCV LA    GR4,KU3C07               SET ADDRESS OF PSEUDO-CODE      65800001
         ST    GR4,PAR1                  GROUP IN PAR1 PARAMETER WORD.  65870001
         LA    GR4,KUPSC3               SET LENGTH OF PSEUDO-CODE GROUP 65940001
         ST    GR4,PAR2                  IN PAR2 PARAMETER WORD.        66010001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS BYTES.  66080001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE GROUP TO     66150001
*                                        TEXT.                          66220001
*                                                                     * 66227001
**       OUTPUT THE PROLOGUE COMPILRR LABEL TO TEXT.                 ** 66234001
*                                                                     * 66241001
         LA    GR4,KU3C10               SET ADDRESS OF LABEL ITEM IN    66248001
         ST    GR4,PAR1                  PAR1.                          66255001
         LA    GR4,KUTRLN               SET LENGTH OF LABEL TRIPLE      66262001
         ST    GR4,PAR2                  IN PAR2.                       66269001
         BAL   RR,MV3A                  OUTPUT LABEL TO TEXT.           66276001
*                                                                     * 66290001
**       THE LOOP SKELETON EPILOGUE IS STACKED IN SCRATCH CORE WITH  ** 66360001
**       AN EXTRA 3   BYTE TYPE MARKER. THE MARKER CONTAINS THE      ** 66430001
**       ITDO 2ND OPERAND AND THE TYPE OF LOOP TO WHICH THE EPILOGUE ** 66500001
**       BELONGS. THIS IS EPILOGUE TYPE 4.                           ** 66570001
*                                                                     * 66640001
         L     GR4,KUSCPT               SET STACK POINTER IN REGISTER.  66710001
         MVC   KUMLEN(KUEPL4,GR4),KU3C13                                66780001
*                                       STORE SKELETON IN SCRATCH CORE. 66850001
         LA    GR4,KUMLEN+KUEPL4(GR4)   UPDATE STACK POINTER BY LENGTH  66920001
*                                        OF EPILOGUR + 3 BYTE MARKER.   66990001
         MVC   0(2,GR4),KUSTIT          INSERT ITDO 2ND OPERAND.        67060001
         MVI   2(GR4),KUMRK4            INSERT MARKER TO SHOW EPILOGUE  67130001
*                                        IS FOR SKELETON TYPE 4.        67200001
         ST    GR4,KUSCPT               SAVE STACK POINTER.             67270001
*                                                                     * 67340001
**       RESTORE BASIC SKELETON FROM SAVE AREA.                      ** 67410001
*                                                                     * 67480001
SKL3REST MVC   KUSKEL3,KUSKLT           RESTORE BASIC SKELETON          67550001
*                                                                     * 67620001
**       RETURN TO CALLING ROUTINE WITH ZERO RETURN CODE.            ** 67690001
*                                                                     * 67760001
SKL3EXIT IEMKLVE                                                        67830001
         EJECT                                                          67900001
*********************************************************************** 67970001
*                                                                     * 68040001
**             KUSKL2 - GENERATE SKELETON FOR VARIABLE STEP USING    ** 68110001
**                       SINDEXES.                                   ** 68180001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 68250001
**       THE SKELETON SET UP AS KUSKL2 IS SAVED BEFORE IT IS         ** 68320001
**       MODIFIED AND RESTORED AFTER USE.                            ** 68390001
**       THE SKELETON DICTIONARY REFERENCES ARE INSERTED FROM STORED ** 68460001
**       TRIPLE OPERANDS.                                            ** 68530001
**       THE SKELETON COMPILER LABELS ARE INSERTED FROM THOSE ALREADY** 68600001
**       PRESENT AND FROM LABELS GENERATED EARLIER IN PHASE.         ** 68670001
**       THE SYMBOLIC REGISTERS ARE INSERTED FROM THOSE GENERATED AND** 68740001
**       STORED EARLIER IN PHASE.                                    ** 68810001
**       THE SKELETON PROLOGUE IS OUTPUT TO TEXT AND THE EPILOGUE IS ** 68880001
**       STACKED IN SCRATCH CORE.                                    ** 68950001
**       THE RETURN CODE VALUE IS : -                                ** 69020001
**                       0 - NORMAL ONLY.                            ** 69090001
*                                                                     * 69160001
*********************************************************************** 69230001
*                                                                     * 69300001
KUSKL2   IEMKENT  TYPE=2                                                69370001
*                                                                     * 69440001
*                                                                     * 69510001
**       STORE BASIC SKELETON BEFORE MODIFICATION.                   ** 69580001
*                                                                     * 69650001
         MVC   KUSKLT(KULEN2),KUSKEL2   STORE VAR STEP SNDX SKELETON.   69720001
*                                                                     * 69790001
**       INSERT DICTIONARY REFERENCES AS REQUIRED. FIRST STATUS      ** 69860001
**       SWITCH 5 IS TESTED AND IF INITIAL IS A FIXED BINARY INTEGER ** 69930001
**       THEN FIRST TRIPLE OF SKELETON IS NOP'D AND DR(INIT) REPLACES** 70000001
**       DR(CV) IN FIRST LOAD TRIPLE.                                ** 70070001
*                                                                     * 70140001
         TM    KUSBYT,KUS5ON            TEST STATUS SWITCH 5.           70210001
         BZ    SKL2STRT                 BRANCH IF NOT FIX BIN INT.      70280001
         MVI   KU2C01,XTRPNOP           SET NOP CODE.                   70350001
         MVC   KU2T02,KUSTDO            INSERT DR(INIT) INSTEAD OF      70420001
*                                        DR(CV).                        70490001
         B     SKL2CONT                 BRANCH TO FILL REMAINING        70560001
*                                        TRIPLE OPERANDS.               70630001
*                                                                     * 70700001
**       FOR INITIAL NON FIXED BINARY INTEGER FILL ASGN TRIPLE.      ** 70770001
*                                                                     * 70840001
SKL2STRT MVC   KU2O01,KUSTCV            SET DR(CV) AND DR(INIT) IN      70910001
         MVC   KU2T01,KUSTDO             ASGN TRIPLE.                   70980001
         MVC   KU2T02,KUSTCV            SET DR(CV) IN 2ND OP OF FIRST   71050001
*                                        LOAD INSTRUCTION.              71120001
*                                                                     * 71190001
**       INSERT REMAINING DICTIONARY REFERENCES AS REQUIRED.         ** 71260001
*                                                                     * 71330001
SKL2CONT MVC   KU2T03,KUSTBP       SET DR(STEP) IN 2ND OPERAND.         71400001
         MVC   KU2T04,KUSTTP       SET DR(LIMIT) IN 2ND OPERAND.        71470001
         MVC   KU2T15,KUSTCV       SET DR(CV) IN 2ND OPERANDS OF STORE  71540001
         MVC   KU2T25,KUSTCV                                            71570001
         MVC   KU2T24,KUSTCV             INSTRUCTIONS.                  71610001
*                                                                     * 71680001
**       INSERT SYMBOLIC REGISTERS IN SKELETON. THESE REGISTERS HAVE ** 71750001
**       ALREADY BEEN OBTAINED AND INSERTED IN RESPECTIVE STORAGE    ** 71820001
**       SLOTS. FOR THIS SKELETON THE SYMBOLIC REGISTER FOR CV IS    ** 71890001
**       ALLOCATED BEFORE KU AND GIVEN IN FIRST OPERAND OF CV TRIPLE.** 71960001
*                                                                     * 72030001
         MVC   KURGCV,KUSTOP            SET SYMBOLIC REGISTER SLOT FROM 72100001
*                                        STORED CV TRIPLE 1ST OPERAND.  72170001
         MVC   KU2O02,KURGCV            SET SYM REG FOR CV IN LOAD.     72240001
         MVC   KU2O03,KURGST            SET SYMREG FOR STEP IN LOAD.    72310001
         MVC   KU2O04,KURGLM            SET SYM REG FOR LIMIT IN LOAD.  72380001
         MVC   KU2T05,KURGST            SET SYM REG FOR STEP IN KEEP.   72450001
         MVC   KU2T06,KURGLM            SET SYM REG FOR LIMIT IN KEEP.  72520001
         MVC   KU2O07,KURGCV            SET SYM REG FOR CV AND STEP IN  72590001
         MVC   KU2T07,KURGST             SR INSTRUCTION.                72660001
         MVC   KU2O08,KURGST            SET SYM REG FOR STEP IN LTR     72730001
         MVC   KU2T08,KURGST             INSTRUCTION.                   72800001
         MVC   KU2O10,KURGLM            SET SYM REG FOR STEP IN         72870001
*                                        BCTR INSTRUCTION.              72940001
         MVC   KU2O12,KURGCV            SET SYM REG FOR CV IN BXLE.     73010001
         MVC   KU2O13,KURGST            SET SYM REG FOR STEP IN OSM2.   73080001
         MVC   KU2O15,KURGCV            SET SYM REG FOR CV IN STORE.    73150001
         MVC   KU2O25,KURGCV             AND ALSO LOAD.                 73180001
*                                                                     * 73220001
**             DO GROUP                                              ** 73290001
*                                                                     * 73360001
         MVC   KU2O16,KURGST            SET SYM REG FOR STEP IN LTR     73430001
         MVC   KU2T16,KURGST             INSTRUCTION.                   73500001
         MVC   KU2O19,KURGCV            SET SYM REG FOR CV IN BXLE.     73570001
         MVC   KU2O20,KURGST            SET SYM REG FOR STEP IN OSM2.   73640001
         MVC   KU2O22,KURGST            SET SYM REG FOR STEP AND LIMIT  73710001
         MVC   KU2O23,KURGLM             IN DROP INSTRUCTIONS.          73780001
         MVC   KU2O24,KURGCV                                            73790001
         OI    KUSBYT,KUS7ON            SET SWITCH TO SHOW GENERATED    73800001
*                                        SYMBOLIC REGS HAVE BEEN USED.  73810001
*                                                                     * 73820001
*                                                                     * 73850001
**       INSERT LABELS IN SKELETON. LAST LABEL (CL.4) IS INSERTED    ** 73920001
**       WHEN 2ND HALF OF THE LOOP IS INSERTED IN OUTPUT TEXT SINCE  ** 73990001
**       IT IS NOT KNOWN UNTIL ITD' TRIPLE HAS BEEN FOUND.           ** 74060001
*                                                                     * 74130001
SKL2LABL MVC   KU2T09,KULAB1            INSERT 1ST GENERATED LABEL.     74200001
         MVC   KU2T11,KULAB2            INSERT 2ND GENERATED LABEL.     74270001
         MVC   KU2T14,KUPLAB            INSERT LABEL TAKEN FROM CLN2    74340001
*                                        INSTRUCTION IN LOOP PROLOGUE.  74410001
         MVC   KU2T17,KULAB2            INSERT 2ND GENERATED LABEL.     74480001
         MVC   KU2T18,KULAB1            INSERT GENERATED COMPILER LABEL 74550001
         MVC   KU2T21,KUSTIT            INSERT LABEL FROM LOOP EPILOGUE 74620001
         MVC   KU2T12,KUSTIT             TAKEN FROM ITDO 2ND OPERAND.   74690001
         MVC   KU2T19,KUPLAB            INSERT LABEL FROM LOOP PROLOGUE 74760001
*                                                                     * 74766001
**       NO-OP STORE AND LOAD AT HEAD AND TAIL OF LOOP IF PERMITTED. ** 74772001
*                                                                     * 74778001
SKL2SNOP TM    KUSBYT,KUS3ON            IF SWITCH 3 IS ON THEN PUT      74784001
         BZ    SKL2LNOP                  IGNORE OVER STORE INSTRUCTION  74790001
         MVC   KU2C15(5),KUIGNR          AT HEAD OF LOOP.               74796001
*                                                                     * 74802001
SKL2LNOP TM    KUABYT,KUS3ON            IF SWITCH 3 (AUX) IS ON THEN    74808001
         BZ    SKL2OUTP                  PUT IGNORE OVER LOAD AT TAIL   74814001
         MVC   KU2C25(5),KUIGNR          OF LOOP.                       74820001
*                                                                     * 74830001
**       THE VARIABLE STEP LOOP USING SINDEXES IS NOW COMPLETE. THE  ** 74900001
**       PROLOGUE IS NOW INSERTED IN OUTPUT TEXT WHILE THE SKELETON  ** 74970001
**       EPILOGUE IS STACKED IN SCRATCH CORE.                        ** 74990020
*                                                                     * 75010020
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE TO ** 75030020
**       BE OUTPUT TO TEXT.                                          ** 75050020
*                                                                     * 75070020
SKL2OUTP XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.  32286 75090020
         LA    GR4,KU2C03               SET ADDRESS OF PSEUDO-    32286 75110020
         ST    GR4,PAR1                  CODE IN PAR1.            32286 75130020
         LA    GR4,10                   SET LENGTH OF CODE TO BE  32286 75150020
         ST    GR4,PAR2                  OUTPUT IN PAR2           32286 75170020
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE.       32286 75190020
*                                                                     * 75210020
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF ASGN TRIPLE    ** 75230020
**       TO BE OUTPUT TO TEXT.                                       ** 75250020
*                                                                     * 75270020
         LA    GR4,KU2C01               SET ADDRESS OF TRIPLE IN  32286 75290020
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           75460001
         LA    GR4,KUTRLN               SET LENGTH OF CODE TO BE OUTPUT 75530001
         ST    GR4,PAR2                  IN PAR2 PARAMETER WORD.        75600001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          75670001
*                                                                     * 75740001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE TO ** 75810001
**       BE OUTPUT TO TEXT.                                          ** 75880001
*                                                                     * 75950001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS BYTES.  76020001
         LA    GR4,KU2C02               SET ADDRESS OF PSEUDO-CODE IN   76090001
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           76160001
         LA    GR4,KUPSC4               SET LENGTH OF CODE TO BE OUTPUT 76230001
         ST    GR4,PAR2                  IN PAR2 PARAMETER WORD.        76300001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     76370001
*                                                                     * 76440001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF TRIPLE TO BE   ** 76510001
**       OUTPUT TO TEXT.                                             ** 76580001
*                                                                     * 76650001
         LA    GR4,KU2C11               SET ADDRESS OF TRIPLE IN THE    76720001
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           76790001
         LA    GR4,KUTRLN               SET LENGTH OF CODE TO BE OUTPUT 76860001
         ST    GR4,PAR2                  IN PAR2 PARAMETER WORD.        76930001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          77000001
*                                                                     * 77070001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE    ** 77140001
**       ITEM TO BE OUTPUT TO TEXT.                                  ** 77210001
*                                                                     * 77280001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS BYTE.   77350001
         LA    GR4,KU2C12               SET ADDRESS OF PSEUDO-CODE IN   77420001
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           77490001
         LA    GR4,KUPSC5               SET LENGTH OF CODE TO BE OUTPUT 77560001
         ST    GR4,PAR2                  IN PAR2 PARAMETER WORD.        77630001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     77700001
*                                                                    *  77770001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF TRIPLE TO BE   ** 77840001
**       OUTPUT TO TEXT.                                             ** 77910001
*                                                                     * 77980001
         LA    GR4,KU2C14               SET ADDRESS OF TRIPLE IN THE    78050001
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           78120001
         LA    GR4,KUTRLN               SET LENGTH OF CODE TO BE OUTPUT 78190001
         ST    GR4,PAR2                  IN PAR2 PARAMETER WORD.        78260001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          78330001
*                                                                     * 78400001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE    ** 78470001
**       ITEM TO BE OUTPUT TO TEXT NEXT.                             ** 78540001
*                                                                     * 78610001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS BYTES.  78680001
         LA    GR4,KU2C15               SET ADDRESS OF PSEUDO-CODE.     78750001
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           78820001
         LA    GR4,KUPSC2               SET LENGTH  OF PSEUDO-CODE IN   78890001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           78960001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     79030001
*                                                                     * 79100001
**       THE LOOP SKELETON EPILOGUE IS STACKED IN SCRATCH CORE WITH  ** 79170001
**       AN EXTRA 3 BYTE TYPE MARKER. THE MARKER CONTAINS THE       **  79240001
**       ITDO 2ND OPERAND AND THE TYPE OF LOOP TO WHICH THE EPILOGUE ** 79310001
**       BELONGS. THIS IS EPILOGUE TYPE 2.                           ** 79380001
*                                                                     * 79450001
         L     GR4,KUSCPT               SET STACK POINTER IN REGISTER.  79520001
         MVC   KUMLEN(KUEPL2,GR4),KU2C25                                79590001
*                                       STORE SKELETON IN SCRATCH CORE. 79660001
         LA    GR4,KUEPL2+KUMLEN(GR4)   UPDATE STACK POINTER BY LENGTH  79730001
*                                        OF EPILOGUE + 3 BYTE MARKER.   79800001
         MVC   0(2,GR4),KUSTIT          INSERT ITDO 2ND OPERAND.        79870001
         MVI   2(GR4),KUMRK2            INSERT MARKER TO SHOW EPILOGUE  79940001
*                                        IS FOR SKELETON TYPE 2.        80010001
         ST    GR4,KUSCPT               SAVE UPDATED STACK POINTER.     80080001
*                                                                     * 80150001
**       RESTORE  BASIC SKELETON FROM SAVE AREA.                     ** 80220001
*                                                                     * 80290001
SKL2REST MVC   KUSKEL2,KUSKLT           RESTORE BASIC SKELETON.         80360001
*                                                                     * 80430001
**       RETURN TO CALLING ROUTINE WITH ZERO RETURN CODE.            ** 80500001
*                                                                     * 80570001
SKL2EXIT IEMKLVE                                                        80640001
         EJECT                                                          80710001
*********************************************************************** 80780001
*                                                                     * 80850001
**             KUSKL1 - GENERATE SKELETON FOR VARIABLE STEP WHEN     ** 80920001
**                       SINDEXES ARE NOT USED.                      ** 80990001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS: -         ** 81060001
**       THE SKELETON SET UP AS KUSKL1 IS SAVED BEFORE IT IS         ** 81130001
**       MODIFIED AND IS RESTORED AFTER USE.                         ** 81200001
**       THE SKELETON DICTIONARY REFERENCES ARE INSERTED FROM STORED ** 81270001
**       TRIPLE OPERANDS.                                            ** 81340001
**       THE SKELETON COMPILER LABELS ARE INSERTED FROM THOSE ALREADY** 81410001
**       PRESENT AND FROM LABELS GENERATED EARLIER IN PHASE.         ** 81480001
**       THE SYMBOLIC REGISTERS ARE INSERTED FROM THOSE GENERATED AND** 81550001
**       STORED EARLIER IN PHASE.                                    ** 81620001
**       THE SKELETON PROLOGUE IS OUTPUT TO TEXT AND THE EPILOGUE IS ** 81690001
**       STACKED IN SCRATCH CORE.                                    ** 81760001
**       THE RETURN CODE VALUE IS :-                                 ** 81830001
**                       0 - NORMAL ONLY.                            ** 81900001
*                                                                     * 81970001
*********************************************************************** 82040001
*                                                                     * 82110001
KUSKL1   IEMKENT  TYPE=2                                                82180001
*                                                                     * 82250001
**       STORE BASIC SKELETON BEFORE MODIFICATION.                   ** 82320001
*                                                                     * 82390001
         MVC   KUSKLT(KULEN1),KUSKEL1   STORE VAR STEP NO SNDX          82460001
*                                        SKELETON.                      82530001
*                                                                     * 82600001
**       INSERT DICTIONARY REFERENCES AS REQUIRED, FIRST STATUS      ** 82670001
**       SWITCH 5 IS TESTED AND IF INITIAL IS A FIXED BINARY INTEGER ** 82740001
**       THEN FIRST TRIPLE OF SKELETON IS NOP'D AND DR(INIT) REPLACES** 82810001
**       DR(CV) IN FIRST LOAD TRIPLE.                                ** 82880001
*                                                                     * 82950001
         TM    KUSBYT,KUS5ON            TEST STATUS SWITCH 5.           83020001
         BZ    SKL1STRT                 BRANCH IF NOT FIX BIN INT EGER. 83090001
         MVI   KU1C01,XTRPNOP           SET NOP CODE.                   83160001
         MVC   KU1T03,KUSTDO            INSERT DR(INIT) INSTEAD OF      83230001
*                                        DR(CV).                        83300001
         B     SKL1CONT                 BRANCH TO FILL REMAINING TRIPLE 83370001
*                                        OPERANDS.                      83440001
*                                                                     * 83510001
**       FOR INITIAL NON FIXED BINARY INTEGER FILL ASGN TRIPLE.      ** 83580001
*                                                                     * 83650001
SKL1STRT MVC   KU1O01,KUSTCV            SET DR(CV) AND DR(INIT) IN      83720001
         MVC   KU1T01,KUSTDO             ASGN TRIPLE.                   83790001
         MVC   KU1T03,KUSTCV            SET DR(CV) IN 2ND OP OF FIRST   83860001
*                                        LOAD INSTRUCTION.              83930001
*                                                                     * 84000001
**       A TEMPORARY IS REQUIRED AND A DICTIONARY REFERENCE FOR THIS ** 84030001
**       IS OBTAINED. THE TEMPORARY IS CHAINED IN THE AUTOMATIC      ** 84060001
**       CHAIN USING THE CURRENT ENTRY TYPE 1 THE DIC REFERENCE OF   ** 84090001
**       WHICH IS TAKEN FROM SCBLK SCAN SLOT.                        ** 84120001
*                                                                     * 84150001
SKL1CONT MVC   PAR1+2(2),SCBLK          PUT DIC REFERENCE IN PAR1.      84180001
         L     LR,ZDRFAB                SET ADDRESS OF CONVERSION       84210001
*                                        ROUTINE IN LINK REGISTER.      84240001
         BALR  RR,LR                    PERFORM CONVERSION.             84270001
         L     GR5,PAR1                 SET ENTRY BASE POINTER REGISTER 84300001
         MVC   KUTEMP+3(2),KUAUTO(GR5)  SET HEAD OF CURRENT CHAIN IN    84330001
*                                        TEMPORARY SKELETON.            84360001
         MVC   KUTEMP+21(2),KULEVL(GR5) SET LEVEL AND COUNT IN          84390001
*                                        TEMPORARY SKELETON.            84420001
         LA    GR4,KUTEMP               SET ADDRESS OF DICTIONARY ENTRY 84450001
         ST    GR4,PAR1                 SKELETON IN PAR1.               84480001
         LA    GR4,L'KUTEMP             SET LENGTH OF SKELETON ENTRY    84510001
         ST    GR4,PAR2                  IN PAR2.                       84560001
         L     LR,ZDICRF                SET LINK REGISTER WITH ADDRESS  84630001
*                                        OF ROUTINE TO MAKE DICT ENTRY  84700001
         BALR  RR,LR                    MAKE DICTIONARY ENTRY           84770001
*                                                                     * 84840001
**       PAR1 NOW CONTAINS DR(TEMP) AND THIS IS INSERTED WHERE       ** 84910001
**       REQUIRED                                                    ** 84980001
*                                                                     * 85050001
         MVC   KUAUTO(2,GR5),PAR1+2     SET NEW HEAD OF CHAIN IN ENTRY  85100001
*                                        TYPE 1.                        85150001
         MVC   KU1T02,PAR1+2            PUT DICTIONARY REFERENCE OF     85200001
         MVC   KU1T07,PAR1+2             THE NEWLY CREATED TEMPORARY    85250001
         MVC   KU1T12,PAR1+2             IN THE APPROPRIATE ELEMENTS    85300001
         MVC   KU1T20,PAR1+2             OF THE TYPE 1 LOOP CONTROL     85350001
         MVC   KU1T28,PAR1+2             SKELETON.                      85400001
         MVC   KU1T04,KUSTBP            SET DR(STEP) IN LOAD INSTR.     85470001
         MVC   KU1T05,KUSTTP            SET DR(LIMIT) IN LOAD INSTR.    85540001
         MVC   KU1T29,KUSTCV            SET DR(CV) IN FINAL ST INSTR.   85610001
         MVC   KU1T19,KUSTCV            AND STORE AND LOAD INSTRUCTIONS 85630001
         MVC   KU1T18,KUSTCV             EITHER SIDE OF DO GROUP.       85650001
*                                                                     * 85680001
**       INSERT COMPILER LABELS IN SKELETON TYPE 1.                  ** 85750001
*                                                                     * 85820001
         MVC   KU1T10,KULAB2            INSERT GENERATED LABELS IN BC   85890001
         MVC   KU1T14,KULAB1             AND CLN1 ELEMENTS.             85960001
         MVC   KU1T15,KUSTIT            INSERT LABELS TAKEN FROM LOOP   86030001
         MVC   KU1T17,KUPLAB             EPILOGUE AND PROGOGUE.         86100001
         MVC   KU1T23,KULAB1            INSERT GENERATED LABELS IN BC   86170001
         MVC   KU1T24,KULAB2             AND CLN1 ELEMENTS.             86240001
         MVC   KU1T25,KUPLAB            INSERT LABELS TAKEN FROM LOOP   86310001
         MVC   KU1T27,KUSTIT             EPILOGUE AND PROLOGUE.         86380001
*                                                                     * 86390001
**       NO-OP BUY AND SELL TRIPLES AS CORRECTION.                   ** 86400001
*                                                                     * 86410001
         MVI   KU1C02,XTRPNOP           NO-OP BUY AND SELL              86420001
         MVI   KU1C28,XTRPNOP           NO-OP BUY AND SELL              86430001
*                                                                     * 86450001
**       THE LOOP SKELETON TYPE 1 IS NOW COMPLETE. THE SKELETON      ** 86520001
**       PROLOGUE IS OUTPUT TO TEXT. THE EPILOGUE IS STACKED IN      ** 86590001
**       SCRATCH CORE. PAR1 AND PAR2 ARE SET WITH ADDRESS AND        ** 86660001
**       LENGTH OF BUY TRIPLE TO BE OUTPUT TO TEXT.                  ** 86730020
*                                                                     * 86800020
         LA    GR4,KU1C02               SET ADDRESS OF TRIPLE IN  32286 86870020
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           86940001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE IN   32286 87010020
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           87080001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.    32286 87086020
*                                                                     * 87092020
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE TO ** 87098020
**       BE OUTPUT TO TEXT.                                          ** 87104020
*                                                                     * 87110020
         XC    SCSTK,SCSTK                                        32286 87116020
         MVI   SCSTK+KUONED,KURSTA      SET REGISTER STATUS CODE. 32286 87122020
         LA    GR4,KU1C04               SET ADDRESS OF PSEUDO-    32286 87128020
         ST    GR4,PAR1                  CODE IN PAR1.            32286 87134020
         LA    GR4,10                   SET LENGTH OF CODE TO BE  32286 87140020
         ST    GR4,PAR2                  OUTPUT IN PAR2           32286 87146020
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE.       32286 87152020
*                                                                     * 87158020
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF AGSN TRIPLE    ** 87164020
**       TO BE OUTPUT TO TEXT.                                       ** 87170020
*                                                                     * 87176020
         LA    GR4,KU1C01               SET ADDRESS OF TRIPLE IN  32286 87182020
         ST    GR4,PAR1                  PAR1.                    32286 87188020
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE IN   32286 87194020
         ST    GR4,PAR2                  PAR2.                    32286 87200020
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.    32286 87206020
*                                                                     * 87220001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE    ** 87290001
**       ITEM TO BE OUTPUT TO TEXT.                                  ** 87360001
*                                                                     * 87430001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.        87500001
         MVI   SCSTK+KUONED,KURSTA      SET REGISTER STATUS CODE.       87570001
         LA    GR4,KU1C03               SET ADDRESS OF PSEUDO-CODE      87640001
         ST    GR4,PAR1                  ITEM IN PAR1.                  87710001
         LA    GR4,KUPSCA               SET LENGTH OF PSEUDO-CODE ITEM  87780001
         ST    GR4,PAR2                 IN PAR2 PARAMETER WORD.         87850001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE.             87920001
*                                                                     * 87990001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF TRIPLE TO BE   ** 88060001
**       OUTPUT TO TEXT.                                             ** 88130001
*                                                                     * 88200001
         LA    GR4,KU1C14               SET ADDRESS OF TRIPLE IN PAR1   88270001
         ST    GR4,PAR1                  SLOT.                          88340001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE ITEM IN    88410001
         ST    GR4,PAR2                  PAR2.                          88480001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT           88550001
*                                                                     * 88620001
*        SET ADDRESS AND LENGTH OF PSEUDO-CODE ITEM IN PAR1 AND      ** 88690001
**       PAR2 PARAMETER WORDS.                                       ** 88760001
*                                                                     * 88830001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.        88900001
         LA    GR4,KU1C15               SET ADDRESS OF PSEUDO-CODE IN   88970001
         ST    GR4,PAR1                  PAR1.                          89040001
         LA    GR4,KUPSC5               SET LENGTH OF PSEUDO-CODE IN    89110001
         ST    GR4,PAR2                  PAR2.                          89180001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     89250001
*                                                                     * 89320001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF TRIPLE ITEM    ** 89390001
*                                                                     * 89460001
         LA    GR4,KU1C17               SET ADDRESS OF TRIPLE ITEM IN   89530001
         ST    GR4,PAR1                  PAR1.                          89600001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE ITEM IN    89670001
         ST    GR4,PAR2                  PAR2.                          89740001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT           89810001
*                                                                     * 89880001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF STORE PSEUDO-  ** 89950001
**        CODE TO BE OUTPUT.                                         ** 90020001
*                                                                     * 90090001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.        90160001
         LA    GR4,KU1C18               SET ADDRESS OF PSEUDO-CODE ITEM 90230001
         ST    GR4,PAR1                 IN PAR1.                        90300001
         LA    GR4,KUPSC2               SE LENGTH OF PSEUD-CODE IN      90370001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           90440001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     90510001
*                                                                     * 90580001
**       THE LOOP SKELETON TYPE 1 EPILOGUE IS STACKED IN SCRATCH CORE** 90650001
**       WITH AN EXTRA 3 BYTE TYPE MARKER. THE MARKER CONTAINS THE   ** 90720001
**       ITDO 2ND OPERAND AND THE TYPE OF LOOP TO WHICH THE EPILOGUE ** 90790001
**       BELONGS. THIS IS EPILOGUE TYPE 1.                           ** 90860001
*                                                                     * 90930001
         L     GR4,KUSCPT               SET STACK POINTER REGISTER.     91000001
         MVC   KUMLEN(KUEPL1,GR4),KU1C19                                91070001
*                                       STORE SKELETON IN SCRATCH CORE. 91140001
         LA    GR4,KUEPL1+KUMLEN(GR4)   UPDATE STACK POINTER BY LENGTH  91210001
*                                        OF EPILOGUE + 3 BYTE MARKER.   91280001
         MVC   0(2,GR4),KUSTIT          INSERT ITDO 2ND OPERAND.        91350001
         MVI   2(GR4),KUMRK1            INSERT MARKER TO SHOW EPILOGUE  91420001
*                                        IS FOR SKELETON TYPE 1.        91490001
         ST    GR4,KUSCPT               SAVE UPDATED STACK POINTER.     91560001
*                                                                     * 91630001
**       RESTORE BASIC SKELETON FROM SAVE AREA.                      ** 91700001
*                                                                     * 91770001
SKL1REST MVC   KUSKEL1,KUSKLT           RESTORE BASIC SKELETON.         91840001
*                                                                     * 91910001
**       RETURN TO CALLING ROUTINE WITH ZERO RETURN CODE.            ** 91980001
*                                                                     * 92050001
SKL1EXIT IEMKLVE                                                        92120001
         EJECT                                                          92190001
*                                                                     * 94640001
         LTORG                                                          94670001
         EJECT                                                          94710001
         END                                                            94780001
