MB       TITLE 'IEMMB, PSEUDO-VARIABLES AND MULTIPLE ASSIGNMENT, PSEUDOC00040013
               -CODE GENERATION, OS/360 PL/I COMPILER(F)'               00080013
*              STATUS - CHANGE LEVEL 0                                  00120013
*                                                                       00160013
* R20    258600 466000,* 926800,*                                A32295 00170020
* R20  257500  882000                                             32295 00180020
* ###  514580,*               ### - SEE ID#                       40099 00190046
*                                                                       00200013
*                                                                       00240013
*              FUNCTIONS - (1) SCANS INPUT TEXT ONCE AND CREATES        00280013
*        NEW TEXT STRING.                                               00320013
*                          (2) REMOVES FROM THE TEXT THE FOLLOWING      00360013
*        TRIPLES-                                                       00400013
*                                  3A  PSI       PSEUDO-VARIABLE.       00440013
*                                  7A  PSI'      PSEUDO-VARIABLE'.      00480013
*                          (3) GENERATES ADDITIONAL TEXT IN THE FORM    00520013
*        OF TRIPLES OR PSEUDO-CODE TO REPLACE THE PSEUDO-VARIABLE       00560013
*        MARKERS. THE NATURE OF THIS TEXT IS DESCRIBED IN DETAIL IN     00600013
*        THE APPROPRIATE SECTIONS OF BLOCK IEMMC.                       00640013
*                          (4) REORDERS TEMPORARY RESULT DESCRIPTIONS   00680013
*        IN SEQUENCES OF MULTIPLE ASSIGNMENTS SO THAT ASSIGNMENTS       00720013
*        ARE EFFECTED IN THE CORRECT SEQUENCE.                          00760013
*                                                                       00800013
*                                                                       00840013
*                                                                       00880013
*              ENTRY POINTS - (1) FROM COMPILER CONTROL. THE MODULE     00920013
*        BASE IS LOADED, BLOCK IEMMC LOADED, THE SCAN ROUTINE           00960013
*        INITIALIZED, AND A 4K BYTE BLOCK OF SCRATCH CORE OBTAINED      01000013
*        FOR STACKING PURPOSES.                                         01040013
*                             (2) MMV35  SUBROUTINE TO MOVE 5 BYTES OF  01080013
*        PSEUDO-CODE TO OUTPUT.                                         01120013
*                             (3) MMV3U  MOVES A SPECIFIED NUMBER OF    01160013
*        BYTES OF PSEUDO-CODE TO OUTPUT.                                01200013
*                             (4) MMV3A5 SUBROUTINE TO MOVE 5 BYTE      01240013
*        TRIPLE TO OUTPUT.                                              01280013
*                             (5) MMV3AU MOVES A SPECIFIED LENGTH OF    01320013
*        TRIPLE TEXT TO OUTPUT.                                         01360013
*                             (6) OUTMPD CONSTRUCTS TWO OR THREE TMPDS  01400013
*        FROM THE INTERNAL 11 BYTE TMPD AND PLACES THEM IN THE OUTPUT.  01440013
*                             (7) ARGTMP CONSTRUCTS AN INTERNAL 11      01480013
*        BYTE TMPD TO DESCRIBE A PSEUDO-VARIABLE ARGUMENT.              01520013
*                             (8) DRFTMP CONSTRUCTS AN INTERNAL 11      01560013
*        BYTE TMPD GIVEN A DICTIONARY REFERENCE.                        01600013
*                             (9) GETWKS ALLOWS SPACE IN THE WORKSPACE  01640013
*        STACK OF THE CURRENT STATEMENT FOR CONVERSION OF SOURCE TO     01680013
*        PSEUDO-VARIABLE TARGET TYPE.                                   01720013
*                            (10) DROP1  DROPS REGISTERS ASSOCIATED     01760013
*        WITH A GIVEN TMPD IF THE DROP SWITCH IS ON, I.E. FOR OTHER     01800013
*        THAN A MULTIPLE ASSIGNMENT SOURCE.                             01840013
*                            (11) DROP2  DROPS REGISTERS ASSOCIATED     01880013
*        WITH A GIVEN TMPD.                                             01920013
*                            (12) ERROR  MAKE ERROR ENTRY.              01960013
*                            (13) CADNFL GIVEN A TMPD DESCRIBING AN     02000013
*        ARITHMETIC DATUM, RETURNS THE LENGTH OF THE DATUM IF REAL, OR  02040013
*        THE LENGTH OF THE REAL PART IF COMPLEX.                        02080013
*                            (14) TARGET CONVERTS AN ASSIGNMENT SOURCE  02120013
*        TO THE TYPE SPECIFIED FOR THE PSEUDO-VARIABLE TARGET           02160013
*                            (15) OUTRIP COPIES THE CURRENT INPUT TEXT  02200013
*        TRIPLE (WHICH MAY BE ASSIGN OR COMMA), AND, IF ASSIGN, ALSO    02240013
*        COPIES INTO THE OUTPUT TRIPLES DESCRIBING THE RIGHT-HAND-SIDE. 02280013
*                            (16) CHECKW CHECKS THAT THE WORKSPACE      02320013
*        COUNT HAS NOT EXCEEDED THE MAXIMUM.                            02360013
*                                                                       02400013
*                                                                       02440013
*                                                                       02480013
*              INPUT - DICTIONARY AND OUTPUT TEXT FROM PREVIOUS PHASE.  02520013
*        TEXT DESCRIBING PSEUDO-VARIABLES IS ASSUMED TO HAVE THE        02560013
*        FOLLOWING STANDARD FORM -                                      02600013
*                                                                       02640013
*        PSI       DICT.REF  --        DICT REF IS LIBRARY ROUTINE (C2) 02680013
*                                    OR BUILT IN FUNCTION (04) ENTRY    02720013
*                                    WITH VARIABLES CODE BYTE IN BYTE 7 02760013
*        ***********                                                    02800013
*        TRIPLES DESCRIBING AN ARGUMENT     THE SECTION BETWEEN THE     02840013
*        BUY-ASSIGN OR IGNORE TRIPLE      ASTERISKS IS REPEATED FOR     02880013
*        DOUBLE COMMA  --    DICT.REF/00  EACH PSEUDO-VARIABLE          02920013
*        TMPDS FOR RESULT IF 00           ARGUMENT.                     02960013
*        ***********                                                    03000013
*        PSI'      DICT.REF  --        DICT REF OF ORIGINAL BUILT-IN    03040013
*                                    OR GENERIC BUILT-IN (06) ENTRY.    03080013
*        TMPD      RESULT TYPE         TMPDS DESCRIBE RESULT TYPE OF    03120013
*        TMPD                        THE CORRESPONDING FUNCTION (THESE  03160013
*                                    ARE SUPPLIED BY THE GENERIC PHASE) 03200013
*              THE CONTENTS OF THE RESULT TMPD ARE                      03240013
*        COMPLEX                       COMPLEX. HIGHER TYPE OF THE      03280013
*                                    TWO ARGUMENTS.                     03320013
*        EVENT                         STRING. BIT, LENGTH 1, FIXED     03360013
*        IMAG                          REAL. SAME TYPE AS ARGUMENT      03400013
*                                    WHEN CONVERTED TO ARITHMETIC       03440013
*        ONCHAR                        STRING. CHARACTER ADJ. VARYING   03480013
*        ONSOURCE                      STRING. CHARACTER ADJ. VARYING   03520013
*        PRIORITY                      REAL FIXED BINARY (15,0)         03560013
*        REAL                          REAL. SAME TYPE AS ARGUMENT      03600013
*                                    WHEN CONVERTED TO ARITHMETIC       03640013
*        SUBSTR                        STRING. ADJ. VARYING, BIT OR     03680013
*                                    CHAR ACCORDING TO FIRST ARGUMENT   03720013
*        UNSPEC                        STRING. ADJ. VARYING BIT.        03760013
*                                                                       03800013
*              THE POINT AT WHICH THE PSEUDO-VARIABLE IS ACTUALLY USED  03840013
*        IS ALSO DESCRIBED BY A 00 ARGUMENT ASSOCIATED WITH A SPECIAL   03880013
*        TRIPLE PAIR  LEFT-TMPD IN WHICH OPERAND 1 OF THE LEFT IS 00FF. 03920013
*                                                                       03960013
*        TEXT  DESCRIBING MULTIPLE ASSIGNMENTS IS ASSUMED TO HAVE THE   04000013
*        FOLLOWING STANDARD FORM-                                       04040013
*        ***********                                                    04080013
*        MULTIPLE   DICT.REF/00  DICT.REF/00      THE SECTION BETWEEN   04120013
*          ASSIGN                                 ASTERISKS IS REPEATED 04160013
*        TMPD/LEFT  TARGET TYPE IF OPERAND 1 OF   FOR EACH TARGET AFTER 04200013
*        TMPD         MULTIPLE ASSIGN IS 00       THE FIRST.            04240013
*        ***********                                                    04280013
*        SIMPLE     DICT.REF/00  DICT.REF/00                            04320013
*          ASSIGN                                                       04360013
*        TMPD/LEFT  SOURCE TYPE IF OPERAND 2 OF                         04400013
*        TMPD         ASSIGN IS 00                                      04440013
*        TMPD/LEFT  TARGET TYPE IF OPERAND 1 OF                         04480013
*        TMPD         ASSIGN IS 00                                      04520013
*              THE OPERAND 2 FIELD IS THE SAME FOR EACH ASSIGN MARKER.  04560013
*        IF OPERAND 1 IS A DICTIONARY REFERENCE THEN IT IS IN THE       04600013
*        CORRECT POSITION IN THE SEQUENCE. IF IT IS 00 THEN THE         04640013
*        ASSOCIATED TMPD IS THAT OBTAINED BY REASSIGNING THE TMPDS IN   04680013
*        REVERSE ORDER.                                                 04720013
*                                                                       04760013
*                                                                       04800013
*                                                                       04840013
*              OUTPUT - DICTIONARY WITH, POSSIBLY, LIBRARY FUNCTION,    04880013
*        ERROR MESSAGE, CONSTANT AND TEMPORARY STRING DOPE VECTORS      04920013
*        ADDED.                                                         04960013
*                       NEW TEXT STRING WITH TRIPLES LISTED IN THE      05000013
*        FUNCTIONS PARAGRAPH DELETED. THE OUTPUT FOR EACH PSEUDO-       05040013
*        VARIABLE IS DESCRIBED IN DETAIL IN IEMMC. THE OUTPUT FOR       05080013
*        MULTIPLE ASSIGNMENTS IS A REORDERING OF THE INPUT SO THAT      05120013
*        TMPD OR LEFT DESCRIPTIONS OF THE RIGHT HAND SIDE ARE REPEATED  05160013
*        AFTER EVERY ASSIGNMENT, AND DESCRIPTIONS OF THE LEFT HAND      05200013
*        SIDES APPEAR IN THE CORRECT SEQUENCE.                          05240013
*                                                                       05280013
*                                                                       05320013
*                                                                       05360013
*              EXTERNAL ROUTINES - (1) ZDRFOF. COMPILER CONTROL         05400013
*        ROUTINE TO MAKE A DICTIONARY ENTRY.                            05440013
*                                  (2) ZLDWOF. COMPILER CONTROL PHASE   05480013
*        LOADING ROUTINE.                                               05520013
*                                  (3) ZRFAOF. COMPILER CONTROL         05560013
*        DICTIONARY REFERENCE TO ABSOLUTE ADDRESS.                      05600013
*                                  (4) ZRLSOF. COMPILER CONTROL         05640013
*        RELEASE CONTROL.                                               05680013
*                                  (5) ZTXROF. COMPILER CONTROL         05720013
*        ABSOLUTE ADDRESS TO SYMBOLIC TEXT REFERENCE                    05760013
*                                  (6) ZUEROF. COMPILER CONTROL         05800013
*        ERROR ENTRY ROUTINE                                            05840013
*                                  (7) ZUGCOF. COMPILER CONTROL         05880013
*        ROUTINE TO OBTAIN SCRATCH CORE.                                05920013
*                                  (8) ZURCOF. COMPILER CONTROL         05960013
*        ROUTINE TO RELEASE SCRATCH CORE.                               06000013
*                                  (9) SCINIT. SCAN PHASE ROUTINE TO    06040013
*        PERFORM INITIALIZATION FOR THIS PHASE                          06080013
*                                  (10) SC1    SCAN PHASE ROUTINE       06120013
*        WHICH SCANS FROM THE CURRENT TRIPLE AND RETURNS CONTROL ON     06160013
*        THE FIRST TRIPLE OF INTEREST,HAVING MOVED INTERVENING TEXT     06200013
*                                 (11) SC2     SCAN PHASE ROUTINE       06240013
*        PERFORMING THE SAME FUNCTION AS SC1 EXCEPT THAT CURRENT        06280013
*        TRIPLE IS MOVED TO OUTPUT WITHOUT EXAMINATION.                 06320013
*                                 (12) SC3     SCAN PHASE ROUTINE       06360013
*        PERFORMING THE SAME FUNCTION AS SC1 EXCEPT THAT THE CURRENT    06400013
*        TRIPLE IS DELETED.                                             06440013
*                                 (13) SC4     SCAN PHASE ROUTINE       06480013
*        WHICH SETS THE INPUT POINTER TO ADDRESS THE NEXT TRIPLE, BUT   06520013
*        DOES NOT FREE THE CURRENT TRIPLE                               06560013
*                                 (14) SC5     SCAN ROUTINE PERFORMING  06600013
*        SAME FUNCTION AS SC4 EXCEPT THAT THE CURRENT TRIPLE IS FREED.  06640013
*                                 (15) SC10    SCAN PHASE ROUTINE TO    06680013
*        CONVERT SYMBOLIC TEXT POINTER TO ABSOLUTE.                     06720013
*                                 (16) SC10A   SCAN PHASE ROUTINE TO    06760013
*        IGNORE A PSEUDO-CODE BLOCK.                                    06800013
*                                 (17) MV3     SCAN PHASE ROUTINE TO    06840013
*        MOVE PSEUDO-CODE STRINGS INTO OUTPUT TEXT.                     06880013
*                                 (18) MV3A    SCAN PHASE ROUTINE TO    06920013
*        MOVE TRIPLE TEXT STRINGS INTO OUTPUT.                          06960013
*                                 (19) MB9000. IN BLOCK IEMMC.          07000013
*        GENERATES CODE FOR EVENT PSEUDO-VARIABLE.                      07040013
*                                 (20) MB9100. IN BLOCK IEMMC.          07080013
*        GENERATES CODE FOR ONCHAR PSEUDO-VARIABLE.                     07120013
*                                 (21) MB9200. IN BLOCK IEMMC.          07160013
*        GENERATES CODE FOR ONSOURCE PSEUDO-VARIABLE.                   07200013
*                                 (22) MB9300. IN BLOCK IEMMC.          07240013
*        GENERATES CODE FOR PRIORITY PSEUDO-VARIABLE.                   07280013
*                                 (23) MB9400. IN BLOCK IEMMC.          07320013
*              GENERATES CODE FOR COMPLEX PSEUDO-VARIABLE               07360013
*                                 (24) MB9500. IN BLOCK IEMMC.          07400013
*              GENERATES CODE FOR IMAG PSEUDO-VARIABLE.                 07440013
*                                 (25) MB9600. IN BLOCK IEMMC.          07480013
*              GENERATES CODE FOR REAL PSEUDO-VARIABLE.                 07520013
*                                 (26) MB9700. IN BLOCK IEMMC.          07560013
*              GENERATES CODE FOR UNSPEC PSEUDO-VARIABLE.               07600013
*                                 (27) MB9800. IN BLOCK IEMMC.          07640013
*              GENERATES CODE FOR SUBSTR PSEUDO-VARIABLE.               07680013
*                                      (28) MB1000. IN BLOCK IEMMC.     07690046
*              GENERATES CODE FOR STRING PSEUDO-VARIABLE.               07700046
*                                                                       07720013
*                                                                       07760013
*                                                                       07800013
*              EXITS - NORMAL - MB0010 ENTERED UPON RECOGNITION OF      07840013
*        END-OF-TEXT MARKER.                                            07880013
*                                                                       07920013
*                                                                       07960013
*                                                                       08000013
*              EXITS -ERROR- MBABT2.  TERMINATION OF COMPILATION        08040013
*        OWING TO- (1) INVALID RETURN FROM SCAN                         08080013
*                  (2) INVALID INPUT TO GETWKS ROUTINE.                 08120013
*                                                                       08160013
*                                                                       08200013
*                                                                       08240013
*              TABLES/WORKAREAS.- ONE TABLE, IN IEMMB, IS USED IN       08280013
*        CONJUNCTION WITH SCAN. IT IS USED TO SCAN FOR PSI, PSI' AND    08320013
*        MULTIPLE ASSIGNMENT MARKERS, TOGETHER WITH THOSE TRIPLES SUCH  08360013
*        AS STATEMENT LABELS WHICH SCAN MUST IN ANY CASE EXAMINE.       08400013
*        DURING THE SCAN OF PSEUDO-VARIABLE ARGUMENT TEXT, I.E. IN THE  08440013
*        REGION BETWEEN PSI AND PSI' MARKERS A SCAN IS ALSO MADE FOR    08480013
*        FUNCTION, BUY/ASSIGN, IGNORE, DOUBLE COMMA AND SUCH OTHER      08520013
*        TRIPLES AS GO TO THE DEFITION OF PSEUDO-VARIABLE ARGUMENT.     08560013
*              AFTER PSI OR MULTIPLE ASSIGN A SCAN IS ALSO MADE FOR     08600013
*        SIMPLE ASSIGN.                                                 08640013
*                                 ONE WORKAREA, A 4K BYTE BLOCK OF      08680013
*        SCRATCH CORE, IS USED THROUGHOUT THE PHASE TO STACK PSEUDO-    08720013
*        VARIABLE MARKERS AND 11 BYTE INTERNAL TEMPORARY RESULT         08760013
*        DESCRIPTORS, OR DOUBLE COMMA TRIPLES. ENTRIES MAY THUS HAVE    08800013
*        ONE OF THE FOLLOWING FIVE FORMS-                               08840013
*                  (1) 3A (PSI) FOLLOWED BY ONE BYTE DEFINING THE       08880013
*        PSEUDO-VARIABLE                                                08920013
*                  (2) 58 (TMPD) FOLLOWED BY 10 BYTES WITH SAME FORMAT  08960013
*                      68     AS OPERANDS OF 3 TMPD SEQUENCE. 00 IS A   09000013
*                      00     PRIVATE CODE FOR ARITH, LABEL OR FILE     09040013
*                             CONSTANT.                                 09080013
*                  (3) 42 (DOUBLE COMMA) FOLLOWED BY 4 BYTES, THE LAST  09120013
*                             TWO OF WHICH CONTAIN A DICTIONARY REF.    09160013
*                  (4) 7A (PSI') FOLLOWED BY 11 BYTE TEMPORARY          09200013
*                             DESCRIPTION OF PSEUDO-VARIABLE TARGET     09240013
*                             AS PROVIDED BY THE GENERIC PHASE          09280013
*                  (5) AC (SELL) FOLLOWED BY FOUR BYTES. A SELL TRIPLE  09320013
*        FOUND FOLLOWING A PSI' MARKER                                  09360013
*        TWO ADDRESS SLOTS AND TWO REGISTERS ARE USED DURING THE USE    09400013
*        OF THIS WORKAREA- (1) DURING CONSTRUCTION OF THE STACK, STKR   09440013
*        ADDRESSES THE NEXT FREE BYTE AND STKLHS CONTAINS THE ADDRESS   09480013
*        OF THE RIGHT HAND SIDE DESCRIPTOR, IF ANY.                     09520013
*                          (2) DURING REMOVAL OF ENTRIES FROM THE       09560013
*        STACK, STKR ADDRESSES THE NEXT LEFT HAND SIDE DESCRIPTOR TO    09600013
*        BE USED, PSVR ADDRESSES THE NEXT PSEUDO-VARIABLE ARGUMENT.     09640013
*        STKLHS CONTAINS THE ADDRESS OF THE RIGHT HAND SIDE DESCRIPTOR  09680013
*        EITHER IN THE STACK OR CONSTRUCTED IF IT IS A DICTIONARY REF.  09720013
*        PSVNXT CONTAINS THE ADDRESS OF THE NEXT PSEUDO VARIABLE ENTRY  09760013
*                                                                       09800013
*                                                                       09840013
*                                                                       09880013
*              ATTRIBUTES - NONREUSABLE                                 09920013
*                                                                       09960013
*                                                                       10000013
*                                                                       10040013
*              NOTES (1) THIS PHASE REQUIRES NO MODIFICATION AS A       10080013
*        RESULT OF CHANGES IN THE INTERNAL REPRESENTATION OF EXTERNAL   10120013
*        GRAPHICS.                                                      10160013
*                    (2) REFERENCES TO EXTERNAL ROUTINES AND THE        10200013
*        COMMUNICATIONS REGION ARE MADE BY MEANS OF RELOCATABLE         10240013
*        SYMBOLS OBTAINED BY A SUITABLE COMBINATION OF OFFSET           10280013
*        DEFINITIONS AND USING STATEMENTS.                              10320013
*                    (3) REGISTER USAGE.                                10360013
*        BASRG1. PHASE BASE AND SCAN ROUTINE PARAMETER BLOCK POINTER.   10400013
*        BASRG2. BASE FOR BLOCK IEMMC                                   10440013
*        SCNBAS. BASE OF SCAN PHASE (IEMLA)                             10480013
*        CONBAS. BASE OF COMPILER CONTROL AREA                          10520013
*        DICBAS. BASE OF COMMUNICATIONS REGION                          10560013
*        IPTR    INPUT TEXT POINTER                                     10600013
*        TRTR    RESULT REGISTER RETURNED BY SCAN ROUTINES              10640013
*        RR      RETURN REGISTER FOR SUBROUTINE CALLS                   10680013
*        LR      LINK REGISTER FOR EXTERNAL ROUTINE CALLS               10720013
*        STKR    STACK POINTER                                          10760013
*        PSVR    CURRENT PSEUDO-VARIABLE STACK ENTRY POINTER            10800013
*        R1,R2   SUBROUTINE ARGUMENT REGISTERS                          10840013
*        HR0-2   WORK REGISTERS                                         10880013
*                    (4) TECHNIQUES.                                    10920013
*              THE STACK,WHOSE INDIVIDUAL ITEMS WERE DESCRIBED UNDER    10960013
*        WORKAREAS,HAS THE FOLLOWING GENERAL FORM-                      11000013
*                                                                       11040013
*              PSI                                                      11080013
*              DOUBLE COMMA OR 11 BYTE      THIS SECTION IS REPEATED    11120013
*                  TEMPORARY ENTRIES      ONCE FOR EACH PSEUDO-VBLE     11160013
*                  FOR EACH ARGUMENT      INVOLVED IN THE ASSIGNMENT    11200013
*              PSI'                                                     11240013
*              PSEUDO-VBLE RESULT TMPD                                  11280013
*                                                                       11320013
*              RIGHT HAND SIDE TMPD         STKLHS CONTAINS THE ADDRESS 11360013
*                  DESCRIPTION IN AN      OF THIS ENTRY AT THE START OF 11400013
*                  INTERMEDIATE RESULT    THE UNSTACKING PROCESS        11440013
*                                                                       11480013
*              LEFT HAND SIDE  TMPD         THIS SECTION CONTAINS AN    11520013
*                  DESCRIPTIONS IF PSEUDO  ENTRY FOR EACH TARGET WHICH  11560013
*                  VARIABLES OR SUBSCRIPTS REQUIRES A TMPD. THEIR ORDER 11600013
*                                          IS THE REVERSE OF THE SOURCE 11640013
*                                          STATEMENT ORDER. AT END OF   11680013
*                                          STACKING STKR ADDRESSES NEXT 11720013
*                                          FREE BYTE                    11760013
*              DURING UNSTACKING I.E. CODE GENERATION PSVR SCANS        11800013
*        FORWARDS THROUGH THE PSEUDO VARIABLE DEFINITIONS AND STKR      11840013
*        SCANS BACKWARDS THROUGH THE LEFT HAND SIDE DESCRIPTIONS.       11880013
*              THE STACKING AND UNSTACKING IS PERFORMED BY TWO SCANS    11920013
*        OF THE TEXT IN THE NEIGHBOURHOOD OF A MULTIPLE OR PSEUDO-      11960013
*        VARIABLE ASSIGNMENT, THE FIRST TO STACK TMPDS, AND THE SECOND  12000013
*        TO GENERATE ASSIGNMENTS IN THE CORRECT SEQUENCE.               12040013
*              PSEUDO-VARIABLE INPUT TEXT, I.E. THE TEXT BETWEEN PSI    12080013
*        AND PSI' MARKERS IS TREATED IN A SPECIAL MANNER BY SETTING UP  12120013
*        ADDITIONAL EXIT CODES IN THE SCAN TRANSLATE TABLE. THESE       12160013
*        EXITS ARE FOR IGNORE, BUY/ASSIGN, FUNCTION AND FUNCTION'. THE  12200013
*        LATTER PAIR SERVE MERELY TO KEEP A LEVEL COUNT SO THAT THE     12240013
*        FORMER CAN BE IGNORED EXCEPT AT THE TOP LEVEL, WHEN THEY MARK  12280013
*        PSEUDO-VARIABLE ARGUMENTS. THE ARGUMENT ARE PLACED IN THE      12320013
*        STACK EITHER IN THE SAME FORM AS THE INPUT DOUBLE COMMA TRIPLE 12360013
*        OR AS AN 11 BYTE TMPD IF THE ARGUMENT IS NOT A SIMPLE DICT.    12400013
*        REF. WHEN GENERIC HAS INTRODUCED A BUY/ASSIGN AND THE          12440013
*        ARGUMENT IS NOT AN INDEX (AS SUBSTR ARGUMENTS 2 AND 3), THE    12480013
*        ORIGINAL ARGUMENT IS USED AND THE BUY/ASSIGN DROPPED.          12520013
         EJECT                                                          12560013
IEMMB    START 0                                                        12600013
         PRINT NODATA                                                   12640013
*                       DEFINITIONS OF SYMBOLS                          12680013
         SPACE 1                                                        12720013
*        GENERAL PURPOSE REGISTER NAMES AND USE                         12760013
BASRG1   EQU   3                       BASE REGISTER AND SCAN PARAMETER 12800013
*                                    BLOCK POINTER                      12840013
BASRG2   EQU   9                       BASE OF SECOND BLOCK             12880013
IPTR     EQU   1                       INPUT TEXT POINTER               12920013
TRTR     EQU   2                       RESULT REGISTER RETURNED BY SCAN 12960013
*                                    ROUTINES                           13000013
RR       EQU   14                      RETURN REGISTER                  13040013
LR       EQU   15                      LINK REGISTER                    13080013
CONBAS   EQU   11                      COMPILER CONTROL BASE            13120013
DICBAS   EQU   13                      DICTIONARY BASE                  13160013
SCNBAS   EQU   12                      BASE OF SCAN TRANSFER VECTOR     13200013
STKR     EQU   4                       STACK POINTER                    13240013
PSVR     EQU   10                      POINTER TO CURRENT  PSEUDO-      13280013
*                                    VARIABLE DESCRIPTION               13320013
HR0      EQU   0                       WORK REGISTER 0                  13360013
HR1      EQU   5                                     1                  13400013
HR2      EQU   6                                     2                  13440013
R1       EQU   7                       PARAMETER REG 1                  13480013
R2       EQU   8                       PARAMETER REG 2                  13520013
         SPACE 1                                                        13560013
*        BRANCH MNEMONIC DEFINITIONS                                    13600013
B        EQU   15                      BRANCH                           13640013
NOP      EQU   0                       NO-OP                            13680013
         SPACE 1                                                        13720013
BH       EQU   2                       BRANCH ON HIGH                   13760013
BL       EQU   4                                 LOW                    13800013
BE       EQU   8                                 EQUAL                  13840013
BNH      EQU   13                                NOT HIGH               13880013
BNL      EQU   11                                NOT LOW                13920013
BNE      EQU   7                                 NOT EQUAL              13960013
         SPACE 1                                                        14000013
BO       EQU   1                                 OVERFLOW/ONES          14040013
BP       EQU   2                                 PLUS                   14080013
BM       EQU   4                                 MINUS/MIXED            14120013
BZ       EQU   8                                 ZERO                   14160013
         SPACE 1                                                        14200013
BNO      EQU   14                                NOT OVERFLOW/ONES      14240013
BNP      EQU   13                                NOT PLUS               14280013
BNM      EQU   11                                NOT MINUS/MIXED        14320013
BNZ      EQU   7                                 NOT ZERO               14360013
         SPACE 1                                                        14400013
*        DEFINITIONS OF 4K BLOCKS USED TO EFFECT AUTOMATIC BASE         14440013
*        REGISTER ASSIGNMENT FOR COMMUNICATIONS REFERENCES              14480013
         SPACE 1                                                        14520013
BLOCK1   EQU   *                                                        14560013
BLOCK2   EQU   BLOCK1+X'1000'                                           14600013
CONBLK   EQU   BLOCK1+X'2000'                                           14640013
DICBLK   EQU   BLOCK1+X'3000'                                           14680013
SCNBLK   EQU   BLOCK1+X'4000'                                           14720013
         SPACE 1                                                        14760013
         USING BLOCK1,BASRG1                                            14800013
         USING BLOCK2,BASRG2                                            14840013
         USING CONBLK,CONBAS                                            14880013
         USING DICBLK,DICBAS                                            14920013
         USING SCNBLK,SCNBAS                                            14960013
         SPACE 2                                                        15000013
*        DEFINITIONS OF CONTROL PHASE TRANSFER VECTOR OFFSETS           15040013
ZUGCOF   EQU   CONBLK+X'10'            GET SCRATCH CORE                 15080013
ZURCOF   EQU   CONBLK+X'18'            RELEASE SCRATCH CORE             15120013
ZABTOF   EQU   CONBLK+X'20'            ABORT                            15160013
ZLDWOF   EQU   CONBLK+X'24'            LOAD AND WAIT                    15200013
ZDRFOF   EQU   CONBLK+X'2C'            MAKE DICT ENTRY. RETURN REF      15240013
ZUEROF   EQU   CONBLK+X'30'            MAKE ERROR ENTRY                 15280013
ZRFAOF   EQU   CONBLK+X'34'            DICT REF TO ABSOLUTE             15320013
ZRLSOF   EQU   CONBLK+X'48'            RELEASE CONTROL                  15360013
ZTXROF   EQU   CONBLK+X'50'            ABS TO SYMBOLIC TEXT REF         15400013
         SPACE 2                                                        15440013
*        DEFINITIONS OF DICTIONARY COMMUNICATION REGION OFFSETS         15480013
         SPACE 1                                                        15520013
ZCOMM    EQU   DICBLK+304              BASE OF INTER-PHASE REGION       15560013
ZMYNAM   EQU   DICBLK+112              PHASE NAME CELL                  15600013
PAR1     EQU   DICBLK+128              PARAMETER 1                      15640013
PAR2     EQU   PAR1+4                            2                      15680013
PAR3     EQU   PAR2+4                            3                      15720013
PAR4     EQU   PAR3+4                            4                      15760013
PAR5     EQU   PAR4+4                            5                      15800013
PAR6     EQU   PAR5+4                            6                      15840013
PAR7     EQU   PAR6+4                            7                      15880013
PAR8     EQU   PAR7+4                            8                      15920013
         SPACE 2                                                        15960013
*        DEFINITIONS OF SCAN ROUTINE TRANSFER VECTOR OFFSETS            16000013
         SPACE 1                                                        16040013
SCTV     EQU   SCNBLK                                                   16080013
SCINIT   EQU   SCTV                                                     16120013
SC1      EQU   SCINIT+4                SCAN FROM CURRENT IP AND MOVE    16160013
SC2      EQU   SC1+4                   MOVE CURRENT AND SCAN FROM NEXT  16200013
SC3      EQU   SC2+4                   IGNORE CURRENT.  SCAN FROM NEXT  16240013
SC4      EQU   SC3+4                   SKIP TO NEXT. MARK TEXT WANTED   16280013
SC5      EQU   SC4+4                                           FREE     16320013
SC6      EQU   SC5+4                   SKIP,TRT NEXT,MARK TEXT WANTED   16360013
SC7      EQU   SC6+4                                           FREE     16400013
SC8      EQU   SC7+4                   MOVE IP TO FIRST AFTER JMP-WANT  16440013
SC9      EQU   SC8+4                                              FREE  16480013
SC10     EQU   SC9+4                   CONVERT SYMBOLIC TEXT PTR TO ABS 16520013
SC10A    EQU   SC10+4                  SKIP IP TO FIRST AFTER JMP       16560013
SCNERR   EQU   SC10A+4                                                  16600013
         SPACE 1                                                        16640013
MVTV     EQU   SCNERR+4                                                 16680013
MV1      EQU   MVTV                    MOVE TEXT FROM SYMBOLIC ADDR-END 16720013
MV2      EQU   MV1+4                   MOVE TEXT FROM SYMB ADDR-COUNT   16760013
MV3      EQU   MV2+4                   MOVE TEXT FROM ABS ADDR-COUNT    16800013
MV3A     EQU   MV3+4                   MOVE TRIPLES FROM ABS ADDR-COUNT 16840013
MV4      EQU   MV3A+4                  AS MV3+BLOCK SPANNING            16880013
MVERR    EQU   MV4+4                                                    16920013
         SPACE 1                                                        16960013
*              DEFINITIONS OF ENTRY POINTS TO EXTERNAL ROUTINES CALLED  17000013
*        BY THIS BLOCK                                                  17040013
         SPACE 1                                                        17080013
MB9000   EQU   BLOCK2                  EVENT                            17120013
MB9100   EQU   MB9000+4                ONCHAR                           17160013
MB9200   EQU   MB9100+4                ONSOURCE                         17200013
MB9300   EQU   MB9200+4                PRIORITY                         17240013
MB9400   EQU   MB9300+4                COMPLEX                          17280013
MB9500   EQU   MB9400+4                IMAG                             17320013
MB9600   EQU   MB9500+4                REAL                             17360013
MB9700   EQU   MB9600+4                UNSPEC                           17400013
MB9800   EQU   MB9700+4                SUBSTRING                        17440013
MB9900   EQU   MB9800+4                STATUS                           17460015
MB1000   EQU   MB9900+4                STRING                           17470046
         SPACE 1                                                        17480013
*              DEFINITIONS OF THE CODES USED IN THE SCAN TRT TABLE BY   17520013
*        THE SCAN ROUTINE                                               17560013
         SPACE 1                                                        17600013
A        EQU   4                        FORMAT                          17640013
Z        EQU   8                        FORMAT'                         17680013
C        EQU   48                      PROC                             17720013
D        EQU   52                      BEGIN                            17760013
E        EQU   56                      PROC'                            17800013
F        EQU   60                      BEGIN'                           17840013
G        EQU   28                       JMP                             17880013
H        EQU   32                       SN,SL,CN,CL,SN2                 17920013
I        EQU   72                       EOP2                            17960013
X        EQU   36                      ERROR OR END-OF-BLOCK TRIPLE     18000013
         SPACE 2                                                        18040013
*        DEFINITIONS OF DICTIONARY ENTRY CODES                          18080013
         SPACE 1                                                        18120013
DRCON    EQU   X'88'                   CONSTANT                         18160013
         SPACE 2                                                        18200013
*              OFFSETS OF FIELDS IN DICTIONARY ENTRIES                  18240013
         SPACE 1                                                        18280013
DEETLC   EQU   3                       LEVEL/COUNT IN ET1               18320013
DEFCOD   EQU   7                       FUNCTION CODE BYTE BEFORE        18360013
*                                    GENERIC SELECTION                  18400013
DECNDT   EQU   9                       DATA DESCRIPTION OF CONSTANT     18440013
DECNCH   EQU   3                       CHAIN FIELD                      18480013
DECNAP   EQU   5                       APPARENT TYPE                    18520013
DECNTY   EQU   8                       TYPE CODE                        18560013
DEPIC    EQU   19                      PICTURE REF OFFSET               18600013
DEPICW   EQU   11                      APPARENT LENGTH IN PICTURE       18640013
DEOT4    EQU   14                      OTHER 4 CODE BYTE                18680013
DEDATA   EQU   15                      DATA DESCRIPTION FIELD           18720013
DCNBCD   EQU   14                                                       18760013
DCNLN   EQU   6                                                         18800013
DATCAD   EQU   X'80'                   CAD/NUMERIC FIELD                18840013
DATNNF   EQU   X'08'                   NUMERIC FIELD                    18880013
DATBIN   EQU   X'04'                   BINARY                           18920013
DATFLT   EQU   X'02'                   FLOAT                            18960013
DATCMP   EQU   X'01'                   COMPLEX                          19000013
DATLS    EQU   X'10'                   LONG                             19040013
DATBIT   EQU   X'04'                   BIT                              19080013
DATFXD   EQU   DATFLT+DATBIN           FIXED DECIMAL TEST MASK          19120013
         SPACE 2                                                        19160013
*        DEFINITIONS OF TRIPLE OPERATORS                                19200013
         SPACE 1                                                        19240013
TRIDNT   EQU   X'07'                   IDENT                            19280013
TRSTRN   EQU   X'15'                   STRING                           19320013
TRKYTO   EQU   X'1A'                   KEYTO                            19360013
TRRPLY   EQU   X'25'                   REPLY                            19400013
TRALAS   EQU   X'37'                   BUY/ASSIGN                       19440013
TRIGNR   EQU   X'38'                   IGNORE                           19480013
TRPSI    EQU   X'3A'                   PSEUDO VARIABLE                  19520013
TRFUN    EQU   X'3C'                   FUNCTION                         19560013
TRCOM    EQU   X'41'                   COMMA                            19600013
TRDCOM   EQU   X'42'                   DOUBLE COMMA                     19640013
TRASN1   EQU   X'47'                   ASSIGN                           19680013
TRASN2   EQU   X'57'                   MULTIPLE ASSIGN                  19720013
TRTMPD   EQU   X'58'                   TMPD                             19760013
TRJMP    EQU   X'5B'                   JUMP                             19800013
TRLEFT   EQU   X'68'                   LEFT                             19840013
TRPSIP   EQU   X'7A'                   PSI'                             19880013
TRFUNP   EQU   X'7C'                   FUNCTION'                        19920013
TRSELL   EQU   X'AC'                   SELL                             19960013
         SPACE 2                                                        20000013
*        DEFINITIONS OF PSEUDO-CODE OPERATORS                           20040013
         SPACE 1                                                        20080013
PSDROP   EQU   X'06'                   DROP                             20120013
         SPACE 2                                                        20160013
*        OTHER ASSEMBLY PARAMETERS                                      20200013
         SPACE 1                                                        20240013
R14      EQU   14                      ARITHMETIC STANDARD REGISTERS    20280013
R15      EQU   15                                                       20320013
         SPACE 1                                                        20360013
TMPDF1   EQU   1                       TMPD FIELD 1                     20400013
TMPWO    EQU   X'C0'                   WORKSPACE OFFSET FLAGS           20440013
TMPXR    EQU   X'20'                   INDEX REGISTER FLAG              20480013
TMPLO    EQU   X'10'                   LITTERAL OFFSET FLAG             20520013
TMP3     EQU   X'10'                   THREE TMPD FLAG BIT              20560013
TMPRST   EQU   X'FF'-TMPWO-TMPXR       MASK TO RESET FLAG BITS          20600013
TMPDF2   EQU   2                                  2                     20640013
TMPDF3   EQU   3                                  3                     20680013
TMPDF5   EQU   5                                  5                     20720013
TMPDF6   EQU   7                                  6                     20760013
TMPDF7   EQU   9                                  7                     20800013
         EJECT                                                          20840013
*                       INITIALIZATION OF PHASE                         20880013
*              FUNCTIONS - (1) SETS UP SCAN PARAMETER BLOCK BASE        20920013
*        REGISTER FOR USE BOTH AS PHASE BASE AND PARAMETER REGISTER.    20960013
*                          (2) LOADS THE SECOND BLOCK IEMMC.            21000013
*                          (3) INITIALIZES SCAN ROUTINE.                21040013
*                          (4) GET A 4K BYTE BLOCK OF SCRATCH CORE      21080013
*        FOR USE IN STACKING PSEUDO-VARIABLES AND MULTIPLE ASSIGNMENTS. 21120013
*                                                                       21160013
*              ENTRY POINT - MB0000 FROM COMPILER CONTROL               21200013
*                                                                       21240013
*              EXTERNAL ROUTINES - (1) ZLDWOF. LOAD PHASE               21280013
*                                  (2) SCINIT. INITIALIZE SCAN          21320013
*                                  (3) ZUGCOF. GET SCRATCH CORE         21360013
*                                                                       21400013
*              EXITS - NORMAL - ENTER SCANNING SECTION                  21440013
*                                                                       21480013
*              EXITS - ERROR - NONE.                                    21520013
         SPACE 1                                                        21560013
MB0000   DC    C'MB'                   NAME OF PHASE                    21600013
         L     BASRG1,PAR1             LOAD BASE REGISTER OF PHASE      21640013
         MVC   ZMYNAM(2),MB0000        PLACE NAME OF PHASE IN           21680013
         BC    B,MB0001              COMMUNICATIONS REGION              21720013
         SPACE 2                                                        21760013
*              DEFINITIONS OF ENTRY POINTS AND WORKSPACE REFERENCED     21800013
*        BY EXTERNAL BLOCKS (SCAN AND IEMMC)                            21840013
         SPACE 1                                                        21880013
*              THE FOLLOWING TEXT REPRESENTS THE SCAN ROUTINE           21920013
*        PARAMETER BLOCK, COMPRISING TRANSLATE TABLE AND TEXT BLOCK     21960013
*        INFORMATION.                                                   22000013
         SPACE 1                                                        22040013
         CNOP  0,4                     ALIGN TO WORD BOUNDARY           22080013
SCPRAM   EQU   *                                                        22120013
SCTRT    DC    AL1(X)                  ERROR               00           22160013
         DC    XL15'0'                                     01-0F        22200013
         DC    XL2'0'                                      10-11        22240013
         DC    AL1(N)                  LIST                12           22280013
         DC    AL1(N)                  EDIT                13           22320013
         DC    AL1(N)                  DATA                14           22360013
         DC    XL11'0'                                     15-1F        22400013
         DC    XL16'0'                                     20-2F        22440013
         DC    XL10'0'                                     30-39        22480013
         DC    AL1(J)                  PSEUDO-VARIABLE     3A           22520013
         DC    XL5'0'                                      3B-3F        22560013
         DC    XL16'0'                                     40-4F        22600013
         DC    XL2'0'                                      50-51        22640013
         DC    AL1(P)                  LIST'               52           22680013
         DC    AL1(P)                  EDIT'               53           22720013
         DC    AL1(P)                  DATA'               54           22760013
         DC    XL2'0'                                      55-56        22800013
         DC    AL1(M)                  MULTIPLE ASSIGN     57           22840013
         DC    XL3'0'                                      58-5A        22880013
         DC    AL1(G)                  JMP                 5B           22920013
         DC    XL4'0'                                      5C-5F        22960013
         DC    XL16'0'                                     60-6F        23000013
         DC    XL10'0'                                     70-79        23040013
         DC    AL1(K)                  PSEUDO-VARIABLE'    7A           23080013
         DC    XL5'0'                                      7B-7F        23120013
         DC    XL16'0'                                     80-8F        23160013
         DC    XL16'0'                                     90-9F        23200013
         DC    XL16'0'                                     A0-AF        23240013
         DC    XL3'0'                                      B0-B2        23280013
         DC    AL1(C)                  PROC                B3           23320013
         DC    X'0'                                        B4           23360013
         DC    AL1(D)                  BEGIN               B5           23400013
         DC    XL6'0'                                      B6-BB        23440013
         DC    AL1(H)                  SN2                 BC           23480013
         DC    XL2'0'                                      BD-BE        23520013
         DC    AL1(A)                  FORMAT              BF           23560013
         DC    XL16'0'                                     C0-CF        23600013
         DC    AL1(H)                  SN                  D0           23640013
         DC    X'0'                                        D1           23680013
         DC    AL1(H)                  SL                  D2           23720013
         DC    X'0'                                        D3           23760013
         DC    AL1(H)                  CN                  D4           23800013
         DC    XL11'0'                                     D5-DF        23840013
         DC    XL13'0'                                     E0-EC        23880013
         DC    AL1(X)                  END-OF-BLOCK        ED           23920013
         DC    AL1(I)                  EOP2                EE           23960013
         DC    X'0'                                        EF           24000013
         DC    XL3'0'                                      F0-F2        24040013
         DC    AL1(E)                  PROC'               F3           24080013
         DC    X'0'                                        F4           24120013
         DC    AL1(F)                  BEGIN'              F5           24160013
         DC    XL9'0'                                      F6-FE        24200013
         DC    AL1(Z)                  FORMAT'             FF           24240013
         SPACE 1                                                        24280013
*              END OF SCAN TRANSLATE TABLE                              24320013
*              THE FOLLOWING IS THE REMAINDER OF THE SCAN PARAMETER     24360013
*        BLOCK                                                          24400013
         SPACE 1                                                        24440013
SCEOBI   DC    F'0'                    ADDRESS OF END OF IP BLOCK       24480013
SCEOBO   DC    F'0'                                      OP             24520013
SCJMP    DC    F'0'                    SYMBOLIC POSITION OF JMP TRIPLE  24560013
SCPCG    DC    F'0'                    COUNT OF PSEUDO CODE GENERATED   24600013
SCTXTI   DC    F'0'                    NAME OF IP BLOCK                 24640013
SCTXTO   DC    F'0'                            OP                       24680013
SCWKSC   DC    F'0'                    CURRENT WORKSPACE COUNT          24720013
SCBLK    DC    H'0'                    DICT REF OF CURRENT BLOCK        24760013
SCSTK    DC    H'0'                    CURRENT REGISTER USAGE           24800013
SCWSDR   DC    H'0'                    DICT REF OF CURRENT WORKSPACE    24840013
SCOPT    DC    X'00'                   PREFIX OPTION BYTE               24880013
         DC    X'00'                                                    24920013
         SPACE 1                                                        24960013
*              END OF SCAN PARAMETER BLOCK                              25000013
         SPACE 1                                                        25040013
*              ENTRY POINTS USED BY IEMMC                               25080013
         USING SCPRAM,BASRG1                                            25120013
         BC    B,MMV35                 PSEUDO-CODE MOVING ROUTINES      25160013
         BC    B,MMV3U                                                  25200013
         BC    B,MMV3A5                TRIPLE MOVING ROUTINES           25240013
         BC    B,MMV3AU                                                 25280013
         BC    B,OUTMPD                PLACE TMPD IN OUTPUT             25320013
         BC    B,ARGTMP                CREATE TMPD FOR ARGUMENT         25360013
         BC    B,DRFTMP                CREATE TMPD FROM DICT ENTRY      25400013
         BC    B,GETWKS                GET WORKSPACE FOR TARGET         25440013
         BC    B,DROP1                 DROP REGISTERS                   25480013
         BC    B,DROP2                                                  25520013
         BC    B,ERROR                 ERROR ENTRY ROUTINE              25560013
         BC    B,CADNFL                GET LENGTH OF DATUM              25600013
         BC    B,TARGET                CONVERT TO PV TARGET TYPE        25640013
         BC    B,OUTRIP                OUTPUT TRIPLES IN INPUT TEXT     25680013
         BC    B,CHECKW                CHECK WORKSPACE COUNT            25720013
         BC    B,CONVT                 CONVERT CONSTANT TO TARGET TYPE  25740015
         BC    B,MB1330                                                 25750001
         B     SELLSTK                                            32295 25755020
*              WORKSPACE USED BY IEMMC                                  25760013
PSVTGT   DS    F                       POINTER TO PV TARGET TMPD        25800013
STKLHS   DS    F                       POINTER TO RHS DESCRIPTION       25840013
TDBSAVE  DC    F'0'                                                     25860001
SELSAV   DC    5F'0'                   TEMP RESULT SAVE AREA     A32295 25870020
LENGTH   DS    H                       LENGTH RESULT RETURNED BY CADNFL 25880013
WSWKS    DS    H                       WORKSPACE OFFSET SLOT            25920013
TMPD0    DS    11C                     WORKSPACE FOR A TMPD             25960013
SWDATA   DS    C                       DATA INPUT/ASSIGN SWITCH         26000013
EVFLG    DS    C                                                        26040013
         EJECT                                                          26080013
*              BEGIN INITIALIZATION OF PHASE                            26120013
*              SET UP BASE ADDRESS OF PHASE AT BEGINNING OF SCAN BLOCK  26160013
*        SO THAT SAME REGISTER CAN BE USED FOR BASE AND SCAN PARAMETER  26200013
         SPACE 1                                                        26240013
         USING MB0000,BASRG1                                            26280013
         SPACE 1                                                        26320013
MB0001   LA    BASRG1,SCPRAM                                            26360013
         USING SCPRAM,BASRG1                                            26400013
         SPACE 1                                                        26440013
*              LOAD SECOND BLOCK OF THIS PHASE (IEMMC)                  26480013
         SPACE 1                                                        26520013
         LA    HR1,CNLDMC              POINT PAR1 AT MCZZ               26560013
         ST    HR1,PAR1                                                 26600013
         L     LR,ZLDWOF               LOAD MC                          26640013
         BALR  RR,LR                                                    26680013
         L     BASRG2,PAR1             LOAD BASE FOR MC                 26720013
         SPACE 1                                                        26760013
         BAL   RR,SCINIT               PERFORM SCAN INITIALIZATION      26800013
*                                    FOR THIS PHASE                     26840013
         SPACE 1                                                        26880013
*              GET A 4K BYTE SCRATCH AREA FOR SETTING UP PSEUDO-        26920013
*        VARIABLE AND MULTIPLE ASSIGNMENT STACKS                        26960013
         SPACE 1                                                        27000013
         LA    HR1,8                   SET PAR1=8 TO REQUEST A 4K       27040013
         ST    HR1,PAR1              BYTE SCRATCH AREA                  27080013
         L     LR,ZUGCOF                                                27120013
         BALR  RR,LR                   ON RETURN, PLACE ADDRESS OF      27160013
         L     STKR,PAR1             AREA IN STACK REGISTER, AND SAVE   27200013
         ST    STKR,STKBSE         VALUE IN STKBSE.                     27240013
         SPACE 1                                                        27280013
*              INITIALIZATION OF PHASE NOW COMPLETED                    27320013
         EJECT                                                          27360013
*                       MAIN INPUT TEXT SCANNING SECTION                27400013
*              FUNCTIONS - THE NEXT TRIPLE OF INTEREST, AS DEFINED BY   27440013
*        THE CURRENT STATE OF THE SCAN TRANSLATE TABLE, IS FOUND, AND   27480013
*        THE TRANSLATED CODE VALUE USED TO ENTER THE APPROPRIATE        27520013
*        PROCESSING SECTION.                                            27560013
*                                                                       27600013
*              ENTRY POINTS - (1) MB0002 TO SCAN FROM CURRENT TRIPLE    27640013
*                             (2) MB0003 NEXT TRIPLE ALREADY FOUND      27680013
*                                                                       27720013
*              EXTERNAL ROUTINES - SC1.                                 27760013
*                                                                       27800013
*              EXITS - NORMAL - VIA BRANCH TABLE TO PROCESSING SECTION  27840013
*                                                                       27880013
*              EXITS - ERROR -  MBABT1 ON INVALID RETURN FROM SCAN      27920013
         SPACE 1                                                        27960013
*              ENTRY IS AT THIS POINT WHEN SCANNING IS TO COMMENCE      28000013
*        FROM THE CURRENT INPUT TEXT POINTER VALUE                      28040013
         SPACE 1                                                        28080013
MB0002   BAL   RR,SC1                  SCAN ROUTINE RETURNS HAVING      28120013
*                                    UPDATED IPTR AND SET TRT VALUE OF  28160013
*                                    CURRENT TRIPLE                     28200013
         SPACE 1                                                        28240013
*              ENTRY AT THIS POINT WHEN TRT VALUE OF CURRENT TRIPLE IS  28280013
*        KNOWN AND IS OF INTEREST TO THIS PHASE                         28320013
MB0003   EQU   *                                                        28360013
         SPACE 1                                                        28400013
         EX    0,MB0004(TRTR)                                           28440013
         SPACE 1                                                        28480013
*              BRANCH TABLE FOR TRIPLE OPERATOR SCAN VALUES             28520013
         SPACE 1                                                        28560013
MB0004   EQU   *-C                                                      28600013
         BC    B,MB0040                PROC                             28640013
         BC    B,MB0041                BEGIN                            28680013
         BC    B,MB0042                PROC'                            28720013
         BC    B,MB0043                BEGIN'                           28760013
         BC    B,MBABT1                JMP, SL ETC. ARE NOT SCANNED     28800013
         BC    B,MBABT1              FOR BY THIS PHASE                  28840013
EOP2     BC    B,MB0010                EOP2                             28880013
PSI      BC    B,MB0011                PSEUDO-VARIABLE                  28920013
PSIP     BC    B,MB0012                PSEUDO-VARIABLE'                 28960013
ASSN1    BC    B,MB0013                ASSIGN                           29000013
ASSN2    BC    B,MB0014                MULTIPLE ASSIGN                  29040013
DL       BC    B,MB0015                LIST, EDIT OR DATA               29080013
DLP      BC    B,MB0016                LIST', EDIT' OR DATA'            29120013
*              THE FOLLOWING ARE SCANNED FOR ONLY BETWEEN PSI AND PSI'  29160013
*        WHEN ARGUMENTS OF THE PSEUDO-VARIABLE ARE BEING COLLECTED.     29200013
ARGB     BC    B,MB0020                                                 29240013
ARGTB    BC    B,MB0021                                                 29280013
FNB      BC    B,MB0022                                                 29320013
FNPB     BC    B,MB0023                                                 29360013
         SPACE 1                                                        29400013
*              DEFINITIONS OF THE CODES USED IN THE SCAN TRT TABLE FOR  29440013
*        TRIPLES OF INTEREST TO THIS PHASE                              29480013
         SPACE 1                                                        29520013
J        EQU   PSI-MB0004              PSI                              29560013
K        EQU   PSIP-MB0004             PSI'                             29600013
L        EQU   ASSN1-MB0004            ASSIGN                           29640013
M        EQU   ASSN2-MB0004            MULTIPLE ASSIGN                  29680013
N        EQU   DL-MB0004               DATA, LIST                       29720013
P        EQU   DLP-MB0004              DATA', LIST'                     29760013
         SPACE 1                                                        29800013
*              AUXILIARY LIST OF DEFINITIONS FOR TRIPLES SCANNED ONLY   29840013
*        INTERMITTENTLY.                                                29880013
         SPACE 1                                                        29920013
A1       EQU   ARGB-MB0004             ARGUMENT (BUY/ASSIGN)            29960013
A2       EQU   ARGTB-MB0004            ARGUMENT (IGNORE)                30000013
A3       EQU   FNB-MB0004              FUNCTION                         30040013
A4       EQU   FNPB-MB0004             FUNCTION'                        30080013
         EJECT                                                          30120013
*                       EOP TRIPLE                                      30160013
*              FUNCTIONS - (1) THE 4K BYTE BLOCK OF SCRATCH CORE        30200013
*        OBTAINED DURING INITIALIZATION.                                30240013
*                          (2) RELEASE BLOCK IEMMB AND IEMMC AND        30280013
*        RETURN TO COMPILER CONTROL TO ENTER NEXT PHASE.                30320013
*                                                                       30360013
*              ENTRY POINT - MB0010 FROM SCANNING SECTION UPON          30400013
*        RECOGNITION OF END-OF-TEXT MARKER                              30440013
         SPACE 1                                                        30480013
MB0010   LA    HR1,1                   AT THIS STAGE JUST ONE 4K BLOCK  30520013
         ST    HR1,PAR1              REMAINS, NAMELY THE ONE OBTAINED   30560013
         L     LR,ZURCOF             DURING INITIALIZATION. RELEASE IT  30600013
         BALR  RR,LR                                                    30640013
         SPACE 1                                                        30680013
MB1001   BC    NOP,MBABT3              BRANCH TO ABORT IF SWITCH SET AS 30720013
SWABRT   EQU   MB1001+1              A RESULT OF EXPRESSION ARGUMENT    30760013
         SPACE 1                                                        30800013
         LA    HR1,CNRLS               FINALLY RELEASE THE PHASE        30840013
         ST    HR1,PAR1                                                 30880013
         SR    HR1,HR1                                                  30920013
         ST    HR1,PAR2                                                 30960013
         L     LR,ZRLSOF               CALL ZRLSCTL                     31000013
         BALR  RR,LR                   CONTROL NOW PASSES TO NEXT       31040013
*                                    PHASE                              31080013
         SPACE 2                                                        31120013
*                       ABORT EXIT                                      31160013
         SPACE 1                                                        31200013
MBABT1   L     HR1,ERID01              INVALID RETURN VALUE FROM SCAN.  31240013
MBABT2   BAL   RR,ERROR                MAKE ERROR ENTRY                 31280013
MBABT3   L     LR,ZABTOF               CALL ABORT                       31320013
         BALR  RR,LR                                                    31360013
         EJECT                                                          31400013
*                       PSEUDO-VARIABLE                                 31440013
*              FUNCTIONS - (1) SETS THE NO-PSEUDO-VARIABLE SWITCH OFF   31480013
*        IN THE ASSIGN TRIPLE SECTION.                                  31520013
*                          (2) LOOKS AT THE DICTIONARY ENTRY REFERENCED 31560013
*        IN THE OPERAND 1 SLOT OF THE TRIPLE AND SETS A PSEUDO-VARIABLE 31600013
*        MARKER AND CODE BYTE IN THE STACK. THE CODE BYTE VALUES ARE-   31640013
*              0    ERROR- PSEUDO-VARIABLE NOT RECOGNIZED.              31680013
*              4    EVENT     ENTRY CODE 03 IN BYTE 7 OF ENTRY          31720013
*              8    ONCHAR               06                             31760013
*              12   ONSOURCE             08                             31800013
*              16   PRIORITY             0C                             31840013
*              20   COMPLEX              1B                             31880013
*              24   IMAG                 1F                             31920013
*              28   REAL                 23                             31960013
*              32   UNSPEC               28                             32000013
*              36   SUBSTR               30                             32040013
*              40      STATUS          34                               32050046
*              44      STRING          26                               32060046
*                          (3) BUMPS THE STACK REGISTER BY 2 FOR PSI    32080013
*        MARKER AND CODE BYTE.                                          32120013
*                          (4) IN THE CASE OF AN ERROR, ABORTS          32160013
*                          (5) FOR NORMAL CASES, PLACES CURRENT         32200013
*        PSEUDO-VBLE CODE IN PSVCUR AND SETS LEVEL AND COUNT TO ZERO    32240013
*        THEN CHANGES SCAN TRT TABLE TO LOOK FOR PSEUDO-VARIABLE        32280013
*        ARGUMENTS.                                                     32320013
*                                                                       32360013
*              ENTRY - MB0011 FROM SCANNING SECTION UPON RECOGNITION    32400013
*        OF PSI TRIPLE.                                                 32440013
*                                                                       32480013
*              EXTERNAL ROUTINES - SC5                                  32520013
*                                  SC10A                                32560013
*                                  ZRFAOF                               32600013
*                                                                       32640013
*              EXITS - NORMAL - RETURN TO SCAN SECTION                  32680013
*                                                                       32720013
*              EXITS - ERROR - MB1106 TO PSI' SECTION WHEN PSEUDO-VBLE  32760013
*        DICTIONARY ENTRY NOT RECOGNIZED.                               32800013
         SPACE 1                                                        32840013
MB0011   CLC   1(2,IPTR),CN00FF        IF OPERAND IS NOT A DICTIONARY   32880013
         BC    BNH,MB0002            REFERENCE PASS THE TEXT UNCHANGED  32920013
         SPACE 1                                                        32960013
         NI    SWNOPV,X'0F'            RESET NO PSEUDO-VARIABLE SWITCH  33000013
         MVI   0(STKR),TRPSI         AND PLACE A PSI MARKER IN THE      33040013
*                                    STACK.                             33080013
         MVC   PAR1+2(2),1(IPTR)       GET DICTIONARY ENTRY REFERENCED  33120013
         L     LR,ZRFAOF             IN TRIPLE OPERAND 1                33160013
         BALR  RR,LR                                                    33200013
         L     HR1,PAR1                                                 33240013
         SPACE 1                                                        33280013
         LA    HR2,PSVEND-PSTABL       FIND THE PSEUDO VARIABLE IN THE  33320013
MB1101   LA    R1,PSTABL-1(HR2)      LIST AT PSTABL.                    33360013
         CLC   0(1,R1),DEFCOD(HR1)                                      33400013
         BC    BE,MB1102               BRANCH ON MATCH, OTHERWISE TEST  33440013
         BCT   HR2,MB1101            NEXT BYTE                          33480013
         SPACE 1                                                        33520013
*              PSEUDO-VARIABLE CODE NOT RECOGNIZED. GENERIC SELECTION   33560013
*        HAS ALREADY GENERATED AN ERROR MESSAGE, SO JUST ABORT.         33600013
         SPACE 1                                                        33640013
         L     LR,ZABTOF                                                33680013
         BALR  RR,LR                                                    33720013
         SPACE 2                                                        33760013
*              PSEUDO-VARIABLE CODE RECOGNIZED. SET CODE BYTE IN STACK  33800013
*        AND PREPARE TO SCAN FOR ARGUMENTS.                             33840013
         SPACE 1                                                        33880013
MB1102   AR    HR2,HR2                 DOUBLE LOOP COUNTER THEN         33920013
         AR    HR2,HR2                 DOUBLE AGAIN AND STORE CODE IN   33960013
         STC   HR2,1(0,STKR)         STACK AND UPDATE STACK POINTER     34000013
         STH   HR2,PSVCUR              SET CURRENT PSV CELL             34040013
         LA    STKR,2(0,STKR)                                           34080013
         SPACE 1                                                        34120013
         BAL   RR,SWITCH               CHANGE TRT TABLE TO SCAN FOR     34160013
         MVI   SCTRT+TRASN1,0        FUNCTION, BUY/ASSIGN AND IGNORE    34200013
*                                    BUT NOT SIMPLE ASSIGN              34240013
         SR    HR1,HR1                 SET ARGUMENT LEVEL TO ZERO.      34280013
         ST    HR1,PSVLVL                                               34320013
         STH   HR1,PSVCNT              SET ARGUMENT COUNT TO ZERO       34360013
         NI    SWERR,X'0F'             RESET ERROR SWITCH IN PSI'       34400013
*                                    SECTION                            34440013
         SPACE 1                                                        34480013
         BAL   RR,SC3                  DROP PSI AND SCAN TO NEXT        34520013
         BC    B,MB0003              TRIPLE OF INTEREST, THEN GO TO     34560013
*                                    SEE WHAT IT IS                     34600013
         EJECT                                                          34640013
*                       PSEUDO-VARIABLE'                                34680013
*              FUNCTIONS - (1) RESETS THE SCAN TRT TABLE TO SUSPEND     34720013
*        SCANNING FOR PSEUDO-VARIABLE ARGUMENTS.                        34760013
*                          (2) SETS A PSI' MARKER IN THE STACK, SKIPS   34800013
*        THE PSI' TRIPLE AND BUMPS THE STACK POINTER BY 1.              34840013
*                          (3) COPIES THE TMPDS FOLLOWING THE PSI'      34880013
*        TRIPLE INTO THE STACK IN THE FORM OF AN 11 BYTE TMPD, AND      34920013
*        DROPS THEM FROM THE TEXT.                                      34960013
*                          (4) IF THE PSEUDO-VARIABLE IS A DATA LIST    35000013
*        ITEM (NEXT TRIPLE IS A COMMA AND DATA LIST SWITCH IS ON),      35040013
*        THEN PSVR IS SET TO ADDRESS THE STACK BASE, WHERE THE PSEUDO-  35080013
*        VBLE DESCRIPTION MUST START.                                   35120013
*                                                                       35160013
*              ENTRIES - (1) MB0012  FROM SCAN SECTION ON RECOGNITION   35200013
*        OF PSI' TRIPLE.                                                35240013
*                        (2) MB1202  FROM PSI SECTION WHEN PSEUDO-VBLE  35280013
*        UNRECOGNIZED AND DESCRIPTION HAS BEEN DELETED.                 35320013
*                                                                       35360013
*              EXTERNAL ROUTINES - SC5                                  35400013
*                                                                       35440013
*              EXITS - NORMAL - RETURN TO SCANNING SECTION.             35480013
*                                                                       35520013
*              EXITS - ERROR - NONE.                                    35560013
         SPACE 1                                                        35600013
MB0012   CLC   1(2,IPTR),CN00FF        IF OPERAND IS NOT A DICTIONARY   35640013
         BC    BNH,MB0002            REFERENCE PASS THE TEXT UNCHANGED  35680013
         SPACE 1                                                        35720013
         BAL   RR,SWITCH               CHANGE TRT TABLE                 35760013
         MVI   SCTRT+TRASN1,L                                           35800013
MB1204   BC    NOP,MB1205              ERROR SWITCH. BRANCH IF AN       35840013
SWERR    EQU   MB1204+1              EXPRESSION HAS BEEN USED AS A      35880013
*                                    PSEUDO VARIABLE ARGUMENT           35920013
         SPACE 1                                                        35960013
*              ENTRY FROM PSI SECTION WHEN PSEUDO-VARIABLE INVALID      36000013
         SPACE 1                                                        36040013
MB1202   BAL   RR,SC5                  DROP PSI' TRIPLE                 36080013
         MVI   0(STKR),TRPSIP          SET PSI' MARKER IN STACK AND     36120013
         LA    STKR,1(0,STKR)        BUMP POINTER BY 1                  36160013
         NI    TMPDF1(IPTR),TMPRST     RESET FLAG BITS IN TMPD          36200013
         BAL   RR,MVTMPD               PUT TMPDS FOLLOWING PSI' INTO    36240013
*                                    STACK                              36280013
MB1203   CLI   0(IPTR),TRSELL          NOW SEE IF THERE ARE ANY SELLS   36320013
         BC    BNE,MB1201            FOLLOWING THE PSEUDO-VARIABLE. IF  36360013
*                                    SO THEY MUST BE SAVED IN THE STACK 36400013
         MVC   0(5,STKR),0(IPTR)     AND REGENERATED AFTER THE PSEUDO-  36440013
         LA    STKR,5(0,STKR)        VARIABLE HAS BEEN USED.            36480013
         ST    STKR,MAXSEL                                              36520013
         BAL   RR,SC5                  DROP SELL FROM TEXT, THEN LOOK   36560013
         BC    B,MB1203              AT NEXT TRIPLE.                    36600013
         SPACE 1                                                        36640013
MB1201   BC    B,MB1206                BRANCH TO TEST FOR KEYTO, REPLY  36680013
SWNODL   EQU   MB1201+1              STRING OR IDENT UNLESS IN DATA     36720013
*                                    LIST.                              36760013
         SPACE 1                                                        36800013
         CLI   0(IPTR),TRCOM           TEST SUCCESSOR TRIPLE FOR COMMA  36840013
         BC    BNE,MB0002            AND GO TO SCAN IF NOT              36880013
         SPACE 1                                                        36920013
*              PSEUDO-VARIABLE IN INPUT DATA LIST.                      36960013
         SPACE 1                                                        37000013
MB1207   L     PSVR,STKBSE             POINT PSVR AT STACK BASE         37040013
         OI    SWDATA,X'F0'            SET DATA ITEM SWITCH ON          37080013
         BC    B,MB1322                GO TO COMMON SECTION TO BRANCH   37120013
*                                    TO APPROPRIATE PV ROUTINE          37160013
         SPACE 2                                                        37200013
*              PSEUDO-VARIABLE NOT IN DATA LIST                         37240013
         SPACE 1                                                        37280013
MB1206   LA    HR2,PVLSTL              TEST TO SEE IF TRIPLE FOLLOWING  37320013
MB1208   LA    HR1,PVLIST-1(HR2)     IS ONE OF IDENT, REPLY, STRING     37360013
         CLC   0(1,IPTR),0(HR1)      OR KEYTO, AND IF ONE OF THESE      37400013
         BC    BE,MB1207             SET THE DATA SWITCH ON TO CAUSE    37440013
         BCT   HR2,MB1208            GENERATION OF CODE FOR PSEUDO-     37480013
         BC    B,MB0002              VARIABLES USED AS OPTION ARGUMENTS 37520013
         SPACE 3                                                        37560013
*              ERROR SECTION                                            37600013
*        ENTERED WHEN PSEUDO-VARIABLE ARGUMENT IS EXPRESSION            37640013
         SPACE 1                                                        37680013
MB1205   MVC   PAR7+2(2),1(IPTR)       MOVE DICT REF OF ERRONEOUS PSV   37720013
         L     HR1,ERID02            INTO PAR7                          37760013
         BAL   RR,ERROR                MAKE ERROR ENTRY                 37800013
         OI    SWABRT,X'F0'            SET ABORT ON EXIT SWITCH ON AND  37840013
         BC    B,MB1202              RESUME NORMAL PROCESSING           37880013
         EJECT                                                          37920013
*                       ASSIGN                                          37960013
*              FUNCTIONS - THIS SECTION CAUSES THE UNSTACKING OF STACK  38000013
*        ENTRIES ACCUMULATED DURING PREVIOUS SCANNING, AND THE          38040013
*        GENERATION OF CODE FOR PSEUDO-VARIABLES AND MULTIPLE ASSIGNS.  38080013
*        THE SECTION HAS TWO DISTINCT PARTS-                            38120013
*                       (1) STACKING OF TMPDS FOR CURRENT ASSIGNMENT.   38160013
*              IF THE MULTIPLE ASSIGNMENT SWITCH IS OFF (I.E. THIS      38200013
*        DOES NOT MARK THE END OF A SEQUENCE OF MULTIPLE ASSIGNMENTS)   38240013
*        OR IF THE 'NO PSEUDO-VARIABLE' SWITCH IS ON (I.E. THIS IS NOT  38280013
*        A PSEUDO-VARIABLE ASSIGNMENT),THEN THE ASSIGN TRIPLE IS        38320013
*        MOVED TO OUTPUT AND SCANNING RESUMED FROM THE NEXT TRIPLE.     38360013
*              IF THE MULTIPLE ASSIGNMENT IS OFF, THEN THE TMPDS, IF    38400013
*        ANY, FOLLOWING THE ASSIGN ARE CHECKED TO SEE IF THE TARGET IS  38440013
*        A PSEUDO-VARIABLE. IF NOT THE ASSIGN TRIPLE IS MOVED TO        38480013
*        OUTPUT AND SCANNING RESUMED (THIS CASE ARISES WHEN ASSIGNMENTS 38520013
*        HAVE BEEN GENERATED BY THE DO EXPANSION OR EXPRESSION          38560013
*        EVALUATION PHASES FOR THE EVALUATION OF THE RIGHT HAND SIDE    38600013
*        TO BE ASSIGNED TO A PSEUDO-VARIABLE). IF THE TARGET IS A       38640013
*        PSEUDO-VARIABLE TREATMENT IN THIS PART IS THE SAME AS FOR      38680013
*        MULTIPLE ASSIGN SWITCH ON.                                     38720013
*              IF THE MULTIPLE ASSIGN SWITCH IS ON THE CURRENT TRIPLE   38760013
*        IS SKIPPED AND ANY TMPDS FOLLOWING IT MOVED INTO THE STACK     38800013
*        IN THE FORM OF 11 BYTE TMPD ENTRIES.                           38840013
*              FINALLY THE INPUT TEXT POINTER IS RESTORED TO ADDRESS    38880013
*        THE FIRST (POSSIBLY ONLY) ASSIGNMENT TRIPLE OF THE SEQUENCE    38920013
*        IN PREPARATION FOR THE RE-SCAN WHICH CONSTITUTES THE SECOND    38960013
*        PART OF THIS SECTION.                                          39000013
*                       (2) RE-SCAN OF ASSIGNMENTS AND UNSTACKING.      39040013
*              THE CURRENT TRIPLE, WHICH MAY BE AN ASSIGN OR A          39080013
*        MULTIPLE ASSIGN TRIPLE, IS EXAMINED.                           39120013
*              IF ITS FIRST OPERAND FIELD (THE TARGET) IS NOT 00, I.E.  39160013
*        NOT AN INTERMEDIATE RESULT,THE TRIPLE IS MOVED TO THE OUTPUT   39200013
*        STRING, AND, IF ITS OPERAND 2 FIELD (THE SOURCE) IS 00, THE    39240013
*        INTERMEDIATE RESULT DESCRIPTION IN THE STACK WHICH IS          39280013
*        ADDRESSED BY STKLHS IS ALSO PLACED IN THE OUTPUT.              39320013
*              IF ITS FIRST OPERAND IS 00 THEN THE TARGET IS DESCRIBED  39360013
*        BY A TMPD WHICH, BY VIRTUE OF THE MANNER IN WHIC THE STACK IS  39400013
*        CONSTRUCTED, IS THE CURRENT TOP ENTRY. THIS TOP ENTRY IS       39440013
*        EXAMINED TO SEE IF IT IS A PSEUDO-VARIABLE (LEFT CODE AND 'FF' 39480013
*        IN THIRD BYTE). IF NOT THE PROCEDURE IS THE SAME AS ABOVE      39520013
*        (FIRST OPERAND NOT 00 CASE) EXCEPTING THE INCLUSION OF AN      39560013
*        OPERAND 1 TMPD TAKEN FROM THE TOP OF THE STACK AND THE REMOVAL 39600013
*        OF THAT TOP ENTRY FROM THE STACK.                              39640013
*              IF THE TARGET OPERAND IS A PSEUDO-VARIABLE THEN ITS      39680013
*        DESCRIPTION IS TO BE FOUND AT THE CURRENT BOTTOM OF THE STACK. 39720013
*        A SCAN UP THE STACK LOOKING FOR A PSI' MARKER IS MADE SO AS    39760013
*        TO ESTABLISH IN PSVNXT THE NEXT CURRENT BOTTOM OF THE STACK    39800013
*        (THIS WILL BE THE DESCRIPTION OF THE NEXT PSEUDO-VARIABLE IN   39840013
*        THE CASE OF MULTIPLE PSEUDO-VARIABLE ASSIGNMENTS). THE         39880013
*        IDENTIFICATION CODE FOLLOWING THE PSI MARKER AT THE BOTTOM     39920013
*        OF THE STACK IS THEN USED TO SELECT THE CORRECT ENTRY IN       39960013
*        BLOCK IEMMC TO GENERATE CODE FOR THIS PSEUDO-VARIABLE.         40000013
*              ON EXHAUSTION OF THE STACK, I.E. AFTER THE SIMPLE        40040013
*        ASSIGN HAS BEEN PROCESSED IN THE SECOND SCAN, OR WHEN THE      40080013
*        PSEUDO-VARIABLE HAS BEEN DEALT WITH, SWITCHES ARE RESET TO     40120013
*        THEIR INITIAL VALUES AND SCANNING RESUMED.                     40160013
*                                                                       40200013
*              ENTRY POINTS - (1) MB0013. FROM SCANNING SECTION ON      40240013
*        FINDING A SIMPLE ASSIGNMENT TRIPLE.                            40280013
*                             (2) MB1322. FROM THE PSI' SECTION WHEN    40320013
*        A PSEUDO-VARIABLE WHICH IS NOT A DO LOOP CONTROL VARIABLE      40360013
*        HAS BEEN FOUND IN A DATA LIST.                                 40400013
*                                                                       40440013
*              EXTERNAL ROUTINES - (1) ZTXROF.                          40480013
*                                  (2) SC4.                             40520013
*                                  (3) SC5.                             40560013
*                                  (4) SC10.                            40600013
*                                  (5) PSEUDO-VARIABLE ROUTINES IN      40640013
*        BLOCK IEMMC.                                                   40680013
*                                                                       40720013
*              EXITS - NORMAL - RETURN TO TEXT SCANNING SECTION.        40760013
*                                                                       40800013
*              EXITS - ERROR - NONE.                                    40840013
*                                                                       40880013
*              NOTES - (1) REGISTER USAGE.                              40920013
*        PSVR POINTS TO THE BOTTOM OF THE STACK                         40960013
*        STKR POINTS AT THE CURRENT TOP OF THE STACK                    41000013
*                       (2) ADDRESS SLOTS.                              41040013
*        STKLHS CONTAINS ADDRESS OF RIGHT-HAND-SIDE TMPD IN THE STACK,  41080013
*                  OR, IF THERE IS NONE, A TMPD CONSTRUCTED FROM THE    41120013
*                  SOURCE DICTIONARY REFERENCE, OR, FOR A DATA LIST     41160013
*                  ITEM, IS MEANINGLESS.                                41200013
*        PSVTGT CONTAINS ADDRESS OF TMPD DESCRIPTION OF PSEUDO-VARIABLE 41240013
*                  RESULT TYPE IN THE STACK.                            41280013
*        PSVNXT CONTAINS ADDRESS OF NEXT PSEUDO-VARIABLE DESCRIPTION    41320013
*                  IN THE STACK.                                        41360013
         SPACE 2                                                        41400013
*              FIRST PART OF SECTION                                    41440013
         SPACE 1                                                        41480013
MB0013   BC    NOP,MB1302              BRANCH IF MULTIPLE ASSIGNMENT    41520013
SWMULT   EQU   MB0013+1                                                 41560013
         SPACE 1                                                        41600013
MB1301   BC    B,MB4001                BRANCH IF NO PSEUDO-VARIABLES    41640013
SWNOPV   EQU   MB1301+1                                                 41680013
         SPACE 1                                                        41720013
*              PSEUDO-VARIABLE AND NOT MULTIPLE ASSIGNMENT              41760013
         ST    STKR,STKLHS             SAVE CURRENT STACK POINTER       41800013
         ST    IPTR,PAR2               CONVERT THE CURRENT ABSOLUTE     41840013
         MVC   PAR1(4),SCTXTI        INPUT TEXT ADDRESS TO SYMBOLIC     41880013
         L     LR,ZTXROF                                                41920013
         BALR  RR,LR                                                    41960013
         MVC   WSTXRF(4),PAR1                                           42000013
         SPACE 1                                                        42040013
         CLC   1(2,IPTR),CNZERO        NOW CHECK TO MAKE SURE THAT      42080013
         BC    BNE,MB4001            WE SHOULD DO SOMETHING ABOUT THIS  42120013
*                                    ASSIGN. TO BE WORTHY OF OUR        42160013
         CLC   3(2,IPTR),CNZERO      ATTENTION IT MUST HAVE 00 OPERAND  42200013
         BC    BNE,MB1306            ONE AND PSEUDO VARIABLE TARGET.    42240013
         SPACE 1                                                        42280013
         BAL   RR,SC4                  IF OPERAND 2 IS ZERO, SKIP OVER  42320013
         BAL   RR,MVTMPW             ASSOCIATED TMPDS BY PUTTING THEM   42360013
         BC    B,MB1307              IN THE STACK                       42400013
         SPACE 1                                                        42440013
MB1306   BAL   RR,SC4                  OPERAND 2 NOT 00, SKIP THE       42480013
*                                    ASSIGN TRIPLE                      42520013
         SPACE 1                                                        42560013
MB1307   CLI   0(IPTR),TRLEFT          NOW CHECK THE OPERAND 1 TMPD     42600013
         BC    BNE,MB1308            FOR PSEUDO-VARIABLE. BRANCH        42640013
*                                    IF NOT.                            42680013
         CLI   2(IPTR),X'FF'                                            42720013
         BC    BE,MB1305               IF PSI TMPD, THEN GO TO PUT IT   42760013
*                                    IN THE STACK AND START             42800013
*                                    PROCESSING.                        42840013
         SPACE 1                                                        42880013
MB1308   L     STKR,STKLHS             OTHERWISE RESTORE THE STACK      42920013
         MVC   PAR1(4),WSTXRF        POINTER AND THE INPUT TEXT         42960013
         BAL   RR,SC10               POINTER AND RESUME SCAN BY         43000013
         L     IPTR,PAR1             MOVING ASSIGN TO OUTPUT AND        43040013
         BC    B,MB4001              SCANNING FROM NEXT TRIPLE.         43080013
         SPACE 1                                                        43120013
*              MULTIPLE ASSIGNMENT                                      43160013
         SPACE 1                                                        43200013
MB1302   CLC   1(4,IPTR),CNZERO        BRANCH IF BOTH OPERANDS OF THE   43240013
         BC    BNE,MB1303            ASSIGN TRIPLE ARE NOT ZERO         43280013
         BAL   RR,SC4                  BOTH 00. SKIP ASSIGN TRIPLE AND  43320013
         BAL   RR,MVTMPW             PUT TMPDS IN STACK.                43360013
         BC    B,MB1305                                                 43400013
         SPACE 1                                                        43440013
MB1303   CLC   1(2,IPTR),CNZERO        NOT BOTH 00. SEE IF ONE OF THEM  43480013
         BC    BE,MB1304             IS. BRANCH IF FIRST OPERAND 00.    43520013
         SPACE 1                                                        43560013
         CLC   3(2,IPTR),CNZERO                                         43600013
         BC    BNE,MB1310              BRANCH IF NEITHER IS ZERO        43640013
         SPACE 1                                                        43680013
MB1304   BAL   RR,SC4                  SKIP ASSIGN TRIPLE               43720013
         SPACE 1                                                        43760013
MB1305   BAL   RR,MVTMPW               PUT TMPDS IN STACK               43800013
         SPACE 1                                                        43840013
*              NOW RESTORE TEXT POINTER TO FIRST ASSIGNMENT TRIPLE      43880013
         SPACE 1                                                        43920013
MB1310   MVC   PAR1(4),WSTXRF          WSTXRF CONTAINS SYMBOLIC ADDRESS 43960013
         BAL   RR,SC10               OF FIRST ASSIGNMENT TRIPLE         44000013
         L     IPTR,PAR1             ASSOCIATED WITH CURRENT STACK.     44040013
         SPACE 3                                                        44080013
*              SECOND PART OF SECTION                                   44120013
         SPACE 1                                                        44160013
*              THE FOLLOWING SECTION RESCANS THE ASSIGNMENT LIST AND    44200013
*        DEALS TEMPORARIES OFF THE TOP OF THE STACK SO AS TO ASSIGN     44240013
*        IN THE CORRECT SEQUENCE.                                       44280013
         SPACE 1                                                        44320013
         L     PSVR,STKBSE             POINT PSVR AT FIRST PSEUDO-      44360013
*                                    VARIABLE DESCRIPTION (IF ANY)      44400013
       SPACE   1                                                        44440013
MB1311   CLI   0(IPTR),TRASN2          TEST FOR MULTIPLE ASSIGN         44480013
         BC    BE,MB1314                                                44520013
         SPACE 1                                                        44560013
         CLI   0(IPTR),TRASN1          TEST FOR ASSIGN                  44600013
         BC    BE,MB1313                                                44640013
         SPACE 1                                                        44680013
MB1312   BAL   RR,SC5                  IF NEITHER, MUST BE TMPD OR LEFT 44720013
         BC    B,MB1311              DROP IT FROM TEXT                  44760013
         SPACE 1                                                        44800013
*              MULTIPLE ASSIGN                                          44840013
         SPACE 1                                                        44880013
MB1314   OI    SWDROP,X'F0'            SET DROP SWITCH TO PREVENT       44920013
*                                    DROPPING OF RHS REGISTERS          44960013
         SPACE 1                                                        45000013
*              MULTIPLE AND SIMPLE ASSIGN                               45040013
         SPACE 1                                                        45080013
MB1313   CLC   1(2,IPTR),CNZERO                                         45120013
         BC    BE,MB1318               BRANCH IF FIRST OPERAND 00       45160013
         SPACE 1                                                        45200013
         LR    R1,IPTR                 FIRST OPERAND NOT 00. COPY       45240013
         BAL   RR,MMV3A5             TRIPLE INTO OUTPUT                 45280013
         CLC   3(2,IPTR),CNZERO        TEST FOR 00 SECOND OPERAND AND   45320013
         BC    BNE,MB1316            BRANCH IF NOT 00                   45360013
         SPACE 1                                                        45400013
*              OPERAND 2 00. COPY TMPDS FOR RHS FROM STACK              45440013
         L     R1,STKLHS               STKLHS CONTAINS ADDRESS OF RHS   45480013
         BAL   RR,OUTMPD             ENTRY IN STACK                     45520013
         SPACE 1                                                        45560013
*              IF THE TRIPLE WAS MULTIPLE ASSIGN, SKIP IT AND CONTINUE  45600013
*        SCAN FOR ASSIGN. IF TRIPLE WAS ASSIGN, DROP IT AND SUCCEEDING  45640013
*        TMPDS AND RESET SWITCHES. RETURN TO MAIN SCAN.                 45680013
         SPACE 1                                                        45720013
MB1316   CLI   0(IPTR),TRASN1                                           45760013
         BC    BNE,MB1312              BRANCH IF NOT ASSIGN             45800013
         SPACE 1                                                        45840013
MB1317   BAL   RR,SC5                  ASSIGN. SKIP INPUT TEXT TO FIRST 45880013
         CLI   0(IPTR),TRTMPD        TRIPLE FOLLOWING ASSIGN AND        45920013
         BC    BE,MB1317             ASSOCIATED TMPDS.                  45960013
         CLI   0(IPTR),TRLEFT                                           46000013
         BC    BE,MB1317                                                46040013
         SPACE 1                                                        46080013
MB1340   BC    B,MB1341                BRANCH IF SELL SWITCH IS OFF     46120013
SWSELL   EQU   MB1340+1                                                 46160013
         SPACE 1                                                        46200013
         OI    SWSELL,X'F0'            IF SELL SWITCH IS ON, COPY SELL  46240013
         LA    R1,ST03               TRIPLE FROM SAVE SLOT ST03         46280013
         BAL   RR,MMV3A5             RESET SELL SWITCH (THE SOLD ITEM   46320013
*                                   IS THE RHS RESULT FOR WHICH SPACE   46360013
*                                    HAS HAD TO BE BOUGHT               46400013
         SPACE 1                                                        46440013
*              THE FOLLOWING CODE SCANS THE STACK AND PUTS OUT SELL     46480013
*        TRIPLES IN THE CORRECT SEQUENCE                                46520013
         SPACE 1                                                        46560013
MB1341   LH    PSVR,SELSAV             CHECK COUNT OF TEMPS GOT  A32295 46566020
         LTR   PSVR,PSVR               BY STRUT1 TO SEE IF THERE A32295 46572020
         BZ    MB1350                  ARE ANY TO SELL.  NO      A32295 46578020
         LA    STKR,SELSAV             YES. POINT AT HWORD COUNT A32295 46584020
MB1349   LA    STKR,2(STKR)            BUMP TO NEXT TEMP DIC REF A32295 46590020
         MVC   ST03+3(2),0(STKR)       MOVE IT TO SELL SKELETON  A32295 46596020
         LA    R1,ST03                                                  46602020
         BAL   RR,MMV3A5               GO TO OUTPUT SELL         A32295 46608020
         BCT   PSVR,MB1349             LOOP IF THERE ARE MORE    A32295 46614020
         XC    SELSAV(2),SELSAV        OTHERWISE CLEAR HW COUNT  A32295 46620020
         SPACE 1                                                        46626020
MB1350   L     PSVR,MAXSEL                                              46632020
         SPACE 1                                                        46640013
MB1348   LTR   R2,PSVR                 R2 ADDRESSES NEXT END-OF-SELLS.  46680013
         BC    BZ,MB1347             EXIT IF ZERO                       46720013
         SPACE 1                                                        46760013
         L     STKR,STKBSE             GET BASE OF STACK ADDRESS AND    46800013
         SR    PSVR,PSVR             SET NEXT END-OF SELLS TO ZERO.     46840013
         SPACE 1                                                        46880013
MB1342   CR    STKR,R2                 SEE IF END OF SELLS REACHED YET  46920013
         BC    BNL,MB1343            AND BRANCH IF YES.                 46960013
         SPACE 1                                                        47000013
         LA    HR1,1(0,STKR)           EXAMINE STACK ENTRY AND EMERGE   47040013
         CLI   0(STKR),TRPSIP        WITH HR1 ADDRESSING THE NEXT       47080013
         BC    BE,MB1344             ENTRY. SPECIAL EXIT FOR SELLS.     47120013
         LA    HR1,1(0,HR1)            PSI' IS 1 BYTE                   47160013
         CLI   0(STKR),TRPSI           PSI IS 2 BYTES                   47200013
         BC    BE,MB1344                                                47240013
         LA    HR1,3(0,HR1)                                             47280013
         CLI   0(STKR),TRDCOM          DOUBLE COMMA IS 5                47320013
         BC    BE,MB1344                                                47360013
         CLI   0(STKR),TRSELL                                           47400013
         BC    BE,MB1345               SPECIAL EXIT FOR SELL            47440013
         LA    HR1,6(0,HR1)            TMPD IS 11                       47480013
         SPACE 1                                                        47520013
MB1344   LR    STKR,HR1                GO TO LOOK AT NEXT ENTRY         47560013
         BC    B,MB1342                                                 47600013
         SPACE 1                                                        47640013
*              SELL FOUND IN STACK                                      47680013
MB1345   LR    R1,STKR                 R1 IS SET TO ADDRESS THE FIRST   47720013
*                                    SELL IN THE GROUP                  47760013
MB1346   LA    STKR,5(0,STKR)          POINT STKR AT NEXT ENTRY AND     47800013
         CR    STKR,R2               TEST FOR TOP OF SELL STACK. IF     47840013
         BC    BNL,MB1343            TOP GO TO GENERATE TRIPLE OUTPUT   47880013
         SPACE 1                                                        47920013
         CLI   0(STKR),TRSELL          IF NOT TEST FOR SELL ENTRY AND   47960013
         BC    BE,MB1346             CARRY ON SCANNING IF IT IS.        48000013
         SPACE 1                                                        48040013
         LR    PSVR,STKR               OTHERWISE USE CURRENT STACK      48080013
         BC    B,MB1342              POINTER AS NEXT TOP OF SELL STACK  48120013
*                                    AND GO TO LOOK FOR NEXT GROUP.     48160013
         SPACE 1                                                        48200013
*              LAST GROUP FOUND. GENERATE SELL TRIPLES                  48240013
MB1343   SR    R2,R1                   R1 ADDRESSES FIRST SELL, R2 END  48280013
         BAL   RR,MMV3AU               GENERATE TRIPLES.                48320013
         BC    B,MB1348                LOOK FOR NEXT GROUP.             48360013
         SPACE 2                                                        48400013
*              ALL SELLS GENERATED. RESTORE SWITCHES.                   48440013
MB1347   ST    R2,MAXSEL               RESET MAXSEL TO ZERO             48480013
         NI    SWMULT,X'0F'            RESET MULTIPLE ASSIGN            48520013
         NI    SWDROP,X'0F'            RESET DROP SWITCH                48560013
         OI    SWNOPV,X'F0'            SET NO PSEUDO-VARIABLES          48600013
         MVI   SCTRT+TRASN1,0          STOP SCAN FOR ASSIGN.            48640013
         L     STKR,STKBSE             POINT STKR AT THE STACK BASE     48680013
         BC    B,MB0002                RETURN TO SCAN                   48720013
         SPACE 2                                                        48760013
*              LEFT HAND SIDE OF ASSIGNMENT IS DESCRIBED BY AN          48800013
*        INTERMEDIATE RESULT TMPD OR LEFT. TEST FOR PSEUDO-VARIABLE.    48840013
*        IF NOT PSEUDO-VARIABLE COPY ASSIGN TRIPLE AND TMPDS TO OUTPUT. 48880013
         SPACE 1                                                        48920013
MB1318   SH    STKR,CN0011             SET POINTER TO NEXT ELEMENT IN   48960013
         CLI   0(STKR),TRLEFT        STACK AND TEST FOR LEFT. BRANCH    49000013
         BC    BNE,MB1319            IF NOT LEFT                        49040013
         SPACE 1                                                        49080013
         TM    2(STKR),X'FF'           IF LEFT, TEST FRO PSEUDO-VAR     49120013
         BC    BO,MB1320             AND BRANCH IF IT IS.               49160013
         SPACE 1                                                        49200013
MB1319   LR    R1,IPTR                 NOT PSEUDO-VARIABLE. COPY TRIPLE 49240013
         BAL   RR,MMV3A5                                                49280013
         CLC   3(2,IPTR),CNZERO        TEST OPERAND 2 OF ASSIGN TRIPLE  49320013
         BC    BNE,MB1315            AND BRANCH IF NON-ZERO             49360013
         SPACE 1                                                        49400013
         L     R1,STKLHS               IF 00 PUT OUT TMPDS FOR OPERAND  49440013
         BAL   RR,OUTMPD             2                                  49480013
         SPACE 1                                                        49520013
MB1315   LR    R1,STKR                 PUT OUT TMPDS FOR OPERAND 1      49560013
         BAL   RR,OUTMPD                                                49600013
         BC    B,MB1316                GO TO SEE IF MORE ASSIGNS TO     49640013
*                                    BE DONE                            49680013
         SPACE 2                                                        49720013
*              LEFT HAND SIDE OF ASSIGNMENT IS A PSEUDO-VARIABLE. THE   49760013
*        DESCRIPTION IN THE STACK IS ADDRESSED BY PSVR. THE FOLLOWING   49800013
*        SECTION PERFORMS THE AD HOC TREATMENT REQUIRED FOR EACH        49840013
         SPACE 1                                                        49880013
MB1320   CLC   3(2,IPTR),CNZERO        TEST FOR INTERMEDIATE VALUE      49920013
         BC    BE,MB132Z                                                49960001
         SPACE 1                                                        50000013
         LA    R1,3(0,IPTR)            NOT INTERMEDIATE VALUE. POINT    50040013
         BAL   RR,DRFTMP             R1 AT DICT REF AND OBTAIN TMPD     50080013
         MVC   TMPDRH(11),TMPD0        PUT TMPD RETURNED BY DRFTMP INTO 50120013
         LA    R1,TMPDRH             TMPDRH AND POINT STKLMS AT IT      50160013
         ST    R1,STKLHS                                                50200013
         ST    R1,TDBSAVE                                               50220001
         SPACE 1                                                        50240013
MB1321   L     HR1,STKLHS              TEST THE RIGHT-HAND-SIDE         50280013
         CLI   0(HR1),TRTMPD         DESCRIPTION. IF IT IS A LEFT, THEN 50320013
         BC    BE,MB1323             IT CANNOT BE A LEGAL RHS FOR A PSV 50360013
         SPACE 1                                                        50400013
         CLI   0(HR1),TRLEFT           IF IT IS A CONSTANT IT MUST      50440013
         BC    BE,MB1330             BE OTHER THAN FILE OR LABEL        50480013
         SPACE 1                                                        50520013
         CLI   TMPDF2(HR1),DRCON                                        50560013
         BC    BNE,MB1330              BRANCH. ERROR IF NOT DATA CONST. 50600013
         SPACE 1                                                        50640013
MB1323   NI    SWDATA,X'0F'            SET DATA ITEM SWITCH OFF         50680013
         SPACE 2                                                        50720013
*              THE FOLLOWING SECTION IS COMMON TO ASSIGNMENT AND DATA   50760013
*        LIST PSEUDO-VARIABLES. IT SCANS DOWN THE PSEUDO-VARIABLE STACK 50800013
*        LOOKING FOR THE END OF THE CURRENT ENTRY AND SETS PSVNXT       50840013
*        TO ADDRESS THE NEXT ENTRY IF THERE IS ONE. IT THEN BRANCHES    50880013
*        TO A SECTION OF CODE PECULIAR TO THE CURRENT PSEUDO-VARIABLE   50920013
         SPACE 1                                                        50960013
MB1322   MVC   PSVCUR+1(1),1(PSVR)     COPY PV CODE BYTE AND POINT      51000013
         LA    PSVR,2(0,PSVR)        PSVR AT FIRST ARGUMENT             51040013
         LR    HR1,PSVR                                                 51080013
         SPACE 1                                                        51120013
MB1325   CLI   0(HR1),TRPSIP           SCAN DOWN STACK LOOKING FOR      51160013
         BC    BE,MB1326             PSI'                               51200013
         SPACE 1                                                        51240013
         CLI   0(HR1),TRDCOM                                            51280013
         LA    HR1,5(0,HR1)            DOUBLE COMMA, ADD 5              51320013
         BC    BE,MB1325                                                51360013
         LA    HR1,6(0,HR1)            TMPD, ADD 11                     51400013
         BC    B,MB1325                                                 51440013
       SPACE 1                                                          51442001
MB132Z   L     R1,STKLHS                                                51444001
         TM    1(R1),X'C0'             DOES FIELD 5 CONTAIN DIC. REF.   51446001
         BC    BZ,MB132Y             BRANCH ON YES.                     51448001
         TM    1(R1),X'01'             DOES FIELD 6 CONTAIN DIC. REF.   51450001
         BC    BZ,MB1321             BRANCH ON NO.                      51452001
         LA    R1,7(0,R1)              POINT AT DIC. REF.               51454001
         BC    B,MB132W                                                 51456001
MB132Y   TM    6(R1),X'01'   DOES F5 CONTAIN D.R.+1? IF SO IT IS  40099 51456646
         BO    MB1321        A D.V. ENTRY DESCRIBING A VAR STRING 40099 51457246
*                            CAT RESULT. THE ENTRY IS NO USE      40099 51457846
*                            TO DRFTMP. USE TMPD'S UNCHANGED.     40099 51458446
         LA    R1,5(0,R1)              POINT  AT DIC REF.               51459046
MB132W   BAL   RR,DRFTMP             OBTAIN TDB CONTAINING TMPDS        51460001
         MVC   TMPDRH(11),TMPD0                                         51462001
         LA    R1,TMPDRH                                                51464001
         ST    R1,TDBSAVE                                               51466001
         BC    B,MB1321                                                 51468001
         SPACE 1                                                        51480013
MB1326   LA    HR1,1(0,HR1)                                             51520013
         ST    HR1,PSVTGT              SET PSVTGT TO ADDRESS RESULT     51560013
         LA    HR1,11(0,HR1)         TMPD SET UP BY GENERIC PHASE       51600013
MB1329   C     HR1,MAXSEL              IF THIS STACK POINTER IS LESS    51640013
         BC    BNL,MB1324            THAN END OF SELLS LOOK FOR SELLS   51680013
         SPACE 1                                                        51720013
         CLI   0(HR1),TRSELL           IF THE NEXT STACK ENTRY IS A     51760013
         BC    BNE,MB1324            SELL, SKIP OVER IT AND LOOK AT     51800013
         LA    HR1,5(0,HR1)          THE NEXT ENTRY.                    51840013
         BC    B,MB1329                                                 51880013
         SPACE 1                                                        51920013
MB1324   ST    HR1,PSVNXT              PSVNXT SET TO ADDRESS NEXT PSV   51960013
*                                    STACK ENTRY, IF ANY.               52000013
         SPACE 1                                                        52040013
         LH    HR1,PSVCUR              GET CODE AND USE TO BRANCH       52080013
         EX    0,MB1327(HR1)                                            52120013
         SPACE 1                                                        52160013
MB1328   TM    SWDATA,X'F0'            ON RETURN GO TO ASSIGN OR INPUT  52200013
         BC    BNZ,MB1317            LIST SECTION AS REQUIRED           52240013
         SPACE 1                                                        52280013
         L     PSVR,PSVNXT             GET ADDRESS OF NEXT PSEUDO-VAR   52320013
         BC    B,MB1316              IN STACK                           52360013
         SPACE 1                                                        52400013
*              BRANCH TABLE OF ENTRIES TO PSEUDO-VARIABLE ROUTINES      52440013
         SPACE 1                                                        52480013
MB1327   EQU   *-4                                                      52520013
         BAL   RR,MB9000               EVENT                            52560013
         BAL   RR,MB9100               ONSOURCE                         52600013
         BAL   RR,MB9200               ONCHAR                           52640013
         BAL   RR,MB9300               PRIORITY                         52680013
         BAL   RR,MB9400               COMPLEX                          52720013
         BAL   RR,MB9500               IMAG                             52760013
         BAL   RR,MB9600               REAL                             52800013
         BAL   RR,MB9700               UNSPEC                           52840013
         BAL   RR,MB9800               SUBSTRING                        52880013
         BAL   RR,MB9900               STATUS                           52900015
         BAL   RR,MB1000                STRING.                         52910001
         SPACE 2                                                        52920013
*              THE FOLLOWING SECTION IS ENTERED WHEN THE RIGHT HAND     52960013
*        SIDE OF AN ASSIGNMENT IS NOT SUCH THAT IT CAN BE ASSIGNED TO   53000013
*        A PSEUDO-VARIABLE. HR1 ADDRESSES DESCRIPTION OF RHS. DROP ANY  53040013
*        REGISTERS ASSOCIATED WITH RHS, AND WITH THE PSEUDO-VARIABLE    53080013
*        ARGUMENTS. DROP THE ASSIGN AND ANY TMPDS FROM TEXT             53120013
         SPACE 1                                                        53160013
MB1330   LR    R1,HR1                  POINT R1 AT TMPD DESCRIBING RHS  53200013
         BAL   RR,DROP1              AND DROP IF NOT MULTIPLE ASSIGN.   53240013
         SPACE 1                                                        53280013
         L     HR1,ERID03              MAKE ERROR ENTRY 'RHS NOT DATA   53320013
         BAL   RR,ERROR              TYPE WHICH CAN BE ASSIGNED TO PV'  53360013
         SPACE 1                                                        53400013
*              NOW SCAN DOWN STACK LOOKING FOR PSI' AND DROPPING ANY    53440013
*        REGISTERS ON THE WAY.                                          53480013
         SPACE 1                                                        53520013
         LA    PSVR,2(0,PSVR)          POINT PSVR AT FIRST ARGUMENT     53560013
MB1331   CLI   0(PSVR),TRPSIP                                           53600013
         BC    BE,MB1333               BRANCH IF PSI' FOUND             53640013
         SPACE 1                                                        53680013
         CLI   0(PSVR),TRDCOM                                           53720013
         BC    BNE,MB1332                                               53760013
         SPACE 1                                                        53800013
         LA    PSVR,5(0,PSVR)          DOUBLE COMMA. BUMP STACK POINTER 53840013
         BC    B,MB1331              BY 5                               53880013
         SPACE 1                                                        53920013
MB1332   LR    R1,PSVR                 TMPD. DROP REGISTERS AND BUMP    53960013
         BAL   RR,DROP2              STACK POINTER BY 11                54000013
         LA    PSVR,11(0,PSVR)                                          54040013
         BC    B,MB1331                                                 54080013
         SPACE 1                                                        54120013
MB1333   LA    PSVR,12(0,PSVR)         PSI'. BUMP POINTER PAST PSI'     54160013
         BC    B,MB1316              AND TMPD IN STACK, THEN GO TO      54200013
*                                    DROP ASSIGN AND ASSOCIATED TMPDS   54240013
         EJECT                                                          54280013
*                       MULTIPLE ASSIGN                                 54320013
*              FUNCTIONS - THIS SECTION IS ENTERED WHENEVER A MULTIPLE  54360013
*        ASSIGNMENT MARKER IS ENCOUNTERED IN THE SOURCE TEXT.           54400013
*                       (1) IF THIS IS THE FIRST OF A SEQUENCE OF       54440013
*        ASSIGNMENTS (MULTIPLE ASSIGN SWITCH OFF) THEN THE MULTIPLE     54480013
*        ASSIGN SWITCH IS SET ON AND THE POSITION OF THE TRIPLE SAVED   54520013
*        IN SYMBOLIC FORM IN WSTXRF SO THAT THE INPUT POINTER CAN BE    54560013
*        RESTORED TO THIS POINT FOR THE SECOND SCAN.                    54600013
*                      (2) IF THE FIRST OPERAND OF THE TRIPLE IS 00     54640013
*        THEN THE FOLLOWING TMPD IS MOVED INTO THE STACK AS A STANDARD  54680013
*        ELEVEN BYTE ENTRY.                                             54720013
*                      (3) IF THE NEXT TRIPLE (FOLLOWING THE TMPDS IF   54760013
*        ANY) IS A SELL, THEN THE SELL SWITCH IS SET ON AND THE TRIPLE  54800013
*        SAVED IN THE SPECIAL SLOT ST03. THE SELL IN THIS CONTEXT IS    54840013
*        OF THE SOURCE DATUM . IT APPEARS AT THIS POINT IN THE INPUT    54880013
*        BECAUSE THE EXPRESSION EVALUATION PHASE GENERATES IT AFTER     54920013
*        THE FIRST USE OF THE SOURCE. THE TRIPLE IS HELD IN ST03 UNTIL  54960013
*        THE END OF THE SECOND SCAN OF THE ASSIGNMENT, AND IS THEN      55000013
*        REGURGITATED FOLLOWING THE LAST ASSIGNMENT.                    55040013
*                                                                       55080013
*              NOTES - DURING THE FIRST SCAN OF THE SEQUENCE OF         55120013
*        ASSIGNMENTS IT IS NECESSARY TO USE SC4 INSTEAD OF SC5 TO       55160013
*        SKIP TRIPLES TO AVOID FREEING THE INPUT TEXT BLOCK.            55200013
         SPACE 1                                                        55240013
MB0014   TM    SWMULT,X'F0'                                             55280013
         BC    BNZ,MB1401              BRANCH IF ALREADY MET MULT. ASS. 55320013
         SPACE 1                                                        55360013
         ST    STKR,STKLHS             FIRST MULT. ASS. TRIPLE. SAVE    55400013
         ST    IPTR,PAR2             STACK POINTER VALUE (POINTS TO     55440013
         MVC   PAR1(4),SCTXTI        END OF ANY PSEUDO-VARIABLE         55480013
         L     LR,ZTXROF             DESCRIPTIONS). SAVE SYMBOLIC TEXT  55520013
         BALR  RR,LR                 REFERENCE.                         55560013
         MVC   WSTXRF(4),PAR1                                           55600013
         OI    SWMULT,X'F0'            SET MULT. ASS. SWITCH ON         55640013
         MVI   SCTRT+TRASN1,L          START SCAN FOR ASSIGN            55680013
         SPACE 1                                                        55720013
*              IF TRIPLE IS FOLLOWED BY TMPDS, MOVE THESE TO THE STACK  55760013
MB1401   CLC   1(2,IPTR),CNZERO                                         55800013
         BC    BNZ,MB1402              BRANCH IF NO TMPDS FOLLOWING     55840013
         SPACE 1                                                        55880013
         BAL   RR,SC4                  TMPDS FOLLOWING. SKIP MULTIPLE   55920013
         BAL   RR,MVTMPW             ASSIGN TRIPLE AND MOVE TMPDS TO    55960013
*                                    STACK                              56000013
         BC    B,MB1403                GO TO TEST FOR SELL              56040013
         SPACE 1                                                        56080013
MB1402   BAL   RR,SC4                  SKIP MULTIPLE ASSIGN TRIPLE      56120013
MB1403   CLI   0(IPTR),TRSELL          IF SUCCESSOR TRIPLE IS A SELL    56160013
         BC    BNE,MB0002            IT MUST BE SAVED AND SUBSEQUENTLY  56200013
*                                    PUT OUT AT THE END OF THE ASSIGNS  56240013
*                                    RETURN TO SCAN IF NOT              56280013
         MVC   ST03(5),0(IPTR)         IF IT IS A SELL IT MUST BE       56320013
         NI    SWSELL,X'0F'          PRESERVED AND PUT OUT AT THE END   56360013
*                                    OF THE MULTIPLE ASSIGNMENTS        56400013
*                                      FALL THROUGH TO DROP SELL        56440013
         SPACE 1                                                        56480013
         BAL   RR,SC4                  SKIP SELL TRIPLE AND RETURN TO   56520013
         BC    B,MB0002              SCAN                               56560013
         EJECT                                                          56600013
*                       DATA LIST DELIMITER TRIPLES                     56640013
*              FUNCTIONS - THIS SECTION IS ENTERED WHENEVER A DATA      56680013
*        LIST DELIMITER IS ENCOUNTERED IN THE INPUT TEXT. THE 'NOT-     56720013
*        DATA-LIST' SWITCH IS SET OFF FOR LIST, DATA AND EDIT TRIPLES   56760013
*        AND IS SET ON FOR LIST', DATA' AND EDIT' TRIPLES               56800013
*                                                                       56840013
*              ENTRY POINTS - MB0015. LIST,DATA,EDIT                    56880013
*                             MB0016. LIST',DATA',EDIT'                 56920013
         SPACE 1                                                        56960013
MB0015   NI    SWNODL,X'0F'            RESET SWITCH, PASS TRIPLE INTO   57000013
         BAL   RR,SC2                OUTPUT AND SCAN FROM NEXT TRIPLE   57040013
         BC    B,MB0003                                                 57080013
         SPACE 1                                                        57120013
MB0016   OI    SWNODL,X'F0'            SET SWITCH, PASS TRIPLE INTO     57160013
         BAL   RR,SC2                OUTPUT AND SCAN FROM NEXT TRIPLE   57200013
         BC    B,MB0003                                                 57240013
         EJECT                                                          57280013
*                       BUY/ASSIGN                                      57320013
*              FUNCTIONS - THIS SECTION IS ENTERED WHENEVER A           57360013
*        BUY/ASSIGN IS FOUND BETWEEN PSEUDO VARIABLE DELIMITERS.        57400013
*                      (1) IF THE LEVEL COUNT OF FUNCTION MARKERS IS    57440013
*        NON-ZERO, THEN THE ARGUMENT MUST BE OF A FUNCTION, NOT THE     57480013
*        PSEUDO-VARIABLE. THE TRIPLE IS PASSED INTO THE OUTPUT TEXT     57520013
*        AND OTHERWISE IGNORED                                          57560013
*                      (2) IF THE FUNCTION LEVEL COUNT IS ZERO, THE     57600013
*        THIS TRIPLE AND ITS SUCCESSOR REPRESENT A PSEUDO-VARIABLE      57640013
*        ARGUMENT, PROVIDED THE SUCCESSOR IS A DOUBLE COMMA. A CHECK    57680013
*        IS MADE FOR THIS AND IF NOT A DOUBLE COMMA THE CURRENT TRIPLE  57720013
*        IS PASSED INTO THE OUTPUT AND OTHERWISE IGNORED                57760013
*              IF THE SUCCESSOR IS A DOUBLE COMMA THEN AN ARGUMENT      57800013
*        HAS BEEN FOUND. A TEST IS MADE TO SEE WHETHER IT SHOULD BE     57840013
*        A VARIABLE OR AN INDEX. IF AN INDEX THE DOUBLE COMMA ARGUMENT  57880013
*        IS USED TO MAKE A STACK ENTRY AND THE BUY/ASSIGN TRIPLE IS     57920013
*        MOVED INTO THE OUTPUT TEXT. IF A VARIABLE, THEN THE            57960013
*        GENERIC PHASE HAS HAD TO CONVERT THE ARGUMENT BY VIRTUE OF     58000013
*        OF ITS COMMON TREATMENT OF PSEUDO-VARIABLES AND FUNCTIONS.     58040013
*        FOR PRESENT PURPOSES IT IS NECESSARY TO REVERT TO THE ORIGINAL 58080013
*        ARGUMENT BY USING THE SOURCE OF THE BUY/ASSIGN AS THE ARGUMENT 58120013
*        AND DELETING THE ASSIGNMENT.                                   58160013
         SPACE 1                                                        58200013
MB0020   CLC   PSVLVL(4),CNZERO        TEST LEVEL COUNT AND GO TO PASS  58240013
         BC    BNE,MB2002            TRIPLE DIRECTLY TO OUTPUT IF NOT   58280013
*                                    LEVEL 1.                           58320013
*              SCAN AHEAD FOR DOUBLE COMMA                              58360013
         ST    IPTR,PAR2               CONVERT INPUT ADDRESS TO SYMBOL  58400013
         MVC   PAR1(4),SCTXTI        TEXT ADDRESS                       58440013
         L     LR,ZTXROF                                                58480013
         BALR  RR,LR                                                    58520013
         MVC   WS55(4),PAR1            WS55= REQUIRED TEXT REFERENCE    58560013
         SPACE 1                                                        58600013
         CLC   3(2,IPTR),CNZERO                                         58640013
         BC    BNE,MB2005                                               58680013
         SPACE 1                                                        58720013
         BAL   RR,SC4                  SKIP OVER ONE (DICTIONARY REF)   58760013
         TM    TMPDF1(IPTR),TMPLO    THREE (INTERMEDIATE RESULT) OR     58800013
         BC    BZ,MB2003             FOUR (INTERMEDIATE RESULT WITH     58840013
         BAL   RR,SC4                LITTERAL OFFSET) TRIPLES, MARKING  58880013
MB2003   BAL   RR,SC4                TEXT AS STILL WANTED.              58920013
MB2005   BAL   RR,SC4                  NOW TEST FOR DOUBLE              58960013
*                                    COMMA                              59000013
         NI    SWDCOM,X'0F'            SET DOUBLE COMMA SWITCH ON       59040013
         CLI   0(IPTR),TRDCOM                                           59080013
         BC    BE,MB2006               BRANCH IF DOUBLE COMMA           59120013
         SPACE 1                                                        59160013
         OI    SWDCOM,X'F0'            SET DOUBLE COMMA SWITCH OFF      59200013
*              RESTORE TEXT POINTER                                     59240013
MB2006   MVC   PAR1(4),WS55            USE SC10 AND SYMBOLIC TEXT       59280013
         BAL   RR,SC10               REFERENCE IN WS55                  59320013
         L     IPTR,PAR1                                                59360013
         SPACE 1                                                        59400013
MB2007   BC    B,MB2002                BRANCH TO PUT ASSIGN IN OUTPUT   59440013
SWDCOM   EQU   MB2007+1              AND OTHERWISE IGNORE IF THERE WAS  59480013
*                                    NO DOUBLE COMMA                    59520013
         SPACE 1                                                        59560013
*              DOUBLE COMMA FOLLOWING ASSIGN. FIND OUT WHAT SORT OF     59600013
*        ARGUMENT THIS IS.                                              59640013
*              ENTRY FROM IGNORE SECTION                                59680013
         SPACE 1                                                        59720013
MB2050   LH    HR1,PSVCUR              GET CURRENT PSEUDO-VARIABLE      59760013
         SRL   HR1,1                 CODE, HALVE IT AND PICK UP ENTRY   59800013
         LH    HR1,PSDSC1-2(HR1)     IN DESCRIPTION TABLE 1             59840013
         LTR   HR1,HR1                                                  59880013
         BC    BZ,MB2010               BRANCH IF ALL VARIABLES          59920013
         SPACE 1                                                        59960013
         LH    HR0,PSVCNT              NOT ALL VARIABLES. PICK UP ARG.  60000013
         LA    HR1,PSDSC2(HR1)       COUNT AND TABLE 2 ENTRY AND LOOK   60040013
         LH    HR2,0(HR1)            FOR MATCH.                         60080013
         SPACE 1                                                        60120013
MB2008   CH    HR0,0(HR1,HR2)                                           60160013
         BC    BE,MB2020               BRANCH ON MATCH (ARGUMENT IS AN  60200013
         BCTR  HR2,0                 INDEX)                             60240013
         BCT   HR2,MB2008              FALL THROUGH IF NOT INDEX        60280013
         SPACE 1                                                        60320013
*              ARGUMENT IS VARIABLE.                                    60360013
         SPACE 1                                                        60400013
MB2010   ST    STKR,WSSTKR             SAVE CURRENT STACK REGISTER      60440013
         LA    R1,SC5                POINTER AND POINT R1 AT SC5        60480013
         CLI   0(IPTR),TRIGNR          TEST FOR IGNORE AND BRANCH IF    60520013
         BC    BNE,MB2014            NOT, OTHERWISE DELETE TRIPLE AND   60560013
         BAL   RR,SC5                POINT R1 AT MB2013.                60600013
         LA    R1,MB2013                                                60640013
         SPACE 1                                                        60680013
MB2014   CLC   3(2,IPTR),CNZERO        TEST FOR 00 OPERAND IN THE       60720013
         BC    BNE,MB2011            ASSIGN. BRANCH IF NOT              60760013
         SPACE 1                                                        60800013
         BAL   RR,SC5                  SKIP THE ASSIGN, MOVE TMPDS TO   60840013
         BAL   RR,MVTMPD             STACK, SKIP THE DOUBLE COMMA AND   60880013
         BC    B,MB2012              INCREMENT ARGUMENT COUNT           60920013
         SPACE 1                                                        60960013
*              NON-ZERO OPERAND IN ASSIGN                               61000013
MB2011   MVI   0(IPTR),TRDCOM          CHANGE ASSIGN TO DOUBLE COMMA    61040013
         MVC   0(5,STKR),0(IPTR)     COPY TRIPLE TO STACK. UPDATE STACK 61080013
         LA    STKR,5(0,STKR)        POINTER.                           61120013
         SPACE 1                                                        61160013
         BAL   RR,SC5                  SKIP DOUBLE COMMA AND ASSIGN     61200013
MB2012   BALR  RR,R1                   CALL SC5 (BUY/ASSIGN) OR FALL    61240013
*                                    THROUGH TO NEXT INSTRN. (IGNORE)   61280013
MB2013   LH    HR1,PSVCNT              INCREMENT ARGUMENT COUNT         61320013
         LA    HR1,1(0,HR1)                                             61360013
         STH   HR1,PSVCNT                                               61400013
         SPACE 1                                                        61440013
*              NOW TEST ARGUMENT TO ENSURE THAT IT WAS NOT AN           61480013
*        EXPRESSION OR FUNCTION                                         61520013
         SPACE 1                                                        61560013
         L     R1,WSSTKR               POINT AT STACK ENTRY JUST MADE   61600013
         CLI   0(R1),TRDCOM            TEST FOR DOUBLE COMMA AND        61640013
         BC    BNE,MB2015            BRANCH IF NOT                      61680013
         SPACE 1                                                        61720013
         MVC   PAR1+2(2),3(R1)         DOUBLE COMMA. GET DICTIONARY     61760013
MB2017   L     LR,ZRFAOF             ENTRY OF ARGUMENT AND TEST TO      61800013
         BALR  RR,LR                 SEE IF IT IS A TEMPORARY.          61840013
         L     HR1,PAR1                                                 61880013
         TM    DEOT4(HR1),X'60'                                         61920013
         BC    BZ,MB0002               RETURN TO SCAN IF NOT TEMP.      61960013
         SPACE 1                                                        62000013
MB2016   OI    SWERR,X'F0'             IF TEMP OR EXPRESSION RESULT     62040013
         BC    B,MB0002              SET ERROR SWITCH IN PSI' SECTION   62080013
*                                    AND RETURN TO SCAN                 62120013
         SPACE 1                                                        62160013
MB2015   CLI   0(R1),TRTMPD            NOT DOUBLE COMMA - MUST BE LEFT  62200013
         BC    BNE,MB0002            OR TMPD. RETURN TO SCAN IF NOT     62240013
*                                    TMPD                               62280013
         TM    TMPDF1(R1),X'C0'        FOR TMPD DESCRIMINATE BETWEEN    62320013
         BC    BZ,MB2018             WORKSPACE ,REGISTER BY NAME/VALUE  62360013
         BC    BO,MB2019             AND DICTIONARY REFERENCE           62400013
         SPACE 1                                                        62440013
         TM    TMPDF1(R1),X'40'        REGISTER BY NAME OR VALUE        62480013
         BC    BNZ,MB0002            RETURN TO SCAN IF BY NAME          62520013
         BC    B,MB2016              ERROR IF BY VALUE                  62560013
         SPACE 1                                                        62600013
MB2019   TM    TMPDF2(R1),DATCAD       WORKSPACE OFFSET. THIS CAN BE    62640013
         BC    BNZ,MB2016            VALID ONLY IF THE ARGUMENT IS A    62680013
         TM    TMPDF1(R1),X'01'      STRING AND THERE IS A DICT REF     62720013
         BC    BZ,MB2016             IN FIELD 6 OF THE TMPD.            62760013
         SPACE 1                                                        62800013
         MVC   PAR1+2(2),TMPDF6(R1)    CHECK THAT REF IN FIELD 6 IS     62840013
         BC    B,MB2017              NOT THAT OF A TEMPORARY.           62880013
         SPACE 1                                                        62920013
MB2018   TM    TMPDF1(R1),X'30'                                         62960001
         BC    BZ,MB2016             ONLY IN CONJUNCTION WITH AN INDEX  63000013
*                                    REGISTER, AND IN THAT CASE THE     63040013
         MVC   PAR1+2(2),TMPDF5(R1)  DICTIONARY ENTRY MAY NOT BE THAT   63080013
         BC    B,MB2017              OF A TEMPORARY.                    63120013
         SPACE 2                                                        63160013
*              ARGUMENT IS INDEX                                        63200013
         SPACE 1                                                        63240013
MB2020   CLI   0(IPTR),TRIGNR          IF CURRENT TRIPLE IS IGNORE      63280013
         BC    BE,MB2101             RETURN TO IGNORE SECTION           63320013
         SPACE 1                                                        63360013
MB2022   LR    R1,IPTR                 COPY TRIPLE INTO OUTPUT AND      63400013
         BAL   RR,MMV3A5             DROP FROM INPUT                    63440013
         BAL   RR,SC5                                                   63480013
         CLI   0(IPTR),TRDCOM                                           63520013
         BC    BNE,MB2022              FALL THROUGH ON DOUBLE COMMA     63560013
         SPACE 1                                                        63600013
MB2021   MVC   0(5,STKR),0(IPTR)       MOVE DOUBLE COMMA INTO STACK     63640013
         LA    STKR,5(0,STKR)                                           63680013
         BAL   RR,SC5                  DROP TRIPLE AND GO TO            63720013
         BC    B,MB2013              UPDATE COUNT                       63760013
         EJECT                                                          63800013
*                       IGNORE                                          63840013
*              FUNCTIONS - THIS SECTION IS ENTERED WHENEVER AN IGNORE   63880013
*        TRIPLE IS ENCOUNTERED BETWEEN PSEUDO-VARIABLE DELIMITER        63920013
*        TRIPLES. THE VALUE OF THE FUNCTION LEVEL COUNT IS CHECKED      63960013
*        AND-          (1) IF NON-ZERO THE IGNORE BELONGS TO THE        64000013
*        DEFINITION OF A FUNCTION ARGUMENT AND IS PASSED THROUGH TO     64040013
*        THE OUTPUT TEXT.                                               64080013
*                      (2) IF ZERO THE IGNORE BELONGS TO AN IGNORE-     64120013
*        DOUBLE COMMA PAIR DEFINING AN ARGUMENT OF THE PSEUDO-VARIABLE. 64160013
*        THE IGNORE IS DROPPED FROM THE TEXT AND THE DOUBLE COMMA       64200013
*        TRIPLE MOVED INTO THE STACK AND REMOVED FROM THE TEXT.         64240013
         SPACE 1                                                        64280013
MB0021   CLC   PSVLVL(4),CNZERO        IF NOT AT LEVEL 1 GO TO PASS     64320013
         BC    BNE,MB2002            TRIPLE TO OUTPUT AND RESUME SCAN   64360013
         BC    B,MB2050                GO TO IDENTIFY ARGUMENT TYPE     64400013
*                                    AND CHECK FOR EXPRESSIONS          64440013
         SPACE 1                                                        64480013
MB2101   BAL   RR,SC5                  RETURN FROM BUY/ASSIGN SECTION   64520013
*                                    FOR INDEX. DROP IGNORE LOOK AT ,,  64560013
         CLC   3(2,IPTR),CNZERO        AT LEVEL 1 TEST FOR 00 ARGUMENT  64600013
         BC    BNE,MB2021            BRANCH IF NOT                      64640013
         SPACE 1                                                        64680013
         BAL   RR,SC5                  INTERMEDIATE VALUE OPERAND. SKIP 64720013
         BAL   RR,MVTMPD             DOUBLE COMMA, PLACE TMPD IN STACK  64760013
         BC    B,MB2013              THEN GO TO BUMP ARGUMENT COUNT     64800013
*                       FUNCTION, FUNCTION'                             64840013
*              FUNCTIONS - THIS SECTION IS ENTERED WHENEVER A FUNCTION  64880013
*        DELIMITER TRIPLE IS ENCOUNTERED BETWEEN PSEUDO-VARIABLE        64920013
*        DELIMITERS. THE FUNCTION LEVEL COUNT WHICH IS MAINTAINED IN    64960013
*        SUCH REGIONS TO FACILITATE DISTINCTION BETWEEN FUNCTION AND    65000013
*        PSEUDO-VARIABLE ARGUMENTS IS INCREASED (FUNCTION) OR REDUCED   65040013
*        (FUNCTION') BY ONE.                                            65080013
         SPACE 1                                                        65120013
MB0022   L     HR1,PSVLVL              ADD 1 TO LEVEL                   65160013
         LA    HR1,1(0,HR1)                                             65200013
MB2001   ST    HR1,PSVLVL                                               65240013
MB2002   BAL   RR,SC2                  PASS MARKER TO OUTPUT AND SCAN   65280013
         BC    B,MB0003              FROM NEXT TRIPLE                   65320013
         SPACE 1                                                        65360013
MB0023   L     HR1,PSVLVL              SUBTRACT 1 FROM LEVEL            65400013
         BCTR  HR1,0                                                    65440013
         BC    B,MB2001                                                 65480013
         EJECT                                                          65520013
*                       BLOCK TRIPLES                                   65560013
         SPACE 1                                                        65600013
*              THIS SECTION IS ENTERED WHENEVER A BLOCK DEMARCATION     65640013
*        TRIPLE IS ENCOUNTERED IN THE SOURCE TEXT.                      65680013
*        ACTION.  LEVEL AND COUNT NUMBERS FOR THE BLOCK JUST ENTERED    65720013
*        ARE EXTRACTED AND KEPT IN A SLOT IN THE PHASE.                 65760013
         SPACE 1                                                        65800013
MB0040   EQU   *                                                        65840013
MB0041   EQU   *                                                        65880013
MB0042   EQU   *                                                        65920013
MB0043   LH    HR1,SCBLK               GET CURRENT BLOCK REF.           65960013
         LTR   HR1,HR1                                                  66000013
         BC    BZ,MB4001               BRANCH IF ZERO                   66040013
         SPACE 1                                                        66080013
         STH   HR1,PAR1+2              IF NON-ZERO GET DICTIONARY ENTRY 66120013
         L     LR,ZRFAOF             OF ET1 AND COPY LEVEL AND COUNT    66160013
         BALR  RR,LR                                                    66200013
         L     HR1,PAR1                                                 66240013
         MVC   WSLVCT(2),DEETLC(HR1)                                    66280013
         SPACE 1                                                        66320013
MB4001   BAL   RR,SC2                  PASS TRIPLE INTO OUTPUT AND      66360013
         BC    B,MB0003              SCAN FROM NEXT.                    66400013
         EJECT                                                          66440013
*                       SUBROUTINE SWITCH                               66480013
         SPACE 1                                                        66520013
*              THIS SUBROUTINE SWITCHES THE TRT TABLE ENTRIES FOR       66560013
*        FUNCTION, FUNCTION', IGNORE, FUNNY ASSIGN AND ASSIGN           66600013
         SPACE 1                                                        66640013
SWITCH   XI    SCTRT+TRALAS,A1                                          66680013
         XI    SCTRT+TRIGNR,A2                                          66720013
         XI    SCTRT+TRFUN,A3                                           66760013
         XI    SCTRT+TRFUNP,A4                                          66800013
         BCR   B,RR                    RETURN                           66840013
         EJECT                                                          66880013
*                       SUBROUTINE MVTMPD/MVTMPW                        66920013
         SPACE 1                                                        66960013
*              THIS SUBROUTINE COPIES TMPDS FROM INPUT TEXT TO STACK.   67000013
*        INPUT. STKR POINTS TO THE NEXT BYTE IN THE STACK               67040013
*               IPTR POINTS TO THE FIRST TRIPLE                         67080013
*        OUTPUT. ELEVEN BYTES ARE PLACED IN THE STACK, THE FIRST BEING  67120013
*        TMPD OR LEFT, THE REST BEING THE STANDARD 10.                  67160013
*               STKR AND IPTR ARE UPDATED                               67200013
*              MVTMPD SKIPS TMPDS AND MARKS THE BLOCK FREE (SC5)        67240013
*              MVTMPW SKIPS TMPDS BUT MARKS THE BLOCK WANTED (SC4)      67280013
         SPACE 1                                                        67320013
MVTMPD   LA    LR,SC5                  MVTMPD ENTRY - USE SC5           67360013
         BC    B,MB5002                                                 67400013
         SPACE 1                                                        67440013
MVTMPW   LA    LR,SC4                  MVTMPW ENTRY - USE SC4           67480013
         SPACE 1                                                        67520013
MB5002   ST    RR,WSRR01               SAVE RETURN REGISTER             67560013
         ST    LR,WSLR01               STORE LR                         67600013
         MVC   0(5,STKR),0(IPTR)       MOVE LEFT OR TMPD TRIPLE TO      67640013
         L     LR,WSLR01                                                67680013
         BALR  RR,LR                 STACK. SKIP OVER THE TRIPLE        67720013
         MVC   5(4,STKR),1(IPTR)       MOVE CONTENS TO SUCCESSOR        67760013
         L     LR,WSLR01                                                67800013
         BALR  RR,LR                 TRIPLE TO STACK AND SKIP OVER      67840013
*                                    THAT TRIPLE TOO                    67880013
         TM    1(STKR),TMP3            TEST THREE TMPD BIT IN FIRST     67920013
         BC    BZ,MB5001             TMPD. BRANCH IF ONLY TWO           67960013
         SPACE 1                                                        68000013
         MVC   9(2,STKR),1(IPTR)       MOVE FIELD FROM THIRD TMPD AND   68040013
         L     LR,WSLR01                                                68080013
         BALR  RR,LR                 SKIP OVER IT.                      68120013
         SPACE 1                                                        68160013
MB5001   LA    STKR,11(0,STKR)         UPDATE STACK POINTER. RESTORE    68200013
         L     RR,WSRR01             RETURN REGISTER AND RETURN         68240013
         BCR   B,RR                                                     68280013
         EJECT                                                          68320013
*                       SUBROUTINES MMV35, MMV3U (PSEUDO-CODE MOVE)     68360013
         SPACE 1                                                        68400013
*              THESE SUBROUTINES SET UP CALLS TO THE SCAN ROUTINE MV3   68440013
*        INPUT. R1 ADDRESSES TEXT, R2 CONTAINS LENGTH (MMV3U ONLY)      68480013
         SPACE 1                                                        68520013
MMV35    LA    R2,5                    SET TEXT LENGTH TO 5             68560013
         SPACE 1                                                        68600013
MMV3U    LA    LR,MV3                  GET ENTRY ADDRESS OF MV3         68640013
         BC    B,MB5101                                                 68680013
         SPACE 2                                                        68720013
*                       SUBROUTINES MMV3A5, MMV3AU (TRIPLE MOVE)        68760013
         SPACE 1                                                        68800013
*              THESE SUBROUTINES SET UP CALLS TO THE SCAN ROUTINE MV3A  68840013
*        INPUT. R1 ADDRESSES TEXT, R2 CONTAINS LENGTH (MMV3AU ONLY)     68880013
         SPACE 1                                                        68920013
MMV3A5   LA    R2,5                    SET TEXT LENGTH TO 5             68960013
         SPACE 1                                                        69000013
MMV3AU   LA    LR,MV3A                 GET ENTRY ADDRESS OF MV3A        69040013
         SPACE 1                                                        69080013
MB5101   ST    R1,PAR1                 SET UP PAR1 AND PAR2             69120013
         ST    R2,PAR2                                                  69160013
         ST    RR,WSRR01                                                69200013
         BALR  RR,LR                                                    69240013
         L     RR,WSRR01                                                69280013
         BCR   B,RR                    RETURN                           69320013
         EJECT                                                          69360013
*                       SUBROUTINE OUTMPD                               69400013
         SPACE 1                                                        69440013
*              THIS SUBROUTINE MOVES TMPDS AND LEFTS INTO THE OUTPUT    69480013
*        TEXT.                                                          69520013
*        INPUT. R1 ADDRESSES AN 11 BYTE DESCRIPTOR AS USED IN THE       69560013
*        STACK                                                          69600013
         SPACE 1                                                        69640013
OUTMPD   ST    RR,WSRR02               SAVE RETURN REGISTER             69680013
         LR    HR1,R1                  SAVE R1                          69700015
         MVC   ST00(5),0(R1)           COPY FIRST LEFT OR TMPD. NEXT    69720013
         MVC   ST01+1(4),5(R1)       FOUR CHARACTERS FORM SECOND TMPD   69760013
         LA    R2,10                                                    69800013
         TM    1(R1),TMP3              TEST FOR THREE TMPDS AND BRANCH  69840013
         BC    BZ,MB5201             IF ONLY TWO                        69880013
         SPACE 1                                                        69920013
         MVC   ST02+1(2),9(R1)         COPY THIRD TMPD FIELD AND SET    69960013
         LA    R2,15                 COUNT TO 15                        70000013
MB5201   LA    R1,ST00                 POINT R1 AT TMPDS AND MOVE TO    70040013
         BAL   RR,MMV3AU             OUTPUT                             70080013
         LR    R1,HR1                  RESTORE R1                       70100015
         L     RR,WSRR02               RESTORE AND RETURN               70120013
         BCR   B,RR                                                     70160013
         EJECT                                                          70200013
*                       SUBROUTINE ARGTMP                               70240013
         SPACE 1                                                        70280013
*              THIS SUBROUTINE CREATES AN ELEVEN BYTE TMPD FOR          70320013
*        ARGUMENTS OF PSEUDO-VARIABLES                                  70360013
*        INPUT.  R1 ADDRESSES PSEUDO-VARIABLE ARGUMENT STACK ENTRY      70400013
*        OUTPUT. TMPD0 CONTAINS TMPD. CODE BYTE IS TMPD FOR DATA        70440013
*        VARIABLE, LEFT FOR TASK,EVENT OR FILE VARIABLE, ZERO FOR CONST 70480013
         SPACE 1                                                        70520013
ARGTMP   CLI   0(R1),TRDCOM                                             70560013
         BC    BE,MB5301               BRANCH IF COMMA IN STACK         70600013
         SPACE 1                                                        70640013
         MVC   TMPD0(11),0(R1)         NOT COMMA OR PSI'. COPY TMPD     70680013
         LA    R1,11(0,R1)             POINT R1 AT NEXT ARGUMENT        70720013
         BCR   B,RR                    RETURN                           70760013
         SPACE 1                                                        70800013
MB5301   ST    RR,WSRR02               COMMA. SAVE RETURN REGISTER      70840013
         LA    R1,3(0,R1)            POINT R1 AT DICT REF AND CALL      70880013
         BAL   RR,DRFTMP             DRFTMP TO OBTAIN TMPD              70920013
         LA    R1,2(0,R1)              POINT R1 AT NEXT ARGUMENT        70960013
         L     RR,WSRR02               RESTORE AND RETURN               71000013
         BCR   B,RR                                                     71040013
         EJECT                                                          71080013
*                       SUBROUTINE DRFTMP                               71120013
         SPACE 1                                                        71160013
*              THIS SUBROUTINE GENERATES AN ELEVEN BYTE TMPD FROM A     71200013
*        DICTIONARY REFERENCE.                                          71240013
*        INPUT.  R1 ADDRESSES 2 BYTE DICT REF                           71280013
*        OUTPUT. TMPD0 CONTAINS THE CONSTRUCTED TMPD                    71320013
         SPACE 1                                                        71360013
DRFTMP   ST    RR,WSRR01               SAVE RETURN REGISTER             71400013
         XC    TMPD0(11),TMPD0         CLEAR TMPD0                      71440013
         MVC   TMPD0+TMPDF5(2),0(R1)   COPY DICT REF INTO TMPD0 FIELD 5 71480013
         MVC   PAR1+2(2),0(R1)       AND PAR1                           71520013
         L     LR,ZRFAOF                                                71560013
         BALR  RR,LR                   GET DICT ENTRY                   71600013
         L     HR1,PAR1                                                 71640013
         SPACE 1                                                        71680013
         TM    0(HR1),X'0F'            TEST FOR DATA VARIABLE. BRANCH   71720013
         BC    BNO,MB5402            IF IT IS NOT.                      71760013
         SPACE 1                                                        71800013
         MVI   TMPD0,TRTMPD            SET TMPD AND COPY DED            71840013
         MVC   TMPD0+TMPDF2(3),DEDATA(HR1)                              71880013
         TM    TMPD0+TMPDF2,DATNNF     TEST FOR PICTURE AND BRANCH IF   71920013
         BC    BNZ,MB5401            NONE.                              71960013
         MVC   TMPD0+TMPDF2+1(2),DEPIC(HR1)      FOR PICTURE CASE       72000013
*                                    COPY PICTURE REF INTO TMPD.        72040013
         SPACE 1                                                        72080013
MB5401   L     RR,WSRR01               RESTORE AND RETURN               72120013
         BCR   B,RR                                                     72160013
         SPACE 1                                                        72200013
MB5402   TM    0(HR1),X'07'            NOT DATA VARIABLE. TEST FOR      72240013
         BC    BNZ,MB5403            CONSTANT.                          72280013
         SPACE 1                                                        72320013
         MVI   TMPD0,0                 ENTRY IS FILE, LABEL OR NUMERIC  72360013
         MVC   TMPD0+2(1),0(HR1)     CONSTANT. MAKE SPECIAL TMPD WITH   72400013
*                                    ZERO CODE.                         72440013
         BC    B,MB5401                RETURN                           72480013
         SPACE 1                                                        72520013
MB5403   MVI   TMPD0,TRLEFT            LABEL, FILE, EVENT OR TASK       72560013
         IC    HR2,0(0,HR1)          VARIABLE. GET CODE BYTE FROM       72600013
         N     HR2,CN000F            TABLE AND INSERT IN TMPD FIELD 2   72640013
         IC    HR2,LFTCOD(HR2)                                          72680013
         STC   HR2,TMPD0+TMPDF2                                         72720013
         BC    B,MB5401                                                 72760013
         EJECT                                                          72800013
*                       SUBROUTINE GETWKS                               72840013
         SPACE 1                                                        72880013
*              THIS SUBROUTINE EXAMINES THE DATA DESCRIPTION IN THE     72920013
*        TEMPORARY DESCRIPTOR. IT DETERMINES BOTH THE AMOUNT AND THE    72960013
*        ALIGNMENT OF WORKSPACE REQUIRED, UPDATES THE SCAN WORKSPACE    73000013
*        SLOT AND SETS UP TMPD0 TO INDICATE USE OF WORKSPACE.           73040013
*        INPUT. R1 ADDRESSES A TEMPORARY DESCRIPTOR                     73080013
         SPACE 1                                                        73120013
GETWKS   ST    RR,WSRR02               SAVE RETURN REGISTER             73160013
         CLI   0(R1),TRTMPD            ABORT IF TMPD IS NOT A DATA      73200013
         BC    BNE,MBABT1            DESCRIPTOR I.E. IF IT DESCRIBES    73240013
*                                    A CONSTANT, FILE, EVENT, TASK OR   73280013
*                                    LABEL                              73320013
         TM    TMPDF2(R1),DATCAD       FIELD 2 OF TMPD CONTAINS DATA    73360013
         BC    BZ,MB5501             BYTE. TEST FOR ARITHMETIC OR       73400013
*                                    STRING. BRANCH IF STRING           73440013
*              ARITHMETIC DATUM                                         73480013
         BAL   RR,CADNFL               GET LENGTH OF DATUM AND LOAD     73520013
         LH    HR1,LENGTH            INTO HR1                           73560013
         SPACE 1                                                        73600013
         TM    TMPDF2(R1),DATFXD       TEST AND BRANCH IF FIXED DECIMAL 73640013
         BC    BZ,MB5504             (NO ALIGNING OF WORKSPACE REQD)    73680013
         SPACE 1                                                        73720013
         LH    HR2,SCWKSC              FOR FIXED BINARY AND FLOAT,      73760013
         AR    HR2,HR1               WORKSPACE MUST BE ROUNDED UP TO    73800013
         BCTR  HR2,0                 APPROPRIATE BOUNDARY               73840013
         LCR   HR0,HR1                                                  73880013
         NR    HR2,HR0                                                  73920013
         BAL   RR,CHECKW               UPDATE COUNT AFTER CHECKING      73960013
         SPACE 1                                                        74000013
*              CHECK ARITHMETIC DATA FOR COMPLEX, AND IF SO DOUBLE      74040013
*        THE LENGTH                                                     74080013
MB5504   TM    TMPDF2(R1),DATCMP                                        74120013
         BC    BZ,MB5506               IF NOT COMPLEX, BRANCH. ELSE     74160013
         AR    HR1,HR1               DOUBLE LENGTH                      74200013
         SPACE 1                                                        74240013
*              FOR ALL ITEMS ADD THE LENGTH TO THE WORKSPACE COUNT AND  74280013
*        SET UP TMPD0 TO USE THE ALLOCATED WORKSPACE                    74320013
         SPACE 1                                                        74360013
MB5506   MVC   TMPDF5(2,R1),SCWKSC     COPY WORKSPACE OFFSET INTO TMPD  74400013
         OI    TMPDF1(R1),TMPWO      SET 'TEMPORARY OFFSET' BITS ON     74440013
         LH    HR2,SCWKSC              UPDATE WORKSPACE STACK SIZE BY   74480013
         AR    HR2,HR1               LENGTH OF DATUM.                   74520013
         BAL   RR,CHECKW               CHECK COUNT DOES NOT EXCEED MAX  74560013
         SPACE 1                                                        74600013
         L     RR,WSRR02               RESTORE AND RETURN               74640013
         BCR   B,RR                                                     74680013
         SPACE 2                                                        74720013
*              STRING DATUM                                             74760013
MB5501   MVC   WS55(2),TMPDF3(R1)      GET LENGTH OF STRING FROM        74800013
         LH    HR1,WS55              TMPD0                              74840013
         TM    TMPDF2(R1),DATBIT       TEST STRING BASE AND BRANCH      74880013
         BC    BNZ,MB5506            IF CHARACTER                       74920013
         SPACE 1                                                        74960013
         LA    HR1,7(0,HR1)            BIT STRING. DETERMINE NUMBER OF  75000013
         SRL   HR1,3                 BYTES CONTAINING THE STRING        75040013
         BC    B,MB5506                                                 75080013
         EJECT                                                          75120013
*                       SUBROUTINES DROP1 AND DROP2                     75160013
         SPACE 1                                                        75200013
*              THESE SUBROUTINES ARE USED TO EFFECT THE DROPPING OF     75240013
*        PHYSICAL OR SYMBOLIC REGISTERS. THEY ARE GENERALLY USED WHEN   75280013
*        PSEUDO-CODE HAS BEEN GENERATED FOR SOME PSEUDO-VARIABLE, OR    75320013
*        WHEN ERRONEOUS INPUT HAS RESULTED IN SUPPRESSION OF SOME       75360013
*        OPERATION.                                                     75400013
*              INPUT. R1 ADDRESSES AN 11 BYTE TMPD                      75440013
*              OUTPUT. ANY REGISTERS SPECIFIED IN THE INPUT TMPD ARE    75480013
*        DROPPED BY GENERATING A DROP PSEUDO-CODE ITEM OR BY SETTING    75520013
*        BITS TO ZERO IN THE SCAN PARAMETER BLOCK.                      75560013
*              ENTRIES. DROP1  DROPS REGISTERS ONLY IF THE DROP SWITCH  75600013
*        IS ON.                                                         75640013
*                       DROP2  ALWAYS DROPS.                            75680013
         SPACE 1                                                        75720013
DROP1    BCR   NOP,RR                  RETURN IF NO DROPPING            75760013
SWDROP   EQU   DROP1+1                                                  75800013
         SPACE 1                                                        75840013
DROP2    ST    RR,WSRR02               SAVE RETURN REGISTER             75880013
         SPACE 1                                                        75920013
         TM    TMPDF1(R1),TMPWO        TEST FLAG BITS AND BRANCH IF     75960013
         BC    BM,MB5603             THEY INDICATE A REGISTER NUMBER    76000013
*                                    IN FIELD 5                         76040013
         SPACE 1                                                        76080013
MB5601   TM    TMPDF1(R1),TMPXR        TEST FOR INDEX REGISTER AND      76120013
         BC    BNZ,MB5604            BRANCH IF PRESENT                  76160013
         SPACE 1                                                        76200013
MB5602   L     RR,WSRR02               RESTORE AND RETURN               76240013
         BCR   B,RR                                                     76280013
         SPACE 1                                                        76320013
*              TEMPORARY RESULT DESCRIBED BY REGISTER                   76360013
         SPACE 1                                                        76400013
MB5603   ST    R1,WSR101               SAVE POINTER TO TMPD             76440013
         TM    TMPDF1,X'80'            DESCRIMINATE BETWEEN NAME AND    76480013
         BC    BZ,MB5605             VALUE.                             76520013
         SPACE 1                                                        76560013
*              FLAGS 10 - REGISTER BY VALUE                             76600013
         TM    TMPDF2,DATFLT           TEST FOR FLOATING RESULT. IF     76640013
         BC    BZ,MB5606             NOT BRANCH TO GENERAL PHYSICAL     76680013
*                                    REGISTER SECTION                   76720013
*              FLOATING REGISTER                                        76760013
         IC    HR1,TMPDF5+1(0,R1)      LOAD FLOATING REGISTER NUMBER    76800013
         N     HR1,CN0007            INTO HR1 AND DIVIDE BY 2           76840013
         SRL   HR1,1                                                    76880013
         LA    HR1,REGMSK(HR1)         GET ADDRESS OF MASK BYTE AND     76920013
         NC    SCSTK(1),0(HR1)       SET FLOATING REGISTER FLAG BITS    76960013
*                                    TO ZERO IN SCAN PARAMETER BLOCK    77000013
         BC    B,MB5610                GO TO TEST FOR INDEX             77040013
         SPACE 1                                                        77080013
*              FLAGS 01 - REGISTER BY NAME                              77120013
MB5605   CLC   TMPDF5(2,R1),CN00FF     TEST REGISTER AND BRANCH IF      77160013
         BC    BNH,MB5606            NOT SYMBOLIC                       77200013
         SPACE 1                                                        77240013
*              SYMBOLIC REGISTER                                        77280013
         MVC   PS011(2),TMPDF5(R1)     PLACE REGISTER NUMBER IN DROP    77320013
         LA    R1,PS01               PSEUDO-CODE SKELETON AND MOVE TO   77360013
         LA    R2,3                  OUTPUT TEXT                        77400013
         BAL   RR,MMV3U                                                 77440013
         BC    B,MB5610                GO TO TEST FOR INDEX             77480013
         SPACE 1                                                        77520013
*              PHYSICAL REGISTER OR REGISTER BY VALUE                   77560013
MB5606   CLI   TMPDF5+1,R14            TEST FOR PHYSICAL REGISTER 14    77600013
         BC    BNE,MB5607            OR 15.                             77640013
         SPACE 1                                                        77680013
         NI    SCSTK+1,X'7F'           14. RESET FIRST BIT IN SCSTK+1   77720013
         BC    B,MB5610              THEN GO TO TEST FOR INDEX          77760013
         SPACE 1                                                        77800013
MB5607   CLI   TMPDF5+1,R15                                             77840013
         BC    BNE,MB5610                                               77880013
         SPACE 1                                                        77920013
         NI    SCSTK+1,X'BF'           15. RESET SECOND BIT IN SCSTK+1  77960013
         SPACE 1                                                        78000013
MB5610   L     R1,WSR101               RESTORE R1 THEN GO TO TEST FOR   78040013
         BC    B,MB5601              INDEX REGISTER                     78080013
         SPACE 2                                                        78120013
*              TEMPORARY RESULT USES INDEX REGISTER                     78160013
         SPACE 1                                                        78200013
MB5604   ST    R1,WSR101               SAVE R1                          78240013
         MVC   PS011(2),TMPDF6(R1)     PLACE REGISTER NUMBER IN DROP    78280013
         LA    R1,PS01               PSEUDO-CODE AND MOVE TO OUTPUT     78320013
         LA    R2,3                  TEXT                               78360013
         BAL   RR,MMV3U                                                 78400013
         L     R1,WSR101               RESTORE R1                       78440013
         BC    B,MB5602                RETURN                           78480013
         EJECT                                                          78520013
*                       SUBROUTINE ERROR                                78560013
         SPACE 1                                                        78600013
*              THIS SUBROUTINE MAKES ERROR ENTRIES IN THE DICTIONARY    78640013
*        INPUT. HR1 CONTAINS ERROR CODE WORD                            78680013
         SPACE 1                                                        78720013
ERROR    ST    RR,WSRR01               SAVE RETURN REGISTER             78760013
         ST    HR1,PAR6                PLACE CODE WORD IN PAR6, THEN    78800013
         L     LR,ZUEROF             CALL ZUERR TO MAKE ENTRY           78840013
         BALR  RR,LR                                                    78880013
         L     RR,WSRR01               RESTORE AND RETUNR               78920013
         BCR   B,RR                                                     78960013
         EJECT                                                          79000013
*                       SUBROUTINE CADNFL                               79040013
         SPACE 1                                                        79080013
*              THIS SUBROUTINE DETERMINES THE LENGTH IN BYTES OF THE    79120013
*        INTERNAL FORM OF AN ITEM DESCRIBED BY A TMPD. IN THE CASE OF   79160013
*        COMPLEX THE LENGTH RETURNED IS THAT OF ONE HALF ONLY.          79200013
*              INPUT. R1 ADDRESSES A NON-STRING TMPD                    79240013
*              OUTPUT. THE HALF WORD LENGTH CONTAINS THE LENGTH IN      79280013
*        BYTES                                                          79320013
         SPACE 1                                                        79360013
CADNFL   TM    TMPDF2(R1),DATNNF       TEST FOR NUMERIC FIELD AND       79400013
         BC    BZ,MB5901             BRANCH IF IT IS                    79440013
         SPACE 1                                                        79480013
*              CAD                                                      79520013
         SPACE 1                                                        79560013
         LA    HR1,4                                                    79600013
         TM    TMPDF2(R1),DATFLT       TEST FOR FIXED OR FLOAT AND      79640013
         BC    BZ,MB5902             BRANCH IF FIXED                    79680013
         SPACE 1                                                        79720013
         TM    TMPDF2(R1),DATLS        FLOAT. TEST FOR LONG OR SHORT    79760013
         BC    BZ,MB5910             AND BRANCH IF SHORT (LENGTH=4)     79800013
         LA    HR1,8                 ELSE LENGTH=8                      79840013
         BC    B,MB5910                                                 79880013
         SPACE 1                                                        79920013
MB5902   TM    TMPDF2(R1),DATBIN       FIXED. TEST FOR BINARY OR        79960013
         BC    BNZ,MB5910            DECIMAL. IF BINARY LENGTH=4        80000013
         SPACE 1                                                        80040013
         IC    HR1,TMPDF2+1(0,R1)      DECIMAL. LENGTH=FLOOR(PRECISION  80080013
         LA    HR1,2(0,HR1)          +2/2)                              80120013
         SRL   HR1,1                                                    80160013
         SPACE 1                                                        80200013
MB5910   STH   HR1,LENGTH              STORE RESULT IN LENGTH AND       80240013
         BCR   B,RR                  RETURN.                            80280013
         SPACE 2                                                        80320013
*              NUMERIC FIELD                                            80360013
         SPACE 1                                                        80400013
MB5901   ST    RR,WSRR01               SAVE RETURN REGISTER             80440013
         SR    HR1,HR1                 SET HR1 TO ZERO                  80480013
         MVC   PAR1+2(2),TMPDF2+1(R1)  GET PICTURE REF FROM TMPD        80520013
         L     LR,ZRFAOF                                                80560013
         BALR  RR,LR                                                    80600013
         L     HR2,PAR1                HR2 ADDRESSES PICTURE ENTRY      80640013
         SPACE 1                                                        80680013
         IC    HR1,DEPICW(0,HR2)       GET APPARENT WIDTH               80720013
         L     RR,WSRR01               RESTORE AND GO TO RETURN         80760013
         BC    B,MB5910                                                 80800013
         EJECT                                                          80840013
*                       SUBROUTINE TARGET                               80880013
         SPACE 1                                                        80920013
*              THIS SUBROUTINE IS USED BY PSEUDO-VARIABLES PRIORITY,    80960013
*        EVENT AND COMPLEX TO OBTAIN WORKSPACE FOR, AND CONVERT RIGHT-  81000013
*        HAND-SIDES TO,THE PSEUDO-VARIABLE TARGET TYPE.                 81040013
*              INPUT. STKLHS CONTAINS ADDRESS OF TMPD WHICH DESCRIBES   81080013
*        THE RHS (IF ASSIGN)                                            81120013
*                     PSVTGT CONTAINS ADDRESS OF TMPD WHICH DESCRIBES   81160013
*        THE PSEUDO-VARIABLE TARGET.                                    81200013
*              OUTPUT. PSVTGT CONTAINS ADDRESS OF TMPD DESCRIBING BOTH  81240013
*        RHS AND PV TARGET, NECESSARY ASSIGNMENTS HAVING BEEN MADE. FOR 81280013
*        DATA LIST ITEMS THE COMMA TRIPLE IS GENERATED TO EFFECT        81320013
*        READING INTO THE TARGET                                        81360013
         SPACE 1                                                        81400013
TARGET   ST    RR,WSRR03               SAVE RETURN REGISTER             81440013
         L     R1,PSVTGT               PICK UP POINTERS TO PSEUDO-VAR   81480013
         L     R2,STKLHS             TARGET AND RIGHT HAND SIDE         81520013
         SPACE 1                                                        81560013
         TM    SWDATA,X'F0'            TEST FOR DATA LIST ITEM AND      81600013
         BC    BNZ,MB6001            BRANCH IF IT IS.                   81640013
         SPACE 1                                                        81680013
*              ASSIGNMENT                                               81720013
         SPACE 1                                                        81760013
         CLI   0(R2),TRTMPD            TEST FOR CONSTANT ON THE RIGHT   81800013
         BC    BNE,MB6002            BRANCH IF CONSTANT.                81840013
         SPACE 1                                                        81880013
*              ASSIGNMENT OF VARIABLE                                   81920013
         SPACE 1                                                        81960013
         TM    TMPDF2(R1),DATCAD       TEST TYPE OF VARIABLE AND        82000013
         BC    BZ,MB6005                                                82040013
         SPACE 1                                                        82080013
*              ASSIGNMENT OF VARIABLE TO CAD TARGET                     82120013
         TM    TMPDF1(R2),X'01'        TEST FOR REFERENCE IN FIELD 6 I1 82124016
         BC    BZ,MB6017             AND BRANCH TO INVESTIGATE IT    I1 82128016
         MVC   PAR1+2(2),TMPDF6(R2)  FOR ALIGNMENT IF SO             I1 82132016
         BC    B,MB6016                                              I1 82136016
         SPACE                                                          82140016
MB6017   TM    TMPDF1(R2),X'C0'        TEST FOR DICT. REF. IN FIELD5 I1 82144016
         BC    BNZ,MB6018            AND BRANCH IF NOT               I1 82148016
         MVC   PAR1+2(2),TMPDF5(R2)    MOVE REF TO PAR1 AND CONVERT  I1 82152016
         SPACE                                                          82156016
MB6016   L     LR,ZRFAOF             TO ABSOLUTE                     I1 82160016
         BALR  RR,LR                                                 I1 82164016
         L     HR1,PAR1                POINT R1 AT ENTRY AND         I1 82168016
         TM    DEOT4(HR1),X'08'      TEST WHETHER ALIGNED OR NOT     I1 82172016
         BC    BNO,MB6005            ASSIGN TO WORKSPACE IF UNALND   I1 82176016
         SPACE                                                          82180016
MB6018   CLC   TMPDF2(3,R1),TMPDF2(R2) COMPARE THE TWO DESCRIPTIONS  I1 82184016
         BC    BE,MB6004             AND BRANCH IF IDENTICAL            82200013
         SPACE 1                                                        82240013
*              ASSIGNMENT OF VARIABLE TO STRING OR CAD TARGET WITH      82280013
*        CONVERSION REQUIRED                                            82320013
         SPACE 1                                                        82360013
MB6005   BAL   RR,GETWKS               GET WORKSPACE FOR TARGET         82400013
         LR    R1,IPTR                 PUT OUT ASSIGN OR MULTIPLE       82440013
         BAL   RR,MMV3A5             ASSIGN FROM INPUT                  82480013
         CLC   3(2,IPTR),CNZERO        TEST FOR INTERMEDIATE RHS        82520013
         BC    BNE,MB6006                                               82560013
         SPACE 1                                                        82600013
         L     R1,STKLHS               IF INTERMEDIATE PUT OUT TMPDS    82640013
         BAL   RR,OUTMPD             FOR RHS                            82680013
         SPACE 1                                                        82720013
MB6006   L     R1,PSVTGT               PUT OUT TMPDS FOR LHS            82760013
         BAL   RR,OUTMPD                                                82800013
         BC    B,MB6010                RETURN                           82840013
         SPACE 2                                                        82880013
*              ASSIGNMENT OF VARIABLE TO STRING OR CAD TARGET AND NO    82920013
*        CONVERSION REQUIRED.                                           82960013
         SPACE 1                                                        83000013
MB6004   MVC   0(11,R1),0(R2)          COPY LHS DESCRIPTOR INTO TARGET  83040013
*                                    DESCRIPTOR                         83080013
         SPACE 1                                                        83120013
MB6010   L     RR,WSRR03               RESTORE AND RETURN               83160013
         MVI   EVFLG,X'00'                                              83200013
         BCR   B,RR                                                     83240013
         SPACE 2                                                        83280013
*              ASSIGNMENT OF VARIABLE TO STRING TARGET                  83320013
MB6003   XC    TMPDF2(1,R1),TMPDF2(R2)                                  83360013
         TM    TMPDF2(R1),DATBIT       NO CONVERSION IF BOTH BIT OR     83400013
         BC    BZ,MB6004             BOTH CHARACTER                     83440013
         SPACE 1                                                        83480013
         XC    TMPDF2(1,R1),TMPDF2(R2) RESTORE TARGET TYPE DESCRIPTOR   83520013
         BC    B,MB6005              THEN GO TO CONVERT                 83560013
         SPACE 2                                                        83600013
*              ASSIGNMENT OF CONSTANT                                   83640013
         SPACE 1                                                        83680013
         SPACE                                                          83682015
MB6002   BAL   RR,CONVT                CONVERT TO TARGET TYPE           83684015
         BC    B,MB6010                                                 83686015
         SPACE                                                          83688015
*              DATA LIST ITEM                                           83690015
         SPACE                                                          83692015
MB6001   BAL   RR,GETWKS               GET WORKSPACE FOR TARGET         83694015
         LR    R1,IPTR                                                  83696015
         BAL   RR,MMV3A5               PUT OUT COMMA TRIPLE FROM        83698015
         BC    B,MB6006                INPUT TEXT                       83700015
         EJECT                                                          83702015
*              SUBROUTINE CONVERT                                       83704015
         SPACE                                                          83706015
*        FUNCTIONS  THE SUBROUTINE REQUESTS CONVERSION OF A             83708015
*        CONSTANT TO THE TARGET TYPE. AS A SPECIAL CONCESSION,          83710015
*        IF THE CURRENT PSV IS EVENT AND THE CONSTANT IS A BIT          83712015
*        STRING,PS12 IS SET UP AS THE BCD OF THE CONSTANT.              83714015
*        IN THIS CASE RETURN IS MADE AT RR+4                            83716015
         SPACE                                                          83718015
*        INPUT -  R1 ADDRESSES TARGET TMPD                              83720015
*              -  R2 ADDRESSES SOURCE TMPD                              83722015
*                                                                       83724015
*        OUTPUT-  TARGET TMPD AND INPUT ASSIGN CONTAIN CONVERTED        83726015
*                 CONSTANT                                              83728015
         SPACE 3                                                        83730015
CONVT    ST    RR,WSRR04               SAVE RETURN REGISTER             83732015
         MVC   PAR1+2(2),TMPDF5(R2)    GET DICTIONARY ENTRY OF CONSTANT 83734015
         MVC   TMPDF5(2,R1),TMPDF5(R2) COPY DICT REF INTO TARGET TMPD   83760013
         L     LR,ZRFAOF                                                83800013
         BALR  RR,LR                                                    83840013
         L     HR1,PAR1                HR1 ADDRESSES CONST ENTRY        83880013
         CLI   EVFLG,X'FF'             TEST FOR EVENT                   83920015
         BC    BE,MB6013               BRANCH IF SO                     83960013
MB6012   NI    EVFLG,X'7F'           TURN EVENT FLAG OFF                84000015
         SPACE 1                                                        84040013
         TM    DECNTY(HR1),X'01'       TEST WHETHER CONVERSION HAS      84080013
         BC    BZ,MB6007             ALREADY BEEN REQUESTED. BRANCH YES 84120013
         SPACE 1                                                        84160013
         NI    DECNTY(HR1),X'FE'       CONVERSION NOT YET REQUESTED.    84200013
         MVC   DECNDT(3,HR1),TMPDF2(R1)    CONVERSION REQUESTED, COPY   84240013
         BC    B,MB6015              TARGET TYPE FROM PSVTGT AND RETURN 84280015
         SPACE 1                                                        84320013
MB6007   TM    DECNTY(HR1),X'C0'       TEST WHETHER SPECIAL CONVERSION  84360013
         BC    BM,MB6011             AND BRANCH IF SO                   84400013
         SPACE 1                                                        84440013
         CLC   DECNDT(3,HR1),TMPDF2(R1)    NORMAL CONVERSION REQUESTED  84480013
         BC    BE,MB6008             COMPARE TARGET TYPE WITH PSEUDO-   84520013
*                                    VARIABLE TARGET TYPE. BRANCH IF    84560013
*                                    SAME                               84600013
MB6011   MVC   PAR1+2(2),DECNCH(HR1)   NOT SAME. SEE IF THERE ARE MORE  84640013
         MVC   TMPDF5(2,R1),PAR1+2   CONSTANTS IN THE CHAIN FOR THIS    84680013
         CLC   PAR1+2(2),CNZERO      PARTICULAR VALUE.                  84720013
         BC    BE,MB6009               BRANCH IF END OF CHAIN           84760013
         SPACE 1                                                        84800013
         L     LR,ZRFAOF               NOT END OF CHAIN                 84840013
         BALR  RR,LR                                                    84880013
         L     HR2,PAR1                GET ADDRESS OF ENTRY             84920013
         SPACE 1                                                        84960013
         CLC   1(2,HR2),DE010          COMPARE LENGTH WITH THAT OF      85000013
         BC    BNE,MB6009            CONSTANT WITHOUT BCD. IF UNEQUAL   85040013
*                                    END OF CHAIN FOR THIS CONSTANT     85080013
         LR    HR1,HR2                 IF EQUAL GO TO TEST NEW ENTRY    85120013
         BC    B,MB6007                                                 85160013
         SPACE 1                                                        85200013
MB6009   MVC   DE011(2),TMPDF5(R1)     NO CONSTANT OF CORRECT TYPE.     85240013
         MVC   DE012(3),DECNAP(HR1)  MUST MAKE ENTRY IN CHAIN FOR       85280013
         MVC   DE013(3),TMPDF2(R1)   REQUIRED TYPE. COPY CHAIN AND      85320013
*                                    APPARENT TYPE, SET TARGET TYPE     85360013
         LA    HR2,DE01                MAKE ENTRY                       85400013
         ST    HR2,PAR1                                                 85440013
         LA    HR2,DE01L                                                85480013
         ST    HR2,PAR2                                                 85520013
         L     LR,ZDRFOF                                                85560013
         BALR  RR,LR                                                    85600013
         SPACE 1                                                        85640013
         MVC   DECNCH(2,HR1),PAR1+2    COPY NEW ENTRY REF INTO OLD      85680013
         MVC   TMPDF5(2,R1),PAR1+2   ENTRY AND TARGET TMPD              85720013
         SPACE 1                                                        85760013
MB6008   MVC   3(2,IPTR),TMPDF5(R1)    CURRENT ENTRY CORRECT TYPE. COPY 85800013
         NI    EVFLG,X'7F'             SET EVENT FLAG OFF               85900015
         L     RR,WSRR04               REF INTO OPERAND 2 OF ASSIGN     86000015
         BCR   B,RR                  IN INPUT TEXT. THEN RETURN         86100015
*              EVENT PSV                                                86280013
         SPACE                                                          86320013
MB6013   TM    DECNAP(HR1),X'84'       TEST FOR BIT STRING CONSTANT     86360013
         BC    BNZ,MB6012              IF NOT PROCESS NORMALLY          86400015
         TM    DCNBCD(HR1),X'FE'       IS FIRST DIGIT 1 OR 0            86440013
         BC    BNZ,MB6012              IF NOT PROCESS NORMALLY          86480013
         LH    HR2,DCNLN(HR1)                                           86520013
         LTR   HR2,HR2                                                  86560013
        BC    BE,MB6014                                                 86600013
         MVI   EVFLG,X'8F'             SET FLG TO                       86640015
         TM    DCNBCD(HR1),X'01'       TEST FOR 0 OR 1                  86680013
        BC    BO,MB6015                                                 86720013
MB6014  MVI   EVFLG,X'F0'             SET FLAG FOR NI SKELETON          86760013
MB6015   L     RR,WSRR04                                                86800015
         BCR   B,RR                                                     86840013
         EJECT                                                          86880013
*                       SUBROUTINE OUTRIP                               86920013
         SPACE 1                                                        86960013
*              THIS SUBROUTINE COPIES THE CURRENT ASSIGN OR COMMA       87000013
*        TRIPLE AND TMPDS FOR RHS OF ASSIGN IF NECESSARY                87040013
         SPACE 1                                                        87080013
OUTRIP   ST    RR,WSRR03               SAVE RETURN REGISTER             87120013
         LR    R1,IPTR                 COPY ASSIGN OR SINGLE COMMA      87160013
         BAL   RR,MMV3A5                                                87200013
         SPACE 1                                                        87240013
         CLC   3(2,IPTR),CNZERO        TEST FOR 00 OPERAND 1 AND GO     87280013
         BC    BNE,MB6301            TO RETURN IF NOT                   87320013
         SPACE 1                                                        87360013
         TM    SWDATA,X'F0'            TEST FOR DATA LIST               87400013
         BC    BNZ,MB6301                                               87440013
         SPACE 1                                                        87480013
         L     R1,STKLHS               ASSIGNMENT. COPY RHS TMPD        87520013
         BAL   RR,OUTMPD                                                87560013
MB6301   L     RR,WSRR03               RESTORE AND RETURN               87600013
         BCR   B,RR                                                     87640013
         EJECT                                                          87680013
*                       SUBROUTINE CHECKW                               87720013
         SPACE 1                                                        87760013
*              THIS SUBROUTINE CHECKS THAT A NEW WORKSPACE COUNT VALUE  87800013
*        DOES NOT EXCEED THE IMPLEMENTATION MAXIMUM OF 16383.           87840013
*        ON ENTRY HR2 CONTAINS THE UPDATED COUNT TO BE STORED IN THE    87880013
*        SCAN WORKSPACE COUNT SLOT.                                     87920013
         SPACE 1                                                        87960013
CHECKW   STH   HR2,SCWKSC              STORE UPDATED COUNT              88000013
         C     HR2,MAXWKS              COMPARE WITH 16384 AND RETURN    88040013
         BCR   BL,RR                 IF LESS.                           88080013
         SPACE 1                                                        88120013
         L     HR1,ERID04              OTHERWISE TERMINATE WITH ERROR   88160013
         BC    B,MBABT2              MESSAGE                            88200013
         EJECT                                                          88201020
*                        SUBROUTINE  SELLSTK                      32295 88202020
         SPACE 1                                                  32295 88203020
*    CHECKS TO SEE IF THE TEMP WITH DESCRIPTION POINTED AT        32295 88204020
*    BY HR1 MUST BE SOLD, AND IF SO ADDS ITS D.R. TO THE          32295 88205020
*    STACK OF TEMPS TO BE SOLD.                                   32295 88206020
*                                                                 32295 88207020
*              EXITS - NORMAL    TO RR.                           32295 88208020
*                    - ERROR  MESSAGE & ABORT IF STACK IS FULL.   32295 88209020
          SPACE 3                                                 32295 88210020
ERID10   DS    0F                                                 32295 88211020
         DC    X'00'                                              32295 88212020
         DC    AL2(ERCD10)                                        32295 88213020
          DC   AL1(AERROR+STATNO)                                 32295 88214020
ERCD10   EQU   X'0677'             TOO MUCH W/S NEEDED.           32295 88215020
SELLKPRR DC    F'0'                                               32295 88216020
NINE     DC    H'9'                                               32295 88217020
         SPACE 3                                                  32295 88218020
SELLSTK  ST    RR,SELLKPRR                                        32295 88219020
         TM    0(HR1),X'02'            MUST THIS D. R. BE SOLD   A32295 88220020
         BCR   BZ,RR                   NO                        A32295 88221020
         LH    LR,SELSAV               PICK UP COUNT OF OTHER    A32295 88222020
*                                      DIC REFS TO BE SOLD       A32295 88223020
         LA    LR,1(LR)                ADD 1 TO COUNT OF TEMPS   A32295 88224020
         CH    LR,NINE                 IF NUMBER OF TEMP RESULTS A32295 88225020
         BNH   MB9501                  EXCEEDS 9, THE SAVE AREAE A32295 88226020
         L     HR1,ERID10              FOR TEMPS IS FULL SO      A32295 88227020
         BAL   RR,ERROR                PUT OUT TERMINAL MESSAGE  A32295 88228020
         L     LR,ZABTOF                ABORT                    A32295 88229020
         BALR  RR,LR                                             A32295 88230020
MB9501   STH   LR,SELSAV                                                88231020
         AR    LR,LR                   DOUBLE IT TO GIVE OFFSET  A32295 88232020
*                                      AT WHICH THIS D.R. MAY BE A32295 88233020
*                                      STORED.                   A32295 88234020
         LA    LR,SELSAV(LR)           ADD OFFSET TO START OF STACK ..  88235020
         MVC   0(2,LR),4(HR1)          PUT TEMP D.R. IN STACK    A32295 88236020
         NI    1(LR),X'FC'             CLEAR BOTTOM TWO BITS     A32295 88237020
         BR    RR                                                 32295 88238020
         EJECT                                                          88240013
*                       CONSTANTS AND WORKSPACE AREAS                   88280013
         SPACE 1                                                        88320013
*              INSTRUCTIONS EXECUTED REMOTELY                           88360013
         SPACE 1                                                        88400013
*              CONSTANTS                                                88440013
CNZERO   DC    F'0'                                                     88480013
CN0007   DC    F'7'                    MASK FOR LOW 3 BITS              88520013
CN000F   DC    F'15'                   MASK FOR LOW 4 BITS              88560013
MAXSEL   DC    F'0'                    END-OF-SELLS ADDRESS             88600013
MAXWKS   DC    F'16384'                MAX WORKSPACE COUNT VALUE        88640013
CN0011   DC    H'11'                   LENGTH OF TMPD ENTRY IN STACK    88680013
CN00FF   DC    X'00FF'                 COMPARAND FOR PSI OPERAND        88720013
CNLDMC   DC    C'MCZZ'                 LOAD MC                          88760013
CNRLS    DC    C'MBMCZZ'               RELEASE MB AND MC                88800013
LFTCOD   DC    X'0000000000000080'     CODES FOR LEFT TEMPORARY         88840013
         DC    X'0020000060000000'   DESCRIPTION                        88880013
REGMSK   DC    X'77BBDDEE'             MASK TO DROP FLOATING REGISTERS  88920013
*                                    0,2,4 OR 6 FROM SCAN STACK         88960013
         SPACE 2                                                        89000013
*              LIST OF TRIPLES REPRESENTING OPTIONS WHICH MAY HAVE      89040013
*        PSEUDO-VARIABLE ARGUMENTS.                                     89080013
         SPACE 1                                                        89120013
PVLIST   DC    AL1(TRRPLY)             REPLY  (DISPLAY)                 89160013
         DC    AL1(TRIDNT)             IDENT  (OPEN)                    89200013
         DC    AL1(TRKYTO)             KEYTO  (READ)                    89240013
         DC    AL1(TRSTRN)             STRING (GET OR PUT)              89280013
PVLSTL   EQU   *-PVLIST                                                 89320013
         SPACE 2                                                        89360013
*              TABLE OF PSEUDO VARIABLE CODES                           89400013
         SPACE 1                                                        89440013
PSTABL   DC    X'03'                   EVENT                            89480013
         DC    X'06'                   ONCHAR                           89520013
         DC    X'08'                   ONFIELD                          89560013
         DC    X'89'                   PRIORITY                         89600015
         DC    X'1B'                   COMPLEX                          89640013
         DC    X'1F'                   IMAG                             89680013
         DC    X'23'                   REAL                             89720013
         DC    X'28'                   UNSPEC                           89760013
         DC    X'30'                   SUBSTRING                        89800013
         DC    X'34'                   STATUS                           89820015
         DC    X'26'                   STRING.                          89830001
PSVEND   EQU   *                                                        89840013
         SPACE 1                                                        89880013
*              PSEUDO-VARIABLE DESCRIPTION TABLE 1                      89920013
*        ENTRIES CORRESPOND TO THOSE IN THE PRECEDING TABLE. A ZERO     89960013
*        ENTRY INDICATES THAT ALL ARGUMENTS ARE VARIABLES. A NON-ZERO   90000013
*        ENTRY POINTS TO AN ENTRY IN THE SECOND TABLE WHICH IS A LIST   90040013
*        OF INDEX ARGUMENT NUMBERS.                                     90080013
         SPACE 1                                                        90120013
PSDSC1   DC    H'0'                                                     90160013
         DC    H'0'                                                     90200013
         DC    H'0'                                                     90240013
         DC    H'0'                                                     90280013
         DC    H'0'                                                     90320013
         DC    H'0'                                                     90360013
         DC    H'0'                                                     90400013
         DC    H'0'                                                     90440013
         DC    AL2(PS2SUB-PSDSC2)                                       90480013
         DC    H'0'                                                     90500001
         SPACE 1                                                        90520013
*              PSEUDO-VARIABLE DESCRIPTION TABLE 2                      90560013
*        ENTRIES FOR PSEUDO-VARIABLES WITH INDEX ARGUMENT CONSIST OF    90600013
*        THE LENGTH OF THE ENTRY AND THE ARGUMENT NUMBERS WHICH ARE     90640013
*        INDICES (STARTING FROM ZERO)                                   90680013
         SPACE 1                                                        90720013
PSDSC2   DC    H'0'                    DUMMY                            90760013
PS2SUB   DC    H'4'                    SUBSTRING HAS SECOND AND THIRD   90800013
         DC    H'1'                  ARGUMENTS INTEGER                  90840013
         DC    H'2'                                                     90880013
         SPACE 1                                                        90920013
*              ERROR ENTRY CODES                                        90960013
         SPACE 1                                                        91000013
         DS    0F                                                       91040013
ERID01   DC    X'00'                                                    91080013
         DC    AL2(ERCD01)                                              91120013
         DC    AL1(AERROR+STATNO)                                       91160013
ERID02   DC    X'00'                                                    91200013
         DC    AL2(1067)               PSEUDO-VAR WITH ILLEGAL ARG.     91240013
         DC    AL1(AERROR+STATNO+DICREF)                                91280013
ERID03   DC    X'00'                                                    91320013
         DC    AL2(ERCD03)                                              91360013
         DC    AL1(SERROR+STATNO)                                       91400013
ERID04   DC    X'00'                                                    91440013
         DC    AL2(ERCD04)                                              91480013
         DC    AL1(AERROR+STATNO)                                       91520013
         SPACE 1                                                        91560013
STATNO   EQU   X'40'                   STATEMENT NUMBER REQUIRED        91600013
DICREF   EQU   X'10'                   DICT REF WITH MESSAGE            91640013
SERROR   EQU   X'04'                   SERIOUS ERROR                    91680013
AERROR   EQU   X'00'                   TERMINAL ERROR                   91720013
ERCD01   EQU   X'0651'                 ILLEGAL RETURN FROM SC AN IN SN  91760013
ERCD03   EQU   X'0653'                 RHS OF SN CANNOT BE ASSIGNED TO  91800013
*                                    A PSEUDO-VARIABLE                  91840013
ERCD04   EQU   1655                    WORKSPACE COUNT MAX EXCEEDED     91880013
         SPACE 2                                                        91920013
*              DICTIONARY ENTRY SKELETONS                               91960013
         SPACE 1                                                        92000013
DE01     DC    AL1(DRCON)              CONSTANT                         92040013
DE010    DC    AL2(DE01L)                                               92080013
DE011    DC    AL2(0)                  CHAIN SLOT                       92120013
DE012    DC    X'000000'               TYPE (APPARENT)                  92160013
         DC    X'00'                   FLAG BYTE - NORMAL CONSTANT      92200013
DE013    DC    AL3(0)                  TYPE (TARGET)                    92240013
         DC    AL2(0)                                                   92280013
DE01L    EQU   *-DE01                  LENGTH                           92320013
         SPACE 2                                                        92360013
*              TRIPLE SKELETONS                                         92400013
         SPACE 1                                                        92440013
ST00     DC    5X'00'                                                   92480013
ST01     DC    AL1(TRTMPD)             TMPD                             92520013
         DC    4X'00'                                                   92560013
ST02     DC    AL1(TRTMPD)             TMPD                             92600013
         DC    4X'00'                                                   92640013
ST03     DC    X'AC20000000'           SELL SAVE SLOT                   92680020
         SPACE 1                                                        92720013
         SPACE 2                                                        92760013
*              PSEUDO-CODE SKELETONS                                    92800013
         SPACE 1                                                        92840013
PS01     DC    AL1(PSDROP)             DROP                             92880013
PS011    DC    AL2(0)                                                   92920013
         SPACE 2                                                        92960013
*              TEMPORARY DESCRIPTOR SKELETONS                           93000013
         SPACE 1                                                        93040013
TM01     DC    AL1(TRTMPD)                                              93080013
         DC    X'008C0F80'             FIXED BINARY (15,0)              93120013
         DC    6X'00'                                                   93160013
         SPACE 2                                                        93200013
*              WORKSPACE AND SAVE AREAS                                 93240013
         SPACE 1                                                        93280013
STKBSE   DC    F'0'                    STACK BASE (SET DURING INITLN.)  93320013
PSVLVL   DC    F'0'                    ARGUMENT LEVEL IN PSEUDO-VBLE.   93360013
WSTXRF   DC    F'0'                    TEXT REF OF ASSIGN TRIPLE        93400013
PSVNXT   DC    F'0'                    NEXT PV STACK ENTRY ADDRESS      93440013
WSSTKR   DC    F'0'                    STACK POINTER SAVE SLOT          93480013
WSRR01   DC    F'0'                    RR SAVE 1                        93520013
WSRR02   DC    F'0'                            2                        93560013
WSRR03   DC    F'0'                            3                        93600013
WSRR04   DS    F                                                        93620015
WSLR01   DC    F'0'                    LR SAVE SLOT                     93640013
WSR101   DC    F'0'                    R1 SAVE                          93680013
WS55     DC    F'0'                    SCRATCH SPACE                    93720013
PSVCUR   DC    H'0'                    CODE OF CURRENT PSEUDO-VBLE.     93760013
PSVCNT   DC    H'0'                    PSEUDO-VARIABLE ARGUMENT COUNT   93800013
WSLVCT   DC    H'0'                    LEVEL/COUNT OF CURRENT BLOCK.    93840013
TMPDRH   DC    11X'00'                 RHS TMPD                         93880013
         END   IEMMB                                                    93920013
