LV       TITLE 'IEMLV,STRING UTILITIES,PSEUDO CODE GENERATION,PL/I F.'  00100015
         SPACE 3                                                        00200015
*              STATUS - CHANGE LEVEL 0.                                 00300015
* R20  789000                                                     33905 00330000
* THIS MODULE MUST BE AT LEAST AS BIG AS IEMMO.                   33905 00360000
         SPACE 3                                                        00400015
*              FUNCTION (1) TO CONVERT ANY DATA ITEM TO A STRING.       00500015
*                       (2) TO PRODUCE A STRING DOPE VECTOR (SDV)       00600015
*        DESCRIPTION FROM A STANDARD STRING DESCRIPTION.                00700015
*                       (3) THE PHASE IS LOADED AND AVAILABLE FOR USE   00800015
*        BY ALL PSEUDO-CODE PHASES BETWEEN LW AND OE.                   00900015
         SPACE 3                                                        01000015
*              ENTRY POINT (1) 'STUT0' FROM PREVIOUS PHASE TO SET UP    01100015
*        TRANSFER VECTORS 'ZSTUT1','ZSTUT2' IN COMMUNICATIONS REGION IN 01200015
*        DICTIONARY WITH ADDRESSES OF ENTRY POINTS 'STUT1','STUT2'.     01300015
*                          (2) 'STUT1' TO CONVERT TO A STRING. 'PAR1'   01400015
*        CONTAINS A DICTIONARY REFERENCE,RIGHT ADJUSTED, OR ADDRESS OF  01500015
*        TDB (TEMPORARY DESCRIPTION BLOCK). 'PAR2+3' CONTAINS A FLAG    01600015
*        BYTE,SET AS FOLLOWS - BITS 0,1  00 - CHARACTER STRING RESULT.  01700015
*                                        11 - BIT STRING RESULT.        01800015
*                              BIT  2     0 - PAR1 CONTAINS DICT REF.   01900015
*                                         1 - PAR1 CONTAINS TDB ADDRESS 02000015
*                              BIT  3     0 - STRING RESULT REQUIRED.   02100015
*                                         1 - SDV RESULT REQUIRED.      02200015
*        IF THE RESULT SPACE IS BOUGHT,X'02' IS ADDED TO BYTE 1 ('FLAG) 02300015
*        OF RESULT DESCRIPTION TO INDICATE THAT USER MUST SELL SPACE.   02400015
*                          (3) 'STUT2' TO PRODUCE A SDV DESCRIPTION.    02500015
*        'PAR1' CONTAINS THE ADDRESS OF THE TDB OF THE SOURCE STRING.   02600015
*        IF BYTE 1 OF SOURCE DESCRIPTION IS X'41', SYMBOLIC REGISTER IS 02700015
*        DROPPED. IF BYTE 1 IS X'49', SYMBOLIC REGISTER IS NOT DROPPED. 02800015
         SPACE 3                                                        02900015
*              INPUT (1) DICTIONARY REFERENCE RIGHT ADJUSTED IN 'PAR1'. 03000015
*                    (2) TDB OR TEMPORARY DESCRIPTION BLOCK OF 10 BYTES 03100015
*        CONTAINING THE SAME INFORMATION AS THE OPERAND FIELDS OF A     03200015
*        GROUP OF 3 TMPD TRIPLES.                                       03300015
         SPACE 3                                                        03400015
*              OUTPUT - 'PAR1' CONTAINS ADDRESS OF TDB DESCRIBING THE   03500015
*        RESULT.                                                        03600015
         SPACE 3                                                        03700015
*              EXTERNAL ROUTINE (1) 'ZDRFAB' IN CONTROL PHASE TO        03800015
*        CONVERT SYMBOLIC DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.     03900015
*                               (2) 'ZDICRF' IN CONTROL PHASE TO CREATE 04000015
*        NEW DICTIONARY ENTRY.                                          04100015
*                               (3) 'MV3' IN SCAN PHASE LA TO MOVE      04200015
*        PSEUDO-CODE TO OUTPUT TEXT.                                    04300015
*                               (4) 'MV3A' IN SCAN PHASE LA TO MOVE     04400015
*        TRIPLES TO OUTPUT TEXT.                                        04500015
         SPACE 3                                                        04600015
*              EXIT-NORMAL (1) TO INSTRUCTION AFTER INVOCATION WHEN     04700015
*        RESULT IS A STRING. 'PAR1' CONTAINS TDB ADDRESS.               04800015
*                          (2) TO 1ST,2ND,3RD INSTRUCTION AFTER         04900015
*        INVOCATION WHEN RESULT IS STRING DOPE VECTOR. THE RETURN POINT 05000015
*        DEPENDS ON THE SDV TYPE -                                      05100015
*        1ST INSTRUCTION - DICTIONARY REFERENCE + 1.                    05200015
*        2ND INSTRUCTION - TEMPORARY WORKSPACE OFFSET.                  05300015
*        3RD INSTRUCTION - DICTIONARY REFERENCE + INDEX REGISTER.       05400015
         SPACE 3                                                        05500015
*              EXIT-ERROR - NONE. IF INPUT TO 'STRUT2' DOES NOT         05600015
*        DESCRIBE A STRING CORRECTLY, THE INPUT DESCRIPTION IS RETURNED 05700015
*        AS THE RESULT.                                                 05800015
         SPACE 3                                                        05900015
*              WORK-AREA - INCLUDED IN PHASE.                           06000015
         SPACE 3                                                        06100015
*              ATTRIBUTES - THIS BLOCK IS NOT READ-ONLY AND NOT RE-     06200015
*        ENTRANT.                                                       06300015
         SPACE 3                                                        06400015
*              NOTES (1) THIS BLOCK REQUIRES NO MODIFICATION AS A       06500015
*        RESULT OF CHANGES IN THE INTERNAL REPRESENTATION OF EXTERNAL   06600015
*        GRAPHICS.                                                      06700015
*                                                                       06800015
*                    (2) THE LENGTH OF THE RESULTANT STRING IN 'STRUT1' 06900015
*        IS GIVEN BY THE PL/I LANGUAGE SPECIFICATIONS.                  07000015
*                                                                       07100015
*                    (3) IF THE RESULTANT STRING IN 'STRUT1' IS OF      07200015
*        FIXED LENGTH,LESS THAN 256 BYTES, IT IS PUT IN TEMPORARY WORK- 07300015
*        SPACE AND THE FOLLOWING TRIPLES ARE GENERATED --               07400015
*                                             X'47'    00    00         07500015
*                    X'47'    00   SDR        TMPD (  SOURCE   )        07600015
*                    TMPD (  RESULT   )   OR  TMPD (DESCRIPTION)        07700015
*                    TMPD (DESCRIPTION)       TMPD (  RESULT   )        07800015
*                                             TMPD (DESCRIPTION)        07900015
*                                                                       08000015
*                    (4) IF THE RESULTANT STRING IN 'STRUT1' IS         08100015
*        ADJUSTABLE OR LONGER THAN 255 BYTES, A DICTIONARY ENTRY IS     08200015
*        MADE AND A BUY-ASSIGN TRIPLE IS GENERATED --                   08300015
*                                             X'37'    TDR    00        08400015
*                    X'37'   TDR   SDR    OR  TMPD  (  SOURCE   )       08500015
*                                             TMPD  (DESCRIPTION)       08600015
*                                                                       08700015
*                    (5) 'STRUT2' PRODUCES THE FOLLOWING SDV            08800015
*        DESCRIPTIONS --                                                08900015
*        .............................................................. 09000015
*             INPUT TYPE                .     SDV TYPE                  09100015
*        .............................................................. 09200015
*        NON-BASED SCALAR STRING IN DICT. DICT REF + 1,WITH SDV BIT ON. 09300015
*        REF OR DICT REF + 1.           .                               09400015
*        .............................................................. 09500015
*        BASED SCALAR STRING IN DICT    . SDV IN TEMP WORKSPACE CREATED 09560015
*        REF OR DICT REF + 1. NEITHER   .BY PSEUDO-CODE WITH SDV BIT ON 09620015
*        STUCTURE MEMBER NOR ADJUSTABLE .        L   SRE,DR(PTR)        09680015
*                                       .        L   SRO,SDV+4          09740015
*                                       .        STM SRE,SRO,T          09800015
*        .............................................................. 09860015
*        BASED SCALAR STRING IN DICT    . SDV IN TEMP WORKSPACE CREATED 09920015
*        REF OR DICT REF + 1 WHICH IS   .BY PSEUDO-CODE WITH SDV BIT ON 09980015
*        A MEMBER OF A STRUCTURE,BUT    .        LM  SRE,SRO,SKDV       10040015
*        NON-ADJUSTABLE                 .        A   SRE,DR(PTR)        10100015
*                                       .        STM SRE,SRO,T          10160015
*        .............................................................. 10220015
*        BASED SCALAR STRING IN DICT    . SDV IN TEMP WORKSPACE CREATED 10280015
*        REF OR DICT REF + 1 WHICH IS   .BY PSEUDO-CODE WITH SDV BIT ON 10340015
*        ADJUSTABLE, BUT NOT A STRUCTURE.        L   SRE,DR(PTR)        10400015
*        MEMBER                         .        L   SRO,DR(LENGTH)     10460015
*                                       .        STM SRE,SRO,T          10520015
*                                       .        STH SRO,T+4            10580015
*        .............................................................. 10640015
*        BASED SCALAR STRING IN DICT    . SDV IN TEMP WORKSPACE CREATED 10700015
*        REF OR DICT REF + 1 ,WHICH IS  .BY      L   SRE,DR(PTR)        10760015
*        BOTH STRUCTURE MEMBER AND      .        A   SRE,SKDV           10820015
*        ADJUSTABLE                     .        L   SRO,DR(LENGTH)     10880015
*                                       .        STM SRE,SRO,T          10940015
*                                       .        STH SRO,T+4            11000015
*        .............................................................. 11200015
*         FIXED,NON-ADJUST SCALAR STRING. DICT REF + 1 FOR TEMP WORK-   11300015
*        IN TEMP WORKSPACE.             .SPACE SDV ENTRY.               11400015
*        .............................................................. 11500015
*         FIXED,NON-ADJUST STRING ARRAY . SDV IN TEMP WORKSPACE CREATED 11600015
*        ELEMENT IN SYMBOLIC ADDRESS    .BY PSEUDO-CODE --              11700015
*        REGISTER.                      .        ST   SR,WS+0           11800015
*                                       .        LA   G0,LENGTH         11900015
*                                       .        STH  G0,WS+4           12000015
*                                       .        STH  G0,WS+6           12100015
*                                       .      ( DROP SR )              12200015
*        .............................................................. 12300015
*         FIXED,ADJUST ARRAY ELEMENT SDV. NO CHANGE.                    12400015
*        IN TEMP WORKSPACE.             .                               12500015
*        .............................................................. 12600015
*         VARYING ARRAY ELEMENT SDV IN  . NO CHANGE.                    12700015
*        DICT REF + INDEX REGISTER.     .                               12800015
*        .............................................................. 12900015
         EJECT                                                          13000015
         SPACE 2                                                        13100015
IEMLV    START 0                                                        13200015
*                       ASSEMBLY CONSTANTS                              13300015
*                       GENERAL REGISTERS.                              13400015
G0       EQU   0                       WORKING                 SCRATCH  13500015
IP       EQU   1                       INPUT POINTER           RESERVED 13600015
LVBASE   EQU   2                       STRING UTILITY BASE              13700015
PAR      EQU   3                       SCAN PARAMETER BASE              13800015
GRN      EQU   4                       EVEN MULT REGISTER               13900015
G1       EQU   5                       ODD MULT REGISTER,SCRATCH        14000015
DSR      EQU   6                       OUTPUT TRIPLE POINTER            14100015
CTVR     EQU   11                      CONTROL TRANSFER VECTOR BASE     14200015
SCBASE   EQU   12                      SCAN PHASE BASE                  14300015
DICR     EQU   13                      DICTIONARY COMMON BASE           14400015
LR       EQU   14                      LINK, RETURN                     14500015
RR       EQU   14                      LINK, RETURN                     14600015
BR       EQU   15                      BRANCH                           14700015
*                       MASKS FOR BRANCH ON CONDITION.                  14800015
*              INSTRUCTION TYPE -      COMPARISON,ARITHMETIC,MASK TEST  14900015
NOP      EQU   0                       NOP.                             15000015
BO       EQU   1                           --    ,OVERFLOW  ,ALL ONES   15100015
BH       EQU   2                       HIGH      ,PLUS      ,    --     15200015
BL       EQU   4                       LOW       ,MINUS     ,MIXED 0-1  15300015
BNE      EQU   7                       NOT EQUAL ,NOT ZERO  ,NOT ALL 0  15400015
BZ       EQU   8                       EQUAL     ,ZERO      ,ALL ZEROS  15500015
BE       EQU   8                                                        15600015
BNL      EQU   11                      NOT LOW   ,NOT MINUS ,NOT MIXED  15700015
BN1      EQU   12                          --    ,    --    ,NOT ALL 1  15800015
BNH      EQU   13                      NOT HIGH  ,NOT PLUS  ,    --     15900015
BNO      EQU   14                      BRANCH NOT ONES                  15950015
B        EQU   15                      UNCONDITIONAL.                   16000015
*              TRIPLE LAYOUT - USUALLY BASED ON IR                      16100015
TPOPN    EQU   0                       OPERATOR    - 1 BYTE             16200015
TPOD1    EQU   1                       1ST OPERAND - 2 BYTES            16300015
TPOD2    EQU   3                       2ND OPERAND - 2 BYTES            16400015
*                       DESCRIPTION ITEM LAYOUT- OFFSETS FROM START     16500015
DESFLG   EQU   0                       FLAG BYTE                        16600015
DESCDE   EQU   1                       CODE BYTE                        16700015
DESP     EQU   2                       PRECISION BYTE                   16800015
DESQ     EQU   3                       SCALE FACTOR BYTE                16900015
DESBSE   EQU   4                       BASE ADDRESS BYTES (2)           17000015
DESNDX   EQU   6                       NDX (INDEX) BYTES (2)            17100015
DESOFS   EQU   8                       OFS (OFFSET) BYTES (2)           17200015
DESLTH   EQU   10                      BYTE LENGTH FOR P-D  (2 BYTES)   17300015
ISTK     EQU   10                                                       17400015
*                       PSEUDO-CODE LAYOUT - RR,RX,RS,SI OPERATIONS.    17500015
PCSZ3    EQU   3                       SIZE OF 3 BYTE PC                17600015
PCSZ5    EQU   5                       SIZE OF 5 BYTE PC                17700015
PCOPN    EQU   0                       P-C OPERATION CODE               17800015
PCOD1    EQU   1                       P-C 1ST OPERAND                  17900015
PCOD2    EQU   3                       P-C 2ND OPERAND                  18000015
PCOSM    EQU   5                       P-C OFFSET MARKER CODE           18100015
PCOSM1   EQU   6                       P-C OFFSET MARKER FIELD 1        18200015
PCOSM2   EQU   8                       P-C OFFSET MARKER FIELD 2        18300015
*                       PSEUDO-CODE LAYOUT - SS OPERATIONS              18400015
PCSZ8    EQU   8                       SIZE OF 8 BYTE PC                18500015
PCSZ12   EQU   12                    SIZE OF 12 BYTE PC                 18600015
*PCOPN   EQU   0                       P-C OPERATION CODE               18700015
PCFLG    EQU   1                       P-C FLAG                         18800015
PCLNG    EQU   2                       BYTE LENGTH OF PC INSTRUCTION    18900015
PCF1     EQU   3                       LENGTH CODES - L OR  L1,L2       19000015
PCF2     EQU   4                       P-C 1ST OPERAND - DR/SYM REG     19100015
PCF3     EQU   6                       P-C 2ND OPERAND - DR/SYM REG     19200015
PCF4     EQU   8                       P-C 1ST OFFSET                   19300015
PCF5     EQU   10                      P-C 2ND OFFSET                   19400015
*              LAYOUT OF DICTIONARY ENTRY FOR CONSTANT.                 19500015
DCFLG    EQU   0                       FLAG =X'88' FOR CONSTANT         19600015
DCLNG    EQU   1                       TOTAL LENGTH                     19700015
DCCHN    EQU   3                       CONSTANT CHAIN                   19800015
DCDED1   EQU   5                       APPARENT DED (3 BYTES)           19900015
DCTYP    EQU   8                       TYPE                             20000015
DCDED2   EQU   9                       REQUIRED DED                     20100015
DCINIT   EQU   12                      INITIAL VALUE BYTES              20200015
DCVAL    EQU   14                      VALUE OF CONSTANT                20300015
CONDE    EQU   X'88'                   CONSTANT DE CODE BYTE            20400015
*              LAYOUT OF DICT ENTRY FOR TEMP SDV                        20500015
DDVOFS   EQU   5                       OFFSET OF STRING IN TEMP STACK   20600015
DDVDR    EQU   8                       DICTIONARY ENTRY OF WORKSPACE    20650015
DDVLNG   EQU   10                      LENGTH OF STRING                 20700015
*              LAYOUT OF DICT ENTRY FOR ENTRY TYPE 1                    20800015
DE1LC    EQU   3                       LEVEL,COUNT                      20900015
DE1AUT   EQU   11                      START OF AUTO CHAIN FOR BLOCK    21000015
*              LAYOUT OF DICT ENTRY FOR VARIABLE                        21100015
DEFLG    EQU   0                       FLAG BYTE                        21200015
DELNG    EQU   1                       LENGTH OF ENTRY                  21300015
DECHN    EQU   3                       AUTOMATIC CHAIN                  21400015
DEDED    EQU   8                       ACTUAL DED IN DED2 DICT ENTRY    21500015
DEVAR    EQU   11                      VARIABLE BYTE                    21600015
DEOTH2   EQU   12                      OTHER 2 CODE BYTE                21700015
DEOTH3   EQU   13                      'OTHER 3' CODE BYTE              21800015
DEDATA   EQU   15                      DATA BYTES                       21900015
DESYMB   EQU   19                      SYMBOL/PICTURE SLOT              22000015
*              LAYOUT OF DICT ENTRY FOR PICTURE                         22100015
DEPICP   EQU   9                       P,Q OF PICTURE                   22200015
DEPICW   EQU   11                      APPARENT LENGTH OF PICTURE       22300015
DSYPIC   EQU   9                       PIC DR IN SYMBOL,DED ENTRY       22400015
BUYLC    EQU   25                      LEVEL,COUNT FOR BUY DICT ENTRY   22500015
VARDE    EQU   X'0F'                   CODE FOR DICT ENTRY FOR VARIABLE 22600015
GRE      EQU   14                      EVEN ARITH REGISTER              22700015
GRO      EQU   15                      ODD ARITH REGISTER               22800015
*              PSEUDO-CODE OPERATION CODES.                             22900015
DROP     EQU   X'06'                   DROP                             23000015
OSM1     EQU   X'10'                   OFFSET MARKER 1 (LITERAL)        23100015
L        EQU   X'88'                   FIX BINARY LOAD                  23200015
A        EQU   X'8A'                                                    23300015
STH      EQU   X'95'                   STH                              23400015
LA       EQU   X'A0'                   LA                               23500015
ST       EQU   X'A5'                   ST                               23600015
MVC      EQU   X'C1'                                                    23700015
OSM3     EQU   X'BD'                   OSM3                             23720015
LM       EQU   X'70'                   LM                               23740015
STM      EQU   X'79'                   STM                              23760015
*              TRIPLE OPERATION CODES.                                  23800015
FUNASN   EQU   X'37'                   SPECIAL ASSIGN                   23900015
ASSGN    EQU   X'47'                   ASSIGN                           24000015
TMPD     EQU   X'58'                   TEMPORARY DESCRIPTION            24100015
         EJECT                                                          24200015
         USING *,LVBASE                                                 24300015
         USING SCTRT,PAR                                                24400015
         USING D,DICR                                                   24500015
         USING Z,CTVR                                                   24600015
         USING SC,SCBASE                                                24700015
NAME     DC    C'LV'                                                    24800015
         SPACE 2                                                        24900015
*              INITIALISATION ENTRY TO SET TRANSFER VECTORS.            25000015
*                                                                       25100015
STUT0    L     LVBASE,PAR1             LOAD BASE REGISTER               25200015
         BC    B,STUT0A                BRANCH TO INITIALISATION         25300015
         SPACE 2                                                        25400015
         USING RGSAVE,LVBASE                                            25500015
         SPACE 2                                                        25600015
*              'STRUT1' ENTRY POINT - INITIALISE ONLY.                  25700015
*                                                                       25800015
STUT1    LA    BR,RGSAVE-*(BR)         POINT AT BEGINNING OF CODE       25900015
         STM   RR,DSR,0(BR)            STORE ALL REGISTERS USED         26000015
         MVC   4(4,BR),ZSTUT1          CORRECT CONTENTS OF BR           26100015
         LR    LVBASE,BR               LOAD BASE REGISTER               26200015
         BC    B,STRUT1                START                            26300015
         SPACE 2                                                        26400015
*              'STRUT2' ENTRY POINT - INITIALISE ONLY.                  26500015
*                                                                       26600015
STUT2    LA    BR,RGSAVE-*(BR)         POINT AT BEGINNING OF CODE       26700015
         STM   RR,DSR,0(BR)            STORE ALL REGISTERS USED         26800015
         MVC   4(4,BR),ZSTUT2          CORRECT CONTENTS OF BR           26900015
         LR    LVBASE,BR               LOAD BASE REGISTER               27000015
         BC    B,STRUT2                START                            27100015
         SPACE 2                                                        27200015
*              REGISTER SAVE AREA AND BASE LOCATION FOR PHASE.          27300015
*                                                                       27400015
*        THE 9-WORD REGISTER SAVE AREA OVERWRITES THE PHASE INITIAL-    27500015
*        ISATION CODE.                                                  27600015
*        +++++++++++++++++++++++++++++++++++++++++++++++++++*LV 001-TSS 27650000
RGSAVE   DS    0F                      START OF SAVE AREA FOR 9 REGS    27700015
*        ----------------------------------------------------LV 001-TSS 27750000
NDSAVE   EQU   RGSAVE+36               END OF REGISTER SAVE AREA        27800015
         SPACE 2                                                        27900015
*              PHASE INITIALISATION.                                    28000015
         USING NAME,LVBASE                                              28100015
STUT0A   MVC   ZMYNAM(2),NAME                                           28200015
         MVI   ZDROLF,X'FF'            SET FLAG FOR COMPILER CONTROL    28300015
         LA    BR,STUT1                                                 28400015
         ST    BR,ZSTUT1               STUT1 ADDRESS IN COMMUN SLOT     28500015
         LA    BR,STUT2                                                 28600015
         ST    BR,ZSTUT2               STUT2 ADDRESS IN COMMUN SLOT     28700015
         LA    BR,NULBLK                                                28800015
         ST    BR,PAR1                 DON'T RELEASE ANY BLOCKS         28900015
         XC    PAR2(4),PAR2                                             29000015
         L     BR,RLSCTL               TRANSFER TO NEXT PHASE           29100015
         BCR   B,BR                                                     29200015
         USING RGSAVE,LVBASE                                            29300015
         EJECT                                                          29400015
*              'STRUT1' SUBROUTINE.                                     29500015
         SPACE 2                                                        29600015
*              SET UP SOURCE TDB.                                       29700015
STRUT1   MVC   FLAG(1),PAR2+3          FLAG CODE BYTE                   29800015
         NI    FLAG,X'FE'              CLEAR BIT 7                      29900015
         XC    TPASGN+TPOD1(4),TPASGN+TPOD1   CLEAR ASSIGN OPERANDS     30000015
         L     BR,ZDRFAB                                                30100015
         TM    FLAG,X'20'              TEST FLAG,                       30200015
         BC    BZ,LSUT1                BRANCH IF DICT REF IN PAR1.      30300015
         L     G1,PAR1                 GET ADDRESS OF SOURCE TDB,       30400015
         MVC   STDB(ISTK),0(G1)        AND MOVE TO SOURCE BUFFER.       30500015
         MVC   TPASGN+5+TPOD1(4),0(G1)       SET 1ST TMPD               30600015
         MVC   TPASGN+10+TPOD1(4),4(G1)      SET 2ND TMPD               30700015
         LA    DSR,TPASGN+15                                            30800015
         TM    STDB+DESFLG,X'10'                                        30900015
         BC    BZ,LSUT0                BRANCH IF ONLY 2 TMPD'S          31000015
         MVC   TPOD1(2,DSR),8(G1)      MOVE 3RD TMPD                    31100015
         LA    DSR,5(DSR)              BUMP POINTER                     31200015
LSUT0    MVC   PAR1+2(2),STDB+DESP     MOVE POSSIBLE PICTURE DICT REF   31300015
         BC    B,LSUT1C                                                 31400015
LSUT1    MVC   STDB+DESBSE(2),PAR1+2   DICT REF IN SOURCE BUFFER        31500015
         MVC   TPASGN+TPOD2(2),PAR1+2        SET 2ND OPND IN ASSIGN     31600015
         BALR  LR,BR                   ABSOLUTE                         31700015
         L     G1,PAR1                                                  31800015
         MVC   STDB+DESCDE(3),DEDATA(G1)    MOVE DED BYTES              31900015
         MVI   STDB+DESFLG,X'00'       DICT REF TYPE SOURCE             32000015
         LA    DSR,TPASGN+5                                             32100015
         CLI   DEFLG(G1),CONDE                                          32200015
         BC    BNE,LSUT1B              BRANCH IF NOT CONSTANT           32300015
LSUT1A   MVC   STDB+DESCDE(3),DCDED1(G1)                                32400015
         OI    FLAG,X'01'              SET FLAG FOR CONSTANT            32500015
         MVI   TTDB+DESFLG,X'00'       SET NEW DICT REF IN TARGET TDB   32600015
         BC    B,LSUT2                                                  32700015
LSUT1B   MVC   PAR1+2(2),DESYMB(G1)    MOVE POSSIBLE PICTURE DICT REF   32800015
LSUT1C   TM    STDB+DESCDE,X'08'                                        32900015
         BC    BO,LSUT2                BRANCH IF CODED TYPE             33000015
         BALR  RR,BR                   CONVERT SYMBOLIC TO ABSOLUTE     33100015
         L     G1,PAR1                                                  33200015
         MVC   PAR1+2(2),DSYPIC(G1)    MOVE POSSIBLE PICTURE DICT REF   33300015
         CLI   DEFLG(G1),X'C7'         TEST FOR SYMBOL OR DED DICT REF  33400015
         BCR   BZ,BR                   IF YES,CONVERT PIC DR TO ABS     33500015
         MVC   STDB+DESP(2),DEPICW(G1) PUT PICTURE LENGTH IN SOURCE DED 33600015
         TM    STDB+DESCDE,X'80'                                        33700015
         BC    BZ,LSUT18               BRANCH IF STRING SOURCE          33800015
         TM    FLAG,X'C0'                                               33900015
         BC    BZ,LSUT2                BRANCH IF CHAR TARGET            34000015
         MVC   STDB+DESP(2),DEPICP(G1) PUT PICTURE P,Q IN SOURCE DED    34100015
         SPACE 2                                                        34200015
*              SET UP TARGET DATA TYPE AND LENGTH.                      34300015
LSUT2    TM    STDB+DESCDE,X'80'       TEST SOURCE FOR ARITH/STRING     34400015
         BC    BZ,LSUT18               BRANCH IF STRING                 34500015
         SR    G1,G1                                                    34600015
         IC    G1,STDB+DESP            SOURCE PRECISION - R.            34700015
         TM    FLAG,X'C0'                                               34800015
         BC    BZ,LSUT7                BRANCH IF CHARACTER RESULT       34900015
         SPACE 2                                                        35000015
*              ARITH TYPE SOURCE AND BIT STRING TARGET.                 35100015
LSUT3    MVI   TTDB+DESCDE,X'28'       TARGET TYPE                      35200015
LSUT3A   TM    STDB+DESCDE,X'02'       TEST SOURCE FOR FLOAT/FIXED      35300015
         BC    BO,LSUT4                BRANCH IF FLOATING.              35400015
         SR    G0,G0                                                    35500015
         IC    G0,STDB+DESQ                                             35600015
         SH    G0,SF0                  SOURCE SCALE FACTOR - S.         35700015
         SR    G1,G0                   (R-S).                           35800015
         BC    BNL,LSUT4               BRANCH IF NOT NEGATIVE.          35900015
         SR    G1,G1                   SET TO ZERO.                     36000015
LSUT4    TM    STDB+DESCDE,X'04'       TEST SOURCE FOR DEC/BIN,         36100015
         BC    BO,LSUT5                BRANCH IF BINARY.                36200015
         M     GRN,DBMULT              MULT R*3.32 IN GRN,G1.           36300015
         A     G1,CEIL1                ROUND UP                         36400015
         SRA   G1,20                                                    36500015
LSUT5    CH    G1,FXMAXP               COMPARE WITH MAX FIX PREC,       36600015
         BC    BNH,LSUT6               BRANCH IF SMALLER.               36700015
         LH    G1,FXMAXP               SET TO MAX PRECISION.            36800015
LSUT6    STH   G1,TTDB+DESP            SET RESULT BIT LENGTH.           36900015
         LA    G1,7(G1)                ROUND UP AND                     37000015
         SRL   G1,3                    DIVIDE BY 8.                     37100015
         BC    B,LSUT17                                                 37200015
         SPACE 2                                                        37300015
*              ARITH TYPE SOURCE AND CHARACTER STRING TARGET.           37400015
LSUT7    MVI   TTDB+DESCDE,X'2C'       SET TARGET TO CHAR STRING        37500015
         TM    STDB+DESCDE,X'08'       TEST SOURCE FOR CODED/NF         37600015
         BC    BZ,LSUT15               BRANCH IF NF                     37700015
         TM    STDB+DESCDE,X'04'       TEST SOURCE FOR DEC/BIN,         37800015
         BC    BO,LSUT9                BRANCH IF BINARY                 37900015
LSUT8    TM    STDB+DESCDE,X'02'       TEST SOURCE FOR FLOAT/FIX        38000015
         BC    BO,LSUT14               BRANCH IF FLOAT                  38100015
         STH   G1,TTDB+DESP            SAVE PRECISION                   38200015
         IC    G1,STDB+DESQ                                             38300015
         SH    G1,SF0                  SOURCE SCALE FACTOR - S          38400015
         BC    B,LSUT11                                                 38500015
LSUT9    M     GRN,BDMULT              MULT  R*1/3.32 IN GRN,G1         38600015
         A     G1,CEIL1                ROUND UP                         38700015
         SRA   G1,20                                                    38800015
         TM    STDB+DESCDE,X'02'       TEST SOURCE FOR FLOAT/FIX        38900015
         BC    BO,LSUT14               BRANCH IF FLOAT                  39000015
         LA    G1,1(G1)                BUMP PRECISION BY 1              39100015
         STH   G1,TTDB+DESP                                             39200015
         IC    G1,STDB+DESQ                                             39300015
         SH    G1,SF0                  SOURCE SCALE FACTOR - S          39400015
         M     GRN,BDMULT              MULT  S*1/3.32 IN GRN,G1         39500015
         LTR   G1,G1                                                    39600015
         BC    BNH,LSUT10              BRANCH IF LESS THAN ZERO         39700015
         A     G1,CEIL1                ROUND UP                         39800015
LSUT10   SRA   G1,20                   TRUNCATE                         39900015
LSUT11   BC    BL,LSUT12               BRANCH IF S .LT. ZERO            40000015
         CH    G1,TTDB+DESP                                             40100015
         BC    BH,LSUT12               BRANCH IF S .GT. R               40200015
         LA    G1,3                    SET FOR (R+3) LENGTH             40300015
         BC    B,LSUT13                                                 40400015
LSUT12   LPR   G0,G1                   MAKE S POSITIVE                  40500015
         LA    G1,6                    SET FOR  (R+6) LENGTH            40600015
         CH    G0,H99                                                   40700015
         BC    BH,LSUT13               BRANCH IF S GREATER THAN 99      40800015
         BCTR  G1,0                    SET FOR  (R+5) LENGTH            40900015
         CH    G0,H9                                                    41000015
         BC    BH,LSUT13               BRANCH IF S GREATER THAN 9       41100015
         BCTR  G1,0                    SET FOR  (R+4) LENGTH            41200015
LSUT13   AH    G1,TTDB+DESP            ADD PRECISION R                  41300015
         BC    B,LSUT15                                                 41400015
LSUT14   LA    G1,6(G1)                SET FOR (R+6) LENGTH - FLOAT     41500015
LSUT15   TM    STDB+DESCDE,X'01'       TEST SOURCE FOR REAL/COMPLEX     41600015
         BC    BZ,LSUT16               BRANCH IF REAL                   41700015
         AR    G1,G1                                                    41800015
         TM    STDB+DESCDE,X'08'                                        41900015
         BC    BZ,LSUT16               BRANCH IF NF                     42000015
         LA    G1,1(G1)                LENGTH =2*W+1                    42100015
LSUT16   STH   G1,TTDB+DESP            SET LENGTH                       42200015
         SPACE 2                                                        42300015
*              GENERATE FIXED LENGTH CALLING SEQUENCE                   42400015
LSUT17   TM    FLAG,X'01'                                               42500015
         BC    BO,LSUT21               BRANCH IF CONSTANT               42600015
         CH    G1,MAXSTR               TEST BYTE LENGTH OF RESULT       42700015
         BC    BH,LSUT29               BRANCH IF GREATER THAN 255       42800015
         LH    G0,SCWKSC               CURRENT TOP OF TEMP CORE         42900015
         STH   G0,TTDB+DESBSE                                           43000015
         STH   G1,TTDB+DESNDX          STRING BYTE LENGTH               43100015
         AR    G0,G1                                                    43200015
         STH   G0,SCWKSC               NEW TOP OF TEMP CORE             43300015
         MVI   TTDB+DESFLG,X'C0'       SET TO TEMP CORE TYPE            43400015
         SPACE 2                                                        43500015
*              SET UP ASSIGNMENT TRIPLE AND TMPD'S                      43600015
         MVI   TPASGN+TPOPN,ASSGN      SET TRIPLE TO ASSIGN             43700015
LSUT27   MVC   TPOD1(4,DSR),TTDB       SET TARGET DESCRIPTION IN        43800015
         MVC   5+TPOD1(4,DSR),TTDB+4   ASSIGN TMPDS                     43900015
         LA    DSR,10(DSR)             TRIPLE FINISH                    44000015
         BC    B,LSUT26                                                 44100015
         SPACE 2                                                        44200015
*              CONSTANT SOURCE.                                         44300015
LSUT21   MVC   TTDB+DESBSE(2),STDB+DESBSE  MOVE INPUT CONSTANT DR       44400015
LCON1    L     G1,PAR1                 ABSOLUTE CONSTANT ADDRESS        44500015
         TM    DCTYP(G1),X'C0'                                          44600015
         BC    BL,LCON3                BRANCH IF INITIAL DATA CONSTANT  44700015
         TM    DCTYP(G1),X'01'         TEST USED BIT                    44800015
         BC    BZ,LCON2                BRANCH IF ALREADY IN USE         44900015
         MVC   DCINIT(2,G1),ZSTAT      MOVE IN CURRENT STATMENT NO      45000015
         MVC   DCDED2(3,G1),TTDB+DESCDE SET REQUIRED DED IN DICT.       45100015
         NI    DCTYP(G1),X'F8'         SET USED,NO DV,NO DED            45200015
         BC    B,LSUT22                RETURN                           45300015
LCON2    CLC   DCDED2(2,G1),TTDB+DESCDE TEST FOR DED MATCH              45400015
         BC    BE,LSUT22               RETURN IF DED'S ARE THE SAME     45500015
LCON3    NC    DCCHN(2,G1),DCCHN(G1)   GET NEXT CONSTANT IN CHAIN       45600015
         BC    BZ,LCON5                BRANCH IF END OF CHAIN           45700015
LCON4    MVC   TTDB+DESBSE(2),DCCHN(G1) NEXT CONSTANT DR                45800015
         MVC   PAR1+2(2),DCCHN(G1)                                      45900015
         L     BR,ZDRFAB                                                46000015
         BALR  RR,BR                   NEXT CONSTANT DR TO ABSOLUTE     46100015
         L     BR,PAR1                                                  46200015
         CLC   DCLNG(2,BR),DECON+DCLNG TEST FOR LENGTH 14               46300015
         BC    BE,LCON1                BRANCH IF STILL SAME CONSTANT    46400015
         SPACE                                                          46500015
*              END OF CONSTANT CHAIN, SO CREATE NEW DICT ENTRY.         46600015
         SPACE                                                          46700015
LCON5    MVC   DECON+DCCHN(5),DCCHN(G1) MOVE CHAIN,DED1,TYPE TO SKEL    46800015
         LA    BR,DECON                                                 46900015
         ST    BR,PAR1                 SKELETON ADDRESS                 47000015
         LA    BR,DCVAL                                                 47100015
         ST    BR,PAR2                 SKELETON LENGTH                  47200015
         L     BR,ZDICRF               CREATE NEW DICT ENTRY            47300015
         BALR  RR,BR                                                    47400015
         MVC   DCCHN(2,G1),PAR1+2      CHAIN LAST CON TO NEW CON        47500015
         BC    B,LCON4                                                  47600015
         SPACE 2                                                        47700015
*              STRING TYPE SOURCE.                                      47800015
LSUT18   MVC   TTDB+DESCDE(3),STDB+DESCDE  SET RESULT TYPE AND LENGTH   47900015
         OI    TTDB+DESCDE,X'2C'       SET RESULT TO CHARACTER STRING   48000015
         TM    FLAG,X'C0'                                               48100015
         BC    BZ,LSUT20                                                48200015
         NI    TTDB+DESCDE,X'FB'       SET RESULT TO BIT STRING         48300015
LSUT20   TM    TTDB+DESCDE,X'50'                                        48400015
         BC    BNE,LSUT29              BRANCH IF ADJUSTABLE OR VARYING  48500015
         LH    G1,STDB+DESP            FIXED LENGTH                     48600015
         TM    TTDB+DESCDE,X'04'                                        48700015
         BC    BZ,LSUT6                BRANCH IF BIT STRING RESULT      48800015
         BC    B,LSUT16                BRANCH IF CHAR STRING RESULT     48900015
         SPACE 2                                                        49000015
*              CREATE DICTIONARY ENTRY FOR BUY VARIABLE                 49100015
LSUT29   MVC   DEBUY+DEDATA(3),TTDB+DESCDE  PUT DED IN SKELETON         49200015
         LA    G1,DEBUY                                                 49300015
         BAL   RR,DEAUVR               CREATE DICT ENTRY                49400015
         MVC   TTDB+DESBSE(2),PAR1+2   SET DR IN TARGET TDB             49500015
         MVI   TTDB+DESFLG,X'02'       SET FLAG IN TARGET TDB           49600015
         SPACE 2                                                        49700015
*              SET UP SPECIAL ASSIGN TRIPLE AND MOVE TO OUTPUT          49800015
         MVI   TPASGN+TPOPN,FUNASN     SET TRIPLE TO SPECIAL ASSIGN     49900015
         MVC   TPASGN+TPOD1(2),PAR1+2  SET DR IN SPECIAL ASSIGN         50000015
LSUT26   LA    G1,TPASGN                                                50100015
         ST    G1,PAR1                 TRIPLE START                     50200015
         SR    DSR,G1                                                   50300015
         ST    DSR,PAR2                                                 50400015
         BAL   RR,MV3A                 MOVE TRIPLES TO OUTPUT           50500015
LSUT22   LA    G1,TTDB                                                  50600015
         ST    G1,PAR1                 RESULT ADDRESS                   50700015
         TM    FLAG,X'10'              TEST FOR STRING/DV RESULT        50800015
         BC    BZ,LSUT60               RETURN IF SDV NOT WANTED         50900015
         EJECT                                                          51000015
*              'STRUT2' SUBROUTINE.                                     51100015
         SPACE 2                                                        51200015
STRUT2   L     G1,PAR1                                                  51300015
         MVC   PTDB(ISTK),0(G1)        SOURCE DESCRIPTION INTO BUFFER   51400015
         TM    PTDB+DESCDE,X'80'                                        51500015
         BC    BO,STERR                BRANCH IF NOT STRING TYPE        51600015
         TM    PTDB+DESFLG,X'C0'                                        51700015
         BC    BNE,LSUT54              BRANCH IF NOT DICT REF           51800015
         TM    PTDB+DESFLG,X'20'                                        51900015
         BC    BO,LSUT53               BRANCH IF INDEX REGISTER         52000015
         NI    PTDB+DESBSE+1,X'FC'     REMOVE LOW ORDER 2 BITS          52100015
         MVC   PAR1+2(2),PTDB+DESBSE                                    52200015
         L     BR,ZDRFAB               CONVERT SYMBOLIC DICT REF        52300015
         BALR  RR,BR                   TO ABSOLUTE ADDRESS              52400015
         L     G1,PAR1                                                  52500015
         TM    DEFLG(G1),VARDE                                          52600015
         BC    BN1,LSUT52              BRANCH IF NOT A VARIABLE         52700015
         TM    DEOTH2(G1),X'03'        TEST FOR BASED VARIABLE          52800015
         BC    BO,LSUT46               BRANCH IF POSSIBLY BASED         52900015
LSUT45   OI    DEOTH3(G1),X'80'        SET REQUIRES DV BIT ON           53000015
         BC    B,LSUT51              FOR NON BASED VARIABLE             53100015
LSUT46   TM    DEVAR(G1),X'02'                                          53200015
         BC    BN1,LSUT45              BRANCH IF NOT BASED              53300015
         TM    DEVAR(G1),X'20'                                          53400015
         BC    BO,LSUT44               BRANCH IF STRUCTURE MEMBER       53500015
         TM    PTDB+DESCDE,X'40'                                        53600015
         BC    BO,LSUT47             AVOID DV REQ BIT FOR ADJ BASED     53700015
LSUT44   OI    DEOTH3(G1),X'80'      SET REQUIRES DV BIT ON             53800015
         SPACE                                                          53900015
*              GENERATE SDV IN WORKSPACE FOR BASED VARIABLE.            54000015
         SPACE                                                          54100015
LSUT47   MVC   UTBUF1(1),DEVAR(G1)                                      54200015
         LA    G0,7                    GET DICT REF FOR BASED POINTER   54300015
         TM    DEVAR(G1),X'01'         CHECK CONTROLLED FROM ALLOC BIT  54400015
         BC    BZ,LSUT50               BRANCH IF NOT SET                54500015
         LA    G0,9                                                     54600015
LSUT50   MVC   UTBUF(2),DELNG(G1)      DICT ENTRY LENGTH                54700015
         AH    G1,UTBUF                                                 54800015
         SR    G1,G0                   POINTER SLOT ADDRESS             54900015
         MVC   PCL1(2),0(G1)           MOVE DIC REF OF POINTER  TO L    54970015
         MVC   PCL2(2),PTDB+DESBSE     MOVE DIC REF OF BASED VARIABLE   54990015
         OI    PCL2+1,X'01'            CHANGE TO DIC REF OF SDV         55010015
         BAL   RR,GETWS                GET 8 BYTES OF WORD ALIGNED      55040015
         STH   BR,PCSTM2            WORKSPACE. STORE OFFSET IN STH      55110015
         STH   G1,PCLS5                SKELETON,OFFSET+4 IN STH         55180015
         MVC   PCSTM1(2),SCWSDR        MOVE WKS DIC.REF. INTO STH SKL   55250015
         SPACE                                                          55320015
         TM    PTDB+DESCDE,X'40'       TEST IF ADJUSTABLE               55390015
         BC    BO,LSUT49             BRANCH IF SO                       55460015
         SPACE                                                          55530015
         TM    UTBUF1,X'20'            TEST IF STRUCTURE MEMBER         55600015
         BC    BO,LSUT48             BRANCH IF SO                       55670015
         SPACE                                                          55740015
*        N-A , NOT STRUCTURE MEMBER                                     55810015
         SPACE                                                          55880015
         LA    RR,PCL                  POINT RR AT L SKELETON           56090015
         LA    BR,PCLL2                BR AT LENGTH OF L,L,STM,DROP     56160015
         BC    B,LSUT58                BRANCH TO CREATE SEQUENCE        56230015
         SPACE                                                          56300015
*        N-A , STRUCTURE MEMBER                                         56370015
         SPACE                                                          56440015
LSUT48   MVC   PCLM1(2),PCL2           MOVE DEC REF OF SKDV TO SKEL.    56510015
         MVC   PCA1(2),PCL1            MOVE IN POINTER DIC REF          56580015
         LA    RR,PCLM                 POINT RR AT LM SKELETON          56720015
         LA    BR,PCLML                LOAD BR WITH LENGTH              56790015
         STM   RR,BR,PAR1              STORE IN PAR1 AND PAR2           56860015
         BAL   RR,MV3                  PUT PSEUDO-CODE IN OUTPUT        56930015
         SPACE                                                          57000015
         LA    RR,PCSTM                POINT RR AT STM SKELETON         57070015
         LA    BR,PCSTML               LOAD BR WITH LENGTH              57140015
         BC    B,LSUT58                STORE IN PAR1 AND PAR2           57210015
*                                      MOVE TO OUTPUT                   57280015
         SPACE 2                                                        57350015
         SPACE                                                          57420015
*        ADJUSTABLE BASED  STRINGS                                      57490015
         SPACE                                                          57560015
LSUT49   LA    RR,PCL                  POINT RR AT LOAD SKELETON        57630015
         LA    BR,PCLL1                BR CONTAINS LENGTH               57700015
         STM   RR,BR,PAR1              MOVE FOLLOWING TO OUTPUT -       57770015
         BAL   RR,MV3                      L  SRE,POINTER               57840015
         SPACE                                                          57910015
         MVC   PCA1(2),PCL2            MOVE DIC REF OF SKDV TO SKEL     58010015
         MVC   PCLS1(2),PTDB+DESP      MOVE DIC REF OF LENGTH VARIABLE  58120015
         MVC   PCLS2(2),SCWSDR         FILL IN WORKSPACE DIC REF        58190015
         MVC   PCLS4(2),SCWSDR                                          58220015
         MVC   PCLS3(2),PCSTM2         AND OFFSET                       58260015
         LA    RR,PCLS                 ARRANGE RR,BR TO PUT OUT A SR,DV 58330015
         LA    BR,PCLSL1             L SRO,L  STM SRE,SRO,T STH SRO,T+4 58400015
         TM    UTBUF1,X'20'            TEST IF STRUCTURE MEMBER  IF IT  58470015
         BC    BNO,LSUT58            IS NOT THE FIRST ADD FROM THE D.V  58540015
         LA    RR,PCA                IS NOT REQUIRED                    58610015
         LA    BR,PCLSL2                                                58680015
         BC    B,LSUT58                MOVE SEQUENCE TO OUTPUT          58750015
         SPACE 2                                                        58820015
LSUT52   CLI   DEFLG(G1),CONDE                                          59300015
         BC    BE,LSUT63               BRANCH IF CONSTANT               59350015
         CLI   DEFLG(G1),X'C0'         TEST FOR SDV  ENTRY              59400015
         BC    BE,LSUT51               RETURN IF SO                     59450015
         BC    B,STERR                 OTHERWISE IT IS IN ERROR         59500015
LSUT63   OI    DCTYP(G1),X'02'         SET BIT IN DE FOR DOPE VECTOR    59550015
LSUT51   OI    PTDB+DESBSE+1,X'01'     SET LOW ORDER BIT IN DICT REF    59600015
         BC    B,LSUT62                                                 59700015
LSUT53   TM    PTDB+DESCDE,X'10'                                        59800015
         BC    BZ,STERR                BRANCH IF FIXED STRING           59900015
         LA    G1,8                                                     60000015
         BC    B,LSUT61                                                 60100015
LSUT54   BC    BN1,LSUT55              BRANCH IF SYMBOLIC REGISTER      60200015
*              TEMPORARY OFFSET TYPE.                                   60300015
         TM    PTDB+DESCDE,X'50'                                        60400015
         BC    BNE,LSUT59              BRANCH IF ADJUSTABLE OR VARYING  60500015
*              CREATE SDV DICT ENTRY FOR TEMP                           60600015
         MVC   DETSDV+DDVOFS+1(2),PTDB+DESBSE  PUT TEMP OFFSET IN DE    60700015
         MVC   DETSDV+DDVLNG(2),PTDB+DESP   PUT STRING LENGTH IN DE     60800015
         TM    PTDB+DESCDE,X'08'       TEST FOR PICTURE                 60810015
         BC    BO,LSUT57               BRANCH IF NOT                    60820015
         MVC   PAR1+2(2),PTDB+DESP     MOVE PICTURE REF.                60830015
         L     BR,ZDRFAB                                                60840015
         BALR  RR,BR                   CONVERT TO ABSOLUTE              60850015
         L     G1,PAR1                                                  60860015
         MVC   DETSDV+DDVLNG(2),DEPICW(G1)  LENGTH OF PICTURE           60870015
LSUT57   MVC   DETSDV+DDVDR(2),SCWSDR  MOVE IN DIC REF OF WORKSPACE     60880015
         LA    G1,DETSDV               POINT TO SDV SKELETON            60900015
         BAL   RR,DEAUVR               CREATE DICT ENTRY                61000015
         MVC   PTDB+DESBSE(2),PAR1+2   PUT NEW DICT REF IN DESCRIPTION  61100015
         MVI   PTDB+DESFLG,X'00'       CHANGE TO DICT REF TYPE          61200015
         BC    B,LSUT51                                                 61300015
*              SYMBOLIC REGISTER TYPE                                   61400015
LSUT55   TM    PTDB+DESFLG,X'40'                                        61500015
         BC    BZ,STERR                BRANCH IF REGISTER,BY VALUE      61600015
         TM    PTDB+DESCDE,X'50'                                        61700015
         BC    BNE,STERR               BRANCH IF ADJUSTABLE OR VARYING  61800015
         MVC   PCLA+PCOSM1(2),PTDB+DESP   SET UP  LA  G0,STRING.LENGTH  61900015
         TM    PTDB+DESCDE,X'08'                                        62000015
         BC    BO,LSUT56               BRANCH IF CODED TYPE             62100015
         MVC   PAR1+2(2),PTDB+DESP     PICTURE DICT REF                 62200015
         L     BR,ZDRFAB                                                62300015
         BALR  RR,BR                                                    62400015
         L     G1,PAR1                 ABSOLUTE ADDRESS OF PICTURE      62500015
         MVC   PCLA+PCOSM1(2),DEPICW(G1)  LENGTH OF STRING PICTURE      62600015
LSUT56   MVC   PCST+PCOD1(2),PTDB+DESBSE  SET UP  ST SR,T+0             62700015
         MVC   PCST+PCOD2(2),SCWSDR                                     62800015
         BAL   RR,GETWS                GET SDV WORKSPACE                62900015
         MVC   PCST+PCOSM1(2),PTDB+DESBSE                               63000015
         MVC   PCDRP+PCOD1(2),PCST+PCOD1   SET UP DROP SR               63100015
         STH   G1,UTBUF                                                 63200015
         MVC   PCSTH1+PCOD2(2),SCWSDR      SET UP STH  G0,T+4           63300015
         MVC   PCSTH1+PCOSM1(2),UTBUF                                   63400015
         LA    G1,2(G1)                BUMP TEMP                        63500015
         STH   G1,UTBUF                                                 63600015
         MVC   PCSTH2+PCOD2(2),SCWSDR      SET UP STH  G0,T+6           63700015
         MVC   PCSTH2+PCOSM1(2),UTBUF                                   63800015
         LA    RR,PCST                                                  63900015
         LA    BR,PCLN                                                  64000015
         TM    PTDB+DESFLG,X'08'                                        64100015
         BC    BZ,LSUT58               BRANCH IF DROP WANTED            64200015
         LA    BR,PCLN1                CHANGE LENGTH TO OMIT DROP       64300015
LSUT58   STM   RR,BR,PAR1              PC START AND LENGTH              64400015
         BAL   RR,MV3                       MOVE TRIPLES TO OUTPUT      64500015
         MVI   PTDB+DESFLG,X'C0'            SET DESCRIPTION TO TEMP     64600015
LSUT59   LA    G1,4                         RETURN OFFSET FOR TEMP CORE 64700015
LSUT61   A     G1,RGSAVE                                                64800015
         ST    G1,RGSAVE               BUMP RETURN ADDRESS              64900015
LSUT62   LA    G0,PTDB                                                  65000015
         ST    G0,PAR1                      POINT TO RESULT DESCRIPTION 65100015
LSUT60   LM    RR,DSR,RGSAVE           RESTORE REGISTERS                65200015
         BCR   B,RR                    RETURN TO CALLER                 65300015
STERR    EQU   LSUT60                  ERROR RETURN                     65400015
         EJECT                                                          65500015
*              DEAUVR SUBROUTINE CREATES A DICTIONARY ENTRY WITH THE    65600015
*              SKELETON POINTED AT BY REGISTER G1. THIS ENTRY IS PUT IN 65700015
*              THE AUTOMATIC CHAIN FOR THE CURRENT BLOCK. THE SYMBOLIC  65800015
*              DICT REF OF THE NEW ENTRY IS IN PAR1 ON EXIT.            65900015
*                                                                       66000015
DEAUVR   ST    RR,DEAVRR               SAVE RETURN REGISTER             66100015
         MVC   PAR1+2(2),SCBLK         SYMB ADDRESS OF CURRENT BLOCK    66200015
         L     BR,ZDRFAB               ENTRY TYPE 1.                    66300015
         BALR  RR,BR                   GET ABSOLUTE ADDRESS             66400015
         L     GRN,PAR1                                                 66500015
         MVC   DECHN(2,G1),DE1AUT(GRN)  PUT START OF AUT CHN IN NEW DE  66600015
         CLI   DEFLG(G1),X'8F'                                          66700015
         BC    BNE,DEAU1               BRANCH IF NOT BUY DICT ENTRY     66800015
         MVC   BUYLC(2,G1),DE1LC(GRN)  SET LEVEL AND COUNT              66900015
DEAU1    ST    G1,PAR1                 SKELETON ADDRESS                 67000015
         SR    BR,BR                                                    67100015
         ST    BR,PAR2                                                  67200015
         MVC   PAR2+2(2),DELNG(G1)     SET SKELETON LENGTH              67300015
         L     BR,ZDICRF                                                67400015
         BALR  RR,BR                   CREATE NEW DICT ENTRY            67500015
         MVC   DE1AUT(2,GRN),PAR1+2    UPDATE START OF AUTO CHAIN       67600015
         L     RR,DEAVRR                                                67700015
         BCR   B,RR                    RETURN                           67800015
         EJECT                                                          67900015
*              GETWS SUBROUTINE ALLOCATES 8 BYTES OF WORD               68000015
*        ALIGNED WORKSPACE FOR A STRING DOPE VECTOR. THE ALIGNED        68100015
*        WORKSPACE OFFSET IS RETURNED IN REGISTER BR AND PTDB+DESBSE.   68200015
*        THE OFFSET + 4 IS RETURNED IN REGISTER G1.                     68300015
         SPACE                                                          68400015
GETWS    LH    BR,SCWKS                CURRENT WS OFFSET                68500015
         LA    BR,3(BR)                ROUND UP                         68600015
         N     BR,F4                                                    68700015
         LA    G1,8(BR)                ADD 8 BYTES                      68800015
         STH   G1,SCWKS                NEW WORKSPACE COUNT              68900015
         LA    G1,4(BR)                                                 69000015
         STH   BR,PTDB+DESBSE                                           69100015
         BCR   B,RR                                                     69200015
         EJECT                                                          69300015
*              CONSTANTS.                                               69400015
         DS    0F                                                       69500015
F4       DC    X'FFFFFFFC'                                              69600015
DBMULT   DC    X'00351EB8'             DECIMAL-BINARY MULT 3.32         69700015
BDMULT   DC    X'0004D1BC'             BINARY-DECIMAL MULT 1/3.32       69800015
CEIL1    DC    X'000FFFFF'             ROUNDING-UP CONSTANT             69900015
SF0      DC    H'128'                  SCALE FACTOR BASE                70000015
FXMAXP   DC    H'31'                   MAXIMUM FIXED BIN PRECISION      70100015
H9       DC    H'9'                                                     70200015
H99      DC    H'99'                                                    70300015
MAXSTR   DC    H'255'                  MAX STRING LENGTH IN TEMP        70400015
NULBLK   DC    C'ZZ'                                                    70500015
         SPACE 2                                                        70600015
*              PSEUDO-CODE TO CREATE SDV IN TEMP CORE STACK FOR         70700015
*        BASED VARIABLE.                                                70800015
*        SKELETONS PCL TO PCSTM  ARE INEXTRICABLY INTERTWINED           70850015
         DS    0H                                                       70900015
         DC    AL1(0)                  PADDING                          70950015
PCL      DC    AL1(L)                  L                                71000015
         DC    X'7FEE'                 EVEN REGISTER OF PAIR            71050015
PCL1     DC    AL2(0)                  DIC REF OF POINTER               71100015
PCLL1    EQU   *-PCL                                                    71150015
         DC    AL1(L)                  L                                71200015
         DC    X'3FEE'                 ODD REGISTER OF PAIR             71250015
PCL2     DC    AL2(0)                  DIC REF OF SKDV                  71300015
         DC    AL1(OSM1)               OSM1                             71350015
         DC    AL2(4)                  OFFSET 4                         71400015
PCSTM    DC    AL1(STM)                STM                              71450015
         DC    X'7FEE'                 EVEN REGISTER OF PAIR            71500015
PCSTM1   DC    AL2(0)                  DIC REF OF WORKSPACE             71550015
         DC    AL1(OSM3)               OSM3                             71600015
PCSTM2   DC    AL2(0)                  OFFSET IN WORKSPACE              71650015
         DC    X'3FEE'                 ODD  REGISTER OF PAIR            71700015
         DC    AL1(DROP)               DROP                             71750015
         DC    X'7FEE'                 EVEN  REGISTER OF PAIR           71800015
         DC    AL1(DROP)               DROP                             71850015
         DC    X'3FEE'                 ODD   REGISTER OF PAIR           71900015
PCSTML   EQU   *-PCSTM                 LENGTH                           71950015
PCLL2    EQU   *-PCL                                                    72000015
         SPACE                                                          72050015
         DS    0H                                                       72100015
PCLM     DC    AL1(LM)                 LM                               72200015
         DC    X'7FEE'                 EVEN REGISTER OF PAIR            72250015
PCLM1    DC    AL2(0)                  DIC REF OF SKDV                  72300015
         DC    AL1(OSM3)               OSM3                             72350015
         DC    AL2(0)                  OFFSET FROM SKDV                 72400015
         DC    X'3FEE'                 ODD REGISTER OF PAIR             72450015
PCA      DC    AL1(A)                  A                                72500015
         DC    X'7FEE'                 EVEN REGISTER                    72550015
PCA1     DC    AL2(0)                  DIC REF OF POINTER /SKDV         72600015
PCLML    EQU   *-PCLM                                                   72650015
PCLS     DC    AL1(L)                  L                                72700015
         DC    X'3FEE'                 ODD REGISTER OF PAIR             72750015
PCLS1    DC    AL2(0)                  DIC REF OF LENGTH VARIABLE       72800015
         DC    AL1(STM)                STM                              72850015
         DC    X'7FEE'                 EVEN REG OF PAIR                 72900015
PCLS2    DC    AL2(0)                  DIC REF OF WORKSPACE             72950015
         DC    AL1(OSM3)               OSM3                             73000015
PCLS3    DC    AL2(0)                  WORKSPACE OFFSET                 73050015
         DC    X'3FEE'                 ODD REG OF PAIR                  73100015
         DC    AL1(STH)                STH                              73150015
         DC    X'3FEE'                 ODD REG OF PAIR                  73200015
PCLS4    DC    AL2(0)                  DIC REF OF WORKSPACE             73250015
         DC    AL1(OSM1)               OSM1                             73300015
PCLS5    DC    AL2(0)                  OFFSET ADD 4 TO PREVIOUS OFFSET  73350015
         DC    AL1(DROP)               DROP                             73400015
         DC    X'7FEE'                 EVEN REGISTER OF PAIR            73450015
         DC    AL1(DROP)               DROP                             73500015
         DC    X'3FEE'                 ODD REGISTER OF PAIR             73550015
PCLSL1   EQU   *-PCLS                                                   73600015
PCLSL2   EQU   *-PCA                                                    73650015
*              PSEUDO-CODE TO CREATE SDV IN TEMP CORE STACK             73900015
PCST     DC    AL1(ST)                 ST   SR,T+0                      74000015
         DC    AL4(0)                                                   74100015
         DC    AL1(OSM1)                                                74200015
         DC    AL2(0)                                                   74300015
PCLA     DC    AL1(LA)                 LA   G0,LENGTH                   74400015
         DC    X'80000000'                                              74500015
         DC    AL1(OSM1)                                                74600015
         DC    AL2(0)                                                   74700015
PCSTH1   DC    AL1(STH)                STH  G0,T+4                      74800015
         DC    AL4(0)                                                   74900015
         DC    AL1(OSM1)                                                75000015
         DC    AL2(0)                                                   75100015
PCSTH2   DC    AL1(STH)                STH  G0,T+6                      75200015
         DC    AL4(0)                                                   75300015
         DC    AL1(OSM1)                                                75400015
         DC    AL2(0)                                                   75500015
PCLN1    EQU   *-PCST                                                   75600015
PCDRP    DC    AL1(DROP)               DROP SR                          75700015
         DC    AL2(0)                                                   75800015
PCLN     EQU   *-PCST                                                   75900015
         SPACE 2                                                        76000015
*              TRIPLE SKELETONS.                                        76100015
TPASGN   DC    AL1(ASSGN)              ASSIGN   OO  SOURCE              76200015
         DC    AL4(0)                                                   76300015
         DC    AL1(TMPD)               TMPD                             76400015
         DC    AL4(0)                                                   76500015
         DC    AL1(TMPD)               TMPD                             76600015
         DC    AL4(0)                                                   76700015
         DC    AL1(TMPD)               TMPD                             76800015
         DC    AL4(0)                                                   76900015
         DC    AL1(TMPD)               TMPD                             77000015
         DC    AL4(0)                                                   77100015
         DC    AL1(TMPD)               TMPD                             77200015
         DC    AL4(0)                                                   77300015
         SPACE 2                                                        77400015
*              DICTIONARY ENTRY SKELETONS.                              77500015
DETSDV   DC    X'C0000C000000000000000000'  DOPE VECTOR FOR STRING TEMP 77600015
DEBUY    DC    X'8F001B000000000000000080'   BUY VARIABLE               77700015
         DC    X'00802800000000000000000000FFFF'                        77800015
         SPACE 2                                                        77900015
*              WORKSPACE.                                               78000015
DEAVRR   DC    F'0'                                                     78100015
STDB     DC    5H'0'                   SOURCE DESCRIPTION BUFFER        78200015
TTDB     DC    5H'0'                   TARGET DESCRIPTION BUFFER        78300015
PTDB     EQU   STDB                    STRUT2 DESCRIPTION BUFFER        78400015
UTBUF    DC    H'0'                    BUFFER                           78500015
UTBUF1   DC    X'0'                    BUFFER                           78600015
FLAG     DC    X'0'                                                     78700015
         SPACE 5                                                        78800015
DECON    DC    X'88000E000000000001'   PARTIAL SKEL FOR CONSTANT D.E.   78900015
         ORG   IEMLV+X'845'                                       33905 78950000
         EJECT                                                          79000015
*              LAYOUT OF SCAN PARAMETER BLOCK.                          79100015
SCTRT    EQU   4096+NAME                                                79200015
*              BEGINNING OF FULL-WORD ITEMS                             79300015
SCEOBI   EQU   SCTRT+256               ABSOLUTE ADRESS OF END OF IP BLK 79400015
SCEOBO   EQU   SCEOBI+4                ABSOLUTE ADRESS OF END OF OP BLK 79500015
SCJMP    EQU   SCEOBO+4                SYMBOLIC POSITION OF JMP TRIPLE  79600015
SCPCG    EQU   SCJMP+4                 COUNT OF PSEUDOCODE GENERATED    79700015
SCTXTI   EQU   SCPCG+4                 SYMB NAME OF IP BLOCK IN BYTE 2  79800015
SCTXTO   EQU   SCTXTI+4                SYMB NAME OF OP BLOCK IN BYTE 2  79900015
SCWKSC   EQU   SCTXTO+4                CURRENT WORKSPACE COUNT          80000015
SCWKS    EQU   SCWKSC                                                   80100015
*              END OF FULL-WORD ITEMS                                   80200015
SCBLK    EQU   SCWKSC+4                DICT REFERENCE OF CURRENT BLOCK  80300015
SCSTK    EQU   SCBLK+2                 CURRENT REGISTER USAGE           80400015
SCWSDR   EQU   SCSTK+2                 DICT REF OF CURRENT WORKSPACE    80500015
*              END OF 2-BYTE ITEMS                                      80600015
SCOPT    EQU   SCWSDR+2                PRE-FIX OPTION BYTE              80700015
*              END OF 1-BYTE ITEMS                                      80800015
*              DICTIONARY COMMUNICATIONS REGION.                        80900015
D        EQU   4096+SCTRT                                               81000015
ZMYNAM   EQU   D+112                   NAME OF CURRENT PHASE            81100015
ZSTAT    EQU   D+126                   CURRENT STATEMENT NUMBER         81200015
PAR1     EQU   D+128                                                    81300015
PAR2     EQU   D+132                                                    81400015
PAR5     EQU   D+144                                                    81500015
PAR6     EQU   D+148                                                    81600015
PAR7     EQU   D+152                                                    81700015
PAR8     EQU   D+156                                                    81800015
ZDROLF   EQU   D+186                   FLAG=X'FF' TO HALT CONT ROUTINES 81900015
*                                    PHASE SCAN POINTER AT PHASE LV     82000015
CCCODE   EQU   D+232                   CODE BYTE FOR DECK PUNCH         82100015
STEXT    EQU   D+256                                                    82200015
ZTEXT    EQU   D+256                                                    82300015
ZTBSZE   EQU   D+264                                                    82400015
ZCOMM    EQU   D+304                   BASE OF PHASE COMMOM             82500015
ZSTUT1   EQU   ZCOMM+24                TRANSFER VECTOR TO STRUT1        82600015
ZSMREG   EQU   ZCOMM+40                CURRENT SYMBOLIC REGISTER NUMBER 82700015
Z2FILE   EQU   ZCOMM+44                                                 82800015
ZSTACH   EQU   ZCOMM+68                START OF STATIC CHAIN            82900015
ZCONCH   EQU   ZCOMM+78                BEGINNING OF CONSTANT CHAIN      83000015
ZEQMAX   EQU   ZCOMM+82                CURRENT COMPILER LABEL           83100015
ZOSMRG   EQU   ZCOMM+84                HIGHEST OPTIMISING SYMBOLIC REG  83200015
ZSTUT2   EQU   ZCOMM+88                TRANSFER VECTOR TO STRUT2        83300015
*                       TRANSFER VECTORS TO CONTROL PHASE (BASE = CTVR) 83400015
Z        EQU   4096+D                                                   83500015
ZUGC     EQU   Z+16                    ALLOCATE SCRATCH CORE            83600015
ZUTXTC   EQU   Z+20                    GET NEXT TEXT BLOCK              83700015
ZURC     EQU   Z+24                    RELEASE SCRATCH CORE             83800015
ZABORT   EQU   Z+32                    DUMP AND STOP                    83900015
ZLOAD    EQU   Z+36                    LOAD PHASE AND RETURN TO CALLER  84000015
ZDICRF   EQU   Z+44                    MAKE ENTRY IN DICTIONARY         84100015
ZUERR    EQU   Z+48                    ERROR MESSAGE                    84200015
ZDRFAB   EQU   Z+52                    CONTROL COMMS. OFFSET            84300015
ZDUMP    EQU   Z+56                                                     84400015
ZUDUMP   EQU   Z+56                    DUMP                             84500015
RLSCTL   EQU   Z+72                    RELEASE PHASES AND GO TO NEXT    84600015
ZTXTRF   EQU   Z+80                    TEXT ABS ADDRESS TO SYMBOLIC     84700015
ZTXTAB   EQU   Z+84                    TEXT SYMBOLIC ADDRESS TO ABS     84800015
ZCHAIN   EQU   Z+88                    GET NEXT TEXT BLOCK IN CHAIN     84900015
ZALTER   EQU   Z+92                    ALTER STATUS OF TEXT BLOCK       85000015
ZDABRF   EQU   Z+96                    DICT ABS ADDRESS TO SYMBOLIC     85100015
         SPACE 2                                                        85200015
SC       EQU   4096+Z                  TRANSFER VECTORS TO SCAN         85300015
SCINIT   EQU   SC                                                       85400015
SC1      EQU   4+SCINIT                                                 85500015
SC2      EQU   4+SC1                                                    85600015
SC3      EQU   4+SC2                                                    85700015
SC4      EQU   4+SC3                                                    85800015
SC5      EQU   4+SC4                                                    85900015
SC6      EQU   4+SC5                                                    86000015
SC7      EQU   4+SC6                                                    86100015
SC8      EQU   4+SC7                                                    86200015
SC9      EQU   4+SC8                                                    86300015
SC10     EQU   4+SC9                                                    86400015
SC10A    EQU   4+SC10                                                   86500015
SCNERR   EQU   4+SC10A                                                  86600015
MV1      EQU   4+SCNERR                                                 86700015
MV2      EQU   4+MV1                                                    86800015
MV3      EQU   4+MV2                                                    86900015
MV3A     EQU   4+MV3                                                    87000015
MV4      EQU   4+MV3A                                                   87100015
         END   IEMLV                                                    87200015
