RG       TITLE 'IEMRG, SECOND PASS, REGISTER ALLOCATION, PL/I F'        00040013
*              REGISTER ALLOCATER. SECOND CONTROL SECTION.              00080013
*                                                                       00120013
*                                                                       00160013
*              STATUS-CHANGE LEVEL 0                                    00240013
*                                                                       00260064
* 5.4  A 360600                                                KT 54713 00262064
* 5.4  C 394800                                                KT 54713 00264064
* 5.2B C 411800,806400                                         KT 38181 00266064
* 5.2B C 394800                                                KT 34339 00268064
* 5.2  C 414500                                               JRT 30324 00270064
* 5.1  C7827970                                                   27213 00272064
* 5.1  C 645302                                                    H379 00274064
* 5.1  C 180890,702004,825100                                     27143 00276064
*                                                                       00280013
*                                                                       00320013
*                                                                       00360013
*                                                                       00400013
*              THIS CONTROL SECTION CONTAINS TWO SUBROUTINES, OBREGS    00450001
*        AND LOOKAH, WHICH ARE BRANCHED TO FROM THE MAIN LINE           00500001
*        PROCESSING IN PHASE RF.                                        00550042
         SPACE 5                                                        00600001
*        THE SUBROUTINE 'OBREGS'.                                       00650001
         SPACE 1                                                        00700001
*              THE FUNCTION OF THIS SUBROUTINE IS TO PROCESS THE        00750001
*        REQUESTS FOR REGISTERS PRESENTED IN 'LIST' AND ASSIGN PHYSICAL 00800001
*        REGISTERS TO THESE REQUESTS.                                   00850001
*              THE FOLLOWING LISTS/TABLES ARE USED BY OBREGS:           00900001
*              1) LIST - THIS INDICATES THE REGISTERS REQUIRED FROM     00950001
*                        THIS CALL OF OBREGS. IT IS HELD IN PHASE RF.   01000001
*              2) REGTAB - THIS IS A TABLE CONTAINING INFORMATION ON    01050001
*                        THE CURRENT STATUS AND USE OF THE PHYSICAL     01100001
*                        REGISTERS 1-8. THE OTHER PHYSICAL REGISTERS,   01150001
*                        0 AND 9-15 ARE NOT ALLOCATED AS GENERAL        01200001
*                        REGISTERS BY REGISTER ALLOCATOR. THEY ARE      01250001
*                        ONLY USED BY CODE MAKING A SPECIFIC REQUEST    01300001
*                        FOR THEM, OR FOR SPECIFIC BASES. REGTAB IS     01350001
*                        HELD IN PHASE RF.                              01400001
*              3) SYMBOLIC REGISTER CHAIN - THIS IS A LIST CONTAINING   01450001
*                        INFORMATION ABOUT ALL SYMBOLIC REGISTERS       01500001
*                        WHICH HAVE BEEN STORED IN PRIVATE STORAGE      01550001
*                        OFFSETS. THESE WILL BE REGISTERS DISPLACED     01600001
*                        FROM A PHYSICAL REGISTER (AND THEREFORE FROM   01650001
*                        REGTAB) BY REASON OF A REGISTER BIND. THIS     01700001
*                        CHAIN IS HELD IN SCRATCH CORE.                 01750001
*              4) ASSIGNED REGISTER CHAINS - THESE LISTS CONTAIN        01800001
*                        INFORMATION ABOUT ASSIGNED REGISTERS WHICH     01850001
*                        HAVE BEEN DISPLACED FROM REGTAB. THERE IS      01900001
*                        ONE CHAIN FOR EACH ASSIGNED REGISTER 1-8.      01950001
*                        ASSIGNED REGISTERS ARE USUALLY ONLY DISPLACED  02000001
*                        BY NESTED ASSIGNED USE OF THE SAME REGISTER    02050001
*                        SUCH AS IN NESTED FUNCTION CALLS. THIS CHAIN   02100001
*                        IS HELD IN SCRATCH CORE.                       02150001
*              5) FREE PRIVATE STORAGE CELL CHAIN - THIS LIST CONTAINS  02200001
*                        THE OFFSETS OF ALL PRIVATE STORAGE CELLS NOT   02250001
*                        CURRENTLY IN USE. THIS CHAIN IS HELD IN        02300001
*                        SCRATCH CORE.                                  02350001
*              6) SINDEX TABLE - THIS TABLE INDICATES WHICH PHYSICAL    02400001
*                        REGISTERS CURRENTLY HAVE SINDEXES ASSIGNED     02450001
*                        TO THEM. A SINDEX MAY BE ASSIGNED TO A         02500001
*                        PHYSICAL REGISTER, BUT NOT ACTUALLY BE IN      02550001
*                        THAT REGISTER AT A GIVEN POINT. THIS TABLE     02600001
*                        IS HELD IN PHASE RF.                           02650001
*              THE FORMATS PF ALL THE ABOVE TABLES ARE GIVEN IN THE     02700001
*        EQU'S WHICH APPEAR BELOW, OR IN THE INTRODUCTIIN TO PHASES     02750001
*        RF AND RH.                                                     02800001
         SPACE 3                                                        02850001
*              THE OPERATION OF THE SUBROUTINE IS AS FOLLOWS:           02900001
         SPACE 1                                                        02950001
*              1) LIST IS SCANNED FOR REQUESTS FOR SYMBOLIC REGISTERS.  03000001
*        IF A REQUEST IS FOUND REGTAB IS SCANNED. IF THE SYMBOLIC       03050001
*        REGISTER IS IN REGTAB THE PHYSICAL REGISTER NUMBER IS SET      03100001
*        IN LIST AND THE REQUEST IS MARKED AS SATISFIED. IF THE         03150001
*        REGISTER IS NOT IN REGTAB IT IS ADDED TO REQLST, A LIST OF     03200001
*        REQUESTS NOT YET SATISFIED. REQLST IS HELD IN PHASE RF.        03250001
         SPACE 1                                                        03300001
*              2) LIST IS SCANNED FOR REQUESTS FOR ASSIGNED REGISTERS.  03350001
*        IF A REQUEST IS FOUND FOR AN ASSIGNED REGISTER OUT OF THE      03400001
*        RANGE 1-8 THE REQUEST IS MARKED SATISFIED, AND THE PHYSICAL    03450001
*        REGISTER NUMBER IS INSERTED INT LIST. IF A REQUEST IS FOUND IN 03500001
*        THE RANGE 1-8 THE REGTAB ENTRY IS ACCESSED. IF THE PHYSICAL    03550001
*        REGISTER IS ALREADY OCCUPIED BY AN ASSIGNED REGISTER AT THE    03600001
*        CURRENT IPRM/EPRM (ICOUNT) LEVEL THEN THE REQUEST IS           03650001
*        SATISFIED. IF THE PHYSICAL REGISTER CURRENTLY HAS A DIFFERENT  03700001
*        USE THE REGISTER IS FREED UP FOR THIS NEW USE. THIS MAY        03750001
*        INVOLVE GENERATING A STORE TO SAVE THE CURRENT USE, OR, IF THE 03800001
*        CURRENT USE IS IN THIS INSTRUCTION, GENERATING A LOAD          03850001
*        REGISTER. THIS LAST CASE IS DEALT WITH BY ADDING THE CURRENT   03900001
*        USE TO REQLST AND INDICATING THAT THE REQUEST IS CURRENTLY     03950001
*        IN A 'WRONG' REGISTER.                                         04000001
         SPACE 1                                                        04050001
*              3) AS EACH REQUEST IS ADDED TO REQLST A COUNT, REGREQ,   04100001
*        IS INCREMENTED BY 1 FOR A SINGLE REGISTER OR 8 FOR A PAIR,     04150001
*        GIVING THE NUMBER OF REQUESTS STILL TO BE SATISFIED.           04200001
         SPACE 1                                                        04250001
*              4) REGTAB IS SCANNED BUILDING STLIST, A LIST OF THE      04300001
*        STATUS OF EACH PHYSICAL REGISTER. THIS STATUS GIVES A          04350001
*        PRIORITY TO EACH REGISTER, FROM ZERO FOR A FREE REGISTER TO    04400001
*        128 FOR A REGISTER WANTED IN THIS INSTRUCTION.                 04450001
         SPACE 1                                                        04500001
*              5) SUFFICIENT REGISTERS ARE FREED IN REGTAB (GENERATING  04550001
*        STORES AS NECESSARY) TO SATISFY THE NUMBER OF REQUESTS GIVEN   04600001
*        BY THE COUNT REGREQ. THESE REGISTERS ARE SELECTED IN           04650001
*        ASCENDING ORDER OF PRIORITY, I.E. THOSE WITH THE LOWEST STATUS 04700001
*        ARE FREED FIRST. AS THE REGISTERS ARE FREED THEY ARE ADDED     04750001
*        TO A LIST OF FREE REGISTERS, FRLIST.                           04800001
         SPACE 1                                                        04850001
*              6) REGISTERS ARE ALLOCATED FROM FRLIST TO SATISFY THE    04900001
*        REQUESTS IN REQLST. THE REGNUM FIELD IS COMPLETED IN LIST,     04950001
*        AND THE REGTAB ENTRIES ARE UPDATED TO SHOW THEIR NEW USES.     05000001
*        LOADS OR LOAD REGISTERS ARE GENERATED FOR ANY REGISTERS WHICH  05050001
*        HAVE A PREVIOUS VALUE IN PRIVATE STORAGE OR ANOTHER REGISTER.  05100001
         SPACE 1                                                        05150001
*              7) CONTROL IS RETURNED TO THE CALLING ROUTINE.           05200001
         SPACE 3                                                        05250001
*        THE ENTRY POINT IS AT OBREGS, BRANCHED TO BY BAL R14,OBREGS,   05300001
*        VIA THE TRANSFER VECTOR AT THE START OF RG.                    05350001
*        THE EXIT IS A BRANCH ON R14.                                   05400001
*        THE SUBROUTINE USES A NUMBER OF EXTERNAL SERVICE ROUTINES      05450001
*        HELD IN PHASE RF. THESE ARE DESCRIBED IN RF.                   05500001
         EJECT                                                          05550001
*        THE SUBROUTINE 'LOOKAH'.                                       05600001
         SPACE 1                                                        05650001
*              THE FUNCTION OF THIS SUBROUTINE IS TO LOOK AHEAD FROM    05700001
*        A BRANCH OUT POINT TO SEE IF THERE IS ANY REGISTER ACTIVITY    05750001
*        BEFORE THE BRANCH IN POINT. IF ALL ACTIVITY IS SAFE THE        05800001
*        BRANCH MAY BE OPTIMISED.                                       05850001
*              THIS SUBROUTINE IS ONLY USED UNDER OPT=2 OR GREATER,     05900001
*        AND IS ONLY INVOKED FOR BRANCHES WHICH HAVE BEEN MARKED AS     05950001
*        POSSIBLY OPTIMISABLE BY PHASE RD. FOR THE BRANCH TO HAVE       06000001
*        BEEN SO MARKED BY RD IT MUST SATISFY THE FOLLOWING             06050001
*        CONDITIONS:                                                    06100001
*                   1) THE BRANCH OUT POINT MUST PRECEED ITS BRANCH IN  06150001
*                      POINT                                            06200001
*                   2) THE BRANCH IN POINT MUST BE ONLY REFERENCED IN   06250001
*                      THE ONE BRANCH OUT INSTRUCTION, AND IN NO OTHER  06300001
*                      INSTRUCTION                                      06350001
*                   3) THE BRANCH OUT MUST BE A BC INSTRUCTION, AND     06400001
*                      THE BRANCH IN MUST BE AN EQU ITEM                06450001
         SPACE 3                                                        06500001
*              THE OPERATION OF THE SUBROUTINE IS AS FOLLOWS:           06550001
         SPACE 1                                                        06600001
*              A SCAN FORWARD IS MADE FROM THE BC INSTRUCTION, LOOKING  06650001
*        FOR ITS EQU ITEM.                                              06700001
*              IF A BRANCH IN OR BRANCH OUT IS FOUND BEFORE MEETING     06750001
*        THE EQU ITEM THE SCAN IS TERMINATED.                           06800001
*              IF A REGISTER USE IS DETECTED WHICH CANNOT BE SATISFIED  06850001
*        FROM THE CURRENT CONTENTS OF REGTAB THEN THE SCAN IS           06900001
*        TERMINATED.                                                    06950001
*              IF THERE ARE MORE THAN FIVE PSEUDO-CODE ITEMS BEFORE THE 07000001
*        EQU IS MET THEN THE SCAN IS TERMINATED.                        07050001
*              IF THE SCAN IS TERMINATED FOR ANY OF THE ABOVE REASONS   07100001
*        THEN THE BRANCH IS MARKED AS NOT OPTIMISABLE, AND A RETURN     07150001
*        IS MADE TO THE MAIN PROCESSING ROUTINE IN RH.                  07200001
*              IF THE EQU IS MET BEFORE TERMINATING THE SCAN THE EQU    07250001
*        IS MARKED OPTIMISABLE, AND LOADS AND STORES ARE OMITTED AT     07300001
*        THE BRANCH OUT. THE MAIN SCAN IS THEN RESUMED. WHEN THE        07350001
*        MARKED EQU IS MET LOADS AND STORES ARE AGAIN OMITTED.          07400001
         EJECT                                                          07450001
         SPACE 5                                                        08360013
IEMRG    START 0                                                        08400013
         USING *,GRRG                                                   08440013
CR       EQU   *+4096                  COMMUNICATIONS REGION            08480013
         USING CR,GRDIC                                                 08520013
CC       EQU   *+8192                  COMPILER CONTROL                 08560013
         USING CC,GRCC                                                  08600013
RF       EQU   *+12288                 BLOCK RF                         08640013
         USING RF,GRRF                                                  08680013
         DC    C'RG'                                                    08720013
         EJECT                                                          08760013
*              TRANSFER VECTOR TO ROUTINES IN RG                        08810001
         SPACE 3                                                        08860001
         BC    B,OB950                                                  08910001
         BC    B,OBREGS                                                 08960001
         BC    B,LOOKAH                                                 09010001
         EJECT                                                          09080013
*              THIS IS THE MAIN ENTRY POINT TO OBREGS AND IS USED TO    09120013
*        OBTAIN PHYSICAL REGISTER NUMBERS FOR THE SYMBOLIC AND          09160013
*        ASSIGNED REGISTERS IN LIST.                                    09200013
         SPACE 4                                                        09240013
*              FIRST SCAN OF LIST                                       09280013
*                                                                       09320013
*              FUNCTION/OPERATION   LIST IS SCANNED FOR OCCURRENCES     09360013
*        OF BASES AND SYMBOLIC REGISTERS. IF A REQUEST FOR A BASE IS    09400013
*        MET NO OTHER REQUESTS MUST BE PRESENT. A REQUEST FOR A BASE    09440013
*        IS SERVICED IMMEDIATELY. REQUESTS FOR SYMBOLIC REGISTERS ARE   09480013
*        ENTERED IN REQLST, IF THEY ARE NOT ALREADY IN A REGISTER. LIST 09520013
*        IS MODIFIED TO REFLECT WHAT HAS HAPPENED. IF A PAIR MEMBER IS  09560013
*        REQUESTED AND IS NOT ALREADY IN A REGISTER TWO ENTRIES ARE     09600013
*        MADE IN REQLST.                                                09640013
*                                                                       09680013
*              ENTRY POINT - OBREGS TO PERFORM ABOVE SCAN. OUTPUT       09720013
*        PARAMETERS ARE  REGISTER T -POINTING TO NEXT FREE SPACE IN     09760013
*        REQLST                                                         09800013
*                                 REGREQ - CONTAINING THE NUMBER OF     09840013
*        REGISTERS REQUIRED.                                            09880013
*                                                                       09920013
*              EXTERNAL ROUTINES - CHAIN IN IEMRF IS USED TO SCAN DOWN  09960013
*        THE LIST OF STORED SYMBOLIC REGISTERS.                         10000013
*                                                                       10040013
*              EXITS NORMAL - AFTER OB017 IF A BASE IS REQUIRED (LIST   10080013
*        IS NOT FULLY SCANNED IN THIS CASE)                             10120013
*                           - AFTER OB031 TO OB300 WHEN LIST HAS BEEN   10160013
*        FULLY SCANNED.                                                 10200013
*                                                                       10240013
*              EXITS ERROR - NONE                                       10280013
*                                                                       10320013
*              TABLES/WORK AREAS  LIST AND REGTAB IN IEMRF ARE USED     10360013
*                                 REQLST IN THIS MODULE IS CONSTRUCTED  10400013
*                                 THE LIST OF STORED SYMBOLIC REGISTERS 10440013
*        IN SCRATCH IS SCANNED.                                         10480013
*                                                                       10520013
*              NOTES - IF A REQUIRED REGISTER IS FOUND IN THE REGISTER  10560013
*        TABLE ,  CODE BITS IN FIELD F1 ( E.G. ALTERED BY THIS          10600013
*        INSTRUCTION) ARE SET AS INDICATED BY THE 'LIST' ENTRY. IF A    10640013
*        REQUESTED SYMBOLIC REGISTER IS FOUND TO BE STORED, THE         10680013
*        OFFSET FROM PREG WHERE IT IS STORED IS ENTERED IN THE F4       10720013
*        FIELD OF THE REQLST ENTRY. IF TWO REQUESTS FOR THE SAME        10760013
*        SYMBOLIC REGISTER ARE MADE, AND THIS IS NOT IN A PHYSICAL      10800013
*        REGISTER, ONLY ONE ENTRY IN REQLST IS MADE.                    10840013
         SPACE 3                                                        10880013
OBREGS   STM   14,8,OBSTOR             SAVE REGISTERS                   10920013
         MVI   REQLST,OFF               ZEROISE REQLST                  10930001
         MVC   REQLST+1(54),REQLST                                      10940001
         MVI   BALRSW,OFF                                               10960013
        CLI   0(R1),MCBALR            IS THIS A BALR BEING PROCESSED    11000013
         BC    BE,ABNTST               BRANCH, IF SO.                   11040013
OB10    EQU   *                                                         11080013
         LA    P,LIST                  SET UP THE REGISTER TO SCAN LIST 11120013
         LA    T,REQLST              AND REQLST POINTER T SUCH THAT     11160013
*                                    REQLIST IS EMPTY.                  11200013
         SR    LR,LR                   TEST FOR AN EXTRA BASE REGISTER  11240013
         CLI   SW1,ON                BEING REQUIRED BECAUSE OF          11280013
         BC    BE,OB018              A REFERENCE TO A LABEL. BRANCH IF  11320013
         ST    LR,REGREQ             ONE IS.  OTHERWISE SET REGREQ=0    11360013
         SPACE                                                          11400013
OB015    CLI   CODE1(P),BASREQ         DOES CODE1 IN THE CURRENT ENTRY  11440013
*                                    IN LIST REQUIRE A BASE             11480013
         BC    BNE,OB020               BRANCH IF NOT.                   11520013
         SPACE                                                          11560013
         SPACE                                                          11600013
OB017    LA    LR,1(LR)                SET REGREQ TO ONE.               11640013
         ST    LR,REGREQ                                                11680013
         MVI   BSW,ON                  SET BASE SWITCH ON               11720013
         SPACE 10                                                       11722015
OBASE    SR    R3,R3                                                    11724015
         STH   R3,BSTBAS                                                11726015
         BCTR  R3,0                                                     11728015
         STH   R3,BNADI                                                 11730015
         CLI   MADI+1,23               IF MORE THAN SIX ADI'S USED      11730515
         BC    BH,OB560              BRANCH SINCE NO ATTEMPT TO COMMON  11731015
*                                    IS MADE.                           11731515
         LA    R3,BSETAB                                                11732015
         LA    REGNO,REGTAB                                             11734015
         LA    PHRGNO,1                                                 11736015
         SPACE                                                          11738015
OBS1     TM    F1(REGNO),X'40'         BRANCH IF REGISTER IS NOT A BASE 11740015
         BC    BO,OBS10                                                 11742015
         TM    F1(REGNO),X'80'                                          11744015
         BC    BZ,OBS10                                                 11746015
         SR    LR,LR                   OTHERWISE, PICK UP LENGTH-1 OF   11748015
         IC    LR,F3+2(REGNO)        ASSOCIATED BASE TAB ENTRY          11750015
         LTR   LR,LR                   LENGTH-1=0 MEANS BASE CANNOT BE  11750615
         BC    BE,OBS10              COMMONED. IF THE CASE, BRANCH      11751215
         CH    LR,BNADI                BRANCH OUT IF NOT LONGER THAN    11752015
         BC    BLE,OBS10             BEST MATCH SO FAR,                 11754015
         CH    LR,MADI               OR IF LONGER THAN REQUIRED FOR     11756015
         BC    BH,OBS10              BASE BEING REQUESTED               11758015
         EX    LR,ADICMP               OTHERWISE COMPARE ADI'S          11760015
         BC    BNE,OBS10               IF DIFFERENT GO TO TRY NEXT REG. 11762015
ADICMP   CLC   ADILST(0),0(R3)         EXECUTED ABOVE                   11764015
         SPACE 3                                                        11766015
         STH   LR,BNADI                THIS IS THE BEST MATCH FOUND SO  11768015
         STH   PHRGNO,BSTBAS         FAR. SAVE INFORMATION IDENTIFYING  11770015
         ST    REGNO,BSTRGT          IT.                                11772015
         SPACE                                                          11774015
         CH    LR,MADI                 IF FULL LENGTH MATCH, NO NEED    11776015
         BC    BE,OB871              TO SEAFCH FURTHER                  11778015
         SPACE 3                                                        11780015
OBS10    C     REGNO,REGNO2            IS THIS THE END OF REGTAB        11782015
         BC    BE,OB560                BRANCH IF SO TO GET A REGISTER   11784015
         LA    REGNO,RGTLTH(REGNO)     BUMP REGTAB POINTER              11786015
         LA    R3,BTLTH(0,R3)          BUMP BSETAB POINTER              11788015
         LA    PHRGNO,1(0,PHRGNO)      BUMP REGISTER NUMBER             11790015
         BC    B,OBS1                  RETURN TO EXAMINE NEW REGISTER   11792015
         EJECT                                                          11794015
         SPACE                                                          11800013
OB018    LA    LR,1(LR)                                                 11840013
         ST    LR,REGREQ               SET REGREQ TO ONE.               11880013
         SPACE                                                          11920013
OB020    CLI   CODE1(P),EXORAS         HAS THIS ENTRY TO BE EXAMINED    11960013
         BC    BE,OB035                BRANCH IF IT HAS                 12000013
         SPACE                                                          12040013
OB030    LA    P,LSTLTH(P)             BUMP P TO NEXT ELEMENT IN LIST.  12080013
OB031    C     P,P2                    IS THIS THE END OF LIST          12120013
         BC    BNE,OB015               BRANCH TO EXAMINE THE ELEMENT IN 12160013
*        LIST IF THIS IS NOT THE END.                                   12200013
         SPACE 2                                                        12240013
*              THE SYMBOLIC REGISTERS IN LIST HAVE BEEN EXAMINED SO     12280013
*        NOW BRANCH TO EXAMINE THE ASSIGNED REGISTERS.                  12320013
         BC    B,OB300                                                  12360013
         SPACE 2                                                        12400013
OB035    NI    REGNAM(P),NOBIT0        SET OFF THE FIRST FLAG BIT IN    12440013
*                                    THE REGISTER NAME.                 12480013
         CLI   REGNAM(P),ALLZRO        TEST FOR THE TOP BYTE OF THE     12520013
*        SYMBOLIC REGISTER NUMBER BEING ZERO. IT WILL BE AN ASSIGNED    12560013
*        REGISTER IF IT IS.                                             12600013
         SPACE                                                          12640013
         BC    BZ,OB030                BRANCH IF NOT SYMBOLIC           12680013
         L     PHRGNO,ONE              SET PHYSICAL REGISTER NUMBER TO  12720013
         LA    REGNO,REGTAB          ONE AND SET REGNO TO POINT AT THE  12760013
*                                    REGISTER TABLE.                    12800013
         MVC   REG(2),REGNAM(P)        STORE THE NAME OF THE SYMBOLIC   12840013
*                                    REGISTER IN REG.                   12880013
         SPACE 2                                                        12920013
OB040    TM    F1(REGNO),BITS01        TEST FOR THE CONTENTS OF THE     12960013
*        PHYSICAL REGISTER BEING THE VALUE OF A SYMBOLIC REGISTER.      13000013
         BC    BO,OB050                BRANCH IF IT IS SYMBOLIC         13040013
         SPACE                                                          13080013
OB045    C     REGNO,REGNO2            TEST FOR THE LAST ENTRY IN THE   13120013
*                                    REGISTER TABLE.                    13160013
         BC    BE,OB100                BRANCH IF IT IS.                 13200013
         A     PHRGNO,ONE              BUMP PHYSICAL REGISTER NUMBER BY 13240013
         LA    REGNO,RGTLTH(REGNO)   1 BUMP REGNO BY THE LENGTH OF AN   13280013
*                                    ENTRY IN THE REGISTER TABLE.       13320013
         BC    B,OB040                 BRANCH TO EXAMINE THE NEXT ENTRY 13360013
         SPACE                                                          13400013
*        HERE THE CONTENTS OF THE PHYSICAL REGISTER IS THE VALUE OF A   13440013
*        SYMBOLIC REGISTER.                                             13480013
         SPACE                                                          13520013
OB050    CLC   REG(2),F3+1(REGNO)      IS THE REGISTER NAME IN REG THE  13560013
*        SAME AS THAT OCCUPYING THE PHYSICAL REGISTER.                  13600013
         BC    BNE,OB045               BRANCH IF IT IS NOT.             13640013
         SPACE 2                                                        13680013
*        WE HAVE FOUND THAT THE PHYSICAL REGISTER  CONTAINS THE VALUE   13720013
*        OF THE SYMBOLIC REGISTER WE ARE EXAINING                       13760013
         SPACE                                                          13800013
         MVI   CODE1(P),INREG          MARK THE ABOVE FACT IN LIST.     13840013
         STC   PHRGNO,REGNAM+1(P)      STORE THE PHYSICAL REGISTER      13880013
         STC   PHRGNO,REGNUM(P)      NUMBER IN CORRECT FIELDS IN LIST.  13920013
         OI    F1(REGNO),WANTED        MARK THE PHYSICAL REGISTER       13960013
*                                    WANTED                             14000013
         TM    CODE2(P),CHNGES         IS THIS SYMBOLIC REGISTER        14040013
*                                    CHANGED BY THE INSTRUCTION         14080013
         BC    BZ,OB070                BRANCH IF IT IS NOT.             14120013
         SPACE                                                          14160013
         OI    F1(REGNO),CHNGED       MARK THE PHYSICAL REGISTER AS     14200013
*                                    CHANGED.                           14240013
OB070    EQU   *                                                        14320001
         SPACE                                                          14400013
OB075    TM    F1(REGNO),PAIRMM        IS THE PHYSICAL REGISTER A       14440013
*                                    MEMBER OF A PAIR.                  14480013
         BC    BNO,OB030               BRANCH IF IT IS NOT.             14520013
         SPACE                                                          14560013
*              WE NOW HAVE TO TEST FOR THE PHYSICAL REGISTER NUMBER     14600013
*        BEING EVEN.                                                    14640013
         EX    PHRGNO,TESTUM           SEE OB400.                       14680013
         BC    BZ,OB080                BRANCH IF THERE WAS NO LOW       14720013
*        ORDER BIT IN THE PHYSICAL REGISTER NUMBER.                     14760013
         SPACE                                                          14800013
         BCTR  PHRGNO,0                DECREMENT THE REGISTER NUMBER    14840013
         S     REGNO,RGTBLT          BY ONE AND THE REGISTER TABLE      14880013
*        POINTER BY THE LENGTH OF AN ENTRY.                             14920013
         BC    B,OB090                                                  14960013
         SPACE                                                          15000013
*        HERE THE PHYSICAL REGISTER NUMBER WAS EVEN SO THE OTHER HALF   15040013
*        OF THE PAIR IS OBTAINED BY BUMPING BY ONE.                     15080013
OB080    LA    PHRGNO,1(PHRGNO)        BUMP THE REGISTER NUMBER BY ONE  15120013
         LA    REGNO,RGTLTH(REGNO)   AND THE TABLE POINTER BY AN ENTRY  15160013
*                                    LENGTH.                            15200013
OB090    EQU   *                                                        15280001
         SPACE                                                          15360013
OB095    OI    F1(REGNO),WANTED        MARK THIS OTHER MEMBER AS WANTED 15400013
         TM    CODE2(P),CHNGES         DOES THE INSTRUCTION BEING       15440013
*        EXAMINED CHANGE THE CONTENTS OF THIS MEMBER OF THE PAIR.       15480013
         BC    BZ,OB030                BRANCH IF IT DOES NOT            15520013
         SPACE                                                          15560013
         OI    F1(REGNO),CHNGED        OTHERWISE MARK THE PHYSICAL      15600013
*                                    REGISTER AS CHANGED.               15640013
         BC    B,OB030                                                  15680013
         SPACE 10                                                       15720013
*              AT THIS POINT THE SYMBOLIC REGISTER IS NOT ALREADY IN A  15760013
*        PHYSICAL REGISTER. IT MUST BE ADDED TO THE REQUEST LIST REQLST 15800013
*        IF IT IS NOT ALREADY IN THERE.                                 15840013
         SPACE 2                                                        15880013
OB100    LA    P16,REQLST              SET P16 TO HEAD OF REQLST        15920013
OB110    CR    P16,T                   IS THIS THE END OF REQLST        15960013
         BC    BE,OB150                BRANCH IF IT IS.                 16000013
         TM    F1(P16),BITS01          TEST FIRST TWO BITS IN FIELD F1  16040013
*                                    FOR ALL ONES TO INDICATE SYMBOLIC  16080013
         BC    BO,OB120                BRANCH IF SYMBOLIC               16120013
OB115    LA    P16,RQLLTH(P16)         OTHERWISE BUMP P16 BY THE LENGTH 16160013
*        OF AN ENTRY IN REQLST                                          16200013
         BC    B,OB110                 BRANCH TO EXAMINE NEXT ENTRY IN  16240013
*                                    REQLST.                            16280013
         SPACE 4                                                        16320013
OB120    CLC   REG(2),F3+1(P16)        IS THE NAME OF THE SYMBOLIC      16360013
*        REGISTER IN REQLST THE SAME AS THAT IN REG.                    16400013
         BC    BNE,OB115               BRANCH IF IT IS NOT.             16440013
         SPACE 2                                                        16480013
*        THE REGISTER NAME IS ALREADY IN REQLST SO NO NEW ENTRY NEED    16520013
*        BE MADE FOR IT. THE ENTRY IN LIST MUST BE MARKED AS REQUIRING  16560013
*        A REGISTER.                                                    16600013
         SPACE                                                          16640013
         MVI   0(P),FNDREG                                              16680013
         LR    LR,P16                  CALCULATE THE OFFSET OF P16      16720013
         LA    RR,REQLST             FROM THE START OF REQLST.          16760013
         SR    LR,RR                                                    16800013
         STH   LR,PHYSRG               STORE THIS OFFSET IN THE ENTRY   16840013
         MVC   REGNAM(2,P),PHYSRG    IN LIST POINTED AT BY P.           16880013
         SPACE                                                          16920013
         TM    CODE2(P),CHNGES         IS THIS OCCURRENCE OF THE        16960013
*        SYMBOLIC REGISTER ALTERED BY THE INSTRUCTION                   17000013
         BC    BNO,OB030               BRANCH IF IT IS NOT              17040013
         OI    F1(P16),CHNGED          OTHERWISE MARK REQLIST AS        17080013
*                                    BEING CHANGED.                     17120013
         BC    B,OB030                 BRANCH TO EXAMINE THE NEXT       17160013
*                                    ITEM IN LIST.                      17200013
         SPACE 4                                                        17240013
*              THE END OF REQLIST HAS BEEN FOUND WITHOUT FINDING THE    17280013
*        SYMBOLIC REGISTER. THE SYMBOLIC REGISTER CHAIN IS NOW SCANNED  17320013
*        FOR THIS NAME.                                                 17360013
         SPACE                                                          17400013
OB150    LA    R2,SYMCHD+1             SET UP THE ADDRESS OF THE HEAD   17440013
*                                    OF THE SYMBOLIC CHAIN.             17480013
         LA    R3,COMPRG               SET UP THE ADDRESS OF AN         17520013
*                                    INSTRUCTION TO COMPAIR THE NAME IN 17560013
*                                    THE CHAIN ENTRY WITH THAT IN REG   17600013
*                                                                       17640013
         BAL   RR,CHAIN                                                 17680013
         SPACE                                                          17720013
         LA    R2,MINUS1-PSTOFF        FIRST RETURN, NOT FOUND SO SET   17760013
*        R2 TO POINT THE DISTANCE BEFORE A WORD OF F'S THAT THE PSTOR   17800013
*        OFFSET IS FROM THE START OF A CHAIN ENTRY                      17840013
         SPACE                                                          17880013
         MVC   PSTOR2(2),PSTOFF(R2)    THIS INSTRUCTION MOVES EITHER    17920013
*        THE PSTOR OFFSET OR ALL F'S INTO PSTOR2.                       17960013
         SPACE 1                                                        17966001
         TM    SYM1(R2),BIT1            IS THIS ASINDEX REGISTER -      17972001
         BC    BZ,OB160                   SET RELEVANT BIT IN CODE2     17978001
         OI    CODE2(P),NOST              OF LIST IF SO                 17984001
OB160    EQU   *                                                        17990001
         SPACE                                                          18000013
         MVI   F1(T),SUWNP                                   THE FIELD  18040013
*        F1 IN THE NEW ENTRY TO BE MADE IN REQLST IS SET TO  SYMBOLIC,  18080013
*        UNCHANGED, WANTED, NOT PAIR.                                   18120013
         MVC   F3+1(2,T),REG           STORE THE CONTENTS OF REG IN THE 18160013
*                                    NEW ENTRY ON REQLST, AND ALSO THE  18200013
         MVC   F4(2,T),PSTOR2        VALUE OF PSTOR2.                   18240013
         MVI   F5(T),ALLONE            FIELD F5 EQUALS X'FF'            18280013
         TM    CODE2(P),CHNGES         DOES THE SYMBOLIC REGISTER HAVE  18320013
*                                    ITS VALUE ALTERED.                 18360013
         BC    BZ,OB170                BRANCH IF IT DOES NOT.           18400013
         OI    F1(T),CHNGED            MARK THE ENTRY IN REQLST AS      18440013
*                                    BEING CHANGED BY THIS INSTRUCTION. 18480013
OB170    TM    CODE2(P),NOST           CAN THIS REGISTER BE STORED      18520013
         BC    BZ,OB180                BRANCH IF IT CAN.                18560013
         OI    F1(T),DNST              INDICATE  NEVER TO BE STORED     18600013
         OI    F1(T),BIT7                AND INDICATE SINDEX BIT TO     18610001
*                                        BE TRANSFERRED TO REGTAB       18620001
         SPACE                                                          18640013
OB180    MVI   0(P),FNDREG             MARK LIST TO INDICATE THAT A     18680013
*                                    REGISTER MUST BE FOUND.            18720013
         LR    LR,T                                                     18760013
         LA    RR,REQLST               CALCULATE OFFSET OF NEW ENTRY IN 18800013
         SR    LR,RR                 REQLST FROM START OF REQLST.       18840013
         STH   LR,PHYSRG               STORE THIS OFFSET IN THE ENTRY   18880013
         MVC   REGNAM(2,P),PHYSRG    IN P BEING EXAMINED.               18920013
         CLC   PSTOR2(2),MINUS1        IS PSTOR2 ALL F'S.               18960013
         BC    BE,OB210                BRANCH IF IT IS.                 19000013
         SPACE                                                          19040013
         TM    PARBYT(R2),BIT0         IS THE ENTRY FOUND IN TH         19080013
*        SYMBOLIC REGISTER CHAIN A MEMBER OF A PAIR.                    19120013
         BC    BO,OB220                BRANCH IF IT IS.                 19160013
         SPACE                                                          19200013
OB190    L     LR,REGREQ                                                19240013
         LA    LR,1(LR)                BUMP REQREG BY ONE.              19280013
         ST    LR,REGREQ                                                19320013
OB200    LA    T,RQLLTH(T)             BUMP T BY THE LENGTH OF AN       19360013
*                                    ENTRY IN REQLST.                   19400013
         BC    B,OB030                 BRANCH TO EXAMINE THE NEXT       19440013
*                                    ENTRY IN LIST.                     19480013
         SPACE                                                          19520013
OB210    TM    REG,BIT1                IS THE SYMBOLIC REGISTER NUMBER  19560013
*                                       REG A MEMBER OF A PAIR.         19600013
         BC    BZ,OB190                BRANCH IF IT IS NOT.             19640013
         SPACE                                                          19680013
OB220    L     LR,REGREQ               BUMP  REQREG BY 8 SINCE A        19720013
         LA    LR,8(LR)              PAIR IS REQUIRED.                  19760013
         ST    LR,REGREQ                                                19800013
         OI    F1(T),PAIRMM            SET THE MEMBER OF PAIR BIT ON IN 19840013
*                                    NEW ENTRY IN REQLST.               19880013
         LA    T,RQLLTH(T)             UPDATE THE POINTER TO THE END OF 19920013
*                                    REQLST.                            19960013
         XI    REG,BIT1                CHANGE THE SETTING OF THE        20000013
*        MEMBER OF PAIR BIT IN THE SYMBOLIC REGISTER NAME IN REG.       20040013
         CLC   PSTOR2(2),MINUS1        DOES PSTOR2 CONTAIN ALL F'S.     20080013
         BC    BE,OB230                BRANCH IF IT DOES                20120013
         SPACE 2                                                        20160013
*        WE MUST NOW SEARCH THE SYMBOLIC REGISTER CHAIN FOR THE OTHER   20200013
*        MEMBER OF THE PAIR.                                            20240013
         SPACE                                                          20280013
         LA    R2,SYMCHD+1             SET UP THE ADDRESSES OF THE      20320013
         LA    R3,COMPRG             CHAIN HEAD AND THE COMPARE         20360013
*                                    INSTRUCTION TO BE EXECUTED.        20400013
         BAL   RR,CHAIN                BRANCH TO SCAN CHAIN             20440013
         SPACE                                                          20480013
         BAL   R4,CMPERR               IT IS AN ERROR IF                20520001
*        SYMBOLIC REGISTER CANNOT BE FOUND.                             20560013
         SPACE                                                          20600013
         MVC   PSTOR2(2),PSTOFF(R2)    THE FOUND RETURN. UPDATE PSTOR2  20640013
         SPACE                                                          20680013
OB230    MVI   F1(T),SUWP              MARK THE NEW ENTRY ON REQLST     20720013
*        AS SYMBOLIC, UNCHANGED, WANTED, A MEMBER OF A PAIR             20760013
         MVC   F3+1(2,T),REG           PUT THE SYMBOLIC REGISTER NUMBER 20800013
         MVC   F4(2,T),PSTOR2        AND PRIVATE STORAGE OFFSET IN THE  20840013
         MVI   F5(T),ALLONE            FIELD F5 EQUALS X'FF', IE NOT    20880013
*                                    IN A REGISTER ALREADY.             20920013
*                                    NEW ENTRY IN REQLST.               20960013
         SPACE 1                                                        20965001
         TM    CODE2(P),NOST            IS OTHER MEMBER OF A PAIR A     20970001
         BC    BZ,OB240                   SINDEX - IF SO SET BIT TO     20975001
         OI    F1(T),DNST                 INDICATE THIS MEMBER A        20980001
*                                         SINDEX ALSO                   20985001
OB240    EQU   *                                                        20990001
         TM    CODE2(P),CHNGES         IS THE REGISTER CORRESPONDING TO 21000013
*        THE OTHER MEMBER OF THE PAIR IN LIST ALTERED BY THE            21040013
*        INSTRUCTION BEING CONSIDERED.                                  21080013
         BC    BZ,OB200                BRANCH IF NOT ALTERED.           21120013
         SPACE                                                          21160013
         OI    F1(T),CHNGED            MARK THE ENTRY IN REQLST AS      21200013
         BC    B,OB200               CHANGED THEN BRANCH TO BUMP        21240013
*                                    ADDRESS OF END OF REQLST           21280013
         EJECT                                                          21320013
*              LIST HAS BEEN SCANNED FOR SYMBOLIC REGISTER NAMES AND    21360013
*        MUST NOW BE SCANNED FOR ASSIGNED REGISTERS.                    21400013
*                                                                       21440013
*              FUNCTION/OPERATION. LIST IS SCANNED FOR A SECOND TIME,   21480013
*        THIS TIME FOR ASSIGNED REGISTERS. IF THE REQUEST IS FOR A      21520013
*        REGISTER OUTSIDE THE RANGE 1 THRU 8 IT IS GRANTED WITH NO      21560013
*        FURTHER EXAMINATION. OTHERWISE THE RELEVANT REGISTER TABLE     21600013
*        ENTRY IS EXAMINED. IF THE TABLE ENTRY IS USED BY AN ENTRY      21640013
*        WHICH IS NOT AN ENTRY FOR AN ASSIGNED REGISTER AT THE CURRENT  21680013
*        LEVEL.THE REGISTER IS FREED.     IF THE ENTRY SPECIFIES THAT   21720013
*        IT IS REQUIRED IN THE CURRENT INSTRUCTION, AN ENTRY IS MADE    21760013
*        IN REQLST, INDICATING THAT A 'LOAD REGISTER' SHOULD BE         21800013
*        GENERATED LATER. IF THE REGISTER IS NOT REQUIRED IT IS STORED  21840013
*        IN PRIVATE STORAGE, UNLESS IT IS A BASE, WHEN IT IS MERELY     21880013
*        FREED.                                                         21920013
*                                                                       21960013
*              ENTRY POINT - OB300. THE INPUT PARAMETERS ARE LIST,      22000013
*        REGTAB, AND ALL THE CHAINS RECORDING INFORMATION ABOUT         22040013
*        STORED REGISTERS.    OUTPUT IS THE UPDATED VERSIONS OF THESE   22080013
*        AND POSSIBLY ADDITIONS TO REQLST.                              22120013
*                                                                       22160013
*              EXTERNAL ROUTINES - THE FOLLOWING SUBROUTINES IN IEMRF   22200013
*        ARE CALLED.        1) STORE1 TO GENERATE THE STORE OF AN       22240013
*        ASSIGNED REGISTER                                              22280013
*                           2) STORE2 TO GENERATE THE STORE OF A        22320013
*        SYMBOLIC REGISTER                                              22360013
*                           3) SERCH2 TO SCAN AN ASSIGNED CHAIN         22400013
*                           4) LOAD1 TO GENERATE LOAD OF A REGISTER     22440013
*                           5) FINREG TO CONVERT A NUMBER TO A REGISTER 22480013
*        TABLE ADDRESS.                                                 22520013
*                                                                       22560013
*              EXIT-NORMAL  AFTER OB310 TO OB560 WHEN LIST HAS BEEN     22600013
*        FULLY SCANNED.                                                 22640013
*                                                                       22680013
*              EXIT-ERROR   AFTER OB383 A BAL RR,CERR1 IS EXECUTED IF   22720013
*        AN ASSIGNED REGISTER IS STATED AS HAVING A PREVIOUS VALUE      22760013
*        AND NON CAN BE LOCATED.                                        22800013
*                                                                       22840013
*              TABLES/WORK AREAS.  LIST, REGTAB, AND THE ASSOCIATED     22880013
*        CHAINS IN IEMRF ARE USED. REQLST MAY BE UPDATED.               22920013
*                                                                       22960013
*              NOTES  IF A BASE IS REQIRED FOR THE INSTRUCTION BEING    23000013
*        EXAMINED, AND THE SAME REGISTER NUMBER AS THAT OF AN ASSIGNED  23040013
*        REGISTER ALSO REQUESTED IN THE INSTRUCTION HAS BEEN GIVEN,     23080013
*        NO REALLOCATION IS GIVEN. THIS IS BECAUSE NO CODE IS           23120013
*        GENERATED IN WHICH AN ASSIGNED REGISTER REQUIRING A PREVIOUS   23160013
*        VALUE AND A BASE ARE REQUIRED IN THE SAME INSTRUCTION.         23200013
*                                                                       23240013
         SPACE 4                                                        23280013
OB300    LA    P,LIST                  POINT P AT START OF LIST.        23320013
OB310    C     P,P2                    IS THIS THE END OF LIST          23360013
         BC    BE,OB560                BRANCH IT IS.                    23400013
         SPACE                                                          23440013
         CLI   CODE1(P),EXORAS         IS THIS ENTRY AN ASSIGNED        23480013
*                                    REGISTER.                          23520013
         BC    BE,OB330                BRANCH IF IT IS.                 23560013
         SPACE                                                          23600013
OB320    LA    P,LSTLTH(P)             BUMP P BY THE LENGTH OF AN ENTRY 23640013
*                                    IN LIST.                           23680013
         BC    B,OB310                 BRANCH TO EXAMINE NEXT ENTRY IN  23720013
*                                    LIST                               23760013
         SPACE                                                          23800013
OB330    CLI   REGNAM(P),ALLZRO        THIS IS AN ASSIGNED REGISTER IF  23840013
*                                    THE FIRST BYTE IS ZERO.            23880013
         BC    BE,OB340                BRANCH IF IT IS                  23920013
         SPACE                                                          23960013
         BAL   R4,CMPERR               OTHERWISE THERE IS AN ERROR      24000001
*                                    INTERNAL TO THIS PHASE.            24040013
         SPACE                                                          24080013
OB340    SR    PHRGNO,PHRGNO                                            24120013
         IC    PHRGNO,REGNAM+1(P)      PICK UP THE ASSIGNED REGISTER    24160013
*                                    NUMBER.                            24200013
         CH    PHRGNO,NINE             IS THE ASSIGNED REGISTER NUMBER  24240013
*                                    GREATER THAN OR EQUAL TO NINE      24280013
         BC    BL,OB359                BRANCH IF IT IS NOT.             24320013
OB345    MVI   CODE1(P),INREG          INDICATE THAT THE REGISTER WILL  24360013
*                                    BE ALREADY LOADED                  24400013
OB350    STC   PHRGNO,REGNUM(P)        OTHERWISE STORE THE REGISTER     24440013
*        NUMBER IN THE ENTRY IN LIST.                                   24480013
         BC    B,OB320                 BRANCH TO EXAMINE THE NEXT       24520013
*                                    ENTRY IN LIST.                     24560013
         SPACE                                                          24600013
OB359    LTR   PHRGNO,PHRGNO                                            24640013
         BC    BZ,OB345                                                 24680013
         LR    R2,PHRGNO               BRANCH TO SET UP REGNO TO POINT  24720013
         BAL   RR,FINREG             AT THE REGISTER TABLE.             24760013
         SPACE                                                          24800013
OB360    TM    F1(REGNO),BIT1          BRANCH IF THE REGISTER IS FREE   24840013
         BC    BZ,OB380              OR A BASE.                         24880013
         SPACE                                                          24920013
         TM    F1(REGNO),WANTED        BRANCH IF THIS REGISTER IS       24960013
         BC    BO,OB450              ALREADY WANTED IN THE INSTRUCTION  25000013
         SPACE                                                          25040013
         TM    F1(REGNO),BITS01        IS THE REGISTER SYMBOLIC.        25080013
         BC    BO,OB390                BRANCH IF IT IS.                 25120013
         SPACE                                                          25160013
*        WE MUST NOW HAVE AN ASSIGNED REGISTER.                         25200013
OB370    CLC   ICOUNT(2),F3+1(REGNO)   IS THE CURRENT ICOUNT EQUAL TO   25240013
*        THAT WHICH WAS STORED WHEN THE REGISTER WAS LOADED.            25280013
         BC    BE,OB385                BRANCH IF IT IS.                 25320013
         SPACE                                                          25360013
         BAL   RR,STORE1               OTHERWISE THE CONTENTS MUST BE   25400013
*                                    STORED.                            25440013
*              PATHS FOR ASSIGNED AT THE WRONG LEVEL, BASE, FREE, AND   25480013
*        SYMBOLIC CONVERGE HERE                                         25520013
         SPACE                                                          25560013
OB380    MVI   F1(REGNO),AUWNP         MARK REGISTER IN REGISTER TABLE  25600013
*        AS ASSIGNED, UNCHANGED, WANTED, NOT PAIR MEMBER.               25640013
         MVI   F3(REGNO),0                                              25680013
         MVC   F3+1(2,REGNO),ICOUNT    SET THE ICOUNT FIELD IN THE      25720013
*        REGISTER TABLE TO THE VALUE OF ICOUNT.                         25760013
*                                      IF THE ASSIGNED REGISTER IS ONE  25800013
         TM    CODE2(P),FMAS         OF THE SPECIAL ONES IN FORMAT      25840013
         BC    BZ,OB383              OR DATA LIST CODE, THE FOURTH BIT  25880013
         MVI   F3(REGNO),BIT3        OF F3 IS SET TO ONE, OTHERWISE IT  25920013
*                                    IS ZERO. CODE2 INDICATES WHETHER   25960013
*                                    THE REGISTER IS SPECIAL.           26000013
OB383    MVC   F4(2,REGNO),MINUS1      INITIALISE F4 TO FFFF            26040013
         BAL   RR,SERCH2               SCAN ASSIGNED CHAIN FOR THIS     26080013
         BC    B,OB384                                                  26120013
         SPACE                                                          26160013
         MVC   F3(F3PF4,REGNO),ASS3(R2)  MOVE IN WHOLE OF F3 AND F4     26200001
         BAL   RR,LOAD1                BRANCH TO LOAD ASSIGNED REGISTER 26240013
         OI    F1(REGNO),CHNGED        MARK AS CHANGED                  26280013
         SPACE 1                                                        26288001
         TM    ASS3(R2),BIT1            IF THIS IS A SINDEX REGISTER    26296001
         BC    BZ,OB385                  SET RELEVANT BIT IN F1         26304001
         OI    F1(REGNO),DNST            IN REGTAB ENTRY                26312001
OB385    OI    F1(REGNO),WANTED        MARK WANTED IN THIS INSTRUCTION  26320013
         STC   PHRGNO,REGNUM(P)        STORE THE PHYSICAL REGISTER      26360013
         MVI   CODE1(P),INREG        NUMBER IN THE CORRECT FIELD, AND   26400013
*                                    MARK LIST ENTRY 'ALREADY LOADED'   26440013
         TM    CODE2(P),CHNGES         IS THE REGISTER IN LIST CHANGED  26480013
*        BY THE INSTRUCTION BEING EXAMINED.                             26520013
         BC    BZ,OB320                                                 26560001
         SPACE                                                          26600013
         OI    F1(REGNO),CHNGED        MARK THE ENTRY IN REGISTER       26640013
*                                    TABLE AS CHANGED.                  26680013
         BC    B,OB320                                                  26840013
OB384    LA    RR,OB385                THE REGISTER HAS NOT GOT A VALUE 26880013
         TM    CODE2(P),HASPRI       IN STORAGE.  SHOULD IT HAVE        26920013
         BCR   BZ,RR                   BRANCH IF NOT                    26960013
         L     LR,OBSTOR+12                                             27000013
         CLI   0(LR),MCSR                                               27040013
         BCR   BE,RR                                                    27080013
         CLI   0(LR),MCLM                                               27088015
         BCR   BE,RR                                                    27096015
         CLI   0(LR),MCXR                                               27104015
         BCR   BE,RR                                                    27112015
         BC    B,CERR1                 OTHERWISE ERROR                  27120013
         SPACE 4                                                        27160013
OB390    BAL   RR,STORE2                                                27200013
         TM    F1(REGNO),PAIRMM        IS THE SYMBOLIC REGISTER IN      27240013
*        THE REGISTER TABLE A MEMBER OF A PAIR.                         27280013
         BC    BZ,OB380                BRANCH IF IT IS NOT.             27320013
         SPACE                                                          27360013
         ST    REGNO,REGNST            STORE THE REGISTER REGNO         27400013
         ST    PHRGNO,PHRGN2          THE NUMBER IN PHRGNO.             27440013
         SPACE                                                          27480013
*        WE HAVE TO FIND THE OTHER MEMBER OF THE PAIR                   27520013
*        FIRST FIND WHETHER THE REGISTER NUMBER CORRESPONDING TO THE    27560013
*        ADDRESS IN REGNO IS CDD OR EVEN.                               27600013
         SPACE                                                          27640013
OB400    EX    PHRGNO,TESTUM           IF PHRGNO HAS ITS LAST BIT ONE   27680013
*        THE RESULT OF THE TEST-UNDER-MASK EXICUTED WILL GIVE A ONE'S   27720013
*        CONDITION OTHERWISE THE CONDITION IS ZERO.                     27760013
         BC    BZ,OB410                                                 27800013
         BCTR  PHRGNO,0                PHRGNO CONTAINS AN ODD NUMBER    27840013
         S     REGNO,RGTBLT          THEREFORE IT MUST BE DECREMENTED   27880013
*                                    BY ONE. REGNO IS DECREASED BY ONE  27920013
*                                    TABLE ENTRY LENGTH.                27960013
         BC    B,OB420                                                  28000013
         SPACE                                                          28040013
OB410    LA    PHRGNO,1(PHRGNO)        HERE THE CONTENTS WERE EVEN SO   28080013
         LA    REGNO,RGTLTH(REGNO)   BOTH PHRGNO AND REGNO ARE BUMPED.  28120013
         SPACE                                                          28160013
OB420    BAL   RR,STORE2                                                28200013
         L     REGNO,REGNST            RESTORE REGNO AND PHRGNO WITH    28240013
         L     PHRGNO,PHRGN2         THE VALUES FOR THE FIRST MEMBER    28280013
*                                    OF THE PAIR MET.                   28320013
         BC    B,OB380                                                  28360013
         SPACE 10                                                       28400013
*        HERE THE PHYSICAL REGISTER CORRESPONDING TO AN ASSIGNED        28440013
*        REGISTER HAS BEEN MARKED AS WANTED FOR SOME OTHER PURPOSE      28480013
*        THAN THE ASSIGNED REGISTER.                                    28520013
         SPACE 2                                                        28560013
*              IF THE REGISTER ALREADY WANTED IS AN ASSIGNED REGISTER   28600013
*        THEN THE REQUESTS ARE THE SAME.                                28640013
         SPACE                                                          28680013
OB450    TM    F1(REGNO),BIT0                                           28720013
         BC    BO,OB460                                                 28760013
         TM    F1(REGNO),BIT1                                           28800013
         BC    BO,OB370                                                 28840013
         SPACE                                                          28880013
OB460    TM    F1(REGNO),PAIRMM        IS THE REGISTER OCCUPYING THE    28920013
*                                    PHYSICAL REGISTER A MEMBER OF A    28960013
         BC    BZ,OB480              PAIR. BRANCH IF NOT.               29000013
         SPACE                                                          29040013
         L     LR,REGREQ                                                29080013
         LA    LR,8(LR)                BUMP REQREG BY EIGHT             29120013
         ST    LR,REGREQ                                                29160013
         MVI   PSW,ON                                                   29200013
         ST    REGNO,REGNST            SAVE THE PHYSICAL REGISTER       29240013
         ST    PHRGNO,PHRGN2         NUMBER AND THE CORRESPONDING       29280013
*        ADDRESS IN THE REGISTER TABLE.                                 29320013
*        TEST FOR THE VALUE IN PHRGNO BEING EVEN.                       29360013
         EX    PHRGNO,TESTUM           SEE OB400                        29400013
         BC    BZ,OB470                BRANCH IF IT IS.                 29440013
         SPACE                                                          29480013
         BCTR  PHRGNO,0                DECREMENT THE REGISTER NUMBER    29520013
         S     REGNO,RGTBLT          AND POINTER                        29560013
         BC    B,OB490                                                  29600013
         SPACE                                                          29640013
OB470    LA    PHRGNO,1(PHRGNO)        BUMP THE REGISTER NUMBER AND     29680013
         LA    REGNO,RGTLTH(REGNO)   POINTER.                           29720013
         BC    B,OB490                                                  29760013
         SPACE                                                          29800013
OB480    L     LR,REGREQ                                                29840013
         LA    LR,1(LR)                                                 29880013
         ST    LR,REGREQ                                                29920013
         SPACE                                                          29960013
OB490    MVC   F1(F134,T),F1(REGNO)    COPY FIELDS F1,F3, AND F4 FROM   30000013
*        THE REGISTER TABLE TO THE SPACE FOR A NEW ENTRY IN REQLST.     30040013
         STC   PHRGNO,F5(T)            STORE THE PHYSICAL REGISTER      30080013
*                                    NUMBER IN THE NEW ENTRY.           30120013
         LR    LR,T                                                     30160013
         LA    RR,REQLST               CALCULATE T - REQLST AND STORE   30200013
         SR    LR,RR                 IN OFT.                            30240013
         STH   LR,OFT                                                   30280013
         LA    T,RQLLTH(T)             UPDATE T TO POINT AT NEXT ENTRY  30320013
         SPACE 4                                                        30360013
*        WE HAVE NOW TO SCAN LIST TO FIND THE SYMBOLIC REGISTER         30400013
*        WHICH IS IN THE PHYSICAL REGISTER CORRESPONDING TO THE         30440013
*        ASSIGNED ONE WE HAVE.                                          30480013
         SPACE                                                          30520013
         LA    P16,LIST                SET P16 TO POINT AT THE HEAD     30560013
*                                    OF LIST                            30600013
OB510    C     P16,P2                  IS THIS THE END OF LIST          30640013
         BC    BE,OB530                BRANCH IF IT IS                  30680013
         SPACE                                                          30720013
         CLI   CODE1(P16),INREG        IS THERE A SYMBOLIC REGISTER IN  30760013
*                                    A PHYSICAL REGISTER.               30800013
         BC    BE,OB520                BRANCH IF THERE IS.              30840013
         SPACE                                                          30880013
OB515    LA    P16,LSTLTH(P16)         OTHERWISE BUMP P16 TO NEXT ENTRY 30920013
         BC    B,OB510               AND BRANCH TO EXAMINE IT.          30960013
         SPACE                                                          31000013
OB520    EX    PHRGNO,CLIM             EXECUTE A COMPARE IMMEDIATE TO   31040013
*        TEST WHETHER THE PHYSICAL REGISTER IS THE ONE WE REQUIRE.      31080013
         BC    BNE,OB515               GO TO TEST THE NEXT ENTRY IF IT  31120013
*                                    IS NOT                             31160013
         SPACE                                                          31200013
*        WE HAVE FOUND THE REGISTER WE WANT, NOW WE MUST FREE IT.       31240013
         SPACE                                                          31280013
         MVI   CODE1(P16),FNDREG       INDICATE THAT WE MUST FIND A     31320013
*                                    REGISTER LATER.                    31360013
         MVC   REGNAM(2,P16),OFT       MOVE THE OFFSET OF THE ENTRY     31400013
*        WE HAVE JUST MADE IN REQLIST INTO THE ENTRY IN LIST            31440013
         BC    B,OB515                 BRANCH TO EXAMINE NEXT ENTRY     31480013
*                                    IN LIST.                           31520013
         SPACE                                                          31560013
OB530    CLI   PSW,ON                                                   31600013
         BC    BNE,OB380               BRANCH IF PSW IS NOT ON          31640013
         NI    F1(REGNO),NOTB01        MARK THE REGISTER TABLE ENTRY    31680013
*                                    AS FREE.                           31720013
         L     REGNO,REGNST            REST REGNO AND PHRGNO FOR THE    31760013
         L     PHRGNO,PHRGN2         ORIGINAL MEMBER OF THE PAIR.       31800013
         MVI   PSW,OFF                                                  31840013
         BC    B,OB490                 NOW PRCESS THE OTHER PAIR        31880013
*                                    MEMBER.                            31920013
         SPACE 4                                                        31960013
         EJECT                                                          32000013
*              LIST HAS BEEN SCANNED TWICE, ONCE FOR SYMBOLIC REGISTERS 32040013
*        ONCE FOR ASSIGNED REGISTERS. LISTS OF FREE PHYSICAL REGISTERS  32080013
*        AND AND ASSIGNED REGISTERS IN PHYSICAL REGISTERS ARE           32120013
*        CONSTRUCTED.                                                   32160013
         SPACE                                                          32200013
*              ALTERNATIVELY A BASE IS REQUIRED AND LIST HAS NOT        32240013
*        BEEN FULLY SCANNED.                                            32280013
         SPACE 2                                                        32320013
*              LISTS OF THE CURRENT STATUS OF REGISTERS IS CONSTRUCTED  32360013
*                                                                       32400013
*              FUNCTION/OPERATION - REGISTER TABLE IS SCANNED AND A     32470001
*        STATUS FOR EACH REGISTER IS CALCULATED. A LIST OF FREE         32540001
*        REGISTERS IS BUILT                                             32610001
*              IF WHILE ADDING A REGISTER TO THE LIST OF FREE           32680013
*        REGISTERS IT IS FOUND THAT SUFFICIENT FREE REGISTERS ARE       32720013
*        AVAILABLE ,THE SCAN OF THE REGISTER TABLE IS TERMINATED.       32760013
*                                                                       32800013
*              ENTRY POINT - OB560 TO PERFORM THE ABOVE                 32840013
*                                                                       32880013
*              EXTERNAL ROUTINE  CERR2, CALLED AFTER OB570. THIS IS A   32920013
*        TERMINAL COMPILER ERROR AND IS CALLED IF MORE THAN ONE         32960013
*        REGISTER PAIR IS REQUIRED IN AN INSTRUCTION.                   33000013
*                                                                       33040013
*             EXITS NORMAL  1) AFTER OB560 TO RETURN IF NO REGISTERS    33080013
*        ARE REQUIRED AND A BRANCH IN OR OUT POINT IS NOT BEING         33120013
*        PROCESSED.                                                     33160013
*                           2) AFTER OB600 TO OB630 IF THE SCAN OF      33200013
*        THE REGISTER TABLE IS COMPLETED BEFORE SUFFICIENT FREE         33240013
*        REGISTERS HAVE BEEN FOUND.                                     33280013
*                           3) AFTER OB620 TO OB835 IF THERE ARE        33320013
*        ENOUGH FREE REGISTERS TO SATISFY THE REQUSTS.                  33360013
*                                                                       33400013
*              EXIT ERROR   AFTER OB570 TO CERR1 AS DESCRIBED ABOVE     33440013
*                                                                       33480013
*              TABLES/WORK AREAS: REGTAB IN IEMRF                       33520001
*                                 FREELIST IS GENERATED                 33560001
*                                                                       33600013
*              NOTES  N/A                                               33640013
*                                                                       33680013
         SPACE 4                                                        33720013
OB560    L     LR,REGREQ                                                33760013
         ST    T,REQTOP                STORE THE POINTER TO THE TOP OF  33800013
*                                    REQUEST LIST.                      33840013
         LTR   LR,LR                                                    33880013
         BC    BNZ,OB570               TEST FOR REGREQ BEING ZERO AND   33920013
*                                    BRANCH IF NOT.                     33960013
         CLI   SW0,OFF                 BRANCH TO RETURN IF SW0 IS OFF   34000013
         BC    BE,RETURN                                                34040013
         BC    B,OB675                                                  34080013
         SPACE                                                          34120013
         SPACE                                                          34160013
OB570    CH    LR,FIFTN                COMPARE REGREQ WITH FIFTEEN      34200013
         BC    BLE,OB580               BRANCH IF LESS THAN OR EQUAL     34240013
*                                      OTHERWISE COMPILER ERROR SINCE   34280013
         BC    B,CERR2               MORE THAN ONE PAIR REQUIRED        34320013
         SPACE                                                          34360013
OB580    L     REGNO,REGNO2        SET REGNO TO POINT AT LAST           34400013
         LA    PHRGNO,8              ENTRY IN THE REGISTER TABLE AND    34440013
*                                    THE PHYSICAL REGISTER NUMBER TO    34480013
*                                    EIGHT.                             34520001
         MVI   STLIST,64             BLOCK BDY., AND HAS NOT BEEN PER-  34640013
         MVC   STLIST+1(8),STLIST    FORMED. INITIALISE STATUS LIST     34680013
         SPACE                                                          34840013
OB584    TM    F1(REGNO),BITS01        TEST FOR THE REGISTER BEING      34880013
         LA    P7,STLIST(PHRGNO)                                        34900001
         BC    BZ,OB610              EXAMINED BEING FREE. BRANCH IF IT  34920013
*                                    IS.                                34960013
         TM    F1(REGNO),WANTED      IS REGISTER WANTED IN THIS INSTR   34970001
         BC    BO,OB585                 BRANCH IF SO                    34980001
         SPACE                                                          35000013
         TM    F1(REGNO),DNST        IS THIS REGISTER NOT TO BE STORED  35050001
         BC    BNZ,OB600                BRANCH IF SO                    35100001
         TM    F1(REGNO),BITS01        TEST FOR THE REGISTER BEING      35160013
         BC    BO,OB589              SYMBOLIC BRANCH IF IT IS           35200013
         TM    F1(REGNO),BIT1          TEST FOR THE SECOND BIT BEING    35240013
         BC    BZ,OB586              ONE. WE HAVE AN ASSIGNED REGISTER  35280013
*                                    IF IT IS.                          35320013
         MVI   0(P7),ASGNST            SET STATUS FOR  ASSIGNED         35360001
         BC    B,OB600                                                  35400013
OB585    MVI   0(P7),128               SET STATUS FOR WANTED            35410001
         BC    B,OB600                                                  35420001
         SPACE                                                          35440013
*              A BASE IS GIVEN STATUS N-1 WHERE N IS NO. OF BYTES       35470015
*        REQUIRED TO SET IT IP, UNLESS IT IS AN INTERMEDIATE VALUE IN C 35500015
*         CALCULATING  ANOTHER BASE, WHEN IT IS GIVEN STATUS 20, OR     35530015
*        WHEN IT CAN BE CALCULATED FROM ANOTHER BASE THE IT IX GIVEN A  35560015
*        STATUS OF 2.                                                   35590015
OB586    MVC   0(1,P7),F3+2(REGNO)           ASSUME NEITHER DEPENDENT   35620001
         TM    F1(REGNO),DEPON+DPNDNT        NOR DEPENDED ON            35650001
         BC    BZ,OB600                      BRANCH IF ASSUMPTION       35680001
         MVI   0(P7),2                       ASSUME DEPENDENT           35710001
          TM   F1(REGNO),DEPON                                          35770015
         BC    BZ,OB600                      BRANCH IF ASSUMPTION       35810001
         MVI   0(P7),20                   DEPENDED ON                   35850001
          BC   B,OB600                                                  35890015
         SPACE                                                          36000013
OB589    MVI   0(P7),INST               SET STATUS FOR SYMBOLIC REG     36060001
         TM    F1(REGNO),PAIRMM        * IS THIS A PAIR MEMBER    54713 36066064
         BC    BZ,OB590                * NO, LEAVE STATUS AS SET  54713 36072064
         MVI   0(P7),19                * YES, SET STATUS OF 19    54713 36078064
*        STATUS 19 CHOSEN AS 19 = STATUS OF BASE REQIRING         54713 36084064
*        FIVE 4-BYTE INSTRUCTIONS TO SET UP AND IS                54713 36090064
*        THEREFORE CONSIDERED A FAIR TRADEOFF . IFF               54713 36096064
*        EXPERIENCE SHOWS THIS VALUE INADEQUATE FEEL FREE         54713 36102064
*        TO ADJUST IT TO YOUR PARTICULAR NEEDS                    54713 36108064
OB590    EQU   *                                                  54713 36114064
         SPACE 2                                                        36120013
*        IS THIS THE END OF THE REGISTER TABLE.                         36160013
OB600    S     REGNO,RGTBLT            DECREMENT POINTER TO REGISTER    36200013
         BCT   PHRGNO,OB584          TABLE AND REGISTER NUMBER.         36240013
         BC    B,OB799                 BRANCH ALSO IF THIS IS THE END   36280001
*                                    OF REGISTER TABLE.                 36320013
         SPACE 2                                                        36360013
OB610    MVI   0(P7),0                  SET STATUS FOR FREE REG         36400001
         BC    B,OB600                                                  36440013
         SPACE 5                                                        36440401
*              ROUTINE TO SCAN REQLST FOR SINDEXES WHICH SHOULD BE      36440801
*        ALLOCATED TO A SPECIFIC REGISTER. THESE ALLOCATIONS ARE MADE   36441201
*        UNLESS THE REGISTER CONTAINS AN ASSIGNED REGISTER AT THE       36441601
*        CURRENT ICOUNT LEVEL, OR THE REGISTER HAS PREVIOUSLY BEEN      36442001
*        MARKED AS WANTED IN THIS INSTRUCTION.  IN THESE CASES THE      36442401
*        SINDEXES ARE LEFT TO BE ALLOCATED IN THE NORMAL WAY.           36442801
         SPACE 1                                                        36443201
OB799    LA    P,REQLST                SET UP POINTER TO REQLST         36443601
         SPACE 1                                                        36444001
OB700    C     P,REQTOP                CHECK FOR END OF REQLST -        36444401
         BC    BNL,OB630                 BRANCH OUT IF SO               36444801
         SPACE 1                                                        36445201
         TM    F1(P),DNST              IS THIS A SINDEX -               36445601
         BC    BO,OB705                  BRANCH OUT IF SO               36446001
         SPACE 1                                                        36446401
OB703    LA    P,RQLLTH(P)             BUMP REQLST POINTER + CHECK      36446801
         BC    B,OB700                   NEXT ENTRY                     36447201
         SPACE 1                                                        36447601
OB705    LA    R3,SINTAB+14            SET POINTER TO SINTAB            36448001
         LA    R2,8                      AND R2 TO PHYS REG NO          36448101
         MVI   STLIST+1,127            SET STATUS OF REG 1 SO THAT      36448201
*                                        IT WILL ONLY BE CHOSEN IF      36448301
*                                        ALL OTHER REGS ARE WANTED      36448401
*                                        IN THIS INSTRUCTION. THIS      36448501
*                                        IS ONLY DONE WHEN A SINDEX     36448601
*                                        IS WANTED IN THE INSTR.        36448701
OB710    CLC   0(2,R3),F3+1(P)         IS THIS SINTAB ENTRY FOR THIS    36448801
         BC    BE,OB720                  REG. - BRANCH IF SO            36449201
         SH    R3,TWO                  SCAN TO NEXT SINTAB ENTRY        36449601
         BCT   R2,OB710                                                 36450001
         SPACE 1                                                        36450401
*                                      THERE IS NO SINTAB ENTRY FOR     36450801
         BC    B,OB703                   THIS REG.                      36451201
         SPACE 2                                                        36451601
OB720    LR    PHRGNO,R2               SET REGNO TO POINT TO REGTAB     36452001
         BAL   RR,FINREG                 ENTRY, SAVING PHYS. REG. NO.   36452401
         MVI   PAIR,OFF                SET PAIR INDICATOR OFF           36452801
         TM    F1(P),PAIRMM            IS IT A PAIR MEMBER - IF         36453201
         BC    BZ,OB725                  SO SET PAIR TO PHYS. REGNO     36453601
         STC   PHRGNO,PAIR                                              36454001
OB725    EQU   *                                                        36454401
         SPACE 1                                                        36454801
         TM    F1(REGNO),BIT0          IS REGTAB ENTRY OCCUPIED BY      36455201
         BC    BO,OB730                  AN ASSIGNED REGISTER AT        36455601
         TM    F1(REGNO),BIT1            THE CURRENT ICOUNT - BRANCH    36456001
         BC    BZ,OB730                  OUT IF NOT                     36456401
         CLC   F3+1(2,REGNO),ICOUNT                                     36456801
         BC    BE,OB703                BRANCH IF IT IS                  36457201
OB730    TM    F1(REGNO),WANTED         IS IT WANTED IN THIS INSTR.     36457601
         BC    BO,OB703                   BRANCH IF SO                  36458001
         CLI   PAIR,OFF                IS IT A PAIR MEMBER              36458401
         BC    BE,OB740                  BRANCH IF NOT                  36458801
         SPACE 1                                                        36459201
         X     PHRGNO,ONE              SET PHRGNO TO OTHER PAIR         36459601
         LR    R2,PHRGNO                 MEMBER + FIND REGTAB ENTRY     36460001
         X     PHRGNO,ONE              RESTORE VALUE OF PHRGNO          36460401
         BAL   RR,FINREG                                                36460801
         TM    F1(REGNO),BIT0          IS REGTAB ENTRY FOR PAIR         36461201
         BC    BO,OB740                  OCCUPIED BY AN ASSIGNED        36461601
         TM    F1(REGNO),BIT0            REG. AT CURRENT ICOUNT         36462001
         BC    BZ,OB740                  - CONTINUE IF NOT AND          36462401
         CLC   F3+1(2,REGNO),ICOUNT      BRANCH OUT IF SO               36462801
         BC    BE,OB703                                                 36463201
         SPACE 1                                                        36463601
*                                      AT THIS POINT THE REGISTER       36464001
*                                        FOR THIS SINDEX (AND ITS       36464401
*                                        PAIR IF ANY) IS AVAILABLE      36464801
*                                        FOR USE BY THE SINDEX          36465201
OB740    L     R3,REGREQ               DECREMENT REGREQ FOR THIS        36465601
         BCTR  R3,0                      REGISTER WE HAVE ALLOCATED     36466001
         ST    R3,REGREQ                                                36466401
         SPACE 1                                                        36466801
         BAL   RR,OB631C               BRANCH TO FREE REGISTER AND      36467201
*                                        IF NECESSARY STORE ITS         36467601
*                                        CONTENTS                       36468001
         STC   PHRGNO,F6(P)            STORE PHYS. REG. NO.             36468401
         CLI   PAIR,OFF                IS THIS A PAIR MEMBER            36468801
         BC    BE,OB703                  BRANCH IF NOT                  36469201
*                                      IF IT IS A PAIR, P POINTS        36469601
*                                        TO THE REQLST ENTRY FOR        36470001
*                                        THE ORIGINAL REGISTER          36470401
         X     PHRGNO,ONE               SET PHRGNO TO OTHER PAIR        36470501
*                                         MEMBER                        36470601
         L     R3,REGREQ               DECREMENT REGREQ BY SIX          36470801
         SH    R3,H6                     WITH THE SINGLE DECREMENT      36471201
         ST    R3,REGREQ                 FOR EACH HALF OF THE PAIR      36471601
*                                        THIS MAKES EIGHT NET.          36472001
         LR    R3,P                    SAVE REQLST POINTER              36472401
         LA    P,RQLLTH(P)             BUMP REQLST POINTER              36472801
         XI    F3+1(P),BIT1            CHECK THAT REQLST ENTRY IS       36473201
         CLC   F3+1(2,P),F3+1(R3)        FOR PAIR MEMBER -              36473601
         BC    BE,OB750                  BRANCH IF SO.                  36474001
         BAL   R4,CMPERR                 ELSE ERROR.                    36474401
OB750    XI    F3+1(P),BIT1            RESTORE REQLST ENTRY             36474801
         MVI   PAIR,OFF                SWITCH PAIR FLAG OFF             36475201
         BC    B,OB740                                                  36475601
         SPACE 5                                                        36480013
OB630    MVI   PRSW,OFF                                                 36520013
         LA    Q,FRLIST                SET UP POINTER TO TOP OF FREE-   36560013
         ST    Q,FRTOP               LIST                               36600013
OB950    EQU   *                                                        36610001
         SR    P7,P7                                                    36620001
         LR    P8,P7                                                    36630001
OB630A   CLI   REGREQ+3,8              IS A REGISTER PAIR REQUIRED      36640013
         BC    BL,OB632                BRANCH IF NOT                    36680013
         SPACE                                                          36720013
*              THE REGISTER STATUS LIST WILL BE SCANNED FOR THE PAIR    36760013
*        WITH THE LOWEST TOTAL STATUS VALUE.                            36800013
         SPACE                                                          36840013
         MVI   PRSW,ON                 SET SWITCH TO INDICATE PAIR      36880013
         MVI   BSTPR,X'4F'           BEING LOOKED FOR. INITIALISE BEST  36920013
         LA    PHRGNO,8              STATUS SO FAR TO HIGH VALUE        36960013
         SPACE                                                          37000013
OB631    SH    PHRGNO,TWO              SCAN BACK TO NEXT PAIR.          37040013
         BC    BZ,OB631A               BRANCH IF END OF LIST            37080013
         SPACE                                                          37120013
         IC    P7,STLIST(PHRGNO)       SUM STATUS VALUES OF PAIR        37160013
         IC    P8,STLIST+1(PHRGNO)                                      37200013
         AR    P7,P8                                                    37240013
         BC    BZ,OB631E               BRANCH IF FREE PAIR FOUND - NO   37280013
*                                   NEED TO SCAN FURTHER.               37320013
         CH    P7,BSTPR                TOTAL STATUS BETTER (I.E. LOWER  37360013
         BC    BHE,OB631             THAN PREVIOUS LOWEST  BRANCH IFNOT 37400013
         STC   PHRGNO,BSTRG            SAVE BEST EVEN SO FAR.           37440013
         STH   P7,BSTPR                AND STATUS OF PAIR               37480013
         BC    B,OB631                                                  37520013
         SPACE 3                                                        37560013
*              THE STATUS LIST HAS BEEN COMPLETELY SCANNED. A FREE      37600013
*        PAIR WAS NOT FOUND.  THE BEST PAIR'S EVEN REGISTER IS IN CELL, 37640013
*        BSTRG. ITS STATUS IS IN BSTPR.                                 37680013
         SPACE                                                          37720013
OB631A   IC    PHRGNO,BSTRG                                             37760013
OB631E   STC   PHRGNO,PAIR             ENTRY POINT FOR FREE PAIR FOUND  37880013
         L     LR,REGREQ               REDUCE REQUIRED REGISTER COUNT   37920013
         SH    LR,EIGHT                BY 8                             37960013
         ST    LR,REGREQ                                                38000013
OB631G   LA    RR,OB631H                                                38008001
         SPACE 3                                                        38016001
*        ENTRY POINT OT FREE A SYMBOLIC REGISTER. THIS ROUTINE HAS BEEN 38024001
*        MADE INTO A SUBROUTINE WITH A RETURN ON RR. PHRGNO CONTAINS    38032001
*        THE REGISTER NUMBER TO BE FREED                                38040001
         SPACE 1                                                        38048001
OB631C   EQU   *                                                        38056001
         ST    RR,LASAVE               SAVE RETURN REGISTER             38064001
OB631B   LA    LR,STLIST(PHRGNO)       SET LR TO POINT TO REGISTER'S    38080013
         LR    R2,PHRGNO             STATUS. SET REGNO TO POINT TO      38120013
         BAL   RR,FINREG             REGTAB ENTRY                       38160013
         LA    RR,OB631D                                                38200013
         TM    F1(REGNO),BITS01                                         38240013
         BCR   BZ,RR                   BRANCH IF FREE                   38280013
         BC    BO,STORE2               STORE IF NECESSARY IF SYMBOLIC   38320013
*                                    AND MARK FREE                      38360013
         TM    F1(REGNO),BIT1                                           38400013
         BC    BO,STORE1               STORE ASSIGNED AND MARK FREE     38440013
         NI    F1(REGNO),NOTB01        FREE BASE                        38480001
OB631D   MVI   0(LR),128               MARK REGISTER AS TAKEN           38520013
         L     RR,LASAVE                                                38528001
         BCR   B,RR                                                     38536001
         SPACE 1                                                        38544001
OB631H   EQU   *                                                        38552001
         CLI   PRSW,ON                                                  38560013
         BC    BNE,OB633B                                               38600013
          EX    PHRGNO,TESTUM          TEST BIT 31 OF PHRGNO            38640001
         BC    BNZ,OB631F                                               38680013
         LA    PHRGNO,1(PHRGNO)                                         38720013
         BC    B,OB631B                                                 38760013
OB631F   MVI   PRSW,OFF                                                 38800013
*              A PAIR IS NO LONGER REQUIRED                             38840013
         SPACE                                                          38880013
OB632    CLI   REGREQ+3,0              HAVE WE SUFFICIENT REGISTERS     38920013
         BC    BNE,OB632A              IF NOT, BRANCH TO FIND MORE      38960013
         CLI   SW0,ON                  IS IT A BRANCH.   IF SO,         39000013
         BC    BE,OB675                REGISTERS MUST BE IN STORAGE     39040013
         BC    B,OB835                                                  39080013
         SPACE 5                                                        39120013
OB632A   LA    PHRGNO,8                PREPARE REVERSE SCAN OF STUTUS   39160013
         MVI   BST,X'4F'               INITIALISE BEST STATUS VALUE     39200013
         SPACE                                                          39240013
*                                    LIST                               39280013
OB633    IC    P7,STLIST(PHRGNO)       SCAN STATUS LIST FOR LOWEST      39320013
         LTR   P7,P7                 STATUS VALUE                       39360013
         BC    BE,OB631G                                                39400001
         CH    P7,BST                  IS STATUS LOWER THAN PREVIOUS    39440013
         BC    BHE,OB633A              LOWEST                     54713 39480064
         STH   P7,BST                                                   39520013
         STC   PHRGNO,BSTRG            SAVE REGISTER WITH LOWEST STATUS 39560013
OB633A   BCT   PHRGNO,OB633          SO FAR. RETURN TO EXAMINE NEXT.    39600013
         IC    PHRGNO,BSTRG            OTHERWISE, GO TO FREE MOST       39720013
         BC    B,OB631G                SUITABLE REGISTER                39760001
OB633B   L     LR,REGREQ                                                39800013
         BCTR  LR,0                                                     39840013
         ST    LR,REGREQ                                                39880013
         L     Q,FRTOP                 ADD REGISTER TO FREE-LIST        39920013
         STC   PHRGNO,0(Q)                                              39960013
         LA    Q,1(0,Q)                                                 40000013
         ST    Q,FRTOP                                                  40040013
*              CHECK THAT THIS REGISTER IS NOT HALF AN ACTIVE PAIR      40080013
         SPACE                                                          40120013
         EX    PHRGNO,TUM2             IS THIS REGISTER 1 OR 8          40160013
         BC    BZ,OB632                BRANCH IF SO. (CANNOT BE PAIR    40200013
*                                    MEMBER).                           40240013
         X     PHRGNO,ONE              SET PHRGNO TO OTHER MEMBER OF    40280013
         LR    R2,PHRGNO                                                40300001
         BAL   RR,FINREG             PAIR                               40320013
         LA    RR,OB632                                                 40360013
         TM    F1(REGNO),BITS01+PAIRMM IS IT A SYMBOLIC REGISTER AND    40400013
*                                    A PAIR MEMBER                      40440013
         BCR   BNO,RR                  BRANCH IF NOT                    40480013
         BC    B,STORE2                STORE IT AS WELL                 40540001
TUM2     TM    H6+1,0                EXECUTED ABOVE                     40600013
         SPACE                                                          40640013
*              A BRANCH (BUT NOT A NORMAL BALR) OR A BRANCH-IN POINT IS 40680013
*        BEING PROCESSED.  ALL CURRENT REGISTERS MUST HAVE THEIR VALUE  40720013
*        IN STORAGE.                                                    40760013
         SPACE                                                          40800013
OB675    MVC   SW3(1),SW2              SET SW3 ON IF BRANCH OUT SO THAT 40840013
*                                    STORED REGISTERS ARE NOT FREED.    40880013
         LA    PHRGNO,1                SET START OF LOOP                40920001
         SPACE                                                          40960013
*              SCAN THE REGISTER TABLE STORING REG                      41000013
OB676    LR    R2,PHRGNO                                                41040013
         BAL   RR,FINREG               SET REGNO TO POINT TO            41080013
         LA    RR,OB677                SET RETURN REGISTER              41120013
         CLI   BALRSW,ON               IS ITEM BALR                     41150001
         BC    BNE,OB678B                                         38181 41180042
         TM    F1(REGNO),BIT0                                     38181 41210042
         BC    BO,OB678A                                          38181 41240042
         TM    F1(REGNO),BIT1                                     38181 41270042
         BCR   BO,RR                                              38181 41300042
OB678A   CLI   SW4,ON                  * ARE WE IN EDIT CODE      38181 41330042
         BC    BNE,OB678B              * NO, THEN TEST FOR EITHER COND  41360042
         TM    F1(REGNO),WANTED                                   38181 41390042
         BCR   BO,RR                                              38181 41420042
         B     OB678C                                             38181 41450042
OB678B   TM    F1(REGNO),DNST+WANTED   * SINEX OR WANTED REG      38181 41480042
         BCR   BNZ,RR                                             38181 41510042
OB678C   BAL   RR,STOREQ                                          38181 41540042
OB676A   EQU   *                                                        41640013
         CLI   SW3,ON                  NEED BASES BE FREED              41680013
         BC    BE,OB677                BRANCH IF NOT                    41720001
         NI    F1(REGNO),NOTB01        FREE BASE                        41760013
OB677    LA    PHRGNO,1(PHRGNO)        BUMP TO NEXT REG                 42660001
         CH    PHRGNO,EIGHT              IS IT END OF REGTAB -          43560001
         BC    BLE,OB676                 BRANCH IF NOT                  44460001
         BC    B,OB835                 GO TO ALLOCATE REGISTERS         45360001
         EJECT                                                          46640013
*        HERE WE ALLOCATE TO THE REQUESTS FROM REQLIST REGISTERS FROM   46680013
*        FREE-LIST.                                                     46720013
*                                                                       46760013
*              FUNCTION/OPERATION THIS IS THE FINAL ACTION OF THE       46800013
*        PHASE. REQLST IS SCANNED FOR REQUESTS AND REGISTERS ALLOCATED  46840013
*        FROM FREELIST. IF A PAIR IS REQUESTED THE EVEN MEMBER OF       46880013
*        THIS IS IN THE SLOT PAIR. WHEN REQLST HAS BEEN SCANNED THE     46920013
*        ALLOCATED REGISTER NUMBERS ARE PLACED IN A FIELD IN REQLST.    46960013
*        FINALLY LIST IS SCANNED, AND THE OFFSET OF THE CORRESPONDING   47000013
*        REQLST ENTRY USED TO PICK UP THE ACTUAL REGISTER ALLOCATED.    47040013
*        THIS NUMBER IS PLACED IN THE LIST ENTRY. IF NECESSARY A        47080013
*        LOAD OF THE REGISTER FROM PRIVATE STORAGE, OR FROM ANOTHER     47120013
*        REGISTER IS GENERATED.                                         47160013
*                                                                       47200013
*              ENTRY POINTS -  OB835 TO PERFORM THE ABOVE TASKS FOR     47240013
*        SYMBOLIC AND ASSIGNED REGISTERS. THE WORK FOR BASES STARTS     47280013
*        AT OB860 SINCE REQTOP POINTS AT THE START OF REQLST.           47320013
*                                                                       47360013
*              EXTERNAL ROUTINE - ALL IN IEMRF                          47400013
*                           1) FINREG TO CONVERT A REGISTER NUMBER      47440013
*        TO A REGISTER TABLE ADDRESS.                                   47480013
*                           2) LOADRG TO GENERATE AN RR LOAD REGISTER.  47520013
*                           3) LOAD1 TO GENERATE AN RX LOAD.            47560013
*                              CERR3 IS IN IEMRG. THIS IS CALLED IF     47600013
*        A SYMBOLIC REGISTER SHOULD HAVE A PREVIOUS VALUE BUT NO        47640013
*        RECORD OF THIS CAN BE FOUND.                                   47680013
*                                                                       47720013
*              EXIT-NORMAL  AT RETURN. THIS IS THE END OF THE ROUTINE   47760013
*        ALL REGISTERS USED ARE RESTORED. THE REGISTERS ALLOCATED ARE   47800013
*        IN THE REGISTER NUMBER FIELDS OF LIST.                         47840013
*                                                                       47880013
*              EXITS ERROR - NONE                                       47920013
*                                                                       47960013
*              TABLES/WORK AREAS  REQLST, LIST, REGTAB, AND THE LISTS   48000013
*        OF DETAILS OF STORED REGISTERS ARE USED AND UPDATED.           48040013
*                                                                       48080013
*              NOTES - IF A SYMBOLIC REGISTER SHOULD HAVE A PREVIOUS    48120013
*        VALUE AND NONE CAN BE FOUND, AN ERROR MESSAGE TO THIS          48160013
*        EFFECT IS GENERATED, AND REGISTER  12 INSERTED IN THE PLACE    48200013
*        OF THE TRUE NUMBER ALLOCATED. SUBSEQUENT USES WILL PRODUCE     48240013
*        THE TRUE NUMBER.                                               48280013
*                                                                       48320013
OB835    LA    P,REQLST                SET UP POINTERS TO REQLIST AND   48360013
         LA    Q,FRLIST              FREE-LIST.                         48400013
         SPACE                                                          48440013
OB838    C     P,REQTOP                IS THIS THE END OF REQLIST       48480013
         BC    BE,OB860                BRANCH IF IT IS.                 48520013
         SPACE 1                                                        48524001
         CLI   F6(P),OFF               HAS REGISTER BEEN ALLOCATED      48528001
         BC    BE,OB839                  ABOVE - BRANCH IF NOT          48532001
         IC    PHRGNO,F6(P)            PICK UP REGNO. SET               48536001
         LR    R2,PHRGNO                 REGNO TO POINT TO REGTAB       48540001
         LA    RR,OB847                  ENTRY, AND BRANCH TO           48544001
         BC    B,FINREG                  PROCESS - RETURN TO OB847      48548001
OB839    EQU   *                                                        48552001
         SPACE                                                          48560013
         TM    F1(P),PAIRMM            IS THIS REGISTER A MEMBER OF A   48600013
*                                    PAIR.                              48640013
         BC    BO,OB850                BRANCH IF IT IS.                 48680013
         SPACE                                                          48720013
OB840    CLI   0(Q),ALLZRO             IS THE NEXT REGISTER NUMBER IN   48760013
*                                    FREE-LIST ZERO.                    48800013
         BC    BNE,OB845               BRANCH IF IT IS NOT.             48840013
         SPACE                                                          48880013
         LA    Q,1(Q)                                                   48920013
         BC    B,OB840                                                  48960013
         SPACE                                                          49000013
OB845    SR    PHRGNO,PHRGNO           SET UP THE PHYSICAL REGISTER     49040013
         IC    PHRGNO,0(Q)           NUMBER IN A REGISTER.              49080013
         LR    R2,PHRGNO               BRANCH TO SET UP REGNO FOR THIS  49120013
         BAL   RR,FINREG             NUMBER.                            49160013
         SPACE                                                          49200013
         STC   PHRGNO,F6(P)            STORE THE REGISTER NUMBER IN     49240013
*                                    REQLIST.                           49280013
         LA    Q,1(Q)                  BUMP THE POINTER TO FREE-LIST.   49320013
OB847    MVC   F1(F134,REGNO),F1(P)    MOVE THE REQLIST DESCRIPTION     49360013
*                                    INTO THE REGISTER TABLE.           49400013
         NI    F1(REGNO),NOBIT5        SET SINDEX BIT OFF - THIS WILL   49408001
*                                        BE RE-SET ON LATER IF THIS     49416001
*                                        REGISTER CAN BE TAKEN AS A     49424001
*                                        SINDEX                         49432001
         TM    F1(P),DNST+BIT7         IF DNST AND BIT7 ARE ON THE      49433001
         BC    BNO,OB848                 SINDEX BIT MUST BE SET ON      49434001
         OI    F1(REGNO),DNST            IN REGTAB AS IT WILL NOT       49435001
*                                        BE SET ON LATER IN THESE       49436001
*                                        CIRCUMSTANCES.                 49437001
OB848    EQU   *                                                        49438001
         LA    P,RQLLTH(P)             BUMP THE POINTER TO REQLIST.     49440013
         BC    B,OB838                 BRANCH TO EXAMINE THE NEXT ENTRY 49480013
         SPACE                                                          49520013
OB850    MVC   F6(1,P),PAIR            MOVE THE EVEN MEMBER OF PAIR IN  49560013
         TM    F3+2(P),BIT7            IS THE REGISTER NUMBER IN FIELD  49600013
*                                    F3 EVEN.                           49640013
         BC    BZ,OB853                BRANCH IF IT IS                  49680013
         TM    F3+1(P),BIT1            IS THE 'PAIR' BIT ZERO           49720013
         BC    BZ,OB855                HERE BITS 1 AND 15 ARE DIFFERENT 49760013
         BC    B,OB854                 HERE BITS 1 AND 15 ARE THE SAME  49800013
OB853    TM    F3+1(P),BIT1            IS THE 'PAIR' BIT                49840013
         BC    BO,OB855                HERE BITS 1 AND 15 ARE DIFFERENT 49880013
OB854    OI    F6(P),BIT7              HERE BITS 1 AND 15 ARE THE SAME  49920013
*                                    SO PUT THE ODD BIT ON IN THE       49960013
*                                    REQLIST ENTRY.                     50000013
OB855    IC    R2,F6(P)                CONVERT THE REGISTER JUST CHOSEN 50040013
         BAL   RR,FINREG             TO A POINTER TO THE REGISTER TABLE 50080013
         SPACE                                                          50120013
         BC    B,OB847                 BRANCH TO COMPLETE THE ENTRY IN  50160013
*                                    THE REGISTER TABLE.                50200013
         SPACE                                                          50240013
OB860    LA    P,LIST                  SET UP A POINTER TO LIST.        50280013
         ST    Q,Q2                    SAVE THE POINTER TO NEXT ENTRY   50320013
*                                    IN FREE-LIST.                      50360013
OB862    C     P,P2                    IS THIS THE END OF LIST.         50400013
         BC    BE,OB910                BRANCH IF IT IS.                 50440013
         SPACE                                                          50480013
         CLI   0(P),NULL               IS THIS A NULL ENTRY.            50520013
         BC    BNE,OB865               BRANCH IF NOT                    50560013
         LA    P,LSTLTH(P)             BUMP THE POINTER TO LIST TO      50600013
*                                    TEST THE NEXT ENTRY                50640013
         BC    B,OB862                 BRANCH TO DO THE TEST.           50680013
         SPACE                                                          50720013
OB865    CLI   0(P),BASREQ             IS A BASE REQUIRED               50760013
         BC    BE,OB870                BRANCH IF IT IS                  50800013
         SPACE                                                          50840013
         CLI   0(P),FNDREG             IS A REGISTER REQUIRED           50880013
         BC    BE,OB875                BRANCH IF IT IS                  50920013
         SPACE                                                          50960013
         BC    B,OB907                 OTHERWISE IGNORE THE ENTRY       51000013
         SPACE 2                                                        51040013
OB870    SR    PHRGNO,PHRGNO                                            51048015
         IC    PHRGNO,FRLIST           PICK UP FREE REGISTER            51056015
         LR    R2,PHRGNO                                                51064015
         BAL   RR,FINREG               FIND ITS REGTAB ENTRY            51072015
         SPACE 3                                                        51080015
*              PHRGNO CONTAINS REGISTER NUMBER                          51088015
*              REGNO POINTS TO REGTAB ENTRY                             51096015
*        P POINTS TO LIST ENTRY                                         51104015
*                                                                       51112015
OB871    MVI   CODE1(P),INREG          SET UP BASE IN LIST              51120015
         STC   PHRGNO,REGNUM(P)                                         51128015
         STC   PHRGNO,REGNAM(P)                                         51136015
         STC   PHRGNO,BASE                                              51144015
          MVI  F1(REGNO),BIT0+WANTED     MARK AS BASE AND WANTED        51145015
         TM    ADILST+1,X'10'            MUST THIS BE DROPPED AT        51146015
         BC    BZ,*+8                STATEMENT BOUNDARIES               51147015
         OI    F3(REGNO),X'20'     IF SO,SET BIT IN REGTAB              51148015
         SPACE                                                          51152015
         LH    LR,BNADI                                                 51160015
         LTR   LR,LR                   HAS A PART WAY BASE ALREADY BEEN 51168015
         BC    BL,OB871B             COMPUTED. BRANCH IF NOT            51176015
         CH    LR,MADI                 IS IT COMPLETE                   51184015
         BC    BE,RETURN               RETURN IF SO                     51192015
         SPACE                                                          51200015
          L    RR,BSTRGT                                                51202015
         OI    F1(RR),DEPON            MARK PART-WAY BASE AS DEPENDED   51204015
         OI    F1(REGNO),DPNDNT      ON, AND NEW BASE AS DEPENDENT      51206015
         SR    RR,RR                                                    51208015
         IC    RR,ADILST+1(LR)                                          51216015
         LA    RR,TRTAB(RR)                                             51224015
         CLI   0(RR),X'A4'                                              51232015
         BC    BE,*+12                 BRANCH IF LOAD                   51240015
         CLI   0(RR),XD                DOES FIRST OP NEED PREVIOUS VA   51248015
         BC    BNE,OB871C            LUE. BRANCH IF SO.                 51256015
         SPACE                                                          51264015
         MVC   BASE(1),BSTBAS+1                                         51272015
         STC   PHRGNO,CHBS             SET CHANGE BASE FLAG FOR ADIMOV  51280015
         BC    B,OB871B                                                 51288015
OB871C   LA    T,BSTBAS+1-F5                                            51296015
         SPACE                                                          51304015
         BAL   RR,LOADRG               GENERATE A LOAD REGISTER FROM    51312015
*                                    THE PART-WAY BASE INTO A NEW ONE   51320015
         SPACE 3                                                        51328015
*              THE ADI'S NECESSARY TO SET UP THE BASE ARE NOW PUT OUT.  51336015
*        THEY COME FROM ADILST, STARTING AT ADILST+BNADI+1 (THOSE       51344015
*        BEFORE THIS POINT HAVE ALREADY GONE TO SETTING UP THE BASE     51352015
*        FROM WHICH A LR WAS GENERATED).                                51360015
         SPACE                                                          51368015
OB871B   LA    R1,ADISKT               SET UP R1 FOR ADIMOV             51376015
         LA    T,1(0,LR)               THIS INSTRUCTION IS NECESSARY    51384015
*                                    MERELY TO AVOID ASSEMBLY FLAGS     51392015
*                                    ARISING FOR ODD ADDRESSES INDEXED  51400015
*                                    BY ODD VALUES.                     51408015
         SPACE                                                          51416015
OB872    L     LR,ADILST(T)          POINT TO NEXT ADI                  51424015
         ST    LR,ADISKT+1         MOVE IY INTO SKELETON                51432015
         CLI   ADISKT+1,X'0A'          IS THIS A SPECIAL ADI            51432615
         BC    BNE,OB872A              BRANCH IF NOT                    51433215
         SPACE                                                          51433815
         MVI   ADISKT+1,X'8A'          CHANGE TO ADD                    51434415
         SPACE                                                          51435015
         MVC   CHBS(1),BASE            CURRENT BASE AS FIRST OP.        51435615
         MVC   BASE(1),INTBAS          SKDV BASE AS 2ND OP. BASE        51436215
         CLI   INTBAS,0                DEBUGGING AID                    51436815
         BC    BNE,*+6                                                  51437415
         DC    H'0'                                                     51438015
         MVI   INTBAS,0                                                 51438615
OB872A   EQU   *                                                        51439215
         BAL   RR,ADIMOV               PYT IT OUT                       51440015
         SPACE                                                          51448015
         LA    T,4(0,T)                                                 51456015
         CH    T,MADI                                                   51464015
         BC    BL,OB872                                                 51472015
         CLI   MADI+1,23               IF MORE THAN SIX ADI'S USED,     51474015
         BC    BH,OB873              BRANCH.                            51476015
         MH    PHRGNO,H24                                               51480015
         LA    PHRGNO,BSETAB-24(PHRGNO)  SET POINTER TO BASE TAB ENTRY  51488015
         IC    LR,MADI+1                                                51496015
         STC   LR,F3+2(REGNO)          SET UP ADI LENGTH-1 IN REGTAB    51512015
         EX    LR,SETBS                SET UP BSETAB ENTRY FOR THIS BAE 51520015
         BC    B,RETURN                                                 51528015
SETBS    MVC   0(0,PHRGNO),ADILST      EXECUTED ABOVE                   51536015
         SPACE 3                                                        51537015
OB873    MVI   F3+2(REGNO),0           SET LENGTH-1 OF STTING UP ADI'S  51538015
*                                    TOMZERO - INDICATES NO COMMONING   51539015
         BC    B,RETURN                                                 51540015
         EJECT                                                          51544015
OB875    MVC   TEMP1(2),REGNAM(P)      SET UP T TO POINT AT THE REQLIST 51600013
         LA    T,REQLST              ENTRY CORRESPONDING TO THE LIST    51640013
         AH    T,TEMP1               ENTRY.                             51680013
         SPACE                                                          51720013
         SR    PHRGNO,PHRGNO           PICK THE PHYSICAL REGISTER       51760013
         IC    PHRGNO,F6(T)          NUMBER OUT.                        51800013
         STC   PHRGNO,REGNAM+1(P)      STORE IT IN THE REGISTER NAME    51840013
*                                    FIELD.                             51880013
         LR    R2,PHRGNO               BRANCH TO LOAD UP REGNO FOR      51920013
         BAL   RR,FINREG             THIS PHYSICAL REGISTER.            51960013
         SPACE                                                          52000013
         TM    F1(T),PAIRMM                                             52040013
         BC    BZ,OB890                BRANCH IF REGISTER IS NOT A      52080001
*                                    PAIR MEMBER.                       52120013
         SPACE                                                          52160013
         LA    LR,REQLST               SET A POINTER TO THE START OF    52200013
         MVI   PSW,ON                REQLIST AND PAIR SWITCH ON.        52240013
         SPACE                                                          52280013
*        SCAN REQLIST FOR THE OTHER PAIR MEMBER.                        52320013
         SPACE                                                          52360013
OB880    TM    F1(LR),PAIRMM           IS THIS A PAIR MEMBER            52400013
         BC    BO,OB884                BRANCH IF IT IS                  52440013
         SPACE                                                          52480013
OB882    LA    LR,RQLLTH(LR)           BUMP POINT TO NEXT ENTRY IN      52520013
         BC    B,OB880               REQLIST IF NOT. BRANCH TO EXAMINE  52560013
*                                    THE NEXT ENTRY.                    52600013
         SPACE                                                          52640013
OB884    CR    LR,T                    IS THIS THE MEMBER OF THE PAIR   52680013
*                                    WE HAVE ALREADY.                   52720013
         BC    BE,OB882                BRANCH IF IT IS.                 52760013
         SPACE                                                          52800013
         ST    T,TEMP2                 IF THIS IS THE OTHER MEMBER,     52840013
         LR    T,LR                  STORE THE ADDRESS OF THE REQLIST   52880013
*                                    ENTRY OF THE FIRST, AND SET T TO   52920013
*                                    POINT AT THIS NEW ENTRY.           52960013
*              PROCEDE AS THOUGH THE ITEM WERE NOT A PAIR MEMBER.       53000013
         SPACE 2                                                        53040013
OB888    SR    PHRGNO,PHRGNO           GET THE PHYSICAL REGISTER        53080013
         IC    PHRGNO,F6(T)          NUMBER FROM THE ENTRY IN REQLIST   53120013
         LR    R2,PHRGNO             POINTED AT BY T. BRANCH TO SET UP  53160013
         BAL   RR,FINREG             REGNO FOR THIS NUMBER.             53200013
         SPACE                                                          53240013
OB890    EQU   *                                                        53260001
         TM    F5(T),ALLONE            WAS THE VALUE ALREADY IN ANOTHER 53280013
*                                    REGISTER.                          53320013
         BC    BO,OB895                BRANCH IF IT WAS NOT.            53360013
         SPACE                                                          53400013
         BAL   RR,LOADRG               BRANCH TO GENERATE LOAD REGISTER 53440013
         SPACE                                                          53480013
         MVI   F5(T),ALLZRO            INDICATE THAT THE VALUE IS NOT   53520013
         OI    F1(T),1                 INDICATE LOAD CARRIED OUT        53560013
         BC    B,OB900               NOW IN A REGISTER.                 53600013
         SPACE 2                                                        53640013
*        GENERATE A LOAD OF THE REGGISTER IF NECESSARY                  53650001
         SPACE 1                                                        53660001
OB895    EQU   *                                                        53670001
         TM    CODE2(P),HASPRI         BRANCH IF REG FLAGGED 'NO        53680001
         BC    BZ,OB898                  PREVIOUS VALUE'                53690001
         CLC   F4(2,T),MINUS1          BRANCH TO LOAD REG IF IT HAS     53700001
         BC    BNE,OB897                 A PRIVATE STORAGE OFFSET       53710001
         TM    F1(T),1                 IF LOAD HAS BEEN CREATED         53720001
         BC    BO,OB902                  IGNORE THIS REQUEST            53730001
         SPACE 1                                                        53740001
*        A COMPILER ERROR EXISTS EXCEPT FOR THE SPECIAL CASES           53750001
*        OF LM, SR, XR ITEMS.                                           53760001
         SPACE 1                                                        53770001
         L     RR,OBSTOR+12                                             53780001
         CLI   0(RR),MCLM              IF ITEM LM - BRANCH TO IGNORE    53790001
         BC    BE,OB902                  REQUEST                        53800001
         CLI   0(RR),MCSR              IF ITEM IS SR OR XR WITH SAME    53810001
         BC    BE,OB896                  REGISTER NUMBER IN EACH        53820001
         CLI   0(RR),MCXR                FIELD, REGISTER IS BEING       53830001
         BC    BNE,*+14                  CLEARED AND IT IS NOT AN       53840001
OB896    CLC   1(1,RR),3(RR)             ERROR                          53850001
         BC    BE,OB902                                                 53860001
         BAL   RR,CERR3                ERROR IF ABOVE CONDITIONS        53870001
*                                        NOT SATISFIED                  53880001
         MVI   REGNAM+1(P),12          SET REGNAM TO 12 TO INDICATE     53890001
         BC    B,OB902                   ERROR - BRANCH                 53900001
         SPACE 2                                                        53910001
*        A REGISTER FLAGGED 'NO PREVIOUS VALUE' NEED NOT BE LOADED      53920001
*        EXCEPT IN A NUMBER OF SPECIL CASES, WHICH ARE LOADED IF        53930001
*       A PRIVATE STORAGE OFFSET EXISTS.  THESE ARE -                   53940001
*             USSL AND USNG REGISTERS                                   53950001
*             REGISTER PAIR MEMBER                                      53960001
         SPACE 1                                                        53970001
OB898    EQU   *                                                        53980001
         CLI   PSW,ON                  IS PAIR SWITCH ON - IF SO        53990001
         BC    BE,OB899                  BRANCH TO GENERATE LOAD        54000001
         L     RR,OBSTOR+12                                             54010001
         CLI   0(RR),MCUSSL            IS ITEM USSL -                   54020001
         BC    BE,OB899                  BRANCH IF SO                   54030001
         CLI   0(RR),MCUSNG            IS ITEM USNG -                   54040001
         BC    BE,OB899                  BRANCH IF SO                   54050001
         SPACE 1                                                        54060001
         BC    B,OB902                 BRANCH TO OMIT LOAD              54070001
         SPACE 1                                                        54080001
OB899    CLC   F4(2,T),MINUS1          IS PRIVATE STORAGE ALL F'S       54090001
         BC    BE,OB902                  IF SO BRANCH TO OMIT LOAD      54100001
         SPACE                                                          54400013
OB897    MVC   PSTOR2(2),F4(T)         MOVE THE PRIVATE STORAGE OFFSET  54440013
*                                    TO PSTOR2                          54480013
         BAL   RR,LOAD1                GENERATE LOAD OF SYMBOLIC        54520013
*                                    REGISTER.                          54560013
OB900    MVC   F4(2,T),MINUS1                                           54600013
         SPACE                                                          54640013
         OI    F1(T),1                 INDICATE LOAD CARRIED OUT        54680013
         SPACE                                                          54840013
OB902    CLI   PSW,ON                                                   54880013
         BC    BNE,OB905               BRANCH IF THE SECOND MEMBER OF   54920013
*                                    A PAIR HAS NOT TO BE TREATED.      54960013
         SPACE                                                          55000013
         L     T,TEMP2                 LOAD UP T FOR THE OTHER MEMBER   55040013
         MVI   PSW,OFF               OF THE PAIR. SET THE PAIR SWITCH   55080013
         BC    B,OB888               OFF. BRANCH TO DEAL WITH THIS      55120013
*                                    MEMBER                             55160013
         SPACE                                                          55200013
OB905    MVC   REGNUM(1,P),REGNAM+1(P) PUT THE REGISTER NUMBER          55240013
*                                    ALLOCATED IN THE CORRECT PLACE IN  55280013
*                                    THE ENTRY IN LIST.                 55320013
*                                                                       55360013
OB907    LA    P,LSTLTH(P)             BUMP BY THE SIZE OF AN ENTRY     55400013
*                                    IN LIST.                           55440013
         BC    B,OB862                                                  55480013
         SPACE 4                                                        55520013
OB910    EQU   *                                                        55560013
         SPACE                                                          55600013
RETURN   LM    14,8,OBSTOR             LOAD UP ALL THE REGISTERS USED   55640013
         BCR   B,RR                    RETURN.                          55670001
         EJECT                                                          55700001
*                       THE ROUTINE ABNTST                              55730001
*                                                                       55760001
*              FUNCTION/OPERATION                                       55790001
*              THIS ROUTINE EXAMINES A BALR TO DETERMINE WHETHER        55800001
*        REGISTERS NEED TO BE STORED BEFORE THE BRANCH. REGISTERS       55810001
*        MUST BE STORED IF                                              55820001
*        EITHER 1) THE BALR IS NOT A FUNCTION REFERENCE OR SUBROUTINE   55830001
*                  CALL                                                 55840001
*            OR 2) THE BALR IS TO A ROUTINE WHICH CAN GIVE AN ABNORMAL  55850001
*                  RETURN                                               55860001
*              IF THE BALR IS NOT TO R15 OR IS FOLLOWED BY AN IPRM'     55870001
*        WITH A NON-ZERO OPERAND THEN IT IS NOT A FUNCTION OR           55880001
*        SUBROUTINE REFERENCE.                                          55890001
*              IF THE BALR IS FOLLOWED BY AN EPRM' THE DICTIONARY       55900001
*        ENTRY OF THE SECOND OPERAND OF THE LOAD INTO R15 IS EXAMINED.  55910001
*        IF THE 'ENTRY' BYTE SHOWS THAT THE CALLED PROC IS REDUCIBLE    55920001
*        THEN THE PROC CANNOT GIVE AN ABNORMAL RETURN.                  55930001
         SPACE 1                                                        55940001
*              ENTRY POINT: ABNTST WITH R1 POINTING AT THE BALR IN      55950001
*        INPUT TEXT AND LDREF CONTAINING THE DICTIONARY REFERENCE       55960001
*        FROM THE LAST RX LOAD. THIS IS ASSUMED TO BE A LOAD INTO R15.  55970001
         SPACE 1                                                        55980001
*              EXITS: 1) IF THE BALR IS 'NORMAL' (I.E. ALWAYS PROVIDES  55990001
*        A NORMAL RETURN) THEN CONTROL IS PASSED TO 'RETURN' - THE EXIT 56000001
*        POINT FROM OBREGS TO SKIP ALL REGISTER PROCESSING.             56010001
*                     2) IF THE BALR IS 'ABNORMAL' (I.E. MAY PROVIDE AN 56020001
*        ABNORMAL RETURN) THEN CONTROL IS PASSED TO 'OB10' - THE POINT  56030001
*        OF INVOCATION OF ABNTST.                                       56040001
*                                                                       56300001
*              EXTERNAL ROUTINES 1) ZCHAIN IN IEMAA TO GET NEXT TEXT    56330001
*        BLOCK IF END OF BLOCK MARKER FOUND.                            56360001
*                                2) ZDRFAB TO CONVERT DICTIONARY        56390001
*        REFERENCE TO ABSOLUTE.                                         56420001
*                                                                       56660001
*              TABLES/WORK AREAS -N/A                                   56690001
*                                                                       56720001
*              NOTES - N/A                                              56750001
         SPACE 5                                                        56780001
ABNTST   CLC   3(2,R1),FIFTN                                            56810001
         MVI   BALRSW,ON                                                56840001
         BC    BNE,OB10                                                 56870001
AB1      CLI   5(R1),IPRMP                                              56900001
         BC    BE,AB2                  BRANCH IF FOLLOWED BY IPRM'      56930001
         SPACE                                                          56960001
         CLI   5(R1),EPRMP                                              56990001
         SPACE                                                          57020001
         BC    BE,AB3                  BRANCH IF FOLLOWED BY EPRM58     57050001
         CLI   5(R1),EOB                                                57080001
         BC    BNE,NORM                                                 57110001
*                                    PRECEDING A BEGIN BLOCK).          57140001
         MVI   PAR2+3,NOCHNG           INDICATOR BYTE SAYING LEAVE      57170001
         MVC   PAR1+1(1),SBUFNM      THIS TEXT BLOCK BUSY               57200001
         L     LR,ZCHAIN               CHAIN TO NEXT BLOCK              57230001
         BALR  RR,LR                                                    57260001
         SPACE                                                          57290001
         L     R1,PAR2                                                  57320001
         SH    R1,FIVE                                                  57350001
         BC    B,AB1                                                    57380001
         SPACE                                                          57410001
AB2      CLC   6(2,R1),ZEROS           DOES IPRM' REGISTER FIELD CONT-  57440001
         BC    BNE,OB10              AIN ZERO. UF NOT, ABNORMAL         57470001
         BC    B,NORM                  OTHERWISE NORMAL                 57500001
         SPACE                                                          57530001
AB3      MVC   PAR1+2(2),LDREF         LDREF CONTAINS THE DICTIONARY    57560001
*                                    REFERENCE OF THE SOURCE FIELD IN   57590001
*                                    THE LAST RX LOAD MET BY RH.        57620001
         L     LR,ZDRFAB                                                57650001
         BALR  RR,LR                   BRANCH TO DECODE REFERENCE       57680001
         SPACE                                                          57710001
         L     RR,PAR1                 PICK UP ABSOLUTE ADDRESS.        57740001
         CLI   0(RR),ENTLAB                                             57770001
         BC    BE,OB1330               BRANCH FOR INTERNAL ENTRY LABEL  57800001
         SPACE                                                          57830001
         CLI   0(RR),ENTP4                                              57860001
         BC    BE,OB1320               BRANCH FOR AN EXTERNAL ENTRY     57890001
*                                    LABEL. (ENTRY TYPE 4 )             57920001
         CLI   0(RR),ENTP5                                              57950001
         BC    BE,OB1320               BRANCH FOR A FORMAL PARAMETER    57980001
*                                    ENTRY LABEL (ENTRY TYPE 5 )        58010001
NORM     MVI   REG1,14                                                  58040001
         MVI   REG2,15                                                  58070001
         BC    B,RETURN                                                 58100001
         SPACE                                                          58130001
OB1320   TM    ENTBYT(RR),BIT0          TEST ENTRY BYTE IN ENTRY TYPE   58160001
         BC    B,OB1345                   4 OR 5 FOR IRREDUCIBLE        58190001
         SPACE                                                          58220001
*        INVOCATION OF INTERNAL ENTRY LABEL.                            58250001
OB1330   MVC   PAR1+2(2),E2INEL(RR)                                     58280001
         BALR  RR,LR                   DECODE REFERENCE TO ENTRY TYPE 2 58310001
         SPACE                                                          58340001
         L     RR,PAR1                                                  58370001
         MVC   PAR1+2(2),E3INE2(RR)                                     58400001
         BALR  RR,LR                   AND THEN OF ENTRY TYPE 3.        58430001
         SPACE                                                          58460001
         L     RR,PAR1                                                  58490001
         TM    ENTB3(RR),BIT0           TEST ENTRY BYTE IN ENTRY TYPE   58510001
*                                         3 FOR IRREDUCIBLE             58530001
OB1345   BC    BO,OB10                  BRANCH IF IRREDUCIBLE - I.E.    58550001
*                                         ABNORMAL RETURN POSSIBLE      58570001
         BC    B,NORM                   BRANCH IF ONLY NORMAL RETURN    58590001
*                                         POSSIBLE                      58610001
         SPACE 10                                                       58640001
*              ERROR ROUTINES.                                          58670001
         SPACE                                                          58700001
CERR1    LA    PHRGNO,13                                                58730001
         MVC   PAR6+1(3),MS2708                                         58760001
         BC    B,CALL                                                   58790001
CERR3    MVC   PAR6+1(3),MS2709                                         58820001
         BC    B,CALL                                                   58850001
CERR2    MVC   PAR6+1(3),MS270A                                         58880001
         LA    RR,ABRET                                                 58910001
         SPACE                                                          58940001
CALL     L     LR,ZUERR                                                 58970001
         BCR   B,LR                                                     59000001
         SPACE                                                          59030001
ABRET    L     LR,ZABORT                                                59060001
         BALR  RR,LR                                                    59090001
         EJECT                                                          59120001
*                      LOOK AHEAD ROUTINE                               59150001
         SPACE 3                                                        59180001
*           THIS ROUTINE IS CALLED FROM RH WHEN A BC TO AN EQU VALUE    59210001
*        IS MET, AND THE OPTIMISATION LEVEL IS 2 OR GREATER             59240001
*              THE ROUTINE SCANS AHEAD FROM THE BC, LOOKING FOR THE     59270001
*        RELEVANT EQU ITEM. IF                                          59300001
*               A) THE EQU IS FOUND BEFORE ANY OTHER BRANCH IN OR       59330001
*                  OUT POINTS,                                          59360001
*           AND B) THE CONTENTS OF REGTAB IS NOT CHANGED BETWEEN THE    59390001
*                  BC AND THE EQU,                                      59420001
*           AND C) THE EQU HAS BEEN MARKED OPTIMISABLE BY PHASE RD      59460001
*                     THEN THE SAVING AND RESTORING OF REGISTERS        59510001
*        BETWEEN THE TWO ITEMS IS UNNECESSARY.                          59540001
*              IF ANY OF THE ABOVE CONDITIONS IS NOT SATISFIED THE      59570001
*        LOADS AND STORES CANNOT BE OMITTED.                            59600001
*              A MAXIMUM OF FIVE PSEUDO-CODE INSTRUCTIONS ARE SCANNED,  59630001
*        AND IF THE EQU IS NOT FOUND WITHIN THIS LIMIT THE LOADS AND    59660001
*        STORES ARE NOT OMITTED. THIS REDUCES THE TIME SPENT SCANNING   59690001
*        FOR NON-OPTIMISABLE EQUS, WHILE STILL CATCHING THE MAJORITY    59720001
*        OF OPTIMISABLE CASES.                                          59750001
*              IF THE BRANCH IS OF THE FORM   BC B,CL.N   THEN THE      59752001
*        TEXT IS TESTED FOR THE SEQUENCE:                               59754001
*                             BC   B,CL.N    (UNCONDITIONAL BRANCH)     59756001
*                      CL.M   EQU  *         (LABEL)                    59758001
*                             FMT            (FORMAT HEADER)            59760001
*        WHICH OCCURS AT THE START OF INLINE FORMAT CODE.  IF THIS      59762001
*        SEQUENCE DOES OCCUR, THE BRANCH POINT IS FLAGGED AS            59764001
*        OPTIMISABLE.  THE EQU IS ALSO FLAGGED AS OPTIMISABLE TO        59766001
*        AVOID GENERATING CODE IN THE DEAD SPACE BETWEEN THE            59768001
*        UNCONDITIONAL BRANCH AND THE EQU.                              59770001
         SPACE 1                                                        59772001
*        THE RETURN ADDRESS IS GIVEN IN R14                             59900001
         SPACE 1                                                        59930001
*        LAOPT SWITCH IS SET ON IF OPTIMISATION IS TO BE DONE, AND      59960001
*        OFF IF NOT.                                                    59990001
         SPACE 1                                                        59996001
*        THE ENTRY POINT IS:                                            60002001
         SPACE 1                                                        60008001
LOOKAH   EQU   *                                                        60014001
         SPACE 2                                                        60020001
         STM   RR,R4,LASAVE            SAVE REGISTERS USED              60050001
         MVC   LAEVAL(2),3(R1)         SAVE EQU NUMBER                  60080001
         SPACE 2                                                        60110001
*        REGTAB IS CHECKED FOR A FREE REGISTER TO BASE LABEL OF BC      60140001
*        ITEM. IF A FREE REGISTER DOES NOT EXIST A BASE REGISTER        60170001
*        IS FREED. IF A BASE REGISTER DOES NOT EXIST REGISTER 1 IS      60200001
*        FREED.                                                         60230001
         SPACE 1                                                        60260001
         SR    R4,R4                   ZERO IN R4                       60290001
         LA    R0,8                    PREPARE A REVERSE SCAN           60320001
LAPR1    LR    R2,R0                     OF REGTAB                      60350001
         BAL   RR,FINREG                                                60380001
         TM    F1(REGNO),BITS01        TEST REGTAB ENTRY                60410001
         BC    BZ,LAPR10                 BRANCH IF FREE                 60440001
         BC    BO,LAPR3                  BRANCH IF SYMBOLIC             60470001
         TM    F1(REGNO),BIT1                                           60500001
         BC    BO,LAPR3                  BRANCH IF ASSIGNED             60530001
         LR    R4,R0                   SAVE BASE PHYS. REG NO           60560001
LAPR3    BCT   R0,LAPR1                CONTINUE SCAN                    60590001
         SPACE 1                                                        60620001
*        NO FREE REGISTER                                               60650001
         SPACE 1                                                        60680001
         LTR   R4,R4                   TEST FOR A BASE REGISTER         60710001
         BC    BZ,LAPR4                  BRANCH IF NO BASE              60740001
         LR    R2,R4                                                    60770001
         BAL   RR,FINREG                                                60800001
         NI    F1(REGNO),NOTB01        FREE BASE                        60830001
         BC    B,LAPR10                                                 60860001
         SPACE 1                                                        60890001
*        NO FREE REGISTER OR BASE REGISTER - FREE REGISTER 1            60920001
         SPACE 1                                                        60950001
LAPR4    LA    PHRGNO,1                                                 60980001
         LA    REGNO,REGTAB                                             61010001
         BAL   RR,STOREQ               STORE CONTENTS OF REG 1 AND      61040001
*                                        FREE REGISTER                  61070001
LAPR10   EQU   *                       A FREE REGISTER EXISTS OR HAS    61100001
*                                        BEEN CREATED.                  61130001
         SPACE 2                                                        61160001
         LA    R3,5                    SET COUNT OF NUMBER OF ITEMS     61190001
*                                        SCANNED TO 5.                  61220001
         MVI   LAOPT,OFF               SET OPTIMISATION SWITCH OFF      61250001
         MVI   LANBLK,ON                SET NEW BLOCK SWITCH TO X'FF'   61280001
*                                         INITIALLY.                    61310001
         CLI   2(R1),B                 IS BRANCH UNCONDITIONAL          61320001
         BC    BNE,LAPR20                BRANCH IF NOT                  61330001
         OI    LAOPT,BIT0                IF SO SET BIT0 OF LAOPT ON     61340001
LAPR20   LA    R1,5(R1)                BUMP R1 AS LOOKAHEAD POINTER     61350001
         SPACE 1                                                        61360001
*              TEST NEXT ITEM AND BRANCH TO APPROPRIATE ROUTINE         61400001
         SPACE 1                                                        61430001
LATEST   SR    R2,R2                                                    61460001
         TRT   0(1,R1),TRTAB                                            61490001
         BC    B,*(R2)                                                  61520001
         SPACE 1                                                        61550001
*              THIS TRANSFER VECTOR SHARES THE TRANSLATE TABLE USED     61580001
*        BY THE MAIN SCAN ROUTINE IN RH, AND SO MUST HAVE THE SAME      61610001
*        NUMBER OF ENTRIES. IF THE TRANSLATE TABLE IS ALTERED BOTH      61640001
*        VECTORS MAY NEED ALTERATION.                                   61670001
         SPACE 1                                                        61700001
*                          HEX     ITEMS                                61730001
*                         OFFSET                                        61760001
         SPACE 1                                                        61790001
         BC    B,LA5BYT     04     RR ITEMS (<70), SPM (51),            61820001
*                                  RX ITEMS (>6F)                       61850001
         BC    B,LA5BYT     08     RR + RX COMPARES AND STORES, EX (A6) 61880001
         BC    B,LA5BYT     0C     RR LOADS (<70), LH (90), LA (A0),    61910001
*                                  LA' (B7)                             61940001
         BC    B,LASKP5     10     SI ITEMS                             61970001
         BC    B,LAOUT      14     BC                                   62000001
         BC    B,LAOUT      18     BCR                                  62030001
         BC    B,LAOUT      1C     BCT                                  62060001
         BC    B,LABCTR     20     BCTR                                 62090001
         BC    B,LAOUT      24     BAL                                  62120001
         BC    B,LASKP5     28     RR + RX FLOAT PT. ITEMS              62150001
         BC    B,LA5BYT     2C     REG. SHIFTS                          62180001
         BC    B,LA5BYT     30     STM                                  62210001
         BC    B,LASS       34     SS ITEMS                             62240001
         BC    B,LA3BYT     38     OSM1                                 62270001
         BC    B,LASKP3     3C     PASS                                 62300001
         BC    B,LA5BYT     40     OSM3                                 62330001
         BC    B,LASKP3     44     3-BYTE ITEMS TO BE SKIPPED           62360001
         BC    B,LAEOB      48     EOB                                  62390001
         BC    B,LASKP3     4C     DROP                                 62420001
         BC    B,LAOUT      50     PROC, BGN                            62450001
         BC    B,LAOUT      54     PRC', BGN'                           62480001
         BC    B,LAOUT      58     EPRM                                 62510001
         BC    B,LAOUT      5C     IPRM                                 62540001
         BC    B,LAOUT      60     EPRM'                                62570001
         BC    B,LAOUT      64     IPRM'                                62600001
         BC    B,LAFMT     68     FMT                                   62630001
         BC    B,LAOUT      6C     FMT'                                 62660001
         BC    B,LASKP3     70     PLBS                                 62690001
         BC    B,LAOUT      74     EOP                                  62720001
         BC    B,LASKP5     78     5-BYTE ITEMS TO BE SKIPPED           62750001
         BC    B,LAOUT      7C     ILLEGAL ITEM                         62780001
         BC    B,LAEQU      80     EQU, SL1, CL1                        62810001
         BC    B,LAOUT      84     ADI                                  62840001
         BC    B,LASKP3     88     BGNP                                 62870001
         BC    B,LASKP3     8C     BGNP'                                62900001
         BC    B,LAOUT      90     ABS, RWA                             62930001
         BC    B,LASKP3     94     PCBS                                 62960001
         BC    B,LASKP3     98     PLBS'                                62990001
         BC    B,LAOUT      9C     BCT'                                 63020001
         BC    B,LAOUT      A0     BALR                                 63050001
         BC    B,LA5BYT     A4     RX LOADS (LM,IC,CVB)                 63080001
         BC    B,LAOUT      A8     USNG                                 63110001
         BC    B,LAOUT      AC     USSL                                 63140001
         BC    B,LASKPV     B0     DRPL, SINL                           63170001
         BC    B,LAOUT      B4     BCTA', BCTA                          63200001
         BC    B,LAOUT      B8     EDIT                                 63230001
         BC    B,LAOUT      BC     EDIT'                                63260001
         BC    B,LASKP3     C0     DROB'                                63290001
         BC    B,LASKP5     C4     SN                                   63320001
         BC    B,LASKP5     C8     BSW                                  63350001
         BC    B,LASKV5     CC     IGN2                                 63380001
         BC    B,LASKP2     D0     IGN8                                 63410001
         BC    B,LAOUT      D4     BXLE, BXH                            63440001
         EJECT                                                          63470001
*              END OF BLOCK ROUTINE                                     63500001
LAEOB    EQU   *                                                        63530001
         MVI   PAR2+3,OFF               SET STATUS OF OLD BLOCK NOT     63560001
*                                         TO BE CHANGED (I.E. REMAIN    63590001
*                                         BUSY)                         63620001
         MVC   PAR1+1(1),SBUFNM         SET NAME OF OLD BLOCK           63650001
         L     LR,ZCHAIN                BRANCH TO GET NEXT BUFFER       63680001
         BALR  RR,LR                                                    63710001
         SPACE 1                                                        63740001
         L     R1,PAR2                  LOAD LOOK AHEAD POINTER WITH    63770001
*                                         ADDRESS OF NEW BLOCK          63800001
         MVC   LANBLK(1),PAR1+1         SAVE NAME OF NEW BLOCK SO THAT  63830001
*                                         IT CAN BE RELEASED AT END OF  63860001
*                                         LOOK AHEAD.                   63890001
         BC    B,LATEST                 BRANCH TO TEST NEXT ITEM        63920001
         SPACE 5                                                        63924001
*        FMT ROUTINE                                                    63928001
LAFMT    EQU   *                                                        63932001
         TM    LAOPT,BIT0              DOES FMT FOLLOW UNCONDITIONAL    63936001
         BC    BO,LAEQU2                 BRANCH, IF SO BRANCH           63940001
         BC    B,LAOUT                   IF NOT BRANCH OUT              63944001
         SPACE 6                                                        63950001
*              EQU ROUTINE                                              63980001
LAEQU    EQU   *                                                        64010001
         TM    LAOPT,BIT1              IS THIS THE SECOND EQU           64020001
         BC    BO,LAOUT                  BRANCH OUT IF SO               64030001
         CLI   0(R1),MCEQU              CHECK THAT THIS ITEM IS AN EQU  64040001
         BC    BNE,LAOUT                  - IF NOT IT IS A LABEL        64070001
         SPACE 1                                                        64100001
         TM    1(R1),BIT0               TEST IF THIS EQU OPTIMISABLE    64130001
         BC    BZ,LAEQU1                 - BRANCH IF NOT                64160001
         SPACE 1                                                        64190001
         NI    1(R1),NOBIT0             SET BIT0 OFF                    64220001
         CLC   1(2,R1),LAEVAL           IS THIS THE CORRECT EQU         64250001
         BC    BNE,LAEQU1                - BRANCH OUT IF NOT            64280001
         SPACE 1                                                        64310001
         OI    1(R1),BIT1               SET BIT1 ON TO INDICATE LOADS   64340001
*                                         AND STORES ARE TO BE OMITTED  64370001
*                                         WHEN THE EQU IS REACHED IN    64400001
*                                         THE MAIN SCAN.                64430001
LAEQU2   MVI   LAOPT,ON                SET SWITCH ON TO INDICATE        64460001
*                                         OPTIMISATION TO BE DONE       64490001
         BC    B,LAOUT                  BRANCH OUT OF LOOK AHEAD        64520001
         SPACE 3                                                        64522001
LAEQU1   EQU   *                                                        64524001
         TM    LAOPT,BIT0              DOES EQU FOLLOW UNCONDITIONAL    64526001
         BC    BZ,LAEQU3                 BRANCH - BRANCH IF NOT         64528001
         OI    1(R1),BIT1              SET OPTIMISATION BIT ON EQU      64530001
         LA    R0,8                    PREPARE A REVERSE SCAN      H379 64530219
LAEQU5   LR    R2,R0                     OF REGTAB                 H379 64530419
         BAL   RR,FINREG                                           H379 64530619
         TM    F1(REGNO),BIT1          IS IT FREE OR BASE          H379 64530819
         BO    LAEQU4                  BRANCH IF NOT               H379 64531019
         NI    F1(REGNO),NOTB01        FREE THE REGISTER           H379 64531219
LAEQU4   BCT   R0,LAEQU5               CONTINUE SCAN               H379 64531419
LAEQU3   SR    R3,R3                   SET R3 TO ZERO SO ONLY ONE       64532001
*                                        MORE ITEM IS TESTED            64534001
         OI    LAOPT,BIT1              SET BIT1 OF LAOPT TO SHOW        64536001
*                                        AN EQU HAS BEEN MET            64538001
         BC    B,LASKP3                BRANCH TO PROCESS LAST ITEM      64540001
         SPACE 6                                                        64550001
*              ROUTINES TO SKIP OVER ITEMS                              64580001
         SPACE 1                                                        64610001
LASKP3   LA    R1,3(R1)                 BUMP LOOK AHEAD POINTER         64640001
         BC    B,LATEST                 TEST NEXT ITEM                  64670001
         SPACE 3                                                        64700001
LASKP5   LA    R1,5(R1)                 BUMP LOOK AHEAD POINTER         64730001
         BC    B,LATEST                 TEST NEXT ITEM                  64760001
         SPACE 3                                                        64790001
LASKPV   SR    R2,R2                    PICK UP LENGTH OF VARIABLE      64820001
         IC    R2,2(R1)                   LENGTH ITEM                   64850001
         AR    R1,R2                    BUMP LOOK AHEAD POINTER         64880001
         BC    B,LANEXT                 TEST NEXT ITEM                  64910001
         SPACE 3                                                        64940001
LASKP2   LA    R1,2(R1)                 BUMP LOOK AHEAD POINTER         64970001
         BC    B,LATEST                 TEST NEXT ITEM                  65000001
         SPACE 3                                                        65030001
LASKV5   SR    R2,R2                    THIS CODE FOR BUMPING OVER A    65060001
         IC    R2,1(R1)                   PTRSR ITEM IS COPIED FROM     65090001
         LA    R1,5(R2,R1)                EXISTING V4 CODE IN RF.       65120001
         BC    B,LATEST                                                 65150001
         EJECT                                                          65180001
*              ROUTINES TO CHECK REGISTER USAGE                         65210001
*        EACH REGISTER USED IS PLACED IN SYMREG, AND ROUTINE LACHCK     65240001
*        IS CALLED. THIS ROUTINE ONLY RETURNS IF THE REGISTER USE       65270001
*        IS IN REGTAB. IF IT IS NOT IN REGTAB, ROUTINE BRANCHES TO      65300001
*        LAOUT                                                          65330001
         SPACE 1                                                        65360001
*              3-BYTE ITEMS                                             65390001
         SPACE 1                                                        65420001
LA3BYT   MVC   SYMREG(2),1(R1)          PUT 1ST OP INTO LARGNO          65450001
         NI    SYMREG,NOBIT0            ENSURE BIT0 IS OFF              65480001
         BAL   RR,LACHCK                CHECK REG USAGE                 65510001
         LA    R1,3(R1)                 IF OK BUMP LOOK AHEAD POINTER   65540001
         BC    B,LANEXT                   AND BRANCH TO NEXT ITEM       65570001
         SPACE 3                                                        65600001
*              5-BYTE ITEMS                                             65630001
         SPACE 1                                                        65660001
LA5BYT   CLI   0(R1),MCSPM              IF SPM ITEM OR RX, RS ITEM      65690001
         BC    BE,LAFOP                   THEN BRANCH OUT TO CHECK      65720001
         CLI   0(R1),MCLM                 1ST OPND AND OPTIONALLY       65750001
         BC    BHE,LAFOP                  2ND OPND                      65780001
*                                       CHECK BOTH OPERANDS             65810001
LABOP    MVC   SYMREG(2),1(R1)                                          65840001
         NI    SYMREG,NOBIT0                                            65870001
         BAL   RR,LACHCK                                                65900001
         MVC   SYMREG(2),3(R1)                                          65930001
         NI    SYMREG,NOBIT0                                            65960001
         BAL   RR,LACHCK                                                65990001
         LA    R1,5(R1)                                                 66020001
         BC    B,LANEXT                                                 66050001
         SPACE 1                                                        66080001
LAFOP    TM    1(R1),BIT0               IF BIT0 IS ON THE SECOND        66110001
         BC    BO,LABOP                   OPERAND ALSO CONTAINS A       66140001
*                                         REGISTER USAGE                66170001
         MVC   SYMREG(2),1(R1)                                          66200001
         BAL   RR,LACHCK                                                66230001
LAMOP    LA    R1,5(R1)                 BUMP INPUT POINTER              66260001
         BC    B,LANEXT                                                 66290001
         SPACE 3                                                        66320001
         SPACE 3                                                        66350001
*              SS ITEMS                                                 66380001
         SPACE 1                                                        66410001
LASS     TM    1(R1),BIT1              CHECK IF F2 IS A SYMBOLIC        66440001
         BC    BZ,LASS1                  REGISTER - BRANCH IF NOT       66470001
         MVC   SYMREG(2),4(R1)                                          66500001
         BAL   RR,LACHCK                                                66530001
LASS1    TM    1(R1),BIT2              CHECK IF F3 IS A SYMBOLIC        66560001
         BC    BZ,LASKPV                 REGISTER - BRANCH IF NOT       66590001
         MVC   SYMREG(2),6(R1)                                          66620001
         BAL   RR,LACHCK                                                66650001
         BC    B,LASKPV                                                 66680001
         SPACE 5                                                        66683001
*        BCTR ITEM                                                      66686001
         SPACE 1                                                        66689001
LABCTR   EQU   *                                                        66692001
         CLC   3(2,R1),ZEROS           IF 2ND OP OF BCTR ZERO - THEN    66695001
         BC    BE,LA5BYT                 IT IS NOT A BRANCH POINT.      66698001
*                                        BRANCH TO 5 BYTE ROUTINE.      66701001
         BC    B,LAOUT                 IF BCTR IS A BRANCH POINT        66704001
*                                        OPTIMISATION IS NOT POSS.      66707001
         EJECT                                                          66710001
LACHCK   LR    R4,RR                    SAVE RETURN REGISTER            66740001
         LR    LR,R1                    SAVE R1                         66770001
         CLI   SYMREG,OFF               TEST IF REGISTER IS ASSIGNED    66800001
         BC    BE,LACASS                  - BRANCH OUT IF SO            66830001
         SPACE 1                                                        66860001
         BAL   RR,RTABSH                BRANCH TO FIND A REGTAB ENTRY   66890001
*                                         FOR THIS SYMBOLIC.            66920001
         BC    B,LAOUT                  RETURN POINT IF NOT FOUND -     66950001
*                                         NO OPTIMISATION POSSIBLE      66980001
         BC    B,LACOUT                 RETURN POINT IF ENTRY FOUND -   67010001
*                                         EXIT FROM THIS ROUTINE        67040001
         SPACE 3                                                        67070001
LACASS   CLI   SYMREG+1,OFF            IF ASS. REG. NOT BETWEEN         67100001
         BC    BE,LACOUT                 1 AND 8, THEN IGNORE           67130001
         CLI   SYMREG+1,BIT4             THIS USE                       67160001
         BC    BH,LACOUT                                                67190001
         SR    R2,R2                    PICK UP ASSIGNED REGISTER       67220001
         IC    R2,SYMREG+1                NUMBER.                       67250001
         BAL   RR,FINREG                                                67280001
         TM    F1(REGNO),BITS01                                         67310001
         BC    BNM,LAOUT                IF ENTRY IS NOT ASSIGNED        67340001
         TM    F1(REGNO),BIT0             BRANCH OUT TO FAIL            67370001
         BC    BNZ,LAOUT                                                67400001
         BC    B,LACOUT                 OTHERWISE RETURN                67430001
         SPACE 1                                                        67460001
         SPACE 2                                                        67490001
LACOUT   LR    R1,LR                    RESTORE R1                      67520001
         BCR   B,R4                                                     67550001
         EJECT                                                          67580001
LANEXT   BCT   R3,LATEST                BRANCH TO TEST NEXT ITEM IF     67610001
*                                         LESS THAN FIVE HAVE BEEN      67640001
*                                         SCANNED                       67670001
         SPACE 8                                                        67700001
*              RETURN FROM LOOK AHEAD                                   67730001
LAOUT    CLI   LANBLK,ON                HAS END OF BLOCK BEEN MET       67760001
         BC    BE,LAO1                    - BRANCH IF NOT               67790001
         MVC   PAR1+1(1),LANBLK         RELEASE NEW BLOCK - SET TO      67820001
         MVI   PAR2+3,LAWNTD              WANTED                        67850001
         L     LR,ZALTER                                                67880001
         BALR  RR,LR                                                    67910001
LAO1     LM    RR,R4,LASAVE             RESTORE REGISTERS               67940001
         BCR   B,RR                     RETURN                          67970001
         EJECT                                                          68000001
*                       CHARACTER STRING CONSTANTS AND WORK AREAS       68030001
         SPACE                                                          69600013
*        REQLST HAS THE SAME FORMAT AS REGLST FOR THE FIRST EIGHT BYTES 69640013
*        THERE ARE TWO EXTRA FIELDS, F5 AND F6, EACH ONE BYTE LONG AND  69680013
*        ON THE END OF EACH ENTRY                                       69720013
REQLST   DC    5C'ABCDEFGHIJK'         SPACE FOR FIVE ENTRIES IN REQLST 69760013
RQLLTH   EQU   11                      LENGTH OF A REQLST ENTRY         69800013
F5       EQU   9                                                        69840013
F6       EQU   10                                                       69880013
PSW      DC    C'X'                                                     69920013
BSW      DC    C'Y'                                                     69960013
SW5      DC    C'B'                                                     70040013
CURBUF   DC    C'1'                    STORAGE FOR NAME OF CURRENT      70120013
*                                    BUFFER DURING LOOK AHEAD.          70160013
MS2708   DC    X'0A9444'                                                70200013
MS2709   DC    X'0A9544'                                                70240013
MS270A   DC    X'0A9640'                                                70280013
         EJECT                                                          70320013
*                       HALF-WORD SAVE AREAS AND CONSTANTS              70360013
         SPACE                                                          70400013
PHYSRG   DC    H'0'                    USED TO STORE THE PHYSICAL       70440013
*        REGISTER NUMBER WHEN SCANNING THE REGISTER TABLE.              70480013
NINE     DC    H'9'                                                     70520013
OFT      DC    H'-1'                                                    70560013
FIFTN    DC    H'15'                                                    70600013
TWO      DC    H'2'                                                     70640013
EIGHT    DC    H'8'                                                     70680013
TEMP1    DC    H'-1'                                                    70720013
FIVE     DC    H'5'                                                     70760013
H6       DC    H'6'                                                     70800013
H24      DC    H'24'                                                    70820015
CLIM     CLI   REGNAM+1(P16),0         THIS INSTRUCTION IS EXECUTED     70840013
*        WHEN THE PHYSICAL REGISTER NUMBER IN PHRGNO IS TO BE COMPARED  70880013
*        WITH THAT IN AN ENTRY IN LIST.                                 70920013
         SPACE                                                          70960013
         EJECT                                                          71000013
*                       FULL WORD SAVE AREAS                            71040013
OBSTOR   DC    11F'0'                  REGISTER SAVE AREA.              71080013
         SPACE                                                          71120013
ONE      DC    F'1'                                                     71160013
TEMP2    DC    F'-1'                                                    71200013
ZEROS    DC    F'0'                                                     71240013
COMPRG   CLC   RGSMOF(2,R2),REG        INSTRUCTION USED BY FINREG.      71280013
RGTBLT   DC    A(RGTLTH)               A WORD CONTAINING THE LENGTH OF  71320013
*        A REGISTER TABLE ENTRY.                                        71360013
MINUS1   DC    F'-1'                                                    71400013
REGNST   DC    F'-1'                   SAVE AREAS FOR THE REGISTERS     71440013
PHRGN2   DC    F'-1'                 REGNO AND PHRGNO.                  71480013
         SPACE                                                          71520013
REQTOP   DC    F'-1'                                                    71560013
BSTRGT   DS    F                       POINTER TO REGTAB ENTRY FOR BEST 71570015
*                                    BASE.                              71580015
BALRSW   DC    X'0'                                                     71600013
         SPACE 5                                                        71610001
*                  DATA FOR LOOK AHEAD                                  71620001
         SPACE 1                                                        71630001
LAWNTD   EQU   X'83'                                                    71640001
         EJECT                                                          71680013
*                       SYMBOLIC CODE BYTES                             71720013
         SPACE                                                          71760013
ON       EQU   X'FF'                   *    SWITCH SETTINGS     *       71800013
OFF      EQU   X'00'                   *                        *       71840013
RRMAX    EQU   X'6F'                   MAX CODE FOR RR INSTRUCTION.NO   71880013
*                                    OTHER TYPE IS LESS THAN THIS.      71920013
ADI      EQU   X'BE'                                                    71960013
OSM1     EQU   X'10'                                                    72000013
OSM2     EQU   X'11'                                                    72040013
OSM3     EQU   X'BD'                                                    72080013
EOB      EQU   X'21'                                                    72120013
MCUSNG   EQU   X'36'                                                    72140001
MCBALR   EQU   X'4F'                                                    72160013
MCLM     EQU   X'70'                                                    72200013
FMAS     EQU   X'10'                                                    72240013
INST     EQU   1                                                        72280013
ASGNST   EQU   24                                                       72320013
MCSR     EQU   X'4B'                                                    72360013
MCXR     EQU   X'47'                                                    72400013
MCEQU    EQU   X'07'                                                    72410001
MCSPM    EQU   X'51'                                                    72420001
MCLAPR   EQU   X'B7'                                                    72423001
MCUSSL   EQU   X'D8'                                                    72426001
MCSINL   EQU   X'DB'                                                    72430001
IPRMP    EQU   X'1D'                                                    72440013
EPRMP    EQU   X'1E'                                                    72480013
ENTLAB   EQU   X'01'                   CODE BYTE FOR INTERNAL ENTRY     72520013
ENTP4    EQU   X'03'                LABEL, EXTERNAL ENTRY POINT,        72560013
ENTP5    EQU   X'83'                FORMAL PARAMETER ENTRY POINT.       72600013
ENTBYT   EQU   13                      OFFSET OF ENTRY CODE BYTE IN     72640013
*                                    ENTRY TYPE 4 OR 5.                 72680013
E2INEL   EQU   11                      OFFSET OF REFERENCE TO ENTRY     72760013
*                                    TYPE2 IN ENTRY LABEL.              72800013
E3INE2   EQU   3                       OFFSET OF REFERENCE TO ENTRY     72840013
*                                    TYPE3 IN ENTRY TYPE2.              72880013
ENTB3    EQU   10                      OFFSET OF ENTRY CODE BYTE IN     72920013
*                                    ENTRY TYPE3.                       72960013
BTLTH    EQU   24                                                       72970015
XD       EQU   12                                                       72980015
         SPACE 4                                                        73000013
BIT0     EQU   X'80'                   **                       **      73040013
BIT1     EQU   X'40'                   **                       **      73080013
BIT2     EQU   X'20'                   **    MASKS USED FOR     **      73120013
BIT3     EQU   X'10'                   **                       **      73160013
BIT4     EQU   X'08'                   **    SETTING ON BITS    **      73200013
BIT5     EQU   X'04'                   **                       **      73240013
BIT6     EQU   X'02'                   **    IN A BYTE.         **      73280013
BIT7     EQU   X'01'                   **                       **      73320013
NOBIT0   EQU   X'7F'                   **                       **      73360013
NOBIT1   EQU   X'BF'                   **                       **      73400013
NOBIT2   EQU   X'DF'                   **    MASKS USED FOR     **      73440013
NOBIT3   EQU   X'EF'                   **                       **      73480013
NOBIT4   EQU   X'F7'                   **    SETTING OFF        **      73520013
NOBIT5   EQU   X'FB'                   **                       **      73560013
NOBIT6   EQU   X'FD'                   **    BITS IN A BYTE.    **      73600013
NOBIT7   EQU   X'FE'                   **                       **      73640013
         SPACE 4                                                        73680013
NOTB01   EQU   X'3F'                                                    73720013
ALLZRO   EQU   X'00'                                                    73760013
ALLONE   EQU   X'FF'                                                    73800013
         EJECT                                                          73840013
*                       REGISTERS USED                                  73880013
GRDIC    EQU   13                      POINTER TO COMMUNICATIONS REGION 73920013
GRCC     EQU   11                      POINTER TO COMPILER CONTROL      73960013
GRRF     EQU   9                       *                 *              74000013
GRRG     EQU   10                      *   BLOCK BASES   *              74040013
GRRH     EQU   12                      *                 *              74080013
         SPACE                                                          74120013
P        EQU   4                       POINTER TO LIST.                 74160013
T        EQU   5                       POINTER TO END OF REQLST         74200013
REGNO    EQU   6                       POINTER TO THE REGISTER TABLE.   74240013
PHRGNO   EQU   7                       COUNT OF THE PHYSICAL REGISTER   74280013
*        NUMBER WHEN SCANNING THE REGISTER TABLE.                       74320013
P16      EQU   8                   TEMPORARY POINTER                    74360013
RP       EQU   8                       RESERVE POINTER                  74380001
RR       EQU   14                                                       74400013
R14      EQU   14                                                       74420001
LR       EQU   15                                                       74440013
P7       EQU   1                       *    POINTERS AT  FRLIST  *      74480013
P8       EQU   2                       *                 USLIST  *      74520013
P11      EQU   3                       *                 ASLIST  *      74560013
P9       EQU   4                       POINTER FOR USTACK               74600013
P18      EQU   5                       POINTER FOR PSTACK               74640013
Q        EQU   5                                                        74680013
R        EQU   5                                                        74720013
R0       EQU   0                                                        74760013
R1       EQU   1                                                        74800013
R2       EQU   2                                                        74840013
R3       EQU   3                                                        74880013
R4       EQU   4                                                        74920013
R5       EQU   5                                                        74960013
R6       EQU   6                                                        75000013
R7       EQU   7                                                        75040013
R8       EQU   8                                                        75080013
P1       EQU   6                                                        75120013
SP       EQU   1                                                        75130001
         SPACE 2                                                        75140001
PBREG    EQU   10                      OBJECT PROGRAM BASE              75150001
         EJECT                                                          75160013
*                       BRANCH MNEMONICS.                               75200013
BE       EQU   8                                                        75240013
BNE      EQU   7                                                        75280013
BZ       EQU   8                                                        75320013
BNZ      EQU   7                                                        75360013
B        EQU   15                                                       75400013
BO       EQU   1                                                        75440013
BNO      EQU   14                                                       75480013
BL       EQU   4                                                        75520013
BLE      EQU   12                                                       75560013
BM       EQU   4                                                        75600013
BH       EQU   2                                                        75640013
BHE      EQU   10                                                       75680013
BNM      EQU   11                                                       75690001
NOP      EQU   0                                                        75700001
BNL      EQU   11                                                       75710001
         EJECT                                                          75720013
*              DUMMY CONTROL SECTION FOR DICTIONARY                     75760013
         SPACE                                                          75800013
PAR1     EQU   128+CR                                                   75840013
PAR2     EQU   PAR1+4                                                   75880013
PAR3     EQU   PAR2+4                                                   75920013
PAR4     EQU   PAR3+4                                                   75960013
PAR5     EQU   PAR4+4                                                   76000013
PAR6     EQU   PAR5+4                                                   76040013
ZOPT     EQU   CR+196                                                   76060001
         EJECT                                                          76080013
*              DUMMY CONTROL SECTION FOR COMPILER CONTROL               76120013
         SPACE                                                          76160013
ZABORT   EQU   CC+X'20'                                                 76200013
ZUERR    EQU   CC+X'30'                                                 76240013
ZDUMP    EQU   CC+X'38'                                                 76280013
ZTXTRF   EQU   CC+X'50'                                                 76320013
ZTXTAB   EQU   CC+X'54'                                                 76360013
ZCHAIN   EQU   CC+X'58'                                                 76400013
ZALTER   EQU   CC+X'5C'                                                 76440013
*                       CODES TO INDICATE TO COMPILER CONTOL THAT A     76480013
BFUNW    EQU   X'02'                   BUFFER IS NOT WANTED             76520013
NOCHNG   EQU   X'00'                   BUFFER DOES NOT REQUIRE A STATUS 76560013
*                                    CHANGE.                            76600013
ZDRFAB   EQU   X'34'+CC                                                 76640013
         EJECT                                                          76680013
*                       DUMMY CONTROL SECTION FOR THE FIRST BLOCK RF.   76720013
         SPACE                                                          76760013
         SPACE 3                                                        76800013
*              OFFSETS IN TRANSFER VECTOR OF SUBROUTINES IN RF          76840013
         SPACE                                                          76880013
CMPERR   EQU   RF+16                   * COMPILER ERROR                 76980042
ADIMOV   EQU   CMPERR+4                * MOVE ADI INST TO O/P FILE      77080042
CHAIN    EQU   ADIMOV+4                * SEARCHES A CHAIN               77180042
FINREG   EQU   CHAIN+4                 *                                77280042
LOAD1    EQU   FINREG+4                * LOADS REG FROM PRIVATE STORAGE 77380042
LOADRG   EQU   LOAD1+4                 * GENERATES A LOAD REGISTER      77480042
RTABSH   EQU   LOADRG+4                * SEARCHES REGTAB FOR SYM REGS   77580042
SERCH2   EQU   RTABSH+4                * SEARCHES ASSIGNED REG CHAIN    77680042
STORE1   EQU   SERCH2+4                * STORES ASSIGNED REGISTER       77780042
STORE2   EQU   STORE1+4                * STORES SYMBOLIC REGISTER       77880042
STOREQ   EQU   STORE2+4                * STORES PHYSICAL REGISTER       77980042
         SPACE 3                                                        78280013
*              OFFSETS OF DATA COMMON TO MORE THAN ONE CONTROL SECTION. 78320013
*        SUCH DATA IS STORED IN RF                                      78360013
         SPACE                                                          78400013
SBSWD    EQU   STOREQ+4                                                 78440042
P2       EQU   SBSWD+4        POINTS ONE BYTE BEYOND LAST BYTE OF LIST  78480013
REGNO2   EQU   P2+4           POINTER TO LAST ENTRY IN REGISTER TABLE   78520013
SYMCHD   EQU   REGNO2+4       HEAD OF SYMBOLIC CHAIN                    78560013
SHOLHD   EQU   SYMCHD+4       HEAD OF CHAIN OF HOLES FOR SYMBOLIC AND   78600013
*                           ASSIGNED CHAIN                              78640013
PSTCHD   EQU   SHOLHD+4       HEAD OF CHAIN OF FREE PRIVATE STORAGE     78680013
*                           CELLS                                       78720013
PHOLHD   EQU   PSTCHD+4       HEAD OF CHAIN OF HOLES FOR PRIVATE        78760013
*                           STORAGE CHAIN                               78800013
Q2       EQU   PHOLHD+4       POINTER TO LIST OF FREE REGISTERS         78840013
OLDLNK   EQU   Q2+4            POINTER SET BY CHAIN ROUTINE             78880013
TEXLEN   EQU   OLDLNK+4       LENGTH OF CURRENTLY GENERATED T5XT        78920013
STAKPT   EQU   TEXLEN+4       POINTS TO STACK ENTRY FOR CURRENT BLOCK   78960013
REGREQ   EQU   STAKPT+4       NUMBER OF REGISTERS REQUIRED AT ANY POINT 79000013
*                           IN OBREGS.                                  79040013
CBSAVE   EQU   REGREQ+4                                                 79060015
CBUFPT   EQU   CBSAVE+4                                                 79080015
STLIST   EQU   CBUFPT+4                                                 79100015
BROUT    EQU   STLIST+9                                                 79120013
FRLIST   EQU   BROUT+3                                                  79170001
MADI     EQU   FRLIST+8                LENGTH-1 OF ADILST               79230015
INTBAS   EQU   MADI+2                                                   79250015
ADISKT   EQU   INTBAS+1                SKELETON ADI                     79270015
FRTOP    EQU   ADISKT+5                ADDRESS OF END FRLST             79290015
BSTPR    EQU   FRTOP+4                                                  79320013
BST      EQU   BSTPR+2                                                  79360013
PRSW     EQU   BST+2                                                    79400013
BSTRG    EQU   PRSW+2                                                   79440001
BSETAB   EQU   BSTRG+2                 TABLE OF ADI'S DESCRIBING BASES  79490015
ADILST   EQU   BSETAB+192              LIST OF ADI'S PASSED WITH A REQU 79500015
*                                    EST FOR A BASE                     79510015
BSTBAS   EQU   ADILST+56               BEST BASE FOUND SO FAR AND       79520015
BNADI    EQU   BSTBAS+2              CORRESPONDING LENGTH-1 OF ITS ADIS 79530015
BCTREG   EQU   BNADI+2               INTER TO REGISTER TABLE ENTRY FOR  79533016
*                                  OPERAND OF BCT BCT, BCT' OR BCTR     79536016
SPSTOR   EQU   BCTREG+4            SAVE SOURCE POINTER                  79539016
DROPST   EQU   SPSTOR+4            RETURN ADDRESS DURING FRE PRIVATE    79542016
*                                  STORAGE ROUTINE                      79545016
DRPLST   EQU   DROPST+4            REGISTER SAVE AREA DURING USSL/DRPL  79548016
HTEMP    EQU   DRPLST+12           TEMPORARY                            79551016
HM24     EQU   HTEMP+2             -SIZE OF BSETAB ENTRY                79554016
TSW1     EQU   HM24+2  TEMPORARY STORE FOR SW1 AT BRANCH BEFORE FMT'    79557016
FMTSW    EQU   TSW1+1     SWITCH TO INDICATE AT A DROP THAT THE         79560016
*                                  PRIVATE STORAGE CELL MUXT NOT BE     79563016
*                                  REUSED                               79566016
FMTPSW   EQU   FMTSW+1            FLAG FOR FMT' TO SPECIAL CASE THE     79567001
*                                   FOLLOWING EQU                       79568001
BCTSW    EQU   FMTPSW+2           ON DURING BCT, BCT', OR BCTR ONLY     79569001
CATSW    EQU   BCTSW+1             CATEGORY OF CURRENT INSTRUCTION      79572016
SSINST   EQU   CATSW+1 SS INSTRUCTIONS BUILT HERE                       79575016
SSFLAG   EQU   SSINST+8            TEMPORARY STORAGE FOR FLAG BYTE OF   79578016
*                                  SS INSTRUCTIONS                      79581016
CTEMP    EQU   SSFLAG+1            TEMPORARY                            79584016
RXINST   EQU   CTEMP+1             RX OR SI INSTRUCTIONS BUILT HERE     79587016
PSTST    EQU   RXINST+5            HEAD OF FREE PRIVATE STORAGE CHAIN   79590016
TESTUM   EQU   PSTST+3                                                  79593016
*                           A REGISTER.                                 79600013
LDREF    EQU   TESTUM+4       DICT REF FROM RX LOAD.                    79640013
SYMCNT   EQU   LDREF+2        COUNT OF SYMBOLIC REGISTERS IN USLIST     79680013
USECNT   EQU   SYMCNT+2       COUNT OF ALL REGISTERS IN USLIST          79720013
PSTOR    EQU   USECNT+2       AMMOUNT OF PRIVATE STORAGE THAT IS        79760013
*                           CURRENTLY REQUIRED                          79800013
PSTOR2   EQU   PSTOR+2        OFFSET OF CURRENTLY CONSIDERED PRIVATE    79840013
*                           STORAGE CELL                                79880013
ICOUNT   EQU   PSTOR2+2       IPRM/EPRM NESTING LEVEL                   79920013
SYMREG   EQU   ICOUNT+2       PARAMETER TO RTABSH                       79960013
CURTRF   EQU   SYMREG+2       NAME OF CURRENTLY SCANNED BUFFER OF       80000013
*                           INSERTION FILE                              80040013
BASE     EQU   CURTRF+3       PARAMETER FOR ADIMOV ROUTINE              80080013
CHBS     EQU   BASE+1                                                   80100015
SBUFNM   EQU   CHBS+1                  NAME ON CURRENT SOURCE BUFFER    80120015
         SPACE                                                          80160013
*              THE FOLLOWING SWITCHES DESCRIBE THE CURRENTLY CONSIDERED 80200013
*        PSEUDO-CODE INSTRUCTION. (THE COMMENTS DESCRIBE WHEN EACH      80240013
*        SWITCH IS ON)                                                  80280013
         SPACE                                                          80320013
SW0      EQU   SBUFNM+3       ANY BRANCH INSTRUCTION                    80360013
SW1      EQU   SW0+1          INSTRUCTION REFERRING TO LABEL OR EQU     80400013
*                           VALUE                                       80440013
SW2      EQU   SW1+1          BC OR BCR INSTRUCTION WITH CONDITION CODE 80480013
*                           NOT FIFTEEN                                 80520013
SW3      EQU   SW2+1          SW2 IS ON AND OBREGS HAS A SURPL          80560013
*                           REGISTER                                    80600013
SW4      EQU   SW3+1              ON IF WITHIN EDIT,EDITPRIME     38181 80610042
MLSW     EQU   SW4+1              ON IF BASE REGISTER REQUIRES          80620042
*                                 MORE THAN ONE INSTRUCTION TO LOAD IT  80630042
BCFMT    EQU   MLSW+1         SWITCH TO INDICATE BC OR BCR FOLLOWED     80670001
*                               BY FMT'                                 80700001
REG      EQU   BCFMT+1        SAVE AREA FOR SYMBOLIC REGNO              80730001
PAIR     EQU   REG+2          RESULT FROM FRTEST                        80760001
TESMSK   EQU   PAIR+1         USED BY TESTUM                            80800013
         EJECT                                                          80840013
REGTAB   EQU   TESMSK+1       REGISTER TABLE                            80880013
*                       FORMAT OF THE REGISTER TABLE                    80920013
         SPACE 4                                                        80960013
HEADAC   EQU   0                       OFFSET FROM START OF AN ENTRY OF 81000013
*                                    HEAD OF ASSIGNED CHAIN.            81040013
PSTOFF   EQU   6                       THE OFFSET OF THE PRIVATE        81080013
*                                    STORAGE OFFSET IN A SYMBOLIC OR    81120013
*                                    ASSIGNED REGISTER CHAIN.           81160013
SYM1     EQU   3                       FLAG BYTE                        81170001
*                                        BIT0   PAIR BIT                81180001
*                                        BIT1   SINDEX BIT              81190001
ASS1     EQU   4                       OFFSET OF ICOUNT IN ASSIGNED     81200013
ASS2     EQU   PSTOFF                REGISTER CHAIN ELEMENT.            81240013
*                                     NOT WANTED OR PAIR MEMBER, AND    81280013
*                                     ALTERED SINCE LAST LOADED.        81320013
ASS3     EQU   3                       OFFSET OF INDICATOR BYTE         81330001
*                                        BIT1   SINDEX BIT              81340001
RGSMOF   EQU   4                       OFFSET OF SYMBOLIC REGISTER      81360013
*                                    NAME IN ABOVE CHAIN.               81400013
PARBYT   EQU   3                       OFFSET OF PAIR BYTE IN SYMBOLIC  81440013
*                                    REGISTER CHAIN ENTRY               81480013
F3PF4    EQU   5                       LENGTH OF F3 PLUS F4, AND F1     81520013
*                                    PLUS F3 PLUS F4.                   81560013
F134     EQU   6                                                        81600013
F1       EQU   3                       OFFSET OF FIELD F1 FROM START OF 81640013
*                                    AN ENTRY                           81680013
         SPACE                                                          81720013
*                       CODES IN F1                                     81760013
BITS01   EQU   X'C0'                   BITS INDICATING  X'00' FREE,     81800013
*        X'01' ASSIGNED, X'10' BASE, X'11' SYMBOLIC.                    81840013
WANTED   EQU   X'20'                   BIT TO INDICATE THAT THE         81880013
*        REGISTER IS REQUIRED IN THE INSTRUCTION.                       81920013
PAIRMM   EQU   X'10'                   BIT TO INDICATE THAT THE         81960013
*        REGISTER IS A MEMBER OF A PAIR.                                82000013
CHNGED   EQU   X'08'                   BIT TO INDICATE THAT THE         82040013
*        REGISTER IS CHANGED BY THE INSTRUCTION.                        82080013
DNST     EQU   X'04'                   BIT TO INDICATE THAT THIS        82120013
*        REGISTER MUST NEVER BE STORED.                                 82160013
DEPON    EQU   X'02'                   A BASE WHICH IS AN INTERMEDIATE  82166015
*                                    VALUE IN THE CALCULATION OF ANOTH- 82172015
*                                    ER BASE.                           82178015
DPNDNT    EQU  X'01'                   A BASE WHICH CAN BE CALCULATED S 82184015
*                                    STARTING FROM ANOTHER              82190015
SUWNP    EQU   X'E0'                   SYMBOLIC, UNCHANGED, WANTED, NOT 82200013
*                                    PAIR.                              82240013
SUWP     EQU   X'F0'                   SYMBOLIC, UNCHANGED, WANTED,     82280013
AUWNP    EQU   X'60'                   ASSIGNED, UNCHANGED, WANTED, NOT 82320013
*                                    PAIR.                              82360013
ASNWPA   EQU   X'48'                   F1 CODE TO INDICATE ASSIGNED,    82370001
*                                      NOT WANTED OR PAIR, ALTERED      82380001
*                                        SINCE LAST LOADED              82390001
F3       EQU   4                       OFFSET OF FIELDS F3 AND F4       82400013
F4       EQU   7                     FROM THE START OF AN ENTRY         82440013
RGTLTH   EQU   9                       LENGTH OF AN ENTRY IN THE        82480013
*                                    REGISTER TABLE.                    82520013
         EJECT                                                          82560013
*              LIST IS SET UP BY BLOCK RF TO INDICATE THE REGISTERS     82600013
*        REQUIRED BY THE INSTRUCTION BEING EXAMINED.                    82640013
LIST     EQU   REGTAB+72      LIST (LIST OF REQUIRED REGISTERS)         82680013
CODE1    EQU   0                       *                        *       82720013
REGNAM   EQU   1                       *   OFFSETS FROM THE     *       82760013
REGNUM   EQU   3                       *   START OF LIST        *       82800013
CODE2    EQU   4                       *                        *       82840013
ENDLST  EQU   LIST+25                 25 IS THE PRODCT OF THE LENGTH    82880013
*        OF AN ENTRY IN LIST MULTIPLIED BY THE NUMBER OF ENTRIES.       82920013
         SPACE                                                          82960013
*              SETTINGS OF CODE1 IN LIST                                83000013
EXORAS   EQU   X'3C'                   EXAMINED OR ASSIGNED             83040013
INREG    EQU   X'0F'                   REGISTER ALREADY LOADED          83080013
FNDREG   EQU   X'F0'                   REGISTER REQUIRED                83120013
BASREQ   EQU   X'FF'                   BASE REGISTER REQUIRED           83160013
NULL     EQU   X'00'                   THIS LIST ENTRY IS TO BE IGNORED 83200013
LSTLTH   EQU   5                       LENGTH OF ONE ENTRY IN LIST.     83240013
LBASE1   EQU   LIST                                                     83280013
LBASE2   EQU   LBASE1+LSTLTH                                            83320013
REG1     EQU   LBASE2+LSTLTH+REGNUM                                     83360013
REG2     EQU   REG1+LSTLTH                                              83400013
         SPACE                                                          83440013
*                       SETTINGS OF CODE2 IN LIST.                      83480013
CHNGES   EQU   X'80'                   THE INSTRUCTION BEING CONSIDERED 83520013
*        CHANGES THE REGISTER DEFINED BY THIS ENTRY.                    83560013
HASPRI   EQU   X'40'                   THE DESCRIBED REGISER HAS A      83600013
*        VALUE IN STORAGE WITH WHICH IT MUST BE LOADED.                 83640013
NOST     EQU   X'20'                   REGISTER MUST NOT BE STORED.     83680013
         SPACE                                                          83720013
         EJECT                                                          83725001
LASAVE   EQU   LIST+27                                                  83730042
LAEVAL   EQU   LASAVE+28               *    DATA AREAS                  83735001
LAOPT    EQU   LAEVAL+2                *    FOR LOOK AHEAD              83742001
LANBLK   EQU   LAOPT+1                 *                                83750001
TRTAB    EQU   LANBLK+1                TRANSLATE TABLE FOR              83755001
*                                        PSEUDO-CODE ITEMS              83760001
SINTAB   EQU   TRTAB+256               SINDEX TABLE                     83765001
         SPACE 3                                                        83770001
         LTORG                                                          83785001
         ORG   IEMRG+4095                                               83790001
         END   IEMRG                                                    83800013
