LRDE     TITLE 'IHKABLRD - LINE ANALYSIS READ'                          00050020
IHKABLRD CSECT                                                          00100020
* 001800-014400,019200-019800,033600-040800,120000,236010-236080  19018 00650020
* 478800,604200,654600,666000-666600,749400-770400                19018 00700020
* 778800-779400,781200,787200-823800,872400                       19018 00750020
* 747600-748800                                                  A24717 00800020
* 643800-644400                                                  A27468 00850020
* 157200,515400,636000,862800-863400                               000D 00900020
* 445800-446400,970800                                             000D 00950020
* 473400-542400,862200-866400,933000-934200                      A26537 01000020
*                                                                A32862 01050020
*                                                                A32875 01100020
*A596100-596400,747200                                           A35897 01110020
*D474500                                                         A40161 01120020
*A474100-474700,480500,730600-730800                             A40161 01130020
*C302500,653000                                                  A40166 01135020
*A678000                                                          M6294 01140020
*D747200                                                          M6294 01145020
*A114100-114300                                                  A37771 01147021
*A620900-622100                                                  A47439 01157021
*D621000-622000                                                  A47439 01167021
*C593500,611000                                                  A47967 01177021
*A198100-198200,324800-325100,559600-559900,681100-681200        A48402 01187021
*D325000                                                         A48402 01197021
*A235700                                                         A51866 01207021
*                                                                     * 01217021
* STATUS - CHANGE LEVEL 1, RELEASE 21.6                               * 01227021
*                                                                     * 01237021
*FUNCTION/OPERATION - THE BASIC FUNCTIONS OF THIS ROUTINE ARE         * 01250020
*   1. READ THE INPUT DATA USING BTAM                                 * 01300020
*   2. RECOGNIZE THE DATA LINK CONTROL CHARACTERS ON THE INPUT RECORD * 01350020
*   3. SEQUENCE CHECK THE JECL COMMANDS - RJSTART, CONTINUE, LOGON,   * 01400020
*      LOGOFF AND RJEND                                               * 01450020
*   4. CHECK FOR THE INVALID JECL COMMANDS - RJENDF AND RJENDC        * 01500020
*   5. WRITE THE JECL AND JCL RECORDS ON SYS1.SYSJOBQE USING THE OS   * 01550020
*      QUEUE MANAGER                                                  * 01600020
*   6. START A NEW QUEUE ENTRY FOR JECL AND JCL WHEN A JED CARD OR A  * 01650020
*      JOB CARD NOT PRECEDED BY A JED IS FOUND                        * 01700020
*   7. WRITE SYSIN DATA ON A SEQUENTIAL DISK DATA SET WHICH WAS JUST  * 01750020
*      ALLOCATED                                                      * 01800020
*   8. SUPPORT SYSTEM MANAGEMENT FACILITIES (SMF) BY COUNTING     19018 01850020
*      RECORDS SPOOLED TO SYSIN DATA SETS. THE COUNT IS PLACED    19018 01900020
*      IN A SPACE PARAMETER ON THE THIRD GENERATED SYSIN CARD.    19018 01950020
*                                                                     * 02000020
*ENTRY POINTS -                                                       * 02050020
*        IHKABLRD - TO PROCESS THE BTAM INPUT.                        * 02100020
*   CALLING SEQUENCE - LA    1,PARAM                                  * 02150020
*                      LA    13,SAVE AREA FOR THIS LINE               * 02200020
*                      L     15,=V(IHKABLRD)                          * 02250020
*                      BR    15                                       * 02300020
*   WHERE PARAM IS A WORD CONTAINING THE LCB ADDRESS                  * 02350020
*                                                                     * 02400020
*        IHKABCON - TO ENABLE IHKABALC TO GET THE BASE FOR A DSECT OF * 02450020
*   THIS CONSTANT AREA.                                               * 02500020
*                                                                     * 02550020
*        IHKABXCN - TO ENABLE IHKABXMT TO GET THE BASE FOR A DSECT 000A 02600020
*   OF THE CONSTANT AREA.                                          000A 02650020
*                                                                  000A 02700020
*        IHKABRET - TO WRITE A RECORD (JCL) AND RETURN TO LST     19018 02750020
*                                                                 19018 02800020
*INPUT - BTAM PUTS 80-CHARACTER CARD IMAGES AND THE DATA LINK CONTROL * 02850020
*   CHARACTERS IN THE INPUT BUFFER ON EACH READ.  THE READ INITIAL IS * 02900020
*   DONE BY THE LINE SCHEDULER PRIOR TO CALLING THIS ROUTINE WHICH    * 02950020
*   ISSUES THE READ CONTINUE'S.                                       * 03000020
*                                                                     * 03050020
*OUTPUT - THE JECL AND JCL IS ON SYS1.SYSJOBQE, TWO 80-CHARACTER CARD * 03100020
*   IMAGES PER EACH 176-BYTE RECORD.  THE SYSIN DATA SET(S) ARE ON    * 03150020
*   DISK, BLOCKED ACCORDING TO THE BLOCK SIZE SPECIFIED ON THE DD CARD* 03200020
*   IN THE RJE PROCEDURE.  THE MAXIMUM BLOCK SIZE IS 400 BYTES.  IF NO* 03250020
*   BLOCK SIZE WAS SPECIFIED, UNBLOCKED (80-BYTE) RECORDS ARE WRITTEN * 03300020
*                                                                     * 03350020
*EXTERNAL ROUTINES -                                                  * 03400020
*        IHKAADSP - DISPATCHER          TO ALLOW PROCESSING OF OTHER  * 03450020
*                                       LINES WHILE WAITING FOR I/O TO* 03500020
*                                       COMPLETE.                     * 03550020
*        IHKABALC - SYSIN ALLOCATION    TO ALLOCATE A SYSIN DATA SET. * 03600020
*        IHKABXMT - ERR MSG TRANSMITTER TO TRANSMIT AN ERROR       000A 03650020
*                                       MESSAGE TO THE LINE        000A 03700020
*        IHKCAVER - COMMAND INTERPRETER TO CHECK THE SYNTAX OF AN     * 03750020
*                                       RJSTART OR LOGON CARD.        * 03800020
*        IHKCBLDM - BUILD MESSAGE       TO GET A POINTER TO AN ERROR  * 03850020
*                                       MESSAGE.                      * 03900020
*        IHKCCSCN - SCAN                TO FIND THE START OF FIELDS ON* 03950020
*                                       JECL AND JCL CARDS.           * 04000020
*        IHKCDFMR - FAST TABLE MANAGER  TO WRITE UPDATED FAST TABLE   * 04050020
*                                       ENTRY ON DISK.                * 04100020
*        IHKCDSCH - FAST TABLE SEARCH   TO SEARCH FAST TABLE FOR      * 04150020
*                                       AVAILABLE ENTRY OR DUPLICATE  * 04200020
*                                       JOB NAME                      * 04250020
*        IHKCHUPK - UNPACK ROUTINE      TO EXPAND RECORDS FROM     000D 04300020
*                                       A COMPRESSING TERMINAL     000D 04350020
*        IHKQMNGR -                     TO INTERFACE WITH IEFQMSSS 000A 04400020
*                                       AND IEFQDELE               000A 04450020
*        BSAM                           TO WRITE THE SYSIN DATA SETS  * 04500020
*                                       ON DISK.                      * 04550020
*        BTAM                           TO READ INPUT FROM THE LINE   * 04600020
*                                                                     * 04650020
*EXITS - NORMAL - RETURN IS MADE TO THE LINE SCHEDULER WITH A      000A 04700020
*   RETURN CODE IN REGISTER 15 AS FOLLOWS                          000A 04750020
*    0 - RETURN FOR NON-SWITCHED LINE OR AFTER RJENDC OR RJENDF    000A 04800020
*    8 - ERROR MESSAGE WAS SENT ON SWITCHED LINE SO LINE SCHEDULER 000A 04850020
*        MUST SEND EOT                                             000A 04900020
*   12 - LINE SCHEDULER SHOULD CALL IHKABLWR BECAUSE AN OUT-OF-    000A 04950020
*        SPACE CONDITION OCCURRED                                  000A 05000020
*   20 - RJENDC OR RJENDF NOT QUEUED BECAUSE SYS1.SYSJOBQE IS      000A 05050020
*        TEMPORARILY OUT OF SPACE                                  000A 05100020
*   24 - NORMAL RETURN FOR SWITCHED LINE                           000A 05150020
*   28 - RETURN TO SEND EOT TO 2780 ON SWITCHED LINE BECAUSE       000A 05200020
*        RJSTART OR LOGON IS REQUIRED.                             000A 05250020
*                                                                     * 05300020
*EXITS - ERROR - THE LINE ERROR RECOVERY PROCEDURES ARE THOSE SUPPLIED* 05350020
*   BY OS/BTAM/BSCS.  IF AN ERROR OCCURS ON THE LINE, IT IS RETRIED BY* 05400020
*   BTAM SIX TIMES.  IF THE ERROR IS NOT RECOVERABLE, BTAM POSTS A BAD* 05450020
*   RETURN CODE (41).  IF LINE ANALYSIS READ FINDS A BAD RETURN CODE, * 05500020
*   IT EXECUTES THE FOLLOWING PROCEDURE.  THE USER EXIT ROUTINE (OR A * 05550020
*   DUMMY ROUTINE) IS CALLED WITH A POINTER TO THE LINE DECB IN       * 05600020
*   REGISTER 1.  THEN IN THE TERMINAL DIRECTORY ENTRY, THE ENQUEUE    * 05650020
*   JOBS AND ENQUEUE MESSAGES BITS ARE TURNED OFF, THE DEQUEUE     000A 05700020
*   NOTHING BIT IS TURNED ON, THE RJSTART AND LOGON SWITCHES ARE   000A 05750020
*   TURNED OFF.  AN RJENDF CARD WITH THE LINE ERROR MESSAGE ON IT  000A 05800020
*   IS GENERATED AND PUT ON THE JECL AND JCL QUEUE ENTRY.  THE     000A 05850020
*   QUEUE ENTRY IS ENQUEUED FOR THE READER, AND RETURN IS MADE TO  000A 05900020
*   THE LINE SCHEDULER.                                            000A 05950020
*                                                                     * 06000020
*   IHKABXMT IS CALLED IF ANY OF THE FOLLOWING ERRORS OCCURS       000A 06050020
*   1. RJSTART OR LOGON IS MISSING OR INVALID,                        * 06100020
*   2. RJENDF OR RJENDC IS SUBMITTED FROM THE TERMINAL,               * 06150020
*   3. A JOB CARD IS MISSING OR THE JOB NAME IS MISSING, TOO LONG, OR * 06200020
*      DUPLICATE,                                                     * 06250020
*   4. THE FAST TABLE IS FULL,                                        * 06300020
*   5. THE CENTRAL IS OUT OF SPACE FOR SYSIN OR ON SYS1.SYSJOBQE,  000A 06350020
*   6. THE SYSIN DATA SET IS TOO LONG, OR                          000A 06400020
*   7. A DISK I/O ERROR OCCURS.                                    000A 06450020
*                                                                     * 06500020
*   AN ERROR MESSAGE IS SENT TO THE TERMINAL, AND FOR CASES 4, 5   000A 06550020
*   AND 7 A MESSAGE IS ALSO SENT TO THE CENTRAL OPERATOR.  IF THE  000A 06600020
*   WRITE TO THE TERMINAL IS UNSUCCESSFUL, AN RJENDF CARD WITH THE 000A 06650020
*   ERROR MESSAGE IS GENERATED, IF POSSIBLE, AND PUT ON THE JECL   000A 06700020
*   AND JCL QUEUE ENTRY.  THE QUEUE ENTRY IS ENQUEUED FOR THE      000A 06750020
*   READER, AND RETURN IS MADE TO THE LINE SCHEDULER.              000A 06800020
*                                                                     * 06850020
*   ABNORMAL CENTRAL CLOSEDOWN IS INITIATED WHEN AN UNRECOVERABLE  000B 06900020
*   ERROR IS ENCOUNTERED.                                          000B 06950020
*                                                                  000B 07000020
*TABLES/WORK AREAS - EACH LINE HAS A LINE CONTROL BLOCK (LCB),        * 07050020
*   SUB-TASK CONTROL BLOCK (STCB), 452-BYTE DISK BUFFER, 18-WORD      * 07100020
*   REGISTER SAVE AREA, A DECB AND DCB FOR LINE I/O, AND A DECB AND   * 07150020
*   DCB FOR DISK I/O ASSOCIATED WITH IT.  WHILE THE LINE IS SENDING   * 07200020
*   INPUT, A BTAM BUFFER IS ALSO USED.  THE FAST TABLE, THE TERMINAL  * 07250020
*   DIRECTORY AND THE AVT TABLE OF ADDRESSES ARE REFERENCED.          * 07300020
*                                                                     * 07350020
*ATTRIBUTES - IT IS REENTRANT.                                        * 07400020
*                                                                     * 07450020
*NOTES - THE OPERATION OF THIS SUBROUTINE DEPENDS UPON AN INTERNAL    * 07500020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 07550020
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED SO* 07600020
*   THAT REDEFINITION OF CHARACTER-TYPE CONSTANTS, BY REASSEMBLY, WILL* 07650020
*   RESULT IN A CORRECT MODULE FOR THE NEW DEFINITION EXCEPT FOR THE  * 07700020
*   CODE WHICH VERIFIES THAT THE JOB NAME STARTS WITH AN ALPHABETIC   * 07750020
*   CHARACTER.  THE CODE ASSUMES THAT ALL SPECIAL CHARACTERS HAVE A   * 07800020
*   LOWER HEX CODE THAN THE LETTERS, THAT THE NUMBERS HAVE A HIGHER   * 07850020
*   HEX CODE, THAT THE HEX CODE FOR A IS THE LOWEST ALPHABETIC, THAT  * 07900020
*   THE HEX CODE FOR Z IS THE HIGHEST ALPHABETIC, AND THAT THE NUMERIC* 07950020
*   FIELDS OF THE LETTERS RUN FROM 1 THROUGH 9 EXCEPT FOR E1.  THE    * 08000020
*   LAST 5 EQUATES ARE USED FOR THIS CODE.                            * 08050020
*   THE CODE WHICH INSERTS THE SYSIN COUNT INTO THE SPACE PARA-   19018 08100020
*   METER OF THE THIRD GENERATED SYSIN CARD ASSUMES THAT THE      19018 08150020
*   HEXADECIMAL REPRESENTATION OF THE NUMBERS IS 'F0' THROUGH     19018 08200020
*   'F9'. THE EQUATE FOR THE ZONE IS LABELLED 'LRDZONE'.          19018 08250020
*     NOTE                                                       A26537 08300020
*    THE SUB ROUTINE STARTING  STARTING FROM SEQUENCE NUMBER     A26537 08350020
*  473290-542400 HAS BEEN REARRANGED SUCH THAT IT IS A SUB-      A26537 08400020
*  ROUTINE WITH ITS OWN BASE REG . THIS WAS DONE TO MAKE ROOM    A26537 08450020
*  IN THIS MODULE FOR FUTURE FIXES AND MODIFICATIONS .           A26537 08500020
*  ALSO CHARACTER CONSTANTS AND OTHER DEPENDENT CODE WAS EITHER  A26537 08550020
*  DELETED  FROM THE MAIN ROUTINE AND MOVED OR DUPLICATED        A26537 08600020
*  IN THE SUB ROUTINE                                            A26537 08650020
         SPACE 2                                                        08700020
R0       EQU   0                                                        08750020
R1       EQU   1                   QUEUE MANAGER PARAM. AREA POINTER    08800020
R2       EQU   2                   LCB POINTER                          08850020
R3       EQU   3                   BUFFER POINTER                       08900020
R4       EQU   4                   0 OR 80 FOR JECL-JCL BUFFER POINTER  08950020
*                                  END OF BUFFER FOR DISK BUFFER PTR    09000020
R5       EQU   5                   BTAM BUFFER POINTER                  09050020
R6       EQU   6                   END OF BTAM BUFFER POINTER           09100020
R7       EQU   7                   DECB POINTER (LINE OR DISK)          09150020
R8       EQU   8                   DCB POINTER FOR DISK                 09200020
R9       EQU   9                   VARIABLE                             09250020
R10      EQU   10                  VARIABLE                             09300020
R11      EQU   11                  TERMINAL DIRECTORY POINTER           09350020
R12      EQU   12                  BASE REGISTER                        09400020
R13      EQU   13                  SAVE AREA POINTER                    09450020
R14      EQU   14                  RETURN REGISTER                      09500020
R15      EQU   15                  ENTRY POINT REGISTER                 09550020
         SPACE                                                          09600020
         EXTRN IHKCDFLN,IHKCDSOC,IHKCDTDR,IHKCACOM                      09650020
         ENTRY IHKABCON            FOR DSECT IN IHKABALC                09700020
         ENTRY IHKABRET                                           19018 09750020
         ENTRY IHKABXCN            FOR DSECT IN IHKABXMT           000A 09800020
         SPACE                                                          09850020
         BALR  R12,0               INITIALIZE BASE REGISTER             09900020
         USING *,R12                                                    09950020
         USING IOPARAMS,R1                                              10000020
         USING LCBDSECT,R2                                              10050020
         USING IECTDECB,R7                                              10100020
         USING IHADCB,R8                                                10150020
         USING TDIREC,R11                                               10200020
         USING LRDCVT,R14                                               10250020
         USING LRDQMRES,R15                                             10300020
         B     LRDSKIP                                                  10350020
         DC    C'IHKABLRD'                                              10400020
LRDSKIP  DS    0H                                                       10450020
*                                                                       10500020
*********************************************************************** 10550020
*                                                                       10600020
*                   INITIALIZE REGISTERS AND ASSIGN QUEUE ENTRY         10650020
*                                                                       10700020
*********************************************************************** 10750020
*                                                                       10800020
          L     R2,0(R1)           GET LCB ADDRESS                      10850020
         NI    LCBNSWFL,LCBSWOFF   TURN OFF LCB SWITCHES                10900020
         L     R7,LCBDDECB         GET DISK DECB POINTER FROM LCB       10950020
         L     R8,DECDCBAD         GET ADDRESS FOR DCB                  11000020
         MVC   0(88,R8),LRDSYSDD   MOVE MODEL DCB FOR SYSIN DATA SETS   11050020
         L     R7,LCBLDECB         GET LINE DECB POINTER FROM LCB       11100020
         BAL   R10,LRDBUFPT        GET POINTERS TO START AND END   000A 11150020
*                                  OF BTAM BUFFER                  000A 11200020
         ST    R5,LCBWORKA         SAVE ADDRESS OF BTAM INPUT BUFFER    11250020
         L     R11,LCBTDIR         GET TERMINAL DIRECTORY PTR           11300020
         LA    R10,LRDCHECK        SET RETURN ADDRESS                   11350020
         SR    R4,R4               SET BUFFER INDEX TO 0         A27468 11400020
         L     R4,LCBBUFER    CLEAR THE QMPCL SO THAT IF THE JOB A37771 11410021
         XC    LRDXMT32(LRDXMT4,R4),LRDXMT32(R4) Q IS FULL AND   A37771 11420021
*                             THE MSG CAN'T BE SENT - NO ABEND   A37771 11430021
         SPACE 1                                                        11450020
         CLI   LCBTYPLN,LCBMULPT   CHECK FOR MULTI-POINT LINE      000A 11500020
         BNE   LRDASGST            BRANCH IF NOT MULTI-POINT LINE  000A 11550020
         LA    R5,1(R5)            STEP PAST POLLING CHARACTER     000A 11600020
LRDASGST L     R14,CVTPTR          GET ADDRESS OF CVT                   11650020
         L     R15,CVTJOB          GET ADDRESS OF Q MGR RESIDENT AREA   11700020
         LH    R9,QMNOTM           GET NUMBER OF AVAIL. LOGICAL TRACKS  11750020
         SH    R9,QMTBT            SUBTRACT NUMBER OF LOGICAL TRACKS    11800020
*                                  RESERVED FOR INITIATORS              11850020
         MH    R9,QMLPT            MULTIPLY BY NUMBER OF RECORDS/TRACK  11900020
*                                  R9 NOW HAS NUMBER OF AVAIL. RECORDS  11950020
         CH    R9,LRD200           CHECK THRESHOLD OF 200 RECORDS  000A 12000020
         BNH   LRDQMSPA            BRANCH IF NOT MORE THAN 200 RECORDS  12050020
LRDASGS2 L     R1,LCBBUFER         GET QUEUE MANAGER PARAM. AREA ADDR.  12100020
         MVC   QMNAM(8),LRDTASK    PUT RJETASK AS JOBNAME               12150020
         XC    QMFLT(23),QMFLT     CLEAR NEXT SIX WORDS OF QMPA         12200020
         LA    R9,QMPCA            GET ADDRESS OF EXTERNAL AREA         12250020
         ST    R9,QMPCL            STORE IN LAST WORD OF QMPA           12300020
         MVI   QMPOP,QMASGS        STORE ASSIGN/START CODE              12350020
         MVI   QMTPY,LRDSYSIN      SET FOR SYSIN QUEUE                  12400020
         MVI   QMPCM,LRD2TTRS      TO ASSIGN TWO TTR'S                  12450020
         BAL   R9,LRDQMNGR         ASSIGN/START                    000A 12500020
         BC    7,LRDQMIOA          BRANCH IF I/O ERROR                  12550020
         L     R1,LCBBUFER         GET QUEUE MANAGER PARAM. AREA ADDR.  12600020
         L     R9,QMPEX            GET TTR FOR SECOND WRITE             12650020
         ST    R9,QMCHN            STORE AS CHAINING FROM FIRST RECORD  12700020
         L     R9,QMPCA            GET TTR FOR FIRST WRITE              12750020
         ST    R9,QMPEX            STORE AS TTR FOR FIRST WRITE         12800020
         LA    R3,QMCHN            GET JECL AND JCL BUFFER ADDRESS      12850020
         SR    R4,R4               SET BUFFER INDEX TO 0           000D 12900020
         MVI   LRDCDIND(R3),LRDNOCRD INDICATE NO CARDS IN BUFFER        12950020
         NI    LCBNSWFL,LCBNQOFF   INDICATE NO CARDS TO ENQUEUE    000A 13000020
         BR    10                                                       13050020
         SPACE 1                                                        13100020
LRDCHECK BAL   R9,LRDCKEOT         CHECK DATA LINK CONTROL CHARACTERS   13150020
         LTR   R11,R11             TEST FOR TERMINAL DIRECTORY POINTER  13200020
         BZ    LRDRJNEC            BRANCH IF RJSTART REQUIRED           13250020
         TM    TDIRSWCH,TDIRRJSN   ALLOW FOR MULTIPOINT            000C 13300020
         BZ    LRDRJNEC            IF NOT RJSTARTED, NEEDS TO BE   000C 13350020
LRDCKTYP DS    0H                                                  000C 13400020
         BAL   R14,LRDUNPK         UNPACK RECORD INTO OUTPUT BUFFER000C 13450020
         CLC   0(3,R3),LRDDOTS     CHECK FOR JECL                  000C 13500020
         BNE   LRDJCLCK            BRANCH IF NOT A JECL CARD            13550020
*                                                                       13600020
*********************************************************************** 13650020
*                                                                       13700020
*                   CHECK FOR CERTAIN JECL COMMANDS                     13750020
*                                                                       13800020
*********************************************************************** 13850020
*                                                                       13900020
         NI    TDIRSWCH+2,TDIRJCLF TURN OFF JCL SWITCH                  13950020
         TM    TDIRSWCH,TDIRDDAN   TEST DD* SWITCH - SYSIN DATA         14000020
         BC    14,LRDRJS           BRANCH IF DD * SWITCH NOT ON         14050020
         BAL   R10,LRDSYEND        BRANCH IF DD * SWITCH ON             14100020
         B     LRDCKTYP            GO PROCESS RECORD               000C 14150020
LRDRJS   LA    R9,LRDCONTI         SET RETURN ADDRESS                   14200020
         SPACE 1                                                        14250020
LRDRJSTR LA    R10,3(R3)           GET STARTING ADDRESS FOR SCAN   000C 14300020
         ST    R10,LRDSADDR        STORE IN PARAMETER LIST              14350020
         LA    R10,70(R3)          GET STOPPING ADDRESS FOR SCAN   000C 14400020
         ST    R10,LRDSSTOP        STORE IN PARAMETER LIST              14450020
         XC    LRDSCAN(4),LRDSCAN      SET UP PARM FOR SCAN        000C 14500020
         LA    R1,LRDSCAN          GET ADDRESS OF PARAMETER LIST        14550020
         L     R15,LRDCCSCN        GET ADDRESS OF SCAN ROUTINE          14600020
         BALR  R14,R15             CALL SCAN TO FIND FIRST NON-BLANK    14650020
         LTR   R15,R15             TEST FOR NON-BLANK CHARACTER FOUND   14700020
         BZ    LRDNULL             BRANCH IF NO OPERATION ON CARD       14750020
         CLC   0(8,R1),LRDRJSTT    CHECK FOR RJSTART CARD          000C 14800020
         BE    LRDRJSRT            BRANCH IF FOUND                      14850020
         BR    R9                  BRANCH TO LRDCONTI OR LRDRJMIS       14900020
         SPACE 1                                                        14950020
LRDCONTI CLC   0(9,R1),LRDCONT     CHECK FOR CONTINUE CARD              15000020
         BE    LRDCONTU            BRANCH IF FOUND                      15050020
         CLC   0(6,R1),LRDLOGON    CHECK FOR LOGON CARD                 15100020
         BE    LRDLOGN             BRANCH IF FOUND                      15150020
         CLC   0(4,R1),LRDJED      CHECK FOR JED CARD                   15200020
         BE    LRDJEDCD            BRANCH IF FOUND                      15250020
         CLC   0(7,R1),LRDLOGOF    CHECK FOR LOGOFF CARD                15300020
         BE    LRDLOGF             BRANCH IF FOUND                      15350020
         CLC   0(6,R1),LRDRJEND    CHECK FOR RJEND CARD                 15400020
         BE    LRDRJND             BRANCH IF FOUND                      15450020
         CLC   0(7,R1),LRDRJNDF    CHECK FOR RJENDF CARD                15500020
         BE    LRDRJF              BRANCH IF FOUND - ERROR              15550020
         CLC   0(7,R1),LRDRJNDC    CHECK FOR RJENDC                     15600020
         BE    LRDRJF              BRANCH IF FOUND - ERROR              15650020
LRDSEQCK TM    TDIRSWCH,TDIRRJLG   TEST FOR RJSTART AND LOGON FOUND     15700020
         BO    LRDJCLBF            BRANCH IF BOTH FOUND ALREADY         15750020
         SPACE                                                          15800020
*                                                                       15850020
*********************************************************************** 15900020
*                                                                       15950020
*                   HANDLE ERRORS ON INPUT DATA                         16000020
*                                                                       16050020
*********************************************************************** 16100020
*                                                                       16150020
*                                  MISSING RJSTART OR LOGON             16200020
* 335400                                                         A28204 16250020
LRDRJMIS LA    R0,LRDXMT52         GET INPUT CODE FOR IHKABXMT     000A 16300020
         B     LRDCLXMT            CALL IHKABXMT TO ABORT INPUT    000A 16350020
         SPACE 2                                                   000A 16400020
*                                  INVALID RJSTART OR LOGON - SEND 000A 16450020
*                                  COMMAND INTERPRETER'S MESSAGE   000A 16500020
LRDRJINV LA    R0,LRDXMT44         GET INPUT CODE FOR IHKABXMT     000A 16550020
LRDRJLG  STM   R0,R1,LCBPARM1      STORE INPUT CODE AND            000A 16600020
*                                  POINTER TO MESSAGE              000A 16650020
         B     LRDXMTCL            CALL IHKABXMT TO SEND MESSAGE   000A 16700020
         SPACE 2                                                        16750020
*                                  RJENDF OR RJENDC IS AN INAVLID  000A 16800020
*                                  OPERATION                       000A 16850020
LRDRJF   TM    TDIRSWCH+2,TDIRMCHN TEST FOR 2780 OR CPU            000A 16900020
         BZ    LRD2780             BRANCH IF 2780 TO GET NEXT CARD 000A 16950020
         MVI   LRDBOFS+1,LRDOFS20  PUT MESSAGE OFFSET AS PARAMETER 000A 17000020
         LA    R0,LRDXMT48         GET INPUT CODE FOR IHKABXMT     000A 17050020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 17100020
         SPACE 2                                                        17150020
LRDNULL  LTR   R11,R11             IS THERE A TERMINAL DIRECTORY PTR    17200020
         BZ    LRDRJMIS            BRANCH IF NO POINTER - ERROR         17250020
         B     LRDSEQCK                                                 17300020
         SPACE 2                                                        17350020
LRDRJNEC DS    0H                                                  000C 17400020
         LA    R3,4(R3)            STEP PAST INFO                  000C 17450020
         MVC   0(80,R3),0(R5)      MOVE CARD TO OUTPUT BUFFER      000C 17500020
         CLC   0(3,R3),LRDDOTS     CHECK FOR JECL                  000C 17550020
         BNE   LRDRJMIS            BRANCH IF NOT JECL - MISSING RJSTART 17600020
         BAL   R9,LRDRJSTR         TO TEST FOR RJSTART CARD             17650020
         B     LRDRJMIS            RJSTART MISSING - ERROR              17700020
         SPACE 2                                                        17750020
*                                                                       17800020
*********************************************************************** 17850020
*                                                                       17900020
*                   PROCESS JECL                                        17950020
*                                                                       18000020
*********************************************************************** 18050020
*                                                                       18100020
*                   RJSTART CARD                                        18150020
*                                                                       18200020
LRDRJSRT ST    R1,LRDCDOPR         STORE ADDRESS OF OPERATION AS PARAM  18250020
         MVI   LRDCDOPR,LRDRJSCD   STORE RJSTART CODE AS PARAMETER      18300020
         CLI   LCBTYPLN,LCBPTPT    CHECK FOR POINT-TO-POINT LINE   000A 18350020
         BNE   LRDRJSR             BRANCH IF NOT POINT-TO-POINT    000A 18400020
         SR    R11,R11             CLEAR TDIR POINTER SO IHKCAVER  000A 18450020
*                                  WILL SEARCH TDIR FOR TERMID     000A 18500020
LRDRJSR  EQU   *                                                   000A 18550020
         LA    R10,LRDRJSTA                                             18600020
         SPACE 1                                                        18650020
LRDCALCI ST    R3,LRDCDBEG         STORE START OF CARD IMAGE       000C 18700020
         L     R9,LCBTDIR          SAVE TDIR POINTER               000C 18750020
         ST    R11,LRDCTDIR        STORE TERMINAL DIRECTORY POINTER     18800020
         LA    R1,LRDCDOPR         GET ADDRESS OF PARAMETER LIST        18850020
         O     R1,LRDBLDM          SET HIGH ORDER BIT TO INDICATE THAT  18900020
*                                  THE CALL IS FROM COLLECTOR-EMITTER   18950020
         L     R15,LRDCAINT        GET ADDRESS OF COMMAND INTERPRETER   19000020
         BALR  R14,R15             CHECK RJSTART SYNTAX AND TERMINAL ID 19050020
         LTR   R15,R15             TEST RETURN CODE                     19100020
         BR    R10                                                      19150020
         SPACE 1                                                        19200020
LRDRJSTA DS    0H                                                  000C 19250020
         L     R11,LRDCTDIR        GET TERMINAL DIRECTORY POINTER       19300020
         BZ    LRDRJSOK            RJSTART IS VALID                000C 19350020
         LTR   R11,R9              RESTORE TDIR POINTER            000C 19400020
         BZ    LRDRJINV            ERROR IF FIRST RJSTART BAD      000C 19450020
         TM    TDIRSWCH,TDIRRJSN   SEE IF ALREADY RJSTARTED        000C 19500020
         BZ    LRDRJINV            NO, SEND ERROR MESSAGE          000C 19550020
LRDRJSOK DS    0H                                                  000C 19600020
         CLC   LCBTDIR+1(3),LRDCTDIR+1  SAME TERMID AS ALREADY ON? 1657 19650020
         BE    LRDRJSGD            YES, LET HIM ON               A21657 19700020
         CLC   LCBTDIR+1(3),LRDBLDM+1   TERMINAL ON LINE YET     A21657 19750020
         BNE   LRDRJSBD            NO, SEND ERROR MESSAGE          1657 19800020
LRDRJTST TM    TDIRSWCH+1,TDIRDABN IS ANOTHR LINE RJENDFING      A48402 19810021
         BO    LRDRJWT        THIS TERMINAL - BRANCH IF SO       A48402 19820021
         L     R9,LRDLCBAD         GET FIRST LCB ADDR.           A21657 19850020
         LM    R14,R15,LRDLINES    GET LCB COUNT AND LENGTH ADDR A21657 19900020
         LH    R14,0(R14)          GET LCB COUNT                 A21657 19950020
         LA    R2,0(R2)            INSURE HIGH ORDER BYTE ZERO   A21657 20000020
LRDLLOOP DS    0H                                                A21657 20050020
         CLC   LRDCTDIR+1(3),13(R9) IS THIS TERMID ON LINE       A21657 20100020
         BE    LRDRJSBD            YES, CAN'T GET ON HERE        A21657 20150020
         AH    R9,0(R15)           STEP TO NEXT LCB              A21657 20200020
         BCT   R14,LRDLLOOP        TRY NEXT LCB                  A21657 20250020
LRDRJSGD DS    0H                                                  1657 20300020
         ST    R11,LCBTDIR         STORE IN LCB                         20350020
         OI    TDIRSWCH+2,TDIRSWCN  PRESET FOR SWITCHED            1657 20400020
         CLI   LCBTYPLN,LCBSWTCH   CHECK FOR SWITCHED LINE         000A 20450020
         BE    LRDSETSW            BRANCH IF SWITCHED LINE         000A 20500020
         NI    TDIRSWCH+2,TDIRSWCF SET FOR NON-SWITCHED LINE       000A 20550020
LRDSETSW DS    0H                                                  1657 20600020
         OI    TDIRSWCH,TDIRRJSN   TURN ON RJSTART SWITCH               20650020
         ST    R2,TDIRLCB          STORE LCB ADDR IN TERMINAL DIRECTORY 20700020
         B     LRDJCLBF            BRANCH TO MOVE CARD TO JECL BUFFER   20750020
         SPACE 2                                                        20800020
LRDRJST2 C     R2,TDIRLCB          COMPARE CURRENT LCB WITH LCB IN      20850020
*                                  TERMINAL DIRECTORY ENTRY ALREADY     20900020
         BE    LRDRJSGD            BRANCH IF THE SAME              1657 20950020
*                                  TWO LINES ARE USING THE SAME TERMID  21000020
LRDRJSBD DS    0H                                                  1657 21050020
         LA    R0,LRDXMT40         GET INPUT CODE FOR IHKABXMT     000A 21100020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 21150020
         SPACE 2                                                        21200020
*                                                                       21250020
*                   CONTINUE CARD                                       21300020
*                                                                       21350020
LRDCONTU TM    TDIRSWCH,TDIRRJSN   TEST FOR RJSTART FOUND ALREADY       21400020
         BO    LRDJCLBF            BRANCH IF FOUND                      21450020
         B     LRDRJMIS            BRANCH ON ERROR                      21500020
         SPACE 2                                                        21550020
*                                                                       21600020
*                   LOGON CARD                                          21650020
*                                                                       21700020
LRDLOGN  TM    TDIRSWCH,TDIRRJSN   TEST FOR RJSTART FOUND ALREADY       21750020
         BZ    LRDRJMIS            BRANCH IF NO PRECEDING RJSTART-ERROR 21800020
         ST    R1,LRDCDOPR         STORE ADDRESS OF OPERATION AS PARAM  21850020
         MVI   LRDCDOPR,LRDLGNCD   STORE LOGON CODE AS PARAMETER        21900020
         BAL   R10,LRDCALCI                                             21950020
         BC    7,LRDRJINV          BRANCH IF ERROR RETURN CODE     000A 22000020
         OI    TDIRSWCH,TDIRLGNN   SET LOGON SWITCH ON                  22050020
         B     LRDJCLBF            BRANCH TO MOVE CARD TO JECL BUFFER   22100020
         SPACE 2                                                        22150020
*                                                                       22200020
*                   JED CARD                                            22250020
*                                                                       22300020
LRDJEDCD TM    TDIRSWCH,TDIRRJLG   TEST FOR RJSTART AND LOGON FOUND     22350020
         BC    14,LRDRJMIS         BRANCH IF ONE OR BOTH MISSING   000A 22400020
         OI    TDIRSWCH+1,TDIRJEDN TURN ON JED SWITCH                   22450020
         TM    LCBNSWFL,LCBNQBIT   TEST FOR CARDS TO BE ENQUEUED   000A 22500020
         BZ    LRDJCLBF            BR IF NO CARDS IN QUEUE ENTRY   000A 22550020
         BAL   R10,LRDWRJCL        WRITE LAST RECORD AND ENQUEUE        22600020
         BAL   R10,LRDASGST        ASSIGN/START NEW QUEUE ENTRY         22650020
         B     LRDJCLBF                                                 22700020
         SPACE 2                                                        22750020
*                                                                       22800020
*                   LOGOFF CARD                                         22850020
*                                                                       22900020
LRDLOGF  TM    TDIRSWCH,TDIRRJLG   TEST FOR RJSTART AND LOGON FOUND     22950020
         BC    14,LRDRJMIS         BRANCH IF ONE OR BOTH MISSING   000A 23000020
         NI    TDIRSWCH,TDIRLGNF   TURN OFF LOGON SWITCH                23050020
         B     LRDJCLBF            BRANCH TO MOVE CARD TO JECL BUFFER   23100020
         SPACE 2                                                        23150020
*                                                                       23200020
*                   RJEND CARD                                          23250020
*                                                                       23300020
LRDRJND  TM    TDIRSWCH,TDIRRJSN   TEST FOR RJSTART FOUND ALREADY       23350020
         BZ    LRDRJMIS            BRANCH IF NO PRECEDING RJSTART-ERROR 23400020
         NI    TDIRSWCH,TDIRRJLF   TURN OFF RJSTART AND LOGON SWITCHES  23450020
         NI    TDIRSTAT,TDIRNQJF   TURN OFF ENQUEUE JOBS BIT IN TDIR    23500020
         OI    TDIRSTAT,TDIRDQMN   SET DEQUEUE MESSAGES ONLY BIT        23550020
         MVC   3(6,R3),LRDRJEND  PUT 'RJEND' IN COL. 4           A51866 23570021
         B     RJENDR             GO DO SPECIAL RJEND PROCESS    A26537 23600020
         SPACE 1                                                        23650020
*                                                                       23700020
*********************************************************************** 23750020
*                                                                       23800020
*                   PUT CARD IN JECL AND JCL BUFFER                     23850020
*                   WRITE BUFFER IF FULL                                23900020
*                                                                       23950020
*********************************************************************** 24000020
*                                                                       24050020
LRDJCLBF DS    0H                                                  000C 24100020
         L     R1,LCBBUFER         GET QMPA ADDRESS                000C 24150020
         LA    R3,QMCHN            GET DISK BUFFER ADDRESS         000C 24200020
         OI    LCBNSWFL,LCBNQBIT   INDICATE CARDS TO BE ENQUEUED   000A 24250020
         X     R4,LRDDEC80         SET JCL BUFFER INDEX TO 80 OR 0      24300020
         STC   R4,LRDCDIND(R3)     TO INDICATE 1 OR 2 CARDS IN BUFFER   24350020
*                                  (80 MEANS 1 CARD, 0 MEANS 2 CARDS)   24400020
         BZ    LRDFULL             BUFFER FULL                     000C 24450020
         TM    TDIRSWCH,TDIRRJSN   RJEND RECEIVED?                 000C 24500020
         BO    LRDNOTFL            NO, CONTINUE SAME BUFFER        000C 24550020
         X     R4,LRDDEC80         INDICATE NEXT MOVE TO BEG.      000C 24600020
LRDFULL  DS    0H                                                  000C 24650020
         LA    R10,LRDNOTFL                                             24700020
         SPACE 1                                                        24750020
LRDWRASG LR    R9,R11              GET ADDR OF TERMINAL DIRECTORY ENTRY 24800020
         S     R9,LRDCDTDR         SUBTRACT START OF TERM DIREC ENTRIES 24850020
         ST    R9,LRDRELTD(R3)     STORE RELATIVE DISPLACEMENT WITHIN   24900020
*                                  TERMINAL DIRECTORY                   24950020
         L     R1,LCBBUFER         GET QUEUE MANAGER PARAM. AREA ADDR.  25000020
         MVI   QMPOP,QMWRTA        STORE WRITE AND ASSIGN CODE          25050020
         MVI   QMPCM,LRDWR1AS      WRITE ONE RECORD AND ASSIGN ONE TTR  25100020
         ST    R3,QMPCA            STORE ADDR OF BUFFER TO BE WRITTEN   25150020
         BAL   R9,LRDQMNGR         WRITE AND ASSIGN                000A 25200020
         BC    7,LRDQMIOE          BRANCH IF I/O ERROR                  25250020
         L     R1,LCBBUFER         GET QUEUE MANAGER PARAM. AREA ADDR.  25300020
         L     R9,QMCHN            GET TTR FOR NEXT WRITE               25350020
         ST    R9,QMPEX            PUT TTR IN PROPER PARAMETER WORD     25400020
         L     R9,QMPCA            GET TTR JUST ASSIGNED                25450020
         ST    R9,QMCHN            SAVE IN CHAINING WORD OF BUFFER      25500020
         MVI   LRDCDIND(R3),LRDNOCRD INDICATE NO CARDS IN BUFFER        25550020
         BR    R10                                                      25600020
         SPACE 2                                                   000A 25650020
LRDQMNGR ST    R1,LCBPARM1         STORE QMPA ADDRESS FOR IHKQMNGR 000A 25700020
         L     R7,LCBDDECB         GET ADDRESS OF DISK DECB        000A 25750020
         XC    DECSDECB(4),DECSDECB CLEAR ECB                      000A 25800020
         ST    R7,LCBPARM2         STORE ECB ADDRESS FOR IHKQMNGR  000A 25850020
         LA    R0,LCBPARM1         GET ADDRESS OF PARAMETER LIST   000A 25900020
         LA    R1,LCBQMECB         GET ADDRESS OF ECB FOR IHKQMNGR 000A 25950020
         POST  (1),(0)             POST THE ECB FOR IHKQMNGR       000A 26000020
         LR    R1,R7               GET ADDRESS OF DISK ECB         000A 26050020
         L     R15,LRDAADSP        GET ADDRESS OF DISPATCHER       000A 26100020
         BALR  R14,R15             HAS MULTIPLE WAIT               000A 26150020
         CLI   DECSDECB+3,LRDZERO  CHECK RETURN CODE               000A 26200020
         BR    R9                                                  000A 26250020
         SPACE 2                                                   000A 26300020
LRDNTFUL LA    R3,80(R3)           STEP DISK BUFFER PTR TO NEXT CARD    26350020
*                                                                       26400020
*********************************************************************** 26450020
*                                                                       26500020
*                   TEST IF BTAM BUFFER EMPTY                           26550020
*                   ISSUE READ CONTINUE IF EMPTY                        26600020
*                                                                       26650020
*********************************************************************** 26700020
*                                                                       26750020
LRDNOTFL TM    TDIRSWCH+2,TDIRMCHN TEST FOR CPU OR 2780                 26800020
         BZ    LRD2780             BRANCH IF 2780                       26850020
         TM    TDIRRB,TDIRPNRN     DID WE UNPACK THIS RECORD?      000C 26900020
         BNO   LRDSTP80            NO, STEP BUFFER POINTER BY 80   000C 26950020
         SR    R15,R15             CLEAR REG. FOR IC               000C 27000020
         IC    R15,0(R5)           GET LENGTH OF RECORD            000C 27050020
         AR    R5,R15              STEP TO NEXT RECORD             000C 27100020
         B     LRDBTAM             CHECK FOR END OF BUFFER         000C 27150020
LRDSTP80 LA    R5,80(R5)           STEP BTAM BUFFER PTR TO NEXT CARD    27200020
LRDBTAM  OI    TDIRRB,TDIRUNPN     RECORDS WILL BE UNPACKEDIF NEC. 000C 27250020
         CR    R5,R6               CHECK FOR END OF BTAM BUFFER    000C 27300020
         BL    LRDNXTCD            BRANCH IF NOT END OF BUFFER          27350020
LRDREAD  LA    R9,LRDNXTCD         SET RETURN ADDRESS                   27400020
         SPACE 1                                                        27450020
         L     R7,LCBLDECB         GET LINE DECB ADDRESS           000A 27500020
LRDRDTT  L     R5,DECAREA          GET ADDRESS OF BTAM BUFFER      000A 27550020
         SR    R0,R0               CLEAR FIRST WORD OF BTAM BUFFER 000A 27600020
         ST    R0,0(0,R5)          TO PERMIT CHECKING FOR CARD JAM 000A 27650020
         READ  (7),TT,MF=E         READ FROM LINE                  000A 27700020
         BAL   R10,LRDSIO          CHECK FOR SUCCESSFUL READ       000A 27750020
         BNE   LRDBDRD             BRANCH IF NOT SUCCESSFUL             27800020
LRDSRDTP BAL   R10,LRDBUFPT        GET POINTERS TO START AND END   000A 27850020
*                                  OF BTAM BUFFER                  000A 27900020
LRDCKEOT CLI   0(R5),LRDEOTCR      CHECK FOR EOT                        27950020
         BE    LRDEOT              BRANCH IF FOUND                      28000020
         CLC   0(2,R5),LRDSOHD     CHECK FOR SOH D                 000A 28050020
         BE    LRDDISCN            BRANCH IF DISCONTINUED INPUT         28100020
         CLC   0(2,R5),LRDSOHR     CHECK FOR SOH R                 000A 28150020
         BE    LRDRESUM            BRANCH IF RESUMING NORMAL INPUT      28200020
         CLC   0(2,R5),LRDDLSTX    CHECK FOR DLE STX                    28250020
         BNE   LRDBDRD             BRANCH IF NOT FOUND                  28300020
         LA    R5,2(R5)            STEP POINTER PAST DATA LINK CHARS.   28350020
         BR    R9                                                       28400020
         SPACE 1                                                        28450020
LRDNXTCD DS    0H                                                A28204 28500020
         LTR   R11,R11             TDIR POINTER?                 A28204 28550020
         BZ    LRDRJNEC            NO, NEED RJSTART              A28204 28600020
         TM    TDIRSWCH,TDIRDDDN   TEST DD DATA SWITCH           A28204 28650020
         BZ    LRDCKTYP            BRANCH IF NOT PROCESSING DD DATA     28700020
         BAL   R14,LRDUNPK         UNPACK RECORD INTO OUTPUT BUFFER000C 28750020
         B     LRDMVSYS            BRANCH IF PROCESSING DD DATA SYSIN   28800020
         SPACE 2                                                        28850020
LRDBUFPT L     R5,DECAREA          GET ADDRESS OF BTAM BUFFER      000A 28900020
         LH    R6,DECLNGTH         GET LENGTH OF BUFFER            000A 28950020
         LH    R0,DECCOUNT         GET NUMBER OF UNFILLED BYTES    000A 29000020
         SR    R6,R0               GET NO. OF BYTES OF DATA IN BUF 000A 29050020
         BZ    LRDBDRD             BRANCH TO RJENDF IF NO DATA     000A 29100020
         AR    R6,R5               SET REG 6 TO END OF BUFFER      000A 29150020
         BCTR  R6,0                SUBTRACT NO. DATA LINK CHARS.   000C 29200020
         LR    R15,R8           SAVE DISK DCB POINTER              000D 29250020
         L     R8,DECDCBAD        GET LINE DCB POINTER             000D 29300020
         TM    DCBXMODE,ITBCHAR   TEST IF ITB MODE SET             000D 29350020
         BZ    LRDITB             NO DONT DECREMENT COUNT          000D 29400020
         BCTR  R6,R0              YES DECREMENT COUNT BY ONE       000D 29450020
LRDITB   EQU   *                                                   000D 29500020
         LR    R8,R15             RESTORE DISK DCB POINTER         000D 29550020
         BR    R10                                                 000A 29600020
         SPACE 2                                                   000A 29650020
*                                                                       29700020
*********************************************************************** 29750020
*                                                                       29800020
*                   EOT RECEIVED - CLEAN UP AND CALL LINE SCHEDULER     29850020
*                                                                       29900020
*********************************************************************** 29950020
*                                                                       30000020
LRDEOT   LTR   R11,R11             CHECK FOR TERMINAL DIRECTORY POINTER 30050020
         BZ    LRDDELET            BRANCH IF NO POINTER                 30100020
         TM    TDIRSWCH+1,TDIRDIPN TEST DISCONTINUED INPUT SWITCH       30150020
         BO    LRDDISCT            BRANCH IF ON                         30200020
LRD1130  TM    TDIRSWCH,TDIRSYSN       TEST DD DATA AND DD* SW   A40166 30250020
         BZ    LRDWRTJC            BRANCH IF BOTH SWITCHES OFF          30300020
         BAL   R10,LRDSYEND        WRITE LAST SYSIN RECORD AND CLOSE    30350020
LRDWRTJC LA    R10,LRDRELBF        SET RETURN ADDRESS                   30400020
         SPACE 1                                                        30450020
LRDWRJCL LR    R9,R11              GET ADDR OF TERMINAL DIRECTORY ENTRY 30500020
         S     R9,LRDCDTDR         SUBTRACT START OF TERM DIREC ENTRIES 30550020
         LR    R8,R3               SAVE ADDRESS OF CARD IMAGE      000C 30600020
         L     R1,LCBBUFER         GET QUEUE MANAGER PARAM AREA ADD000C 30650020
         LA    R3,QMCHN            GET ADDRESS OF OUTPUT BUFFER    000C 30700020
         ST    R9,LRDRELTD(R3)     STORE RELATIVE DISPLACEMENT WITHIN   30750020
*                                  TERMINAL DIRECTORY                   30800020
         MVI   QMPOP,QMWREN        STORE ENQUEUE CODE                   30850020
         MVI   QMPNC,LRDWR1        TO WRITE ONE RECORD                  30900020
         TM    LRDCDIND(R3),LRD1CRD TEST FOR NUMBER OF CARDS IN BUFFER  30950020
         BC    9,LRD1CARD          BRANCH IF ONE OR TWO CARDS IN BUFFER 31000020
         MVI   LRDCDIND(R3),LRDNOCRD INDICATE NO CARDS IN BUFFER        31050020
LRD1CARD SR    R9,R9                                                    31100020
         ST    R9,0(R3)            SET CHAINING TTR TO ZERO             31150020
         ST    R3,QMPCA            STORE ADDR OF BUFFER TO BE WRITTEN   31200020
         BAL   R9,LRDQMNGR         WRITE AND ENQUEUE               000A 31250020
         BC    7,LRDQMIOE          BRANCH IF I/O ERROR                  31300020
         MVC   4(80,R3),0(R8)      MOVE CARD TO BEGINNING OF BUFFER000C 31350020
         L     R8,DECDCBAD         RESTORE DCB POINTER             000C 31400020
         L     R1,LCBBUFER         GET ADDRESS OF JOB NAME              31450020
         CLC   QMNAM(8),LRDTASK    CHECK FOR JOBNAME                    31500020
         BE    LRDNOFST            BRANCH IF ONLY JECL ON QUEUE ENTRY   31550020
         L     R15,LRDCDSCH        GET ENTRY POINT OF FAST TABLE SEARCH 31600020
         BALR  R14,R15             FIND FAST TABLE ENTRY JUST ASSIGNED  31650020
*                                  UPON RETURN REGISTER 1 CONTAINS THE  31700020
*                                  ADDRESS OF FAST TABLE ENTRY          31750020
         L     R15,LRDCDFMR        GET ENTRY POINT OF FAST TABLE MGR    31800020
         BALR  R14,R15             WRITE FAST TABLE ENTRY ON DISK       31850020
LRDNOFST BR    R10                                                      31900020
         SPACE 1                                                        31950020
LRDRELBF L     R7,LCBLDECB         GET ADDRESS OF LINE DECB             32000020
         L     R8,DECDCBAD         GET ADDRESS OF LINE DCB              32050020
         L     R5,LCBWORKA         GET ADDRESS OF BTAM BUFFER           32100020
         SR    R9,R9               STORE ZERO IN FIRST WORD OF BTAM     32150020
         ST    R9,0(R5)            BUFFER TO INDICATE NO CHAINING       32200020
         RELBUF (8),(5)            RELEASE BTAM'S BUFFER                32250020
         LTR   R11,R11             CHECK FOR TERMINAL DIRECTORY POINTER 32300020
         BZ    LRDCKSWL            BRANCH IF NONE                       32350020
         NI    TDIRSWCH,TDIRDARF   TURN OFF DD DATA, DD *, AND          32400020
*                                  NO RJENDF SWITCHES                   32450020
         NI    TDIRSWCH+1,TDIRJDD  TURN OFF JED, DISABLE, AND    A48402 32480021
TDIRJDD  EQU   X'F8'          DISCONTINUED INPUT SWITCHES        A48402 32510021
         NI    TDIRSWCH+2,TDIRJCLF TURN OFF JCL SWITCH                  32550020
         TM    12(R11),TDIRRJN     TEST RJEND RECEIVED           A26537 32600020
         BO    LRDWAIT            YES RJEND PROCEES GO WAIT      A26537 32650020
LRDRTL   EQU   *                                                 A26537 32700020
         TM    LCBNSWFL,LCBLST28   TEST FOR RETURN 28 TO IHKABLST  000A 32750020
         BO    LRDLST28            BRANCH IF SO                    000A 32800020
         TM    LCBNSWFL,LCBSTRJE   TEST FOR RETURN 0 TO IHKABLST        32850020
         BO    LRDRTLST            BRANCH IF SO                         32900020
         TM    TDIRSWCH+2,TDIRLWRN TEST BRANCH TO LWR SWITCH            32950020
         BO    LRDBRLWR            BRANCH IF ON                         33000020
         CLI   LCBTYPLN,LCBSWTCH   TEST FOR SWITCHED LINE               33050020
         BE    LRDRTOUT            BRANCH IF SWITCHED LINE              33100020
LRDRTLST EQU   *                                                        33150020
         TM     LCBFLG,LCB3977    TEST FOR 3977 MODEM              000D 33200020
         BZ    LRDRTSLT           NO DO NORMAL RETURN              000D 33250020
         LA    R15,LRDSTSLT       SET RETURN CODE TO LST FOR LOPEN 000D 33300020
         B     LRDRETLS           FUNCTION                         000D 33350020
LRDRTSLT LA    R15,LRDCDLST       SET RETURN (NORMAL) FOR IHKABLST 000D 33400020
LRDRETLS L     R14,LRDABLST        GET RETURN ADDRESS OF LINE SCHEDULER 33450020
         BR    R14                 RETURN TO LINE SCHEDULER             33500020
         SPACE 2                                                        33550020
LRDLST28 LA    R15,LRDSW278        RETURN TO SEND EOT TO 2780 ON   000A 33600020
*                                  SWITCHED LINE                   000A 33650020
         B     LRDRETLS            RETURN TO LINE SCHEDULER        000A 33700020
         SPACE 2                                                   000A 33750020
LRDCKSWL CLI   LCBTYPLN,LCBSWTCH   CHECK FOR SWITCHED LINE              33800020
         BNE   LRDRTLST            TO SET RETURN CODE FOR IHKABLST 000A 33850020
         TM    LCBNSWFL,LCBLST28   TEST FOR RETURN 28 TO IHKABLST  000A 33900020
         BO    LRDLST28            BRANCH IF SO                    000A 33950020
         TM    LCBNSWFL,LCBERRSW   TEST ERROR SWITCH                    34000020
         BZ    LRDRTLST            BRANCH IF OFF                        34050020
LRDRTEOT LA    R15,LRDCDEOT        SET RETURN CODE FOR IHKABEOT         34100020
         B     LRDRETLS            RETURN TO LINE SCHEDULER             34150020
         SPACE 2                                                        34200020
LRDRTOUT TM    LCBNSWFL,LCBRJNDF   TEST FOR RJENDF GENERATED       000A 34250020
         BO    LRDRTLST            BRANCH IF SO                    000A 34300020
LRDTSTER TM    LCBNSWFL,LCBERRSW   TEST ERROR SWITCH                    34350020
         BO    LRDRTEOT            BRANCH IF ON                         34400020
         LA    R15,LRDCDSWL        SET RETURN CODE FOR SWITCHED LINE    34450020
         B     LRDRETLS            RETURN TO LINE SCHEDULER             34500020
         SPACE 2                                                        34550020
LRDBRLWR NI    TDIRSWCH+2,TDIRLWRF TURN OFF BRANCH TO LWR SWITCH        34600020
         LA    R15,LRDCDLWR        SET RETURN CODE FOR IHKABLWR         34650020
         B     LRDRETLS            RETURN TO LINE SCHEDULER             34700020
         SPACE 2                                                        34750020
LRD2780  EQU   *                                                        34800020
         LA    R5,84(R5)          STEP BTAM BUFFER PTR TO NEXT CARD     34950020
         B     LRDBTAM                                                  35000020
         SPACE 2                                                        35050020
LRDDISCN LTR   R11,R11             CHECK FOR TDIR POINTER          000A 35100020
         BZ    LRDREAD             BRANCH IF NO TDIR POINTER       000A 35150020
         OI    TDIRSWCH+1,TDIRDIPN TURN ON DISCONTINUED INPUT SW   000A 35200020
         B     LRDREAD             READ MORE INPUT                      35250020
         SPACE 2                                                        35300020
LRDRESUM LTR   R11,R11             CHECK FOR TDIR POINTER          000A 35350020
         BZ    LRDREAD             BRANCH IF NO TDIR POINTER       000A 35400020
         NI    TDIRSWCH+1,TDIRDIPF TURN OFF DISCONTINUED INPUT SW  000A 35450020
         B     LRDREAD                                                  35500020
         SPACE 2                                                        35550020
*                                                                       35600020
*********************************************************************** 35650020
*                                                                       35700020
*                   EOT RECEIVED IN DISCONTINUED INPUT MODE             35750020
*                   ISSUE READ INITIAL FOR NON-SWITCHED LINE            35800020
*                   ISSUE WRITE RESET AND READ CONTINUE FOR SWITCHED LN 35850020
*                                                                       35900020
*********************************************************************** 35950020
*                                                                       36000020
LRDDISCT L     R7,LCBLDECB         GET POINTER TO DECB FOR LINE         36050020
         L     R14,LRDZZAVT        GET BASE OF AVT DSECT                36100020
         USING IHKZZAVT,R14        BASE OF AVT DSECT                    36150020
         L     R15,IHKZZRCS        GET ADDRESS OF WARMSTART AND         36200020
*                                  STOP BITS                            36250020
         TM    0(R15),LRDSTRJE     TEST STOP RJE BIT                    36300020
         BO    LRDSTOP             BRANCH IF ON                         36350020
         CLI   LCBTYPLN,LCBSWTCH   CHECK FOR SWITCHED LINE              36400020
         BE    LRDRDTQ             BRANCH IF SWITCHED LINE              36450020
         CLI   LCBTYPLN,LCBPTPT    CHECK FOR POINT-TO-POINT LINE        36500020
         BE    LRDRDAGN            BRANCH IF POINT-TO-POINT LINE        36550020
         L     R10,LCBDFTRM        GET ADDRESS OF DFTRMLST IN LCB  000A 36600020
         BCTR  R10,0               SUBTRACT ONE TO GET ADDRESS OF  000A 36650020
*                                  ATTRIBUTE CHAR BEFORE DFTRMLST  000A 36700020
         SR    R9,R9               GET ATTRIBUTE CHARACTER IN      000A 36750020
         IC    R9,0(R10)           REGISTER 9                      000A 36800020
         SRL   R9,5                GET LENGTH OF EACH ENTRY IN     000A 36850020
*                                  DFTRMLST                        000A 36900020
         SH    R9,LRD3             IGNORE ENQ AND INDEX AFTER      000A 36950020
*                                  POLLING CHARACTER(S)            000A 37000020
         L     R10,DECENTRY        GET ADDRESS OF CURRENT POLLING  000A 37050020
*                                  ENTRY                           000A 37100020
CHKSYN   EQU   *                                                   000D 37150020
         CLI   0(R10),LRDSYNC     CHECK FOR SYN CHARACTER          000D 37200020
         BNE   OKAY               NO SYN CHARACTER CONTINUE        000D 37250020
         LA    R10,1(R10)         STEP POINTER FORWARD             2756 37300020
         BCTR  R9,0               DECREMENT COUNT TO DELETE SYNS   000D 37350020
         B     CHKSYN             GO CHECK FOR ANOTHER SYN         000D 37400020
OKAY     EQU   *                                                   000D 37450020
         EX    R9,LRDMVSEL         MOVE POLLING CHARACTER(S) TO    000A 37500020
*                                  DFTRMLST IN TERMINAL DIRECTORY  000A 37550020
         LA    R9,TDIRDFTA+3       GET ADDR OF DEFINE TERMINAL LIST000C 37600020
LRDRDAGN READ  (7),TI,,,,(9),MF=E  READ INPUT DATA                      37650020
         BAL   R10,LRDSIO          CHECK FOR SUCCESSFUL READ            37700020
         BNE   LRDCKRST            BRANCH IF UNSUCCESSFUL               37750020
         TM    DECFLAGS,LRDRTPL    CHECK FOR READ ENDED BY RESETPL 000A 37800020
*                                  ON MULTI-POINT LINE             000A 37850020
         BO    LRDDISCT            BRANCH IF SO                    000A 37900020
         BAL   R10,LRDBUFPT        GET POINTER TO START AND END    000A 37950020
*                                  OF BTAM BUFFER                  000A 38000020
         CLI   LCBTYPLN,LCBMULPT   CHECK FOR MULTI-POINT LINE      000A 38050020
         BNE   LRDSTP1             BRANCH IF NOT MULTI-POINT LINE  000A 38100020
         LA    R5,1(R5)            STEP PAST POLLING CHARACTER     000A 38150020
LRDSTP1  BAL   R9,LRDCKEOT         CHECK DATA LINK CONTROL CHARS.  000A 38200020
         B     LRDNXTCD                                            000A 38250020
LRDCKRST CLI   DECSDECB,LRDRSTPL   TEST COMPLETION CODE FOR RESETPL     38300020
*                                  ON POINT-TO-POINT LINE          000A 38350020
         BE    LRDDISCT            BRANCH IF 48 TO READ AGAIN           38400020
         B     LRDBDRD             BRANCH TO RJENDF                     38450020
         SPACE 2                                                        38500020
LRDRDTQ  LA    R9,9                SET LOOP COUNTER FOR READ ENQ        38550020
         OI    DECTYPE,LRDTOFLG    INDICATE NO BTAM ERROR MESSAGE  000A 38600020
*                                  FOR TIME OUT                    000A 38650020
         WRITE (7),TN,MF=E         WRITE RESET AND GET ENQ AS RESPONSE  38700020
         BAL   R10,LRDSIO          CHECK FOR SUCCESSFUL READ            38750020
         BNE   LRDCKTIM            BRANCH IF UNSUCCESSFUL COMPLETION    38800020
         CLI   DECRESPN,LRDENQ     CHECK FOR ENQ IN RESPONSE FIELD      38850020
         BE    LRDREAD             ENQ RECEIVED DO READ CONTINUE   000E 38900020
         CLI   DECRESPN,LRDEOTCR   EOT CHECK                       000E 38950020
         BE    LRDRDTQ             EOT RECEIVED DO WRITE EOT       000E 39000020
         B     LRDBDRD             INVALID CHAR DO RJENDF          000E 39050020
         SPACE 2                                                        39100020
LRDRDTQR EQU   *                                                   000A 39150020
         OI    DECTYPE,LRDTOFLG    INDICATE NO BTAM ERROR MESSAGE  000A 39200020
*                                  FOR TIME OUT                    000A 39250020
         READ  (7),TQ,MF=E         READ ENQ                        000A 39300020
         BAL   R10,LRDSIO          CHECK FOR SUCCESSFUL READ            39350020
         BE    LRDREAD             BRANCH IF SUCCESSFUL COMPLETION      39400020
LRDCKTIM TM    DECSENS0,LRDTMOUT   TEST FOR TIME OUT                    39450020
         BZ    LRDBDRD             BRANCH TO RJENDF IF NOT TIME OUT     39500020
         BCT   R9,LRDRDTQR         REPEAT READ ENQ 7 TIMES              39550020
         B     LRDBDRD             RJENDF AFTER EXECUTING READ ENQ 8    39600020
*                                  TIMES                                39650020
         SPACE 2                                                        39700020
LRDSIO   LTR   R15,R15             TEST FOR SUCCESSFUL START OF READ    39750020
         BC    7,LRDBDRD           BRANCH IF UNSUCCESSFUL START         39800020
         LR    R1,R7               GET ADDRESS OF LINE ECB         000A 39850020
         L     R15,LRDAADSP        GET ADDRESS OF DISPATCHER            39900020
         BALR  R14,R15             HAS MULTIPLE WAIT                    39950020
         NI    DECTYPE,LRDTOOFF    RESET FOR BTAM ERROR MESSAGE    000A 40000020
*                                  FOR TIME OUT                    000A 40050020
         CLI   DECSDECB,LRD7F      TEST FOR SUCCESSFUL COMPLETION       40100020
         BR    R10                                                      40150020
         SPACE 2                                                        40200020
LRDSTOP  OI    LCBNSWFL,LCBSTRJE   INDICATE RETURN OF ZERO              40250020
         NI    TDIRSWCH+1,TDIRDIPF TURN OFF DISCONTINUED INPUT SWITCH   40300020
         XC    0(4,R5),0(R5)       CLEAR EOT STX ENQ FROM BTAM BUF 000A 40350020
         B     LRDEOT              CLEAN UP AND RETURN TO IHKABLST      40400020
         SPACE 2                                                        40450020
LRDJCLCK CLC   0(2,R3),LRDSLASH    CHECK FOR JCL CARD              000C 40500020
         BNE   LRDSYSDT            BRANCH IF NOT JCL - IT IS SYSIN DATA 40550020
*                                                                       40600020
*********************************************************************** 40650020
*                                                                       40700020
*                   PROCESS JCL                                         40750020
*                   CHECK FOR JOB, DD * OR DD DATA CARD                 40800020
*                                                                       40850020
*********************************************************************** 40900020
*                                                                       40950020
         TM    TDIRSWCH,TDIRRJLG   TEST FOR RJSTART AND LOGON FOUND     41000020
         BC    14,LRDRJMIS         BRANCH IF ONE OR BOTH MISSING   000A 41050020
         TM    TDIRSWCH,TDIRDDAN   TEST DD * SWITCH                     41100020
         BC    14,LRDJCL           BRANCH IF DD * SWITCH NOT ON         41150020
         BAL   R10,LRDSYEND        BRANCH IF DD * SWITCH ON             41200020
         B     LRDCKTYP            GO PROCESS RECORD               000C 41250020
LRDJCL   LA    R10,70(R3)          GET STOPPING ADDRESS FOR SCAN   000C 41300020
         CLI   2(R3),ASTER         CHECK FOR //* (COMMENT)       A22260 41350020
ASTER    EQU   C'*'                                              A22260 41400020
         BNE   LRDNOTC            NO,NOT COMMENTD                A26537 41450020
         TM    TDIRSWCH+2,TDIRJCLN ARE WE IN JCL?                A22260 41500020
         BZ    LRDNOJOB            NO, NO JOB CARD ERROR         A22260 41550020
         B     LRDJCLBF            YES, VALID COMMENT CARD       A22260 41600020
LRDNOTC  EQU   *                                                 A26537 41650020
         L     R12,OTHRBASE       SET BASE FOR SUB ROUTINE       A26537 41700020
         BR    R12                AND GO TO IT                   A26537 41750020
LRDDDATA OI    TDIRSWCH,TDIRDDDN   TURN ON DD DATA SWITCH          000C 41800020
*                                                                       41850020
*********************************************************************** 41900020
*                                                                       41950020
*                   DD * OR DD DATA CARD RECEIVED                       42000020
*                   ALLOCATE AND OPEN SYSIN DATA SET                    42050020
*                   MODIFY DD CARD                                      42100020
*                                                                       42150020
*********************************************************************** 42200020
*                                                                       42250020
LRDDDCRD MVC   DCBDDNAM(8),LCBDDNAM PUT DDNAME OF LINE'S SYSIN DD CARD  42300020
*                                   IN DCB                              42350020
         LA    R11,LRDJFCB         SET RETURN ADDRESS                   42400020
         SPACE 1                                                        42450020
         USING LRDCVT,R14          SET BASE OF CVT                 000A 42500020
LRDGTUCB L     R14,CVTPTR          GET ADDRESS OF CVT              000A 42550020
         L     R1,CVTTCBP          GET ADDRESS OF TCB ADDRESSES    000A 42600020
         L     R1,4(R1)            GET ADDRESS OF TCB              000A 42650020
         L     R9,TCBTIO(R1)       GET ADDRESS OF TIOT             000A 42700020
         USING LRDTIOT1,R9         SET BASE FOR TIOT                    42750020
LRDTIOT  SR    R10,R10             CLEAR REGISTER 10                    42800020
         IC    R10,TIOELNGH        GET LENGTH OF THIS DD ENTRY          42850020
         LTR   R10,R10             TEST FOR END OF DD ENTRIES IN TIOT   42900020
         BNZ   LRDON               BRANCH IF NOT END OF DD ENTRIES 000B 42950020
*                                  BAD RJE PROCEDURE               000B 43000020
*                                  SYSIN DD CARD FOR LINE MISSING  000B 43050020
LRDAB987 DS    0H                                                  000B 43100020
         USING IHKZZAVT,R14                                        000B 43150020
         L     R14,LRDZZAVT                                        000B 43200020
         L     R1,IHKZZRCS                                         000B 43250020
         OI    0(R1),LRD17ERR                                      000B 43300020
LRD17ERR EQU   X'03'                                               000B 43350020
         L     R15,IHKZZASE                                        000B 43400020
         BR    R15                                                 000B 43450020
         USING LRDCVT,R14                                          000B 43500020
LRDON    DS    0H                                                  000B 43550020
         CLC   TIOEDDNM(8),LCBDDNAM COMPARE DDNAME TO SYSIN DATA DDNAME 43600020
         BE    LRDUCB              BRANCH IF EQUAL                      43650020
         AR    R9,R10              STEP TO NEXT DD ENTRY IN TIOT        43700020
         B     LRDTIOT                                                  43750020
LRDUCB   LA    R10,TIOESTTB        GET ADDRESS OF UCB ADDRESS           43800020
         ST    R10,LRDUCBAD        STORE FOR ALLOCATE ROUTINE           43850020
         BR    R11                                                      43900020
         SPACE 1                                                        43950020
LRDJFCB  DS    0H                                                  000C 44000020
         L     R1,LRDSVBLK         GET ADDR OF BLANK AFTER DDNAME  000A 44050020
         MVC   1(18,R1),0(R1)      PUT BLANKS AFTER DDNAME         000A 44100020
LRDALC   ST    R4,LCBPARM1         STORE JECL-JCL BUFFER INDEX     000A 44150020
         L     R14,LRDZZAVT        GET BASE OF AVT DSECT                44200020
         USING IHKZZAVT,R14        SET BASE OF AVT DSECT                44250020
         ST    R2,IHKZZLCB         STORE LCB ADDRESS                    44300020
         LA    R1,IHKZZLCB         GET ADDRESS OF PARAMETER             44350020
         L     R15,LRDABALC        GET ADDR OF SYSIN ALLOCATION ROUTINE 44400020
         BALR  R14,R15                                                  44450020
         L     R11,LCBTDIR         RESET TERMINAL DIRECTORY ADDR   000A 44500020
         B     *+4(R15)            BRANCH ON RETURN CODE                44550020
         B     LRDSETRG            NORMAL RETURN                        44600020
         B     LRDQMIOE            QUEUE MANAGER I/O ERROR              44650020
         B     LRDSYSSP            OUT OF SPACE FOR SYSIN DATA          44700020
         B     LRDIOALC            I/O ERROR ON ALLOCATE                44750020
         SPACE 2                                                        44800020
LRDSETRG EQU   *                                                   000A 44850020
         SR    R3,R3                    START WITH ZERO COUNT     19018 44900020
         STH   R3,LCBSMFCT              STORE IN COUNTER FIELD    19018 44950020
         L     R3,LCBBUFER         INITIALIZE REGISTER 3 TO START OF    45000020
         LA    R3,LRDDSKBF(R3)     DISK BUFFER                          45050020
         LR    R4,R3               SET REGISTER 4 TO END OF             45100020
         AH    R4,DCBBLKSI         DISK BUFFER                          45150020
         B     LRDNOTFL                                                 45200020
         SPACE 2                                                        45250020
LRDSCJCL LA    R1,LRDSCAN          GET ADDRESS OF PARAMETER LIST   000A 45300020
         L     R15,LRDCCSCN        GET ADDRESS OF SCAN ROUTINE     000A 45350020
         BALR  R14,R15             CALL SCAN TO FIND CHARACTER     000A 45400020
         LTR   R15,R15             TEST RETURN CODE                000A 45450020
         BCR   7,R9                IF FOUND, RETURN                1654 45500020
         TM    TDIRSWCH+2,TDIRJCLN IS JCL SWITCH ON                1654 45550020
         BZ    LRDNOJOB            NO, STATEMENT INVALID           1654 45600020
         B     LRDJCLBF            IF ON, IT'S OK                  1654 45650020
         SPACE 2                                                   000A 45700020
LRDDDAST OI    TDIRSWCH,TDIRDDAN   TURN ON DD * SWITCH                  45750020
         B     LRDDDCRD                                                 45800020
         SPACE 2                                                        45850020
LRDJEDSW NI    TDIRSWCH+1,TDIRJEDF TURN OFF JED SWITCH                  45900020
*                                  NO JOB CARD                          45950020
LRDNOJOB LA    R0,LRDXMT8          GET INPUT CODE FOR IHKABXMT     000A 46000020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 46050020
         SPACE 2                                                        46100020
*                                                                       46150020
*********************************************************************** 46200020
*                                                                       46250020
*                   PROCESS JOB CARD                                    46300020
*                   START NEW QUEUE ENTRY IF NO JED BEFORE JOB          46350020
*                   GET FAST TABLE ENTRY FOR JOB                        46400020
*                                                                       46450020
*********************************************************************** 46500020
*                                                                       46550020
LRDJOBCD OI    TDIRSWCH+2,TDIRJCLN TURN ON JCL SWITCH                   46600020
         TM    TDIRSWCH+1,TDIRJEDN TEST JED SWITCH                      46650020
         BO    LRDJEDFD            BRANCH IF ON                         46700020
         TM    LCBNSWFL,LCBNQBIT   TEST FOR CARDS TO BE ENQUEUED   000A 46750020
         BZ    LRDJEDFD            BR IF NO CARDS IN QUEUE ENTRY   000A 46800020
         BAL   R10,LRDWRJCL        WRITE LAST RECORD AND ENQUEUE        46850020
         BAL   R10,LRDASGST        ASSIGN/START NEW QUEUE ENTRY         46900020
         LA    R3,4(R3)            SET POINTER TO BUFFER           000C 46950020
LRDJEDFD NI    TDIRSWCH+1,TDIRJEDF TURN OFF JED SWITCH                  47000020
         L     R1,LCBBUFER         GET QUEUE MANAGER PARAM AREA ADDRESS 47050020
         LH    R9,LCBCHARS         GET NO. OF CHARS. IN JOBNAME  A22268 47100020
         STH   R9,LRDJOBCH(R1)     SAVE NO. OF CHARS. IN JOBNAME   000A 47150020
         LTR   R9,R9               TEST FOR NO JOB NAME                 47200020
         BZ    LRDINVNM            BRANCH IF NO JOB NAME                47250020
         CH    R9,LRD8             TEST FOR JOBNAME TOO LONG       000A 47300020
         BH    LRDINVNM            BRANCH IF MORE THAN 8 CHARACTERS     47350020
*                                  VERIFY THAT JOB NAME STARTS WITH AN  47400020
*                                  NATIONAL OR ALPHABETIC CHAR.  A40161 47410020
         CLI   2(R3),LRD$          IS 1ST CHAR OF JOBNAME A $    A40161 47420020
         BE    GOODNAME            YES, THE JOBNAME IS VALID     A40161 47430020
         CLI   2(R3),LRD#          IS 1ST CHAR OF JOBNAME A #    A40161 47440020
         BE    GOODNAME            YES, THE JOBNAME IS VALID     A40161 47450020
         CLI   2(R3),LRD@          IS 1ST CHAR OF JOBNAME A @    A40161 47460020
         BE    GOODNAME            YES, THE JOBNAME IS VALID     A40161 47470020
         CLI   2(R3),LRDA          CHECK FOR LOWEST ALPHABETIC     000C 47500020
         BL    LRDINVNM            BRANCH IF NOT ALPHABETIC OR NUMERIC  47550020
         CLI   2(R3),LRDZ          CHECK FOR HIGHEST ALPHABETIC    000C 47600020
         BH    LRDINVNM            BRANCH IF NUMERIC                    47650020
         MVC   LRDCHAR(1),2(R3)    MOVE FIRST CHARACTER OF JOBNAME 000C 47700020
         NI    LRDCHAR,LRDCLRHI    ZERO HIGH ORDER 4 BITS OF CHARACTER  47750020
         CLI   LRDCHAR,LRDZERO     CHECK FOR ZERO NUMERIC FIELD         47800020
         BE    LRDINVNM            BRANCH IF ZERO                       47850020
         CLI   LRDCHAR,LRDNINE     CHECK NUMERIC FIELD                  47900020
         BH    LRDINVNM            BRANCH IF HIGHER THAN 9              47950020
         CLI   2(R3),LRDINVCR      CHECK FOR X'E1' (INVALID)       000C 48000020
         BE    LRDINVNM            BRANCH IF EQUAL                      48050020
GOODNAME EQU   *                   THE JOBNAME IS VALID          A40161 48070020
         MVI   QMNAM,LRDBLANK      PUT BLANKS AS JOB NAME IN QUEUE      48100020
         MVC   QMNAM+1(7),QMNAM    MANAGER PARAMETER AREA               48150020
         BCTR  R9,0                SUBTRACT ONE FROM CHARACTER COUNT    48200020
         EX    R9,LRDMVJOB         MOVE JOB NAME INTO QMPA              48250020
         L     R15,LRDCDSCH        GET ENTRY POINT OF FAST TABLE SEARCH 48300020
         BALR  R14,R15             CHECK FOR EMPTY ENTRY                48350020
         SH    R15,LRD4            TEST RETURN CODE                000A 48400020
         BZ    LRDJOBNM            BRANCH IF EMPTY SLOT AVAILABLE       48450020
         BM    LRDDUPJB            BRANCH IF DUPLICATE JOB NAME         48500020
*                                  FAST TABLE IS FULL                   48550020
         LA    R0,LRDXMT16         GET INPUT CODE FOR IHKABXMT     000A 48600020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 48650020
         SPACE 2                                                        48700020
         USING FASTAB,R1           SET BASE FOR FAST TABLE              48750020
LRDJOBNM L     R15,LCBBUFER        GET ADDRESS OF JOBNAME               48800020
         MVC   FASTNAME(8),0(R15)  PUT JOB NAME IN FAST TABLE TO        48850020
*                                  RESERVE ENTRY AND CLEAR REST OF      48900020
*                                  ENTRY EXCEPT TWO TTRS                48950020
         MVI   FASTJIB,FASTIOUT    CLEAR JOB INFORMATION BYTE      000B 49000020
         XC    FASTDSB(2),FASTDSB  CLEAR FASTDSB AND FASTDSBE           49050020
         L     R9,LRDCDFLN         GET ADDRESS OF FAST TABLE LENGTH     49100020
         LH    R9,0(R9)            GET FAST TABLE LENGTH                49150020
         SH    R9,LRD18            TO SKIP CLEARING FIRST          000A 49200020
*                                  17 BYTES OF FAST TABLE ENTRY         49250020
         EX    R9,LRDCLFST         CLEAR REST OF FAST TABLE ENTRY       49300020
         B     LRDJCLBF                                                 49350020
         USING IOPARAMS,R1         RESTORE QMPA BASE                    49400020
         SPACE 2                                                        49450020
*                                  DUPLICATE JOB NAME                   49500020
LRDDUPJB LA    R0,LRDXMT4          GET INPUT CODE FOR IHKABXMT     000A 49550020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 49600020
         SPACE 2                                                        49650020
*                                  NO JOB NAME                          49700020
LRDINVNM SR    R0,R0               INPUT CODE FOR IHKABXMT         000D 49750020
LRDCLXMT ST    R0,LCBPARM1         STORE AS PARAMETER              000A 49800020
         ST    R3,LCBPARM2         STORE POINTER TO CARD           000C 49850020
LRDXMTCL ST    R6,LCBPARM3         STORE PTR TO END OF BTAM BUFFER 000A 49900020
         L     R14,LRDZZAVT        GET BASE OF AVT DSECT           000A 49950020
         USING IHKZZAVT,R14        BASE OF AVT DSECT               000A 50000020
         ST    R2,IHKZZLCB         STORE LCB ADDRESS               000A 50050020
         LA    R1,IHKZZLCB         GET ADDRESS OF PARAMETER        000A 50100020
         L     R15,LRDABXMT        CALL ROUTINE WHICH TRANSMITS    000A 50150020
         BALR  R14,R15             AN ERROR MESSAGE                000A 50200020
IHKABRET DS    0H                                                 19018 50250020
         B     *+4(R15)            BRANCH ON RETURN CODE           000A 50300020
         B     LRDEOT                                              000A 50350020
         B     LRDRELBF                                            000A 50400020
         B     LRDEBDWT            RJENDF WITH ERROR MSG.        A27468 50450020
         B     LRDEBDRD            RJENDF WITH LINE ERROR        A27468 50500020
         B      LRDWRTJC            WRITE JCL BUFFER              19018 50550020
         B     LRDDELET            DELETE QUEUE ENTRY             19018 50600020
         B     LRDSTRET           GO SET RETURN CODE               000E 50650020
         B     LRDDISCT            BRANCH TO DISCONTINUE FUNCTION  000E 50700020
         B     LRDRDTQ             BRANCH TO READ ENQ FUNCTION     000E 50750020
LRDSTRET EQU   *                                                   000E 50800020
         LA    R10,LRDRTLST        SET TO RETURN TO IHKABLST      19018 50850020
         B     LRDWRJCL            WRITE JCL                      19018 50900020
         SPACE 2                                                        50950020
LRDSYSDT TM    TDIRSWCH,TDIRDDAN   TEST DD * SWITCH                     51000020
         BC    12,LRDBLKCK         BRANCH IF NOT READING DD* INPUT 000A 51050020
*                                                                       51100020
*********************************************************************** 51150020
*                                                                       51200020
*                   PROCESS SYSIN DATA                                  51250020
*                                                                       51300020
*********************************************************************** 51350020
*                                                                       51400020
LRDMVSYS CLC   0(3,R3),LRDENDDT    TEST FOR /*                     000C 51450020
         LA    R10,LRDNOTFL        SET RETURN ADDRESS                   51500020
         BE    LRDSYEND            BRANCH IF FOUND                      51550020
         LH    R7,LCBSMFCT              GET NO. OF SYSIN RECORDS  19018 51600020
         LA    R7,1(R7)                 ADD ONE                   19018 51650020
         STH   R7,LCBSMFCT              STORE NEW TOTAL           19018 51700020
         LA    R9,80(R3)           STEP DISK BUFFER POINTER             51750020
         CR    R9,R4               TEST FOR END OF DISK BUFFER          51800020
         BL    LRDNTFUL            BRANCH IF BUFFER NOT FULL            51850020
         SPACE 1                                                        51900020
         L     R7,LCBDDECB         GET DISK DECB ADDRESS FROM LCB       51950020
         L     R9,LCBBUFER         GET ADDRESS OF BEGINNING OF          52000020
         LA    R9,LRDDSKBF(R9)     OUTPUT BUFFER                        52050020
LRDSYSWR WRITE (7),SF,,(9),MF=E    WRITE BUFFER TO SYSIN DATA SET       52100020
         LA    R1,0(R7)            GET DISK ECB ADDRESS                 52150020
         L     R15,LRDAADSP        GET ADDRESS OF  DISPATCHER           52200020
         BALR  R14,R15             GO TO MULTIPLE WAIT                  52250020
         CHECK (1)                                                      52300020
         TM    TDIRSWCH,TDIREOSN   TEST FOR END OF SYSIN                52350020
         L     R3,LCBBUFER         RESET REGISTER 3 TO START OF         52400020
         LA    R3,LRDDSKBF(R3)     DISK BUFFER                          52450020
         BZ    LRDNOTFL            BRANCH IF NOT END OF SYSIN           52500020
         NI    TDIRSWCH,TDIREOSF   TURN OFF END OF SYSIN SWITCH         52550020
LRDCLOSE CLOSE ((8))               CLOSE SYSIN DATA SET                 52600020
         NI    TDIRSWCH,TDIRSYSF   TURN OFF DD DATA AND DD * SWITCHES   52650020
         L     R3,LCBBUFER         SET REGISTER 3 TO BEGINNING OF       52700020
         LA    R3,LRDQMCHN(R3)     JECL AND JCL BUFFER                  52750020
         LH    R4,LCBSMFCT              GET TOTAL SYSIN COUNT     19018 52800020
         CVD   R4,LRDDECNO              CONVERT TO DECIMAL        19018 52850020
         UNPK  LRDUPDEC(8),LRDDECNO+4(4) UNPACK COUNT             19018 52900020
         OI    LRDUPDEC+7,LRDZONE       PUT 'F' IN SIGN POSITION  19018 52950020
         MVC   LRDSMFCD+11(6),LRDUPDEC+2 MOVE COUNT TO CARD       19018 53000020
         MVI   4(R3),LRDBLANK           BLANK OUT BUFFER          19018 53050020
         MVC   5(79,R3),4(R3)           ...                       19018 53100020
         MVC   19(19,R3),LRDSMFCD       MOVE TO JCL BUFFER        19018 53150020
         MVC   4(2,R3),LRDSLASH         MOVE //                   19018 53200020
         L     R4,LRDDEC80         INDEX FOR JCL BUFFER           19018 53250020
         MVI   LRDCDIND(R3),LRD1CRD INDICATE ONE CARD IN BUFFER   19018 53300020
         BR    R10                                                      53350020
         SPACE 2                                                        53400020
LRDSYEND L     R9,LCBBUFER         SET REGISTER 9 TO START OF DISK      53450020
         LA    R9,LRDDSKBF(R9)     BUFFER                               53500020
         L     R7,LCBDDECB         GET DISK DECB POINTER FROM LCB       53550020
         SR    R3,R9               GET NUMBER OF BYTES IN DISK BUFFER   53600020
         LTR   R3,R3               TEST FOR NO DATA IN DISK BUFFER      53650020
         BZ    LRDCLOSE            BRANCH AROUND WRITE IF NO DATA       53700020
         STH   R3,DCBBLKSI         SET BLOCK SIZE FOR SHORT RECORD      53750020
         OI    TDIRSWCH,TDIREOSN   TURN ON END OF SYSIN SWITCH          53800020
         B     LRDSYSWR                                                 53850020
         SPACE 2                                                        53900020
LRDBLKCK CLI   0(R3),LRDBLANK      CHECK FOR BLANK IN COL. 1       000C 53950020
         BNE   LRDGENSY            BRANCH IF NOT BLANK             000A 54000020
         CLC   1(79,R3),0(R3)      CHECK FOR BLANKS IN 2-80        000C 54050020
         BE    LRDRJF              UNDEFINED OPERATION             000C 54100020
         SPACE 2                                                   000A 54150020
LRDGENSY CLC   0(3,R3),LRDENDDT    TEST FOR /*                     000C 54200020
         BE    LRDNOTFL            BR IF FOUND TO GET NEXT CARD    000A 54250020
         CLC   0(2,R3),LRDDOTS     CHECK FOR .. IN COLS. 1 AND 2   000C 54300020
         BE    LRDSEQCK            QUEUE JECL CARD SO READER CAN   000A 54350020
*                                  GENERATE UNDEFINED OPERATION    000A 54400020
*                                  MESSAGE BECAUSE COL 3 NOT BLANK 000A 54450020
         TM    TDIRSWCH+2,TDIRJCLN TEST JCL SWITCH                 000A 54500020
         BNO   LRDRJF              BRANCH IF NOT ON BECAUSE        000C 54550020
*                                  NOT PROCESSING JOB              000A 54600020
         OI    TDIRSWCH,TDIRDDAN   TURN ON DD * SWITCH             000A 54650020
         BAL   R15,LRDFIXR3        GET CORRECT DISK BUFFER POINTER 000C 54700020
         MVC   4(8,R10),LRDGNSYS   PUT '//SYSIN ' IN JECL-JCL BUF  000A 54750020
         MVC   12(72,R10),11(R10)  PUT BLANKS IN COLUMNS 9-80      000A 54800020
         TM    TDIRSWCH+2,TDIRMCHN TEST FOR CPU OR 2780            000A 54850020
         BZ    LRDSYS27            BRANCH IF 2780                  000A 54900020
         TM    TDIRRB,TDIRPNRN    COMPRESSING TERMINAL?            000C 54950020
         BNO   LRDNOTCE           NO, USE REGULAR STEPPING BACK    000C 55000020
         BCTR  R5,0               JUST BACK UP ONE BYTE TO AVOID   000C 55050020
*                                 BOTH STEPPING BEYOND BEGINNING   000C 55100020
*                                 OF BUFFER AND OVERLAYING INFO    000C 55150020
         MVI   0(R5),X'01'        INDICATE THAT WE STEPPED BACK 1  000C 55200020
         B     LRDGNSY2           CONTINUE                         000C 55250020
LRDNOTCE DS    0H                                                  000C 55300020
         SH    R5,EIGHTY           BACK UP BTAM BUFFER POINTER BY  000C 55350020
*                                  ONE CARD SO FIRST SYSIN CARD IS 000A 55400020
*                                  NOT SKIPPED                     000A 55450020
LRDGNSY2 MVC   DCBDDNAM(8),LCBDDNAM PUT DDNAME OF LINE'S SYSIN     000A 55500020
*                                   DD CARD IN DCB                 000A 55550020
         BAL   R11,LRDGTUCB        GET ADDRESS OF UCB ADDRESS      000A 55600020
         SR    R11,R11                                             000C 55650020
         STH   R11,LCBPARM3+2                                      000C 55700020
         B     LRDALC              GO TO ALLOCATE ROUTINE          000A 55750020
LRDSYS27 SH    R5,LRD84            BACK UP BTAM BUFFER POINTER BY  000A 55800020
*                                  ONE CARD SO FIRST SYSIN CARD IS 000A 55850020
*                                  NOT SKIPPED                     000A 55900020
         B     LRDGNSY2                                            000A 55950020
LRDRJWT  LA    R1,DUMECB      LOOP TO WAIT FOR OTHER LINES       A48402 55960021
         L     R15,LRDAADSP   RJENDF TO BE QUEUED                A48402 55970021
         BALR  R14,R15                                           A48402 55980021
         B     LRDRJTST                                          A48402 55990021
         SPACE 2                                                   000A 56000020
*                                                                       56050020
*********************************************************************** 56100020
*                                                                       56150020
*                   ERROR HANDLING SECTION                              56200020
*                                                                       56250020
*********************************************************************** 56300020
*                                                                       56350020
*                                  EXLST ROUTINE                        56400020
LRDOUTSP OI    TDIRRB,TDIREXLN     TURN ON EXLST SWITCH                 56450020
         LA    R15,1               SET RETURN CODE FOR EOV ROUTINE      56500020
         BR    R14                 RETURN TO EOV ROUTINE WHICH THEN     56550020
*                                  COMES TO MY SYNAD EXIT               56600020
         SPACE 2                                                        56650020
*                                  OUT OF SPACE FOR SYSIN               56700020
LRDSYSSP NI    TDIRSWCH,TDIRSYSF   TURN OFF DD DATA AND DD * SWITCHES   56750020
LRDSYSP2 LA    R0,LRDXMT20         GET INPUT CODE FOR IHKABXMT     000A 56800020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 56850020
         SPACE 2                                                        56900020
*                                  OUT OF SPACE FOR SYSIN OR            56950020
*                                  SYSIN LIMIT EXCEEDED OR              57000020
*                                  I/O ERROR ON SYSIN DATA SET          57050020
LRDSYNAD TM    TDIRRB,TDIREXLN     TEST EXLST SWITCH                    57100020
         BO    LRDSYSP2            BRANCH IF ON - OUT OF SPACE          57150020
         L     R9,DCBDEBAD         GET ADDRESS OF DEB FOR SYSIN         57200020
         CLI   DEBNMEXT(R9),LRDNMEXT TEST NUMBER OF EXTENTS IN DEB      57250020
         BL    LRDDSKER            BRANCH IF REALLY DISK I/O ERROR      57300020
*                                  SYSIN LIMIT EXCEEDED                 57350020
         LA    R0,LRDXMT12         GET INPUT CODE FOR IHKABXMT     000A 57400020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 57450020
         SPACE 2                                                        57500020
*                                  OUT OF SPACE FOR QUEUE ENTRY         57550020
LRDQMSPA LA    R0,LRDXMT24         GET INPUT CODE FOR IHKABXMT     000A 57600020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 57650020
         SPACE 2                                                        57700020
*                                  I/O ERROR ON ASSIGN/START            57750020
LRDQMIOA LA    R0,LRDXMT28         GET INPUT CODE FOR IHKABXMT     000A 57800020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 57850020
         SPACE 2                                                        57900020
*                                  I/O ERROR ON Q MGR NOT ASSIGN/START  57950020
LRDQMIOE CLC   LCBWORKA,LRDSPENT   CHECK FOR ENTRY AT IHKABRJF INSTEAD  58000020
*                                  OF AT IHKABLRD                       58050020
         BE    LRDNOTQD            BRANCH IF ENTERED AT IHKABRJF        58100020
         LA    R0,LRDXMT32         GET INPUT CODE FOR IHKABXMT     000A 58150020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 58200020
         SPACE 2                                                        58250020
*                                  I/O ERROR ON ALLOCATE                58300020
LRDIOALC NI    TDIRSWCH,TDIRSYSF   TURN OFF DD DATA AND DD * SWITCHES   58350020
LRDIOSYS LA    R0,LRDXMT36         GET INPUT CODE FOR IHKABXMT     000A 58400020
         B     LRDCLXMT            CALL IHKABXMT TO SEND MESSAGE   000A 58450020
         SPACE 2                                                        58500020
*                                  I/O ERROR ON SYSIN DATA SET          58550020
LRDDSKER L     R3,LCBBUFER         RESET REGISTER 3 TO START OF         58600020
         LA    R3,LRDDSKBF(R3)     DISK BUFFER                          58650020
         BAL   R11,LRDGTUCB        GET ADDRESS OF UCB ADDRESS           58700020
         L     R11,LCBTDIR         RESET WITH TERMINAL DIRECTORY ADDR   58750020
         B     LRDIOSYS            WRITE MESSAGE TO CENTRAL AND REMOTE  58800020
         SPACE 2                                                   000C 58850020
*                                  UNPACKED RECORD REC'D FOR PACKED000C 58900020
LRDGOOF2 L     R7,LCBLDECB         GET DECB ADDRESS                000C 58950020
         WRITE (7),TN,MF=E         WRITE EOT                       000C 59000020
         BAL   R10,LRDSIO          GO TO CHECK ON I/O              000C 59050020
         LA    R10,LRDCKSYS        SET TO RETURN TO CHECK SYSIN    000C 59100020
         B     LRDWMSRT            BRANCH TO RJENDF                000C 59150020
         SPACE 2                                                        59200020
*                                  BTAM READ FAILED                     59250020
LRDEBDRD DS    0H                                                A47967 59300021
LRDBDRD  LTR   R11,R11             TEST FOR TERMINAL DIRECTORY POINTER  59350020
         BZ    LRDDELET            BRANCH IF NO POINTER                 59400020
         LA    R10,LRDCKSYS        SET RETURN ADDRESS                   59450020
         SPACE 1                                                        59500020
*                                  LINE FAILURE                         59550020
         L     R5,DECAREA         LOAD BUFF POINTER              A24704 59600020
         CLC   0(3,R5),LRDSTKUN    HAS 2770 STACKER UNLOAD BUTON A35897 59610020
*                                  BEEN PRESSED.                 A35897 59620020
         BE    LRDDISCT            YES, ALLOW TIME FOR THE       A35897 59630020
*                                  STACKER TO BE UNLOADED        A35897 59640020
         CLC   0(3,R5),LRDCDJAM   CHECK FOR EOT STX ENQ AFTER    A24704 59650020
*                                 ERROR WHICH MEANS CARD JAM AT  A24704 59700020
*                               2780                             A24704 59750020
         ST    R5,0(R5)            PREVENT LOOP IF TERM. OFFLINE A24712 59800020
         BE    LRDDISCT           BRANCH IF SO TO GIVE TIME FOR  A24704 59850020
*                                 JAM TO BE CORRECTED            A24704 59900020
LRDUSER  L     R9,LRDCDSOC         GET RJETABLE ADDRESS                 59950020
         L     R1,LCBLDECB         GET DECB ADDRESS FOR USER            60000020
         L     R15,LRDUSREX(R9)    GET LINE ERROR USER EXIT ADDRESS     60050020
         BALR  R14,R15             BRANCH TO USER EXIT OR DUMMY         60100020
LRDWMSRT NI    TDIRSTAT,TDIRNQJM   TURN OFF ENQUEUE JOBS AND ENQUEUE    60150020
*                                  MESSAGES BITS                        60200020
         OI    TDIRSTAT,TDIRDQNN   SET DEQUEUE NOTHING BIT              60250020
         OI    LCBNSWFL,LCBRJNDF   INDICATE RJENDF GENERATED       000A 60300020
         NI    TDIRSWCH,TDIRRJLF   TURN OFF RJSTART AND LOGON SWITCHES  60350020
         NI    TDIRSWCH+2,TDIRLWRF TURN OFF BRANCH TO LWR SWITCH        60400020
         L     R14,LRDZZAVT        GET BASE OF AVT DSECT                60450020
         L     R15,IHKZZECB        GET ADDRESS OF ECBLIST OF IHKCCPLM   60500020
         MVI   0(R15),LRDPOST      POST THE MESSAGE ECB                 60550020
         MVI   4(R15),LRDPOST      POST THE JOB ECB                     60600020
         USING LRDCVT,R14          RESET BASE OF CVT                    60650020
         BR    R10                                                      60700020
         SPACE 1                                                        60750020
LRDCKSYS DS    0H                  GENERATE RJENDF                19018 60800020
         LA    R0,LRDXMT64         OFFSET FOR IHKABXMT            19018 60850020
         SR    R4,R4                    INITIALIZE REG 4         19018  60900020
         B     LRDCLXMT            CALL IHKABXMT                  19018 60950020
         SPACE 2                                                        61000020
*                                  WRITE WAS UNSUCCESSFUL               61050020
LRDEBDWT DS    0H                                                A47967 61100021
LRDBADWT LTR   R11,R11             CHECK FOR TERMINAL DIRECTORY POINTER 61150020
         BZ    LRDNOTRM            BRANCH IF NO TDIR POINTER            61200020
         TM    TDIRSWCH,TDIRRJFN   TEST NO RJENDF SWITCH                61250020
         BO    LRDNORJF            BRANCH IF ON                         61300020
         L     R9,LCBBUFER         GET ADDRESS OF LAST 79 BYTES OF 000A 61350020
         LA    R9,LRDMSGBF(R9)     THE OUTPUT BUFFER               000A 61400020
         BAL   R15,LRDFIXR3        GET CORRECT DISK BUFFER POINTER 000C 61450020
         MVC   4(10,R10),LRDDOTS   PUT '.. RJENDF ' ON CARD             61500020
         MVC   14(60,R10),11(R9)   PUT MESSAGE ON RJENDF CARD           61550020
         BAL   R10,LRDUSER         GO TO USER EXIT AND SET RJENDF BITS  61600020
         LR    R9,R3               GET ADDRESS OF JECL AND JCL BUFFER   61650020
         LA    R0,LRDXMT68         OFFSET FOR IHKABXMT            19018 61700020
         B     LRDCLXMT            CALL IHKABXMT                  19018 61750020
LRDNORJF NI    TDIRSWCH,TDIRRJFF   TURN OFF NO RJENDF SWITCH            61800020
         B     LRDRELBF                                                 61850020
LRDNOTRM DS    0H                  NO TDIR POINTER                19018 61900020
         LA    R0,LRDXMT72         OFFSET FOR IHKABXMT            19018 61950020
         B     LRDCLXMT            CALL IHKABXMT                  19018 62000020
LRDDELET L     R1,LCBBUFER         GET QMPA ADDRESS                     62050020
         SR    R15,R15        IS ADDRESS OF EXTENSION            A47439 62090021
         C     R15,QMPCL      OF QMPA ZERO                       A47439 62130021
         BE    LRDRELBF       YES - SKIP DELETE                  A47439 62170021
         ST    R15,QMPCL      NO - ZERO IT FOR THE NEXT TIME     A47439 62210021
         MVI   QMPOP,QMDELE        STORE DELETE CODE                    62250020
         BAL   R9,LRDQMNGR         DELETE                          000A 62300020
         BC    7,LRDQMIOE          BRANCH IF I/O ERROR                  62350020
         B     LRDRELBF                                                 62400020
         SPACE 2                                                   000A 62450020
LRDNOTQD LA    R15,LRDCDNRC        SET RETURN CODE FOR RJENDC OR RJENDF 62500020
*                                  NOT QUEUED                           62550020
         B     LRDRETLS            RETURN TO LINE SCHEDULER             62600020
         SPACE 4                                                   000C 62650020
LRDUNPK  DS    0H                  SUBROUTINE TO UNPACK INPUT      000C 62700020
         TM    TDIRSWCH,TDIRSYSN   ARE WE IN SYSIN?                000C 62750020
         BNZ   LRDINSYS            YES, DON'T CHANGE R3            000C 62800020
         L     R1,LCBBUFER         GET QMPA ADDRESS                000C 62850020
         LA    R3,QMCHN            GET DISK BUFFER POINTER         000C 62900020
         LA    R3,4(R3,R4)         GET ADDRESS OF CORRECT RECORD   000C 62950020
LRDINSYS DS    0H                                                  000C 63000020
         TM    TDIRRB,TDIRPUPN     WAS UNPACK SELECTED?            000C 63050020
         BO    LRDUNP              BRANCH IF SO                    000C 63100020
         MVC   0(80,R3),0(R5)      MOVE RECORD TO OUTPUT BUFFER    000C 63150020
         BR    R14                 RETURN                          000C 63200020
LRDUNP   DS    0H                                                  000C 63250020
         CLC   0(2,R5),LRDDOTS     HAS REMOTE SENT AN UNPACKED CARD000C 63300020
         BE    LRDGOOF2            YES, RJENDF THE TERMINAL        000C 63350020
         ST    R5,LCBPARM2         STORE INPUT ADDRESS             000C 63400020
         ST    R3,LCBPARM3         STORE OUTPUT ADDRESS            000C 63450020
         LR    R1,R2               GET LCB ADDRESS                 000C 63500020
         L     R15,LRDADUPK        GET UNPACK ENTRY POINT ADDRESS  000C 63550020
         L     R15,0(R15)          GET UNPACK ENTRY POINT          000C 63600020
         BR    R15                 GO UNPACK RECORD                000C 63650020
         SPACE 4                                                   000C 63700020
LRDFIXR3 DS    0H                                                  000C 63750020
         L     R1,LCBBUFER         GET QMPA ADDRESS                000C 63800020
         LA    R3,QMCHN            GET DISK BUUFER ADDRESS         000C 63850020
         LR    R10,R3              SAVE ADDRESS                    000C 63900020
         AR    R10,R4              ADD BUFFER INDEX (0 OR 80)      000C 63950020
         BR    R15                 RETURN                          000C 64000020
*****************************************************************A26537 64050020
*  THIS ROUTINE READS UNITIL AN EOT IS RECEIVED.                *A26537 64100020
*  IT THEN HOLDS UP LINE I/O OPERATION UNTIL THE RJEND IS       *A26537 64150020
*  PROCESSED.  AFTER THE RJEND MESSAGE IS SENT THE LINE IS      *A26537 64200020
*  AGAIN CONDITIONED TO PROCESS MORE INPUT                      *A26537 64250020
*****************************************************************A26537 64300020
RJENDR   EQU   *                                                 A26537 64350020
         L     R7,LCBLDECB        LOADS LINE DECB POINTER        A26537 64400020
         L     R5,DECAREA          LOADS POINTER TO BUFFER       A26537 64450020
         SR    R0,R0                                             A26537 64500020
         ST    R0,0(0,R5)          STORE ZERO IN FIRST WORD OF   A26537 64550020
*                                  BUFFER SO CHECK FOR EOT CAN BEA26537 64600020
*                                  MADE                          A26537 64650020
         READ  (7),TRV,MF=E                                      A26537 64700020
         BAL   R10,LRDSIO          CHECK COMPLETION CODE         A26537 64750020
         BNE   SKFLUSH             DONT FLUSH TO EOT ON ERROR    A26537 64800020
         CLI   0(R5),LRDEOTCR      CHECK IF EOT RECEIVED         A26537 64850020
         BNE   RJENDR              NO READ TILL WE GET IT        A26537 64900020
SKFLUSH  EQU   *                                                 A26537 64950020
         MVC   LRDXMT12(4,R3),LCBDDECB   MOVE IN ECB TO BE POSTEDA26537 65000020
         X     R4,LRDDEC80        SET JCL BUFFER INDEX TO 80 OR 0A26537 65050020
         L     R1,LCBBUFER        GET QMPA ADDRESS               A26537 65100020
         LA    R15,QMCHN          SET POINTER TO DISK BUFFER     A26537 65150020
         STC   R4,LRDCDIND(R15)   INDICATE 1 OR 2 CARDS IN BUFF  A26537 65200020
         OI    12(R11),TDIRRJN    SET RJEND RECEIVED FLAG        A26537 65250020
         B     LRD1130                 QUEUE RJEND COMMAND       A40166 65300020
LRDWAIT  EQU   *                                                 A26537 65350020
         NI    12(R11),TDIROFF     TURN OFF RJEND RECEIVED       A26537 65400020
         L     R1,LCBDDECB        LOAD DISK ECB POINTER          A26537 65450020
         MVI   0(R1),LRDZERO       SET OFF COMP BIT IN ECB       A26537 65500020
         ST    R1,16(R3)          PUT POINTER IN BUFFER          A26537 65550020
         L     R15,LRDAADSP       GET POINTER TO DISPATCHER      A26537 65600020
         BALR  R14,R15                                           A26537 65650020
         B     LRDRTL             RETURN TO IHKABLST             A26537 65700020
         SPACE 4                                                   000C 65750020
*********************************************************************** 65800020
*                                                                       65850020
*                   EXECUTED INSTRUCTIONS                               65900020
*                                                                       65950020
*********************************************************************** 66000020
*                                                                       66050020
LRDMVJOB MVC   QMNAM(0),2(R3)      MOVE JOBNAME INTO QMPA          000C 66100020
LRDMVSEL MVC   TDIRDFTA+3(0),0(R10) TO MOVE POLLING CHARACTERS TO  000C 66150020
*                                  DFTRMLST IN TERMINAL DIRECTORY  000A 66200020
         USING FASTAB,R1           SET BASE FOR FAST TABLE ENTRY        66250020
LRDCLFST XC    FASTALT(0),FASTALT  CLEAR END OF FAST TABLE ENTRY        66300020
         SPACE 2                                                        66350020
*                                                                       66400020
*********************************************************************** 66450020
*                                                                       66500020
*                   READ ONLY MODEL DCB FOR SYSIN DATA SETS             66550020
*                   IN REAL DCB, DDNAME AND BLKSIZE ARE FILLED IN       66600020
*                   FROM LINE SYSIN DD CARD                             66650020
*                                                                       66700020
*********************************************************************** 66750020
*                                                                       66800020
LRDSYSDD DCB   DSORG=PS,MACRF=(W),DEVD=DA,LRECL=80,RECFM=FB,           X66850020
               EXLST=LRDEXLST,SYNAD=LRDSYNAD,                          X66900020
               DDNAME=LRDAPR03                                     000A 66950020
         SPACE 2                                                        67000020
*                                                                       67050020
*********************************************************************** 67100020
*                                                                       67150020
*                   CONSTANTS AND DSECTS                                67200020
*                                                                       67250020
*********************************************************************** 67300020
LRDSMFCD DC    C'SPACE=(80,(000000))'   SPACE PARM. FOR SMF COUN  19018 67350020
*                                                                       67400020
LRDSYNC  EQU   X'32'                   CLOC SYNC CHARACTER         000D 67450020
*                                  PARAMETER LIST FOR IHKCAVER          67500020
*                                  (COMMAND INTERPRETER)                67550020
LRDCDOPR DS    F                   CODE AND ADDRESS OF OPERATION        67600020
LRDCDBEG DS    F                   BEGINNING ADDRESS OF CARD IMAGE      67650020
LRDCTDIR DS    F                   TERMINAL DIRECTORY POINTER           67700020
LRDADUPK DC    V(IHKADUPK)         ADDRESS OF ADDRESS  OF UNPACK   000C 67750020
LRDSTKUN DC    X'10022D'           DLE,STX,ENQ-2770 STCKR UNLOAD  M6294 67800020
LRDLCBAD DC    A(IHKCDLCB)         ADDR. OF FIRST LCB            A21657 67850020
* THESE NEXT TWO ADDRESSES MUST BE CONTIGUOUS.                   A21657 67900020
LRDLINES DC    A(IHKCDNOL)         ADDR. OF NO. OF LINES         A21657 67950020
         DC    A(IHKCDLGL)         ADDR. OF LCB LENGTH           A21657 68000020
         EXTRN IHKCDLCB,IHKCDNOL,IHKCDLGL                        A21657 68050020
         SPACE 2                                                        68100020
DUMECB   DS    0F                                                A48402 68110021
         DC    X'40000000'                                       A48402 68120021
         SPACE 3                                                  19018 68150020
*   NOTE: ALL THE FOLLOWING CONSTANTS ARE DSECTED IN EITHER       19018 68200020
*        IHKABXMT, IHKABALC, OR IHKCHALC.  THEREFORE, IF ANY      19018 68250020
*        CHANGES ARE MADE, THESE DSECTS MUST ALSO BE CHANGED.     19018 68300020
         SPACE 1                                                  19018 68350020
IHKABXCN DS    0D                  START OF DSECT IN IHKABXMT     19018 68400020
*                                  PARAMETER LIST FOR IHKCBLDM (BLDMSG) 68450020
LRDBLDM  DC    X'80000000'         BUILD BUT DO NOT ENQUEUE MESSAGE     68500020
LRDBOFS  DC    X'0000'             MESSAGE OFFSET                       68550020
LRDBPMNO DS    C                   NUMBER OF MESSAGE PARAMETER CHARS.   68600020
LRDBPARM DS    CL24                MESSAGE PARAMETER CHARACTERS         68650020
         SPACE 2                                                        68700020
         CNOP  0,4                                                      68750020
*                                  PARAMETER LIST FOR IHKCCSCN (SCAN)   68800020
LRDSCAN  DC    H'0'                MAXIMUM SCAN LENGTH OR ZERO          68850020
LRDSBLNK DC    H'0'                TO SEARCH FOR FIRST NON-BLANK CHAR.  68900020
LRDSADDR DS    F                   STARTING ADDRESS FOR SCAN            68950020
LRDSSTOP DS    F                   STOPPING ADDRESS FOR SCAN            69000020
LRDSCHAR DC    C' '                TO STOP ON FIRST BLANK CHARACTER     69050020
         DC    C'),'               OR RIGHT PAREN OR COMMA         000C 69100020
         SPACE 2                                                        69150020
LRDSYSIN EQU   39                  SYSIN QUEUE NUMBER                   69200020
LRD2TTRS EQU   X'20'               TO ASSIGN TWO TTR'S                  69250020
LRDWR1AS EQU   X'11'               WRITE ONE RECORD AND ASSIGN ONE TTR  69300020
LRDWR1   EQU   X'01'               TO WRITE ONE RECORD                  69350020
LRD1CRD  EQU   80                  TO INDICATE ONE CARD IN JCL BUFFER   69400020
LRDNOCRD EQU   X'10'               INDICATE NO CARDS IN JCL BUFFER      69450020
TCBTIO   EQU   12                  DISPLACEMENT FOR TIOT ADDRESS   000A 69500020
*                                  IN TCB                          000A 69550020
DEBNMEXT EQU   16                  BYTE IN DEB FOR NUMBER OF EXTENTS    69600020
DEBUCBAD EQU   32                  DISPLACEMENT FOR UCB ADDRESS IN DEB  69650020
LRDNMEXT EQU   16                  MAXIMUM NUMBER OF EXTENTS            69700020
LRDUSREX EQU   16                  LINE ERROR USER EXIT DISPLACEMENT    69750020
LRDEOTCR EQU   X'37'               EOT                                  69800020
LRDENQ   EQU   X'2D'               ENQ                                  69850020
LRDBLANK EQU   C' '                TO PUT BLANKS IN A FIELD             69900020
LRDCHAR1 EQU   C'1'                TO INDICATE REMOTE MESSAGE      000A 69950020
LRD7F    EQU   X'7F'               GOOD COMPLETION CODE FOR I/O         70000020
LRDRSTPL EQU   X'48'               COMPLETION CODE AFTER RESETPL        70050020
LRDRTPL  EQU   X'04'               DECB STATUS FLAG AFTER RESETPL  000A 70100020
LRDTOFLG EQU   X'40'               TO INDICATE IN DECTYPE NO BTAM  000A 70150020
*                                  ERROR MESSAGE FOR TIME OUT      000A 70200020
LRDTOOFF EQU   X'BF'               TO RESET DECTYPE FOR BTAM ERROR 000A 70250020
*                                  MESSAGE FOR TIME OUT            000A 70300020
LRDTMOUT EQU   X'01'               TO CHECK FOR TIME OUT IN DECSENS0    70350020
LRDRJSCD EQU   8                   RJSTART CODE FOR IHKCAVER            70400020
LRDLGNCD EQU   4                   LOGON CODE FOR IHKCAVER              70450020
LRDZERO  EQU   0                                                        70500020
LRDOFS13 EQU   13                  LINE ERROR                           70550020
LRDOFS20 EQU   20                  INVALID OPERATION - RJENDC OR RJENDF 70600020
LRD15CHR EQU   15                  15 MESSAGE PARAMETERS                70650020
LRDCDLST EQU   0                   RETURN CODE FOR IHKABLST             70700020
LRDSTSLT EQU   32                 RETURN CODE FOR LOPEN FUNCTION   000D 70750020
LRDCDEOT EQU   8                   RETURN CODE FOR IHKABEOT             70800020
LRDCDLWR EQU   12                  RETURN CODE FOR IHKABLWR             70850020
LRDCDNRC EQU   20                  RETURN CODE FOR RJENDC OR RJENDF     70900020
*                                  NOT QUEUED                           70950020
LRDCDSWL EQU   24                  RETURN CODE FOR SWITCHED LINE        71000020
LRDSW278 EQU   28                  RETURN TO IHKABLST TO SEND EOT  000A 71050020
*                                  TO 2780 ON SWITCHED LINE        000A 71100020
LRDXMT0  EQU   0                   INVALID JOBNAME                 000A 71150020
LRDXMT4  EQU   4                   DUPLICATE JOBNAME               000A 71200020
LRDXMT8  EQU   8                   NO JOB CARD                     000A 71250020
LRDXMT12 EQU   12                  SYSIN LIMIT EXCEEDED            000A 71300020
LRDXMT16 EQU   16                  MAX JOBS EXCEEDED               000A 71350020
LRDXMT20 EQU   20                  OUT OF SPACE - SYSIN            000A 71400020
LRDXMT24 EQU   24                  OUT OF SPACE - SYS1.SYSJOBQE    000A 71450020
LRDXMT28 EQU   28                  I/O ERROR ON ASSIGN/START       000A 71500020
LRDXMT32 EQU   32                  I/O ERROR ON Q MGR NOT A/S      000A 71550020
LRDXMT36 EQU   36                  I/O ERROR ON ALLOCATE OR SYSIN  000A 71600020
LRDXMT40 EQU   40                  INVALID TERMID                  000A 71650020
LRDXMT44 EQU   44                  INVALID RJSTART OR LOGON        000A 71700020
LRDXMT48 EQU   48                  INVALID OPERATION - RJENDC OR F 000A 71750020
LRDXMT52 EQU   52                  RJSTART OR LOGON REQUIRED       000A 71800020
LRDXMT56 EQU   56                  UNDEFINED KEYWORD               000C 71850020
LRDXMT60 EQU   60                  ILLEGAL KEYWORD PARAMETER       000C 71900020
LRDXMT64 EQU   64                  OFFSET 64 - LRDGENJF           19018 71950020
LRDXMT68 EQU   68                  OFFSET FOR IHKABXMT - LRDGNRF  19018 72000020
LRDXMT72 EQU   72                  OFFSET 72 - LRDWRTD            19018 72050020
ITBCHAR  EQU   X'40'               BIT SET FOR ITB MODE            000E 72100020
LRDQMCHN EQU   44                  DISPLACEMENT OF JECL-JCL BUFFER      72150020
LRDDSKBF EQU   48                  DISPLACEMENT FOR DISK BUFFER    000A 72200020
LRDRELTD EQU   164                 DISPLACEMENT FOR RELATIVE TDIR PTR   72250020
LRDCDIND EQU   168                 DISPLACEMENT FOR CARD INDICATOR      72300020
LRDSCDHF EQU   200                 DISPLACEMENT FOR SECOND HALF OF BUF  72350020
LRDMSGBF EQU   373                 DISPLACEMENT FOR MESSAGE IN BUFFER   72400020
LRDJOBCH EQU   448                 DISPLACEMENT FOR NUMBER OF      000A 72450020
*                                  CHARACTERS IN JOBNAME           000A 72500020
LRDPOST  EQU   X'40'               TO POST THE ECB'S OF IHKCCPLM        72550020
LRDABCLS EQU   19                  TO CHECK FOR RJENDF WITH ABNORMAL    72600020
*                                  CENTRAL CLOSEDOWN MESSAGE            72650020
LRDNOMSG EQU   X'FF'               FOR RJENDF WITH NO MESSAGE      000A 72700020
LRDSTRJE EQU   X'80'               TO TEST STOP RJE BIT                 72750020
LRDZONE  EQU   X'F0'               ZONE FOR NUMBERS               19018 72800020
LRDA     EQU   C'A'                LOWEST ALPHABETIC CHARACTER          72850020
LRDZ     EQU   C'Z'                HIGHEST ALPHABETIC CHARACTER         72900020
LRDCLRHI EQU   X'0F'               TO ZERO HIGH ORDER 4 BITS            72950020
LRDNINE  EQU   X'09'               TO CHECK NUMERIC FIELD               73000020
LRDINVCR EQU   X'E1'               TO CHECK FOR INVALID CHARACTER       73050020
LRD#     EQU   C'#'                VALID CHAR IN JOBNAME         A40161 73060020
LRD$     EQU   C'$'                VALID CHAR IN JOBNAME         A40161 73070020
LRD@     EQU   C'@'                VALID CHAR IN JOBNAME         A40161 73080020
         SPACE 2                                                        73100020
LRDENDDT DC    CL3'/*'             /* CARD FOR END OF SYSIN DATA        73150020
LRDDOTS  DC    CL3'..'             TO CHECK FOR JECL CARD               73200020
LRDRJNDF DC    C'RJENDF '                                               73250020
LRDRJSTT DC    C'RJSTART '                                              73300020
LRDLOGON DC    C'LOGON '                                                73350020
LRDCONT  DC    C'CONTINUE '                                             73400020
LRDJED   DC    C'JED '                                                  73450020
LRDLOGOF DC    C'LOGOFF '                                               73500020
LRDRJEND DC    C'RJEND '                                                73550020
LRDDOTRC DC    CL3'..'             TO BUILD RJENDC CARD                 73600020
LRDRJNDC DC    C'RJENDC '                                               73650020
LRDJOB   DC    C'JOB '                                             000A 73700020
LRDDATA  DC    C'DATA '            TO TEST FOR DD DATA CARD        000A 73750020
LRDDD    DC    C'DD '              TO TEST FOR DD CARD             000A 73800020
LRDGNSYS DC    C'//SYSIN '         TO GENERATE DD * CARD           000A 73850020
LRDCHAR  DS    C                   TO VERIFY ALPHABETIC CHARACTER       73900020
         SPACE                                                          73950020
IHKABCON DS    0F                  START OF DSECT IN IHKABALC      000A 74000020
LRDSPENT DC    F'0'                TO TEST FOR SPECIAL ENTRY - IHKABRJF 74050020
LRDSLASH DC    CL3'//'             TO CHECK FOR JCL CARD AND            74100020
*                                  TO HELP BUILD SYSIN DD CARD          74150020
LRDTASK  DC    C'RJETASK '         JOB NAME FOR QMPA IF ONLY JECL       74200020
         SPACE 1                                                        74250020
LRDHEADR DC    X'01'               SOH                                  74300020
         DC    C'3310060'          HEADER FOR CPU                       74350020
         DC    X'26'               ETB                                  74400020
LRDDLSTX DC    X'1002'             DLE STX                              74450020
LRDSOHD  DC    X'01'               SOH                                  74500020
         DC    C'D'                MEANS DISCONTINUED INPUT             74550020
LRDSOHR  DC    X'01'               SOH                                  74600020
         DC    C'R'                MEANS RESUME NORMAL INPUT            74650020
LRDCDJAM DC    X'37022D'          EOT STX ENQ CHECK FOR CARD JAM A24704 74700020
         SPACE 1                                                        74750020
LRDCHARS DS    H                   NO. OF CHARS IN JOBNAME/DDNAME  000A 74800020
LRD3     DC    H'3'                TO IGNORE ENQ AND INDEX AFTER   000A 74850020
*                                  POLLING CHARACTER(S)            000A 74900020
LRD4     DC    H'4'                                                000A 74950020
LRD8     DC    H'8'                TO TEST LENGTH OF JOBNAME       000A 75000020
LRD18    DC    H'18'                                               000A 75050020
LRD84    DC    H'84'               TO BACK UP BTAM BUFFER POINTER  000A 75100020
LRD200   DC    H'200'              THRESHOLD FOR AVAIL Q MGR REC.  000A 75150020
LRDUCBAD DS    F                   WILL HAVE ADDRESS OF UCB ADDRESS     75200020
LRDDEC80 DC    F'80'               TO INDEX JECL-JCL BUFFER             75250020
TDIROFF  EQU   X'BF'              FLAG TO TURN OFF RJEND RECEIVEDA26537 75300020
TDIRRJN  EQU   X'40'              SET ON RJEND RECEIVED FLAG     A26537 75350020
EIGHTY   EQU   LRDDEC80+2          HALFWORD OF 80                  000D 75400020
LRDSVBLK DS    F                   TO SAVE ADDR OF BLANK AFTER DDNAME   75450020
         SPACE                                                          75500020
LRDCCSCN DC    V(IHKCCSCN)         ENTRY POINT OF SCAN                  75550020
LRDAADSP DC    V(IHKAADSP)         ENTRY POINT OF DISPATCHER            75600020
LRDCAINT DC    V(IHKCAVER)         ENTRY POINT OF COMMAND INTERPRETER   75650020
LRDCBLDM DC    V(IHKCBLDM)         ENTRY POINT OF BUILD MESSAGE         75700020
LRDCDFMR DC    V(IHKCDFMR)         ENTRY POINT OF FAST TABLE MANAGER    75750020
LRDCDSCH DC    V(IHKCDSCH)         ENTRY POINT OF FAST TABLE SEARCH     75800020
LRDABALC DC    V(IHKABALC)         ENTRY POINT OF SYSIN ALLOCATION RTN  75850020
LRDABLST DC    V(IHKABLST)         ENTRY POINT OF LINE SCHEDULER        75900020
LRDABXMT DC    V(IHKABXMT)         ENTRY POINT OF ROUTINE WHICH    000A 75950020
*                                  TRANSMITS AN ERROR MESSAGE      000A 76000020
LRDABLRD DC    A(IHKABLRD+2)       TO SET BASE REGISTER                 76050020
LRDCDFLN DC    A(IHKCDFLN)         ADDRESS OF LENGTH OF FAST TABLE      76100020
LRDCDSOC DC    A(IHKCDSOC)         RJETABLE ADDRESS                     76150020
LRDCDTDR DC    A(IHKCDTDR)         START OF TERMINAL DIRECTORY ENTRIES  76200020
LRDZZAVT DC    A(IHKCACOM)         ADDRESS OF AVT CONSTANTS             76250020
         SPACE 2                                                   000A 76300020
LRDEXLST DC    X'88'                                               000A 76350020
         DC    AL3(LRDOUTSP)       OUT OF SPACE ROUTINE            000A 76400020
         CNOP  0,8                                                19018 76450020
LRDUPDEC DS    2F                  FOR UNPACKED DECIMAL           19018 76500020
LRDDECNO DS    2F                  FOR PACKED DECIMAL             19018 76550020
OTHRBASE DC    A(LRDNOTCM)        BASE FOR FOR DD CARD PROCESSINGA26537 76600020
         DROP  12                                                       76650020
SUBASE   EQU   12                                                A26537 76700020
         USING *,SUBASE                                          A26537 76750020
LRDNOTCM DS    0H                                                A26537 76800020
         ST    R10,LRDSSTO         STORE IN PARAMETER LIST       A26537 76850020
         LA    R10,2(R3)           GET STARTING ADDRESS FOR SCAN A26537 76900020
         ST    R10,LRDSADD         STORE IN PARAMETER LIST       A26537 76950020
         MVI   LRDSBLN+1,LRDFSTB   TO SEARCH FOR FIRST BLANK CHARA26537 77000020
         BAL   R9,LRDSCJC          SCAN TO BLANK CHARACTER       A26537 77050020
         ST    R1,LRDSADD          STORE STARTING ADDRESS FOR    A26537 77100020
*                                  SCAN                          A26537 77150020
         L     R14,LRDSVBL        LOAD ADDRESS OF PTR TO BLANK   A26537 77200020
         ST    R1,0(R14)          PUT ADDRESS IN THAT AREA       A26537 77250020
         SR    R1,R10              SUBTRACT STARTING ADDRESS OF  A26537 77300020
*                                  NAME                          A26537 77350020
*                                  FROM END TO GET NUMBER OF     A26537 77400020
*                                  CHARACTERS                    A26537 77450020
         STH   R1,LCBCHARS         SAVE NUMBER OF CHARACTERS     A22268 77500020
         MVI   LRDSBLN+1,X'00'    SEARCH FOR NON BLANK CHARACTER A26537 77550020
         BAL   R9,LRDSCJC          SCAN TO NON-BLANK CHARACTER   A26537 77600020
         CLC   0(4,R1),LRDJO       TEST FOR JOB CARD             A26537 77650020
         LA    R14,FOURT          SET FOR ENTRY TO BRANCH TBL    A26537 77700020
         BE    BRNTABL            BRANCH IF FOUND                A26537 77750020
         TM    TDIRSWCH+1,TDIRJEDN TEST JED SWITCH               A26537 77800020
         LA    R14,EIGHTT         SET FOR ENTRY TO BRANCH TBL    A26537 77850020
         BO    BRNTABL            BRANCH IF ON                   A26537 77900020
         TM    TDIRSWCH+2,TDIRJCLN TEST JCL SWITCH               A26537 77950020
         LA    R14,TWELV          SET FOR ENTRY TO BRANCH TABL   A26537 78000020
         BC    14,BRNTABL         IF NOT ON MISSING JOB CARD     A26537 78050020
         CLC   0(3,R1),LRDD        TEST FOR DD CARD              A26537 78100020
         LA    R14,SIXTEEH        SET FOR ENTRY TO BRANCH TABL   A26537 78150020
         BC    7,BRNTABL          IF NOT DD  CARD                A26537 78200020
         LA    R10,2(R1)           GET ADDRESS OF BLANK AFTER DD A26537 78250020
         ST    R10,LRDSADD         STORE AS STARTING ADDRESS FOR A26537 78300020
*                                  SCAN                          A26537 78350020
         BAL   R9,LRDSCJC          SCAN TO NON-BLANK CHARACTER   A26537 78400020
         SR    R9,R9               CLEAR REGISTER 9              A26537 78450020
         STH   R9,LCBPARM3+2       PUT 0 IN LCBPARM3 FOR ALC     A26537 78500020
         CLC   0(2,R1),LRDASTB     CHECK FOR BLANK AFTER DD *    A26537 78550020
         LA    R14,TWENT          SET FOR ENTRY TO BRANCH TABL   A26537 78600020
         BE    BRNTABL            YES IGNORE DCB PARAM ROUNTINE  A26537 78650020
         CLC   0(5,R1),LRDDAT      CHECK FOR BLANK AFTER DD DATA A26537 78700020
         LA    R14,THIRTY36       SET ENTRY TO BRANCH TABLE      A26537 78750020
         BE    BRNTABL             IF THERE IGNORE DCB PARAM ROUTA26537 78800020
         CLC  0(2,R1),LRDASTCM     CHECK FOR COMMA AFTER DD *    A26537 78850020
         BE    LRDACOMA            BRANCH AROUND CHECK FOR DD    A26537 78900020
*                                  DATA                          A26537 78950020
         CLC   0(5,R1),LRDATACM    CHECK FOR COMMA AFTER DD DATA A26537 79000020
         LA    R14,SIXTEEH        SET FOR ENTRY TO BRANCH TABL   A26537 79050020
         BNE   BRNTABL            IF NOT DD DATA OR * BRANCH     A26537 79100020
         OI    TDIRSWCH,TDIRDDDN   TURN ON DD DATA SWITCH        A26537 79150020
         LA    R1,5(R1)            GET ADDRESS OF BYTE AFTER DATAA26537 79200020
         B     LRDONECM                                          A26537 79250020
WORK     DS    D                                                 A26537 79300020
LRDPACK  PACK  WORK(8),0(0,R10)                                  A26537 79350020
LRDACOMA OI    TDIRSWCH,TDIRDDAN   TURN ON DD * SWITCH           A26537 79400020
         LA    R1,2(R1)            GET ADDRESS OF BYTE AFTER DD *A26537 79450020
LRDONECM CLC   0(4,R1),LRDCBPRM    CHECK FOR DCB=                A26537 79500020
         BNE   LRDUNDEF            IF NOT THERE GO TO ERROR      A26537 79550020
*                                  ROUTINE                       A26537 79600020
         LA    R1,4(R1)            UPDATE COUNTER TO SUBPARAMETERA26537 79650020
         CLI   0(R1),C'('          CHECK FOR ( BEFORE            A26537 79700020
*                                  SUBPARAMETER                  A26537 79750020
         BNE   LRDBUFCK            IF NOT THERE BRANCH           A26537 79800020
         OI    LCBPARM3,TIOSDSP2   SET PARENTHESIS SWITCH        A26537 79850020
         LA    R1,1(R1)            IF THERE IGNORE IT            A26537 79900020
         BAL   R9,LRDTOCOM         CHECK FOR MULTIPLE COMMAS     A26537 79950020
LRDBUFCK CLC   0(6,R1),LRDBUFNO    CHECK FOR BUFNO PARAMETER     A26537 80000020
         BNE   LRDBLKSI            IF NOT THERE BRANCH           A26537 80050020
         MVI   LRDSBLN+1,X'03'     SET UP PARAMETER FOR SCAN     A26537 80100020
         ST    R1,LRDSADD          STARTING POINT FOR SCAN       A26537 80150020
         LA    R1,20(R1)           STOPPING POINT FOR SCAN       A26537 80200020
         ST    R1,LRDSSTO          STORE IN PARAMETER LIST       A26537 80250020
         BAL   R9,LRDSCJC          SCAN TO BLANK, COMMA OR R     A26537 80300020
*                                  PARENTHESIS                   A26537 80350020
         CLI   0(R1),C','          IS IT A COMMA?                A26537 80400020
         BNE   LRDFRMAT            IF NOT BLKSIZE WAS NOT        A26537 80450020
*                                  SPECIFIED                     A26537 80500020
         LA    R1,1(R1)            GO TO ADDRESS AFTER COMMA     A26537 80550020
         BAL   R9,LRDTOCOM         CHECK FOR MULTIPLE COMMAS     A26537 80600020
LRDBLKSI CLC   0(8,R1),LRDBLOCK    CHECK FOR BLKSIZE PARAMETER   A26537 80650020
         BNE   LRDUNDEF            IF NOT GO TO ERROR ROUTINE    A26537 80700020
         LA    R1,8(R1)            GET ADDRESS OF BLKSIZE PARAM  A26537 80750020
         ST    R1,LRDSADD          STORE STARTING POINT FOR SCAN A26537 80800020
         LR    R10,R1              SAVE ADDRESS OF BLKSIZE PARAM A26537 80850020
         LA    R1,10(R1)           SET STOPPING POINT FOR SCAN   A26537 80900020
         ST    R1,LRDSSTO          STORE IT IN PARAMETER LIST    A26537 80950020
         MVI   LRDSBLN+1,X'03'  NUMBER OF CHARACTERS SCANNED FOR A26537 81000020
         BAL   R9,LRDSCJC          SCAN TO BLANK,COMMA, OR )     A26537 81050020
         LR    R9,R1               SAVE ADDRESS OF DELIMETER     A26537 81100020
         SR    R1,R10              DETERMINE LENGTH OF PARAMETER A26537 81150020
         LTR   R1,R1               IS BLKSIZE = BLANK ?          A26537 81200020
         BZ    LRDINVAL            IF SO, LET HIM KNOW           A26537 81250020
         LR    R14,R1              GET LENGTH OF PARAM FOR BCT   A32862 81300020
LRDHARVD TM    0(R10),X'F0'        IS THIS BYTE NUMERIC ?        A32862 81350020
         BNO   LRDINVAL            NO? THST'S A BADIE            A32862 81400020
         LA    R10,1(R10)          POINT TO THE NEXT BYTE AND    A32862 81450020
         BCT   R14,LRDHARVD        CHECK IT THE SAME WAY         A32862 81500020
         SR    R10,R1              RESTORE POINTER TO BLKSIZE    A32862 81550020
         BCTR  R1,0                                              A27468 81600020
         EX    R1,LRDPACK          PACK THE BLKSIZE WITH THEM    A26537 81650020
         CVB   R1,WORK             CONVERT BLKSIZE TO BINARY     A26537 81700020
         LTR   R1,R1               CHECK FOR BLKSIZE OF ZERO     A26537 81750020
         BC    12,LRDINVAL         IF SO GO TO ERROR ROUTINE     A26537 81800020
         LA    R14,400             CHECK TO SEE THAT BLKSIZE IS  A26537 81850020
*                                  NOT                           A26537 81900020
         CR    R1,R14              GREATER THAN 400              A26537 81950020
         BH    LRDFORMT            IF SO, USE BLKSIZE IN PROC    A26537 82000020
         SR    R14,R14             CLEAR REG 14 FOR DIVIDE       A26537 82050020
         LR    R15,R1              PUT PARAM IN REG 15 FOR DIVIDEA26537 82100020
         LA    R1,80               CHECK TO SEE THAT THE BLKSIZE A26537 82150020
*                                  IS                            A26537 82200020
         DR    R14,R1              A MULTIPLE OF 80 BY DIVIDING  A26537 82250020
*                                  AND                           A26537 82300020
         LTR   R14,R14             TESTING FOR REMAINDER         A26537 82350020
         BC    7,LRDINVAL          IF NOT GO TO ERROR ROUTINE    A26537 82400020
         MH    R15,EIGHTTY         MULTIPLY TO GET PARAMETER BACKA26537 82450020
         STH   R15,LCBPARM3+2      STORE BLKSIZE FOR ALLOCATION  A26537 82500020
LRDFORMT LR    R1,R9               CHECK FORMAT OF CARD          A26537 82550020
LRDFRMAT CLI   0(R1),C' '          IS IT A BLANK ?               A26537 82600020
         BE    LRDSWHON            IF SO, SEE IF PAREN SWITCH IS A26537 82650020
*                                  ON                            A26537 82700020
         CLI   0(R1),C','          IS IT A COMMA ?               A26537 82750020
         BNE   LRDSWHOF            IF NOT, SEE IF PAREN SWITCH ONA26537 82800020
         BAL   R9,LRDTOCOM         CHECK FOR MULTIPLE COMMAS     A26537 82850020
LRDPARAM CLC   0(6,R1),LRDBUFNO    CHECK FOR BUFNO PARAMETER     A26537 82900020
         BNE   LRDUNDEF            IF NO, GO TO ERROR ROUTINE    A26537 82950020
         ST    R1,LRDSADD          STARTING POINT FOR SCAN       A26537 83000020
         LA    R1,10(R1)           GET STOPPING POINT FOR SCAN   A26537 83050020
         ST    R1,LRDSSTO          STORE IN PARAMETER LIST       A26537 83100020
         MVI   LRDSBLN+1,X'02'     NUMBER OF CHARACTERS SCANNED  A26537 83150020
         BAL   R9,LRDSCJC          SCAN FOR BLANK OR RIGHT PAREN A26537 83200020
         CLI   0(R1),C' '          IS IT A BLANK ?               A26537 83250020
         BE    LRDSWHON            IF SO, SEE IF PAREN SWITCH IS A26537 83300020
*                                  ON                            A26537 83350020
LRDSWHOF TM    LCBPARM3,TIOSDSP2   IS PAREN SWITCH ON ?          A26537 83400020
         BC    12,LRDUNDEF         IF NOT SEND ERROR MESSAGE     A26537 83450020
         B     LRDOFFSW                                          A26537 83500020
LRDSWHON TM    LCBPARM3,TIOSDSP2   IS PAREN SWITCH ON ?          A26537 83550020
         BO    LRDUNDEF            IF SO, SEND ERROR MESSAGE     A26537 83600020
LRDOFFSW NI    LCBPARM3,X'00'      TURN OFF PAREN SWTCH          A26537 83650020
         LA    R14,TWENT28        SET FOR ENTRY TO BRANCH TABL   A26537 83700020
         B     BRNTABL            RETURN TO MAIN ROUNTINE        A26537 83750020
LRDTOCOM CLI   0(R1),C','          CHECK FOR MULTIPLE COMMAS     A26537 83800020
         BCR    7,R9               IF NOT A COMMA BRANCH         A26537 83850020
         LA    R1,1(R1)            IF IT IS A COMMA, IGNORE IT   A26537 83900020
         B     LRDTOCOM            CHECK FOR MORE MULTIPLE COMMASA26537 83950020
LRDUNDEF LA    R0,LRDXM56         GET PARAMTER FOR XMT           A26537 84000020
         LA    R14,THIRTY32       SET FOR ENTRY TO BRANCH TABL   A26537 84050020
         B     BRNTABL            TRANSMIT ERROR MESSAGE         A26537 84100020
LRDINVAL LA    R0,LRDXM60         GET PARAMETER FOR XNT          A26537 84150020
         LA    R14,THIRTY32       SET FOR ENTRY TO BRANCH TABL   A26537 84200020
         B     BRNTABL            TRANSMIT ERROR MESSAGE         A26537 84250020
LRDSCJC  LA    R1,LRDSCA           GET ADDRESS OF PARAMETER LIST A26537 84300020
         L     R15,LRDCCSC         GET ADDRESS OF SCAN ROUTINE   A26537 84350020
         BALR  R14,R15             CALL SCAN TO FIND CHARACTER   A26537 84400020
         LTR   R15,R15             TEST RETURN CODE              A26537 84450020
         BCR   7,R9                IF FOUND, RETURN              A26537 84500020
         TM    TDIRSWCH+2,TDIRJCLN IS JCL SWITCH ON              A26537 84550020
         LA    R14,TWELV          SET FOR ENTRY TO BRANCH TABL   A26537 84600020
         BZ    BRNTABL            NO,STATEMENT INVALID           A26537 84650020
         LA    R14,SIXTEEH        SET FOR ENTRY TO BRANCH TABL   A26537 84700020
         B     BRNTABL            IF ON IT'S OK                  A26537 84750020
BRNTABL  EQU   *                                                 A26537 84800020
         LR    R15,R12            SET NEW BASE                   A26537 84850020
         DROP  12                                                A26537 84900020
         USING LRDNOTCM,R15                                      A26537 84950020
         L     R12,LRDBASE        SET BASE FOR MAIN ROUTINE      A26537 85000020
         B     *+4(14)            BRANCH INTO BRANCH TABLE       A26537 85050020
         DROP  15                                                A26537 85100020
         USING IHKABLRD+2,R12                                    A26537 85150020
         B     LRDJOBCD                                          A26537 85200020
         B     LRDJEDSW                                          A26537 85250020
         B     LRDNOJOB                                          A26537 85300020
         B     LRDJCLBF                                          A26537 85350020
         B     LRDDDAST                                          A26537 85400020
         B     LRDDDCRD                                          A26537 85450020
         B     LRDCLXMT                                          A26537 85500020
         B     LRDDDATA                                          A25637 85550020
LRDCCSC  DC    V(IHKCCSCN)        ENTRY OF SCAN ROUTINE          A26537 85600020
LRDSCA   DC    H'0'                                              A26537 85650020
LRDSBLN  DC    H'0'                                              A26537 85700020
LRDSADD  DC    F'0'               STARTING ADDRESS OF SCAN       A26537 85750020
LRDSSTO  DC    F'0'               STOPPING ADDRESS OF SCAN       A26537 85800020
LRDCHA   DC    C' '                                              A26537 85850020
         DC    C'),'               ON RIGHT PAREN OR COMMA       A26537 85900020
LRDJO    DC    C'JOB '                                           A26537 85950020
LRDD     DC    C'DD '             TEST FOR DD CARD               A26537 86000020
LRDASTB  DC    C'* '              TEST FOR * BLANK               A26537 86050020
LRDDAT   DC    C'DATA '           TEST FOR DD DATA CARD          A26537 86100020
LRDASTCM DC    C'*,'                                             A26537 86150020
LRDATACM DC    C'DATA,'                                          A26537 86200020
LRDCBPRM DC    C'DCB='                                           A26537 86250020
LRDBUFNO DC    C'BUFNO='                                         A26537 86300020
LRDBLOCK DC    C'BLKSIZE='                                       A26537 86350020
EIGHTTY  DC    H'0080'                                           A26537 86400020
LRDXM56  EQU   56                 CODE FOR IMPROPER DD CARD      A26537 86450020
LRDXM60  EQU   60                 CODE FOR IMPROPER DD CARD      A26537 86500020
LRDSVBL  DC    A(LRDSVBLK)                                       A26537 86550020
LRDBASE  DC    A(IHKABLRD+2)      BASE FOR MAIN ROUTINE          A26537 86600020
FOURT    EQU   0                  INDEX INTO BRANCH TABLE        A26537 86650020
EIGHTT   EQU   4                  INDEX INTO BRANCH TABLE        A26537 86700020
TWELV    EQU   8                  INDEX INTO BRANCH TABLE        A26537 86750020
SIXTEEH  EQU   12                 INDEX INTO BRANCH TABLE        A26537 86800020
TWENT    EQU   16                 INDEX INTO BRANCH TABLE        A26537 86850020
TWENT28  EQU   20                 INDEX INTO BRANCH TABLE        A26537 86900020
THIRTY32 EQU   24                 INDEX INTO BRANCH TABLE        A26537 86950020
THIRTY36 EQU   28                 INDEX TO BRANCH TABLE          A26537 87000020
LRDFSTB  EQU   X'01'              SCAN FOR FIRST BLANK CHARACTER A26537 87050020
         EJECT                                                          96060000
         IEFQMNGR                  QUEUE MANAGER PARAMETER AREA         96120000
QMPCA    DS    CL4                 BUFFER ADDRESS OR TTR FROM ASSIGN    96180000
QMPEX    DS    CL4                 TTR FOR WRITE                        96240000
QMCHN    DS    CL4                 TTR FOR NEXT WRITE                   96300000
         EJECT                                                          96360000
LRDQMRES DSECT                                                          96420000
         IEFQMRES                  QUEUE MANAGER RESIDENT AREA          96480000
         EJECT                                                          96540000
         IECTDECB                                                       96600000
         EJECT                                                          96660000
         DCBD   DSORG=(BS,BX),DEVD=(DA,BS)                         000E 96720000
         EJECT                                                          96780000
LRDTIOT1 DSECT                                                          96840000
         IEFTIOT1                                                       96900000
         EJECT                                                          96960000
LRDCVT   DSECT                                                          97020000
         CVT                                                            97080000
         IHKDSECT TDIR                                                  97140000
TDIRNQJM EQU   X'CF'               TURN OFF ENQUEUE JOBS AND ENQUEUE    97200000
*                                  MESSAGES BITS                        97260000
TDIRSYSF EQU   X'3F'               TURN OFF DD DATA AND DD * SWITCHES   97320000
TDIRSYSN EQU   X'C0'               TEST DD DATA AND DD * SWITCHES       97380000
TDIRRJLF EQU   X'E7'               TURN OFF RJSTART AND LOGON SWITCHES  97440000
TDIRRJLG EQU   X'18'               TEST RJSTART AND LOGON SWITCHES      97500000
TDIRDARF EQU   X'3E'               TURN OFF DD DATA, DD *, NO RJENDF    97560000
TDIRJDIP EQU   X'FA'               TURN OFF JED AND DISCONTINUED INPUT  97620000
         IHKDSECT ,,FASTAB                                              97680000
         IHKDSECT ,,,,,AVT                                              97740000
         IHKDSECT ,,,,LCB                                               97800000
LCBSWOFF EQU   X'00'               TO TURN OFF LCB SWITCHES             97860000
LCBNQBIT EQU   X'80'               INDICATE CARDS TO ENQUEUE       000A 97920000
LCBNQOFF EQU   X'7F'               INDICATE NO CARDS TO ENQUEUE    000A 97980000
LCBERRSW EQU   X'40'               INDICATE RETURN 8 TO IHKABLST        98040000
LCBSTRJE EQU   X'20'               INDICATE RETURN OF ZERO TO LST       98100000
LCBRJNDF EQU   X'10'               INDICATE RJENDF GENERATED       000A 98160000
LCBLST28 EQU   X'08'               INDICATE RETURN 28 TO IHKABLST  000A 98220000
         END                                                            98280000
