PM       TITLE 'IEMPM, SYMBOL TABLES AND DEDS, STORAGE ALLOCN. PL/I F'  00070013
*              STATUS - CHANGE LEVEL 0                                  00140013
         SPACE 3                                                        00210013
*              FUNCTION - 1. ROUTINE 'SYMTAB' ALLOCATES STATIC STORAGE  00280013
*        FOR THE SYMBOL TABLE OF THE VARIABLE THAT IS PASSED TO IT FROM 00350013
*        ONE OF THE ROUTINES IN MODULE PL.                              00420013
         SPACE                                                          00490013
*                         2. ROUTINE 'DEDAL' ALLOCATES STATIC STORAGE   00560013
*        FOR THE DED OF THE VARIABLE THAT IS PASSED TO IT FROM ONE OF   00630013
*        THE ROUTINES IN MODULE PL.                                     00700013
         SPACE 3                                                        00770013
*              ENTRY POINTS - IN TRANSFER VECTOR AT HEAD OF THE MODULE, 00840013
*        'SYMTAB' AND 'DEDAL1'. THESE BRANCH STRAIGHT INTO EACH OF THE  00910013
*        ROUTINES DESCRIBED ABOVE. CONTROL ALWAYS ARRIVES FROM MODULE   00980013
*        PL.                                                            01050013
         SPACE 3                                                        01120013
*              INPUT - THE PARAMETER REGION, WHICH IS POINTED AT BY     01190013
*        REGISTER 'GPARAM', AND ALSO THE SLOT 'CURRDR' FROM WHICH       01260013
*        ROUTINE 'SYMTAB' PICKS UP THE DICT. REF. OF THE CURRENT        01330013
*        VARIABLE. ALSO THE DED SCRATCH AREA, PASSED FROM PHASE PD.     01400013
         SPACE 3                                                        01470013
*              OUTPUT - SYMBOL TABLE DICT. ENTRIES, MADE BY ROUTINE     01540013
*        'SYMTAB' AND DED DICTIONARY ENTRIES MADE BY ROUTINE 'DEDAL'.   01610013
*        DICTIONARY REFERENCES TO THE SYMBOL TABLE OR DED DICT. ENTRY   01680013
*        ARE PLACED IN THE 'SYMBOL SLOT' OF THE VARIABLE CONCERNED.     01750013
         SPACE 3                                                        01820013
*              EXTERNAL ROUTINES - CONTROL PHASE ROUTINES ONLY,         01890013
         SPACE                                                          01960013
*              ZDICRF - CONSTRUCTS DICTIONARY ENTRY RETURNING ITS       02030013
*                       REFERENCE.                                      02100013
         SPACE                                                          02170013
*              ZDRFAB - CONVERTS DICTIONARY REFERENCE TO ABSOLUTE       02240013
*                       ADDRESS.                                        02310013
         SPACE 3                                                        02380013
*              EXITS - NORMAL - TWO INSTRUCTIONS AFTER 'DEDRTA', RETURN 02450013
*        CONTROL TO MODULE PL.                                          02520013
         SPACE 3                                                        02590013
*              EXITS - ERROR - NONE.                                    02660013
         SPACE 3                                                        02730013
*              TABLES / WORK AREAS - THE 'STANDARD DED' TABLE, AND THE  02800013
*        PARAMETER REGION. (FOR DESCRIPTION, SEE COMMENTS AT START OF   02870013
*        MODULE PL).                                                    02940013
         SPACE 3                                                        03010013
*              ATTRIBUTES - RE-USABLE.                                  03080013
         SPACE 3                                                        03150013
*              NOTES - THE OPERATION OF THIS MODULE DEPENDS ON AN       03220013
*        INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS 03290013
*        EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING HAS    03360013
*        BEEN ARRANGED SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS,   03430013
*        BY RE-ASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW    03500013
*        DEFINITIONS.                                                   03570013
         EJECT                                                          03640013
IEMPM    START 0                                                        03710013
         USING *,PMBASE                                                 03780013
         DC    C'PM'                                                    03850013
         SPACE 4                                                        03920013
*              TRANSFER VECTOR FOR THIS MODULE.                         03990013
         SPACE                                                          04060013
         BC    B,DEDAL1                                                 04130013
         BC    B,DEDAL2                                                 04200013
         BC    B,SYMTAB                                                 04270013
SWADDR   DC    F'0'                    SWITCH TABLE ADDRESS.            04340013
DEDSCR   DC    F'0'                     START OF DED SCRATCH AREA.      04410013
ENDSCR   DC    F'0'                     END OF DED SCRATCH AREA.        04480013
CURRDR   DC    H'0'                    TWO BYTE SLOT WHICH IS UPDATED   04550013
*                                    TO CONTAIN DICT.REF.OF CURRENT     04620013
*                                    VARIABLE                           04690013
         EJECT                                                          04760013
*              'SYMTAB' ROUTINE.                                        04830013
         SPACE 2                                                        04900013
*              THIS ROUTINE IS CALLED BY ANY OF THE ROUTINES WHICH SCAN 04970013
*        THE DICTIONARY CHAINS, ETC. THE ROUTINE ALLOCATES STORAGE IN   05040013
*        THE STATIC CONTROL SECTION FOR THE SYMBOL TABLE OF THE         05110013
*        VARIABLE WHICH IS PASSED TO IT.                                05180013
         SPACE                                                          05250013
*              THIS ROUTINE PICKS UP FROM CURRDR THE DICT. REF. OF THE  05320013
*        VARIABLE IN QUESTION.                                          05390013
         SPACE                                                          05460013
*              FOR DATA ITEMS, WE MUST ALLOCATE A DED AS WELL AS A      05530013
*        SYMBOL TABLE, SO WE CALL THE ROUTINE DEDAL2, WHICH ALLOCATES   05600013
*        STORAGE FOR THE DED, AND THEN RETURNS TO THE LINK ADDRESS SET  05670013
*        FOR THE 'SYMTAB' ROUTINE.                                      05740013
         SPACE                                                          05810013
*              FOR LABEL VARIABLES, NO DED IS REQUIRED, AND WE GO       05880013
*        STRAIGHT BACK TO THE LINK ADDRESS.                             05950013
         SPACE 4                                                        06020013
SYMTAB   STM   GRBASE,GPARAM,REGSTO    SAVE REGISTERS                   06090013
         SPACE                                                          06160013
         MVC   PAR1+2(2,GRDCPT),CURRDR POINT GRDCNT AT CURRENT          06230013
         BAL   GRR,STEVE             VARIABLE'S DICT. ENTRY.            06300013
         L     GRDCNT,PAR1(0,GRDCPT)                                    06370013
         SPACE 3                                                        06440013
*              FIRST WE WANT TO KNOW IF THIS THE FIRST 'SYMBOL'         06510013
*        VARIABLE IN THIS BLOCK. SO WE CONSULT THE SWITCH TABLE.        06580013
         SPACE 2                                                        06650013
*              BUT FIRST WE MUST OBTAIN THE CURRENT BLOCK NUMBER FROM   06720013
*        THE VARIABLE'S DICT ENTRY                                      06790013
         SPACE                                                          06860013
         XR    GR1,GR1                 SET UP IN GR1 THE OFFSET OF THE  06930013
         IC    GR1,LENGTH+1(GRDCNT)  BCD LENGTH BYTE                    07000013
         SPACE                                                          07070013
         LA    GR1,0(GR1,GRDCNT)       GR1 NOW CONTAINS OFFSET OF       07140013
         S     GR1,NO2               'BLOCK LEVEL' BYTE.                07210013
         SPACE                                                          07280013
*              WE NOW MAKE A SPECIAL CASE OF FORMAL PARAMETERS.         07350013
         TM    OTHER2(GRDCNT),FMPRAM   FOR FORMAL PARAMETERS WE PICK    07420013
         BC    BZ,Z3A                UP THE BLOCK COUNT FROM THE FP1    07490013
         MVC   PAR1+2(2,GRDCPT),0(GR1) ENTRY.                           07560013
         BAL   GRR,STEVE                                                07630013
         L     GR1,PAR1(0,GRDCPT)                                       07700013
         SR    GR2,GR2                                                  07770013
         IC    GR2,FP1LC+1(0,GR1)                                       07840013
         BC    B,Z3B                                                    07910013
         SPACE                                                          07980013
*              HERE IT IS NOT A FORMAL PARAMETER.                       08050013
Z3A      SR    GR2,GR2                                                  08120013
         IC    GR2,1(0,GR1)            SET UP BLOCK COUNT IN GR2.       08190013
         SPACE                                                          08260013
Z3B      STC   GR2,COUNT                                                08330013
         LA    GR2,0(GR2,GR2)          DOUBLE IT                        08400013
         SPACE 2                                                        08470013
*              NOW WE TEST THE TWO BYTE SLOT AT AN OFFSET OF 2N FROM    08540013
*        THE START OF THE SWITCH TABLE, (WHERE N IS THE BLOCK COUNT).   08610013
         SPACE                                                          08680013
         SR    GR0,GR0                 IS IT ZERO                       08750013
         L     GR1,SWADDR                                               08820013
         CH    GR0,0(GR2,GR1)                                           08890013
         BC    BNE,Z1                                                   08960013
         SPACE 3                                                        09030013
*              HERE THE SWITCH IN THE SWITCH TABLE IS ZERO, I.E. THIS   09100013
*        IS THE FIRST 'SYMBOL' VARIABLE IN THE (N-1)TH. BLOCK.          09170013
         SPACE 2                                                        09240013
*              WE NOW SCAN THE CHAIN OF ENTRY TYPE 1'S FOR THE ONE      09310013
*        CORRESPONDING TO THIS BLOCK                                    09380013
         SPACE                                                          09450013
         MVC   PAR1+2(2,GRDCPT),ZPROC1+2(GRDCPT) PICK UP HEAD OF ENTRY  09520013
*                                    TYPE 1 CHAIN AND SET IT UP IN PAR1 09590013
Z3       L     GRL,ZDRFAB(0,GRCP)      BRANCH AND LINK TO CONTROL PHASE 09660013
         BALR  GRR,GRL               ROUTINE ZDRFAB, TO PICK UP ABS.    09730013
*                                    ADDRESS OF ENTRY TYPE 1.           09800013
         SPACE 2                                                        09870013
         L     GR1,PAR1(0,GRDCPT)      POINT GR1 AT THE ENTRY TYPE 1.   09940013
         SPACE 2                                                        10010013
         CLC   COUNT(1),E1CNT(GR1)     COMPARE BLOCK COUNTS             10080013
         BC    BE,Z2                                                    10150013
         SPACE 2                                                        10220013
*              HERE WE HAVE NOT FOUND THE CORRECT ENTRY TYPE 1, SO PICK 10290013
*        UP THE NEXT ONE IN THE CHAIN                                   10360013
         SPACE                                                          10430013
         MVC   PAR1+2(2,GRDCPT),E1E1(GR1) SET UP DICT.REF. TO NEXT      10500013
*                                    ENTRY TYPE 1 IN PAR1               10570013
         CLC   PAR1+2(2,GRDCPT),NO0    IS THIS THE END OF THE CHAIN     10640013
         BC    BNE,Z3                                                   10710013
         SPACE 2                                                        10780013
*              HERE WE HAVE COME TO THE END OF THE ENTRY TYPE 1 CHAIN   10850013
*        WITHOUT FINDING THE ONE FOR THE CURRENT BLOCK, SO THIS IS A    10920013
*        COMPILER ERROR, AND WE DUMP                                    10990013
         SPACE                                                          11060013
         DC    X'0000'                 INTERRUPT                        11130013
         SPACE 4                                                        11200013
*              HERE WE HAVE FOUND THE ENTRY TYPE 1 FOR THE CURRENT      11270013
*        BLOCK, AND WE STORE THE DICT.REF. TO THE CURRENT VARIABLE INIT 11340013
         SPACE 2                                                        11410013
Z2       MVC   E1SYMT(2,GR1),CURRDR                                     11480013
         SPACE                                                          11550013
*              NOW WE ARE READY TO SET UP THE 'SYMBOL TABLE' DICT.ENTRY 11620013
*        SO WE GO TO CONSTRUCT IT                                       11690013
         SPACE                                                          11760013
         BC    B,Z4                                                     11830013
         SPACE 4                                                        11900013
*              HERE WE HAVE FOUND THE SWITCH TABLE CONTAINS A NON-ZERO  11970013
*        SLOT CORRESPONDING TO THIS BLOCK. I.E. THE CURRENT BLOCK HAS   12040013
*        ALREADY BEEN GIVEN AT LEAST ONE SYMBOL VARIABLE, AND THE DICT. 12110013
*        REF.TO THE MOST RECENT ONE IS STORED IN THE TWO-BYTE SWITCH.   12180013
         SPACE                                                          12250013
*              WE NOW PICK UP THE DICT ENTRY TO THIS MOST RECENT SYMBOL 12320013
*        VARIABLE.                                                      12390013
         SPACE                                                          12460013
Z1       L     GR1,SWADDR              POINT GR1 AT THE SWITCH.         12530013
         LA    GR1,0(GR2,GR1)                                           12600013
         MVC   PAR1+2(2,GRDCPT),0(GR1)  SET UP THE DICT.REF. IN PAR1.   12670013
         SPACE                                                          12740013
         L     GRL,ZDRFAB(0,GRCP)       CALL ZDRFAB ROUTINE TO CONVERT  12810013
         BALR  GRR,GRL                DICT.REF. TO ABSOLUTE ADDRESS.    12880013
         SPACE                                                          12950013
         L     GR1,PAR1(0,GRDCPT)      POINT GR1 AT DICT ENTRY FOR      13020013
*                                    THE VARIABLE                       13090013
         SPACE 2                                                        13160013
*              NOW WE WANT TO PICK UP THE SYMBOL TABLE DICT.ENTRY FOR   13230013
*        THIS PREVIOUS VARIABLE                                         13300013
         SPACE                                                          13370013
         MVC   PAR1+2(2,GRDCPT),SYMSLT(GR1) SET UP ITS DICT.REF.IN PAR1 13440013
         SPACE 2                                                        13510013
         L     GRL,ZDRFAB(0,GRCP)      BRANCH TO ZDRFAB ROUTINE TO      13580013
         BALR  GRR,GRL               CONVERT TO ABS. ADDRESS            13650013
         SPACE 2                                                        13720013
         L     GR1,PAR1(0,GRDCPT)      POINT GR1 AT THE SYMBOL TABLE    13790013
*                                    DICT.ENTRY.                        13860013
         SPACE 2                                                        13930013
*              NOW WE SET UP THE DICT.REF. OF THE CURRENT SYMBOL        14000013
*        VARIABLE IN THIS SYMBOL TABLE ENTRY FOR THE PREVIOUS VARIABLE. 14070013
         SPACE                                                          14140013
         MVC   STNEXT(2,GR1),CURRDR                                     14210013
         SPACE 6                                                        14280013
*              HERE WE SET UP THE BUILD AREA FOR THE SYMBOL TABLE DICT. 14350013
*        ENTRY FOR THE CURRENT VARIABLE. (A NOMINAL DICT. ENTRY MAY     14420013
*        HAVE BEEN MADE ALREADY, BUT IF IT HAS, WE SIMPLY COPY THE      14490013
*        BUILD AREA INTO THE READY MADE DICT. ENTRY)                    14560013
         SPACE 2                                                        14630013
Z4       LA    GRBILD,BLDARA           POINT GRBILD AT THE BUILD AREA   14700013
         SPACE                                                          14770013
         MVI   0(GRBILD),X'00'         CLEAR FIRST TWENTY BYTES OF      14840013
         MVC   1(20,GRBILD),0(GRBILD) BUILD AREA                        14910013
         SPACE 2                                                        14980013
*              NOW WE SET UP THE VARIOUS CONSTITUENTS OF THE SYMBOL     15050013
*        TABLE DICT. ENTRY                                              15120013
         SPACE 2                                                        15190013
*              MOVE IN INITIAL CODE BYTE                                15260013
         SPACE                                                          15330013
         MVI   STCDBT(GRBILD),X'C7'                                     15400013
         SPACE 2                                                        15470013
*              MOVE IN LENGTH (18)                                      15540013
         SPACE                                                          15610013
         MVI   STLGTH(GRBILD),X'00'                                     15680013
         MVI   STLGTH+1(GRBILD),X'12'                                   15750013
         SPACE 2                                                        15820013
*              SET UP STATIC OFFSET OF THE SYMBOL TABLE                 15890013
         SPACE                                                          15960013
*              FIRST WE MUST 4-BYTE ALIGN THE STATIC STORAGE LOCATION   16030013
*        COUNTER                                                        16100013
         SPACE                                                          16170013
         L     GR1,NO3                                                  16240013
         AR    GRLC,GR1                ADD THREE                        16310013
         SPACE                                                          16380013
         L     GR1,ALIGN4                                               16450013
         NR    GRLC,GR1                AND OUT THE LOW ORDER TWO BITS   16520013
         SPACE                                                          16590013
         ST    GRLC,TMFWST               STORE THE LOCATION COUNTER IN  16660013
         MVC   STATST(3,GRBILD),TMFWST+1 THE 'SYMBOL TABLE OFFSET' SLOT 16730013
         SPACE                                                          16800013
*              NOW WE HAVE FINISHED SETTING UP THE BUILD AREA           16870013
         SPACE 3                                                        16940013
*              WE NOW FIND OUT WHETHER A SYMBOL TABLE DICT. ENTRY HAS   17010013
*        ALREADY BEEN MADE BY AN EARLIER PHASE.                         17080013
*              WE TEST THE SLOT IN THE VARIABLE'S DICT. ENTRY WHICH     17150013
*        POINTS TO ITS SYMBOL TABLE ENTRY                               17220013
         SPACE                                                          17290013
         MVC   PAR1+2(2,GRDCPT),CURRDR POINT GRDCNT AT CURRENT          17360013
         BAL   GRR,STEVE             VARIABLE'S DICT. ENTRY.            17430013
         L     GRDCNT,PAR1(0,GRDCPT)                                    17500013
         SPACE                                                          17570013
         CLC   SYMSLT(2,GRDCNT),NO0    IS THE DICT. REF. ZERO           17640013
         BC    BE,Z5A                                                   17710013
         SPACE                                                          17780013
*              HERE THE 'SYMBOL SLOT' IS NON-ZERO.                      17850013
         SPACE                                                          17920013
         MVC   PAR1+2(2,GRDCPT),SYMSLT(GRDCNT) WE FOLLOW UP THE DICT.   17990013
*                                    REF. TO SEE IF IT POINTS AT A      18060013
         L     GRL,ZDRFAB(0,GRCP)    SYMBOL TABLE DICT. ENTRY           18130013
         BALR  GRR,GRL                                                  18200013
         SPACE                                                          18270013
         L     GR2,PAR1(0,GRDCPT)                                       18340013
         CLI   0(GR2),X'C7'                                             18410013
         BC    BE,Z5                                                    18480013
         SPACE 2                                                        18550013
*              HERE WE HAVE FOUND THAT THE VARIABLE DOES NOT YET HAVE   18620013
*        A SYMBOL TABLE DICT. ENTRY.                                    18690013
         SPACE                                                          18760013
Z5A      ST    GRBILD,PAR1(0,GRDCPT)   POINT PAR1 AT BUILD AREA         18830013
         SPACE                                                          18900013
         MVC   STVAR(2,GRBILD),CURRDR  SET UP DICT REF OF CURRENT       18970013
*                                    VARIABLE IN SYMTAB ENTRY.          19040013
         SPACE                                                          19110013
         MVC   PAR2(4,GRDCPT),NO18     SET UP LENGTH OF ENTRY IN PAR2   19180013
         SPACE 2                                                        19250013
         L     GRL,ZDICRF(0,GRCP)      BRANCH TO ZDICRF ROUTINE TO MAKE 19320013
         BALR  GRR,GRL               THE DICT. ENTRY                    19390013
         SPACE 2                                                        19460013
*              THE ENTRY IS IN THE DICTIONARY, AND NOW WE PUT ITS DICT. 19530013
*        REF. INTO THE 'SYMBOL' SLOT IN THE CURRENT VARIABLE'S ENTRY    19600013
         SPACE                                                          19670013
         MVC   DRDED(2),PAR1+2(GRDCPT)                                  19740013
          TM   DATABT(GRDCNT),NOPICT                                    19810013
          BC   BZ,Z5B                                                   19880013
          MVC  SYMSLT(2,GRDCNT),DRDED                                   19950013
         SPACE                                                          20020013
*              WE NOW JOIN THE NEW ENTRY ONTO THE STATIC CHAIN.         20090013
Z5B       MVC  PAR1+2(2,GRDCPT),ZEOSC(GRDCPT)                           20160013
         BAL   GRR,STEVE                                                20230013
         L     GR1,PAR1(0,GRDCPT)                                       20300013
         MVC   CHAIN(2,GR1),DRDED                                       20370013
         MVC   ZEOSC(2,GRDCPT),DRDED                                    20440013
         SPACE 2                                                        20510013
*              NOW WE GO TO CALCULATE THE SIZE OF THE SYMBOL TABLE      20580013
         SPACE                                                          20650013
         BC    B,Z6                                                     20720013
         SPACE 3                                                        20790013
*              HERE WE HAVE FOUND THAT THE CURRENT VARIABLE ALREADY HAS 20860013
*        A SYMBOL TABLE DICT. ENTRY. SO WE FIND OUT ITS ADDRESS.        20930013
         SPACE                                                          21000013
Z5       OI    FLAG,FLAG1              SET ON FLAG TO SAY THAT NO       21070013
*                                    CHAINING REQUIRED AT END OF DEDAL  21140013
*                                    ROUTINE.                           21210013
         MVC   PAR1+2(2,GRDCPT),CURRDR POINT GRDCNT AT CURRENT          21280013
         BAL   GRR,STEVE             VARIABLE'S DICT. ENTRY.            21350013
         L     GRDCNT,PAR1(0,GRDCPT)                                    21420013
         SPACE                                                          21490013
         MVC   DRDED(2),SYMSLT(GRDCNT)                                  21560013
         SPACE                                                          21630013
         MVC   PAR1+2(2,GRDCPT),SYMSLT(GRDCNT) SET UP ITS DICT.REF. IN  21700013
*                                    PAR1.                              21770013
         SPACE 2                                                        21840013
         L     GRL,ZDRFAB(0,GRCP)      BRANCH TO ZDRFAB ROUTINE TO      21910013
         BALR  GRR,GRL               CONVERT REF. TO ABS. ADDRESS       21980013
         SPACE 2                                                        22050013
         L     GR1,PAR1(0,GRDCPT)      POINT GR1 AT THE DICT.ENTRY      22120013
         SPACE                                                          22190013
         MVC   STATST(3,GR1),STATST(GRBILD) MOVE THE OFFSET IN STATIC   22260013
*                                    OF THE SYMBOL TABLE INTO THE DICT. 22330013
*                                    ENTRY, PICKING IT UP FROM THE      22400013
*                                    BUILD AREA.                        22470013
         SPACE 4                                                        22540013
         SPACE                                                          22610013
         MVC   PAR1+2(2,GRDCPT),CURRDR SET GRDCNT TO POINT AT DICT.     22680013
         BAL   GRR,STEVE             ENTRY FOR CURRENT VARIABLE. (SINCE 22750013
         L     GRDCNT,PAR1(0,GRDCPT) THE BLOCK COULD HAVE BEEN MOVED    22820013
*                                    DUE TO SPILLING).                  22890013
         SPACE 3                                                        22960013
*              HERE WE CALCULATE THE LENGTH OF THE SYMBOL TABLE.        23030013
         SPACE                                                          23100013
*              FIRST WE NEED THE BCD LENGTH.                            23170013
         SPACE                                                          23240013
Z6       SR    GR3,GR3                                                  23310013
         TM    OTHER2(GRDCNT),FMPRAM   IF THIS IS A FORMAL PARAM, WE    23380013
         BC    BZ,Z6H                GO TO THE FP1 TO PICK UP THE BCD.  23450013
         IC    GR3,LENGTH+1(0,GRDCNT)                                   23520013
         LA    GR3,0(GR3,GRDCNT)                                        23590013
         S     GR3,NO2                                                  23660013
         MVC   PAR1+2(2,GRDCPT),0(GR3)                                  23730013
         BAL   GRR,STEVE                                                23800013
         L     GRDCNT,PAR1(0,GRDCPT)                                    23870013
         SR    GR3,GR3                                                  23940013
Z6H      IC    GR3,LENGTH+1(0,GRDCNT)                                   24010013
         LA    GR3,0(GR3,GRDCNT)                                        24080013
         SR    GR2,GR2                                                  24150013
         IC    GR2,0(0,GR3)                                             24220013
         LA    GR2,2(0,GR2)            SET UP BCD LENGTH+2 IN GR2.      24290013
         MVC   PAR1+2(2,GRDCPT),CURRDR                                  24360013
         BAL   GRR,STEVE                                                24430013
         L     GRDCNT,PAR1(0,GRDCPT)   RESTORE GRDCNT                   24500013
         SPACE 2                                                        24570013
*              IF THE VARIABLE IS A STRUCTURE MEMBER, WE MUST ADD IN    24640013
*        THE BCD LENGTHS OF ITS CONTAINING STRUCTURES.                  24710013
Z6J      TM    0(GRDCNT),X'20'                                          24780013
         BC    BZ,Z6A                                                   24850013
         SPACE                                                          24920013
*              WE NOW PICK UP THE DICT REF OF THE CONTAINING STRUCTURE  24990013
Z6G      TM    0(GRDCNT),X'0F'                                          25060013
         BC    BNO,Z6B                                                  25130013
         LA    GR3,VARINF(0,GRDCNT)    POINT GR3 AT VAR. INFO. (IN DATA 25200013
         BC    B,Z6C                 ITEM).                             25270013
Z6B      LA    GR3,STRVNF(0,GRDCNT)    AND HERE FOR STRUCTURES OR LABEL 25340013
*                                    VARIABLES.                         25410013
Z6C      TM    VARBLE(GRDCNT),X'80'                                     25480013
         BC    BZ,Z6D                                                   25550013
         LA    GR3,VINF1(0,GR3)                                         25620013
Z6D      TM    VARBLE(GRDCNT),X'40'                                     25690013
         BC    BZ,Z6E                                                   25760013
         LA    GR3,VINF2(0,GR3)                                         25830013
*              NOW GR3 POINTS AT THE STRUCTURE INFORMATION.             25900013
         SPACE                                                          25970013
Z6E      MVC   CNTREF(2),2(GR3)                                         26040013
         MVC   PAR1+2(2,GRDCPT),CNTREF NOW PICK UP THE CONTAINING       26110013
         BAL   GRR,STEVE             STRUCTURE.                         26180013
         L     GRDCNT,PAR1(0,GRDCPT)                                    26250013
         TM    OTHER2(GRDCNT),FMPRAM                                    26320013
         BC    BZ,Z6F                                                   26390013
         TM    OTHER4(GRDCNT),MAJSTR                                    26460013
         BC    BZ,Z6F                                                   26530013
         MVC   PAR1+2(2,GRDCPT),CHAIN(GRDCNT)                           26600013
         BAL   GRR,STEVE                                                26670013
         L     GRDCNT,PAR1(0,GRDCPT)                                    26740013
Z6F      SR    GR1,GR1                 SET UP BCD LENGTH-1 IN GR1.      26810013
         IC    GR1,LENGTH+1(0,GRDCNT)                                   26880013
         IC    GR1,0(GR1,GRDCNT)                                        26950013
         MVC   PAR1+2(2,GRDCPT),CNTREF RESTORE GRDCNT.                  27020013
         BAL   GRR,STEVE                                                27090013
         L     GRDCNT,PAR1(0,GRDCPT)                                    27160013
         LA    GR2,2(GR1,GR2)          BUMP GR2 BY BCD LENGTH + 1.      27230013
         TM    OTHER4(GRDCNT),MAJSTR   IS THIS THE MAJOR STRUCTURE.     27300013
         BC    BZ,Z6G                                                   27370013
         SPACE 3                                                        27440013
Z6K      MVC   PAR1+2(2,GRDCPT),CURRDR RESTORE GRDCNT.                  27510013
         BAL   GRR,STEVE                                                27580013
         L     GRDCNT,PAR1(0,GRDCPT)                                    27650013
         SPACE 2                                                        27720013
*              NOW THE TOTAL LENGTH OF THE BCD (INCLUDING               27790013
*        QUALIFICATION). IS IN GR2                                      27860013
         SPACE                                                          27930013
Z6A      LA    GR2,3(0,GR2)            BUMP UP TO NEXT FACTOR OF 4.     28000013
         L     GR1,ALIGN4                                               28070013
         NR    GR2,GR1                                                  28140013
         SPACE                                                          28210013
         LA    GR2,16(0,GR2)           BUMP BY 16                       28280013
         SPACE 2                                                        28350013
*              NOW WE HAVE FOUND THE LENGTH OF THE SYMBOL TABLE, SO WE  28420013
*        BUMP THE LOCATION COUNTER BY THIS LENGTH.                      28490013
         SPACE                                                          28560013
         LA    GRLC,0(GR2,GRLC)                                         28630013
         SPACE 4                                                        28700013
*              NOW WE PICK THE SWITCH TABLE ENTRY FOR THE CURRENT BLOCK 28770013
*        AND STORE IN IT THE DICT.REF. TO THE VARIABLE WE HAVE JUST     28840013
*        PROCESSED                                                      28910013
         SPACE                                                          28980013
         XR    GR2,GR2                 PICK UP BLOCK COUNT FROM 'COUNT' 29050013
         IC    GR2,COUNT             SLOT                               29120013
         SPACE                                                          29190013
         LA    GR2,0(GR2,GR2)          DOUBLE IT TO OBTAIN OFFSET DOWN  29260013
*                                    SWITCH TABLE                       29330013
         SPACE                                                          29400013
         L     GR1,SWADDR              POINT GR1 AT THE CORRECT SWITCH  29470013
         LA    GR1,0(GR2,GR1)                                           29540013
         SPACE                                                          29610013
         MVC   0(2,GR1),CURRDR         MOVE IN THE DICT.REF.            29680013
         SPACE                                                          29750013
*              NOW THE SWITCH TABLE HAS BEEN SET UP.                    29820013
         SPACE 3                                                        29890013
*              WE NOW DECIDE WHETHER THIS VARIABLE NEEDS A DED AS WELL  29960013
*        AS A SYMBOL TABLE.                                             30030013
         SPACE 2                                                        30100013
         TM    0(GRDCNT),X'0F'         IS IT A DATA ITEM                30170013
         BC    BO,Z8                                                    30240013
         SPACE                                                          30310013
         TM    0(GRDCNT),X'07'         IS IT A LABEL VARIABLE           30380013
         BC    BO,Z7                                                    30450013
         SPACE                                                          30520013
         TM    0(GRDCNT),X'0E'       IS IT A STRUCTURE                  30530015
         BC    BO,CRUNCH             WELL, IT SHOULDN'T BE.             30540015
         SPACE                                                          30550015
         TM    0(GRDCNT),X'0C'       IS IT A TASK OR EVENT VARIABLE     30560015
         BC    BO,Z7                 IF SO, TREAT AS LABEL.             30570015
         SPACE                                                          30580015
CRUNCH   DC    H'0'                  IF NOT DATA, LABEL, TASK OR EVENT  30590015
*                                     VARIABLE, COMPILER ERROR. DUMP.   30600015
         SPACE 2                                                        30660013
*              HERE IT IS A LABEL VARIABLE, SO NO DED IS REQUIRED.      30730013
         SPACE                                                          30800013
Z7       LM    GRBASE,GPARAM,REGSTO    RESTORE REGISTERS                30870013
         BCR   BR,GRR                                                   30940013
         SPACE 2                                                        31010013
*              HERE IT IS A DATA ITEM, SO A DED IS REQUIRED.            31080013
         SPACE                                                          31150013
Z8       SR    GR1,GR1                 SET UP PARAMETER REGION FOR      31220013
         LH    GR1,CURRDR            DEDAL ROUTINE                      31290013
         STH   GR1,PARAM5(0,GPARAM)                                     31360013
         LA    GR2,SYMSLT(0,0)                                          31430013
         STH   GR2,PARAM1(0,GPARAM)                                     31500013
         LA    GR2,DATABT(0,0)                                          31570013
         STH   GR2,PARAM2(0,GPARAM)                                     31640013
         TM    DATABT(GRDCNT),NOPICT                                    31710013
         BC    BZ,Z8A                                                   31780013
         XC    PARAM3(2,GPARAM),PARAM3(GPARAM)                          31850013
         BC    B,Z8B                                                    31920013
Z8A      MVC   TMFWST(2),SYMSLT(GRDCNT)                                 31990013
         TM    FLAG,FLAG1              IF WE CONSTRUCTED THIS SYMTAB,   32060013
         BC    BO,Z8C                MOVE PICTURE REF INTO IT.          32130013
         MVC   PAR1+2(2,GRDCPT),DRDED                                   32200013
         BAL   GRR,STEVE                                                32270013
         L     GR3,PAR1(0,GRDCPT)                                       32340013
         MVC   STDED+1(2,GR3),TMFWST                                    32410013
Z8C      MVC   PAR1+2(2,GRDCPT),DRDED   POINT GR2 AT THE DICT. ENTRY    32480013
         BAL   GRR,STEVE                 FOR THE DED.                   32550013
         L     GR2,PAR1(0,GRDCPT)                                       32620013
         LA    GR2,STDED+1(0,GR2)       POINT GR2 AT THE PICTURE DICT.  32690013
         MVC   PAR1+2(2,GRDCPT),DRDED    REF. IN THE DED'S DICT. ENTRY, 32760013
         ST    GR2,PAR2(0,GRDCPT)        AND PUT THE DICT. REF. OF THAT 32830013
         L     GRL,ZDABRF(0,GRCP)        SLOT INTO PARAM3.              32900013
         BALR  GRR,GRL                                                  32970013
         MVC   PARAM3(2,GPARAM),PAR1+2(GRDCPT)                          33040013
         MVI   PARAM4(GPARAM),X'FF'     PUT FLAG IN PARAM4 TO INDICATE  33110013
*                                        THAT PARAM3 CONTAINS A DICT.   33180013
*                                        REF.                           33250013
         SPACE                                                          33320013
         OI    FLAG,NEWSYM             SET 'NEW SYMTAB' FLAG.           33390013
         SPACE                                                          33460013
Z8B      LM    GRBASE,GPARAM,REGSTO     RESTORE REGISTERS               33530013
         SPACE 2                                                        33600013
         BC    B,DEDAL2                BRANCH TO DEDAL2 ROUTINE         33670013
         EJECT                                                          33740013
*              DATA AREA FOR SYMTAB ROUTINE                             33810013
         SPACE 4                                                        33880013
REGSTO   DC    16F'0'                  SAVE AREA FOR REGISTERS          33950013
COUNT    DC    X'00'                   CURRENT BLOCK COUNT              34020013
NO1      DC    F'1'                    INTEGERS                         34090013
NO2      DC    F'2'                                                     34160013
NO3      DC    F'3'                                                     34230013
NO4      DC    F'4'                                                     34300013
NO5      DC    F'5'                                                     34370013
NO6      DC    F'6'                                                     34440013
NO7      DC    F'7'                                                     34510013
NO8      DC    F'8'                                                     34580013
NO9      DC    F'9'                                                     34650013
NO0      DC    F'0'                                                     34720013
TMFWST   DC    F'0'                    TEMPORARY FULL WORD STORAGE      34790013
ALIGN4   DC    X'FFFFFFFC'             MASK FOR 4-BYTE ALIGNING         34860013
BLDARA   DC    5F'0'                   BUILD AREA FOR DICTIONARY ENTRY  34930013
NO18     DC    F'18'                                                    35000013
FLAG     DC    X'00'                                                    35070013
FLAG1    EQU   X'80'                   ' THE CURRENT VARIABLE HAS BEEN  35140013
*                                    GIVEN A SYMBOL TABLE. '            35210013
OLDPIC   EQU   X'40'                   PICTURE FLAG.                    35280013
NEWSYM   EQU   X'20'                   NEW SYMTAB FLAG.                 35350013
CNTREF   DC    H'0'                    DICT REF OF CONTAINING STRUCTURE 35420013
         EJECT                                                          35490013
*              DEDAL ROUTINE                                            35560013
         SPACE 4                                                        35630013
*              THIS ROUTINE IS CALLED TO ALLOCATE STORAGE FOR THE DED   35700013
*        OF A PARTICULAR VARIABLE, AND SET UP A 'DED' DICT. ENTRY       35770013
*                   DEDAL1   THE ROUTINE IS ENTERED HERE IF THE         35840013
         SPACE 2                                                        35910013
         SPACE                                                          35980013
*                             VARIABLE NEEDS SIMPLY A DED AND HENCE AN  36050013
*                             ORDINARY 'DED' DICT. ENTRY IS REQUIRED    36120013
         SPACE                                                          36190013
*                   DEDAL2   THE ROUTINE IS ENTERED HERE IF THE         36260013
*                             VARIABLE HAS ALREADY BEEN ALLOCATED A     36330013
*                             SYMBOL TABLE. THUS A 'SYMBOL TABLE' DICT. 36400013
*                             ENTRY HAS ALREADY BEEN MADE. THE 'DED'    36470013
*                             INFORMATION IS SET UP IN THE 'SYMBOL      36540013
*                             TABLE' DICT, ENTRY, AND NO 'DED' DICT.    36610013
*                             ENTRY IS MADE.                            36680013
         SPACE 2                                                        36750013
*              SINCE THIS ROUTINE ALLOCATES DEDS FOR DIFFERENT TYPES    36820013
*        OF VARIABLE, THE DED INFORMATION IS NOT AVAILABLE AT STANDARD  36890013
*        PLACES IN THE VARIABLE'S DICT, ENTRY. FOR THIS REASON, THE     36960013
*        DEDAL ROUTINE EXPECTS TO FIND THE 5 PARAMETERS IN THE          37030013
*        PARAMETER REGION CONTAINING INFORMATION TO ENABLE THE VARIOUS  37100013
*        SLOTS IN THE VARIABLE'S DICT. ENTRY TO BE FOUND (SEE THE       37170013
*        PARAMETER REGION).                                             37240013
         SPACE 2                                                        37310013
*              COMMON STORAGE AND DICT. ENTRIES ARE ALLOCATED TO        37380013
*        VARIABLES WITH IDENTICAL DEDS (SEE 'FORMAT OF DED ENTRIES IN   37450013
*        SCRATCH STORAGE').                                             37520013
         SPACE 6                                                        37590013
*              DEDAL1 ENTRY POINT.                                      37660013
         SPACE 2                                                        37730013
*              THE VARIABLE IN QUESTION NEEDS A DED BUT NO SYMBOL TABLE 37800013
         SPACE 4                                                        37870013
*              FIRST WE INITIALIZE THE RETURN SLOTS RETRN1, RETRN2.     37940013
*        THESE WILL CONTAIN EXIT ADDRESSES FROM THE 'DEDAL' ROUTINE.    38010013
         SPACE 2                                                        38080013
DEDAL1   STM   GRBASE,GPARAM,REGST1     SAVE REGISTERS.                 38150013
         SPACE 2                                                        38220013
         LA    GRR,X1                                                   38290013
         ST    GRR,RETRN1                                               38360013
         SPACE                                                          38430013
         LA    GRR,DED150                                               38500013
         ST    GRR,RETRN2                                               38570013
               SPACE                                                    38640013
         MVI   VARISW,X'FF'            SET VARISW TO SHOW VARIABLE HAS  38710013
*              A DED, BUT NO SYMBOL-TABLE.                              38780013
         SPACE 2                                                        38850013
*              NOW WE POINT GR1 AT THE VARIABLE'S DATA BYTE.            38920013
         SPACE                                                          38990013
DED100   MVC   PAR1+2(2,GRDCPT),PARAM5(GPARAM)  PICK UP THE VARIABLE'S  39060013
         BAL   GRR,STEVE             DICT. REF. AND CONVERT TO          39130013
         L     GR1,PAR1(0,GRDCPT)    ABSOLUTE.                          39200013
         ST    GR1,ABS               STORE ADDRESS IN 'ABS'.            39270013
         CLI   0(GR1),X'88'            CONSTANT ?                       39271001
         BC    BNE,DED105              NO                               39272001
         AH    GR1,PARAM2(0,GPARAM)    POINT AT DATA BYTE               39273001
         TM    0(GR1),X'8C'            FIXED BIN ?                      39273301
         BC    BNO,MOVEDB              NO                               39273601
         TM    0(GR1),X'62'            MAKE SURE                        39273901
         BC    BNE,MOVEDB              NO                               39274201
         BC    B,NOTBIN                FIXED BIN CONSTS ARE FULLWORD    39274501
*                                                                       39275001
*   TEST FOR DO LOOP TEMP                                               39280001
DED105   TM    0(GR1),X'80'            TEMP OR PARAMETER ?              39290001
         BC    BZ,NOTEMP    GO IF NOT                                   39300001
         TM    12(GR1),X'08'    IS IT PARAM                             39310001
         BC    BO,NOTEMP    GO IF SO                                    39320001
*  IT IS A DO LOOP TEMP SO SET LONG BIT OFF IF BINARY FIXED             39330001
         TM    15(GR1),X'8C'    FIXBIN                                  39340001
         BC    BNO,NOTEMP       GO IF NOT                               39350001
         TM    15(GR1),X'62'    ARE WE SURE                             39360001
         BC    BNE,NOTEMP    GO IF NOT                                  39370001
         TM    18(GR1),X'80'           ARG BIT SET ?                    39372001
         BC    BO,NOTEMP               YES, SO TREAT AS VARIABLE        39374001
         TM    OTHER3(GR1),X'20'       NEEDS NO STORAGE ?               39376001
         BC    BO,NOTEMP               NO                               39378001
         AH    GR1,PARAM2(0,GPARAM)    POINT AT DATABYTE                39380001
         BC    B,NOTBIN                                                 39390001
NOTEMP   AH    GR1,PARAM2(0,GPARAM)    POINT AT DATABYTE                39400001
         SPACE 2                                                        39410013
*              NOW WE SET UP THE FIRST THREE BYTES OF AN 8-BYTE BUILD   41370013
*        AREA CALLED DEDINF. THESE THREE BYTES WILL HAVE THE SAME       41440013
*        FORMAT AS THE FIRST THREE BYTES OF A DED SCRATCH ENTRY (Q.V.), 41510013
*        AND WILL BE USED AS A COMPARISON WHEN SCANNING THE DED SCRATCH 41580013
*        ENTRIES.                                                       41650013
*              FIRST WE DETERMINE THE THE TYPE OF DED.                  41680015
         SPACE                                                          41710015
*     IF THE DR IS FIXBIN THEN THE LONG/SHORT BIT IS FLIPPED            41714001
*           1  =  HWB                                                   41718001
*    2  =  FULLWORD                                                     41722001
         SPACE                                                          41726001
         TM    0(GR1),X'88'    IS IT FIXED                              41730001
         BC    BNO,MOVEDB       GO IF NOT                               41734001
         TM    0(GR1),X'62'      ARE WE SURE                            41738001
         BC    BNE,MOVEDB     GO IF UNSURE                              41740001
         TM    0(GR1),X'04'    IS IT BIN                                41742001
         BC    BZ,NOTBIN    GO IF NOT                                   41744001
         TM    1(GR1),X'F0'       IS IT P>15                            41746001
         BC    BNE,NOTBIN          GO IF SO                             41750001
         OI    0(GR1),X'10'        SET LONG BIT ON FOR HWB              41754001
         BC    B,MOVEDB                                                 41758001
NOTBIN   NI    0(GR1),X'EF'   SET LONG BIT OFF FOR FULLWORD             41762001
MOVEDB   MVC   DEDINF(1),0(GR1)   MOVE IN DATA BYTE                     41766001
         SPACE                                                          41770015
         MVI   DEDTYP,X'01'                                             41800015
         TM    0(GR1),CADNUM                                            41830015
         BC    BZ,DED115               VARIABLE IS A STRING.            41860015
         SPACE                                                          41890015
*        IT IS ARITHMETIC, POINTER, OR OFFSET. TEST FOR NUMERIC FIELD.  41920015
         SPACE                                                          41950015
         TM    0(GR1),CAD                                               41980015
         BC    BZ,DED130               NUMERIC FIELD.                   42010015
         TM    0(GR1),OFFPNT           TEST FOR OFFSET OR POINTER.      42040015
         BC    BO,DED115                                                42070015
         MVC   DEDINF+1(2),1(GR1)      NO. VARIABLE IS CAD. MOVE IN     42100015
         BC    B,SCRSCN                 PRECISION BYTES AND GO TO SCAN  42130015
*                                       SCRATCH.                        42160015
         SPACE                                                          42190015
*              VARIABLE IS STRING, POINTER OR OFFSET.                   42220015
         SPACE                                                          42250015
DED115   TM    0(GR1),PICT             IS IT A PICTURED STRING          42280015
         BC    BZ,DED130               YES.                             42310015
         MVI   DEDINF+1,X'00'          NO.. SET THE REMAINING TWO       42340015
         MVI   DEDINF+2,X'00'                BYTES TO ZERO.             42420013
         BC    B,SCRSCN                 GO TO SCAN SCRATCH.             42490013
         SPACE                                                          42560013
*              HERE THE VARIABLE HAS A PICTURE. INSERT THE DICT. REF.   42630013
*        OF THE PICTURE INTO THE REMAINING TWO BYTES.                   42700013
*        FIRST TEST WHETHER PARAM3 CONTAINS A DICT. REF. OR AN OFFSET.  42770013
         SPACE                                                          42840013
DED130   MVI   DEDTYP,X'00'                                             42880015
         CLI   PARAM4(GPARAM),X'FF'                                     42920015
         BC    BNE,DED133            OFFSET.                            42980013
         MVC   DEDINF+1(2),PARAM3(GPARAM)        DICT. REF.             43050013
         BC    B,SCRSCN                                                 43120013
         SPACE                                                          43190013
DED133   L     GR2,ABS               HERE PARAM3 CONTAINS AN OFFSET.    43260013
         AH    GR2,PARAM3(0,GPARAM)    POINT GR2 AT THE SLOT CONTAINING 43330013
*                                         THE DICT. REF.OF THE PICTURE. 43400013
         MVC   DEDINF+1(2),0(GR2)                                       43470013
         SPACE                                                          43540013
*              WE CAN NOW SCAN THE DED ENTRIES IN SCRATCH STORAGE TO    43610013
*        TEST FOR A PREVIOUS OCCURRENCE OF AN IDENTICAL DED.            43680013
         SPACE                                                          43750013
SCRSCN   L     GR3,DEDSCR               POINT GR3 AT THE START OF THE   43820013
*                                            DED ENTRIES.               43890013
DED135   CLC   STATOF(3,GR3),LSTENT     HAVE WE REACHED THE END OF THE  43960013
         BC    BNE,DED140                    DED ENTRIES                44030013
         SPACE                                                          44100013
*              WE HAVE REACHED THE END OF THE DED ENTRIES WITHOUT       44170013
*        FINDING AN IDENTICAL DED. GO TO MAKE NEW DED DICT. ENTRY       44240013
*        AND/OR ALLOCATE STATIC STORAGE.                                44310013
         SPACE                                                          44380013
         L     GRR,RETRN1                                               44450013
         BCR   B,GRR                                                    44520013
         SPACE                                                          44590013
*              THERE ARE STILL SOME ENTRIES LEFT... CARRY ON SCANNING.  44660013
         SPACE                                                          44730013
DED140   CLC   0(3,GR3),DEDINF          ARE THESE DEDS IDENTICAL        44800013
         BC    BNE,DED145                                               44870013
         SPACE                                                          44940013
*              THE SEARCH WAS SUCCESSFUL. GO TO USE OLD ENTRY.          45010013
         SPACE                                                          45080013
DED142   L     GRR,RETRN2                                               45150013
         BCR   B,GRR                                                    45220013
         SPACE                                                          45290013
DED145   LA    GR3,8(0,GR3)             CARRY ON SEARCHING.             45360013
         BC    B,DED135                                                 45430013
         SPACE 3                                                        45500013
*              HERE WE HAVE FOUND AN IDENTICAL DED. WE PUT THE OLD DEDS 45570013
*        DICT. REF. INTO A SLOT IN THE VARIABLE'S DICT. ENTRY.          45640013
         SPACE                                                          45710013
DED150   OI    FLAG,FLAG1                                               45780013
         L     GR2,ABS                 POINT GR2 AT THE SLOT IN THE     45850013
         AH    GR2,PARAM1(0,GPARAM)    VARIABLES DICT.REF.              45920013
         MVC   0(2,GR2),SCRREF(GR3)     MOVE THE DICT. REF. OF THE DED  45990013
*                        ENTRY INTO THE VARIABLE'S DICT. ENTRY.         46060013
         BC    B,DEDRTN                                                 46130013
         SPACE 4                                                        46200013
*              AT THIS POINT IN THE ROUTINE WE ARE ABOUT TO ALLOCATE    46270013
*        STORAGE FOR A DED WHICH IS NOT IDENTICAL TO ANY PREVIOUS DED.  46340013
*        THE DED/SYMBOL DICT. ENTRY IS POINTED AT BY GR2. WE WILL ALSO  46410013
*        PUT THE BIT PATTERN OF THE DED INTO ITS DICT.ENTRY.            46480013
         SPACE 2                                                        46550013
*              FIRST WE STORE THE LOCATION COUNTER IN THE DED/SYMBOL    46620013
*        DICT. ENTRY AS THE OFFSET OF THE DED                           46690013
         SPACE                                                          46760013
X7       TM    FLAG,OLDPIC             IS THIS THE CASE OF A COMMONED   46830013
         BC    BO,X7A                PICTURE.                           46900013
         ST    GRLC,TMFWST                                              46970013
         MVC   DDSTOF(3,GR2),TMFWST+1                                   47040013
         SPACE 2                                                        47110013
*              WE NOW CHECK WHETHER THERE IS ROOM IN SCRATCH STORAGE    47180013
*        FOR ANOTHER DED ENTRY. IF THERE IS, WE COMPLETE THE SKELETON   47250013
*        AND MOVE IT INTO SCRATCH. THE NEXT AVAILABLE SLOT (IF ANY) IS  47320013
*        POINTED AT BY GR3.                                             47390013
*              WE DO NOT MAKE A SCRATCH ENTRY IF THE CURRENT VARIABLE   47460013
*        HAS A SYMBOL TABLE.                                            47530013
         SPACE 2                                                        47600013
X7A      CLI   VARISW,X'00'            NO SCRATCH ENTRY IF VARIABLE     47670013
         BC    BE,DED155                 HAS A SYMBOL TABLE.            47740013
         C     GR3,ENDSCR              IS THERE ROOM FOR ANOTHER        47810013
*                                            DED SCRATCH ENTRY          47880013
         BC    BH,DED155                NO... SO CANNOT MAKE AN ENTRY.  47950013
         MVC   DEDINF+STATOF(3),DDSTOF(GR2)  THERE IS ROOM. MOVE STATIC 48020013
*                   OFFSET OF DED INTO THE SKELETON.                    48090013
         MVC   0(8,GR3),DEDINF          MOVE SKELETON INTO SCRATCH.     48160013
         MVC   STATOF+8(3,GR3),LSTENT   SET END-OF-ENTRIES MARKER.      48230013
         SPACE 2                                                        48300013
*              NOW WE CALCULATE THE LENGTH OF THE DED.                  48370013
         SPACE 2                                                        48440013
DED155   MVC   PAR1+2(2,GRDCPT),PARAM5(GPARAM)     PICK UP VARIABLE'S   48510013
         BAL   GRR,STEVE               DICT. REF. AND CONVERT TO        48580013
         L     GR1,PAR1(0,GRDCPT)      ABSOLUTE (DICT. BLOCKS MAY HAVE  48650013
         ST    GR1,ABS                 BEEN SPILLED).                   48720013
         AH    GR1,PARAM2(0,GPARAM)    POINT GR1 AT THE VARIABLES DATA  48790013
*                                        BYTE.                          48860013
         SPACE                                                          48930013
         TM    FLAG,OLDPIC                                              49000013
         BC    BO,X10                                                   49070013
         SPACE                                                          49140013
         TM    0(GR1),CADNUM           IS IT CAD/NUM. FIELD             49210013
         BC    BZ,X8                                                    49280013
         SPACE 2                                                        49350013
*              IT IS CAD/NUM. FIELD, POINTER OR OFFSET.                 49380015
         SPACE                                                          49410015
         TM    0(GR1),CAD              IS IT NUM. FIELD                 49440015
         BC    BZ,X9                   YES.                             49470015
         SPACE                                                          49500015
         TM    0(GR1),OFFPNT           IS IT POINTER OR OFFSET          49530015
         BC    BO,X11                  YES.                             49560015
         SPACE                                                          49590015
         SPACE 2                                                        49700013
*              HERE IT IS CAD, SO THE DED IS 3 BYTES LONG.              49770013
         SPACE                                                          49840013
         LA    GRLC,3(GRLC)            BUMP LOCATION COUNTER BY THREE   49910013
         BC    B,X10                                                    49980013
         SPACE 2                                                        50050013
*              HERE IT IS NUMERIC FIELD, SO THE DED LENGTH IS 5 PLUS    50120013
*        THE LENGTH OF THE PICTURE.                                     50190013
         SPACE                                                          50260013
X9       LA    GRLC,5(GRLC)            BUMP LOCATION COUNTER BY FIVE    50330013
         SPACE 2                                                        50400013
*              NOW WE PICK UP THE DICT.ENTRY FOR THE PICTURE            50470013
         SPACE                                                          50540013
*              FIRST TEST WHETHER PARAM3 CONTAINS A DICT. REF. OR AN    50610013
*        OFFSET.                                                        50680013
         SPACE                                                          50750013
X12      CLI   PARAM4(GPARAM),X'FF'                                     50820013
         BC    BNE,X14                  OFFSET.                         50890013
         MVC   PAR1+2(2,GRDCPT),PARAM3(GPARAM)    DICT. REF.            50960013
         BAL   GRR,STEVE                POINT GR3 AT DICT. ENTRY FOR    51030013
         L     GR3,PAR1(0,GRDCPT)        THE PICTURE.                   51100013
         BC    B,X16                                                    51170013
         SPACE                                                          51240013
X14      L     GR3,ABS                  HERE PARAM3 CONTAINS AN OFFSET. 51310013
         AH    GR3,PARAM3(0,GPARAM)     POINT GR3 AT PICTURE DICT.      51380013
*                                       ENTRY.                          51450013
         SPACE                                                          51520013
X16      MVC   PAR1+2(2,GRDCPT),0(GR3)  SET UP THE DICT. REF. IN PAR1   51590013
         MVC   PICREF(2),0(GR3)      AND INTO 'PICREF' SLOT             51660013
         SPACE 2                                                        51730013
         L     GRL,ZDRFAB(0,GRCP)      BRANCH TO ZDRFAB ROUTINE TO PICK 51800013
         BALR  GRR,GRL               UP ADDRESS OF PICTURE DICT.ENTRY   51870013
         SPACE 2                                                        51940013
         L     GR3,PAR1(0,GRDCPT)      POINT GR3 AT PICTURE DICT. ENTRY 52010013
         SPACE                                                          52080013
         MVC   PAR1+2(2,GRDCPT),DRDED  RESTORE GR2.                     52150013
         BAL   GRR,STEVE                                                52220013
         L     GR2,PAR1(0,GRDCPT)                                       52290013
         MVC   PAR1+2(2,GRDCPT),PARAM5(GPARAM)   RESTORE GR1 (DICT.     52360013
         BAL   GRR,STEVE               BLOCKS MAY HAVE BEEN SPILLED).   52430013
         L     GR1,PAR1(0,GRDCPT)                                       52500013
         ST    GR1,ABS                                                  52570013
         AH    GR1,PARAM2(0,GPARAM)                                     52640013
         SPACE                                                          52710013
         MVC   PICOFF(3,GR3),DDSTOF(GR2) MOVE STATIC OFFSET OF DED INTO 52780013
*                                    PICTURE DICT ENTRY.                52850013
         SPACE                                                          52920013
         XR    GR4,GR4                                                  52990013
         IC    GR4,PICLTH(GR3)         SET UP PICTURE LENGTH BYTE IN    53060013
*                                    GR4                                53130013
         SPACE 2                                                        53200013
         LA    GRLC,0(GR4,GRLC)        BUMP LOCATION COUNTER BY PICTURE 53270013
         BC    B,X10                 LENGTH.                            53340013
         SPACE 2                                                        53410013
*              HERE WE HAVE FOUND FROM THE DATA BYTE THAT THE DED       53480013
*        DESCRIBES A STRING                                             53550013
         SPACE                                                          53620013
X8       TM    0(GR1),NOPICT           IS IT A PICTURE                  53690013
         BC    BO,X11                                                   53760013
         SPACE 2                                                        53830013
*              HERE IT IS A STRING AND IT IS A PICTURE, SO THE DED      53900013
*        LENGTH IS 3 PLUS LENGTH OF THE PICTURE                         53970013
         SPACE                                                          54040013
         LA    GRLC,3(GRLC)                                             54110013
         SPACE                                                          54180013
         BC    B,X12                   FROM HERE, THE PROCESSING OF     54250013
*                                    THE  'STRING, PICTURE' CASE IS THE 54320013
*                                    SAME AS THE 'NUMERIC FIELD' CASE.  54390013
         SPACE 2                                                        54460013
*              HERE IT IS AN UNPICTURED STRING, POINTER OR OFFSET. DED  54530015
*        IS ONE BYTE LONG.                                              54600013
         SPACE                                                          54670013
X11      LA    GRLC,1(GRLC)            BUMP LOCATION COUNTER BY ONE.    54740013
         SPACE 4                                                        54810013
*              HERE WE HAVE BUMPED THE LOCATION COUNTER BY THE CORRECT  54880013
*        AMOUNT FOR EACH OF THE POSSIBLE LENGTHS OF THE DED.            54950013
         SPACE                                                          55020013
*              WE NOW SET UP THE BIT PATTERN OF THE DED (EXCLUDING ANY  55090013
*        PICTURE SPECIFICATION) IN THE DED/SYMBOL DICT.ENTRY.           55160013
*              THE DED/SYMBOL DICT. ENTRY IS POINTED AT BY GR2, AND THE 55230013
*        DATA BYTE IN THE VARIABLE'S DICT.ENTRY IS POINTED AT BY GR1.   55300013
         SPACE                                                          55370013
X10      MVC   DDDED(1,GR2),0(GR1)     MOVE IN THE DATA BYTE            55440013
         SPACE                                                          55510013
         TM    0(GR1),NOPICT           IS THERE A PICTURE DICT.REF.     55580013
         BC    BO,X13                                                   55650013
         SPACE                                                          55720013
         TM    FLAG,OLDPIC                                              55790013
         BC    BO,DEDRTN                                                55860013
         SPACE                                                          55930013
         TM    FLAG,NEWSYM                                              56000013
         BC    BO,DEDRTN                                                56070013
         SPACE                                                          56140013
*              HERE THERE IS A PICTURE DICT.REF.TO MOVE IN. IT IS IN    56210013
*        THE 'PICREF' SLOT.                                             56280013
         SPACE                                                          56350013
         MVC   DDDED+1(2,GR2),PICREF                                    56420013
         BC    B,DEDRTN                BRANCH TO RETURN POINT           56490013
         SPACE 2                                                        56560013
*              HERE THERE IS NO PICTURE (OR NUMERIC FIELD).             56630013
         SPACE                                                          56700013
X13      TM    0(GR1),CADNUM           IS IT A STRING                   56770013
         BC    BZ,DEDRTN                                                56840013
         SPACE                                                          56850015
         TM    0(GR1),OFFPNT           IS IT POINTER OR OFFSET          56860015
         BC    BO,DEDRTN               YES.                             56870015
         SPACE 2                                                        56910013
*              HERE IT IS CAD. WE MUST MOVE IN THE PRECISION AND        56980013
*        SCALE FACTOR. THESE ARE THE TWO BYTES IMMEDIATELY FOLLOWING    57050013
*        THE DATA BYTE.                                                 57120013
         SPACE                                                          57190013
         MVC   DDDED+1(2,GR2),1(GR1)                                    57260013
         SPACE 4                                                        57330013
*              HERE WE HAVE ALLOCATED STORAGE FOR THE DED AND UP ITS    57400013
*        BIT PATTERN.                                                   57470013
         SPACE 2                                                        57540013
         BC    B,DEDRTN                BRANCH TO RETURN POINT           57610013
         SPACE 4                                                        57680013
*              HERE WE HAVE COME FROM THE DEDAL1 ENTRY POINT, AND NO    57750013
*        PREVIOUS DED HAS BEEN IDENTICAL WITH THE CURRENT ONE.          57820013
         SPACE 2                                                        57890013
*              WE NOW MAKE A DICT. ENTRY FOR THE DED.                   57960013
         SPACE                                                          58030013
X1       LA    GRBILD,BLDARA           POINT GRBILD AT THE BUILD AREA   58100013
         SPACE                                                          58170013
         MVI   0(GRBILD),X'00'         CLEAR THE FIRST TWENTY BYTES OF  58240013
         MVC   1(20,GRBILD),0(GRBILD) THE BUILD AREA.                   58310013
         SPACE 2                                                        58380013
         MVI   DDCODE(GRBILD),DDCDBT   MOVE IN INITIAL CODE BYTE        58450013
         SPACE                                                          58520013
         MVI   DDLGTH(GRBILD),X'00'    SET UP THE LENGTH OF THE ENTRY   58590013
         MVI   DDLGTH+1(GRBILD),DDLENG                                  58660013
         SPACE 2                                                        58730013
*              WE NOW WANT TO KNOW WHETHER A PICTURE IS ASSOCIATED WITH 58800013
*        THIS VARIABLE                                                  58870013
         SPACE                                                          58940013
         L     GR1,ABS                  POINT GR1 AT THE DATA BYTE      59010013
         AH    GR1,PARAM2(0,GPARAM)                                     59080013
         SPACE                                                          59150013
         TM    0(GR1),NOPICT           TEST THE 'PICTURE' BIT           59220013
         BC    BO,X15                                                   59290013
         SPACE 2                                                        59360013
*              HERE THERE IS A PICTURE                                  59430013
         SPACE                                                          59500013
         L     GR2,ABS                  POINT GR2 AT THE SLOT           59570013
         AH    GR2,PARAM3(0,GPARAM)     CONTAINING THE PICTURE DICT REF 59640013
         SPACE                                                          59710013
         MVC   DDPCRF(2,GRBILD),0(GR2) MOVE ITS DICT.REF. INTO THE      59780013
*                                    BUILD AREA.                        59850013
         SPACE 2                                                        59920013
         MVC   PAR1+2(2,GRDCPT),0(GR2)                                  59990013
         BAL   GRR,STEVE               PICK UP 'PICTURE' DICT ENTRY     60060013
         L     GR2,PAR1(0,GRDCPT)      COMPARE THE OFFSET SLOT WITH 3.  60130013
         CLC   PICOFF(3,GR2),NO3+1   IF NOT GREATER, THE PICTURE HAS    60200013
         BC    BNH,X15               NOT BEEN ALLOCATED BEFORE.         60270013
         SPACE                                                          60340013
         MVC   DDSTOF(3,GRBILD),PICOFF(GR2) MOVE STATIC OFFSET FROM THE 60410013
*                                    PICTURE DICT ENTRY INTO THE DED.   60480013
*                                    ENTRY.                             60550013
         OI    FLAG,OLDPIC             SET 'OLD PICTURE' FLAG           60620013
         SPACE 4                                                        60690013
*              WE NOW PUT THE NEW DICT ENTRY INTO THE DICTIONARY.       60760013
         SPACE 2                                                        60830013
X15      ST    GRBILD,PAR1(0,GRDCPT)   POINT PAR1 AT THE BUILD AREA     60900013
         SPACE                                                          60970013
         MVC   PAR2(4,GRDCPT),NO11     SET UP LENGTH OF ENTRY IN PAR2   61040013
         SPACE 2                                                        61110013
         L     GRL,ZDICRF(0,GRCP)      BRANCH TO ZDICRF ROUTINE TO MAKE 61180013
         BALR  GRR,GRL               THE DICT. ENTRY.                   61250013
         SPACE 2                                                        61320013
         LA    GR1,DRDED               POINT GR1 AT SLOT WHICH IS TO    61390013
*                                    TAKE DED'S DICT REF.               61460013
         SPACE                                                          61530013
         MVC   0(2,GR1),PAR1+2(GRDCPT) SET UP DICT REF OF DED.          61600013
*                                    DICT.REF.                          61670013
         SPACE                                                          61740013
*              WE PUT THE DED DICT. REF. INTO THE SKELETON OF A NEW     61810013
*        SCRATCH ENTRY.                                                 61880013
         SPACE                                                          61950013
         MVC   DEDINF+SCRREF(2),0(GR1)                                  62020013
         SPACE 4                                                        62090013
*              WE NOW JOIN THE NEW DICT. ENTRY ONTO THE END OF THE      62160013
*        STATIC CHAIN                                                   62230013
         SPACE 2                                                        62300013
         MVC   PAR1+2(2,GRDCPT),ZEOSC(GRDCPT) SET UP DICT.REF. OF LAST  62370013
*                                    MEMBER OF STATIC CHAIN INTO PAR1.  62440013
         SPACE 2                                                        62510013
         L     GRL,ZDRFAB(0,GRCP)      BRANCH TO ZDRFAB ROUTINE TO PICK 62580013
         BALR  GRR,GRL               UP ADDRESS OF DICT.ENTRY.          62650013
         SPACE 2                                                        62720013
         L     GR2,PAR1(0,GRDCPT)      POINT GR2 AT THE DICT.ENTRY      62790013
         SPACE                                                          62860013
         MVC   CHAIN(2,GR2),0(GR1)     CHAIN NEW DED ENTRY ONTO CURRENT 62930013
*                                    LAST MEMBER OF STATIC CHAIN.       63000013
         SPACE                                                          63070013
         MVC   ZEOSC(2,GRDCPT),0(GR1)  UPDATE COMM REGION SLOT WITH     63140013
*                                    DICT.REF. TO NEW LAST MEMBER OF    63210013
*                                    STATIC CHAIN.                      63280013
         SPACE 2                                                        63350013
*              NOW WE PICK UP THE ADDRESS OF THE DED ENTRY              63420013
         SPACE                                                          63490013
         MVC   PAR1+2(2,GRDCPT),0(GR1) SET UP ITS DICT REF IN PAR1      63560013
         SPACE 2                                                        63630013
         L     GRL,ZDRFAB(0,GRCP)      BRANCH TO ZDRFAB ROUTINE TO PICK 63700013
         BALR  GRR,GRL               UP ABSOLUTE ADDRESS OF THE ENTRY.  63770013
         SPACE 2                                                        63840013
         L     GR2,PAR1(0,GRDCPT)      POINT GR2 AT THE DED ENTRY       63910013
         SPACE 2                                                        63980013
         BC    B,X7                    NOW GO TO ALLOCATE STORAGE FOR   64050013
*                                    THE DED.                           64120013
         EJECT                                                          64190013
*              DEDAL2 ENTRY POINT                                       64260013
         SPACE 2                                                        64330013
*              THE VARIABLE IN QUESTION NEEDS A DED AND HAS ALREADY     64400013
*        BEEN ALLOCATED A SYMBOL TABLE.                                 64470013
         SPACE 4                                                        64540013
DEDAL2   STM   GRBASE,GPARAM,REGST1    SAVE REGISTERS                   64610013
         SPACE 2                                                        64680013
*              FIRST WE INITIALIZE THE RETURN SLOTS.                    64750013
         SPACE 2                                                        64820013
         LA    GRR,DED160               WE WILL RETURN TO DED160 IF NO  64890013
         ST    GRR,RETRN1     PREVIOUS IDENTICAL DED HAS BEEN FOUND.    64960013
         SPACE                                                          65030013
         LA    GRR,DED170               WE WILL RETURN TO DED170 IF WE  65100013
         ST    GRR,RETRN2     FIND AN IDENTICAL DED.                    65170013
               SPACE                                                    65240013
         MVI   VARISW,X'00'            SET VARISW TO SHOW VARIABLE HAS  65310013
*              A SYMBOL-TABLE.                                          65380013
         SPACE 2                                                        65450013
*              NOW WE BRANCH TO DEDAL1-ROUTINE TO SET UP THE 3-BYTE     65520013
*        AREA 'DEDINF'.                                                 65590013
         SPACE                                                          65660013
         BC    B,DED100                                                 65730013
         SPACE 2                                                        65800013
*              DEDAL1 RETURNS CONTROL TO HERE IF NO PREVIOUS IDENTICAL  65870013
*        DED IS FOUND.                                                  65940013
         SPACE                                                          66010013
DED160   XC    DEDINF+SCRREF(2),DEDINF+SCRREF                           66080013
         TM    DEDTYP,X'01'          IS THERE A PICTURE                 66150013
         BC    BO,DED165                                                66220013
         SPACE                                                          66290013
*              HERE THERE IS A PICTURE.                                 66360013
         SPACE                                                          66430013
         MVC   PAR1+2(2,GRDCPT),DRDED                                   66500013
         BAL   GRR,STEVE                                                66570013
         L     GRBILD,PAR1(0,GRDCPT)                                    66640013
         MVC   PAR1+2(2,GRDCPT),PARAM3(GPARAM)                          66710013
         BAL   GRR,STEVE                                                66780013
         L     GR1,PAR1(0,GRDCPT)       POINT GR1 AT PICTURE ENTRY.     66850013
         MVC   DDPCRF(2,GRBILD),0(GR1)                                  66920013
         MVC   PAR1+2(2,GRDCPT),0(GR1)                                  66990013
         BAL   GRR,STEVE                                                67060013
         L     GR1,PAR1(0,GRDCPT)      COMPARE THE STATIC OFFSET WITH 3 67130013
         CLC   PICOFF(3,GR1),NO3+1   IF NOT GREATER, THE PICTURE HAS    67200013
         BC    BNH,DED165            NOT BEEN ALLOCATED BEFORE.         67270013
         MVC   PAR1+2(2,GRDCPT),DRDED                                   67340013
         BAL   GRR,STEVE                                                67410013
         L     GR2,PAR1(0,GRDCPT)                                       67480013
         MVC   DDSTOF(3,GR2),PICOFF(GR1)                                67550013
         OI    FLAG,OLDPIC                                              67620013
         BC    B,X7                                                     67690013
         SPACE 2                                                        67760013
*              WE POINT GR2 AT THE DED/SYMBOL DICT.ENTRY                67830013
         SPACE                                                          67900013
DED165   MVC   PAR1+2(2,GRDCPT),DRDED   PUT DICT. REF. OF SYMTAB ENTRY  67970013
*                                    INTO PAR1.                         68040013
         SPACE 2                                                        68110013
         L     GRL,ZDRFAB(0,GRCP)      BRANCH TO ZDRFAB ROUTINE TO PICK 68180013
         BALR  GRR,GRL               UP THE ADDRESS OF THE ENTRY        68250013
         SPACE 2                                                        68320013
         L     GR2,PAR1(0,GRDCPT)      NOW GR2 POINTS AT THE ENTRY      68390013
         SPACE                                                          68460013
         BC    B,X7                    GO TO ALLOCATE STORAGE FOR THE   68670013
*                                    DED.                               68740013
         SPACE 4                                                        68810013
*              DEDAL1 RETURNS CONTROL TO HERE IF IT FINDS AN IDENTICAL  68880013
*        DED.  GR3 POINTS AT THE ENTRY IN SCRATCH STORAGE OF THE        68950013
*        PREVIOUS DED.                                                  69020013
         SPACE                                                          69090013
*              WE MOVE THE STATIC OFFSET OF THE DED INTO THE EXISTING   69160013
*        SYMBOL TABLE ENTRY.                                            69230013
*              FIRST WE PICK UP THE SYMBOL TABLE DICT. ENTRY            69300013
         SPACE                                                          69370013
DED170   MVC   PAR1+2(2,GRDCPT),DRDED                                   69440013
         L     GRL,ZDRFAB(0,GRCP)                                       69510013
         BALR  GRR,GRL                                                  69580013
         L     GR2,PAR1(0,GRDCPT)       POINT GR2 AT THE SYMBOL ENTRY.  69650013
         SPACE                                                          69720013
         MVC   STDDOF(3,GR2),STATOF(GR3)     MOVE THE STATIC OFFSET OF  69790013
*                   THE DED INTO THE SYMBOL TABLE ENTRY.                69860013
         SPACE 2                                                        69930013
         MVC   STDED(3,GR2),0(GR3)      MOVE IMAGE OF DED AND/OR        70000013
*                   PICTURE DICT. REF. INTO SYMBOL TABLE ENTRY.         70070013
         OI    FLAG,FLAG1                                               70140013
         SPACE 6                                                        70210013
*              THIS IS THE RETURN POINT OUT OF THE DEDAL ROUTINE.       70280013
         SPACE 2                                                        70350013
DEDRTN   TM    FLAG,FLAG1              HAVE WE ALREADY ALLOCATED A      70420013
         BC    BO,DEDRTA             SYMBOL TABLE                       70490013
         MVC   PAR1+2(2,GRDCPT),PARAM5(GPARAM)                          70560013
         BAL   GRR,STEVE                                                70630013
         L     GR1,PAR1(0,GRDCPT)                                       70700013
         ST    GR1,ABS                 POINT GR1 AT SLOT TO TAKE THE    70770013
         AH    GR1,PARAM1(0,GPARAM)     DICT.REF. OF THE DED ENTRY      70840013
         MVC   0(2,GR1),DRDED          AND MOVE THE DICT.REF. IN.       70910013
DEDRTA   MVI   FLAG,0                  CLEAR FLAG BYTE.                 70980013
         MVI   PARAM4(GPARAM),X'00'     CLEAR PARAM4.                   71050013
         LM    GRBASE,GPARAM,REGST1    RESTORE REGISTERS                71120013
*                                    LOCATION COUNTER.                  71190013
         SPACE                                                          71260013
         BCR   BR,GRR                  RETURN                           71330013
         EJECT                                                          71400013
*              DATA AREA FOR DEDAL ROUTINE                              71470013
         SPACE 4                                                        71540013
REGST1   DC    16F'0'                  STORAGE AREA FOR REGISTERS.      71610013
NO11     DC    F'11'                                                    71680013
ABS      DC    F'0'                     SLOT TO STORE THE ABSOLUTE      71750013
*                   ADDRESS OBTAINED FROM THE DICT. REF. PASSED IN      71820013
*                   PARAM5.                                             71890013
PICREF   DC    H'0'                    SLOT TO TAKE DICT.REF.OF PICTURE 71960013
DCRF     DC    H'0'                    DICT. REF. SLOT                  72030013
DFPRDC   DC    X'0680'                 DEFAULT PRECISION AND SCALING    72100013
*                                    (DECIMAL DATA).                    72170013
DFPRBN   DC    X'0F80'                 DEFAULT PRECISION AND SCALING    72240013
*                                    (BINARY DATA).                     72310013
RETRN1   DC    F'0'                     SLOT TO CONTAIN THE ADDRESS TO  72380013
*                        WHICH DEDAL1 RETURNS CONTROL IF NO PREVIOUS    72450013
*                        IDENTICAL DED IS FOUND.                        72520013
RETRN2   DC    F'0'                     SLOT TO CONTAIN THE ADDRESS TO  72590013
*                        WHICH DEDAL1 RETURNS CONTROL IF AN IDENTICAL   72660013
*                        DED IS FOUND.                                  72730013
DRDED    DC    H'0'                    DED DICTIONARY REFERENCE.        72800013
DEDTYP   DC    X'0'                     FLAG TO INDICATE TYPE OF DED.   72870013
LSTENT   DC    X'FFFFFF'                MARKER FOR LAST DED SCRATCH     72940013
*                                             ENTRY.                    73010013
VARISW   DC    X'0'                                                     73080013
PICT     EQU   X'08'                                                    73150013
         EJECT                                                          73220013
*              THIS ROUTINE CALLS 'ZDRFAB'. IT EXPECTS TO BE CALLED IN  73290013
*        THIS WAY,                                                      73360013
*                            BAL   GRR,STEVE                            73430013
*              THUS SAVING FOUR BYTES IN THE CALLING SEQUENCE.          73500013
         SPACE 4                                                        73570013
STEVE    L     GRL,ZDRFAB(0,GRCP)                                       73640013
         BCR   BR,GRL                                                   73710013
         EJECT                                                          73780013
*              OFFSETS OF SLOTS IN COMMUNICATIONS REGION                73850013
         SPACE 4                                                        73920013
PAR1     EQU   X'80'                                                    73990013
PAR2     EQU   X'84'                                                    74060013
ZCOMM    EQU   304                                                      74130013
ZLSKEL   EQU   ZCOMM+36                DICT REF OF LAST SKELEOTN D.V.   74200013
ZEOSC    EQU   ZCOMM+38                LAST MEMBER OF STATIC CHAIN      74270013
ZSICSZ   EQU   ZCOMM+56                SIZE OF STATIC CONTROL SECTION   74340013
ZPROC1   EQU   ZCOMM+64                HEAD OF ENTRY TYPE 1 CHAIN       74410013
ZSTACH   EQU   ZCOMM+68                HEAD OF STATIC CHAIN             74480013
ZCITEM   EQU   ZCOMM+80                HEAD OF CONTROLLED CHAIN         74550013
         EJECT                                                          74620013
*              OFFSETS OF THE SLOTS IN AN 'ENTRY TYPE 1' DICT. ENTRY    74690013
         SPACE 4                                                        74760013
E1CDBT   EQU   0                       CODE BYTE                        74830013
E1LGTH   EQU   E1CDBT+1                LENGTH                           74900013
E1LEV    EQU   E1LGTH+2                LEVEL                            74970013
E1CNT    EQU   E1LEV+1                 COUNT                            75040013
E1CONT   EQU   E1CNT+1                 DICT.REF.OF ENTRY TYPE 1 OF      75110013
*                                    CONTAINING BLOCK(BACKWARD CHAIN)   75180013
E1DRLB   EQU   E1CONT+2                DICT.REF.OF FIRST LABEL ON THIS  75250013
*                                    PROC. STATEMENT                    75320013
E1E1     EQU   E1DRLB+2                DICT.REF OF NEXT ENTRY TYPE 1    75390013
E1AUTO   EQU   E1E1+2                  AUTOMATIC CHAIN                  75460013
E1SYMT   EQU   E1AUTO+12               DICT.REF.OF FIRST 'SYMBOL'       75530013
*                                    VARIABLE IN THIS BLOCK.            75600013
E1ENCH   EQU   E1SYMT+17               DICT.REF.OF FIRST E1 FOR ENTRY   75670013
*                                    STATEMENT.                         75740013
E1PRNO    EQU  E1ENCH+24             SLOT CONTAINING TWICE NUMBER OF    75810015
*                                    PARAMETERS.                        75880013
E1FP1R   EQU   E1PRNO+1                SLOT CONTAINING DICT.REF. OF     75950013
*                                    FIRST FORMAL PARAMETER TYPE 1      76020013
         EJECT                                                          76090013
*              OFFSETS IN AN 'ENTRY TYPE 1' DICT. ENTRY (FOR AN ENTRY   76160013
*        STATEMENT).                                                    76230013
         SPACE 4                                                        76300013
E1ENCB   EQU   0                       CODE BYTE                        76370013
E1ENPN   EQU   E1ENCB+12               SLOT CONTAINING TWICE NUMBER OF  76440013
*                                    PARAMETERS.                        76510013
E1ENPR   EQU   E1ENPN+1                SLOT CONTAINING FIRST DICT.REF.  76580013
*                                    TO AN FP1.                         76650013
         EJECT                                                          76720013
*              OFFSETS IN AN ENTRY TYPE 2 DICT. ENTRY                   76790013
         SPACE 4                                                        76860013
E2CDBT   EQU   0                       INITIAL CODE BYTE                76930013
E2LGTH   EQU   E2CDBT+1                LENGTH                           77000013
E2E3     EQU   E2LGTH+2                CHAIN TO ENTRY TYPE 3            77070013
E2DATA   EQU   E2E3+5                  DATA BYTE                        77140013
E2DTIN   EQU   E2DATA+1                DATA INFORMATION                 77210013
E2DDRF   EQU   E2DTIN+3                DICT.REF.FOR DED/PICTURE         77280013
         EJECT                                                          77350013
*              OFFSETS IN AN ENTRY TYPE 3 DICT. ENTRY                   77420013
         SPACE 4                                                        77490013
E3CDBT   EQU   0                       CODE BYTE                        77560013
E3E2     EQU   E3CDBT+5                DICT.REF. OF ENTRY TYPE 2.       77630013
         SPACE 2                                                        77700013
E3CODE   EQU   X'84'                   HEX VALUE OF INITIAL CODE BYTE   77770013
E3AUTO   EQU   11                      AUTO CHAIN SLOT                  77840013
         EJECT                                                          77910013
*              OFFSETS IN AN ENTRY TYPE 4 DICT. ENTRY                   77980013
         SPACE 4                                                        78050013
E4CODE   EQU   X'03'                   CODE BYTE VALUE                  78120013
         EJECT                                                          78190013
*              OFFSETS IN AN ENTRY TYPE 5 DICT. ENTRY                   78260013
         SPACE 4                                                        78330013
E5CODE   EQU   X'83'                   CODE BYTE VALUE                  78400013
         EJECT                                                          78470013
*              OFFSETS OF THE SLOTS IN A 'DATA ITEM' DICTIONARY ENTRY   78540013
         SPACE 4                                                        78610013
CODBYT   EQU   0                       CODE BYTE                        78680013
LENGTH   EQU   CODBYT+1                LENGTH SLOT                      78750013
CHAIN    EQU   LENGTH+2                CHAIN SLOT                       78820013
OFFSET   EQU   CHAIN+2                 OFFSET                           78890013
DCLNUM   EQU   OFFSET+3                DECLARE NUMBER                   78960013
OTHER1   EQU   DCLNUM+2                OTHER 1 CODE BYTE                79030013
VARBLE   EQU   OTHER1+1                VARIABLE CODE BYTE               79100013
OTHER2   EQU   VARBLE+1                OTHER 2 CODE BYTE                79170013
OTHER3   EQU   OTHER2+1                OTHER 3 CODE BYTE                79240013
OTHER4   EQU   OTHER3+1                OTHER 4 CODE BYTE                79310013
DATABT   EQU   OTHER4+1                DATA CODE BYTE                   79380013
DATINF   EQU   DATABT+1                DATA INFORMATION                 79450013
SYMSLT   EQU   DATINF+3                SYMBOL SLOT                      79520013
VARINF   EQU   SYMSLT+2                VARIABLE INFORMATION             79590013
         EJECT                                                          79660013
*              OFFSETS IN A 'STRUCTURE' DICT.ENTRY                      79730013
         SPACE 4                                                        79800013
STRCDB   EQU   0                       CODE BYTE                        79870013
STRLTH   EQU   STRCDB+1                LENGTH                           79940013
STRCHN   EQU   STRLTH+2                CHAIN                            80010013
STROFF   EQU   STRCHN+2                OFFSET                           80080013
STRDCL   EQU   STROFF+3                DECLARE NUMBER                   80150013
STROT1   EQU   STRDCL+2                OTHER1 CODE BYTE                 80220013
STRVAR   EQU   STROT1+1                VARIABLE CODE BYTE               80290013
STROT2   EQU   STRVAR+1                OTHER2 CODE BYTE                 80360013
STROT3   EQU   STROT2+1                OTHER3 CODE BYTE                 80430013
STROT4   EQU   STROT3+1                OTHER4 CODE BYTE                 80500013
STRVNF   EQU   STROT4+1                VARIABLE INFORMATION             80570013
         SPACE 2                                                        80640013
STRCB1   EQU   X'2E'                   DIFFERENT POSSIBLE CODE BYTES    80710013
STRCB2   EQU   X'3E'                                                    80780013
STRCB3   EQU   X'AE'                                                    80850013
STRCB4   EQU   X'BE'                                                    80920013
         EJECT                                                          80990013
*              OFFSETS IN A 'LABEL VARIABLE' DICT.ENTRY                 81060013
         SPACE 4                                                        81130013
LBCDBT   EQU   0                       CODE BYTE                        81200013
LBLGTH   EQU   LBCDBT+1                LENGTH                           81270013
LBCHN    EQU   LBLGTH+2                CHAIN                            81340013
LBOFF    EQU   LBCHN+2                 STORAGE OFFSET                   81410013
LBDCLN   EQU   LBOFF+3                 DECLARE NUMBER                   81480013
LBOTH1   EQU   LBDCLN+2                OTHER1 CODE BYTE                 81550013
LBVRBL   EQU   LBOTH1+1                VARIABLE CODE BYTE               81620013
LBOTH2   EQU   LBVRBL+1                OTHER2 CODE BYTE                 81690013
LBOTH3   EQU   LBOTH2+1                OTHER3 CODE BYTE                 81760013
LBOTH4   EQU   LBOTH3+1                OTHER4 CODE BYTE                 81830013
LBVBLE   EQU   LBOTH4+1                VARIABLE INFORMATION             81900013
         EJECT                                                          81970013
*              OFFSETS IN A 'FORMAL PARAMETER TYPE 1' ENTRY.            82040013
         SPACE 4                                                        82110013
FP1CB    EQU   0                       CODE BYTE                        82180013
FP1LTH   EQU   FP1CB+1                 LENGTH                           82250013
FP1PRD   EQU   FP1LTH+4                DICT.REF.OF PARAMETER DESCRIPTN. 82320013
FP1LC    EQU   FP1PRD+2                LEVEL AND COUNT                  82390013
         EJECT                                                          82460013
*              OFFSETS OF SLOTS IN A 'SYMBOL TABLE' DICT.ENTRY          82530013
         SPACE 4                                                        82600013
STCDBT   EQU   0                       CODE BYTE                        82670013
STLGTH   EQU   STCDBT+1                LENGTH                           82740013
STCHN    EQU   STLGTH+2                CHAIN SLOT                       82810013
STDDOF   EQU   STCHN+2                 OFFSET OF DED IN STATIC          82880013
STDED    EQU   STDDOF+3                DED/PICTURE TABLE DICT.REF.      82950013
STATST   EQU   STDED+3                 OFFSET OF SYMBOL TABLE IN STATIC 83020013
STNEXT   EQU   STATST+3                DICT.REF.OF NEXT SYMBOL VARIABLE 83090013
*                                    IN THIS BLOCK (OR DICT.REF. OF     83160013
*                                    CONTAINING ENTRY TYPE 1            83230013
STVAR    EQU   STNEXT+2                DICT. REF. OF ITEM REQUIRING     83300013
*                                    ENTRY IN SYMBOL TABLE.             83370013
         EJECT                                                          83440013
*              FORMAT OF A 'DED' DICT. ENTRY                            83510013
         SPACE 4                                                        83580013
DDCODE   EQU   0                       CODE BYTE                        83650013
DDLGTH   EQU   DDCODE+1                LENGTH                           83720013
DDSTCH   EQU   DDLGTH+2                STATIC CHAIN                     83790013
DDSTOF   EQU   DDSTCH+2                STATIC OFFSET                    83860013
DDDED    EQU   DDSTOF+3                ACTUAL DED                       83930013
DDPCRF   EQU   DDDED+1                 DICT.REF. OF PICTURE             84000013
         SPACE 2                                                        84070013
DDCDBT   EQU   X'C7'                   HEX VALUE OF INITIAL CODE BYTE   84140013
DDLENG   EQU   X'0B'                   HEX VALUE OF LENGTH OF ENTRY     84210013
         EJECT                                                          84280013
*              OFFSETS OF SLOTS IN A 'DED2' DICT. ENTRY                 84350013
         SPACE 4                                                        84420013
D2CDBT   EQU   0                       CODE BYTE                        84490013
D2LGTH   EQU   D2CDBT+1                LENGTH                           84560013
D2CHN    EQU   D2LGTH+2                CHAIN                            84630013
D2OFF    EQU   D2CHN+2                 OFFSET                           84700013
D2DED    EQU   D2OFF+3                 ACTUAL DED                       84770013
         EJECT                                                          84840013
*              OFFSETS OF SLOTS IN 'CONSTANT' DICT.ENTRY                84910013
         SPACE 4                                                        84980013
CCDBT    EQU   0                       CODE BYTE                        85050013
CLNGTH   EQU   CCDBT+1                 LENGTH                           85120013
CCHAIN   EQU   CLNGTH+2                CHAIN                            85190013
CTYPE    EQU   CCHAIN+5                TYPE BYTE                        85260013
         SPACE                                                          85330013
CDED     EQU   X'04'                   'DED REQUIRED' BIT(IN TYPE BYTE) 85400013
         SPACE                                                          85470013
CDATA    EQU   CTYPE+1                 DATA BYTE                        85540013
CDEDRF   EQU   CDATA+1                 DICT.REF. OF DED ENTRY           85610013
         EJECT                                                          85680013
*              FORMAT OF A 'PICTURE' DICT. ENTRY                        85750013
         SPACE 4                                                        85820013
PICCB    EQU   0                       CODE BYTE                        85890013
PICOFF   EQU   PICCB+5                 OFFSET SLOT                      85960013
PICLTH   EQU   PICOFF+7                LENGTH BYTE                      86030013
         SPACE 2                                                        86100013
PICCBT   EQU   X'C8'                   HEX VALUE OF CODE BYTE           86170013
         EJECT                                                          86240013
*              SYMBOLIC REPRESENTATION OF THE OTHER1 CODE BYTE          86310013
         SPACE                                                          86380013
SYMBOL   EQU   X'80'                   SYMBOL BIT                       86450013
CHECK    EQU   X'20'                   CHECK BIT                        86520013
LSMSTR   EQU   X'08'                   LAST MEMBER OF STRUCTURE         86590013
SYMCHK   EQU   SYMBOL+CHECK            SYMBOL AND CHECK BITS.           86660013
         EJECT                                                          86730013
*              SYMBOLIC REPRESENTATION OF THE 'OTHER2' CODE BYTE.       86800013
         SPACE 4                                                        86870013
FMPRAM   EQU   X'08'                   FORMAL PARAMETER.                86940013
         EJECT                                                          87010013
*              SYMBOLIC REPRESENTATION OF THE OTHER3 CODE BYTE          87080013
         SPACE 2                                                        87150013
DED      EQU   X'40'                   DED BIT                          87220013
         EJECT                                                          87290013
*              SYMBOLIC REPRESENTATION OF THE OTHER4 CODE BYTE          87360013
         SPACE 2                                                        87430013
MAJSTR   EQU   X'04'                   MAJOR STRUCTURE BIT              87500013
         EJECT                                                          87570013
*              SYMBOLIC REPRESENTATION OF THE DATA BYTE                 87640013
         SPACE 4                                                        87710013
*              THERE ARE TWO INTERPRETATIONS OF THIS BYTE, DEPENDING    87780013
*        ON THE VALUE OF THE FIRST BIT.                                 87850013
         SPACE 3                                                        87920013
*              CASE OF CAD/NUMERIC FIELD  (FIRST BIT = 1)               87990013
         SPACE                                                          88060013
CADNUM   EQU   X'80'                   CAD/NUMERIC FIELD                88130013
OFFPNT   EQU   X'40'                   OFFSET/POINTER BIT.              88200015
STERLG   EQU   X'20'                   STERLING                         88270013
LONG     EQU   X'10'                   LONG                             88340013
SHORT    EQU   X'EF'                   SHORT                            88410013
CAD      EQU   X'08'                   CAD                              88480013
NUMFLD   EQU   X'F7'                   NUMERIC FIELD                    88550013
BINARY   EQU   X'04'                   BINARY                           88620013
DECMAL   EQU   X'FB'                   DECIMAL                          88690013
FLOAT    EQU   X'02'                   FLOAT                            88760013
FIXED    EQU   X'FD'                   FIXED                            88830013
COMPLX   EQU   X'01'                   COMPLEX                          88900013
REAL     EQU   X'FE'                   REAL                             88970013
         SPACE 3                                                        89040013
*              CASE OF STRING  (FIRST BIT = 0)                          89110013
         SPACE                                                          89180013
STRING   EQU   X'7F'                   STRING                           89250013
         SPACE                                                          89320013
ADJLTH   EQU   X'40'                   ADJUSTABLE LENGTH                89390013
ALIGN    EQU   X'20'                   ALIGNED                          89460013
PACKED   EQU   X'DF'                   PACKED                           89530013
VARYNG   EQU   X'10'                   VARYING                          89600013
NOPICT   EQU   X'08'                   NO PICTURE                       89670013
PICTUR   EQU   X'F7'                   PICTURE                          89740013
CHAR     EQU   X'04'                   CHARACTER                        89810013
BIT      EQU   X'FB'                   BIT                              89880013
         EJECT                                                          89950013
*              OFFSETS CORRESPONDING TO EACH BIT OF THE VARIABLE        90020013
*        INFORMATION BYTE.                                              90090013
         SPACE 4                                                        90160013
VINF1    EQU   4                       SECOND OFFSET SLOT               90230013
VINF2    EQU   3                       DIMENSIONED SLOT                 90300013
VINF3    EQU   10                      STRUCTURE MEMBER SLOT            90370013
VINF4    EQU   2                       POS SLOT                         90440013
VINF5    EQU   4                       INITIAL VALUE OR LIKE SLOT       90510013
VINF6    EQU   4                       DEFINED OR EXTERNAL SLOT         90580013
VINF7    EQU   3                       DEFINED WITH EXPRESSION SLOT     90650013
VINF8    EQU   0                       NOT USED                         90720013
         EJECT                                                          90790013
*              TRANSFER VECTOR TO CONTROL PHASE ROUTINES                90860013
         SPACE 4                                                        90930013
ZUGC     EQU   X'10'                                                    91000013
ZUTXTC   EQU   X'14'                                                    91070013
ZURC     EQU   X'18'                                                    91140013
ZABORT   EQU   X'20'                                                    91210013
ZLOADW   EQU   X'24'                                                    91280013
ZDICAB   EQU   X'28'                                                    91350013
ZDICRF   EQU   X'2C'                                                    91420013
ZUERR    EQU   X'30'                                                    91490013
ZDRFAB   EQU   X'34'                                                    91560013
RLSCTL   EQU   X'48'                                                    91630013
ZTXTRF   EQU   X'50'                                                    91700013
ZTXTAB   EQU   X'54'                                                    91770013
ZDABRF   EQU   X'60'                                                    91840013
         EJECT                                                          91910013
*              FORMAT OF DED ENTRIES IN SCRATCH STORAGE                 91980013
         SPACE 3                                                        92050013
*              WHEN SEVERAL IDENTICAL DEDS OCCUR, ONLY ONE DED DICT.    92120013
*        ENTRY IS MADE AND ONLY ONE STATIC STORAGE AREA IS ALLOCATED.   92190013
*        WHEN A DED IS REQUIRED, DEDAL CHECKS TO SEE IF AN IDENTICAL    92260013
*        DED HAS OCCURRED PREVIOUSLY. THIS IT DOES BY SCANNING DOWN A   92330013
*        REGION OF SCRATCH CORE CONTAINING AN ENTRY FOR EACH TYPE OF    92400013
*        DED SO FAR ENCOUNTERED.                                        92470013
*              PHASE PD FIRST OBTAINS 4K OF SCRATCH STORAGE, AND USES   92540013
*        THE LAST 3584 BYTES TO MAKE DED ENTRIES FOR DED2'S IN THE SAME 92610013
*        WAY AS DOES PM (THE OTHER 512 BYTES ARE RESERVED FOR THE       92680013
*        SWITCH TABLE (Q.V.)). PD PASSES THE ADDRESS OF THE BEGINNING   92750013
*        OF THE SCRATCH AREA THROUGH A SLOT IN THE COMMUNICATIONS       92820013
*        REGION. DEDAL USES THE ENTRIES MADE BY PD IN ADDITION TO ITS   92890013
*        OWN.                                                           92960013
         SPACE                                                          93030013
*              THE FORMAT OF EACH ENTRY IS AS FOLLOWS.                  93100013
         SPACE                                                          93170013
DEDINF   DC    XL8'0'                                                   93240013
       SPACE                                                            93310013
*              BYTES 0 THROUGH 2.    THE ACTUAL DED. IN THE CASE OF A   93380013
*        PICTURED DED, BYTE 0 IS THE DATA BYTE, AND BYTES 1 AND 2 ARE   93450013
*        THE DICT. REF. OF THE PICTURE.                                 93520013
         SPACE                                                          93590013
*              BYTES 3 THROUGH 5.    THE OFFSET IN STATIC OF THE DED.   93660013
         SPACE                                                          93730013
*              BYTES 6 AND 7.        THE DICT. REF. OF THE DED.         93800013
         SPACE                                                          93870013
*              HENCE THE FOLLOWING OFFSETS.....                         93940013
         SPACE                                                          94010013
STATOF   EQU   3                        OFFSET OF STATIC SLOT           94080013
SCRREF   EQU   6                        OFFSET OF DICT. REF.            94150013
         EJECT                                                          94220013
*              THE PARAMETER REGION                                     94290013
         SPACE 2                                                        94360013
*              THIS IS AN AREA USED BY THE DEDAL ROUTINE TO HAVE PASSED 94430013
*        TO IT THE VARIOUS PARAMETERS IT NEEDS. THE PARAMETERS ARE SET  94500013
*        UP BY THE ROUTINE WHICH CALLS IT AT THE DEDAL1 ENTRY POINT.    94570013
         SPACE                                                          94640013
*              IT IS SIX HALF-WORDS LONG.                               94710013
         SPACE                                                          94780013
PARAM    DC    6H'0'                                                    94850013
         SPACE 2                                                        94920013
*              THE PARAMETER REGION IS POINTED AT BY THE REGISTER       94990013
*        GPARAM                                                         95060013
         SPACE 2                                                        95130013
*              PARAM1,PARAM2 AND PARAM3 CONTAIN OFFSETS WHICH MUST BE   95200013
*        ADDED TO THE ABSOLUTE ADDRESS OF THE DICTIONARY ENTRY OF THE   95270013
*        VARIABLE IN ORDER TO POINT AT CERTAIN SLOTS IN THAT ENTRY.     95340013
         SPACE                                                          95410013
*              THE FORMAT IS AS FOLLOWS.                                95480013
         SPACE                                                          95550013
PARAM1   EQU   0                        OFFSET FOR SLOT WHICH IS TO     95620013
*                        TAKE THE DICT. REF. TO THE DED ENTRY.          95690013
         SPACE                                                          95760013
PARAM2   EQU   PARAM1+2                 OFFSET FOR THE DATA BYTE.       95830013
         SPACE                                                          95900013
PARAM3   EQU   PARAM2+2                 OFFSET FOR THE SLOT WHICH IS TO 95970013
*        TAKE THE DICT. REF. OF ANY PICTURE (BUT SEE PARAM4).           96040013
         SPACE                                                          96110013
PARAM4   EQU   PARAM3+2                 THIS IS USED AS A FLAG IN       96180013
*        CERTAIN CASES. SOMETIMES, ON ENTRY TO DEDAL2, WE CANNOT        96250013
*        GUARANTEE THAT THE VARIABLE'S DICT. ENTRY AND ITS PICTURE      96320013
*        DICT. ENTRY WILL BE IN THE SAME BLOCK. IN SUCH CASES, WE MUST  96390013
*        HAVE A DICT. REF. PASSED IN PARAM3, RATHER THAN AN OFFSET AS   96460013
*        IS NORMALLY THE CASE. THEREFORE WE SET A FLAG IN PARAM4.       96530013
         SPACE                                                          96600013
PARAM5   EQU   PARAM4+2                 DICT. REF. OF VARIABLE.         96670013
         SPACE                                                          96740013
PARAM6   EQU   PARAM5+2                DICT.REF.OF VARIABLE             96810013
*                                    (USED BY STRSCN ROUTINE)           96880013
         EJECT                                                          96950013
*              REGISTER ASSIGNMENT                                      97020013
         SPACE 6                                                        97090013
GR0      EQU   0                       UTILITY                          97160013
GR1      EQU   1                       UTILITY                          97230013
GR2      EQU   2                       UTILITY                          97300013
GR3      EQU   3                       UTILITY                          97370013
GR4      EQU   4                       UTILITY                          97440013
GRSTND   EQU   5                       POINTER TO STANDARD DED TABLE    97510013
GPARAM   EQU   6                       POINTER TO (DEDAL) PARAMETER     97580013
*                                    REGION                             97650013
GRBILD   EQU   7                       POINTER TO DICT.ENTRY BUILD AREA 97720013
GRLC     EQU   8                       LOCATION COUNTER REGISTER        97790013
GRBASE   EQU   9                       BASE REGISTER                    97860013
GRDCNT   EQU   10                      POINTER TO DICT.ENTRY CURRENTLY  97930013
*                                    BEING PROCESSED                    98000013
GRCP     EQU   11                      POINTER TO CONTROL PHASE         98070013
PMBASE   EQU   12                      BASE REGISTER FOR MODULE PM      98140013
GRDCPT   EQU   13                      POINTER TO DICTIONARY            98210013
GRR      EQU   14                      RETURN REGISTER                  98280013
GRL      EQU   15                      LINK REGISTER                    98350013
         EJECT                                                          98420013
*              BRANCH MNEMONICS.                                        98490013
         SPACE 4                                                        98560013
B        EQU   15                                                       98630013
BR       EQU   15                                                       98700013
NOP      EQU   0                                                        98770013
NOPR     EQU   0                                                        98840013
BH       EQU   2                                                        98910013
BL       EQU   4                                                        98980013
BE       EQU   8                                                        99050013
BNH      EQU   13                                                       99120013
BNL      EQU   11                                                       99190013
BNE      EQU   7                                                        99260013
BO       EQU   1                                                        99330013
BM       EQU   4                                                        99400013
BZ       EQU   8                                                        99470013
BNO      EQU   14                                                       99540013
         SPACE 6                                                        99610013
         END   IEMPM                                                    99680013
