KV       TITLE 'IEMKV DO LOOP CONTROL AND MERGE PATCHES OPTIMISATION,  C00020001
               OS/360 PL/1 F COMPILER'                                  00040001
         SPACE 3                                                        00060001
*              'IEMKV' COMPRISES A SERIES OF SUBROUTINES CALLED FROM  * 00080001
*        'IEMKU'. A FULL DESCRIPTION OF BOTH MODULES IS GIVEN AT HEAD * 00100001
*        OF 'IEMKU'.                                                  * 00120001
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*KV 001-TSS 00126056
*        ----------------------------------------------------KV 001-TSS 00132056
         EJECT                                                          00140001
         COPY  IEMKUEQ                                                  00200001
         COPY  IEMKCOM                                                  00300001
         COPY  IEMKUTL                                                  00400001
         COPY  IEMKEQU                                                  00500001
         COPY  IEMKPCH                                                  00600001
         COPY  IEMKTRP                                                  00800001
         COPY  IEMKSCN                                                  00900001
         COPY  IEMKSLA                                                  01000001
         DCBD                                                           01200001
         COPY  IEMKKUT                                                  01300001
         COPY  IEMKUCM                                                  01400001
IEMKV    CSECT                                                          01500001
         USING *,GR8                    PROVIDE BASE REGISTER FOR THE   01600001
*                                        KV CSECT.                      01700001
         USING XTRP,GR7                 PROVIDE BASE REGISTER FOR XTRP  01800001
*                                        DSECT                          01900001
KVNAME   DC    C'KV'                                                    02000001
         B     KVPTCH                   BRANCH TO PATCH SUBROUTINE.     02100001
         B     KVCOMR                   BRANCH TO COMR  SUBROUTINE.     02200001
         B     KVCOMA                   BRANCH TO COMA  SUBROUTINE.     02300001
         B     KVSSUB                   BRANCH TO SSUB  SUBROUTINE.     02400001
         B     KVSSBP                   BRANCH TO SSB'  SUBROUTINE.     02500001
         B     KVJUMP                   BRANCH TO PSEUDO-CODE ROUTINE.  02600001
         B     KVSUBS                   BRANCH TO SUBS  SUBROUTINE.     02700001
         B     KVSUBP                   BRANCH TO SUB'  SUBROUTINE.     02800001
         B     KVITDP                   BRANCH TO ITD'  SUBROUTINE.     02900001
         B     KVERRS                   BRANCH TO ERROR SUBROUTINE.     03000001
         B     KUSETS                   BRANCH TO INITIALISING ROUTINE. 03020001
         B     KUENDS                   BRANCH TO END PHASE ROUTINE.    03050001
         B     *                                                        03130001
         B     *                                                        03210001
         COPY  IEMKVCM                                                  03300001
*********************************************************************** 03400001
*                                                                     * 03500001
**             KVPTCH - PATCH PROCESSING SUBROUTINE                  ** 03600001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS : -        ** 03700001
**        THE TEXT BLOCK CONTAINING THE PATCH IS OBTAINED USING THE  ** 03800001
**        ZTXTAB PROCESSING ROUTINE.                                 ** 03900001
**        THE TYPE OF PATCH IS DETERMINED FROM THE FIRST TRIPLE AND  ** 04000001
**        IS PROCESSED ACCORDINGLY.                                  ** 04100001
**        IF FIRST TRIPLE IS ITD' THEN IT IS PROCESSED BEFORE PATCH. ** 04200001
**        IF FIRST TRIPLE IS ITDO THEN PATCH IS PROCESSED FIRST.     ** 04300001
**        IF FIRST TRIPLE IS NEITHER OF ABOVE THEN PATCH ONLY IS     ** 04400001
**        PROCESSED.                                                 ** 04500001
**        THE PATCH IS SCANNED TRIPLE BY TRIPLE AND EACH TRIPLE IS   ** 04600001
**        OUTPUT TO TEXT BEFORE NEXT TRIPLE IS PROCESSED.            ** 04700001
**        WHENEVER AN SSUB TRIPLE IS ENCOUNTERED ITS SYMBOLIC ADDRESS** 04800001
**        IS OBTAINED BEFORE IT IS OUTPUT TO TEXT.                   ** 04900001
**        WHENEVER AN SSB' TRIPLE IS ENCOUNTERED THE OCCURENCES OF   ** 05000001
**        COMA AND COMR TRIPLES IN SUBSCRIPT LIST IS CHECKED AND SSUB** 05100001
**        OBTAINED AND ALTERED IF NECESSARY.                         ** 05200001
**        OCCURENCES OF NON NULL COMA TRIPLES ARE NOTED.             ** 05300001
**        THE 2ND OPERAND OF COMR TRIPLES IS STORED.                 ** 05400001
**        AT END OF PATCH NEXT PATCH IN CHAIN IS OBTAINED IF THERE IS** 05500001
**        ONE AND IT IS PROCESSED SIMILARLY.                         ** 05600001
**        THE KVPTCH SUBROUTINE RETURN CODE VALUES ARE :             ** 05700001
**                       0 - OPTIMIZABLE ITDO FOUND.                 ** 05800001
**                       4 - UNOPTIMISABLE ITDO FOUND                ** 05860001
**                       8 - NO ITDO IN PATCH                        ** 05920001
*                                                                     * 06000001
*********************************************************************** 06100001
*                                                                     * 06200001
KVPTCH   IEMKENT  TYPE=1                                                06300001
*                                                                     * 06400001
**       PROVIDE BASE REGISTER FOR PATCH DESCRIPTOR DSECT AND CLEAR  ** 06500001
**       PATCH PROCESSING WORK AREAS AND SWITCHES.                   ** 06600001
*                                                                     * 06700001
         USING XPCH,GR6                 PROVIDE BASE FOR PATCH DSECT.   06800001
         XC    KVPCHN,KVPCHN            CLEAR CHAIN TEXT REF STORAGE.   06900001
*                                                                     * 07000001
**       USE ZTXTAB PROCESSING ROUTINE TO OBTAIN PATCH ADDRESS FROM  ** 07100001
**       PTCH TRIPLE 2ND OP AND SET TRIPLE DESCRIPTOR DSECT BASE     ** 07200001
**       REGISTER TO POINT TO FIRST TRIPLE OF PATCH.                 ** 07300001
*                                                                     * 07400001
         MVC   PAR1,XTRPOP1             SET TEXT REF IN PAR1.           07500001
*                                           FULL WORD.                  07600001
PTCHAINS NI    PAR1,KUS1OF              ENSURE STATUS OF BLOCK WILL BE  07700001
*                                        CHANGED.                       07800001
         MVC   KVWORD,PAR1              STORE T-BLOCK NUMBER.           07805001
*                                                                     * 07810001
**       SET UP TABLE OF TEXT BLOCK NOS FOR FUTURE USE IN FREEING    ** 07820001
**       ALL TEXT BLOCKS USED FOR THE PATCH FILE.                    ** 07830001
*                                                                     * 07840001
         SR    GR4,GR4                  CLEAR REGISTER.                 07850001
         IC    GR4,PAR1+1               SET TEXT BLOCK NO IN REGISTER.  07860001
         LA    GR4,KVTBLK(GR4)          SET ADDRESS OF NTH BYTE OF      07870001
         MVC   0(1,GR4),PAR1+1           TABLE IN REGISTER AND INSERT   07880001
*                                        TEXT BLOCK NO N INTO THAT BYTE 07890001
         L     LR,ZTXTAB                SET ADDRESS OF CONVERSION       07900001
         BALR  RR,LR                     ROUTINE IN BRANCH REGISTER AND 08000001
*                                        OBTAIN ABSOLUTE ADDRESS.       08100001
         L     GR6,PAR1                 PUT ADDRESS OF PATCH IN DSECT   08200001
*                                        BASE REGISTER.                 08300001
*                                                                     * 08400001
**       STORE PATCH CHAIN ENTRY IN APPROPRIATE SLOT AND SET XTRP    ** 08500001
**       DSECT BASE REGISTER FROM ADDRESS OF FIRST TRIPLE IN PATCH.  ** 08600001
**                                                                   ** 08700001
*                                                                     * 08800001
         MVC   KVPCHN,XPCHCHN           STORE CHAIN REFERENCE.          08900001
         LA    GR7,XPCHDATA             SET BASE REGISTER OF XTRP DSECT 09000001
*                                                                     * 09100001
**       CHECK PATCH CODE BYTE IF FIRST TRIPLE OF PATCH IS NOT AN    ** 09200001
**       NOP TRIPLE.                                                 ** 09300001
*                                                                     * 09400001
         CLI   XTRPCODE,XTRPNOP         CHECK FIRST PATCH TRIPLE AND    09500001
         BE    PTCHNOPS                 IF IT IS NOP CHECK FOR EOP.     09600001
         CLI   XPCHCODE,XPCHITDP        TEST WHETHER 1ST TRIPLE IS      09700001
*                                        ITD' TRIPLE.                   09900001
         BE    PTCHITDP                 BRANCH IF FIRST TRIPLE IS ITD'. 10000001
         CLI   XPCHCODE,XPCHITDO        TEST WHETHER 1ST TRIPLE IS      10100001
*                                        ITDO TRIPLE.                   10200001
         BE    PTCHSTOR                 ITDO IS STORED AND PROCESSED    10260001
*                                        AT END OF PATCH.               10320001
         CLI   XPCHCODE,XPCHLAST        CHECK IF FIRST TRIPLE IS TO BE  10380001
*                                        INSERTED LAST INTO TEXT.       10440001
         BNE   PTCHTEST                 PROCESS 1ST TRIPLE NORMALLY.    10500001
*                                                                     * 10560001
**       1ST TRIPLE MUST BE STORED EITHER BECAUSE IT IS AN ITDO      ** 10620001
**       TRIPLE OR BECAUSE PATCH CODE INDICATES THAT IT MUST BE THE  ** 10680001
**       LAST INSERTION IN PATCH.                                    ** 10740001
*                                                                     * 10800001
PTCHSTOR MVC   KVITDO,XTRP              STORE TRIPLE IN RESERVED SLOT.  10860001
         OI    KVSBT1,KUS2ON            SET KV STATUS SWITCH 2 TO SHOW  10920001
*                                        THAT THIS TRIPLE MUST BE       10980001
*                                        PROCESSED LATER.               11040001
         B     PTCHSCAN                 BRANCH TO PATCH PROCESSING.     11200001
*                                                                     * 11210001
**       IF INITIAL NOP IS FOLLOWED IMMEDIATELY BY AN EOP TRIPLE     ** 11220001
**       THEN END OF PATCH CHAIN HAS BEEN REACHED.                   ** 11230001
*                                                                     * 11240001
PTCHNOPS LA    GR7,5(0,GR7)             UPDATE POINTER TO NEXT TRIPLE.  11250001
         CLI   XTRPCODE,XTRPEOPT        IS IT END OF PATCH TRIPLE.      11260001
         BNE   PTCHTEST                 NOT END SO GO TO SCAN PATCH.    11270001
         B     PTCHFNAL                 IT IS END OF PATCH.             11280001
*                                                                     * 11290001
*                                                                     * 11300001
**       PERFORM SUBROUTINE TO PROCESS ITD' TRIPLE BEFORE CONTINUING ** 11400001
**       WITH PATCH PROCESSING.                                      ** 11500001
*                                                                     * 11600001
PTCHITDP BAL   RR,KVITDP                PROCESS ITD' TRIPLE.            11700001
*                                                                     * 11800001
**       THE SEQUENTIAL PATCH SCAN AND PROCESSING ROUTINE FOLLOWS.   ** 11900001
**       THE CURRENT PATCH TRIPLE POINTER IS UPDATED AND TRIPLES OF  ** 12000001
**       INTEREST ARE FIRST PROCESSED AS NECESSARY AND THEN OUTPUT TO** 12100001
**       TEXT.                                                       ** 12200001
*                                                                     * 12300001
PTCHSCAN LA    GR7,5(0,GR7)             UPDATE TRIPLE POINTER.          12400001
PTCHTEST SR    PR2,PR2                  ZEROISE THE TRT RETURN REGISTER 12500001
         TRT   XTRPCODE,KVTTAB          SEARCH FOR REQUIRED TRIPLE.     12600001
         LA    RR,PTCHTOUT              SET RETURN POINT.               12700001
         B     PTCHBRCH(PR2)            INDEX BR TABLE WITH RETRN VALUE 12800001
PTCHBRCH B     PTCHTOUT                 OUTPUT CURRENT  TRIPLE TO TEXT. 12900001
         B     PTCHENDS                 PERFORM PATCH END PROCESSING.   13000001
         B     KVSSUB                   PROCESS SSUB TRIPLE.            13100001
         B     KVSSBP                   PROCESS SSBP TRIPLE.            13200001
         B     KVCOMR                   PROCESS COMR TRIPLE.            13400001
         B     KVCOMA                   PROCESS COMA TRIPLE.            13420001
         B     PTCHSCAN                 NOP AND BUY CHAMELEON TRIPLES   13440001
         B     PTCHSCAN                  ARE IGNORED.                   13460001
         B     PTCHSTNO                 EXPAND STNO TRIPLE.             13480001
         B     PTCHNODO                 SET RETURN CODE AND EXIT.       13485001
         B     KVSUBS                   PROCESS SUBS TRIPLE.            13490001
         B     KVSUBP                   PROCESS SUB' TRIPLE.            13495001
         LA    RR,PTCHTEST              RETURN POINT AFTER KVJUMP.      13500001
         B     KVJUMP                   OUTPUT TRIPLE AND PSEUDO-CODE.  13600001
*                                                                     * 13610001
**       STATEMENT NUMBER AND LABEL TRIPLES MUST BE EXPANDED TO M    ** 13616001
**       BYTES BY SCAN.                                              ** 13622001
*                                                                     * 13630001
PTCHSTNO LR    PR1,GR7                  SET SCAN INPUT POINTER AT STNO. 13640001
         BAL   RR,SC6                   OUTPUT STNO TO TEXT.            13650001
         B     PTCHSCAN                 RETURN TO CONTINUE PATCH SCAN.  13660001
*                                                                     * 13700001
**       OUTPUT CURRENT PATCH TRIPLE TO TEXT AND RETURN TO UPDATE    ** 13800001
**       POINTER AND REPEAT PROCESS.                                 ** 13900001
*                                                                     * 14000001
PTCHTOUT ST    GR7,PAR1                 SET CURRENT TRIPLE ADDR IN PAR1 14100001
         LA    GR4,KUTRLN               SET LENGTH OF CURRENT TRIPLE    14200001
         ST    GR4,PAR2                  IN PAR2.                       14300001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          14400001
         B     PTCHSCAN                 RETURN TO UPDATE TRIPLE POINTER 14500001
*                                                                     * 14600001
**       DETERMINE WHETHER PATCH IS CHAINED. IF IT IS OBTAIN NEXT    ** 14700001
**       PATCH AND REPEAT. IF NOT CHECK FOR OUTSTANDING TRIPLE HELD  ** 14800001
**       FROM START OF PATCH AND PROCESS AS NECESSARY.               ** 14900001
**       MARK CURRENT PATCH FILE TEXT BLOCK WANTED.                  ** 14920001
*                                                                     * 14940001
PTCHENDS CLC   KVPCHN,KUZERO            TEST IF PATCH IS CHAINED.       14948001
         BE    PTCHFNAL                 IF NOT SEE IF STORED TRIPLE YET 14956001
*                                        TO BE PROCESSED.               14964001
         MVC   PAR1,KVWORD              SET BLOCK NO IN PAR1.           14972001
         MVI   PAR2+3,X'03'             SET WANTED CODE IN PAR2.        14980001
         L     LR,ZALTER                ALTER BLOCK STATUS.             15000001
         BALR  RR,LR                                                    15020001
         XC    KVWORD,KVWORD            CLEAR BLOCK NO STORAGE.         15040001
*                                                                     * 15060001
         MVC   PAR1+1(3),KVPCHN         SET CHAINING TEXT REF IN PAR1.  15220001
         B     PTCHAINS                 OBTAIN NEXT PATCH AND CONTINUE. 15260001
*                                                                     * 15300001
PTCHFNAL MVC   PAR1,KVWORD              SET CURRENT PATCH FILE BLOCK NO 15310001
         MVI   PAR2+3,X'03'              IN PAR1 AND 'WANTED' CODE IN   15320001
         L     LR,ZALTER                 PAR2.                          15330001
         BALR  RR,LR                    MARK THIS BLOCK WANTED.         15340001
         XC    KVWORD,KVWORD            CLEAR BLOCK NO STORAGE.         15350001
*                                                                     * 15360001
         TM    KVSBT1,KUS2ON            HAS 1ST TRIPLE OF PATCH YET     15370001
*                                        TO BE PROCESSED.               15380001
         BZ    PTCHNODO                 RETURN TO USER AFTER SETTING    15420001
*                                        RETURN CODE.                   15460001
         LA    GR7,KVITDO               SET XTRP DSECT MASK ON TRIPLE.  15500001
         CLI   XTRPCODE,XTRPITDO        TEST IF HELD TRIPLE IS AN ITDO. 15540001
         BE    PTCHITDO                 IF SO PERFORM KUITDO.           15580001
*                                       OTHERWISE RETURN TO PATCH SCAN  15660001
*                                        AND PERFORM PROCESSING FOR     15740001
         B     PTCHTEST                  HELD TRIPLE.                   15820001
*                                                                     * 15900001
*                                                                     * 15980001
PTCHNODO LA    RC,8                     SET CODE TO SHOW NO ITDO.       16160001
         B     PTCHEXIT                 EXIT TO CALLING MODULE.         16180001
PTCHITDO BAL   RR,KUITDO                PERFORM ITDO PROCESSING.        16220001
*                                                                     * 16300001
**       RETURN TO CALLING MODULE WITH RETURN CODE SET BY KUITDO.    ** 16400001
*                                                                     * 16500001
PTCHEXIT IEMKLVE  RC=(RC)                                               16600001
         EJECT                                                          16700001
*********************************************************************** 16800001
*                                                                     * 16900001
**             KVCOMR - PROCESS COMR TRIPLE                          ** 17000001
**       THIS SUBROUTINE DETERMINES WHETHER A SSUB LIST IS CURRENTLY ** 17100001
**       BEING PROCESSED AND STORES THE 2ND OPERAND IN APPROPRIATE   ** 17200001
**       SLOT. IF COMR OCCURS MORE THAN ONCE IN EITHER CASE AN       ** 17300001
**       APPROPRIATE SWITCH IS SET ON.                               ** 17400001
**        RETURN CODE VALUE IS 0 - NORMAL ONLY.                      ** 17500001
*                                                                     * 17600001
*********************************************************************** 17700001
*                                                                     * 17800001
KVCOMR   IEMKENT  TYPE=LL2                                              17900001
         TM    KVSBT1,KUS3ON            TEST WHETHER SSUB LIST IS       18000001
*                                        CURRENTLY BEING PROCESSED.     18100001
         BO    COMRINSD                 BRANCH IF INSIDE SSUB LIST.     18200001
         CLC   KVOCOM,KUZERO            TEST IF COMR ALREADY ENCOUNTRD. 18300001
         BE    COMROSTR                 IF NOT STORE 2ND OPERAND.T.     18400001
         OI    KVSBT2,KUS5ON            SET STATUS SWITCH TO SHOW       18500001
*                                        MULTIPLE OCCURENCE.            18600001
COMROSTR MVC   KVOCOM,XTRPOP2           STORE COMR 2ND OPERAND.         18700001
         B     COMREXIT                 LEAVE KVCOMR SUBROUTINE..T.     18800001
*                                                                     * 18900001
**       COMR HAS OCCURED INSIDE CURRENT SSUB LIST.                  ** 19000001
*                                                                     * 19100001
COMRINSD CLC   KVICOM,KUZERO            TEST IF COMR ALREADY ENCOUNTRD. 19200001
         BE    COMRISTR                 IF NOT STORE 2ND OPERAND.T.     19300001
         OI    KVSBT1,KUS4ON            SET STATUS SWITCH TO SHOW       19400001
*                                        MULTIPLE OCCURENCE.            19500001
COMRISTR MVC   KVICOM,XTRPOP2           STORE COMR 2ND OPERAND.         19600001
*                                                                     * 19700001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE.             ** 19800001
*                                                                     * 19900001
COMREXIT IEMKLVE                                                        20000001
         EJECT                                                          20100001
*********************************************************************** 20200001
*                                                                     * 20300001
**             KVCOMA - PROCESS COMA TRIPLE                          ** 20400001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 20500001
**        FOR A COMA-NULL (COMA 00FF FFFF) NO ACTION IS TAKEN.       ** 20600001
**        WHEN A NON NULL COMA IS ENCOUNTERED THE REQUIRED STATUS    ** 20700001
**        SWITCHES ARE TESTED TO DETERMINE IF SUBS OR SSUB IS BEING  ** 20800001
**        PROCESSED AND AN APPROPRIATE STATUS SWITCH IS SET.         ** 20900001
**       RETURN CODE VALUE IS 0 - NORMAL ONLY.                       ** 21000001
*                                                                     * 21100001
*********************************************************************** 21200001
*                                                                     * 21300001
KVCOMA   IEMKENT  TYPE=LL2                                            * 21400001
*                                                                     * 21500001
         CLC   XTRPOP2,KUHIGH           CHECK FOR COMA-NULL.            21600001
         BE    COMAEXIT                 IF NULL EXIT FROM KVCOMA.       21700001
         TM    KVSBT2,KUS2ON            TEST WHETHER SUBS LIST IS       21800001
*                                        CURRENTLY BEING PROCESSED.     21900001
         BZ    COMAEXIT                 IF SUBS LIST NOT CURRENT LEAVE  22000001
*                                        KVCOMA SUBROUTINE.             22100001
         TM    KVSBT1,KUS3ON            TEST WHETHER SSUB LIST IS       22200001
*                                       CURRENTLY BEING PROCESSED.      22300001
         BO    COMAINSD                 BRANCH IF INSIDE SSUB LIST.     22400001
         OI    KVSBT2,KUS6ON            SET STATUS SWITCH TO SHOW NON   22500001
*                                        NULL COMA OUTSIDE SSUB LIST.   22600001
         B     COMAEXIT                 LEAVE KVCOMA SUBROUTINE.ST.     22700001
COMAINSD OI    KVSBT1,KUS7ON            SET SWITCH TO SHOW NON NULL 2ND 22800001
*                                        OPERAND INSIDE SSUB LIST.      22900001
*                                                                     * 23000001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE.             ** 23100001
*                                                                     * 23200001
COMAEXIT IEMKLVE                                                        23300001
         EJECT                                                          23400001
*********************************************************************** 23500001
*                                                                     * 23600001
**             KVJUMP - OUTPUT PSEUDO-CODE ITEM TO TEXT              ** 23700001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :          ** 23800001
**        THE PSEUDO-CODE ADDRESS AND LENGTH ARE SET IN PAR1 & PAR2. ** 23900001
**        LA ROUTINE  MV3 IS USED TO MOVE THE PSEUDO-CODE ITEM TO    ** 24000001
**        OUTPUT TEXT.                                               ** 24100001
**        THE PATCH TRIPLE POINTER REGISTER IS UPDATED BY THE LENGTH ** 24200001
**        IN THE JUMP 1ST OPERAND.                                   ** 24300001
**        RETURN CODE VALUE IS 0 - NORMAL ONLY.                      ** 24400001
*                                                                     * 24500001
*********************************************************************** 24600001
*                                                                     * 24700001
KVJUMP   IEMKENT  TYPE=LL2                                              24800001
*                                                                     * 24900001
         LA    GR4,5(0,GR7)             SET ADDRESS OF PSEUDO-CODE IN   25000001
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           25100001
         XC    PAR2,PAR2                CLEAR PAR2 PARAMETER WORD.      25200001
         MVC   PAR2+2(2),XTRPOP1                                        25300001
*                                       SET LENGTH IN PAR2.             25400001
         AH    GR7,PAR2+2               INCREMENT XTRP BASE REGISTER.   25500001
         L     GR4,PAR2                 SET VALUE 5 - TRIPLE LENGTH -   25520001
         LA    GR5,5                     IN REGISTER AND SUBTRACT FROM  25540001
         SR    GR4,GR5                   PSEUDO-LENGTH.                 25560001
         ST    GR4,PAR2                 PAR2 IS NOW SET.                25580001
         MVC   SCSTK,0(GR7)             SET REGISTER STATUS BYTES.      25600001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     25700001
*                                                                     * 25800001
**       UPDATE TRIPLE DSECT BASE REGISTER SO THAT RETURN MAY BE MADE** 25900001
**       DIRECTLY TO TRIPLE TEST ROUTINE.                            ** 26000001
*                                                                     * 26100001
         LA    GR7,2(0,GR7)             UPDATE XTRP BASE TO POINT TO    26200001
*                                        NEXT PATCH FILE ITEM.          26300001
*                                                                     * 26400001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE VALUE.       ** 26500001
*                                                                     * 26600001
JUMPEXIT IEMKLVE                                                        26700001
         EJECT                                                          26800001
*********************************************************************** 26900001
*                                                                       27000001
**             KVSSUB - PROCESS SSUB TRIPLE                           * 27100001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :          ** 27200001
**        THE STATUS SWITCH IS SET ON TO INDICATE START OF SSUB LIST.** 27300001
**        THE DICTIONRY REFERENCE OF THE ARRAY IS OBTAINED AND IF THE** 27400001
**        ARRAY IS A ARRAY OF STRINGS A STATUS SWITCH IS SET ON. IF  ** 27500001
**        ITS  NOT AN ARRAY OF STRINGS THE TEXT REFERENCE OF THE     ** 27600001
**        CURRNT OUTPUT TEXT POINTER IS OBTAINED AND STORED.         ** 27700001
**        THE SWITCHES AND STORAGE SLOTS RESERVED FOR SSUB LIST      ** 27800001
**        PROCESSING ARE CLEARED.                                    ** 27900001
**        RETURN CODE VALUE IS 0 - NORMAL ONLY.                      ** 28000001
*                                                                     * 28100001
*********************************************************************** 28200001
*                                                                     * 28300001
KVSSUB   IEMKENT  TYPE=LL2                                              28400001
*                                                                     * 28500001
*                                                                     * 28600001
**       INITIALISE SWITCHES AND STORAGE SLOTS RELEVANT TO SSUB LIST.** 28700001
*                                                                     * 28800001
         OI    KVSBT1,KUS3ON            SWITCH NOW SHOWS START OF SSUB. 28900001
         NI    KVSBT1,KUS4OF            CLEAR STATUS SWITCHES THAT MAY  29000001
         NI    KVSBT1,KUS7OF             BE SET WHILE SSUB LIST IS      29100001
         NI    KVSBT1,KUS8OF             BEING PROCESSED.               29200001
         XC    KVICOM,KVICOM            STORAGE SLOT FOR COMR TRIPLE.   29300001
*                                                                     * 29400001
**       OBTAIN DICTIONARY ENTRY OF ARRAY FROM SSUB 1ST OPERAND      ** 29500001
*                                                                     * 29600001
         MVC   PAR1+2(2),XTRPOP1       SET DR(ARRAY) IN PAR1.           29700001
         L     LR,ZDRFAB                SET ADDRESS OF CONVERSION       29900001
*                                        ROUTINE IN BRANCH REGISTER.    30000001
         BALR  RR,LR                    GET ABSOLUTE DICTIONARY ADDRESS 30100001
         L     GR4,PAR1                 SET BASE POINTER TO DICTIONARY  30200001
*                                        ENTRY.                         30300001
         TM    KUDATA(GR4),KUS1ON       TEST HIGH ORDER BIT OF DATA     30400001
*                                        BYTE FOR STRING.               30500001
         BO    SSUBTREF                 BRANCH TO STORE TEXT REF IF     30600001
*                                        ARRAY IS NOT ARRAY OF STRINGS. 30700001
         OI    KVSBT1,KUS8ON            SET STATUS SWITCH  ON AND EXIT  30800001
         B     SSUBEXIT                 FROM KVSSUB IF ARRAY OF STRINGS 30900001
*                                                                     * 31000001
**       OBTAIN TEXT REFERENCE OF CURRENT OUTPUT TEXT POINTER USING  ** 31100001
**       ZTXTRF PROCESSING ROUTINE.                                  ** 31200001
*                                                                     * 31300001
SSUBTREF L     GR4,SCTXTO               PLACE WORD CONTAINING OUTPUT    31400001
         ST    GR4,PAR1                  TEXT BLOCK NAME IN PAR1.       31500001
         L     GR4,ZPCOP                SET CURRENT ADDRESS IN OUTPUT   31600001
         ST    GR4,PAR2                  TEXT BLOCK IN PAR2.            31700001
         L     LR,ZTXTRF                LOAD BRANCH REGISTER.           31800001
         BALR  RR,LR                    GET TEXT REFERENCE OF CURRENT   31900001
         L     GR4,PAR1                  OUTPUT POINTER AND STORE IN    32000001
         ST    GR4,KVSSST                RESERVED SLOT.                 32100001
*                                                                     * 32200001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE VALUE.       ** 32300001
*                                                                     * 32400001
SSUBEXIT IEMKLVE                                                        32500001
         EJECT                                                          32600001
*********************************************************************** 32700001
*                                                                     * 32800001
**             KVSSBP - PROCESS SSB' TRIPLE.                         ** 32900001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS : -        ** 33000001
**        THE KU STATUS SWITCH 3 IS SET OFF TO INDICATE THAT END OF  ** 33100001
**        SSUB LIST HAS BEEN REACHED.                                ** 33200001
**        THE OCCURENCES OF COMA AND COMR TRIPLES IN THE SSUB LIST   ** 33300001
**        ARE CHECKED AND THE SSUB TRIPLE 2ND OPERAND IS CHANGED IF  ** 33400001
**        NECESSARY.                                                 ** 33500001
**        THE RETURN CODE VALUE IS 0 - NORMAL ONLY.                  ** 33600001
*                                                                     * 33700001
*********************************************************************** 33800001
*                                                                     * 33900001
KVSSBP   IEMKENT  TYPE=1                                                34000001
*                                                                     * 34100001
         NI    KVSBT1,KUS3OF            SET STATUS SWITCH 3 OFF.        34200001
*                                                                     * 34300001
**       TEST IF ARRAY IS ARRAY OF STRINGS. IF IT IS SSUB 2ND OP     ** 34400001
**       REMAINS UNALTERED.                                          ** 34500001
*                                                                     * 34600001
         TM    KVSBT1,KUS8ON            TEST IF ARRAY OF STRINGS.       34700001
         BO    SSBPEXIT                 IF ARRAY OF STRINGS EXIT.       34800001
*                                                                     * 34900001
**       TEST FOR OCCURENCE OF NON NULL COMA 2ND OPERAND IN SSUB     ** 35000001
**       LIST. IF THERE ARE ONLY COMA - NULL TRIPLES PRESENT BRANCH  ** 35100001
**       TO SET SSUB TRIPLE 2ND OPERAND ACCORDINGLY.                 ** 35200001
*                                                                     * 35300001
         B     SSBPEXIT                 CANCEL REMAINDER OF ROUTINE.    35350001
         TM    KVSBT1,KUS7ON            TEST FOR PRESENCE OF NON NULL   35400001
*                                        COMA 2ND OPERAND IN LIST.      35500001
         BO    SSBPEXIT                 IF ANY PRESENT LEAVE KVSSBP.    35600001
         TM    KVSBT1,KUS4ON            TEST IF MORE THAN ONE COMR      35700001
*                                        PRESENT IN LIST.               35800001
         BO    SSBPEXIT                 LEAVE KVSSBP IF MORE THAN ONE.  35900001
*                                                                     * 36000001
**       IF THERE IS ONE COMR ONLY THEN SSUB 2ND OPERAND IS SET TO   ** 36100001
**       COMR 2ND OPERAND. IF THERE IS NO COMR IN LIST AND ONLY      ** 36200001
**       COMA - NULL THEN SSUB 2ND OPERAND IS SET TO 0000.           ** 36300001
*                                                                     * 36400001
         CLC   KVICOM,KUZERO            TEST IF ANY COMR PRESENT IN     36500001
*                                        SSUB LIST.                     36600001
         BE    SSBPZERO                 IF THERE IS NONE THEN SET SSUB  36700001
*                                        2ND OPERAND TO ZERO.           36800001
*                                                                     * 36900001
**       OBTAIN SSUB TRIPLE USING ZTXTAB AND STORED TEXT REFERENCE.  ** 37000001
**       STATUS OF BLOCK IS NOT CHANGED.                             ** 37100001
*                                                                     * 37200001
         ST    GR7,KVSTRG               STORE CURRENT TRIPLE POINTER.   37300001
         L     GR4,KVSSST               SET DICTIONARY REFERENCE OF     37400001
         ST    GR4,PAR1                  SSUB IN PAR1.                  37500001
         OI    PAR1,KUTFLG              SET NO STATUS CHANGE OPTION.    37600001
         L     LR,ZTXTAB                SET ADDRESS OF CONVERSION       37700001
         BALR  RR,LR                     ROUTINE IN BRANCH REGISTER AND 37800001
*                                        OBTAIN ABSOLUTE ADDRESS.       37900001
         L     GR7,PAR1                 PUT TRIPLE DSECT MASK OVER      38000001
*                                        SSUB TRIPLE.                   38100001
*                                                                     * 38200001
**       PUT COMR 2ND OPERAND IN SSUB TRIPLE 2ND OPERAND.            ** 38300001
*                                                                     * 38400001
SSBPREG1 MVC   XTRPOP2,KVICOM           INSERT REGISTER IN SSUB.        38500001
         B     SSBPREST                 RESTORE CURRENT TRIPLE POINTER. 38600001
*                                                                     * 38700001
**       PUT 0000 IN 2ND OPERAND OF SSUB TRIPLE.                     ** 38800001
*                                                                     * 38900001
SSBPZERO XC    XTRPOP2,XTRPOP2          CLEAR 2ND OPERAND.              39000001
SSBPREST L     GR7,KVSTRG               RESTORE CURRENT TRIPLE POINTER. 39100001
*                                                                     * 39200001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE.             ** 39300001
*                                                                     * 39400001
SSBPEXIT IEMKLVE                                                        39500001
         EJECT                                                          39600001
*********************************************************************** 39700001
*                                                                     * 39800001
**             KVSUBS - PROCESS SUBS AND SUBO TRIPLES.               ** 39900001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS : -        ** 40000001
**        SUBS LIST PROCESSING WORK AREAS ARE CLEARED AND SWITCHES   ** 40100001
**        ZEROIZED FOR EACH SUBS LIST ENCOUNTERED. THIS ENSURES THAT ** 40200001
**        ONLY INNERMOST SUBS LIST CONTENTS ARE TAKEN ACCOUNT OF WHEN** 40300001
**        SUB' IS PROCESSED.                                         ** 40400001
**        A STATUS SWITCH IS SET TO INDICATE THAT SUBS LIST IS       ** 40500001
**        CURRENTLY BEING PROCESSED.                                 ** 40600001
**        THE DICTIONARY REFERENCE OF THE ARRAY IS OBTAINED AND IF   ** 40700001
**        THE ARRAY IS AN ARRAY OF STRINGS A STATUS SWITCH IS SET ON.** 40800001
**        IF IT IS NOT AN ARRAY OF STRINGS THE TEXT REFERENCE OF THE ** 40900001
**        CURRENT OUTPUT TEXT POINTER IS OBTAINED AND STORED.        ** 41000001
**        ANY SUBO TRIPLE IS REPLACED BY A SUBS TRIPLE AND AN OFS    ** 41100001
**        TRIPLE WHICH ARE BOTH OUTPUT TO TEXT.                      ** 41200001
**        THE SUBROUTINE RETURN CODE VALUE IS :-                     ** 41300001
**                       0 - NORMAL ONLY.                            ** 41400001
*                                                                     * 41500001
*********************************************************************** 41600001
*                                                                     * 41700001
KVSUBS   IEMKENT  TYPE=2                                                41800001
*                                                                     * 41900001
*                                                                     * 42000001
**       CLEAR SUBS LIST PROCESSING WORK AREAS AND SWITCHES.         ** 42100001
*                                                                     * 42200001
         XC    KVOCOM,KVOCOM            CLEAR COMR OPERAND STORE.       42300001
         XC    KVSBST,KVSBST            CLEAR SUBS TEXT REF STORAGE.    42400001
         XC    KVSBT1,KVSBT1            ALL SWITCHES IN KVSBT1 MAY BE   42500001
*                                        ZEROIZED AS SUBS CANNOT OCCUR  42600001
*                                        WITHIN PATCH.                  42700001
         XC    KVSBT2,KVSBT2             CLEAR KVSBT2.                  42750001
*                                                                     * 42800001
**       SET SWITCH TO INDICATE START OF SUBS LIST.                  ** 42900001
*                                                                     * 43000001
         OI    KVSBT2,KUS2ON            SET SWITCH ON.                  43100001
*                                                                     * 43200001
**       OBTAIN DICTIONARY ENTRY OF ARRAY FROM SUBS 1ST OPERAND.     ** 43300001
*                                                                     * 43400001
         MVC   PAR1+2(2),XTRPOP1                                        43500001
*                                       SET DR(ARRAY) IN PAR1.          43600001
         L     LR,ZDRFAB                SET ADDRESS OF CONVERSION       43700001
*                                        ROUTINE IN BRANCH REGISTER.    43800001
         BALR  RR,LR                    GET ABSOLUTE DICTIONARY ADDRESS 43900001
         L     GR4,PAR1                 SET BASE POINTER TO DICTIONARY  44000001
*                                        ENTRY.                         44100001
         TM    KUDATA(GR4),KUS1ON       TEST HIGH ORDER BIT OF DATA     44200001
*                                        BYTE FOR STRING.               44300001
         BO    SUBSSUBO                 BRANCH TO TEST FOR SUBO.        44400001
*                                        IF ARRAY IS NOT ONE OF STRINGS 44500001
         OI    KVSBT2,KUS3ON            SET STATUS SWITCH.              45300001
*                                                                     * 46100001
**       TEST IF TRIPLE IS SUBS OR SUBO. IF SUBO REPLACE BY SUBS AND ** 46200001
**       OFS BEFORE OUTPUT TO TEXT.                                  ** 46300001
*                                                                     * 46400001
SUBSSUBO OI    KVSBT2,KUS1ON            SET SWITCH TO SHOW SUBS T-REF   46430001
*                                        HAS TO BE FOUND.               46460001
         CLI   XTRPCODE,XTRPSUBO        TEST WHETHER SUBS OR SUBO.      46500001
         BNE   SUBSEXIT                 IF SUBS TRIPLE EXIT SUBROUTINE. 46600001
*                                                                     * 46620001
         NI    KVSBT2,KUS1OF            SET SWITCH OFF AS SUBS T-REF    46640001
*                                       NEED NOT BE FOUND LATER.        46660001
         MVC   KVSOFS,XTRPOP2           STORE SUBO 2ND OPERAND.         46700001
         XC    XTRPOP2,XTRPOP2          SET SECOND OPERAND OF SUBO      46900001
         MVI   XTRPOP2+1,KUHVAL          TRIPLE TO X'00FF'.             47000001
         MVI   XTRPCODE,XTRPSUBS        CHANGE SUBO TO SUBS OPCODE.     47100001
*                                                                     * 47200001
**       THE NEW SUBS TRIPLE IS NOW OUTPUT TO TEXT.                  ** 47300001
*                                                                     * 47400001
         LA    GR4,XTRPCODE             SET ADDRESS OF TRIPLE IN        47500001
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           47600001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE IN PAR2    47700001
         ST    GR4,PAR2                  PARAMETER WORD.                47800001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          47900001
*                                                                     * 47906001
**       OBTAIN TEXT REFERENCE OF CURRENT OUTPUT TEXT POINTER USING  ** 47912001
**       ZTXTRF PROCESSING ROUTINE AND HENCE GET T-REF OF SUBS TRPL  ** 47918001
*                                                                     * 47924001
SUBSTREF L     GR4,SCTXTO               PLACE WORD CONTAINING OUTPUT    47930001
         ST    GR4,PAR1                  TEXT BLOCK NAME IN PAR1.       47936001
         L     GR4,ZPCOP                SET CURRENT ADDRESS TO OUTPUT   47942001
         ST    GR4,PAR2                  TEXT BLOCK IN PAR2.            47948001
         L     LR,ZTXTRF                LOAD BRANCH REGISTER.           47954001
         BALR  RR,LR                    GET TEXT REFERENCE OF CURRENT   47960001
         L     GR4,PAR1                  OUTPUT POINTER AND STORE IN    47966001
         LA    GR5,KUTRLN               SUBTRACT LENGTH OF TRIPLE TO    47972001
         SR    GR4,GR5                   GIVE TEXT REF OF SUBS.         47978001
         ST    GR4,KVSBST                RESERVED SLOT.                 47984001
*                                                                     * 48000001
**       THE OFS TRIPLE IS NOW SET UP IN THE PLACE OF SUBS TRIPLE.   ** 48100001
*                                                                     * 48200001
         MVI   XTRPCODE,XTRPOFS         CHANGE SUBS TO OFS OPCODE.      48300001
         MVC   XTRPOP1,KVSOFS           SET UP 1ST OFS OPERAND.         48400001
*                                                                     * 48500001
**       TEST FOR -VE OFFSET AND SET STATUS SWITCH ACCORDINGLY.      ** 48600001
*                                                                     * 48700001
         TM    XTRPOP2,KUS1ON          TEST HIGH ORDER BIT.             48800001
         BZ    SUBSEXIT                 RETURN TO CALLING MODULE.       48900001
         OI    KVSBT2,KUS4ON           SET STATUS SWITCH ON.            49000001
*                                                                     * 49100001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE.             ** 49200001
*                                                                     * 49300001
SUBSEXIT IEMKLVE                                                        49400001
         EJECT                                                          49500001
*********************************************************************** 49600001
*                                                                     * 49700001
**             KVSUBP - PROCESS SUB' TRIPLE                          ** 49800001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS : -        ** 49900001
**        THE APPROPRIATE STATUS SWITCH IS SET OFF TO INDICATE THAT  ** 50000001
**        END OF SUBS LIST HAS BEEN REACHED.                         ** 50100001
**        THE OCCURENCE OF COMA AND COMR TRIPLES IN THE SUBS LIST ARE** 50200001
**        CHECKED AND THE SUBS TRIPLE 2ND OPERAND IS CHANGED IF      ** 50300001
**        NECESSARY.                                                 ** 50400001
**        THE RETURN CODE VALUE IS 0 - NORMAL ONLY.                  ** 50500001
**                                                                   ** 50600001
*                                                                     * 50700001
*********************************************************************** 50800001
*                                                                     * 50900001
KVSUBP   IEMKENT  TYPE=1                                              * 51000001
*                                                                       51100001
         NI    KVSBT2,KUS2OF            SET SUBS LIST PROCESSING        51200001
*                                        INDICATOR SWITCH OFF.          51300001
*                                                                     * 51400001
**       TEST WHETHER ARRAY WAS ARRAY OF STRINGS OR THERE WAS -VE    ** 51500001
**       OFFSET IN THE SUBS LIST. IN EITHER CASE SUBS TRIPLE REMAINS ** 51600001
**       UNALTERED.                                                  ** 51700001
*                                                                     * 51800001
         TM    KVSBT2,KUS3ON            TEST IF ARRAY OF STRINGS.       51900001
         BO    SUBPEXIT                 IF ARRAY OF STRINGS EXIT.       52000001
         TM    KVSBT2,KUS4ON            TEST FOR -VE OFFSET.            52100001
         BO    SUBPEXIT                 IF -VE OFFSET EXIT FROM KVSUBP. 52200001
*                                                                     * 52300001
**       TEST FOR OCCURENCE OF NON NULL COMA 2ND OPERAND IN SUBS     ** 52400001
**       LIST OR MORE THAN 1 COMR.                                   ** 52500001
*                                                                     * 52700001
         TM    KVSBT2,KUS6ON            TEST FOR PRESENCE OF NON NULL   52800001
*                                        COMA 2ND OPERAND IN LIST.      52900001
         BO    SUBPEXIT                 IF ANY PRESENT LEAVE KVSUBP.    53000001
         TM    KVSBT2,KUS5ON            TEST IF MORE THAN 1 COMR        53100001
*                                        PRESENT IN LIST.               53200001
         BO    SUBPEXIT                 LEAVE KVSUBP IF MORE THAN ONE.  53300001
**       OBTAIN SUBS TRIPLE USING ZTXTAB AND STORED TEXT REF.        ** 53307001
**       STATUS OF BLOCK IS NOT CHANGED.                             ** 53314001
*                                                                     * 53321001
         ST    GR7,KVSTRG                STORE CURRENT TRIPLE POINTER.  53328001
         L     GR4,KVSBST               SET DICTIONARY REFERENCE OF     53335001
         ST    GR4,PAR1                  SUBS TRIPLE IN PAR1.           53342001
         OI    PAR1,KUTFLG              GIVE NO STATUS CHANGE OPTION.   53349001
         L     LR,ZTXTAB                SET ADDRESS OF CONVERSION       53356001
         BALR  RR,LR                     ROUTINE IN BRANCH REGISTER AND 53363001
*                                        OBTAIN ABSOLUTE ADDRESS.       53370001
         L     GR7,PAR1                 PUT TRIPLE DSECT MASK OVER SUBS 53377001
*                                        TRIPLE.                        53384001
*                                                                     * 53391001
*                                                                     * 53400001
**       IF THERE IS ONE COMR ONLY THEN SUBS 2ND OPERAND IS SET TO   ** 53500001
**       COMR 2ND OPERAND. IF THERE IS NO COMR IN LIST AND ONLY      ** 53600001
**       COMA - NULL THEN SUBS 2ND OPERAND IS SET TO 0000.           ** 53700001
*                                                                     * 53800001
         CLC   KVOCOM,KUZERO            TEST IF ANY COMR PRESENT IN     53900001
*                                        SUBS LIST.                     54000001
         BE    SUBPZERO                 IF THERE IS NONE THEN SET SUBS  54100001
*                                        2ND OPERAND TO ZERO.           54200001
*                                                                     * 55600001
**       PUT COMR 2ND OPERAND IN SUBS TRIPLE 2ND OPERAND.            ** 55700001
*                                                                     * 55800001
SUBPREG1 MVC   XTRPOP2,KVOCOM           INSERT REGISTER IN SUBS TRIPLE. 55900001
         B     SUBPREST                 LEAVE KVSUBP SUBROUTINE.        56000001
*                                                                     * 56100001
**       PUT X'0000' IN 2ND OPERAND OF SUBS TRIPLE                   ** 56200001
*                                                                     * 56300001
SUBPZERO XC    XTRPOP2,XTRPOP2          CLEAR 2ND OPERAND.              56400001
SUBPREST L     GR7,KVSTRG               RESTORE CURRENT TRIPLE POINTER. 56500001
*                                                                     * 56600001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE.             ** 56700001
*                                                                     * 56800001
SUBPEXIT IEMKLVE                                                        56900001
         EJECT                                                          57000001
*********************************************************************** 57100001
*                                                                     * 57200001
**             KVITDP - INSERT LOOP EPILOGUE IN OUTPUT TEXT.         ** 57300001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 57400001
**        THE 2ND OPERAND OF THE ITD' TRIPLE IS CHECKED TO DETERMINE ** 57500001
**        WHETHER HIGH ORDER BIT IS ON THUS INDICATING THAT LOOP HAS ** 57600001
**        BEEN OPTIMIZED AND A SKELETON EPILOGUE STACKED.            ** 57700001
**        THE ITD' TRIPLE IN AN OPTIMIZABLE LOOP IS REPLACED IN THE  ** 57800001
**        OUTPUT TEXT BY THE 2ND HALF OF LOOP CONTROL SKELETON WHICH ** 57900001
**        HAS BEEN FILLED IN AND STACKED IN SCRATCH CORE.            ** 58000001
**        IF STACKING ERROR OCCURS THE APPROPRIATE ERROR SWITCH BIT  ** 58100001
**        IS SET ON AND PHASE ERROR ROUTINE IS PERFORMED.            ** 58200001
**        IF STACK MARKER MATCHES ITD' 2ND OPERAND IN AN OPTIMIZABLE ** 58300001
**        LOOP THEN EPILOGUE IS WITHDRAWN FROM STACK, STACK POINTER  ** 58400001
**        IS UPDATED AND EPILOGUE IS INSERTED INTO OUTPUT TEXT.      ** 58500001
**        WHEN NO OPTIMIZATION HAS BEEN PERFORMED AND NO STACK ENTRY ** 58600001
**        MADE THE ITD' TRIPLE IS OUTPUT TO TEXT DIRECTLY.           ** 58700001
**        THE SUBROUTINE RETURN CODE VALUE IS : -                    ** 58800001
**                       0 - NORMAL ONLY.                            ** 58900001
*                                                                     * 59000001
*********************************************************************** 59100001
*                                                                     * 59200001
KVITDP   IEMKENT  TYPE=2                                                59300001
*                                                                     * 59400001
         SR    RC,RC                    ZEROIZE RETURN CODE REGISTER.   59500001
         TM    XTRPOP2,KUTFLG           TEST HIGH ORDER BIT OF ITDO'    59600001
*                                        2ND OPERAND.                   59700001
         BZ    ITDPNOOP                 BRANCH IF LOOP HAS NOT BEEN     59800001
*                                        MARKED OPTIMIZED AND EPILOGUE  59900001
*                                        THEREFORE NOT STACKED.         60000001
         NI    XTRPOP2,KUS1OF           SET HIGH ORDER BIT OFF.         60100001
*                                                                     * 60200001
**       DECREMENT ITDO NESTING LEVEL COUNT BY ONE FOR EACH ITDO'    ** 60300001
**       MARKED AS HAVING BEEN OPTIMIZED.                            ** 60400001
*                                                                     * 60500001
         SR    GR4,GR4                  CLEAR REGISTER.                 60600001
         IC    GR4,KUNEST               INSERT COUNT IN REGISTER.       60700001
         BCTR  GR4,GR0                  DECREMENT COUNT.                60800001
         STC   GR4,KUNEST               RESTORE COUNT.                  60900001
*                                                                     * 61000001
**       LOOP HAS BEEN OPTIMIZED. THEREFORE ITDO' 2ND OPERAND MUST   ** 61100001
**       MATCH EPILOGUE MARKER OR ERROR HAS OCCURED.                 ** 61200001
*                                                                     * 61300001
*                                                                     * 61400001
         L     GR4,KUSCPT               SET STACK POINTER IN REGISTER.  61500001
         CLC   XTRPOP2,0(GR4)           COMPARE ITDO' 2ND OP AND MARKER 61600001
*                                        IN EPILOGUE.                   61700001
         BE    ITDPMTCH                 IF EQUAL BRANCH TO WITHDRAW     61800001
*                                        EPILOGUE FROM STACK.           61900001
         MVI   KUERBT,X'05'             ERROR PARAMETER NUMBER - 5.     62000001
         B     KVERRS                   PERFORM PHASE ERROR ROUTINE.    62100001
*                                                                     * 62200001
**       ITDO' MATCHES EPILOGUE MARKER. TEST EPILOGUE TYPE. IF END OF** 62300001
**       STACK REACHED ERROR HAS OCCURED. OTHERWISE WITHDRAW EPILOGUE** 62400001
**       FROM STACK AND UPDATE STACK POINTER.                        ** 62500001
*                                                                     * 62700001
ITDPMTCH CLI   KUTWOB(GR4),KUMARK       TEST EPILOGUE TYPE.             62800001
         BNE   ITDPTOUT                 IF NOT END OF STACK BRANCH TO   62900001
*                                        SKIP ITD' AND CLN2 TRIPLES.    63000001
         MVI   KUERBT,X'06'             ERROR PARAMETER NUMBER - 6.     63100001
         B     KVERRS                   PERFORM PHASE ERROR ROUTINE.    63200001
*                                                                     * 63300001
**       WHEN OPTIMISED ITD' ENCOUNTERED ITD' AND FOLLOWING CLN2     ** 63330001
**       TRIPLE ARE BOTH IGNORED.                                    ** 63360001
*                                                                     * 63390001
ITDPTOUT L     PR1,KUREG1               SET PR1 BEFORE USING SCAN.      63420001
         ST    PR1,KUREG1               SAVE THE SCAN INPUT POINTER.    63510001
*                                                                     * 63540001
**       DETERMINE EPILOGUE TYPE AND PROCESS ACCORDINGLY.            ** 63570001
*                                                                     * 63600001
ITDPTEST CLI   2(GR4),KUMRK4            TEST EPILOGUE TYPE.             63700001
         CLI   2(GR4),KUMRK4            TEST EPILOGUE TYPE.             63900001
         BE    ITDPTYP4                 IF TYPE 4 BRANCH AND PROCESS.   64000001
         CLI   2(GR4),KUMRK3            IF NOT EPILOGUE TYPE 4 TEST IF  64100001
*                                        TYPE 3.                        64200001
         BE    ITDPTYP3                 IF TYPE 3 BRANCH AND PROCESS.   64300001
         CLI   2(GR4),KUMRK2            IF NOT EPILOGUE TYPE 3 TEST IF  64400001
*                                        TYPE 2.                        64500001
         BE    ITDPTYP2                 IF TYPE 2 BRANCH AND PROCESS.   64600001
         CLI   2(GR4),KUMRK1            IF NOT EPILOGUE TYPE 2 TEST IF  64700001
*                                        TYPE 1.                        64800001
         BE    ITDPTYP1                 IF TYPE 1 BRANCH AND PROCESS.   64900001
*                                                                     * 64960001
         MVI   KUERBT,X'01'             ERROR PARAMETER NUMBER - 1.     65020001
         B     KVERRS                   PERFORM PHASE ERROR ROUTINE.    65100001
*                                                                     * 65200001
**       WITHDRAW EPILOGUE TYPE 4 FROM STACK AND UPDATE STACK POINTR.** 65300001
*                                                                     * 65500001
ITDPTYP4 LA    GR5,KUMLEN+KUEPL4        SET DECREMENTING VALUE.         65600001
         SR    GR4,GR5                  UPDATE STACK POINTER REGISTER.  65700001
         MVC   KUSKLT(KULEN3),KUSKEL3   SAVE SKELETON TYPE 3.           65800001
         MVC   KU3C13(KUEPL4),KUMLEN(GR4)                               65900001
*                                       WITHDRAW TYPE 4 EPILOGUE AND    66000001
*                                        INSERT IN CORRECT PART OF TYPE 66100001
*                                        3 SKELETON.                    66200001
         ST    GR4,KUSCPT               SAVE UPDATED STACK POINTER.     66400001
*                                                                     * 66500001
**       OUTPUT THE EPILOGUE TYPE 4 TO TEXT.                         ** 66600001
*                                                                     * 66700001
*                                                                     * 66800001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF COMPILER LABEL ** 66900001
**       TRIPLE AND OUTPUT TRIPLE TO TEXT.                           ** 67000001
*                                                                     * 67100001
         LA    GR4,KU3C13               SET ADDRESS OF TRIPLE ITEM      67200001
         ST    GR4,PAR1                  IN PAR1 PARAMETER WORD.        67300001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE ITEM IN    67400001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           67500001
         BAL   RR,MV3A                  OUTPUT TRIPLE ITEM TO TEXT.     67600001
*                                                                     * 67700001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUD-CODE ITEM** 67800001
**       AND OUTPUT PSEUDO-CODE TO TEXT.                             ** 67900001
*                                                                     * 68000001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS         68100001
         LA    GR4,KU3C14               SET ADDRESS OF PSEUDO-CODE      68200001
         ST    GR4,PAR1                  IN PAR1 PARAMETER WORD.        68300001
         LA    GR4,KUPSC5               SET LENGTH OF PSEUDO-CODE IN    68400001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           68500001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     68600001
*                                                                     * 69600001
**       RESTORE TYPE 3 SKELETON FROM STORE AREA AND EXIT FROM       ** 69700001
**       SUBROUTINE.                                                 ** 69800001
*                                                                     * 69900001
         MVC   KUSKEL3,KUSKLT           RESTORE SKELETON TYPE 3,        70000001
         B     ITDPEXIT                 BRANCH TO EXIT SUBROUTINE.      70100001
*                                                                     * 70200001
**       WITHDRAW EPILOGUE TYPE 3 FROM STACK AND UPDATE STACK        ** 70300001
**       POINTER REGISTER                                            ** 70400001
*                                                                     * 70500001
ITDPTYP3 LA    GR5,KUMLEN+KUEPL3        SET DECREMENT VALUE.            70600001
         SR    GR4,GR5                  UPDATE STACK POINTER REGISTER.  70700001
         MVC   KUSKLT(KULEN3),KUSKEL3   SAVE SKELETON TYPE 3.           70800001
         MVC   KU3C12(KUEPL3),KUMLEN(GR4)                               70900001
*                                       WITHDRAW TYPE 3 EPILOGUE AND    71000001
*                                        INSERT IN CORRECT PART OF TYPE 71100001
*                                        3 SKELETON.                    71200001
         ST    GR4,KUSCPT               SAVE UPDATED STACK POINTER.     71300001
*                                                                     * 71400001
**       OUTPUT EPILOGUE TYPE 3 TO TEXT.                             ** 71500001
*                                                                     * 71600001
*                                                                     * 71700001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF LOAD PSEUDO-   ** 71800001
**       CODE ITEM AND OUTPUT TO TEXT.                               ** 71900001
*                                                                     * 72000001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.        72100001
         LA    GR4,KU3C12               SET ADDRESS OF PSEUDO-CODE ITEM 72200001
         ST    GR4,PAR1                  IN PAR1 PARAMETER WORD.        72300001
         LA    GR4,KUTRLN               SET LENGTH OF PSEUDO-CODE IN    72400001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           72500001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     72600001
*                                                                     * 72700001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF COMPILER LABEL ** 72800001
**       TRIPLE AND OUTPUT TRIPLE TO TEXT.                           ** 72900001
*                                                                     * 73000001
         LA    GR4,KU3C13               SET ADDRESS OF TRIPLE ITEM      73100001
         ST    GR4,PAR1                  IN PAR1 PARAMETER WORD.        73200001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE ITEM IN    73300001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           73400001
         BAL   RR,MV3A                  OUTPUT TRIPLE ITEM TO TEXT.     73500001
*                                                                     * 73600001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUD-CODE ITEM** 73700001
**       AND OUTPUT PSEUDO-CODE TO TEXT.                             ** 73800001
*                                                                     * 73900001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS         74000001
         LA    GR4,KU3C14               SET ADDRESS OF PSEUDO-CODE      74100001
         ST    GR4,PAR1                  IN PAR1 PARAMETER WORD         74200001
         LA    GR4,KUPSC5               SET LENGTH OF PSEUDO-CODE IN    74300001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           74400001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     74500001
*                                                                     * 75500001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF FINAL PSEUDO-  ** 75600001
**       CODE ITEM AND OUTPUT PSEUDO-CODE TO TEXT.                   ** 75700001
*                                                                     * 75800001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS         75900001
         LA    GR4,KU3C17               SET ADDRESS OF PSEUDO-CODE ITEM 76000001
         ST    GR4,PAR1                  IN PAR1 PARAMETER WORD.        76100001
         LA    GR4,KUPSC6               SET LENGTH OF PSEUDO-CODE IN    76200001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           76300001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     76400001
*                                                                     * 76500001
**       RESTORE TYPE 3 SKELETON FROM STORE AREA AND EXIT FROM       ** 76600001
**       SUBROUTINE.                                                 ** 76700001
*                                                                     * 76800001
         MVC   KUSKEL3,KUSKLT           RESTORE SKELETON TYPE 3,        76900001
         B     ITDPEXIT                 BRANCH TO EXIT SUBROUTINE.      77000001
*                                                                     * 77100001
**       WITHDRAW EPILOGUE TYPE 2 FROM STACK AND UPDATE STACK        ** 77200001
**       POINTER REGISTER.                                           ** 77300001
*                                                                     * 77400001
ITDPTYP2 LA    GR5,KUMLEN+KUEPL2        SET DECREMENT VALUE.            77500001
         SR    GR4,GR5                  UPDATE STACK POINTER REGISTER.  77600001
         MVC   KUSKLT(KULEN2),KUSKEL2   SAVE SKELETON TYPE 2.           77700001
         MVC   KU2C25(KUEPL2),KUMLEN(GR4)                               77800001
*                                       WITHDRAW TYPE 2 EPILOGUE FROM   77900001
*                                        STACK AND INSERT IN CORRECT    78000001
*                                        PART OF TYPE 2 SKELETON.       78100001
         ST    GR4,KUSCPT               SAVE UPDATED STACK POINTER.     78200001
*                                                                     * 78300001
**       OUTPUT EPILOGUE TYPE 2 TO TEXT.                             ** 78400001
*                                                                     * 78500001
*                                                                     * 78600001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE    ** 78700001
**       ITEM AND OUTPUT PSEUDO-CODE TO TEXT.                        ** 78800001
*                                                                     * 78900001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.        79000001
         LA    GR4,KU2C25               SET ADDRESS OF PSEUDO-CODE      79100001
         ST    GR4,PAR1                  IN PAR1.                       79200001
         LA    GR4,15                                                   79300001
         ST    GR4,PAR2                  IN PAR2 PARAMETER WORD.        79400001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     79500001
*                                                                     * 79600001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF TRIPLE AND     ** 79700001
**       OUTPUT TRIPLE TO TEXT.                                      ** 79800001
*                                                                     * 79900001
         LA    GR4,KU2C18               SET ADDRESS OF COMPILER LABEL   80000001
         ST    GR4,PAR1                  TRIPLE IN PAR1 PARAMETER WORD. 80100001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE IN PAR2    80200001
         ST    GR4,PAR2                  PARAMETER WORD.                80300001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          80400001
*                                                                     * 80500001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE    ** 80600001
**       ITEM AND OUTPUT PSEUDO-CODE TO TEXT.                        ** 80700001
*                                                                     * 80800001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.        80900001
         LA    GR4,KU2C19               SET ADDRESS OF PSEUDO-CODE ITEM 81000001
         ST    GR4,PAR1                  IN PAR1 PARAMETER WORD.        81100001
         LA    GR4,KUPSC5               SET LENGTH OF PSEUDO-CODE IN    81200001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           81300001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     81400001
*                                                                     * 81500001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF TRIPLE ITEM    ** 81600001
**       AND OUTPUT TRIPLE TO TEXT.                                  ** 81700001
*                                                                     * 81800001
         LA    GR4,KU2C21               SET ADDRESS OF COMPILER LABEL   81900001
         ST    GR4,PAR1                  TRIPLE IN PAR1.                82000001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE IN PAR2    82100001
         ST    GR4,PAR2                  PARAMETER WORD.                82200001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          82300001
*                                                                     * 82400001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE    ** 82500001
**       ITEM AND OUTPUT PSEUDO-CODE TO TEXT.                        ** 82600001
*                                                                     * 82700001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.        82800001
         LA    GR4,KU2C22               SET ADDRESS OF DROP PSEUDO-CODE 82900001
         ST    GR4,PAR1                  IN PAR1 PARAMETER WORD.        83000001
         LA    GR4,KUPSC8               SET LENGTH OF PSEUDO-CODE IN    83100001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           83200001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     83300001
*                                                                     * 83400001
**       RESTORE TYPE 2 SKELETON FROM STORE AREA AND EXIT FROM       ** 83500001
**       SUBROUTINE.                                                 ** 83600001
*                                                                     * 83700001
         MVC   KUSKEL2,KUSKLT           RESTORE SKELETON TYPE 2,        83800001
         B     ITDPEXIT                 BRANCH TO EXIT SUBROUTINE.      83900001
*                                                                     * 84000001
**       WITHDRAW EPILOGUE TYPE 1 FROM STACK, INSERT LABEL AND       ** 84100001
**       UPDATE THE STACK POINTER.                                   ** 84200001
*                                                                     * 84300001
ITDPTYP1 LA    GR5,KUMLEN+KUEPL1        SET DECREMENT VALUE.            84400001
         SR    GR4,GR5                  UPDATE STACK POINTER REGISTER.  84500001
         MVC   KUSKLT(KULEN1),KUSKEL1   SAVE SKELETON TYPE 1.           84600001
         MVC   KU1C19(KUEPL1),KUMLEN(GR4)                               84700001
*                                       WITHDRAW TYPE 1 EPILOGUE AND    84800001
*                                        INSERT IN CORRECT PART OF TYPE 84900001
*                                        3 SKELETON.                    85000001
         ST    GR4,KUSCPT               SAVE UPDATED STACK POINTER.     85050001
*                                                                     * 85100001
**       OUTPUT EPILOGUE TYPE 1 TO TEXT.                             ** 85200001
*                                                                     * 85300001
*                                                                     * 85400001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE    ** 85500001
**       ITEM AND OUTPUT TO TEXT.                                    ** 85600001
*                                                                     * 85700001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.        85800001
         MVI   SCSTK+1,KURSTA           SET REGISTER STATUS VALUE.      85900001
         LA    GR4,KU1C19               SET ADDRESS OF PSEUDO-CODE IN   86000001
         ST    GR4,PAR1                  PAR1 PARAMETER WORD.           86100001
         LA    GR4,KUPSC9               SET LENGTH OF PSEUD-CODE ITEM   86200001
         ST    GR4,PAR2                  IN PAR2.                       86300001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     86400001
*                                                                     * 86500001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF  TRIPLE ITEM   ** 86600001
**       AND OUTPUT TRIPLE TO TEXT.                                  ** 86700001
*                                                                     * 86800001
         LA    GR4,KU1C24               SET ADDRESS OF TRIPLE IN PAR1   86900001
         ST    GR4,PAR1                  PARAMETER WORD.                87000001
         LA    GR4,KUTRLN               SET LENGTH OF TRIPLE ITEM IN    87100001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           87200001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          87300001
*                                                                     * 87400001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE    ** 87500001
**       ITEM AND OUTPUT PSEUDO-CODE TO TEXT.                        ** 87600001
*                                                                     * 87700001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.        87800001
         MVI   SCSTK+1,KURSTA           SET REGISTER STATUS VALUE.      87900001
         LA    GR4,KU1C25               SET ADDRESS OF PSEUDO-CODE IN   88000001
         ST    GR4,PAR1                 PAR1 PARAMETER WORD.            88100001
         LA    GR4,KUPSC5               SET LENGTH OF PSEUDO-CODE IN    88200001
         ST    GR4,PAR2                 PAR2 PARAMETER WORD.            88300001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     88400001
*                                                                     * 88500001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF TRIPLE ITEM    ** 88600001
**       AND OUTPUT TRIPLE TO TEXT.                                  ** 88700001
*                                                                     * 88800001
         LA    GR4,KU1C27               SET ADDRESS OF TRIPLE IN PAR1   88900001
         ST    GR4,PAR1                  PARAMETER WORD.                89000001
         LA    GR4,10                   SET LENGTH OF TRIPLE IN PAR2    89100001
         ST    GR4,PAR2                  PARAMETER WORD.                89200001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          89300001
*                                                                     * 89400001
**       SET PAR1 AND PAR2 WITH ADDRESS AND LENGTH OF PSEUDO-CODE    ** 89500001
**       ITEM AND OUTPUT PSEUDO-CODE TO TEXT.                        ** 89600001
*                                                                     * 89700001
         XC    SCSTK,SCSTK              ZEROIZE REGISTER STATUS.        89800001
         LA    GR4,KU1C29               SET ADDRESS OF PSEUDO-CODE ITEM 89900001
         ST    GR4,PAR1                  IN PAR1.                       90000001
         LA    GR4,KUPSC2               SET LENGTH OF PSEUDO-CODE IN    90100001
         ST    GR4,PAR2                  PAR2 PARAMETER WORD.           90200001
         BAL   RR,MV3                   OUTPUT PSEUDO-CODE TO TEXT.     90300001
*                                                                     * 90400001
**       RESTORE TYPE 1 SKELETON FROM STORE AREA AND EXIT FROM       ** 90500001
**       SUBROUTINE.                                                 ** 90600001
*                                                                     * 90700001
         MVC   KUSKEL1,KUSKLT           RESTORE SKELETON TYPE 1,        90800001
         B     ITDPEXIT                 BRANCH TO EXIT SUBROUTINE.      90900001
*                                                                     * 91000001
**       ITDO' HAS BEEN MARKED TO INDICATE LOOP HAS NOT BEEN         ** 91100001
**       OPTIMIZED AND EPILOGUE NOT STACKED. ITDO' IND OPERAND IS    ** 91200001
**       TESTED AND AN ERROR IS INDICATED IF 2ND OPERAND AND EPILOGUE** 91300001
**       MARKER ARE MATCHED. IF THEY ARE NOT MATCHED ITDO' TRIPLE IS ** 91400001
**       OUTPUT AND EXIT MADE FROM SUBROUTINE.                       ** 91500001
*                                                                     * 91600001
ITDPNOOP L     GR4,KUSCPT               SET STACK POINTER TO REGISTER.  91660001
         CLC   XTRPOP2,0(GR4)           COMPARE ITD' 2ND OPERAND AND    91720001
*                                        MARKER IN EPILOGUE.            91800001
         BNE   ITDPNORM                 IF NOT MATCHED BRANCH TO OUTPUT 91900001
*                                        ITDO' TRIPLE TO TEXT.          92000001
         MVI   KUERBT,X'09'             ERROR PARAMETER NUMBER - 9.     92100001
         B     KVERRS                   PERFORM PHASE ERROR ROUTINE.    92200001
*                                                                     * 92300001
**       OUTPUT ITDO' TRIPLE TO TEXT FOR NORMAL UNOPTIMIZED CASE.    ** 92400001
*                                                                     * 92500001
ITDPNORM ST    GR7,PAR1                 SET TRIPLE ADDRESS IN PAR1.     92540001
         LA    GR4,KUTRLN               SET LENGTH OF CURRENT TRIPLE IN 92580001
         ST    GR4,PAR2                  PAR2.                          92620001
         BAL   RR,MV3A                  OUTPUT TRIPLE TO TEXT.          92660001
*                                                                     * 92700001
**       EXIT FROM SUBROUTINE WITH ZERO RETURN CODE                  ** 92800001
*                                                                     * 92900001
ITDPEXIT IEMKLVE                                                        93000001
         EJECT                                                          93100001
*********************************************************************** 93200001
*                                                                     * 93300001
**             KVERRS - PHASE ERROR ROUTINE.                         ** 93400001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 93500001
**        THE NUMERIC PARAMETER FOR THE ERROR IS INSERTED IN PAR5.   ** 93600001
**        THE MESSAGE NUMBER IS INSERTED IN PAR6.                    ** 93700001
**        THE ZUERR  PROCESSING ROUTINE IS THEN USED TO STORE THE    ** 93800001
**        DIAGNOSTIC MESSAGE IN THE DICTIONARY.                      ** 93900001
**        CONTROL IS PASSED TO THE ZABORT PROCESSING ROUTINE.        ** 94000001
*                                                                     * 94100001
**********************************************************************  94200001
*                                                                     * 94300001
KVERRS   IEMKENT  TYPE=LL2                                              94400001
*                                                                     * 94500001
         XC    PAR5,PAR5                                                94560001
         MVC   PAR5+3(1),KUERBT         SET NUMERIC PARAMETER IN PAR5.  94620001
*                                       SET NUMERIC PARAMETER IN PAR5.  94700001
         MVC   PAR6+1(2),KVBORT                                         94800001
*                                       SET ERROR MESSAGE NO IN PAR6.   94900001
         MVI   PAR6+3,X'60'             SET BITS TO GIVE STATEMENT NO   94960001
*                                        AND NUMERIC PARAMETER.         95020001
         L     LR,ZUERR                 INSERT DIAGNOSTIC MESSAGE IN    95100001
         BALR  RR,LR                     DICTIONARY.                    95200001
         L     LR,ZABORT                                                95300001
         BALR  RR,LR                    ABORT ROUTINE.                  95400001
*                                                                     * 95500001
**       END ERROR ROUTINE WITH STANDARD MACRO.                      ** 95600001
*                                                                     * 95602001
ERRSEXIT IEMKLVE                                                        95604001
         EJECT                                                          95606001
*********************************************************************** 95608001
*                                                                     * 95610001
**             KUSETS - PROCESSING INITIALIZATION SUBROUTINE.        ** 95612001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS :-         ** 95614001
**        SYMBOLIC REGISTERS ARE OBTAINED IF REQUIRED.               ** 95616001
**        THE DICTIONARY REFERENCE STORAGE SLOTS ARE CLEARED.        ** 95618001
**        APPROPRIATE PHASE STATUS SWITCH BYTES ARE ZEROISED.        ** 95620001
**        COMPILER LABELS ARE OBTAINED AND RESPECTIVE STORAGE SLOTS  ** 95622001
**        ARE UPDATED.                                               ** 95624001
**        THE SUBROUTINE RETURN CODE VALUE IS :                      ** 95626001
**                       0 - NORMAL ONLY.                            ** 95628001
*                                                                     * 95630001
*********************************************************************** 95632001
*                                                                     * 95634001
KUSETS   IEMKENT  TYPE=2                                                95636001
*                                                                     * 95724001
**       OBTAIN TWO COMPILER LABELS AND INSERT IN RESERVED SLOTS     ** 95726001
**       IF LAST OBTAINED HAVE BEEN USED.                            ** 95728001
*                                                                     * 95730001
SETSLABL TM    KUABYT,KUS1ON            ARE NEW LABELS REQUIRED.        95732001
         BZ    SETSINIT                 BRANCH IF NOT.                  95734001
         LA    GR4,KUINCR               SET INCREMENT VALUE IN REGISTER 95736001
         AH    GR4,ZEQMAX               INCREMENT CURRENT LABEL COUNT.  95738001
         STH   GR4,ZEQMAX               STORE UPDATED COUNT IN COMM     95740001
         STH   GR4,KULAB1                REGION AND PHASE SLOT.         95742001
         LA    GR4,KUINCR               SET INCREMENT VALUE IN REGISTER 95744001
         AH    GR4,ZEQMAX               INCREMENT CURRENT LABEL COUNT.  95746001
         STH   GR4,ZEQMAX               STORE UPDATED COUNT IN COMM     95748001
         STH   GR4,KULAB2                REGION AND PHASE SLOT.         95750001
*                                                                     * 95752001
**       CLEAR DIC REF STORAGE SLOTS AND ZEROISE APPROPRIATE PHASE   ** 95754001
**       STATUS SWITCHES.                                            ** 95756001
*                                                                     * 95758001
SETSINIT XC    KUSTDR,KUSTDR            CLEAR OPERAND STORAGE SLOTS.    95760001
         NI    KUSBYT,X'01'             SET SWITCHES 1 THRU 7 OFF.      95762001
         XC    KUABYT,KUABYT            ZEROISE KU AUX STATUS SWITCH.   95764001
         XC    KVSBT1,KVSBT1            ZEROISE 1ST KV STATUS BYTE.     95766001
*                                                                     * 95768001
**       RETURN TO CALLING MODULE WITH ZERO RETURN CODE              ** 95770001
*                                                                     * 95772001
SETSEXIT IEMKLVE                                                        95774001
         EJECT                                                          95776001
*********************************************************************** 95802001
*                                                                     * 95803001
**             KUENDS - KU PHASE END PROCESSING SUBROUTINE.          ** 95804001
**       THIS SUBROUTINE PERFORMS THE FOLLOWING FUNCTIONS : -        ** 95805001
**        THE LOOP EPILOGUE STACK IS CHECKED TO ENSURE THAT IT IS    ** 95806001
**        EMPTY.                                                     ** 95807001
**        SCRATCH CORE BLOCKS ARE RELEASED.                          ** 95808001
**        PATCH FILE TEXT BLOCKS ARE RELEASED.                       ** 95809001
**        KV MODULE IS RELEASED AND RETURN IS MADE TO CONTROL.       ** 95810001
**        THERE IS NO RETURN TO CALLING ROUTINE                      ** 95811001
*                                                                     * 95812001
*********************************************************************** 95813001
*                                                                     * 95814001
KUENDS   IEMKENT  TYPE=3                                                95815001
*                                                                     * 95816001
ENDSSTCK L     GR4,KUSCPT               SET STACK POINTER IN REGISTER.  95817001
         CLI   2(GR4),KUMARK            TEST EPILOGUE TYPE.             95818001
         BE    ENDSRSCR                 BRANCH TO RELEASE SCRATCH IF    95819001
*                                        END OF STACK HAS BEEN REACHED. 95820001
         MVI   KUERBT,X'08'             ERROR PARAMETER NUMBER - 8.     95821001
         B     KVERRS                   BRANCH TO ERROR ROUTINE.        95822001
*                                                                     * 95823001
**       RELEASE SCRATCH CORE.                                       ** 95824001
*                                                                     * 95825001
ENDSRSCR LA    GR4,1                    SET NO OF ENTRIES TO ZUGC IN    95826001
         ST    GR4,PAR1                  PAR1.                          95827001
         L     LR,ZURC                  RELEASE SCRATCH STORAGE         95828001
         BALR  RR,LR                     ALLOCATED BY ZUGC.             95829001
*                                                                     * 95830001
**       FREE THOSE TEXT BLOCKS USED FOR THE PATCH FILE.             ** 95831001
*                                                                     * 95832001
         MVI   PAR2+3,KUFREE            SET CODE BYTE FOR FREEING.      95833001
         XC    PAR1,PAR1                CLEAR PAR1.                     95834001
         LA    GR4,KVTBLK-1             SET ADDR OF T BLK TABLE IN REG. 95835001
ENDSTREL LA    GR4,1(0,GR4)             INCREMENT POINTER.              95836001
         CLI   0(GR4),X'5B'             IF END OF TABLE IS REACHED THEN 95837001
         BE    ENDSRLSE                  BRANCH TO RELEASE PHASE.       95838001
         CLI   0(GR4),X'FF'             IF BLOCK HAS NOT BEEN USED THEN 95839001
         BE    ENDSTREL                  BRANCH TO INCREMENT TO NEXT.   95840001
         MVC   PAR1+1(1),0(GR4)         OTHERWISE SET BLOCK NO IN PAR1. 95841001
         L     LR,ZALTER                SET ADDRESS OF ALTER ROUTINE    95842001
         BALR  RR,LR                     IN LINK REGISTER AND BRANCH.   95843001
         B     ENDSTREL                 RETURN TO TRY NEXT BYTE.        95844001
*                                                                     * 95845001
**       RELEASE MODULES KU AND KV AND PASS CONTROL TO NEXT REQUESTED** 95846001
*                                                                     * 95847001
ENDSRLSE XC    PAR2,PAR2                CLEAR PAR2.                     95848001
         LA    GR4,KUKVRL               SET ADDRESS OF RELEASE LIST IN  95849001
         ST    GR4,PAR1                  PAR1.                          95850001
         L     LR,RLSCTL                RELEASE KV AND PASS CONTROL.    95851001
         BALR  RR,LR                                                    95852001
*                                                                     * 95853001
ENDSEXIT IEMKLVE                                                        95854001
         EJECT                                                          95855001
         EJECT                                                          95900001
         LTORG                                                          96000001
         LTORG                                                          96260001
         END                                                            96300001
