OM       TITLE 'IEMOM IN-LINE DATA CONVERSION,DEC TO BIN,CHAR,PIC'      00040013
*                                                                       00080013
*                                                                       00120013
*                                                                       00160013
*                                                                       00200013
*              STATUS-CHANGE LEVEL 0.                                   00240013
* 5.3B A 201300,855200,856000                                 MCB 47647 00248056
*      C 345200-346400,349600-350800,369200-376800,           MCB 47647 00256056
*      C 788400-789200,790800,792000,817200,846400-847600     MCB 47647 00264056
*      D 815600-816000,818400-819200,841600-843200            MCB 47647 00272056
*                                                                       00280013
*                                                                       00320013
*              FUNCTION/OPERATION                                       00360013
*                                                                       00400013
*              THIS LOGICAL PHASE(OM-ON-OO)SCANS TEXT FOR CONVRT MACROS 00440013
*        REPLACING THESE BY IN-LINE PSEUDO-CODE.THE CONVERSIONS ARE     00480013
*                                                                       00520013
*              OM   DEC TO PIC WITH ZERO SUPPR,E.G.'ZZ,ZZV.999'         00560013
*                   DEC TO PIC WITH DRIFTING STRINGS,E.G.'S,SSS,999$'   00600013
*                                                                       00640013
*              ON   DEC TO PIC E.G. '999V99+'                           00680013
*                   PIC TO DEC E.G. '999V99+'                           00720013
*                                                                       00760013
*              OO   DEC TO BIN (INCLUDING SIZE OPTION)                  00800013
*                   DEC TO CHAR(L.T. 256 BYTES,DEC PREC GT=SCALE GT=0)  00840013
*                   LIBR CALL GENERATION(FOR IMPRACTICABLE IN-LINE CODE 00880013
*                                                                       00920013
*              REGISTER USAGE WHICH IS COMMON TO THE THREE PHYSICAL     00960013
*        PHASES IS AS FOLLOWS                                           01000013
*        RH    8    BASE OF SCRATCH CORE                                01040013
*        RI    9    BASE OF OM                                          01080013
*        RJ    10   BASE OF ON                                          01120013
*        RK    11   BASE OF CONTROL                                     01160013
*        RL    12   BASE OF OO                                          01200013
*        RM    13   BASE OF DICTIONARY                                  01240013
*        LR    14   LINK REG                                            01280013
*        BR    15   BRANCH REG                                          01320013
*                                                                       01360013
*                                                                       01400013
*              OM PHYSICAL PHASE,FUNCTION/OPERATION                     01440013
*                                                                       01480013
*                                                                       01520013
*              GETS SCRATCH CORE                                        01560013
*              LOADS PHASES ON,OO                                       01600013
*              SCANS TEXT FOR THE STANDARDISED 28-BYTE CONVERT MACROS   01640013
*        LEFT THERE BY OG.OM THEN SAVES ALL REGS AND BRANCHES ON THE    01680013
*        TRANSFER VECTOR HELD AT THE END OF THE CONV MACRO:             01720013
*                                                                       01760013
*        0     UNPACK   (ON)    DEC TO PIC(NO PUNCT OR ZERO SUPPR)      01800013
*        4     PACK     (ON)    PIC TO DEC                              01840013
*        8     EDIT     (OM)    DEC TO PIC(PUNCT OR ZERO SUPPR)         01880013
*        12    EDMK     (OM)    DEC TO PIC(DRIFTING STRINGS)            01920013
*        16    DTOB     (OO)    DEC TO BIN                              01960013
*        20    DTOC     (OO)    DEC TO CHAR STRING                      02000013
*                                                                       02040013
*              THE LIBRARY CALL GENERATION ROUTINE IS CALLED ONLY FROM  02080013
*        WITHIN THE OTHER ROUTINES WHEN THEY FAIL TO GENERATE IN-LINE   02120013
*        CODE                                                           02160013
*                                                                       02200013
*             ENTRY POINTS                                              02240013
*                                                                       02280013
*        TEXTSC     MAIN ENTRY POINT TO SCAN TEXT                       02320013
*                                                                       02360013
*        CHARIN     ENTRY FOR DEC TO CHAR CONVERSION WHEN THE EQUIV     02400013
*                            PICTURE HAS BEEN GENERATED BY OO           02440013
*                                                                       02480013
*              LOCAL EXIT POINTS                                        02520013
*        UNPACK     DEC TO PIC IN ON                                    02560013
*        PACK       PIC TO DEC IN ON                                    02600013
*        DTOB       DEC TO BIN IN OO                                    02640013
*        DTOC       DEC TO CHAR IN OO                                   02680013
*        GIVEUP     LIBR CALL IN OO                                     02720013
*        DICENT     COMMON UP DIC ENTRIES IN ON                         02760013
*                                                                       02800013
*              EXTERNAL ROUTINES                                        02840013
*        RLSCTL     RELEASE CONTROL                                     02880013
*        ZALTER     ALTER BLOCK STATUS                                  02920013
*        ZCHAIN     FIND NEXT BLOCK IN CHAIN                            02960013
*        ZDRFAB     DIC REF TO ABS                                      03000013
*        ZLOADW     LOAD AND WAIT                                       03040013
*        ZTXTAB     TXT REF TO ABS                                      03080013
*        ZTXTRF     ABS TO TXT REF                                      03120013
*        ZUTXTC     GET EMPTY BLOCK                                     03160013
*        ZUGC       GET SCRATCH CORE                                    03200013
*        ZURC       RELEASE SCRATCH CORE                                03240013
*                                                                       03280013
*              IN ADDITION THE FOLLOWING EXTERNAL COMMUNICATION SLOTS   03320013
*        ARE SET OR USED                                                03360013
*                                                                       03400013
*        Z2FILE     2ND FILE POINTER                                    03440013
*        ZCONCH     CONST CHAIN TAIL                                    03480013
*        ZEQMAX     MAX EQU VALUE                                       03520013
*        ZMYNAM     OWN NAME                                            03560013
*        ZNXTLC     END OF CURRENT TEXT                                 03600013
*        ZTRAN2     INTERNAL TO EXTERNAL TRANSLATE                      03640013
*        STARTX     START OF TEXT                                       03680013
*        TXTSZ      LENGTH OF TEXT                                      03720013
*        PAR1                                                           03760013
*        PAR2                                                           03800013
*                                                                       03840013
*                                                                       03880013
*              EXIT-NORMAL    AT 'EXIT' WHEN END OF TEXT REACHED        03920013
*                                                                       03960013
*              EXIT-ERROR     AT 'ERROR' THERE IS A TRAP WHICH WILL     04000013
*        THROW UP ERRORS IN OM-ON-OO OR POSSIBLY OG                     04040013
*                                                                       04080013
*                                                                       04120013
*              ATTRIBUTES     THIS MODULE IS REUSABLE                   04160013
*                                                                       04200013
*              ITS OPERATION DOES NOT DEPEND ON A PARTICULAR INTERNAL   04240013
*        REPRESENTATION OF THE EXTERNAL CHAR SET                        04280013
         EJECT                                                          04320013
IEMOM    START 0                                                        04360013
         USING *,9                                                      04400013
         USING IEMOM+X'1000',RJ                                         04440013
         USING IEMOM+X'2000',RL                                         04480013
         USING IEMOM+X'3000',RH                                         04520013
SCR      EQU   IEMOM+X'3000'           BEGINNING OF SCRATCH STOEAGE     04560013
         SPACE                                                          04600013
ILNGTH   EQU   SCR                     H NO OF BYTES OF IN-LINE CODE TO 04640013
*                                        BE ADDED VIA THE BUFFER,'BUFF' 04680013
CNVBF    EQU   SCR+3                   28C THIS 28 BYTE BUFFER HOLDS    04720013
*                                        THE CONVERT MACRO FOR DECODING 04760013
SF1      EQU   CNVBF+3                 C SOURCE FLAG                    04800013
SF2      EQU   CNVBF+4                 C SOURCE DATA BYTE               04840013
SF3      EQU   CNVBF+5                 C SOURCE PRECISION               04880013
SF4      EQU   CNVBF+6                 C SOURCE SCALE                   04920013
SF5      EQU   CNVBF+7                 H DR,TEMP OFST,REG BY NAME/VALUE 04960013
SF6      EQU   CNVBF+9                 H INDEX REG OR NOTHING           05000013
SF7      EQU   CNVBF+11                H ADDITIONAL OFFSET              05040013
         SPACE                                                          05080013
TF1      EQU   CNVBF+13                C TARGET FLAG                    05120013
TF2      EQU   CNVBF+14                C TARGET DATA BYTE               05160013
TF3      EQU   CNVBF+15                C TARGET PRECISION               05200013
TF4      EQU   CNVBF+16                C TARGET SCALE                   05240013
TF5      EQU   CNVBF+17                H DR,TEMP OFST,REG BY NAME/VALUE 05280013
TF6      EQU   CNVBF+19                H INDEX REG OR NOTHING           05320013
TF7      EQU   CNVBF+21                H ADDITIONAL OFFSET              05360013
         SPACE                                                          05400013
CS       EQU   CNVBF+23                C SOURCE CODE BYTE(SEE PHASE OH) 05440013
CT       EQU   CNVBF+24                C TARGET CODE BYTE(SEE PHASE OH) 05480013
CWO      EQU   CNVBF+25                H OFFSET ON WORKSPACE            05520013
CTV      EQU   CNVBF+27                C TRANSFER VECTOR                05560013
         SPACE 2                                                        05600013
BUFF     EQU   CNVBF+28                256C BUFFER FOR IN-LINE CODE     05640013
*                                        GENERATED BY OH ON OO.         05680013
WSDR     EQU   BUFF+256                DIC REF OF WORK SPACE            05720013
WSDR1    EQU   WSDR+2                  2C DIC REF /F TYPE 1 WS          05760013
WSDR2    EQU   WSDR1+2                 2C DIC REF OF TYPE3 WS           05800013
AUTO     EQU   WSDR2+2                                                  05840013
         SPACE 2                                                        05880013
DRSAVE   EQU   SCR+296                 2C SAVE AREA FOR DIC REF         05920013
CHEND    EQU   SCR+298                  2C HEAD OF CONST CHAIN          05960013
         SPACE                                                          06000013
PS       EQU   SCR+300                 H PRECISION OF SOURCE            06040013
QS       EQU   PS+2                    H SCALE OF SOURCE                06080013
LS       EQU   PS+4                    H LENGTH IN BYTES OF SOURCE      06120013
         SPACE                                                          06160013
PT       EQU   PS+6                    H PRECISION OF TARGET            06200013
QT       EQU   PS+8                    H SCALE OF TARGET                06240013
LT       EQU   PS+10                   H LENGTH IN BYTES OF TARGET      06280013
         SPACE                                                          06320013
LINK1    EQU   PS+12                   F LINK ADDRESS FOR MAIN SUBRS    06360013
LINK2    EQU   PS+16                   F LINK ADDRESS FOR INTERNALSUBRS 06400013
         SPACE                                                          06440013
MAPSTT   EQU   PS+20                   F ADDR OF START OF MAP           06480013
MAPEND   EQU   PS+24                   F ADDR OF LAST ACTIVE BYTE OFMAP 06520013
         SPACE                                                          06560013
RHTDGT   EQU   PS+28                   H POINTS AT THE FIRST FIGIT FORM 06600013
*                                        THE RIGHT WHICH A DIGIT OF THE 06640013
*                                        SOURCE ACTUALLY MAPS ONTO      06680013
PLNGTH   EQU   PS+30                   H LNTH OF PIC CHAR STRING        06720013
CNSTLH   EQU   PS+32                   H LENGTH OF FULL CONSTANT TO BE  06760013
*                                        USED IN ED OR EDMK (INCL RIGHT 06800013
*                                        PAD,PATTERN OR LEFT PAD.)      06840013
EDLNTH   EQU   PS+34                   H LENGTH OF THE 'PATTERN' SUBSTR 06880013
*                                        OF FULL EDITING CONST.         06920013
RPLNTH   EQU   PS+36                   H LENGTH OF RIGHT PAD            06960013
EPLUSR   EQU   PS+38                   H SUM OF RPLNTH+EDLNTH           07000013
SCEOFS   EQU   PS+40                   H NO OF BYTES OF SCE MAPPED      07040013
         SPACE                                                          07080013
SDGCNT   EQU   PS+42                   H ROURCE DIGIT COUNT             07120013
TDGCNT   EQU   PS+44                   H TARGET DIGIT COUNT             07160013
         SPACE                                                          07200013
UNCEND   EQU   PS+48                   F POINTS AT END OF UNC STACK     07240013
         SPACE                                                          07280013
CCOUNT   EQU   PS+52                   F POINTS AT TOP OF CNDPTR STACK  07320013
UCOUNT   EQU   PS+56                   F POINTS AT TOP OF UNCPTR STACK  07360013
         SPACE                                                          07400013
DRPLP    EQU   PS+60                   F POINTS AT TOP OF DROP STACK    07440013
SINLP    EQU   PS+64                   F POINTS AT TOP OF SAVE STACK    07480013
         SPACE                                                          07520013
OTXTHS   EQU   PS+68                   F OLD TEXT HEAD,SYMB             07560013
NTXTHS   EQU   PS+72                   F NEW TEXT HEAD,SYMB             07600013
A        EQU   PS+76                                                    07640013
         SPACE 4                                                        07680013
         SPACE                                                          07720013
EDWSFG   EQU   A                       C FLAG SET TO SIGNIFY THAT ED OR 07760013
*                                        EDMK MUST BE INTO WORKSPACE,   07800013
*                                        NOT DIRECT INTO TARGET         07840013
SIGTRG   EQU   A+1                     C SIGNIFICANCE TRIGGER,USED TO   07880013
*                                        MARK WHEN A 'SIGNIFICANCE      07920013
*                                        START' CHAR HAS BEEN PUT IN    07960013
*                                        THE EDITING PATTERN            08000013
RTSPRT   EQU   A+2                     C RIGHT SUPPRESSION TRIGGER(USED 08040013
*                                        WHEN ZERO SUPPRESSION EXTENDS  08080013
*                                        TO THE RIGHT OF THE SOURCE     08120013
*                                      DIGIT POSITIONS).                08160013
FILL     EQU   A+3                     C BLANK OR '*'                   08200013
         SPACE                                                          08240013
CNDCHR   EQU   A+4                     4C STACK OF CONDITIONAL CHARS.   08280013
CNDPTR   EQU   A+8                     4C STACK OF POINTERS SHOWING     08320013
*                                        WHERE TO PUT CNDTNL CHARS.     08360013
UNCCHR   EQU   A+12                    11C STACK OF UNCNDTNL CHARS.     08400013
UNCPTR   EQU   A+23                    11C STACK OF PTRS FOR UNCNL CHRS 08440013
         SPACE                                                          08480013
VEEFLG   EQU   A+35                    C THESE 2 FLAGS ARE USED IN THE  08520013
PNCTFL   EQU   A+36                    C SCAN FOR UNTACKLABLE PICTURES  08560013
CONDCD   EQU   A+37                    C FLAG SET TO SIGNIFY THAT       08600013
*                                        ED/EDMK SETS CONDITION CODE    08640013
RPALTP   EQU   A+38                    C POINTER TO BEGGINNING OF RPALT 08680013
DIGTEX   EQU   A+39                  C FLAG ALL TGT DIGITS EXHAUSTED    08720013
ZOUTFL   EQU   A+40                    C FLAG USED TO TEST FEASIBLE PIC 08740015
         SPACE 2                                                        08760013
MAP      EQU   SCR+512                 256C THIS AREA HOLDS THE PIC     08800013
*                                        STRING BEFORE PROCESSING AND   08840013
*                                        THE EDIT STRING AFTER.IT IS    08880013
*                                        PRECEDED BY 18 BYTES OF WKSP   08920013
*                                        TO ALLOW CSKEL1 TO BE INSERTED 08960013
*                                        IN FRONT OF CONST.THE EXTRA 4  09000013
*                                        BYTES ARE TO ALLOW THE PROCSSD 09040013
*                                        EDIT STRING TO EXCEED THE      09080013
*                                        ORIGINAL STRING.               09120013
         SPACE                                                          09160013
RPALTR   EQU   MAP+256                 256C THIS AREA HOLDS THE ALTERN- 09200013
*                                        ATIVE RIGHT PAD CONST WHEN     09240013
*                                        RIGHT SUPPRESSION EXISTS.      09280013
DUMP     EQU   RPALTR+256              16F REGISTER SAVE AREA           09320013
         EJECT                                                          09360013
         DC    C'OM'                                                    09400013
         L     9,PAR1(13)              SET BASE ADDRESS OF OM           09440013
         BC    B,TEXTSC                SCAN TEXT                        09480013
         BC    B,CHARIN                ENTRY FROM D TO C CONV(EDMK)     09520013
         BC    B,CHERIN                ENTRY FROM D TO C CONV(ED)       09560013
TEXTSC   MVC   ZMYNAM(2,13),IEMOM       SET OWN NAME                    09600013
         SPACE                                                          09640013
         MVI   PAR1+3(13),X'03'        ASK FOR 1536 BYTES OF SCRATCH    09680013
         L     15,ZUGC(11)             STORE.                           09720013
         BALR  14,15                                                    09760013
         SPACE                                                          09800013
         NI    PAR1+3(13),X'00'        ALIGN SCR ON 256 BYTE BOUNDARY   09840013
         L     RH,PAR1(13)             SET RH AS BASE FOR SCRATCH       09880013
         LA    RH,256(RH)              POINT RH BACK WITHIN SCR AREA    09920013
         SPACE                                                          09960013
         LA    RA,LDLSTN                                                10000013
         ST    RA,PAR1(13)             POINT PAR1 AT 'ONZZ'             10040013
         L     15,ZLOADW(11)                                            10080013
         BALR  14,15                   LOAD PHASE ON                    10120013
         L     RJ,PAR1(13)             RJ IS BASE ADDR OF ON            10160013
         SPACE                                                          10200013
         LA    RA,LDLSTO                                                10240013
         ST    RA,PAR1(13)             POINT PAR1 AT 'OOZZ'             10280013
         BALR  14,15                   LOAD PHASE OO                    10320013
         L     RL,PAR1(13)             RL IS BASE ADDR OF OO            10360013
         SPACE                                                          10400013
         MVC   CHEND(2),ZCONCH(13)     PUT HEAD OF CONST CHAIN IN CHEND 10440013
         SPACE                                                          10480013
         MVC   PAR1(4,13),STARTX(13)    PUT START OF TEXT IN PAR1       10520013
         L     15,ZTXTAB(11)            CONVERT SYMBOLIC START OF TEXT  10560013
         BALR  14,15                  TO ABSOLUTE IN PAR1               10600013
         SPACE                                                          10640013
         MVC   OTXTHS(4),STARTX(13)     SAVE OLD TEXT HEAD (SYBOLIC)    10680013
         L     RA,PAR1(13)             POINT RA AT OLD TEXT HEAD(ABS)   10720013
         SR    RO,RO                                                    10760013
         ST    RO,PAR2(13)              CLEAR PAR2                      10800013
         L     15,ZUTXTC(11)            GET EMPTY TEXT BLOCK (SYBOLIC   10840013
         BALR  14,15                  IN PAR1, ABSOLUTE IN PAR2)        10880013
         MVC   NTXTHS(4),PAR1(13)       SAVE NEW TEXT HEAD (SYBOLIC)    10920013
         MVC   STARTX(4,13),NTXTHS     SET NEW START OF TEXT            10960013
         L     RD,PAR2(13)             POINT RD AT NEW TEXT HEAD(ABS)   11000013
         EJECT                                                          11040013
*              THE FOLLOWING CODE COPIES OLD TEXT BLOCKS ACROSS INTO    11080013
*        NEW BLOCKS REMOVING ANY 'CNVC' MACROS AND PASSING THESE TO THE 11120013
*        APPROPRIATE ROUTINE IN OM-ON-OO WHICH WILL GENERATE    IN-LINE 11160013
*        CODE FOR THE CONVERSION AND PASSES THIS BACK VIA A BUFFER,     11200013
*        'BUFF' WHICH CON TAINS ONLY PSEUDOCODE.A.HALFWORD 'ILNGTH'     11240013
*        GIVES THE NO. OF BYTES IN THE BUFFER.                          11280013
*              RA IS THE INPUT TEXT POINTER                             11320013
*              RD IS THE OUTPUT TEXT POINTER                            11360013
*              RE COUNTS THE NO. OF BYTES(+3) PUT IN THE NEW BLOCK      11400013
*              RC HOLDS THE LENGTH OF THE CURRENT ITEM                  11440013
         SPACE 4                                                        11480013
         LA    RE,3                    USE RE TO HOLD CURRENT LENGTH+3  11520013
*                                    OF NEW TEXT BLOCK                  11560013
         BC    B,LOOP6                 ENTER MAIN SCAN LOOP             11600013
         SPACE                                                          11640013
CONT2    AR    RD,RC                   UPDATE OUTPUT POINTER            11680013
CONT1    AR    RA,RC                   UPDATE INPUT POINTER             11720013
         SPACE                                                          11760013
LOOP6    CLI   0(RA),X'40'             IS NEXT ITEM 3-BYTE?             11800013
         BC    BL,THREEB               IF SO,BRANCH                     11840013
         SPACE                                                          11880013
         CLI   0(RA),X'C0'             IS NEXT ITEM 5-BYTE?             11920013
         BC    BL,FIVEB                IF SO,BRANCH                     11960013
         SPACE                                                          12000013
         CLI   0(RA),X'DC'             IS NEXT ITEM VAR,NOT CNVC?       12040013
         BC    BL,VARB                 IF SO,BRANCH                     12080013
         SPACE                                                          12120013
         CLI   0(RA),X'E0'             IS NEXT ITEM CNVC?               12160013
         BC    BL,CNVCDE               IF SO,BRANCH                     12200013
         SPACE                                                          12240013
*              THIS DEALS WITH VARIABLE LENGTH PSEUDOCODE ITEMS         12280013
VARB     SR    RC,RC                                                    12320013
         IC    RC,2(RA)                LOAD LENGTH OF VARIABLE ITEM     12360013
         SPACE                                                          12400013
         BAL   RG,TSTRM                CHECK FOR ENOUGH ROOM IN BLOCK   12440013
         SPACE                                                          12480013
         STC   RC,*+5                  SET LENGTH CODE OF NEXT INSTR    12520013
         MVC   0(RC,RD),0(RA)          COPY VAR LENGTH PSCODE ITEM      12560013
         SPACE                                                          12600013
         BC    B,CONT2                 BACK TO CONTINUE SCAN            12640013
         SPACE 2                                                        12680013
*              THIS DEALS WITH 5-BYTE PSEUDOCODE ITEMS                  12720013
FIVEB    LA    RC,5                    LOAD LENGTH OF ITEM              12760013
         BAL   RG,TSTRM                CHECK FOR ENOUGH ROOM IN BLOCK   12800013
         MVC   0(5,RD),0(RA)           COPY TEXT ACROSS                 12840013
         BC    B,CONT2                 CONTINUE SCAN                    12880013
         SPACE 2                                                        12920013
*              THIS DEALS WITH 3-BYTE PSEUDOCODE ITEMS                  12960013
THREEB   LA    RC,3                    LOAD LENGTH OF ITEM              13000013
         BAL   RG,TSTRM                CHECK FOR ENOUGH ROOM IN BLOCK   13040013
         SPACE                                                          13080013
         CLI   0(RA),X'21'             TEST FOR 'END OF BLOCK'          13120013
         BC    BZ,EOBLK                                                 13160013
         SPACE                                                          13200013
         MVC   0(3,RD),0(RA)           COPY TEXT ACROSS                 13240013
         SPACE                                                          13280013
         TM    0(RA),X'08'             IS 3-BYTE ITEM IN UPPER HALF OF  13320013
         BC    BZ,CONT2                TABLE? BRANCH IF SO              13360013
         SPACE                                                          13400013
         TM    0(RA),X'E6'             TEST FOR PROC,PROC',BEGIN,BEGIN' 13440013
         BC    BZ,PROC                                                  13480013
         SPACE                                                          13520013
         CLI   0(RA),X'39'             TEST FOR FORMAT                  13560013
         BC    BZ,FMTON                SET WS TO TYPE 3                 13600013
         CLI   0(RA),X'3A'             TEST FOR FORMAT'                 13640013
         BC    BZ,FMTOFF               SET WS TO TYPE 1                 13680013
         SPACE                                                          13720013
         CLI   0(RA),X'0B'             TEST FOR END OF PROG1            13760013
         BC    BZ,EOP                                                   13800013
         CLI   0(RA),X'0C'             TEST FOR END OF PROG2            13840013
         BC    BZ,EOP2                                                  13880013
         SPACE                                                          13920013
         BC    B,CONT2                 CONTINUE SCAN                    13960013
         EJECT                                                          14000013
*              THE END OF THE INPUT BLOCK HAS BEEN FOUND.MARK THE OLD   14040013
*        BLOCK 'FREE' AND GET NEXT TEXT BLOCK.POINT RA AT HEAD OF NEW   14080013
*        BLOCK.                                                         14120013
EOBLK    MVC   PAR1(4,13),OTXTHS       PUT OLD TEXT NAME IN PAR1        14160013
         MVI   PAR2+3(13),X'01'        MARK OLD BLOCK FREE              14200013
         L     15,ZCHAIN(11)           GET NEXT TEXT BLOCK              14240013
         BALR  14,15                                                    14280013
         SPACE                                                          14320013
         MVC   OTXTHS(4),PAR1(13)      SAVE OLD TEXT HEAD(SYMB)         14360013
         L     RA,PAR2(13)             POINT RA AT TEXT HEAD            14400013
         BC    B,LOOP6                 CONTINUE TEXT SCAN               14440013
         SPACE 2                                                        14480013
*              THIS SUBROUTINE CHECKS WHETHER THERE IS ENOUGH ROOM IN   14520013
*        THE CURRENT BLOCK,TO ADD THE NEW PSEUDOCODE ITEM(WHOSE LENGTH  14560013
*        IS IN RC).THE TEST ALWAYS LEAVES AT LEAST 3 FREE BYTES SO THAT 14600013
*        END OF BLOCK CAN BE PUT IN.                                    14640013
*              THE RETURN REG IS RG.                                    14680013
TSTRM    AR    RE,RC                   ADD PSCODE ITEM LENGTH TO CURRNT 14720013
*                                    BLOCK LENGTH.                      14760013
         C     RE,TXTSZ(13)            DOES IT EXCEED ALLOWED SIZE?     14800013
         BCR   BL,RG                   NO,THEN EXIT                     14840013
         SPACE                                                          14880013
*              THERE IS NOT ENOUGH ROOM LEFT IN NEW BLOCK TO TAKE THE   14920013
*        NEXT ITEM.SO PUT 'END OF BLOCK',MARK BLOCK 'NOT WANTED'AND GET 14960013
*        NEW BLOCK.RESET RE AND RD.RETURN REG. IS RG.                   15000013
         SPACE 4                                                        15040013
         MVC   0(3,RD),EOBMK           MOVE END OF BLK MARKER INTO TEXT 15080013
         SPACE                                                          15120013
         MVC   PAR1(4,13),NTXTHS       PUT CURRENT NAME OF NEW BLOCK IN 15160013
*                                      PAR1                             15200013
         MVI   PAR2+3(13),X'82'        MARK CURRENT BLK 'NOT WANTED'    15240013
         L     15,ZUTXTC(11)           GET NEXT EMPTY BLK AND CHAIN IT  15280013
         BALR  14,15                                                    15320013
         SPACE                                                          15360013
         MVC   NTXTHS(4),PAR1(13)      SAVE NEW TEXT HEAD(SYMB)         15400013
         L     RD,PAR2(13)             POINT AT NEW TEXT HEAD(ABS)      15440013
         LA    RE,3(RC)                RESET CURRENT LENGTH OF NEW BLCK 15480013
         BCR   B,RG                                                     15520013
         SPACE 4                                                        15560013
*              THIS DEALS WITH PROC, PROC', BEGIN, BEGIN', ALL OF WHICH 15600013
*        ARE TREATED IDENTICALLY.THE VALUES OF WK SP DIC REFS 1 AND 2   15640013
*        ARE SET.                                                       15680013
         SPACE 2                                                        15720013
PROC     CLC   1(2,RA),K0              IS DR ZERO?                      15760013
         BC    BE,CONT2                SO END OF TEXT                   15800013
         SPACE                                                          15840013
         MVC   PAR1+2(2,13),1(RA)      PUT PROC DR IN PAR1              15880013
         MVC   AUTO(2),1(RA)           AND IN AUTO SLOT                 15920013
         L     15,ZDRFAB(11)           FIND ABS ADDR OF DIC ENTRY       15960013
         BALR  14,15                                                    16000013
         SPACE                                                          16040013
         L     RB,PAR1(13)             LOAD ENTRY ADDR                  16080013
         MVC   WSDR1(2),13(RB)         GET DR OF WS TUPE1               16120013
         MVC   WSDR2(2),17(RB)         GET DR OF WS TYPE3               16160013
         SPACE 2                                                        16200013
*              SET FORMAT ES TO NORMAL 'OFF' STATE                      16240013
         SPACE 2                                                        16280013
FMTOFF   MVC   WSDR(2),WSDR1                                            16320013
         BC    B,CONT2                 CONTINUE SCAN                    16360013
         SPACE 2                                                        16400013
*              SET FORMAT WS ON                                         16440013
         SPACE 2                                                        16480013
FMTON    MVC   WSDR(2),WSDR2                                            16520013
         BC    B,CONT2                 CONTINUE SCAN                    16560013
         SPACE 2                                                        16600013
         SPACE 2                                                        16640013
*              THIS SETS THE SECOND FILE POINTER                        16680013
         SPACE 2                                                        16720013
EOP       LA    RO,3(RD)               POINT RO AT START OF 2ND FILE    16760013
          ST   RO,PAR2(13)              SET IN PAR2                     16800013
         MVC   PAR1(4,13),NTXTHS       PUT SYM ADDR OF CRNT BLK IN PAR1 16840013
         L      15,ZTXTRF(11)                                           16880013
         BALR  14,15                   GET SYM STRT OF 2ND FILE IN PAR1 16920013
          MVC   Z2FILE(4,13),PAR1(13)  PUT IN Z2FILE SLOT               16960013
         BC     B,CONT2                CONTINUE SCAN                    17000013
         SPACE 4                                                        17040013
*              END OF PROGRAM                                           17080013
*        THIS MARKS THE LAST OLD BLK FREE AND LAST NEW ONE 'NOT         17120013
*        WANTED'                                                        17160013
EOP2     MVC   PAR1(4,13),NTXTHS        PUT NEW BLOCK ADDRESS IN PAR1   17200013
         ST    RD,PAR2(13)              POINT PAR2 AT EOP2              17240013
         L     15,ZTXTRF(11)                                            17280013
         BALR  14,15                    GET SYM ADDR OF EOP2 IN PAR1    17320013
         MVC   ZNXTLC(4,13),PAR1(13)   PUT IN ZNXTLC SLOT               17360013
         MVC   PAR1(4,13),NTXTHS       PUT NEW BLOCK ADDRESS IN PAR1    17400013
         MVI   PAR2+3(13),X'02'          MARK NEW BLOCK 'NOT WANTED'    17440013
         L     15,ZALTER(11)                                            17480013
         BALR  14,15                   ENTER ZALTER                     17520013
         SPACE                                                          17560013
         MVC   PAR1(4,13),OTXTHS       PUT OLD BLOCK ADDRESS IN PAR 1   17600013
         MVI   PAR2+3(13),X'01'                                         17640013
         BALR  14,15                   ENTER ZALTER                     17680013
         SPACE                                                          17720013
         MVI   PAR1+3(13),X'01'        RELEASE ALL SCRATCH STORE        17760013
         L     15,ZURC(11)                                              17800013
         BALR  14,15                                                    17840013
         SPACE                                                          17850015
         BAL   14,WARCON               OUTPUT FINAL WARNING MESSAGE     17860015
         SPACE                                                          17880013
         SPACE                                                          17920013
EXIT     LA    RA,RLSLST               POINT RA AT RELEASE LIST         17960013
         ST    RA,PAR1(13)             SET POINTER IN PAR1              18000013
         SR    RA,RA                                                    18040013
         ST    RA,PAR2(13)             CLEAR PAR2                       18080013
         L     15,RLSCTL(11)           POINT 15 AT RELEASE CONTROL      18120013
         BALR  14,15                   END OF PHASE                     18160013
         EJECT                                                          18200013
*              A CNVC MACRO HAS BEEN FOUND.SAVE ALL REGS AND BRANCH ON  18240013
*        TRANSFER VECTOR                                                18280013
         SPACE 2                                                        18320013
CNVCDE   MVC   CNVBF(MCROLH),0(RA)     PUT CONV MACRO IN BUFFER         18360013
         MVC   ZSTAT(2,RM),MCROLH(RA)  SAVE STATEMENT NO.               18380015
         SPACE                                                          18400013
         SR    RC,RC                                                    18440013
         IC    RC,CTV                  LOAD TRANSFER VECTOR             18480013
         CH    RC,K32                  IS TRANSFER VECTOR>=32,IE IN OP? 18490015
         BC    BNL,PASS                YES,SO PASS CNVC MACRO THROUGH   18500015
         STM   0,15,DUMP               SAVE ALL REGISTERS               18520013
         BAL   14,SWTCH1(RC)           BRANCH TO SUBROUTINES FOR CODE   18560013
*                                      GENERATION                       18600013
         SPACE 4                                                        18640013
*              ON RETURN FROM CODE GENERATION ROUTINES CHECK THAT NEW   18680013
*        CODE WILL FIT IN BLOCK,PUT IT IN AND CONTINUE SCAN.            18720013
         SPACE 2                                                        18760013
         LM    0,15,DUMP               RESTORE ALL REGISTERS            18800013
         SPACE                                                          18840013
         LH    RC,ILNGTH               GET IN LINE LENGTH               18880013
CONT47   BAL   RG,TSTRM                TEST FOR ROOM IN NEW BLOCK       18920015
         SPACE                                                          18960013
         STC   RC,*+5                  STORE LENGTH CODE IN MVC INSTR.  19000013
         MVC   0(RC,RD),BUFF             MOVE IN LINE CODE INTO TEXT    19040013
         AR    RD,RC                   UPDATE OUTPUT POINTER            19080013
         IC    RC,2(RA)                GET LENGTH OF CONVC MACRO        19120013
         BC     B,CONT1                BACK TO CONTINUE SCAN            19160013
         SPACE 2                                                        19168015
PASS     MVC   BUFF(MCROLH),CNVBF      OLD CNV MACRO=NEW'IN-LINE'CODE   19176015
         LA    RC,MCROLH               RC HOLDS IN-LINE CODE LENGTH     19184015
         STC   RC,BUFF+2               NEW LENGTH OF MACRO (LESS SN)    19188015
         BC    B,CONT47                BACK TO MAIN FLOW                19192015
         EJECT                                                          19200013
SWTCH1   BC    B,UNPACK                DEC TO PIC(NO PUNCT OR SUPPR.)   19240013
         BC    B,PACK                  PIC TO DEC                       19280013
         BC    B,EDIT                  DEC TO PIC (PUNCT.AND SUPPR)     19320013
         BC    B,EDMK                  DEC TO PIC (DRIFTING STRING)     19360013
         BC    B,DTOB                  DEC TO BIN                       19400013
         BC    B,DTOC                  DEC TO CHAR(U>=V>=0)             19440013
         SPACE 4                                                        19480013
         EJECT                                                          19520013
*        CONSTANTS AND OFFSETS                                          19560013
         SPACE 4                                                        19600013
K0       DC    H'0'                                                     19640013
K1       DC    H'1'                                                     19680013
K3       DC    H'3'                                                     19720013
K32      DC    H'32'                                                    19740015
RLSLST   DC    C'OMONOOZZ'             RELEASE LIST                     19760013
LDLSTN   DC    C'ONZZ'                                                  19800013
LDLSTO   DC    C'OOZZ'                                                  19840013
EOBMK    DC    X'210000'               END OF BLOCK MARKER              19880013
         EJECT                                                          19920013
ON       EQU   IEMOM+X'1000'                                            19960013
OO       EQU   IEMOM+X'2000'                                            20000013
         SPACE                                                          20040013
UNPACK   EQU   ON+2                                                     20080013
PACK     EQU   UNPACK+4                                           54764 20120064
WARNCN   EQU   PACK+4                                             54764 20125064
WARCON   EQU   WARNCN+4                                           54764 20130064
PLUSZERO EQU   WARCON+4      MAKES DE FOR PACKED ZERO CONSTANT.   47647 20135056
DICENT   EQU   PLUSZERO+4              ROUTINE TO COMMON CONSTS.  54764 20140064
ACONSTR  EQU   DICENT+4                OFFSET-2 OF CONSTR IN ON.  54764 20150064
DTOB     EQU   OO+2   '                OFFSET FOR ENTRY TO DEC TO BIN   20160013
DTOC     EQU   OO+6                    OFFSET FOR ENTRY FOR DC TO CHAR  20200013
GIVEUP   EQU   OO+10                   FALL BACK ON LIBR CALL           20240013
         SPACE                                                          20320013
STARTX   EQU   256                     START OF TEXT POINTER            20360013
ZSTAT    EQU   X'7E'                                                    20380015
PAR1     EQU   X'80'                                                    20400013
PAR2     EQU   X'84'                                                    20440013
ZTXTAB   EQU   X'54'                   CONVERT SYMB, TO ABS.            20480013
ZALTER   EQU   X'5C'                   SET STATUS OF BLOCK              20520013
ZUTXTC   EQU   X'14'                   FIND VACANT TEXT BLOCK           20560013
ZMYNAM   EQU   112                                                      20600013
ZDRFAB   EQU   X'34'                   CONVERT DIC REF TO ABS           20640013
ZLOADW   EQU   X'24'                                                    20680013
TXTSZ    EQU   264                     LENGTH OF TEXT BLOCK             20720013
ZCHAIN   EQU   X'58'                   GET NEXT BLOCK IN CHAIN          20760013
ZTXTRF   EQU   X'50'                                                    20800013
ZNXTLC   EQU   276                                                      20840013
Z2FILE   EQU   348                                                      20880013
ZUGC     EQU   X'10'                                                    20920013
ZURC     EQU   X'18'                                                    20960013
         SPACE 4                                                        21000013
RLSCTL   EQU   X'48'                                                    21040013
MCROLH   EQU   28                                                       21080013
WSOFST   EQU   13                      OFFSET IN ENTRY TYPE ONE TO      21120013
*                                      GIVE WORKSPACE DIC REF           21160013
         SPACE 4                                                        21200013
RO       EQU   0                                                        21240013
RA       EQU   1                                                        21280013
RB       EQU   2                                                        21320013
RC       EQU   3                                                        21360013
RD       EQU   4                                                        21400013
RE       EQU   5                                                        21440013
RF       EQU   6                                                        21480013
RG       EQU   7                                                        21520013
RH       EQU   8                                                        21560013
RI       EQU   9                                                        21600013
RJ       EQU   10                                                       21640013
RK       EQU   11                                                       21680013
RL       EQU   12                                                       21720013
RM       EQU   13                                                       21760013
         EJECT                                                          21800013
B        EQU   15                    BRANCH UNCOND.                     21840013
BH       EQU   2                     BRANCH ON HIGH                     21880013
BL       EQU   4                     BRANCH ON LOW                      21920013
BE       EQU   8                     BRANCH IF EQUAL                    21960013
BNH      EQU   13                    BRANCH IF NOT HIGH                 22000013
BNL      EQU   11                    BRANCH ON NOT LOW                  22040013
BNE      EQU   7                     BRANCH NOT EQUAL                   22080013
BO       EQU   1                     BRANCH ON O/F OR ONES              22120013
BP       EQU   2                     BRANCH ON PLUS                     22160013
BM       EQU   4                     BRANCH ON MINUS OR MIXED           22200013
BZ       EQU   8                     BRANCH ON ZERO                     22240013
BNM      EQU   9                       BRANCH ON NOT MIXED              22280013
BNZ      EQU   7                       BRANCH ON NOT ZERO               22320013
BNO      EQU   14                                                 24017 22340001
         EJECT                                                          22360013
*              THIS CODE COMPILES IN-LINE ED CODE,FOR DEC TO PIC CONVRT 22400013
*        WHERE EITHER THE PICTURE CONTAINS PUNCTUATION (,/. OR B) OR IT 22440013
*        CONTAINS ZERO SUPPRESSION (BUT NOT DRIFTING CHARS).EDMK DEALS  22480013
*        WITH DRIFTING CHARS AND MUCH OF THE CODE FOR ED AND EDMK IS    22520013
*        COMMON. IN PARTICULAR THE EDITING PATTERNS ARE GENERATED BY    22560013
*        THE SAME SUBROUTINE (PTNGEN).INITIALISATION OF SCALES AND      22600013
*        LENGTH IS BY COMMON SUBROUTINE (INTLSE).                       22640013
         SPACE 4                                                        22680013
EDIT     ST    14,LINK1                SAVE RETURN ADDRESS              22720013
         BAL   14,INTLSE               INITIALISE SCALES AND LENGTHS    22760013
         SPACE 2                                                        22800013
CHERIN   EQU   *                                                        22840013
         BAL   14,PTNGEN               GENERATE COMPLETE EDITING PATTRN 22880013
*                                    AND PUT IN CONSTANT CHAIN.         22920013
         MVI   ED1,X'CE'               PUT ED CODE IN EDIT SKELETON     22960013
         LA    RD,3+USSL               POINT RD AT USE LIST             23000013
         SPACE 2                                                        23040013
*              AT THIS POINT ED AND EDMK MIX.                           23080013
         SPACE 2                                                        23120013
EDMKIN   LA    RB,BUFF                 POINT RB AT OUTPUT BUFFER FOR    23160013
*                                    IN-LINE CODE                       23200013
         SPACE 2                                                        23240013
         SPACE 2                                                        23280013
*              THE NEXT TWO SUBR ENTRYS TAKE CARE OF ANY 'LOAD ADDRESS' 23320013
*        INSTRS THAT MAY HAVE TO BE INSERTED.RA IS SET TO POINT AT      23360013
*        FIRST THE SOURCE FIELDS (SI-S7) AND THEN THE TGT FIELDS(T1-T7) 23400013
*              THE REG USED IN 'LOAD ADDRESS' IS ASSIGNED 14 OR 15,14   23440013
*        BEING SET INITIALLY AND THE SUBR ADDING 1 EVERY TIME A REG IS  23480013
*        USED.IN ADDITION F2 IS USED TO INDICATE WHETHER SUBSEQUENT     23520013
*        COMPILED INSTRUCTIONS SHOULD REGARD F5 AS 'REG BY NAME'.THE    23560013
*        CODE IS    SCE IS DIC REF      SF2 IS '00'                     23600013
*                   SCE IS R BY NAME    SF2 IS '20'                     23640013
*                   TGT IS DIC REF      TF2 IS '00'                     23680013
*                   TGT IS R BY NAME    TF2 IS '40'                     23720013
*              THIS ALLOWS SF2 OR TF2 TO BE 'ORED' WITH THE CODE BYTE   23760013
*        OF THE NEW INSTR.DIC REF INCLUDES WORK SPACE.REG BY VALUE HAS  23800013
*        NO MEANING                                                     23840013
         SPACE 2                                                        23880013
*              IN ADDITION THE SUBROUTINE WILL DROP THE INDEX REG(S) IF 23920013
*        REQUIRED.THERE ARE 4 FORMS OF CNVC PSEUDOCODE CORRESPONDING TO 23960013
*                                                                       24000013
*              DC   DROP ALL REGS                                       24040013
*              DD   DROP TGT REGS                                       24080013
*              DE   DROP SCE REGS                                       24120013
*              DF   DROP NONE                                           24160013
*              IT ALSO TAKES CARE OF DROP,SAVE AND USE LISTS            24200013
         SPACE 4                                                        24240013
         LA    RE,3+DRPL               POINT RE AT DROP LIST            24280013
         LA    RF,3+SINL               POINT RF AT SAVE LIST            24320013
         SPACE                                                          24360013
         MVC   LAREG(2),K14            INITIALISE LA REG AS '14'        24400013
         LA    RA,SF1                  POINT RA AT SCE FIELD 1 IN CNVC  24440013
*                                    MACRO                              24480013
         MVI   SF2,X'20'               SET REG BY NAME FLAG IN SF2 AS   24520013
*                                    DEFAULT VALUE                      24560013
         MVI   SF3,X'00'               USE F3 TO SAY DONT DROP REG      24600013
         TM    CNVBF,X'01'             SHOULD SCE BE DROPPED?           24640013
         BC    BO,CONT28               NO,SO SKIP                       24680013
         MVI   SF3,X'01'               YES,SET FLAG                     24720013
CONT28   BAL   14,LAINDX               CREATE LA INSTR FOR SCE IF INDXD 24760013
         SPACE                                                          24800013
         LA    RA,TF1                  POINT RA AT TGT FIELD            24840013
         MVI   TF2,X'40'               SET REG BY NAME FLAG IN TF2 AS   24880013
*                                    DEFAULT VALUE                      24920013
         MVI   TF3,X'00'               USE F3 TO SAY DONT DROP REG      24960013
         TM    CNVBF,X'02'             SHOULD TGT BE DROPPED?           25000013
         BC    BO,CONT29               NO,SO SKIP                       25040013
         MVI   TF3,X'01'               YES,SET FLAG                     25080013
CONT29   BAL   14,LAINDX               CREATE LA INSTR FOR TGT IF INDXD 25120013
         SPACE 4                                                        25160013
*              THE LAINDX SUBR HAS DROPPED ANY DROPABLE INDEX REGS.WE   25200013
*        MUST PUT A USSL FOR ALL REMAINING REGS AND SAVE THE POINTERS   25240013
*        TO DRPL AND SINL.                                              25280013
         SPACE 4                                                        25320013
         ST    RE,DRPLP                SAVE DROP LIST POINTER           25360013
         ST    RF,SINLP                SAVE SAVE LIST POINTER           25400013
         SPACE                                                          25440013
         LA    RA,USSL                 POINT RA AT USSL SKELETON+1      25480013
         SR    RD,RA                   GET LENGTH OF USSL STACK         25520013
         CH    RD,K3                   TEST FOR NULL LIST               25560013
         BC    BE,CONT44               SKIP NULL                        25600013
         CLI   CTV,X'0C'               IF IN EDMK GENERATE        31177 25606020
         BNE   NOU1                                               31177 25612020
         MVC   0(3,RB),USNG1           USING FOR REG1             31177 25618020
         LA    RB,3(RB)                                           31177 25624020
NOU1     EQU   *                                                  31177 25630020
         STC   RD,USSL+2               SET LENGTH IN SKELETON           25640013
         STC   RD,*+5                  SET LENGTH OF NEXT INSTR         25680013
         MVC   0(RD,RB),USSL           PUT USSL IN BUFFER               25720013
         AR    RB,RD                   UPDATE BUFFER POINTER            25760013
         EJECT                                                          25800013
         SPACE                                                          25840013
*              AT THIS POINT COMPILATION SPLITS INTO 2 STREAMS DEPENDNG 25880013
*        ON WHETHER ED/EDMK CAN BE DONE DIRECT INTO TGT,OR WHETHER WK.  25920013
*        SP MUST BE USED.THE EDIT PATTERN ALWAYS CONTAINS A FILL AT THE 25960013
*        FRONT WHICH MAY CAUSE IT TO EXCEED THE SIZE OF THE TGT,OR      26000013
*        THERE MAY BE OTHER REASONS.THE DECISION TO EDIT INTO WK SP IS  26040013
*        MADE DURING GENERATION OF THE EDIT PATTERN.                    26080013
         SPACE 2                                                        26120013
CONT44   CLI   EDWSFG,X'01'            IS 'EDIT IN WORK SPACE' FLAG SET 26160013
         BC    BE,USEWS                IF SO BRANCH TO USEWS.           26200013
         SPACE 2                                                        26240013
*              NOW WE CAN EDIT STRAIGHT ON TO THE TARGET(WHICH MAY BE   26280013
*        DIC REF,REG BY NAME,OR IN WK SP.INDEXED TGT WILL ALREADY HAVE  26320013
*        BEEN CONVERTED TO ASSIGNED REG(14/15)BY NAME).                 26360013
         SPACE                                                          26400013
*              GENERATE 'MVC  TGT(LT),CONST'                            26440013
         MVI   MVCFLG,X'10'            SET DEFAULT FLAG                 26480013
         OC    MVCFLG(1),TF2           OR WITH TGT BASE REG FLAG        26520013
         MVI   MVCLTH,X'0A'            SET LENGTH OF THIS MVC INSTR     26560013
         LH    RA,LT                   LOAD LENGTH OF TARGET FIELD      26600013
         SH    RA,K1                   SUBTR 1                          26640013
         STC   RA,MVCTLH               SET LENGTH CODE OF MVC INSTR.    26680013
         SPACE                                                          26720013
         MVC   DRTGT1(2),TF5           MOVE IN DIC REF OF TGT (OR REG   26760013
*                                    BY NAME)                           26800013
          MVC   TGTOF1(2),TF7           ADD TEMP OFFSET(IF WK SP)       26840013
         SPACE                                                          26880013
         MVC   0(10,RB),MVC            MOVE COMPLETE INSTR INTO BUFFER  26920013
         LA    RB,10(RB)               UPDATE BUFFER POINTER            26960013
         SPACE 4                                                        27000013
         CLI   CTV,X'0C'               ARE WE IN EDMK?                  27040013
         BC    BNE,CONT36              NO,SO CONTINUE WITH EDIT         27080013
         SPACE 4                                                        27120013
*              IF IN EDMK,GENERATE 'LA  1,SIGSTART' TO SET REG1 POINTNG 27160013
*        AT SIG START CHAR,IN CASE SIGNIFICANCE IS NOT FORCED BY DIGIT. 27200013
         SPACE 2                                                        27240013
         MVC   DRTGT3(2),TF5           SET DIC REF OR REG BY NAME       27280013
          MVI   LAREG2,X'00'            CLEAR FLAG                      27320013
         CLI   TF2,X'40'               WAS TF5 REG BY NAME              27360013
         BC    BNE,CONT37              NO,SO SKIP                       27400013
         MVI   LAREG2,X'80'            YES,SO SET FLAG                  27440013
         SPACE                                                          27480013
CONT37   SR    RA,RA                                                    27520013
         IC    RA,SIGPTR               GET SIG STRT POINTER(REL TO MAP) 27560013
         AH    RA,LT                   LT-PLNGTH+SIGPTR GIVES THE OFSET 27600013
         SH    RA,PLNGTH             FROM FRONT OF ED CONST             27640013
         AH    RA,TF7                  ADD TEMP OFFSET,IF ANY           27680013
          AH    RA,K1                   ADD 1 TO COMPENSATE FOR BCTR 1, 27720013
         STH   RA,SIGPTR               SET AS OFFSET IN LA INSTR.       27760013
         SPACE                                                          27800013
         MVC   0(8,RB),LA2             PUT LA AND OSM1 IN BUFFER        27840013
         ST    RB,LASAV    SAVE ADDR OF LA                              27860001
         LA    RB,8(RB)                UPDATE BUFFER POINTER            27880013
         SPACE 4                                                        27920013
*              GENERATE 'ED TGT+LT-EDLNTH-RPLNTH(EDLNTH),SCE+LS-SCEOFS' 27960013
         SPACE 2                                                        28000013
CONT36   MVI   EDFLAG,X'18'            SET DEFAULT FLAG                 28040013
         OC    EDFLAG(1),SF2           OR WITH SCE BASE REG FLAG        28080013
         OC    EDFLAG(1),TF2           OR WITH TGT BAS  REG FLAG        28120013
         LH    RA,EDLNTH               LOAD LENGTH OF EDIT PATTERN      28160013
         SH    RA,K1                   SUBTR1                           28200013
         STC   RA,EDFLTH               SET LENGTH CODE OF ED INSTR.     28240013
         MVC   DRTGT2(2),TF5           SET DR OF TGT (OR REG BY NAME)   28280013
         SPACE                                                          28320013
         MVC   DRSCE2(2),SF5           SET DR OF SCE (OR REG BY NAME)   28360013
         SPACE                                                          28400013
         LH    RA,LT                   LOAD LENGTH OF TGT IN BYTES      28440013
         SH    RA,EPLUSR               SUBTR LENGTHS OF EDIT PATTERN    28480013
*                                    AND RIGHT PAD                      28520013
         AH    RA,TF7                  ADD IN OFFSET ,IF ANY            28560013
         STH   RA,TGTOF2               SET TGT OFFSET                   28600013
         SPACE                                                          28640013
         LH    RA,LS                   LOAD LENGTH OF SCE IN BYTES      28680013
         SH    RA,SCEOFS               SUBTR NO OF BYTES ACTUALLY       28720013
*                                    MAPPED IN EDIT                     28760013
         AH    RA,SF7                  ADD IN OFFSET ,IF ANY            28800013
         STH   RA,SCEOF2               SET SCE OFFSET                   28840013
         SPACE                                                          28880013
         MVC   0(12,RB),ED1            MOVE COMPLETE INSTR INTO BUFFER  28920013
         LA    RB,12(RB)               UPDATE BUFFER POINTER            28960013
         SPACE 2                                                        29000013
         CLI   CTV,X'0C'               ARE WE IN EDMK?                  29040013
         BC    BNE,CONT39              NO,SO SKIP                       29080013
         BAL   14,BCTRGN               YES,GENERATE BCTR 1,0 ETC.       29120013
         SPACE 4                                                        29160013
CONT39   BC    B,CONT21                NOW ADD MVI INSTRS               29200013
         SPACE 2                                                        29240013
*              THIS GENERATES     'MVC   WS( ),CONST                    29280013
*                                 ED     WS( ),SCE+OFS                  29320013
*                                  MVC   TGT( ),WS+OFS',                29360013
*        WHEN EDIT CANNOT BE DONE DIRECT INTO THE TARGET.               29400013
         SPACE 4                                                        29440013
*              GENERATE  'MVC   WS(EDLNTH+RPLNTH),CONST'                29480013
         SPACE 2                                                        29520013
USEWS    MVI   MVCFLG,X'10'            SET DEFAULT FLAG                 29560013
         MVI   MVCLTH,X'0A'            SET LENGTH OF MVC INSTR          29600013
         LH    RA,EPLUSR               GET EDIT LENGTH PLUS RIGHTPADLTH 29640013
         SH    RA,K1                   SUBTR 1                          29680013
         STC   RA,MVCTLH               SET TGT FIELD LNTH FOR MVC INSTR 29720013
         MVC   DRTGT1(2),WSDR          PUT WK SP AS TARGET FIELD        29760013
         MVC   TGTOF1(2),CWO           PUT IN CURRENT OFFSET ON WK SP   29800013
         SPACE                                                          29840013
         MVC   0(10,RB),MVC            MOVE COMPLETE INSTR INTO BUFFER  29880013
         LA    RB,10(RB)               UPDATE BUFFER POINTER            29920013
         SPACE 4                                                        29960013
         CLI   CTV,X'0C'               ARE WE IN EDMK?                  30000013
         BC    BNE,CONT35              NO,SO CONTINUE WITH EDIT         30040013
         SPACE 4                                                        30080013
*              IF IN EDMK,GENERATE 'LA  1,SIGSTART' TO SET REG1 POINTNG 30120013
*        AT SIG START CHAR,IN CASE SIGNIFICANCE IS NOT FORCED BY DIGIT. 30160013
         SPACE 2                                                        30200013
         MVC   DRTGT3(2),WSDR          PUT WK SP AS TARGET FIELD        30240013
         MVI   LAREG2,X'00'            SET DEFAULT FLAG                 30280013
         SR    RA,RA                                                    30320013
         IC    RA,SIGPTR               PICK UP SIG STRT POINTER(REL TO  30360013
*                                    MAP)                               30400013
         AH    RA,CNSTLH               CNSTLH-PLNGTH+SIGPTR IS OFFSET   30440013
         SH    RA,PLNGTH             FROM FRONT OF ED CONST.            30480013
         AH    RA,CWO                  ADD ANY CURRENT OFFSET ON WK.SP. 30520013
          AH    RA,K1                   ADD 1 TO COMPENSATE FOR BCTR1,0 30560013
         STH   RA,SIGPTR               SET AS OFFSET IN LA INSTR        30600013
         SPACE                                                          30640013
        MVC   0(8,RB),LA2              PUT LA AND OSM1 IN BUFFER        30680013
         ST    RB,LASAV    SAVE ADDR OF LA                              30700001
         LA    RB,8(RB)                UPDATE BUFFER POINTER            30720013
         SPACE 4                                                        30760013
*              GENERATE    'ED   WS(EDLNTH),SCE+LS-SCEOFS'              30800013
         SPACE 2                                                        30840013
CONT35   MVI   EDFLAG,X'18'            SET DEFAULT FLAG                 30880013
         OC    EDFLAG(1),SF2           OR WOTH SCE BASE REG FLAG        30920013
         LH    RA,EDLNTH               GET LENGTH OF EDIT PATTERN       30960013
         SH    RA,K1                   SUBTR 1                          31000013
         STC   RA,EDFLTH               SET FIELD LENGTH FOR EDIT INSTR. 31040013
         MVC   DRTGT2(2),WSDR          SET WK SP AS TGT OF INSTR        31080013
         MVC   DRSCE2(2),SF5           SET SCE DIC REF (OR REG BY NAME) 31120013
         SPACE                                                          31160013
         MVC   TGTOF2(2),CWO           SET TGT OFFSET AS WS OFFSET      31200013
         LH    RA,LS                   GET SCE LENGTH IN BYTES          31240013
         SH    RA,SCEOFS               SUBTR NO OF BYTES ACTUALLY ACTVE 31280013
*                                    IN THE EDIT INSTR                  31320013
         AH    RA,SF7                  ADD IN OFFSET ,IF ANY            31360013
         STH   RA,SCEOF2               SET AS OFFSET IN EDIT INSTR      31400013
         MVC   0(12,RB),ED1            MOVE COMPETED INSTR INTO BUFFER  31440013
         LA    RB,12(RB)               UPDATE BUFFER POINTER.           31480013
         SPACE 2                                                        31520013
         CLI   CTV,X'0C'               ARE WE IN EDMK?                  31560013
         BC    BNE,CONT38              NO,SO SKIP                       31600013
         BAL   14,BCTRGN               GENERATE BCTR 1,0 ETC.           31640013
         SPACE 4                                                        31680013
*              GENERATE    'MVC   TGT(LT),WS+EDLNTH+RPLNTH-LT'          31720013
         SPACE 2                                                        31760013
CONT38   MVI   MVCFLG,X'18'            SET DEFAULT FLAG                 31800013
         OC    MVCFLG(1),TF2           OR WITH TGT BASE REG FLAG        31840013
         MVI   MVCLTH,X'0C'            SET LENGTH OF THIS INSTR.        31880013
         LH    RA,LT                   GET TARGET LENGTH IN BYTES       31920013
         SH    RA,K1                   SUBTR 1                          31960013
         STC   RA,MVCTLH               SET LENGTH CODE FOR THIS INSTR   32000013
         MVC   DRTGT1(2),TF5           SET TGT DIC REF (OR REG BY NAME) 32040013
         SPACE                                                          32080013
         MVC   DRCNST(2),WSDR          SET DR WK SP AS SCE              32120013
         MVC   TGTOF1(2),TF7           ADD OFFSET,IF ANY                32160013
         LH    RA,CWO                  GET CURRENT OFFSET ON WK SP      32200013
         AH    RA,EPLUSR               ADD EDLNTH + RPLNTH              32240013
         SH    RA,LT                   SUBTR TGT LNTH                   32280013
         STH   RA,SCEOF1               SET AS OFFSET TO THIS INSTR      32320013
         MVC   0(12,RB),MVC            MOVE COMPLETED INSTR INTO BUFFER 32360013
         LA    RB,12(RB)               UPDATE BUFFER POINTER            32400013
         SPACE 4                                                        32440013
         BC    B,CONT21                NOW ADD MVI INSTRS               32480013
         EJECT                                                          32520013
         SPACE 2                                                        32560013
*              THE NEXT SECTION IS CONCERNED WITH GENERATING IN-LINE    32600013
*        'MVI' INSTRS.THESE ARE CALLED UNCONDITIONAL AND CONDITIONAL    32640013
*        ACCORDING TO WHETHER THEY ARE PRECEDED BY A CONDTNL BRANCH.    32680013
*        UNCNDTNL MVI'S ARISE FROM                                      32720013
*              1)BLANKS (B) INCLOSED WITHIN A DRIFTING * STRING         32760013
*                       E.G. PIC '**B*BB9'                              32800013
*              2)S+-$,./B OVERWRITTEN IN THE EDITING PATTERN BY THE     32840013
*                       'FILL' OR BY DIGIT SELECT IN THE 'ADFILL'       32880013
*                       SECTION OF THE EDIT PATTERN,(PROVIDED THE OVER- 32920013
*                       WRITING CHAR IS NOT THE SAME AS THE OVERWRITTN) 32960013
         SPACE                                                          33000013
*              THERE CAN ONLY BE ONE CONDITIONAL MVI IN A PICTURE(DUE   33040013
*        TO A LANGUAGE MOD NOT KNOWN WHEN THIS PHASE WAS INITIALLY      33080013
*        WRITTEN).THIS ARISES FROM NON-DRIFTING S + OR -.               33120013
*              NOTE THAT THE 'NORMAL' TREATMENT OF MVI'S DOES NOT       33160013
*        INCLUDE THE EDMK DRIFTING CHAR.THIS IS DEALT WITH BY THE       33200013
*        SUBR  'BCTRGN'.                                                33240013
         SPACE 4                                                        33280013
CONT21   LA    RC,UNCCHR               POINT RC AT HEAD OF UNCCHR STACK 33320013
         LH    RG,UNPTCH               LOAD RO WITH ADDR(UNCPTR-UNCCHR) 33360013
         L     RE,UCOUNT               POINT RE AT TOP OF UNC STACK     33400013
         BAL   14,MVIS                 GENERATE UNCONDNL MVI INSTRS.    33440013
         SPACE 2                                                        33480013
         TM    RTSPRT,X'01'            IS RIGHT SUPPRESSION TRIGGER SET 33520013
         BC    BO,RSCODE               YES,BRANCH TO RIGHT SUPPR CODE   33560013
         SPACE                                                          33600013
CONT27   LA    RC,CNDCHR               LOAD ADDR OF HEAD OF CNDNL STACK 33640013
         C     RC,CCOUNT             I S STACK COUNT EQUAL TO HEAD      33680013
         BC    BE,REGORG               IF SO THEN THERE ARE NO CONDTNL  33720013
*                                    CHARS TO BE INSERTED,AND SO NO     33760013
*                                    MORE CODE TO BE GENERATED.         33800013
*                                      IF NOT THEN THE CONDTNL MVI'S    33840013
*                                    MUST BE PRECEDED BY A 'BC  10,CL', 33880013
*                                    I.E. BRANCH IF THE EDITED NO. IS   33920013
*                                    GR THAN OR =0.THE COND CODE WILL   33960013
         SPACE                                                          34000013
*              ED/EDMK ONLY SET THE CONDITION CODE IF THEY ENCOUNTER    34040013
*        THE SIGN DURING EDIT.SO IF THE EDIT PATTERN IS SHORTER THAN    34080013
*        THE SCE IT WILL BE NECESSARY TO SET THE COND CODE WITH A TEST  34120013
*        UNDER MASK.THIS CAN BE GENERATED BY THE TUMASK SUBROUTINE      34160013
*        WHICH WILL ONLY BE CALLED IF                                   34200013
*              1)ED/EDMK DOES NOT SET COND CODE.THIS IS INDICATED BY    34240013
*                     THE CONDCD FLAG (1 IF COND CODE WILL BE SET)      34280013
*        AND   2)A CONDITIONAL MVI(AND THEREFORE A COND BRANCH)EXISTS   34320013
*        OR    3)THE SPECIAL CASE 'RIGHT SUPPRESSION'EXISTS.IN THIS     34360013
*                     CASE A BRANCH ON ZERO MUST BE GENERATED.          34400013
*        OR    4)IN EDMK THE DRIFTING CHAR IS CONDTNL (S+-).            34440013
         SPACE 4                                                        34480013
         BAL   14,SETCC      SET C.C. AND BUMP EQU #.             47647 34580056
         SPACE                                                          34680013
*              THIS SECTION ASSUMES THE COND CODE WILL BE SET AND GEN-  34720013
*        ERATES                                                         34760013
*                        BC   10,CL.N                                   34800013
*                        MVI  TGT+X,'COND CHAR'                         34840013
*                 CL.N   EQU  *                                         34880013
         SPACE 2                                                        34920013
         MVC   EQUVAL(2),ZEQMAX(13) PUT EQU# INTO BC INSTRN.      47647 35020056
         MVC   0(5,RB),BC              PUT BC INSTR IN BUFFER           35120013
         LA    RB,5(RB)                UPDATE BUFFER POINTER            35160013
         SPACE 2                                                        35200013
         LA    RC,CNDCHR               POINT RC AT COND CHAR STACK      35240013
         L     RE,CCOUNT               POINT RE AT TOP OF COND STACK    35280013
         SPACE                                                          35320013
         LH    RG,CNPTCH               LOAD RO WITH ADDR(CNDPTR-CNDCHR) 35360013
         BAL   14,MVIS                 GENERATE CONDITIONAL MVI INSTRS. 35400013
         SPACE 2                                                        35440013
         MVI   0(RB),X'07'             PUT 'EQU' CODE IN BUFFER         35480013
         MVC   1(2,RB),EQUVAL          AND ITS CORRESP VALUE            35520013
         LA    RB,3(RB)                UPDATE BUFFER POINTER            35560013
         SPACE 2                                                        35600013
REGORG   LA    RA,DRPL                 POINT RA AT DRPL SKELETON        35640013
         L     RD,DRPLP                GET DROP LIST POINTER            35680013
         SR    RD,RA                   GET LENGTH OF DRPL               35720013
         CH    RD,K3                   TEST FOR NULL LIST               35760013
         BC    BE,CONT45               SKIP NULL                        35800013
         STC   RD,DRPL+2               SET LENGTH IN SKELETON           35840013
         STC   RD,*+5                  SET LENGTH IN NEXT INSTR         35880013
         MVC   0(RD,RB),DRPL           PUT DRPL IN BUFFER               35920013
         AR    RB,RD                   UPDATE BUFFER POINTER            35960013
         SPACE                                                          36000013
CONT45   LA    RA,SINL                 POINT RA AT SINL SKELETON+1      36040013
         L     RD,SINLP                GET SAVE LIST POINTER            36080013
         SR    RD,RA                   GET LENGTH OF SINL               36120013
         CH    RD,K3                   TEST FOR NULL LIST               36160013
         BE    DROP1                   SKIP NULL                  31177 36200020
         STC   RD,SINL+2               SET LENGTH IN SKELETON           36240013
         STC   RD,*+5                  SET LENGTH OF NEXT INSTR         36280013
         MVC   0(RD,RB),SINL           PUT SINL IN BUFFER               36320013
         AR    RB,RD                   UPDATE BUFFER POINTER            36360013
         SPACE 1                                                        36366020
DROP1    CLI   CTV,X'0C'               IF IN EDMK GENERATE        31177 36372020
         BNE   EDEXIT                                             31177 36378020
         MVC   0(3,RB),DROP            DROP FOR REG 1             31177 36384020
         LA    RB,3(RB)                                           31177 36390020
         SPACE 4                                                        36400013
*              ALL THE IN-LINE CODE HAS NOW BEEN GENERATED,AND RB       36440013
*        POINTS AT THE BUFFER.SO SET THE IN-LINE PSEUDOCODE LENGTH IN   36480013
*        ILNGTH AND RETURN TO MAIN SCAN.                                36520013
         SPACE 2                                                        36560013
EDEXIT   LA    RC,BUFF                                                  36600013
         SR    RB,RC                                                    36640013
         STH   RB,ILNGTH               SET LENGTH OF IN-LINE CODE       36680013
         SPACE                                                          36720013
         L     14,LINK1                                                 36760013
         BCR   B,14                    EXIT FROM EDIT OR EDMK SUBRS.    36800013
         SPACE                                                          36840013
         EJECT                                                          36880013
*   THIS SUBROUTINE GENERATES "CP  SOURCE,C..=PL1'0' " TO SET THE 47647 36900056
*   CONDITION CODE FOR CASES WHERE IT WAS NOT SET BY ED OR EDMK.  47647 36920056
*   IT THEN GETS THE NEXT EQU NO. FOR USE IN BC INSTRUCTIONS.     47647 36940056
         SPACE 1                                                  47647 36960056
SETCC    EQU   *                                                  47647 36980056
         ST    14,SETCCSAV                                        47647 37000056
         CLI   CONDCD,X'01'  IS C.C. ALREADY SET?                 47647 37020056
         BE    SETCC2        YES. CP NOT NEEDED.                  47647 37040056
         MVI   CPFLG,X'10'   DR+OFFSET IN F3 & F5.                47647 37060056
         TM    SF2,X'20'     IS SOURCE REG-BY-NAME?               47647 37080056
         BZ    SETCC1        NO, BRANCH.                          47647 37100056
         OI    CPFLG,X'40'   SET BIT FOR F3 IS REG.               47647 37120056
SETCC1   MVC   0(3,RB),CP    MOVE FIRST PART TO BUFFER.           47647 37140056
         MVC   4(2,RB),SF5   MOVE DR OR REG,                      47647 37160056
         MVC   8(2,RB),SF7    AND OFFSET TO BUFFER.               47647 37180056
         BAL   14,PLUSZERO   GET DR..CONSTANT ZERO,               47647 37200056
         MVC   6(2,RB),PAR1+2(13) AND MOVE INTO F4.               47647 37220056
         LH    RO,LS         GET SOURCE LENGTH.                   47647 37240056
         BCTR  RO,0          MINUS 1,                             47647 37260056
         SLL   RO,4          SHIFT TO L1 FIELD OF INSTRN.         47647 37280056
         STC   RO,3(,RB)     L2 IS ZERO. PUT L1 & L2 INTO BUFFER. 47647 37300056
         LA    RB,10(,RB)    BUMP BUFFER PTR.                     47647 37320056
         MVI   CONDCD,X'01'  SAY C.C. NOW SET.                    47647 37340056
SETCC2   LH    RO,ZEQMAX(,13)          ADD 1 TO EQU               47647 37360056
         AH    RO,K1                   NUMBER IN                  47647 37380056
         STH   RO,ZEQMAX(,13)          COMMUNICATIONS REGION.     47647 37400056
         L     14,SETCCSAV                                        47647 37420056
         BR    14                                                 47647 37440056
SETCCSAV DC    F'0'          SAVE FOR REG 14.                     47647 37460056
         EJECT                                                          37720013
*              THIS CODE COMPILES IN-LINE EDMK CODE FOR DEC TO PIC      37760013
*        CONVERSION WHERE THE PICTURE CONTAINS A DRIFTING CHARACTER.    37800013
         SPACE 4                                                        37840013
EDMK     ST    14,LINK1                SAVE RETURN ADDRESS              37880013
         SPACE 2                                                        37920013
         BAL   14,INTLSE               INITIALISE SCALES AND LENGTHS    37960013
*                                    AND PUT IN CONSTANT CHAIN.         38000013
CHARIN   MVI   ED1,X'CF'               PUT EDMK IN EDIT SKELETON        38040013
         BAL   14,PTNGEN               GENERATE COMPLETE EDIT PATTERN   38080013
         LA    RD,USSL+5               POINT RD AT USE LIST             38120013
         MVC   USSL+3(2),K1            PUT ASSIGNED REG1 IN USSL        38160013
         SPACE 2                                                        38200013
         BC    B,EDMKIN                JOIN ED GENERATION CODE          38240013
         SPACE 4                                                        38280013
         EJECT                                                          38320013
*              THIS SUBROUTINE SETS UP THE VALUES OF SCALE,PRECISION    38360013
*        AND LENGTH OF SOURCE AND TARGET.                               38400013
         SPACE 2                                                        38440013
INTLSE   ST    14,LINK2                SAVE RETURN ADDRESS              38480013
         SR    RB,RB                                                    38520013
         IC    RB,SF3                  LOAD SCE PRECISION               38560013
         STH   RB,PS                   SAVE IN PS                       38600013
         SPACE                                                          38640013
         LA    RB,2(RB)                SCE PREC+2                       38680013
         SRA   RB,1                    HALVE AND LOSE REMAINDER         38720013
         STH   RB,LS                   SAVE SCE LENGTH IN LS            38760013
         SPACE                                                          38800013
         IC    RB,SF4                  LOAD SCE SCALE                   38840013
         STH   RB,QS                   SAVE IN QS                       38880013
         SPACE                                                          38920013
         MVC   PAR1+2(2,13),TF3        DIC REF OF PIC TO PAR1           38960013
         L     15,ZDRFAB(11)                                            39000013
         BALR  14,15                   CONV DR TO ABS                   39040013
         SPACE                                                          39080013
         L     RA,PAR1(13)             PUT ABS DIC REF IN RA            39120013
         IC    RB,9(RA)                GET TGT PRECISION                39160013
         STH   RB,PT                   SAVE IN PT                       39200013
         SPACE                                                          39240013
         IC    RB,10(RA)               GET TGT SCALE                    39280013
         STH   RB,QT                   SAVE IN QT                       39320013
         SPACE                                                          39360013
         IC    RB,11(RA)               GET TGT FIELD LENGTH             39400013
         STH   RB,LT                   SAVE IN LT                       39440013
         SPACE                                                          39480013
         MVC   PLNGTH(2),1(RA)         MOVE PICTURE CHARLENGTH +13 TO   39520013
         LH    RB,PLNGTH             PLNGTH AND INTO RB                 39560013
         SH    RB,K14                  SUBTR 14 FROM PIC LENGTH+13      39600013
         STC   RB,*+5                  SET LENGTH CODE OF NEXT INSTR.   39640013
         MVC   MAP(RB),13(RA)          PUT PICT STRING IN MAP           39680013
         LA    RA,13(RA,RB)            SAVE ADDR OF LAST PIC CHAR       39690001
         ST    RA,PICEND                                                39700001
         SPACE                                                          39720013
         LA    RB,1(RB)                RESET RB TO LENGTH OF PICTURE    39760013
         STH   RB,PLNGTH               SAVE IN PLNGTH                   39800013
         SPACE                                                          39840013
         L     14,LINK2                                                 39880013
         BCR   B,14                                                     39920013
         EJECT                                                          39960013
*              THIS SUBROUTINE IS USED BY THE EDIT AND EDMK CONVERSION  40000013
*        GENERATION ROUTINES.THERE ARE 5 MAIN SECTIONS.                 40040013
*              1)FIND THE'DRIFTING'CHARACTER(S + - $ Z OR *).           40080013
*                        (ALSO ELIMINATE UNTOUCHABLE CASES)             40120013
*              2)SET RIGHT PAD.                                         40160013
*              3)GENERATE EDITING PATTERN.                              40200013
*              4)SET LEADING 'FILL' OR 'FILLS'.                         40240013
*              5)SET LEFT PAD.                                          40280013
*                                                                       40320013
*              THE DRIFTING CHARACTER IS FOUND BY A SIMPLE SCAN THROUGH 40360013
*        THE PICTURE.THE OTHER FOUR SECTIONS ADD UP TO ONE SCAN OF THE  40400013
*        PICTURE FROM RIGHT TO LEFT TAKING EACH PICTURE CHARACTER ONE   40440013
*        AT A TIME.  ALL FIVE SECTIONS USE A COMMON SUBROUTINE 'CHARSC' 40480013
*        TO EXAMINE THE NEXT PICTURE CHAR.'CHARSC' TRANSFERS CONTROL TO 40520013
*        AN ADDRESS WHICH IS DEDUCED FROM                               40560013
*              1)THE CHAR BEING EXAMINED (Z*S+-$9VB,/.)                 40600013
*              2)A LIST OF SINGLE BYTE OFFSETS SET ON ENTRY TO 'CHARSC' 40640013
*        E.G. SUPPOSE A '+' IS FOUND IN THE PICTURE.THIS IS THE FOURTH  40680013
*        POSSIBLE CHARACTER SO THE FOURTH BYTE OF THE OFFSET LIST WILL  40720013
*        BE TAKEN.ITS VALUE E.G.76 WILL THEN POINT TO OFFSET 76 FROM PN 40760013
*        THE ADDRESS IMMEDIATELY FOLLOWING THE SUBROUTINE CALL.         40800013
         EJECT                                                          40840013
*              THIS IS THE FIRST SECTION OF THE SUBROUTINE              40880013
         SPACE 4                                                        40920013
*              FIND DRIFTING CHARACTER (S + - $ Z OR *)                 40960013
         SPACE                                                          41000013
*              TWO COUNTS ARE USED, IN RA AND RB. RA COUNTS THROUGH THE 41040013
*        PICTURE CHARACTERS FROM LEFT TO RIGHT. FOR EACH VALUE OF RA,   41080013
*        RB COUNTS THROUGH THE REMAINING CHARACTERS TO SEARCH FOR COIN- 41120013
*        CIDENCE WITH THE TEST CHAR WHICH RA POINTS AT.INITIALLY THE    41160013
*        PICTURE IS HELD IN 'MAP' WITH ITS LENGTH IN 'PLNGTH'.          41200013
         SPACE 4                                                        41240013
PTNGEN   ST    14,LINK2                SAVE RETURN ADDRESS              41280013
         LA    RA,MAP                  GET ADDR OF START OF MAP         41320013
         ST    RA,MAPSTT               SAVE IN MAPSTT                   41360013
         AH    RA,PLNGTH               ADD LENGTH OF PICTURE            41400013
          SH   RA,K1                   SUBTRACT 1                       41440013
         ST    RA,MAPEND               STORE AS END OF MAP              41480013
         LA    RA,MAP                  SET OUTER COUNT TO FIRST CHAR.   41520013
         MVI   FILLMK,X'00'            SET FILLMK TO NULL               41560013
         MVI   FILL,X'00'              SET FILL TO NULL           24017 41580001
         SPACE                                                          41600013
LOOP8    BAL   14,CHARSC               LOOK AT CHAR. OF PICTURE         41640013
*                                      N.B.CHARSC COUNTS RA DOWN 1      41680013
         SPACE                                                          41720013
P1       DC    AL1(SETFLL-P1)          Z                                41760013
         DC    AL1(SETFLL-P1)          *                                41800013
         DC    AL1(DRFTER-P1)          S                                41840013
         DC    AL1(DRFTER-P1)          +                                41880013
         DC    AL1(DRFTER-P1)          -                                41920013
         DC    AL1(DRFTER-P1)          $                                41960013
         DC    AL1(NODRFT-P1)          9                                42000013
         DC    AL1(NODRFT-P1)          V                                42040013
         DC    AL1(NODRFT-P1)          B                                42080013
         DC    AL1(NODRFT-P1)          ,                                42120013
         DC    AL1(NODRFT-P1)          /                                42160013
         DC    AL1(NODRFT-P1)          .                                42200013
         DC    AL1(ERROR1-P1)          FILLMK (NOT USED)                42240013
         SPACE 2                                                        42280013
ERROR1   BC    B,ERROR                                            24017 42300001
DRFTER   LA    RB,2(RA)                POINT RB AT NEXT CHAR AFTER      42320013
*                                      TEST CHAR                        42360013
         SPACE                                                          42400013
LOOP7    CLC   0(1,RB),1(RA)           COMPARE TEST CHAR WITH ONE OFTHE 42440013
*                                    SUCCEEDING CHARS.                  42480013
         BC    BE,SETFLL               IF THE TWO CHARS.AGREE THEN THE  42520013
*                                    DRIFTING CHAR HAS BEEN FOUND.SO    42560013
*                                    BRANCH TO SET 'FILL' AND 'FILLMK'  42600013
         LA    RB,1(RB)                IF NO AGREEMENT THEN INCREASE    42640013
*                                    INNER COUNT BY 1                   42680013
         C     RB,MAPEND               COMP.INNERCNT WITH END OF STRING 42720013
         BC    BNH,LOOP7               BACK IF UNTESTED CHARS REMAIN    42760013
         SPACE                                                          42800013
NODRFT   LA    RA,2(RA)                ADD 1 TO OUTER COUNT             42840013
         C     RA,MAPEND               COMP. OUTERCNT WITH END OFSTRING 42880013
         BC    BL,LOOP8                BACK IF AT LEAST TWO CHARS LEFT  42920013
         SPACE                                                          42960013
         TM    0(RA),X'39'             ASTERISK OR Z              24017 43010001
         BC    BNO,FILTR1                                         24017 43060001
         SH    RA,K1                                              24017 43110001
         SPACE 2                                                        43160013
*              TWO SIMILAR CHARS HAVE BEEN FOUND (OF THE CHARS.         43200013
*        S + - $ Z *).SINCE ONLY ONE DRIFTING STRING IS ALLOWED PER     43240013
*        PICTURE THIS CHAR. MUST BE THE DRIFTING CHAR.                  43280013
         SPACE 2                                                        43320013
SETFLL   MVC   FILLMK(1),1(RA)         SET FILLMK TO DRIFTING CHAR.     43360013
         MVI   FILL,X'40'              SET FILL=BLANK                   43400013
         CLI   FILLMK,X'79'            COMPARE DRIFTING CHAR WITH '*'   43440013
         BC    BNE,FILTR1              NO,THEN GOTO TEST FOR ROGUEPUNCT 43480013
         MVI   FILL,X'79'              FILL=* IF DRIFTING CHAR IS *     43520013
         SPACE 4                                                        43560013
         EJECT                                                          43600013
*              THIS ROUTINE ELIMINATES A SPECIAL CASE OF PICTURE WHICH  43640013
*        CANNOT BE TACKLED BY ED OR EDMK,NAMELY WHEN PUNCTUATION ,./    43680013
*        APPEARS BETWEEN THE RIGHTMOST ZERO SUPPRESSION CHAR AND THE    43720013
*        LEFTMOST '9',AND IS NOT 'MASKED' BY 'V'.                       43760013
*              E.G.   ZZ,9  **.9  ZZ/V9 CANNOT BE TACKLED WHILE         43800013
*                     ZZV.9  **B9  CAN                                  43840013
*                                                                       43880013
*              THIS ROUTINE SCANS THE PICTURE FROM LEFT TO RIGHT SETTNG 43920013
*        FLAGS 'VEEFLG' AND 'PNCTFL' TO DETECT THE IMPOSSIBLE CASES     43960013
         SPACE 4                                                        44000013
FILTR1   LA    RA,MAP                  POINT RA AT FRONT OF PICTURE     44040013
         MVI   VEEFLG,X'00'            CLEAR V FLAG                     44080013
         MVI   PNCTFL,X'02'            PUNCT FLAG HAS FIRST TIME FLAG   44100015
         MVI   ZOUTFL,X'00'            CLEAR ZOUT FLAG                  44120015
         SPACE                                                          44160013
LOOP14   BAL   14,CHARSC               LOOK AT CHAR OF PICTURE          44200013
         SPACE                                                          44240013
P0       DC    AL1(IGNORE-P0)          Z                                44280013
         DC    AL1(IGNORE-P0)          *                                44320013
         DC    AL1(SETSYN-P0)          S                                44360015
         DC    AL1(SETSYN-P0)          +                                44400015
         DC    AL1(SETSYN-P0)          -                                44440015
         DC    AL1(SETSYN-P0)          $                                44480015
         DC    AL1(NINE1-P0)           9                                44520013
         DC    AL1(FLAGV-P0)           V                                44560013
         DC    AL1(IGNORE-P0)          B                                44600013
         DC    AL1(PUNCT3-P0)          ,                                44640013
         DC    AL1(PUNCT3-P0)          /                                44680013
         DC    AL1(PUNCT3-P0)          .                                44720013
         DC    AL1(FILL1-P0)           FILLMK                           44760013
         SPACE 4                                                        44800013
SETSYN   OI    ZOUTFL,X'08'            BIT SET FOR SIGN                 44810015
         BC    B,IGNORE                                                 44820015
         SPACE 2                                                        44830015
FILL1    MVI   VEEFLG,X'00'            CLEAR BOTH FLAGS EVERY TIME THE  44840013
         MVI   PNCTFL,X'00'            DRIFTING CHAR IS FOUND           44880013
         SPACE                                                          44920013
IGNORE   LA    RA,2(RA)                UPDATE INPUT MAP POINTER         44960013
         C     RA,MAPEND               HAS END OF PIC BEEN REACHED?     45000013
         BC    BNH,LOOP14              NO,GO ROUND LOOP AGAIN           45040013
         SPACE                                                          45080013
*        WE HAVE GOT TO THE END OF THE PICTURE WITHOUT FINDING A '9'.   45120013
*        GIVE UP IF DRIFTING Z OR * WITH V, SIGN OR LEADING PUNCT       45160015
         SPACE                                                          45200013
         CLI   CTV,X'08'             ARE WE IN EDIT?                    45240013
         BC    BNE,TESTTP              NO,  BRANCH                      45260015
         SPACE                                                          45280015
         TM    ZOUTFL,X'0E'                                             45300015
         BC    BNZ,OUT                                                  45320015
         SPACE 2                                                        45340015
*        NOW TEST FOR TRAILING PUNCTUATION                              45360015
TESTTP   CLI   PNCTFL,X'01'            IS PUNCT FLAG SET AT END OF STR? 45380015
         BC    BE,OUT                  YES,THEN IT IS UNMASKED,GIVE UP  45400013
         SPACE                                                          45440013
         BC    B,FILTR2                NO,SO ON WITH NEXT TEST          45480013
         SPACE                                                          45520013
PUNCT3   CLI   VEEFLG,X'01'            IS V FLAG SET?(IS PUNCT MASKED?) 45560013
         BC    BE,IGNORE               IF SO IGNORE                     45600013
         SPACE                                                          45640013
         OC    ZOUTFL(1),PNCTFL        X'02' BIT SET FOR LEADING PUNCT  45660015
         MVI   PNCTFL,X'01'            IF NOT THEN SET PUNCT FLAG       45680013
         BC    B,IGNORE                                                 45720013
         SPACE                                                          45760013
FLAGV    MVI   VEEFLG,X'01'            SET V FLAG                       45800013
         OI    ZOUTFL,X'04'          X'04' BIT SET FOR V                45820015
         BC    B,IGNORE                                                 45840013
         SPACE                                                          45880013
NINE1    CLI   PNCTFL,X'01'            IS PUNCT FLAG SET ON ENCOUNTRING 45920013
*                                    FIRST 9?                           45960013
         BC    BNE,FILTR2              NO,SO GO TO NEXT TEST            46000013
         SPACE                                                          46040013
OUT      L     14,LINK1                YES,THEN GIVE UP ON THIS PICT.   46080013
         BC    B,GIVEUP                                                 46120013
         SPACE 4                                                        46160013
*              ANOTHER CASE THAT CANNOT BE TACKLED IN-LINE IS WHEN THE  46200013
*        SOURCE IS ALIGNED COMPLETELY TO THE RIGHT OF THE TGT.          46240013
*              E.G.    (3,3) TO 'ZZ9'                                   46280013
*                   OR (4,6) TO 'ZZV.9'                                 46320013
*              NAMELY IF SCE PREC-SCE SCALE LESS THAN OR = TO -TGTSCALE 46360013
         SPACE 2                                                        46400013
FILTR2   LH    RO,PS                   LOAD SCE PREC                    46440013
         AH    RO,QT                   ADD TGT SCALE                    46480013
         SH    RO,QS                   SUBTR SCE SCALE                  46520013
         BC    BNH,OUT                 GIVE UP IF NOT GT 0              46560013
         SPACE 4                                                        46600013
*              NOW WE ELIMINATE THE CASE WHERE THE SCE IS ALIGNED       46640013
*        COMPLETELY TO THE LEFT OF THE TGT.                             46680013
*              E.G.   (3,-3) TO 'ZZ9'                                   46720013
*                 OR  (4,0)  TO 'V.999,9'                               46760013
*        THIS CASE COULD THEORETICALLY BE DONE IN-LINE BUT IS NOT WORTH 46800013
*        THE TROUBLE.                                                   46840013
*        THE CONDITION IS TGT SCALE-TGT PREC GTEQ SCE SCALE             46880013
         SPACE 2                                                        46920013
         LH    RO,QT                   GET TGT SCALE                    46960013
         SH    RO,PT                   SUBTR TGT PREC.                  47000013
         SH    RO,QS                   AND SCALE SCE                    47040013
         BC    BNL,OUT                                                  47080013
         SPACE                                                          47120013
         EJECT                                                          47200013
*              THIS IS THE SECOND SECTION OF THE EDIT PATTERN GENRATION 47240013
*        SUBROUTINE AND IT CREATES THE 'RIGHT PAD'.THIS IS THE SUBSTRNG 47280013
*        ON THE EXTREME RIGHT OF THE TOTAL STRING AND IT IS NOT USED IN 47320013
*        THE EDIT OR EDMK INSTR.IT APPEARS IN ORDER TO SUPPLY EITHER    47360013
*              1)ANY ODD CHARS THAT APPEAR TO THE RIGHT OF THE PICTURE  47400013
*                    E.G.'$'                                            47440013
*        OR    2)ANY OVERLAPPING DIGITS WHEN THE PIC OVERLAPS THE SORCE 47480013
*                    ON THE RIGHT,                                      47520013
*        DIGIT POSITIONS TRANSLATE INTO '0'. $,/. ARE COPIED.           47560013
*        S AND + TRANSLATE TO '+'.B- TRANSLATE  TO BLANK.V IS IGNORED   47600013
*              THE FIRST FEW INSTRS MERELY SET UP VARIOUS INITIAL VALUS 47640013
         SPACE 4                                                        47680013
SETRPD   L     RA,MAPEND               RA IS USED TO COUNT BACKWARDS    47720013
*                                    THRU THE ORIGINAL PIC STRING.IT IS 47760013
*                                    INITIALLY SET TO POINT TO THE      47800013
*                                    RIGHTMOST CHAR OF PICTURE.         47840013
         SPACE                                                          47880013
         L     RB,MAPEND               RB IS USED TO COUNT BACK THROUGH 47920013
*                                    NEWLY CREATED PATTERN,WHICH WILL   47960013
*                                    CORRESPOND ONE FOR ONE WITH THE    48000013
*                                    ORIGINAL PIC EXCEPT WHEN 'V' IS    48040013
*                                    OMITTED,AND EXCEPT WHEN ONE OR TWO 48080013
*                                    LEFT OF NEW PATTERN.               48120013
*                                    EXTRA FILL CHARS. APPEAR ON THE    48160013
         SPACE                                                          48200013
         LH    RC,QS                   LOAD SCALE OF SOURCE             48240013
         SH    RC,QT                   SUBTRACT SCALE OF TARGET         48280013
         BC    BNL,CONT4                                                48320013
         SR    RC,RC                                                    48360013
CONT4    STH   RC,SDGCNT               SOURCE DIGIT COUNT IS QS-QT OR 0 48400013
         SPACE                                                          48440013
         MVI   RTSPRT,X'00'            CLEAR RIGHT SUPPRESSION TRIGGER  48480013
         SPACE                                                          48520013
*              THE RIGHT SUPPRESSION TRIGGER IS SET TO 1 WHEN A ZERO    48560013
*        SUPPRESSION CHAR (Z * OR DRIFTING S + - $) IS DETECTED IN A    48600013
*        PIC POSITION COMPLETELY TO THE RIGHT OF THE SCE.               48640013
*              E.G.  (3,0) TO 'ZZZV.Z'                                  48680013
*               OR   (4,-2)TO 'SSS9'                                    48720013
*        FOR FURTHER DETAILS SEE SECTION 'RSCODE'                       48760013
         SPACE 2                                                        48800013
         LA    RD,CNDCHR               RD AND RE POINT TO TWO STACKS    48840013
         LA    RE,UNCCHR             WHICH HOLD RESPECTIVEY LISTS OF    48880013
*                                    CONDTNL AND UNCNDTNL CHARS WHICH   48920013
*                                    ARE TO BE INSERTED (VIA IN-LINE    48960013
*                                    MVI INSTRS) INTO THE FINAL PICTURE 49000013
         SPACE                                                          49040013
         LA    RF,UNCPTR-1                                              49080013
         ST    RF,UNCEND               POINT UNCEND AT END OF UNC STACK 49120013
         MVI   SIGTRG,X'00'            CLEAR THE SIGNIFICANCE TRIGGER   49160013
*                                    WHEN SCANNING BACK THROUGH THE     49200013
*                                    PIC THE FIRST DRIFTING CHAR MUST   49240013
*                                    BE REPLACED BY A SIGNIFICANCE STRT 49280013
*                                    CHAR.THEN THE SIGTRIG WILL BE SET  49320013
*                                    TO ONE AND SUBSEQUENT DRIFTING CHS 49360013
*                                    WILL BE REPLACED BY DIGIT SELECT   49400013
         SPACE                                                          49440013
         MVI   CONDCD,X'00'            CLEAR CONDITION CODE FLAG        49480013
         SPACE                                                          49520013
*              THE CONDITION CODE FLAG WILL BE SET TO 1 TO SIGNIFY THAT 49560013
*        THE IN-LINE CODE GENERATED WILL SET THE CONDITION CODE AT RUN  49600013
*        TIME.(THIS MAY BE BY ED,EDMK OR BY TM)                         49640013
         SPACE 2                                                        49680013
         MVI   DIGTEX,X'00'            CLEAR DIGIT EXHAUSTED FLAG       49720013
         SPACE                                                          49760013
*              THE DIGIT EXHAUSTED FLAG WILL BE SET WHEN ALL DIGIT      49800013
*        CHARS OF THE PICTURE HAVE BEEN SCANNED.THIS WILL THEN SIGNIFY  49840013
*        THAT  FURTHER PUNTUATION(ON THE LEFT)WILL NOT BE SUPPRESSED    49880013
         SPACE 2                                                        49920013
         LH    RC,QT                   LOAD SCALE OF TARGET             49960013
         SH    RC,QS                   SUBTR SCALE OF SCE               50000013
         BC    BL,CONT31               BRANCH IF ED WLDNT SETCOND CODE  50040013
         SPACE                                                          50080013
         MVI   CONDCD,X'01'            SET COND CODE FLAG               50120013
         SPACE                                                          50160013
CONT31   AH    RC,K1                   ADD 1                            50200013
         SPACE                                                          50240013
         BC    BH,CONT23               BRANCH IF RC=RHTDGT GT 0         50280013
         LA    RC,1                                                     50320013
CONT23   STH   RC,RHTDGT               SET RIGHT DIGIT POINTER          50360013
         SR    RC,RC                   USE RC AS TEMPORARY TGT DIGT CNT 50400013
         SPACE 4                                                        50440013
CONT5    BAL   14,CHARSC               LOOK AT CHAR OF PICTURE          50480013
         SPACE                                                          50520013
P2       DC    AL1(ERROR2-P2)          Z                                50560013
         DC    AL1(ERROR2-P2)          *                                50600013
         DC    AL1(SIGN1-P2)           S                                50640013
         DC    AL1(PLUS1-P2)           +                                50680013
         DC    AL1(MINUS1-P2)          -                                50720013
         DC    AL1(COPY10-P2)          $                                50760013
         DC    AL1(DIGIT1-P2)          9                                50800013
         DC    AL1(VEE1-P2)            V                                50840013
         DC    AL1(COPY6-P2)           B                                50880013
         DC    AL1(COPY2-P2)           ,                                50920013
         DC    AL1(COPY2-P2)           /                                50960013
         DC    AL1(COPY2-P2)           .                                51000013
         DC    AL1(RHTSPR-P2)          FILLMK                           51040013
         SPACE 4                                                        51080013
RHTSPR   CLI   SIGTRG,X'01'            IS SIG TRIG SET?                 51120013
         BC    BE,SIGSET               YES SO SKIP                      51160013
         MVI   SIGTRG,X'01'            NO,SO SET                        51200013
         STC   RB,SIGPTR               SAVE SIG START POINTER           51240013
         SPACE                                                          51280013
SIGSET   LA    RC,1(RC)                ADD 1 TO TGT DIGIT COUNT         51320013
         CH    RC,RHTDGT               DO TGT DIGITS OVER LAP SOURCE?   51360013
         BC    BE,SETRPL               YES THEN GO TO 3RD SECTION       51400013
         SPACE                                                          51440013
         MVI   RTSPRT,X'01'            IF FILLMK IS FOUND NV THE TARGE  51480013
*                                    DIGITS TO THE RIGHT OF THE SOURCE, 51520013
*                                    THEN A SPECIAL CASE 'RIGHT SUPPRES 51560013
*                                    SION' EXISTS.SET THE RIGHT SUPPRES 51600013
*                                    SION TRIGGER.                      51640013
         SPACE                                                          51680013
         MVI   0(RB),X'00'             PUT '0' IN 'NORMAL'CONST         51720013
         MVI   256(RB),X'40'           PUT 'BLANK' IN RPALTR,THE SECND  51760013
*                                     CONST WHICH IS USED IF SCE IS 0   51800013
         SPACE                                                          51840013
         CLI   FILL,X'79'              IS DRIFTING CHAR *               51880013
         BC    BNE,SKIP5               NO,SO SKIP                       51920013
         SPACE                                                          51960013
         MVI   256(RB),X'79'           YES,SO SET IN RPALTR             52000013
         SPACE                                                          52040013
SKIP5    BC    B,CONT7                 CONTINUE SCAN                    52080013
        SPACE                                                           52120013
DIGIT1   LA    RC,1(RC)                ADD 1 TO TGT DIGIT OOUNT         52160013
         SPACE                                                          52200013
         CH    RC,RHTDGT               COMPARE TGT DIGIT COUNT TO DETCT 52240013
         BC    BE,SETRPL             OVERLAP WITH SOURCE.BRANCH ON FRST 52280013
*                                    ALIGNED DIGIT OF SOURCE TO THIRD   52320013
*                                    SECTION OF SUBROUTINE,WHICH WILL   52360013
*                                    GENERATE THE ACTUAL EDIT PATTERN   52400013
         SPACE                                                          52440013
         MVI   0(RB),X'00'             NON-SUPPRESSED DIGIT REPLACEDBY0 52480013
         MVI   256(RB),X'00'           AND IN RPALT                     52520013
         SPACE                                                          52560013
CONT7    SH    RB,K1                   COUNT DOWN 1 IN OUTPUT PTTRN PTR 52600013
         BC    B,CONT5                 BACK TO CONTINUE RIGHT PAD SCAN  52640013
         SPACE                                                          52680013
VEE1     CLI   SIGTRG,X'01'            HAS ZERO SUPPR OCCURRED RHT OF V 52720013
         BC    BNE,CONT5               NO,CONTINUE SCAN                 52760013
         BC    B,OUT                   YES,GIVE UP IN-LINE CONVERSION   52800013
         SPACE 2                                                        52840013
SIGN1    MVI   0(RB),X'75'             COPY 'S' AS '+'                  52880013
         MVI   256(RB),X'75'           AND IN RPALT                     52920013
         MVI   0(RD),X'73'             PUT '-' IN CONDITIONAL LIST      52960013
         BC    B,CONT6                                                  53000013
         SPACE 2                                                        53040013
PLUS1    MVI   0(RB),X'75'             COPY '+' AS '+'                  53080013
         MVI   256(RB),X'75'           AND IN RPALT                     53120013
         MVI   0(RD),X'40'             PUT 'B' IN CONDITIONAL LIST      53160013
         BC    B,CONT6                                                  53200013
         SPACE 2                                                        53240013
MINUS1   MVI   0(RB),X'40'             COPY '-' AS 'B'                  53280013
         MVI   256(RB),X'40'           AND IN RPALT                     53320013
         MVI   0(RD),X'73'             PUT '-' IN CONDITIONAL LIST      53360013
         BC    B,CONT6                                                  53400013
         SPACE 2                                                        53440013
CONT6    STC   RB,CNDPTR-CNDCHR(RD)    SAVE OUTPUT STRING POINTER AS    53480013
*                                    PTR FOR CONDTNL IN-LINE MVI        53520013
         LA    RD,1(RD)                ADD 1 TO CNDTNL POINTER COUNT    53560013
         BC    B,CONT7                 CONTINUE RIGHT PAD SCAN          53600013
         SPACE 2                                                        53640013
ERROR2   BC    B,ERROR                                                  53680013
         SPACE                                                          53720013
COPY10   MVC   256(1,RB),1(RA)         COPY INTO RPALT                  53760013
COPY1    MVC   0(1,RB),1(RA)           COPY CHAR ACROSS FROM INPUT      53800013
*                                    STRING TO OUTPUT STRING ($ ,./)    53840013
         BC    B,CONT7                 CONTINUE RIGHT PAD SCAN          53880013
         SPACE                                                          53920013
COPY2    MVI   256(RB),X'40'           PUT BLANK IN PPALTR              53960013
         BC    B,COPY1                                                  54000013
         SPACE                                                          54040013
COPY6    MVI   0(RB),X'40'             PUT BLANK IN OUTPUT STREAM       54080013
         MVI   256(RB),X'40'           AND IN RPALT                     54120013
         BC    B,CONT7                 CONTINUE RIGHT PAD SCAN          54160013
         SPACE 4                                                        54200013
SETRPL   SH    RC,K1                  SUBTR 1 FROM TGTDGCT FOR DIGIT    54240013
*                                    WHICH HAS NOT BEEN MAPPED          54280013
         STH   RC,TDGCNT              RC HELD TBT DIGIT COUNT           54320013
         L     RC,MAPEND              LOAD ADDR OF END OF PICTURE       54360013
         SR    RC,RB                   SUBTR OUTPUT COUNT TO GET NUMBER 54400013
         STH   RC,RPLNTH             OF PLACES IN RIGHT PAD             54440013
         STC   RB,RPALTP               SAVE RPALTR POINTER              54480013
         SPACE                                                          54520013
         BC    B,PATGEN                NOW GO TO 3RD SECTION            54560013
         EJECT                                                          54600013
*              THIS IS THE THIRD SECTION OF THE EDIT PATTERN GENERATION 54640013
*        SUBROUTINE AND IT CREATES THE 'PATTERN',OR THE CENTRAL SUBSTR. 54680013
*        OF THE WHOLE CONSTANT,WHICH ACTUALLY FEATURES IN THE EDIT OR   54720013
*        EDMK INSTR.DIGIT SELECT CHARACTERS REPLACE ALL '9' OR DRIFTING 54760013
*        DIGIT POSITIONS EXCEPT FOR THE DRIFTING CHAR IMMEDIATELY TOTHE 54800013
*        LEFT OF THE FIRST '9',WHICH IS REPLACED BY A SIGNIFICANCESTART 54840013
*        CHARACTER.PUNCTUATION IS COPIED,EXCEPT BLANK WHEN THE FILL IS  54880013
*        '*' AND THE SIGNIFICANCE TRIGGER IS SET.                       54920013
         SPACE 4                                                        54960013
PATGEN   LA    RA,1(RA)                RESET INPUT POINTER FOR CHAR     55000013
*                                    WHICH HAS NOT BEEN COPIED          55040013
         SPACE                                                          55080013
LOOP10   LH    RC,TDGCNT               LOAD TARGET DIGIT COUNT          55120013
         CH    RC,PT                   COMPARE WITH NO. OF DIGITS INTGT 55160013
         BC    BE,LOOP11               IF TGT DIGITS EXHAUSTED THEN     55200013
*                                      BRANCH TO FOURTH SECTION,TO ADD  55240013
*                                      THE FILL CHAR TO THE EDIT PATTRN 55280013
         SPACE                                                          55320013
         LH    RC,SDGCNT               LOAD SOURCE DIGIT COUNT          55360013
         CH    RC,PS                   COMP WITH NO.OF DIGITS IN SOURCE 55400013
         BC    BE,LOOP11               BRANCH TO FOURTH SECT IF SOURCE  55440013
*                                    IS EXHAUSTED.                      55480013
         SPACE 2                                                        55520013
LOOP9    BAL   14,CHARSC               LOOK AT CHAR. OF PICTURE         55560013
         SPACE                                                          55600013
P3       DC    AL1(ERROR3-P3)          Z                                55640013
         DC    AL1(ERROR3-P3)          *                                55680013
         DC    AL1(ERROR3-P3)          S                                55720013
         DC    AL1(ERROR3-P3)          +                                55760013
         DC    AL1(ERROR3-P3)          -                                55800013
         DC    AL1(ERROR3-P3)          $                                55840013
         DC    AL1(DIGSEL-P3)          9                                55880013
         DC    AL1(VEE2-P3)            V                                55920013
         DC    AL1(BLANK1-P3)          B                                55960013
         DC    AL1(COPY3-P3)           ,                                56000013
         DC    AL1(COPY3-P3)           /                                56040013
         DC    AL1(COPY3-P3)           .                                56080013
         DC    AL1(TSTSIG-P3)          FILLMK                           56120013
         SPACE 4                                                        56160013
TSTSIG   CLI   SIGTRG,X'00'            TEST SIGNIFICANCE TRIGGER        56200013
         BC    BNE,DIGSEL              BRANCH IF SET TO PUT DIGITSELECT 56240013
         SPACE                                                          56280013
         MVI   SIGTRG,X'01'            SET SIG TRIG IF NOT SET ALREADY  56320013
         STC   RB,SIGPTR               SAVE POINTER TO SIG START        56360013
         MVI   0(RB),X'C7'             PUT SIGNIFICANCE START IN PATTRN 56400013
         BC    B,CONT8                 CONTINUE TO UPDATE TDGCNT,SDGCNT 56440013
         SPACE 2                                                        56480013
VEE2     CLI   SIGTRG,X'01'            HAS ZERO SUPPR OCCURRED RHT OF V 56520013
         BC    BNE,LOOP9               NO,CONTINUE SCAN                 56560013
         BC    B,OUT                   YES,GIVE UP IN-LINE CONVERSION   56600013
         SPACE                                                          56640013
ERROR3   BC    B,ERROR                                                  56680013
         SPACE                                                          56720013
DIGSEL   MVI   0(RB),X'7B'             MOVE DIGIT SELECT CHAR INTO PTRN 56760013
         SPACE                                                          56800013
CONT8    LH    RC,TDGCNT               ADD 1 TO TGT DIGIT COUNT         56840013
         LA    RC,1(RC)                                                 56880013
         STH   RC,TDGCNT                                                56920013
         SPACE                                                          56960013
         LH    RC,SDGCNT               ADD 1 TO SOURCE DIGIT COUNT      57000013
         LA    RC,1(RC)                                                 57040013
         STH   RC,SDGCNT                                                57080013
         SPACE                                                          57120013
         BC    B,CONT9                 CONTINUE AND UPDATE OUTPUT COUNT 57160013
         SPACE 2                                                        57200013
BLANK1   CLI   FILL,X'40'              COMP FILL WITH BLANK             57240013
         BC    BE,COPY7                BRANCH IF BLANK                  57280013
         SPACE                                                          57320013
         CLI   SIGTRG,X'00'            TEST SIGNIFICANCE TRIGGER        57360013
         BC    BE,COPY7                BRANCH IF NOT SET                57400013
         SPACE                                                          57440013
         MVI   0(RE),X'40'             UNCOND MVI BLANK                 57480013
         STC   RB,UNCPTR-UNCCHR(RE)    SAVE OUTPUT POINTER AS POINTER   57520013
*                                    FOR UNCNDTL IN-LINE MVI            57560013
         LA    RE,1(RE)                ADD 1 TO COUNT OF UNCNDTL CHARS. 57600013
         SPACE                                                          57640013
         C     RE,UNCEND               IS UNC STACK FULL?               57680013
         BC    BH,OUT                  IF SO GIVE UP THIS CONVERSION    57720013
         SPACE                                                          57760013
COPY7    MVI   0(RB),X'40'             PUT BLANK IN OUTPUT SYREAM       57800013
         BC    B,CONT9                                                  57840013
         SPACE                                                          57880013
COPY3    MVC   0(1,RB),1(RA)           COPY CHAR FROM INPUT TO OUTPUT   57920013
         SPACE                                                          57960013
CONT9    SH    RB,K1                   UPDATE OUTPUT STRING COUNT       58000013
         BC    B,LOOP10                BACK TO CONTINUE SCAN            58040013
         SPACE 4                                                        58080013
LOOP11   CLI   FILL,X'00'              IS FILL ZERO?                    58120013
         BC    BNZ,ADFILL              NO,GO TO 4TH SECT                58160013
         MVI   1(RB),X'C7'             YES OVERWRITE MOST SIG DIGIT WIT 58200013
*                                    SIGNIFICANCE START                 58240013
         BC    B,ADFILL                GO TO 4TH SECTION                58280013
         EJECT                                                          58320013
*              THIS IS THE FOURTH SECTION OF THE EDIT PATTRN GENERATION 58360013
*        SUBROUTINE AND IT ADDS TO THE PATTERN SO FAR CREATE EITHER ONE 58400013
*        OR TWO FILL CHARACTERS ON THE LEFT,THE FIRST BEING USED AS THE 58440013
*        FILL GENERATION IN EDIT,THE SECOND BEING REQUIRED ONLY TO ALGN 58480013
*        THE EDIT INSTR TO A FULL BYTE BOUNDARY.CNDTL OR UNCNDTL EDIT   58520013
*        CHARS. WHICH ARE OVERWRITTEN BY EITHER OF THESE FILLS HAVE TO  58560013
*        BE REPLACED BY IN-LINE MVI INSTRS.                             58600013
         SPACE 4                                                        58640013
ADFILL   C     RA,MAPSTT               COMP INPUT COUNT WITH STARTOFMAP 58680013
         BC    BL,CONT10               IF NO MORE CHARS LEFT IN INP     58720013
*                                    PIC THEN BRANCH ROUND CODE WHICH   58760013
*                                    LOOKS AT NEXT CHAR                 58800013
         SPACE 2                                                        58840013
         CLI   FILL,X'00'              IS THERE A DRIFTING STRING?      58880013
         BC    BE,SKIP6                NO,SO CONTINUE                   58920013
         SPACE                                                          58960013
         CLI   SIGTRG,X'01'            HAS DRRFTING STRING STARTED?     59000013
         BC    BNE,OUT                 NO,SO GIVE UP                    59040013
         SPACE                                                          59080013
SKIP6    LH    RC,TDGCNT               GET TGT DIGIT COUNT              59120013
         CLI   CTV,X'08'               ARE WE IN EDIT?  (Z * OR 9)      59160013
         BC    BE,SKIP3                THEN TGT DIG COUNT IS TRUE COUNT 59200013
         SPACE                                                          59240013
         BCTR  RC,0                    SUBTR 1 FOR EXTRA S + - OR $     59280013
         SPACE                                                          59320013
SKIP3    CH    RC,PT                   IS DRIFTING STRING EXHAUSTED?    59360013
         BC    BL,SKIP4                   NO, SO CONTINUE NORMALLY      59400013
         SPACE                                                          59440013
         MVI   DIGTEX,X'01'            YES,SO FLAG'DIGITS EXHAUSTED'    59480013
         SPACE                                                          59520013
SKIP4    BAL   14,CHARSC                  LOOK AT NEXT CHAR OF PICTURE  59560013
         SPACE                                                          59600013
P4       DC    AL1(ERROR4-P4)        Z                                  59640013
         DC    AL1(ERROR4-P4)        *                                  59680013
         DC    AL1(SIGN2-P4)         S                                  59720013
         DC    AL1(PLUS2-P4)         +                                  59760013
         DC    AL1(MINUS2-P4)          -                                59800013
         DC    AL1(COPY4-P4)           $                                59840013
         DC    AL1(NINE2-P4)           9                                59880013
         DC    AL1(VEE3-P4)            V                                59920013
         DC    AL1(COPY8-P4)           B                                59960013
         DC    AL1(PUNCT1-P4)          ,                                60000013
         DC    AL1(PUNCT1-P4)          /                                60040013
         DC    AL1(PUNCT1-P4)          .                                60080013
         DC    AL1(DIGCNT-P4)          FILLMK                           60120013
         SPACE 4                                                        60160013
ERROR4   BC    B,ERROR                                                  60200013
         SPACE                                                          60240013
VEE3     CLI   SIGTRG,X'01'            HAS ZERO SUPPR OCCURRED RHT OF V 60280013
         BC    BNE,ADFILL              NO,CONTINUE SCAN                 60320013
         BC    B,OUT                   YES,GIVE UP IN-LINE CONVERSION   60360013
         SPACE                                                          60400013
PUNCT1   TM    SIGTRG,X'01'            IS SG TRIG SET?                  60440013
         BC    BZ,COPY4                IFNOT THEN COPY PUNCTUATION      60480013
         SPACE                                                          60520013
         CLI   DIGTEX,X'01'            IS THE DRIFTING STRING FINISHED? 60560013
         BC    BE,COPY4                 YES,SO COPY PUNCT               60600013
         SPACE                                                          60640013
         BC    B,CONT10                 NO,SO SUPPRESS                  60680013
DIGCNT   LH    RC,TDGCNT               ADD 1 TO TGT DIGIT COUNT         60720013
         LA    RC,1(RC)                                                 60760013
         STH   RC,TDGCNT                                                60800013
         SPACE                                                          60840013
CONT10   TM    SDGCNT+1,X'01'          IS SOURCE DIGIT COUNT ODD?       60880013
         BC    BNE,ENDADF              IF SO THE GO TO END OF ADD FILL  60920013
         SPACE                                                          60960013
         MVI   0(RB),X'7B'             NO, PUT DIGIT SELECT IN FRONT    61000013
         BCTR  RB,0                    UPDATE OUTPUT POINTER            61040013
         SPACE                                                          61080013
         LH    RC,SDGCNT               IF EVEN THEN ADD ONE TO SOURCE   61120013
         LA    RC,1(RC)                DIGIT COUNT AND GO ROUND LOOP    61160013
         STH   RC,SDGCNT               AGAIN                            61200013
         BC    B,ADFILL                                                 61240013
         SPACE                                                          61280013
NINE2    LH    RC,TDGCNT               ADD 1 TO TGT DIGIT COUNT         61320013
         LA    RC,1(RC)                                                 61360013
         STH   RC,TDGCNT                                                61400013
         SPACE                                                          61440013
         CLI   FILL,X'00'              IS FILL ZERO?                    61480013
         BC    BZ,CONT10               YES,IGNORE 9                     61520013
         SPACE                                                          61560013
         BC    B,OUT                   GIVE UP IF 9'S TO LEFT OF SOURCE 61600013
*                                    WITH DRIFTING STRINGS              61640013
         SPACE 2                                                        61680013
SIGN2    MVI   0(RE),X'75'             UNCONDITIONAL CHAR '+'           61720013
         MVI   0(RD),X'73'             CONDITIONAL CHAR '-'             61760013
         BC    B,CONT11                                                 61800013
         SPACE 2                                                        61840013
PLUS2    MVI   0(RE),X'75'             UNCONDTNL '+'                    61880013
         MVI   0(RD),X'40'             CONDTNL 'BLANK'                  61920013
         BC    B,CONT11                                                 61960013
         SPACE 2                                                        62000013
MINUS2   MVI   0(RE),X'40'             UNCONDTNL 'BLANK'                62040013
         MVI   0(RD),X'73'             CONDTNL '-'                      62080013
         BC    B,CONT11                                                 62120013
         SPACE 2                                                        62160013
CONT11   STC   RB,CNDPTR-CNDCHR(RD)    SAVE OUTPUT POINTER AS POINTER   62200013
*                                    FOR CONDTNL IN-LINE MVI            62240013
         LA    RD,1(RD)                ADD 1 TO COUNT OF CNDTNL CHARS.  62280013
         SPACE                                                          62320013
CONT12   STC   RB,UNCPTR-UNCCHR(RE)    SAVE OUTPUT PTR AS PTR FOR       62360013
*                                    UNCONDTNL IN-LINE MVI              62400013
         LA    RE,1(RE)                ADD 1 TO COUNT OF UNCNDTNL CHARS 62440013
         BC    B,CONT10                CONTINUE LOOP                    62480013
         SPACE                                                          62520013
         C     RE,UNCEND               IS UNC STACK FULL?               62560013
         BC    BH,OUT                  IF SO GIVE UP                    62600013
         SPACE                                                          62640013
COPY8    CLI   FILL,X'40'              IS FILL BLANK?                   62680013
         BC    BE,CONT10                IF SO IGNORE  B                 62720013
         MVI   0(RE),X'40'              IF NOT THEN PUT MVI BLANK       62760013
         BC    B,CONT12                CONTINUE SCAN                    62800013
         SPACE 2                                                        62840013
COPY4    MVC   0(1,RE),1(RA)           COPY PICT CHAR INTO UNCNDTL LIST 62880013
         BC    B,CONT12                GO TO UPDATE UNCNDPTR AND COUNT  62920013
         SPACE                                                          62960013
ENDADF   MVC   0(1,RB),FILL            PUT THE FILL INTO EDIT PATTERN   63000013
         BCTR  RB,0                    UPDATE OUTPUT POINTER            63040013
         SPACE                                                          63080013
         LH    RC,SDGCNT               LOAD SOURCE DIGIT COUNT          63120013
         LA    RC,1(RC)                ADD 1                            63160013
         SRL   RC,1                    HALVE                            63200013
         STH   RC,SCEOFS               SAVE AS SOURCE OFFSET(IE THE NO. 63240013
*                                    OF BYTES OF SOURCE ACTUALLY USED)  63280013
         SPACE                                                          63320013
         L     RC,MAPEND               LOAD ADDRESS OF END OF STRING    63360013
         SR    RC,RB                   SUBTR OUTPUT STRING POINTER      63400013
         SH    RC,RPLNTH               SUBTR LENGTH OF RIGHT PAD        63440013
         STH   RC,EDLNTH               SAVE LENGTH OF EDIT PATTERN      63480013
         EJECT                                                          63520013
*              THIS IS THE LAST SECTION OF THE EDIT PATTERN GENERATION  63560013
*        SUBROUTINE AND IT CREATES THE PASSIVE 'LEFT PAD' OR STRING OF  63600013
*        CHARS ON THE LEFT OF THE PATTERN WHICH ARE COPIED STRAIGHT     63640013
*        ON TO THE TARGET.THE SIGN CHARS ARE COPIED IN THEIR UNCONDTNL  63680013
*        FORM AND CONDTNL CHARS ARE SET IN THE COND LIST.PUNCTUATION IS 63720013
*        REPLACED BY FILL (UNLESS FILL=0).                              63760013
         SPACE 4                                                        63800013
LOOP12   C     RA,MAPSTT               COMP INPUT COUNT WITH STARTOFMAP 63840013
         BC    BL,ENDPTN               IF NO MORE CHARS IN PIC THE END  63880013
*                                    PATTERN GENERATION SUBROUTINE      63920013
         SPACE                                                          63960013
         LH    RC,TDGCNT               GET TGT DIGIT COUNT              64000013
         CLI   CTV,X'08'               ARE WE IN EDIT CODE?             64040013
         BC    BE,SKIP1                YES,SO SKIP                      64080013
         SPACE                                                          64120013
         BCTR  RC,0                    NO,SO SUBTR 1 FROM EFFECTIVE CNT 64160013
         SPACE                                                          64200013
SKIP1    CH    RC,PT                   ARE ALL TGT DIGITS EXHAUSTED?    64240013
         BC    BL,SKIP2                NO,SO SKIP                       64280013
         SPACE                                                          64320013
         MVI   DIGTEX,X'01'            YES,SO FLAG THAT THIS IS SO      64360013
         SPACE                                                          64400013
SKIP2    BAL   14,CHARSC               LOOK AT NEXT CHAR                64440013
         SPACE                                                          64480013
P5       DC    AL1(ERROR5-P5)          Z                                64520013
         DC    AL1(ERROR5-P5)          *                                64560013
         DC    AL1(SIGN3-P5)           S                                64600013
         DC    AL1(PLUS3-P5)           +                                64640013
         DC    AL1(MINUS3-P5)          -                                64680013
         DC    AL1(COPY5-P5)           $                                64720013
         DC    AL1(NINE-P5)            9                                64760013
         DC    AL1(VEE4-P5)            V                                64800013
         DC    AL1(COPY9-P5)           B                                64840013
         DC    AL1(PUNCT2-P5)          ,                                64880013
         DC    AL1(PUNCT2-P5)          /                                64920013
         DC    AL1(PUNCT2-P5)          .                                64960013
         DC    AL1(CPYFIL-P5)          FILLMK                           65000013
         SPACE 4                                                        65040013
ERROR5   BC    B,ERROR                                                  65080013
         SPACE                                                          65120013
CPYFIL   MVC   0(1,RB),FILL            COPY FILL INTO LEFT PAD          65160013
CONT46   LH    RC,TDGCNT               ADD 1 TO TGT DIGIT COUNT         65200013
         LA    RC,1(RC)                                                 65240013
         STH   RC,TDGCNT                                                65280013
         SPACE                                                          65320013
CONT14   SH    RB,K1                   UPDATE STRING POINTER            65360013
         BC    B,LOOP12                BACK TO CONTINUE SCAN            65400013
         SPACE                                                          65440013
VEE4     CLI   SIGTRG,X'01'            HAS ZERO SUPPR OCCURRED RHT OF V 65480013
         BC    BNE,LOOP12              NO,CONTINUE SCAN                 65520013
         BC    B,OUT                   YES,GIVE UP IN-LINE CONVERSION   65560013
         SPACE                                                          65600013
SIGN3    MVI   0(RB),X'75'             PUT '+' IN STRING                65640013
         MVI   0(RD),X'73'             PUT '-' IN CONDTNL LIST          65680013
         BC    B,CONT13                                                 65720013
         SPACE                                                          65760013
PLUS3    MVI   0(RB),X'75'             PUT '+' IN STRING                65800013
         MVI   0(RD),X'40'             PUT 'BL' IN CONDTNL LIST         65840013
         BC    B,CONT13                                                 65880013
         SPACE                                                          65920013
MINUS3   MVI   0(RB),X'40'             PUT 'BL' IN STRING               65960013
         MVI   0(RD),X'73'             PUT '-'  IN CONDTNL LIST         66000013
         BC    B,CONT13                                                 66040013
         SPACE                                                          66080013
CONT13   STC   RB,CNDPTR-CNDCHR(RD)    SAVE POINTER TO CNDTNL MVI       66120013
         LA    RD,1(RD)                ADD 1 TO COUNT OF CNDTNL CHARS   66160013
         BC    B,CONT14                CONTINUE SCAN                    66200013
         SPACE                                                          66240013
COPY5    MVC   0(1,RB),1(RA)           COPY $      STRAIGHT ONTO STRING 66280013
         BC    B,CONT14                CONTINUE SCAN                    66320013
         SPACE                                                          66360013
COPY9    MVI   0(RB),X'40'             PUT BLANK IN OUTPUT STREAM       66400013
         BC    B,CONT46                UPDATE TGT DIGIT COUNT           66440013
         SPACE                                                          66480013
NINE     MVI   0(RB),X'00'             COPY '9' AS '0'                  66520013
         CLI   FILLMK,X'00'               IS THERE NO DRIFTING STRING?  66560013
         BC    BE,CONT14                YES,SOCARRY ON                  66600013
         BC    B,OUT                   GIVE UP IF 9'S TO LEFT OF SOURCE 66640013
*                                    WITH DRIFTING STRINGS              66680013
         SPACE                                                          66720013
PUNCT2   CLI   DIGTEX,X'01'            ANY SUPPRESSED DIGITS STILL?     66760013
         BC    BE,COPY5                NO,SO COPY PUNCT                 66800013
         CLI   FILLMK,X'00'            IS FILLMK ZERO?                  66840013
         BC    BE,COPY5                YES,SO COPY PUNCT                66880013
         SPACE                                                          66920013
         MVC   0(1,RB),FILL            NO,COPY FILL                     66960013
         BC    B,CONT14                                                 67000013
ERROR    DC    X'0000'                 COMPILER ERROR. INVALID CHAR IN  67040013
*                                    PIC IN DEC TO PIC IN-LINE CONVRSN. 67080013
         SPACE                                                          67120013
         SPACE 2                                                        67160013
*              AN ERROR IS NOT LIKELY TO BE RUN TO GROUND HERE,SO NO    67200013
*        EXTERNAL MESSAGE HAS BEEN GENERATED.IF ONE DOES OCCUR CHECK    67240013
*              1. THIS PHASE,IN PARTICULAR 'CHARSC85 SUBROUTINE WHICH   67280013
*                     MAY HAVE FOUND SOME CHARACTER NOT INCLUDED IN ITS 67320013
*                     LIST OF 13 DECODE CHARS.                          67360013
*              2. PHASE OG-OH-OI WHICH MAY HAVE PASSED A PICTURE NOT    67400013
*                     ACCEPTABLE TO IN-LINE CONVERSION OR WHICH MAY     67440013
*                     SET THE CODE TO'EDMK'ON AN 'EDIT'PIC OR VICE-VERS 67480013
*              3. PHASE FQ WHICH MAY HAVE PASSED AN INVALID PICTURE OR  67520013
*                     HAVE DECODED A VALID ONE INCORRECTLY              67560013
*              4. DEC TO CHAR CONVERSION IN PHASE OO,WHICH GENERATES A  67600013
*                     DEC TO PIC WITH AN ARTIFICIAL PICTURE             67640013
         EJECT                                                          67680013
EDINWS   MVI   EDWSFG,X'01'            SET'EDIT IN WORK SPACE' FLAG     67720013
         CH    RA,CNSTLH               COMP EDLNTH+RPLNTH WITH CNSTLH   67760013
         BC    BE,NOPATN               IF CORRECT                       67800013
         SPACE                                                          67840013
ERROR6   DC    X'0000'                 ERROR IN THIS PHASE (LENGTH OF   67880013
*                                    EDIT PATTERN INCORRECT).           67920013
         SPACE 4                                                        67960013
ENDPTN   L     RC,MAPEND               LOAD ADDRESS OF END OF STRING    68000013
         SR    RC,RB                   SUBTR CURRENT POINTER            68040013
         STH   RC,CNSTLH               SAVE AS LENGTH OF CONSTANT       68080013
         SPACE                                                          68120013
         MVI   EDWSFG,X'00'            UNSET 'EDIT IN WORKSPACE' FLAG   68160013
         LH    RA,EDLNTH               LOAD LENGTH OF EDIT PATTERN      68200013
         AH    RA,RPLNTH               ADD LENGTH OF RIGHT PAD          68240013
         STH   RA,EPLUSR               SAVE SUM OF RP AND EP LENGTHS    68280013
         CH    RA,LT                   COMPARE SUM WITH LENGTH OF TGT   68320013
         BC    BH,EDINWS               BRANCH IF PATTERN OVERFLOWS TGT  68360013
         SPACE                                                          68400013
         CH    RC,LT                   COMPARE TGT LNGTH WITH STRINGLTH 68440013
         BC    BNE,ERROR6              IF NOT EQUAL THEN ERROR INTHISPH 68480013
         SPACE 4                                                        68520013
*              NOW PUT THE FULL STRING(LEFT PAD,PATTERN AND RIGHT PAD)  68560013
*        INTO THE CONST CHAIN                                           68600013
         SPACE                                                          68640013
NOPATN   BAL   RG,STCNST               ENTER STORE CONST SUBROUTINE     68680013
         SPACE                                                          68720013
         MVC   DRCNST(2),PAR1+2(13)    SAVE DIC REF OF CONST.           68760013
         SPACE                                                          68800013
*              NOW PUT 'RPALTR' INTO DICT.IF RGHT SUP TRIG IS NOT SET   68840013
*        RPALTR WILL NOT BE USED(ALTHOUGH IT HAS BEEN CORRECTLY GENRTED 68880013
         SPACE 2                                                        68920013
         TM    RTSPRT,X'01'            IS RIGHT SUPPRESSION TRIGGER SET 68960013
         BC    BZ,CONT34               NO,SO SKIP STORING ALTER CONST   69000013
         SPACE                                                          69040013
         LH    RC,RPLNTH               LENGTH OF RIGHT PADST IN RC      69080013
         SR    RB,RB                                                    69120013
         IC    RB,MAPEND+3             GET SIGNIF BYTE OF MAPEND ADDR   69160013
         SR    RC,RB                   SUBTR FROM RP LENGTH             69200013
         IC    RB,SIGPTR               GET RIGHT DIGIT POSN             69240013
         AR    RC,RB                   ADD TO GET ALTER CONST LENGTH    69280013
         CLI   CTV,X'0C'               ARE WE IN EDMK?                  69320013
         BC    BNE,CONT15              NO SO SKIP                       69360013
          SPACE                                                         69400013
         SH    RC,K1                   -1 TO ALLOW FOR MVI DRIFTING CHR 69440013
         BC    BZ,NOCNST               IF NOW 0 THEN CONST IS NULL,SO   69480013
*                                      UNSET RIGHT SUPPR TRIG           69520013
CONT15   IC    RB,RPALTP               GET REL POINTER TO ALTER CONST   69560013
         LA    RA,RPALTR               GET BASE OF CONST AREA           69600013
         AR    RB,RA                   ADD TO GET ACTUAL ADDR OF CONST  69640013
         SPACE                                                          69680013
         LR    RA,RC                   LOAD LENGTH OF ALTER CONST       69720013
         BCTR  RA,0                    SUBTR 1 TO GET AS MVC LNGTH CODE 69760013
         STC   RA,RPALTP               SAVE IN RPALTP SLOT              69800013
         SPACE                                                          69840013
         BAL   RG,STCNST               PUT RPALTR IN DIC                69880013
         SPACE                                                          69920013
         MVC   DRPALT(2),PAR1+2(13)    SAVE DIC REF OF RPALTR           69960013
         SPACE                                                          70000013
CONT34   ST    RD,CCOUNT           SAVE POINTERS TO TOP OF COND         70040013
         ST    RE,UCOUNT           AND UNCOND STACKS                    70080013
         L     14,LINK2                                                 70120013
         SPACE 4                                                        70160013
         BCR   15,14                   EXIT FROM SUBROUTINE             70200013
         SPACE 2                                                        70240013
NOCNST   MVI   RTSPRT,X'00'            CLEAR RTSUPPR TRIG IF NULL CONST 70280013
         BC    B,CONT34                BACK TO MAIN FLOW                70320013
         EJECT                                                          70360013
*              THIS SUBR PUTS A STRING CONSTANT INTO THE DIC.IT USES    70400013
*        CSKEL1 AS SKELETON FOR DATA DESCRIPTION.                       70440013
*              RB POINTS AT BYTE BEFORE CONST.                          70480013
*              RC HOLDS LENGTH OF CONST.                                70520013
*              THE DIC REF IS RETYRNED IN PAR1+2                        70560013
*              DICENT IS CALLED IN PHASE ON                             70600013
         SPACE 2                                                        70640013
STCNST   STH   RC,CSKEL1+6             STORE LENGTH OF STRING IN SKELTN 70680013
         STH   RC,CSKEL1+10                                             70720013
         SPACE                                                          70760013
         LR    RA,RB                                                    70800013
         SH    RA,K13                  POINT RA 14 BYTES IN FRONT CONST 70840013
         MVC   0(14,RA),CSKEL1         PUT FULL SKEL IN FRONT OF CONST  70880013
         SPACE                                                          70920013
         LR    RO,RB                   SAVE RB                          70960013
         LR    RF,RD                   SAVE RD                          71000013
        SPACE                                                           71040013
         BAL   RD,DICENT               MAKE DIC ENTRY                   71080013
         SPACE                                                          71120013
         LR    RB,RO                   RESTORE RB                       71160013
         LR    RD,RF                   RESTORE RD                       71200013
         SPACE                                                          71240013
         BCR   B,RG                    EXIT FROM SUBROUTINE             71280013
         SPACE                                                          71320013
         EJECT                                                          71360013
*              THIS SUBROUTINE LOOKS AT THE NEXT (BACKWARDS) CHAR INTHE 71400013
*        INPUT PICTURE STRING AND RETURNS CONTROL TO AN OFFSET DEFINED  71440013
*        BY THE LIST IMMEDIATELY FOLLOWING THE SUBROUTINE CALL.THE CHAR 71480013
*        IS COMPARED WITH FILLMK (THE DRIFTING CHAR)FIRST.THE STRING    71520013
*        POINTER IS UPDATED.RF AND RG ARE USED.                         71560013
         SPACE 4                                                        71600013
CHARSC   SH    RA,K1                   UPDATE PIC STRING POINTER        71640013
         LH    RG,LISTLN               LOAD RG WITH LIST LENGTH         71680013
         SPACE                                                          71720013
LOOP13   LA    RF,CHLIST(RG)           POINT RF AT END OF CHAR LIST     71760013
         CLC   1(1,RA),0(RF)           COMP PIC CHR WITH CHAR FROM LIST 71800013
         BC    BE,FOUND                BRANCH IF SAME                   71840013
         SH    RG,K1                   COUNT DOWN IN LIST POINTER       71880013
         BC    BNL,LOOP13              BACK IF LIST NOT EXHAUSTED       71920013
         BC    B,ERROR                 CHAR NOT FOUND                   71960013
FOUND    SR    RF,RF                                                    72000013
         IC    RF,0(RG,14)             GET BRANCH OFFSET IN RF          72040013
         BC    B,0(RF,14)              BRANCH TO OFFSET ADDRESS         72080013
         SPACE 4                                                        72120013
CHLIST   DC    X'39'                   Z                                72160013
         DC    X'79'                   *                                72200013
         DC    X'32'                   S                                72240013
         DC    X'75'                   +                                72280013
         DC    X'73'                   -                                72320013
         DC    X'30'                   $                                72360013
         DC    X'09'                   9                                72400013
         DC    X'35'                   V                                72440013
         DC    X'12'                   B                                72480013
         DC    X'41'                   ,                                72520013
         DC    X'77'                   /                                72560013
         DC    X'46'                   .                                72600013
FILLMK   DC    X'00'                   FILLMK (=DRIFTING CHAR)          72640013
         EJECT                                                          72680013
*              THIS SUBROUTINE INVESTIGATES THE STATUS OF EITHER SOURCE 72720013
*        OR TGT AND PUTS A 'LOAD ADDRESS' INSTR IN-LINE WHEN THIS IS    72760013
*        NECESSARY.IT THEN 'STANDARDISES' THE STATUS OF SCE OR TGT SO   72800013
*        THAT F5 CONTAINS EITHER                                        72840013
*              1)DIC REF OF SCE OR TGT                                  72880013
*              2)DIC REF OF WS                                          72920013
*              3)REG BY NAME IF EITHER 1)IT WAS REG BY NAME INITIALLY   72960013
*                                   OR 2)SCE OR TGT WAS INDEXED.        73000013
*              THE REG USED IN 'LOAD ADDRESS' IS ASSIGNED 14 OR 15,14   73040013
*        BEING SET INITIALLY AND THE SUBR ADDING 1 EVERY TIME A REG IS  73080013
*        USED.IN ADDITION F2 IS USED TO INDICATE WHETHER SUBSEQUENT     73120013
*        COMPILED INSTRUCTIONS SHOULD REGARD F5 AS 'REG BY NAME'.THE    73160013
*        CODE IS    SCE IS DIC REF      SF2 IS '00'                     73200013
*                   SCE IS R BY NAME    SF2 IS '20'                     73240013
*                   TGT IS DIC REF      TF2 IS '00'                     73280013
*                   TGT IS R BY NAME    TF2 IS '40'                     73320013
*              THIS ALLOWS SF2 OR TF2 TO BE 'ORED' WITH THE CODE BYTE   73360013
*        OF THE NEW INSTR.DIC REF INCLUDES WORK SPACE.REG BY VALUE HAS  73400013
*        NO MEANING                                                     73440013
*        ON EXIT F6 WILL NO LONGER CONTAIN ANYTHING USEFUL (THE INDEX   73480013
*        WILL HAVE BEEN INCORPORATED INTO F5).                          73520013
*        F7 WILL ALWAYS CONTAIN THE FULL OFFSET (INCLUDING ANY TEMP     73560013
*        OFFSET ON WORKSPACE).                                          73600013
*          NOTE THAT REG BY VALUE HAS NO SIGNIFICANCE FOR DEC OR PICS.  73640013
*                                                                       73680013
*          ON ENTRY RA POINTS TO SF1 OR TF1                             73720013
         SPACE 4                                                        73760013
LAINDX   TM    0(RA),X'C0'             IS FS TEMP OFFSET ON WK SP?      73800013
         BC    12,NOTWS                NO, THEN BRANCH                  73840013
         SPACE                                                          73880013
         LH    RC,4(RA)                LOAD TEMP OFFSET ON WS           73920013
         AH    RC,8(RA)                ADD ADDTNL OFFSET                73960013
         STH   RC,8(RA)                SAVE AS 'FULL' OFFSET.           74000013
         MVC   4(2,RA),WSDR            PUT DIC REF OF WK SP IN F5       74040013
         SPACE                                                          74080013
CONT24   MVI   1(RA),X'00'             CLEAR F2 TO SHOW NO REG IN F5    74120013
         BCR   B,14                    EXIT FROM LAINDX SUBR.           74160013
         SPACE 4                                                        74200013
*              DATA ITEM IS NOT IN WORK SPACE.                          74240013
         SPACE 2                                                        74280013
NOTWS    TM    0(RA),X'C0'             IS F5 REG BY NAME?               74320013
         BC    BNM,CONT43              NO,SO SKIP DRPL/USSL/SINL        74360013
         SPACE                                                          74400013
         TM    2(RA),X'01'             SHOULD REG BE DROPPED?           74440013
         BC    BZ,SINL1                NO,SO SKIP                       74480013
         SPACE                                                          74520013
         MVC   0(2,RE),4(RA)           PUT REG NAME IN DROP LIST        74560013
         LA    RE,2(RE)                UPDATE DROP LIST POINTER         74600013
         BC    B,USSL1                                                  74640013
         SPACE                                                          74680013
SINL1    MVC   0(2,RF),4(RA)           PUT REG IN SAVE IF NEC LIST      74720013
         LA    RF,2(RF)                UPDATE SINL POINTER              74760013
         SPACE                                                          74800013
USSL1    MVC   0(2,RD),4(RA)           PUT REG IN USE LIST              74840013
         LA    RD,2(RD)                UPDATE USSL POINTER              74880013
         SPACE                                                          74920013
CONT43   TM    0(RA),X'20'             DOES F6 HOLD INDEX REG?          74960013
         BC    BNZ,INDEXD              BRANCH IF SO                     75000013
         SPACE                                                          75040013
         TM    0(RA),X'C0'             IF NOT THEN IS F5 REG BY NAME?   75080013
         BC    BNM,CONT24              IF NOT,EXIT FROM SUBR CLEARINGF6 75120013
         SPACE                                                          75160013
         BCR   B,14                    IF SO EXIT WITH F2 FLAG SET      75200013
         SPACE                                                          75240013
INDEXD   MVC   LADATA(2),4(RA)         PUT IDENTIFIER IN F5 INTO LA     75280013
         MVC   4(2,RA),LAREG           REPLACE F5 BY LA REG (14 OR 15)  75320013
         MVC   INDEX(2),6(RA)          PUT INDEX REG VALUE IN OSM2      75360013
         MVC   0(8,RB),LA              PUT'LA 14,DATA  OSM2  INDEX'INTO 75400013
*                                    BUFFER                             75440013
         TM    0(RA),X'C0'             WAS F5 REG BY NAME?              75480013
         BC    BNM,CONT26              NO,SO SKIP INSTR                 75520013
         SPACE                                                          75560013
         MVI   1(RB),X'80'             YES,SET FLAG IN LA INSTR         75600013
CONT26   LA    RB,8(RB)                UPDATE BUFFER POINTER            75640013
         SPACE                                                          75680013
         TM    2(RA),X'01'             SHOULD INDEX REG BE DROPPED?     75720013
         BC    BZ,USSL2                NO,SO SKIP                       75760013
         SPACE                                                          75800013
         SPACE                                                          75840013
         MVI   0(RB),X'06'             DROP CODE                        75880013
         MVC   1(2,RB),6(RA)           PUT INDEX REG VALUE IN INSTR     75920013
         LA    RB,3(RB)                UPDATE BUFFER POINTER            75960013
         SPACE                                                          76000013
         BC    B,CONT30                                                 76040013
         SPACE                                                          76080013
USSL2    MVC   0(2,RD),6(RA)           PUT INDEX REG IN USSL            76120013
         LA    RD,2(RD)                UPDATE USSL POINTER              76160013
         SPACE                                                          76200013
         MVC   0(2,RF),6(RA)           PUT INDEX REG IN SINL            76240013
         LA    RF,2(RF)                UPDATE SINL POINTER              76280013
         SPACE                                                          76320013
CONT30   LH    RC,LAREG                ADD 1 TO ASSIGNED REG VALUE      76360013
         AH    RC,K1                   SINCE IT HAS BEEN USED.(ONLY 14  76400013
         STH   RC,LAREG                AND 15 GET USED IN PRACTICE)     76440013
         BCR   B,14                    EXIT FROM SUBR WITH F2 FLAG SET  76480013
         EJECT                                                          76520013
*              THIS SUBR INSERTS UNCDNL/CNDNL  'MOVE IMMEDIATE' INSTRS  76560013
*        INTO IN-LINE BUFFER.THESE MAY BE NECESSARY BECAUSE THE FILL    76600013
*        HAS OVERWRITTEN A PUNCTUATION SIGN,BECAUSE A BLANK APPEARS IN  76640013
*        THE MIDDLE OF A STRING OF *'S OR BECAUSE A CONDITIONAL MVI     76680013
*        FOLLOWS,OR BECAUSE S + OR - ARE USED                           76720013
*              RE POINTS AT THE END OF THE UNCCHR/CNCCHR STACK.POINTERS 76760013
*        IN THE PTR STACKS   POINT AT THE ADDRESS IN MAP WHERE THE CHAR 76800013
*        OCCURS.TO GET THE IN-LINE OFFSET'MAPEND-LT-1'MUST BE SUBTRACTD 76840013
*                ON ENTRY RC POINTS AT UNCCHR/CNDCHR,RG HOLDS EITHER    76880013
*        UNCPTR-UNCCHR OR CNDPTR-CNDCHR.                                76920013
         SPACE 4                                                        76960013
MVIS     CR    RC,RE                   IS STACK COUNT EQUAL TO HEAD?    77000013
         BCR   BE,14                   YES,THEN NO MORE CHARS.EXIT SUBR 77040013
         SPACE                                                          77080013
         SH    RE,K1                   COUNT BACK DOWN IN UNCDTNL COUNT 77120013
         MVI   0(RB),X'B1'             PUT 'MVI' CODE IN IN-LINE BUFFER 77160013
         MVC   3(2,RB),TF5             PUT DIC REF OF PIC IN MVI INSTR  77200013
         L     15,ZTRAN2(13)                                            77240013
         TR    0(1,RE),0(15)           TRANSLATE CHAR TO EXTERNAL CODE  77280013
         MVC   2(1,RB),0(RE)           PUT TRANSLATED CHAR INTO INSTR   77320013
         MVI   1(RB),X'00'             CLEAR UNUSED BYTE OF MVI INSTR   77360013
         SPACE                                                          77400013
         TM    TF2,X'40'               IS TF5 REG BY NAME?              77440013
         BC    BZ,CONT22               NO, THEN BRANCH                  77480013
         OI    1(RB),X'80'             YES, THEN SET FLAG IN MVI INSTR  77520013
*              NOW GENERATE 'OSM1' FOR OFFSET THROUGH PIC.              77560013
         SPACE                                                          77600013
CONT22   SR    RF,RF                                                    77640013
         IC    RF,0(RE,RG)             GET CHAR POINTER REL TO MAPSTT   77680013
         AH    RF,LT                                                    77720013
         SH    RF,PLNGTH               NOW REL TO TGT                   77760013
         SPACE                                                          77800013
         AH    RF,TF7                  ADD ANY OFFSET THAT MAY ALREADY  77840013
*                                    EXIST                              77880013
         STH   RF,OSM1OF               SET AS OFFSET IN OSM1            77920013
         MVC   5(3,RB),OSM1            MOVE OSM1 INSTR INTO BUFFER      77960013
         LA    RB,8(RB)                UPDATE BUFFER POINTER (FOR OSM1  78000013
*                                    AND ALSO FOR PRECEDING MVI)        78040013
         SPACE                                                          78080013
         BC    B,MVIS                                                   78120013
         EJECT                                                          78160013
*              THIS CODE COVERS A SPECIAL CASE,NAMELY WHEN SUPPRESSION  78200013
*        CHARACTERS EXIST TO THE RIGHT OF THE ACTIVE DIGIT POSITIONS.   78240013
*        E.G.CONVERT DEC(5,-2)TO PIC'ZZZZ9'.IN THIS CASE THE'RIGHT PAD' 78280013
*        COVERS 'Z9' AND IT IS NOT PREKNOWN WHAT THE 'Z' WILL APPEAR    78320013
*        AS.IF THE SOURCE IS NON-ZERO THEN THE Z BECOMES A '0'.IF THE   78360013
*        SOURCE IS ZERO THEN IT BECOMES 'FILL'.THE '9' WILL ALWAYS      78400013
*        BECOME A '0'.SIMILARLY , / OR . EMBEDDED IN SUCH SUPPRESSION   78440013
*        CHARS WILL BE COPIED OR REPLACED BY THE FILL.                  78480013
*              THE TECHNIQUE USED IS TO GENERATE THE MAP CONSTANT AS IF 78520013
*        THE SOURCE WERE NON-ZERO,I.E.Z IS MAPPED AS '0' AND , / . ARE  78560013
*        COPIED.IN ADDITION A FURTHER SUBSTRING CONSTANT 'RPALTR' IS    78600013
*        GENERATED,AS A COMPLETELY INDEPENDANT CONSTANT,WITH Z , / .    78640013
*        MAPPED AS FILL.IN LINE,AFTER THE NORMAL CODE,A BRANCH ON SCE   78680013
*        NOT ZERO JUMPS ROUND A MVC INSTR WHICH BRINGS DOWN RPALTR TO   78720013
*        OVERWRITE THE ORIGINAL RIGHT PAD.                              78760013
         SPACE 4                                                        78800013
RSCODE   BAL   14,SETCC      SET C.C. AND BUMP EQU #.             47647 78880056
         SPACE 4                                                        78960013
*              GENERATE   'BC    7,CL.N'                                79000013
         SPACE                                                          79040013
         MVC   EQUVL2(2),ZEQMAX(13) PUT EQU# INTO BC INSTRN.      47647 79140056
         MVC   0(5,RB),BC2             PUT BC2 IN BUFFER                79240013
         LA    RB,5(RB)                UPDATE BUFFER POINTER            79280013
         SPACE                                                          79320013
*              GENERATE   'MVC   TGT+LT-RPLNTH(RPALTP),RPALT'           79360013
         SPACE                                                          79400013
         MVI   MVCFLG,X'10'            SET DEFAULT FLAG                 79440013
         OC    MVCFLG(1),TF2           OR WITH TGT BASE REG FLAG        79480013
         MVI   MVCLTH,X'0A'            SFT LENGTH OF THIS INSTR         79520013
         MVC   MVCTLH(1),RPALTP        GET LENGTH CODE SAVED IN RPALTP  79560013
         MVC   DRTGT1(2),TF5           SET TGT DIC REF(OR REG BY NAME)  79600013
         SPACE                                                          79640013
         MVC   DRCNST(2),DRPALT        GET SPECIAL CONSTANT DIC REF     79680013
         LH    RA,LT                   GET TGT LENGTH IN BYTES          79720013
         SH    RA,RPLNTH               SUBTR LENGTH OF CONST            79760013
         AH    RA,TF7                  ADD IN OFFSET ,IF ANY            79800013
         STH   RA,TGTOF1               SET AS SOLE OFFSET TO THIS INSTR 79840013
         SPACE                                                          79880013
         MVC   0(10,RB),MVC            MOVE COMPLETE INSTR INTO BUFFER  79920013
         LA    RB,10(RB)               UPDATE BUFFER POINTER            79960013
         SPACE                                                          80000013
*              GENERATE   'CL.N  EQU  *'                                80040013
         SPACE                                                          80080013
         MVI   0(RB),X'07'             PUT EQU CODE IN BUFFER           80120013
         MVC   1(2,RB),EQUVL2          AND ITS CORRESP VALUE            80160013
         LA    RB,3(RB)                UPDATE BUFFER POINTER            80200013
         SPACE                                                          80240013
         BC    B,CONT27                NOW CONTINUE NORMAL COMPILING    80280013
         EJECT                                                          80320013
*              THIS SUBROUTINE GENERATES                                80360013
*                        BCTR   1,0                                     80400013
*                        MVI    0(1),UDRIFT                             80440013
*                        BC     10,CL.N                                 80480013
*                        MVI    0(1),CDRIFT                             80520013
*                  CL.N  EQU    *                                       80560013
*                                                                       80600013
*        IT IS ONLY USED BY EDMK. UDRIFT IS THE UNCOND VALUE OF THE     80640013
*        DRIFTING CHAR,AND CDRIFT IS THE CONDITIONAL VALUE.E.G.IF THE   80680013
*        DRIFTING CHAR IS 'S' THEN UDRIFT='+',CDRIFT='-'.FOR '$' ONLY   80720013
*        THE FIRST TWO INSTRS ARE GENERATED.                            80760013
         SPACE 4                                                        80800013
BCTRGN   L     RC,PICEND  GET LAST PIC CHAR                             80805001
         LTR   RC,RC                                                    80810001
         BC    BZ,CON21                                                 80815001
         XC    PICEND(4),PICEND                                         80820001
TESV     CLI   0(RC),X'35'   IS IT V                                    80825001
         BC    BE,BACKUP   GO IF SO                                     80830001
         CLI   0(RC),X'12'  IS IT A B                                   80835001
         BC    BNE,TESFIL    GO IF NOT                                  80840001
BACKUP   BCTR  RC,0  IGNORE THE B AT END                                80845001
         BC    B,TESV                                                   80850001
TESFIL   CLC   FILLMK(1),0(RC)   IS IT SAME AS DRIFTER                  80855001
         BC    BNE,CON21               GO IF NOT                        80860001
         L     RC,LASAV                                                 80865001
         MVC   1(7,RC),NINELA                                           80870001
CON21    CLI   FILLMK,X'32'                                             80875001
         BC    BE,DRSIGN                                                80880013
         SPACE                                                          80920013
         CLI   FILLMK,X'75'                                             80960013
         BC    BE,DRPLUS                                                81000013
         SPACE                                                          81040013
         CLI   FILLMK,X'73'                                             81080013
         BC    BE,DRMNUS                                                81120013
         SPACE                                                          81160013
         MVI   UDRIFT,X'30'                                             81200013
         SPACE                                                          81240013
CONT40   L     15,ZTRAN2(13)                                            81280013
         TR    UDRIFT(1),0(15)         TRANS UDRIFT TO EXT CODE         81320013
         TR    CDRIFT(1),0(15)         TRANS CDRIFT TO EXT CODE         81360013
         SPACE 2                                                        81400013
         CLI   FILLMK,X'30'            IS DRIFTING CHAR '$'?            81440013
         BC    BE,DOLLAR               YES,BRANCH                       81480013
         SPACE                                                          81520013
         SPACE                                                          81640013
         ST    14,LINK2                SAVE RETURN REG                  81680013
         BAL   14,SETCC      SET C.C. AND BUMP EQU #.             47647 81720056
         L     14,LINK2                RESET LINK REG                   81760013
         SPACE                                                          81800013
         MVC   EQUVL3(2),ZEQMAX(13)    PUT IN BRANCH INSTR.             81960013
         MVC   EQUVL4(2),ZEQMAX(13)    AND IN EQU *                     82000013
         SPACE                                                          82040013
         MVC   0(23,RB),BCTR           PUT BCTR ETC IN BUFFER     31177 82080020
         LA    RB,23(RB)                                          31177 82120020
         SPACE                                                          82160013
         BCR   B,14                    EXIT FROM SUBROUTINE             82200013
         SPACE 2                                                        82240013
DOLLAR   MVC   0(10,RB),BCTR           PUT BCTR  MVI IN BUFFER          82280013
         LA    RB,10(RB)                                          31177 82340020
         BCR   B,14                    EXIT FROM SUBR                   82400013
         SPACE 4                                                        82440013
DRSIGN   MVI   UDRIFT,X'75'            S GOES TO +/-                    82480013
         MVI   CDRIFT,X'73'                                             82520013
         BC    B,CONT40                                                 82560013
         SPACE                                                          82600013
DRPLUS   MVI   UDRIFT,X'75'            + GOES TO +/B                    82640013
         MVI   CDRIFT,X'40'                                             82680013
         BC    B,CONT40                                                 82720013
         SPACE                                                          82760013
DRMNUS   MVI   UDRIFT,X'40'            - GOES TO B/-                    82800013
         MVI   CDRIFT,X'73'                                             82840013
         BC    B,CONT40                                                 82880013
         EJECT                                                          82920013
*              CONSTANTS USED BY EDIT AND EDMK                          83000013
         SPACE 2                                                        83040013
         CNOP  0,4                     ALIGN MVC ON HALF WORD           83080013
         DS    C                                                        83120013
LA       DC    X'A0'                   CODE BYTE                        83160013
LAREG    DC    X'000E'               H ASSIGNED REG 14 OR 15            83200013
LADATA   DC    X'0000'                 DIC REF OR REG BY NAME           83240013
OSM2     DC    X'11'                   CODE BYTE                        83280013
INDEX    DC    X'0000'                 INDEX REG                        83320013
         SPACE                                                          83360013
         DS    C                                                        83400013
MVC      DC    X'C1'                   CODE BYTE                        83440013
MVCFLG   DC    X'00'                   FLAG                             83480013
MVCLTH   DC    X'00'                   LENGTH OF THIS INSTR             83520013
MVCTLH   DC    X'00'                   LENGTH OF TARGET FIELD (-1)      83560013
DRTGT1   DC    X'0000'                 DIC REF OF TGT                   83600013
DRCNST   DC    X'0000'                 DIC REF OF SCE                   83640013
TGTOF1   DC    X'0000'               H OFFSET ON TGT                    83680013
SCEOF1   DC    X'0000'               H OFFSET ON SCE                    83720013
         SPACE                                                          83760013
ED1      DC    X'CE'                   CODE BYTE                        83800013
EDFLAG   DC    X'00'                   FLAG                             83840013
         DC    X'0C'                   LENGTH OF THIS INSTR.            83880013
EDFLTH   DC    X'00'                   LENGTH OF TARGET FIELD (-1)      83920013
DRTGT2   DC    X'0000'                 DIC REF OF TGT                   83960013
DRSCE2   DC    X'0000'                 DIC REF OF SCE                   84000013
TGTOF2   DC    X'0000'               H OFFSET ON TGT                    84040013
SCEOF2   DC    X'0000'               H OFFSET ON SCE                    84080013
         SPACE                                                          84120013
         SPACE                                                          84360013
         DS    C                                                        84400013
BC2      DC    X'81'                   CODE BYTE                        84440013
         DC    X'40'                   FLAG SAYING 'EQU VALUE'          84480013
         DC    X'07'                   CONDITION CODE                   84520013
EQUVL2   DC    X'0000'               H EQU VALUE                        84560013
         SPACE                                                          84600013
CP       DC    X'C9'         CP OP-CODE                           47647 84650056
CPFLG    DC    X'00'            FLAG BYTE                         47647 84700056
         DC    X'0A'            PSEUDO-CODE LENGTH.               47647 84750056
OSM1     DC    X'10'                   CODE BYTE                        84800013
OSM1OF   DC    X'0000'               H OFFSET                           84840013
         SPACE 2                                                        84880013
*              THIS 'LOAD ADDRESS' AND OSM1 IS USED IN EDMK TO SET REG1 84920013
*        TO POINT AT THE SIGNIFICANCE START.ALIGN ON HALF WORD.         84960013
         SPACE 2                                                        85000013
LA2      DC    X'A0'                   CODE BYTE                        85040013
LAREG2   DC    X'0001'                 REG 1                            85080013
DRTGT3   DC    X'0000'                 DIC REF OF TFT(OR WS)            85120013
         SPACE                                                          85160013
SGOSM1   DC    X'10'                   CODE BYTE                        85200013
SIGPTR   DC    X'0000'               H OFFSET OF SIG START              85240013
         SPACE 2                                                        85280013
BCTR     DC    X'4400010000'           BCTR 1,0                         85320013
         SPACE                                                          85360013
         DC    X'B180'                 MVI CODE WITH FLAG               85400013
UDRIFT   DC    X'00'                   UNCOND DRIFTING CHAR             85440013
         DC    X'0001'                 REG1,FOR MVI 0(1),X'UDRIFT'      85480013
         SPACE                                                          85520013
BC       EQU   *                                                  47647 85540056
         DC    X'81400A'               BC  10,EQU                       85560013
EQUVL3   DC    X'0000'                 EQU VALUE                        85600013
EQUVAL   EQU   EQUVL3                                             47647 85620056
         SPACE                                                          85640013
         DC    X'B180'                 MVI CODE WITH FLAG               85680013
CDRIFT   DC    X'00'                   COND DRIFTING CHAR               85720013
         DC    X'0001'                 REG1,FOR MVI 0(1),X'CDRIFT'      85760013
         SPACE                                                          85800013
         DC    X'07'                   EQU CODE BYTE                    85840013
EQUVL4   DC    X'0000'                 EQU VALUE                        85880013
         SPACE                                                          85920013
DROP     DC    X'060001'               DROP REG 1                 31177 85940020
         SPACE 1                                                        85960020
USNG1    DC    X'360001'               USE REG 1                  31177 85980020
         SPACE 2                                                        86000013
*              SKELETONS FOR DROP LIST,USE LIST,SAVE LIST               86040013
         SPACE 2                                                        86080013
USSL     DC    X'D88000'               CODE,FLAG,LENGTH                 86120013
         DS    8C                      SPACE FOR 4 REGS                 86160013
         SPACE                                                          86200013
DRPL     DC    X'D98000'               CODE,FLAG,LENGTH                 86240013
         DS    8C                      SPACE FOR 4 REGS                 86280013
         SPACE                                                          86320013
SINL     DC    X'DB8000'               CODE,FLAG,LENGTH                 86360013
         DS    8C                      SPACE FOR 4 REGS                 86400013
         SPACE                                                          86440013
         CNOP  0,4                                                      86480013
CSKEL1   DC    X'88000000002C0000002C00000000' CONSTANT DIC REF SKELETN 86520013
*                                              FOR EDIT CHAR STRING     86560013
         SPACE                                                          86600013
DRPALT   DS    H                                                        86640013
LISTLN   DC    H'13'                   LENGTH OF LIST OF CHARS TESTED   86680013
K14      DC    H'14'                 FOR IN CHARSC                      86720013
K13      DC    H'13'                                                    86760013
UNPTCH   DC    AL2(UNCPTR-UNCCHR)                                       86800013
CNPTCH   DC    AL2(CNDPTR-CNDCHR)                                       86840013
LASAV    DS    F      ADDR OF LA                                        86850001
PICEND   DC    F'0'                                                     86860001
NINELA   DC    X'80010009100001'   SKELETON OF FALSE LA                 86870001
         SPACE 4                                                        86880013
ZCONCH   EQU   382                                                      86920013
ZDICRF   EQU   X'2C'                                                    86960013
ZTRAN2   EQU   72                                                       87000013
ZEQMAX   EQU   386                                                      87040013
         SPACE                                                          87080013
         ORG   IEMOM+X'FFF'                                             87090001
OMEND    DC    X'00'                                                    87100001
         END   IEMOM                                                    87120013
