IKM133   CSECT                                                          00200019
*********************************************************************** 00400019
*                                                                     * 00600019
*TITLE: IKM133-EXPRESSION SCAN                                        * 00800019
*                                                                     * 01000019
*STATUS: CHANGE LEVEL 000                                             * 01200019
*                                                                     * 01400019
*FUNCTION/OPERATION: SCANS AN EXPRESSION CLASSIFIED TOKEN STRING FOR  * 01600019
*   POSSIBLE ERRORS.TWO SCAN MODES INDICATED IN SUBSCRF ARE POSSIBLE. * 01800019
*   SUBSCF WILL BE SET WHEN THE CURRENT POSITION IN THE TOKENSTRING   * 02000019
*   IS INSIDE A SUBSCRIPT.WHENEVER A LEFT PARENTHESIS IS FOUND THE    * 02200019
*   MATCHING RIGHT PARENTHESIS TOKEN WILL BE MODIFIED IN ONE OF TWO   * 02400019
*   WAYS DEPENDING ON WHETHER THE PARENTHESIES ENCLOSE A SUBSCRIPT OR * 02600019
*   AN ORDINARY EXPRESSION.THE INFORMATION ABOUT THE SCAN MODE WILL BE* 02800019
*   TRANSFERRED ACROSS THE PARENTHESES BY INSERTING THE SUBSCRF BIT IN* 03000019
*   THE RIGHTMOST BIT IN MODIFIED TOKEN.                              * 03200019
*                                                                     * 03400019
*     EXPRESSION MODIFIED RIGHT PARENTHESES:    X'22' SUBSCRFL OFF    * 03600019
*                                               X'23' SUBSCRFL ON     * 03800019
*     SUBSCRIPT  MODIFIED RIGHT PARENTHESES:    X'24' SUBSCRFL OFF    * 04000019
*                                               X'25' SUBSCRFL ON     * 04200019
*   THE REFER OPTION USED IN DECLARATION IS ALSO CHECKED IN           * 04400019
*   THIS MODULE.                                                        04600019
*ENTRY POINT: IKM133                                                  * 04800019
*   CALLING SEQUENCE: L     R15,VIKM133                               * 05000019
*                     BALR  R14,R15                                   * 05200019
*                                                                     * 05400019
*INPUT: START OF EXPRESSION IN EXPBEG IN DATAAREA.                    * 05600019
*       END OF EXPRESSION IN EXPEND IN DATAAREA.                      * 05800019
*                                                                     * 06000019
*OUTPUT: N/A                                                          * 06200019
*                                                                     * 06400019
*EXTERNAL ROUTINES: IKM12 ERROR MESSAGE CONSTRUCTION                  * 06600019
*                                                                     * 06800019
*EXITS -NORMAL:       L     R13,SAVELEV4+4                            * 07000019
*                     RETURN (R14,R12)                                * 07200019
*      -ERROR: N/A                                                    * 07400019
*                                                                     * 07600019
*TABLES/WORKAREAS: DATAAREA ADDRESSABLE VIA DSECT BASED ON REG 12     * 07800019
*                                                                     * 08000019
*ATTRIBUTES: REENTRANT                                                * 08200019
*                                                                     * 08400019
*********************************************************************** 08600019
         USING *,15                                                     08800019
         USING DATAAREA,12             REG 12 POINTS AT DSECT           09000019
         USING LEVELTAB,11                                              09100019
         STM   R14,R12,D12(R13)        SAVE REGISTERS                   09200019
         ST    R13,SAVELEV4+D4         SAVEAREA FOR THIS ROUTINE        09400019
         LA    R10,SAVELEV4                                             09600019
         ST    R10,D8(R13)                                              09800019
         LR    R13,R10                                                  10000019
         BAL   ERR,START133                                             10300019
         USING *,ERR                                                    10600019
ERRMSG   SR    R1,R1                                                    10900019
         IC    R1,D1(RET)                                               11200019
         LR    RET2,RET                                                 11500019
         L     R15,VIKM12              GO TO ERRORMODULE                11800019
         BALR  R14,R15                                                  12100019
         B     2(RET2)                 GO BACK IN SEQUENCE              12400019
START133 L     POINT,EXPBEG            FIRST TOKEN IN EXPRESSION        12800019
         L     EXPREND,EXPEND          FIRST TOKEN AFTER EXPRESSION     13000019
         LA    R8,EXPRETRN                                              13400019
         LA    R4,RESTART                                               13600019
         SR    ARRF,ARRF                                                13800019
         MVI   FL133,X00               ZERO INTERNAL FLAGS              14000019
         CR    POINT,EXPREND           EXPRESSION TERMINATED            14200019
         BNE   PRFIXTST                NO                               14400019
         ST    POINT,INSERT1           YES, SET T UP INSERT             14600019
         BALR  RET,ERR                 GO TO ERRORROUTINE               14800019
         DC    H'80'                   USE MESSAGE 80                   15000019
* OPERAND MISSING BEFORE XXX                                            15200019
EXPRETRN NI    COMFLAG2,255-REFERFL    SET OFF FLAG FOR REFER           15400019
         NI    COMFLAG1,255-DIMREFFL   SET OFF FLAG FOR REFER IN        15600019
*                                      DIMENSION                        15800019
         L     R13,SAVELEV4+D4         RESTORE REGISTERS                16000019
         LM    R14,R12,D12(R13)                                         16200019
         BR    R14                     GO BACK TO INVOKING ROUTIN       16400019
PRFXTST1 BALR  RET,NXTOK          GET NEXT TOKEN                        17600019
         CR    POINT,EXPREND      END OF EXPRESSION FOUND               17800019
         BNL   EXPERR7    OPRRAND MISSING AFTER XXX                     18000019
PRFIXTST CLI   D0(POINT),INOT          NO,NOT                           18200019
         BL    IDENTTST           NO                                    18400019
         CLI   D0(POINT),IMINUS        MINUS SIGN                       18600019
         BNH   PRFXTST1           NOT, PLUS OR MINUS FOUND              18800019
IDENTTST CLI   D0(POINT),IIDENT        IDENTIFIER                       19000019
         BE    IDENTFND           YES                                   19200019
CONSTTST CLI   D0(POINT),ILIT          NO, LITERAL                      19400019
         BE    CONSTFD1           YES                                   19600019
         BL    CONSTFND           NO, CONSTANT FOUND                    19800019
         CLI   D0(POINT),IOPEN         LEFT PARENTHESIS                 20000019
         BE    OPENFND            YES                                   20200019
         TM    D0(POINT),X20           NO OPERAND FOUND                 20400019
         BO    EXPERR9            OPERAND MISSING AFTER XXX             20600019
         CLI   D0(POINT),IDOT          POINT                            20800019
         BE    EXPERR11           YES ERROR                             21000019
         LTR   ARRF,ARRF          ANV PARENTHESIS IN EXPR.              21200019
         BZ    EXPERR2            NO, ERROR                             21400019
         CLI   D0(POINT),ICOMMA        COMMA                            21600019
         BE    EXPERR10           YES, ERROR                            21800019
EXPERR2  ST    POINT,INSERT1      PREPARE FOR INSERT                    22000019
         LR    OLDTOKEN,POINT     SAVE POINTER                          22200019
         BALR  RET,NXTOK          GET NEXT TOKEN                        22400019
         ST    POINT,INSERT2      PREPARE FOR INSERT                    22600019
         BALR  RET,ERR            GO TO ERRORROUTINE                    22800019
         DC    H'20'              USE MESSAGE 20                        23000019
*INVALID PREFIX OPERATOR XXX PRECEDING YYY                              23200019
         LR    POINT,OLDTOKEN     RESTORE POINTER                       23400019
         BR    R4                                                       23600019
OPENFND  LR    OLDTOKEN,POINT     RAVE POINTER                          23800019
         L     R15,VIKM132             SKIP PARENTHESIS                 24000019
         BALR  R14,R15                 GO TO IKM 132                    24200019
         STC   ARRF,D0(POINT)          STORE RIGHT PAREN TOKEN BYTE IN  24400019
         OI    D0(POINT),RPE           CHANGE TOKEN TYPE BYTE TO MARK T 24600019
         SR    ARRF,ARRF          ZERO REGISTER                         24800019
         CLI   D1(POINT),ILIT          LITERAL                          25000019
         BNE   SETEFLAG           NO                                    25200019
REPSTTST LR    POINT,OLDTOKEN     RESTORE POINTER                       25400019
         BALR  RET,NXTOK          GET NEXT TOKEN                        25600019
         CLI   D0(POINT),ICONST        CONSTANT                         25800019
         BNE   SETEFLAG           NO                                    26000019
         CLI   D1(POINT),INTEG         DECIMAL INTEGER                  26200019
         BNE   SETEFLAG           NO                                    26400019
         BALR  RET,NXTOK          YES GET NEXT TOKEN                    26600019
         TM    D0(POINT),RPE           RIGHT PAREN OFEXPR.FND           26800019
         BNO   SETEFLAG           NO SAVE                               27000019
         IC    ARRF,D0(POINT)          YES, SAVE TOKEN BYTE             27200019
         N     ARRF,M1            ZERO REG                              27400019
         MVI   D0(POINT),ICLOSE        RESTORE THE CLOSE PAREN          27600019
         BALR  RET,NXTOK          GET NEXT TOKEN                        27800019
         B     CONSTFD1                                                 28000019
SETEFLAG LR    POINT,OLDTOKEN     RESTORE POINTER                       28200019
         BALR  RET,NXTOK          GET NEXT TOKEN                        28400019
         B     PRFIXTST                                                 28600019
IDENTFND BALR  RET,NXTOK          GET NEXT TOKEN                        28800019
         CR    POINT,EXPREND      END OF EXPRESSION                     29000019
         BCR   ELV,R8                                                   29200019
         CLI   D0(POINT),IOPEN         NO, LEFT PARENTHESIS             29400019
         BNE   POINTTST           NO                                    29600019
         LR    OLDTOKEN,POINT     YES                                   29800019
         L     R15,VIKM132             SKIP PARENTHESES                 30000019
         BALR  R14,R15                 GO TO IKM 132                    30200019
         STC   ARRF,D0(POINT)          STORE RIGHT PAREN TOKEN BYTE IN  30400019
         OI    D0(POINT),RPS           MARK RIGHT PAREN IN SUBSCRIPT    30600019
         LA    ARRF,D1                 ADD ONE REG ARRF                 30800019
         LR    POINT,OLDTOKEN     RESTORE POINTER                       31000019
STARTST  BALR  RET,NXTOK          GET NEXT TOKEN                        31200019
         CLI   D0(POINT),ISTAR         ASTERISK                         31400019
         BNE   PRFIXTST           NO                                    31600019
         LR    OLDTOKEN,POINT     SAVE POINTER                          31800019
         BALR  RET,NXTOK          GET NEXT TOKEN                        32000019
         CLI   D0(POINT),ICOMMA        COMMA                            32200019
         BE    STARTST            YES                                   32400019
         TM    D0(POINT),RPS           RIGHT PAREN ONSUBSRRIPT FOUND    32600019
         BO    RPAFND             YES                                   32800019
         LR    POINT,OLDTOKEN     RESTORE POINTER                       33000019
         B     PRFIXTST                                                 33200019
POINTTST CLI   D0(POINT),IDOT          POINT                            33400019
         BE    QUALFTST           YES                                   33600019
         CLI   D0(POINT),IARROW        NO,ARROW                         33800019
         BE    QUALFTS1           YES                                   34000019
         NI    FL133,NEXPRPQF     NO, SET OFF FLAG FOR POINTER          34200019
* QUALIFICA                                                             34400019
INFIXTST CLI   D0(POINT),IPLUS         PLUS SIGN                        34600019
         BL    CLOSETST           NO                                    34800019
         CLI   D0(POINT),IEXPON        EXPONENT                         35000019
         BNH   PRFXTST1           NO                                    35200019
CLOSETST TM    D0(POINT),RPE           CLOSING PAREN INEXPR. FND        35400019
         BO    RPEFND             YES, GO TO RPEFND                     35600019
         TM    D0(POINT),RPS           CLOSING       IN SUB CR  FND     35800019
         BO    RPAFND             YES, GO TO RRAFND                     36000019
         LTR   ARRF,ARRF               INSIDE EXPRESSION?               36200019
         BZ    ERRTST                  YES                              36400019
         CLI   D0(POINT),ICOMMA        NO,INSIDE SUBSCRIPT              36600019
         BE    STARTST                                                  36800019
ERRTST   CLI   D0(POINT),ILIT          NO, LITERAL                      37000019
         BNH   EXPERR8            OPERATOR MISSING AFTER XXX            37200019
EXPERR1  ST    POINT,INSERT1      PREPARE FOR INSERT IN MSG             37400019
         BALR  RET,ERR            GO TO ERRORROUTINE                    37600019
         DC    H'89'              USE MESSAGE 89                        37800019
*INVALID OPERATOR XXX                                                   38000019
         B     RESTART2                                                 38200019
CONSTFND CLI   D1(POINT),ISUB          CONSTANT FOUND, ISUB             38400019
         BNE   CONSTFD1           NO                                    38600019
         TM    COMFLAG2,ISUBFLAG  ISUB FLAGGED                          38800019
         BO    CONSTFD2           YES                                   39000019
         TM    FL133,EISUBFL      ISUB IN EXPRESSION FOUND              39200019
         BO    CONSTFD1           YES                                   39400019
         LA    R1,ISUBW                PREP FOR INSERT OF 'ISUB'        39600019
         ST    R1,INSERT1                                               39800019
         BALR  RET,ERR            GO TO ERRORROUTINE                    40000019
         DC    H'40'              USE MESSAGE 40                        40200019
* ISUB NOT PERMITTED IN THIS CONTEXT                                    40400019
         BR    R8                                                       40600019
CONSTFD2 NI    COMFLAG2,NISUBFL   SET OFF ISUB FLAG                     40800019
         OI    FL133,EISUBFL      FLAG ISUB IN EXPRESSION               41000019
CONSTFD1 BALR  RET,NXTOK          GET NEXT TOKEN                        41200019
         CR    POINT,EXPREND      END OF EXPRESSOIN                     41400019
         BCR   ELV,R8                                                   41600019
         B     INFIXTST           NO                                    41800019
QUALFTS1 TM    FL133,EXPRPQFL     POINTER QUALIFICATION FOUND           42000019
         BO    QUALFTS2           YES                                   42200019
         OI    FL133,EXPRPQFL     NO, FLAG PTR QUALIFICATION            42400019
         B     QUALFTST                                                 42600019
QUALFTS2 BALR  RET,ERR            GO TO ERROROUTINE                     42800019
         DC    H'86'              USE MESSAGE 86                        43000019
* POINTER QUALIFIER FOLLOWS POINTER QUALIFIER OR SUBSCRIPT              43200019
QUALFTST BALR  RET,NXTOK          GET NEXT TOKEN                        43400019
         CR    POINT,EXPREND      END OF EXPRESSION                     43600019
         BNL   EXPERR6            IDENTIFIER MISSING AFTER XXX          43800019
         CLI   D0(POINT),IIDENT        NO, IDENTIFIER                   44000019
         BE    IDENTFND           YES                                   44200019
EXPERR6  BCTR  POINT,R0                SUBTRACT 1 FROM POINT            44400019
         ST    POINT,INSERT1      PREPARE FOR INSERT                    44600019
         BALR  RET,ERR            GO TO ERRORROUTINE                    44800019
         DC    H'90'              USE MESSAGE 90                        45000019
*IDENTIFIER MISSING AFTER XXX                                           45200019
         BR    R4                                                       45400019
RPEFND   IC    ARRF,D0(POINT)          INSERT                           45600019
         N     ARRF,M1            ZERO REGISTER                         45800019
         MVI   D0(POINT),ICLOSE        RESET TOKEN TYPE BYTE            46000019
         BALR  RET,NXTOK          GET NEXT TOKEN                        46200019
         CR    POINT,EXPREND      END OF EXPRESSION                     46400019
         BCR   ELV,R8                                                   46600019
         B     INFIXTST           NO, GO TO INFIXTST                    46800019
RPAFND   IC    ARRF,D0(POINT)          INSETR TOKEN TYPE BYTE  ARR      47000019
         N     ARRF,M1            ZERO REGISTER                         47200019
         MVI   D0(POINT),ICLOSE        RESET TOKEN TYPE BYTE            47400019
         BALR  RET,NXTOK          GET NEXT TOKEN                        47600019
         CR    POINT,EXPREND      END OF EXPRESSION                     47800019
         BCR   ELV,R8                                                   48000019
         OI    FL133,EXPRPQFL     POINTER QUALIFICATION FLAG            48200019
         B     POINTTST                                                 48400019
EXPERR7  BCTR  POINT,R0                SUBTRACT 1 FROM POINT            48600019
         ST    POINT,INSERT1           PREPARE FOR INSERT               48800019
         BALR  RET,ERR            GO TO ERRORROUTINE                    49000019
         DC    H'87'              USE MESSAGE 87                        49200019
*OPERAND MISSING AFTER XXX                                              49400019
         BR    R8                                                       49600019
EXPERR8  CLI   D1(POINT),KREFER        REFER OPTION FOUND               49800019
         LA    R1,ERREFER              LOAD ADDRESS OF ERROR EXIT       50000019
         BNE   ERR8               NO, ERROR                             50200019
         TM    COMFLAG2,REFERFL   YES, REFER ALLOWED                    50400019
         BZ    ERR8               NO, ERROR                             50600019
         TM    FL24,STRUFLAG      INSIDE A STRUCTURE                    50800019
         BCR   EIG,R1                  IF EQUAL,ERROR                   51000019
         TM    FL24+3,BASEDFL     IS THE STRUCTURE BASED                51200019
         BCR   EIG,R1                  IF EQUAL,ERROR                   51400019
         TM    COMFLAG1,DIMREFFL                                        51600019
         BZ    REF1                                                     51800019
         L     R15,LEVCOUNT            LEVEL IN STRUCTURE               52000019
         IC    R15,DIMLVTAB+D1(R15)    GET CORRESPONDING DIMENSION      52200019
         BCTR  R15,R1                  ERROR IF NOT IN FIRST DIMENSION  52400019
REF1     L     POINT,EXPBEG            POINT TO BEGINNING OF EXPRESS    52600019
         B     REF21                                                    52800019
REF2     BALR  RET,NXTOK               GET NEXT TOKEN                   53000019
REF21    CLI   D0(POINT),IIDENT        IDENTIFIER                       53200019
         BCR   SEV,R1                  IF NOT IDENTIFIER ,ERROR         53400019
         BALR  RET,NXTOK               GET NEXT TOKEN                   53600019
         CLI   D0(POINT),IDOT          POINT                            53800019
         BE    REF2                                                     54000019
         CLI   D0(POINT),IARROW        ARROW                            54200019
         BE    REF2                                                     54400019
         CLC   D0(L2,POINT),IDNTREF    KEYWORD REFER                    54600019
         BCR   SEV,R1                  IF NOT , ERROR                   54800019
         BALR  RET,NXTOK          GET NEXT TOKEN                        55000019
         CLI   D0(POINT),IOPEN         LEFT PARENTHESIS                 55200019
         BCR   SEV,R1                  IF NOT EQUAL,ERROR               55400019
NEXTA    BALR  RET,NXTOK          GET NEXT TOKEN                        55600019
         CLI   D0(POINT),IIDENT        IDENTIFIER                       55800019
         BCR   SEV,R1                  IF NOT EQUAL,ERROR               56000019
         BALR  RET,NXTOK          GET NEXT TOKEN                        56200019
         CLI   D0(POINT),ICLOSE        RIGHT PARENTHESIS                56400019
         BCR   SEV,R1                  IF NOT EQUAL,ERROR               56600019
         BALR  RET,NXTOK          GET NEXT TOKEN                        56800019
         CLI   D0(POINT),ICOLON        COLON FOUND                      57000019
         BCR   EIG,R1                  IF YES , ERROR                   57200019
         CR    POINT,EXPREND      END OF EXPRESSION                     57400019
         BCR   EIG,R8                                                   57600019
ERREFER  BALR  RET,ERR            GO TO ERRORROUTINE                    57800019
         DC    H'36'              USE MESSAGE 36                        58000019
* ILLEGAL USE OR INCORRECT FORMAT OF REFER OPTION                       58200019
REF5     L     POINT,EXPBEG            LOAD BEGINNING OF EXPRESSION     58400019
REF4     BALR  RET,NXTOK               GET NEXT TOKEN                   58600019
         CR    POINT,EXPREND                                            58800019
         BCR   EIG,R8                  IF END OF EXPR GO BACK           59000019
         TM    D0(POINT),X'20'         TEST IF MODIFIED RIGHT PAREN     59200019
         BZ    REF4                                                     59400019
         MVI   D0(POINT),ICLOSE        REMODIFY RIGHT PAREN             59600019
         B     REF4                                                     59800019
ERR8     ST    POINT,INSERT1      PREPARE FOR INSERT                    60000019
         BALR  RET,ERR            GO TO ERROROUTINE                     60200019
         DC    H'91'              USE MESSAGE 91                        60400019
*OPERATOR MISSING BEFORE XXX                                            60600019
         BR    R4                                                       60800019
EXPERR9  BCTR  POINT,R0                SUBTRACT 1 FROM POINT            61000019
         ST    POINT,INSERT1      PREPARE FOR INSERT                    61200019
         BALR  RET,ERR            GO TO ERRORROUTINE                    61400019
         DC    H'87'              USE MESSAGE 87                        61600019
* OPERAND MISSING AFTER XXX                                             61800019
         BR    R4                                                       62000019
EXPERR10 BCTR  POINT,R0                SUBTRACT 1 FROM POINT            62200019
         ST    POINT,INSERT1      PREPARE FOR INSERT                    62400019
         BALR  RET,ERR            GO TO ERRORROUTINE                    62600019
         DC    H'87'              USE MESSAGE 87                        62800019
* OPERAND MISSING AFTER XXX                                             63000019
         LA    POINT,D1(POINT)         UPDATE TOKEN POINTER             63200019
         B     STARTST                                                  63400019
EXPERR11 CLI   D1(POINT),ILIT          LITERAL                          63600019
         BNH   EXPERR2            IDENT OR CON FOUND, ERROR             63800019
         CLI   D1(POINT),IOPEN         LEFT PARENTHESIS                 64000019
         BE    EXPERR2            YES, ERROR                            64200019
         BALR  RET,ERR            GO TO ERRORROUTINE                    64400019
         DC    H'23'              USE MESSAGE 23                        64600019
* SOLITARY DECIMAL POINT FOUND IN OPERAND POSITION                      64800019
RESTART  BALR  RET,NXTOK          GET NEXT TOKEN                        65000019
         CR    POINT,EXPREND      END OF EXPRESSION                     65200019
         BCR   EIG,R8                                                   65400019
RESTART2 TM    D0(POINT),RPE           RIGHT PAREN OF EXPR FND?         65600019
         BO    RPEFND             YES, GO TO RPEFND                     65800019
         TM    D0(POINT),RPS           RIGHT PAREN OF SUBSCR. FND       66000019
         BO    RPAFND             YES,                                  66200019
         CLI   D0(POINT),ICOMMA        COMMA                            66400019
         BCR   SEV,R4                                                   66600019
RESTART1 LTR   ARRF,ARRF          SUBSCRIPTED VAR. FOUND                66800019
         BCR   EIG,R4                                                   67000019
         B     STARTST                                                  67200019
         DS    0F                                                       67400019
M1       DC    X'00000001'                                              67600019
ISUBW    DC    X'000007'          TOKEN 'ISUB' FOR INSERT               67800019
         DC    C'ISUB'                                                  68000019
IDNTREF  DC    AL2(256*IIDENT+KREFER)  FIRST TWO BYTES IN REFER         68200019
L2       EQU   2                       LENGTH 2                         68400019
REFERPTR EQU   X'20'                   POINTER FOUND IN REFER OPT       68600019
K1       EQU   1                                                        68800019
INTEG    EQU   X'01'                                                    69000019
RPE      EQU   X'22'              SYNBOLER FOR RIGHT PAREN IN EXPR.     69200019
RPS      EQU   X'24'              SYNBOL FOR RIGHT PAREN IN SUBSCR.     69400019
ISUB     EQU   X'0D'                                                    69600019
CLOSEW   EQU   X'03'                                                    69800019
EISUBFL  EQU   B'01000000'        ISUB IN EXPRESSION                    70200019
EXPRPQFL EQU   B'10000000'        POINTER QUALIFICATION                 70600019
NEXPRPQF EQU   B'01111111'                                              70800019
STRUFLAG EQU   B'10000000'        INSIDE STRUCTURE                      71400019
BASEDFL  EQU   B'00000100'        BASED STRUCTURE FOUND                 71600019
R0       EQU   0                                                        71800019
R8       EQU   8                                                        72000019
R15      EQU   15                                                       72200019
EIG      EQU   8                                                        72400019
SEV      EQU   7                                                        72600019
FOU      EQU   4                                                        72800019
ELV      EQU   11                                                       73000019
NXTOK    EQU   11                                                       73200019
EXPREND  EQU   9                  END OF EXPRESSION                     73400019
RET2     EQU   7                                                        73500019
RET      EQU   14                                                       73600019
OLDTOKEN EQU   6                  SAVE REGISTER FOR TOKEN PTF           73800019
ARRF     EQU   5                                                        74000019
R4       EQU   4                                                        74200019
ERR      EQU   3                  POINTER TO ERRORROUTINE               74400019
POINT    EQU    2                                                       74600019
R1       EQU   1                                                        74800019
R14      EQU   14                                                       75000019
R12      EQU   12                                                       75200019
D12      EQU   12                                                       75400019
R13      EQU   13                                                       75600019
D4       EQU   4                                                        75800019
R10      EQU   10                                                       76000019
D8       EQU   8                                                        76200019
D0       EQU   0                                                        76400019
D1       EQU   1                                                        76600019
D2       EQU   2                                                        76800019
X00      EQU   X'00'                                                    77000019
X20      EQU   X'20'                                                    77200019
         IKMDATA                                                        77400019
         ORG   SLASK2                                                   77600019
FL24     DS    1D                                                       77800019
         DS    16F                                                      78000019
DIMLVTAB DS    32F                                                      78200019
         DS    8F                                                       78400019
DIMCOUNT DS    1F                                                       78600019
LEVCOUNT DS    1F                                                       78800019
         ORG   SLASK4                                                   79000019
FL133    DS    1C                                                       79200019
         END                                                            79400019
