LG       TITLE 'IEMLG, DO EXPANSION, PSEUDO-CODE GENERATION, OS/360 PL/C00030013
               I COMPILER(F)'                                           00060013
*              STATUS - CHANGE LEVEL 0                                  00090013
*                                                                       00120013
*                                                                       00150013
*                                                                       00180013
*              FUNCTIONS - (1) SCANS INPUT TEXT ONCE AND CREATES NEW    00210013
*        OUTPUT TEXT STRING.                                            00240013
*                          (2) REMOVES FROM TEXT THE FOLLOWINGTRIPLES-  00270013
*                                  B7  ITDO.           ITERATIVE LOOP   00300013
*                                  F7  ITDO'.          END OF LOOP      00330013
*                                  B9  DO.             DO GROUP MARKER  00360013
*                                  F9  DO'.            END OF DO GROUP  00390013
*                                  61  RIGHT ARROW.    CONTROL VAR END  00420013
*                                  64  INVERTED COMMA  NEW SPECIFICN.   00450013
*                                  80  TO              DELIMITERS OF    00480013
*                                  C0  TO'           LOOP LIMITS.       00510013
*                                  82  BY              DELIMITERS OF    00540013
*                                  C2  BY'           LOOP INCREMENTS.   00570013
*                                  84  WHILE           DELIMITERS OF    00600013
*                                  C4  WHILE'        WHILE CLAUSE.      00630013
*                                  8C  CV              CONTROL VARIABLE 00660013
*                                  CC  CV'             END OF SPECS.    00690013
*                          (3) GENERATES ADDITIONAL TEXT IN THE FORM    00720013
*        OF EITHER TRIPLES OR PSEUDO-CODE TO REPLACE THE ABOVE TRIPLES  00750013
*        AND RESULT IN GENERATION OF INSTRUCTIONS FOR DO LOOPS.         00780013
*                                                                       00810013
*                                                                       00840013
*                                                                       00870013
*              ENTRY POINTS - (1) FROM COMPILER CONTROL. THE MODULE     00900013
*        BASE IS LOADED, BLOCK IEMLH LOADED AND INITIALIZED, THE SCAN   00930013
*        ROUTINE IS INITIALIZED, AND A BLOCK OF SCRATCH CORE IS         00960013
*        OBTAINED FOR CONSTRUCTION OF DO CONTROL BLOCKS.                00990013
*                                                                       01020013
*                                                                       01050013
*                                                                       01080013
*              INPUT - DICTIONARY AND OUTPUT TEXT FROM PREVIOUS PHASE.  01110013
*        TEXT DESCRIBING DO LOOPS IS ASSUMED TO TAKE ONE OF THE         01140013
*        FOLLOWING STANDARD FORMS-                                      01170013
*              (A) ITERATIVE LOOPS.                                     01200013
*        ITDO        --      --                                         01230013
*          CONTROL VARIABLE TRIPLES                                     01260013
*        CV      LOOP      00 OR DICT. REF.                             01290013
*          INITIAL VALUE TRIPLES                                        01320013
*        ARROW   LAB1      00 OR DICT. REF.                             01350013
*        TO          --      --              PRESENT ONLY IF THERE IS   01380013
*          UPPER LIMIT TRIPLES               AN UPPER LIMIT SPECIFIED   01410013
*        TO'         --    00 OR DICT. REF.  *                          01440013
*        BY          --      --              PRESENT ONLY IF THERE IS   01470013
*          INCREMENT TRIPLES                 A TO OR A BY SPECIFIED     01500013
*        BY'         --    00 OR DICT. REF.  *                          01530013
*        WHILE   LOOP        --              PRESENT ONLY IF THERE IS   01560013
*          WHILE CLAUSE TRIPLES              A WHILE CLAUSE SPECIFIED   01590013
*        WHILE'  LAB1      00 OR DICT. REF.  *                          01620013
*        ****************                                               01650013
*        CLN2        --    LABN              THIS SECTION BETWEEN THE   01680013
*          INITIAL VALUE TRIPLES           ROWS OF ASTERISKS IS         01710013
*        INVCOM  LAB(N+1)  00 OR DICT. REF REPEATED FOR EACH LOOP       01740013
*          --                              SPECIFICATION AFTER THE      01770013
*          --                              FIRST.                       01800013
*        WHILE'  LAB(N+1)  00 OR DICT. REF                              01830013
*        ****************                                               01860013
*        CV'         --      --                                         01890013
*        CLN1        --      LOOP           START OF LOOP               01920013
*                                                                       01950013
*          TRIPLES AND PSEUDO-CODE REPRESENTING THE FUNCTIONS TO BE     01980013
*        PERFORMED WITHIN THE DO LOOP.                                  02010013
*                                                                       02040013
*        ITDO'       --      --             END OF LOOP                 02070013
*        CLN2        --      LABN           LAST LABEL DEFINED IN       02100013
*                                         WHILE', ARROW OR INVCOM.      02130013
*                                                                       02160013
*              (B) DO GROUPS (NON-ITERATIVE)                            02190013
*        DO          --      --                                         02220013
*        WHILE       --      --              PRESENT ONLY IF THERE IS   02250013
*          WHILE CLAUSE TRIPLES              A WHILE CLAUSE SPECIFIED   02280013
*        WHILE'      LAB1    00 OR DICT. REF.*                          02310013
*                                                                       02340013
*          TRIPLES AND PSEUDO-CODE REPRESENTING THE FUNCTIONS TO BE     02370013
*        PERFORMED WITHIN THE DO GROUP                                  02400013
*                                                                       02430013
*        DO'         --      --             END OF GROUP                02460013
*        CLN2        --      LAB1                                       02490013
*                                                                       02520013
*                                                                       02550013
*                                                                       02580013
*                   OUTPUT - DICTIONARY WITH, POSSIBLY, ERROR ENTRIES,  02610013
*        VARIABLE AND CONSTANT ENTRIES ADDED.                           02640013
*                            NEW TEXT STRING WITH ALL TRIPLES LISTED    02670013
*        IN THE FUNCTIONS PARAGRAPH DELETED. CORRESPONDING TO THE TWO   02700013
*        TYPES OF INPUT FOR DO GROUPS OUTPUT TAKES THE FOLLOWING        02730013
*        GENERAL FORMS.                                                 02760013
*              (A) ITERATIVE LOOPS                                      02790013
*        ITDO (PSEUDO-CODE ITEM)                                        02820013
*        TRIPLES TO ASSIGN ANY CONTROL VARIABLE SUBSCRIPTS TO FIXED     02850013
*              BINARY INTEGER TEMPORARIES WHICH CANNOT BE INCORPORATED  02880013
*              INTO THE WORKSPACE STACK(UNLESS SUBSCRIPT CONSTANT)      02910013
*        TRIPLES TO ASSIGN INITIAL VALUE, UPPER LIMIT AND INCREMENT     02940013
*              EXPRESSIONS TO TEMPORARIES OF TYPE,SCALE,MODE AND        02970013
*              PRECISION DEFINED BY THE EXPRESSION RESULT. THERE IS NO  03000013
*              ASSIGNMENT IF THE EXPRESSION IS A CONSTANT.              03030013
*        LA SYMBOLIC REGISTER, LABEL1 (PSEUDO-CODE).                    03060013
*        TRIPLES TO ASSIGN INITIAL VALUE TO CONTROL VARIABLE            03090013
*        GOLN  LABEL2  (TRIPLE)        BRANCH ROUND BUMPING CODE        03120013
*        CLN2  LABEL1  (TRIPLE)        DEFINE POINT OF RETURN FROM END  03150013
*        TRIPLES TO INCREMENT CONTROL VARIABLE. THESE TRIPLES ARE NOT   03180013
*              GENERATED IF THERE IS NO BY CLAUSE.                      03210013
*        CLN1  LABEL2  (TRIPLE)                                         03240013
*        TRIPLES TO COMPARE CONTROL VARIABLE AND UPPER LIMIT. IF THE    03270013
*              INCREMENT IS A CONSTANT THIS CONSISTS OF ONE COMPARISON  03300013
*              TRIPLE AND IF TRIPLE. IF THE INCREMENT EXPRESSION IS     03330013
*              NOT CONSTANT THEN THREE COMPARISONS ARE GENERATED. THE   03360013
*              FIRST TESTS THE SIGN OF THE INCREMENT AND BRANCHES TO    03390013
*              ONE OF THE OTHER TWO TESTS WHICH COMPARE THE CONTROL     03420013
*              VARIABLE WITH THE UPPER LIMIT AND CAUSE AN EXIT FROM     03450013
*              THE LOOP IF THIS HAS BEEN EXCEEDED IN THE DIRECTION      03480013
*              APPROPRIATE TO THE INCREMENT SIGN.                       03510013
*        TRIPLES FOR THE WHILE CLAUSE, UNCHANGED FROM THE INPUT.        03540013
*        AN IF TRIPLE TO EXIT ON FAILURE                                03570013
*                                                                       03600013
*        AT THE BOTTOM OF THE LOOP THE FOLLOWING IS GENERATED-          03630013
*        BCR  SYMBOLIC REGISTER (PSEUDO-CODE)                           03660013
*        ITDO' (PSEUDO-CODE)                                            03690013
*        CLN2  LABN     COPY OF INPUT LABEL TRIPLE                      03720013
*        TRIPLES TO SELL ANY CONTROLLED TEMPORARIES WHICH MAY HAVE      03750013
*              BEEN REQUIRED FOR VARYING STRING CONTROL EXPRESSIONS.    03780013
*                                                                       03810013
*              (B) DO GROUPS.                                           03840013
*              FOR DO GROUPS WITH NO WHILE CLAUSE THE DO AND DO'        03870013
*        TRIPLES ARE SUPPRESSED AND NO CODE IS GENERATED.               03900013
*              FOR DO GROUPS WITH WHILE CLAUSES THE OUTPUT IS-          03930013
*        ITDO (PSEUDO-CODE ITEM)                                        03960013
*        CLN2  LABEL1                                                   03990013
*        TRIPLES FOR THE WHILE CLAUSE, UNCHANGED FROM THE INPUT.        04020013
*        AN IF TRIPLE TO EXIT ON FAILURE.                               04050013
*                                                                       04080013
*        AT THE BOTTOM OF THE LOOP, MARKED BY A DO' TRIPLE-             04110013
*        GOLN  LABEL1                                                   04140013
*        ITDO' (PSEUDO-CODE)                                            04170013
*        CLN2  LAB1                                                     04200013
*                                                                       04230013
*                                                                       04260013
*                                                                       04290013
*              EXTERNAL ROUTINES - (1) ZDRFOF. COMPILER CONTROL         04320013
*        ROUTINE TO MAKE A DICTIONARY ENTRY.                            04350013
*                                  (2) ZABTOF. COMPILER CONTROL         04380013
*        COMPILATION TERMINATION.                                       04410013
*                                  (3) ZRLSOF. COMPILER CONTROL         04440013
*        RELEASE CONTROL.                                               04470013
*                                  (4) ZLDWOF. COMPILER CONTROL         04500013
*        PHASE LOADING ROUTINE.                                         04530013
*                                  (5) ZRFAOF. COMPILER CONTROL         04560013
*        DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.                      04590013
*                                  (6) ZTXROF. COMPILER CONTROL         04620013
*        ABSOLUTE ADDRESS TO SYMBOLIC TEXT REFERENCE.                   04650013
*                                  (7) ZUEROF. COMPILER CONTROL         04680013
*        ERROR ENTRY ROUTINE.                                           04710013
*                                  (8) ZUGCOF. COMPILER CONTROL         04740013
*        ROUTINE TO OBTAIN SCRATCH CORE.                                04770013
*                                  (9) ZURCOF. COMPILER CONTROL         04800013
*        ROUTINE TO RELEASE SCRATCH CORE.                               04830013
*                                 (10) SCINIT. SCAN PHASE ROUTINE TO    04860013
*        PERFORM INITIALIZATION FOR THIS PHASE.                         04890013
*                                 (11) SC1     SCAN PHASE ROUTINE       04920013
*        WHICH SCANS FROM THE CURRENT TRIPLE AND RETURNS CONTROL ON     04950013
*        THE FIRST TRIPLE OF INTEREST, HAVING MOVED INTERVENING TEXT    04980013
*        TO THE OUTPUT STRING.                                          05010013
*                                 (12) SC2     SCAN PHASE ROUTINE       05040013
*        PERFORMING SAME FUNCTION AS SC1 EXCEPT THAT CURRENT TRIPLE     05070013
*        IS MOVED TO OUTPUT WITHOUT EXAMINATION.                        05100013
*                                 (13) SC3     SCAN PHASE ROUTINE       05130013
*        PERFORMING SAME FUNCTION AS SC1 EXCEPT THAT CURRENT TRIPLE     05160013
*        IS DELETED.                                                    05190013
*                                 (14) SC5     SCAN PHASE ROUTINE       05220013
*        WHICH SETS THE INPUT POINTER TO ADDRESS THE NEXT TRIPLE AND    05250013
*        DELETES THE CURRENT TRIPLE.                                    05280013
*                                 (15) SC10    SCAN PHASE ROUTINE       05310013
*        TO CONVERT SYMBOLIC TEXT POINTER TO ABSOLUTE.                  05340013
*                                 (16) MV3     SCAN PHASE ROUTINE       05370013
*        TO MOVE PSEUDO-CODE STRINGS INTO OUTPUT.                       05400013
*                                 (17) MV3A    SCAN PHASE ROUTINE       05430013
*        TO MOVE TRIPLE TEXT STRINGS INTO OUTPUT.                       05460013
*                                 (18) EXPINT. IN BLOCK IEMLH.          05490013
*        INITIALIZATION ROUTINE FOR EXPRESSION ANALYSER.                05520013
*                                 (19) EXPEVR. IN BLOCK IEMLH.          05550013
*        ANALYSER ENTRY POINT TO RESUME ANALYSIS OF AN EXPRESSION       05580013
*        INTERRUPTED BY AN IMBEDDED DO LOOP.                            05610013
*                                 (20) EXPEVL. IN BLOCK IEMLH.          05640013
*        ANALYSER ENTRY POINT TO START ANALYSIS OF A NEW EXPRESSION     05670013
*                                                                       05700013
*                                                                       05730013
*                                                                       05760013
*              EXITS - NORMAL - LG0010 ENTERED UPON RECOGNITION OF      05790013
*        END-OF-TEXT MARKER.                                            05820013
*                                                                       05850013
*                                                                       05880013
*                                                                       05910013
*              EXITS - ERROR - LGABRT. TERMINATION OF COMPILATION       05940013
*        OWING TO- (1) INVALID RETURN FROM SCAN.                        05970013
*                  (2) ILLEGAL COMBINATION OF TRIPLES AT WHILE'.        06000013
*                  (3) NESTED PSEUDO-VARIABLE MARKERS.                  06030013
*                  (4) EXHAUSTION OF SYMBOLIC REGISTER NAMES.           06060013
*                  (5) INSUFFICIENT SCRATCH CORE AVAILABLE.             06090013
*                                                                       06120013
*                                                                       06150013
*                                                                       06180013
*              TABLES/WORKAREAS.- TWO TABLES ARE USED IN CONJUNCTION    06210013
*        WITH THE SCAN PHASE. THE FIRST, IN IEMLG, IS USED TO SCAN FOR  06240013
*        DO LOOP TRIPLES LISTED IN THE FUNCTIONS SECTION, TOGETHER      06270013
*        WITH THOSE TRIPLES SUCH AS STATEMENT LABELS WHICH SCAN MUST    06300013
*        IN ANY CASE EXAMINE.                                           06330013
*                             THE SECOND, IN IEMLG, IS USED BY THE      06360013
*        EXPRESSION ANALYSER TO SEEK THOSE TRIPLES WHICH REPRESENT      06390013
*        PREFIX OR INFIX OPERATIONS, OR WHICH MAY IMPLY THE USE OF AN   06420013
*        INTERMEDIATE RESULT, TOGETHER WITH THE TRIPLES TO',BY', RIGHT  06450013
*        ARROW, INVERTED COMMA AND ITDO WHICH REQUIRE A RETURN TO IEMLG 06480013
*                             OTHER TABLES IN IEMLG WHICH ARE USED      06510013
*        DURING THE SCANNING OF LOOP CONTROL VARIABLE TRIPLES ARE       06540013
*        DESCRIBED BELOW IN THE TECHNIQUES SECTION.                     06570013
*              TWO MAIN WORKAREAS ARE USED BY THIS PHASE. THE FIRST,    06600013
*        WHICH IS IN SCRATCH CORE IS USED BY IEMLG TO STACK INFORMATION 06630013
*        OBTAINED DURING SCANNING OF DO LOOP TRIPLES. STACKING ARISES   06660013
*        BECAUSE DO LOOPS MAY BE NESTED AND CERTAIN INFORMATION, SUCH   06690013
*        AS THE LOOP CLOSE REGISTER MUST BE HELD UNTIL THE END OF THE   06720013
*        LOOP. EACH DO OR ITDO TRIPLE CAUSES AN ENTRY TO BE MADE IN     06750013
*        THE STACK, AND EACH DO' OR ITDO' CAUSES THE TOP ENTRY TO BE    06780013
*        DELETED. THE ENTRIES HAVE THE FOLLOWING FORMAT-                06810013
*        BYTE. BIT. FUNCTION.                                           06840013
*        0     0    1 IF THERE IS A TO CLAUSE                           06870013
*              1    1 IF THERE IS A BY CLAUSE                           06900013
*              2    1 IF THERE IS A WHILE CLAUSE                        06930013
*              3    1 IF THE 'BY' EXPRESSION IS A CONSTANT              06960013
*              4    1 IF THE 'BY' EXPRESSION IS CONSTANT AND NEGATIVE   06990013
*              5    1 IF THE END OF SPECIFICATIONS HAS BEEN REACHED     07020013
*              6    1 IF FOR THIS LOOP AN EXPRESSION IS CURRENTLY       07050013
*                        BEING ANALYSED.                                07080013
*              7    1 IF THIS IS THE FIRST SPECIFICATION                07090015
*        1     0    1 IF THERE IS A SEGMENT OF TEXT TO BE GENERATED     07110013
*                        WHENEVER THE CONTROL VARIABLE IS REFERENCED    07140013
*              1    1 IF CONTROL VARIABLE TEXT CURRENTLY BEING SCANNED  07170013
*              2    1 IF CONTROL VARIABLE IS SUBSCRIPTED AND IS A       07200013
*                        LABEL, EVENT, FILE, TASK, POINTER OR AREA.     07230013
*              3    1 IF CONTROL VARIABLE IS A PSEUDO-VARIABLE.         07260013
*        2     0    1 IF 'DO' AS OPPOSED TO 'ITDO'                      07290013
*              1    1 IF LOOP IS ITERATIVE, I.E. NOT JUST DO-END OR     07320013
*                        DO CONTROL VAR.=EXPRESSION-END                 07350013
*              2    1 IF THE LOOP IS A FORMAT LIST ITERATION I.E. THE   07380013
*                        ITDO WAS PRECEDED BY RPL.                      07410013
*              3    1 IF THE LOOP AROSE FROM AN INITIAL VALUE LIST. THE 07440013
*                        BIT IS ALWAYS SET IN CONJUNCTION WITH 2.       07470013
*              4    1 IF THE LOOP IS NOT INITIAL VALUE OR FORMAT LOOP,  07480015
*                        BUT MAY NEVERTHELESS BE OPTIMIZED.             07490015
*        3          PSEUDO-VARIABLE CODE BYTE                           07500013
*              ALTERNATIVELY, IF THE LOOP IS TO BE OPTIMIZED, THIS BYTE 07506015
*              CONTAINS                                                 07512015
*              0   1 IF CV IS A TEMPORARY                               07518015
*              3   1 IF FOFL IS ENABLED FOR THE DO STATEMENT            07524015
*        4-7        ADDRESS OF STACK ENTRY FOR CONTAINING DO LOOP.      07530013
*        8          HEAD OF CHAIN OF CONTROLLED TEMPORARIES TO BE SOLD  07560013
*                   AT END OF LOOP.                                     07590013
*        10         LOOP CLOSE SYMBOLIC REGISTER OR LOOP CLOSE LABEL    07620013
*                   REFERENCE                                           07650013
*        THIS COMPLETES THE PART OF THE ENTRY WHICH IS RETAINED UNTIL   07680013
*        THE DO' OR ITDO' IS ENCOUNTERED. THE FOLLOWING PART IS         07710013
*        MAINTAINED ONLY UNTIL TEXT FOR THE TOP OF THE LOOP HAS BEEN    07740013
*        GENERATED, UNLESS THE LOOP IS TO BE OPTIMIZED.                 07770015
*        12         DICT. REF OF INITIAL VALUE EXPRESSION               07800013
*        14         DICT. REF OF 'TO' EXPRESSION.                       07830013
*        16         DICT. REF OF 'BY' EXPRESSION.                       07860013
*        18         DICT. REF OF CONTROL VARIABLE                       07890013
*        20         LABEL NUMBER OF START OF LOOP (OBTAINED FROM        07920013
*                   CV OR WHILE TRIPLE                                  07950013
*        22         LABEL NUMBER OF NEXT SPECIFICATION (OBTAINED        07980013
*                   FROM RIGHT ARROW, INVERTED COMMA OR WHILE' TRIPLE)  08010013
*        THIS COMPLETES THE PART OF THE ENTRY WHICH IS ALWAYS PRESENT   08040013
*        DURING LOOP TEXT GENERATION. THE FOLLOWING PART IS PRESENT     08070013
*        ONLY IF CONTROL VARIABLE TEXT MUST BE GENERATED WHENEVER THE   08100013
*        CONTROL VARIABLE IS REFERENCED.                                08130013
*        24         PSEUDO-VARIABLE CODE BYTE                           08160013
*        25-27      POSITION OF PSI' TRIPLE                             08190013
*        28         LENGTH OF CONTROL VARIABLE TEXT.                    08220013
*        30 ONWARDS CONTROL VARIABLE TEXT                               08250013
*                                                                       08280013
*        DURING CONTROL VARIABLE TEXT SCANNING THE FORMAT OF THE LATTER 08310013
*        PART OF THE DO BLOCK IS AS FOLLOWS-                            08340013
*        8          RETURN REGISTER SAVE 1                              08370013
*        12                              2                              08400013
*        16         PSEUDO VARIABLE ARGUMENT COUNTER                    08430013
*        18         SYMBOLIC TEXT POINTER 1                             08460013
*        21                               2                             08490013
*                                                                       08520013
*              THE SECOND WORKSPACE AREA MENTIONED ABOVE IS A 1024      08550013
*        BYTE SCRATCH AREA USED BY THE EXPRESSION ANALYSER (BLOCK       08580013
*        IEMLH) TO STACK INTERMEDIATE RESULT TYPES DURING THE ANALYSIS  08610013
*        OF LOOP CONTROL EXPRESSIONS. IT IS OBTAINED BY THE ROUTINE     08640013
*        EXPINT WHICH INITIALIZES THE BLOCK, AND IS RELEASED DURING     08670013
*        THE END-OF-TEXT PROCEDURE IN IEMLG. THE NATURE OF THE ENTRIES  08700013
*        IN THIS STACK IS THE SAME AS IN PHASE LS, WHERE THEY ARE       08730013
*        DESCRIBED IN DETAIL.                                           08760013
*                                                                       08790013
*                                                                       08820013
*                                                                       08850013
*              ATTRIBUTES - NON-REUSABLE                                08880013
*                                                                       08910013
*                                                                       08940013
*                                                                       08970013
*              NOTES (1) THIS PHASE REQUIRES NO MODIFICATION AS A       09000013
*        RESULT OF CHANGES IN THE INTERNAL REPRESENTATION OF EXTERNAL   09030013
*        GRAPHICS.                                                      09060013
*                    (2) REFERENCES TO EXTERNAL ROUTINES, THE           09090013
*        COMMUNICATIONS REGION, AND THE CURRENT ENTRY IN THE DO STACK   09120013
*        ARE MADE BY MEANS OF RELOCATEABLE SYMBOLS OBTAINED BY A        09150013
*        SUITABLE COMBINATION OF OFFSET DEFINITIONS AND USING           09180013
*        STATEMENTS.                                                    09210013
*                    (3) REGISTER USAGE.                                09240013
*        BASRG1. PHASE BASE AND SCAN ROUTINE PARAMETER BLOCK POINTER    09270013
*        EXPBAS. BASE FOR EXPRESSION ANALYSER (IEMLH)                   09300013
*        SCNBAS. BASE OF SCAN PHASE (IEMLA)                             09330013
*        CONBAS. BASE OF COMPILER CONTROL AREA.                         09360013
*        DICBAS. BASE OF COMMUNICATIONS REGION.                         09390013
*        DOBASE. POINTER TO THE CURRENT DO STACK ENTRY.                 09420013
*        IPTR    INPUT TEXT POINTER                                     09450013
*        TRTR    RESULT REGISTER RETURNED BY SCAN ROUTINES              09480013
*        RR      RETURN REGISTER FOR SUBROUTINE CALLS.                  09510013
*        LR      LINK REGISTER FOR EXTERNAL ROUTINE CALLS.              09540013
*        R1,R2   SUBROUTINE ARGUMENT REGISTERS.                         09570013
*        HR0-3   WORKING REGISTERS.                                     09600013
*                       (4) TECHNIQUES.                                 09630013
*                                    THE CONTROL VARIABLE TEXT IN A     09660013
*        STACK ENTRY IS DERIVED FROM THE CONTROL VARIABLE DESCRIPTION   09690013
*        TRIPLES IN THE INPUT TEXT, I.E. THOSE TRIPLES APPEARING        09720013
*        BETWEEN AN ITDO TRIPLE AND THE ASSOCIATED CV TRIPLE. IF THERE  09750013
*        IS NO SUCH TEXT, THEN THE VARIABLE IS A SIMPLE SCALAR AND ITS  09780013
*        DICT REF IS PLACED IN THE CV SLOT OF THE STACK ENTRY. IF       09810013
*        THERE IS TEXT THEN THE VARIABLE MUST BE SUBSCRIPTED, OR        09840013
*        DEFINED, OR A PSEUDO-VARIABLE. DURING THE SCANNING OF THIS     09870013
*        PART OF THE TEXT THE SPECIAL ROUTINES CVSCAN AND MOVOUT ARE    09900013
*        USED TO CONTROL THE INPUT TEXT POINTER. TRIPLES ARE MOVED      09930013
*        SINGLY AND ARE EXAMINED INDIVIDUALLY RATHER THAN BY MEANS OF   09960013
*        THE GENERAL SCAN ROUTINES.                                     09990013
*              THE OUTCOME IS THE ASSIGNMENT OF SUBSCRIPT EXPRESSIONS   10020013
*        TO INTEGER TEMPORARIES AND THE CONSTRUCTION OF A TEXT STRING   10050013
*        IN THE STACK WHICH IS USED WHENEVER THE CONTROL VARIABLE IS    10080013
*        REQUIRED. A SPECIAL CASE IS THE PSEUDO-VARIABLE WHICH MUST     10110013
*        HAVE ITS DELIMITING TRIPLES SET TO PSI,PSI' OR FUNCTION,       10140013
*        FUNCTION' ACCORDING AS THE VARIABLE IS BEING USED AS A         10170013
*        SOURCE OR TARGET.                                              10200013
         EJECT                                                          10230013
IEMLG    START 0                                                        10260013
         PRINT NODATA                                                   10290013
*                       DEFINITIONS OF SYMBOLS                          10320013
         SPACE 1                                                        10350013
*        GENERAL PURPOSE REGISTER NAMES AND USE                         10380013
LGBASE   EQU   3                       BASE OF BLOCK LG/PARAM BLOCK     10410013
LHBASE   EQU   10                      BASE OF BLOCK LH                 10440013
IPTR     EQU   1                       INPUT TEXT POINTER               10470013
TRTR     EQU   2                       RESULT REGISTER RETURNED BY SCAN 10500013
*                                    ROUTINES                           10530013
RR       EQU   14                      RETURN REGISTER                  10560013
LR       EQU   15                      LINK REGISTER                    10590013
CONBAS   EQU   11                      COMPILER CONTROL BASE            10620013
DICBAS   EQU   13                      DICTIONARY BASE                  10650013
SCNBAS   EQU   12                      BASE OF SCAN TRANSFER VECTOR     10680013
DOBASE   EQU   4                       POINTER TO CURRENT DO STACK      10710013
*                                    ENTRY IN SCRATCH CORE              10740013
HR0      EQU   0                       WORK REGISTER 0                  10770013
HR1      EQU   5                                     1                  10800013
R1       EQU   6                       ARGUMENT REG 1                   10830013
R2       EQU   7                                    2                   10860013
         SPACE 1                                                        10890013
*        BRANCH MNEMONIC DEFINITIONS                                    10920013
B        EQU   15                      BRANCH                           10950013
NOP      EQU   0                       NO-OP                            10980013
         SPACE 1                                                        11010013
BH       EQU   2                       BRANCH ON HIGH                   11040013
BL       EQU   4                                 LOW                    11070013
BE       EQU   8                                 EQUAL                  11100013
BNH      EQU   13                                NOT HIGH               11130013
BNL      EQU   11                                NOT LOW                11160013
BNE      EQU   7                                 NOT EQUAL              11190013
         SPACE 1                                                        11220013
BO       EQU   1                                 OVERFLOW/ONES          11250013
BP       EQU   2                                 PLUS                   11280013
BM       EQU   4                                 MINUS/MIXED            11310013
BZ       EQU   8                                 ZERO                   11340013
         SPACE 1                                                        11370013
BNO      EQU   14                                NOT OVERFLOW/ONES      11400013
BNP      EQU   13                                NOT PLUS               11430013
BNM      EQU   11                                NOT MINUS/MIXED        11460013
BNZ      EQU   7                                 NOT ZERO               11490013
         SPACE 1                                                        11520013
*        DEFINITIONS OF 4K BLOCKS USED TO EFFECT AUTOMATIC BASE         11550013
*        REGISTER ASSIGNMENT FOR COMMUNICATIONS REFERENCES              11580013
         SPACE 1                                                        11610013
LGBLOK   EQU   *                                                        11640013
LHBLOK   EQU   *+X'1000'                                                11670013
CONBLK   EQU   *+X'2000'                                                11700013
DICBLK   EQU   *+X'3000'                                                11730013
SCNBLK   EQU   *+X'4000'                                                11760013
DOBLOK   EQU   *+X'5000'                                                11790013
         SPACE 1                                                        11820013
         USING LGBLOK,LGBASE                                            11850013
         USING LHBLOK,LHBASE                                            11880013
         USING CONBLK,CONBAS                                            11910013
         USING DICBLK,DICBAS                                            11940013
         USING SCNBLK,SCNBAS                                            11970013
         USING DOBLOK,DOBASE                                            12000013
         SPACE 2                                                        12030013
*        DEFINITIONS OF EXPRESSION ANALYSIS ROUTINE OFFSETS             12060013
         SPACE 1                                                        12090013
EXPTMP   EQU   LHBLOK                  ANALYSIS ROUTINE RETURN SLOT     12120013
EXPINT   EQU   LHBLOK                  INITIALIZATION                   12150013
EXPEVR   EQU   EXPINT+4                RESUME ANALYSIS                  12180013
EXPEVL   EQU   EXPEVR+4                START ANALYSIS                   12210013
EXPTST   EQU   EXPEVL+4                TEST FOR OPTIMIZABLE LOOP.       12220015
         SPACE 2                                                        12240013
*        DEFINITIONS OF CONTROL PHASE TRANSFER VECTOR OFFSETS           12270013
ZUGCOF   EQU   CONBLK+X'10'            GET SCRATCH CORE                 12300013
ZURCOF   EQU   CONBLK+X'18'            RELEASE SCRATCH CORE             12330013
ZABTOF   EQU   CONBLK+X'20'            ABORT                            12360013
ZLDWOF   EQU   CONBLK+X'24'            LOAD AND WAIT                    12390013
ZDRFOF   EQU   CONBLK+X'2C'            MAKE DICT ENTRY. RETURN REF      12420013
ZUEROF   EQU   CONBLK+X'30'            MAKE ERROR ENTRY                 12450013
ZRFAOF   EQU   CONBLK+X'34'            DICT REF TO ABSOLUTE             12480013
ZRLSOF   EQU   CONBLK+X'48'            RELEASE CONTROL                  12510013
ZTXROF   EQU   CONBLK+X'50'            ABS TO SYMBOLIC TEXT REF         12540013
         SPACE 2                                                        12570013
*        DEFINITIONS OF DICTIONARY COMMUNICATION REGION OFFSETS         12600013
         SPACE 1                                                        12630013
ZCOMM    EQU   DICBLK+304              BASE OF INTER-PHASE REGION       12660013
ZMYNAM   EQU   DICBLK+112              PHASE NAME CELL                  12690013
PAR1     EQU   DICBLK+128              PARAMETER 1                      12720013
PAR2     EQU   PAR1+4                            2                      12750013
PAR3     EQU   PAR2+4                            3                      12780013
PAR4     EQU   PAR3+4                            4                      12810013
PAR5     EQU   PAR4+4                            5                      12840013
PAR6     EQU   PAR5+4                            6                      12870013
PAR7     EQU   PAR6+4                            7                      12900013
PAR8     EQU   PAR7+4                            8                      12930013
ZSMREG   EQU   ZCOMM+40                SYMBOLIC REGISTER NUMBER         12960013
ZCONCH   EQU   ZCOMM+78                HEAD OF CONSTANTS CHAIN          12990013
ZCITEM   EQU   ZCOMM+80                HEAD OF CONTROLLED CHAIN         13020013
ZEQMAX   EQU   ZCOMM+82                NEXT LABEL NUMBER SLOT           13050013
         SPACE 2                                                        13080013
*        DEFINITIONS OF SCAN ROUTINE TRANSFER VECTOR OFFSETS            13110013
         SPACE 1                                                        13140013
SCTV     EQU   SCNBLK                                                   13170013
SCINIT   EQU   SCTV                                                     13200013
SC1      EQU   SCINIT+4                SCAN FROM CURRENT IP AND MOVE    13230013
SC2      EQU   SC1+4                   MOVE CURRENT AND SCAN FROM NEXT  13260013
SC3      EQU   SC2+4                   IGNORE CURRENT.  SCAN FROM NEXT  13290013
SC4      EQU   SC3+4                   SKIP TO NEXT. MARK TEXT WANTED   13320013
SC5      EQU   SC4+4                                           FREE     13350013
SC6      EQU   SC5+4                   MOVE INPUT TRIPLE. MARK WANTED   13380013
SC7      EQU   SC6+4                                           FREE     13410013
SC8      EQU   SC7+4                   MOVE IP TO FIRST AFTER JMP-WANT  13440013
SC9      EQU   SC8+4                                              FREE  13470013
SC10     EQU   SC9+4                   CONVERT SYMBOLIC TEXT PTR TO ABS 13500013
SC11     EQU   SC10+4                  SKIP OVER PSEUDO-CODE - WANTED   13530013
SC12     EQU   SC11+4                                          FREE     13560013
         SPACE 1                                                        13590013
MVTV     EQU   SC12+4                                                   13620013
MV2      EQU   MVTV+4                  MOVE P/C TO CONTIGUOUS OUTPUT    13650013
MV3      EQU   MV2+4                   MOVE USER P/C TO OUTPUT          13680013
MV3A     EQU   MV3+4                   MOVE USER TRIPLES TO OUTPUT      13710013
         SPACE 1                                                        13740013
*              DEFINITIONS OF THE CODES USED IN THE SCAN TRT TABLE BY   13770013
*        THE SCAN ROUTINE                                               13800013
         SPACE 1                                                        13830013
A1       EQU   40                      FORMAT                           13860013
A2       EQU   44                      FORMAT'                          13890013
C        EQU   48                      PROC                             13920013
D        EQU   52                      BEGIN                            13950013
E        EQU   56                      PROC'                            13980013
F        EQU   60                      BEGIN'                           14010013
G        EQU   28                       JMP                             14040013
H        EQU   32                       SN,SL,CN,CL,SN2                 14070013
X        EQU   36                      ERROR OR END-OF-BLOCK TRIPLE     14100013
I        EQU   72                       EOP2                            14130013
         SPACE 2                                                        14160013
*        DEFINITIONS OF DO BLOCK OFFSETS                                14190013
         SPACE 1                                                        14220013
DOF1     EQU   DOBLOK                  FLAG BYTE 1                      14250013
DOF1TO   EQU   X'80'                   'TO' BIT                         14280013
DOF1BY   EQU   X'40'                   'BY' BIT                         14310013
DOF1WL   EQU   X'20'                   'WHILE'BIT                       14340013
DOF1CN   EQU   X'10'                   'CONSTANT BY' BIT                14370013
DOF1NG   EQU   X'08'                   'NEGATIVE BY' BIT                14400013
DOF1ES   EQU   X'04'                   'END-OF-SPECIFICATIONS' BIT      14430013
DOF1VL   EQU   X'02'                   CURRENTLY PERFORMING EXPRESSION  14460013
*                                    EVALUATION                         14490013
DOF1FS   EQU   X'01'                   'FIRST SPECIFICATION' BIT        14500015
DOF2     EQU   DOBLOK+1                FLAG BYTE 2                      14520013
DOF2CV   EQU   X'80'                   CONTROL VARIABLE TEXT TO MOVE    14550013
DOF2SC   EQU   X'40'                   SCANNING CONTROL VARIABLE FLAG   14580013
DOF2NS   EQU   X'FF'-DOF2SC            RESET MASK FOR SCANNING FLAG     14610013
DOF2ND   EQU   X'20'                   SUBSCRIPTED CONTROL VARIABLE     14640013
DOF2PS   EQU   X'10'                   CONTROL IS PSEUDO VARIABLE       14670013
DOF3     EQU   DOBLOK+2                FLAG BYTE 3                      14700013
DOF3DO   EQU   X'80'                   DO NOT ITDO                      14730013
DOF3IT   EQU   X'40'                   ITERATIVE                        14760013
DOF3RP   EQU   X'20'                   FORMAT LIST REPLICATION LOOP     14790013
DOF3IV   EQU   X'10'                   INITIAL VALUE REPLICATION LOOP   14820013
DOF3OP   EQU   X'08'                   OPTIMIZED LOOP, NOT FORMAT OR    14830015
*                                    INITIAL VALUE LOOP.                14840015
DOPCOD   EQU   DOBLOK+3                PSEUDO-VARIABLE CODE BYTE        14850013
DOTEMP   EQU   X'80'                 TEMPORARY CV BIT                   14860015
DOPREV   EQU   DOBLOK+4                ADDRESS OF NESTING DO BLOCK      14880013
DOE0     EQU   DOBLOK+8                REFERENCE TO CHAIN OF E TEMPS    14910013
DOR0     EQU   DOE0+2                  RETURN REGISTER (ITDO ONLY)      14940013
DOL0     EQU   DOR0                    LABEL FOR RETURN (DO ONLY)       14970013
DOCORE   EQU   DOR0+2                  CORE PRESERVED TO ITDO' OR DO'   15000013
DOE1     EQU   DOCORE                  DICT REF OF INITIAL VALUE EXPRN  15030013
DOE2     EQU   DOE1+2                  DICT REF OF 'TO' EXPRESSION      15060013
DOE3     EQU   DOE2+2                  DICT REF OF 'BY' EXPRESSION      15090013
DOCV     EQU   DOE3+2                  DICT REF OF CONTROL VARIABLE     15120013
DOLOOP   EQU   DOCV+2                  DICT REF OF LOOP COMPILER LABEL  15150013
DOLABI   EQU   DOLOOP+2                REF OF LABEL OF NEXT SPECIFICATN 15180013
DOVAR    EQU   DOLABI+2                START OF VARIABLE PART OF BLOCK  15210013
DOPP     EQU   DOVAR                   POSITION OF PSI' IN CV TEXT      15240013
DOLV     EQU   DOVAR+4                 LENGTH OF CV TEXT                15270013
DOTXT    EQU   DOLV+2                  START OF TEXT                    15300013
DOMIN    EQU   DOTXT                                                    15330013
DOMINL   EQU   DOMIN-DOBLOK            MINIMUM INITIAL DO BLOCK LENGTH  15360013
*              LAYOUT OF BLOCK DURING CONTROL VARIABLE SCAN             15390013
DORR1    EQU   DOBLOK+8                RR SAVE 1                        15420013
DORR2    EQU   DORR1+4                 RR SAVE 2                        15450013
DOCOM    EQU   DORR2+4                 ARGUMENT COUNT FOR PSEDO-VBLES   15480013
DOSIP1   EQU   DOCOM+2                 SYMBOLIC TEXT POINTER 1          15510013
DOSIP2   EQU   DOSIP1+3                                      2          15540013
DOSCNL   EQU   DOSIP2+3-DORR1          LENGTH OF SCANNING PART OF DO.   15570013
         SPACE 2                                                        15600013
*        DEFINITIONS OF DICTIONARY ENTRY CODES                          15630013
         SPACE 1                                                        15660013
DRSL     EQU   X'00'                   LABEL CONSTANT                   15690013
DRCON    EQU   X'88'                   CONSTANT                         15720013
DRTEMP   EQU   X'8F'                   SCALAR TEMPORARY                 15750013
DRDATA   EQU   X'0F'                   DATA VARIABLE                    15780013
DRSTRC   EQU   X'0E'                   STRUCTURE MEMBER                 15810013
         SPACE 2                                                        15840013
*              OFFSETS OF FIELDS IN DICTIONARY ENTRIES                  15870013
         SPACE 1                                                        15900013
CHAIN    EQU   3                       HASH CHAIN FIELD                 15930013
FRECHN   EQU   6                       SLOT USED FOR CHAINING           15960013
*                                    CONTROLLED TEMPORARIES             15990013
DEVAR    EQU   11                      VARIABLE BYTE                    16020013
VARSEC   EQU   X'80'                 SECOND OFFSET FLAG                 16050013
VARCTL   EQU   X'01'                 ALLOCATION ENTRY FLAG              16080013
VARNCT   EQU   X'FF'-VARCTL          MASK TO RESET FLAG                 16110013
DEOT2    EQU   12                      OTHER 2 BYTE                     16140013
OT2FP    EQU   X'08'                 FORMAL PARAMETER FLAG              16170013
OT2CTL   EQU   X'03'                 CONTROLLED                         16200013
OT2NCT   EQU   X'FF'-OT2CTL          MASK TO RESET CONTROLLED FLAGS     16230013
DEDATA   EQU   15                      DATA BYTE                        16260013
DATCAD   EQU   X'80'                 ARITHMETIC DATUM FLAG              16290013
DATADJ   EQU   X'40'                 ADJUSTABLE STRING FLAG             16320013
DATPTR   EQU   X'40'                 POINTER                            16350013
DATARE   EQU   X'02'                 AREA                               16380013
DATPIC   EQU   X'08'                 PICTURED BIT                       16410013
DATDCN   EQU   X'88'                   DECIMAL FIXED                    16440013
DEPICT   EQU   19                      PICTURE REF                   I8 16450016
         SPACE 1                                                        16470013
DECNDB   EQU   5                       DATA BYTE IN CONSTANT            16500013
DECNVL   EQU   14                      VALUE IN CONSTANT ENTRY          16530013
DEFCOD   EQU   7                       FUNCTION CODE BYTE BEFORE        16560013
*                                    GENERIC SELECTION                  16590013
DEAUTO   EQU   11                      HEAD OF AUTOMATIC CHAIN IN ET1   16620013
ET1LC    EQU   3                       LEVEL AND COUNT IN ET1           16650013
         SPACE 2                                                        16680013
*        DEFINITIONS OF TRIPLE OPERATORS                                16710013
         SPACE 1                                                        16740013
TRRPL    EQU   X'1C'                   RPL                              16770013
TRNULF   EQU   X'2F'                   NULL FUNCTION                    16800013
TRALAS   EQU   X'37'                   ALLOCATE AND ASSIGN              16830013
TRIGNR   EQU   X'38'                   IGNORE                           16860013
TRPSI    EQU   X'3A'                   PSEUDO-VARIABLE                  16890013
TRFUN    EQU   X'3C'                   FUNCTION                         16920013
TRARY    EQU   X'3E'                   ARRAY                            16950013
TRCOM    EQU   X'41'                   COMMA                            16980013
TRDCOM   EQU   X'42'                   DOUBLE COMMA                     17010013
TRASGN   EQU   X'47'                   ASSIGN                           17040013
TRTMPD   EQU   X'58'                   TMPD                             17070013
TRJUMP   EQU   X'5B'                   JUMP                             17100013
TRLORE   EQU   X'65'                   LESS THAN OR EQUAL               17130013
TRGORE   EQU   X'67'                   GREATER THAN OR EQUAL            17160013
TRGTR    EQU   X'6D'                   GREATER                          17190013
TRLESS   EQU   X'6F'                   LESS                             17220013
TRMIN    EQU   X'73'                   -                                17250013
TRPLUS   EQU   X'75'                   +                                17280013
TRPSIP   EQU   X'7A'                                                    17310013
TRUNM    EQU   X'7B'                   UNARY -                          17340013
TRFUNP   EQU   X'7C'                   FUNCTION'                        17370013
TRUNP    EQU   X'7D'                   UNARY +                          17400013
TRARYP   EQU   X'7E'                   ARRAY'                           17430013
TRTO     EQU   X'80'                   TO                               17460013
TRBY     EQU   X'82'                   BY                               17490013
TRFREE   EQU   X'83'                   FREE                             17520013
TRWHIL   EQU   X'84'                   WHILE                            17550013
TRCV     EQU   X'8C'                   CV                               17580013
TRGOLN   EQU   X'A8'                   GO TO LABEL NUMBER               17610013
TRITDO   EQU   X'B7'                   ITDO                             17640013
TRIF     EQU   X'BB'                   IF                               17670013
TRBYP    EQU   X'C2'                   BY'                              17700013
TRCVP    EQU   X'CC'                   CV'                              17730013
TRCLN1   EQU   X'D1'                   COMPILER LABEL NUMBER TYPE 1     17760013
TRCLN2   EQU   X'D3'                   COMPILER LABEL NUMBER TYPE 2     17790013
TRITDP   EQU   X'F7'                   ITDO'                            17820013
         SPACE 2                                                        17850013
*        DEFINITIONS OF PSEUDO-CODE OPERATORS                           17880013
         SPACE 1                                                        17910013
PSDROP   EQU   X'06'                   DROP                             17940013
PSITDO   EQU   X'0F'                   ITDO                             17970013
PSITDP   EQU   X'1F'                   ITDO'                            18000013
PSERR    EQU   X'3C'                   ERROR CODE                       18030013
PSBCR    EQU   X'41'                   BCR                              18060013
PSLTR    EQU   X'52'                   LTR                              18090013
PSBCTP   EQU   X'80'                   BCT TO LABEL NUMBER              18120013
PSBC     EQU   X'81'                   BC                               18150013
PSL      EQU   X'88'                   L                                18180013
PSC      EQU   X'89'                   C                                18190015
PSA      EQU   X'8A'                   A                                18200015
PSST     EQU   X'A5'                   ST                               18210013
PSLAP    EQU   X'B7'                   LA'                              18240013
PSUSLD   EQU   X'D8'                   USSLD                            18270013
PSSNLS   EQU   X'DB'                   SINLST                           18300013
         SPACE 2                                                        18330013
*        OTHER ASSEMBLY PARAMETERS                                      18360013
         SPACE 1                                                        18390013
SUBSTR   EQU   X'30'                   CODE FOR 'SUBSTR' IN GENERIC     18420013
*                                    ENTRY.                             18450013
DOF1TW   EQU   DOF1TO+DOF1WL           TO OR WHILE                      18480013
DOF1EW   EQU   DOF1ES+DOF1WL           END-OF-SPECS OR WHILE            18510013
DOF1NV   EQU   X'FF'-DOF1VL                                             18540013
DOF3IR   EQU   DOF3IT+DOF3RP+DOF3IV    INIT+REPLN+ITERATIVE             18570013
MINUS    EQU   X'73'                   INTERNAL - SIGN                  18580015
         EJECT                                                          18600013
*                       INITIALIZATION OF PHASE                         18630013
         SPACE 1                                                        18660013
LG0000   DC    C'LG'                   NAME OF PHASE                    18690013
         L     LGBASE,PAR1             LOAD BASE REGISTER OF BLOCK LG   18720013
         MVC   ZMYNAM(2),LG0000        PLACE NAME OF PHASE IN           18750013
         BC    B,LG0001              COMMUNICATIONS REGION              18780013
         SPACE 2                                                        18810013
*              THE FOLLOWING TEXT REPRESENTS THE SCAN ROUTINE           18840013
*        PARAMETER BLOCK, COMPRISING TRANSLATE TABLE AND TEXT BLOCK     18870013
*        INFORMATION.                                                   18900013
         SPACE 1                                                        18930013
         CNOP  0,4                     ALIGN TO WORD BOUNDARY           18960013
SCPRAM   EQU   *                                                        18990013
SCTRT    DC    AL1(X)                  ERROR               00           19020013
         DC    XL15'0'                                     01-0F        19050013
         DC    XL15'0'                                     10-1E        19080013
         DC    AL1(B1)                 FORMAT LIST         1F           19110013
         DC    XL16'0'                                     20-2F        19140013
         DC    XL16'0'                                     30-3F        19170013
         DC    XL16'0'                                     40-4F        19200013
         DC    XL11'0'                                     50-5A        19230013
         DC    AL1(G)                  JUMP                5B           19260013
         DC    XL3'0'                                      5C-5E        19290013
         DC    AL1(B2)                 FORMAT LIST'        5F           19320013
         DC    X'0'                                        60           19350013
         DC    AL1(V)                  CONTROL VAR ASSIGN  61           19380013
         DC    XL2'0'                                      62-63        19410013
         DC    AL1(W)                  REPEATED CV ASSIGN  64           19440013
         DC    XL11'0'                                     65-6F        19470013
         DC    XL16'0'                                     70-7F        19500013
         DC    AL1(P)                  TO                  80           19530013
         DC    X'0'                                        81           19560013
         DC    AL1(R)                  BY                  82           19590013
         DC    X'0'                                        83           19620013
         DC    AL1(T)                  WHILE               84           19650013
         DC    XL7'0'                                      85-8B        19680013
         DC    AL1(N)                  CV                  8C           19710013
         DC    XL3'0'                                      8D-8F        19740013
         DC    XL16'0'                                     90-9F        19770013
         DC    XL16'0'                                     A0-AF        19800013
         DC    XL3'0'                                      B0-B2        19830013
         DC    AL1(C)                  PROC                B3           19860013
         DC    X'0'                                        B4           19890013
         DC    AL1(D)                  BEGIN               B5           19920013
         DC    X'0'                                        B6           19950013
         DC    AL1(J)                  ITDO                B7           19980013
         DC    X'0'                                        B8           20010013
         DC    AL1(L)                  DO                  B9           20040013
         DC    XL2'0'                                      BA-BB        20070013
         DC    AL1(H)                  SN2                 BC           20100013
         DC    XL2'0'                                      BD-BE        20130013
         DC    AL1(A1)                 FORMAT              BF           20160013
         DC    AL1(Q)                  TO'                 C0           20190013
         DC    X'0'                                        C1           20220013
         DC    AL1(S)                  BY'                 C2           20250013
         DC    X'0'                                        C3           20280013
         DC    AL1(U)                  WHILE'              C4           20310013
         DC    XL7'0'                                      C5-CB        20340013
         DC    AL1(O)                  CV'                 CC           20370013
         DC    XL3'0'                                      CD-CF        20400013
         DC    AL1(H)                  SN                  D0           20430013
         DC    X'0'                                        D1           20460013
         DC    AL1(H)                  SL                  D2           20490013
         DC    X'0'                                        D3           20520013
         DC    AL1(H)                  CN                  D4           20550013
         DC    XL11'0'                                     D5-DF        20580013
         DC    XL13'0'                                     E0-EC        20610013
         DC    AL1(X)                  END-OF-BLOCK        ED           20640013
         DC    AL1(I)                  EOP2                EE           20670013
         DC    X'0'                                        EF           20700013
         DC    XL3'0'                                      F0-F2        20730013
         DC    AL1(E)                  PROC'               F3           20760013
         DC    X'0'                                        F4           20790013
         DC    AL1(F)                  BEGIN'              F5           20820013
         DC    X'0'                                        F6           20850013
         DC    AL1(K)                  ITDO'               F7           20880013
         DC    X'0'                                        F8           20910013
         DC    AL1(M)                  DO'                 F9           20940013
         DC    XL5'0'                                      FA-FE        20970013
         DC    AL1(A2)                 FORMAT'             FF           21000013
         SPACE 1                                                        21030013
*              END OF SCAN TRANSLATE TABLE                              21060013
*              THE FOLLOWING IS THE REMAINDER OF THE SCAN PARAMETER     21090013
*        BLOCK                                                          21120013
         SPACE 1                                                        21150013
SCSTAD   DC    F'0'                    ADDRESS OF PREVIOUS STATEMENT.   21180015
SCEOBO   DC    F'0'                                      OP             21210013
SCJMP    DC    F'0'                    SYMBOLIC POSITION OF JMP TRIPLE  21240013
SCPCG    DC    F'0'                    COUNT OF PSEUDO CODE GENERATED   21270013
SCTXTI   DC    F'0'                    NAME OF IP BLOCK                 21300013
SCTXTO   DC    F'0'                            OP                       21330013
SCWKSC   DC    F'0'                    CURRENT WORKSPACE COUNT          21360013
SCBLK    DC    H'0'                    DICT REF OF CURRENT BLOCK        21390013
SCSTK    DC    H'0'                    CURRENT REGISTER USAGE           21420013
SCWSDR   DC    H'0'                    DICT REF OF CURRENT WORKSPACE    21450013
SCOPT    DC    X'00'                   PREFIX OPTION BYTE               21480013
         DC    X'00'                                                    21510013
         SPACE 1                                                        21540013
*              END OF SCAN PARAMETER BLOCK                              21570013
         SPACE 2                                                        21600013
*              THE AREA BEGINNING AT WORKSP IS USED BOTH FOR            21630013
*        INITIALIZATION CODE AND FOR WORKSPACE DURING EXECUTION OF      21660013
*        THE PHASE.                                                     21690013
         DS    0F                                                       21720013
WORKSP   EQU   *                                                        21750013
         EJECT                                                          21780013
*              BEGIN INITIALIZATION OF PHASE                            21810013
*              SET UP BASE ADDRESS OF PHASE AT BEGINNING OF SCAN BLOCK  21840013
*        SO THAT SAME REGISTER CAN BE USED FOR BASE AND SCAN PARAMETER  21870013
         SPACE 1                                                        21900013
LG0001   LA    LGBASE,SCPRAM-LG0000(0,LGBASE)                           21930013
         USING SCPRAM,LGBASE                                            21960013
         SPACE 1                                                        21990013
*              LOAD SECOND CONTROL SECTION                              22020013
         LA    HR1,CNLDLH                                               22050013
         ST    HR1,PAR1                                                 22080013
         L     LR,ZLDWOF               LOAD LH                          22110013
         BALR  RR,LR                                                    22140013
         L     LHBASE,PAR1             LOAD BASE FOR LH                 22170013
         SPACE 1                                                        22200013
         BAL   RR,SCINIT               PERFORM SCAN INITIALIZATION      22230013
*                                    FOR THIS PHASE                     22260013
         SPACE 1                                                        22290013
         BAL   RR,EXPINT               PERFORM EXPRESSION ANALYSIS      22320013
*                                    INITIALIZATION                     22350013
         SPACE 1                                                        22380013
*              GET 3K OF SCRATCH AND SET UP DUMMY DO BLOCK              22410013
         LA    HR1,6                   SET PAR1=6, REQUESTING 3072      22440013
         ST    HR1,PAR1              BYTE SCRATCH AREA                  22470013
         L     LR,ZUGCOF                                                22500013
         BALR  RR,LR                   ON RETURN, PLACE ADDRESS OF      22530013
         L     DOBASE,PAR1           AREA IN DOBASE                     22560013
         SPACE 1                                                        22590013
         LR    HR1,DOBASE                                               22620013
         XC    0(DOMINL,HR1),0(HR1)    CLEAR DUMMY DO BLOCK             22650013
         SPACE 1                                                        22680013
*              INITIALIZATION OF PHASE NOW COMPLETED                    22710013
         EJECT                                                          22740013
*              MAIN INPUT TEXT SCANNING SECTION. THE SCAN ROUTINE SC1   22770013
*        IS USED TO SEEK TRIPLES RELEVANT TO DO EXPANSION. ON ENTRY     22800013
*        TO THIS SECTION REGISTERS ARE CORRECTLY SET TO POINT AT THE    22830013
*        INPUT TEXT AND THE SCAN PARAMETER BLOCK.                       22860013
         SPACE 1                                                        22890013
*              ENTRY IS AT THIS POINT WHEN SCANNING IS TO COMMENCE      22920013
*        FROM THE CURRENT INPUT TEXT POINTER VALUE                      22950013
         SPACE 1                                                        22980013
LG0002   BAL   RR,SC1                  SCAN ROUTINE RETURNS HAVING      23010013
         EX    0,LG0004(TRTR)        UPDATED IPTR.                      23040013
         SPACE 1                                                        23070013
LG0003   BAL   RR,SC3                  DELETE CURRENT TRIPLE AND SCAN   23100013
         EX    0,LG0004(TRTR)                                           23130013
         SPACE 1                                                        23160013
*              BRANCH TABLE FOR TRIPLE OPERATOR SCAN VALUES             23190013
         SPACE 1                                                        23220013
LG0004   EQU   *-A1                                                     23250013
         BC    B,LG0030                FORMAT                           23280013
         BC    B,LG0031                FORMAT'                          23310013
         BC    B,LG0040                PROC                             23340013
         BC    B,LG0041                BEGIN                            23370013
         BC    B,LG0042                PROC'                            23400013
         BC    B,LG0043                BEGIN'                           23430013
         BC    B,LGABT0                JMP, SL ETC. ARE NOT SCANNED     23460013
         BC    B,LGABT0              FOR BY THIS PHASE.                 23490013
EOP2     BC    B,LG0010                EOP2                             23520013
ITDO     BC    B,LG0011                ITDO                             23550013
ITDOP    BC    B,LG0012                ITDO'                            23580013
DO       BC    B,LG0013                DO                               23610013
DOP      BC    B,LG0014                DO'                              23640013
CV       BC    B,LG0015                CV                               23670013
CVP      BC    B,LG0016                CV'                              23700013
TO       BC    B,LG0017                TO                               23730013
TOP      BC    B,LG0018                TO'                              23760013
BY       BC    B,LG0019                BY                               23790013
BYP      BC    B,LG0020                BY'                              23820013
WHILE    BC    B,LG0021                WHILE                            23850013
WHILEP   BC    B,LG0022                WHILE'                           23880013
ASSGN1   BC    B,LG0023                FIRST ASSIGN                     23910013
ASSGN2   BC    B,LG0024                SUBSEQUENT ASSIGN                23940013
RPL      BC    B,LG0028                RPL                              23970013
FMTL     BC    B,LG0030                FORMAT LIST                      24000013
FMTLP    BC    B,LG0031                FORMAT LIST'                     24030013
         SPACE 1                                                        24060013
*              DEFINITIONS OF THE CODES USED IN THE SCAN TRT TABLE FOR  24090013
*        TRIPLES OF INTEREST TO THIS PHASE                              24120013
         SPACE 1                                                        24150013
J        EQU   ITDO-LG0004              ITDO                            24180013
K        EQU   ITDOP-LG0004            ITDO'                            24210013
L        EQU   DO-LG0004               DO                               24240013
M        EQU   DOP-LG0004              DO'                              24270013
N        EQU   CV-LG0004               CV                               24300013
O        EQU   CVP-LG0004              CV'                              24330013
P        EQU   TO-LG0004               TO                               24360013
Q        EQU   TOP-LG0004              TO'                              24390013
R        EQU   BY-LG0004               BY                               24420013
S        EQU   BYP-LG0004              BY'                              24450013
T        EQU   WHILE-LG0004            WHILE                            24480013
U        EQU   WHILEP-LG0004           WHILE'                           24510013
V        EQU   ASSGN1-LG0004           FIRST ASSIGN                     24540013
W        EQU   ASSGN2-LG0004           SUBSEQUENT ASSIGN                24570013
Z        EQU   RPL-LG0004              RPL                              24600013
B1       EQU   FMTL-LG0004             FORMAT LIST                      24630013
B2       EQU   FMTLP-LG0004            FORMAT LIST'                     24660013
         EJECT                                                          24690013
*                       EOP TRIPLE                                      24720013
         SPACE 1                                                        24750013
*              THIS SECTION IS ENTERED WHEN THE END OF PROGRAM TRIPLE   24780013
*        IS ENCOUNTERED                                                 24810013
*              ACTION. SCRATCH CORE STILL OUTSTANDING IS RELEASED AND   24840013
*        THEN BLOCKS LG AND LH ARE RELEASED AND CONTROL PASSES TO THE   24870013
*        NEXT PHASE                                                     24900013
         SPACE 1                                                        24930013
LG0010   LA    HR1,2                   TWO SCRATCH BLOCKS REMAIN, THE   24960013
         ST    HR1,PAR1              FIRST USED BY THIS BLOCK, AND      24990013
         L     LR,ZURCOF             THAT USED BY EXPRESSION ANALYSER.  25020013
         BALR  RR,LR                                                    25050013
         SPACE 1                                                        25080013
         LA    HR1,CNRLS               FINALLY RELEASE THE PHASE        25110013
         ST    HR1,PAR1                                                 25140013
         SR    HR1,HR1                                                  25170013
         ST    HR1,PAR2                                                 25200013
         L     LR,ZRLSOF               CALL ZRLSCTL                     25230013
         BALR  RR,LR                   CONTROL NOW PASSES TO NEXT       25260013
*                                    PHASE                              25290013
         SPACE 2                                                        25320013
*                       ABORT EXIT                                      25350013
         SPACE 1                                                        25380013
LGABT0   L     HR1,ERID05              ERROR RETURN FROM SCAN           25410013
         SPACE 1                                                        25440013
LGABRT   ST    HR1,PAR6              ANSTORE ERROR CODE AND ABORT       25470013
         L     LR,ZUEROF                                                25500013
         BALR  RR,LR                                                    25530013
         L     LR,ZABTOF               CALL ABORT                       25560013
         BALR  RR,LR                                                    25590013
         EJECT                                                          25620013
*                       ITDO TRIPLE                                     25650013
         SPACE 1                                                        25680013
*              THIS SECTION IS ENTERED WHEN AN ITDO TRIPLE IS FOUND     25710013
*        IN THE TEXT.                                                   25740013
*              ACTION. THE CURRENT DO BLOCK IS PUSHED DOWN AND AN AREA  25770013
*        INITIALIZED FOR THE DO TEXT ABOUT TO BE PROCESSED.             25800013
         SPACE 1                                                        25830013
LG0011   BAL   RR,PSHDWN               PUSH DOWN STACK AND INITIALIZE   25860013
*                                    NEW DO BLOCK                       25890013
         OI    DOF2,DOF2SC             SET 'SCANNING CONTROL VARIABLE'  25920013
         OI    DOF1,DOF1FS             SET FIRST SPECIFICATION BIT      25930015
         BAL   RR,SC5                  DROP ITDO TRIPLE FROM TEXT AND   25950013
         LA    R1,SP04               INSERT ITDO PSEUDO-CODE ITEM       25980013
         LA    R2,3                                                     26010013
         BAL   RR,LMV3U                                                 26040013
         SPACE 1                                                        26070013
         CLI   0(IPTR),TRRPL           NOW TEST WHETHER THE NEXT        26100013
         BC    BNE,LG1102            TRIPLE IS RPL. IF IT IS THEN THIS  26130013
         MVI   SWRPL,DOF3IR          LOOP REPRESENTS A REPLICATION IN   26160013
         BAL   RR,SC5                AN INITIAL VALUE LIST. SET INITIAL 26190013
*                                    VALUE AND REPLICATION BITS IN DO.  26220013
         SPACE 1                                                        26250013
LG1102   OI    DOF3,0                  THIS SETS THE RPL BIT ON IN      26280013
SWRPL    EQU   LG1102+1              FLAG 3 IF THIS LOOP AROSE FROM     26310013
         MVI   SWRPL,0               A FORMAT REPLICATION.              26340013
         SPACE 1                                                        26370013
         CLI   0(IPTR),TRCV            TEST TO SEE IF THE NEXT TRIPLE   26400013
         BC    BE,LG0015             IS CV, AND GO DIRECTLY TO THAT     26430013
*                                    SECTION IF IT IS CV.               26460013
         SPACE 1                                                        26490013
*              THE CONTROL VARIABLE IS MORE THAN JUST A SCALAR          26520013
LG1101   LA    R1,LISTCV               USE CVSCAN WITH A LIST WHICH     26550013
         BAL   RR,CVSCAN             CONSISTS OF JUST THE CV TRIPLE.    26580013
         SPACE 1                                                        26610013
         CLI   0(IPTR),TRARY           ON RETURN THE INPUT POINTER      26640013
         BC    BE,LG0025             ADDRESSES THE LAST UNPRIMED        26670013
*                                    DELIMITER AT LEVEL 1               26700013
         CLI   0(IPTR),TRPSI         PRECEDING THE CV TRIPLE.           26730013
         BC    BE,LG0026               TEXT BETWEEN ITDO AND THIS       26760013
*                                    TRIPLE HAS BEEN MOVED TO OUTPUT    26790013
         CLI   0(IPTR),TRFUN           TEST THE CURRENT TRIPLE          26820013
         BC    BE,LG0027             AND GO TO THE APPROPRIATE          26850013
*                                    SECTION TO SCAN THE ARGUMENTS      26880013
*                                    OR SUBSCRIPTS AND ASSIGN TO        26910013
*                                    INTEGER TEMPORARIES AS NECESSARY   26940013
         SPACE 1                                                        26970013
*              AT THIS POINT SECOND RELEASE MUST TEST FOR DYNAMIC       27000013
*        DEFINED (ADF COMPILER FUNCTION)                                27030013
         SPACE 1                                                        27060013
         BAL   RR,MOVOUT               IF NONE OF ABOVE, MOVE TEXT      27090013
*                                    TO CV AND PROCEED FROM THERE       27120013
         BC    B,LG0015                                                 27150013
         EJECT                                                          27180013
*                       ITDO' TRIPLE                                    27210013
         SPACE 1                                                        27240013
*              THIS SECTION IS ENTERED WHEN AN ITDO' TRIPLE IS          27270013
*        FOUND IN THE TEXT                                              27300013
*              ACTION.  LOOP CLOSING INSTRUCTIONS ARE GENERATED. THE    27330013
*        ITDO' AND FOLLOWING COMPILER LABEL TRIPLES ARE COPIED INTO     27360013
*        THE OUTPUT TEXT, FOLLOWED BY FREE TRIPLES AS NECESSARY TO      27390013
*        RELEASE ANY TEMPORARIES USED IN THE LOOP                       27420013
         SPACE 1                                                        27450013
LG0012   TM    DOF3,DOF3IT             TEST THE ITERATIVE FLAG AND      27480013
         BC    BZ,LG1202             BRANCH IF NOT ON (NO LOOP CLOSE)   27510013
         SPACE 1                                                        27540013
         TM    DOF3,DOF3RP             TEST FOR FORMAT REPLICATION AND  27570013
         BC    BNZ,LG1220            GO TO GENERATE SPECIAL CLOSE CODE  27600013
         SPACE 1                                                        27607015
         TM    DOF3,DOF3OP             TEST FOR OPTIMIZEABLE CASE AND   27614015
         BC    BNZ,LG1230            GO TO GENERATE BUMP AND TEST CODE  27621015
         SPACE 1                                                        27630013
*              GENERATE LOOP CLOSING INSTRUCTIONS                       27660013
         SPACE 1                                                        27690013
         MVC   SP011(2),DOR0           SET UP BCR B,R0                  27720013
         MVC   SP002(2),DOR0                  DROP R0  PSEUDO-CODE AND  27750013
         LA    R1,SP00               GENERATE A PSEUDO-CODE BRANCH ON   27780013
         LA    R2,8                  REGISTER, FOLLOWED BY A DROP       27810013
         BAL   RR,LMV3U                                                 27840013
         SPACE 1                                                        27870013
*              NOW TEST TO SEE WHETHER ANY TEMPORARIES NEED TO BE SOLD  27900013
         SPACE 1                                                        27930013
LG1201   LA    R1,SP05                 PLACE ITDO' PSEUDO-CODE IN       27960013
         LA    R2,3                  OUTPUT TEXT, THEN DROP THE         27990013
         BAL   RR,LMV3U              THE ITDO' TRIPLE FROM              28020013
LG1202   BAL   RR,SC5                THE OUTPUT TEXT                    28050013
         SPACE 1                                                        28080013
         CLC   DOE0(2),CNZERO          IF NO TEMPORARIES ARE TO BE      28110013
         BC    BE,LG1210             SOLD GO TO PUSH UP DO STACK        28140013
         SPACE 1                                                        28170013
         BAL   RR,SC7                  MOVE LABEL TO OUTPUT AND POINT   28200013
*                                    IPTR AT NEXT TRIPLE.               28230013
         SPACE 1                                                        28260013
         MVC   ST112(2),DOE0           PREPARE TO FREE FIRST TEMPORARY  28290013
LG1204   LA    R1,ST11                                                  28320013
         BAL   RR,LMV3A5               GENERATE FREE TRIPLE             28350013
         MVC   PAR1+2(2),ST112                                          28380013
         L     LR,ZRFAOF               GET DICTIONARY ENTRY OF TEMP     28410013
         BALR  RR,LR                 DICT REF. AND PICK UP THE CHAIN    28440013
         L     HR1,PAR1              FIELD FROM THE ENTRY AND PLACE IT  28470013
         MVC   ST112(2),FRECHN(HR1)  IN THE FREE SKELETON. CLEAR THE    28500013
         MVC   FRECHN(2,HR1),CNZERO  CHAIN FIELD IN THE ENTRY           28530013
         CLC   ST112(2),CNZERO                                          28560013
         BC    BNE,LG1204              FALL THROUGH AT THE END OF THE   28590013
*                                    CHAIN                              28620013
*        NOW PUSH UP THE DO STACK AND RESTORE THE STATUS OF THE OUTER   28650013
*        BLOCK                                                          28680013
         SPACE 1                                                        28710013
LG1210   L     DOBASE,DOPREV           CHAIN BACK TO CONTAINING ENTRY   28740013
         TM    DOF1,DOF1VL             TEST FOR CURRENT EXPRESSION      28770013
         BC    BZ,LG1203             ANALYSIS AND BRANCH IF NOT         28800013
         SPACE 1                                                        28830013
         BAL   RR,EXPEVR               IF EVALUATING AN EXPRESSION      28860013
         BC    B,LG0002              RETURN TO THAT SECTION TO          28890013
*                                    CONTINUE ANALYSIS                  28920013
         SPACE 1                                                        28950013
LG1203   TM    DOF2,DOF2SC             TEST FOR CONTROL VARIABLE        28980013
         BC    BZ,LG0002             SCANNING. RESUME NORMAL SCAN IF    29010013
         BC    B,LG0500              NOT, OTHERWISE RE-ENTER MOVOUT     29040013
*                                    TO CONTINUE MOVE CONTROL VARIABLE  29070013
*                                    TEXT INTO OUTPUT                   29100013
         SPACE 3                                                        29130013
*              FORMAT OR INITIAL VALUE REPLICATION                      29160013
         SPACE 1                                                        29190013
LG1220   BAL   RR,LMV3US               GENERATE USSLD 1,2,7 TO AVOID    29220013
*                                    UNNECESSARY SAVING (FORMAT CASE)   29250013
         SPACE 1                                                        29280013
         MVC   SP091(2),DOE0           PUT PRESERVED COUNTER REF IN     29310013
         MVC   SP092(2),DOR0         LOAD AND LABEL NUMBER IN BCT'.     29340013
         LA    R1,SP09                 GENERATE                         29370013
         LA    R2,SP09L                L 14,CV                          29400013
         BAL   RR,LMV3U                BCT 14,LABEL OF LOOP             29430013
         SPACE 1                                                        29460013
         BAL   RR,SC5                  DELETE ITDO' AND COPY LABEL      29490013
         BAL   RR,SC7                                                   29520013
         BAL   RR,LMV3SN               GENERATE SINLIST FOR FORMAT      29550013
         SPACE 1                                                        29580013
         BC    B,LG1210                NOW GO TO CHAIN BACK TO          29610013
*                                    CONTAINING LOOP.                   29640013
         SPACE 3                                                        29640615
*              OPTIMIZABLE LOOP. THE COUNT AND TEST CODE IS GENERATED   29641215
*        AT THE END OF THE LOOP. THE CODE SEQUENCE IS -                 29641815
*              ITDO  14                MARKER TO INDICATE USE OF 14 TO  29642415
*                                    LS                                 29643015
*                  L    14,CV                                           29643615
*                  A    14,BY                                           29644215
*              CLN2  LABI              ENTRY FROM CODE AT TOP OF LOOP   29644815
*                  ST   14,CV                                           29645415
*                  C    14,TO                                           29646015
*                  BC   BX,LOOP        X IS BNH (+VE BY) BNL (-VE BY)   29646615
         SPACE 1                                                        29647215
LG1230    XC   DOPCOD(1),SCOPT         COMPARE THE FIXED OVERFLOW       29647816
         TM    DOPCOD,X'10'          PREFIX ON THE DO AND END           29648416
         BC    BZ,LG1232             STATEMENTS                         29649016
         SPACE 1                                                        29649616
         L     HR1,SCSTAD              IF DIFFERENT, SWITCH THE OPTION  29650216
         XI    2(HR1),X'10'          ON THE END STATEMENT               29650816
         SPACE 1                                                        29651415
LG1232   LA    R1,ST18                                                  29652015
         BAL   RR,LMV3A5               GENERATE ITDO 14                 29652615
         SPACE 1                                                        29653215
         MVC   SP101(2),DOCV           SET UP SKELETON AND GENERATE     29653815
         MVC   SP102(2),DOE3         LOAD AND ADD.                      29654415
         LA    R1,SP10                                                  29655015
         LA    R2,SP10L                                                 29655615
         BAL   RR,LMV3U                                                 29656215
         SPACE 1                                                        29656815
         BAL   RR,SC5                  DELETE ITDO' AND COPY LABEL      29657415
         BAL   RR,SC7                INTO OUTPUT                        29658015
         SPACE 1                                                        29658615
         MVC   SP081(2),DOCV           SET UP SKELETON AND GENERATE     29659215
         MVC   SP082(2),DOE2         STORE, COMPARE AND BRANCH          29659815
         MVC   SP084(2),DOLOOP                                          29660415
         MVI   SP083,BNH               THE BRANCH CODE IS SET TO BNH    29661015
         TM    DOF1,DOF1NG           OR BNL ACCORDING AS THE BY IS      29661615
         BC    BZ,LG1231             +VE OR -VE.                        29662215
         MVI   SP083,BNL                                                29662815
LG1231   LA    R1,SP08                                                  29663415
         LA    R2,SP08L                                                 29664015
         BAL   RR,LMV3U                                                 29664615
         SPACE 1                                                        29665215
         BC    B,LG1210                NOW GO TO POP UP DO STACK AND    29665815
*                                    RETURN TO SCAN                     29666415
         EJECT                                                          29670013
*                       DO TRIPLE                                       29700013
         SPACE 1                                                        29730013
*              THIS SECTION IS ENTERED WHEN A DO TRIPLE IS FOUND IN     29760013
*        THE TEXT.                                                      29790013
*              ACTION. THE CURRENT DO BLOCK IS PUSHED DOWN AND A NEW    29820013
*        ONE INITIALIZED. A FLAG IS SET IN THE NEW DO BLOCK TO INDICATE 29850013
*        THAT THE BLOCK WAS HEADED BY DO NOT ITDO. THE DO TRIPLE        29880013
*        IS DROPPED FROM THE TEXT.                                      29910013
         SPACE 1                                                        29940013
LG0013   BAL   RR,PSHDWN               PUSH DOWN STACK AND INITIALIZE   29970013
*                                    NEW DO BLOCK                       30000013
         OI    DOF3,DOF3DO             SET DO FLAG                      30030013
         BC    B,LG0003                GO TO DELETE DO AND SCAN ON      30060013
         EJECT                                                          30090013
*                       DO' TRIPLE                                      30120013
         SPACE 1                                                        30150013
*              THIS SECTION IS ENTERED WHEN A DO' TRIPLE IS FOUND       30180013
*        IN THE TEXT.                                                   30210013
*              ACTION. IF THE BLOCK IS NOT ITERATIVE THE DO' IS DROPPED 30240013
*        AND THE DO STACK PUSHED UP.                                    30270013
*                      IF THE BLOCK IS ITERATIVE A GOTO L0 IS GENERATED 30300013
*        FOLLOWED BY ITDO', AND THE STACK THEN PUSHED UP                30330013
         SPACE 1                                                        30360013
LG0014   TM    DOF3,DOF3IT             BRANCH IF LOOP NOT ITERATIVE     30390013
         BC    BZ,LG1202                                                30420013
         SPACE 1                                                        30450013
         MVC   ST092(2),DOL0           LOOP IS ITERATIVE. PUT L0 IN     30480013
         LA    R1,ST09               OPERAND FIELD OF GOTO AND MOVE     30510013
         BAL   RR,LMV3A5             TO OUTPUT TEXT                     30540013
         SPACE 1                                                        30570013
         BC    B,LG1201                GENERATE ITDO' AND POPUP DO      30600013
*                                    STACK                              30630013
         EJECT                                                          30660013
*                       CV TRIPLE                                       30690013
         SPACE 1                                                        30720013
*              THIS SECTION IS ENTERED WHEN A CV TRIPLE IS FOUND IN     30750013
*        THE SOURCE TEXT                                                30780013
*              ACTION. THE SCANNING FLAG IS RESET AND THE               30810013
*        LOOP ENTRY ADDRESS IS COPIED FROM THE CV OPERAND 1, THE TRIPLE 30840013
*        IS DROPPED AND THE EXPRESSION ANALYSIS ROUTINE INVOKED TO      30870013
*        DETERMINE THE TYPE OF EXPRESSION 1.                            30900013
         SPACE 1                                                        30930013
LG0015   NI    DOF2,DOF2NS             RESET CONTROL VARIABLE SCAN FLAG 30960013
         XC    DORR1(DOSCNL),DORR1     CLEAR DO BLOCK AGAIN             30990013
         MVC   DOLOOP(2),1(IPTR)       COPY LOOP DICT REF INTO DO BLOCK 31020013
         SPACE 1                                                        31050013
         MVC   DOCV(2),3(IPTR)         COPY OPERAND 2 OF CV TRIPLE INTO 31080013
         MVC   PAR1+2(2),DOCV        CV SLOT, THEN TEST FOR ARRAY OR    31110013
         BAL   RR,TESTAR             STRUCTURE AND PUT OUT ERROR        31140013
*                                    MESSAGE IF NOT SCALAR.             31170013
         SPACE 1                                                        31200013
         L     HR1,ZSMREG              NOW GET THE NEXT SYMBOLIC        31230013
         LA    HR1,1(0,HR1)          REGISTER NUMBER.                   31260013
         ST    HR1,ZSMREG                                               31290013
         C     HR1,CNSMAX              COMPARE WITH MAXIMUM             31320013
         BC    BL,LG1501                                                31350013
         SPACE 1                                                        31380013
         L     HR1,ERID01              ABORT IF MAXIMUM EXCEEDED        31410013
         BC    B,LGABRT                                                 31440013
         SPACE 1                                                        31470013
LG1501   STH   HR1,DOR0                STORE REGISTER NUMBER IN DO      31500013
*                                    BLOCK                              31530013
         BAL   RR,SC5                  DELETE THE CV TRIPLE             31560013
         TM    DOF2,DOF2CV             NOW TEST TO SEE WHETHER THE      31590013
         BC    BZ,LG1502             CONTROL VARIABLE IS A SUBSCRIPTED  31620013
         CLI   DOTXT,TRARY           LABEL, POINTER0 AREA, EVENT ETC.   31650013
         BC    BNE,LG1502                                               31680013
         MVC   PAR1+2(2),DOTXT+1       IF SUBSCRIPTED, GET ENTRY OF     31710013
         L     LR,ZRFAOF             ARRAY                              31740013
         BALR  RR,LR                                                    31770013
         L     HR1,PAR1                                                 31800013
         SPACE 1                                                        31830013
         TM    0(HR1),DRDATA                                            31860013
         BC    BO,LG1503               BRANCH IF DATA VARIABLE.         31890013
         SPACE 1                                                        31920013
         TM    0(HR1),DRSTRC                                            31950013
         BC    BNO,LG1504              BRANCH IF NOT STRUCTURE          31980013
         SPACE 1                                                        32010013
         BAL   RR,LG0351                A SUBSCRIPTED STRUCTURE MAY NOT 32040013
         BC    B,LG1502              APPEAR AS CONTROL VARIABLE.        32070013
*                                    GENERATE ERROR STOP THEN TREAT AS  32100013
*                                    NORMAL DATA.                       32130013
         SPACE 1                                                        32160013
LG1503   TM    DEDATA(HR1),DATCAD      DATA VARIABLE                    32190013
         BC    BZ,LG1505               BRANCH IF STRING OR AREA         32220013
         SPACE 1                                                        32250013
         TM    DEDATA(HR1),DATPTR      CAD OR POINTER                   32280013
         BC    BZ,LG1502               BRANCH IF NOT POINTER            32310013
         BC    B,LG1504                FOR POINTER GO TO SET SPECIAL    32340013
*                                    SUBSCRIPTED CONTROL VARIABLE BIT   32370013
         SPACE 1                                                        32400013
LG1505   TM    DEDATA(HR1),DATARE      STRING OR AREA                   32430013
         BC    BZ,LG1502               BRANCH IF NOT AREA               32460013
         SPACE 1                                                        32490013
LG1504   OI    DOF2,DOF2ND             AREA,POINTER,LABEL,EVENT         32520013
         BAL   RR,CVCODE             FILEOR TASK. SET SPECIAL           32550013
*                                    SUBSCRIPT BIT AND PUT OUT CV TEXT  32580013
LG1502   BAL   RR,EXPEVL               GO TO ANALYSER. ON RETURN THE    32610013
         BC    B,LG0002              INPUT POINTER ADDRESSES A TRIPLE   32640013
*                                    OF INTEREST. GO TO SEE WHAT IT IS  32670013
         EJECT                                                          32700013
*                       CV' TRIPLE                                      32730013
         SPACE 1                                                        32760013
         SPACE 1                                                        32790013
*              THIS SECTION IS ENTERED WHENEVER A CV' TRIPLE IS FOUND   32820013
*        IN THE INPUT TEXT.                                             32850013
*              ACTION. ALL CODE FOR THE TOP OF THE LOOP HAS ALREADY     32880013
*        BEEN GENERATED. THE BOTTOM OF THE LOOP REQUIRES ONLY THE       32910013
*        INFORMATION UP TO DOCORE. THE REMAINDER OF THE DO BLOCK IS     32940013
*        RELEASED, IN PARTICULAR ANY ADDITIONAL SCRATCH BLOCKS REQUIRED 32970013
*        FOR CONTROL VARIABLE TEXT. THE CV' IS DROPPED FROM THE TEXT    33000013
         SPACE 1                                                        33030013
LG0016   EQU   LG0003                  DELETE CV' AND SCAN ON.          33060013
         EJECT                                                          33090013
*                       TO TRIPLE                                       33120013
         SPACE 1                                                        33150013
*              THIS SECTION IS ENTERED WHENEVER A TO TRIPLE IS FOUND    33180013
*        IN THE INPUT TEXT                                              33210013
*              ACTION. THE 'TO' BIT IS SET IN THE DO BLOCK. THE TO      33240013
*        TRIPLE IS DROPPED FROM THE TEXT AND THE EXPRESSION ANALYSIS    33270013
*        ROUTINE INVOKED TO DETERMINE THE EXPRESSION 2 TYPE.            33300013
         SPACE 1                                                        33330013
LG0017   OI    DOF1,DOF1TO             SET TO FLAG                      33360013
         SPACE 1                                                        33420013
         TM    DOF3,DOF3RP             TEST FOR FORMAT REPLICATION      33450013
         BC    BZ,LG1701             AND BRANCH IF NOT.                 33480013
         SPACE 1                                                        33510013
         LA    R1,ST16                 FOR REPLICATION PREPARE FOR      33540013
         LA    R2,15                 ASSIGNMENT OF EXPRESSION 2 TO      33570013
         BAL   RR,LG0151             REGISTER 14 BY GENERATING A NULL   33600013
*                                    FUNCTION AT THIS POINT.            33630013
         SPACE 1                                                        33660013
LG1701   BAL   RR,SC5                  DELETE TRIPLE                    33680015
         BAL   RR,EXPEVL               CALL EXPRESSION ANALYSER         33700015
         BC    B,LG0002                RETURN TO TEST CURRENT TRIPLE    33720013
         EJECT                                                          33750013
*                       TO' TRIPLE                                      33780013
         SPACE 1                                                        33810013
*              THIS SECTION IS ENTERED WHENEVER A TO' TRIPLE IS FOUND   33840013
*        IN THE INPUT TEXT.                                             33870013
*              ACTION. TESTOP IS CALLED TO TEST THE OPERAND AND ASSIGN  33900013
*        IT TO A TEMPORARY IF NOT CONSTANT. THE DICTIONARY REFERENCE    33930013
*        OF THE RESULT OF EXPRESSION 2 IS THEN SAVED IN THE DO BLOCK    33960013
         SPACE 1                                                        33990013
LG0018   TM    DOF3,DOF3RP             TEST FIRST FOR FORMAT REPLIC'N   34020013
         BC    BZ,LG1801             BRANCH IF NOT                      34050013
         SPACE 1                                                        34080013
         MVC   DOE2(2),3(IPTR)         FORMAT REPLICATION. USE OPERAND  34110013
         BC    B,LG2311              2 OF TO' DIRECTLY AS EXPRESSION 2  34140013
*                                    AND CHECK FOR ERRONEOUS ARRAY OR   34170013
*                                    STRUCTURE SPECIFICATION            34200013
         SPACE 1                                                        34230013
LG1801   BAL   RR,TESTOP               OTHERWISE ASSIGN TO TEMPORARY    34260013
         MVC   DOE2(2),WSDREF        RESULT IN WSDREF                   34290013
         SPACE 1                                                        34320013
         BC    B,LG2301                NOW GO TO DROP THE TO' TRIPLE    34350013
*                                    AND EXAMINE THE SUCCESSOR TRIPLE   34380013
         EJECT                                                          34410013
*                       BY TRIPLE                                       34440013
         SPACE 1                                                        34470013
*              THIS SECTION IS ENTERED WHENEVER A BY TRIPLE IS FOUND    34500013
*        IN THE INPUT TEXT.                                             34530013
*              ACTION. THE 'BY' FLAG IS SET IN THE DO BLOCK AND THE     34560013
*        ITERATIVE FLAG IS SET ON. THE BY TRIPLE IS DROPPED AND A       34590013
*        CALL MADE TO THE EXPRESSION ANALYSER.                          34680015
         SPACE 1                                                        34770013
LG0019   OI    DOF1,DOF1BY             SET BY FLAG AND ITERATIVE FLAG   34800013
         OI    DOF3,DOF3IT                                              34830013
         BC    B,LG1701                GO TO DELETE CURRENT TRIPLE      35430015
*                                    AND CALL EXPRESSION ANALYSER.      36030015
         EJECT                                                          36780013
*                       BY' TRIPLE                                      36810013
         SPACE 1                                                        36840013
*              THIS SECTION IS ENTERED WHENEVER A BY' TRIPLE IS FOUND   36870013
*        IN THE INPUT TEXT.                                             36900013
*              ACTION. TESTOP IS USED TO DETERMINE WHETHER THE EXP 3    36930013
*        IS CONSTANT. THE DICTIONARY REFERENCE RETURNED BY TESTOP IS    36960013
*        PLACED IN THE E3 SLOT OF THE DO BLOCK AND, IF CONSTANT THE     36990013
*        CONSTANT (POSITIVE) INCREMENT FLAG IS SET.  THE BY' TRIPLE     37020013
*        IS DROPPED AND ITS SUCCESSOR EXAMINED.                         37050013
         SPACE 1                                                        37080013
LG0020   BAL   RR,TESTOP               TESTOP LEAVES DICT REF OF THE    37110013
         MVC   DOE3(2),WSDREF        EXPRESSION 3 RESULT IN WSDREF      37140013
         SPACE 1                                                        37170013
LG2001   OI    DOF1,0                  THE IMMEDIATE BYTE OF THIS       37200013
SWCON    EQU   LG2001+1              INSTRUCTION IS SET BY TESTOP IF    37230013
         BC    B,LG2301              THE EXPRESSION IS CONSTANT. GO     37260013
*                                    TO SKIP BY' AND EXAMINE NEXT TRIP  37290013
         EJECT                                                          37320013
*                       WHILE TRIPLE                                    37350013
         SPACE 1                                                        37380013
*              THIS SECTION IS ENTERED WHENEVER A WHILE TRIPLE IS       37410013
*        FOUND IN THE INPUT TEXT.                                       37440013
*              ACTION. THE WHILE FLAG IS SET IN THE DO BLOCK AND IF     37470013
*        THE DO FLAG IS ON, AN ITDO TRIPLE AND COMPILER LABEL TRIPLE.   37500013
*        THE ITERATIVE BIT IS SET AND THE OPERAND 1 FIELD OF THE        37530013
*        TRIPLE COPIED INTO DOLOOP. THE WHILE TRIPLE IS THE DROPPED     37560013
         SPACE 1                                                        37590013
LG0021   OI    DOF1,DOF1WL             SET WHILE BIT                    37620013
         TM    DOF3,DOF3DO             TEST FOR 'DO' AND BRANCH IF      37650013
         BC    BZ,LG2101             NOT (I.E 'ITDO')                   37680013
         SPACE 1                                                        37710013
*              FOR DO GENERATE ITDO AND CL L0.                          37740013
         SPACE 1                                                        37770013
         OI    DOF3,DOF3IT             SET ITERATIVE BIT                37800013
         LA    R1,SP04                 PLACE ITDO PSEUDO-CODE IN        37830013
         LA    R2,3                  OUTPUT TEXT                        37860013
         BAL   RR,LMV3U                                                 37890013
         SPACE 1                                                        37920013
         BAL   RR,NXTEQU               GET NEXT LABEL NUMBER            37950013
         STH   R1,DOL0                 COPY NUMBER INTO CLN2 AND        37980013
         MVC   ST022(2),DOL0         DOL0.                              38010013
         LA    R1,ST02                                                  38040013
         BAL   RR,LMV3A5               PUT OUT COMPILER LABEL           38070013
         SPACE 1                                                        38100013
LG2101   MVC   DOLOOP(2),1(IPTR)       COPY LOOP ENTRY LABEL INTO       38130013
         BC    B,LG0003              DOLOOP AND GO TO DELETE WHILE      38160013
         EJECT                                                          38190013
*                       WHILE' TRIPLE                                   38220013
         SPACE 1                                                        38250013
*              THIS SECTION IS ENTERED WHENEVER A WHILE' TRIPLE IS      38280013
*        FOUND IN THE INPUT TEXT.                                       38310013
*              ACTION. OPERAND 1 (LABEL OF NEXT SPECIFICATION) IS       38340013
*        COPIED INTO DOLABI AND THE WHILE' TRIPLE IS DROPPED FROM THE   38370013
*        TEXT. SECTION 3 CODE IS THEN GENERATED                         38400013
         SPACE 1                                                        38430013
LG0022   MVC   DOLABI(2),1(IPTR)       COPY LABELI FROM OPERAND 1 OF    38460013
*                                    WHILE' TRIPLE                      38490013
         MVC   ST082(2),3(IPTR)        COPY WHILE EXPRESSION INTO IF    38520013
*                                    TRIPLE OPERAND 2                   38550013
         BAL   RR,SC5                  SKIP OVER THE WHILE' TRIPLE AND  38580013
*                                    EXAMINE THENEXT TRIPLE             38610013
         CLI   0(IPTR),TRCVP                                            38640013
         BC    BE,LG2201               BRANCH IF CV'                    38670013
         SPACE 1                                                        38700013
         TM    DOF3,DOF3DO             TEST FOR DO AS OPPOSED TO ITDO   38730013
         BC    BZ,LG2203             AND BRANCH IF ITDO.                38760013
         SPACE 1                                                        38790013
LG2201   OI    DOF1,DOF1ES             SET END OF-SPECIFICATIONS BIT    38820013
*                                    IN DO BLOCK                        38850013
         BAL   RR,CODE3                GENERATE SECTION 3 CODE THEN     38880013
         BC    B,LG0002              RETURN TO MAIN SCAN                38910013
         SPACE 1                                                        38940013
LG2203   BAL   RR,CODE3                CL. AND ITDO. NOT END OF SPECS.  38970013
         BC    B,LG2305              GENERATE SECTION 3 CODE,THEN GO TO 39000013
*                                    START EXPRESSION ANALYSIS FOR      39030013
*                                    NEXT EXPRESSION 1.                 39060013
         EJECT                                                          39090013
*                       ASSIGN1 AND ASSIGN2 TRIPLES                     39120013
         SPACE 1                                                        39150013
*              THIS SECTION IS ENTERED WHENEVER A CONTROL VARIABLE      39180013
*        ASSIGNMENT TRIPLE IS ENCOUNTERED                               39210013
*              ACTION.  FOR ASSIGN2 THE ITERATIVE FLAG IS SET IN THE    39240013
*        DO BLOCK. IN BOTH CASES OPERAND 1 OF THE TRIPLE (NEXT SPEC     39270013
*        LABEL) IS PLACED IN THE LABELI SLOT OF THE DO BLOCK AND THE    39300013
*        SECOND OPERAND IS TESTED TO DESCRIMINATE BETWEEN A DECLARED    39330013
*        VARIABLE OR TEMPORARY RESULT, AND A CONSTANT. IN THE FORMER    39360013
*        CASE A DICTIONARY ENTRY IS MADE FOR A TEMPORARY, AND THE       39390013
*        EXPRESSION 1 RESULT ASSIGNED TO IT. THE DICT REF OF THE TEMP   39420013
*        OR CONSTANT IS PLACED IN THE E1 SLOT OF THE DO BLOCK. THE      39450013
*        CURRENT TRIPLE IS DROPPED AND THE NEXT TRIPLE EXAMINED FOR     39480013
*        WHILE,CV' OR CL. IN ANY OF THESE CASES SECTION 2 CODE IS       39510013
*        GENERATED AT ONCE.                                             39540013
         SPACE 1                                                        39570013
*              ASSIGN 2 ENTRY                                           39600013
LG0024   OI    DOF3,DOF3IT             MARK DO AS ITERATIVE             39630013
         SPACE 1                                                        39660013
*              ASSIGN 1 ENTRY                                           39690013
LG0023   MVC   DOLABI(2),1(IPTR)       OPERAND 1 IS LABEL OF NEXT SPEC  39720013
*                                    PLACE IT IN DO BLOCK               39750013
         SPACE 1                                                        39780013
*              NOW TEST TO SEE WHETHER THE NEXT TRIPLE IS TO OR BY.     39810013
*        IF NOT THERE IS NO NEED TO ASSIGN EXPRESSION 1 TO A TEMPORARY  39840013
         BAL   RR,CTXTRF               GET SYMBOLIC ADDRESS OF INPUT,   39870013
         L     HR1,PAR1              THEN LOOK AHEAD ONE TRIPLE TO      39900013
         BAL   RR,SC4                GET THE CODE OF THE NEXT TRIPLE    39930013
         MVC   WSRR01(1),0(IPTR)                                        39960013
         ST    HR1,PAR1                RESTORE IPTR TO DO ASSIGN        39990013
         BAL   RR,SC10               TRIPLE.                            40020013
         SPACE 1                                                        40050013
         CLI   WSRR01,TRTO             TEST FOR TO OR BY AND IF         40080013
         BC    BE,LG2310             EITHER GO TO ASSIGN EXPRESSION 1   40110013
         CLI   WSRR01,TRBY           TO A TEMPORARY IF NECESSARY.       40140013
         BC    BE,LG2310                                                40170013
         SPACE 1                                                        40200013
*              NEXT TRIPLE IS NOT TO OR BY SO USE OPERAND 2 OF DO       40230013
*        EQUALS AS SOURCE FOR ASSIGNMENT DIRECTLY TO CONTROL VARIABLE   40260013
*        UNLESS THERE IS CONTROL VARIABLE TEXT TO BE COPIED. IN THIS    40290013
*        CASE, IF THE DO EQUALS OPERAND IS AN EXPRESSION THE            40320013
*        ASSIGNMENT WOULD BE PRECEDED BY LHS AND RHS DEFINITIONS IN     40350013
*        THE REVERSE ORDER.                                             40380013
         SPACE 1                                                        40410013
         TM    DOF2,DOF2CV             IF NO CONTROL VARIABLE TEXT      40440013
         BC    BZ,LG2312             ASSIGNMENT WILL BE RIGHT           40470013
         SPACE 1                                                        40500013
         TM    DOF2,DOF2ND             IF SUBSCRIPTED POINTER ETC. THEN 40530013
         BC    BNZ,LG2312            CV TEXT HAS ALREADY BEEN PUT OUT   40560013
*                                    AND ASSIGNMENT WILL BE ALL RIGHT   40590013
         SPACE 1                                                        40620013
          CLC   3(2,IPTR),CNZERO       IF CONTROL VARIABLE TEXT, STILL  40650013
         BC    BE,LG2310             ALL RIGHT IF NOT EXPRESSION        40680013
*              IT IS POSSIBLE TO ASSIGN DIRECTLY                        40710013
LG2312   MVC   DOE1(2),3(IPTR)                                          40740013
         SPACE 1                                                        40770013
*              SPECIFICATION WITHOUT TO OR BY, OR REPLICATION LOOP.     40800013
LG2311   NI    DOF1,DOF1NV             RESET ANALYSIS FLAG AND THEN     40830013
         MVC   PAR1+2(2),3(IPTR)     TEST THE OPERAND FOR ARRAY OR      40860013
         BAL   RR,TESTAR             STRUCTURE (ERROR IF NOT SCALAR)    40890013
         SPACE 1                                                        40920013
*              THE FOLLOWING SECTION IS COMMON TO THIS TRIPLE AND ALSO  40950013
*        TO' AND BY'. IT DETERMINES WHETHER THE CURRENT TRIPLE IS THE   40980013
*        LAST OF THIS SPECIFICATION, AND, IF SO, GENERATES SECTION 2    41010013
*        CODE.                                                          41040013
         SPACE 1                                                        41070013
LG2301   BAL   RR,SC5                  SKIP THE CURRENT TRIPLE AND      41100013
         CLI   0(IPTR),TRWHIL        LOOK AT THE NEXT ONE.              41130013
         BC    BE,LG2302               BRANCH IF WHILE                  41160013
         SPACE 1                                                        41190013
         CLI   0(IPTR),TRCVP                                            41220013
         BC    BE,LG2303               BRANCH IF CV'                    41250013
         SPACE 1                                                        41280013
         CLI   0(IPTR),TRCLN1                                           41310013
         BC    BE,LG2304               BRANCH IF CLN1                   41340013
         SPACE 1                                                        41370013
         CLI   0(IPTR),TRCLN2                                           41400013
         BC    BE,LG2304               BRANCH IF CLN2                   41430013
         SPACE 1                                                        41460013
*              IF THE SUCCESSOR TRIPLE IS NONE OF THE ABOVE IT MUST     41490013
*        PERTAIN TO THE ITERATION PART OF THE CURRENT SPECIFICATION     41520013
         SPACE 1                                                        41550013
         BC    B,LG0002                GO TO SCAN FROM CURRENT TRIPLE   41580013
         SPACE 2                                                        41610013
*              SUCCESSOR TRIPLE IS WHILE                                41640013
         SPACE 1                                                        41670013
LG2302   OI    DOF1,DOF1WL             SET THE WHILE AND ITERATIVE      41700013
         OI    DOF3,DOF3IT           FLAGS AND THEN GENERATE SECTION 2  41730013
         BAL   RR,CODE2              CODE. ENTER WHILE SECTION.         41760013
         BC    B,LG0021                                                 41790013
         SPACE 2                                                        41820013
*              SUCCESSOR TRIPLE IS CV'                                  41850013
         SPACE 1                                                        41880013
LG2303   OI    DOF1,DOF1ES             SET END OF SPECIFICATIONS BIT    41910013
         BAL   RR,CODE2              IN DO BLOCK, GENERATE SECTION 2    41940013
         BC    B,LG0016              CODE THEN ENTER CV' SECTION        41970013
         SPACE 2                                                        42000013
*              SUCCESSOR TRIPLE IS CL                                   42030013
         SPACE 1                                                        42060013
LG2304   BAL   RR,CODE2                GENERATE SECTION 2 CODE, CLEAR   42090013
LG2305   MVI   DOF1,0                FLAG BYTE 1 FOR THE NEXT           42120013
*                                    SPECIFICATION.                     42150013
         TM    DOF2,DOF2ND             TEST FOR SPECIAL SUBSCRIPTED     42180013
         BC    BZ,LG2306             CV CASE AND IN THAT CASE PUT OUT   42210013
*                                    CONTROL VARIABLE TEXT AFTER THE    42240013
         BAL   RR,SC7                LABEL                              42270013
         BAL   RR,CVCODE                                                42300013
         SPACE 1                                                        42330013
LG2306   BAL   RR,EXPEVL               ANALYSE THE NEXT                 42360013
         BC    B,LG0002              EXPRESSION 1                       42390013
         SPACE 2                                                        42420013
*              SUCCESSOR IS TO OR BY OR NEITHER THE CONTROL VARIABLE    42450013
*        NOR THE DO EQUALS IS A DICT. REF.                              42480013
         SPACE 1                                                        42510013
LG2310   BAL   RR,TESTOP               EXAMINE OPERAND 2 OF DO EQUALS   42540013
         MVC   DOE1(2),WSDREF        AND ASSIGN TO TEMPORARY IF         42570013
         BC    B,LG2301              NECESSARY. GO TO DELETE CURRENT    42600013
*                                    TRIPLE AND TEST SUCCESSOR.         42630013
         EJECT                                                          42660013
*              CONTROL VARIABLE SCANNING SECTION                        42690013
*                                                                       42720013
*              FUNCTIONS - THIS SECTION IS ENTERED FROM THE ITDO        42750013
*        SECTION FOR CASES IN WHICH THE CONTROL VARIABLE IS OTHER       42780013
*        THAN A SIMPLE SCALAR. THE INPUT TEXT IS ANALYSED AND DIVIDED   42810013
*        BETWEEN THE OUTPUT TEXT AND THE DO BLOCK IN SUCH A WAY THAT    42840013
*        ANY SUBSCRIPTS ARE EVALUATED AND ASSIGNED TO INTEGER           42870013
*        TEMPORARIES BEFORE THE LOOP IS ENTERED, AND ALL USES OF THE    42900013
*        CONTROL VARIABLE IN THE LOOP EMPLOY THESE TEMPORARIES AS       42930013
*        SUBSCRIPTS.                                                    42960013
*                                                                       42990013
*              ENTRY POINTS - (1) LG0025 FOR SUBSCRIPT MARKER           43020013
*                             (2) LG0026 FOR PSEUDO-VARIABLE MARKER     43050013
*                                                                       43080013
*              INPUT - IPTR ADDRESSES THE FIRST TRIPLE OF THE CONTROL   43110013
*        VARIABLE TEXT.                                                 43140013
*                                                                       43170013
*              OUTPUT - CONTROL VARIABLE TEXT HAS BEEN SCANNED AND      43200013
*        DIVIDED BETWEEN OUTPUT AND DO BLOCK. ASSIGNMENTS OF INDEX      43230013
*        EXPRESSIONS TO INTER TEMPORARIES HAVE BEEN MADE.               43260013
         EJECT                                                          43290013
*              SUBSCRIPTAND STATIC DEFINED SUBSCRIPT                    43320013
*              ALL ARGUMENTS OF , TRIPLES AT LEVEL 1 BETWEEN THE        43350013
*        CURRENT INPUT TRIPLE AND ITS CORRESPONDING PRIMED DELIMITER    43380013
*        ARE ASSIGNED TO FIXED BINARY INTEGERS. ON RETURN IPTR          43410013
*        ADDRESSES TRIPLE FOLLOWING PRIMED MARKER                       43440013
         SPACE 1                                                        43470013
LG0025   BAL   RR,SUBSCN               USE SUBROUTINE TO DO THE ABOVE   43500013
         BC    B,LG1101              THEN RETURN TO ITDO SECTION TO     43530013
*                                    MOVE ANYTHING BETWEEN THE PRIMED   43560013
*                                    DELIMITER AND CV. (IN CASE IT      43590013
*                                    CONTAINS A DO LOOP)                43620013
         EJECT                                                          43650013
*              PSEUDO-VARIABLE                                          43680013
*              THE PSEUDO-VARIABLE IS IDENTIFIED. AN ARGUMENT COUNT     43710013
*        IS MAINTAINED ENABLING THE INDEX ARGUMENTS OF SUBSTR TO BE     43740013
*        IDENTIFIED AND CONVERTED TO INTEGER TEMPORARY. OTHER ARGUMENTS 43770013
*        ARE ANALYSED FOR SUBSCRIPTS AND THE SUBSCRIPTS ASSIGNED TO     43800013
*        TEMPORARIES. ON RETURN IPTR ADDRESSES TRIPLE FOLLOWING THE     43830013
*        TMPDS AFTER THE PRIMED MARKER.                                 43860013
         SPACE 1                                                        43890013
LG0026   OI    DOF2,DOF2PS             SET PSEUDO-VARIABLE FLAG BIT     43920013
*                                    IN DO BLOCK                        43950013
LG0027   MVC   PAR1+2(2),1(IPTR)       GET DICTIONARY ENTRY OF OPERAND  43980013
         L     LR,ZRFAOF             ONE OF PSI OR FUNCTION TRIPLE      44010013
         BALR  RR,LR                                                    44040013
         L     HR1,PAR1                                                 44070013
         MVC   DOPCOD(1),DEFCOD(HR1)   COPY PSEUDO-VARIABLE CODE BYTE   44100013
         SPACE 1                                                        44130013
*              NOW START SCANNING FOR ARGUMENTS                         44160013
         BAL   RR,CVCOPY               MOVE PSI TRIPLE TO DO BLOCK      44190013
LG2603   LA    R1,LISTPV               SCAN FOR BUY/ASSIGN, IGNORE      44220013
         BAL   RR,CVSCAN             AND PSI'.                          44250013
         SR    HR1,HR1                 ON RETURN IPTR ADDRESSES ONE OF  44280013
         IC    HR1,DORR1             THE ABOVE, OR AN UNPRIMED DELIMIT  44310013
         BC    B,LG2604(HR1)         AT LEVEL 1                         44340013
         SPACE 1                                                        44370013
LG2604   BC    B,LG2606                BUY/ASSIGN                       44400013
         BC    B,LG2606                IGNORE                           44430013
         BC    B,LG2601                PSI'                             44460013
         CLI   0(IPTR),TRFUNP          FUNCTION'. CHECK TO SEE THAT     44490013
         BC    B,LG2602              IPTR IS ADDRESSING FUNCTION'       44520013
         SPACE 1                                                        44550013
LG2601   CLI   0(IPTR),TRPSIP          PSI'. CHECK TO SEE THAT IPTR     44580013
LG2602   BC    BE,LG2605             IS ADDRESSING PSI'                 44610013
         BAL   RR,MOVOUT               IF NOT MOVE TEXT TO PRIMED TRIPL 44640013
LG2605   BAL   RR,CVCOPY               PLACE PRIMED TRIPLE IN DO BLOCK  44670013
         BAL   RR,CVCOPY             TEXT FOLLOWED BY THE TWO TMPDS,    44700013
         BAL   RR,CVCOPY             THEN GO BACK TO ITDO SECTION TO    44730013
         BC    B,LG1101              MOVE OUT ANYTHING ELSE BETWEEN     44760013
*                                    THE TMPDS AND CV.                  44790013
         SPACE 1                                                        44820013
*              BUY/ASSIGN OR IGNORE                                     44850013
LG2606   CLI   0(IPTR),TRALAS          FIND OUT WHETHER WE ARE IN FACT  44880013
         BC    BE,LG2607             LOOKING AT BUY/ASSIGN OR IGNORE    44910013
         CLI   0(IPTR),TRIGNR                                           44940013
         BC    BE,LG2607                                                44970013
         SPACE 1                                                        45000013
         BAL   RR,PSTYP0               WE ARE LOOKING AT A PRECEDING    45030013
         BC    B,LG2620              DELIMITER. FIND OUT WHETHER THIS   45060013
*                                    ARGUMENT IS AN INDEX. BRANCH IF    45090013
*                                    A VARIABLE                         45120013
         BAL   RR,MOVOUT               INTEGER. MOVE TEXT UP TO BUY/    45150013
*                                    ASSIGN OR IGNORE                   45180013
LG2607   BAL   RR,PSTYP1               DETERMINE ARGUMENT TYPE AND      45210013
*                                    ADD ONE TO ARGUMENT COUNT.         45240013
         BC    B,LG2610                VARIABLE.                        45270013
*                                      INTEGER. THE CURRENT ARGUMENT,   45300013
LG2612   CLI   0(IPTR),TRIGNR        IF NOT CONSTANT, MUST BE ASSIGNED  45330013
         BC    BE,LG2608             TO AN INTEGER TEMPORARY            45360013
         SPACE 1                                                        45390013
         BAL   RR,ASSIGN               BUY/ASSIGN. ARGUMENT MUST BE     45420013
         MVI   0(IPTR),TRIGNR        CONVERTED. PUT IGNORE TRIPLE IN    45450013
         BAL   RR,CVCOPY             DO TEXT, FOLLOWED BY DOUBLE COMMA  45480013
LG2609   MVC   3(2,IPTR),WSDREF      WITH INTEGER AS OPERAND            45510013
LG2611   BAL   RR,CVCOPY                                                45540013
         BC    B,LG2603                GO TO LOOK FOR NEXT PSEUDO       45570013
*                                    VARIABLE ARGUMENT                  45600013
LG2608   BAL   RR,CVCOPY               IGNORE TRIPLE IN TEXT. COPY INTO 45630013
         BAL   RR,ASSIGN             DO TEXT, ASSIGN DOUBLE COMMA       45660013
         BC    B,LG2609              OPERAND TO INTEGER AND GO TO PLACE 45690013
*                                    THAT IN DO TEXT ALSO               45720013
         SPACE 1                                                        45750013
LG2610   BAL   RR,CVCOPY               ARGUMENT IS A VARIABLE. SIMPLY   45780013
         MVC   PAR1+2(2),3(IPTR)     COPY THE FIRST TRIPLE, TEST THE    45810013
         BAL   RR,TESTAR             SECOND FOR SCALAR ARGUMENT, THEN   45840013
         BC    B,LG2611              GO TO COPY IT.                     45870013
         SPACE 2                                                        45900013
*              ARGUMENT IS A VARIABLE PRECEDED BY DELIMITED GROUP OF    45930013
*        TRIPLES. IF SUBSCRIPTS PRESENT, ASSIGN TO INTEGER TEMPORARIES  45960013
         SPACE 1                                                        45990013
LG2620   CLI   0(IPTR),TRARY           TEST FOR SUBSCRIPT OR STATIC     46020013
         BC    BE,LG2621             DEFINED SUBSCRIPT.                 46050013
         SPACE 1                                                        46080013
         MVC   PAR6(4),ERID07          IF NEITHER THIS IS AN ERROR      46110013
         L     LR,ZUEROF             BECAUSE A PSEUDO-VARIABLE CAN      46140013
         BALR  RR,LR                 HAVE ONLY SCALAR OR SUBSCRIPTED    46170013
         BAL   RR,MOVOUT             ARGUMENTS. MOVE TEXT TO BUY/       46200013
         BAL   RR,PSTYP1             ASSIGN OR IGNORE, COUNT AS ONE     46230013
         BC    B,LG2612              ARGUMENT, THEN TREAT AS INDEX      46260013
         BC    B,LG2612              ARGUMENT.                          46290013
         SPACE 1                                                        46320013
*                                      FOR SUBSCRIPTED ARGUMENT USE     46350013
LG2621   BAL   RR,SUBSCN             SUBSCN TO ASSIGN SUBCRIPTS TO      46380013
         BC    B,LG2603              INTEGERS. RETURN POINTING AT       46410013
*                                    TRIPLE FOLLOWING PRIMED MARKER, GO 46440013
*                                    TO COPY ANYTHING ELSE UP TO BUY/   46470013
*                                    ASSIGN OR IGNORE                   46500013
         EJECT                                                          46530013
*                       RPL TRIPLE                                      46560013
         SPACE 1                                                        46590013
*              THIS SECTION IS ENTERED WHENEVER AN RPL TRIPLE IS        46620013
*        ENCOUNTERED IN A FORMAT LIST. SUCH RPL TRIPLES ARE HARBINGERS  46650013
*        OF ITERATIVE DO LOOPS CONSTRUCTED FROM FORMAT ITEM REPLICATION 46680013
*        FACTORS. AN INSTRUCTION IN THE ITDO SECTION IS INITIALIZED     46710013
*        TO CAUSE THE SETTING OF THE RPL BIT IN THE DO BLOCK.           46740013
         SPACE 1                                                        46770013
LG0028   MVI   SWRPL,DOF3RP            SET INSTRUCTION AND THEN GO TO   46800013
         BC    B,LG4001              COPY RPL AND CONTINUE.             46830013
         SPACE 3                                                        46860013
*                       FORMAT AND FORMAT LIST TRIPLES                  46890013
         SPACE 1                                                        46920013
*              THE SCAN TRT TABLE IS SET TO EXIT ON RPL TRIPLES         46950013
*        DURING THE SCAN OF THE FORMAT LIST.                            46980013
         SPACE 1                                                        47010013
LG0030   MVI   SCTRT+TRRPL,Z           SET SCAN CODE FOR RPL AND COPY   47040013
         BC    B,LG4001              TRIPLE TO OUTPUT                   47070013
         SPACE 3                                                        47100013
*                       FORMAT' AND FORMAT LIST' TRIPLES                47130013
         SPACE 1                                                        47160013
*              THE RPL ENTRY IN THE SCAN TRT TABLE IS RESET TO AVOID    47190013
*        ATTEMPTING TO PRODUCE SPECIAL CODE FOR ITERATIONS IN DATA      47220013
*        LISTS.                                                         47250013
         SPACE 1                                                        47280013
LG0031   MVI   SCTRT+TRRPL,0           RESET ENTRY AND COPY TRIPLE      47310013
         BC    B,LG4001                                                 47340013
         EJECT                                                          47370013
*                       BLOCK TRIPLES - PROC,PROC',BEGIN AND BEGIN'     47400013
         SPACE 1                                                        47430013
*              THIS SECTION IS ENTERED WHENEVER A BLOCK DEMARCATION     47460013
*        TRIPLE IS FOUND IN THE SOURCE TEXT.                            47490013
*              ACTION. THE LEVEL AND COUNT NUMBERS OF THE BLOCK JUST    47520013
*        ENTERED ARE PLACED IN THE COMPILER LABEL SKELETON              47550013
*        DICTIONARY ENTRY.                                              47580013
         SPACE 1                                                        47610013
LG0040   EQU   *                                                        47640013
LG0041   EQU   *                                                        47670013
LG0042   EQU   *                                                        47700013
LG0043   EQU   *                                                        47730013
         LH    HR1,SCBLK               GET CURRENT BLOCK REFERENCE AND  47760013
         LTR   HR1,HR1               TEST FOR ZERO. RETURN TO SCAN IF   47790013
         BC    BZ,LG4001             IT IS ZERO                         47820013
         SPACE 1                                                        47850013
         STH   HR1,PAR1+2              OTHERWISE GET DICTIONARY ENTRY   47880013
         L     LR,ZRFAOF             OF CURRENT BLOCK AND COPY THE      47910013
         BALR  RR,LR                 LEVEL AND COUNT INTO COMPILER      47940013
         L     HR1,PAR1              LABEL ENTRY SKELETON               47970013
         MVC   SD02C1(2),ET1LC(HR1)    SET LEVEL/COUNT FOR BOTH CTL AND 48000013
         MVC   SD02C2(2),ET1LC(HR1)  NON-CTL VARIABLE TEMPORARIES       48030013
         SPACE 1                                                        48060013
LG4001   BAL   RR,SC2                  PASS TRIPLE INTO OUTPUT TEXT     48090013
         EX    0,LG0004(TRTR)        SCAN FOR NEXT TRIPLE.              48120013
         EJECT                                                          48150013
*                       SUBROUTINES LMV35 AND LMV3U                     48180013
         SPACE 1                                                        48210013
*              THESE SUBROUTINES SET UP PARAMETERS FOR CALLS TO THE     48240013
*        SCAN MOVE ROUTINE MV3.                                         48270013
*        INPUT.  R1 ADDRESSES PSEUDO-CODE TEXT                          48300013
*                R2 CONTAINS THE TEXT LENGTH (LMV3U) OR 5 IS IMPLIED    48330013
*              FOR THE LENGTH (LMV35)                                   48360013
         SPACE 1                                                        48390013
LMV35    LA    R2,5                    SET TEXT LENGTH TO 5             48420013
         SPACE 1                                                        48450013
LMV3U    LA    LR,MV3                  GET ENTRY ADDRESS OF MV3         48480013
         BC    B,LG0150                                                 48510013
         SPACE 2                                                        48540013
*                       SUBROUTINES LMV3A5 AND LMV3AU                   48570013
         SPACE 1                                                        48600013
*              THESE SUBROUTINES SET UP PARAMETERS FOR CALLS TO THE     48630013
*        SCAN MOVE ROUTINE MV3A.                                        48660013
*        INPUT.  R1 ADDRESSES TRIPLE TEXT                               48690013
*              LENGTH MOVED IS 5 BYTES (LMV3A5) OR 10 (LMV3AU)          48720013
         SPACE 1                                                        48750013
LMV3A5   LA    R2,5                    SET TEXT LENGTH TO 5             48780013
         BC    B,LG0151                                                 48810013
         SPACE 1                                                        48840013
LMV3AU   LA    R2,10                   SET TEXT LENGTH TO 10            48870013
LG0151   LA    LR,MV3A                 GET ENTRY ADDRESS OF MV3A        48900013
         SPACE 1                                                        48930013
LG0150   ST    R2,PAR2                 SET TEXT LENGTH IN PAR2          48960013
         ST    R1,PAR1                 SET START OF TEXT ADDRESS IN     48990013
*                                    PARAMETER 1                        49020013
         BCR   B,LR                    RETURN INDIRECTLY VIA MV3 OR     49050013
*                                    MV3A AS REQUIRED                   49080013
         SPACE 2                                                        49110013
*                       SUBROUTINES LMV3US AND LMV3SN                   49140013
         SPACE 1                                                        49170013
*              THESE SUBROUTINES ARE USED BY SECTIONS WHICH GENERATE    49200013
*        REPLICATION CODE TO PUT OUT USSLD 1,2 AND 7 OR SINLIST 1,2,7   49230013
*        FOR FORMAT REPLICATIONS BUT NOT INITIAL VALUE REPLICATIONS.    49260013
         SPACE 1                                                        49290013
LMV3US   MVI   SP06,PSUSLD             SET USSLD CODE                   49320013
         BC    B,LG0152                                                 49350013
         SPACE 1                                                        49380013
LMV3SN   MVI   SP06,PSSNLS             SET SINLIST CODE                 49410013
         SPACE 1                                                        49440013
LG0152   TM    DOF3,DOF3IV             TEST FOR IINTIAL VALUE REP AND   49470013
         BCR   BNZ,RR                IF SO RETURN WITHOUT GENERATING    49500013
*                                    A LIST.                            49530013
         LA    R1,SP06                 OTHERWISE, I.E. FOR FORMAT LIST  49560013
         LA    R2,SP06L              REPLICATION, PRODUCE PHYSICAL      49590013
         BC    B,LMV3U               REGISTER LIST                      49620013
         EJECT                                                          49650013
*                            SUBROUTINE CODE2                           49680013
         SPACE 1                                                        49710013
*              THIS SUBROUTINE GENERATES TEXT FOR THAT PART OF THE DO   49740013
*        LOOP EXPANSION CONCERNED WITH ASSIGNMENT TO, BUMPING OF, AND   49770013
*        TESTING OF THE CONTROL VARIABLE                                49800013
*        INPUT. DOBASE POINTS TO THE CURRENT DO BLOCK WHICH CONTAINS    49830013
*        ALL NECESSARY INFORMATION.                                     49860013
         SPACE 1                                                        49890013
CODE2    ST    RR,WSRR01               SAVE RETURN REGISTER             49920013
         TM    DOF3,DOF3RP             TEST FOR SPECIAL CASE OF FORMAT  49950013
         BC    BNZ,LG0250            LIST REPLICATION.                  49980013
         SPACE 1                                                        50010013
         BAL   RR,EXPTST             EXPTST WHICH DETERMINES WHETHER    50016015
         BC    B,LG0260              THIS DO LOOP IS OPTIMIZEABLE.      50022015
*                                    BRANCH IF IT IS, FALL THROUGH IF   50028015
*                                    NOT                                50034015
         XC    LI1(8),LI1              CLEAR LABEL REFERENCE TABLE      50040013
         MVC   ST071(2),DOE2           INITIALIZE THE COMPARISON - IF   50070013
         MVC   ST072(2),DOCV         TRIPLE PAIR TO COMPARE EXPRESSION  50100013
         MVC   ST082(2),CNZERO       2 WITH THE CONTROL VARIABLE.       50130013
         SPACE 1                                                        50160013
*              NOW TEST WHETHER A LOOP CLOSE WILL BE NECESSARY,AND IF   50190013
*        SO SET UP A RETURN REGISTER                                    50220013
         TM    DOF1,DOF1BY             TEST FOR BY CLAUSE, AND IF       50250013
         BC    BNZ,LG0203            PRESENT GO TO GENERATE AN LA       50280013
         SPACE 1                                                        50310013
         MVC   LI1(2),DOLABI           IF NO BY, THE LOOP IS EXECUTED   50340013
         TM    DOF3,DOF3IT           ONLY ONCE FOR THIS SPECIFICATION   50370013
         BC    BNZ,LG0201            BUT MUST BE CLOSED IF THERE IS     50400013
*                                    MORE THAN ONE SPECIFICATION OR     50430013
         TM    DOF1,DOF1ES           IF THIS IS NOT THE LAST            50460013
         BC    BNZ,LG0202                                               50490013
         BC    B,LG0201              BRANCH IF NOT LAST                 50520013
         SPACE 1                                                        50550013
*              THE FOLLOWING SECTION GENERATES A GO TO INTO THE LOOP    50580013
*        FOR BY WITHOUT TO OR WHILE AND MULTIPLE SPECS, AND FOR         50610013
*        INITIAL VALUE ONLY AND MULTIPLE SPECS.                         50640013
         SPACE 1                                                        50670013
LG0204   TM    DOF1,DOF1EW             TEST FOR WHILE OR END-OF-SPECS   50700013
         BC    BNZ,LG0200            AND RETURN IF EITHER               50730013
         SPACE 1                                                        50760013
         MVC   ST002(2),DOLOOP         IF NEITHER GENERATE A GO TO INTO 50790013
         LA    R1,ST00               THE LOOP, THEN RETURN              50820013
         BC    B,LG0205                                                 50850013
         SPACE 1                                                        50880013
LG0203   BAL   RR,NXTEQU               WHEN THERE IS A BY GET A LABEL   50910013
         STH   R1,LI1                NUMBER FOR LI1                     50940013
         SPACE 1                                                        50970013
LG0201   MVC   SP021(2),DOR0           NOW GENERATE A LOAD ADDRESS OF   51000013
         MVC   SP022(2),LI1          LI1 INTO R0 FOR THE LOOP CLOSE     51030013
         LA    R1,SP02               BRANCH                             51060013
         BAL   RR,LMV35                                                 51090013
         SPACE 1                                                        51120013
*              NOW GENERATE TEXT FOR THE ASSIGNMENT TO THE CONTROL      51150013
*        VARIABLE OF ITS INITIAL VALUE (EXPRESSION 1)                   51180013
         SPACE 1                                                        51210013
LG0202   TM    DOF2,DOF2ND             TEST FOR THE SPECIAL CASE OF     51240013
         BC    BNZ,*+8               SUBSCRIPTED POINTER ETC. AND ALSO  51270013
         BAL   RR,CVCODE             FOR THE EXISTENCE OF CV TEXT       51300013
*                                    AND GENERATE IF NECESSARY.         51330013
         MVC   ST011(2),DOCV           NOW PRODUCE AN ASSIGNMENT        51360013
         MVC   ST012(2),DOE1         CV=EXPRESSION1                     51390013
         LA    R1,ST01                                                  51420013
         BAL   RR,LMV3A5                                                51450013
         SPACE 1                                                        51480013
*              NOW TEST TO DETERMINE WHAT INCREMENTING AND TESTING      51510013
*        CODE IS REQUIRED                                               51540013
         TM    DOF1,DOF1BY             IF THERE IS A BY MORE TEXT IS TO 51570013
         BC    BZ,LG0204             BE GENERATED. BRANCH IF NOT BY.    51600013
         SPACE 1                                                        51630013
         MVC   LI2(2),DOLOOP           SET LI2=LOOP ENTRY POINT, THEN   51660013
         TM    DOF1,DOF1TW           TEST FOR A TO OR A WHILE, IN WHICH 51690013
         BC    BZ,LG0211             CASE A NEW LABEL IS NEEDED         51720013
         SPACE 1                                                        51750013
         BAL   RR,NXTEQU               FOR TO OR WHILE GET A NEW LABEL  51780013
         STH   R1,LI2                NUMBER FOR LI2                     51810013
         SPACE 1                                                        51840013
*              NOW GENERATE GO TO LI2  TO BRANCH ROUND THE INCREMENT    51870013
*        CODE AND DEFINE LI1 (RETURN ADDRESS FROM LOOP CLOSE FOR THIS   51900013
*        ITERATION)                                                     51930013
LG0211   MVC   ST002(2),LI2            GOLN  LI2                        51960013
         MVC   ST022(2),LI1            CLN2  LI1                        51990013
         LA    R1,ST00                                                  52020013
         BAL   RR,LMV3AU               GENERATE OUTPUT TRIPLES          52050013
         SPACE 1                                                        52080013
*              THE FOLLOWING SECTION GENERATES TRIPLES TO INCREMENT     52110013
*        THE CONTROL VARIABLE BY THE VALUE OF EXPRESSION 3              52140013
         SPACE 1                                                        52170013
         BAL   RR,CVCODE               TEST FOR CONTROL VARIABLE TEXT   52200013
*                                    AND GENERATE IT IF NECESSARY       52230013
         LA    R1,TRFUN                                                 52260013
         BAL   RR,SWTCHP               SWITCH PSI TO FUNCTION IF        52290013
*                                    NECESSARY                          52320013
         SPACE 1                                                        52350013
         BAL   RR,CVCODE               GENERATE RIGHT-HAND-SIDE CONTROL 52380013
*                                    VARIABLE TEXT                      52410013
         SPACE 1                                                        52560013
LG0214   MVC   ST031(2),DOCV           SET UP INCREMENTING TRIPLE AND   52590013
         MVC   ST032(2),DOE3         ASSIGNMENT TRIPLE                  52620013
         MVC   ST041(2),DOCV                                            52650013
         LA    R1,ST03                 MOVE TRIPLE PAIR TO OUTPUT TEXT  52680013
         BAL   RR,LMV3AU                                                52710013
         SPACE 1                                                        52740013
*              NOW TEST TO SEE IF ANY TESTING CODE IS NEEDED, AND IF    52770013
*        NOT RETURN                                                     52800013
         SPACE 1                                                        52830013
         TM    DOF1,DOF1TW             TEST FOR TO OR WHILE             52860013
         BC    BZ,LG0204             BRANCH IF NEITHER TO TEST FOR      52890013
*                                    END-OF-SPECS                       52920013
         SPACE 1                                                        52950013
*              ENTER HERE IF THERE IS A TO OR A WHILE CLAUSE            52980013
         MVC   ST132(2),LI2            SET LI2 AS OPERAND 2 IN CLN1     53010013
         LA    R1,ST13               TRIPLE, THEN MOVE TO OUTPUT TEXT   53040013
         BAL   RR,LMV3A5                                                53070013
         SPACE 1                                                        53100013
*              TEST FOR 'TO'.                                           53130013
         TM    DOF1,DOF1TO             RETURN IF THERE IS NO 'TO',      53160013
         BC    BZ,LG0200             OTHERWISE GENERATE COMPARISON CODE 53190013
         SPACE 1                                                        53220013
*              ENTER HERE AFTER GENERATING INCREMENTING CODE TO CREATE  53250013
*        TESTING CODE TO COMPARE THE CONTROL VARIABLE WITH EXPRESSION 2 53280013
         SPACE 1                                                        53310013
         MVC   LI4(2),DOLOOP           SET LI4 EQUAL TO LOOP ENTRY LBL  53340013
         SPACE 1                                                        53370013
         TM    DOF1,DOF1CN             TEST FOR CONSTANT BY EXPRESSION  53400013
         BC    BNZ,LG0223            BRANCH IF CONSTANT                 53430013
         SPACE 1                                                        53460013
         BAL   RR,NXTEQU               IF NOT CONSTANT, CODE TO TEST    53490013
         STH   R1,LI3                EXPRESSION 3 WILL BE REQUIRED.     53520013
*                                    OBTAIN AUXILIARY LABEL LI3.        53550013
         SPACE 1                                                        53580013
         TM    DOF1,DOF1WL             TEST AND BRANCH IF THERE IS A    53610013
         BC    BZ,LG0222             WHILE CLAUSE                       53640013
         SPACE 1                                                        53670013
         BAL   RR,NXTEQU               FOR A WHILE CLAUSE CREATE A      53700013
         STH   R1,LI4                NEW LABEL FOR LI4.                 53730013
         SPACE 1                                                        53760013
*              GENERATE CODE TO TEST SIGN OF EXPRESSION 3               53790013
         SPACE 1                                                        53820013
LG0222   CLC   DRFZRO(2),CNZERO        TEST FOR CONSTANT ENTRY ALREADY  53850013
         BC    BNE,LG0221            MADE FOR ZERO. BRANCH IF THERE IS  53880013
*                                    AN ENTRY                           53910013
         LA    R1,SD01                 OTHERWISE MAKE SUCH AN ENTRY IN  53940013
         LA    R2,ZCONCH             THE CONSTANT CHAIN.                53970013
         BAL   RR,DICCHN                                                54000013
         MVC   DRFZRO(2),ZCONCH        SAVE REF OF ENTRY                54030013
         SPACE 1                                                        54060013
LG0221   MVC   ST051(2),DOE3           SET UP A GREATER OR EQUAL        54090013
         MVC   ST052(2),DRFZRO       COMPARISON BETWEEN EXPRESSION 2    54120013
         MVC   ST061(2),LI3          AND THE CONTROL VARIABLE FOLLOWED  54150013
         LA    R1,ST05               BY A BRANCH TO LI3 IF FALSE        54180013
         BAL   RR,LMV3AU                                                54210013
         SPACE 1                                                        54240013
*              GENERATE COMPARISON OF EXPRESSION 2 AND THE CONTROL      54270013
*        VARIALE FOR THE CASE EXPRESSION 3 POSITIVE. THIS SECTION IS    54300013
*        ALSO ENTERED FOR CONSTANT POSITIVE EXPRESSION 3 IN OTHER THAN  54330013
*        THE LAST SPECIFICATION                                         54360013
         SPACE 1                                                        54390013
LG0225   MVC   ST081(2),LI4            SET  LESS  EXP2,CV               54420013
         MVI   ST07,TRLESS                  IF    LI4,00                54450013
         BAL   RR,COMPAR               SET UP REST OF FIELDS AND PLACE  54480013
*                                    TRIPLES IN OUTPUT TEXT             54510013
         TM    DOF1,DOF1CN             IF THE SECTION WAS ENTERED FOR   54540013
         BC    BNZ,LG0200            POSITIVE CONSTANT BY NO MORE CODE  54570013
*                                    IS NEEDED                          54600013
*              NOW GENERATE TRIPLES TO GO TO NEXT SPECIFICATION AND     54630013
*        DEFINE LI3                                                     54660013
         SPACE 1                                                        54690013
         MVC   ST122(2),DOLABI         GOLN  LABEL I                    54720013
         MVC   ST132(2),LI3            CLN1  LI3                        54750013
         LA    R1,ST12                                                  54780013
*                                      INSERT 10 BYTES OF TRIPLE CODE   54810013
         BAL   RR,LMV3AU             INTO OUTPUT TEXT THEN GO TO        54840013
         BC    B,LG0226              GENERATE A COMPARISON FOR THE CASE 54870013
*                                    EXPRESSION 2 NEGATIVE              54900013
         SPACE 1                                                        54930013
*              CONSTANT EXPRESSION 3. ONLY ONE COMPARISON OF EXPRESSION 54960013
*        2 AND CONTROL VARIABLE NEED BE GENERATED                       54990013
         SPACE 1                                                        55020013
LG0223   TM    DOF1,DOF1NG             TEST FOR SIGN OF EXPRESSION 3    55050013
         BC    BNZ,LG0226            AND BRANCH IF NEGATIVE             55080013
         SPACE 1                                                        55110013
         TM    DOF1,DOF1EW             POSITIVE. IF THIS IS NOT THE     55140013
         BC    BZ,LG0225             LAST SPECIFICATION AND THERE IS    55170013
*                                    NO WHILE,I.E. CONTINUATION OF THE  55200013
         MVC   ST081(2),DOLABI       LOOP IS NOT EFFECTED BY FALLING    55230013
         MVI   ST07,TRGORE           THROUGH, CREATE STANDARD POSITIVE  55260013
         BAL   RR,COMPAR             CASE TRIPLES. OTHERWISE PRODUCE    55290013
*                                      G OR E  EXP2,CV                  55320013
         BC    B,LG0200                IF      LABELI,00                55350013
         SPACE 1                                                        55380013
*              GENERATE COMPARISON CODE FOR EXPRESSION 2 AND THE        55410013
*        CONTROL VARIABLE FOR THE CASE EXPRESSION 3 NEGATIVE. THIS      55440013
*        SECTION IS ENTERED FOR BOTH CONSTANT AND VARIABLE FORMS OF     55470013
*        EXPRESSION 3                                                   55500013
         SPACE 1                                                        55530013
LG0226   TM    DOF1,DOF1EW             BRANCH IF A WHILE CLAUSE FOLLOWS 55560013
         BC    BNZ,LG0228            OR IF THIS IS THE LAST SPECIFICN   55590013
         SPACE 1                                                        55620013
         MVC   ST081(2),DOLOOP         FOR NEITHER WHILE NOR LAST SPEC  55650013
         MVI   ST07,TRGTR            THE CODE FALLS THROUGH INTO THE    55680013
         BAL   RR,COMPAR             NEXT SPEC AT THE END OF THE        55710013
*                                    CURRENT ONE. GENERATE              55740013
         BC    B,LG0200                GREATER  EXP2,CV                 55770013
*                                      IF       LOOP,00                 55800013
         SPACE 1                                                        55830013
LG0228   MVC   ST081(2),DOLABI         FOR WHILE OR LAST SPEC THE CODE  55860013
         MVI   ST07,TRLORE           FALLS THROUGH INTO CONTINUATION    55890013
         BAL   RR,COMPAR             OF THE CURRENT SPEC. GENERATE      55920013
*                                      LESS OR EQUAL   EXP2,CV          55950013
*                                      IF              LABELI,00        55980013
         SPACE 1                                                        56010013
*              RETURN SECTION. IF THERE IS A WHILE CLAUSE LI4 MUST BE   56040013
*        DEFINED AT THIS POINT, OTHERWISE IT IS EQUIVALENT TO THE LOOP  56070013
*        ENTRY LABEL                                                    56100013
         SPACE 1                                                        56130013
         TM    DOF1,DOF1WL                                              56160013
         BC    BZ,LG0200               BRANCH IF NO WHILE               56190013
         SPACE 1                                                        56220013
         TM    DOF1,DOF1CN                                              56250013
         BC    BNZ,LG0200              BRANCH IF CONSTSANT INCREMENT    56280013
         SPACE 1                                                        56310013
         MVC   ST132(2),LI4            OTHERWISE GENERATE CLN1 LI4      56340013
         LA    R1,ST13                                                  56370013
LG0205   BAL   RR,LMV3A5                                                56400013
         SPACE 1                                                        56430013
LG0200   LA    R1,TRPSI                PLACE PSI CODE IN R1 AND THEN    56460013
         BAL   RR,SWTCHP             SWITCH THE CONTROL DESCRIPTION IF  56490013
*                                    NECESSARY FOR NEXT SPECIFICATION   56520013
         L     RR,WSRR01                                                56550013
         BCR   B,RR                                                     56580013
         SPACE 2                                                        56610013
*              SPECIAL CASE OF FORMAT LIST REPLICATION. IPTR ADDRESSES  56640013
*        CV', DOE2 CONTAINS REFERENCE OR 00 FOR UPPER LIMIT.            56670013
         SPACE 1                                                        56700013
LG0250   MVC   ST171(2),DOE2           COPY EXPRESSION 2 DESCRIPTION    56730013
         LA    R1,ST17               INTO TRIPLES WHICH CAUSE IT TO     56760013
         BAL   RR,LMV3A5             BE ASSIGNED TO REGISTER 14 BY      56790013
*                                    VALUE.                             56820013
         SPACE 1                                                        56850013
         BAL   RR,LMV3US               GENERATE USSLD 1,2,7 TO AVOID    56880013
*                                    SAVING AND RESTORING (FORMAT CASE) 56910013
         SPACE 1                                                        56940013
         LH    HR1,DOE2                TEST FOR DICTIONARY REFERENCE    56970013
         LTR   HR1,HR1               IN EXPRESSION 2.                   57000013
         BC    BZ,LG0251                                                57030013
         SPACE 1                                                        57060013
         STH   HR1,PAR1+2              IF DICTIONARY REFERENCE ACCESS   57090013
         L     LR,ZRFAOF             ENTRY TO SEE IF IT IS A CONSTANT   57120013
         BALR  RR,LR                                                    57150013
         L     HR1,PAR1                                                 57180013
         CLI   0(HR1),DRCON            BRANCH IF NOT CONSTANT TO        57210013
         BC    BNE,LG0251            PRODUCE TESTING CODE.              57240013
         SPACE 1                                                        57270013
         CLI   DECNDB(HR1),DATDCN      IF CONSTANT CHECK FOR NON-ZERO   57300013
         BC    BNE,LG0251            DECIMAL INTEGER CONSTANT - FOR     57330013
         CLI   DECNVL(HR1),0         ALL OTHERS GENERATE TEST CODE      57360013
         BC    BNE,LG0252                                               57390013
         SPACE 1                                                        57420013
*              REPLICATION FACTOR IS NOT A NON-ZERO DECIMAL INTEGER     57450013
*        CONSTANT. GENERATE PSEUDO-CODE TO TEST THE CONTENTS OF         57480013
*        REGISTER 14 AND BRANCH TO END OF LOOP IF NOT GREATER THAN      57510013
*        ZERO.                                                          57540013
         SPACE 1                                                        57570013
LG0251   MVC   SP071(2),DOLABI         SET END OF LOOP LABEL IN         57600013
         LA    R1,SP07               BRANCH AND GENERATE                57630013
         LA    R2,SP07L                LTR 14,14                        57660013
         BAL   RR,LMV3U                BC  BNP,LABI                     57690013
         SPACE 1                                                        57720013
*              NOW LOAD 14 WITH VALUE OF REPLICATION FACTOR, FOLLOWED   57750013
*        BY LOOP LABEL, FOLLOWED BY STORE INTO COUNTER VARIABLE.        57780013
         SPACE 1                                                        57810013
LG0252   BAL   RR,SC5                  DROP CV' AND COPY LABEL          57840013
         BAL   RR,SC7                                                   57870013
         MVC   SP081(2),DOCV           GENERATE                         57900013
         LA    R1,SP08                 ST 14,CV                         57930013
         BAL   RR,LMV35                                                 57960013
         BAL   RR,LMV3SN               GENERATE SINLIST FOR FORMAT      57990013
         MVC   DOE0(2),DOCV            PRESERVE CV REF TO END OF LOOP   58020013
         MVC   DOR0(2),DOLOOP          PRESERVE LOOP LABEL NUMBER       58050013
         BC    B,LG0002                NOW RETURN TO SCAN FROM CURRENT  58080013
*                                    TRIPLE.                            58110013
         SPACE 2                                                        58111015
*              SPECIAL CASE. EXPTST HAS FOUND THAT CV IS FIXED BINARY   58112015
*        INTEGER VARIABLE, AND FROM BY AND TO ARE BINARY INTEGER OR     58113015
*        CONSTANT. ALSO, IF CV IS NOT A TEMPORARY, SIZE IS DISABLED     58114015
*        AND THE PREFIX OPTION FOR FIXED OVERFLOW REMAINS UNCHANGED IN  58115015
*        THE BLOCK (I.E. MUST BE THE SAME ON THE DO AND END STATEMENTS) 58116015
*              GENERATE L  14,FROM                                      58117015
*                       BC B,LABI                                       58118015
*        AND MARK THE DO BLOCK AS OPTIMIZED. ALSO TURN OFF THE END-OF-  58119015
*        SPECS BIT TO PREVENT OVERWRITING OF THE END OF THE DO BLOCK    58120015
*        BY BLOCKS FOR NESTED DO'S.                                     58121015
         SPACE 1                                                        58122015
LG0260   LA    R1,ST18                 GENERATE ITDO 14 TO INDICATE     58123015
         BAL   RR,LMV3A5             REGISTER USE TO LS.                58124015
         SPACE 1                                                        58125015
         MVC   SP111(2),DOE1           GENERATE LOAD AND BRANCH, USING  58126015
         MVC   SP112(2),DOLABI       THE 'END-OF-LOOP' LABEL            58127015
         LA    R1,SP11                                                  58128015
         LA    R2,SP11L                                                 58129015
         BAL   RR,LMV3U                                                 58130015
         SPACE 1                                                        58131015
         OI    DOF3,DOF3OP             SET OPTIMIZE BIT ON AND TURN     58132015
         XI    DOF1,DOF1ES           OFF END-OF-SPECS, THEN RETURN      58133015
         BC    B,LG0200                                                 58134015
         SPACE 3                                                        58140013
*                       SUBROUTINE SWTCHP                               58170013
         SPACE 1                                                        58200013
*              THIS SUBROUTINE SWITCHES PSI AND PSI' MARKERS AND        58230013
*        FUNCTION AND FUNCTION' MARKERS IN CV TEXT                      58260013
         SPACE 1                                                        58290013
SWTCHP   TM    DOF2,DOF2PS             TEST FOR PSEUDO CONTROL          58320013
         BCR   BZ,RR                 VARIABLE AND RETURN IF NOT         58350013
         SPACE 1                                                        58380013
         STC   R1,DOTXT                SET NEW CODE IN FIRST TRIPLE OF  58410013
         L     HR1,DOPP              CONTROL VARIABLE DESCRIPTION,      58440013
         STC   R1,0(0,HR1)           PICK UP ADDRESS OF PRIMED MARKER   58470013
         OI    0(HR1),X'40'          AND SET THAT TO NEW PRIMED CODE    58500013
         BCR   B,RR                    RETURN                           58530013
         EJECT                                                          58560013
*                       SUBROUTINE NXTEQU                               58590013
         SPACE 1                                                        58620013
*              THIS SUBROUTINE UPDATES THE LABEL NUMBER SLOT AND        58650013
*        RETURNS THE UPDATED VALUE IN R1.                               58680013
         SPACE 1                                                        58710013
NXTEQU   LH    R1,ZEQMAX                                                58740013
         LA    R1,1(0,R1)              ADD 1 TO LABEL NUMBER SLOT       58770013
         STH   R1,ZEQMAX                                                58800013
         BCR   B,RR                    RETURN                           58830013
         EJECT                                                          58860013
*                       SUBROUTINECODE3                                 58890013
         SPACE 1                                                        58920013
*              THIS SUBROUTINE COMPARISON TRIPLES FROM THE WHILE CLAUSE 58950013
*        INPUT. THE INPUT INFORMATION IS IN THE CURRENT DO BLOCK. THE   58980013
*        OPERAND OF THE WHILE' HAS ALREADY BEEN PLACED IN THE           59010013
*        COMPARISON TRIPLE.                                             59040013
*        OUTPUT. TRIPLES ARE INSERTED IN THE OUTPUT TEXT TO TEXT THE    59070013
*        EXPRESSION.                                                    59100013
         SPACE 1                                                        59130013
CODE3    MVC   ST081(2),DOLABI         PUT NEXT SPEC LABEL IN IF        59160013
*                                    OPERAND 1                          59190013
         LA    R1,ST08                 POINT R1 AT IF TRIPLE            59220013
         TM    DOF1,DOF1ES             TEST AND BRANCH IF END-OF-SPEC   59250013
         BC    BNZ,LMV3A5              RETURN PUTTING OUT 1 TRIPLES     59280013
*                                      NOT END-OF-SPEC. MUST ALSO       59310013
         MVC   ST092(2),DOLOOP       GENERATE A GO TO INTO THE LOOP     59340013
         BC    B,LMV3AU                RETURN PUTTING OUT 2 TRIPLES     59370013
         EJECT                                                          59400013
*                       SUBROUTINE CVSCAN                               59430013
*              THIS SUBROUTINE IS USED TO SCAN CONTROL VARIABLE         59460013
*        DESCRIPTION TEXT.                                              59490013
*        INPUT. IPTR ADDRESSES FIRST INPUT TRIPLE                       59520013
*               R1 ADDRESSES A STRING OF TRIPLE OPERATORS FOR WHICH     59550013
*        THE ROUTINE IS TO LOOK IN ADDITION TO THE STANDARD SET OF      59580013
*        FUNCTION DELIMITERS, ITDO AND JUMP.                            59610013
*        OUTPUT. IPTR ADDRESSES EITHER THE LAST FUNCTION DELIMITER      59640013
*        (UNPRIMED) ENCOUNTERED AT LEVEL 1, OR ONE OF THE SPECIAL       59670013
*        TRIPLES ADDRESSED BY R1.                                       59700013
*               DOSIP2 CONTAINS THE SYMBOLIC ADDRESS OF THE FIRST       59730013
*        SPECIAL TRIPLE ENCOUNTERED AT LEVEL 0.                         59760013
*               TEXT BETWEEN THE ORIGINAL IPTR AND THE RETURNED IPTR    59790013
*        HAS BEEN MOVED INTO THE OUTPUT, AND ANY NESTED DOS EXPANDED.   59820013
         SPACE 1                                                        59850013
CVSCAN   ST    RR,DORR1                SAVE RETURN REGISTER IN DO BLOCK 59880013
         BAL   RR,CTXTRF               CONVERT CURRENT IP TO SYMBOLIC   59910013
         MVC   DOSIP2(3),PAR1+1      AND SAVE IN DO BLOCK               59940013
         XC    LEVEL(2),LEVEL          SET LEVEL COUNT TO ZERO          59970013
LG0101   NC    LEVEL(2),LEVEL          TEST FOR LEVEL 0 AND IGNORE      60000013
         BC    BNZ,LG0113            FOLLOWING TEST IF NOT              60030013
         SPACE 1                                                        60060013
         LR    R2,R1                   POINT R2 AT INPUT TRIPLE LIST    60090013
         BAL   RR,TRPTST               TEST CURRENT TRIPLE AND BRANCH   60120013
         BC    B,LG0100              IF IT IS ONE ADDRESSED BY R1       60150013
         SPACE 1                                                        60180013
LG0113   LA    R2,LISTUD               IF NOT LOOK FOR UNPRIMED         60210013
         BAL   RR,TRPTST             DELIMITERS.                        60240013
         BC    B,LG0103                BRANCH IF FOUND.                 60270013
         SPACE 1                                                        60300013
         LA    R2,LISTPD               IF NOT LOOK FOR PRIMED           60330013
         BAL   RR,TRPTST             DELIMITERS.                        60360013
         BC    B,LG0106                BRANCH IF FOUND                  60390013
         SPACE 1                                                        60420013
LG0102   LA    RR,LG0101               SET RR TO RE-ENTER SCAN LOOP     60450013
         CLI   0(IPTR),TRJUMP          TEST FOR JUMP THEN               60480013
         BC    BNE,SC4               SKIP INPUT TRIPLE OR               60510013
         BC    B,SC11                SKIP INPUT PSEUDO-CODE             60540013
         SPACE 1                                                        60570013
*              UNPRIMED DELIMITER                                       60600013
LG0103   LH    HR1,LEVEL               TEST CURRENT LEVEL. IF ZERO      60630013
         LTR   HR1,HR1               THIS IS THE LATEST DELIMITER AT    60660013
         BC    BNZ,LG0104            LEVEL 1. IF NON-ZERO JUST GO TO    60690013
*                                    BUMP LEVEL COUNT BY 1              60720013
         BAL   RR,CTXTRF               IF ZERO, PUT SYMBOLIC TEXT NAME  60750013
         MVC   DOSIP1(3),PAR1+1      IN DO BLOCK AND SET LEVEL 1 SWITCH 60780013
         OI    SWLVL1,X'F0'                                             60810013
         SPACE 1                                                        60840013
LG0104   LA    HR1,1(0,HR1)            ADD ONE TO LEVEL COUNT           60870013
         SPACE 1                                                        60900013
LG0105   STH   HR1,LEVEL               STORE NEW LEVEL COUNT VALUE      60930013
         BC    B,LG0102              THEN GO TO LOOK AT NEXT TRIPLE     60960013
         SPACE 1                                                        60990013
*              PRIMED DELIMITER                                         61020013
LG0106   LH    HR1,LEVEL               DECREASE LEVEL COUNT BY ONE.     61050013
         BCTR  HR1,0                                                    61080013
         BC    B,LG0105                                                 61110013
         SPACE 1                                                        61140013
*              ONE OF INPUT ARGUMENT TRIPLES FOUND AT LEVEL ZERO        61170013
LG0100   SR    R2,R1                   R1 ADDRESS INPUT STRING OF       61200013
         AR    R2,R2                 TRIPLES. R2 ADDRESSES MEMBER FOUND 61230013
         AR    R2,R2                 MULTIPLY DIFFERENCE BY 4 AND STORE 61260013
         STC   R2,DORR1              IN HIGH BYTE OF DORR1.             61290013
         BAL   RR,CTXTRF               CONVERT INPUT POINTER TO         61320013
         MVC   WSTXRF(4),PAR1        SYMBOLIC AND SAVE IN WSTXRF        61350013
         SPACE 1                                                        61380013
         MVI   PAR1,0                  USE SC10 TO RESTORE IPTR TO      61410013
         MVC   PAR1+1(3),DOSIP2      ITS POSITION ON ENTERING CVSCAN    61440013
         BAL   RR,SC10                                                  61470013
         L     IPTR,PAR1                                                61500013
         SPACE 1                                                        61530013
         MVC   DOSIP2(3),WSTXRF+1      NOW SAVE THE TEXT REFERENCE OF   61560013
*                                    THE TRIPLE FOUND IN DOSIP2         61590013
*              NOW TEST WHETHER DELIMITER TRIPLE WAS FOUND              61620013
LG0120   BC    NOP,LG0121              THIS SWITCH IS A BRANCH IF A     61650013
SWLVL1   EQU   LG0120+1              DELIMITER HAS BEEN FOUND, A NOP    61680013
*                                    IF NOT                             61710013
         MVC   DOSIP1(3),DOSIP2        NO DELIMITER. COPY DOSIP2 INTO   61740013
*                                    DOSIP1 SO THAT MOVOUT MOVES TO     61770013
*                                    FOUND TRIPLE                       61800013
LG0121   NI    SWLVL1,X'0F'            RESET LEVEL 1 SWITCH, THEN GO    61830013
         BC    B,LG0500              TO MOVOUT TO MOVE TEXT UP TO LAST  61860013
*                                    LEVEL 1 DELIMITER OR FOUND TRIPLE  61890013
         EJECT                                                          61920013
*                       SUBROUTINE TRPTST                               61950013
*              THIS SUBROUTINE TEST THE CURRENT TRIPLE TO SEE IF IT IS  61980013
*        ONE OF A STRING OF TRIPLES ADDRESSED BY R2.                    62010013
*        INPUT. R1 ADDRESSES STRING OF TRIPLE OPERATORS DELIMITED BY A  62040013
*              00 BYTE.                                                 62070013
*        OUTPUT. RETURN TO 0(RR) TRIPLE FOUND                           62100013
*                          4(RR) TRIPLE NOT FOUND                       62130013
*               R2 ADDRESSES TRIPLE FOUND                               62160013
         SPACE 1                                                        62190013
TRPTST   CLI   0(R2),0                 TEST FOR 00 AND RETURN 'NOT      62220013
         BC    BE,4(0,RR)            FOUND' IF IT IS                    62250013
         SPACE 1                                                        62280013
         CLC   0(1,R2),0(IPTR)         RETURN 'FOUND' IF TRIPLE INPUT   62310013
         BCR   BE,RR                 SAME AS CURRENT VALUE IN STRING    62340013
         SPACE 1                                                        62370013
         LA    R2,1(0,R2)              BUMP R2 TO LOOK AT NEXT BYTE     62400013
         BC    B,TRPTST              IN STRING.                         62430013
         SPACE 3                                                        62460013
*                       SUBROUTINE TESTAR                               62490013
*              THIS SUBROUTINE EXAMINES THE ENTRY IN PAR1+2 AND, IF     62520013
*        NON-ZERO, TESTS THE DICTIONARY ENTRY TO SEE IF IT IS SCALAR.   62550013
*        IF NOT SCALAR AN ERROR ENTRY IS MADE AND THE STOP PSEUDO-CODE  62580013
*        GENERATED.                                                     62610013
         SPACE 1                                                        62640013
TESTAR   CLC   PAR1+2(2),CNZERO                                         62670013
         BCR   BE,RR                   RETURN IF ARGUMENT IS ZERO       62700013
         SPACE 1                                                        62730013
         ST    RR,WSRR02               SAVE REGISTER                    62760013
         L     LR,ZRFAOF               GET DICT ENTRY                   62790013
         BALR  RR,LR                                                    62820013
         L     HR1,PAR1                                                 62850013
         L     RR,WSRR02               RESTORE AND FALL THROUGH INTO    62880013
*                                    TESTAS.                            62910013
         SPACE 3                                                        62940013
*                       SUBROUTINE TESTAS                               62970013
*              THIS SUBROUTINE TESTS THE DICTIONARY ENTRY WHOSE ADDRESS 63000013
*        IS IN HR1 AND GENERATES AN ERRORSTOP PSEUDO-CODE ITEM AND      63030013
*        ERROR MESSAGE IF THE ENTRY IS NOT A SCALAR.                    63060013
         SPACE 1                                                        63090013
TESTAS   TM    0(HR1),X'30'            TEST ARRAY AND STRUCTURE BITS    63120013
         BCR   BZ,RR                 AND RETURN IF ZERO.                63150013
         SPACE 1                                                        63180013
         TM    0(HR1),X'10'            TEST FOR DIMENSIONED AND BRANCH  63210013
         BC    BNZ,LG0351            TO ERROR IF IT IS.                 63240013
         SPACE 1                                                        63270013
         MVN   CNZRO(1),0(HR1)         NON-DIMENSIONED STRUCTURE ITEM.  63300013
         CLI   CNZRO,X'0E'           TEST FOR BASE ELEMENT BY LOOKING   63330013
         BCR   BNE,RR                FOR CODES X'XE'. RETURN IF NOT     63360013
*                                    STRUCTURE ITEM.                    63390013
         SPACE 1                                                        63420013
LG0351   ST    RR,WSRR02                                                63450013
         LA    R1,SP03                 PUT OUT ERROR PSEUDO/CODE        63480013
         LA    R2,3                                                     63510013
         BAL   RR,LMV3U                                                 63540013
         MVC   PAR6(4),ERID04                                           63570013
         L     LR,ZUEROF               PUT OUT ERROR MESSAGE            63600013
         L     RR,WSRR02               RESTORE AND RETURN               63630013
         BCR   B,LR                                                     63660013
         EJECT                                                          63690013
*                       SUBROUTINE COMPAR                               63720013
         SPACE 1                                                        63750013
*              THIS SUBROUTINE GENERATES COMPARISON AND IF TRIPLES FOR  63780013
*        THE TESTING CODE IMPLIED BY A 'TO' CLAUSE. THE TRIPLE          63810013
*        SKELETONS ST07 AND ST08 ARE USED. THE OP. CODE IN ST07 AND THE 63840013
*        LABEL IN ST08 HAVE BEEN INSERTED BEFORE THE CALL. THE ROUTINE  63870013
*        INSERTS INTO THE OUTPUT TEXT ANY ADDITIONAL TRIPLE REQUIRED    63900013
*        TO DESCRIBE THE CONTROL VARIABLE                               63930013
         SPACE 1                                                        63960013
COMPAR   ST    RR,WSRR02                                                63990013
         BAL   RR,CVCODE               INSERT CONTROL VARIABLE DEFINING 64020013
*                                    CODE IF NECESSARY                  64050013
         LA    R1,ST07                 POINT R1 AT COMPARE - IF PAIR    64080013
*                                      MOVE THE COMPARISON/TEST TRIPLE  64110013
         BAL   RR,LMV3AU             PAIR INTO THE OUTPUT TEXT          64140013
         SPACE 1                                                        64170013
         L     RR,WSRR02               RESTORE RR AND RETURN            64200013
         BCR   B,RR                                                     64230013
         EJECT                                                          64260013
*                       SUBROUTINE CTXTRF                               64290013
         SPACE 1                                                        64320013
*              THIS SUBROUTINE IS USED TO CALL ZTXROF FOR CONVERSION    64350013
*        OF THE CURRENT INPUT POINTER VALUE TO A SYMBOLIC TEXT REF.     64380013
         SPACE 1                                                        64410013
CTXTRF   ST    IPTR,PAR2               STORE INPUT POINTER              64440013
         MVC   PAR1(4),SCTXTI                                           64470013
         L     LR,ZTXROF               CALL ZTXROF. ON RETURN PAR1      64500013
         BCR   B,LR                  CONTAINS THE SYMBOLIC ADDRESS      64530013
         SPACE 3                                                        64560013
*                       SUBROUTINE DICCHN                               64590013
         SPACE 1                                                        64620013
*              THIS SUBROUTINE MAKES A DICTIONARY ENTRY AND PLACES IT   64650013
*        AT THE HEAD OF A SPECIFIED CHAIN.                              64680013
*        INPUT. R1 ADDRESSES DICT ENTRY, R2 ADDRESSES CHAIN HEAD SLOT   64710013
         SPACE 1                                                        64740013
DICCHN   ST    RR,WSRR06               SAVE RETURN REGISTER             64770013
         MVC   CHAIN(2,R1),0(R2)       PLACE CURRENT CHAIN HEAD VALUE   64800013
*                                    IN CHAIN SLOT IN SKELETON ENTRY    64830013
         ST    R1,PAR1                 SET PAR1 TO ADDRESS SKELETON     64860013
         MVC   PAR2(2),CNZERO        ENTRY AND PUT OUT LENGTH IN PAR2   64890013
         MVC   PAR2+2(2),1(R1)                                          64920013
         L     LR,ZDRFOF               MAKE ENTRY                       64950013
         BALR  RR,LR                                                    64980013
         SPACE 1                                                        65010013
         MVC   0(2,R2),PAR1+2          PLACE REF OF ENTRY IN CHAIN      65040013
         MVC   WSDREF(2),PAR1+2      HEAD SLOT AND WSDREF               65070013
         L     RR,WSRR06               RESTORE AND RETURN               65100013
         BCR   B,RR                                                     65130013
         EJECT                                                          65160013
*                       SUBROUTINE TESTOP                               65190013
         SPACE 1                                                        65220013
*              THIS SUBROUTINE TESTS OPERAND 2 OF THE CURRENT TRIPLE    65250013
*        IF 00 I.E. AN INTERMEDIATE RESULT, THEN A DICTIONARY ENTRY     65280013
*        IS MADE FOR A TEMPORARY WHOSE CHARACTERISTICS ARE THOSE TO     65310013
*        BE FOUND IN THE TMPD OPERAND SKELETON IN EXPTMP (PLACED THERE  65340013
*        BY THE EXPRESSION ANALYSIS ROUTINE). TRIPLES ARE PLACED IN     65370013
*        THE OUTPUT TEXT TO BUY THIS TEMP AND ASSIGN THE INTERMEDIATE   65400013
*        RESULT TO IT.                                                  65430013
*        IF NOT 00 I.E. A DICTIONARY REFERENCE, THE ENTRY IS EXAMINED,  65460013
*        AND, IF CONSTANT, THE CONSTANT SWITCH IS SET. OTHERWISE AN     65490013
*        ENTRY IS MADE FOR A TEMPORARY WITH THE SAME DATA TYPE, AND     65520013
*        TRIPLES GENERATED TO BUY THIS TEMP AND ASSIGN THE VARIABLE TO  65550013
*        IT.                                                            65580013
*        IN ALL CASES THE DICT REF OF THE RESULT IS LEFT IN WSDREF.     65610013
         SPACE 1                                                        65640013
*                       SUBROUTINE ASSIGN                               65670013
         SPACE 1                                                        65700013
*              THIS SUBROUTINE IS EXACTLY THE SAME AS TESTOP EXCEPT     65730013
*        FOR AN INITIAL INSTRUCTION WHICH SETS THE TEMPORARY            65760013
*        DESCRIPTION FIELD NORMALLY SET UP BY EXPRESSION ANALYSIS       65790013
*        TO INDICATE FIXED BINARY INTEGER. THE ROUTINE IS USED BY       65820013
*        THE CONTROL VARIABLE SUBSCRIPT SECTION                         65850013
         SPACE 1                                                        65880013
ASSIGN   MVC   EXPTMP(4),FIXBIN        SET DATA DESCRIPTION WORD TO     65910013
         OI    SWTEST,X'F0'          FIXED BINARY. SET TESTOP ENTRY     65940013
         BC    B,LG0801              SWITCH OFF                         65970013
         SPACE 1                                                        66000013
TESTOP   NI    SWTEST,X'0F'            SET TESTOP ENTRY SWITCH ON       66030013
         NI    DOF1,DOF1NV           RESET EXPRESSION EVALUATION BIT    66060013
         MVI   SWCON,0               AND CONSTANT BY SWITCH             66090013
         SPACE 1                                                        66120013
*              START COMMON SECTION                                     66150013
LG0801   ST    RR,WSRR01               SAVE RETURN REGISTER             66180013
         CLC   3(2,IPTR),CNZERO        TEST OPERAND 2 AND BRANCH IF     66210013
         BC    BE,LG0802             INTERMEDIATE RESULT                66240013
         SPACE 1                                                        66270013
*              OPERAND IS DICTIONARY ENTRY                              66300013
         SPACE 1                                                        66330013
         MVC   PAR1+2(2),3(IPTR)       GET DICTIONARY ENTRY OF          66360013
         L     LR,ZRFAOF             OPERAND                            66390013
         BALR  RR,LR                                                    66420013
         L     HR1,PAR1                                                 66450013
         SPACE 1                                                        66480013
         BAL   RR,TESTAS               TEST FOR ARRAY OR STRUCTURE AND  66510013
*                                    PUT OUT ERROR MESSAGE IF EITHER    66540013
         SPACE 1                                                        66570013
         CLI   0(HR1),DRCON            TEST FOR CONSTANT                66600013
         BC    BE,LG0808                                                66630013
         SPACE 1                                                        66660013
         CLI   0(HR1),DRSL             TEST FOR LABEL CONSTANT          66690013
         BC    BNE,LG0803                                               66720013
         SPACE 1                                                        66750013
*              OPERAND IS A CONSTANT                                    66780013
LG0808   TM    DECNDB(HR1),DATCAD      IF CHARACTER OR BIT STRING       66787015
         BC    BZ,LG0804             CONSTANT IGNORE ( I.E. TREAT AS    66794015
*                                    A VARIABLE)                        66801015
         OI    SWCON,DOF1CN            FOR ARITHMETIC CONSTANTS SET     66808015
         CLI   DECNVL(HR1),MINUS     CONSTANT AND IF APPLICABLE, -VE.   66815015
         BC    BNE,LG0804            BY SWITCHES.                       66822015
         OI    SWCON,DOF1NG                                             66829015
         SPACE 1                                                        66840013
*              CONSTANT OR SCALAR TEMPORARY                             66870013
LG0804   MVC   WSDREF(2),3(IPTR)       SET WSDREF FROM OPERAND 2        66900013
         SPACE 1                                                        66930013
*              COMMON RETURN                                            66960013
LG0800   L     RR,WSRR01               RESTORE AND RETURN               66990013
         BCR   B,RR                                                     67020013
         SPACE 2                                                        67050013
*              NON-CONSTANT DICTIONARY ENTRY                            67080013
LG0803   BC    B,LG0802                BRANCH IF ASSIGN ENTRY           67110013
SWTEST   EQU   LG0803+1                                                 67140013
         SPACE 1                                                        67170013
*              FOR TESTOP ENTRY, TEST FOR SCALAR TEMPORARY, AND IF      67200013
*        THIS IS THE CASE, DO NOT ASSIGN TO ANOTHER TEMPORARY           67230013
         CLI   0(HR1),DRTEMP                                            67260013
         BC    BNE,LG0806              BRANCH IF NOT 8F CODE            67290013
         SPACE 1                                                        67320013
         TM    DEOT2(HR1),OT2FP        TEST FORMAL PARAMETER BIT. IF    67350013
         BC    BZ,LG0804             ZERO ENTRY IS SCALAR TEMPORARY     67380013
*                                    SET UP BY LOOP OPTIMIZER           67410013
         SPACE 1                                                        67440013
*              OPERAND IS DICTIONARY ENTRY WHICH IS NEITHER A CONSTANT  67470013
*        NOR A SCALAR TEMPORARY. SET UP TMPEXP FROM ENTRY AND ENTER     67500013
*        TYPE ANALYSIS SECTION                                          67530013
         SPACE 1                                                        67560013
LG0806   MVC   EXPTMP(1),0(HR1)        ENTRY CODE                       67590013
         MVC   EXPTMP+1(3),DEDATA(HR1) MOVE DATA CODE BYTES IN CASE     67620013
*                                    ENTRY IS DATA VARIABLE.            67650013
         MVC   WSPICT(2),DEPICT(HR1)   COPY PICTURE REF IF ANY          67660016
         SPACE 1                                                        67680013
*              DATA TYPE ANALYSIS SECTION                               67710013
         SPACE 1                                                        67740013
LG0802   NI    EXPTMP,X'0F'            PRESERVE ONLY LOW 4 BITS OF      67770013
*                                    CODE BYTE                          67800013
         CLI   EXPTMP,X'0F'                                             67830013
         BC    BE,LG0810               BRANCH IF DATA VARIABLE          67860013
         SPACE 1                                                        67890013
         CLI   EXPTMP,X'0B'                                             67920013
         BC    BE,LG0830               BRANCH IF CONSTANT (UMBRELLA)    67950013
         SPACE 1                                                        67980013
*        ALL OTHERS WILL COME TO A STICKY END BECAUSE THEY CANNOT BE    68010013
*        ASSIGNED. MAKE AN ERROR ENTRY AND RESET THE DATA DESCRIPTOR    68040013
*        TO FIXED BINARY TO PATCH THINGS UP FOR THE PRESENT             68070013
         SPACE 1                                                        68100013
         MVC   PAR6(4),ERID06                                           68130013
         L     LR,ZUEROF                                                68160013
         BALR  RR,LR                                                    68190013
         EX    0,ASSIGN                SET TYPE TO FIXED BINARY         68220013
         BC    B,LG0802                                                 68250013
         SPACE 1                                                        68280013
*              DATA VARIABLE (CODE BYTE 0F)                             68310013
LG0810   MVC   SD02+DEDATA(3),EXPTMP+1 COPY DATA BYTES INTO THE         68340013
         LA    R1,SD02               SKELETON ENTRY. POINT R1 AT ENTRY  68370013
         XC    DEPICT(2,R1),DEPICT(R1) CLEAR PICTURE FIELD           I8 68380016
         TM    DEDATA(R1),DATPIC       IF THE TEMORARY WE ARE ABOUT  I8 68390016
         BC    BNZ,LG0811            TO MAKE IS PICTURE THEN THE     I8 68400016
         MVC   DEPICT(2,R1),WSPICT   PICTURE REF IS IN WSPICT           68410016
LG0811   EQU   *                                                        68420016
         TM    DEDATA(R1),DATCAD       TEST CAD/STRING BIT AND BRANCH   68430013
         BC    BZ,LG0812             IF STRING                          68460013
         SPACE 1                                                        68490013
*              CAD                                                      68520013
LG0814   NI    DEVAR(R1),VARNCT        ALSO USED FOR FIXED STRINGS.     68550013
         MVI   2(R1),SD02L1          SET LENGTH FOR SECOND OFFSET SLOT  68580013
*                                    AND RESET CTL ALLOCATION FLAG      68610013
         MVC   PAR1+2(2),SCBLK         R1 CONTAINS DICT ENTRY SKELETON  68640013
         L     LR,ZRFAOF             ADDRESS. THE ENTRY IS TO BE ADDED  68670013
         BALR  RR,LR                 TO THE AUTOMATIC CHAIN, SO ACCESS  68700013
         L     HR1,PAR1              THE CURRENT BLOCK ET1              68730013
         SPACE 1                                                        68760013
         NI    DEOT2(R1),OT2NCT        RESET CONTROLLED STORAGE CLASS   68790013
         LA    R2,DEAUTO(0,HR1)        R2 ADDRESSES AUTOMATIC CHAIN     68820013
         BAL   RR,DICCHN             SLOT. MAKE ENTRY AND CHAIN         68850013
         LA    R1,ST01                 POINT R1 AT ASSIGN TRIPLE        68880013
         SPACE 1                                                        68910013
*              COMMON SECTION TO PLACE ASSIGNMENT TRIPLE IN OUTPUT      68940013
LG0813   MVC   1(2,R1),WSDREF          PLACE DICT REF (SET UP BY        68970013
         MVC   3(2,R1),3(IPTR)       DICCHN) IN OPERAND 1 OF TRIPLE     69000013
         BAL   RR,LMV3A5             ADDRESSED BY R1. COPY OPERAND 2    69030013
         BC    B,LG0800              FROM INPUT TRIPLE. PLACE TRIPLE    69060013
*                                    IN OUTPUT AND RETURN               69090013
         SPACE 2                                                        69120013
*              STRING                                                   69150013
LG0812   TM    DEDATA(R1),DATADJ       TEST FOR ADJUSTABLE. IF NOT      69180013
         BC    BZ,LG0814             TREAT AS ORDINARY CAD.             69210013
         SPACE 1                                                        69240013
*              ADJUSTABLE STRING                                        69270013
         OI    DEOT2(R1),OT2CTL        SET CONTROLLED STORAGE CLASS     69300013
         OI    DEVAR(R1),VARCTL        SET CONTROLLED ALLOCATION FLAG   69330013
         MVI   2(R1),SD02L2            SET LENGTH FIELD FOR CONTROLLED  69360013
         SPACE 1                                                        69390013
         MVC   FRECHN(2,R1),DOE0       COPY FREE CHAIN HEAD INTO THE    69420013
         LA    R2,ZCITEM             SKELETON. POINT R2 AT THE CONTROL  69450013
         BAL   RR,DICCHN             CHAIN HEAD AND MAKE ENTRY          69480013
         MVC   DOE0(2),WSDREF          COPY REF OF NEW ENTRY INTO FREE  69510013
*                                    CHAIN HEAD                         69540013
         MVC   PAR1+2(2),WSDREF        GET THE ABSOLUTE ADDRESS OF THE  69570013
         L     LR,ZRFAOF             ENTRY WHICH HAS JUST BEEN MADE     69600013
         BALR  RR,LR                 AND INSERT THE ENTRY'S REFERENCE   69630013
         L     R1,PAR1               SO THAT THE MARKER FOR REGISTER    69660013
         MVC   DECTL(2,R1),WSDREF    ALLOCATION CAN BE SET UP CORRECTLY 69690013
         LA    R1,ST15                 POINT R1 AT ALLOCATE AND ASSIGN  69720013
         BC    B,LG0813              TRIPLE AND GO TO PUT IT IN OUTPUT  69750013
         SPACE 2                                                        69780013
*              UMBRELLA CONSTANT                                        69810013
LG0830   MVC   SWCON(1),EXPTMP+1       COPY CONSTANT AND -VE. BITS      69840013
         MVC   WSDREF(2),EXPTMP+2      COPY DICT REF OF CONSTANT        69870013
         BC    B,LG0800                RETURN                           69900013
         EJECT                                                          69930013
*                       SUBROUTINE MOVOUT                               69960013
*              THIS SUBROUTINE MOVES INPUT TEXT INTO OUTPUT UP TO THE   69990013
*        TRIPLE WHOSE SYMBOLIC ADDRESS IS IN DOSIP1. ITDOS NESTED       70020013
*        WITHIN THE TEXT ARE HANDLED BY RESUMING NORMAL SCANNING AND    70050013
*        RETURNING TO LG0500 FROM THE ITDO' SECTION WHEN THE DOF2CV     70080013
*        FLAG BIT IS 1.                                                 70110013
         SPACE 1                                                        70140013
MOVOUT   ST    RR,DORR1                SAVE RETURN REGISTER IN CURRENT  70170013
*                                    DO BLOCK                           70200013
         MVC   DOSIP1(3),DOSIP2        COPY DOSIP2 INTO DOSIP1          70230013
         SPACE 1                                                        70260013
LG0500   BAL   RR,CTXTRF               ENTRY FROM ITDO' OR CVSCAN - RR  70290013
         CLC   DOSIP1(3),PAR1+1      ALREADY SAVED AND DOSIP 1 SET UP.  70320013
         BC    BNE,LG0501            CONVERT IP TO SYMBOLIC, COMPARE    70350013
*                                    WITH TEXT REF. BRANCH IF UNEQUAL   70380013
         SPACE 1                                                        70410013
         L     RR,DORR1                IF EQUAL, RETURN                 70440013
         BCR   B,RR                                                     70470013
         SPACE 1                                                        70500013
LG0501   CLI   0(IPTR),TRITDO          IF UNEQUAL SEE IF THE TRIPLE IS  70530013
         BC    BE,LG0002             ITDO. IF IT IS GO TO NORMAL        70560013
*                                    SCANNING TO MATCHING ITDO'         70590013
         SPACE 1                                                        70620013
         LA    RR,LG0500               OTHERWISE CHECK FOR JUMP OR      70650013
         CLI   0(IPTR),TRJUMP        OTHER TRIPLE AND LOOP BACK TO TOP  70680013
         BC    BNE,SC7               OF ROUTINE VIA APPROPRIATE SCAN    70710013
         BC    B,SC9                 ROUTINE.                           70740013
         EJECT                                                          70770013
*                       SUBROUTINE SUBSCN                               70800013
*              THIS SUBROUTINE SCANS SUBSCRIPTS IN CONTROL VARIABLE,    70830013
*        ASSIGNS THEM TO INTEGER TEMPORARIES, AND SETS UP TEXT IN THE   70860013
*        DO BLOCK COMPRISING THE DELIMITER TRIPLES AND COMMA TRIPLES    70890013
*        WITH INTEGER TEMPORARY (OR CONSTANT) ARGUMENTS.                70920013
         SPACE 1                                                        70950013
SUBSCN   ST    RR,DORR2                SAVE RETURN REGISTER             70980013
         BAL   RR,CVCOPY               MOVE CURRENT TRIPLE TO DO TEXT   71010013
LG0951   LA    R1,LISTSC               SCAN FOR SUBSCRIPT PRIMED        71040013
         BAL   RR,CVSCAN             MARKERS OR COMMA.                  71070013
         SPACE 1                                                        71100013
         CLI   DORR1,0                 ON RETURN IPTR ADDRESSES ONE OF  71130013
         BC    BE,LG0954             THE ABOVE OR A DELIMITER. BRANCH   71160013
*                                    IF SUBSCRIPT' MET.                 71190013
         SPACE 1                                                        71220013
         CLI   0(IPTR),TRCOM           COMMA. TEST TO SEE IF WE ARE     71250013
         BC    BE,LG0953             ACTUALLY LOOKING AT A COMMA        71280013
         SPACE 1                                                        71310013
         BAL   RR,MOVOUT               IF NOT, MOVE TEXT UP TO THE      71340013
*                                    COMMA TRIPLE                       71370013
         SPACE 1                                                        71400013
LG0953   BAL   RR,ASSIGN               CONVERT ARGUMENT TO BINARY       71430013
         MVC   3(2,IPTR),WSDREF      INTEGER TEMPORARY AND PLACE        71460013
         BAL   RR,CVCOPY             COMMA TRIPLE IN DO TEXT, ASSIGN    71490013
         BC    B,LG0951              IN OUTPUT. GO TO LOOK FOR NEXT     71520013
*                                    ARGUMENT                           71550013
         SPACE 1                                                        71580013
LG0954   BAL   RR,MOVOUT               MOVE TEXT PRECEDING PRIMED       71610013
*                                    MARKER                             71640013
         BAL   RR,CVCOPY               COPY THE PRIMED TRIPLE INTO THE  71670013
         L     RR,DORR2              DO TEXT AND RETURN                 71700013
         BCR   B,RR                                                     71730013
         EJECT                                                          71760013
*                       SUBROUTINE CVCODE                               71790013
         SPACE 1                                                        71820013
*              THIS SUBROUTINE IS USED BY CODE2 TO MOVE INTO THE OUTPUT 71850013
*        TEXT ANY TRIPLES NECESSARY TO DEFINE THE CONTROL VARIABLE AT   71880013
*        POINTS OF USE. THE FLAG BIT DOF2CV INDICATES THE EXISTENCE OF  71910013
*        SUCH TEXT. THE TEXT ITSELF IS APPENDED TO THE CURRENT DO BLOCK 71940013
*        AND MAY SPAN SCRATCH CORE BLOCKS.                              71970013
         SPACE 1                                                        72000013
CVCODE   TM    DOF2,DOF2CV             TEST CV FLAG AND RETURN IF ZERO  72030013
         BCR   BZ,RR                 I.E. NO CONTROL VARIABLE TEXT      72060013
         SPACE 1                                                        72090013
*              MOVE TEXT TO OUTPUT                                      72120013
         LA    R1,DOTXT                POINT R1 AT TEXT AND LOAD LENGTH 72150013
         LH    R2,DOLV               INTO R2, THEN GENERATE TEXT AND    72180013
         BC    B,LG0151              RETURN INDIRECTLY                  72210013
         EJECT                                                          72240013
*                       SUBROUTINE CVCOPY                               72270013
         SPACE 1                                                        72300013
*              THIS SUBROUTINE MOVES THE CURRENT INPUT TRIPLE INTO      72330013
*        THE CONTROL VARIABLE TEXT BLOCK. IF THE TRIPLE IS PSI' ITS     72360013
*        POSITION IN CV TEXT IS NOTED IN DOPP                           72390013
         SPACE 1                                                        72420013
CVCOPY   OI    DOF2,DOF2CV             SET CONTROL VARIABLE TEXT FLAG   72450013
         LA    R1,DOTXT                POINT R1 AT CURRENT END OF       72480013
         LH    HR1,DOLV              CONTROL VARIABLE TEXT              72510013
         AR    R1,HR1                                                   72540013
         MVC   0(5,R1),0(IPTR)         COPY CURRENT INPUT TRIPLE        72570013
         LA    HR1,5(0,HR1)            UPDATE LENGTH OF TEXT            72600013
         STH   HR1,DOLV                                                 72630013
         CLI   0(IPTR),TRPSIP          IF THE CURRENT TRIPLE IS NOT     72660013
         BC    BNE,SC5               PSI' RETURN VIA SC5.               72690013
         ST    R1,DOPP                 FOR PSI' PUT COPY ADDRESS IN     72720013
         BC    B,SC5                 DO BLOCK THE GO TO DELETE TRIPLE   72750013
         EJECT                                                          72780013
*                       SUBROUTINE PSHDWN                               72810013
         SPACE 1                                                        72840013
*              THIS SUBROUTINE IS USED BY THE DO AND ITDO SECTIONS      72870013
*        TO OBTAIN AND INITIALIZE SPACE FOR A NEW DO BLOCK AND TO SET   72900013
*        THE DOBASE REGISTER TO ADDRESS IT                              72930013
         SPACE 1                                                        72960013
PSHDWN   LA    HR1,DOCORE              POINT AT END OF CORE OF PRESENT  72990013
         TM    DOF1,DOF1ES           BLOCK AND BRANCH IF END-OF-SPECS   73020013
         BC    BNZ,LG0601            BIT IS ON                          73050013
         SPACE 1                                                        73080013
         LA    HR1,DOVAR               POINT AT END OF FIXED PART OF    73110013
         TM    DOF2,DOF2CV           DO BLOCK AND BRANCH IF THERE IS    73140013
         BC    BZ,LG0601             NO CONTROL VARIABLE TEXT           73170013
         SPACE 1                                                        73200013
         LA    HR1,DOMIN               POINT AT END OF CV TEXT IN THIS  73230013
         AH    HR1,DOLV              DO BLOCK                           73260013
         LA    HR1,3(0,HR1)            ROUND UP TO WORD BOUNDARY FOR    73290013
         N     HR1,CNMASK            THOSE CASES INVOLVING CV TEXT      73320013
         SPACE 1                                                        73350013
*              NOW POINT DOBASE AT NEW AREA AND INITIALIZE IT           73380013
         SPACE 1                                                        73410013
LG0601   LR    R1,DOBASE                                                73440013
         LR    DOBASE,HR1              POINT DOBASE AT NEW AREA         73470013
         SPACE 1                                                        73500013
         XC    0(DOMINL,DOBASE),0(DOBASE)   CLEAR UP TO DOMIN           73530013
         ST    R1,DOPREV               SET BACKWARD CHAIN               73560013
         BCR   B,RR                                                     73590013
         EJECT                                                          73620013
*                       SUBROUTINES PSTYP0 AND PSTYP1                   73650013
         SPACE 1                                                        73680013
*              THESE SUBROUTINES ARE USED TO DETERMINE THE TYPE OF THE  73710013
*        CURRENT PSEUDO-VARIABLE ARGUMENT. THEY RETURN TO 0,RR FOR      73740013
*        VARIABLE AND 4,RR FOR INTEGER. THE PSTYP1 ENTRY ADDS ONE TO    73770013
*        THE ARGUMENT COUNT                                             73800013
         SPACE 1                                                        73830013
PSTYP1   LH    HR1,DOCOM               ADD 1 TO THE CURRENT VALUE OF    73860013
         LA    HR0,1(0,HR1)          DOCOM AND PLACE THE PREVIOUS       73890013
         STH   HR0,DOCOM             VALUE IN HR0                       73920013
         LR    HR0,HR1                                                  73950013
         BC    B,LG0901                                                 73980013
         SPACE 1                                                        74010013
PSTYP0   LH    HR0,DOCOM                                                74040013
         SPACE 1                                                        74070013
LG0901   CLI   DOPCOD,SUBSTR           RETURN 'VARIABLE' FOR ALL BUT    74100013
         BCR   BNE,RR                SUBSTRING.                         74130013
         SPACE 1                                                        74160013
         LTR   HR0,HR0                 FIRST ARGUMENT OF SUBSTRING IS   74190013
         BCR   BZ,RR                 'VARIABLE'.                        74220013
         BC    B,4(0,RR)               REST ARE 'INTEGER'               74250013
         EJECT                                                          74280013
*                       CONSTANTS AND WORKSPACE AREAS                   74310013
         SPACE 1                                                        74340013
*              CONSTANTS                                                74370013
CNZERO   DC    F'0'                                                     74400013
CNSMAX   DC    F'16384'                MAX SYMBOLIC REG NUMBER          74430013
CNMASK   DC    F'-4'                                                    74460013
FIXBIN   DC    X'0F8C1F80'             DESCRIPTOR FOR FIXED BINARY      74490013
*                                    PRECISION 31                       74520013
DRFZRO   DC    H'0'                    DICT REF OF ZERO CONSTANT        74550013
CNLDLH   DC    C'LHZZ'                                                  74580013
CNRLS    DC    C'LGLHZZ'               RELEASE LG,LH                    74610013
CNZRO    DC    X'00'                   USED IN STRUCTURE ITEM TEST      74640013
         SPACE 2                                                        74670013
*              CONTROL VARIABLE SCANNING LISTS                          74700013
         SPACE 1                                                        74730013
LISTUD   DC    AL1(TRPSI)              UNPRIMED DELIMITER TRIPLES       74760013
         DC    AL1(TRFUN)                                               74790013
         DC    AL1(TRARY)                                               74820013
         DC    AL1(TRITDO)                                              74850013
         DC    X'00'                                                    74880013
         SPACE 1                                                        74910013
LISTPD   DC    AL1(TRPSIP)             PRIMED DELIMITER TRIPLES         74940013
         DC    AL1(TRFUNP)                                              74970013
         DC    AL1(TRARYP)                                              75000013
         DC    AL1(TRITDP)                                              75030013
         DC    X'00'                                                    75060013
         SPACE 1                                                        75090013
LISTCV   DC    AL1(TRCV)               CV                               75120013
         DC    X'00'                                                    75150013
         SPACE 1                                                        75180013
LISTSC   DC    AL1(TRARYP)             SUBSCRIPT PRIMED AND ARGUMENTS   75210013
         DC    AL1(TRCOM)                                               75240013
         DC    X'00'                                                    75270013
         SPACE 1                                                        75300013
LISTPV   DC    AL1(TRALAS)             PSEUDO-VARIABLE' AND ARGUMENTS   75330013
         DC    AL1(TRIGNR)                                              75360013
         DC    AL1(TRPSIP)                                              75390013
         DC    AL1(TRFUNP)                                              75420013
         DC    X'00'                                                    75450013
         SPACE 2                                                        75480013
*              ERROR ENTRY CODES                                        75510013
         SPACE 1                                                        75540013
         DS    0F                                                       75570013
ERID01   DC    X'00'                                                    75600013
         DC    AL2(ERCD01)                                              75630013
         DC    AL1(AERROR)                                              75660013
ERID03   DC    X'00'                                                    75690013
         DC    AL2(ERCD03)                                              75720013
         DC    AL1(AERROR)                                              75750013
ERID04   DC    X'00'                                                    75780013
         DC    AL2(ERCD04)                                              75810013
         DC    AL1(SERROR+STATNO)                                       75840013
ERID05   DC    X'00'                                                    75870013
         DC    AL2(ERCD05)                                              75900013
         DC    AL1(AERROR+STATNO)                                       75930013
ERID06   DC    X'00'                                                    75960013
         DC    AL2(ERCD06)                                              75990013
         DC    AL1(SERROR+STATNO)                                       76020013
ERID07   DC    X'00'                                                    76050013
         DC    AL2(ERCD07)                                              76080013
         DC    AL1(SERROR+STATNO)                                       76110013
         SPACE 1                                                        76140013
STATNO   EQU   X'40'                   STATEMENT NUMBER REQUIRED        76170013
SERROR   EQU   X'04'                   FLAGS FOR SERIOUS ERROR          76200013
AERROR   EQU   X'00'                   FLAGS FOR CATASTROPHIC ERROR     76230013
ERCD01   EQU   X'0621'                 SYMBOLIC REGISTER NUMBER MAX     76260013
*                                    EXCEEDED                           76290013
ERCD03   EQU   X'0623'                 SCRATCH CORE EXHAUSTED           76320013
ERCD04   EQU   X'0624'                 ARRAY/STRUCTURE SHOULD BE SCALAR 76350013
ERCD05   EQU   X'0651'                 ERROR RETURN FROM SCAN           76380013
ERCD06   EQU   X'0626'                 INVALID LOOP CONTROL EXPRESSION  76410013
*                                    OR CONTROL VARIABLE SUBSCRIPT IN-  76440013
ERCD07   EQU   X'0627'                 INVALID PSEUDO-VAR ARGUMENT      76470013
         SPACE 2                                                        76500013
*              DICTIONARY ENTRY SKELETONS                               76530013
         SPACE 1                                                        76560013
SD01     DC    AL1(DRCON)                                               76590013
         DC    AL2(15)                 LENGTH=15                        76620013
         DC    AL2(0)                  CHAIN FIELD                      76650013
         DC    X'88018001'             DATA-BYTE,PRECISION,SCALE,TYPE   76680013
         DC    5X'00'                                                   76710013
         DC    X'00'                   INTERNALLY CODED BCD ZERO        76740013
         SPACE 1                                                        76770013
SD02     DC    AL1(DRTEMP)             SCALAR TEMPORARY                 76800013
         DC    XL20'00'                FIXED INFORMATION                76830013
         DC    XL4'00'                 SECOND OFFSET SLOT               76860013
DECTL    EQU   *-SD02                  OFFSET OF CONTROLLED REFERENCE   76890013
SD02C1   DC    XL2'00'                 LEVEL/COUNT IF NOT CONTROL'D     76920013
SD02L1   EQU   *-SD02                  LENGTH OF ENTRY IF NOT CONTROL'D 76950013
SD02C2   DC    XL2'00'                 LEVEL/COUNT IF CONTROLLED        76980013
SD02L2   EQU   *-SD02                  LENGTH OF ENTRY IF CONTROLLED    77010013
         ORG   SD02+DEVAR                                               77040013
         DC    AL1(VARSEC)             SECOND OFFSET SLOT BIT           77070013
         ORG   SD02+SD02L2                                              77100013
         DC    XL16'00'                                                 77130013
         SPACE 2                                                        77160013
*              TRIPLE SKELETONS                                         77190013
         SPACE 1                                                        77220013
ST00     DC    AL1(TRGOLN)             GO TO LABEL NUMBER               77250013
         DC    AL2(0)                                                   77280013
ST002    DC    AL2(0)                LOCATION FIELD                     77310013
         SPACE 1                                                        77340013
ST02     DC    AL1(TRCLN2)             COMPILER LABEL NUMBER TYPE 2     77370013
         DC    AL2(0)                                                   77400013
ST022    DC    AL2(0)                                                   77430013
         SPACE 1                                                        77460013
ST01     DC    AL1(TRASGN)             ASSIGN                           77490013
ST011    DC    AL2(0)                                                   77520013
ST012    DC    AL2(0)                                                   77550013
         SPACE 1                                                        77580013
ST03     DC    AL1(TRPLUS)             +                                77610013
ST031    DC    AL2(0)                                                   77640013
ST032    DC    AL2(0)                                                   77670013
         SPACE 1                                                        77700013
ST04     DC    AL1(TRASGN)             ASSIGN                           77730013
ST041    DC    AL2(0)                                                   77760013
         DC    AL2(0)                                                   77790013
         SPACE 1                                                        77820013
ST05     DC    AL1(TRGORE)                                              77850013
ST051    DC    AL2(0)                                                   77880013
ST052    DC    AL2(0)                                                   77910013
         SPACE 1                                                        77940013
ST06     DC    AL1(TRIF)                                                77970013
ST061    DC    AL2(0)                                                   78000013
         DC    AL2(0)                                                   78030013
         SPACE 1                                                        78060013
ST07     DC    AL1(0)                  OPERATOR INSERTED                78090013
ST071    DC    AL2(0)                                                   78120013
ST072    DC    AL2(0)                                                   78150013
         SPACE 1                                                        78180013
ST08     DC    AL1(TRIF)                                                78210013
ST081    DC    AL2(0)                                                   78240013
ST082    DC    AL2(0)                                                   78270013
         SPACE 1                                                        78300013
ST09     DC    AL1(TRGOLN)             GO TO LABEL NUMBER               78330013
         DC    AL2(0)                                                   78360013
ST092    DC    AL2(0)                                                   78390013
         SPACE 1                                                        78420013
ST11     DC    AL1(TRFREE)             FREE                             78450013
         DC    AL2(0)                                                   78480013
ST112    DC    AL2(0)                                                   78510013
         SPACE 1                                                        78540013
ST12     DC    AL1(TRGOLN)             GO TO LABEL NUMBER               78570013
         DC    AL2(0)                                                   78600013
ST122    DC    AL2(0)                  LABEL NUMBER                     78630013
         SPACE 1                                                        78660013
ST13     DC    AL1(TRCLN1)             COMPILER LABEL NUMBER TYPE 1     78690013
         DC    AL2(0)                                                   78720013
ST132    DC    AL2(0)                  LABEL NUMBER                     78750013
         SPACE 1                                                        78780013
ST15     DC    AL1(TRALAS)             ALLOCATE AND ASSIGN              78810013
         DC    AL2(0)                                                   78840013
ST152    DC    AL2(0)                                                   78870013
         SPACE 1                                                        78900013
*              TRIPLES USED TO ASSIGN AN ITERATION COUNT TO REGISTER    78930013
*        14 FOR FORMAT REPLICATIONS.                                    78960013
ST16     DC    AL1(TRNULF)             NULL FUNCTION                    78990013
         DC    X'00000000'                                              79020013
         DC    AL1(TRTMPD)             DEFAULT BINARY INTEGER IN        79050013
         DC    X'808C0F80'           REGISTER BY VALUE.                 79080013
         DC    AL1(TRTMPD)                                              79110013
         DC    AL2(14)                                                  79140013
         DC    X'0000'                                                  79170013
         SPACE 1                                                        79200013
ST17     DC    AL1(TRASGN)                                              79230013
         DC    AL2(0)                                                   79260013
ST171    DC    AL2(0)                  'TO' EXPRESSION                  79290013
         SPACE 1                                                        79296015
ST18     DC    AL1(TRITDO)             ITDO 14 TRIPLE SIGNALLING        79302015
         DC    AL2(0)                REGISTER USE TO LS                 79308015
         DC    AL2(14)                                                  79314015
         SPACE 2                                                        79320013
*              PSEUDO-CODE SKELETONS                                    79350013
         SPACE 1                                                        79380013
SP00     DC    AL1(PSBCR)              BCR B,LOCN REGISTER              79410013
         DC    AL2(15)                                                  79440013
SP002    DC    AL2(0)                  LOCATION REGISTER FIELD          79470013
         SPACE 1                                                        79500013
SP01     DC    AL1(PSDROP)             DROP REGISTER                    79530013
SP011    DC    AL2(0)                  REGISTER FIELD                   79560013
         SPACE 1                                                        79590013
SP02     DC    AL1(PSLAP)              LA'                              79620013
SP021    DC    AL2(0)                                                   79650013
SP022    DC    AL2(0)                                                   79680013
         SPACE 1                                                        79710013
SP03     DC    AL1(PSERR)              ERROR CODE                       79740013
         SPACE 1                                                        79770013
SP04     DC    AL1(PSITDO)             ITDO                             79800013
         SPACE 1                                                        79830013
SP05     DC    AL1(PSITDP)             ITDO'                            79860013
         SPACE 1                                                        79890013
*              USING LIST/ SINLIST USED FOR FORMAT REPLICATION          79920013
SP06     DC    AL1(0)                  USSLD/SINLST                     79950013
         DC    X'80'                   NON-MACHINE INST. FLAG           79980013
         DC    AL1(SP06L)                                               80010013
         DC    AL2(1)                  REGISTERS 1,2 AND 7              80040013
         DC    AL2(2)                                                   80070013
         DC    AL2(7)                                                   80100013
SP06L    EQU   *-SP06                                                   80130013
         SPACE 1                                                        80160013
*              TEST CODE FOR VALUE IN FORMAT REPLICATION.               80190013
SP07     DC    AL1(PSLTR)              LTR 14,14                        80220013
         DC    AL2(14)                                                  80250013
         DC    AL2(14)                                                  80280013
         SPACE 1                                                        80310013
         DC    AL1(PSBC)               BNP END-OF-LOOP                  80340013
         DC    X'400D'                                                  80370013
SP071    DC    AL2(0)                                                   80400013
SP07L    EQU   *-SP07                                                   80430013
         SPACE 1                                                        80460013
*              STORE COUNTER IN CONTROL TEMPORARY                       80490013
SP08     DC    AL1(PSST)               ST 14,CV                         80520013
         DC    AL2(14)                                                  80550013
SP081    DC    AL2(0)                                                   80580013
         SPACE 1                                                        80582015
         DC    AL1(PSC)                C 14,TO                          80584015
         DC    AL2(14)                                                  80586015
SP082    DC    AL2(0)                                                   80588015
         SPACE 1                                                        80590015
         DC    AL1(PSBC)               BC BNH,LOOP (BY +VE)             80592015
         DC    X'40'                      BNL,LOOP (BY -VE)             80594015
SP083    DC    X'00'                                                    80596015
SP084    DC    AL2(0)                                                   80598015
SP08L    EQU   *-SP08                                                   80600015
         SPACE 1                                                        80610013
*              RESTORE COUNTER AND COUNT, USED AT END OF FORMAT         80640013
*        REPLICATION LOOP                                               80670013
SP09     DC    AL1(PSL)                L 14,CV                          80700013
         DC    AL2(14)                                                  80730013
SP091    DC    AL2(0)                                                   80760013
         SPACE 1                                                        80790013
         DC    AL1(PSBCTP)             BCT 14,LOOP                      80820013
         DC    AL2(14)                                                  80850013
SP092    DC    AL2(0)                                                   80880013
SP09L    EQU   *-SP09                                                   80910013
         SPACE 1                                                        80911015
*              BUMP CONTROL VARIABLE (OPTIMIZED LOOP)                   80912015
SP10     DC    AL1(PSL)                L 14,CV                          80913015
         DC    AL2(14)                                                  80914015
SP101    DC    AL2(0)                                                   80915015
         SPACE 1                                                        80916015
         DC    AL1(PSA)                A 14,BY                          80917015
         DC    AL2(14)                                                  80918015
SP102    DC    AL2(0)                                                   80919015
SP10L    EQU   *-SP10                                                   80920015
         SPACE 1                                                        80921015
*              SET INITIAL VALUE OF CONTROL VARIABLE (OPTIMIZED LOOP)   80922015
SP11     DC    AL1(PSL)                L 14,FROM                        80923015
         DC    AL2(14)                                                  80924015
SP111    DC    AL2(0)                                                   80925015
         SPACE 1                                                        80926015
         DC    AL1(PSBC)               BC B,LABI                        80927015
         DC    X'400F'                                                  80928015
SP112    DC    AL2(0)                                                   80929015
SP11L    EQU   *-SP11                                                   80930015
         SPACE 2                                                        80940013
*              WORKSPACE AND SAVE AREAS                                 80970013
         SPACE 1                                                        81000013
SCRCUR   EQU   WORKSP                  ADDRESS OF CURRENT SCRATCH BLOCK 81030013
WSRR01   EQU   SCRCUR+4                RR SAVE 1                        81060013
WSRR02   EQU   WSRR01+4                        2                        81090013
WSRR03   EQU   WSRR02+4                        3                        81120013
WSRR04   EQU   WSRR03+4                        4                        81150013
WSRR05   EQU   WSRR04+4                        5                        81180013
WSRR06   EQU   WSRR05+4                        6                        81210013
WSTXRF   EQU   WSRR06+4                TEXT REFERENCE SAVE SLOT         81240013
LI1      EQU   WSTXRF+4                LABEL 1                          81270013
LI2      EQU   LI1+2                         2                          81300013
LI3      EQU   LI2+2                         3                          81330013
LI4      EQU   LI3+2                         4                          81360013
LEVEL    EQU   LI4+2                   LEVEL COUNT USED DURING CVSCAN   81390013
WSDREF   EQU   LEVEL+2                 DICT REF RETURNED BY TESTOP      81420013
WSPICT   EQU   WSDREF+2                PICTURE REF                      81430016
         END   IEMLG                                                    81450013
