LT       TITLE 'IEMLT,EXPRESSION EVALUATION,PSEUDO CODE GENR,PL/I F.'   00050015
         SPACE 3                                                        00100015
*              STATUS - CHANGE LEVEL 0.                                 00150015
         SPACE 3                                                        00200015
*              FUNCTION - SUBSIDUARY BLOCK TO BLOCK LS,CONTAINING THE   00250015
*        FOLLOWING SUBROUTINES - 'ARITH','GETADX','ADDSTK','RELSTK',    00300015
*        'GETFR','GETGR','ERROR'.                                       00350015
         SPACE 3                                                        00400015
*              ENTRY POINTS (1) AT 'ARITH','ARITH2' TO PROCESS ARITH-   00450015
*        METIC TRIPLES. USED BY BLOCKS LS,LU.                           00500015
*                           (2) AT 'RESLT1','RESLT2' TO COMPLETE THE    00550015
*        PROCESSING OF ARITHMETIC TYPE TRIPLES. USED BY ALL BLOCKS.     00600015
*                           (3) AT 'GETADX','GETADS','GETAS1' TO SET UP 00650015
*        OPERANDS IN PSEUDO-CODE INSTRUCTIONS. USED BY ALL BLOCKS.      00700015
*                           (4) AT 'ADDSTK' TO ADD ITEMS TO INTER-      00750015
*        MEDIATE RESULT STACK. USED BY ALL BLOCKS.                      00800015
*                           (5) AT 'RELSTK','RLSTK1','ITEM2' TO RELEASE 00850015
*        ITEMS FROM THE INTERMEDIATE RESULT STACK. USED BY ALL BLOCKS.  00900015
*                           (6) AT 'GETFR','GETGR','GETGRE' TO OBTAIN   00950015
*        FLOATING AND GENERAL REGISTERS FOR ARITHMETIC. USED BY ALL     01000015
*        BLOCKS.                                                        01050015
*                           (7) AT 'STGENR','STREG2','STREG4' TO STORE  01100015
*        REGISTERS OR GET ALIGNED WORKSPACE. USED BY ALL BLOCKS.        01150015
*                           (8) AT 'ERROR','CERROR' TO GENERATE ERROR   01200015
*        MESSAGE DICTIONARY ENTRIES. USED BY ALL BLOCKS.                01250015
         SPACE 3                                                        01300015
*              INPUT - AS FOR PHASE LS.                                 01350015
         SPACE 3                                                        01400015
*              OUTPUT - AS FOR PHASE LS.                                01450015
         SPACE 3                                                        01500015
*              EXTERNAL ROUTINES (1) 'ZUERR' IN CONTROL PHASE TO CREATE 01550015
*        ERROR MESSAGE DICTIONARY ENTRY.                                01600015
*                                (2) 'SC5' IN BLOCK LA TO BUMP INPUT    01650015
*        POINTER TO NEXT TRIPLE.                                        01700015
*                                (3) 'DICDES' IN BLOCK LS TO SET UP A   01750015
*        DESCRIPTION FROM A DICTIONARY ENTRY.                           01800015
*                                (4) 'CONVT','CONST' IN BLOCK LS TO     01850015
*        GENERATE CONVERSIONS AND HANDLE CONSTANTS.                     01900015
*                                (5) 'ASSIGN' IN BLOCK LS TO GENERATE   01950015
*        AN ASSIGN TRIPLE AND TMPD'S.                                   02000015
*                                (6) 'MOVEPC' IN BLOCK LS TO MOVE       02050015
*        PSEUDO-CODE FROM BUFFER TO OUTPUT TEXT.                        02100015
*                                (7) 'SWOP' IN BLOCK LS TO INTERCHANGE  02150015
*        OPERANDS.                                                      02200015
*                                (8) 'SETCPX' IN BLOCK LU TO INITIALISE 02250015
*        FOR COMPLEX ARITHMETIC.                                        02300015
*                                (9) 'TSTOD1','TSTOD2' IN BLOCK LS TO   02350015
*        TEST FOR ZERO OPERANDS IN COMPLEX ARITHMETIC.                  02400015
*                               (10) 'SBGTNR' IN BLOCK LS TO GET NEXT   02450015
*        SYMBOLIC REGISTER.                                             02500015
         SPACE 3                                                        02550015
*              EXIT-NORMAL (AFTER 'ARITH' BLOCK)                        02600015
*                          (1) TO 'NXTPL' TO SCAN NEXT TRIPLE.          02650015
*                          (2) TO 'GENRPD' TO GENERATE PSEUDO-CODE FOR  02700015
*        PACKED DECIMAL OPERATIONS.                                     02750015
*                          (3) TO 'STRING' TO PROCESS STRING TRIPLES.   02800015
*                          (4) TO 'EXPONT' TO PROCESS EXPONENTIAL       02850015
*        TRIPLES.                                                       02900015
*                          (5) TO 'LB0' TO RESCAN THE CURRENT TRIPLE.   02950015
*                          (6) TO 'LSUB1' TO STACK RESULT AND CONTINUE  03000015
*        SCAN.                                                          03050015
*                          (7) TO 'CPLEX' TO INITIALISE FOR IMAGINARY   03100015
*        PART COMPLEX ARITHMETIC.                                       03150015
*              EXIT-NORMAL (AFTER SUBROUTINES)                          03200015
*                          (8) TO INSTRUCTION AFTER INVOCATION.         03250015
         SPACE 3                                                        03300015
*              EXIT-ERROR - TO 'ZABORT' AFTER COMPILER OR TERMINAL      03350015
*        ERRORS.                                                        03400015
         SPACE 3                                                        03450015
*              WORK AREA - 4K OF SCRATCH CORE IS USED. THE FIRST 1K IS  03500015
*        USED FOR CONSTANTS SET UP BY BLOCK LR. THE REMAINDER IS USED   03550015
*        FOR WORKSPACE AND STACKS.                                      03600015
         SPACE 3                                                        03650015
*              ATTRIBUTES - THIS BLOCK IS NOT READ-ONLY AND NOT         03700015
*        RE-ENTRANT.                                                    03750015
         SPACE 3                                                        03800015
*              NOTES - THIS BLOCK REQUIRES NO MODIFICATION AS A RESULT  03850015
*        OF CHANGES IN THE INTERNAL REPRESENTATION OF EXTERNAL          03900015
*        GRAPHICS.                                                      03950015
         EJECT                                                          04000015
IEMLT    START 0                                                        04050015
*                       ASSEMBLY CONSTANTS                              04100015
BDIC     EQU   X'C300'                 BEGINNING OF TEST DICTIONARY     04150015
ISTK     EQU   10                      BYTES/ITEM IN DESCRIPTION STACK  04200015
BIT01    EQU   X'C0'                   MASK FOR BITS 0,1                04250015
PDON     EQU   X'88'                   1 BITS MASK FOR PD               04300015
PDOFF    EQU   X'06'                   0 BITS MASK FOR PD               04350015
XSTOFF   EQU   X'90'                   0 BITS MASK FOR FIXED LEN STRING 04400015
CSTON    EQU   X'04'                   1 BITS MASK FOR CHAR STRING      04450015
ASTON    EQU   X'20'                   1 BITS MASK FOR ALIGNED STRING   04500015
OFSOFF   EQU   X'EF'                   SWITCH OFF OFS BIT IN FLAG       04550015
OFSON    EQU   X'10'                                                    04600015
*                       GENERAL REGISTERS.                              04650015
G0       EQU   0                       ARITHMETIC REGISTER              04700015
IR       EQU   1                       INPUT POINTER                    04750015
IP       EQU   1                       INPUT POINTER                    04800015
DSR      EQU   2                       REGISTER FOR DESR BUFFER.        04850015
TRTBSE   EQU   2                       TRANSLATE RESULT                 04900015
PAR      EQU   3                       SCAN PARAMETER BASE              04950015
WSR      EQU   3                       WORKSPACE BASE                   05000015
GRN      EQU   4                     ARGUMENT OF RELEASE STACK          05050015
G1       EQU   5                       SCRATCH POINTER                  05100015
STR      EQU   6                       STACK POINTER                    05150015
PCR      EQU   7                       PC BUFFER POINTER                05200015
OP       EQU   8                       OUTPUT POINTER                   05250015
LUBASE   EQU   8                       BLOCK LU BASE                    05300015
LTBASE   EQU   9                       BLOCK LT BASE                    05350015
LSBASE   EQU   10                      BLOCK LS BASE                    05400015
CTVR     EQU   11                      BASE OF CONTROL PH TRANS VECTORS 05450015
SCBASE   EQU   12                      SCAN PHASE BASE                  05500015
DICR     EQU   13                      BASE OF DICT COMMUNICATION RGION 05550015
GRE      EQU   14                      EVEN ARITHMETIC REGISTER         05600015
RR       EQU   14                      RETURN REGISTER                  05650015
GRO      EQU   15                      ODD ARITHMETIC REGISTER          05700015
BR       EQU   15                      LINK REGISTER                    05750015
*                       MASKS FOR BRANCH ON CONDITION.                  05800015
*              INSTRUCTION TYPE -      COMPARISON,ARITHMETIC,MASK TEST  05850015
NOP      EQU   0                       NOP.                             05900015
BM       EQU   4                       BRANCH IF MIXED                  05950015
BO       EQU   1                           --    ,OVERFLOW  ,ALL ONES   06000015
BH       EQU   2                       HIGH      ,PLUS      ,    --     06050015
BL       EQU   4                       LOW       ,MINUS     ,MIXED 0-1  06100015
BNE      EQU   7                       NOT EQUAL ,NOT ZERO  ,NOT ALL 0  06150015
BZ       EQU   8                       EQUAL     ,ZERO      ,ALL ZEROS  06200015
BE       EQU   8                                                        06250015
BNL      EQU   11                      NOT LOW   ,NOT MINUS ,NOT MIXED  06300015
BN1      EQU   12                          --    ,    --    ,NOT ALL 1  06350015
BNH      EQU   13                      NOT HIGH  ,NOT PLUS  ,    --     06400015
B        EQU   15                      UNCONDITIONAL.                   06450015
*              TRIPLE LAYOUT - USUALLY BASED ON IR                      06500015
TPOPN    EQU   0                       OPERATOR    - 1 BYTE             06550015
TPOD1    EQU   1                       1ST OPERAND - 2 BYTES            06600015
TPOD2    EQU   3                       2ND OPERAND - 2 BYTES            06650015
*                       DESCRIPTION ITEM LAYOUT- OFFSETS FROM START     06700015
DESFLG   EQU   0                       FLAG BYTE                        06750015
DESCDE   EQU   1                       CODE BYTE                        06800015
DESP     EQU   2                       PRECISION BYTE                   06850015
DESQ     EQU   3                       SCALE FACTOR BYTE                06900015
DESBSE   EQU   4                       BASE ADDRESS BYTES (2)           06950015
DESNDX   EQU   6                       NDX (INDEX) BYTES (2)            07000015
DESOFS   EQU   8                       OFS (OFFSET) BYTES (2)           07050015
DESLTH   EQU   10                      BYTE LENGTH FOR P-D  (2 BYTES)   07100015
DESTK    EQU   12                      TEMP STACK CODE                  07150015
TOTDES   EQU   14                      LENGTH OF FULL DESCRIPTION       07200015
*                       PSEUDO-CODE LAYOUT - RR,RX,RS,SI OPERATIONS.    07250015
PCSZ3    EQU   3                       SIZE OF 3 BYTE PC                07300015
PCSZ5    EQU   5                       SIZE OF 5 BYTE PC                07350015
PCOPN    EQU   0                       P-C OPERATION CODE               07400015
PCOD1    EQU   1                       P-C 1ST OPERAND                  07450015
PCOD2    EQU   3                       P-C 2ND OPERAND                  07500015
PCOSM    EQU   5                       P-C OFFSET MARKER CODE           07550015
PCOSM1   EQU   6                       P-C OFFSET MARKER FIELD 1        07600015
PCOSM2   EQU   8                       P-C OFFSET MARKER FIELD 2        07650015
*                       PSEUDO-CODE LAYOUT - SS OPERATIONS              07700015
PCSZ8    EQU   8                       SIZE OF 8 BYTE PC                07750015
PCSZ12   EQU   12                    SIZE OF 12 BYTE PC                 07800015
*PCOPN   EQU   0                       P-C OPERATION CODE               07850015
PCFLG    EQU   1                       P-C FLAG                         07900015
PCLNG    EQU   2                       BYTE LENGTH OF PC INSTRUCTION    07950015
PCF1     EQU   3                       LENGTH CODES - L OR  L1,L2       08000015
PCF2     EQU   4                       P-C 1ST OPERAND - DR/SYM REG     08050015
PCF3     EQU   6                       P-C 2ND OPERAND - DR/SYM REG     08100015
PCF4     EQU   8                       P-C 1ST OFFSET                   08150015
PCF5     EQU   10                      P-C 2ND OFFSET                   08200015
*              LAYOUT OF DICTIONARY ENTRY FOR CONSTANT.                 08250015
DCFLG    EQU   0                       FLAG =X'88' FOR CONSTANT         08300015
DCLNG    EQU   1                       TOTAL LENGTH                     08350015
DCCHN    EQU   3                       CONSTANT CHAIN                   08400015
DCDED1   EQU   5                       APPARENT DED (3 BYTES)           08450015
DCTYP    EQU   8                       TYPE                             08500015
DCDED2   EQU   9                       REQUIRED DED                     08550015
DCINIT   EQU   12                      INITIAL VALUE BYTES              08600015
DCVAL    EQU   14                      VALUE OF CONSTANT                08650015
*              LAYOUT OF DICT ENTRY FOR TEMP SDV                        08700015
DDVOFS   EQU   5                       OFFSET OF STRING IN TEMP STACK   08750015
DDVLNG   EQU   10                      LENGTH OF STRING                 08800015
*              LAYOUT OF DICT ENTRY FOR ENTRY TYPE 1                    08850015
DE1AUT   EQU   11                      START OF AUTO CHAIN FOR BLOCK    08900015
*              LAYOUT OF DICT ENTRY FOR VARIABLE                        08950015
DEFLG    EQU   0                       FLAG BYTE                        09000015
DELNG    EQU   1                       LENGTH OF ENTRY                  09050015
DECHN    EQU   3                       AUTOMATIC CHAIN                  09100015
DEDED    EQU   8                       ACTUAL DED IN DED2 DICT ENTRY    09150015
DEOTH3   EQU   13                      'OTHER 3' CODE BYTE              09200015
DEDATA   EQU   15                      DATA BYTES                       09250015
*              REGISTER DESCRIPTION BLOCKS (4 FLOATING, 2 GENERAL )     09300015
RGBLSZ   EQU   4                       SIZE OF REGISTER BLOCK           09350015
RGD1     EQU   0                       CODE BYTE- = 0 IF NOT IN USE,    09400015
*                                             AND = 1,2,3,4 IF IN USE.  09450015
RGD2     EQU   1                       ADDRESS OF CORRESPONDING ITEM    09500015
*                                      IN DESCRIPTION STACK.            09550015
*                       PSEUDO-CODE OPERATION CODES                     09600015
LC       EQU   X'00'                   BASIC LOAD COMPLEMENT            09650015
EXPON    EQU   X'00'                                                    09700015
AND      EQU   X'05'                   BASIC AND                        09750015
DROP     EQU   X'06'                   DROP                             09800015
EQU      EQU   X'07'                   EQU                              09850015
L        EQU   X'08'                   BASIC LOAD OPERATION             09900015
CPR      EQU   X'09'                   BASIC COMPARE                    09950015
ADD      EQU   X'0A'                   BASIC ADD                        10000015
SUB      EQU   X'0B'                   BASIC SUBTRACT                   10050015
MULT     EQU   X'0C'                   BASIC MULTIPLY                   10100015
DIV      EQU   X'0D'                   BASIC DIVIDE                     10150015
IPRM     EQU   X'0D'                   IPRM                             10200015
OSM1     EQU   X'10'                   OFFSET MARKER 1 (LITERAL ONLY)   10250015
OSM2     EQU   X'11'                   OFFSET MARKER 2 (REGISTER ONLY)  10300015
BUY      EQU   X'16'                   BUY                              10350015
IPRMD    EQU   X'1D'                   IPRM'                            10400015
CONCAT   EQU   X'21'                                                    10450015
ERR      EQU   X'3C'                   ERROR                            10500015
NR       EQU   X'45'                   NR                               10550015
SR       EQU   SUB+X'40'               SR                               10600015
BALR     EQU   X'4F'                   BALR                             10650015
SPM      EQU   X'51'                   SPM                              10700015
LTR      EQU   X'52'                   LTR                              10750015
SLA      EQU   X'71'                   SLA                              10800015
SLDA     EQU   X'72'                   SLDA                             10850015
SRA      EQU   X'75'                   SRA                              10900015
SRDA     EQU   X'76'                   SRDA                             10950015
STM      EQU   X'79'                   STORE MULTIPLE                   11000015
BC       EQU   X'81'                   BC                               11050015
LH       EQU   X'90'                   LH                               11100015
CH       EQU   X'91'                   CH                               11150015
AH       EQU   X'92'                   AH                               11200015
STH      EQU   X'95'                   STH                              11250015
STD      EQU   X'97'                   STORE LONG FLOAT                 11300015
LA       EQU   X'A0'                   LA OPERATION CODE                11350015
ST       EQU   X'A5'                   STORE GENERAL REGISTER           11400015
STE      EQU   X'A7'                   STORE SHORT FLOAT                11450015
MVI      EQU   X'B1'                   MVI                              11500015
XI       EQU   X'B6'                   XI                               11550015
OSM3     EQU   X'BD'                   OFFSET MARKER 3 (LITERAL+REG)    11600015
CLC      EQU   X'C0'                   CLC                              11650015
MVC      EQU   X'C1'                   MVC                              11700015
CONV     EQU   X'D6'                   CONVERT MACRO                    11750015
MSA      EQU   X'28'                   ASSIGN WITHOUT DROPPING SOURCE   11800015
ASSGN    EQU   X'47'                   ASSIGN TRIPLE                    11850015
NFUNC    EQU   X'2F'                   NULL COMPILER FUNCTION           11900015
TMPD     EQU   X'58'                   TEMP DESCRIPTION TRIPLE          11950015
FXB      EQU   X'00'                   MODIFIER FOR FIXED BINARY        12000015
FLD      EQU   X'10'                   MODIFIER FOR LONG FLOAT          12050015
FLE      EQU   X'20'                   MODIFIER FOR SHORT FLOAT         12100015
PKD      EQU   X'C0'                   MODIFIER FOR PACKED DECIMAL      12150015
         EJECT                                                          12200015
         USING *,LTBASE                                                 12250015
         USING BGWS,WSR                                                 12300015
         USING D,DICR                                                   12350015
         USING Z,CTVR                                                   12400015
         USING SC,SCBASE                                                12450015
         USING LS,LSBASE                                                12500015
         USING LU,LUBASE                                                12550015
BEGIN    DC    C'LT'                   BLOCK NAME                       12600015
*              TRANSFER VECTORS.                                        12650015
         BC    B,ARITH                 'ARITH' ENTRY                    12700015
         BC    B,ARITH2                                                 12750015
         BC    B,ADDSTK                'ADDSTK' ENTRY                   12800015
         BC    B,RELSTK                'RELSTK' ENTRY                   12850015
         BC    B,RLSTK1                'RLSTK1' ENTRY                   12900015
         BC    B,ITEM2                 'ITEM2'  ENTRY                   12950015
         BC    B,GETFR                 'GETFR'  ENTRY                   13000015
         BC    B,GETGR                                                  13050015
         BC    B,GETGRE                                                 13100015
         BC    B,STGENR                                                 13150015
         BC    B,STREG2                                                 13200015
         BC    B,STREG4                                                 13250015
         BC    B,GETADX                                                 13300015
         BC    B,GETADS                                                 13350015
         BC    B,GETAS1                                                 13400015
         BC    B,RESLT1                                                 13450015
         BC    B,RESLT2                                                 13500015
         EJECT                                                          13550015
*              PROCESS ARITHMETIC AND COMPARISON TRIPLES.               13600015
         SPACE 1                                                        13650015
*              FUNCTION (1) CALCULATE RESULT TYPE,PRECISION AND SCALING 13700015
*        FOR ARITHMETIC AND COMPARISON TRIPLES. GENERATE CONVERSIONS    13750015
*        WHEN THE OPERAND AND RESULT TYPES DIFFER.                      13800015
*                       (2) CALCULATE SHIFTS FOR FIXED POINT OPERATIONS 13850015
*                       (3) GENERATE PSEUDO-CODE FOR EXPRESSION TRIPLES 13900015
*        GIVING FLOAT OR FIXED BINARY TYPE RESULTS.                     13950015
*                       (4) GENERATE PSEUDO-CODE FOR ADD,MULTIPLY AND   14000015
*        DIVIDE FUNCTIONS GIVING FLOAT OR FIXED BINARY TYPE RESULTS.    14050015
         SPACE 1                                                        14100015
*              ENTRY POINT (1) 'ARITH' TO PROCESS EXPRESSION TRIPLE     14150015
*        ADDRESSED BY INPUT POINTER 'IP'.                               14200015
*                          (2) 'ARITH2' TO GENERATE PSEUDO-CODE FOR     14250015
*        EXPRESSIONS. THE RESULT TYPE CALCULATION AND CONVERSIONS ARE   14300015
*        NOT REQUIRED. USED FOR POWER OF 2 (SQUARING).                  14350015
*                          (3) 'RESLT1' TO STACK A RESULT BEFORE        14400015
*        RELEASING ANY STACKED OPERANDS. USED FOR PACKED DECIMAL AND    14450015
*        EXPONENTIAL OPERATIONS.                                        14500015
*                          (4) 'RESLT2' TO STACK A RESULT AFTER         14550015
*        RELEASING ANY STACKED OPERANDS. USED FOR FLOATING AND FIXED    14600015
*        BINARY OPERATIONS.                                             14650015
         SPACE 1                                                        14700015
*              EXTERNAL ROUTINE (1) 'SC5' IN BLOCK LA TO BUMP INPUT     14750015
*        POINTER TO NEXT TRIPLE.                                        14800015
*                               (2) 'DICDES' IN BLOCK LS TO SET UP A    14850015
*        DESCRIPTION FROM A DICTIONARY ENTRY.                           14900015
*                               (3) 'CONVT','CONST' IN BLOCK LS TO      14950015
*        GENERATE CONVERSIONS AND HANDLE CONSTANTS.                     15000015
*                               (4) 'ASSIGN' IN BLOCK LS TO GENERATE    15050015
*        AN ASSIGN TRIPLE AND TMPD'S.                                   15100015
*                               (5) 'MOVEPC' IN BLOCK LS TO MOVE        15150015
*        PSEUDO-CODE FROM BUFFER TO OUTPUT TEXT.                        15200015
*                               (6) 'SWOP' IN BLOCK LS TO INTERCHANGE   15250015
*        OPERANDS.                                                      15300015
*                               (7) 'SETCPX' IN BLOCK LU TO INITIALISE  15350015
*        FOR COMPLEX ARITHMETIC.                                        15400015
*                               (8) 'TSTOD1','TSTOD2' IN BLOCK LS TO    15450015
*        TEST FOR ZERO OPERANDS IN COMPLEX ARITHMETIC.                  15500015
*                               (9) 'GETADX','GETADS','GETAS1' TO SET   15550015
*        UP ADDRESSES IN PSEUDO-CODE.                                   15600015
*                              (10) 'GETFR','GETGR','GETGRE','GETGRO'   15650015
*        TO GET FLOATING OR GENERAL REGISTERS FOR ARITHMETIC.           15700015
*                              (11) 'ADDSTK' TO ADD ITEMS TO THE INTER- 15750015
*        MEDIATE RESULT STACK.                                          15800015
*                              (12) 'RELSTK','RLSTK1' TO RELEASE ITEMS  15850015
*        FROM THE INTERMEDIATE RESULT STACK.                            15900015
*                              (13) 'ITEM2' TO GET THE ADDRESS OF THE   15950015
*        2ND ITEM FROM TOP OF STACK.                                    16000015
*                              (14) 'ERROR' TO GENERATE ERROR MESSAGE   16050015
*        DICTIONARY ENTRIES FOR ILLEGAL COMBINATIONS OF OPERAND TYPES   16100015
*        (NO. 1607) AND ILLEGAL COMPLEX COMPARISONS(NO. 1608).          16150015
         SPACE 1                                                        16200015
*              EXIT-NORMAL (1) TO 'NXTPL' TO SCAN NEXT TRIPLE.          16250015
*                          (2) TO 'GENRPD' TO GENERATE PSEUDO-CODE FOR  16300015
*        PACKED DECIMAL OPERATIONS.                                     16350015
*                          (3) TO 'STRING' TO PROCESS STRING TRIPLES.   16400015
*                          (4) TO 'EXPONT' TO PROCESS EXPONENTIAL       16450015
*        TRIPLES.                                                       16500015
*                          (5) TO 'LB0' TO RESCAN THE CURRENT TRIPLE.   16550015
*                          (6) TO 'LSUB1' TO STACK RESULT AND CONTINUE  16600015
*        SCAN.                                                          16650015
*                          (7) TO 'CPLEX' TO INITIALISE FOR IMAGINARY   16700015
*        PART COMPLEX ARITHMETIC.                                       16750015
         SPACE 1                                                        16800015
*              EXIT-ERROR - NONE.                                       16850015
         SPACE 1                                                        16900015
*              NOTES (1) THE CALCULATION OF THE RESULT TYPE,PRECISION   16950015
*        AND SCALING IS GIVEN BY THE PL/I LANGUAGE SPECIFICATIONS FOR   17000015
*        EXPRESSION EVALUATION.                                         17050015
*                                                                       17100015
*                    (2) FIXED POINT OPERATIONS MAY REQUIRE 2 SHIFTS.   17150015
*        IN GENERAL,GENERATED CODE IS - LOAD INSTRUCTION.               17200015
*                                       SHIFT X DIGITS.                 17250015
*                                       ARITH INSTRUCTION.              17300015
*                                       SHIFT Y DIGITS.                 17350015
*        IF THE OPERANDS HAVE(PRECISION,SCALE FACTOR) OF (P,Q) AND      17400015
*        (R,S),THEN FOR FIXED BINARY OPERATIONS --                      17450015
*              +,-,COMPARE    X = MIN(32,ABS(Q-R) ) RIGHT, Y = X LEFT.  17500015
*              *              X = 0                      , Y =32 LEFT.  17550015
*              /              X = P RIGHT                , Y = 0.       17600015
*        FOR PACKED DECIMAL OPERATIONS, Y = 0 AND --                    17650015
*              +,-,COMPARE    X = MIN(16, ABS(Q-R) ) LEFT.              17700015
*              *              X = 0.                                    17750015
*              /              X = 15-P LEFT.                            17800015
*                                                                       17850015
*              SHIFTS ARE MODIFIED FOR ADD,MULTIPLY,DIVIDE FUNCTIONS    17900015
*        WITH FIXED POINT RESULTS OF (PRECISION,SCALE FACTOR) OF (T,U). 17950015
*        FOR FIXED BINARY RESULTS --                                    18000015
*              ADD            X = ABS(Q-R) RIGHT, Y = U-MIN(Q,R) LEFT.  18050015
*              MULTIPLY       X = 0             , Y = U+32-Q-R   LEFT.  18100015
*              DIVIDE         X = 32+Q-S-U RIGHT, Y = 0.                18150015
*        SHIFTS ARE NORMALLY DOUBLE. IF Y LT 0, SHIFTS ARE SINGLE. IF   18200015
*        BOTH SHIFTS GE 32 ,THEN BOTH ARE SET TO 32. OTHERWISE LIMITS   18250015
*        OF 63 AND 31 ARE USED FOR DOUBLE AND SINGLE SHIFTS. A FINAL    18300015
*        ASSIGNMENT TESTS FOR SIZE CONDITIONS.                          18350015
*        FOR PACKED DECIMAL RESULTS, Y = 0 AND --                       18400015
*              ADD            X = MIN(16,ABS(Q-R)) LEFT.                18450015
*              MULTIPLY       X = 0.                                    18500015
*              DIVIDE         X = Q-S-U            LEFT.                18550015
*        A ZAP TESTS FOR FIXED OVERFLOW CONDITION AND A FINAL ASSIGN-   18600015
*        MENT TRUNCATES ON LEFT AND RIGHT AND TESTS FOR SIZE CONDITION. 18650015
*                                                                       18700015
*                    (3) THE FOLLOWING PSEUDO-CODE IS GENERATED FOR     18750015
*        FLOATING ARITHMETIC --   LE   FR,A    FOR  +  A  B             18800015
*                                 AE   FR,B    WHEN A,B SHORT,IN CORE   18850015
*        IF A IS IN REGISTER FRA THEN --                                18900015
*                                 AE   FRA,B                            18950015
*        IF A AND B ARE IN REGISTERS FRA,FRB,THEN --                    19000015
*                                 AER  FRA,FRB                          19050015
*        THE OPERATION MAY BE LONG OR SE,ME,DE,CE.                      19100015
*        IF B IS IN REGISTER FRB  THEN --                               19150015
*           . +            . -            . *            . /            19200015
*           . AE   FRB,A   . LCER FRB,FRB . ME   FRB,A   . LE   FR,A    19250015
*           .              . AE   FRB,A   .              . DER  FR,FRB  19300015
*                                                                       19350015
*                    (4) THE FOLLOWING PSEUDO-CODE IS GENERATED FOR     19400015
*        FIXED BINARY ARITHMETIC --                                     19450015
*           . +,COMPARE    . -            . *            . /            19500015
*           . L    GRE,A   . L    GRE,A   . L    GRO,A   . L    GRE,A   19550015
*           . SRDA GRE,X   . SRDA GRE,X   . M    GRE,B   . SR   GRO,GRO 19600015
*           . A,C  GRE,B   . S    GRE,B   . SLDA GRE,Y   . SLDA GRE,X   19650015
*           . SLDA GRE,Y   . SLDA GRE,Y   .              . D    GRE,B   19700015
*           .      OR      .      OR      .              .              19750015
*           . L    GR,A    . L    GRE,B   .              .              19800015
*           . A,C  GR,B    . LCR  GRE,GRE .              .              19850015
*           .              . SRDA GRE,X   .              .              19900015
*           .              . A    GRE,A   .              .              19950015
*           .              . SLDA GRE,Y   .              .              20000015
*        X,Y ARE SHIFTS IN NOTE(2). GRE,GRO ARE EVEN,ODD GENERAL        20050015
*        REGISTERS OF A PAIR (14,15). GR IS EITHER REGISTER.            20100015
         EJECT                                                          20150015
ARITH    MVI   ARCOD,0                                                  20200015
         MVI   RELCOD,0                                                 20250015
         LA    G0,2                                                     20300015
         TM    OPCOD,X'10'             TEST WHETHER 1 OR 2 OPERANDS     20350015
         BC    BZ,LBE24                BRANCH IF 2 OPERANDS             20400015
         LA    G0,1                                                     20450015
LBE24    STH   G0,OPND                 SET COUNT FOR LOOPS              20500015
*              TEST FOR '00' OPERANDS AND SET DESCRIPTION BUFFERS       20550015
         LA    DSR,DES2                DESCRIPTION BUFFER OF 2ND OPERND 20600015
         LH    G0,OPND                 LOOP COUNT                       20650015
         SR    G1,G1                   NUMBER OF TEMPS USED             20700015
         LA    STR,TPOD2(IP)           2ND OPERAND ADDRESS              20750015
LBE5     NC    0(2,STR),0(STR)         TEST OPERAND BYTES               20800015
         BC    BZ,LBE1                 BRANCH IF '00' (IN DESR STACK)   20850015
         MVC   DESBSE(2,DSR),0(STR)    MOVE DICT ENTRY                  20900015
         BAL   RR,DICDES               GET DESCRIPTION FROM DICT        20950015
         BC    B,LBE2                                                   21000015
LBE1     LTR   G1,G1                   TEST NUMBER OF TEMPS,            21050015
         BC    BZ,LBE3                 BRANCH IF THIS IS FIRST.         21100015
         BAL   RR,ITEM2                GET ADDRESS OF 2ND ITEM IN STR   21150015
         LA    G0,1                    RESTORE LOOP COUNTER             21200015
         BC    B,LBE4                                                   21250015
LBE3     L     STR,LSTK                GET TOP STACK ITEM               21300015
LBE4     MVC   0(ISTK,DSR),0(STR)      MOVE COMPLETE DESCRIPTION        21350015
         LA    G1,1(G1)                BUMP TEMP COUNT                  21400015
         STC   G1,DESTK(DSR)           STORE TEMP COUNT IN DESCRIPTION  21450015
         CLI   AMDBUF+DESFLG,0                                          21500015
         BC    BZ,LBE2                 BRANCH IF NOT AMD FUNCTION       21550015
         CLI   DESFLG(DSR),X'00'                                        21600015
         BC    BNE,LBE2                BRANCH IF NOT DICT REF ALONE     21650015
         CLI   DESNDX(DSR),X'80'                                        21700015
         BC    BNE,LBE2                BRANCH IF NOT CONSTANT           21750015
         MVI   DESTK(DSR),X'80'        SET ARGUMENT TO CONSTANT TYPE    21800015
LBE2     TM    DESCDE(DSR),X'CC'                                        21850015
         BC    BO,LBE26                BRANCH IF POINTER OR OFFSET      21900015
         CLI   DESCDE(DSR),X'C0'                                        21950015
         BC    BNE,LBE26               BRANCH IF CONSTANT OR VARIABLE   22000015
         MVC   PAR7+2(2),DESBSE(DSR)   MOVE DICT REF                    22050015
         MVC   PAR6+1(3),ERR47         LABEL,EVENT,FILE OR TASK,SO      22100015
         BAL   RR,ERROR                GENERATE ERROR MESSAGE           22150015
         MVC   DESCDE(3,DSR),FIXBIN    SET TO FIXED BINARY (31,0)       22200015
LBE26    LA    DSR,DES1                1ST OPERAND DESCRIPTION          22250015
         LA    STR,TPOD1(IP)           1ST OPERAND ADDRESS              22300015
         BCT   G0,LBE5                 TEST LOOP COUNT                  22350015
         STH   G1,NTMP                                                  22400015
*              SET TYPE AND CHARACTERISTICS OF RESULT                   22450015
         MVC   DEST+DESCDE(1),DES1+DESCDE                               22500015
         OC    DEST+DESCDE(1),DES2+DESCDE  'OR' 1ST AND 2ND TYPE CODES  22550015
         CLI   OPCOD,CONCAT                                             22600015
         BC    BZ,STRING               BRANCH IF CONCAT                 22650015
LBE17    CLI   OPCOD,CPR                                                22700015
         BC    BH,LBE15                BRANCH IF NOT COMPARE OR EXPON   22750015
         CLI   OPCOD,EXPON                                              22800015
         BC    BZ,LBE15                BRANCH IF EXPONENTIAL            22850015
         TM    DEST+DESCDE,X'CC'                                        22900015
         BC    BN1,LBE22               BRANCH IF NOT PTR OR OFS RESULT  22950015
         SPACE                                                          23000015
*              CHECK FOR CONVERSION FROM OFFSET TO POINTER TYPE.        23050015
         SPACE                                                          23100015
         CLC   DES1+DESCDE(1),DES2+DESCDE                               23150015
         BC    BE,LBE20                BRANCH IF TYPES BOTH OFS OR PTR  23200015
         LA    G1,DES2                 POINT G1 AT DES2, DSR POINTS     23203015
*                                    AT DES1                            23206015
         CLI   DES1+DESCDE,X'DC'       TEST FOR FIRST OPERAND OFFSET    23210015
         BC    BE,LBE19                BRANCH IF SO                     23220015
         CLI   DES2+DESCDE,X'DC'       TEST FOR SECOND OPND OFFSET      23230015
         BC    BNE,LBE22             BRANCH IF ERRONEOUS TARGET TYPE    23240015
         LA    DSR,DES2                POINT DSR AT DES2                23250015
         LA    G1,DES1               G1 AT DES1                         23260015
*                                                                       23270015
*        NOW DSR POINTS AT AN OFFSET DESCRIPTION, AND G1 AT A POINTER   23280015
*        TYPE. IN ORDER TO FORCE A WARNING MESSAGE WHEN NULL/NULLO      23290015
*        IS MISUSED,CONVERSION OF THE CONSTANT IS REQUESTED.            23300015
*                                                                       23310015
LBE19    MVC   DESBUF+DESCDE(3),PTRDES                                  23350015
         CLI   DESTK(G1),X'80'         IF THE POINTER IS NOT A          23380015
         BC    BNE,LBE23             CONSTANT,CONVERSION AS LANGUAGE    23410015
         SPACE                                                          23440015
         LR    DSR,G1                  OTHERWISE CONVERT NULL TO        23470015
         OI    DESBUF+DESCDE,X'10'   OFFSET TYPE TO GET WARNING         23500015
LBE23    BAL   RR,CONVT                                                 23530015
LBE20    MVC   DES1+DESCDE(3),FIXBIN   CHANGE BOTH OPERAND DESCRIPTIONS 23600015
         MVC   DES2+DESCDE(3),FIXBIN TO FIXED BINARY (31,0)             23650015
LBE22    IC    G0,OPCOD                COMPARE OPCOD IS 1,2,3,4,5,6,    23700015
         SLL   G0,1                    SO DOUBLE TO GET MASK FOR        23750015
         STC   G0,CPMASK               BRANCH IF FALSE.                 23800015
         MVI   OPCOD,CPR                                                23850015
         TM    DEST+DESCDE,X'80'                                        23900015
         BC    BZ,STRING               BRANCH IF BOTH OPNDS ARE STRING  23950015
         TM    DEST+DESCDE,X'01'                                        24000015
         BC    BZ,LBE15                BRANCH IF BOTH OPERANDS REAL     24050015
         CLI   CPMASK,6                                                 24100015
         BC    BZ,LBE15                BRANCH IF 'EQUAL' COMPARE        24150015
         CLI   CPMASK,8                                                 24200015
         BC    BZ,LBE15                BRANCH IF 'NOT EQUAL' COMPARE    24250015
         MVC   PAR6+1(3),ERR48                                          24300015
         BAL   RR,ERROR                GENERATE ERROR MESSAGE           24350015
         MVI   CPMASK,6                SET TO 'EQUAL' COMPARE           24400015
LBE15    MVI   DEST+DESCDE,X'88'                                        24450015
         LH    G0,OPND                 LOOP COUNT                       24500015
         LA    DSR,DES2                2ND OPERAND DESCRIPTION.         24550015
         SR    G1,G1                                                    24600015
LBE9     TM    DESCDE(DSR),X'80'       TEST BIT 0                       24650015
         BC    BZ,LBE7                 BRANCH IF OPERAND IS STRING TYPE 24700015
         TM    DESCDE(DSR),X'01'       TEST FOR COMPLEX OPERAND         24750015
         BC    BZ,LBE6                 BRANCH IF REAL                   24800015
         AR    G1,G0                   ADD IN LOOP COUNTER              24850015
LBE6     OC    DEST+DESCDE(1),DESCDE(DSR)  ARITH TYPE SO 'OR' IN TYPE   24900015
         TM    DESCDE(DSR),X'02'                                        24950015
         BC    BO,LBE8                 BRANCH IF FLOATING               25000015
         NI    DESCDE(DSR),X'EF'       MAKE FIXED TYPE SHORT            25050015
         BC    B,LBE8                                                   25100015
LBE7     OI    DEST+DESCDE,X'10'       SET LONG BIT ON IN RESULT     I8 25130016
         TM    DESCDE(DSR),X'04'                                     I8 25160016
         BC    BO,LBE8                 BRANCH IF CHARACTER STRING       25200015
         OI    DEST+DESCDE,X'04'       SET BINARY BIT ON IN RESULT      25250015
LBE8     LA    DSR,DES1                1ST OPERAND DESCRIPTION          25300015
         BCT   G0,LBE9                 LOOP TEST                        25350015
         NI    DEST+DESCDE,X'9F'       REMOVE STERLING BIT              25400015
         STH   G1,CPX                  SET COMPLEX TYPE                 25450015
         OC    CPX+1(1),OPCOD                                           25500015
         CLI   OPCOD,EXPON                                              25550015
         BC    BZ,EXPONT               BRANCH IF EXPONENTIAL OPERATION  25600015
         TM    DEST+DESCDE,X'02'                                        25650015
         BC    BO,LBE18                BRANCH IF FLOATING RESULT        25700015
         NI    DEST+DESCDE,X'EF'       MAKE FIXED RESULT SHORT          25750015
         BC    B,LBE21                                                  25800015
LBE18    OC    DEST+DESCDE(1),AMDBUF+DESCDE  FLOAT AMD FUNC RESULT      25850015
         SPACE 2                                                        25900015
*              TEST FOR OPERAND CONVERSIONS AND CONSTANTS.              25950015
LBE21    LH    G0,OPND                 LOOP COUNT                       26000015
         LA    DSR,DES2                POINT AT DES2                    26050015
LBE11    TM    DESCDE(DSR),X'02'                                        26100015
         BC    BO,LBE25                BRANCH IF FLOATING               26150015
         NI    DESCDE(DSR),X'EF'       MAKE FIXED TYPE SHORT            26200015
LBE25    CLC   DEST+DESCDE(1),DESCDE(DSR)  COMPARE OPERAND AND RESULT   26250015
         BC    BZ,LBE10                    TYPES, BRANCH IF SAME.       26300015
         MVC   DESBUF+DESCDE(1),DEST+DESCDE  MOVE TARGET DED TO BUFFER  26350015
         BAL   RR,CONVT                                                 26400015
         BC    B,LBE16                                                  26450015
LBE10    CLI   DESTK(DSR),X'80'                                         26500015
         BC    BNE,LBE16               BRANCH IF NOT A CONSTANT         26550015
         BAL   RR,CONST                                                 26600015
LBE16    LA    DSR,DES1                POINT AT 1ST OPERAND DESCRIPTION 26650015
         BCT   G0,LBE11                TEST LOOP                        26700015
*              SET PC OPERATION CODE TO LONG,SHORT FLOAT/PACK DEC/FIXED 26750015
ARITH2   TM    DEST+DESCDE,X'02'                                        26800015
         BC    BZ,LBE12                BRANCH IF FIXED                  26850015
         TM    DEST+DESCDE,X'10'                                        26900015
         BC    BZ,LBE13                BRANCH IF SHORT FLOAT            26950015
         MVI   OPTYP,FLD               SET OP TYPE LONG FLOAT           27000015
         BC    B,LBUN1                                                  27050015
LBE13    MVI   OPTYP,FLE               SET OP TYPE TO SHORT FLOAT       27100015
         BC    B,LBUN1                                                  27150015
LBE12    MVI   BIGN,0                  FIXED, SO SET BIG N              27200015
         TM    DEST+DESCDE,X'04'                                        27250015
         BC    BO,LBE14                BRANCH IF FIXED BINARY           27300015
         MVI   BIGN+1,15               BIGN=15                          27350015
         SR    G1,G1                                                    27400015
         IC    G1,DES1+DESP            1ST OPERAND PRECISION            27450015
         SRA   G1,1                                                     27500015
         LA    G1,1(G1)                                                 27550015
         STH   G1,DES1+DESLTH          1ST OPERAND BYTE SIZE            27600015
         IC    G1,DES2+DESP            2ND OPERAND PRECISION            27650015
         SRA   G1,1                                                     27700015
         LA    G1,1(G1)                                                 27750015
         STH   G1,DES2+DESLTH          2ND OPERAND BYTE SIZE            27800015
         BC    B,LBUN1                                                  27850015
LBE14    MVI   BIGN+1,31               BIGN=31                          27900015
         MVI   OPTYP,FXB                                                27950015
LBUN1    TM    OPCOD,X'10'                                              28000015
         BC    BZ,LBUN3                BRANCH IF 2 OPERANDS             28050015
         SPACE 2                                                        28100015
*              UNARY PLUS,MINUS OPERATIONS                              28150015
         NI    OPCOD,X'0F'             SET OPERATOR TO INFIX +,-        28200015
         TM    DES2+DESCDE,X'06'                                        28250015
         BC    BZ,LBUN4                BRANCH IF PACKED DECIMAL         28300015
         LA    BR,GETFR                ADDRESS OF'GET FLOAT REGISTER'   28350015
         TM    DES2+DESCDE,X'02'                                        28400015
         BC    BO,LBUN2                BRANCH IF FLOATING               28450015
         LA    BR,GETGR                ADDRESS OF 'GET GEN REGISTER'    28500015
LBUN2    BAL   RR,SETCPX                                                28550015
         BAL   RR,SWOP                 PUT DES2 INTO REGISTER IF NOT PD 28600015
         MVC   DEST(TOTDES),DES1       SET RESULT TYPE                  28650015
         BC    B,FXC8                  STACK RESULT AND GET NEXT TRIPLE 28700015
LBUN4    MVC   DEST(4),DES2            SET RESULT TYPE                  28750015
         MVI   ARCOD,X'10'             SET FOR SWOP                     28800015
         SR    G1,G1                                                    28850015
         STH   G1,SHFT1                ZERO 1ST SHIFT                   28900015
         IC    G1,DES2+DESP            RESULT PRECISION                 28950015
         LH    G0,DES2+DESLTH                                           29000015
         BC    B,GENRPD                GO TO GENERATE PD CODE           29050015
LBUN3    TM    DEST+DESCDE,X'02'                                        29100015
         BC    BZ,LBFX1                BRANCH IF FIXED                  29150015
*                                                                       29200015
*              GENERATE CODE FOR FLOATING ARITHMETIC.                   29250015
*                                                                       29300015
LBFL1    CLC   DES1+DESP(1),DES2+DESP  COMPARE OPERAND PRECISIONS       29350015
         BC    BH,LBFL8                BRANCH IF 1ST OPERAND LONGER     29400015
         MVC   DEST+DESP(1),DES2+DESP  SET RESULT PRECISION             29450015
         BC    B,LBFL9                                                  29500015
LBFL8    MVC   DEST+DESP(1),DES1+DESP  SET RESULT PRECISION             29550015
LBFL9    LA    BR,GETFR                BRANCH FOR FLOAT REGISTER        29600015
         BAL   RR,SETCPX               SET COMPLEX BUFFERS OR CALL SEQ  29650015
         CLI   AMDBUF,0                                                 29700015
         BC    BZ,LBFL9A               BRANCH IF NOT AMD FUNCTION       29750015
         MVC   DEST+DESCDE(3),AMDBUF+DESCDE  RESET RESULT DED           29800015
LBFL9A   TM    DEST+DESCDE,X'01'                                        29850015
         BC    BZ,LBFL2                BRANCH IF REAL RESULT            29900015
         LA    RR,LBFL12                                                29950015
         ST    RR,CPXRET               RESET COMPLEX RETURN             30000015
         CLI   OPCOD,MULT                                               30050015
         BC    BNL,LBFL6               BRANCH IF MULT OR DIVIDE         30100015
LBFL12   BAL   RR,TSTOD1               TEST WHETHER 1ST OPND IS ZERO    30150015
         BC    B,LBFL11                BRANCH IF ZERO - SUBR LOADS      30200015
LBFL2    TM    DES2+DESFLG,X'80'       TEST 2ND OPERAND                 30250015
         BC    BZ,LBFL3                BRANCH IF NOT IN REGISTER        30300015
         TM    DES2+DESFLG,X'40'                                        30350015
         BC    BO,LBFL3                BRANCH IF NOT IN REGISTER        30400015
         TM    DES1+DESFLG,X'80'       TEST 1ST OPERAND                 30450015
         BC    BZ,LBFL4                BRANCH IF NOT IN REGISTER        30500015
         TM    DES1+DESFLG,X'40'                                        30550015
         BC    BZ,LBFL5                BRANCH IF IN REGISTER            30600015
LBFL4    CLI   OPCOD,DIV               TEST OP CODE                     30650015
         BC    BZ,LBFL6                BRANCH IF OP IS DIVISION         30700015
         BAL   RR,SWOP                 SWOP OPERANDS                    30750015
LBFL5    MVC   PCOD1(2,PCR),DES1+DESBSE  SET REGISTER IN PC             30800015
         LH    G1,DES1+DESBSE          RESULT REGISTER NUMBER           30850015
         STH   G1,REG                  SET REG TO RESULT REGISTER NUM   30900015
         C     G1,SEVEN                                                 30950015
         BC    BNL,ERROR1              CREATE ERROR MESSAGE AND ABORT   31000015
LBFL10   SLL   G1,1                                                     31050015
         LA    G1,FRBLK(G1)                                             31100015
         ST    G1,DESAD                STORE ADDRESS OF RESULT REG BLK  31150015
         OI    RGD1(G1),16             SET FOR FUTURE USE               31200015
LBFL7    MVI   DEST+DESFLG,X'80'          SET RESULT REGISTER IN TARGET 31250015
         MVC   DEST+DESBSE(2),PCOD1(PCR)  DESCRIPTION                   31300015
         BAL   RR,TSTOD2               TEST WHETHER 2ND OPND IS IMAG 0  31350015
         BC    B,LBE35                                                  31400015
         MVC   PCOPN(1,PCR),OPCOD      SET OP CODE TO A,S,M,D,C         31450015
         OC    PCOPN(1,PCR),OPTYP      SET OP TYPE TO LONG/SHORT FLOAT  31500015
         LA    DSR,DES2                                                 31550015
         BAL   RR,GETADX               SET 2ND OPERAND IN PC            31600015
         BC    B,LBE35                 RETURN                           31650015
LBFL3    TM    DES1+DESFLG,X'80'       TEST 1ST OPERAND                 31700015
         BC    BZ,LBFL6                BRANCH IF NOT IN REGISTER        31750015
         TM    DES1+DESFLG,X'40'                                        31800015
         BC    BZ,LBFL5                BRANCH IF IN REGISTER            31850015
LBFL6    LA    DSR,DES1                                                 31900015
         BALR  RR,BR                   GET A FLOATING REGISTER          31950015
LBFL11   MVC   PCOD1(2,PCR),REG        SET NEW REGISTER IN PC           32000015
         BC    B,LBFL7                                                  32050015
*                                                                       32100015
*              GENERATE CODE FOR FIXED ARITHMETIC.                      32150015
*                                                                       32200015
LBFX1    SR    G0,G0                                                    32250015
         IC    G0,DES1+DESQ            SCALE FACTOR OF 1ST OPERAND (Q)  32300015
         SR    G1,G1                                                    32350015
         IC    G1,DES2+DESQ            SCALE FACTOR OF 2ND OPERAND (S)  32400015
         MVI   SHFT1+2,SRDA            SET 1ST SHIFT TO 'SRDA'          32450015
         MVI   SHFT2+2,SLDA            SET 2ND SHIFT TO 'SLDA'          32500015
         SR    GRN,GRN                                                  32550015
         IC    GRN,AMDBUF+DESQ         FUNCTION SCALE FACTOR =(U)       32600015
         CLI   OPCOD,MULT                                               32650015
         BC    BZ,LBFX20               BRANCH IF MULTIPLY               32700015
         CLI   OPCOD,DIV                                                32750015
         BC    BZ,LBFX21               BRANCH IF DIVIDE                 32800015
         SPACE 2                                                        32850015
*              ADD,SUBTRACT,COMPARE OPERATIONS.                         32900015
LBFX2    SR    G0,G1                   (Q-S)=(X)                        32950015
         LA    BR,GETGRE               LOAD EVEN REGISTER OF PAIR       33000015
         LTR   G0,G0                                                    33050015
         BC    BNL,LBFX3               BRANCH IF SHIFT NOT NEGATIVE     33100015
         OI    ARCOD,X'10'             SET BIT FOR SWOP                 33150015
         LPR   G0,G0                                                    33200015
         BC    B,LBFX4                                                  33250015
LBFX3    IC    G1,DES1+DESQ            RESULT SCALE FACTOR = (Q)        33300015
LBFX4    STH   G0,SHFT1                SHIFT1= (S)                      33350015
         STH   G1,DEST+DESP            NORMAL RESULT SCALE FACTOR (N)   33400015
         IC    G0,DES1+DESP            1ST OPERAND PRECISION (P)        33450015
         IC    G1,DES2+DESP            2ND OPERAND PRECISION (R)        33500015
         TM    ARCOD,X'10'                                              33550015
         BC    BO,LBFX4A               BRANCH IF NEGATIVE SHIFT         33600015
         AH    G1,SHFT1                (R+Q-S)                          33650015
         BC    B,LBFX4B                                                 33700015
LBFX4A   AH    G0,SHFT1                (P-Q+S)                          33750015
LBFX4B   CR    G0,G1                   COMPARE (P,R+Q-S) OR(P-Q+S,R)    33800015
         BC    BL,LBFX4C                                                33850015
         LR    G1,G0                                                    33900015
LBFX4C   LH    G0,SHFT1                                                 33950015
LBFX4D   LA    G1,1(G1)                NORMAL RESULT PRECISION          34000015
         SH    GRN,DEST+DESP           (U-N)                            34050015
         CLI   AMDBUF+DESFLG,0                                          34100015
         BC    BNE,LBFX4E              BRANCH IF AMD FUNCTION           34150015
         SR    GRN,GRN                 NORMAL ARITH-SO CLEAR            34200015
         MVC   AMDBUF+DESQ(1),DEST+DESQ  FUNCTION SF = NORMAL SF        34250015
LBFX4E   TM    DEST+DESCDE,X'04'                                        34300015
         BC    BZ,GENRPD               IF DECIMAL,GO TO PD CODE GENER   34350015
         AR    G1,GRN                  TOTAL PRECISION+FUNCT SHIFT      34400015
         CH    G1,BIGN                                                  34450015
         BC    BNH,LBFX4F              BRANCH IF LARGER THAN BIG N      34500015
         LH    G1,BIGN                 SET TO BIG N                     34550015
LBFX4F   STC   G1,DEST+DESP                                             34600015
         AR    GRN,G0                  (X=S+U-N)                        34650015
         BC    BH,LBFX6                BRANCH IF GREATER THAN ZERO      34700015
         CLI   OPCOD,MULT                                               34750015
         BC    BZ,LBFX5                BRANCH IF MULTIPLY FUNCTION      34800015
         MVI   SHFT1+2,SRA             1ST SHIFT SET TO 'SRA'           34850015
         LA    BR,GETGR                LOAD A SINGLE REGISTER           34900015
LBFX5    MVI   SHFT2+2,SRA             2ND SHIFT SET TO 'SRA'           34950015
         LPR   GRN,GRN                                                  35000015
         BC    B,LBFX8                                                  35050015
LBFX6    CH    G0,H32                                                   35100015
         BC    BH,LBFX10               BRANCH IF SHIFT GREATER THAN 32  35150015
         CLI   OPCOD,MULT                                               35200015
         BC    BZ,LBFX8                BRANCH IF MULTIPLY               35250015
         LTR   G0,G0                                                    35300015
         BC    BH,LBFX7                BRANCH IF SHIFT GREATER THAN 0   35350015
         MVI   SHFT2+2,SLA             2ND SHIFT SET TO 'SLA'           35400015
         LA    BR,GETGR                LOAD A SINGLE REGISTER           35450015
         BC    B,LBFX8                                                  35500015
LBFX7    CLI   OPCOD,CPR                                                35550015
         BC    BZ,LBFX7A               BRANCH IF COMPARE                35600015
         CLC   AMDBUF+DESQ(1),DEST+DESQ                                 35650015
         BC    BNH,LBFX8               BRANCH IF FUNC SF .LE. NORMAL SF 35700015
LBFX7A   CH    G0,H32                                                   35750015
         BC    BZ,LBFX8                BRANCH IF SHIFT = 32             35800015
         OI    ARCOD,X'08'             SET BIT TO GENERATE  SR  GRO,GRO 35850015
LBFX8    MVC   DEST+DESQ(1),AMDBUF+DESQ                                 35900015
         BC    B,LBFX11                                                 35950015
LBFX10   CH    GRN,H32                                                  36000015
         BC    BNH,LBFX8               BRANCH IF EXTRA SHIFT .LE. 32    36050015
         LH    GRN,H32                 SET SHIFT SIZES TO 32            36100015
         STH   GRN,SHFT1                                                36150015
LBFX11   STH   GRN,SHFT2                                                36200015
         BC    B,FXC1                                                   36250015
         SPACE 2                                                        36300015
*              MULTIPLY OPERATION.                                      36350015
LBFX20   LA    BR,GETGRO               SET TO LOAD ODD REGISTER OF PAIR 36400015
         AR    G1,G0                   NORMAL RESULT SCALE FACTOR       36450015
         SH    G1,SF0                                                   36500015
         STH   G1,DEST+DESP            NORMAL RESULT SCALE FACTOR (N)   36550015
         SR    G1,G1                                                    36600015
         STH   G1,SHFT1                ZERO 1ST SHIFT                   36650015
         IC    G0,DES1+DESP            1ST OPERAND PRECISION (P)        36700015
         IC    G1,DES2+DESP            2ND OPERAND PRECISION (R)        36750015
         AR    G1,G0                   (P+R)                            36800015
         LA    G0,32                   NORMAL BINARY 2ND SHIFT IS 32    36850015
         TM    DEST+DESCDE,X'04'                                        36900015
         BC    BO,LBFX4D               BRANCH IF FIXED BINARY           36950015
         LH    G0,DES1+DESLTH                                           37000015
LFX20A   AH    G0,DES2+DESLTH          WORKSPACE LENGTH IN BYTES        37050015
         BC    B,LBFX4D                                                 37100015
         SPACE 2                                                        37150015
*              DIVIDE OPERATION.                                        37200015
LBFX21   SR    G0,G1                   (Q-S)                            37250015
         SH    GRN,SF0                 FUNCTION RESULT SCALE FACTOR     37300015
         CLI   AMDBUF+DESFLG,0                                          37350015
         BC    BNE,LBFX24                                               37400015
         IC    G1,DES1+DESP            1ST OPERAND PRECISION (P)        37450015
         SR    G0,G1                   (-P+Q-S)                         37500015
         LH    GRN,BIGN                                                 37550015
         AR    G0,GRN                  (N-P+Q-S)                        37600015
         AH    G0,SF0                                                   37650015
         STC   G0,AMDBUF+DESQ          NORMAL RESULT SCALE FACTOR       37700015
         STC   GRN,DEST+DESP           NORMAL RESULT PRECISION          37750015
         LR    G0,G1                   (P)                              37800015
LBFX24   MVC   DEST+DESQ(1),AMDBUF+DESQ  RESULT SCALE FACTOR            37850015
         TM    DEST+DESCDE,X'04'                                        37900015
         BC    BZ,LBFX25               BRANCH IF DECIMAL                37950015
         SR    G0,GRN                                                   38000015
         BC    BNL,LBFX22              BRANCH IF SHIFT WILL BE .GE. 32  38050015
         OI    ARCOD,X'08'             SET BIT TO GENERATE  SR  GRO,GRO 38100015
LBFX22   AH    G0,H32                                                   38150015
         BC    BNL,LBFX23              BRANCH IF SHIFT RIGHT            38200015
         MVI   SHFT1+2,SLA             SET 1ST SHIFT TO 'SLA'           38250015
         LPR   G0,G0                                                    38300015
LBFX23   STH   G0,SHFT1                SET 1ST SHIFT SIZE               38350015
         SR    GRN,GRN                 ZERO 2ND SHIFT                   38400015
         LA    BR,GETGRE               SET TO LOAD EVEN REGISTER        38450015
         BC    B,LBFX8                                                  38500015
LBFX25   SR    GRN,G0                                                   38550015
         STH   GRN,SHFT1                                                38600015
         SR    GRN,GRN                 ZERO FUNCTION SHIFT              38650015
         LH    G1,BIGN                 NORMAL RESULT PRECISION          38700015
         LA    G0,8                                                     38750015
         BC    B,LFX20A                                                 38800015
         SPACE 2                                                        38850015
*              GENERATE FIXED BINARY PSEUDO CODE.                       38900015
FXC1     BAL   RR,SETCPX               SET COMPLEX RETURN               38950015
         TM    ARCOD,X'10'                                              39000015
         BC    BZ,FXC2                 BRANCH IF NO SWOP                39050015
         BAL   RR,SWOP                                                  39100015
         BC    B,FXC4                                                   39150015
FXC2     BAL   RR,TSTOD1               TEST 1ST OPERAND                 39200015
         BC    B,FXC4                  BRANCH IF COMPLEX ZERO           39250015
FXC3     LA    DSR,DES1                                                 39300015
         BALR  RR,BR                   LOAD REGISTER                    39350015
FXC4     TM    ARCOD,X'08'                                              39400015
         BC    BZ,FXC5                 BRANCH IF ODD REGISTER NOT CLEAR 39450015
         MVC   0(LPCI1,PCR),PCIN1                                       39500015
         LA    PCR,PCSZ5(PCR)          GENERATE   SR   GRO,GRO          39550015
FXC5     LA    DSR,SHFT1                                                39600015
         BAL   RR,GNSHFT               GENERATE 1ST SHIFT               39650015
         BAL   RR,TSTOD2               TEST 2ND OPERAND                 39700015
         BC    B,FXC6                  BRANCH IF COMPLEX ZERO           39750015
         MVC   PCOPN(1,PCR),OPCOD                                       39800015
         OI    PCOPN(PCR),FXB          SET OPERATION CODE               39850015
         MVC   PCOD1(2,PCR),REG        SET REGISTER                     39900015
         LA    DSR,DES2                                                 39950015
         BAL   RR,GETADX               GENERATE   OP   REG,DES2         40000015
FXC6     CLI   OPCOD,CPR                                                40050015
         BC    BZ,FXC10                BRANCH IF COMPARE                40100015
         LA    DSR,SHFT2                                                40150015
         BAL   RR,GNSHFT               GENERATE 2ND SHIFT               40200015
         MVI   DEST+DESFLG,X'80'                                        40250015
         LH    G1,REG                                                   40300015
         CLI   OPCOD,DIV                                                40350015
         BC    BNE,FXC7                                                 40400015
         LA    G1,GRBLK+RGBLSZ                                          40450015
         ST    G1,DESAD                                                 40500015
         LA    G1,GRO                                                   40550015
FXC7     STH   G1,DEST+DESBSE          RESULT REGISTER                  40600015
FXC8     CLI   DEST+DESP,21                                             40650015
         BC    BNH,FXC9                BRANCH IF SHORT                  40700015
         OI    DEST+DESCDE,X'10'                                        40750015
FXC9     CLI   AMDBUF+DESFLG,0                                          40800015
         BC    BZ,LBE35                BRANCH IF NOT AMD FUNCTION       40850015
         MVC   DESBUF(6),DEST                                           40900015
         MVC   DESBUF+DESCDE(3),AMDBUF+DESCDE   TARGET DESCRIPTION      40950015
         LA    DSR,DEST                                                 41000015
         BAL   RR,ASSIGN                                                41050015
         MVC   DEST(ISTK),DESBUF       SET FUNCTION RESULT DESCRIPTION  41100015
         BC    B,LBE35                                                  41150015
FXC10    CLI   SHFT2+1,X'00'                                            41200015
         BC    BE,LBE35                BRANCH IF ZERO SHIFT             41250015
         LA    G0,1                                                     41300015
         AH    G0,ZEQMAX                                                41350015
         STH   G0,ZEQMAX               BUMP CURRENT COMPILER LABEL NO   41400015
         MVC   0(LPCI4,PCR),PCIN4                                       41450015
         MVC   PCOD2(2,PCR),ZEQMAX             SLOT CURRENT COMPILER    41500015
         MVC   3*PCSZ5+PCOD1(2,PCR),ZEQMAX    LABLE INTO BRANCH INSTRS. 41550015
         LA    PCR,3*PCSZ5+PCSZ3(PCR)  BUMP PC POINTER                  41600015
         BC    B,LBE35                                                  41650015
RESLT1   TM    ARCOD,X'04'                                              41700015
         BC    BZ,LBE36                BRANCH IF NOT COMPLEX FLT FUNCT  41750015
         MVC   DESBUF(ISTK),DEST       CONSTRUCT LONG TO SHORT ASSIGN   41800015
         LH    BR,DESBUF+DESBSE        WORKSPACE OFFSET                 41850015
         LA    BR,4(BR)                                                 41900015
         STH   BR,DESBUF+DESBSE                                         41950015
         LA    DSR,DESBUF                                               42000015
         MVI   PCOPN(PCR),MVC                                           42050015
         MVI   PCF1(PCR),3                                              42100015
         BAL   RR,GETAS1                                                42150015
         LA    BR,4(BR)                                                 42200015
         STH   BR,DESBUF+DESBSE                                         42250015
         BAL   RR,GETADS               GENERATE  MVC  T+4(4),T+8        42300015
         NI    DEST+DESCDE,X'EF'       SET RESULT TO SHORT              42350015
LBE36    LA    DSR,DEST                                                 42400015
         BAL   RR,ADDSTK               ADD WORK SPACE TO TEMP CORE STK  42450015
         LH    GRN,NTMP                NO OF TEMPS                      42500015
         CLI   OPCOD,CPR                                                42550015
         BC    BNE,LBFX34              BRANCH IF NOT COMPARE            42600015
         LA    GRN,1(GRN)              ADD ONE TO NO OF TEMPS           42650015
         BC    B,LBE30                                                  42700015
LBFX34   LTR   GRN,GRN                                                  42750015
         BC    BZ,NXT3                 BRANCH IF NO TEMPS               42800015
         BAL   RR,RLSTK1               RELEASE TEMPS                    42850015
         BC    B,NXT3                                                   42900015
LBE35    TM    DEST+DESCDE,X'01'       TEST RESULT                      42950015
         BC    BO,CPLEX                BRANCH TO COMPLEX ROUTINE        43000015
RESLT2   EQU   *                                                        43050015
         LH    GRN,NTMP                REMAINING TEMPORARIES            43100015
         LTR   GRN,GRN                                                  43150015
         BC    BZ,LBE32                BRANCH IF NO TEMPORARIES         43200015
LBE30    BAL   RR,RELSTK               RELEASE TEMPORARIES              43250015
LBE32    CLI   OPCOD,CPR                                                43300015
         BC    BZ,LBE31                BRANCH IF COMPARE                43350015
         LA    DSR,DEST                                                 43400015
LBE34    BAL   RR,ADDSTK               ADD RESULT TO STACK              43450015
NXT3     BC    B,NXTPL                 GET NEXT TRIPLE OF INTEREST      43500015
LBE31    BAL   RR,SC5                                                   43550015
         TRT   0(1,IP),SCTRT(PAR)      TRANSLATE NEXT TRIPLE            43600015
         STC   TRTBSE,OPCOD                                             43650015
         CLI   OPCOD,X'D0'                                              43700015
         BC    BNE,LBE33               BRANCH IF NOT IF,WHILE',TT       43750015
         NC    PCOD2(2,IP),PCOD2(IP)                                    43800015
         BC    BNE,LBE33               BRANCH IF 2ND OPERAND NOT '00'   43850015
         MVC   PCOD2+1(1,IP),CPMASK    INSERT MASK                      43900015
         BAL   RR,MOVEPC               MOVE PC TO OUTPUT                43950015
         BC    B,LSUB1                 EXTRA TRIPLE TO OP AND GET NEXT  44000015
LBE33    LA    DSR,BITDES              POINT AT BIT STRING,LENGTH 1     44050015
         L     G0,CSTK                                                  44100015
         STH   G0,BITDES+DESBSE        SET CURRENT TOP OF CORE STACK    44150015
         LA    G0,1                                                     44200015
         AH    G0,ZEQMAX                                                44250015
         STH   G0,ZEQMAX               BUMP CURRENT COMPILER LABEL NO   44300015
         MVC   0(LPCI5,PCR),PCIN5                                       44350015
         BAL   RR,GETADS               SET UP PC -     MVI  S,X'00'     44400015
         MVC   PCOD1+1(1,PCR),CPMASK                                    44450015
         MVC   PCOD2(2,PCR),ZEQMAX                     BC   MASK,LBL    44500015
         LA    PCR,PCSZ5(PCR)          BUMP PC POINTER                  44550015
         BAL   RR,GETADS                               MVI  S,X'80'     44600015
         MVC   PCOD1(2,PCR),ZEQMAX                LBL  EQU  *           44650015
         LA    PCR,PCSZ3(PCR)          BUMP PC POINTER                  44700015
         BAL   RR,ADDSTK               ADD BIT STRING TO STACK          44750015
         BAL   RR,MOVEPC               MOVE PSEUDO CODE TO OUTPUT       44800015
         BC    B,LB0                   RE-SCAN THIS TRIPLE              44850015
         EJECT                                                          44900015
*              GETAD SUBROUTINE TO CONSTRUCT ADDRESSES IN PSEUDO-CODE   44950015
         SPACE 1                                                        45000015
*              FUNCTION - TO CONSTRUCT OPERANDS FOR PSEUDO-CODE FROM A  45050015
*        STANDARD DESCRIPTION ADDRESSED BY REGISTER DSR. THE CURRENT    45100015
*        PSEUDO-CODE INSTRUCTION IS ADDRESSED BY REGISTER PCR.          45150015
         SPACE 1                                                        45200015
*              ENTRY POINT (1) 'GETADX' TO CONSTRUCT A 2ND OPERAND FOR  45250015
*        RR OR RX TYPE INSTRUCTIONS. 'PCR' IS INCREMENTED OVER THE      45300015
*        CURRENT INSTRUCTION.                                           45350015
*                          (2) 'GETAS1' TO CONSTRUCT A 1ST OPERAND FOR  45400015
*        SS TYPE INSTRUCTIONS. AN EXTRA LA MAY BE INSERTED.             45450015
*                          (3) 'GETADS' TO CONSTRUCT A 2ND OPERAND FOR  45500015
*        RS OR SS TYPE INSTRUCTIONS. AN EXTRA LA AND ASSOCIATED DROP'S  45550015
*        MAY BE INSERTED. 'PCR' IS INCREMENTED OVER THE CURRENT         45600015
*        INSTRUCTION AND ANY LA'S OR DROP'S.                            45650015
         SPACE 1                                                        45700015
*              EXTERNAL ROUTINE - 'SBGTNR' IN BLOCK LS TO GET NEXT      45750015
*        SYMBOLIC REGISTER.                                             45800015
         SPACE 1                                                        45850015
*              EXIT-NORMAL - TO INSTRUCTION AFTER INVOCATION.           45900015
         SPACE 1                                                        45950015
*              EXIT-ERROR (1) TO 'ERROR1' WITH BAD REGISTER NUMBER.     46000015
*        ERROR MESSAGE NUMBER 1600.                                     46050015
*                         (2) TO 'CERROR' WITH BAD DESCRIPTION. ERROR   46100015
*        MESSAGE NUMBER 1604.                                           46150015
         SPACE 1                                                        46200015
*              NOTES - REGISTERS G0,G1 ARE CHANGED.                     46250015
*                      REGISTER PCR IS INCREMENTED.                     46300015
*                      REGISTER DSR IS NOT CHANGED.                     46350015
         SPACE 3                                                        46400015
GETADX   ST    RR,GETRR                SAVE RETURN REGISTER             46450015
         MVI   GETCOD,X'80'            SET CODE FOR GETADX ENTRY        46500015
LBLA20   TM    DESFLG(DSR),BIT01       TEST BITS 0,1 OF FLAG            46550015
         BC    BNL,LBLA1               BRANCH IF NOT MIXED              46600015
         TM    DESFLG(DSR),X'80'       TEST BIT 0                       46650015
         BC    BZ,LBLA2                BRANCH IF 0,    BITS 01 ARE '01' 46700015
         CLC   DESBSE(2,DSR),MAXREG    REGISTER BY VALUE,SO TEST        46750015
         BC    BH,ERROR1               BRANCH IF NOT ABSOLUTE REGISTER  46800015
LBLA25   MVC   PCOD2(2,PCR),DESBSE(DSR) PUT REGISTER IN 2ND OPERAND     46850015
         OI    PCOPN(PCR),X'40'        MAKE OPERATION RR TYPE           46900015
         LA    G1,PCSZ5                PC SIZE                          46950015
         BC    B,GETRTN                                                 47000015
LBLA1    TM    DESFLG(DSR),BIT01       TEST BITS 0,1 OF FLAG            47050015
         BC    BZ,LBLA3                BRANCH IF DICTIONARY ENTRY '00'  47100015
         MVC   PCOD2(2,PCR),SCWSDR(PAR) DICT ENTRY OF CURRENT TEMP      47150015
         LH    G0,DESBSE(DSR)          MAIN OFFSET FROM BASE,           47200015
         TM    DESFLG(DSR),X'10'                                        47250015
         BC    BZ,LBLA23               BRANCH IF NO 2ND OFFSET          47300015
         AH    G0,DESOFS(DSR)          ADD 2ND OFFSET, IF ANY,          47350015
LBLA23   STH   G0,GETBUF               PUT IN BUFFER AND                47400015
         MVC   PCOSM1(2,PCR),GETBUF    STORE IN OSM PC.                 47450015
         BC    B,LBLA4                                                  47500015
LBLA2    OI    PCOD1(PCR),X'80'        SET MARKER FOR REGISTER,BY NAME. 47550015
LBLA3    MVC   PCOD2(2,PCR),DESBSE(DSR)   MOVE DICT REF OR ADDRESS REG  47600015
         SR    G1,G1                                                    47650015
         TM    DESFLG(DSR),X'30'       TEST FLAG BITS 2,3               47700015
         BC    BZ,LBLA6                BRANCH IF NO INDEX OR OFFSET     47750015
         BC    BL,LBLA5                BRANCH IF ONE OF INDEX,OFFSET    47800015
         MVC   PCOSM1(2,PCR),DESOFS(DSR)  MOVE OFFSET TO OSM PC         47850015
         MVC   PCOSM2(2,PCR),DESNDX(DSR)  AND INDEX REGISTER.           47900015
         MVI   PCOSM(PCR),OSM3         SET OPERATION                    47950015
         LA    G1,PCSZ5                                                 48000015
         BC    B,LBLA6                                                  48050015
LBLA5    TM    DESFLG(DSR),X'20'       TEST FLAG BIT 2                  48100015
         BC    BO,LBLA7                BRANCH IF INDEX ONLY             48150015
         MVC   PCOSM1(2,PCR),DESOFS(DSR)  OFFSET ONLY, SO MOVE TO PC    48200015
LBLA4    MVI   PCOSM(PCR),OSM1         AND SET OPERATION CODE           48250015
         BC    B,LBLA8                                                  48300015
LBLA7    MVC   PCOSM1(2,PCR),DESNDX(DSR)  INDEX ONLY, SO MOVE IT TO PC  48350015
         MVI   PCOSM(PCR),OSM2         AND SET OPERATION                48400015
LBLA8    LA    G1,PCSZ3                                                 48450015
LBLA6    LA    G1,PCSZ5(G1)            BUMP PC SIZE                     48500015
LBLA9    TM    GETCOD,X'20'                                             48550015
         BC    BO,LBLA10               BRANCH IF NOT GETADX ENTRY       48600015
         OI    PCOPN(PCR),X'80'        MAKE OPERATION RX TYPE           48650015
         BC    B,GETRTN                                                 48700015
*              GETADS ENTRY POINT CONSTRUCTS A 2ND OPERAND ADDRESS IN   48750015
*        RS,SI, OR SS TYPE PSEUDO-CODE FROM A STANDARD DESCRIPTION.     48800015
*                                                                       48850015
*              GETAS1 ENTRY POINT CONSTRUCTS A 1ST OPERAND ADDRESS IN   48900015
*        SS TYPE PSEUDO-CODE FROM A STANDARD DESCRIPTION.               48950015
*                                                                       49000015
GETAS1   EQU   *                                                        49050015
         MVI   GETCOD,X'40'            SET BIT 1 ON FOR GETAS1 ENTRY    49100015
         BC    B,LBLA11                                                 49150015
GETADS   EQU   *                                                        49200015
         MVI   GETCOD,X'00'            SET CODE FOR GETADS ENTRY        49250015
LBLA11   ST    RR,GETRR                SAVE RETURN REGISTER             49300015
         TM    DESFLG(DSR),X'80'       TEST BITS 0,1 FOR '10'           49350015
         BC    BN1,LBLA12                                               49400015
         TM    DESFLG(DSR),X'40'                                        49450015
         BC    BO,LBLA13               BRANCH IF TEMP '11'              49500015
         MVC   PAR6+1(3),ERR44         REGISTER BY VALUE, SO ERROR      49550015
         BC    B,CERROR                ERROR MESSAGE AND ABORT          49600015
LBLA12   TM    DESFLG(DSR),X'20'       TEST BIT 2 FOR INDEX             49650015
         BC    BZ,LBLA13                                                49700015
*              TWO REGISTERS ARE USED OR IMPLIED, SO GENERATE AN EXTRA  49750015
*              LA   SR,BASE(YR)   INSTRUCTION.                          49800015
         MVC   12(12,PCR),0(PCR)       MOVE CURRENT INSTRUCTION FORWARD 49850015
         MVI   PCOPN(PCR),LA           SET OPERATION CODE TO LA         49900015
         BAL   RR,SBGTNR               GET A SYMBOLIC REGISTER          49950015
         STH   G1,LDATA+2                                               50000015
         MVC   PCOD1(2,PCR),LDATA+2    SET 1ST REGISTER                 50050015
         LH    G1,LDATA                                                 50100015
         LA    G1,PCSZ3(G1)                                             50150015
         STH   G1,LDATA                BUMP NUMBER OF DROP'S            50200015
         LA    G1,DROPPC-PCSZ3+PCOD1(G1)                                50250015
         MVC   0(2,G1),LDATA+2         SET DROP PC                      50300015
         OI    GETCOD,X'20'            SET CODE BYTE AND                50350015
         BC    B,LBLA20                BRANCH TO RX TYPE CODING         50400015
LBLA10   AR    G1,PCR                NEXT PC                            50450015
         MVC   0(12,G1),12(PCR)        MOVE ORIGINAL INSTRUCTION BACK   50500015
         LR    PCR,G1                                                   50550015
         MVI   DESFLG(DSR),X'40'       CHANGE DESCRIPTION TO REG        50600015
         MVC   DESBSE(2,DSR),LDATA+2   BY NAME                          50650015
         NI    GETCOD,X'DF'            RESET CODE BYTE                  50700015
LBLA13   TM    PCOPN(PCR),BIT01        TEST OPERATION CODE AND          50750015
         BC    BN1,LBLA20              BRANCH TO RX TYPE IF RS OR SI    50800015
         MVI   SSFLG,X'00'                                              50850015
         LA    G1,PCF2(PCR)            SET POINTER TO 1ST OPERAND FIELD 50900015
         TM    GETCOD,X'40'            TEST CODE FOR ENTRY POINT        50950015
         BC    BO,LBLA14               BRANCH IF THIS IS 1ST OPERAND    51000015
         LA    G1,PCF3-PCF2(G1)        2ND OPERAND, SO BUMP POINTER     51050015
         BC    B,LBLA21                                                 51100015
LBLA14   MVI   PCLNG(PCR),PCSZ8        1ST OPERAND, SO SET LENGTH       51150015
LBLA21   TM    DESFLG(DSR),BIT01       TEST DESCRIPTION                 51200015
         BC    BZ,LBLA15               BRANCH IF DICTIONARY REF         51250015
         BC    BL,LBLA16               BRANCH IF SYMB ADDRESS REGISTER  51300015
         MVC   0(2,G1),SCWSDR(PAR)     TEMP OFFSET, MOVE TEMP DICT REF  51350015
         LH    G0,DESBSE(DSR)                                           51400015
         TM    DESFLG(DSR),X'10'                                        51450015
         BC    BZ,LBLA24               BRANCH IF NO 2ND OFFSET          51500015
         AH    G0,DESOFS(DSR)          ADD TEMP OFFSET AND 2ND OFFSET   51550015
         BC    B,LBLA24                                                 51600015
LBLA16   OI    SSFLG,X'20'             SET FLAG FOR SYMB ADDRESS REG.   51650015
LBLA15   MVC   0(2,G1),DESBSE(DSR)     MOVE DICT REF OR SYMB REG.       51700015
         TM    DESFLG(DSR),X'10'       TEST FOR OFS IN DESCRIPTION      51750015
         BC    BZ,LBLA18               BRANCH IF NO OFS                 51800015
         LH    G0,DESOFS(DSR)                                           51850015
LBLA24   STH   G0,GETBUF                                                51900015
LBLA17   OI    SSFLG,X'08'             SET FLAG FOR OFFSET              51950015
         SR    G1,G1                                                    52000015
         IC    G1,PCLNG(PCR)           CURRENT LENGTH OF OPERATION      52050015
         LA    G0,PCF5-PCF4(G1)        BUMP BY FIELD SIZE AND           52100015
         STC   G0,PCLNG(PCR)           RESET LENGTH                     52150015
         AR    G1,PCR                  POINT TO NEXT OFFSET FIELD       52200015
         MVC   0(2,G1),GETBUF          MOVE OFFSET                      52250015
LBLA18   SR    G1,G1                                                    52300015
         TM    GETCOD,X'40'            TEST CODE FOR ENTRY POINT        52350015
         BC    BZ,LBLA22               BRANCH IF THIS IS 2ND OPERAND    52400015
         IC    G0,SSFLG                1ST OPERAND, SO SHIFT FLAG BITS  52450015
         SLL   G0,1                    LEFT ONE BIT                     52500015
         STC   G0,PCFLG(PCR)           SET FLAG BITS                    52550015
         BC    B,GETRTX                                                 52600015
LBLA22   IC    G1,PCLNG(PCR)           PC SIZE FROM LENGTH              52650015
LBLA19   OC    PCFLG(1,PCR),SSFLG      ADD ANY BITS TO SS FLAG BYTE     52700015
GETRTN   EQU   *                                                        52750015
         AR    PCR,G1                BUMP PC POINTER                    52800015
         CLI   LDATA+1,0                                                52850015
         BC    BZ,GETRTX               BRANCH IF NO DROP'S              52900015
         MVC   0(6,PCR),DROPPC         MOVE PC SKELETON                 52950015
         AH    PCR,LDATA               BUMP PC POINTER FOR ANY DROP'S   53000015
         MVI   LDATA+1,0               RESET NUMBER OF DROP'S           53050015
GETRTX   L     RR,GETRR                                                 53100015
         BCR   B,RR                    RETURN                           53150015
MAXREG   DC    H'15'                   MAX REGISTER NUMBER              53200015
         EJECT                                                          53250015
*                       STACKING SUBROUTINE                             53300015
         SPACE 1                                                        53350015
*              FUNCTION - TO MAINTAIN THE STACK OF INTERMEDIATE RESULT  53400015
*        DESCRIPTIONS AND WORKSPACE.                                    53450015
         SPACE 1                                                        53500015
*              ENTRY POINT (1) 'ADDSTK' TO ADD A DESCRIPTION,ADDRESSED  53550015
*        BY REGISTER DSR,TO THE STACKS. IF TEMPORARY WORKSPACE IS       53600015
*        NEEDED,ITS SPECIFICATION IS ADDED TO THE DESCRIPTION.          53650015
*                          (2) 'RELSTK' TO RELEASE THE TOP N ACTIVE     53700015
*        ITEMS FROM THE RESULT STACK. REGISTER GRN CONTAINS N.          53750015
*                          (3) 'RLSTK1' TO SAVE THE TOP ACTIVE ITEM AND 53800015
*        RELEASE THE NEXT N ACTIVE ITEMS FROM THE RESULT STACK.         53850015
*        REGISTER GRN CONTAINS N.                                       53900015
*                          (4) 'ITEM2' TO SET REGISTER STR TO THE 2ND   53950015
*        ACTIVE ITEM FROM THE TOP OF THE STACK.                         54000015
         SPACE 1                                                        54050015
*              EXTERNAL ROUTINE (1) 'ERROR' TO CREATE MESSAGE NUMBER    54100015
*        1601 IF STACK CONTAINS MORE THAN 200 ITEMS.                    54150015
         SPACE 1                                                        54200015
*              EXIT-NORMAL - TO INSTRUCTION AFTER INVOCATION.           54250015
         SPACE 1                                                        54300015
*              EXIT-ERROR - TO 'CERROR' IF RELEASES ARE REQUESTED WHEN  54350015
*        STACK IS EMPTY. ERROR MESSAGE NUMBER 1602.                     54400015
         SPACE 1                                                        54450015
*              WORK AREA - THE STACK OCCUPIES 2000 BYTES OF SCRATCH     54500015
*        STORAGE.                                                       54550015
         SPACE 1                                                        54600015
*              NOTES - REGISTERS G0,G1,GRN,STR ARE USED.                54650015
*                      REGISTER DSR IS NOT CHANGED.                     54700015
         SPACE 3                                                        54750015
ADDSTK   EQU   *                                                        54800015
         ST    RR,STKRR                SAVE RETURN REGISTER.            54850015
         L     STR,PSTK                BUMP ADDRESS OF DESCRIPTION      54900015
         LA    STR,ISTK(STR)           STACK ITEM AND SET PSTK, LSTK    54950015
         ST    STR,PSTK                                                 55000015
         ST    STR,LSTK                                                 55050015
         C     STR,MSTK                COMPARE WITH MAXIMUM STACK SIZE. 55100015
         BC    BL,LBLS43               BRANCH IF SPACE IN DESR STACK    55150015
         MVC   PAR6+1(3),ERR41                                          55200015
         BC    B,CERROR                ABORT STACK FULL                 55250015
LBLS43   MVC   0(ISTK,STR),0(DSR)      MOVE DESCRIPTION TO STACK        55300015
         CLI   DESFLG(STR),X'FF'                                        55350015
         BC    BE,LBLS8                BRANCH IF STRUNG FLAG            55400015
         TM    DESFLG(STR),X'04'                                        55450015
         BC    BZ,LBLS32               BRANCH IF SUBSTR BIT IS NOT SET  55500015
         MVI   GETLW,X'0F'             SET TO LOAD PHASE LW             55550015
         BC    B,RETURN              FOR DICT REF OR WORKSPACE OFFSET   55600015
LBLS32   TM    DESFLG(STR),X'80'                                        55650015
         BC    BZ,RETURN               BRANCH IF DICT REF OR REG BY NAM 55700015
         TM    DESFLG(STR),X'C0'                                        55750015
         BC    BO,LBLS2                BRANCH IF TEMP IN WORKSPACE      55800015
         SPACE                                                          55850015
*              ITEM IS IN A REGISTER BY VALUE.                          55900015
         SPACE                                                          55950015
         CLI   BGPC,NFUNC                                               56000015
         BC    BNE,LBLS48              BRANCH IF NOT NULL FUNCTION      56050015
         XC    DESNDX(4,STR),DESNDX(STR) CLEAR REGISTER BLOCK ADDRESS   56100015
         BC    B,RETURN              IN TEMP STACK AND RETURN           56150015
LBLS48   L     G1,DESAD                ADDRESS OF REGISTER BLOCK        56200015
         ST    STR,0(G1)               STACK ADDRESS IN REGISTER BLOCK  56250015
         MVC   DESNDX(4,STR),DESAD     AND BLOCK ADDRESS IN STACK       56300015
         SR    G0,G0                                                    56350015
         TM    DESCDE(STR),X'02'                                        56400015
         BC    BO,LBLS36               BRANCH IF FLOATING               56450015
         IC    G0,NGR                                                   56500015
         A     G0,ONE                                                   56550015
         STC   G0,NGR                  BUMP NO OF ACTIVE GENERAL REGS   56600015
         BC    B,LBLS37                                                 56650015
LBLS36   IC    G0,NFR                                                   56700015
         A     G0,ONE                                                   56750015
         STC   G0,NFR                  BUMP NUMBER OF ACTIVE FLOAT REGS 56800015
LBLS37   STC   G0,RGD1(G1)             SET LATEST USE NO                56850015
         BC    B,RETURN                                                 56900015
LBLS8    MVI   DESFLG(STR),X'C0'       SET UP SKELETON STRING DESCRIPT< 56950015
         XC    DESP(8,STR),DESP(STR)   ZERO LENGTH STRING IN TEMP       57000015
         MVC   DESBSE(2,STR),CSTK+2                                     57050015
         MVI   GETLW,X'0F'             SET FLAG TO LOAD PHASE LW        57100015
LBLS2    LH    G0,DESBSE(STR)          UPDATE CORE STACK - GET BASE     57150015
         AH    G0,DESNDX(STR)          BUMP TOP OF STACK WITH NDX.      57200015
         TM    DESFLG(STR),X'10'                                        57250015
         BC    BZ,LBLS44               BRANCH IF 2ND OFFSET NOT USED    57300015
         AH    G0,DESOFS(STR)          ADD 2ND OFFSET                   57350015
LBLS44   ST    G0,CSTK                 STORE NEW STACK SIZE             57400015
         CH    G0,SCWKSC(PAR)          TEST AGAINST THE MAXIMUM TEMP    57450015
         BC    BNH,LBLS6               CORE FOR THIS STATEMENT,         57500015
         STH   G0,SCWKSC(PAR)          UPDATE MAX IF NECESSARY          57550015
LBLS6    EQU   *                                                        57600015
RETURN   EQU   *                                                        57650015
         NI    RELCOD,X'F7'            SET TO DROP                      57700015
         L     RR,STKRR                   LOAD RETURN REGISTER, AND     57750015
         BCR   B,RR                       RETURN TO CALLER.             57800015
*                       RELSTK(N) ENTRY POINT                           57850015
RELSTK   EQU   *                                                        57900015
         ST    RR,STKRR                SAVE RETURN REGISTER             57950015
         L     STR,LSTK                SET DES STACK POINTER TO LOGICAL 58000015
         NI    RELCOD,X'0F'            TOP AND RELEASE CODE TO ZERO     58050015
         C     STR,BSTK                                                 58100015
         BC    BL,LBLSER               BRANCH IF STACK EMPTY            58150015
LBLS27   TM    DESFLG(STR),X'02'                                        58200015
         BC    BO,LBLS21               BRANCH IF ITEM TO BE HELD        58250015
         TM    DESFLG(STR),X'C0'                                        58300015
         BC    BO,LBLS45               BRANCH IF ITEM IN TEMP CORE STCK 58350015
         BC    BZ,LBLS23               BRANCH IF ITEM HAS DICT REF      58400015
         TM    DESFLG(STR),X'80'                                        58450015
         BC    BO,LBLS46               BRANCH IF REGISTER BY VALUE      58500015
         MVC   DESNDX(2,STR),DESBSE(STR)  SYMB REGISTER WITH ADDRESS    58550015
         BC    B,LBLS47                GO TO DROP                       58600015
LBLS46   NC    DESNDX(4,STR),DESNDX(STR) ITEM IN REGISTER BY VALUE      58650015
         BC    BZ,LBLS22               BRANCH IF NULL FUNCTION RESULT   58700015
         SR    G0,G0                                                    58750015
         ST    G1,STKG1                SAVE ARG REGISTER                58800015
         MVC   STKBUF(4),DESNDX(STR)   BLOCK ADDRESS FOR RELEASED       58850015
         L     G1,STKBUF               REGISTER.                        58900015
         MVN   STKBUF(1),RGD1(G1)      STORE USE NUMBER FOR FLOAT REGS  58950015
         ST    G0,0(G1)                CLEAR BLOCK                      59000015
         TM    DESCDE(STR),X'02'       TEST DESCRIPTION                 59050015
         BC    BZ,LBLS38               BRANCH IF FIXED                  59100015
         LA    G1,4                    EXAMINE ALL BLOCKS               59150015
         LA    DSR,FRBLK               COMPARE USE NO IN EACH BLOCK     59200015
LBLS41   CLC   RGD1(1,DSR),STKBUF      WITH USE NO OF RELEASED REGISTER 59250015
         BC    BNH,LBLS40              BRANCH IF USE NO ALREADY SMALLER 59300015
         IC    G0,RGD1(DSR)            LARGER,                          59350015
         S     G0,ONE                                                   59400015
         STC   G0,RGD1(DSR)                                             59450015
LBLS40   LA    DSR,RGBLSZ(DSR)         BUMP BLOCK ADDRESS               59500015
         BCT   G1,LBLS41               LOOP TEST                        59550015
         IC    G0,NFR                                                   59600015
         S     G0,ONE                  SUBTRACT ONE FROM NUMBER OF      59650015
         STC   G0,NFR                  FLOATING REGISTERS IN USE.       59700015
         BC    B,LBLS39                                                 59750015
LBLS38   IC    G0,NGR                                                   59800015
         S     G0,ONE                  SUBTRACT ONE FROM NUMBER OF      59850015
         STC   G0,NGR                  GENERAL REGISTERS IN USE         59900015
LBLS39   L     G1,STKG1                RESTORE ARG REGISTER             59950015
         BC    B,LBLS22                                                 60000015
LBLS23   TM    DESFLG(STR),X'20'       ITEM IS DICTIONARY REFERENCE     60050015
         BC    BZ,LBLS22               BRANCH IF NO INDEX REGISTER      60100015
LBLS47   CLC   DESNDX(2,STR),ZOSMRG                                     60150015
         BC    BNH,LBLS22              BRANCH IF AN OPTIMISING REGISTER 60200015
         TM    RELCOD,X'08'                                             60250015
         BC    BO,LBLS22               BRANCH IF NO DROP NEEDED         60300015
         TM    DESFLG(STR),X'05'       TEST SUBSTR BITS                 60350015
         BC    BO,LBLS22               AVOID DROP IF SET                60400015
         MVI   PCOPN(PCR),DROP           INSERT DROP PC                 60450015
         MVC   PCOD1(2,PCR),DESNDX(STR)                                 60500015
         LA    PCR,PCSZ3(PCR)                                           60550015
         BC    B,LBLS22                                                 60600015
LBLS45   TM    DESCDE(STR),X'D0'                                        60650015
         BC    BNE,LBLS21              BRANCH IF NOT FIXED STRING       60700015
         NC    DESP(2,STR),DESP(STR)                                    60750015
         BC    BNE,LBLS21              BRANCH IF NOT ZERO LENGTH        60800015
LBLS22   OI    DESFLG(STR),X'04'       SET BIT FOR CORE STACK INACTIVE  60850015
LBLS21   OI    DESFLG(STR),X'08'       SET BIT FOR DESR STACK INACTIVE  60900015
LBLS24   S     STR,ITEMSZ              SUBTRACT ONE ITEM                60950015
         C     STR,BSTK                                                 61000015
         BC    BNL,LBLS34              BRANCH, UNLESS BOTTOM OF STACK   61050015
         BCT   GRN,LBLSER                                               61100015
         BC    B,LBLS25                NOT AN ERROR IF NEW N =0         61150015
LBLSER   MVC   PAR6+1(3),ERR42         HIT BOTTOM TOO SOON, SO ERROR    61200015
         BC    B,CERROR                ERROR MESSAGE AND ABORT          61250015
LBLS34   TM    DESFLG(STR),X'08'       TEST NEW ITEM                    61300015
         BC    BO,LBLS24               BRANCH IF ALREADY RELEASED       61350015
         BCT   GRN,LBLS27              LOOP AGAIN, UNLESS FINISHED      61400015
LBLS25   TM    RELCOD,X'20'            TEST ENTRY POINT                 61450015
         BC    BO,RETURN               RETURN IF ITEM2 ENTRY            61500015
         C     STR,ASTK                COMPARE STACK POINTER TO LOW     61550015
         BC    BNL,LBLS28             LIMIT FOR RELEASE,BRANCH IF .GE.  61600015
         ST    STR,ASTK                UPDATE LOW LIMIT                 61650015
LBLS28   TM    RELCOD,X'80'            WHICH ENTRY WAS USED,            61700015
         BC    BO,LBLS29               BRANCH IF IT WAS RLSTK1.         61750015
         ST    STR,LSTK                RESET LOGICAL TOP OF STACK       61800015
LBLS29   NI    RELCOD,X'BF'            SET REL BIT ZERO                 61850015
         L     STR,PSTK                POINT AT PHYSICAL TOP OF DES STK 61900015
LBLS33   TM    DESFLG(STR),X'02'                                        61950015
         BC    BO,LBLS30               BRANCH IF ITEM TO BE HELD        62000015
         TM    DESFLG(STR),X'08'                                        62050015
         BC    BZ,LBLS30               BRANCH IF ACTIVE IN DESR STACK   62100015
         TM    DESFLG(STR),X'0C'       TEST AND BRANCH IF ITEM NOT      62150015
         BC    BO,LBLS31               ACTIVE IN EITHER STACK           62200015
         LH    G0,DESBSE(STR)                                           62250015
         AH    G0,DESNDX(STR)          ADD BASE,INDEX AND OFFSET.       62300015
         TM    DESFLG(STR),X'10'                                        62350015
         BC    BZ,LBLS42               BRANCH IF NO OFFSET              62400015
         AH    G0,DESOFS(STR)                                           62450015
LBLS42   C     G0,CSTK                 COMPARE WITH TOP OF CORE STACK   62500015
         BC    BL,LBLS30               BRANCH IF LOWER                  62550015
         OI    RELCOD,X'40'            SET RELEASE BIT =1               62600015
         LH    G0,DESBSE(STR)          REDUCE TOP OF CORE STACK         62650015
         ST    G0,CSTK                 BY THIS ITEM                     62700015
         OI    DESFLG(STR),X'04'       CORE STACK INACTIVE              62750015
LBLS31   C     STR,PSTK                                                 62800015
         BC    BL,LBLS30               BRANCH IF NOT TOP DES STACK ITEM 62850015
         L     G0,PSTK                 REDUCE TOP OF PHYSICAL STACK     62900015
         S     G0,ITEMSZ               BY 1 ITEM                        62950015
         ST    G0,PSTK                                                  63000015
         C     G0,ASTK                 COMPARE TOP WITH LOW LIMIT       63050015
         BC    BNH,RETURN              BRANCH TO END OF ROUTINE         63100015
LBLS30   S     STR,ITEMSZ              SUBTRACT 1 ITEM FROM STACK POINT 63150015
         C     STR,ASTK                COMPARE WITH LOW LIMIT           63200015
         BC    BH,LBLS33               BRANCH IF GREATER                63250015
         TM    RELCOD,X'40'                                             63300015
         BC    BO,LBLS29               BRANCH IF RELEASE IN THIS PASS   63350015
         BC    B,RETURN                BRANCH TO END OF ROUTINE         63400015
*                       RLSTK1 (N) ENTRY POINT                          63450015
RLSTK1   EQU   *                                                        63500015
         NI    RELCOD,X'0F'                                             63550015
         OI    RELCOD,X'80'            RELEASE CODE BIT 0 TO '1'        63600015
         LA    GRN,1(GRN)              BUMP N BY 1                      63650015
LBLS35   L     STR,LSTK                SET STACK POINTER TO LOGICAL TOP 63700015
         ST    RR,STKRR                SAVE RETURN REGISTER             63750015
         BC    B,LBLS24                NOW GET GOING.                   63800015
*              ITEM2 ENTRY SETS THE STACK POINTER,STR,TO THE 2ND ACTIVE 63850015
*              ITEM IN DESCRIPTION STACK.                               63900015
ITEM2    EQU   *                                                        63950015
         NI    RELCOD,X'0F'                                             64000015
         OI    RELCOD,X'20'            SET CODE FOR ENTRY               64050015
         LA    GRN,1                                                    64100015
         BC    B,LBLS35                                                 64150015
ITEMSZ   DC    A(ISTK)                 BYTES/ITEM IN DESCRIPTION STACK  64200015
PDSIZE   DC    H'8'                    MAX NO OF BYTES FOR PD VARIABLE  64250015
         EJECT                                                          64300015
*              GET REGISTER SUBROUTINES.                                64350015
         SPACE 1                                                        64400015
*              FUNCTION (1) TO OBTAIN A FLOATING OR GENERAL ARITHMETIC  64450015
*        REGISTER AND,OPTIONALLY, TO LOAD IT FROM THE DESCRIPTION       64500015
*        ADDRESSED BY REGISTER DSR.                                     64550015
*                       (2) TO OBTAIN ALIGNED WORKSPACE AND,OPTIONALLY, 64600015
*        TO STORE REGISTERS.                                            64650015
         SPACE 1                                                        64700015
*              ENTRY POINT (1) 'GETFR' TO OBTAIN A FLOATING REGISTER.IF 64750015
*        NONE ARE FREE, ONE IS STORED.                                  64800015
*                          (2) 'GETGR' TO OBTAIN A SINGLE GENERAL ARITH 64850015
*        REGISTER.                                                      64900015
*                          (3) 'GETGRE' TO OBTAIN AN EVEN-ODD PAIR OF   64950015
*        GENERAL REGISTERS AND LOAD THE EVEN REGISTER.                  65000015
*                          (4) 'GETGRO' TO OBTAIN AN EVEN-ODD PAIR OF   65050015
*        GENERAL REGISTERS AND LOAD THE ODD REGISTER.                   65100015
*                          (5) 'STGENR' TO STORE ALL GENERAL REGISTERS  65150015
*        CURRENTLY IN USE.                                              65200015
*                          (6) 'STREG2' TO STORE A FLOATING REGISTER,   65250015
*        WHOSE DESCRIPTION BLOCK IS ADDRESSED BY REGISTER DSR.          65300015
*                          (7) 'STREG4' TO OBTAIN 4 OR 8 BYTES OF       65350015
*        TEMPORARY WORKSPACE. THE RESULTING WORKSPACE SPECIFICATION IS  65400015
*        ADDED TO THE DESCRIPTION ADDRESSED BY REGISTER STR.            65450015
         SPACE 1                                                        65500015
*              EXTERNAL ROUTINE (1) 'GETADX' TO CONSTRUCT 2ND OPERAND   65550015
*        FOR PSEUDO-CODE.                                               65600015
         SPACE 1                                                        65650015
*              EXIT-NORMAL - TO INSTRUCTION AFTER INVOCATION.           65700015
         SPACE 1                                                        65750015
*              EXIT-ERROR (1) TO 'ERROR1' WITH BAD REGISTER NUMBERS.    65800015
*        ERROR MESSAGE NUMBER 1600.                                     65850015
*                         (2) TO 'CERROR' WITH ERRORS IN REGISTER       65900015
*        HOUSEKEEPING. ERROR MESSAGE NUMBER 1603.                       65950015
         SPACE 1                                                        66000015
*              NOTES (1) REGISTERS G0,G1 ARE CHANGED.                   66050015
*                        REGISTER STR IS CHANGED EXCEPT IN 'STREG4'.    66100015
*                        REGISTER DSR IS PRESERVED EXCEPT IN 'STGENR'.  66150015
*                        REGISTER BR IS PRESERVED.                      66200015
*                    (2) OPTIONS ARE CONTROLLED BY BYTE 'REGCOD' --     66250015
*        BIT 1 = 0 TO LOAD NEW REGISTER.                                66300015
*              = 1 TO NOT LOAD NEW REGISTER.                            66350015
*        BIT 3 = 0 NORMALLY.                                            66400015
*              = 1 IN CALLING SEQUENCE GENERATION.                      66450015
         EJECT                                                          66500015
*              GETFR ENTRY OBTAINS A FLOATING REGISTER. IF ALL FLOATING 66550015
*              REGISTERS ARE ALREADY IN USE, THE REGISTER LONGEST IN    66600015
*              USE IS STORED AND REUSED.                                66650015
*                                                                       66700015
GETFR    EQU   *                                                        66750015
         ST    RR,REGRR                SAVE RETURN REGISTER             66800015
         LA    G0,4                    INITIALISE LOOP                  66850015
         ST    DSR,REGDSR                                               66900015
         LA    DSR,FRBLK               ADDRESS OF FR0 DESCRIPTION BLOCK 66950015
         SR    G1,G1                                                    67000015
         CLI   NFR,X'04'                                                67050015
         BC    BL,LBLR1                BRANCH IF FLT REG FREE           67100015
LBLR7    IC    G1,RGD1(DSR)                                             67150015
         BCT   G1,LBLR2                USE CODE - 1 ,BRANCH IF NON-0    67200015
         ST    DSR,DESAD               SAVE POINTER TO REGISTER BLOCK   67250015
         MVI   NFR,3                   NUMBER OF FLOAT REGS = 3         67300015
LBLR2    STC   G1,RGD1(DSR)            STORE USE NO IN REG DESR BLOCK   67350015
         LA    DSR,RGBLSZ(DSR)         BUMP BLOCK ADDRESS               67400015
         BCT   G0,LBLR7                TEST LOOP COUNT                  67450015
         L     DSR,DESAD               BLOCK OF REGISTER TO BE SAVED    67500015
         BAL   RR,STREG2               BRANCH TO STORE REGISTER ROUTINE 67550015
*              LOAD NEW REGISTER FROM ARGUMENT                          67600015
LBLR11   MVC   LREG(2),REG             LOAD REGISTER = RESULT REGISTER  67650015
LBLR9    L     DSR,REGDSR              POINTER TO ARGUMENT DESCRIPTION  67700015
         TM    REGCOD,X'80'                                             67750015
         BC    BO,REGRTN               RETURN IF NO-LOAD WANTED         67800015
         TM    REGCOD,X'10'                                       16210 67804017
         BC    BZ,LBLR9A               BRANCH IF SDR NOT WANTED   16210 67808017
*        GENERATE     SDR   FR,FR                                 16210 67812017
*                     LE    FR,OPERAND                            16210 67816017
*        TO LOAD A SHORT OPERAND INTO A LONG REGISTER             16210 67820017
SDR      EQU   SUB+FLD+X'40'                                      16210 67824017
         MVI   PCOPN(PCR),SDR                                     16210 67828017
         MVC   PCOD1(2,PCR),LREG                                  16210 67832017
         MVC   PCOD2(2,PCR),LREG                                  16210 67836017
         LA    PCR,PCSZ5(PCR)                                     16210 67840017
LBLR9A   EQU   *                                                  16210 67844017
         MVI   PCOPN(PCR),L            SET LOAD OP CODE                 67850015
         OC    PCOPN(1,PCR),OPTYP      SET OP TYPE                      67900015
         MVC   PCOD1(2,PCR),LREG       SET REGISTER IN 1ST OPERAND      67950015
         BAL   RR,GETADX               SET ADDRESS OF 2ND OPERAND       68000015
REGRTN   MVI   REGCOD,0                CLEAR CODE BYTE                  68050015
         L     RR,REGRR                                                 68100015
         BCR   B,RR                    RETURN                           68150015
*              GET FIRST FREE FLOATING REGISTER                         68200015
LBLR1    TM    RGD1(DSR),X'FF'         TEST 1ST BYTE OF REG DESCRIPTION 68250015
         BC    BZ,LBLR10               BRANCH IF REGISTER NOT IN USE    68300015
         LA    DSR,RGBLSZ(DSR)         BUMP BLOCK ADDRESS               68350015
         BCT   G0,LBLR1                                                 68400015
         MVC   PAR6+1(3),ERR43         NO REG BLOCKS FREE AFTER ALL     68450015
         BC    B,CERROR                ERROR MESSAGE AND ABORT          68500015
LBLR10   LA    G1,4                                                     68550015
         SR    G1,G0                                                    68600015
         AR    G1,G1                   CALCULATE FLOAT REGISTER NUMBER  68650015
         BC    B,LBLR17                                                 68700015
*                                                                       68750015
*              GETGR ENTRY OBTAINS A GENERAL REGISTER.IF BOTH AVAILABLE 68800015
*              ARITHMETIC REGISTERS ARE FREE, THE EVEN REGISTER IS      68850015
*              PICKED. IF BOTH ARE ALREADY IN USE, THE EVEN ONE IS      68900015
*              STORED AND REUSED.                                       68950015
*                                                                       69000015
GETGR    EQU   *                                                        69050015
         ST    RR,REGRR                SAVE RETURN REGISTER             69100015
         TM    REGCOD,X'80'                                             69150015
         BC    BO,LBLR12               BRANCH IF NO-LOAD                69200015
         TM    DESFLG(DSR),X'80'       TEST FLAG BITS 01                69250015
         BC    BZ,LBLR12               BRANCH IF NOT '1-'               69300015
         TM    DESFLG(DSR),X'40'                                        69350015
         BC    BO,LBLR12               BRANCH IF NOT '-0'               69400015
         LH    G1,DESBSE(DSR)                                           69450015
         STH   G1,REG                  SAVE REGISTER NUMBER             69500015
         C     G1,GRNUM                TEST REGISTER NUMBER             69550015
         LA    G1,GRBLK                SET FOR EVEN REGISTER BLOCK      69600015
         BC    BZ,LBLR13               BRANCH IF EVEN                   69650015
         LA    G1,RGBLSZ(G1)           BUMP TO ODD REGISTER BLOCK       69700015
LBLR13   ST    G1,DESAD                ADDRESS OF REGISTER BLOCK        69750015
         OI    RGD1(G1),X'80'          INDICATE REGISTER TO BE REUSED   69800015
         BC    B,REGRTN                                                 69850015
*              GET A SINGLE ARITHMETIC REGISTER                         69900015
LBLR12   ST    DSR,REGDSR                                               69950015
         LA    DSR,GRBLK               ADDRESS OF EVEN REGISTER BLOCK   70000015
         CLI   NGR,X'02'                                                70050015
         BC    BNL,LBLR14              BRANCH IF NO FREE REGISTERS      70100015
         TM    RGD1(DSR),X'FF'                                          70150015
         BC    BZ,LBLR15               BRANCH IF EVEN REGISTER FREE     70200015
         L     G1,GRNUM+RGBLSZ         ODD REGISTER NUMBER              70250015
         LA    DSR,RGBLSZ(DSR)         BUMP POINTER TO ODD REGISTER     70300015
         BC    B,LBLR17                                                 70350015
LBLR14   BAL   RR,STREG1               STORE EVEN REGISTER              70400015
         MVI   NGR,1                   NUMBER OF GENERAL REGS = 1       70450015
         MVI   GRBLK,0                 CLEAR REGISTER BLOCK             70500015
LBLR15   L     G1,GRNUM                EVEN REGISTER TO BE USED         70550015
LBLR17   STH   G1,REG                  STORE REGISTER NUMBER            70600015
         ST    DSR,DESAD               STORE ADDRESS OF REGISTER BLOCK  70650015
         BC    B,LBLR11                                                 70700015
*                                                                       70750015
*              GETGRE ENTRY OBTAINS AN EVEN-ODD PAIR OF GENERAL         70800015
*              REGISTERS AND LOADS THE EVEN REGISTER.                   70850015
*                                                                       70900015
GETGRE   EQU   *                                                        70950015
         LA    G1,0                    SET ADDRESS POINTER FOR EVEN     71000015
         BC    B,LBLR20                                                 71050015
*                                                                       71100015
*              GETGRO ENTRY OBTAINS AN EVEN-ODD PAIR OF GENERAL         71150015
*              REGISTERS AND LOADS THE ODD REGISTER.                    71200015
*                                                                       71250015
GETGRO   EQU   *                                                        71300015
         LA    G1,4                    SET ADDRESS POINTER FOR ODD      71350015
LBLR20   ST    RR,REGRR                                                 71400015
         ST    DSR,REGDSR                                               71450015
         L     G0,GRNUM(G1)                                             71500015
         STH   G0,LREG                 REGISTER NUMBER FOR LOAD         71550015
         L     G0,GRNUM                                                 71600015
         STH   G0,REG                  EVEN RESULT REGISTER             71650015
         LA    G0,GRBLK                                                 71700015
         ST    G0,DESAD                SET ADDRESS OF REGISTER BLOCK    71750015
         TM    DESFLG(DSR),X'80'       TEST FLAG BITS 01 OF ARGUMENT    71800015
         BC    BZ,LBLR21               BRANCH IF NOT '1-'               71850015
         TM    DESFLG(DSR),X'40'                                        71900015
         BC    BO,LBLR21               BRANCH IF NOT '-0'               71950015
         LH    G0,DESBSE(DSR)          FLAG IS '10' - REGISTER BY VALUE 72000015
         OI    REGCOD,X'80'            SET CODE TO NO LOAD              72050015
         C     G0,GRNUM(G1)            COMPARE WITH REGISTER NUMBER OF  72100015
         BC    BZ,LBLR24               SAME PARITY, BRANCH IF SAME      72150015
         NI    REGCOD,X'7F'            SET CODE TO LOAD                 72200015
LBLR22   X     G1,FOUR                 CHANGE PARITY                    72250015
         C     G0,GRNUM(G1)            COMPARE WITH OTHER REGISTER NO   72300015
         BC    BNE,ERROR1              CREATE ERROR MESSAGE AND ABORT   72350015
LBLR24   X     G1,FOUR                 CHANGE PARITY TO NON-ARG REG     72400015
         LA    DSR,GRBLK(G1)           SET ADDRESS                      72450015
         TM    RGD1(DSR),X'FF'         TEST ORIGINAL REGISTER           72500015
         BC    BZ,LBLR9                BRANCH IF NOT ORIGINALLY'IN USE' 72550015
         MVI   NGR,1                   NO OF GENERAL REGISTERS = 1      72600015
         MVI   RGD1(DSR),0             CLEAR REGISTER BLOCK             72650015
         BAL   RR,STREG1               BRANCH TO STORE REGISTER ROUTINE 72700015
         BC    B,LBLR9                                                  72750015
*              ARGUMENT NOT ALREADY IN REGISTER                         72800015
*                                                                       72850015
*              STGENR ENTRY STORES THE GENERAL ARITHMETIC REGISTERS     72900015
*              CURRENTLY IN USE. WHEN USED BEFORE A CALLING SEQUENCE,   72950015
*              REGISTERS ARE NOT RELOADED.                              73000015
STGENR   ST    RR,REGRR                SAVE RETURN REGISTER             73050015
LBLR21   CLI   NGR,X'02'               ARE BOTH REGISTERS IN USE,       73100015
         BC    BNE,LBLR23              BRANCH IF ONE OR BOTH FREE       73150015
         LA    DSR,GRBLK                                                73200015
         LA    G1,8                    LENGTH OF TEMP CORE NEEDED       73250015
         BAL   RR,STREG3               BRANCH TO STORE REGISTER ROUTINE 73300015
*              SET PC INSTRUCTION FOR STM AND CHANGE DESCRIPTION STACK  73350015
*              ITEM FOR 2ND REGISTER                                    73400015
         SR    PCR,G1                  REMOVE LAST PC INCREMENT         73450015
         MVI   PCOPN(PCR),STM          SET OPCODE TO STM                73500015
         MVI   PCOSM(PCR),OSM3         SET OFFSET OP CODE               73550015
         L     STR,GRBLK+RGBLSZ+RGD1   DESR STACK ITEM FOR 2ND REG      73600015
         MVC   PCOSM2(2,PCR),DESBSE(STR)  SET 2ND REGISTER IN PC        73650015
         LA    PCR,PCSZ5+PCSZ5(PCR)    BUMP PC POINTER                  73700015
         BAL   RR,CPROD1               TEST WHETHER OPERAND IN THIS REG 73750015
LBLR28   OI    DESFLG(STR),X'C0'       CHANGE ITEM FLAG TO TEMP OFFSET  73800015
         L     G1,CSTK                                                  73850015
         S     G1,FOUR                 TEMP CORE OFFSET IS TOP OF STACK 73900015
         STH   G1,DESBSE(STR)          -4.                              73950015
         XC    DESNDX(4,STR),DESNDX(STR)  ZERO NDX AND OFS BYTES AND    74000015
         MVI   DESNDX+1(STR),X'04'     SET LENGTH TO 4                  74050015
         BAL   RR,CPROD2               IFNEEDED,CHANGE OPERAND DESCPT   74100015
         BC    B,LBLR27                                                 74150015
*              1 OR 2 FREE ARITHMETIC REGISTERS                         74200015
LBLR23   LA    DSR,GRBLK                                                74250015
         TM    RGD1(DSR),X'FF'         TEST EVEN GENERAL REGISTER       74300015
         BC    BNE,LBLR26              BRANCH IF IN USE                 74350015
         LA    DSR,RGBLSZ(DSR)         BUMP DSR TO NEXT BLOCK           74400015
         TM    RGD1(DSR),X'FF'         TEST ODD GENERAL REGISTER        74450015
         BC    BZ,LBLR31               BRANCH IF NOT IN USE             74500015
LBLR26   BAL   RR,STREG1               STORE REGISTER                   74550015
LBLR27   MVI   NGR,0                   NO OF GENERAL REGS = 0           74600015
         MVI   GRBLK,0                 CLEAR EVEN REGISTER BLOCK        74650015
         MVI   GRBLK+RGBLSZ,0          CLEAR ODD REGISTER BLOCK         74700015
LBLR31   TM    REGCOD,X'20'                                             74750015
         BC    BO,REGRTN               RETURN IF CALLING SEQUENCE       74800015
         BC    B,LBLR9                 BRANCH TO LOAD                   74850015
GRNUM    DC    A(GRE)                  EVEN ARITHMETIC REGISTER         74900015
         DC    A(GRO)                  ODD  ARITHMETIC REGISTER         74950015
         SPACE 3                                                        75000015
*              GENERATE PC TO STORE REGISTERS IN TEMP CORE.             75050015
*                                                                       75100015
*        STREG1 ENTRY STORES A SINGLE GENERAL REGISTER.                 75150015
*        STREG2 ENTRY STORES A FLOATING REGISTER.                       75200015
*        STREG3 ENTRY STORES AN EVEN-ODD PAIR OF GENERAL REGISTERS.     75250015
STREG1   MVI   PCOPN(PCR),ST           SET PC OPN TO STORE              75300015
STREG2   LA    G1,4                    LENGTH OF TEMP STORAGE NEEDED    75350015
STREG3   L     STR,RGD1(DSR)           ADDRESS OF ITEM IN DESR STACK    75400015
         ST    RR,STRGRR                                                75450015
         ST    DSR,STGDSR              SAVE DSR                         75500015
         MVC   PCOD1(2,PCR),DESBSE(STR) SET PC OPERAND 1 TO REGISTER    75550015
         NI    REGCOD,X'BF'            SET BIT 1 TO ZERO FOR STORE      75600015
         BAL   RR,CPROD1               TEST WHETHER OPERAND IN THIS REG 75650015
LBLR29   MVI   DESFLG(STR),X'C0'       CHANGE FLAG TO TEMP OFFSET       75700015
         STH   G1,DESNDX(STR)                                           75750015
         L     G1,CSTK                 TOP OF CORE STACK                75800015
         STH   G1,DESBSE(STR)          STORE IN DESR BASE               75850015
         LCR   G1,G1                                                    75900015
         TM    DESCDE(STR),X'02'                                        75950015
         BC    BN1,LBLR16              BRANCH IF FIXED                  76000015
         MVC   REG(2),PCOD1(PCR)       SAVE FLOAT REGISTER NO           76050015
         TM    DESCDE(STR),X'9A'       TEST TYPE OF PREVIOUS USE        76100015
         BC    BO,LBLR3                BRANCH IF LONG FLOAT             76150015
         MVI   PCOPN(PCR),STE          SET PC OPN TO SHORT FLOAT STORE  76200015
         BC    B,LBLR34                                                 76250015
LBLR16   CLI   DESCDE(STR),X'CC'       TEST FOR POINTER                 76270015
         BC    BE,LBLR34               LEAVE SHORT IF SO                76290015
         CLI   DESP(STR),21            TEST PRECISION OF FIXED ITEM     76310015
         BC    BNH,LBLR34              BRANCH IF SHORT                  76350015
         OI    DESCDE(STR),X'10'       RESET TO LONG                    76400015
LBLR34   N     G1,THREE                BYTE OFFSET FROM WORD BOUNDARY   76450015
         BC    B,LBLR4                                                  76500015
LBLR3    MVI   PCOPN(PCR),STD          SET PC OPN TO LONG FLOAT STORE   76550015
         MVI   DESNDX+1(STR),X'08'     SET ITEM LENGTH TO 8             76600015
         N     G1,SEVEN                BYTE OFS FROM D-WORD BOUNDARY    76650015
LBLR4    BC    BZ,LBLR5                BRANCH IF OFFSET IS ZERO,        76700015
         STH   G1,DESOFS(STR)          OTHERWISE SET OFFSET             76750015
         OI    DESFLG(STR),X'10'       AND ITS FLAG BIT.                76800015
LBLR5    TM    REGCOD,X'40'                                             76850015
         BCR   BO,RR                   BRANCH IF NO LOAD NEEDED         76900015
         A     G1,CSTK                 ADD TOP OF CORE STACK            76950015
         AH    G1,DESNDX(STR)          AND ITEM LENGTH TO OFFSET TO GET 77000015
         ST    G1,CSTK                 NEW TOP OF STACK                 77050015
         CH    G1,SCWKSC(PAR)          COMPARE TO MAXIMUM STACK SIZE    77100015
         BC    BNH,LBLR6                                                77150015
         STH   G1,SCWKSC(PAR)          UPDATE IF NECESSARY              77200015
LBLR6    TM    DESCDE(STR),X'02'                                        77250015
         BC    BO,LBLR6A               BRANCH IF FLOAT                  77300015
         MVI   DESNDX+1(STR),X'04'   IF STM CHANGE LENGTH TO 4          77350015
LBLR6A   BAL   RR,CPROD2               IF NEEDED,CHANGE OPND DESCPT     77400015
LBLR30   LR    DSR,STR                                                  77450015
         BAL   RR,GETADX               SET 2ND OPERAND IN PC            77500015
         L     RR,STRGRR                                                77550015
         L     DSR,STGDSR              RESTORE DSR                      77600015
         BCR   B,RR                                                     77650015
*                                                                       77700015
*              STREG4 ENTRY GET 4 OR 8 BYTES OF ALIGNED TEMP CORE       77750015
*                                                                       77800015
STREG4   OI    REGCOD,X'40'            SET BIT 1 = 1 FOR NO-STORE       77850015
         LA    G1,4                                                     77900015
         BC    B,LBLR29                                                 77950015
         EJECT                                                          78000015
* TRT TABLE ENTRIES                                                     78050015
*      OPERATOR     IF FOR SCAN ONLY    FOR SCAN AND USER               78100015
*       FORMAT               4                40                        78150015
*       FORMAT'              8                44                        78200015
*       PROC                12                48                        78250015
*       BEGIN               16                52                        78300015
*       PROC'               20                56                        78350015
*       BEGIN'              24                60                        78400015
*       JMP                 28                64                        78450015
*       SN,SL,CN,CL,SN2     32                68                        78500015
*       ERROR               36                72                        78550015
*                                                                       78600015
*              LAYOUT OF SCAN PARAMETER BLOCK                           78650015
SCTRT    EQU   0                       INDICATES TRIPLES OF INTEREST    78700015
*              BEGINNING OF FULL-WORD ITEMS                             78750015
SCEOBI   EQU   SCTRT+256               ABSOLUTE ADRESS OF END OF IP BLK 78800015
SCEOBO   EQU   SCEOBI+4                ABSOLUTE ADRESS OF END OF OP BLK 78850015
SCJMP    EQU   SCEOBO+4                SYMBOLIC POSITION OF JMP TRIPLE  78900015
SCPCG    EQU   SCJMP+4                 COUNT OF PSEUDOCODE GENERATED    78950015
SCTXTI   EQU   SCPCG+4                 SYMB NAME OF IP BLOCK IN BYTE 2  79000015
SCTXTO   EQU   SCTXTI+4                SYMB NAME OF OP BLOCK IN BYTE 2  79050015
SCWKSC   EQU   SCTXTO+4                CURRENT WORKSPACE COUNT          79100015
SCWKS    EQU   SCWKSC                                                   79150015
*              END OF FULL-WORD ITEMS                                   79200015
SCBLK    EQU   SCWKSC+4                DICT REFERENCE OF CURRENT BLOCK  79250015
SCSTK    EQU   SCBLK+2                 CURRENT REGISTER USAGE           79300015
SCWSDR   EQU   SCSTK+2                 DICT REF OF CURRENT WORKSPACE    79350015
*              END OF 2-BYTE ITEMS                                      79400015
SCOPT    EQU   SCWSDR+2                PRE-FIX OPTION BYTE              79450015
*              END OF 1-BYTE ITEMS                                      79500015
         EJECT                                                          79550015
*              WORKSPACE.                                               79600015
BGWS     EQU   4096+BEGIN                                               79650015
         SPACE 2                                                        79700015
*              TRT TABLE TO SCAN TRIPLES,SCAN PARAMETER BLOCK.          79750015
SCPARM   EQU   BGWS                                                     79800015
ASSIGN   EQU   296+SCPARM              TRANSFER VECTORS TO BLOCK LR     79850015
SETMPD   EQU   4+ASSIGN                                                 79900015
DECNST   EQU   4+SETMPD                                                 79950015
SWOP     EQU   4+DECNST                                                 80000015
STALRG   EQU   4+SWOP                                                   80050015
GNSHFT   EQU   4+STALRG                                                 80100015
CPROD1   EQU   4+GNSHFT                                                 80150015
CPROD2   EQU   4+CPROD1                                                 80200015
ERROR1   EQU   4+CPROD2                                                 80250015
CERROR   EQU   4+ERROR1                                                 80300015
ERROR    EQU   4+CERROR                                                 80350015
         SPACE                                                          80400015
*              FULL-WORD CONSTANTS                                      80450015
ONE      EQU   4+ERROR       (DC  F'1')                                 80500015
TWO      EQU   4+ONE         (DC  F'2')                                 80550015
H2       EQU   2+TWO         (DC  H'2')                                 80600015
THREE    EQU   4+TWO         (DC  F'3')                                 80650015
FOUR     EQU   4+THREE       (DC  F'4')                                 80700015
SEVEN    EQU   4+FOUR        (DC  F'7')                                 80750015
H7       EQU   2+SEVEN       (DC  H'7')                                 80800015
F12      EQU   4+SEVEN       (DC  F'12')                                80850015
F63      EQU   4+F12         (DC  F'63')                                80900015
DBMULT   EQU   4+F63         (DC  X'00351EB8')   3.32 SCALED (31,20)    80950015
CEIL1    EQU   4+DBMULT      (DC  X'000FFFFF')   ROUND UP               81000015
         SPACE 1                                                        81050015
*              HALF-WORD CONSTANTS.                                     81100015
H32      EQU   4+CEIL1       (DC  H'32')                                81150015
FLMAXP   EQU   2+H32         (DC  H'53')    MAY FLOAT BINARY PRECISION  81200015
SF0      EQU   2+FLMAXP      (DC  H'128')   ZERO SCALE FACTOR           81250015
FXMAXP   EQU   2+SF0         (DC  H'31')    MAX FIXED BINARY PRECISION  81300015
MAXSF    EQU   2+FXMAXP      (DC  H'255')   MAX SCALE FACTOR            81350015
         SPACE 1                                                        81400015
*              DICTIONARY ENTRY LIST FOR LIBRARY SUBROUTINE NAMES.      81450015
*              EXPONENTIALS.                                            81500015
EXPSUB   EQU   4+MAXSF       (DC  A(X'C2B6'))    IHEXXL                 81550015
*                            (DC  A(X'C2B0'))    IHEXIL                 81600015
*                            (DC  A(X'C2B7'))    IHEXXS                 81650015
*                            (DC  A(X'C2B1'))    IHEXIS                 81700015
EXPPKD   EQU   16+EXPSUB     (DC  A(X'C2AF'))    IHEXID                 81750015
PKDEXP   EQU   EXPPKD-EXPSUB                                            81800015
EXPFXB   EQU   4+EXPPKD      (DC  A(X'C2AE'))    IHEXIB                 81850015
FXBEXP   EQU   EXPFXB-EXPSUB                                            81900015
EXPCPX   EQU   4+EXPFXB      (DC  A(X'C2B9'))    IHEXXZ                 81950015
CPXEXP   EQU   EXPCPX-EXPSUB                                            82000015
*                            (DC  A(X'C2B5'))    IHEXIZ                 82050015
*                            (DC  A(X'C2B8'))    IHEXXW                 82100015
*                            (DC  A(X'C2B4'))    IHEXIW                 82150015
*                            (DC  A(X'C2B3'))    IHEXIV                 82200015
*                            (DC  A(X'C2B2'))    IHEXIV                 82250015
*              COMPLEX MULT1PLY,DIVIDE.                                 82300015
CPXSUB   EQU   24+EXPCPX     (DC  A(X'C271'))    IHEMZZ0                82350015
*                            (DC  A(X'C24A'))    IHEDZZ0                82400015
*                            (DC  A(X'C270'))    IHEMZW0                82450015
*                            (DC  A(X'C249'))    IHEDZW0                82500015
*                            (DC  A(X'C26F'))    IHEMZVM                82550015
*                            (DC  A(X'C26E'))    IHEMZVD                82600015
CPXFXB   EQU   24+CPXSUB     (DC  A(X'C26D'))    IHEMZUM                82650015
FXBCPX   EQU   CPXFXB-CPXSUB                                            82700015
*                            (DC  A(X'C26C'))    IHEMZUD                82750015
CPXAMD   EQU   8+CPXFXB      (DC  A(X'C2C4'))    IHEMPV0                82800015
AMDSUB   EQU   CPXAMD-CPXSUB-PKDEXP                                     82850015
*                            (DC  A(X'C2C2'))    IHEDVV0                82900015
*                            (DC  A(X'C2C3'))    IHEMPU0                82950015
*                            (DC  A(X'C2C1'))    IHEDVU0                83000015
ADDFN    EQU   16+CPXAMD     (DC  A(X'C2BF'))    IHEADD0                83050015
FNADD    EQU   ADDFN-CPXAMD                                             83100015
*                            (DC  A(X'C2C0'))    IHEADV0                83150015
         SPACE 1                                                        83200015
*              DESCRIPTIONS.                                            83250015
PSIDES   EQU   8+ADDFN       (DC  X'00C000000000000OFF00') PSI VAR      83300015
BITDES   EQU   10+PSIDES     (DC  X'C0280001000000010000') COMPARE RSLT 83350015
CHARST   EQU   10+BITDES     (DC  X'880580')  CHAR STRING TO ARITH      83400015
BITST    EQU   3+CHARST      (DC  X'8C0F80')  BIT STRING TO ARITH       83450015
FIXBIN   EQU   3+BITST       (DC  X'9C1F80')  FIXED BINARY(31,0)        83500015
PTRDES   EQU   3+FIXBIN                POINTER DED                      83550015
         SPACE 1                                                        83600015
*              BLOCK NAMES.                                             83650015
NAMBK1   EQU   3+PTRDES      (DC  C'LSLTLU')                            83700015
NAMBK4   EQU   6+NAMBK1      (DC  C'ZZ'    )                            83750015
NAMBK5   EQU   2+NAMBK4      (DC  C'LWLXZZ')                            83800015
NAMBK6   EQU   8+NAMBK5           ( DC  MPZZ)                           83850015
NAMBK7   EQU   4+NAMBK6      (DC  C'LV')                                83900015
         SPACE 1                                                        83950015
*              PSEUDO-CODE SKELETONS.                                   84000015
DROPPC   EQU   2+NAMBK7                          DROP SR1,DROP SR2      84050015
PCIN1    EQU   6+DROPPC                          SR   GRO,GRO           84100015
LPCI1    EQU   5                                                        84150015
PCIN2    EQU   LPCI1+PCIN1                       SRDA GRE,X             84200015
LPCI2    EQU   3                                                        84250015
PCIN3    EQU   LPCI2+PCIN2                       SLDA GRE,X             84300015
LPCI3    EQU   3                                                        84350015
PCIN4    EQU   LPCI3+PCIN3                                              84400015
PCN1     EQU   PCIN4                             BC   BNE,LBL           84450015
LPCN1    EQU   5                                                        84500015
*                                                NR   GRO,GRO           84550015
*                                                BC   BZ,LBL            84600015
*                                                LTR  GRE,GRE           84650015
PCN2     EQU   15+PCIN4                LBL   EQU  *                     84700015
LPCN2    EQU   3                                                        84750015
LPCI4    EQU   18                                                       84800015
PCIN5    EQU   LPCI4+PCIN4                       MVI  **,X'00'          84850015
*                                                BC   MASK,LBL          84900015
*                                                MVI  **,X'80'          84950015
*                                           LBL  EQU  *                 85000015
LPCI5    EQU   24                                                       85050015
PCIN7    EQU   LPCI5+PCIN5                       XI   **,X'01'          85100015
LPCI7    EQU   3                                                        85150015
PCIN10   EQU   LPCI7+PCIN7                       IPRM                   85200015
*                                                LA   RA,**             85250015
LPCI13   EQU   6                                                        85300015
PCIN14   EQU   8+PCIN10                          LA   RB,**             85350015
LPCI11   EQU   11                                                       85400015
LPCI14   EQU   3                                                        85450015
PCIN15   EQU   5+PCIN14                          LA   RC,**             85500015
LPCI15   EQU   3                                                        85550015
LPCI10   EQU   16                                                       85600015
PCIN12   EQU   LPCI10+PCIN10                     L    BR,**             85650015
*                                                BALR RR,BR             85700015
*                                                IPRM'                  85750015
LPCI12   EQU   13                                                       85800015
PCIN16   EQU   LPCI12+PCIN12                     LA   RD,**             85850015
LPCI16   EQU   3                                                        85900015
PCIN17   EQU   LPCI16+PCIN16                     LA   RE,**             85950015
LPCI17   EQU   3                                                        86000015
PCIN18   EQU   LPCI17+PCIN17                     LA   RF,**             86050015
LPCI18   EQU   3                                                        86100015
PCIN19   EQU   LPCI18+PCIN18                     STM  RA,RF,**          86150015
*                                                LA   RA,**             86200015
LPCI19   EQU   13                                                       86250015
         SPACE 1                                                        86300015
*              DICTIONARY ENTRY SKELETONS.                              86350015
         SPACE                                                          86400015
DEDED2   EQU   LPCI19+PCIN19 (DC  X'C1000B0000000000000000')  DED2      86450015
DEBIFN   EQU   11+DEDED2     (DC  X'C2000E0000000000000000000101') BIF  86500015
DECON    EQU   14+DEBIFN     (DC  X'88000E0000000000010000000000') CONS 86550015
DEFL1    EQU   14+DECON      (DC  X'88001200008A0600C08A06000000'       86600015
*                             DC  X'41100000')    FLOAT '1.0'           86650015
DEPDZ    EQU   18+DEFL1      (DC  X'88000F000088018000880180000000') Z  86700015
         SPACE 1                                                        86750015
*              ERROR CODES.                                             86800015
ERR40    EQU   15+DEPDZ      (DC  X'064040')     ILLEGAL REG NUMBER     86850015
ERR41    EQU   3+ERR40       (DC  X'064140)      MORE THAN 200 TEMPS    86900015
ERR42    EQU   3+ERR41       (DC  X'064240')     NOT ENOUGH TEMPS       86950015
ERR43    EQU   3+ERR42       (DC  X'064300')     BAD COUNT OF FLOAT REG 87000015
ERR44    EQU   3+ERR43       (DC  X'064440')     REG 2ND OPN FOR RS,SS  87050015
ERR45    EQU   3+ERR44       (DC  X'064544')     SF OVER/UNDERFLOW      87100015
ERR46    EQU   3+ERR45       (DC  X'064640')     SINGLE TMPD ONLY       87150015
ERR47    EQU   3+ERR46       (DC  X'064754')     'LEFT' TYPE IN EXPRESS 87200015
ERR48    EQU   3+ERR47       (DC  X'064848')     ILLEGAL COMPLEX COMPAR 87250015
ERR49    EQU   3+ERR48       (DC  X'064940')     ILLEGAL DICT REF       87300015
ERR4D    EQU   3+ERR49       (DC  X'064D54')     ILLEGAL ARRAY OR STRUC 87350015
ERRSR    EQU   3+ERR4D       (DC  X'062100')     SYMBOLIC REG OVERFLOW  87400015
NDCON    EQU   3+ERRSR                                                  87450015
         EJECT                                                          87500015
MODU8    EQU   NDCON+7-BGWS                                             87550015
DBLE     EQU   MODU8/8*8                                                87600015
BGVAR    EQU   BGWS+DBLE               BEGINNING OF VARIABLE WORKSPACE  87650015
*              VARIABLES (BLOCK 1 )                                     87700015
EXPBUF   EQU   BGVAR        (DS  D )   D-WORD BUFFER FOR EXPONENTIALS   87750015
DCDSRR   EQU   BGVAR          (DS F )  RETURN REGISTER FOR DICDES       87800015
DEAVRR   EQU   4+DCDSRR     (DS  F )   RETURN REGISTER FOR DEAUVR       87850015
ASGNRR   EQU   DEAVRR       (DS  F )   RETURN REGISTER FOR ASSIGN       87900015
STBR     EQU   4+DEAVRR     (DS  F )   BRANCH REGISTER                  87950015
ALRGRR   EQU   4+STBR       (DS  F )   RETURN REGISTER FOR STALRG       88000015
REGSUB   EQU   4+ALRGRR     (DS  F )   REGISTER SUBROUTINE ADDRESS      88050015
SHFT1    EQU   4+REGSUB     (DS  F )   1ST SHIFT DESCRIPTION            88100015
SHFT2    EQU   4+SHFT1      (DS  F )   2ND SHIFT DESCRIPTION            88150015
CPXRET   EQU   4+SHFT2      (DS  F )   COMPLEX RETURN REGISTER          88200015
DES1     EQU   4+CPXRET      (DS 7H)   1ST OPERAND DESCRIPTION          88250015
DES2     EQU   TOTDES+DES1   (DS 7H)   2ND OPERAND DESCRIPTION          88300015
DEST     EQU   TOTDES+DES2   (DS 7H)   RESULT DESCRIPTION               88350015
NTMP     EQU   TOTDES+DEST   (DS H )   NO OF TEMPS USED                 88400015
OPND     EQU   2+NTMP       (DS  H )   NO OF OPERANDS IN USE            88450015
CPX      EQU   2+OPND       (DS  H )   COMPLEX CODE                     88500015
*                                      CPX = 0 FOR REAL   ,REAL   OPNDS 88550015
*                                          = 1     COMPLEX,REAL         88600015
*                                          = 2     REAL   ,COMPLEX      88650015
*                                          = 3     COMPLEX,COMPLEX      88700015
BIGN     EQU   2+CPX        (DS  H )   BIG N FOR FIXED ARITH            88750015
OPCOD    EQU   2+BIGN       (DS  C )   OPERATION CODE AFTER TRANSLATE   88800015
OPTYP    EQU   1+OPCOD      (DS  C )   OPERATION TYPE                   88850015
CPMASK   EQU   1+OPTYP      (DS  C )   COMPARE MASK TO BRANCH ON FALSE  88900015
ARCOD    EQU   1+CPMASK     (DS  C )   ARITHMETIC CODE BYTE             88950015
*                                       BIT 0 = 1 FOR NO SCALING SHIFT  89000015
*                                           1 = 1     SWOP WITH PD- OPN 89050015
*                                           2 = 1     NO LOAD IN SWOP   89100015
*                                       BIT 3 = 1     SWOP REQUIRED     89150015
*                                       BIT 4 = 1     CLEAR ODD REG     89200015
*                                       BIT 5 = 1     L-S CPX FLT FUNCT 89250015
         SPACE 2                                                        89300015
*             'GET ADDRESS' SUBROUTINE WORKSPACE                        89350015
GETRR    EQU   3+ARCOD      (DS  F )   RETURN REGISTER                  89400015
LDATA    EQU   4+GETRR      (DS  F )   NUMBER OF DROPS,DROP REG BUFFER  89450015
GETBUF   EQU   4+LDATA      (DS  H )   WORK SPACE                       89500015
SSFLG    EQU   2+GETBUF     (DS  C )   INTERMEDIATE FLAG FOR SS P-C     89550015
GETCOD   EQU   1+SSFLG      (DS  C )   CODE BYTE, SET AS FOLLOWS        89600015
*                                      BIT 0 = 1 FOR GETADX ENTRY       89650015
*                                            = 0     GETADS ENTRY       89700015
*                                      BIT 1 = 1     GETAS1 ENTRY       89750015
*                                      BIT 2 = 1     CONSTRUCT LA       89800015
         SPACE 2                                                        89850015
*              STACKING SUBROUTINE WORKSPACE                            89900015
STKVR1   EQU   1+GETCOD                BEGINNING OF VARIABLES FOR STACK 89950015
STKRR    EQU   STKVR1       (DS  F )   RETURN REGISTER                  90000015
STKG1    EQU   4+STKRR      (DS  F )   ARGUMENT REGISTER                90050015
ASTK     EQU   4+STKG1      (DS  F )   LOW LIMIT OF SEARCH DOWN DES STK 90100015
BSTK     EQU   4+ASTK       (DS  F )   BEGINNING OF DESCRIPTION STACK   90150015
MSTK     EQU   4+BSTK       (DS  F )   UPPER LIMIT OF DESCRIPTION STACK 90200015
LSTK     EQU   4+MSTK       (DS  F )   LOGICAL TOP DESCRIPTION          90250015
PSTK     EQU   4+LSTK       (DS  F )   PHYSICAL TOP DESCRIPTION         90300015
CSTK     EQU   4+PSTK       (DS  F )   CURRENT TOP OF CORE STACK        90350015
STKBUF   EQU   4+CSTK       (DS  F )   WORK SPACE                       90400015
RELCOD   EQU   4+STKBUF     (DS  C )   CODE BYTE, SET AS FOLLOWS        90450015
*                                      BIT 0 =1 - USING RLSTK1 ENTRY    90500015
*                                            =0 - USING RELSTK ENTRY    90550015
*                                      BIT 1 =1 - ITEM BEEN RELEASED    90600015
*                                            =0 - NO ITEM RELEASED      90650015
*                                      BIT 2 =1 - USING ITEM2 ENTRY     90700015
*                                            =0 - NOT ITEM2 ENTRY       90750015
*                                      BIT 4 =1 - NO REG DROP NEEDED    90800015
GETLW    EQU   1+RELCOD     (DS  C )   FLAG FOR LOADING PHASE LW        90850015
         SPACE 2                                                        90900015
*             'GET REGISTER' SUBROUTINE WORK SPACE                      90950015
GRBLK    EQU   4+RELCOD     (DS  2F)   GENERAL REGISTER BLOCKS          91000015
FRBLK    EQU   2*4+GRBLK    (DS  4F)   FLOATING REGISTER BLOCKS         91050015
STRGRR   EQU   4*4+FRBLK    (DS  F )   RETURN REGISTER FOR STREG SUB    91100015
STGDSR   EQU   4+STRGRR      (DS F )   SAVE AREA FOR DSR REGISTER       91150015
REGRR    EQU   4+STGDSR      (DS F )   RETURN REGISTER                  91200015
REGDSR   EQU   4+REGRR      (DS  F )   ARGUMENT REGISTER                91250015
DESAD    EQU   4+REGDSR     (DS  F )   ADDRESS OF REGISTER BLOCK        91300015
REG      EQU   4+DESAD      (DS  H )   REGISTER ALLOCATED               91350015
LREG     EQU   2+REG        (DS  H )   REGISTER FOR LOAD                91400015
REGCOD   EQU   2+LREG       (DS  C )   CODE BYTE, BIT 0 = 1 FOR NO LOAD 91450015
*                                                 BIT 1 = 1 -NO STORE   91500015
*                                                 BIT 2 = 1 -CALL SEQ   91550015
*                                                 BIT 3=1 - SDR   16210 91570017
NGR      EQU   1+REGCOD     (DS  C )   NUMBER OF GENERAL REGS IN USE    91600015
NFR      EQU   1+NGR        (DS  C )   NUMBER OF FLOAT REGS IN USE      91650015
         SPACE 2                                                        91700015
*              SWOP SUBROUTINE WORK SPACE                               91750015
SWOPRR   EQU   2+NFR        (DS  F )   RETURN REGISTER                  91800015
DESBUF   EQU   4+SWOPRR      (DS 7H)   DESCRIPTION BUFFER               91850015
DMPRR    EQU   TOTDES+2+DESBUF (DS F ) DUMP RETURN REGISTER             91900015
         SPACE 2                                                        91950015
*              'CONVERT' SUBROUTINE WORKSPACE                           92000015
CVTRR    EQU   4+DMPRR       (DS F )   RETURN REGISTER                  92050015
CVTBUF   EQU   4+CVTRR       (DS F )   WORKSPACE                        92100015
CVTG0    EQU   4+CVTBUF      (DS F )   REGISTER G0                      92150015
CVTDSR   EQU   4+CVTG0       (DS F )   SAVE REGISTER DSR                92200015
         SPACE 2                                                        92250015
*              COMPLEX ROUTINE WORK SPACE.                              92300015
CPXBF1   EQU   4+CVTDSR     (DS  7H)   DES1,RESULT BUFFER               92350015
CPXBF2   EQU   14+CPXBF1    (DS  7H)   DES2 BUFFER                      92400015
         SPACE 2                                                        92450015
*              ADD,MULT,DIVIDE FUNCTION WORKSPACE.                      92500015
FNSTAT   EQU   14+CPXBF2    (DS  F )   FUNCTION STACK POINTER           92550015
AMDBUF   EQU   4+FNSTAT     (DS  F )   BUFFER FOR FUNCTION DED          92600015
         SPACE 2                                                        92650015
*              VARIABLES WITH EXTENDED SPACE REQUIREMENTS               92700015
FNBUF    EQU   4+AMDBUF     (DS  51C ) FUNCTION STACK                   92750015
MOD8     EQU   FNBUF+58-BGWS                                            92800015
DBL      EQU   MOD8/8*8                                                 92850015
BGPC     EQU   BGWS+DBL                128 BYTE PSEUDO-CODE BUFFER      92900015
NDPC     EQU   128+BGPC                                                 92950015
BGSTK    EQU   2096+BGWS    (DS 1000H) BEGINNING OF DESCRIPTION STACK   93000015
STKVR2   EQU   1000*2+BGSTK                                             93050015
         SPACE 2                                                        93100015
*                       DICTIONARY COMMUNICATIONS REGION (BASE = DICR)  93150015
D        EQU   4096+BGWS                                                93200015
ZMYNAM   EQU   D+112                   NAME OF CURRENT PHASE            93250015
PAR1     EQU   D+128                                                    93300015
PAR2     EQU   D+132                                                    93350015
PAR5     EQU   D+144                                                    93400015
PAR6     EQU   D+148                                                    93450015
PAR7     EQU   D+152                                                    93500015
PAR8     EQU   D+156                                                    93550015
STEXT    EQU   D+256                                                    93600015
ZTEXT    EQU   D+256                                                    93650015
ZTBSZE   EQU   D+264                                                    93700015
ZCOMM    EQU   D+304                   BASE OF PHASE COMMOM             93750015
ZFLAG3   EQU   ZCOMM+18                                                 93800015
ZSMREG   EQU   ZCOMM+40                CURRENT SYMBOLIC REGISTER NUMBER 93850015
Z2FILE   EQU   ZCOMM+44                                                 93900015
ZSTACH   EQU   ZCOMM+68                START OF STATIC CHAIN            93950015
ZCONCH   EQU   ZCOMM+76                BEGINNING OF CONSTANT CHAIN      94000015
ZEQMAX   EQU   ZCOMM+82                CURRENT COMPILER LABEL           94050015
ZOSMRG   EQU   ZCOMM+84                HIGHEST OPTIMISING SYMBOLIC REG  94100015
*                       TRANSFER VECTORS TO CONTROL PHASE (BASE = CTVR) 94150015
Z        EQU   4096+D                                                   94200015
ZUGC     EQU   Z+16                    ALLOCATE SCRATCH CORE            94250015
ZUTXTC   EQU   Z+20                    GET NEXT TEXT BLOCK              94300015
ZURC     EQU   Z+24                    RELEASE SCRATCH CORE             94350015
ZABORT   EQU   Z+32                    DUMP AND STOP                    94400015
ZLOAD    EQU   Z+36                    LOAD PHASE AND RETURN TO CALLER  94450015
ZDICRF   EQU   Z+44                    MAKE ENTRY IN DICTIONARY         94500015
ZUERR    EQU   Z+48                    ERROR MESSAGE                    94550015
ZDRFAB   EQU   Z+52                    CONTROL COMMS. OFFSET            94600015
ZDUMP    EQU   Z+56                                                     94650015
ZUDUMP   EQU   Z+56                    DUMP                             94700015
REQEST   EQU   Z+64                    MARK BLOCKS                      94750015
RLSCTL   EQU   Z+72                    RELEASE PHASES AND GO TO NEXT    94800015
ZTXTRF   EQU   Z+80                    TEXT ABS ADDRESS TO SYMBOLIC     94850015
ZTXTAB   EQU   Z+84                    TEXT SYMBOLIC ADDRESS TO ABS     94900015
ZCHAIN   EQU   Z+88                    GET NEXT TEXT BLOCK IN CHAIN     94950015
ZALTER   EQU   Z+92                    ALTER STATUS OF TEXT BLOCK       95000015
ZDABRF   EQU   Z+96                    DICT ABS ADDRESS TO SYMBOLIC     95050015
         SPACE 2                                                        95100015
SC       EQU   4096+Z                  TRANSFER VECTORS TO SCAN         95150015
SCINIT   EQU   SC                                                       95200015
SC1      EQU   4+SCINIT                                                 95250015
SC2      EQU   4+SC1                                                    95300015
SC3      EQU   4+SC2                                                    95350015
SC4      EQU   4+SC3                                                    95400015
SC5      EQU   4+SC4                                                    95450015
SC6      EQU   4+SC5                                                    95500015
SC7      EQU   4+SC6                                                    95550015
SC8      EQU   4+SC7                                                    95600015
SC9      EQU   4+SC8                                                    95650015
SC10     EQU   4+SC9                                                    95700015
SC10A    EQU   4+SC10                                                   95750015
SCNERR   EQU   4+SC10A                                                  95800015
MV1      EQU   4+SCNERR                                                 95850015
MV2      EQU   4+MV1                                                    95900015
MV3      EQU   4+MV2                                                    95950015
MV3A     EQU   4+MV3                                                    96000015
MV4      EQU   4+MV3A                                                   96050015
         SPACE 2                                                        96100015
LS       EQU   4096+SC                 TRANSFER VECTORS TO BLOCK LS     96150015
NXTPL    EQU   2+LS                                                     96200015
DICDES   EQU   4+NXTPL                                                  96250015
CONVT    EQU   4+DICDES                                                 96300015
CONST    EQU   4+CONVT                                                  96350015
LSUB1    EQU   4+CONST                                                  96400015
MOVEPC   EQU   4+LSUB1                                                  96450015
STRING   EQU   4+MOVEPC                                                 96500015
CPLEX    EQU   4+STRING                                                 96550015
TSTOD1   EQU   4+CPLEX                                                  96600015
TSTOD2   EQU   4+TSTOD1                                                 96650015
GENRPD   EQU   4+TSTOD2                                                 96700015
LB0      EQU   4+GENRPD                                                 96750015
SBGTNR   EQU   4+LB0                                                    96800015
         SPACE 2                                                        96850015
LU       EQU   4096+LS                 TRANSFER VECTORS TO BLOCK LU     96900015
EXPONT   EQU   LU                                                       96950015
SETCPX   EQU   4+EXPONT                                                 97000015
ADDFUN   EQU   4+SETCPX                                                 97050015
         SPACE 2                                                        97100015
         END   IEMLT                                                    97150015
