RB       TITLE 'IEMRB, REGISTER ALLOCATION FIRST PASS, PL/I F'          00030013
*    681000                                                        0250 00040013
* R19 150536,258506,437440                                        24680 00045019
* R19 344300                                                      24694 00050019
* R19 604300                                                      25850 00055019
* R19 341500                                                      28477 00057019
* ###    141100-141200,150280,150536         ### - SEE ID#        38178 00058046
*                                                                       00060013
* R21    150539,510300                                            41963 00070021
*                                                                       00090013
*                                                                       00120013
*              STATUS-CHANGE LEVEL 0                                    00150013
*                                                                       00180013
*                                                                       00210013
*                                                                       00240013
*              FUNCTION/OPERATION - THIS ROUTINE ANALYSES AND INSERTS   00270013
*        ADDRESSING MECHANISMS IN THE OUTPUT TEXT AND THE INSERTION     00300013
*        FILE. ON ENTRY THE RELEVANT DICTIONARY REFERENCE IS POINTED    00330013
*        TO AND ANY ASSOCIATED ADDEND IS IN THE CELL ADSLOT. THE        00360013
*        DICTIONARY REFERENCE IS DECOMPOSED INTO A WORD ALIGNED         00390013
*        DICTIONARY ADDRESS AND AN OFFSET, CODE. THE DICTIONARY ENTRY   00420013
*        IS ACCESSED AND APPROPRIATE ACTION TAKEN FOR EACH OF THE       00450013
*        POSSIBLE ENTRY TYPES. A TABLE IS CONSTRUCTED, LISTING THE      00480013
*        VARIOUS STEPS REQUIRED TO ADDRESS THE DATA INDICATED BY THE    00510013
*        REFERENCE. THIS TABLE IS CALLED THE 'STEP' TABLE. TABLE        00540013
*        ENTRIES HAVE THE FOLLOWING FORMAT.                             00570013
*         O                        1                                    00600013
*         ***********************************************************   00630013
*         *NUMBER INDICATING      *FIRST BIT=0.LAST 7 GIVE OFFSET IN*   00660013
*         *ROUTINE TO BE PERFORMED*DICTIONARY ENTRY TO OFFSET SLOT  *   00690013
*         *TO GENERATE ADDRESSING *FIRST BIT=1.LAST 7 GIVE OFFSET IN*   00720013
*         *  INSTRUCTIONS         *BRANCH VECTOR TO SPECIAL ROUTINE.*   00750013
*         ***********************************************************   00780013
*          2                            4                               00810013
*         *******************************************************       00840013
*         *DICTIONARY REFERENCE +      * SYMBOLIC NAME(DICT REF+*       00870013
*         *CODE TO BE USED IN          *CODE)FOR DATA MADE      *       00900013
*         *GENERATED INSTRUCTION FOR   *ACCESSIBLE BY ADDRESSING*       00930013
*         *FINALLY ACCESSING DATA (OR 0*INSTRUCTIONS.           *       00960013
*         *******************************************************       00990013
*                                                                       01020013
*              THE FIRST FIELD MAY BE ONE OF 1 THRU 5.                  01050013
*              1. IMPLIES LOADING OF A REGISTER WITH A 'PSEUDO-         01080013
*        REGISTER' VALUE. THIS IS REQUIRED                              01110013
*                A) FOR CONTROLLED DATA TO ADDRESS THE DATA OR ITS      01140013
*        DOPE VECTOR.                                                   01170013
*                B) FOR NON-CURRENT AUTOMATIC. THE ADDRESS OF THE       01200013
*        START OF NON CURRENT DSA'S IS LOADED FROM THE DISPLAY CELL     01230013
*        IN THE PRV.                                                    01260013
*              IN BOTH THESE CASES IT IS ARRANGED THAT THE PRV OFFSET   01290013
*        BE INSERTED IN THE INSTRUCTION AS A LOAD CONSTANT.             01320013
*                                                                       01350013
*              2. IMPLIES ADDRESSING AUTOMATIC OR STATIC INTERNAL,      01380013
*        WHERE THE OFFSET IS KNOWN. IT REQUIRES THAT A REGISTER BE      01410013
*        LOADED WITH THE ADDRESS OF THE 4K OFFSET IMMEDIATELY BELOW     01440013
*        THAT IMPLIED BY THE KNOWN OFFSET. WITHIN THE FIRST OFFSET      01470013
*        NO REGISTER LOADING IS REQUIRED, ADP, SDP, OR THE REGISTER     01500013
*        LOADED FROM THE DISPLAY CELL. IS USED. WHERE THE ADDRESS IS    01530013
*        WITHIN THE DSA OR STATIC DATA AREA (AS OPPOSED TO BELOW IT),   01560013
*        AND BLOW THE 8TH OFFSET, CODE TO LOAD THE REGISTER FROM THE    01590013
*        ASSOCIATED ADDRESSING VECTOR IS GENERATED IN OTHER CASES CODE  01620013
*        TO LOAD A REGISTER WITH THE APPROPRIATE MULTIPLE OF 4096       01650013
*        USING  LA  REG,CONSTANT(0)   SLL REG,12 , AND FINALLY AN AR    01680013
*        INSTRUCTION TO INCREMENT THE LOADED REGISTER BY THE BASE (     01710013
*        ADP, SDP, OR FROM THE DISPLAY CELL) IS GENERATED.              01740013
*                                                                       01770013
*              3. IMPLIES A SINGLE LEVEL OF INDIRECT ADDRESSING, I.E.   01800013
*        THE GENERATION OF A LOAD INSTRUCTION TO LOAD A REGISTER WITH   01830013
*        THE CONTENTS OF THE CELL ADDRESSED BY THE OFFSET INDICATED IN  01860013
*        THE THIRD FIELD OF THE IMMEDIATELY PRECEDING TABLE ENTRY AND   01890013
*        THE CURRENT BASE. (THIS BASE MAY BE SDP, ADP, OR A REGISTER    01920013
*        LOADED AS A RESULT OF A PRIOR GENERATED INSTRUCTION).          01950013
*                                                                       01980013
*              4. THE THIRD FIELD IS TO BE USED AS OPERAND OF THE       02010013
*        NEXT INSTRUCTION.                                              02040013
*                                                                       02070013
*              5. AN AR INSTRUCTION ADDING THE PRVP INTO THE CURRENT    02100013
*        BASE IS TO BE GENERATED.                                       02130013
*                                                                       02160013
*                                                                       02190013
*              THE FOLLOWING DESCRIBES THE TABLE ENTRIES THAT ARE       02220013
*        CONSTRUCTED FOR THE VARIOUS CASES                              02250013
*                                                                       02280013
*           ***STATIC INTERNAL***    BASE = SDP                         02310013
*                                                                       02340013
*             1) SCALAR NON-STRING, ARRAYS AND STRINGS ADDRESSED        02370013
*        DIRECTLY                                                       02400013
*                  2       5      DR+0     DR+0                         02430013
*             2) ARRAYS AND STRINGS ADDRESSED VIA DOPE VECTOR           02460013
*                  2      22      DR+1     DR+1                         02490013
*                  3       0       0       DR+0                         02520013
*             3) ALL DEDS                                               02550013
*                  2       5      DR+2     DR+2                         02580013
*           ***STATIC EXTERNAL***   BASE = SDP                          02610013
*             1) SCALARS NOT IN STRUCTURES                              02640013
*                 2        5      DR+3    DR+3                          02670013
*                 3        0      0       DR+0                          02700013
*             2) ARRAYS AND STRINGS NOT IN STRUCTURES                   02730013
*                 2        5      DR+3    DR+3                          02760013
*                 3        0      0       DR+1                          02790013
*                 3        0      0       DR+0                          02820013
*             3) STRUCTURE MEMBERS                                      02850013
*                 2        5      DR(MAJ.STR)+3   DR(MAJ.STR)+3         02880013
*                 3        5      DR+1    0 OR DR+1 FOR STRINGS/ARRAYS  02910013
*                 3        0      0       DR+0                          02940013
*                                                                       02970013
*           ***AUTOMATIC OF CURRENT BLOCK***  BASE = ADD                03000013
*              AS FOR STATIC INTERNAL                                   03030013
*                                                                       03060013
*           ***AUTOMATIC OF NON CURRENT BLOCK*** BASE= PRVP             03090013
*                 1        0      BLKREF+2  0                           03120013
*                 THEN AS FOR STATIC INTERNAL                           03150013
*         BLKREF IS THE REFERENCE OF THE ENTRY TYPE1 FOR THE BLOCK      03180013
*         IN WHICH THE VARIABLE WAS DECLARED.                           03210013
*                                                                       03240013
*           ***PARAMETER IN CURRENT BLOCK***  BASE = ADP                03270013
*              THEN AS FOR STATIC EXTERNAL                              03300013
*                                                                       03330013
*           ***PARAMETER IN NON-CURRENT BLOCK*** BASE = PRVP            03360013
*                 1        0      BLKREF+2  0                           03390013
*              THEN AS STATIC EXTERNAL                                  03420013
*                                                                       03450013
*           ***CONTROLLED***                                            03480013
*             1) SCALARS NOT IN STRUCTURES                              03510013
*                 1        0      DR+3      0                           03540013
*             2) ARRAYS/STRINGS NOT IN STRUCTURES                       03570013
*                 1        0      DR+3      0                           03600013
*                 3        0      0         0                           03630013
*             3) STRUCTURE MEMBERS                                      03660013
*                 1        0      DR(MAJ.STR)+3   0                     03690013
*                 4        0      DR+1            0                     03720013
*                 3        0      0               0                     03750013
*                                                                       03780013
*           ***CONTROLLED PARAMETERS***  BASE = ADP IF CURRENT BLOCK    03810013
*                                               OTHERWISE PRVP          03840013
*              THE FIRST ENTRY IN EACH TABLE IS OMITTED IF THE ITEM     03870013
*              IS INTERNAL TO THE CURRENT BLOCK.                        03900013
*             1) SCALARS NOT IN STRUCTURES                              03930013
*                 1        0      BLKREF+2  0                           03960013
*                 2        5      DR+3      DR+3                        03990013
*                 3        0      0         0                           04020013
*                 5        0      0         0                           04050013
*                 3        0      0         DR+0                        04080013
*             2) ARRAYS/STRINGS NOT IN STRUCTURES                       04110013
*                 1        0      BLKREF+2  0                           04140013
*                 2        5      DR+3      DR+3                        04170013
*                 3        0      0         0                           04200013
*                 5        0      0         0                           04230013
*                 3        0      0         DR+1                        04260013
*                 3        0      0         DR+0                        04290013
*             3) STRUCTURE MEMBER                                       04320013
*                 1        0      BLKREF+2  0                           04350013
*                 2        5      DR(MAJ.STR)+3  DR(MAJ.STR)+3          04380013
*                 3        0      0         0                           04410013
*                 5        0      0         0                           04440013
*                 3        0      0         0 OR DR+1 IF ARRAY/STRING   04470013
*                 3        0      0         DR+0                        04500013
*                                                                       04530013
*              ON COMPLETION OF THE ABOVE TABLE IT IS SCANNED FROM MOST 04560013
*        RECENT ENTRY TO FIRST TO DETERMINE WHETHER CODE TO COMPUTE     04590013
*        ANY OF THE ADDRESSES IMPLIED BY TABLE ENTRIES HAS ALREADY      04620013
*        BEEN GENERATED.                                                04650013
*                                                                       04680013
*        THIS DETERMINATION IS ACHIEVED BY ACCESSING THE DICTIONARY     04710013
*        ENTRY LISTED IN THE FOURTH TABLE FIELD AND FOLLOWING A CHAIN   04740013
*        WHICH STARTS THERE AND INCLUDES DETAILS OF CODE GENERATED AND  04770013
*        ASSOCIATED WITH THAT DICTIONARY ENTRY. A SATISFACTORY MATCH    04800013
*        IS FOUND WHEN AN ENTRY SPECIFYING THE CURRENT BLOCK NUMBER AND 04830013
*        CODE (DICTIONARY REFERENCE FROM WORD BOUNDARY) IS DETECTED.    04860013
*        THIS ENTRY SPECIFIES THE PRIVATE STORAGE OFFSET WHERE THE      04890013
*        ADDRESS IS STORED. INSTRUCTIONS ARE CONSTRUCTED TO LOAD A      04920013
*        REGISTER FROM THIS PRIVATE STORAGE CELL.                       04950013
*              IF A MATCH IS FOUND THE SCAN IS REVERSED FROM THAT POINT 04980013
*        AND CODE IS PRODUCED FOR THE ENTRIES MET. THE CODE TO BE       05010013
*        PRODUCED IS DETERMINED BY THE LEADING CODE BYTE IN THE TABLE   05040013
*        ENTRY.                                                         05070013
*              IF NO MATCH IS FOUND THE REVERSE SCAN IS CARRIED OUT     05100013
*        OVER THE WHOLE OF THE TABLE.                                   05130013
*              WHEN A TYPE 2 ENTRY IS BEING CONSIDERED IT MAY BE THAT   05160013
*        ADDRESSING INSTRUCTIONS HAVE BEEN PRODUCED FOR ANOTHER         05190013
*        VARIABLE, PRODUCING IN PRIVATE STORAGE THE ADDRESS OF A FOUR   05220013
*        K SECTION WHICH IS BELOW THE DESIRED ADDRESS, AND WITHIN FOUR  05250013
*        K OF IT. DETAILS OF THIS KIND OF ADDRESSING ARE CHAINED FROM   05280013
*        THE STACK ENTRY FOR THE BLOCK IN WHICH THE VARIABLE IS         05310013
*        INTERNAL.                                                      05340013
*              THE ADDRESSING INSTRUCTIONS ARE ALL 'ADI' INSTRUCTIONS   05370013
*        AS DESCRIBED IN THE INTRODUCTION TO IEMRA.                     05400013
*                                                                       05430013
*                                                                       05460013
*                                                                       05490013
*              ENTRY POINT - DRTEST  REGISTER R2 POINTS AT THE          05520013
*        DICTIONARY REFERENCE TO BE EXAMINED. THIS IS THE ONLY ENTRY    05550013
*        POINT, THE WHOLE MODULE BEING ONE ROUTINE TO PERFORM THE       05580013
*        TASKS DESCRIBED ABOVE.                                         05610013
*                                                                       05640013
*                                                                       05670013
*                                                                       05700013
*              INPUT - THE DICTIONARY AND THE ASSOCIATED CHAINS IN THE  05730013
*        INSERTION FILE WHICH HAVE BEEN CREATED BY PREVIOUS CALLS TO    05760013
*        THIS ROUTINE. THE FORMAT IS DESCRIBED IN OUTPUT.               05790013
*                                                                       05820013
*                                                                       05850013
*                                                                       05880013
*              OUTPUT - ADI INSTRUCTIONS IN THE OUTPUT STREAM OR        05910013
*        INSERTION FILE. THEIR FORMAT IS DESCRIBED IN THE DESCRIPTION   05940013
*        AT THE START OF IEMRA.                                         05970013
*                     - CHAIN ENTRIES IN THE INSERTION FILE. THESE      06000013
*        ENTRIES ARE USED FOR RECORDING DETAILS OF ADDRESSES WHICH      06030013
*        HAVE BEEN CALCULATED PREVIOUSLY. THE CHAIN HEADS ARE IN        06060013
*        EITHER A DICTIONARY ENTRY FOR THE ITEM ADDRESSED OR THE        06090013
*        STACK ENTRY FOR THE BLOCK IN WHICH THE ITEM IS INTERNAL. THE   06120013
*        TYPES OF ENTRY MADE IN THE INSERTION FILE ARE AS FOLLOWS       06150013
*                                                                       06180013
*              1) X'FF' OR X'7F' ENTRIES WHICH ARE EIGHT BYTES LONG     06190001
*        AND MAY BE IGNORED BY THE NEXT PHASE. EACH ENTRY CONTAINS      06200001
*        DETAILS OF ADDRESSES CALCULATED BY DRTEST, AND THEY ARE        06210001
*        USED TO FACILITATE THE COMMONING OF BASES IN THE OBJECT CODE.  06220001
*                     1     2      3       5           8                06240013
*              ****************************************                 06270013
*              *ABOVE*BLOCK* CODE * PSTOR *TEXT REF OF*                 06300013
*              *BYTE * NO. *      *       *NEXT ENTRY *                 06330013
*              ****************************************                 06360013
*                                                                       06390013
*              BLOCK NO -  NUMBER OF BLOCK IN WHICH ADDRESS IS          06420013
*                   REQUIRED (FOR DATA ITEM),OR NUMBER OF BLOCK TO      06450013
*              WHICH REQUIRED ADDRESS IS LOCAL                          06480013
*              CODE - OFFSET FROM WORD BOUNDARY IN DICTIONARY REFERENCE 06510013
*              CASE, OTHERWISE SECTION NUMBER (OFFSET/4096) (BLOCK      06540013
*              CASE.                                                    06570013
*                                                                       06600013
*              PSTOR - OFFSET FROM REGISTER 9 (PREG) WHERE ADDRESS      06630013
*              IS STORED.                                               06660013
*                                                                       06690013
*        THE CODE BYTE '7F' INDICATES THAT THE ENTRY WAS CONSTRUCTED    06720013
*        FROM A TYPE 2 STEP TABLE ENTRY, AND HENCE THE ADDRESSING       06750013
*        INSTRUCTIONS CALCULATE THE ADDRESS OF THE NEAREST 4K SECTION   06780013
*        RATHER THAN THE ADDRESS OF THE ITEM ITSELF.                    06810013
*                                                                       06840013
*        2)    'FE' ENTRY - THIS IS USED TO CONTAIN THE CONTENTS OF     06870013
*        THE SLOT IN A DICTIONARY ENTRY WHICH BECOMES THE CHAIN HEAD.   06900013
*        THE FORMAT IS                                                  06930013
*                     1        4       6                                06960013
*              ************************                                 06990013
*              *X'FE'*PREVIOUS* DICT  *                                 07020013
*              *     *CONTENTS* REF   *                                 07050013
*              ************************                                 07080013
*                                                                       07110013
*        3)    '21' END OF INSERTION FILE TEXT BLOCK                    07140013
*                                                                       07170013
*        4)    '00' DISCONTINUITY IN ADDRESSING INSTRUCTIONS IN         07200013
*              INSERTION FILE. THE TEXT REFERENCE OF THE NEXT ITEM      07230013
*              FOLLOWS THE X'00'                                        07260013
*        5)    '01' END OF ADDRESSING INSTRUCTIONS                      07290013
*                                                                       07320013
*                                                                       07350013
*                                                                       07380013
*              EXTERNAL ROUTINES- THE FOLLOWING ROUTINES IN IEMAA ARE   07410013
*        CALLED.                                                        07440013
*              1)ZDRFAB TO CONVERT A DICTIONARY REFENCE TO AN ADDRESS   07470013
*              2)ZTXTAB TO CONVERT A TEXT REFERENCE TO ABSOLUTE         07500013
*              3)ZTXTRF TO CONVERT A TEXT ADDRESS TO A REFERENCE        07530013
*                                                                       07560013
*              THE ROUTINES AND DATA IN IEMRA WHICH ARE USED IN THIS    07590013
*        CONTROL SECTION ARE GIVEN IN THE EQU'S UNDER THE TITLE         07620013
*             'OFFSETS OF TRANSFER VECTOR AND COMMON DATA IN FIRST      07650013
*        CONTROL SECTION'.                                              07680013
*                                                                       07710013
*                                                                       07740013
*                                                                       07770013
*              EXIT-NORMAL - AT DREXIT ON COMPLETION OF CREATION OF     07800013
*        ADDRESSING INSTRUCTIONS (IF ANY).                              07830013
*                                                                       07860013
*                                                                       07890013
*                                                                       07920013
*              EXITS-ERROR - WHEN AN ERROR IN THE INPUT IS FOUND A      07950013
*        BAL  R4,CMPERR  IS EXECUTED. R4 THE CONTAINS THE ADDRESS OF    07980013
*        THE CODE FOLLOWING THAT WHICH FOUND THE ERROR.                 08010013
*                                                                       08040013
*                                                                       08070013
*                                                                       08100013
*              TABLES/WORK AREAS. THE ONLY MAJOR WORK AREA IS THE STEP  08130013
*        TABLE. ITS PURPOSE AND THE FORMAT OF IS ENTRIES IS DESCRIBED   08160013
*        ABOVE UNDER 'FUNCTION/OPERATION'.                              08190013
*                                                                       08220013
*                                                                       08250013
*                                                                       08280013
*              ATTRIBUTES - THIS MODULE IS REUSABLE.                    08310013
*                                                                       08340013
*                                                                       08370013
*                                                                       08400013
*              NOTES - REGISTER USAGE IS DESCRIBED IN THE EQU'S         08430013
*        BELOW.  THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A    08460013
*        PARTICULAR INTERNAL PEPRESENTATION OF THE EXTERNAL CHARACTER   08490013
*        SET.                                                           08520013
         EJECT                                                          08527001
*        ALTERATIONS TO PHASE RB FOR VERSION 5.                         08534001
         SPACE 2                                                        08541001
*        1)    RC HAS BEEN REORGANISED, AND ROUTINES IN RC ARE          08548001
*        BRANCHED TO BY A TRANSFER VECTOR HELD IN RC. LABELS            08555001
*        REFERENCED IN RB HAVE BEEN RE-EQUATED.                         08562001
         EJECT                                                          08569001
IEMRB    START 0                                                        08580013
RB       EQU   IEMRB                                                    08610013
         USING *,R12                                                    08640013
RA       EQU   *+4096         THIS IS A TRICK THAT IS USED BECAUSE      08670013
         USING RA,R10       DSECTS ARE UNAVAILABLE                      08700013
COMREG   EQU   *+8192                                                   08730013
         USING COMREG,R11                                               08760013
DB       EQU   *+12288                                                  08790013
         USING DB,R13                                                   08820013
RC       EQU   *+16384                                                  08850013
         USING RC,8                                                     08880013
         EJECT                                                          08910013
*              THE COMPLETE LIST OF QUANTITIES EQUATED WITH CONSTANTS   08940013
*        FOLLOWS. IF ONE OF THESE CONSTANTS CHANGES IT IS ALWAYS        08970013
*        SUFFICIENT JUST TO CHANGE THE RELEVANT EQU CARD                09000013
         SPACE 3                                                        09030013
*              REGISTER USAGE                                           09060013
         SPACE                                                          09090013
*                   CONTENTS OF REGISTER           DOMAIN OF USAGE      09120013
         SPACE                                                          09150013
R0       EQU   0    ALWAYS CONTAINS ZERO               THROUGHOUT       09180013
SP       EQU   1    SOURCE POINTER                     OUTSIDE DRTEST   09210013
OP       EQU   1    POINTER TO CURRENT DICT. ENTRY    DURING STEP-TABLE 09240013
*                                                   BUILDING IN DRTEST  09270013
OFT      EQU   1    VALUE OF OFFSET                   AFTER  STEP-TABLE 09300013
*                                                   BUILDING IN DRTEST  09330013
R2       EQU   2    PARAMETER AND WORKING REGISTER     THROUGHOUT       09360013
R3       EQU   3    PARAMETER AND WORKING REGISTER     THROUGHOUT       09390013
R4       EQU   4    PARAMETER AND WORKING REGISTER     THROUGHOUT       09420013
R5       EQU   5    WORKING REGISTER                   OUTSIDE DRTEST   09450013
TP       EQU   5    STEP-TABLE POINTER                 IN DRTEST        09480013
IP       EQU   6    INSERTION FILE POINTER             THROUGHOUT       09510013
DP       EQU   7    WORKING REGISTER, USUALLY A        THROUGHOUT       09540013
*                   DICTIONARY POINTER                                  09570013
CP       EQU   8    CREATED FILE POINTER               THROUGHOUT       09600013
CNP      EQU   9    POINTER TO CREATED INSTRUCTION     SECOND HALF OF   09630013
*                   IN SCRATCH CORE                    DRTEST           09660013
SCP      EQU   9    STACK POINTER                      OUTSIDE SECOND   09690013
*                                                      HALF OF DRTEST   09720013
R10      EQU   10   PROGRAM BASE                       THROUGHOUT       09750013
R11      EQU   11   POINTER TO COMPILER CONTROL REGION THROUGHOUT       09780013
R12      EQU   12   SECOND PROGRAM BASE                THROUGHOUT       09810013
R13      EQU   13   POINTER TO COMMUNICATIONS REGION   THROUGHOUT       09840013
R14      EQU   14   LINK REGISTER                      THROUGHOUT       09870013
RR       EQU   R14  PSEUDONYM FOR R14                  THROUGHOUT       09900013
R15      EQU   15   DESTINATION ADDRESS REGISTER       THROUGHOUT       09930013
LR       EQU   R15  PSEUDONYM FOR R15                  THROUGHOUT       09960013
         SPACE 3                                                        09990013
*              BIT MASKS FOR TM AND IMMEDIATE INSTRUCTIONS              10020013
         SPACE                                                          10050013
BIT0     EQU   X'80'                                                    10080013
BIT1     EQU   X'40'                                                    10110013
BIT2     EQU   X'20'                                                    10140013
BIT3     EQU   X'10'                                                    10170013
BIT4     EQU   X'08'                                                    10200013
BIT5     EQU   X'04'                                                    10230013
BIT6     EQU   X'02'                                                    10260013
BIT7     EQU   X'01'                                                    10290013
BITS01   EQU   X'C0'                                                    10320013
BITS67   EQU   X'03'                                                    10350013
BITS12   EQU   X'60'                                                    10380013
BITS23   EQU   X'30'                                                    10410013
BIT456   EQU   X'0E'                                                    10440013
         SPACE 3                                                        10470013
*              OFFSETS IN STACK ENTRY FOR BLOCK                         10500013
         SPACE                                                          10530013
BLSTSZ   EQU   38                      SIZE OF STACK ENTRY              10560015
         SPACE                                                          10590013
STW2OF   EQU   1         OFFSET TO WORKSPACE 2 ADDRESS SLOT.            10620013
STCHD    EQU   4         OFFSET OF ADDRESSING CHAIN HEADER              10650013
STE1RF   EQU   12        OFFSET OF REFERENCE TO ENTRY TYPE 1            10680013
STLEV    EQU   15        OFFSET OF LEVEL NUMBER                         10710013
STBLOC   EQU   16        OFFSET OF BLOCK NUMBER                         10740013
STADOF   EQU   2         OFFSET OF FIELD CONTAINING DSA OFFSET OF       10770013
*        ADDRESSING VECTOR                                              10800013
STWSP    EQU   34                  OFFSET TO STACKED DICT REF TO 1ST    10820015
*                                  WORK SPACE REQUIREMENT               10840015
STWSP3   EQU   36             OFFSET TO STACKED DICTIONARY REFERENCE TO 10860015
         SPACE 3                                                        10890013
*              OFFSETS OF FIELDS IN DICTIONARY ENTRIES                  10920013
         SPACE                                                          10950013
ELABTV   EQU   5         POINTER TO TRANSFER VECTOR IN ENTRY LABEL      10980013
*                      ENTRY                                            11010013
E1DSA    EQU   25        SIZE OF DSA IN ENTRY TYPE 1                    11040013
E1LEV    EQU   3         LEVEL NUMBER OF ENTRY TYPE 1                   11070013
E1SYM    EQU   23        REFERENCE TO SYMBOL TABLE ENTRY OF ENTRY TYPE1 11100013
E18AD    EQU   28        OFFSET OF ADDRESSING VECTOR IN ENTRY TYPE 1    11130013
E1RTSW   EQU   34        OFFSET OF RETURN SWITCH FOR ENTRY TYPE 1       11160013
E1RET    EQU   37        OFFSET OF RETURN POINTER FOR ENTRY TYPE 1      11190013
E1PSTO   EQU   19        SLOT IN ENTRY TYPE 1 WHERE SIZE OF PRIVATE     11220013
*                      STORAGE IS STORED BETWEEN PHASES                 11250013
E1CNWK   EQU   31        OFFSET OF CONTROLLED WORKSPACE IN ENTRY TYPE 1 11280013
E1T2WK   EQU   58        OFFSET OF CONTROLLED WORKSPACE IN ENTRY TYPE1  11310013
E2DED    EQU   12        REFERENCE TO DED OF ENTRY TYPE 2               11340013
E3E1     EQU   3         REFERENCE TO ENTRY TYPE 1 FROM ENTRY TYPE 3    11370013
E3E2     EQU   5         REFERENCE TO ENTRY TYPE 2 FROM ENTRY TYPE 3    11400013
E3RET    EQU   7         OFFSET OF RETURNED VALUE IN ENTRY TYPE 3       11430013
E4ADCN   EQU   5         OFFSET OF LOAD CONSTANT IN ENTRY TYPE 4 OR 5   11460013
E4RET    EQU   8         OFFSET FOR RETURNED VALUE IN ENTRY TYPE 4 OR 5 11490013
E4DED    EQU   18        REFERENCE TO DED FOR ENTRY TYPE 4 OR 5         11520013
LABBCD   EQU   8         OFFSET OF REFERENCE TO BCD OF LABEL CONSTANT.  11550013
LABOFF   EQU   5         OFFSET OF LOAD CONSTANT FOR LABEL CONSTANT     11580013
DOFF     EQU   5         FIRST OFFSET SLOT FOR DATA VARIABLE, LABEL     11610013
*                      VARIABLE OR STRUCTURE                            11640013
DHASH    EQU   3         HASH CHAIN FOR ABOVE TYPES OF ENTRY            11670013
DDECNO   EQU   8         DECLARE NUMBER FOR ABOVE                       11700013
DOTH1    EQU   10        OTHER 1 BYTE FOR ABOVE                         11730013
DOTH2    EQU   DOTH1+2   OTHER 2 BYTE FOR ABOVE                         11760013
DOTH3    EQU   DOTH1+3   OTHER 3 BYTE FOR ABOVE                         11790013
DOTH4    EQU   DOTH1+4   OTHER 4 BYTE FOR ABOVE                         11820013
DVAR     EQU   DOTH1+1   VARIABLE BYTE FOR ABOVE                        11850013
DDAT     EQU   DOTH1+5   DATA BYTE FOR DATA VARIABLE                    11880013
DDED     EQU   19        REFERENCE TO DED FOR DATA VARIABLE             11910013
DVARIN   EQU   21        VARIABLE INFORMATION FOR DATA VARIABLE         11940013
SVARIN   EQU   15        VARIABLE INFORMATION FOR STRUCTURE OR LABEL    11970013
*                      VARIABLE                                         12000013
DCDED    EQU   10        REFERENCE TO DED FOR DATA CONSTANT             12030013
ONLEV    EQU   9         LEVEL NUMBER IN ON CONDITION ENTRY             12060013
FILLEV   EQU   21        LEVEL NUMBER IN FILE PARAMETER                 12090013
FIRSOF   EQU   5         OFFSET OF FIRST OFFSET SLOT                    12120013
DVSKLT   EQU   8         REFENCE TO DOPE VECTOR SKELETON IN TEMPORARY   12150013
*                      DOPE VECTOR                                      12180013
SKDOPE   EQU   11                                                       12210013
*                      VECTOR SKELETON                                  12240013
DEDOFF   EQU   5         FIRST OFFSET SLOT IN DED ENTRY                 12270013
SYMOFF   EQU   5         FIRST OFFSET SLOT IN SYMBOL TABLE ENTRY        12300013
D2OFF    EQU   22        SECOND OFFSET SLOT FOR DATA VARIABLE (CONSID-  12330013
*                      ERED AS A 3-BYTE OFFSET FIELD)                   12360013
SL2OFF   EQU   16        DITTO FOR LABEL OR STRUCTURE                   12390013
SYMTOF   EQU   11        OFFSET TO SYMBOL TABLE OFFSET                  12420013
RDVITM   EQU   8         OFFSET OF THE DICTIONARY REFERENCE OF OWNER    12450013
*                      OF THE RDV ENTRY.                                12480013
         SPACE 3                                                        12510013
*              OFFSETS AND FIELD SIZES IN VARIABLE INFORMATION          12540013
         SPACE                                                          12570013
OFF2SZ   EQU   3         SIZE OF OFFSET 2 SLOT, NOT INCLUDING THE BIT   12600013
*                      OFFSET BYTE                                      12630013
DIMSIZ   EQU   3         SIZE OF DIMENSIONALITY INFORMATION             12660013
CONTOF   EQU   2         OFFSET FROM START OF STRUCTURING INFORMATION   12690013
*                      OF REFERENCE TO CONTAINING STRUCTURE             12720013
NXELOF   EQU   4         OFFSET FROM START OF STRUCTURING INFORMATION   12750013
*                      OF REFERENCE TO NEXT STRUCTURE ELEMENT           12780013
         SPACE 3                                                        12810013
*              BITS IN DICTIONARY CODE BYTES                            12840013
         SPACE                                                          12870013
FPBIT    EQU   BIT4      FORMAL PARAMETER BIT IN OTHER 2 BYTE           12900013
LSTBIT   EQU   BIT0      'LISTING REQUIRED' BIT IN CCCODE               12930013
NDVBIT   EQU   BIT0      'NEEDS DOPE VECTOR' BIT IN OTHER 3 BYTE        12960013
SBIT     EQU   BIT2      STRUCTURE BIT IN CLASS CODE BYTE               12990013
ASBITS   EQU   X'30'     ARRAY AND STRUCTURE BITS IN CLASS CODE BYTE    13020013
STRBIT   EQU   BIT0      STRING BIT IN DATA BYTE                        13050013
DIMBIT   EQU   BIT1      DIMENSIONED BIT IN VARIABLE CODE BYTE          13080013
MSTBIT   EQU   BIT5      MAJOR STRUCTURE BIT IN OTHER 4 BYTE            13110013
         SPACE 3                                                        13140013
*              CODES FOR SECOND STEP-TABLE FIELD TO INDICATE SPECIAL    13170013
*        ADDRESSING                                                     13200013
         SPACE                                                          13230013
SP1      EQU   X'84'     ENTRY TYPE 1 WITH CODE OF ONE                  13260013
SP2      EQU   X'88'     ENTRY TYPE 3 WITH CODE OF ZERO                 13290013
SP3      EQU   X'8C'     ENTRY TYPE 2 WITH CODE OF TWO                  13320013
SP4      EQU   X'90'     ENTRY TYPE 4 WITH CODE OF TWO                  13350013
SP5      EQU   X'94'     DATA ITEM WITH CODE OF TWO                     13380013
SP6      EQU   X'98'     TEMPORARY DOPE VECTOR WITH CODE OF ZERO        13410013
SP7      EQU   X'9C'     ZSTACH WITH CODE OF ONE                        13440013
SP8      EQU   X'A0'     ZSTACH WITH CODE OF TWO                        13470013
SP9      EQU   X'A4'     DED OF A DATA CONSTANT                         13500013
SP10     EQU   X'A8'     BCD OF LABEL CONSTANT                          13530013
         SPACE 3                                                        13560013
*              NAMES OF REGISTERS USED IN GENERATED CODE                13590013
         SPACE                                                          13620013
PRVP     EQU   12             PSEUDO-REGISTER VECTOR POINTER            13650013
ADP      EQU   13             AUTOMATIC DATA POINTER                    13680013
SDP      EQU   11             STATIC DATA POINTER                       13710013
R1       EQU   1              REGISTER ONE                              13740013
PREG     EQU   9              PRIVATE STORAGE POINTER                   13770013
GR2      EQU   2              REGISTER TWO                              13800013
PREGL    EQU   PREG+BIT1      PREG WITH 'LITERAL OFFSET' BIT ON         13830013
R1L      EQU   R1+BIT1        R1 WITH 'LITERAL OFFSET' BIT ON           13860013
GR2L     EQU   GR2+BIT1       GR2 WITH 'LITERAL OFFSET' BIT ON          13890013
         SPACE 3                                                        13920013
*              OFFSETS OF TRANSFER VECTOR AND COMMON DATA IN FIRST      13950013
*        CONTROL SECTION                                                13980013
         SPACE                                                          14010013
RELIBF   EQU   RA+12          ROUTINE TO RELEASE BUFFER                 14040013
ADINST   EQU   RELIBF+4       ROUTINE TO OUTPUT INSTRUCTIONS            14070013
ADIBUF   EQU   ADINST+4       ROUTINE TO ADD TEXT TO INSERTION FILE     14100013
ADCBUF   EQU   ADIBUF+4                ADDS TO OUTPUT BUFFER            14110015
PTRCDE   EQU   ADCBUF+4                INITIALIZES SCAN OF CODE FOR     14120015
*                                    ADDRESSING BASED VARIABLES         14130015
CURPTR   EQU   RC+600                  CONTAINS OUTPUT POINTER          14190013
BWDPTR   EQU   CURPTR+4                 POINTER TO WHERE CURRENT BASE   14220013
BSECNT   EQU   BWDPTR+4              WORD IS TO GO AND COUNT OF BITS    14250013
*                                    LEFT IN CURRENT BASE WORD          14280013
BWDCDE   EQU   BSECNT+3                BASE WORD CODE BYTE              14310013
BSEWRD   EQU   BWDCDE+1                BASE WORD                        14340013
DRADD    EQU   BSEWRD+4                                                 14370013
OFTMP    EQU   DRADD+4                                                  14400013
CNPMIN   EQU   OFTMP+4                                                  14430013
CNPMAX   EQU    CNPMIN+4 MAXIMUM VALUE OF CNP BEFORE SCRATCH OVERFLOW   14460013
SCRST    EQU   CNPMAX+4  POINTS TO FIRST BYTE OF SCRATCH                14490013
SCPMAX   EQU   SCRST+4   MAXIMUM VALUE OF SCP BEFORE STACK OVERFLOW     14500001
CBFMAX   EQU   SCPMAX+4                                                 14507046
IBFMAX   EQU   CBFMAX+4                                                 14514046
BVENV    EQU   IBFMAX+4                                                 14521046
ADSLOT   EQU   BVENV+8                                                  14530015
PSTOR    EQU   ADSLOT+2  SIZE OF PRIVATE STORAGE FOR CURRENT BLOCK      14550013
MDRPCT   EQU   PSTOR+2             COUNT OF ITEMS IN MDRP TABLE         14570001
OSMSKT   EQU   MDRPCT+2            SPACE FOR BUILDING OSM1 OR OSM2      14590001
ADSLT1   EQU   OSMSKT+5  STORAGE FOR STORED VALUES OF ADSLOT. TO BE     14610013
ADSLT2   EQU   ADSLT1+2 SED IN OSM1 OR OSM3.                            14640013
SPSW     EQU   ADSLT2+2  SWITCH ON IF SPECIAL SS INSTRUCTION.           14670013
OPNO     EQU   SPSW+1    SWITCH TO INDICATE OPERAND NUMBER.             14700013
GENFL    EQU   OPNO+1 )  SWITCHED ON IF EXTRA ITEMS REQUIRE GENERATION  14730013
*                      AFTER AN INSTRUCTION HAS BEEN OUTPUT             14760013
OSMFL    EQU   GENFL+1   SWITCHED ON IF AN OSM MUST BE GENERATED        14790013
SSFLG    EQU   OSMFL+1   SWITCHED ON FOR AN SS INSTRUCTION              14820013
OSMP     EQU   SSFLG+1   SWITCHED ON IF AN OSM1 OR OSM3 IS PRESENT      14850013
PROGSW   EQU   OSMP+1    SWITCHED ON IF IN THE PROLOG                   14880013
ILSW     EQU   PROGSW+1  SWITCHED ON IF IN-LINE CODE IS REQUIRED        14910013
FMTSW    EQU   ILSW+1 )  SWITCHED ON IF THE SCAN IS IN A REMOTE FORMAT  14940013
ADISKT   EQU   FMTSW+1   SKELETON 'ADI' INSTRUCTION. BIT INDICATING     14970013
CBUFNM   EQU   ADISKT+5                                                 14978046
IBUFNM   EQU   CBUFNM+3                                                 14986046
SBUFNM   EQU   IBUFNM+3                                                 14994046
CSTATE   EQU   SBUFNM+3                                                 15002046
LDPTR    EQU   CSTATE+1                                                 15010046
USASBS   EQU   LDPTR+14                                                 15020015
RXSAVE   EQU   USASBS+5                                                 15022015
RXINST   EQU   RXSAVE+5                                                 15024015
SSFLSV   EQU   RXINST+5                                                 15026015
OSMPSV   EQU   SSFLSV+1                                                 15028015
CCTAB    EQU   RC+2                                                     15030013
         SPACE 8                                                        15032001
*        TRANSFER VECTOR TO ROUTINES IN RC                              15034001
         SPACE 1                                                        15036001
SETSDR   EQU   RC+514                                                   15038001
CHKSK    EQU   SETSDR+4                                                 15040001
SCRTXT   EQU   CHKSK+4                                                  15042001
LMDRP    EQU   SCRTXT+4                                                 15044001
CHDRP    EQU   LMDRP+4                                                  15046001
EQUOFL   EQU   CHDRP+4                                                  15048001
GETSCR   EQU   EQUOFL+4                                                 15050001
BUMPOF   EQU   GETSCR+4                                                 15052001
RELTXT   EQU   BUMPOF+4                                                 15052601
DECOMP   EQU   RELTXT+4                                                 15052821
CHNSCN   EQU   DECOMP+4                                                 15053021
GETCBF   EQU   CHNSCN+4                                                 15053221
GETIBF   EQU   GETCBF+4                                                 15053421
GETSBF   EQU   GETIBF+4                                                 15053621
A4KRTN   EQU   GETSBF+4                                           41963 15053821
         EJECT                                                          15054001
F4096    EQU   RC+800                                                   15060013
F0       EQU   F4096+4                                                  15090013
F7       EQU   F0+4                                                     15120013
F32K     EQU    F7+4                                                    15150013
NOTOP2   EQU   F32K+4                                                   15180013
ATEMP    EQU   NOTOP2+4                                                 15210013
ADSTOR   EQU   ATEMP+4                                                  15240013
GFSTOR   EQU   ADSTOR+4                                           38178 15260046
DRPT     EQU   GFSTOR+4                                           38178 15280046
OFTAB    EQU   DRPT+4                                                   15300013
SCPSTO   EQU   OFTAB+4                 STORAGE FOR SCP                  15330013
OPT      EQU   SCPSTO+4                STORAGE FOR S3P                  15360013
SETSTO   EQU   OPT+4                   STORAGE FOR R14 IN SETSDR        15390013
DRSTOR   EQU   SETSTO+4                STORAGE FOR SP                   15420013
SPSTOR   EQU   DRSTOR+4                SAVE SCAN POINTER                15450013
TPMAX    EQU   SPSTOR+4                POINTS TO POSITION IN STEP       15480013
RTPTR    EQU   TPMAX+4                                                  15510013
PROFT    EQU   RTPTR+4                                                  15540013
CNPINT   EQU   PROFT+4                                                  15570013
ZEROS    EQU   CNPINT+4                                           23469 15580001
OPST     EQU   ZEROS+4                                            23469 15590001
*                                    TABLE FROM WHICH A 'RETRY' CAN BE  15600013
*                                    MADE                               15630013
H0       EQU   F0                                                       15660013
H1       EQU   OPST+4                                             23469 15690001
H2       EQU   H1+2                                                     15720013
H3       EQU   H2+2                                                     15750013
H4      EQU   H3+2                                                      15780013
H5      EQU   H4+2                                                      15810013
H6       EQU   H5+2                                                     15840013
H7       EQU   F7+2                                                     15870013
H8       EQU   H6+2                                                     15900013
H16      EQU   H8+2                                                     15930013
HSTSIZ   EQU   H16+2                                                    15960013
H80      EQU   HSTSIZ+2                                                 15990013
H4096    EQU   F4096+2                                                  16020013
CHTEMP   EQU   H80+2                                                    16050013
*              DICTIONARY REFERENCES                                    16080013
         SPACE                                                          16110013
TDR      EQU   CHTEMP+2                PARAMETER TO DRTEST              16140013
ADR      EQU   TDR+2                   VALUE RETURNED BY DECOMP         16170013
SDR      EQU   ADR+2                                                    16200013
NXTOFT   EQU   SDR+2                   REFERENCE TO BE SLOTTED INTO     16230013
*                                    NEXT GENERATED INSTRUCTION.        16260013
DDR      EQU   NXTOFT+2                VALUE RETURNED BY SETDDR         16290013
DR       EQU   DDR+2                   TDR WITH CODE SUBTRACTED         16320013
DR1      EQU   DR+2                    ALWAYS HSA VALUE DR+1            16350013
DR2      EQU   DR1+2                   ALWAYS HAS VALUE DR+2            16380013
DR3      EQU   DR2+2                   ALWAYS HAS VALUE DR+3            16410013
PADSLT   EQU   DR3+2                   TEMPORARY STORAGE FOR ADSLOT     16440013
         SPACE                                                          16470013
         SPACE                                                          16500013
*              INTEGERS AND HALF WORD ALIGNED ITEMS                     16530013
PSTOR2   EQU   PADSLT+2                                                 16560013
HTEMP    EQU   PSTOR2+2                TEMPORARY                        16590013
STEPTB   EQU   HTEMP+2                                                  16620013
*              MISCELLANEOUS                                            16650013
ENDCHN   EQU   STEPTB+42                                                16680013
PSW      EQU   ENDCHN+3                                                 16710013
LSW      EQU   PSW+1                                                    16740013
TSW      EQU   LSW+1                                                    16770013
NCSW     EQU   TSW+1                                                    16800013
TBYTE    EQU   NCSW+1                                                   16830013
INST5    EQU   TBYTE+1                                                  16860013
INST11   EQU   INST5+4                                                  16890013
INST12   EQU   INST11+4                                                 16920013
FESKLT   EQU   INST12+4                                                 16950013
FFSKLT   EQU   FESKLT+6                                                 16980013
TEMTRF   EQU   FFSKLT+8                                                 17010013
BLSW     EQU   TEMTRF+3                                                 17040013
RELSW    EQU   BLSW+1                                                   17070013
PSLDSW   EQU   RELSW+1                                                  17100013
PILSW    EQU   PSLDSW+1                                                 17130013
BASE     EQU   PILSW+1                                                  17160013
PBASE    EQU   BASE+1                                                   17190013
BLKNO EQU      PBASE+1                                                  17220013
RBLKNO   EQU   BLKNO+1                                                  17250013
CODE     EQU   RBLKNO+1                                                 17280013
OFTCNT   EQU   CODE+1                                                   17310013
OPLEV    EQU   OFTCNT+1                                                 17340013
ACODE    EQU   OPLEV+1                                                  17370013
NO2      EQU   ACODE+1                                                  17400013
ELEMNT   EQU   NO2+1                                                    17430013
         SPACE 3                                                        17460013
*              OFFSETS OF ADCONS OF COMPILER CONTROL ROUTINES           17490013
         SPACE                                                          17520013
ZUGC     EQU   COMREG+X'10'                                             17550013
ZUTXTC   EQU   COMREG+X'14'                                             17580013
ZURC     EQU   COMREG+X'18'                                             17610013
ZABORT   EQU   COMREG+X'20'                                             17640013
ZLOADW   EQU   COMREG+X'24'                                             17670013
LOADW    EQU   ZLOADW                                                   17700013
ZDRFAB   EQU   COMREG+X'34'                                             17730013
ZDUMP    EQU   COMREG+X'38'                                             17760013
ZTXTRF   EQU   COMREG+X'50'                                             17790013
ZTXTAB   EQU   COMREG+X'54'                                             17820013
ZCHAIN   EQU   COMREG+X'58'                                             17850013
ZALTER   EQU   COMREG+X'5C'                                             17880013
ZEND     EQU   COMREG+X'6C'                                             17910013
         SPACE 3                                                        17940013
*              OFFSETS OF QUANTITIES IN COMMUNICATIONS REGION FOR       17970013
*        PROTIOS VERSION                                                18000013
         SPACE                                                          18030013
ZTV      EQU   DB+64                                                    18060013
ZMYNAM   EQU   DB+112                                                   18090013
PAR1     EQU   DB+128                                                   18120013
PAR2     EQU   PAR1+4                                                   18150013
PAR5     EQU   PAR1+16                                                  18160001
ZOPT     EQU   DB+196                                                   18170001
CCCODE   EQU   DB+232                                                   18180013
STARTX   EQU   DB+256                                                   18210013
TXTSZ    EQU   DB+264                                                   18240013
LOCK     EQU   DB+274                                                   18270013
ZCOMM    EQU   DB+304                                                   18300013
ZSTACH   EQU   ZCOMM+68                                                 18330013
NOLIST  EQU    X'20'                                                    18360013
CRCODE   EQU   DB+X'E8'                                                 18390013
         SPACE 3                                                        18420013
*              OP. CODES FOR MACHINE INSTRUCTIONS AND PSEUDO-INST-      18450013
*        RUCTIONS                                                       18480013
         SPACE                                                          18510013
*              MACHINE INSTRUCTIONS                                     18540013
         SPACE                                                          18570013
MCA      EQU   X'8A'          A                                         18600013
MCS      EQU   X'8B'          S                                         18630013
MCST     EQU   X'A5'          ST                                        18660013
MCL      EQU   X'88'          L                                         18690013
MCSLL    EQU   X'74'          SLL                                       18720013
MCLA     EQU   X'A0'          LA                                        18750013
MCAR     EQU   X'4A'          AR                                        18780013
MCLCR    EQU   X'40'          LCR                                       18810013
MCLR     EQU   X'48'          LR                                        18840013
         SPACE                                                          18870013
*              PSEUDO-INSTRUCTIONS                                      18900013
         SPACE                                                          18930013
ADI      EQU   X'BE'          ADDRESSING INSTRUCTION FOR COMMUNICATION  18960013
*                           WITH NEXT PHASE                             18990013
PSLD     EQU   X'2C'          ITEM FOR COMMUNICATION WITH LISTING PHASE 19020013
EOB      EQU   X'21'          END-OF-BUFFER MARKER                      19110013
PIJMP    EQU   X'00'          PIJMP, PIEND AND PIINST ARE PSEUDO INST-  19140013
PIEND    EQU   X'01'        RUCTIONS FOR COMMUNICATION WITH THE NEXT    19170013
         SPACE 3                                                        19200013
*              BRANCH MNEMONICS                                         19230013
         SPACE                                                          19260013
B        EQU   15                                                       19290013
BH       EQU   2                                                        19320013
BL       EQU   4                                                        19350013
BE       EQU   8                                                        19380013
BNH      EQU   13                                                       19410013
BNL      EQU   11                                                       19440013
BNE      EQU   7                                                        19470013
BO       EQU   1                                                        19500013
BP       EQU   2                                                        19530013
BM       EQU   4                                                        19560013
BZ       EQU   8                                                        19590013
BNZ      EQU   7                                                        19620013
BNO      EQU   14                                                       19650013
         SPACE 3                                                        19710013
*              SETTINGS OF SWITCHES                                     19740013
         SPACE                                                          19770013
ON       EQU   X'FF'                                                    19800013
OFF      EQU   0                                                        19830013
         SPACE 3                                                        19860013
*              SETTINGS OF STATUS OF BUFFERS FOR ZALTER ETC.            19890013
         SPACE                                                          19920013
WANTED   EQU   X'03'     WANTED                                         19950013
FREE     EQU   X'01'     FREE                                           19980013
UNWANT   EQU   X'02'     UNWANTED                                       20010013
BUSY     EQU   X'04'     BUSY                                           20040013
CWANT    EQU   X'83'     CHAIN AND MARK WANTED                          20070013
CUNWAN   EQU   X'82'     CHAIN AND MARK UNWANTED                        20100013
         SPACE 3                                                        20130013
*              DICTIONARY ENTRY CODE BYTES.                             20160013
         SPACE                                                          20190013
ENTYP5   EQU   X'83'     ENTRY TYPE 5                                   20220013
SYMTAB   EQU   X'C7'     SYMBOL TABLE ENTRY                             20250013
         SPACE 5                                                        20280013
*              MISCELLANEOUS                                            20310013
         SPACE                                                          20340013
FILL     EQU   0         INDICATOR TO SHOW THAT A FIELD IS TO BE OVER-  20370013
*                      WRITTEN                                          20400013
CCSTR    EQU   12        CODE FOR CCTAB SUCH THAT ALL ITEMS WITH        20430013
*                      'OTHER' CODE BYTES ARE LESS THAN OR EQUAL TO IT  20460013
S4096    EQU   0         OFFSET IN STATIC OF CONSTANT 4096              20490013
         EJECT                                                          20520013
*              DRTEST ROUTINE                                           20550013
         SPACE                                                          20580013
*        THE DRTEST ROUTINE IS SUPPLIED A DICTIONARY REFERENCE AS       20610013
*        PARAMETER.  IT GENERATES INSTRUCTIONS AS NECESSARY TO MAKE THE 20640013
*        ITEM  REPRESENTED BY THE DICTIONARY ENTRY ADDRESSIBLE AT       20670013
*        OBJECT TIME                                                    20700013
         SPACE                                                          20730013
*        PARAMETERS--    R2 POINTS AT THE DICTIONARY REFERENCE TO BE    20760013
*        EXAMINED                                                       20790013
         SPACE                                                          20820013
*        REGISTERS--INPUT     R2,CP,IP,SCP,R14                          20850013
*                   RESET     CP,IP                                     20880013
*                   CLOBBERED  R2,R3,R4,TP,DP,R15                       20910013
         SPACE 3                                                        20940013
*              INITIALIZATION AND IDENTIFICATION OF DICTIONARY ENTRIES  20970013
         SPACE                                                          21000013
PHASRB   DC    C'RB'                    NAME OF CONTROL SECTION         21030013
DRTEST   EQU   *                                                        21040001
         CLC   0(2,R2),H0              DICT REF OF ZERO IS              21060016
         BCR   BE,R14                 USED TO INDICATE A NULL FIELD IN  21090013
*                                     AN LA INSTRUCTION, AND CAN BE     21120013
*                                     IGNORED                           21150013
         MVI   BASE,10                 INITIALIZE BASE                  21180013
         MVI   NOOFF,OFF             SET NO OFFSET SWITCH OFF           21210013
         ST    R14,DRSTOR               PRESERVE LINK                   21240013
         ST    SP,SPSTOR                STORE SP (TO PROVIDE EXTRA      21270013
         ST    SCP,SCPSTO               STORE SCP (REGISTER IS USED     21300013
*                                     FOR DIFFERENT PURPOSE LATER IN    21330013
*                                     DRTEST)                           21360013
         ST    R0,RTPTR                 INITIALISE RTPTR TO ZERO.       21390013
         ST    R2,DRPT                  PRESERVE POINTER TO PARAMETER   21420013
         MVC   PILSW(1),ILSW            PRESERVE INPUT VALUES OF ILSW   21450013
REENT    MVC   PADSLT(2),ADSLOT       AND ADSLOT                        21480013
         MVC   TDR(2),0(R2)             PLACE PARAMETER IN TDR          21510013
         LH    R2,TDR                   DECOMPOSE PARAMETER INTO A      21540013
         STH   R0,DR                                                    21570013
         BAL   R14,DECOMP             DICTIONARY REFERENCE AND A CODE,  21600013
*                                     AND SET OP TO POINT AT DICTIONARY 21630013
         ST    DP,DRADD                                                 21660013
         MVC   CODE(1),ACODE          ENTRY AND DR TO REFERENCE IT      21690013
         LR    OP,DP                                                    21720013
         LH    R4,ADR                                                   21750013
         STH   R4,DR                    SET DR1 = DR+1                  21780013
         LA    R4,3(R4)                     DR2 = DR+2                  21810013
         STH   R4,DR3                       DR3 = DR+3                  21840013
         BCTR  R4,0                     (THESE QUANTITIES ARE EXTENS-   21870013
         STH   R4,DR2                 IVELY USED IN THE CODE THAT       21900013
         BCTR  R4,0                   FOLLOWS, AND HENCE HAVE BEEN      21930013
         STH   R4,DR1                 PRECOMPUTED)                      21960013
         MVC   LOCK(2),TDR             LOCK DICTIONARY REFERENCE AT DR  21990015
*                                     IN CORE                           22020013
         LA    TP,STEPTB                INITIALIZE STEP-TABLE POINTER   22050013
         BAL   R14,UPTP1                INITIALIZE STEP-TABLE ENTRY     22080013
         SPACE                                                          22110013
         SR    R2,R2                    EXAMINE DICTIONARY ENTRY AT OP  22140013
         TRT   0(1,OP),CCTAB          AND SWITCH TO APPROPRIATE ROUTINE 22170013
         BC    B,*(R2)                  HEX CODE     DICTIONARY ENTRY   22200013
         SPACE                                                          22230013
         BAL   R4,CMPERR                ANYTHING NOT ADDRESSIBLE        22260013
         BC    B,LDATA                  DATA ITEM                       22290013
         BC    B,LSLE                   STRUCTURE OR LABEL,TASK,OR      22320013
*                                     EVENT DATA                        22350013
         BC    B,ENT1                   ENTRY TYPE1                     22380013
         BC    B,ENT2                   ENTRY TYPE2                     22410013
         BC    B,ENT3                   ENTRY TYPE3                     22440013
         BC    B,ENT4                   ENTRY TYPE4                     22470013
         BC    B,PARAM1                ENTRY TYPE 5                     22500013
         BC    B,LSTAT                  STATIC ITEM REQUIRING CODE OF   22530013
*                                     ZERO                              22560013
         BC    B,DCONST                 DATA CONSTANT                   22590013
         BC    B,LABCON                 LABEL CONSTANT                  22620013
         BC    B,LCL                    COMPILER LABEL                  22650013
         BC    B,TEMPDV                 DOPE VECTOR FOR TEMPORARY       22680013
         BC    B,LSTACH                 ZSTACH                          22710013
         BC    B,DREX1                                                  22740013
         BC    B,LFILE                 FILE CONSTANT                    22770013
         BC    B,ONCOND                 ON ENTRY                        22800013
         BC    B,LWORK                  WORKSPACE REQUIREMENT           22830013
         BC    B,LRDV                   RDV ENTRY                       22860013
         BC    B,NOPT                ITEMS WHICH MUST HAVE A DICT REF   22890013
*                                    PASSED, NOT AN OFFSET, AND WHICH   22920013
*                                    ARE TO BE TREATED AT LSTAT         22950013
         SPACE 10                                                       22980013
NOPT     MVI   NOOFF,ON              SPECIFY NO OFFSET                  23010013
         BC    B,LSTAT                                                  23040013
         EJECT                                                          23070013
*              THE FOLLOWING SECTIONS OF CODE DEAL WITH THE             23100013
*        CONSTRUCTION OF THE STEP-TABLE FOR REFERENCES TO STRUCTURES,   23130013
*        LABEL VARIABLES, DATA VARIABLES (BUT NOT DEDS OF DATA          23160013
*        VARIABLES), AND EVENT DATA                                     23190013
         SPACE 10                                                       23220013
*              CASE OF DATA ITEM                                        23250013
         SPACE                                                          23280013
LDATA    CLI   CODE,2                   BRANCH OUT FOR A REFERENCE TO   23310013
         BC    BE,L50                 A DED                             23340013
         SPACE                                                          23370013
*              ENTRY POINT FOR STRUCTURES, LABEL VARIABLES, AND EVENT   23400013
*        DATA                                                           23430013
         SPACE                                                          23460013
LSLE     TM    DOTH4(OP),BITS12         BRANCH OUT IF NOT A TEMPORARY   23490013
*                                     TYPE 2                            23520013
         BC    BZ,DTA                                                   23550013
         CLI   CODE,2                   BRANCH OUT FOR A REFERENCE TO   23580013
         BC    BE,L50                 A DED                             23610013
         MVI   BASE,ADP                 SET BASE TO ADP                 23640013
         ST    SCP,OFTAB                SET OFTAB TO POINT TO LATEST    23670013
*                                     STACK ENTRY                       23700013
         TM    0(OP),BITS23                                             23730013
         BC    BNZ,L52                 BRANCH IF AN AGGREGATE           23760013
         TM    DOTH4(OP),BIT7           TEST THE 'INCORPORATE IN        23790013
*                                     TEMPORARY STACK' BIT. IF ONE      23820013
*                                     THIS IS NOT A NORMAL TEMPORARY    23850013
         BC    BO,L55                 TYPE 2. BRANCH TO DEAL WITH IT.   23880013
L52      MVI   ILSW,ON                 CAUSE CODE TO BE IN LINE         23910013
         BC    B,DTD                    BRANCH TO PARAMETER ROUTINE     23940013
         SPACE 3                                                        23970013
*              CASE OF DED                                              24000013
         SPACE                                                          24030013
L50      MVI   1(TP),SP5                MAKE STEP-TABLE ENTRY FOR       24060013
         MVC   4(2,TP),TDR            INDIRECT ADDRESSING OF DED IN     24090013
         BC    B,DTP                  STATIC                            24120013
         SPACE 5                                                        24150013
*              CASE OF A TEMPORARY TYPE 2 WHICH HAS BEEN INCORPORATED   24180013
*        IN THE PSEUDO-CODE WORKSPACE.                                  24210013
         SPACE                                                          24240013
L55      CLI   CODE,1                BRANCH TO TREAT AS NORMAL AUTO-    24270013
         BC    BE,AUTO               MATIC ITEM IF ADDRESS OF DOPE      24300013
*                                    VECTOR REQUIRED.                   24330013
         LH    R4,FIRSOF+1(OP)          THE FIRST OFFSET SLOT IN THIS   24360013
*                                    TYPE OF ENTRY HAS ONLY TWO BYTES   24390013
         N     R4,NOTOP2             OF USEFUL INFORMATION, AND IS      24420013
*                                    HALF WORD ALIGNED.                 24450013
         L     R2,DRPT                 LOAD POINTER TO PARAMETER        24480013
         MVC   0(2,R2),STWSP(SCP)      CHANGE PARAMETER TO WORK SPACE   24510013
*                                    ENTRY FOR CURRENT BLOCK.           24540013
         CLI   FMTSW,OFF               IF FORMAT SWITCH IS ON CHANGE    24570013
         BC    BE,*+10               THIS TO DICTIONARY REFERENCE TO    24600013
         MVC   0(2,R2),STWSP3(SCP)   WORKSPACE 3.                       24630013
         SPACE                                                          24660013
         BAL   RR,BUMPOF               BRANCH TO MODIFY OFFSET,         24690013
         BC    B,REENT                 RESTART EXAMINATION              24720013
*              CASE OF DATA ITEM, LABEL VARIABLE, STRUCTURE  OR EVENT,  24750013
*        BUT NOT A DED OR A TEMPORARY TYPE2                             24780013
         SPACE                                                          24810013
DTA      TM    DOTH2(OP),FPBIT          BRANCH OUT IF ITEM IS A         24840013
         BC    BO,PARAM               PARAMETER                         24870013
         TM    DOTH2(OP),BITS67         TEST  STORAGE CLASS OF ITEM     24900013
         BC    BZ,AUTO                  AUTOMATIC CASE                  24930013
         BC    BM,STATIC                STATIC CASE                     24960013
         SPACE 3                                                        24990013
*              CONTROLLED CASE                                          25020013
         OI    ADISKT+2,X'10'          SET 'DROP BASE AT STMNT. BDY.'   25023015
         TM    DVAR(OP),BIT6           IS THIS A BASED VARIABLE         25027015
         BC    BO,BSEVBL                                                25034015
         SPACE                                                          25041015
         SPACE                                                          25050013
         MVI   BASE,PRVP                SET PRVP AS BASE                25080013
         MVI   ILSW,ON                  SWITCH ON ILSW                  25110013
         CLI   CODE,3                   IF CODE IS THREE THEN RETURN    25140013
         BC    BE,DREXIT              (CASE OF REFERENCE TO PSEUDO-     25170013
*                                     REGISTER)                         25200013
         TM    DOTH4(OP),BIT5           BRANCH OUT IF ITEM IS A MEMBER  25230013
         BC    BO,L68                 OF A STRUCTURE BUT NOT A MAJOR    25260013
         TM    DVAR(OP),BIT2          STRUCTURE                         25290013
         BC    BO,L51                                                   25320013
L68      MVI   0(TP),1                  MAKE STEP-TABLE ENTRY OF FORM   25350013
         MVC   2(2,TP),DR3                  1,0,DR+3,0                  25380013
         TM    DOTH4(OP),BIT5           BRANCH OUT IF ITEM IS A (MAJOR) 25410013
         BC    BO,L140                STRUCTURE                         25440013
         TM    DVAR(OP),BIT1            BRANCH OUT IF ITEM IS AN ARRAY  25470013
         BC    BO,L141                OR A STRING                       25500013
         TM    0(OP),X'0F'                                              25530015
         BC    BNO,DTB1                BRANCH IF LABEL, EVENT OR TASK.  25560015
         TM    DDAT(OP),BIT0                                            25590013
         BC    BZ,L141                                                  25620013
         TM    DOTH3(OP),BIT6          THE 'FIRST OFFSET SLOT FILLED'   25650013
         BC    BZ,DTB1               BIT INDICATES IN THIS CASE THAT    25680013
*                                    THE OFFSET MUST BE BUMPED BY 4     25710013
         LA    R4,4                                                     25740013
         BAL   RR,BUMPOF             IF THE BIT IS ONE                  25770013
         BC    B,DTB1                                                   25800013
         SPACE 3                                                        25830013
         SPACE 5                                                        25830515
BSEVBL   MVC   BVENV(8),DRSTOR         SAVE RETURN REG, AND SP          25831015
         MVC   SSFLSV(2),SSFLG      SAVE FLAGS                          25831215
         SR    R2,R2                   FIND D.R. OF POINTER BY          25836015
         IC    R2,2(0,OP)            WORKING BACK FROM END OF ENTRY     25836515
         SH    R2,H7                                                    25837015
         TM    0(OP),X'0E'                                              25837515
         BC    BO,KLM                                                   25838015
         SH    R2,H2                                                    25838515
KLM      TM    DVAR(OP),X'01'                                           25839015
         BC    BZ,LMN                                                   25839515
         SH    R2,H2                                                    25840015
LMN      AR    R2,OP                                                    25840515
         MVC   LDPTR+3(2),0(R2)        D.R. OF POINTER INTO SKELETON    25841015
         MVI   LDPTR+5,X'FD'           INITIALIZE TO ASSUME NOT ARRAY   25841515
         LR    R3,OP                                                    25842015
         XC    HTEMP(2),HTEMP          INITIALIZE FOR ZERO OSM          25842215
         TM    0(OP),X'30'           OR STRUCTURE                       25842515
         BC    BZ,PQR                                                   25843015
         MVI   LDPTR+5,X'FC'                                            25843515
*                                    INCLUDE ADD FROM SKDV              25844015
         TM    0(OP),X'20'             IS IT A STRUCTURE MEMBER         25845015
         BC    BZ,OPQ                  BRANCH IF NOT                    25845515
         TM    0(R3),X'0F'                                              25845915
         BC    BNO,*+8                 BRANCH IF NOT DATA               25846315
         LA    R3,D2OFF-SL2OFF(0,R3)                                    25846715
         SPACE                                                          25847115
         MVC   HTEMP(2),SL2OFF+1(R3)   PICK UP OFFSET OF D.V. OF        25847515
*                                    MEMBER                             25847915
         SPACE                                                          25848515
         BAL   RR,SETSDR               SET R3 TO MAJOR STRUCTURE        25849015
OPQ      L     R2,DRPT                                                  25849515
         XC    0(2,R2),0(R2)                                            25850015
PQR      MVC   LDPTR+8(2),8(R3)        D.R. OF SKDV INTO SKELETON       25850515
         TM    1(R3),BIT0              HAS ADDR CHAIN BEEN STARTED24680 25850619
         BZ    PQR1                    BRANCH IF NOT              24680 25850719
         LR    DP,R3                   IF SO SCAN TO END OF CHAIN 24680 25850819
         BAL   R14,CHNSCN              TO PICK UP PREVIOUS        24680 25850919
         MVC   LDPTR+8(1),TEMTRF+2     CONTENTS OF DCL NO SLOT    24680 25851019
PQR1     MVC   LDPTR+11(2),HTEMP       SET UP OSM                       25851119
         CLI   CODE,1                                                   25851219
         BC    BNE,CHKSK                                                25851515
*                                      OTHERWISE, IT MUST BE TREATED AS 25852015
         L     R2,DRPT               A REFERENCE TO THE SKDV.  CHANGE   25852515
         MVC   0(2,R2),LDPTR+8       INPUT TO SKDV REF.                 25853015
*                                    PICK UP ANY OFFSET WITHIN SKDV     25853515
         LH    R4,HTEMP              AS JUST FOUND                      25854015
         BAL   RR,BUMPOF               CHANGE OR CREATE OSM             25854515
         BC    B,REENT                 RE-ENTER TO ADDRESS SKDV         25855015
*              CASE OF CONTROLLED STRUCTURE MEMBER                      25860013
         SPACE                                                          25890013
L51      BAL   R14,SETSDR               CALL ROUTINE TO SET SDR AS      25920013
*                                     REFERENCE TO MAJOR STRUCTURE      25950013
         MVI   0(TP),1                  MAKE STEP-TABLE ENTRY OF FORM   25980013
         LH    R4,SDR                      1,0,SDR+3,0                  26010013
         LA    R4,3(R4)                                                 26040013
         STH   R4,2(TP)                                                 26070013
         BAL   R14,UPTP                 UPDATE TP                       26100013
         SPACE                                                          26130013
         MVI   0(TP),4                  MAKE STEP-TABLE ENTRY OF FORM   26160013
         MVC   2(2,TP),DR1                   4,0,DR+1,0                 26190013
         TM    0(OP),X'0F'                                              26200015
         BC    BO,L141                                                  26210015
         TM    0(OP),X'0E'                                              26220015
         BC    BO,L140                                                  26230015
L141     CLI   CODE,1                   IF CODE IS ONE STEP-TABLE IS    26280013
         BC    BE,DTB1                COMPLETE                          26310013
         SPACE                                                          26340013
*              THIS IS THE ENTRY POINT FOR AN ENTRY TYPE5 WHEN NOT      26370013
*        IN A PROLOG.                                                   26400013
         SPACE                                                          26430013
L141A    BAL   R14,UPTP                 UPDATE TP.                      26460013
         SPACE                                                          26490013
         MVI   0(TP),3                  MAKE STEP-TABLE ENTRY OF FORM   26520013
*                                           3,0,0,0                     26550013
         BC    B,DTB1                   PROCEED WITH ANALYSIS OF TABLE  26580013
         SPACE 3                                                        26610013
*              CASE OF CONTROLLED STRUCTURE                             26640013
         SPACE                                                          26670013
         SPACE 10                                                       26700013
*              CASE OF PARAMETER. EITHER A STRUCTURE OR A DATA OR LABEL 26730013
*        VARIABLE                                                       26760013
PARAM    MVI   PSW,ON                   SWITCH ON PSW                   26790013
         MVI   ILSW,ON                                                  26820013
         SPACE                                                          26850013
*              THE LEVEL AND COUNT FOR A FORMAL PARAMETER ARE IN THE    26880013
*        FORMAL PARAMETER TYPE1 DICTIONARY ENTRY. THE TWO BYTES WHICH   26910013
*        NORMALLY CONTAIN L AND C IN THIS CONTAIN THE DICTIONARY        26940013
*        REFERENCE OF THE FORMAL PARAMETER TYPE1 ENTRY.                 26970013
         SPACE 2                                                        27000013
         SPACE                                                          27030013
*              IF THE PARAMETER IS A MEMBER OF A STRUCTURE, BUT IS NOT  27060013
*        A MAJOR STRUCTURE ITS LEVEL AND COUNT WILL BE IN THE ENTRY     27090013
*        ITSELF, NOT IN THE FORMAL PARAMETER TYPE 1.                    27120013
         SPACE                                                          27150013
         TM    DOTH4(OP),BIT5          BRANCH TO AUTO IF THE ITEM       27180013
         BC    BO,PARAM1             IS A MEMBER OF A STRUCTURE, BUT    27210013
         TM    DVAR(OP),BIT2         IS NOT A MAJOR STRUCTURE.          27240013
*                                      AND IS NOT CONTROLLED      23469 27244001
         BZ    PARAM1                                             23469 27248001
         TM    DOTH2(OP),BITS67        IS IT CONTROLLED           23469 27252001
         BNO   AUTO                                               23469 27256001
         SPACE                                                          27260001
*        IF HERE THIS IS A MEMBER OF A CONTROLLED STRUCTURE       23469 27264001
*        PARAMETER. TO ADDRESS THE CORRECT DSA THE FORMAL         23469 27268001
*        PARAMETER TYPE1 OF THE MAJOR STRUCTURE MUST BE ACCESSED. 23469 27272001
         SPACE                                                          27276001
         BAL   R14,SETSDR              ACCESS MAJOR STRUCTURE     23469 27280001
         ST    OP,OPST                 STORE POINTER              23469 27284001
         LR    OP,R3                   POINT AT MAJOR STRUCTURE   23469 27288001
         SPACE                                                          27300013
PARAM1   MVC   HTEMP(2),1(OP)          R4 IS MADE TO POINT AT THE       27330013
         NI    HTEMP,X'7F'             SET TOP BIT TO ZERO IN CASE      27360013
*                                    AN ADDRESSING CHAIN HAS            27390013
*                                    BEEN STARTED.                      27420013
         LH    R4,HTEMP               DICTIONARY REFERENCE AT THE       27450013
         AR    R4,OP                  FORMAL PARAMETER TEPE1.           27480013
         SH    R4,H2                                                    27510013
         SPACE                                                          27540013
         MVC   PAR1+2(2),0(R4)          THIS IS DECODED                 27570013
         L     LR,ZDRFAB                                                27600013
         BALR  RR,LR                                                    27630013
         SPACE                                                          27660013
         L     LR,PAR1                  R4 IS THEN SET TO POINT AT THE  27690013
         SR    R4,R4                  BYTE FOLLOWING THE FORMAL         27720013
         IC    R4,2(LR)               PARAMETER TYPE1 ENTRY.            27750013
         AR    R4,LR                                                    27780013
         CLC   OPST(4),ZEROS           ARE WE OBTAINING BLOCK     23469 27783001
*                                      LEVEL OF A CONTROLLED      23469 27786001
*                                      STRUCTURE PARAMETER        23469 27789001
         BE    PARAM2                  SKIP IF NOT                23469 27792001
         L     OP,OPST                 POINT AT MEMBER AGAIN      23469 27795001
         MVC   OPST(4),ZEROS           CLEAR STORE                23469 27798001
         B     AUTO1                   AND BRANCH                 23469 27801001
         SPACE                                                          27804001
PARAM2   EQU   *                                                  23469 27807001
         CLI   0(OP),ENTYP5            BRANCH IF AN ENTRY TYPE 5 IS     27810013
         BC    BE,ENT5A              IS BEING PROCESSED                 27840013
         BC    B,AUTO1                  THEN THE AUTOMATIC PATH IS      27870013
*                                     JOINED.                           27900013
         SPACE                                                          27930013
*              CASE OF AUTOMATIC ITEM                                   27960013
         SPACE                                                          27990013
AUTO     SR    R4,R4                    FIND LENGTH OF DICTIONARY ENTRY 28020013
         IC    R4,2(OP)               AND HENCE FIND ITS LEVEL NUMBER   28050013
         AR    R4,OP                  (WHICH IS STORED IN THE PENULT-   28080013
AUTO1    SH    R4,H2                  IMATE BYTE)                       28110013
         MVC   OPLEV(1),0(R4)           SET OPLEV TO VALUE OF LEVEL NO  28140013
         BAL   R14,SETBLK               CALL ROUTINE TO ADDRESS THE     28170013
*                                     REQUIRED DSA                      28200013
         CLI   PSW,ON                   BRANCH OUT IF ITEM IS A         28230013
         BC    BE,DTD1                PARAMETER                         28260013
L57      CLI   CODE,1                  BRANCH OUT IF CODE IS ONE OR     28290013
         BC    BE,DEFFIX                                                28320013
         TM    DOTH3(OP),BIT6         ENTRY HAS NOT BEEN FILLED         28350013
         BC    BZ,DEFFIX               GO TEST IF STATIC DEFINED. 15896 28370017
*                                    IF SO DV WILL BE IN AUTO.    15896 28390017
         SPACE                                                          28410013
*              CASE OF AUTOMATIC OR STATIC ITEM WITH CODE OF ZERO       28440013
*        WHERE THE OFFSET IS KNOWN AT COMPILE TIME                      28470013
         CLI   PROGSW,ON                                                28500013
         BC    BE,L57A                 BRANCH IF IN PROLOGUE. D.V. MAY  28530013
*                                    NOT HAVE BEEN SET UP,.             28560013
         SPACE                                                          28590013
         TM    DOTH3(OP),NDVBIT         IF ITEM IS ALSO ADDRESSIBLE VIA 28620013
         BC    BZ,L57A                A DOPE VECTOR, SET RTPTR TO       28650013
         ST    TP,RTPTR               POINT TO LATEST STEP-TABLE ENTRY  28680013
*                                     SO THAT CURRENT ENVIRONMENT CAN   28710013
*                                     BE RESTORED IF IT LATER TURNS OUT 28740013
*                                     TO BE BETTER TO ADDRESS THE ITEM  28770013
*                                     VIA ITS DOPE VECTOR (OTHERWISE    28800013
*                                     RTPTR RETAINS ITS INITIAL VALUE   28830013
*                                     OF ZERO)                          28860013
         ST    OP,OPT                   REMEMBER OP IN CASE ENVIRONMENT 28890013
*                                     HAS TO BE STORED                  28920013
L57A     MVI   1(TP),DOFF             MAKE STEP TABLE ENTRY OF FORM     28950013
         LH    R4,DR                         2,(OFFSET OF FIRST SLOT),  28980013
         STH   R4,2(TP)                        DR+0,DR+0                29010013
         STH   R4,4(TP)                                                 29040013
         BC    B,DTB1                   PROCEED WITH ANALYSIS OF TABLE  29070013
         SPACE 5                                                        29100013
*              DOPE VECTORS OF STATIC DEFINED ITEMS ARE IN AUTOMATIC SO 29130013
DEFFIX   CLI   BASE,SDP                IF STATIC.....                   29160013
         BC    BNE,DTU                                                  29190013
         TM    DOTH4(OP),BIT3                                      1006 29200013
         BC    BO,AUTO                                             1006 29210013
         TM    DVAR(OP),BIT6           .... AND DEFINED ITEM....        29220013
         BC    BZ,DTU                                                   29250013
         BC    B,AUTO                  ....RETURN TO TREAT AS AUTO      29280013
         SPACE 10                                                       29310013
*              CASE OF STATIC ITEM                                      29340013
         SPACE                                                          29370013
STATIC   MVC   OFTAB(4),SCRST           SET OFTAB TO START OF SCRATCH   29400013
         MVI   BASE,SDP                 BASE = SDP                      29430013
         TM    DOTH2(OP),BIT5           BRANCH OUT ON STATIC EXTERNAL   29460013
         BC    BO,DTD                 CASE                              29490013
         BC    B,L57                    RETURN TO MAIN ROUTINE          29520013
         SPACE 10                                                       29550013
*              CASE OF AUTOMATIC OR STATIC ITEM, AND CODE OF ONE OR     29580013
*        CODE OF ZERO AND FIRST ADDRESS SLOT IN DICTIONARY UNFILLED     29610013
*        (ADDRESSING OF DOPE VECTOR)                                    29640013
         SPACE                                                          29670013
DTU      TM    DOTH3(OP),BIT7           IF THE SECOND SLOT IS NOT       29700013
         BC    BO,*+8                 FILLED THEN THERE IS A COMPILER   29730013
         BAL   R4,CMPERR              ERROR                             29760013
         SPACE                                                          29790013
         MVI   1(TP),D2OFF              MAKE STEP-TABLE ENTRY OF FORM   29820013
         TM    0(OP),X'0F'                  2,(OFFSET OF SECOND SLOT),  29850013
         BC    BO,*+8                        DR+1,DR+1                  29880013
         MVI   1(TP),SL2OFF           (POSITION OF SECOND OFFSET DE-    29910013
         LH    R4,DR1                 PENDS ON WHETHER ITEM IS A DATA   29940013
         STH   R4,2(TP)               VARIABLE)                         29970013
         STH   R4,4(TP)                                                 30000013
         SPACE                                                          30030013
         CLI   CODE,1                   BRANCH OUT TO ANALYSE STEP-     30060013
         BC    BE,DTB1                TABLE IF CODE IS ONE              30090013
         BAL   R14,UPTP                 UPDATE TP                       30120013
         SPACE                                                          30150013
         MVI   0(TP),3                  MAKE STEP-TABLE ENTRY OF FORM   30180013
         MVC   4(2,TP),DR                  3,0,0,DR+0                   30210013
         BC    B,DTB1                   PROCEED WITH ANALYSIS OF TABLE  30240013
         SPACE 10                                                       30270013
*              CASE OF PARAMETER OR TEMPORARY TYPE2 OR STATIC EXTERNAL  30300013
*        ITEM                                                           30330013
         SPACE                                                          30360013
DTD1     MVI   PSW,OFF             SWITCH OFF PSW  (PARAMETER CASE)     30390013
DTD      TM    DOTH4(OP),BIT5      BRANCH OUT IF ITEM IS A MEMBER OF A  30420013
         BC    BO,L70            STRUCTURE  BUT NOT A MAJOR STRUCTURE   30450013
         TM    DVAR(OP),BIT2                                            30480013
         BC    BO,L62                                                   30510013
L70      MVI   1(TP),DOFF          MAKE STEP-TABLE ENTRY OF FORM        30540013
         LH    R4,DR3                 2, (OFFSET OF FIRST SLOT),        30570013
         STH   R4,2(TP)                 DR+3, DR+3                      30600013
         STH   R4,4(TP)                                                 30630013
         CLI   CODE,3                   IF CODE IS THREE, PROCEED WITH  30660013
         BC    BE,DTB1                ANALYSIS OF TABLE                 30690013
         BAL   R14,UPTP                 UPDATE TP                       30720013
         SPACE                                                          30750013
         TM    DOTH2(OP),BITS67         BRANCH OUT IN CASE OF           30780013
         BC    BO,DTE1                CONTROLLED PARAMETER              30810013
DTG      TM    0(OP),ASBITS             BRANCH TO L59 IF ITEM IS NOT    30840013
         BC    BNZ,L61                A STRUCTURE, ARRAY  OR STRING     30870013
         TM    0(OP),X'0F'                                              30900013
         BC    BNO,L59                                                  30930013
         TM    DDAT(OP),STRBIT                                          30960013
         BC    BO,L59                                                   30990013
         SPACE                                                          31020013
*              CASE OF PARAMETER, TEMPORARY TYPE 2 OR STATIC EXTERNAL   31050013
*        ITEM THAT IS ADDRESSED VIA A DOPE VECTOR                       31080013
         SPACE                                                          31110013
L61      MVI   0(TP),3                  MAKE STEP-TABLE ENTRY OF FORM   31140013
         MVC   4(2,TP),DR1                 3,0,0,DR+1                   31170013
         CLI   CODE,1                   PROCEED WITH ANALYSIS OF STEP-  31200013
         BC    BE,DTB1                TABLE IF CODE IS ONE              31230013
         BAL   R14,UPTP                 UPDATE TP                       31260013
         SPACE                                                          31290013
         BC    B,DTG1                  BRANCH TO GENERATE LAST STEP     31320013
*                                    TABLE ENTRY.                       31350013
         SPACE 3                                                        31380013
*              CASE OF SCALAR NON-STRING PARAMETER                      31410013
         SPACE                                                          31440013
         SPACE                                                          31470013
*              OTHER CASES OF PARAMETERS BRANCH IN HERE                 31500013
         SPACE                                                          31530013
DTG1     MVI   0(TP),3                  MAKE STEP-TABLE ENTRY OF FORM   31560013
         MVC   4(2,TP),DR                    3,0,0,DR+0                 31590013
         BC    B,DTB1                   PROCEED WITH ANALYSIS OF TABLE  31620013
         SPACE 10                                                       31650013
*              CASE OF STRUCTURE MEMBER THAT IS A PARAMETER, TEMP TYPE2 31680013
*        OR STATIC EXTERNAL. IN ALL THESE CASES THERE IS AN OBJECT TIME 31710013
*        SLOT POINTING AT THE DOPE VECTOR OF THE MAJOR STRUCTURE. THUS  31740013
*        IT IS NECESSARY AT COMPILE TIME TO FIND THE DICTIONARY ENTRY   31770013
*        OF THE MAJOR STRUCTURE IN ORDER TO FIND THE OFFSET OF THIS     31800013
*        SLOT                                                           31830013
         SPACE                                                          31860013
         SPACE                                                          31890013
L62      BAL   R14,SETSDR               SET SDR TO REFERENCE MAJOR      31920013
*                                     STRUCTURE                         31950013
         MVI   0(TP),2                  MAKE STEP TABLE ENTRY OF FORM   31980013
         MVI   1(TP),DOFF             2, (OFFSET OF FIRST SLOT)         32010013
         LH    R4,SDR                       SDR+3, SDR+3                32040013
         LA    R4,3(R4)                                                 32070013
         STH   R4,2(TP)                                                 32100013
         STH   R4,4(TP)                                                 32130013
         BAL   R14,UPTP                 UPDATE TP                       32160013
         SPACE                                                          32190013
         TM    DOTH2(OP),BITS67         BRANCH OUT IN CASE OF           32220013
         BC    BO,DTE1                CONTROLLED PARAMETER              32250013
DTF      MVN   TBYTE(1),0(SP)           BRANCH OUT IF ITEM IS A         32280013
         CLI   TBYTE,X'0E'            STRUCTURE                         32310013
         BC    BE,DTH                                                   32340013
         MVI   0(TP),3                  MAKE STEP-TABLE ENTRY OF FORM   32370013
         MVI   1(TP),DOFF                 3,(OFFSET OF FIRST SLOT),     32400013
         LH    R4,DR1                       DR+1, X                     32430013
         STH   R4,2(TP)               WHERE X IS DR+1 IF ITEM IS ARRAY  32460013
         LH    R4,SDR                                                   32490013
         LA    R4,1(R4)                                                 32520013
         STH   R4,4(TP)                                                 32550013
L65      CLI   CODE,1                   IF CODE IS ONE, THEN PROCEED    32580013
         BC    BE,DTB1                WITH ANALYSIS OF TABLE            32610013
         BAL   R14,UPTP                 UPDATE TP                       32640013
         SPACE                                                          32670013
         BC    B,DTG1                   BRANCH TO MAIN ROUTINE TO       32700013
*                                     CREATE LAST STEP-TABLE ENTRY      32730013
         SPACE 2                                                        32760013
*              CASE OF A STRUCTURE THAT IS EITHER STATIC EXTERNAL,      32790013
*        A PARAMETER OR A TEMPORARY TYPE2                               32820013
         SPACE                                                          32850013
DTH      EQU   *                                                        32880013
         SPACE                                                          32910013
*              IT IS NOW NECESSARY TO FIND THE FIRST BASE ELEMENT OF    32940013
*        THE STRUCTURE, SINCE THIS FEATURES IN THE FOURTH FIELD OF THE  32970013
*        STEP-TABLE ENTRY THAT IS CREATED, BECAUSE THE DOPE VECTOR OF   33000013
*        THE BASE ELEMENT IS CONSIDERED AS THE ITEM MADE ADDRESSIBLE    33030013
         SPACE                                                          33060013
         LR    R3,OP                    INITIALIZE R3 TO POINT TO DICT- 33090013
*                                     IONARY ENTRY OF CURRENT STRUCTURE 33120013
DTHA     LA    R4,SL2OFF+OFF2SZ(R3)     SET R4 TO POINT TO ITEM IN      33150013
         TM    DVAR(R3),DIMBIT        VARIABLE INFORMATION BEYOND       33180013
*                                     SECOND OFFSET SLOT                33210013
         BC    BZ,*+8                   BUMP R4 IF VARIABLE INFORMATION 33240013
         LA    R4,DIMSIZ(R4)          CONTAINS A FIELD FOR DIMENSION-   33270013
*                                     ALITY                             33300013
         SPACE                                                          33330013
*              R4 NOW POINTS AT THE STRUCTURING INFORMATION             33360013
         SPACE                                                          33390013
         MVC   PAR1+2(2),NXELOF(R4)    SET DDR TENTATIVELY AS NEXT      33420013
         MVC   DDR(2),PAR1+2          STRUCTURE ELEMENT AND LINK TO     33450013
         L     R15,ZDRFAB             THIS ELEMENT                      33480013
         BALR  R14,R15                                                  33510013
         SPACE                                                          33540013
         L     R3,PAR1                  IF NEW ELEMENT IS A STRUCTURE,  33570013
         MVN   TBYTE(1),0(R3)         REPEAT THE ABOVE PROCESS. OTHER-  33600013
         CLI   TBYTE,X'0E'            WISE THE REQUIRED BASE ELEMENT    33630013
         BC    BE,DTHA                HAS BEEN FOUND                    33660013
         SPACE                                                          33690013
*              DDR NOW REFERENCES THE FIRST BASE ELEMENT OF THE STRUCT- 33720013
*        URE                                                            33750013
         SPACE                                                          33780013
         MVI   0(TP),3                  MAKE STEP-TABLE ENTRY OF FORM   33810013
         MVI   1(TP),DOFF                  3,(OFFSET OF FIRST SLOT),    33840013
         MVC   2(2,TP),DR1                   DR+1, DDR+1                33870013
         LH    R4,DDR                                                   33900013
         LA    R4,1(R4)                                                 33930013
         STH   R4,4(TP)                                                 33960013
         BC    B,DTB1                   PROCEED WITH ANALYSIS OF STEP-  33990013
*                                     TABLE                             34020013
         SPACE 10                                                       34050013
*              CASE OF CONTROLLED PARAMETER                             34080013
         SPACE                                                          34110013
DTE1     MVI   ILSW,ON                  SWITCH ON ILSW                  34140013
         MVI   NOOFF,ON                SAY NO OFFSET ALLOWED      28477 34150019
         MVI   0(TP),3                  MAKE STEP-TABLE ENTRY OF FORM   34170013
*                                           3,0,0,0                     34200013
         BAL   R14,UPTP                 UPDATE TP                       34230013
         SPACE                                                          34260013
         MVI   0(TP),5                  MAKE TYPE 5 SET TABLE ENTRY     34290013
         SPACE                                                          34320013
         BAL   R14,UPTP                UPDATE TP                        34350013
         CLI   0(OP),X'8F'                                              34353013
         BC    BNE,DTE2                BRANCH IF NOT                    34356013
         SPACE                                                          34359013
         TM    DDAT(OP),X'92'          IS THIS DOUBLE FLOAT             34362013
         BC    BNO,DTE2                                                 34365013
         LA    R4,4                    IF SO AN OFFSET OF FOUR IS RE-   34368013
         BAL   RR,BUMPOF             QUIRED TO GIVE 8 BYTE ALIGNMENT    34371013
DTE2     EQU   *                                                        34374013
         TM    DOTH4(OP),BIT5           BRANCH TO DTF IF ITEM IS A      34380013
         BC    BO,DTG                 MEMBER OF A STRUCTURE, NOT A      34410013
         TM    DVAR(OP),BIT2           MAJOR STRUCTURE, UNLESS    24694 34430019
         BZ    DTG                     CODE IS 3, IN WHICH CASE   24694 34450019
         CLI   CODE,3                  GO TO ANALYSE TABLE.       24694 34470019
         BE    DTB1                    OTHERWISE BRANCH TO DTG.   24694 34490019
         B     DTF                                                24694 34510019
         EJECT                                                          34530013
*              THE FOLLOWING SECTIONS OF CODE DEAL WITH THE CREATION OF 34560013
*        THE STEP-TABLE FOR REFERENCES TO ITEMS OTHER THAN DATA OR      34590013
*        LABEL VARIABLES OR STRUCTURES                                  34620013
         SPACE 10                                                       34650013
         EJECT                                                          34680013
*              CASE OF ITEM WHICH MUST HAVE A CODE OF ZERO, AND WHERE   34710013
*        IT IS REQUIRED TO ADDRESS STATIC AT AN OFFSET GIVEN BY THE     34740013
*        FIRST OFFSET SLOT                                              34770013
         SPACE                                                          34800013
LSTAT    CLI   CODE,0                   CHECK THAT CODE IS ZERO         34830013
         BC    BE,LSTAT1               IF CODE IS NOT ZERO IT IS        34860013
         BC    B,K30A                ASSUMED THAT IT IS ONE AND IS      34890013
*                                    A REFERENCE TO THE BCD ENTRY       34920013
*                                    FOR AN ENTRY LABEL.                34950013
         SPACE                                                          34980013
LSTAT1   MVI   1(TP),FIRSOF             SET BASE AND OFTAB FOR ADDRESS- 35010013
DTP      MVC   OFTAB(4),SCRST         ING STATIC , AND MAKE STEP-TABLE  35040013
         MVI   BASE,SDP               ENTRY OF FORM                     35070013
K2       MVC   2(2,TP),TDR                   2,(FIRST OFFSET),TDR,0     35100013
         CLI   0(OP),SYMTAB            BRANCH TO ANALYSIS OF TABLE IF   35130013
         BC    BNE,DTB1              THIS IS NOT A SYMBOL TABLE ENTRY   35160013
         SPACE                                                          35190013
         MVI   1(TP),SYMTOF            OTHERWISE CHANGE OFFSET OF       35220013
         BC    B,DTB1                OFFSET TO THAT FOR SYMBOL TABLE    35250013
         SPACE 5                                                        35280013
*              CASE OF ITEM WHICH MUST HAVE CODE OF ZERO, AND WHERE IT  35310013
*        IS REQUIRED TO ADDRESS AUTOMATIC AT AN OFFSET GIVEN BY THE     35340013
*        FIRST OFFSET SLOT. BEFORE THIS CODE IS ENTERED, OPLEV MUST BE  35370013
*        PRESET TO CONTAIN THE LEVEL NUMBER OF THE BLOCK CONTAINING THE 35400013
*        REQUIRED AUTOMATIC                                             35430013
         SPACE                                                          35460013
LAUTO    BAL   R14,SETBLK              CALL ROUTINE TO ADDRESS REQUI-   35490013
*                                     RED DSA (ROUTINE SETS BASE AND    35520013
*                                     OFTAB)                            35550013
         MVI   1(TP),FIRSOF             MAKE STEP-TABLE ENTRY OF FORM   35580013
         BC    B,K2                          2,(FIRST OFFSET),TDR,0     35610013
         EJECT                                                          35640013
*              ACTION FOR ENTRY TYPE ONE                                35670013
         SPACE                                                          35700013
ENT1     CLI   CODE,3                                                   35730013
         BC    BE,ENT13                                                 35760013
         CLI   CODE,1                   IF CODE IS ZERO, FINAL ASSEMBLY 35790013
         BC    BH,DREX1                                                 35820013
         BC    BL,DREXIT                                                35850013
*                                     IS ALWAYS ADDRESSIBLE             35880013
         SPACE                                                          35910013
*              CASE OF ENTRY TYPE 1 WITH CODE OF ONE (ADDRESS OF FIRST  35940013
*        SYMTAB ENTRY IN STATIC)                                        35970013
         SPACE                                                          36000013
         MVI   1(TP),SP1                SET SECOND STEP-TABLE FIELD FOR 36030013
         BC    B,DTP                  INDIRECT ADDRESSING AND PROCEED   36060013
*                                     AS FOR STANDARD STATIC CASE       36090013
         SPACE 3                                                        36120013
*              CASE OF ENTRY TYPE 1 WITH CODE OF THREE (REFERENCE TO    36150013
*        RETURN SWITCH IN (NOT NECESSARILY CURRENT) AUTOMATIC)          36180013
         SPACE                                                          36210013
ENT13    MVC   OPLEV(1),E1LEV(OP)       CALL ROUTINE FOR SETTING BASE   36240013
         BAL   R14,SETBLK             AND OFTAB FOR ADDRESSING REQUIRED 36270013
*                                     AUTOMATIC                         36300013
         MVI   1(TP),E1RTSW             MAKE STEP-TABLE ENTRY FOR       36330013
         BC    B,K2                   ADDRESSING REQUIRED SLOT          36360013
         EJECT                                                          36390013
*              ACTION FOR ENTRY TYPE 2 (ADDRESS IN STATIC OF DED)       36420013
         SPACE                                                          36450013
ENT2     CLI   CODE,2                   CHECK THAT CODE IS TWO          36480013
         BC    BE,*+8                                                   36510013
         BAL   R4,CMPERR                                                36540013
         SPACE                                                          36570013
         MVI   1(TP),SP3                SET SECOND STEP-TABLE FIELD FOR 36600013
         BC    B,DTP                  INDIRECT ADDRESSING, AND PROCEED  36630013
*                                     AS FOR STANDARD STATIC CASE       36660013
         EJECT                                                          36690013
*              ACTION FOR ENTRY TYPE THREE                              36720013
         SPACE                                                          36750013
ENT3     MVC   PAR1+2(2),E3E1(OP)       LINK TO ENTRY TYPE ONE IN ORDER 36780013
         L     R15,ZDRFAB             TO FIND LEVEL NUMBER              36810013
         BALR  R14,R15                                                  36840013
         SPACE                                                          36870013
         L     DP,PAR1                                                  36900013
         MVC   OPLEV(1),E1LEV(DP)       SET OPLEV TO LEVEL NUMBER       36930013
         CLI   CODE,0                   BRANCH ACCORDING TO CODE BYTE   36960013
         BC    BE,K5                                                    36990013
         BC    B,K6                    CODE MUST BE ONE                 37020013
         SPACE 3                                                        37050013
*              ENTRY TYPE 3 WITH CODE OF ZERO (ADDRESS OF POINTER TO    37080013
*        TARGET FIELD OF FUNCTION VALUE)                                37110013
         SPACE                                                          37140013
K5       BAL   R14,SETBLK               CALL ROUTINE TO ADDRESS THE     37170013
*                                     REQUIRED DSA                      37200013
         MVI   1(TP),SP2                SET SECOND FIELD FOR INDIRECT   37230013
         BC    B,K2                   ADDRESSING AND PROCEED TO CREATE  37260013
*                                     STEP-TABLE ENTRY                  37290013
         SPACE 3                                                        37320013
*              ENTRY TYPE 3 WITH CODE OF ONE (ADDRESS IN AUTO OF        37350013
*        CONTAINING BLOCK WHICH CONTAINS FUNCTION VALUE DESCRIPTION)    37380013
         SPACE                                                          37410013
K6       CLI   OPLEV,1                  IF THE ENTRY TYPE 3 DOES NOT    37440013
         BC    BE,K3A                 BELONG TO THE OUTER MOST BLOCK    37470013
         SR    R4,R4                  THE LEVEL OF THE CONTAINING BLOCK 37500013
         IC    R4,OPLEV               IS FOUND, AND ITS AUTOMATIC       37530013
         BCTR  R4,0                   IS ADDRESSED.                     37560013
         STC   R4,OPLEV                                                 37590013
K3A      BAL   R14,SETBLK               CALL ROUTINE TO ADDRESS         37620013
*                                     REQUIRED DSA                      37650013
         MVI   1(TP),E3RET              SET DICTIONARY OFFSET OF        37680013
         BC    B,K2                   ADDRESSING SLOT IN TABLE AND      37710013
*                                     PROCEED TO MAKE FULL ENTRY        37740013
         EJECT                                                          37770013
*              ACTION FOR ENTRY TYPE FOUR                               37800013
         SPACE                                                          37830013
ENT4     CLI   CODE,0                   SWITCH ACCORDING TO CODE BYTE   37860013
         BC    BE,K9                                                    37890013
K14      CLI   CODE,1                                                   37920013
         BC    BE,K10                                                   37950013
         CLI   CODE,2                                                   37980013
         BC    BE,K11                                                   38010013
         BAL   R4,CMPERR                CODE OF THREE IS ILLEGAL        38040013
         SPACE 3                                                        38070013
*              CASE OF ENTRY TYPE FOUR WITH CODE OF ZERO (ADDRESS OF    38100013
*        LOAD CONSTANT IN STATIC)                                       38130013
         SPACE                                                          38160013
K9       MVI   1(TP),E4ADCN             SET DICTIONARY OFFSET OF        38190013
          MVI   NOOFF,ON                                                38220013
         BC    B,DTP                  ADDRESSING SLOT AND PROCEED TO    38250013
*                                     GENERATE FULL STEP TABLE ENTRY    38280013
*                                     FOR ADDRESSING STATIC             38310013
         SPACE 3                                                        38340013
*              CASE OF ENTRY TYPE 4 OR 5 WITH CODE OF ONE (SLOT IN      38370013
*        CONTAINING BLOCK FOR FUNCTION VALUE). ROUTINE IS ENTERED AT    38400013
*        K15 FOR ENTRY TYPE5 WITH CODE OF ZERO                          38430013
         SPACE                                                          38460013
K10      EQU   *                       SET DICTIONARY OFFSET OF         38490013
         MVC   HTEMP(2),1(OP)         ADDRESSING SLOT IN SECOND FIELD   38520013
         LR    R4,OP                    SET LEVEL NUMBER FROM THE PEN-  38550013
         AH    R4,HTEMP               ULTIMATE BYTE OF THE DICTIONARY   38580013
K15      SH    R4,H2                  ENTRY                             38610013
         MVI   NO2,E4RET                                                38640013
         MVC   OPLEV(1),0(R4)                                           38670013
         BAL   R14,SETBLK               CALL ROUTINE FOR ADDRESSING     38700013
*                                     REQUIRED DSA                      38730013
         MVC   1(1,TP),NO2              MAKE STEP-TABLE ENTRY FOR       38760013
         BC    B,K2                   ADDRESSING AUTOMATIC              38790013
         SPACE 3                                                        38820013
*              CASE OF ENTRY TYPE 4 OR 5 WITH CODE OF TWO (REFERENCE    38850013
*        TO DED OF FUNCTION VALUE)                                      38880013
         SPACE                                                          38910013
K11      MVI   1(TP),SP4                MAKE STEP TABLE ENTRY FOR       38940013
         BC    B,DTP                  ADDRESSING STATIC WITH SECOND     38970013
*                                     FIELD SET FOR INDIRECT ADDRESSING 39000013
         EJECT                                                          39030013
*              ACTION FOR ENTRY TYPE FIVE                               39060013
         SPACE                                                          39090013
ENT5A    CLI   CODE,1                  TYPE5 IS IDENTICAL TO TYPE4      39120013
         BC    BE,K15                UNLESS CODE IS ZERO                39150013
         BC    BH,K11                                                   39180013
         SPACE                                                          39210013
         MVI   NO2,E4ADCN                                               39240013
         MVI   ILSW,ON                                                  39270013
         SH    R4,H2                   PICK UP BLOCK COUNT FOR          39300013
         MVC   OPLEV(1),0(R4)        PARAMETER.                         39330013
         BAL   R14,SETBLK              CALL ROUTINE TO ADDRESS CORRECT  39360013
*                                    DSA.                               39390013
         MVC   1(1,TP),NO2             COMPLETE TABLE ENTRY             39420013
         MVC   2(2,TP),TDR                                              39450013
         CLI   PROGSW,ON               IF THIS REFERENCE IS NOT IN      39480013
         BC    BNE,L141A             THE PROLOG, AN INDIRECT LOAD MUST  39510013
          MVI   NOOFF,ON                                                39540013
*                                    BE GENERATED. OTHERWISE TABLE      39570013
         BC    B,DTB1                SCAN IS COMPLETE                   39600013
         EJECT                                                          39630013
*              ACTION FOR DATA CONSTANT                                 39660013
         SPACE                                                          39690013
DCONST   CLI   CODE,1                   BRANCH OUT IF CODE IS ONE       39720013
         BC    BE,K21                                                   39750013
         CLI   CODE,2                   IF CODE IS NOT TWO, IT SHOULD   39780013
         BC    BNE,LSTAT              BE THE STANDARD STATIC ADDRESS-   39810013
*                                     ING CASE                          39840013
         SPACE                                                          39870013
*              CASE OF DATA CONSTANT WITH CODE OF TWO (REFERENCE TO     39900013
*        DED IN STATIC)                                                 39930013
         SPACE                                                          39960013
         MVI   1(TP),SP9                MAKE STEP TABLE ENTRY TO        39990013
         BC    B,DTP                  ADDRESS THE SLOT IN STATIC        40020013
         SPACE 3                                                        40050013
*              CASE OF DATA CONSTANT WITH CODE OF ONE (REFERENCE TO     40080013
*        DOPE VECTOR)                                                   40110013
         SPACE                                                          40140013
K21      LH    R4,ADSLOT                DOPE VECTOR IS LOCATED EIGHT    40170013
         SH    R4,H8                  BYTES BEFORE STORAGE. HENCE SUB-  40200013
         STH   R4,ADSLOT              TRACT 8 FROM ADSLOT AND PROCEED   40230013
         MVI   NOOFF,ON                                                 40260013
         BC    B,LSTAT1               WITH STANDARD STATIC ADDRESSING   40290013
         EJECT                                                          40320013
*              ACTION FOR LABEL CONSTANT                                40350013
         SPACE                                                          40380013
LABCON   CLI   CODE,1                   SWITCH ACCORDING TO CODE BYTE   40410013
         BC    BE,K30A                                                  40440013
         SPACE                                                          40470013
*              ENTRY POINT FOR COMPILER LABEL CASE                      40500013
         SPACE                                                          40530013
LCL      CLI   CODE,0                   IF CODE IS ZERO, FINAL ASSEMBLY 40560013
         BC    BE,DREXIT              DOES THE WORK                     40590013
         CLI   CODE,3                                                   40620013
         BC    BE,K30                                                   40650013
         BAL   R4,CMPERR                                                40680013
         SPACE 3                                                        40710013
*              CASE OF LABEL CONSTANT WITH CODE OF THREE (REFERENCE TO  40740013
*        LOAD CONSTANT IN STATIC)                                       40770013
         SPACE                                                          40800013
K30      MVI   NOOFF,ON                                                 40830013
         MVI   1(TP),LABOFF            MAKE STEP-TABLE ENTRY FOR        40860013
         BC    B,DTP                  ADDRESSING LOAD CONSTANT IN       40890013
*                                     STATIC                            40920013
         SPACE 3                                                        40950013
*              LABEL CONSTANT WITH CODE OF ONE (REFERENCE TO BCD IN     40980013
*        STATIC)                                                        41010013
         SPACE                                                          41040013
K30A     MVI   1(TP),SP10               MAKE STEP TABLE ENTRY FOR       41070013
         BC    B,DTP                  ADDRESSING BCD IN STATIC          41100013
         EJECT                                                          41130013
*              CASE OF DOPE VECTOR ENTRY FOR TEMPORARY                  41160013
         SPACE                                                          41190013
TEMPDV   CLI   CODE,0                   SWITCH ACCORDING TO CODE, WHICH 41220013
         BC    BE,TM1                 SHOULD BE ONE OR ZERO             41250013
         CLI   CODE,1                                                   41280013
         BC    BE,TM2                                                   41310013
         BAL   R4,CMPERR                                                41340013
         SPACE 3                                                        41370013
*              CASE OF REFERENCE TO DOPE VECTOR + 0 (ADDRESS OF STRING) 41400013
         SPACE                                                          41430013
TM1      MVI   1(TP),SP6                SET SECOND STEP-TABLE FIELD     41460013
*                                     FOR A SPECIAL OFFSET              41490013
TM3      MVI   BASE,ADP                 SET BASE AND OFTAB FOR ADDRESS- 41520013
         ST    SCP,OFTAB              ING CURRENT AUTOMATIC, AND MAKE   41550013
         BC    B,K2                   STEP-TABLE ENTRY                  41580013
         SPACE 3                                                        41610013
*              CASE OF DOPE VECTOR WITH CODE OF ONE (ADDRESS OF DOPE    41640013
*        VECTOR ITSELF)                                                 41670013
         SPACE                                                          41700013
TM2      MVI   1(TP),FIRSOF             ADDRESS CURRENT AUTOMATIC USING 41730013
         BC    B,TM3                  FIRST OFFSET SLOT                 41760013
         SPACE 5                                                        41790013
*              CASE OF REFERENCE TO WORKSPACE REQUIREMENT               41820013
         SPACE                                                          41850013
LWORK    CLI   CODE,0                   CODE SHOULD BE ONE              41880013
         BC    BE,TM2                   ADDRESS CURRENT AUTOMATIC AT    41910013
STCHER   BAL   R4,CMPERR                                                41940013
         SPACE 5                                                        41970013
*              CASE OF REFERENCE TO ZSTACH (THIS IS AN ARTIFICIAL WAY   42000013
*        OF REFERRING TO WORKSPACE IN THE CURRENT DSA                   42030013
         SPACE                                                          42060013
LSTACH   CLI   CODE,1                   CODE SHOULD BE ONE OR TWO       42090013
         BC    BE,LS1                                                   42120013
         CLI   CODE,2                                                   42150013
         BC    BE,LS2                                                   42180013
         SPACE                                                          42210013
*              A CODE OF 3 MEANS A REFERENCE TO THE PSEUDO REGISTER     42240013
*        IHEQERR. ALL THAT REQUIRES TO BE DONE IS MAKE THE BASE PRVP.   42270013
         SPACE                                                          42300013
         CLI   CODE,3                                                   42330013
         BC    BNE,STCHER                                               42360013
         MVI   BASE,PRVP                                                42390013
         MVI   ILSW,ON                                                  42420013
         BC    B,DREXIT                                                 42450013
         SPACE                                                          42480013
         SPACE 3                                                        42510013
*              CASE OF REFERENCE TO ZSTACH+1 ( REFERENCE TO PROLOG      42540013
*        WORKSPACE FOR CONTROLLED)                                      42570013
         SPACE                                                          42600013
LS1      MVI   1(TP),SP7                SET SECOND STEP-TABLE FIELD FOR 42630013
         BC    B,TM3                  INDIRECT ADDRESSING OF OFFSET,    42660013
*                                     AND PROCEED TO CODE TO ADDRESS    42690013
*                                     CURRENT AUTOMATIC                 42720013
         SPACE 3                                                        42750013
*              CASE OF REFERENCE TO ZSTACH+2 (REFERENCE TO WORKSPACE    42780013
*        FOR TEMPORARY TYPE 2 WORKSPACE)                                42810013
         SPACE                                                          42840013
LS2      MVI   1(TP),SP8                SET SECOND STEP-TABLE FIELD FOR 42870013
         BC    B,TM3                  INDIRECT ADDRESSING OF OFFSET,    42900013
*                                     AND PROCEED TO CODE TO ADDRESS    42930013
*                                     CURRENT AUTOMATIC                 42960013
         SPACE 5                                                        42990013
*              CASE OF ON CONDITION ENTRY ( AS DISTINCT FROM THE        43020013
*        SPECIAL TYPE OF ENTRY FOR A CONDITION CONDITION). IN THIS      43050013
*        CASE IT IS REQUIRED TO ADDRESS THE SLOT IN AUTOMATIC THAT      43080013
*        DEFINES THE ACTION TO BE TAKEN IF A PARTICULAR CONDITION IS    43110013
*        RAISED                                                         43140013
         SPACE                                                          43170013
ONCOND   MVC   OPLEV(1),ONLEV(OP)       SET OPLEV AS LEVEL NUMBER AND   43200013
         BC    B,LAUTO                GO TO STANDARD ROUTINE FOR        43230013
*                                     AUTOMATIC                         43260013
         SPACE 5                                                        43290013
*              ACTION FOR FILE CONSTANT.                                43320013
         SPACE                                                          43350013
LFILE    MVC   OFTAB(4),SCRST                                           43380013
         MVI   BASE,SDP                                                 43410013
         TM    DOTH2(OP),BIT5                                           43440013
         BC    BO,L70                                                   43470013
         SPACE                                                          43500013
         CLI   CODE,0                                                   43530013
         BC    BE,L57A                                                  43560013
         BAL   R4,CMPERR                                                43590013
         EJECT                                                          43620013
         SPACE                                                          43650013
*              CASE OF AN RDV ENTRY                                     43680013
         SPACE 2                                                        43710013
LRDV     MVC   PAR1+2(2),RDVITM(OP)                                     43740013
         TM    1(OP),BIT0              HAS ADDR CHAIN BEEN STARTED24680 43744019
         BZ    LRDV1                   BRANCH IF NOT              24680 43748019
         LR    DP,OP                   IF SO SCAN TO END OF CHAIN 24680 43752019
         BAL   R14,CHNSCN              TO PICK UP PREVIOUS        24680 43756019
         MVC   PAR1+2(1),TEMTRF+2      CONTENTS OF DCL NO SLOT    24680 43760019
LRDV1    EQU   *                                                  24680 43764019
         L     R15,ZDRFAB              DECODE THE REFERENCE OF THE      43770013
         BALR  R14,R15                OWNER OF THE RDV.                 43800013
         SPACE                                                          43830013
         L     R14,PAR1                BRANCH ADDRESS DEPENDS UPON      43860013
         TM    DOTH2(R14),BITS67     STORAGE CLASS OF OWNER.            43890013
         BC    BM,LSTAT1                                                43920013
         BC    BZ,RDVAUT                                                43950013
         SPACE                                                          43980013
RDVAUT   SR    R4,R4                   FIND THE BLOCK COUNT OF THE      44010013
         IC    R4,2(R14)             OWNER OF THE RDV, THEN CALL        44040013
         AR    R4,R14                SETBLK TO MAKE A STEP TABLE        44070013
         SH    R4,H2                 ENTRY IF IT IS NOT IN THE CURRENT  44100013
         MVC   OPLEV(1),0(R4)        BLOCK.                             44130013
         BAL   R14,SETBLK                                               44160013
         BC    B,L57A                  BRANCH TO COMPLETE STEP TABLE    44190013
*                                                                       44220013
         EJECT                                                          44250013
*              THE FOLLOWING SECTION OF CODE IS USED TO SCAN THE FOURTH 44280013
*        FIELDS OF THE ENTRIES IN THE STEP-TABLE, STARTING WITH THE     44310013
*        LAST, TO FIND OUT IF THE REQUIRED ADDRESS HAS ALREADY BEEN     44340013
*        PLACED IN A PRIVATE STORAGE CELL. IF SO, CONTROL COMES OUT AT  44370013
*        DTY. IF NOT, OR IF IN-LINE CODE IS REQUIRED, CONTROL COMES OUT 44400013
*        AT DTZ.                                                        44430013
         SPACE 3                                                        44460013
DTB1     ST    TP,TPMAX                 SET TPMAX TO POINT TO LAST      44490013
*                                     STEP-TABLE FIELD                  44520013
         MVI   PSLDSW,OFF               SET SWITCH TO INDICATED THAT NO 44550013
*                                     PSLD INSTRUCTIONS HAVE YET BEEN   44580013
*                                     GENERATED                         44610013
         MVC   BLKNO(1),STBLOC(SCP)     BLKNO IS CURRENT BLOCK NUMBER   44640013
         LA    CNP,BLSTSZ-5(SCP)        STACK REGISTER IS NOW USED TO   44670013
         LA    R4,5(CNP)              POINT TO CONSTRUCTED INSTRUCT-    44700013
         ST    R4,CNPMIN              IONS IN SCRATCH. UNDER THIS NEW   44730013
*                                     GUISE IT IS CALLED CNP            44760013
         ST    CNP,CNPINT               STORE INITIAL VALUE OF CNP.     44790013
*                                     NOTE THAT CNP POINTS AT THE       44820013
*                                     CURRENT CONSTRUCTED INSTRUCTION,  44850013
*                                     WHILE CNPMIN POINTS AT THE FIRST  44880013
*                                     ONE. WHEN NO INSTRUCTIONS HAVE    44910013
*                                     BEEN CONSTRUCTED, CNP IS LESS     44940013
*                                     THAN CNPMIN                       44970013
         CLI   ILSW,ON                  BRANCH OUT IF IN-LINE CODE IS   45000013
         BC    BE,DTZ                 REQUIRED                          45030013
         BC    B,L80                    BRANCH INTO TABLE SCANNING LOOP 45060013
         SPACE                                                          45090013
L81      LA    R4,STEPTB                INSTRUCTIONS FOR CONTROLLING    45120013
         CR    TP,R4                  SCAN OF STEP-TABLE FROM LAST ITEM 45150013
         BC    BE,DTZ                 TO FIRST ITEM                     45180013
         SH    TP,H6                                                    45210013
L80      LH    R2,4(TP)                 IF FOURTH STEP-TABLE FIELD IS   45240013
         LTR   R2,R2                  ZERO, ADDRESS HAS NOT PREVIOUSLY  45270013
         BC    BZ,L81                 BEEN GENERATED                    45300013
         BAL   R14,DECOMP               DECOMPOSE FOURTH FIELD INTO A   45330013
*                                     REFERENCE (WITH POINTER) AND CODE 45360013
         TM    1(DP),BIT0               IF THERE IS NO ADDRESSING CHAIN 45390013
         BC    BZ,L81                 THEN PROCEED WITH NEXT ENTRY      45420013
         MVC   TEMTRF(2),DHASH(DP)      MOVE CHAIN HEADER INTO A CONT-  45450013
         MVC   TEMTRF+2(1),DDECNO(DP) IGUOUS FIELD                      45480013
         LA    R2,TEMTRF                                                45510013
L84      MVC   PAR1+1(3),0(R2)          LINK TO NEXT ELEMENT OF CHAIN   45540013
         MVI   PAR1,128                                                 45570013
         L     R15,ZTXTAB                                               45600013
         BALR  R14,R15                                                  45630013
         SPACE                                                          45660013
         L     R3,PAR1                                                  45690013
         MVC   ELEMNT(7),1(R3)          MOVE CHAIN ELEMENT INTO SAFE    45720013
*                                     PLACE SO THAT THE BLOCK IT IS IN  45750013
*                                     CAN  BE RELEASED                  45780013
         LA    R2,ELEMNT                BRANCH OUT IF BLOCK NUMBER OF   45810013
         CLC   0(1,R2),BLKNO          CHAIN ELEMENT IS THE CURRENT      45840013
         BC    BE,L83                 BLOCK NUMBER                      45870013
L85      CLC   4(3,R2),ENDCHN           IF LINK FIELD CONTAINS END-OF-  45900013
         BC    BE,L81                 CHAIN MARKER THEN RESUME          45930013
*                                     SCANNING OF STEP-TABLE            45960013
         LA    R2,4(R2)                 SET R2 TO POINT TO LINK FIELD   45990013
         BC    B,L84                  AND PROCEED WITH NEXT CHAIN       46020013
*                                     ELEMENT                           46050013
         SPACE 3                                                        46080013
*              CASE OF CHAIN ELEMENT WITH SAME BLOCK NUMBER AS THE      46110013
*        CURRENT BLOCK                                                  46140013
         SPACE                                                          46170013
L83      CLC   1(1,R2),ACODE            CONTINUE WITH SCANNING OF CHAIN 46200013
         BC    BNE,L85                IF CODE BYTE IS UNEQUAL TO ACODE  46230013
         MVC   PSTOR2(2),2(R2)          SET PSTOR2 AS OFFSET IN PRIVATE 46260013
*                                     STORAGE WHERE REQUIRED ADDRESS    46290013
*                                     HAS PREVIOUSLY BEEN STORED        46320013
         CLI   0(R3),X'7F'              IS INDIRECT ADDRESSING USED     46325001
         BC    BE,INDADR                  BRANCH IF SO                  46330001
         BC    B,*+8                    IF NOT BRANCH ROUND NEXT        46335001
L102     MVI   TSW,ON                     INSTRUCTION                   46340001
L101     MVI   BASE,PREG                                                46345001
         BC    B,DTY                                                    46350001
         SPACE 5                                                        46355001
*        WITH INDIRECT ADDRESSING, A SLOT IS PRESERVED POINTING AT      46360001
*        THE 4K BOUNDARY IMMEDIATELY BELOW THE VIRTUAL ORIGIN OF THE    46365001
*        ITEM. BASES CAN ONLY BE COMMONED WHEN THE DISPLACEMENT OF      46370001
*        THE VIRTUAL ORIGIN FROM THE 4K BOUNDARY, PLUS ANY DISPLACEMENT 46375001
*        SPECIFIED IN ADSLOT IS LESS THAN 4095.                         46380001
         SPACE 3                                                        46385001
INDADR   EQU   *                                                        46390001
         CLI   1(TP),DOFF               CHECK FOR OFFSET1 SLOT          46395001
         BC    BNE,L102                   BRANCH IF NOT                 46400001
         C     TP,TPMAX                 CHECK FOR LAST STEP TABLE       46405001
         BC    BNE,L102                   ENTRY - BRANCH IF NOT         46410001
         CLC   ADSLOT(2),H0             IF NO VALUE IN ADSLOT BASES     46415001
         BC    BE,L102                    MAY BE COMMONED               46420001
         ST    R2,INDSTR                SAVE REGISTER 2                 46425001
         LH    R2,2(TP)                 CALL DECOMP TO SET DP TO        46430001
         BAL   R14,DECOMP                 POINT AT DICT REF             46435001
         MVC   ADSTOR(3),DOFF(DP)       PICK UP CONTENTS OF OFFSET1     46440001
         L     R14,ADSTOR                 SLOT IN REG 14                46445001
         SRA   R14,8                                                    46450001
         TM    DOTH3(DP),BIT5           IS OFFSET NEGATIVE              46455001
         BC    BZ,*+6                     IF NOT BRANCH                 46460001
         LCR   R14,R14                    IF SO NEGATE                  46465001
         SPACE 1                                                        46470001
         LR    R15,R14                  SET R15 EQUAL TO OFFSET1 +      46475001
         AH    R15,ADSLOT                 ADSLOT                        46480001
         SRA   R14,12                   DIVIDE BY 4096                  46485001
         SRA   R15,12                   DIVIDE BY 4096                  46490001
         L     R2,INDSTR                RESET REGISTER R2               46495001
         CR    R14,R15                  IF R14 EQUALS R15 THE TWO       46500001
         BC    BE,L102                    OFFSETS BOTH LIE IN THE       46505001
*                                         SAME 4K BLOCK AND BASES MAY   46510001
*                                         BE COMMONED                   46515001
         BC    B,L85                    IF R14 NOT EQUAL TO R15 NO      46520001
*          COMMONING IS POSSIBLE.                                       46525001
*                                         BRANCH TO CONTINUE SCAN.      46530001
INDSTR   DS    F                                                        46535001
         EJECT                                                          46560013
*              THE FOLLOWING SECTIONS OF CODE DEAL WITH THE SCANNING    46590013
*        OF THE STEP-TABLE TO CREATE MACHINE INSTRUCTIONS FOR ADDRESS-  46620013
*        ING. IF A REQUIRED ADDRESS HAS BEEN FOUND TO BE IN PRIVATE     46650013
*        STORAGE, SCANNING COMMENCES WITH THE ENTRY REFERENCING THE     46680013
*        REQUIRED ADDRESS IN ITS FOURTH FIELD. OTHERWISE SCANNING       46710013
*        STARTS AT THE BEGINNING OF THE TABLE. ENTRIES ARE SCANNED ONE- 46740013
*        BY-ONE UNTIL THE END OF THE TABLE IS REACHED, AND THE APPROP-  46770013
*        RIATE INSTRUCTION(S) (IF ANY) ARE GENERATED FOR EACH ENTRY.    46800013
*        THESE INSTRUCTIONS ARE TEMPORARILY PLACED IN SCRATCH CORE,     46830013
*        SINCE IT MAY NOT YET BE KNOWN WHETHER THEY WILL END UP IN THE  46860013
*        CREATED FILE OR THE INSERTION FILE.                            46890013
*              GENERATED INSTRUCTIONS, WHICH ARE ALWAYS RR, RX OR SHIFT 46920013
*        INSTRUCTIONS, HAVE A SPECIAL FORMAT. EACH INSTRUCTION OCCUPIES 46950013
*        FIVE BYTES, OF WHICH THE FIRST ALWAYS CONTAINS AN 'ADI'        46980013
*        MARKER, AND THE SECOND THE OP. CODE. THE THIRD BYTE HAS THE    47010013
*        FOLLOWING FORMAT                                               47040013
*              BIT0      HAS VALUE ONE ONLY IF THE CURRENT SEQUENCE OF  47070013
*                      ADI INSTRUCTIONS IS TO ADDRESS THE FIRST OPERAND 47100013
*                      OF AN (SS) INSTRUCTION                           47130013
*              BIT1      HAS VALUE ONE ONLY IF THE LAST TWO BYTES       47160013
*                      CONTAIN A LITERAL OFFSET FOR AN RX INSTRUCTION   47190013
*              BIT2      HAS VALUE ZERO IF A WORKING REGISTER IS        47220013
*                      REQUIRED AS FIRST OPERAND, ONE IF R2 IS          47250013
*                      REQUIRED (SEE ADD ROUTINE)                       47280013
*              BIT3      ALWAYS ZERO                                    47310013
*              BITS4-7   SECOND OPERAND(RR CASE)OR BASE REGISTER FOR    47340013
*                      SECOND OPERAND(OTHER CASES)                      47370013
*        THE FOURTH AND FIFTH BITS ARE UNUSED IN THE RR CASE, CONTAIN   47400013
*        A LITERAL OFFSET IN THE SHIFT CASE, AND CONTAIN EITHER A       47430013
*        DICTIONARY REFERENCE OR LITERAL OFFSET ACCORDING TO THE        47460013
*        SETTING OF BIT1 OF THE THIRD BYTE IN THE RX CASE               47490013
*              ALL SEQUENCES OF GENERATED INSTRUCTIONS REQUIRE A WORK-  47520013
*        ING REGISTER. THIS IS USUALLY USED AS THE FIRST OPERAND OF     47550013
*        ALL THE GENERATED  INSTRUCTIONS.  THE WORKING  REGISTER IS     47580013
*        OBTAINED DURING THE NEXT PHASE. IF THE WORKING REGISTER IS     47610013
*        REQUIRED AS THE SECOND OPERAND, IT IS REPRESENTED BY R1. THE   47640013
*        ACTUAL VALUE IS SUBSTITUTED DURING THE NEXT PHASE              47670013
         SPACE 3                                                        47700013
*              THE FOLLOWING CODE IS ENTERED WHEN IT IS REQUIRED TO     47730013
*        LOAD  A  BASE  REGISTER WITH AN ADDRESS STORED IN PRIVATE      47760013
*        STORAGE AT AN OFFSET GIVEN BY PSTOR2. THE CODE IS ENTERED WITH 47790013
*        LSW OFF IF, DURING THE REVERSE SCAN OF THE STEP-TABLE, A REQU- 47820013
*        IRED ADDRESS IS FOUND TO BE IN PRIVATE STORAGE. THE CODE IS    47850013
*        ENTERED WITH LSW ON  IF, AFTER THE ADDRESSING INSTRUCTIONS     47880013
*        HAVE BEEN GENERATED, IT IS DECIDED TO CALCULATE THE ADDRESS AT 47910013
*        PROLOG TIME AND THEREAFTER LOAD IT FROM PRIVATE STORAGE        47940013
         SPACE                                                          47970013
DTY      BAL   R14,CONSTR               IF PSTOR2 DOES NOT EXCEED 4095, 48000013
*                                     THEN CONSTRUCT  INSTRUCTION       48030013
         MVI   1(CNP),MCL             OF FORM                           48060013
         OI    2(CNP),PREGL                 L     PREG,(PSTOR2)         48090013
         MVC   3(2,CNP),PSTOR2        SETTING BIT TO INDICATE A LITERAL 48120013
         LH    R4,PSTOR2              OFFSET IN THE OPERAND FIELD       48150013
         CH    R4,H4096                                                 48180013
         BC    BL,L91                                                   48210013
         SPACE                                                          48240013
*              CASE WHERE REQUIRED ADDRESS IS IN PRIVATE STORAGE AT AN  48270013
*        OFFSET GREATER THAN 4095. IN THIS CASE THE PRIVATE STORAGE     48300013
*        ADDRESSING VECTOR IS USED                                      48330013
         SPACE                                                          48360013
         SRL   R4,12                    OFFSET OF REQUIRED SLOT IN      48390013
         SLL   R4,2                   PRIVATE STORAGE ADDRESSING VECTOR 48420013
         STH   R4,HTEMP               IS N WHERE N = (PSTOR2/409)*4     48450013
         MVC   3(2,CNP),HTEMP           CONSTRUCT INSTRUCTION OF FORM   48480013
*                                            L    PREG,N                48510013
*                                     (NOTE COMMONNING OF SET-UP CODE)  48540013
         BAL   R14,CONSTR               CONSTRUCT INSTRUCTION OF FORM   48570013
*                                            L    R1,K                  48600013
         MVI   1(CNP),MCL             WHERE K IS PSTOR2 MODULO 4096     48630013
         OI    2(CNP),R1L                                               48660013
         MVC   3(2,CNP),PSTOR2                                          48690013
         NI    3(CNP),X'0F'                                             48720013
         SPACE                                                          48750013
L91      EQU   *                                                        48780013
L92      CLI   LSW,ON                   RETURN TO FINALIZATION ROUTINE  48810013
         BC    BE,DTY1                IF LSW IS ON                      48840013
         SPACE                                                          48870013
         STH   R0,NXTOFT               SET NXTOFT TO ZERO IF THE        48900013
         CLI   TSW,OFF               ADDRESS JUST LOADED IS THAT IN     48930013
         BC    BE,DTQ3                                                  48960013
         MVI   TSW,OFF               FOURTH FIELD ADDRESSABLE USE THE   48990013
*                                    THIRD FIELD TO SET UP NXTOFT.      49020013
         SPACE 10                                                       49050013
*              CODE ENTERED AFTER A STEP-TABLE ENTRY HAS BEEN           49080013
*        PROCESSED. THE CODE PERFORMS CLEARING UP OPERATIONS, AND       49110013
*        PROCEEDS TO THE NEXT TABLE ENTRY                               49140013
         SPACE                                                          49170013
DTQ1     MVC   NXTOFT(2),2(TP)          SET NXTOFT TO 3-RD STEP-TABLE   49200013
DTQ2     C     CNP,CNPINT            FIELD.IF NO INSTRUCTIONS HAVE      49230013
         BC    BE,*+8                BEEN GENERATEDDO NOY ALTER BASE    49260013
         MVI   BASE,R1               OTHERWISE SET TO ONE.              49290013
         C     TP,TPMAX                 BRANCH OUT IF ALL STEP-TABLE    49320013
         BC    BE,DTL                 ENTRIES HAVE BEEN EXAMINED        49350013
         LA    TP,6(TP)                 OTHERWISE UPDATE TP AND PROCEED 49380013
         BC    B,L93                  WITH NEXT ENTRY                   49410013
         SPACE 5                                                        49440013
DTQ3     CLI   0(TP),3                                                  49470013
         BC    BNE,DTQ2                                                 49500013
         CH    R0,2(TP)                                                 49530013
         BC    BE,DTQ2                                                  49560013
         BC    B,DTQ1                                                   49590013
         SPACE 10                                                       49620013
*              CODE FOR EXAMINING A STEP-TABLE AND SWITCHING TO THE     49650013
*        APPROPRIATE INSTRUCTION-GENERATING ROUTINE ACCORDING TO THE    49680013
*        CONTENTS OF FIRST STEP-TABLE FIELD                             49710013
         SPACE                                                          49740013
DTZ      LA    TP,STEPTB                INITIALIZE TP TO POINT TO FIRST 49770013
*                                     ENTRY                             49800013
         MVC   PBASE(1),BASE            PRESERVE BASE INCASE A RENTRY   49830013
*                                     IS REQUIRED.                      49860013
L93      CLI   0(TP),1                  EXAMINE FIRST BYTE OF STEP-     49890013
         BC    BE,RTN1                TABLE ENTRY AND SWITCH TO APPROP- 49920013
         CLI   0(TP),2                RIATE ROUTINE                     49950013
         BC    BE,RTN2                                                  49980013
         CLI   0(TP),3                                                  50010013
         BC    BE,RTN3                                                  50040013
         CLI   0(TP),4                                                  50070013
         BC    BE,RTN4                                                  50100013
         BC    B,RTN5                                                   50130013
         SPACE                                                          50160013
         SPACE 10                                                       50190013
*              ACTION FOR STEP-TABLE ENTRIES WITH  ONE  IN FIRST BYTE   50220013
         SPACE                                                          50250013
RTN1     BAL   R14,CONSTR               CONSTRUCT INSTRUCTION OF FORM   50280013
         SPACE                                                          50310013
         MVI   1(CNP),MCL                 L  BASE,(THIRD STEP-TABLE     50340013
         OC    2(1,CNP),BASE                                  FIELD     50370013
         OC    3(2,CNP),2(TP)                                           50400013
         STH   R0,NXTOFT                ZEROIZE NXTOFT                  50430013
         BC    B,DTQ2                   PROCEED WITH NEXT STEP-TABLE    50460013
*                                     ENTRY                             50490013
         SPACE 10                                                       50520013
*              ACTION FOR STEP-TABLE ENTRIES WITH THREE IN FIRST BYTE   50550013
         SPACE                                                          50580013
RTN3     BAL   R14,CONSTR               CONSTRUCT INSTRUCTION OF FORM   50610013
         SPACE                                                          50640013
         MVI   1(CNP),MCL                    L   BASE,NXTOFT            50670013
         OC    2(1,CNP),BASE          WHERE NXTOFT IS A DICTIONARY      50700013
         MVC   3(2,CNP),NXTOFT        REFERENCE OR ZERO (WHICH COUNTS   50730013
*                                     AS A NULL DICTIONARY REFERENCE)   50760013
         CLI   OFTMP,255                                                50790013
         BC    BNE,RTN31                                                50820013
         MVC   3(2,CNP),OFTMP+2                                         50850013
         OI    2(CNP),BIT1                                              50880013
         NI    3(CNP),X'7F'                                             50910013
         MVI   OFTMP,0                                                  50940013
RTN31    EQU   *                                                        50970013
DTQ      CLC   4(2,TP),H0               IF FOURTH TABLE FIELD HAS BEEN  51000013
         BE    DTQ1                    SET,CHECK IF D.V. OFFSET   41963 51020021
         BAL   R14,A4KRTN              >4K,CHECK IF IT IS WORTH   41963 51040021
         BAL   R14,CHECK              STORING THE ADDRESS JUST          51060013
*                                     CALCULATED, AND, IF SO, ARRANGE   51090013
         BC    BNH,DTQ1               TO PUT IT IN PRIVATE STORAGE      51120013
         BAL   R14,ADD2                                                 51150013
         SPACE                                                          51180013
         BC    B,DTQ1                                                   51210013
         SPACE 10                                                       51240013
*              ACTION FOR STEP-TABLE ENTRIES WITH FOUR IN FIRST BYTE    51270013
         SPACE                                                          51300013
RTN4     MVC   NXTOFT(2),2(TP)          SET NXTOFT FROM SECOND STEP.    51330013
         BC    B,DTQ2                 TABLE FIELD AND CONTINUE WITH     51360013
*                                     NEXT ITEM                         51390013
         SPACE 10                                                       51420013
*              ACTION FOR STEP TABLE ENTRIES WITH 5 IN FIRST BYTE.      51450013
         SPACE                                                          51480013
RTN5     BAL   R14,CONSTR                                               51510013
         SPACE                                                          51540013
         MVI   1(CNP),MCAR             GENERATE INSTRUCTION OF FORM     51570013
         OI    2(CNP),PRVP                  AR  R1,PRVP                 51600013
         BC    B,DTQ2                                                   51630013
         SPACE 10                                                       51660013
*              ACTION FOR STEP-TABLE ENTRIES WITH TWO IN FIRST BYTE     51690013
*        (ADDRESSING ITEMS IN DSA OR IN STATIC)                         51720013
         SPACE                                                          51750013
RTN2     LH    R2,2(TP)                 CALL DECOMP TO SET DP TO POINT  51780013
         BAL   R14,DECOMP             TO DICT. REF IN THIRD FIELD       51810013
         SPACE                                                          51840013
*              IT IS NOW NECESSARY TO FIND THE DICTIONARY OFFSET FROM   51870013
*        DP IN WHICH THE OBJECT TIME ADDRESSING OFFSET CAN BE FOUND.    51900013
*        IN NORMAL CASES THE DICTIONARY OFFSET IS GIVEN BY THE SECOND   51930013
*        TABLE FIELD, BUT IN SOME CASES THE REQUIRED OBJECT TIME OFFSET 51960013
*        IS NOT IN THE REFERENCED DICTIONARY ENTRY, BUT IN ANOTHER      51990013
*        DICTIONARY ENTRY POINTED AT BY THE GIVEN DICTIONARY ENTRY      52020013
*        (E.G. IF A REFERENCE TO AN ENTRY TYPE3 + ZERO IS GIVEN, THE    52050013
*        REQUIRED OFFSET IS IN THE ENTRY TYPE1). IN THESE LATTER CASES  52080013
*        WHERE 'INDIRECT ADDRESSING' IS REQUIRED, THE FIRST BIT OF THE  52110013
*        SECOND STEP-TABLE FIELD IS ON. THERE IS A SPECIAL ROUTINE FOR  52140013
*        EACH  CASE OF INDIRECT ADDRESSING                              52170013
         SPACE                                                          52200013
         TM    1(TP),BIT0               BIT0 OF SECOND FIELD IS ON IF   52230013
         BC    BZ,L150                SPECIAL ADDRESSING IS REQUIRED    52260013
         NI    1(TP),X'7F'              IN THIS CASE THE REMAINING BITS 52290013
         SR    R4,R4                  GIVE A SWITCH CODE TO BRANCH TO   52320013
         IC    R4,1(TP)               THE APPROPRIATE INDIRECT ADDRESS- 52350013
         BC    B,*(R4)                                                  52380013
         BC    B,SPRT1                  ENTRY TYPE 1 WITH CODE OF ONE   52410013
         BC    B,SPRT2                  ENTRY TYPE 3 WITH CODE OF ZERO  52440013
         BC    B,SPRT3                  ENTRY TYPE 2 WITH CODE OF TWO   52470013
         BC    B,SPRT4                  ENTRY TYPE 4 WITH CODE OF TWO   52500013
         BC    B,SPRT5                  DATA ITEM WITH CODE OF TWO      52530013
         BC    B,SPRT6                  TEMPORARY DOPE VECTOR WITH CODE 52560013
*                                     OF ZERO                           52590013
         BC    B,SPRT7                  ZSTACH WITH CODE OF ONE         52620013
         BC    B,SPRT8                  ZSTACH WITH CODE OF TWO         52650013
         BC    B,SPRT9                 DED OF DATA CONSTANT             52680013
         BC    B,SPRT10                 LABEL BCD ENTRY                 52710013
         SPACE 3                                                        52740013
*              THE ADDRESSING ROUTINES WHICH FOLLOW RESET DP AND THE    52770013
*        FIRST  STEP-TABLE FIELD  TO GIVE A DICTIONARY POINTER AND      52800013
*        OFFSET TO THE SLOT CONTAINING THE REQUIRED OBJECT TIME OFFSET  52830013
         SPACE 3                                                        52860013
*              ROUTINE FOR ENTRY TYPE ONE WITH CODE OF ONE              52890013
         SPACE                                                          52920013
SPRT1    MVI   MOVOFT,E1SYM             LINK  TO FIRST SYMBOL TABLE     52950013
         MVI   1(TP),SYMOFF           ENTRY FOR THE BLOCK               52980013
         BC    B,DCHAIN                                                 53010013
         SPACE 3                                                        53040013
*              ROUTINE FOR ENTRY TYPE THREE WITH CODE OF ZERO           53070013
         SPACE                                                          53100013
SPRT2    MVI   MOVOFT,E3E1              LINK TO ENTRY TYPE ONE TO FIND  53130013
         MVI   1(TP),E1RET            OFFSET FOR RETURNED VALUE         53160013
         BC    B,DCHAIN                                                 53190013
         SPACE 3                                                        53220013
*              ROUTINE FOR ENTRY TYPE  TWO  WITH CODE OF TWO            53250013
         SPACE                                                          53280013
SPRT3    MVI   MOVOFT,E2DED           IN STATIC                         53310013
         MVI   1(TP),DEDOFF                                             53340013
         BC    B,DCHAIN                                                 53370013
         SPACE 3                                                        53400013
*              ROUTINE FOR ENTRY TYPE FOUR OR FIVE WITH CODE OF TWO     53430013
         SPACE                                                          53460013
SPRT4    MVI   MOVOFT,E4DED             LINK TO ASSOCIATED DED TO FIND  53490013
         MVI   1(TP),DEDOFF           OFFSET IN STATIC                  53520013
         BC    B,DCHAIN                                                 53550013
         SPACE 3                                                        53580013
*              ROUTINE FOR DATA ITEM AND CODE OF TWO                    53610013
         SPACE                                                          53640013
SPRT5    MVI   MOVOFT,DDED              LINK TO ASSOCIATED DED TO FIND  53670013
SPRT5A   MVI   1(TP),DEDOFF           ITS OFFSET IN STATIC.             53700013
         BC    B,DCHAIN                                                 53730013
         SPACE 3                                                        53760013
*              ROUTINE FOR TEMPORARY DOPE VECTOR WITH CODE OF ZERO      53790013
         SPACE                                                          53820013
SPRT6    MVI   MOVOFT,DVSKLT            LINK TO DOPE VECTOR SKELETON TO 53850013
         MVI   1(TP),SKDOPE           FIND OFFSET OF STRING FROM START  53880013
         BC    B,DCHAIN               OF DSA                            53910013
         SPACE 3                                                        53940013
*              CASE OF REFERENCE TO ZSTACH+1 (REFERENCE TO PROLOG       53970013
*        WORKSPACE FOR CONTROLLED)                                      54000013
         SPACE                                                          54030013
SPRT7    MVI   1(TP),E1CNWK             LINK TO CURRENT ENTRY TYPE1 TO  54060013
         L     R2,SCPSTO                FIND OFFSET OF CONTROLLED WORK  54090013
SPRT7A   MVC   PAR1+2(2),STE1RF(R2)   SPACE                             54120013
         BC    B,DCHN1                                                  54150013
         SPACE 3                                                        54180013
*              CASE OF REFERENCE TO ZSTACH+2 (REFERENCE TO PROLOG       54210013
*        WORKSPACE FOR TEMPORARY TYPE 2)                                54240013
         SPACE                                                          54270013
SPRT8    L     R2,SCPSTO                PICK UP OFFSET TO SLOT IN ENTRY 54300013
         MVC   1(1,TP),STW2OF(R2)     TYPE 1. THEN TREAT AS FOR         54330013
*                                     CONTROLLED CASE.                  54360013
         BC    B,SPRT7A                                                 54390013
         SPACE 3                                                        54420013
*              CASE OF A REFERENCE TO A DATA CONSTANT'S DED. THE        54450013
*        REFERENCE TO THE DED IS IN THE CONSTANTS ENTRY.                54480013
         SPACE                                                          54510013
SPRT9    MVI   MOVOFT,DCDED             PUT OFFSET OF DED REFERENCE     54540013
         BC    B,SPRT5A               IN MOVE INSTRUCTION.              54570013
         SPACE                                                          54600013
*              CASE OF A REFERENCE TO THE BCD OF A LABEL CONSTANT.      54630013
*        THE REFERENCE TO THE ENTRY IS IN THE DECLARE NUMBER SLOT.      54660013
         SPACE                                                          54690013
SPRT10   MVI   MOVOFT,LABBCD           PUT OFFSET OF BCD REFERENCE IN   54720013
         BC    B,SPRT5A              MOVE INSTRUCTION.                  54750013
         SPACE 3                                                        54780013
*              ALL SPECIAL ADDRESSING PATHS CONVERGE HERE               54810013
         SPACE                                                          54840013
DCHAIN   MVC   PAR1+2(2),FILL(DP)       THE LAST BYTE OF THIS INSTRUCT- 54870013
MOVOFT   EQU   DCHAIN+5               ION IS FILLED WITH THE REQUIRED   54900013
DCHN1    L     R15,ZDRFAB             OFFSET                            54930013
         BALR  R14,R15                  LINK TO REQUIRED DICTIONARY     54960013
*                                     ENTRY AND SET DP TO POINT TO IT   54990013
         L     DP,PAR1                                                  55020013
         SPACE                                                          55050013
*              ALL PATHS FROM RTN2 RE-CONVERGE HERE                     55080013
         SPACE                                                          55110013
L150     MVC   *+11(1),1(TP)            LOAD OFT WITH NUMBER IN DICT-   55140013
         MVC   ADSTOR(3),FILL(DP)     IONARY AT AN OFFSET FROM DP GIVEN 55170013
         L     OFT,ADSTOR             BY FIRST STEP TABLE FIELD.        55200013
         SRA   OFT,8                                                    55230013
         SR    R4,R4                    IF DICTIONARY ENTRY IS FOR A    55260013
         IC    R4,0(DP)               DATA ITEM, LABEL, OR STRUCTURE    55290013
         LA    R4,CCTAB(R4)           (THESE ITEMS HAVE LOW CODES IN    55320013
         CLI   0(R4),CCSTR            THE TRANSLATE TABLE) AND FIRST    55350013
         BC    BH,L153                OFFSET IS REQUIRED THEN TEST BIT  55380013
         CLI   1(TP),DOFF             TO SEE IF OFFSET REQUIRES NEGAT-  55410013
         BC    BNE,L153               ING, AND NEGATE IT IF NECESSARY   55440013
         TM    DOTH3(DP),BIT5                                           55470013
         BC    BZ,*+6                                                   55500013
         LCR   OFT,OFT                                                  55530013
         SPACE                                                          55560013
*              NOW IT IS TESTED WHETHER ANY LITERAL OFFSET ADDEND,      55590013
*        SPECIFIED BY AN OSM ON THE  ORIGINAL  MACHINE  INSTRUCTION,    55620013
*        SHOULD BE TAKEN INTO ACCOUNT. THIS SHOULD ONLY BE DONE IF THE  55650013
*        CURRENT ENTRY IS THE LAST STEP-TABLE ENTRY                     55680013
         SPACE                                                          55710013
L153     LR    R2,OFT                   FIRST PRESERVE CURRENT VALUE    55740013
         SRL   R2,12                  OF OFFSET, SHIFTED RIGHT TWELVE   55770013
         ST    R2,PROFT              PLACES                             55800013
         ST    OFT,OFTMP                                                55830013
         MVI   OFTMP,0                                                  55860013
         NI    OFTMP+2,X'0F'                                            55890013
         OI    OFTMP+2,X'80'                                            55920013
         TM    CRCODE,NOLIST                                            55950013
         BC    BNO,L1530             BRANCH IF LISTING REQUIRED         55980013
         MVI   OFTMP,255                                                56010013
         CLI   NOOFF,OFF                                                56040013
         BC    BE,L1530              BRANCH IF OFFSET ALLOWED           56070013
         MVI   OFTMP,0                                                  56100013
L1530    C     TP,TPMAX                IF THIS IS THE LAST STEP TABLE   56130013
         BC    BNE,L153A              ENTRY THEN BUMP OFT BY ADDEND AND 56160013
         AH    OFT,ADSLOT             ZEROIZE ADDEND TO INDICATE IT HAS 56190013
         STH   R0,ADSLOT              BEEN ACCOUNTED FOR                56220013
         SPACE 3                                                        56250013
*              HAVING FOUND THE OFFSET OF THE REQUIRED VARIABLE FROM    56280013
*        THE START OF STATIC OR AUTOMATIC, IT IS NOW NECESSARY TO FIND  56310013
*        OUT IF IT IS ADDRESSIBLE                                       56340013
         SPACE                                                          56370013
L153A    LTR   OFT,OFT                  IF OFFSET IS BETWEEN ZERO AND   56400013
         BC    BM,L153B               4095, THERE IS NO ADDRESSING      56430013
         CH    OFT,H4096              PROBLEM, AND CONTROL PROCEEDS TO  56460013
         BC    BL,DTQ1                THE CLEARING UP CODE              56490013
         SPACE                                                          56520013
*              CASE WHERE OFFSET IS NOT BETWEEN ZERO AND 4096           56550013
         SPACE                                                          56580013
L153B    SRL   OFT,12                   DIVIDE OFFSET BY 4096 AND STORE 56610013
         STC   OFT,OFTCNT             IT IN OFTCNT                      56640013
         C     OFT,F7                   IF OFFSET IS NOT NOW BETWEEN    56670013
         BC    BH,DTT                 ZERO AND SEVEN, THEN BRANCH OUT   56700013
*                                     (IN NEGATIVE CASE FIRST EIGHT     56730013
*                                     BITS ARE NOW ZERO)                56760013
         SPACE                                                          56790013
*              CASE WHERE REQUIRED ITEM IS ADDRESSIBLE VIA THE ADDRESS- 56820013
*        ING VECTOR                                                     56850013
         SPACE                                                          56880013
         CLI   BASE,R1                  IF ITEM IS NOT IN CURRENT BLOCK 56910013
         BC    BNE,L97                (I.E. IF AN INSTRUCTION HAS       56940013
         L     R4,SCPSTO              ALREADY BEEN GENERATED), THEN SEE 56970013
         LA    R2,STCHD(R4)           IF REQUIRED OFFSET IS ALREADY IN  57000013
*                                     PRIVATE STORAGE                   57030013
         L     R4,OFTAB                                                 57040001
         MVC   RBLKNO(1),STBLOC(R4)     SET RBLKNO AS BLOCK NUMBER OF   57060013
*                                     REQUIRED BLOCK                    57090013
L100     CLC   0(3,R2),ENDCHN           SEARCH CHAIN ASSOCIATED WITH    57120013
         BC    BE,L97                 CURRENT BLOCK OF INSTRUCTIONS TO  57150013
*                                     ADDRESS VARIABLES IN OUTER BLOCKS 57180013
*                                     IF REQUIRED ADDRESS HAS ALREADY   57210013
L98      MVC   PAR1+1(3),0(R2)        BEEN GENERATED THEN SET PSTOR2    57240013
         MVI   PAR1,128                                                 57270013
         L     R15,ZTXTAB             AS THE OFFSET OF THE PRIVATE      57300013
         BALR  R14,R15                STORAGE CELL THAT CONTAINS THE    57330013
         SPACE                                                          57360013
         L     R4,PAR1                ADDRESS. OTHERWISE BRANCH OUT     57390013
         MVC   ELEMNT(7),1(R4)                                          57420013
         SPACE                                                          57450013
         LA    R2,ELEMNT+4              (EACH CHAIN ELEMENT IS MOVED    57480013
         CLC   ELEMNT(1),RBLKNO       INTO ELEMNT SO THAT THE TEXT      57510013
         BC    BNE,L100               BLOCK THAT CONTAINS IT CAN BE     57540013
         CLC   ELEMNT+1(1),OFTCNT     MARKED AS UNWANTED)               57570013
         BC    BNE,L100                                                 57600013
         SPACE                                                          57630013
*              CASE WHERE THERE HAS BEEN A PREVIOUS REQUIREMENT FOR     57660013
*        THE SAME SECTION OF THE SAME DSA, AND A SLOT IN PRIVATE        57690013
*        STORAGE HAS BEEN RESERVED FOR ITS ADDRESS                      57720013
         SPACE                                                          57750013
         MVC   PSTOR2(2),ELEMNT+2       PLACE OFFSET IN PSTOR2          57780013
         L     CNP,CNPINT               RESET CNP, THUS DELETING        57810013
*                                     PREVIOUSLY CONSTRUCTED INSTRUCT-  57840013
*                                     IONS                              57870013
         MVI   BASE,PREG                SET PREG AS BASE                57900013
         MVI   TSW,ON                  INDICATE THAT THE FOURTH FIELD   57930013
*                                    IS MADE ADRESSABLE, NOT ADDRESSED  57960013
         BC    B,DTY                    PROCEED TO GENERATE LOAD        57990013
*                                     INSTRUCTION                       58020013
         SPACE 3                                                        58050013
*              THE FOLLOWING CODE GENERATES INSTRUCTIONS TO ADDRESS     58080013
*        ITEMS WHOSE ADDRESS EITHER TOO LARGE OR TOO SMALL (I.E. NEG-   58110013
*        ATIVE)FOR DIRECT ADDRESSING. WHEN THIS SITUATION IS REACHED    58140013
*        THERE  CANNOT BE MORE THAN ONE PREVIOUSLY GENERATED INSTRUCT-  58170013
*        ION. IF THE REQUIRED OFFSET IS REGARDED AS A 24-BIT SIGNED     58200013
*        INTEGER, AND X IS THE NUMBER IN THE FIRST TWELVE BITS, AND Y   58230013
*        THE NUMBER IN THE FOLLOWING 12 BITS, THEN THE CODE THAT        58260013
*        FOLLOWS GENERATES INSTRUCTIONS OF FORM                         58290013
*                  LA    R1,X(0)                                        58320013
*                   SLL  R1,12                                          58350013
*        FOLLOWED BY                                                    58380013
*                   A    R1,(DISPLAY CELL)                              58410013
*        IF THE REQUIRED ADDRESS IS IN NON-CURRENT AUTOMATIC, OR BY     58440013
*                   AR   R1,(ADP OR SDP)                                58470013
*        OTHERWISE. THE ORIGINAL DICTIONARY REFERENCE IS ASSEMBLED AS   58500013
*        AN OFFSET Y FROM REGISTER R1 BY LATER PHASES                   58530013
         SPACE                                                          58560013
DTT      C     OFT,PROFT               IF SECTION THAT IS NOW           58590013
         BC    BE,DTTA                REQUIRED WOULD HAVE BEEN DIFFER-  58620013
         MVI   ILSW,ON                ENT IF THERE HAD BEEN NO LITERAL  58650013
         BC    B,DTTB                 OFFSET, THEN GENERATE IN-LINE     58680013
*                                     CODE AS NO COMMONNING UP IS PER-  58710013
*                                     FORMED IN CASES SUCH AS THIS      58740013
         SPACE                                                          58770013
*              CASE WHERE THE PARTICULAR SECTION THAT IS REQUIRED       58800013
*        IS NOT AFFECTED BY A LITERAL OFFSET. (I.E. LITERAL OFFSET IS   58830013
*        SMALL OR NON-EXISTENT)                                         58860013
         SPACE                                                          58890013
DTTA     C     R0,RTPTR                 BRANCH OUT IF IT IS POSSIBLE    58920013
         BC    BNE,L110               TO ADDRESS THE ITEM VIA A DOPE    58950013
*                                     VECTOR                            58980013
         SPACE                                                          59010013
*              CASES WHERE IT IS NECESSARY TO GENERATE INSTRUCTIONS TO  59040013
*        ADDRESS A DSA SECTION NOT DIRECTLY ADDRESSIBLE                 59070013
         SPACE                                                          59100013
DTTB     C     CNP,CNPINT                                               59130013
         BC    BE,L103                  IF THERE IS A PREVIOUS INST-    59160013
         MVC   INST5+1(3),2(CNP)      RUCTION. IT IS ERASED AND THE     59280013
         SH    CNP,H5                 REQUIRED QUANTITY IS ADDED ON TO  59310013
         MVI   NCSW,ON                R1 AFTER THE REQUIRED MULTIPLE OF 59340013
*                                     4096 HAS BEEN ADDED TO IT         59370013
L103     BAL   R14,CONSTR               GENERATE INSTRUCTION OF FORM    59400013
*                                          LA     0,X                   59430013
         MVI   1(CNP),MCLA            WHERE X IS A LITERAL OFFSET       59460013
         OI    2(CNP),BIT1            HAVING AS VALUE THE FIRST 12 BITS 59490013
         STH   OFT,HTEMP              OF THE REQUIRED OFFSET, WHERE     59520013
         NI    HTEMP,X'0F'            THIS OFFSET IS REGARDED AS A      59550013
         MVC   3(2,CNP),HTEMP         24-BIT SIGNED NUMBER              59580013
         BAL   R14,CONSTR               GENERATE INSTRUCTION OF FORM    59610013
*                                         SLL     12                    59640013
         OC    1(4,CNP),INST11                                          59670013
         BAL   R14,CONSTR               IF THERE WAS A PREVIOUS LOAD    59700013
         SPACE                                                          59730013
         CLI   NCSW,OFF               INSTRUCTION, ADD TO R1 THE VALUE  59760013
         BC    BE,L109                THAT WAS TO BE LOADED, OTHERWISE  59790013
         OC    1(4,CNP),INST5         ADD THE BASE TO R1 USING AN       59820013
         MVI   NCSW,OFF               INSTRUCTION OF FORM               59850013
         BC    B,DTQ                       AR     BASE                  59880013
         SPACE                                                          59910013
L109     MVI   1(CNP),MCAR                                              59940013
         MVN   2(1,CNP),BASE                                            59970013
         BC    B,DTQ                                                    60000013
         SPACE 5                                                        60030013
*              CASE WHERE THE OFFSET OF A REQUIRED ITEM IS NOT BETWEEN  60060013
*        ZERO AND (8*4096) - 1, AND THE ITEM POSSESSES A DOPE VECTOR.   60090013
*        IN SUCH CASES IT IS MORE CONVENIENT TO ADDRESS THE ITEM VIA    60120013
*        ITS DOPE VECTOR RATHER THAN DIRECTLY. THUS CONTROL PASSES      60150013
*        BACK TO THE EARLIER ROUTINES SO THAT THE STEP-TABLE CAN BE     60180013
*        REBUILT TO REFLECT THE NEW METHOD OF ADDRESSING                60210013
         SPACE                                                          60240013
L110     L     TP,RTPTR                 RESTORE ENVIRONMENT AT WHICH    60270013
         ST    R0,RTPTR               ADDRESSING PATHS DIVERGED, AND    60300013
         L     SCP,SCPSTO             BRANCH BACK INTO ROUTINE FOR      60330013
         MVC   ADSLOT(2),PADSLT       BUILDING STEP-TABLE               60360013
         MVC   BASE(1),PBASE                                            60390013
         L     OP,OPT                                                   60420013
         MVI   OFTMP,0                                            25850 60430019
         BC    B,DEFFIX                GO TEST IF STATIC DEFINED. 15896 60440017
*                                    IF SO DV WILL BE IN AUTO.    15896 60460017
         SPACE 3                                                        60480013
*              CASE WHERE ITEM WITH OFFSET EXCEEDING 4095 CAN BE        60510013
*        ADDRESSED USING THE ADDRESSING VECTOR                          60540013
         SPACE                                                          60570013
L97      L     R4,OFTAB                 SET OFFSET OF RELEVANT SLOT IN  60600013
         MVC   HTEMP(2),STADOF(R4)    ADDRESSING VECTOR IN HTEMP. THE   60630013
         SR    R4,R4                                                    60660013
         IC    R4,OFTCNT              VALUE OF THIS OFFSET IS           60690013
         SLL   R4,2                     (OFFSET OF ADDRESSING VECTOR)   60720013
         AH    R4,HTEMP                 + OFTCNT*4                      60750013
         STH   R4,HTEMP                                                 60780013
         BAL   R14,CONSTR               CONSTRUCT INSTRUCTION OF FORM   60810013
         SPACE                                                          60840013
         OI    1(CNP),MCL                   L  BASE,(VALUE OF HTEMP)    60870013
         OI    2(CNP),BIT1                                              60900013
         OC    2(1,CNP),BASE                                            60930013
         MVC   3(2,CNP),HTEMP                                           60960013
         BAL   R14,CHECK                TEST WHETHER IT IS WORTH STOR-  60990013
*                                     ING IN PRIVATE STORAGE THE ADD-   61020013
         BC    BNH,DTQ1               RESS OF THE REQUIRED DSA SECTION  61050013
         BAL   R14,ADD                AND IF SO PRESERVE THE ADDRESS    61080013
*                                     FOR LATER USE                     61110013
         BC    B,DTQ1                                                   61140013
               EJECT                                                    61170013
*              THIS SECTION OF CODE IS ENTERED AFTER THE ADI INSTRUCT-  61200013
*        IONS HAVE BEEN BUILT UP. THESE INSTRUCTIONS ARE EITHER ADDED   61230013
*        TO THE CREATED FILE, OR, IF THE INSTRUCTIONS STORE AN ADDRESS  61260013
*        IN PRIVATE STORAGE, THEY ARE ADDED TO THE INSERTION FILE AND   61290013
*        NEW INSTRUCTIONS ARE GENERATED TO EXTRACT THE ADDRESS FROM     61320013
*        PRIVATE STORAGE                                                61350013
         SPACE 3                                                        61380013
DTL      C     CNP,CNPINT               BRANCH TO L120 IF NO INSTRUCT-  61410013
         BC    BE,L120                IONS HAVE BEEN GENERATED OR IF    61440013
         CLI   1(CNP),MCST            THE LAST INSTRUCTION IS NOT A     61470013
         BC    BNE,L120               STORE (I.E. IF ADDRESS HAS NOT    61500013
*                                     BEEN PLACED IN PRIVATE STORAGE)   61530013
         SPACE                                                          61560013
*              CASE WHERE INSTRUCTIONS ARE TO BE ADDED TO THE INSERTION 61590013
*        FILE                                                           61620013
         SPACE                                                          61650013
         SR    R2,R2                    CALL ADINST TO ADD GENERATED    61680013
         BAL   R14,ADINST             INSTRUCTIONS TO INSERTION FILE    61710013
         SPACE                                                          61740013
         L     CNP,CNPINT               RE-INITIALIZE CNP, THUS ERASING 61770013
*                                     PREVIOUSLY CONSTRUCTED INSTRUCT-  61800013
*                                     IONS                              61830013
         MVI   LSW,ON                   PROCEED TO GENERATE CODE TO     61860013
         BC    B,DTY                  LOAD THE REQUIRED ADDRESS FROM    61890013
*                                     PRIVATE STORAGE. (CONTROL RETURNS 61920013
*                                     AT DTY1)                          61950013
         SPACE 10                                                       61980013
*              FINALIZATION OF ROUTINE-- THE ADDITION OF THE GENERATED  62010013
*        INSTRUCTIONS TO THE CREATED FILE                               62040013
         SPACE                                                          62070013
DTY1     MVI   LSW,OFF                  SWITCH OFF LSW                  62100013
L120     L     R4,DRPT                  PLACE NXTOFT IN PLACE OF        62130013
         MVC   0(2,R4),NXTOFT         ORIGINAL DICTIONARY REFERENCE     62160013
         LH    R4,ADSLOT                NOW ARRANGE TO TAKE ACCOUNT OF  62190013
         LTR   R4,R4                  ANY ADDEND                        62220013
         BC    BZ,L125                                                  62250013
         MVI   INST12,MCA               IF ADDEND IS POSITIVE, GENERATE 62280013
         BC    BP,L126                ADD INSTRUCTIONS. IF IT IS        62310013
         MVI   INST12,MCS             NEGATIVE NEGATE IT, ADD 4095 AND  62340013
         LPR   R4,R4                  GENERATE SUBTRACT INSTRUCTIONS    62370013
         LA    R4,4095(R4)                                              62400013
L126     CH    R4,H4096                 SUCCESSIVELY SUBTRACT 4096 FROM 62430013
         BC    BL,L125                ADDEND AND GENERATE AN ADD OR     62460013
         SH    R4,H4096               SUBTRACT INSTRUCTION UNTIL ADDEND 62490013
         BAL   R14,CONSTR             BECOMES LESS THAN 4096            62520013
         SPACE                                                          62550013
         OC    1(4,CNP),INST12         MOVE INST12 ITEM INTO STACK      62570001
*                                        PRESERVING BITS SET BY CONSTR  62590001
         BC    B,L126                                                   62610013
         SPACE                                                          62640013
*              FINAL ADDITION OF CREATED INSTRUCTIONS TO CREATED FILE   62670013
         SPACE                                                          62700013
L125     LA    R2,4                     CALL ADINST TO ADD GENERATED    62730013
         BAL   R14,ADINST             INSTRUCTIONS TO CREATED FILE      62760013
         SPACE                                                          62790013
         BC    B,DREXIT                                                 62820013
DREX1    MVI   BASE,12                                                  62850013
DREXIT  CLI   BASE,9                  IS THIS A BASE PROVIDED BY        62880013
         BC    BL,DREX2              PHASE IEMRF. BRANCH IF SO          62910013
         CLI   SSFLG,ON                                                 62913015
         BC    BE,DREX3                BRANCH IF SS                     62916015
         CLI   RXINST,ADI              IS THIS AN INSTRUCTION CREATING  62919015
         BC    BNE,DREX3             POINTER  BRANCH IF NOT             62922015
         MVN   RXINST+2(1),BASE                                         62925015
         BC    B,DREX2                                                  62928015
DREX3    EQU   *                                                        62931015
         IC    SP,BASE                 PICK UP BASE                     62940013
         N     SP,THREE                SELECT LAST TWO BITS             62970013
         LH    SCP,BSECNT                                               63000013
         SH    SCP,H2                                                   63030013
         STH   SCP,BSECNT                                               63060013
          SLL   SP,0(SCP)                                               63090013
         O     SP,BSEWRD                                                63120013
         ST    SP,BSEWRD                                                63150013
        SPACE                                                           63180013
DREX2    L     SP,SPSTOR                                                63210013
         L     SCP,SCPSTO                                               63240013
         MVC   ILSW(1),PILSW            RESET ILSW TO ITS ORIGINAL      63270013
*                                     STATE                             63300013
         L     R14,DRSTOR               RETURN                          63330013
         BCR   B,R14                                                    63360013
         EJECT                                                          63390013
*              ADD AND ADD2 ROUTINES                                    63420013
         SPACE                                                          63450013
*        THE ADD AND ADD2 ROUTINES ARE CALLED WHEN IT IS REQUIRED  TO   63480013
*        STORE A GIVEN ADDRESS IN PRIVATE STORAGE. THE ROUTINES GENER-  63510013
*        ATE THE APPROPRIATE STORING INSTRUCTION(S), AND ADD INFORM-    63540013
*        ATION ABOUT THE GIVEN ADDRESS TO THE APPROPRIATE CHAIN, SO     63570013
*        THAT IF THE SAME ADDRESS IS REQUIRED AGAIN, THE SAME PRIVATE   63600013
*        STORAGE ADDRESS CAN BE USED. (NOTE THAT THE REQUIRED ADDRESS   63630013
*        WILL BE SET UP AT PROLOG TIME, NOT AT ITS PLACE OF FIRST USE   63660013
*        IN THE CODE.)  THE ROUTINES PLACE IN PSTOR2 THE PRIVATE        63690013
*        STORAGE OFFSET AT WHICH THE GIVEN ADDRESS HAS BEEN STORED      63720013
*        THE GIVEN ADDRESS CAN EITHER BE OF A SECTION OF THE DSA OF     63750013
*        SOME OUTER BLOCK OR AN ADDRESS ASSOCIATED WITH A VARIABLE.     63780013
*        IN THE FORMER CASE, THE ADD ROUTINE  IS  USED AND THE ADDRESS- 63810013
*        ING INFORMATION IS ADDED TO THE CHAIN ASSOCIATED WITH THE      63840013
*        ENTRY IN THE STACK FOR THE CURRENT BLOCK. IN THE LATTER CASE,  63870013
*        THE ADD2 ROUTINE IS USED AND THE INFORMATION IS ADDED TO THE   63900013
*        CHAIN ASSOCIATED WITH THE DICTIONARY ENTRY FOR THE VARIABLE.   63930013
*        CHAINS ARE STORED IN THE INSERTION FILE, AND ARE NOT ERASED    63960013
*        UNTIL THE NEXT PHASE PROCESSES THE INSERTION FILE. HOWEVER IN  63990013
*        THE FORMER OF THE ABOVE CASES, THE INFORMATION IN THE CHAIN IS 64020013
*        ONLY USEFUL FOR THE DURATION OF THE BLOCK WITH WHICH IT IS     64050013
*        ASSOCIATED.                                                    64080013
*        CHAIN ENTRIES HAVE THE FOLLOWING FORM                          64110013
*              BYTE 0    ALWAYS CONTAINS 'FF'                           64140013
*              BYTE 1    CONTAINS BLOCK NUMBER OF BLOCK IN WHICH ADD-   64170013
*                      RESS IS REQUIRED (ADD2 CASE) OR BLOCK NUMBER OF  64200013
*                      BLOCK TO WHICH REQUIRED ADDRESS IS LOCAL (ADD    64230013
*                      CASE)                                            64260013
*              BYTE 2    CODE (DICTIONARY REFERENCE CASE) OR SECTION    64290013
*                      NUMBER,I.E. DSA OFFSET/4096 (BLOCK CASE)         64320013
*              BYTES 3-4 OFFSET OF PRIVATE STORAGE CELL CONTAINING      64350013
*                      ADDRESS                                          64380013
*              BYTES 5-7 LINK(TEXT REFERENCE)                           64410013
         SPACE                                                          64440013
*        PARAMETERS--    BLKNO CONTAINS THE CURRENT BLOCK NUMBER, AND,  64470013
*                      IN THE ADD CASE, OFTCNT CONTAINS THE REQUIRED    64500013
*                      SECTION NUMBER. IN THE ADD2 CASE, TP POINTS AT   64530013
*                      A STEP-TABLE ENTRY WITH THE REQUIRED ADDRESS IN  64560013
*                      THE FOURTH FIELD                                 64590013
         SPACE                                                          64620013
*        REGISTERS--INPUT     TP,IP,CNP,R14                             64650013
*                   RESET     IP,CNP                                    64680013
*                   CLOBBERED  DP,R2,R3,R4,R15                          64710013
         SPACE 3                                                        64740013
ADD2     CLI   ILSW,ON                  DO NOTHING IF IN-LINE CODE IS   64770013
         BCR   BE,R14                 REQUIRED                          64800013
         ST    R14,ADSTOR               STORE LINK                      64830013
         MVI   BLSW,OFF                 SET SWITCH THAT INDICATES WHICH 64860013
*                                     ENTRY POINT WAS USED              64890013
         LH    R2,4(TP)                 DECOMPOSE FOURTH FIELD OF       64920013
         BAL   R14,DECOMP             STEP-TABLE INTO A REFERENCE AND A 64950013
*                                     CODE                              64980013
         MVC   TEMTRF(2),DHASH(DP)      PLACE CHAIN HEADER IN A CONT-   65010013
         MVC   TEMTRF+2(1),DDECNO(DP) IGUOUS AREA                       65040013
         TM    1(DP),BIT0               IF FIRST BIT OF LENGTH FIELD IS 65070013
         BC    BO,M6                  ZERO THEN THE CHAIN HAS NOT YET   65100013
*                                     BEEN STARTED                      65130013
         MVC   FESKLT+1(3),TEMTRF       STORE PREVIOUS CONTENTS OF      65160013
         MVC   FESKLT+4(2),ADR        FIELDS TO BE USED AS A CHAIN      65190013
         LA    R2,FESKLT              HEADER AS A SPECIAL INSERTION     65220013
         LA    R3,6                   FILE ENTRY OF FORM                65250013
         BAL   R14,ADIBUF                 FE,(PREVIOUS CONTENTS),       65280013
*                                         (DICTIONARY REFERENCE)        65310013
*                                     CONTENTS WILL BE RESTORED IN NEXT 65340013
*                                     PHASE                             65370013
         MVC   TEMTRF(3),ENDCHN         SET END-OF-CHAIN MARKER AS NEW  65400013
         OI    1(DP),BIT0             LINK, AND SET BIT IN LENGTH FIELD 65430013
         SPACE                                                          65460013
*              NOW CONSTRUCT ENTRY IN ADDRESSING CHAIN AND PLACE IT IN  65490013
*        THE INSERTION FILE                                             65520013
         SPACE                                                          65550013
M6       MVC   FFSKLT+1(2),BLKNO        USE BLOCK NUMBER OF CURRENT     65580013
*                                     BLOCK IN ADD2 CASE                65610013
         SPACE                                                          65640013
*              ALL PATHS CONVERGE HERE                                  65670013
         SPACE                                                          65700013
M6A      MVC   FFSKLT+2(1),ACODE        CREATE CHAIN ELEMENT OF FORM    65730013
         MVC   FFSKLT+3(2),PSTOR          X'FF', BLKNO, ACODE, PSTOR,   65760013
         MVC   FFSKLT+5(3),TEMTRF         (PREVIOUS LINK FIELD)         65790013
         LA    R2,FFSKLT                                                65820013
         LA    R3,8                                                     65850013
         BAL   R14,ADIBUF                                               65880013
         SPACE                                                          65910013
         MVC   PAR1+1(3),IBUFNM         CALCULATE TEXT REFERENCE TO     65940013
         LR    R4,IP                  THE INSERTION FILE ENTRY THAT HAS 65970013
         SH    R4,H8                  JUST BEEN GENERATED               66000013
         ST    R4,PAR2                                                  66030013
         CLI   0(TP),2                 CHANGE THE CODE BYTE OF THE      66060013
         BC    BNE,*+8               ENTRY IN THE INSERTION FILE TO     66090013
         MVI   0(R4),X'7F'           7F IF A TYPE 2 STEP TABLE ENTRY    66120013
*                                    IS BEEING PROCESSED.               66150013
         L     R15,ZTXTRF                                               66180013
         BALR  R14,R15                                                  66210013
         SPACE                                                          66240013
         CLI   BLSW,OFF                 IF ELEMENT IS IN A BLOCK CHAIN, 66270013
         BC    BE,M2                  SET CHAIN HEADER IN STACK TO      66300013
         MVC   STCHD(3,DP),PAR1+1     REFERENCE NEW ELEMENT             66330013
         BC    B,M4                     OTHERWISE, IN THE DICTIONARY    66360013
M2       MVC   DHASH(2,DP),PAR1+1     ENTRY CASE, SET CHAIN HEADER IN   66390013
         MVC   DDECNO(1,DP),PAR1+3    TWO DISJOINT FIELDS OF THE ENTRY  66420013
*                                     TYPE1                             66450013
         SPACE                                                          66480013
*              INSTRUCTION(S) ARE NOW GENERATED TO STORE THE DESIGNATED 66510013
*        ADDRESS IN PRIVATE STORAGE                                     66540013
         SPACE                                                          66570013
M4       BAL   R14,CONSTR               PREPARE TO CONSTRUCT INSTRUC-   66600013
*                                     TION, SETTING BASE AS PREG AND    66630013
         OI    2(CNP),PREGL           SWITCHING ON 'LITERAL OFFSET' BIT 66660013
         CLC   PSTOR(2),H4096           SKIP IF PRIVATE STORAGE IS NOT  66690013
         BC    BL,AM1                 OVER THE OFFSET                   66720013
         SPACE                                                          66750013
*              CASE WHERE PRIVATE STORAGE CELL IS OVER THE OFFSET. IT   66780013
*        IS NECESSARY TO USE THE PRIVATE STORAGE ADDRESSING VECTOR. IN  66810013
*        THIS CASE AN EXTRA WORKING REGISTER IS NEEDED, AND REGISTER 2  66840013
*        IS USED. THE GENERATED INSTRUCTIONS ARE SLOTTED IN AT THE END  66870013
*        OF THE COMMON PROLOG CODE, WHEN REGISTER TWO, AMONG OTHERS, IS 66900013
*        FREE                                                           66930013
         SPACE                                                          66960013
         LH    R4,PSTOR                 OFFSET IN ADDRESSING VECTOR     66990013
         SRL   R4,12                  IS GIVEN BY N WHERE               67020013
         SLL   R4,2                        N = (PSTOR/4096) * 4         67050013
         MVI   1(CNP),MCL               GENERATE INSTRUCTION OF FORM    67080013
         OI    2(CNP),BIT2                   L    PREG,N                67110013
         STH   R4,HTEMP               WITH BIT SET TO INDICATE R2 IS    67140013
         MVC   3(2,CNP),HTEMP         THE FIRST OPERAND                 67170013
         BAL   R14,CONSTR               PREPARE TO CONSTRUCT SECOND     67200013
*                                     INSTRUCTION, SETTING BASE AS R2   67230013
         OI    2(CNP),GR2L                                              67260013
         SPACE                                                          67290013
*              BOTH CASES RE-CONVERGE, THE BASE REGISTER FOR THIS NEXT  67320013
*        INSTRUCTION HAVING BEEN SET TO  PREG OR R2 AS APPROPRIATE      67350013
         SPACE                                                          67380013
AM1      MVI   1(CNP),MCST              GENERATE INSTRUCTION OF FORM    67410013
         MVC   3(2,CNP),PSTOR              ST    (PRESET BASE),         67440013
         NI    3(CNP),X'0F'                      (PSTOR MOD 4096)       67470013
         MVC   PSTOR2(2),PSTOR          SET PSTOR2 AS OFFSET OF         67500013
*                                     DESIGNATED ADDRESS                67530013
         LH    R4,PSTOR                 UPDATE PRIVATE STORAGE SIZE BY  67560013
         LA    R4,4(R4)               FOUR AND TEST FOR OVERFLOW        67590013
         C     R4,F32K                                                  67620013
         BC    BNL,ERROR2                                               67650013
         STH   R4,PSTOR                                                 67680013
         L     R14,ADSTOR               RESTORE LINK AND RETURN         67710013
         BCR   B,R14                                                    67740013
         SPACE 10                                                       67770013
*              ENTRY POINT FOR 'ADD' ROUTINE. THIS ROUTINE ADDS AN      67800013
*        ITEM TO THE ADDRESSING CHAIN OF THE CURRENT BLOCK. THE         67830013
*        CORRESPONDING STACK ENTRY IS POINTED AT BY SCPSTO.             67860013
         SPACE                                                          67890013
ADD      CLI   ILSW,ON                  RETURN IF IN-LINE CODE IS       67920013
         BCR   BE,R14                 REQUIRED                          67950013
         ST    R14,ADSTOR                                               67980013
         MVC   ACODE(1),OFTCNT          SET ACODE AS OFFSET COUNT       68010013
         L     DP,SCPSTO                SET TEMTRF TO CONTAIN CHAIN     68040013
         MVC   TEMTRF(3),STCHD(DP)    HEADER, AND PLACE BLOCK NUMBER OF 68070013
         L     R4,OFTAB               REQUIRED BLOCK IN SKELETON  10250 68090013
         MVC   FFSKLT+1(1),STBLOC(R4)                             10250 68110013
         MVI   BLSW,ON                  SET SWITCH TO INDICATE THAT     68130013
         BC    B,M6A                  THIS ENTRY POINT HAS BEEN USED    68160013
*                                     AND PROCEED TO CREATE CHAIN       68190013
*                                     ELEMENT                           68220013
         EJECT                                                          68250013
*              CHECK ROUTINE                                            70110013
         SPACE                                                          70140013
*        THE CHECK ROUTINE SETS THE CONDITION BITS TO 'PLUS' IF THE     70170013
*        NUMBER OF CONSTRUCTED INSTRUCTIONS EXCEEDS THE NUMBER OF       70200013
*        INSTRUCTIONS REQUIRED TO LOAD AN ADDRESS FROM PRIVATE STORAGE, 70230013
*        I.E. IF THERE IS ANY POINT IN STORING IN PRIVATE STORAGE  THE  70260013
*        ADDRESS CALCULATED BY THE CONSTRUCTED INSTRUCTIONS. RR INST-   70290013
*        RUCTIONS ARE NOT SPECIALLY DIFFERENTIATED SINCE THERE CAN BE   70320013
*        AT MOST ONE OF THEM                                            70350013
         SPACE                                                          70380013
*        PARAMETERS--    PSTOR CONTAINS THE CURRENT PRIVATE STORAGE     70410013
*                      SIZE                                             70440013
*                        PSLDSW IS ON IF ONE OF THE CURRENT INSTRUCT-   70470013
*                      IONS IS A PSLD (THERE CANNOT BE MORE THAN ONE    70500013
*                      PSLD)                                            70530013
         SPACE                                                          70560013
*        REGISTERS--INPUT      CNP,R14                                  70590013
*                   RESET     NONE                                      70620013
*                   CLOBBERED  R4,R15                                   70650013
         SPACE 3                                                        70680013
CHECK    LR    R4,CNP                   NUMBER OF CONSTRUCTED INSTRUCT- 70710013
         S     R4,CNPMIN              IONS IS (CNP-CNPMIN)/5 + 1,       70740013
         LA    R15,5                  UNLESS ONE OF THE CONSTRUCTED     70770013
         CLI   PSLDSW,ON              INSTRUCTIONS IS A PSLD, IN WHICH  70800013
         BC    BE,*+6                 CASE THE NUMBER IS ONE LESS       70830013
         AR    R4,R15                                                   70860013
         CLC   PSTOR(2),H4096           SUBTRACT ONE IF PSTOR IS LESS   70890013
         BC    BL,*+6                 THAN 4096, TWO OTHERWISE          70920013
         SR    R4,R15                                                   70950013
         SR    R4,R15                   THIS INSTRUCTION GIVES THE      70980013
         BCR   B,R14                  REQUIRED SETTING OF THE CONDITION 71010013
*                                     BITS                              71040013
         EJECT                                                          71070013
*              CONSTR ROUTINE                                           71100013
         SPACE                                                          71130013
*        THE CONSTRUCT ROUTINE IS USED TO PREPARE THE WAY FOR THE       71160013
*        ADDITION OF AN 'ADI' INSTRUCTION TO THE STACK                  71190013
         SPACE                                                          71220013
*        PARAMETERS--  THE BIT IN THE ADI INSTRUCTION TO INDICATE WHICH 71250013
*                      OPERAND IS TO BE MODIFIED IS SET IN THE BASIC    71280013
*                      ROUTINE OF THIS PHASE                            71310013
         SPACE                                                          71340013
*        REGISTERS--INPUT     CNP,R14                                   71370013
*                   RESET     CNP                                       71400013
*                   CLOBBERED  NONE                                     71430013
         SPACE      3                                                   71460013
CONSTR   LA    CNP,5(CNP)               UPDATE CNP                      71490013
         SPACE                                                          71610013
         MVC   0(5,CNP),ADISKT          PLACE SKELETON INSTRUCTION IN   71640013
         BCR   B,R14                  STACK AND RETURN. THE SKELETON    71670013
*                                     INSTRUCTION CONSISTS OF AN 'ADI'  71700013
*                                     MARKER FOLLOWED BY FOUR BYTES     71730013
*                                     WHICH ARE ALL ZERO EXCEPT THE     71760013
*                                     BIT INDICATING WHICH OPERAND IS   71790013
*                                     TO BE MODIFIED, WHICH IS SET      71820013
*                                     APPROPRIATELY                     71850013
         EJECT                                                          71880013
*              SETBLK ROUTINE                                           72780013
         SPACE                                                          72810013
*        THE SETBLK ROUTINE IS SUPPLIED A LEVEL NUMBER AS PARAMETER     72840013
*        AND FINDS THE BLOCK THAT HAS THAT LEVEL NUMBER, GENERATING A   72870013
*        STEP-TABLE ENTRY IF NECESSARY TO ADDRESS THE BLOCK             72900013
         SPACE                                                          72930013
*        PARAMETERS--  OPLEV CONTAINS THE LEVEL NUMBER                  72960013
         SPACE                                                          72990013
*        REGISTERS--INPUT     SCP,R14                                   73020013
*                   RESET     CNP                                       73050013
*                   CLOBBERED R4,R3                                     73080013
         SPACE 3                                                        73110013
SETBLK   CLC   STLEV(1,SCP),OPLEV       IF OPLEV IS EQUAL TO LEVEL      73140013
         BC    BNE,ST1                NUMBER OF CURRENT BLOCK THEN      73170013
         MVI   BASE,ADP               SET ADP AS BASE AND SET OFTAB TO  73200013
         ST    SCP,OFTAB              POINT TO LATEST STACK ENTRY       73230013
         BCR   B,R14                                                    73260013
         SPACE                                                          73290013
*              CASE OF ITEM NOT IN CURRENT BLOCK                        73320013
         SPACE                                                          73350013
ST1      LR    R4,SCP                   SEARCH STACK FOR AN ENTRY WITH  73380013
ST3      SH    R4,HSTSIZ              LEVEL NUMBER EQUAL TO OPLEV       73410013
         CLC   STLEV(1,R4),OPLEV                                        73440013
         BC    BE,ST2                                                   73470013
         C     R4,SCRST                 IF NO SUCH ENTRY IS FOUND THERE 73500013
         BC    BH,ST3                 IS A COMPILER ERROR               73530013
         BAL   R4,CMPERR                                                73560013
         SPACE                                                          73590013
*              R4  NOW POINTS AT THE RELEVANT STACK ENTRY               73620013
         SPACE                                                          73650013
ST2      ST    R4,OFTAB                 OFTAB = R4                      73680013
         MVI   BASE,PRVP                BASE = PRVP                     73710013
         MVI   0(TP),1                  MAKE STEP-TABLE ENTRY OF FORM   73740013
         MVC   HTEMP(2),STE1RF(R4)           1,0,REF+2,0                73770013
         LH    R3,HTEMP               WHERE REF IS THE DICTIONARY       73800013
         LA    R3,2(R3)               REFERENCE TO THE ENTRY TYPE 1 OF  73830013
         STH   R3,2(TP)               THE CONTAINING BLOCK              73860013
         BC    B,UPTP                   UPDATE TP  CONTROL WILL RETURN  73890013
*                                     TO THE ROUTINE THAT CALLED THIS   73920013
*                                     ROUTINE                           73950013
         EJECT                                                          73980013
*                   UPTP ROUTINE (INCLUDING UPTP1 ROUTINE)              74010013
         SPACE                                                          74040013
*              THE UPTP ROUTINE UPDATES TP, THE STEP-TABLE POINTER, AND 74070013
*        MAKES A PRELIMINARY ENTRY IN THE NEXT POSITION OF THE STEP-    74100013
*        TABLE                                                          74130013
         SPACE                                                          74160013
*        PARAMETERS--    NONE                                           74190013
         SPACE                                                          74220013
*        REGISTERS--INPUT     TP,R14                                    74250013
*                   RESET     TP                                        74280013
*                   CLOBBERED  NONE                                     74310013
         SPACE 3                                                        74340013
UPTP     LA    TP,6(TP)                 UPDATE TP                       74370013
UPTP1    MVI   0(TP),2                  MAKE PRELIMINARY STEP-TABLE     74400013
         XC    1(5,TP),1(TP)          ENTRY OF FORM                     74430013
*                                         2,0,0,0                       74460013
*                                       (WHERE THE REQUIRED ENTRY DIF-  74490013
*                                     FERS FROM THIS, THE RELEVANT      74520013
*                                     FIELDS WILL BE OVERWRITTEN)       74550013
         BCR   B,R14                    RETURN                          74580013
         EJECT                                                          75780013
*              BRANCH LABEL DEFINITIONS                                 75810013
L59      EQU   DTG1                                                     75840013
L140     EQU   DTB1                                                     75870013
         EJECT                                                          75900013
THREE    DC    F'3'                                                     75930013
NOOFF    DC    X'00'                                                    75960013
CMPERR   EQU   THREE                    FIRST BYTE IS X'00'             78960001
ERROR2   EQU   CMPERR                                                   81960001
         EJECT                                                          84960001
         LTORG                                                          87960001
         ORG   IEMRB+4095                                               90960001
         END   IEMRB                                                    93960001
