LST8   TITLE    'IHKABLST -- LINE SCHEDULER'                            00100019
IHKABLSD CSECT                                                          00200019
*1210515000-518000,642000                                          000B 00300019
*2561697000                                                        1657 00400019
* 258000,261000,359600,485000,487000,492000,495000,506000,511000   000D 00500019
* 512000,518000-519000,540000,5590,003000-009000                   000D 00600019
* 744000,747000                                                  A29519 00630020
*                                                                A28208 00660020
*D253500                                                         A35889 00666020
*A252500                                                         A35889 00672020
*C807000,808000                                                  A37785 00678020
*D501000                                                         A37794 00684020
*C281000,539000,583000                                           A37794 00690020
*A126500,148400,149200-149600,151100-151500,160300-160600        A43087 00692021
*A774100-774900,847100-847500                                    A43087 00694021
*C148800                                                         A43087 00696021
*D638000,708000                                                  A47940 00696621
*A248100-248700,608020-608840,638000-638500                      A47940 00697221
*C220000,222000,319000,352000,640000                             A47940 00697821
*A792200-792600                                                  A53111 00698421
*C702000,714000,790000,798000                                    A53111 00699021
*D769000                                                         A60657 00700021
*A769000-769600                                                  A60657 00740021
*                                                                     * 00780021
         ENTRY IHKABLST                                                 00820021
         EXTRN IHKCACOM                                                 00860021
*********************************************************************** 00900019
*TITLE LINE SCHEDULER 'IHKABLST'                                      * 01000019
*                                                                     * 01100021
*STATUS: CHANGE LEVEL 2, RELEASE 21.7                                 * 01150021
*                                                                     * 01200019
*FUNCTION/OPERATION: THE BASIC FUNCTIONS OF THE LINE SCHEDULER ARE:   * 01300019
*   1. CHECKS FOR QUEUED OUTPUT ON THE TERMINAL QUEUE.                * 01400019
*   2. DOES A READ/INITIAL TO ESTABLISH CONTACT WITH THE REMOTE.      * 01500019
*    A TESTS AFTER ATTEMPTED I/O TO DETERMINE THAT THE CONTROL UNIT IS* 01600019
*    STILL OPERATIONAL.IF NOT SENDS THAT LINE SUB TASK TO THE DISPATCH* 01700019
*    TO WAIT FOR A CLOSE DOWN                                         * 01800019
*   3. HALTS ACTIVITY ON EACH LINE TO INITIATE THE STOP RJE           * 01900019
*   4. RJENDS EACH ACTIVE TERMINAL AFTER A WARMSTART                  * 02000019
*   5. OPENS THE DCBS FOR THE LINES                                   * 02100019
*    A TESTS THE OPEN FLAGS FOR THE LINE DCB AND IF THE DCB DID NOT   * 02200019
*    OPEN, IT PRINTS A MESSAGE INDICATING IT COULD NOT AND SEND THAT  * 02300019
*    SUB TASK TO THE DISPATCHER TO AWAIT A RJE CLOSEDOWN.             * 02400019
*   6. FLAGS EACH LINE CONTROL BLOCK TO INDICATE WHAT TYPE OF LINE THE* 02500019
*      LCB IS ASSOCIATED                                              * 02600019
*                                                                     * 02700019
*ENTRY POINT                                                          * 02800019
*        IHKABLSD                                                     * 02900019
*   THIS ENTRY POINT DOES THE OPENS FOR THE LINE AND FLAGS THE LCB AS * 03000019
*   TO THE TYPE OF LINE                                               * 03100019
*        IHKABLST                                                     * 03200019
*   THIS ENTRY POINT IS A BRANCH TABLE. THE SPECIFIC ENTRY INTO THE   * 03300019
*   BRANCH TABLE IS DETERMINED BY THE RETURN CODE IN REGISTER 15. THE * 03400019
*   FOLLOWING CODES DETERMINE THE FUNCTION NEEDED BY THE RETURNING    * 03500019
*   SUB-ROUTINE.                                                      * 03600019
*                                                                     * 03700019
*   O-NORMAL RETURN. LINE SCHEDULER WILL DO ITS NORMAL FUNCTIONS      * 03800019
*   4-GO TO IHKABREQ. LINE ANALYSIS WRITE RETURNS TO THIS POINT       * 03900019
*     BECAUSE THE LINE SCHEDULER CALLED IT TO SEND OUTPUT AND IT WAS  * 04000019
*     UNABLE TO DO SO.                                                * 04100019
*   8-GO TO IHKABEOT THIS SUB-ROUTINE SWAPS EOTS WITH THE REMOTE TERM-* 04200019
*     INAL ON A SWITCHED LINE. UNTIL AN ENQ IS RECEIVED INDICATING THE* 04300019
*     REMOTE WISHES TO SEND INPUT, OR UNTIL THERE IS OUTPUT TO SEND   * 04400019
*     THE REMOTE.                                                     * 04500019
*   12-EXITS TO LINE ANALYSIS WRITE ROUTINE BECAUSE LINE ANALYSIS READ* 04600019
*     HAS RUN OUT OF SPACE TO SPOOL THE INPUT.                        * 04700019
*   16-EXIT TO RJENDF ROUTINE. THIS IS A RETURN EXIT THROUGH THE LINE * 04800019
*     SCHEDULER FROM THE LINE ANALYSIS WRITE ROUTINE TO THE LINE      * 04900019
*     ANALYSIS READ TO BUILD AN RJENDF.                               * 05000019
*   20-EXITS TO THE DISPATCHER TO WAIT FOR THE LINE ANALYSIS READ TO  * 05100019
*   24-RETURN CODE INDICATES A NORMAL RETURN FROM LINE ANALYSIS READ  * 05200019
*     ON A SWITCHED LINE.                                             * 05300019
*     GET QUEUE SPACE. THIS SITUATION ARISES WHEN THE LINE SCHEDULER  * 05400019
*INPUT:400 CHARACTER RECORDS  FIVE 80-CHARACTER CARD IMAGES           * 05500019
*     REQUESTS LINE ANALYSIS READ TO ENQUEUE A RJENDF OR RJENDC.      * 05600019
*                                                                     * 05700019
*OUTPUT: THE OUTPUT IS THE INPUT RECEIVED BY THE READ/INITIAL         * 05800019
*                                                                     * 05900019
*EXTERNAL ROUTINES                                                    * 06000019
*        IHKAADSP- DISPATCHER CONTAINS MULTIPLE WAIT                  * 06100019
*        IHKABLRD- LINE ANALYSIS(READ). STRIPS DATA LINK CONTROL      * 06200019
*   CHARACTERS AND WRITES INPUT TO DISK.                              * 06300019
*        IHKABLWR- LINE ANALYSIS(WRITE). WRITE OUTPUT TO REMOTE WORK  * 06400019
*   STATIONS.                                                         * 06500019
*                                                                     * 06600019
*EXITS-NORMAL                                                         * 06700019
*   REGISTER 15 CONTAINS ADDRESS POINTER TO:                          * 06800019
*        IHKAADSP                                                     * 06900019
*        IHKABLRD                                                     * 07000019
*        IHKABLWR                                                     * 07100019
*                                                                     * 07200019
*EXITS-ERROR:                                                         * 07300019
*        IHKABRJF-ENTRY POINT IN IHKABLRD TO BUILD RJENDF.            * 07400019
*        IHKAADSP-ERROR ON OPEN OR BAD CONTROL UNIT                   * 07500019
*                                                                     * 07600019
*TABLES/WORK AREAS:                                                   * 07700019
*   LINE CONTROL BLOCK- CONTROL BLOCK WHICH CONTAINS POINTERS TO OTHER* 07800019
*   CONTROL BLOCKS AND BUFFERS.                                       * 07900019
*                                                                     * 08000019
*ATTRIBUTES:RE-ENTRANT                                                * 08100019
*NOTES - THE OPERATION OF THIS SUBROUTINE DEPENDS UPON AN INTERNAL    * 08200019
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 08300019
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED SO* 08400019
*   THAT REDEFINITION OF CHARACTER-TYPE CONSTANTS, BY REASSEMBLY, WILL* 08500019
*   RESULT IN A CORRECT MODULE FOR THE NEW DEFITION.                  * 08600019
*********************************************************************** 08700019
R0       EQU   0                                                        08800019
R1       EQU   1                                                        08900019
R2       EQU   2                                                        09000019
R3       EQU   3                                                        09100019
R4       EQU   4                                                        09200019
R5       EQU   5                                                        09300019
R6       EQU   6                                                        09400019
R7       EQU   7                                                        09500019
R8       EQU   8                                                        09600019
R9       EQU   9                                                        09700019
R10      EQU   10                                                       09800019
R11      EQU   11                                                       09900019
R12      EQU   12                                                       10000019
R13      EQU   13                                                       10100019
R14      EQU   14                                                       10200019
R15      EQU   15                                                       10300019
LSTOPN   EQU   X'12'    OPENS FLAG SETTINGS FOR SUCCESSFUL OPEN         10400019
LSTSTPB  EQU   X'80'     STOP RJE BIT  SET BY  IHKCASTP                 10500019
LSTWRMB  EQU   X'40'     WARMSTART BIT SET BY  IHKCBSDQ                 10600019
LSTWJDAB EQU   X'20'     WAIT ON SYSDEQ BIT SET BY INKCBSDQ             10700019
LSTDCNTC EQU   X'02'     DISCONTINUE SWITCH SET BY CONTENTION ON LINE   10800019
LSTDCNT  EQU   X'80'     DISCONTINUE SWITCH SET BY DISCONTINUE ABORT    10900019
LSTCONTT EQU   X'60'     CONTINUE SWITCH INDICATORS SET BY A CONTINUE   11000019
LSTEOT   EQU   X'37'     FOR EOT IN DECB RESPONSE FIELD                 11100019
LSTENQ   EQU   X'2D'     FOR ENQ IN DECB RESPONSE FIELD                 11200019
DEBUCBAD EQU   32        DISPLACEMENT VALUE IN DEB FOR UCB ADDRESS      11300019
UCBTBYT2 EQU   17        DISPLACEMENT VALUE IN UCB FOR DEVICE TYPE      11400019
LSTDISAB EQU   X'02'     SWITCH INDICATING A DISABLED SWITCHED LINE     11500019
LSTRJSTR EQU   X'10'     TEST IF RJSTART SWITCH IS SET     **********   11600019
LSTTEN   EQU   X'10'                                                    11700019
LSTTWO   EQU   2         THIS VALUE IS THE LENGTH OF THE POLLING CHA-   11800019
LSTTYMDL EQU   X'40'    UCB INDICATES A MULTI-DROP LINE                 11900019
LSTTYSW  EQU   X'10'    UCB INDICATES A SWITCHED LINE                   12000019
*                        ACTERS IN THE TERMINAL TABLE                   12100019
UCBNAME  EQU   13                  OFFSET IN UCB TO UCBNAME             12200019
LSTTHREE EQU   X'03'               NUMBER OF CHARS MOVED INTO MGS1      12300019
LSTMSIN2 EQU   18                                                       12400019
LSTMSIN1 EQU   35                                                       12500019
LSTEIGHT EQU   X'08'               NUMBER OF CHARS MOVED INTO MSG1      12600019
LSTWTMOD EQU   X'20'                    WORLD TRADE MODEM SWITCH A43087 12650021
*********************************************************************** 12700019
* THIS ROUTINE SETS AN INDICATOR IN THE LCB TO INDICATE THE TYPE OF   * 12800019
* TERMINALS THAT ARE HOOKED TO THIS PARTICULAR LINE. THIS ROUTINE     * 12900019
* ONCE FOR EACH LINE                                                  * 13000019
*********************************************************************** 13100019
         USING *,R14                                                    13200019
         USING LCBDSECT,R2                                              13300019
         USING IECTDECB,R3                                              13400019
         USING IHADCB,R4                                                13500019
         USING IHKZZAVT,R5                                              13600019
         B     Z                                                        13700019
         DC    C'IHKABLST'                                              13800019
Z       EQU   *                                                         13900019
         L     R3,LCBLDECB         USING LCB POINTER IN REG2 THE DECB   14000019
         L     R4,DECDCBAD         POINTER IS LOADED FROM THE LCB. FROM 14100019
         OPEN  ((4))               THE DECB AN ADDRESS OF THE DCB.      14200019
         L     R12,LSTABLST        SETS BASE                            14300019
         TM    DCBOFLGS,LSTOPN      TEST OPEN FLAGS                     14400019
         BNO   LSTDDMSS            NO GO TO WRITE MSG                   14500019
         L     R5,DCBDEBAD         THE DCB  AN ADDRESS OF THE DEB. FROM 14600019
         L     R6,DEBUCBAD(R5)     THE DEB AN ADDRESS TO THE UCB.       14700019
         TM    UCBTBYT2(R6),LSTTYMDL THE UCB RJE DETERMINES THE TYPE OF 14800019
*                                       LINE LCB IS USED FOR     A43087 14840021
         BO    LSTVERMP                 VERIFY THAT LINE WAS     A43087 14880021
*                                       DEFINED AS MULTI-PT IN   A43087 14920021
*                                       RJELINE MACRO            A43087 14960021
         TM    UCBTBYT2(R6),LSTTYSW  LCB IS FLAG WITH A                 15000019
         BO    LSTSW                   FF= A SWITCHED LINE              15100019
         TM    LCBLDECB,LSTWTMOD        VERIFY THAT PT/PT LINE   A43087 15110021
         BO    LSTERR                   HAS NOT BEEN DEFINED AS  A43087 15120021
         L     R8,LCBDFTRM              SWITCHED LINE VIA        A43087 15130021
         CLI   LSTZEROO(R8),LSTANST     RJELINE MACRO            A43087 15140021
         BE    LSTERR                                            A43087 15150021
         MVI   LCBTYPLN,LCBPTPT        FE= A POINT TO POINT             15200019
         B     LSTSEBAS                FD= A MULTI POINT                15300019
*                                                                       15400019
*                                  ONCE INITIALIZED AT START UP TIME    15500019
*                                  PART OF THE LINE SCHEDULER IS NEVER  15600019
*                                  RE-ENTERED.                          15700019
*                                                                       15800019
LSTSW    MVI   LCBTYPLN,LCBSWTCH   INDICATE SWITCHED LINE               15900019
         B     LSTSEBAS                                                 16000019
LSTVERMP CLI   LCBTABNM,LSTDZERO        IF MP LINE THIS LCB      A43087 16030021
         BE    LSTERR                   FIELD SHOULD NOT BE ZERO A43087 16060021
LSTMP    MVI   LCBTYPLN,LCBMULPT   INDICATE MULTI-POINT LINE            16100019
LSTSEBAS XR    R15,R15             SETS RETURN CODE FOR ENTRY      000A 16200019
*********************************************************************** 16300019
*   THE  FOLLOWING IS A BRANCH TABLE THAT DETERMINES WHAT FUNCTION    * 16400019
*   HAS BEEN COMPLETED THIS IN TURN TELLS THE LINE SCHEDULER WHICH    * 16500019
*   FUNCTION MUST FOLLOW                                              * 16600019
*        THE RETURN CODE IN REGISTER 15 ARE                           * 16700019
*          0   GO TO LSTBEGIN                                         * 16800019
*          4   GO TO IHKABREQ                                         * 16900019
*          8   GO TO IHKABEOT                                         * 17000019
*          12  EXIT TO IHKABLWR                                       * 17100019
*          16  EXIT TO RJENDF ROUTINE                                 * 17200019
*          20  EXIT TO OUT OF SPACE RJEND                             * 17300019
*          24  NORMAL RETURN ON SWITCHED FROM IHKABLRD                * 17400019
*          28  ENTRY TO SEND ABORT EOT                                * 17500019
*********************************************************************** 17600019
IHKABLST EQU   *                                                        17700019
         USING TDIREC,R4                                                17800019
         BALR  R12,0                                                    17900019
         USING *,R12                                                    18000019
         L     R3,LCBLDECB         SETS BASE FOR LINE DECB DSECT   000A 18100019
         L     R4,LCBTDIR          SETS BASE FOR TDIREC DSECT      000A 18200019
         B     *+4(15)                                                  18300019
         B     LSTBEGIN            NORMAL RETURN                        18400019
         B     IHKABREQ            GO DO A READ CONTINUE                18500019
         B     IHKABEOT            GO DO A WRITE EOT                    18600019
         B     LSTBYPAS            EXIT TO IHKABLWR                     18700019
         B     LSTRJLRD            EXIT TO RJENDF ROUTINE               18800019
         B     LSTOUTSP            EXIT TO OUT OF SPACE                 18900019
         B     LSTABOUT            EXIT TO CHECK OUTPUT ROUTINE         19000019
         B     LSTABORT            EXIT TO ABORT ROUTINE           000A 19100019
         B     LSTOPEN                                             000D 19200019
*********************************************************************** 19300019
*  THIS  ROUTINE   CHECKS    WHAT TYPE OF LINE ITS SERVICING. IF THERE* 19400019
*  IS ANY OUTPUT TO BE SENT. SHOULD THIS LINE BE CLOSED DOWN  IF THE  * 19500019
*  LINE IS SWITCHED HAS IT BEEN DISABLED                              * 19600019
*********************************************************************** 19700019
LSTBEGIN L     R3,LCBLDECB         SETS BASE FOR LINE DECB DSECT        19800019
         L     R4,LCBTDIR          SETS BASE FOR TDIREC DSECT           19900019
         BAL   R9,LSTWMSTP                                              20000019
         LTR   R4,R4               CHECKS LCB TO SEE IF THEIR IS A USER 20100019
         BC    8,LSTRDTI           ON THIS LINE                         20200019
         TM    TDIRSWCH+1,LSTDISAB CHECKS FOR A DISCONNECTED TERMINAL   20300019
         BZ    LSTBYPAS            IF NOT CONTINUE                      20400019
         NI    TDIRSWCH+1,TDIRDABF  RESETS DISABLE SWITCH               20500019
         XC    LCBTDIR,LCBTDIR     IF SO ZERO LCB POINTER TO TDE AND    20600019
         XC    TDIRLCB,TDIRLCB     ZERO LCB PTR IN TDE           A28208 20630020
         NI    TDIRSWCH,TDIRRJSF   TURN OFF RJSTART SWCH         A28208 20660020
         B     LSTRDTI             DO A READ INITIAL                    20700019
LSTBYPAS CLI   LCBTYPLN,LCBMULPT   CHECKS TO SEE IF THIS IS A MULTI-    20800019
         BE    LSTLSTCK            POINT LINE                           20900019
         LA    R10,LSTRDENQ       SET RETURN FROM OUTPUT CHECK ROUTINE  21000019
         B     LSTWRCHK            GO TO CHECK FOR OUTPUT ROUTINE       21100019
*********************************************************************** 21200019
* THIS ROUTINE  IS ENTERED TO DO A READ OPERATION BECAUSE OUTPUT CANT * 21300019
* BE SENT OR THERE ISNT ANY TO BE SENT                                * 21400019
*********************************************************************** 21500019
IHKABREQ EQU   *                                                        21600019
LSTDISCT BAL   R9,LSTWMSTP         CHECK FOR STP OR WRMSTART            21700019
LSTRDENQ CLI   LCBTYPLN,LCBSWTCH   CHECKS TO SEE IF THIS IS A SWITCHED  21800019
         BNE   LSTCDCHK            LINE - BRANCH IF NOT            000A 21900019
         BAL   R14,LSTCLRBF  THIS IS A READ CONTINUE TO CONTINUE A47940 22000021
         READ  (1),TT,,'S','S',MF=E ON A SWITCHED OR LEASED LINE        22100019
LSTRETST LA    R9,LSTBDRD     SET ERROR RETUN EXIT               A47940 22200021
         LA    R10,LSTLRDEX        SETS NORMAL EXIT                000A 22300019
*********************************************************************** 22400019
* THIS ROUTINE CHECKS FOR SUCCESSFUL START I/O IF GOOD PASSES         * 22500019
* CONTROL TO THE DISPATCHER TO WAIT FOR THE I/O TO FINISH. IT THEN    * 22600019
* CHECK FOR A GOOD COMPLETION CODE. IF THE COMPLETION CODE IS A X'7F'*  22700019
* IT PASSE CONTROL TO THE LINE ANALYSIS  READ ROUTINE. IF THE         * 22800019
* COMPLETION CODE IS X'48' IT GOES TO IHKABLST. IF IT IS X'41' IT     * 22900019
* RJENDFS THE TERMINAL. THIS SUBROUTINE IS USED BY BOTH BTAM READS   *  23000019
* IN THIS ROUTINE.                                                    * 23100019
*********************************************************************** 23200019
LSTRDTST C     R15,LSTERROR        CHECKS FOR OPERATIONAL CONTROL UNIT  23300019
         BE    LSTQUIT             EXIT TO MSG WRITTER                  23400019
         LTR   R15,R15             TESTS FOR A GOOD SIO OF NOT RELEASE  23500019
         LA    R8,LSTBEGIN         SETS RENTRY POINT FOR RELEASE BUFFER 23600019
         BC    7,LSTRBUFF          THE BUFFER                           23700019
         L     R15,LSTAADSP        GOES TO DISPATCHER WITH ECB POINTER  23800019
         BALR  14,15               IN REG 1                             23900019
         NI    DECTYPE,LSTTOOFF    RESET FOR BTAM ERROR MESSAGE    000A 24000019
*                                  FOR TIME OUT                    000A 24100019
         L     R14,LSTREIGH(R1)   LOAD DCB POINTER                 000D 24200019
         NI    LSTRFIVE(R14),LSTHIBTF  SET FLAG FOR IMED INTERP OFF000D 24300019
         TM    DECFLAGS,LSTHIOP    TESTS FOR NEG RETURN ON POLL    000A 24400019
         BO    LSTRBUFF            ON I/O HALTED RELEASE BUFFER    000A 24500019
         CLI   0(R1),LSTGIO        CHECK FOR GOOD I/O                   24600019
         BCR   8,R10               BRANCH TO NORMAL EXIT           000A 24700019
         BR    R9                  BRANCH TO ERROR EXIT            000A 24800019
         SPACE                                                          24810021
LSTBDRD  L     R15,DECAREA                                       A47940 24820021
         CLC   0(3,R15),STKUN  WAS STACKER UNLOAD BUTTON PRESSED A47940 24830021
         BE    REREAD              YES - BRANCH                  A47940 24840021
         CLC   0(3,R15),CDJAM      WAS THERE A CARD JAM          A47940 24850021
         BE    REREAD                   YES - BRANCH             A47940 24860021
         SPACE                                                          24870021
LSTRESPL CLI   0(R1),LSTHIO        CHECKS FOR A RESET POLL              24900019
         BE    LSTRBUFF            GOES TO RELEASE BUFFER ROUTINE       25000019
         CLI   LCBTYPLN,LCBMULPT   CHECK FOR MULTIPOINT LINE       000A 25100019
         BNE   LSTSKIP2            BRANCH IF NOT MULTIPOINT        000A 25200019
         BAL   R8,LSTRBUFF        GO DO RELEASE BUFF             A35889 25250020
         BAL   R15,LSTCKBD         IF MULTIPOINT, GO TO SUBROUT    000A 25300019
*                                    TO PUT TDIR ADDR IN LCBTDIR,  000A 25400019
*                                    SET R7 TO TERM TABLE ENTRY    000A 25500019
LSTHERE  EQU   *                                                   000A 25600019
         TM    LSTZEROO(R7),LSTHIBIT HAS THIS ERROR OCCURED BEFORE 000D 25700019
         BO    LSTLSTCK            YES, GO READ TI FOR NEXT        000A 25800019
*                                    TERM IN POLLING LIST          000A 25900019
         OI    LSTZEROO(R7),LSTHIBIT  SET ERROR FLAG               000D 26000019
         L     R4,LCBTDIR          GET TERMINAL DIRECTORY ENTRY    000A 26100019
         MVC   LSTTRMBD,TDIRTERM   INSERT TERMID INTO MSG          000A 26200019
         LA    R1,LSTBADMS         PASS MSG TO WTO                 000A 26300019
         SVC   35                  SEND TERM NOT RESPONDING MSG    000A 26400019
         B     LSTRJEDF            DOES THIS TERM NEED RJENDING    000A 26500019
LSTSKIP2 EQU   *                                                   000A 26600019
         L     R4,LCBTDIR          IS THIS ERROR ON A READ INIT    000A 26700019
         LTR   R4,R4               OPERATION. IF SO, THE LINE IS   000A 26800019
         BC    8,LSTHNGUP          NOT RJENDF                           26900019
         LA    R8,LSTRJEDF         ANY OTHER COMPLETION CODE IS         27000019
         B     LSTRBUFF            CONSIDERED AS AN ERROR               27100019
*******************************************************************000A 27200019
* THIS ROUTINE CHECKS FOR CONTENTION DISCONTINUE ON MULTI-POINT    000A 27300019
* LINE                                                             000A 27400019
*******************************************************************000A 27500019
LSTCDCHK EQU   *                                                   000A 27600019
         CLI   LCBTYPLN,LCBMULPT   CHECK FOR MULTI-POINT LINE      000A 27700019
         BNE   LSTRDTI             BRANCH IF NOT MULTI-POINT       000A 27800019
         TM    TDIRSWCH+2,TDIRCDSN CHECK FOR CONTENTION DISCONTINUE000A 27900019
         BZ    LSTLSTCK            BRANCH IF NOT                   000A 28000019
         BAL   R5,NOTEST           GET NUMBER OF POLLING CHARS.  A37794 28100020
         L     R7,LCBCTMTB         LOAD TERM TABLE POINTER         000D 28200019
         L     R5,LSTZEROO(R7)     GET CURRENT TERM TABLE POINTER  000A 28300019
CHKSYN   EQU   *                                                  M2642 28310019
         CLI   LSTZEROO(R5),LSTSYNC  CHECK FOR SYNC CHARACTER     M2642 28320019
         BNE   ALRIGHT            NO SYN LET POINTER BE           M2642 28330019
         LA    R5,LSTONE(R5)      STEP POINTER FORWARD            M2642 28340019
         BCTR  R10,0              DECREASE POINTER BY ONE         M2642 28350019
         B     CHKSYN             CHECK AGAIN                     M2642 28360019
ALRIGHT  EQU   *                                                  M2642 28370019
         EX    R10,LSTMVPOL        MOVE POLLING CHARACTER(S) FROM  000A 28400019
*                                  TERM TABLE TO DFTRMLST IN TDIR  000A 28500019
         LA    R8,TDIRDFTA+3       GET ADDRESS OF DFTRMLST FOR     000C 28600019
*                                  POLLING JUST THIS TERMINAL      000A 28700019
         B     LSTRDTIA            READ TO CLEAR LINE              000A 28800019
*********************************************************************** 28900019
* THIS IS A COMMON ROUTINE THAT DETERMINES IF THERE IS OUTPUT AND IF  * 29000019
* THERE IS CAN IT BE SENT                                             * 29100019
*********************************************************************** 29200019
LSTWRCHK L     R4,LCBTDIR          LOADS TDE POINTER                    29300019
         LTR   R4,R4               CHECKS IF POINTER EXIST              29400019
         BC    7,LSTWRCHI          IF SO CHECK FOR OUTPUT               29500019
         CLI   LCBTYPLN,LCBSWTCH   CHECK FOR SWCH LINE                  29600019
         BE    IHKABEOT            YES GO SEND EOT                      29700019
         B     LSTRDTI             NO GO DO READ INITIAL                29800019
LSTWRCHI TM    TDIRSTAT,TDIRDQNN   TEST IF DEQUEUE NOTHING IS SET  000A 29900019
         BO    LSTRETUR            IF SO RETURN                    000A 30000019
         TM    TDIRSWCH+1,LSTDCNT  CHECK IF THIS TERMINAL HAS DISCON-   30100019
         BO    LSTCONTU            TINUED OUTPUT IF SO CHECK CONTINUE   30200019
         TM    TDIRSWCH+2,LSTDCNTC CHECK FOR CONTENTION DISCONTINUE     30300019
         BO    LSTLWREX            IF SO OK TO GO TO IHKABLWR           30400019
         CLC   TDIRFQEB+1(3),LSTZEROQ  CHECKS ANY OUTPUT ENQUED FOR     30500019
         BNE   LSTLWREX            THIS TERMINAL IF SO GO TO IHKABLWR   30600019
LSTRETUR BR    R10                 RETURN TO CALLING SUB ROUTINE        30700019
LSTCONTU TM    TDIRSWCH+1,LSTCONTT CHECK IF TERMINAL HAS CONTINUED      30800019
         BZ    LSTRETUR            NO= RETURN TO CALLING SUB ROUTINE    30900019
         B     LSTLWREX            YES= GO TO IHKABLWR                  31000019
*********************************************************************** 31100019
*  THIS ROUTINE DOES A READ INITIAL  OPERATION                        * 31200019
*********************************************************************** 31300019
LSTRDTI  BAL   R9,LSTWMSTP         CHECKS TO SEE IF THE RJEND PROCEDURE 31400019
*                                  SHOULD BE ENTERED                    31500019
         CLI   LCBTYPLN,LCBMULPT   CHECK FOR MULTI-POINT LINE      000A 31600019
         BE    LSTLSTCK            YES CHECK FOR O/P FIRST         000A 31700019
LSTRDTIT L     R8,LCBDFTRM         LOADS DEFINE TERMINAL LIST POINTER   31800019
LSTRDTIA BAL   R14,LSTCLRBF   INITIALIZE FOR READ                A47940 31900021
*******************************************************************000D 32000019
*  THIS ROUTINE CHECKS FOR A SWITCHED WORLD TRADE MODEM           *000D 32100019
*******************************************************************000D 32200019
         TM     LCBFLG,LCBSWRLD   TEST FOR WORLD TRADE MODEM       000D 32300019
         BC    8,LSTRDTID          NO SKIP WORLD TRADE PROCESSING  000D 32400019
         CLI   LCBTYPLN,LCBSWTCH   CHECK FOR SWITCH LINE           000D 32500019
         BNE   LSTRDTID            NO GO DO READ INITIAL           000D 32600019
         L     R6,LSTEIGHT(R1)    LOADS DCB ADDRESS                000D 32700019
         USING IHADCB,R6                                           000D 32800019
         L     R11,DCBBUFCB        GET BUFFER CONTROL BLOCK ADDRESS000D 32900019
         DROP  R6                                                  000D 33000019
         L     R7,LSTDZERO(R11)    GETS BUFFER ADDRESS             000D 33100019
         LA    R7,LSTFOUR(R7)     STEPS PTR PAST CHAIN PTR IN BUFF 000D 33200019
         MVI   LSTDZERO(R7),LSTMKCH     MOVES TONE CHAR IN AREA    000D 33300019
         MVC   LSTONE(LSTMARK,R7),LSTDZERO(R7)  PROPAGATES TONE    000D 33400019
         MVC   LSTMAR(LSTMRK,R7),LSTMARK(R7)   INTO BUFFER AREA    000D 33500019
         IC    R9,LSTEIGHT(R8)    SAVES FIRST BYTE OF AREA         000D 33600019
         ST    R7,LSTEIGHT(R8)     STORE  POINTER IN DFTRMLST      000D 33700019
         STC   R9,LSTEIGHT(R8)    RESTORES FIRST OF AREA           000D 33800019
LSTRDTID EQU   *                                                   000D 33900019
         TM    LCBLDECB,LCBZTDRN   TEST ZERO LCBTDIR FLAG          000B 34000020
         BZ    LSTSKZER            NOT ON SKIP ZEROING             000B 34100019
         XC    LCBTDIR,LCBTDIR     ZEROES TDIR PTR IN LCB          000B 34200019
         LTR   R4,R4               TEST FOR TDIR PTR             A28208 34210020
         BZ    NOTDIR              NO PTRC SKIP ZERO FUNCTION    A28208 34220020
         XC    TDIRLCB,TDIRLCB     ZERO TDIR LCB AND TURN        A28208 34230020
         NI    TDIRSWCH,TDIRRJSF   TURN OFF RJSTART SWITCH       A28208 34240020
NOTDIR   EQU   *                                                 A28208 34250020
         NI    LCBLDECB,LCBZTDRF   RESETS ZERO LCBTDIR FLAG        000B 34320020
LSTSKZER  EQU   *                                                  000B 34400019
         CLI   LSTZEROO(R8),LSTANST  CHECK FOR LIST WITH ID VERIF  000D 34500019
         BE    LSTRDTC             YES DO TC TYPE OF READ INITIAL  000D 34600019
         READ  (1),TI,,'S','S',(8),MF=E  DOES READ INITIAL FOR INPUT    34700019
LSTLSTLS EQU   *                                                   000D 34800019
         CLI   LCBTYPLN,LCBMULPT   CHECKS FOR MULTI-DROP           000A 34900019
         BNE   LSTDONT                                             000A 35000019
         OI    DECTYPE,LSTTOFLG    INDICATE NO BTAM ERROR MSG      000A 35100019
LSTDONT  LA    R9,LSTBDRD                                        A47940 35200021
         LA    R10,LSTLRDEX        SETS NORMAL EXIT                000A 35300019
         B     LSTRDTST                  FROM SOME TERMINAL ON THISLINE 35400019
LSTRDTC  EQU   *                                                   000D 35500019
         READ  (R1),TC,,'S','S',(R8),MF=E                          000D 35600019
         B     LSTLSTLS            GO CHECK I/O OPERATION          000D 35700019
**********************************************************************  35800019
* THIS ROUTINE INDEXES THE POLLING POINTER TO THE NEXT ENTRY          * 35900019
*  AND CHECKS  FOR END OF LIST. IF END OF LIST IS FOUND               * 36000019
* THE BEGINNING OF LIST ADDRESS IS USED                               * 36100019
**********************************************************************  36200019
LSTLSTCK L     R3,LCBLDECB         SET BASE FOR DSECT              000A 36300019
         CLI   DECPOLPT,LSTDZERO   CHECKS FOR FRIST TIME POLL      000A 36400019
         BE    LSTRDTIT            YES GO LOAD BEGINNING OF LIST   000A 36500019
         BAL   R10,LSTNSWCH        GO CHECK FOR OUTPUT             000A 36600019
LSTDFIND L     R9,LCBDFTRM         LOADS POLLING ADDRESS LIST      000A 36700019
         XC    LCBTDIR,LCBTDIR     CLEAR TERMINAL DIR ENTRY POINTER000A 36800019
         BCTR  R9,R0               DEC COUNT                       000A 36900019
         SR    R10,R10                                             000A 37000019
         IC    R10,LSTZEROO(R9)    GETS ENTRY WIDTH                000A 37100019
         SRL   R10,LSTFIVE         SHIFTS OFF UNWANTED BITS        000A 37200019
LSTPOLPT AR    R9,R10              MOVES POINTER TO INDEX BYTE     000A 37300019
         CLI   LSTONE(R9),LCBPTPT  CHECKS FOR END OF LIST          000A 37400019
         BE    LSTRDTIT            YES LOAD FIRST OF LIST          000A 37500019
         CLC   DECPOLPT(LSTONE),LSTZEROO(R9) CHECKS IF THIS WASLAST000A 37600019
         BNE   LSTPOLPT            ENTRY POLLED IF NOT GO TO NEXT  000A 37700019
         LA    R8,LSTONE(R9)       YES SET POINTER TO POLLING      000A 37800019
         B     LSTRDTIA            NO USE POINTER IN REG 8         000A 37900019
*********************************************************************** 38000019
* THIS ROUTINE DOES A BTAM RELEASE BUFFER. THIS ROUTINE IS ENTERED    * 38100019
* BECAUSE OF A LINE FAILURE OR A RESET POLL                           * 38200019
*********************************************************************** 38300019
LSTRBUFF L     R6,DECDCBAD         LOADS DCB ADDRESS                    38400019
         L     R10,LCBBUFER       LOADS DISK BUFF PTR            A22264 38500019
         LA    R10,LSTQMPA(R10)   ADJUST PTR PAST QMPA           A26531 38600019
         L     R7,DECAREA         LOADS LINE BUFF PTR            A22264 38700019
         LA    R7,0(R7)            ZERO OUT HI ORDER BYTE        A22264 38750020
         CR    R7,R10             ARE THEY = YES SKIP RELEASE    A22264 38800019
         BCR   8,R8               BUFF WRONG BUFFER              A22264 38900019
         SR    R9,R9               CLEAR REG FOR STORE           A24701 39000019
         ST    R9,0(R7)            IN BTAM BUFFER                A24701 39100019
         RELBUF (6),(7)            AT START OF ROUTINE                  39200019
         BR    R8                                                       39300019
*********************************************************************** 39400019
*  THIS ROUTINE IS THE RJENDC PROCEDURE TO COAST RJE TO A HALT. THIS  * 39500019
*  ROUTINE INSURES THAT EACH LINE IS INACTIVE WHEN THE SYSTEM IS TO BE* 39600019
*  SHUT DOWN. IT GENERATES A RJENDC FOR THE RJE SYSTEM AND WAITS      * 39700019
*  UNTIL A CLOSE DOWN MESSAGE IS GENERATED THEN POSTS THAT TERMINALS  * 39800019
*  STOP RJE ECB TO DEACTIVATE                                         * 39900019
*********************************************************************** 40000019
LSTSTOP  CLI   LCBTYPLN,LCBMULPT   CHECK FOR MULTIPOINT            000A 40100019
         BE    LSTMDGOA            PROCESS MULTIDROP               000A 40200019
         L     R6,LCBTDIR          LOAD TDIR ENTRY POINTER         000A 40300019
         LTR   R6,R6               CHECKS FOR NO TERM THIS LINE         40400019
         BC    8,LSTFINI           IF NO TERM GO TO EXIT                40500019
LSTMDGOA CLI   LCBFLAG,LSTCGONE    TESTS IF RJENDC MSG GONE             40600019
         BE    LSTPOST                                                  40700019
         CLI   LCBFLAG,LSTDISP    CHECKS IF MSG IS ENQUEUED             40800019
         BE    LSTROUTB                                                 40900019
LSTROUTC CLI   LCBFLAG,LSTLRDC    CHECKS IF IHKABLRD GENERATED RJENDC   41000019
         BE    LSTROUTA                                                 41100019
         CLI   LCBTYPLN,LCBMULPT   CHECKS FOR NON-SWITCHED LINE         41200019
         BE    LSTNSWH                                                  41300019
LSTMDGO  MVI   LCBFLAG,LSTLRDC     SETS ROUTA FLAG TO EXIT              41400019
         SR    R1,R1               SET A 0 IN REG1 FOR RJENDC AND GOES  41500019
         ST    R1,LCBPARM1         STORES RJEND CODE IN LCB             41600019
         L     R5,LSTCOCOM         SET BASE FOR DSECT                   41700019
         ST    R2,IHKZZLCB         STORE LCB POINTER IN PARM LIST       41800019
         LA    R1,IHKZZLCB         LOADS POINTER TO PARM LIST           41900019
         L     R15,LSTABRJF        TO LRD TO GET COMMAND BUILT AND QUED 42000019
         BR    R15                                                      42100019
LSTROUTA MVI   LCBFLAG,LSTDISP     SETS ROUTEB FLAG AND GOES TO DIS-    42200019
         L     R1,LCBDDECB         LOADS ECB POINTER FOR WAIT           42300019
         MVI   0(R1),LSTDZERO      ZEROES WAIT BIT IN ECB               42400019
         L     R15,LSTAADSP        PATCHER TO WAIT FOR RJEND TO INDICAT 42500019
         BALR  14,15               E MESSAGE IS READY                   42600019
         B     LSTSTOP                                                  42700019
LSTROUTB MVI   LCBFLAG,LSTCGONE    SETS MSG GONE (RJENDC)               42800019
         TM    TDIRSWCH+1,LSTDSCNT TESTS FOR DISCONTINUED TERMINAL IF   42900019
         BO    LSTPOST             SO FORGET MSG NOT SENT               43000019
         B     LSTLWREX            GO TO IHKABLWR                       43100019
LSTPOST  TM    TDIRSWCH+2,LSTDCNTC CHECKS FOR A CONTENTION              43200019
         BO    LSTCONT             ON WRITING RJENDC MSG                43300019
         MVI   LCBFLAG,LSTDZERO    RESETS MSG GONE FLAG            000A 43400019
         MVI   TDIRSECB,LSTPOSTT   POSTS THIS TERMINAL AS CLOSEDOWN     43500019
         CLI   LCBTYPLN,LCBMULPT   CHECKS FOR A MULTI-POINT LINE        43600019
         BE    LSTNSWH                                             000A 43700019
LSTMDONE L     R1,LCBDDECB         AND TO DISPATCHER TO AWAIT RJE       43800019
         MVI   0(R1),LSTDZERO      CLOSEDOWN                            43900019
         L     R15,LSTAADSP                                             44000019
         BR    R15                 GO TO DISPATCHER                     44100019
*********************************************************************** 44200019
*   THIS ROUTINE CREATES AN RJENDF FOR WARMSTART                      * 44300019
*********************************************************************** 44400019
LSTRJNDF L     R5,LSTCOCOM         ESTABLISHES BASE FOR DSECT           44500019
         L     R4,IHKZZTDR         LOADS BEGINNING OF TDE               44600019
         L     R7,IHKZZTLN         LOADS LENGTH OF EACH TDE             44700019
         LH    R7,0(R7)            LOADS VALUE OF LENGTH                44800019
         L     R8,IHKZZTNB         LOADS TOTAL NUMBER OF TDE'S          44900019
         LH    R11,0(R8)           LOADS TOTAL NUMBER                   45000019
         LA    R11,1(R11)          ADD ONE TO COUNT                     45100019
LSTRJCH  TM    LSTSAVE+1,LSTRJC    TEST IF CONTROL SHOULD GO TO RJENDC  45200019
         LA    R10,LSTRJCH         ROUTINE AND SETS UP RENTRY POINT     45300019
         BO    LSTRJCPT            GO IF SWITCH IS ON                   45400019
LSTRJCH1 TM    TDIRSWCH,LSTRJSTR   CHECKS TO SEE IF TERMINAL HAS        45500019
         LA    R10,LSTRJCH1        ALREADY RJENDED                      45600019
         BC    8,LSTINDEX                                               45700019
         ST    R4,LCBTDIR          STORES CURRENT TDIR ENTRY IN LCB     45800019
         LH    R1,LSTCODE          SET CODE FOR PROPER RJEND IN REG1    45900019
         LA    R10,LSTEXLRD        AND EXIT TO IHKABLRD EXIT            46000019
         B     LSTINDEX                                                 46100019
LSTEXLRD ST    R1,LCBPARM1         STORES RJEND CODE IN LCB             46200019
LSTRJLRD L     R5,LSTCOCOM         SET BASE FOR DSECT                   46300019
         ST    R2,IHKZZLCB         STORE LCB POINTER IN PARM LIST       46400019
         OI    LCBLDECB,LCBZTDRN   SETS ZERO LCBTDIR FLAG          000B 46500020
         LA    R1,IHKZZLCB         LOADS POINTER TO PARM LIST           46600019
         L     R15,LSTABRJF        GO TO RJENDF ROUTINE                 46700019
         BR    R15                                                      46800019
LSTINDEX AR    R4,R7               INDEXES POINTER TO NEXT TDE          46900019
         BCTR  R11,R10              CHECKS FOR LAST TDE                 47000019
         B     LSTCHECK            RETURNS TO CALLING SUBROUTINE        47100019
LSTENDRF MVI   LSTSAVE,LSTDZERO    RESETS RJEND FIRSTIME SWITCH         47200019
         XC    LCBTDIR,LCBTDIR     ZEROES TDIR PTR IN LCB          000A 47300019
         L     R8,LSTCDRCS                                              47400019
         NI    0(R8),LSTRESET      RESETS WARMSTART BIT                 47500019
         B     LSTBEGIN            BEGINNING                            47600019
*********************************************************************** 47700019
* THIS ROUTINE SETS UP A DUMMY WAIT FOR ENTRY INTO THE DISPATCHER     * 47800019
* UNTIL THE SYSDEQ ROUTINE FINISHES POLICING THE SYSOUT QUEUE         * 47900019
* ALSO STORES REGISTERS FOR RETURN FROM DISPATCHER                    * 48000019
*********************************************************************** 48100019
LSTOUTSP MVI   LCBFLAG,LSTDZERO    RESETS RJEND SWITCH                  48200019
LSTRIDE  SR    R14,R14                                                  48300019
         L     R1,LCBLDECB        LOADS ECB POINTER IN REG1             48400019
         LA    R15,LSTBEGIN                                             48500019
         STM   R14,R12,12(R13)     STORES OWN REGISTERS FOR RETURN      48600019
         L     R15,LSTAADSP       LOADS ADDRESS OF DISPATCHER           48700019
         BR    R15                GO TO DISPATCHER                      48800019
*********************************************************************** 48900019
*  THIS  ROUTINE DETERMINES WHAT TERMINAL ON A MULTI-DROP LINE. THIS  * 49000019
*  DONE BY PICKING UP ITS POLLING CHARACTERS FROM THE DEFINE TERMINAL * 49100019
*  LIST AND COMPARING THEM AGAINST THE POLLING CHARACTERS IN THE      * 49200019
*  TERMINAL TABLE. WHEN AN EQUAL COMPARE OCCURS THE CORRESPONDING     * 49300019
*  TERMINAL DIRECTORY ENTRY IS PLACED IN THE LINE CONTROL BLOCK. THEN * 49400019
*  CONTROL IS PASSED TO IHKABLRD                                      * 49500019
*********************************************************************** 49600019
LSTMUTCK EQU   *                                                   000A 49700019
         LA    R15,LSTCKGD         SET RETURN ADDRESS              000A 49800019
LSTCKBD  EQU   *                                                   000A 49900019
         LA    R5,LSTEXCTE         SET RETURN ADDRESS              000A 50000019
         LTR   R4,R4              TEST FOR TDIR POINTER           M2642 50110019
         BC    8,NOTEST           NO DONT DO CHECK                M2642 50120019
         TM    TDIRSWCH+2,TDIRCDSN  TEST FOR INTERNAL DISCONTINUE M2642 50130019
         BO    LSTRDEXT           YES NO NEED TO DO IT LEAVE      M2642 50160019
NOTEST   EQU   *                                                  M2642 50180019
         L     R7,LCBCTMTB         LOADS TERMINAL TABLE POINTER    000A 50200019
         LA    R7,LSTSIXX(R7)     STEP PAST FIRST SIX BYTES        000D 50300019
         L     R8,DECENTRY         LOADS PTR TO ENTRY IN DFTRMLST  000A 50400019
         L     R9,LCBDFTRM         LOADS PTR TO BEGINNING OF DFTRM 000A 50500019
         BCTR  R9,R0               LST AND ADJUSTS PTR TO ITS HEADR000A 50600019
         SR    R10,R10             FROM IT THE WIDTH OF EACH ENTRY 000A 50700019
         IC    R10,LSTZEROO(R9)    IS OBTAINED AFTER SHIFTING OF   000A 50800019
         SRL   R10,LSTFIVE         UN-NECESSARY BITS AND REDUCING  000A 50900019
         S     R10,LSTTO           THE WIDTH TO ELIMINATE CONSTANT 000A 51000019
*                                  REGION.                         000A 51100019
         BR    R5                                                  000A 51200019
LSTEXCTE EX    R10,LSTCOMPR        COMPARES POLL CHARS OF BOTH     000A 51300019
         BE    LSTMOVE             TABLES,CHECKING FOR = COMPARE   000A 51400019
         LA    R7,LSTFIVE(R10,R7)  INDEX TO NEXT ENTRY IN TERMINAL 000D 51500019
         B     LSTEXCTE            TABLE AND EXECUTES ANOTHER COMP 000A 51600019
LSTMOVE  EQU   *                                                   000D 51700019
         LA    R7,LSTONE(R10,R7)   SET ADDRESS PAST POLL CHARS     000D 51800019
         MVC   LCBTDIR+1(LSTTHREE),LSTONE(R7)  MOVE TDE TO LCB     000D 51900019
         BR    R15                 IF ENTRY WAS AT LSTMUTCH,       000A 52000019
*                                    EXIT TO LSTCKGD.              000A 52100019
*                                  IF ENTRY WAS AT LSTCKBD,        000A 52200019
*                                    EXIT TO LSTHERE.              000A 52300019
LSTCKGD  TM    LSTZEROO(R7),LSTHIBIT CHECK FLAG IN TERM TABLE      000D 52400019
         BNO   LSTRDEXT            TERM HAS BEEN RESPONDING NORMALY000A 52500019
*                                    CALL IHKABLRD                 000A 52600019
         NI    LSTZEROO(R7),LSTHIBTF TERM HAS FINALLY RESPONDED    000D 52700019
*                                    TURN OFF ERROR SWITCH         000A 52800019
         L     R4,LCBTDIR          GET TERMINAL DIRECTORY ENTRY    000A 52900019
         MVC   LSTTRMGD,TDIRTERM   PUT TERMID TO MSG               000A 53000019
         LA    R1,LSTGDMS          PASS MSG TO WTO                 000A 53100019
         SVC   35                  SEND TERM NOW RESPONDING MSG    000A 53200019
         B     LSTRDEXT            NOW CALL IHKABLRD               000A 53300019
*********************************************************************** 53400019
*  THIS ROUTINE CHECKS ALL TERMINALS ON A MULTI-DROP LINE             * 53500019
*  FOR OUTPUT IF NO OUTPUT EXIST IT RETURN TO THE READ INITIAL        * 53600019
*********************************************************************** 53700019
LSTNSWCH EQU   *                                                   000D 53800019
         BAL   R5,NOTEST           GET ENTRY WIDTH OF POLL CHARS A37794 53900020
         LR    R4,R10              THEN  ADD CONSTANT OF FOR TO    000D 54000019
         LA    R5,LSTONE(R4)       SET ENTRY WIDTH OF POLL CHARS   000D 54100019
         LA    R4,LSTFIVE(R4)      SET ENTRY WIDTH OF TERM TABLE   000D 54200019
         L     R9,LCBCTMTB         LOADS TERMINAL TABLE POINTER    000D 54300019
         L     R11,LSTZEROO(R9)    LOADS CURR TERM TABLE POINTER   000A 54400019
         LR    R8,R9                                               000A 54500019
         SR    R7,R7                                               000A 54600019
         IC    R7,LCBTABNM         LOADS NUM OF ENTRIES IN TERM TBL000A 54700019
         MR    R6,R4               FINDS TOTAL LENGTH OF TABLE     000A 54800019
         AR    R8,R7               SETS POINTER TO END OF TABLE    000A 54900019
         LA    R8,LSTSIXX(R8)      ADD CONTROL WORD WIDTH          000D 55000019
         LR    R6,R4               NOT INDEX TO NEXT ENTRY AND     000D 55100019
LSTGOOF   DS    0H                                                 000B 55200019
         LA    R11,LSTZEROO(R6,R11)   GO TO                        000D 55300019
         CR    R11,R8              CHECKS FOR END OF TABLE IF ENDOF000B 55400019
         BE    LSTSET              TABLE SET FIRST TIME SWITCH IF  000B 55500019
LSTGETIT EQU   *                                                   000D 55600019
         AR    R11,R5              SET ADDRESS IN BY NUMBER OF     000D 55700019
*                                  POLLING CHARACTERS              000D 55800019
         MVC   LCBTDIR(LSTFOUR),LSTZEROO(R11) MOVE TDE TO LCB      000D 55900019
         SR    R11,R5             SET ADDRESS BACK TO BEGINNING OF 000D 56000019
*                                  THIS ENTRY                      000D 56100019
         L     R4,LCBTDIR          ORY POINTER FROM TERMINAL TABLE 000A 56200019
*                                  TO LCB AND LOADS REG4 TO SET    000A 56300019
         ST    R11,LSTZEROO(R9)    BASE OF DSECT AND EXIT TO OUTPUT000A 56400019
*                                  CHECKER AFTER STORING CURR PTR  000A 56500019
         BAL   R10,LSTWRCHK        IN THE TERMINAL TABLE           000A 56600019
         L     R11,LSTZEROO(R9)    RELOADS CURR TERM TABLE POINTER 000A 56700019
         B     LSTGOOF                                             000B 56800019
LSTSET   TM    LSTFOUR(R9),LSTBDOP TEST FIRST TIME SWITCH          000A 56900019
         BO    LSTDONE             IF ON ROUTINE IS FINISHED       000A 57000019
         OI    LSTFOUR(R9),LSTBDOP IF OFF SET ON AND RE-INITIALIZE 000A 57100019
         LA    R11,LSTSIXX(R9)     TERMINAL TABLE POINTER TO BEGIN 000A 57200019
         B     LSTGETIT            NING AND CHECK FOR OUTPUT AGAIN 000A 57300019
LSTDONE  LA    R11,LSTSIXX(R9)     CLEAN UP RESETS FIRSTIME SWITCH 000A 57400019
         ST    R11,LSTZEROO(R9)    RE-INITIALIZES CURRENT TERMINAL 000A 57500019
         NI    LSTFOUR(R9),LSTGIO  TABLE POINTER TO BEGINNING AND  000A 57600019
         B     LSTDFIND            EXIT TO THE READ INITIAL ROUTINE000A 57700019
*********************************************************************** 57800019
*  THIS ROUTINE GENERATES A RJENDC FOR ALL TERMINALS ON A             * 57900019
*         MULTI-DROP LINE                                             * 58000019
*********************************************************************** 58100019
LSTNSWH  EQU   *                                                   000D 58200019
         BAL   R5,NOTEST           GET ENTRY WIDTH OF POLL CHARS A37794 58300020
         LR    R11,R10             SAVE IT IN REG 11               000D 58400019
         L     R7,LCBCTMTB         LOADS TERMINAL TABLE POINTER    000D 58500019
         SR    R9,R9               CLEARS REG 9                    000A 58600019
         TS    LSTFIVE(R7)         SETS FIRSTIME SWITCH TO SKIP    000A 58700019
         BC    7,LSTSKIP           THE FOLLOWING INSTRUCTION       000A 58800019
         LA    R6,LSTSIXX(R7)      INDEX POINTER PAST TABLER HRDR  000A 58900019
         IC    R9,LCBTABNM         INSERTS # OF ENTRIES IN TABLE   000A 59000019
         B     LSTTEST2                                            000A 59100019
LSTSKIP  L     R6,LSTZEROO(R7)     LOADS CURRENT ENTRY IN TERM TABL000A 59200019
         IC    R9,LSTFOUR(R7)      INSERTS NUMBER OF ENTRIES LEFT  000A 59300019
LSTTEST2 LTR   R9,R9               TESTS IF ANY LEFT TO PROCESS    000A 59400019
         BC    8,LSTMDONE          NO THATS ALL                    000A 59500019
         LR    R14,R6             SAVE REG FOR OTHER USE           000D 59600019
         LA    R14,LSTONE(R11,R14) SET TO POINT TO TDIR ADDRESS    000D 59700019
         MVC   LCBTDIR(4),LSTZEROO(R14)  MOVES ADDRESS POINTER TO  000D 59800019
         L     R4,LCBTDIR          WORDBOUNDRY AND LOADS IN REG 4  000A 59900019
         LA    R10,LSTTEST2        SETS RETURN TO TEST NEW TERM    000A 60000019
         TM    TDIRSWCH,LSTRJSTR   TEST IF TERM HAS RJENDED        000A 60100019
         BZ    LSTADDIX            YES GO TO NEXT ONE              000A 60200019
         LA    R10,LSTMDGO         SET RETURN TO GO PROCESS RJENDC 000A 60300019
LSTADDIX BCTR  R9,R0               DECREASE COUNT BY ONE           000A 60400019
         STC   R9,LSTFOUR(R7)      STORE COUNT IN TERM TABLE       000A 60500019
         LA    R6,LSTFIVE(R11,R6)  SET TO NEXT TABLR ENTRY         000D 60600019
         ST    R6,LSTZEROO(R7)     STORE NEW POINTER IN TERM TABLE 000A 60700019
         BR    R10                 RETURN                          000A 60800019
*****************************************************************A47940 60802021
*       THIS ROUTINE PERMITS THE 2770 OPERATOR TIME TO UNLOAD   *A47940 60804021
*       THE STACKER OR RECOVER FROM A CARD JAM                  *A47940 60806021
*****************************************************************A47940 60808021
REREAD   CLI   LCBTYPLN,LCBSWTCH   FOR A NON-SWITCHED LINE,      A47940 60810021
         BNE   LSTRDTI                  JUST TRY AGAIN           A47940 60812021
LSTRDTQ  LA    R6,9           SET LOOP COUNTER FOR READ ENQ      A47940 60814021
         BAL   R14,LSTCLRBF        INITIALIZE FOR WRITE          A47940 60816021
         OI    DECTYPE,X'40'  INDICATE NO BTAM ERR MSG ON TIMEOUTA47940 60818021
         WRITE (1),TN,MF=E    WRITE RESET AND GET ENQ RESPONSE   A47940 60820021
         LA    R9,LSTCKTIM    SET ERROR RETURN EXIT              A47940 60822021
         BAL   R10,LSTRDTST   CHECK FOR SUCCESSFUL READ          A47940 60824021
         CLI   DECRESPN,X'2D' CHECK FOR ENQ                      A47940 60826021
         BE    LSTREAD        YES - DO READ CONTINUE             A47940 60828021
         CLI   DECRESPN,X'37' CHECK FOR EOT                      A47940 60830021
         BE    LSTRDTQ        YES - REPEAT WRITE RESET           A47940 60832021
         B     LSTBDRD        INVALID CHAR - DO RJENDF           A47940 60834021
         SPACE                                                          60836021
LSTRDTQR OI    DECTYPE,X'40'  NO BTAM ERR MSG ON TIMEOUT, PLEASE A47940 60838021
         LR    R0,R6     SAVE LOOP COUNTER                       A47940 60840021
         BAL   R9,LSTWMSTP    CHECK STOP BIT                     A47940 60842021
         LR    R6,R0     RESTORE LOOP COUNTER                    A47940 60844021
         READ  (1),TQ,MF=E    READ ENQ                           A47940 60846021
         LA    R10,LSTREAD   SET NORMAL RETURN EXIT              A47940 60848021
         BAL   R9,LSTRDTST    CHECK FOR SUCCESSFUL READ          A47940 60850021
LSTCKTIM TM    DECSENS0,X'01' READ UNSUCCESSFUL - TEST IF TIMEOUTA47940 60852021
         BZ    LSTBDRD       NO - DO RJENDF                      A47940 60854021
         BCT   R6,LSTRDTQR    YES - REPEAT READ ENQ 7 TIMES      A47940 60856021
         B     LSTBDRD        DO RJENDF AFTER 8 READ ENQ TRIES   A47940 60858021
         SPACE                                                          60860021
LSTREAD  LA    R14,LSTREAD1   INITIALIZE FOR READ CONTINUE       A47940 60862021
LSTCLRBF L     R1,LCBLDECB   ROUTINE TO INITIALIZE FOR I/O       A47940 60864021
         LR    R3,R1          SET REGS 1 & 3 TO LINE DECB        A47940 60866021
         L     R15,DECAREA    ZERO FIRST WORD OF BUFFER          A47940 60868021
         XC    0(4,R15),0(R15)                                   A47940 60870021
         BR    R14            RETURN TO CALLER                   A47940 60872021
LSTREAD1 BAL   R9,LSTWMSTP    CHECK STOP BIT                     A47940 60874021
         READ (1),TT,MF=E     READ CONTINUE                      A47940 60876021
         B     LSTRETST       RETURN TO PROCESS INPUT            A47940 60878021
         SPACE                                                          60880021
STKUN    DC    X'10022D' DLE-STX-ENQ MEANS 2770 STACKER UNLOAD   A47940 60882021
CDJAM    DC    X'37022D' EOT-STX-ENQ MEANS 2770/2780 CARD JAM    A47940 60884021
*********************************************************************** 60900019
*      THIS IS A COMMON IHKABLRD EXIT ROUTINE                         * 61000019
*********************************************************************** 61100019
LSTLRDEX CLI   LCBTYPLN,LCBMULPT   TESTS FOR MULTI-DROP LINE IF SO      61200019
         BE    LSTMUTCK            EXITS TO MULTI-DROP INPUT ROUTINE    61300019
LSTRDEXT L     R15,LSTABLRD                                             61400019
         L     R5,LSTCOCOM         SET BASE FOR DSECT                   61500019
         ST    R2,IHKZZLCB         STORE LCB POINTER IN PARM LIST       61600019
         LA    R1,IHKZZLCB         LOADS POINTER TO PARM LIST           61700019
         BR    R15       THIS IS A COMMON IHKABLRD EXIT                 61800019
*********************************************************************** 61900019
*    THIS IS A COMMON EXIT ROUTINE TO THE LINE WRITE ROUTINE          * 62000019
*********************************************************************** 62100019
LSTLWREX L     R15,LSTABLWR        THIS IS A COMMON IHKABLWR EXIT       62200019
         L     R5,LSTCOCOM         SET BASE FOR DSECT                   62300019
         ST    R2,IHKZZLCB         STORE LCB POINTER IN PARM LIST       62400019
         LA    R1,IHKZZLCB         LOADS POINTER TO PARM LIST           62500019
         BR    R15                                                      62600019
*********************************************************************** 62700019
*     THIS IS A COMMON EXIT ROUTINE TO THE DISPATCHER                   62800019
*********************************************************************** 62900019
LSTDSPEX L     R1,LCBLDECB         LOAD ECB POINTER FOR WAIT            63000019
LSTDSPE2 LA    R14,LSTBEGIN        LOADS 14 WITH THE RETURN ADDRESS     63100019
         L     R15,LSTAADSP        LOADS DISPATCHER ENTRY POINT         63200019
         BR    R15       THIS IS A COMMON IHKAADSP EXIT                 63300019
*********************************************************************** 63400019
* THIS IS A COMMON RJENDF ROUTINE                                     * 63500019
*********************************************************************** 63600019
LSTRJEDF LTR   R4,R4               CHECKS FOR TDE POINTER          000A 63700019
         LA    R8,LSTRDTI     SET RENTRY PT FOR REL BUFF         A47940 63800021
         BC    7,LSTRBUFF     NO - DONT BUILD RJENDF             A47940 63850021
         TM    TDIRSWCH,LSTRJSTR   CHECKS IF TDE HAS RJSTARTED     000A 63900019
         BZ    LSTRBUFF       NO - DONT BUILD RJENDF             A47940 64000021
         SPACE                                                          64100019
         SPACE                                                          64200019
         SR    R1,R1                                                    64300019
         LH    R1,LSTCODEF         THIS CODE INDICATES TO IHKABLRD THAT 64400019
         B     LSTEXLRD            IT SHOULD GENERATE A RJENDF          64500019
LSTRJCCK TM    LSTSAVE+1,LSTRJC    CHECKS IF RJENDC SWITCH IS SET       64600019
         BO    LSTSTOP                                                  64700019
         L     R6,LCBTDIR          SAVES TDIR POINTER IN LCB FOR LATER  64800019
         ST    R6,LSTSAVE+4        RESTORE                              64900019
         OI    LSTSAVE+1,LSTRJC    SET A SWITCH INDICATING A RJENDC     65000019
         B     LSTRJNDF            INSTEAD OF RJENDF                    65100019
LSTRJCPT TM    TDIRSWCH,LSTRJSTR   TESTS FOR A RJENDED TERNINAL IF SO   65200019
         BZ    LSTINDEX            SKIP TERMINAL  *****************     65300019
         TM    TDIRSTAT,LSTTEN     TESTS ENQUEUE MSG SWITCH IF ON TER   65400019
         BO    LSTINDEX            MINAL HAS NOT FINISHED RETURN        65500019
         CLC   TDIRFQEB+1(3),LSTZEROQ  CHECKS IF ALL MSG ARE GONE       65600019
         BNE   LSTINDEX            IF NOT RETURN                        65700019
         MVI   TDIRSECB,LSTPOSTT   POSTS ECB IN TDE INDICATING TERMINAL 65800019
         B     LSTINDEX            CLOSE DOWN CDMPLETE                  65900019
LSTCHECK TM    LSTSAVE+1,LSTRJC    THIS ROUTINE CHECK TYPE OF RJEND     66000019
         BO    LSTZERO            SWITCH ON RJENDC                      66100019
        B     LSTENDRF         SWITCH OFF RJENDF                        66200019
LSTZERO  L     R6,LSTSAVE+4        RESTORE TERMINAL DIRECTORY POINTER   66300019
         ST    R6,LCBTDIR          TO LCB SO IT CAN BE PROCESSED        66400019
         MVI   LSTSAVE+1,LSTRJC    RESETS RJENDC SWITCH                 66500019
         CLI   LCBTYPLN,LCBMULPT   CHECKS FOR MULTI-DROP LINE      000A 66600019
         BE    LSTNSWH                                             000A 66700019
         LTR   R6,R6               TESTS IF TDE POINTER IN LCB IS ZERO  66800019
         BC    8,LSTFINI           IF SO NO TDE ON THIS LINE FINISHED   66900019
         B     LSTSTOP             IF SO GO TO STOP ROUTINE             67000019
*********************************************************************** 67100019
*  THIS IS A COMMON ROUTINE THAT CHECKS FOR STOP AND WARMSTART        * 67200019
*********************************************************************** 67300019
LSTWMSTP L     R6,LSTCDRCS         LOADS POINTER TO IHKCDRCS            67400019
         TM    0(R6),LSTRDER      CHECKS TO SEE IF READER HAS FINISHED  67500019
         BO    LSTRIDE            WARMSTART                             67600019
         TM    0(R6),LSTWRMB       TESTS FOR WRMSTART IF ON GENERATES   67700019
         BO    LSTRJNDF            A RJENDF FOR EACH ACTIVE TERMINAL    67800019
         TM    0(R6),LSTWJDAB      CHECKS TO SEE IF SYSDEQ HAS FINISHED 67900019
         BO    LSTRIDE             IF NOT GOES TO DISPATCHER TO WAIT    68000019
         TM    0(R6),LSTSTPB       TESTS FOR STOP RJE BIT,IF ON GOES    68100019
         BO    LSTRJCCK            TO RJENDC PROCEDURE                  68200019
         BR    R9                  IF NO BIT ARE SET RETURN             68300019
*********************************************************************** 68400019
* THIS ROUTINE IS DESIGNED TO KEEP A SWITCHED OPEN UNTIL THERE IS     * 68500019
* EITHER OUTPUT FOR THE REMOTE OR INPUT FROM THE REMOTE. THE LINE     * 68600019
* WILL REMAIN OPEN INTIL THE USER DESIRES TO HANG UP BY RJENDING      * 68700019
*********************************************************************** 68800019
IHKABEOT EQU   *                                                        68900019
         L     R3,LCBLDECB         LOADS BASE FOR DECB DSECT            69000019
         L     R4,LCBTDIR          LOADS BASE FOR TDIREC DSECT          69100019
LSTWREOT LR    R1,R3                                                    69200019
         OI    DECTYPE,LSTTOFLG    INDICATE NO BTAM ERROR MESSAGE  000A 69300019
*                                  FOR TIME OUT                    000A 69400019
         MVI   DECRESPN,LSTDZERO   ZEROES DECB RESPONSE FIELD           69500019
         WRITE (1),TN,MF=E         WRITES EOT FOR SWITCHED LINE         69600019
         LA    R9,LSTOUTP         SET ERROR RETURN EXIT            000D 69700019
         BAL   R10,LSTRDTST        SETS NORMAL RETURN EXIT         000A 69800019
LSTEOTCK CLI   DECRESPN,LSTEOT     CHECK IF THE RESPONSE TO THE EOT WAS 69900019
         BE    LSTABOUT            AN EOT IF SO NO INPUT FROM REMOTE    70000019
         CLI   DECRESPN,LSTENQ     CHECK IF THE RESPONSE WAS AN ENQ     70100019
         BE    LSTDISCT  ENQ MEANS REMOTE I/P                    A53111 70200021
         B     LSTOUTP             2780 GO DO READ ENQ             000A 70300019
LSTABOUT BAL   R9,LSTWMSTP         CHECK FOR STOP RJE                   70400019
         BAL   R10,LSTWRCHK        GO TO CHECK FOR OUTPUT ROUTINE       70500019
         L     R4,LCBTDIR          SETS BASE FOR DSECT             000A 70600019
LSTWAIT  L     R1,LCBLDECB         LOADS ECB POINTER               000A 70700019
         OI    DECTYPE,LSTTOFLG    INDICATE NO BTAM ERROR MESSAGE  000A 70900019
*                                  FOR TIME OUT                    000A 71000019
         L     R8,LSTREIGH(R1)    LOADS DCB POINTER                000D 71100019
         OI    LSTRFIVE(R8),LSTHIBIT SET FLAG FOR IMMED INTERP ON  000D 71200019
         READ  (1),TQ,MF=E         DOES A READ ENQ                 000A 71300019
         LA    R10,LSTDISCT   SET RENTRY FOR ENQ RECEIVED        A53111 71400021
         BAL   R9,LSTRDTST         GOES TO TEST I/O ROUTINE        000A 71500019
LSTOUTP  LR    R3,R1               SETS BASE FOR DSECT             000A 71600019
         TM    DECSENS0,LSTTIMO    TEST IF ERROR WAS A TIME OUT    000A 71700019
         BZ    LSTRJED             NO GO DO RJENDF                 000A 71800019
         B     LSTABOUT           GO CHECK FOR OUTPUT              000D 71900019
LSTRJED  LH    R1,LSTFF            SETS CODE FOR RJENDF            000A 72000019
         B     LSTRJEDF            NO OUTPUT AVAILABLE DO RJENDF   000A 72100019
*********************************************************************** 72200019
* THIS ROUTINE HANDLES A CONTENTION PROBLEM WHILE THE WRITER IS TRYING* 72300019
* TO WRITE THE CLOSE DOWN MESSAGE IT READS THE INCOMING DATA AND      * 72400019
* RESPONDS WITH AN EOT TO ABORT THE TRANSMISSION                      * 72500019
*********************************************************************** 72600019
LSTCONT  MVI   LCBFLAG,LSTDISP     RESETS ROUTEB FLAG              000A 72700019
         CLI   LCBTYPLN,LSTMDSW    CHECKS FOR MSG GONE INDICATOR   000A 72800019
         BE    LSTWREOT                                                 72900019
         L     R1,LCBLDECB         LOADS ECB POINTER                    73000019
         LR    R3,R1               SETS BASE FOR DSECT             000A 73100019
         READ  (1),TT,,'S','S',MF=E   READ TO CLEAR LINE           000A 73200019
         LA    R9,LSTSKIP2         SET UP RETURN ADDRESS           1657 73300019
         BAL   R10,LSTRDTST        SETS NORMAL RETURN EXIT         000A 73400019
         WRITE (1),TN,MF=E         WRITES EOT AND GOES                  73500019
         LA    R9,LSTRESPL         SET ERROR EXIT                  000A 73600019
         BAL   R10,LSTRDTST        SETS NORMAL RETURN EXIT         000A 73700019
         B     LSTLWREX            GOES BACK TO IHKABLWR TO SEND MSG    73800019
*********************************************************************** 73900019
*  THIS ROUTINE DOES A DISABLE IF THERE IS AN ERROR ON A READ INITIAL * 74000019
*  OPERATION ON A SWITCHED LINE                                       * 74100019
*********************************************************************** 74200019
LSTHNGUP CLI   LCBTYPLN,LCBSWTCH   CHECK TO SEE IF ITS A SWITCHED LINE  74300019
         BNE   LSTRBUFF           NO GO TO RELEASE BUFF ROUTINE  A29519 74400020
         L     R1,LCBLDECB         YES WRITE AN EOT DISABLE             74500019
         WRITE (1),TD,MF=E                                              74600019
         LA    R9,LSKIP            SET ERROR RETURN EXIT         A29519 74700020
         BAL   R10,LSTRDTST        SETS NORMAL RETURN EXIT         000A 74800019
         LA    R8,LSTBEGIN         SET RETURN ADDRESS                   74900019
LSKIP    EQU   *                                                 A28208 74910020
         LTR   R4,R4               TEST FOR TDIR PTR             A28208 74920020
         BZ    LAYAWAY             NO SKIP ZERO FUNCTION         A28208 74930020
         XC    TDIRLCB,TDIRLCB     ZERO LCB PTR IN TDIR          A28208 74940020
         NI    TDIRSWCH,TDIRRJSF   TURN OFF RJSTART SWTCH        A28208 74950020
LAYAWAY  EQU   *                                                 A28208 74960020
         XC    LCBTDIR,LCBTDIR     ZEROES TDE POINTER                   75000019
         B     LSTRBUFF            GO TO RELEASE BUFFER ROUTINE         75100019
*********************************************************************** 75200019
*    THIS ROUTINE DOES A WRITE TO OPERATOR INFORMING HIM THAT         * 75300019
*     RJE COULD NOT OPEN A PARTICLAR DCB                              * 75400019
*********************************************************************** 75500019
         USING  IHADCB,R4                                               75600019
LSTDDMSS MVC   LSTPMSG1+LSTMSIN1(LSTEIGHT),DCBDDNAM  MOVES DDNAME       75700019
*                                                  . INTO MSG           75800019
         LA    R1,LSTPMSG1                                              75900019
         SVC   35                                                       76000019
         B     LSTFINI                                                  76100019
*********************************************************************** 76200019
*    THIS ROUTINE INFORMS THE OPERATOR THAT A PARTICULAR LINE IS      * 76300019
*     PLACED IN AN INACTIVE STATE BECAUSE OF A NON-OPERATIONAL        * 76400019
*     CONTROL UNIT                                                    * 76500019
*********************************************************************** 76600019
LSTQUIT  L     R4,DECDCBAD         LOADS ADDRESS OF DCB                 76700019
         L     R5,DCBDEBAD         LOADS ADDRESS OF DEB                 76800019
         SR    R6,R6                   CLEAR FOR IC              A60657 76900021
         IC    R6,DECRLN               DECB'S REL LINE #         A60657 76920021
         SLL   R6,2                    X 4 FOR INDEX IN DEB      A60657 76940021
         L     R6,DEBUCBAD-4(R5,R6)    UCB ADDRESS               A60657 76960021
         MVC   LSTPMSG2+LSTMSIN2(LSTTHREE),UCBNAME(R6) MOVES LINE NAME  77000019
*                                                       INTO MSG        77100019
         LA    R1,LSTPMSG2                                              77200019
         SVC   35                                                       77300019
         B     LSTFINI             GO WAIT FOR A CLOSEDOWN              77400019
*********************************************************************** 77410021
*    THIS ROUTINE INFORMS THE OPERATOR THAT THE LINE TYPE        A43087 77420021
*    DEFINED IN THE UCB DOES NOT MATCH THE LINE TYPE AS          A43087 77430021
*    DEFINED BY THE RJE USER IN THE RJELINE MACRO.               A43087 77440021
*********************************************************************** 77450021
LSTERR   MVC   LSTPMSG3+LSTMSIN2(LSTTHREE),UCBNAME(R6) MOVE LINE A43087 77460021
         LA    R1,LSTPMSG3                      NUMBER INTO MSGE A43087 77470021
         SVC   35                                                A43087 77480021
         B     LSTFINI                  GO WAIT FOR CLOSEDOWN    A43087 77490021
*********************************************************************** 77500019
* THIS ROUTINE SEND AN ABORT EOT ON A SWITCHED LINE AND ALLOWS THE    * 77600019
* 2780 NINE TIMEOUTS TO RECOVER AND SEND MORE INPUT                   * 77700019
*********************************************************************** 77800019
         USING TDIREC,R4                                           000A 77900019
LSTABORT LA    R6,LSTEIGHT         LOAD A COUNT OF EIGHT FOR BCT   000A 78000019
         L     R3,LCBLDECB         LOADS LINE DECB                 000A 78100019
         L     R4,LCBTDIR          LOADS TERM DIRECTORY POINTER    000A 78200019
         LR    R1,R3                                               000A 78300019
         OI    DECTYPE,LSTTOFLG    INDICATE NO BTAM ERROR MESSAGE  000A 78400019
*                                  FOR TIME OUT                    000A 78500019
         WRITE (1),TN,MF=E         WRITE EOT                       000A 78600019
         LA    R10,LSTEOTCK        SET RETURN TO CHECK RESPONSE    000A 78700019
         BAL   R9,LSTRDTST         SETS ERROR-RETuRN EXIT          000A 78800019
LSTESTIO CLI   DECRESPN,LSTENQ     TEST RESPONSE FIELD FOR ENQ.    000A 78900019
         BE    LSTDISCT       IF ENQ IN GO READ CONTINUE         A53111 79000021
         TM    DECSENS0,LSTTIMO    TEST FOR TIME OUT               000A 79100019
         BZ    LSTRJEDF            NO GO DO RJENDF                 000A 79200019
         LR    R0,R6     SAVE LOOP COUNTER                       A53111 79220021
         BAL   R9,LSTWMSTP    CHECK STOP BIT                     A53111 79240021
         LR    R6,R0     RESTORE LOOP COUNTER                    A53111 79260021
         OI    DECTYPE,LSTTOFLG    INDICATE NO BTAM ERROR MESSAGE  000A 79300019
*                                  FOR TIME OUT                    000A 79400019
         READ  (1),TQ,MF=E         YES READ ENQ FOR NINE TIMES     000A 79500019
         LA    R9,LSTCOUNT         SETS ERROR RETURN EXIT          000A 79600019
         BAL   R10,LSTRDTST        SETS NORMAL RETURN EXIT         000A 79700019
         B     LSTDISCT                                          A53111 79800021
LSTCOUNT BCT   R6,LSTESTIO         COUNT NOT ZERO CHECK I/O        000A 79900019
         B     LSTRJEDF            COUNT ZERO DO RJENDF            000A 80000019
*******************************************************************000D 80100019
* THIS ROUTINE  DOES A BTAM LOPEN  IT IS USED EXCLUSIVLY FOR IBM  *000D 80200019
* WORLD TRADE MODEN 3977 MODEL2                                   *000D 80300019
*******************************************************************000D 80400019
LSTOPEN  EQU   *                                                   000D 80500019
         LOPEN (R3)                DISABLES AND ENABLES THE LINE   000D 80600019
         LTR   R15,R15             DID LOPEN WORK ? (NO WAIT AFT)A37785 80700020
         BZ    LSTBEGIN            YES, RETURN                   A37785 80800020
         B     LSTQUIT            CONTROL UNIT FAILURE STOP        000D 80900019
LSTFINI  L     R1,LCBDDECB         LOADS LINE ECB IN ONE AND SETS THE   81000019
         MVI   0(R1),LSTDZERO      COMPLETION BIT OFF IN ECB            81100019
LSTGDBYE B     LSTDSPE2            AND GOES TO THE DISPATCHER TO AWAIT  81200019
*                                  RJE CLOSE DOWN                       81300019
LSTCOMPR CLC   LSTZEROO(LSTZEROO,R7),LSTZEROO(R8) COMPARE FOR EXCUTE    81400019
LSTMVPOL MVC   TDIRDFTA+3(LSTZEROO),LSTZEROO(R5) MOVE POLLING      000C 81500019
*                                  CHARACTER(S) FROM TERMINAL      000A 81600019
*                                  TABLE TO DFTRMLST IN TDIR       000A 81700019
LSTSAVE  DC    2F'00'                                              000A 81800019
LSTWRBND DC    F'00'                                                    81900019
LSTCODE  DC    H'19'              CODE INDICATING ABNORMAL CENTRAL BOMB 82000019
LSTABLST DC    A(IHKABLST+2)       ENTRY POINT IN LINE SHEDULER SETBASE 82100019
LSTAADSP DC    V(IHKAADSP)         ENTRY ADDRESS OF DISPATCHER          82200019
LSTABLRD DC    V(IHKABLRD)         ENTRY ADDRESS OF LINE ANALYSIS READ  82300019
LSTABLWR DC    V(IHKABLWR)         ENTRY ADDRESS OF LINE ANALYSIS WRITE 82400019
LSTZEROQ DC    X'000000'           CONTANT TO CHECK TDIRFQEB FOR ZERO   82500019
LSTABRJF DC    V(IHKABRJF)         ENTRY POINT TO LRD FOR RJENDF        82600019
LSTCDRCS DC    V(IHKCDRCS)         ADDRESS OF STOP AND WRMSTART SWITCHS 82700019
LSTTO    DC    F'03'              FACTOR TO ELIIMNATE BTAM CONSTANTS    82800019
LSTSIX   DC    F'06'               THIS VALUE IS LENGTH OF EACH ENTRY   82900019
*                                  IN THE TERMINAL TABLE                83000019
LSTCODEF DC    H'13'     CODE INDICATOR  TO IHKABLR THAT IT IS TO GEN-  83100019
*                        ERATE A RJENDF                                 83200019
LSTFF    DC    X'00FF'     CODE FOR NO RJENDF MESSAGE              000A 83300019
LSTCOCOM DC    V(IHKCACOM)         ENTRY POINT TO AVT IN COMMAND INTERP 83400019
LSTERROR DC    X'00000014'         RETURN CODE SET BY BTAM FOR          83500019
*                                  A NON OPERATIONAL CONTROL UNIT       83600019
LSTPMSG1 DC    H'44'                                                    83700019
         DC    X'8000'                                             000C 83800019
         DC    C' IHK065I UNABLE TO OPEN DDNAME=XXXXXXXX '              83900019
         DC    X'10004000'         MCS CODES FOR COI, SS           000C 84000019
LSTCAINT DC    V(IHKCAINT)         INCLUDED IN THIS ROUTINE TO FORCE    84100019
*                                  LKED TO INCLUDE THIS ROUTINE THERE   84200019
*                                  BY GETTING THE REST OF RJE           84300019
LSTPMSG2 DC    H'38'                                                    84400019
         DC    X'8000'                                             000C 84500019
         DC    C' IHK064I LINE XXX NOT OPERATIONAL '                    84600019
         DC    X'10004000'         MCS CODES FOR COI, SS           000C 84700019
         DS    0F                                                A43087 84710021
LSTPMSG3 DC    H'42'                                             A43087 84720021
         DC    X'8000'                                           A43087 84730021
         DC    C' IHK069I LINE XXX DEFINED INCORRECTLY '         A43087 84740021
         DC    X'10004000'              MCS CODES FOR COI, SS    A43087 84750021
         DS    0F                                                  000A 84800019
LSTGDMS  DC    AL2(LSTGDMSX-*)                                     000A 84900019
         DC    X'8000'                                             000C 85000019
         DC    C'IHK066I '                                         000A 85100019
LSTTRMGD DC    CL8' ',C' '                                         000A 85200019
         DC    C'NOW RESPONDING TO POLLING'                        000A 85300019
LSTGDMSX EQU   *                                                   000A 85400019
         DC    X'10004000'         MCS CODES FOR COI, SS           000C 85500019
*                                                                  000A 85600019
         DS    0F                                                  000A 85700019
LSTBADMS DC    AL2(LSTBDMSX-*)                                     000A 85800019
         DC    X'8000'                                             000C 85900019
         DC    C'IHK067I '                                         000A 86000019
LSTTRMBD DC    CL8' ',C' '                                         000A 86100019
         DC    C'NOT RESPONDING TO POLLING'                        000A 86200019
LSTBDMSX EQU   *                                                   000A 86300019
         DC    X'10004000'         MCS CODES FOR COI, SS           000C 86400019
LSTZEROO EQU   0         DISPLACEMENT FACTOR                            86500019
LSTONE   EQU   1         DISPLACEMENT FACTOR                            86600019
LSTTTWO  EQU   2         DISPLACEMENT FACTOR                            86700019
LSTFOUR  EQU   4         DISPLACEMENT FACTOR                            86800019
LSTFIVE  EQU   5         DISPLACEMENT FACTOR                            86900019
LSTSIXX  EQU   6         DISPLACEMENT FACTOR                            87000019
LSTREIGH EQU   8                  DISPLACEMENT FACTOR              000D 87100019
LSTRFIVE EQU   35                 DISPLACEMENT FACTOR              000D 87200019
LSTHIBIT EQU   X'80'               MASK OF 3RD BYTE OF TERM TABLE  000A 87300019
*                                    ENTRY, INDICATES RESPONSE     000A 87400019
*                                    STATE OF POLLED TERMINAL      000A 87500019
LSTHIBTF EQU   X'7F'               NEGATIVE OF ABOVE MASK          000A 87600019
LSTRDER  EQU   X'08'               SWITCH FOR READER WARMSTART     000A 87700019
LSTTIMO  EQU   X'01'    SENSE SETTING INDICATING TIME OUT               87800019
LSTTOFLG EQU   X'40'               TO INDICATE IN DECTYPE NO BTAM  000A 87900019
*                                  ERROR MESSAGE FOR TIME OUT      000A 88000019
LSTTOOFF EQU   X'BF'               TO RESET DECTYPE FOR BTAM ERROR 000A 88100019
*                                  MESSAGE FOR TIME OUT            000A 88200019
LSTWRITE EQU   X'01'     INDICATES PREVIOUS OPER WAS A WRITE       000A 88300019
LSTHIOP  EQU   X'04'               SETTING FOR NEGATIVE RESPONSE TO000A 88400019
*              POLLING                                             000A 88500019
LSTDSCNT EQU   X'80'    SWITCH INDICATING A DISCONTINUED TERMINAL       88600019
DCBBUFC  EQU   X'14'    INDEX IN DCB TO BUFFER CONTROL BLOCK PTR   000A 88700019
LSTDZERO EQU   X'00'               USED TO ZERO ANY BYTE REFERENCE      88800019
LSTPOSTT EQU   X'40'              USED TO POST ECBS                     88900019
LSTGIO   EQU   X'7F'               CODE FOR GOOD BTAM RETURN            89000019
LSTHIO   EQU   X'48'               CODE FOR RESET POLL BTAM RETURN      89100019
LSTCGONE EQU   X'20'     SWITCH INDICATING RJENDC MSG GONE              89200019
LSTRESET EQU   X'BF'    SETS OFF WARMSTART BIT                          89300019
LSTDISP  EQU   X'80'     SWITCH INDICATING GO TO DISPATCHER TO WAIT FOR 89400019
*                        RJENDC TO POST ECB INDICATING RJENDC MSG READY 89500019
LSTLRDC  EQU   X'40'     SWITCH INDICATING GONE TO IHKABLRD TO HAVE     89600019
*                        RJENDC ENQUEUED                                89700019
LSTMDSW  EQU   X'FF'     SWITCH SET IN TERMINAL TABLE INDICATING THAT   89800019
*                        THIS TERMINAL HAS A RJENDC MSG GENERATED       89900019
LSTMSGON EQU   X'FE'     SWITCH SET IN TERMINAL TABLE INDICATING THAT   90000019
*                        THIS TERMINAL HAS RJENDC MSG SENT              90100019
LSTBDOP  EQU   X'80'    SWITCH SET TO INDICATE THAT 2701,02,03 IS       90200019
*                       NOT OPERATIONAL                                 90300019
LSTRJC   EQU   X'08'     SWITCH INDICATOR THAT A RJENDC IS DESIRED AND  90400019
*                        NOT RJENDF                                     90500019
LSTRTIB  EQU   *                                                   000D 90600019
LSTNINE  EQU   9              DISPLACEMENT FACTOR                  000D 90700019
LSTMARK  EQU   256            DISPLACEMENT FACTOR FOR MOVE OF TONE 000D 90800019
*                             CHARACTERS                           000D 90900019
LSTMRK   EQU   154            DISPLACEMENT FACTOR FOR MOVE OF TONE 000D 91000019
*                             CHARACTERS                           000D 91100019
LSTQMPA  EQU   48                 DISPLACEMENT FOR QMPA          A22264 91200019
LSTSYNC  EQU   X'32'              LINE SYNC CHARACTER             M2642 91250019
LSTMKCH  EQU   X'FF'          TONE CHARACTERS FOR LINE             000D 91300019
LSTMAR   EQU   257                DISPLACEMENT FACTOR              000D 91400019
LSTANST  EQU   X'FF'        CHECK FOR AN SWLST WITH ID CHARS IN    000D 91500019
*                           DEFINE TERMINAL LIST                   000D 91600019
         DCBD      DSORG=BX,DEVD=BS                                     91700019
         IECTDECB                                                       91800019
         IHKDSECT TDIR,,,,LCB,AVT                                       91900019
         END                                                            92000019
