RA       TITLE 'IEMRA, REGISTER ALLOCATION FIRST PASS,PL/I F'           00030013
*                                                                       00060013
*                                                                       00090013
*                                                                       00120013
*                                                                       00150013
*              STATUS-CHANGE LEVEL 0.                                   00180013
* R20 816400                                                      31644 00190020
*                                                                       00210013
* ###    255270,255835,373500,387300,581100-592200,641400         38178 00220046
*                      ### - SEE ID#                                    00230046
* R21    255839                                                   41963 00235021
*                                                                       00240013
*                                                                       00270013
*              FUNCTION/OPERATION                                       00300013
*              THIS PHASE PROCESSES ADDRESSING MECHANISMS.              00330013
*                                                                       00360013
*              DURING OBJECT TIME EXECUTION THE FOLLOWING REGISTERS     00390013
*        ARE EXISTANT ALL THE TIME THAT CONTROL IS WITHIN COMPILED      00420013
*                   1.  SDP - THE STATIC DATA POINTER.  THIS IS SET TO  00450013
*        THE START OF THE STATIC INTERNAL DATA AREA                     00480013
*                   2.  ADP - THE AUTOMATIC DATA POINTER  THIS IS SET   00510013
*        TO THE START OF THE AUTOMATIC DATA AREA FOR THE CURRENT BLOCK  00540013
*                   3.  PRVP - THE PSUEDO REGISTER VECTOR POINTER.      00570013
*        THIS IS SET TO THE START OF THE PRV FOR THE CURRENT TASK.      00600013
*              IN ADDITION THE REGISTER PREG IS SET TO A REGION AT THE  00630013
*        TOP OF THE CURRENT AUTOMATIC DATA AREA WHERE ADDRESS VALUES    00660013
*        AND SYMBOLIC REGISTER VALUES ARE STORED WHEN THEY ARE NOT      00690013
*        CONTAINED IN PHYSICAL REGISTERS.                               00720013
*                                                                       00750013
*              THE START OF THE AUTOMATIC DATA FOR NON CURRENT BLOCKS   00780013
*        IS STORED IN A PSEUDO REGISTER.  THIS VALUE MAY BE LOADED INTO 00810013
*        A PHYSICAL REGISTER USING THE PRV OFFSET (AS A LOAD CONSTANT)  00840013
*        AND PRVP AS BASE.  THIS REGISTER IS THEN USED FOR ADDRESSING   00870013
*        DATA IN THE ASSOCIATED AUTOMATIC DATA AREA.                    00900013
*                                                                       00930013
*              THE OFFSETS OF STORAGE FOR STATIC INTERNAL DATA AND      00960013
*        AUTOMATIC DATA OF SIZE KNOWN AT COMPILE TIME IS COMPUTED AT    00990013
*        COMPILE TIME AND RECORDED IN THE DICTIONARY ENTRY FOR THE      01020013
*        DATA.  IF THIS OFFSET IS LESS THAN 4K THE DATA MAY BE ACCESSED 01050013
*        DIRECTLY BY REFERENCING INSTRUCTIONS USING SDP OR ADP AS BASE  01080013
*        WITH THE APPROPRIATE OFFSET.  IF THE OFFSET IS GREATER THAN 4K 01110013
*        INDIRECT ADDRESSING MUST BE USED.                              01140013
*                                                                       01170013
*              IT IS ARRANGED THAT AT OBJECT TIME THE STATIC INTERNAL   01200013
*        DATA AREA, AND THE AUTOMATIC DATA AREA FOR EACH BLOCK          01230013
*        CONTAINS, WITHIN THE FIRST 4K, A VECTOR OF ADDRESSES.  THIS    01260013
*        VECTOR CONTAINS THE ABSOLUTE ADDRESSES OF THE FIRST I 4K       01290013
*        BLOCKS OF STORAGE OF THE ASSOCIATED DATA AREA.  I IS THE       01320013
*        NUMBER OF 4K BLOCKS IN THE DATA AREA OR 8, WHICHEVER LESS.     01350013
*        DATA OF FIXED SIZE HAVING ADDRESSES WITHIN THE 2ND THROUGH ITH 01380013
*        4K BLOCK OF THE DATA AREA ARE ADDRESSED BY LOADING A REGISTER  01410013
*        FROM THE VECTOR AND USING THIS REGISTER AS BASE TO ACCESS THE  01440013
*        DATA.                                                          01470013
*              DATA OF FIXED SIZE HAVING ADDRESSES OUTSIDE THIS REGION  01500013
*        ARE ADDRESSED BY COMPILING A  LA  REGISTER,NUMBER OF 4K OFFSET 01530013
*                                      SLL REGISTER,12                  01560013
*                                      AR  REGISTER,SDP OR ADP          01590013
*        THIS REGISTER IS THEN USED AS BASE TO ACCESS THE DATA.         01620013
*                                                                       01650013
*              DATA OF SIZE UNKNOWN AT COMPILE TIME IN AUTOMATIC IS     01680013
*        ADDRESSED INDIRECTLY VIA A DOPE VECTOR.  THE DOPE VECTOR SIZE  01710013
*        IS KNOWN AT COMPILE TIME AND IT IS THEREFORE SITUATED IN THE   01740013
*        FIXED AUTOMATIC DATA REGION AND CAN BE ADDRESSED AS DESCRIBED  01770013
*        ABOVE.                                                         01800013
*                                                                       01830013
*              EACH AGGREGATE OF STATIC EXTERNAL DATA HAS AN ASSOCIATED 01860013
*        CELL IN THE STATIC INTERNAL DATA AREA.  THIS CELL IS ADDRESSED 01890013
*        AS DESCRIBED ABOVE, AND IT IS ARRANGED AT OBJECT TIME THIS     01920013
*        CELL WILL CONTAIN EITHER THE ADDRESS OF THE DATA, OR ITS DOPE  01950013
*        VECTOR.  IN THE FORMER CASE THE DATA IS ADDRESSED INDIRECTLY   01980013
*        VIA THE CELL.  IN THE LATTER CASE THE DATA IS ADDRESSED DOUBLY 02010013
*        INDIRECTLY VIA THE CELL AND THE DOPE VECTOR.                   02040013
*                                                                       02070013
*              EACH PARAMETER TO A PROCEDURE HAS AN ASSOCIATED CELL IN  02100013
*        THE AUTOMATIC DATA AREA FOR THE PROCEDURE.  THIS CELL IS       02130013
*        ADDRESSED AS DESCRIBED ABOVE.  PARAMETERS ARE ADDRESSED IN THE 02160013
*        SAME WAY AS DESCRIBED FOR STATIC EXTERNAL DATA, USING THIS     02190013
*        CELL.                                                          02220013
*                                                                       02250013
*              CONTROLLED DATA IS REFERENCED INDIRECTLY.  A REGISTER IS 02280013
*        FIRST LOADED FROM THE ASSOCIATED PSEUDO REGISTER USING PRVP AS 02310013
*        BASE AND ARRANGING FOR THE PRV OFFSET TO BE INSERTED IN THE    02340013
*        INSTRUCTION AS A LOAD CONSTANT.  THIS REGISTER THEN ADDRESSES  02370013
*        EITHER THE DATA OR ITS DOPE VECTOR.  IN THE LATTER CASE A      02400013
*        FURTHER LOAD IS REQUIRED TO ADDRESS THE DATA.                  02430013
*                                                                       02460013
*              IF IT REQUIRES MORE THAN ONE INSTRUCTION TO LOAD A BASE  02490013
*        REGISTER IN ORDER TO PERMIT ADDRESSING OF DATA REFERENCED IN   02520013
*        A PSEUDO CODE INSTRUCTION, THE LOADING INSTRUCTIONS ARE        02550013
*        EXTRACTED TO THE PROLOGUE OF THE BLOCK.  A STORE INSTRUCTION   02580013
*        IS CONSTRUCTED TO STORE THE BASE VALUE IN A PRIVATE STORAGE    02610013
*        CELL (THE REGION ADDRESSED BY PREG).  THE DATA REFERENCED BY   02640013
*        THE PSEUDO CODE INSTRUCTION IS THEN ADDRESSED BY LOADING A     02670013
*        REGISTER FROM THIS CELL AND USING IT AS BASE.  ALL FURTHER     02700013
*        REFERENCES IN THE BLOCK TO THIS DATA THEN USE THIS CELL FOR    02730013
*        ADDRESSING.                                                    02760013
*              IF WHILE COMPUTING A BASE AS DESCRIBED ABOVE             02790013
*        INTERMEDIATE BASES ARE INCIDENTALLY COMPUTED, E.G. A DOPE      02820013
*        VECTOR ADDRESS OBTAINED WHILE COMPUTING A STATIC EXTERNAL      02850013
*        STRING DATA ADDRESS, THIS BASE IS ALSO STORED IN A PRIVATE     02880013
*        STORE CELL.  SUBSEQUENT REFERENCES TO THE DOPE VECTOR THEN USE 02910013
*        THIS CELL FOR ADDRESSING. SIMILARLY IF A STRING DOPE VECTOR    02940013
*        BASE HAS BEEN STORED IN A PRIVATE STORE CELL AND THE STRING    02970013
*        ITSELF IS REFERENCED, THE CELL IS USED IN ADDRESSING THE       03000013
*        STRING.                                                        03030013
*                                                                       03060013
*              GENERAL ACTION OF PHASE                                  03090013
*                                                                       03120013
*              THE PROGRAM TEXT IS SCANNED AND INSTRUCTIONS REFERENCING 03150013
*        DICTIONARY ENTRIES EXAMINED.                                   03180013
*                                                                       03210013
*              A STACK IS MAINTAINED IN SCRATCH CORE WITH ENTRIES OF    03240013
*        THE FOLLOWING FORMAT FOR EACH BEGIN OR PROCEDURE DETECTED.     03270013
*        THE ENTRIES ARE UNSTACKED ON DETECTION OF END PROCEDURE OR END 03300013
*              1.  THE OUTPUT STRING FROM THE PHASE.  THIS IS THE       03330013
*        BEGIN.                                                         03360013
*        PROGRAM TEXT AFTER MODIFICATION.                               03390013
*              2.  THE INSERTION FILE.  INSTRUCTIONS FOR INSERTION IN   03420013
*        BLOCK PROLOGUES IS BUILT UP IN THIS REGION.                    03450013
*              FURTHER TEXT BLOCKS FOR THESE USES ARE OBTAINED AS       03480013
*        REQUIRED AND CHAINED TO THE APPROPRIATE PRECEDING BLOCK.       03510013
*        PROGRAM TEXT BLOCKS ARE FREED AFTER THEY HAVE BEEN SCANNED     03540013
*        OVER.                                                          03570013
*              WHEN AN INSTRUCTION IS DETECTED THE OPERAND FIELDS ARE   03600013
*        EXAMINED IN TURN.  IF A DICTIONARY REFERENCE IS FOUND, ANY     03630013
*        ASSOCIATED ADDEND IS PICKED UP AND THE ROUTINE 'DR TEST'       03660013
*        INVOKED TO ANALYSE THE REQUIRED ADDRESSING MECHANISMS, AND TO  03690013
*        INSERT THE APPROPRIATE CODE.                                   03720013
*                                                                       03750013
*              IN ADDITION TO PERFORMING THE ADDRESSING CALCULATIONS    03780013
*        DESCRIBED ABOVE, TWO SUBSIDIARY FUNCTIONS ARE CARRIED OUT.     03810013
*              1) CODE IS GENERATED AT THE START OF SOURCE STATEMENTS   03840013
*        TO ENABLE OR DISABLE ON CONDITION SLOTS FOR PREFIX OPTIONS.    03870013
*        THE ACTION TAKEN DEPENDS UPON WHETHER THE STATEMENT STARTS     03900013
*        WITH A LABEL OR NOT. IF IT DOES START WITH A LABEL, THEN       03930013
*        SINCE NO FLOW TRACE IS CARRIED OUT, IT IS ASSUMED THAT         03960013
*        CONTROL MAY ENTER FROM ANYWHERE IN THE PROCEDURE. THEREFORE,   03990013
*        THE CODE GENERATED IS TO SET UP THE ON SLOTS IN THE DSA FOR    04020013
*        ALL THE PREFIX OPTIONS MENTIONED ON THE STATEMENT. IF THE      04050013
*        STATEMENT DOES NOT START WITH A LABEL THEN CODE IS GENERATED   04080013
*        TO CHANGE THE SETTINGS OF THE ON SLOTS FROM THAT REQUIRED BY   04110013
*        THE PREVIOUS STATEMENT TO THAT NECESSARY FOR THE CURRENT ONE.  04140013
*          A COMPILER LABEL FOLLOWED BY A STATEMENT NUMBER IS TREATED   04170013
*        AS A STATEMENT LABEL.                                          04200013
*              2) ON MEETING AN 'ERROR CODE' PSEUDO-CODE MARKER (X'3C') 04230013
*        A CALLING SEQUENCE TO THE LIBRARY ERROR PACKAGE IS COMPILED,   04260013
*        PASSING THE STATEMENT NUMBER AS A PARAMETER. THIS CODE         04290013
*        MARKER IS PRODUCED WHEN A SEVERE SOURCE ERROR HAS BEEN FOUND.  04320013
*                                                                       04350013
*                                                                       04380013
*                                                                       04410013
*              ENTRY POINT - AT TWO BYTES FROM THE START OF THE MODULE  04440013
*        CONTROL IS PASSED FROM IEMAA WITH PAR1 IN THE COMMUNICATIONS   04470013
*        REGION OF THE DICTIONARY CONTAINING THE ADDRESS OF IEMRA.      04500013
*                                                                       04530013
*                                                                       04560013
*                                                                       04590013
*              INPUT- THE SOURCE TEXT,WHOSE STARTING SYMBOLIC REFERENCE 04620013
*        IS IN THE COMMUNICATIONS REGION OF THE DICTIONARY AT STARTX    04650013
*                   - THE DICTIONARY                                    04680013
*                                                                       04710013
*              DICTIONARY ENTRIES ARE ALIGNED TO WORD BOUNDARIES. THE   04740013
*        VALUES DICT REF+O, +1, +2, AND +3 HAVE SPECIAL SIGNIFICANCE.   04770013
*        THE MEANINGS ARE TABULATED BELOW.                              04800013
*                                                                       04830013
*          DATA    *  DR+3     *  DR+2     *  DR+1     *  DR+0          04860013
*      ***********************************************************      04890013
*      STATIC      *           *           *           *                04920013
*      INTERNAL    *           *           *1) SCALAR  *1)SCALARS -     04950013
*      AUTOMATIC,  *  NOT USED *           * STRINGS - *DATA ADDRESS    04980013
*      DEFINED     *           *           * SDV ADDR- *                05010013
*      ............*...........*           * ESS       *                05040013
*                  * PSEUDO    *           *2) ARRAYS  *2) ARRAYS -     05070013
*      CONTROLLED  * REGISTER  *           * ADV       *VIRTUAL ORIGIN  05100013
*      (NON PARAM) * ADDRES    *   DED     * ADDRESS(*)*ADDRESS(*)      05130013
*                  * (ONLY FOR *           *3) STRUCT- *                05160013
*                  * LEVEL 1   *   OR      * URES -    *3) STRUCTURES   05190013
*                  * ITEMS)    *           *STRUCTURE  * - NOT USED     05220013
*      ............*...........*   PICTURE *D.V. ADDR- *                05250013
*                  *ADDRESS IN *           *ESS.       *                05280013
*      CONTROLLED  *AUTO OF    *   ADDRESS *4)NON-STRI-*                05310013
*      PARAMETER   *PSEUDO     *           *NG SCALAR  *                05340013
*                  *REGISTER   *   IN      *STRUCTURE  *                05370013
*                  *OFFSET SLOT*           *MEMBERS-   *                05400013
*      ............*...........*   STATIC  *ADDRESS OF *                05430013
*      PARAMETER   *ADDRESS IN *   NOT USED*POINTER    *                05460013
*      (NON        *AUTO OF    *           *5)NON-     *                05490013
*      CONTROLLED) *POINTER TO *   FOR     *STRING     *                05520013
*      TEMPORARY   *DATA OR    *           *SCALAR     *                05550013
*      TYPE 2      *DOPE VECTOR*   LABELS, *DEFINED    *                05580013
*      ............*...........*           *DATA-      *                05610013
*                  *ADDRESS OF *   STRUCT- *ADDRESS OF *                05640013
*      STATIC      *LOAD       *   URES.   *POINTER    *                05670013
*      EXTERNAL    *CONSTANT IN*           *-----------*---------       05700013
*                  *STATIC     *           *(*)IF ARRAY OF VARYING      05730013
*                  *           *           *STRINGS, THEN VIRTUAL       05760013
*                  *           *           *ORIGIN AND DOPE VECTOR      05790013
*                  *           *           *ADDRESSES ARE OF ARRAY      05820013
*                  *           *           *OF SDV'S                    05850013
*      **********************************************************       05880013
*      ENTRY TYPE1 * ADDRESS IN*PREDO      *ADDRESS OF * OFFSET OF      05910013
*      PROC/BEGIN  *AUTO OF    *REGISTER   *FIRST      * PCBS FROM      05940013
*                  *PROCEDURE  *ADDRESS FOR*SYMTAB ENTR* START OF       05970013
*                  *OF RETURN  *DISPLAY    *Y IN STATIC* BLOCK          06000013
*                  *SWITCH.    *CELL       *FOR BLOCK  *                06030013
*      **********************************************************       06060013
*                  *           *ADDRESS IN *           *                06090013
*      ENTRY TYPE 2* NOT USED  *STATIC OF  * NOT USED  * NOT USED       06120013
*                  *           *DED FOR VAL*           *                06150013
*                  *           *UE RETURNED*           *                06180013
*      **********************************************************       06210013
*                  *          *            *ADDRESS IN *ADDRESS IN      06240013
*      ENTRY TYPE3 * NOT USED * NOT USED   *AUTO OF    *AUTO OF SLOT    06270013
*                  *          *            *DECLARING  *FOR POINTER     06300013
*                  *          *            *BLOCK OF   *TO TARGET       06330013
*                  *          *            *1ST APROX  *FIELD           06360013
*                  *          *            *OF VALUE   *                06390013
*                  *          *            *RETURNED   *                06420013
*      **********************************************************       06450013
*                  *          *            *           * ADDRESS IN     06480013
*      ENTRY TYPE4 * NOT USED * AS TYPE 2  * AS ABOVE  * STATIC OF      06510013
*                  *          *            *           *LOAD CONST      06540013
*                  *          *            *           *FOR REAL        06570013
*                  *          *            *           *ENTRY POINT     06600013
*      **********************************************************       06630013
*      INTERNAL    *          *            *           *                06660013
*      ENTRY LABEL.*          *            *           *                06690013
*      BUILTIN     * NOT USED * NOT USED   * NOT USED  * AS ABOVE       06720013
*      FUNCTION.   *          *            *           *                06750013
*      LIBRARY     *          *            *           *                06780013
*        RATHER THAN THE ADDRESS OF THE ITEM ITSELF.  FOR ARRAYS THE    06790001
*        ADDRESS OF THE NEAREST 4K SECTION TO THE VIRTUAL ORIGIN IS     06800001
*        CALCULATED BY THE ADDRESSING INSTRUCTIONS.                     06810001
*      **********************************************************       06840013
*                  *          *            *           *1)IN PROLOG.    06870013
*      ENTRY TYPE 5*          *            *           *ADDRESS OF      06900013
*      (PARAMETER) * NOT USED * AS TYPE 2  * AS TYPE 3 *POINTER IN      06930013
*                  *         *             *           *AUTO TO TWO     06960013
*                  *         *             *           *WORD PARAM.     06990013
*                  *         *             *           *2)ELSEWHERE     07020013
*                  *         *             *           *FIRST WORD      07050013
*                  *         *             *           *OF ABOVE        07080013
*                  *         *             *           *PARAMETER       07110013
*      **********************************************************       07140013
*                  *          * PROLOG     * WORKSPACE * NOT USED       07170013
*        ZSTACH    * REFERENCE* WORKSPACE  * USED FOR  *                07200013
*      (CODE X'50' * TO       * FOR BUYING * ALLOCATE  *                07230013
*      AT DICT REF * IHEQERR  * STORAGE    * STATEMENTS*                07260013
*        '0174'    *          *  (WP .)    *           *                07290013
*      **********************************************************       07320013
*      CONSTANT    *          * DED ADDRESS*SDV ADDRESS*                07350013
*      (NOT LABEL  * NOT USED * IN STATIC  *IN STATIC  * ADDRESS        07380013
*                  *          *            *(STRINGS   * IN STATIC      07410013
*                  *          *            * ONLY      *                07440013
*      **********************************************************       07470013
*       LABEL      * ADDRESS  *            * ADDRESS   * ADDRESS        07500013
*       CONSTANT   *IN STATIC * NOT USED   * OF BCD    * OF             07530013
*                  *OF LOAD   *            * IN STATIC * LABEL          07560013
*                  *CONSTANT  *            *           *                07590013
*      **********************************************************       07620013
*      INTERNAL    *          *            *           *DCB ADDRESS     07650013
*      FILE CONST, * NOT USED * NOT USED   * NOT USED  *IN STATIC,      07680013
*      FILE TEMP   *          *            *           *AUTOMATIC       07710013
*      **********************************************************       07740013
*      EXTERNAL    *DCB POINTR*            *           * ADDRESS        07770013
*      FILE CONST, *IN  STATIC* NOT USED   * NOT USED  * OF DCB         07800013
*      FILE PARAM. * AUTOMATIC*            *           *                07830013
*      **********************************************************       07860013
*      DED2,'CONDI-*          *            *           *                07890013
*      -TION'CONDI-* NOT USED * NOT USED   * NOT USED  * ADDRESS        07920013
*      -TION,SYMTAB*          *            *           * IN STATIC      07950013
*      ENTRY       *          *            *           *                07980013
*      **********************************************************       08010013
*      ON CONDITION*          *            *           *                08040013
*      ENTRY,WORK- * NOT USED * NOT USED   * NOT USED  * ADDRESS        08070013
*      SPACE REQUIR*          *            *           * IN AUTO        08100013
*      EMENT       *          *            *           *                08130013
*      **********************************************************       08160013
*      INVOCATION  *          *            *           *PSEUDO          08190013
*      COUNT       * NOT USED * NOT USED   * NOT USED  *REGISTER        08220013
*                  *          *            *           *ADDRESS         08250013
*      **********************************************************       08280013
*      DOPE VECTOR *          *            *SDV ADDRESS* STRING         08310013
*      ENTRY FOR   * NOT USED * NOT USED   *IN AUTO    * ADDRESS        08340013
*      STRING TEMP *          *            *           *                08370013
*      *********************************************************        08400013
*                                                                       08430013
*                                                                       08460013
*                                                                       08490013
*              THE FOLLOWING IS THE SEQUENCE OF CODE AND SPECIAL        08520013
*        MARKERS USED IN A PROCEDURES PROLOG.                           08550013
*            START      PROC  - CONTAINS REFERENCE OF ENTRY TYPE 1.     08580013
*                       PCC   - CONTAINS THE PREFIX OPTIONS BYTE FROM   08610013
*        THE PROCEDURE STATEMENT.                                       08640013
*          REPEATED     ABS   - INDICATES ABSOLUTE CODE FOLLOWS         08670013
*          FOR EACH  ***CL    - FOLLOWED BY DICT REF OF LABEL           08700013
*          LABEL ON  *        - CODE FOR ENTRY AT THIS LABEL            08730013
*          PROC      ***BC  B, TO DSA CODE.                             08760013
*                                                                       08790013
*             AAA    ****     - CODE TO GET A NEW DSA.                  08820013
*          REPEATED    ***                                              08850013
*          FOR EACH    *      - CODE TO SET A SWITCH FOR RETURN(EXP)    08880013
*          LABEL       ***                                              08910013
*                       ABS'  - END OF ABSOLUTE CODE                    08940013
*                                                                       08970013
*                             - CODE TO COPY OVER PARAMETERS FOR        09000013
*                      PRIMARY ENTRY POINT.                             09030013
*                       BAL   8,COMMON                                  09060013
*                       BC    B,APPARENT ENTRY POINT (MAIN)             09090013
*                COMMON BALR  10,0                                      09120013
*                        *    - CODE WHICH IS COMMON TO ALL ENTRY       09150013
*                        *      POINTS. THIS INCLUDES INITIALISATION    09180013
*                        *      OF THE DSA, CODE TO REQUEST STORAGE     09210013
*                        *      FOR VDA'S , AND THE INITIALISATION OF   09240013
*                        *      THESE.                                  09270013
*                       LA   10,EQUNO                                   09300013
*                       PINS  - THE PROLOG INSERTION POINT. IT IS HERE  09330013
*        THAT ANY ADDRESSING INSTRUCTIONS GENERATED BY RA/RB AND        09360013
*        MERGED BY RF/RG/RH ARE INSERTED                                09390013
*                       BCR   B,10                                      09420013
*                       PLBS  8  - PROLOG BLOCK SYMBOL. CONTROL         09450013
*        ENTERS HERE WITH REGISTER 8 SET UP.                            09480013
*                       PLBS'    - END OF PROLOG BLOCK                  09510013
*                                                                       09540013
*                       ABS                                             09570013
*        REPEATED    ***   CODE TO STORE REGISTERS, CODE TO BAL TO *R E 09600013
*        FOR EACH    *     LABEL AAA TO GET DSA, CODE TO SET SWITCH*E A 09630013
*        LABEL ON    *     FOR RETURN(EXP).                        *P C 09660013
*        ENTRY STMNT ***   BC  B,COPYPARAMS                        *E H 09690013
*                                                                  *A   09720013
*                       DCA (ADDRESS OF LAST LABEL ON PROC)        *T E 09750013
*                       ABS'                                       *  N 09780013
*                    COPYPARAMS                                    *F T 09810013
*                       L  10,A(START)                             *O R 09840013
*                       BAL 8,COMMON                               *R Y 09870013
*                       BC  B,APPARANT                             *    09900013
*                       PCCBS                                           09930013
*                       SL   DICT REF OF ENTRY TYPE1 FOR PROC           09960013
*                                                                       09990013
*                                                                       10020013
*                                                                       10050013
*              OUTPUT- TEXT, IN THE FORM OF PSEDO-CODE STARTING AT      10080013
*        THE SYMBOLIC REFERENCE GIVEN IN STARTX. IN ADDITION            10110013
*              1) ABSOLUTE CODE IS GENERATED IN THE PROLOG AT THE       10140013
*        PROLOG INSERTION POINT TO SET UP AN ADDRESSING VECTOR FOR      10170013
*        THE REGISTER USED BY REGISTER ALLOCATER ITSELF, PREG. THIS     10200013
*        CODE IS DELIMITED BY X'34' ITEMS TO INDICATE TO FINAL ASSEMBLY 10230013
*        THAT THIS CODE MAY BE DELETED IF IT IS NOT USED. THIS IS       10260013
*        INDICATED BY A FLAG SET IN THE CORRESPONDING ENTRY TYPE1 (SEE  10290013
*        THE CODE GENERATION FOR DETAILS)                               10320013
*              2) ADDRESSING PSEUDO INSTRUCTIONS (ADI INSTRUCTIONS)     10350013
*        ARE GENERATED. THE INSTRUCTIONS ARE EXPANDED BY THE NEXT       10380013
*        PHYSICAL PHASE OF REGISTER ALLOCATER INTO PROPER INSTRUCTIONS  10410013
*        WHICH LEAVE THE ADDRESS FOR THE BASE REQUIRED IN A REGISTER.   10440013
*        THIS REGISTER NEED NOT BE SPECIFIED, BUT MAY, IN FACT, BE      10470013
*        IMPLIED, AND BE PROVIDED BY THE NEXT PHASE OF REGISTER         10500013
*        ALLOCATER. IF THE ADDRESSING IS BEING CARRIED OUT IN PROLOG    10530013
*        CODE, THE REGISTER IS SPECIFIED. THE FORMAT OF AN ADI IS AS    10560013
*        FOLLOWS.                                                       10590013
*                                                                       10620013
*               EACH ADI IS FIVE BYTES LONG AND REPRESENTS AN RR, RX,   10650013
*        OR SHIFT INSTRUCTION.  THE FIRST BYTE ALWAYS CONTAINS 'ADI' ,  10680013
*        THE SECOND BYTE CONTAINS THE OP CODE, AND THE THIRD IS         10710013
*        INTERPRETED AS FOLLOWS                                         10740013
*                                                                       10770013
*                    BIT0   HAS VALUE ONE ONLY IF THE CURRENT SEQUENCE  10800013
*                           OF ADI INSTRUCTIONS IS TO ADDRESS THE FIRST 10830013
*                           OPERAND OF AN (SS) INSTRUCTION.             10860013
*                    BIT1   HAS VALUE ONE ONLY IF THE LAST TWO BYTES    10890013
*                           CONTAIN A LITERAL OFFSET FOR AN RX          10920013
*                           INSTRUCTION                                 10950013
*                    BIT2   HAS VALUE ZERO IF A WORKING REGISTER IS     10980013
*                           REQUIRED AS FIRST OPERAND, ONE IF R2 IS     11010013
*                           REQUIRED (SEE ADD ROUTINE IN IEMRB)         11040013
*                    BIT3   HAS VALUE ONE IF THE BASE IS TO BE DROPPED  11050015
*                           AT STATEMENT BOUNDARIES.  THIS APPLIES TO   11060015
*                           BASES OF CONTROLLED OR BASED ITEMS WHICH    11070015
*                           MAY BE CHANGED BY AN ON UNIT.               11080015
*                    BITS 4-7  SECOND OPERAND FOR RR INSTRUCTIONS, OR   11100013
*                           BASE FOR SECOND OPERAND IN OTHER CASES.     11130013
*              THE FOURTH AND FIFTH BYTES CONTAIN A LITERAL OFFSET IN   11160013
*        SHIFT CASES, ARE UNUSED IN RR CASE, AND CONTAIN EITHER A       11190013
*        LITERAL OFFSET OR DICTIONARY REFERENCE IN OTHER CASES          11220013
*        DEPENDING UPON THE SETTING OF BIT1.                            11250013
*                                                                       11280013
*              3) AN INSERTION FILE IS GENERATED. THIS FILE (A          11310013
*        COLLECTION OF TEXT BLOCKS) CONTAINS ADI INSTRUCTIONS FOR       11340013
*        ADDRESSING SEQUENCES WHICH ARE TO BE PLACED IN A PROLOG.       11370013
*        BECAUSE OF BLOCK NESTING ALL THE INSTRUCTIONS TO BE INSERTED   11400013
*        IN ONE PROLOG NEED NOT BE SEQUENTIAL IN THE INSERTION FILE,    11430013
*        BUT MAY BE CHAINED TOGETHER. THE INSERTION FILE WILL,          11460013
*        THEREFORE, CONTAIN  OTHER ITEMS BESIDES ADI INSTRUCTIONS.      11490013
*        THESE ARE AS FOLLOWS                                           11520013
*                                                                       11550013
*              1) X'FF' ENTRIES WHICH ARE 8 BYTES LONG AND MAY BE       11580013
*        IGNORED BY THE NEXT PHASE                                      11610013
*              2) X'FE' ENTRIES.THESE CONTAIN INFORMATION FROM A        11640013
*        DICTIONARY ENTRY WHICH MUST BE REPLACED. ITEM IS 6 BYTES LONG  11670013
*              3)'JMP' ENTRIES. THESE CONTAIN THE TEXT REFERENCE OF     11700013
*        THE NEXT INSTRUCTION TO BE INSERTED.                           11730013
*              4) END OF BLOCK MARKER. THE NEXT INSTRUCTION IS AT THE   11760013
*        START OF THE TEXT BLOCK CHAINED TO THE CURRENT ONE.            11790013
*              5) END OF ADDRESSING STREAM MARKER                       11820013
*          THE TEXT REFERENCE OF THE START OF THE ADDRESSING STREAM IS  11850013
*        IN THE THIRD,FOURTH AND FIFTH BYTES OF THE SPECIAL  ADI        11880013
*        INSTRUCTION WHICH IS PLACED AT THE PROLOG INSERTION POINT. THI 11910013
*        SPECIAL ADI HAS X'20' IN ITS SECOND BYTE.                      11940013
*                                                                       11970013
*                                                                       12000013
*                                                                       12000415
*                                                                       12000815
*              ALTERATIONS AND ADDITIONS FOR LIST PROCESSING.           12001215
*                                                                       12001615
*                                                                       12002015
*              RA FINDS A DICTIONARY REFERENCE AND CALLS DRTEST (RB) AS 12002415
*        USUAL.  IF THE REFERENCE IS TO A BASED VARIABLE IT MUST BE     12002815
*        ADDRESSED VIA ITS POINTER.  IN THE SIMPLEST CASE, ALL THAT IS  12003215
*        REQUIRED IS A LOAD FROM THE POINTER INTO A BASE REGISTER.  IF  12003615
*        THE VARIABLE IS AN ELEMENT OF AN ARRAY OR STRUCTURE, THE       12004015
*        POINTER HOLDS THE ADDRESS OF THE FIRST BYTE OF STORAGE         12004415
*        OCCUPIED BY THE AGGREGATE.  A FURTHER ADD INTO THE BASEFROM    12004815
*        THE VARIABLE'S SKELETON DOPE VECTOR ADDRESS THE VIRTUAL ORIGIN 12005215
*        OF AN ARRAY OR THE ELEMENT OF A STRUCTURE                      12005615
*              THESE INSTRUCTIONS ARE NOT SET UP AS ORDINARY ADI'S      12006015
*        SINCE THE POINTER OR SKDV MAY THEMSELVES REQUIRE ADDRESSING.   12006415
*        INSTEAD, IF THE SKDV DOES NOT REQUIRE ANY QDDRESSING INSTRUC-  12006815
*        TIONS (I.E. IT IS WITHIN 4K OF THE START OF STATIC), A         12007215
*        SKELETON, LDPTR, IS SET UP AS FOLLOWS:                         12007615
*                       SPECIAL MARKER                                  12008015
*                       LOAD FROM POINTER                               12008415
*                       SPECIAL MARKER, OR END MARKER                   12008815
*                       ADD FROM SKDV                                   12009215
*                       END MARKER                                      12009615
*                                                                       12010015
*              IF AN ADD FROM THE SKDV IS NOT REQUIRED, THE SECOND      12010415
*        SPECIAL MARKER IS REPLACED BY AN END MARKER.                   12010815
*              THE INPUT POINTER IS SET TO POINT TO THE START OF        12011215
*        THE SKELETON AND CONTROL RETURNED TO RA.                       12011615
*                                                                       12012015
*              RA FINDS A SPECIAL MARKER AND CONVERTS THE FOLLOWING     12012415
*        INSTRUCTION TO ADI FORM.  DRTEST IS CALLED TO ADDRESS THE POI- 12012815
*        NTER BEFORE THE INSTRUCTION IS PUT OUT, AS HAPPENS FOR NORMAL  12013215
*        INPUT.  THE ADI'S FOR THE BASED VARIABLE, THEREFORE, APPEAR AS 12013615
*        A CONTINUOUS STREAM WHICH MAY INCLUDE POINTER ADDRESSING       12014015
*        ADI'S.                                                         12014415
*              ON FINDING THE END MARKER, RA RESETS THE INPUT POINTER   12014815
*        AND CONTINUES   AS BEFORE.                                     12015215
*              IF THE SKDV REQUIRES ADDRESSING INSTRUCTIONS TO SET A    12015615
*        BASE REGISTER WITHIN 4K OF IT, A DIFFERENT REGISTER MUST BE    12016015
*        USED FROM THAT WHICH WILL EVENTUALLY ADDRESS THE BASED         12016415
*        VARIABLE. (OTHERWISE, AN INTERMEDIATE VALUE WILL BE LOST).     12016815
*        THEREFORE, A CONTINUOUS STREAM OF ADI'S CANNOT BE USED. IN     12017215
*        THIS CASE, DRTEST PUTS OUT ONE OF TWO SKELETONS, INTB1 OR      12017615
*        INTB2 (SEE DC'S IN IEMRC) TO ADDRESS THE SKDV.  THE INITIAL    12018015
*        CODE BYTE OF THE SKELETONS TELLS RF TO CREATE A BASE AND SAVE  12018415
*        IT FOR LATER USE.  THE CODE BYTE FOR ADD IN SKELETON, LDPTR,   12018815
*        IS REPLACED BY A SPECIAL MARKER TO TELL RF TO USE THE BASE     12019215
*        IT  HAS RECENTLY SAVED.                                        12019615
*              AFTER THE SKDV ADI'S HAVE BEEN GENERATED, LDPTR IS SCAN- 12020015
*        NED AS DESCRIBED ABOVE.                                        12020415
*                                                                       12020815
*                                                                       12021215
*              A REFERENCE TO A BASED VARIABLE'S DOPE VECTOR IS TO BE   12021615
*        TREATED BY RA AS A REFERENCE TO THE SKELETON DOPE VECTOR.      12022015
*        DRTEST SUBSTITUTES THE (D.R.+1) FOR THE DOPE VECTOR WITH THE   12022415
*        DICTIONARY REFERENCE OF THE SKDV. AND RE-ENTERS ITSELF TO      12022815
*        ADDRESS THE SKDV NORMALLY.                                     12023215
*                                                                       12023615
*                                                                       12024015
*                                                                       12030013
*              EXTERNAL ROUTINES                                        12060013
*                           1) DRTEST IN IEMRB. PROCESSES A DICTIONARY  12090013
*        REFERENCE IT IS PASSED AND PRODUCES ANY NECESSARY ADDRESSING   12120013
*        INSTRUCTIONS.                                                  12150013
*                           2) THE FOLLOWING ROUTINES IN IEMAA ARE USED 12180013
*                  ZUGC TO GET SCRATCH CORE                             12210013
*                  ZUTXTC TO GET A NEW TEXT BLOCK                       12240013
*                  ZURC TO RELEASE SCRATCH CORE                         12270013
*                  ZLOADW  TO LOAD AND WAIT ON A MODULE                 12300013
*                  ZDICRF TO MAKE A DICTIONARY ENTRY AND RETURN A       12330013
*                                                         REFERENCE     12360013
*                  ZDRFAB TO CONVERT A DICTIONARY REFERENCE TO ABSOLUTE 12390013
*                  RLSCTL TO RELEASE CONTROL OF IEMRA AND IEMRB, AND    12420013
*        PASS CONTROL TO IEMRF                                          12450013
*                  ZTXTRF TO CONVERT A TEXT ADDRESS TO A REFERENCE      12480013
*                  ZTXTAB TO CONVERT A TEXT REFERENCE TO ABSOLUTE       12510013
*                  ZCHAIN TO CHAIN FROM ONE TEXT BLOCK TO NEXT          12540013
*                  ZALTER TO CHANGE STATUS OF TEXT BLOCK                12570013
*                                                                       12600013
*                                                                       12630013
*                                                                       12660013
*              EXIT-NORMAL   AT  ACT8A ON COMPLETION OF SCANNING INPUT  12690013
*                                                                       12720013
*                                                                       12750013
*                                                                       12780013
*              EXIT-ERROR    ON FINDING A LOGICAL ERROR IN THE INPUT    12810013
*        THE ERROR IS SIGNALLED BY EXECUTING  BAL  R4,ERROR. ERROR IS   12840013
*        A ZERO LOCATION WHICH CAUSES AN INTERRUPT, AND DUMP. THE       12870013
*        ADDRESS IN REGISTER 4 GIVES THE LOCATION IN THE PHASE WHERE    12900013
*        THE ERROR WAS DETECTED. THESE STOPS SHOULD NEVER OCCUR. IF     12930013
*        THEY DO, THIS TYPE OF STOP IS PREFERABLE TO A ZABORT SINCE     12960013
*        REGISTERS ARE PRESERVED                                        12990013
*                                                                       13020013
*                                                                       13050013
*              TABLES/WORK AREAS  ARE DESCRIBED WITH THE STORAGE THEY   13080013
*        OCCUPY AT THE END OF THE PHASE                                 13110013
*                                                                       13140013
*                                                                       13170013
*                                                                       13200013
*              ATTRIBUTES   THIS MODULE IS NOT REUSABLE                 13230013
*                                                                       13260013
*                                                                       13290013
*                                                                       13320013
*              NOTES   REGISTER USE IS GIVEN IN THE EQU'S AT THE HEAD   13350013
*        OF THE PHASE                                                   13380013
*                      THE OPERATION OF THIS MODULE DOES NOT DEPEND     13410013
*        UPON A PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL      13440013
*        CHARACTER SET.                                                 13470013
         EJECT                                                          13472001
*              ALTERATIONS TO PHASE RA FOR VERSION 5.                   13474001
         SPACE 2                                                        13476001
*        1)    RC HAS BEEN REORGANISED, AND ROUTINES IN RC ARE          13478001
*        BRANCHED TO BY A TRANSFER VECTOR HELD IN RC. LABELS            13480001
*        REFERENCED IN RA HAVE BEEN RE-EQUATED.                         13482001
         SPACE 1                                                        13484001
*        2)    A SECTION OF CODE HAS BEEN REMOVED FROM THE              13486001
*        INITIALISATION CODE, AND MADE INTO A ROUTINE, 'GETSCR'         13488001
*        IN RC.                                                         13490001
         SPACE 1                                                        13492001
*        3)    THE ACTION FOR DROP AND DRPL PSEUDO-CODE ITEMS HAVE      13494001
*        BEEN ALTERED TO TEST FOR MULTIPLE DROPS.                       13496001
         SPACE 1                                                        13498001
*        4)    A NEW PSEUDO-CODE ITEM, MDRP, HAS BEEN CATERED FOR.      13500001
         SPACE 1                                                        13502001
*        5)    THE PSEUDO-CODE ITEMS BXLE AND BXH WERE NOT PREVIOUSLY   13504001
*        USED. THESE ARE NOW ALLOWED, WITH AN EQU VALUE IN THE          13506001
*        SECOND OPERAND.                                                13508001
         SPACE 1                                                        13510001
*        6)    THE NUMBER OF EQUS GENERATED IN THE COMPILATION          13512001
*        IS CHECKED TO BE LESS THAN 16K.                                13514001
         EJECT                                                          13516001
IEMRA    START 0                                                        13530013
RA       EQU   IEMRA                                                    13560013
         USING *,R10                                                    13590013
RB       EQU   *+4096         THIS IS A TRICK THAT IS USED BECAUSE      13620013
         USING RB,R12       DSECTS ARE UNAVAILABLE                      13650013
COMREG   EQU   *+8192                                                   13680013
         USING COMREG,R11                                               13710013
DB       EQU   *+12288                                                  13740013
         USING DB,R13                                                   13770013
RC       EQU   *+16384                                                  13800013
         USING RC,RCBASE                                                13830013
         EJECT                                                          13860013
*              THE COMPLETE LIST OF QUANTITIES EQUATED WITH CONSTANTS   13890013
*        FOLLOWS. IF ONE OF THESE CONSTANTS CHANGES IT IS ALWAYS        13920013
*        SUFFICIENT JUST TO CHANGE THE RELEVANT EQU CARD                13950013
         SPACE 3                                                        13980013
*              REGISTER USAGE                                           14010013
         SPACE                                                          14040013
*                   CONTENTS OF REGISTER           DOMAIN OF USAGE      14070013
         SPACE                                                          14100013
R0       EQU   0    ALWAYS CONTAINS ZERO               THROUGHOUT       14130013
SP       EQU   1    SOURCE POINTER                     OUTSIDE DRTEST   14160013
OP       EQU   1    POINTER TO CURRENT DICT. ENTRY    DURING STEP-TABLE 14190013
*                                                   BUILDING IN DRTEST  14220013
OFT      EQU   1    VALUE OF OFFSET                   AFTER  STEP-TABLE 14250013
*                                                   BUILDING IN DRTEST  14280013
LBRA     EQU   1    REGISTER IN LIBRARY CALLING SEQUENCE.               14310013
R2       EQU   2    PARAMETER AND WORKING REGISTER     THROUGHOUT       14340013
R3       EQU   3    PARAMETER AND WORKING REGISTER     THROUGHOUT       14370013
R4       EQU   4    PARAMETER AND WORKING REGISTER     THROUGHOUT       14400013
R5       EQU   5    WORKING REGISTER                   OUTSIDE DRTEST   14430013
TP       EQU   5    STEP-TABLE POINTER                 IN DRTEST        14460013
IP       EQU   6    INSERTION FILE POINTER             THROUGHOUT       14490013
DP       EQU   7    WORKING REGISTER, USUALLY A        THROUGHOUT       14520013
*                   DICTIONARY POINTER                                  14550013
RCBASE   EQU   8                                                        14580013
CNP      EQU   9    POINTER TO CREATED INSTRUCTION     SECOND HALF OF   14610013
*                   IN SCRATCH CORE                    DRTEST           14640013
SCP      EQU   9    STACK POINTER                      OUTSIDE SECOND   14670013
*                                                      HALF OF DRTEST   14700013
R10      EQU   10   PROGRAM BASE                       THROUGHOUT       14730013
R11      EQU   11   POINTER TO COMPILER CONTROL REGION THROUGHOUT       14760013
R12      EQU   12   SECOND PROGRAM BASE                THROUGHOUT       14790013
R13      EQU   13   POINTER TO COMMUNICATIONS REGION   THROUGHOUT       14820013
R14      EQU   14   LINK REGISTER                      THROUGHOUT       14850013
RR       EQU   R14  PSEUDONYM FOR R14                  THROUGHOUT       14880013
R15      EQU   15   DESTINATION ADDRESS REGISTER       THROUGHOUT       14910013
LR       EQU   R15  PSEUDONYM FOR R15                  THROUGHOUT       14940013
         SPACE 3                                                        14970013
*              OFFSETS OF FIELDS IN DICTIONARY ENTRIES                  15000013
         SPACE                                                          15030013
ELABTV   EQU   5         POINTER TO TRANSFER VECTOR IN ENTRY LABEL      15060013
*                      ENTRY                                            15090013
E1DSA    EQU   25        SIZE OF DSA IN ENTRY TYPE 1                    15120013
E1LEV    EQU   3         LEVEL NUMBER OF ENTRY TYPE 1                   15150013
E1SYM    EQU   23        REFERENCE TO SYMBOL TABLE ENTRY OF ENTRY TYPE1 15180013
E18AD    EQU   28        OFFSET OF ADDRESSING VECTOR IN ENTRY TYPE 1    15210013
E1RTSW   EQU   34        OFFSET OF RETURN SWITCH FOR ENTRY TYPE 1       15240013
E1RET    EQU   37        OFFSET OF RETURN POINTER FOR ENTRY TYPE 1      15270013
E1WSPR   EQU   13        OFFSET OF DICTIONARY REFERENCE OF FIRST        15300013
*                      WORKSPACE ENTRY IN AN ENTRY TYPE 1.              15330013
E1PSTO   EQU   19        SLOT IN ENTRY TYPE 1 WHERE SIZE OF PRIVATE     15360013
*                      STORAGE IS STORED BETWEEN PHASES                 15390013
BE1OPT   EQU   55                                                       15400015
PE1OPT   EQU   63                      DISPLACEMENT OF OPT. BYTE        15410015
E1T2WK   EQU   60                                                       15420015
B1T2WK   EQU   52                                                       15450015
E1CHB    EQU   59                                                       15480015
*                      OPTIONS CHANGED BYTE.                            15510013
STNLBL   EQU   8         OFFSET OF STATEMENT NUMBER IN LABEL            15540013
E1PRLS   EQU   43        OFFSET IN PROCEDURE ENTRY TYPE 1 OF LIST OF    15570013
*                      DICTIONARY REFERENCES TO PREFIX OPTIONS.         15600013
BE1PRL   EQU   35        AS ABOVE BUT FOR BEGIN ENTRY TYPE 1.           15630013
E2DED    EQU   12        REFERENCE TO DED OF ENTRY TYPE 2               15660013
E3E1     EQU   3         REFERENCE TO ENTRY TYPE 1 FROM ENTRY TYPE 3    15690013
E3E2     EQU   5         REFERENCE TO ENTRY TYPE 2 FROM ENTRY TYPE 3    15720013
E3RET    EQU   7         OFFSET OF RETURNED VALUE IN ENTRY TYPE 3       15750013
E4ADCN   EQU   5         OFFSET OF LOAD CONSTANT IN ENTRY TYPE 4 OR 5   15780013
E4RET    EQU   8         OFFSET FOR RETURNED VALUE IN ENTRY TYPE 4 OR 5 15810013
E4DED    EQU   18        REFERENCE TO DED FOR ENTRY TYPE 4 OR 5         15840013
LABOFF   EQU   5         OFFSET OF LOAD CONSTANT FOR LABEL CONSTANT     15870013
OTH1LB   EQU   10        OFFSET OF OTHER1 CODE BYTE IN LABEL CONSTANT   15900013
DOFF     EQU   5         FIRST OFFSET SLOT FOR DATA VARIABLE, LABEL     15930013
*                      VARIABLE OR STRUCTURE                            15960013
DHASH    EQU   3         HASH CHAIN FOR ABOVE TYPES OF ENTRY            15990013
DDECNO   EQU   8         DECLARE NUMBER FOR ABOVE                       16020013
DOTH1    EQU   10        OTHER 1 BYTE FOR ABOVE                         16050013
DOTH2    EQU   DOTH1+2   OTHER 2 BYTE FOR ABOVE                         16080013
DOTH3    EQU   DOTH1+3   OTHER 3 BYTE FOR ABOVE                         16110013
DOTH4    EQU   DOTH1+4   OTHER 4 BYTE FOR ABOVE                         16140013
DVAR     EQU   DOTH1+1   VARIABLE BYTE FOR ABOVE                        16170013
DDAT     EQU   DOTH1+5   DATA BYTE FOR DATA VARIABLE                    16200013
DDED     EQU   19        REFERENCE TO DED FOR DATA VARIABLE             16230013
DVARIN   EQU   21        VARIABLE INFORMATION FOR DATA VARIABLE         16260013
SVARIN   EQU   15        VARIABLE INFORMATION FOR STRUCTURE OR LABEL    16290013
*                      VARIABLE                                         16320013
         SPACE 3                                                        16350013
*              OFFSETS OF FIELDS IN STACK ENTRY FOR A BLOCK             16380013
         SPACE                                                          16410013
BLSTSZ   EQU   38                      SIZE OF STACK ENTRY              16440015
BLSTAT   EQU   7         SIZE OF STACK ENTRY FOR STATIC ADDRESSING      16470013
         SPACE                                                          16500013
STCHNB   EQU   0         OFFSET OF OPTIONS CHANGE BYTE                  16530013
STW2OF   EQU   1         OFFSET OF OFFSET TO WORKSPACE 2.               16560013
STADOF   EQU   2         OFFSET OF ADDRESSING VECTOR                    16590013
STCHD    EQU   4         HEAD OF ADDRESSING CHAIN                       16620013
STPSTO   EQU   7         VALUE OF PSTOR                                 16650013
STJMP    EQU   9         TEXT REFERENCE TO 'JMP' INSTRUCTION            16680013
STE1RF   EQU   12        REFERENCE TO ENTRY TYPE 1                      16710013
STNLEV   EQU   14        VALUE OF NLEVEL                                16740013
STLEV    EQU   15        LEVEL NUMBER                                   16770013
STBLOC   EQU   STLEV+1   BLOCK NUMBER (MUST BE CONTIGUOUS WITH LEVEL    16800013
*                      NUMBER)                                          16830013
STCURR   EQU   17        OFFSET OF STACKED CURRENT OPTIONS BYTE         16860013
STPRLS   EQU   18        OFFSET OF STACKED LIST OF DICTIONARY REFERENC- 16890013
*                     -ES TO PREFIX OPTIONS.                            16920013
STWSP    EQU   34                  OFFSET TO STACKED DICT REF TO 1ST    16950015
*                                  WORK SPACE REQUIREMENT               16980015
STWSP3   EQU   36             OFFSET TO STACKED DICTIONARY REFERENCE TO 17010015
*                      THIRD WORKSPACE REQUIREMENT.                     17040013
         SPACE 3                                                        17070013
*              NAMES OF REGISTERS USED IN GENERATED CODE                17100013
         SPACE                                                          17130013
PRVP     EQU   12             PSEUDO-REGISTER VECTOR POINTER            17160013
ADP      EQU   13             AUTOMATIC DATA POINTER                    17190013
SDP      EQU   11             STATIC DATA POINTER                       17220013
R1       EQU   1              REGISTER ONE                              17250013
PREG     EQU   9              PRIVATE STORAGE POINTER                   17280013
PBREG    EQU   10             PROGRAM BASE                              17310013
         SPACE 3                                                        17340013
*              ENTRY POINT FOR DRTEST ROUTINE                           17370013
         SPACE                                                          17400013
DRTEST   EQU   RB+2                                                     17430013
         SPACE 3                                                        17460013
*              OFFSETS OF ADCONS OF COMPILER CONTROL ROUTINES           17490013
         SPACE                                                          17520013
ZUGC     EQU   COMREG+X'10'                                             17550013
STNOFF   EQU   8         STATEMENT NUMBER IN A DATUM OR LABEL ENTRY     17580013
ZUTXTC   EQU   COMREG+X'14'                                             17610013
ZURC     EQU   COMREG+X'18'                                             17640013
ZABORT   EQU   COMREG+X'20'                                             17670013
ZLOADW   EQU   COMREG+X'24'                                             17700013
ZDICRF   EQU   COMREG+X'2C'                                             17730013
LOADW    EQU   ZLOADW                                                   17760013
ZUERR    EQU   COMREG+X'30'                                             17770001
ZDRFAB   EQU   COMREG+X'34'                                             17790013
ZDUMP    EQU   COMREG+X'38'                                             17820013
REQEST   EQU   COMREG+X'40'                                             17850013
RELESE   EQU   COMREG+X'44'                                             17880013
RLSCTL   EQU   COMREG+X'48'                                             17910013
ZTXTRF   EQU   COMREG+X'50'                                             17940013
ZTXTAB   EQU   COMREG+X'54'                                             17970013
ZCHAIN   EQU   COMREG+X'58'                                             18000013
ZALTER   EQU   COMREG+X'5C'                                             18030013
ZEND     EQU   COMREG+X'6C'                                             18060013
         SPACE 3                                                        18090013
*              OFFSETS OF QUANTITIES IN COMMUNICATIONS REGION FOR       18120013
*        PROTIOS VERSION                                                18150013
         SPACE                                                          18180013
ZTV      EQU   DB+64                                                    18210013
ZMYNAM   EQU   DB+112                                                   18240013
ZSTAT    EQU   DB+126                                                   18270013
PAR1     EQU   DB+128                                                   18300013
PAR2     EQU   PAR1+4                                                   18330013
PAR5     EQU   PAR1+16                                                  18340001
ZOPT     EQU   DB+196                                                   18350001
CCCODE   EQU   DB+232                                                   18360013
STARTX   EQU   DB+256                                                   18390013
TXTSZ    EQU   DB+264                                                   18420013
LOCK     EQU   DB+274                                                   18450013
ZCOMM    EQU   DB+304                                                   18480013
ZFLAG4   EQU   ZCOMM+19                                                 18510013
ZSMREG   EQU   ZCOMM+42                                                 18540013
ZSTACH   EQU   ZCOMM+68                                                 18570013
ZEQMAX   EQU   ZCOMM+82                                                 18600013
SIBFNM   EQU   ZCOMM+0                                                  18630013
EXSTAT   EQU   ZCOMM+48                                                 18660013
M91BYT   EQU   DB+X'BC'                                                 18690013
M91BIT   EQU   1                                                        18720013
         SPACE 3                                                        18750013
*              OP. CODES FOR MACHINE INSTRUCTIONS AND PSEUDO-INST-      18780013
*        RUCTIONS                                                       18810013
         SPACE                                                          18840013
*              MACHINE INSTRUCTIONS                                     18870013
         SPACE                                                          18900013
MCA      EQU   X'8A'          A                                         18930013
MCS      EQU   X'8B'          S                                         18960013
MCST     EQU   X'A5'          ST                                        18990013
MCL      EQU   X'88'          L                                         19020013
MCSLL    EQU   X'74'          SLL                                       19050013
MCLA     EQU   X'A0'          LA                                        19080013
MCAH     EQU   X'92'          AH                                        19110013
MCBXLE   EQU   X'7B'          BXLE                                      19140013
MCAR     EQU   X'4A'          AR                                        19170013
MCLCR    EQU   X'40'          LCR                                       19200013
MCLR     EQU   X'48'          LR                                        19230013
MCBC     EQU   X'81'          BC                                        19260013
MCNI     EQU   X'B2'          AND IMMEDIATE                             19290013
MCOI     EQU   X'B3'          OR  IMMEDIATE                             19320013
MCLAP    EQU   X'B7'          LA OF EQU VALUE                           19350013
MCBAL    EQU   X'8F'          BAL                                       19380013
MCMVI    EQU   X'B1'          MVI                                       19410013
         SPACE                                                          19440013
*              PSEUDO-INSTRUCTIONS                                      19470013
         SPACE                                                          19500013
ADI      EQU   X'BE'          ADDRESSING INSTRUCTION FOR COMMUNICATION  19530013
*                           WITH NEXT PHASE                             19560013
BGNP     EQU   X'28'          BEGIN FOR PROLOGLESS BLOCK                19590013
BGNPP    EQU   X'29'          END OF PROLOGLESS BLOCK                   19620013
PSLD     EQU   X'2C'          ITEM FOR COMMUNICATION WITH LISTING PHASE 19650013
OSM1     EQU   X'10'          OSM1                                      19680013
OSM2     EQU   X'11'          OSM2                                      19710013
OSM3     EQU   X'BD'          OSM3                                      19740013
EOB      EQU   X'21'          END-OF-BUFFER MARKER                      19770013
EOP      EQU   X'0B'          END-OF-PROGRAM MARKER                     19800013
PIJMP    EQU   X'00'          PIJMP, PIEND AND PIINST ARE PSEUDO INST-  19830013
PIEND    EQU   X'01'        RUCTIONS FOR COMMUNICATION WITH THE NEXT    19860013
PIINS    EQU   X'02'        PHASE                                       19890013
ABS      EQU   X'2D'          DELIMETER AT START OF ABSOLUTE CODE       19920013
ABSP     EQU   X'2E'          DELIMETER AT END OF ABSOLUTE CODE         19950013
EQU      EQU   X'07'          INDICATES 'EQU' COMPILER LABEL            19980013
ADR      EQU   X'24'          INDICATES SPARE REGISTER FOR USE BY FINAL 20010013
*                           ASSEMBLY                                    20040013
DROP     EQU   X'06'          DROP                                      20070013
BLBSP    EQU   X'31'          BLBS'                                     20100013
SL       EQU   X'7C'                                                    20130013
SN       EQU   X'7D'                                                    20160013
CL       EQU   X'7E'                                                    20190013
EQUPR    EQU   X'BE'                   EQU'                             20220013
RWA      EQU   X'34'               DELEMITS THE ABSOLUTE CODE USED TO   20250013
*                            SET UP THE ADDRESSING VECTOR IN PRIVATE    20280013
*                                STORAGE.                               20310013
ALIGN    EQU   X'2F'          ALIGN TO FULL WORD                        20340013
IPRM     EQU   X'0D'          IPRM                                      20370013
IPRMP    EQU   X'1D'          IPRM'                                     20400013
DCF2     EQU   X'B8'          FULL WORD CONSTANT                        20430013
FMT      EQU   X'39'          REMOTE FORMAT ITEM                        20460013
IGN5     EQU   X'FE'                                                    20490046
         SPACE 3                                                        20520013
*              BRANCH MNEMONICS                                         20550013
         SPACE                                                          20580013
B        EQU   15                                                       20610013
BH       EQU   2                                                        20640013
BL       EQU   4                                                        20670013
BE       EQU   8                                                        20700013
BNH      EQU   13                                                       20730013
BNL      EQU   11                                                       20760013
BNE      EQU   7                                                        20790013
BO       EQU   1                                                        20820013
BP       EQU   2                                                        20850013
BM       EQU   4                                                        20880013
BZ       EQU   8                                                        20910013
BNZ      EQU   7                                                        20940013
BNM      EQU   11                                                       20970013
BNO      EQU   14                                                       20980015
NOP      EQU   0                                                        21000013
         SPACE 3                                                        21030013
*              SETTINGS OF SWITCHES                                     21060013
         SPACE                                                          21090013
ON       EQU   X'FF'                                                    21120013
OFF      EQU   0                                                        21150013
         SPACE 3                                                        21180013
*              MASKS FOR TM AND LOGICAL INSTRUCTIONS                    21210013
         SPACE                                                          21240013
BIT0     EQU   X'80'                                                    21270013
BIT1     EQU   X'40'                                                    21300013
BIT2     EQU   X'20'                                                    21330013
BIT3     EQU   X'10'                                                    21360013
BIT4     EQU   X'08'                                                    21390013
BIT5     EQU   X'04'                                                    21420013
BIT6     EQU   X'02'                                                    21450013
BIT7     EQU   X'01'                                                    21480013
BITS01   EQU   X'C0'                                                    21510013
BITS67   EQU   X'03'                                                    21540013
BITS12   EQU   X'60'                                                    21570013
BIT456   EQU   X'0E'                                                    21600013
ALLZRO   EQU   X'00'                                                    21630013
ALLONE   EQU   X'FF'                                                    21660013
NOTB0    EQU   X'7F'                                                    21690013
         SPACE 3                                                        21720013
*              SETTINGS OF STATUS OF BUFFERS FOR ZALTER ETC.            21750013
         SPACE                                                          21780013
WANTED   EQU   X'03'     WANTED                                         21810013
FREE     EQU   X'01'     FREE                                           21840013
UNWANT   EQU   X'02'     UNWANTED                                       21870013
BUSY     EQU   X'04'     BUSY                                           21900013
CWANT    EQU   X'83'     CHAIN AND MARK WANTED                          21930013
CUNWAN   EQU   X'82'     CHAIN AND MARK UNWANTED                        21960013
         SPACE 3                                                        21990013
*              MISCELLANEOUS                                            22020013
         SPACE                                                          22050013
FILL     EQU   0         INDICATOR TO SHOW THAT A FIELD IS TO BE OVER-  22080013
*                      WRITTEN                                          22110013
S4096    EQU   0         OFFSET IN STATIC OF CONSTANT 4096              22140013
PET1     EQU   X'80'     PROCEDURE ENTRY TYPE 1 CODE BYTE.              22170013
EET1     EQU   X'82'     'ENTRY' ENTRY TYPE 1                           22200013
ZSTCD    EQU   X'50'     CODE BYTE IN ENTRY AT ZSTACH                   22230013
NDVBIT   EQU   BIT0      'NEEDS DOPE VECTOR BIT' IN OTHER3 BYTE         22260013
CHKBIT   EQU   X'20'     CHECK BIT IN OTHER1 CODE BYTE IN LABEL         22290013
*                      CONSTANT                                         22320013
MVILTH   EQU   8         LENGTH OF MVI INSTRUCTION USED TO UPDATE THE   22350013
*                      STATEMENT NUMBER SLOT IN THE DSA.                22380013
DVDBIT   EQU   X'10'                   DVD ENTRY EXISTS                 22410013
RDVBIT   EQU   X'01'                   RDV ENTRY EXISTS.                22440013
MAJSTR   EQU   BIT5                    MAJOR STRUCTURE                  22470013
         SPACE 3                                                        22500013
*              VALUES OF SWITCH CODES IN TRANSLATE TABLE. (THESE VALUES 22530013
*        SHOULD NOT BE CHANGED WITHOUT CHANGING THE ORDER OF THE BRANCH 22560013
*        INSTRUCTIONS FOLLOWING THE 'TRT' )                             22590013
         SPACE                                                          22620013
XA       EQU   4         THREE-BYTE ITEM NOT REQUIRING SPECIAL ACTION   22650013
XB       EQU   8         FIVE-BYTE ITEM NOT REQUIRING SPECIAL ACTION    22680013
XC       EQU   12        RX OR SI INSTRUCTION WHICH MAY INVOLVE A DICT- 22710013
*                      IONARY REFERENCE                                 22740013
XS       EQU   16        SS INSTRUCTION                                 22770013
XL       EQU   20        END-OF-BUFFER MARKER                           22800013
XF       EQU   24        PROCEDURE OR BEGIN                             22830013
XG       EQU   28        END OF BLOCK OR PROCEDURE                      22860013
XH       EQU   32        END-OF-PROGRAM MARKER                          22890013
XI       EQU   36        PLBS                                           22920013
XJ       EQU   40        END OF PROLOG (PCBS OR BGPE)                   22950013
XK       EQU   44        IGNORE ITEM                                    22980013
XE       EQU   48        ILLEGAL ITEM                                   23010013
XM       EQU   52        ABSOLUTE CODE                                  23040013
XN       EQU   56        PROLOG INSERTION POINT (PINS OR BLBS')         23070013
XO       EQU   60        SN                                             23100013
XP       EQU   64        SL                                             23130013
XQ       EQU   68        CL                                             23160013
XR       EQU   72        PLBS'                                          23190013
XU       EQU   76        CALL TO ERROR                                  23220013
XT       EQU   80        END OF CALL TO ERROR                           23250013
XV       EQU   84        SN2                                            23280013
XW       EQU   88        PCC                                            23310013
XX       EQU   92        FMT                                            23340013
XY       EQU   96        FMT'                                           23370013
         SPACE 10                                                       23400013
*              SWITCH FOR TRANSLATE TABLE FOR DICTIONARY ITEMS          23430013
YA       EQU   8         DATA ITEM                                      23460013
YB       EQU   12        STRUCTURE OR LABEL, TASK OR EVENT VARIABLE     23490013
YC       EQU   16        ENTRY TYPE1                                    23520013
YD       EQU   20        ENTRY TYPE2                                    23550013
YE       EQU   4         ERROR -- ITEM THAT SHOULD NOT BE REFERENCED    23580013
*                      IN THE TEXT.                                     23610013
YF       EQU   24        ENTRY TYPE3                                    23640013
YG       EQU   28        ENTRY TYPE4                                    23670013
YH       EQU   32        ENTRY TYPE5                                    23700013
YK       EQU   40        DATA CONSTANT                                  23730013
YL       EQU   44        LABEL CONSTANT                                 23760013
YM       EQU   52        DOPE VECTOR FOR STRING TEMPORARY               23790013
YN       EQU   56        REFERENCE TO ZSTACH                            23820013
YP       EQU   60        INVOCATION COUNT                               23850013
YQ       EQU   64        FILE CONSTANT                                  23880013
YR       EQU   68        ON CONDITION ENTRY                             23910013
YS       EQU   72        WORKSPACE REQUIREMENT                          23940013
YT       EQU   36        STATIC ITEM REQUIRING CODE OF ZERO             23970013
YJ       EQU   48        COMPILER LABEL                                 24000013
YY       EQU   76        RDV ENTRY                                      24030013
         EJECT                                                          24060013
*              PHASE INITIALIZATION AND TRANSFER VECTOR                 24090013
         SPACE 3                                                        24120013
PHASRA   DC    C'RA'                                                    24150013
         L     R10,PAR1                                                 24180013
         BC    B,LLOAD                                                  24210013
         CNOP  0,4                                                      24240013
         SPACE 5                                                        24270013
*              TRANSFER VECTOR                                          24300013
         SPACE                                                          24330013
*        THESE ARE THE BRANCH-IN POINTS FOR ROUTINES IN THIS CONTROL    24360013
*        SECTION THAT ARE CALLED FROM THE SECOND CONTROL SECTION        24390013
         SPACE                                                          24420013
         BC    B,RELIBF                                                 24450013
         BC    B,ADINST                                                 24480013
         BC    B,ADIBUF                                                 24510013
         BC    B,ADCBUF                                                 24540015
         BC    B,PTRCDE                                                 24580015
         SPACE                                                          24600013
*        DATA  COMMON TO BOTH CONTROL SECTIONS                          24630013
         SPACE                                                          24660013
CURPTR   EQU   RC+600                  CONTAINS OUTPUT POINTER          24690013
BWDPTR   EQU   CURPTR+4                 POINTER TO WHERE CURRENT BASE   24720013
BSECNT   EQU   BWDPTR+4              WORD IS TO GO AND COUNT OF BITS    24750013
*                                    LEFT IN CURRENT BASE WORD          24780013
BWDCDE   EQU   BSECNT+3                BASE WORD CODE BYTE              24810013
BSEWRD   EQU   BWDCDE+1                BASE WORD                        24840013
DRADD    EQU   BSEWRD+4                                                 24870013
OFTMP    EQU   DRADD+4                                                  24900013
CNPMIN   EQU   OFTMP+4                                                  24930013
CNPMAX   EQU    CNPMIN+4 MAXIMUM VALUE OF CNP BEFORE SCRATCH OVERFLOW   24960013
SCRST    EQU   CNPMAX+4  POINTS TO FIRST BYTE OF SCRATCH                24990013
SCPMAX   EQU   SCRST+4   MAXIMUM VALUE OF SCP BEFORE STACK OVERFLOW     25000001
CBFMAX   EQU   SCPMAX+4                                                 25007046
IBFMAX   EQU   CBFMAX+4                                                 25014046
BVENV    EQU   IBFMAX+4                                                 25021046
ADSLOT   EQU   BVENV+8                                                  25030015
PSTOR    EQU   ADSLOT+2  SIZE OF PRIVATE STORAGE FOR CURRENT BLOCK      25050013
MDRPCT   EQU   PSTOR+2                  COUNT OF ITEMS IN MDRP TABLE    25070001
OSMSKT   EQU   MDRPCT+2            SPACE FOR BUILDING OSM1 OR OSM2      25090001
ADSLT1   EQU   OSMSKT+5  STORAGE FOR STORED VALUES OF ADSLOT. TO BE     25110013
ADSLT2   EQU   ADSLT1+2 SED IN OSM1 OR OSM3.                            25140013
SPSW     EQU   ADSLT2+2  SWITCH ON IF SPECIAL SS INSTRUCTION.           25170013
OPNO     EQU   SPSW+1    SWITCH TO INDICATE OPERAND NUMBER.             25200013
GENFL    EQU   OPNO+1 )  SWITCHED ON IF EXTRA ITEMS REQUIRE GENERATION  25230013
*                      AFTER AN INSTRUCTION HAS BEEN OUTPUT             25260013
OSMFL    EQU   GENFL+1   SWITCHED ON IF AN OSM MUST BE GENERATED        25290013
SSFLG    EQU   OSMFL+1   SWITCHED ON FOR AN SS INSTRUCTION              25320013
OSMP     EQU   SSFLG+1   SWITCHED ON IF AN OSM1 OR OSM3 IS PRESENT      25350013
PROGSW   EQU   OSMP+1    SWITCHED ON IF IN THE PROLOG                   25380013
ILSW     EQU   PROGSW+1  SWITCHED ON IF IN-LINE CODE IS REQUIRED        25410013
FMTSW    EQU   ILSW+1 )  SWITCHED ON IF THE SCAN IS IN A REMOTE FORMAT  25440013
ADISKT   EQU   FMTSW+1   SKELETON 'ADI' INSTRUCTION. BIT INDICATING     25470013
CBUFNM   EQU   ADISKT+5                                                 25477046
IBUFNM   EQU   CBUFNM+3                                                 25484046
SBUFNM   EQU   IBUFNM+3                                                 25491046
CSTATE   EQU   SBUFNM+3                                                 25498046
LDPTR    EQU   CSTATE+1                                                 25505046
USASBS   EQU   LDPTR+14                                                 25514015
RXSAVE   EQU   USASBS+5                                                 25521015
RXINST   EQU   RXSAVE+5                                                 25523015
SSFLSV   EQU   RXINST+5                                                 25525015
OSMPSV   EQU   SSFLSV+1                                                 25527015
CCTAB    EQU   RC+2                                                     25530013
TRTAB    EQU   CCTAB+256                                                25560013
         SPACE 8                                                        25562001
*        TRANSFER VECTOR TO ROUTINES IN RC                              25564001
         SPACE 1                                                        25566001
SETSDR   EQU   TRTAB+256                                                25568001
CHKSK    EQU   SETSDR+4                                                 25570001
SCRTXT   EQU   CHKSK+4                                                  25572001
LMDRP    EQU   SCRTXT+4                                                 25574001
CHDRP    EQU   LMDRP+4                                                  25576001
EQUOFL   EQU   CHDRP+4                                                  25578001
GETSCR   EQU   EQUOFL+4                                                 25580001
BUMPOF   EQU   GETSCR+4                                                 25582001
RELTXT   EQU   BUMPOF+4                                                 25582221
DECOMP   EQU   RELTXT+4                                                 25582421
CHNSCN   EQU   DECOMP+4                                                 25582621
GETCBF   EQU   CHNSCN+4                                                 25582821
GETIBF   EQU   GETCBF+4                                                 25583021
GETSBF   EQU   GETIBF+4                                                 25583221
A4KRTN   EQU   GETSBF+4                                           41963 25583421
         EJECT                                                          25584001
         SPACE 5                                                        25590013
*              CONTINUATION OF INITIALIZATION CODE                      25620013
*                                                                       25650013
*              FUNCTION/OPERATION -  THIS SECTION OF CODE PERFORMS THE  25680013
*        FOLLOWING INITIALISATION TASKS.                                25710013
*                                1) SETS RA IN ZMYNAME                  25740013
*                                2) LOAD AND WAITS ON IEMRB AND LOADS   25770013
*        ITS BASE REGISTER.                                             25800013
*                                3) SAVES THE NAME OF THE FIRST INPUT   25830013
*        TEXT BLOCK AND SETS SP TO POINT AT ITS FIRST BYTE.             25860013
*                                4) ZEROISES REGISTER 0                 25890013
*                                5) GETS FOUR K OF SCRATCH AND SETS     25920013
*        POINTERS TO ITS START AND END                                  25950013
*                                6) MAKES AN INITIAL ENTRY,IN THE STACK 25980013
*        DESCRIBING CONTAING BLOCKS, TO REPRESENT STATIC.               26010013
*                                7) GETS A TEXT BLOCK FOR THE OUTPUT    26040013
*        FILE AND SAVES ITS NAME IN STARTX                              26070013
*                                6) GETS A TEXT BLOCK FOR THE INSERTION 26100013
*        FILE.                                                          26130013
*                                       9) GETS A SCRATCH TEXT BLOCK    26140001
*        FOR USE AS MDRP TABLE                                          26150001
*                                                                       26160013
*              ENTRY POINT - LLOAD   NO PARAMETERS. CONTROL ENTERS BY   26190013
*      A BRANCH AFTER LOADING IEMRA'S BASE WHEN CONTROL IS PASSED BY    26220013
*      IEMAA.                                                           26250013
*                                                                       26280013
*              EXTERNAL ROUTINES - 1) ZLOADW IN IEMAA TO LOAD IEMRB     26310013
*                                  2) ZTXTAB IN IEMAA TO CONVERT A      26340013
*      SYMBOLIC TEXT REFERENCE TO ABSOLUTE                              26370013
*                                  3) ZUGC IN IEMAA TO GET SCRATCH      26400013
*        CORE.                                                          26430013
*                                  4) GETCBUF IN IEMRA TO GET AN        26460013
*        OUTPUT BUFFER.                                                 26490013
*                                  5) GETIBUF IN IEMRA TO GET AN        26520013
*        INSERTION FILE.                                                26550013
*                                                                       26580013
*              EXIT NORMAL   AT EXIT1 ON COMPLETION OF ABOVE TASKS      26610013
*        BRANCH TO LA TO SCAN TEXT.                                     26640013
*                                                                       26670013
*              EXIT ERROR - IF 4K OF SCRATCH CANNOT BE OBTAINED BRANCH  26700013
*        TO CMPERR.                                                     26730013
*                                                                       26760013
*              TABLES/WORK AREAS - N/A                                  26790013
*                                                                       26820013
*              NOTES - REGISTER USAGE IS DESCRIBED IN PREVIOUS EQU'S.   26850013
*                                                                       26880013
*                                                                       26910013
LLOAD    MVC   ZMYNAM(2),PHASRA         SET NAME OF THIS PHASE IN       26940013
*                                     COMMUNICATIONS REGION             26970013
         LA    R4,RBNAM                 CALL ZLOADW TO LOAD SECOND      27000013
         ST    R4,PAR1                CONTROL SECTION OF THE PHASE      27030013
         L     R15,ZLOADW             AND SET R12 AS BASE REGISTER FOR  27060013
         BALR  R14,R15                IT                                27090013
         SPACE                                                          27120013
         L     R12,PAR1                                                 27150013
         LA    R4,RCNAM                                                 27180013
         ST    R4,PAR1                                                  27210013
         BALR  R14,R15                                                  27240013
         L     RCBASE,PAR1                                              27270013
         SPACE                                                          27300013
         SPACE                                                          27330013
         TM    ZFLAG4,X'40'            ARE THERE MORE THAN 255 STATE-   27360013
         BC    BO,*+8                BRANCH IF SO.                      27390013
         MVI   MODIFY,X'49'          OTHERWISE MODIFY LATER INSTR-      27420013
*                                    UCTION TO A CH SO THAT THE FIRST   27450013
*                                    BYTE OF THE STATEMENT NUMBER       27480013
*                                    IS NOT UNNECESSARILY UPDATED       27510013
*              IT IS NOW DECIDED WHETHER FLUSH INSTRUCTIONS FOR THE     27540013
*        MODEL 91 OPTION NEED BE GENERATED.  IN ORDER TO AVOID REPEATED 27570013
*        TESTING, FLOW IS ALTERED BY INSTRUCTION MODIFICATION.          27600013
*              FLUSH INSTRUCTIONS WILL BE REQUIRED AT EACH NEW STATE-   27630013
*        MENT IF THE STATEMENT NUMBER OPTION IS IN FORCE.  THEY WILL    27660013
*        BE REQUIRED ONLY WHEN PREFIX OPTIONS CHANGE, OTHERWISE.        27690013
*              INITIALLY THE CODE IS SET ASSUMING MODEL 91 AND STATE-   27720013
*        MENT NUMBER OPTIONS APPLY.                                     27750013
         SPACE 2                                                        27780013
         TM    M91BYT,M91BIT                                            27810013
         BC    BZ,STOPSN                                                27840013
         SPACE                                                          27870013
         TM    CCCODE+3,BIT0                                            27900013
         BC    BZ,STET                                                  27930013
         MVI   MOD1,X'45'              MODIFY LATER INSTRUCTION SO THAT 27960013
*                                    FLUSH INSTRUCTIONS ARE GENERATED B 27990013
*                                    BEFORE PREFIX OPTIONS CHANGE CODE  28020013
STOPSN   MVI   MOD2+1,X'F0'            MODIFY LATER INSTRUCTION SO THAT 28050013
*                                    FLUSH INSTRUCTIONS ARE NOT         28080013
*                                    GENERATED AT CHANGE OF ST. NO.     28110013
STET     EQU   *                                                        28140013
         SPACE                                                          28170013
         MVC   SBUFNM(3),STARTX+1       SET NAME OF FIRST SOURCE BUFFER 28200013
         L     R4,STARTX                                                28230013
         ST    R4,PAR1                  CONVERT REFERENCE TO FIRST BYTE 28260013
         L     R15,ZTXTAB            OF TEXT TO A POINTER AND STORE IT  28290013
         BALR  R14,R15                IN SP  (THIS CALL OF ZTXTAB MARKS 28320013
*                                     THE BUFFER AS BUSY)               28350013
         L     SP,PAR1                                                  28380013
         SPACE 3                                                        28450001
*        A SECTION OF CODE HAS BEEN REMOVED TO RC TO PROVIDE            28520001
*          MORE SPACE IN RA. THE CODE INITIALISES R0 AND GETS           28590001
*          4K OF SCRATCH CORE, SETTING VARIOUS POINTERS TO IT.          28660001
         SPACE 1                                                        28730001
         BAL   R14,GETSCR                                               28800001
         SPACE 1                                                        28870001
         SPACE                                                          28980013
*              NOW MAKE FIRST STACK ENTRY, WHICH CONTAINS INFORMATION   29010013
*        ABOUT ADDRESSING STATIC. THIS ENTRY HAS THE SAME FORMAT AS     29040013
*        THE BEGINNING OF A STACK ENTRY FOR A BLOCK. (STACK ENTRIES FOR 29070013
*        A BLOCK CONTAIN SIMILAR INFORMATION ABOUT ADDRESSING AUTOMATIC 29100013
*        FOR THAT BLOCK)                                                29130013
         SPACE                                                          29160013
         MVC   STADOF(2,SCP),H0         SET OFFSET OF ADDRESSING VECTOR 29190013
*                                     EMPTY                             29220013
         MVC   STCHD(3,SCP),ENDCHN    AS ZERO AND ADDRESSING CHAIN  AS  29250013
         LA    SCP,BLSTAT(SCP)          UPDATE STACK POINTER            29280013
         ST    SCP,STKST                SET STKST TO POINT AT STACK     29310013
*                                     ENTRY FOR OUTERMOST BLOCK         29340013
         SPACE                                                          29370013
*              NOW GET BUFFERS FOR OUTPUT FROM THE PHASE                29400013
         SPACE                                                          29430013
         MVI   CSTATE,X'00'             GET FIRST BUFFER FOR CREATED    29460013
         LA    R2,BWDCDE               SET R2 TO PREVENT GETCBF FROM    29490013
*                                    PUTTING OUT A BASE WORD.           29520013
         ST     R2,BWDPTR              SET BWDPTR SO THAT FIRST ATTEMPT 29550013
*                                    AT PUTTING OUT THE 'PREVIOUS'      29580013
*                                    BASE WORD DOES NOTHING.            29610013
         BAL   R14,GETCBF             TEXT                              29640013
         SPACE                                                          29670013
         MVC   STARTX+1(3),CBUFNM       PLACE REFERENCE TO START OF     29700013
*                                     CREATED TEXT IN COMMUNICATIONS    29730013
*                                     REGION                            29760013
         BAL   R14,GETIBF               GET FIRST BUFFER FOR INSERTION  29790013
*                                     FILE                              29820013
         MVC   EOPINS+1(3),IBUFNM       REMEMBER NAME OF FIRST BUFFER   29850013
*                                     OF THE INSERTION FILE             29880013
         BAL   R14,SCRTXT               GET BLOCK OF SCRATCH TEXT FOR   29890001
*                                         MDRP TABLE                    29900001
EXIT1    BC    B,LA                     BEGIN ANALYSIS OF SOURCE TEXT   29910013
         EJECT                                                          29940013
*              GENERAL SCAN OF THE INPUT TEXT                           29970013
*                                                                       30000013
*              FUNCTION/OPERATION                                       30030013
*              THE CODE FOR THE BASIC SCAN ROUTINE FOLLOWS. THE SOURCE  30060013
*        CODE IS SCANNED TO FIND ALL THOSE PSEUDO-CODE ITEMS THAT       30090013
*        REQUIRE SPECIAL TREATMENT, I.E. ITEMS THAT MAY INVOLVE DICT-   30120013
*        IONARY REFERENCES AND ITEMS DELIMITING BLOCKS AND PROLOGS. THE 30150013
*        DRTEST ROUTINE IS CALLED TO FIND OUT IF ANY EXTRA ADDRESSING   30180013
*        IS NEEDED TO ACCESS QUANTITIES REPRESENTED BY DICTIONARY REF-  30210013
*        ERENCES. A NEW SOURCE FILE IS CREATED                          30240013
*              AT EACH STATEMENT NUMBER AND STATEMENT LABEL THE         30270013
*      PREFIX OPTIONS BYTE IS INSPECTED. AT A STATEMENT NUMBER THE      30300013
*      DIFFERENCE BETWEEN THE OPTIONS BYTE FOR THE NEW STATEMENT AND    30330013
*      THE PREVIOUS STATEMENT IS CALCULATED. IF THERE IS A DIFFERENCE   30360013
*      CODE IS GENERATED TO SET THE ON SLOTS FOR THE PREFIX OPTIONS     30390013
*      WHICH ARE DIFFERENT TO THE SETTING (ENABLED/DISABLED) REQUIRED   30420013
*      BY THE NEW STATEMENT.  AT A STATEMENT LABEL THE 'OPTIONS         30450013
*      CHANGED BYTE' FOR THE CURRENT BLOCK IS INSPECTED. (THE OPTIONS   30480013
*      CHANGED BYTE HAS A ONE BIT FOR EACH PREFIX OPTION CHANGED IN     30510013
*      THE BLOCK). CODE IS GENERATED FOR EACH BIT IN THE OPTIONS        30540013
*      CHANGED BYTE TO SET THE CORRESPONDING ON SLOT ENABLED OR         30570013
*      DISABLED AS IS INDICATED BY THE CURRENT PREFIX OPTIONS BYTE. A   30600013
*      STATEMENT NUMBER PRECEDED BY A COMPILER LABEL IS TREATED AS A    30630013
*      STATEMENT LABEL.  THE PREFIX OPTION FOR AN END STATEMENT IS      30660013
*      IGNORED. THIS IS INDICATED BY BIT7 BEING A ONE.                  30690013
*                                                                       30720013
*              ENTRY POINT - LA, NO PARAMETERS                          30750013
*                                                                       30780013
*              EXTERNAL ROUTINES 1) ADCBUF IN IEMRA  TO ADD TEXT TO     30810013
*      OUTPUT STREAM                                                    30840013
*                                2) DRTEST IN IEMRB  TO PRODUCE ANY     30870013
*         NECESSARY ADDRESSING INSTRUCTIONS FOR A GIVEN DICTIONARY      30900013
*         REFERENCE.                                                    30930013
*                                3) ADTEST IN IEMRA - TO DETERMINE      30960013
*         WHETHER A LITERAL OFFSET IS LESS THAN 4K AND TO PRODUCE EXTRA 30990013
*         INSTRUCTIONS IF IT IS NOT.                                    31020013
*                                4) GETSBUF IN IEMRA -TO GET THE NEXT   31050013
*        INPUT TEXT BLOCK.                                              31080013
*                                5) TXTRF IN IEMAA - TO CONVERT AN      31110013
*        ABSOLUTE ADDRESS TO SYMBOLIC REFERENCE.                        31140013
*                                6) ZDRFAB IN IEMAA - CONVERTS A        31170013
*        DICTIONARY REFERENCE TO ABSOLUTE                               31200013
*                                7) ADIBUF -IN IEMRA  ADDS ITEMS TO     31230013
*        THE INSERTION FILE.                                            31260013
*                                8) ZTXTAB - IN IEMAA CONVERTS A        31290013
*        SYMBOLIC TEXT REFERENCE TO ABSOLUTE.                           31320013
*                                9) RELIBUF - IN IEMRA -MARKS AN        31350013
*        INSERTION FILE TEXT BLOCK WANTED UNLESS IT IS THE CURRENT      31380013
*        ONE, WHEN IT IS LEFT BUSY.                                     31410013
*                                10) ZALTER - IN IEMAA CHANGES THE      31440013
*        STATUS OF A TEXT BLOCK.                                        31470013
*                                                                       31500013
*              EXIT-NORMAL   EXIT2  ON REACHING THE END OF THE SOURCE   31530013
*        TEXT                                                           31560013
*                                                                       31590013
*              EXIT-ERROR    WHEN AN ERROR IS DETECTED IN THE INTERNAL  31620013
*        WORKINGS OF THE COMPILER, A BAL R4,CMPERR IS EXECUTED. THE     31650013
*        COMMENT BY THE ADDRESS IN R4 THEN GIVES THE REASON FOR THE     31680013
*        ERROR STOP                                                     31710013
*                                                                       31740013
*              TABLES/WORK AREAS - ALL WORK AREAS AND CONSTANTS ARE     31770013
*        GIVEN AT THE END OF THE MODULE. THE MOST IMPORTANT IS THE      31800013
*        TRANSLATE TABLE TRTAB USED FOR SWITCHING ON THE ITEMS FOUND IN 31830013
*        THE SOURCE STREAM.                                             31860013
*                                                                       31890013
*              NOTES - REGISTER USE IS GIVEN IN THE EQU'S AT THE        31920013
*        START OF THE MODULE.                                           31950013
*                                                                       31980013
L6       BAL   R14,ADCBUF               MOVE PREVIOUS ITEM TO CREATED   32010013
*                                     FILE                              32040013
LA       CLI   GENFL,ON                 BRANCH IF AN EXTRA PSEUDO-CODE  32070013
         BC    BE,PSCEXT              ITEM REQUIRES GENERATION.         32100013
LAA      SR    R2,R2                    TEST FORM OF PSEUDO-CODE ITEM   32130013
         TRT   0(1,SP),TRTAB          AND SWITCH TO APPROPRIATE ROUTINE 32160013
         BC    B,*(R2)                                                  32190013
         BC    B,ACT1                   NON-SPECIAL 3-BYTE INSTRUCTION  32220013
         BC    B,ACT2                   NON-SPECIAL 5-BYTE INSTRUCTION  32250013
         BC    B,ACT3                   RX,RS OR SI INSTRUTION          32280013
         BC    B,ACT4                   SS INSTRUCTION                  32310013
         BC    B,ACT5                   END BUFFER MARKER               32340013
         BC    B,ACT6                   BEGIN OR PROC                   32370013
         BC    B,ACT7                   END OF BLOCK OR PROCEDURE       32400013
EXIT2    BC    B,ACT8                   END OF PROGRAM                  32430013
         BC    B,ACT9                   PLBS                            32460013
         BC    B,ACT10                  END OF PROLOG                   32490013
         BC    B,LCOPYL                 IGNORE VAR. LENGTH ITEM         32520001
         BAL   R4,CMPERR                ILLEGAL ITEM                    32550013
         BC    B,ACT12                  ABSOLUTE CODE                   32580013
         BC    B,ACT13                       PINS                       32610013
         BC    B,ACT14                  SN                              32640013
         BC    B,ACT15                  SL                              32670013
         BC    B,ACT16                  CL                              32700013
         BC    B,ACT17                  PLBS'                           32730013
         BC    B,LIBCAL                                                 32760013
         BC    B,LIBEND                                                 32790013
         BC    B,ACT18                  SN2                             32820013
         BC    B,ACT19                  PCC                             32850013
         BC    B,ACT20                  FMT                             32880013
         BC    B,ACT21                  FMT'                            32910013
         BC    B,GENY3B                                                 32940013
         BC    B,ENDPTR                                                 32950015
          BC   B,MAKADI                                                 32956015
         BC    B,SPADI                                                  32962015
         LA    SP,3(0,SP)              PFMT - TO BE SKIPPED             32964016
         BC    B,LA                                                     32966016
         BAL   R14,CHDRP         (124)  DROP, DRPL, SINL, OR USSL -     32966301
*                                         CHECK FOR REG IN MDRP         32966601
         CLI   0(SP),DROP                 TABLE AND RETURN TO NORMAL    32967001
         BC    BE,ACT1                    ROUTINE                       32967501
         BC    B,LCOPYL                                                 32968001
         BAL   R14,LMDRP         (140)  MDRP                            32968501
         BC    B,LAA                                                    32969001
         SPACE 10                                                       32970013
*              A PSEUDO-CODE ITEM REQUIRES GENERATION                   33000013
PSCEXT   CLI   OSMFL,ON                 BRANCH IF IT IS NOT AN OSM      33030013
         BC    BNE,LDROP              REQUIRING GENERATION.             33060013
         SPACE                                                          33090013
*              AN OSM1 OR OSM3 IS TO BE GENERATED. THE LENGTH TO BE     33120013
*        OUTPUT DEPENDS UPON THE CODE BYTE.                             33150013
         LA    R2,OSMSKT                SET UP PARAMETERS FOR ADCBUF    33180013
         LA    R3,3                   AS IF AND OSM1 IS BEING           33210013
         CLI   OSMSKT,OSM1            GENERATED. IF THIS IS NOT TRUE    33240013
         BC    BE,*+8                 ONLY THE 'LENGTH' PARAMETER       33270013
         LA    R3,5                   NEED BE ALTERED.                  33300013
         BAL   R14,ADCBUF               OUTPUT THE OSM.                 33330013
         SPACE                                                          33360013
         MVI   OSMFL,OFF                SET OSMFL OFF.                  33390013
         CLI   DROPSW,ON                BRANCH IF THERE ARE 'DROP'S TO  33420013
         BC    BE,LDROP               BE GENERATED.                     33450013
         MVI   GENFL,OFF                OTHERWISE PROCESS NEXT ITEM.    33480013
         BC    B,LAA                                                    33510013
         EJECT                                                          33511015
         EJECT                                                          33511115
MAKADI   MVC   RXINST+2(1),ADISKT+2                                     33511215
         OI    RXINST+2,X'11'                                           33511315
         MVI   RXINST,ADI                                               33511415
         MVC   RXINST+1(1),1(SP)                                        33511515
         MVC   RXINST+3(2),3(SP)                                        33511615
         MVI   SSFLG,OFF                                                33511715
         MVI   OSMP,OFF                                                 33511815
         MVC   GSVE(2),GENFL         SAVE GENFL AND OSMFL               33512016
         MVI   GENFL,OFF                                                33512216
         MVI   OSMFL,OFF                                                33512416
         BC    B,ACT3A                                                  33512616
         SPACE 5                                                        33512816
*              HERE CODE TO SET UP A POINTER IS TO BE SCANNED AS        33513016
*        THOUGH IT WERE IN THE INPUT STREAM.                            33513216
         SPACE                                                          33513416
         SPACE                                                          33514015
PTRCDE   LA    SP,LDPTR                                                 33515015
         MVC   RXSAVE(5),RXINST                                         33516015
         BC    B,LAA                                                    33517015
         SPACE 5                                                        33518015
*              THE INSTRUCTION BEING EXAMINED IS AN ADD FROM A SKDV     33518315
*        WHICH HAS ALREADY BEEN ADDRESSED.                              33518615
         SPACE                                                          33518915
SPADI    LR    R2,SP                                                    33519215
         MVI   0(SP),ADI                                                33519515
         MVC   2(1,SP),ADISKT+2        COPY 1ST/2ND OP. FLAG            33519815
         OI    2(SP),X'11'             SET 'DROP AT END OF STMNT.' BIT  33520115
*                                    AND SET BASE =1(SEE ADIMOV IN RF)  33520415
         LA    R3,8                                                     33520715
         BAL   RR,ADCBUF                                                33521015
         MVI   LDPTR+6,X'8A'           RESTORE SKELETON                 33521315
         SPACE 5                                                        33521615
ENDPTR   MVC   SSFLG(2),SSFLSV        RESTORE SS AND OSM PRESENT FLAGS  33521915
         MVC   GENFL(2),GSVE         RESTORE GENFL AND OSMFL            33525916
         SPACE                                                          33531015
ENDPT2    L     RR,BVENV               RESTORE ENVIRONMENT              33532015
         L     SP,BVENV+4                                               33533015
         MVC   RXINST(5),RXSAVE                                         33534015
         BCR   B,RR                                                     33535015
         EJECT                                                          33540013
*              CASE WHERE SYMBOLIC REGISTERS HAVE BEEN CREATED BY THIS  33570013
*        PHASE, AND IT IS NECESSARY TO INSERT DROP INSTRUCTIONS FOR THE 33600013
*        REGISTERS AT THE FIRST OPPORTUNITY. WHEN THIS CODE IS ENTERED, 33630013
*        DROPIN  CONTAINS THE REQUIRED (ONE OR TWO) DROP INSTRUCTIONS   33660013
*        AND MVLENG CONTAINS THE LENGTH OF DROPIN (SEE ADTEST ROUTINE). 33690013
         SPACE                                                          33720013
LDROP    CLI   0(SP),OSM1               A DROP INSTRUCTION MUST NOT BE  33750013
         BC    BE,LAA                 INSERTED BETWEEN AN INSTRUCTION   33780013
         CLI   0(SP),OSM2             AND A FOLLOWING OSM. THUS NO      33810013
         BC    BE,LAA                 ACTION CAN BE TAKEN IF THE        33840013
         CLI   0(SP),OSM3             CURRENT ITEM IS AN OSM1, OSM2,    33870013
         BC    BE,LAA                 OSM3 OR EOB                       33900013
         CLI   0(SP),EOB                                                33930013
         BC    BE,LAA                                                   33960013
         MVI   DROPSW,OFF               IN OTHER CASES, SWITCH OFF      33990013
         LA    R2,DROPIN              DROPSW AND ADD DROP INSTRUCTIONS  34020013
         SR    R3,R3                  TO CREATED FILE                   34050013
         IC    R3,MVLENG                                                34080013
         BAL   R14,ADCBUF                                               34110013
         SPACE                                                          34140013
         MVI   GENFL,OFF                SWITCH OFF GENFL                34170013
         SPACE                                                          34200013
         BC    B,LAA                    RESUME SCANNING                 34230013
         EJECT                                                          34260013
*              ACTIONS PERFORMED FOR THE VARIOUS PSEUDO-CODE ITEMS      34290013
         SPACE 5                                                        34320013
ACT17    MVC   THSPRC(1),CURRNT         SAVE THE CURRENT OPTIONS BYTE   34350013
         SPACE 3                                                        34380013
*              ACTION FOR 3-BYTE ITEM NOT REQUIRING SPECIAL ATTENTION   34410013
         SPACE                                                          34440013
ACT1     LA    R3,3                     SET LENGTH TO 3 AND BRANCH TO   34490001
         BC    B,ACT2A                    COPY ITEM TO OUTPUT           34540001
         SPACE 10                                                       34590013
*              ACTION FOR 5-BYTE ITEM NOT REQUIRING SPECIAL ATTENTION   34620013
         SPACE                                                          34650013
ACT2     LA    R3,5                     SET LENGTH                      34670001
ACT2A    LR    R2,SP                    SET PARAMETERS FOR MOVING ITEM  34690001
*                                         TO CREATED FILE               34710001
         AR    SP,R3                    UPDATE SP                       34730001
         BC    B,L6                     PROCEED WITH NEXT ITEM          34770013
         SPACE 10                                                       34800013
*              ACTION FOR RX OR SI INSTRUCTION WHICH MAY INVOLVE A      34830013
*        DICTIONARY REFERENCE THAT REQUIRES ADDRESSING INSTRUCTIONS TO  34860013
*        BE GENERATED.  ( RS INSTRUCTIONS SHOULD NEVER INVOLVE DICTION- 34890013
*        ARY REFERENCES AND THUS CAN BE SKIPPED OVER WITHOUT EXAMIN-    34920013
*        ATION. BRANCH INSTRUCTIONS ARE ALSO SKIPPED OVER, SINCE ANY    34950013
*        DICTIONARY REFERENCES INVOLVED ARE ADDRESSED AT FINAL ASSEMBLY 34980013
*        TIME. THE ONLY EXCEPTIONS ARE BC INSTRUCTIONS, WHICH MAY       35010013
*        REQUIRE THE SERVICES OF THE ADTEST ROUTINE)                    35040013
         SPACE                                                          35070013
ACT3     MVC   RXINST(5),0(SP)          MOVE ITEM TO RXINST             35100013
         MVI   ADISKT+2,0               SWITCH BIT SO THAT GENERATED    35130013
*                                     ADI INSTRUCTIONS REFER TO SECOND  35160013
*                                     OPERAND                           35190013
ACT3A    EQU   *                                                        35200015
         LA    SP,5(SP)                 UPDATE SP                       35220013
L4       CLI   0(SP),OSM1               TEST FOLLOWING TRIPLE, BRANCH   35250013
         BC    BE,L2                  OUT IF IT IS AN ADDEND OR 'EOB'   35280013
         CLI   0(SP),OSM3             MARKER                            35310013
         BC    BE,L2                                                    35340013
         CLI   0(SP),EOB                                                35370013
         BC    BE,L3                                                    35400013
         STH   R0,ADSLOT                SET ADSLOT TO ZERO IF THERE IS  35430013
         BC    B,L2A                   NO ADDEND                        35460015
         SPACE                                                          35490013
L2       MVC   ADSLOT(2),1(SP)          SET ADSLOT TO VALUE OF ADDEND   35520013
         MVI   OSMP,ON                                                  35526015
L2A      EQU   *                                                        35532015
          CLI  RXINST,ADI                                               35538015
          BC    BE,L7A1                                                 35544015
         CLI   RXINST,MCBC              SKIP UNLESS CURRENT INSTRUCTION 35550013
         BC    BNE,L7A                IS A BC                           35580013
         TM    RXINST+1,BIT1            IF SECOND OPERAND IS AN EQU     35610013
         BC    BO,L7                  VALUE, NO EXAMINATION IS REQUIRED 35640013
         TM    RXINST+1,BIT0           IF DICT REF OR EQU VALUE         35670013
         BC    BZ,L7                 AS 2ND FIELD, THEN NOTHING TO DO   35700013
         TM    ADSLOT,BIT0              IF THE ADDEND IS NEGATIVE,      35730013
         BC    BZ,*+8                 THERE IS A COMPILER ERROR, SINCE  35760013
         BAL   R4,CMPERR              ADTEST WOULD CLOBBER THE          35790013
*                                     CONDITION BITS IN THIS CASE       35820013
L7A      LA    R2,RXINST+3              SET R2 TO POINT AT SECOND       35850013
*                                     OPERAND                           35880013
         TM    RXINST+1,BIT0            BRANCH OUT IF ADDRESS FIELD IS  35910013
         BC    BNZ,L5                 NOT A DICTIONARY REFERENCE        35940013
         CLI   BSECNT+1,0              IS THERE ROOM IN BSEWRD FOR      35970013
          BAL  R5,BSROOM                                                36000013
L7A1      LA   R2,RXINST+3                                              36030015
         BAL   R14,DRTEST               CALL DRTEST                     36060013
         SPACE                                                          36090013
         CLI   OFTMP,X'FF'                                              36120013
         BC    BNE,L7                                                   36150013
         MVC   RXINST+3(2),OFTMP+2                                      36180013
         MVI   OFTMP,0                                                  36186015
         CLI   RXINST,ADI                                               36192015
         BC    BE,L7C                                                   36198015
         BC    BE,L7B                                                   36204015
         OI    RXINST+1,X'80'                                           36210013
         BC    B,L7                                                     36220015
L7C      NI    RXINST+3,X'7F'          SWITCH OFF LIT.OFF BIT IN        36230015
*                                    DISPLACEMENT FIELD OF ADI'S        36240015
         OI    RXINST+2,X'40'                                           36250015
L7       LA    R2,RXINST                SET PARAMETERS TO ADD RXINST TO 36270013
         LA    R3,5                   CREATED FILE                      36300013
         MVI   OSMP,OFF                                                 36310015
         BC    B,L6                     PROCEED WITH NEXT ITEM          36330013
         SPACE 3                                                        36360013
BSROOM   BCR   BH,R5                    RETURN IF ROOM IN BASEWORD      36390013
L7B      L     R2,BWDPTR               OUT PUT CURRENT BASE WORD        36420013
         MVC   0(5,R2),BWDCDE                                           36450013
         SPACE                                                          36480013
         ST    R0,BSEWRD               INITIALIZE NEW BASE WORD         36510013
         MVI   BSECNT+1,32                                              36540013
         LA    R3,5                    AND PUT IT OUT TO RESESVE        36570013
         BAL   R14,ADCBUF            SPACE IN OUT-PUT STREAM            36600013
        SH    R4,H5                                                     36630013
         ST    R4,BWDPTR               RECORD WHERE COMPLETED BSEWRD    36660013
         BCR   B,R5                  IS TO BE MOVED TO. RETURN          36690013
         SPACE 5                                                        36720013
*              CASE WHERE INSTRUCTION DOES NOT CONTAIN A DICTIONARY     36750013
*        REFERENCE                                                      36780013
         SPACE                                                          36810013
L5       BAL   R14,ADTEST               CALL ADTEST                     36840013
         SPACE                                                          36870013
         BC    B,L7                     RETURN TO MAIN ROUTINE          36900013
         SPACE 3                                                        36930013
*              CASE OF 'EOB' MARKER FOLLOWING THE ITEM                  36960013
         SPACE                                                          36990013
L3       BAL   R14,GETSBF               CHAIN TO THE NEXT SOURCE BUFFER 37020013
*                                     AND PROCEED TO EXAMINE ITS FIRST  37050013
         BC    B,L4                   ITEM TO SEE IF IT IS AN ADDEND    37080013
         SPACE 10                                                       37110013
*              ACTION FOR SS INSTRUCTION                                37140013
         SPACE                                                          37170013
*              EXAMINE FIRST OPERAND                                    37200013
         SPACE                                                          37230013
ACT4     MVI   SSFLG,ON                 INDICATE THAT AN SS INSTRUCTION 37260013
*                                     IS BEING PROCESSED.               37290013
         CLI   BSECNT+1,2              IF INSUFFICIENT ROOM IN BASE     37320013
         BAL   R5,BSROOM                                                37350013
         MVI   ADISW,OFF                                          38178 37360046
         MVI   ADISKT+2,BIT0            SET BIT SO THAT GENERATED ADI   37380013
*                                     INSTRUCTIONS REFER TO FIRST       37410013
*                                     OPERAND                           37440013
         STH   R0,ADSLOT                ADSLOT = 0                      37470013
         TM    1(SP),BIT3               RESET ADSLOT TO CONTAIN ADDEND  37500013
         BC    BZ,*+10                FOR FIRST OPERAND, IF THERE IS    37530013
         MVC   ADSLOT(2),8(SP)        ONE                               37560013
         LA    R2,4(SP)                 SET R2 TO POINT AT FIRST        37590013
*                                     OPERAND                           37620013
         TM    1(SP),BIT1               BRANCH OUT IF FIRST OPERAND IS  37650013
         BC    BO,L8                  NOT A DICTIONARY REFERENCE        37680013
         BAL   R14,DRTEST               CALL DRTEST FOR ADDRESSING      37710013
*                                     FIRST OPERAND                     37740013
         CLI   OFTMP,X'FF'                                              37770013
         BC    BNE,L11                                                  37800013
         MVC   4(2,SP),OFTMP+2                                          37830013
         OI    1(SP),BIT1                                               37860013
         MVI   OFTMP,0                                                  37890013
         SPACE 3                                                        37920013
*              NOW EXAMINE SECOND OPERAND                               37950013
         SPACE                                                          37980013
L11      MVI   ADISKT+2,0               MAKE ADI INSTRUCTIONS REFER TO  38010013
         CLI   BSECNT+1,0                                               38040013
         BAL   R5,BSROOM                                                38070013
*                                     SECOND FIELD                      38100013
         STH   R0,ADSLOT                ADSLOT = 0                      38130013
         TM    1(SP),BIT4               IF THERE IS AN ADDEND SET       38160013
         BC    BZ,L9                  ADSLOT FROM VALUE AT EIGHTH OR    38190013
         LR    R4,SP                  TENTH BYTE OF INSTRUCTION ACCORD- 38220013
         TM    1(SP),BIT3             ING AS WHETHER OR NOT ADDEND      38250013
         BC    BZ,*+8                 FIELD FOR FIRST OPERAND WAS       38280013
         LA    R4,2(R4)               PRESENT                           38310013
         MVC   ADSLOT(2),8(R4)                                          38340013
L9       LA    R2,6(SP)                 SET R2 TO POINT AT SECOND       38370013
*                                     OPERAND                           38400013
         TM    1(SP),BIT2               BRANCH OUT IF SECOND OPERAND IS 38430013
         BC    BO,L10                 NOT A DICTIONARY REFERENCE        38460013
         BAL   R14,DRTEST               CALL DRTEST FOR ADDRESSING OF   38490013
*                                     SECOND OPERAND                    38520013
         CLI   OFTMP,X'FF'                                              38550013
         BC    BNE,L12                                                  38580013
         MVC   6(2,SP),OFTMP+2                                          38610013
         OI    1(SP),BIT2                                               38640013
         MVI   OFTMP,0                                                  38670013
L12      LR    R2,SP                                                    38700013
         MVI   SSFLG,OFF                INDICATE END OF SS INSTRUCTION  38730013
         SPACE 2                                                        38731046
*        THIS ROUTINE CHECKS, AT THE END OF PROCESSING AN SS INST,      38732046
*        WHETHER AN ADI FOLLOWED BY ADDRESSING CODE OF THE FORM         38733046
*        LA,OSM1,SLL,AR HAS BEEN OUTPUT PRIOR TO THE SS INST.           38734046
*        IF THIS IS THE CASE THE ADI IS MADE AN IGN5 ITEM AND           38735046
*        REWRITTEN AFTER THE ADDRESSING SEQUENCE. CARE HAS BEEN TAKEN   38736046
*        NOT TO CROSS TEXT BLOCK BOUNDARIES WHEN DOING THIS BY          38737046
*        ALLOWING FOR THE POSSIBLE SHIFT OF CODE WHEN OUTPUTTING THE    38738046
*        ADI. THIS ROUTINE WAS FOUND TO BE NECESSARY AS A RESULT        38739046
*        OF APAR 38178. THE ADI WAS BEING USED BY PHASE RF TO MODIFY    38740046
*        THE LA INST OF THE ADDRESSING SEQUENCE, NOT THE SS INST.       38741046
         CLI   ADISW,ON                * IS THIS ADI FOLLWD       38178 38742046
         BNE   L9B                                                      38743046
         L     R15,ADILOC              * LOCATE 1ST ADI           38178 38744046
         CLI   0(R15),ADI              * CHECK WERE AT RIGHT SPOT 38178 38745046
         BE    L9A                     * YES CARRY ON             38178 38746046
         BAL   R4,CMPERR               * NO, DISASTER             38178 38747046
L9A      EQU   *                                                  38178 38748046
         MVC   ADITEMP(5),0(R15)       * SAVE THIS ADI            38178 38749046
         MVI   0(R15),IGN5             * DELETE ADI AT THIS PNT   38178 38750046
         MVC   1(2,R15),H5             * SET LENGTH TO 5          38178 38751046
         LA    R2,ADITEMP              * OUTPUT ADI AT NEW PNT    38178 38752046
         LA    R3,5                                               38178 38753046
         BAL   R14,ADCBUF                                         38178 38754046
L9B      EQU   *                                                        38755046
         CLI   SPSW,ON                  BRANCH IF THIS IS A SPECIAL     38760013
         BC    BE,L12A                CASE.                             38790013
         SPACE                                                          38820013
LCOPYL   SR    R3,R3                    SET R3 TO CONTAIN LENGTH AND    38850001
         IC    R3,2(SP)                   BRANCH TO COPY ITEM TO        38880001
         BC    B,ACT2A                    OUTPUT                        38910001
         SPACE 2                                                        38970013
*              THE SS INSTRUCTION HAS TO BE MODIFIED TO INCLUDE EITHER  39000013
*        OR BOTH OFFSETS IN ADSLT1 AND 2.                               39030013
L12A     SR    R3,R3                    PICK UP LENGTH OF SS INSTRUCT-  39060013
         IC    R3,2(SP)                -ION AND MOVE INSTRUCTION        39090013
         STC   R3,*+5                 INTO WORK SPACE                   39120013
         MVC   SSPACE(0),0(SP)                                          39150013
         AR    SP,R3                    BUMP SOURCE POINTER.            39180013
         CLI   OPNO,2                   BRANCH ACCORDING AS THE SECOND, 39210013
         BC    BE,L12C                FIRST, OR BOTH OPERANDS REQUIRE   39240013
         BC    BL,L12B                AN OFFSET.                        39270013
*              HERE BOTH OPERANDS REQUIRE THE ADDITION OF AN OSM.       39300013
         MVC   SSPACE+8(4),ADSLT1       MOVE THEM IN                    39330013
         OI    SSPACE+1,X'18'           INDICATE BOTH PRESENT           39360013
         LA    R3,4(R3)                                                 39390013
         BC    B,L12D+4                                                 39420013
         SPACE                                                          39450013
*              HERE THE FIRST OPERAND REQUIRES AN OFFSET.               39480013
         SPACE                                                          39510013
L12B     TM    SSPACE+1,BIT4            BRANCH IF SECOND OPERAND HAS    39540013
         BC    BZ,*+10                NO OFFSET.                        39570013
         MVC   SSPACE+10(2),SSPACE+8    IF IT HAS, MOVE IT ALONG TWO    39600013
         MVC   SSPACE+8(2),ADSLT1       INSERT THE OFFSET FOR THE       39630013
*                                     FIRST OPERAND.                    39660013
         OI    SSPACE+1,BIT3            INDICATE FIRST OPERAND PRESENT  39690013
L12D     LA    R3,2(R3)                 BUMP LENGTH BY 2 AND STORE IN   39720013
         STC   R3,SSPACE+2            NEW SS INSTRUCTION.               39750013
         LA    R2,SSPACE                                                39780013
         SPACE                                                          39810013
         SPACE                                                          39840013
         MVI   SPSW,OFF                END OF SPECIAL SS INSTRUCTION    39870013
         MVI   OPNO,0                                                   39900013
         BC    B,L6                     PROCEED WITH NEXT ITEM          39930013
         SPACE 5                                                        39960013
*              HERE THE SECOND OPERAND REQUIRES AN OFFSET               39990013
L12C     LA    R2,SSPACE(R3)            POINT R2 AT THE BYTE AFTER THE  40020013
         MVC   0(2,R2),ADSLT2         CURRENT END. MOVE IN OFFSET       40050013
         OI    SSPACE+1,BIT4         VALUE AND MARK PRESENCE            40080013
         BC    B,L12D                   BRANCH TO OUTPUT THE INSTRUCT   40110013
*                                     -ION.                             40140013
         SPACE 3                                                        40170013
*              CASE OF FIRST OPERAND NOT A DICTIONARY REFERENCE         40200013
         SPACE                                                          40230013
L8       BAL   R14,ADTEST               CALL ADTEST                     40260013
         SPACE                                                          40290013
         BC    B,L11                    PROCEED WITH SECOND OPERAND     40320013
         SPACE 3                                                        40350013
*              CASE OF SECOND OPERAND NOT A DICTIONARY REFERENCE        40380013
         SPACE                                                          40410013
L10      BAL   R14,ADTEST               CALL ADTEST                     40440013
         SPACE                                                          40470013
         BC    B,L12                    RETURN TO MAIN ROUTINE          40500013
         SPACE 10                                                       40530013
*              ACTION AT 'EOB' MARKER                                   40560013
         SPACE                                                          40590013
ACT5     BAL   R14,GETSBF               GET NEW SOURCE BUFFER           40620013
         SPACE                                                          40650013
         BC    B,LA                     PROCEED WITH NEXT ITEM          40680013
         SPACE  10                                                      40710013
*              ACTION FOR BEGIN OR PROC                                 40740013
         SPACE                                                          40770013
ACT6     MVC   PAR1+2(2),1(SP)          SET DP TO POINT TO ENTRY TYPE 1 40800013
         L     R15,ZDRFAB             FOR BLOCK OR PROC                 40830013
         BALR  R14,R15                                                  40860013
         SPACE                                                          40890013
         L     DP,PAR1                                                  40920013
        SPACE 1                                                         40920301
        MVC   CHTEMP(2),E1PSTO(DP)    AALIGN THE NEXT AVAILABLE         40920601
         LH    R14,CHTEMP                PRIVATE STORAGE OFFSET         40920901
         LA    R14,3(R14)                SLOT ONTO A FULLWORD           40921201
         N     R14,MASK1                 BOUNDARY                       40921501
         STH   R14,CHTEMP                                               40921801
         MVC   E1PSTO(2,DP),CHTEMP                                      40922101
        SPACE 1                                                         40922401
*              THE DSA SIZE IS FOUND EITHER IN THE ENTRY TYPE 1 OR IN   40923015
*              ITS STATIC DSA ENTRY.                                    40926015
         LR    R14,DP                                                   40929015
         CLI   0(R14),PET1             IS IT A PROC                     40932015
         BC    BNE,*+8                 BRANCH IF NOT                    40935015
         LA    R14,PE1OPT-BE1OPT(R14)  ACCOUNT FOR EXTRA DISPLACEMENT   40938015
         TM    BE1OPT(R14),BIT1        IS THERER A ST ATIC DSA          40941015
         LA    R14,E1DSA(DP)                                            40944015
         BC    BZ,ACT6J                BRANCH IF NOT                    40947015
         MVC   PAR1+2(2),E1DSA+1(DP)   CONVERT REF TO STATIC DSA ENTRY  40950015
         BALR  R14,R15                                                  40953015
         SPACE                                                          40956015
         SPACE                                                          40959015
         L     R14,PAR1                POINT R14 TO DSA SIZE SLOT       40962015
         LA    R14,7(R14)                                               40965015
         SPACE                                                          40968015
ACT6J    MVC   DSASIZ+1(3),0(R14)                                       40971015
         L     R4,DSASIZ                BRANCH OUT IF BLOCK HAS NO      40980013
         LTR   R4,R4                  PROLOG                            41010013
         BC    BZ,L13                                                   41040013
         LA    R4,7(0,R4)            ALIGN TO 8 BYTE                    41070016
         N     R4,MASK2              BOUNDARY                           41100016
         ST    R4,DSASIZ              TYPE 1                            41130013
         MVC   0(3,R14),DSASIZ+1                                        41160015
         MVC   INSTRF(1),IBUFNM                                         41190013
         LR    R2,SP                   OUTPUT THE PROC OR BEGIN MARKER  41220013
         LA    R3,3                                                     41250013
         BAL   R14,ADCBUF                                               41280013
         CLI   FIRSW,ON                 FOR THE OUTERMOST BLOCK, SKIP   41310013
         BC    BE,L14                 OVER INSTRUCTIONS TO STACK THE    41340013
*                                     INFORMATION IN THE CONTAINING     41370013
*                                     BLOCK                             41400013
*              IF THIS IS A LABELLED BEGIN BLOCK THE PREFIX OPTIONS     41430013
*        FOR THE CONTAINING BLOCK MUST BE SET AS AN THE PROC OR BEGIN   41460013
*        STATEMENT FOR THAT BLOCK.                                      41490013
         CLI   0(DP),PET1              BRANCH IF THIS IS A PROCEDURE    41520013
         BC    BE,ACT6A              STATEMENT                          41550013
         CLI   34(DP),X'D0'            BRANCH IF BEGIN NOT LABELLED.    41580013
         BC    BE,ACT6A                                                 41610013
         SPACE                                                          41640013
         MVC   PAR1+2(2),STE1RF(SCP)   DECODE REFERENCE TO CONTAINING   41670013
         L     R15,ZDRFAB            ENTRY TYPE 1.                      41700013
         BALR  R14,R15                                                  41730013
         SPACE                                                          41760013
         L     R14,PAR1                                                 41790013
         LA    R2,E1PRLS(R14)                                           41820013
         CLI   0(R14),PET1                                              41850013
         BC    BE,*+8                                                   41880013
         LA    R2,BE1PRL(R14)          SET CURRENT TO OPTIONS BYTE      41910013
         MVC   CURRNT(1),16(R2)      FROM BLOCK HEADING STATENENT       41940015
         MVC   TEMP(1),STCHNB(SCP)     TEMP IS PREFIX OPTIONS CHANGED   41970013
         MVI   TSW,ON                                                   42030013
         BC    B,GENFL1                BRANCH TO GENERATE CODE TO       42060013
ACT6A    MVI   TSW,OFF               SET ON SLOTS.                      42090013
         LA    R2,JMP00                PLACE 'JUMP' INSTRUCTION IN      42120013
         LA    R3,4                  INSERTION FILE                     42150013
         BAL   R14,ADIBUF                                               42180013
         SPACE                                                          42210013
         MVC   PAR1+1(3),IBUFNM        CONVERT ADDRESS OF NEXT FREE     42240013
         ST    IP,PAR2               BYTE TO A REFERENCE                42270013
         L     R15,ZTXTRF                                               42300013
         BALR  R14,R15                                                  42330013
         SPACE                                                          42360013
         MVC   INSTRF(3),PAR1+1        SAVE THE REFERENCE               42390013
         LH    R2,PAR1+2               CALCULATE AND STACK THE          42420013
         SH    R2,H4                 REFERENCE TO THE JUMP INSTRUCTION  42450013
         STH   R2,PAR1+2                                                42480013
         MVC   STJMP(3,SCP),PAR1+1                                      42510013
         MVC   STPSTO(2,SCP),PSTOR     STACK VALUE OF PSTOR             42540013
         MVC   STNLEV(1,SCP),NLEVEL+1                                   42570013
         MVC   STCURR(1,SCP),CURRNT     STACK THE CURRENT OPTIONS BYTE  42600013
         SPACE                                                          42630013
         LA    SCP,BLSTSZ(SCP)          UPDATE STACK POINTER            42660013
         C     SCP,SCPMAX               THERE IS A COMPILER ERROR IF    42690013
         BC    BNH,*+8                THE STACK HAS OVERFLOWED          42720013
         BAL   R4,CMPERR                                                42750013
         SPACE                                                          42780013
         MVC   PAR1+1(3),IBUFNM                                         42810013
         ST    IP,PAR2                  RESET INSTRF AS TEXT REFERENCE  42840013
         L     R15,ZTXTRF             TO IP                             42870013
         BALR  R14,R15                                                  42900013
         SPACE                                                          42930013
         MVC   INSTRF(3),PAR1+1                                         42960013
L14      MVI   FIRSW,OFF                SWITCH OFF FIRSW                42990013
         MVC   STE1RF(2,SCP),1(SP)      STACK DICT REF TO ENTRY TYPE 1  43020013
         STH   R0,NLEVEL                ZEROIZE NLEVEL                  43050013
         MVC   STADOF(2,SCP),E18AD+1(DP)  STACK OFFSET OF ADDRESSING    43080013
         MVC   STCHD(3,SCP),ENDCHN    VECTOR AND ZEROIZE ADDRESSING     43110013
*                                     CHAIN FOR BLOCK                   43140013
         MVC   STWSP(2,SCP),E1WSPR(DP)  STACK DICTIONARY REFERENCE OF   43170013
*                                     WORKSPACE.                        43200013
         MVC   STWSP3(2,SCP),E1WSPR+4(DP) AND ALSO REFERENCE OF TYPE 3  43230013
*                                       WORKSPACE.                      43260013
         MVI   STW2OF(SCP),E1T2WK       STORE THE OFFSET TO WORKSPACE 2 43290013
         LA    R2,E1PRLS(DP)            SET UP R2 TO POINT AT LIST OF   43320013
         CLI   0(DP),PET1             PREFIX OPTION REFERENCES. IF THIS 43350013
         BC    BE,L15                 IS NOT A PROCEDURE ENTRY THEN     43380013
         LA    R2,BE1PRL(DP)          RESET R2 FOR A BEGIN STATEMENT.   43410013
         MVI   STW2OF(SCP),B1T2WK       CHANGE OFFSET TO WORKSPACE 2    43440013
*                                     FOR A BEGIN.                      43470013
L15      MVC   STPRLS(16,SCP),0(R2)                                     43510015
         MVC   CURRNT(1),16(R2)        SAVE THE PREFIX BYTE FROM THE    43550015
*                                    PROC/BEGIN STATEMENT.              43590013
         STH   R0,PSTOR                 ZEROIZE PSTOR                   43620013
         MVI   PROGSW,ON                SWITCH ON PROGSW AND ILSW       43650013
         MVI   ILSW,ON                                                  43680013
         MVC   STLEV(2,SCP),E1LEV(DP)   STACK LEVEL AND BLOCK NUMBERS   43710013
         LA    SP,3(SP)                BUMP SCAN POINTER AND BRANCH     43740013
         BC    B,LAA                 TO TEST NEXT ITEM.                 43770013
         SPACE 3                                                        43800013
*              CASE OF BLOCK WITH NO PROLOG                             43830013
         SPACE                                                          43860013
L13      MVI   0(SP),BGNP               CHANGE ITEM TO SPECIAL CODE FOR 43890013
*                                     BENEFIT OF NEXT PHASE             43920013
         LH    R4,NLEVEL                NLEVEL = NLEVEL + 1             43950013
         LA    R4,1(R4)                                                 43980013
         STH   R4,NLEVEL                                                44010013
         BC    B,ACT1                   ADD ITEM TO CREATED FILE AND    44040013
*                                     PROCEED WITH NEXT ITEM            44070013
         SPACE 5                                                        44100013
*              CASE OF PCC ITEM - THE PREFIX OPTIONS CARRIER.           44130013
         SPACE                                                          44160013
ACT19    MVC   STCHNB(1,SCP),1(SP)     PICK UP AND STACK THE PREFIX     44190013
         LA    SP,3(SP)              OPTIONS CHAINGED BYTE. DO NOT COPY 44220013
         BC    B,LAA                 ITEM TO OUTPUT                     44250013
         SPACE 10                                                       44280013
*              ACTION AT END OF BLOCK OR PROCEDURE                      44310013
         SPACE                                                          44340013
ACT7     CH    R0,NLEVEL                BRANCH OUT IF IT IS THE END OF  44370013
         BC    BNE,L17                A PROLOGLESS BLOCK                44400013
         MVC   PAR1+2(2),STE1RF(SCP)    SET DP TO POINT TO ENTRY TYPE 1 44430013
         L     R15,ZDRFAB             FOR CURRENT BLOCK                 44460013
         BALR  R14,R15                                                  44490013
         SPACE                                                          44520013
         L     DP,PAR1                                                  44550013
         MVC   E1PSTO(2,DP),PSTOR       STORE PSTOR IN SPARE BYTES IN   44580013
         LA    R2,END00               ENTRY TYPE1                       44610013
         LA    R3,1                     ADD 'END' INSTRUCTION TO        44640013
         BAL   R14,ADIBUF             INSERTION FILE                    44670013
         SPACE                                                          44700013
         C     SCP,STKST                BRANCH OUT IF AT END OF OUTER-  44730013
         BC    BE,ACT1                MOST BLOCK                        44760013
         SH    SCP,HBLSZ               DOWNDATE STACK POINTER           44790013
         MVC   CURRNT(1),STCURR(SCP)   RESET CURRENT FROM STACK         44820013
         MVC   PAR1+1(3),STJMP(SCP)     PLACE IN R4 A POINTER TO THE    44850013
         L     R15,ZTXTAB             'JMP' INSTRUCTION THAT WAS        44880013
         BALR  R14,R15                PREVIOUSLY  INSERTED IN THE       44910013
         SPACE                                                          44940013
         L     R4,PAR1                INSERTION FILE                    44970013
         MVC   PAR1+1(3),IBUFNM         CONVERT IP TO A REFERENCE, AND  45000013
         ST    IP,PAR2                INSERT THIS REFERENCE IN THE      45030013
         L     R15,ZTXTRF             'JMP' INSTRUCTION                 45060013
         BALR  R14,R15                                                  45090013
         SPACE                                                          45120013
         MVC   1(3,R4),PAR1+1                                           45150013
         LA    R2,9(SCP)                ABOVE CALL OF ZTXTAB MARKED A   45180013
         BAL   R14,RELIBF             BLOCK BUSY. CALL ROUTINE TO MARK  45210013
*                                     IT WANTED, UNLESS IT IS THE       45240013
*                                     CURRENT BLOCK                     45270013
L18      MVC   PSTOR(2),STPSTO(SCP)     UNSTACK PSTOR AND NLEVEL        45300013
         MVC   NLEVEL+1(1),STNLEV(SCP)                                  45330013
         MVI   BSW,ON                  NEXT STATEMENT MUST BE TREATED   45360013
*                                    AS LABELED FOR UPDATING STATEMENT  45390013
*                                    NUMBER SLOT.                       45420013
         BC    B,ACT1                   ADD ITEM TO CREATED FILE AND    45450013
*                                     PROCEED WITH NEXT ITEM            45480013
         SPACE 3                                                        45510013
*              CASE OF END OF BLOCK WITH NO PROLOG                      45540013
         SPACE                                                          45570013
L17      MVI   0(SP),BGNPP              CHANGE CODE FOR BENEFIT OF      45600013
*                                     NEXT PHASE                        45630013
         LH    R4,NLEVEL                DECREASE NLEVEL BY ONE          45660013
         BCTR  R4,0                                                     45690013
         STH   R4,NLEVEL                                                45720013
         BC    B,ACT1                   ADD ITEM TO CREATED FILE AND    45750013
*                                     PROCEED WITH NEXT ITEM            45780013
*        BEGINNING OF THE PROLOG CODE, COMMON TO ALL ENTRY POINTS,      45810013
*        WHICH SETS UP AUTOMATIC. ALL PROLOG CODE EXECUTED BEFORE THIS  45840013
*        POINT IS GENERATED AS ABSOLUTE CODE. AT THIS POINT CODE IS     45870013
*        GENERATED TO SET UP PREG, THE REGISTER THAT POINTS TO PRIVATE  45900013
*        STORAGE. A 'BLBS' ITEM IS USED IN PLACE OF A PLBS IN THE       45930013
*        PROLOG OF A BEGIN BLOCK                                        45960013
         SPACE                                                          45990013
ACT9     LR    R2,SP                    ADD CURRENT SOURCE PSEUDO-CODE  46020013
         LA    R3,3                   ITEM TO CREATED FILE              46050013
         LA    R5,ADCBUF                                                46080013
         BALR  R14,R5                                                   46110013
         SPACE                                                          46140013
         LA    SP,3(SP)                 UPDATE SOURCE POINTER           46170013
         LA    R2,ENDCHN                                                46200016
         LA    R3,2                                                     46230016
         BAL   RR,ADCBUF                                                46260016
         SPACE                                                          46290013
         LA    R2,INSTA                 SET UP PARAMETERS FOR           46320013
         LA    R3,5                   GENERATION OF FIRST INSTRUCTION.  46350013
         SPACE                                                          46380013
         L     R4,DSASIZ                SET DSAOFT TO DSASIZ MODULO     46410013
         STH   R4,DSAOFT              4096.                             46440013
         NI    DSAOFT,X'0F'                                             46470013
         SRA   R4,12                    SKIP GENERATION OF EXTRA        46500013
         BC    BZ,L20                 INSTRUCTIONS IF DSASIZ IS LESS    46530013
         STH   R4,OSMINS+1            THAN 4096. SAVE OFFSET NUMBER.    46560013
         MVI   INSTA+4,0                INDICATE ZERO BASE              46590013
         NI    INSTA+1,NOTB0          AND NOT DICT. REF IN SECOND FIELD 46620013
         BALR  R14,R5                   GENERATE  LA  PREG,0            46650013
         SPACE                                                          46680013
         LA    R2,OSMINS                GENERATE  OSM1 (DSASIZ/4096)    46710013
         LA    R3,3                                                     46740013
         BALR  R14,R5                                                   46770013
         SPACE                                                          46800013
         SPACE                                                          46830013
         LA    R2,INSTB                 GENERATE INSTRUCTION OF FORM    46860013
         LA    R3,5                          SLL  PREG,12               46890013
         BALR  R14,R5                                                   46920013
         SPACE                                                          46950013
         LA    R2,INSTD                 GENERATE INSTRUCTION OF FORM    46980013
         LA    R3,5                          LA   PREG,PREG             47010013
         BALR  R14,R5                                                   47040013
         LA    R2,INSTE                 SET UP PARAMETERS TO GENERATE   47070013
         LA    R3,5                     OSM3  DSAOFT  ADP               47100013
         BC    B,L21                    BRANCH TO GENERATE              47130013
         SPACE                                                          47160013
L20      MVI   INSTA+4,ADP              INDICATE THAT THE SECOND FIELD  47190013
         OI    INSTA+1,BIT0           IS A REGISTER AND THAT IT IS ADP  47220013
         BALR  R14,R5                   GENERATE  LA  PREG, ADP         47250013
         SPACE                                                          47280013
         LA    R2,OSMINS                SET UP PARAMETERS TO GENERATE   47310013
         LA    R3,3                     OSM1  DSAOFT                    47340013
L21      MVC   1(2,R2),DSAOFT           FILL IN DSAOFT                  47370013
         BALR  R14,R5                   BRANCH TO GENERATE              47400013
         SPACE                                                          47430013
*              HAVING SET UP PREG, THE REGISTER THAT POINTS TO PRIVATE  47460013
*        STORAGE, STORE IT IN THE DSA SO THAT IT CAN BE CONVENIENTLY    47490013
*        RELOADED IF CLOBBERED. THE SLOT USED IS THE FIRST SLOT OF THE  47520013
*        ADDRESSING VECTOR                                              47550013
         SPACE                                                          47580013
         MVC   INSTC+6(2),STADOF(SCP)   GENERATE INSTRUCTION OF FORM    47610013
         SPACE                                                          47640013
*              NOW SET UP ADDRESSING VECTOR FOR PRIVATE STORAGE SUCH    47670013
*        THAT, FOR I = 1 TO 7, THE SLOT AT PREG + 4*I CONTAINS THE      47700013
*        VALUE OF PREG + 4096*I. (C.F. STATIC AND AUTOMATIC ADDRESSING  47730013
*        VECTORS)                                                       47760013
         SPACE                                                          47790013
         LH    R4,ZEQMAX                GET A NEW EQU VALUE AND SLOT    47820013
         LA    R4,1(R4)               IT INTO THE SKELETON CODE         47850013
         C     R4,F32K                  MAKE SURE THAT ALL EQU VALUES   47880013
         BC    BNL,ERROR1             ARE NOT EXHAUSTED                 47910013
         STH   R4,ZEQMAX                                                47940013
         MVC   EQUIN1(2),ZEQMAX                                         47970013
         MVC   EQUIN2(2),ZEQMAX                                         48000013
         LA    R2,ABSCOD                ADD TO CREATED FILE A SEQUENCE  48030013
         LA    R3,ABSLEN              OF ABSOLUTE CODE FOR SETTING UP   48060013
         BAL   R14,ADCBUF             THE ADDRESSING VECTOR             48090013
         SPACE                                                          48120013
         MVC   PAR1+2(2),STE1RF(SCP)                                    48130016
         L     R15,ZDRFAB                                               48140016
         BALR  R14,R15                                                  48150016
         L     R14,PAR1                                                 48160016
         MVC   PSTOR(2),E1PSTO(R14)                                     48170016
         BC    B,LA                   AVAILABLE PRIVATE STORAGE OFFSET  48180013
*                                     AND PROCEED WITH NEXT ITEM        48210013
         SPACE 10                                                       48240013
*              ACTION AT END OF PROLOG (THIS IS INDICATED BY A 'PCBS'   48270013
*        OR 'BGPE' PSEUDO-CODE ITEM)                                    48300013
         SPACE                                                          48330013
ACT10    MVI   PROGSW,OFF               SWITCH OFF PROGSW,ILSW          48360013
         MVI   ILSW,OFF                                                 48390013
         MVI   BSW,ON                  THE FIRST NON PROLOG STATEMENT   48420013
*                                    MUST BE TREATED AS A               48450013
*                                    BRANCH-IN POINT.                   48480013
         BC    B,ACT1                   ADD ITEM TO CREATED FILE AND    48510013
*                                     PROCEED WITH NEXT ITEM            48540013
         SPACE 10                                                       48570013
*              ACTION FOR 'IGNORE' ITEM                                 48600013
         SPACE                                                          48630013
ACT11    MVC   CHTEMP+1(1),2(SP)        UPDATE SP BY LENGTH OF ITEM     48660013
         AH    SP,CHTEMP              AND IGNORE IT, PROCEEDING TO THE  48690013
         BC    B,LA                   NEXT ITEM                         48720013
         SPACE 10                                                       48750013
*              ACTION AT  ABS .  THIS PSEUDO-CODE ITEM PRECEDES A       48780013
*        BLOCK OF ABSOLUTE PROLOG CODE THAT CAN BE SKIPPED OVER         48810013
*        WITHOUT FURTHER ACTION                                         48840013
         SPACE                                                          48870013
ACT12    LA    R3,3                     ADD ITEM TO CREATED FILE        48900013
ACT12A   LR    R2,SP                                                    48930013
         LA    SP,0(R3,SP)                                              48960013
         BAL   R14,ADCBUF                                               48990013
         SPACE                                                          49020013
         CLI   0(SP),EOB                IF END-OF-BLOCK MARKER IS       49050013
         BC    BNE,*+8                FOUND, RESUME SCANNING IN NEXT    49080013
         BAL   R14,GETSBF             SOURCE BUFFER                     49110013
         SPACE                                                          49140013
         CLI   0(SP),ABSP               SCAN SOURCE FILE UNTIL ABS' IS  49170013
         BC    BE,ACT1                FOUND, ADDING TO THE CREATED FILE 49200013
         CLI   0(SP),X'40'            ALL THE ITEMS SKIPPED OVER. THESE 49230013
         BC    BL,ACT12               ITEMS MUST BE RR OR RX INSTRUCT-  49260013
         LA    R3,2                   IONS OR THREE-BYTE PSEUDO-INST-   49290013
         CLI   0(SP),X'70'            RUCTIONS                          49320013
         BC    BL,ACT12A                                                49350013
         LA    R3,5                                                     49380013
         BC    B,ACT12A                                                 49410013
         SPACE 10                                                       49440013
*              ACTION AT PROLOG INSERTION POINT. THIS IS THE POINT AT   49470013
*        THE END OF THE COMMON PROLOG CODE AT WHICH ADDRESSING          49500013
*        INSTRUCTIONS CAN BE INSERTED. IT IS INDICATED BY A PINS        49530013
*        MARKER IN THE PROCEDURE CASE AND A BLBS' MARKER IN THE BEGIN   49560013
*        CASE                                                           49590013
         SPACE                                                          49620013
ACT13    LA    R2,ADIINS                GENERATE PSEUDO-INSTRUCTION TO  49650013
         LA    R3,5                   TELL THE NEXT PHASE TO INSERT     49680013
         BAL   R14,ADCBUF             AT THIS POINT ALL THE ADDRESSING  49710013
*                                     INSTRUCTIONS PLACED IN THE INSER- 49740013
*                                     TION FILE BY THIS PHASE           49770013
         CLI   0(SP),BLBSP              ADD ITEM TO CREATED FILE IF IT  49800013
         BC    BE,ACT1                IS A BLBS', OTHERWISE DELETE IT   49830013
         LA    SP,3(SP)                                                 49860013
         BC    B,LA                                                     49890013
         EJECT                                                          49920013
*                       ACTION FOR SL                                   49950013
         SPACE                                                          49980013
ACT15    MVC   PAR1+2(2),3(SP)                                          50010013
         L     LR,ZDRFAB               CONVERT DICTIONARY REFERENCE     50040013
         BALR  RR,LR                 FOLLOWING SL TO ABSOLUTE.          50070013
         SPACE                                                          50100013
         L     LR,PAR1                                                  50130013
         CLI   0(LR),PET1              IS IT A PROCEDURE ENTRY TYPE 1   50160013
         BC    BE,ACT15B               BRANCH IF IT IS.                 50190013
         MVI   BSW,ON                SET FLAG TO INDICATE BOTH HALVES   50200016
*                                    OF STATEMENT NO. ARE TO BE         50210016
*                                    UPDATED                            50220016
         CLI   0(LR),EET1                                               50230016
         BC    BNE,ACT15D              BRANCH IF NOT ENTRY TYPE  1      50240016
         SPACE                                                          50250016
         MVC   PAR1+2(2),7(LR)                                          50260016
         L     LR,ZDRFAB               DECODE REF TO STMNT LABEL        50270016
         BALR  RR,LR                                                    50280016
         L     LR,PAR1                                                  50290016
ACT15D   EQU   *                                                        50300016
         MVC   STNERS(2),STNLBL(LR)    SAVE THE STATEMENT NUMBER.       50310013
*              IF THE CHECK BIT IS ON, THE STATEMENT NUMBER IS IN       50340013
*        THE BCD ENTRY WHICH IS POINTED AT BY THE STATEMENT NUMBER      50370013
*        SLOT.                                                          50400013
         TM    OTH1LB(LR),CHKBIT       TEST OTHER1 CODE BYTE            50430013
         BC    BZ,ACT15C                                                50460013
         MVC   PAR1+2(2),STNLBL(LR)    DECODE REFERENCE TO BCD ENTRY    50490013
         L     LR,ZDRFAB                                                50520013
         BALR  RR,LR                                                    50550013
         SPACE                                                          50580013
         L     LR,PAR1                                                  50610013
         MVC   STNERS(2),3(LR)         MOVE STATEMENT NUMBER            50640013
         SPACE                                                          50670013
ACT15C   MVC   TEMP(1),STCHNB(SCP)     SET TEMP TO 'OPTIONS-CHANGED'    50700013
*                                    BYTE IN BLOCK STACK ENTRY.         50730013
ACT15A   MVC   PREV(1),CURRNT          SET PREVIOUS TO OPTIONS BYTE     50790013
         MVC   CURRNT(1),2(SP)       WHICH WAS CURRNT, AND PICK UP NEW  50820013
*                                    OPTIONS BYTE.                      50850013
         LR    R2,SP                   SET UP PARAMETERS FOR OUTPUTTING 50880013
*                                    THE SL OR SN.                      50910013
         LA    SP,5(SP)                BUMP SCAN POINTER PAST ITEM.     50940013
         MVC   ZSTAT(2),STNERS         UPDATE ZSTAT                     50970013
         BC    B,GENFLP                BRANCH TO GENERATE INSTRUCTIONS  51000013
*                                    TO SET FLAGS IN DSA.               51030013
ACT15B   MVC   CURRNT,THSPRC           PICK UP STATUS OF OPTIONS BYTE   51060013
*                                    AS IT WAS AT END OF PROLOG.        51090013
         BC    B,ACT2                  BRANCH TO COPY SL TO OUTPUT      51120013
         SPACE 10                                                       51150013
*              ACTION ON SN2 - SECOND FILE STATEMENT NUMBER             51180013
         SPACE                                                          51210013
ACT18    MVC   PAR1+2(2),3(SP)         CALCULATE THE ABSOLUTE ADDRESS   51240013
         L     LR,ZDRFAB             OF THE ITEM WHOSE SECOND FILE      51270013
         BALR  RR,LR                 STATEMENT THIS IS.                 51300013
         SPACE                                                          51330013
         L     RR,PAR1                                                  51360013
         MVC   LOCK(2),3(SP)           LOCK IN THE BLOCK CONTAINING     51390013
*              NOW TEST FOR THE ITEM BEING ARITHMETIC, STRING OR LABEL  51420013
*        DATA.                                                          51450013
         TM    0(RR),7                                                  51480013
         BC    BO,ACT17A               BRANCH IF IT IS                  51510013
         TM    0(RR),14                                                 51540013
         BC    BO,ACT17A               BRANCH IF STRUCTURE              51570013
*              THE TYPE MUST NOW BE ENTRY TYPE 3, 4, OR 5.              51600013
         MVC   HTEMP(2),1(RR)          CALCULATE THE ADDRESS OF THE     51630013
         AH    RR,HTEMP              END OF THE ENTRY, THEN MOVE THE    51660013
         BCTR  RR,0                  STATEMENT NUMBER INTO THE CALL OF  51690013
         BCTR  RR,0                  THE LIBRARY ERROR ROUTINE.         51720013
         MVC   STNERS(2),0(RR)                                          51750013
         BC    B,ACT14A                                                 51780013
         SPACE 2                                                        51810013
ACT17A   LR    R4,RR                                                    51840013
         TM    0(RR),X'20'             IF THE ITEM IS A MEMBER OF A     51870013
         BC    BZ,ACT17E             STRUCTURE AND NOT MAJOR,           51900013
         TM    DOTH4(RR),MAJSTR      THE STATEMENT NUMBER IS IN         51930013
         BC    BZ,ACT17D             THE CORRECT PLACE.                 51960013
ACT17E   TM    DOTH3(RR),NDVBIT        IF THE 'DOPE VECTOR REQUIRED'    51990013
         BC    BZ,ACT17B             BIT IS ONE, THE STATEMENT NUMBER   52020013
         SPACE                                                          52050013
         MVC   PAR1+2(2),STNOFF(RR)  WILL BE IN THE SKELETON DOPE       52080013
         BALR  RR,LR                 VECTOR, IF IT IS NOT, THE NUMBER   52110013
*                                    IS IN THE ENTRY ITSELF.            52140013
         L     RR,PAR1                                                  52170013
*        IF THE DVD BIT IS ON THE STATEMENT NUMBER WILL HAVE            52200013
*        BEEN MOVED INTO THAT ENTRY.                                    52230013
ACT17B   TM    DOTH1(R4),DVDBIT                                         52260013
         BC    BZ,ACT17C               BRANCH IF NO DVD.                52290013
         SPACE                                                          52320013
         MVC   PAR1+2(2),STNOFF(RR)    DECODE REFERENCE TO DVD ENTRY    52350013
         BALR  RR,LR                                                    52380013
         L     RR,PAR1                 SET REGISTER RR TO POINT 8       52410013
         LA    RR,2(RR)              BYTES BEFORE THE STATEMENT NUMBER  52440013
         SPACE                                                          52470013
ACT17C   TM    DOTH4(R4),RDVBIT        IF AN RDV ENTRY HAS BEEN MADE    52500013
         BC    BZ,ACT17D             THE STATEMENT NUMBER IS IN THAT.   52530013
         SPACE                                                          52560013
         MVC   PAR1+2(2),STNOFF(RR)                                     52590013
         BALR  RR,LR                   SET REGISTER RR TO POINT 8       52620013
         L     RR,PAR1                 BYTES BEFORE STATEMENT NUMBER    52650013
         LA    RR,10(RR)             IN RDV ENTRY                       52680013
         SPACE                                                          52710013
ACT17D   MVC   STNERS(2),STNOFF(RR)                                     52740013
         XC    LOCK(2),LOCK            CLEAR LOCK SLOT                  52770013
         BC    B,ACT14A                                                 52800013
         SPACE 10                                                       52830013
*              ACTION ON SN                                             52860013
         SPACE                                                          52890013
ACT14    CLC   3(2,SP),H0              IGNORE THE ITEM IF THE           52920013
         BC    BE,ACT2               STATEMENT NUMBER IS ZERO           52950013
         MVC   STNERS(2),3(SP)         SAVE THE STATEMENT NUMBER        52980013
ACT14A   MVC   TEMP(1),CURRNT          CALCULATE THE DIFFERENCE         53010013
         XC    TEMP(1),2(SP)         BETWEEN THE OLD AND NEW OPTIONS    53040013
*                                    BYTES.                             53070013
         BC    B,ACT15A                                                 53100013
         SPACE 10                                                       53130013
ACT16    MVI   BSW,ON                                                   53160013
ACT16X   CLI   0(SP),CL                IS THIS A CL                     53190013
         BC    BNE,ACT16U              BRANCH IF NOT                    53220013
         SPACE                                                          53250013
         LA    R3,5                    OUT-PUT CL, LENGTH=5             53280013
         LR    R2,SP                                                    53310013
ACT16R   BAL   RR,ADCBUF                                                53340013
         LA    SP,5(0,SP)              BUMP TO NEXT ITEM.               53370013
         BC    B,ACT16X                GO TO EXAMINE IT.                53400013
ACT16U   CLI   0(SP),SL                IF STATEMENT LABEL               53430013
         BC    BE,ACT15                GO TO PROCESS IT AS USUAL        53460013
         SPACE                                                          53490013
         CLI   0(SP),EQUPR             IF EQU' GO TO CHANGE TO EQU THEN 53520013
         BC    BE,ACT16Q             TREAT AS CL                        53550013
         SPACE                                                          53580013
         CLI   0(SP),SN                IF STATEMENT NUMBER, TREAT AS    53610013
         BC    BNE,ACT16V            AS USUAL. BRANCH IF NOT            53640013
         MVC   STNERS(2),3(SP)                                          53670013
         BC    B,ACT15C                                                 53700013
         SPACE                                                          53730013
ACT16Q   MVI   2(SP),EQU               CHANGE EQU' TO EQU AND OUTPUT    53760013
         LA    R2,2(0,SP)            IT                                 53790013
         LA    R3,3                    LENGTH=3                         53820013
         BC    B,ACT16R                                                 53850013
         SPACE                                                          53880013
ACT16V   CLI   0(SP),EOB               IF END OF BLOCK                  53910013
         BC    BE,ACT16W               GO TO GET NEXT BLOCK             53940013
         SPACE                                                          53970013
         MVC   TEMP(1),STCHNB(SCP)     THE LAST EQU' OR CL HAS BEEN     54000013
         MVC   ZSTAT(2),STNERS       SEEN SO GO TO GENERATE PREFIX      54030013
         BC    B,GENY05              OPTIONS CODE.                      54060013
         SPACE                                                          54090013
ACT16W   BAL   RR,GETSBF               GET NEXT BLOCK                   54120013
         BC    B,ACT16X                GO TO EXAMINE FIRST ITEM IN IT   54150013
         SPACE 5                                                        54180013
*              ACTION ON MEETING A FORMAT MARKER.                       54210013
         SPACE                                                          54240013
*              THE SWITCH INDICATING THAT THE SCAN IS IN A REMOTE       54270013
*        FORMAT IS SWITCHED ON.                                         54300013
ACT20    MVI   FMTSW,ON                                                 54330013
         BC    B,ACT1                                                   54360013
         SPACE 5                                                        54390013
*              ACTION ON MEETING AN 'END OF FORMAT' MARKER.             54420013
         SPACE                                                          54450013
*              THE ABOVE SWITCH IS TURNED OFF.                          54480013
ACT21    MVI   FMTSW,OFF                                                54510013
         BC    B,ACT1                                                   54540013
         SPACE 10                                                       54570013
*              ACTION AT THE MARKER INDICATING A SOURCE PROGRAM ERROR   54600013
         SPACE                                                          54630013
*              A CALLING SEQUENCE TO THE LIBRARY ROUTINE IHEERRC        54660013
*        IS GENERATED IN LINE.                                          54690013
         SPACE                                                          54720013
LIBCAL   CLI   LIBENT,ON               BRANCH IF A DICTIONARY ENTRY     54750013
         BC    BE,LIB50              FOR THE LIBRARY ROUTINE HAS BEEN   54780013
*                                    MADE.                              54810013
         L     R2,ZSTACH                                                54840013
         LA    R2,3(R2)                 ALIGN SIZE OF STATIC TO FULL    54870001
         N     R2,MASK1              WORD BOUNDARY                      54900013
         ST    R2,LIBSKT+4             STORE STATIC OFFSET IN SKELETON  54930013
*                                    OF DICT.ENTRY FOR LIBRARY ROUTINE  54960013
         AH    R2,H4                   BUMP SIZE OF STATIC BY 4         54990013
         ST    R2,ZSTACH                                                55020013
         MVI   ZSTACH,ZSTCD            RESET CODE BYTE IN ZSTACH.       55050013
         SPACE                                                          55080013
*              NOW PUT THE ENTRY IN THE DICTIONARY AND ADD IT TO THE    55110013
*        EXTERNALS PART OF STATIC.                                      55140013
         MVC   PAR1+2(2),EXSTAT        DECODE THE REFERENCE TO THE      55170013
         L     LR,ZDRFAB             FIRST ITEM IN EXTERNAL CHAIN.      55200013
         BALR  RR,LR                                                    55230013
         SPACE                                                          55260013
         L     R2,PAR1                                                  55290013
         MVC   LIBSKT+3(2),3(R2)       MOVE THE REFERENCE TO SECOND     55320013
*                                    ITEM IN STATIC CHAIN INTO SKELETON 55350013
         LA    R3,LIBSKT               PUT ADDRESS AND LENGTH OF        55380013
         ST    R3,PAR1               SKELETON IN PAR1 AND PAR2          55410013
         LA    R3,LIBLTH                                                55440013
         ST    R3,PAR2                                                  55470013
         L     LR,ZDICRF               COPY SKELETON INTO DICTIONARY    55500013
         BALR  RR,LR                                                    55530013
         SPACE                                                          55560013
         MVC   3(2,R2),PAR1+2          INSERT NEW ENTRY IN STATIC       55590013
         MVC   LIBRF(2),PAR1+2       EXTERNAL CHAIN, AND IN CODE        55620013
*                                    SKELETON                           55650013
         MVI   LIBENT,ON               INDICATE THAT AN ENTRY HAS BEEN  55680013
*                                    MADE.                              55710013
         SPACE                                                          55740013
*              NOW THE CALLING SEQUENCE MUST BE OUTPUT.                 55770013
         SPACE                                                          55800013
LIB50    LA    SP,3(SP)                BUMP SCAN POINTER PAST ITEM      55830013
         ST    SP,SPSAVE               SAVE SCAN POINTER                55860013
         SPACE                                                          55890013
         LH    R3,ZEQMAX               GET A NEW EQU VALUE AND STORE    55920013
         LA    R3,1(R3)              IN THE CODE SKELETON IN TWO PLACES 55950013
         C     R3,F32K                                                  55980013
         BC    BNL,ERROR1              IT IS AN ERROR IF THE EQU VALUE  56010013
         STH   R3,ZEQMAX             EXCEEDS 32K-1.                     56040013
         MVC   POS1EQ(2),ZEQMAX                                         56070013
         MVC   POS2EQ(2),ZEQMAX                                         56100013
         SPACE                                                          56130013
         LA    SP,LBCODE               SET SCAN POINTER TO CODE         56160013
         BC    B,LAA                 SKELETON AND BRANCH TO OUTPUT.     56190013
         SPACE 10                                                       56220013
*              ACTION ON MEETING MARKER AT END OF ABOVE CALLING         56250013
*        SEQUENCE.                                                      56280013
         SPACE                                                          56310013
LIBEND   L     SP,SPSAVE               RESET SCAN POINTER TO ITEM AFTER 56340013
         BC    B,LAA                 SOURCE ERROR AND CONTINUE SCAN.    56370013
         EJECT                                                          56400013
*              FUNCTION/OPERATION    THIS SECTION OF CODE PERFORMS THE  56430013
*        FOLLOWING TASKS.          1) MARK LAST SOURCE BLOCK FREE       56460013
*                                  2) MARK LAST OUTPUT BUFFER UNWANTED  56490013
*                                  3) MARK INSERTION FILE WANTED        56520013
*                                  4) RELEASE SCRATCH CORE              56550013
*                                  5) RELEASE CONTROL OF IEMRA AND      56580013
*        IEMRB, AND PASS CONTROL TO IEMRF.                              56610013
*                                       6) CHECK THAT NUMBER OF         56620001
*        COMPILER GENERATED LABELS HAS NOT EXCEEDED 16,383              56630001
*                                                                       56640013
*              EXTERNAL ROUTINES - 1) ADCBUF IN IEMRA TO ADD TO OUTPUT  56670013
*        FILE                                                           56700013
*                                  2) ZALTER IN IEMAA TO CHANGE STATUS  56730013
*        OF A TEXT BLOCK.                                               56760013
*                                  3) ZURC IN IEMAA TO RELEASE SCRATCH. 56790013
*                                  4) RLSCTL IN IEMAA TO PASS CONTROL   56820013
*        TO NEXT MODULE                                                 56850013
*                                                                       56880013
*              EXIT-NORMAL   EXIT3 TO PASS CONTROL TO IEMRF             56910013
*                                                                       56940013
*              EXITS-ERROR - NONE                                       56970013
*                                                                       57000013
*              TABLES/WORK AREAS - NONE                                 57030013
*                                                                       57060013
*              NOTES - NO SPECIAL CONDITIONS EXIST.                     57090013
*                                                                       57120013
*                                                                       57150013
ACT8     L     R2,BWDPTR               OUT PUT PREVIOUS BASE WORD       57180013
         MVC   0(5,R2),BWDCDE                                           57210013
         SPACE                                                          57240013
         LA    R2,EOPINS               ADD TO CREATED FILE THE EOP      57270013
         LA    R3,4                  MARKER  FOLLOWED BY A TEXT REFER-  57300013
         BAL   R14,ADCBUF            ENCE TO THE FIRST INSERTION FILE   57330013
*                                    BUFFER. THIS INFORMATION IS REQU-  57360013
*                                    IRED BY THE NEXT PHASE             57390013
         MVC   PAR1+1(3),SBUFNM        MARK CURRENT SOURCE BUFFER FREE  57420013
         MVI   PAR2+3,FREE                                              57450013
         L     R15,ZALTER                                               57480013
         BALR  R14,R15                                                  57510013
         MVC   PAR1+1(3),CBUFNM        MARK CURRENT CREATED BUFFER AS   57540013
         MVI   PAR2+3,UNWANT         UNWANTED                           57570013
         BALR  R14,R15                                                  57600013
         MVC   PAR1+1(3),IBUFNM        MARK CURRENT BUFFER OF           57630013
         MVI   PAR2+3,WANTED         INSERTION FILE AS WANTED           57660013
         BALR  R14,R15                                                  57690013
         BAL   R14,RELTXT               IF USED, MARK FREE TEXT BLOCK   57700001
*                                         USED FOR MDROP TABLE          57710001
         LA    R4,1                    RELEASE SCRATCH CORE             57720013
         ST    R4,PAR1                                                  57750013
         L     R15,ZURC                                                 57780013
         BALR  R14,R15                                                  57810013
         MVC   SIBFNM(1),IBUFNM        SAVE NAME OF CURRENT INSERTION   57840013
*                                    BUFFER                             57870013
         MVC   LOCK(2),H0              UNLOCK ANY DICTIONARY BLOCK      57900013
*                                    THAT IS LOCKED                     57930013
         TM    ZEQMAX,X'C0'             CHECK NO. OF EQU'S LESS THAN    57940001
         BC    BNZ,EQUOFL                 16K - BRANCH IF NOT           57950001
         LA    R4,RABLST               RELEASE BOTH CONTROL SECTIONS    57960013
         ST    R4,PAR1               OF THIS PHASE AND HAND CONROL TO   57990013
         ST    R0,PAR2               RF                                 58020013
         L     R15,RLSCTL                                               58050013
ACT8A    BALR  R14,R15                                                  58080013
         EJECT                                                          58100046
*                  ADCBUF ROUTINE                                       58120046
*                                                                       58140013
*              FUNCTION/OPERATION                                       58170013
*                                                                       58200013
*              THIS ROUTINE ADDS TEXT TO THE CREATED FILE               58230013
         SPACE                                                          58260013
*        PARAMETERS--   R2 POINTS AT THE TEXT TO BE MOVED, AND          58290013
*                       R3 GIVES ITS LENGTH (WHICH MUST BE BETWEEN ONE  58320013
*                           AND THE MINUMUM TEXT BUFFER SIZE)           58350013
         SPACE                                                          58380013
*              REGISTERS--INPUT   R2,R3,R14                             58410013
*                   RESET     CP                                        58440013
*                   CLOBBERED  R4,R15,R3 (R3 IS ALWAYS REDUCED BY ONE)  58470013
         SPACE 3                                                        58500013
ADCBUF   L     R15,CURPTR                                               58530013
         LA    R4,0(R3,R15)            * BUMP R4 BY TEXT LENGTH   38178 58540046
         ST    R4,CURPTR               * UPDATE OUTPUT POINTER    38178 58550046
         CLI   SSFLG,ON                * ARE E LOOKING AT SS INST 38178 58560046
         BNE   ADD1                    * NO, EXIT                 38178 58570046
         CLI   0(R2),ADI               * IS THIS AN ADI           38178 58580046
         BNE   ADD1                    * NO, EXIT                 38178 58590046
         MVI   ADISW,X'F0'             * SAY, HERE GOES AN ADI    38178 58600046
         TM    2(R2),BIT0              * IS THIS FOR FIRST OP     38178 58610046
         BZ    ADD1                    * NO, BYPASS               38178 58620046
         ST    R15,ADILOC              * REMEMBER THIS ADI        38178 58630046
         LA    R4,18(R4)               * ALLOW FOR POSSIBLE       38178 58640046
*                                      * LA,OSM1,SLL,AR SEQUENCE  38178 58650046
ADD1     EQU   *                                                        58660046
         C     R4,CBFMAX                                          38178 58670046
         BNL   AL1                                                38178 58680046
         BCTR  R3,0                    * DECREASE R3 TO LENGTH-1        58690046
         EX    R3,MVC1                 * MOVE TEXT TO CREATED FL        58700046
         BCR   B,R14                    RETURN                          58740013
         SPACE                                                          58770013
MVC1     MVC   0(FILL,R15),0(R2)       DUMMY MOVE INSTRUCTION, USED BY  58800013
*                                     EXECUTE INSTRUCTION ABOVE         58830013
         SPACE 3                                                        58860013
*              CASE OF THERE NOT BEING ENOUGH ROOM LEFT IN THE CURRENT  58890013
*        BUFFER                                                         58920013
         SPACE                                                          58950013
AL1      ST    R14,AFSTOR               STORE LINK                      58980013
         MVI   0(R15),EOB              PLACE 'EOB' MARKER AT END OF     59010013
         MVI   CSTATE,CUNWAN          OLD BLOCK, AND CALL ROUTINE TO    59040013
         BAL   R14,GETCBF             GET NEW BUFFER AND CHAIN IT ON,   59070013
*                                     MARKING THE OLD ONE AS UNWANTED   59100013
         L     R14,AFSTOR               RESTORE LINK REGISTER           59130013
         BC    B,ADCBUF                 BEGIN AGAIN                     59160013
         EJECT                                                          59190013
*                   ADIBUF  ROUTINE                                     59220013
         SPACE                                                          59250013
*              THE ADIBUF ROUTINE ADDS TEXT TO THE INSERTION FILE       59280013
*              ENTRY POINT  ADIBUF                                      59310013
*        PARAMETERS--   R2 POINTS AT THE TEXT TO BE MOVED, AND          59340013
*                       R3 GIVES ITS LENGTH (WHICH MUST BE BETWEEN ONE  59370013
*                          AND TWELVE)                                  59400013
*                                                                       59430013
*              EXTERNAL ROUTINES  - 1) GETIBF TO GET A NEW BUFFER FOR   59460013
*      THE INSERTION FILE.                                              59490013
*              EXIT-NORMAL    AT AF3 ON R14 WHEN ITEM HAS BEEN ADDED    59520013
*                                                                       59550013
*              EXIT-ERROR   NONE                                        59580013
*                                                                       59610013
*              TABLES/WORK AREAS - NONE                                 59640013
*                                                                       59670013
*              NOTES                                                    59700013
*        REGISTERS--INPUT     R2,R3,IP,R14                              59730013
*                   RESET     IP                                        59760013
*                   CLOBBERED  R3,R4,R15                                59790013
         SPACE 3                                                        59820013
ADIBUF   LR    R4,R3                    BRANCH OUT IF CURRENT BUFFER    59850013
         AR    R4,IP                  DOES NOT CONTAIN ENOUGH ROOM      59880013
         C     R4,IBFMAX                (NOTE THAT 'LA' INSTRUCTION     59910013
         BC    BNL,AF1                CANNOT BE USED)                   59940013
AF2      BCTR  R3,0                     DECREASE R3 TO (LENGTH - 1)     59970013
         EX    R3,MVC2                  MOVE TEXT INTO INSERTION FILE   60000013
         LA    IP,1(R3,IP)              UPDATE IP                       60030013
AF3      BCR   B,R14                    RETURN                          60060013
         SPACE                                                          60090013
MVC2     MVC   0(FILL,IP),0(R2)         DUMMY MOVE INSTRUCTION USED BY  60120013
*                                     EXECUTE INSTRUCTION ABOVE         60150013
         SPACE 3                                                        60180013
*              CASE OF THERE NOT BEING ENOUGH ROOM LEFT IN THE CURRENT  60210013
*        BUFFER                                                         60240013
AF1      ST    R14,AFSTOR               STORE LINK                      60270013
         MVI   0(IP),EOB                PLACE 'EOB' MARKER AT END OF    60300013
         MVI   CSTATE,CWANT           OLD BLOCK, AND CALL GETIBF TO GET 60330013
         BAL   R14,GETIBF             A NEW BUFFER AND CHAIN IT ON,     60360013
*                                     MARKING THE OLD BUFFER AS  WANTED 60390013
         L     R14,AFSTOR               RESTORE LINK                    60420013
         BC    B,AF2                    BEGIN AGAIN                     60450013
         EJECT                                                          60480013
*              ADINST ROUTINE                                           60510013
*                                                                       60540013
*              FUNCTION/OPERATION                                       60570013
*        THE ADINST ROUTINE ADDS A SEQUENCE OF INSTRUCTIONS IN SCRATCH  60600013
*        CORE TO EITHER THE INSERTION FILE OR THE CREATED FILE. THE     60630013
*        INSTRUCTION IN SCRATCH ARE IN CONTIGUOUS FIVE-BYTE FIELDS      60660013
*        AND ARE EITHER FIVE-BYTE 'ADI' INSTRUCTIONS OR LEFT-ALIGNED    60690013
*        THREE-BYTE 'PSLD' INSTRUCTIONS                                 60720013
*                                                                       60750013
*              ENTRY POINT   ADINST                                     60780013
*        PARAMETERS--    R2 CONTAINS ZERO IF INSTRUCTIONS ARE TO BE THE 60810013
*                        INSERTION FILE, OR FOUR  IF THEY ARE TO BE     60840013
*                        ADDED TO THE CREATED FILE                      60870013
*                                                                       60900013
*              EXTERNAL ROUTINES -  ADCBUF AND ADIBUF TO ADD            60930013
*        INSTRUCTIONS TO THE CREATED OR INSERTION FILE.                 60960013
*                                                                       60990013
*              EXIT-NORMAL    AT AT2 ON R14 WHEN ALL INSTRUCTIONS       61020013
*        HAVE BEEN OUTPUT                                               61050013
*                                                                       61080013
*              EXIT-ERROR - NONE                                        61110013
*                                                                       61140013
*              TABLES/WORK AREAS   SCRATCH CORE                         61170013
*                                                                       61200013
*                                                                       61230013
*              NOTES                                                    61260013
*        REGISTERS--INPUT     R2,IP,CP,CNP,R14                          61290013
*                   RESET     EITHER IP OR CP                           61320013
*                   CLOBBERED  R2,R3,R4,CNP,R15                         61350013
         SPACE 3                                                        61380013
ADINST   C     CNP,CNPMIN               PERFORM NO ACTION IF THERE ARE  61410013
         BCR   BL,R14                 NO CONSTRUCTED INSTRUCTIONS       61440013
         ST    R14,ATSTOR               STORE LINK                      61470013
         LA    DP,ADCBUF                SET DP TO CONTAIN ADDRESS OF    61500013
         BC    B,*+4(R2)              ROUTINE THAT ADDS CODE TO THE     61530013
         LA    DP,ADIBUF              APPROPRIATE BUFFER                61560013
         ST    CNP,CNSTOP                                               61590013
         L     CNP,CNPMIN               SET CNP TO POINT TO THE         61620013
*                                     INSTRUCTION                       61650013
AT1      LR    R2,CNP                   CALL ROUTINE TO ADD INSTRUCT-   61680013
         LA    R3,5                   ION TO RELEVANT BUFFER, WITH R2   61710013
         CLI   0(R2),ADI              POINTING AT THE INSTRUCTION. THE  61740013
         BC    BE,*+8                 LENGTH IS 3 OR 5 DEPENDING ON     61770013
         LA    R3,3                   WHETHER IT IS AN ADI              61800013
         BALR  R14,DP                                                   61830013
         SPACE                                                          61860013
         C     CNP,CNSTOP               UPDATE CNP AND REPEAT UNTIL     61890013
         LA    CNP,5(CNP)             LAST INSTRUCTION HAS BEEN OUTPUT  61920013
         BC    BL,AT1                                                   61950013
         L     R14,ATSTOR               RETURN                          61980013
         BCR   B,R14                    RETURN                          62010013
         EJECT                                                          62040013
*              ADTEST ROUTINE                                           62070013
*                                                                       62100013
*              FUNCTION/OPERATION                                       62130013
*        THE ADTEST ROUTINE IS ENTERED IF AN ADDRESS FIELD CONTAINS     62160013
*        A REGISTER(R) AND A LITERAL OFFSET(N).THE ROUTINE TESTS IF THE 62190013
*        OFFSET IS 'OUT OF BOUNDS', I.E. NOT BETWEEN 0 AND 4095. IF THE 62220013
*        OFFSET IS NOT OUT OF BOUNDS, THE ROUTINE PERFORMS NO ACTION.   62250013
*        OTHERWISE THE ROUTINE OBTAINS A SYMBOLIC REGISTER (S), AND     62280013
*        EXTENDS N WITH SIGN BITS TO FORM A 24-BIT NUMBER. TAKING X AS  62310013
*        THE FIRST TWELVE BITS OF THIS NUMBER, AND Y AS THE NEXT 12,    62340013
*        THE GENERATED INSTRUCTIONS HAVE FORM                           62370013
*                   LA   S,X                                            62400013
*                   SLL  S,12                                           62430013
*                   AR   S,R                                            62460013
*        THE ADD REGISTER IS NOT GENERATED IF R IS REGISTER ZERO.       62490013
*        THESE ARE GENERATED AS ORDINARY IN-LINE INSTRUCTIONS PRECEDING 62520013
*        THE INSTRUCTION CONTAINING THE OUT OF BOUNDS ADDRESS FIELD.    62550013
*        NO ADI INSTRUCTIONS ARE GENERATED IN THIS CASE. R IS REPLACED  62580013
*        BY S IN THE ORIGINAL INSTRUCTION, AND THE ADDRESS FIELD IS     62610013
*        ASSEMBLED BY LATER PHASES AS AN OFFSET Y FROM REGISTER R.      62640013
*        THE ROUTINE SWITCHES ON DROPSW, A PSEUDO-INSTRUCTION  TO       62670013
*        DROP S IS ADDED TO THE (POSSIBLY NULL) SEQUENCE OF DROP        62700013
*        INSTRUCTIONS FOR THE CURRENT MACHINE INSTRUCTION, AND MVLENG   62730013
*        IS SET AS THE LENGTH IN BYTES OF THIS SEQUENCE. THE DROP       62760013
*        INSTRUCTIONS ARE INSERTED INTO THE CODE AT THE FIRST POSSIBLE  62790013
*        OPPORTUNITY                                                    62820013
*                                                                       62850013
*              ENTRY-POINT  ADTEST CALLED BY BAL  R14,ADTEST            62880013
*        PARAMETERS--    ADSLOT CONTAINS THE OFFSET AND R2 POINTS AT    62910013
*                        THE FIELD IN THE CURRENT MACHINE INSTRUCTION   62940013
*                        WHICH CONTAINS R                               62970013
*                                                                       63000013
*              EXTERNAL ROUTINES - ADCBUF IN IEMRA TO ADD AN ITEM TO    63030013
*        THE CREATED FILE.                                              63060013
*                                                                       63090013
*              EXIT-NORMAL   AT ATEXIT ON R14                           63120013
*                                                                       63150013
*              EXIT-ERROR    TO ERROR1 IF ALL SYMBOLIC REGISTER NUMBERS 63180013
*        HAVE BEEN USED.                                                63210013
*                                                                       63240013
*              TABLES/WORK AREAS - NONE                                 63270013
*                                                                       63300013
*              NOTES                                                    63330013
*        REGISTERS--INPUT     R2,CP,R14                                 63360013
*                   RESET     CP                                        63390013
*                   CLOBBERED  R2,R3,R4,R15                             63420013
         SPACE 3                                                        63450013
ADTEST   LH    R4,ADSLOT                TEST IF OFFSET IS OUT OF        63480013
         CH    R4,H4096               BOUNDS                            63510013
         BC    BNL,ATA                                                  63540013
         LTR   R4,R4                                                    63570013
         BCR   BNM,R14                  IF NOT, RETURN                  63600013
         SPACE                                                          63630013
*              CASE WHERE OFFSET IS OUT OF BOUNDS                       63660013
         SPACE                                                          63690013
ATA      ST    R2,REGPT                 PRESERVE LINK AND PARAMETER     63720013
         ST    R14,ADSTOR                                               63750013
         LH    R3,ZSMREG                OBTAIN A NEW SYMBOLIC REGISTER  63780013
         LA    R3,1(R3)               (S)                               63810013
         CH    R3,H16K                                                  63840013
         BC    BNL,ERROR1                                               63870013
         STH   R3,ZSMREG                                                63900013
         MVC   REGIN1(2),ZSMREG         MOVE S INTO SKELETON MACHINE    63930013
         MVC   REGIN2(2),ZSMREG       INSTRUCTIONS                      63960013
         SRL   R4,12                    SLOT X (SEE COMMENT AT HEAD OF  63990013
         STH   R4,HTEMP               ROUTINE) INTO SKELETON INSTRUCT-  64020013
         MVC   SIZIN(2),HTEMP         IONS                              64050013
         LA    R2,ATSKLT                GENERATE FIRST TWO INSTRUCTIONS 64080013
         LA    R3,13                  (LA AND SLL)                      64110013
         BAL   R14,ADCBUF                                               64140013
         OI    ADISW,X'0F'             * SET ON 2ND HALF SW       38178 64150046
         SPACE                                                          64170013
*              IF R IS REGISTER ZERO, ALL THAT NEEDS TO BE DONE IS      64200013
*        REPLACE IT IN THE ORIGINAL INSTRUCTION BY THE SYMBOLIC         64230013
*        REGISTER. IF IT IS NOT ZERO, IT IS STILL REPLACED IN THE       64260013
*        ORIGINAL INSTRUCTION, AND ALSO AN ADD REGISTER IS OUTPUT.      64290013
         SPACE                                                          64320013
         L     R2,REGPT                PUT 'R' IN ADD REGISTER SKELETON 64350013
         MVC   ARSKLT+3(2),0(R2)                                        64380013
         MVC   0(2,R2),ZSMREG          PUT SYMBOLIC REGISTER IN PLACE   64410013
         CLC   ARSKLT+3(2),H0        OF R.                              64440013
         BC    BE,ATD                  BRANCH IF R ZERO.                64470013
         SPACE                                                          64500013
         MVC   ARSKLT+1(2),ZSMREG      PUT SYMBOLIC REGISTER IN ADD     64530013
*                                    REGISTER SKELETON.                 64560013
         LA    R2,ARSKLT               OUTPUT ADD REGISTER.             64590013
         LA    R3,5                                                     64620013
         BAL   R14,ADCBUF                                               64650013
         SPACE                                                          64680013
ATD      CLI   DROPSW,ON                TEST WHETHER CURRENT INSTRUCTI  64710013
         BC    BE,ATC                 ION HAS PREVIOUSLY HAD AN OFFSET  64740013
*                                     OUT OF BOUNDS (E.G INSTRUCTION    64770013
*                                       MVC  -1(R1),9999(R2)        )   64800013
         SPACE                                                          64830013
*              CASE WHERE THIS IS THE FIRST OCCURRENCE                  64860013
         SPACE                                                          64890013
         MVI   MVLENG,3                 GENERATE INSTRUCTION IN DROPIN  64920013
         MVC   DROPIN+1(2),ZSMREG     TO DROP S, AND SET LENGTH AS 3    64950013
         MVI   DROPSW,ON                SWITCH ON DROPSW                64980013
         MVI   GENFL,ON                SWITCH ON GENERATE FLAG          65010013
         BC    B,ATEXIT                 RETURN                          65040013
         SPACE                                                          65070013
*              CASE WHERE THIS IS THE SECOND OCCURRENCE OF AN OFFSET    65100013
*        OUT OF BOUNDS IN THE CURRENT INSTRUCTION                       65130013
         SPACE                                                          65160013
ATC      MVI   MVLENG,6                 MOVE S INTO SECOND SLOT IN      65190013
         MVC   DROPIN+4(2),ZSMREG     DROPIN, AND SET LENGTH AS SIX     65220013
ATEXIT   L     R14,ADSTOR               RESTORE LINK AND RETURN         65250013
         BCR   B,R14                                                    65280013
         EJECT                                                          65310013
*                       THE ROUTINE GENFLP                              65340013
*                                                                       65370013
*              FUNCTION/OPERATION                                       65400013
*              THIS ROUTINE TAKES AS INPUT TWO BYTES, TEMP AND CURRENT. 65430013
*        IF A ONE BIT IS IN POSITION I IN THE BYTE TEMP, CODE IS        65460013
*        GENERATED TO SET FLAGS IN THE CORRESPONDING ON SLOT TO         65490013
*        ENABLE OR DISABLE THE CONDITION ACCORDING AS THE CORRESPONDING 65520013
*        BIT IN CURRENT IS ONE OR ZERO.                                 65550013
*              THE RETURN FROM THIS ROUTINE IS NOT ON R14, BUT IS       65580013
*        ALWAYS TO LAA.                                                 65610013
*              R2 IS ASSUMED TO BE SET UP TO POINT AT A FIVE BYTE ITEM  65640013
*        TO BE OUTPUT.                                                  65670013
*              ENTRY POINT  GENFLP  CALLED BY BC B,GENFLP. THE          65700013
*        PARAMETERS ARE LISTED ABOVE                                    65730013
*                           GENFL1 IF IN BEGIN PROLOG                   65760013
*                                                                       65790013
*              EXTERNAL ROUTINE  - ADCBUF IN IEMRA TO ADD AN ITEM TO    65820013
*        THE CREATED FILE.                                              65850013
*                                                                       65880013
*              EXIT-NORMAL    BEFORE TESTMP TO LAA, WHEN ALL THE        65910013
*        PREFIX OPTIONS HAVE BEEN GENERATED.                            65940013
*                                                                       65970013
*              EXITS-ERROR  NONE                                        66000013
*                                                                       66030013
*              NOTES- FOR THE CORRECT CODE TO BE GENERATED IT IS        66060013
*        ESSENTIAL THAT THE DICTIONARY REFERENCES FOR PREFIX OPTIONS    66090013
*        SHOULD BE IN THE SAME ORDER IN THE ENTRY TYPE 1 (PROCEDURE     66120013
*        OR BEGIN ) AS THE BITS REPRESENTING PREFIX OPTIONS IN THE      66150013
*        OPTIONS BYTE.                                                  66180013
         SPACE 5                                                        66210013
GENFLP   LA    R3,5                                                     66240013
         BAL   RR,ADCBUF               OUTPUT ITEM REQUIRED.            66270013
         SPACE                                                          66300013
*              OUTPUT CODE TO UPDATE STATEMENT NUMBER SLOT.             66330013
*              UNLESS THIS IS A FORMAT LIST                             66360013
GENY05   CLI   0(SP),FMT                                                66390013
         BC    BNE,GENY07                                               66420013
         MVI   BSW,OFF                                                  66450013
         BC    B,GENFL1                                                 66480013
         SPACE                                                          66510013
GENY07   CLI   0(SP),EOB                                                66540013
         BC    BNE,GENSN               BRANCH IF NOT END OF BUFFER      66570013
         SPACE                                                          66600013
         BAL   RR,GETSBF               GET NEXT INPUT BLOCK AND LOAD SP 66630013
         SPACE                                                          66660013
         BC    B,GENY05                                                 66690013
         SPACE                                                          66720013
GENSN    BAL   RR,UPSN                                                  66750013
         SPACE                                                          66780013
GENFL1   CLI   0(SP),IPRM              IF IPRM WITH X'20' BIT IN        66790015
         BC    BNE,*+12              ITS SECOND BYTE ON                 66800015
         TM    1(SP),X'20'             THEN NO UPDATING OF THE          66810015
         BC    BO,GENY6              ON SLOTS IS REQUIRED (END          66840013
*                                    STATEMENT)                         66870013
         NC    TEMP(1),STCHNB(SCP)     ONLY THE OPTIONS ALTERED IN      66900013
*                                    BLOCK NEED HAVE CODE GENERATED     66930013
*                                    FOR THEM. (BITS ARE SET TO ONE     66960013
*                                    FOR DEFAULT).                      66990013
         CLI   TEMP,ALLZRO             ARE THERE ANY INSTRUCTIONS TO    67020013
         BC    BE,GENY6              BE GENERATED. BRANCH IF NOT        67050013
         LA    R2,FLUSH                PREPARE TO GENERATE MOD 91       67080013
         LA    R3,5                  FLUSH INSTRUCTION                  67110013
MOD1     CH    RR,ADCBUF               ASSEMBLED EFFECTIVELY AS NO OP.  67140013
*                                    BUT MAY HAVE BEEN MODIFIED EARLIER 67170013
*                                    TO A BAL INSTRUCTION               67200013
         LA    R3,STPRLS(SCP)          POINT R3 AT LIST OF DICTIONARY   67230013
         LA    R4,16(R3)               REFERENCES OF PREFIX OPTIONS     67260015
         ST    R4,ENDLST             IES, AND ENDLST TO THE END         67290013
*                                    PREFIX OPTIONS ENABLED.            67320013
         LA    R5,128                  SET R5 TO TEST FIRST BIT         67350013
GENY1    EX    R5,TESTMP               TEST BIT IN TEMP BYTE.           67380013
         BC    BZ,GENY4                BRANCH IF NO CODE IS TO BE       67410013
*                                    GENERATED.                         67440013
         EX    R5,TESTCR               TEST BIT IN CURRENT BYTE         67470013
         BC    BO,GENY2                BRANCH TO GENERATE ENABLING      67500013
*                                    CODE.                              67530013
         MVI   FLAGST,MCOI             SET UP FLAG SETTING INSTRUCTION  67560013
         MVI   FLAGST+2,X'40'        TO DISABLE.                        67590013
         BC    B,GENY3                                                  67620013
GENY2    MVI   FLAGST,MCNI             SET UP FLAG SETTING INSTRUCTION  67650013
         MVI   FLAGST+2,X'BF'        TO ENABLE                          67680013
GENY3    ST    R3,GENSTO                                                67710013
GENY3A   MVC   FLAGST+DESTOF(2),0(R3)                                   67740013
         ST    SP,SPSAVE                                                67770013
         ST    R5,R5SAVE                                                67800013
         LA    SP,FLAGST                                                67830013
         BC    B,LAA                                                    67860013
GENY3B   L     SP,SPSAVE                                                67890013
         L     R5,R5SAVE                                                67920013
         SPACE                                                          67950013
         L     R3,GENSTO                                                67980013
GENY4    SRA   R5,1                    SHIFT TO TEST NEXT BIT.          68010013
         LA    R3,2(R3)                BUMP POINTER TO LIST OF PREFIX   68040013
         C     R3,ENDLST             REFERENCES. BRANCH IF THIS IS NOT  68070013
         BC    BNE,GENY1             THE END.                           68100013
GENY6    CLI   TSW,ON                  END                              68130013
         BC    BNE,LAA                 BRANCH IF NOT IN BEGIN PROLOG    68160013
         MVC   PAR1+2(2),1(SP)         RESET POINTER TO ENTRY TYPE 1    68190013
         L     R15,ZDRFAB                                               68220013
         BALR  R14,R15                                                  68250013
         L     DP,PAR1                                                  68280013
         BC    B,ACT6A                 BRANCH IF YES                    68310013
         SPACE 2                                                        68340013
TESTMP   TM    TEMP,0                  USED FOR TESTING FOR ONE BITS IN 68370013
*                                    SPECIFIC POSITIONS IN TEMP AND     68400013
TESTCR   TM    CURRNT,0              CURRNT.                            68430013
         EJECT                                                          68460013
         EJECT                                                          71730013
*                   RELIBF ROUTINE                                      71760013
*                                                                       71790013
*              FUNCTION/OPERATION                                       71820013
*              THE RELIBF ROUTINE IS SUPPLIED A TEXT REFERENCE TO THE   71850013
*        INSERTION FILE. IT MARKS THE BUFFER DESIGNATED BY THE TEXT     71880013
*        REFERENCE AS WANTED UNLESS IT IS THE CURRENT BUFFER, IN WHICH  71910013
*        CASE IT LEAVES THE BUFFER AS BUSY                              71940013
*                                                                       71970013
*              ENTRY POINT  RELIBF   CALLED BY  BAL  R14,RELIBF         72000013
*        PARAMETERS--    R2 POINTS AT THE TEXT REFERENCE TO BE EXAMINED 72030013
*                                                                       72060013
*              EXTERNAL ROUTINE  ZALTER IN IEMAA TO CHANGE STATUS OF    72090013
*        A TEXT BLOCK.                                                  72120013
*              EXIT-NORMAL ON REGISTER R14, POSSIBLY FROM ZALTER        72150013
*                                                                       72180013
*              EXITS-ERROR  NONE                                        72210013
*                                                                       72240013
*              NOTES                                                    72270013
*        REGISTERS--INPUT     R2,R14                                    72300013
*                   RESET     NONE                                      72330013
*                   CLOBBERED  R15                                      72360013
         SPACE 3                                                        72390013
RELIBF   CLC   IBUFNM(1),0(R2)          IF REFERENCE IS TO CURRENT      72420013
         BCR   BE,R14                 BUFFER THEN RETURN                72450013
         MVC   PAR1+1(3),0(R2)          OTHERWISE CALL ZALTER TO MARK   72480013
         MVI   PAR2+3,WANTED          THE BUFFER WANTED AND RETURN      72510013
         L     R15,ZALTER             CONTROL TO THE POINT OF CALL OF   72540013
         BCR   B,R15                  THIS ROUTINE                      72570013
         EJECT                                                          72600013
*              UPSN ROUTINE                                             72630013
*                                                                       72660013
*              FUNCTION/OPERATION. CODE IS GENERATED TO UPDATE THE      72690013
*        STATEMENT NUMBER SLOT IN THE CURRENT DSA. IF BSW IS ON THE     72720013
*        WHOLE OF THE STATEMENT NUMBER IS UPDATED, IF IT IS NOT, THEN   72750013
*        ONLY ENOUGH CODE TO CHANGE THE STATEMENT NUMBER FROM THE       72780013
*        PREVIOUS ONE TO THE CURRENT IS GENERATED. I.E. CONSIDERING     72810013
*        THE STATEMENT NUMBER AS TWO BYTES ONLY THOSE WHICH CHANGE      72840013
*        ARE ALTERED. THE CODE GENERATED IS ONE OR TWO MOVE IMMEDIATE   72870013
*        INSTRUCTIONS                                                   72900013
*                                                                       72930013
*              ENTRY POINT - UPSN TO PERFORM ABOVE TASK                 72960013
*                                                                       72990013
*              EXTERNAL ROUTINE -ADCBUF IN IEMRA TO ADD THE MVI'S TO    73020013
*        THE OUTPUT                                                     73050013
*                                                                       73080013
*              EXIT NORMAL - ON R14                                     73110013
*                                                                       73140013
*              EXITS ERROR - NONE                                       73170013
*                                                                       73200013
*              TABLES/WORK AREAS - ONLY SKELETONS OF MVI INSTRUCTIONS   73230013
*                                                                       73260013
*              NOTES - REGISTERS R2, R3 AND R15 ARE CLOBBERED. THE      73290013
*        SWITCH BSW INDICATES WHETHER A BRANCH-IN POINT IS BEING        73320013
*        PROCESSED.                                                     73350013
*                                                                       73380013
*                                                                       73410013
*                                                                       73440013
UPSN     ST    R14,ADSTOR              SAVE RETURN REGISTER.            73470013
         TM    CCCODE+3,BIT0                                            73500013
         BCR   BO,R14                  RETURN IF OPTION NOT REQUIRED    73530013
         SPACE                                                          73560013
MOD2     BC    NOP,UPSN0               MAY HAVE BEEN MODIFIED. SEE      73590013
*                                    PHASE INITIALISATION CODE.         73620013
         LA    R2,FLUSH                                                 73650013
         LA    R3,5                                                     73680013
         BAL   RR,ADCBUF                                                73710013
UPSN0    EQU   *                                                        73740013
         CLI   BSW,ON                  BRANCH IF BRANCH-IN POINT IS     73770013
         BC    BE,UPSN1               BEING PROCESSED                   73800013
         SPACE                                                          73830013
         CLC   ZSTAT(2),LSTSN          HAS STATEMENT NUMBER CHANGED     73860013
         L     R14,ADSTOR                                               73890013
         BCR   BE,R14                  RETURN IF NOT                    73920013
         SPACE                                                          73950013
         CLC   ZSTAT(1),LSTSN          HAS FIRST BYTE CHANGED           73980013
         BC    BE,UPSN2                IF NOT ONLY GENERATE CODE FOR    74010013
*                                    SECOND.                            74040013
         SPACE                                                          74070013
UPSN1    MVI   BSW,OFF                 SET BRANCH SWITCH OFF            74100013
         MVC   MVI2SN(1),ZSTAT         GENERATE INSTRUCTION TO UPDATE   74130013
         LA    R2,MVI2               FIRST BYTE OF STATEMENT NUMBER.    74160013
         LA    R3,MVILTH                                                74190013
*                                    BEING PROCESSED.                   74220013
MODIFY   BAL   RR,ADCBUF             IF THERE ARE LESS THAN 256 BYTES   74250013
*                                    STATEMENTS, THE FIRST BYTE OF THE  74280013
*                                    STATEMENT NUMBER CANNOT CHANGE SO  74310013
*                                    THIS INSTRUCTION WILL HAVE BEEN    74340013
*                                    MODIFIED TO A COMPARE HALFWORD     74370013
*                                    (I.E. IN EFFEC, A NO-OP) AT THE    74400013
*                                    START OF THE PHASE.                74430013
UPSN2    MVC   LSTSN(2),ZSTAT          UPDATE RECORD OF LAST STATEMENT  74460013
*                                    NUMBER TO NEW ONE.                 74490013
         MVC   MVI1SN(1),ZSTAT+1       INSERT SECOND BYTE OF STATEMENT  74520013
         LA    R2,MVI1               NUMBER                             74550013
         LA    R3,MVILTH                                                74580013
         L     R14,ADSTOR              OUTPUT THE MVI AND RETURN        74610013
         BC    B,ADCBUF                                                 74640013
         EJECT                                                          74670013
*              ERROR ROUTINES                                           74700013
         SPACE                                                          74730013
*        ONLY THREE TYPES OF ERROR ARE DETECTED BY THIS PHASE, AND ALL  74760013
*        ARE DISASTEROUS. THE ERRORS ARE COMPILER ERROR, SYMBOLIC NAMES 74790013
*        OR EQU VALUE NAMES RUNNING OUT, AND PRIVATE STORAGE OVERFLOW   74820013
         SPACE 3                                                        74850013
*              ACTION AT COMPILER ERROR                                 74880013
         SPACE                                                          74910013
*        A COMPILER ERROR RESULTS IF THERE IS AN ERROR IN THE SOURCE    74940013
*        TEXT OR DICTIONARY, OR IF THE WORKING OF THE PHASE GOES WRONG. 74970013
*        WHEN SUCH AN ERROR IS DETECTED, THE INSTRUCTION                75000013
*              BAL   R4,CMPERR                                          75030013
*        IS EXECUTED, AND THUS THE CAUSE OF THE ERROR CAN BE DEDUCED    75060013
*        FROM R4                                                        75090013
         SPACE                                                          75120013
CMPERR   DC    X'0'                                                     75210015
ERROR1   EQU   *-1                                                      75300015
ERROR2   EQU   *-1                                                      75390015
         EJECT                                                          75480013
*              THE FOLLOWING ARE THE CONSTANTS THAT ARE USED            75510013
         SPACE 3                                                        75540013
*              FULL-WORD CONSTANTS                                      75570013
         SPACE                                                          75600013
F32K     DC    F'32768'                                                 75630013
MASK1    DC    X'FFFFFFFC'              MASK FOR ALIGNING TO A WORD     75660013
*                                     BOUNDARY                          75690013
MASK2    DC    X'FFFFFFF8'                                              75700016
         SPACE 3                                                        75720013
*              HALF-WORD CONSTANTS                                      75750013
         SPACE                                                          75780013
H0       DC    H'0'                                                     75810013
H4       DC    H'4'                                                     75870013
H5       DC    H'5'                                                     75900013
HBLSZ    DC    AL2(BLSTSZ)              SIZE OF STACK ENTRY             75930013
H4096    DC    H'4096'                                                  75990013
H16K     DC    H'16384'                                                 76020013
         SPACE 3                                                        76050013
*              MISCELLANEOUS                                            76080013
         SPACE                                                          76110013
ENDCHN   EQU   MASK1                    END MARKER FOR CHAIN OF TEXT    76140001
*                                         REFERENCES IS X'FFFFFF'       76170001
RABLST   DC    C'RARBRCZZ'                                              76200013
RBNAM    EQU   RABLST+2                                                 76230013
RCNAM    EQU   RBNAM+2                                                  76260013
JMP00    DC    AL1(PIJMP)               'JUMP' INSTRUCTION, USED WHERE  76290013
         DC    AL3(0)                 THERE IS A DISCONTINUITY OF THE   76320013
*                                     INSERTION FILE CODE FOR A BLOCK   76350013
END00    DC    AL1(PIEND)               'END' INSTRUCTION, INDICATING   76380013
*                                     THE END OF THE INSERTION FILE     76410013
*                                     CODE FOR A BLOCK                  76440013
TEMP     DS    C         USED AS A PARAMETER TO GENFLP                  76470013
PREV     DS    C         CONTAINS THE OPTIONS BYTE OF THE PREVIOUS      76500013
*                      STATEMENT                                        76530013
CURRNT   DS    C         CONTAINS THE OPTIONS BYTE OF THE CURRENT       76560013
*                      STATEMENT                                        76590013
THSPRC   DS    C         CONTAINS THE SETTING OF THE OPTIONS BYTE AT    76620013
*                      THE END OF THE PROLOG.                           76650013
         EJECT                                                          76680013
*              SKELETON INSTRUCTIONS FOR ADDITION TO CREATED FILE       76710013
         SPACE                                                          76740013
         DS    0H                  INSTRUCTION TO ALIGN OSMINS+1        76770013
INSTA    DC    AL1(MCLA)           INSTRUCTION OF FORM                  76800013
         DC    AL2(PREG)                LA   PREG,0                     76830013
         DC    AL2(0)                                                   76860013
OSMINS   DC    AL1(OSM1)           OSM1 INSTRUCTION                     76890013
         DC    AL2(FILL)         (FIELD TO BE INSERTED MUST BE ALIGNED  76920013
*                                TO A HALF-WORD BOUNDARY)               76950013
INSTB    DC    AL1(MCSLL)          INSTRUCTION OF FORM                  76980013
         DC    AL2(PREG)                SLL  PREG,12                    77010013
         DC    AL2(12)                                                  77040013
XXXXXX   DC    X'0'                                                     77070013
         DC    AL1(BIT0)                ST   PREG,ADP                   77100013
         DC    AL1(PREG)                                                77130013
         DC    AL2(ADP)          FOLLOWED BY                            77160013
         DC    AL1(OSM1)                OSM1 (INSERTED FIELD)           77190013
         DC    AL2(FILL)                                                77220013
INSTD    DC    AL1(MCLA)           INSTRUCTION OF FORM                  77250013
         DC    AL1(BIT0)                LA   PREG,PREG                  77280013
         DC    AL1(PREG)                                                77310013
         DC    AL2(PREG)                                                77340013
INSTE    DC    AL1(OSM3)           INSTRUCTION OF FORM                  77370013
         DC    AL2(0)                                                   77400013
         DC    AL2(ADP)                OSM3  0  ADP                     77430013
EOPINS   DC    AL1(EOP)            EOP MARKER  FOLLOWED BY FIELD FOR    77460013
         DC    AL3(FILL)         TEXT REFERENCE TO FIRST INSERTION FILE 77490013
*                                BUFFER                                 77520013
ADIINS   DC    AL1(ADI)            SPECIAL 'ADI' INSTRUCTION TO         77550013
         DC    AL1(PIINS)        INDICATE PROLOG INSERTION POINT        77580013
INSTRF   DC    AL3(FILL)                                                77610013
         SPACE                                                          77640013
ATSKLT   DC    AL1(MCLA)                PAIR OF INSTRUCTIONS OF FORM    77670013
REGIN1   DC    AL2(FILL)                     LA   (INSERTED FIELD),0    77700013
         DC    AL2(0)                                                   77730013
         DC    AL1(OSM1)                     OSM1 (INSERTED FIELD)      77760013
SIZIN    DC    AL2(FILL)                                                77790013
         DC    AL1(MCSLL)                    SLL  (INSERTED FIELD),12   77820013
REGIN2   DC    AL2(FILL)                                                77850013
         DC    AL2(12)                                                  77880013
         SPACE                                                          77910013
LASKLT   DC    AL1(MCLA)                INSTRUCTION OF FORM             77940013
         DC    AL2(FILL)                     LA   (INSERTED FIELD),     77970013
         DC    AL2(FILL)                          (INSERTED FIELD)      78000013
         DC    AL1(OSM2)                     OSM2 (INSERTED FIELD)      78030013
         DC    AL2(FILL)                                                78060013
         SPACE                                                          78090013
DROPIN   DC    AL1(DROP)                PAIR OF INSTRUCTIONS OF FORM    78120013
         DC    AL2(FILL)                     DROP (INSERTED FIELD)      78150013
         DC    AL1(DROP)                     DROP (INSERTED FIELD)      78180013
         DC    AL2(FILL)                                                78210013
*              FLAG SETTING INSTRUCTION.                                78240013
FLAGST   DC    AL1(0)    SPACE FOR OPCODE NI OR OI                      78270013
         DC    AL2(0)    SPACE FOR MASK                                 78300013
         DC    AL2(0)    SPACE FOR DICTIONARY REFERENCE TO PREFIX       78330013
         DC    AL1(OSM1)                                                78360013
         DC    AL2(4)    OFFSET OF 4.                                   78390013
         DC    X'FE'                                                    78420013
ARSKLT   DC    AL1(MCAR)               INSTRUCTION OF FORM              78450013
         DC    AL2(FILL)                                                78480013
         DC    AL2(FILL)             AR (INSERTED FIELD),(INSERTED      78510013
*                                                            FIELD)     78540013
DESTOF   EQU   3         OFFSET OF DICTIONARY REFERENCES IN FLAG        78570013
*                      SETTING INSTRUCTION.                             78600013
FLAGLT   EQU   8         LENGTH OF ABOVE INSTRUCTION.                   78630013
         SPACE 3                                                        78660013
*              SKELETON OF DICTIONARY ENTRY FOR LIBRARY ROUTINE         78690013
*        IHEERRC                                                        78720013
         SPACE                                                          78750013
         CNOP  0,4                     ALIGN TO WORD BOUNDARY           78780013
LIBSKT   DC    X'C2000E'               CODE BYTE AND LENGTH             78810013
         DC    5X'00'                  SPACE FOR STATIC CHAIN AND       78840013
*                                    OFFSET                             78870013
         DC    X'4D'                   LIBRARY CODE                     78900013
         DC    X'0000000101'           NO STATEMENT NUMBER,UNIT LEVEL   78930013
*                                    AND COUNT.                         78960013
LIBLTH   EQU   14                      LENGTH OF ABOVE ENTRY            78990013
         SPACE 5                                                        79020013
*              CALLING SEQUENCE TO LIBRARY ROUTINE IHEERRC              79050013
LBCODE   DC    AL1(IPRM)                                                79080013
         DC    AL2(0)                                                   79110013
         DC    AL1(MCL)                                                 79140013
         DC    AL2(LR)                                                  79170013
LIBRF    DC    AL2(FILL)               SPACE FOR DICTIONARY REFERENCE   79200013
*                                    TO LIBRARY ROUTINE                 79230013
         DC    AL1(MCLAP)                                               79260013
         DC    AL2(RR)                 LA' RR,EQU-VALUE                 79290013
POS1EQ   DC    AL2(FILL)                                                79320013
         SPACE                                                          79350013
         DC    AL1(ALIGN)                                               79380013
         DC    AL2(0)                                                   79410013
         SPACE                                                          79440013
         DC    AL1(MCBAL)                                               79470013
         DC    X'80'                                                    79500013
         DC    AL1(LBRA)                                                79530013
         DC    AL2(LR)                                                  79560013
         SPACE                                                          79590013
         DC    AL1(IPRMP)                                               79620013
         DC    AL2(0)                                                   79650013
         SPACE                                                          79680013
         DC    AL1(DCF2)                                                79710013
         DC    X'0300'                                                  79740013
STNERS   DC    AL2(FILL)                                                79770013
         SPACE                                                          79800013
         DC    AL1(EQU)                                                 79830013
POS2EQ   DC    AL2(FILL)                                                79860013
         DC    X'FF'                                                    79890013
         SPACE                                                          79920013
         SPACE 5                                                        79950013
MVI1     DC    AL1(MCMVI)                                               79980013
         DC    X'80'                                                    80010013
MVI1SN   DC    AL1(FILL)                                                80040013
         DC    AL2(13)                                                  80070013
         DC    AL1(OSM1)                                                80100013
         DC    AL2(99)                                                  80130013
         SPACE                                                          80160013
MVI2     DC    AL1(MCMVI)                                               80190013
         DC    X'80'                                                    80220013
MVI2SN   DC    AL1(FILL)                                                80250013
         DC    AL2(13)                                                  80280013
         DC    AL1(OSM1)                                                80310013
         DC    AL2(98)                                                  80340013
         SPACE 2                                                        80370013
FLUSH    DC    X'4100010000'                                            80400013
         EJECT                                                          80430013
*              THE FOLLOWING IS A SEQUENCE OF ABSOLUTE CODE TO SET UP   80460013
*        THE PRIVATE STORAGE ADDRESSING VECTOR. THIS CODE IS IN A FORM  80490013
*        SUITABLE FOR THE FINAL ASSEMBLY PHASE. IT IS IGNORED BY THE    80520013
*        REGISTER ALLOCATOR PHASE                                       80550013
         SPACE                                                          80580013
ABSCOD   DC    AL1(RWA)            ABSOLUTE CODE WHICH MAY BE           80610013
*                                DELETED.                               80640013
         DC    AL2(0)                                                   80670013
INSTC    DC    AL1(MCST)                                                80700013
         DC    X'900D0000'                                              80730013
         DC    AL1(OSM2)                                                80760013
         DC    X'0000'                                                  80790013
         DC    AL1(MCLR)                LR   4,PREG                     80820013
         DC    AL1(X'40'+PREG)                                          80850013
         DC    AL1(MCLA)                LA   1,4(0,PREG)                80880013
         DC    X'10'                                                    80910013
         DC    AL1(PREG)                                                80940013
         DC    AL2(0)                                                   80970013
         DC    AL1(OSM2)                                                81000013
         DC    AL2(4)                                                   81030013
         DC    AL1(MCLA)                LA   2,4(0,0)                   81060013
         DC    X'20000000'                                              81090013
         DC    AL1(OSM2)                                                81120013
         DC    AL2(4)                                                   81150013
         DC    AL1(MCLA)                LA   3,28(0,PREG)               81180013
         DC    X'30'                                                    81210013
         DC    AL1(PREG)                                                81240013
         DC    AL2(0)                                                   81270013
         DC    AL1(OSM2)                                                81300013
         DC    AL2(28)                                                  81330013
         DC    AL1(EQU)                 EQU  (INSERTED EQU VALUE)       81360013
EQUIN1   DC    AL2(FILL)                                                81390013
         DC    AL1(MCAH)                AH   4,=H'4096'                 81420013
         DC    X'40'                                                    81450013
         DC    AL1(SDP)                                                 81480013
         DC    AL2(0)                                                   81510013
         DC    AL1(OSM2)                                                81540013
         DC    AL2(S4096+2)                                             81570013
         DC    AL1(MCST)                ST   4,0(1)                     81600013
         DC    X'40010000'                                              81630013
         DC    AL1(ADR)                                           31644 81640020
         DC    X'0808'                                            31644 81650020
         DC    AL1(MCBXLE)              BXLE R1,R2,(INSERED EQU         81660013
         DC    X'12'                                VALUE)(PBREG)       81690013
         DC    AL1(PBREG+BIT0)                                          81720013
EQUIN2   DC    AL2(FILL)                                                81750013
         DC    AL1(RWA)            END OF ABOVE CODE.                   81780013
         DC    AL2(0)                                                   81810013
         SPACE 2                                                        81840013
ABSLEN   EQU   EQUIN2-ABSCOD+5          LENGTH OF ABSOLUTE CODE         81870013
         EJECT                                                          81900013
*              THE FOLLOWING ARE THE QUANTITIES HAVING INITIAL VALUES   81930013
*        AND THE TEMPORARIES CONTAINING FIELDS THAT ARE PERMANENTLY     81960013
*        ZERO                                                           81990013
         SPACE                                                          82020013
FIRSW    DC    AL1(ON)                  SWITCH TO INDICATE FIRST        82050013
*                                     PROCEDURE STATEMENT               82080013
TSW      DC    AL1(OFF)                SWITCH TO INDICATE BEGIN PROLOG  82110013
LSTSN    DC    H'0'                    HOLDS LAST STATEMENT NUMBER      82140013
DSASIZ   DC    F'0'                     SIZE OF DSA. FIRST BYTE  IS     82170013
*                                     ALWAYS ZERO                       82200013
CHTEMP   DC    H'0'                     USED FOR ONE-BYTE POSITIVE INT- 82230013
*                                     EGERS. FIRST BYTE IS ALWAYS ZERO  82260013
DROPSW   DC    AL1(OFF)                 SWITCH THAT INDICATES DROP      82290013
*                                     INSTRUCTIONS ARE TO BE INSERTED   82320013
LIBENT   DC    AL1(OFF)                 SWITCH TO INDICATE WHETHER A    82350013
*                                     DICTIONARY ENTRY FOR IHEERRC      82380013
*                                     HAS BEEN MADE.                    82410013
BSW      DC    AL1(OFF)       SWITCH FOR UPSN TO INDICATE A BRANCH IN   82440013
*                           POINT.                                      82470013
         EJECT                                                          82500013
*              A LIST OF ALL THE VARIABLES FOLLOWS                      82530013
         SPACE 3                                                        82560013
*              POINTERS                                                 82590013
         SPACE                                                          82620013
ADSTOR   DS    F         STORAGE FOR R14 IN ADTEST                      82650013
AFSTOR   DS    F         STORAGE FOR R14 IN ADIBUF AND ADCBUF           82680013
CNSTOP   DS    F         POINTS TO LAST GENERATED INSTRUCTION IN STACK  82710013
ATSTOR   DS    F         STORAGE FOR R14 IN ADINST                      82770013
STKST    DS    F        POINTER TO STACK ENTRY FOR OUTERMOST BLOCK      82890013
REGPT    DS    F         STORAGE FOR PARAMETER OF ADTEST                82950013
GENSTO   DS    F         STORAGE FOR POINTER TO LIST OF PREFIX OPTIONS  82980013
ENDLST   DS    F         ADDRESS OF END OF THIS LIST.                   83010013
SPSAVE   DS    F                                                        83040013
R5SAVE   DS    F                                                        83070013
ADILOC   DS    F                       * POINTS AT LAST ADI GEND  38178 83080046
         SPACE 3                                                        83100013
*              INTEGERS AND HALF-WORD ALIGNED ITEMS                     83130013
         SPACE                                                          83160013
NLEVEL   DS    H         NUMBER OF PROLOGLESS BLOCKS NESTED WITHIN      83190013
*                      CURRENT BLOCK                                    83220013
HTEMP    DS    H         TEMPORARY                                      83250013
DSAOFT   DS    H         DSA SIZE MODULO 4096                           83280013
         SPACE 3                                                        83310013
*              MISCELLANEOUS                                            83490013
         SPACE                                                          83520013
ADISW    DS    C                       * USED TO IND ADI SEQUENCES38178 83550046
ADITEMP  DS    CL5                     * HOLDS ADI DURING TXT SHFL38178 83580046
MVLENG   DS    C         LENGTH OF CURRENT SEQUENCE OF DPOP INSTRUCT-   83610013
*                      IONS                                             83640013
SSPACE   DS    12C       TEMPORARY AREA FOR SS INSTRUCTION.             83670013
GSVE     DC    2X'0'                                                    83730001
         SPACE 3                                                        83790013
         EJECT                                                          83820013
         SPACE 5                                                        83850013
         LTORG                                                          83860001
         ORG   IEMRA+4095                                               83870001
         END   IEMRA                                                    83880013
