ORT1     TITLE  ' OUTPUT ROUTING AND TRANSMITTING ROUTINE '             00060018
         SPACE                                                          00120018
IHKABORT CSECT                                                          00180018
         ENTRY IHKABLWT                                                 00240018
         EXTRN IHKADPCK                                                 00300018
         EXTRN    IHKTRTAB                                              00360018
* 113400,114600,120600,122400,123000,123600,125400,129600,130200   000D 00410019
* 171600,417600,418200,419400,528600,573000,591600,606000-606600   000D 00460019
* 612000,633600,765600,766200,817200,823200,823800,824400,825000   000D 00510019
*C622400                                                         A35908 00520020
*C192600-193100,790600,791800                                    A37778 00530020
*A 303100-303200,792360-792440                                   A53110 00540021
         SPACE 2                                                        00560019
*********************************************************************** 00610019
*---------------------------------------------------------------------* 00660019
*********************************************************************** 00710019
*-*                                                                 *-* 00760019
*-*                                                                 *-* 00810019
*-*  N A M E  --                                                    *-* 00860019
*-*                                                                 *-* 00910019
*-*     IHKABORT -  OUTPUT ROUTING AND TRANSMITTING MODULE          *-* 00960019
*-*                                                                 *-* 01010019
*-*                                                                 *-* 01060019
*-* STATUS: CHANGE LEVEL 2, RELEASE 21.7                            *-* 01110021
*-*                                                                 *-* 01160019
*-*                                                                 *-* 01210019
*-*  F U N C T I O N / O P E R A T I O N  --                        *-* 01260019
*-*                                                                 *-* 01310019
*-*     THE FUNCTIONS OF THIS MODULE ARE AS FOLLOWS -               *-* 01360019
*-*                                                                 *-* 01410019
*-*     1.  CONSTRUCT AND TRANSMIT HEADERS CONTAINING CONTROL       *-* 01460019
*-*     INFORMATION TO CPU WORK STATIONS.  TWO TYPES OF HEADERS ARE *-* 01510019
*-*     TRANSMITTED TO CPU WORK STATIONS, DATA AND CLOSEDOWN.       *-* 01560019
*-*                                                                 *-* 01610019
*-*     A.  THE DATA HEADER DESCRIBES THE RJE OUTPUT WHICH WILL BE  *-* 01660019
*-*     SENT TO THE WORK STATION FOLLOWING THE RECEIPT OF THE       *-* 01710019
*-*     HEADER.  DATA HEADERS ARE TRANSMITTED IN NON-TRANSPARENT    *-* 01760019
*-*     TEXT MODE AND HAVE THE FOLLOWING FORMAT AND CONTENT --      *-* 01810019
*-*                                                                 *-* 01860019
*-*      ********************************************************** *-* 01910019
*-*      *+0   *+1      *+2         *+3      *+4      *+8   *+9   * *-* 01960019
*-*      * SOH * DEVICE *  CONTROL  * RECORD * RECORD * STX * ETX * *-* 02010019
*-*      *     *  TYPE  * CHARACTER * FORMAT *  SIZE  *     *     * *-* 02060019
*-*      *     *        *           *        *        *     *     * *-* 02110019
*-*      ********************************************************** *-* 02160019
*-*                                                                 *-* 02210019
*-*     WHERE --                                                    *-* 02260019
*-*                                                                 *-* 02310019
*-*        SOH IS THE DATA LINK START OF HEADER CHARACTER           *-* 02360019
*-*                                                                 *-* 02410019
*-*        DEVICE TYPE CONTAINS --                                  *-* 02460019
*-*                                                                 *-* 02510019
*-*           C'1' FOR OUTPUT DESTINED FOR THE WORK STATION PRINTER *-* 02560019
*-*           C'2' FOR OUTPUT DESTINED FOR THE WORK STATION PUNCH   *-* 02610019
*-*           C'3' FOR RJE MESSAGE OUTPUT FOR EITHER THE WORK       *-* 02660019
*-*                STATION PRINTER/KEYBOARD IF AVAILABLE OR PRINTER *-* 02710019
*-*           C'4' FOR OUTPUT SPECIFIED TO BE PROCESSED BY A USER   *-* 02760019
*-*                EXIT AT THE WORK STATION.                        *-* 02810019
*-*                                                                 *-* 02860019
*-*        CONTROL CHARACTER INFORMATION --                         *-* 02960019
*-*                                                                 *-* 03010019
*-*           C'1' SPECIFIES OUTPUT CONTAINS MACHINE CODE CARRIAGE  *-* 03060019
*-*                CONTROL CHARACTERS.                              *-* 03110019
*-*           C'2' SPECIFIES OUTPUT CONTAINS ASA CARRIAGE CONTROL   *-* 03160019
*-*                CHARACTERS.                                      *-* 03210019
*-*           C'3' SPECIFIES CARRIAGE CONTROL CHARACTERS ARE NOT    *-* 03260019
*-*                PART OF THE OUTPUT                               *-* 03310019
*-*                                                                 *-* 03360019
*-*        RECORD FORMAT INFORMATION --                             *-* 03410019
*-*           C'1' SPECIFIES OUTPUT AS FIXED/UNBLOCKED              *-* 03460019
*-*           C'2' SPECIFIES OUTPUT AS FIXED/BLOCKED                *-* 03510019
*-*           C'3' SPECIFIES OUTPUT AS VARIABLE/UNBLOCKED           *-* 03560019
*-*           C'4' SPECIFIES OUTPUT AS VARIABLE/BLOCKED             *-* 03610019
*-*           C'5' SPECIFIES OUTPUT AS UNDEFINED                    *-* 03660019
*-*                                                                 *-* 03710019
*-*        RECORD SIZE CONTAINS --                                  *-* 03760019
*-*                                                                 *-* 03810019
*-*           THE LOGICAL RECORD LENGTH IN DECIMAL VALUE OF THE RJE *-* 03860019
*-*           OUTPUT WHICH WILL FOLLOW.                             *-* 03910019
*-*                                                                 *-* 03960019
*-*        STX IS THE DATA LINK CONTROL TEXT STARTING CHARACTER.    *-* 04010019
*-*                                                                 *-* 04060019
*-*        ETX IS THE DATA LINK CONTROL TEXT ENDING CHARACTER.      *-* 04110019
         EJECT                                                          04130021
*-*                                                                 *-* 04160019
*-*     B.  THE CLOSEDOWN HEADER IS TRANSMITTED TO THE CPU WORK     *-* 04210019
*-*     STATIONS WHEN THE CENTRAL OPERATOR ENTERS A STOP COMMAND    *-* 04260019
*-*     FOR THE RJE TASK.  THE HEADER TELLS THE CPU WORK STATION    *-* 04310019
*-*     THAT RJE ACTIVITY IS BEING TERMINATED AT THE CENTRAL SYSTEM *-* 04360019
*-*     AND HAS THE FOLLOWING FORMAT AND CONTENT --                 *-* 04410019
*-*                                                                 *-* 04460019
*-*                ********************************                 *-* 04510019
*-*                *     *            *     *     *                 *-* 04560019
*-*                * SOH * CLOSEDOWN  * STX * ETX *                 *-* 04610019
*-*                *     * INDICATOR  *     *     *                 *-* 04660019
*-*                *     *            *     *     *                 *-* 04710019
*-*                ********************************                 *-* 04760019
*-*                                                                 *-* 04810019
*-*     WHERE --                                                    *-* 04860019
*-*                                                                 *-* 04910019
*-*         SOH IS THE DATA LINK CONTROL START OF HEADER CHARACTER. *-* 04960019
*-*                                                                 *-* 05010019
*-*         CLOSEDOWN INDICATOR CONTAINS --                         *-* 05060019
*-*                                                                 *-* 05110019
*-*           C'5' TO TELL THE CPU WORK STATION THAT THE CENTRAL    *-* 05160019
*-*           OPERATOR HAS INITIATED CENTRAL CLOSEDOWN.             *-* 05210019
*-*                                                                 *-* 05260019
*-*         STX IS THE DATA LINK CONTROL TEXT STARTING CHARACTER.   *-* 05310019
*-*                                                                 *-* 05360019
*-*         ETX IS THE DATA LINK CONTROL TEXT ENDING CHARACTER.     *-* 05410019
*-*                                                                 *-* 05460019
*-*                                                                 *-* 05510019
         EJECT                                                          05560019
*-*     2.  RJE OUTPUT TRANSMISSION TO CPU WORK STATIONS.           *-* 05610019
*-*                                                                 *-* 05660019
*-*         ALL RJE OUTPUT TRANSMISSIONS TO CPU WORK STATIONS ARE   *-* 05710019
*-*     SENT IN THE TRANSPARENT MODE OF COMMUNICATION. THIS OUTPUT  *-* 05760019
*-*     CONSISTS OF EITHER MESSAGE OUTPUT OR JOB OUTPUT.  THE       *-* 05810019
*-*     MAXIMUM LENGTH OF OUTPUT TRANSMISSIONS IS 404 BYTES.  THIS  *-* 05860019
*-*     ALLOWS A MAXIMUM OF 400 BYTES OF DATA AND FOUR DATA LINK    *-* 05910019
*-*     CONTROL CHARACTERS PER TRANSMISSION.                        *-* 05960019
*-*                                                                 *-* 06010019
*-*     A.  MESSAGE OUTPUT IS TRANSMITTED AS FIXED/UNBLOCKED        *-* 06060019
*-*     DATA AND HAS A RECORD LENGTH OF SIXTY BYTES.                *-* 06110019
*-*                                                                 *-* 06160019
*-*     B.  JOB OUTPUT MAY CONSIST OF PUNCH, PRINTER, OR USER EXIT  *-* 06210019
*-*     DATA.  PUNCH AND PRINTER OUTPUT PROCESSING VARIES ACCORDING *-* 06260019
*-*     TO RECORD FORMAT, THE AVAILIBILITY OF THE COMPRESS/EXPAND   *-* 06310019
*-*     FACILITY OF THE WORK STATION, AND THE LENGTH OF THE OUTPUT  *-* 06360019
*-*     RECORD BEING PROCESSED.  USER EXIT DATA IS ALWAYS PROCESSED *-* 06410019
*-*     AS FOLLOWS.                                                 *-* 06460019
*-*                                                                 *-* 06510019
*-*     - USER EXIT OUTPUT PROCESSING -                             *-* 06560019
*-*                                                                 *-* 06610019
*-*         USER EXIT OUTPUT IS TRANSMITTED IN BLOCKS OF DATA WHERE *-* 06660019
*-*     THE BLOCK LENGTH OF THE DATA TRANSMITTED IS DETERMINED      *-* 06710019
*-*     BY THE DCB LRECL FIELD FOR THE DATA SET.                    *-* 06760019
*-*                                                                 *-* 06810019
*-*     - PUNCH AND PRINTER OUTPUT PROCESSING -                     *-* 06860019
*-*                                                                 *-* 06910019
*-*         RECORD LENGTH IS CHECKED AGAINST MAXIMUM DEVICE SIZE    *-* 06960019
*-*     EIGHTY BYTES IS ALLOWED FOR PUNCHED OUTPUT AND MAXIMUM      *-* 07010019
*-*     PRINTER SIZE IS CONTAINED IN THE TDIRPRNT FIELD OF THE      *-* 07060019
*-*     WORK STATION'S TERMINAL DIRECTORY ENTRY.  IF THE OUTPUT     *-* 07110019
*-*     DATA CONTAINS CARRIAGE CONTROL CHARACTERS A RECORD LENGTH   *-* 07160019
*-*     OF DEVICE SIZE PLUS ONE.  IF THE RECORD LENGTH EXCEEDS THAT *-* 07210019
*-*     WHICH IS DETERMINED AS ALLOWABLE THE DATA IS TRUNCATED TO   *-* 07260019
*-*     THE MAXIMUM SIZE FOR THE DEVICE.  A RECORD IS TRUNCATED TO  *-* 07310019
*-*     ALLOWABLE LIMITS REGARDLESS OF WHETHER OR NOT THE WORK      *-* 07360019
*-*     STATION HAS THE COMPRESS/EXPAND FACILITY.                   *-* 07410019
*-*                                                                 *-* 07460019
*-*         RECORD FORMAT PROCESSING IS DEPENDENT UPON THE PRESENCE *-* 07510019
*-*     OF THE COMPRESS/EXPAND FEATURE AT THE WORK STATION.  IF THE *-* 07560019
*-*     WORK STATION DOES NOT HAVE COMPRESS/EXPAND CAPABILITY, ALL  *-* 07610019
*-*     PUNCH AND PRINTER OUTPUT IS TRANSMITTED AS FIXED BLOCKED.   *-* 07660019
*-*     VARIABLE AND UNDEFINED DATA IS PADDED WITH BLANKS TO THE    *-* 07710019
*-*     MAXIMUM DEVICE SIZE, BLOCKED USING THIS LENGTH, AND         *-* 07760019
*-*     TRANSMITTED WHEN THE BUFFER CANNOT HOLD ANOTHER RECORD OF   *-* 07810019
*-*     THIS LENGTH.  THE BLOCKING FACTOR USED FOR FIXED LENGTH     *-* 07860019
*-*     DATA IS THAT OF THE LOGICAL RECORD IF IT IS NOT GREATER     *-* 07910019
*-*     THAN THE MAXIMUM DEVICE SIZE.                               *-* 07960019
*-*                                                                 *-* 08010019
         EJECT                                                          08060019
*-*         COMPRESS/EXPAND PROCESSING INVOLVES REMOVING TRAILING   *-* 08110019
*-*     AND IMBEDDED BLANKS IN PUNCH AND PRINTER OUTPUT. EACH       *-* 08160019
*-*     COMPRESSED OUTPUT RECORD HAS THE FOLLOWING FORMAT.          *-* 08210019
*-*                                                                 *-* 08260019
*-*     *********************************************************** *-* 08310019
*-*     *    **    *      *    *    *      *    *     *    *      * *-* 08360019
*-*     * TT ** LL * TEXT * BB * LL * TEXT * BB * ... * LL * TEST * *-* 08410019
*-*     *    **    *      *    *    *      *    *     *    *      * *-* 08460019
*-*     *********************************************************** *-* 08510019
*-*                                                                 *-* 08560019
*-*     WHERE --                                                    *-* 08610019
*-*         TT IS THE TOTAL LENGTH OF THE COMPRESSED RECORD         *-* 08660019
*-*            (INCLUDING THE TT BYTE.)                             *-* 08710019
*-*                                                                 *-* 08760019
*-*         LL IS THE LENGTH OF THE FOLLOWING TEXT (NOT INCLUDING   *-* 08810019
*-*            THE LL BYTE).                                        *-* 08860019
*-*                                                                 *-* 08910019
*-*         BB IS THE NUMBER OF BLANKS SUPPRESSED BEFORE THE        *-* 08960019
*-*            NEXT TEXT AREA OF THE RECORD.                        *-* 09010019
*-*                                                                 *-* 09060019
*-*     ** NOTE **                                                  *-* 09110019
*-*         THERE IS NO BB BYTE COUNT AT THE END OF THE COMPRESSED  *-* 09160019
*-*         RECORD TO INDICATE THE NUMBER OF TRAILING BLANKS        *-* 09210019
*-*         SUPPRESSED IN THE RECORD.                               *-* 09260019
*-*                                                                 *-* 09310019
*-*     OUTPUT DATA IS ALWAYS COMPRESSED IN THE BTAM BUFFER.  IF    *-* 09360019
*-*     THE BUFFER CANNOT HOLD THE MAXIMUM LENGTH RECORD. THE BTAM  *-* 09410019
*-*     BUFFER IS EMPTY BY WRITING THE DATA TO THE WORK STATION.    *-* 09460019
*-*     THE RECORD IS THEN COMPRESSED INTO THE EMPTY BUFFER AND     *-* 09510019
*-*     THE TTR IS SAVED FOR DISCONTINUE PROCESSING.                *-* 09560019
*-*                                                                 *-* 09610019
*-*     3.  RJE  OUTPUT TRANSMISSION TO 2780 / 2770 WORK STATIONS   *-* 09660019
*-*                                                                 *-* 09710019
*-*         RJE OUTPUT TRANSMISSION TO THE 2780/2770 USES BOTH      *-* 09760019
*-*     THE TRANSPARENT AND NONTRANSPARENT MODE OF BINARY           *-* 09810019
*-*     SYNCHRONOUS COMMUNICATION.  THE TRANSPARENT MODE IS USED    *-* 09860019
*-*     ONLY TO SEND PUNCH OUTPUT.  ALL OTHER OUTPUT, RJE MESSAGE,  *-* 09910019
*-*     USER EXIT, AND PRINTER IS SENT IN NONTRANSPARENT TEXT MODE. *-* 09960019
*-*     THIS OUTPUT IS EDITED PRIOR TO TRANSMISSION.  IF ANY DATA   *-* 10010019
*-*     LINK CONTROL CHARACTERS ARE FOUND IN OUTPUT WHICH IS TO BE  *-* 10060019
*-*     PRINTED, THEY ARE REPLACED WITH BLANKS.                     *-* 10110019
*-*                                                                 *-* 10160019
*-*     4.  CONVERSION OF CARRIAGE CONTROL CHARACTERS TO EQUIVALENT *-* 10210019
*-*     2780/2770 CARRIAGE OPERATIONS                               *-* 10260019
*-*                                                                 *-* 10310019
*-*         MACHINE CODE AND ASA CARRIAGE CONTROL CHARACTERS ARE    *-* 10360019
*-*     TRANSLATED TO THE PROPER ESCAPE SEQUENCE WHICH PROVIDES     *-* 10410019
*-*     THE EQUIVALENT CARRIAGE OPERATION ON THE PRINTER            *-* 10460019
*-*     CHANNEL SKIPS OF NINE  THRU TWELVE                          *-* 10510019
*-*     WHICH ARE NOT PROVIDED AS CARRIAGE CONTROL FUNCTIONS WITH   *-* 10560019
*-*     THE 2780 ESCAPE SEQUENCE DEFAULT TO WRITE AND SPACE ONE (   *-* 10610019
*-*     MACHINE CODE) OR SPACE ONE AND WRITE(ASA). CHANNEL SKIPS    *-* 10660019
*-*     OF 9 THRU 12 ARE RESOLVED FOR THE 2770. SUPPRESS SPACE IS   *-* 10710019
*-*     NOT SUPPORTED FOR EITHER THE 2780 OR 2770.                  *-* 10760019
*-*                                                                 *-* 10860019
*-*         DATA SETS NOT CONTAINING CARRIAGE CONTROL CHARACTERS    *-* 10910019
*-*     ARE PRECEDED WITH AN ESCAPE SEQUENCE TO SKIP TO CHANNEL ONE *-* 10960019
*-*     AND THE OUTPUT IS SINGLE SPACED ON THE PRINTER.             *-* 11010019
*-*                                                                 *-* 11060019
*-*     STACKER SELECT CARRIAGE CONTROL CHARACTERS FOR PUNCH        *-* 11110019
*-*     OUTPUT ARE IGNORED. THE 2770 PUNCH MUST BE OUTPUT DEVICE 2  *-* 11160019
*-*                                                                 *-* 11210019
*-*     5.  BLOCKING 2780 OUTPUT                                    *-* 11260019
*-*                                                                 *-* 11310019
*-*         PUNCH OUTPUT IS TRANSMITTED AS FIXED UNBLOCKED 80       *-* 11360019
*-*     CHARACTER RECORDS.  TRAILING BLANKS ARE REMOVED FROM        *-* 11410019
*-*     PRINTED OUTPUT AND BLOCKED UP TO SEVEN RECORDS PER          *-* 11460019
*-*     TRANSMISSION DEPENDING ON WHETHER THE WORK STATION HAS THE  *-* 11510019
*-*     MULTIPLE RECORD TRANSMISSION FEATURE (MRT).  IF THE         *-* 11560019
*-*     WORK STATION DOES NOT HAVE MRT, TRANSMISSIONS WILL NOT      *-* 11610019
*-*     CONTAIN MORE THAN TWO RECORDS.  IF MRT IS INSTALLED AT THE  *-* 11660019
*-*     WORK STATION, A MAXIMUM OF SEVEN RECORDS WILL BE SENT PER   *-* 11710019
*-*     TRANSMISSION IF THE LINE BUFFER CAN HOLD THEM.              *-* 11760019
*-*                                                                 *-* 11810019
*-*     6.  BTAM ERROR PROCESSING                                   *-* 11860019
*-*                                                                 *-* 11910019
*-*         UNRECOVERABLE LINE ERRORS ARE PROCESSED BY INVOKING     *-* 11960019
*-*     RJENDF PROCEDURES.  EOT RESPONSES TO WRITE OPERATIONS       *-* 12010019
*-*     INVOKE DISCONTINUE PROCESSING.  IF A CONTENTION SITUATION   *-* 12060019
*-*     OCCURS WHILE BIDDING FOR THE LINE,  INTERNAL DISCONTINUE    *-* 12110019
*-*     PROCEDURES ARE INVOKED.                                     *-* 12160019
*-*                                                                 *-* 12210019
*-*                                                                 *-* 12260019
*-*                                                                 *-* 12310019
*-*  E N T R Y   P O I N T  --                                      *-* 12360019
*-*                                                                 *-* 12410019
*-*     IHKABLWT IS THE ENTRY POINT ASSIGNED TO THIS MODULE.  IT    *-* 12460019
*-*     IS CALLED BY IHKCHLWR (MFT ENVIRONMENT) AND IHKABLWR (MVT   *-* 12510019
*-*     ENVIRONMENT).                                               *-* 12560019
*-*                                                                 *-* 12610019
*-*                                                                 *-* 12660019
*-*  I N P U T  --                                                  *-* 12710019
*-*                                                                 *-* 12760019
*-*     LCBPARM1 POSITIVE - LOGICAL RECORDS OF JOB OUTPUT OR AN RJE *-* 12810019
*-*                         MESSAGE TO BE SENT TO THE WORK STATION. *-* 12860019
*-*     LCBPARM1 NEGATIVE - TRANSMIT CLOSE DOWN HEADER TO CPU       *-* 12910019
*-*                         WORK STATIONS.                          *-* 12960019
*-*     LCBPARM1 ZERO - INSURE LINE BUFFER EMPTY AND PREPARE TO     *-* 13010019
*-*                     PROCESS HEADER REQUIREMENTS.                *-* 13060019
         EJECT                                                          13110021
*-*  O U T P U T  --                                                *-* 13210019
*-*                                                                 *-* 13260019
*-*     CONTENTS OF LINE BUFFER TRANSMITTED TO THE WORK STATION.    *-* 13310019
*-*                                                                 *-* 13360021
*-*  E X T E R N A L   R O U T I N E S  --                          *-* 13410019
*-*                                                                 *-* 13460019
*-*         IHKCHDSP- TO WAIT FOR LINE I/O COMPLETION.              *-* 13510019
*-*         IHKCHPCK- TO COMPRESS OUTPUT RECORDS FOR TRANSMISSION   *-* 13560019
*-*                   TO CPU WORK STATIONS WITH THIS CAPABILITY.    *-* 13610019
*-*                                                                 *-* 13660019
*-*                                                                 *-* 13710019
*-*  E X I T S  --                                                  *-* 13760019
*-*                                                                 *-* 13810019
*-*     NORMAL- RETURN TO THE LWR MODULE WITH REG. 15 CONTAINING    *-* 13860019
*-*             A ZERO RETURN CODE                                  *-* 13910019
*-*     ERROR- RETURN TO THE LWR MODULE WITH REG. 15 CONTAINING     *-* 13960019
*-*             A FOUR RETURN CODE AND LCBPARM1 CONTAINING ONE OF   *-* 14010019
*-*             THE FOLLOWING VALUES.                               *-* 14060019
*-*          1.  LCBPARM1 POSITIVE-  LINE FAILURE                   *-* 14110019
*-*          2.  LCBPARM1 NEGATIVE-  DISCONTINUE                    *-* 14160019
*-*          3.  LCBPARM1 ZERO-  CONTENTION                         *-* 14210019
*-*                                                                 *-* 14260019
*-*                                                                 *-* 14310019
*-*  T A B L E S / W O R K A R E A S                                *-* 14360019
*-*                                                                 *-* 14410019
*-*     LINE CONTROL BLOCK- LINE DISCRIPTION AND PARAMETER LIST     *-* 14460019
*-*     TERMINAL DIRECTORY ENTRY- WORK STATION DESCRIPTION AND      *-* 14510019
*-*                               STATUS                            *-* 14560019
*-*     IHKTRTAB- TRANSLATE TABLE FOR 2780/2770 PRINTER OUTPUT EDIT *-* 14610019
*-*     LINE DECB- DETERMINE WRITE OPERATION COMPLETION STATUS      *-* 14660019
*-*     LWR/LWT WORK AREA- OUTPUT DESCRIPTION AND REENTRANT         *-* 14710019
*-*                        WORK AREA                                *-* 14760019
*-*     BTAM OUTPUT BUFFER- GATHER OUTPUT FOR TRANSMISSION          *-* 14810019
*-*                                                                 *-* 14860019
*-*                                                                 *-* 14910019
*-*  A T T R I B U T E S  --                                        *-* 14960019
*-*                                                                 *-* 15010019
*-*     RESIDENT AND SO-SO REENTRANT                                *-* 15060019
*-*                                                                 *-* 15110019
*-*                                                                 *-* 15160019
*-*  N O T E S --                                                   *-* 15210019
*-*                                                                 *-* 15260019
*-*         THIS MODULE APPLICABLE TO RELEASE 18 AND ABOVE.         *-* 15310019
*-*     EXECUTION OF THIS MODULE DEPENDS UPON AN INTERNAL CHARACTER *-* 15360019
*-*     SET COMPATIBLE TO THAT DURING ASSEMBLY.                     *-* 15410021
*-*                                                                 *-* 15610019
*-*******************************************************************-* 15660019
*---------------------------------------------------------------------* 15710019
*********************************************************************** 15760019
         EJECT                                                          15810019
*********************************************************************** 15860019
*---------------------------------------------------------------------* 15910019
*-*******************************************************************-* 15960019
*-*                                                                 *-* 16010019
*-*      S Y M B O L I C   R E G I S T E R   U S A G E              *-* 16060019
*-*                                                                 *-* 16110019
*-*                                                                 *-* 16160019
*-*******************************************************************-* 16210019
*---------------------------------------------------------------------* 16260019
*********************************************************************** 16310019
         SPACE 2                                                        16360019
ZIP      EQU   0                   GENERAL WORK REGISTER                16410019
         SPACE                                                          16460019
PAR      EQU   1                   PARAMETER LIST ADDRESS FOR LINKAGE   16510019
*                                   AND LINE DECB BASE (DSECT)          16560019
LCB      EQU   2                   LINE CONTROL BLOCK BASE (DSECT)      16610019
         SPACE                                                          16660019
TDE      EQU   3                   TERMINAL DIRECTORY ENTRY BASE (DSECT 16710019
         SPACE                                                          16760019
LNK      EQU   4                   INTERNAL BRANCH REGISTER             16810019
         SPACE                                                          16860019
EWA      EQU   5                   EMITTOR WORK AREA BASE (DSECT)       16910019
         SPACE                                                          16960019
LNG      EQU   6                   RECORD LENGTH PASSED IN LCB          17010019
         SPACE                                                          17060019
RAD      EQU   7                   RECORD ADDRESS PASSED IN LCB AND     17110019
*                                  - OVERFLOW BUFFER ADDRESS            17160019
         SPACE                                                          17210019
CBA      EQU   8                   CURRENT FREE BUFFER AREA ADDRESS     17260019
         SPACE                                                          17310019
CNT      EQU   9                   BUFFER RECORD COUNT                  17360019
         SPACE                                                          17410019
LK2      EQU   9                   INTERNAL BRANCH REGISTER             17460019
         SPACE                                                          17510019
MRL      EQU  10                   MAXIMUM RECORD LENGTH                17560019
         SPACE                                                          17610019
BSA      EQU  11                   BUFFER START ADDRESS                 17660019
         SPACE                                                          17710019
BAS      EQU  12                   MODULE BASE ADDRESS                  17760019
         SPACE                                                          17810019
SAV      EQU  13                   MODULE SAVE AREA ADDRESS             17860019
         SPACE                                                          17910019
BAC      EQU  14                   RETURN LINKAGE AND WORK REG          17960019
         SPACE                                                          18010019
GO       EQU  15                   ENTRY LINKAGE, RETURN CODE, AND      18060019
*                                  - WORK REG                           18110019
         EJECT                                                          18160019
*********************************************************************** 18210019
*---------------------------------------------------------------------* 18260019
*-*******************************************************************-* 18310019
*-*                                                                 *-* 18360019
*-*      S Y M B O L I C   D I S P L A C E M E N T S ,              *-* 18410019
*-*         V A L U E S ,   AND   L E N G T H S                     *-* 18460019
*-*                                                                 *-* 18510019
*-*******************************************************************-* 18560019
*---------------------------------------------------------------------* 18610019
*********************************************************************** 18660019
         SPACE 2                                                        18710019
ZERO     EQU   0         DISPLACEMENT, LENGTH AND VALUE                 18760019
ONE      EQU   1         DISPLACEMENT, LENGTH AND VALUE                 18810019
TWO      EQU   2         DISPLACEMENT, LENGTH AND VALUE                 18860019
TRE      EQU   3         DISPLACEMENT AND LENGTH                        18910019
FOR      EQU   4         DISPLACEMENT, LENGTH AND VALUE                 18960019
SEV      EQU   7         VALUE                                          19010019
ATE      EQU   8         LENGTH                                         19060019
TWLV     EQU  12         DISPLACEMENT                                   19110019
RJENDF   EQU  13         VALUE FOR BTAM LINE ERROR INDICATOR            19160019
FIFTEEN  EQU   15                  DISPLACEMENT FACTOR             000D 19210019
TOT124   EQU   124                 2770 BUFFER SIZE              A37778 19260020
TOT252   EQU   252                 2770 EXTENDED BUFFER SIZE     A37778 19310020
BLANK    EQU   X'40'               BLANK FOR ALL WIPE OUTS         000D 19360019
QMPA     EQU  48         DISPLACEMENT OF THE LINE BUFFER FROM LCBBUFER  19410019
STY      EQU  60         DISPLACEMENT                                   19460019
ATY      EQU  80         DISPLACEMENT                                   19510019
L80      EQU  80                                                        19560019
PUNLNG   EQU  81         MAXIMUM PUNCH OUTPUT LENGTH                    19610019
L199     EQU 199         LENGTH                                         19660019
L200     EQU 200         LENGTH                                         19710019
D202     EQU 202         DISPLACEMENT                                   19760019
D203     EQU 203         DISPLACEMENT                                   19810019
D241     EQU 241         DISPLACEMENT FOR ASA CODE TRANSLATION          19860019
SKIPD256 EQU 256         DISPLACEMENT                                   19910019
L256     EQU 256         LENGTH                                         19960019
BSIZ     EQU 396         LENGTH OF LINE BUFFER LESS DATA LINK CONTROL   20010019
         SPACE                                                          20060019
* SHIFT INSTRUCTION VALUES                                              20110019
         SPACE                                                          20160019
D256     EQU   8         SHIFT VALUE TO DIVIDE BY 256                   20210019
D24      EQU  24         SHIFT VALUE TO CONVERT HIGH ORDER BYTE TO LOW  20260019
*                        - ORDER BYTE                                   20310019
SHIF25   EQU  25         SHIFT VALUE TO REMOVE SKIP INDICATOR IN C.C.   20360019
         EJECT                                                          20410021
* OUTPUT DESCRIPTION VALUES                                             20460019
         SPACE                                                          20510019
FU       EQU   C'1'      FIXED UNBLOCKED FORMAT                         20560019
FB       EQU   C'2'      FIXED BLOCKED FORMAT                           20610019
PUNO     EQU   C'2'      PUNCH OUTPUT                                   20660019
MO       EQU   C'3'      MESSAGE OUTPUT                                 20710019
UXO      EQU   C'4'      USER EXIT OUTPUT                               20760019
MC       EQU   C'1'      DATA CONTAINS MACHINE CODE CARRIAGE CONTROL    20810019
ASA      EQU   C'2'      DATA CONTAINS ASA CARRIAGE CONTROL             20860019
NCC      EQU   C'3'      DATA CONTAINS NO CARRIAGE CONTROL CHARACTERS   20910019
         SPACE                                                          20960019
* SYMBOLIC CONDITION CODES                                              21110019
         SPACE                                                          21160019
ON       EQU   1         BRANCH ON CONDITION ONES                       21210019
HI       EQU   2         BRANCH ON CONDITION HIGH                       21260019
LO       EQU   4         BRANCH ON CONDITION LOW                        21310019
NE       EQU   7         BRANCH ON CONDITION NOT EQUAL                  21360019
EQ       EQU   8         BRANCH ON CONDITION EQUAL                      21410019
         SPACE                                                          21460019
* CPU HEADER LENGTHS                                                    21510019
         SPACE                                                          21560019
CHDR     EQU   3         CPU CLOSEDOWN HEADER LENGTH LESS ONE           21610019
HDRLNG   EQU   9         NORMAL CPU HEADER LENGTH LESS ONE              21660019
         SPACE                                                          21710019
* BINARY SYNCHRONOUS DATA LINK CONTROL CHARACTERS                       21760019
         SPACE                                                          21810019
SOH      EQU   X'01'     START OF HEADER CHARACTER                      21860019
STX      EQU   X'02'     START OF TEXT CHARACTER                        21910019
ETX      EQU   X'03'     END OF TEXT CHARACTER                          21960019
US       EQU   X'1F'     UNIT SEPARATOR CHARACTER                       22010019
ESC      EQU   X'27'     ESCAPE CHARACTER                               22060019
EOT      EQU   X'37'     END OF TRANSMISSION CHARACTER                  22110019
NAK      EQU   X'3D'     NEGATIVE ACKNOWLEDGEMENT CHARACTER             22160019
WACK     EQU   X'6B'               WAIT BEFORE ACKNOWLEDGEMENT     000D 22210019
IRS      EQU   X'1E'               RECORD SEPATOR CHARACTER        000D 22260019
TIMEOUT  EQU   X'01'              TIMEOUT BIT IN DECB              000D 22310019
ENQ      EQU   X'2D'              BID FOR LINE CONTROL CHARACTER   000E 26080018
ETB      EQU   X'26'               ETB CHARACTER FOR LINE CONTROL  000D 26085019
TDIRETXO EQU   X'08'                                                    26090019
TDIRETXF EQU   X'F7'                                                    26095019
         EJECT                                                          26097021
         SPACE                                                          26100018
* BTAM COMPLETION CODES AND FLAGS                                       26160018
         SPACE                                                          26220018
CONTENT  EQU   X'10'     CONTENTION OCCURRED ON WRITE OPERATION         26280018
IOERR    EQU   X'41'     I/O ERROR OCCURRED                             26340018
NORMAL   EQU   X'7F'     NORMAL COMPLETION                              26400018
*    BTAM     DECTYPE    FLAGS                                     000D 26450019
WTI      EQU   X'02'               WRITE INITIAL                   000D 26500019
WTIX     EQU   X'12'               WRITE INITIAL TRANSPARENT       000D 26550019
         SPACE                                                          26600019
* 2780 COMPONENT SELECTION CHARACTERS                                   26650019
         SPACE                                                          26700019
PRTID    EQU   C'3'      PRINTER SELECTION CHARACTER                    26750019
PUNID    EQU   C'4'      PUNCH SELECTION CHARACTER                      26800019
DC1      EQU   X'11'               2770 PRINTER SELECTION CHARACTER000D 26850019
DC2      EQU   X'12'               2770 PUNCH SELECTION CHARACTER  000D 26900019
         SPACE                                                          26950019
* MACHINE CODE MASKS AND COMMAND CODES                                  27000019
CONE     EQU   X'F1'               SKIP TO CHANNEL ONE             000D 27050019
         SPACE                                                          27100019
IMMEDOP  EQU   X'03'     MASK USED TO TEST FOR AN IMMEDIATE OPERATION   27150019
SKIPOPR  EQU   X'80'     MASK USED TO TEST FOR A SKIP OPERATION         27200019
WRTSP1   EQU   X'09'     WRITE AND SINGLE SPACE COMMAND CODE            27250019
WRTSP2   EQU   X'11'     WRITE AND DOUBLE SPACE COMMAND CODE            27300019
WRTSP3   EQU   X'19'     WRITE AND TRIPLE SPACE COMMAND CODE            27350019
         SPACE                                                          27400019
* SELECTED ASA CARRIAGE CONTROL CHARACTERS                              27450019
         SPACE                                                          27500019
F0       EQU   C'0'      DOUBLE SPACE AND WRITE CARRIAGE CONTROL        27550019
F8       EQU   C'8'      SKIP TO CHANNEL 8 AND WRITE CARRIAGE CONTROL   27600019
ASTIS    EQU   C'-'      TRIPLE SPACE AND WRITE CARRIAGE CONTROL        27650019
ABLE     EQU   C'A'                                                000D 27700019
CHARB    EQU   C'B'                SKIP TO CHANNEL ELEVEN          000D 27750019
CHARC    EQU   C'C'                SKIP TO CHANNEL 12              000D 27800019
         SPACE                                                          27850019
* TEMPORARY DSECT RELATED MASKS                                         27900019
         SPACE                                                          27950019
LCBSWOFF EQU   X'00'     MASK USED TO SET LCBNSWFL BYTE SWITCHES OFF    28000019
BLNK     EQU   C' '                                                     28050019
         EJECT                                                          28100019
*********************************************************************** 28150019
*---------------------------------------------------------------------* 28200019
*-*******************************************************************-* 28250019
*-*                                                                 *-* 28300019
*-*               E N T R Y   L I N K A G E                         *-* 28350019
*-*                                                                 *-* 28400019
*-*******************************************************************-* 28450019
*---------------------------------------------------------------------* 28500019
*********************************************************************** 28550019
         SPACE 2                                                        28600019
IHKABLWT DS    0H             **** MODULE ENTRY POINT                   28650019
         SPACE                                                          28700019
         B     TWLV(ZIP,GO)        BRANCH AROUND MODULE ID              28750019
         SPACE                                                          28800019
         DC    CL8'IHKABORT'       MODULE IDENTIFICATION                28850019
         SPACE                                                          28900019
*        L     LCB,ZERO(PAR)       GET LINE CONTROL BLOCK (LCB) ADDRESS 28950019
    USING      LCBDSECT,LCB        TELL ASSEMBLER ABOUT LCB DSECT       29000019
         SPACE                                                          29050019
*        L     EWA,LCBWORKA        GET EMITTOR WORK AREA ADDRESS FROM   29100019
*                                  - LCB                                29150019
    USING      LWKWORK,EWA         TELL ASSEMBLER ABOUT EMITTOR WORK    29200019
*                                  - AREA DSECT                         29250019
         SPACE                                                          29300019
*        L     TDE,LCBTDIR         GET TERMINAL DIRECTORY ENTRY ADDRESS 29350019
    USING      TDIREC,TDE          TELL ASSEMBLER OF DSECT BASE         29400019
         SPACE                                                          29450019
    USING      IECTDECB,PAR        TELL ASSEMBLER OF DSECT BASE         29500019
         SPACE                                                          29550019
         STM   LNK,BAC,LWKSAVE     SAVE REGS FOR MICKEY MOUSE INTERFACE 29600019
         BALR  BAS,ZIP             SET UP MODULE ADDRESSABILITY         29650019
         SPACE                                                          29700019
    USING      *,BAS               TELL ASSEMBLER OF BASE REG CHOICE    29750019
         SPACE 2                                                        29800019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 29850019
*                                                                     * 29900019
*        I N I T I A L I Z E   AND   R E T R I E V E   P A R M S      * 29950019
*                                                                     * 30000019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 30050019
         SPACE                                                          30100019
         L     BSA,LCBBUFER        GET LINE BUFFER POINTER LESS QMPA    30150019
         LA    BSA,QMPA(BSA)       STEP PAST QMPA FOR LINE BUFFER ADDR  30200019
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 30250019
         BO    BUF2770             YES COMPUTE BUFFER END          000D 30300019
         TM    TDIRSWCH+2,TDIRMCHN      IS THIS A 2780           A53110 30310021
         BZ    BUF2780                  YES - COMPUTE BUFFER END A53110 30320021
         LA    ZIP,BSIZ(BSA)       GET END OF BUFFER ADDRESS FOR        30350019
*                                  - BLOCKING SUBROUTINES USE           30400019
RESUME   DS    0H                                                  000D 30450019
         ST    ZIP,LWKBFEND        SAVE BUFFER ENDING ADDRESS           30600018
         LM    LNG,RAD,LCBPARM1    GET LOGICAL RECORD LENGTH AND ADDR   30660018
         SPACE 2                                                        30780018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 30840018
*                                                                     * 30900018
*     D E T E R M I N E   R E A S O N   FOR   E N T R Y               * 30960018
*                                                                     * 31020018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 31080018
         SPACE                                                          31140018
         LM    CBA,MRL,LWKORTSV    PICK UP BUFFER MANAGEMENT INFO       31200018
         LTR   LNG,LNG             WHY HAS MODULE BEEN ENTERED          31260018
         BM    HANGITUP            CENTRAL CLOSEDOWN - HANG IT UP TILL  31320018
*                                  - NEXT START UP                      31380018
         SPACE                                                          31440018
         BZ    SOEOD          STARTING NEW OR FINISHED WITH CURRENT     31500018
*                             - DATA SET, MAKE SURE THAT ALL DATA WAS   31560018
*                             - TRANSMITTED.                            31620018
         SPACE 2                                                        31680018
*********************************************************************** 31740018
*---------------------------------------------------------------------* 31800018
*-*******************************************************************-* 31860018
*-*                                                                 *-* 31920018
*-*            P R O C E S S   O U T P U T   D A T A                *-* 31980018
*-*                                                                 *-* 32040018
*-*******************************************************************-* 32100018
*---------------------------------------------------------------------* 32160018
*********************************************************************** 32220018
         SPACE                                                          32280018
         TM    TDIRSWCH+2,TDIRBUFN IS BUFFER EMPTY                      32340018
         BO    NOSAV               NO, DONT SAVE TTR                    32400018
         SPACE                                                          32460018
         MVC   TDIRDTTR(FOR),LWKTTR  SAVE CURRENT TTR FOR POSSIBLE      32520018
*                                    - DISCONTINUE                      32580018
         OI    TDIRSWCH+2,TDIRBUFN MARK BUFFER NOT EMPTY                32640018
         SPACE                                                          32700018
NOSAV    DS    0H             **** DEFINE TAG                           32760018
         TM    TDIRSWCH+2,TDIRHDRN IS HEADER REQUIRED                   32820018
         BO    NOHEAD              NO, GO PROCESS OUTPUT                32880018
         SPACE                                                          32940018
         OI    TDIRSWCH+2,TDIRHDRN INDICATE HEADER PROCESSED            33000018
         TM    TDIRSWCH+2,TDIRMCHN IS THIS A CPU WORK STATION           33060018
         BZ    HEAD2780            NO, GO PROCESS 2780 HEADER RQ'MENTS  33120018
         EJECT                                                          33180018
         SPACE 2                                                        33240018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 33300018
*                                                                     * 33360018
*              P R O C E S S   C P U   H E A D E R                    * 33420018
*                                                                     * 33480018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 33540018
         SPACE                                                          33600018
         LA    CBA,HDRLNG(BSA)     GET LENGTH OF HEADER                 33660018
         MVI   ZERO(BSA),SOH       PLACE SOH IN LINE BUFFER             33720018
         MVC   ONE(TRE,BSA),LWKID  PLACE DEVICE ID, CONTROL CHARACTER   33780018
*                                  - TYPE AND RECORD FORMAT IN HEADER   33840018
         MVI   ATE(BSA),STX        STANDARDIZE HEADER FORMAT WITH STX   33900018
         L     MRL,LWKRECSZ        GET LENGTH OF USER EXIT DATA         33960018
         CLI   LWKID,UXO           IS THIS USER EXIT OUTPUT             34020018
         BE    UXHEAD              YES, GO PROCESS USER EXIT HEADER     34080018
         SPACE                                                          34140018
         LR    MRL,LNG             GET MESSAGE LENGTH FOR CONVERT       34200018
         CLI   LWKID,MO            IS THIS MESSAGE OUTPUT               34260018
         BE    MSGHEAD             YES, GO PROCESS MSG OUTPUT HEADER    34320018
         SPACE                                                          34380018
         MVI   TRE(BSA),FB         SET RECORD FORMAT AS FIXED BLOCKED   34440018
         BAL   LNK,CHKRECSZ        DETERMINE BLOCKING SIZE FOR PUNCH OR 34500018
*                                  - PRINTER                            34560018
         SPACE                                                          34620018
UXHEAD   DS    0H             **** DEFINE TAG FOR BRANCHING             34680018
MSGHEAD  DS    0H             **** DEFINE TAG FOR BRANCHING             34740018
         SPACE                                                          34800018
         CVD   MRL,LWKDOUBL        CONVERT LENGTH TO PACKED DECIMAL     34860018
         UNPK  FOR(FOR,BSA),LWKDOUBL(ATE)    UNPACK LENGTH IN LINE BUFR 34920018
         BAL   LNK,OUTWCNT         SEND HEADER TO WORK STATION          34980018
         SPACE 2                                                        35040018
         OI    TDIRSWCH+2,TDIRBUFN MARK BUFFER NOT EMPTY                35100018
         SPACE                                                          35160018
NOHEAD   DS    0H             **** DEFINE TAG FOR BRANCHING             35220018
         TM    TDIRSWCH+2,TDIRMCHN IS THIS A CPU WORK STATION           35280018
         BZ    NOHEAD80            NO, PROCESS OUTPUT FOR 2780          35340018
         SPACE                                                          35400018
*       C H E C K   C P U   O U T P U T   T Y P E                       35460018
         SPACE                                                          35520018
HADHEAD  DS    0H            **** DEFINE TAG                            35580018
         CLI   LWKID,MO            HAVE MESSAGE OUTPUT                  35640018
         BE    SNDMSG              YES, HANDLE MESSAGE OUTPUT           35700018
         SPACE                                                          35760018
         CLI   LWKID,UXO           DO WE HAVE USER EXIT OUTPUT          35820018
         BE    HANDUX              YES, HANDLE USER EXIT DATA           35880018
         EJECT                                                          35940018
         SPACE 2                                                        36000018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 36060018
*                                                                     * 36120018
*        P R O C E S S   O U T P U T   D E S T I N E D   FOR   C P U  * 36180018
*           P R I N T E R   OR   P U N C H                            * 36240018
*                                                                     * 36300018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 36360018
         SPACE                                                          36420018
         CR    LNG,MRL             IS LENGTH LONGER THAN MAX SIZE       36480018
         BNH   NOTRUNC             NO, USE LENGTH PASSED FOR PACKING    36540018
         SPACE                                                          36600018
         LR    LNG,MRL             TRUNCATE LENGTH TO MAZIMUM DEVICE    36660018
         SPACE                                                          36720018
NOTRUNC  DS    0H             **** DEFINE TAG FOR BRANCHING             36780018
         SPACE                                                          36840018
         TM    TDIRRB,TDIRPUPN     DOES WORK STATION HAVE UNPACK OPTION 36900018
         BO    PACKIT              YES, SUPRESS BLANKS IN OUTPUT        36960018
         SPACE                                                          37020018
         BCTR  LNG,ZIP             DECREMENT LENGTH ONE FOR MOVE        37080018
         SPACE                                                          37140018
         EX    LNG,MOVREC          MOVE TEXT TO BUFFER                  37200018
         SPACE                                                          37260018
         LA    CBA,ZERO(MRL,CBA)   UPDATE CURRENT BUFFER LOCATION       37320018
         SPACE                                                          37380018
FINUP    DS    0H             **** DEFINE TAG                           37440018
         LA    GO,ZERO(MRL,CBA)    STEP ON RECORD PAST CURRENT LOCATION 37500018
         C     GO,LWKBFEND         IS THIS OUTSIDE LINE BUFFER LIMITS   37560018
         BNH   EXIT                NO, GO BACK AND GET MORE DATA        37620018
         SPACE                                                          37680018
         B     OUTWCTE             GO SEND DATA AND RETURN              37740018
         SPACE 2                                                        37800018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 37860018
*                                                                     * 37920018
*   C O M P R E S S / E X P A N D   O P T I O N   P R O C E S S O R   * 37980018
*                                                                     * 38040018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 38100018
         SPACE 2                                                        38160018
PACKIT   DS    0H             **** DEFINE TAG FOR BRANCHING             38220018
         SPACE                                                          38280018
         STM   LNG,CBA,LCBPARM1    PASS PARAMETERS TO PACK ROUTINE      38340018
         LR    PAR,LCB             GET PARAMETERS FOR PACK ROUTINE      38400018
         L     GO,PACKENTY         GET ADDRESS OF IHKCHPCK ENTRY ADDR   38460018
         L     GO,ZERO(GO)         GET IHKCHPCK ENTRY POINT             38520018
         BALR  BAC,GO              SUPRESS BLANKS IN RECORD             38580018
         SPACE                                                          38640018
         SR    BAC,BAC             CLEAR REGISTER                       38700018
         IC    BAC,ZERO(CBA)       GET LENGTH OF PACKED RECORD          38760018
         SPACE                                                          38820018
         LA    CBA,ZERO(BAC,CBA)   UPDATE LINE BUFFER ADDRESS           38880018
         B     FINUP               FINISH OUTPUT PROCESSING AND RETURN  38940018
         SPACE 2                                                        39060018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 39120018
*                                                                     * 39180018
*   C P U   U S E R   E X I T    O U T P U T   P R O C E S S O R      * 39240018
*                                                                     * 39300018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 39360018
         SPACE                                                          39420018
HANDUX   DS    0H             **** DEFINE TAG                           39480018
         LR    BAC,LNG             GET USER EXIT DATA LENGTH            39540018
         SRDL  BAC,D256            DIVIDE LENGTH BY 256 FOR MOVE        39600018
         SPACE                                                          39660018
         LTR   BAC,BAC                  HAVE 256 OR MORE BYTES          39720018
         BZ    MOVEUX                   NO SKIP 256 MOVE                39780018
         SPACE                                                          39840018
         MVC   ZERO(L256,CBA),ZERO(RAD) MOVE 256 BYTES OF USER EXIT OUT 39900018
         LA    CBA,SKIPD256(CBA)   UPDATE BUFFER LOCATION               39960018
         LA    RAD,SKIPD256(RAD)   UPDATE RECORD LOCATION               40020018
         SPACE                                                          40080018
MOVEUX   DS    0H             **** DEFINE TAG                           40140018
         SRL   GO,D24              GET REMAINDER IN LOW ORDER BYTE      40200018
         LTR   GO,GO                    HAVE ANY REMAINDER              40260018
         BZ    OUTWCTE             NO,SEND WHAT WE HAVE AND RETURN      40320018
         SPACE                                                          40380018
         EX    GO,MOVREC           MOVE REMAINDER INTO LINE BUFFER      40440018
         LA    CBA,ZERO(GO,CBA)    UPDATE BUFFER LOCATION               40500018
         SPACE                                                          40560018
         B     OUTWCTE             SEND WHAT WE HAVE AND RETURN         40620018
         EJECT                                                          40650021
         SPACE 2                                                        40680018
*********************************************************************** 40740018
*---------------------------------------------------------------------* 40800018
*-*******************************************************************-* 40860018
*-*                                                                 *-* 40920018
*-*    L I N E   B U F F E R   C L E A N - U P   P R O C E S S O R  *-* 40980018
*-*                                                                 *-* 41040018
*-*******************************************************************-* 41100018
*---------------------------------------------------------------------* 41160018
*********************************************************************** 41220018
         SPACE 2                                                        41280018
SOEOD    DS    0H            **** DEFINE TAG                            41340018
         NI    LCBNSWFL,LCBSWOFF   TURN OFF LCB SWITCHES                41400018
         NI    TDIRSWCH+2,TDIRHDRF SET HEADER REQUIRED FOR NEXT ENTRY   41460018
*                                  - FOR THIS LINE                      41520018
         OI    TDIRSWC,TDIRETXO   TURN ON ETX TO BE SENT SWITCH    000D 41550019
         TM    TDIRSWCH+2,TDIRBUFN IS THERE ANYTHING IN THE BUFFER      41580018
         BZ    EXIT                NO, EXIT TO                          41640018
         SPACE                                                          41700018
         TM    TDIRSWCH+2,TDIRMCHN IS WORK STATION CPU             000D 41750019
         BO    OUTWCTE             YES WRITE SEND OUTPUT TO CPU    000D 41800019
         SPACE                                                          41850019
         B     OUTWCNTE            NO SEND OUTPUT TO 2780               41900019
         SPACE 2                                                        42000019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 42050019
*                                                                     * 42100019
*   P R O C E S S   2 7 8 0   H E A D E R   R E Q U I R E M E N T S   * 42150019
*                                                                     * 42200019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 42250019
         SPACE 2                                                        42300019
HEAD2780 DS    0H             **** DEFINE TAG                           42350019
         BAL   LNK,CHKRECSZ        GET MAXIMUM RECORD LENGTH            42400019
         TM    TDIRSWC,TDIR2770   IS IT A 2770                     000D 42450019
         BO    WEOT               YES WRITE AN EOT                 000D 42500019
RETWEOT  EQU   *                                                   000D 42550019
         SPACE                                                          42600019
         CLI   LCBTYPLN,LCBMULPT   IS THIS A MULTIPOINT LINE            42650019
         BE    MULTHEAD            YES, SET UP FOR COMPONENT SELECTION  42700019
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 42750019
         BO    SELPUN              YES SELECT PRINTER OR PUNCH     000D 42800019
         SPACE                                                          42850019
         CLI   LWKID,PUNO          HAVE PUNCH OUTPUT                    42900019
         BE    SELPUN              YES, SELECT PUNCH WITH ESCAPE SEQ    42950019
*                                  - SEQUENCE BEFORE SENDING OUTPUT     43000019
         EJECT                                                          43050021
SKIPPUN  DS    0H             **** DEFINE TAG                           43100019
         MVI   ZERO(BSA),STX       INDICATE START OF TEXT               43150019
         LR    CBA,BSA             INITIALIZE FREE BUFFER AREA ADDRESS  43200019
         SR    CNT,CNT             INITIALIZE BUFFER RECORD COUNT       43250019
         SPACE                                                          43300019
         CLI   LWKCNTRL,NCC        DATA CONTAIN OWN CARRIAGE CONTROL    43350019
         BNE   NOHEAD80            YES, PROCESS INITIAL CARRIAGE CNTRL  43400019
         SPACE                                                          43450019
         MVC   ONE(TRE,CBA),SKIPIT MOVE IN ESCAPE SEQUENCE TO SKIP TO   43500019
*                                  - CHANNEL ONE                        43550019
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 43600019
         BZ    FORGETIT            NO FORGET OVERLAY               000D 43650019
         MVI   TRE(CBA),IRS        OVERLAY US WITH IRS             000D 43700019
FORGETIT DS    0H                                                  000D 43750019
         LA    CNT,ONE(CNT)        UPDATE BUFFER RECORD COUNT           43800019
         LA    CBA,TRE(CBA)        UPDATE FREE BUFFER AREA ADDRESS      43850019
         SPACE 2                                                        43900019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 43950019
*                                                                     * 44000019
*    C H E C K   FOR   P U N C H   OR   P R I N T E R   O U T P U T   * 44050019
*                                                                     * 44100019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 44150019
         SPACE                                                          44200019
NOHEAD80 DS    0H             **** DEFINE TAG                           44250019
         CR    LNG,MRL             DATA LENGTH GREATER THAN DEVICE SIZE 44300019
         BNH   NOCHANG             NO, DO NOT TRUNCATE DATA LENGTH      44350019
         SPACE                                                          44400019
         LR    LNG,MRL             TRUNCATE DATA LENGTH TO DEVICE SIZE  44450019
         SPACE                                                          44500019
NOCHANG  DS    0H             **** DEFINE TAG                           44550019
         CLI   LWKID,PUNO          HAVE OUTPUT FOR PUNCH                44600019
         BE    PUNCH80             YES, PROCESS PUNCH OUTPUT            44650019
         EJECT                                                          44700019
         SPACE 2                                                        44750019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 44800019
*                                                                     * 44850019
*        P R O C E S S   2 7 8 0   P R I N T E R   O U T P U T        * 44900019
*                                                                     * 44950019
*           S T A R T   BY   S U P P R E S S I N G                    * 45000019
*        T R A I L I N G   B L A N K S   IN THE   O U T P U T         * 45050019
*                                                                     * 45100019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 45150019
         SPACE                                                          45200019
         LA    GO,ZERO(LNG,RAD)    GET END OF DATA ADDRESS              45250019
         SPACE                                                          45300019
GOTOIT   DS    0H             **** DEFINE TAG                           45350019
         BCTR  GO,ZIP              GET ADDRESS OF BYTE TO BE CHECKED    45400019
         CLI   ZERO(GO),BLNK       BYTE CONTAIN BLANK CHARACTER         45450019
         BNE   DUNIT               NO, HAVE FOUND LAST NONBLANK - EXIT  45500019
         SPACE                                                          45550019
         BCT   LNG,GOTOIT          REDUCE DATA LENGTH AND CHECK NEXT    45600019
*                                  - BYTE IF NOT ALL DATA CHECKED       45650019
         SPACE                                                          45700019
         LA    LNG,ONE             NEED AT LEAST ONE DATA CHARACTER     45750019
         SPACE                                                          45800019
DUNIT    DS    0H             **** DEFINE TAG                           45850019
         BAL   LNK,CHKBUF          HANDLE BUFFER MANAGEMENT             45900019
         SPACE 2                                                        45950019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 46000019
*                                                                     * 46050019
*    N E E D   TO   P R O C E S S   C A R R I A G E   C O N T R O L   * 46100019
*                  C H A R A C T E R S   IN THE   D A T A             * 46150019
*                                                                     * 46200019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 46250019
         SPACE                                                          46300019
         CLI   LWKCNTRL,NCC        CONTROL CHAR ABSENT FROM DATA        46350019
         BNE   CNVTCC              NO, CONVERT CARRIAGE CONTROL TO 2780 46400019
*                                  - EQUIVALENT                         46450019
         SPACE                                                          46500019
         BCTR  RAD,ZIP             STEP BACK RECORD ADDRESS             46550019
         EJECT                                                          46570021
         SPACE 2                                                        46600019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 46650019
*                                                                     * 46700019
* P R O C E S S   D A T A   WITHOUT   C A R R I A G E   C O N T R O L * 46750019
*                                                                     * 46800019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 46850019
         SPACE                                                          46900019
DEFAULT  DS    0H             **** DEFINE TAG                           46950019
         MVC   ONE(TWO,CBA),ESCS   MOVE IN SINGLE SPACE ESCAPE SEQUENCE 47000019
         LA    CBA,TRE(CBA)        UPDATE FREE BUFFER AREA ADDRESS      47050019
         SPACE                                                          47100019
CONTCC   DS    0H             **** DEFINE TAG                           47150019
         BCTR  LNG,ZIP             SET UP LENGTH FOR TRANSLATE FUNCTION 47200019
         SPACE 2                                                        47300019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 47350019
*                                                                     * 47400019
*   R E M O V E   B I S Y N C H   D A T A   L I N K   C O N T R O L   * 47450019
*        C H A R A C T E R S   FROM   P R I N T E R   O U T P U T     * 47500019
*                                                                     * 47550019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 47600019
         SPACE                                                          47650019
         LA    RAD,ONE(RAD)        STEP UP RECORD ADDRESS BY ONE        47700019
         L     BAC,TRTABAD         GET TRANSLATE TABLE ADDRESS          47750019
         EX    LNG,TRINST          BLANK DATA LINK CONTROL CHARACTERS   47800019
*                                  - IN DATA TO BE TRANSMITTED          47850019
         SPACE                                                          47900019
         EX    LNG,MOVREC          MOVE DATA TO LINE BUFFER             47950019
         SPACE                                                          48000019
         LA    CBA,ONE(LNG,CBA)    UPDATE FREE BUFFER AREA ADDRESS      48050019
         SPACE                                                          48100019
SKIPDATA DS    0H             **** DEFINE TAG                           48150019
         LA    CNT,ONE(CNT)        UPDATE BUFFER RECORD COUNT           48200019
         OI    TDIRSWCH+2,TDIRBUFN SET BUFFER NOT EMPTY INDICATOR       48250019
         MVI   ZERO(CBA),US        PLACE END OF RECORD IN LINE BUFFER   48300019
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 48350019
         BZ    NOT2770             NO FORGET IRS                   000D 48400019
         MVI   ZERO(CBA),IRS       USE IRS INSTEAD OF US           000D 48450019
NOT2770  DS    0H                                                  000D 48500019
         SPACE                                                          49140018
         CLI   LWKID,MO            IS THIS RJE MESSAGE OUTPUT           49200018
         BE    OUTWCNTE            YES, XMIT RJE MSG OUTPUT UNBLOCKED   49260018
         EJECT                                                          49290021
         SPACE 2                                                        49320018
*********************************************************************** 49380018
*---------------------------------------------------------------------* 49440018
*-*******************************************************************-* 49500018
*-*                                                                 *-* 49560018
*-*                 R E T U R N   L I N K A G E                     *-* 49620018
*-*                                                                 *-* 49680018
*-*******************************************************************-* 49740018
*---------------------------------------------------------------------* 49800018
*********************************************************************** 49860018
         SPACE 2                                                        49920018
EXIT     DS    0H             **** DEFINE TAG                           49980018
         TM    TDIRSWC,TDIR2770   TEST FOR 2770                    000D 49990019
         BO    WEOD               YES SEND STX-ETX SEQ TO DESELECT 000D 50000019
EXITA    EQU   *                                                        50010019
         SR    GO,GO               SET ZERO RETURN CODE                 50040018
         SPACE                                                          50100018
EXITERR  DS    0H            **** DEFINE TAG                            50160018
         NI    TDIRSWC,TDIRWACF    TURN OFF WACK FLAG              000E 50190018
         NI    TDIRSWC,TDIRETXF   TURN OFF END OF TEXT CHAR INDIC  000D 50200019
         STM   CBA,MRL,LWKORTSV    SAVE LINE BUFFER AND DATA INFO       50220018
         LM    LNK,BAC,LWKSAVE     RESTORE IHKABLWR REGS                50280018
         BR    BAC                                                      50340018
         EJECT                                                          50400018
         SPACE 2                                                        50460018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 50520018
*                                                                     * 50580018
*            P R O C E S S   C A R R I A G E   C O N T R O L          * 50640018
*                 C H A R A C T E R S   IN   D A T A                  * 50700018
*                                                                     * 50760018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 50820018
         SPACE                                                          50880018
CNVTCC   DS    0H             **** DEFINE TAG                           50940018
         BAL   LNK,DOCNVRT         GET ADDRESS OF 2780 EQUIVALENT FOR   51000018
*                                  - ASA OR MACHINE CODE CARRIAGE CNTRL 51060018
         BCT   LNG,HAVEONE         REDUCE RECORD LENGTH BY ONE          51120018
         SPACE                                                          51180018
         LA    LNG,ONE             NEED AT LEAST ONE DATA CHARACTER     51240018
         SPACE                                                          51300018
HAVEONE  DS    0H             **** DEFINE TAG                           51360018
         LTR   GO,GO               DEFAULT CARRIAGE CONTROL SUFFICIENT  51420018
         BZ    DEFAULT             YES, HANDLE DATA AS NO CARRIAGE      51480018
*                                  - CONTROL CHARACTER PRESENT          51540018
         SPACE                                                          51600018
         MVI   ONE(CBA),ESC                                             51660018
         MVC   TWO(ONE,CBA),ZERO(GO) MOVE EQUIVALENT 2780 CARRIAGE      51720018
*                                  - CONTROL IN ESCAPE SEQUENCE         51780018
         LA    CBA,TRE(CBA)        UPDATE FREE BUFFER AREA ADDRESS      51840018
         CLI   LWKCNTRL,MC         IS CONTROL CHARACTER MACHINE CODE    51900018
         BNE   DOASA               NO, HANDLE ASA CODE                  51960018
         SPACE                                                          52020018
         TM    ZERO(RAD),IMMEDOP   DO WE HAVE AN IMMEDIATE OPERATION    52080018
         BNO   CONTCC              NO, PLACE DATA IN LINE BUFFER        52140018
         SPACE                                                          52200018
         B     SKIPDATA            FORGET DATA BUT EXECUTE CONTROL FUNC 52260018
         SPACE                                                          52320018
DOASA    DS    0H            **** DEFINE TAG                            52380018
         MVI   ZERO(CBA),US        SET END OF RECORD IN LINE BUFFER     52440018
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 52480019
         BZ    NOT2770A            NO FORGET IRS                   000D 52520019
         MVI   ZERO(CBA),IRS       USE IRS INSTEAD OF US           000D 52560019
NOT2770A DS    0H                                                  000D 52600019
         LA    CNT,ONE(CNT)        UPDATE BUFFER RECORD COUNT           52640019
         LA    LNK,DEFAULT         GET RETURN FOR BUFFER CHECKING ROUT. 52680019
         EJECT                                                          52720019
         SPACE 2                                                        52760019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 52800019
*                                                                     * 52840019
*    H A N D L E  2780/2770  B U F F E R  M A N A G E M E N T         * 52880019
*                                                                     * 52920019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 52960019
         SPACE 2                                                        53000019
CHKBUF   DS    0H             **** DEFINE TAG                           53040019
         LA    GO,SEV              ASSUME 2780 WITH MULTIPLE RECORD     53080019
*                                  - TRANSMISSION FEATURE               53120019
         TM    TDIRRB,TDIRMRTN     DOES 2780 HAVE FEATURE               53160019
         BO    HASIT               YES, USE SEVEN RECORD MAX FOR BUFFER 53200019
*                                  - RECORD CONTROL                     53240019
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 53280019
         BO    HASIT               THATS NICE USE SEVEN RECORDS MAX000D 53320019
         SPACE                                                          53360019
         LA    GO,TWO              NO, USE TWO RECORD MAX FOR BUFFER    53400019
*                                  - RECORD CONTROL                     53440019
         SPACE                                                          53480019
HASIT    DS    0H             **** DEFINE TAG                           53520019
         CR    GO,CNT              BUFFER RECORD COUNT MET              53560019
         BNH   OUTWCNT             YES, EMPTY BUFFER BEFORE CONTINUING  53600019
         SPACE                                                          53640019
         L     ZIP,LWKBFEND        GET BUFFER END ADDRESS               53680019
         SR    ZIP,CBA             GET REMAINING FREE SPACE IN BUFFER   53720019
         CR    ZIP,LNG             CAN LINE BUFFER HOLD THIS RECORD     53760019
         BL    OUTWCNT             NO, SEND WHAT WE HAVE IN LINE BUFFER 53800019
         SPACE                                                          53840019
         BR    LNK                 PLACE RECORD IN LINE BUFFER          53880019
         EJECT                                                          53920019
         SPACE 2                                                        53960019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 54000019
*                                                                     * 54040019
*     D E T E R M I N E   M A X I M U M   R E C O R D   L E N G T H   * 54080019
*                                                                     * 54120019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 54160019
         SPACE 2                                                        54200019
CHKRECSZ DS    0H             **** DEFINE TAG                           54240019
         LA    MRL,PUNLNG          GET MAXIMUM PUNCH RECORD LENGTH      54280019
         CLI   LWKID,PUNO          IS THIS PUNCH OUTPUT                 54320019
         BE    CKTERM              YES, CHECK FOR CONTROL CHARACTER     54360019
         SPACE                                                          54400019
         SR    MRL,MRL             CLEAR REGISTER                       54440019
         IC    MRL,TDIRPRNT        GET MAXIMUM PRINT DATA RECORD LENGTH 54480019
         LA    MRL,ONE(MRL)        ALLOW FOR CARRIAGE CONTROL CHARACTER 54520019
CKTERM   DS    0H             **** DEFINE TAG                           54560019
         SPACE                                                          54600019
         CLI   LWKCNTRL,NCC        IS CONTROL CHARACTER PART OF RECORD  54640019
         BNE   ALLOWCC             YES, ALLOW RECORD LENGTH PLUS ONE    54680019
         SPACE                                                          54720019
         BCTR  MRL,ZIP             DISCARD POSSIBILITY OF CONTROL CHAR  54760019
         SPACE                                                          54800019
ALLOWCC  DS    0H             **** DEFINE TAG                           54840019
         SR    GO,GO               CLEAR REGISTER                       54880019
         C     GO,LWKRECSZ         IS RECORD LENGTH ZERO                54920019
         BCR   EQ,LNK              YES, USE DEVICE SIZE FOR BLOCKING    54960019
         SPACE                                                          55000019
         CR    MRL,LNG             IS RECORD LENGTH TO BIG FOR DEVICE   55040019
         BCR   LO,LNK              YES, USE DEVICE SIZE FOR BLOCKING    55080019
         SPACE                                                          55120019
         LR    MRL,LNG             USED FIXED RECORD LENGTH FOR BLOCK   55160019
         BR    LNK                 RETURN TO MAINLINE                   55200019
         SPACE 2                                                        55240019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 55280019
*                                                                     * 55320019
*      C O N V E R T   C A R R I A G E   C O N T R O L   TO THE       * 55360019
*             2 7 8 0   E Q U I V A L E N T                           * 55400019
*             2780/2770    E Q U I V A L E N T                        * 55440019
*                                                                     * 55480019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 55520019
         SPACE 2                                                        55560019
DOCNVRT  DS    0H             **** DEFINE TAG                           55600019
         SR    GO,GO               SET DEFAULT 2780 CARRIAGE CONTROL    55640019
*                                  - SUFFICIENT                         55680019
         CLI   LWKCNTRL,ASA        NEED TO CONVERT ASA CONTROL CHAR     55720019
         BE    HAVEASA             YES, CONVERT ASA TO 2780 EQUIVALENT  55760019
         EJECT                                                          55800019
         SPACE 2                                                        55840019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 55880019
*                                                                     * 55920019
*    C O N V E R T  M A C H I N E  C O D E  T O 2 7 8 0 / 2 7 7 0     * 55960019
*                                                                     * 56000019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 56040019
         SPACE 2                                                        56080019
         TM    ZERO(RAD),SKIPOPR   IS THIS A SKIP OPERATION             56120019
         BO    SKIPTO8             CONVERT SHIP OPERATION TO 2780 EQUI. 56160019
         SPACE                                                          56200019
         LA    GO,MCCSPOP          GET ADDRESS OF 2780 EQUIVALENT SPACE 56240019
*                                  - OPERATIONS                         56280019
         TM    ZERO(RAD),WRTSP3    CHECK FOR WRITE  AND TRIPLE SPACE    56320019
         BCR   ON,LNK              IT IS, SELECT 2780 TS EQUIVALENT     56360019
         SPACE                                                          56400019
         BCTR  GO,ZIP              SELECT WRITE AND DOUBLE SPACE        56440019
         TM    ZERO(RAD),WRTSP2    CHECK FOR WRITE AND DOUBLE SPACE     56480019
         BCR   ON,LNK              IT IS, SELECT 2780 DS EQUIVALENT     56520019
         SPACE                                                          56560019
         BCTR  GO,ZIP              DEFAULT TO WRITE AND SINGLE SPACE    56600019
         BR    LNK                 RETURN                               56640019
         SPACE                                                          56680019
SKIPTO8  DS    0H             **** DEFINE TAG                           56720019
         LR    BAC,GO              AND ANOTHER                          56760019
         IC    GO,ZERO(RAD)        GET CARRIAGE CONTROL CHARACTER       56800019
         SLL   GO,SHIF25           GET RID OF SKIP INDICATOR            56840019
         SLDL  BAC,FOR             SEPARATE INCREMENT FROM CONTROL CHAR 56880019
         LA    GO,MCCSPOP          GET 2780 DEFAULT                000D 56920019
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 56960019
         BO    OVER                YES DONT USE DEFAULT            000D 57000019
         SR    GO,GO               SUB  REG                        000D 57040019
         CH    BAC,HALF08          IS CHANNEL SKIP MORE THAN EIGHT 000D 57080019
         BCR   HI,LNK              YES USE DEFAULT                 000D 57120019
OVER     DS    0H                                                  000D 57160019
         LA    GO,SKIPCNVT(BAC)    GET ADDRESS OF EQUIVALENT 2780 CNTRL 57200019
         BR    LNK                 RETURN WITH INFO                     57240019
         SPACE 2                                                        57280019
         EJECT                                                          57320019
         SPACE 2                                                        57360019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 57400019
*                                                                     * 57440019
*    C O N V E R T  A S A C O D E  T O  2 7 8 0 / 2 7 7 0             * 57480019
*                                                                     * 57520019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 57560019
         SPACE 2                                                        57600019
HAVEASA  DS    0H             **** DEFINE TAG                           57640019
         SPACE                                                          57680019
         CLI   ZERO(RAD),F0        CHECK ASA CONTROL CHARACTER TYPE     57720019
         BL    SPACEOP             HANDLE SPACE OPERATION               57760019
         SPACE                                                          57800019
         BH    SKIPOP              HANDLE SKIP OPERATION                57840019
         SPACE                                                          57880019
         LA    GO,ASADS            HAVE AN ASA DOUBLE SPACE OPERATION   57920019
*                                  - SINGLE SPACE PRINTER BEFORE        57960019
*                                  - SENDING OUTPUT TO 2780             58000019
         BR    LNK                                                      58040019
         SPACE                                                          58080019
SPACEOP  DS    0H             **** DEFINE TAG                           58120019
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 58160019
         BZ    OVERX               NO CONTINUE AS IF ITS A 2780    000D 58200019
         CLI   ZERO(RAD),ABLE      HAVE CHANNEL SKIP               000D 58240019
         BNL   SKIPOP              YES SKIP 10,11 OR 12            000D 58280019
OVERX    DS    0H                                                  000D 58320019
         CLI   ZERO(RAD),ASTIS     IS SPACE OPERATION ASA TRIPLE SPACE  58360019
         BCR   NE,LNK              NO, DEFAULT TO SINGLE SPACE          58400019
         SPACE                                                          58440019
         LA    GO,ASATS            DOUBLE SPACE PRINTER BEFORE SENDING  58480019
         BR    LNK                 - OUTPUT TO 2780                     58520019
         SPACE                                                          58560019
SKIPOP   DS    0H             **** DEFINE TAG                           58600019
         CLI   ZERO(RAD),F8        NEED TO SKIP PAST 8             000D 58640019
         BNH   DOALL               NO SKIP 2770 OR 2780            000D 58680019
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 58720019
         BCR   EQ,LNK              NO DONT SKIP 2780               000D 58760019
DOALL    DS    0H                                                  000D 58800019
         CLI   ZERO(RAD),CONE      SKIP CHANNEL 1 THRU 9           000D 58840019
         BNL   FRIGIT              YES SKIP THEM                   000D 58880019
         LA    GO,ABC+2            ASSUME CHANNEL 12               000D 58920019
         CLI   ZERO(RAD),CHARC     IS IT CHANNEL 12                000D 58960019
         BCR   EQ,LNK              VERY GOOD SKIP IT               000D 59000019
         BCTR  GO,ZIP              ASSUME CHANNEL 11               000D 59040019
         CLI   ZERO(RAD),CHARB     IS IT ELEVEN                    000D 59080019
         BCR   EQ,LNK              VERY GOOD SKIP IT               000D 59120019
         BCTR  GO,ZIP              ASSUME CHANNEL 10               000D 59160019
         CLI   ZERO(RAD),ABLE      IS IT TEN                       000D 59200019
         BCR   EQ,LNK              SKIP TO TEN                     000D 59240019
         SR    GO,GO               FORGET SUPPRESS SPACE           000D 59280019
         BR    LNK                 DONE IT HERE DOIT TOIT THERE    000D 59320019
FRIGIT   DS    0H                                                  000D 59360019
         SPACE                                                          59400019
         IC    GO,ZERO(RAD)        GET CONTROL CHARACTER                59440019
         LA    GO,ASACNVT(GO)      GET POSITION OF EQUIVALEN 2780       59480019
         BR    LNK                 - CARRIAGE CONTROL AND RETURN        59520019
         EJECT                                                          59560019
         SPACE 2                                                        59600019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 59640019
*                                                                     * 59680019
*    2780/2770  M U L T I P O I N T   C O N S I D E R A T I O N S     * 59720019
*                                                                     * 59760019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 59800019
         SPACE 2                                                        59840019
MULTHEAD DS    0H             **** DEFINE TAG                           59880019
         NI    TDIRSWCH+1,TDIRWRTF SET WRITE INITIAL TO FORCE COMPONENT 59920019
*                                  - SELECTION                          59960019
         TM    TDIRSWC,TDIR2770    IS IT A 2770                    000D 60000019
         BO    DONTF3IT            YES DONT PUT IN F3 CHAR         000D 60040019
         MVI   TDIRDFTM+1,PRTID    SELECT PRINTER WHILE SELECTING       60080019
         B     SKIPPUN             CONTINUE HEADER PROCESSING           60120019
DONTF3IT DS    0H                                                  000D 60160019
         MVI   TDIRDFTM+2,DC1      SELECT 2770 PRINTER             000D 60200019
         CLI   LWKID,PUNO          CHECK IF IT REALLY WANTS PUNCH  000D 60240019
         BNE   PUNITNOT            NO LEAVE IT A PRINTER           000D 60280019
         MVI   TDIRDFTM+2,DC2      NO SELECT A PUNCH               000D 60320019
PUNITNOT EQU   *                                                   000D 60360019
         B     SKIPPUN                                             000D 60400019
         SPACE 2                                                        60440019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 60480019
*                                                                     * 60520019
*        2 7 8 0   P U N C H   O U T P U T   P R O C E S S O R        * 60560019
*                                                                     * 60600019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 60640019
         SPACE 2                                                        60680019
PUNCH80  DS    0H             **** DEFINE TAG                           60720019
         MVC   ZERO(TRE,BSA),DLESTX MOVE IN DLE STX DATA LINK CONTROL   60760019
         MVC   TRE(L80,BSA),TWO(BSA) BLANK REMAINING BUFFER AREA        60800019
         SPACE                                                          60840019
         CLI   LWKCNTRL,NCC        CARRIAGE CONTROL ABSENT FROM DATA    60880019
         BE    NOCC                YES, FORGET CARRIAGE CONTROL PROCESS 60920019
         SPACE                                                          60960019
         LA    RAD,ONE(RAD)        SKIP OVER CARRIAGE CONTROL IN DATA   61000019
         BCTR  LNG,ZIP             FORGET CONTROL CHARACTER LENGTH      61040019
         SPACE                                                          61080019
NOCC     DS    0H             **** DEFINE TAG                           61120019
         LA    CBA,TWO(BSA)        UPDATE FREE BUFFER AREA ADDRESS      61160019
         BCTR  LNG,ZIP             DECREMENT LENGTH ONE FOR MOVE        61200019
         EX    LNG,MOVREC          MOVE PUNCH OUTPUT TO LINE BUFFER     61240019
         SPACE                                                          61280019
         LA    CBA,ATY(CBA)        UPDATE FREE BUFFER ADDRESS           61320019
         B     OUTWCTE             TRANSMIT DATA AND RETURN             61360019
         SPACE 2                                                        61400019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 61440019
*                                                                     * 61480019
*    2780 AND 2770      S E L E C T I O N P R O C E S S O R           * 61520019
*                                                                     * 61560019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 61600019
         SPACE 2                                                        61640019
SELPUN   DS    0H             **** DEFINE TAG                           61680019
         LA    CBA,TRE(BSA)        UPDATE FREE BUFFER AREA ADDRESS      61720019
         MVC   ZERO(TRE,BSA),SEQ4  PLACE ESCAPE SEQUENCE TO SELECT 2780 61760019
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 61800019
         BZ    OVARY               NO FORGET IT                    000D 61840019
         MVI   TWO(BSA),BLANK      STAMP OUT 2780 COMPONENT SELECT 000D 61880019
         CLI   LCBTYPLN,LCBMULPT   CHECK FOR MULTI DROP LINE       000D 61920019
         BE    OVARY               YES SKIP DEVICE SELECT CHAR     000D 61960019
         MVI   ONE(BSA),DC1        SELECT 2770 PRINTER             000D 62000019
         CLI   LWKID,PUNO          A PUNCH NEEDED                  000D 62040019
         BNE   OVARY               NO DONE SELECTING               000D 62080019
         MVI   ONE(BSA),DC2        SELECT A PUNCH                  000D 62120019
OVARY    DS    0H                                                  000D 62160019
*                                  - PUNCH IN LINE BUFFER               62200019
         LA    LNK,SKIPPUN         GET RETURN AFT SELCTING DVICE A35908 62240020
         B     OUTWCNT             SELECT PUNCH                         62280019
WEOT     EQU   *                                                   000D 62320019
         MVI   ZERO(BSA),STX      MOVEIN STX CHARACTER             000D 62420019
         MVI   ONE(BSA),ETX       MOVEIN ETX CHARACTER             000D 62520019
         LA    CBA,TWO(BSA)        SET BUFFER POINTER              000D 62620019
         LA    LNK,RETWEOT        SET RETURN ADDRESS               000D 62720019
         LA    LK2,OUTWANT        SET RETURN ADDRESS               000D 62820019
         B     SETUPT             GO SETUP FOR LINE I/O            000D 62920019
WEOD     EQU   *                                                        63020019
         TM    TDIRSWC,TDIRETXO   SHOULD STX ETX BE SENT           000D 63120019
         BZ    EXITA               NO RETURN NORMAL                000D 63220019
         MVI   ZERO(BSA),STX       MOVE IN STX CHARACTER           000D 63320019
         MVI   ONE(BSA),ETX        MOVE IN ETX CHARACTER           000D 63420019
         LA    CBA,TWO(BSA)        SET LENGTH PARAMETER            000D 63520019
         LA    LK2,OUTWANT         SET RETURN REG                  000D 63620019
         LA    LNK,EXITA           SET RETURN REG                  000D 63720019
         B     SETUPT              GO SET UP BUFFER AND DO WRITE   000D 63820019
         EJECT                                                          63960018
         SPACE 2                                                        64020018
*********************************************************************** 64080018
*---------------------------------------------------------------------* 64140018
*-*******************************************************************-* 64200018
*-*                                                                 *-* 64260018
*-*          C E N T R A L   C L O S E D O W N   H E A D E R        *-* 64320018
*-*             P R O C E S S O R   FOR   C P U                     *-* 64380018
*-*                                                                 *-* 64440018
*-*******************************************************************-* 64500018
*---------------------------------------------------------------------* 64560018
*********************************************************************** 64620018
         SPACE 2                                                        64680018
HANGITUP DS    0H             **** DEFINE TAG FOR BRANCHING             64740018
         LA    CBA,CHDR(BSA)       GET LENGTH OF CLOSEDOWN HEADER       64800018
         NI    LCBNSWFL,LCBSWOFF   TURN OFF LCB SWITCHES                64860018
         MVC   ZERO(CHDR,BSA),CLOS MOVE HEADER INTO LINE BUFFER         64920018
         SPACE 2                                                        64980018
*********************************************************************** 65040018
*---------------------------------------------------------------------* 65100018
*-*******************************************************************-* 65160018
*-*                                                                 *-* 65220018
*-*  N O N - T R A N S P A R E N T   W R I T E    P R O C E S S O R *-* 65280018
*-*                                                                 *-* 65340018
*-*******************************************************************-* 65400018
*---------------------------------------------------------------------* 65460018
*********************************************************************** 65520018
         SPACE 2                                                        65580018
OUTWCNTE DS    0H             **** DEFINE TAG                           65640018
         LA    LNK,EXIT            SET RETURN AS EXIT                   65700018
OUTWCNT  DS    0H             **** DEFINE TAG                           65760018
         BAL   LK2,SETUPNT         SET UP PARAMETERS FOR BTAM WRITE     65820018
OUTWANT  EQU   *                                                        65850019
         SPACE                                                          65880018
         TM    TDIRSWCH+1,TDIRWRTN IS INITIAL OPERATION REQUIRED        65940018
         BO    WRTTT               NO, DO WRITE CONTINUE                66000018
         SPACE                                                          66060018
         CLI   LCBTYPLN,LCBSWTCH   IS THIS A SWITCHED LINE              66120018
         BNE   WRTTI               NO, DO A WRITE INITIAL OPERATION     66180018
         EJECT                                                          66240018
         SPACE 2                                                        66300018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 66360018
*                                                                     * 66420018
*              W R I T E   E N Q U I R Y   O P E R A T I O N          * 66480018
*                                                                     * 66540018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 66600018
WRTENQ   DS    0H                                                  000D 66650019
         SPACE                                                          66700019
    WRITE      (1),TQ,MF=E         WRITE ENQ TO BID FOR THE LINE        66750019
         SPACE                                                          66800019
         BAL   LK2,CHKOUT          CHECK OUT WRITE FOR ERROR            66850019
         TM    TDIRSWC,TDIRWCOF    WAS WACK RECEIVED BEFORE        000D 66900019
         BO    WRTDUN1            YES PROCESS NEXT RECORD          000D 66950019
         SPACE 2                                                        67000019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 67050019
*                                                                     * 67100019
*          W R I T E   C O N T I N U E   O P E R A T I O N            * 67150019
*                                                                     * 67200019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 67250019
         SPACE                                                          67300019
WRTTT    DS    0H             **** DEFINE TAG                           67350019
         SPACE                                                          67400019
    WRITE      (1),TT,,(BSA),(CBA),MF=E      WRITE CONTINUE            *67450019
                                             - NONTRANSPARENT           67500019
         EJECT                                                          67520021
         SPACE 2                                                        67550019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 67600019
*                                                                     * 67650019
*           P O S T   B T A M   W R I T E   P R O C E S S I N G       * 67700019
*                                                                     * 67750019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 67800019
         SPACE 2                                                        67850019
WRTDUN   DS    0H             **** DEFINE TAG                           67900019
         BAL   LK2,CHKOUT          CHECK OUT WRITE FOR ERRORS           67950019
WRTDUN1  DS    0H                                                  000D 68000019
         SPACE                                                          68050019
         OI    TDIRSWCH+1,TDIRWRTN SET WRITE CONTINUE REQUIRED          68100019
         SPACE                                                          68150019
         TM    TDIRSWCH+2,TDIRMCHN IS THIS A 2780 WORK STATION          68200019
         BZ    BUF80               YES, PROCESS 2780 BUFFER REQ'MENTS   68250019
         SPACE 2                                                        68350019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 68400019
*                                                                     * 68450019
*   H A N D L E   C P U   B U F F E R   R E Q U I R E M E N T S       * 68500019
*                                                                     * 68550019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 68600019
         SPACE                                                          68650019
         MVC   ZERO(TRE,BSA),DLESTX MOVE IN DLE STX DATA LINK CONTROL   68700019
         MVC   TRE(L200,BSA),TWO(BSA) BLANK SOME OF LINE BUFFER         68750019
         MVC   D203(L199,BSA),D202(BSA) BLANK REMAINING LINE BUFFER     68800019
         SPACE                                                          68850019
         LA    CBA,TWO(BSA)        UPDATE FREE BUFFER AREA ADDRESS      68900019
         BR    LNK                 RETURN TO OUTPUT PROCESSING          68950019
         SPACE 2                                                        69000019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 69050019
*                                                                     * 69100019
*     H A N D L E   2 7 8 0   B U F F E R   R E Q U I R E M E N T S   * 69150019
*                                                                     * 69200019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 69250019
         SPACE                                                          69300019
BUF80    DS    0H             **** DEFINE TAG                           69350019
         LR    CBA,BSA             INITIALIZE FREE BUFFER AREA ADDRESS  69400019
         SR    CNT,CNT             INITIALIZE BUFFER RECORD COUNT       69450019
         MVC   TDIRDTTR(FOR),LWKTTR SAVE CURRENT TTR FOR POSSIBLE DSCNT 69500019
         MVI   ZERO(BSA),STX       PLACE DATA LINK CONTROL IN BUFFER    69550019
         BR    LNK                 RETURN TO OUTPUT PROCESSING          69600019
         EJECT                                                          69620021
         SPACE 2                                                        69650019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 69700019
*                                                                     * 69750019
*            W R I T E   I N I T I A L   O P  E R A T I O N           * 69800019
*                                                                     * 69850019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 69900019
         SPACE                                                          69950019
WRTTI    DS    0H             **** DEFINE TAG                           70000019
         SPACE                                                          70050019
    WRITE      (1),TI,,(BSA),(CBA),(BAC),,MF=E    WRITE INITIAL        *70100019
                                                  - NONTRANSPARENT      70150019
         SPACE                                                          70200019
         B     WRTDUN              CHECK OUT WRITE                      70250019
         SPACE 2                                                        70300021
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 70350019
*                                                                     * 70400019
*      C P U   M E S S A G E   O U T P U T   P R O C E S S O R        * 70450019
*                                                                     * 70500019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 70550019
         SPACE                                                          70600019
SNDMSG   DS    0H             **** DEFINE TAG                           70650019
         EX    LNG,MOVREC          MOVE MESSAGE INTO LINE BUFFER        70700019
         LA    CBA,STY(CBA)        UPDATE BUFFER ADDRESS                70750019
         EJECT                                                          70770021
         SPACE 2                                                        70800019
*********************************************************************** 70850019
*---------------------------------------------------------------------* 70900019
*-*******************************************************************-* 70950019
*-*                                                                 *-* 71000019
*-*      T R A N S P A R E N T   W R I T E   P R O C E S S O R      *-* 71050019
*-*                                                                 *-* 71100019
*-*******************************************************************-* 71150019
*---------------------------------------------------------------------* 71200019
*********************************************************************** 71250019
         SPACE 2                                                        71300019
OUTWCTE  DS    0H             **** DEFINE TAG                           71350019
         LA    LNK,EXIT            SET EXIT AS RETURN                   71400019
         SPACE                                                          71450019
OUTWCT   DS    0H             **** DEFINE TAG                           71500019
         BAL   LK2,SETUPT          SET UP PARMS FOR BTAM WRITE          71550019
         SPACE                                                          71600019
         TM    TDIRSWCH+1,TDIRWRTN IS INITIAL OPERATION REQUIRED        71650019
         BO    WRTTTX              NO, DO A WRITE CONTINUE              71700019
         TM    TDIRSWC,TDIR2770    IS THIS A 2770                  000D 71750019
         BZ    NOTRUE              NO FORGET IT DO 2780            000D 71800019
         MVI   TDIRDFTM+2,DC2      SELECT A 2770 PUNCH             000D 71850019
         B     WRTTIX              GO TELL 2770 THE GOOD NEWS      000D 71900019
NOTRUE   DS    0H                                                  000D 71950019
         SPACE                                                          72000019
         MVI   TDIRDFTM+1,PUNID    PLACE PUNCH SELECTION IN DEFINE      72050019
*                                  - TERMINAL LIST                      72100019
         SPACE 2                                                        72150019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 72200019
*                                                                     * 72250019
*            W R I T E   I N I T I A L   O P E R A T I O N            * 72300019
*                                                                     * 72350019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 72400019
WRTTIX   DS    0H                                                  000D 72450019
         SPACE                                                          73080018
         WRITE  (1),TIE,,(BSA),(CBA),(BAC),,MF=E  WRITE INITIAL    000D*73140019
                                                  - TRANSPARENT         73200018
         SPACE                                                          73260018
         B     WRTDUN              CHECK OUT WRITE OPERATION            73320018
         EJECT                                                          73380018
         SPACE 2                                                        73440018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 73500018
*                                                                     * 73560018
*          W R I T E   C O N T I N U E   O P E R A T I O N            * 73620018
*                                                                     * 73680018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 73740018
         SPACE 2                                                        73800018
WRTTTX   DS    0H             **** DEFINE TAG                           73860018
         SPACE                                                          73920018
         WRITE  (1),TTE,,(BSA),(CBA),MF=E     WRITE CONTINUE       000D*73980019
                                                  - TRANSPARENT         74040018
         SPACE                                                          74100018
         B     WRTDUN              CHECK OUT WRITE OPERATION            74160018
         SPACE 2                                                        74220018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 74280018
*                                                                     * 74340018
*      S E T U P   B T A M   W R I T E   P A R A M E T E R S          * 74400018
*                                                                     * 74460018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 74520018
         SPACE 2                                                        74580018
SETUPNT  DS    0H             **** DEFINE TAG                           74640018
         TM    TDIRSWC,TDIR2770    TEST FOR 2770                   000D 74650019
         BZ    NOITSNOT            NO SKIP MOVING IRS CHARACTER    000D 74660019
         MVI   ZERO(CBA),IRS       YES MOVE IN IRS CHAR FOR CARR   000D 74670019
         LA    CBA,ONE(CBA)        STEP BUFFER POINTER BY ONE      000E 74680018
         MVI   ZERO(CBA),ETB      MOVE IN END OF TEXT CHARACTER    000D 74682019
         TM    TDIRSWC,TDIRETXO   TEST IF END OF TEXT IS ON        000D 74684019
         BZ    OVERETX            NO DONT MOVE IN END OF TEXT CHAR 000D 74686019
NOITSNOT DS    0H                  ****DEFINE TAG                  000D 74706019
         MVI   ZERO(CBA),ETX       PLACE ENDING DATA LINK CONTROL AFTER 74726019
*                                  - DATA TO BE TRANSMITTED             74760018
OVERETX  EQU   *                                                        74790019
         LA    CBA,ONE(CBA)        UPDATE FREE BUFFER AREA ADDRESS      74820018
         SPACE                                                          74880018
SETUPT   DS    0H             **** DEFINE TAG                           74940018
         SR    CBA,BSA             COMPUTE DATA LENGTH                  75000018
         L     PAR,LCBLDECB        GET LINE DECB ADDRESS FROM LCB       75060018
         LA    BAC,TDIRDFTM        GET DEFINE TERMINAL LIST ADDRESS     75120018
         BR    LK2                 RETURN AND SEND DATA                 75180018
         EJECT                                                          75240018
         SPACE 2                                                        75300018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 75360018
*                                                                     * 75420018
*    D E T E R M I N E   S U C C E S S   OR   F A I L U R E   OF      * 75480018
*           W R I T E   O P E R A T I O N   E X E C U T E D           * 75540018
*                                                                     * 75600018
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 75660018
         SPACE                                                          75720018
CHKOUT   DS    0H             **** DEFINE TAG                           75780018
         NI    TDIRSWCH+2,TDIRBUFF SET LINE BUFFER EMPTY                75840018
         LTR   GO,GO               WAS IT A GOOD START I/O              75900018
         BNZ   OUTERR              NO, CHECK OUT ERROR                  75960018
         SPACE                                                          76020018
         L     GO,LWKADISP         GET RJE DISPATCHER ENTRY POINT       76080018
         BALR  BAC,GO              WAIT FOR I/O COMPLETION IN DISP      76140018
         SPACE                                                          76200018
         CLI   DECSDECB,NORMAL     NORMAL COMPLETION                    76260018
         BNE   HADERR              NO, CHECK OUT ERROR                  76320018
         SPACE                                                          76380018
         SR    ZIP,ZIP             SET DISCONTINUE INDICATION           76440018
         CLI   DECRESPN,EOT        WHAT CAUSED NORMAL COMPLETION, EOT   76500018
*                                  - NAK, ACK0-1,OR WACK           000D 76540019
         LA    GO,FIFTEEN          SET COUNT FOR NUMBER OF RETRYS  000D 76580019
         BL    TSTMOR              HAD POSITIVE ACKNOWLEDGEMENT    000D 76620019
         SPACE                                                          76660019
         BE    DISCONT             HAD EOT RESPONSE, DISCONTINUE OUTPUT 76700019
         SPACE 2                                                        76740019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 76780019
*                                                                     * 76820019
*      I N T E R N A L   D I S C O N T I N U E   P R O C E S S O R    * 76860019
*                                                                     * 76900019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 76940019
         SPACE                                                          76980019
INTLDIS  DS    0H             **** DEFINE TAG                           77020019
         LNR   ZIP,BAS             HAD NEGATIVE ACKNOWLEDGEMENT OR      77060019
*                                  - CONTENTION, SET INTERNAL DISCONT.  77100019
         EJECT                                                          77120021
         SPACE 2                                                        77140019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 77180019
*                                                                     * 77220019
*              D I S C O N T I N U E   O U T P U T                    * 77260019
*                                                                     * 77300019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 77340019
         SPACE                                                          77380019
         SPACE                                                          77420019
DISCONT  DS    0H             **** DEFINE TAG                           77460019
         LTR   LNG,LNG             CLOSEDOWN PROCESSING                 77500019
         BM    EXIT                YES, IGNORE ERROR AND DO GOOD RETURN 77540019
         SPACE                                                          77580019
         ST    ZIP,LCBPARM1        PASS RETURN INFO ON BAD RETURN       77620019
         NI    TDIRSWCH+2,TDIRHDRF SET HEADER REQUIRED INDICATOR        77660019
         LA    GO,FOR              SET ERROR INDICATOR                  77700019
         B     EXITERR             RETURN WITH ERROR                    77740019
         SPACE 2                                                        77820019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 77860019
*                                                                     * 77900019
*         C H E C K O U T   E R R O R   R E C O V E R Y               * 77940019
*                                                                     * 77980019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 78020019
         SPACE 2                                                        78060019
HADERR   DS    0H             **** DEFINE TAG                           78100019
         CLI   DECSDECB,IOERR      IS I/O ERROR INDICATED               78140019
         BNE   OUTERR              NO, GO DO AN LINE ERROR RJEND        78180019
         SPACE                                                          78220019
         TM    DECFLAGS,CONTENT    IS THIS CONTENTION                   78260019
         BO    INTLDIS             YES, SET INTERNAL DISCONTINUE IND.   78300019
         CLI   DECRESPN,NAK       CHECK FOR NAK RESPONSE TO        000D 78340019
*                                  SELECTION                       000D 78380019
         BNE   OUTERR             NO NAK DO RJENDF                 000D 78420019
         CLI   DECTYPE,WTI         YES CHECK IF WRITE IS NON-TRANS 000D 78460019
         BE    WRTTI              PARENT YES DO WRITE TI           000D 78500019
         CLI   DECTYPE,WTIX        IS IT A TRANSPARENT WRITE       000D 78540019
         BE    WRTTIX             YES DO A WRITE TTIX              000D 78580019
*                                  NO DO RJENDF                    000D 78620019
         EJECT                                                          78640021
         SPACE 2                                                        78660019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 78700019
*                                                                     * 78740019
*              L I N E   E R R O R   P R O C E S S O R                * 78780019
*                                                                     * 78820019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 78860019
         SPACE                                                          78900019
OUTERR   DS    0H             **** DEFINE TAG                           78940019
         LA    ZIP,RJENDF          SET LINE ERROR INDICATOR             78980019
         B     DISCONT             RETURN WITH ERROR                    79020019
BUF2770  LA    ZIP,TOT124(BSA)     GUESS IT IS A LITTLE BUFFER   A37778 79060020
         TM    TDIRSWC,TDIREB27    IS IT A BIGGY                   000D 79100019
         BZ    RESUME              NO GOOD GUESS                   000D 79140019
         LA    ZIP,TOT252(BSA)     BAD ITS A BIGGY               A37778 79180020
         B     RESUME              BACK TO MAINLINR                000D 79220019
         SPACE                                                          79228021
BUF2780  LA    ZIP,390(BSA)   SET 2780 BFR SIZE TO 390+CTLCHRS   A53110 79236021
         B     RESUME                                            A53110 79244021
         SPACE                                                          79252021
TSTMOR   DS    0H                                                  000D 79260019
         CLI   DECRESPN+1,WACK     WAS THE RESPONSE A WACK         000D 79300019
         BCR   NE,LK2              NO THANKS BE \3 ALI             000D 79340019
         CLI   DECTYPE,X'02'      CHECK FOR WRITE ININTIAL         000D 79380019
         BE    WRTTI              SELECTION IF SO RETRANSMIT       000D 79420019
         CLI   DECTYPE,X'12'      INITIAL SELECTION                000D 79460019
         BE    WRTTIX             NO TREAT AS NORMAL WACK          000D 79500019
         TM    TDIRSWC,TDIRWCOF    YES WAS IT RECEIVED BEFORE      000D 79540019
         BO    WACKIT              YES GO WRITE ENQ                000D 79580019
         LA    GO,FIFTEEN          SET COUNT FOR NUMBER OF RETRYS  000D 79620019
         ST    GO,LCBPARM3         SAVE THE BEAUTY FOR FUTHER REF  000D 79660019
         OI    TDIRSWC,TDIRWCON    SET SWITCH THAT WACK RECEIVED   000D 79700019
WACKIT   DS    0H                                                  000D 79740019
         L     GO,LCBPARM3         RELOAD NUMBER OF RETRYS LEFT    000D 79780019
         BCT   GO,TGIT             IF COUNT NOT ZERO GO DO WRT ENQ 000D 79820019
         B     OUTERR              COUNT ZERO ITS AN ERROR GIVE UP 000D 79860019
TGIT     DS    0H                                                  000D 79900019
         ST    GO,LCBPARM3         STORE COUNT FOR LATER REF       000D 79940019
         B     WRTENQ              GO DO WRITE ENQ                 000D 79980019
         EJECT                                                          80000021
         SPACE 2                                                        80020019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 80060019
*                                                                     * 80100019
*            E X E C U T E D   I N S T R U C T I O N S                * 80140019
*                                                                     * 80180019
*-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* *-* 80220019
         SPACE 2                                                        80260019
MOVREC   MVC   ZERO(ZERO,CBA),ZERO(RAD) MOVE DATA TO LINE BUFFER        80300019
         SPACE                                                          80340019
TRINST   TR    ZERO(ZERO,RAD),ZERO(BAC) REPLACE DATA LINK CONTROL       80380019
*                                       - CHARACTERS IN 2780 PRINTER    80420019
*                                       - OUTPUT WITH BLANKS            80460019
         SPACE                                                          80540019
*********************************************************************** 80580019
*---------------------------------------------------------------------* 80620019
*-*******************************************************************-* 80660019
*-*                                                                 *-* 80700019
*-*      C O N S T A N T S   U S E D   BY THIS   R O U T I N E      *-* 80740019
*-*                                                                 *-* 80780019
*-*******************************************************************-* 80820019
*---------------------------------------------------------------------* 80860019
*********************************************************************** 80900019
         SPACE 2                                                        80940019
TRTABAD  DC    A(IHKTRTAB)                                              80980019
PACKENTY DC    A(IHKADPCK)    IHKCHPCK ENTRY POINT ADDRESS              81020019
HALF08   DC    H'08'                                               000D 81060019
SKIPIT   DC    X'27C11F'      2780 SKIP TO CHANNEL ONE ESCAPE SEQUENCE  81100019
DLESTX   DC    X'100240'      DLE STX DATA LINK CONTROL PLUS A BLANK    81140019
CLOS     DC    X'01F502'     CPU CENTRAL CLOSEDOWN HEADER               81180019
SEQ4     DC    X'0227F4'      STX PLUS 2780 ESCAPE SEQUENCE TO SELECT   81220019
*                             - THE PUNCH TO RECEIVE OUTPUT             81260019
ESCS     DC    X'27'          2780 WRITE AND SPACE ONE ESCAPE SEQUENCE  81300019
ASADS    DC    C'/'                                                000D 81340019
ASATS    DS    0C             2780 TRIPLE SPACE AND WRITE ASA CODE      81380019
*                             - EQUIVALENT                              81420019
         DC    C'S'           2780 WRITE AND SPACE TWO MACHINE CODE     81460019
*                             - EQUIVALENT                              81500019
MCCSPOP  DC    C'T'           2780 WRITE AND SPACE THREE MACHINE CODE   81540019
*                             - EQUIVALENT                              81580019
         ORG   *-D241                                                   81620019
ASACNVT  DS    0C             BASE TO INDEX 2780 ASA CODE SKIP EQUIV.   81660019
         DS    240C           FILLER                                    81700019
SKIPCNVT DS    CL1                 BASE TO INDEX 2780/2770 MACHINE 000D 81740019
*                                  CODE CHANNEL                         81780019
         DC    C'ABCDEFGHI'        SKIP  EQUIVALENTS               000D 81820019
ABC      DC    C'JKL'                                              000D 81860019
LIST     DC    2F'00'                                                   82430018
OPEN     DC    X'00'                                                    82450018
         EJECT                                                          82560018
*********************************************************************** 82620018
*---------------------------------------------------------------------* 82680018
*-*******************************************************************-* 82740018
*-*                                                                 *-* 82800018
*-*       E M I T T O R   W O R K   A R E A   D S E C T             *-* 82860018
*-*                                                                 *-* 82920018
*-*      THIS WORKAREA DSECT IS USED BOTH BY IHKABLWR, IHKCHLWR,    *-* 82980018
*-*   AND IHKABORT.  IF THE WORKAREA IS CHANGED, THE CORRESPOND-    *-* 83040018
*-*   ING DSECT CHANGES MUST BE MADE TO ALL OF THESE MODULES.       *-* 83100018
*-*                                                                 *-* 83160018
*-*      THE WORKAREA IS GETMAINED BY IHKABLWR(MVT) OR IHKCHLWR(MFT)*-* 83220018
*-*   WHEN IHKABLST CALLS ON THIS ROUTINES TO PROCESS OUTPUT FOR    *-* 83280018
*-*   A PARTICULAR WORK STATION.  THIS AREA IS FREEMAINED WHEN      *-* 83340018
*-*   THERE IS NO MORE OUTPUT ON THE QUEUE TO BE PROCESSED AND      *-* 83400018
*-*   CONTROL IS RETURNED TO IHKABLST.                              *-* 83460018
*-*                                                                 *-* 83520018
*-*      THE SIZE OF THE AREA OBTAINED IS SPECIFIED WITH THE        *-* 83580018
*-*   EQUATED TAG, LWRSIZE, IN THE LWR MODULE.  AN INCREASE OR      *-* 83640018
*-*   DECREASE IN THE WORKAREA SIZE IS SPECIFIED BY REDEFINING      *-* 83700018
*-*   THIS SYMBOLIC TAG.                                            *-* 83760018
*-*                                                                 *-* 83820018
*-*******************************************************************-* 83880018
*---------------------------------------------------------------------* 83940018
*********************************************************************** 84000018
         SPACE                                                          84060018
         SPACE                                                          84120018
LWKWORK  DSECT                                                          84180018
LWKADFST DS    CL4                      ADDR OF FASTABLE ENTRY          84240018
LWKADJED DS    CL4                      ADDR OF CORE JED ENTRY          84300018
LWKADDSB DS    CL4                      ADDR OF DSB POINTING TO DATA    84360018
*                                         SET TO BE SCRATCHED           84420018
LWKDOUBL EQU   LWKADDSB                 DOUBLE WORD FOR DECIMAL CONVERT 84480018
LWKADQMP DS    CL4                      ADDR OF QUEUE MANAGER PARAMETER 84540018
*                                       AREA                            84600018
LWKADCBS DS    CL4                      A(IHKCDCBS)                     84660018
LWKADISP DS    CL4                      V(IHKAADSP)                     84720018
*                                         FIRST BIT-                    84780018
*                                           '1'-MSG                     84840018
*                                           '0'-BRDCST                  84900018
LWKMDQK  DS    CL4                      CONTROL VALUE                   84960018
LWKMDQIO DS    CL4                      ADDR OF 60 BYTE I/O AREA        85020018
LWKMDQTD DS    CL4                      ADDR OF TERMINAL DIRECTORY      85080018
*                                         ENTRY                         85140018
*                                         FIRST BIT-                    85200018
*                                           '1'-DO NOT DELETE TEXT      85260018
*                                           '0'-DELETE TEXT             85320018
LWKTIOTO DS    CL4                      ADDR OF OLD TIOT                85380018
LWKTIOTN DS    CL4                      ADDR OF NEW TIOT IN GETMAIN     85440018
LWKTIOTL DS    CL4                      NO. BYTES IN TIOT GETMAIN AREA  85500018
LWKADTCB DS    CL4                      ADDRESS OF TCB                  85560018
LWKSYSCT DS    C                        COUNTER OF 24 SYSOUT CLASSES    85620018
LWKID    DS    C                        IDENTIFIES DESTINATION DEVICE   85680018
LWKPRINH EQU   C'1'                       PRINTER                       85740018
LWKPUNCH EQU   C'2'                       PUNCH                         85800018
LWKEYBDH EQU   C'3'                       KEYBOARD                      85860018
LWKUSEXH EQU   C'4'                       USER EXIT                     85920018
LWKCNTRL DS    C                        IDENTIFIES CONTROL CHARACTERS   85980018
LWKMACHH EQU   C'1'                       MACHINE CODE                  86040018
LWKASACH EQU   C'2'                       ASA                           86100018
LWKNONEH EQU   C'3'                       NONE                          86160018
LWKRECFM DS    C                        RECORD FORMAT                   86220018
LWKFXUBH EQU   C'1'                       FIXED UNBLOCKED               86280018
LWKFXBLH EQU   C'2'                       FIXED BLOCKED                 86340018
LWKVAUBH EQU   C'3'                       VARIABLE UNBLOCKED            86400018
LWKVARBH EQU   C'4'                       VARIABLE BLOCKED              86460018
LWKUNDFH EQU   C'5'                       UNDEFINED                     86520018
LWKRECSZ DS    CL4                      RECORD SIZE(BINARY)             86580018
LWKTIME  DS    XL8                      TIME AND DATE             19018 86588018
LWKCOUNT DS    XL4                      SYSOUT COUNT              19018 86596018
LWKSTATS DS    XL1                      ERROR STATUS              19018 86604018
LWKIOERR EQU   X'04'                    ERROR INDICATOR           19018 86612018
LWKDS    DS    XL1                      DATA SET COUNT            19018 86620018
LWKPAD   DS    XL2                      UNUSED, NEEDED TO PAD     19018 86628018
LWKTTR   DS    CL4                      TTR OF LAST BLOCK OF SYSOUT     86640018
*                                         DATA JUST READ                86700018
LWKSAVE  DS    11CL4                    SAVE AREA FOR REGS 4-14         86760018
LWKSAVE6 DS    CL4                      HOLDS REG 6 DURING SMB HANDLER  86820018
LWKSTABF DS    CL4                      ADDR OF INPUT BUFFER            86880018
LWKENDBF DS    CL4                      ADDR OF 1ST BYTE BEYOND         86940018
LWKDTTR  DS    CL4                      TTR TO START READING            87000018
LWKBFEND DS    CL4                      ABOUT BUFFER END ADDRESS        87060018
LWKORTSV DS    CL12                     IHKABOUT BUFFER MANG INFO       87120018
         SPACE                                                          87180018
*********************************************************************** 87240018
         SPACE 2                                                        87300018
    IHKDSECT   TDIR,,,,LCB                                              87360018
         EJECT                                                          87420018
    IECTDECB                                                            87480018
         END                                                            87540018
