LS       TITLE 'IEMLS,EXPRESSION EVALUATION,PSEUDO CODE GENR,PL/I F.'   00040015
         SPACE 3                                                        00080015
*              STATUS - CHANGE LEVEL 0.                                 00120015
*     RELEASE 17 CONTAINS A FIX FOR APAR 14876                          00140017
         SPACE 3                                                        00160015
*3262 532800                                                      14418 00180016
* R18  383700 390200,384000,*                                     18388 00190001
*  R19   464800                                                   27134 00195019
* ###  268960                   ### - SEE ID#                     38172 00197020
*              FUNCTIONS - (1) CONTROL TEXT SCAN AND BRANCH TO PROCESS- 00200015
*        ING ROUTINES.AT END OF TEXT,RELEASE BLOCKS AND CORE AND BRANCH 00240015
*        TO NEXT BLOCK.                                                 00280015
*                          (2)                                          00320015
*                          (3) PROCESS STRING OPERATORS.                00360015
*                          (4) PROCESS TRIPLES WITH '00' OPERANDS.      00400015
*                          (5) PROCESS SUBSCRIPT TRIPLES.               00440015
*                          (6) PROCESS CALL,FUNCTION,PSEUDO-VARIABLE    00480015
*        AND ASSOCIATED TRIPLES.                                        00520015
*                          (7) GENERATE PSEUDO-CODE FOR ARITHMETIC      00560015
*        OPERATORS WITH PACKED DECIMAL OPERANDS.                        00600015
*                          (8) OBTAIN SYMBOLIC UNASSIGNED REGISTERS.    00640015
*                          (9) UTILITY SUBROUTINES 'DICDES','CONVT',    00680015
*        'MOVEPC','STALRG','ASSIGN','CPLEX','TSTOD','SWOP'.             00720015
         SPACE 3                                                        00760015
*              ENTRY POINTS - (1) AT 'LB0','LSUB1','NXTPL' IN TEXT SCAN 00800015
*        ROUTINE TO CONTINUE WITH SCAN. USED BY ALL BLOCKS.             00840015
*                             (2)                                       00880015
*                             (3) AT 'STRING' TO PROCESS CONCAT AND     00920015
*        STRING COMPARE OPERATORS. USED BY BLOCK LT.                    00960015
*                             (4) AT 'GENRPD' TO GENERATE PSEUDO-CODE   01000015
*        FOR ARITHMETIC OPERATORS WITH PACKED DECIMAL OPERANDS. USED BY 01040015
*        BLOCK LT.                                                      01080015
*                             (5) AT 'DICDES' FOR SUBROUTINE TO         01120015
*        CONSTRUCT DESCRIPTION FROM DICTIONARY ENTRY. USED BY BLOCKS LT 01160015
*        AND LU.                                                        01200015
*                             (6) AT 'CONVT' AND 'CONST' FOR SUBROUTINE 01240015
*        TO CONVERT TYPES AND SET CONSTANT DICTIONARY ENTRIES. USED BY  01280015
*        BLOCK LT.                                                      01320015
*                             (7) AT 'MOVEPC' FOR SUBROUTINE TO MOVE    01360015
*        PSEUDO-CODE TO OUTPUT TEXT. USED BY BLOCKS LT,LU.              01400015
*                             (8) AT 'STALRG' FOR SUBROUTINE TO STORE   01440015
*        ALL ARITHMETIC REGISTERS IN USE. USED BY BLOCKS LT,LU.         01480015
*                             (9) AT 'ASSIGN' FOR SUBROUTINE TO         01520015
*        GENERATE ASSIGN TRIPLES AND TMPD'S. USED BY BLOCK LT.          01560015
*                            (10) AT 'CPLEX','TSTOD1','TSTOD2' FOR      01600015
*        SUBROUTINES FOR COMPLEX ARITHMETIC.USED BY BLOCK LT.           01640015
*                            (11) AT 'SWOP' FOR SUBROUTINE TO INTER-    01680015
*        CHANGE OPERANDS. USED BY BLOCKS LT,LU.                         01720015
         SPACE 3                                                        01760015
*              INPUT - TEXT FROM PREVIOUS PHASE IN THE FORM OF TRIPLES  01800015
*        AND PSEUDO-CODE. DICTIONARY ENTRIES FOR THE DICTIONARY REFER-  01840015
*        ENCES IN THE TRIPLES EXAMINED.                                 01880015
         SPACE 3                                                        01920015
*              OUTPUT - TEXT IN FORM OF TRIPLES AND PSEUDO-CODE. NEW    01960015
*        DICTIONARY ENTRIES MAY BE MADE AND OLD ENTRIES MAY BE MODIFIED 02000015
         SPACE 3                                                        02040015
*                                                                       02080015
*              EXTERNAL ROUTINES (1) 'ZDRFAB' IN CONTROL PHASE TO       02120015
*        CONVERT SYMBOLIC DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.     02160015
*                                (2) 'ZDICRF' IN CONTROL PHASE TO       02200015
*        CONSTRUCT A NEW DICTIONARY ENTRY.                              02240015
*                                (3)                                    02280015
*                                (4)                                    02320015
*                                (5) 'ZURC' IN CONTROL PHASE TO RELEASE 02360015
*        SCRATCH CORE.                                                  02400015
*                                (6) 'REQEST' IN CONTROL PHASE TO MARK  02440015
*        BLOCK WANTED OR NOT-WANTED.                                    02480015
*                                (7) 'SCINIT','SC1','SC2','SC3','SC5'   02520015
*        IN BLOCK LA TO SCAN TEXT.                                      02560015
*                                (8) 'MV3','MV3A' IN BLOCK LA TO MOVE   02600015
*        TRIPLES AND PSEUDO-CODE TO OUTPUT TEXT.                        02640015
*                                (9) 'ADDSTK','RELSTK','RLSTK1','ITEM2' 02680015
*        IN BLOCK LT TO MANIPULATE TEMPORARY RESULT STACKS.             02720015
*                               (10) 'GETFR','GETGR' IN BLOCK LT TO GET 02760015
*        ARITHMETIC REGISTERS.                                          02800015
*                               (11) 'STGENR','STREG2' IN BLOCK LT TO   02840015
*        STORE ARITHMETIC REGISTERS.                                    02880015
*                               (12) 'STREG4' IN BLOCK LT TO GET        02920015
*        ALIGNED TEMPORARY WORKSPACE.                                   02960015
*                               (13) 'GETADX','GETADS','GETAS1' IN      03000015
*        BLOCK LT TO CONSTRUCT ADDRESSES FOR PSEUDO-CODE.               03040015
*                               (14) 'ERROR' IN BLOCK LT FOR ERRORS.    03080015
*                                                                       03120015
*                               (15) 'SETCPX' IN BLOCK LU TO INITIALISE 03160015
*        FOR COMPLEX ARITHMETIC.                                        03200015
         SPACE 3                                                        03240015
*              EXITS-NORMAL (1) 'RLSCTL' IN CONTROL PHASE TO RELEASE    03280015
*        BLOCKS AND BRANCH TO NEXT BLOCK. USED AT END OF TEXT.          03320015
*                           (2) 'ARITH' IN BLOCK LT TO PROCESS          03360015
*        ARITHMETIC OPERATORS.                                          03400015
*                           (3) 'RESLT1','RESLT2' IN BLOCK LT TO FINISH 03440015
*        PROCESSING ARITHMETIC OPERATORS. USED AFTER GENERATED PACKED-  03480015
*        DECIMAL PSEUDO-CODE.                                           03520015
         SPACE 3                                                        03560015
*              EXIT-ERROR - 'CERROR' IN BLOCK LT TO ABORT AFTER A       03600015
*        TERMINAL COMPILER ERROR.                                       03640015
         SPACE 3                                                        03680015
*              WORK AREA - 4K OF SCRATCH CORE IS USED. THE FIRST 1K IS  03720015
*        USED FOR CONSTANTS SET UP BY BLOCK LR. THE REMAINDER IS USED   03760015
*        WORKSPACE AND STACKS.                                          03800015
         SPACE 3                                                        03840015
*              ATTRIBUTES - THIS BLOCK IS NOT READ-ONLY AND NOT         03880015
*        RE-ENTRANT.                                                    03920015
         SPACE 3                                                        03960015
*              NOTES - THIS BLOCK REQUIRES NO MODIFICATION AS A RESULT  04000015
*        OF CHANGES IN THE INTERNAL REPRESENTATION OF EXTERNAL          04040015
*        GRAPHICS.                                                      04080015
         EJECT                                                          04120015
IEMLS    START 0                                                        04160015
*                       ASSEMBLY CONSTANTS                              04200015
*                       GENERAL REGISTERS.                              04240015
G0       EQU   0                       WORKING                 SCRATCH  04280015
IP       EQU   1                       INPUT POINTER           RESERVED 04320015
TRTBSE   EQU   2                       TRANSLATE RESULT        SCRATCH  04360015
DSR      EQU   2                       DESCRIPTION POINTER.             04400015
PAR      EQU   3                       SCAN PARAMETER BASE              04440015
WSR      EQU   3                       WORKSPACE BASE                   04480015
GRN      EQU   4                       ARG FOR RELEASE STACK            04520015
G1       EQU   5                       SCRATCH WORKING REGISTER         04560015
STR      EQU   6                       STACK POINTER, SCRATCH POINTER   04600015
PCR      EQU   7                       PC BUFFER POINTER                04640015
OP       EQU   8                       OUTPUT POINTER                   04680015
LUBASE   EQU   8                       BLOCK LU BASE                    04720015
LTBASE   EQU   9                       BLOCK LT BASE                    04760015
LSBASE   EQU   10                      BLOCK LS BASE                    04800015
CTVR     EQU   11                      CONTROL TRANSFER VECTOR BASE     04840015
SCBASE   EQU   12                      SCAN PHASE BASE                  04880015
DICR     EQU   13                      DICTIONARY COMMON BASE           04920015
LR       EQU   14                      LINK, RETURN                     04960015
RR       EQU   14                      LINK, RETURN                     05000015
BR       EQU   15                      BRANCH                           05040015
*                       MASKS FOR BRANCH ON CONDITION.                  05080015
*              INSTRUCTION TYPE -      COMPARISON,ARITHMETIC,MASK TEST  05120015
NOP      EQU   0                       NOP.                             05160015
BO       EQU   1                           --    ,OVERFLOW  ,ALL ONES   05200015
BH       EQU   2                       HIGH      ,PLUS      ,    --     05240015
BL       EQU   4                       LOW       ,MINUS     ,MIXED 0-1  05280015
BNE      EQU   7                       NOT EQUAL ,NOT ZERO  ,NOT ALL 0  05320015
BZ       EQU   8                       EQUAL     ,ZERO      ,ALL ZEROS  05360015
BE       EQU   8                                                        05400015
BNL      EQU   11                      NOT LOW   ,NOT MINUS ,NOT MIXED  05440015
BN1      EQU   12                          --    ,    --    ,NOT ALL 1  05480015
BNH      EQU   13                      NOT HIGH  ,NOT PLUS  ,    --     05520015
B        EQU   15                      UNCONDITIONAL.                   05560015
*              TRIPLE LAYOUT - USUALLY BASED ON IR                      05600015
TPOPN    EQU   0                       OPERATOR    - 1 BYTE             05640015
TPOD1    EQU   1                       1ST OPERAND - 2 BYTES            05680015
TPOD2    EQU   3                       2ND OPERAND - 2 BYTES            05720015
*                       DESCRIPTION ITEM LAYOUT- OFFSETS FROM START     05760015
DESFLG   EQU   0                       FLAG BYTE                        05800015
DESCDE   EQU   1                       CODE BYTE                        05840015
DESP     EQU   2                       PRECISION BYTE                   05880015
DESQ     EQU   3                       SCALE FACTOR BYTE                05920015
DESBSE   EQU   4                       BASE ADDRESS BYTES (2)           05960015
DESNDX   EQU   6                       NDX (INDEX) BYTES (2)            06000015
DESOFS   EQU   8                       OFS (OFFSET) BYTES (2)           06040015
DESLTH   EQU   10                      BYTE LENGTH FOR P-D  (2 BYTES)   06080015
DESTK    EQU   12                      TEMP STACK CODE                  06120015
ISTK     EQU   10                                                       06160015
TOTDES   EQU   14                      LENGTH OF FULL DESCRIPTION       06200015
*                       PSEUDO-CODE LAYOUT - RR,RX,RS,SI OPERATIONS.    06240015
PCSZ3    EQU   3                       SIZE OF 3 BYTE PC                06280015
PCSZ5    EQU   5                       SIZE OF 5 BYTE PC                06320015
PCOPN    EQU   0                       P-C OPERATION CODE               06360015
PCOD1    EQU   1                       P-C 1ST OPERAND                  06400015
PCOD2    EQU   3                       P-C 2ND OPERAND                  06440015
PCOSM    EQU   5                       P-C OFFSET MARKER CODE           06480015
PCOSM1   EQU   6                       P-C OFFSET MARKER FIELD 1        06520015
PCOSM2   EQU   8                       P-C OFFSET MARKER FIELD 2        06560015
*                       PSEUDO-CODE LAYOUT - SS OPERATIONS              06600015
PCSZ8    EQU   8                       SIZE OF 8 BYTE PC                06640015
PCSZ12   EQU   12                    SIZE OF 12 BYTE PC                 06680015
*PCOPN   EQU   0                       P-C OPERATION CODE               06720015
PCFLG    EQU   1                       P-C FLAG                         06760015
PCLNG    EQU   2                       BYTE LENGTH OF PC INSTRUCTION    06800015
PCF1     EQU   3                       LENGTH CODES - L OR  L1,L2       06840015
PCF2     EQU   4                       P-C 1ST OPERAND - DR/SYM REG     06880015
PCF3     EQU   6                       P-C 2ND OPERAND - DR/SYM REG     06920015
PCF4     EQU   8                       P-C 1ST OFFSET                   06960015
PCF5     EQU   10                      P-C 2ND OFFSET                   07000015
*              LAYOUT OF DICTIONARY ENTRY FOR CONSTANT.                 07040015
DCFLG    EQU   0                       FLAG =X'88' FOR CONSTANT         07080015
DCLNG    EQU   1                       TOTAL LENGTH                     07120015
DCCHN    EQU   3                       CONSTANT CHAIN                   07160015
DCDED1   EQU   5                       APPARENT DED (3 BYTES)           07200015
DCTYP    EQU   8                       TYPE                             07240015
DCDED2   EQU   9                       REQUIRED DED                     07280015
DCINIT   EQU   12                      INITIAL VALUE BYTES              07320015
DCVAL    EQU   14                      VALUE OF CONSTANT                07360015
*              LAYOUT OF DICT ENTRY FOR TEMP SDV                        07400015
DDVOFS   EQU   5                       OFFSET OF STRING IN TEMP STACK   07440015
DDVLNG   EQU   10                      LENGTH OF STRING                 07480015
*              LAYOUT OF DICT ENTRY FOR ENTRY TYPE 1                    07520015
DE1AUT   EQU   11                      START OF AUTO CHAIN FOR BLOCK    07560015
*              LAYOUT OF DICT ENTRY FOR BUILT-IN FUNCTION.              07600015
BICODE   EQU   8                       BUILT-IN FUNCTION CODE           07640015
ILF      EQU   X'92'                   1ST IN-LINE FUNCTION             07680015
*              LAYOUT OF DICT ENTRY FOR VARIABLE                        07720015
DEFLG    EQU   0                       FLAG BYTE                        07760015
DELNG    EQU   1                       LENGTH OF ENTRY                  07800015
DECHN    EQU   3                       AUTOMATIC CHAIN                  07840015
DEDED    EQU   8                       ACTUAL DED IN DED2 DICT ENTRY    07880015
DEOTH3   EQU   13                      'OTHER 3' CODE BYTE              07920015
DEOTH4   EQU   14                      'OTHER 4' CODE BYTE              07960015
DEDATA   EQU   15                      DATA BYTES                       08000015
DESYMB   EQU   19                      SYMBOL SLOT                      08040015
*              LAYOUT OF DICT ENTRY FOR PICTURE.                        08080015
DEPICW   EQU   11                      PICTURE DICT ENTRY-APPARENT LNTH 08120015
*                                                                       08160015
VARDE    EQU   X'0F'                   MASK FOR VARIABLE DICT ENTRY     08200015
STRDE    EQU   X'0E'                   MASK FOR STRUCTURE ITEM          08240015
DIMDE    EQU   X'10'                   MASK FOR ARRAY DICT ENTRY        08280015
LABDE    EQU   X'08'                   MASK FOR LABEL DICT ENTRY        08320015
FILDE    EQU   X'04'                   MASK FOR FILE DICT ENTRY         08360015
TSKDE    EQU   X'01'                   MASK FOR TASK DICT ENTRY         08400015
*              REGISTER DESCRIPTION BLOCKS (4 FLOATING, 2 GENERAL )     08440015
RGBLSZ   EQU   4                       SIZE OF REGISTER BLOCK           08480015
RGD1     EQU   0                       CODE BYTE- = 0 IF NOT IN USE,    08520015
*                                             AND = 1,2,3,4 IF IN USE.  08560015
RGD2     EQU   1                       ADDRESS OF CORRESPONDING ITEM    08600015
*                                      IN DESCRIPTION STACK.            08640015
*                       PSEUDO-CODE OPERATION CODES                     08680015
LC       EQU   X'00'                   BASIC LOAD COMPLEMENT            08720015
AND      EQU   X'05'                   BASIC AND                        08760015
DROP     EQU   X'06'                   DROP                             08800015
EQU      EQU   X'07'                   EQU                              08840015
L        EQU   X'08'                   BASIC LOAD OPERATION             08880015
CPR      EQU   X'09'                   BASIC COMPARE                    08920015
ADD      EQU   X'0A'                   BASIC ADD                        08960015
SUB      EQU   X'0B'                   BASIC SUBTRACT                   09000015
MULT     EQU   X'0C'                   BASIC MULTIPLY                   09040015
DIV      EQU   X'0D'                   BASIC DIVIDE                     09080015
IPRM     EQU   X'0D'                   IPRM                             09120015
OSM1     EQU   X'10'                   OFFSET MARKER 1 (LITERAL ONLY)   09160015
OSM2     EQU   X'11'                   OFFSET MARKER 2 (REGISTER ONLY)  09200015
BUY      EQU   X'16'                   BUY                              09240015
IPRMD    EQU   X'1D'                   IPRM'                            09280015
NR       EQU   X'45'                   NR                               09320015
SR       EQU   SUB+X'40'               SR                               09360015
BALR     EQU   X'4F'                   BALR                             09400015
SPM      EQU   X'51'                   SPM                              09440015
LTR      EQU   X'52'                   LTR                              09480015
LTER     EQU   X'53'                   LTER                             09520015
LTDR     EQU   X'54'                   LTDR                             09560015
SLDA     EQU   X'72'                   SLDA                             09600015
SRDA     EQU   X'76'                   SRDA                             09640015
STM      EQU   X'79'                   STORE MULTIPLE                   09680015
BC       EQU   X'81'                   BC                               09720015
LH       EQU   X'90'                   LH                               09760015
CH       EQU   X'91'                   CH                               09800015
AH       EQU   X'92'                   AH                               09840015
STH      EQU   X'95'                   STH                              09880015
STD      EQU   X'97'                   STORE LONG FLOAT                 09920015
LA       EQU   X'A0'                   LA OPERATION CODE                09960015
ST       EQU   X'A5'                   STORE GENERAL REGISTER           10000015
STE      EQU   X'A7'                   STORE SHORT FLOAT                10040015
MVI      EQU   X'B1'                   MVI                              10080015
XI       EQU   X'B6'                   XI                               10120015
OSM3     EQU   X'BD'                   OFFSET MARKER 3 (LITERAL+REG)    10160015
CLC      EQU   X'C0'                   CLC                              10200015
MVC      EQU   X'C1'                   MVC                              10240015
MVZ      EQU   X'C4'                   MVZ                              10280015
ZAP      EQU   X'C8'                   ZAP                              10320015
CONV     EQU   X'D6'                   CONVERT MACRO                    10360015
MSA      EQU   X'28'                   ASSIGN WITHOUT DROPPING SOURCE   10400015
NOPTP    EQU   X'3F'                   NOP TRIPLE                       10420001
ASSGN    EQU   X'47'                   ASSIGN TRIPLE                    10440015
MASSGN   EQU   X'57'                   MULTIPLE ASSIGN                  10480015
TMPD     EQU   X'58'                   TEMP DESCRIPTION TRIPLE          10520015
LEFT     EQU   X'68'                   TMPD FOR LABEL,EVENT,FILE,TASK   10560015
OFS      EQU   X'78'                   OFFSET TRIPLE                    10580001
FCNP     EQU   X'7C'                   FUNCTION' TRIPLE                 10600015
NFUNC    EQU   X'2F'                   NULL FUNCTION TRIPLE             10640015
ITDO     EQU   X'B7'                    ITDO TRIPLE                     10660015
FXB      EQU   X'00'                   MODIFIER FOR FIXED BINARY        10680015
FLD      EQU   X'10'                   MODIFIER FOR LONG FLOAT          10720015
FLE      EQU   X'20'                   MODIFIER FOR SHORT FLOAT         10760015
PKD      EQU   X'C0'                   MODIFIER FOR PACKED DECIMAL      10800015
DCDATA   EQU   15                      DATA BYTES FOR VAR IN DICT       10840015
EOP2OP   EQU   72                      EOP2 OP CODE                     10880015
CSDECP   EQU   5                       FIX DEC PRECISN OF CONVERTED CS  10920015
PLUSZ    EQU   X'C0'                   PLUS ZONE                        10960015
RA       EQU   1                       1ST IMPLICIT REGISTER            11000015
RB       EQU   2                       2ND IMPLICIT REGISTER            11040015
RC       EQU   3                       3RD IMPLICIT REGISTER            11080015
RD       EQU   4                       4TH IMPLICIT REGISTER            11120015
RE       EQU   5                       5TH IMPLICIT REGISTER            11160015
RRE      EQU   14                      EXECUTION RETURN REGISTER        11200015
BRE      EQU   15                      EXECUTION BRANCH REGISTER        11240015
         SPACE 3                                                        11280015
         USING *,LSBASE                                                 11320015
         USING BGWS,WSR                                                 11360015
         USING D,DICR                                                   11400015
         USING Z,CTVR                                                   11440015
         USING SC,SCBASE                                                11480015
         USING LT,LTBASE                                                11520015
         USING LU,LUBASE                                                11560015
NAME     DC    C'LS'                   BLOCK NAME                       11600015
*              TRANSFER VECTORS                                         11640015
         BC    B,NXTPL                                                  11680015
         BC    B,DICDES                                                 11720015
         BC    B,CONVT                                                  11760015
         BC    B,CONST                                                  11800015
         BC    B,LSUB1                                                  11840015
         BC    B,MOVEPC                                                 11880015
         BC    B,STRING                                                 11920015
         BC    B,CPLEX                                                  11960015
         BC    B,TSTOD1                                                 12000015
         BC    B,TSTOD2                                                 12040015
         BC    B,GENRPD                                                 12080015
         BC    B,LB0                                                    12120015
         BC    B,SBGTNR                                                 12160015
         EJECT                                                          12200015
*              TEXT SCAN.                                               12240015
*                                                                       12280015
*              FUNCTION (1) CALL SCAN PHASE FOR NEXT TRIPLE OF INTEREST 12320015
*                       (2) BRANCH TO PROCESSING ROUTINE.               12360015
*                       (3) RELEASE BLOCKS LS,LT,LU AND SCRATCH CORE,   12400015
*        MARK BLOCKS LW,LX,MP AND GET NEXT PHASE.                       12440015
*                                                                       12480015
*              ENTRY POINT (1) 'LB0' TO START TO SCAN AND MOVE TEXT AT  12520015
*        THE TRIPLE ADDRESSED BY REGISTER IP.                           12560015
*                          (2) 'NXTPL' TO MOVE ANY PSEUDO-CODE TO THE   12600015
*        OUTPUT TEXT,SKIP THE CURRENT TRIPLE ADDRESSED BY REGISTER IP,  12640015
*        AND SCAN AND MOVE THE INPUT TEXT UP TO THE NEXT TRIPLE OF      12680015
*        INTEREST.                                                      12720015
*                          (3) 'LSUB1' TO MOVE THE CURRENT TRIPLE       12760015
*        ADDRESSED BY REGISTER IP TO THE OUTPUT TEXT,AND SCAN AND MOVE  12800015
*        THE INPUT TEXT UP TO THE NEXT TRIPLE OF INTEREST.              12840015
*                                                                       12880015
*              EXTERNAL ROUTINES (1) 'SC1' IN BLOCK LA TO GET NEXT      12920015
*        TRIPLE OF INTEREST STARTING AT CURRENT TRIPLE.                 12960015
*                                (2) 'SC2' IN BLOCK LA TO MOVE CURRENT  13000015
*        TRIPLE TO OUTPUT AND GET NEXT TRIPLE OF INTEREST.              13040015
*                                (3) 'SC3' IN BLOCK LA TO SKIP CURRENT  13080015
*        TRIPLE AND GET NEXT TRIPLE OF INTEREST.                        13120015
*                                (4) 'REQEST' IN CONTROL PHASE TO MARK  13160015
*        A BLOCK WANTED OR NOT-WANTED.                                  13200015
*                                (5) 'ZURC' IN CONTROL PHASE TO RELEASE 13240015
*        SCRATCH CORE.                                                  13280015
*                                (6) 'RLSCTL' IN CONTROL PHASE TO       13320015
*        RELEASE BLOCKS AND GO TO NEXT BLOCK.                           13360015
*                                (7) 'MOVEPC' IN BLOCK LS TO MOVE       13400015
*        PSEUDO-CODE TO THE OUTPUT TEXT.                                13440015
*                                                                       13480015
*              EXIT-NORMAL (1) TO 'ARITH' IN BLOCK LT FOR ARITHMETIC    13520015
*        OPERATORS.                                                     13560015
*                          (2) TO 'LZZ1','LZZ2','LZZ3' FOR TRIPLES      13600015
*        WHICH MIGHT USE A TEMPORARY RESULT.                            13640015
*                          (3) TO 'SUBSPT' FOR SUBSCRIPT TRIPLES.       13680015
*                          (4) TO 'BITSTR' FOR BIT STRING OPERATORS.    13720015
*                          (5) TO 'FUNCT' FOR FUNCTION AND PSEUDO-      13760015
*        VARIABLE TRIPLES.                                              13800015
*                          (6) TO 'CALLT' FOR CALL TRIPLES.             13840015
*                          (7) TO 'FCTP' FOR FUNCTION AND PSEUDO-       13880015
*        VARIABLE PRIMED TRIPLES.                                       13920015
*                          (8) TO 'FCTARG' FOR FUNCTION ARGUMENT TRIPLE 13960015
*                          (9) TO 'IGNT' FOR IGNORE TRIPLES.            14000015
*                         (10) TO 'PSI' FOR UMBRELLA TRIPLES.           14040015
*                         (11) TO NEXT PHASE AT END OF TEXT.            14080015
*                                                                       14120015
*              EXIT-ERROR - NONE.                                       14160015
*                                                                       14200015
*              NOTES -'OPCOD'CONTAINS THE TRANSLATED OPERATION CODE.    14240015
*                     WORK REGISTERS ARE NOT PRESERVED.                 14280015
         EJECT                                                          14320015
LB0      BAL   LR,SC1                  GET 1ST TRIPLE OF INTEREST       14360015
*                                                                       14400015
*              TRIPLE POINTED AT BY IP.                                 14440015
*              TRIPLE OPERATOR TRANSLATED INTO TRTBSE                   14480015
*                                                                       14520015
NEWTRP   STC   TRTBSE,OPCOD                                             14560015
         TM    OPCOD,X'80'             TEST BIT 0                       14600015
         BC    BZ,LB4                  BRANCH IF ZERO - END TYPE        14640015
         LA    PCR,BGPC                                                 14680015
         S     TRTBSE,F63                                               14720001
         BC    BNL,GENBR(TRTBSE)       GENERAL BRANCH IF NOT EXPRESSION 14760001
         NI    OPCOD,X'3F'             REMOVE BIT 0                     14800015
         XC    AMDBUF(4),AMDBUF        CLEAR ADD,MULT,DIV BUFFER        14840015
         BC    B,ARITH                                                  14880015
         SPACE 2                                                        15000015
*        GENERAL BRANCHES TO ROUTINES TO PROCESS NON-EXPRESSION TYPE    15040015
*        TRIPLES.                                                       15080015
*                                                                       15120015
GENBR    BC    B,EDT                   EDIT OR FORMAT LIST              15160015
         BC    B,LZZ1                  BOTH OPERANDS MAY BE '00'        15200015
         BC    B,LZZ2                  1ST OPERAND MAY BE '00'          15240015
         BC    B,LZZ3                  2ND OPERAND MAY BE '00'          15280015
         BC    B,LZZ3                  IF,WHILE',TT                     15320015
         BC    B,SUBSPT                SUBSCRIPT                        15360015
         BC    B,EOP2                  END OF PROGRAM                   15400015
         BC    B,FUNCT                 FUNCTION OR PSEUDO-VARIABLE      15440015
         BC    B,BITSTR                AND,OR,NOT - BIT STRINGS         15480015
         BC    B,FCTARG                FUNCTION ARGUMENT                15520015
         BC    B,FCTP                  FUNCTION,P-V PRIMED              15560015
         BC    B,CALLT                 CALL                             15600015
         BC    B,PSI                   UMBRELLA - ADD ANY DESCPT TO STK 15640015
         BC    B,CFCTP                 COMPILER FUNCTION PRIMED         15680015
         BC    B,IGNT                  IGNORE TRIPLE                    15720015
         BC    B,NXTPL1                REMOVE BUYCH,STAS,EDAS TRIPLES   15760001
         SPACE 2                                                        15800015
NXTPL    BAL   RR,MOVEPC               MOVE P-C TO OUTPUT               15840015
NXTPL1   BAL   RR,SC3                  GET NEXT TRIPLE OF INTEREST      15880015
         BC    B,NEWTRP                START TO PROCESS                 15920015
         SPACE 3                                                        15960015
*              EDIT OR FORMAT LIST.                                     16000015
EDT      LH    G0,SCWKS(PAR)                                            16040015
         ST    G0,CSTK                 BUMP WORKSPACE TO MAXIMUM        16080015
         SPACE 2                                                        16120015
LSUB1    BAL   RR,SC2                  MOVE CURRENT TRIPLE TO OUTPUT,   16160015
         BC    B,NEWTRP              GET NEXT AND START TO PROCESS.     16200015
         SPACE 3                                                        16240015
*              END OF STATEMENT OR PROGRAM.                             16280015
LB4      CLI   OPCOD,EOP2OP                                             16320015
         BC    BZ,EOP2                 BRANCH IF EOP2                   16360015
         LH    G0,SCWKSC(PAR)                                           16400015
         ST    G0,CSTK                 RESET SIZE OF CURRENT TEMP WKS   16440015
         BC    B,LB0                   RESCAN CURRENT TRIPLE.           16480015
EOP2     LA    BR,NAMBK5             MARK LW,LX WANTED                  16520015
         LA    G0,NAMBK4             NO NOT- WANTED BLOCKS              16560015
         CLI   GETLW,0                                                  16600015
         BC    BNE,LB5               BRANCH IF LW USED                  16640015
         LR    G0,BR                 MARK LW,LX NOT-WANTED              16680015
         LA    BR,NAMBK6             MARK MP WANTED                     16720015
         TM    ZFLAG3,X'04'                                             16760015
         BC    BO,LB5                BRANCH IF MP WANTED                16800015
         MVC   NAMBK5+6(4),NAMBK6     MOVE MP FROM NOT WANTED TO WANTED 16840015
LB5      STM   BR,G0,PAR1                                               16880015
         L     BR,REQEST                                                16920015
         BALR  RR,BR                                                    16960015
         LA    G0,1                                                     17000015
         ST    G0,PAR1                                                  17040015
         L     BR,ZURC                                                  17080015
         BALR  RR,BR                   RELEASE SCRATCH CORE             17120015
         LA    G0,NAMBK1                                                17160015
         ST    G0,PAR1                                                  17200015
         LA    G0,NAMBK7               PHASE LV                         17240015
         ST    G0,PAR2                                                  17280015
         L     BR,RLCTLX               RELEASE LS,LT,LU AND LOAD LV     17320015
         BCR   B,BR                                                     17360015
         EJECT                                                          17400015
*              STRING TRIPLES.                                          17440015
*                                                                       17480015
*              FUNCTION - TO INSERT SKELETON STRING DESCRIPTIONS IN THE 17520015
*        TEMPORARY STACK FOR STRING OPERATORS.                          17560015
*                                                                       17600015
*              ENTRY POINT (1) 'STRING' FOR CONCAT AND COMPARE          17640015
*        OPERATORS.                                                     17680015
*                          (2) 'BITSTR' FOR BIT STRING OPERATORS AND,   17720015
*        OR,NOT.                                                        17760015
*                                                                       17800015
*              EXTERNAL ROUTINES (1) 'STALRG' IN BLOCK LS TO STORE ANY  17840015
*        REGISTERS IN USE.                                              17880015
*                                (2) 'MOVEPC' IN BLOCK LS TO MOVE       17920015
*        PSEUDO-CODE TO THE OUTPUT TEXT.                                17960015
*                                                                       18000015
*              EXIT-NORMAL - TO 'LZZ1' TO BE PROCESSED AS TRIPLES WITH  18040015
*        2 POSSIBLY ZERO OPERANDS.                                      18080015
*                                                                       18120015
*              EXIT-ERROR - NONE.                                       18160015
*                                                                       18200015
STRING   TM    DEST+DESCDE,X'84'       CONCAT,COMPARE- TEST RESULT TYPE 18240015
         BC    BZ,BITSTR               BRANCH IF BOTH OPNDS BIT STRING  18280015
         MVI   DEST+DESCDE,X'2C'       SET RESULT TO CHAR STRING        18320015
         BC    B,LST1                                                   18360015
BITSTR   MVI   DEST+DESCDE,X'28'       SET RESULT TO BIT STRING         18400015
LST1     MVI   DEST+DESFLG,X'FF'       SET FOR STRING TEMP              18440015
         NI    OPCOD,X'BF'             SET OPCODE TO EXPRESSION TYPE    18480015
         BAL   RR,STALRG               STORE ALL REGISTERS              18520015
         BAL   RR,MOVEPC               MOVE ANY P-C TO OUTPUT           18560015
         MVI   GETLW,X'0F'             SET TO LOAD STRING PHASE LW      18600015
         EJECT                                                          18640015
*              TRIPLES WHICH MAY USE TEMPORARY RESULTS AS OPERANDS.     18680015
*                                                                       18720015
*              FUNCTION (1) TO INSERT TMPD OR LEFT TRIPLES DESCRIBING   18760015
*        TEMPORARY RESULTS WHEN AN OPERAND IS ZERO.                     18800015
*                       (2) TO RELEASE THESE TEMPORARIES FROM THE       18840015
*        TEMPORARY STACK.                                               18880015
*                                                                       18920015
*              ENTRY POINT (1) 'LZZ1' FOR TRIPLE WHICH MAY HAVE BOTH    18960015
*        OPERANDS ZERO.                                                 19000015
*                          (2) 'LZZ2' FOR TRIPLE WHICH MAY HAVE 1ST     19040015
*        OPERAND ZERO.                                                  19080015
*                          (3) 'LZZ3' FOR TRIPLE WHICH MAY HAVE 2ND     19120015
*        OPERAND ZERO.                                                  19160015
*                          (4) 'LZZ17' TO MOVE TRIPLE AND TMPD'S TO THE 19200015
*        OUTPUT TEXT.                                                   19240015
*                                                                       19280015
*              EXTERNAL ROUTINES (1) 'MV3A' IN BLOCK LA TO MOVE TRIPLES 19320015
*        TO THE OUTPUT TEXT.                                            19360015
*                                (2) 'RELSTK' IN BLOCK LT TO RELEASE    19400015
*        TEMPORARY RESULTS FROM THE STACK.                              19440015
*                                (3) 'ITEM2' IN BLOCK LT TO GET THE     19480015
*        ADDRESS OF THE 2ND ITEM IN THE TEMPORARY STACK.                19520015
*                                (4) 'SETMPD' TO GENERATE TMPD TRIPLES. 19560015
*                                                                       19600015
*              EXIT-NORMAL (1) TO 'NXTPL' TO MOVE PSEUDO-CODE AND GET   19640015
*        NEXT TRIPLE.                                                   19680015
*                          (2) TO 'NXTPL1' TO GET NEXT TRIPLE.          19720015
*                                                                       19760015
*              EXIT-ERROR - NONE.                                       19800015
*                                                                       19840015
*              NOTES - NO REGISTERS ARE PRESERVED.                      19880015
*                                                                       19920015
         EJECT                                                          19960015
LZZ1     LA    G0,2                    SET LOOP COUNT                   20000015
         BC    B,LZZ4                                                   20040015
LZZ2     LA    G0,1                    LOOP COUNT                       20080015
         LA    G1,TPOD1(IP)            ADDRESS OF 1ST OPERAND           20120015
         BC    B,LZZ5                                                   20160015
LZZ3     LA    G0,1                    LOOP COUNT                       20200015
LZZ4     LA    G1,TPOD2(IP)            ADDRESS OF 2ND OPERAND           20240015
LZZ5     SR    GRN,GRN                                                  20280015
         MVC   0(5,PCR),0(IP)          MOVE TRIPLE TO BUFFER            20320015
         LA    PCR,5(PCR)              BUMP POINTER                     20360015
LZZ6     NC    0(2,G1),0(G1)           TEST OPERAND                     20400015
         BC    BNE,LZZ7                BRANCH IF NOT '00'               20440015
         LTR   GRN,GRN                 TEST NUMBER OF '00'              20480015
         BC    BZ,LZZ8                 BRANCH IF THIS IS 1ST FOUND      20520015
         BAL   LR,ITEM2                GET ADDRESS OF 2ND TEMP DESCPT   20560015
         LA    G0,1                    RESTORE LOOP COUNT               20600015
         LR    GRN,G0                  AND TEMP COUNT                   20640015
         BC    B,LZZ9                                                   20680015
LZZ8     L     STR,LSTK                ADDRESS OF TEMP AT TOP OF STACK  20720015
LZZ9     LA    GRN,1(GRN)              BUMP NO OF TEMPS                 20760015
         BAL   RR,SETMPD               CREATE TMPD TRIPLES              20800015
LZZ7     LA    G1,TPOD1(IP)            ADDRESS OF 1ST OPERAND           20840015
         BCT   G0,LZZ6                 LOOP TEST                        20880015
LZZ17    STH   GRN,NTMP                SAVE NO OF TEMPS                 20920015
         LA    G0,BGPC                                                  20960015
         ST    G0,PAR1                 START OF TRIPLES                 21000015
         SR    PCR,G0                  NO OF BYTES OF TRIPLES           21040015
         ST    PCR,PAR2                                                 21080015
         BAL   LR,MV3A                 MOVE TRIPLE AND ANY TMPDS TO OP  21120015
         LA    PCR,BGPC                                                 21160015
         OI    RELCOD,X'08'            SET FOR NO DROP                  21200015
         TM    OPCOD,X'40'                                              21240015
         BC    BZ,RESLT2               BRANCH IF STRING EXPRESSION      21280015
         LH    GRN,NTMP                                                 21320015
         LTR   GRN,GRN                                                  21360015
         BC    BZ,NXTPL1               BRANCH IF NO TEMPS USED          21400015
         BAL   LR,RELSTK               RELEASE TEMPS FROM STACK         21440015
         SPACE 1                                                        21480015
*        UPDATE REGISTER STATUS BYTES IN TEXT IF ANY CHANGES.           21520015
         SPACE 1                                                        21560015
         CLI   TPOPN(IP),MASSGN                                         21600015
         BC    BE,NXTPL                AVOID UPDATE IF MULTIPLE ASSIGN  21640015
         LH    GRN,SCSTK(PAR)                                           21680015
         BAL   LR,RGSTAT               UPDATE STATUS                    21720015
         CH    GRN,SCSTK(PAR)                                           21760015
         BC    BE,NXTPL                BRANCH IF STATUS UNCHANGED       21800015
         XC    PAR2(4),PAR2                                             21840015
         BAL   LR,MV3                  MOVE ZERO LENTH PC               21880015
         BC    B,NXTPL                 GO TO MOVE PC AND GET NEXT TRIPL 21920015
         EJECT                                                          21960015
*              SUBSCRIPT TRIPLES.                                       22000015
*                                                                       22040015
*              FUNCTION (1) TO INSERT THE NEXT ODD SYMBOLIC REGISTER IN 22080015
*        THE TRIPLE AND STACK THE RESULT AS A DICTIONARY REFERENCE AND  22120015
*        INDEX REGISTER.                                                22160015
*                       (2) IF THE VARIABLE IS A STRING, TO STACK A     22200015
*        SKELETON STRING DESCRIPTION.                                   22240015
*                                                                       22280015
*              ENTRY POINT (1) 'SUBSPT' FOR SUBSCRIPT TRIPLE,ADDRESSED  22320015
*        BY REGISTER IP.                                                22360015
*                                                                       22400015
*              EXTERNAL ROUTINE (1) 'DICDES' IN BLOCK LS TO CONSTRUCT A 22440015
*        DESCRIPTION FROM A DICTIONARY REFERENCE                        22480015
*                               (2) 'SBGNOR' IN BLOCK LS TO GET NEXT    22520015
*        ODD SYMBOLIC REGISTER.                                         22560015
*                               (3) 'ADDSTK' IN BLOCK LT TO ADD RESULT  22600015
*        TO TEMPORARY STACK.                                            22640015
*                                                                       22680015
*              EXIT-NORMAL - TO 'LSUB1' TO MOVE TRIPLE TO OUTPUT AND    22720015
*        GET NEXT TRIPLE OF INTEREST.                                   22760015
*                                                                       22800015
*              EXIT-ERROR - NONE.                                       22840015
*                                                                       22880015
*              NOTES - REGISTERS ARE NOT PRESERVED                      22920015
*                                                                       22960015
SUBSPT   LA    DSR,DES1                                                 23000015
         MVC   DESBSE(2,DSR),PCOD1(IP) MOVE DICT REF OF VARIABLE TO BUF 23040015
         BAL   LR,DICDES               GET DICTIONARY DESCRIPTION       23080015
         MVC   BGPC(5),0(IP)           SAVE SUBS TRIPLE                 23090001
         BAL   RR,SC5                  GET NEXT TRIPLE                  23100001
         TM    DESCDE(DSR),X'80'                                        23120015
         BC    BO,LSUB3                BRANCH IF ARITHMETIC TYPE        23160015
         MVI   DESFLG(DSR),X'FF'       STRING TYPE - SO SET DESCRIPTION 23200015
         BC    B,LSUB4                                                  23240015
LSUB3    MVC   DESNDX(2,DSR),BGPC+PCOD2                                 23248001
         CLI   PCOPN(IP),OFS                                            23256001
         BC    BNE,LSUB5               BRANCH IF NOT OFFSET TRIPLE      23264001
         TM    PCOD1(IP),X'80'                                          23272001
         BC    BO,LSUB7                BRANCH IF NEGATIVE OFFSET        23280001
         TM    DESCDE(DSR),X'08'                                        23288001
         BC    BZ,LSUB7                BRANCH IF PICTURE                23296001
         TM    DESCDE(DSR),X'02'                                        23304001
         BC    BO,OFS1                 BRANCH IF FLOAT                  23312001
         TM    DESCDE(DSR),X'05'                                        23320001
         BC    BO,LSUB7                BRANCH IF NON-PIC CPLX FIX BIN   23328001
OFS1     OI    DESFLG(DSR),X'10'                                        23336001
         MVC   DESOFS(2,DSR),PCOD1(IP) SET OFFSET IN DESCRIPTION        23344001
         MVI   PCOPN(IP),NOPTP         REMOVE OFS TRIPLE                23352001
LSUB5    CLI   DESNDX(DSR),X'00'                                        23360001
         BC    BNE,LSUB6               BRANCH IF REGISTER ALREADY GIVEN 23368001
         CLI   DESNDX+1(DSR),X'00'                                      23376001
         BC    BE,LSUB4                BRANCH IF NO REGISTER WANTED     23384001
LSUB7    BAL   RR,SBGTNR               GET NEXT SYMBOLIC REGISTER       23392001
         STH   G1,DESNDX(DSR)          STORE XR IN DESCRIPTION          23400001
         MVC   BGPC+PCOD2(2),DESNDX(DSR)  STORE XR IN SUBS TRIPLE       23408001
LSUB6    OI    DESFLG(DSR),X'20'       SET DESCRIPTION FLAG FOR INDEX   23416001
LSUB4    BAL   LR,ADDSTK               ADD DESCRIPTION TO TEMP STACK    23440015
         LA    G0,BGPC                                                  23450001
         ST    G0,PAR1                                                  23460001
         LA    G0,5                                                     23470001
         ST    G0,PAR2                                                  23480001
         BAL   RR,MV3A                 MOVE SUBS TRIPLE TO OUTPUT       23490001
         BC    B,LB0                   RETURN AND RESCAN LAST TRIPLE    23500001
         EJECT                                                          23520015
*              CALL,FUNCTION,PSEUDO-VARIABLE AND ASSOCIATED TRIPLES.    23560015
*                                                                       23600015
*              FUNCTIONS - TO MAINTAIN A STACK DESCRIBING THE STATUS OF 23640015
*        NESTED FUNCTIONS,WHICH MAY BE INSIDE CALLS OR PSEUDO-VARIABLE. 23680015
*        EACH ITEM IN STACK IS 1 BYTE LONG,AND HAS FOLLOWING FORMATS -  23720015
*        X'20' AFTER FUNCTION TRIPLE FOLLOWING CALL.                    23760015
*        X'00' AFTER FUNCTION TRIPLE WHICH IS NOT ADD,MULT,DIVIDE, OR   23800015
*        PSEUDO-VARIABLE TRIPLE.                                        23840015
*              AFTER ADD,MULT,DIVIDE FUNCTION,BYTE HAS FORMATS -        23880015
*        X'4-' BEFORE 1ST ARGUMENT IS STACKED.                          23920015
*        X'8-' AFTER 1ST ARGUMENT IS STACKED.                           23960015
*        X'C-' AFTER 2ND ARGUMENT IS STACKED.                           24000015
*        X'-A' FOR ADD FUNCTION.                                        24040015
*        X'-C' FOR MULTIPLY FUNCTION.                                   24080015
*        X'-D' FOR DIVIDE FUNCTION.                                     24120015
*                                                                       24160015
*                       (2) TO PUT FUNCTION RESULT IN A REGISTER OR IN  24200015
*        TEMPORARY WORKSPACE AND ADD TO STACK.                          24240015
*                                                                       24280015
*              ENTRY POINTS(1)'CALLT'FROM SCAN IF CALL TRIPLE.          24320015
*                          (2)'FUNCT'FROM SCAN IF FUNCTION OR PSEUDO-   24360015
*        VARIABLE TRIPLE.                                               24400015
*                          (3)'FCTARG'FROM SCAN IF ARGUMENT TRIPLE ',,' 24440015
*                          (4)'FCTP'FROM SCAN IF FUNCTION PRIMED OR     24480015
*        PSEUDO-VARIABLE PRIMED TRIPLE.                                 24520015
*                                                                       24560015
*              EXTERNAL ROUTINES (1) 'ZDRFAB' IN COMPILER CONTROL.      24600015
*                                (2) 'ADDSTK' IN LT STACKS INTERMEDIATE 24640015
*        RESULT DESCRIPTION.                                            24680015
*                                (3) 'DICDES' IN LS CREATES A TEMPORARY 24720015
*        DESCRIPTION FROM A DICTIONARY REFERENCE.                       24760015
*                                (4) 'SC5' IN LA GETS NEXT TRIPLE FROM  24800015
*        TEXT.                                                          24840015
*                                (5) 'STREG4' IN LT GET ALIGNED CORE IN 24880015
*        TEMPORARY WORKSPACE.                                           24920015
*                                (6) 'GETFR' IN LT GETS FLOAT REGISTER. 24960015
*                                (7) 'GETGR' IN LT GETS GENERAL REGSTR. 25000015
*                                (8) 'SBGTNR' IN LS GETS SYMBOLIC REG.  25040015
*                                (9) 'MV3A' IN LA MOVES TRIPLES TO O/P. 25080015
*                                                                       25120015
*              EXITS-NORMAL (1) TO 'LSUB1' TO MOVE CURRENT TRIPLE TO    25160015
*        OUTPUT TEXT AND GET NEXT TRIPLE OF INTEREST.                   25200015
*                           (2) TO 'NXTPL1' TO DELETE CURRENT TRIPLE    25240015
*        AND GET NEXT TRIPLE OF INTEREST.                               25280015
*                           (3) TO 'ARITH' TO PROCESS ARITHMETIC TRIPLE 25320015
*        SET UP FOR ADD,MULT,DIVIDE FUNCTION.                           25360015
*                           (4) TO 'LZZ3' AS NORMAL TRIPLE WHICH MAY    25400015
*        HAVE '00' 2ND OPERAND.                                         25440015
*                           (5) TO 'LZZ17' TO MOVE FUNCTION PRIMED AND  25480015
*        TMPD TRIPLES TO OUTPUT TEXT AND GET NEXT TRIPLE OF INTEREST.   25520015
*                           (6) TO 'LB0' TO RESCAN CURRENT TRIPLE.      25560015
*                                                                       25600015
*              EXITS-ERROR (1) TO 'CERROR' IF FUNCTION NOT FOLLOWED BY  25640015
*        TMPD OR LEFT TRIPLES.                                          25680015
*                                                                       25720015
*              NOTES - ALL WORK REGISTERS MAY BE CHANGED.               25760015
         SPACE 2                                                        25800015
CALLT    ST    IP,PAR1                                                  25840015
         LA    G0,5                                                     25880015
         ST    G0,PAR2                                                  25920015
         BAL   RR,MV3A                 MOVE CALL TRIPLE TO OUTPUT TEXT  25960015
         BAL   RR,SC5                  GET NEXT TRIPLE                  26000015
         CLI   TPOPN(IP),X'3C'                                          26040015
         BC    BNE,LB0                 RESCAN TRIPLE IF NOT FUNCTION    26080015
MTFN     BAL   RR,STKFN                GET NEXT BYTE IN FUNCTION STACK  26120015
         MVI   0(DSR),X'20'            SET FOR CALL FUNCTION OR MTF     26160015
         BC    B,LSUB1                                                  26200015
         SPACE 2                                                        26240015
FUNCT    BAL   RR,STKFN                GET NEXT BYTE IN FUNCTION STACK  26280015
         MVI   0(DSR),0                SET FOR NORMAL FUNCTION OR P-V   26320015
         CLI   1(IP),X'0'                                               26360015
         BC    BE,FNCT2                BRANCH IF NOT DICT REF           26400015
         MVC   PAR1+2(2),TPOD1(IP)                                      26440015
         L     BR,ZDRFAB               CONVERT SYMBOLIC DICT REFERENCE  26480015
         BALR  RR,BR                 TO ABSOLUTE.                       26520015
         L     STR,PAR1                                                 26560015
         CLI   DEFLG(STR),X'C2'                                         26600015
         BC    BNE,FNCT2               BRANCH IF NOT BUILT-IN FUNCTION  26640015
         TM    BICODE(STR),X'F8'                                        26680015
         BC    BN1,FNCT1               BRANCH IF NOT ADD,MULT,DIVIDE    26720015
         OI    0(DSR),X'40'                                             26760015
         MVN   0(1,DSR),BICODE(STR)    SET FOR ARITH FUNCTION           26800015
         BC    B,NXTPL1                DELETE THIS TRIPLE,GET NEXT.     26840015
FNCT1    CLI   BICODE(STR),X'A7'       TEST FOR PRIORITY                26860015
         BC    BE,FNCT2                LIB CALL IF SO                   26880015
         CLI   BICODE-1(STR),X'4A'                                      26884001
         BC    BE,FNCT2                BRANCH IF TRANSLATE FUNCTION     26888001
         CLI   BICODE-1(STR),X'4B'                                      26892001
         BC    BE,FNCT2                BRANCH IF VERIFY FUNCTION        26896001
         TM    SCOPT(PAR),X'01'        IS STRINGRANGE ENABLED?    38172 26897020
         BO    FNCT2                   YES, ENSURE REGS ARE SAVED.38172 26898020
         CLI   BICODE(STR),ILF                                          26900015
         BC    BNL,LSUB1               RETURN IF IN-LINE FUNCTION       26920015
FNCT2    BAL   RR,STALRG               STORE ALL REGISTERS              26960015
         BAL   RR,MOVEPC               MOVE ANY PSEUDO-CODE TO OUTPUT   27000015
         BC    B,LSUB1                 RETURN                           27040015
         SPACE 2                                                        27080015
IGNT     CLI   0(IP),ITDO               TEST FOR ITDO TRIPLE            27083015
         BC    BNE,IGNT3                AND BRANCH IF NOT               27086015
*        AN ITDO TRIPLE HAS BEEN FOUND. THIS DELIMITS A SECTION         27089015
*        OF PSEUDO-CODE USING REGISTERS 14 OR 15.  IF THE               27092015
*        REGISTER IS NOT ALREADY FREE IT IS STORED                      27095015
         SPACE                                                          27098015
         LA    DSR,GRBLK               POINT DSR AT EVEN REG BLOCK      27101015
         CLI   4(IP),X'0E'              TEST FOR REGISTER 14            27104015
         BC    BE,IGNT1                                                 27107015
         LA    DSR,RGBLSZ(DSR)          IF NOT POINT DSR AT ODD REG     27110015
IGNT1    TM    RGD1(DSR),X'FF'          TEST IF REGISTER IS FREE        27113015
         BC    BZ,IGNT2                 IF SO DELETE TRIPLE             27116015
         MVI   PCOPN(PCR),ST            SET OPERATION CODE TO STORE     27119015
         BAL   RR,STREG2                STORE REGISTER                  27122015
         MVI   RGD1(DSR),0              SHOW REGISTER FREE              27125015
         IC    DSR,NGR                  NUMBER OF REGISTERS IN USE      27128015
         S     DSR,ONE                  SUBTRACT ONE                    27131015
         STC   DSR,NGR                                                  27134015
IGNT2    BC    B,NXTPL1                 DELETE ITDO TRIPLE              27137015
         SPACE 2                                                        27140015
IGNT3    L     DSR,FNSTAT                                               27143015
         TM    0(DSR),X'C0'                                             27160015
         BC    BZ,LSUB1                BRANCH IF NORMAL FUNCTION        27200015
         BC    B,NXTPL1                A,M,D FUNCTION,SO DELETE TRIPLE  27240015
         SPACE 2                                                        27280015
FCTARG   L     DSR,FNSTAT                                               27320015
         CLI   TPOPN(IP),X'37'                                          27360015
         BC    BNE,FARG1               BRANCH IF NOT BUY ASSIGN         27400015
         TM    0(DSR),X'C0'                                             27440015
         BC    BZ,LZZ1                 BRANCH IF NORMAL FUNCTION OR P-V 27480015
         NC    TPOD1(2,IP),TPOD1(IP)                                    27520015
         BC    BZ,LZZ1                 BRANCH IF 1ST OPERAND '00'       27560015
         MVC   PAR1(4),SCTXTI(PAR)                                      27600015
         ST    IP,PAR2                                                  27640015
         L     BR,ZTXTRF                                                27680015
         BALR  RR,BR                                                    27720015
         L     STR,PAR1                SYMBOLIC POINTER TO TRIPLE       27760015
         BAL   RR,SC4                  GET NEXT TRIPLE AND SAVE IN BUFF 27800015
         MVC   0(5,PCR),0(IP)                                           27840015
         ST    STR,PAR1                                                 27880015
         BAL   RR,SC10                 GO BACK TO PREVIOUS TRIPLE       27920015
         L     IP,PAR1                 RESET INPUT POINTER              27960015
         CLI   TPOPN(PCR),X'42'        TEST NEXT TRIPLE                 28000015
         BC    BNE,LZZ3                BRANCH IF NOT FUNCTION ARG       28040015
         CLC   TPOD1(2,IP),TPOD2(PCR)                                   28080015
         BC    BNE,LZZ3                BRANCH IF DICT REFS NOT SAME     28120015
         MVC   PAR1+2(2),TPOD1(IP)                                      28160015
         L     BR,ZDRFAB                                                28200015
         BALR  RR,BR                   ABSOLUTE ADDRESS OF DICT ENTRY   28240015
         L     STR,PAR1                                                 28280015
         NI    DEOTH3(STR),X'7F'                                        28320015
         OI    DEOTH4(STR),X'01'       NEUTRALISE DICT ENTRY            28360015
         MVC   0(2,PCR),TPOD2(IP)      SAVE 2ND OPERAND                 28400015
         BAL   RR,SC5                  GET FUNCTION ARG TRIPLE          28440015
         MVC   PCOD2(2,IP),0(PCR)      CHANGE 2ND OPERAND               28480015
FARG1    TM    0(DSR),X'C0'                                             28520015
         BC    BZ,LZZ3                 BRANCH IF NORMAL FUNCTION OR P-V 28560015
         BC    BO,NXTPL1               DELETE IF ALREADY 2 ARGUMENTS    28600015
         OI    0(DSR),X'80'                                             28640015
         XI    0(DSR),X'40'            RESET STATUS TO '8-' OR 'C-'     28680015
         NC    PCOD2(2,IP),PCOD2(IP)   TEST 2ND OPERAND FOR '00'        28720015
         BC    BZ,NXTPL1               DELETE TRIPLE IF ARG IN STACK    28760015
         MVC   DES1+DESBSE(2),PCOD2(IP)                                 28800015
         LA    DSR,DES1                                                 28840015
         BAL   RR,DICDES               SET UP DESCRIPTION FROM DICT     28880015
         MVC   DESNDX(1,DSR),DESTK(DSR)  SET TYPE IN INDEX FIELD        28920015
FARG2    BAL   RR,ADDSTK               ADD TO STACK                     28960015
         BC    B,NXTPL1                DELETE TRIPLE AND GET NEXT       29000015
         SPACE 2                                                        29040015
*              FUNCTION' AND PSEUDO-VARIABLE' TRIPLES.                  29080015
FCTP     L     DSR,FNSTAT              CURRENT ITEM IN FUNCTION STACK   29120015
         LR    STR,DSR                                                  29160015
         BCTR  STR,0                   SUBTRACT 1                       29200015
         ST    STR,FNSTAT              REMOVE ITEM FROM FUNCTION STACK  29240015
         CLI   0(DSR),X'20'                                             29280015
         BC    BZ,LSUB1                BRANCH IF CALL FUNCTION          29320015
         TM    0(DSR),X'C0'                                             29360015
         BC    BZ,FCTDES               BRANCH IF NORMAL FUNCTION OR P-V 29400015
         BAL   RR,NXTMPD               GET NEXT TMPD TRIPLE             29440015
         MVC   AMDBUF(4),TPOD1(IP)     MOVE RESULT DED TO BUFFER        29480015
         BAL   RR,NXTMPD               GET NEXT TMPD TRIPLE             29520015
         MVC   OPCOD(1),0(DSR)                                          29560015
         NI    OPCOD,X'0F'             SET OPERATOR TO +,*,/            29600015
         XC    TPOD1(4,IP),TPOD1(IP)   SET OPERANDS TO '00'             29640015
         BC    B,ARITH                 BRANCH TO ARITHMETIC PROCESSOR   29680015
         SPACE 1                                                        29720015
FCTDES   CLI   TPOPN(IP),FCNP                                           29760015
         BC    BNE,PSI                 BRANCH AS PSEUDO-VAR IF NOT FUNC 29800015
         SPACE 2                                                        29840015
*              TMPD TRIPLES GIVING FUNCTION TYPE.                       29880015
CFCTP    MVC   BGPC(5),0(IP)           MOVE PRIMED TRIPLE TO BUFFER     29920015
         BAL   RR,NXTMPD               GET NEXT TMPD TRIPLE             29960015
         MVC   BGPC+5(5),0(IP)         MOVE TO BUFFER                   30000015
         BAL   RR,NXTMPD               GET NEXT TMPD TRIPLE             30040015
         MVC   BGPC+10(5),0(IP)        MOVE TO BUFFER                   30080015
LFCT1    MVC   DES1(4),BGPC+5+TPOD1                                     30120015
         MVC   DES1+4(4),BGPC+10+TPOD1 MOVE DESCRIPTION TO DES1         30160015
         CLI   BGPC,NFUNC              BRANCH IF NOT NULL COMPILER      30200015
         BC    BNE,LFCT1A            FUNCTION                           30240015
         MVC   DES1+DESOFS(2),DES1+DESP  MOVE POSSIBLE PIC DR           30280015
         LA    DSR,DES1                ADDRESS OF DESCRTPTION           30320015
         TM    DES1+DESCDE,X'80'                                        30360015
         BC    BO,FARG2                ARITH, ADD TO STK,GET NXT TPL    30400015
         LA    PCR,BGPC+15                                              30440015
         BC    B,LFCT12                                                 30480015
LFCT1A   LA    PCR,BGPC+15                                              30520015
         TM    DES1+DESFLG,X'C0'                                        30560015
         BC    BZ,LFCT8                BRANCH IF DICT REF               30600015
         BC    BL,LFCT7                BRANCH IF '10','01' REGISTER V,N 30640015
         L     G1,CSTK                                                  30680015
         STH   G1,DES1+DESBSE          SET CURRENT TOP OF CORE STACK    30720015
         TM    DES1+DESFLG,X'04'       TEST SUBSTR BIT                  30760015
         BC    BO,LFCT8                BRANCH IF SUBSTR RESULT          30800015
         TM    DES1+DESCDE,X'80'                                        30840015
         BC    BZ,LFCT12               BRANCH IF STRING                 30880015
         TM    DES1+DESCDE,X'08'                                        30920015
         BC    BZ,LFCT14               BRANCH IF PICTURE                30960015
         TM    DES1+DESCDE,X'06'                                        31000015
         BC    BZ,LFCT3                BRANCH IF PACKED DECIMAL ARITH   31040015
         LA    STR,DES1                FLOAT OR FIXED BIN ARITH         31080015
         BAL   RR,STREG4               GET ALIGNED CORE                 31120015
         TM    DES1+DESFLG,X'10'                                        31160015
         BC    BZ,LFCT2                BRANCH IF NO 2ND OFFSET          31200015
         OI    BGPC+5+TPOD1,X'10'      RESET FLAG FOR 2ND OFFSET        31240015
         MVI   TPOPN(PCR),TMPD         GENERATE EXTRA TMPD TRIPLE       31280015
         MVC   TPOD1(2,PCR),DES1+DESOFS                                 31320015
         LA    PCR,5(PCR)              BUMP SIZE OF TMPD TRIPLES        31360015
LFCT2    LH    G1,DES1+DESNDX          RESULT LENGTH                    31400015
         BC    B,LFCT4                                                  31440015
LFCT3    SR    G1,G1                   PACKED DECIMAL ARITH TYPE        31480015
         IC    G1,DES1+DESP            PRECISION                        31520015
         LA    G1,2(G1)                                                 31560015
         SRL   G1,1                    BYTE SIZE                        31600015
LFCT4    TM    DES1+DESCDE,X'01'       TEST TYPE FOR REAL/COMPLEX       31640015
         BC    BZ,LFCT5                BRANCH IF REAL                   31680015
         AR    G1,G1                   DOUBLE LENGTH OF TEMP CORE       31720015
LFCT5    STH   G1,DES1+DESNDX          SET LENGTH OF TEMP CORE          31760015
         BC    B,LFCT8                                                  31800015
LFCT7    TM    DES1+DESFLG,X'80'                                        31840015
         BC    BZ,LFCT11               BRANCH IF REGISTER BY NAME       31880015
         OI    REGCOD,X'80'            SET REGISTER CODE FOR NO-LOAD    31920015
         MVC   BGPC+15(15),BGPC        IN CASE PC TO STORE A REGISTER   31960015
         LA    PCR,BGPC                IS NEEDED,SAVE TRIPLES,RESET PCR 32000015
         TM    DES1+DESCDE,X'02'       TEST FUNCTION DESCRIPTION        32040015
         BC    BZ,LFCT9                BRANCH IF FIXED                  32080015
         BAL   RR,GETFR                GET FLOATING REGISTER            32120015
         BC    B,LFCT10                                                 32160015
LFCT9    BAL   RR,GETGR                GET SINGLE GENERAL REGISTER      32200015
LFCT10   MVC   DES1+DESBSE(2),REG      SET REGISTER IN DESCRIPTION      32240015
         MVC   DES1+DESNDX(4),DESAD    REGISTER BLOCK ADDRESS           32280015
         NI    REGCOD,X'7F'            RESTORE REGISTER CODE            32320015
         BAL   RR,MOVEPC               PC TO STORE REGISTERS            32360015
         MVC   BGPC(15),BGPC+15        RESET TRIPLES AND POINTER        32400015
         LA    PCR,BGPC+15                                              32440015
         BC    B,LFCT8                                                  32480015
LFCT11   BAL   RR,SBGTNR               GET NEXT SYMBOLIC REGISTER       32520015
         STH   G1,DES1+DESBSE          STORE IN DESCRIPTION             32560015
LFCT8    MVC   BGPC+10+TPOD1(4),DES1+DESBSE  SET 2ND TMPD TRIPLE        32600015
LFCT6    LA    DSR,DES1                                                 32640015
         BAL   RR,ADDSTK               ADD TEMP TO STACKS               32680015
         SR    GRN,GRN                 CLEAR NO OF TEMPS                32720015
         BC    B,LZZ17                                                  32760015
LFCT12   MVI   DES1+DESFLG,X'FF'       SET FOR STRING TEMP              32800015
         BC    B,LFCT6                                                  32840015
LFCT14   MVC   PAR1+2(2),BGPC+10+TPOD1 MOVE DICT REF OF PICTURE         32880015
         MVC   BGPC+5+TPOD2(2),PAR1+2  SET IN FUNCTION TMPD             32920015
         MVC   DES1+DESOFS(2),PAR1+2    SET IN TEMP DESCRIPTION         32960015
         L     BR,ZDRFAB                CONVERT PICTURE DICT REF TO     33000015
         BALR  RR,BR                  ABSOLUTE                          33040015
         L     STR,PAR1                                                 33080015
         SR    G1,G1                                                    33120015
         IC    G1,DEPICW(STR)          NUMERIC FIELD LENGTH             33160015
         BC    B,LFCT5                                                  33200015
         SPACE 4                                                        33240015
*              PSEUDO VARIABLE.                                         33280015
PSI      LA    DSR,PSIDES              POINT AT PSEUDO-VAR DESCRIPTION  33320015
         BAL   RR,ADDSTK               STACK RESULT                     33340001
         BC    B,LSUB1                 GET NEXT TRIPLE                  33360001
         SPACE 2                                                        33400015
*              SUBROUTINE TO BUMP FUNCTION STACK POINTER.               33440015
STKFN    L     DSR,FNSTAT              CURRENT TOP OF STACK             33480015
         LA    DSR,1(DSR)                                               33520015
         ST    DSR,FNSTAT              NEW TOP OF STACK                 33560015
         BCR   B,RR                                                     33600015
         SPACE 2                                                        33640015
*              SUBROUTINE TO GET NEXT TMPD TRIPLE                       33680015
NXTMPD   ST    RR,DMPRR                                                 33720015
         BAL   RR,SC5                  GET NEXT TRIPLE                  33760015
         L     RR,DMPRR                                                 33800015
         CLI   TPOPN(IP),TMPD                                           33840015
         BCR   BZ,RR                   RETURN IF TMPD TRIPLE            33880015
         CLI   TPOPN(IP),LEFT                                           33920015
         BCR   BZ,RR                   RETURN IF LEFT TRIPLE            33960015
         MVC   PAR6+1(3),ERR46                                          34000015
         BC    B,CERROR                CREATE ERROR MESSAGE AND ABORT   34040015
         EJECT                                                          34080015
*              GET NEXT SYMBOLIC REGISTER.                              34120015
*                                                                       34160015
*              FUNCTION - TO GET NEXT AVAILABLE SYMBOLIC UNASSIGNED     34200015
*        REGISTER. THE NAME WILL BE PROVIDED IN REGISTER WRB (G1).      34240015
*                                                                       34280015
*              ENTRY POINT (1) 'SBGTNR' GETS NEXT REGISTER.             34320015
*                          (2) 'SBGNER' GETS NEXT EVEN REGISTER OF PAIR 34360015
*                          (3) 'SBGNOR' GETS NEXT ODD REGISTER OF PAIR. 34400015
*                                                                       34440015
*              EXTERNAL ROUTINE - NONE.                                 34480015
*                                                                       34520015
*              EXIT-NORMAL - TO INSTRUCTION AFTER INVOCATION.           34560015
*                                                                       34600015
*              EXIT-ERROR - NONE.                                       34640015
*                                                                       34680015
         SPACE 2                                                        34720015
*              ENTRY POINT WHEN ANY                                     34760015
*        REGISTER IS REQUIRED.                                          34800015
         SPACE                                                          34840015
WRB      EQU   G1                                                       34880015
SBGTNR   MVI   SBEO,0                  SET MASK FOR ANY REGISTER.       34920015
SBG01    LA    WRB,1                 SET WRB EQUAL TO AN INCREMENT OF   34960015
SBG02    AH    WRB,ZSMREG+2          ONE. ADD THIS TO CURRENT SYMBOLIC  35000015
         CH    WRB,SBMXRG              IF GREATER THAN MAXIMUM SIZE, GO 35040015
         BC    BH,SBERR              TOAN ERROR ROUTINE.                35080015
SBG03    STH   WRB,ZSMREG+2            PLACE NEW NAME IN ZSMREG AND IF  35120015
         AH    WRB,SBEO                APPROPRIATE SET THE EVEN/ODD BIT 35160015
         BCR   B,LR                  TO ONE AND RETURN.                 35200015
         SPACE                                                          35240015
*              EVEN REGISTER REQUIRED                                   35280015
         SPACE                                                          35320015
SBGNER   TM    ZSMREG+3,X'01'          IF CURRENT NAME IS EVEN, GO TO   35360015
         BC    BZ,SBG05              SBG05. IF ODD, SET MASK            35400015
SBG04    MVI   SBEO,X'40'            WITH EVEN/ODD BIT AND GO TO SBG01  35440015
         BC    B,SBG01                                                  35480015
         SPACE                                                          35520015
*              ODD REGISTER REQUIRED                                    35560015
         SPACE                                                          35600015
SBGNOR   TM    ZSMREG+3,X'01'          IF CURRENT NAME IS EVEN, GO TO   35640015
         BC    BZ,SBG04              SBG04. IF ODD, SET MASK            35680015
SBG05    LA    WRB,2                 WITH EVEN/ODD BIT, SET WRB EQUAL   35720015
         MVI   SBEO,X'40'            TO AN INCREMENT OF TWO AND GO TO   35760015
         BC    B,SBG02               SBG02.                             35800015
         SPACE                                                          35840015
*              ROUTINES INVOKED.                                        35880015
         SPACE                                                          35920015
SBERR    BCR   B,LR                    ERROR ROUTINE.                   35960015
         SPACE                                                          36000015
*              HALF WORD BOUNDARY LOCATIONS                             36040015
         SPACE                                                          36080015
SBEO     DC    H'0'                    MASK                             36120015
SBMXRG   DC    H'16127'                MAX VALUE OF SYMBOLIC REGISTER   36160015
         EJECT                                                          36200015
*              CONSTRUCT DESCRIPTION FROM DICTIONARY ENTRY.             36240015
*                                                                       36280015
*              FUNCTION - CONSTRUCT DESCRIPTION FOR A CONSTANT OR       36320015
*        VARIABLE WITH A DICTIONARY REFERENCE. THE DICTIONARY ENTRY     36360015
*        TYPE IS CHECKED AND THE DED MOVED TO THE DESCRIPTION. IF THE   36400015
*        VARIABLE IS A LABEL,EVENT,FILE OR TASK, THE 1ST DED BYTE IS    36440015
*        SET TO X'C0' AND THE FOLLOWING CODE IS SET IN THE OFS FIELD -  36480015
*              X'00' FOR LABEL                                          36520015
*              X'80'     EVENT                                          36560015
*              X'A0'     FILE                                           36600015
*              X'E0'     TASK                                           36640015
*                                                                       36680015
*              ENTRY POINT - 'DICDES'. REGISTER DSR ADDRESSES THE       36720015
*        DESCRIPTION WHICH ALREADY CONTAINS THE DICTIONARY REFERENCE.   36760015
*                                                                       36800015
*              EXTERNAL ROUTINE (1) 'ZDRFAB' IN CONTROL PHASE TO        36840015
*        CONVERT SYMBOLIC DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.     36880015
*                               (2) 'ERROR' IN BLOCK LT TO CREATE ERROR 36920015
*        MESSAGE 1613 IF DICTIONARY ENTRY OF STRUCTURE OR UNSUBSCRIPTED 36960015
*        ARRAY.                                                         37000015
*                                                                       37040015
*              EXIT-NORMAL - TO INSTRUCTION AFTER INVOCATION.           37080015
*                                                                       37120015
*              EXIT-ERROR - TO CERROR IF DICTIONARY REFERENCE IS LESS   37160015
*        THAN  X'0100',CREATING ERROR MESSAGE 1609 AND ABORTING.        37200015
*                                                                       37240015
*              NOTES.- REGISTERS STR,BR ARE CHANGED.                    37280015
*                                                                       37320015
DICDES   ST    LR,DCDSRR                                                37360015
         MVC   PAR1+2(2),DESBSE(DSR)                                    37400015
         MVC   PAR6+1(3),ERR49                                          37440015
         CLI   DESBSE(DSR),0           TEST DICT REFERENCE              37480015
         BC    BZ,CERROR               BRANCH TO ERROR IF 1ST BYTE = 0  37520015
         L     BR,ZDRFAB               CONVERT SYMBOLIC DICT ENTRY      37560015
         BALR  LR,BR                   TO ABSOLUTE                      37600015
         L     STR,PAR1                                                 37640015
         CLI   DCFLG(STR),X'88'                                         37680015
         BC    BZ,LDIC1                BRANCH IF A CONSTANT             37720015
         MVI   DESTK(DSR),0            SET STACK STATUS TO 'DICTIONARY' 37760015
         TM    DCFLG(STR),VARDE                                         37800015
         BC    BN1,LDIC3               BRANCH IF NOT A VARIABLE         37840015
         MVC   DESCDE(3,DSR),DEDATA(STR)  MOVE VARIABLE DED             37880015
         MVC   DESOFS(2,DSR),DESYMB(STR)  PIC DICT REF,IF USED          37920015
         TM    DCFLG(STR),DIMDE                                         37960015
         BC    BZ,LDIC2                BRANCH IF NOT AN ARRAY           38000015
         CLI   OPCOD,X'D4'                                              38040015
         BC    BZ,LDIC2                BRANCH IF THIS IS SUBSCRIPT TRPL 38080015
         BC    B,LDIC4                 GO TO GENERATE ERROR MESSAGE     38120015
LDIC3    TM    DCFLG(STR),STRDE                                         38160015
         BC    BN1,LDIC5               BRANCH IF NOT A STRUCTURE        38200015
         MVC   DESCDE(3,DSR),FIXBIN    SET TYPE TO FIX BINARY(31,0)     38240015
LDIC4    MVC   PAR6+1(3),ERR4D                                          38280015
         MVC   PAR7+2(2),DESBSE(DSR)                                    38320015
         BAL   RR,ERROR                GENERATE ERROR MESSAGE           38360015
         MVI   DESFLG(DSR),X'80'                               A18388   38380001
         XC    DESBSE(2,DSR),DESBSE(DSR)                       A18388   38400001
         B     LDIC2A                                          A18388   38420001
LDIC5    MVI   DESCDE(DSR),X'C0'       SET 2ND CODE BYTE FOR L,E,F,T    38440015
         MVI   DESOFS(DSR),X'00'       SET OFFSET CODE TO LABEL         38480015
         TM    DCFLG(STR),LABDE                                         38520015
         BC    BZ,LDIC2                BRANCH IF LABEL                  38560015
         MVI   DESOFS(DSR),X'A0'       SET OFFSET CODE TO FILE          38600015
         TM    DCFLG(STR),FILDE                                         38640015
         BC    BZ,LDIC2                BRANCH IF FILE                   38680015
         MVI   DESOFS(DSR),X'E0'       SET OFFSET CODE TO TASK          38720015
         TM    DCFLG(STR),TSKDE                                         38760015
         BC    BZ,LDIC2                BRANCH IF TASK                   38800015
         MVI   DESOFS(DSR),X'80'       SET OFFSET CODE TO EVENT         38840015
         BC    B,LDIC2                                                  38880015
LDIC1    MVC   DESCDE(3,DSR),DCDED1(STR)  MOVE APPARENT DED             38920015
         MVI   DESTK(DSR),X'80'        SET STACK STATUS TO 'CONSTANT'   38960015
LDIC2    MVI   DESFLG(DSR),X'00'       SET DESCRIPTION FLAG             39000015
LDIC2A   EQU   *                                               A18388   39020001
         L     LR,DCDSRR                                                39040015
         BCR   B,LR                    RETURN                           39080015
         EJECT                                                          39120015
*              MOVE PSEUDO-CODE SUBROUTINE.                             39160015
*                                                                       39200015
*              FUNCTION -   MOVE ANY PSEUDO-CODE IN BUFFER TO OUTPUT    39240015
*        TEXT AND RESET REGISTER STATUS BYTES FOR SCAN.                 39280015
*                                                                       39320015
*              ENTRY POINT - 'MOVEPC'. PSEUDO-CODE IN BUFFER IS BETWEEN 39360015
*        'BGPC' AND ADDRESS IN REGISTER PCR. REGISTER USAGE IS GIVEN    39400015
*        BY THE REGISTER CONTROL BLOCKS.                                39440015
*              ENTRY POINT - 'RGSTAT' CAUSES REGISTER STATUS BYTES      39480015
*        IN SCAN PARAMETER BLOCK TO BE UPDATED.                         39520015
*                                                                       39560015
*              EXTERNAL ROUTINE - 'MV3' IN BLOCK LA TO MOVE PSEUDO-CODE 39600015
*        TO OUTPUT TEXT.                                                39640015
*                                                                       39680015
*              EXIT-NORMAL - TO INSTRUCTION AFTER INVOCATION.           39720015
*                                                                       39760015
*              EXIT-ERROR - NONE.                                       39800015
*                                                                       39840015
*              NOTES - REGISTERS G0,G1,STR ARE CHANGED.                 39880015
*                      REGISTER PCR IS RESET TO ADDRESS 'BGPC'.         39920015
*                                                                       39960015
MOVEPC   MVI   MOVCOD,X'00'            SET ENTRY POINT CODE             40000015
         LA    G0,BGPC                                                  40040015
         SR    PCR,G0                                                   40080015
         BC    BZ,LZZ16                BRANCH IF NO PC IN BUFFER        40120015
         ST    G0,PAR1                                                  40160015
         ST    PCR,PAR2                SET ARGUMENTS FOR MOVE PC        40200015
*              SET REGISTER STATUS BYTES.                               40240015
LZZ10    ST    LR,DCDSRR               SAVE LINK REGISTER               40280015
         ST    DSR,CVTDSR              SAVE REGISTER DSR                40320015
         LA    G0,4                                                     40360015
         SR    G1,G1                                                    40400015
         LA    DSR,FRBLK               POINT TO 1ST FLOAT REG BLOCK     40440015
LZZ11    SLL   G1,1                                                     40480015
         CLI   RGD1(DSR),0                                              40520015
         BC    BZ,LZZ12                BRANCH IF REG NOT IN USE         40560015
         LA    G1,1(G1)                IN USE, SO SET BIT               40600015
         L     STR,RGD1(DSR)                                            40640015
         TM    DESCDE(STR),X'10'       TEST FOR LONG/SHORT              40680015
         BC    BZ,LZZ12                BRANCH IF SHORT                  40720015
         LA    G1,16(G1)               SET BIT FOR LONG FLOAT           40760015
LZZ12    LA    DSR,RGBLSZ(DSR)         BUMP POINTER TO NEXT REG BLOCK   40800015
         BCT   G0,LZZ11                LOOP TEST                        40840015
         STC   G1,SCSTK(PAR)           STORE FLOAT REGISTERS STATUS     40880015
         MVI   SCSTK+1(PAR),0                                           40920015
         CLI   GRBLK,0                 TEST GENERAL REGISTER BLOCKS     40960015
         BC    BZ,LZZ13                BRANCH IF EVEN REG NOT IN USE    41000015
         OI    SCSTK+1(PAR),X'80'      SET EVEN GEN REGISTER BIT        41040015
LZZ13    CLI   GRBLK+RGBLSZ,0                                           41080015
         BC    BZ,LZZ14                BRANCH IF ODD REG NOT IN USE     41120015
         OI    SCSTK+1(PAR),X'40'      SET ODD GEN REGISTER BIT         41160015
LZZ14    CLI   MOVCOD,X'01'            TEST ENTRY POINT                 41200015
         BC    BE,LZZ15                                                 41240015
         BAL   LR,MV3                  MOVE PC TO OUTPUT                41280015
LZZ15    L     LR,DCDSRR                                                41320015
         L     DSR,CVTDSR              RESTORE DSR                      41360015
LZZ16    LA    PCR,BGPC                RESET PC POINTER                 41400015
         BCR   B,LR                    RETURN                           41440015
RGSTAT   MVI   MOVCOD,X'01'            SET ENTRY POINT CODE             41480015
         BC    B,LZZ10                                                  41520015
         EJECT                                                          41560015
*              CONVERT AND CONSTANT SUBROUTINE.                         41600015
*                                                                       41640015
*              FUNCTION (1) TO GENERATE TRIPLES TO CHANGE THE TYPE OF   41680015
*        A VARIABLE IN A MIXED EXPRESSION. THE PRECISION AND SCALE      41720015
*        FACTOR OF THE TARGET IS CALCULATED. THE SOURCE IS RELEASE FROM 41760015
*        THE RESULT STACK IF NECESSARY AND THE TARGET IS ADDED TO THE   41800015
*        STACK.                                                         41840015
*                       (2) TO SET THE TARGET DED IN CONSTANT TYPE      41880015
*        DICTIONARY ENTRIES. IF THE ENTRY IS ALREADY USED FOR ANOTHER   41920015
*        TARGET DED, A NEW ENTRY IS CONSTRUCTED AND CHAINED TO THE      41960015
*        ORIGINAL.                                                      42000015
*                                                                       42040015
*              ENTRY POINT (1) 'CONVT' TO CONVERT TO THE TARGET TYPE IN 42080015
*        DESCRIPTION BUFFER 'DESBUF'. REGISTER DSR ADDRESSES THE SOURCE 42120015
*        DESCRIPTION.                                                   42160015
*                          (2) 'CONST' TO SET DICTIONARY ENTRY FOR      42200015
*        CONSTANT. REGISTER DSR ADDRESSES THE SOURCE DESCRIPTION WHICH  42240015
*        CONTAINS THE TARGET TYPE AND THE DICTIONARY REFERENCE OF THE   42280015
*        CONSTANT.                                                      42320015
*                                                                       42360015
*              EXTERNAL ROUTINE (1) 'ZDRFAB' IN CONTROL PHASE TO        42400015
*        CONVERT SYMBOLIC DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.     42440015
*                               (2) 'ZDICRF' IN CONTROL PHASE TO        42480015
*        CONSTRUCT NEW DICTIONARY REFERENCE.                            42520015
*                               (3) 'STALRG' IN BLOCK LS TO STORE ALL   42560015
*        REGISTERS IN USE.                                              42600015
*                               (4) 'STREG4' IN BLOCK LT TO GET ALIGNED 42640015
*        CORE IN TEMPORARY WORKSPACE.                                   42680015
*                               (5) 'ASSIGN' IN BLOCK LS TO GENERATE AN 42720015
*        ASSIGNMENT TRIPLE WITH TMPD'S.                                 42760015
*                               (6) 'DECNST' IN BLOCK LS TO CONSTRUCT   42800015
*        A DICTIONARY ENTRY FOR CONSTANTS.                              42840015
*                               (7) 'GETFR' IN BLOCK LT TO GET A FLOAT  42880015
*        REGISTER.                                                      42920015
*                               (8) 'ADDSTK' IN BLOCK LT TO ADD RESULT  42960015
*        TO TEMPORARY STACK.                                            43000015
*                               (9) 'RELSTK' IN BLOCK LT TO RELEASE     43040015
*        ITEM FROM TEMPORARY STACK.                                     43080015
*                              (10) 'ERROR' IN BLOCK LT TO CREATE ERROR 43120015
*        DICTIONARY ENTRY IF SCALE FACTOR OVERFLOWS.                    43160015
*                                                                       43200015
*              EXIT-NORMAL - TO INSTRUCTION AFTER INVOCATION.           43240015
*                                                                       43280015
*              EXIT-ERROR - CREATE ERROR MESSAGE '1605' IF SCALE FACTOR 43320015
*        OVERFLOW. CONTINUE TO PROCESS.                                 43360015
*                                                                       43400015
*              NOTES - REGISTERS G1,GRN,STR,BR ARE CHANGED.             43440015
*                      REGISTERS G0,DSR,RR ARE PRESERVED.               43480015
         EJECT                                                          43520015
CONVT    ST    RR,CVTRR                STORE RETURN REGISTER            43560015
         ST    G0,CVTG0          SAVE G0                                43600015
         ST    DSR,CVTDSR              STRING TYPE - SAVE SOURCE POINTR 43640015
         MVC   DESBUF+DESTK(1),DESTK(DSR)   SAVE STACK CODE             43680015
         TM    DESCDE(DSR),X'80'       TEST SOURCE TYPE                 43720015
         BC    BO,LCV20                BRANCH IF CAD OR NF              43760015
         OI    DESBUF+DESTK,X'40'      SET BIT IN STACK CODE FOR STRING 43800015
         TM    DESCDE(DSR),X'04'                                        43840015
         LA    DSR,CHARST-DESCDE       'FIX DEC' DESCPT FOR CHAR STRING 43880015
         BC    BO,LCV20                BRANCH IF CHAR STRING            43920015
LCV21    LA    DSR,BITST-DESCDE        'FIX BIN' DESCPT FOR BIT STRING  43960015
LCV20    MVC   CVTBUF(1),DESBUF+DESCDE                                  44000015
         XC    CVTBUF(1),DESCDE(DSR)   CODE BYTE CHANGES                44040015
         TM    CPX+1,X'0F'                                              44080015
         BC    BO,LCV27                BRANCH IF COMPLEX SUBROUTINE     44120015
         TM    CVTBUF,X'01'            TEST COMPLEX/REAL BIT            44160015
         BC    BZ,LCV27                BRANCH IF NO CHANGE              44200015
         NI    DESBUF+DESCDE,X'FE'     SET TARGET TO REAL               44240015
         NI    CVTBUF,X'1E'            MASK AND TEST CHANGES            44280015
         BC    BNE,LCV27               BRANCH IF CHANGES                44320015
         TM    DESBUF+DESTK,X'80'                                       44360015
         BC    BO,LCV1                 BRANCH IF CONSTANT               44400015
         TM    DESBUF+DESTK,X'40'                                       44440015
         BC    BZ,CVTRET               RETURN IF NOT STRING             44480015
LCV27    TM    CVTBUF,X'04'            TEST BINARY/DECIMAL BIT          44520015
         BC    BZ,LCV1                 BRANCH IF NO CHANGE              44560015
         SR    G1,G1                   DECIMAL TO BINARY                44600015
         IC    G1,DESP(DSR)            SOURCE PRECISION                 44640015
         M     GRN,DBMULT              MULTIPLY IN GRN,G1               44680015
         A     G1,CEIL1                                                 44720015
         SRA   G1,20                   TARGET PRECISION                 44760015
         TM    DESBUF+DESCDE,X'02'                                      44800015
         BC    BZ,LCV4                 BRANCH IF FIXED TARGET           44840015
         CH    G1,FLMAXP               COMPARE WITH MAX FLT BIN PREC    44880015
         BC    BNH,LCV2                BRANCH IF NOT GREATER            44920015
         LH    G1,FLMAXP               USE MAXIMUM PRECISION            44960015
LCV2     STC   G1,DESBUF+DESP                                           45000015
         BC    B,LCV3                                                   45040015
LCV4     LA    G1,1(G1)                BUMP PRECISION BY 1              45080015
         CH    G1,FXMAXP                                                45120015
         BC    BNH,LCV5                BRANCH IF .LE. 31                45160015
         LH    G1,FXMAXP               SET TO 31                        45200015
LCV5     STC   G1,DESBUF+DESP                                           45240015
         IC    G1,DESQ(DSR)            SCALE FACTOR                     45280015
         SH    G1,SF0                                                   45320015
         M     GRN,DBMULT              SF*3.32                          45360015
         LTR   G1,G1                                                    45400015
         BC    BNH,LCV6                BRANCH IF NEGATIVE               45440015
         A     G1,CEIL1                ROUND UP                         45480015
LCV6     SRA   G1,20                                                    45520015
         AH    G1,SF0                                                   45560015
         BC    BL,LCV9                 BRANCH IF SF .LT. -128           45600015
         CH    G1,MAXSF                                                 45640015
         BC    BNH,LCV8                BRANCH IF SF .LE. +127           45680015
LCV9     MVC   PAR6+1(3),ERR45         SF OUT OF RANGE,SO               45720015
         BAL   RR,ERROR                CREATE ERROR MESSAGE AND         45760015
         LH    G1,MAXSF                                                 45800015
         XR    G1,GRN                  SET RESULT TO MAX OR MIN SF      45840015
LCV8     STC   G1,DESBUF+DESQ                                           45880015
         TM    DESBUF+DESTK,X'80'                                       45920015
         BC    BZ,LCV7                 BRANCH IF NOT CONSTANT           45960015
LCV8A    L     DSR,CVTDSR              RESTORE DSR                      46000015
         BC    B,LCON1                 GO TO CONSTANT ROUTINE           46040015
LCV1     MVC   DESBUF+DESP(2),DESP(DSR)   SET TARGET (P,Q)              46080015
LCV3     TM    DESBUF+DESTK,X'80'                                       46120015
         BC    BO,LCV8A                BRANCH IF CONSTANT               46160015
         TM    DESCDE(DSR),X'0A'                                        46200015
         BC    BO,LCV7A                BRANCH IF SOURCE IS FLOAT CAD    46240015
LCV7     BAL   LR,STALRG               STORE ALL REGS IN USE            46280015
         TM    DESBUF+DESCDE,X'06'     TEST TARGET                      46320015
         BC    BNE,LCV26               BRANCH IF NOT FIXED DECIMAL      46360015
         MVI   DESBUF+DESFLG,X'C0'     PACKED DECIMAL TARGET            46400015
         L     G1,CSTK                                                  46440015
         STH   G1,DESBUF+DESBSE        SET CURRENT TOP OF CORE STACK    46480015
         SR    G1,G1                                              27134 46500019
         IC    G1,DESBUF+DESP          PRECISION IN DIGITS              46520015
         LA    G1,2(G1)                                                 46560015
         SRL   G1,1                    BYTE SIZE                        46600015
         BC    B,LCV26A                                                 46640015
LCV7A    TM    DESBUF+DESCDE,X'01'                                      46680015
         BC    BZ,LCV10                BRANCH IF REAL SOURCE AND TARGET 46720015
         TM    CVTBUF,X'11'                                             46760015
         BC    BZ,CVTRET               RETURN IF DEC/BIN CHANGE ONLY    46800015
LCV26    LA    STR,DESBUF                                               46840015
         BAL   RR,STREG4               GET TEMP CORE                    46880015
         LH    G1,DESBUF+DESNDX                                         46920015
LCV26A   TM    DESBUF+DESCDE,X'01'                                      46960015
         BC    BZ,LCV11                BRANCH IF REAL                   47000015
         AR    G1,G1                                                    47040015
LCV11    STH   G1,DESBUF+DESNDX                                         47080015
LCV23    L     DSR,CVTDSR              POINT TO ORIGINAL SOURCE DESCPT  47120015
         TM    DESTK(DSR),X'FD'                                         47160015
         BC    BNE,LCV23A              BRANCH IF IN STACK OR CONSTANT   47200015
         TM    DESFLG(DSR),X'20'                                        47240001
         BC    BZ,LCV23A               BRANCH IF NOT INDEXED            47280001
         OI    RELCOD,X'08'            SET FOR NO DROP                  47320015
LCV23A   BAL   RR,ASSIGN               GENERATE ASSIGNMENT TRIPLE       47360015
         MVC   0(ISTK,DSR),DESBUF      CHANGE SOURCE DESCPT TO TARGET   47400015
         OI    RELCOD,X'08'            SET FOR NO DROP                  47440015
         BC    B,LCV14                                                  47480015
LCV10    MVC   DESCDE(2,DSR),DESBUF+DESCDE  CHANGE TYPE AND P TO TARGET 47520015
         MVC   DESAD(4),DESNDX(DSR)    SET REG BLOCK ADDRESS            47560015
         TM    CVTBUF,X'10'            TEST LONG/SHORT BIT              47600015
         BC    BZ,CVTRET               RETURN IF NO CHANGE              47640015
         TM    DESFLG(DSR),X'80'                                        47680015
         BC    BZ,LCV18                BRANCH IF SOURCE NOT IN REGISTER 47720015
         TM    DESFLG(DSR),X'40'                                        47760015
         BC    BO,LCV18                BRANCH IF SOURCE NOT IN REGISTER 47800015
         CLI   NFR,4                                                    47810001
         BC    BL,LCV18                BRANCH IF FREE FLOAT REGISTER    47820001
         LA    STR,DEFL1               CREATE DICTIONARY ENTRY FOR      47840015
         BAL   RR,DECNST             SHORT FLOATING '1.0'               47880015
ME       EQU   MULT+FLE+X'80'                                           47920015
LCV19    MVI   PCOPN(PCR),ME            GENERATE  ME  FR,=1.0           47960015
         MVC   PCOD1(2,PCR),DESBSE(DSR) INSERT REGISTER                 48000015
         MVC   PCOD2(2,PCR),DEFL1+DCCHN   INSERT DICT REF FOR '1.0'     48040015
         LA    PCR,PCSZ5(PCR)           BUMP POINTER                    48080015
         L     G1,DESAD                                                 48120015
         L     G1,0(G1)                                                 48160015
         MVC   DESCDE(2,G1),DESCDE(DSR)  RESET DED IN STACK             48200015
         BC    B,LCV16                                                  48240015
LCV18    MVI   OPTYP,FLE               SET OPTYP TO SHORT FLOAT         48280015
         OI    REGCOD,X'10'            FLAG TO CLEAR DOUBLE REG   16210 48340017
         BAL   RR,GETFR                FLOAT REGISTER CONTAINS SOURCE   48400015
         MVI   DESFLG(DSR),X'80'       CHANGE SOURCE DESCRIPTION        48640015
         MVC   DESBSE(2,DSR),REG       TO REGISTER, BY VALUE            48680015
LCV14    MVC   DESBUF+DESTK(1),RELCOD   SAVE RELCOD                     48720015
         BAL   RR,ADDSTK             ADD TARGET TO STACK                48760015
         LA    GRN,1                                                    48800015
         CLI   DESTK(DSR),1            TEST STACK CODE                  48840015
         BC    BZ,LCV14A             BRANCH IF ORIGINALLY TOP OF STACK  48880015
         AH    GRN,NTMP                                                 48920015
         STH   GRN,NTMP                BUMP NUMBER OF TEMPS             48960015
         BC    B,LCV15                                                  49000015
LCV14A   MVC   RELCOD(1),DESBUF+DESTK   RESET RELCOD                    49040015
         BAL   RR,RLSTK1             RELEASE 2ND ITEM                   49080015
LCV15    NI    DES1+DESTK,X'80'        CLEAR 1ST OPND CODE UNLESS CONST 49120015
LCV16    L     DSR,CVTDSR              RESET REGISTER DSR               49160015
CVTRET   L     G0,CVTG0                RESTORE G0                       49200015
CONRET   L     RR,CVTRR                RESTORE RETURN REGISTER          49240015
         BCR   B,RR                    RETURN                           49280015
*                                                                       49320015
*              CONST SUBROUTINE TO SET UP DICTIONARY ENTRY FOR CONSTANT 49360015
*              OPERAND.                                                 49400015
*                                                                       49440015
CONST    ST    RR,CVTRR                                                 49480015
         MVC   DESBUF+DESCDE(3),DESCDE(DSR)  USE SOURCE DED IN TARGET   49520015
LCON1    TM    DEST+DESCDE,X'CC'       TEST FOR POINTER/OFFSET          49540015
         BC    BO,LCON8B             AVOID LONG/SHORT ALTERATION IF SO  49560015
         TM    DESBUF+DESCDE,X'82'     TEST FIXED / FLOAT               49580015
         BC    BN1,LCON8               BRANCH IF NOT FLOAT              49600015
         MVI   DESBUF+DESQ,X'80'       SET SCALE FACTOR TO ZERO         49640015
         BC    B,LCON8B                                                 49680015
LCON8    CLI   DESBUF+DESP,6           FIXED,SO SET LONG/SHORT BIT      49720015
         BC    BNH,LCON8B              BRANCH IF ALWAYS SHORT .LE. 6    49760015
         TM    DESBUF+DESCDE,X'04'                                      49800015
         BC    BZ,LCON8A               BRANCH IF DECIMAL AND LONG       49840015
         CLI   DESBUF+DESP,21                                           49880015
         BC    BNH,LCON8B              BRANCH IF SHORT BINARY .LE. 21   49920015
LCON8A   OI    DESBUF+DESCDE,X'10'     SET TO LONG                      49960015
LCON8B   MVC   PAR1+2(2),DESBSE(DSR)   SYMBOLIC DICT REF OF CONSTANT    50000015
         L     BR,ZDRFAB                                                50040015
         BALR  LR,BR                   ABSOLUTE ADDRESS OF DICT ENTRY   50080015
LCON2    L     STR,PAR1                                                 50120015
         MVI   DECON+DCTYP,X'01'       SET SKELETON TYPE TO UNUSED      50160015
         TM    DCTYP(STR),X'C0'        TEST TYPE BYTE                   50200015
         BC    BL,LCON3                BRANCH IF INITIAL DATA CONSTANT  50240015
         OC    DECON+DCTYP(1),DCTYP(STR)  SKELETON TYPE                 50280015
         TM    DCTYP(STR),X'01'                                         50320015
         BC    BO,LCON6                BRANCH IF NOT ALREADY IN USE     50360015
         CLC   DESBUF+DESCDE(3),DCDED2(STR)                             50400015
         BC    BZ,LCON7                BRANCH IF TARGET DEDS ARE SAME   50440015
LCON3    NC    DCCHN(2,STR),DCCHN(STR) TEST FOR END OF CONSTANT CHAIN   50480015
         BC    BZ,LCON5                BRANCH IF END OF CHAIN           50520015
         MVC   PAR1+2(2),DCCHN(STR)                                     50560015
LCON4    MVC   DESBSE(2,DSR),PAR1+2    UPDATE DICT REF IN DESCRIPTION   50600015
         BALR  LR,BR                   CONVERT SYMBOLIC REF TO ABSOLUTE 50640015
         L     G1,PAR1                                                  50680015
         CLC   DCLNG(2,G1),DECON+DCLNG TEST FOR LENGTH 14               50720015
         BC    BZ,LCON2                BRANCH IF STILL SAME CONSTANT    50760015
LCON5    MVC   DECON+DCCHN(5),DCCHN(STR)  SET CHAIN AND SOURCE DED IN   50800015
         LA    G1,DECON                                                 50840015
         ST    G1,PAR1                                                  50880015
         LA    G1,DCVAL                                                 50920015
         ST    G1,PAR2                                                  50960015
         L     BR,ZDICRF                                                51000015
         BALR  LR,BR                   ADD NEW ENTRY TO DICTIONARY      51040015
         MVC   DCCHN(2,STR),PAR1+2     COMPLETE CHAIN                   51080015
         L     BR,ZDRFAB                                                51120015
         BC    B,LCON4                                                  51160015
LCON6    TM    DCDED1(STR),X'CC'       TEST FOR OFFSET OR POINTER TYPE  51170015
         BC    BN1,LCON6A              BRANCH IF NOT SO                 51180015
         TM    DESBUF+DESCDE,X'CC'     TEST TARGET FOR POINTER/OFFSET   51183015
         BC    BO,LCON6A               GENUINE CONVERSION REQUEST       51186015
         MVC   DCDED2(3,STR),DCDED1(STR)  MAKE SOURCE AND TARGET        51190015
         BC    B,LCON6B                SAME IF EITHER                   51200015
         BC    B,LCON6B              SAME IF CONVERSION TO FIXED BIN.   51205015
LCON6A   MVC   DCDED2(3,STR),DESBUF+DESCDE    SET TARGET DED            51210015
LCON6B   MVC   DCINIT(2,STR),ZSTAT     MOVE IN STATEMENT NO             51220015
         NI    DCTYP(STR),X'F8'        SET IN USE,NO DED,DV             51280015
LCON7    MVC   DESCDE(3,DSR),DESBUF+DESCDE  CHANGE SOURCE DESPT.        51320015
         BC    B,CONRET                RETURN                           51360015
         EJECT                                                          51400015
*              COMPLEX ARITHMETIC SUBROUTINES.                          51440015
*                                                                       51480015
*              FUNCTION (1) UTILITY USED AFTER COMPLEX ARITHMETIC.      51520015
*        AFTER PASS 1, THE PASS 2 OPERANDS ARE SET FROM THE BUFFERS,THE 51560015
*        REAL RESULT IS STORED IN TEMP CORE,AND THE COMPLETE RESULT     51600015
*        DESCRIPTION IS SAVED IN THE BUFFERS.                           51640015
*        AFTER PASS 2, THE RESULT IS STORED IN TEMP STACK,AND THE       51680015
*        RESULT DESCRIPTION MOVED TO 'DEST'.                            51720015
*                       (2) TEST FOR MISSING OPERANDS DURING COMPLEX    51760015
*        ARITHMETIC.                                                    51800015
*                                                                       51840015
*              ENTRY POINT (1) 'CPLEX' TO HANDLE RESULTS AND OPERANDS   51880015
*        AFTER EACH PASS FOR FLOAT OR FIXED BINARY TYPES.               51920015
*                          (2) 'CPLXPD' AS 'CPLEX' FOR PACKED DECIMAL   51960015
*        TYPE.                                                          52000015
*                          (3) 'TSTOD1' TO TEST FOR A MISSING 1ST       52040015
*        OPERAND.                                                       52080015
*                          (4) 'TSTOD2' TO TEST FOR A MISSING 2ND       52120015
*        OPERAND.                                                       52160015
*                                                                       52200015
*              EXTERNAL ROUTINE (1)'STREG2' IN BLOCK LT TO STORE A      52240015
*        REGISTER IN TEMPORARY WORKSPACE.                               52280015
*                               (2)'GETFR' (IMPLICIT) IN BLOCK LT TO    52320015
*        GET A FLOAT REGISTER.                                          52360015
*                               (3)'GETGR' (IMPLICIT) IN BLOCK LT TO    52400015
*        GET A GENERAL ARITHMETER REGISTER.                             52440015
*                                                                       52480015
*              EXIT-NORMAL (1) FROM 'CPLEX' TO ADDRESS IN 'CPXRET' TO   52520015
*        GENERATE CODE FOR IMAGINARY PART.                              52560015
*                          (2) FROM 'CPLEX' TO 'RESLT1' IN BLOCK LT IF  52600015
*        PACKED DECIMAL TYPE.                                           52640015
*                          (3) FROM 'CPLEX' TO 'RESLT2 IN BLOCK LT IF   52680015
*        NOT PACKED DECIMAL TYPE.                                       52720015
*                          (4) FROM 'TSTOD' TO INSTRUCTION AFTER        52760015
*        INVOCATION IF OPERAND IS MISSING.                              52800015
*                          (5) FROM 'TSTOD' TO (INSTRUCTION+4) AFTER    52840015
*        INVOCATION IF OPERAND IS PRESENT.                              52880015
*                                                                       52920015
*              EXIT-ERROR - NONE.                                       52960015
*                                                                       53000015
*              NOTES - REGISTERS G0,G1,STR,DSR,RR ARE CHANGED.          53040015
         EJECT                                                          53080015
CPLEX    CLI   OPCOD,CPR                                                53120015
         BC    BZ,CPLXPD               BRANCH IF COMPARE                53160015
         L     DSR,DESAD               RESULT REG DESCPT BLOCK ADDRESS  53200015
         LA    STR,DEST                PUT RESULT DESCPT ADDRESS IN     53240015
         ST    STR,STRGRR            REGISTER BLOCK               14418 53260016
         MVC   RGD1+1(3,DSR),STRGRR+1                             14418 53280016
         MVI   PCOPN(PCR),ST                                            53320015
         BAL   RR,STREG2               STORE REGISTER IN TEMP STACK     53360015
CPLXPD   CLI   CPX+1,0                                                  53400015
         BC    BZ,CPLX7                BRANCH IF 2ND PASS               53440015
TOTDS2   EQU   2*TOTDES                TOTAL SIZE OF COMPLEX BUFFERS    53480015
         MVC   DES1(TOTDS2),CPXBF1     RESET OPERANDS                   53520015
         MVC   OPCOD(1),CPX+1          RESET OP CODE                    53560015
         MVI   CPX+1,0                                                  53600015
         L     RR,CPXRET               COMPLEX RETURN ADDRESS           53640015
         L     BR,REGSUB               RESTORE GET-REG SUBR ADDRESS     53680015
         CLI   OPCOD,CPR                                                53720015
         BC    BZ,CPLX1                BRANCH IF COMPARE                53760015
         TM    DEST+DESCDE,X'06'                                        53800015
         BCR   BZ,RR                   RETURN IF PACKED DECIMAL         53840015
         LH    G1,DEST+DESNDX          RESULT LENGTH FOR REAL           53880015
         AR    G1,G1                   DOUBLE FOR COMPLEX LENGTH        53920015
         STH   G1,DEST+DESNDX                                           53960015
CPLX3    MVC   CPXBF1(TOTDES),DEST     MOVE RESULT TO COMPLEX BUF       54000015
         BCR   B,RR                    RETURN TO GENERATE IMAG CODE     54040015
CPLX1    LA    G1,1                                                     54080015
         AH    G1,ZEQMAX                                                54120015
         STH   G1,ZEQMAX               BUMP CURRENT COMPILER LABEL NO   54160015
         MVC   PCN1+PCOD2(2),ZEQMAX    PUT LABEL IN PC SKELETONS        54200015
         MVC   PCN2+PCOD1(2),ZEQMAX                                     54240015
         MVC   0(LPCN1,PCR),PCN1                                        54280015
         LA    PCR,PCSZ5(PCR)          GENERATE   BC   BNE,LBL          54320015
         BC    B,CPLX3                                                  54360015
CPLX7    CLI   OPCOD,CPR                                                54400015
         BC    BZ,CPLX2                BRANCH IF COMPARE                54440015
         MVC   DEST(TOTDES),CPXBF1     RESULT DESCRIPTION               54480015
         BC    B,RESLT2                RETURN TO NORMAL FINISH          54520015
CPLX2    MVC   0(LPCN2,PCR),PCN2                                        54560015
         LA    PCR,PCSZ3(PCR)          GENERATE  LBL  EQU   *           54600015
         TM    DEST+DESCDE,X'06'                                        54640015
         BC    BNE,RESLT2              NORMAL FINISH IF NOT PD          54680015
         OC    DEST+DESNDX(2),CPXBF1+DESNDX  CORRECT LENGTH IF ONE      54720015
         BC    B,RESLT1                REAL OPERAND AND FINISH          54760015
         SPACE 3                                                        54800015
*        'TEST OPERAND' SUBROUTINE TO TEST FOR ZERO IMAGINARY PART OF   54840015
*        COMPLEX VARIABLES.                                             54880015
*        IF ZERO IS FOUND,RETURN TO NEXT INSTRUCTION IN CALLER.         54920015
*        IF ZERO NOT FOUND,RETURN TO (NEXT INSTRUCTION+4) IN CALLER.    54960015
*        'TSTOD1' ALSO CLEARS CURRENT REGISTER IF ZERO FOUND.           55000015
*        'TSTOD1' TESTS 1ST OPERAND, 'TSTOD2' TESTS 2ND OPERAND.        55040015
TSTOD1   MVI   CPX,X'80'               SET FLAG FOR 'TSTOD1' ENTRY      55080015
         LA    DSR,DES1                1ST OPERAND ADDRESS              55120015
         BC    B,TSDL1                                                  55160015
*                                                                       55200015
TSTOD2   MVI   CPX,X'00'               SET FLAG FOR 'TSTOD2' ENTRY      55240015
         LA    DSR,DES2                2ND OPERAND ADDRESS              55280015
TSDL1    TM    DESFLG(DSR),X'C0'                                        55320015
         BC    BNE,4(RR)               RETURN IF NOT DICT REF           55360015
         CLI   DESBSE(DSR),0                                            55400015
         BC    BNE,4(RR)               RETURN IF DICT REF NOT X'00--'   55440015
         ST    RR,CVTRR                                                 55480015
         TM    CPX,X'80'                                                55520015
         BC    BZ,TSDL3                BRANCH IF 'TSTOD2' ENTRY         55560015
         TM    DESCDE(DSR),X'06'                                        55600015
         BC    BZ,TSDL5                BRANCH IF PACKED DECIMAL         55640015
         TM    DESCDE(DSR),X'01'                                        55680015
         BC    BZ,TSDL2                BRANCH IF REAL OPERAND           55720015
*              COMPLEX OPERAND - CAN ONLY BE REAL PART OF COMPLEX CONST 55760015
         OI    REGCOD,X'80'            SET FOR NO LOAD                  55800015
         BALR  RR,BR                   GET REGISTER                     55840015
         L     RR,CVTRR                                                 55880015
TSDL2    MVI   PCOPN(PCR),SR           SET OP CODE TO SR                55920015
         OC    PCOPN(1,PCR),OPTYP      SET TO CORRECT TYPE              55960015
         BC    B,TSDL4                                                  56000015
TSDL3    CLI   OPCOD,CPR                                                56040015
         BCR   BNE,RR                  RETURN IF NOT COMPARE            56080015
         TM    DESCDE(DSR),X'06'                                        56120015
         BC    BZ,TSDL6                BRANCH IF PACKED DECIMAL         56160015
         MVI   PCOPN(PCR),LTR          SET OPCODE TO LTR                56200015
         TM    DESCDE(DSR),X'02'                                        56240015
         BC    BZ,TSDL4                BRANCH IF FIXED BINARY           56280015
         MVI   PCOPN(PCR),LTER         SET OPCODE TO LTER               56320015
         TM    DESCDE(DSR),X'10'                                        56360015
         BC    BZ,TSDL4                BRANCH IF SHORT FLOAT            56400015
         MVI   PCOPN(PCR),LTDR         SET OPCODE TO LTDR               56440015
TSDL4    MVC   PCOD1(2,PCR),REG                                         56480015
         MVC   PCOD2(2,PCR),REG        GENERATE  SR   REG,REG           56520015
         LA    PCR,5(PCR)              BUMP PC POINTER                  56560015
         MVC   DESBSE(2,DSR),REG       RESET OPERAND TO REGISTER BY     56600015
         MVI   DESFLG(DSR),X'80'     VALUE.                             56640015
         BCR   B,RR                    RETURN                           56680015
TSDL5    SR    G0,G0                   SET SHIFT TO ZERO                56720015
TSDL6    LA    STR,DEPDZ                                                56760015
         BAL   RR,DECNST               CREATE DICT ENTRY FOR P-D ZERO   56800015
         MVC   DESBSE(2,DSR),DCCHN(STR)  SET DIC REF IN DESCRIPTION     56840015
         L     RR,CVTRR                                                 56880015
         MVI   DESP(DSR),1             SET PRECISION TO 1               56920015
         MVI   DESLTH+1(DSR),1         SET LENGTH TO 1                  56960015
         MVI   DESTK(DSR),X'80'        SET CONSTANT MARKER              57000015
         TM    CPX,X'80'                                                57040015
         BCR   BO,RR                   RETURN IF 'TSTOD1' ENTRY         57080015
         BC    B,4(RR)                 RETURN                           57120015
         EJECT                                                          57160015
*              GENERATE PACKED DECIMAL PSEUDO-CODE.                     57200015
*                                                                       57240015
*              FUNCTION - GENERATE PSEUDO-CODE FOR PACKED DECIMAL       57280015
*        ARITHMETIC OPERATIONS.                                         57320015
*                                                                       57360015
*              ENTRY POINT - 'GENRPD'. OPERAND DESCRIPTIONS ARE IN      57400015
*        'DES1' AND 'DES2'. RESULT DED IS IN DESCRIPTION 'DEST'.        57440015
*        OPERATOR IS IN OPCOD. REGISTER G0 CONTAINS SHIFT.              57480015
*                                                                       57520015
*              EXTERNAL ROUTINES (1) 'SETCPX' IN BLOCK 'LU' TO INITIAL- 57560015
*        ISE COMPLEX ARITHMETIC.                                        57600015
*                                (2) 'TSTOD1','TSTOD2' IN BLOCK LS TO   57640015
*        TEST FOR MISSING OPERANDS.                                     57680015
*                                (3) 'ASSIGN' IN BLOCK LS TO GENERATE   57720015
*        ASSIGN TRIPLE TO SHIFT PACKED DECIMAL.                         57760015
*                                (4) 'GETADX','GETADS','GETAS1' IN      57800015
*        BLOCK LT TO SET UP OPERANDS IN PSEUDO-CODE.                    57840015
*                                (5) 'SWOP' IN BLOCK LS TO INTERCHANGE  57880015
*        OPERANDS.                                                      57920015
*                                (6) 'CPLXPD' IN BLOCK LS TO START      57960015
*        COMPLEX 2ND PASS.                                              58000015
*                                                                       58040015
*              EXIT-NORMAL - TO 'RESLT1' IN BLOCK LT.                   58080015
*                                                                       58120015
*              EXIT-ERROR - NONE.                                       58160015
*                                                                       58200015
*              NOTES - NO REGISTERS ARE PRESERVED.                      58240015
         EJECT                                                          58280015
GENRPD   CLI   OPCOD,MULT                                               58320015
         BC    BNL,LBFX15              BRANCH IF MULT OR DIVIDE         58360015
         CLI   OPND+1,1                                                 58400015
         BC    BZ,LBFX15               BRANCH IF UNARY                  58440015
         LTR   G0,G0                   TEST SHIFT                       58480015
         BC    BZ,LFX12A               BRANCH IF ZERO                   58520015
         XI    ARCOD,X'10'             CHANGE SWOP BIT                  58560015
LFX12A   CLI   AMDBUF+DESFLG,0                                          58600015
         BC    BZ,LBFX13               BRANCH IF NOT AMD FUNCTION       58640015
         LA    G1,1(G1)                BUMP PRECISION BY 1              58680015
         CH    G1,H32                  TEST IF RESULT IN 16 BYTES       58720015
         BC    BL,LBFX14               BRANCH IF IN 16 BYTES            58760015
         LA    BR,FNADD                                                 58800015
         TM    DEST+DESCDE,X'01'                                        58840015
         BC    BZ,ADDFUN               BRANCH IF REAL                   58880015
         LA    BR,4(BR)                                                 58920015
         BC    B,ADDFUN                GO TO SET UP CALL SEQ TO LIBRARY 58960015
LBFX13   CH    G1,H32                  TEST PRECISION                   59000015
         BC    BL,LBFX14               BRANCH IF 31 OR LESS             59040015
         SR    G0,G1                   MODIFY SHIFT                     59080015
         LA    G1,31                   NEW PRECISION =31                59120015
         AR    G0,G1                   NEW SHIFT = S - (TOT P - 31)     59160015
         AH    G0,ONE+2              ADD ONE                            59180015
         STH   G0,SHFT1                                                 59200015
LBFX14   LA    G0,2(G1)                                                 59240015
         SRL   G0,1                    WORKSPACE SIZE IN BYTES          59280015
LBFX15   STH   G0,DEST+DESNDX                                           59320015
         AR    G0,G0                                                    59360015
         BCTR  G0,0                    PRECISION OF WORKSPACE           59400015
         STH   G0,SHFT1+2                                               59440015
         CH    G1,BIGN                                                  59480015
         BC    BNH,LBFX18                                               59520015
         LH    G1,BIGN                                                  59560015
LBFX18   STC   G1,DEST+DESP            NORMAL PRECISION                 59600015
         CLI   AMDBUF+DESFLG,0                                          59640015
         BC    BZ,LBFX19               BRANCH IF NOT AMD FUNCTION       59680015
         CLI   OPCOD,DIV                                                59720015
         BC    BZ,LBFX19               BRANCH IF DIVIDE FUNCTION        59760015
         AR    GRN,G0                  FUNCTION SHIFT                   59800015
         SH    GRN,BIGN                                                 59840015
         BC    BH,LBFX16               BRANCH IF GREATER THAN ZERO      59880015
         SR    GRN,GRN                                                  59920015
LBFX16   CR    GRN,G0                                                   59960015
         BC    BNH,LBFX17                                               60000015
         LR    GRN,G0                                                   60040015
LBFX17   STH   GRN,SHFT2               2ND SHIFT                        60080015
         SR    G0,GRN                                                   60120015
         STC   G0,DEST+DESP            INTERMEDIATE RESULT PRECISION    60160015
         BC    B,LBFX20                GO TO GENERATE CODE              60200015
LBFX19   SR    G0,G1                                                    60240015
         STH   G0,SHFT2                                                 60280015
         NI    SHFT2+1,X'FE'           MAKE SHIFT EVEN-MVN NOT WANTED   60320015
LBFX20   L     G1,CSTK                 PUT CURRENT TOP OF STACK IN      60360015
         STH   G1,DEST+DESBSE        RESULT DESCRIPTION.                60400015
         MVI   DEST+DESFLG,X'C0'       SET FLAG FOR TEMP CORE           60440015
         CLI   DEST+DESP,6             TEST PRECISION                   60480015
         BC    BNH,LBFX35              BRANCH IF SHORT                  60520015
         OI    DEST+DESCDE,X'10'       SET TO LONG                      60560015
LBFX35   BAL   RR,SETCPX               SET COMPLEX RETURN               60600015
         TM    ARCOD,X'10'                                              60640015
         BC    BZ,LBFX38               BRANCH IF NO SWOP                60680015
         BAL   RR,SWOP                 SWOP OPERANDS                    60720015
         BC    B,LBFX39                                                 60760015
LBFX38   BAL   RR,TSTOD1               TEST 1ST OPND FOR COMPLEX ZERO   60800015
         BC    B,LBFX48                                                 60840015
LBFX39   LH    G0,SHFT1                                                 60880015
LBFX48   LA    DSR,DES1                                                 60920015
         LTR   G0,G0                   TEST SHIFT                       60960015
         BC    BNE,LBFX36              BRANCH IF SHIFT REQUIRED         61000015
         CLI   OPCOD,CPR                                                61040015
         BC    BNE,LBFX36              BRANCH IF NOT COMPARE            61080015
         STH   G0,DEST+DESNDX          COMPARE SAME SF'S,SO CLEAR       61120015
         LH    G0,DES1+DESLTH        WORKSPACE AND POINT AT 1ST OPERAND 61160015
         BC    B,LBFX37              FOR 1ST INSTRUCTION                61200015
LBFX36   MVC   DESBUF(ISTK),DEST                                        61240015
         LH    G1,SHFT1+2                                               61280015
         STC   G1,DESBUF+DESP          RESET APPARENT PRECISION         61320015
         IC    G1,DES1+DESQ            1ST OPERAND SCALE FACTOR         61360015
         AR    G1,G0                   ADD SHIFT                        61400015
         STC   G1,DESBUF+DESQ          WORKSPACE SCALE FACTOR           61440015
         NI    DESBUF+DESCDE,X'FE'     SET TARGET TO REAL               61480015
         OI    RELCOD,X'08'            SET FOR NO DROP IF XR            61520015
         BAL   RR,ASSIGN               GENERATE ASSIGN FOR P-D SHIFT    61560015
         LA    DSR,DEST                                                 61600015
         TM    ARCOD,X'40'                                              61640015
         BC    BZ,LBFX31               BRANCH IF NO SWOP WITH -         61680015
         MVI   OPCOD,SUB            MOVE SUBTRACT TO OPCODE       14876 61780017
LBFX31   LH    G0,DEST+DESNDX          RESULT LENGTH                    62000015
LBFX37   CLI   OPND+1,1                                                 62040015
         BC    BZ,LFX37A           BRANCH IF UNARY OPERATION      14876 62080017
         ST    DSR,STGDSR              SAVE REGISTER                    62120015
         BAL   RR,TSTOD2                                                62160015
         BC    B,LFX37B                GO IF 2ND OPND COMPLEX 0   14876 62169017
         BC    B,LFX37C                BRANCH IF NOT              14876 62178017
LFX37B   TM    ARCOD,X'40'                                        14876 62187017
         BC    BZ,LBFX40               BRANCH IF NO SWAP WITH -   14876 62196017
         LA    DSR,DES2                SET UP PD 0 AS 2ND OPND    14876 62205017
         LA    STR,DEPDZ                                          14876 62214017
         BAL   RR,DECNST               CREATE DIC ENTRY FOR PD 0  14876 62223017
         MVC   DESBSE(2,DSR),DCCHN(STR)   SET DIC REF IN DESCRIP  14876 62232017
         MVI   DESP(DSR),1             SET PRECISION TO 1         14876 62241017
         MVI   DESLTH+1(DSR),1         SET LENGTH TO 1            14876 62250017
         MVI   DESTK(DSR),X'80'        SET CONSTANT MARKER        14876 62259017
LFX37C   BCTR  G0,0                    LENGTH-1                   14876 62268017
         SLL   G0,4                    SHIFT TO TOP OF BYTE             62280015
         AH    G0,DES2+DESLTH          2ND OPERAND LENGTH               62320015
         BCTR  G0,0                    LENGTH-1                         62360015
         STC   G0,PCF1(PCR)            STORE IN PC                      62400015
         MVC   PCOPN(1,PCR),OPCOD      SET ARITHMETIC OPERATION AND SET 62440015
         OI    PCOPN(PCR),PKD        TO PACKED DECIMAL.                 62480015
         L     DSR,STGDSR              RESTORE REGISTER                 62520015
         BAL   RR,GETAS1               SET RESULT AS PC 1ST OPERAND     62560015
         LA    DSR,DES2                                                 62600015
         BAL   RR,GETADS               SET 2ND OPERAND AS PC 2ND OPND   62640015
LFX37A   TM    ARCOD,X'40'                                        14876 62643017
         BC    BZ,LBFX40           BRANCH IF NO SWAP WITH -       14876 62646017
         MVC   0(LPCI7,PCR),PCIN7  PC SKELETON FOR XI -,X'01'     14876 62649017
         LA    DSR,DEST                                           14876 62652017
         LH    G0,DEST+DESNDX      WORKSPACE SIZE                 14876 62655017
         BCTR  G0,0                SUBTRACT 1                     14876 62658017
         STH   G0,DEST+DESOFS      STORE AS 2ND OFFSET            14876 62661017
         OI    DEST+DESFLG,X'10'  SET FLAG                        14876 62664017
         BAL   RR,GETADX           SET 2ND OPERAND IN PC          14876 62667017
         MVI   DEST+DESFLG,X'C0'  RESET FLAG                      14876 62670017
LBFX40   LH    G1,DEST+DESNDX          WORKSPACE SIZE                   62680015
         TM    DEST+DESCDE,X'01'                                        62720015
         BC    BZ,LBFX41               BRANCH IF REAL RESULT            62760015
         CLI   OPCOD,CPR                                                62800015
         BC    BZ,CPLXPD               BRANCH IF COMPLEX COMPARE        62840015
         CLI   CPX+1,0                                                  62880015
         BC    BZ,LBFX42               BRANCH IF 2ND PASS               62920015
         AH    G1,DEST+DESBSE                                           62960015
         STH   G1,DEST+DESBSE          BUMP RESULT ADDRESS TO IMAG PART 63000015
         BC    B,CPLXPD                RETURN FOR 2ND PASS              63040015
LBFX41   CLI   OPCOD,CPR                                                63080015
         BC    BZ,RESLT1               BRANCH IF COMPARE                63120015
LBFX42   CLI   OPCOD,DIV                                                63160015
         BC    BNE,LBFX43              BRANCH IF NOT DIVIDE             63200015
         TM    DEST+DESCDE,X'01'                                        63240015
         BC    BZ,LBFX49               BRANCH IF REAL DIVIDE            63280015
LBFX43   LH    G0,SHFT2                2ND SHIFT IN DIGITS              63320015
         SRA   G0,1                    IN BYTES = X                     63360015
         BC    BZ,LBFX44               BRANCH IF NO 2ND SHIFT           63400015
         SR    G1,G0                                                    63440015
         STH   G1,DEST+DESNDX          RESULT LENGTH                    63480015
         OI    DEST+DESFLG,X'10'                                        63520015
LBFX46   STH   G0,DEST+DESOFS          SET 2ND OFFSET                   63560015
         MVI   PCF1(PCR),X'77'         SET PC LENGTHS FOR DIVIDE        63600015
         CLI   OPCOD,DIV                                                63640015
         BC    BZ,LBFX47               BRANCH IF DIVIDE                 63680015
*              INSERT OVERFLOW TESTS                                    63720015
         TM    SHFT2+1,X'01'                                            63760015
         BC    BZ,LFX46A               BRANCH IF EVEN 2ND SHIFT         63800015
         MVI   PCOPN(PCR),MVZ          GENERATE  MVZ  T(1),T+X          63840015
         MVI   PCF1(PCR),0             LENGTH =1                        63880015
         LA    DSR,DESBUF                                               63920015
         BAL   RR,GETAS1                                                63960015
         LA    DSR,DEST                                                 64000015
         BAL   RR,GETADS                                                64040015
         LH    G1,DEST+DESNDX                                           64080015
LFX46A   BCTR  G1,0                                                     64120015
         SLL   G1,4                                                     64160015
         AH    G1,DESBUF+DESNDX                                         64200015
         BCTR  G1,0                                                     64240015
         STC   G1,PCF1(PCR)            SET LENGTHS FOR SS INSTRUCTION   64280015
LBFX47   MVI   PCOPN(PCR),ZAP          GENERATE   ZAP  DEST,DESBUF      64320015
         LA    DSR,DEST                                                 64360015
         BAL   RR,GETAS1               SET 1ST OPERAND IN PC            64400015
         LA    DSR,DESBUF                                               64440015
         BAL   RR,GETADS               SET 2ND OPERAND IN PC            64480015
LBFX44   TM    DEST+DESCDE,X'01'                                        64520015
         BC    BZ,LBFX49               BRANCH IF REAL RESULT            64560015
         LH    G1,DEST+DESNDX          RESULT LENGTH                    64600015
         CLI   CPX+1,0                                                  64640015
         BC    BNE,LBFX45              BRANCH IF 2ND ZAP GENERATED      64680015
         MVI   CPX+1,X'FF'                                              64720015
         L     G0,CSTK                                                  64760015
         STH   G0,DEST+DESBSE                                           64800015
         STH   G0,DESBUF+DESBSE                                         64840015
         LH    G0,DESBUF+DESNDX        WORKSPACE LENGTH                 64880015
         SR    G0,G1                                                    64920015
         AR    G0,G0                                                    64960015
         BC    BH,LBFX46               BRANCH IF 2ND ZAP NEEDED         65000015
LBFX45   AR    G1,G1                                                    65040015
         STH   G1,DEST+DESNDX          DOUBLE LENGTH OF COMPLEX RESULT  65080015
LBFX49   CLI   AMDBUF+DESFLG,0                                          65120015
         BC    BZ,RESLT1               FINISH IF NOT AMD FUNCTION       65160015
         LA    DSR,DEST                                                 65200015
         BAL   RR,ADDSTK               ADD RESULT TO STACK              65240015
         LA    G1,1                                                     65280015
         AH    G1,NTMP                                                  65320015
         STH   G1,NTMP                 BUMP NUMBER OF TEMPS             65360015
         MVI   DESBUF+DESFLG,X'C0'                                      65400015
         MVC   DESBUF+DESCDE(3),AMDBUF+DESCDE   FUNCTION DED            65440015
         MVC   DESBUF+DESBSE(2),CSTK+2          WORKSPACE OFFSET        65480015
         IC    G1,DESBUF+DESP          FUNCTION PRECISION               65520015
         LA    G1,2(G1)                                                 65560015
         SLL   G1,1                    BYTE LENGTH                      65600015
         TM    DESBUF+DESCDE,X'01'                                      65640015
         BC    BZ,LBFX50               BRANCH IF REAL                   65680015
         AR    G1,G1                   COMPLEX,SO DOUBLE LENGTH         65720015
LBFX50   STH   G1,DESBUF+DESNDX                                         65760015
         BAL   RR,ASSIGN               ASSIGN TO FUNCTION (P,Q)         65800015
         MVC   DEST(ISTK),DESBUF       RESET RESULT DESCRIPTION         65840015
         BC    B,RESLT1                FINISH                           65880015
         EJECT                                                          65920015
* TRT TABLE ENTRIES                                                     65960015
*      OPERATOR     IF FOR SCAN ONLY    FOR SCAN AND USER               66000015
*       FORMAT               4                40                        66040015
*       FORMAT'              8                44                        66080015
*       PROC                12                48                        66120015
*       BEGIN               16                52                        66160015
*       PROC'               20                56                        66200015
*       BEGIN'              24                60                        66240015
*       JMP                 28                64                        66280015
*       SN,SL,CN,CL,SN2     32                68                        66320015
*       ERROR               36                72                        66360015
*                                                                       66400015
*              LAYOUT OF SCAN PARAMETER BLOCK                           66440015
SCTRT    EQU   0                       INDICATES TRIPLES OF INTEREST    66480015
*              BEGINNING OF FULL-WORD ITEMS                             66520015
SCEOBI   EQU   SCTRT+256               ABSOLUTE ADRESS OF END OF IP BLK 66560015
SCEOBO   EQU   SCEOBI+4                ABSOLUTE ADRESS OF END OF OP BLK 66600015
SCJMP    EQU   SCEOBO+4                SYMBOLIC POSITION OF JMP TRIPLE  66640015
SCPCG    EQU   SCJMP+4                 COUNT OF PSEUDOCODE GENERATED    66680015
SCTXTI   EQU   SCPCG+4                 SYMB NAME OF IP BLOCK IN BYTE 2  66720015
SCTXTO   EQU   SCTXTI+4                SYMB NAME OF OP BLOCK IN BYTE 2  66760015
SCWKSC   EQU   SCTXTO+4                CURRENT WORKSPACE COUNT          66800015
SCWKS    EQU   SCWKSC                                                   66840015
*              END OF FULL-WORD ITEMS                                   66880015
SCBLK    EQU   SCWKSC+4                DICT REFERENCE OF CURRENT BLOCK  66920015
SCSTK    EQU   SCBLK+2                 CURRENT REGISTER USAGE           66960015
SCWSDR   EQU   SCSTK+2                 DICT REF OF CURRENT WORKSPACE    67000015
*              END OF 2-BYTE ITEMS                                      67040015
SCOPT    EQU   SCWSDR+2                PRE-FIX OPTION BYTE              67080015
*              END OF 1-BYTE ITEMS                                      67120015
         EJECT                                                          67160015
*              WORKSPACE.                                               67200015
BGWS     EQU   4096+NAME                                                67240015
         SPACE 2                                                        67280015
*              TRT TABLE TO SCAN TRIPLES,SCAN PARAMETER BLOCK.          67320015
SCPARM   EQU   BGWS                                                     67360015
ASSIGN   EQU   296+SCPARM              TRANSFER VECTORS TO BLOCK LR     67400015
SETMPD   EQU   4+ASSIGN                                                 67440015
DECNST   EQU   4+SETMPD                                                 67480015
SWOP     EQU   4+DECNST                                                 67520015
STALRG   EQU   4+SWOP                                                   67560015
GNSHFT   EQU   4+STALRG                                                 67600015
CPROD1   EQU   4+GNSHFT                                                 67640015
CPROD2   EQU   4+CPROD1                                                 67680015
ERROR1   EQU   4+CPROD2                                                 67720015
CERROR   EQU   4+ERROR1                                                 67760015
ERROR    EQU   4+CERROR                                                 67800015
         SPACE                                                          67840015
*              FULL-WORD CONSTANTS                                      67880015
ONE      EQU   4+ERROR       (DC  F'1')                                 67920015
TWO      EQU   4+ONE         (DC  F'2')                                 67960015
H2       EQU   2+TWO         (DC  H'2')                                 68000015
THREE    EQU   4+TWO         (DC  F'3')                                 68040015
FOUR     EQU   4+THREE       (DC  F'4')                                 68080015
SEVEN    EQU   4+FOUR        (DC  F'7')                                 68120015
H7       EQU   2+SEVEN       (DC  H'7')                                 68160015
F12      EQU   4+SEVEN       (DC  F'12')                                68200015
F63      EQU   4+F12         (DC  F'63')                                68240015
DBMULT   EQU   4+F63         (DC  X'00351EB8')   3.32 SCALED (31,20)    68280015
CEIL1    EQU   4+DBMULT      (DC  X'000FFFFF')   ROUND UP               68320015
         SPACE 1                                                        68360015
*              HALF-WORD CONSTANTS.                                     68400015
H32      EQU   4+CEIL1       (DC  H'32')                                68440015
FLMAXP   EQU   2+H32         (DC  H'53')    MAY FLOAT BINARY PRECISION  68480015
SF0      EQU   2+FLMAXP      (DC  H'128')   ZERO SCALE FACTOR           68520015
FXMAXP   EQU   2+SF0         (DC  H'31')    MAX FIXED BINARY PRECISION  68560015
MAXSF    EQU   2+FXMAXP      (DC  H'255')   MAX SCALE FACTOR            68600015
         SPACE 1                                                        68640015
*              DICTIONARY ENTRY LIST FOR LIBRARY SUBROUTINE NAMES.      68680015
*              EXPONENTIALS.                                            68720015
EXPSUB   EQU   4+MAXSF       (DC  A(X'C2B6'))    IHEXXL                 68760015
*                            (DC  A(X'C2B0'))    IHEXIL                 68800015
*                            (DC  A(X'C2B7'))    IHEXXS                 68840015
*                            (DC  A(X'C2B1'))    IHEXIS                 68880015
EXPPKD   EQU   16+EXPSUB     (DC  A(X'C2AF'))    IHEXID                 68920015
PKDEXP   EQU   EXPPKD-EXPSUB                                            68960015
EXPFXB   EQU   4+EXPPKD      (DC  A(X'C2AE'))    IHEXIB                 69000015
FXBEXP   EQU   EXPFXB-EXPSUB                                            69040015
EXPCPX   EQU   4+EXPFXB      (DC  A(X'C2B9'))    IHEXXZ                 69080015
CPXEXP   EQU   EXPCPX-EXPSUB                                            69120015
*                            (DC  A(X'C2B5'))    IHEXIZ                 69160015
*                            (DC  A(X'C2B8'))    IHEXXW                 69200015
*                            (DC  A(X'C2B4'))    IHEXIW                 69240015
*                            (DC  A(X'C2B3'))    IHEXIV                 69280015
*                            (DC  A(X'C2B2'))    IHEXIV                 69320015
*              COMPLEX MULT1PLY,DIVIDE.                                 69360015
CPXSUB   EQU   24+EXPCPX     (DC  A(X'C271'))    IHEMZZ0                69400015
*                            (DC  A(X'C24A'))    IHEDZZ0                69440015
*                            (DC  A(X'C270'))    IHEMZW0                69480015
*                            (DC  A(X'C249'))    IHEDZW0                69520015
*                            (DC  A(X'C26F'))    IHEMZVM                69560015
*                            (DC  A(X'C26E'))    IHEMZVD                69600015
CPXFXB   EQU   24+CPXSUB     (DC  A(X'C26D'))    IHEMZUM                69640015
FXBCPX   EQU   CPXFXB-CPXSUB                                            69680015
*                            (DC  A(X'C26C'))    IHEMZUD                69720015
CPXAMD   EQU   8+CPXFXB      (DC  A(X'C2C4'))    IHEMPV0                69760015
AMDSUB   EQU   CPXAMD-CPXSUB-PKDEXP                                     69800015
*                            (DC  A(X'C2C2'))    IHEDVV0                69840015
*                            (DC  A(X'C2C3'))    IHEMPU0                69880015
*                            (DC  A(X'C2C1'))    IHEDVU0                69920015
ADDFN    EQU   16+CPXAMD     (DC  A(X'C2BF'))    IHEADD0                69960015
FNADD    EQU   ADDFN-CPXAMD                                             70000015
*                            (DC  A(X'C2C0'))    IHEADV0                70040015
         SPACE 1                                                        70080015
*              DESCRIPTIONS.                                            70120015
PSIDES   EQU   8+ADDFN       (DC  X'00C000000000000OFF00') PSI VAR      70160015
BITDES   EQU   10+PSIDES     (DC  X'C0280001000000010000') COMPARE RSLT 70200015
CHARST   EQU   10+BITDES     (DC  X'880580')  CHAR STRING TO ARITH      70240015
BITST    EQU   3+CHARST      (DC  X'8C0F80')  BIT STRING TO ARITH       70280015
FIXBIN   EQU   3+BITST       (DC  X'9C1F80')  FIXED BINARY(31,0)        70320015
PTRDES   EQU   3+FIXBIN                POINTER DED                      70360015
         SPACE 1                                                        70400015
*              BLOCK NAMES.                                             70440015
NAMBK1   EQU   3+PTRDES      (DC  C'LSLTLU')                            70480015
NAMBK4   EQU   6+NAMBK1      (DC  C'ZZ'    )                            70520015
NAMBK5   EQU   2+NAMBK4      (DC  C'LWLXZZ')                            70560015
NAMBK6   EQU   8+NAMBK5           ( DC  MPZZ)                           70600015
NAMBK7   EQU   4+NAMBK6      (DC  C'LV')                                70640015
         SPACE 1                                                        70680015
*              PSEUDO-CODE SKELETONS.                                   70720015
DROPPC   EQU   2+NAMBK7                          DROP SR1,DROP SR2      70760015
PCIN1    EQU   6+DROPPC                          SR   GRO,GRO           70800015
LPCI1    EQU   5                                                        70840015
PCIN2    EQU   LPCI1+PCIN1                       SRDA GRE,X             70880015
LPCI2    EQU   3                                                        70920015
PCIN3    EQU   LPCI2+PCIN2                       SLDA GRE,X             70960015
LPCI3    EQU   3                                                        71000015
PCIN4    EQU   LPCI3+PCIN3                                              71040015
PCN1     EQU   PCIN4                             BC   BNE,LBL           71080015
LPCN1    EQU   5                                                        71120015
*                                                NR   GRO,GRO           71160015
*                                                BC   BZ,LBL            71200015
*                                                LTR  GRE,GRE           71240015
PCN2     EQU   15+PCIN4                LBL   EQU  *                     71280015
LPCN2    EQU   3                                                        71320015
LPCI4    EQU   18                                                       71360015
PCIN5    EQU   LPCI4+PCIN4                       MVI  **,X'00'          71400015
*                                                BC   MASK,LBL          71440015
*                                                MVI  **,X'80'          71480015
*                                           LBL  EQU  *                 71520015
LPCI5    EQU   24                                                       71560015
PCIN7    EQU   LPCI5+PCIN5                       XI   **,X'01'          71600015
LPCI7    EQU   3                                                        71640015
PCIN10   EQU   LPCI7+PCIN7                       IPRM                   71680015
*                                                LA   RA,**             71720015
LPCI13   EQU   6                                                        71760015
PCIN14   EQU   8+PCIN10                          LA   RB,**             71800015
LPCI11   EQU   11                                                       71840015
LPCI14   EQU   3                                                        71880015
PCIN15   EQU   5+PCIN14                          LA   RC,**             71920015
LPCI15   EQU   3                                                        71960015
LPCI10   EQU   16                                                       72000015
PCIN12   EQU   LPCI10+PCIN10                     L    BR,**             72040015
*                                                BALR RR,BR             72080015
*                                                IPRM'                  72120015
LPCI12   EQU   13                                                       72160015
PCIN16   EQU   LPCI12+PCIN12                     LA   RD,**             72200015
LPCI16   EQU   3                                                        72240015
PCIN17   EQU   LPCI16+PCIN16                     LA   RE,**             72280015
LPCI17   EQU   3                                                        72320015
PCIN18   EQU   LPCI17+PCIN17                     LA   RF,**             72360015
LPCI18   EQU   3                                                        72400015
PCIN19   EQU   LPCI18+PCIN18                     STM  RA,RF,**          72440015
*                                                LA   RA,**             72480015
LPCI19   EQU   13                                                       72520015
         SPACE 1                                                        72560015
*              DICTIONARY ENTRY SKELETONS.                              72600015
         SPACE                                                          72640015
DEDED2   EQU   LPCI19+PCIN19 (DC  X'C1000B0000000000000000')  DED2      72680015
DEBIFN   EQU   11+DEDED2     (DC  X'C2000E0000000000000000000101') BIF  72720015
DECON    EQU   14+DEBIFN     (DC  X'88000E0000000000010000000000') CONS 72760015
DEFL1    EQU   14+DECON      (DC  X'88001200008A0600C08A06000000'       72800015
*                             DC  X'41100000')    FLOAT '1.0'           72840015
DEPDZ    EQU   18+DEFL1      (DC  X'88000F000088018000880180000000') Z  72880015
         SPACE 1                                                        72920015
*              ERROR CODES.                                             72960015
ERR40    EQU   15+DEPDZ      (DC  X'064040')     ILLEGAL REG NUMBER     73000015
ERR41    EQU   3+ERR40       (DC  X'064140)      MORE THAN 200 TEMPS    73040015
ERR42    EQU   3+ERR41       (DC  X'064240')     NOT ENOUGH TEMPS       73080015
ERR43    EQU   3+ERR42       (DC  X'064300')     BAD COUNT OF FLOAT REG 73120015
ERR44    EQU   3+ERR43       (DC  X'064440')     REG 2ND OPN FOR RS,SS  73160015
ERR45    EQU   3+ERR44       (DC  X'064544')     SF OVER/UNDERFLOW      73200015
ERR46    EQU   3+ERR45       (DC  X'064640')     SINGLE TMPD ONLY       73240015
ERR47    EQU   3+ERR46       (DC  X'064754')     'LEFT' TYPE IN EXPRESS 73280015
ERR48    EQU   3+ERR47       (DC  X'064848')     ILLEGAL COMPLEX COMPAR 73320015
ERR49    EQU   3+ERR48       (DC  X'064940')     ILLEGAL DICT REF       73360015
ERR4D    EQU   3+ERR49       (DC  X'064D54')     ILLEGAL ARRAY OR STRUC 73400015
ERRSR    EQU   3+ERR4D       (DC  X'062100')     SYMBOLIC REG OVERFLOW  73440015
NDCON    EQU   3+ERRSR                                                  73480015
         EJECT                                                          73520015
MODU8    EQU   NDCON+7-BGWS                                             73560015
DBLE     EQU   MODU8/8*8                                                73600015
BGVAR    EQU   BGWS+DBLE               BEGINNING OF VARIABLE WORKSPACE  73640015
*              VARIABLES (BLOCK 1 )                                     73680015
EXPBUF   EQU   BGVAR        (DS  D )   D-WORD BUFFER FOR EXPONENTIALS   73720015
DCDSRR   EQU   BGVAR          (DS F )  RETURN REGISTER FOR DICDES       73760015
DEAVRR   EQU   4+DCDSRR     (DS  F )   RETURN REGISTER FOR DEAUVR       73800015
ASGNRR   EQU   DEAVRR       (DS  F )   RETURN REGISTER FOR ASSIGN       73840015
STBR     EQU   4+DEAVRR     (DS  F )   BRANCH REGISTER                  73880015
ALRGRR   EQU   4+STBR       (DS  F )   RETURN REGISTER FOR STALRG       73920015
REGSUB   EQU   4+ALRGRR     (DS  F )   REGISTER SUBROUTINE ADDRESS      73960015
SHFT1    EQU   4+REGSUB     (DS  F )   1ST SHIFT DESCRIPTION            74000015
SHFT2    EQU   4+SHFT1      (DS  F )   2ND SHIFT DESCRIPTION            74040015
CPXRET   EQU   4+SHFT2      (DS  F )   COMPLEX RETURN REGISTER          74080015
DES1     EQU   4+CPXRET      (DS 7H)   1ST OPERAND DESCRIPTION          74120015
DES2     EQU   TOTDES+DES1   (DS 7H)   2ND OPERAND DESCRIPTION          74160015
DEST     EQU   TOTDES+DES2   (DS 7H)   RESULT DESCRIPTION               74200015
NTMP     EQU   TOTDES+DEST   (DS H )   NO OF TEMPS USED                 74240015
OPND     EQU   2+NTMP       (DS  H )   NO OF OPERANDS IN USE            74280015
CPX      EQU   2+OPND       (DS  H )   COMPLEX CODE                     74320015
*                                      CPX = 0 FOR REAL   ,REAL   OPNDS 74360015
*                                          = 1     COMPLEX,REAL         74400015
*                                          = 2     REAL   ,COMPLEX      74440015
*                                          = 3     COMPLEX,COMPLEX      74480015
BIGN     EQU   2+CPX        (DS  H )   BIG N FOR FIXED ARITH            74520015
OPCOD    EQU   2+BIGN       (DS  C )   OPERATION CODE AFTER TRANSLATE   74560015
OPTYP    EQU   1+OPCOD      (DS  C )   OPERATION TYPE                   74600015
CPMASK   EQU   1+OPTYP      (DS  C )   COMPARE MASK TO BRANCH ON FALSE  74640015
ARCOD    EQU   1+CPMASK     (DS  C )   ARITHMETIC CODE BYTE             74680015
*                                       BIT 0 = 1 FOR NO SCALING SHIFT  74720015
*                                           1 = 1     SWOP WITH PD- OPN 74760015
*                                           2 = 1     NO LOAD IN SWOP   74800015
*                                       BIT 3 = 1     SWOP REQUIRED     74840015
*                                       BIT 4 = 1     CLEAR ODD REG     74880015
*                                       BIT 5 = 1     L-S CPX FLT FUNCT 74920015
         SPACE 2                                                        74960015
*             'GET ADDRESS' SUBROUTINE WORKSPACE                        75000015
GETRR    EQU   3+ARCOD      (DS  F )   RETURN REGISTER                  75040015
LDATA    EQU   4+GETRR      (DS  F )   NUMBER OF DROPS,DROP REG BUFFER  75080015
GETBUF   EQU   4+LDATA      (DS  H )   WORK SPACE                       75120015
SSFLG    EQU   2+GETBUF     (DS  C )   INTERMEDIATE FLAG FOR SS P-C     75160015
GETCOD   EQU   1+SSFLG      (DS  C )   CODE BYTE, SET AS FOLLOWS        75200015
MOVCOD   EQU   GETCOD                  USED FOR ENTRY POINT MOVEPC      75240015
*                                      BIT 0 = 1 FOR GETADX ENTRY       75280015
*                                            = 0     GETADS ENTRY       75320015
*                                      BIT 1 = 1     GETAS1 ENTRY       75360015
*                                      BIT 2 = 1     CONSTRUCT LA       75400015
         SPACE 2                                                        75440015
*              STACKING SUBROUTINE WORKSPACE                            75480015
STKVR1   EQU   1+GETCOD                BEGINNING OF VARIABLES FOR STACK 75520015
STKRR    EQU   STKVR1       (DS  F )   RETURN REGISTER                  75560015
STKG1    EQU   4+STKRR      (DS  F )   ARGUMENT REGISTER                75600015
ASTK     EQU   4+STKG1      (DS  F )   LOW LIMIT OF SEARCH DOWN DES STK 75640015
BSTK     EQU   4+ASTK       (DS  F )   BEGINNING OF DESCRIPTION STACK   75680015
MSTK     EQU   4+BSTK       (DS  F )   UPPER LIMIT OF DESCRIPTION STACK 75720015
LSTK     EQU   4+MSTK       (DS  F )   LOGICAL TOP DESCRIPTION          75760015
PSTK     EQU   4+LSTK       (DS  F )   PHYSICAL TOP DESCRIPTION         75800015
CSTK     EQU   4+PSTK       (DS  F )   CURRENT TOP OF CORE STACK        75840015
STKBUF   EQU   4+CSTK       (DS  F )   WORK SPACE                       75880015
RELCOD   EQU   4+STKBUF     (DS  C )   CODE BYTE, SET AS FOLLOWS        75920015
*                                      BIT 0 =1 - USING RLSTK1 ENTRY    75960015
*                                            =0 - USING RELSTK ENTRY    76000015
*                                      BIT 1 =1 - ITEM BEEN RELEASED    76040015
*                                            =0 - NO ITEM RELEASED      76080015
*                                      BIT 2 =1 - USING ITEM2 ENTRY     76120015
*                                            =0 - NOT ITEM2 ENTRY       76160015
*                                      BIT 4 =1 - NO REG DROP NEEDED    76200015
GETLW    EQU   1+RELCOD     (DS  C )   FLAG FOR LOADING PHASE LW        76240015
         SPACE 2                                                        76280015
*             'GET REGISTER' SUBROUTINE WORK SPACE                      76320015
GRBLK    EQU   4+RELCOD     (DS  2F)   GENERAL REGISTER BLOCKS          76360015
FRBLK    EQU   2*4+GRBLK    (DS  4F)   FLOATING REGISTER BLOCKS         76400015
STRGRR   EQU   4*4+FRBLK    (DS  F )   RETURN REGISTER FOR STREG SUB    76440015
STGDSR   EQU   4+STRGRR      (DS F )   SAVE AREA FOR DSR REGISTER       76480015
REGRR    EQU   4+STGDSR      (DS F )   RETURN REGISTER                  76520015
REGDSR   EQU   4+REGRR      (DS  F )   ARGUMENT REGISTER                76560015
DESAD    EQU   4+REGDSR     (DS  F )   ADDRESS OF REGISTER BLOCK        76600015
REG      EQU   4+DESAD      (DS  H )   REGISTER ALLOCATED               76640015
LREG     EQU   2+REG        (DS  H )   REGISTER FOR LOAD                76680015
REGCOD   EQU   2+LREG       (DS  C )   CODE BYTE, BIT 0 = 1 FOR NO LOAD 76720015
*                                                 BIT 1 = 1 -NO STORE   76760015
*                                                 BIT 2 = 1 -CALL SEQ   76800015
*                                                 BIT 3=1 - SDR   16210 76820017
NGR      EQU   1+REGCOD     (DS  C )   NUMBER OF GENERAL REGS IN USE    76840015
NFR      EQU   1+NGR        (DS  C )   NUMBER OF FLOAT REGS IN USE      76880015
         SPACE 2                                                        76920015
*              SWOP SUBROUTINE WORK SPACE                               76960015
SWOPRR   EQU   2+NFR        (DS  F )   RETURN REGISTER                  77000015
DESBUF   EQU   4+SWOPRR      (DS 7H)   DESCRIPTION BUFFER               77040015
DMPRR    EQU   TOTDES+2+DESBUF (DS F ) DUMP RETURN REGISTER             77080015
         SPACE 2                                                        77120015
*              'CONVERT' SUBROUTINE WORKSPACE                           77160015
CVTRR    EQU   4+DMPRR       (DS F )   RETURN REGISTER                  77200015
CVTBUF   EQU   4+CVTRR       (DS F )   WORKSPACE                        77240015
CVTG0    EQU   4+CVTBUF      (DS F )   REGISTER G0                      77280015
CVTDSR   EQU   4+CVTG0       (DS F )   SAVE REGISTER DSR                77320015
         SPACE 2                                                        77360015
*              COMPLEX ROUTINE WORK SPACE.                              77400015
CPXBF1   EQU   4+CVTDSR     (DS  7H)   DES1,RESULT BUFFER               77440015
CPXBF2   EQU   14+CPXBF1    (DS  7H)   DES2 BUFFER                      77480015
         SPACE 2                                                        77520015
*              ADD,MULT,DIVIDE FUNCTION WORKSPACE.                      77560015
FNSTAT   EQU   14+CPXBF2    (DS  F )   FUNCTION STACK POINTER           77600015
AMDBUF   EQU   4+FNSTAT     (DS  F )   BUFFER FOR FUNCTION DED          77640015
         SPACE 2                                                        77680015
*              VARIABLES WITH EXTENDED SPACE REQUIREMENTS               77720015
FNBUF    EQU   4+AMDBUF     (DS  51C ) FUNCTION STACK                   77760015
MOD8     EQU   FNBUF+58-BGWS                                            77800015
DBL      EQU   MOD8/8*8                                                 77840015
BGPC     EQU   BGWS+DBL                128 BYTE PSEUDO-CODE BUFFER      77880015
NDPC     EQU   128+BGPC                                                 77920015
BGSTK    EQU   2096+BGWS    (DS 1000H) BEGINNING OF DESCRIPTION STACK   77960015
STKVR2   EQU   1000*2+BGSTK                                             78000015
         SPACE 2                                                        78040015
*                       DICTIONARY COMMUNICATIONS REGION (BASE = DICR)  78080015
D        EQU   4096+BGWS                                                78120015
ZMYNAM   EQU   D+112                   NAME OF CURRENT PHASE            78160015
ZSTAT    EQU   D+126                                                    78200015
PAR1     EQU   D+128                                                    78240015
PAR2     EQU   D+132                                                    78280015
PAR5     EQU   D+144                                                    78320015
PAR6     EQU   D+148                                                    78360015
PAR7     EQU   D+152                                                    78400015
PAR8     EQU   D+156                                                    78440015
CCCODE   EQU   D+232                   CODE BYTE FOR DECK PUNCH         78480015
STEXT    EQU   D+256                                                    78520015
ZTEXT    EQU   D+256                                                    78560015
ZTBSZE   EQU   D+264                                                    78600015
ZCOMM    EQU   D+304                   BASE OF PHASE COMMOM             78640015
ZFLAG3   EQU   ZCOMM+18                                                 78680015
ZSMREG   EQU   ZCOMM+40                CURRENT SYMBOLIC REGISTER NUMBER 78720015
Z2FILE   EQU   ZCOMM+44                                                 78760015
ZSTACH   EQU   ZCOMM+68                START OF STATIC CHAIN            78800015
ZCONCH   EQU   ZCOMM+76                BEGINNING OF CONSTANT CHAIN      78840015
ZEQMAX   EQU   ZCOMM+82                CURRENT COMPILER LABEL           78880015
ZOSMRG   EQU   ZCOMM+84                HIGHEST OPTIMISING SYMBOLIC REG  78920015
*                       TRANSFER VECTORS TO CONTROL PHASE (BASE = CTVR) 78960015
Z        EQU   4096+D                                                   79000015
ZUGC     EQU   Z+16                    ALLOCATE SCRATCH CORE            79040015
ZUTXTC   EQU   Z+20                    GET NEXT TEXT BLOCK              79080015
ZURC     EQU   Z+24                    RELEASE SCRATCH CORE             79120015
ZABORT   EQU   Z+32                    DUMP AND STOP                    79160015
ZLOAD    EQU   Z+36                    LOAD PHASE AND RETURN TO CALLER  79200015
ZDICRF   EQU   Z+44                    MAKE ENTRY IN DICTIONARY         79240015
ZUERR    EQU   Z+48                    ERROR MESSAGE                    79280015
ZDRFAB   EQU   Z+52                    CONTROL COMMS. OFFSET            79320015
ZDUMP    EQU   Z+56                                                     79360015
ZUDUMP   EQU   Z+56                    DUMP                             79400015
REQEST   EQU   Z+64                    MARK BLOCKS                      79440015
RLSCTL   EQU   Z+72                    RELEASE PHASES AND GO TO NEXT    79480015
ZTXTRF   EQU   Z+80                    TEXT ABS ADDRESS TO SYMBOLIC     79520015
ZTXTAB   EQU   Z+84                    TEXT SYMBOLIC ADDRESS TO ABS     79560015
ZCHAIN   EQU   Z+88                    GET NEXT TEXT BLOCK IN CHAIN     79600015
ZALTER   EQU   Z+92                    ALTER STATUS OF TEXT BLOCK       79640015
ZDABRF   EQU   Z+96                    DICT ABS ADDRESS TO SYMBOLIC     79680015
RLCTLX   EQU   Z+128                   RELEASE PHASES AND LOAD LV       79720015
         SPACE 2                                                        79760015
SC       EQU   4096+Z                  TRANSFER VECTORS TO SCAN         79800015
SCINIT   EQU   SC                                                       79840015
SC1      EQU   4+SCINIT                                                 79880015
SC2      EQU   4+SC1                                                    79920015
SC3      EQU   4+SC2                                                    79960015
SC4      EQU   4+SC3                                                    80000015
SC5      EQU   4+SC4                                                    80040015
SC6      EQU   4+SC5                                                    80080015
SC7      EQU   4+SC6                                                    80120015
SC8      EQU   4+SC7                                                    80160015
SC9      EQU   4+SC8                                                    80200015
SC10     EQU   4+SC9                                                    80240015
SC10A    EQU   4+SC10                                                   80280015
SCNERR   EQU   4+SC10A                                                  80320015
MV1      EQU   4+SCNERR                                                 80360015
MV2      EQU   4+MV1                                                    80400015
MV3      EQU   4+MV2                                                    80440015
MV3A     EQU   4+MV3                                                    80480015
MV4      EQU   4+MV3A                                                   80520015
         SPACE 2                                                        80560015
LT       EQU   4096+SC                 TRANSFER VECTORS TO BLOCK LT     80600015
ARITH    EQU   2+LT                                                     80640015
ARITH2   EQU   4+ARITH                                                  80680015
ADDSTK   EQU   4+ARITH2                                                 80720015
RELSTK   EQU   4+ADDSTK                                                 80760015
RLSTK1   EQU   4+RELSTK                                                 80800015
ITEM2    EQU   4+RLSTK1                                                 80840015
GETFR    EQU   4+ITEM2                                                  80880015
GETGR    EQU   4+GETFR                                                  80920015
GETGRE   EQU   4+GETGR                                                  80960015
STGENR   EQU   4+GETGRE                                                 81000015
STREG2   EQU   4+STGENR                                                 81040015
STREG4   EQU   4+STREG2                                                 81080015
GETADX   EQU   4+STREG4                                                 81120015
GETADS   EQU   4+GETADX                                                 81160015
GETAS1   EQU   4+GETADS                                                 81200015
RESLT1   EQU   4+GETAS1                                                 81240015
RESLT2   EQU   4+RESLT1                                                 81280015
         SPACE 2                                                        81320015
LU       EQU   4096+LT                 TRANSFER VECTORS TO BLOCK LU     81360015
EXPONT   EQU   LU                                                       81400015
SETCPX   EQU   4+EXPONT                                                 81440015
ADDFUN   EQU   4+SETCPX                                                 81480015
         SPACE 2                                                        81520015
         END   IEMLS                                                    81560015
