**********************************************************************  00010019
*                                                                    *  00020019
*TITLE: IKM001 - CONTROL PHASE - 20K VERSION                         *  00030019
*                                                                    *  00040019
*STATUS: CHANGE LEVEL 000                                            *  00050019
*                                                                    *  00060019
*FUNCTION/OPERATION: THIS IS THE MAIN ENTRY OF THE SYNTAX CHECKER.   *  00070019
*   THERE ARE FOUR POSSIBLE TYPES OF ENTRY DEPENDING UPON THE BIT    *  00080019
*   SETTINGS IN THE COMMUNICATION AREA.                              *  00090019
*   1. NO MAIN STORAGE HAS BEEN RESERVED FOR THE DATAAREA.           *  00100019
*      MAIN STORAGE IS REQUESTED AND THE CONSTANT PARTS OF THE       *  00110019
*      DATAAREA IS INITIALIZED.PROCESSING CONTINUES IN 2.            *  00120019
*   2. FIELDS IN THE DATAAREA ARE INITIALIZED,THE SOURCE TEXT IS     *  00130019
*      SCANNED FOR STATEMENTS AND THE STATEMENTS ARE MOVED ONE BY    *  00140019
*      ONE INTO THE DATAAREA.CONTROL IS GIVEN IN THE FOLLOWING ORDER *  00150019
*      TO IKM02 FOR TRANSLATION INTO INTERNAL TOKENS OF C48 OR C60   *  00160019
*      SOURCE CODE AND TO IKM03 FOR STATEMENT CLASSIFICATION.IKM03   *  00170019
*      GIVES A RETURN CODE SAYING THAT CHECKING IS COMPLETE OR THAT  *  00180019
*      CONTROL SHOULD BE GIVEN TO ONE OF THE ROUTINES IKM21,IKM22    *  00190019
*      OR IKM23,WHERE THE CHECKING IS COMPLETED.                     *  00200019
*   3. CONTROL IS GIVEN TO THE ERROR MESSAGE ROUTINE IKM12 TO        *  00210019
*      CONTINUE THE OUTSTANDING REQUEST FOR AN ERROR MESSAGE TO BE   *  00220019
*      CONSTRUCTED                                                   *  00230019
*   4. MAIN STORAGE FOR THE DATAAREA IS RELEASED.                    *  00240019
*                                                                    *  00250019
*ENTRY POINT: IKM001                                                 *  00260019
*                                                                    *  00270019
*INPUT: ADDRESS OF A PARAMETER LIST IN REG 1.                        *  00280019
*       PARAMETERLIST:   DC   A(FIRST SOURCEBUFFER IN CHAIN)         *  00290019
*                        DC   A(ADDRESS OF COMMUNICATION AREA)       *  00300019
*                        DC   A(ADDRESS OF OPTION WORD)              *  00310019
*                                                                    *  00320019
*OUTPUT: ADDRESS OF EVENTUAL ERROR MESSAGE AND ADDRESS OF DATAAREA   *  00330019
*   TO COMMUNICATION AREA.                                           *  00340019
*                                                                    *  00350019
*EXTERNAL ROUTINES: IKM02,IKM03,IKM21,IKM22,IKM23.                   *  00360019
*                                                                    *  00370019
*EXITS-NORMAL:      L     R13,SAVELEV1+4                             *  00380019
*                   LM    R14,R12,12(R13)                            *  00390019
*                   LA    R15,RETURN CODE                            *  00400019
*                   BR    R14                                        *  00410019
*                                                                    *  00420019
*        RETURN CODES:   0 - NO ERROR,CHECKING COMPLETE              *  00430019
*                        4 - ERROR,ADDRESS OF DIAGNOSTIC MESSAGE     *  00440019
*                            STORED IN COMMUNICATION AREA,SECOND     *  00450019
*                            WORD,CHECKING COMPLETE                  *  00460019
*                        8 - ERROR,ADDRESS OF DIAGNOSTIC MESSAGE     *  00470019
*                            STORED IN COMMUNICATION AREA,SECOND     *  00480019
*                            WORD,CONTINUED CHECKING POSSIBLE        *  00490019
*                       12 - OPTION WORD BYTE 3,BIT 3 = 1 AND THE    *  00500019
*                            LAST STATEMENT IN THE INPUT BUFFER(S)   *  00510019
*                            IS INCOMPLETE.ANY COMPLETE STATEMENT(S) *  00520019
*                            PRESENT IN THE INPUT BUFFER(S) HAS      *  00530019
*                            BEEN CHECKED.THE CHECKER MAY BE ENTERED *  00540019
*                            AGAIN WITH MORE INPUT BUFFER(S) CHAINED *  00550019
*                            TO THE PRESENT BUFFER(S) OR ENTERED     *  00560019
*                            TO REQUEST AN ERROR MESSAGE.            *  00570019
*                       16 - ENOUGH STORAGE FOR WORK AREAS NOT       *  00580019
*                            AVAILABLE                               *  00590019
*                                                                    *  00600019
*TABLES/WORKAREAS: DATAAREA ADDRESSABLE VIA DSECT BASED ON REG 12    *  00610019
*                                                                    *  00620019
*ATTRIBUTES: REENTRANT                                               *  00630019
*                                                                    *  00640019
**********************************************************************  00650019
*                  REL 20 DELETIONS                                     00750020
* 640000                                                         S20046 00850020
IKM001   CSECT                                                          01000019
         IKMBASE                                                        02000019
         LTR   15,15                   TST IF RETURN CODE=O             03000019
         BNZ   RESTART                 IF NOT CHECK NEXT STMNT          04000019
STATSORT L     15,V03                                                   05000019
         BALR  14,15                   GO TO IKMO3                      06000019
         LA    14,RESTART                                               07000019
         LTR   15,15                   TST IF RETURN CODE=O             08000019
         BZ    RESTART                 YES,   CHECK NEXT STMNT          09000019
         L     R2,STATBEG              POINT AT BEGNG OF STMNT          10000019
         CLI   1(R2),KDELETE           TST IF STMNT STARTS BY DELETE    11000019
         BL    L21                     IF DO GET PUT FORMAT             12000019
         CLI   1(R2),KGO                                                13000019
         BE    L21                                                      14000019
         CLI   1(R2),KGOTO                                              15000019
         BE    L21                                                      16000019
         CLI   1(R2),KFREE             TST FOR FREE                     17000019
         BL    L22                     IF DELETE, LOCATE READ REWRITE,  18000019
         CLI   1(R2),KALLOC            TST FOR ALLOCATE                 19000019
         BE    L23                     IF ALLOCATE                      20000019
         CLI   1(R2),KDCL              TST FOR SECLARE                  21000019
         BE    L23                     IF DECLARE                       22000019
L22      OI    DEMANDFL,X'40'                                           23000019
         B     LOADTEST                                                 24000019
L23      OI    DEMANDFL,X'20'          FLAG MODULR IKM23 DEMANDED       25000019
         B     LOADTEST                                                 26000019
L21      OI    DEMANDFL,X'80'          FLAG MODULE IKM21 DEMANDED       27000019
         LA    14,ONTST                                                 28000019
LOADTEST TM    LOADFLAG,X'E0'          ANY MODULE LOADED ALREADY        29000019
         BZ    NODELETE                NO                               30000019
         XC    DEMANDFL,LOADFLAG       IS DEMANDED MODULE LOADED        31000019
         BZ    NOLOAD                  YES,NO LOADING ACTION            32000019
         TM    LOADFLAG,X'80'          MODULE IKM21 LOADED              33000019
         BO    DEL21                   YES,DELETE THE MODULE            34000019
         TM    LOADFLAG,X'40'          IS MODULE IKM22 LOADED           35000019
         BO    DEL22                   YES,DELETE THE MODULE            36000019
DEL23    DELETE    EP=IKM23                                             37000019
         B     NODELETE                                                 38000019
DEL22    DELETE    EP=IKM22                                             39000019
         B     NODELETE                                                 40000019
DEL21    DELETE    EP=IKM21                                             41000019
NODELETE TM    DEMANDFL,X'01'          TERMINATE SYNTAX CHECKER         42000019
         BO    THEEND                  YES                              43000019
         XC    LOADFLAG,LOADFLAG       ZERO LOADFLAG                    44000019
         TM    DEMANDFL,X'80'          MODULE IKM21 DEMANDED            45000019
         BO    LOAD21                  YES,LOAD                         46000019
         TM    DEMANDFL,X'40'          MODULE IKM22 DEMANDED            47000019
         BO    LOAD22                  YES,LOAD                         48000019
LOAD23   LOAD  EP=IKM23                                                 49000019
         B     OUT                                                      50000019
LOAD22   LOAD  EP=IKM22                                                 51000019
         B     OUT                                                      52000019
LOAD21   LOAD  EP=IKM21                                                 53000019
OUT      OC    LOADFLAG,DEMANDFL       FLAG MODULE NOW LOADED           54000019
         ST    0,MODULE                STARTADDR OF LOADED MODULE       55000019
NOLOAD   OC    DEMANDFL,LOADFLAG                                        56000019
         L     15,MODULE               GET ADDR OF LOADED MODULE        57000019
         BR    15                      BRANCH TO LOADED MODULE          58000019
ONTST    TM    COMFLAG1,ONFLAG                                          59000019
         BO    STATSORT                                                 60000019
RESTART  LM    CHARP,CHARC,ENDP        AFTER COMPLETE CHECK OR ERROR    61000019
         NI    COMFLAG1,CLEAR1         EXCEPT FOR SOURCE-LINENO-ERRFL   62000019
         NI    COMFLAG2,ESFLAG                                          63000019
         L     OLDBUFFP,STARTP+8       POINT AT FIRST BUFFER     S20046 63100020
*                                      TO STMNT JUST CHECKED     S20046 63200020
BUFFPTST CR    OLDBUFFP,BUFFP          STILL IN THE SAME BUFFER? S20046 63300020
         BE    CHECK1                  YES,DO NOT RELEASE BUFFER S20046 63400020
         LR    R2,OLDBUFFP                                       S20046 63500020
         L     OLDBUFFP,0(OLDBUFFP)    POINT AT NEXT BUFFER      S20046 63600020
         OI    0(R2),B'10000000'       NO,RELEASE BUFFER         S20046 63700020
         B     BUFFPTST                CAN BUFFER BE RELEASED?   S20046 63800020
VSERV    DC    V(IKM12)                                                 64100019
         DC    V(IKM131)                                                64200019
         DC    V(IKM132)                                                64300019
         DC    V(IKM133)                                                64400019
         DC    V(IKM134)                                                64500019
         DC    V(IKM135)                                                64600019
         DC    V(IKM136)                                                64700019
COMAREA  DSECT                                                          65000019
COMFL    EQU   *                                                        66000019
DATAAR   DS    1F                                                       67000019
ERRMESS  DS    1F                                                       68000019
         DS    2F                                                       69000019
         IKMDATA                                                        70000019
         ORG   SLASK2                                                   71000019
FL00     DS    1C                                                       72000019
GM       DS    3F                                                       74000019
         DS    0D                                                S20046 75000020
SLASKD   DS    1D                                                S20046 76000020
EIGHTREG DS    1F                                                       78000019
         END                                                            79000019
